lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use bytes;
   6 use Scope::Upper ();
   7 use Catalyst::Exception;
   8 use Catalyst::Log;
   9 use Catalyst::Request;
  10 use Catalyst::Request::Upload;
  11 use Catalyst::Response;
  12 use Catalyst::Utils;
  13 use Catalyst::Controller;
  14 use Devel::InnerPackage ();
  15 use File::stat;
  16 use Module::Pluggable::Object ();
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use URI ();
  21 use URI::http;
  22 use URI::https;
  23 use Tree::Simple qw/use_weak_refs/;
  24 use Tree::Simple::Visitor::FindByUID;
  25 use Class::C3::Adopt::NEXT;
  26 use attributes;
  27 use utf8;
  28 use Carp qw/croak carp shortmess/;
  29
  30 BEGIN { require 5.008001; }
  31
  32 has stack => (is => 'ro', default => sub { [] });
  33 has stash => (is => 'rw', default => sub { {} });
  34 has state => (is => 'rw', default => 0);
  35 has stats => (is => 'rw');
  36 has action => (is => 'rw');
  37 has counter => (is => 'rw', default => sub { {} });
  38 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  39 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  40 has namespace => (is => 'rw');
  41
  42 sub depth { scalar @{ shift->stack || [] }; }
  43 sub comp { shift->component(@_) }
  44
  45 sub req {
  46     # carp "the use of req() is deprecated in favour of request()";
  47     my $self = shift; return $self->request(@_);
  48 }
  49 sub res {
  50     # carp "the use of res() is deprecated in favour of response()";
  51     my $self = shift; return $self->response(@_);
  52 }
  53
  54 # For backwards compatibility
  55 sub finalize_output { shift->finalize_body(@_) };
  56
  57 # For statistics
  58 our $COUNT     = 1;
  59 our $START     = time;
  60 our $RECURSION = 1000;
  61 our $DETACH    = "catalyst_detach\n";
  62 our $GO        = "catalyst_go\n";
  63
  64 #I imagine that very few of these really need to be class variables. if any.
  65 #maybe we should just make them attributes with a default?
  66 __PACKAGE__->mk_classdata($_)
  67   for qw/components arguments dispatcher engine log dispatcher_class
  68   engine_class context_class request_class response_class stats_class
  69   setup_finished/;
  70
  71 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  72 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  73 __PACKAGE__->request_class('Catalyst::Request');
  74 __PACKAGE__->response_class('Catalyst::Response');
  75 __PACKAGE__->stats_class('Catalyst::Stats');
  76
  77 # Remember to update this in Catalyst::Runtime as well!
  78
  79 our $VERSION = '5.8000_06';
  80
  81 {
  82     my $dev_version = $VERSION =~ /_\d{2}$/;
  83     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  84 }
  85
  86 $VERSION = eval $VERSION;
  87
  88 sub import {
  89     my ( $class, @arguments ) = @_;
  90
  91     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  92     # callers @ISA.
  93     return unless $class eq 'Catalyst';
  94
  95     my $caller = caller();
  96     return if $caller eq 'main';
  97
  98     # Kill Adopt::NEXT warnings if we're a non-RC version
  99     unless (_IS_DEVELOPMENT_VERSION()) {
 100         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 101     }
 102
 103     my $meta = Moose::Meta::Class->initialize($caller);
 104     #Moose->import({ into => $caller }); #do we want to do this?
 105
 106     unless ( $caller->isa('Catalyst') ) {
 107         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 108         $meta->superclasses(@superclasses);
 109     }
 110     unless( $meta->has_method('meta') ){
 111         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 112     }
 113
 114     $caller->arguments( [@arguments] );
 115     $caller->setup_home;
 116 }
 117
 118 =head1 NAME
 119
 120 Catalyst - The Elegant MVC Web Application Framework
 121
 122 =head1 SYNOPSIS
 123
 124 See the L<Catalyst::Manual> distribution for comprehensive
 125 documentation and tutorials.
 126
 127     # Install Catalyst::Devel for helpers and other development tools
 128     # use the helper to create a new application
 129     catalyst.pl MyApp
 130
 131     # add models, views, controllers
 132     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 133     script/myapp_create.pl view MyTemplate TT
 134     script/myapp_create.pl controller Search
 135
 136     # built in testserver -- use -r to restart automatically on changes
 137     # --help to see all available options
 138     script/myapp_server.pl
 139
 140     # command line testing interface
 141     script/myapp_test.pl /yada
 142
 143     ### in lib/MyApp.pm
 144     use Catalyst qw/-Debug/; # include plugins here as well
 145
 146     ### In lib/MyApp/Controller/Root.pm (autocreated)
 147     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 148         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 149         $c->stash->{template} = 'foo.tt'; # set the template
 150         # lookup something from db -- stash vars are passed to TT
 151         $c->stash->{data} =
 152           $c->model('Database::Foo')->search( { country => $args[0] } );
 153         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 154             $c->forward( 'bar' ); # process another action
 155             # do something else after forward returns
 156         }
 157     }
 158
 159     # The foo.tt TT template can use the stash data from the database
 160     [% WHILE (item = data.next) %]
 161         [% item.foo %]
 162     [% END %]
 163
 164     # called for /bar/of/soap, /bar/of/soap/10, etc.
 165     sub bar : Path('/bar/of/soap') { ... }
 166
 167     # called for all actions, from the top-most controller downwards
 168     sub auto : Private {
 169         my ( $self, $c ) = @_;
 170         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 171             $c->res->redirect( '/login' ); # require login
 172             return 0; # abort request and go immediately to end()
 173         }
 174         return 1; # success; carry on to next action
 175     }
 176
 177     # called after all actions are finished
 178     sub end : Private {
 179         my ( $self, $c ) = @_;
 180         if ( scalar @{ $c->error } ) { ... } # handle errors
 181         return if $c->res->body; # already have a response
 182         $c->forward( 'MyApp::View::TT' ); # render template
 183     }
 184
 185     ### in MyApp/Controller/Foo.pm
 186     # called for /foo/bar
 187     sub bar : Local { ... }
 188
 189     # called for /blargle
 190     sub blargle : Global { ... }
 191
 192     # an index action matches /foo, but not /foo/1, etc.
 193     sub index : Private { ... }
 194
 195     ### in MyApp/Controller/Foo/Bar.pm
 196     # called for /foo/bar/baz
 197     sub baz : Local { ... }
 198
 199     # first Root auto is called, then Foo auto, then this
 200     sub auto : Private { ... }
 201
 202     # powerful regular expression paths are also possible
 203     sub details : Regex('^product/(\w+)/details$') {
 204         my ( $self, $c ) = @_;
 205         # extract the (\w+) from the URI
 206         my $product = $c->req->captures->[0];
 207     }
 208
 209 See L<Catalyst::Manual::Intro> for additional information.
 210
 211 =head1 DESCRIPTION
 212
 213 Catalyst is a modern framework for making web applications without the
 214 pain usually associated with this process. This document is a reference
 215 to the main Catalyst application. If you are a new user, we suggest you
 216 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 217
 218 See L<Catalyst::Manual> for more documentation.
 219
 220 Catalyst plugins can be loaded by naming them as arguments to the "use
 221 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 222 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 223 C<My::Module>.
 224
 225     use Catalyst qw/My::Module/;
 226
 227 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 228 fully qualify the name by using a unary plus:
 229
 230     use Catalyst qw/
 231         My::Module
 232         +Fully::Qualified::Plugin::Name
 233     /;
 234
 235 Special flags like C<-Debug> and C<-Engine> can also be specified as
 236 arguments when Catalyst is loaded:
 237
 238     use Catalyst qw/-Debug My::Module/;
 239
 240 The position of plugins and flags in the chain is important, because
 241 they are loaded in the order in which they appear.
 242
 243 The following flags are supported:
 244
 245 =head2 -Debug
 246
 247 Enables debug output. You can also force this setting from the system
 248 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 249 settings override the application, with <MYAPP>_DEBUG having the highest
 250 priority.
 251
 252 =head2 -Engine
 253
 254 Forces Catalyst to use a specific engine. Omit the
 255 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 256
 257     use Catalyst qw/-Engine=CGI/;
 258
 259 =head2 -Home
 260
 261 Forces Catalyst to use a specific home directory, e.g.:
 262
 263     use Catalyst qw[-Home=/usr/mst];
 264
 265 This can also be done in the shell environment by setting either the
 266 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 267 is replaced with the uppercased name of your application, any "::" in
 268 the name will be replaced with underscores, e.g. MyApp::Web should use
 269 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 270
 271 =head2 -Log
 272
 273     use Catalyst '-Log=warn,fatal,error';
 274
 275 Specifies a comma-delimited list of log levels.
 276
 277 =head2 -Stats
 278
 279 Enables statistics collection and reporting. You can also force this setting
 280 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 281 environment settings override the application, with <MYAPP>_STATS having the
 282 highest priority.
 283
 284 e.g.
 285
 286    use Catalyst qw/-Stats=1/
 287
 288 =head1 METHODS
 289
 290 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 291
 292 =head2 $c->action
 293
 294 Returns a L<Catalyst::Action> object for the current action, which
 295 stringifies to the action name. See L<Catalyst::Action>.
 296
 297 =head2 $c->namespace
 298
 299 Returns the namespace of the current action, i.e., the URI prefix
 300 corresponding to the controller of the current action. For example:
 301
 302     # in Controller::Foo::Bar
 303     $c->namespace; # returns 'foo/bar';
 304
 305 =head2 $c->request
 306
 307 =head2 $c->req
 308
 309 Returns the current L<Catalyst::Request> object, giving access to
 310 information about the current client request (including parameters,
 311 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 312
 313 =head2 REQUEST FLOW HANDLING
 314
 315 =head2 $c->forward( $action [, \@arguments ] )
 316
 317 =head2 $c->forward( $class, $method, [, \@arguments ] )
 318
 319 Forwards processing to another action, by its private name. If you give a
 320 class name but no method, C<process()> is called. You may also optionally
 321 pass arguments in an arrayref. The action will receive the arguments in
 322 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 323 C<< $c->req->args >> will be restored to the previous values.
 324
 325 Any data C<return>ed from the action forwarded to, will be returned by the
 326 call to forward.
 327
 328     my $foodata = $c->forward('/foo');
 329     $c->forward('index');
 330     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 331     $c->forward('MyApp::View::TT');
 332
 333 Note that forward implies an C<<eval { }>> around the call (actually
 334 C<execute> does), thus de-fatalizing all 'dies' within the called
 335 action. If you want C<die> to propagate you need to do something like:
 336
 337     $c->forward('foo');
 338     die $c->error if $c->error;
 339
 340 Or make sure to always return true values from your actions and write
 341 your code like this:
 342
 343     $c->forward('foo') || return;
 344
 345 =cut
 346
 347 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 348
 349 =head2 $c->detach( $action [, \@arguments ] )
 350
 351 =head2 $c->detach( $class, $method, [, \@arguments ] )
 352
 353 =head2 $c->detach()
 354
 355 The same as C<forward>, but doesn't return to the previous action when
 356 processing is finished.
 357
 358 When called with no arguments it escapes the processing chain entirely.
 359
 360 =cut
 361
 362 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 363
 364 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 365
 366 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 367
 368 Almost the same as C<forward>, but does a full dispatch, instead of just
 369 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 370 C<auto> and the method you go to are called, just like a new request.
 371
 372 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 373 This means, for example, that $c->action methods such as C<name>, C<class> and
 374 C<reverse> return information for the visited action when they are invoked
 375 within the visited action.  This is different from the behavior of C<forward>
 376 which continues to use the $c->action object from the caller action even when
 377 invoked from the callee.
 378
 379 C<$c-E<gt>stash> is kept unchanged.
 380
 381 In effect, C<visit> allows you to "wrap" another action, just as it
 382 would have been called by dispatching from a URL, while the analogous
 383 C<go> allows you to transfer control to another action as if it had
 384 been reached directly from a URL.
 385
 386 =cut
 387
 388 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 389
 390 =head2 $c->go( $action [, \@captures, \@arguments ] )
 391
 392 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 393
 394 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 395 instead of just calling the new C<$action> /
 396 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 397 method you visit are called, just like a new request.
 398
 399 C<$c-E<gt>stash> is kept unchanged.
 400
 401 =cut
 402
 403 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 404
 405 =head2 $c->response
 406
 407 =head2 $c->res
 408
 409 Returns the current L<Catalyst::Response> object, see there for details.
 410
 411 =head2 $c->stash
 412
 413 Returns a hashref to the stash, which may be used to store data and pass
 414 it between components during a request. You can also set hash keys by
 415 passing arguments. The stash is automatically sent to the view. The
 416 stash is cleared at the end of a request; it cannot be used for
 417 persistent storage (for this you must use a session; see
 418 L<Catalyst::Plugin::Session> for a complete system integrated with
 419 Catalyst).
 420
 421     $c->stash->{foo} = $bar;
 422     $c->stash( { moose => 'majestic', qux => 0 } );
 423     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 424
 425     # stash is automatically passed to the view for use in a template
 426     $c->forward( 'MyApp::View::TT' );
 427
 428 =cut
 429
 430 around stash => sub {
 431     my $orig = shift;
 432     my $c = shift;
 433     my $stash = $orig->($c);
 434     if (@_) {
 435         my $new_stash = @_ > 1 ? {@_} : $_[0];
 436         croak('stash takes a hash or hashref') unless ref $new_stash;
 437         foreach my $key ( keys %$new_stash ) {
 438           $stash->{$key} = $new_stash->{$key};
 439         }
 440     }
 441
 442     return $stash;
 443 };
 444
 445
 446 =head2 $c->error
 447
 448 =head2 $c->error($error, ...)
 449
 450 =head2 $c->error($arrayref)
 451
 452 Returns an arrayref containing error messages.  If Catalyst encounters an
 453 error while processing a request, it stores the error in $c->error.  This
 454 method should only be used to store fatal error messages.
 455
 456     my @error = @{ $c->error };
 457
 458 Add a new error.
 459
 460     $c->error('Something bad happened');
 461
 462 =cut
 463
 464 sub error {
 465     my $c = shift;
 466     if ( $_[0] ) {
 467         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 468         croak @$error unless ref $c;
 469         push @{ $c->{error} }, @$error;
 470     }
 471     elsif ( defined $_[0] ) { $c->{error} = undef }
 472     return $c->{error} || [];
 473 }
 474
 475
 476 =head2 $c->state
 477
 478 Contains the return value of the last executed action.
 479
 480 =head2 $c->clear_errors
 481
 482 Clear errors.  You probably don't want to clear the errors unless you are
 483 implementing a custom error screen.
 484
 485 This is equivalent to running
 486
 487     $c->error(0);
 488
 489 =cut
 490
 491 sub clear_errors {
 492     my $c = shift;
 493     $c->error(0);
 494 }
 495
 496 # search components given a name and some prefixes
 497 sub _comp_search_prefixes {
 498     my ( $c, $name, @prefixes ) = @_;
 499     my $appclass = ref $c || $c;
 500     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 501     $filter = qr/$filter/; # Compile regex now rather than once per loop
 502
 503     # map the original component name to the sub part that we will search against
 504     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 505         grep { /$filter/ } keys %{ $c->components };
 506
 507     # undef for a name will return all
 508     return keys %eligible if !defined $name;
 509
 510     my $query  = ref $name ? $name : qr/^$name$/i;
 511     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 512
 513     return map { $c->components->{ $_ } } @result if @result;
 514
 515     # if we were given a regexp to search against, we're done.
 516     return if ref $name;
 517
 518     # regexp fallback
 519     $query  = qr/$name/i;
 520     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 521
 522     # no results? try against full names
 523     if( !@result ) {
 524         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 525     }
 526
 527     # don't warn if we didn't find any results, it just might not exist
 528     if( @result ) {
 529         # Disgusting hack to work out correct method name
 530         my $warn_for = lc $prefixes[0];
 531         my $msg = "Used regexp fallback for \$c->{$warn_for}('${name}'), which found '" .
 532            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 533            "component resolution is unreliable and unsafe.";
 534         my $short = $result[0];
 535         $short =~ s/.*?Model:://;
 536         my $shortmess = Carp::shortmess('');
 537         if ($shortmess =~ m#Catalyst/Plugin#) {
 538            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 539               "plugin's config";
 540         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 541            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 542               "component's config";
 543         } else {
 544            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 545               "but if you really wanted to search, pass in a regexp as the argument " .
 546               "like so: \$c->${warn_for}(qr/${name}/)";
 547         }
 548         $c->log->warn( "${msg}$shortmess" );
 549     }
 550
 551     return @result;
 552 }
 553
 554 # Find possible names for a prefix
 555 sub _comp_names {
 556     my ( $c, @prefixes ) = @_;
 557     my $appclass = ref $c || $c;
 558
 559     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 560
 561     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 562     return @names;
 563 }
 564
 565 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 566 sub _filter_component {
 567     my ( $c, $comp, @args ) = @_;
 568
 569     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 570         return $comp->ACCEPT_CONTEXT( $c, @args );
 571     }
 572
 573     return $comp;
 574 }
 575
 576 =head2 COMPONENT ACCESSORS
 577
 578 =head2 $c->controller($name)
 579
 580 Gets a L<Catalyst::Controller> instance by name.
 581
 582     $c->controller('Foo')->do_stuff;
 583
 584 If the name is omitted, will return the controller for the dispatched
 585 action.
 586
 587 If you want to search for controllers, pass in a regexp as the argument.
 588
 589     # find all controllers that start with Foo
 590     my @foo_controllers = $c->controller(qr{^Foo});
 591
 592
 593 =cut
 594
 595 sub controller {
 596     my ( $c, $name, @args ) = @_;
 597
 598     if( $name ) {
 599         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 600         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 601         return $c->_filter_component( $result[ 0 ], @args );
 602     }
 603
 604     return $c->component( $c->action->class );
 605 }
 606
 607 =head2 $c->model($name)
 608
 609 Gets a L<Catalyst::Model> instance by name.
 610
 611     $c->model('Foo')->do_stuff;
 612
 613 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 614
 615 If the name is omitted, it will look for
 616  - a model object in $c->stash->{current_model_instance}, then
 617  - a model name in $c->stash->{current_model}, then
 618  - a config setting 'default_model', or
 619  - check if there is only one model, and return it if that's the case.
 620
 621 If you want to search for models, pass in a regexp as the argument.
 622
 623     # find all models that start with Foo
 624     my @foo_models = $c->model(qr{^Foo});
 625
 626 =cut
 627
 628 sub model {
 629     my ( $c, $name, @args ) = @_;
 630
 631     if( $name ) {
 632         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 633         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 634         return $c->_filter_component( $result[ 0 ], @args );
 635     }
 636
 637     if (ref $c) {
 638         return $c->stash->{current_model_instance}
 639           if $c->stash->{current_model_instance};
 640         return $c->model( $c->stash->{current_model} )
 641           if $c->stash->{current_model};
 642     }
 643     return $c->model( $c->config->{default_model} )
 644       if $c->config->{default_model};
 645
 646     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 647
 648     if( $rest ) {
 649         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 650         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 651         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 652         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 653         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 654     }
 655
 656     return $c->_filter_component( $comp );
 657 }
 658
 659
 660 =head2 $c->view($name)
 661
 662 Gets a L<Catalyst::View> instance by name.
 663
 664     $c->view('Foo')->do_stuff;
 665
 666 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 667
 668 If the name is omitted, it will look for
 669  - a view object in $c->stash->{current_view_instance}, then
 670  - a view name in $c->stash->{current_view}, then
 671  - a config setting 'default_view', or
 672  - check if there is only one view, and return it if that's the case.
 673
 674 If you want to search for views, pass in a regexp as the argument.
 675
 676     # find all views that start with Foo
 677     my @foo_views = $c->view(qr{^Foo});
 678
 679 =cut
 680
 681 sub view {
 682     my ( $c, $name, @args ) = @_;
 683
 684     if( $name ) {
 685         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 686         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 687         return $c->_filter_component( $result[ 0 ], @args );
 688     }
 689
 690     if (ref $c) {
 691         return $c->stash->{current_view_instance}
 692           if $c->stash->{current_view_instance};
 693         return $c->view( $c->stash->{current_view} )
 694           if $c->stash->{current_view};
 695     }
 696     return $c->view( $c->config->{default_view} )
 697       if $c->config->{default_view};
 698
 699     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 700
 701     if( $rest ) {
 702         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 703         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 704         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 705         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 706         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 707     }
 708
 709     return $c->_filter_component( $comp );
 710 }
 711
 712 =head2 $c->controllers
 713
 714 Returns the available names which can be passed to $c->controller
 715
 716 =cut
 717
 718 sub controllers {
 719     my ( $c ) = @_;
 720     return $c->_comp_names(qw/Controller C/);
 721 }
 722
 723 =head2 $c->models
 724
 725 Returns the available names which can be passed to $c->model
 726
 727 =cut
 728
 729 sub models {
 730     my ( $c ) = @_;
 731     return $c->_comp_names(qw/Model M/);
 732 }
 733
 734
 735 =head2 $c->views
 736
 737 Returns the available names which can be passed to $c->view
 738
 739 =cut
 740
 741 sub views {
 742     my ( $c ) = @_;
 743     return $c->_comp_names(qw/View V/);
 744 }
 745
 746 =head2 $c->comp($name)
 747
 748 =head2 $c->component($name)
 749
 750 Gets a component object by name. This method is not recommended,
 751 unless you want to get a specific component by full
 752 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 753 should be used instead.
 754
 755 If C<$name> is a regexp, a list of components matched against the full
 756 component name will be returned.
 757
 758 =cut
 759
 760 sub component {
 761     my ( $c, $name, @args ) = @_;
 762
 763     if( $name ) {
 764         my $comps = $c->components;
 765
 766         if( !ref $name ) {
 767             # is it the exact name?
 768             return $c->_filter_component( $comps->{ $name }, @args )
 769                        if exists $comps->{ $name };
 770
 771             # perhaps we just omitted "MyApp"?
 772             my $composed = ( ref $c || $c ) . "::${name}";
 773             return $c->_filter_component( $comps->{ $composed }, @args )
 774                        if exists $comps->{ $composed };
 775
 776             # search all of the models, views and controllers
 777             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 778             return $c->_filter_component( $comp, @args ) if $comp;
 779         }
 780
 781         # This is here so $c->comp( '::M::' ) works
 782         my $query = ref $name ? $name : qr{$name}i;
 783
 784         my @result = grep { m{$query} } keys %{ $c->components };
 785         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 786
 787         if( $result[ 0 ] ) {
 788             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 789             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 790             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 791             return $c->_filter_component( $result[ 0 ], @args );
 792         }
 793
 794         # I would expect to return an empty list here, but that breaks back-compat
 795     }
 796
 797     # fallback
 798     return sort keys %{ $c->components };
 799 }
 800
 801 =head2 CLASS DATA AND HELPER CLASSES
 802
 803 =head2 $c->config
 804
 805 Returns or takes a hashref containing the application's configuration.
 806
 807     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 808
 809 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 810 like myapp.conf in your applications home directory. See
 811 L<Catalyst::Plugin::ConfigLoader>.
 812
 813 =head3 Cascading configuration.
 814
 815 The config method is present on all Catalyst components, and configuration
 816 will be merged when an application is started. Configuration loaded with
 817 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 818 followed by configuration in your top level C<MyApp> class. These two
 819 configurations are merged, and then configuration data whos hash key matches a
 820 component name is merged with configuration for that component.
 821
 822 The configuration for a component is then passed to the C<new> method when a
 823 component is constructed.
 824
 825 For example:
 826
 827     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 828     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 829
 830 will mean that C<MyApp::Model::Foo> receives the following data when
 831 constructed:
 832
 833     MyApp::Model::Foo->new({
 834         bar => 'baz',
 835         quux => 'frob',
 836         overrides => 'me',
 837     });
 838
 839 =cut
 840
 841 around config => sub {
 842     my $orig = shift;
 843     my $c = shift;
 844
 845     croak('Setting config after setup has been run is not allowed.')
 846         if ( @_ and $c->setup_finished );
 847
 848     $c->$orig(@_);
 849 };
 850
 851 =head2 $c->log
 852
 853 Returns the logging object instance. Unless it is already set, Catalyst
 854 sets this up with a L<Catalyst::Log> object. To use your own log class,
 855 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 856 C<< __PACKAGE__->setup >>.
 857
 858  __PACKAGE__->log( MyLogger->new );
 859  __PACKAGE__->setup;
 860
 861 And later:
 862
 863     $c->log->info( 'Now logging with my own logger!' );
 864
 865 Your log class should implement the methods described in
 866 L<Catalyst::Log>.
 867
 868
 869 =head2 $c->debug
 870
 871 Returns 1 if debug mode is enabled, 0 otherwise.
 872
 873 You can enable debug mode in several ways:
 874
 875 =over
 876
 877 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 878
 879 =item The -Debug option in your MyApp.pm
 880
 881 =item By declaring "sub debug { 1 }" in your MyApp.pm.
 882
 883 =back
 884
 885 Calling $c->debug(1) has no effect.
 886
 887 =cut
 888
 889 sub debug { 0 }
 890
 891 =head2 $c->dispatcher
 892
 893 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 894
 895 =head2 $c->engine
 896
 897 Returns the engine instance. See L<Catalyst::Engine>.
 898
 899
 900 =head2 UTILITY METHODS
 901
 902 =head2 $c->path_to(@path)
 903
 904 Merges C<@path> with C<< $c->config->{home} >> and returns a
 905 L<Path::Class::Dir> object.
 906
 907 For example:
 908
 909     $c->path_to( 'db', 'sqlite.db' );
 910
 911 =cut
 912
 913 sub path_to {
 914     my ( $c, @path ) = @_;
 915     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 916     if ( -d $path ) { return $path }
 917     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 918 }
 919
 920 =head2 $c->plugin( $name, $class, @args )
 921
 922 Helper method for plugins. It creates a class data accessor/mutator and
 923 loads and instantiates the given class.
 924
 925     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 926
 927     $c->prototype->define_javascript_functions;
 928
 929 B<Note:> This method of adding plugins is deprecated. The ability
 930 to add plugins like this B<will be removed> in a Catalyst 5.81.
 931 Please do not use this functionality in new code.
 932
 933 =cut
 934
 935 sub plugin {
 936     my ( $class, $name, $plugin, @args ) = @_;
 937
 938     # See block comment in t/unit_core_plugin.t
 939     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 940
 941     $class->_register_plugin( $plugin, 1 );
 942
 943     eval { $plugin->import };
 944     $class->mk_classdata($name);
 945     my $obj;
 946     eval { $obj = $plugin->new(@args) };
 947
 948     if ($@) {
 949         Catalyst::Exception->throw( message =>
 950               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 951     }
 952
 953     $class->$name($obj);
 954     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 955       if $class->debug;
 956 }
 957
 958 =head2 MyApp->setup
 959
 960 Initializes the dispatcher and engine, loads any plugins, and loads the
 961 model, view, and controller components. You may also specify an array
 962 of plugins to load here, if you choose to not load them in the C<use
 963 Catalyst> line.
 964
 965     MyApp->setup;
 966     MyApp->setup( qw/-Debug/ );
 967
 968 =cut
 969
 970 sub setup {
 971     my ( $class, @arguments ) = @_;
 972     croak('Running setup more than once')
 973         if ( $class->setup_finished );
 974
 975     unless ( $class->isa('Catalyst') ) {
 976
 977         Catalyst::Exception->throw(
 978             message => qq/'$class' does not inherit from Catalyst/ );
 979     }
 980
 981     if ( $class->arguments ) {
 982         @arguments = ( @arguments, @{ $class->arguments } );
 983     }
 984
 985     # Process options
 986     my $flags = {};
 987
 988     foreach (@arguments) {
 989
 990         if (/^-Debug$/) {
 991             $flags->{log} =
 992               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 993         }
 994         elsif (/^-(\w+)=?(.*)$/) {
 995             $flags->{ lc $1 } = $2;
 996         }
 997         else {
 998             push @{ $flags->{plugins} }, $_;
 999         }
1000     }
1001
1002     $class->setup_home( delete $flags->{home} );
1003
1004     $class->setup_log( delete $flags->{log} );
1005     $class->setup_plugins( delete $flags->{plugins} );
1006     $class->setup_dispatcher( delete $flags->{dispatcher} );
1007     $class->setup_engine( delete $flags->{engine} );
1008     $class->setup_stats( delete $flags->{stats} );
1009
1010     for my $flag ( sort keys %{$flags} ) {
1011
1012         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1013             &$code( $class, delete $flags->{$flag} );
1014         }
1015         else {
1016             $class->log->warn(qq/Unknown flag "$flag"/);
1017         }
1018     }
1019
1020     eval { require Catalyst::Devel; };
1021     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1022         $class->log->warn(<<"EOF");
1023 You are running an old script!
1024
1025   Please update by running (this will overwrite existing files):
1026     catalyst.pl -force -scripts $class
1027
1028   or (this will not overwrite existing files):
1029     catalyst.pl -scripts $class
1030
1031 EOF
1032     }
1033
1034     if ( $class->debug ) {
1035         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1036
1037         if (@plugins) {
1038             my $column_width = Catalyst::Utils::term_width() - 6;
1039             my $t = Text::SimpleTable->new($column_width);
1040             $t->row($_) for @plugins;
1041             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1042         }
1043
1044         my $dispatcher = $class->dispatcher;
1045         my $engine     = $class->engine;
1046         my $home       = $class->config->{home};
1047
1048         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1049         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1050
1051         $home
1052           ? ( -d $home )
1053           ? $class->log->debug(qq/Found home "$home"/)
1054           : $class->log->debug(qq/Home "$home" doesn't exist/)
1055           : $class->log->debug(q/Couldn't find home/);
1056     }
1057
1058     # Call plugins setup, this is stupid and evil.
1059     {
1060         no warnings qw/redefine/;
1061         local *setup = sub { };
1062         $class->setup;
1063     }
1064
1065     # Initialize our data structure
1066     $class->components( {} );
1067
1068     $class->setup_components;
1069
1070     if ( $class->debug ) {
1071         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1072         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1073         for my $comp ( sort keys %{ $class->components } ) {
1074             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1075             $t->row( $comp, $type );
1076         }
1077         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1078           if ( keys %{ $class->components } );
1079     }
1080
1081     # Add our self to components, since we are also a component
1082     if( $class->isa('Catalyst::Controller') ){
1083       $class->components->{$class} = $class;
1084     }
1085
1086     $class->setup_actions;
1087
1088     if ( $class->debug ) {
1089         my $name = $class->config->{name} || 'Application';
1090         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1091     }
1092     $class->log->_flush() if $class->log->can('_flush');
1093
1094     # Make sure that the application class becomes immutable at this point,
1095     # which ensures that it gets an inlined constructor. This means that it
1096     # works even if the user has added a plugin which contains a new method.
1097     # Note however that we have to do the work on scope end, so that method
1098     # modifiers work correctly in MyApp (as you have to call setup _before_
1099     # applying modifiers).
1100     Scope::Upper::reap(sub {
1101         my $meta = Class::MOP::get_metaclass_by_name($class);
1102         $meta->make_immutable unless $meta->is_immutable;
1103     }, Scope::Upper::SCOPE(1));
1104
1105     $class->setup_finalize;
1106 }
1107
1108
1109 =head2 $app->setup_finalize
1110
1111 A hook to attach modifiers to.
1112 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1113 Also better than C< setup_finished(); >, as that is a getter method.
1114
1115     sub setup_finalize {
1116
1117         my $app = shift;
1118
1119         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1120
1121         $app->next::method(@_);
1122
1123
1124     }
1125
1126 =cut
1127
1128 sub setup_finalize {
1129     my ($class) = @_;
1130     $class->setup_finished(1);
1131 }
1132
1133 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1134
1135 =head2 $c->uri_for( $path, @args?, \%query_values? )
1136
1137 =over
1138
1139 =item $action
1140
1141 A Catalyst::Action object representing the Catalyst action you want to
1142 create a URI for. To get one for an action in the current controller,
1143 use C<< $c->action('someactionname') >>. To get one from different
1144 controller, fetch the controller using C<< $c->controller() >>, then
1145 call C<action_for> on it.
1146
1147 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1148 using C<< $c->req->captures >>.
1149
1150   # For the current action
1151   $c->uri_for($c->action, $c->req->captures);
1152
1153   # For the Foo action in the Bar controller
1154   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1155
1156 =back
1157
1158 =cut
1159
1160 sub uri_for {
1161     my ( $c, $path, @args ) = @_;
1162
1163     if ( blessed($path) ) { # action object
1164         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1165                          ? shift(@args)
1166                          : [] );
1167         my $action = $path;
1168         $path = $c->dispatcher->uri_for_action($action, $captures);
1169         if (not defined $path) {
1170             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1171                 if $c->debug;
1172             return undef;
1173         }
1174         $path = '/' if $path eq '';
1175     }
1176
1177     undef($path) if (defined $path && $path eq '');
1178
1179     my $params =
1180       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1181
1182     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1183     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1184
1185     unshift(@args, $path);
1186
1187     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1188         my $namespace = $c->namespace;
1189         if (defined $path) { # cheesy hack to handle path '../foo'
1190            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1191         }
1192         unshift(@args, $namespace || '');
1193     }
1194
1195     # join args with '/', or a blank string
1196     my $args = join('/', grep { defined($_) } @args);
1197     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1198     $args =~ s!^/+!!;
1199     my $base = $c->req->base;
1200     my $class = ref($base);
1201     $base =~ s{(?<!/)$}{/};
1202
1203     my $query = '';
1204
1205     if (my @keys = keys %$params) {
1206       # somewhat lifted from URI::_query's query_form
1207       $query = '?'.join('&', map {
1208           my $val = $params->{$_};
1209           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1210           s/ /+/g;
1211           my $key = $_;
1212           $val = '' unless defined $val;
1213           (map {
1214               $_ = "$_";
1215               utf8::encode( $_ ) if utf8::is_utf8($_);
1216               # using the URI::Escape pattern here so utf8 chars survive
1217               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1218               s/ /+/g;
1219               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1220       } @keys);
1221     }
1222
1223     my $res = bless(\"${base}${args}${query}", $class);
1224     $res;
1225 }
1226
1227 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1228
1229 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1230
1231 =over
1232
1233 =item $path
1234
1235 A private path to the Catalyst action you want to create a URI for.
1236
1237 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1238 >> and passing the resulting C<$action> and the remaining arguments to C<<
1239 $c->uri_for >>.
1240
1241 You can also pass in a Catalyst::Action object, in which case it is passed to
1242 C<< $c->uri_for >>.
1243
1244 =back
1245
1246 =cut
1247
1248 sub uri_for_action {
1249     my ( $c, $path, @args ) = @_;
1250     my $action = blessed($path)
1251       ? $path
1252       : $c->dispatcher->get_action_by_path($path);
1253     unless (defined $action) {
1254       croak "Can't find action for path '$path'";
1255     }
1256     return $c->uri_for( $action, @args );
1257 }
1258
1259 =head2 $c->welcome_message
1260
1261 Returns the Catalyst welcome HTML page.
1262
1263 =cut
1264
1265 sub welcome_message {
1266     my $c      = shift;
1267     my $name   = $c->config->{name};
1268     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1269     my $prefix = Catalyst::Utils::appprefix( ref $c );
1270     $c->response->content_type('text/html; charset=utf-8');
1271     return <<"EOF";
1272 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1273     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1274 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1275     <head>
1276     <meta http-equiv="Content-Language" content="en" />
1277     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1278         <title>$name on Catalyst $VERSION</title>
1279         <style type="text/css">
1280             body {
1281                 color: #000;
1282                 background-color: #eee;
1283             }
1284             div#content {
1285                 width: 640px;
1286                 margin-left: auto;
1287                 margin-right: auto;
1288                 margin-top: 10px;
1289                 margin-bottom: 10px;
1290                 text-align: left;
1291                 background-color: #ccc;
1292                 border: 1px solid #aaa;
1293             }
1294             p, h1, h2 {
1295                 margin-left: 20px;
1296                 margin-right: 20px;
1297                 font-family: verdana, tahoma, sans-serif;
1298             }
1299             a {
1300                 font-family: verdana, tahoma, sans-serif;
1301             }
1302             :link, :visited {
1303                     text-decoration: none;
1304                     color: #b00;
1305                     border-bottom: 1px dotted #bbb;
1306             }
1307             :link:hover, :visited:hover {
1308                     color: #555;
1309             }
1310             div#topbar {
1311                 margin: 0px;
1312             }
1313             pre {
1314                 margin: 10px;
1315                 padding: 8px;
1316             }
1317             div#answers {
1318                 padding: 8px;
1319                 margin: 10px;
1320                 background-color: #fff;
1321                 border: 1px solid #aaa;
1322             }
1323             h1 {
1324                 font-size: 0.9em;
1325                 font-weight: normal;
1326                 text-align: center;
1327             }
1328             h2 {
1329                 font-size: 1.0em;
1330             }
1331             p {
1332                 font-size: 0.9em;
1333             }
1334             p img {
1335                 float: right;
1336                 margin-left: 10px;
1337             }
1338             span#appname {
1339                 font-weight: bold;
1340                 font-size: 1.6em;
1341             }
1342         </style>
1343     </head>
1344     <body>
1345         <div id="content">
1346             <div id="topbar">
1347                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1348                     $VERSION</h1>
1349              </div>
1350              <div id="answers">
1351                  <p>
1352                  <img src="$logo" alt="Catalyst Logo" />
1353                  </p>
1354                  <p>Welcome to the  world of Catalyst.
1355                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1356                     framework will make web development something you had
1357                     never expected it to be: Fun, rewarding, and quick.</p>
1358                  <h2>What to do now?</h2>
1359                  <p>That really depends  on what <b>you</b> want to do.
1360                     We do, however, provide you with a few starting points.</p>
1361                  <p>If you want to jump right into web development with Catalyst
1362                     you might want to start with a tutorial.</p>
1363 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1364 </pre>
1365 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1366 <pre>
1367 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1368 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1369 </code></pre>
1370                  <h2>What to do next?</h2>
1371                  <p>Next it's time to write an actual application. Use the
1372                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1373                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1374                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1375                     they can save you a lot of work.</p>
1376                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1377                     <p>Also, be sure to check out the vast and growing
1378                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1379                     you are likely to find what you need there.
1380                     </p>
1381
1382                  <h2>Need help?</h2>
1383                  <p>Catalyst has a very active community. Here are the main places to
1384                     get in touch with us.</p>
1385                  <ul>
1386                      <li>
1387                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1388                      </li>
1389                      <li>
1390                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1391                      </li>
1392                      <li>
1393                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1394                      </li>
1395                  </ul>
1396                  <h2>In conclusion</h2>
1397                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1398                     as we enjoyed making it. Please contact us if you have ideas
1399                     for improvement or other feedback.</p>
1400              </div>
1401          </div>
1402     </body>
1403 </html>
1404 EOF
1405 }
1406
1407 =head1 INTERNAL METHODS
1408
1409 These methods are not meant to be used by end users.
1410
1411 =head2 $c->components
1412
1413 Returns a hash of components.
1414
1415 =head2 $c->context_class
1416
1417 Returns or sets the context class.
1418
1419 =head2 $c->counter
1420
1421 Returns a hashref containing coderefs and execution counts (needed for
1422 deep recursion detection).
1423
1424 =head2 $c->depth
1425
1426 Returns the number of actions on the current internal execution stack.
1427
1428 =head2 $c->dispatch
1429
1430 Dispatches a request to actions.
1431
1432 =cut
1433
1434 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1435
1436 =head2 $c->dispatcher_class
1437
1438 Returns or sets the dispatcher class.
1439
1440 =head2 $c->dump_these
1441
1442 Returns a list of 2-element array references (name, structure) pairs
1443 that will be dumped on the error page in debug mode.
1444
1445 =cut
1446
1447 sub dump_these {
1448     my $c = shift;
1449     [ Request => $c->req ],
1450     [ Response => $c->res ],
1451     [ Stash => $c->stash ],
1452     [ Config => $c->config ];
1453 }
1454
1455 =head2 $c->engine_class
1456
1457 Returns or sets the engine class.
1458
1459 =head2 $c->execute( $class, $coderef )
1460
1461 Execute a coderef in given class and catch exceptions. Errors are available
1462 via $c->error.
1463
1464 =cut
1465
1466 sub execute {
1467     my ( $c, $class, $code ) = @_;
1468     $class = $c->component($class) || $class;
1469     $c->state(0);
1470
1471     if ( $c->depth >= $RECURSION ) {
1472         my $action = $code->reverse();
1473         $action = "/$action" unless $action =~ /->/;
1474         my $error = qq/Deep recursion detected calling "${action}"/;
1475         $c->log->error($error);
1476         $c->error($error);
1477         $c->state(0);
1478         return $c->state;
1479     }
1480
1481     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1482
1483     push( @{ $c->stack }, $code );
1484
1485     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1486
1487     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1488
1489     my $last = pop( @{ $c->stack } );
1490
1491     if ( my $error = $@ ) {
1492         if ( !ref($error) and $error eq $DETACH ) {
1493             die $DETACH if($c->depth > 1);
1494         }
1495         elsif ( !ref($error) and $error eq $GO ) {
1496             die $GO if($c->depth > 0);
1497         }
1498         else {
1499             unless ( ref $error ) {
1500                 no warnings 'uninitialized';
1501                 chomp $error;
1502                 my $class = $last->class;
1503                 my $name  = $last->name;
1504                 $error = qq/Caught exception in $class->$name "$error"/;
1505             }
1506             $c->error($error);
1507             $c->state(0);
1508         }
1509     }
1510     return $c->state;
1511 }
1512
1513 sub _stats_start_execute {
1514     my ( $c, $code ) = @_;
1515
1516     return if ( ( $code->name =~ /^_.*/ )
1517         && ( !$c->config->{show_internal_actions} ) );
1518
1519     my $action_name = $code->reverse();
1520     $c->counter->{$action_name}++;
1521
1522     my $action = $action_name;
1523     $action = "/$action" unless $action =~ /->/;
1524
1525     # determine if the call was the result of a forward
1526     # this is done by walking up the call stack and looking for a calling
1527     # sub of Catalyst::forward before the eval
1528     my $callsub = q{};
1529     for my $index ( 2 .. 11 ) {
1530         last
1531         if ( ( caller($index) )[0] eq 'Catalyst'
1532             && ( caller($index) )[3] eq '(eval)' );
1533
1534         if ( ( caller($index) )[3] =~ /forward$/ ) {
1535             $callsub = ( caller($index) )[3];
1536             $action  = "-> $action";
1537             last;
1538         }
1539     }
1540
1541     my $uid = $action_name . $c->counter->{$action_name};
1542
1543     # is this a root-level call or a forwarded call?
1544     if ( $callsub =~ /forward$/ ) {
1545
1546         # forward, locate the caller
1547         if ( my $parent = $c->stack->[-1] ) {
1548             $c->stats->profile(
1549                 begin  => $action,
1550                 parent => "$parent" . $c->counter->{"$parent"},
1551                 uid    => $uid,
1552             );
1553         }
1554         else {
1555
1556             # forward with no caller may come from a plugin
1557             $c->stats->profile(
1558                 begin => $action,
1559                 uid   => $uid,
1560             );
1561         }
1562     }
1563     else {
1564
1565         # root-level call
1566         $c->stats->profile(
1567             begin => $action,
1568             uid   => $uid,
1569         );
1570     }
1571     return $action;
1572
1573 }
1574
1575 sub _stats_finish_execute {
1576     my ( $c, $info ) = @_;
1577     $c->stats->profile( end => $info );
1578 }
1579
1580 =head2 $c->_localize_fields( sub { }, \%keys );
1581
1582 =cut
1583
1584 #Why does this exist? This is no longer safe and WILL NOT WORK.
1585 # it doesnt seem to be used anywhere. can we remove it?
1586 sub _localize_fields {
1587     my ( $c, $localized, $code ) = ( @_ );
1588
1589     my $request = delete $localized->{request} || {};
1590     my $response = delete $localized->{response} || {};
1591
1592     local @{ $c }{ keys %$localized } = values %$localized;
1593     local @{ $c->request }{ keys %$request } = values %$request;
1594     local @{ $c->response }{ keys %$response } = values %$response;
1595
1596     $code->();
1597 }
1598
1599 =head2 $c->finalize
1600
1601 Finalizes the request.
1602
1603 =cut
1604
1605 sub finalize {
1606     my $c = shift;
1607
1608     for my $error ( @{ $c->error } ) {
1609         $c->log->error($error);
1610     }
1611
1612     # Allow engine to handle finalize flow (for POE)
1613     my $engine = $c->engine;
1614     if ( my $code = $engine->can('finalize') ) {
1615         $engine->$code($c);
1616     }
1617     else {
1618
1619         $c->finalize_uploads;
1620
1621         # Error
1622         if ( $#{ $c->error } >= 0 ) {
1623             $c->finalize_error;
1624         }
1625
1626         $c->finalize_headers;
1627
1628         # HEAD request
1629         if ( $c->request->method eq 'HEAD' ) {
1630             $c->response->body('');
1631         }
1632
1633         $c->finalize_body;
1634     }
1635
1636     if ($c->use_stats) {
1637         my $elapsed = sprintf '%f', $c->stats->elapsed;
1638         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1639         $c->log->info(
1640             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1641     }
1642
1643     return $c->response->status;
1644 }
1645
1646 =head2 $c->finalize_body
1647
1648 Finalizes body.
1649
1650 =cut
1651
1652 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1653
1654 =head2 $c->finalize_cookies
1655
1656 Finalizes cookies.
1657
1658 =cut
1659
1660 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1661
1662 =head2 $c->finalize_error
1663
1664 Finalizes error.
1665
1666 =cut
1667
1668 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1669
1670 =head2 $c->finalize_headers
1671
1672 Finalizes headers.
1673
1674 =cut
1675
1676 sub finalize_headers {
1677     my $c = shift;
1678
1679     my $response = $c->response; #accessor calls can add up?
1680
1681     # Check if we already finalized headers
1682     return if $response->finalized_headers;
1683
1684     # Handle redirects
1685     if ( my $location = $response->redirect ) {
1686         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1687         $response->header( Location => $location );
1688
1689         if ( !$response->has_body ) {
1690             # Add a default body if none is already present
1691             $response->body(
1692                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1693             );
1694         }
1695     }
1696
1697     # Content-Length
1698     if ( $response->body && !$response->content_length ) {
1699
1700         # get the length from a filehandle
1701         if ( blessed( $response->body ) && $response->body->can('read') )
1702         {
1703             my $stat = stat $response->body;
1704             if ( $stat && $stat->size > 0 ) {
1705                 $response->content_length( $stat->size );
1706             }
1707             else {
1708                 $c->log->warn('Serving filehandle without a content-length');
1709             }
1710         }
1711         else {
1712             # everything should be bytes at this point, but just in case
1713             $response->content_length( bytes::length( $response->body ) );
1714         }
1715     }
1716
1717     # Errors
1718     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1719         $response->headers->remove_header("Content-Length");
1720         $response->body('');
1721     }
1722
1723     $c->finalize_cookies;
1724
1725     $c->engine->finalize_headers( $c, @_ );
1726
1727     # Done
1728     $response->finalized_headers(1);
1729 }
1730
1731 =head2 $c->finalize_output
1732
1733 An alias for finalize_body.
1734
1735 =head2 $c->finalize_read
1736
1737 Finalizes the input after reading is complete.
1738
1739 =cut
1740
1741 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1742
1743 =head2 $c->finalize_uploads
1744
1745 Finalizes uploads. Cleans up any temporary files.
1746
1747 =cut
1748
1749 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1750
1751 =head2 $c->get_action( $action, $namespace )
1752
1753 Gets an action in a given namespace.
1754
1755 =cut
1756
1757 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1758
1759 =head2 $c->get_actions( $action, $namespace )
1760
1761 Gets all actions of a given name in a namespace and all parent
1762 namespaces.
1763
1764 =cut
1765
1766 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1767
1768 =head2 $c->handle_request( $class, @arguments )
1769
1770 Called to handle each HTTP request.
1771
1772 =cut
1773
1774 sub handle_request {
1775     my ( $class, @arguments ) = @_;
1776
1777     # Always expect worst case!
1778     my $status = -1;
1779     eval {
1780         if ($class->debug) {
1781             my $secs = time - $START || 1;
1782             my $av = sprintf '%.3f', $COUNT / $secs;
1783             my $time = localtime time;
1784             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1785         }
1786
1787         my $c = $class->prepare(@arguments);
1788         $c->dispatch;
1789         $status = $c->finalize;
1790     };
1791
1792     if ( my $error = $@ ) {
1793         chomp $error;
1794         $class->log->error(qq/Caught exception in engine "$error"/);
1795     }
1796
1797     $COUNT++;
1798
1799     if(my $coderef = $class->log->can('_flush')){
1800         $class->log->$coderef();
1801     }
1802     return $status;
1803 }
1804
1805 =head2 $c->prepare( @arguments )
1806
1807 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1808 etc.).
1809
1810 =cut
1811
1812 sub prepare {
1813     my ( $class, @arguments ) = @_;
1814
1815     # XXX
1816     # After the app/ctxt split, this should become an attribute based on something passed
1817     # into the application.
1818     $class->context_class( ref $class || $class ) unless $class->context_class;
1819
1820     my $c = $class->context_class->new({});
1821
1822     # For on-demand data
1823     $c->request->_context($c);
1824     $c->response->_context($c);
1825
1826     #surely this is not the most efficient way to do things...
1827     $c->stats($class->stats_class->new)->enable($c->use_stats);
1828     if ( $c->debug ) {
1829         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1830     }
1831
1832     #XXX reuse coderef from can
1833     # Allow engine to direct the prepare flow (for POE)
1834     if ( $c->engine->can('prepare') ) {
1835         $c->engine->prepare( $c, @arguments );
1836     }
1837     else {
1838         $c->prepare_request(@arguments);
1839         $c->prepare_connection;
1840         $c->prepare_query_parameters;
1841         $c->prepare_headers;
1842         $c->prepare_cookies;
1843         $c->prepare_path;
1844
1845         # Prepare the body for reading, either by prepare_body
1846         # or the user, if they are using $c->read
1847         $c->prepare_read;
1848
1849         # Parse the body unless the user wants it on-demand
1850         unless ( $c->config->{parse_on_demand} ) {
1851             $c->prepare_body;
1852         }
1853     }
1854
1855     my $method  = $c->req->method  || '';
1856     my $path    = $c->req->path;
1857     $path       = '/' unless length $path;
1858     my $address = $c->req->address || '';
1859
1860     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1861       if $c->debug;
1862
1863     $c->prepare_action;
1864
1865     return $c;
1866 }
1867
1868 =head2 $c->prepare_action
1869
1870 Prepares action. See L<Catalyst::Dispatcher>.
1871
1872 =cut
1873
1874 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1875
1876 =head2 $c->prepare_body
1877
1878 Prepares message body.
1879
1880 =cut
1881
1882 sub prepare_body {
1883     my $c = shift;
1884
1885     return if $c->request->_has_body;
1886
1887     # Initialize on-demand data
1888     $c->engine->prepare_body( $c, @_ );
1889     $c->prepare_parameters;
1890     $c->prepare_uploads;
1891
1892     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1893         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1894         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1895             my $param = $c->req->body_parameters->{$key};
1896             my $value = defined($param) ? $param : '';
1897             $t->row( $key,
1898                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1899         }
1900         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1901     }
1902 }
1903
1904 =head2 $c->prepare_body_chunk( $chunk )
1905
1906 Prepares a chunk of data before sending it to L<HTTP::Body>.
1907
1908 See L<Catalyst::Engine>.
1909
1910 =cut
1911
1912 sub prepare_body_chunk {
1913     my $c = shift;
1914     $c->engine->prepare_body_chunk( $c, @_ );
1915 }
1916
1917 =head2 $c->prepare_body_parameters
1918
1919 Prepares body parameters.
1920
1921 =cut
1922
1923 sub prepare_body_parameters {
1924     my $c = shift;
1925     $c->engine->prepare_body_parameters( $c, @_ );
1926 }
1927
1928 =head2 $c->prepare_connection
1929
1930 Prepares connection.
1931
1932 =cut
1933
1934 sub prepare_connection {
1935     my $c = shift;
1936     $c->engine->prepare_connection( $c, @_ );
1937 }
1938
1939 =head2 $c->prepare_cookies
1940
1941 Prepares cookies.
1942
1943 =cut
1944
1945 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1946
1947 =head2 $c->prepare_headers
1948
1949 Prepares headers.
1950
1951 =cut
1952
1953 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1954
1955 =head2 $c->prepare_parameters
1956
1957 Prepares parameters.
1958
1959 =cut
1960
1961 sub prepare_parameters {
1962     my $c = shift;
1963     $c->prepare_body_parameters;
1964     $c->engine->prepare_parameters( $c, @_ );
1965 }
1966
1967 =head2 $c->prepare_path
1968
1969 Prepares path and base.
1970
1971 =cut
1972
1973 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1974
1975 =head2 $c->prepare_query_parameters
1976
1977 Prepares query parameters.
1978
1979 =cut
1980
1981 sub prepare_query_parameters {
1982     my $c = shift;
1983
1984     $c->engine->prepare_query_parameters( $c, @_ );
1985
1986     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1987         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1988         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1989             my $param = $c->req->query_parameters->{$key};
1990             my $value = defined($param) ? $param : '';
1991             $t->row( $key,
1992                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1993         }
1994         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1995     }
1996 }
1997
1998 =head2 $c->prepare_read
1999
2000 Prepares the input for reading.
2001
2002 =cut
2003
2004 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2005
2006 =head2 $c->prepare_request
2007
2008 Prepares the engine request.
2009
2010 =cut
2011
2012 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2013
2014 =head2 $c->prepare_uploads
2015
2016 Prepares uploads.
2017
2018 =cut
2019
2020 sub prepare_uploads {
2021     my $c = shift;
2022
2023     $c->engine->prepare_uploads( $c, @_ );
2024
2025     if ( $c->debug && keys %{ $c->request->uploads } ) {
2026         my $t = Text::SimpleTable->new(
2027             [ 12, 'Parameter' ],
2028             [ 26, 'Filename' ],
2029             [ 18, 'Type' ],
2030             [ 9,  'Size' ]
2031         );
2032         for my $key ( sort keys %{ $c->request->uploads } ) {
2033             my $upload = $c->request->uploads->{$key};
2034             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2035                 $t->row( $key, $u->filename, $u->type, $u->size );
2036             }
2037         }
2038         $c->log->debug( "File Uploads are:\n" . $t->draw );
2039     }
2040 }
2041
2042 =head2 $c->prepare_write
2043
2044 Prepares the output for writing.
2045
2046 =cut
2047
2048 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2049
2050 =head2 $c->request_class
2051
2052 Returns or sets the request class.
2053
2054 =head2 $c->response_class
2055
2056 Returns or sets the response class.
2057
2058 =head2 $c->read( [$maxlength] )
2059
2060 Reads a chunk of data from the request body. This method is designed to
2061 be used in a while loop, reading C<$maxlength> bytes on every call.
2062 C<$maxlength> defaults to the size of the request if not specified.
2063
2064 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
2065 directly.
2066
2067 Warning: If you use read(), Catalyst will not process the body,
2068 so you will not be able to access POST parameters or file uploads via
2069 $c->request.  You must handle all body parsing yourself.
2070
2071 =cut
2072
2073 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2074
2075 =head2 $c->run
2076
2077 Starts the engine.
2078
2079 =cut
2080
2081 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2082
2083 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2084
2085 Sets an action in a given namespace.
2086
2087 =cut
2088
2089 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2090
2091 =head2 $c->setup_actions($component)
2092
2093 Sets up actions for a component.
2094
2095 =cut
2096
2097 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2098
2099 =head2 $c->setup_components
2100
2101 Sets up components. Specify a C<setup_components> config option to pass
2102 additional options directly to L<Module::Pluggable>. To add additional
2103 search paths, specify a key named C<search_extra> as an array
2104 reference. Items in the array beginning with C<::> will have the
2105 application class name prepended to them.
2106
2107 All components found will also have any
2108 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2109 Note, that modules which are B<not> an I<inner package> of the main
2110 file namespace loaded will not be instantiated as components.
2111
2112 =cut
2113
2114 sub setup_components {
2115     my $class = shift;
2116
2117     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2118     my $config  = $class->config->{ setup_components };
2119     my $extra   = delete $config->{ search_extra } || [];
2120
2121     push @paths, @$extra;
2122
2123     my $locator = Module::Pluggable::Object->new(
2124         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2125         %$config
2126     );
2127
2128     my @comps = sort { length $a <=> length $b } $locator->plugins;
2129     my %comps = map { $_ => 1 } @comps;
2130
2131     my $deprecated_component_names = grep { /::[CMV]::/ } @comps;
2132     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2133         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2134     ) if $deprecated_component_names;
2135
2136     for my $component ( @comps ) {
2137
2138         # We pass ignore_loaded here so that overlay files for (e.g.)
2139         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2140         # we know M::P::O found a file on disk so this is safe
2141
2142         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2143         #Class::MOP::load_class($component);
2144
2145         my $module  = $class->setup_component( $component );
2146         my %modules = (
2147             $component => $module,
2148             map {
2149                 $_ => $class->setup_component( $_ )
2150             } grep {
2151               not exists $comps{$_}
2152             } Devel::InnerPackage::list_packages( $component )
2153         );
2154
2155         for my $key ( keys %modules ) {
2156             $class->components->{ $key } = $modules{ $key };
2157         }
2158     }
2159 }
2160
2161 =head2 $c->setup_component
2162
2163 =cut
2164
2165 sub setup_component {
2166     my( $class, $component ) = @_;
2167
2168     unless ( $component->can( 'COMPONENT' ) ) {
2169         return $component;
2170     }
2171
2172     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2173     my $config = $class->config->{ $suffix } || {};
2174
2175     my $instance = eval { $component->COMPONENT( $class, $config ); };
2176
2177     if ( my $error = $@ ) {
2178         chomp $error;
2179         Catalyst::Exception->throw(
2180             message => qq/Couldn't instantiate component "$component", "$error"/
2181         );
2182     }
2183
2184     Catalyst::Exception->throw(
2185         message =>
2186         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2187     ) unless blessed($instance);
2188
2189     return $instance;
2190 }
2191
2192 =head2 $c->setup_dispatcher
2193
2194 Sets up dispatcher.
2195
2196 =cut
2197
2198 sub setup_dispatcher {
2199     my ( $class, $dispatcher ) = @_;
2200
2201     if ($dispatcher) {
2202         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2203     }
2204
2205     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2206         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2207     }
2208
2209     unless ($dispatcher) {
2210         $dispatcher = $class->dispatcher_class;
2211     }
2212
2213     Class::MOP::load_class($dispatcher);
2214
2215     # dispatcher instance
2216     $class->dispatcher( $dispatcher->new );
2217 }
2218
2219 =head2 $c->setup_engine
2220
2221 Sets up engine.
2222
2223 =cut
2224
2225 sub setup_engine {
2226     my ( $class, $engine ) = @_;
2227
2228     if ($engine) {
2229         $engine = 'Catalyst::Engine::' . $engine;
2230     }
2231
2232     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2233         $engine = 'Catalyst::Engine::' . $env;
2234     }
2235
2236     if ( $ENV{MOD_PERL} ) {
2237         my $meta = Class::MOP::get_metaclass_by_name($class);
2238
2239         # create the apache method
2240         $meta->add_method('apache' => sub { shift->engine->apache });
2241
2242         my ( $software, $version ) =
2243           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2244
2245         $version =~ s/_//g;
2246         $version =~ s/(\.[^.]+)\./$1/g;
2247
2248         if ( $software eq 'mod_perl' ) {
2249
2250             if ( !$engine ) {
2251
2252                 if ( $version >= 1.99922 ) {
2253                     $engine = 'Catalyst::Engine::Apache2::MP20';
2254                 }
2255
2256                 elsif ( $version >= 1.9901 ) {
2257                     $engine = 'Catalyst::Engine::Apache2::MP19';
2258                 }
2259
2260                 elsif ( $version >= 1.24 ) {
2261                     $engine = 'Catalyst::Engine::Apache::MP13';
2262                 }
2263
2264                 else {
2265                     Catalyst::Exception->throw( message =>
2266                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2267                 }
2268
2269             }
2270
2271             # install the correct mod_perl handler
2272             if ( $version >= 1.9901 ) {
2273                 *handler = sub  : method {
2274                     shift->handle_request(@_);
2275                 };
2276             }
2277             else {
2278                 *handler = sub ($$) { shift->handle_request(@_) };
2279             }
2280
2281         }
2282
2283         elsif ( $software eq 'Zeus-Perl' ) {
2284             $engine = 'Catalyst::Engine::Zeus';
2285         }
2286
2287         else {
2288             Catalyst::Exception->throw(
2289                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2290         }
2291     }
2292
2293     unless ($engine) {
2294         $engine = $class->engine_class;
2295     }
2296
2297     Class::MOP::load_class($engine);
2298
2299     # check for old engines that are no longer compatible
2300     my $old_engine;
2301     if ( $engine->isa('Catalyst::Engine::Apache')
2302         && !Catalyst::Engine::Apache->VERSION )
2303     {
2304         $old_engine = 1;
2305     }
2306
2307     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2308         && Catalyst::Engine::Server->VERSION le '0.02' )
2309     {
2310         $old_engine = 1;
2311     }
2312
2313     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2314         && $engine->VERSION eq '0.01' )
2315     {
2316         $old_engine = 1;
2317     }
2318
2319     elsif ($engine->isa('Catalyst::Engine::Zeus')
2320         && $engine->VERSION eq '0.01' )
2321     {
2322         $old_engine = 1;
2323     }
2324
2325     if ($old_engine) {
2326         Catalyst::Exception->throw( message =>
2327               qq/Engine "$engine" is not supported by this version of Catalyst/
2328         );
2329     }
2330
2331     # engine instance
2332     $class->engine( $engine->new );
2333 }
2334
2335 =head2 $c->setup_home
2336
2337 Sets up the home directory.
2338
2339 =cut
2340
2341 sub setup_home {
2342     my ( $class, $home ) = @_;
2343
2344     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2345         $home = $env;
2346     }
2347
2348     $home ||= Catalyst::Utils::home($class);
2349
2350     if ($home) {
2351         #I remember recently being scolded for assigning config values like this
2352         $class->config->{home} ||= $home;
2353         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2354     }
2355 }
2356
2357 =head2 $c->setup_log
2358
2359 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2360 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2361 log to.
2362
2363 This method also installs a C<debug> method that returns a true value into the
2364 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2365 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2366
2367 Note that if the log has already been setup, by either a previous call to
2368 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2369 that this method won't actually set up the log object.
2370
2371 =cut
2372
2373 sub setup_log {
2374     my ( $class, $levels ) = @_;
2375
2376     $levels ||= '';
2377     $levels =~ s/^\s+//;
2378     $levels =~ s/\s+$//;
2379     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels || '';
2380
2381     unless ( $class->log ) {
2382         $class->log( Catalyst::Log->new(keys %levels) );
2383     }
2384
2385     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2386     if ( defined($env_debug) or $levels{debug} ) {
2387         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2388         $class->log->debug('Debug messages enabled');
2389     }
2390 }
2391
2392 =head2 $c->setup_plugins
2393
2394 Sets up plugins.
2395
2396 =cut
2397
2398 =head2 $c->setup_stats
2399
2400 Sets up timing statistics class.
2401
2402 =cut
2403
2404 sub setup_stats {
2405     my ( $class, $stats ) = @_;
2406
2407     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2408
2409     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2410     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2411         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2412         $class->log->debug('Statistics enabled');
2413     }
2414 }
2415
2416
2417 =head2 $c->registered_plugins
2418
2419 Returns a sorted list of the plugins which have either been stated in the
2420 import list or which have been added via C<< MyApp->plugin(@args); >>.
2421
2422 If passed a given plugin name, it will report a boolean value indicating
2423 whether or not that plugin is loaded.  A fully qualified name is required if
2424 the plugin name does not begin with C<Catalyst::Plugin::>.
2425
2426  if ($c->registered_plugins('Some::Plugin')) {
2427      ...
2428  }
2429
2430 =cut
2431
2432 {
2433
2434     sub registered_plugins {
2435         my $proto = shift;
2436         return sort keys %{ $proto->_plugins } unless @_;
2437         my $plugin = shift;
2438         return 1 if exists $proto->_plugins->{$plugin};
2439         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2440     }
2441
2442     sub _register_plugin {
2443         my ( $proto, $plugin, $instant ) = @_;
2444         my $class = ref $proto || $proto;
2445
2446         # no ignore_loaded here, the plugin may already have been
2447         # defined in memory and we don't want to error on "no file" if so
2448
2449         Class::MOP::load_class( $plugin );
2450
2451         $proto->_plugins->{$plugin} = 1;
2452         unless ($instant) {
2453             no strict 'refs';
2454             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2455               my @superclasses = ($plugin, $meta->superclasses );
2456               $meta->superclasses(@superclasses);
2457             } else {
2458               unshift @{"$class\::ISA"}, $plugin;
2459             }
2460         }
2461         return $class;
2462     }
2463
2464     sub setup_plugins {
2465         my ( $class, $plugins ) = @_;
2466
2467         $class->_plugins( {} ) unless $class->_plugins;
2468         $plugins ||= [];
2469         for my $plugin ( reverse @$plugins ) {
2470
2471             unless ( $plugin =~ s/\A\+// ) {
2472                 $plugin = "Catalyst::Plugin::$plugin";
2473             }
2474
2475             $class->_register_plugin($plugin);
2476         }
2477     }
2478 }
2479
2480 =head2 $c->stack
2481
2482 Returns an arrayref of the internal execution stack (actions that are
2483 currently executing).
2484
2485 =head2 $c->stats_class
2486
2487 Returns or sets the stats (timing statistics) class.
2488
2489 =head2 $c->use_stats
2490
2491 Returns 1 when stats collection is enabled.  Stats collection is enabled
2492 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2493 environment variable is set.
2494
2495 Note that this is a static method, not an accessor and should be overloaded
2496 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2497
2498 =cut
2499
2500 sub use_stats { 0 }
2501
2502
2503 =head2 $c->write( $data )
2504
2505 Writes $data to the output stream. When using this method directly, you
2506 will need to manually set the C<Content-Length> header to the length of
2507 your output data, if known.
2508
2509 =cut
2510
2511 sub write {
2512     my $c = shift;
2513
2514     # Finalize headers if someone manually writes output
2515     $c->finalize_headers;
2516
2517     return $c->engine->write( $c, @_ );
2518 }
2519
2520 =head2 version
2521
2522 Returns the Catalyst version number. Mostly useful for "powered by"
2523 messages in template systems.
2524
2525 =cut
2526
2527 sub version { return $Catalyst::VERSION }
2528
2529 =head1 INTERNAL ACTIONS
2530
2531 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2532 C<_ACTION>, and C<_END>. These are by default not shown in the private
2533 action table, but you can make them visible with a config parameter.
2534
2535     MyApp->config->{show_internal_actions} = 1;
2536
2537 =head1 CASE SENSITIVITY
2538
2539 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2540 mapped to C</foo/bar>. You can activate case sensitivity with a config
2541 parameter.
2542
2543     MyApp->config->{case_sensitive} = 1;
2544
2545 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2546
2547 =head1 ON-DEMAND PARSER
2548
2549 The request body is usually parsed at the beginning of a request,
2550 but if you want to handle input yourself, you can enable on-demand
2551 parsing with a config parameter.
2552
2553     MyApp->config->{parse_on_demand} = 1;
2554
2555 =head1 PROXY SUPPORT
2556
2557 Many production servers operate using the common double-server approach,
2558 with a lightweight frontend web server passing requests to a larger
2559 backend server. An application running on the backend server must deal
2560 with two problems: the remote user always appears to be C<127.0.0.1> and
2561 the server's hostname will appear to be C<localhost> regardless of the
2562 virtual host that the user connected through.
2563
2564 Catalyst will automatically detect this situation when you are running
2565 the frontend and backend servers on the same machine. The following
2566 changes are made to the request.
2567
2568     $c->req->address is set to the user's real IP address, as read from
2569     the HTTP X-Forwarded-For header.
2570
2571     The host value for $c->req->base and $c->req->uri is set to the real
2572     host, as read from the HTTP X-Forwarded-Host header.
2573
2574 Obviously, your web server must support these headers for this to work.
2575
2576 In a more complex server farm environment where you may have your
2577 frontend proxy server(s) on different machines, you will need to set a
2578 configuration option to tell Catalyst to read the proxied data from the
2579 headers.
2580
2581     MyApp->config->{using_frontend_proxy} = 1;
2582
2583 If you do not wish to use the proxy support at all, you may set:
2584
2585     MyApp->config->{ignore_frontend_proxy} = 1;
2586
2587 =head1 THREAD SAFETY
2588
2589 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2590 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2591 believe the Catalyst core to be thread-safe.
2592
2593 If you plan to operate in a threaded environment, remember that all other
2594 modules you are using must also be thread-safe. Some modules, most notably
2595 L<DBD::SQLite>, are not thread-safe.
2596
2597 =head1 SUPPORT
2598
2599 IRC:
2600
2601     Join #catalyst on irc.perl.org.
2602
2603 Mailing Lists:
2604
2605     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2606     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2607
2608 Web:
2609
2610     http://catalyst.perl.org
2611
2612 Wiki:
2613
2614     http://dev.catalyst.perl.org
2615
2616 =head1 SEE ALSO
2617
2618 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2619
2620 =head2 L<Catalyst::Manual> - The Catalyst Manual
2621
2622 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2623
2624 =head2 L<Catalyst::Engine> - Core engine
2625
2626 =head2 L<Catalyst::Log> - Log class.
2627
2628 =head2 L<Catalyst::Request> - Request object
2629
2630 =head2 L<Catalyst::Response> - Response object
2631
2632 =head2 L<Catalyst::Test> - The test suite.
2633
2634 =head1 PROJECT FOUNDER
2635
2636 sri: Sebastian Riedel <sri@cpan.org>
2637
2638 =head1 CONTRIBUTORS
2639
2640 abw: Andy Wardley
2641
2642 acme: Leon Brocard <leon@astray.com>
2643
2644 Andrew Bramble
2645
2646 Andrew Ford
2647
2648 Andrew Ruthven
2649
2650 andyg: Andy Grundman <andy@hybridized.org>
2651
2652 audreyt: Audrey Tang
2653
2654 bricas: Brian Cassidy <bricas@cpan.org>
2655
2656 Caelum: Rafael Kitover <rkitover@io.com>
2657
2658 chansen: Christian Hansen
2659
2660 chicks: Christopher Hicks
2661
2662 David E. Wheeler
2663
2664 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2665
2666 Drew Taylor
2667
2668 esskar: Sascha Kiefer
2669
2670 fireartist: Carl Franks <cfranks@cpan.org>
2671
2672 gabb: Danijel Milicevic
2673
2674 Gary Ashton Jones
2675
2676 Geoff Richards
2677
2678 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2679
2680 jcamacho: Juan Camacho
2681
2682 jhannah: Jay Hannah <jay@jays.net>
2683
2684 Jody Belka
2685
2686 Johan Lindstrom
2687
2688 jon: Jon Schutz <jjschutz@cpan.org>
2689
2690 marcus: Marcus Ramberg <mramberg@cpan.org>
2691
2692 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2693
2694 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2695
2696 mugwump: Sam Vilain
2697
2698 naughton: David Naughton
2699
2700 ningu: David Kamholz <dkamholz@cpan.org>
2701
2702 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2703
2704 numa: Dan Sully <daniel@cpan.org>
2705
2706 obra: Jesse Vincent
2707
2708 omega: Andreas Marienborg
2709
2710 Oleg Kostyuk <cub.uanic@gmail.com>
2711
2712 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2713
2714 rafl: Florian Ragwitz <rafl@debian.org>
2715
2716 sky: Arthur Bergman
2717
2718 the_jester: Jesse Sheidlower
2719
2720 t0m: Tomas Doran <bobtfish@bobtfish.net>
2721
2722 Ulf Edvinsson
2723
2724 willert: Sebastian Willert <willert@cpan.org>
2725
2726 =head1 LICENSE
2727
2728 This library is free software, you can redistribute it and/or modify it under
2729 the same terms as Perl itself.
2730
2731 =cut
2732
2733 no Moose;
2734
2735 __PACKAGE__->meta->make_immutable;
2736
2737 1;