lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Devel::InnerPackage ();
  18 use File::stat;
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use utf8;
  32 use Carp qw/croak carp shortmess/;
  33
  34 BEGIN { require 5.008004; }
  35
  36 has stack => (is => 'ro', default => sub { [] });
  37 has stash => (is => 'rw', default => sub { {} });
  38 has state => (is => 'rw', default => 0);
  39 has stats => (is => 'rw');
  40 has action => (is => 'rw');
  41 has counter => (is => 'rw', default => sub { {} });
  42 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  43 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  44 has namespace => (is => 'rw');
  45
  46 sub depth { scalar @{ shift->stack || [] }; }
  47 sub comp { shift->component(@_) }
  48
  49 sub req {
  50     my $self = shift; return $self->request(@_);
  51 }
  52 sub res {
  53     my $self = shift; return $self->response(@_);
  54 }
  55
  56 # For backwards compatibility
  57 sub finalize_output { shift->finalize_body(@_) };
  58
  59 # For statistics
  60 our $COUNT     = 1;
  61 our $START     = time;
  62 our $RECURSION = 1000;
  63 our $DETACH    = Catalyst::Exception::Detach->new;
  64 our $GO        = Catalyst::Exception::Go->new;
  65
  66 #I imagine that very few of these really need to be class variables. if any.
  67 #maybe we should just make them attributes with a default?
  68 __PACKAGE__->mk_classdata($_)
  69   for qw/components arguments dispatcher engine log dispatcher_class
  70   engine_class context_class request_class response_class stats_class
  71   setup_finished/;
  72
  73 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  74 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  75 __PACKAGE__->request_class('Catalyst::Request');
  76 __PACKAGE__->response_class('Catalyst::Response');
  77 __PACKAGE__->stats_class('Catalyst::Stats');
  78
  79 # Remember to update this in Catalyst::Runtime as well!
  80
  81 our $VERSION = '5.80018';
  82 $VERSION = eval $VERSION;
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 104     }
 105
 106     $caller->arguments( [@arguments] );
 107     $caller->setup_home;
 108 }
 109
 110 sub _application { $_[0] }
 111
 112 =head1 NAME
 113
 114 Catalyst - The Elegant MVC Web Application Framework
 115
 116 =head1 SYNOPSIS
 117
 118 See the L<Catalyst::Manual> distribution for comprehensive
 119 documentation and tutorials.
 120
 121     # Install Catalyst::Devel for helpers and other development tools
 122     # use the helper to create a new application
 123     catalyst.pl MyApp
 124
 125     # add models, views, controllers
 126     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 127     script/myapp_create.pl view MyTemplate TT
 128     script/myapp_create.pl controller Search
 129
 130     # built in testserver -- use -r to restart automatically on changes
 131     # --help to see all available options
 132     script/myapp_server.pl
 133
 134     # command line testing interface
 135     script/myapp_test.pl /yada
 136
 137     ### in lib/MyApp.pm
 138     use Catalyst qw/-Debug/; # include plugins here as well
 139
 140     ### In lib/MyApp/Controller/Root.pm (autocreated)
 141     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 142         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 143         $c->stash->{template} = 'foo.tt'; # set the template
 144         # lookup something from db -- stash vars are passed to TT
 145         $c->stash->{data} =
 146           $c->model('Database::Foo')->search( { country => $args[0] } );
 147         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 148             $c->forward( 'bar' ); # process another action
 149             # do something else after forward returns
 150         }
 151     }
 152
 153     # The foo.tt TT template can use the stash data from the database
 154     [% WHILE (item = data.next) %]
 155         [% item.foo %]
 156     [% END %]
 157
 158     # called for /bar/of/soap, /bar/of/soap/10, etc.
 159     sub bar : Path('/bar/of/soap') { ... }
 160
 161     # called for all actions, from the top-most controller downwards
 162     sub auto : Private {
 163         my ( $self, $c ) = @_;
 164         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 165             $c->res->redirect( '/login' ); # require login
 166             return 0; # abort request and go immediately to end()
 167         }
 168         return 1; # success; carry on to next action
 169     }
 170
 171     # called after all actions are finished
 172     sub end : Private {
 173         my ( $self, $c ) = @_;
 174         if ( scalar @{ $c->error } ) { ... } # handle errors
 175         return if $c->res->body; # already have a response
 176         $c->forward( 'MyApp::View::TT' ); # render template
 177     }
 178
 179     ### in MyApp/Controller/Foo.pm
 180     # called for /foo/bar
 181     sub bar : Local { ... }
 182
 183     # called for /blargle
 184     sub blargle : Global { ... }
 185
 186     # an index action matches /foo, but not /foo/1, etc.
 187     sub index : Private { ... }
 188
 189     ### in MyApp/Controller/Foo/Bar.pm
 190     # called for /foo/bar/baz
 191     sub baz : Local { ... }
 192
 193     # first Root auto is called, then Foo auto, then this
 194     sub auto : Private { ... }
 195
 196     # powerful regular expression paths are also possible
 197     sub details : Regex('^product/(\w+)/details$') {
 198         my ( $self, $c ) = @_;
 199         # extract the (\w+) from the URI
 200         my $product = $c->req->captures->[0];
 201     }
 202
 203 See L<Catalyst::Manual::Intro> for additional information.
 204
 205 =head1 DESCRIPTION
 206
 207 Catalyst is a modern framework for making web applications without the
 208 pain usually associated with this process. This document is a reference
 209 to the main Catalyst application. If you are a new user, we suggest you
 210 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 211
 212 See L<Catalyst::Manual> for more documentation.
 213
 214 Catalyst plugins can be loaded by naming them as arguments to the "use
 215 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 216 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 217 C<My::Module>.
 218
 219     use Catalyst qw/My::Module/;
 220
 221 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 222 fully qualify the name by using a unary plus:
 223
 224     use Catalyst qw/
 225         My::Module
 226         +Fully::Qualified::Plugin::Name
 227     /;
 228
 229 Special flags like C<-Debug> and C<-Engine> can also be specified as
 230 arguments when Catalyst is loaded:
 231
 232     use Catalyst qw/-Debug My::Module/;
 233
 234 The position of plugins and flags in the chain is important, because
 235 they are loaded in the order in which they appear.
 236
 237 The following flags are supported:
 238
 239 =head2 -Debug
 240
 241 Enables debug output. You can also force this setting from the system
 242 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 243 settings override the application, with <MYAPP>_DEBUG having the highest
 244 priority.
 245
 246 =head2 -Engine
 247
 248 Forces Catalyst to use a specific engine. Omit the
 249 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 250
 251     use Catalyst qw/-Engine=CGI/;
 252
 253 =head2 -Home
 254
 255 Forces Catalyst to use a specific home directory, e.g.:
 256
 257     use Catalyst qw[-Home=/usr/mst];
 258
 259 This can also be done in the shell environment by setting either the
 260 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 261 is replaced with the uppercased name of your application, any "::" in
 262 the name will be replaced with underscores, e.g. MyApp::Web should use
 263 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 264
 265 =head2 -Log
 266
 267     use Catalyst '-Log=warn,fatal,error';
 268
 269 Specifies a comma-delimited list of log levels.
 270
 271 =head2 -Stats
 272
 273 Enables statistics collection and reporting. You can also force this setting
 274 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 275 environment settings override the application, with <MYAPP>_STATS having the
 276 highest priority.
 277
 278 e.g.
 279
 280    use Catalyst qw/-Stats=1/
 281
 282 =head1 METHODS
 283
 284 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 285
 286 =head2 $c->action
 287
 288 Returns a L<Catalyst::Action> object for the current action, which
 289 stringifies to the action name. See L<Catalyst::Action>.
 290
 291 =head2 $c->namespace
 292
 293 Returns the namespace of the current action, i.e., the URI prefix
 294 corresponding to the controller of the current action. For example:
 295
 296     # in Controller::Foo::Bar
 297     $c->namespace; # returns 'foo/bar';
 298
 299 =head2 $c->request
 300
 301 =head2 $c->req
 302
 303 Returns the current L<Catalyst::Request> object, giving access to
 304 information about the current client request (including parameters,
 305 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 306
 307 =head2 REQUEST FLOW HANDLING
 308
 309 =head2 $c->forward( $action [, \@arguments ] )
 310
 311 =head2 $c->forward( $class, $method, [, \@arguments ] )
 312
 313 Forwards processing to another action, by its private name. If you give a
 314 class name but no method, C<process()> is called. You may also optionally
 315 pass arguments in an arrayref. The action will receive the arguments in
 316 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 317 C<< $c->req->args >> will be restored to the previous values.
 318
 319 Any data C<return>ed from the action forwarded to, will be returned by the
 320 call to forward.
 321
 322     my $foodata = $c->forward('/foo');
 323     $c->forward('index');
 324     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 325     $c->forward('View::TT');
 326
 327 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 328 an C<< eval { } >> around the call (actually
 329 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 330 all 'dies' within the called action. If you want C<die> to propagate you
 331 need to do something like:
 332
 333     $c->forward('foo');
 334     die join "\n", @{ $c->error } if @{ $c->error };
 335
 336 Or make sure to always return true values from your actions and write
 337 your code like this:
 338
 339     $c->forward('foo') || return;
 340
 341 Another note is that C<< $c->forward >> always returns a scalar because it
 342 actually returns $c->state which operates in a scalar context.
 343 Thus, something like:
 344
 345     return @array;
 346
 347 in an action that is forwarded to is going to return a scalar,
 348 i.e. how many items are in that array, which is probably not what you want.
 349 If you need to return an array then return a reference to it,
 350 or stash it like so:
 351
 352     $c->stash->{array} = \@array;
 353
 354 and access it from the stash.
 355
 356 =cut
 357
 358 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 359
 360 =head2 $c->detach( $action [, \@arguments ] )
 361
 362 =head2 $c->detach( $class, $method, [, \@arguments ] )
 363
 364 =head2 $c->detach()
 365
 366 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 367 doesn't return to the previous action when processing is finished.
 368
 369 When called with no arguments it escapes the processing chain entirely.
 370
 371 =cut
 372
 373 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 374
 375 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 376
 377 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 378
 379 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 380 but does a full dispatch, instead of just calling the new C<$action> /
 381 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 382 you go to are called, just like a new request.
 383
 384 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 385 This means, for example, that C<< $c->action >> methods such as
 386 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 387 L<reverse|Catalyst::Action/reverse> return information for the visited action
 388 when they are invoked within the visited action.  This is different from the
 389 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 390 continues to use the $c->action object from the caller action even when
 391 invoked from the callee.
 392
 393 C<< $c->stash >> is kept unchanged.
 394
 395 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 396 allows you to "wrap" another action, just as it would have been called by
 397 dispatching from a URL, while the analogous
 398 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 399 transfer control to another action as if it had been reached directly from a URL.
 400
 401 =cut
 402
 403 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 404
 405 =head2 $c->go( $action [, \@captures, \@arguments ] )
 406
 407 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 408
 409 The relationship between C<go> and
 410 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 411 the relationship between
 412 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 413 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 414 C<< $c->go >> will perform a full dispatch on the specified action or method,
 415 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 416 C<go> escapes the processing of the current request chain on completion, and
 417 does not return to its caller.
 418
 419 =cut
 420
 421 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 422
 423 =head2 $c->response
 424
 425 =head2 $c->res
 426
 427 Returns the current L<Catalyst::Response> object, see there for details.
 428
 429 =head2 $c->stash
 430
 431 Returns a hashref to the stash, which may be used to store data and pass
 432 it between components during a request. You can also set hash keys by
 433 passing arguments. The stash is automatically sent to the view. The
 434 stash is cleared at the end of a request; it cannot be used for
 435 persistent storage (for this you must use a session; see
 436 L<Catalyst::Plugin::Session> for a complete system integrated with
 437 Catalyst).
 438
 439     $c->stash->{foo} = $bar;
 440     $c->stash( { moose => 'majestic', qux => 0 } );
 441     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 442
 443     # stash is automatically passed to the view for use in a template
 444     $c->forward( 'MyApp::View::TT' );
 445
 446 =cut
 447
 448 around stash => sub {
 449     my $orig = shift;
 450     my $c = shift;
 451     my $stash = $orig->($c);
 452     if (@_) {
 453         my $new_stash = @_ > 1 ? {@_} : $_[0];
 454         croak('stash takes a hash or hashref') unless ref $new_stash;
 455         foreach my $key ( keys %$new_stash ) {
 456           $stash->{$key} = $new_stash->{$key};
 457         }
 458     }
 459
 460     return $stash;
 461 };
 462
 463
 464 =head2 $c->error
 465
 466 =head2 $c->error($error, ...)
 467
 468 =head2 $c->error($arrayref)
 469
 470 Returns an arrayref containing error messages.  If Catalyst encounters an
 471 error while processing a request, it stores the error in $c->error.  This
 472 method should only be used to store fatal error messages.
 473
 474     my @error = @{ $c->error };
 475
 476 Add a new error.
 477
 478     $c->error('Something bad happened');
 479
 480 =cut
 481
 482 sub error {
 483     my $c = shift;
 484     if ( $_[0] ) {
 485         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 486         croak @$error unless ref $c;
 487         push @{ $c->{error} }, @$error;
 488     }
 489     elsif ( defined $_[0] ) { $c->{error} = undef }
 490     return $c->{error} || [];
 491 }
 492
 493
 494 =head2 $c->state
 495
 496 Contains the return value of the last executed action.
 497 Note that << $c->state >> operates in a scalar context which means that all
 498 values it returns are scalar.
 499
 500 =head2 $c->clear_errors
 501
 502 Clear errors.  You probably don't want to clear the errors unless you are
 503 implementing a custom error screen.
 504
 505 This is equivalent to running
 506
 507     $c->error(0);
 508
 509 =cut
 510
 511 sub clear_errors {
 512     my $c = shift;
 513     $c->error(0);
 514 }
 515
 516 sub _comp_search_prefixes {
 517     my $c = shift;
 518     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 519 }
 520
 521 # search components given a name and some prefixes
 522 sub _comp_names_search_prefixes {
 523     my ( $c, $name, @prefixes ) = @_;
 524     my $appclass = ref $c || $c;
 525     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 526     $filter = qr/$filter/; # Compile regex now rather than once per loop
 527
 528     # map the original component name to the sub part that we will search against
 529     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 530         grep { /$filter/ } keys %{ $c->components };
 531
 532     # undef for a name will return all
 533     return keys %eligible if !defined $name;
 534
 535     my $query  = ref $name ? $name : qr/^$name$/i;
 536     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 537
 538     return @result if @result;
 539
 540     # if we were given a regexp to search against, we're done.
 541     return if ref $name;
 542
 543     # skip regexp fallback if configured
 544     return
 545         if $appclass->config->{disable_component_resolution_regex_fallback};
 546
 547     # regexp fallback
 548     $query  = qr/$name/i;
 549     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 550
 551     # no results? try against full names
 552     if( !@result ) {
 553         @result = grep { m{$query} } keys %eligible;
 554     }
 555
 556     # don't warn if we didn't find any results, it just might not exist
 557     if( @result ) {
 558         # Disgusting hack to work out correct method name
 559         my $warn_for = lc $prefixes[0];
 560         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 561            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 562            "component resolution is unreliable and unsafe.";
 563         my $short = $result[0];
 564         # remove the component namespace prefix
 565         $short =~ s/.*?(Model|Controller|View):://;
 566         my $shortmess = Carp::shortmess('');
 567         if ($shortmess =~ m#Catalyst/Plugin#) {
 568            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 569               "plugin's config";
 570         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 571            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 572               "component's config";
 573         } else {
 574            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 575               "but if you really wanted to search, pass in a regexp as the argument " .
 576               "like so: \$c->${warn_for}(qr/${name}/)";
 577         }
 578         $c->log->warn( "${msg}$shortmess" );
 579     }
 580
 581     return @result;
 582 }
 583
 584 # Find possible names for a prefix
 585 sub _comp_names {
 586     my ( $c, @prefixes ) = @_;
 587     my $appclass = ref $c || $c;
 588
 589     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 590
 591     my @names = map { s{$filter}{}; $_; }
 592         $c->_comp_names_search_prefixes( undef, @prefixes );
 593
 594     return @names;
 595 }
 596
 597 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 598 sub _filter_component {
 599     my ( $c, $comp, @args ) = @_;
 600
 601     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 602         return $comp->ACCEPT_CONTEXT( $c, @args );
 603     }
 604
 605     return $comp;
 606 }
 607
 608 =head2 COMPONENT ACCESSORS
 609
 610 =head2 $c->controller($name)
 611
 612 Gets a L<Catalyst::Controller> instance by name.
 613
 614     $c->controller('Foo')->do_stuff;
 615
 616 If the name is omitted, will return the controller for the dispatched
 617 action.
 618
 619 If you want to search for controllers, pass in a regexp as the argument.
 620
 621     # find all controllers that start with Foo
 622     my @foo_controllers = $c->controller(qr{^Foo});
 623
 624
 625 =cut
 626
 627 sub controller {
 628     my ( $c, $name, @args ) = @_;
 629
 630     if( $name ) {
 631         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 632         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 633         return $c->_filter_component( $result[ 0 ], @args );
 634     }
 635
 636     return $c->component( $c->action->class );
 637 }
 638
 639 =head2 $c->model($name)
 640
 641 Gets a L<Catalyst::Model> instance by name.
 642
 643     $c->model('Foo')->do_stuff;
 644
 645 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 646
 647 If the name is omitted, it will look for
 648  - a model object in $c->stash->{current_model_instance}, then
 649  - a model name in $c->stash->{current_model}, then
 650  - a config setting 'default_model', or
 651  - check if there is only one model, and return it if that's the case.
 652
 653 If you want to search for models, pass in a regexp as the argument.
 654
 655     # find all models that start with Foo
 656     my @foo_models = $c->model(qr{^Foo});
 657
 658 =cut
 659
 660 sub model {
 661     my ( $c, $name, @args ) = @_;
 662     my $appclass = ref($c) || $c;
 663     if( $name ) {
 664         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 665         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 666         return $c->_filter_component( $result[ 0 ], @args );
 667     }
 668
 669     if (ref $c) {
 670         return $c->stash->{current_model_instance}
 671           if $c->stash->{current_model_instance};
 672         return $c->model( $c->stash->{current_model} )
 673           if $c->stash->{current_model};
 674     }
 675     return $c->model( $appclass->config->{default_model} )
 676       if $appclass->config->{default_model};
 677
 678     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 679
 680     if( $rest ) {
 681         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 682         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 683         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 684         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 685         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 686     }
 687
 688     return $c->_filter_component( $comp );
 689 }
 690
 691
 692 =head2 $c->view($name)
 693
 694 Gets a L<Catalyst::View> instance by name.
 695
 696     $c->view('Foo')->do_stuff;
 697
 698 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 699
 700 If the name is omitted, it will look for
 701  - a view object in $c->stash->{current_view_instance}, then
 702  - a view name in $c->stash->{current_view}, then
 703  - a config setting 'default_view', or
 704  - check if there is only one view, and return it if that's the case.
 705
 706 If you want to search for views, pass in a regexp as the argument.
 707
 708     # find all views that start with Foo
 709     my @foo_views = $c->view(qr{^Foo});
 710
 711 =cut
 712
 713 sub view {
 714     my ( $c, $name, @args ) = @_;
 715
 716     my $appclass = ref($c) || $c;
 717     if( $name ) {
 718         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 719         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 720         return $c->_filter_component( $result[ 0 ], @args );
 721     }
 722
 723     if (ref $c) {
 724         return $c->stash->{current_view_instance}
 725           if $c->stash->{current_view_instance};
 726         return $c->view( $c->stash->{current_view} )
 727           if $c->stash->{current_view};
 728     }
 729     return $c->view( $appclass->config->{default_view} )
 730       if $appclass->config->{default_view};
 731
 732     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 733
 734     if( $rest ) {
 735         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 736         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 737         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 738         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 739         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 740     }
 741
 742     return $c->_filter_component( $comp );
 743 }
 744
 745 =head2 $c->controllers
 746
 747 Returns the available names which can be passed to $c->controller
 748
 749 =cut
 750
 751 sub controllers {
 752     my ( $c ) = @_;
 753     return $c->_comp_names(qw/Controller C/);
 754 }
 755
 756 =head2 $c->models
 757
 758 Returns the available names which can be passed to $c->model
 759
 760 =cut
 761
 762 sub models {
 763     my ( $c ) = @_;
 764     return $c->_comp_names(qw/Model M/);
 765 }
 766
 767
 768 =head2 $c->views
 769
 770 Returns the available names which can be passed to $c->view
 771
 772 =cut
 773
 774 sub views {
 775     my ( $c ) = @_;
 776     return $c->_comp_names(qw/View V/);
 777 }
 778
 779 =head2 $c->comp($name)
 780
 781 =head2 $c->component($name)
 782
 783 Gets a component object by name. This method is not recommended,
 784 unless you want to get a specific component by full
 785 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 786 should be used instead.
 787
 788 If C<$name> is a regexp, a list of components matched against the full
 789 component name will be returned.
 790
 791 If Catalyst can't find a component by name, it will fallback to regex
 792 matching by default. To disable this behaviour set
 793 disable_component_resolution_regex_fallback to a true value.
 794
 795     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 796
 797 =cut
 798
 799 sub component {
 800     my ( $c, $name, @args ) = @_;
 801
 802     if( $name ) {
 803         my $comps = $c->components;
 804
 805         if( !ref $name ) {
 806             # is it the exact name?
 807             return $c->_filter_component( $comps->{ $name }, @args )
 808                        if exists $comps->{ $name };
 809
 810             # perhaps we just omitted "MyApp"?
 811             my $composed = ( ref $c || $c ) . "::${name}";
 812             return $c->_filter_component( $comps->{ $composed }, @args )
 813                        if exists $comps->{ $composed };
 814
 815             # search all of the models, views and controllers
 816             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 817             return $c->_filter_component( $comp, @args ) if $comp;
 818         }
 819
 820         # This is here so $c->comp( '::M::' ) works
 821         my $query = ref $name ? $name : qr{$name}i;
 822
 823         my @result = grep { m{$query} } keys %{ $c->components };
 824         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 825
 826         if( $result[ 0 ] ) {
 827             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 828             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 829             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 830             return $c->_filter_component( $result[ 0 ], @args );
 831         }
 832
 833         # I would expect to return an empty list here, but that breaks back-compat
 834     }
 835
 836     # fallback
 837     return sort keys %{ $c->components };
 838 }
 839
 840 =head2 CLASS DATA AND HELPER CLASSES
 841
 842 =head2 $c->config
 843
 844 Returns or takes a hashref containing the application's configuration.
 845
 846     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 847
 848 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 849 like C<myapp.conf> in your applications home directory. See
 850 L<Catalyst::Plugin::ConfigLoader>.
 851
 852 =head3 Cascading configuration
 853
 854 The config method is present on all Catalyst components, and configuration
 855 will be merged when an application is started. Configuration loaded with
 856 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 857 followed by configuration in your top level C<MyApp> class. These two
 858 configurations are merged, and then configuration data whose hash key matches a
 859 component name is merged with configuration for that component.
 860
 861 The configuration for a component is then passed to the C<new> method when a
 862 component is constructed.
 863
 864 For example:
 865
 866     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 867     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 868
 869 will mean that C<MyApp::Model::Foo> receives the following data when
 870 constructed:
 871
 872     MyApp::Model::Foo->new({
 873         bar => 'baz',
 874         quux => 'frob',
 875         overrides => 'me',
 876     });
 877
 878 =cut
 879
 880 around config => sub {
 881     my $orig = shift;
 882     my $c = shift;
 883
 884     croak('Setting config after setup has been run is not allowed.')
 885         if ( @_ and $c->setup_finished );
 886
 887     $c->$orig(@_);
 888 };
 889
 890 =head2 $c->log
 891
 892 Returns the logging object instance. Unless it is already set, Catalyst
 893 sets this up with a L<Catalyst::Log> object. To use your own log class,
 894 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 895 C<< __PACKAGE__->setup >>.
 896
 897  __PACKAGE__->log( MyLogger->new );
 898  __PACKAGE__->setup;
 899
 900 And later:
 901
 902     $c->log->info( 'Now logging with my own logger!' );
 903
 904 Your log class should implement the methods described in
 905 L<Catalyst::Log>.
 906
 907
 908 =head2 $c->debug
 909
 910 Returns 1 if debug mode is enabled, 0 otherwise.
 911
 912 You can enable debug mode in several ways:
 913
 914 =over
 915
 916 =item By calling myapp_server.pl with the -d flag
 917
 918 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 919
 920 =item The -Debug option in your MyApp.pm
 921
 922 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 923
 924 =back
 925
 926 Calling C<< $c->debug(1) >> has no effect.
 927
 928 =cut
 929
 930 sub debug { 0 }
 931
 932 =head2 $c->dispatcher
 933
 934 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 935
 936 =head2 $c->engine
 937
 938 Returns the engine instance. See L<Catalyst::Engine>.
 939
 940
 941 =head2 UTILITY METHODS
 942
 943 =head2 $c->path_to(@path)
 944
 945 Merges C<@path> with C<< $c->config->{home} >> and returns a
 946 L<Path::Class::Dir> object. Note you can usually use this object as
 947 a filename, but sometimes you will have to explicitly stringify it
 948 yourself by calling the C<< ->stringify >> method.
 949
 950 For example:
 951
 952     $c->path_to( 'db', 'sqlite.db' );
 953
 954 =cut
 955
 956 sub path_to {
 957     my ( $c, @path ) = @_;
 958     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 959     if ( -d $path ) { return $path }
 960     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 961 }
 962
 963 =head2 $c->plugin( $name, $class, @args )
 964
 965 Helper method for plugins. It creates a class data accessor/mutator and
 966 loads and instantiates the given class.
 967
 968     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 969
 970     $c->prototype->define_javascript_functions;
 971
 972 B<Note:> This method of adding plugins is deprecated. The ability
 973 to add plugins like this B<will be removed> in a Catalyst 5.81.
 974 Please do not use this functionality in new code.
 975
 976 =cut
 977
 978 sub plugin {
 979     my ( $class, $name, $plugin, @args ) = @_;
 980
 981     # See block comment in t/unit_core_plugin.t
 982     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 983
 984     $class->_register_plugin( $plugin, 1 );
 985
 986     eval { $plugin->import };
 987     $class->mk_classdata($name);
 988     my $obj;
 989     eval { $obj = $plugin->new(@args) };
 990
 991     if ($@) {
 992         Catalyst::Exception->throw( message =>
 993               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 994     }
 995
 996     $class->$name($obj);
 997     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 998       if $class->debug;
 999 }
1000
1001 =head2 MyApp->setup
1002
1003 Initializes the dispatcher and engine, loads any plugins, and loads the
1004 model, view, and controller components. You may also specify an array
1005 of plugins to load here, if you choose to not load them in the C<use
1006 Catalyst> line.
1007
1008     MyApp->setup;
1009     MyApp->setup( qw/-Debug/ );
1010
1011 =cut
1012
1013 sub setup {
1014     my ( $class, @arguments ) = @_;
1015     croak('Running setup more than once')
1016         if ( $class->setup_finished );
1017
1018     unless ( $class->isa('Catalyst') ) {
1019
1020         Catalyst::Exception->throw(
1021             message => qq/'$class' does not inherit from Catalyst/ );
1022     }
1023
1024     if ( $class->arguments ) {
1025         @arguments = ( @arguments, @{ $class->arguments } );
1026     }
1027
1028     # Process options
1029     my $flags = {};
1030
1031     foreach (@arguments) {
1032
1033         if (/^-Debug$/) {
1034             $flags->{log} =
1035               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1036         }
1037         elsif (/^-(\w+)=?(.*)$/) {
1038             $flags->{ lc $1 } = $2;
1039         }
1040         else {
1041             push @{ $flags->{plugins} }, $_;
1042         }
1043     }
1044
1045     $class->setup_home( delete $flags->{home} );
1046
1047     $class->setup_log( delete $flags->{log} );
1048     $class->setup_plugins( delete $flags->{plugins} );
1049     $class->setup_dispatcher( delete $flags->{dispatcher} );
1050     $class->setup_engine( delete $flags->{engine} );
1051     $class->setup_stats( delete $flags->{stats} );
1052
1053     for my $flag ( sort keys %{$flags} ) {
1054
1055         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1056             &$code( $class, delete $flags->{$flag} );
1057         }
1058         else {
1059             $class->log->warn(qq/Unknown flag "$flag"/);
1060         }
1061     }
1062
1063     eval { require Catalyst::Devel; };
1064     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1065         $class->log->warn(<<"EOF");
1066 You are running an old script!
1067
1068   Please update by running (this will overwrite existing files):
1069     catalyst.pl -force -scripts $class
1070
1071   or (this will not overwrite existing files):
1072     catalyst.pl -scripts $class
1073
1074 EOF
1075     }
1076
1077     if ( $class->debug ) {
1078         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1079
1080         if (@plugins) {
1081             my $column_width = Catalyst::Utils::term_width() - 6;
1082             my $t = Text::SimpleTable->new($column_width);
1083             $t->row($_) for @plugins;
1084             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1085         }
1086
1087         my $dispatcher = $class->dispatcher;
1088         my $engine     = $class->engine;
1089         my $home       = $class->config->{home};
1090
1091         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1092         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1093
1094         $home
1095           ? ( -d $home )
1096           ? $class->log->debug(qq/Found home "$home"/)
1097           : $class->log->debug(qq/Home "$home" doesn't exist/)
1098           : $class->log->debug(q/Couldn't find home/);
1099     }
1100
1101     # Call plugins setup, this is stupid and evil.
1102     # Also screws C3 badly on 5.10, hack to avoid.
1103     {
1104         no warnings qw/redefine/;
1105         local *setup = sub { };
1106         $class->setup unless $Catalyst::__AM_RESTARTING;
1107     }
1108
1109     # Initialize our data structure
1110     $class->components( {} );
1111
1112     $class->setup_components;
1113
1114     if ( $class->debug ) {
1115         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1116         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1117         for my $comp ( sort keys %{ $class->components } ) {
1118             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1119             $t->row( $comp, $type );
1120         }
1121         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1122           if ( keys %{ $class->components } );
1123     }
1124
1125     # Add our self to components, since we are also a component
1126     if( $class->isa('Catalyst::Controller') ){
1127       $class->components->{$class} = $class;
1128     }
1129
1130     $class->setup_actions;
1131
1132     if ( $class->debug ) {
1133         my $name = $class->config->{name} || 'Application';
1134         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1135     }
1136
1137     # Make sure that the application class becomes immutable at this point,
1138     B::Hooks::EndOfScope::on_scope_end {
1139         return if $@;
1140         my $meta = Class::MOP::get_metaclass_by_name($class);
1141         if (
1142             $meta->is_immutable
1143             && ! { $meta->immutable_options }->{replace_constructor}
1144             && (
1145                    $class->isa('Class::Accessor::Fast')
1146                 || $class->isa('Class::Accessor')
1147             )
1148         ) {
1149             warn "You made your application class ($class) immutable, "
1150                 . "but did not inline the\nconstructor. "
1151                 . "This will break catalyst, as your app \@ISA "
1152                 . "Class::Accessor(::Fast)?\nPlease pass "
1153                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1154         }
1155         $meta->make_immutable(
1156             replace_constructor => 1,
1157         ) unless $meta->is_immutable;
1158     };
1159
1160     if ($class->config->{case_sensitive}) {
1161         $class->log->warn($class . "->config->{case_sensitive} is set.");
1162         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1163     }
1164
1165     $class->setup_finalize;
1166     # Should be the last thing we do so that user things hooking
1167     # setup_finalize can log..
1168     $class->log->_flush() if $class->log->can('_flush');
1169     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1170 }
1171
1172
1173 =head2 $app->setup_finalize
1174
1175 A hook to attach modifiers to.
1176 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1177 Also better than C< setup_finished(); >, as that is a getter method.
1178
1179     sub setup_finalize {
1180
1181         my $app = shift;
1182
1183         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1184
1185         $app->next::method(@_);
1186
1187
1188     }
1189
1190 =cut
1191
1192 sub setup_finalize {
1193     my ($class) = @_;
1194     $class->setup_finished(1);
1195 }
1196
1197 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1198
1199 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1200
1201 Constructs an absolute L<URI> object based on the application root, the
1202 provided path, and the additional arguments and query parameters provided.
1203 When used as a string, provides a textual URI.
1204
1205 If no arguments are provided, the URI for the current action is returned.
1206 To return the current action and also provide @args, use
1207 C<< $c->uri_for( $c->action, @args ) >>.
1208
1209 If the first argument is a string, it is taken as a public URI path relative
1210 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1211 relative to the application root (if it does). It is then merged with
1212 C<< $c->request->base >>; any C<@args> are appended as additional path
1213 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1214
1215 If the first argument is a L<Catalyst::Action> it represents an action which
1216 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1217 optional C<\@captures> argument (an arrayref) allows passing the captured
1218 variables that are needed to fill in the paths of Chained and Regex actions;
1219 once the path is resolved, C<uri_for> continues as though a path was
1220 provided, appending any arguments or parameters and creating an absolute
1221 URI.
1222
1223 The captures for the current request can be found in
1224 C<< $c->request->captures >>, and actions can be resolved using
1225 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1226 path, use C<< $c->uri_for_action >> instead.
1227
1228   # Equivalent to $c->req->uri
1229   $c->uri_for($c->action, $c->req->captures,
1230       @{ $c->req->args }, $c->req->params);
1231
1232   # For the Foo action in the Bar controller
1233   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1234
1235   # Path to a static resource
1236   $c->uri_for('/static/images/logo.png');
1237
1238 =cut
1239
1240 sub uri_for {
1241     my ( $c, $path, @args ) = @_;
1242
1243     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1244         $path = $path->path_prefix;
1245         $path =~ s{/+\z}{};
1246         $path .= '/';
1247     }
1248
1249     if ( blessed($path) ) { # action object
1250         my $captures = [ map { s|/|%2F|; $_; }
1251                         ( scalar @args && ref $args[0] eq 'ARRAY'
1252                          ? @{ shift(@args) }
1253                          : ()) ];
1254         my $action = $path;
1255         $path = $c->dispatcher->uri_for_action($action, $captures);
1256         if (not defined $path) {
1257             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1258                 if $c->debug;
1259             return undef;
1260         }
1261         $path = '/' if $path eq '';
1262     }
1263
1264     undef($path) if (defined $path && $path eq '');
1265
1266     my $params =
1267       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1268
1269     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1270     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1271     s|/|%2F| for @args;
1272
1273     unshift(@args, $path);
1274
1275     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1276         my $namespace = $c->namespace;
1277         if (defined $path) { # cheesy hack to handle path '../foo'
1278            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1279         }
1280         unshift(@args, $namespace || '');
1281     }
1282
1283     # join args with '/', or a blank string
1284     my $args = join('/', grep { defined($_) } @args);
1285     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1286     $args =~ s!^/+!!;
1287     my $base = $c->req->base;
1288     my $class = ref($base);
1289     $base =~ s{(?<!/)$}{/};
1290
1291     my $query = '';
1292
1293     if (my @keys = keys %$params) {
1294       # somewhat lifted from URI::_query's query_form
1295       $query = '?'.join('&', map {
1296           my $val = $params->{$_};
1297           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1298           s/ /+/g;
1299           my $key = $_;
1300           $val = '' unless defined $val;
1301           (map {
1302               my $param = "$_";
1303               utf8::encode( $param ) if utf8::is_utf8($param);
1304               # using the URI::Escape pattern here so utf8 chars survive
1305               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1306               $param =~ s/ /+/g;
1307               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1308       } @keys);
1309     }
1310
1311     my $res = bless(\"${base}${args}${query}", $class);
1312     $res;
1313 }
1314
1315 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1316
1317 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1318
1319 =over
1320
1321 =item $path
1322
1323 A private path to the Catalyst action you want to create a URI for.
1324
1325 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1326 >> and passing the resulting C<$action> and the remaining arguments to C<<
1327 $c->uri_for >>.
1328
1329 You can also pass in a Catalyst::Action object, in which case it is passed to
1330 C<< $c->uri_for >>.
1331
1332 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1333
1334 For example, if the action looks like:
1335
1336  package MyApp::Controller::Users;
1337
1338  sub lst : Path('the-list') {}
1339
1340 You can use:
1341
1342  $c->uri_for_action('/users/lst')
1343
1344 and it will create the URI /users/the-list.
1345
1346 =back
1347
1348 =cut
1349
1350 sub uri_for_action {
1351     my ( $c, $path, @args ) = @_;
1352     my $action = blessed($path)
1353       ? $path
1354       : $c->dispatcher->get_action_by_path($path);
1355     unless (defined $action) {
1356       croak "Can't find action for path '$path'";
1357     }
1358     return $c->uri_for( $action, @args );
1359 }
1360
1361 =head2 $c->welcome_message
1362
1363 Returns the Catalyst welcome HTML page.
1364
1365 =cut
1366
1367 sub welcome_message {
1368     my $c      = shift;
1369     my $name   = $c->config->{name};
1370     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1371     my $prefix = Catalyst::Utils::appprefix( ref $c );
1372     $c->response->content_type('text/html; charset=utf-8');
1373     return <<"EOF";
1374 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1375     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1376 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1377     <head>
1378     <meta http-equiv="Content-Language" content="en" />
1379     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1380         <title>$name on Catalyst $VERSION</title>
1381         <style type="text/css">
1382             body {
1383                 color: #000;
1384                 background-color: #eee;
1385             }
1386             div#content {
1387                 width: 640px;
1388                 margin-left: auto;
1389                 margin-right: auto;
1390                 margin-top: 10px;
1391                 margin-bottom: 10px;
1392                 text-align: left;
1393                 background-color: #ccc;
1394                 border: 1px solid #aaa;
1395             }
1396             p, h1, h2 {
1397                 margin-left: 20px;
1398                 margin-right: 20px;
1399                 font-family: verdana, tahoma, sans-serif;
1400             }
1401             a {
1402                 font-family: verdana, tahoma, sans-serif;
1403             }
1404             :link, :visited {
1405                     text-decoration: none;
1406                     color: #b00;
1407                     border-bottom: 1px dotted #bbb;
1408             }
1409             :link:hover, :visited:hover {
1410                     color: #555;
1411             }
1412             div#topbar {
1413                 margin: 0px;
1414             }
1415             pre {
1416                 margin: 10px;
1417                 padding: 8px;
1418             }
1419             div#answers {
1420                 padding: 8px;
1421                 margin: 10px;
1422                 background-color: #fff;
1423                 border: 1px solid #aaa;
1424             }
1425             h1 {
1426                 font-size: 0.9em;
1427                 font-weight: normal;
1428                 text-align: center;
1429             }
1430             h2 {
1431                 font-size: 1.0em;
1432             }
1433             p {
1434                 font-size: 0.9em;
1435             }
1436             p img {
1437                 float: right;
1438                 margin-left: 10px;
1439             }
1440             span#appname {
1441                 font-weight: bold;
1442                 font-size: 1.6em;
1443             }
1444         </style>
1445     </head>
1446     <body>
1447         <div id="content">
1448             <div id="topbar">
1449                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1450                     $VERSION</h1>
1451              </div>
1452              <div id="answers">
1453                  <p>
1454                  <img src="$logo" alt="Catalyst Logo" />
1455                  </p>
1456                  <p>Welcome to the  world of Catalyst.
1457                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1458                     framework will make web development something you had
1459                     never expected it to be: Fun, rewarding, and quick.</p>
1460                  <h2>What to do now?</h2>
1461                  <p>That really depends  on what <b>you</b> want to do.
1462                     We do, however, provide you with a few starting points.</p>
1463                  <p>If you want to jump right into web development with Catalyst
1464                     you might want to start with a tutorial.</p>
1465 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1466 </pre>
1467 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1468 <pre>
1469 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1470 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1471 </code></pre>
1472                  <h2>What to do next?</h2>
1473                  <p>Next it's time to write an actual application. Use the
1474                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1475                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1476                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1477                     they can save you a lot of work.</p>
1478                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1479                     <p>Also, be sure to check out the vast and growing
1480                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1481                     you are likely to find what you need there.
1482                     </p>
1483
1484                  <h2>Need help?</h2>
1485                  <p>Catalyst has a very active community. Here are the main places to
1486                     get in touch with us.</p>
1487                  <ul>
1488                      <li>
1489                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1490                      </li>
1491                      <li>
1492                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1493                      </li>
1494                      <li>
1495                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1496                      </li>
1497                  </ul>
1498                  <h2>In conclusion</h2>
1499                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1500                     as we enjoyed making it. Please contact us if you have ideas
1501                     for improvement or other feedback.</p>
1502              </div>
1503          </div>
1504     </body>
1505 </html>
1506 EOF
1507 }
1508
1509 =head1 INTERNAL METHODS
1510
1511 These methods are not meant to be used by end users.
1512
1513 =head2 $c->components
1514
1515 Returns a hash of components.
1516
1517 =head2 $c->context_class
1518
1519 Returns or sets the context class.
1520
1521 =head2 $c->counter
1522
1523 Returns a hashref containing coderefs and execution counts (needed for
1524 deep recursion detection).
1525
1526 =head2 $c->depth
1527
1528 Returns the number of actions on the current internal execution stack.
1529
1530 =head2 $c->dispatch
1531
1532 Dispatches a request to actions.
1533
1534 =cut
1535
1536 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1537
1538 =head2 $c->dispatcher_class
1539
1540 Returns or sets the dispatcher class.
1541
1542 =head2 $c->dump_these
1543
1544 Returns a list of 2-element array references (name, structure) pairs
1545 that will be dumped on the error page in debug mode.
1546
1547 =cut
1548
1549 sub dump_these {
1550     my $c = shift;
1551     [ Request => $c->req ],
1552     [ Response => $c->res ],
1553     [ Stash => $c->stash ],
1554     [ Config => $c->config ];
1555 }
1556
1557 =head2 $c->engine_class
1558
1559 Returns or sets the engine class.
1560
1561 =head2 $c->execute( $class, $coderef )
1562
1563 Execute a coderef in given class and catch exceptions. Errors are available
1564 via $c->error.
1565
1566 =cut
1567
1568 sub execute {
1569     my ( $c, $class, $code ) = @_;
1570     $class = $c->component($class) || $class;
1571     $c->state(0);
1572
1573     if ( $c->depth >= $RECURSION ) {
1574         my $action = $code->reverse();
1575         $action = "/$action" unless $action =~ /->/;
1576         my $error = qq/Deep recursion detected calling "${action}"/;
1577         $c->log->error($error);
1578         $c->error($error);
1579         $c->state(0);
1580         return $c->state;
1581     }
1582
1583     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1584
1585     push( @{ $c->stack }, $code );
1586
1587     no warnings 'recursion';
1588     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1589
1590     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1591
1592     my $last = pop( @{ $c->stack } );
1593
1594     if ( my $error = $@ ) {
1595         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1596             $error->rethrow if $c->depth > 1;
1597         }
1598         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1599             $error->rethrow if $c->depth > 0;
1600         }
1601         else {
1602             unless ( ref $error ) {
1603                 no warnings 'uninitialized';
1604                 chomp $error;
1605                 my $class = $last->class;
1606                 my $name  = $last->name;
1607                 $error = qq/Caught exception in $class->$name "$error"/;
1608             }
1609             $c->error($error);
1610             $c->state(0);
1611         }
1612     }
1613     return $c->state;
1614 }
1615
1616 sub _stats_start_execute {
1617     my ( $c, $code ) = @_;
1618     my $appclass = ref($c) || $c;
1619     return if ( ( $code->name =~ /^_.*/ )
1620         && ( !$appclass->config->{show_internal_actions} ) );
1621
1622     my $action_name = $code->reverse();
1623     $c->counter->{$action_name}++;
1624
1625     my $action = $action_name;
1626     $action = "/$action" unless $action =~ /->/;
1627
1628     # determine if the call was the result of a forward
1629     # this is done by walking up the call stack and looking for a calling
1630     # sub of Catalyst::forward before the eval
1631     my $callsub = q{};
1632     for my $index ( 2 .. 11 ) {
1633         last
1634         if ( ( caller($index) )[0] eq 'Catalyst'
1635             && ( caller($index) )[3] eq '(eval)' );
1636
1637         if ( ( caller($index) )[3] =~ /forward$/ ) {
1638             $callsub = ( caller($index) )[3];
1639             $action  = "-> $action";
1640             last;
1641         }
1642     }
1643
1644     my $uid = $action_name . $c->counter->{$action_name};
1645
1646     # is this a root-level call or a forwarded call?
1647     if ( $callsub =~ /forward$/ ) {
1648         my $parent = $c->stack->[-1];
1649
1650         # forward, locate the caller
1651         if ( exists $c->counter->{"$parent"} ) {
1652             $c->stats->profile(
1653                 begin  => $action,
1654                 parent => "$parent" . $c->counter->{"$parent"},
1655                 uid    => $uid,
1656             );
1657         }
1658         else {
1659
1660             # forward with no caller may come from a plugin
1661             $c->stats->profile(
1662                 begin => $action,
1663                 uid   => $uid,
1664             );
1665         }
1666     }
1667     else {
1668
1669         # root-level call
1670         $c->stats->profile(
1671             begin => $action,
1672             uid   => $uid,
1673         );
1674     }
1675     return $action;
1676
1677 }
1678
1679 sub _stats_finish_execute {
1680     my ( $c, $info ) = @_;
1681     $c->stats->profile( end => $info );
1682 }
1683
1684 =head2 $c->finalize
1685
1686 Finalizes the request.
1687
1688 =cut
1689
1690 sub finalize {
1691     my $c = shift;
1692
1693     for my $error ( @{ $c->error } ) {
1694         $c->log->error($error);
1695     }
1696
1697     # Allow engine to handle finalize flow (for POE)
1698     my $engine = $c->engine;
1699     if ( my $code = $engine->can('finalize') ) {
1700         $engine->$code($c);
1701     }
1702     else {
1703
1704         $c->finalize_uploads;
1705
1706         # Error
1707         if ( $#{ $c->error } >= 0 ) {
1708             $c->finalize_error;
1709         }
1710
1711         $c->finalize_headers;
1712
1713         # HEAD request
1714         if ( $c->request->method eq 'HEAD' ) {
1715             $c->response->body('');
1716         }
1717
1718         $c->finalize_body;
1719     }
1720
1721     if ($c->use_stats) {
1722         my $elapsed = sprintf '%f', $c->stats->elapsed;
1723         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1724         $c->log->info(
1725             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1726     }
1727
1728     return $c->response->status;
1729 }
1730
1731 =head2 $c->finalize_body
1732
1733 Finalizes body.
1734
1735 =cut
1736
1737 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1738
1739 =head2 $c->finalize_cookies
1740
1741 Finalizes cookies.
1742
1743 =cut
1744
1745 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1746
1747 =head2 $c->finalize_error
1748
1749 Finalizes error.
1750
1751 =cut
1752
1753 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1754
1755 =head2 $c->finalize_headers
1756
1757 Finalizes headers.
1758
1759 =cut
1760
1761 sub finalize_headers {
1762     my $c = shift;
1763
1764     my $response = $c->response; #accessor calls can add up?
1765
1766     # Check if we already finalized headers
1767     return if $response->finalized_headers;
1768
1769     # Handle redirects
1770     if ( my $location = $response->redirect ) {
1771         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1772         $response->header( Location => $location );
1773
1774         if ( !$response->has_body ) {
1775             # Add a default body if none is already present
1776             $response->body(
1777                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1778             );
1779         }
1780     }
1781
1782     # Content-Length
1783     if ( $response->body && !$response->content_length ) {
1784
1785         # get the length from a filehandle
1786         if ( blessed( $response->body ) && $response->body->can('read') )
1787         {
1788             my $stat = stat $response->body;
1789             if ( $stat && $stat->size > 0 ) {
1790                 $response->content_length( $stat->size );
1791             }
1792             else {
1793                 $c->log->warn('Serving filehandle without a content-length');
1794             }
1795         }
1796         else {
1797             # everything should be bytes at this point, but just in case
1798             $response->content_length( length( $response->body ) );
1799         }
1800     }
1801
1802     # Errors
1803     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1804         $response->headers->remove_header("Content-Length");
1805         $response->body('');
1806     }
1807
1808     $c->finalize_cookies;
1809
1810     $c->engine->finalize_headers( $c, @_ );
1811
1812     # Done
1813     $response->finalized_headers(1);
1814 }
1815
1816 =head2 $c->finalize_output
1817
1818 An alias for finalize_body.
1819
1820 =head2 $c->finalize_read
1821
1822 Finalizes the input after reading is complete.
1823
1824 =cut
1825
1826 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1827
1828 =head2 $c->finalize_uploads
1829
1830 Finalizes uploads. Cleans up any temporary files.
1831
1832 =cut
1833
1834 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1835
1836 =head2 $c->get_action( $action, $namespace )
1837
1838 Gets an action in a given namespace.
1839
1840 =cut
1841
1842 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1843
1844 =head2 $c->get_actions( $action, $namespace )
1845
1846 Gets all actions of a given name in a namespace and all parent
1847 namespaces.
1848
1849 =cut
1850
1851 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1852
1853 =head2 $c->handle_request( $class, @arguments )
1854
1855 Called to handle each HTTP request.
1856
1857 =cut
1858
1859 sub handle_request {
1860     my ( $class, @arguments ) = @_;
1861
1862     # Always expect worst case!
1863     my $status = -1;
1864     eval {
1865         if ($class->debug) {
1866             my $secs = time - $START || 1;
1867             my $av = sprintf '%.3f', $COUNT / $secs;
1868             my $time = localtime time;
1869             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1870         }
1871
1872         my $c = $class->prepare(@arguments);
1873         $c->dispatch;
1874         $status = $c->finalize;
1875     };
1876
1877     if ( my $error = $@ ) {
1878         chomp $error;
1879         $class->log->error(qq/Caught exception in engine "$error"/);
1880     }
1881
1882     $COUNT++;
1883
1884     if(my $coderef = $class->log->can('_flush')){
1885         $class->log->$coderef();
1886     }
1887     return $status;
1888 }
1889
1890 =head2 $c->prepare( @arguments )
1891
1892 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1893 etc.).
1894
1895 =cut
1896
1897 sub prepare {
1898     my ( $class, @arguments ) = @_;
1899
1900     # XXX
1901     # After the app/ctxt split, this should become an attribute based on something passed
1902     # into the application.
1903     $class->context_class( ref $class || $class ) unless $class->context_class;
1904
1905     my $c = $class->context_class->new({});
1906
1907     # For on-demand data
1908     $c->request->_context($c);
1909     $c->response->_context($c);
1910
1911     #surely this is not the most efficient way to do things...
1912     $c->stats($class->stats_class->new)->enable($c->use_stats);
1913     if ( $c->debug ) {
1914         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1915     }
1916
1917     #XXX reuse coderef from can
1918     # Allow engine to direct the prepare flow (for POE)
1919     if ( $c->engine->can('prepare') ) {
1920         $c->engine->prepare( $c, @arguments );
1921     }
1922     else {
1923         $c->prepare_request(@arguments);
1924         $c->prepare_connection;
1925         $c->prepare_query_parameters;
1926         $c->prepare_headers;
1927         $c->prepare_cookies;
1928         $c->prepare_path;
1929
1930         # Prepare the body for reading, either by prepare_body
1931         # or the user, if they are using $c->read
1932         $c->prepare_read;
1933
1934         # Parse the body unless the user wants it on-demand
1935         unless ( ref($c)->config->{parse_on_demand} ) {
1936             $c->prepare_body;
1937         }
1938     }
1939
1940     my $method  = $c->req->method  || '';
1941     my $path    = $c->req->path;
1942     $path       = '/' unless length $path;
1943     my $address = $c->req->address || '';
1944
1945     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1946       if $c->debug;
1947
1948     $c->prepare_action;
1949
1950     return $c;
1951 }
1952
1953 =head2 $c->prepare_action
1954
1955 Prepares action. See L<Catalyst::Dispatcher>.
1956
1957 =cut
1958
1959 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1960
1961 =head2 $c->prepare_body
1962
1963 Prepares message body.
1964
1965 =cut
1966
1967 sub prepare_body {
1968     my $c = shift;
1969
1970     return if $c->request->_has_body;
1971
1972     # Initialize on-demand data
1973     $c->engine->prepare_body( $c, @_ );
1974     $c->prepare_parameters;
1975     $c->prepare_uploads;
1976
1977     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1978         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1979         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1980             my $param = $c->req->body_parameters->{$key};
1981             my $value = defined($param) ? $param : '';
1982             $t->row( $key,
1983                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1984         }
1985         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1986     }
1987 }
1988
1989 =head2 $c->prepare_body_chunk( $chunk )
1990
1991 Prepares a chunk of data before sending it to L<HTTP::Body>.
1992
1993 See L<Catalyst::Engine>.
1994
1995 =cut
1996
1997 sub prepare_body_chunk {
1998     my $c = shift;
1999     $c->engine->prepare_body_chunk( $c, @_ );
2000 }
2001
2002 =head2 $c->prepare_body_parameters
2003
2004 Prepares body parameters.
2005
2006 =cut
2007
2008 sub prepare_body_parameters {
2009     my $c = shift;
2010     $c->engine->prepare_body_parameters( $c, @_ );
2011 }
2012
2013 =head2 $c->prepare_connection
2014
2015 Prepares connection.
2016
2017 =cut
2018
2019 sub prepare_connection {
2020     my $c = shift;
2021     $c->engine->prepare_connection( $c, @_ );
2022 }
2023
2024 =head2 $c->prepare_cookies
2025
2026 Prepares cookies.
2027
2028 =cut
2029
2030 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2031
2032 =head2 $c->prepare_headers
2033
2034 Prepares headers.
2035
2036 =cut
2037
2038 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2039
2040 =head2 $c->prepare_parameters
2041
2042 Prepares parameters.
2043
2044 =cut
2045
2046 sub prepare_parameters {
2047     my $c = shift;
2048     $c->prepare_body_parameters;
2049     $c->engine->prepare_parameters( $c, @_ );
2050 }
2051
2052 =head2 $c->prepare_path
2053
2054 Prepares path and base.
2055
2056 =cut
2057
2058 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2059
2060 =head2 $c->prepare_query_parameters
2061
2062 Prepares query parameters.
2063
2064 =cut
2065
2066 sub prepare_query_parameters {
2067     my $c = shift;
2068
2069     $c->engine->prepare_query_parameters( $c, @_ );
2070
2071     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
2072         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
2073         for my $key ( sort keys %{ $c->req->query_parameters } ) {
2074             my $param = $c->req->query_parameters->{$key};
2075             my $value = defined($param) ? $param : '';
2076             $t->row( $key,
2077                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2078         }
2079         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2080     }
2081 }
2082
2083 =head2 $c->prepare_read
2084
2085 Prepares the input for reading.
2086
2087 =cut
2088
2089 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2090
2091 =head2 $c->prepare_request
2092
2093 Prepares the engine request.
2094
2095 =cut
2096
2097 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2098
2099 =head2 $c->prepare_uploads
2100
2101 Prepares uploads.
2102
2103 =cut
2104
2105 sub prepare_uploads {
2106     my $c = shift;
2107
2108     $c->engine->prepare_uploads( $c, @_ );
2109
2110     if ( $c->debug && keys %{ $c->request->uploads } ) {
2111         my $t = Text::SimpleTable->new(
2112             [ 12, 'Parameter' ],
2113             [ 26, 'Filename' ],
2114             [ 18, 'Type' ],
2115             [ 9,  'Size' ]
2116         );
2117         for my $key ( sort keys %{ $c->request->uploads } ) {
2118             my $upload = $c->request->uploads->{$key};
2119             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2120                 $t->row( $key, $u->filename, $u->type, $u->size );
2121             }
2122         }
2123         $c->log->debug( "File Uploads are:\n" . $t->draw );
2124     }
2125 }
2126
2127 =head2 $c->prepare_write
2128
2129 Prepares the output for writing.
2130
2131 =cut
2132
2133 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2134
2135 =head2 $c->request_class
2136
2137 Returns or sets the request class.
2138
2139 =head2 $c->response_class
2140
2141 Returns or sets the response class.
2142
2143 =head2 $c->read( [$maxlength] )
2144
2145 Reads a chunk of data from the request body. This method is designed to
2146 be used in a while loop, reading C<$maxlength> bytes on every call.
2147 C<$maxlength> defaults to the size of the request if not specified.
2148
2149 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2150 directly.
2151
2152 Warning: If you use read(), Catalyst will not process the body,
2153 so you will not be able to access POST parameters or file uploads via
2154 $c->request.  You must handle all body parsing yourself.
2155
2156 =cut
2157
2158 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2159
2160 =head2 $c->run
2161
2162 Starts the engine.
2163
2164 =cut
2165
2166 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2167
2168 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2169
2170 Sets an action in a given namespace.
2171
2172 =cut
2173
2174 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2175
2176 =head2 $c->setup_actions($component)
2177
2178 Sets up actions for a component.
2179
2180 =cut
2181
2182 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2183
2184 =head2 $c->setup_components
2185
2186 This method is called internally to set up the application's components.
2187
2188 It finds modules by calling the L<locate_components> method, expands them to
2189 package names with the L<expand_component_module> method, and then installs
2190 each component into the application.
2191
2192 The C<setup_components> config option is passed to both of the above methods.
2193
2194 Installation of each component is performed by the L<setup_component> method,
2195 below.
2196
2197 =cut
2198
2199 sub setup_components {
2200     my $class = shift;
2201
2202     my $config  = $class->config->{ setup_components };
2203
2204     my @comps = sort { length $a <=> length $b }
2205                 $class->locate_components($config);
2206     my %comps = map { $_ => 1 } @comps;
2207
2208     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2209     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2210         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2211     ) if $deprecatedcatalyst_component_names;
2212
2213     for my $component ( @comps ) {
2214
2215         # We pass ignore_loaded here so that overlay files for (e.g.)
2216         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2217         # we know M::P::O found a file on disk so this is safe
2218
2219         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2220
2221         # Needs to be done as soon as the component is loaded, as loading a sub-component
2222         # (next time round the loop) can cause us to get the wrong metaclass..
2223         $class->_controller_init_base_classes($component);
2224     }
2225
2226     for my $component (@comps) {
2227         my $instance = $class->components->{ $component } = $class->setup_component($component);
2228         my @expanded_components = $instance->can('expand_modules')
2229             ? $instance->expand_modules( $component, $config )
2230             : $class->expand_component_module( $component, $config );
2231         for my $component (@expanded_components) {
2232             next if $comps{$component};
2233             $class->_controller_init_base_classes($component); # Also cover inner packages
2234             $class->components->{ $component } = $class->setup_component($component);
2235         }
2236     }
2237 }
2238
2239 =head2 $c->locate_components( $setup_component_config )
2240
2241 This method is meant to provide a list of component modules that should be
2242 setup for the application.  By default, it will use L<Module::Pluggable>.
2243
2244 Specify a C<setup_components> config option to pass additional options directly
2245 to L<Module::Pluggable>. To add additional search paths, specify a key named
2246 C<search_extra> as an array reference. Items in the array beginning with C<::>
2247 will have the application class name prepended to them.
2248
2249 =cut
2250
2251 sub locate_components {
2252     my $class  = shift;
2253     my $config = shift;
2254
2255     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2256     my $extra   = delete $config->{ search_extra } || [];
2257
2258     push @paths, @$extra;
2259
2260     my $locator = Module::Pluggable::Object->new(
2261         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2262         %$config
2263     );
2264
2265     my @comps = $locator->plugins;
2266
2267     return @comps;
2268 }
2269
2270 =head2 $c->expand_component_module( $component, $setup_component_config )
2271
2272 Components found by C<locate_components> will be passed to this method, which
2273 is expected to return a list of component (package) names to be set up.
2274
2275 =cut
2276
2277 sub expand_component_module {
2278     my ($class, $module) = @_;
2279     return Devel::InnerPackage::list_packages( $module );
2280 }
2281
2282 =head2 $c->setup_component
2283
2284 =cut
2285
2286 # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2287 #         nearest to Catalyst::Controller first, no matter what order stuff happens
2288 #         to be loaded. There are TODO tests in Moose for this, see
2289 #         f2391d17574eff81d911b97be15ea51080500003
2290 sub _controller_init_base_classes {
2291     my ($app_class, $component) = @_;
2292     return unless $component->isa('Catalyst::Controller');
2293     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2294         Moose::Meta::Class->initialize( $class )
2295             unless find_meta($class);
2296     }
2297 }
2298
2299 sub setup_component {
2300     my( $class, $component ) = @_;
2301
2302     unless ( $component->can( 'COMPONENT' ) ) {
2303         return $component;
2304     }
2305
2306     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2307     my $config = $class->config->{ $suffix } || {};
2308     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2309     # methods also pass it. local to avoid pointlessly shitting in config
2310     # for the debug screen, as $component is already the key name.
2311     local $config->{catalyst_component_name} = $component;
2312
2313     my $instance = eval { $component->COMPONENT( $class, $config ); };
2314
2315     if ( my $error = $@ ) {
2316         chomp $error;
2317         Catalyst::Exception->throw(
2318             message => qq/Couldn't instantiate component "$component", "$error"/
2319         );
2320     }
2321
2322     unless (blessed $instance) {
2323         my $metaclass = Moose::Util::find_meta($component);
2324         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2325         my $component_method_from = $method_meta->associated_metaclass->name;
2326         my $value = defined($instance) ? $instance : 'undef';
2327         Catalyst::Exception->throw(
2328             message =>
2329             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2330         );
2331     }
2332     return $instance;
2333 }
2334
2335 =head2 $c->setup_dispatcher
2336
2337 Sets up dispatcher.
2338
2339 =cut
2340
2341 sub setup_dispatcher {
2342     my ( $class, $dispatcher ) = @_;
2343
2344     if ($dispatcher) {
2345         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2346     }
2347
2348     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2349         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2350     }
2351
2352     unless ($dispatcher) {
2353         $dispatcher = $class->dispatcher_class;
2354     }
2355
2356     Class::MOP::load_class($dispatcher);
2357
2358     # dispatcher instance
2359     $class->dispatcher( $dispatcher->new );
2360 }
2361
2362 =head2 $c->setup_engine
2363
2364 Sets up engine.
2365
2366 =cut
2367
2368 sub setup_engine {
2369     my ( $class, $engine ) = @_;
2370
2371     if ($engine) {
2372         $engine = 'Catalyst::Engine::' . $engine;
2373     }
2374
2375     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2376         $engine = 'Catalyst::Engine::' . $env;
2377     }
2378
2379     if ( $ENV{MOD_PERL} ) {
2380         my $meta = Class::MOP::get_metaclass_by_name($class);
2381
2382         # create the apache method
2383         $meta->add_method('apache' => sub { shift->engine->apache });
2384
2385         my ( $software, $version ) =
2386           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2387
2388         $version =~ s/_//g;
2389         $version =~ s/(\.[^.]+)\./$1/g;
2390
2391         if ( $software eq 'mod_perl' ) {
2392
2393             if ( !$engine ) {
2394
2395                 if ( $version >= 1.99922 ) {
2396                     $engine = 'Catalyst::Engine::Apache2::MP20';
2397                 }
2398
2399                 elsif ( $version >= 1.9901 ) {
2400                     $engine = 'Catalyst::Engine::Apache2::MP19';
2401                 }
2402
2403                 elsif ( $version >= 1.24 ) {
2404                     $engine = 'Catalyst::Engine::Apache::MP13';
2405                 }
2406
2407                 else {
2408                     Catalyst::Exception->throw( message =>
2409                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2410                 }
2411
2412             }
2413
2414             # install the correct mod_perl handler
2415             if ( $version >= 1.9901 ) {
2416                 *handler = sub  : method {
2417                     shift->handle_request(@_);
2418                 };
2419             }
2420             else {
2421                 *handler = sub ($$) { shift->handle_request(@_) };
2422             }
2423
2424         }
2425
2426         elsif ( $software eq 'Zeus-Perl' ) {
2427             $engine = 'Catalyst::Engine::Zeus';
2428         }
2429
2430         else {
2431             Catalyst::Exception->throw(
2432                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2433         }
2434     }
2435
2436     unless ($engine) {
2437         $engine = $class->engine_class;
2438     }
2439
2440     Class::MOP::load_class($engine);
2441
2442     # check for old engines that are no longer compatible
2443     my $old_engine;
2444     if ( $engine->isa('Catalyst::Engine::Apache')
2445         && !Catalyst::Engine::Apache->VERSION )
2446     {
2447         $old_engine = 1;
2448     }
2449
2450     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2451         && Catalyst::Engine::Server->VERSION le '0.02' )
2452     {
2453         $old_engine = 1;
2454     }
2455
2456     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2457         && $engine->VERSION eq '0.01' )
2458     {
2459         $old_engine = 1;
2460     }
2461
2462     elsif ($engine->isa('Catalyst::Engine::Zeus')
2463         && $engine->VERSION eq '0.01' )
2464     {
2465         $old_engine = 1;
2466     }
2467
2468     if ($old_engine) {
2469         Catalyst::Exception->throw( message =>
2470               qq/Engine "$engine" is not supported by this version of Catalyst/
2471         );
2472     }
2473
2474     # engine instance
2475     $class->engine( $engine->new );
2476 }
2477
2478 =head2 $c->setup_home
2479
2480 Sets up the home directory.
2481
2482 =cut
2483
2484 sub setup_home {
2485     my ( $class, $home ) = @_;
2486
2487     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2488         $home = $env;
2489     }
2490
2491     $home ||= Catalyst::Utils::home($class);
2492
2493     if ($home) {
2494         #I remember recently being scolded for assigning config values like this
2495         $class->config->{home} ||= $home;
2496         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2497     }
2498 }
2499
2500 =head2 $c->setup_log
2501
2502 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2503 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2504 log to.
2505
2506 This method also installs a C<debug> method that returns a true value into the
2507 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2508 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2509
2510 Note that if the log has already been setup, by either a previous call to
2511 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2512 that this method won't actually set up the log object.
2513
2514 =cut
2515
2516 sub setup_log {
2517     my ( $class, $levels ) = @_;
2518
2519     $levels ||= '';
2520     $levels =~ s/^\s+//;
2521     $levels =~ s/\s+$//;
2522     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2523
2524     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2525     if ( defined $env_debug ) {
2526         $levels{debug} = 1 if $env_debug; # Ugly!
2527         delete($levels{debug}) unless $env_debug;
2528     }
2529
2530     unless ( $class->log ) {
2531         $class->log( Catalyst::Log->new(keys %levels) );
2532     }
2533
2534     if ( $levels{debug} ) {
2535         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2536         $class->log->debug('Debug messages enabled');
2537     }
2538 }
2539
2540 =head2 $c->setup_plugins
2541
2542 Sets up plugins.
2543
2544 =cut
2545
2546 =head2 $c->setup_stats
2547
2548 Sets up timing statistics class.
2549
2550 =cut
2551
2552 sub setup_stats {
2553     my ( $class, $stats ) = @_;
2554
2555     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2556
2557     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2558     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2559         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2560         $class->log->debug('Statistics enabled');
2561     }
2562 }
2563
2564
2565 =head2 $c->registered_plugins
2566
2567 Returns a sorted list of the plugins which have either been stated in the
2568 import list or which have been added via C<< MyApp->plugin(@args); >>.
2569
2570 If passed a given plugin name, it will report a boolean value indicating
2571 whether or not that plugin is loaded.  A fully qualified name is required if
2572 the plugin name does not begin with C<Catalyst::Plugin::>.
2573
2574  if ($c->registered_plugins('Some::Plugin')) {
2575      ...
2576  }
2577
2578 =cut
2579
2580 {
2581
2582     sub registered_plugins {
2583         my $proto = shift;
2584         return sort keys %{ $proto->_plugins } unless @_;
2585         my $plugin = shift;
2586         return 1 if exists $proto->_plugins->{$plugin};
2587         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2588     }
2589
2590     sub _register_plugin {
2591         my ( $proto, $plugin, $instant ) = @_;
2592         my $class = ref $proto || $proto;
2593
2594         Class::MOP::load_class( $plugin );
2595         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2596             if $plugin->isa( 'Catalyst::Component' );
2597         $proto->_plugins->{$plugin} = 1;
2598         unless ($instant) {
2599             no strict 'refs';
2600             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2601               my @superclasses = ($plugin, $meta->superclasses );
2602               $meta->superclasses(@superclasses);
2603             } else {
2604               unshift @{"$class\::ISA"}, $plugin;
2605             }
2606         }
2607         return $class;
2608     }
2609
2610     sub setup_plugins {
2611         my ( $class, $plugins ) = @_;
2612
2613         $class->_plugins( {} ) unless $class->_plugins;
2614         $plugins ||= [];
2615
2616         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2617
2618         for my $plugin ( reverse @plugins ) {
2619             Class::MOP::load_class($plugin);
2620             my $meta = find_meta($plugin);
2621             next if $meta && $meta->isa('Moose::Meta::Role');
2622
2623             $class->_register_plugin($plugin);
2624         }
2625
2626         my @roles =
2627             map { $_->name }
2628             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2629             map { find_meta($_) }
2630             @plugins;
2631
2632         Moose::Util::apply_all_roles(
2633             $class => @roles
2634         ) if @roles;
2635     }
2636 }
2637
2638 =head2 $c->stack
2639
2640 Returns an arrayref of the internal execution stack (actions that are
2641 currently executing).
2642
2643 =head2 $c->stats_class
2644
2645 Returns or sets the stats (timing statistics) class.
2646
2647 =head2 $c->use_stats
2648
2649 Returns 1 when stats collection is enabled.  Stats collection is enabled
2650 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2651 environment variable is set.
2652
2653 Note that this is a static method, not an accessor and should be overridden
2654 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2655
2656 =cut
2657
2658 sub use_stats { 0 }
2659
2660
2661 =head2 $c->write( $data )
2662
2663 Writes $data to the output stream. When using this method directly, you
2664 will need to manually set the C<Content-Length> header to the length of
2665 your output data, if known.
2666
2667 =cut
2668
2669 sub write {
2670     my $c = shift;
2671
2672     # Finalize headers if someone manually writes output
2673     $c->finalize_headers;
2674
2675     return $c->engine->write( $c, @_ );
2676 }
2677
2678 =head2 version
2679
2680 Returns the Catalyst version number. Mostly useful for "powered by"
2681 messages in template systems.
2682
2683 =cut
2684
2685 sub version { return $Catalyst::VERSION }
2686
2687 =head1 CONFIGURATION
2688
2689 There are a number of 'base' config variables which can be set:
2690
2691 =over
2692
2693 =item *
2694
2695 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2696
2697 =item *
2698
2699 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2700
2701 =item *
2702
2703 C<disable_component_resolution_regex_fallback> - Turns
2704 off the deprecated component resolution functionality so
2705 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2706 are called then regex search will not be attempted on string values and
2707 instead C<undef> will be returned.
2708
2709 =item *
2710
2711 C<home> - The application home directory. In an uninstalled application,
2712 this is the top level application directory. In an installed application,
2713 this will be the directory containing C<< MyApp.pm >>.
2714
2715 =item *
2716
2717 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2718
2719 =item *
2720
2721 C<name> - The name of the application in debug messages and the debug and
2722 welcome screens
2723
2724 =item *
2725
2726 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2727 until it is accessed. This allows you to (for example) check authentication (and reject
2728 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2729
2730 =item *
2731
2732 C<root> - The root directory for templates. Usually this is just a
2733 subdirectory of the home directory, but you can set it to change the
2734 templates to a different directory.
2735
2736 =item *
2737
2738 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2739 namespaces from which components will be loaded (and constructed and stored in
2740 C<< $c->components >>).
2741
2742 =item *
2743
2744 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2745 to be shown in hit debug tables in the test server.
2746
2747 =item *
2748
2749 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2750
2751 =back
2752
2753 =head1 INTERNAL ACTIONS
2754
2755 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2756 C<_ACTION>, and C<_END>. These are by default not shown in the private
2757 action table, but you can make them visible with a config parameter.
2758
2759     MyApp->config(show_internal_actions => 1);
2760
2761 =head1 ON-DEMAND PARSER
2762
2763 The request body is usually parsed at the beginning of a request,
2764 but if you want to handle input yourself, you can enable on-demand
2765 parsing with a config parameter.
2766
2767     MyApp->config(parse_on_demand => 1);
2768
2769 =head1 PROXY SUPPORT
2770
2771 Many production servers operate using the common double-server approach,
2772 with a lightweight frontend web server passing requests to a larger
2773 backend server. An application running on the backend server must deal
2774 with two problems: the remote user always appears to be C<127.0.0.1> and
2775 the server's hostname will appear to be C<localhost> regardless of the
2776 virtual host that the user connected through.
2777
2778 Catalyst will automatically detect this situation when you are running
2779 the frontend and backend servers on the same machine. The following
2780 changes are made to the request.
2781
2782     $c->req->address is set to the user's real IP address, as read from
2783     the HTTP X-Forwarded-For header.
2784
2785     The host value for $c->req->base and $c->req->uri is set to the real
2786     host, as read from the HTTP X-Forwarded-Host header.
2787
2788 Additionally, you may be running your backend application on an insecure
2789 connection (port 80) while your frontend proxy is running under SSL.  If there
2790 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2791 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2792 be created properly.
2793
2794 In the case of passing in:
2795
2796     X-Forwarded-Port: 443
2797
2798 All calls to C<uri_for> will result in an https link, as is expected.
2799
2800 Obviously, your web server must support these headers for this to work.
2801
2802 In a more complex server farm environment where you may have your
2803 frontend proxy server(s) on different machines, you will need to set a
2804 configuration option to tell Catalyst to read the proxied data from the
2805 headers.
2806
2807     MyApp->config(using_frontend_proxy => 1);
2808
2809 If you do not wish to use the proxy support at all, you may set:
2810
2811     MyApp->config(ignore_frontend_proxy => 1);
2812
2813 =head1 THREAD SAFETY
2814
2815 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2816 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2817 believe the Catalyst core to be thread-safe.
2818
2819 If you plan to operate in a threaded environment, remember that all other
2820 modules you are using must also be thread-safe. Some modules, most notably
2821 L<DBD::SQLite>, are not thread-safe.
2822
2823 =head1 SUPPORT
2824
2825 IRC:
2826
2827     Join #catalyst on irc.perl.org.
2828
2829 Mailing Lists:
2830
2831     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2832     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2833
2834 Web:
2835
2836     http://catalyst.perl.org
2837
2838 Wiki:
2839
2840     http://dev.catalyst.perl.org
2841
2842 =head1 SEE ALSO
2843
2844 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2845
2846 =head2 L<Catalyst::Manual> - The Catalyst Manual
2847
2848 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2849
2850 =head2 L<Catalyst::Engine> - Core engine
2851
2852 =head2 L<Catalyst::Log> - Log class.
2853
2854 =head2 L<Catalyst::Request> - Request object
2855
2856 =head2 L<Catalyst::Response> - Response object
2857
2858 =head2 L<Catalyst::Test> - The test suite.
2859
2860 =head1 PROJECT FOUNDER
2861
2862 sri: Sebastian Riedel <sri@cpan.org>
2863
2864 =head1 CONTRIBUTORS
2865
2866 abw: Andy Wardley
2867
2868 acme: Leon Brocard <leon@astray.com>
2869
2870 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
2871
2872 Andrew Bramble
2873
2874 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
2875
2876 Andrew Ruthven
2877
2878 andyg: Andy Grundman <andy@hybridized.org>
2879
2880 audreyt: Audrey Tang
2881
2882 bricas: Brian Cassidy <bricas@cpan.org>
2883
2884 Caelum: Rafael Kitover <rkitover@io.com>
2885
2886 chansen: Christian Hansen
2887
2888 chicks: Christopher Hicks
2889
2890 Chisel Wright C<pause@herlpacker.co.uk>
2891
2892 Danijel Milicevic C<me@danijel.de>
2893
2894 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
2895
2896 David Naughton, C<naughton@umn.edu>
2897
2898 David E. Wheeler
2899
2900 dhoss: Devin Austin <dhoss@cpan.org>
2901
2902 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2903
2904 Drew Taylor
2905
2906 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2907
2908 esskar: Sascha Kiefer
2909
2910 fireartist: Carl Franks <cfranks@cpan.org>
2911
2912 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
2913
2914 gabb: Danijel Milicevic
2915
2916 Gary Ashton Jones
2917
2918 Gavin Henry C<ghenry@perl.me.uk>
2919
2920 Geoff Richards
2921
2922 groditi: Guillermo Roditi <groditi@gmail.com>
2923
2924 hobbs: Andrew Rodland <andrew@cleverdomain.org>
2925
2926 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2927
2928 jcamacho: Juan Camacho
2929
2930 jester: Jesse Sheidlower C<jester@panix.com>
2931
2932 jhannah: Jay Hannah <jay@jays.net>
2933
2934 Jody Belka
2935
2936 Johan Lindstrom
2937
2938 jon: Jon Schutz <jjschutz@cpan.org>
2939
2940 Jonathan Rockway C<< <jrockway@cpan.org> >>
2941
2942 Kieren Diment C<kd@totaldatasolution.com>
2943
2944 konobi: Scott McWhirter <konobi@cpan.org>
2945
2946 marcus: Marcus Ramberg <mramberg@cpan.org>
2947
2948 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2949
2950 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2951
2952 mugwump: Sam Vilain
2953
2954 naughton: David Naughton
2955
2956 ningu: David Kamholz <dkamholz@cpan.org>
2957
2958 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2959
2960 numa: Dan Sully <daniel@cpan.org>
2961
2962 obra: Jesse Vincent
2963
2964 Octavian Rasnita
2965
2966 omega: Andreas Marienborg
2967
2968 Oleg Kostyuk <cub.uanic@gmail.com>
2969
2970 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2971
2972 rafl: Florian Ragwitz <rafl@debian.org>
2973
2974 random: Roland Lammel <lammel@cpan.org>
2975
2976 Robert Sedlacek C<< <rs@474.at> >>
2977
2978 sky: Arthur Bergman
2979
2980 t0m: Tomas Doran <bobtfish@bobtfish.net>
2981
2982 Ulf Edvinsson
2983
2984 Viljo Marrandi C<vilts@yahoo.com>
2985
2986 Will Hawes C<info@whawes.co.uk>
2987
2988 willert: Sebastian Willert <willert@cpan.org>
2989
2990 Yuval Kogman, C<nothingmuch@woobling.org>
2991
2992 =head1 LICENSE
2993
2994 This library is free software. You can redistribute it and/or modify it under
2995 the same terms as Perl itself.
2996
2997 =cut
2998
2999 no Moose;
3000
3001 __PACKAGE__->meta->make_immutable;
3002
3003 1;