lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/container components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80032';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the callee.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@captures, \@arguments ] )
 425
 426 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 427
 428 The relationship between C<go> and
 429 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 430 the relationship between
 431 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 432 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 433 C<< $c->go >> will perform a full dispatch on the specified action or method,
 434 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 435 C<go> escapes the processing of the current request chain on completion, and
 436 does not return to its caller.
 437
 438 @arguments are arguments to the final destination of $action. @captures are
 439 arguments to the intermediate steps, if any, on the way to the final sub of
 440 $action.
 441
 442 =cut
 443
 444 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 445
 446 =head2 $c->response
 447
 448 =head2 $c->res
 449
 450 Returns the current L<Catalyst::Response> object, see there for details.
 451
 452 =head2 $c->stash
 453
 454 Returns a hashref to the stash, which may be used to store data and pass
 455 it between components during a request. You can also set hash keys by
 456 passing arguments. The stash is automatically sent to the view. The
 457 stash is cleared at the end of a request; it cannot be used for
 458 persistent storage (for this you must use a session; see
 459 L<Catalyst::Plugin::Session> for a complete system integrated with
 460 Catalyst).
 461
 462     $c->stash->{foo} = $bar;
 463     $c->stash( { moose => 'majestic', qux => 0 } );
 464     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 465
 466     # stash is automatically passed to the view for use in a template
 467     $c->forward( 'MyApp::View::TT' );
 468
 469 =cut
 470
 471 around stash => sub {
 472     my $orig = shift;
 473     my $c = shift;
 474     my $stash = $orig->($c);
 475     if (@_) {
 476         my $new_stash = @_ > 1 ? {@_} : $_[0];
 477         croak('stash takes a hash or hashref') unless ref $new_stash;
 478         foreach my $key ( keys %$new_stash ) {
 479           $stash->{$key} = $new_stash->{$key};
 480         }
 481     }
 482
 483     return $stash;
 484 };
 485
 486
 487 =head2 $c->error
 488
 489 =head2 $c->error($error, ...)
 490
 491 =head2 $c->error($arrayref)
 492
 493 Returns an arrayref containing error messages.  If Catalyst encounters an
 494 error while processing a request, it stores the error in $c->error.  This
 495 method should only be used to store fatal error messages.
 496
 497     my @error = @{ $c->error };
 498
 499 Add a new error.
 500
 501     $c->error('Something bad happened');
 502
 503 =cut
 504
 505 sub error {
 506     my $c = shift;
 507     if ( $_[0] ) {
 508         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 509         croak @$error unless ref $c;
 510         push @{ $c->{error} }, @$error;
 511     }
 512     elsif ( defined $_[0] ) { $c->{error} = undef }
 513     return $c->{error} || [];
 514 }
 515
 516
 517 =head2 $c->state
 518
 519 Contains the return value of the last executed action.
 520 Note that << $c->state >> operates in a scalar context which means that all
 521 values it returns are scalar.
 522
 523 =head2 $c->clear_errors
 524
 525 Clear errors.  You probably don't want to clear the errors unless you are
 526 implementing a custom error screen.
 527
 528 This is equivalent to running
 529
 530     $c->error(0);
 531
 532 =cut
 533
 534 sub clear_errors {
 535     my $c = shift;
 536     $c->error(0);
 537 }
 538
 539 =head2 COMPONENT ACCESSORS
 540
 541 =head2 $c->controller($name)
 542
 543 Gets a L<Catalyst::Controller> instance by name.
 544
 545     $c->controller('Foo')->do_stuff;
 546
 547 If the name is omitted, will return the controller for the dispatched
 548 action.
 549
 550 If you want to search for controllers, pass in a regexp as the argument.
 551
 552     # find all controllers that start with Foo
 553     my @foo_controllers = $c->controller(qr{^Foo});
 554
 555
 556 =cut
 557
 558 sub controller {
 559     my ( $c, $name, @args ) = @_;
 560     my $container = $c->container->get_sub_container('controller');
 561     unshift @args, $c;
 562
 563     if( $name ) {
 564         # Direct component hash lookup to avoid costly regexps
 565         return $container->get_component($name, \@args)
 566             if $container->has_service($name) && !ref $name;
 567
 568         return $container->get_component_regexp( $c, $name, \@args );
 569     }
 570
 571     return $c->component( $c->action->class );
 572 }
 573
 574 =head2 $c->model($name)
 575
 576 Gets a L<Catalyst::Model> instance by name.
 577
 578     $c->model('Foo')->do_stuff;
 579
 580 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 581
 582 If the name is omitted, it will look for
 583  - a model object in $c->stash->{current_model_instance}, then
 584  - a model name in $c->stash->{current_model}, then
 585  - a config setting 'default_model', or
 586  - check if there is only one model, and return it if that's the case.
 587
 588 If you want to search for models, pass in a regexp as the argument.
 589
 590     # find all models that start with Foo
 591     my @foo_models = $c->model(qr{^Foo});
 592
 593 =cut
 594
 595 sub model {
 596     my ( $c, $name, @args ) = @_;
 597     my $appclass = ref($c) || $c;
 598     my $container = $c->container->get_sub_container('model');
 599     unshift @args, $c;
 600
 601     if( $name ) {
 602         # Direct component hash lookup to avoid costly regexps
 603         return $container->get_component($name, \@args)
 604             if $container->has_service($name) && !ref $name;
 605
 606         return $container->get_component_regexp( $c, $name, \@args );
 607     }
 608
 609     if (ref $c) {
 610         return $c->stash->{current_model_instance}
 611           if $c->stash->{current_model_instance};
 612         return $c->model( $c->stash->{current_model} )
 613           if $c->stash->{current_model};
 614     }
 615     return $c->model( $appclass->config->{default_model} )
 616       if $appclass->config->{default_model};
 617
 618 # FIXME: will this still be mantained?
 619     my( $comp, $rest ) = $container->get_service_list;
 620
 621     if( $rest ) {
 622         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 623         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 624         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 625         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 626         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 627     }
 628
 629     return $container->get_component( $comp, \@args );
 630 }
 631
 632
 633 =head2 $c->view($name)
 634
 635 Gets a L<Catalyst::View> instance by name.
 636
 637     $c->view('Foo')->do_stuff;
 638
 639 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 640
 641 If the name is omitted, it will look for
 642  - a view object in $c->stash->{current_view_instance}, then
 643  - a view name in $c->stash->{current_view}, then
 644  - a config setting 'default_view', or
 645  - check if there is only one view, and return it if that's the case.
 646
 647 If you want to search for views, pass in a regexp as the argument.
 648
 649     # find all views that start with Foo
 650     my @foo_views = $c->view(qr{^Foo});
 651
 652 =cut
 653
 654 sub view {
 655     my ( $c, $name, @args ) = @_;
 656     my $appclass = ref($c) || $c;
 657     my $container = $c->container->get_sub_container('view');
 658     unshift @args, $c;
 659
 660     if( $name ) {
 661         if ( !ref $name ) { # Direct component hash lookup to avoid costly regexps
 662             if ( $container->has_service($name) ) {
 663                 return $container->get_component($name, \@args);
 664             }
 665             else {
 666                 $c->log->warn( "Attempted to use view '$name', but does not exist" );
 667             }
 668         }
 669
 670         return $container->get_component_regexp( $c, $name, \@args );
 671     }
 672
 673     if (ref $c) {
 674         return $c->stash->{current_view_instance}
 675           if $c->stash->{current_view_instance};
 676         return $c->view( $c->stash->{current_view} )
 677           if $c->stash->{current_view};
 678     }
 679     return $c->view( $appclass->config->{default_view} )
 680       if $appclass->config->{default_view};
 681
 682     my( $comp, $rest ) = $container->get_service_list;
 683
 684     if( $rest ) {
 685         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 686         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 687         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 688         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 689         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 690     }
 691
 692     return $container->get_component( $comp, \@args );
 693 }
 694
 695 =head2 $c->controllers
 696
 697 Returns the available names which can be passed to $c->controller
 698
 699 =cut
 700
 701 sub controllers {
 702     my ( $c ) = @_;
 703     return $c->container->get_sub_container('controller')->get_service_list;
 704 }
 705
 706 =head2 $c->models
 707
 708 Returns the available names which can be passed to $c->model
 709
 710 =cut
 711
 712 sub models {
 713     my ( $c ) = @_;
 714     return $c->container->get_sub_container('model')->get_service_list;
 715 }
 716
 717
 718 =head2 $c->views
 719
 720 Returns the available names which can be passed to $c->view
 721
 722 =cut
 723
 724 sub views {
 725     my ( $c ) = @_;
 726     return $c->container->get_sub_container('view')->get_service_list;
 727 }
 728
 729 =head2 $c->comp($name)
 730
 731 =head2 $c->component($name)
 732
 733 Gets a component object by name. This method is not recommended,
 734 unless you want to get a specific component by full
 735 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 736 should be used instead.
 737
 738 If C<$name> is a regexp, a list of components matched against the full
 739 component name will be returned.
 740
 741 If Catalyst can't find a component by name, it will fallback to regex
 742 matching by default. To disable this behaviour set
 743 disable_component_resolution_regex_fallback to a true value.
 744
 745     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 746
 747 =cut
 748
 749 sub component {
 750     my ( $c, $component, @args ) = @_;
 751     unshift @args, $c;
 752
 753     if ( $component ) {
 754         my ($type, $name) = _get_component_type_name($component);
 755
 756         if ($type && $c->container->has_sub_container($type)) {
 757             my $container = $c->container->get_sub_container($type);
 758
 759             if( !ref $component && $container->has_service($name) ) {
 760                 return $container->get_component( $name, \@args );
 761             }
 762
 763             return $container->get_component_regexp( $c, $name, \@args );
 764         }
 765
 766         return
 767             if $c->config->{disable_component_resolution_regex_fallback} && !ref $component;
 768
 769         # This is here so $c->comp( '::M::' ) works
 770         my $query = ref $component ? $component : qr{$component}i;
 771
 772         for my $subcontainer_name (qw/model view controller/) {
 773             my $subcontainer = $c->container->get_sub_container($subcontainer_name);
 774             my @components   = $subcontainer->get_service_list;
 775             my @result       = grep { m{$query} } @components;
 776
 777             if (@result) {
 778                 return map { $subcontainer->get_component( $_, \@args ) } @result
 779                     if ref $component;
 780
 781                 $c->log->warn( Carp::shortmess(qq(Found results for "${component}" using regexp fallback)) );
 782                 $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 783                 $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 784
 785                 return $subcontainer->get_component( $result[0], \@args );
 786             }
 787         }
 788
 789         # I would expect to return an empty list here, but that breaks back-compat
 790     }
 791
 792     # fallback
 793     return sort keys %{ $c->components };
 794 }
 795
 796 =head2 CLASS DATA AND HELPER CLASSES
 797
 798 =head2 $c->config
 799
 800 Returns or takes a hashref containing the application's configuration.
 801
 802     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 803
 804 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 805 like C<myapp.conf> in your applications home directory. See
 806 L<Catalyst::Plugin::ConfigLoader>.
 807
 808 =head3 Cascading configuration
 809
 810 The config method is present on all Catalyst components, and configuration
 811 will be merged when an application is started. Configuration loaded with
 812 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 813 followed by configuration in your top level C<MyApp> class. These two
 814 configurations are merged, and then configuration data whose hash key matches a
 815 component name is merged with configuration for that component.
 816
 817 The configuration for a component is then passed to the C<new> method when a
 818 component is constructed.
 819
 820 For example:
 821
 822     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 823     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 824
 825 will mean that C<MyApp::Model::Foo> receives the following data when
 826 constructed:
 827
 828     MyApp::Model::Foo->new({
 829         bar => 'baz',
 830         quux => 'frob',
 831         overrides => 'me',
 832     });
 833
 834 It's common practice to use a Moose attribute
 835 on the receiving component to access the config value.
 836
 837     package MyApp::Model::Foo;
 838
 839     use Moose;
 840
 841     # this attr will receive 'baz' at construction time
 842     has 'bar' => (
 843         is  => 'rw',
 844         isa => 'Str',
 845     );
 846
 847 You can then get the value 'baz' by calling $c->model('Foo')->bar
 848 (or $self->bar inside code in the model).
 849
 850 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 851 as a way of reading config within your code, as this B<will not> give you the
 852 correctly merged config back. You B<MUST> take the config values supplied to
 853 the constructor and use those instead.
 854
 855 =cut
 856
 857 around config => sub {
 858     my $orig = shift;
 859     my $c = shift;
 860
 861     croak('Setting config after setup has been run is not allowed.')
 862         if ( @_ and $c->setup_finished );
 863
 864     $c->$orig(@_);
 865 };
 866
 867 =head2 $c->log
 868
 869 Returns the logging object instance. Unless it is already set, Catalyst
 870 sets this up with a L<Catalyst::Log> object. To use your own log class,
 871 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 872 C<< __PACKAGE__->setup >>.
 873
 874  __PACKAGE__->log( MyLogger->new );
 875  __PACKAGE__->setup;
 876
 877 And later:
 878
 879     $c->log->info( 'Now logging with my own logger!' );
 880
 881 Your log class should implement the methods described in
 882 L<Catalyst::Log>.
 883
 884
 885 =head2 $c->debug
 886
 887 Returns 1 if debug mode is enabled, 0 otherwise.
 888
 889 You can enable debug mode in several ways:
 890
 891 =over
 892
 893 =item By calling myapp_server.pl with the -d flag
 894
 895 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 896
 897 =item The -Debug option in your MyApp.pm
 898
 899 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 900
 901 =back
 902
 903 The first three also set the log level to 'debug'.
 904
 905 Calling C<< $c->debug(1) >> has no effect.
 906
 907 =cut
 908
 909 sub debug { 0 }
 910
 911 =head2 $c->dispatcher
 912
 913 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 914
 915 =head2 $c->engine
 916
 917 Returns the engine instance. See L<Catalyst::Engine>.
 918
 919
 920 =head2 UTILITY METHODS
 921
 922 =head2 $c->path_to(@path)
 923
 924 Merges C<@path> with C<< $c->config->{home} >> and returns a
 925 L<Path::Class::Dir> object. Note you can usually use this object as
 926 a filename, but sometimes you will have to explicitly stringify it
 927 yourself by calling the C<< ->stringify >> method.
 928
 929 For example:
 930
 931     $c->path_to( 'db', 'sqlite.db' );
 932
 933 =cut
 934
 935 sub path_to {
 936     my ( $c, @path ) = @_;
 937     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 938     if ( -d $path ) { return $path }
 939     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 940 }
 941
 942 =head2 $c->plugin( $name, $class, @args )
 943
 944 Helper method for plugins. It creates a class data accessor/mutator and
 945 loads and instantiates the given class.
 946
 947     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 948
 949     $c->prototype->define_javascript_functions;
 950
 951 B<Note:> This method of adding plugins is deprecated. The ability
 952 to add plugins like this B<will be removed> in a Catalyst 5.81.
 953 Please do not use this functionality in new code.
 954
 955 =cut
 956
 957 sub plugin {
 958     my ( $class, $name, $plugin, @args ) = @_;
 959
 960     # See block comment in t/unit_core_plugin.t
 961     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 962
 963     $class->_register_plugin( $plugin, 1 );
 964
 965     eval { $plugin->import };
 966     $class->mk_classdata($name);
 967     my $obj;
 968     eval { $obj = $plugin->new(@args) };
 969
 970     if ($@) {
 971         Catalyst::Exception->throw( message =>
 972               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 973     }
 974
 975     $class->$name($obj);
 976     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 977       if $class->debug;
 978 }
 979
 980 =head2 MyApp->setup
 981
 982 Initializes the dispatcher and engine, loads any plugins, and loads the
 983 model, view, and controller components. You may also specify an array
 984 of plugins to load here, if you choose to not load them in the C<use
 985 Catalyst> line.
 986
 987     MyApp->setup;
 988     MyApp->setup( qw/-Debug/ );
 989
 990 =cut
 991
 992 sub setup {
 993     my ( $class, @arguments ) = @_;
 994     croak('Running setup more than once')
 995         if ( $class->setup_finished );
 996
 997     unless ( $class->isa('Catalyst') ) {
 998
 999         Catalyst::Exception->throw(
1000             message => qq/'$class' does not inherit from Catalyst/ );
1001     }
1002
1003     if ( $class->arguments ) {
1004         @arguments = ( @arguments, @{ $class->arguments } );
1005     }
1006
1007     # Process options
1008     my $flags = {};
1009
1010     foreach (@arguments) {
1011
1012         if (/^-Debug$/) {
1013             $flags->{log} =
1014               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1015         }
1016         elsif (/^-(\w+)=?(.*)$/) {
1017             $flags->{ lc $1 } = $2;
1018         }
1019         else {
1020             push @{ $flags->{plugins} }, $_;
1021         }
1022     }
1023
1024     $class->setup_config();
1025     $class->setup_home( delete $flags->{home} );
1026
1027     $class->setup_log( delete $flags->{log} );
1028     $class->setup_plugins( delete $flags->{plugins} );
1029     $class->setup_dispatcher( delete $flags->{dispatcher} );
1030     $class->setup_engine( delete $flags->{engine} );
1031     $class->setup_stats( delete $flags->{stats} );
1032
1033     for my $flag ( sort keys %{$flags} ) {
1034
1035         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1036             &$code( $class, delete $flags->{$flag} );
1037         }
1038         else {
1039             $class->log->warn(qq/Unknown flag "$flag"/);
1040         }
1041     }
1042
1043     eval { require Catalyst::Devel; };
1044     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1045         $class->log->warn(<<"EOF");
1046 You are running an old script!
1047
1048   Please update by running (this will overwrite existing files):
1049     catalyst.pl -force -scripts $class
1050
1051   or (this will not overwrite existing files):
1052     catalyst.pl -scripts $class
1053
1054 EOF
1055     }
1056
1057     if ( $class->debug ) {
1058         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1059
1060         if (@plugins) {
1061             my $column_width = Catalyst::Utils::term_width() - 6;
1062             my $t = Text::SimpleTable->new($column_width);
1063             $t->row($_) for @plugins;
1064             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1065         }
1066
1067         my $dispatcher = $class->dispatcher;
1068         my $engine     = $class->engine;
1069         my $home       = $class->config->{home};
1070
1071         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1072         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1073
1074         $home
1075           ? ( -d $home )
1076           ? $class->log->debug(qq/Found home "$home"/)
1077           : $class->log->debug(qq/Home "$home" doesn't exist/)
1078           : $class->log->debug(q/Couldn't find home/);
1079     }
1080
1081     # Call plugins setup, this is stupid and evil.
1082     # Also screws C3 badly on 5.10, hack to avoid.
1083     {
1084         no warnings qw/redefine/;
1085         local *setup = sub { };
1086         $class->setup unless $Catalyst::__AM_RESTARTING;
1087     }
1088
1089     # Initialize our data structure
1090     $class->components( {} );
1091
1092     $class->setup_components;
1093
1094     if ( $class->debug ) {
1095         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1096         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1097         for my $comp ( sort keys %{ $class->components } ) {
1098             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1099             $t->row( $comp, $type );
1100         }
1101         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1102           if ( keys %{ $class->components } );
1103     }
1104
1105     # Add our self to components, since we are also a component
1106     if( $class->isa('Catalyst::Controller') ){
1107       $class->components->{$class} = $class;
1108     }
1109
1110     $class->setup_actions;
1111
1112     if ( $class->debug ) {
1113         my $name = $class->config->{name} || 'Application';
1114         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1115     }
1116
1117     # Make sure that the application class becomes immutable at this point,
1118     B::Hooks::EndOfScope::on_scope_end {
1119         return if $@;
1120         my $meta = Class::MOP::get_metaclass_by_name($class);
1121         if (
1122             $meta->is_immutable
1123             && ! { $meta->immutable_options }->{replace_constructor}
1124             && (
1125                    $class->isa('Class::Accessor::Fast')
1126                 || $class->isa('Class::Accessor')
1127             )
1128         ) {
1129             warn "You made your application class ($class) immutable, "
1130                 . "but did not inline the\nconstructor. "
1131                 . "This will break catalyst, as your app \@ISA "
1132                 . "Class::Accessor(::Fast)?\nPlease pass "
1133                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1134         }
1135         $meta->make_immutable(
1136             replace_constructor => 1,
1137         ) unless $meta->is_immutable;
1138     };
1139
1140     if ($class->config->{case_sensitive}) {
1141         $class->log->warn($class . "->config->{case_sensitive} is set.");
1142         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1143     }
1144
1145     $class->setup_finalize;
1146     # Should be the last thing we do so that user things hooking
1147     # setup_finalize can log..
1148     $class->log->_flush() if $class->log->can('_flush');
1149     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1150 }
1151
1152 =head2 $app->setup_finalize
1153
1154 A hook to attach modifiers to. This method does not do anything except set the
1155 C<setup_finished> accessor.
1156
1157 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1158
1159 Example:
1160
1161     after setup_finalize => sub {
1162         my $app = shift;
1163
1164         ## do stuff here..
1165     };
1166
1167 =cut
1168
1169 sub setup_finalize {
1170     my ($class) = @_;
1171     $class->setup_finished(1);
1172 }
1173
1174 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1175
1176 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1177
1178 Constructs an absolute L<URI> object based on the application root, the
1179 provided path, and the additional arguments and query parameters provided.
1180 When used as a string, provides a textual URI.  If you need more flexibility
1181 than this (i.e. the option to provide relative URIs etc.) see
1182 L<Catalyst::Plugin::SmartURI>.
1183
1184 If no arguments are provided, the URI for the current action is returned.
1185 To return the current action and also provide @args, use
1186 C<< $c->uri_for( $c->action, @args ) >>.
1187
1188 If the first argument is a string, it is taken as a public URI path relative
1189 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1190 relative to the application root (if it does). It is then merged with
1191 C<< $c->request->base >>; any C<@args> are appended as additional path
1192 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1193
1194 If the first argument is a L<Catalyst::Action> it represents an action which
1195 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1196 optional C<\@captures> argument (an arrayref) allows passing the captured
1197 variables that are needed to fill in the paths of Chained and Regex actions;
1198 once the path is resolved, C<uri_for> continues as though a path was
1199 provided, appending any arguments or parameters and creating an absolute
1200 URI.
1201
1202 The captures for the current request can be found in
1203 C<< $c->request->captures >>, and actions can be resolved using
1204 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1205 path, use C<< $c->uri_for_action >> instead.
1206
1207   # Equivalent to $c->req->uri
1208   $c->uri_for($c->action, $c->req->captures,
1209       @{ $c->req->args }, $c->req->params);
1210
1211   # For the Foo action in the Bar controller
1212   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1213
1214   # Path to a static resource
1215   $c->uri_for('/static/images/logo.png');
1216
1217 =cut
1218
1219 sub uri_for {
1220     my ( $c, $path, @args ) = @_;
1221
1222     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1223         $path = $path->path_prefix;
1224         $path =~ s{/+\z}{};
1225         $path .= '/';
1226     }
1227
1228     undef($path) if (defined $path && $path eq '');
1229
1230     my $params =
1231       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1232
1233     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1234     foreach my $arg (@args) {
1235         utf8::encode($arg) if utf8::is_utf8($arg);
1236         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1237     }
1238
1239     if ( blessed($path) ) { # action object
1240         s|/|%2F|g for @args;
1241         my $captures = [ map { s|/|%2F|g; $_; }
1242                         ( scalar @args && ref $args[0] eq 'ARRAY'
1243                          ? @{ shift(@args) }
1244                          : ()) ];
1245
1246         foreach my $capture (@$captures) {
1247             utf8::encode($capture) if utf8::is_utf8($capture);
1248             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1249         }
1250
1251         my $action = $path;
1252         $path = $c->dispatcher->uri_for_action($action, $captures);
1253         if (not defined $path) {
1254             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1255                 if $c->debug;
1256             return undef;
1257         }
1258         $path = '/' if $path eq '';
1259     }
1260
1261     unshift(@args, $path);
1262
1263     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1264         my $namespace = $c->namespace;
1265         if (defined $path) { # cheesy hack to handle path '../foo'
1266            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1267         }
1268         unshift(@args, $namespace || '');
1269     }
1270
1271     # join args with '/', or a blank string
1272     my $args = join('/', grep { defined($_) } @args);
1273     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1274     $args =~ s!^/+!!;
1275     my $base = $c->req->base;
1276     my $class = ref($base);
1277     $base =~ s{(?<!/)$}{/};
1278
1279     my $query = '';
1280
1281     if (my @keys = keys %$params) {
1282       # somewhat lifted from URI::_query's query_form
1283       $query = '?'.join('&', map {
1284           my $val = $params->{$_};
1285           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1286           s/ /+/g;
1287           my $key = $_;
1288           $val = '' unless defined $val;
1289           (map {
1290               my $param = "$_";
1291               utf8::encode( $param ) if utf8::is_utf8($param);
1292               # using the URI::Escape pattern here so utf8 chars survive
1293               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1294               $param =~ s/ /+/g;
1295               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1296       } @keys);
1297     }
1298
1299     my $res = bless(\"${base}${args}${query}", $class);
1300     $res;
1301 }
1302
1303 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1304
1305 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1306
1307 =over
1308
1309 =item $path
1310
1311 A private path to the Catalyst action you want to create a URI for.
1312
1313 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1314 >> and passing the resulting C<$action> and the remaining arguments to C<<
1315 $c->uri_for >>.
1316
1317 You can also pass in a Catalyst::Action object, in which case it is passed to
1318 C<< $c->uri_for >>.
1319
1320 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1321
1322 For example, if the action looks like:
1323
1324  package MyApp::Controller::Users;
1325
1326  sub lst : Path('the-list') {}
1327
1328 You can use:
1329
1330  $c->uri_for_action('/users/lst')
1331
1332 and it will create the URI /users/the-list.
1333
1334 =back
1335
1336 =cut
1337
1338 sub uri_for_action {
1339     my ( $c, $path, @args ) = @_;
1340     my $action = blessed($path)
1341       ? $path
1342       : $c->dispatcher->get_action_by_path($path);
1343     unless (defined $action) {
1344       croak "Can't find action for path '$path'";
1345     }
1346     return $c->uri_for( $action, @args );
1347 }
1348
1349 =head2 $c->welcome_message
1350
1351 Returns the Catalyst welcome HTML page.
1352
1353 =cut
1354
1355 sub welcome_message {
1356     my $c      = shift;
1357     my $name   = $c->config->{name};
1358     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1359     my $prefix = Catalyst::Utils::appprefix( ref $c );
1360     $c->response->content_type('text/html; charset=utf-8');
1361     return <<"EOF";
1362 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1363     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1364 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1365     <head>
1366     <meta http-equiv="Content-Language" content="en" />
1367     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1368         <title>$name on Catalyst $VERSION</title>
1369         <style type="text/css">
1370             body {
1371                 color: #000;
1372                 background-color: #eee;
1373             }
1374             div#content {
1375                 width: 640px;
1376                 margin-left: auto;
1377                 margin-right: auto;
1378                 margin-top: 10px;
1379                 margin-bottom: 10px;
1380                 text-align: left;
1381                 background-color: #ccc;
1382                 border: 1px solid #aaa;
1383             }
1384             p, h1, h2 {
1385                 margin-left: 20px;
1386                 margin-right: 20px;
1387                 font-family: verdana, tahoma, sans-serif;
1388             }
1389             a {
1390                 font-family: verdana, tahoma, sans-serif;
1391             }
1392             :link, :visited {
1393                     text-decoration: none;
1394                     color: #b00;
1395                     border-bottom: 1px dotted #bbb;
1396             }
1397             :link:hover, :visited:hover {
1398                     color: #555;
1399             }
1400             div#topbar {
1401                 margin: 0px;
1402             }
1403             pre {
1404                 margin: 10px;
1405                 padding: 8px;
1406             }
1407             div#answers {
1408                 padding: 8px;
1409                 margin: 10px;
1410                 background-color: #fff;
1411                 border: 1px solid #aaa;
1412             }
1413             h1 {
1414                 font-size: 0.9em;
1415                 font-weight: normal;
1416                 text-align: center;
1417             }
1418             h2 {
1419                 font-size: 1.0em;
1420             }
1421             p {
1422                 font-size: 0.9em;
1423             }
1424             p img {
1425                 float: right;
1426                 margin-left: 10px;
1427             }
1428             span#appname {
1429                 font-weight: bold;
1430                 font-size: 1.6em;
1431             }
1432         </style>
1433     </head>
1434     <body>
1435         <div id="content">
1436             <div id="topbar">
1437                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1438                     $VERSION</h1>
1439              </div>
1440              <div id="answers">
1441                  <p>
1442                  <img src="$logo" alt="Catalyst Logo" />
1443                  </p>
1444                  <p>Welcome to the  world of Catalyst.
1445                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1446                     framework will make web development something you had
1447                     never expected it to be: Fun, rewarding, and quick.</p>
1448                  <h2>What to do now?</h2>
1449                  <p>That really depends  on what <b>you</b> want to do.
1450                     We do, however, provide you with a few starting points.</p>
1451                  <p>If you want to jump right into web development with Catalyst
1452                     you might want to start with a tutorial.</p>
1453 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1454 </pre>
1455 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1456 <pre>
1457 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1458 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1459 </code></pre>
1460                  <h2>What to do next?</h2>
1461                  <p>Next it's time to write an actual application. Use the
1462                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1463                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1464                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1465                     they can save you a lot of work.</p>
1466                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1467                     <p>Also, be sure to check out the vast and growing
1468                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1469                     you are likely to find what you need there.
1470                     </p>
1471
1472                  <h2>Need help?</h2>
1473                  <p>Catalyst has a very active community. Here are the main places to
1474                     get in touch with us.</p>
1475                  <ul>
1476                      <li>
1477                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1478                      </li>
1479                      <li>
1480                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1481                      </li>
1482                      <li>
1483                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1484                      </li>
1485                  </ul>
1486                  <h2>In conclusion</h2>
1487                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1488                     as we enjoyed making it. Please contact us if you have ideas
1489                     for improvement or other feedback.</p>
1490              </div>
1491          </div>
1492     </body>
1493 </html>
1494 EOF
1495 }
1496
1497 =head1 INTERNAL METHODS
1498
1499 These methods are not meant to be used by end users.
1500
1501 =head2 $c->components
1502
1503 Returns a hash of components.
1504
1505 =cut
1506
1507 around components => sub {
1508     my $orig  = shift;
1509     my $class = shift;
1510     my $comps = shift;
1511
1512     return $class->$orig if ( !$comps );
1513
1514 # FIXME: should this ugly kludge exist?
1515     $class->setup_config unless defined $class->container;
1516
1517 # FIXME: should there be a warning here, not to use this accessor to create the components?
1518     my $components = {};
1519
1520     my $containers;
1521     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
1522
1523     for my $component ( keys %$comps ) {
1524         $components->{ $component } = $comps->{$component};
1525
1526         my ($type, $name) = _get_component_type_name($component);
1527
1528 # FIXME: shouldn't the service name be $name?
1529         $containers->{$type}->add_service(Catalyst::BlockInjection->new( name => $name, block => sub { return $class->setup_component($component) } ));
1530     }
1531
1532     return $class->$orig($components);
1533 };
1534
1535 =head2 $c->context_class
1536
1537 Returns or sets the context class.
1538
1539 =head2 $c->counter
1540
1541 Returns a hashref containing coderefs and execution counts (needed for
1542 deep recursion detection).
1543
1544 =head2 $c->depth
1545
1546 Returns the number of actions on the current internal execution stack.
1547
1548 =head2 $c->dispatch
1549
1550 Dispatches a request to actions.
1551
1552 =cut
1553
1554 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1555
1556 =head2 $c->dispatcher_class
1557
1558 Returns or sets the dispatcher class.
1559
1560 =head2 $c->dump_these
1561
1562 Returns a list of 2-element array references (name, structure) pairs
1563 that will be dumped on the error page in debug mode.
1564
1565 =cut
1566
1567 sub dump_these {
1568     my $c = shift;
1569     [ Request => $c->req ],
1570     [ Response => $c->res ],
1571     [ Stash => $c->stash ],
1572     [ Config => $c->config ];
1573 }
1574
1575 =head2 $c->engine_class
1576
1577 Returns or sets the engine class.
1578
1579 =head2 $c->execute( $class, $coderef )
1580
1581 Execute a coderef in given class and catch exceptions. Errors are available
1582 via $c->error.
1583
1584 =cut
1585
1586 sub execute {
1587     my ( $c, $class, $code ) = @_;
1588     $class = $c->component($class) || $class;
1589     $c->state(0);
1590
1591     if ( $c->depth >= $RECURSION ) {
1592         my $action = $code->reverse();
1593         $action = "/$action" unless $action =~ /->/;
1594         my $error = qq/Deep recursion detected calling "${action}"/;
1595         $c->log->error($error);
1596         $c->error($error);
1597         $c->state(0);
1598         return $c->state;
1599     }
1600
1601     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1602
1603     push( @{ $c->stack }, $code );
1604
1605     no warnings 'recursion';
1606     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1607     #      I have no idea how, ergo $ret (which appears to fix the issue)
1608     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1609
1610     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1611
1612     my $last = pop( @{ $c->stack } );
1613
1614     if ( my $error = $@ ) {
1615         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1616             $error->rethrow if $c->depth > 1;
1617         }
1618         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1619             $error->rethrow if $c->depth > 0;
1620         }
1621         else {
1622             unless ( ref $error ) {
1623                 no warnings 'uninitialized';
1624                 chomp $error;
1625                 my $class = $last->class;
1626                 my $name  = $last->name;
1627                 $error = qq/Caught exception in $class->$name "$error"/;
1628             }
1629             $c->error($error);
1630         }
1631         $c->state(0);
1632     }
1633     return $c->state;
1634 }
1635
1636 sub _stats_start_execute {
1637     my ( $c, $code ) = @_;
1638     my $appclass = ref($c) || $c;
1639     return if ( ( $code->name =~ /^_.*/ )
1640         && ( !$appclass->config->{show_internal_actions} ) );
1641
1642     my $action_name = $code->reverse();
1643     $c->counter->{$action_name}++;
1644
1645     my $action = $action_name;
1646     $action = "/$action" unless $action =~ /->/;
1647
1648     # determine if the call was the result of a forward
1649     # this is done by walking up the call stack and looking for a calling
1650     # sub of Catalyst::forward before the eval
1651     my $callsub = q{};
1652     for my $index ( 2 .. 11 ) {
1653         last
1654         if ( ( caller($index) )[0] eq 'Catalyst'
1655             && ( caller($index) )[3] eq '(eval)' );
1656
1657         if ( ( caller($index) )[3] =~ /forward$/ ) {
1658             $callsub = ( caller($index) )[3];
1659             $action  = "-> $action";
1660             last;
1661         }
1662     }
1663
1664     my $uid = $action_name . $c->counter->{$action_name};
1665
1666     # is this a root-level call or a forwarded call?
1667     if ( $callsub =~ /forward$/ ) {
1668         my $parent = $c->stack->[-1];
1669
1670         # forward, locate the caller
1671         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1672             $c->stats->profile(
1673                 begin  => $action,
1674                 parent => "$parent" . $c->counter->{"$parent"},
1675                 uid    => $uid,
1676             );
1677         }
1678         else {
1679
1680             # forward with no caller may come from a plugin
1681             $c->stats->profile(
1682                 begin => $action,
1683                 uid   => $uid,
1684             );
1685         }
1686     }
1687     else {
1688
1689         # root-level call
1690         $c->stats->profile(
1691             begin => $action,
1692             uid   => $uid,
1693         );
1694     }
1695     return $action;
1696
1697 }
1698
1699 sub _stats_finish_execute {
1700     my ( $c, $info ) = @_;
1701     $c->stats->profile( end => $info );
1702 }
1703
1704 =head2 $c->finalize
1705
1706 Finalizes the request.
1707
1708 =cut
1709
1710 sub finalize {
1711     my $c = shift;
1712
1713     for my $error ( @{ $c->error } ) {
1714         $c->log->error($error);
1715     }
1716
1717     # Allow engine to handle finalize flow (for POE)
1718     my $engine = $c->engine;
1719     if ( my $code = $engine->can('finalize') ) {
1720         $engine->$code($c);
1721     }
1722     else {
1723
1724         $c->finalize_uploads;
1725
1726         # Error
1727         if ( $#{ $c->error } >= 0 ) {
1728             $c->finalize_error;
1729         }
1730
1731         $c->finalize_headers;
1732
1733         # HEAD request
1734         if ( $c->request->method eq 'HEAD' ) {
1735             $c->response->body('');
1736         }
1737
1738         $c->finalize_body;
1739     }
1740
1741     $c->log_response;
1742
1743     if ($c->use_stats) {
1744         my $elapsed = sprintf '%f', $c->stats->elapsed;
1745         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1746         $c->log->info(
1747             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1748     }
1749
1750     return $c->response->status;
1751 }
1752
1753 =head2 $c->finalize_body
1754
1755 Finalizes body.
1756
1757 =cut
1758
1759 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1760
1761 =head2 $c->finalize_cookies
1762
1763 Finalizes cookies.
1764
1765 =cut
1766
1767 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1768
1769 =head2 $c->finalize_error
1770
1771 Finalizes error.
1772
1773 =cut
1774
1775 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1776
1777 =head2 $c->finalize_headers
1778
1779 Finalizes headers.
1780
1781 =cut
1782
1783 sub finalize_headers {
1784     my $c = shift;
1785
1786     my $response = $c->response; #accessor calls can add up?
1787
1788     # Check if we already finalized headers
1789     return if $response->finalized_headers;
1790
1791     # Handle redirects
1792     if ( my $location = $response->redirect ) {
1793         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1794         $response->header( Location => $location );
1795
1796         if ( !$response->has_body ) {
1797             # Add a default body if none is already present
1798             $response->body(
1799                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1800             );
1801         }
1802     }
1803
1804     # Content-Length
1805     if ( defined $response->body && length $response->body && !$response->content_length ) {
1806
1807         # get the length from a filehandle
1808         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1809         {
1810             my $stat = stat $response->body;
1811             if ( $stat && $stat->size > 0 ) {
1812                 $response->content_length( $stat->size );
1813             }
1814             else {
1815                 $c->log->warn('Serving filehandle without a content-length');
1816             }
1817         }
1818         else {
1819             # everything should be bytes at this point, but just in case
1820             $response->content_length( length( $response->body ) );
1821         }
1822     }
1823
1824     # Errors
1825     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1826         $response->headers->remove_header("Content-Length");
1827         $response->body('');
1828     }
1829
1830     $c->finalize_cookies;
1831
1832     $c->engine->finalize_headers( $c, @_ );
1833
1834     # Done
1835     $response->finalized_headers(1);
1836 }
1837
1838 =head2 $c->finalize_output
1839
1840 An alias for finalize_body.
1841
1842 =head2 $c->finalize_read
1843
1844 Finalizes the input after reading is complete.
1845
1846 =cut
1847
1848 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1849
1850 =head2 $c->finalize_uploads
1851
1852 Finalizes uploads. Cleans up any temporary files.
1853
1854 =cut
1855
1856 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1857
1858 =head2 $c->get_action( $action, $namespace )
1859
1860 Gets an action in a given namespace.
1861
1862 =cut
1863
1864 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1865
1866 =head2 $c->get_actions( $action, $namespace )
1867
1868 Gets all actions of a given name in a namespace and all parent
1869 namespaces.
1870
1871 =cut
1872
1873 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1874
1875 =head2 $app->handle_request( @arguments )
1876
1877 Called to handle each HTTP request.
1878
1879 =cut
1880
1881 sub handle_request {
1882     my ( $class, @arguments ) = @_;
1883
1884     # Always expect worst case!
1885     my $status = -1;
1886     eval {
1887         if ($class->debug) {
1888             my $secs = time - $START || 1;
1889             my $av = sprintf '%.3f', $COUNT / $secs;
1890             my $time = localtime time;
1891             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1892         }
1893
1894         my $c = $class->prepare(@arguments);
1895         $c->dispatch;
1896         $status = $c->finalize;
1897     };
1898
1899     if ( my $error = $@ ) {
1900         chomp $error;
1901         $class->log->error(qq/Caught exception in engine "$error"/);
1902     }
1903
1904     $COUNT++;
1905
1906     if(my $coderef = $class->log->can('_flush')){
1907         $class->log->$coderef();
1908     }
1909     return $status;
1910 }
1911
1912 =head2 $c->prepare( @arguments )
1913
1914 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1915 etc.).
1916
1917 =cut
1918
1919 sub prepare {
1920     my ( $class, @arguments ) = @_;
1921
1922     # XXX
1923     # After the app/ctxt split, this should become an attribute based on something passed
1924     # into the application.
1925     $class->context_class( ref $class || $class ) unless $class->context_class;
1926
1927     my $c = $class->context_class->new({});
1928
1929     # For on-demand data
1930     $c->request->_context($c);
1931     $c->response->_context($c);
1932
1933     #surely this is not the most efficient way to do things...
1934     $c->stats($class->stats_class->new)->enable($c->use_stats);
1935     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1936         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1937     }
1938
1939     #XXX reuse coderef from can
1940     # Allow engine to direct the prepare flow (for POE)
1941     if ( $c->engine->can('prepare') ) {
1942         $c->engine->prepare( $c, @arguments );
1943     }
1944     else {
1945         $c->prepare_request(@arguments);
1946         $c->prepare_connection;
1947         $c->prepare_query_parameters;
1948         $c->prepare_headers;
1949         $c->prepare_cookies;
1950         $c->prepare_path;
1951
1952         # Prepare the body for reading, either by prepare_body
1953         # or the user, if they are using $c->read
1954         $c->prepare_read;
1955
1956         # Parse the body unless the user wants it on-demand
1957         unless ( ref($c)->config->{parse_on_demand} ) {
1958             $c->prepare_body;
1959         }
1960     }
1961
1962     my $method  = $c->req->method  || '';
1963     my $path    = $c->req->path;
1964     $path       = '/' unless length $path;
1965     my $address = $c->req->address || '';
1966
1967     $c->log_request;
1968
1969     $c->prepare_action;
1970
1971     return $c;
1972 }
1973
1974 =head2 $c->prepare_action
1975
1976 Prepares action. See L<Catalyst::Dispatcher>.
1977
1978 =cut
1979
1980 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1981
1982 =head2 $c->prepare_body
1983
1984 Prepares message body.
1985
1986 =cut
1987
1988 sub prepare_body {
1989     my $c = shift;
1990
1991     return if $c->request->_has_body;
1992
1993     # Initialize on-demand data
1994     $c->engine->prepare_body( $c, @_ );
1995     $c->prepare_parameters;
1996     $c->prepare_uploads;
1997 }
1998
1999 =head2 $c->prepare_body_chunk( $chunk )
2000
2001 Prepares a chunk of data before sending it to L<HTTP::Body>.
2002
2003 See L<Catalyst::Engine>.
2004
2005 =cut
2006
2007 sub prepare_body_chunk {
2008     my $c = shift;
2009     $c->engine->prepare_body_chunk( $c, @_ );
2010 }
2011
2012 =head2 $c->prepare_body_parameters
2013
2014 Prepares body parameters.
2015
2016 =cut
2017
2018 sub prepare_body_parameters {
2019     my $c = shift;
2020     $c->engine->prepare_body_parameters( $c, @_ );
2021 }
2022
2023 =head2 $c->prepare_connection
2024
2025 Prepares connection.
2026
2027 =cut
2028
2029 sub prepare_connection {
2030     my $c = shift;
2031     $c->engine->prepare_connection( $c, @_ );
2032 }
2033
2034 =head2 $c->prepare_cookies
2035
2036 Prepares cookies.
2037
2038 =cut
2039
2040 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2041
2042 =head2 $c->prepare_headers
2043
2044 Prepares headers.
2045
2046 =cut
2047
2048 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2049
2050 =head2 $c->prepare_parameters
2051
2052 Prepares parameters.
2053
2054 =cut
2055
2056 sub prepare_parameters {
2057     my $c = shift;
2058     $c->prepare_body_parameters;
2059     $c->engine->prepare_parameters( $c, @_ );
2060 }
2061
2062 =head2 $c->prepare_path
2063
2064 Prepares path and base.
2065
2066 =cut
2067
2068 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2069
2070 =head2 $c->prepare_query_parameters
2071
2072 Prepares query parameters.
2073
2074 =cut
2075
2076 sub prepare_query_parameters {
2077     my $c = shift;
2078
2079     $c->engine->prepare_query_parameters( $c, @_ );
2080 }
2081
2082 =head2 $c->log_request
2083
2084 Writes information about the request to the debug logs.  This includes:
2085
2086 =over 4
2087
2088 =item * Request method, path, and remote IP address
2089
2090 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2091
2092 =item * Request parameters
2093
2094 =item * File uploads
2095
2096 =back
2097
2098 =cut
2099
2100 sub log_request {
2101     my $c = shift;
2102
2103     return unless $c->debug;
2104
2105     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2106     my $request = $dump->[1];
2107
2108     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2109     $method ||= '';
2110     $path = '/' unless length $path;
2111     $address ||= '';
2112     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2113
2114     $c->log_request_headers($request->headers);
2115
2116     if ( my $keywords = $request->query_keywords ) {
2117         $c->log->debug("Query keywords are: $keywords");
2118     }
2119
2120     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2121
2122     $c->log_request_uploads($request);
2123 }
2124
2125 =head2 $c->log_response
2126
2127 Writes information about the response to the debug logs by calling
2128 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2129
2130 =cut
2131
2132 sub log_response {
2133     my $c = shift;
2134
2135     return unless $c->debug;
2136
2137     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2138     my $response = $dump->[1];
2139
2140     $c->log_response_status_line($response);
2141     $c->log_response_headers($response->headers);
2142 }
2143
2144 =head2 $c->log_response_status_line($response)
2145
2146 Writes one line of information about the response to the debug logs.  This includes:
2147
2148 =over 4
2149
2150 =item * Response status code
2151
2152 =item * Content-Type header (if present)
2153
2154 =item * Content-Length header (if present)
2155
2156 =back
2157
2158 =cut
2159
2160 sub log_response_status_line {
2161     my ($c, $response) = @_;
2162
2163     $c->log->debug(
2164         sprintf(
2165             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2166             $response->status                            || 'unknown',
2167             $response->headers->header('Content-Type')   || 'unknown',
2168             $response->headers->header('Content-Length') || 'unknown'
2169         )
2170     );
2171 }
2172
2173 =head2 $c->log_response_headers($headers);
2174
2175 Hook method which can be wrapped by plugins to log the responseheaders.
2176 No-op in the default implementation.
2177
2178 =cut
2179
2180 sub log_response_headers {}
2181
2182 =head2 $c->log_request_parameters( query => {}, body => {} )
2183
2184 Logs request parameters to debug logs
2185
2186 =cut
2187
2188 sub log_request_parameters {
2189     my $c          = shift;
2190     my %all_params = @_;
2191
2192     return unless $c->debug;
2193
2194     my $column_width = Catalyst::Utils::term_width() - 44;
2195     foreach my $type (qw(query body)) {
2196         my $params = $all_params{$type};
2197         next if ! keys %$params;
2198         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2199         for my $key ( sort keys %$params ) {
2200             my $param = $params->{$key};
2201             my $value = defined($param) ? $param : '';
2202             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2203         }
2204         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2205     }
2206 }
2207
2208 =head2 $c->log_request_uploads
2209
2210 Logs file uploads included in the request to the debug logs.
2211 The parameter name, filename, file type, and file size are all included in
2212 the debug logs.
2213
2214 =cut
2215
2216 sub log_request_uploads {
2217     my $c = shift;
2218     my $request = shift;
2219     return unless $c->debug;
2220     my $uploads = $request->uploads;
2221     if ( keys %$uploads ) {
2222         my $t = Text::SimpleTable->new(
2223             [ 12, 'Parameter' ],
2224             [ 26, 'Filename' ],
2225             [ 18, 'Type' ],
2226             [ 9,  'Size' ]
2227         );
2228         for my $key ( sort keys %$uploads ) {
2229             my $upload = $uploads->{$key};
2230             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2231                 $t->row( $key, $u->filename, $u->type, $u->size );
2232             }
2233         }
2234         $c->log->debug( "File Uploads are:\n" . $t->draw );
2235     }
2236 }
2237
2238 =head2 $c->log_request_headers($headers);
2239
2240 Hook method which can be wrapped by plugins to log the request headers.
2241 No-op in the default implementation.
2242
2243 =cut
2244
2245 sub log_request_headers {}
2246
2247 =head2 $c->log_headers($type => $headers)
2248
2249 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2250
2251 =cut
2252
2253 sub log_headers {
2254     my $c       = shift;
2255     my $type    = shift;
2256     my $headers = shift;    # an HTTP::Headers instance
2257
2258     return unless $c->debug;
2259
2260     my $column_width = Catalyst::Utils::term_width() - 28;
2261     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2262     $headers->scan(
2263         sub {
2264             my ( $name, $value ) = @_;
2265             $t->row( $name, $value );
2266         }
2267     );
2268     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2269 }
2270
2271
2272 =head2 $c->prepare_read
2273
2274 Prepares the input for reading.
2275
2276 =cut
2277
2278 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2279
2280 =head2 $c->prepare_request
2281
2282 Prepares the engine request.
2283
2284 =cut
2285
2286 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2287
2288 =head2 $c->prepare_uploads
2289
2290 Prepares uploads.
2291
2292 =cut
2293
2294 sub prepare_uploads {
2295     my $c = shift;
2296
2297     $c->engine->prepare_uploads( $c, @_ );
2298 }
2299
2300 =head2 $c->prepare_write
2301
2302 Prepares the output for writing.
2303
2304 =cut
2305
2306 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2307
2308 =head2 $c->request_class
2309
2310 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2311
2312 =head2 $c->response_class
2313
2314 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2315
2316 =head2 $c->read( [$maxlength] )
2317
2318 Reads a chunk of data from the request body. This method is designed to
2319 be used in a while loop, reading C<$maxlength> bytes on every call.
2320 C<$maxlength> defaults to the size of the request if not specified.
2321
2322 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2323 directly.
2324
2325 Warning: If you use read(), Catalyst will not process the body,
2326 so you will not be able to access POST parameters or file uploads via
2327 $c->request.  You must handle all body parsing yourself.
2328
2329 =cut
2330
2331 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2332
2333 =head2 $c->run
2334
2335 Starts the engine.
2336
2337 =cut
2338
2339 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2340
2341 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2342
2343 Sets an action in a given namespace.
2344
2345 =cut
2346
2347 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2348
2349 =head2 $c->setup_actions($component)
2350
2351 Sets up actions for a component.
2352
2353 =cut
2354
2355 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2356
2357 =head2 $c->setup_config
2358
2359 =cut
2360
2361 sub setup_config {
2362     my $class = shift;
2363
2364     my %args = %{ $class->config || {} };
2365
2366     my @container_classes = ( "${class}::Container", 'Catalyst::Container');
2367     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2368
2369     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2370
2371     my $container = $container_class->new( %args, name => "$class" );
2372     $class->container($container);
2373
2374     my $config = $container->resolve(service => 'config');
2375     $class->config($config);
2376     $class->finalize_config; # back-compat
2377 }
2378
2379 =head $c->finalize_config
2380
2381 =cut
2382
2383 sub finalize_config { }
2384
2385 =head2 $c->setup_components
2386
2387 This method is called internally to set up the application's components.
2388
2389 It finds modules by calling the L<locate_components> method, expands them to
2390 package names with the L<expand_component_module> method, and then installs
2391 each component into the application.
2392
2393 The C<setup_components> config option is passed to both of the above methods.
2394
2395 Installation of each component is performed by the L<setup_component> method,
2396 below.
2397
2398 =cut
2399
2400 sub setup_components {
2401     my $class = shift;
2402
2403     my $config  = $class->config->{ setup_components };
2404
2405     my @comps = $class->locate_components($config);
2406     my %comps = map { $_ => 1 } @comps;
2407
2408     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2409     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2410         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2411     ) if $deprecatedcatalyst_component_names;
2412
2413     for my $component ( @comps ) {
2414
2415         # We pass ignore_loaded here so that overlay files for (e.g.)
2416         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2417         # we know M::P::O found a file on disk so this is safe
2418
2419         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2420     }
2421
2422     my $containers;
2423     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
2424
2425     for my $component (@comps) {
2426         my $instance = $class->components->{ $component } = $class->setup_component($component);
2427         if ( my ($type, $name) = _get_component_type_name($component) ) {
2428             $containers->{$type}->add_service(Catalyst::BlockInjection->new( name => $name, block => sub { return $instance } ));
2429         }
2430         my @expanded_components = $instance->can('expand_modules')
2431             ? $instance->expand_modules( $component, $config )
2432             : $class->expand_component_module( $component, $config );
2433         for my $component (@expanded_components) {
2434             next if $comps{$component};
2435
2436             $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @expanded_components;
2437             $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2438                 qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2439             ) if $deprecatedcatalyst_component_names;
2440
2441             if (my ($type, $name) = _get_component_type_name($component)) {
2442                 $containers->{$type}->add_service(Catalyst::BlockInjection->new( name => $name, block => sub { return $class->setup_component($component) } ));
2443             }
2444
2445             $class->components->{ $component } = $class->setup_component($component);
2446         }
2447     }
2448 }
2449
2450 sub _get_component_type_name {
2451     my $component = shift;
2452     my @parts     = split /::/, $component;
2453
2454     while (my $type = shift @parts) {
2455         return ('controller', join '::', @parts)
2456             if $type =~ /^(c|controller)$/i;
2457
2458         return ('model', join '::', @parts)
2459             if $type =~ /^(m|model)$/i;
2460
2461         return ('view', join '::', @parts)
2462             if $type =~ /^(v|view)$/i;
2463     }
2464 }
2465
2466 =head2 $c->locate_components( $setup_component_config )
2467
2468 This method is meant to provide a list of component modules that should be
2469 setup for the application.  By default, it will use L<Module::Pluggable>.
2470
2471 Specify a C<setup_components> config option to pass additional options directly
2472 to L<Module::Pluggable>. To add additional search paths, specify a key named
2473 C<search_extra> as an array reference. Items in the array beginning with C<::>
2474 will have the application class name prepended to them.
2475
2476 =cut
2477
2478 sub locate_components {
2479     my $class  = shift;
2480     my $config = shift;
2481
2482     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2483     my $extra   = delete $config->{ search_extra } || [];
2484
2485     push @paths, @$extra;
2486
2487     my $locator = Module::Pluggable::Object->new(
2488         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2489         %$config
2490     );
2491
2492     # XXX think about ditching this sort entirely
2493     my @comps = sort { length $a <=> length $b } $locator->plugins;
2494
2495     return @comps;
2496 }
2497
2498 =head2 $c->expand_component_module( $component, $setup_component_config )
2499
2500 Components found by C<locate_components> will be passed to this method, which
2501 is expected to return a list of component (package) names to be set up.
2502
2503 =cut
2504
2505 sub expand_component_module {
2506     my ($class, $module) = @_;
2507     return Devel::InnerPackage::list_packages( $module );
2508 }
2509
2510 =head2 $c->setup_component
2511
2512 =cut
2513
2514 sub setup_component {
2515     my( $class, $component ) = @_;
2516
2517     unless ( $component->can( 'COMPONENT' ) ) {
2518         return $component;
2519     }
2520
2521     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2522     my $config = $class->config->{ $suffix } || {};
2523     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2524     # methods also pass it. local to avoid pointlessly shitting in config
2525     # for the debug screen, as $component is already the key name.
2526     local $config->{catalyst_component_name} = $component;
2527
2528     my $instance = eval { $component->COMPONENT( $class, $config ); };
2529
2530     if ( my $error = $@ ) {
2531         chomp $error;
2532         Catalyst::Exception->throw(
2533             message => qq/Couldn't instantiate component "$component", "$error"/
2534         );
2535     }
2536     elsif (!blessed $instance) {
2537         my $metaclass = Moose::Util::find_meta($component);
2538         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2539         my $component_method_from = $method_meta->associated_metaclass->name;
2540         my $value = defined($instance) ? $instance : 'undef';
2541         Catalyst::Exception->throw(
2542             message =>
2543             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2544         );
2545     }
2546
2547     return $instance;
2548 }
2549
2550 =head2 $c->setup_dispatcher
2551
2552 Sets up dispatcher.
2553
2554 =cut
2555
2556 sub setup_dispatcher {
2557     my ( $class, $dispatcher ) = @_;
2558
2559     if ($dispatcher) {
2560         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2561     }
2562
2563     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2564         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2565     }
2566
2567     unless ($dispatcher) {
2568         $dispatcher = $class->dispatcher_class;
2569     }
2570
2571     Class::MOP::load_class($dispatcher);
2572
2573     # dispatcher instance
2574     $class->dispatcher( $dispatcher->new );
2575 }
2576
2577 =head2 $c->setup_engine
2578
2579 Sets up engine.
2580
2581 =cut
2582
2583 sub setup_engine {
2584     my ( $class, $engine ) = @_;
2585
2586     if ($engine) {
2587         $engine = 'Catalyst::Engine::' . $engine;
2588     }
2589
2590     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2591         $engine = 'Catalyst::Engine::' . $env;
2592     }
2593
2594     if ( $ENV{MOD_PERL} ) {
2595         my $meta = Class::MOP::get_metaclass_by_name($class);
2596
2597         # create the apache method
2598         $meta->add_method('apache' => sub { shift->engine->apache });
2599
2600         my ( $software, $version ) =
2601           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2602
2603         $version =~ s/_//g;
2604         $version =~ s/(\.[^.]+)\./$1/g;
2605
2606         if ( $software eq 'mod_perl' ) {
2607
2608             if ( !$engine ) {
2609
2610                 if ( $version >= 1.99922 ) {
2611                     $engine = 'Catalyst::Engine::Apache2::MP20';
2612                 }
2613
2614                 elsif ( $version >= 1.9901 ) {
2615                     $engine = 'Catalyst::Engine::Apache2::MP19';
2616                 }
2617
2618                 elsif ( $version >= 1.24 ) {
2619                     $engine = 'Catalyst::Engine::Apache::MP13';
2620                 }
2621
2622                 else {
2623                     Catalyst::Exception->throw( message =>
2624                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2625                 }
2626
2627             }
2628
2629             # install the correct mod_perl handler
2630             if ( $version >= 1.9901 ) {
2631                 *handler = sub  : method {
2632                     shift->handle_request(@_);
2633                 };
2634             }
2635             else {
2636                 *handler = sub ($$) { shift->handle_request(@_) };
2637             }
2638
2639         }
2640
2641         elsif ( $software eq 'Zeus-Perl' ) {
2642             $engine = 'Catalyst::Engine::Zeus';
2643         }
2644
2645         else {
2646             Catalyst::Exception->throw(
2647                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2648         }
2649     }
2650
2651     unless ($engine) {
2652         $engine = $class->engine_class;
2653     }
2654
2655     Class::MOP::load_class($engine);
2656
2657     # check for old engines that are no longer compatible
2658     my $old_engine;
2659     if ( $engine->isa('Catalyst::Engine::Apache')
2660         && !Catalyst::Engine::Apache->VERSION )
2661     {
2662         $old_engine = 1;
2663     }
2664
2665     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2666         && Catalyst::Engine::Server->VERSION le '0.02' )
2667     {
2668         $old_engine = 1;
2669     }
2670
2671     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2672         && $engine->VERSION eq '0.01' )
2673     {
2674         $old_engine = 1;
2675     }
2676
2677     elsif ($engine->isa('Catalyst::Engine::Zeus')
2678         && $engine->VERSION eq '0.01' )
2679     {
2680         $old_engine = 1;
2681     }
2682
2683     if ($old_engine) {
2684         Catalyst::Exception->throw( message =>
2685               qq/Engine "$engine" is not supported by this version of Catalyst/
2686         );
2687     }
2688
2689     # engine instance
2690     $class->engine( $engine->new );
2691 }
2692
2693 =head2 $c->setup_home
2694
2695 Sets up the home directory.
2696
2697 =cut
2698
2699 sub setup_home {
2700     my ( $class, $home ) = @_;
2701
2702     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2703         $home = $env;
2704     }
2705
2706     $home ||= Catalyst::Utils::home($class);
2707
2708     if ($home) {
2709         #I remember recently being scolded for assigning config values like this
2710         $class->config->{home} ||= $home;
2711         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2712     }
2713 }
2714
2715 =head2 $c->setup_log
2716
2717 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2718 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2719 log to.
2720
2721 This method also installs a C<debug> method that returns a true value into the
2722 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2723 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2724
2725 Note that if the log has already been setup, by either a previous call to
2726 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2727 that this method won't actually set up the log object.
2728
2729 =cut
2730
2731 sub setup_log {
2732     my ( $class, $levels ) = @_;
2733
2734     $levels ||= '';
2735     $levels =~ s/^\s+//;
2736     $levels =~ s/\s+$//;
2737     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2738
2739     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2740     if ( defined $env_debug ) {
2741         $levels{debug} = 1 if $env_debug; # Ugly!
2742         delete($levels{debug}) unless $env_debug;
2743     }
2744
2745     unless ( $class->log ) {
2746         $class->log( Catalyst::Log->new(keys %levels) );
2747     }
2748
2749     if ( $levels{debug} ) {
2750         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2751         $class->log->debug('Debug messages enabled');
2752     }
2753 }
2754
2755 =head2 $c->setup_plugins
2756
2757 Sets up plugins.
2758
2759 =cut
2760
2761 =head2 $c->setup_stats
2762
2763 Sets up timing statistics class.
2764
2765 =cut
2766
2767 sub setup_stats {
2768     my ( $class, $stats ) = @_;
2769
2770     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2771
2772     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2773     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2774         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2775         $class->log->debug('Statistics enabled');
2776     }
2777 }
2778
2779
2780 =head2 $c->registered_plugins
2781
2782 Returns a sorted list of the plugins which have either been stated in the
2783 import list or which have been added via C<< MyApp->plugin(@args); >>.
2784
2785 If passed a given plugin name, it will report a boolean value indicating
2786 whether or not that plugin is loaded.  A fully qualified name is required if
2787 the plugin name does not begin with C<Catalyst::Plugin::>.
2788
2789  if ($c->registered_plugins('Some::Plugin')) {
2790      ...
2791  }
2792
2793 =cut
2794
2795 {
2796
2797     sub registered_plugins {
2798         my $proto = shift;
2799         return sort keys %{ $proto->_plugins } unless @_;
2800         my $plugin = shift;
2801         return 1 if exists $proto->_plugins->{$plugin};
2802         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2803     }
2804
2805     sub _register_plugin {
2806         my ( $proto, $plugin, $instant ) = @_;
2807         my $class = ref $proto || $proto;
2808
2809         Class::MOP::load_class( $plugin );
2810         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2811             if $plugin->isa( 'Catalyst::Component' );
2812         $proto->_plugins->{$plugin} = 1;
2813         unless ($instant) {
2814             my $meta = Class::MOP::get_metaclass_by_name($class);
2815             $meta->superclasses($plugin, $meta->superclasses);
2816         }
2817         return $class;
2818     }
2819
2820     sub setup_plugins {
2821         my ( $class, $plugins ) = @_;
2822
2823         $class->_plugins( {} ) unless $class->_plugins;
2824         $plugins = Data::OptList::mkopt($plugins || []);
2825
2826         my @plugins = map {
2827             [ Catalyst::Utils::resolve_namespace(
2828                   $class . '::Plugin',
2829                   'Catalyst::Plugin', $_->[0]
2830               ),
2831               $_->[1],
2832             ]
2833          } @{ $plugins };
2834
2835         for my $plugin ( reverse @plugins ) {
2836             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2837             my $meta = find_meta($plugin->[0]);
2838             next if $meta && $meta->isa('Moose::Meta::Role');
2839
2840             $class->_register_plugin($plugin->[0]);
2841         }
2842
2843         my @roles =
2844             map  { $_->[0]->name, $_->[1] }
2845             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2846             map  { [find_meta($_->[0]), $_->[1]] }
2847             @plugins;
2848
2849         Moose::Util::apply_all_roles(
2850             $class => @roles
2851         ) if @roles;
2852     }
2853 }
2854
2855 =head2 $c->stack
2856
2857 Returns an arrayref of the internal execution stack (actions that are
2858 currently executing).
2859
2860 =head2 $c->stats
2861
2862 Returns the current timing statistics object. By default Catalyst uses
2863 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2864 L<< stats_class|/"$c->stats_class" >>.
2865
2866 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2867 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2868 profile explicitly, although MyApp.pm still won't profile nor output anything
2869 by itself.
2870
2871 =head2 $c->stats_class
2872
2873 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2874
2875 =head2 $c->use_stats
2876
2877 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2878
2879 Note that this is a static method, not an accessor and should be overridden
2880 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2881
2882 =cut
2883
2884 sub use_stats { 0 }
2885
2886
2887 =head2 $c->write( $data )
2888
2889 Writes $data to the output stream. When using this method directly, you
2890 will need to manually set the C<Content-Length> header to the length of
2891 your output data, if known.
2892
2893 =cut
2894
2895 sub write {
2896     my $c = shift;
2897
2898     # Finalize headers if someone manually writes output
2899     $c->finalize_headers;
2900
2901     return $c->engine->write( $c, @_ );
2902 }
2903
2904 =head2 version
2905
2906 Returns the Catalyst version number. Mostly useful for "powered by"
2907 messages in template systems.
2908
2909 =cut
2910
2911 sub version { return $Catalyst::VERSION }
2912
2913 =head1 CONFIGURATION
2914
2915 There are a number of 'base' config variables which can be set:
2916
2917 =over
2918
2919 =item *
2920
2921 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2922
2923 =item *
2924
2925 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2926
2927 =item *
2928
2929 C<disable_component_resolution_regex_fallback> - Turns
2930 off the deprecated component resolution functionality so
2931 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2932 are called then regex search will not be attempted on string values and
2933 instead C<undef> will be returned.
2934
2935 =item *
2936
2937 C<home> - The application home directory. In an uninstalled application,
2938 this is the top level application directory. In an installed application,
2939 this will be the directory containing C<< MyApp.pm >>.
2940
2941 =item *
2942
2943 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2944
2945 =item *
2946
2947 C<name> - The name of the application in debug messages and the debug and
2948 welcome screens
2949
2950 =item *
2951
2952 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2953 until it is accessed. This allows you to (for example) check authentication (and reject
2954 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2955
2956 =item *
2957
2958 C<root> - The root directory for templates. Usually this is just a
2959 subdirectory of the home directory, but you can set it to change the
2960 templates to a different directory.
2961
2962 =item *
2963
2964 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2965 namespaces from which components will be loaded (and constructed and stored in
2966 C<< $c->components >>).
2967
2968 =item *
2969
2970 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2971 to be shown in hit debug tables in the test server.
2972
2973 =item *
2974
2975 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
2976 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
2977 for more information.
2978
2979 =item *
2980
2981 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2982
2983 =back
2984
2985 =head1 INTERNAL ACTIONS
2986
2987 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2988 C<_ACTION>, and C<_END>. These are by default not shown in the private
2989 action table, but you can make them visible with a config parameter.
2990
2991     MyApp->config(show_internal_actions => 1);
2992
2993 =head1 ON-DEMAND PARSER
2994
2995 The request body is usually parsed at the beginning of a request,
2996 but if you want to handle input yourself, you can enable on-demand
2997 parsing with a config parameter.
2998
2999     MyApp->config(parse_on_demand => 1);
3000
3001 =head1 PROXY SUPPORT
3002
3003 Many production servers operate using the common double-server approach,
3004 with a lightweight frontend web server passing requests to a larger
3005 backend server. An application running on the backend server must deal
3006 with two problems: the remote user always appears to be C<127.0.0.1> and
3007 the server's hostname will appear to be C<localhost> regardless of the
3008 virtual host that the user connected through.
3009
3010 Catalyst will automatically detect this situation when you are running
3011 the frontend and backend servers on the same machine. The following
3012 changes are made to the request.
3013
3014     $c->req->address is set to the user's real IP address, as read from
3015     the HTTP X-Forwarded-For header.
3016
3017     The host value for $c->req->base and $c->req->uri is set to the real
3018     host, as read from the HTTP X-Forwarded-Host header.
3019
3020 Additionally, you may be running your backend application on an insecure
3021 connection (port 80) while your frontend proxy is running under SSL.  If there
3022 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3023 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3024 be created properly.
3025
3026 In the case of passing in:
3027
3028     X-Forwarded-Port: 443
3029
3030 All calls to C<uri_for> will result in an https link, as is expected.
3031
3032 Obviously, your web server must support these headers for this to work.
3033
3034 In a more complex server farm environment where you may have your
3035 frontend proxy server(s) on different machines, you will need to set a
3036 configuration option to tell Catalyst to read the proxied data from the
3037 headers.
3038
3039     MyApp->config(using_frontend_proxy => 1);
3040
3041 If you do not wish to use the proxy support at all, you may set:
3042
3043     MyApp->config(ignore_frontend_proxy => 1);
3044
3045 =head1 THREAD SAFETY
3046
3047 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3048 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3049 believe the Catalyst core to be thread-safe.
3050
3051 If you plan to operate in a threaded environment, remember that all other
3052 modules you are using must also be thread-safe. Some modules, most notably
3053 L<DBD::SQLite>, are not thread-safe.
3054
3055 =head1 SUPPORT
3056
3057 IRC:
3058
3059     Join #catalyst on irc.perl.org.
3060
3061 Mailing Lists:
3062
3063     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3064     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3065
3066 Web:
3067
3068     http://catalyst.perl.org
3069
3070 Wiki:
3071
3072     http://dev.catalyst.perl.org
3073
3074 =head1 SEE ALSO
3075
3076 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3077
3078 =head2 L<Catalyst::Manual> - The Catalyst Manual
3079
3080 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3081
3082 =head2 L<Catalyst::Engine> - Core engine
3083
3084 =head2 L<Catalyst::Log> - Log class.
3085
3086 =head2 L<Catalyst::Request> - Request object
3087
3088 =head2 L<Catalyst::Response> - Response object
3089
3090 =head2 L<Catalyst::Test> - The test suite.
3091
3092 =head1 PROJECT FOUNDER
3093
3094 sri: Sebastian Riedel <sri@cpan.org>
3095
3096 =head1 CONTRIBUTORS
3097
3098 abw: Andy Wardley
3099
3100 acme: Leon Brocard <leon@astray.com>
3101
3102 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3103
3104 Andrew Bramble
3105
3106 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3107
3108 Andrew Ruthven
3109
3110 andyg: Andy Grundman <andy@hybridized.org>
3111
3112 audreyt: Audrey Tang
3113
3114 bricas: Brian Cassidy <bricas@cpan.org>
3115
3116 Caelum: Rafael Kitover <rkitover@io.com>
3117
3118 chansen: Christian Hansen
3119
3120 chicks: Christopher Hicks
3121
3122 Chisel Wright C<pause@herlpacker.co.uk>
3123
3124 Danijel Milicevic C<me@danijel.de>
3125
3126 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3127
3128 David Naughton, C<naughton@umn.edu>
3129
3130 David E. Wheeler
3131
3132 dhoss: Devin Austin <dhoss@cpan.org>
3133
3134 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3135
3136 Drew Taylor
3137
3138 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3139
3140 esskar: Sascha Kiefer
3141
3142 fireartist: Carl Franks <cfranks@cpan.org>
3143
3144 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3145
3146 gabb: Danijel Milicevic
3147
3148 Gary Ashton Jones
3149
3150 Gavin Henry C<ghenry@perl.me.uk>
3151
3152 Geoff Richards
3153
3154 groditi: Guillermo Roditi <groditi@gmail.com>
3155
3156 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3157
3158 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3159
3160 jcamacho: Juan Camacho
3161
3162 jester: Jesse Sheidlower C<jester@panix.com>
3163
3164 jhannah: Jay Hannah <jay@jays.net>
3165
3166 Jody Belka
3167
3168 Johan Lindstrom
3169
3170 jon: Jon Schutz <jjschutz@cpan.org>
3171
3172 Jonathan Rockway C<< <jrockway@cpan.org> >>
3173
3174 Kieren Diment C<kd@totaldatasolution.com>
3175
3176 konobi: Scott McWhirter <konobi@cpan.org>
3177
3178 marcus: Marcus Ramberg <mramberg@cpan.org>
3179
3180 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3181
3182 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3183
3184 mugwump: Sam Vilain
3185
3186 naughton: David Naughton
3187
3188 ningu: David Kamholz <dkamholz@cpan.org>
3189
3190 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3191
3192 numa: Dan Sully <daniel@cpan.org>
3193
3194 obra: Jesse Vincent
3195
3196 Octavian Rasnita
3197
3198 omega: Andreas Marienborg
3199
3200 Oleg Kostyuk <cub.uanic@gmail.com>
3201
3202 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3203
3204 rafl: Florian Ragwitz <rafl@debian.org>
3205
3206 random: Roland Lammel <lammel@cpan.org>
3207
3208 Robert Sedlacek C<< <rs@474.at> >>
3209
3210 SpiceMan: Marcel Montes
3211
3212 sky: Arthur Bergman
3213
3214 szbalint: Balint Szilakszi <szbalint@cpan.org>
3215
3216 t0m: Tomas Doran <bobtfish@bobtfish.net>
3217
3218 Ulf Edvinsson
3219
3220 Viljo Marrandi C<vilts@yahoo.com>
3221
3222 Will Hawes C<info@whawes.co.uk>
3223
3224 willert: Sebastian Willert <willert@cpan.org>
3225
3226 wreis: Wallace Reis <wallace@reis.org.br>
3227
3228 Yuval Kogman, C<nothingmuch@woobling.org>
3229
3230 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3231
3232 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3233
3234 =head1 COPYRIGHT
3235
3236 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3237
3238 =head1 LICENSE
3239
3240 This library is free software. You can redistribute it and/or modify it under
3241 the same terms as Perl itself.
3242
3243 =cut
3244
3245 no Moose;
3246
3247 __PACKAGE__->meta->make_immutable;
3248
3249 1;