lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use bytes;
   8 use B::Hooks::EndOfScope ();
   9 use Catalyst::Exception;
  10 use Catalyst::Exception::Detach;
  11 use Catalyst::Exception::Go;
  12 use Catalyst::Log;
  13 use Catalyst::Request;
  14 use Catalyst::Request::Upload;
  15 use Catalyst::Response;
  16 use Catalyst::Utils;
  17 use Catalyst::Controller;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use attributes;
  31 use utf8;
  32 use Carp qw/croak carp shortmess/;
  33
  34 BEGIN { require 5.008001; }
  35
  36 has stack => (is => 'ro', default => sub { [] });
  37 has stash => (is => 'rw', default => sub { {} });
  38 has state => (is => 'rw', default => 0);
  39 has stats => (is => 'rw');
  40 has action => (is => 'rw');
  41 has counter => (is => 'rw', default => sub { {} });
  42 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  43 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  44 has namespace => (is => 'rw');
  45
  46 sub depth { scalar @{ shift->stack || [] }; }
  47 sub comp { shift->component(@_) }
  48
  49 sub req {
  50     my $self = shift; return $self->request(@_);
  51 }
  52 sub res {
  53     my $self = shift; return $self->response(@_);
  54 }
  55
  56 # For backwards compatibility
  57 sub finalize_output { shift->finalize_body(@_) };
  58
  59 # For statistics
  60 our $COUNT     = 1;
  61 our $START     = time;
  62 our $RECURSION = 1000;
  63 our $DETACH    = Catalyst::Exception::Detach->new;
  64 our $GO        = Catalyst::Exception::Go->new;
  65
  66 #I imagine that very few of these really need to be class variables. if any.
  67 #maybe we should just make them attributes with a default?
  68 __PACKAGE__->mk_classdata($_)
  69   for qw/components arguments dispatcher engine log dispatcher_class
  70   engine_class context_class request_class response_class stats_class
  71   setup_finished/;
  72
  73 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  74 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  75 __PACKAGE__->request_class('Catalyst::Request');
  76 __PACKAGE__->response_class('Catalyst::Response');
  77 __PACKAGE__->stats_class('Catalyst::Stats');
  78
  79 # Remember to update this in Catalyst::Runtime as well!
  80
  81 our $VERSION = '5.80007';
  82
  83 {
  84     my $dev_version = $VERSION =~ /_\d{2}$/;
  85     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  86 }
  87
  88 $VERSION = eval $VERSION;
  89
  90 sub import {
  91     my ( $class, @arguments ) = @_;
  92
  93     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  94     # callers @ISA.
  95     return unless $class eq 'Catalyst';
  96
  97     my $caller = caller();
  98     return if $caller eq 'main';
  99
 100     # Kill Adopt::NEXT warnings if we're a non-RC version
 101     unless (_IS_DEVELOPMENT_VERSION()) {
 102         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 103     }
 104
 105     my $meta = Moose::Meta::Class->initialize($caller);
 106     unless ( $caller->isa('Catalyst') ) {
 107         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 108         $meta->superclasses(@superclasses);
 109     }
 110     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 111     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 112
 113     unless( $meta->has_method('meta') ){
 114         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 115     }
 116
 117     $caller->arguments( [@arguments] );
 118     $caller->setup_home;
 119 }
 120
 121 sub _application { $_[0] }
 122
 123 =head1 NAME
 124
 125 Catalyst - The Elegant MVC Web Application Framework
 126
 127 =head1 SYNOPSIS
 128
 129 See the L<Catalyst::Manual> distribution for comprehensive
 130 documentation and tutorials.
 131
 132     # Install Catalyst::Devel for helpers and other development tools
 133     # use the helper to create a new application
 134     catalyst.pl MyApp
 135
 136     # add models, views, controllers
 137     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 138     script/myapp_create.pl view MyTemplate TT
 139     script/myapp_create.pl controller Search
 140
 141     # built in testserver -- use -r to restart automatically on changes
 142     # --help to see all available options
 143     script/myapp_server.pl
 144
 145     # command line testing interface
 146     script/myapp_test.pl /yada
 147
 148     ### in lib/MyApp.pm
 149     use Catalyst qw/-Debug/; # include plugins here as well
 150
 151     ### In lib/MyApp/Controller/Root.pm (autocreated)
 152     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 153         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 154         $c->stash->{template} = 'foo.tt'; # set the template
 155         # lookup something from db -- stash vars are passed to TT
 156         $c->stash->{data} =
 157           $c->model('Database::Foo')->search( { country => $args[0] } );
 158         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 159             $c->forward( 'bar' ); # process another action
 160             # do something else after forward returns
 161         }
 162     }
 163
 164     # The foo.tt TT template can use the stash data from the database
 165     [% WHILE (item = data.next) %]
 166         [% item.foo %]
 167     [% END %]
 168
 169     # called for /bar/of/soap, /bar/of/soap/10, etc.
 170     sub bar : Path('/bar/of/soap') { ... }
 171
 172     # called for all actions, from the top-most controller downwards
 173     sub auto : Private {
 174         my ( $self, $c ) = @_;
 175         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 176             $c->res->redirect( '/login' ); # require login
 177             return 0; # abort request and go immediately to end()
 178         }
 179         return 1; # success; carry on to next action
 180     }
 181
 182     # called after all actions are finished
 183     sub end : Private {
 184         my ( $self, $c ) = @_;
 185         if ( scalar @{ $c->error } ) { ... } # handle errors
 186         return if $c->res->body; # already have a response
 187         $c->forward( 'MyApp::View::TT' ); # render template
 188     }
 189
 190     ### in MyApp/Controller/Foo.pm
 191     # called for /foo/bar
 192     sub bar : Local { ... }
 193
 194     # called for /blargle
 195     sub blargle : Global { ... }
 196
 197     # an index action matches /foo, but not /foo/1, etc.
 198     sub index : Private { ... }
 199
 200     ### in MyApp/Controller/Foo/Bar.pm
 201     # called for /foo/bar/baz
 202     sub baz : Local { ... }
 203
 204     # first Root auto is called, then Foo auto, then this
 205     sub auto : Private { ... }
 206
 207     # powerful regular expression paths are also possible
 208     sub details : Regex('^product/(\w+)/details$') {
 209         my ( $self, $c ) = @_;
 210         # extract the (\w+) from the URI
 211         my $product = $c->req->captures->[0];
 212     }
 213
 214 See L<Catalyst::Manual::Intro> for additional information.
 215
 216 =head1 DESCRIPTION
 217
 218 Catalyst is a modern framework for making web applications without the
 219 pain usually associated with this process. This document is a reference
 220 to the main Catalyst application. If you are a new user, we suggest you
 221 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 222
 223 See L<Catalyst::Manual> for more documentation.
 224
 225 Catalyst plugins can be loaded by naming them as arguments to the "use
 226 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 227 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 228 C<My::Module>.
 229
 230     use Catalyst qw/My::Module/;
 231
 232 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 233 fully qualify the name by using a unary plus:
 234
 235     use Catalyst qw/
 236         My::Module
 237         +Fully::Qualified::Plugin::Name
 238     /;
 239
 240 Special flags like C<-Debug> and C<-Engine> can also be specified as
 241 arguments when Catalyst is loaded:
 242
 243     use Catalyst qw/-Debug My::Module/;
 244
 245 The position of plugins and flags in the chain is important, because
 246 they are loaded in the order in which they appear.
 247
 248 The following flags are supported:
 249
 250 =head2 -Debug
 251
 252 Enables debug output. You can also force this setting from the system
 253 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 254 settings override the application, with <MYAPP>_DEBUG having the highest
 255 priority.
 256
 257 =head2 -Engine
 258
 259 Forces Catalyst to use a specific engine. Omit the
 260 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 261
 262     use Catalyst qw/-Engine=CGI/;
 263
 264 =head2 -Home
 265
 266 Forces Catalyst to use a specific home directory, e.g.:
 267
 268     use Catalyst qw[-Home=/usr/mst];
 269
 270 This can also be done in the shell environment by setting either the
 271 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 272 is replaced with the uppercased name of your application, any "::" in
 273 the name will be replaced with underscores, e.g. MyApp::Web should use
 274 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 275
 276 =head2 -Log
 277
 278     use Catalyst '-Log=warn,fatal,error';
 279
 280 Specifies a comma-delimited list of log levels.
 281
 282 =head2 -Stats
 283
 284 Enables statistics collection and reporting. You can also force this setting
 285 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 286 environment settings override the application, with <MYAPP>_STATS having the
 287 highest priority.
 288
 289 e.g.
 290
 291    use Catalyst qw/-Stats=1/
 292
 293 =head1 METHODS
 294
 295 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 296
 297 =head2 $c->action
 298
 299 Returns a L<Catalyst::Action> object for the current action, which
 300 stringifies to the action name. See L<Catalyst::Action>.
 301
 302 =head2 $c->namespace
 303
 304 Returns the namespace of the current action, i.e., the URI prefix
 305 corresponding to the controller of the current action. For example:
 306
 307     # in Controller::Foo::Bar
 308     $c->namespace; # returns 'foo/bar';
 309
 310 =head2 $c->request
 311
 312 =head2 $c->req
 313
 314 Returns the current L<Catalyst::Request> object, giving access to
 315 information about the current client request (including parameters,
 316 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 317
 318 =head2 REQUEST FLOW HANDLING
 319
 320 =head2 $c->forward( $action [, \@arguments ] )
 321
 322 =head2 $c->forward( $class, $method, [, \@arguments ] )
 323
 324 Forwards processing to another action, by its private name. If you give a
 325 class name but no method, C<process()> is called. You may also optionally
 326 pass arguments in an arrayref. The action will receive the arguments in
 327 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 328 C<< $c->req->args >> will be restored to the previous values.
 329
 330 Any data C<return>ed from the action forwarded to, will be returned by the
 331 call to forward.
 332
 333     my $foodata = $c->forward('/foo');
 334     $c->forward('index');
 335     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 336     $c->forward('MyApp::View::TT');
 337
 338 Note that forward implies an C<<eval { }>> around the call (actually
 339 C<execute> does), thus de-fatalizing all 'dies' within the called
 340 action. If you want C<die> to propagate you need to do something like:
 341
 342     $c->forward('foo');
 343     die $c->error if $c->error;
 344
 345 Or make sure to always return true values from your actions and write
 346 your code like this:
 347
 348     $c->forward('foo') || return;
 349
 350 =cut
 351
 352 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 353
 354 =head2 $c->detach( $action [, \@arguments ] )
 355
 356 =head2 $c->detach( $class, $method, [, \@arguments ] )
 357
 358 =head2 $c->detach()
 359
 360 The same as C<forward>, but doesn't return to the previous action when
 361 processing is finished.
 362
 363 When called with no arguments it escapes the processing chain entirely.
 364
 365 =cut
 366
 367 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 368
 369 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 370
 371 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 372
 373 Almost the same as C<forward>, but does a full dispatch, instead of just
 374 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 375 C<auto> and the method you go to are called, just like a new request.
 376
 377 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 378 This means, for example, that $c->action methods such as C<name>, C<class> and
 379 C<reverse> return information for the visited action when they are invoked
 380 within the visited action.  This is different from the behavior of C<forward>
 381 which continues to use the $c->action object from the caller action even when
 382 invoked from the callee.
 383
 384 C<$c-E<gt>stash> is kept unchanged.
 385
 386 In effect, C<visit> allows you to "wrap" another action, just as it
 387 would have been called by dispatching from a URL, while the analogous
 388 C<go> allows you to transfer control to another action as if it had
 389 been reached directly from a URL.
 390
 391 =cut
 392
 393 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 394
 395 =head2 $c->go( $action [, \@captures, \@arguments ] )
 396
 397 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 398
 399 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 400 instead of just calling the new C<$action> /
 401 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 402 method you visit are called, just like a new request.
 403
 404 C<$c-E<gt>stash> is kept unchanged.
 405
 406 =cut
 407
 408 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 409
 410 =head2 $c->response
 411
 412 =head2 $c->res
 413
 414 Returns the current L<Catalyst::Response> object, see there for details.
 415
 416 =head2 $c->stash
 417
 418 Returns a hashref to the stash, which may be used to store data and pass
 419 it between components during a request. You can also set hash keys by
 420 passing arguments. The stash is automatically sent to the view. The
 421 stash is cleared at the end of a request; it cannot be used for
 422 persistent storage (for this you must use a session; see
 423 L<Catalyst::Plugin::Session> for a complete system integrated with
 424 Catalyst).
 425
 426     $c->stash->{foo} = $bar;
 427     $c->stash( { moose => 'majestic', qux => 0 } );
 428     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 429
 430     # stash is automatically passed to the view for use in a template
 431     $c->forward( 'MyApp::View::TT' );
 432
 433 =cut
 434
 435 around stash => sub {
 436     my $orig = shift;
 437     my $c = shift;
 438     my $stash = $orig->($c);
 439     if (@_) {
 440         my $new_stash = @_ > 1 ? {@_} : $_[0];
 441         croak('stash takes a hash or hashref') unless ref $new_stash;
 442         foreach my $key ( keys %$new_stash ) {
 443           $stash->{$key} = $new_stash->{$key};
 444         }
 445     }
 446
 447     return $stash;
 448 };
 449
 450
 451 =head2 $c->error
 452
 453 =head2 $c->error($error, ...)
 454
 455 =head2 $c->error($arrayref)
 456
 457 Returns an arrayref containing error messages.  If Catalyst encounters an
 458 error while processing a request, it stores the error in $c->error.  This
 459 method should only be used to store fatal error messages.
 460
 461     my @error = @{ $c->error };
 462
 463 Add a new error.
 464
 465     $c->error('Something bad happened');
 466
 467 =cut
 468
 469 sub error {
 470     my $c = shift;
 471     if ( $_[0] ) {
 472         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 473         croak @$error unless ref $c;
 474         push @{ $c->{error} }, @$error;
 475     }
 476     elsif ( defined $_[0] ) { $c->{error} = undef }
 477     return $c->{error} || [];
 478 }
 479
 480
 481 =head2 $c->state
 482
 483 Contains the return value of the last executed action.
 484
 485 =head2 $c->clear_errors
 486
 487 Clear errors.  You probably don't want to clear the errors unless you are
 488 implementing a custom error screen.
 489
 490 This is equivalent to running
 491
 492     $c->error(0);
 493
 494 =cut
 495
 496 sub clear_errors {
 497     my $c = shift;
 498     $c->error(0);
 499 }
 500
 501 sub _comp_search_prefixes {
 502     my $c = shift;
 503     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 504 }
 505
 506 # search components given a name and some prefixes
 507 sub _comp_names_search_prefixes {
 508     my ( $c, $name, @prefixes ) = @_;
 509     my $appclass = ref $c || $c;
 510     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 511     $filter = qr/$filter/; # Compile regex now rather than once per loop
 512
 513     # map the original component name to the sub part that we will search against
 514     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 515         grep { /$filter/ } keys %{ $c->components };
 516
 517     # undef for a name will return all
 518     return keys %eligible if !defined $name;
 519
 520     my $query  = ref $name ? $name : qr/^$name$/i;
 521     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 522
 523     return @result if @result;
 524
 525     # if we were given a regexp to search against, we're done.
 526     return if ref $name;
 527
 528     # regexp fallback
 529     $query  = qr/$name/i;
 530     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 531
 532     # no results? try against full names
 533     if( !@result ) {
 534         @result = grep { m{$query} } keys %eligible;
 535     }
 536
 537     # don't warn if we didn't find any results, it just might not exist
 538     if( @result ) {
 539         # Disgusting hack to work out correct method name
 540         my $warn_for = lc $prefixes[0];
 541         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 542            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 543            "component resolution is unreliable and unsafe.";
 544         my $short = $result[0];
 545         $short =~ s/.*?Model:://;
 546         my $shortmess = Carp::shortmess('');
 547         if ($shortmess =~ m#Catalyst/Plugin#) {
 548            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 549               "plugin's config";
 550         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 551            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 552               "component's config";
 553         } else {
 554            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 555               "but if you really wanted to search, pass in a regexp as the argument " .
 556               "like so: \$c->${warn_for}(qr/${name}/)";
 557         }
 558         $c->log->warn( "${msg}$shortmess" );
 559     }
 560
 561     return @result;
 562 }
 563
 564 # Find possible names for a prefix
 565 sub _comp_names {
 566     my ( $c, @prefixes ) = @_;
 567     my $appclass = ref $c || $c;
 568
 569     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 570
 571     my @names = map { s{$filter}{}; $_; }
 572         $c->_comp_names_search_prefixes( undef, @prefixes );
 573
 574     return @names;
 575 }
 576
 577 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 578 sub _filter_component {
 579     my ( $c, $comp, @args ) = @_;
 580
 581     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 582         return $comp->ACCEPT_CONTEXT( $c, @args );
 583     }
 584
 585     return $comp;
 586 }
 587
 588 =head2 COMPONENT ACCESSORS
 589
 590 =head2 $c->controller($name)
 591
 592 Gets a L<Catalyst::Controller> instance by name.
 593
 594     $c->controller('Foo')->do_stuff;
 595
 596 If the name is omitted, will return the controller for the dispatched
 597 action.
 598
 599 If you want to search for controllers, pass in a regexp as the argument.
 600
 601     # find all controllers that start with Foo
 602     my @foo_controllers = $c->controller(qr{^Foo});
 603
 604
 605 =cut
 606
 607 sub controller {
 608     my ( $c, $name, @args ) = @_;
 609
 610     if( $name ) {
 611         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 612         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 613         return $c->_filter_component( $result[ 0 ], @args );
 614     }
 615
 616     return $c->component( $c->action->class );
 617 }
 618
 619 =head2 $c->model($name)
 620
 621 Gets a L<Catalyst::Model> instance by name.
 622
 623     $c->model('Foo')->do_stuff;
 624
 625 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 626
 627 If the name is omitted, it will look for
 628  - a model object in $c->stash->{current_model_instance}, then
 629  - a model name in $c->stash->{current_model}, then
 630  - a config setting 'default_model', or
 631  - check if there is only one model, and return it if that's the case.
 632
 633 If you want to search for models, pass in a regexp as the argument.
 634
 635     # find all models that start with Foo
 636     my @foo_models = $c->model(qr{^Foo});
 637
 638 =cut
 639
 640 sub model {
 641     my ( $c, $name, @args ) = @_;
 642
 643     if( $name ) {
 644         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 645         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 646         return $c->_filter_component( $result[ 0 ], @args );
 647     }
 648
 649     if (ref $c) {
 650         return $c->stash->{current_model_instance}
 651           if $c->stash->{current_model_instance};
 652         return $c->model( $c->stash->{current_model} )
 653           if $c->stash->{current_model};
 654     }
 655     return $c->model( $c->config->{default_model} )
 656       if $c->config->{default_model};
 657
 658     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 659
 660     if( $rest ) {
 661         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 662         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 663         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 664         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 665         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 666     }
 667
 668     return $c->_filter_component( $comp );
 669 }
 670
 671
 672 =head2 $c->view($name)
 673
 674 Gets a L<Catalyst::View> instance by name.
 675
 676     $c->view('Foo')->do_stuff;
 677
 678 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 679
 680 If the name is omitted, it will look for
 681  - a view object in $c->stash->{current_view_instance}, then
 682  - a view name in $c->stash->{current_view}, then
 683  - a config setting 'default_view', or
 684  - check if there is only one view, and return it if that's the case.
 685
 686 If you want to search for views, pass in a regexp as the argument.
 687
 688     # find all views that start with Foo
 689     my @foo_views = $c->view(qr{^Foo});
 690
 691 =cut
 692
 693 sub view {
 694     my ( $c, $name, @args ) = @_;
 695
 696     if( $name ) {
 697         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 698         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 699         return $c->_filter_component( $result[ 0 ], @args );
 700     }
 701
 702     if (ref $c) {
 703         return $c->stash->{current_view_instance}
 704           if $c->stash->{current_view_instance};
 705         return $c->view( $c->stash->{current_view} )
 706           if $c->stash->{current_view};
 707     }
 708     return $c->view( $c->config->{default_view} )
 709       if $c->config->{default_view};
 710
 711     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 712
 713     if( $rest ) {
 714         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 715         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 716         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 717         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 718         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 719     }
 720
 721     return $c->_filter_component( $comp );
 722 }
 723
 724 =head2 $c->controllers
 725
 726 Returns the available names which can be passed to $c->controller
 727
 728 =cut
 729
 730 sub controllers {
 731     my ( $c ) = @_;
 732     return $c->_comp_names(qw/Controller C/);
 733 }
 734
 735 =head2 $c->models
 736
 737 Returns the available names which can be passed to $c->model
 738
 739 =cut
 740
 741 sub models {
 742     my ( $c ) = @_;
 743     return $c->_comp_names(qw/Model M/);
 744 }
 745
 746
 747 =head2 $c->views
 748
 749 Returns the available names which can be passed to $c->view
 750
 751 =cut
 752
 753 sub views {
 754     my ( $c ) = @_;
 755     return $c->_comp_names(qw/View V/);
 756 }
 757
 758 =head2 $c->comp($name)
 759
 760 =head2 $c->component($name)
 761
 762 Gets a component object by name. This method is not recommended,
 763 unless you want to get a specific component by full
 764 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 765 should be used instead.
 766
 767 If C<$name> is a regexp, a list of components matched against the full
 768 component name will be returned.
 769
 770 =cut
 771
 772 sub component {
 773     my ( $c, $name, @args ) = @_;
 774
 775     if( $name ) {
 776         my $comps = $c->components;
 777
 778         if( !ref $name ) {
 779             # is it the exact name?
 780             return $c->_filter_component( $comps->{ $name }, @args )
 781                        if exists $comps->{ $name };
 782
 783             # perhaps we just omitted "MyApp"?
 784             my $composed = ( ref $c || $c ) . "::${name}";
 785             return $c->_filter_component( $comps->{ $composed }, @args )
 786                        if exists $comps->{ $composed };
 787
 788             # search all of the models, views and controllers
 789             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 790             return $c->_filter_component( $comp, @args ) if $comp;
 791         }
 792
 793         # This is here so $c->comp( '::M::' ) works
 794         my $query = ref $name ? $name : qr{$name}i;
 795
 796         my @result = grep { m{$query} } keys %{ $c->components };
 797         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 798
 799         if( $result[ 0 ] ) {
 800             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 801             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 802             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 803             return $c->_filter_component( $result[ 0 ], @args );
 804         }
 805
 806         # I would expect to return an empty list here, but that breaks back-compat
 807     }
 808
 809     # fallback
 810     return sort keys %{ $c->components };
 811 }
 812
 813 =head2 CLASS DATA AND HELPER CLASSES
 814
 815 =head2 $c->config
 816
 817 Returns or takes a hashref containing the application's configuration.
 818
 819     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 820
 821 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 822 like myapp.conf in your applications home directory. See
 823 L<Catalyst::Plugin::ConfigLoader>.
 824
 825 =head3 Cascading configuration.
 826
 827 The config method is present on all Catalyst components, and configuration
 828 will be merged when an application is started. Configuration loaded with
 829 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 830 followed by configuration in your top level C<MyApp> class. These two
 831 configurations are merged, and then configuration data whose hash key matches a
 832 component name is merged with configuration for that component.
 833
 834 The configuration for a component is then passed to the C<new> method when a
 835 component is constructed.
 836
 837 For example:
 838
 839     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 840     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 841
 842 will mean that C<MyApp::Model::Foo> receives the following data when
 843 constructed:
 844
 845     MyApp::Model::Foo->new({
 846         bar => 'baz',
 847         quux => 'frob',
 848         overrides => 'me',
 849     });
 850
 851 =cut
 852
 853 around config => sub {
 854     my $orig = shift;
 855     my $c = shift;
 856
 857     croak('Setting config after setup has been run is not allowed.')
 858         if ( @_ and $c->setup_finished );
 859
 860     $c->$orig(@_);
 861 };
 862
 863 =head2 $c->log
 864
 865 Returns the logging object instance. Unless it is already set, Catalyst
 866 sets this up with a L<Catalyst::Log> object. To use your own log class,
 867 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 868 C<< __PACKAGE__->setup >>.
 869
 870  __PACKAGE__->log( MyLogger->new );
 871  __PACKAGE__->setup;
 872
 873 And later:
 874
 875     $c->log->info( 'Now logging with my own logger!' );
 876
 877 Your log class should implement the methods described in
 878 L<Catalyst::Log>.
 879
 880
 881 =head2 $c->debug
 882
 883 Returns 1 if debug mode is enabled, 0 otherwise.
 884
 885 You can enable debug mode in several ways:
 886
 887 =over
 888
 889 =item By calling myapp_server.pl with the -d flag
 890
 891 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 892
 893 =item The -Debug option in your MyApp.pm
 894
 895 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 896
 897 =back
 898
 899 Calling C<< $c->debug(1) >> has no effect.
 900
 901 =cut
 902
 903 sub debug { 0 }
 904
 905 =head2 $c->dispatcher
 906
 907 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 908
 909 =head2 $c->engine
 910
 911 Returns the engine instance. See L<Catalyst::Engine>.
 912
 913
 914 =head2 UTILITY METHODS
 915
 916 =head2 $c->path_to(@path)
 917
 918 Merges C<@path> with C<< $c->config->{home} >> and returns a
 919 L<Path::Class::Dir> object. Note you can usually use this object as
 920 a filename, but sometimes you will have to explicitly stringify it
 921 yourself by calling the C<<->stringify>> method.
 922
 923 For example:
 924
 925     $c->path_to( 'db', 'sqlite.db' );
 926
 927 =cut
 928
 929 sub path_to {
 930     my ( $c, @path ) = @_;
 931     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 932     if ( -d $path ) { return $path }
 933     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 934 }
 935
 936 =head2 $c->plugin( $name, $class, @args )
 937
 938 Helper method for plugins. It creates a class data accessor/mutator and
 939 loads and instantiates the given class.
 940
 941     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 942
 943     $c->prototype->define_javascript_functions;
 944
 945 B<Note:> This method of adding plugins is deprecated. The ability
 946 to add plugins like this B<will be removed> in a Catalyst 5.81.
 947 Please do not use this functionality in new code.
 948
 949 =cut
 950
 951 sub plugin {
 952     my ( $class, $name, $plugin, @args ) = @_;
 953
 954     # See block comment in t/unit_core_plugin.t
 955     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 956
 957     $class->_register_plugin( $plugin, 1 );
 958
 959     eval { $plugin->import };
 960     $class->mk_classdata($name);
 961     my $obj;
 962     eval { $obj = $plugin->new(@args) };
 963
 964     if ($@) {
 965         Catalyst::Exception->throw( message =>
 966               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 967     }
 968
 969     $class->$name($obj);
 970     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 971       if $class->debug;
 972 }
 973
 974 =head2 MyApp->setup
 975
 976 Initializes the dispatcher and engine, loads any plugins, and loads the
 977 model, view, and controller components. You may also specify an array
 978 of plugins to load here, if you choose to not load them in the C<use
 979 Catalyst> line.
 980
 981     MyApp->setup;
 982     MyApp->setup( qw/-Debug/ );
 983
 984 =cut
 985
 986 sub setup {
 987     my ( $class, @arguments ) = @_;
 988     croak('Running setup more than once')
 989         if ( $class->setup_finished );
 990
 991     unless ( $class->isa('Catalyst') ) {
 992
 993         Catalyst::Exception->throw(
 994             message => qq/'$class' does not inherit from Catalyst/ );
 995     }
 996
 997     if ( $class->arguments ) {
 998         @arguments = ( @arguments, @{ $class->arguments } );
 999     }
1000
1001     # Process options
1002     my $flags = {};
1003
1004     foreach (@arguments) {
1005
1006         if (/^-Debug$/) {
1007             $flags->{log} =
1008               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1009         }
1010         elsif (/^-(\w+)=?(.*)$/) {
1011             $flags->{ lc $1 } = $2;
1012         }
1013         else {
1014             push @{ $flags->{plugins} }, $_;
1015         }
1016     }
1017
1018     $class->setup_home( delete $flags->{home} );
1019
1020     $class->setup_log( delete $flags->{log} );
1021     $class->setup_plugins( delete $flags->{plugins} );
1022     $class->setup_dispatcher( delete $flags->{dispatcher} );
1023     $class->setup_engine( delete $flags->{engine} );
1024     $class->setup_stats( delete $flags->{stats} );
1025
1026     for my $flag ( sort keys %{$flags} ) {
1027
1028         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1029             &$code( $class, delete $flags->{$flag} );
1030         }
1031         else {
1032             $class->log->warn(qq/Unknown flag "$flag"/);
1033         }
1034     }
1035
1036     eval { require Catalyst::Devel; };
1037     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1038         $class->log->warn(<<"EOF");
1039 You are running an old script!
1040
1041   Please update by running (this will overwrite existing files):
1042     catalyst.pl -force -scripts $class
1043
1044   or (this will not overwrite existing files):
1045     catalyst.pl -scripts $class
1046
1047 EOF
1048     }
1049
1050     if ( $class->debug ) {
1051         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1052
1053         if (@plugins) {
1054             my $column_width = Catalyst::Utils::term_width() - 6;
1055             my $t = Text::SimpleTable->new($column_width);
1056             $t->row($_) for @plugins;
1057             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1058         }
1059
1060         my $dispatcher = $class->dispatcher;
1061         my $engine     = $class->engine;
1062         my $home       = $class->config->{home};
1063
1064         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1065         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1066
1067         $home
1068           ? ( -d $home )
1069           ? $class->log->debug(qq/Found home "$home"/)
1070           : $class->log->debug(qq/Home "$home" doesn't exist/)
1071           : $class->log->debug(q/Couldn't find home/);
1072     }
1073
1074     # Call plugins setup, this is stupid and evil.
1075     # Also screws C3 badly on 5.10, hack to avoid.
1076     {
1077         no warnings qw/redefine/;
1078         local *setup = sub { };
1079         $class->setup unless $Catalyst::__AM_RESTARTING;
1080     }
1081
1082     # Initialize our data structure
1083     $class->components( {} );
1084
1085     $class->setup_components;
1086
1087     if ( $class->debug ) {
1088         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1089         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1090         for my $comp ( sort keys %{ $class->components } ) {
1091             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1092             $t->row( $comp, $type );
1093         }
1094         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1095           if ( keys %{ $class->components } );
1096     }
1097
1098     # Add our self to components, since we are also a component
1099     if( $class->isa('Catalyst::Controller') ){
1100       $class->components->{$class} = $class;
1101     }
1102
1103     $class->setup_actions;
1104
1105     if ( $class->debug ) {
1106         my $name = $class->config->{name} || 'Application';
1107         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1108     }
1109     $class->log->_flush() if $class->log->can('_flush');
1110
1111     # Make sure that the application class becomes immutable at this point,
1112     B::Hooks::EndOfScope::on_scope_end {
1113         return if $@;
1114         my $meta = Class::MOP::get_metaclass_by_name($class);
1115         if (
1116             $meta->is_immutable
1117             && ! { $meta->immutable_options }->{replace_constructor}
1118             && (
1119                    $class->isa('Class::Accessor::Fast')
1120                 || $class->isa('Class::Accessor')
1121             )
1122         ) {
1123             warn "You made your application class ($class) immutable, "
1124                 . "but did not inline the\nconstructor. "
1125                 . "This will break catalyst, as your app \@ISA "
1126                 . "Class::Accessor(::Fast)?\nPlease pass "
1127                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1128         }
1129         $meta->make_immutable(replace_constructor => 1)
1130             unless $meta->is_immutable;
1131     };
1132
1133     $class->setup_finalize;
1134 }
1135
1136
1137 =head2 $app->setup_finalize
1138
1139 A hook to attach modifiers to.
1140 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1141 Also better than C< setup_finished(); >, as that is a getter method.
1142
1143     sub setup_finalize {
1144
1145         my $app = shift;
1146
1147         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1148
1149         $app->next::method(@_);
1150
1151
1152     }
1153
1154 =cut
1155
1156 sub setup_finalize {
1157     my ($class) = @_;
1158     $class->setup_finished(1);
1159 }
1160
1161 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1162
1163 =head2 $c->uri_for( $path, @args?, \%query_values? )
1164
1165 =over
1166
1167 =item $action
1168
1169 A Catalyst::Action object representing the Catalyst action you want to
1170 create a URI for. To get one for an action in the current controller,
1171 use C<< $c->action('someactionname') >>. To get one from different
1172 controller, fetch the controller using C<< $c->controller() >>, then
1173 call C<action_for> on it.
1174
1175 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1176 using C<< $c->req->captures >>.
1177
1178   # For the current action
1179   $c->uri_for($c->action, $c->req->captures);
1180
1181   # For the Foo action in the Bar controller
1182   $c->uri_for($c->controller('Bar')->action_for('Foo'), $c->req->captures);
1183
1184 =back
1185
1186 =cut
1187
1188 sub uri_for {
1189     my ( $c, $path, @args ) = @_;
1190
1191     if ( blessed($path) ) { # action object
1192         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1193                          ? shift(@args)
1194                          : [] );
1195         my $action = $path;
1196         $path = $c->dispatcher->uri_for_action($action, $captures);
1197         if (not defined $path) {
1198             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1199                 if $c->debug;
1200             return undef;
1201         }
1202         $path = '/' if $path eq '';
1203     }
1204
1205     undef($path) if (defined $path && $path eq '');
1206
1207     my $params =
1208       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1209
1210     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1211     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1212
1213     unshift(@args, $path);
1214
1215     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1216         my $namespace = $c->namespace;
1217         if (defined $path) { # cheesy hack to handle path '../foo'
1218            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1219         }
1220         unshift(@args, $namespace || '');
1221     }
1222
1223     # join args with '/', or a blank string
1224     my $args = join('/', grep { defined($_) } @args);
1225     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1226     $args =~ s!^/+!!;
1227     my $base = $c->req->base;
1228     my $class = ref($base);
1229     $base =~ s{(?<!/)$}{/};
1230
1231     my $query = '';
1232
1233     if (my @keys = keys %$params) {
1234       # somewhat lifted from URI::_query's query_form
1235       $query = '?'.join('&', map {
1236           my $val = $params->{$_};
1237           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1238           s/ /+/g;
1239           my $key = $_;
1240           $val = '' unless defined $val;
1241           (map {
1242               my $param = "$_";
1243               utf8::encode( $param ) if utf8::is_utf8($param);
1244               # using the URI::Escape pattern here so utf8 chars survive
1245               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1246               $param =~ s/ /+/g;
1247               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1248       } @keys);
1249     }
1250
1251     my $res = bless(\"${base}${args}${query}", $class);
1252     $res;
1253 }
1254
1255 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1256
1257 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1258
1259 =over
1260
1261 =item $path
1262
1263 A private path to the Catalyst action you want to create a URI for.
1264
1265 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1266 >> and passing the resulting C<$action> and the remaining arguments to C<<
1267 $c->uri_for >>.
1268
1269 You can also pass in a Catalyst::Action object, in which case it is passed to
1270 C<< $c->uri_for >>.
1271
1272 =back
1273
1274 =cut
1275
1276 sub uri_for_action {
1277     my ( $c, $path, @args ) = @_;
1278     my $action = blessed($path)
1279       ? $path
1280       : $c->dispatcher->get_action_by_path($path);
1281     unless (defined $action) {
1282       croak "Can't find action for path '$path'";
1283     }
1284     return $c->uri_for( $action, @args );
1285 }
1286
1287 =head2 $c->welcome_message
1288
1289 Returns the Catalyst welcome HTML page.
1290
1291 =cut
1292
1293 sub welcome_message {
1294     my $c      = shift;
1295     my $name   = $c->config->{name};
1296     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1297     my $prefix = Catalyst::Utils::appprefix( ref $c );
1298     $c->response->content_type('text/html; charset=utf-8');
1299     return <<"EOF";
1300 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1301     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1302 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1303     <head>
1304     <meta http-equiv="Content-Language" content="en" />
1305     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1306         <title>$name on Catalyst $VERSION</title>
1307         <style type="text/css">
1308             body {
1309                 color: #000;
1310                 background-color: #eee;
1311             }
1312             div#content {
1313                 width: 640px;
1314                 margin-left: auto;
1315                 margin-right: auto;
1316                 margin-top: 10px;
1317                 margin-bottom: 10px;
1318                 text-align: left;
1319                 background-color: #ccc;
1320                 border: 1px solid #aaa;
1321             }
1322             p, h1, h2 {
1323                 margin-left: 20px;
1324                 margin-right: 20px;
1325                 font-family: verdana, tahoma, sans-serif;
1326             }
1327             a {
1328                 font-family: verdana, tahoma, sans-serif;
1329             }
1330             :link, :visited {
1331                     text-decoration: none;
1332                     color: #b00;
1333                     border-bottom: 1px dotted #bbb;
1334             }
1335             :link:hover, :visited:hover {
1336                     color: #555;
1337             }
1338             div#topbar {
1339                 margin: 0px;
1340             }
1341             pre {
1342                 margin: 10px;
1343                 padding: 8px;
1344             }
1345             div#answers {
1346                 padding: 8px;
1347                 margin: 10px;
1348                 background-color: #fff;
1349                 border: 1px solid #aaa;
1350             }
1351             h1 {
1352                 font-size: 0.9em;
1353                 font-weight: normal;
1354                 text-align: center;
1355             }
1356             h2 {
1357                 font-size: 1.0em;
1358             }
1359             p {
1360                 font-size: 0.9em;
1361             }
1362             p img {
1363                 float: right;
1364                 margin-left: 10px;
1365             }
1366             span#appname {
1367                 font-weight: bold;
1368                 font-size: 1.6em;
1369             }
1370         </style>
1371     </head>
1372     <body>
1373         <div id="content">
1374             <div id="topbar">
1375                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1376                     $VERSION</h1>
1377              </div>
1378              <div id="answers">
1379                  <p>
1380                  <img src="$logo" alt="Catalyst Logo" />
1381                  </p>
1382                  <p>Welcome to the  world of Catalyst.
1383                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1384                     framework will make web development something you had
1385                     never expected it to be: Fun, rewarding, and quick.</p>
1386                  <h2>What to do now?</h2>
1387                  <p>That really depends  on what <b>you</b> want to do.
1388                     We do, however, provide you with a few starting points.</p>
1389                  <p>If you want to jump right into web development with Catalyst
1390                     you might want to start with a tutorial.</p>
1391 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1392 </pre>
1393 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1394 <pre>
1395 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1396 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1397 </code></pre>
1398                  <h2>What to do next?</h2>
1399                  <p>Next it's time to write an actual application. Use the
1400                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1401                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1402                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1403                     they can save you a lot of work.</p>
1404                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1405                     <p>Also, be sure to check out the vast and growing
1406                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1407                     you are likely to find what you need there.
1408                     </p>
1409
1410                  <h2>Need help?</h2>
1411                  <p>Catalyst has a very active community. Here are the main places to
1412                     get in touch with us.</p>
1413                  <ul>
1414                      <li>
1415                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1416                      </li>
1417                      <li>
1418                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1419                      </li>
1420                      <li>
1421                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1422                      </li>
1423                  </ul>
1424                  <h2>In conclusion</h2>
1425                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1426                     as we enjoyed making it. Please contact us if you have ideas
1427                     for improvement or other feedback.</p>
1428              </div>
1429          </div>
1430     </body>
1431 </html>
1432 EOF
1433 }
1434
1435 =head1 INTERNAL METHODS
1436
1437 These methods are not meant to be used by end users.
1438
1439 =head2 $c->components
1440
1441 Returns a hash of components.
1442
1443 =head2 $c->context_class
1444
1445 Returns or sets the context class.
1446
1447 =head2 $c->counter
1448
1449 Returns a hashref containing coderefs and execution counts (needed for
1450 deep recursion detection).
1451
1452 =head2 $c->depth
1453
1454 Returns the number of actions on the current internal execution stack.
1455
1456 =head2 $c->dispatch
1457
1458 Dispatches a request to actions.
1459
1460 =cut
1461
1462 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1463
1464 =head2 $c->dispatcher_class
1465
1466 Returns or sets the dispatcher class.
1467
1468 =head2 $c->dump_these
1469
1470 Returns a list of 2-element array references (name, structure) pairs
1471 that will be dumped on the error page in debug mode.
1472
1473 =cut
1474
1475 sub dump_these {
1476     my $c = shift;
1477     [ Request => $c->req ],
1478     [ Response => $c->res ],
1479     [ Stash => $c->stash ],
1480     [ Config => $c->config ];
1481 }
1482
1483 =head2 $c->engine_class
1484
1485 Returns or sets the engine class.
1486
1487 =head2 $c->execute( $class, $coderef )
1488
1489 Execute a coderef in given class and catch exceptions. Errors are available
1490 via $c->error.
1491
1492 =cut
1493
1494 sub execute {
1495     my ( $c, $class, $code ) = @_;
1496     $class = $c->component($class) || $class;
1497     $c->state(0);
1498
1499     if ( $c->depth >= $RECURSION ) {
1500         my $action = $code->reverse();
1501         $action = "/$action" unless $action =~ /->/;
1502         my $error = qq/Deep recursion detected calling "${action}"/;
1503         $c->log->error($error);
1504         $c->error($error);
1505         $c->state(0);
1506         return $c->state;
1507     }
1508
1509     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1510
1511     push( @{ $c->stack }, $code );
1512
1513     no warnings 'recursion';
1514     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1515
1516     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1517
1518     my $last = pop( @{ $c->stack } );
1519
1520     if ( my $error = $@ ) {
1521         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1522             $error->rethrow if $c->depth > 1;
1523         }
1524         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1525             $error->rethrow if $c->depth > 0;
1526         }
1527         else {
1528             unless ( ref $error ) {
1529                 no warnings 'uninitialized';
1530                 chomp $error;
1531                 my $class = $last->class;
1532                 my $name  = $last->name;
1533                 $error = qq/Caught exception in $class->$name "$error"/;
1534             }
1535             $c->error($error);
1536             $c->state(0);
1537         }
1538     }
1539     return $c->state;
1540 }
1541
1542 sub _stats_start_execute {
1543     my ( $c, $code ) = @_;
1544
1545     return if ( ( $code->name =~ /^_.*/ )
1546         && ( !$c->config->{show_internal_actions} ) );
1547
1548     my $action_name = $code->reverse();
1549     $c->counter->{$action_name}++;
1550
1551     my $action = $action_name;
1552     $action = "/$action" unless $action =~ /->/;
1553
1554     # determine if the call was the result of a forward
1555     # this is done by walking up the call stack and looking for a calling
1556     # sub of Catalyst::forward before the eval
1557     my $callsub = q{};
1558     for my $index ( 2 .. 11 ) {
1559         last
1560         if ( ( caller($index) )[0] eq 'Catalyst'
1561             && ( caller($index) )[3] eq '(eval)' );
1562
1563         if ( ( caller($index) )[3] =~ /forward$/ ) {
1564             $callsub = ( caller($index) )[3];
1565             $action  = "-> $action";
1566             last;
1567         }
1568     }
1569
1570     my $uid = $action_name . $c->counter->{$action_name};
1571
1572     # is this a root-level call or a forwarded call?
1573     if ( $callsub =~ /forward$/ ) {
1574
1575         # forward, locate the caller
1576         if ( my $parent = $c->stack->[-1] ) {
1577             $c->stats->profile(
1578                 begin  => $action,
1579                 parent => "$parent" . $c->counter->{"$parent"},
1580                 uid    => $uid,
1581             );
1582         }
1583         else {
1584
1585             # forward with no caller may come from a plugin
1586             $c->stats->profile(
1587                 begin => $action,
1588                 uid   => $uid,
1589             );
1590         }
1591     }
1592     else {
1593
1594         # root-level call
1595         $c->stats->profile(
1596             begin => $action,
1597             uid   => $uid,
1598         );
1599     }
1600     return $action;
1601
1602 }
1603
1604 sub _stats_finish_execute {
1605     my ( $c, $info ) = @_;
1606     $c->stats->profile( end => $info );
1607 }
1608
1609 =head2 $c->_localize_fields( sub { }, \%keys );
1610
1611 =cut
1612
1613 #Why does this exist? This is no longer safe and WILL NOT WORK.
1614 # it doesnt seem to be used anywhere. can we remove it?
1615 sub _localize_fields {
1616     my ( $c, $localized, $code ) = ( @_ );
1617
1618     my $request = delete $localized->{request} || {};
1619     my $response = delete $localized->{response} || {};
1620
1621     local @{ $c }{ keys %$localized } = values %$localized;
1622     local @{ $c->request }{ keys %$request } = values %$request;
1623     local @{ $c->response }{ keys %$response } = values %$response;
1624
1625     $code->();
1626 }
1627
1628 =head2 $c->finalize
1629
1630 Finalizes the request.
1631
1632 =cut
1633
1634 sub finalize {
1635     my $c = shift;
1636
1637     for my $error ( @{ $c->error } ) {
1638         $c->log->error($error);
1639     }
1640
1641     # Allow engine to handle finalize flow (for POE)
1642     my $engine = $c->engine;
1643     if ( my $code = $engine->can('finalize') ) {
1644         $engine->$code($c);
1645     }
1646     else {
1647
1648         $c->finalize_uploads;
1649
1650         # Error
1651         if ( $#{ $c->error } >= 0 ) {
1652             $c->finalize_error;
1653         }
1654
1655         $c->finalize_headers;
1656
1657         # HEAD request
1658         if ( $c->request->method eq 'HEAD' ) {
1659             $c->response->body('');
1660         }
1661
1662         $c->finalize_body;
1663     }
1664
1665     if ($c->use_stats) {
1666         my $elapsed = sprintf '%f', $c->stats->elapsed;
1667         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1668         $c->log->info(
1669             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1670     }
1671
1672     return $c->response->status;
1673 }
1674
1675 =head2 $c->finalize_body
1676
1677 Finalizes body.
1678
1679 =cut
1680
1681 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1682
1683 =head2 $c->finalize_cookies
1684
1685 Finalizes cookies.
1686
1687 =cut
1688
1689 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1690
1691 =head2 $c->finalize_error
1692
1693 Finalizes error.
1694
1695 =cut
1696
1697 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1698
1699 =head2 $c->finalize_headers
1700
1701 Finalizes headers.
1702
1703 =cut
1704
1705 sub finalize_headers {
1706     my $c = shift;
1707
1708     my $response = $c->response; #accessor calls can add up?
1709
1710     # Check if we already finalized headers
1711     return if $response->finalized_headers;
1712
1713     # Handle redirects
1714     if ( my $location = $response->redirect ) {
1715         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1716         $response->header( Location => $location );
1717
1718         if ( !$response->has_body ) {
1719             # Add a default body if none is already present
1720             $response->body(
1721                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1722             );
1723         }
1724     }
1725
1726     # Content-Length
1727     if ( $response->body && !$response->content_length ) {
1728
1729         # get the length from a filehandle
1730         if ( blessed( $response->body ) && $response->body->can('read') )
1731         {
1732             my $stat = stat $response->body;
1733             if ( $stat && $stat->size > 0 ) {
1734                 $response->content_length( $stat->size );
1735             }
1736             else {
1737                 $c->log->warn('Serving filehandle without a content-length');
1738             }
1739         }
1740         else {
1741             # everything should be bytes at this point, but just in case
1742             $response->content_length( bytes::length( $response->body ) );
1743         }
1744     }
1745
1746     # Errors
1747     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1748         $response->headers->remove_header("Content-Length");
1749         $response->body('');
1750     }
1751
1752     $c->finalize_cookies;
1753
1754     $c->engine->finalize_headers( $c, @_ );
1755
1756     # Done
1757     $response->finalized_headers(1);
1758 }
1759
1760 =head2 $c->finalize_output
1761
1762 An alias for finalize_body.
1763
1764 =head2 $c->finalize_read
1765
1766 Finalizes the input after reading is complete.
1767
1768 =cut
1769
1770 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1771
1772 =head2 $c->finalize_uploads
1773
1774 Finalizes uploads. Cleans up any temporary files.
1775
1776 =cut
1777
1778 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1779
1780 =head2 $c->get_action( $action, $namespace )
1781
1782 Gets an action in a given namespace.
1783
1784 =cut
1785
1786 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1787
1788 =head2 $c->get_actions( $action, $namespace )
1789
1790 Gets all actions of a given name in a namespace and all parent
1791 namespaces.
1792
1793 =cut
1794
1795 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1796
1797 =head2 $c->handle_request( $class, @arguments )
1798
1799 Called to handle each HTTP request.
1800
1801 =cut
1802
1803 sub handle_request {
1804     my ( $class, @arguments ) = @_;
1805
1806     # Always expect worst case!
1807     my $status = -1;
1808     eval {
1809         if ($class->debug) {
1810             my $secs = time - $START || 1;
1811             my $av = sprintf '%.3f', $COUNT / $secs;
1812             my $time = localtime time;
1813             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1814         }
1815
1816         my $c = $class->prepare(@arguments);
1817         $c->dispatch;
1818         $status = $c->finalize;
1819     };
1820
1821     if ( my $error = $@ ) {
1822         chomp $error;
1823         $class->log->error(qq/Caught exception in engine "$error"/);
1824     }
1825
1826     $COUNT++;
1827
1828     if(my $coderef = $class->log->can('_flush')){
1829         $class->log->$coderef();
1830     }
1831     return $status;
1832 }
1833
1834 =head2 $c->prepare( @arguments )
1835
1836 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1837 etc.).
1838
1839 =cut
1840
1841 sub prepare {
1842     my ( $class, @arguments ) = @_;
1843
1844     # XXX
1845     # After the app/ctxt split, this should become an attribute based on something passed
1846     # into the application.
1847     $class->context_class( ref $class || $class ) unless $class->context_class;
1848
1849     my $c = $class->context_class->new({});
1850
1851     # For on-demand data
1852     $c->request->_context($c);
1853     $c->response->_context($c);
1854
1855     #surely this is not the most efficient way to do things...
1856     $c->stats($class->stats_class->new)->enable($c->use_stats);
1857     if ( $c->debug ) {
1858         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1859     }
1860
1861     #XXX reuse coderef from can
1862     # Allow engine to direct the prepare flow (for POE)
1863     if ( $c->engine->can('prepare') ) {
1864         $c->engine->prepare( $c, @arguments );
1865     }
1866     else {
1867         $c->prepare_request(@arguments);
1868         $c->prepare_connection;
1869         $c->prepare_query_parameters;
1870         $c->prepare_headers;
1871         $c->prepare_cookies;
1872         $c->prepare_path;
1873
1874         # Prepare the body for reading, either by prepare_body
1875         # or the user, if they are using $c->read
1876         $c->prepare_read;
1877
1878         # Parse the body unless the user wants it on-demand
1879         unless ( $c->config->{parse_on_demand} ) {
1880             $c->prepare_body;
1881         }
1882     }
1883
1884     my $method  = $c->req->method  || '';
1885     my $path    = $c->req->path;
1886     $path       = '/' unless length $path;
1887     my $address = $c->req->address || '';
1888
1889     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1890       if $c->debug;
1891
1892     $c->prepare_action;
1893
1894     return $c;
1895 }
1896
1897 =head2 $c->prepare_action
1898
1899 Prepares action. See L<Catalyst::Dispatcher>.
1900
1901 =cut
1902
1903 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1904
1905 =head2 $c->prepare_body
1906
1907 Prepares message body.
1908
1909 =cut
1910
1911 sub prepare_body {
1912     my $c = shift;
1913
1914     return if $c->request->_has_body;
1915
1916     # Initialize on-demand data
1917     $c->engine->prepare_body( $c, @_ );
1918     $c->prepare_parameters;
1919     $c->prepare_uploads;
1920
1921     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1922         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1923         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1924             my $param = $c->req->body_parameters->{$key};
1925             my $value = defined($param) ? $param : '';
1926             $t->row( $key,
1927                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1928         }
1929         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1930     }
1931 }
1932
1933 =head2 $c->prepare_body_chunk( $chunk )
1934
1935 Prepares a chunk of data before sending it to L<HTTP::Body>.
1936
1937 See L<Catalyst::Engine>.
1938
1939 =cut
1940
1941 sub prepare_body_chunk {
1942     my $c = shift;
1943     $c->engine->prepare_body_chunk( $c, @_ );
1944 }
1945
1946 =head2 $c->prepare_body_parameters
1947
1948 Prepares body parameters.
1949
1950 =cut
1951
1952 sub prepare_body_parameters {
1953     my $c = shift;
1954     $c->engine->prepare_body_parameters( $c, @_ );
1955 }
1956
1957 =head2 $c->prepare_connection
1958
1959 Prepares connection.
1960
1961 =cut
1962
1963 sub prepare_connection {
1964     my $c = shift;
1965     $c->engine->prepare_connection( $c, @_ );
1966 }
1967
1968 =head2 $c->prepare_cookies
1969
1970 Prepares cookies.
1971
1972 =cut
1973
1974 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1975
1976 =head2 $c->prepare_headers
1977
1978 Prepares headers.
1979
1980 =cut
1981
1982 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1983
1984 =head2 $c->prepare_parameters
1985
1986 Prepares parameters.
1987
1988 =cut
1989
1990 sub prepare_parameters {
1991     my $c = shift;
1992     $c->prepare_body_parameters;
1993     $c->engine->prepare_parameters( $c, @_ );
1994 }
1995
1996 =head2 $c->prepare_path
1997
1998 Prepares path and base.
1999
2000 =cut
2001
2002 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2003
2004 =head2 $c->prepare_query_parameters
2005
2006 Prepares query parameters.
2007
2008 =cut
2009
2010 sub prepare_query_parameters {
2011     my $c = shift;
2012
2013     $c->engine->prepare_query_parameters( $c, @_ );
2014
2015     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
2016         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
2017         for my $key ( sort keys %{ $c->req->query_parameters } ) {
2018             my $param = $c->req->query_parameters->{$key};
2019             my $value = defined($param) ? $param : '';
2020             $t->row( $key,
2021                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2022         }
2023         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2024     }
2025 }
2026
2027 =head2 $c->prepare_read
2028
2029 Prepares the input for reading.
2030
2031 =cut
2032
2033 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2034
2035 =head2 $c->prepare_request
2036
2037 Prepares the engine request.
2038
2039 =cut
2040
2041 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2042
2043 =head2 $c->prepare_uploads
2044
2045 Prepares uploads.
2046
2047 =cut
2048
2049 sub prepare_uploads {
2050     my $c = shift;
2051
2052     $c->engine->prepare_uploads( $c, @_ );
2053
2054     if ( $c->debug && keys %{ $c->request->uploads } ) {
2055         my $t = Text::SimpleTable->new(
2056             [ 12, 'Parameter' ],
2057             [ 26, 'Filename' ],
2058             [ 18, 'Type' ],
2059             [ 9,  'Size' ]
2060         );
2061         for my $key ( sort keys %{ $c->request->uploads } ) {
2062             my $upload = $c->request->uploads->{$key};
2063             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2064                 $t->row( $key, $u->filename, $u->type, $u->size );
2065             }
2066         }
2067         $c->log->debug( "File Uploads are:\n" . $t->draw );
2068     }
2069 }
2070
2071 =head2 $c->prepare_write
2072
2073 Prepares the output for writing.
2074
2075 =cut
2076
2077 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2078
2079 =head2 $c->request_class
2080
2081 Returns or sets the request class.
2082
2083 =head2 $c->response_class
2084
2085 Returns or sets the response class.
2086
2087 =head2 $c->read( [$maxlength] )
2088
2089 Reads a chunk of data from the request body. This method is designed to
2090 be used in a while loop, reading C<$maxlength> bytes on every call.
2091 C<$maxlength> defaults to the size of the request if not specified.
2092
2093 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
2094 directly.
2095
2096 Warning: If you use read(), Catalyst will not process the body,
2097 so you will not be able to access POST parameters or file uploads via
2098 $c->request.  You must handle all body parsing yourself.
2099
2100 =cut
2101
2102 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2103
2104 =head2 $c->run
2105
2106 Starts the engine.
2107
2108 =cut
2109
2110 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2111
2112 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2113
2114 Sets an action in a given namespace.
2115
2116 =cut
2117
2118 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2119
2120 =head2 $c->setup_actions($component)
2121
2122 Sets up actions for a component.
2123
2124 =cut
2125
2126 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2127
2128 =head2 $c->setup_components
2129
2130 Sets up components. Specify a C<setup_components> config option to pass
2131 additional options directly to L<Module::Pluggable>. To add additional
2132 search paths, specify a key named C<search_extra> as an array
2133 reference. Items in the array beginning with C<::> will have the
2134 application class name prepended to them.
2135
2136 All components found will also have any
2137 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2138 Note, that modules which are B<not> an I<inner package> of the main
2139 file namespace loaded will not be instantiated as components.
2140
2141 =cut
2142
2143 sub setup_components {
2144     my $class = shift;
2145
2146     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2147     my $config  = $class->config->{ setup_components };
2148     my $extra   = delete $config->{ search_extra } || [];
2149
2150     push @paths, @$extra;
2151
2152     my $locator = Module::Pluggable::Object->new(
2153         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2154         %$config
2155     );
2156
2157     my @comps = sort { length $a <=> length $b } $locator->plugins;
2158     my %comps = map { $_ => 1 } @comps;
2159
2160     my $deprecated_component_names = grep { /::[CMV]::/ } @comps;
2161     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2162         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2163     ) if $deprecated_component_names;
2164
2165     for my $component ( @comps ) {
2166
2167         # We pass ignore_loaded here so that overlay files for (e.g.)
2168         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2169         # we know M::P::O found a file on disk so this is safe
2170
2171         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2172         #Class::MOP::load_class($component);
2173
2174         my $module  = $class->setup_component( $component );
2175         my %modules = (
2176             $component => $module,
2177             map {
2178                 $_ => $class->setup_component( $_ )
2179             } grep {
2180               not exists $comps{$_}
2181             } Devel::InnerPackage::list_packages( $component )
2182         );
2183
2184         for my $key ( keys %modules ) {
2185             $class->components->{ $key } = $modules{ $key };
2186         }
2187     }
2188 }
2189
2190 =head2 $c->setup_component
2191
2192 =cut
2193
2194 sub _controller_init_base_classes {
2195     my ($app_class, $component) = @_;
2196     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2197         Moose::Meta::Class->initialize( $class )
2198             unless find_meta($class);
2199     }
2200 }
2201
2202 sub setup_component {
2203     my( $class, $component ) = @_;
2204
2205     unless ( $component->can( 'COMPONENT' ) ) {
2206         return $component;
2207     }
2208
2209     # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2210     #         nearest to Catalyst::Controller first, no matter what order stuff happens
2211     #         to be loaded. There are TODO tests in Moose for this, see
2212     #         f2391d17574eff81d911b97be15ea51080500003
2213     if ($component->isa('Catalyst::Controller')) {
2214         $class->_controller_init_base_classes($component);
2215     }
2216
2217     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2218     my $config = $class->config->{ $suffix } || {};
2219
2220     my $instance = eval { $component->COMPONENT( $class, $config ); };
2221
2222     if ( my $error = $@ ) {
2223         chomp $error;
2224         Catalyst::Exception->throw(
2225             message => qq/Couldn't instantiate component "$component", "$error"/
2226         );
2227     }
2228
2229     unless (blessed $instance) {
2230         my $metaclass = Moose::Util::find_meta($component);
2231         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2232         my $component_method_from = $method_meta->associated_metaclass->name;
2233         my $value = defined($instance) ? $instance : 'undef';
2234         Catalyst::Exception->throw(
2235             message =>
2236             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2237         );
2238     }
2239     return $instance;
2240 }
2241
2242 =head2 $c->setup_dispatcher
2243
2244 Sets up dispatcher.
2245
2246 =cut
2247
2248 sub setup_dispatcher {
2249     my ( $class, $dispatcher ) = @_;
2250
2251     if ($dispatcher) {
2252         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2253     }
2254
2255     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2256         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2257     }
2258
2259     unless ($dispatcher) {
2260         $dispatcher = $class->dispatcher_class;
2261     }
2262
2263     Class::MOP::load_class($dispatcher);
2264
2265     # dispatcher instance
2266     $class->dispatcher( $dispatcher->new );
2267 }
2268
2269 =head2 $c->setup_engine
2270
2271 Sets up engine.
2272
2273 =cut
2274
2275 sub setup_engine {
2276     my ( $class, $engine ) = @_;
2277
2278     if ($engine) {
2279         $engine = 'Catalyst::Engine::' . $engine;
2280     }
2281
2282     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2283         $engine = 'Catalyst::Engine::' . $env;
2284     }
2285
2286     if ( $ENV{MOD_PERL} ) {
2287         my $meta = Class::MOP::get_metaclass_by_name($class);
2288
2289         # create the apache method
2290         $meta->add_method('apache' => sub { shift->engine->apache });
2291
2292         my ( $software, $version ) =
2293           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2294
2295         $version =~ s/_//g;
2296         $version =~ s/(\.[^.]+)\./$1/g;
2297
2298         if ( $software eq 'mod_perl' ) {
2299
2300             if ( !$engine ) {
2301
2302                 if ( $version >= 1.99922 ) {
2303                     $engine = 'Catalyst::Engine::Apache2::MP20';
2304                 }
2305
2306                 elsif ( $version >= 1.9901 ) {
2307                     $engine = 'Catalyst::Engine::Apache2::MP19';
2308                 }
2309
2310                 elsif ( $version >= 1.24 ) {
2311                     $engine = 'Catalyst::Engine::Apache::MP13';
2312                 }
2313
2314                 else {
2315                     Catalyst::Exception->throw( message =>
2316                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2317                 }
2318
2319             }
2320
2321             # install the correct mod_perl handler
2322             if ( $version >= 1.9901 ) {
2323                 *handler = sub  : method {
2324                     shift->handle_request(@_);
2325                 };
2326             }
2327             else {
2328                 *handler = sub ($$) { shift->handle_request(@_) };
2329             }
2330
2331         }
2332
2333         elsif ( $software eq 'Zeus-Perl' ) {
2334             $engine = 'Catalyst::Engine::Zeus';
2335         }
2336
2337         else {
2338             Catalyst::Exception->throw(
2339                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2340         }
2341     }
2342
2343     unless ($engine) {
2344         $engine = $class->engine_class;
2345     }
2346
2347     Class::MOP::load_class($engine);
2348
2349     # check for old engines that are no longer compatible
2350     my $old_engine;
2351     if ( $engine->isa('Catalyst::Engine::Apache')
2352         && !Catalyst::Engine::Apache->VERSION )
2353     {
2354         $old_engine = 1;
2355     }
2356
2357     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2358         && Catalyst::Engine::Server->VERSION le '0.02' )
2359     {
2360         $old_engine = 1;
2361     }
2362
2363     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2364         && $engine->VERSION eq '0.01' )
2365     {
2366         $old_engine = 1;
2367     }
2368
2369     elsif ($engine->isa('Catalyst::Engine::Zeus')
2370         && $engine->VERSION eq '0.01' )
2371     {
2372         $old_engine = 1;
2373     }
2374
2375     if ($old_engine) {
2376         Catalyst::Exception->throw( message =>
2377               qq/Engine "$engine" is not supported by this version of Catalyst/
2378         );
2379     }
2380
2381     # engine instance
2382     $class->engine( $engine->new );
2383 }
2384
2385 =head2 $c->setup_home
2386
2387 Sets up the home directory.
2388
2389 =cut
2390
2391 sub setup_home {
2392     my ( $class, $home ) = @_;
2393
2394     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2395         $home = $env;
2396     }
2397
2398     $home ||= Catalyst::Utils::home($class);
2399
2400     if ($home) {
2401         #I remember recently being scolded for assigning config values like this
2402         $class->config->{home} ||= $home;
2403         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2404     }
2405 }
2406
2407 =head2 $c->setup_log
2408
2409 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2410 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2411 log to.
2412
2413 This method also installs a C<debug> method that returns a true value into the
2414 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2415 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2416
2417 Note that if the log has already been setup, by either a previous call to
2418 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2419 that this method won't actually set up the log object.
2420
2421 =cut
2422
2423 sub setup_log {
2424     my ( $class, $levels ) = @_;
2425
2426     $levels ||= '';
2427     $levels =~ s/^\s+//;
2428     $levels =~ s/\s+$//;
2429     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2430
2431     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2432     if ( defined $env_debug ) {
2433         $levels{debug} = 1 if $env_debug; # Ugly!
2434         delete($levels{debug}) unless $env_debug;
2435     }
2436
2437     unless ( $class->log ) {
2438         $class->log( Catalyst::Log->new(keys %levels) );
2439     }
2440
2441     if ( $levels{debug} ) {
2442         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2443         $class->log->debug('Debug messages enabled');
2444     }
2445 }
2446
2447 =head2 $c->setup_plugins
2448
2449 Sets up plugins.
2450
2451 =cut
2452
2453 =head2 $c->setup_stats
2454
2455 Sets up timing statistics class.
2456
2457 =cut
2458
2459 sub setup_stats {
2460     my ( $class, $stats ) = @_;
2461
2462     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2463
2464     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2465     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2466         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2467         $class->log->debug('Statistics enabled');
2468     }
2469 }
2470
2471
2472 =head2 $c->registered_plugins
2473
2474 Returns a sorted list of the plugins which have either been stated in the
2475 import list or which have been added via C<< MyApp->plugin(@args); >>.
2476
2477 If passed a given plugin name, it will report a boolean value indicating
2478 whether or not that plugin is loaded.  A fully qualified name is required if
2479 the plugin name does not begin with C<Catalyst::Plugin::>.
2480
2481  if ($c->registered_plugins('Some::Plugin')) {
2482      ...
2483  }
2484
2485 =cut
2486
2487 {
2488
2489     sub registered_plugins {
2490         my $proto = shift;
2491         return sort keys %{ $proto->_plugins } unless @_;
2492         my $plugin = shift;
2493         return 1 if exists $proto->_plugins->{$plugin};
2494         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2495     }
2496
2497     sub _register_plugin {
2498         my ( $proto, $plugin, $instant ) = @_;
2499         my $class = ref $proto || $proto;
2500
2501         Class::MOP::load_class( $plugin );
2502
2503         $proto->_plugins->{$plugin} = 1;
2504         unless ($instant) {
2505             no strict 'refs';
2506             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2507               my @superclasses = ($plugin, $meta->superclasses );
2508               $meta->superclasses(@superclasses);
2509             } else {
2510               unshift @{"$class\::ISA"}, $plugin;
2511             }
2512         }
2513         return $class;
2514     }
2515
2516     sub setup_plugins {
2517         my ( $class, $plugins ) = @_;
2518
2519         $class->_plugins( {} ) unless $class->_plugins;
2520         $plugins ||= [];
2521
2522         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2523
2524         for my $plugin ( reverse @plugins ) {
2525             Class::MOP::load_class($plugin);
2526             my $meta = find_meta($plugin);
2527             next if $meta && $meta->isa('Moose::Meta::Role');
2528
2529             $class->_register_plugin($plugin);
2530         }
2531
2532         my @roles =
2533             map { $_->name }
2534             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2535             map { find_meta($_) }
2536             @plugins;
2537
2538         Moose::Util::apply_all_roles(
2539             $class => @roles
2540         ) if @roles;
2541     }
2542 }
2543
2544 =head2 $c->stack
2545
2546 Returns an arrayref of the internal execution stack (actions that are
2547 currently executing).
2548
2549 =head2 $c->stats_class
2550
2551 Returns or sets the stats (timing statistics) class.
2552
2553 =head2 $c->use_stats
2554
2555 Returns 1 when stats collection is enabled.  Stats collection is enabled
2556 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2557 environment variable is set.
2558
2559 Note that this is a static method, not an accessor and should be overridden
2560 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2561
2562 =cut
2563
2564 sub use_stats { 0 }
2565
2566
2567 =head2 $c->write( $data )
2568
2569 Writes $data to the output stream. When using this method directly, you
2570 will need to manually set the C<Content-Length> header to the length of
2571 your output data, if known.
2572
2573 =cut
2574
2575 sub write {
2576     my $c = shift;
2577
2578     # Finalize headers if someone manually writes output
2579     $c->finalize_headers;
2580
2581     return $c->engine->write( $c, @_ );
2582 }
2583
2584 =head2 version
2585
2586 Returns the Catalyst version number. Mostly useful for "powered by"
2587 messages in template systems.
2588
2589 =cut
2590
2591 sub version { return $Catalyst::VERSION }
2592
2593 =head1 INTERNAL ACTIONS
2594
2595 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2596 C<_ACTION>, and C<_END>. These are by default not shown in the private
2597 action table, but you can make them visible with a config parameter.
2598
2599     MyApp->config->{show_internal_actions} = 1;
2600
2601 =head1 CASE SENSITIVITY
2602
2603 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2604 mapped to C</foo/bar>. You can activate case sensitivity with a config
2605 parameter.
2606
2607     MyApp->config->{case_sensitive} = 1;
2608
2609 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2610
2611 =head1 ON-DEMAND PARSER
2612
2613 The request body is usually parsed at the beginning of a request,
2614 but if you want to handle input yourself, you can enable on-demand
2615 parsing with a config parameter.
2616
2617     MyApp->config->{parse_on_demand} = 1;
2618
2619 =head1 PROXY SUPPORT
2620
2621 Many production servers operate using the common double-server approach,
2622 with a lightweight frontend web server passing requests to a larger
2623 backend server. An application running on the backend server must deal
2624 with two problems: the remote user always appears to be C<127.0.0.1> and
2625 the server's hostname will appear to be C<localhost> regardless of the
2626 virtual host that the user connected through.
2627
2628 Catalyst will automatically detect this situation when you are running
2629 the frontend and backend servers on the same machine. The following
2630 changes are made to the request.
2631
2632     $c->req->address is set to the user's real IP address, as read from
2633     the HTTP X-Forwarded-For header.
2634
2635     The host value for $c->req->base and $c->req->uri is set to the real
2636     host, as read from the HTTP X-Forwarded-Host header.
2637
2638 Obviously, your web server must support these headers for this to work.
2639
2640 In a more complex server farm environment where you may have your
2641 frontend proxy server(s) on different machines, you will need to set a
2642 configuration option to tell Catalyst to read the proxied data from the
2643 headers.
2644
2645     MyApp->config->{using_frontend_proxy} = 1;
2646
2647 If you do not wish to use the proxy support at all, you may set:
2648
2649     MyApp->config->{ignore_frontend_proxy} = 1;
2650
2651 =head1 THREAD SAFETY
2652
2653 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2654 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2655 believe the Catalyst core to be thread-safe.
2656
2657 If you plan to operate in a threaded environment, remember that all other
2658 modules you are using must also be thread-safe. Some modules, most notably
2659 L<DBD::SQLite>, are not thread-safe.
2660
2661 =head1 SUPPORT
2662
2663 IRC:
2664
2665     Join #catalyst on irc.perl.org.
2666
2667 Mailing Lists:
2668
2669     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2670     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2671
2672 Web:
2673
2674     http://catalyst.perl.org
2675
2676 Wiki:
2677
2678     http://dev.catalyst.perl.org
2679
2680 =head1 SEE ALSO
2681
2682 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2683
2684 =head2 L<Catalyst::Manual> - The Catalyst Manual
2685
2686 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2687
2688 =head2 L<Catalyst::Engine> - Core engine
2689
2690 =head2 L<Catalyst::Log> - Log class.
2691
2692 =head2 L<Catalyst::Request> - Request object
2693
2694 =head2 L<Catalyst::Response> - Response object
2695
2696 =head2 L<Catalyst::Test> - The test suite.
2697
2698 =head1 PROJECT FOUNDER
2699
2700 sri: Sebastian Riedel <sri@cpan.org>
2701
2702 =head1 CONTRIBUTORS
2703
2704 abw: Andy Wardley
2705
2706 acme: Leon Brocard <leon@astray.com>
2707
2708 Andrew Bramble
2709
2710 Andrew Ford
2711
2712 Andrew Ruthven
2713
2714 andyg: Andy Grundman <andy@hybridized.org>
2715
2716 audreyt: Audrey Tang
2717
2718 bricas: Brian Cassidy <bricas@cpan.org>
2719
2720 Caelum: Rafael Kitover <rkitover@io.com>
2721
2722 chansen: Christian Hansen
2723
2724 chicks: Christopher Hicks
2725
2726 David E. Wheeler
2727
2728 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2729
2730 Drew Taylor
2731
2732 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2733
2734 esskar: Sascha Kiefer
2735
2736 fireartist: Carl Franks <cfranks@cpan.org>
2737
2738 gabb: Danijel Milicevic
2739
2740 Gary Ashton Jones
2741
2742 Geoff Richards
2743
2744 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2745
2746 jcamacho: Juan Camacho
2747
2748 jhannah: Jay Hannah <jay@jays.net>
2749
2750 Jody Belka
2751
2752 Johan Lindstrom
2753
2754 jon: Jon Schutz <jjschutz@cpan.org>
2755
2756 marcus: Marcus Ramberg <mramberg@cpan.org>
2757
2758 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2759
2760 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2761
2762 mugwump: Sam Vilain
2763
2764 naughton: David Naughton
2765
2766 ningu: David Kamholz <dkamholz@cpan.org>
2767
2768 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2769
2770 numa: Dan Sully <daniel@cpan.org>
2771
2772 obra: Jesse Vincent
2773
2774 omega: Andreas Marienborg
2775
2776 Oleg Kostyuk <cub.uanic@gmail.com>
2777
2778 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2779
2780 rafl: Florian Ragwitz <rafl@debian.org>
2781
2782 random: Roland Lammel <lammel@cpan.org>
2783
2784 sky: Arthur Bergman
2785
2786 the_jester: Jesse Sheidlower
2787
2788 t0m: Tomas Doran <bobtfish@bobtfish.net>
2789
2790 Ulf Edvinsson
2791
2792 willert: Sebastian Willert <willert@cpan.org>
2793
2794 =head1 LICENSE
2795
2796 This library is free software. You can redistribute it and/or modify it under
2797 the same terms as Perl itself.
2798
2799 =cut
2800
2801 no Moose;
2802
2803 __PACKAGE__->meta->make_immutable;
2804
2805 1;