lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use bytes;
   6 use Scope::Upper ();
   7 use Catalyst::Exception;
   8 use Catalyst::Log;
   9 use Catalyst::Request;
  10 use Catalyst::Request::Upload;
  11 use Catalyst::Response;
  12 use Catalyst::Utils;
  13 use Catalyst::Controller;
  14 use Devel::InnerPackage ();
  15 use File::stat;
  16 use Module::Pluggable::Object ();
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use URI ();
  21 use URI::http;
  22 use URI::https;
  23 use Tree::Simple qw/use_weak_refs/;
  24 use Tree::Simple::Visitor::FindByUID;
  25 use Class::C3::Adopt::NEXT;
  26 use attributes;
  27 use utf8;
  28 use Carp qw/croak carp shortmess/;
  29
  30 BEGIN { require 5.008001; }
  31
  32 has stack => (is => 'ro', default => sub { [] });
  33 has stash => (is => 'rw', default => sub { {} });
  34 has state => (is => 'rw', default => 0);
  35 has stats => (is => 'rw');
  36 has action => (is => 'rw');
  37 has counter => (is => 'rw', default => sub { {} });
  38 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  39 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  40 has namespace => (is => 'rw');
  41
  42 sub depth { scalar @{ shift->stack || [] }; }
  43 sub comp { shift->component(@_) }
  44
  45 sub req {
  46     # carp "the use of req() is deprecated in favour of request()";
  47     my $self = shift; return $self->request(@_);
  48 }
  49 sub res {
  50     # carp "the use of res() is deprecated in favour of response()";
  51     my $self = shift; return $self->response(@_);
  52 }
  53
  54 # For backwards compatibility
  55 sub finalize_output { shift->finalize_body(@_) };
  56
  57 # For statistics
  58 our $COUNT     = 1;
  59 our $START     = time;
  60 our $RECURSION = 1000;
  61 our $DETACH    = "catalyst_detach\n";
  62 our $GO        = "catalyst_go\n";
  63
  64 #I imagine that very few of these really need to be class variables. if any.
  65 #maybe we should just make them attributes with a default?
  66 __PACKAGE__->mk_classdata($_)
  67   for qw/components arguments dispatcher engine log dispatcher_class
  68   engine_class context_class request_class response_class stats_class
  69   setup_finished/;
  70
  71 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  72 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  73 __PACKAGE__->request_class('Catalyst::Request');
  74 __PACKAGE__->response_class('Catalyst::Response');
  75 __PACKAGE__->stats_class('Catalyst::Stats');
  76
  77 # Remember to update this in Catalyst::Runtime as well!
  78
  79 our $VERSION = '5.8000_06';
  80
  81 {
  82     my $dev_version = $VERSION =~ /_\d{2}$/;
  83     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  84 }
  85
  86 $VERSION = eval $VERSION;
  87
  88 sub import {
  89     my ( $class, @arguments ) = @_;
  90
  91     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  92     # callers @ISA.
  93     return unless $class eq 'Catalyst';
  94
  95     my $caller = caller();
  96     return if $caller eq 'main';
  97
  98     # Kill Adopt::NEXT warnings if we're a non-RC version
  99     unless (_IS_DEVELOPMENT_VERSION()) {
 100         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 101     }
 102
 103     my $meta = Moose::Meta::Class->initialize($caller);
 104     #Moose->import({ into => $caller }); #do we want to do this?
 105
 106     unless ( $caller->isa('Catalyst') ) {
 107         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 108         $meta->superclasses(@superclasses);
 109     }
 110     unless( $meta->has_method('meta') ){
 111         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 112     }
 113
 114     $caller->arguments( [@arguments] );
 115     $caller->setup_home;
 116 }
 117
 118 =head1 NAME
 119
 120 Catalyst - The Elegant MVC Web Application Framework
 121
 122 =head1 SYNOPSIS
 123
 124 See the L<Catalyst::Manual> distribution for comprehensive
 125 documentation and tutorials.
 126
 127     # Install Catalyst::Devel for helpers and other development tools
 128     # use the helper to create a new application
 129     catalyst.pl MyApp
 130
 131     # add models, views, controllers
 132     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 133     script/myapp_create.pl view MyTemplate TT
 134     script/myapp_create.pl controller Search
 135
 136     # built in testserver -- use -r to restart automatically on changes
 137     # --help to see all available options
 138     script/myapp_server.pl
 139
 140     # command line testing interface
 141     script/myapp_test.pl /yada
 142
 143     ### in lib/MyApp.pm
 144     use Catalyst qw/-Debug/; # include plugins here as well
 145
 146     ### In lib/MyApp/Controller/Root.pm (autocreated)
 147     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 148         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 149         $c->stash->{template} = 'foo.tt'; # set the template
 150         # lookup something from db -- stash vars are passed to TT
 151         $c->stash->{data} =
 152           $c->model('Database::Foo')->search( { country => $args[0] } );
 153         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 154             $c->forward( 'bar' ); # process another action
 155             # do something else after forward returns
 156         }
 157     }
 158
 159     # The foo.tt TT template can use the stash data from the database
 160     [% WHILE (item = data.next) %]
 161         [% item.foo %]
 162     [% END %]
 163
 164     # called for /bar/of/soap, /bar/of/soap/10, etc.
 165     sub bar : Path('/bar/of/soap') { ... }
 166
 167     # called for all actions, from the top-most controller downwards
 168     sub auto : Private {
 169         my ( $self, $c ) = @_;
 170         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 171             $c->res->redirect( '/login' ); # require login
 172             return 0; # abort request and go immediately to end()
 173         }
 174         return 1; # success; carry on to next action
 175     }
 176
 177     # called after all actions are finished
 178     sub end : Private {
 179         my ( $self, $c ) = @_;
 180         if ( scalar @{ $c->error } ) { ... } # handle errors
 181         return if $c->res->body; # already have a response
 182         $c->forward( 'MyApp::View::TT' ); # render template
 183     }
 184
 185     ### in MyApp/Controller/Foo.pm
 186     # called for /foo/bar
 187     sub bar : Local { ... }
 188
 189     # called for /blargle
 190     sub blargle : Global { ... }
 191
 192     # an index action matches /foo, but not /foo/1, etc.
 193     sub index : Private { ... }
 194
 195     ### in MyApp/Controller/Foo/Bar.pm
 196     # called for /foo/bar/baz
 197     sub baz : Local { ... }
 198
 199     # first Root auto is called, then Foo auto, then this
 200     sub auto : Private { ... }
 201
 202     # powerful regular expression paths are also possible
 203     sub details : Regex('^product/(\w+)/details$') {
 204         my ( $self, $c ) = @_;
 205         # extract the (\w+) from the URI
 206         my $product = $c->req->captures->[0];
 207     }
 208
 209 See L<Catalyst::Manual::Intro> for additional information.
 210
 211 =head1 DESCRIPTION
 212
 213 Catalyst is a modern framework for making web applications without the
 214 pain usually associated with this process. This document is a reference
 215 to the main Catalyst application. If you are a new user, we suggest you
 216 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 217
 218 See L<Catalyst::Manual> for more documentation.
 219
 220 Catalyst plugins can be loaded by naming them as arguments to the "use
 221 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 222 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 223 C<My::Module>.
 224
 225     use Catalyst qw/My::Module/;
 226
 227 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 228 fully qualify the name by using a unary plus:
 229
 230     use Catalyst qw/
 231         My::Module
 232         +Fully::Qualified::Plugin::Name
 233     /;
 234
 235 Special flags like C<-Debug> and C<-Engine> can also be specified as
 236 arguments when Catalyst is loaded:
 237
 238     use Catalyst qw/-Debug My::Module/;
 239
 240 The position of plugins and flags in the chain is important, because
 241 they are loaded in the order in which they appear.
 242
 243 The following flags are supported:
 244
 245 =head2 -Debug
 246
 247 Enables debug output. You can also force this setting from the system
 248 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 249 settings override the application, with <MYAPP>_DEBUG having the highest
 250 priority.
 251
 252 =head2 -Engine
 253
 254 Forces Catalyst to use a specific engine. Omit the
 255 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 256
 257     use Catalyst qw/-Engine=CGI/;
 258
 259 =head2 -Home
 260
 261 Forces Catalyst to use a specific home directory, e.g.:
 262
 263     use Catalyst qw[-Home=/usr/mst];
 264
 265 This can also be done in the shell environment by setting either the
 266 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 267 is replaced with the uppercased name of your application, any "::" in
 268 the name will be replaced with underscores, e.g. MyApp::Web should use
 269 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 270
 271 =head2 -Log
 272
 273     use Catalyst '-Log=warn,fatal,error';
 274
 275 Specifies a comma-delimited list of log levels.
 276
 277 =head2 -Stats
 278
 279 Enables statistics collection and reporting. You can also force this setting
 280 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 281 environment settings override the application, with <MYAPP>_STATS having the
 282 highest priority.
 283
 284 e.g.
 285
 286    use Catalyst qw/-Stats=1/
 287
 288 =head1 METHODS
 289
 290 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 291
 292 =head2 $c->action
 293
 294 Returns a L<Catalyst::Action> object for the current action, which
 295 stringifies to the action name. See L<Catalyst::Action>.
 296
 297 =head2 $c->namespace
 298
 299 Returns the namespace of the current action, i.e., the URI prefix
 300 corresponding to the controller of the current action. For example:
 301
 302     # in Controller::Foo::Bar
 303     $c->namespace; # returns 'foo/bar';
 304
 305 =head2 $c->request
 306
 307 =head2 $c->req
 308
 309 Returns the current L<Catalyst::Request> object, giving access to
 310 information about the current client request (including parameters,
 311 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 312
 313 =head2 REQUEST FLOW HANDLING
 314
 315 =head2 $c->forward( $action [, \@arguments ] )
 316
 317 =head2 $c->forward( $class, $method, [, \@arguments ] )
 318
 319 Forwards processing to another action, by its private name. If you give a
 320 class name but no method, C<process()> is called. You may also optionally
 321 pass arguments in an arrayref. The action will receive the arguments in
 322 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 323 C<< $c->req->args >> will be restored to the previous values.
 324
 325 Any data C<return>ed from the action forwarded to, will be returned by the
 326 call to forward.
 327
 328     my $foodata = $c->forward('/foo');
 329     $c->forward('index');
 330     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 331     $c->forward('MyApp::View::TT');
 332
 333 Note that forward implies an C<<eval { }>> around the call (actually
 334 C<execute> does), thus de-fatalizing all 'dies' within the called
 335 action. If you want C<die> to propagate you need to do something like:
 336
 337     $c->forward('foo');
 338     die $c->error if $c->error;
 339
 340 Or make sure to always return true values from your actions and write
 341 your code like this:
 342
 343     $c->forward('foo') || return;
 344
 345 =cut
 346
 347 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 348
 349 =head2 $c->detach( $action [, \@arguments ] )
 350
 351 =head2 $c->detach( $class, $method, [, \@arguments ] )
 352
 353 =head2 $c->detach()
 354
 355 The same as C<forward>, but doesn't return to the previous action when
 356 processing is finished.
 357
 358 When called with no arguments it escapes the processing chain entirely.
 359
 360 =cut
 361
 362 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 363
 364 =head2 $c->visit( $action [, \@arguments ] )
 365
 366 =head2 $c->visit( $class, $method, [, \@arguments ] )
 367
 368 Almost the same as C<forward>, but does a full dispatch, instead of just
 369 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 370 C<auto> and the method you go to are called, just like a new request.
 371
 372 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 373 This means, for example, that $c->action methods such as C<name>, C<class> and
 374 C<reverse> return information for the visited action when they are invoked
 375 within the visited action.  This is different from the behavior of C<forward>
 376 which continues to use the $c->action object from the caller action even when
 377 invoked from the callee.
 378
 379 C<$c-E<gt>stash> is kept unchanged.
 380
 381 In effect, C<visit> allows you to "wrap" another action, just as it
 382 would have been called by dispatching from a URL, while the analogous
 383 C<go> allows you to transfer control to another action as if it had
 384 been reached directly from a URL.
 385
 386 =cut
 387
 388 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 389
 390 =head2 $c->go( $action [, \@arguments ] )
 391
 392 =head2 $c->go( $class, $method, [, \@arguments ] )
 393
 394 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 395 instead of just calling the new C<$action> /
 396 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 397 method you visit are called, just like a new request.
 398
 399 C<$c-E<gt>stash> is kept unchanged.
 400
 401 =cut
 402
 403 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 404
 405 =head2 $c->response
 406
 407 =head2 $c->res
 408
 409 Returns the current L<Catalyst::Response> object, see there for details.
 410
 411 =head2 $c->stash
 412
 413 Returns a hashref to the stash, which may be used to store data and pass
 414 it between components during a request. You can also set hash keys by
 415 passing arguments. The stash is automatically sent to the view. The
 416 stash is cleared at the end of a request; it cannot be used for
 417 persistent storage (for this you must use a session; see
 418 L<Catalyst::Plugin::Session> for a complete system integrated with
 419 Catalyst).
 420
 421     $c->stash->{foo} = $bar;
 422     $c->stash( { moose => 'majestic', qux => 0 } );
 423     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 424
 425     # stash is automatically passed to the view for use in a template
 426     $c->forward( 'MyApp::View::TT' );
 427
 428 =cut
 429
 430 around stash => sub {
 431     my $orig = shift;
 432     my $c = shift;
 433     my $stash = $orig->($c);
 434     if (@_) {
 435         my $new_stash = @_ > 1 ? {@_} : $_[0];
 436         croak('stash takes a hash or hashref') unless ref $new_stash;
 437         foreach my $key ( keys %$new_stash ) {
 438           $stash->{$key} = $new_stash->{$key};
 439         }
 440     }
 441
 442     return $stash;
 443 };
 444
 445
 446 =head2 $c->error
 447
 448 =head2 $c->error($error, ...)
 449
 450 =head2 $c->error($arrayref)
 451
 452 Returns an arrayref containing error messages.  If Catalyst encounters an
 453 error while processing a request, it stores the error in $c->error.  This
 454 method should only be used to store fatal error messages.
 455
 456     my @error = @{ $c->error };
 457
 458 Add a new error.
 459
 460     $c->error('Something bad happened');
 461
 462 =cut
 463
 464 sub error {
 465     my $c = shift;
 466     if ( $_[0] ) {
 467         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 468         croak @$error unless ref $c;
 469         push @{ $c->{error} }, @$error;
 470     }
 471     elsif ( defined $_[0] ) { $c->{error} = undef }
 472     return $c->{error} || [];
 473 }
 474
 475
 476 =head2 $c->state
 477
 478 Contains the return value of the last executed action.
 479
 480 =head2 $c->clear_errors
 481
 482 Clear errors.  You probably don't want to clear the errors unless you are
 483 implementing a custom error screen.
 484
 485 This is equivalent to running
 486
 487     $c->error(0);
 488
 489 =cut
 490
 491 sub clear_errors {
 492     my $c = shift;
 493     $c->error(0);
 494 }
 495
 496 # search components given a name and some prefixes
 497 sub _comp_search_prefixes {
 498     my ( $c, $name, @prefixes ) = @_;
 499     my $appclass = ref $c || $c;
 500     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 501     $filter = qr/$filter/; # Compile regex now rather than once per loop
 502
 503     # map the original component name to the sub part that we will search against
 504     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 505         grep { /$filter/ } keys %{ $c->components };
 506
 507     # undef for a name will return all
 508     return keys %eligible if !defined $name;
 509
 510     my $query  = ref $name ? $name : qr/^$name$/i;
 511     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 512
 513     return map { $c->components->{ $_ } } @result if @result;
 514
 515     # if we were given a regexp to search against, we're done.
 516     return if ref $name;
 517
 518     # regexp fallback
 519     $query  = qr/$name/i;
 520     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 521
 522     # no results? try against full names
 523     if( !@result ) {
 524         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 525     }
 526
 527     # don't warn if we didn't find any results, it just might not exist
 528     if( @result ) {
 529         # Disgusting hack to work out correct method name
 530         my $warn_for = lc $prefixes[0];
 531         my $msg = "Used regexp fallback for \$c->{$warn_for}('${name}'), which found '" .
 532            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 533            "component resolution is unreliable and unsafe.";
 534         my $short = $result[0];
 535         $short =~ s/.*?Model:://;
 536         my $shortmess = Carp::shortmess('');
 537         if ($shortmess =~ m#Catalyst/Plugin#) {
 538            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 539               "plugin's config";
 540         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 541            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 542               "component's config";
 543         } else {
 544            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 545               "but if you really wanted to search, pass in a regexp as the argument " .
 546               "like so: \$c->${warn_for}(qr/${name}/)";
 547         }
 548         $c->log->warn( "${msg}$shortmess" );
 549     }
 550
 551     return @result;
 552 }
 553
 554 # Find possible names for a prefix
 555 sub _comp_names {
 556     my ( $c, @prefixes ) = @_;
 557     my $appclass = ref $c || $c;
 558
 559     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 560
 561     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 562     return @names;
 563 }
 564
 565 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 566 sub _filter_component {
 567     my ( $c, $comp, @args ) = @_;
 568
 569     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 570         return $comp->ACCEPT_CONTEXT( $c, @args );
 571     }
 572
 573     return $comp;
 574 }
 575
 576 =head2 COMPONENT ACCESSORS
 577
 578 =head2 $c->controller($name)
 579
 580 Gets a L<Catalyst::Controller> instance by name.
 581
 582     $c->controller('Foo')->do_stuff;
 583
 584 If the name is omitted, will return the controller for the dispatched
 585 action.
 586
 587 If you want to search for controllers, pass in a regexp as the argument.
 588
 589     # find all controllers that start with Foo
 590     my @foo_controllers = $c->controller(qr{^Foo});
 591
 592
 593 =cut
 594
 595 sub controller {
 596     my ( $c, $name, @args ) = @_;
 597
 598     if( $name ) {
 599         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 600         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 601         return $c->_filter_component( $result[ 0 ], @args );
 602     }
 603
 604     return $c->component( $c->action->class );
 605 }
 606
 607 =head2 $c->model($name)
 608
 609 Gets a L<Catalyst::Model> instance by name.
 610
 611     $c->model('Foo')->do_stuff;
 612
 613 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 614
 615 If the name is omitted, it will look for
 616  - a model object in $c->stash->{current_model_instance}, then
 617  - a model name in $c->stash->{current_model}, then
 618  - a config setting 'default_model', or
 619  - check if there is only one model, and return it if that's the case.
 620
 621 If you want to search for models, pass in a regexp as the argument.
 622
 623     # find all models that start with Foo
 624     my @foo_models = $c->model(qr{^Foo});
 625
 626 =cut
 627
 628 sub model {
 629     my ( $c, $name, @args ) = @_;
 630
 631     if( $name ) {
 632         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 633         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 634         return $c->_filter_component( $result[ 0 ], @args );
 635     }
 636
 637     if (ref $c) {
 638         return $c->stash->{current_model_instance}
 639           if $c->stash->{current_model_instance};
 640         return $c->model( $c->stash->{current_model} )
 641           if $c->stash->{current_model};
 642     }
 643     return $c->model( $c->config->{default_model} )
 644       if $c->config->{default_model};
 645
 646     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 647
 648     if( $rest ) {
 649         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 650         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 651         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 652         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 653         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 654     }
 655
 656     return $c->_filter_component( $comp );
 657 }
 658
 659
 660 =head2 $c->view($name)
 661
 662 Gets a L<Catalyst::View> instance by name.
 663
 664     $c->view('Foo')->do_stuff;
 665
 666 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 667
 668 If the name is omitted, it will look for
 669  - a view object in $c->stash->{current_view_instance}, then
 670  - a view name in $c->stash->{current_view}, then
 671  - a config setting 'default_view', or
 672  - check if there is only one view, and return it if that's the case.
 673
 674 If you want to search for views, pass in a regexp as the argument.
 675
 676     # find all views that start with Foo
 677     my @foo_views = $c->view(qr{^Foo});
 678
 679 =cut
 680
 681 sub view {
 682     my ( $c, $name, @args ) = @_;
 683
 684     if( $name ) {
 685         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 686         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 687         return $c->_filter_component( $result[ 0 ], @args );
 688     }
 689
 690     if (ref $c) {
 691         return $c->stash->{current_view_instance}
 692           if $c->stash->{current_view_instance};
 693         return $c->view( $c->stash->{current_view} )
 694           if $c->stash->{current_view};
 695     }
 696     return $c->view( $c->config->{default_view} )
 697       if $c->config->{default_view};
 698
 699     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 700
 701     if( $rest ) {
 702         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 703         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 704         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 705         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 706         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 707     }
 708
 709     return $c->_filter_component( $comp );
 710 }
 711
 712 =head2 $c->controllers
 713
 714 Returns the available names which can be passed to $c->controller
 715
 716 =cut
 717
 718 sub controllers {
 719     my ( $c ) = @_;
 720     return $c->_comp_names(qw/Controller C/);
 721 }
 722
 723 =head2 $c->models
 724
 725 Returns the available names which can be passed to $c->model
 726
 727 =cut
 728
 729 sub models {
 730     my ( $c ) = @_;
 731     return $c->_comp_names(qw/Model M/);
 732 }
 733
 734
 735 =head2 $c->views
 736
 737 Returns the available names which can be passed to $c->view
 738
 739 =cut
 740
 741 sub views {
 742     my ( $c ) = @_;
 743     return $c->_comp_names(qw/View V/);
 744 }
 745
 746 =head2 $c->comp($name)
 747
 748 =head2 $c->component($name)
 749
 750 Gets a component object by name. This method is not recommended,
 751 unless you want to get a specific component by full
 752 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 753 should be used instead.
 754
 755 If C<$name> is a regexp, a list of components matched against the full
 756 component name will be returned.
 757
 758 =cut
 759
 760 sub component {
 761     my ( $c, $name, @args ) = @_;
 762
 763     if( $name ) {
 764         my $comps = $c->components;
 765
 766         if( !ref $name ) {
 767             # is it the exact name?
 768             return $c->_filter_component( $comps->{ $name }, @args )
 769                        if exists $comps->{ $name };
 770
 771             # perhaps we just omitted "MyApp"?
 772             my $composed = ( ref $c || $c ) . "::${name}";
 773             return $c->_filter_component( $comps->{ $composed }, @args )
 774                        if exists $comps->{ $composed };
 775
 776             # search all of the models, views and controllers
 777             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 778             return $c->_filter_component( $comp, @args ) if $comp;
 779         }
 780
 781         # This is here so $c->comp( '::M::' ) works
 782         my $query = ref $name ? $name : qr{$name}i;
 783
 784         my @result = grep { m{$query} } keys %{ $c->components };
 785         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 786
 787         if( $result[ 0 ] ) {
 788             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 789             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 790             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 791             return $c->_filter_component( $result[ 0 ], @args );
 792         }
 793
 794         # I would expect to return an empty list here, but that breaks back-compat
 795     }
 796
 797     # fallback
 798     return sort keys %{ $c->components };
 799 }
 800
 801 =head2 CLASS DATA AND HELPER CLASSES
 802
 803 =head2 $c->config
 804
 805 Returns or takes a hashref containing the application's configuration.
 806
 807     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 808
 809 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 810 like myapp.yml in your applications home directory. See
 811 L<Catalyst::Plugin::ConfigLoader>.
 812
 813     ---
 814     db: dsn:SQLite:foo.db
 815
 816
 817 =cut
 818
 819 around config => sub {
 820     my $orig = shift;
 821     my $c = shift;
 822
 823     croak('Setting config after setup has been run is not allowed.')
 824         if ( @_ and $c->setup_finished );
 825
 826     $c->$orig(@_);
 827 };
 828
 829 =head2 $c->log
 830
 831 Returns the logging object instance. Unless it is already set, Catalyst
 832 sets this up with a L<Catalyst::Log> object. To use your own log class,
 833 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 834 C<< __PACKAGE__->setup >>.
 835
 836  __PACKAGE__->log( MyLogger->new );
 837  __PACKAGE__->setup;
 838
 839 And later:
 840
 841     $c->log->info( 'Now logging with my own logger!' );
 842
 843 Your log class should implement the methods described in
 844 L<Catalyst::Log>.
 845
 846
 847 =head2 $c->debug
 848
 849 Overload to enable debug messages (same as -Debug option).
 850
 851 Note that this is a static method, not an accessor and should be overloaded
 852 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 853
 854 =cut
 855
 856 sub debug { 0 }
 857
 858 =head2 $c->dispatcher
 859
 860 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 861
 862 =head2 $c->engine
 863
 864 Returns the engine instance. See L<Catalyst::Engine>.
 865
 866
 867 =head2 UTILITY METHODS
 868
 869 =head2 $c->path_to(@path)
 870
 871 Merges C<@path> with C<< $c->config->{home} >> and returns a
 872 L<Path::Class::Dir> object.
 873
 874 For example:
 875
 876     $c->path_to( 'db', 'sqlite.db' );
 877
 878 =cut
 879
 880 sub path_to {
 881     my ( $c, @path ) = @_;
 882     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 883     if ( -d $path ) { return $path }
 884     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 885 }
 886
 887 =head2 $c->plugin( $name, $class, @args )
 888
 889 Helper method for plugins. It creates a class data accessor/mutator and
 890 loads and instantiates the given class.
 891
 892     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 893
 894     $c->prototype->define_javascript_functions;
 895
 896 B<Note:> This method of adding plugins is deprecated. The ability
 897 to add plugins like this B<will be removed> in a Catalyst 5.9.
 898 Please do not use this functionality in new code.
 899
 900 =cut
 901
 902 sub plugin {
 903     my ( $class, $name, $plugin, @args ) = @_;
 904
 905     # See block comment in t/unit_core_plugin.t
 906     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.9/);
 907
 908     $class->_register_plugin( $plugin, 1 );
 909
 910     eval { $plugin->import };
 911     $class->mk_classdata($name);
 912     my $obj;
 913     eval { $obj = $plugin->new(@args) };
 914
 915     if ($@) {
 916         Catalyst::Exception->throw( message =>
 917               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 918     }
 919
 920     $class->$name($obj);
 921     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 922       if $class->debug;
 923 }
 924
 925 =head2 MyApp->setup
 926
 927 Initializes the dispatcher and engine, loads any plugins, and loads the
 928 model, view, and controller components. You may also specify an array
 929 of plugins to load here, if you choose to not load them in the C<use
 930 Catalyst> line.
 931
 932     MyApp->setup;
 933     MyApp->setup( qw/-Debug/ );
 934
 935 =cut
 936
 937 sub setup {
 938     my ( $class, @arguments ) = @_;
 939     croak('Running setup more than once')
 940         if ( $class->setup_finished );
 941
 942     unless ( $class->isa('Catalyst') ) {
 943
 944         Catalyst::Exception->throw(
 945             message => qq/'$class' does not inherit from Catalyst/ );
 946     }
 947
 948     if ( $class->arguments ) {
 949         @arguments = ( @arguments, @{ $class->arguments } );
 950     }
 951
 952     # Process options
 953     my $flags = {};
 954
 955     foreach (@arguments) {
 956
 957         if (/^-Debug$/) {
 958             $flags->{log} =
 959               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 960         }
 961         elsif (/^-(\w+)=?(.*)$/) {
 962             $flags->{ lc $1 } = $2;
 963         }
 964         else {
 965             push @{ $flags->{plugins} }, $_;
 966         }
 967     }
 968
 969     $class->setup_home( delete $flags->{home} );
 970
 971     $class->setup_log( delete $flags->{log} );
 972     $class->setup_plugins( delete $flags->{plugins} );
 973     $class->setup_dispatcher( delete $flags->{dispatcher} );
 974     $class->setup_engine( delete $flags->{engine} );
 975     $class->setup_stats( delete $flags->{stats} );
 976
 977     for my $flag ( sort keys %{$flags} ) {
 978
 979         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 980             &$code( $class, delete $flags->{$flag} );
 981         }
 982         else {
 983             $class->log->warn(qq/Unknown flag "$flag"/);
 984         }
 985     }
 986
 987     eval { require Catalyst::Devel; };
 988     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 989         $class->log->warn(<<"EOF");
 990 You are running an old script!
 991
 992   Please update by running (this will overwrite existing files):
 993     catalyst.pl -force -scripts $class
 994
 995   or (this will not overwrite existing files):
 996     catalyst.pl -scripts $class
 997
 998 EOF
 999     }
1000
1001     if ( $class->debug ) {
1002         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1003
1004         if (@plugins) {
1005             my $column_width = Catalyst::Utils::term_width() - 6;
1006             my $t = Text::SimpleTable->new($column_width);
1007             $t->row($_) for @plugins;
1008             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1009         }
1010
1011         my $dispatcher = $class->dispatcher;
1012         my $engine     = $class->engine;
1013         my $home       = $class->config->{home};
1014
1015         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1016         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1017
1018         $home
1019           ? ( -d $home )
1020           ? $class->log->debug(qq/Found home "$home"/)
1021           : $class->log->debug(qq/Home "$home" doesn't exist/)
1022           : $class->log->debug(q/Couldn't find home/);
1023     }
1024
1025     # Call plugins setup, this is stupid and evil.
1026     {
1027         no warnings qw/redefine/;
1028         local *setup = sub { };
1029         $class->setup;
1030     }
1031
1032     # Initialize our data structure
1033     $class->components( {} );
1034
1035     $class->setup_components;
1036
1037     if ( $class->debug ) {
1038         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1039         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1040         for my $comp ( sort keys %{ $class->components } ) {
1041             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1042             $t->row( $comp, $type );
1043         }
1044         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1045           if ( keys %{ $class->components } );
1046     }
1047
1048     # Add our self to components, since we are also a component
1049     if( $class->isa('Catalyst::Controller') ){
1050       $class->components->{$class} = $class;
1051     }
1052
1053     $class->setup_actions;
1054
1055     if ( $class->debug ) {
1056         my $name = $class->config->{name} || 'Application';
1057         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1058     }
1059     $class->log->_flush() if $class->log->can('_flush');
1060
1061     # Make sure that the application class becomes immutable at this point,
1062     # which ensures that it gets an inlined constructor. This means that it
1063     # works even if the user has added a plugin which contains a new method.
1064     # Note however that we have to do the work on scope end, so that method
1065     # modifiers work correctly in MyApp (as you have to call setup _before_
1066     # applying modifiers).
1067     Scope::Upper::reap(sub {
1068         my $meta = Class::MOP::get_metaclass_by_name($class);
1069         $meta->make_immutable unless $meta->is_immutable;
1070     }, Scope::Upper::SCOPE(1));
1071
1072     $class->setup_finalize;
1073 }
1074
1075
1076 =head2 $app->setup_finalize
1077
1078 A hook to attach modifiers to.
1079 Using C< after setup => sub{}; > doesn't work, because of quirky things done for plugin setup.
1080 Also better than C< setup_finished(); >, as that is a getter method.
1081
1082     sub setup_finalize {
1083
1084         my $app = shift;
1085
1086         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1087
1088         $app->next::method(@_);
1089
1090
1091     }
1092
1093 =cut
1094
1095 sub setup_finalize {
1096     my ($class) = @_;
1097     $class->setup_finished(1);
1098 }
1099
1100 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1101
1102 =head2 $c->uri_for( $path, @args?, \%query_values? )
1103
1104 =over
1105
1106 =item $action
1107
1108 A Catalyst::Action object representing the Catalyst action you want to
1109 create a URI for. To get one for an action in the current controller,
1110 use C<< $c->action('someactionname') >>. To get one from different
1111 controller, fetch the controller using C<< $c->controller() >>, then
1112 call C<action_for> on it.
1113
1114 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1115 using C<< $c->req->captures >>.
1116
1117   # For the current action
1118   $c->uri_for($c->action, $c->req->captures);
1119
1120   # For the Foo action in the Bar controller
1121   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1122
1123 =back
1124
1125 =cut
1126
1127 sub uri_for {
1128     my ( $c, $path, @args ) = @_;
1129
1130     if ( blessed($path) ) { # action object
1131         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1132                          ? shift(@args)
1133                          : [] );
1134         $path = $c->dispatcher->uri_for_action($path, $captures);
1135         return undef unless defined($path);
1136         $path = '/' if $path eq '';
1137     }
1138
1139     undef($path) if (defined $path && $path eq '');
1140
1141     my $params =
1142       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1143
1144     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1145     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1146
1147     unshift(@args, $path);
1148
1149     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1150         my $namespace = $c->namespace;
1151         if (defined $path) { # cheesy hack to handle path '../foo'
1152            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1153         }
1154         unshift(@args, $namespace || '');
1155     }
1156
1157     # join args with '/', or a blank string
1158     my $args = join('/', grep { defined($_) } @args);
1159     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1160     $args =~ s!^/+!!;
1161     my $base = $c->req->base;
1162     my $class = ref($base);
1163     $base =~ s{(?<!/)$}{/};
1164
1165     my $query = '';
1166
1167     if (my @keys = keys %$params) {
1168       # somewhat lifted from URI::_query's query_form
1169       $query = '?'.join('&', map {
1170           my $val = $params->{$_};
1171           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1172           s/ /+/g;
1173           my $key = $_;
1174           $val = '' unless defined $val;
1175           (map {
1176               $_ = "$_";
1177               utf8::encode( $_ ) if utf8::is_utf8($_);
1178               # using the URI::Escape pattern here so utf8 chars survive
1179               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1180               s/ /+/g;
1181               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1182       } @keys);
1183     }
1184
1185     my $res = bless(\"${base}${args}${query}", $class);
1186     $res;
1187 }
1188
1189 =head2 $c->welcome_message
1190
1191 Returns the Catalyst welcome HTML page.
1192
1193 =cut
1194
1195 sub welcome_message {
1196     my $c      = shift;
1197     my $name   = $c->config->{name};
1198     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1199     my $prefix = Catalyst::Utils::appprefix( ref $c );
1200     $c->response->content_type('text/html; charset=utf-8');
1201     return <<"EOF";
1202 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1203     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1204 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1205     <head>
1206     <meta http-equiv="Content-Language" content="en" />
1207     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1208         <title>$name on Catalyst $VERSION</title>
1209         <style type="text/css">
1210             body {
1211                 color: #000;
1212                 background-color: #eee;
1213             }
1214             div#content {
1215                 width: 640px;
1216                 margin-left: auto;
1217                 margin-right: auto;
1218                 margin-top: 10px;
1219                 margin-bottom: 10px;
1220                 text-align: left;
1221                 background-color: #ccc;
1222                 border: 1px solid #aaa;
1223             }
1224             p, h1, h2 {
1225                 margin-left: 20px;
1226                 margin-right: 20px;
1227                 font-family: verdana, tahoma, sans-serif;
1228             }
1229             a {
1230                 font-family: verdana, tahoma, sans-serif;
1231             }
1232             :link, :visited {
1233                     text-decoration: none;
1234                     color: #b00;
1235                     border-bottom: 1px dotted #bbb;
1236             }
1237             :link:hover, :visited:hover {
1238                     color: #555;
1239             }
1240             div#topbar {
1241                 margin: 0px;
1242             }
1243             pre {
1244                 margin: 10px;
1245                 padding: 8px;
1246             }
1247             div#answers {
1248                 padding: 8px;
1249                 margin: 10px;
1250                 background-color: #fff;
1251                 border: 1px solid #aaa;
1252             }
1253             h1 {
1254                 font-size: 0.9em;
1255                 font-weight: normal;
1256                 text-align: center;
1257             }
1258             h2 {
1259                 font-size: 1.0em;
1260             }
1261             p {
1262                 font-size: 0.9em;
1263             }
1264             p img {
1265                 float: right;
1266                 margin-left: 10px;
1267             }
1268             span#appname {
1269                 font-weight: bold;
1270                 font-size: 1.6em;
1271             }
1272         </style>
1273     </head>
1274     <body>
1275         <div id="content">
1276             <div id="topbar">
1277                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1278                     $VERSION</h1>
1279              </div>
1280              <div id="answers">
1281                  <p>
1282                  <img src="$logo" alt="Catalyst Logo" />
1283                  </p>
1284                  <p>Welcome to the  world of Catalyst.
1285                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1286                     framework will make web development something you had
1287                     never expected it to be: Fun, rewarding, and quick.</p>
1288                  <h2>What to do now?</h2>
1289                  <p>That really depends  on what <b>you</b> want to do.
1290                     We do, however, provide you with a few starting points.</p>
1291                  <p>If you want to jump right into web development with Catalyst
1292                     you might want to start with a tutorial.</p>
1293 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1294 </pre>
1295 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1296 <pre>
1297 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1298 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1299 </code></pre>
1300                  <h2>What to do next?</h2>
1301                  <p>Next it's time to write an actual application. Use the
1302                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1303                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1304                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1305                     they can save you a lot of work.</p>
1306                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1307                     <p>Also, be sure to check out the vast and growing
1308                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1309                     you are likely to find what you need there.
1310                     </p>
1311
1312                  <h2>Need help?</h2>
1313                  <p>Catalyst has a very active community. Here are the main places to
1314                     get in touch with us.</p>
1315                  <ul>
1316                      <li>
1317                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1318                      </li>
1319                      <li>
1320                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1321                      </li>
1322                      <li>
1323                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1324                      </li>
1325                  </ul>
1326                  <h2>In conclusion</h2>
1327                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1328                     as we enjoyed making it. Please contact us if you have ideas
1329                     for improvement or other feedback.</p>
1330              </div>
1331          </div>
1332     </body>
1333 </html>
1334 EOF
1335 }
1336
1337 =head1 INTERNAL METHODS
1338
1339 These methods are not meant to be used by end users.
1340
1341 =head2 $c->components
1342
1343 Returns a hash of components.
1344
1345 =head2 $c->context_class
1346
1347 Returns or sets the context class.
1348
1349 =head2 $c->counter
1350
1351 Returns a hashref containing coderefs and execution counts (needed for
1352 deep recursion detection).
1353
1354 =head2 $c->depth
1355
1356 Returns the number of actions on the current internal execution stack.
1357
1358 =head2 $c->dispatch
1359
1360 Dispatches a request to actions.
1361
1362 =cut
1363
1364 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1365
1366 =head2 $c->dispatcher_class
1367
1368 Returns or sets the dispatcher class.
1369
1370 =head2 $c->dump_these
1371
1372 Returns a list of 2-element array references (name, structure) pairs
1373 that will be dumped on the error page in debug mode.
1374
1375 =cut
1376
1377 sub dump_these {
1378     my $c = shift;
1379     [ Request => $c->req ],
1380     [ Response => $c->res ],
1381     [ Stash => $c->stash ],
1382     [ Config => $c->config ];
1383 }
1384
1385 =head2 $c->engine_class
1386
1387 Returns or sets the engine class.
1388
1389 =head2 $c->execute( $class, $coderef )
1390
1391 Execute a coderef in given class and catch exceptions. Errors are available
1392 via $c->error.
1393
1394 =cut
1395
1396 sub execute {
1397     my ( $c, $class, $code ) = @_;
1398     $class = $c->component($class) || $class;
1399     $c->state(0);
1400
1401     if ( $c->depth >= $RECURSION ) {
1402         my $action = $code->reverse();
1403         $action = "/$action" unless $action =~ /->/;
1404         my $error = qq/Deep recursion detected calling "${action}"/;
1405         $c->log->error($error);
1406         $c->error($error);
1407         $c->state(0);
1408         return $c->state;
1409     }
1410
1411     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1412
1413     push( @{ $c->stack }, $code );
1414
1415     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1416
1417     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1418
1419     my $last = pop( @{ $c->stack } );
1420
1421     if ( my $error = $@ ) {
1422         if ( !ref($error) and $error eq $DETACH ) {
1423             die $DETACH if($c->depth > 1);
1424         }
1425         elsif ( !ref($error) and $error eq $GO ) {
1426             die $GO if($c->depth > 0);
1427         }
1428         else {
1429             unless ( ref $error ) {
1430                 no warnings 'uninitialized';
1431                 chomp $error;
1432                 my $class = $last->class;
1433                 my $name  = $last->name;
1434                 $error = qq/Caught exception in $class->$name "$error"/;
1435             }
1436             $c->error($error);
1437             $c->state(0);
1438         }
1439     }
1440     return $c->state;
1441 }
1442
1443 sub _stats_start_execute {
1444     my ( $c, $code ) = @_;
1445
1446     return if ( ( $code->name =~ /^_.*/ )
1447         && ( !$c->config->{show_internal_actions} ) );
1448
1449     my $action_name = $code->reverse();
1450     $c->counter->{$action_name}++;
1451
1452     my $action = $action_name;
1453     $action = "/$action" unless $action =~ /->/;
1454
1455     # determine if the call was the result of a forward
1456     # this is done by walking up the call stack and looking for a calling
1457     # sub of Catalyst::forward before the eval
1458     my $callsub = q{};
1459     for my $index ( 2 .. 11 ) {
1460         last
1461         if ( ( caller($index) )[0] eq 'Catalyst'
1462             && ( caller($index) )[3] eq '(eval)' );
1463
1464         if ( ( caller($index) )[3] =~ /forward$/ ) {
1465             $callsub = ( caller($index) )[3];
1466             $action  = "-> $action";
1467             last;
1468         }
1469     }
1470
1471     my $uid = $action_name . $c->counter->{$action_name};
1472
1473     # is this a root-level call or a forwarded call?
1474     if ( $callsub =~ /forward$/ ) {
1475
1476         # forward, locate the caller
1477         if ( my $parent = $c->stack->[-1] ) {
1478             $c->stats->profile(
1479                 begin  => $action,
1480                 parent => "$parent" . $c->counter->{"$parent"},
1481                 uid    => $uid,
1482             );
1483         }
1484         else {
1485
1486             # forward with no caller may come from a plugin
1487             $c->stats->profile(
1488                 begin => $action,
1489                 uid   => $uid,
1490             );
1491         }
1492     }
1493     else {
1494
1495         # root-level call
1496         $c->stats->profile(
1497             begin => $action,
1498             uid   => $uid,
1499         );
1500     }
1501     return $action;
1502
1503 }
1504
1505 sub _stats_finish_execute {
1506     my ( $c, $info ) = @_;
1507     $c->stats->profile( end => $info );
1508 }
1509
1510 =head2 $c->_localize_fields( sub { }, \%keys );
1511
1512 =cut
1513
1514 #Why does this exist? This is no longer safe and WILL NOT WORK.
1515 # it doesnt seem to be used anywhere. can we remove it?
1516 sub _localize_fields {
1517     my ( $c, $localized, $code ) = ( @_ );
1518
1519     my $request = delete $localized->{request} || {};
1520     my $response = delete $localized->{response} || {};
1521
1522     local @{ $c }{ keys %$localized } = values %$localized;
1523     local @{ $c->request }{ keys %$request } = values %$request;
1524     local @{ $c->response }{ keys %$response } = values %$response;
1525
1526     $code->();
1527 }
1528
1529 =head2 $c->finalize
1530
1531 Finalizes the request.
1532
1533 =cut
1534
1535 sub finalize {
1536     my $c = shift;
1537
1538     for my $error ( @{ $c->error } ) {
1539         $c->log->error($error);
1540     }
1541
1542     # Allow engine to handle finalize flow (for POE)
1543     my $engine = $c->engine;
1544     if ( my $code = $engine->can('finalize') ) {
1545         $engine->$code($c);
1546     }
1547     else {
1548
1549         $c->finalize_uploads;
1550
1551         # Error
1552         if ( $#{ $c->error } >= 0 ) {
1553             $c->finalize_error;
1554         }
1555
1556         $c->finalize_headers;
1557
1558         # HEAD request
1559         if ( $c->request->method eq 'HEAD' ) {
1560             $c->response->body('');
1561         }
1562
1563         $c->finalize_body;
1564     }
1565
1566     if ($c->use_stats) {
1567         my $elapsed = sprintf '%f', $c->stats->elapsed;
1568         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1569         $c->log->info(
1570             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1571     }
1572
1573     return $c->response->status;
1574 }
1575
1576 =head2 $c->finalize_body
1577
1578 Finalizes body.
1579
1580 =cut
1581
1582 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1583
1584 =head2 $c->finalize_cookies
1585
1586 Finalizes cookies.
1587
1588 =cut
1589
1590 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1591
1592 =head2 $c->finalize_error
1593
1594 Finalizes error.
1595
1596 =cut
1597
1598 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1599
1600 =head2 $c->finalize_headers
1601
1602 Finalizes headers.
1603
1604 =cut
1605
1606 sub finalize_headers {
1607     my $c = shift;
1608
1609     my $response = $c->response; #accessor calls can add up?
1610
1611     # Check if we already finalized headers
1612     return if $response->finalized_headers;
1613
1614     # Handle redirects
1615     if ( my $location = $response->redirect ) {
1616         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1617         $response->header( Location => $location );
1618
1619         if ( !$response->has_body ) {
1620             # Add a default body if none is already present
1621             $response->body(
1622                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1623             );
1624         }
1625     }
1626
1627     # Content-Length
1628     if ( $response->body && !$response->content_length ) {
1629
1630         # get the length from a filehandle
1631         if ( blessed( $response->body ) && $response->body->can('read') )
1632         {
1633             my $stat = stat $response->body;
1634             if ( $stat && $stat->size > 0 ) {
1635                 $response->content_length( $stat->size );
1636             }
1637             else {
1638                 $c->log->warn('Serving filehandle without a content-length');
1639             }
1640         }
1641         else {
1642             # everything should be bytes at this point, but just in case
1643             $response->content_length( bytes::length( $response->body ) );
1644         }
1645     }
1646
1647     # Errors
1648     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1649         $response->headers->remove_header("Content-Length");
1650         $response->body('');
1651     }
1652
1653     $c->finalize_cookies;
1654
1655     $c->engine->finalize_headers( $c, @_ );
1656
1657     # Done
1658     $response->finalized_headers(1);
1659 }
1660
1661 =head2 $c->finalize_output
1662
1663 An alias for finalize_body.
1664
1665 =head2 $c->finalize_read
1666
1667 Finalizes the input after reading is complete.
1668
1669 =cut
1670
1671 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1672
1673 =head2 $c->finalize_uploads
1674
1675 Finalizes uploads. Cleans up any temporary files.
1676
1677 =cut
1678
1679 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1680
1681 =head2 $c->get_action( $action, $namespace )
1682
1683 Gets an action in a given namespace.
1684
1685 =cut
1686
1687 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1688
1689 =head2 $c->get_actions( $action, $namespace )
1690
1691 Gets all actions of a given name in a namespace and all parent
1692 namespaces.
1693
1694 =cut
1695
1696 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1697
1698 =head2 $c->handle_request( $class, @arguments )
1699
1700 Called to handle each HTTP request.
1701
1702 =cut
1703
1704 sub handle_request {
1705     my ( $class, @arguments ) = @_;
1706
1707     # Always expect worst case!
1708     my $status = -1;
1709     eval {
1710         if ($class->debug) {
1711             my $secs = time - $START || 1;
1712             my $av = sprintf '%.3f', $COUNT / $secs;
1713             my $time = localtime time;
1714             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1715         }
1716
1717         my $c = $class->prepare(@arguments);
1718         $c->dispatch;
1719         $status = $c->finalize;
1720     };
1721
1722     if ( my $error = $@ ) {
1723         chomp $error;
1724         $class->log->error(qq/Caught exception in engine "$error"/);
1725     }
1726
1727     $COUNT++;
1728
1729     if(my $coderef = $class->log->can('_flush')){
1730         $class->log->$coderef();
1731     }
1732     return $status;
1733 }
1734
1735 =head2 $c->prepare( @arguments )
1736
1737 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1738 etc.).
1739
1740 =cut
1741
1742 sub prepare {
1743     my ( $class, @arguments ) = @_;
1744
1745     # XXX
1746     # After the app/ctxt split, this should become an attribute based on something passed
1747     # into the application.
1748     $class->context_class( ref $class || $class ) unless $class->context_class;
1749
1750     my $c = $class->context_class->new({});
1751
1752     # For on-demand data
1753     $c->request->_context($c);
1754     $c->response->_context($c);
1755
1756     #surely this is not the most efficient way to do things...
1757     $c->stats($class->stats_class->new)->enable($c->use_stats);
1758     if ( $c->debug ) {
1759         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1760     }
1761
1762     #XXX reuse coderef from can
1763     # Allow engine to direct the prepare flow (for POE)
1764     if ( $c->engine->can('prepare') ) {
1765         $c->engine->prepare( $c, @arguments );
1766     }
1767     else {
1768         $c->prepare_request(@arguments);
1769         $c->prepare_connection;
1770         $c->prepare_query_parameters;
1771         $c->prepare_headers;
1772         $c->prepare_cookies;
1773         $c->prepare_path;
1774
1775         # Prepare the body for reading, either by prepare_body
1776         # or the user, if they are using $c->read
1777         $c->prepare_read;
1778
1779         # Parse the body unless the user wants it on-demand
1780         unless ( $c->config->{parse_on_demand} ) {
1781             $c->prepare_body;
1782         }
1783     }
1784
1785     my $method  = $c->req->method  || '';
1786     my $path    = $c->req->path;
1787     $path       = '/' unless length $path;
1788     my $address = $c->req->address || '';
1789
1790     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1791       if $c->debug;
1792
1793     $c->prepare_action;
1794
1795     return $c;
1796 }
1797
1798 =head2 $c->prepare_action
1799
1800 Prepares action. See L<Catalyst::Dispatcher>.
1801
1802 =cut
1803
1804 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1805
1806 =head2 $c->prepare_body
1807
1808 Prepares message body.
1809
1810 =cut
1811
1812 sub prepare_body {
1813     my $c = shift;
1814
1815     return if $c->request->_has_body;
1816
1817     # Initialize on-demand data
1818     $c->engine->prepare_body( $c, @_ );
1819     $c->prepare_parameters;
1820     $c->prepare_uploads;
1821
1822     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1823         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1824         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1825             my $param = $c->req->body_parameters->{$key};
1826             my $value = defined($param) ? $param : '';
1827             $t->row( $key,
1828                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1829         }
1830         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1831     }
1832 }
1833
1834 =head2 $c->prepare_body_chunk( $chunk )
1835
1836 Prepares a chunk of data before sending it to L<HTTP::Body>.
1837
1838 See L<Catalyst::Engine>.
1839
1840 =cut
1841
1842 sub prepare_body_chunk {
1843     my $c = shift;
1844     $c->engine->prepare_body_chunk( $c, @_ );
1845 }
1846
1847 =head2 $c->prepare_body_parameters
1848
1849 Prepares body parameters.
1850
1851 =cut
1852
1853 sub prepare_body_parameters {
1854     my $c = shift;
1855     $c->engine->prepare_body_parameters( $c, @_ );
1856 }
1857
1858 =head2 $c->prepare_connection
1859
1860 Prepares connection.
1861
1862 =cut
1863
1864 sub prepare_connection {
1865     my $c = shift;
1866     $c->engine->prepare_connection( $c, @_ );
1867 }
1868
1869 =head2 $c->prepare_cookies
1870
1871 Prepares cookies.
1872
1873 =cut
1874
1875 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1876
1877 =head2 $c->prepare_headers
1878
1879 Prepares headers.
1880
1881 =cut
1882
1883 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1884
1885 =head2 $c->prepare_parameters
1886
1887 Prepares parameters.
1888
1889 =cut
1890
1891 sub prepare_parameters {
1892     my $c = shift;
1893     $c->prepare_body_parameters;
1894     $c->engine->prepare_parameters( $c, @_ );
1895 }
1896
1897 =head2 $c->prepare_path
1898
1899 Prepares path and base.
1900
1901 =cut
1902
1903 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1904
1905 =head2 $c->prepare_query_parameters
1906
1907 Prepares query parameters.
1908
1909 =cut
1910
1911 sub prepare_query_parameters {
1912     my $c = shift;
1913
1914     $c->engine->prepare_query_parameters( $c, @_ );
1915
1916     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1917         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1918         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1919             my $param = $c->req->query_parameters->{$key};
1920             my $value = defined($param) ? $param : '';
1921             $t->row( $key,
1922                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1923         }
1924         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1925     }
1926 }
1927
1928 =head2 $c->prepare_read
1929
1930 Prepares the input for reading.
1931
1932 =cut
1933
1934 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1935
1936 =head2 $c->prepare_request
1937
1938 Prepares the engine request.
1939
1940 =cut
1941
1942 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1943
1944 =head2 $c->prepare_uploads
1945
1946 Prepares uploads.
1947
1948 =cut
1949
1950 sub prepare_uploads {
1951     my $c = shift;
1952
1953     $c->engine->prepare_uploads( $c, @_ );
1954
1955     if ( $c->debug && keys %{ $c->request->uploads } ) {
1956         my $t = Text::SimpleTable->new(
1957             [ 12, 'Parameter' ],
1958             [ 26, 'Filename' ],
1959             [ 18, 'Type' ],
1960             [ 9,  'Size' ]
1961         );
1962         for my $key ( sort keys %{ $c->request->uploads } ) {
1963             my $upload = $c->request->uploads->{$key};
1964             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1965                 $t->row( $key, $u->filename, $u->type, $u->size );
1966             }
1967         }
1968         $c->log->debug( "File Uploads are:\n" . $t->draw );
1969     }
1970 }
1971
1972 =head2 $c->prepare_write
1973
1974 Prepares the output for writing.
1975
1976 =cut
1977
1978 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1979
1980 =head2 $c->request_class
1981
1982 Returns or sets the request class.
1983
1984 =head2 $c->response_class
1985
1986 Returns or sets the response class.
1987
1988 =head2 $c->read( [$maxlength] )
1989
1990 Reads a chunk of data from the request body. This method is designed to
1991 be used in a while loop, reading C<$maxlength> bytes on every call.
1992 C<$maxlength> defaults to the size of the request if not specified.
1993
1994 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1995 directly.
1996
1997 Warning: If you use read(), Catalyst will not process the body,
1998 so you will not be able to access POST parameters or file uploads via
1999 $c->request.  You must handle all body parsing yourself.
2000
2001 =cut
2002
2003 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2004
2005 =head2 $c->run
2006
2007 Starts the engine.
2008
2009 =cut
2010
2011 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2012
2013 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2014
2015 Sets an action in a given namespace.
2016
2017 =cut
2018
2019 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2020
2021 =head2 $c->setup_actions($component)
2022
2023 Sets up actions for a component.
2024
2025 =cut
2026
2027 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2028
2029 =head2 $c->setup_components
2030
2031 Sets up components. Specify a C<setup_components> config option to pass
2032 additional options directly to L<Module::Pluggable>. To add additional
2033 search paths, specify a key named C<search_extra> as an array
2034 reference. Items in the array beginning with C<::> will have the
2035 application class name prepended to them.
2036
2037 All components found will also have any
2038 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2039 Note, that modules which are B<not> an I<inner package> of the main
2040 file namespace loaded will not be instantiated as components.
2041
2042 =cut
2043
2044 sub setup_components {
2045     my $class = shift;
2046
2047     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2048     my $config  = $class->config->{ setup_components };
2049     my $extra   = delete $config->{ search_extra } || [];
2050
2051     push @paths, @$extra;
2052
2053     my $locator = Module::Pluggable::Object->new(
2054         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2055         %$config
2056     );
2057
2058     my @comps = sort { length $a <=> length $b } $locator->plugins;
2059     my %comps = map { $_ => 1 } @comps;
2060
2061     my $deprecated_component_names = grep { /::[CMV]::/ } @comps;
2062     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2063         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2064     ) if $deprecated_component_names;
2065
2066     for my $component ( @comps ) {
2067
2068         # We pass ignore_loaded here so that overlay files for (e.g.)
2069         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2070         # we know M::P::O found a file on disk so this is safe
2071
2072         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2073         #Class::MOP::load_class($component);
2074
2075         my $module  = $class->setup_component( $component );
2076         my %modules = (
2077             $component => $module,
2078             map {
2079                 $_ => $class->setup_component( $_ )
2080             } grep {
2081               not exists $comps{$_}
2082             } Devel::InnerPackage::list_packages( $component )
2083         );
2084
2085         for my $key ( keys %modules ) {
2086             $class->components->{ $key } = $modules{ $key };
2087         }
2088     }
2089 }
2090
2091 =head2 $c->setup_component
2092
2093 =cut
2094
2095 sub setup_component {
2096     my( $class, $component ) = @_;
2097
2098     unless ( $component->can( 'COMPONENT' ) ) {
2099         return $component;
2100     }
2101
2102     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2103     my $config = $class->config->{ $suffix } || {};
2104
2105     my $instance = eval { $component->COMPONENT( $class, $config ); };
2106
2107     if ( my $error = $@ ) {
2108         chomp $error;
2109         Catalyst::Exception->throw(
2110             message => qq/Couldn't instantiate component "$component", "$error"/
2111         );
2112     }
2113
2114     Catalyst::Exception->throw(
2115         message =>
2116         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2117     ) unless blessed($instance);
2118
2119     return $instance;
2120 }
2121
2122 =head2 $c->setup_dispatcher
2123
2124 Sets up dispatcher.
2125
2126 =cut
2127
2128 sub setup_dispatcher {
2129     my ( $class, $dispatcher ) = @_;
2130
2131     if ($dispatcher) {
2132         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2133     }
2134
2135     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2136         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2137     }
2138
2139     unless ($dispatcher) {
2140         $dispatcher = $class->dispatcher_class;
2141     }
2142
2143     Class::MOP::load_class($dispatcher);
2144
2145     # dispatcher instance
2146     $class->dispatcher( $dispatcher->new );
2147 }
2148
2149 =head2 $c->setup_engine
2150
2151 Sets up engine.
2152
2153 =cut
2154
2155 sub setup_engine {
2156     my ( $class, $engine ) = @_;
2157
2158     if ($engine) {
2159         $engine = 'Catalyst::Engine::' . $engine;
2160     }
2161
2162     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2163         $engine = 'Catalyst::Engine::' . $env;
2164     }
2165
2166     if ( $ENV{MOD_PERL} ) {
2167         my $meta = Class::MOP::get_metaclass_by_name($class);
2168
2169         # create the apache method
2170         $meta->add_method('apache' => sub { shift->engine->apache });
2171
2172         my ( $software, $version ) =
2173           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2174
2175         $version =~ s/_//g;
2176         $version =~ s/(\.[^.]+)\./$1/g;
2177
2178         if ( $software eq 'mod_perl' ) {
2179
2180             if ( !$engine ) {
2181
2182                 if ( $version >= 1.99922 ) {
2183                     $engine = 'Catalyst::Engine::Apache2::MP20';
2184                 }
2185
2186                 elsif ( $version >= 1.9901 ) {
2187                     $engine = 'Catalyst::Engine::Apache2::MP19';
2188                 }
2189
2190                 elsif ( $version >= 1.24 ) {
2191                     $engine = 'Catalyst::Engine::Apache::MP13';
2192                 }
2193
2194                 else {
2195                     Catalyst::Exception->throw( message =>
2196                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2197                 }
2198
2199             }
2200
2201             # install the correct mod_perl handler
2202             if ( $version >= 1.9901 ) {
2203                 *handler = sub  : method {
2204                     shift->handle_request(@_);
2205                 };
2206             }
2207             else {
2208                 *handler = sub ($$) { shift->handle_request(@_) };
2209             }
2210
2211         }
2212
2213         elsif ( $software eq 'Zeus-Perl' ) {
2214             $engine = 'Catalyst::Engine::Zeus';
2215         }
2216
2217         else {
2218             Catalyst::Exception->throw(
2219                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2220         }
2221     }
2222
2223     unless ($engine) {
2224         $engine = $class->engine_class;
2225     }
2226
2227     Class::MOP::load_class($engine);
2228
2229     # check for old engines that are no longer compatible
2230     my $old_engine;
2231     if ( $engine->isa('Catalyst::Engine::Apache')
2232         && !Catalyst::Engine::Apache->VERSION )
2233     {
2234         $old_engine = 1;
2235     }
2236
2237     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2238         && Catalyst::Engine::Server->VERSION le '0.02' )
2239     {
2240         $old_engine = 1;
2241     }
2242
2243     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2244         && $engine->VERSION eq '0.01' )
2245     {
2246         $old_engine = 1;
2247     }
2248
2249     elsif ($engine->isa('Catalyst::Engine::Zeus')
2250         && $engine->VERSION eq '0.01' )
2251     {
2252         $old_engine = 1;
2253     }
2254
2255     if ($old_engine) {
2256         Catalyst::Exception->throw( message =>
2257               qq/Engine "$engine" is not supported by this version of Catalyst/
2258         );
2259     }
2260
2261     # engine instance
2262     $class->engine( $engine->new );
2263 }
2264
2265 =head2 $c->setup_home
2266
2267 Sets up the home directory.
2268
2269 =cut
2270
2271 sub setup_home {
2272     my ( $class, $home ) = @_;
2273
2274     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2275         $home = $env;
2276     }
2277
2278     $home ||= Catalyst::Utils::home($class);
2279
2280     if ($home) {
2281         #I remember recently being scolded for assigning config values like this
2282         $class->config->{home} ||= $home;
2283         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2284     }
2285 }
2286
2287 =head2 $c->setup_log
2288
2289 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2290 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2291 log to.
2292
2293 This method also installs a C<debug> method that returns a true value into the
2294 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2295 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2296
2297 Note that if the log has already been setup, by either a previous call to
2298 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2299 that this method won't actually set up the log object.
2300
2301 =cut
2302
2303 sub setup_log {
2304     my ( $class, $levels ) = @_;
2305
2306     $levels ||= '';
2307     $levels =~ s/^\s+//;
2308     $levels =~ s/\s+$//;
2309     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels || '';
2310
2311     unless ( $class->log ) {
2312         $class->log( Catalyst::Log->new(keys %levels) );
2313     }
2314
2315     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2316     if ( defined($env_debug) or $levels{debug} ) {
2317         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2318         $class->log->debug('Debug messages enabled');
2319     }
2320 }
2321
2322 =head2 $c->setup_plugins
2323
2324 Sets up plugins.
2325
2326 =cut
2327
2328 =head2 $c->setup_stats
2329
2330 Sets up timing statistics class.
2331
2332 =cut
2333
2334 sub setup_stats {
2335     my ( $class, $stats ) = @_;
2336
2337     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2338
2339     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2340     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2341         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2342         $class->log->debug('Statistics enabled');
2343     }
2344 }
2345
2346
2347 =head2 $c->registered_plugins
2348
2349 Returns a sorted list of the plugins which have either been stated in the
2350 import list or which have been added via C<< MyApp->plugin(@args); >>.
2351
2352 If passed a given plugin name, it will report a boolean value indicating
2353 whether or not that plugin is loaded.  A fully qualified name is required if
2354 the plugin name does not begin with C<Catalyst::Plugin::>.
2355
2356  if ($c->registered_plugins('Some::Plugin')) {
2357      ...
2358  }
2359
2360 =cut
2361
2362 {
2363
2364     sub registered_plugins {
2365         my $proto = shift;
2366         return sort keys %{ $proto->_plugins } unless @_;
2367         my $plugin = shift;
2368         return 1 if exists $proto->_plugins->{$plugin};
2369         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2370     }
2371
2372     sub _register_plugin {
2373         my ( $proto, $plugin, $instant ) = @_;
2374         my $class = ref $proto || $proto;
2375
2376         # no ignore_loaded here, the plugin may already have been
2377         # defined in memory and we don't want to error on "no file" if so
2378
2379         Class::MOP::load_class( $plugin );
2380
2381         $proto->_plugins->{$plugin} = 1;
2382         unless ($instant) {
2383             no strict 'refs';
2384             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2385               my @superclasses = ($plugin, $meta->superclasses );
2386               $meta->superclasses(@superclasses);
2387             } else {
2388               unshift @{"$class\::ISA"}, $plugin;
2389             }
2390         }
2391         return $class;
2392     }
2393
2394     sub setup_plugins {
2395         my ( $class, $plugins ) = @_;
2396
2397         $class->_plugins( {} ) unless $class->_plugins;
2398         $plugins ||= [];
2399         for my $plugin ( reverse @$plugins ) {
2400
2401             unless ( $plugin =~ s/\A\+// ) {
2402                 $plugin = "Catalyst::Plugin::$plugin";
2403             }
2404
2405             $class->_register_plugin($plugin);
2406         }
2407     }
2408 }
2409
2410 =head2 $c->stack
2411
2412 Returns an arrayref of the internal execution stack (actions that are
2413 currently executing).
2414
2415 =head2 $c->stats_class
2416
2417 Returns or sets the stats (timing statistics) class.
2418
2419 =head2 $c->use_stats
2420
2421 Returns 1 when stats collection is enabled.  Stats collection is enabled
2422 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2423 environment variable is set.
2424
2425 Note that this is a static method, not an accessor and should be overloaded
2426 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2427
2428 =cut
2429
2430 sub use_stats { 0 }
2431
2432
2433 =head2 $c->write( $data )
2434
2435 Writes $data to the output stream. When using this method directly, you
2436 will need to manually set the C<Content-Length> header to the length of
2437 your output data, if known.
2438
2439 =cut
2440
2441 sub write {
2442     my $c = shift;
2443
2444     # Finalize headers if someone manually writes output
2445     $c->finalize_headers;
2446
2447     return $c->engine->write( $c, @_ );
2448 }
2449
2450 =head2 version
2451
2452 Returns the Catalyst version number. Mostly useful for "powered by"
2453 messages in template systems.
2454
2455 =cut
2456
2457 sub version { return $Catalyst::VERSION }
2458
2459 =head1 INTERNAL ACTIONS
2460
2461 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2462 C<_ACTION>, and C<_END>. These are by default not shown in the private
2463 action table, but you can make them visible with a config parameter.
2464
2465     MyApp->config->{show_internal_actions} = 1;
2466
2467 =head1 CASE SENSITIVITY
2468
2469 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2470 mapped to C</foo/bar>. You can activate case sensitivity with a config
2471 parameter.
2472
2473     MyApp->config->{case_sensitive} = 1;
2474
2475 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2476
2477 =head1 ON-DEMAND PARSER
2478
2479 The request body is usually parsed at the beginning of a request,
2480 but if you want to handle input yourself, you can enable on-demand
2481 parsing with a config parameter.
2482
2483     MyApp->config->{parse_on_demand} = 1;
2484
2485 =head1 PROXY SUPPORT
2486
2487 Many production servers operate using the common double-server approach,
2488 with a lightweight frontend web server passing requests to a larger
2489 backend server. An application running on the backend server must deal
2490 with two problems: the remote user always appears to be C<127.0.0.1> and
2491 the server's hostname will appear to be C<localhost> regardless of the
2492 virtual host that the user connected through.
2493
2494 Catalyst will automatically detect this situation when you are running
2495 the frontend and backend servers on the same machine. The following
2496 changes are made to the request.
2497
2498     $c->req->address is set to the user's real IP address, as read from
2499     the HTTP X-Forwarded-For header.
2500
2501     The host value for $c->req->base and $c->req->uri is set to the real
2502     host, as read from the HTTP X-Forwarded-Host header.
2503
2504 Obviously, your web server must support these headers for this to work.
2505
2506 In a more complex server farm environment where you may have your
2507 frontend proxy server(s) on different machines, you will need to set a
2508 configuration option to tell Catalyst to read the proxied data from the
2509 headers.
2510
2511     MyApp->config->{using_frontend_proxy} = 1;
2512
2513 If you do not wish to use the proxy support at all, you may set:
2514
2515     MyApp->config->{ignore_frontend_proxy} = 1;
2516
2517 =head1 THREAD SAFETY
2518
2519 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2520 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2521 believe the Catalyst core to be thread-safe.
2522
2523 If you plan to operate in a threaded environment, remember that all other
2524 modules you are using must also be thread-safe. Some modules, most notably
2525 L<DBD::SQLite>, are not thread-safe.
2526
2527 =head1 SUPPORT
2528
2529 IRC:
2530
2531     Join #catalyst on irc.perl.org.
2532
2533 Mailing Lists:
2534
2535     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2536     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2537
2538 Web:
2539
2540     http://catalyst.perl.org
2541
2542 Wiki:
2543
2544     http://dev.catalyst.perl.org
2545
2546 =head1 SEE ALSO
2547
2548 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2549
2550 =head2 L<Catalyst::Manual> - The Catalyst Manual
2551
2552 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2553
2554 =head2 L<Catalyst::Engine> - Core engine
2555
2556 =head2 L<Catalyst::Log> - Log class.
2557
2558 =head2 L<Catalyst::Request> - Request object
2559
2560 =head2 L<Catalyst::Response> - Response object
2561
2562 =head2 L<Catalyst::Test> - The test suite.
2563
2564 =head1 PROJECT FOUNDER
2565
2566 sri: Sebastian Riedel <sri@cpan.org>
2567
2568 =head1 CONTRIBUTORS
2569
2570 abw: Andy Wardley
2571
2572 acme: Leon Brocard <leon@astray.com>
2573
2574 Andrew Bramble
2575
2576 Andrew Ford
2577
2578 Andrew Ruthven
2579
2580 andyg: Andy Grundman <andy@hybridized.org>
2581
2582 audreyt: Audrey Tang
2583
2584 bricas: Brian Cassidy <bricas@cpan.org>
2585
2586 Caelum: Rafael Kitover <rkitover@io.com>
2587
2588 chansen: Christian Hansen
2589
2590 chicks: Christopher Hicks
2591
2592 David E. Wheeler
2593
2594 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2595
2596 Drew Taylor
2597
2598 esskar: Sascha Kiefer
2599
2600 fireartist: Carl Franks <cfranks@cpan.org>
2601
2602 gabb: Danijel Milicevic
2603
2604 Gary Ashton Jones
2605
2606 Geoff Richards
2607
2608 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2609
2610 jcamacho: Juan Camacho
2611
2612 jhannah: Jay Hannah <jay@jays.net>
2613
2614 Jody Belka
2615
2616 Johan Lindstrom
2617
2618 jon: Jon Schutz <jjschutz@cpan.org>
2619
2620 marcus: Marcus Ramberg <mramberg@cpan.org>
2621
2622 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2623
2624 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2625
2626 mugwump: Sam Vilain
2627
2628 naughton: David Naughton
2629
2630 ningu: David Kamholz <dkamholz@cpan.org>
2631
2632 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2633
2634 numa: Dan Sully <daniel@cpan.org>
2635
2636 obra: Jesse Vincent
2637
2638 omega: Andreas Marienborg
2639
2640 Oleg Kostyuk <cub.uanic@gmail.com>
2641
2642 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2643
2644 rafl: Florian Ragwitz <rafl@debian.org>
2645
2646 sky: Arthur Bergman
2647
2648 the_jester: Jesse Sheidlower
2649
2650 t0m: Tomas Doran <bobtfish@bobtfish.net>
2651
2652 Ulf Edvinsson
2653
2654 willert: Sebastian Willert <willert@cpan.org>
2655
2656 =head1 LICENSE
2657
2658 This library is free software, you can redistribute it and/or modify it under
2659 the same terms as Perl itself.
2660
2661 =cut
2662
2663 no Moose;
2664
2665 __PACKAGE__->meta->make_immutable;
2666
2667 1;