lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use String::RewritePrefix;
  32 use Catalyst::EngineLoader;
  33 use utf8;
  34 use Carp qw/croak carp shortmess/;
  35 use Try::Tiny;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39 use Plack::Middleware::LighttpdScriptNameFix;
  40
  41 BEGIN { require 5.008004; }
  42
  43 has stack => (is => 'ro', default => sub { [] });
  44 has stash => (is => 'rw', default => sub { {} });
  45 has state => (is => 'rw', default => 0);
  46 has stats => (is => 'rw');
  47 has action => (is => 'rw');
  48 has counter => (is => 'rw', default => sub { {} });
  49 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  50 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  51 has namespace => (is => 'rw');
  52
  53 sub depth { scalar @{ shift->stack || [] }; }
  54 sub comp { shift->component(@_) }
  55
  56 sub req {
  57     my $self = shift; return $self->request(@_);
  58 }
  59 sub res {
  60     my $self = shift; return $self->response(@_);
  61 }
  62
  63 # For backwards compatibility
  64 sub finalize_output { shift->finalize_body(@_) };
  65
  66 # For statistics
  67 our $COUNT     = 1;
  68 our $START     = time;
  69 our $RECURSION = 1000;
  70 our $DETACH    = Catalyst::Exception::Detach->new;
  71 our $GO        = Catalyst::Exception::Go->new;
  72
  73 #I imagine that very few of these really need to be class variables. if any.
  74 #maybe we should just make them attributes with a default?
  75 __PACKAGE__->mk_classdata($_)
  76   for qw/components arguments dispatcher engine log dispatcher_class
  77   engine_loader context_class request_class response_class stats_class
  78   setup_finished _psgi_app loading_psgi_file/;
  79
  80 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  81 __PACKAGE__->request_class('Catalyst::Request');
  82 __PACKAGE__->response_class('Catalyst::Response');
  83 __PACKAGE__->stats_class('Catalyst::Stats');
  84
  85 # Remember to update this in Catalyst::Runtime as well!
  86
  87 our $VERSION = '5.90004';
  88
  89 sub import {
  90     my ( $class, @arguments ) = @_;
  91
  92     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  93     # callers @ISA.
  94     return unless $class eq 'Catalyst';
  95
  96     my $caller = caller();
  97     return if $caller eq 'main';
  98
  99     my $meta = Moose::Meta::Class->initialize($caller);
 100     unless ( $caller->isa('Catalyst') ) {
 101         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 102         $meta->superclasses(@superclasses);
 103     }
 104     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 105     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 106
 107     unless( $meta->has_method('meta') ){
 108         if ($Moose::VERSION >= 1.15) {
 109             $meta->_add_meta_method('meta');
 110         }
 111         else {
 112             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 113         }
 114     }
 115
 116     $caller->arguments( [@arguments] );
 117     $caller->setup_home;
 118 }
 119
 120 sub _application { $_[0] }
 121
 122 =head1 NAME
 123
 124 Catalyst - The Elegant MVC Web Application Framework
 125
 126 =head1 SYNOPSIS
 127
 128 See the L<Catalyst::Manual> distribution for comprehensive
 129 documentation and tutorials.
 130
 131     # Install Catalyst::Devel for helpers and other development tools
 132     # use the helper to create a new application
 133     catalyst.pl MyApp
 134
 135     # add models, views, controllers
 136     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 137     script/myapp_create.pl view MyTemplate TT
 138     script/myapp_create.pl controller Search
 139
 140     # built in testserver -- use -r to restart automatically on changes
 141     # --help to see all available options
 142     script/myapp_server.pl
 143
 144     # command line testing interface
 145     script/myapp_test.pl /yada
 146
 147     ### in lib/MyApp.pm
 148     use Catalyst qw/-Debug/; # include plugins here as well
 149
 150     ### In lib/MyApp/Controller/Root.pm (autocreated)
 151     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 152         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 153         $c->stash->{template} = 'foo.tt'; # set the template
 154         # lookup something from db -- stash vars are passed to TT
 155         $c->stash->{data} =
 156           $c->model('Database::Foo')->search( { country => $args[0] } );
 157         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 158             $c->forward( 'bar' ); # process another action
 159             # do something else after forward returns
 160         }
 161     }
 162
 163     # The foo.tt TT template can use the stash data from the database
 164     [% WHILE (item = data.next) %]
 165         [% item.foo %]
 166     [% END %]
 167
 168     # called for /bar/of/soap, /bar/of/soap/10, etc.
 169     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 170
 171     # called after all actions are finished
 172     sub end : Action {
 173         my ( $self, $c ) = @_;
 174         if ( scalar @{ $c->error } ) { ... } # handle errors
 175         return if $c->res->body; # already have a response
 176         $c->forward( 'MyApp::View::TT' ); # render template
 177     }
 178
 179 See L<Catalyst::Manual::Intro> for additional information.
 180
 181 =head1 DESCRIPTION
 182
 183 Catalyst is a modern framework for making web applications without the
 184 pain usually associated with this process. This document is a reference
 185 to the main Catalyst application. If you are a new user, we suggest you
 186 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 187
 188 See L<Catalyst::Manual> for more documentation.
 189
 190 Catalyst plugins can be loaded by naming them as arguments to the "use
 191 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 192 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 193 C<My::Module>.
 194
 195     use Catalyst qw/My::Module/;
 196
 197 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 198 fully qualify the name by using a unary plus:
 199
 200     use Catalyst qw/
 201         My::Module
 202         +Fully::Qualified::Plugin::Name
 203     /;
 204
 205 Special flags like C<-Debug> can also be specified as
 206 arguments when Catalyst is loaded:
 207
 208     use Catalyst qw/-Debug My::Module/;
 209
 210 The position of plugins and flags in the chain is important, because
 211 they are loaded in the order in which they appear.
 212
 213 The following flags are supported:
 214
 215 =head2 -Debug
 216
 217 Enables debug output. You can also force this setting from the system
 218 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 219 settings override the application, with <MYAPP>_DEBUG having the highest
 220 priority.
 221
 222 This sets the log level to 'debug' and enables full debug output on the
 223 error screen. If you only want the latter, see L<< $c->debug >>.
 224
 225 =head2 -Home
 226
 227 Forces Catalyst to use a specific home directory, e.g.:
 228
 229     use Catalyst qw[-Home=/usr/mst];
 230
 231 This can also be done in the shell environment by setting either the
 232 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 233 is replaced with the uppercased name of your application, any "::" in
 234 the name will be replaced with underscores, e.g. MyApp::Web should use
 235 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 236
 237 If none of these are set, Catalyst will attempt to automatically detect the
 238 home directory. If you are working in a development environment, Catalyst
 239 will try and find the directory containing either Makefile.PL, Build.PL or
 240 dist.ini. If the application has been installed into the system (i.e.
 241 you have done C<make install>), then Catalyst will use the path to your
 242 application module, without the .pm extension (e.g., /foo/MyApp if your
 243 application was installed at /foo/MyApp.pm)
 244
 245 =head2 -Log
 246
 247     use Catalyst '-Log=warn,fatal,error';
 248
 249 Specifies a comma-delimited list of log levels.
 250
 251 =head2 -Stats
 252
 253 Enables statistics collection and reporting.
 254
 255    use Catalyst qw/-Stats=1/;
 256
 257 You can also force this setting from the system environment with CATALYST_STATS
 258 or <MYAPP>_STATS. The environment settings override the application, with
 259 <MYAPP>_STATS having the highest priority.
 260
 261 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 262
 263 =head1 METHODS
 264
 265 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 266
 267 =head2 $c->action
 268
 269 Returns a L<Catalyst::Action> object for the current action, which
 270 stringifies to the action name. See L<Catalyst::Action>.
 271
 272 =head2 $c->namespace
 273
 274 Returns the namespace of the current action, i.e., the URI prefix
 275 corresponding to the controller of the current action. For example:
 276
 277     # in Controller::Foo::Bar
 278     $c->namespace; # returns 'foo/bar';
 279
 280 =head2 $c->request
 281
 282 =head2 $c->req
 283
 284 Returns the current L<Catalyst::Request> object, giving access to
 285 information about the current client request (including parameters,
 286 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 287
 288 =head2 REQUEST FLOW HANDLING
 289
 290 =head2 $c->forward( $action [, \@arguments ] )
 291
 292 =head2 $c->forward( $class, $method, [, \@arguments ] )
 293
 294 Forwards processing to another action, by its private name. If you give a
 295 class name but no method, C<process()> is called. You may also optionally
 296 pass arguments in an arrayref. The action will receive the arguments in
 297 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 298 C<< $c->req->args >> will be restored to the previous values.
 299
 300 Any data C<return>ed from the action forwarded to, will be returned by the
 301 call to forward.
 302
 303     my $foodata = $c->forward('/foo');
 304     $c->forward('index');
 305     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 306     $c->forward('View::TT');
 307
 308 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 309 an C<< eval { } >> around the call (actually
 310 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 311 exceptions thrown by the called action non-fatal and pushing them onto
 312 $c->error instead. If you want C<die> to propagate you need to do something
 313 like:
 314
 315     $c->forward('foo');
 316     die join "\n", @{ $c->error } if @{ $c->error };
 317
 318 Or make sure to always return true values from your actions and write
 319 your code like this:
 320
 321     $c->forward('foo') || return;
 322
 323 Another note is that C<< $c->forward >> always returns a scalar because it
 324 actually returns $c->state which operates in a scalar context.
 325 Thus, something like:
 326
 327     return @array;
 328
 329 in an action that is forwarded to is going to return a scalar,
 330 i.e. how many items are in that array, which is probably not what you want.
 331 If you need to return an array then return a reference to it,
 332 or stash it like so:
 333
 334     $c->stash->{array} = \@array;
 335
 336 and access it from the stash.
 337
 338 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 339
 340 =cut
 341
 342 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 343
 344 =head2 $c->detach( $action [, \@arguments ] )
 345
 346 =head2 $c->detach( $class, $method, [, \@arguments ] )
 347
 348 =head2 $c->detach()
 349
 350 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 351 doesn't return to the previous action when processing is finished.
 352
 353 When called with no arguments it escapes the processing chain entirely.
 354
 355 =cut
 356
 357 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 358
 359 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 360
 361 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 362
 363 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 364 but does a full dispatch, instead of just calling the new C<$action> /
 365 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 366 you go to are called, just like a new request.
 367
 368 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 369 This means, for example, that C<< $c->action >> methods such as
 370 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 371 L<reverse|Catalyst::Action/reverse> return information for the visited action
 372 when they are invoked within the visited action.  This is different from the
 373 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 374 continues to use the $c->action object from the caller action even when
 375 invoked from the called action.
 376
 377 C<< $c->stash >> is kept unchanged.
 378
 379 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 380 allows you to "wrap" another action, just as it would have been called by
 381 dispatching from a URL, while the analogous
 382 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 383 transfer control to another action as if it had been reached directly from a URL.
 384
 385 =cut
 386
 387 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 388
 389 =head2 $c->go( $action [, \@captures, \@arguments ] )
 390
 391 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 392
 393 The relationship between C<go> and
 394 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 395 the relationship between
 396 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 397 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 398 C<< $c->go >> will perform a full dispatch on the specified action or method,
 399 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 400 C<go> escapes the processing of the current request chain on completion, and
 401 does not return to its caller.
 402
 403 @arguments are arguments to the final destination of $action. @captures are
 404 arguments to the intermediate steps, if any, on the way to the final sub of
 405 $action.
 406
 407 =cut
 408
 409 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 410
 411 =head2 $c->response
 412
 413 =head2 $c->res
 414
 415 Returns the current L<Catalyst::Response> object, see there for details.
 416
 417 =head2 $c->stash
 418
 419 Returns a hashref to the stash, which may be used to store data and pass
 420 it between components during a request. You can also set hash keys by
 421 passing arguments. The stash is automatically sent to the view. The
 422 stash is cleared at the end of a request; it cannot be used for
 423 persistent storage (for this you must use a session; see
 424 L<Catalyst::Plugin::Session> for a complete system integrated with
 425 Catalyst).
 426
 427     $c->stash->{foo} = $bar;
 428     $c->stash( { moose => 'majestic', qux => 0 } );
 429     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 430
 431     # stash is automatically passed to the view for use in a template
 432     $c->forward( 'MyApp::View::TT' );
 433
 434 =cut
 435
 436 around stash => sub {
 437     my $orig = shift;
 438     my $c = shift;
 439     my $stash = $orig->($c);
 440     if (@_) {
 441         my $new_stash = @_ > 1 ? {@_} : $_[0];
 442         croak('stash takes a hash or hashref') unless ref $new_stash;
 443         foreach my $key ( keys %$new_stash ) {
 444           $stash->{$key} = $new_stash->{$key};
 445         }
 446     }
 447
 448     return $stash;
 449 };
 450
 451
 452 =head2 $c->error
 453
 454 =head2 $c->error($error, ...)
 455
 456 =head2 $c->error($arrayref)
 457
 458 Returns an arrayref containing error messages.  If Catalyst encounters an
 459 error while processing a request, it stores the error in $c->error.  This
 460 method should only be used to store fatal error messages.
 461
 462     my @error = @{ $c->error };
 463
 464 Add a new error.
 465
 466     $c->error('Something bad happened');
 467
 468 =cut
 469
 470 sub error {
 471     my $c = shift;
 472     if ( $_[0] ) {
 473         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 474         croak @$error unless ref $c;
 475         push @{ $c->{error} }, @$error;
 476     }
 477     elsif ( defined $_[0] ) { $c->{error} = undef }
 478     return $c->{error} || [];
 479 }
 480
 481
 482 =head2 $c->state
 483
 484 Contains the return value of the last executed action.
 485 Note that << $c->state >> operates in a scalar context which means that all
 486 values it returns are scalar.
 487
 488 =head2 $c->clear_errors
 489
 490 Clear errors.  You probably don't want to clear the errors unless you are
 491 implementing a custom error screen.
 492
 493 This is equivalent to running
 494
 495     $c->error(0);
 496
 497 =cut
 498
 499 sub clear_errors {
 500     my $c = shift;
 501     $c->error(0);
 502 }
 503
 504 sub _comp_search_prefixes {
 505     my $c = shift;
 506     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 507 }
 508
 509 # search components given a name and some prefixes
 510 sub _comp_names_search_prefixes {
 511     my ( $c, $name, @prefixes ) = @_;
 512     my $appclass = ref $c || $c;
 513     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 514     $filter = qr/$filter/; # Compile regex now rather than once per loop
 515
 516     # map the original component name to the sub part that we will search against
 517     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 518         grep { /$filter/ } keys %{ $c->components };
 519
 520     # undef for a name will return all
 521     return keys %eligible if !defined $name;
 522
 523     my $query  = ref $name ? $name : qr/^$name$/i;
 524     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 525
 526     return @result if @result;
 527
 528     # if we were given a regexp to search against, we're done.
 529     return if ref $name;
 530
 531     # skip regexp fallback if configured
 532     return
 533         if $appclass->config->{disable_component_resolution_regex_fallback};
 534
 535     # regexp fallback
 536     $query  = qr/$name/i;
 537     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 538
 539     # no results? try against full names
 540     if( !@result ) {
 541         @result = grep { m{$query} } keys %eligible;
 542     }
 543
 544     # don't warn if we didn't find any results, it just might not exist
 545     if( @result ) {
 546         # Disgusting hack to work out correct method name
 547         my $warn_for = lc $prefixes[0];
 548         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 549            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 550            "component resolution is unreliable and unsafe.";
 551         my $short = $result[0];
 552         # remove the component namespace prefix
 553         $short =~ s/.*?(Model|Controller|View):://;
 554         my $shortmess = Carp::shortmess('');
 555         if ($shortmess =~ m#Catalyst/Plugin#) {
 556            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 557               "plugin's config";
 558         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 559            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 560               "component's config";
 561         } else {
 562            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 563               "but if you really wanted to search, pass in a regexp as the argument " .
 564               "like so: \$c->${warn_for}(qr/${name}/)";
 565         }
 566         $c->log->warn( "${msg}$shortmess" );
 567     }
 568
 569     return @result;
 570 }
 571
 572 # Find possible names for a prefix
 573 sub _comp_names {
 574     my ( $c, @prefixes ) = @_;
 575     my $appclass = ref $c || $c;
 576
 577     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 578
 579     my @names = map { s{$filter}{}; $_; }
 580         $c->_comp_names_search_prefixes( undef, @prefixes );
 581
 582     return @names;
 583 }
 584
 585 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 586 sub _filter_component {
 587     my ( $c, $comp, @args ) = @_;
 588
 589     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 590         return $comp->ACCEPT_CONTEXT( $c, @args );
 591     }
 592
 593     return $comp;
 594 }
 595
 596 =head2 COMPONENT ACCESSORS
 597
 598 =head2 $c->controller($name)
 599
 600 Gets a L<Catalyst::Controller> instance by name.
 601
 602     $c->controller('Foo')->do_stuff;
 603
 604 If the name is omitted, will return the controller for the dispatched
 605 action.
 606
 607 If you want to search for controllers, pass in a regexp as the argument.
 608
 609     # find all controllers that start with Foo
 610     my @foo_controllers = $c->controller(qr{^Foo});
 611
 612
 613 =cut
 614
 615 sub controller {
 616     my ( $c, $name, @args ) = @_;
 617
 618     my $appclass = ref($c) || $c;
 619     if( $name ) {
 620         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 621             my $comps = $c->components;
 622             my $check = $appclass."::Controller::".$name;
 623             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 624         }
 625         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 626         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 627         return $c->_filter_component( $result[ 0 ], @args );
 628     }
 629
 630     return $c->component( $c->action->class );
 631 }
 632
 633 =head2 $c->model($name)
 634
 635 Gets a L<Catalyst::Model> instance by name.
 636
 637     $c->model('Foo')->do_stuff;
 638
 639 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 640
 641 If the name is omitted, it will look for
 642  - a model object in $c->stash->{current_model_instance}, then
 643  - a model name in $c->stash->{current_model}, then
 644  - a config setting 'default_model', or
 645  - check if there is only one model, and return it if that's the case.
 646
 647 If you want to search for models, pass in a regexp as the argument.
 648
 649     # find all models that start with Foo
 650     my @foo_models = $c->model(qr{^Foo});
 651
 652 =cut
 653
 654 sub model {
 655     my ( $c, $name, @args ) = @_;
 656     my $appclass = ref($c) || $c;
 657     if( $name ) {
 658         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 659             my $comps = $c->components;
 660             my $check = $appclass."::Model::".$name;
 661             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 662         }
 663         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 664         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 665         return $c->_filter_component( $result[ 0 ], @args );
 666     }
 667
 668     if (ref $c) {
 669         return $c->stash->{current_model_instance}
 670           if $c->stash->{current_model_instance};
 671         return $c->model( $c->stash->{current_model} )
 672           if $c->stash->{current_model};
 673     }
 674     return $c->model( $appclass->config->{default_model} )
 675       if $appclass->config->{default_model};
 676
 677     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 678
 679     if( $rest ) {
 680         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 681         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 682         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 683         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 684         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 685     }
 686
 687     return $c->_filter_component( $comp );
 688 }
 689
 690
 691 =head2 $c->view($name)
 692
 693 Gets a L<Catalyst::View> instance by name.
 694
 695     $c->view('Foo')->do_stuff;
 696
 697 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 698
 699 If the name is omitted, it will look for
 700  - a view object in $c->stash->{current_view_instance}, then
 701  - a view name in $c->stash->{current_view}, then
 702  - a config setting 'default_view', or
 703  - check if there is only one view, and return it if that's the case.
 704
 705 If you want to search for views, pass in a regexp as the argument.
 706
 707     # find all views that start with Foo
 708     my @foo_views = $c->view(qr{^Foo});
 709
 710 =cut
 711
 712 sub view {
 713     my ( $c, $name, @args ) = @_;
 714
 715     my $appclass = ref($c) || $c;
 716     if( $name ) {
 717         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 718             my $comps = $c->components;
 719             my $check = $appclass."::View::".$name;
 720             if( exists $comps->{$check} ) {
 721                 return $c->_filter_component( $comps->{$check}, @args );
 722             }
 723             else {
 724                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 725             }
 726         }
 727         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 728         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 729         return $c->_filter_component( $result[ 0 ], @args );
 730     }
 731
 732     if (ref $c) {
 733         return $c->stash->{current_view_instance}
 734           if $c->stash->{current_view_instance};
 735         return $c->view( $c->stash->{current_view} )
 736           if $c->stash->{current_view};
 737     }
 738     return $c->view( $appclass->config->{default_view} )
 739       if $appclass->config->{default_view};
 740
 741     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 742
 743     if( $rest ) {
 744         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 745         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 746         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 747         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 748         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 749     }
 750
 751     return $c->_filter_component( $comp );
 752 }
 753
 754 =head2 $c->controllers
 755
 756 Returns the available names which can be passed to $c->controller
 757
 758 =cut
 759
 760 sub controllers {
 761     my ( $c ) = @_;
 762     return $c->_comp_names(qw/Controller C/);
 763 }
 764
 765 =head2 $c->models
 766
 767 Returns the available names which can be passed to $c->model
 768
 769 =cut
 770
 771 sub models {
 772     my ( $c ) = @_;
 773     return $c->_comp_names(qw/Model M/);
 774 }
 775
 776
 777 =head2 $c->views
 778
 779 Returns the available names which can be passed to $c->view
 780
 781 =cut
 782
 783 sub views {
 784     my ( $c ) = @_;
 785     return $c->_comp_names(qw/View V/);
 786 }
 787
 788 =head2 $c->comp($name)
 789
 790 =head2 $c->component($name)
 791
 792 Gets a component object by name. This method is not recommended,
 793 unless you want to get a specific component by full
 794 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 795 should be used instead.
 796
 797 If C<$name> is a regexp, a list of components matched against the full
 798 component name will be returned.
 799
 800 If Catalyst can't find a component by name, it will fallback to regex
 801 matching by default. To disable this behaviour set
 802 disable_component_resolution_regex_fallback to a true value.
 803
 804     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 805
 806 =cut
 807
 808 sub component {
 809     my ( $c, $name, @args ) = @_;
 810
 811     if( $name ) {
 812         my $comps = $c->components;
 813
 814         if( !ref $name ) {
 815             # is it the exact name?
 816             return $c->_filter_component( $comps->{ $name }, @args )
 817                        if exists $comps->{ $name };
 818
 819             # perhaps we just omitted "MyApp"?
 820             my $composed = ( ref $c || $c ) . "::${name}";
 821             return $c->_filter_component( $comps->{ $composed }, @args )
 822                        if exists $comps->{ $composed };
 823
 824             # search all of the models, views and controllers
 825             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 826             return $c->_filter_component( $comp, @args ) if $comp;
 827         }
 828
 829         return
 830             if $c->config->{disable_component_resolution_regex_fallback};
 831
 832         # This is here so $c->comp( '::M::' ) works
 833         my $query = ref $name ? $name : qr{$name}i;
 834
 835         my @result = grep { m{$query} } keys %{ $c->components };
 836         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 837
 838         if( $result[ 0 ] ) {
 839             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 840             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 841             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 842             return $c->_filter_component( $result[ 0 ], @args );
 843         }
 844
 845         # I would expect to return an empty list here, but that breaks back-compat
 846     }
 847
 848     # fallback
 849     return sort keys %{ $c->components };
 850 }
 851
 852 =head2 CLASS DATA AND HELPER CLASSES
 853
 854 =head2 $c->config
 855
 856 Returns or takes a hashref containing the application's configuration.
 857
 858     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 859
 860 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 861 like C<myapp.conf> in your applications home directory. See
 862 L<Catalyst::Plugin::ConfigLoader>.
 863
 864 =head3 Cascading configuration
 865
 866 The config method is present on all Catalyst components, and configuration
 867 will be merged when an application is started. Configuration loaded with
 868 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 869 followed by configuration in your top level C<MyApp> class. These two
 870 configurations are merged, and then configuration data whose hash key matches a
 871 component name is merged with configuration for that component.
 872
 873 The configuration for a component is then passed to the C<new> method when a
 874 component is constructed.
 875
 876 For example:
 877
 878     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 879     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 880
 881 will mean that C<MyApp::Model::Foo> receives the following data when
 882 constructed:
 883
 884     MyApp::Model::Foo->new({
 885         bar => 'baz',
 886         quux => 'frob',
 887         overrides => 'me',
 888     });
 889
 890 It's common practice to use a Moose attribute
 891 on the receiving component to access the config value.
 892
 893     package MyApp::Model::Foo;
 894
 895     use Moose;
 896
 897     # this attr will receive 'baz' at construction time
 898     has 'bar' => (
 899         is  => 'rw',
 900         isa => 'Str',
 901     );
 902
 903 You can then get the value 'baz' by calling $c->model('Foo')->bar
 904 (or $self->bar inside code in the model).
 905
 906 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 907 as a way of reading config within your code, as this B<will not> give you the
 908 correctly merged config back. You B<MUST> take the config values supplied to
 909 the constructor and use those instead.
 910
 911 =cut
 912
 913 around config => sub {
 914     my $orig = shift;
 915     my $c = shift;
 916
 917     croak('Setting config after setup has been run is not allowed.')
 918         if ( @_ and $c->setup_finished );
 919
 920     $c->$orig(@_);
 921 };
 922
 923 =head2 $c->log
 924
 925 Returns the logging object instance. Unless it is already set, Catalyst
 926 sets this up with a L<Catalyst::Log> object. To use your own log class,
 927 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 928 C<< __PACKAGE__->setup >>.
 929
 930  __PACKAGE__->log( MyLogger->new );
 931  __PACKAGE__->setup;
 932
 933 And later:
 934
 935     $c->log->info( 'Now logging with my own logger!' );
 936
 937 Your log class should implement the methods described in
 938 L<Catalyst::Log>.
 939
 940
 941 =head2 $c->debug
 942
 943 Returns 1 if debug mode is enabled, 0 otherwise.
 944
 945 You can enable debug mode in several ways:
 946
 947 =over
 948
 949 =item By calling myapp_server.pl with the -d flag
 950
 951 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 952
 953 =item The -Debug option in your MyApp.pm
 954
 955 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 956
 957 =back
 958
 959 The first three also set the log level to 'debug'.
 960
 961 Calling C<< $c->debug(1) >> has no effect.
 962
 963 =cut
 964
 965 sub debug { 0 }
 966
 967 =head2 $c->dispatcher
 968
 969 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 970
 971 =head2 $c->engine
 972
 973 Returns the engine instance. See L<Catalyst::Engine>.
 974
 975
 976 =head2 UTILITY METHODS
 977
 978 =head2 $c->path_to(@path)
 979
 980 Merges C<@path> with C<< $c->config->{home} >> and returns a
 981 L<Path::Class::Dir> object. Note you can usually use this object as
 982 a filename, but sometimes you will have to explicitly stringify it
 983 yourself by calling the C<< ->stringify >> method.
 984
 985 For example:
 986
 987     $c->path_to( 'db', 'sqlite.db' );
 988
 989 =cut
 990
 991 sub path_to {
 992     my ( $c, @path ) = @_;
 993     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 994     if ( -d $path ) { return $path }
 995     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 996 }
 997
 998 =head2 $c->plugin( $name, $class, @args )
 999
1000 Helper method for plugins. It creates a class data accessor/mutator and
1001 loads and instantiates the given class.
1002
1003     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1004
1005     $c->prototype->define_javascript_functions;
1006
1007 B<Note:> This method of adding plugins is deprecated. The ability
1008 to add plugins like this B<will be removed> in a Catalyst 5.81.
1009 Please do not use this functionality in new code.
1010
1011 =cut
1012
1013 sub plugin {
1014     my ( $class, $name, $plugin, @args ) = @_;
1015
1016     # See block comment in t/unit_core_plugin.t
1017     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1018
1019     $class->_register_plugin( $plugin, 1 );
1020
1021     eval { $plugin->import };
1022     $class->mk_classdata($name);
1023     my $obj;
1024     eval { $obj = $plugin->new(@args) };
1025
1026     if ($@) {
1027         Catalyst::Exception->throw( message =>
1028               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1029     }
1030
1031     $class->$name($obj);
1032     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1033       if $class->debug;
1034 }
1035
1036 =head2 MyApp->setup
1037
1038 Initializes the dispatcher and engine, loads any plugins, and loads the
1039 model, view, and controller components. You may also specify an array
1040 of plugins to load here, if you choose to not load them in the C<use
1041 Catalyst> line.
1042
1043     MyApp->setup;
1044     MyApp->setup( qw/-Debug/ );
1045
1046 =cut
1047
1048 sub setup {
1049     my ( $class, @arguments ) = @_;
1050     croak('Running setup more than once')
1051         if ( $class->setup_finished );
1052
1053     unless ( $class->isa('Catalyst') ) {
1054
1055         Catalyst::Exception->throw(
1056             message => qq/'$class' does not inherit from Catalyst/ );
1057     }
1058
1059     if ( $class->arguments ) {
1060         @arguments = ( @arguments, @{ $class->arguments } );
1061     }
1062
1063     # Process options
1064     my $flags = {};
1065
1066     foreach (@arguments) {
1067
1068         if (/^-Debug$/) {
1069             $flags->{log} =
1070               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1071         }
1072         elsif (/^-(\w+)=?(.*)$/) {
1073             $flags->{ lc $1 } = $2;
1074         }
1075         else {
1076             push @{ $flags->{plugins} }, $_;
1077         }
1078     }
1079
1080     $class->setup_home( delete $flags->{home} );
1081
1082     $class->setup_log( delete $flags->{log} );
1083     $class->setup_plugins( delete $flags->{plugins} );
1084     $class->setup_dispatcher( delete $flags->{dispatcher} );
1085     if (my $engine = delete $flags->{engine}) {
1086         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1087     }
1088     $class->setup_engine();
1089     $class->setup_stats( delete $flags->{stats} );
1090
1091     for my $flag ( sort keys %{$flags} ) {
1092
1093         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1094             &$code( $class, delete $flags->{$flag} );
1095         }
1096         else {
1097             $class->log->warn(qq/Unknown flag "$flag"/);
1098         }
1099     }
1100
1101     eval { require Catalyst::Devel; };
1102     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1103         $class->log->warn(<<"EOF");
1104 You are running an old script!
1105
1106   Please update by running (this will overwrite existing files):
1107     catalyst.pl -force -scripts $class
1108
1109   or (this will not overwrite existing files):
1110     catalyst.pl -scripts $class
1111
1112 EOF
1113     }
1114
1115     if ( $class->debug ) {
1116         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1117
1118         if (@plugins) {
1119             my $column_width = Catalyst::Utils::term_width() - 6;
1120             my $t = Text::SimpleTable->new($column_width);
1121             $t->row($_) for @plugins;
1122             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1123         }
1124
1125         my $dispatcher = $class->dispatcher;
1126         my $engine     = $class->engine;
1127         my $home       = $class->config->{home};
1128
1129         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1130         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1131
1132         $home
1133           ? ( -d $home )
1134           ? $class->log->debug(qq/Found home "$home"/)
1135           : $class->log->debug(qq/Home "$home" doesn't exist/)
1136           : $class->log->debug(q/Couldn't find home/);
1137     }
1138
1139     # Call plugins setup, this is stupid and evil.
1140     # Also screws C3 badly on 5.10, hack to avoid.
1141     {
1142         no warnings qw/redefine/;
1143         local *setup = sub { };
1144         $class->setup unless $Catalyst::__AM_RESTARTING;
1145     }
1146
1147     # Initialize our data structure
1148     $class->components( {} );
1149
1150     $class->setup_components;
1151
1152     if ( $class->debug ) {
1153         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1154         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1155         for my $comp ( sort keys %{ $class->components } ) {
1156             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1157             $t->row( $comp, $type );
1158         }
1159         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1160           if ( keys %{ $class->components } );
1161     }
1162
1163     # Add our self to components, since we are also a component
1164     if( $class->isa('Catalyst::Controller') ){
1165       $class->components->{$class} = $class;
1166     }
1167
1168     $class->setup_actions;
1169
1170     if ( $class->debug ) {
1171         my $name = $class->config->{name} || 'Application';
1172         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1173     }
1174
1175     # Make sure that the application class becomes immutable at this point,
1176     B::Hooks::EndOfScope::on_scope_end {
1177         return if $@;
1178         my $meta = Class::MOP::get_metaclass_by_name($class);
1179         if (
1180             $meta->is_immutable
1181             && ! { $meta->immutable_options }->{replace_constructor}
1182             && (
1183                    $class->isa('Class::Accessor::Fast')
1184                 || $class->isa('Class::Accessor')
1185             )
1186         ) {
1187             warn "You made your application class ($class) immutable, "
1188                 . "but did not inline the\nconstructor. "
1189                 . "This will break catalyst, as your app \@ISA "
1190                 . "Class::Accessor(::Fast)?\nPlease pass "
1191                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1192         }
1193         $meta->make_immutable(
1194             replace_constructor => 1,
1195         ) unless $meta->is_immutable;
1196     };
1197
1198     if ($class->config->{case_sensitive}) {
1199         $class->log->warn($class . "->config->{case_sensitive} is set.");
1200         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1201     }
1202
1203     $class->setup_finalize;
1204     # Should be the last thing we do so that user things hooking
1205     # setup_finalize can log..
1206     $class->log->_flush() if $class->log->can('_flush');
1207     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1208 }
1209
1210 =head2 $app->setup_finalize
1211
1212 A hook to attach modifiers to. This method does not do anything except set the
1213 C<setup_finished> accessor.
1214
1215 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1216
1217 Example:
1218
1219     after setup_finalize => sub {
1220         my $app = shift;
1221
1222         ## do stuff here..
1223     };
1224
1225 =cut
1226
1227 sub setup_finalize {
1228     my ($class) = @_;
1229     $class->setup_finished(1);
1230 }
1231
1232 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1233
1234 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1235
1236 Constructs an absolute L<URI> object based on the application root, the
1237 provided path, and the additional arguments and query parameters provided.
1238 When used as a string, provides a textual URI.  If you need more flexibility
1239 than this (i.e. the option to provide relative URIs etc.) see
1240 L<Catalyst::Plugin::SmartURI>.
1241
1242 If no arguments are provided, the URI for the current action is returned.
1243 To return the current action and also provide @args, use
1244 C<< $c->uri_for( $c->action, @args ) >>.
1245
1246 If the first argument is a string, it is taken as a public URI path relative
1247 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1248 relative to the application root (if it does). It is then merged with
1249 C<< $c->request->base >>; any C<@args> are appended as additional path
1250 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1251
1252 If the first argument is a L<Catalyst::Action> it represents an action which
1253 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1254 optional C<\@captures> argument (an arrayref) allows passing the captured
1255 variables that are needed to fill in the paths of Chained and Regex actions;
1256 once the path is resolved, C<uri_for> continues as though a path was
1257 provided, appending any arguments or parameters and creating an absolute
1258 URI.
1259
1260 The captures for the current request can be found in
1261 C<< $c->request->captures >>, and actions can be resolved using
1262 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1263 path, use C<< $c->uri_for_action >> instead.
1264
1265   # Equivalent to $c->req->uri
1266   $c->uri_for($c->action, $c->req->captures,
1267       @{ $c->req->args }, $c->req->params);
1268
1269   # For the Foo action in the Bar controller
1270   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1271
1272   # Path to a static resource
1273   $c->uri_for('/static/images/logo.png');
1274
1275 =cut
1276
1277 sub uri_for {
1278     my ( $c, $path, @args ) = @_;
1279
1280     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1281         $path = $path->path_prefix;
1282         $path =~ s{/+\z}{};
1283         $path .= '/';
1284     }
1285
1286     undef($path) if (defined $path && $path eq '');
1287
1288     my $params =
1289       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1290
1291     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1292     foreach my $arg (@args) {
1293         utf8::encode($arg) if utf8::is_utf8($arg);
1294         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1295     }
1296
1297     if ( blessed($path) ) { # action object
1298         s|/|%2F|g for @args;
1299         my $captures = [ map { s|/|%2F|g; $_; }
1300                         ( scalar @args && ref $args[0] eq 'ARRAY'
1301                          ? @{ shift(@args) }
1302                          : ()) ];
1303
1304         foreach my $capture (@$captures) {
1305             utf8::encode($capture) if utf8::is_utf8($capture);
1306             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1307         }
1308
1309         my $action = $path;
1310         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1311         if( !@args && $action->number_of_args ) {
1312             my $expanded_action = $c->dispatcher->expand_action( $action );
1313
1314             my $num_captures = $expanded_action->number_of_captures;
1315             unshift @args, splice @$captures, $num_captures;
1316         }
1317
1318        $path = $c->dispatcher->uri_for_action($action, $captures);
1319         if (not defined $path) {
1320             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1321                 if $c->debug;
1322             return undef;
1323         }
1324         $path = '/' if $path eq '';
1325     }
1326
1327     unshift(@args, $path);
1328
1329     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1330         my $namespace = $c->namespace;
1331         if (defined $path) { # cheesy hack to handle path '../foo'
1332            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1333         }
1334         unshift(@args, $namespace || '');
1335     }
1336
1337     # join args with '/', or a blank string
1338     my $args = join('/', grep { defined($_) } @args);
1339     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1340     $args =~ s!^/+!!;
1341     my $base = $c->req->base;
1342     my $class = ref($base);
1343     $base =~ s{(?<!/)$}{/};
1344
1345     my $query = '';
1346
1347     if (my @keys = keys %$params) {
1348       # somewhat lifted from URI::_query's query_form
1349       $query = '?'.join('&', map {
1350           my $val = $params->{$_};
1351           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1352           s/ /+/g;
1353           my $key = $_;
1354           $val = '' unless defined $val;
1355           (map {
1356               my $param = "$_";
1357               utf8::encode( $param ) if utf8::is_utf8($param);
1358               # using the URI::Escape pattern here so utf8 chars survive
1359               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1360               $param =~ s/ /+/g;
1361               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1362       } @keys);
1363     }
1364
1365     my $res = bless(\"${base}${args}${query}", $class);
1366     $res;
1367 }
1368
1369 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1370
1371 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1372
1373 =over
1374
1375 =item $path
1376
1377 A private path to the Catalyst action you want to create a URI for.
1378
1379 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1380 >> and passing the resulting C<$action> and the remaining arguments to C<<
1381 $c->uri_for >>.
1382
1383 You can also pass in a Catalyst::Action object, in which case it is passed to
1384 C<< $c->uri_for >>.
1385
1386 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1387
1388 For example, if the action looks like:
1389
1390  package MyApp::Controller::Users;
1391
1392  sub lst : Path('the-list') {}
1393
1394 You can use:
1395
1396  $c->uri_for_action('/users/lst')
1397
1398 and it will create the URI /users/the-list.
1399
1400 =back
1401
1402 =cut
1403
1404 sub uri_for_action {
1405     my ( $c, $path, @args ) = @_;
1406     my $action = blessed($path)
1407       ? $path
1408       : $c->dispatcher->get_action_by_path($path);
1409     unless (defined $action) {
1410       croak "Can't find action for path '$path'";
1411     }
1412     return $c->uri_for( $action, @args );
1413 }
1414
1415 =head2 $c->welcome_message
1416
1417 Returns the Catalyst welcome HTML page.
1418
1419 =cut
1420
1421 sub welcome_message {
1422     my $c      = shift;
1423     my $name   = $c->config->{name};
1424     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1425     my $prefix = Catalyst::Utils::appprefix( ref $c );
1426     $c->response->content_type('text/html; charset=utf-8');
1427     return <<"EOF";
1428 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1429     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1430 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1431     <head>
1432     <meta http-equiv="Content-Language" content="en" />
1433     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1434         <title>$name on Catalyst $VERSION</title>
1435         <style type="text/css">
1436             body {
1437                 color: #000;
1438                 background-color: #eee;
1439             }
1440             div#content {
1441                 width: 640px;
1442                 margin-left: auto;
1443                 margin-right: auto;
1444                 margin-top: 10px;
1445                 margin-bottom: 10px;
1446                 text-align: left;
1447                 background-color: #ccc;
1448                 border: 1px solid #aaa;
1449             }
1450             p, h1, h2 {
1451                 margin-left: 20px;
1452                 margin-right: 20px;
1453                 font-family: verdana, tahoma, sans-serif;
1454             }
1455             a {
1456                 font-family: verdana, tahoma, sans-serif;
1457             }
1458             :link, :visited {
1459                     text-decoration: none;
1460                     color: #b00;
1461                     border-bottom: 1px dotted #bbb;
1462             }
1463             :link:hover, :visited:hover {
1464                     color: #555;
1465             }
1466             div#topbar {
1467                 margin: 0px;
1468             }
1469             pre {
1470                 margin: 10px;
1471                 padding: 8px;
1472             }
1473             div#answers {
1474                 padding: 8px;
1475                 margin: 10px;
1476                 background-color: #fff;
1477                 border: 1px solid #aaa;
1478             }
1479             h1 {
1480                 font-size: 0.9em;
1481                 font-weight: normal;
1482                 text-align: center;
1483             }
1484             h2 {
1485                 font-size: 1.0em;
1486             }
1487             p {
1488                 font-size: 0.9em;
1489             }
1490             p img {
1491                 float: right;
1492                 margin-left: 10px;
1493             }
1494             span#appname {
1495                 font-weight: bold;
1496                 font-size: 1.6em;
1497             }
1498         </style>
1499     </head>
1500     <body>
1501         <div id="content">
1502             <div id="topbar">
1503                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1504                     $VERSION</h1>
1505              </div>
1506              <div id="answers">
1507                  <p>
1508                  <img src="$logo" alt="Catalyst Logo" />
1509                  </p>
1510                  <p>Welcome to the  world of Catalyst.
1511                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1512                     framework will make web development something you had
1513                     never expected it to be: Fun, rewarding, and quick.</p>
1514                  <h2>What to do now?</h2>
1515                  <p>That really depends  on what <b>you</b> want to do.
1516                     We do, however, provide you with a few starting points.</p>
1517                  <p>If you want to jump right into web development with Catalyst
1518                     you might want to start with a tutorial.</p>
1519 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1520 </pre>
1521 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1522 <pre>
1523 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1524 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1525 </code></pre>
1526                  <h2>What to do next?</h2>
1527                  <p>Next it's time to write an actual application. Use the
1528                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1529                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1530                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1531                     they can save you a lot of work.</p>
1532                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1533                     <p>Also, be sure to check out the vast and growing
1534                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1535                     you are likely to find what you need there.
1536                     </p>
1537
1538                  <h2>Need help?</h2>
1539                  <p>Catalyst has a very active community. Here are the main places to
1540                     get in touch with us.</p>
1541                  <ul>
1542                      <li>
1543                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1544                      </li>
1545                      <li>
1546                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1547                      </li>
1548                      <li>
1549                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1550                      </li>
1551                  </ul>
1552                  <h2>In conclusion</h2>
1553                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1554                     as we enjoyed making it. Please contact us if you have ideas
1555                     for improvement or other feedback.</p>
1556              </div>
1557          </div>
1558     </body>
1559 </html>
1560 EOF
1561 }
1562
1563 =head1 INTERNAL METHODS
1564
1565 These methods are not meant to be used by end users.
1566
1567 =head2 $c->components
1568
1569 Returns a hash of components.
1570
1571 =head2 $c->context_class
1572
1573 Returns or sets the context class.
1574
1575 =head2 $c->counter
1576
1577 Returns a hashref containing coderefs and execution counts (needed for
1578 deep recursion detection).
1579
1580 =head2 $c->depth
1581
1582 Returns the number of actions on the current internal execution stack.
1583
1584 =head2 $c->dispatch
1585
1586 Dispatches a request to actions.
1587
1588 =cut
1589
1590 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1591
1592 =head2 $c->dispatcher_class
1593
1594 Returns or sets the dispatcher class.
1595
1596 =head2 $c->dump_these
1597
1598 Returns a list of 2-element array references (name, structure) pairs
1599 that will be dumped on the error page in debug mode.
1600
1601 =cut
1602
1603 sub dump_these {
1604     my $c = shift;
1605     [ Request => $c->req ],
1606     [ Response => $c->res ],
1607     [ Stash => $c->stash ],
1608     [ Config => $c->config ];
1609 }
1610
1611 =head2 $c->engine_class
1612
1613 Returns or sets the engine class.
1614
1615 =head2 $c->execute( $class, $coderef )
1616
1617 Execute a coderef in given class and catch exceptions. Errors are available
1618 via $c->error.
1619
1620 =cut
1621
1622 sub execute {
1623     my ( $c, $class, $code ) = @_;
1624     $class = $c->component($class) || $class;
1625     $c->state(0);
1626
1627     if ( $c->depth >= $RECURSION ) {
1628         my $action = $code->reverse();
1629         $action = "/$action" unless $action =~ /->/;
1630         my $error = qq/Deep recursion detected calling "${action}"/;
1631         $c->log->error($error);
1632         $c->error($error);
1633         $c->state(0);
1634         return $c->state;
1635     }
1636
1637     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1638
1639     push( @{ $c->stack }, $code );
1640
1641     no warnings 'recursion';
1642     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1643     #      I have no idea how, ergo $ret (which appears to fix the issue)
1644     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1645
1646     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1647
1648     my $last = pop( @{ $c->stack } );
1649
1650     if ( my $error = $@ ) {
1651         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1652             $error->rethrow if $c->depth > 1;
1653         }
1654         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1655             $error->rethrow if $c->depth > 0;
1656         }
1657         else {
1658             unless ( ref $error ) {
1659                 no warnings 'uninitialized';
1660                 chomp $error;
1661                 my $class = $last->class;
1662                 my $name  = $last->name;
1663                 $error = qq/Caught exception in $class->$name "$error"/;
1664             }
1665             $c->error($error);
1666         }
1667         $c->state(0);
1668     }
1669     return $c->state;
1670 }
1671
1672 sub _stats_start_execute {
1673     my ( $c, $code ) = @_;
1674     my $appclass = ref($c) || $c;
1675     return if ( ( $code->name =~ /^_.*/ )
1676         && ( !$appclass->config->{show_internal_actions} ) );
1677
1678     my $action_name = $code->reverse();
1679     $c->counter->{$action_name}++;
1680
1681     my $action = $action_name;
1682     $action = "/$action" unless $action =~ /->/;
1683
1684     # determine if the call was the result of a forward
1685     # this is done by walking up the call stack and looking for a calling
1686     # sub of Catalyst::forward before the eval
1687     my $callsub = q{};
1688     for my $index ( 2 .. 11 ) {
1689         last
1690         if ( ( caller($index) )[0] eq 'Catalyst'
1691             && ( caller($index) )[3] eq '(eval)' );
1692
1693         if ( ( caller($index) )[3] =~ /forward$/ ) {
1694             $callsub = ( caller($index) )[3];
1695             $action  = "-> $action";
1696             last;
1697         }
1698     }
1699
1700     my $uid = $action_name . $c->counter->{$action_name};
1701
1702     # is this a root-level call or a forwarded call?
1703     if ( $callsub =~ /forward$/ ) {
1704         my $parent = $c->stack->[-1];
1705
1706         # forward, locate the caller
1707         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1708             $c->stats->profile(
1709                 begin  => $action,
1710                 parent => "$parent" . $c->counter->{"$parent"},
1711                 uid    => $uid,
1712             );
1713         }
1714         else {
1715
1716             # forward with no caller may come from a plugin
1717             $c->stats->profile(
1718                 begin => $action,
1719                 uid   => $uid,
1720             );
1721         }
1722     }
1723     else {
1724
1725         # root-level call
1726         $c->stats->profile(
1727             begin => $action,
1728             uid   => $uid,
1729         );
1730     }
1731     return $action;
1732
1733 }
1734
1735 sub _stats_finish_execute {
1736     my ( $c, $info ) = @_;
1737     $c->stats->profile( end => $info );
1738 }
1739
1740 =head2 $c->finalize
1741
1742 Finalizes the request.
1743
1744 =cut
1745
1746 sub finalize {
1747     my $c = shift;
1748
1749     for my $error ( @{ $c->error } ) {
1750         $c->log->error($error);
1751     }
1752
1753     # Allow engine to handle finalize flow (for POE)
1754     my $engine = $c->engine;
1755     if ( my $code = $engine->can('finalize') ) {
1756         $engine->$code($c);
1757     }
1758     else {
1759
1760         $c->finalize_uploads;
1761
1762         # Error
1763         if ( $#{ $c->error } >= 0 ) {
1764             $c->finalize_error;
1765         }
1766
1767         $c->finalize_headers;
1768
1769         # HEAD request
1770         if ( $c->request->method eq 'HEAD' ) {
1771             $c->response->body('');
1772         }
1773
1774         $c->finalize_body;
1775     }
1776
1777     $c->log_response;
1778
1779     if ($c->use_stats) {
1780         my $elapsed = sprintf '%f', $c->stats->elapsed;
1781         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1782         $c->log->info(
1783             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1784     }
1785
1786     return $c->response->status;
1787 }
1788
1789 =head2 $c->finalize_body
1790
1791 Finalizes body.
1792
1793 =cut
1794
1795 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1796
1797 =head2 $c->finalize_cookies
1798
1799 Finalizes cookies.
1800
1801 =cut
1802
1803 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1804
1805 =head2 $c->finalize_error
1806
1807 Finalizes error.
1808
1809 =cut
1810
1811 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1812
1813 =head2 $c->finalize_headers
1814
1815 Finalizes headers.
1816
1817 =cut
1818
1819 sub finalize_headers {
1820     my $c = shift;
1821
1822     my $response = $c->response; #accessor calls can add up?
1823
1824     # Check if we already finalized headers
1825     return if $response->finalized_headers;
1826
1827     # Handle redirects
1828     if ( my $location = $response->redirect ) {
1829         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1830         $response->header( Location => $location );
1831
1832         if ( !$response->has_body ) {
1833             # Add a default body if none is already present
1834             $response->body(<<"EOF");
1835 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1836 <html xmlns="http://www.w3.org/1999/xhtml">
1837   <head>
1838     <title>Moved</title>
1839   </head>
1840   <body>
1841      <p>This item has moved <a href="$location">here</a>.</p>
1842   </body>
1843 </html>
1844 EOF
1845             $response->content_type('text/html; charset=utf-8');
1846         }
1847     }
1848
1849     # Content-Length
1850     if ( defined $response->body && length $response->body && !$response->content_length ) {
1851
1852         # get the length from a filehandle
1853         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1854         {
1855             my $size = -s $response->body;
1856             if ( $size ) {
1857                 $response->content_length( $size );
1858             }
1859             else {
1860                 $c->log->warn('Serving filehandle without a content-length');
1861             }
1862         }
1863         else {
1864             # everything should be bytes at this point, but just in case
1865             $response->content_length( length( $response->body ) );
1866         }
1867     }
1868
1869     # Errors
1870     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1871         $response->headers->remove_header("Content-Length");
1872         $response->body('');
1873     }
1874
1875     $c->finalize_cookies;
1876
1877     $c->engine->finalize_headers( $c, @_ );
1878
1879     # Done
1880     $response->finalized_headers(1);
1881 }
1882
1883 =head2 $c->finalize_output
1884
1885 An alias for finalize_body.
1886
1887 =head2 $c->finalize_read
1888
1889 Finalizes the input after reading is complete.
1890
1891 =cut
1892
1893 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1894
1895 =head2 $c->finalize_uploads
1896
1897 Finalizes uploads. Cleans up any temporary files.
1898
1899 =cut
1900
1901 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1902
1903 =head2 $c->get_action( $action, $namespace )
1904
1905 Gets an action in a given namespace.
1906
1907 =cut
1908
1909 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1910
1911 =head2 $c->get_actions( $action, $namespace )
1912
1913 Gets all actions of a given name in a namespace and all parent
1914 namespaces.
1915
1916 =cut
1917
1918 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1919
1920 =head2 $app->handle_request( @arguments )
1921
1922 Called to handle each HTTP request.
1923
1924 =cut
1925
1926 sub handle_request {
1927     my ( $class, @arguments ) = @_;
1928
1929     # Always expect worst case!
1930     my $status = -1;
1931     try {
1932         if ($class->debug) {
1933             my $secs = time - $START || 1;
1934             my $av = sprintf '%.3f', $COUNT / $secs;
1935             my $time = localtime time;
1936             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1937         }
1938
1939         my $c = $class->prepare(@arguments);
1940         $c->dispatch;
1941         $status = $c->finalize;
1942     }
1943     catch {
1944         chomp(my $error = $_);
1945         $class->log->error(qq/Caught exception in engine "$error"/);
1946     };
1947
1948     $COUNT++;
1949
1950     if(my $coderef = $class->log->can('_flush')){
1951         $class->log->$coderef();
1952     }
1953     return $status;
1954 }
1955
1956 =head2 $class->prepare( @arguments )
1957
1958 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1959 etc.).
1960
1961 =cut
1962
1963 sub prepare {
1964     my ( $class, @arguments ) = @_;
1965
1966     # XXX
1967     # After the app/ctxt split, this should become an attribute based on something passed
1968     # into the application.
1969     $class->context_class( ref $class || $class ) unless $class->context_class;
1970
1971     my $c = $class->context_class->new({});
1972
1973     # For on-demand data
1974     $c->request->_context($c);
1975     $c->response->_context($c);
1976
1977     #surely this is not the most efficient way to do things...
1978     $c->stats($class->stats_class->new)->enable($c->use_stats);
1979     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1980         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1981     }
1982
1983     try {
1984         # Allow engine to direct the prepare flow (for POE)
1985         if ( my $prepare = $c->engine->can('prepare') ) {
1986             $c->engine->$prepare( $c, @arguments );
1987         }
1988         else {
1989             $c->prepare_request(@arguments);
1990             $c->prepare_connection;
1991             $c->prepare_query_parameters;
1992             $c->prepare_headers;
1993             $c->prepare_cookies;
1994             $c->prepare_path;
1995
1996             # Prepare the body for reading, either by prepare_body
1997             # or the user, if they are using $c->read
1998             $c->prepare_read;
1999
2000             # Parse the body unless the user wants it on-demand
2001             unless ( ref($c)->config->{parse_on_demand} ) {
2002                 $c->prepare_body;
2003             }
2004         }
2005     }
2006     # VERY ugly and probably shouldn't rely on ->finalize actually working
2007     catch {
2008         # failed prepare is always due to an invalid request, right?
2009         $c->response->status(400);
2010         $c->response->content_type('text/plain');
2011         $c->response->body('Bad Request');
2012         $c->finalize;
2013         die $_;
2014     };
2015
2016     my $method  = $c->req->method  || '';
2017     my $path    = $c->req->path;
2018     $path       = '/' unless length $path;
2019     my $address = $c->req->address || '';
2020
2021     $c->log_request;
2022
2023     $c->prepare_action;
2024
2025     return $c;
2026 }
2027
2028 =head2 $c->prepare_action
2029
2030 Prepares action. See L<Catalyst::Dispatcher>.
2031
2032 =cut
2033
2034 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2035
2036 =head2 $c->prepare_body
2037
2038 Prepares message body.
2039
2040 =cut
2041
2042 sub prepare_body {
2043     my $c = shift;
2044
2045     return if $c->request->_has_body;
2046
2047     # Initialize on-demand data
2048     $c->engine->prepare_body( $c, @_ );
2049     $c->prepare_parameters;
2050     $c->prepare_uploads;
2051 }
2052
2053 =head2 $c->prepare_body_chunk( $chunk )
2054
2055 Prepares a chunk of data before sending it to L<HTTP::Body>.
2056
2057 See L<Catalyst::Engine>.
2058
2059 =cut
2060
2061 sub prepare_body_chunk {
2062     my $c = shift;
2063     $c->engine->prepare_body_chunk( $c, @_ );
2064 }
2065
2066 =head2 $c->prepare_body_parameters
2067
2068 Prepares body parameters.
2069
2070 =cut
2071
2072 sub prepare_body_parameters {
2073     my $c = shift;
2074     $c->engine->prepare_body_parameters( $c, @_ );
2075 }
2076
2077 =head2 $c->prepare_connection
2078
2079 Prepares connection.
2080
2081 =cut
2082
2083 sub prepare_connection {
2084     my $c = shift;
2085     $c->engine->prepare_connection( $c, @_ );
2086 }
2087
2088 =head2 $c->prepare_cookies
2089
2090 Prepares cookies.
2091
2092 =cut
2093
2094 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2095
2096 =head2 $c->prepare_headers
2097
2098 Prepares headers.
2099
2100 =cut
2101
2102 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2103
2104 =head2 $c->prepare_parameters
2105
2106 Prepares parameters.
2107
2108 =cut
2109
2110 sub prepare_parameters {
2111     my $c = shift;
2112     $c->prepare_body_parameters;
2113     $c->engine->prepare_parameters( $c, @_ );
2114 }
2115
2116 =head2 $c->prepare_path
2117
2118 Prepares path and base.
2119
2120 =cut
2121
2122 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2123
2124 =head2 $c->prepare_query_parameters
2125
2126 Prepares query parameters.
2127
2128 =cut
2129
2130 sub prepare_query_parameters {
2131     my $c = shift;
2132
2133     $c->engine->prepare_query_parameters( $c, @_ );
2134 }
2135
2136 =head2 $c->log_request
2137
2138 Writes information about the request to the debug logs.  This includes:
2139
2140 =over 4
2141
2142 =item * Request method, path, and remote IP address
2143
2144 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2145
2146 =item * Request parameters
2147
2148 =item * File uploads
2149
2150 =back
2151
2152 =cut
2153
2154 sub log_request {
2155     my $c = shift;
2156
2157     return unless $c->debug;
2158
2159     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2160     my $request = $dump->[1];
2161
2162     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2163     $method ||= '';
2164     $path = '/' unless length $path;
2165     $address ||= '';
2166     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2167
2168     $c->log_request_headers($request->headers);
2169
2170     if ( my $keywords = $request->query_keywords ) {
2171         $c->log->debug("Query keywords are: $keywords");
2172     }
2173
2174     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2175
2176     $c->log_request_uploads($request);
2177 }
2178
2179 =head2 $c->log_response
2180
2181 Writes information about the response to the debug logs by calling
2182 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2183
2184 =cut
2185
2186 sub log_response {
2187     my $c = shift;
2188
2189     return unless $c->debug;
2190
2191     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2192     my $response = $dump->[1];
2193
2194     $c->log_response_status_line($response);
2195     $c->log_response_headers($response->headers);
2196 }
2197
2198 =head2 $c->log_response_status_line($response)
2199
2200 Writes one line of information about the response to the debug logs.  This includes:
2201
2202 =over 4
2203
2204 =item * Response status code
2205
2206 =item * Content-Type header (if present)
2207
2208 =item * Content-Length header (if present)
2209
2210 =back
2211
2212 =cut
2213
2214 sub log_response_status_line {
2215     my ($c, $response) = @_;
2216
2217     $c->log->debug(
2218         sprintf(
2219             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2220             $response->status                            || 'unknown',
2221             $response->headers->header('Content-Type')   || 'unknown',
2222             $response->headers->header('Content-Length') || 'unknown'
2223         )
2224     );
2225 }
2226
2227 =head2 $c->log_response_headers($headers);
2228
2229 Hook method which can be wrapped by plugins to log the response headers.
2230 No-op in the default implementation.
2231
2232 =cut
2233
2234 sub log_response_headers {}
2235
2236 =head2 $c->log_request_parameters( query => {}, body => {} )
2237
2238 Logs request parameters to debug logs
2239
2240 =cut
2241
2242 sub log_request_parameters {
2243     my $c          = shift;
2244     my %all_params = @_;
2245
2246     return unless $c->debug;
2247
2248     my $column_width = Catalyst::Utils::term_width() - 44;
2249     foreach my $type (qw(query body)) {
2250         my $params = $all_params{$type};
2251         next if ! keys %$params;
2252         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2253         for my $key ( sort keys %$params ) {
2254             my $param = $params->{$key};
2255             my $value = defined($param) ? $param : '';
2256             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2257         }
2258         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2259     }
2260 }
2261
2262 =head2 $c->log_request_uploads
2263
2264 Logs file uploads included in the request to the debug logs.
2265 The parameter name, filename, file type, and file size are all included in
2266 the debug logs.
2267
2268 =cut
2269
2270 sub log_request_uploads {
2271     my $c = shift;
2272     my $request = shift;
2273     return unless $c->debug;
2274     my $uploads = $request->uploads;
2275     if ( keys %$uploads ) {
2276         my $t = Text::SimpleTable->new(
2277             [ 12, 'Parameter' ],
2278             [ 26, 'Filename' ],
2279             [ 18, 'Type' ],
2280             [ 9,  'Size' ]
2281         );
2282         for my $key ( sort keys %$uploads ) {
2283             my $upload = $uploads->{$key};
2284             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2285                 $t->row( $key, $u->filename, $u->type, $u->size );
2286             }
2287         }
2288         $c->log->debug( "File Uploads are:\n" . $t->draw );
2289     }
2290 }
2291
2292 =head2 $c->log_request_headers($headers);
2293
2294 Hook method which can be wrapped by plugins to log the request headers.
2295 No-op in the default implementation.
2296
2297 =cut
2298
2299 sub log_request_headers {}
2300
2301 =head2 $c->log_headers($type => $headers)
2302
2303 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2304
2305 =cut
2306
2307 sub log_headers {
2308     my $c       = shift;
2309     my $type    = shift;
2310     my $headers = shift;    # an HTTP::Headers instance
2311
2312     return unless $c->debug;
2313
2314     my $column_width = Catalyst::Utils::term_width() - 28;
2315     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2316     $headers->scan(
2317         sub {
2318             my ( $name, $value ) = @_;
2319             $t->row( $name, $value );
2320         }
2321     );
2322     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2323 }
2324
2325
2326 =head2 $c->prepare_read
2327
2328 Prepares the input for reading.
2329
2330 =cut
2331
2332 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2333
2334 =head2 $c->prepare_request
2335
2336 Prepares the engine request.
2337
2338 =cut
2339
2340 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2341
2342 =head2 $c->prepare_uploads
2343
2344 Prepares uploads.
2345
2346 =cut
2347
2348 sub prepare_uploads {
2349     my $c = shift;
2350
2351     $c->engine->prepare_uploads( $c, @_ );
2352 }
2353
2354 =head2 $c->prepare_write
2355
2356 Prepares the output for writing.
2357
2358 =cut
2359
2360 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2361
2362 =head2 $c->request_class
2363
2364 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2365
2366 =head2 $c->response_class
2367
2368 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2369
2370 =head2 $c->read( [$maxlength] )
2371
2372 Reads a chunk of data from the request body. This method is designed to
2373 be used in a while loop, reading C<$maxlength> bytes on every call.
2374 C<$maxlength> defaults to the size of the request if not specified.
2375
2376 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2377 directly.
2378
2379 Warning: If you use read(), Catalyst will not process the body,
2380 so you will not be able to access POST parameters or file uploads via
2381 $c->request.  You must handle all body parsing yourself.
2382
2383 =cut
2384
2385 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2386
2387 =head2 $c->run
2388
2389 Starts the engine.
2390
2391 =cut
2392
2393 sub run {
2394   my $app = shift;
2395   $app->engine_loader->needs_psgi_engine_compat_hack ?
2396     $app->engine->run($app, @_) :
2397       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2398 }
2399
2400 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2401
2402 Sets an action in a given namespace.
2403
2404 =cut
2405
2406 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2407
2408 =head2 $c->setup_actions($component)
2409
2410 Sets up actions for a component.
2411
2412 =cut
2413
2414 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2415
2416 =head2 $c->setup_components
2417
2418 This method is called internally to set up the application's components.
2419
2420 It finds modules by calling the L<locate_components> method, expands them to
2421 package names with the L<expand_component_module> method, and then installs
2422 each component into the application.
2423
2424 The C<setup_components> config option is passed to both of the above methods.
2425
2426 Installation of each component is performed by the L<setup_component> method,
2427 below.
2428
2429 =cut
2430
2431 sub setup_components {
2432     my $class = shift;
2433
2434     my $config  = $class->config->{ setup_components };
2435
2436     my @comps = $class->locate_components($config);
2437     my %comps = map { $_ => 1 } @comps;
2438
2439     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2440     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2441         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2442     ) if $deprecatedcatalyst_component_names;
2443
2444     for my $component ( @comps ) {
2445
2446         # We pass ignore_loaded here so that overlay files for (e.g.)
2447         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2448         # we know M::P::O found a file on disk so this is safe
2449
2450         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2451     }
2452
2453     for my $component (@comps) {
2454         my $instance = $class->components->{ $component } = $class->setup_component($component);
2455         my @expanded_components = $instance->can('expand_modules')
2456             ? $instance->expand_modules( $component, $config )
2457             : $class->expand_component_module( $component, $config );
2458         for my $component (@expanded_components) {
2459             next if $comps{$component};
2460             $class->components->{ $component } = $class->setup_component($component);
2461         }
2462     }
2463 }
2464
2465 =head2 $c->locate_components( $setup_component_config )
2466
2467 This method is meant to provide a list of component modules that should be
2468 setup for the application.  By default, it will use L<Module::Pluggable>.
2469
2470 Specify a C<setup_components> config option to pass additional options directly
2471 to L<Module::Pluggable>. To add additional search paths, specify a key named
2472 C<search_extra> as an array reference. Items in the array beginning with C<::>
2473 will have the application class name prepended to them.
2474
2475 =cut
2476
2477 sub locate_components {
2478     my $class  = shift;
2479     my $config = shift;
2480
2481     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2482     my $extra   = delete $config->{ search_extra } || [];
2483
2484     push @paths, @$extra;
2485
2486     my $locator = Module::Pluggable::Object->new(
2487         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2488         %$config
2489     );
2490
2491     # XXX think about ditching this sort entirely
2492     my @comps = sort { length $a <=> length $b } $locator->plugins;
2493
2494     return @comps;
2495 }
2496
2497 =head2 $c->expand_component_module( $component, $setup_component_config )
2498
2499 Components found by C<locate_components> will be passed to this method, which
2500 is expected to return a list of component (package) names to be set up.
2501
2502 =cut
2503
2504 sub expand_component_module {
2505     my ($class, $module) = @_;
2506     return Devel::InnerPackage::list_packages( $module );
2507 }
2508
2509 =head2 $c->setup_component
2510
2511 =cut
2512
2513 sub setup_component {
2514     my( $class, $component ) = @_;
2515
2516     unless ( $component->can( 'COMPONENT' ) ) {
2517         return $component;
2518     }
2519
2520     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2521     my $config = $class->config->{ $suffix } || {};
2522     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2523     # methods also pass it. local to avoid pointlessly shitting in config
2524     # for the debug screen, as $component is already the key name.
2525     local $config->{catalyst_component_name} = $component;
2526
2527     my $instance = eval { $component->COMPONENT( $class, $config ); };
2528
2529     if ( my $error = $@ ) {
2530         chomp $error;
2531         Catalyst::Exception->throw(
2532             message => qq/Couldn't instantiate component "$component", "$error"/
2533         );
2534     }
2535
2536     unless (blessed $instance) {
2537         my $metaclass = Moose::Util::find_meta($component);
2538         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2539         my $component_method_from = $method_meta->associated_metaclass->name;
2540         my $value = defined($instance) ? $instance : 'undef';
2541         Catalyst::Exception->throw(
2542             message =>
2543             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2544         );
2545     }
2546     return $instance;
2547 }
2548
2549 =head2 $c->setup_dispatcher
2550
2551 Sets up dispatcher.
2552
2553 =cut
2554
2555 sub setup_dispatcher {
2556     my ( $class, $dispatcher ) = @_;
2557
2558     if ($dispatcher) {
2559         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2560     }
2561
2562     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2563         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2564     }
2565
2566     unless ($dispatcher) {
2567         $dispatcher = $class->dispatcher_class;
2568     }
2569
2570     Class::MOP::load_class($dispatcher);
2571
2572     # dispatcher instance
2573     $class->dispatcher( $dispatcher->new );
2574 }
2575
2576 =head2 $c->setup_engine
2577
2578 Sets up engine.
2579
2580 =cut
2581
2582 sub engine_class {
2583     my ($class, $requested_engine) = @_;
2584
2585     if (!$class->engine_loader || $requested_engine) {
2586         $class->engine_loader(
2587             Catalyst::EngineLoader->new({
2588                 application_name => $class,
2589                 (defined $requested_engine
2590                      ? (catalyst_engine_class => $requested_engine) : ()),
2591             }),
2592         );
2593     }
2594
2595     $class->engine_loader->catalyst_engine_class;
2596 }
2597
2598 sub setup_engine {
2599     my ($class, $requested_engine) = @_;
2600
2601     my $engine = do {
2602         my $loader = $class->engine_loader;
2603
2604         if (!$loader || $requested_engine) {
2605             $loader = Catalyst::EngineLoader->new({
2606                 application_name => $class,
2607                 (defined $requested_engine
2608                      ? (requested_engine => $requested_engine) : ()),
2609             }),
2610
2611             $class->engine_loader($loader);
2612         }
2613
2614         $loader->catalyst_engine_class;
2615     };
2616
2617     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2618     return if $class->loading_psgi_file;
2619
2620     Class::MOP::load_class($engine);
2621
2622     if ($ENV{MOD_PERL}) {
2623         my $apache = $class->engine_loader->auto;
2624
2625         my $meta = find_meta($class);
2626         my $was_immutable = $meta->is_immutable;
2627         my %immutable_options = $meta->immutable_options;
2628         $meta->make_mutable if $was_immutable;
2629
2630         $meta->add_method(handler => sub {
2631             my $r = shift;
2632             my $psgi_app = $class->psgi_app;
2633             $apache->call_app($r, $psgi_app);
2634         });
2635
2636         $meta->make_immutable(%immutable_options) if $was_immutable;
2637     }
2638
2639     $class->engine( $engine->new );
2640
2641     return;
2642 }
2643
2644 sub _finalized_psgi_app {
2645     my ($app) = @_;
2646
2647     unless ($app->_psgi_app) {
2648         my $psgi_app = $app->_setup_psgi_app;
2649         $app->_psgi_app($psgi_app);
2650     }
2651
2652     return $app->_psgi_app;
2653 }
2654
2655 sub _setup_psgi_app {
2656     my ($app) = @_;
2657
2658     for my $home (Path::Class::Dir->new($app->config->{home})) {
2659         my $psgi_file = $home->file(
2660             Catalyst::Utils::appprefix($app) . '.psgi',
2661         );
2662
2663         next unless -e $psgi_file;
2664
2665         # If $psgi_file calls ->setup_engine, it's doing so to load
2666         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2667         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2668         # anyway. So set a flag (ick) that tells setup_engine not to populate
2669         # $c->engine or do any other things we might regret.
2670
2671         $app->loading_psgi_file(1);
2672         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2673         $app->loading_psgi_file(0);
2674
2675         return $psgi_app
2676             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2677
2678         warn <<"EOW";
2679 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2680
2681 Its content has been ignored. Please consult the Catalyst::Upgrading
2682 documentation on how to upgrade from Catalyst::Engine::PSGI.
2683 EOW
2684     }
2685
2686     return $app->apply_default_middlewares($app->psgi_app);
2687 }
2688
2689 =head2 $c->apply_default_middlewares
2690
2691 Adds the following L<Plack> middlewares to your application, since they are
2692 useful and commonly needed:
2693
2694 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2695 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2696 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2697 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2698 applied since this middleware is smart enough to conditionally apply itself).
2699
2700 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2701 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2702 $ENV{SCRIPT_NAME}
2703
2704 =cut
2705
2706
2707 sub apply_default_middlewares {
2708     my ($app, $psgi_app) = @_;
2709
2710     $psgi_app = Plack::Middleware::Conditional->wrap(
2711         $psgi_app,
2712         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2713         condition => sub {
2714             my ($env) = @_;
2715             return if $app->config->{ignore_frontend_proxy};
2716             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2717                 || $app->config->{using_frontend_proxy};
2718         },
2719     );
2720
2721     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2722     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2723     $psgi_app = Plack::Middleware::LighttpdScriptNameFix->wrap($psgi_app);
2724
2725     # we're applying this unconditionally as the middleware itself already makes
2726     # sure it doesn't fuck things up if it's not running under one of the right
2727     # IIS versions
2728     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2729
2730     return $psgi_app;
2731 }
2732
2733 =head2 $c->psgi_app
2734
2735 Returns a PSGI application code reference for the catalyst application
2736 C<$c>. This is the bare application without any middlewares
2737 applied. C<${myapp}.psgi> is not taken into account.
2738
2739 This is what you want to be using to retrieve the PSGI application code
2740 reference of your Catalyst application for use in F<.psgi> files.
2741
2742 =cut
2743
2744 sub psgi_app {
2745     my ($app) = @_;
2746     return $app->engine->build_psgi_app($app);
2747 }
2748
2749 =head2 $c->setup_home
2750
2751 Sets up the home directory.
2752
2753 =cut
2754
2755 sub setup_home {
2756     my ( $class, $home ) = @_;
2757
2758     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2759         $home = $env;
2760     }
2761
2762     $home ||= Catalyst::Utils::home($class);
2763
2764     if ($home) {
2765         #I remember recently being scolded for assigning config values like this
2766         $class->config->{home} ||= $home;
2767         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2768     }
2769 }
2770
2771 =head2 $c->setup_log
2772
2773 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2774 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2775 log to.
2776
2777 This method also installs a C<debug> method that returns a true value into the
2778 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2779 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2780
2781 Note that if the log has already been setup, by either a previous call to
2782 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2783 that this method won't actually set up the log object.
2784
2785 =cut
2786
2787 sub setup_log {
2788     my ( $class, $levels ) = @_;
2789
2790     $levels ||= '';
2791     $levels =~ s/^\s+//;
2792     $levels =~ s/\s+$//;
2793     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2794
2795     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2796     if ( defined $env_debug ) {
2797         $levels{debug} = 1 if $env_debug; # Ugly!
2798         delete($levels{debug}) unless $env_debug;
2799     }
2800
2801     unless ( $class->log ) {
2802         $class->log( Catalyst::Log->new(keys %levels) );
2803     }
2804
2805     if ( $levels{debug} ) {
2806         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2807         $class->log->debug('Debug messages enabled');
2808     }
2809 }
2810
2811 =head2 $c->setup_plugins
2812
2813 Sets up plugins.
2814
2815 =cut
2816
2817 =head2 $c->setup_stats
2818
2819 Sets up timing statistics class.
2820
2821 =cut
2822
2823 sub setup_stats {
2824     my ( $class, $stats ) = @_;
2825
2826     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2827
2828     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2829     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2830         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2831         $class->log->debug('Statistics enabled');
2832     }
2833 }
2834
2835
2836 =head2 $c->registered_plugins
2837
2838 Returns a sorted list of the plugins which have either been stated in the
2839 import list or which have been added via C<< MyApp->plugin(@args); >>.
2840
2841 If passed a given plugin name, it will report a boolean value indicating
2842 whether or not that plugin is loaded.  A fully qualified name is required if
2843 the plugin name does not begin with C<Catalyst::Plugin::>.
2844
2845  if ($c->registered_plugins('Some::Plugin')) {
2846      ...
2847  }
2848
2849 =cut
2850
2851 {
2852
2853     sub registered_plugins {
2854         my $proto = shift;
2855         return sort keys %{ $proto->_plugins } unless @_;
2856         my $plugin = shift;
2857         return 1 if exists $proto->_plugins->{$plugin};
2858         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2859     }
2860
2861     sub _register_plugin {
2862         my ( $proto, $plugin, $instant ) = @_;
2863         my $class = ref $proto || $proto;
2864
2865         Class::MOP::load_class( $plugin );
2866         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2867             if $plugin->isa( 'Catalyst::Component' );
2868         $proto->_plugins->{$plugin} = 1;
2869         unless ($instant) {
2870             my $meta = Class::MOP::get_metaclass_by_name($class);
2871             $meta->superclasses($plugin, $meta->superclasses);
2872         }
2873         return $class;
2874     }
2875
2876     sub setup_plugins {
2877         my ( $class, $plugins ) = @_;
2878
2879         $class->_plugins( {} ) unless $class->_plugins;
2880         $plugins = Data::OptList::mkopt($plugins || []);
2881
2882         my @plugins = map {
2883             [ Catalyst::Utils::resolve_namespace(
2884                   $class . '::Plugin',
2885                   'Catalyst::Plugin', $_->[0]
2886               ),
2887               $_->[1],
2888             ]
2889          } @{ $plugins };
2890
2891         for my $plugin ( reverse @plugins ) {
2892             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2893             my $meta = find_meta($plugin->[0]);
2894             next if $meta && $meta->isa('Moose::Meta::Role');
2895
2896             $class->_register_plugin($plugin->[0]);
2897         }
2898
2899         my @roles =
2900             map  { $_->[0]->name, $_->[1] }
2901             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2902             map  { [find_meta($_->[0]), $_->[1]] }
2903             @plugins;
2904
2905         Moose::Util::apply_all_roles(
2906             $class => @roles
2907         ) if @roles;
2908     }
2909 }
2910
2911 =head2 $c->stack
2912
2913 Returns an arrayref of the internal execution stack (actions that are
2914 currently executing).
2915
2916 =head2 $c->stats
2917
2918 Returns the current timing statistics object. By default Catalyst uses
2919 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2920 L<< stats_class|/"$c->stats_class" >>.
2921
2922 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2923 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2924 profile explicitly, although MyApp.pm still won't profile nor output anything
2925 by itself.
2926
2927 =head2 $c->stats_class
2928
2929 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2930
2931 =head2 $c->use_stats
2932
2933 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2934
2935 Note that this is a static method, not an accessor and should be overridden
2936 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2937
2938 =cut
2939
2940 sub use_stats { 0 }
2941
2942
2943 =head2 $c->write( $data )
2944
2945 Writes $data to the output stream. When using this method directly, you
2946 will need to manually set the C<Content-Length> header to the length of
2947 your output data, if known.
2948
2949 =cut
2950
2951 sub write {
2952     my $c = shift;
2953
2954     # Finalize headers if someone manually writes output
2955     $c->finalize_headers;
2956
2957     return $c->engine->write( $c, @_ );
2958 }
2959
2960 =head2 version
2961
2962 Returns the Catalyst version number. Mostly useful for "powered by"
2963 messages in template systems.
2964
2965 =cut
2966
2967 sub version { return $Catalyst::VERSION }
2968
2969 =head1 CONFIGURATION
2970
2971 There are a number of 'base' config variables which can be set:
2972
2973 =over
2974
2975 =item *
2976
2977 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2978
2979 =item *
2980
2981 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2982
2983 =item *
2984
2985 C<disable_component_resolution_regex_fallback> - Turns
2986 off the deprecated component resolution functionality so
2987 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2988 are called then regex search will not be attempted on string values and
2989 instead C<undef> will be returned.
2990
2991 =item *
2992
2993 C<home> - The application home directory. In an uninstalled application,
2994 this is the top level application directory. In an installed application,
2995 this will be the directory containing C<< MyApp.pm >>.
2996
2997 =item *
2998
2999 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3000
3001 =item *
3002
3003 C<name> - The name of the application in debug messages and the debug and
3004 welcome screens
3005
3006 =item *
3007
3008 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3009 until it is accessed. This allows you to (for example) check authentication (and reject
3010 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3011
3012 =item *
3013
3014 C<root> - The root directory for templates. Usually this is just a
3015 subdirectory of the home directory, but you can set it to change the
3016 templates to a different directory.
3017
3018 =item *
3019
3020 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3021 namespaces from which components will be loaded (and constructed and stored in
3022 C<< $c->components >>).
3023
3024 =item *
3025
3026 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3027 to be shown in hit debug tables in the test server.
3028
3029 =item *
3030
3031 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
3032 variable should be used for determining the request path.
3033
3034 Most web server environments pass the requested path to the application using environment variables,
3035 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3036 exposed as C<< $c->request->base >>) and the request path below that base.
3037
3038 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3039 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3040
3041 =over
3042
3043 =item use_request_uri_for_path => 0
3044
3045 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3046 The path is synthesised from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3047 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3048 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3049
3050 However this method has the major disadvantage that it is impossible to correctly decode some elements
3051 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3052 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3053 can't distinguish / vs %2F in paths (in addition to other encoded values).
3054
3055 =item use_request_uri_for_path => 1
3056
3057 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3058 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3059 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3060
3061 Given that this method of path resolution is provably more correct, it is recommended that you use
3062 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3063 aware of the implications of not being able to handle encoded URI paths correctly.
3064
3065 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3066 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3067 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3068 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3069 C<< $c->request->base >> will be incorrect.
3070
3071 =back
3072
3073 =item *
3074
3075 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3076
3077 =back
3078
3079 =head1 INTERNAL ACTIONS
3080
3081 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3082 C<_ACTION>, and C<_END>. These are by default not shown in the private
3083 action table, but you can make them visible with a config parameter.
3084
3085     MyApp->config(show_internal_actions => 1);
3086
3087 =head1 ON-DEMAND PARSER
3088
3089 The request body is usually parsed at the beginning of a request,
3090 but if you want to handle input yourself, you can enable on-demand
3091 parsing with a config parameter.
3092
3093     MyApp->config(parse_on_demand => 1);
3094
3095 =head1 PROXY SUPPORT
3096
3097 Many production servers operate using the common double-server approach,
3098 with a lightweight frontend web server passing requests to a larger
3099 backend server. An application running on the backend server must deal
3100 with two problems: the remote user always appears to be C<127.0.0.1> and
3101 the server's hostname will appear to be C<localhost> regardless of the
3102 virtual host that the user connected through.
3103
3104 Catalyst will automatically detect this situation when you are running
3105 the frontend and backend servers on the same machine. The following
3106 changes are made to the request.
3107
3108     $c->req->address is set to the user's real IP address, as read from
3109     the HTTP X-Forwarded-For header.
3110
3111     The host value for $c->req->base and $c->req->uri is set to the real
3112     host, as read from the HTTP X-Forwarded-Host header.
3113
3114 Additionally, you may be running your backend application on an insecure
3115 connection (port 80) while your frontend proxy is running under SSL.  If there
3116 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3117 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3118 be created properly.
3119
3120 In the case of passing in:
3121
3122     X-Forwarded-Port: 443
3123
3124 All calls to C<uri_for> will result in an https link, as is expected.
3125
3126 Obviously, your web server must support these headers for this to work.
3127
3128 In a more complex server farm environment where you may have your
3129 frontend proxy server(s) on different machines, you will need to set a
3130 configuration option to tell Catalyst to read the proxied data from the
3131 headers.
3132
3133     MyApp->config(using_frontend_proxy => 1);
3134
3135 If you do not wish to use the proxy support at all, you may set:
3136
3137     MyApp->config(ignore_frontend_proxy => 1);
3138
3139 =head1 THREAD SAFETY
3140
3141 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3142 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3143 believe the Catalyst core to be thread-safe.
3144
3145 If you plan to operate in a threaded environment, remember that all other
3146 modules you are using must also be thread-safe. Some modules, most notably
3147 L<DBD::SQLite>, are not thread-safe.
3148
3149 =head1 SUPPORT
3150
3151 IRC:
3152
3153     Join #catalyst on irc.perl.org.
3154
3155 Mailing Lists:
3156
3157     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3158     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3159
3160 Web:
3161
3162     http://catalyst.perl.org
3163
3164 Wiki:
3165
3166     http://dev.catalyst.perl.org
3167
3168 =head1 SEE ALSO
3169
3170 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3171
3172 =head2 L<Catalyst::Manual> - The Catalyst Manual
3173
3174 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3175
3176 =head2 L<Catalyst::Engine> - Core engine
3177
3178 =head2 L<Catalyst::Log> - Log class.
3179
3180 =head2 L<Catalyst::Request> - Request object
3181
3182 =head2 L<Catalyst::Response> - Response object
3183
3184 =head2 L<Catalyst::Test> - The test suite.
3185
3186 =begin stopwords
3187
3188 =head1 PROJECT FOUNDER
3189
3190 sri: Sebastian Riedel <sri@cpan.org>
3191
3192 =head1 CONTRIBUTORS
3193
3194 abw: Andy Wardley
3195
3196 acme: Leon Brocard <leon@astray.com>
3197
3198 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3199
3200 Andrew Bramble
3201
3202 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3203
3204 Andrew Ruthven
3205
3206 andyg: Andy Grundman <andy@hybridized.org>
3207
3208 audreyt: Audrey Tang
3209
3210 bricas: Brian Cassidy <bricas@cpan.org>
3211
3212 Caelum: Rafael Kitover <rkitover@io.com>
3213
3214 chansen: Christian Hansen
3215
3216 chicks: Christopher Hicks
3217
3218 Chisel Wright C<pause@herlpacker.co.uk>
3219
3220 Danijel Milicevic C<me@danijel.de>
3221
3222 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3223
3224 David Naughton, C<naughton@umn.edu>
3225
3226 David E. Wheeler
3227
3228 dhoss: Devin Austin <dhoss@cpan.org>
3229
3230 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3231
3232 Drew Taylor
3233
3234 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3235
3236 esskar: Sascha Kiefer
3237
3238 fireartist: Carl Franks <cfranks@cpan.org>
3239
3240 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3241
3242 gabb: Danijel Milicevic
3243
3244 Gary Ashton Jones
3245
3246 Gavin Henry C<ghenry@perl.me.uk>
3247
3248 Geoff Richards
3249
3250 groditi: Guillermo Roditi <groditi@gmail.com>
3251
3252 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3253
3254 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3255
3256 jcamacho: Juan Camacho
3257
3258 jester: Jesse Sheidlower C<jester@panix.com>
3259
3260 jhannah: Jay Hannah <jay@jays.net>
3261
3262 Jody Belka
3263
3264 Johan Lindstrom
3265
3266 jon: Jon Schutz <jjschutz@cpan.org>
3267
3268 Jonathan Rockway C<< <jrockway@cpan.org> >>
3269
3270 Kieren Diment C<kd@totaldatasolution.com>
3271
3272 konobi: Scott McWhirter <konobi@cpan.org>
3273
3274 marcus: Marcus Ramberg <mramberg@cpan.org>
3275
3276 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3277
3278 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3279
3280 mugwump: Sam Vilain
3281
3282 naughton: David Naughton
3283
3284 ningu: David Kamholz <dkamholz@cpan.org>
3285
3286 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3287
3288 numa: Dan Sully <daniel@cpan.org>
3289
3290 obra: Jesse Vincent
3291
3292 Octavian Rasnita
3293
3294 omega: Andreas Marienborg
3295
3296 Oleg Kostyuk <cub.uanic@gmail.com>
3297
3298 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3299
3300 rafl: Florian Ragwitz <rafl@debian.org>
3301
3302 random: Roland Lammel <lammel@cpan.org>
3303
3304 Robert Sedlacek C<< <rs@474.at> >>
3305
3306 SpiceMan: Marcel Montes
3307
3308 sky: Arthur Bergman
3309
3310 szbalint: Balint Szilakszi <szbalint@cpan.org>
3311
3312 t0m: Tomas Doran <bobtfish@bobtfish.net>
3313
3314 Ulf Edvinsson
3315
3316 Viljo Marrandi C<vilts@yahoo.com>
3317
3318 Will Hawes C<info@whawes.co.uk>
3319
3320 willert: Sebastian Willert <willert@cpan.org>
3321
3322 wreis: Wallace Reis <wallace@reis.org.br>
3323
3324 Yuval Kogman, C<nothingmuch@woobling.org>
3325
3326 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3327
3328 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3329
3330 =end stopwords
3331
3332 =head1 COPYRIGHT
3333
3334 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3335
3336 =head1 LICENSE
3337
3338 This library is free software. You can redistribute it and/or modify it under
3339 the same terms as Perl itself.
3340
3341 =cut
3342
3343 no Moose;
3344
3345 __PACKAGE__->meta->make_immutable;
3346
3347 1;