lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken blessed/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 __PACKAGE__->mk_accessors(
  34     qw/counter request response state action stack namespace stats/
  35 );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52 our $GO        = "catalyst_go\n";
  53
  54 __PACKAGE__->mk_classdata($_)
  55   for qw/components arguments dispatcher engine log dispatcher_class
  56   engine_class context_class request_class response_class stats_class
  57   setup_finished/;
  58
  59 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  60 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  61 __PACKAGE__->request_class('Catalyst::Request');
  62 __PACKAGE__->response_class('Catalyst::Response');
  63 __PACKAGE__->stats_class('Catalyst::Stats');
  64
  65 # Remember to update this in Catalyst::Runtime as well!
  66
  67 our $VERSION = '5.7099_03';
  68
  69 sub import {
  70     my ( $class, @arguments ) = @_;
  71
  72     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  73     # callers @ISA.
  74     return unless $class eq 'Catalyst';
  75
  76     my $caller = caller(0);
  77
  78     unless ( $caller->isa('Catalyst') ) {
  79         no strict 'refs';
  80         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  81     }
  82
  83     $caller->arguments( [@arguments] );
  84     $caller->setup_home;
  85 }
  86
  87 =head1 NAME
  88
  89 Catalyst - The Elegant MVC Web Application Framework
  90
  91 =head1 SYNOPSIS
  92
  93 See the L<Catalyst::Manual> distribution for comprehensive
  94 documentation and tutorials.
  95
  96     # Install Catalyst::Devel for helpers and other development tools
  97     # use the helper to create a new application
  98     catalyst.pl MyApp
  99
 100     # add models, views, controllers
 101     script/myapp_create.pl model MyDatabase DBIC::Schema create=dynamic dbi:SQLite:/path/to/db
 102     script/myapp_create.pl view MyTemplate TT
 103     script/myapp_create.pl controller Search
 104
 105     # built in testserver -- use -r to restart automatically on changes
 106     # --help to see all available options
 107     script/myapp_server.pl
 108
 109     # command line testing interface
 110     script/myapp_test.pl /yada
 111
 112     ### in lib/MyApp.pm
 113     use Catalyst qw/-Debug/; # include plugins here as well
 114
 115     ### In lib/MyApp/Controller/Root.pm (autocreated)
 116     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 117         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 118         $c->stash->{template} = 'foo.tt'; # set the template
 119         # lookup something from db -- stash vars are passed to TT
 120         $c->stash->{data} =
 121           $c->model('Database::Foo')->search( { country => $args[0] } );
 122         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 123             $c->forward( 'bar' ); # process another action
 124             # do something else after forward returns
 125         }
 126     }
 127
 128     # The foo.tt TT template can use the stash data from the database
 129     [% WHILE (item = data.next) %]
 130         [% item.foo %]
 131     [% END %]
 132
 133     # called for /bar/of/soap, /bar/of/soap/10, etc.
 134     sub bar : Path('/bar/of/soap') { ... }
 135
 136     # called for all actions, from the top-most controller downwards
 137     sub auto : Private {
 138         my ( $self, $c ) = @_;
 139         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 140             $c->res->redirect( '/login' ); # require login
 141             return 0; # abort request and go immediately to end()
 142         }
 143         return 1; # success; carry on to next action
 144     }
 145
 146     # called after all actions are finished
 147     sub end : Private {
 148         my ( $self, $c ) = @_;
 149         if ( scalar @{ $c->error } ) { ... } # handle errors
 150         return if $c->res->body; # already have a response
 151         $c->forward( 'MyApp::View::TT' ); # render template
 152     }
 153
 154     ### in MyApp/Controller/Foo.pm
 155     # called for /foo/bar
 156     sub bar : Local { ... }
 157
 158     # called for /blargle
 159     sub blargle : Global { ... }
 160
 161     # an index action matches /foo, but not /foo/1, etc.
 162     sub index : Private { ... }
 163
 164     ### in MyApp/Controller/Foo/Bar.pm
 165     # called for /foo/bar/baz
 166     sub baz : Local { ... }
 167
 168     # first Root auto is called, then Foo auto, then this
 169     sub auto : Private { ... }
 170
 171     # powerful regular expression paths are also possible
 172     sub details : Regex('^product/(\w+)/details$') {
 173         my ( $self, $c ) = @_;
 174         # extract the (\w+) from the URI
 175         my $product = $c->req->captures->[0];
 176     }
 177
 178 See L<Catalyst::Manual::Intro> for additional information.
 179
 180 =head1 DESCRIPTION
 181
 182 Catalyst is a modern framework for making web applications without the
 183 pain usually associated with this process. This document is a reference
 184 to the main Catalyst application. If you are a new user, we suggest you
 185 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 186
 187 See L<Catalyst::Manual> for more documentation.
 188
 189 Catalyst plugins can be loaded by naming them as arguments to the "use
 190 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 191 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 192 C<My::Module>.
 193
 194     use Catalyst qw/My::Module/;
 195
 196 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 197 fully qualify the name by using a unary plus:
 198
 199     use Catalyst qw/
 200         My::Module
 201         +Fully::Qualified::Plugin::Name
 202     /;
 203
 204 Special flags like C<-Debug> and C<-Engine> can also be specified as
 205 arguments when Catalyst is loaded:
 206
 207     use Catalyst qw/-Debug My::Module/;
 208
 209 The position of plugins and flags in the chain is important, because
 210 they are loaded in the order in which they appear.
 211
 212 The following flags are supported:
 213
 214 =head2 -Debug
 215
 216 Enables debug output. You can also force this setting from the system
 217 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 218 settings override the application, with <MYAPP>_DEBUG having the highest
 219 priority.
 220
 221 =head2 -Engine
 222
 223 Forces Catalyst to use a specific engine. Omit the
 224 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 225
 226     use Catalyst qw/-Engine=CGI/;
 227
 228 =head2 -Home
 229
 230 Forces Catalyst to use a specific home directory, e.g.:
 231
 232     use Catalyst qw[-Home=/usr/mst];
 233
 234 This can also be done in the shell environment by setting either the
 235 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 236 is replaced with the uppercased name of your application, any "::" in
 237 the name will be replaced with underscores, e.g. MyApp::Web should use
 238 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 239
 240 =head2 -Log
 241
 242 Specifies log level.
 243
 244 =head2 -Stats
 245
 246 Enables statistics collection and reporting. You can also force this setting
 247 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 248 environment settings override the application, with <MYAPP>_STATS having the
 249 highest priority.
 250
 251 e.g.
 252
 253    use Catalyst qw/-Stats=1/
 254
 255 =head1 METHODS
 256
 257 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 258
 259 =head2 $c->action
 260
 261 Returns a L<Catalyst::Action> object for the current action, which
 262 stringifies to the action name. See L<Catalyst::Action>.
 263
 264 =head2 $c->namespace
 265
 266 Returns the namespace of the current action, i.e., the URI prefix
 267 corresponding to the controller of the current action. For example:
 268
 269     # in Controller::Foo::Bar
 270     $c->namespace; # returns 'foo/bar';
 271
 272 =head2 $c->request
 273
 274 =head2 $c->req
 275
 276 Returns the current L<Catalyst::Request> object, giving access to
 277 information about the current client request (including parameters,
 278 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 279
 280 =head2 REQUEST FLOW HANDLING
 281
 282 =head2 $c->forward( $action [, \@arguments ] )
 283
 284 =head2 $c->forward( $class, $method, [, \@arguments ] )
 285
 286 Forwards processing to another action, by its private name. If you give a
 287 class name but no method, C<process()> is called. You may also optionally
 288 pass arguments in an arrayref. The action will receive the arguments in
 289 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 290 C<< $c->req->args >> will be restored to the previous values.
 291
 292 Any data C<return>ed from the action forwarded to, will be returned by the
 293 call to forward.
 294
 295     my $foodata = $c->forward('/foo');
 296     $c->forward('index');
 297     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 298     $c->forward('MyApp::View::TT');
 299
 300 Note that forward implies an C<<eval { }>> around the call (actually
 301 C<execute> does), thus de-fatalizing all 'dies' within the called
 302 action. If you want C<die> to propagate you need to do something like:
 303
 304     $c->forward('foo');
 305     die $c->error if $c->error;
 306
 307 Or make sure to always return true values from your actions and write
 308 your code like this:
 309
 310     $c->forward('foo') || return;
 311
 312 =cut
 313
 314 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 315
 316 =head2 $c->detach( $action [, \@arguments ] )
 317
 318 =head2 $c->detach( $class, $method, [, \@arguments ] )
 319
 320 =head2 $c->detach()
 321
 322 The same as C<forward>, but doesn't return to the previous action when
 323 processing is finished.
 324
 325 When called with no arguments it escapes the processing chain entirely.
 326
 327 =cut
 328
 329 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 330
 331 =head2 $c->go( $action [, \@arguments ] )
 332
 333 =head2 $c->go( $class, $method, [, \@arguments ] )
 334
 335 Almost the same as C<detach>, but does a full dispatch, instead of just
 336 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 337 C<auto> and the method you go to is called, just like a new request.
 338
 339 C<$c-E<gt>stash> is kept unchanged.
 340
 341 =cut
 342
 343 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 344
 345 =head2 $c->response
 346
 347 =head2 $c->res
 348
 349 Returns the current L<Catalyst::Response> object, see there for details.
 350
 351 =head2 $c->stash
 352
 353 Returns a hashref to the stash, which may be used to store data and pass
 354 it between components during a request. You can also set hash keys by
 355 passing arguments. The stash is automatically sent to the view. The
 356 stash is cleared at the end of a request; it cannot be used for
 357 persistent storage (for this you must use a session; see
 358 L<Catalyst::Plugin::Session> for a complete system integrated with
 359 Catalyst).
 360
 361     $c->stash->{foo} = $bar;
 362     $c->stash( { moose => 'majestic', qux => 0 } );
 363     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 364
 365     # stash is automatically passed to the view for use in a template
 366     $c->forward( 'MyApp::View::TT' );
 367
 368 =cut
 369
 370 sub stash {
 371     my $c = shift;
 372     if (@_) {
 373         my $stash = @_ > 1 ? {@_} : $_[0];
 374         croak('stash takes a hash or hashref') unless ref $stash;
 375         foreach my $key ( keys %$stash ) {
 376             $c->{stash}->{$key} = $stash->{$key};
 377         }
 378     }
 379     return $c->{stash};
 380 }
 381
 382 =head2 $c->error
 383
 384 =head2 $c->error($error, ...)
 385
 386 =head2 $c->error($arrayref)
 387
 388 Returns an arrayref containing error messages.  If Catalyst encounters an
 389 error while processing a request, it stores the error in $c->error.  This
 390 method should only be used to store fatal error messages.
 391
 392     my @error = @{ $c->error };
 393
 394 Add a new error.
 395
 396     $c->error('Something bad happened');
 397
 398 =cut
 399
 400 sub error {
 401     my $c = shift;
 402     if ( $_[0] ) {
 403         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 404         croak @$error unless ref $c;
 405         push @{ $c->{error} }, @$error;
 406     }
 407     elsif ( defined $_[0] ) { $c->{error} = undef }
 408     return $c->{error} || [];
 409 }
 410
 411
 412 =head2 $c->state
 413
 414 Contains the return value of the last executed action.
 415
 416 =head2 $c->clear_errors
 417
 418 Clear errors.  You probably don't want to clear the errors unless you are
 419 implementing a custom error screen.
 420
 421 This is equivalent to running
 422
 423     $c->error(0);
 424
 425 =cut
 426
 427 sub clear_errors {
 428     my $c = shift;
 429     $c->error(0);
 430 }
 431
 432 # search components given a name and some prefixes
 433 sub _comp_search_prefixes {
 434     my ( $c, $name, @prefixes ) = @_;
 435     my $appclass = ref $c || $c;
 436     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 437
 438     # map the original component name to the sub part that we will search against
 439     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 440         grep { /$filter/ } keys %{ $c->components };
 441
 442     # undef for a name will return all
 443     return keys %eligible if !defined $name;
 444
 445     my $query  = ref $name ? $name : qr/^$name$/i;
 446     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 447
 448     return map { $c->components->{ $_ } } @result if @result;
 449
 450     # if we were given a regexp to search against, we're done.
 451     return if ref $name;
 452
 453     # regexp fallback
 454     $query  = qr/$name/i;
 455     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 456
 457     # no results? try against full names
 458     if( !@result ) {
 459         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 460     }
 461
 462     # don't warn if we didn't find any results, it just might not exist
 463     if( @result ) {
 464         $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 465         $c->log->warn( 'Relying on the regexp fallback behavior for component resolution is unreliable and unsafe.' );
 466         $c->log->warn( 'If you really want to search, pass in a regexp as the argument.' );
 467     }
 468
 469     return @result;
 470 }
 471
 472 # Find possible names for a prefix
 473 sub _comp_names {
 474     my ( $c, @prefixes ) = @_;
 475     my $appclass = ref $c || $c;
 476
 477     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 478
 479     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 480     return @names;
 481 }
 482
 483 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 484 sub _filter_component {
 485     my ( $c, $comp, @args ) = @_;
 486
 487     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 488         return $comp->ACCEPT_CONTEXT( $c, @args );
 489     }
 490
 491     return $comp;
 492 }
 493
 494 =head2 COMPONENT ACCESSORS
 495
 496 =head2 $c->controller($name)
 497
 498 Gets a L<Catalyst::Controller> instance by name.
 499
 500     $c->controller('Foo')->do_stuff;
 501
 502 If the name is omitted, will return the controller for the dispatched
 503 action.
 504
 505 If you want to search for controllers, pass in a regexp as the argument.
 506
 507     # find all controllers that start with Foo
 508     my @foo_controllers = $c->controller(qr{^Foo});
 509
 510
 511 =cut
 512
 513 sub controller {
 514     my ( $c, $name, @args ) = @_;
 515
 516     if( $name ) {
 517         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 518         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 519         return $c->_filter_component( $result[ 0 ], @args );
 520     }
 521
 522     return $c->component( $c->action->class );
 523 }
 524
 525 =head2 $c->model($name)
 526
 527 Gets a L<Catalyst::Model> instance by name.
 528
 529     $c->model('Foo')->do_stuff;
 530
 531 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 532
 533 If the name is omitted, it will look for
 534  - a model object in $c->stash->{current_model_instance}, then
 535  - a model name in $c->stash->{current_model}, then
 536  - a config setting 'default_model', or
 537  - check if there is only one model, and return it if that's the case.
 538
 539 If you want to search for models, pass in a regexp as the argument.
 540
 541     # find all models that start with Foo
 542     my @foo_models = $c->model(qr{^Foo});
 543
 544 =cut
 545
 546 sub model {
 547     my ( $c, $name, @args ) = @_;
 548
 549     if( $name ) {
 550         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 551         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 552         return $c->_filter_component( $result[ 0 ], @args );
 553     }
 554
 555     if (ref $c) {
 556         return $c->stash->{current_model_instance}
 557           if $c->stash->{current_model_instance};
 558         return $c->model( $c->stash->{current_model} )
 559           if $c->stash->{current_model};
 560     }
 561     return $c->model( $c->config->{default_model} )
 562       if $c->config->{default_model};
 563
 564     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 565
 566     if( $rest ) {
 567         $c->log->warn( 'Calling $c->model() will return a random model unless you specify one of:' );
 568         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 569         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 570         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 571         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 572     }
 573
 574     return $c->_filter_component( $comp );
 575 }
 576
 577
 578 =head2 $c->view($name)
 579
 580 Gets a L<Catalyst::View> instance by name.
 581
 582     $c->view('Foo')->do_stuff;
 583
 584 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 585
 586 If the name is omitted, it will look for
 587  - a view object in $c->stash->{current_view_instance}, then
 588  - a view name in $c->stash->{current_view}, then
 589  - a config setting 'default_view', or
 590  - check if there is only one view, and return it if that's the case.
 591
 592 If you want to search for views, pass in a regexp as the argument.
 593
 594     # find all views that start with Foo
 595     my @foo_views = $c->view(qr{^Foo});
 596
 597 =cut
 598
 599 sub view {
 600     my ( $c, $name, @args ) = @_;
 601
 602     if( $name ) {
 603         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 604         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 605         return $c->_filter_component( $result[ 0 ], @args );
 606     }
 607
 608     if (ref $c) {
 609         return $c->stash->{current_view_instance}
 610           if $c->stash->{current_view_instance};
 611         return $c->view( $c->stash->{current_view} )
 612           if $c->stash->{current_view};
 613     }
 614     return $c->view( $c->config->{default_view} )
 615       if $c->config->{default_view};
 616
 617     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 618
 619     if( $rest ) {
 620         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 621         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 622         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 623         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 624         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 625     }
 626
 627     return $c->_filter_component( $comp );
 628 }
 629
 630 =head2 $c->controllers
 631
 632 Returns the available names which can be passed to $c->controller
 633
 634 =cut
 635
 636 sub controllers {
 637     my ( $c ) = @_;
 638     return $c->_comp_names(qw/Controller C/);
 639 }
 640
 641 =head2 $c->models
 642
 643 Returns the available names which can be passed to $c->model
 644
 645 =cut
 646
 647 sub models {
 648     my ( $c ) = @_;
 649     return $c->_comp_names(qw/Model M/);
 650 }
 651
 652
 653 =head2 $c->views
 654
 655 Returns the available names which can be passed to $c->view
 656
 657 =cut
 658
 659 sub views {
 660     my ( $c ) = @_;
 661     return $c->_comp_names(qw/View V/);
 662 }
 663
 664 =head2 $c->comp($name)
 665
 666 =head2 $c->component($name)
 667
 668 Gets a component object by name. This method is not recommended,
 669 unless you want to get a specific component by full
 670 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 671 should be used instead.
 672
 673 If C<$name> is a regexp, a list of components matched against the full
 674 component name will be returned.
 675
 676 =cut
 677
 678 sub component {
 679     my ( $c, $name, @args ) = @_;
 680
 681     if( $name ) {
 682         my $comps = $c->components;
 683
 684         if( !ref $name ) {
 685             # is it the exact name?
 686             return $c->_filter_component( $comps->{ $name }, @args )
 687                        if exists $comps->{ $name };
 688
 689             # perhaps we just omitted "MyApp"?
 690             my $composed = ( ref $c || $c ) . "::${name}";
 691             return $c->_filter_component( $comps->{ $composed }, @args )
 692                        if exists $comps->{ $composed };
 693
 694             # search all of the models, views and controllers
 695             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 696             return $c->_filter_component( $comp, @args ) if $comp;
 697         }
 698
 699         # This is here so $c->comp( '::M::' ) works
 700         my $query = ref $name ? $name : qr{$name}i;
 701
 702         my @result = grep { m{$query} } keys %{ $c->components };
 703         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 704
 705         if( $result[ 0 ] ) {
 706             $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 707             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 708             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 709             return $c->_filter_component( $result[ 0 ], @args );
 710         }
 711
 712         # I would expect to return an empty list here, but that breaks back-compat
 713     }
 714
 715     # fallback
 716     return sort keys %{ $c->components };
 717 }
 718
 719 =head2 CLASS DATA AND HELPER CLASSES
 720
 721 =head2 $c->config
 722
 723 Returns or takes a hashref containing the application's configuration.
 724
 725     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 726
 727 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 728 like myapp.yml in your applications home directory. See
 729 L<Catalyst::Plugin::ConfigLoader>.
 730
 731     ---
 732     db: dsn:SQLite:foo.db
 733
 734
 735 =cut
 736
 737 sub config {
 738     my $c = shift;
 739
 740     $c->log->warn("Setting config after setup has been run is not a good idea.")
 741       if ( @_ and $c->setup_finished );
 742
 743     $c->NEXT::config(@_);
 744 }
 745
 746 =head2 $c->log
 747
 748 Returns the logging object instance. Unless it is already set, Catalyst
 749 sets this up with a L<Catalyst::Log> object. To use your own log class,
 750 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 751 C<< __PACKAGE__->setup >>.
 752
 753  __PACKAGE__->log( MyLogger->new );
 754  __PACKAGE__->setup;
 755
 756 And later:
 757
 758     $c->log->info( 'Now logging with my own logger!' );
 759
 760 Your log class should implement the methods described in
 761 L<Catalyst::Log>.
 762
 763
 764 =head2 $c->debug
 765
 766 Overload to enable debug messages (same as -Debug option).
 767
 768 Note that this is a static method, not an accessor and should be overloaded
 769 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 770
 771 =cut
 772
 773 sub debug { 0 }
 774
 775 =head2 $c->dispatcher
 776
 777 Returns the dispatcher instance. Stringifies to class name. See
 778 L<Catalyst::Dispatcher>.
 779
 780 =head2 $c->engine
 781
 782 Returns the engine instance. Stringifies to the class name. See
 783 L<Catalyst::Engine>.
 784
 785
 786 =head2 UTILITY METHODS
 787
 788 =head2 $c->path_to(@path)
 789
 790 Merges C<@path> with C<< $c->config->{home} >> and returns a
 791 L<Path::Class::Dir> object. Must be called after C<< MyApp->setup >>,
 792 which sets up C<< $c->config->{home} >>.
 793
 794 For example:
 795
 796     $c->path_to( 'db', 'sqlite.db' );
 797
 798 =cut
 799
 800 sub path_to {
 801     my ( $c, @path ) = @_;
 802     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 803     if ( -d $path ) { return $path }
 804     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 805 }
 806
 807 =head2 $c->plugin( $name, $class, @args )
 808
 809 Helper method for plugins. It creates a classdata accessor/mutator and
 810 loads and instantiates the given class.
 811
 812     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 813
 814     $c->prototype->define_javascript_functions;
 815
 816 =cut
 817
 818 sub plugin {
 819     my ( $class, $name, $plugin, @args ) = @_;
 820     $class->_register_plugin( $plugin, 1 );
 821
 822     eval { $plugin->import };
 823     $class->mk_classdata($name);
 824     my $obj;
 825     eval { $obj = $plugin->new(@args) };
 826
 827     if ($@) {
 828         Catalyst::Exception->throw( message =>
 829               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 830     }
 831
 832     $class->$name($obj);
 833     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 834       if $class->debug;
 835 }
 836
 837 =head2 MyApp->setup
 838
 839 Initializes the dispatcher and engine, loads any plugins, and loads the
 840 model, view, and controller components. You may also specify an array
 841 of plugins to load here, if you choose to not load them in the C<use
 842 Catalyst> line.
 843
 844     MyApp->setup;
 845     MyApp->setup( qw/-Debug/ );
 846
 847 =cut
 848
 849 sub setup {
 850     my ( $class, @arguments ) = @_;
 851
 852     $class->log->warn("Running setup twice is not a good idea.")
 853       if ( $class->setup_finished );
 854
 855     unless ( $class->isa('Catalyst') ) {
 856
 857         Catalyst::Exception->throw(
 858             message => qq/'$class' does not inherit from Catalyst/ );
 859     }
 860
 861     if ( $class->arguments ) {
 862         @arguments = ( @arguments, @{ $class->arguments } );
 863     }
 864
 865     # Process options
 866     my $flags = {};
 867
 868     foreach (@arguments) {
 869
 870         if (/^-Debug$/) {
 871             $flags->{log} =
 872               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 873         }
 874         elsif (/^-(\w+)=?(.*)$/) {
 875             $flags->{ lc $1 } = $2;
 876         }
 877         else {
 878             push @{ $flags->{plugins} }, $_;
 879         }
 880     }
 881
 882     $class->setup_home( delete $flags->{home} );
 883
 884     $class->setup_log( delete $flags->{log} );
 885     $class->setup_plugins( delete $flags->{plugins} );
 886     $class->setup_dispatcher( delete $flags->{dispatcher} );
 887     $class->setup_engine( delete $flags->{engine} );
 888     $class->setup_stats( delete $flags->{stats} );
 889
 890     for my $flag ( sort keys %{$flags} ) {
 891
 892         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 893             &$code( $class, delete $flags->{$flag} );
 894         }
 895         else {
 896             $class->log->warn(qq/Unknown flag "$flag"/);
 897         }
 898     }
 899
 900     eval { require Catalyst::Devel; };
 901     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 902         $class->log->warn(<<"EOF");
 903 You are running an old script!
 904
 905   Please update by running (this will overwrite existing files):
 906     catalyst.pl -force -scripts $class
 907
 908   or (this will not overwrite existing files):
 909     catalyst.pl -scripts $class
 910
 911 EOF
 912     }
 913
 914     if ( $class->debug ) {
 915         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 916
 917         if (@plugins) {
 918             my $t = Text::SimpleTable->new(74);
 919             $t->row($_) for @plugins;
 920             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 921         }
 922
 923         my $dispatcher = $class->dispatcher;
 924         my $engine     = $class->engine;
 925         my $home       = $class->config->{home};
 926
 927         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 928         $class->log->debug(qq/Loaded engine "$engine"/);
 929
 930         $home
 931           ? ( -d $home )
 932           ? $class->log->debug(qq/Found home "$home"/)
 933           : $class->log->debug(qq/Home "$home" doesn't exist/)
 934           : $class->log->debug(q/Couldn't find home/);
 935     }
 936
 937     # Call plugins setup
 938     {
 939         no warnings qw/redefine/;
 940         local *setup = sub { };
 941         $class->setup;
 942     }
 943
 944     # Initialize our data structure
 945     $class->components( {} );
 946
 947     $class->setup_components;
 948
 949     if ( $class->debug ) {
 950         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 951         for my $comp ( sort keys %{ $class->components } ) {
 952             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 953             $t->row( $comp, $type );
 954         }
 955         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 956           if ( keys %{ $class->components } );
 957     }
 958
 959     # Add our self to components, since we are also a component
 960     $class->components->{$class} = $class;
 961
 962     $class->setup_actions;
 963
 964     if ( $class->debug ) {
 965         my $name = $class->config->{name} || 'Application';
 966         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 967     }
 968     $class->log->_flush() if $class->log->can('_flush');
 969
 970     $class->setup_finished(1);
 971 }
 972
 973 =head2 $c->uri_for( $path, @args?, \%query_values? )
 974
 975 Merges path with C<< $c->request->base >> for absolute URIs and with
 976 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 977 object. If any args are passed, they are added at the end of the path.
 978 If the last argument to C<uri_for> is a hash reference, it is assumed to
 979 contain GET parameter key/value pairs, which will be appended to the URI
 980 in standard fashion.
 981
 982 Note that uri_for is destructive to the passed hashref.  Subsequent calls
 983 with the same hashref may have unintended results.
 984
 985 Instead of C<$path>, you can also optionally pass a C<$action> object
 986 which will be resolved to a path using
 987 C<< $c->dispatcher->uri_for_action >>; if the first element of
 988 C<@args> is an arrayref it is treated as a list of captures to be passed
 989 to C<uri_for_action>.
 990
 991 =cut
 992
 993 sub uri_for {
 994     my ( $c, $path, @args ) = @_;
 995
 996     if ( Scalar::Util::blessed($path) ) { # action object
 997         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 998                          ? shift(@args)
 999                          : [] );
1000         $path = $c->dispatcher->uri_for_action($path, $captures);
1001         return undef unless defined($path);
1002         $path = '/' if $path eq '';
1003     }
1004
1005     undef($path) if (defined $path && $path eq '');
1006
1007     my $params =
1008       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1009
1010     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1011     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1012
1013     unshift(@args, $path);
1014
1015     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1016         my $namespace = $c->namespace;
1017         if (defined $path) { # cheesy hack to handle path '../foo'
1018            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1019         }
1020         unshift(@args, $namespace || '');
1021     }
1022
1023     # join args with '/', or a blank string
1024     my $args = join('/', grep { defined($_) } @args);
1025     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1026     $args =~ s!^/!!;
1027     my $base = $c->req->base;
1028     my $class = ref($base);
1029     $base =~ s{(?<!/)$}{/};
1030
1031     my $query = '';
1032
1033     if (my @keys = keys %$params) {
1034       # somewhat lifted from URI::_query's query_form
1035       $query = '?'.join('&', map {
1036           my $val = $params->{$_};
1037           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1038           s/ /+/g;
1039           my $key = $_;
1040           $val = '' unless defined $val;
1041           (map {
1042               $_ = "$_";
1043               utf8::encode( $_ ) if utf8::is_utf8($_);
1044               # using the URI::Escape pattern here so utf8 chars survive
1045               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1046               s/ /+/g;
1047               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1048       } @keys);
1049     }
1050
1051     my $res = bless(\"${base}${args}${query}", $class);
1052     $res;
1053 }
1054
1055 =head2 $c->welcome_message
1056
1057 Returns the Catalyst welcome HTML page.
1058
1059 =cut
1060
1061 sub welcome_message {
1062     my $c      = shift;
1063     my $name   = $c->config->{name};
1064     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1065     my $prefix = Catalyst::Utils::appprefix( ref $c );
1066     $c->response->content_type('text/html; charset=utf-8');
1067     return <<"EOF";
1068 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1069     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1070 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1071     <head>
1072     <meta http-equiv="Content-Language" content="en" />
1073     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1074         <title>$name on Catalyst $VERSION</title>
1075         <style type="text/css">
1076             body {
1077                 color: #000;
1078                 background-color: #eee;
1079             }
1080             div#content {
1081                 width: 640px;
1082                 margin-left: auto;
1083                 margin-right: auto;
1084                 margin-top: 10px;
1085                 margin-bottom: 10px;
1086                 text-align: left;
1087                 background-color: #ccc;
1088                 border: 1px solid #aaa;
1089             }
1090             p, h1, h2 {
1091                 margin-left: 20px;
1092                 margin-right: 20px;
1093                 font-family: verdana, tahoma, sans-serif;
1094             }
1095             a {
1096                 font-family: verdana, tahoma, sans-serif;
1097             }
1098             :link, :visited {
1099                     text-decoration: none;
1100                     color: #b00;
1101                     border-bottom: 1px dotted #bbb;
1102             }
1103             :link:hover, :visited:hover {
1104                     color: #555;
1105             }
1106             div#topbar {
1107                 margin: 0px;
1108             }
1109             pre {
1110                 margin: 10px;
1111                 padding: 8px;
1112             }
1113             div#answers {
1114                 padding: 8px;
1115                 margin: 10px;
1116                 background-color: #fff;
1117                 border: 1px solid #aaa;
1118             }
1119             h1 {
1120                 font-size: 0.9em;
1121                 font-weight: normal;
1122                 text-align: center;
1123             }
1124             h2 {
1125                 font-size: 1.0em;
1126             }
1127             p {
1128                 font-size: 0.9em;
1129             }
1130             p img {
1131                 float: right;
1132                 margin-left: 10px;
1133             }
1134             span#appname {
1135                 font-weight: bold;
1136                 font-size: 1.6em;
1137             }
1138         </style>
1139     </head>
1140     <body>
1141         <div id="content">
1142             <div id="topbar">
1143                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1144                     $VERSION</h1>
1145              </div>
1146              <div id="answers">
1147                  <p>
1148                  <img src="$logo" alt="Catalyst Logo" />
1149                  </p>
1150                  <p>Welcome to the  world of Catalyst.
1151                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1152                     framework will make web development something you had
1153                     never expected it to be: Fun, rewarding, and quick.</p>
1154                  <h2>What to do now?</h2>
1155                  <p>That really depends  on what <b>you</b> want to do.
1156                     We do, however, provide you with a few starting points.</p>
1157                  <p>If you want to jump right into web development with Catalyst
1158                     you might want to start with a tutorial.</p>
1159 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1160 </pre>
1161 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1162 <pre>
1163 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1164 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1165 </code></pre>
1166                  <h2>What to do next?</h2>
1167                  <p>Next it's time to write an actual application. Use the
1168                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1169                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1170                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1171                     they can save you a lot of work.</p>
1172                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1173                     <p>Also, be sure to check out the vast and growing
1174                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1175                     you are likely to find what you need there.
1176                     </p>
1177
1178                  <h2>Need help?</h2>
1179                  <p>Catalyst has a very active community. Here are the main places to
1180                     get in touch with us.</p>
1181                  <ul>
1182                      <li>
1183                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1184                      </li>
1185                      <li>
1186                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1187                      </li>
1188                      <li>
1189                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1190                      </li>
1191                  </ul>
1192                  <h2>In conclusion</h2>
1193                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1194                     as we enjoyed making it. Please contact us if you have ideas
1195                     for improvement or other feedback.</p>
1196              </div>
1197          </div>
1198     </body>
1199 </html>
1200 EOF
1201 }
1202
1203 =head1 INTERNAL METHODS
1204
1205 These methods are not meant to be used by end users.
1206
1207 =head2 $c->components
1208
1209 Returns a hash of components.
1210
1211 =head2 $c->context_class
1212
1213 Returns or sets the context class.
1214
1215 =head2 $c->counter
1216
1217 Returns a hashref containing coderefs and execution counts (needed for
1218 deep recursion detection).
1219
1220 =head2 $c->depth
1221
1222 Returns the number of actions on the current internal execution stack.
1223
1224 =head2 $c->dispatch
1225
1226 Dispatches a request to actions.
1227
1228 =cut
1229
1230 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1231
1232 =head2 $c->dispatcher_class
1233
1234 Returns or sets the dispatcher class.
1235
1236 =head2 $c->dump_these
1237
1238 Returns a list of 2-element array references (name, structure) pairs
1239 that will be dumped on the error page in debug mode.
1240
1241 =cut
1242
1243 sub dump_these {
1244     my $c = shift;
1245     [ Request => $c->req ],
1246     [ Response => $c->res ],
1247     [ Stash => $c->stash ],
1248     [ Config => $c->config ];
1249 }
1250
1251 =head2 $c->engine_class
1252
1253 Returns or sets the engine class.
1254
1255 =head2 $c->execute( $class, $coderef )
1256
1257 Execute a coderef in given class and catch exceptions. Errors are available
1258 via $c->error.
1259
1260 =cut
1261
1262 sub execute {
1263     my ( $c, $class, $code ) = @_;
1264     $class = $c->component($class) || $class;
1265     $c->state(0);
1266
1267     if ( $c->depth >= $RECURSION ) {
1268         my $action = "$code";
1269         $action = "/$action" unless $action =~ /->/;
1270         my $error = qq/Deep recursion detected calling "$action"/;
1271         $c->log->error($error);
1272         $c->error($error);
1273         $c->state(0);
1274         return $c->state;
1275     }
1276
1277     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1278
1279     push( @{ $c->stack }, $code );
1280
1281     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1282
1283     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1284
1285     my $last = pop( @{ $c->stack } );
1286
1287     if ( my $error = $@ ) {
1288         if ( !ref($error) and $error eq $DETACH ) {
1289             die $DETACH if($c->depth > 1);
1290         }
1291         elsif ( !ref($error) and $error eq $GO ) {
1292             die $GO if($c->depth > 0);
1293         }
1294         else {
1295             unless ( ref $error ) {
1296                 no warnings 'uninitialized';
1297                 chomp $error;
1298                 my $class = $last->class;
1299                 my $name  = $last->name;
1300                 $error = qq/Caught exception in $class->$name "$error"/;
1301             }
1302             $c->error($error);
1303             $c->state(0);
1304         }
1305     }
1306     return $c->state;
1307 }
1308
1309 sub _stats_start_execute {
1310     my ( $c, $code ) = @_;
1311
1312     return if ( ( $code->name =~ /^_.*/ )
1313         && ( !$c->config->{show_internal_actions} ) );
1314
1315     $c->counter->{"$code"}++;
1316
1317     my $action = "$code";
1318     $action = "/$action" unless $action =~ /->/;
1319
1320     # determine if the call was the result of a forward
1321     # this is done by walking up the call stack and looking for a calling
1322     # sub of Catalyst::forward before the eval
1323     my $callsub = q{};
1324     for my $index ( 2 .. 11 ) {
1325         last
1326         if ( ( caller($index) )[0] eq 'Catalyst'
1327             && ( caller($index) )[3] eq '(eval)' );
1328
1329         if ( ( caller($index) )[3] =~ /forward$/ ) {
1330             $callsub = ( caller($index) )[3];
1331             $action  = "-> $action";
1332             last;
1333         }
1334     }
1335
1336     my $uid = "$code" . $c->counter->{"$code"};
1337
1338     # is this a root-level call or a forwarded call?
1339     if ( $callsub =~ /forward$/ ) {
1340
1341         # forward, locate the caller
1342         if ( my $parent = $c->stack->[-1] ) {
1343             $c->stats->profile(
1344                 begin  => $action,
1345                 parent => "$parent" . $c->counter->{"$parent"},
1346                 uid    => $uid,
1347             );
1348         }
1349         else {
1350
1351             # forward with no caller may come from a plugin
1352             $c->stats->profile(
1353                 begin => $action,
1354                 uid   => $uid,
1355             );
1356         }
1357     }
1358     else {
1359
1360         # root-level call
1361         $c->stats->profile(
1362             begin => $action,
1363             uid   => $uid,
1364         );
1365     }
1366     return $action;
1367
1368 }
1369
1370 sub _stats_finish_execute {
1371     my ( $c, $info ) = @_;
1372     $c->stats->profile( end => $info );
1373 }
1374
1375 =head2 $c->_localize_fields( sub { }, \%keys );
1376
1377 =cut
1378
1379 sub _localize_fields {
1380     my ( $c, $localized, $code ) = ( @_ );
1381
1382     my $request = delete $localized->{request} || {};
1383     my $response = delete $localized->{response} || {};
1384
1385     local @{ $c }{ keys %$localized } = values %$localized;
1386     local @{ $c->request }{ keys %$request } = values %$request;
1387     local @{ $c->response }{ keys %$response } = values %$response;
1388
1389     $code->();
1390 }
1391
1392 =head2 $c->finalize
1393
1394 Finalizes the request.
1395
1396 =cut
1397
1398 sub finalize {
1399     my $c = shift;
1400
1401     for my $error ( @{ $c->error } ) {
1402         $c->log->error($error);
1403     }
1404
1405     # Allow engine to handle finalize flow (for POE)
1406     if ( $c->engine->can('finalize') ) {
1407         $c->engine->finalize($c);
1408     }
1409     else {
1410
1411         $c->finalize_uploads;
1412
1413         # Error
1414         if ( $#{ $c->error } >= 0 ) {
1415             $c->finalize_error;
1416         }
1417
1418         $c->finalize_headers;
1419
1420         # HEAD request
1421         if ( $c->request->method eq 'HEAD' ) {
1422             $c->response->body('');
1423         }
1424
1425         $c->finalize_body;
1426     }
1427
1428     if ($c->use_stats) {
1429         my $elapsed = sprintf '%f', $c->stats->elapsed;
1430         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1431         $c->log->info(
1432             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1433     }
1434
1435     return $c->response->status;
1436 }
1437
1438 =head2 $c->finalize_body
1439
1440 Finalizes body.
1441
1442 =cut
1443
1444 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1445
1446 =head2 $c->finalize_cookies
1447
1448 Finalizes cookies.
1449
1450 =cut
1451
1452 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1453
1454 =head2 $c->finalize_error
1455
1456 Finalizes error.
1457
1458 =cut
1459
1460 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1461
1462 =head2 $c->finalize_headers
1463
1464 Finalizes headers.
1465
1466 =cut
1467
1468 sub finalize_headers {
1469     my $c = shift;
1470
1471     # Check if we already finalized headers
1472     return if $c->response->{_finalized_headers};
1473
1474     # Handle redirects
1475     if ( my $location = $c->response->redirect ) {
1476         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1477         $c->response->header( Location => $location );
1478
1479         if ( !$c->response->body ) {
1480             # Add a default body if none is already present
1481             $c->response->body(
1482                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1483             );
1484         }
1485     }
1486
1487     # Content-Length
1488     if ( $c->response->body && !$c->response->content_length ) {
1489
1490         # get the length from a filehandle
1491         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1492         {
1493             my $stat = stat $c->response->body;
1494             if ( $stat && $stat->size > 0 ) {
1495                 $c->response->content_length( $stat->size );
1496             }
1497             else {
1498                 $c->log->warn('Serving filehandle without a content-length');
1499             }
1500         }
1501         else {
1502             # everything should be bytes at this point, but just in case
1503             $c->response->content_length( bytes::length( $c->response->body ) );
1504         }
1505     }
1506
1507     # Errors
1508     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1509         $c->response->headers->remove_header("Content-Length");
1510         $c->response->body('');
1511     }
1512
1513     $c->finalize_cookies;
1514
1515     $c->engine->finalize_headers( $c, @_ );
1516
1517     # Done
1518     $c->response->{_finalized_headers} = 1;
1519 }
1520
1521 =head2 $c->finalize_output
1522
1523 An alias for finalize_body.
1524
1525 =head2 $c->finalize_read
1526
1527 Finalizes the input after reading is complete.
1528
1529 =cut
1530
1531 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1532
1533 =head2 $c->finalize_uploads
1534
1535 Finalizes uploads. Cleans up any temporary files.
1536
1537 =cut
1538
1539 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1540
1541 =head2 $c->get_action( $action, $namespace )
1542
1543 Gets an action in a given namespace.
1544
1545 =cut
1546
1547 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1548
1549 =head2 $c->get_actions( $action, $namespace )
1550
1551 Gets all actions of a given name in a namespace and all parent
1552 namespaces.
1553
1554 =cut
1555
1556 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1557
1558 =head2 $c->handle_request( $class, @arguments )
1559
1560 Called to handle each HTTP request.
1561
1562 =cut
1563
1564 sub handle_request {
1565     my ( $class, @arguments ) = @_;
1566
1567     # Always expect worst case!
1568     my $status = -1;
1569     eval {
1570         if ($class->debug) {
1571             my $secs = time - $START || 1;
1572             my $av = sprintf '%.3f', $COUNT / $secs;
1573             my $time = localtime time;
1574             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1575         }
1576
1577         my $c = $class->prepare(@arguments);
1578         $c->dispatch;
1579         $status = $c->finalize;
1580     };
1581
1582     if ( my $error = $@ ) {
1583         chomp $error;
1584         $class->log->error(qq/Caught exception in engine "$error"/);
1585     }
1586
1587     $COUNT++;
1588     $class->log->_flush() if $class->log->can('_flush');
1589     return $status;
1590 }
1591
1592 =head2 $c->prepare( @arguments )
1593
1594 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1595 etc.).
1596
1597 =cut
1598
1599 sub prepare {
1600     my ( $class, @arguments ) = @_;
1601
1602     $class->context_class( ref $class || $class ) unless $class->context_class;
1603     my $c = $class->context_class->new(
1604         {
1605             counter => {},
1606             stack   => [],
1607             request => $class->request_class->new(
1608                 {
1609                     arguments        => [],
1610                     body_parameters  => {},
1611                     cookies          => {},
1612                     headers          => HTTP::Headers->new,
1613                     parameters       => {},
1614                     query_parameters => {},
1615                     secure           => 0,
1616                     captures         => [],
1617                     uploads          => {}
1618                 }
1619             ),
1620             response => $class->response_class->new(
1621                 {
1622                     body    => '',
1623                     cookies => {},
1624                     headers => HTTP::Headers->new(),
1625                     status  => 200
1626                 }
1627             ),
1628             stash => {},
1629             state => 0
1630         }
1631     );
1632
1633     $c->stats($class->stats_class->new)->enable($c->use_stats);
1634     if ( $c->debug ) {
1635         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1636     }
1637
1638     # For on-demand data
1639     $c->request->{_context}  = $c;
1640     $c->response->{_context} = $c;
1641     weaken( $c->request->{_context} );
1642     weaken( $c->response->{_context} );
1643
1644     # Allow engine to direct the prepare flow (for POE)
1645     if ( $c->engine->can('prepare') ) {
1646         $c->engine->prepare( $c, @arguments );
1647     }
1648     else {
1649         $c->prepare_request(@arguments);
1650         $c->prepare_connection;
1651         $c->prepare_query_parameters;
1652         $c->prepare_headers;
1653         $c->prepare_cookies;
1654         $c->prepare_path;
1655
1656         # Prepare the body for reading, either by prepare_body
1657         # or the user, if they are using $c->read
1658         $c->prepare_read;
1659
1660         # Parse the body unless the user wants it on-demand
1661         unless ( $c->config->{parse_on_demand} ) {
1662             $c->prepare_body;
1663         }
1664     }
1665
1666     my $method  = $c->req->method  || '';
1667     my $path    = $c->req->path;
1668     $path       = '/' unless length $path;
1669     my $address = $c->req->address || '';
1670
1671     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1672       if $c->debug;
1673
1674     $c->prepare_action;
1675
1676     return $c;
1677 }
1678
1679 =head2 $c->prepare_action
1680
1681 Prepares action. See L<Catalyst::Dispatcher>.
1682
1683 =cut
1684
1685 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1686
1687 =head2 $c->prepare_body
1688
1689 Prepares message body.
1690
1691 =cut
1692
1693 sub prepare_body {
1694     my $c = shift;
1695
1696     # Do we run for the first time?
1697     return if defined $c->request->{_body};
1698
1699     # Initialize on-demand data
1700     $c->engine->prepare_body( $c, @_ );
1701     $c->prepare_parameters;
1702     $c->prepare_uploads;
1703
1704     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1705         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1706         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1707             my $param = $c->req->body_parameters->{$key};
1708             my $value = defined($param) ? $param : '';
1709             $t->row( $key,
1710                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1711         }
1712         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1713     }
1714 }
1715
1716 =head2 $c->prepare_body_chunk( $chunk )
1717
1718 Prepares a chunk of data before sending it to L<HTTP::Body>.
1719
1720 See L<Catalyst::Engine>.
1721
1722 =cut
1723
1724 sub prepare_body_chunk {
1725     my $c = shift;
1726     $c->engine->prepare_body_chunk( $c, @_ );
1727 }
1728
1729 =head2 $c->prepare_body_parameters
1730
1731 Prepares body parameters.
1732
1733 =cut
1734
1735 sub prepare_body_parameters {
1736     my $c = shift;
1737     $c->engine->prepare_body_parameters( $c, @_ );
1738 }
1739
1740 =head2 $c->prepare_connection
1741
1742 Prepares connection.
1743
1744 =cut
1745
1746 sub prepare_connection {
1747     my $c = shift;
1748     $c->engine->prepare_connection( $c, @_ );
1749 }
1750
1751 =head2 $c->prepare_cookies
1752
1753 Prepares cookies.
1754
1755 =cut
1756
1757 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1758
1759 =head2 $c->prepare_headers
1760
1761 Prepares headers.
1762
1763 =cut
1764
1765 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1766
1767 =head2 $c->prepare_parameters
1768
1769 Prepares parameters.
1770
1771 =cut
1772
1773 sub prepare_parameters {
1774     my $c = shift;
1775     $c->prepare_body_parameters;
1776     $c->engine->prepare_parameters( $c, @_ );
1777 }
1778
1779 =head2 $c->prepare_path
1780
1781 Prepares path and base.
1782
1783 =cut
1784
1785 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1786
1787 =head2 $c->prepare_query_parameters
1788
1789 Prepares query parameters.
1790
1791 =cut
1792
1793 sub prepare_query_parameters {
1794     my $c = shift;
1795
1796     $c->engine->prepare_query_parameters( $c, @_ );
1797
1798     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1799         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1800         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1801             my $param = $c->req->query_parameters->{$key};
1802             my $value = defined($param) ? $param : '';
1803             $t->row( $key,
1804                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1805         }
1806         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1807     }
1808 }
1809
1810 =head2 $c->prepare_read
1811
1812 Prepares the input for reading.
1813
1814 =cut
1815
1816 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1817
1818 =head2 $c->prepare_request
1819
1820 Prepares the engine request.
1821
1822 =cut
1823
1824 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1825
1826 =head2 $c->prepare_uploads
1827
1828 Prepares uploads.
1829
1830 =cut
1831
1832 sub prepare_uploads {
1833     my $c = shift;
1834
1835     $c->engine->prepare_uploads( $c, @_ );
1836
1837     if ( $c->debug && keys %{ $c->request->uploads } ) {
1838         my $t = Text::SimpleTable->new(
1839             [ 12, 'Parameter' ],
1840             [ 26, 'Filename' ],
1841             [ 18, 'Type' ],
1842             [ 9,  'Size' ]
1843         );
1844         for my $key ( sort keys %{ $c->request->uploads } ) {
1845             my $upload = $c->request->uploads->{$key};
1846             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1847                 $t->row( $key, $u->filename, $u->type, $u->size );
1848             }
1849         }
1850         $c->log->debug( "File Uploads are:\n" . $t->draw );
1851     }
1852 }
1853
1854 =head2 $c->prepare_write
1855
1856 Prepares the output for writing.
1857
1858 =cut
1859
1860 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1861
1862 =head2 $c->request_class
1863
1864 Returns or sets the request class.
1865
1866 =head2 $c->response_class
1867
1868 Returns or sets the response class.
1869
1870 =head2 $c->read( [$maxlength] )
1871
1872 Reads a chunk of data from the request body. This method is designed to
1873 be used in a while loop, reading C<$maxlength> bytes on every call.
1874 C<$maxlength> defaults to the size of the request if not specified.
1875
1876 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1877 directly.
1878
1879 Warning: If you use read(), Catalyst will not process the body,
1880 so you will not be able to access POST parameters or file uploads via
1881 $c->request.  You must handle all body parsing yourself.
1882
1883 =cut
1884
1885 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1886
1887 =head2 $c->run
1888
1889 Starts the engine.
1890
1891 =cut
1892
1893 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1894
1895 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1896
1897 Sets an action in a given namespace.
1898
1899 =cut
1900
1901 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1902
1903 =head2 $c->setup_actions($component)
1904
1905 Sets up actions for a component.
1906
1907 =cut
1908
1909 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1910
1911 =head2 $c->setup_components
1912
1913 Sets up components. Specify a C<setup_components> config option to pass
1914 additional options directly to L<Module::Pluggable>. To add additional
1915 search paths, specify a key named C<search_extra> as an array
1916 reference. Items in the array beginning with C<::> will have the
1917 application class name prepended to them.
1918
1919 All components found will also have any
1920 L<Devel::InnerPackage|inner packages> loaded and set up as components.
1921 Note, that modules which are B<not> an I<inner package> of the main
1922 file namespace loaded will not be instantiated as components.
1923
1924 =cut
1925
1926 sub setup_components {
1927     my $class = shift;
1928
1929     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1930     my $config  = $class->config->{ setup_components };
1931     my $extra   = delete $config->{ search_extra } || [];
1932
1933     push @paths, @$extra;
1934
1935     my $locator = Module::Pluggable::Object->new(
1936         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1937         %$config
1938     );
1939
1940     my @comps = sort { length $a <=> length $b } $locator->plugins;
1941     my %comps = map { $_ => 1 } @comps;
1942
1943     for my $component ( @comps ) {
1944
1945         # We pass ignore_loaded here so that overlay files for (e.g.)
1946         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
1947         # we know M::P::O found a file on disk so this is safe
1948
1949         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1950
1951         my $module  = $class->setup_component( $component );
1952         my %modules = (
1953             $component => $module,
1954             map {
1955                 $_ => $class->setup_component( $_ )
1956             } grep {
1957               not exists $comps{$_}
1958             } Devel::InnerPackage::list_packages( $component )
1959         );
1960
1961         for my $key ( keys %modules ) {
1962             $class->components->{ $key } = $modules{ $key };
1963         }
1964     }
1965 }
1966
1967 =head2 $c->setup_component
1968
1969 =cut
1970
1971 sub setup_component {
1972     my( $class, $component ) = @_;
1973
1974     unless ( $component->can( 'COMPONENT' ) ) {
1975         return $component;
1976     }
1977
1978     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1979     my $config = $class->config->{ $suffix } || {};
1980
1981     my $instance = eval { $component->COMPONENT( $class, $config ); };
1982
1983     if ( my $error = $@ ) {
1984         chomp $error;
1985         Catalyst::Exception->throw(
1986             message => qq/Couldn't instantiate component "$component", "$error"/
1987         );
1988     }
1989
1990     Catalyst::Exception->throw(
1991         message =>
1992         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1993     ) unless eval { $instance->can( 'can' ) };
1994
1995     return $instance;
1996 }
1997
1998 =head2 $c->setup_dispatcher
1999
2000 Sets up dispatcher.
2001
2002 =cut
2003
2004 sub setup_dispatcher {
2005     my ( $class, $dispatcher ) = @_;
2006
2007     if ($dispatcher) {
2008         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2009     }
2010
2011     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2012         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2013     }
2014
2015     unless ($dispatcher) {
2016         $dispatcher = $class->dispatcher_class;
2017     }
2018
2019     unless (Class::Inspector->loaded($dispatcher)) {
2020         require Class::Inspector->filename($dispatcher);
2021     }
2022
2023     # dispatcher instance
2024     $class->dispatcher( $dispatcher->new );
2025 }
2026
2027 =head2 $c->setup_engine
2028
2029 Sets up engine.
2030
2031 =cut
2032
2033 sub setup_engine {
2034     my ( $class, $engine ) = @_;
2035
2036     if ($engine) {
2037         $engine = 'Catalyst::Engine::' . $engine;
2038     }
2039
2040     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2041         $engine = 'Catalyst::Engine::' . $env;
2042     }
2043
2044     if ( $ENV{MOD_PERL} ) {
2045
2046         # create the apache method
2047         {
2048             no strict 'refs';
2049             *{"$class\::apache"} = sub { shift->engine->apache };
2050         }
2051
2052         my ( $software, $version ) =
2053           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2054
2055         $version =~ s/_//g;
2056         $version =~ s/(\.[^.]+)\./$1/g;
2057
2058         if ( $software eq 'mod_perl' ) {
2059
2060             if ( !$engine ) {
2061
2062                 if ( $version >= 1.99922 ) {
2063                     $engine = 'Catalyst::Engine::Apache2::MP20';
2064                 }
2065
2066                 elsif ( $version >= 1.9901 ) {
2067                     $engine = 'Catalyst::Engine::Apache2::MP19';
2068                 }
2069
2070                 elsif ( $version >= 1.24 ) {
2071                     $engine = 'Catalyst::Engine::Apache::MP13';
2072                 }
2073
2074                 else {
2075                     Catalyst::Exception->throw( message =>
2076                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2077                 }
2078
2079             }
2080
2081             # install the correct mod_perl handler
2082             if ( $version >= 1.9901 ) {
2083                 *handler = sub  : method {
2084                     shift->handle_request(@_);
2085                 };
2086             }
2087             else {
2088                 *handler = sub ($$) { shift->handle_request(@_) };
2089             }
2090
2091         }
2092
2093         elsif ( $software eq 'Zeus-Perl' ) {
2094             $engine = 'Catalyst::Engine::Zeus';
2095         }
2096
2097         else {
2098             Catalyst::Exception->throw(
2099                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2100         }
2101     }
2102
2103     unless ($engine) {
2104         $engine = $class->engine_class;
2105     }
2106
2107     unless (Class::Inspector->loaded($engine)) {
2108         require Class::Inspector->filename($engine);
2109     }
2110
2111     # check for old engines that are no longer compatible
2112     my $old_engine;
2113     if ( $engine->isa('Catalyst::Engine::Apache')
2114         && !Catalyst::Engine::Apache->VERSION )
2115     {
2116         $old_engine = 1;
2117     }
2118
2119     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2120         && Catalyst::Engine::Server->VERSION le '0.02' )
2121     {
2122         $old_engine = 1;
2123     }
2124
2125     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2126         && $engine->VERSION eq '0.01' )
2127     {
2128         $old_engine = 1;
2129     }
2130
2131     elsif ($engine->isa('Catalyst::Engine::Zeus')
2132         && $engine->VERSION eq '0.01' )
2133     {
2134         $old_engine = 1;
2135     }
2136
2137     if ($old_engine) {
2138         Catalyst::Exception->throw( message =>
2139               qq/Engine "$engine" is not supported by this version of Catalyst/
2140         );
2141     }
2142
2143     # engine instance
2144     $class->engine( $engine->new );
2145 }
2146
2147 =head2 $c->setup_home
2148
2149 Sets up the home directory.
2150
2151 =cut
2152
2153 sub setup_home {
2154     my ( $class, $home ) = @_;
2155
2156     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2157         $home = $env;
2158     }
2159
2160     unless ($home) {
2161         $home = Catalyst::Utils::home($class);
2162     }
2163
2164     if ($home) {
2165         $class->config->{home} ||= $home;
2166         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2167     }
2168 }
2169
2170 =head2 $c->setup_log
2171
2172 Sets up log.
2173
2174 =cut
2175
2176 sub setup_log {
2177     my ( $class, $debug ) = @_;
2178
2179     unless ( $class->log ) {
2180         $class->log( Catalyst::Log->new );
2181     }
2182
2183     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2184     if ( defined($env_debug) ? $env_debug : $debug ) {
2185         no strict 'refs';
2186         *{"$class\::debug"} = sub { 1 };
2187         $class->log->debug('Debug messages enabled');
2188     }
2189 }
2190
2191 =head2 $c->setup_plugins
2192
2193 Sets up plugins.
2194
2195 =cut
2196
2197 =head2 $c->setup_stats
2198
2199 Sets up timing statistics class.
2200
2201 =cut
2202
2203 sub setup_stats {
2204     my ( $class, $stats ) = @_;
2205
2206     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2207
2208     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2209     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2210         no strict 'refs';
2211         *{"$class\::use_stats"} = sub { 1 };
2212         $class->log->debug('Statistics enabled');
2213     }
2214 }
2215
2216
2217 =head2 $c->registered_plugins
2218
2219 Returns a sorted list of the plugins which have either been stated in the
2220 import list or which have been added via C<< MyApp->plugin(@args); >>.
2221
2222 If passed a given plugin name, it will report a boolean value indicating
2223 whether or not that plugin is loaded.  A fully qualified name is required if
2224 the plugin name does not begin with C<Catalyst::Plugin::>.
2225
2226  if ($c->registered_plugins('Some::Plugin')) {
2227      ...
2228  }
2229
2230 =cut
2231
2232 {
2233
2234     sub registered_plugins {
2235         my $proto = shift;
2236         return sort keys %{ $proto->_plugins } unless @_;
2237         my $plugin = shift;
2238         return 1 if exists $proto->_plugins->{$plugin};
2239         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2240     }
2241
2242     sub _register_plugin {
2243         my ( $proto, $plugin, $instant ) = @_;
2244         my $class = ref $proto || $proto;
2245
2246         # no ignore_loaded here, the plugin may already have been
2247         # defined in memory and we don't want to error on "no file" if so
2248
2249         Catalyst::Utils::ensure_class_loaded( $plugin );
2250
2251         $proto->_plugins->{$plugin} = 1;
2252         unless ($instant) {
2253             no strict 'refs';
2254             unshift @{"$class\::ISA"}, $plugin;
2255         }
2256         return $class;
2257     }
2258
2259     sub setup_plugins {
2260         my ( $class, $plugins ) = @_;
2261
2262         $class->_plugins( {} ) unless $class->_plugins;
2263         $plugins ||= [];
2264         for my $plugin ( reverse @$plugins ) {
2265
2266             unless ( $plugin =~ s/\A\+// ) {
2267                 $plugin = "Catalyst::Plugin::$plugin";
2268             }
2269
2270             $class->_register_plugin($plugin);
2271         }
2272     }
2273 }
2274
2275 =head2 $c->stack
2276
2277 Returns an arrayref of the internal execution stack (actions that are
2278 currently executing).
2279
2280 =head2 $c->stats_class
2281
2282 Returns or sets the stats (timing statistics) class.
2283
2284 =head2 $c->use_stats
2285
2286 Returns 1 when stats collection is enabled.  Stats collection is enabled
2287 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2288 environment variable is set.
2289
2290 Note that this is a static method, not an accessor and should be overloaded
2291 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2292
2293 =cut
2294
2295 sub use_stats { 0 }
2296
2297
2298 =head2 $c->write( $data )
2299
2300 Writes $data to the output stream. When using this method directly, you
2301 will need to manually set the C<Content-Length> header to the length of
2302 your output data, if known.
2303
2304 =cut
2305
2306 sub write {
2307     my $c = shift;
2308
2309     # Finalize headers if someone manually writes output
2310     $c->finalize_headers;
2311
2312     return $c->engine->write( $c, @_ );
2313 }
2314
2315 =head2 version
2316
2317 Returns the Catalyst version number. Mostly useful for "powered by"
2318 messages in template systems.
2319
2320 =cut
2321
2322 sub version { return $Catalyst::VERSION }
2323
2324 =head1 INTERNAL ACTIONS
2325
2326 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2327 C<_ACTION>, and C<_END>. These are by default not shown in the private
2328 action table, but you can make them visible with a config parameter.
2329
2330     MyApp->config->{show_internal_actions} = 1;
2331
2332 =head1 CASE SENSITIVITY
2333
2334 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2335 mapped to C</foo/bar>. You can activate case sensitivity with a config
2336 parameter.
2337
2338     MyApp->config->{case_sensitive} = 1;
2339
2340 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2341
2342 =head1 ON-DEMAND PARSER
2343
2344 The request body is usually parsed at the beginning of a request,
2345 but if you want to handle input yourself, you can enable on-demand
2346 parsing with a config parameter.
2347
2348     MyApp->config->{parse_on_demand} = 1;
2349
2350 =head1 PROXY SUPPORT
2351
2352 Many production servers operate using the common double-server approach,
2353 with a lightweight frontend web server passing requests to a larger
2354 backend server. An application running on the backend server must deal
2355 with two problems: the remote user always appears to be C<127.0.0.1> and
2356 the server's hostname will appear to be C<localhost> regardless of the
2357 virtual host that the user connected through.
2358
2359 Catalyst will automatically detect this situation when you are running
2360 the frontend and backend servers on the same machine. The following
2361 changes are made to the request.
2362
2363     $c->req->address is set to the user's real IP address, as read from
2364     the HTTP X-Forwarded-For header.
2365
2366     The host value for $c->req->base and $c->req->uri is set to the real
2367     host, as read from the HTTP X-Forwarded-Host header.
2368
2369 Obviously, your web server must support these headers for this to work.
2370
2371 In a more complex server farm environment where you may have your
2372 frontend proxy server(s) on different machines, you will need to set a
2373 configuration option to tell Catalyst to read the proxied data from the
2374 headers.
2375
2376     MyApp->config->{using_frontend_proxy} = 1;
2377
2378 If you do not wish to use the proxy support at all, you may set:
2379
2380     MyApp->config->{ignore_frontend_proxy} = 1;
2381
2382 =head1 THREAD SAFETY
2383
2384 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2385 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2386 believe the Catalyst core to be thread-safe.
2387
2388 If you plan to operate in a threaded environment, remember that all other
2389 modules you are using must also be thread-safe. Some modules, most notably
2390 L<DBD::SQLite>, are not thread-safe.
2391
2392 =head1 SUPPORT
2393
2394 IRC:
2395
2396     Join #catalyst on irc.perl.org.
2397
2398 Mailing Lists:
2399
2400     http://lists.rawmode.org/mailman/listinfo/catalyst
2401     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2402
2403 Web:
2404
2405     http://catalyst.perl.org
2406
2407 Wiki:
2408
2409     http://dev.catalyst.perl.org
2410
2411 =head1 SEE ALSO
2412
2413 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2414
2415 =head2 L<Catalyst::Manual> - The Catalyst Manual
2416
2417 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2418
2419 =head2 L<Catalyst::Engine> - Core engine
2420
2421 =head2 L<Catalyst::Log> - Log class.
2422
2423 =head2 L<Catalyst::Request> - Request object
2424
2425 =head2 L<Catalyst::Response> - Response object
2426
2427 =head2 L<Catalyst::Test> - The test suite.
2428
2429 =head1 PROJECT FOUNDER
2430
2431 sri: Sebastian Riedel <sri@cpan.org>
2432
2433 =head1 CONTRIBUTORS
2434
2435 abw: Andy Wardley
2436
2437 acme: Leon Brocard <leon@astray.com>
2438
2439 Andrew Bramble
2440
2441 Andrew Ford
2442
2443 Andrew Ruthven
2444
2445 andyg: Andy Grundman <andy@hybridized.org>
2446
2447 audreyt: Audrey Tang
2448
2449 bricas: Brian Cassidy <bricas@cpan.org>
2450
2451 chansen: Christian Hansen
2452
2453 chicks: Christopher Hicks
2454
2455 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2456
2457 Drew Taylor
2458
2459 esskar: Sascha Kiefer
2460
2461 fireartist: Carl Franks <cfranks@cpan.org>
2462
2463 gabb: Danijel Milicevic
2464
2465 Gary Ashton Jones
2466
2467 Geoff Richards
2468
2469 jcamacho: Juan Camacho
2470
2471 Jody Belka
2472
2473 Johan Lindstrom
2474
2475 jon: Jon Schutz <jjschutz@cpan.org>
2476
2477 marcus: Marcus Ramberg <mramberg@cpan.org>
2478
2479 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2480
2481 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2482
2483 mugwump: Sam Vilain
2484
2485 naughton: David Naughton
2486
2487 ningu: David Kamholz <dkamholz@cpan.org>
2488
2489 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2490
2491 numa: Dan Sully <daniel@cpan.org>
2492
2493 obra: Jesse Vincent
2494
2495 omega: Andreas Marienborg
2496
2497 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2498
2499 sky: Arthur Bergman
2500
2501 the_jester: Jesse Sheidlower
2502
2503 Ulf Edvinsson
2504
2505 willert: Sebastian Willert <willert@cpan.org>
2506
2507 =head1 LICENSE
2508
2509 This library is free software, you can redistribute it and/or modify it under
2510 the same terms as Perl itself.
2511
2512 =cut
2513
2514 1;