lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use Scalar::Util qw/weaken blessed/;
  23 use Tree::Simple qw/use_weak_refs/;
  24 use Tree::Simple::Visitor::FindByUID;
  25 use attributes;
  26 use utf8;
  27 use Carp qw/croak/;
  28
  29 BEGIN { require 5.008001; }
  30
  31 __PACKAGE__->mk_accessors(
  32     qw/counter request response state action stack namespace stats/
  33 );
  34
  35 attributes->import( __PACKAGE__, \&namespace, 'lvalue' );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class setup_finished/;
  56
  57 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  58 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  59 __PACKAGE__->request_class('Catalyst::Request');
  60 __PACKAGE__->response_class('Catalyst::Response');
  61
  62 # Remember to update this in Catalyst::Runtime as well!
  63
  64 our $VERSION = '5.7006';
  65
  66 sub import {
  67     my ( $class, @arguments ) = @_;
  68
  69     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  70     # callers @ISA.
  71     return unless $class eq 'Catalyst';
  72
  73     my $caller = caller(0);
  74
  75     unless ( $caller->isa('Catalyst') ) {
  76         no strict 'refs';
  77         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  78     }
  79
  80     $caller->arguments( [@arguments] );
  81     $caller->setup_home;
  82 }
  83
  84 =head1 NAME
  85
  86 Catalyst - The Elegant MVC Web Application Framework
  87
  88 =head1 SYNOPSIS
  89
  90     # Install Catalyst::Devel for helpers and other development tools
  91     # use the helper to create a new application
  92     catalyst.pl MyApp
  93
  94     # add models, views, controllers
  95     script/myapp_create.pl model Database DBIC::SchemaLoader dbi:SQLite:/path/to/db
  96     script/myapp_create.pl view TT TT
  97     script/myapp_create.pl controller Search
  98
  99     # built in testserver -- use -r to restart automatically on changes
 100     script/myapp_server.pl
 101
 102     # command line testing interface
 103     script/myapp_test.pl /yada
 104
 105     ### in lib/MyApp.pm
 106     use Catalyst qw/-Debug/; # include plugins here as well
 107
 108         ### In lib/MyApp/Controller/Root.pm (autocreated)
 109     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 110         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 111         $c->stash->{template} = 'foo.tt'; # set the template
 112         # lookup something from db -- stash vars are passed to TT
 113         $c->stash->{data} =
 114           $c->model('Database::Foo')->search( { country => $args[0] } );
 115         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 116             $c->forward( 'bar' ); # process another action
 117             # do something else after forward returns
 118         }
 119     }
 120
 121     # The foo.tt TT template can use the stash data from the database
 122     [% WHILE (item = data.next) %]
 123         [% item.foo %]
 124     [% END %]
 125
 126     # called for /bar/of/soap, /bar/of/soap/10, etc.
 127     sub bar : Path('/bar/of/soap') { ... }
 128
 129     # called for all actions, from the top-most controller downwards
 130     sub auto : Private {
 131         my ( $self, $c ) = @_;
 132         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 133             $c->res->redirect( '/login' ); # require login
 134             return 0; # abort request and go immediately to end()
 135         }
 136         return 1; # success; carry on to next action
 137     }
 138
 139     # called after all actions are finished
 140     sub end : Private {
 141         my ( $self, $c ) = @_;
 142         if ( scalar @{ $c->error } ) { ... } # handle errors
 143         return if $c->res->body; # already have a response
 144         $c->forward( 'MyApp::View::TT' ); # render template
 145     }
 146
 147     ### in MyApp/Controller/Foo.pm
 148     # called for /foo/bar
 149     sub bar : Local { ... }
 150
 151     # called for /blargle
 152     sub blargle : Global { ... }
 153
 154     # an index action matches /foo, but not /foo/1, etc.
 155     sub index : Private { ... }
 156
 157     ### in MyApp/Controller/Foo/Bar.pm
 158     # called for /foo/bar/baz
 159     sub baz : Local { ... }
 160
 161     # first Root auto is called, then Foo auto, then this
 162     sub auto : Private { ... }
 163
 164     # powerful regular expression paths are also possible
 165     sub details : Regex('^product/(\w+)/details$') {
 166         my ( $self, $c ) = @_;
 167         # extract the (\w+) from the URI
 168         my $product = $c->req->captures->[0];
 169     }
 170
 171 See L<Catalyst::Manual::Intro> for additional information.
 172
 173 =head1 DESCRIPTION
 174
 175 Catalyst is a modern framework for making web applications without the
 176 pain usually associated with this process. This document is a reference
 177 to the main Catalyst application. If you are a new user, we suggest you
 178 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 179
 180 See L<Catalyst::Manual> for more documentation.
 181
 182 Catalyst plugins can be loaded by naming them as arguments to the "use
 183 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 184 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 185 C<My::Module>.
 186
 187     use Catalyst qw/My::Module/;
 188
 189 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 190 fully qualify the name by using a unary plus:
 191
 192     use Catalyst qw/
 193         My::Module
 194         +Fully::Qualified::Plugin::Name
 195     /;
 196
 197 Special flags like C<-Debug> and C<-Engine> can also be specified as
 198 arguments when Catalyst is loaded:
 199
 200     use Catalyst qw/-Debug My::Module/;
 201
 202 The position of plugins and flags in the chain is important, because
 203 they are loaded in the order in which they appear.
 204
 205 The following flags are supported:
 206
 207 =head2 -Debug
 208
 209 Enables debug output. You can also force this setting from the system
 210 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 211 settings override the application, with <MYAPP>_DEBUG having the highest
 212 priority.
 213
 214 =head2 -Engine
 215
 216 Forces Catalyst to use a specific engine. Omit the
 217 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 218
 219     use Catalyst qw/-Engine=CGI/;
 220
 221 =head2 -Home
 222
 223 Forces Catalyst to use a specific home directory, e.g.:
 224
 225     use Catalyst qw[-Home=/usr/mst];
 226
 227 =head2 -Log
 228
 229 Specifies log level.
 230
 231 =head1 METHODS
 232
 233 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 234
 235 =head2 $c->action
 236
 237 Returns a L<Catalyst::Action> object for the current action, which
 238 stringifies to the action name. See L<Catalyst::Action>.
 239
 240 =head2 $c->namespace
 241
 242 Returns the namespace of the current action, i.e., the URI prefix
 243 corresponding to the controller of the current action. For example:
 244
 245     # in Controller::Foo::Bar
 246     $c->namespace; # returns 'foo/bar';
 247
 248 =head2 $c->request
 249
 250 =head2 $c->req
 251
 252 Returns the current L<Catalyst::Request> object, giving access to
 253 information about the current client request (including parameters,
 254 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 255
 256 =head2 REQUEST FLOW HANDLING
 257
 258 =head2 $c->forward( $action [, \@arguments ] )
 259
 260 =head2 $c->forward( $class, $method, [, \@arguments ] )
 261
 262 Forwards processing to another action, by its private name. If you give a
 263 class name but no method, C<process()> is called. You may also optionally
 264 pass arguments in an arrayref. The action will receive the arguments in
 265 C<@_> and C<$c-E<gt>req-E<gt>args>. Upon returning from the function,
 266 C<$c-E<gt>req-E<gt>args> will be restored to the previous values.
 267
 268 Any data C<return>ed from the action forwarded to, will be returned by the
 269 call to forward.
 270
 271     my $foodata = $c->forward('/foo');
 272     $c->forward('index');
 273     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 274     $c->forward('MyApp::View::TT');
 275
 276 Note that forward implies an C<<eval { }>> around the call (actually
 277 C<execute> does), thus de-fatalizing all 'dies' within the called
 278 action. If you want C<die> to propagate you need to do something like:
 279
 280     $c->forward('foo');
 281     die $c->error if $c->error;
 282
 283 Or make sure to always return true values from your actions and write
 284 your code like this:
 285
 286     $c->forward('foo') || return;
 287
 288 =cut
 289
 290 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 291
 292 =head2 $c->detach( $action [, \@arguments ] )
 293
 294 =head2 $c->detach( $class, $method, [, \@arguments ] )
 295
 296 =head2 $c->detach()
 297
 298 The same as C<forward>, but doesn't return to the previous action when
 299 processing is finished.
 300
 301 When called with no arguments it escapes the processing chain entirely.
 302
 303 =cut
 304
 305 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 306
 307 =head2 $c->response
 308
 309 =head2 $c->res
 310
 311 Returns the current L<Catalyst::Response> object, q.v.
 312
 313 =head2 $c->stash
 314
 315 Returns a hashref to the stash, which may be used to store data and pass
 316 it between components during a request. You can also set hash keys by
 317 passing arguments. The stash is automatically sent to the view. The
 318 stash is cleared at the end of a request; it cannot be used for
 319 persistent storage (for this you must use a session; see
 320 L<Catalyst::Plugin::Session> for a complete system integrated with
 321 Catalyst).
 322
 323     $c->stash->{foo} = $bar;
 324     $c->stash( { moose => 'majestic', qux => 0 } );
 325     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 326
 327     # stash is automatically passed to the view for use in a template
 328     $c->forward( 'MyApp::V::TT' );
 329
 330 =cut
 331
 332 sub stash {
 333     my $c = shift;
 334     if (@_) {
 335         my $stash = @_ > 1 ? {@_} : $_[0];
 336         croak('stash takes a hash or hashref') unless ref $stash;
 337         foreach my $key ( keys %$stash ) {
 338             $c->{stash}->{$key} = $stash->{$key};
 339         }
 340     }
 341     return $c->{stash};
 342 }
 343
 344 =head2 $c->error
 345
 346 =head2 $c->error($error, ...)
 347
 348 =head2 $c->error($arrayref)
 349
 350 Returns an arrayref containing error messages.  If Catalyst encounters an
 351 error while processing a request, it stores the error in $c->error.  This
 352 method should not be used to store non-fatal error messages.
 353
 354     my @error = @{ $c->error };
 355
 356 Add a new error.
 357
 358     $c->error('Something bad happened');
 359
 360 =cut
 361
 362 sub error {
 363     my $c = shift;
 364     if ( $_[0] ) {
 365         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 366         croak @$error unless ref $c;
 367         push @{ $c->{error} }, @$error;
 368     }
 369     elsif ( defined $_[0] ) { $c->{error} = undef }
 370     return $c->{error} || [];
 371 }
 372
 373
 374 =head2 $c->state
 375
 376 Contains the return value of the last executed action.
 377
 378 =head2 $c->clear_errors
 379
 380 Clear errors.  You probably don't want to clear the errors unless you are
 381 implementing a custom error screen.
 382
 383 This is equivalent to running
 384
 385     $c->error(0);
 386
 387 =cut
 388
 389 sub clear_errors {
 390     my $c = shift;
 391     $c->error(0);
 392 }
 393
 394
 395 # search via regex
 396 sub _comp_search {
 397     my ( $c, @names ) = @_;
 398
 399     foreach my $name (@names) {
 400         foreach my $component ( keys %{ $c->components } ) {
 401             return $c->components->{$component} if $component =~ /$name/i;
 402         }
 403     }
 404
 405     return undef;
 406 }
 407
 408 # try explicit component names
 409 sub _comp_explicit {
 410     my ( $c, @names ) = @_;
 411
 412     foreach my $try (@names) {
 413         return $c->components->{$try} if ( exists $c->components->{$try} );
 414     }
 415
 416     return undef;
 417 }
 418
 419 # like component, but try just these prefixes before regex searching,
 420 #  and do not try to return "sort keys %{ $c->components }"
 421 sub _comp_prefixes {
 422     my ( $c, $name, @prefixes ) = @_;
 423
 424     my $appclass = ref $c || $c;
 425
 426     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 427
 428     my $comp = $c->_comp_explicit(@names);
 429     return $comp if defined($comp);
 430     $comp = $c->_comp_search($name);
 431     return $comp;
 432 }
 433
 434 # Find possible names for a prefix
 435
 436 sub _comp_names {
 437     my ( $c, @prefixes ) = @_;
 438
 439     my $appclass = ref $c || $c;
 440
 441     my @pre = map { "${appclass}::${_}::" } @prefixes;
 442
 443     my @names;
 444
 445     COMPONENT: foreach my $comp ($c->component) {
 446         foreach my $p (@pre) {
 447             if ($comp =~ s/^$p//) {
 448                 push(@names, $comp);
 449                 next COMPONENT;
 450             }
 451         }
 452     }
 453
 454     return @names;
 455 }
 456
 457 # Return a component if only one matches.
 458 sub _comp_singular {
 459     my ( $c, @prefixes ) = @_;
 460
 461     my $appclass = ref $c || $c;
 462
 463     my ( $comp, $rest ) =
 464       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 465     return $comp unless $rest;
 466 }
 467
 468 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 469 sub _filter_component {
 470     my ( $c, $comp, @args ) = @_;
 471     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 472         return $comp->ACCEPT_CONTEXT( $c, @args );
 473     }
 474     else { return $comp }
 475 }
 476
 477 =head2 COMPONENT ACCESSORS
 478
 479 =head2 $c->controller($name)
 480
 481 Gets a L<Catalyst::Controller> instance by name.
 482
 483     $c->controller('Foo')->do_stuff;
 484
 485 If the name is omitted, will return the controller for the dispatched
 486 action.
 487
 488 =cut
 489
 490 sub controller {
 491     my ( $c, $name, @args ) = @_;
 492     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 493         @args )
 494       if ($name);
 495     return $c->component( $c->action->class );
 496 }
 497
 498 =head2 $c->model($name)
 499
 500 Gets a L<Catalyst::Model> instance by name.
 501
 502     $c->model('Foo')->do_stuff;
 503
 504 If the name is omitted, it will look for
 505  - a model object in $c->stash{current_model_instance}, then
 506  - a model name in $c->stash->{current_model}, then
 507  - a config setting 'default_model', or
 508  - check if there is only one model, and return it if that's the case.
 509
 510 =cut
 511
 512 sub model {
 513     my ( $c, $name, @args ) = @_;
 514     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 515         @args )
 516       if $name;
 517     if (ref $c) {
 518         return $c->stash->{current_model_instance}
 519           if $c->stash->{current_model_instance};
 520         return $c->model( $c->stash->{current_model} )
 521           if $c->stash->{current_model};
 522         return $c->model( $c->config->{default_model} )
 523           if $c->config->{default_model};
 524     }
 525     return $c->_filter_component( $c->_comp_singular(qw/Model M/), @args );
 526
 527 }
 528
 529 =head2 $c->controllers
 530
 531 Returns the available names which can be passed to $c->controller
 532
 533 =cut
 534
 535 sub controllers {
 536     my ( $c ) = @_;
 537     return $c->_comp_names(qw/Controller C/);
 538 }
 539
 540
 541 =head2 $c->view($name)
 542
 543 Gets a L<Catalyst::View> instance by name.
 544
 545     $c->view('Foo')->do_stuff;
 546
 547 If the name is omitted, it will look for
 548  - a view object in $c->stash{current_view_instance}, then
 549  - a view name in $c->stash->{current_view}, then
 550  - a config setting 'default_view', or
 551  - check if there is only one view, and return it if that's the case.
 552
 553 =cut
 554
 555 sub view {
 556     my ( $c, $name, @args ) = @_;
 557     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 558         @args )
 559       if $name;
 560     if (ref $c) {
 561         return $c->stash->{current_view_instance}
 562           if $c->stash->{current_view_instance};
 563         return $c->view( $c->stash->{current_view} )
 564           if $c->stash->{current_view};
 565         return $c->view( $c->config->{default_view} )
 566           if $c->config->{default_view};
 567     }
 568     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 569 }
 570
 571 =head2 $c->models
 572
 573 Returns the available names which can be passed to $c->model
 574
 575 =cut
 576
 577 sub models {
 578     my ( $c ) = @_;
 579     return $c->_comp_names(qw/Model M/);
 580 }
 581
 582
 583 =head2 $c->views
 584
 585 Returns the available names which can be passed to $c->view
 586
 587 =cut
 588
 589 sub views {
 590     my ( $c ) = @_;
 591     return $c->_comp_names(qw/View V/);
 592 }
 593
 594 =head2 $c->comp($name)
 595
 596 =head2 $c->component($name)
 597
 598 Gets a component object by name. This method is no longer recommended,
 599 unless you want to get a specific component by full
 600 class. C<$c-E<gt>controller>, C<$c-E<gt>model>, and C<$c-E<gt>view>
 601 should be used instead.
 602
 603 =cut
 604
 605 sub component {
 606     my $c = shift;
 607
 608     if (@_) {
 609
 610         my $name = shift;
 611
 612         my $appclass = ref $c || $c;
 613
 614         my @names = (
 615             $name, "${appclass}::${name}",
 616             map { "${appclass}::${_}::${name}" }
 617               qw/Model M Controller C View V/
 618         );
 619
 620         my $comp = $c->_comp_explicit(@names);
 621         return $c->_filter_component( $comp, @_ ) if defined($comp);
 622
 623         $comp = $c->_comp_search($name);
 624         return $c->_filter_component( $comp, @_ ) if defined($comp);
 625     }
 626
 627     return sort keys %{ $c->components };
 628 }
 629
 630
 631
 632 =head2 CLASS DATA AND HELPER CLASSES
 633
 634 =head2 $c->config
 635
 636 Returns or takes a hashref containing the application's configuration.
 637
 638     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 639
 640 You can also use a L<YAML> config file like myapp.yml in your
 641 applications home directory.
 642
 643     ---
 644     db: dsn:SQLite:foo.db
 645
 646
 647 =cut
 648
 649 sub config {
 650     my $c = shift;
 651
 652     $c->log->warn("Setting config after setup has been run is not a good idea.")
 653       if ( @_ and $c->setup_finished );
 654
 655     $c->NEXT::config(@_);
 656 }
 657
 658 =head2 $c->log
 659
 660 Returns the logging object instance. Unless it is already set, Catalyst
 661 sets this up with a L<Catalyst::Log> object. To use your own log class,
 662 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 663 C<< __PACKAGE__->setup >>.
 664
 665  __PACKAGE__->log( MyLogger->new );
 666  __PACKAGE__->setup;
 667
 668 And later:
 669
 670     $c->log->info( 'Now logging with my own logger!' );
 671
 672 Your log class should implement the methods described in
 673 L<Catalyst::Log>.
 674
 675
 676 =head2 $c->debug
 677
 678 Overload to enable debug messages (same as -Debug option).
 679
 680 Note that this is a static method, not an accessor and should be overloaded
 681 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 682
 683 =cut
 684
 685 sub debug { 0 }
 686
 687 =head2 $c->dispatcher
 688
 689 Returns the dispatcher instance. Stringifies to class name. See
 690 L<Catalyst::Dispatcher>.
 691
 692 =head2 $c->engine
 693
 694 Returns the engine instance. Stringifies to the class name. See
 695 L<Catalyst::Engine>.
 696
 697
 698 =head2 UTILITY METHODS
 699
 700 =head2 $c->path_to(@path)
 701
 702 Merges C<@path> with C<$c-E<gt>config-E<gt>{home}> and returns a
 703 L<Path::Class> object.
 704
 705 For example:
 706
 707     $c->path_to( 'db', 'sqlite.db' );
 708
 709 =cut
 710
 711 sub path_to {
 712     my ( $c, @path ) = @_;
 713     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 714     if ( -d $path ) { return $path }
 715     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 716 }
 717
 718 =head2 $c->plugin( $name, $class, @args )
 719
 720 Helper method for plugins. It creates a classdata accessor/mutator and
 721 loads and instantiates the given class.
 722
 723     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 724
 725     $c->prototype->define_javascript_functions;
 726
 727 =cut
 728
 729 sub plugin {
 730     my ( $class, $name, $plugin, @args ) = @_;
 731     $class->_register_plugin( $plugin, 1 );
 732
 733     eval { $plugin->import };
 734     $class->mk_classdata($name);
 735     my $obj;
 736     eval { $obj = $plugin->new(@args) };
 737
 738     if ($@) {
 739         Catalyst::Exception->throw( message =>
 740               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 741     }
 742
 743     $class->$name($obj);
 744     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 745       if $class->debug;
 746 }
 747
 748 =head2 MyApp->setup
 749
 750 Initializes the dispatcher and engine, loads any plugins, and loads the
 751 model, view, and controller components. You may also specify an array
 752 of plugins to load here, if you choose to not load them in the C<use
 753 Catalyst> line.
 754
 755     MyApp->setup;
 756     MyApp->setup( qw/-Debug/ );
 757
 758 =cut
 759
 760 sub setup {
 761     my ( $class, @arguments ) = @_;
 762
 763     $class->log->warn("Running setup twice is not a good idea.")
 764       if ( $class->setup_finished );
 765
 766     unless ( $class->isa('Catalyst') ) {
 767
 768         Catalyst::Exception->throw(
 769             message => qq/'$class' does not inherit from Catalyst/ );
 770     }
 771
 772     if ( $class->arguments ) {
 773         @arguments = ( @arguments, @{ $class->arguments } );
 774     }
 775
 776     # Process options
 777     my $flags = {};
 778
 779     foreach (@arguments) {
 780
 781         if (/^-Debug$/) {
 782             $flags->{log} =
 783               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 784         }
 785         elsif (/^-(\w+)=?(.*)$/) {
 786             $flags->{ lc $1 } = $2;
 787         }
 788         else {
 789             push @{ $flags->{plugins} }, $_;
 790         }
 791     }
 792
 793     $class->setup_home( delete $flags->{home} );
 794
 795     $class->setup_log( delete $flags->{log} );
 796     $class->setup_plugins( delete $flags->{plugins} );
 797     $class->setup_dispatcher( delete $flags->{dispatcher} );
 798     $class->setup_engine( delete $flags->{engine} );
 799
 800     for my $flag ( sort keys %{$flags} ) {
 801
 802         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 803             &$code( $class, delete $flags->{$flag} );
 804         }
 805         else {
 806             $class->log->warn(qq/Unknown flag "$flag"/);
 807         }
 808     }
 809
 810     eval { require Catalyst::Devel; };
 811     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 812         $class->log->warn(<<"EOF");
 813 You are running an old script!
 814
 815   Please update by running (this will overwrite existing files):
 816     catalyst.pl -force -scripts $class
 817
 818   or (this will not overwrite existing files):
 819     catalyst.pl -scripts $class
 820
 821 EOF
 822     }
 823
 824     if ( $class->debug ) {
 825         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 826
 827         if (@plugins) {
 828             my $t = Text::SimpleTable->new(74);
 829             $t->row($_) for @plugins;
 830             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 831         }
 832
 833         my $dispatcher = $class->dispatcher;
 834         my $engine     = $class->engine;
 835         my $home       = $class->config->{home};
 836
 837         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 838         $class->log->debug(qq/Loaded engine "$engine"/);
 839
 840         $home
 841           ? ( -d $home )
 842           ? $class->log->debug(qq/Found home "$home"/)
 843           : $class->log->debug(qq/Home "$home" doesn't exist/)
 844           : $class->log->debug(q/Couldn't find home/);
 845     }
 846
 847     # Call plugins setup
 848     {
 849         no warnings qw/redefine/;
 850         local *setup = sub { };
 851         $class->setup;
 852     }
 853
 854     # Initialize our data structure
 855     $class->components( {} );
 856
 857     $class->setup_components;
 858
 859     if ( $class->debug ) {
 860         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 861         for my $comp ( sort keys %{ $class->components } ) {
 862             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 863             $t->row( $comp, $type );
 864         }
 865         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 866           if ( keys %{ $class->components } );
 867     }
 868
 869     # Add our self to components, since we are also a component
 870     $class->components->{$class} = $class;
 871
 872     $class->setup_actions;
 873
 874     if ( $class->debug ) {
 875         my $name = $class->config->{name} || 'Application';
 876         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 877     }
 878     $class->log->_flush() if $class->log->can('_flush');
 879
 880     $class->setup_finished(1);
 881 }
 882
 883 =head2 $c->uri_for( $path, @args?, \%query_values? )
 884
 885 Merges path with C<< $c->request->base >> for absolute URIs and with
 886 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 887 object. If any args are passed, they are added at the end of the path.
 888 If the last argument to C<uri_for> is a hash reference, it is assumed to
 889 contain GET parameter key/value pairs, which will be appended to the URI
 890 in standard fashion.
 891
 892 Instead of C<$path>, you can also optionally pass a C<$action> object
 893 which will be resolved to a path using
 894 C<< $c->dispatcher->uri_for_action >>; if the first element of
 895 C<@args> is an arrayref it is treated as a list of captures to be passed
 896 to C<uri_for_action>.
 897
 898 =cut
 899
 900 sub uri_for {
 901     my ( $c, $path, @args ) = @_;
 902     my $base     = $c->request->base->clone;
 903     my $basepath = $base->path;
 904     $basepath =~ s/\/$//;
 905     $basepath .= '/';
 906     my $namespace = $c->namespace || '';
 907
 908     if ( Scalar::Util::blessed($path) ) { # action object
 909         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 910                          ? shift(@args)
 911                          : [] );
 912         $path = $c->dispatcher->uri_for_action($path, $captures);
 913         return undef unless defined($path);
 914         $path = '/' if $path eq '';
 915     }
 916
 917     # massage namespace, empty if absolute path
 918     $namespace =~ s/^\/// if $namespace;
 919     $namespace .= '/' if $namespace;
 920     $path ||= '';
 921     $namespace = '' if $path =~ /^\//;
 922     $path =~ s/^\///;
 923     $path =~ s/\?/%3F/g;
 924
 925     my $params =
 926       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 927
 928     for my $value ( values %$params ) {
 929         next unless defined $value;
 930         for ( ref $value eq 'ARRAY' ? @$value : $value ) {
 931             $_ = "$_";
 932             utf8::encode( $_ );
 933         }
 934     };
 935
 936     # join args with '/', or a blank string
 937     my $args = ( scalar @args ? '/' . join( '/', map {s/\?/%3F/g; $_} @args ) : '' );
 938     $args =~ s/^\/// unless $path;
 939     my $res =
 940       URI->new_abs( URI->new_abs( "$path$args", "$basepath$namespace" ), $base )
 941       ->canonical;
 942     $res->query_form(%$params);
 943     $res;
 944 }
 945
 946 =head2 $c->welcome_message
 947
 948 Returns the Catalyst welcome HTML page.
 949
 950 =cut
 951
 952 sub welcome_message {
 953     my $c      = shift;
 954     my $name   = $c->config->{name};
 955     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
 956     my $prefix = Catalyst::Utils::appprefix( ref $c );
 957     $c->response->content_type('text/html; charset=utf-8');
 958     return <<"EOF";
 959 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
 960     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
 961 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 962     <head>
 963         <meta http-equiv="Content-Language" content="en" />
 964         <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
 965         <title>$name on Catalyst $VERSION</title>
 966         <style type="text/css">
 967             body {
 968                 color: #000;
 969                 background-color: #eee;
 970             }
 971             div#content {
 972                 width: 640px;
 973                 margin-left: auto;
 974                 margin-right: auto;
 975                 margin-top: 10px;
 976                 margin-bottom: 10px;
 977                 text-align: left;
 978                 background-color: #ccc;
 979                 border: 1px solid #aaa;
 980             }
 981             p, h1, h2 {
 982                 margin-left: 20px;
 983                 margin-right: 20px;
 984                 font-family: verdana, tahoma, sans-serif;
 985             }
 986             a {
 987                 font-family: verdana, tahoma, sans-serif;
 988             }
 989             :link, :visited {
 990                     text-decoration: none;
 991                     color: #b00;
 992                     border-bottom: 1px dotted #bbb;
 993             }
 994             :link:hover, :visited:hover {
 995                     color: #555;
 996             }
 997             div#topbar {
 998                 margin: 0px;
 999             }
1000             pre {
1001                 margin: 10px;
1002                 padding: 8px;
1003             }
1004             div#answers {
1005                 padding: 8px;
1006                 margin: 10px;
1007                 background-color: #fff;
1008                 border: 1px solid #aaa;
1009             }
1010             h1 {
1011                 font-size: 0.9em;
1012                 font-weight: normal;
1013                 text-align: center;
1014             }
1015             h2 {
1016                 font-size: 1.0em;
1017             }
1018             p {
1019                 font-size: 0.9em;
1020             }
1021             p img {
1022                 float: right;
1023                 margin-left: 10px;
1024             }
1025             span#appname {
1026                 font-weight: bold;
1027                 font-size: 1.6em;
1028             }
1029         </style>
1030     </head>
1031     <body>
1032         <div id="content">
1033             <div id="topbar">
1034                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1035                     $VERSION</h1>
1036              </div>
1037              <div id="answers">
1038                  <p>
1039                  <img src="$logo" alt="Catalyst Logo" />
1040                  </p>
1041                  <p>Welcome to the wonderful world of Catalyst.
1042                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1043                     framework will make web development something you had
1044                     never expected it to be: Fun, rewarding, and quick.</p>
1045                  <h2>What to do now?</h2>
1046                  <p>That really depends  on what <b>you</b> want to do.
1047                     We do, however, provide you with a few starting points.</p>
1048                  <p>If you want to jump right into web development with Catalyst
1049                     you might want to check out the documentation.</p>
1050                  <pre><code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1051 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1052 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual.pod">Catalyst::Manual</a></code></pre>
1053                  <h2>What to do next?</h2>
1054                  <p>Next it's time to write an actual application. Use the
1055                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1056                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1057                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1058                     they can save you a lot of work.</p>
1059                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1060                     <p>Also, be sure to check out the vast and growing
1061                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1062                     you are likely to find what you need there.
1063                     </p>
1064
1065                  <h2>Need help?</h2>
1066                  <p>Catalyst has a very active community. Here are the main places to
1067                     get in touch with us.</p>
1068                  <ul>
1069                      <li>
1070                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1071                      </li>
1072                      <li>
1073                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1074                      </li>
1075                      <li>
1076                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1077                      </li>
1078                  </ul>
1079                  <h2>In conclusion</h2>
1080                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1081                     as we enjoyed making it. Please contact us if you have ideas
1082                     for improvement or other feedback.</p>
1083              </div>
1084          </div>
1085     </body>
1086 </html>
1087 EOF
1088 }
1089
1090 =head1 INTERNAL METHODS
1091
1092 These methods are not meant to be used by end users.
1093
1094 =head2 $c->components
1095
1096 Returns a hash of components.
1097
1098 =head2 $c->context_class
1099
1100 Returns or sets the context class.
1101
1102 =head2 $c->counter
1103
1104 Returns a hashref containing coderefs and execution counts (needed for
1105 deep recursion detection).
1106
1107 =head2 $c->depth
1108
1109 Returns the number of actions on the current internal execution stack.
1110
1111 =head2 $c->dispatch
1112
1113 Dispatches a request to actions.
1114
1115 =cut
1116
1117 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1118
1119 =head2 $c->dispatcher_class
1120
1121 Returns or sets the dispatcher class.
1122
1123 =head2 $c->dump_these
1124
1125 Returns a list of 2-element array references (name, structure) pairs
1126 that will be dumped on the error page in debug mode.
1127
1128 =cut
1129
1130 sub dump_these {
1131     my $c = shift;
1132     [ Request => $c->req ],
1133     [ Response => $c->res ],
1134     [ Stash => $c->stash ],
1135     [ Config => $c->config ];
1136 }
1137
1138 =head2 $c->engine_class
1139
1140 Returns or sets the engine class.
1141
1142 =head2 $c->execute( $class, $coderef )
1143
1144 Execute a coderef in given class and catch exceptions. Errors are available
1145 via $c->error.
1146
1147 =cut
1148
1149 sub execute {
1150     my ( $c, $class, $code ) = @_;
1151     $class = $c->component($class) || $class;
1152     $c->state(0);
1153
1154     if ( $c->depth >= $RECURSION ) {
1155         my $action = "$code";
1156         $action = "/$action" unless $action =~ /->/;
1157         my $error = qq/Deep recursion detected calling "$action"/;
1158         $c->log->error($error);
1159         $c->error($error);
1160         $c->state(0);
1161         return $c->state;
1162     }
1163
1164     my $stats_info = $c->_stats_start_execute( $code ) if $c->debug;
1165
1166     push( @{ $c->stack }, $code );
1167
1168     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1169
1170     $c->_stats_finish_execute( $stats_info ) if $c->debug and $stats_info;
1171
1172     my $last = pop( @{ $c->stack } );
1173
1174     if ( my $error = $@ ) {
1175         if ( !ref($error) and $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1176         else {
1177             unless ( ref $error ) {
1178                 no warnings 'uninitialized';
1179                 chomp $error;
1180                 my $class = $last->class;
1181                 my $name  = $last->name;
1182                 $error = qq/Caught exception in $class->$name "$error"/;
1183             }
1184             $c->error($error);
1185             $c->state(0);
1186         }
1187     }
1188     return $c->state;
1189 }
1190
1191 sub _stats_start_execute {
1192     my ( $c, $code ) = @_;
1193
1194     return if ( ( $code->name =~ /^_.*/ )
1195         && ( !$c->config->{show_internal_actions} ) );
1196
1197     $c->counter->{"$code"}++;
1198
1199     my $action = "$code";
1200     $action = "/$action" unless $action =~ /->/;
1201
1202     # determine if the call was the result of a forward
1203     # this is done by walking up the call stack and looking for a calling
1204     # sub of Catalyst::forward before the eval
1205     my $callsub = q{};
1206     for my $index ( 2 .. 11 ) {
1207         last
1208         if ( ( caller($index) )[0] eq 'Catalyst'
1209             && ( caller($index) )[3] eq '(eval)' );
1210
1211         if ( ( caller($index) )[3] =~ /forward$/ ) {
1212             $callsub = ( caller($index) )[3];
1213             $action  = "-> $action";
1214             last;
1215         }
1216     }
1217
1218     my $node = Tree::Simple->new(
1219         {
1220             action  => $action,
1221             elapsed => undef,     # to be filled in later
1222             comment => "",
1223         }
1224     );
1225     $node->setUID( "$code" . $c->counter->{"$code"} );
1226
1227     # is this a root-level call or a forwarded call?
1228     if ( $callsub =~ /forward$/ ) {
1229
1230         # forward, locate the caller
1231         if ( my $parent = $c->stack->[-1] ) {
1232             my $visitor = Tree::Simple::Visitor::FindByUID->new;
1233             $visitor->searchForUID(
1234                 "$parent" . $c->counter->{"$parent"} );
1235             $c->stats->accept($visitor);
1236             if ( my $result = $visitor->getResult ) {
1237                 $result->addChild($node);
1238             }
1239         }
1240         else {
1241
1242             # forward with no caller may come from a plugin
1243             $c->stats->addChild($node);
1244         }
1245     }
1246     else {
1247
1248         # root-level call
1249         $c->stats->addChild($node);
1250     }
1251
1252     return {
1253         start   => [gettimeofday],
1254         node    => $node,
1255     };
1256 }
1257
1258 sub _stats_finish_execute {
1259     my ( $c, $info ) = @_;
1260     my $elapsed = tv_interval $info->{start};
1261     my $value = $info->{node}->getNodeValue;
1262     $value->{elapsed} = sprintf( '%fs', $elapsed );
1263 }
1264
1265 =head2 $c->_localize_fields( sub { }, \%keys );
1266
1267 =cut
1268
1269 sub _localize_fields {
1270     my ( $c, $localized, $code ) = ( @_ );
1271
1272     my $request = delete $localized->{request} || {};
1273     my $response = delete $localized->{response} || {};
1274
1275     local @{ $c }{ keys %$localized } = values %$localized;
1276     local @{ $c->request }{ keys %$request } = values %$request;
1277     local @{ $c->response }{ keys %$response } = values %$response;
1278
1279     $code->();
1280 }
1281
1282 =head2 $c->finalize
1283
1284 Finalizes the request.
1285
1286 =cut
1287
1288 sub finalize {
1289     my $c = shift;
1290
1291     for my $error ( @{ $c->error } ) {
1292         $c->log->error($error);
1293     }
1294
1295     # Allow engine to handle finalize flow (for POE)
1296     if ( $c->engine->can('finalize') ) {
1297         $c->engine->finalize($c);
1298     }
1299     else {
1300
1301         $c->finalize_uploads;
1302
1303         # Error
1304         if ( $#{ $c->error } >= 0 ) {
1305             $c->finalize_error;
1306         }
1307
1308         $c->finalize_headers;
1309
1310         # HEAD request
1311         if ( $c->request->method eq 'HEAD' ) {
1312             $c->response->body('');
1313         }
1314
1315         $c->finalize_body;
1316     }
1317
1318     if ($c->debug) {
1319         my $elapsed = sprintf '%f', tv_interval($c->stats->getNodeValue);
1320         my $av = sprintf '%.3f', ( $elapsed == 0 ? '??' : ( 1 / $elapsed ) );
1321
1322         my $t = Text::SimpleTable->new( [ 62, 'Action' ], [ 9, 'Time' ] );
1323         $c->stats->traverse(
1324             sub {
1325                 my $action = shift;
1326                 my $stat   = $action->getNodeValue;
1327                 $t->row( ( q{ } x $action->getDepth ) . $stat->{action} . $stat->{comment},
1328                     $stat->{elapsed} || '??' );
1329             }
1330         );
1331
1332         $c->log->info(
1333             "Request took ${elapsed}s ($av/s)\n" . $t->draw . "\n" );
1334     }
1335
1336     return $c->response->status;
1337 }
1338
1339 =head2 $c->finalize_body
1340
1341 Finalizes body.
1342
1343 =cut
1344
1345 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1346
1347 =head2 $c->finalize_cookies
1348
1349 Finalizes cookies.
1350
1351 =cut
1352
1353 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1354
1355 =head2 $c->finalize_error
1356
1357 Finalizes error.
1358
1359 =cut
1360
1361 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1362
1363 =head2 $c->finalize_headers
1364
1365 Finalizes headers.
1366
1367 =cut
1368
1369 sub finalize_headers {
1370     my $c = shift;
1371
1372     # Check if we already finalized headers
1373     return if $c->response->{_finalized_headers};
1374
1375     # Handle redirects
1376     if ( my $location = $c->response->redirect ) {
1377         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1378         $c->response->header( Location => $location );
1379     }
1380
1381     # Content-Length
1382     if ( $c->response->body && !$c->response->content_length ) {
1383
1384         # get the length from a filehandle
1385         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1386         {
1387             if ( my $stat = stat $c->response->body ) {
1388                 $c->response->content_length( $stat->size );
1389             }
1390             else {
1391                 $c->log->warn('Serving filehandle without a content-length');
1392             }
1393         }
1394         else {
1395             $c->response->content_length( bytes::length( $c->response->body ) );
1396         }
1397     }
1398
1399     # Errors
1400     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1401         $c->response->headers->remove_header("Content-Length");
1402         $c->response->body('');
1403     }
1404
1405     $c->finalize_cookies;
1406
1407     $c->engine->finalize_headers( $c, @_ );
1408
1409     # Done
1410     $c->response->{_finalized_headers} = 1;
1411 }
1412
1413 =head2 $c->finalize_output
1414
1415 An alias for finalize_body.
1416
1417 =head2 $c->finalize_read
1418
1419 Finalizes the input after reading is complete.
1420
1421 =cut
1422
1423 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1424
1425 =head2 $c->finalize_uploads
1426
1427 Finalizes uploads. Cleans up any temporary files.
1428
1429 =cut
1430
1431 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1432
1433 =head2 $c->get_action( $action, $namespace )
1434
1435 Gets an action in a given namespace.
1436
1437 =cut
1438
1439 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1440
1441 =head2 $c->get_actions( $action, $namespace )
1442
1443 Gets all actions of a given name in a namespace and all parent
1444 namespaces.
1445
1446 =cut
1447
1448 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1449
1450 =head2 $c->handle_request( $class, @arguments )
1451
1452 Called to handle each HTTP request.
1453
1454 =cut
1455
1456 sub handle_request {
1457     my ( $class, @arguments ) = @_;
1458
1459     # Always expect worst case!
1460     my $status = -1;
1461     eval {
1462         if ($class->debug) {
1463             my $secs = time - $START || 1;
1464             my $av = sprintf '%.3f', $COUNT / $secs;
1465             my $time = localtime time;
1466             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1467         }
1468
1469         my $c = $class->prepare(@arguments);
1470         $c->dispatch;
1471         $status = $c->finalize;
1472     };
1473
1474     if ( my $error = $@ ) {
1475         chomp $error;
1476         $class->log->error(qq/Caught exception in engine "$error"/);
1477     }
1478
1479     $COUNT++;
1480     $class->log->_flush() if $class->log->can('_flush');
1481     return $status;
1482 }
1483
1484 =head2 $c->prepare( @arguments )
1485
1486 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1487 etc.).
1488
1489 =cut
1490
1491 sub prepare {
1492     my ( $class, @arguments ) = @_;
1493
1494     $class->context_class( ref $class || $class ) unless $class->context_class;
1495     my $c = $class->context_class->new(
1496         {
1497             counter => {},
1498             stack   => [],
1499             request => $class->request_class->new(
1500                 {
1501                     arguments        => [],
1502                     body_parameters  => {},
1503                     cookies          => {},
1504                     headers          => HTTP::Headers->new,
1505                     parameters       => {},
1506                     query_parameters => {},
1507                     secure           => 0,
1508                     captures         => [],
1509                     uploads          => {}
1510                 }
1511             ),
1512             response => $class->response_class->new(
1513                 {
1514                     body    => '',
1515                     cookies => {},
1516                     headers => HTTP::Headers->new(),
1517                     status  => 200
1518                 }
1519             ),
1520             stash => {},
1521             state => 0
1522         }
1523     );
1524
1525     if ( $c->debug ) {
1526         $c->stats(Tree::Simple->new([gettimeofday]));
1527         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1528     }
1529
1530     # For on-demand data
1531     $c->request->{_context}  = $c;
1532     $c->response->{_context} = $c;
1533     weaken( $c->request->{_context} );
1534     weaken( $c->response->{_context} );
1535
1536     # Allow engine to direct the prepare flow (for POE)
1537     if ( $c->engine->can('prepare') ) {
1538         $c->engine->prepare( $c, @arguments );
1539     }
1540     else {
1541         $c->prepare_request(@arguments);
1542         $c->prepare_connection;
1543         $c->prepare_query_parameters;
1544         $c->prepare_headers;
1545         $c->prepare_cookies;
1546         $c->prepare_path;
1547
1548         # On-demand parsing
1549         $c->prepare_body unless $c->config->{parse_on_demand};
1550     }
1551
1552     my $method  = $c->req->method  || '';
1553     my $path    = $c->req->path    || '/';
1554     my $address = $c->req->address || '';
1555
1556     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1557       if $c->debug;
1558
1559     $c->prepare_action;
1560
1561     return $c;
1562 }
1563
1564 =head2 $c->prepare_action
1565
1566 Prepares action. See L<Catalyst::Dispatcher>.
1567
1568 =cut
1569
1570 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1571
1572 =head2 $c->prepare_body
1573
1574 Prepares message body.
1575
1576 =cut
1577
1578 sub prepare_body {
1579     my $c = shift;
1580
1581     # Do we run for the first time?
1582     return if defined $c->request->{_body};
1583
1584     # Initialize on-demand data
1585     $c->engine->prepare_body( $c, @_ );
1586     $c->prepare_parameters;
1587     $c->prepare_uploads;
1588
1589     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1590         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1591         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1592             my $param = $c->req->body_parameters->{$key};
1593             my $value = defined($param) ? $param : '';
1594             $t->row( $key,
1595                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1596         }
1597         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1598     }
1599 }
1600
1601 =head2 $c->prepare_body_chunk( $chunk )
1602
1603 Prepares a chunk of data before sending it to L<HTTP::Body>.
1604
1605 See L<Catalyst::Engine>.
1606
1607 =cut
1608
1609 sub prepare_body_chunk {
1610     my $c = shift;
1611     $c->engine->prepare_body_chunk( $c, @_ );
1612 }
1613
1614 =head2 $c->prepare_body_parameters
1615
1616 Prepares body parameters.
1617
1618 =cut
1619
1620 sub prepare_body_parameters {
1621     my $c = shift;
1622     $c->engine->prepare_body_parameters( $c, @_ );
1623 }
1624
1625 =head2 $c->prepare_connection
1626
1627 Prepares connection.
1628
1629 =cut
1630
1631 sub prepare_connection {
1632     my $c = shift;
1633     $c->engine->prepare_connection( $c, @_ );
1634 }
1635
1636 =head2 $c->prepare_cookies
1637
1638 Prepares cookies.
1639
1640 =cut
1641
1642 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1643
1644 =head2 $c->prepare_headers
1645
1646 Prepares headers.
1647
1648 =cut
1649
1650 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1651
1652 =head2 $c->prepare_parameters
1653
1654 Prepares parameters.
1655
1656 =cut
1657
1658 sub prepare_parameters {
1659     my $c = shift;
1660     $c->prepare_body_parameters;
1661     $c->engine->prepare_parameters( $c, @_ );
1662 }
1663
1664 =head2 $c->prepare_path
1665
1666 Prepares path and base.
1667
1668 =cut
1669
1670 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1671
1672 =head2 $c->prepare_query_parameters
1673
1674 Prepares query parameters.
1675
1676 =cut
1677
1678 sub prepare_query_parameters {
1679     my $c = shift;
1680
1681     $c->engine->prepare_query_parameters( $c, @_ );
1682
1683     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1684         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1685         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1686             my $param = $c->req->query_parameters->{$key};
1687             my $value = defined($param) ? $param : '';
1688             $t->row( $key,
1689                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1690         }
1691         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1692     }
1693 }
1694
1695 =head2 $c->prepare_read
1696
1697 Prepares the input for reading.
1698
1699 =cut
1700
1701 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1702
1703 =head2 $c->prepare_request
1704
1705 Prepares the engine request.
1706
1707 =cut
1708
1709 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1710
1711 =head2 $c->prepare_uploads
1712
1713 Prepares uploads.
1714
1715 =cut
1716
1717 sub prepare_uploads {
1718     my $c = shift;
1719
1720     $c->engine->prepare_uploads( $c, @_ );
1721
1722     if ( $c->debug && keys %{ $c->request->uploads } ) {
1723         my $t = Text::SimpleTable->new(
1724             [ 12, 'Parameter' ],
1725             [ 26, 'Filename' ],
1726             [ 18, 'Type' ],
1727             [ 9,  'Size' ]
1728         );
1729         for my $key ( sort keys %{ $c->request->uploads } ) {
1730             my $upload = $c->request->uploads->{$key};
1731             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1732                 $t->row( $key, $u->filename, $u->type, $u->size );
1733             }
1734         }
1735         $c->log->debug( "File Uploads are:\n" . $t->draw );
1736     }
1737 }
1738
1739 =head2 $c->prepare_write
1740
1741 Prepares the output for writing.
1742
1743 =cut
1744
1745 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1746
1747 =head2 $c->request_class
1748
1749 Returns or sets the request class.
1750
1751 =head2 $c->response_class
1752
1753 Returns or sets the response class.
1754
1755 =head2 $c->read( [$maxlength] )
1756
1757 Reads a chunk of data from the request body. This method is designed to
1758 be used in a while loop, reading C<$maxlength> bytes on every call.
1759 C<$maxlength> defaults to the size of the request if not specified.
1760
1761 You have to set C<MyApp-E<gt>config-E<gt>{parse_on_demand}> to use this
1762 directly.
1763
1764 =cut
1765
1766 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1767
1768 =head2 $c->run
1769
1770 Starts the engine.
1771
1772 =cut
1773
1774 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1775
1776 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1777
1778 Sets an action in a given namespace.
1779
1780 =cut
1781
1782 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1783
1784 =head2 $c->setup_actions($component)
1785
1786 Sets up actions for a component.
1787
1788 =cut
1789
1790 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1791
1792 =head2 $c->setup_components
1793
1794 Sets up components. Specify a C<setup_components> config option to pass
1795 additional options directly to L<Module::Pluggable>. To add additional
1796 search paths, specify a key named C<search_extra> as an array
1797 reference. Items in the array beginning with C<::> will have the
1798 application class name prepended to them.
1799
1800 =cut
1801
1802 sub setup_components {
1803     my $class = shift;
1804
1805     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1806     my $config  = $class->config->{ setup_components };
1807     my $extra   = delete $config->{ search_extra } || [];
1808
1809     push @paths, @$extra;
1810
1811     my $locator = Module::Pluggable::Object->new(
1812         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1813         %$config
1814     );
1815
1816     for my $component ( sort { length $a <=> length $b } $locator->plugins ) {
1817         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1818
1819         my $module  = $class->setup_component( $component );
1820         my %modules = (
1821             $component => $module,
1822             map {
1823                 $_ => $class->setup_component( $_ )
1824             } Devel::InnerPackage::list_packages( $component )
1825         );
1826
1827         for my $key ( keys %modules ) {
1828             $class->components->{ $key } = $modules{ $key };
1829         }
1830     }
1831 }
1832
1833 =head2 $c->setup_component
1834
1835 =cut
1836
1837 sub setup_component {
1838     my( $class, $component ) = @_;
1839
1840     unless ( $component->can( 'COMPONENT' ) ) {
1841         return $component;
1842     }
1843
1844     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1845     my $config = $class->config->{ $suffix } || {};
1846
1847     my $instance = eval { $component->COMPONENT( $class, $config ); };
1848
1849     if ( my $error = $@ ) {
1850         chomp $error;
1851         Catalyst::Exception->throw(
1852             message => qq/Couldn't instantiate component "$component", "$error"/
1853         );
1854     }
1855
1856     Catalyst::Exception->throw(
1857         message =>
1858         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1859     ) unless eval { $instance->can( 'can' ) };
1860
1861     return $instance;
1862 }
1863
1864 =head2 $c->setup_dispatcher
1865
1866 Sets up dispatcher.
1867
1868 =cut
1869
1870 sub setup_dispatcher {
1871     my ( $class, $dispatcher ) = @_;
1872
1873     if ($dispatcher) {
1874         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1875     }
1876
1877     if ( $ENV{CATALYST_DISPATCHER} ) {
1878         $dispatcher = 'Catalyst::Dispatcher::' . $ENV{CATALYST_DISPATCHER};
1879     }
1880
1881     if ( $ENV{ uc($class) . '_DISPATCHER' } ) {
1882         $dispatcher =
1883           'Catalyst::Dispatcher::' . $ENV{ uc($class) . '_DISPATCHER' };
1884     }
1885
1886     unless ($dispatcher) {
1887         $dispatcher = $class->dispatcher_class;
1888     }
1889
1890     unless (Class::Inspector->loaded($dispatcher)) {
1891         require Class::Inspector->filename($dispatcher);
1892     }
1893
1894     # dispatcher instance
1895     $class->dispatcher( $dispatcher->new );
1896 }
1897
1898 =head2 $c->setup_engine
1899
1900 Sets up engine.
1901
1902 =cut
1903
1904 sub setup_engine {
1905     my ( $class, $engine ) = @_;
1906
1907     if ($engine) {
1908         $engine = 'Catalyst::Engine::' . $engine;
1909     }
1910
1911     if ( $ENV{CATALYST_ENGINE} ) {
1912         $engine = 'Catalyst::Engine::' . $ENV{CATALYST_ENGINE};
1913     }
1914
1915     if ( $ENV{ uc($class) . '_ENGINE' } ) {
1916         $engine = 'Catalyst::Engine::' . $ENV{ uc($class) . '_ENGINE' };
1917     }
1918
1919     if ( $ENV{MOD_PERL} ) {
1920
1921         # create the apache method
1922         {
1923             no strict 'refs';
1924             *{"$class\::apache"} = sub { shift->engine->apache };
1925         }
1926
1927         my ( $software, $version ) =
1928           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1929
1930         $version =~ s/_//g;
1931         $version =~ s/(\.[^.]+)\./$1/g;
1932
1933         if ( $software eq 'mod_perl' ) {
1934
1935             if ( !$engine ) {
1936
1937                 if ( $version >= 1.99922 ) {
1938                     $engine = 'Catalyst::Engine::Apache2::MP20';
1939                 }
1940
1941                 elsif ( $version >= 1.9901 ) {
1942                     $engine = 'Catalyst::Engine::Apache2::MP19';
1943                 }
1944
1945                 elsif ( $version >= 1.24 ) {
1946                     $engine = 'Catalyst::Engine::Apache::MP13';
1947                 }
1948
1949                 else {
1950                     Catalyst::Exception->throw( message =>
1951                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
1952                 }
1953
1954             }
1955
1956             # install the correct mod_perl handler
1957             if ( $version >= 1.9901 ) {
1958                 *handler = sub  : method {
1959                     shift->handle_request(@_);
1960                 };
1961             }
1962             else {
1963                 *handler = sub ($$) { shift->handle_request(@_) };
1964             }
1965
1966         }
1967
1968         elsif ( $software eq 'Zeus-Perl' ) {
1969             $engine = 'Catalyst::Engine::Zeus';
1970         }
1971
1972         else {
1973             Catalyst::Exception->throw(
1974                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
1975         }
1976     }
1977
1978     unless ($engine) {
1979         $engine = $class->engine_class;
1980     }
1981
1982     unless (Class::Inspector->loaded($engine)) {
1983         require Class::Inspector->filename($engine);
1984     }
1985
1986     # check for old engines that are no longer compatible
1987     my $old_engine;
1988     if ( $engine->isa('Catalyst::Engine::Apache')
1989         && !Catalyst::Engine::Apache->VERSION )
1990     {
1991         $old_engine = 1;
1992     }
1993
1994     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
1995         && Catalyst::Engine::Server->VERSION le '0.02' )
1996     {
1997         $old_engine = 1;
1998     }
1999
2000     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2001         && $engine->VERSION eq '0.01' )
2002     {
2003         $old_engine = 1;
2004     }
2005
2006     elsif ($engine->isa('Catalyst::Engine::Zeus')
2007         && $engine->VERSION eq '0.01' )
2008     {
2009         $old_engine = 1;
2010     }
2011
2012     if ($old_engine) {
2013         Catalyst::Exception->throw( message =>
2014               qq/Engine "$engine" is not supported by this version of Catalyst/
2015         );
2016     }
2017
2018     # engine instance
2019     $class->engine( $engine->new );
2020 }
2021
2022 =head2 $c->setup_home
2023
2024 Sets up the home directory.
2025
2026 =cut
2027
2028 sub setup_home {
2029     my ( $class, $home ) = @_;
2030
2031     if ( $ENV{CATALYST_HOME} ) {
2032         $home = $ENV{CATALYST_HOME};
2033     }
2034
2035     if ( $ENV{ uc($class) . '_HOME' } ) {
2036         $home = $ENV{ uc($class) . '_HOME' };
2037     }
2038
2039     unless ($home) {
2040         $home = Catalyst::Utils::home($class);
2041     }
2042
2043     if ($home) {
2044         $class->config->{home} ||= $home;
2045         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2046     }
2047 }
2048
2049 =head2 $c->setup_log
2050
2051 Sets up log.
2052
2053 =cut
2054
2055 sub setup_log {
2056     my ( $class, $debug ) = @_;
2057
2058     unless ( $class->log ) {
2059         $class->log( Catalyst::Log->new );
2060     }
2061
2062     my $app_flag = Catalyst::Utils::class2env($class) . '_DEBUG';
2063
2064     if (
2065           ( defined( $ENV{CATALYST_DEBUG} ) || defined( $ENV{$app_flag} ) )
2066         ? ( $ENV{CATALYST_DEBUG} || $ENV{$app_flag} )
2067         : $debug
2068       )
2069     {
2070         no strict 'refs';
2071         *{"$class\::debug"} = sub { 1 };
2072         $class->log->debug('Debug messages enabled');
2073     }
2074 }
2075
2076 =head2 $c->setup_plugins
2077
2078 Sets up plugins.
2079
2080 =cut
2081
2082 =head2 $c->registered_plugins
2083
2084 Returns a sorted list of the plugins which have either been stated in the
2085 import list or which have been added via C<< MyApp->plugin(@args); >>.
2086
2087 If passed a given plugin name, it will report a boolean value indicating
2088 whether or not that plugin is loaded.  A fully qualified name is required if
2089 the plugin name does not begin with C<Catalyst::Plugin::>.
2090
2091  if ($c->registered_plugins('Some::Plugin')) {
2092      ...
2093  }
2094
2095 =cut
2096
2097 {
2098
2099     sub registered_plugins {
2100         my $proto = shift;
2101         return sort keys %{ $proto->_plugins } unless @_;
2102         my $plugin = shift;
2103         return 1 if exists $proto->_plugins->{$plugin};
2104         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2105     }
2106
2107     sub _register_plugin {
2108         my ( $proto, $plugin, $instant ) = @_;
2109         my $class = ref $proto || $proto;
2110
2111         unless (Class::Inspector->loaded($plugin)) {
2112             require Class::Inspector->filename($plugin);
2113         }
2114
2115         $proto->_plugins->{$plugin} = 1;
2116         unless ($instant) {
2117             no strict 'refs';
2118             unshift @{"$class\::ISA"}, $plugin;
2119         }
2120         return $class;
2121     }
2122
2123     sub setup_plugins {
2124         my ( $class, $plugins ) = @_;
2125
2126         $class->_plugins( {} ) unless $class->_plugins;
2127         $plugins ||= [];
2128         for my $plugin ( reverse @$plugins ) {
2129
2130             unless ( $plugin =~ s/\A\+// ) {
2131                 $plugin = "Catalyst::Plugin::$plugin";
2132             }
2133
2134             $class->_register_plugin($plugin);
2135         }
2136     }
2137 }
2138
2139 =head2 $c->stack
2140
2141 Returns an arrayref of the internal execution stack (actions that are
2142 currently executing).
2143
2144 =head2 $c->write( $data )
2145
2146 Writes $data to the output stream. When using this method directly, you
2147 will need to manually set the C<Content-Length> header to the length of
2148 your output data, if known.
2149
2150 =cut
2151
2152 sub write {
2153     my $c = shift;
2154
2155     # Finalize headers if someone manually writes output
2156     $c->finalize_headers;
2157
2158     return $c->engine->write( $c, @_ );
2159 }
2160
2161 =head2 version
2162
2163 Returns the Catalyst version number. Mostly useful for "powered by"
2164 messages in template systems.
2165
2166 =cut
2167
2168 sub version { return $Catalyst::VERSION }
2169
2170 =head1 INTERNAL ACTIONS
2171
2172 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2173 C<_ACTION>, and C<_END>. These are by default not shown in the private
2174 action table, but you can make them visible with a config parameter.
2175
2176     MyApp->config->{show_internal_actions} = 1;
2177
2178 =head1 CASE SENSITIVITY
2179
2180 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2181 mapped to C</foo/bar>. You can activate case sensitivity with a config
2182 parameter.
2183
2184     MyApp->config->{case_sensitive} = 1;
2185
2186 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2187
2188 =head1 ON-DEMAND PARSER
2189
2190 The request body is usually parsed at the beginning of a request,
2191 but if you want to handle input yourself or speed things up a bit,
2192 you can enable on-demand parsing with a config parameter.
2193
2194     MyApp->config->{parse_on_demand} = 1;
2195
2196 =head1 PROXY SUPPORT
2197
2198 Many production servers operate using the common double-server approach,
2199 with a lightweight frontend web server passing requests to a larger
2200 backend server. An application running on the backend server must deal
2201 with two problems: the remote user always appears to be C<127.0.0.1> and
2202 the server's hostname will appear to be C<localhost> regardless of the
2203 virtual host that the user connected through.
2204
2205 Catalyst will automatically detect this situation when you are running
2206 the frontend and backend servers on the same machine. The following
2207 changes are made to the request.
2208
2209     $c->req->address is set to the user's real IP address, as read from
2210     the HTTP X-Forwarded-For header.
2211
2212     The host value for $c->req->base and $c->req->uri is set to the real
2213     host, as read from the HTTP X-Forwarded-Host header.
2214
2215 Obviously, your web server must support these headers for this to work.
2216
2217 In a more complex server farm environment where you may have your
2218 frontend proxy server(s) on different machines, you will need to set a
2219 configuration option to tell Catalyst to read the proxied data from the
2220 headers.
2221
2222     MyApp->config->{using_frontend_proxy} = 1;
2223
2224 If you do not wish to use the proxy support at all, you may set:
2225
2226     MyApp->config->{ignore_frontend_proxy} = 1;
2227
2228 =head1 THREAD SAFETY
2229
2230 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2231 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2232 believe the Catalyst core to be thread-safe.
2233
2234 If you plan to operate in a threaded environment, remember that all other
2235 modules you are using must also be thread-safe. Some modules, most notably
2236 L<DBD::SQLite>, are not thread-safe.
2237
2238 =head1 SUPPORT
2239
2240 IRC:
2241
2242     Join #catalyst on irc.perl.org.
2243
2244 Mailing Lists:
2245
2246     http://lists.rawmode.org/mailman/listinfo/catalyst
2247     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2248
2249 Web:
2250
2251     http://catalyst.perl.org
2252
2253 Wiki:
2254
2255     http://dev.catalyst.perl.org
2256
2257 =head1 SEE ALSO
2258
2259 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2260
2261 =head2 L<Catalyst::Manual> - The Catalyst Manual
2262
2263 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2264
2265 =head2 L<Catalyst::Engine> - Core engine
2266
2267 =head2 L<Catalyst::Log> - Log class.
2268
2269 =head2 L<Catalyst::Request> - Request object
2270
2271 =head2 L<Catalyst::Response> - Response object
2272
2273 =head2 L<Catalyst::Test> - The test suite.
2274
2275 =head1 CREDITS
2276
2277 Andy Grundman
2278
2279 Andy Wardley
2280
2281 Andreas Marienborg
2282
2283 Andrew Bramble
2284
2285 Andrew Ford
2286
2287 Andrew Ruthven
2288
2289 Arthur Bergman
2290
2291 Autrijus Tang
2292
2293 Brian Cassidy
2294
2295 Carl Franks
2296
2297 Christian Hansen
2298
2299 Christopher Hicks
2300
2301 Dan Sully
2302
2303 Danijel Milicevic
2304
2305 David Kamholz
2306
2307 David Naughton
2308
2309 Drew Taylor
2310
2311 Gary Ashton Jones
2312
2313 Geoff Richards
2314
2315 Jesse Sheidlower
2316
2317 Jesse Vincent
2318
2319 Jody Belka
2320
2321 Johan Lindstrom
2322
2323 Juan Camacho
2324
2325 Leon Brocard
2326
2327 Marcus Ramberg
2328
2329 Matt S Trout
2330
2331 Robert Sedlacek
2332
2333 Sam Vilain
2334
2335 Sascha Kiefer
2336
2337 Tatsuhiko Miyagawa
2338
2339 Ulf Edvinsson
2340
2341 Yuval Kogman
2342
2343 =head1 AUTHOR
2344
2345 Sebastian Riedel, C<sri@oook.de>
2346
2347 =head1 LICENSE
2348
2349 This library is free software, you can redistribute it and/or modify it under
2350 the same terms as Perl itself.
2351
2352 =cut
2353
2354 1;