lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80028';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 =cut
 374
 375 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 376
 377 =head2 $c->detach( $action [, \@arguments ] )
 378
 379 =head2 $c->detach( $class, $method, [, \@arguments ] )
 380
 381 =head2 $c->detach()
 382
 383 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 384 doesn't return to the previous action when processing is finished.
 385
 386 When called with no arguments it escapes the processing chain entirely.
 387
 388 =cut
 389
 390 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 391
 392 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 393
 394 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 395
 396 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 397 but does a full dispatch, instead of just calling the new C<$action> /
 398 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 399 you go to are called, just like a new request.
 400
 401 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 402 This means, for example, that C<< $c->action >> methods such as
 403 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 404 L<reverse|Catalyst::Action/reverse> return information for the visited action
 405 when they are invoked within the visited action.  This is different from the
 406 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 407 continues to use the $c->action object from the caller action even when
 408 invoked from the callee.
 409
 410 C<< $c->stash >> is kept unchanged.
 411
 412 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 413 allows you to "wrap" another action, just as it would have been called by
 414 dispatching from a URL, while the analogous
 415 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 416 transfer control to another action as if it had been reached directly from a URL.
 417
 418 =cut
 419
 420 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 421
 422 =head2 $c->go( $action [, \@captures, \@arguments ] )
 423
 424 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 425
 426 The relationship between C<go> and
 427 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 428 the relationship between
 429 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 430 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 431 C<< $c->go >> will perform a full dispatch on the specified action or method,
 432 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 433 C<go> escapes the processing of the current request chain on completion, and
 434 does not return to its caller.
 435
 436 @arguments are arguments to the final destination of $action. @captures are
 437 arguments to the intermediate steps, if any, on the way to the final sub of
 438 $action.
 439
 440 =cut
 441
 442 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 443
 444 =head2 $c->response
 445
 446 =head2 $c->res
 447
 448 Returns the current L<Catalyst::Response> object, see there for details.
 449
 450 =head2 $c->stash
 451
 452 Returns a hashref to the stash, which may be used to store data and pass
 453 it between components during a request. You can also set hash keys by
 454 passing arguments. The stash is automatically sent to the view. The
 455 stash is cleared at the end of a request; it cannot be used for
 456 persistent storage (for this you must use a session; see
 457 L<Catalyst::Plugin::Session> for a complete system integrated with
 458 Catalyst).
 459
 460     $c->stash->{foo} = $bar;
 461     $c->stash( { moose => 'majestic', qux => 0 } );
 462     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 463
 464     # stash is automatically passed to the view for use in a template
 465     $c->forward( 'MyApp::View::TT' );
 466
 467 =cut
 468
 469 around stash => sub {
 470     my $orig = shift;
 471     my $c = shift;
 472     my $stash = $orig->($c);
 473     if (@_) {
 474         my $new_stash = @_ > 1 ? {@_} : $_[0];
 475         croak('stash takes a hash or hashref') unless ref $new_stash;
 476         foreach my $key ( keys %$new_stash ) {
 477           $stash->{$key} = $new_stash->{$key};
 478         }
 479     }
 480
 481     return $stash;
 482 };
 483
 484
 485 =head2 $c->error
 486
 487 =head2 $c->error($error, ...)
 488
 489 =head2 $c->error($arrayref)
 490
 491 Returns an arrayref containing error messages.  If Catalyst encounters an
 492 error while processing a request, it stores the error in $c->error.  This
 493 method should only be used to store fatal error messages.
 494
 495     my @error = @{ $c->error };
 496
 497 Add a new error.
 498
 499     $c->error('Something bad happened');
 500
 501 =cut
 502
 503 sub error {
 504     my $c = shift;
 505     if ( $_[0] ) {
 506         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 507         croak @$error unless ref $c;
 508         push @{ $c->{error} }, @$error;
 509     }
 510     elsif ( defined $_[0] ) { $c->{error} = undef }
 511     return $c->{error} || [];
 512 }
 513
 514
 515 =head2 $c->state
 516
 517 Contains the return value of the last executed action.
 518 Note that << $c->state >> operates in a scalar context which means that all
 519 values it returns are scalar.
 520
 521 =head2 $c->clear_errors
 522
 523 Clear errors.  You probably don't want to clear the errors unless you are
 524 implementing a custom error screen.
 525
 526 This is equivalent to running
 527
 528     $c->error(0);
 529
 530 =cut
 531
 532 sub clear_errors {
 533     my $c = shift;
 534     $c->error(0);
 535 }
 536
 537 sub _comp_search_prefixes {
 538     my $c = shift;
 539     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 540 }
 541
 542 # search components given a name and some prefixes
 543 sub _comp_names_search_prefixes {
 544     my ( $c, $name, @prefixes ) = @_;
 545     my $appclass = ref $c || $c;
 546     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 547     $filter = qr/$filter/; # Compile regex now rather than once per loop
 548
 549     # map the original component name to the sub part that we will search against
 550     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 551         grep { /$filter/ } keys %{ $c->components };
 552
 553     # undef for a name will return all
 554     return keys %eligible if !defined $name;
 555
 556     my $query  = ref $name ? $name : qr/^$name$/i;
 557     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 558
 559     return @result if @result;
 560
 561     # if we were given a regexp to search against, we're done.
 562     return if ref $name;
 563
 564     # skip regexp fallback if configured
 565     return
 566         if $appclass->config->{disable_component_resolution_regex_fallback};
 567
 568     # regexp fallback
 569     $query  = qr/$name/i;
 570     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 571
 572     # no results? try against full names
 573     if( !@result ) {
 574         @result = grep { m{$query} } keys %eligible;
 575     }
 576
 577     # don't warn if we didn't find any results, it just might not exist
 578     if( @result ) {
 579         # Disgusting hack to work out correct method name
 580         my $warn_for = lc $prefixes[0];
 581         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 582            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 583            "component resolution is unreliable and unsafe.";
 584         my $short = $result[0];
 585         # remove the component namespace prefix
 586         $short =~ s/.*?(Model|Controller|View):://;
 587         my $shortmess = Carp::shortmess('');
 588         if ($shortmess =~ m#Catalyst/Plugin#) {
 589            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 590               "plugin's config";
 591         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 592            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 593               "component's config";
 594         } else {
 595            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 596               "but if you really wanted to search, pass in a regexp as the argument " .
 597               "like so: \$c->${warn_for}(qr/${name}/)";
 598         }
 599         $c->log->warn( "${msg}$shortmess" );
 600     }
 601
 602     return @result;
 603 }
 604
 605 # Find possible names for a prefix
 606 sub _comp_names {
 607     my ( $c, @prefixes ) = @_;
 608     my $appclass = ref $c || $c;
 609
 610     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 611
 612     my @names = map { s{$filter}{}; $_; }
 613         $c->_comp_names_search_prefixes( undef, @prefixes );
 614
 615     return @names;
 616 }
 617
 618 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 619 sub _filter_component {
 620     my ( $c, $comp, @args ) = @_;
 621
 622     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 623         return $comp->ACCEPT_CONTEXT( $c, @args );
 624     }
 625
 626     return $comp;
 627 }
 628
 629 =head2 COMPONENT ACCESSORS
 630
 631 =head2 $c->controller($name)
 632
 633 Gets a L<Catalyst::Controller> instance by name.
 634
 635     $c->controller('Foo')->do_stuff;
 636
 637 If the name is omitted, will return the controller for the dispatched
 638 action.
 639
 640 If you want to search for controllers, pass in a regexp as the argument.
 641
 642     # find all controllers that start with Foo
 643     my @foo_controllers = $c->controller(qr{^Foo});
 644
 645
 646 =cut
 647
 648 sub controller {
 649     my ( $c, $name, @args ) = @_;
 650
 651     my $appclass = ref($c) || $c;
 652     if( $name ) {
 653         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 654             my $comps = $c->components;
 655             my $check = $appclass."::Controller::".$name;
 656             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 657         }
 658         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 659         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 660         return $c->_filter_component( $result[ 0 ], @args );
 661     }
 662
 663     return $c->component( $c->action->class );
 664 }
 665
 666 =head2 $c->model($name)
 667
 668 Gets a L<Catalyst::Model> instance by name.
 669
 670     $c->model('Foo')->do_stuff;
 671
 672 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 673
 674 If the name is omitted, it will look for
 675  - a model object in $c->stash->{current_model_instance}, then
 676  - a model name in $c->stash->{current_model}, then
 677  - a config setting 'default_model', or
 678  - check if there is only one model, and return it if that's the case.
 679
 680 If you want to search for models, pass in a regexp as the argument.
 681
 682     # find all models that start with Foo
 683     my @foo_models = $c->model(qr{^Foo});
 684
 685 =cut
 686
 687 sub model {
 688     my ( $c, $name, @args ) = @_;
 689     my $appclass = ref($c) || $c;
 690     if( $name ) {
 691         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 692             my $comps = $c->components;
 693             my $check = $appclass."::Model::".$name;
 694             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 695         }
 696         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 697         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 698         return $c->_filter_component( $result[ 0 ], @args );
 699     }
 700
 701     if (ref $c) {
 702         return $c->stash->{current_model_instance}
 703           if $c->stash->{current_model_instance};
 704         return $c->model( $c->stash->{current_model} )
 705           if $c->stash->{current_model};
 706     }
 707     return $c->model( $appclass->config->{default_model} )
 708       if $appclass->config->{default_model};
 709
 710     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 711
 712     if( $rest ) {
 713         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 714         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 715         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 716         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 717         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 718     }
 719
 720     return $c->_filter_component( $comp );
 721 }
 722
 723
 724 =head2 $c->view($name)
 725
 726 Gets a L<Catalyst::View> instance by name.
 727
 728     $c->view('Foo')->do_stuff;
 729
 730 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 731
 732 If the name is omitted, it will look for
 733  - a view object in $c->stash->{current_view_instance}, then
 734  - a view name in $c->stash->{current_view}, then
 735  - a config setting 'default_view', or
 736  - check if there is only one view, and return it if that's the case.
 737
 738 If you want to search for views, pass in a regexp as the argument.
 739
 740     # find all views that start with Foo
 741     my @foo_views = $c->view(qr{^Foo});
 742
 743 =cut
 744
 745 sub view {
 746     my ( $c, $name, @args ) = @_;
 747
 748     my $appclass = ref($c) || $c;
 749     if( $name ) {
 750         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 751             my $comps = $c->components;
 752             my $check = $appclass."::View::".$name;
 753             if( exists $comps->{$check} ) {
 754                 return $c->_filter_component( $comps->{$check}, @args );
 755             }
 756             else {
 757                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 758             }
 759         }
 760         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 761         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 762         return $c->_filter_component( $result[ 0 ], @args );
 763     }
 764
 765     if (ref $c) {
 766         return $c->stash->{current_view_instance}
 767           if $c->stash->{current_view_instance};
 768         return $c->view( $c->stash->{current_view} )
 769           if $c->stash->{current_view};
 770     }
 771     return $c->view( $appclass->config->{default_view} )
 772       if $appclass->config->{default_view};
 773
 774     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 775
 776     if( $rest ) {
 777         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 778         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 779         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 780         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 781         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 782     }
 783
 784     return $c->_filter_component( $comp );
 785 }
 786
 787 =head2 $c->controllers
 788
 789 Returns the available names which can be passed to $c->controller
 790
 791 =cut
 792
 793 sub controllers {
 794     my ( $c ) = @_;
 795     return $c->_comp_names(qw/Controller C/);
 796 }
 797
 798 =head2 $c->models
 799
 800 Returns the available names which can be passed to $c->model
 801
 802 =cut
 803
 804 sub models {
 805     my ( $c ) = @_;
 806     return $c->_comp_names(qw/Model M/);
 807 }
 808
 809
 810 =head2 $c->views
 811
 812 Returns the available names which can be passed to $c->view
 813
 814 =cut
 815
 816 sub views {
 817     my ( $c ) = @_;
 818     return $c->_comp_names(qw/View V/);
 819 }
 820
 821 =head2 $c->comp($name)
 822
 823 =head2 $c->component($name)
 824
 825 Gets a component object by name. This method is not recommended,
 826 unless you want to get a specific component by full
 827 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 828 should be used instead.
 829
 830 If C<$name> is a regexp, a list of components matched against the full
 831 component name will be returned.
 832
 833 If Catalyst can't find a component by name, it will fallback to regex
 834 matching by default. To disable this behaviour set
 835 disable_component_resolution_regex_fallback to a true value.
 836
 837     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 838
 839 =cut
 840
 841 sub component {
 842     my ( $c, $name, @args ) = @_;
 843
 844     if( $name ) {
 845         my $comps = $c->components;
 846
 847         if( !ref $name ) {
 848             # is it the exact name?
 849             return $c->_filter_component( $comps->{ $name }, @args )
 850                        if exists $comps->{ $name };
 851
 852             # perhaps we just omitted "MyApp"?
 853             my $composed = ( ref $c || $c ) . "::${name}";
 854             return $c->_filter_component( $comps->{ $composed }, @args )
 855                        if exists $comps->{ $composed };
 856
 857             # search all of the models, views and controllers
 858             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 859             return $c->_filter_component( $comp, @args ) if $comp;
 860         }
 861
 862         # This is here so $c->comp( '::M::' ) works
 863         my $query = ref $name ? $name : qr{$name}i;
 864
 865         my @result = grep { m{$query} } keys %{ $c->components };
 866         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 867
 868         if( $result[ 0 ] ) {
 869             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 870             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 871             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 872             return $c->_filter_component( $result[ 0 ], @args );
 873         }
 874
 875         # I would expect to return an empty list here, but that breaks back-compat
 876     }
 877
 878     # fallback
 879     return sort keys %{ $c->components };
 880 }
 881
 882 =head2 CLASS DATA AND HELPER CLASSES
 883
 884 =head2 $c->config
 885
 886 Returns or takes a hashref containing the application's configuration.
 887
 888     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 889
 890 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 891 like C<myapp.conf> in your applications home directory. See
 892 L<Catalyst::Plugin::ConfigLoader>.
 893
 894 =head3 Cascading configuration
 895
 896 The config method is present on all Catalyst components, and configuration
 897 will be merged when an application is started. Configuration loaded with
 898 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 899 followed by configuration in your top level C<MyApp> class. These two
 900 configurations are merged, and then configuration data whose hash key matches a
 901 component name is merged with configuration for that component.
 902
 903 The configuration for a component is then passed to the C<new> method when a
 904 component is constructed.
 905
 906 For example:
 907
 908     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 909     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 910
 911 will mean that C<MyApp::Model::Foo> receives the following data when
 912 constructed:
 913
 914     MyApp::Model::Foo->new({
 915         bar => 'baz',
 916         quux => 'frob',
 917         overrides => 'me',
 918     });
 919
 920 It's common practice to use a Moose attribute
 921 on the receiving component to access the config value.
 922
 923     package MyApp::Model::Foo;
 924
 925     use Moose;
 926
 927     # this attr will receive 'baz' at construction time
 928     has 'bar' => (
 929         is  => 'rw',
 930         isa => 'Str',
 931     );
 932
 933 You can then get the value 'baz' by calling $c->model('Foo')->bar
 934
 935 =cut
 936
 937 around config => sub {
 938     my $orig = shift;
 939     my $c = shift;
 940
 941     croak('Setting config after setup has been run is not allowed.')
 942         if ( @_ and $c->setup_finished );
 943
 944     $c->$orig(@_);
 945 };
 946
 947 =head2 $c->log
 948
 949 Returns the logging object instance. Unless it is already set, Catalyst
 950 sets this up with a L<Catalyst::Log> object. To use your own log class,
 951 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 952 C<< __PACKAGE__->setup >>.
 953
 954  __PACKAGE__->log( MyLogger->new );
 955  __PACKAGE__->setup;
 956
 957 And later:
 958
 959     $c->log->info( 'Now logging with my own logger!' );
 960
 961 Your log class should implement the methods described in
 962 L<Catalyst::Log>.
 963
 964
 965 =head2 $c->debug
 966
 967 Returns 1 if debug mode is enabled, 0 otherwise.
 968
 969 You can enable debug mode in several ways:
 970
 971 =over
 972
 973 =item By calling myapp_server.pl with the -d flag
 974
 975 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 976
 977 =item The -Debug option in your MyApp.pm
 978
 979 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 980
 981 =back
 982
 983 The first three also set the log level to 'debug'.
 984
 985 Calling C<< $c->debug(1) >> has no effect.
 986
 987 =cut
 988
 989 sub debug { 0 }
 990
 991 =head2 $c->dispatcher
 992
 993 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 994
 995 =head2 $c->engine
 996
 997 Returns the engine instance. See L<Catalyst::Engine>.
 998
 999
1000 =head2 UTILITY METHODS
1001
1002 =head2 $c->path_to(@path)
1003
1004 Merges C<@path> with C<< $c->config->{home} >> and returns a
1005 L<Path::Class::Dir> object. Note you can usually use this object as
1006 a filename, but sometimes you will have to explicitly stringify it
1007 yourself by calling the C<< ->stringify >> method.
1008
1009 For example:
1010
1011     $c->path_to( 'db', 'sqlite.db' );
1012
1013 =cut
1014
1015 sub path_to {
1016     my ( $c, @path ) = @_;
1017     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1018     if ( -d $path ) { return $path }
1019     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1020 }
1021
1022 =head2 $c->plugin( $name, $class, @args )
1023
1024 Helper method for plugins. It creates a class data accessor/mutator and
1025 loads and instantiates the given class.
1026
1027     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1028
1029     $c->prototype->define_javascript_functions;
1030
1031 B<Note:> This method of adding plugins is deprecated. The ability
1032 to add plugins like this B<will be removed> in a Catalyst 5.81.
1033 Please do not use this functionality in new code.
1034
1035 =cut
1036
1037 sub plugin {
1038     my ( $class, $name, $plugin, @args ) = @_;
1039
1040     # See block comment in t/unit_core_plugin.t
1041     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1042
1043     $class->_register_plugin( $plugin, 1 );
1044
1045     eval { $plugin->import };
1046     $class->mk_classdata($name);
1047     my $obj;
1048     eval { $obj = $plugin->new(@args) };
1049
1050     if ($@) {
1051         Catalyst::Exception->throw( message =>
1052               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1053     }
1054
1055     $class->$name($obj);
1056     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1057       if $class->debug;
1058 }
1059
1060 =head2 MyApp->setup
1061
1062 Initializes the dispatcher and engine, loads any plugins, and loads the
1063 model, view, and controller components. You may also specify an array
1064 of plugins to load here, if you choose to not load them in the C<use
1065 Catalyst> line.
1066
1067     MyApp->setup;
1068     MyApp->setup( qw/-Debug/ );
1069
1070 =cut
1071
1072 sub setup {
1073     my ( $class, @arguments ) = @_;
1074     croak('Running setup more than once')
1075         if ( $class->setup_finished );
1076
1077     unless ( $class->isa('Catalyst') ) {
1078
1079         Catalyst::Exception->throw(
1080             message => qq/'$class' does not inherit from Catalyst/ );
1081     }
1082
1083     if ( $class->arguments ) {
1084         @arguments = ( @arguments, @{ $class->arguments } );
1085     }
1086
1087     # Process options
1088     my $flags = {};
1089
1090     foreach (@arguments) {
1091
1092         if (/^-Debug$/) {
1093             $flags->{log} =
1094               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1095         }
1096         elsif (/^-(\w+)=?(.*)$/) {
1097             $flags->{ lc $1 } = $2;
1098         }
1099         else {
1100             push @{ $flags->{plugins} }, $_;
1101         }
1102     }
1103
1104     $class->setup_home( delete $flags->{home} );
1105
1106     $class->setup_log( delete $flags->{log} );
1107     $class->setup_plugins( delete $flags->{plugins} );
1108     $class->setup_dispatcher( delete $flags->{dispatcher} );
1109     $class->setup_engine( delete $flags->{engine} );
1110     $class->setup_stats( delete $flags->{stats} );
1111
1112     for my $flag ( sort keys %{$flags} ) {
1113
1114         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1115             &$code( $class, delete $flags->{$flag} );
1116         }
1117         else {
1118             $class->log->warn(qq/Unknown flag "$flag"/);
1119         }
1120     }
1121
1122     eval { require Catalyst::Devel; };
1123     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1124         $class->log->warn(<<"EOF");
1125 You are running an old script!
1126
1127   Please update by running (this will overwrite existing files):
1128     catalyst.pl -force -scripts $class
1129
1130   or (this will not overwrite existing files):
1131     catalyst.pl -scripts $class
1132
1133 EOF
1134     }
1135
1136     if ( $class->debug ) {
1137         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1138
1139         if (@plugins) {
1140             my $column_width = Catalyst::Utils::term_width() - 6;
1141             my $t = Text::SimpleTable->new($column_width);
1142             $t->row($_) for @plugins;
1143             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1144         }
1145
1146         my $dispatcher = $class->dispatcher;
1147         my $engine     = $class->engine;
1148         my $home       = $class->config->{home};
1149
1150         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1151         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1152
1153         $home
1154           ? ( -d $home )
1155           ? $class->log->debug(qq/Found home "$home"/)
1156           : $class->log->debug(qq/Home "$home" doesn't exist/)
1157           : $class->log->debug(q/Couldn't find home/);
1158     }
1159
1160     # Call plugins setup, this is stupid and evil.
1161     # Also screws C3 badly on 5.10, hack to avoid.
1162     {
1163         no warnings qw/redefine/;
1164         local *setup = sub { };
1165         $class->setup unless $Catalyst::__AM_RESTARTING;
1166     }
1167
1168     # Initialize our data structure
1169     $class->components( {} );
1170
1171     $class->setup_components;
1172
1173     if ( $class->debug ) {
1174         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1175         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1176         for my $comp ( sort keys %{ $class->components } ) {
1177             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1178             $t->row( $comp, $type );
1179         }
1180         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1181           if ( keys %{ $class->components } );
1182     }
1183
1184     # Add our self to components, since we are also a component
1185     if( $class->isa('Catalyst::Controller') ){
1186       $class->components->{$class} = $class;
1187     }
1188
1189     $class->setup_actions;
1190
1191     if ( $class->debug ) {
1192         my $name = $class->config->{name} || 'Application';
1193         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1194     }
1195
1196     # Make sure that the application class becomes immutable at this point,
1197     B::Hooks::EndOfScope::on_scope_end {
1198         return if $@;
1199         my $meta = Class::MOP::get_metaclass_by_name($class);
1200         if (
1201             $meta->is_immutable
1202             && ! { $meta->immutable_options }->{replace_constructor}
1203             && (
1204                    $class->isa('Class::Accessor::Fast')
1205                 || $class->isa('Class::Accessor')
1206             )
1207         ) {
1208             warn "You made your application class ($class) immutable, "
1209                 . "but did not inline the\nconstructor. "
1210                 . "This will break catalyst, as your app \@ISA "
1211                 . "Class::Accessor(::Fast)?\nPlease pass "
1212                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1213         }
1214         $meta->make_immutable(
1215             replace_constructor => 1,
1216         ) unless $meta->is_immutable;
1217     };
1218
1219     if ($class->config->{case_sensitive}) {
1220         $class->log->warn($class . "->config->{case_sensitive} is set.");
1221         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1222     }
1223
1224     $class->setup_finalize;
1225     # Should be the last thing we do so that user things hooking
1226     # setup_finalize can log..
1227     $class->log->_flush() if $class->log->can('_flush');
1228     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1229 }
1230
1231 =head2 $app->setup_finalize
1232
1233 A hook to attach modifiers to. This method does not do anything except set the
1234 C<setup_finished> accessor.
1235
1236 Applying method modifiers to the C<setup> method doesn't work, because of quirky thingsdone for plugin setup.
1237
1238 Example:
1239
1240     after setup_finalize => sub {
1241         my $app = shift;
1242
1243         ## do stuff here..
1244     };
1245
1246 =cut
1247
1248 sub setup_finalize {
1249     my ($class) = @_;
1250     $class->setup_finished(1);
1251 }
1252
1253 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1254
1255 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1256
1257 Constructs an absolute L<URI> object based on the application root, the
1258 provided path, and the additional arguments and query parameters provided.
1259 When used as a string, provides a textual URI.  If you need more flexibility
1260 than this (i.e. the option to provide relative URIs etc.) see
1261 L<Catalyst::Plugin::SmartURI>.
1262
1263 If no arguments are provided, the URI for the current action is returned.
1264 To return the current action and also provide @args, use
1265 C<< $c->uri_for( $c->action, @args ) >>.
1266
1267 If the first argument is a string, it is taken as a public URI path relative
1268 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1269 relative to the application root (if it does). It is then merged with
1270 C<< $c->request->base >>; any C<@args> are appended as additional path
1271 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1272
1273 If the first argument is a L<Catalyst::Action> it represents an action which
1274 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1275 optional C<\@captures> argument (an arrayref) allows passing the captured
1276 variables that are needed to fill in the paths of Chained and Regex actions;
1277 once the path is resolved, C<uri_for> continues as though a path was
1278 provided, appending any arguments or parameters and creating an absolute
1279 URI.
1280
1281 The captures for the current request can be found in
1282 C<< $c->request->captures >>, and actions can be resolved using
1283 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1284 path, use C<< $c->uri_for_action >> instead.
1285
1286   # Equivalent to $c->req->uri
1287   $c->uri_for($c->action, $c->req->captures,
1288       @{ $c->req->args }, $c->req->params);
1289
1290   # For the Foo action in the Bar controller
1291   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1292
1293   # Path to a static resource
1294   $c->uri_for('/static/images/logo.png');
1295
1296 =cut
1297
1298 sub uri_for {
1299     my ( $c, $path, @args ) = @_;
1300
1301     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1302         $path = $path->path_prefix;
1303         $path =~ s{/+\z}{};
1304         $path .= '/';
1305     }
1306
1307     undef($path) if (defined $path && $path eq '');
1308
1309     my $params =
1310       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1311
1312     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1313     foreach my $arg (@args) {
1314         utf8::encode($arg) if utf8::is_utf8($arg);
1315         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1316     }
1317
1318     if ( blessed($path) ) { # action object
1319         s|/|%2F|g for @args;
1320         my $captures = [ map { s|/|%2F|g; $_; }
1321                         ( scalar @args && ref $args[0] eq 'ARRAY'
1322                          ? @{ shift(@args) }
1323                          : ()) ];
1324
1325         foreach my $capture (@$captures) {
1326             utf8::encode($capture) if utf8::is_utf8($capture);
1327             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1328         }
1329
1330         my $action = $path;
1331         $path = $c->dispatcher->uri_for_action($action, $captures);
1332         if (not defined $path) {
1333             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1334                 if $c->debug;
1335             return undef;
1336         }
1337         $path = '/' if $path eq '';
1338     }
1339
1340     unshift(@args, $path);
1341
1342     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1343         my $namespace = $c->namespace;
1344         if (defined $path) { # cheesy hack to handle path '../foo'
1345            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1346         }
1347         unshift(@args, $namespace || '');
1348     }
1349
1350     # join args with '/', or a blank string
1351     my $args = join('/', grep { defined($_) } @args);
1352     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1353     $args =~ s!^/+!!;
1354     my $base = $c->req->base;
1355     my $class = ref($base);
1356     $base =~ s{(?<!/)$}{/};
1357
1358     my $query = '';
1359
1360     if (my @keys = keys %$params) {
1361       # somewhat lifted from URI::_query's query_form
1362       $query = '?'.join('&', map {
1363           my $val = $params->{$_};
1364           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1365           s/ /+/g;
1366           my $key = $_;
1367           $val = '' unless defined $val;
1368           (map {
1369               my $param = "$_";
1370               utf8::encode( $param ) if utf8::is_utf8($param);
1371               # using the URI::Escape pattern here so utf8 chars survive
1372               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1373               $param =~ s/ /+/g;
1374               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1375       } @keys);
1376     }
1377
1378     my $res = bless(\"${base}${args}${query}", $class);
1379     $res;
1380 }
1381
1382 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1383
1384 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1385
1386 =over
1387
1388 =item $path
1389
1390 A private path to the Catalyst action you want to create a URI for.
1391
1392 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1393 >> and passing the resulting C<$action> and the remaining arguments to C<<
1394 $c->uri_for >>.
1395
1396 You can also pass in a Catalyst::Action object, in which case it is passed to
1397 C<< $c->uri_for >>.
1398
1399 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1400
1401 For example, if the action looks like:
1402
1403  package MyApp::Controller::Users;
1404
1405  sub lst : Path('the-list') {}
1406
1407 You can use:
1408
1409  $c->uri_for_action('/users/lst')
1410
1411 and it will create the URI /users/the-list.
1412
1413 =back
1414
1415 =cut
1416
1417 sub uri_for_action {
1418     my ( $c, $path, @args ) = @_;
1419     my $action = blessed($path)
1420       ? $path
1421       : $c->dispatcher->get_action_by_path($path);
1422     unless (defined $action) {
1423       croak "Can't find action for path '$path'";
1424     }
1425     return $c->uri_for( $action, @args );
1426 }
1427
1428 =head2 $c->welcome_message
1429
1430 Returns the Catalyst welcome HTML page.
1431
1432 =cut
1433
1434 sub welcome_message {
1435     my $c      = shift;
1436     my $name   = $c->config->{name};
1437     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1438     my $prefix = Catalyst::Utils::appprefix( ref $c );
1439     $c->response->content_type('text/html; charset=utf-8');
1440     return <<"EOF";
1441 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1442     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1443 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1444     <head>
1445     <meta http-equiv="Content-Language" content="en" />
1446     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1447         <title>$name on Catalyst $VERSION</title>
1448         <style type="text/css">
1449             body {
1450                 color: #000;
1451                 background-color: #eee;
1452             }
1453             div#content {
1454                 width: 640px;
1455                 margin-left: auto;
1456                 margin-right: auto;
1457                 margin-top: 10px;
1458                 margin-bottom: 10px;
1459                 text-align: left;
1460                 background-color: #ccc;
1461                 border: 1px solid #aaa;
1462             }
1463             p, h1, h2 {
1464                 margin-left: 20px;
1465                 margin-right: 20px;
1466                 font-family: verdana, tahoma, sans-serif;
1467             }
1468             a {
1469                 font-family: verdana, tahoma, sans-serif;
1470             }
1471             :link, :visited {
1472                     text-decoration: none;
1473                     color: #b00;
1474                     border-bottom: 1px dotted #bbb;
1475             }
1476             :link:hover, :visited:hover {
1477                     color: #555;
1478             }
1479             div#topbar {
1480                 margin: 0px;
1481             }
1482             pre {
1483                 margin: 10px;
1484                 padding: 8px;
1485             }
1486             div#answers {
1487                 padding: 8px;
1488                 margin: 10px;
1489                 background-color: #fff;
1490                 border: 1px solid #aaa;
1491             }
1492             h1 {
1493                 font-size: 0.9em;
1494                 font-weight: normal;
1495                 text-align: center;
1496             }
1497             h2 {
1498                 font-size: 1.0em;
1499             }
1500             p {
1501                 font-size: 0.9em;
1502             }
1503             p img {
1504                 float: right;
1505                 margin-left: 10px;
1506             }
1507             span#appname {
1508                 font-weight: bold;
1509                 font-size: 1.6em;
1510             }
1511         </style>
1512     </head>
1513     <body>
1514         <div id="content">
1515             <div id="topbar">
1516                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1517                     $VERSION</h1>
1518              </div>
1519              <div id="answers">
1520                  <p>
1521                  <img src="$logo" alt="Catalyst Logo" />
1522                  </p>
1523                  <p>Welcome to the  world of Catalyst.
1524                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1525                     framework will make web development something you had
1526                     never expected it to be: Fun, rewarding, and quick.</p>
1527                  <h2>What to do now?</h2>
1528                  <p>That really depends  on what <b>you</b> want to do.
1529                     We do, however, provide you with a few starting points.</p>
1530                  <p>If you want to jump right into web development with Catalyst
1531                     you might want to start with a tutorial.</p>
1532 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1533 </pre>
1534 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1535 <pre>
1536 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1537 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1538 </code></pre>
1539                  <h2>What to do next?</h2>
1540                  <p>Next it's time to write an actual application. Use the
1541                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1542                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1543                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1544                     they can save you a lot of work.</p>
1545                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1546                     <p>Also, be sure to check out the vast and growing
1547                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1548                     you are likely to find what you need there.
1549                     </p>
1550
1551                  <h2>Need help?</h2>
1552                  <p>Catalyst has a very active community. Here are the main places to
1553                     get in touch with us.</p>
1554                  <ul>
1555                      <li>
1556                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1557                      </li>
1558                      <li>
1559                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1560                      </li>
1561                      <li>
1562                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1563                      </li>
1564                  </ul>
1565                  <h2>In conclusion</h2>
1566                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1567                     as we enjoyed making it. Please contact us if you have ideas
1568                     for improvement or other feedback.</p>
1569              </div>
1570          </div>
1571     </body>
1572 </html>
1573 EOF
1574 }
1575
1576 =head1 INTERNAL METHODS
1577
1578 These methods are not meant to be used by end users.
1579
1580 =head2 $c->components
1581
1582 Returns a hash of components.
1583
1584 =head2 $c->context_class
1585
1586 Returns or sets the context class.
1587
1588 =head2 $c->counter
1589
1590 Returns a hashref containing coderefs and execution counts (needed for
1591 deep recursion detection).
1592
1593 =head2 $c->depth
1594
1595 Returns the number of actions on the current internal execution stack.
1596
1597 =head2 $c->dispatch
1598
1599 Dispatches a request to actions.
1600
1601 =cut
1602
1603 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1604
1605 =head2 $c->dispatcher_class
1606
1607 Returns or sets the dispatcher class.
1608
1609 =head2 $c->dump_these
1610
1611 Returns a list of 2-element array references (name, structure) pairs
1612 that will be dumped on the error page in debug mode.
1613
1614 =cut
1615
1616 sub dump_these {
1617     my $c = shift;
1618     [ Request => $c->req ],
1619     [ Response => $c->res ],
1620     [ Stash => $c->stash ],
1621     [ Config => $c->config ];
1622 }
1623
1624 =head2 $c->engine_class
1625
1626 Returns or sets the engine class.
1627
1628 =head2 $c->execute( $class, $coderef )
1629
1630 Execute a coderef in given class and catch exceptions. Errors are available
1631 via $c->error.
1632
1633 =cut
1634
1635 sub execute {
1636     my ( $c, $class, $code ) = @_;
1637     $class = $c->component($class) || $class;
1638     $c->state(0);
1639
1640     if ( $c->depth >= $RECURSION ) {
1641         my $action = $code->reverse();
1642         $action = "/$action" unless $action =~ /->/;
1643         my $error = qq/Deep recursion detected calling "${action}"/;
1644         $c->log->error($error);
1645         $c->error($error);
1646         $c->state(0);
1647         return $c->state;
1648     }
1649
1650     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1651
1652     push( @{ $c->stack }, $code );
1653
1654     no warnings 'recursion';
1655     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1656
1657     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1658
1659     my $last = pop( @{ $c->stack } );
1660
1661     if ( my $error = $@ ) {
1662         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1663             $error->rethrow if $c->depth > 1;
1664         }
1665         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1666             $error->rethrow if $c->depth > 0;
1667         }
1668         else {
1669             unless ( ref $error ) {
1670                 no warnings 'uninitialized';
1671                 chomp $error;
1672                 my $class = $last->class;
1673                 my $name  = $last->name;
1674                 $error = qq/Caught exception in $class->$name "$error"/;
1675             }
1676             $c->error($error);
1677             $c->state(0);
1678         }
1679     }
1680     return $c->state;
1681 }
1682
1683 sub _stats_start_execute {
1684     my ( $c, $code ) = @_;
1685     my $appclass = ref($c) || $c;
1686     return if ( ( $code->name =~ /^_.*/ )
1687         && ( !$appclass->config->{show_internal_actions} ) );
1688
1689     my $action_name = $code->reverse();
1690     $c->counter->{$action_name}++;
1691
1692     my $action = $action_name;
1693     $action = "/$action" unless $action =~ /->/;
1694
1695     # determine if the call was the result of a forward
1696     # this is done by walking up the call stack and looking for a calling
1697     # sub of Catalyst::forward before the eval
1698     my $callsub = q{};
1699     for my $index ( 2 .. 11 ) {
1700         last
1701         if ( ( caller($index) )[0] eq 'Catalyst'
1702             && ( caller($index) )[3] eq '(eval)' );
1703
1704         if ( ( caller($index) )[3] =~ /forward$/ ) {
1705             $callsub = ( caller($index) )[3];
1706             $action  = "-> $action";
1707             last;
1708         }
1709     }
1710
1711     my $uid = $action_name . $c->counter->{$action_name};
1712
1713     # is this a root-level call or a forwarded call?
1714     if ( $callsub =~ /forward$/ ) {
1715         my $parent = $c->stack->[-1];
1716
1717         # forward, locate the caller
1718         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1719             $c->stats->profile(
1720                 begin  => $action,
1721                 parent => "$parent" . $c->counter->{"$parent"},
1722                 uid    => $uid,
1723             );
1724         }
1725         else {
1726
1727             # forward with no caller may come from a plugin
1728             $c->stats->profile(
1729                 begin => $action,
1730                 uid   => $uid,
1731             );
1732         }
1733     }
1734     else {
1735
1736         # root-level call
1737         $c->stats->profile(
1738             begin => $action,
1739             uid   => $uid,
1740         );
1741     }
1742     return $action;
1743
1744 }
1745
1746 sub _stats_finish_execute {
1747     my ( $c, $info ) = @_;
1748     $c->stats->profile( end => $info );
1749 }
1750
1751 =head2 $c->finalize
1752
1753 Finalizes the request.
1754
1755 =cut
1756
1757 sub finalize {
1758     my $c = shift;
1759
1760     for my $error ( @{ $c->error } ) {
1761         $c->log->error($error);
1762     }
1763
1764     # Allow engine to handle finalize flow (for POE)
1765     my $engine = $c->engine;
1766     if ( my $code = $engine->can('finalize') ) {
1767         $engine->$code($c);
1768     }
1769     else {
1770
1771         $c->finalize_uploads;
1772
1773         # Error
1774         if ( $#{ $c->error } >= 0 ) {
1775             $c->finalize_error;
1776         }
1777
1778         $c->finalize_headers;
1779
1780         # HEAD request
1781         if ( $c->request->method eq 'HEAD' ) {
1782             $c->response->body('');
1783         }
1784
1785         $c->finalize_body;
1786     }
1787
1788     $c->log_response;
1789
1790     if ($c->use_stats) {
1791         my $elapsed = sprintf '%f', $c->stats->elapsed;
1792         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1793         $c->log->info(
1794             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1795     }
1796
1797     return $c->response->status;
1798 }
1799
1800 =head2 $c->finalize_body
1801
1802 Finalizes body.
1803
1804 =cut
1805
1806 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1807
1808 =head2 $c->finalize_cookies
1809
1810 Finalizes cookies.
1811
1812 =cut
1813
1814 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1815
1816 =head2 $c->finalize_error
1817
1818 Finalizes error.
1819
1820 =cut
1821
1822 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1823
1824 =head2 $c->finalize_headers
1825
1826 Finalizes headers.
1827
1828 =cut
1829
1830 sub finalize_headers {
1831     my $c = shift;
1832
1833     my $response = $c->response; #accessor calls can add up?
1834
1835     # Check if we already finalized headers
1836     return if $response->finalized_headers;
1837
1838     # Handle redirects
1839     if ( my $location = $response->redirect ) {
1840         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1841         $response->header( Location => $location );
1842
1843         if ( !$response->has_body ) {
1844             # Add a default body if none is already present
1845             $response->body(
1846                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1847             );
1848         }
1849     }
1850
1851     # Content-Length
1852     if ( $response->body && !$response->content_length ) {
1853
1854         # get the length from a filehandle
1855         if ( blessed( $response->body ) && $response->body->can('read') )
1856         {
1857             my $stat = stat $response->body;
1858             if ( $stat && $stat->size > 0 ) {
1859                 $response->content_length( $stat->size );
1860             }
1861             else {
1862                 $c->log->warn('Serving filehandle without a content-length');
1863             }
1864         }
1865         else {
1866             # everything should be bytes at this point, but just in case
1867             $response->content_length( length( $response->body ) );
1868         }
1869     }
1870
1871     # Errors
1872     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1873         $response->headers->remove_header("Content-Length");
1874         $response->body('');
1875     }
1876
1877     $c->finalize_cookies;
1878
1879     $c->engine->finalize_headers( $c, @_ );
1880
1881     # Done
1882     $response->finalized_headers(1);
1883 }
1884
1885 =head2 $c->finalize_output
1886
1887 An alias for finalize_body.
1888
1889 =head2 $c->finalize_read
1890
1891 Finalizes the input after reading is complete.
1892
1893 =cut
1894
1895 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1896
1897 =head2 $c->finalize_uploads
1898
1899 Finalizes uploads. Cleans up any temporary files.
1900
1901 =cut
1902
1903 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1904
1905 =head2 $c->get_action( $action, $namespace )
1906
1907 Gets an action in a given namespace.
1908
1909 =cut
1910
1911 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1912
1913 =head2 $c->get_actions( $action, $namespace )
1914
1915 Gets all actions of a given name in a namespace and all parent
1916 namespaces.
1917
1918 =cut
1919
1920 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1921
1922 =head2 $app->handle_request( @arguments )
1923
1924 Called to handle each HTTP request.
1925
1926 =cut
1927
1928 sub handle_request {
1929     my ( $class, @arguments ) = @_;
1930
1931     # Always expect worst case!
1932     my $status = -1;
1933     eval {
1934         if ($class->debug) {
1935             my $secs = time - $START || 1;
1936             my $av = sprintf '%.3f', $COUNT / $secs;
1937             my $time = localtime time;
1938             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1939         }
1940
1941         my $c = $class->prepare(@arguments);
1942         $c->dispatch;
1943         $status = $c->finalize;
1944     };
1945
1946     if ( my $error = $@ ) {
1947         chomp $error;
1948         $class->log->error(qq/Caught exception in engine "$error"/);
1949     }
1950
1951     $COUNT++;
1952
1953     if(my $coderef = $class->log->can('_flush')){
1954         $class->log->$coderef();
1955     }
1956     return $status;
1957 }
1958
1959 =head2 $c->prepare( @arguments )
1960
1961 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1962 etc.).
1963
1964 =cut
1965
1966 sub prepare {
1967     my ( $class, @arguments ) = @_;
1968
1969     # XXX
1970     # After the app/ctxt split, this should become an attribute based on something passed
1971     # into the application.
1972     $class->context_class( ref $class || $class ) unless $class->context_class;
1973
1974     my $c = $class->context_class->new({});
1975
1976     # For on-demand data
1977     $c->request->_context($c);
1978     $c->response->_context($c);
1979
1980     #surely this is not the most efficient way to do things...
1981     $c->stats($class->stats_class->new)->enable($c->use_stats);
1982     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1983         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1984     }
1985
1986     #XXX reuse coderef from can
1987     # Allow engine to direct the prepare flow (for POE)
1988     if ( $c->engine->can('prepare') ) {
1989         $c->engine->prepare( $c, @arguments );
1990     }
1991     else {
1992         $c->prepare_request(@arguments);
1993         $c->prepare_connection;
1994         $c->prepare_query_parameters;
1995         $c->prepare_headers;
1996         $c->prepare_cookies;
1997         $c->prepare_path;
1998
1999         # Prepare the body for reading, either by prepare_body
2000         # or the user, if they are using $c->read
2001         $c->prepare_read;
2002
2003         # Parse the body unless the user wants it on-demand
2004         unless ( ref($c)->config->{parse_on_demand} ) {
2005             $c->prepare_body;
2006         }
2007     }
2008
2009     my $method  = $c->req->method  || '';
2010     my $path    = $c->req->path;
2011     $path       = '/' unless length $path;
2012     my $address = $c->req->address || '';
2013
2014     $c->log_request;
2015
2016     $c->prepare_action;
2017
2018     return $c;
2019 }
2020
2021 =head2 $c->prepare_action
2022
2023 Prepares action. See L<Catalyst::Dispatcher>.
2024
2025 =cut
2026
2027 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2028
2029 =head2 $c->prepare_body
2030
2031 Prepares message body.
2032
2033 =cut
2034
2035 sub prepare_body {
2036     my $c = shift;
2037
2038     return if $c->request->_has_body;
2039
2040     # Initialize on-demand data
2041     $c->engine->prepare_body( $c, @_ );
2042     $c->prepare_parameters;
2043     $c->prepare_uploads;
2044 }
2045
2046 =head2 $c->prepare_body_chunk( $chunk )
2047
2048 Prepares a chunk of data before sending it to L<HTTP::Body>.
2049
2050 See L<Catalyst::Engine>.
2051
2052 =cut
2053
2054 sub prepare_body_chunk {
2055     my $c = shift;
2056     $c->engine->prepare_body_chunk( $c, @_ );
2057 }
2058
2059 =head2 $c->prepare_body_parameters
2060
2061 Prepares body parameters.
2062
2063 =cut
2064
2065 sub prepare_body_parameters {
2066     my $c = shift;
2067     $c->engine->prepare_body_parameters( $c, @_ );
2068 }
2069
2070 =head2 $c->prepare_connection
2071
2072 Prepares connection.
2073
2074 =cut
2075
2076 sub prepare_connection {
2077     my $c = shift;
2078     $c->engine->prepare_connection( $c, @_ );
2079 }
2080
2081 =head2 $c->prepare_cookies
2082
2083 Prepares cookies.
2084
2085 =cut
2086
2087 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2088
2089 =head2 $c->prepare_headers
2090
2091 Prepares headers.
2092
2093 =cut
2094
2095 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2096
2097 =head2 $c->prepare_parameters
2098
2099 Prepares parameters.
2100
2101 =cut
2102
2103 sub prepare_parameters {
2104     my $c = shift;
2105     $c->prepare_body_parameters;
2106     $c->engine->prepare_parameters( $c, @_ );
2107 }
2108
2109 =head2 $c->prepare_path
2110
2111 Prepares path and base.
2112
2113 =cut
2114
2115 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2116
2117 =head2 $c->prepare_query_parameters
2118
2119 Prepares query parameters.
2120
2121 =cut
2122
2123 sub prepare_query_parameters {
2124     my $c = shift;
2125
2126     $c->engine->prepare_query_parameters( $c, @_ );
2127 }
2128
2129 =head2 $c->log_request
2130
2131 Writes information about the request to the debug logs.  This includes:
2132
2133 =over 4
2134
2135 =item * Request method, path, and remote IP address
2136
2137 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2138
2139 =item * Request parameters
2140
2141 =item * File uploads
2142
2143 =back
2144
2145 =cut
2146
2147 sub log_request {
2148     my $c = shift;
2149
2150     return unless $c->debug;
2151
2152     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2153     my $request = $dump->[1];
2154
2155     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2156     $method ||= '';
2157     $path = '/' unless length $path;
2158     $address ||= '';
2159     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2160
2161     $c->log_request_headers($request->headers);
2162
2163     if ( my $keywords = $request->query_keywords ) {
2164         $c->log->debug("Query keywords are: $keywords");
2165     }
2166
2167     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2168
2169     $c->log_request_uploads($request);
2170 }
2171
2172 =head2 $c->log_response
2173
2174 Writes information about the response to the debug logs by calling
2175 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2176
2177 =cut
2178
2179 sub log_response {
2180     my $c = shift;
2181
2182     return unless $c->debug;
2183
2184     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2185     my $response = $dump->[1];
2186
2187     $c->log_response_status_line($response);
2188     $c->log_response_headers($response->headers);
2189 }
2190
2191 =head2 $c->log_response_status_line($response)
2192
2193 Writes one line of information about the response to the debug logs.  This includes:
2194
2195 =over 4
2196
2197 =item * Response status code
2198
2199 =item * Content-Type header (if present)
2200
2201 =item * Content-Length header (if present)
2202
2203 =back
2204
2205 =cut
2206
2207 sub log_response_status_line {
2208     my ($c, $response) = @_;
2209
2210     $c->log->debug(
2211         sprintf(
2212             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2213             $response->status                            || 'unknown',
2214             $response->headers->header('Content-Type')   || 'unknown',
2215             $response->headers->header('Content-Length') || 'unknown'
2216         )
2217     );
2218 }
2219
2220 =head2 $c->log_response_headers($headers);
2221
2222 Hook method which can be wrapped by plugins to log the responseheaders.
2223 No-op in the default implementation.
2224
2225 =cut
2226
2227 sub log_response_headers {}
2228
2229 =head2 $c->log_request_parameters( query => {}, body => {} )
2230
2231 Logs request parameters to debug logs
2232
2233 =cut
2234
2235 sub log_request_parameters {
2236     my $c          = shift;
2237     my %all_params = @_;
2238
2239     return unless $c->debug;
2240
2241     my $column_width = Catalyst::Utils::term_width() - 44;
2242     foreach my $type (qw(query body)) {
2243         my $params = $all_params{$type};
2244         next if ! keys %$params;
2245         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2246         for my $key ( sort keys %$params ) {
2247             my $param = $params->{$key};
2248             my $value = defined($param) ? $param : '';
2249             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2250         }
2251         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2252     }
2253 }
2254
2255 =head2 $c->log_request_uploads
2256
2257 Logs file uploads included in the request to the debug logs.
2258 The parameter name, filename, file type, and file size are all included in
2259 the debug logs.
2260
2261 =cut
2262
2263 sub log_request_uploads {
2264     my $c = shift;
2265     my $request = shift;
2266     return unless $c->debug;
2267     my $uploads = $request->uploads;
2268     if ( keys %$uploads ) {
2269         my $t = Text::SimpleTable->new(
2270             [ 12, 'Parameter' ],
2271             [ 26, 'Filename' ],
2272             [ 18, 'Type' ],
2273             [ 9,  'Size' ]
2274         );
2275         for my $key ( sort keys %$uploads ) {
2276             my $upload = $uploads->{$key};
2277             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2278                 $t->row( $key, $u->filename, $u->type, $u->size );
2279             }
2280         }
2281         $c->log->debug( "File Uploads are:\n" . $t->draw );
2282     }
2283 }
2284
2285 =head2 $c->log_request_headers($headers);
2286
2287 Hook method which can be wrapped by plugins to log the request headers.
2288 No-op in the default implementation.
2289
2290 =cut
2291
2292 sub log_request_headers {}
2293
2294 =head2 $c->log_headers($type => $headers)
2295
2296 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2297
2298 =cut
2299
2300 sub log_headers {
2301     my $c       = shift;
2302     my $type    = shift;
2303     my $headers = shift;    # an HTTP::Headers instance
2304
2305     return unless $c->debug;
2306
2307     my $column_width = Catalyst::Utils::term_width() - 28;
2308     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2309     $headers->scan(
2310         sub {
2311             my ( $name, $value ) = @_;
2312             $t->row( $name, $value );
2313         }
2314     );
2315     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2316 }
2317
2318
2319 =head2 $c->prepare_read
2320
2321 Prepares the input for reading.
2322
2323 =cut
2324
2325 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2326
2327 =head2 $c->prepare_request
2328
2329 Prepares the engine request.
2330
2331 =cut
2332
2333 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2334
2335 =head2 $c->prepare_uploads
2336
2337 Prepares uploads.
2338
2339 =cut
2340
2341 sub prepare_uploads {
2342     my $c = shift;
2343
2344     $c->engine->prepare_uploads( $c, @_ );
2345 }
2346
2347 =head2 $c->prepare_write
2348
2349 Prepares the output for writing.
2350
2351 =cut
2352
2353 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2354
2355 =head2 $c->request_class
2356
2357 Returns or sets the request class.
2358
2359 =head2 $c->response_class
2360
2361 Returns or sets the response class.
2362
2363 =head2 $c->read( [$maxlength] )
2364
2365 Reads a chunk of data from the request body. This method is designed to
2366 be used in a while loop, reading C<$maxlength> bytes on every call.
2367 C<$maxlength> defaults to the size of the request if not specified.
2368
2369 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2370 directly.
2371
2372 Warning: If you use read(), Catalyst will not process the body,
2373 so you will not be able to access POST parameters or file uploads via
2374 $c->request.  You must handle all body parsing yourself.
2375
2376 =cut
2377
2378 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2379
2380 =head2 $c->run
2381
2382 Starts the engine.
2383
2384 =cut
2385
2386 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2387
2388 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2389
2390 Sets an action in a given namespace.
2391
2392 =cut
2393
2394 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2395
2396 =head2 $c->setup_actions($component)
2397
2398 Sets up actions for a component.
2399
2400 =cut
2401
2402 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2403
2404 =head2 $c->setup_components
2405
2406 This method is called internally to set up the application's components.
2407
2408 It finds modules by calling the L<locate_components> method, expands them to
2409 package names with the L<expand_component_module> method, and then installs
2410 each component into the application.
2411
2412 The C<setup_components> config option is passed to both of the above methods.
2413
2414 Installation of each component is performed by the L<setup_component> method,
2415 below.
2416
2417 =cut
2418
2419 sub setup_components {
2420     my $class = shift;
2421
2422     my $config  = $class->config->{ setup_components };
2423
2424     my @comps = $class->locate_components($config);
2425     my %comps = map { $_ => 1 } @comps;
2426
2427     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2428     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2429         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2430     ) if $deprecatedcatalyst_component_names;
2431
2432     for my $component ( @comps ) {
2433
2434         # We pass ignore_loaded here so that overlay files for (e.g.)
2435         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2436         # we know M::P::O found a file on disk so this is safe
2437
2438         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2439     }
2440
2441     for my $component (@comps) {
2442         my $instance = $class->components->{ $component } = $class->setup_component($component);
2443         my @expanded_components = $instance->can('expand_modules')
2444             ? $instance->expand_modules( $component, $config )
2445             : $class->expand_component_module( $component, $config );
2446         for my $component (@expanded_components) {
2447             next if $comps{$component};
2448             $class->components->{ $component } = $class->setup_component($component);
2449         }
2450     }
2451 }
2452
2453 =head2 $c->locate_components( $setup_component_config )
2454
2455 This method is meant to provide a list of component modules that should be
2456 setup for the application.  By default, it will use L<Module::Pluggable>.
2457
2458 Specify a C<setup_components> config option to pass additional options directly
2459 to L<Module::Pluggable>. To add additional search paths, specify a key named
2460 C<search_extra> as an array reference. Items in the array beginning with C<::>
2461 will have the application class name prepended to them.
2462
2463 =cut
2464
2465 sub locate_components {
2466     my $class  = shift;
2467     my $config = shift;
2468
2469     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2470     my $extra   = delete $config->{ search_extra } || [];
2471
2472     push @paths, @$extra;
2473
2474     my $locator = Module::Pluggable::Object->new(
2475         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2476         %$config
2477     );
2478
2479     # XXX think about ditching this sort entirely
2480     my @comps = sort { length $a <=> length $b } $locator->plugins;
2481
2482     return @comps;
2483 }
2484
2485 =head2 $c->expand_component_module( $component, $setup_component_config )
2486
2487 Components found by C<locate_components> will be passed to this method, which
2488 is expected to return a list of component (package) names to be set up.
2489
2490 =cut
2491
2492 sub expand_component_module {
2493     my ($class, $module) = @_;
2494     return Devel::InnerPackage::list_packages( $module );
2495 }
2496
2497 =head2 $c->setup_component
2498
2499 =cut
2500
2501 sub setup_component {
2502     my( $class, $component ) = @_;
2503
2504     unless ( $component->can( 'COMPONENT' ) ) {
2505         return $component;
2506     }
2507
2508     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2509     my $config = $class->config->{ $suffix } || {};
2510     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2511     # methods also pass it. local to avoid pointlessly shitting in config
2512     # for the debug screen, as $component is already the key name.
2513     local $config->{catalyst_component_name} = $component;
2514
2515     my $instance = eval { $component->COMPONENT( $class, $config ); };
2516
2517     if ( my $error = $@ ) {
2518         chomp $error;
2519         Catalyst::Exception->throw(
2520             message => qq/Couldn't instantiate component "$component", "$error"/
2521         );
2522     }
2523
2524     unless (blessed $instance) {
2525         my $metaclass = Moose::Util::find_meta($component);
2526         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2527         my $component_method_from = $method_meta->associated_metaclass->name;
2528         my $value = defined($instance) ? $instance : 'undef';
2529         Catalyst::Exception->throw(
2530             message =>
2531             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2532         );
2533     }
2534     return $instance;
2535 }
2536
2537 =head2 $c->setup_dispatcher
2538
2539 Sets up dispatcher.
2540
2541 =cut
2542
2543 sub setup_dispatcher {
2544     my ( $class, $dispatcher ) = @_;
2545
2546     if ($dispatcher) {
2547         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2548     }
2549
2550     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2551         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2552     }
2553
2554     unless ($dispatcher) {
2555         $dispatcher = $class->dispatcher_class;
2556     }
2557
2558     Class::MOP::load_class($dispatcher);
2559
2560     # dispatcher instance
2561     $class->dispatcher( $dispatcher->new );
2562 }
2563
2564 =head2 $c->setup_engine
2565
2566 Sets up engine.
2567
2568 =cut
2569
2570 sub setup_engine {
2571     my ( $class, $engine ) = @_;
2572
2573     if ($engine) {
2574         $engine = 'Catalyst::Engine::' . $engine;
2575     }
2576
2577     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2578         $engine = 'Catalyst::Engine::' . $env;
2579     }
2580
2581     if ( $ENV{MOD_PERL} ) {
2582         my $meta = Class::MOP::get_metaclass_by_name($class);
2583
2584         # create the apache method
2585         $meta->add_method('apache' => sub { shift->engine->apache });
2586
2587         my ( $software, $version ) =
2588           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2589
2590         $version =~ s/_//g;
2591         $version =~ s/(\.[^.]+)\./$1/g;
2592
2593         if ( $software eq 'mod_perl' ) {
2594
2595             if ( !$engine ) {
2596
2597                 if ( $version >= 1.99922 ) {
2598                     $engine = 'Catalyst::Engine::Apache2::MP20';
2599                 }
2600
2601                 elsif ( $version >= 1.9901 ) {
2602                     $engine = 'Catalyst::Engine::Apache2::MP19';
2603                 }
2604
2605                 elsif ( $version >= 1.24 ) {
2606                     $engine = 'Catalyst::Engine::Apache::MP13';
2607                 }
2608
2609                 else {
2610                     Catalyst::Exception->throw( message =>
2611                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2612                 }
2613
2614             }
2615
2616             # install the correct mod_perl handler
2617             if ( $version >= 1.9901 ) {
2618                 *handler = sub  : method {
2619                     shift->handle_request(@_);
2620                 };
2621             }
2622             else {
2623                 *handler = sub ($$) { shift->handle_request(@_) };
2624             }
2625
2626         }
2627
2628         elsif ( $software eq 'Zeus-Perl' ) {
2629             $engine = 'Catalyst::Engine::Zeus';
2630         }
2631
2632         else {
2633             Catalyst::Exception->throw(
2634                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2635         }
2636     }
2637
2638     unless ($engine) {
2639         $engine = $class->engine_class;
2640     }
2641
2642     Class::MOP::load_class($engine);
2643
2644     # check for old engines that are no longer compatible
2645     my $old_engine;
2646     if ( $engine->isa('Catalyst::Engine::Apache')
2647         && !Catalyst::Engine::Apache->VERSION )
2648     {
2649         $old_engine = 1;
2650     }
2651
2652     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2653         && Catalyst::Engine::Server->VERSION le '0.02' )
2654     {
2655         $old_engine = 1;
2656     }
2657
2658     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2659         && $engine->VERSION eq '0.01' )
2660     {
2661         $old_engine = 1;
2662     }
2663
2664     elsif ($engine->isa('Catalyst::Engine::Zeus')
2665         && $engine->VERSION eq '0.01' )
2666     {
2667         $old_engine = 1;
2668     }
2669
2670     if ($old_engine) {
2671         Catalyst::Exception->throw( message =>
2672               qq/Engine "$engine" is not supported by this version of Catalyst/
2673         );
2674     }
2675
2676     # engine instance
2677     $class->engine( $engine->new );
2678 }
2679
2680 =head2 $c->setup_home
2681
2682 Sets up the home directory.
2683
2684 =cut
2685
2686 sub setup_home {
2687     my ( $class, $home ) = @_;
2688
2689     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2690         $home = $env;
2691     }
2692
2693     $home ||= Catalyst::Utils::home($class);
2694
2695     if ($home) {
2696         #I remember recently being scolded for assigning config values like this
2697         $class->config->{home} ||= $home;
2698         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2699     }
2700 }
2701
2702 =head2 $c->setup_log
2703
2704 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2705 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2706 log to.
2707
2708 This method also installs a C<debug> method that returns a true value into the
2709 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2710 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2711
2712 Note that if the log has already been setup, by either a previous call to
2713 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2714 that this method won't actually set up the log object.
2715
2716 =cut
2717
2718 sub setup_log {
2719     my ( $class, $levels ) = @_;
2720
2721     $levels ||= '';
2722     $levels =~ s/^\s+//;
2723     $levels =~ s/\s+$//;
2724     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2725
2726     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2727     if ( defined $env_debug ) {
2728         $levels{debug} = 1 if $env_debug; # Ugly!
2729         delete($levels{debug}) unless $env_debug;
2730     }
2731
2732     unless ( $class->log ) {
2733         $class->log( Catalyst::Log->new(keys %levels) );
2734     }
2735
2736     if ( $levels{debug} ) {
2737         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2738         $class->log->debug('Debug messages enabled');
2739     }
2740 }
2741
2742 =head2 $c->setup_plugins
2743
2744 Sets up plugins.
2745
2746 =cut
2747
2748 =head2 $c->setup_stats
2749
2750 Sets up timing statistics class.
2751
2752 =cut
2753
2754 sub setup_stats {
2755     my ( $class, $stats ) = @_;
2756
2757     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2758
2759     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2760     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2761         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2762         $class->log->debug('Statistics enabled');
2763     }
2764 }
2765
2766
2767 =head2 $c->registered_plugins
2768
2769 Returns a sorted list of the plugins which have either been stated in the
2770 import list or which have been added via C<< MyApp->plugin(@args); >>.
2771
2772 If passed a given plugin name, it will report a boolean value indicating
2773 whether or not that plugin is loaded.  A fully qualified name is required if
2774 the plugin name does not begin with C<Catalyst::Plugin::>.
2775
2776  if ($c->registered_plugins('Some::Plugin')) {
2777      ...
2778  }
2779
2780 =cut
2781
2782 {
2783
2784     sub registered_plugins {
2785         my $proto = shift;
2786         return sort keys %{ $proto->_plugins } unless @_;
2787         my $plugin = shift;
2788         return 1 if exists $proto->_plugins->{$plugin};
2789         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2790     }
2791
2792     sub _register_plugin {
2793         my ( $proto, $plugin, $instant ) = @_;
2794         my $class = ref $proto || $proto;
2795
2796         Class::MOP::load_class( $plugin );
2797         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2798             if $plugin->isa( 'Catalyst::Component' );
2799         $proto->_plugins->{$plugin} = 1;
2800         unless ($instant) {
2801             my $meta = Class::MOP::get_metaclass_by_name($class);
2802             $meta->superclasses($plugin, $meta->superclasses);
2803         }
2804         return $class;
2805     }
2806
2807     sub setup_plugins {
2808         my ( $class, $plugins ) = @_;
2809
2810         $class->_plugins( {} ) unless $class->_plugins;
2811         $plugins = Data::OptList::mkopt($plugins || []);
2812
2813         my @plugins = map {
2814             [ Catalyst::Utils::resolve_namespace(
2815                   $class . '::Plugin',
2816                   'Catalyst::Plugin', $_->[0]
2817               ),
2818               $_->[1],
2819             ]
2820          } @{ $plugins };
2821
2822         for my $plugin ( reverse @plugins ) {
2823             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2824             my $meta = find_meta($plugin->[0]);
2825             next if $meta && $meta->isa('Moose::Meta::Role');
2826
2827             $class->_register_plugin($plugin->[0]);
2828         }
2829
2830         my @roles =
2831             map  { $_->[0]->name, $_->[1] }
2832             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2833             map  { [find_meta($_->[0]), $_->[1]] }
2834             @plugins;
2835
2836         Moose::Util::apply_all_roles(
2837             $class => @roles
2838         ) if @roles;
2839     }
2840 }
2841
2842 =head2 $c->stack
2843
2844 Returns an arrayref of the internal execution stack (actions that are
2845 currently executing).
2846
2847 =head2 $c->stats
2848
2849 Returns the current timing statistics object. By default Catalyst uses
2850 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2851 L<< stats_class|/"$c->stats_class" >>.
2852
2853 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2854 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2855 profile explicitly, although MyApp.pm still won't profile nor output anything
2856 by itself.
2857
2858 =head2 $c->stats_class
2859
2860 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2861
2862 =head2 $c->use_stats
2863
2864 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2865
2866 Note that this is a static method, not an accessor and should be overridden
2867 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2868
2869 =cut
2870
2871 sub use_stats { 0 }
2872
2873
2874 =head2 $c->write( $data )
2875
2876 Writes $data to the output stream. When using this method directly, you
2877 will need to manually set the C<Content-Length> header to the length of
2878 your output data, if known.
2879
2880 =cut
2881
2882 sub write {
2883     my $c = shift;
2884
2885     # Finalize headers if someone manually writes output
2886     $c->finalize_headers;
2887
2888     return $c->engine->write( $c, @_ );
2889 }
2890
2891 =head2 version
2892
2893 Returns the Catalyst version number. Mostly useful for "powered by"
2894 messages in template systems.
2895
2896 =cut
2897
2898 sub version { return $Catalyst::VERSION }
2899
2900 =head1 CONFIGURATION
2901
2902 There are a number of 'base' config variables which can be set:
2903
2904 =over
2905
2906 =item *
2907
2908 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2909
2910 =item *
2911
2912 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2913
2914 =item *
2915
2916 C<disable_component_resolution_regex_fallback> - Turns
2917 off the deprecated component resolution functionality so
2918 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2919 are called then regex search will not be attempted on string values and
2920 instead C<undef> will be returned.
2921
2922 =item *
2923
2924 C<home> - The application home directory. In an uninstalled application,
2925 this is the top level application directory. In an installed application,
2926 this will be the directory containing C<< MyApp.pm >>.
2927
2928 =item *
2929
2930 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2931
2932 =item *
2933
2934 C<name> - The name of the application in debug messages and the debug and
2935 welcome screens
2936
2937 =item *
2938
2939 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2940 until it is accessed. This allows you to (for example) check authentication (and reject
2941 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2942
2943 =item *
2944
2945 C<root> - The root directory for templates. Usually this is just a
2946 subdirectory of the home directory, but you can set it to change the
2947 templates to a different directory.
2948
2949 =item *
2950
2951 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2952 namespaces from which components will be loaded (and constructed and stored in
2953 C<< $c->components >>).
2954
2955 =item *
2956
2957 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2958 to be shown in hit debug tables in the test server.
2959
2960 =item *
2961
2962 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
2963 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
2964 for more information.
2965
2966 =item *
2967
2968 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2969
2970 =back
2971
2972 =head1 INTERNAL ACTIONS
2973
2974 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2975 C<_ACTION>, and C<_END>. These are by default not shown in the private
2976 action table, but you can make them visible with a config parameter.
2977
2978     MyApp->config(show_internal_actions => 1);
2979
2980 =head1 ON-DEMAND PARSER
2981
2982 The request body is usually parsed at the beginning of a request,
2983 but if you want to handle input yourself, you can enable on-demand
2984 parsing with a config parameter.
2985
2986     MyApp->config(parse_on_demand => 1);
2987
2988 =head1 PROXY SUPPORT
2989
2990 Many production servers operate using the common double-server approach,
2991 with a lightweight frontend web server passing requests to a larger
2992 backend server. An application running on the backend server must deal
2993 with two problems: the remote user always appears to be C<127.0.0.1> and
2994 the server's hostname will appear to be C<localhost> regardless of the
2995 virtual host that the user connected through.
2996
2997 Catalyst will automatically detect this situation when you are running
2998 the frontend and backend servers on the same machine. The following
2999 changes are made to the request.
3000
3001     $c->req->address is set to the user's real IP address, as read from
3002     the HTTP X-Forwarded-For header.
3003
3004     The host value for $c->req->base and $c->req->uri is set to the real
3005     host, as read from the HTTP X-Forwarded-Host header.
3006
3007 Additionally, you may be running your backend application on an insecure
3008 connection (port 80) while your frontend proxy is running under SSL.  If there
3009 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3010 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3011 be created properly.
3012
3013 In the case of passing in:
3014
3015     X-Forwarded-Port: 443
3016
3017 All calls to C<uri_for> will result in an https link, as is expected.
3018
3019 Obviously, your web server must support these headers for this to work.
3020
3021 In a more complex server farm environment where you may have your
3022 frontend proxy server(s) on different machines, you will need to set a
3023 configuration option to tell Catalyst to read the proxied data from the
3024 headers.
3025
3026     MyApp->config(using_frontend_proxy => 1);
3027
3028 If you do not wish to use the proxy support at all, you may set:
3029
3030     MyApp->config(ignore_frontend_proxy => 1);
3031
3032 =head1 THREAD SAFETY
3033
3034 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3035 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3036 believe the Catalyst core to be thread-safe.
3037
3038 If you plan to operate in a threaded environment, remember that all other
3039 modules you are using must also be thread-safe. Some modules, most notably
3040 L<DBD::SQLite>, are not thread-safe.
3041
3042 =head1 SUPPORT
3043
3044 IRC:
3045
3046     Join #catalyst on irc.perl.org.
3047
3048 Mailing Lists:
3049
3050     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3051     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3052
3053 Web:
3054
3055     http://catalyst.perl.org
3056
3057 Wiki:
3058
3059     http://dev.catalyst.perl.org
3060
3061 =head1 SEE ALSO
3062
3063 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3064
3065 =head2 L<Catalyst::Manual> - The Catalyst Manual
3066
3067 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3068
3069 =head2 L<Catalyst::Engine> - Core engine
3070
3071 =head2 L<Catalyst::Log> - Log class.
3072
3073 =head2 L<Catalyst::Request> - Request object
3074
3075 =head2 L<Catalyst::Response> - Response object
3076
3077 =head2 L<Catalyst::Test> - The test suite.
3078
3079 =head1 PROJECT FOUNDER
3080
3081 sri: Sebastian Riedel <sri@cpan.org>
3082
3083 =head1 CONTRIBUTORS
3084
3085 abw: Andy Wardley
3086
3087 acme: Leon Brocard <leon@astray.com>
3088
3089 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3090
3091 Andrew Bramble
3092
3093 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3094
3095 Andrew Ruthven
3096
3097 andyg: Andy Grundman <andy@hybridized.org>
3098
3099 audreyt: Audrey Tang
3100
3101 bricas: Brian Cassidy <bricas@cpan.org>
3102
3103 Caelum: Rafael Kitover <rkitover@io.com>
3104
3105 chansen: Christian Hansen
3106
3107 chicks: Christopher Hicks
3108
3109 Chisel Wright C<pause@herlpacker.co.uk>
3110
3111 Danijel Milicevic C<me@danijel.de>
3112
3113 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3114
3115 David Naughton, C<naughton@umn.edu>
3116
3117 David E. Wheeler
3118
3119 dhoss: Devin Austin <dhoss@cpan.org>
3120
3121 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3122
3123 Drew Taylor
3124
3125 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3126
3127 esskar: Sascha Kiefer
3128
3129 fireartist: Carl Franks <cfranks@cpan.org>
3130
3131 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3132
3133 gabb: Danijel Milicevic
3134
3135 Gary Ashton Jones
3136
3137 Gavin Henry C<ghenry@perl.me.uk>
3138
3139 Geoff Richards
3140
3141 groditi: Guillermo Roditi <groditi@gmail.com>
3142
3143 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3144
3145 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3146
3147 jcamacho: Juan Camacho
3148
3149 jester: Jesse Sheidlower C<jester@panix.com>
3150
3151 jhannah: Jay Hannah <jay@jays.net>
3152
3153 Jody Belka
3154
3155 Johan Lindstrom
3156
3157 jon: Jon Schutz <jjschutz@cpan.org>
3158
3159 Jonathan Rockway C<< <jrockway@cpan.org> >>
3160
3161 Kieren Diment C<kd@totaldatasolution.com>
3162
3163 konobi: Scott McWhirter <konobi@cpan.org>
3164
3165 marcus: Marcus Ramberg <mramberg@cpan.org>
3166
3167 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3168
3169 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3170
3171 mugwump: Sam Vilain
3172
3173 naughton: David Naughton
3174
3175 ningu: David Kamholz <dkamholz@cpan.org>
3176
3177 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3178
3179 numa: Dan Sully <daniel@cpan.org>
3180
3181 obra: Jesse Vincent
3182
3183 Octavian Rasnita
3184
3185 omega: Andreas Marienborg
3186
3187 Oleg Kostyuk <cub.uanic@gmail.com>
3188
3189 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3190
3191 rafl: Florian Ragwitz <rafl@debian.org>
3192
3193 random: Roland Lammel <lammel@cpan.org>
3194
3195 Robert Sedlacek C<< <rs@474.at> >>
3196
3197 SpiceMan: Marcel Montes
3198
3199 sky: Arthur Bergman
3200
3201 szbalint: Balint Szilakszi <szbalint@cpan.org>
3202
3203 t0m: Tomas Doran <bobtfish@bobtfish.net>
3204
3205 Ulf Edvinsson
3206
3207 Viljo Marrandi C<vilts@yahoo.com>
3208
3209 Will Hawes C<info@whawes.co.uk>
3210
3211 willert: Sebastian Willert <willert@cpan.org>
3212
3213 wreis: Wallace Reis <wallace@reis.org.br>
3214
3215 Yuval Kogman, C<nothingmuch@woobling.org>
3216
3217 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3218
3219 =head1 LICENSE
3220
3221 This library is free software. You can redistribute it and/or modify it under
3222 the same terms as Perl itself.
3223
3224 =cut
3225
3226 no Moose;
3227
3228 __PACKAGE__->meta->make_immutable;
3229
3230 1;