lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use Moose::Util qw/find_meta/;
   6 use bytes;
   7 use Scope::Upper ();
   8 use Catalyst::Exception;
   9 use Catalyst::Log;
  10 use Catalyst::Request;
  11 use Catalyst::Request::Upload;
  12 use Catalyst::Response;
  13 use Catalyst::Utils;
  14 use Catalyst::Controller;
  15 use Devel::InnerPackage ();
  16 use File::stat;
  17 use Module::Pluggable::Object ();
  18 use Text::SimpleTable ();
  19 use Path::Class::Dir ();
  20 use Path::Class::File ();
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Tree::Simple qw/use_weak_refs/;
  25 use Tree::Simple::Visitor::FindByUID;
  26 use Class::C3::Adopt::NEXT;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp shortmess/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 has stack => (is => 'ro', default => sub { [] });
  34 has stash => (is => 'rw', default => sub { {} });
  35 has state => (is => 'rw', default => 0);
  36 has stats => (is => 'rw');
  37 has action => (is => 'rw');
  38 has counter => (is => 'rw', default => sub { {} });
  39 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  40 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  41 has namespace => (is => 'rw');
  42
  43 sub depth { scalar @{ shift->stack || [] }; }
  44 sub comp { shift->component(@_) }
  45
  46 sub req {
  47     my $self = shift; return $self->request(@_);
  48 }
  49 sub res {
  50     my $self = shift; return $self->response(@_);
  51 }
  52
  53 # For backwards compatibility
  54 sub finalize_output { shift->finalize_body(@_) };
  55
  56 # For statistics
  57 our $COUNT     = 1;
  58 our $START     = time;
  59 our $RECURSION = 1000;
  60 our $DETACH    = "catalyst_detach\n";
  61 our $GO        = "catalyst_go\n";
  62
  63 #I imagine that very few of these really need to be class variables. if any.
  64 #maybe we should just make them attributes with a default?
  65 __PACKAGE__->mk_classdata($_)
  66   for qw/components arguments dispatcher engine log dispatcher_class
  67   engine_class context_class request_class response_class stats_class
  68   setup_finished/;
  69
  70 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  71 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  72 __PACKAGE__->request_class('Catalyst::Request');
  73 __PACKAGE__->response_class('Catalyst::Response');
  74 __PACKAGE__->stats_class('Catalyst::Stats');
  75
  76 # Remember to update this in Catalyst::Runtime as well!
  77
  78 our $VERSION = '5.80002';
  79
  80 {
  81     my $dev_version = $VERSION =~ /_\d{2}$/;
  82     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  83 }
  84
  85 $VERSION = eval $VERSION;
  86
  87 sub import {
  88     my ( $class, @arguments ) = @_;
  89
  90     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  91     # callers @ISA.
  92     return unless $class eq 'Catalyst';
  93
  94     my $caller = caller();
  95     return if $caller eq 'main';
  96
  97     # Kill Adopt::NEXT warnings if we're a non-RC version
  98     unless (_IS_DEVELOPMENT_VERSION()) {
  99         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 100     }
 101
 102     my $meta = Moose::Meta::Class->initialize($caller);
 103     #Moose->import({ into => $caller }); #do we want to do this?
 104
 105     unless ( $caller->isa('Catalyst') ) {
 106         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 107         $meta->superclasses(@superclasses);
 108     }
 109     unless( $meta->has_method('meta') ){
 110         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 111     }
 112
 113     $caller->arguments( [@arguments] );
 114     $caller->setup_home;
 115 }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 =head2 -Engine
 252
 253 Forces Catalyst to use a specific engine. Omit the
 254 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 255
 256     use Catalyst qw/-Engine=CGI/;
 257
 258 =head2 -Home
 259
 260 Forces Catalyst to use a specific home directory, e.g.:
 261
 262     use Catalyst qw[-Home=/usr/mst];
 263
 264 This can also be done in the shell environment by setting either the
 265 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 266 is replaced with the uppercased name of your application, any "::" in
 267 the name will be replaced with underscores, e.g. MyApp::Web should use
 268 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 269
 270 =head2 -Log
 271
 272     use Catalyst '-Log=warn,fatal,error';
 273
 274 Specifies a comma-delimited list of log levels.
 275
 276 =head2 -Stats
 277
 278 Enables statistics collection and reporting. You can also force this setting
 279 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 280 environment settings override the application, with <MYAPP>_STATS having the
 281 highest priority.
 282
 283 e.g.
 284
 285    use Catalyst qw/-Stats=1/
 286
 287 =head1 METHODS
 288
 289 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 290
 291 =head2 $c->action
 292
 293 Returns a L<Catalyst::Action> object for the current action, which
 294 stringifies to the action name. See L<Catalyst::Action>.
 295
 296 =head2 $c->namespace
 297
 298 Returns the namespace of the current action, i.e., the URI prefix
 299 corresponding to the controller of the current action. For example:
 300
 301     # in Controller::Foo::Bar
 302     $c->namespace; # returns 'foo/bar';
 303
 304 =head2 $c->request
 305
 306 =head2 $c->req
 307
 308 Returns the current L<Catalyst::Request> object, giving access to
 309 information about the current client request (including parameters,
 310 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 311
 312 =head2 REQUEST FLOW HANDLING
 313
 314 =head2 $c->forward( $action [, \@arguments ] )
 315
 316 =head2 $c->forward( $class, $method, [, \@arguments ] )
 317
 318 Forwards processing to another action, by its private name. If you give a
 319 class name but no method, C<process()> is called. You may also optionally
 320 pass arguments in an arrayref. The action will receive the arguments in
 321 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 322 C<< $c->req->args >> will be restored to the previous values.
 323
 324 Any data C<return>ed from the action forwarded to, will be returned by the
 325 call to forward.
 326
 327     my $foodata = $c->forward('/foo');
 328     $c->forward('index');
 329     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 330     $c->forward('MyApp::View::TT');
 331
 332 Note that forward implies an C<<eval { }>> around the call (actually
 333 C<execute> does), thus de-fatalizing all 'dies' within the called
 334 action. If you want C<die> to propagate you need to do something like:
 335
 336     $c->forward('foo');
 337     die $c->error if $c->error;
 338
 339 Or make sure to always return true values from your actions and write
 340 your code like this:
 341
 342     $c->forward('foo') || return;
 343
 344 =cut
 345
 346 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 347
 348 =head2 $c->detach( $action [, \@arguments ] )
 349
 350 =head2 $c->detach( $class, $method, [, \@arguments ] )
 351
 352 =head2 $c->detach()
 353
 354 The same as C<forward>, but doesn't return to the previous action when
 355 processing is finished.
 356
 357 When called with no arguments it escapes the processing chain entirely.
 358
 359 =cut
 360
 361 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 362
 363 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 364
 365 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 366
 367 Almost the same as C<forward>, but does a full dispatch, instead of just
 368 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 369 C<auto> and the method you go to are called, just like a new request.
 370
 371 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 372 This means, for example, that $c->action methods such as C<name>, C<class> and
 373 C<reverse> return information for the visited action when they are invoked
 374 within the visited action.  This is different from the behavior of C<forward>
 375 which continues to use the $c->action object from the caller action even when
 376 invoked from the callee.
 377
 378 C<$c-E<gt>stash> is kept unchanged.
 379
 380 In effect, C<visit> allows you to "wrap" another action, just as it
 381 would have been called by dispatching from a URL, while the analogous
 382 C<go> allows you to transfer control to another action as if it had
 383 been reached directly from a URL.
 384
 385 =cut
 386
 387 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 388
 389 =head2 $c->go( $action [, \@captures, \@arguments ] )
 390
 391 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 392
 393 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 394 instead of just calling the new C<$action> /
 395 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 396 method you visit are called, just like a new request.
 397
 398 C<$c-E<gt>stash> is kept unchanged.
 399
 400 =cut
 401
 402 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 403
 404 =head2 $c->response
 405
 406 =head2 $c->res
 407
 408 Returns the current L<Catalyst::Response> object, see there for details.
 409
 410 =head2 $c->stash
 411
 412 Returns a hashref to the stash, which may be used to store data and pass
 413 it between components during a request. You can also set hash keys by
 414 passing arguments. The stash is automatically sent to the view. The
 415 stash is cleared at the end of a request; it cannot be used for
 416 persistent storage (for this you must use a session; see
 417 L<Catalyst::Plugin::Session> for a complete system integrated with
 418 Catalyst).
 419
 420     $c->stash->{foo} = $bar;
 421     $c->stash( { moose => 'majestic', qux => 0 } );
 422     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 423
 424     # stash is automatically passed to the view for use in a template
 425     $c->forward( 'MyApp::View::TT' );
 426
 427 =cut
 428
 429 around stash => sub {
 430     my $orig = shift;
 431     my $c = shift;
 432     my $stash = $orig->($c);
 433     if (@_) {
 434         my $new_stash = @_ > 1 ? {@_} : $_[0];
 435         croak('stash takes a hash or hashref') unless ref $new_stash;
 436         foreach my $key ( keys %$new_stash ) {
 437           $stash->{$key} = $new_stash->{$key};
 438         }
 439     }
 440
 441     return $stash;
 442 };
 443
 444
 445 =head2 $c->error
 446
 447 =head2 $c->error($error, ...)
 448
 449 =head2 $c->error($arrayref)
 450
 451 Returns an arrayref containing error messages.  If Catalyst encounters an
 452 error while processing a request, it stores the error in $c->error.  This
 453 method should only be used to store fatal error messages.
 454
 455     my @error = @{ $c->error };
 456
 457 Add a new error.
 458
 459     $c->error('Something bad happened');
 460
 461 =cut
 462
 463 sub error {
 464     my $c = shift;
 465     if ( $_[0] ) {
 466         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 467         croak @$error unless ref $c;
 468         push @{ $c->{error} }, @$error;
 469     }
 470     elsif ( defined $_[0] ) { $c->{error} = undef }
 471     return $c->{error} || [];
 472 }
 473
 474
 475 =head2 $c->state
 476
 477 Contains the return value of the last executed action.
 478
 479 =head2 $c->clear_errors
 480
 481 Clear errors.  You probably don't want to clear the errors unless you are
 482 implementing a custom error screen.
 483
 484 This is equivalent to running
 485
 486     $c->error(0);
 487
 488 =cut
 489
 490 sub clear_errors {
 491     my $c = shift;
 492     $c->error(0);
 493 }
 494
 495 # search components given a name and some prefixes
 496 sub _comp_search_prefixes {
 497     my ( $c, $name, @prefixes ) = @_;
 498     my $appclass = ref $c || $c;
 499     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 500     $filter = qr/$filter/; # Compile regex now rather than once per loop
 501
 502     # map the original component name to the sub part that we will search against
 503     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 504         grep { /$filter/ } keys %{ $c->components };
 505
 506     # undef for a name will return all
 507     return keys %eligible if !defined $name;
 508
 509     my $query  = ref $name ? $name : qr/^$name$/i;
 510     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 511
 512     return map { $c->components->{ $_ } } @result if @result;
 513
 514     # if we were given a regexp to search against, we're done.
 515     return if ref $name;
 516
 517     # regexp fallback
 518     $query  = qr/$name/i;
 519     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 520
 521     # no results? try against full names
 522     if( !@result ) {
 523         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 524     }
 525
 526     # don't warn if we didn't find any results, it just might not exist
 527     if( @result ) {
 528         # Disgusting hack to work out correct method name
 529         my $warn_for = lc $prefixes[0];
 530         my $msg = "Used regexp fallback for \$c->{$warn_for}('${name}'), which found '" .
 531            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 532            "component resolution is unreliable and unsafe.";
 533         my $short = $result[0];
 534         $short =~ s/.*?Model:://;
 535         my $shortmess = Carp::shortmess('');
 536         if ($shortmess =~ m#Catalyst/Plugin#) {
 537            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 538               "plugin's config";
 539         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 540            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 541               "component's config";
 542         } else {
 543            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 544               "but if you really wanted to search, pass in a regexp as the argument " .
 545               "like so: \$c->${warn_for}(qr/${name}/)";
 546         }
 547         $c->log->warn( "${msg}$shortmess" );
 548     }
 549
 550     return @result;
 551 }
 552
 553 # Find possible names for a prefix
 554 sub _comp_names {
 555     my ( $c, @prefixes ) = @_;
 556     my $appclass = ref $c || $c;
 557
 558     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 559
 560     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 561     return @names;
 562 }
 563
 564 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 565 sub _filter_component {
 566     my ( $c, $comp, @args ) = @_;
 567
 568     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 569         return $comp->ACCEPT_CONTEXT( $c, @args );
 570     }
 571
 572     return $comp;
 573 }
 574
 575 =head2 COMPONENT ACCESSORS
 576
 577 =head2 $c->controller($name)
 578
 579 Gets a L<Catalyst::Controller> instance by name.
 580
 581     $c->controller('Foo')->do_stuff;
 582
 583 If the name is omitted, will return the controller for the dispatched
 584 action.
 585
 586 If you want to search for controllers, pass in a regexp as the argument.
 587
 588     # find all controllers that start with Foo
 589     my @foo_controllers = $c->controller(qr{^Foo});
 590
 591
 592 =cut
 593
 594 sub controller {
 595     my ( $c, $name, @args ) = @_;
 596
 597     if( $name ) {
 598         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 599         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 600         return $c->_filter_component( $result[ 0 ], @args );
 601     }
 602
 603     return $c->component( $c->action->class );
 604 }
 605
 606 =head2 $c->model($name)
 607
 608 Gets a L<Catalyst::Model> instance by name.
 609
 610     $c->model('Foo')->do_stuff;
 611
 612 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 613
 614 If the name is omitted, it will look for
 615  - a model object in $c->stash->{current_model_instance}, then
 616  - a model name in $c->stash->{current_model}, then
 617  - a config setting 'default_model', or
 618  - check if there is only one model, and return it if that's the case.
 619
 620 If you want to search for models, pass in a regexp as the argument.
 621
 622     # find all models that start with Foo
 623     my @foo_models = $c->model(qr{^Foo});
 624
 625 =cut
 626
 627 sub model {
 628     my ( $c, $name, @args ) = @_;
 629
 630     if( $name ) {
 631         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 632         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 633         return $c->_filter_component( $result[ 0 ], @args );
 634     }
 635
 636     if (ref $c) {
 637         return $c->stash->{current_model_instance}
 638           if $c->stash->{current_model_instance};
 639         return $c->model( $c->stash->{current_model} )
 640           if $c->stash->{current_model};
 641     }
 642     return $c->model( $c->config->{default_model} )
 643       if $c->config->{default_model};
 644
 645     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 646
 647     if( $rest ) {
 648         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 649         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 650         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 651         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 652         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 653     }
 654
 655     return $c->_filter_component( $comp );
 656 }
 657
 658
 659 =head2 $c->view($name)
 660
 661 Gets a L<Catalyst::View> instance by name.
 662
 663     $c->view('Foo')->do_stuff;
 664
 665 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 666
 667 If the name is omitted, it will look for
 668  - a view object in $c->stash->{current_view_instance}, then
 669  - a view name in $c->stash->{current_view}, then
 670  - a config setting 'default_view', or
 671  - check if there is only one view, and return it if that's the case.
 672
 673 If you want to search for views, pass in a regexp as the argument.
 674
 675     # find all views that start with Foo
 676     my @foo_views = $c->view(qr{^Foo});
 677
 678 =cut
 679
 680 sub view {
 681     my ( $c, $name, @args ) = @_;
 682
 683     if( $name ) {
 684         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 685         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 686         return $c->_filter_component( $result[ 0 ], @args );
 687     }
 688
 689     if (ref $c) {
 690         return $c->stash->{current_view_instance}
 691           if $c->stash->{current_view_instance};
 692         return $c->view( $c->stash->{current_view} )
 693           if $c->stash->{current_view};
 694     }
 695     return $c->view( $c->config->{default_view} )
 696       if $c->config->{default_view};
 697
 698     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 699
 700     if( $rest ) {
 701         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 702         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 703         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 704         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 705         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 706     }
 707
 708     return $c->_filter_component( $comp );
 709 }
 710
 711 =head2 $c->controllers
 712
 713 Returns the available names which can be passed to $c->controller
 714
 715 =cut
 716
 717 sub controllers {
 718     my ( $c ) = @_;
 719     return $c->_comp_names(qw/Controller C/);
 720 }
 721
 722 =head2 $c->models
 723
 724 Returns the available names which can be passed to $c->model
 725
 726 =cut
 727
 728 sub models {
 729     my ( $c ) = @_;
 730     return $c->_comp_names(qw/Model M/);
 731 }
 732
 733
 734 =head2 $c->views
 735
 736 Returns the available names which can be passed to $c->view
 737
 738 =cut
 739
 740 sub views {
 741     my ( $c ) = @_;
 742     return $c->_comp_names(qw/View V/);
 743 }
 744
 745 =head2 $c->comp($name)
 746
 747 =head2 $c->component($name)
 748
 749 Gets a component object by name. This method is not recommended,
 750 unless you want to get a specific component by full
 751 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 752 should be used instead.
 753
 754 If C<$name> is a regexp, a list of components matched against the full
 755 component name will be returned.
 756
 757 =cut
 758
 759 sub component {
 760     my ( $c, $name, @args ) = @_;
 761
 762     if( $name ) {
 763         my $comps = $c->components;
 764
 765         if( !ref $name ) {
 766             # is it the exact name?
 767             return $c->_filter_component( $comps->{ $name }, @args )
 768                        if exists $comps->{ $name };
 769
 770             # perhaps we just omitted "MyApp"?
 771             my $composed = ( ref $c || $c ) . "::${name}";
 772             return $c->_filter_component( $comps->{ $composed }, @args )
 773                        if exists $comps->{ $composed };
 774
 775             # search all of the models, views and controllers
 776             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 777             return $c->_filter_component( $comp, @args ) if $comp;
 778         }
 779
 780         # This is here so $c->comp( '::M::' ) works
 781         my $query = ref $name ? $name : qr{$name}i;
 782
 783         my @result = grep { m{$query} } keys %{ $c->components };
 784         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 785
 786         if( $result[ 0 ] ) {
 787             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 788             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 789             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 790             return $c->_filter_component( $result[ 0 ], @args );
 791         }
 792
 793         # I would expect to return an empty list here, but that breaks back-compat
 794     }
 795
 796     # fallback
 797     return sort keys %{ $c->components };
 798 }
 799
 800 =head2 CLASS DATA AND HELPER CLASSES
 801
 802 =head2 $c->config
 803
 804 Returns or takes a hashref containing the application's configuration.
 805
 806     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 807
 808 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 809 like myapp.conf in your applications home directory. See
 810 L<Catalyst::Plugin::ConfigLoader>.
 811
 812 =head3 Cascading configuration.
 813
 814 The config method is present on all Catalyst components, and configuration
 815 will be merged when an application is started. Configuration loaded with
 816 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 817 followed by configuration in your top level C<MyApp> class. These two
 818 configurations are merged, and then configuration data whos hash key matches a
 819 component name is merged with configuration for that component.
 820
 821 The configuration for a component is then passed to the C<new> method when a
 822 component is constructed.
 823
 824 For example:
 825
 826     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 827     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 828
 829 will mean that C<MyApp::Model::Foo> receives the following data when
 830 constructed:
 831
 832     MyApp::Model::Foo->new({
 833         bar => 'baz',
 834         quux => 'frob',
 835         overrides => 'me',
 836     });
 837
 838 =cut
 839
 840 around config => sub {
 841     my $orig = shift;
 842     my $c = shift;
 843
 844     croak('Setting config after setup has been run is not allowed.')
 845         if ( @_ and $c->setup_finished );
 846
 847     $c->$orig(@_);
 848 };
 849
 850 =head2 $c->log
 851
 852 Returns the logging object instance. Unless it is already set, Catalyst
 853 sets this up with a L<Catalyst::Log> object. To use your own log class,
 854 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 855 C<< __PACKAGE__->setup >>.
 856
 857  __PACKAGE__->log( MyLogger->new );
 858  __PACKAGE__->setup;
 859
 860 And later:
 861
 862     $c->log->info( 'Now logging with my own logger!' );
 863
 864 Your log class should implement the methods described in
 865 L<Catalyst::Log>.
 866
 867
 868 =head2 $c->debug
 869
 870 Returns 1 if debug mode is enabled, 0 otherwise.
 871
 872 You can enable debug mode in several ways:
 873
 874 =over
 875
 876 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 877
 878 =item The -Debug option in your MyApp.pm
 879
 880 =item By declaring "sub debug { 1 }" in your MyApp.pm.
 881
 882 =back
 883
 884 Calling $c->debug(1) has no effect.
 885
 886 =cut
 887
 888 sub debug { 0 }
 889
 890 =head2 $c->dispatcher
 891
 892 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 893
 894 =head2 $c->engine
 895
 896 Returns the engine instance. See L<Catalyst::Engine>.
 897
 898
 899 =head2 UTILITY METHODS
 900
 901 =head2 $c->path_to(@path)
 902
 903 Merges C<@path> with C<< $c->config->{home} >> and returns a
 904 L<Path::Class::Dir> object.
 905
 906 For example:
 907
 908     $c->path_to( 'db', 'sqlite.db' );
 909
 910 =cut
 911
 912 sub path_to {
 913     my ( $c, @path ) = @_;
 914     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 915     if ( -d $path ) { return $path }
 916     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 917 }
 918
 919 =head2 $c->plugin( $name, $class, @args )
 920
 921 Helper method for plugins. It creates a class data accessor/mutator and
 922 loads and instantiates the given class.
 923
 924     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 925
 926     $c->prototype->define_javascript_functions;
 927
 928 B<Note:> This method of adding plugins is deprecated. The ability
 929 to add plugins like this B<will be removed> in a Catalyst 5.81.
 930 Please do not use this functionality in new code.
 931
 932 =cut
 933
 934 sub plugin {
 935     my ( $class, $name, $plugin, @args ) = @_;
 936
 937     # See block comment in t/unit_core_plugin.t
 938     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 939
 940     $class->_register_plugin( $plugin, 1 );
 941
 942     eval { $plugin->import };
 943     $class->mk_classdata($name);
 944     my $obj;
 945     eval { $obj = $plugin->new(@args) };
 946
 947     if ($@) {
 948         Catalyst::Exception->throw( message =>
 949               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 950     }
 951
 952     $class->$name($obj);
 953     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 954       if $class->debug;
 955 }
 956
 957 =head2 MyApp->setup
 958
 959 Initializes the dispatcher and engine, loads any plugins, and loads the
 960 model, view, and controller components. You may also specify an array
 961 of plugins to load here, if you choose to not load them in the C<use
 962 Catalyst> line.
 963
 964     MyApp->setup;
 965     MyApp->setup( qw/-Debug/ );
 966
 967 =cut
 968
 969 sub setup {
 970     my ( $class, @arguments ) = @_;
 971     croak('Running setup more than once')
 972         if ( $class->setup_finished );
 973
 974     unless ( $class->isa('Catalyst') ) {
 975
 976         Catalyst::Exception->throw(
 977             message => qq/'$class' does not inherit from Catalyst/ );
 978     }
 979
 980     if ( $class->arguments ) {
 981         @arguments = ( @arguments, @{ $class->arguments } );
 982     }
 983
 984     # Process options
 985     my $flags = {};
 986
 987     foreach (@arguments) {
 988
 989         if (/^-Debug$/) {
 990             $flags->{log} =
 991               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 992         }
 993         elsif (/^-(\w+)=?(.*)$/) {
 994             $flags->{ lc $1 } = $2;
 995         }
 996         else {
 997             push @{ $flags->{plugins} }, $_;
 998         }
 999     }
1000
1001     $class->setup_home( delete $flags->{home} );
1002
1003     $class->setup_log( delete $flags->{log} );
1004     $class->setup_plugins( delete $flags->{plugins} );
1005     $class->setup_dispatcher( delete $flags->{dispatcher} );
1006     $class->setup_engine( delete $flags->{engine} );
1007     $class->setup_stats( delete $flags->{stats} );
1008
1009     for my $flag ( sort keys %{$flags} ) {
1010
1011         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1012             &$code( $class, delete $flags->{$flag} );
1013         }
1014         else {
1015             $class->log->warn(qq/Unknown flag "$flag"/);
1016         }
1017     }
1018
1019     eval { require Catalyst::Devel; };
1020     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1021         $class->log->warn(<<"EOF");
1022 You are running an old script!
1023
1024   Please update by running (this will overwrite existing files):
1025     catalyst.pl -force -scripts $class
1026
1027   or (this will not overwrite existing files):
1028     catalyst.pl -scripts $class
1029
1030 EOF
1031     }
1032
1033     if ( $class->debug ) {
1034         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1035
1036         if (@plugins) {
1037             my $column_width = Catalyst::Utils::term_width() - 6;
1038             my $t = Text::SimpleTable->new($column_width);
1039             $t->row($_) for @plugins;
1040             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1041         }
1042
1043         my $dispatcher = $class->dispatcher;
1044         my $engine     = $class->engine;
1045         my $home       = $class->config->{home};
1046
1047         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1048         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1049
1050         $home
1051           ? ( -d $home )
1052           ? $class->log->debug(qq/Found home "$home"/)
1053           : $class->log->debug(qq/Home "$home" doesn't exist/)
1054           : $class->log->debug(q/Couldn't find home/);
1055     }
1056
1057     # Call plugins setup, this is stupid and evil.
1058     # Also screws C3 badly on 5.10, hack to avoid.
1059     {
1060         no warnings qw/redefine/;
1061         local *setup = sub { };
1062         $class->setup unless $Catalyst::__AM_RESTARTING;
1063     }
1064
1065     # Initialize our data structure
1066     $class->components( {} );
1067
1068     $class->setup_components;
1069
1070     if ( $class->debug ) {
1071         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1072         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1073         for my $comp ( sort keys %{ $class->components } ) {
1074             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1075             $t->row( $comp, $type );
1076         }
1077         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1078           if ( keys %{ $class->components } );
1079     }
1080
1081     # Add our self to components, since we are also a component
1082     if( $class->isa('Catalyst::Controller') ){
1083       $class->components->{$class} = $class;
1084     }
1085
1086     $class->setup_actions;
1087
1088     if ( $class->debug ) {
1089         my $name = $class->config->{name} || 'Application';
1090         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1091     }
1092     $class->log->_flush() if $class->log->can('_flush');
1093
1094     # Make sure that the application class becomes immutable at this point,
1095     # which ensures that it gets an inlined constructor. This means that it
1096     # works even if the user has added a plugin which contains a new method.
1097     # Note however that we have to do the work on scope end, so that method
1098     # modifiers work correctly in MyApp (as you have to call setup _before_
1099     # applying modifiers).
1100     Scope::Upper::reap(sub {
1101         my $meta = Class::MOP::get_metaclass_by_name($class);
1102         $meta->make_immutable(replace_constructor => 1) unless $meta->is_immutable;
1103     }, Scope::Upper::SCOPE(1));
1104
1105     $class->setup_finalize;
1106 }
1107
1108
1109 =head2 $app->setup_finalize
1110
1111 A hook to attach modifiers to.
1112 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1113 Also better than C< setup_finished(); >, as that is a getter method.
1114
1115     sub setup_finalize {
1116
1117         my $app = shift;
1118
1119         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1120
1121         $app->next::method(@_);
1122
1123
1124     }
1125
1126 =cut
1127
1128 sub setup_finalize {
1129     my ($class) = @_;
1130     $class->setup_finished(1);
1131 }
1132
1133 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1134
1135 =head2 $c->uri_for( $path, @args?, \%query_values? )
1136
1137 =over
1138
1139 =item $action
1140
1141 A Catalyst::Action object representing the Catalyst action you want to
1142 create a URI for. To get one for an action in the current controller,
1143 use C<< $c->action('someactionname') >>. To get one from different
1144 controller, fetch the controller using C<< $c->controller() >>, then
1145 call C<action_for> on it.
1146
1147 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1148 using C<< $c->req->captures >>.
1149
1150   # For the current action
1151   $c->uri_for($c->action, $c->req->captures);
1152
1153   # For the Foo action in the Bar controller
1154   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1155
1156 =back
1157
1158 =cut
1159
1160 sub uri_for {
1161     my ( $c, $path, @args ) = @_;
1162
1163     if ( blessed($path) ) { # action object
1164         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1165                          ? shift(@args)
1166                          : [] );
1167         my $action = $path;
1168         $path = $c->dispatcher->uri_for_action($action, $captures);
1169         if (not defined $path) {
1170             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1171                 if $c->debug;
1172             return undef;
1173         }
1174         $path = '/' if $path eq '';
1175     }
1176
1177     undef($path) if (defined $path && $path eq '');
1178
1179     my $params =
1180       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1181
1182     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1183     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1184
1185     unshift(@args, $path);
1186
1187     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1188         my $namespace = $c->namespace;
1189         if (defined $path) { # cheesy hack to handle path '../foo'
1190            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1191         }
1192         unshift(@args, $namespace || '');
1193     }
1194
1195     # join args with '/', or a blank string
1196     my $args = join('/', grep { defined($_) } @args);
1197     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1198     $args =~ s!^/+!!;
1199     my $base = $c->req->base;
1200     my $class = ref($base);
1201     $base =~ s{(?<!/)$}{/};
1202
1203     my $query = '';
1204
1205     if (my @keys = keys %$params) {
1206       # somewhat lifted from URI::_query's query_form
1207       $query = '?'.join('&', map {
1208           my $val = $params->{$_};
1209           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1210           s/ /+/g;
1211           my $key = $_;
1212           $val = '' unless defined $val;
1213           (map {
1214               $_ = "$_";
1215               utf8::encode( $_ ) if utf8::is_utf8($_);
1216               # using the URI::Escape pattern here so utf8 chars survive
1217               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1218               s/ /+/g;
1219               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1220       } @keys);
1221     }
1222
1223     my $res = bless(\"${base}${args}${query}", $class);
1224     $res;
1225 }
1226
1227 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1228
1229 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1230
1231 =over
1232
1233 =item $path
1234
1235 A private path to the Catalyst action you want to create a URI for.
1236
1237 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1238 >> and passing the resulting C<$action> and the remaining arguments to C<<
1239 $c->uri_for >>.
1240
1241 You can also pass in a Catalyst::Action object, in which case it is passed to
1242 C<< $c->uri_for >>.
1243
1244 =back
1245
1246 =cut
1247
1248 sub uri_for_action {
1249     my ( $c, $path, @args ) = @_;
1250     my $action = blessed($path)
1251       ? $path
1252       : $c->dispatcher->get_action_by_path($path);
1253     unless (defined $action) {
1254       croak "Can't find action for path '$path'";
1255     }
1256     return $c->uri_for( $action, @args );
1257 }
1258
1259 =head2 $c->welcome_message
1260
1261 Returns the Catalyst welcome HTML page.
1262
1263 =cut
1264
1265 sub welcome_message {
1266     my $c      = shift;
1267     my $name   = $c->config->{name};
1268     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1269     my $prefix = Catalyst::Utils::appprefix( ref $c );
1270     $c->response->content_type('text/html; charset=utf-8');
1271     return <<"EOF";
1272 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1273     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1274 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1275     <head>
1276     <meta http-equiv="Content-Language" content="en" />
1277     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1278         <title>$name on Catalyst $VERSION</title>
1279         <style type="text/css">
1280             body {
1281                 color: #000;
1282                 background-color: #eee;
1283             }
1284             div#content {
1285                 width: 640px;
1286                 margin-left: auto;
1287                 margin-right: auto;
1288                 margin-top: 10px;
1289                 margin-bottom: 10px;
1290                 text-align: left;
1291                 background-color: #ccc;
1292                 border: 1px solid #aaa;
1293             }
1294             p, h1, h2 {
1295                 margin-left: 20px;
1296                 margin-right: 20px;
1297                 font-family: verdana, tahoma, sans-serif;
1298             }
1299             a {
1300                 font-family: verdana, tahoma, sans-serif;
1301             }
1302             :link, :visited {
1303                     text-decoration: none;
1304                     color: #b00;
1305                     border-bottom: 1px dotted #bbb;
1306             }
1307             :link:hover, :visited:hover {
1308                     color: #555;
1309             }
1310             div#topbar {
1311                 margin: 0px;
1312             }
1313             pre {
1314                 margin: 10px;
1315                 padding: 8px;
1316             }
1317             div#answers {
1318                 padding: 8px;
1319                 margin: 10px;
1320                 background-color: #fff;
1321                 border: 1px solid #aaa;
1322             }
1323             h1 {
1324                 font-size: 0.9em;
1325                 font-weight: normal;
1326                 text-align: center;
1327             }
1328             h2 {
1329                 font-size: 1.0em;
1330             }
1331             p {
1332                 font-size: 0.9em;
1333             }
1334             p img {
1335                 float: right;
1336                 margin-left: 10px;
1337             }
1338             span#appname {
1339                 font-weight: bold;
1340                 font-size: 1.6em;
1341             }
1342         </style>
1343     </head>
1344     <body>
1345         <div id="content">
1346             <div id="topbar">
1347                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1348                     $VERSION</h1>
1349              </div>
1350              <div id="answers">
1351                  <p>
1352                  <img src="$logo" alt="Catalyst Logo" />
1353                  </p>
1354                  <p>Welcome to the  world of Catalyst.
1355                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1356                     framework will make web development something you had
1357                     never expected it to be: Fun, rewarding, and quick.</p>
1358                  <h2>What to do now?</h2>
1359                  <p>That really depends  on what <b>you</b> want to do.
1360                     We do, however, provide you with a few starting points.</p>
1361                  <p>If you want to jump right into web development with Catalyst
1362                     you might want to start with a tutorial.</p>
1363 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1364 </pre>
1365 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1366 <pre>
1367 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1368 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1369 </code></pre>
1370                  <h2>What to do next?</h2>
1371                  <p>Next it's time to write an actual application. Use the
1372                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1373                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1374                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1375                     they can save you a lot of work.</p>
1376                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1377                     <p>Also, be sure to check out the vast and growing
1378                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1379                     you are likely to find what you need there.
1380                     </p>
1381
1382                  <h2>Need help?</h2>
1383                  <p>Catalyst has a very active community. Here are the main places to
1384                     get in touch with us.</p>
1385                  <ul>
1386                      <li>
1387                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1388                      </li>
1389                      <li>
1390                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1391                      </li>
1392                      <li>
1393                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1394                      </li>
1395                  </ul>
1396                  <h2>In conclusion</h2>
1397                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1398                     as we enjoyed making it. Please contact us if you have ideas
1399                     for improvement or other feedback.</p>
1400              </div>
1401          </div>
1402     </body>
1403 </html>
1404 EOF
1405 }
1406
1407 =head1 INTERNAL METHODS
1408
1409 These methods are not meant to be used by end users.
1410
1411 =head2 $c->components
1412
1413 Returns a hash of components.
1414
1415 =head2 $c->context_class
1416
1417 Returns or sets the context class.
1418
1419 =head2 $c->counter
1420
1421 Returns a hashref containing coderefs and execution counts (needed for
1422 deep recursion detection).
1423
1424 =head2 $c->depth
1425
1426 Returns the number of actions on the current internal execution stack.
1427
1428 =head2 $c->dispatch
1429
1430 Dispatches a request to actions.
1431
1432 =cut
1433
1434 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1435
1436 =head2 $c->dispatcher_class
1437
1438 Returns or sets the dispatcher class.
1439
1440 =head2 $c->dump_these
1441
1442 Returns a list of 2-element array references (name, structure) pairs
1443 that will be dumped on the error page in debug mode.
1444
1445 =cut
1446
1447 sub dump_these {
1448     my $c = shift;
1449     [ Request => $c->req ],
1450     [ Response => $c->res ],
1451     [ Stash => $c->stash ],
1452     [ Config => $c->config ];
1453 }
1454
1455 =head2 $c->engine_class
1456
1457 Returns or sets the engine class.
1458
1459 =head2 $c->execute( $class, $coderef )
1460
1461 Execute a coderef in given class and catch exceptions. Errors are available
1462 via $c->error.
1463
1464 =cut
1465
1466 sub execute {
1467     my ( $c, $class, $code ) = @_;
1468     $class = $c->component($class) || $class;
1469     $c->state(0);
1470
1471     if ( $c->depth >= $RECURSION ) {
1472         my $action = $code->reverse();
1473         $action = "/$action" unless $action =~ /->/;
1474         my $error = qq/Deep recursion detected calling "${action}"/;
1475         $c->log->error($error);
1476         $c->error($error);
1477         $c->state(0);
1478         return $c->state;
1479     }
1480
1481     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1482
1483     push( @{ $c->stack }, $code );
1484
1485     no warnings 'recursion';
1486     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1487
1488     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1489
1490     my $last = pop( @{ $c->stack } );
1491
1492     if ( my $error = $@ ) {
1493         if ( !ref($error) and $error eq $DETACH ) {
1494             die $DETACH if($c->depth > 1);
1495         }
1496         elsif ( !ref($error) and $error eq $GO ) {
1497             die $GO if($c->depth > 0);
1498         }
1499         else {
1500             unless ( ref $error ) {
1501                 no warnings 'uninitialized';
1502                 chomp $error;
1503                 my $class = $last->class;
1504                 my $name  = $last->name;
1505                 $error = qq/Caught exception in $class->$name "$error"/;
1506             }
1507             $c->error($error);
1508             $c->state(0);
1509         }
1510     }
1511     return $c->state;
1512 }
1513
1514 sub _stats_start_execute {
1515     my ( $c, $code ) = @_;
1516
1517     return if ( ( $code->name =~ /^_.*/ )
1518         && ( !$c->config->{show_internal_actions} ) );
1519
1520     my $action_name = $code->reverse();
1521     $c->counter->{$action_name}++;
1522
1523     my $action = $action_name;
1524     $action = "/$action" unless $action =~ /->/;
1525
1526     # determine if the call was the result of a forward
1527     # this is done by walking up the call stack and looking for a calling
1528     # sub of Catalyst::forward before the eval
1529     my $callsub = q{};
1530     for my $index ( 2 .. 11 ) {
1531         last
1532         if ( ( caller($index) )[0] eq 'Catalyst'
1533             && ( caller($index) )[3] eq '(eval)' );
1534
1535         if ( ( caller($index) )[3] =~ /forward$/ ) {
1536             $callsub = ( caller($index) )[3];
1537             $action  = "-> $action";
1538             last;
1539         }
1540     }
1541
1542     my $uid = $action_name . $c->counter->{$action_name};
1543
1544     # is this a root-level call or a forwarded call?
1545     if ( $callsub =~ /forward$/ ) {
1546
1547         # forward, locate the caller
1548         if ( my $parent = $c->stack->[-1] ) {
1549             $c->stats->profile(
1550                 begin  => $action,
1551                 parent => "$parent" . $c->counter->{"$parent"},
1552                 uid    => $uid,
1553             );
1554         }
1555         else {
1556
1557             # forward with no caller may come from a plugin
1558             $c->stats->profile(
1559                 begin => $action,
1560                 uid   => $uid,
1561             );
1562         }
1563     }
1564     else {
1565
1566         # root-level call
1567         $c->stats->profile(
1568             begin => $action,
1569             uid   => $uid,
1570         );
1571     }
1572     return $action;
1573
1574 }
1575
1576 sub _stats_finish_execute {
1577     my ( $c, $info ) = @_;
1578     $c->stats->profile( end => $info );
1579 }
1580
1581 =head2 $c->_localize_fields( sub { }, \%keys );
1582
1583 =cut
1584
1585 #Why does this exist? This is no longer safe and WILL NOT WORK.
1586 # it doesnt seem to be used anywhere. can we remove it?
1587 sub _localize_fields {
1588     my ( $c, $localized, $code ) = ( @_ );
1589
1590     my $request = delete $localized->{request} || {};
1591     my $response = delete $localized->{response} || {};
1592
1593     local @{ $c }{ keys %$localized } = values %$localized;
1594     local @{ $c->request }{ keys %$request } = values %$request;
1595     local @{ $c->response }{ keys %$response } = values %$response;
1596
1597     $code->();
1598 }
1599
1600 =head2 $c->finalize
1601
1602 Finalizes the request.
1603
1604 =cut
1605
1606 sub finalize {
1607     my $c = shift;
1608
1609     for my $error ( @{ $c->error } ) {
1610         $c->log->error($error);
1611     }
1612
1613     # Allow engine to handle finalize flow (for POE)
1614     my $engine = $c->engine;
1615     if ( my $code = $engine->can('finalize') ) {
1616         $engine->$code($c);
1617     }
1618     else {
1619
1620         $c->finalize_uploads;
1621
1622         # Error
1623         if ( $#{ $c->error } >= 0 ) {
1624             $c->finalize_error;
1625         }
1626
1627         $c->finalize_headers;
1628
1629         # HEAD request
1630         if ( $c->request->method eq 'HEAD' ) {
1631             $c->response->body('');
1632         }
1633
1634         $c->finalize_body;
1635     }
1636
1637     if ($c->use_stats) {
1638         my $elapsed = sprintf '%f', $c->stats->elapsed;
1639         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1640         $c->log->info(
1641             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1642     }
1643
1644     return $c->response->status;
1645 }
1646
1647 =head2 $c->finalize_body
1648
1649 Finalizes body.
1650
1651 =cut
1652
1653 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1654
1655 =head2 $c->finalize_cookies
1656
1657 Finalizes cookies.
1658
1659 =cut
1660
1661 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1662
1663 =head2 $c->finalize_error
1664
1665 Finalizes error.
1666
1667 =cut
1668
1669 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1670
1671 =head2 $c->finalize_headers
1672
1673 Finalizes headers.
1674
1675 =cut
1676
1677 sub finalize_headers {
1678     my $c = shift;
1679
1680     my $response = $c->response; #accessor calls can add up?
1681
1682     # Check if we already finalized headers
1683     return if $response->finalized_headers;
1684
1685     # Handle redirects
1686     if ( my $location = $response->redirect ) {
1687         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1688         $response->header( Location => $location );
1689
1690         if ( !$response->has_body ) {
1691             # Add a default body if none is already present
1692             $response->body(
1693                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1694             );
1695         }
1696     }
1697
1698     # Content-Length
1699     if ( $response->body && !$response->content_length ) {
1700
1701         # get the length from a filehandle
1702         if ( blessed( $response->body ) && $response->body->can('read') )
1703         {
1704             my $stat = stat $response->body;
1705             if ( $stat && $stat->size > 0 ) {
1706                 $response->content_length( $stat->size );
1707             }
1708             else {
1709                 $c->log->warn('Serving filehandle without a content-length');
1710             }
1711         }
1712         else {
1713             # everything should be bytes at this point, but just in case
1714             $response->content_length( bytes::length( $response->body ) );
1715         }
1716     }
1717
1718     # Errors
1719     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1720         $response->headers->remove_header("Content-Length");
1721         $response->body('');
1722     }
1723
1724     $c->finalize_cookies;
1725
1726     $c->engine->finalize_headers( $c, @_ );
1727
1728     # Done
1729     $response->finalized_headers(1);
1730 }
1731
1732 =head2 $c->finalize_output
1733
1734 An alias for finalize_body.
1735
1736 =head2 $c->finalize_read
1737
1738 Finalizes the input after reading is complete.
1739
1740 =cut
1741
1742 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1743
1744 =head2 $c->finalize_uploads
1745
1746 Finalizes uploads. Cleans up any temporary files.
1747
1748 =cut
1749
1750 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1751
1752 =head2 $c->get_action( $action, $namespace )
1753
1754 Gets an action in a given namespace.
1755
1756 =cut
1757
1758 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1759
1760 =head2 $c->get_actions( $action, $namespace )
1761
1762 Gets all actions of a given name in a namespace and all parent
1763 namespaces.
1764
1765 =cut
1766
1767 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1768
1769 =head2 $c->handle_request( $class, @arguments )
1770
1771 Called to handle each HTTP request.
1772
1773 =cut
1774
1775 sub handle_request {
1776     my ( $class, @arguments ) = @_;
1777
1778     # Always expect worst case!
1779     my $status = -1;
1780     eval {
1781         if ($class->debug) {
1782             my $secs = time - $START || 1;
1783             my $av = sprintf '%.3f', $COUNT / $secs;
1784             my $time = localtime time;
1785             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1786         }
1787
1788         my $c = $class->prepare(@arguments);
1789         $c->dispatch;
1790         $status = $c->finalize;
1791     };
1792
1793     if ( my $error = $@ ) {
1794         chomp $error;
1795         $class->log->error(qq/Caught exception in engine "$error"/);
1796     }
1797
1798     $COUNT++;
1799
1800     if(my $coderef = $class->log->can('_flush')){
1801         $class->log->$coderef();
1802     }
1803     return $status;
1804 }
1805
1806 =head2 $c->prepare( @arguments )
1807
1808 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1809 etc.).
1810
1811 =cut
1812
1813 sub prepare {
1814     my ( $class, @arguments ) = @_;
1815
1816     # XXX
1817     # After the app/ctxt split, this should become an attribute based on something passed
1818     # into the application.
1819     $class->context_class( ref $class || $class ) unless $class->context_class;
1820
1821     my $c = $class->context_class->new({});
1822
1823     # For on-demand data
1824     $c->request->_context($c);
1825     $c->response->_context($c);
1826
1827     #surely this is not the most efficient way to do things...
1828     $c->stats($class->stats_class->new)->enable($c->use_stats);
1829     if ( $c->debug ) {
1830         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1831     }
1832
1833     #XXX reuse coderef from can
1834     # Allow engine to direct the prepare flow (for POE)
1835     if ( $c->engine->can('prepare') ) {
1836         $c->engine->prepare( $c, @arguments );
1837     }
1838     else {
1839         $c->prepare_request(@arguments);
1840         $c->prepare_connection;
1841         $c->prepare_query_parameters;
1842         $c->prepare_headers;
1843         $c->prepare_cookies;
1844         $c->prepare_path;
1845
1846         # Prepare the body for reading, either by prepare_body
1847         # or the user, if they are using $c->read
1848         $c->prepare_read;
1849
1850         # Parse the body unless the user wants it on-demand
1851         unless ( $c->config->{parse_on_demand} ) {
1852             $c->prepare_body;
1853         }
1854     }
1855
1856     my $method  = $c->req->method  || '';
1857     my $path    = $c->req->path;
1858     $path       = '/' unless length $path;
1859     my $address = $c->req->address || '';
1860
1861     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1862       if $c->debug;
1863
1864     $c->prepare_action;
1865
1866     return $c;
1867 }
1868
1869 =head2 $c->prepare_action
1870
1871 Prepares action. See L<Catalyst::Dispatcher>.
1872
1873 =cut
1874
1875 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1876
1877 =head2 $c->prepare_body
1878
1879 Prepares message body.
1880
1881 =cut
1882
1883 sub prepare_body {
1884     my $c = shift;
1885
1886     return if $c->request->_has_body;
1887
1888     # Initialize on-demand data
1889     $c->engine->prepare_body( $c, @_ );
1890     $c->prepare_parameters;
1891     $c->prepare_uploads;
1892
1893     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1894         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1895         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1896             my $param = $c->req->body_parameters->{$key};
1897             my $value = defined($param) ? $param : '';
1898             $t->row( $key,
1899                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1900         }
1901         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1902     }
1903 }
1904
1905 =head2 $c->prepare_body_chunk( $chunk )
1906
1907 Prepares a chunk of data before sending it to L<HTTP::Body>.
1908
1909 See L<Catalyst::Engine>.
1910
1911 =cut
1912
1913 sub prepare_body_chunk {
1914     my $c = shift;
1915     $c->engine->prepare_body_chunk( $c, @_ );
1916 }
1917
1918 =head2 $c->prepare_body_parameters
1919
1920 Prepares body parameters.
1921
1922 =cut
1923
1924 sub prepare_body_parameters {
1925     my $c = shift;
1926     $c->engine->prepare_body_parameters( $c, @_ );
1927 }
1928
1929 =head2 $c->prepare_connection
1930
1931 Prepares connection.
1932
1933 =cut
1934
1935 sub prepare_connection {
1936     my $c = shift;
1937     $c->engine->prepare_connection( $c, @_ );
1938 }
1939
1940 =head2 $c->prepare_cookies
1941
1942 Prepares cookies.
1943
1944 =cut
1945
1946 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1947
1948 =head2 $c->prepare_headers
1949
1950 Prepares headers.
1951
1952 =cut
1953
1954 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1955
1956 =head2 $c->prepare_parameters
1957
1958 Prepares parameters.
1959
1960 =cut
1961
1962 sub prepare_parameters {
1963     my $c = shift;
1964     $c->prepare_body_parameters;
1965     $c->engine->prepare_parameters( $c, @_ );
1966 }
1967
1968 =head2 $c->prepare_path
1969
1970 Prepares path and base.
1971
1972 =cut
1973
1974 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1975
1976 =head2 $c->prepare_query_parameters
1977
1978 Prepares query parameters.
1979
1980 =cut
1981
1982 sub prepare_query_parameters {
1983     my $c = shift;
1984
1985     $c->engine->prepare_query_parameters( $c, @_ );
1986
1987     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1988         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1989         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1990             my $param = $c->req->query_parameters->{$key};
1991             my $value = defined($param) ? $param : '';
1992             $t->row( $key,
1993                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1994         }
1995         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1996     }
1997 }
1998
1999 =head2 $c->prepare_read
2000
2001 Prepares the input for reading.
2002
2003 =cut
2004
2005 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2006
2007 =head2 $c->prepare_request
2008
2009 Prepares the engine request.
2010
2011 =cut
2012
2013 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2014
2015 =head2 $c->prepare_uploads
2016
2017 Prepares uploads.
2018
2019 =cut
2020
2021 sub prepare_uploads {
2022     my $c = shift;
2023
2024     $c->engine->prepare_uploads( $c, @_ );
2025
2026     if ( $c->debug && keys %{ $c->request->uploads } ) {
2027         my $t = Text::SimpleTable->new(
2028             [ 12, 'Parameter' ],
2029             [ 26, 'Filename' ],
2030             [ 18, 'Type' ],
2031             [ 9,  'Size' ]
2032         );
2033         for my $key ( sort keys %{ $c->request->uploads } ) {
2034             my $upload = $c->request->uploads->{$key};
2035             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2036                 $t->row( $key, $u->filename, $u->type, $u->size );
2037             }
2038         }
2039         $c->log->debug( "File Uploads are:\n" . $t->draw );
2040     }
2041 }
2042
2043 =head2 $c->prepare_write
2044
2045 Prepares the output for writing.
2046
2047 =cut
2048
2049 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2050
2051 =head2 $c->request_class
2052
2053 Returns or sets the request class.
2054
2055 =head2 $c->response_class
2056
2057 Returns or sets the response class.
2058
2059 =head2 $c->read( [$maxlength] )
2060
2061 Reads a chunk of data from the request body. This method is designed to
2062 be used in a while loop, reading C<$maxlength> bytes on every call.
2063 C<$maxlength> defaults to the size of the request if not specified.
2064
2065 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
2066 directly.
2067
2068 Warning: If you use read(), Catalyst will not process the body,
2069 so you will not be able to access POST parameters or file uploads via
2070 $c->request.  You must handle all body parsing yourself.
2071
2072 =cut
2073
2074 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2075
2076 =head2 $c->run
2077
2078 Starts the engine.
2079
2080 =cut
2081
2082 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2083
2084 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2085
2086 Sets an action in a given namespace.
2087
2088 =cut
2089
2090 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2091
2092 =head2 $c->setup_actions($component)
2093
2094 Sets up actions for a component.
2095
2096 =cut
2097
2098 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2099
2100 =head2 $c->setup_components
2101
2102 Sets up components. Specify a C<setup_components> config option to pass
2103 additional options directly to L<Module::Pluggable>. To add additional
2104 search paths, specify a key named C<search_extra> as an array
2105 reference. Items in the array beginning with C<::> will have the
2106 application class name prepended to them.
2107
2108 All components found will also have any
2109 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2110 Note, that modules which are B<not> an I<inner package> of the main
2111 file namespace loaded will not be instantiated as components.
2112
2113 =cut
2114
2115 sub setup_components {
2116     my $class = shift;
2117
2118     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2119     my $config  = $class->config->{ setup_components };
2120     my $extra   = delete $config->{ search_extra } || [];
2121
2122     push @paths, @$extra;
2123
2124     my $locator = Module::Pluggable::Object->new(
2125         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2126         %$config
2127     );
2128
2129     my @comps = sort { length $a <=> length $b } $locator->plugins;
2130     my %comps = map { $_ => 1 } @comps;
2131
2132     my $deprecated_component_names = grep { /::[CMV]::/ } @comps;
2133     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2134         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2135     ) if $deprecated_component_names;
2136
2137     for my $component ( @comps ) {
2138
2139         # We pass ignore_loaded here so that overlay files for (e.g.)
2140         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2141         # we know M::P::O found a file on disk so this is safe
2142
2143         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2144         #Class::MOP::load_class($component);
2145
2146         my $module  = $class->setup_component( $component );
2147         my %modules = (
2148             $component => $module,
2149             map {
2150                 $_ => $class->setup_component( $_ )
2151             } grep {
2152               not exists $comps{$_}
2153             } Devel::InnerPackage::list_packages( $component )
2154         );
2155
2156         for my $key ( keys %modules ) {
2157             $class->components->{ $key } = $modules{ $key };
2158         }
2159     }
2160 }
2161
2162 =head2 $c->setup_component
2163
2164 =cut
2165
2166 sub _controller_init_base_classes {
2167     my ($class, $component) = @_;
2168     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2169         Moose->init_meta( for_class => $class )
2170             unless find_meta($class);
2171     }
2172 }
2173
2174 sub setup_component {
2175     my( $class, $component ) = @_;
2176
2177     unless ( $component->can( 'COMPONENT' ) ) {
2178         return $component;
2179     }
2180
2181     # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2182     #         nearest to Catalyst::Controller first, no matter what order stuff happens
2183     #         to be loaded. There are TODO tests in Moose for this, see
2184     #         f2391d17574eff81d911b97be15ea51080500003
2185     if ($component->isa('Catalyst::Controller')) {
2186         $class->_controller_init_base_classes($component);
2187     }
2188
2189     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2190     my $config = $class->config->{ $suffix } || {};
2191
2192     my $instance = eval { $component->COMPONENT( $class, $config ); };
2193
2194     if ( my $error = $@ ) {
2195         chomp $error;
2196         Catalyst::Exception->throw(
2197             message => qq/Couldn't instantiate component "$component", "$error"/
2198         );
2199     }
2200
2201     unless (blessed $instance) {
2202         my $metaclass = Moose::Util::find_meta($component);
2203         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2204         my $component_method_from = $method_meta->associated_metaclass->name;
2205         my $value = defined($instance) ? $instance : 'undef';
2206         Catalyst::Exception->throw(
2207             message =>
2208             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2209         );
2210     }
2211     return $instance;
2212 }
2213
2214 =head2 $c->setup_dispatcher
2215
2216 Sets up dispatcher.
2217
2218 =cut
2219
2220 sub setup_dispatcher {
2221     my ( $class, $dispatcher ) = @_;
2222
2223     if ($dispatcher) {
2224         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2225     }
2226
2227     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2228         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2229     }
2230
2231     unless ($dispatcher) {
2232         $dispatcher = $class->dispatcher_class;
2233     }
2234
2235     Class::MOP::load_class($dispatcher);
2236
2237     # dispatcher instance
2238     $class->dispatcher( $dispatcher->new );
2239 }
2240
2241 =head2 $c->setup_engine
2242
2243 Sets up engine.
2244
2245 =cut
2246
2247 sub setup_engine {
2248     my ( $class, $engine ) = @_;
2249
2250     if ($engine) {
2251         $engine = 'Catalyst::Engine::' . $engine;
2252     }
2253
2254     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2255         $engine = 'Catalyst::Engine::' . $env;
2256     }
2257
2258     if ( $ENV{MOD_PERL} ) {
2259         my $meta = Class::MOP::get_metaclass_by_name($class);
2260
2261         # create the apache method
2262         $meta->add_method('apache' => sub { shift->engine->apache });
2263
2264         my ( $software, $version ) =
2265           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2266
2267         $version =~ s/_//g;
2268         $version =~ s/(\.[^.]+)\./$1/g;
2269
2270         if ( $software eq 'mod_perl' ) {
2271
2272             if ( !$engine ) {
2273
2274                 if ( $version >= 1.99922 ) {
2275                     $engine = 'Catalyst::Engine::Apache2::MP20';
2276                 }
2277
2278                 elsif ( $version >= 1.9901 ) {
2279                     $engine = 'Catalyst::Engine::Apache2::MP19';
2280                 }
2281
2282                 elsif ( $version >= 1.24 ) {
2283                     $engine = 'Catalyst::Engine::Apache::MP13';
2284                 }
2285
2286                 else {
2287                     Catalyst::Exception->throw( message =>
2288                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2289                 }
2290
2291             }
2292
2293             # install the correct mod_perl handler
2294             if ( $version >= 1.9901 ) {
2295                 *handler = sub  : method {
2296                     shift->handle_request(@_);
2297                 };
2298             }
2299             else {
2300                 *handler = sub ($$) { shift->handle_request(@_) };
2301             }
2302
2303         }
2304
2305         elsif ( $software eq 'Zeus-Perl' ) {
2306             $engine = 'Catalyst::Engine::Zeus';
2307         }
2308
2309         else {
2310             Catalyst::Exception->throw(
2311                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2312         }
2313     }
2314
2315     unless ($engine) {
2316         $engine = $class->engine_class;
2317     }
2318
2319     Class::MOP::load_class($engine);
2320
2321     # check for old engines that are no longer compatible
2322     my $old_engine;
2323     if ( $engine->isa('Catalyst::Engine::Apache')
2324         && !Catalyst::Engine::Apache->VERSION )
2325     {
2326         $old_engine = 1;
2327     }
2328
2329     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2330         && Catalyst::Engine::Server->VERSION le '0.02' )
2331     {
2332         $old_engine = 1;
2333     }
2334
2335     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2336         && $engine->VERSION eq '0.01' )
2337     {
2338         $old_engine = 1;
2339     }
2340
2341     elsif ($engine->isa('Catalyst::Engine::Zeus')
2342         && $engine->VERSION eq '0.01' )
2343     {
2344         $old_engine = 1;
2345     }
2346
2347     if ($old_engine) {
2348         Catalyst::Exception->throw( message =>
2349               qq/Engine "$engine" is not supported by this version of Catalyst/
2350         );
2351     }
2352
2353     # engine instance
2354     $class->engine( $engine->new );
2355 }
2356
2357 =head2 $c->setup_home
2358
2359 Sets up the home directory.
2360
2361 =cut
2362
2363 sub setup_home {
2364     my ( $class, $home ) = @_;
2365
2366     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2367         $home = $env;
2368     }
2369
2370     $home ||= Catalyst::Utils::home($class);
2371
2372     if ($home) {
2373         #I remember recently being scolded for assigning config values like this
2374         $class->config->{home} ||= $home;
2375         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2376     }
2377 }
2378
2379 =head2 $c->setup_log
2380
2381 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2382 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2383 log to.
2384
2385 This method also installs a C<debug> method that returns a true value into the
2386 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2387 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2388
2389 Note that if the log has already been setup, by either a previous call to
2390 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2391 that this method won't actually set up the log object.
2392
2393 =cut
2394
2395 sub setup_log {
2396     my ( $class, $levels ) = @_;
2397
2398     $levels ||= '';
2399     $levels =~ s/^\s+//;
2400     $levels =~ s/\s+$//;
2401     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels || '';
2402
2403     unless ( $class->log ) {
2404         $class->log( Catalyst::Log->new(keys %levels) );
2405     }
2406
2407     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2408     if ( defined($env_debug) or $levels{debug} ) {
2409         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2410         $class->log->debug('Debug messages enabled');
2411     }
2412 }
2413
2414 =head2 $c->setup_plugins
2415
2416 Sets up plugins.
2417
2418 =cut
2419
2420 =head2 $c->setup_stats
2421
2422 Sets up timing statistics class.
2423
2424 =cut
2425
2426 sub setup_stats {
2427     my ( $class, $stats ) = @_;
2428
2429     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2430
2431     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2432     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2433         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2434         $class->log->debug('Statistics enabled');
2435     }
2436 }
2437
2438
2439 =head2 $c->registered_plugins
2440
2441 Returns a sorted list of the plugins which have either been stated in the
2442 import list or which have been added via C<< MyApp->plugin(@args); >>.
2443
2444 If passed a given plugin name, it will report a boolean value indicating
2445 whether or not that plugin is loaded.  A fully qualified name is required if
2446 the plugin name does not begin with C<Catalyst::Plugin::>.
2447
2448  if ($c->registered_plugins('Some::Plugin')) {
2449      ...
2450  }
2451
2452 =cut
2453
2454 {
2455
2456     sub registered_plugins {
2457         my $proto = shift;
2458         return sort keys %{ $proto->_plugins } unless @_;
2459         my $plugin = shift;
2460         return 1 if exists $proto->_plugins->{$plugin};
2461         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2462     }
2463
2464     sub _register_plugin {
2465         my ( $proto, $plugin, $instant ) = @_;
2466         my $class = ref $proto || $proto;
2467
2468         # no ignore_loaded here, the plugin may already have been
2469         # defined in memory and we don't want to error on "no file" if so
2470
2471         Class::MOP::load_class( $plugin );
2472
2473         $proto->_plugins->{$plugin} = 1;
2474         unless ($instant) {
2475             no strict 'refs';
2476             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2477               my @superclasses = ($plugin, $meta->superclasses );
2478               $meta->superclasses(@superclasses);
2479             } else {
2480               unshift @{"$class\::ISA"}, $plugin;
2481             }
2482         }
2483         return $class;
2484     }
2485
2486     sub setup_plugins {
2487         my ( $class, $plugins ) = @_;
2488
2489         $class->_plugins( {} ) unless $class->_plugins;
2490         $plugins ||= [];
2491         for my $plugin ( reverse @$plugins ) {
2492
2493             unless ( $plugin =~ s/\A\+// ) {
2494                 $plugin = "Catalyst::Plugin::$plugin";
2495             }
2496
2497             $class->_register_plugin($plugin);
2498         }
2499     }
2500 }
2501
2502 =head2 $c->stack
2503
2504 Returns an arrayref of the internal execution stack (actions that are
2505 currently executing).
2506
2507 =head2 $c->stats_class
2508
2509 Returns or sets the stats (timing statistics) class.
2510
2511 =head2 $c->use_stats
2512
2513 Returns 1 when stats collection is enabled.  Stats collection is enabled
2514 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2515 environment variable is set.
2516
2517 Note that this is a static method, not an accessor and should be overloaded
2518 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2519
2520 =cut
2521
2522 sub use_stats { 0 }
2523
2524
2525 =head2 $c->write( $data )
2526
2527 Writes $data to the output stream. When using this method directly, you
2528 will need to manually set the C<Content-Length> header to the length of
2529 your output data, if known.
2530
2531 =cut
2532
2533 sub write {
2534     my $c = shift;
2535
2536     # Finalize headers if someone manually writes output
2537     $c->finalize_headers;
2538
2539     return $c->engine->write( $c, @_ );
2540 }
2541
2542 =head2 version
2543
2544 Returns the Catalyst version number. Mostly useful for "powered by"
2545 messages in template systems.
2546
2547 =cut
2548
2549 sub version { return $Catalyst::VERSION }
2550
2551 =head1 INTERNAL ACTIONS
2552
2553 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2554 C<_ACTION>, and C<_END>. These are by default not shown in the private
2555 action table, but you can make them visible with a config parameter.
2556
2557     MyApp->config->{show_internal_actions} = 1;
2558
2559 =head1 CASE SENSITIVITY
2560
2561 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2562 mapped to C</foo/bar>. You can activate case sensitivity with a config
2563 parameter.
2564
2565     MyApp->config->{case_sensitive} = 1;
2566
2567 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2568
2569 =head1 ON-DEMAND PARSER
2570
2571 The request body is usually parsed at the beginning of a request,
2572 but if you want to handle input yourself, you can enable on-demand
2573 parsing with a config parameter.
2574
2575     MyApp->config->{parse_on_demand} = 1;
2576
2577 =head1 PROXY SUPPORT
2578
2579 Many production servers operate using the common double-server approach,
2580 with a lightweight frontend web server passing requests to a larger
2581 backend server. An application running on the backend server must deal
2582 with two problems: the remote user always appears to be C<127.0.0.1> and
2583 the server's hostname will appear to be C<localhost> regardless of the
2584 virtual host that the user connected through.
2585
2586 Catalyst will automatically detect this situation when you are running
2587 the frontend and backend servers on the same machine. The following
2588 changes are made to the request.
2589
2590     $c->req->address is set to the user's real IP address, as read from
2591     the HTTP X-Forwarded-For header.
2592
2593     The host value for $c->req->base and $c->req->uri is set to the real
2594     host, as read from the HTTP X-Forwarded-Host header.
2595
2596 Obviously, your web server must support these headers for this to work.
2597
2598 In a more complex server farm environment where you may have your
2599 frontend proxy server(s) on different machines, you will need to set a
2600 configuration option to tell Catalyst to read the proxied data from the
2601 headers.
2602
2603     MyApp->config->{using_frontend_proxy} = 1;
2604
2605 If you do not wish to use the proxy support at all, you may set:
2606
2607     MyApp->config->{ignore_frontend_proxy} = 1;
2608
2609 =head1 THREAD SAFETY
2610
2611 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2612 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2613 believe the Catalyst core to be thread-safe.
2614
2615 If you plan to operate in a threaded environment, remember that all other
2616 modules you are using must also be thread-safe. Some modules, most notably
2617 L<DBD::SQLite>, are not thread-safe.
2618
2619 =head1 SUPPORT
2620
2621 IRC:
2622
2623     Join #catalyst on irc.perl.org.
2624
2625 Mailing Lists:
2626
2627     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2628     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2629
2630 Web:
2631
2632     http://catalyst.perl.org
2633
2634 Wiki:
2635
2636     http://dev.catalyst.perl.org
2637
2638 =head1 SEE ALSO
2639
2640 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2641
2642 =head2 L<Catalyst::Manual> - The Catalyst Manual
2643
2644 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2645
2646 =head2 L<Catalyst::Engine> - Core engine
2647
2648 =head2 L<Catalyst::Log> - Log class.
2649
2650 =head2 L<Catalyst::Request> - Request object
2651
2652 =head2 L<Catalyst::Response> - Response object
2653
2654 =head2 L<Catalyst::Test> - The test suite.
2655
2656 =head1 PROJECT FOUNDER
2657
2658 sri: Sebastian Riedel <sri@cpan.org>
2659
2660 =head1 CONTRIBUTORS
2661
2662 abw: Andy Wardley
2663
2664 acme: Leon Brocard <leon@astray.com>
2665
2666 Andrew Bramble
2667
2668 Andrew Ford
2669
2670 Andrew Ruthven
2671
2672 andyg: Andy Grundman <andy@hybridized.org>
2673
2674 audreyt: Audrey Tang
2675
2676 bricas: Brian Cassidy <bricas@cpan.org>
2677
2678 Caelum: Rafael Kitover <rkitover@io.com>
2679
2680 chansen: Christian Hansen
2681
2682 chicks: Christopher Hicks
2683
2684 David E. Wheeler
2685
2686 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2687
2688 Drew Taylor
2689
2690 esskar: Sascha Kiefer
2691
2692 fireartist: Carl Franks <cfranks@cpan.org>
2693
2694 gabb: Danijel Milicevic
2695
2696 Gary Ashton Jones
2697
2698 Geoff Richards
2699
2700 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2701
2702 jcamacho: Juan Camacho
2703
2704 jhannah: Jay Hannah <jay@jays.net>
2705
2706 Jody Belka
2707
2708 Johan Lindstrom
2709
2710 jon: Jon Schutz <jjschutz@cpan.org>
2711
2712 marcus: Marcus Ramberg <mramberg@cpan.org>
2713
2714 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2715
2716 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2717
2718 mugwump: Sam Vilain
2719
2720 naughton: David Naughton
2721
2722 ningu: David Kamholz <dkamholz@cpan.org>
2723
2724 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2725
2726 numa: Dan Sully <daniel@cpan.org>
2727
2728 obra: Jesse Vincent
2729
2730 omega: Andreas Marienborg
2731
2732 Oleg Kostyuk <cub.uanic@gmail.com>
2733
2734 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2735
2736 rafl: Florian Ragwitz <rafl@debian.org>
2737
2738 sky: Arthur Bergman
2739
2740 the_jester: Jesse Sheidlower
2741
2742 t0m: Tomas Doran <bobtfish@bobtfish.net>
2743
2744 Ulf Edvinsson
2745
2746 willert: Sebastian Willert <willert@cpan.org>
2747
2748 =head1 LICENSE
2749
2750 This library is free software, you can redistribute it and/or modify it under
2751 the same terms as Perl itself.
2752
2753 =cut
2754
2755 no Moose;
2756
2757 __PACKAGE__->meta->make_immutable;
2758
2759 1;