lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use bytes;
   6 use Scope::Upper ();
   7 use Catalyst::Exception;
   8 use Catalyst::Log;
   9 use Catalyst::Request;
  10 use Catalyst::Request::Upload;
  11 use Catalyst::Response;
  12 use Catalyst::Utils;
  13 use Catalyst::Controller;
  14 use Devel::InnerPackage ();
  15 use File::stat;
  16 use Module::Pluggable::Object ();
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use URI ();
  21 use URI::http;
  22 use URI::https;
  23 use Tree::Simple qw/use_weak_refs/;
  24 use Tree::Simple::Visitor::FindByUID;
  25 use Class::C3::Adopt::NEXT;
  26 use attributes;
  27 use utf8;
  28 use Carp qw/croak carp shortmess/;
  29
  30 BEGIN { require 5.008001; }
  31
  32 has stack => (is => 'ro', default => sub { [] });
  33 has stash => (is => 'rw', default => sub { {} });
  34 has state => (is => 'rw', default => 0);
  35 has stats => (is => 'rw');
  36 has action => (is => 'rw');
  37 has counter => (is => 'rw', default => sub { {} });
  38 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  39 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  40 has namespace => (is => 'rw');
  41
  42 sub depth { scalar @{ shift->stack || [] }; }
  43 sub comp { shift->component(@_) }
  44
  45 sub req {
  46     # carp "the use of req() is deprecated in favour of request()";
  47     my $self = shift; return $self->request(@_);
  48 }
  49 sub res {
  50     # carp "the use of res() is deprecated in favour of response()";
  51     my $self = shift; return $self->response(@_);
  52 }
  53
  54 # For backwards compatibility
  55 sub finalize_output { shift->finalize_body(@_) };
  56
  57 # For statistics
  58 our $COUNT     = 1;
  59 our $START     = time;
  60 our $RECURSION = 1000;
  61 our $DETACH    = "catalyst_detach\n";
  62 our $GO        = "catalyst_go\n";
  63
  64 #I imagine that very few of these really need to be class variables. if any.
  65 #maybe we should just make them attributes with a default?
  66 __PACKAGE__->mk_classdata($_)
  67   for qw/components arguments dispatcher engine log dispatcher_class
  68   engine_class context_class request_class response_class stats_class
  69   setup_finished/;
  70
  71 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  72 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  73 __PACKAGE__->request_class('Catalyst::Request');
  74 __PACKAGE__->response_class('Catalyst::Response');
  75 __PACKAGE__->stats_class('Catalyst::Stats');
  76
  77 # Remember to update this in Catalyst::Runtime as well!
  78
  79 our $VERSION = '5.8000_06';
  80
  81 {
  82     my $dev_version = $VERSION =~ /_\d{2}$/;
  83     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  84 }
  85
  86 $VERSION = eval $VERSION;
  87
  88 sub import {
  89     my ( $class, @arguments ) = @_;
  90
  91     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  92     # callers @ISA.
  93     return unless $class eq 'Catalyst';
  94
  95     my $caller = caller();
  96     return if $caller eq 'main';
  97
  98     # Kill Adopt::NEXT warnings if we're a non-RC version
  99     unless (_IS_DEVELOPMENT_VERSION()) {
 100         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 101     }
 102
 103     my $meta = Moose::Meta::Class->initialize($caller);
 104     #Moose->import({ into => $caller }); #do we want to do this?
 105
 106     unless ( $caller->isa('Catalyst') ) {
 107         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 108         $meta->superclasses(@superclasses);
 109     }
 110     unless( $meta->has_method('meta') ){
 111         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 112     }
 113
 114     $caller->arguments( [@arguments] );
 115     $caller->setup_home;
 116 }
 117
 118 =head1 NAME
 119
 120 Catalyst - The Elegant MVC Web Application Framework
 121
 122 =head1 SYNOPSIS
 123
 124 See the L<Catalyst::Manual> distribution for comprehensive
 125 documentation and tutorials.
 126
 127     # Install Catalyst::Devel for helpers and other development tools
 128     # use the helper to create a new application
 129     catalyst.pl MyApp
 130
 131     # add models, views, controllers
 132     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 133     script/myapp_create.pl view MyTemplate TT
 134     script/myapp_create.pl controller Search
 135
 136     # built in testserver -- use -r to restart automatically on changes
 137     # --help to see all available options
 138     script/myapp_server.pl
 139
 140     # command line testing interface
 141     script/myapp_test.pl /yada
 142
 143     ### in lib/MyApp.pm
 144     use Catalyst qw/-Debug/; # include plugins here as well
 145
 146     ### In lib/MyApp/Controller/Root.pm (autocreated)
 147     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 148         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 149         $c->stash->{template} = 'foo.tt'; # set the template
 150         # lookup something from db -- stash vars are passed to TT
 151         $c->stash->{data} =
 152           $c->model('Database::Foo')->search( { country => $args[0] } );
 153         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 154             $c->forward( 'bar' ); # process another action
 155             # do something else after forward returns
 156         }
 157     }
 158
 159     # The foo.tt TT template can use the stash data from the database
 160     [% WHILE (item = data.next) %]
 161         [% item.foo %]
 162     [% END %]
 163
 164     # called for /bar/of/soap, /bar/of/soap/10, etc.
 165     sub bar : Path('/bar/of/soap') { ... }
 166
 167     # called for all actions, from the top-most controller downwards
 168     sub auto : Private {
 169         my ( $self, $c ) = @_;
 170         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 171             $c->res->redirect( '/login' ); # require login
 172             return 0; # abort request and go immediately to end()
 173         }
 174         return 1; # success; carry on to next action
 175     }
 176
 177     # called after all actions are finished
 178     sub end : Private {
 179         my ( $self, $c ) = @_;
 180         if ( scalar @{ $c->error } ) { ... } # handle errors
 181         return if $c->res->body; # already have a response
 182         $c->forward( 'MyApp::View::TT' ); # render template
 183     }
 184
 185     ### in MyApp/Controller/Foo.pm
 186     # called for /foo/bar
 187     sub bar : Local { ... }
 188
 189     # called for /blargle
 190     sub blargle : Global { ... }
 191
 192     # an index action matches /foo, but not /foo/1, etc.
 193     sub index : Private { ... }
 194
 195     ### in MyApp/Controller/Foo/Bar.pm
 196     # called for /foo/bar/baz
 197     sub baz : Local { ... }
 198
 199     # first Root auto is called, then Foo auto, then this
 200     sub auto : Private { ... }
 201
 202     # powerful regular expression paths are also possible
 203     sub details : Regex('^product/(\w+)/details$') {
 204         my ( $self, $c ) = @_;
 205         # extract the (\w+) from the URI
 206         my $product = $c->req->captures->[0];
 207     }
 208
 209 See L<Catalyst::Manual::Intro> for additional information.
 210
 211 =head1 DESCRIPTION
 212
 213 Catalyst is a modern framework for making web applications without the
 214 pain usually associated with this process. This document is a reference
 215 to the main Catalyst application. If you are a new user, we suggest you
 216 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 217
 218 See L<Catalyst::Manual> for more documentation.
 219
 220 Catalyst plugins can be loaded by naming them as arguments to the "use
 221 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 222 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 223 C<My::Module>.
 224
 225     use Catalyst qw/My::Module/;
 226
 227 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 228 fully qualify the name by using a unary plus:
 229
 230     use Catalyst qw/
 231         My::Module
 232         +Fully::Qualified::Plugin::Name
 233     /;
 234
 235 Special flags like C<-Debug> and C<-Engine> can also be specified as
 236 arguments when Catalyst is loaded:
 237
 238     use Catalyst qw/-Debug My::Module/;
 239
 240 The position of plugins and flags in the chain is important, because
 241 they are loaded in the order in which they appear.
 242
 243 The following flags are supported:
 244
 245 =head2 -Debug
 246
 247 Enables debug output. You can also force this setting from the system
 248 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 249 settings override the application, with <MYAPP>_DEBUG having the highest
 250 priority.
 251
 252 =head2 -Engine
 253
 254 Forces Catalyst to use a specific engine. Omit the
 255 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 256
 257     use Catalyst qw/-Engine=CGI/;
 258
 259 =head2 -Home
 260
 261 Forces Catalyst to use a specific home directory, e.g.:
 262
 263     use Catalyst qw[-Home=/usr/mst];
 264
 265 This can also be done in the shell environment by setting either the
 266 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 267 is replaced with the uppercased name of your application, any "::" in
 268 the name will be replaced with underscores, e.g. MyApp::Web should use
 269 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 270
 271 =head2 -Log
 272
 273     use Catalyst '-Log=warn,fatal,error';
 274
 275 Specifies a comma-delimited list of log levels.
 276
 277 =head2 -Stats
 278
 279 Enables statistics collection and reporting. You can also force this setting
 280 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 281 environment settings override the application, with <MYAPP>_STATS having the
 282 highest priority.
 283
 284 e.g.
 285
 286    use Catalyst qw/-Stats=1/
 287
 288 =head1 METHODS
 289
 290 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 291
 292 =head2 $c->action
 293
 294 Returns a L<Catalyst::Action> object for the current action, which
 295 stringifies to the action name. See L<Catalyst::Action>.
 296
 297 =head2 $c->namespace
 298
 299 Returns the namespace of the current action, i.e., the URI prefix
 300 corresponding to the controller of the current action. For example:
 301
 302     # in Controller::Foo::Bar
 303     $c->namespace; # returns 'foo/bar';
 304
 305 =head2 $c->request
 306
 307 =head2 $c->req
 308
 309 Returns the current L<Catalyst::Request> object, giving access to
 310 information about the current client request (including parameters,
 311 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 312
 313 =head2 REQUEST FLOW HANDLING
 314
 315 =head2 $c->forward( $action [, \@arguments ] )
 316
 317 =head2 $c->forward( $class, $method, [, \@arguments ] )
 318
 319 Forwards processing to another action, by its private name. If you give a
 320 class name but no method, C<process()> is called. You may also optionally
 321 pass arguments in an arrayref. The action will receive the arguments in
 322 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 323 C<< $c->req->args >> will be restored to the previous values.
 324
 325 Any data C<return>ed from the action forwarded to, will be returned by the
 326 call to forward.
 327
 328     my $foodata = $c->forward('/foo');
 329     $c->forward('index');
 330     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 331     $c->forward('MyApp::View::TT');
 332
 333 Note that forward implies an C<<eval { }>> around the call (actually
 334 C<execute> does), thus de-fatalizing all 'dies' within the called
 335 action. If you want C<die> to propagate you need to do something like:
 336
 337     $c->forward('foo');
 338     die $c->error if $c->error;
 339
 340 Or make sure to always return true values from your actions and write
 341 your code like this:
 342
 343     $c->forward('foo') || return;
 344
 345 =cut
 346
 347 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 348
 349 =head2 $c->detach( $action [, \@arguments ] )
 350
 351 =head2 $c->detach( $class, $method, [, \@arguments ] )
 352
 353 =head2 $c->detach()
 354
 355 The same as C<forward>, but doesn't return to the previous action when
 356 processing is finished.
 357
 358 When called with no arguments it escapes the processing chain entirely.
 359
 360 =cut
 361
 362 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 363
 364 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 365
 366 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 367
 368 Almost the same as C<forward>, but does a full dispatch, instead of just
 369 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 370 C<auto> and the method you go to are called, just like a new request.
 371
 372 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 373 This means, for example, that $c->action methods such as C<name>, C<class> and
 374 C<reverse> return information for the visited action when they are invoked
 375 within the visited action.  This is different from the behavior of C<forward>
 376 which continues to use the $c->action object from the caller action even when
 377 invoked from the callee.
 378
 379 C<$c-E<gt>stash> is kept unchanged.
 380
 381 In effect, C<visit> allows you to "wrap" another action, just as it
 382 would have been called by dispatching from a URL, while the analogous
 383 C<go> allows you to transfer control to another action as if it had
 384 been reached directly from a URL.
 385
 386 =cut
 387
 388 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 389
 390 =head2 $c->go( $action [, \@captures, \@arguments ] )
 391
 392 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 393
 394 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 395 instead of just calling the new C<$action> /
 396 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 397 method you visit are called, just like a new request.
 398
 399 C<$c-E<gt>stash> is kept unchanged.
 400
 401 =cut
 402
 403 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 404
 405 =head2 $c->response
 406
 407 =head2 $c->res
 408
 409 Returns the current L<Catalyst::Response> object, see there for details.
 410
 411 =head2 $c->stash
 412
 413 Returns a hashref to the stash, which may be used to store data and pass
 414 it between components during a request. You can also set hash keys by
 415 passing arguments. The stash is automatically sent to the view. The
 416 stash is cleared at the end of a request; it cannot be used for
 417 persistent storage (for this you must use a session; see
 418 L<Catalyst::Plugin::Session> for a complete system integrated with
 419 Catalyst).
 420
 421     $c->stash->{foo} = $bar;
 422     $c->stash( { moose => 'majestic', qux => 0 } );
 423     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 424
 425     # stash is automatically passed to the view for use in a template
 426     $c->forward( 'MyApp::View::TT' );
 427
 428 =cut
 429
 430 around stash => sub {
 431     my $orig = shift;
 432     my $c = shift;
 433     my $stash = $orig->($c);
 434     if (@_) {
 435         my $new_stash = @_ > 1 ? {@_} : $_[0];
 436         croak('stash takes a hash or hashref') unless ref $new_stash;
 437         foreach my $key ( keys %$new_stash ) {
 438           $stash->{$key} = $new_stash->{$key};
 439         }
 440     }
 441
 442     return $stash;
 443 };
 444
 445
 446 =head2 $c->error
 447
 448 =head2 $c->error($error, ...)
 449
 450 =head2 $c->error($arrayref)
 451
 452 Returns an arrayref containing error messages.  If Catalyst encounters an
 453 error while processing a request, it stores the error in $c->error.  This
 454 method should only be used to store fatal error messages.
 455
 456     my @error = @{ $c->error };
 457
 458 Add a new error.
 459
 460     $c->error('Something bad happened');
 461
 462 =cut
 463
 464 sub error {
 465     my $c = shift;
 466     if ( $_[0] ) {
 467         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 468         croak @$error unless ref $c;
 469         push @{ $c->{error} }, @$error;
 470     }
 471     elsif ( defined $_[0] ) { $c->{error} = undef }
 472     return $c->{error} || [];
 473 }
 474
 475
 476 =head2 $c->state
 477
 478 Contains the return value of the last executed action.
 479
 480 =head2 $c->clear_errors
 481
 482 Clear errors.  You probably don't want to clear the errors unless you are
 483 implementing a custom error screen.
 484
 485 This is equivalent to running
 486
 487     $c->error(0);
 488
 489 =cut
 490
 491 sub clear_errors {
 492     my $c = shift;
 493     $c->error(0);
 494 }
 495
 496 # search components given a name and some prefixes
 497 sub _comp_search_prefixes {
 498     my ( $c, $name, @prefixes ) = @_;
 499     my $appclass = ref $c || $c;
 500     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 501     $filter = qr/$filter/; # Compile regex now rather than once per loop
 502
 503     # map the original component name to the sub part that we will search against
 504     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 505         grep { /$filter/ } keys %{ $c->components };
 506
 507     # undef for a name will return all
 508     return keys %eligible if !defined $name;
 509
 510     my $query  = ref $name ? $name : qr/^$name$/i;
 511     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 512
 513     return map { $c->components->{ $_ } } @result if @result;
 514
 515     # if we were given a regexp to search against, we're done.
 516     return if ref $name;
 517
 518     # regexp fallback
 519     $query  = qr/$name/i;
 520     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 521
 522     # no results? try against full names
 523     if( !@result ) {
 524         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 525     }
 526
 527     # don't warn if we didn't find any results, it just might not exist
 528     if( @result ) {
 529         # Disgusting hack to work out correct method name
 530         my $warn_for = lc $prefixes[0];
 531         my $msg = "Used regexp fallback for \$c->{$warn_for}('${name}'), which found '" .
 532            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 533            "component resolution is unreliable and unsafe.";
 534         my $short = $result[0];
 535         $short =~ s/.*?Model:://;
 536         my $shortmess = Carp::shortmess('');
 537         if ($shortmess =~ m#Catalyst/Plugin#) {
 538            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 539               "plugin's config";
 540         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 541            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 542               "component's config";
 543         } else {
 544            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 545               "but if you really wanted to search, pass in a regexp as the argument " .
 546               "like so: \$c->${warn_for}(qr/${name}/)";
 547         }
 548         $c->log->warn( "${msg}$shortmess" );
 549     }
 550
 551     return @result;
 552 }
 553
 554 # Find possible names for a prefix
 555 sub _comp_names {
 556     my ( $c, @prefixes ) = @_;
 557     my $appclass = ref $c || $c;
 558
 559     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 560
 561     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 562     return @names;
 563 }
 564
 565 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 566 sub _filter_component {
 567     my ( $c, $comp, @args ) = @_;
 568
 569     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 570         return $comp->ACCEPT_CONTEXT( $c, @args );
 571     }
 572
 573     return $comp;
 574 }
 575
 576 =head2 COMPONENT ACCESSORS
 577
 578 =head2 $c->controller($name)
 579
 580 Gets a L<Catalyst::Controller> instance by name.
 581
 582     $c->controller('Foo')->do_stuff;
 583
 584 If the name is omitted, will return the controller for the dispatched
 585 action.
 586
 587 If you want to search for controllers, pass in a regexp as the argument.
 588
 589     # find all controllers that start with Foo
 590     my @foo_controllers = $c->controller(qr{^Foo});
 591
 592
 593 =cut
 594
 595 sub controller {
 596     my ( $c, $name, @args ) = @_;
 597
 598     if( $name ) {
 599         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 600         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 601         return $c->_filter_component( $result[ 0 ], @args );
 602     }
 603
 604     return $c->component( $c->action->class );
 605 }
 606
 607 =head2 $c->model($name)
 608
 609 Gets a L<Catalyst::Model> instance by name.
 610
 611     $c->model('Foo')->do_stuff;
 612
 613 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 614
 615 If the name is omitted, it will look for
 616  - a model object in $c->stash->{current_model_instance}, then
 617  - a model name in $c->stash->{current_model}, then
 618  - a config setting 'default_model', or
 619  - check if there is only one model, and return it if that's the case.
 620
 621 If you want to search for models, pass in a regexp as the argument.
 622
 623     # find all models that start with Foo
 624     my @foo_models = $c->model(qr{^Foo});
 625
 626 =cut
 627
 628 sub model {
 629     my ( $c, $name, @args ) = @_;
 630
 631     if( $name ) {
 632         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 633         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 634         return $c->_filter_component( $result[ 0 ], @args );
 635     }
 636
 637     if (ref $c) {
 638         return $c->stash->{current_model_instance}
 639           if $c->stash->{current_model_instance};
 640         return $c->model( $c->stash->{current_model} )
 641           if $c->stash->{current_model};
 642     }
 643     return $c->model( $c->config->{default_model} )
 644       if $c->config->{default_model};
 645
 646     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 647
 648     if( $rest ) {
 649         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 650         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 651         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 652         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 653         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 654     }
 655
 656     return $c->_filter_component( $comp );
 657 }
 658
 659
 660 =head2 $c->view($name)
 661
 662 Gets a L<Catalyst::View> instance by name.
 663
 664     $c->view('Foo')->do_stuff;
 665
 666 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 667
 668 If the name is omitted, it will look for
 669  - a view object in $c->stash->{current_view_instance}, then
 670  - a view name in $c->stash->{current_view}, then
 671  - a config setting 'default_view', or
 672  - check if there is only one view, and return it if that's the case.
 673
 674 If you want to search for views, pass in a regexp as the argument.
 675
 676     # find all views that start with Foo
 677     my @foo_views = $c->view(qr{^Foo});
 678
 679 =cut
 680
 681 sub view {
 682     my ( $c, $name, @args ) = @_;
 683
 684     if( $name ) {
 685         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 686         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 687         return $c->_filter_component( $result[ 0 ], @args );
 688     }
 689
 690     if (ref $c) {
 691         return $c->stash->{current_view_instance}
 692           if $c->stash->{current_view_instance};
 693         return $c->view( $c->stash->{current_view} )
 694           if $c->stash->{current_view};
 695     }
 696     return $c->view( $c->config->{default_view} )
 697       if $c->config->{default_view};
 698
 699     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 700
 701     if( $rest ) {
 702         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 703         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 704         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 705         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 706         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 707     }
 708
 709     return $c->_filter_component( $comp );
 710 }
 711
 712 =head2 $c->controllers
 713
 714 Returns the available names which can be passed to $c->controller
 715
 716 =cut
 717
 718 sub controllers {
 719     my ( $c ) = @_;
 720     return $c->_comp_names(qw/Controller C/);
 721 }
 722
 723 =head2 $c->models
 724
 725 Returns the available names which can be passed to $c->model
 726
 727 =cut
 728
 729 sub models {
 730     my ( $c ) = @_;
 731     return $c->_comp_names(qw/Model M/);
 732 }
 733
 734
 735 =head2 $c->views
 736
 737 Returns the available names which can be passed to $c->view
 738
 739 =cut
 740
 741 sub views {
 742     my ( $c ) = @_;
 743     return $c->_comp_names(qw/View V/);
 744 }
 745
 746 =head2 $c->comp($name)
 747
 748 =head2 $c->component($name)
 749
 750 Gets a component object by name. This method is not recommended,
 751 unless you want to get a specific component by full
 752 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 753 should be used instead.
 754
 755 If C<$name> is a regexp, a list of components matched against the full
 756 component name will be returned.
 757
 758 =cut
 759
 760 sub component {
 761     my ( $c, $name, @args ) = @_;
 762
 763     if( $name ) {
 764         my $comps = $c->components;
 765
 766         if( !ref $name ) {
 767             # is it the exact name?
 768             return $c->_filter_component( $comps->{ $name }, @args )
 769                        if exists $comps->{ $name };
 770
 771             # perhaps we just omitted "MyApp"?
 772             my $composed = ( ref $c || $c ) . "::${name}";
 773             return $c->_filter_component( $comps->{ $composed }, @args )
 774                        if exists $comps->{ $composed };
 775
 776             # search all of the models, views and controllers
 777             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 778             return $c->_filter_component( $comp, @args ) if $comp;
 779         }
 780
 781         # This is here so $c->comp( '::M::' ) works
 782         my $query = ref $name ? $name : qr{$name}i;
 783
 784         my @result = grep { m{$query} } keys %{ $c->components };
 785         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 786
 787         if( $result[ 0 ] ) {
 788             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 789             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 790             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 791             return $c->_filter_component( $result[ 0 ], @args );
 792         }
 793
 794         # I would expect to return an empty list here, but that breaks back-compat
 795     }
 796
 797     # fallback
 798     return sort keys %{ $c->components };
 799 }
 800
 801 =head2 CLASS DATA AND HELPER CLASSES
 802
 803 =head2 $c->config
 804
 805 Returns or takes a hashref containing the application's configuration.
 806
 807     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 808
 809 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 810 like myapp.conf in your applications home directory. See
 811 L<Catalyst::Plugin::ConfigLoader>.
 812
 813 =head3 Cascading configuration.
 814
 815 The config method is present on all Catalyst components, and configuration
 816 will be merged when an application is started. Configuration loaded with
 817 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 818 followed by configuration in your top level C<MyApp> class. These two
 819 configurations are merged, and then configuration data whos hash key matches a
 820 component name is merged with configuration for that component.
 821
 822 The configuration for a component is then passed to the C<new> method when a
 823 component is constructed.
 824
 825 For example:
 826
 827     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 828     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 829
 830 will mean that C<MyApp::Model::Foo> receives the following data when
 831 constructed:
 832
 833     MyApp::Model::Foo->new({
 834         bar => 'baz',
 835         quux => 'frob',
 836         overrides => 'me',
 837     });
 838
 839 =cut
 840
 841 around config => sub {
 842     my $orig = shift;
 843     my $c = shift;
 844
 845     croak('Setting config after setup has been run is not allowed.')
 846         if ( @_ and $c->setup_finished );
 847
 848     $c->$orig(@_);
 849 };
 850
 851 =head2 $c->log
 852
 853 Returns the logging object instance. Unless it is already set, Catalyst
 854 sets this up with a L<Catalyst::Log> object. To use your own log class,
 855 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 856 C<< __PACKAGE__->setup >>.
 857
 858  __PACKAGE__->log( MyLogger->new );
 859  __PACKAGE__->setup;
 860
 861 And later:
 862
 863     $c->log->info( 'Now logging with my own logger!' );
 864
 865 Your log class should implement the methods described in
 866 L<Catalyst::Log>.
 867
 868
 869 =head2 $c->debug
 870
 871 Returns 1 if debug mode is enabled, 0 otherwise.
 872
 873 You can enable debug mode in several ways:
 874
 875 =over
 876
 877 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 878
 879 =item The -Debug option in your MyApp.pm
 880
 881 =item By declaring "sub debug { 1 }" in your MyApp.pm.
 882
 883 =back
 884
 885 Calling $c->debug(1) has no effect.
 886
 887 =cut
 888
 889 sub debug { 0 }
 890
 891 =head2 $c->dispatcher
 892
 893 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 894
 895 =head2 $c->engine
 896
 897 Returns the engine instance. See L<Catalyst::Engine>.
 898
 899
 900 =head2 UTILITY METHODS
 901
 902 =head2 $c->path_to(@path)
 903
 904 Merges C<@path> with C<< $c->config->{home} >> and returns a
 905 L<Path::Class::Dir> object.
 906
 907 For example:
 908
 909     $c->path_to( 'db', 'sqlite.db' );
 910
 911 =cut
 912
 913 sub path_to {
 914     my ( $c, @path ) = @_;
 915     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 916     if ( -d $path ) { return $path }
 917     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 918 }
 919
 920 =head2 $c->plugin( $name, $class, @args )
 921
 922 Helper method for plugins. It creates a class data accessor/mutator and
 923 loads and instantiates the given class.
 924
 925     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 926
 927     $c->prototype->define_javascript_functions;
 928
 929 B<Note:> This method of adding plugins is deprecated. The ability
 930 to add plugins like this B<will be removed> in a Catalyst 5.9.
 931 Please do not use this functionality in new code.
 932
 933 =cut
 934
 935 sub plugin {
 936     my ( $class, $name, $plugin, @args ) = @_;
 937
 938     # See block comment in t/unit_core_plugin.t
 939     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 940
 941     $class->_register_plugin( $plugin, 1 );
 942
 943     eval { $plugin->import };
 944     $class->mk_classdata($name);
 945     my $obj;
 946     eval { $obj = $plugin->new(@args) };
 947
 948     if ($@) {
 949         Catalyst::Exception->throw( message =>
 950               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 951     }
 952
 953     $class->$name($obj);
 954     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 955       if $class->debug;
 956 }
 957
 958 =head2 MyApp->setup
 959
 960 Initializes the dispatcher and engine, loads any plugins, and loads the
 961 model, view, and controller components. You may also specify an array
 962 of plugins to load here, if you choose to not load them in the C<use
 963 Catalyst> line.
 964
 965     MyApp->setup;
 966     MyApp->setup( qw/-Debug/ );
 967
 968 =cut
 969
 970 sub setup {
 971     my ( $class, @arguments ) = @_;
 972     croak('Running setup more than once')
 973         if ( $class->setup_finished );
 974
 975     unless ( $class->isa('Catalyst') ) {
 976
 977         Catalyst::Exception->throw(
 978             message => qq/'$class' does not inherit from Catalyst/ );
 979     }
 980
 981     if ( $class->arguments ) {
 982         @arguments = ( @arguments, @{ $class->arguments } );
 983     }
 984
 985     # Process options
 986     my $flags = {};
 987
 988     foreach (@arguments) {
 989
 990         if (/^-Debug$/) {
 991             $flags->{log} =
 992               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 993         }
 994         elsif (/^-(\w+)=?(.*)$/) {
 995             $flags->{ lc $1 } = $2;
 996         }
 997         else {
 998             push @{ $flags->{plugins} }, $_;
 999         }
1000     }
1001
1002     $class->setup_home( delete $flags->{home} );
1003
1004     $class->setup_log( delete $flags->{log} );
1005     $class->setup_plugins( delete $flags->{plugins} );
1006     $class->setup_dispatcher( delete $flags->{dispatcher} );
1007     $class->setup_engine( delete $flags->{engine} );
1008     $class->setup_stats( delete $flags->{stats} );
1009
1010     for my $flag ( sort keys %{$flags} ) {
1011
1012         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1013             &$code( $class, delete $flags->{$flag} );
1014         }
1015         else {
1016             $class->log->warn(qq/Unknown flag "$flag"/);
1017         }
1018     }
1019
1020     eval { require Catalyst::Devel; };
1021     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1022         $class->log->warn(<<"EOF");
1023 You are running an old script!
1024
1025   Please update by running (this will overwrite existing files):
1026     catalyst.pl -force -scripts $class
1027
1028   or (this will not overwrite existing files):
1029     catalyst.pl -scripts $class
1030
1031 EOF
1032     }
1033
1034     if ( $class->debug ) {
1035         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1036
1037         if (@plugins) {
1038             my $column_width = Catalyst::Utils::term_width() - 6;
1039             my $t = Text::SimpleTable->new($column_width);
1040             $t->row($_) for @plugins;
1041             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1042         }
1043
1044         my $dispatcher = $class->dispatcher;
1045         my $engine     = $class->engine;
1046         my $home       = $class->config->{home};
1047
1048         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1049         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1050
1051         $home
1052           ? ( -d $home )
1053           ? $class->log->debug(qq/Found home "$home"/)
1054           : $class->log->debug(qq/Home "$home" doesn't exist/)
1055           : $class->log->debug(q/Couldn't find home/);
1056     }
1057
1058     # Call plugins setup, this is stupid and evil.
1059     {
1060         no warnings qw/redefine/;
1061         local *setup = sub { };
1062         $class->setup;
1063     }
1064
1065     # Initialize our data structure
1066     $class->components( {} );
1067
1068     $class->setup_components;
1069
1070     if ( $class->debug ) {
1071         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1072         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1073         for my $comp ( sort keys %{ $class->components } ) {
1074             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1075             $t->row( $comp, $type );
1076         }
1077         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1078           if ( keys %{ $class->components } );
1079     }
1080
1081     # Add our self to components, since we are also a component
1082     if( $class->isa('Catalyst::Controller') ){
1083       $class->components->{$class} = $class;
1084     }
1085
1086     $class->setup_actions;
1087
1088     if ( $class->debug ) {
1089         my $name = $class->config->{name} || 'Application';
1090         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1091     }
1092     $class->log->_flush() if $class->log->can('_flush');
1093
1094     # Make sure that the application class becomes immutable at this point,
1095     # which ensures that it gets an inlined constructor. This means that it
1096     # works even if the user has added a plugin which contains a new method.
1097     # Note however that we have to do the work on scope end, so that method
1098     # modifiers work correctly in MyApp (as you have to call setup _before_
1099     # applying modifiers).
1100     Scope::Upper::reap(sub {
1101         my $meta = Class::MOP::get_metaclass_by_name($class);
1102         $meta->make_immutable unless $meta->is_immutable;
1103     }, Scope::Upper::SCOPE(1));
1104
1105     $class->setup_finalize;
1106 }
1107
1108
1109 =head2 $app->setup_finalize
1110
1111 A hook to attach modifiers to.
1112 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1113 Also better than C< setup_finished(); >, as that is a getter method.
1114
1115     sub setup_finalize {
1116
1117         my $app = shift;
1118
1119         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1120
1121         $app->next::method(@_);
1122
1123
1124     }
1125
1126 =cut
1127
1128 sub setup_finalize {
1129     my ($class) = @_;
1130     $class->setup_finished(1);
1131 }
1132
1133 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1134
1135 =head2 $c->uri_for( $path, @args?, \%query_values? )
1136
1137 =over
1138
1139 =item $action
1140
1141 A Catalyst::Action object representing the Catalyst action you want to
1142 create a URI for. To get one for an action in the current controller,
1143 use C<< $c->action('someactionname') >>. To get one from different
1144 controller, fetch the controller using C<< $c->controller() >>, then
1145 call C<action_for> on it.
1146
1147 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1148 using C<< $c->req->captures >>.
1149
1150   # For the current action
1151   $c->uri_for($c->action, $c->req->captures);
1152
1153   # For the Foo action in the Bar controller
1154   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1155
1156 =back
1157
1158 =cut
1159
1160 sub uri_for {
1161     my ( $c, $path, @args ) = @_;
1162
1163     if ( blessed($path) ) { # action object
1164         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1165                          ? shift(@args)
1166                          : [] );
1167         my $action = $path;
1168         $path = $c->dispatcher->uri_for_action($action, $captures);
1169         if (not defined $path) {
1170             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1171                 if $c->debug;
1172             return undef;
1173         }
1174         $path = '/' if $path eq '';
1175     }
1176
1177     undef($path) if (defined $path && $path eq '');
1178
1179     my $params =
1180       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1181
1182     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1183     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1184
1185     unshift(@args, $path);
1186
1187     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1188         my $namespace = $c->namespace;
1189         if (defined $path) { # cheesy hack to handle path '../foo'
1190            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1191         }
1192         unshift(@args, $namespace || '');
1193     }
1194
1195     # join args with '/', or a blank string
1196     my $args = join('/', grep { defined($_) } @args);
1197     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1198     $args =~ s!^/+!!;
1199     my $base = $c->req->base;
1200     my $class = ref($base);
1201     $base =~ s{(?<!/)$}{/};
1202
1203     my $query = '';
1204
1205     if (my @keys = keys %$params) {
1206       # somewhat lifted from URI::_query's query_form
1207       $query = '?'.join('&', map {
1208           my $val = $params->{$_};
1209           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1210           s/ /+/g;
1211           my $key = $_;
1212           $val = '' unless defined $val;
1213           (map {
1214               $_ = "$_";
1215               utf8::encode( $_ ) if utf8::is_utf8($_);
1216               # using the URI::Escape pattern here so utf8 chars survive
1217               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1218               s/ /+/g;
1219               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1220       } @keys);
1221     }
1222
1223     my $res = bless(\"${base}${args}${query}", $class);
1224     $res;
1225 }
1226
1227 =head2 $c->welcome_message
1228
1229 Returns the Catalyst welcome HTML page.
1230
1231 =cut
1232
1233 sub welcome_message {
1234     my $c      = shift;
1235     my $name   = $c->config->{name};
1236     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1237     my $prefix = Catalyst::Utils::appprefix( ref $c );
1238     $c->response->content_type('text/html; charset=utf-8');
1239     return <<"EOF";
1240 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1241     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1242 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1243     <head>
1244     <meta http-equiv="Content-Language" content="en" />
1245     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1246         <title>$name on Catalyst $VERSION</title>
1247         <style type="text/css">
1248             body {
1249                 color: #000;
1250                 background-color: #eee;
1251             }
1252             div#content {
1253                 width: 640px;
1254                 margin-left: auto;
1255                 margin-right: auto;
1256                 margin-top: 10px;
1257                 margin-bottom: 10px;
1258                 text-align: left;
1259                 background-color: #ccc;
1260                 border: 1px solid #aaa;
1261             }
1262             p, h1, h2 {
1263                 margin-left: 20px;
1264                 margin-right: 20px;
1265                 font-family: verdana, tahoma, sans-serif;
1266             }
1267             a {
1268                 font-family: verdana, tahoma, sans-serif;
1269             }
1270             :link, :visited {
1271                     text-decoration: none;
1272                     color: #b00;
1273                     border-bottom: 1px dotted #bbb;
1274             }
1275             :link:hover, :visited:hover {
1276                     color: #555;
1277             }
1278             div#topbar {
1279                 margin: 0px;
1280             }
1281             pre {
1282                 margin: 10px;
1283                 padding: 8px;
1284             }
1285             div#answers {
1286                 padding: 8px;
1287                 margin: 10px;
1288                 background-color: #fff;
1289                 border: 1px solid #aaa;
1290             }
1291             h1 {
1292                 font-size: 0.9em;
1293                 font-weight: normal;
1294                 text-align: center;
1295             }
1296             h2 {
1297                 font-size: 1.0em;
1298             }
1299             p {
1300                 font-size: 0.9em;
1301             }
1302             p img {
1303                 float: right;
1304                 margin-left: 10px;
1305             }
1306             span#appname {
1307                 font-weight: bold;
1308                 font-size: 1.6em;
1309             }
1310         </style>
1311     </head>
1312     <body>
1313         <div id="content">
1314             <div id="topbar">
1315                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1316                     $VERSION</h1>
1317              </div>
1318              <div id="answers">
1319                  <p>
1320                  <img src="$logo" alt="Catalyst Logo" />
1321                  </p>
1322                  <p>Welcome to the  world of Catalyst.
1323                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1324                     framework will make web development something you had
1325                     never expected it to be: Fun, rewarding, and quick.</p>
1326                  <h2>What to do now?</h2>
1327                  <p>That really depends  on what <b>you</b> want to do.
1328                     We do, however, provide you with a few starting points.</p>
1329                  <p>If you want to jump right into web development with Catalyst
1330                     you might want to start with a tutorial.</p>
1331 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1332 </pre>
1333 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1334 <pre>
1335 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1336 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1337 </code></pre>
1338                  <h2>What to do next?</h2>
1339                  <p>Next it's time to write an actual application. Use the
1340                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1341                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1342                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1343                     they can save you a lot of work.</p>
1344                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1345                     <p>Also, be sure to check out the vast and growing
1346                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1347                     you are likely to find what you need there.
1348                     </p>
1349
1350                  <h2>Need help?</h2>
1351                  <p>Catalyst has a very active community. Here are the main places to
1352                     get in touch with us.</p>
1353                  <ul>
1354                      <li>
1355                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1356                      </li>
1357                      <li>
1358                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1359                      </li>
1360                      <li>
1361                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1362                      </li>
1363                  </ul>
1364                  <h2>In conclusion</h2>
1365                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1366                     as we enjoyed making it. Please contact us if you have ideas
1367                     for improvement or other feedback.</p>
1368              </div>
1369          </div>
1370     </body>
1371 </html>
1372 EOF
1373 }
1374
1375 =head1 INTERNAL METHODS
1376
1377 These methods are not meant to be used by end users.
1378
1379 =head2 $c->components
1380
1381 Returns a hash of components.
1382
1383 =head2 $c->context_class
1384
1385 Returns or sets the context class.
1386
1387 =head2 $c->counter
1388
1389 Returns a hashref containing coderefs and execution counts (needed for
1390 deep recursion detection).
1391
1392 =head2 $c->depth
1393
1394 Returns the number of actions on the current internal execution stack.
1395
1396 =head2 $c->dispatch
1397
1398 Dispatches a request to actions.
1399
1400 =cut
1401
1402 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1403
1404 =head2 $c->dispatcher_class
1405
1406 Returns or sets the dispatcher class.
1407
1408 =head2 $c->dump_these
1409
1410 Returns a list of 2-element array references (name, structure) pairs
1411 that will be dumped on the error page in debug mode.
1412
1413 =cut
1414
1415 sub dump_these {
1416     my $c = shift;
1417     [ Request => $c->req ],
1418     [ Response => $c->res ],
1419     [ Stash => $c->stash ],
1420     [ Config => $c->config ];
1421 }
1422
1423 =head2 $c->engine_class
1424
1425 Returns or sets the engine class.
1426
1427 =head2 $c->execute( $class, $coderef )
1428
1429 Execute a coderef in given class and catch exceptions. Errors are available
1430 via $c->error.
1431
1432 =cut
1433
1434 sub execute {
1435     my ( $c, $class, $code ) = @_;
1436     $class = $c->component($class) || $class;
1437     $c->state(0);
1438
1439     if ( $c->depth >= $RECURSION ) {
1440         my $action = $code->reverse();
1441         $action = "/$action" unless $action =~ /->/;
1442         my $error = qq/Deep recursion detected calling "${action}"/;
1443         $c->log->error($error);
1444         $c->error($error);
1445         $c->state(0);
1446         return $c->state;
1447     }
1448
1449     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1450
1451     push( @{ $c->stack }, $code );
1452
1453     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1454
1455     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1456
1457     my $last = pop( @{ $c->stack } );
1458
1459     if ( my $error = $@ ) {
1460         if ( !ref($error) and $error eq $DETACH ) {
1461             die $DETACH if($c->depth > 1);
1462         }
1463         elsif ( !ref($error) and $error eq $GO ) {
1464             die $GO if($c->depth > 0);
1465         }
1466         else {
1467             unless ( ref $error ) {
1468                 no warnings 'uninitialized';
1469                 chomp $error;
1470                 my $class = $last->class;
1471                 my $name  = $last->name;
1472                 $error = qq/Caught exception in $class->$name "$error"/;
1473             }
1474             $c->error($error);
1475             $c->state(0);
1476         }
1477     }
1478     return $c->state;
1479 }
1480
1481 sub _stats_start_execute {
1482     my ( $c, $code ) = @_;
1483
1484     return if ( ( $code->name =~ /^_.*/ )
1485         && ( !$c->config->{show_internal_actions} ) );
1486
1487     my $action_name = $code->reverse();
1488     $c->counter->{$action_name}++;
1489
1490     my $action = $action_name;
1491     $action = "/$action" unless $action =~ /->/;
1492
1493     # determine if the call was the result of a forward
1494     # this is done by walking up the call stack and looking for a calling
1495     # sub of Catalyst::forward before the eval
1496     my $callsub = q{};
1497     for my $index ( 2 .. 11 ) {
1498         last
1499         if ( ( caller($index) )[0] eq 'Catalyst'
1500             && ( caller($index) )[3] eq '(eval)' );
1501
1502         if ( ( caller($index) )[3] =~ /forward$/ ) {
1503             $callsub = ( caller($index) )[3];
1504             $action  = "-> $action";
1505             last;
1506         }
1507     }
1508
1509     my $uid = $action_name . $c->counter->{$action_name};
1510
1511     # is this a root-level call or a forwarded call?
1512     if ( $callsub =~ /forward$/ ) {
1513
1514         # forward, locate the caller
1515         if ( my $parent = $c->stack->[-1] ) {
1516             $c->stats->profile(
1517                 begin  => $action,
1518                 parent => "$parent" . $c->counter->{"$parent"},
1519                 uid    => $uid,
1520             );
1521         }
1522         else {
1523
1524             # forward with no caller may come from a plugin
1525             $c->stats->profile(
1526                 begin => $action,
1527                 uid   => $uid,
1528             );
1529         }
1530     }
1531     else {
1532
1533         # root-level call
1534         $c->stats->profile(
1535             begin => $action,
1536             uid   => $uid,
1537         );
1538     }
1539     return $action;
1540
1541 }
1542
1543 sub _stats_finish_execute {
1544     my ( $c, $info ) = @_;
1545     $c->stats->profile( end => $info );
1546 }
1547
1548 =head2 $c->_localize_fields( sub { }, \%keys );
1549
1550 =cut
1551
1552 #Why does this exist? This is no longer safe and WILL NOT WORK.
1553 # it doesnt seem to be used anywhere. can we remove it?
1554 sub _localize_fields {
1555     my ( $c, $localized, $code ) = ( @_ );
1556
1557     my $request = delete $localized->{request} || {};
1558     my $response = delete $localized->{response} || {};
1559
1560     local @{ $c }{ keys %$localized } = values %$localized;
1561     local @{ $c->request }{ keys %$request } = values %$request;
1562     local @{ $c->response }{ keys %$response } = values %$response;
1563
1564     $code->();
1565 }
1566
1567 =head2 $c->finalize
1568
1569 Finalizes the request.
1570
1571 =cut
1572
1573 sub finalize {
1574     my $c = shift;
1575
1576     for my $error ( @{ $c->error } ) {
1577         $c->log->error($error);
1578     }
1579
1580     # Allow engine to handle finalize flow (for POE)
1581     my $engine = $c->engine;
1582     if ( my $code = $engine->can('finalize') ) {
1583         $engine->$code($c);
1584     }
1585     else {
1586
1587         $c->finalize_uploads;
1588
1589         # Error
1590         if ( $#{ $c->error } >= 0 ) {
1591             $c->finalize_error;
1592         }
1593
1594         $c->finalize_headers;
1595
1596         # HEAD request
1597         if ( $c->request->method eq 'HEAD' ) {
1598             $c->response->body('');
1599         }
1600
1601         $c->finalize_body;
1602     }
1603
1604     if ($c->use_stats) {
1605         my $elapsed = sprintf '%f', $c->stats->elapsed;
1606         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1607         $c->log->info(
1608             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1609     }
1610
1611     return $c->response->status;
1612 }
1613
1614 =head2 $c->finalize_body
1615
1616 Finalizes body.
1617
1618 =cut
1619
1620 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1621
1622 =head2 $c->finalize_cookies
1623
1624 Finalizes cookies.
1625
1626 =cut
1627
1628 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1629
1630 =head2 $c->finalize_error
1631
1632 Finalizes error.
1633
1634 =cut
1635
1636 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1637
1638 =head2 $c->finalize_headers
1639
1640 Finalizes headers.
1641
1642 =cut
1643
1644 sub finalize_headers {
1645     my $c = shift;
1646
1647     my $response = $c->response; #accessor calls can add up?
1648
1649     # Check if we already finalized headers
1650     return if $response->finalized_headers;
1651
1652     # Handle redirects
1653     if ( my $location = $response->redirect ) {
1654         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1655         $response->header( Location => $location );
1656
1657         if ( !$response->has_body ) {
1658             # Add a default body if none is already present
1659             $response->body(
1660                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1661             );
1662         }
1663     }
1664
1665     # Content-Length
1666     if ( $response->body && !$response->content_length ) {
1667
1668         # get the length from a filehandle
1669         if ( blessed( $response->body ) && $response->body->can('read') )
1670         {
1671             my $stat = stat $response->body;
1672             if ( $stat && $stat->size > 0 ) {
1673                 $response->content_length( $stat->size );
1674             }
1675             else {
1676                 $c->log->warn('Serving filehandle without a content-length');
1677             }
1678         }
1679         else {
1680             # everything should be bytes at this point, but just in case
1681             $response->content_length( bytes::length( $response->body ) );
1682         }
1683     }
1684
1685     # Errors
1686     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1687         $response->headers->remove_header("Content-Length");
1688         $response->body('');
1689     }
1690
1691     $c->finalize_cookies;
1692
1693     $c->engine->finalize_headers( $c, @_ );
1694
1695     # Done
1696     $response->finalized_headers(1);
1697 }
1698
1699 =head2 $c->finalize_output
1700
1701 An alias for finalize_body.
1702
1703 =head2 $c->finalize_read
1704
1705 Finalizes the input after reading is complete.
1706
1707 =cut
1708
1709 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1710
1711 =head2 $c->finalize_uploads
1712
1713 Finalizes uploads. Cleans up any temporary files.
1714
1715 =cut
1716
1717 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1718
1719 =head2 $c->get_action( $action, $namespace )
1720
1721 Gets an action in a given namespace.
1722
1723 =cut
1724
1725 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1726
1727 =head2 $c->get_actions( $action, $namespace )
1728
1729 Gets all actions of a given name in a namespace and all parent
1730 namespaces.
1731
1732 =cut
1733
1734 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1735
1736 =head2 $c->handle_request( $class, @arguments )
1737
1738 Called to handle each HTTP request.
1739
1740 =cut
1741
1742 sub handle_request {
1743     my ( $class, @arguments ) = @_;
1744
1745     # Always expect worst case!
1746     my $status = -1;
1747     eval {
1748         if ($class->debug) {
1749             my $secs = time - $START || 1;
1750             my $av = sprintf '%.3f', $COUNT / $secs;
1751             my $time = localtime time;
1752             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1753         }
1754
1755         my $c = $class->prepare(@arguments);
1756         $c->dispatch;
1757         $status = $c->finalize;
1758     };
1759
1760     if ( my $error = $@ ) {
1761         chomp $error;
1762         $class->log->error(qq/Caught exception in engine "$error"/);
1763     }
1764
1765     $COUNT++;
1766
1767     if(my $coderef = $class->log->can('_flush')){
1768         $class->log->$coderef();
1769     }
1770     return $status;
1771 }
1772
1773 =head2 $c->prepare( @arguments )
1774
1775 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1776 etc.).
1777
1778 =cut
1779
1780 sub prepare {
1781     my ( $class, @arguments ) = @_;
1782
1783     # XXX
1784     # After the app/ctxt split, this should become an attribute based on something passed
1785     # into the application.
1786     $class->context_class( ref $class || $class ) unless $class->context_class;
1787
1788     my $c = $class->context_class->new({});
1789
1790     # For on-demand data
1791     $c->request->_context($c);
1792     $c->response->_context($c);
1793
1794     #surely this is not the most efficient way to do things...
1795     $c->stats($class->stats_class->new)->enable($c->use_stats);
1796     if ( $c->debug ) {
1797         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1798     }
1799
1800     #XXX reuse coderef from can
1801     # Allow engine to direct the prepare flow (for POE)
1802     if ( $c->engine->can('prepare') ) {
1803         $c->engine->prepare( $c, @arguments );
1804     }
1805     else {
1806         $c->prepare_request(@arguments);
1807         $c->prepare_connection;
1808         $c->prepare_query_parameters;
1809         $c->prepare_headers;
1810         $c->prepare_cookies;
1811         $c->prepare_path;
1812
1813         # Prepare the body for reading, either by prepare_body
1814         # or the user, if they are using $c->read
1815         $c->prepare_read;
1816
1817         # Parse the body unless the user wants it on-demand
1818         unless ( $c->config->{parse_on_demand} ) {
1819             $c->prepare_body;
1820         }
1821     }
1822
1823     my $method  = $c->req->method  || '';
1824     my $path    = $c->req->path;
1825     $path       = '/' unless length $path;
1826     my $address = $c->req->address || '';
1827
1828     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1829       if $c->debug;
1830
1831     $c->prepare_action;
1832
1833     return $c;
1834 }
1835
1836 =head2 $c->prepare_action
1837
1838 Prepares action. See L<Catalyst::Dispatcher>.
1839
1840 =cut
1841
1842 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1843
1844 =head2 $c->prepare_body
1845
1846 Prepares message body.
1847
1848 =cut
1849
1850 sub prepare_body {
1851     my $c = shift;
1852
1853     return if $c->request->_has_body;
1854
1855     # Initialize on-demand data
1856     $c->engine->prepare_body( $c, @_ );
1857     $c->prepare_parameters;
1858     $c->prepare_uploads;
1859
1860     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1861         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1862         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1863             my $param = $c->req->body_parameters->{$key};
1864             my $value = defined($param) ? $param : '';
1865             $t->row( $key,
1866                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1867         }
1868         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1869     }
1870 }
1871
1872 =head2 $c->prepare_body_chunk( $chunk )
1873
1874 Prepares a chunk of data before sending it to L<HTTP::Body>.
1875
1876 See L<Catalyst::Engine>.
1877
1878 =cut
1879
1880 sub prepare_body_chunk {
1881     my $c = shift;
1882     $c->engine->prepare_body_chunk( $c, @_ );
1883 }
1884
1885 =head2 $c->prepare_body_parameters
1886
1887 Prepares body parameters.
1888
1889 =cut
1890
1891 sub prepare_body_parameters {
1892     my $c = shift;
1893     $c->engine->prepare_body_parameters( $c, @_ );
1894 }
1895
1896 =head2 $c->prepare_connection
1897
1898 Prepares connection.
1899
1900 =cut
1901
1902 sub prepare_connection {
1903     my $c = shift;
1904     $c->engine->prepare_connection( $c, @_ );
1905 }
1906
1907 =head2 $c->prepare_cookies
1908
1909 Prepares cookies.
1910
1911 =cut
1912
1913 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1914
1915 =head2 $c->prepare_headers
1916
1917 Prepares headers.
1918
1919 =cut
1920
1921 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1922
1923 =head2 $c->prepare_parameters
1924
1925 Prepares parameters.
1926
1927 =cut
1928
1929 sub prepare_parameters {
1930     my $c = shift;
1931     $c->prepare_body_parameters;
1932     $c->engine->prepare_parameters( $c, @_ );
1933 }
1934
1935 =head2 $c->prepare_path
1936
1937 Prepares path and base.
1938
1939 =cut
1940
1941 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1942
1943 =head2 $c->prepare_query_parameters
1944
1945 Prepares query parameters.
1946
1947 =cut
1948
1949 sub prepare_query_parameters {
1950     my $c = shift;
1951
1952     $c->engine->prepare_query_parameters( $c, @_ );
1953
1954     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1955         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1956         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1957             my $param = $c->req->query_parameters->{$key};
1958             my $value = defined($param) ? $param : '';
1959             $t->row( $key,
1960                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1961         }
1962         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1963     }
1964 }
1965
1966 =head2 $c->prepare_read
1967
1968 Prepares the input for reading.
1969
1970 =cut
1971
1972 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1973
1974 =head2 $c->prepare_request
1975
1976 Prepares the engine request.
1977
1978 =cut
1979
1980 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1981
1982 =head2 $c->prepare_uploads
1983
1984 Prepares uploads.
1985
1986 =cut
1987
1988 sub prepare_uploads {
1989     my $c = shift;
1990
1991     $c->engine->prepare_uploads( $c, @_ );
1992
1993     if ( $c->debug && keys %{ $c->request->uploads } ) {
1994         my $t = Text::SimpleTable->new(
1995             [ 12, 'Parameter' ],
1996             [ 26, 'Filename' ],
1997             [ 18, 'Type' ],
1998             [ 9,  'Size' ]
1999         );
2000         for my $key ( sort keys %{ $c->request->uploads } ) {
2001             my $upload = $c->request->uploads->{$key};
2002             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2003                 $t->row( $key, $u->filename, $u->type, $u->size );
2004             }
2005         }
2006         $c->log->debug( "File Uploads are:\n" . $t->draw );
2007     }
2008 }
2009
2010 =head2 $c->prepare_write
2011
2012 Prepares the output for writing.
2013
2014 =cut
2015
2016 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2017
2018 =head2 $c->request_class
2019
2020 Returns or sets the request class.
2021
2022 =head2 $c->response_class
2023
2024 Returns or sets the response class.
2025
2026 =head2 $c->read( [$maxlength] )
2027
2028 Reads a chunk of data from the request body. This method is designed to
2029 be used in a while loop, reading C<$maxlength> bytes on every call.
2030 C<$maxlength> defaults to the size of the request if not specified.
2031
2032 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
2033 directly.
2034
2035 Warning: If you use read(), Catalyst will not process the body,
2036 so you will not be able to access POST parameters or file uploads via
2037 $c->request.  You must handle all body parsing yourself.
2038
2039 =cut
2040
2041 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2042
2043 =head2 $c->run
2044
2045 Starts the engine.
2046
2047 =cut
2048
2049 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2050
2051 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2052
2053 Sets an action in a given namespace.
2054
2055 =cut
2056
2057 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2058
2059 =head2 $c->setup_actions($component)
2060
2061 Sets up actions for a component.
2062
2063 =cut
2064
2065 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2066
2067 =head2 $c->setup_components
2068
2069 Sets up components. Specify a C<setup_components> config option to pass
2070 additional options directly to L<Module::Pluggable>. To add additional
2071 search paths, specify a key named C<search_extra> as an array
2072 reference. Items in the array beginning with C<::> will have the
2073 application class name prepended to them.
2074
2075 All components found will also have any
2076 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2077 Note, that modules which are B<not> an I<inner package> of the main
2078 file namespace loaded will not be instantiated as components.
2079
2080 =cut
2081
2082 sub setup_components {
2083     my $class = shift;
2084
2085     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2086     my $config  = $class->config->{ setup_components };
2087     my $extra   = delete $config->{ search_extra } || [];
2088
2089     push @paths, @$extra;
2090
2091     my $locator = Module::Pluggable::Object->new(
2092         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2093         %$config
2094     );
2095
2096     my @comps = sort { length $a <=> length $b } $locator->plugins;
2097     my %comps = map { $_ => 1 } @comps;
2098
2099     my $deprecated_component_names = grep { /::[CMV]::/ } @comps;
2100     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2101         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2102     ) if $deprecated_component_names;
2103
2104     for my $component ( @comps ) {
2105
2106         # We pass ignore_loaded here so that overlay files for (e.g.)
2107         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2108         # we know M::P::O found a file on disk so this is safe
2109
2110         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2111         #Class::MOP::load_class($component);
2112
2113         my $module  = $class->setup_component( $component );
2114         my %modules = (
2115             $component => $module,
2116             map {
2117                 $_ => $class->setup_component( $_ )
2118             } grep {
2119               not exists $comps{$_}
2120             } Devel::InnerPackage::list_packages( $component )
2121         );
2122
2123         for my $key ( keys %modules ) {
2124             $class->components->{ $key } = $modules{ $key };
2125         }
2126     }
2127 }
2128
2129 =head2 $c->setup_component
2130
2131 =cut
2132
2133 sub setup_component {
2134     my( $class, $component ) = @_;
2135
2136     unless ( $component->can( 'COMPONENT' ) ) {
2137         return $component;
2138     }
2139
2140     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2141     my $config = $class->config->{ $suffix } || {};
2142
2143     my $instance = eval { $component->COMPONENT( $class, $config ); };
2144
2145     if ( my $error = $@ ) {
2146         chomp $error;
2147         Catalyst::Exception->throw(
2148             message => qq/Couldn't instantiate component "$component", "$error"/
2149         );
2150     }
2151
2152     Catalyst::Exception->throw(
2153         message =>
2154         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2155     ) unless blessed($instance);
2156
2157     return $instance;
2158 }
2159
2160 =head2 $c->setup_dispatcher
2161
2162 Sets up dispatcher.
2163
2164 =cut
2165
2166 sub setup_dispatcher {
2167     my ( $class, $dispatcher ) = @_;
2168
2169     if ($dispatcher) {
2170         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2171     }
2172
2173     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2174         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2175     }
2176
2177     unless ($dispatcher) {
2178         $dispatcher = $class->dispatcher_class;
2179     }
2180
2181     Class::MOP::load_class($dispatcher);
2182
2183     # dispatcher instance
2184     $class->dispatcher( $dispatcher->new );
2185 }
2186
2187 =head2 $c->setup_engine
2188
2189 Sets up engine.
2190
2191 =cut
2192
2193 sub setup_engine {
2194     my ( $class, $engine ) = @_;
2195
2196     if ($engine) {
2197         $engine = 'Catalyst::Engine::' . $engine;
2198     }
2199
2200     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2201         $engine = 'Catalyst::Engine::' . $env;
2202     }
2203
2204     if ( $ENV{MOD_PERL} ) {
2205         my $meta = Class::MOP::get_metaclass_by_name($class);
2206
2207         # create the apache method
2208         $meta->add_method('apache' => sub { shift->engine->apache });
2209
2210         my ( $software, $version ) =
2211           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2212
2213         $version =~ s/_//g;
2214         $version =~ s/(\.[^.]+)\./$1/g;
2215
2216         if ( $software eq 'mod_perl' ) {
2217
2218             if ( !$engine ) {
2219
2220                 if ( $version >= 1.99922 ) {
2221                     $engine = 'Catalyst::Engine::Apache2::MP20';
2222                 }
2223
2224                 elsif ( $version >= 1.9901 ) {
2225                     $engine = 'Catalyst::Engine::Apache2::MP19';
2226                 }
2227
2228                 elsif ( $version >= 1.24 ) {
2229                     $engine = 'Catalyst::Engine::Apache::MP13';
2230                 }
2231
2232                 else {
2233                     Catalyst::Exception->throw( message =>
2234                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2235                 }
2236
2237             }
2238
2239             # install the correct mod_perl handler
2240             if ( $version >= 1.9901 ) {
2241                 *handler = sub  : method {
2242                     shift->handle_request(@_);
2243                 };
2244             }
2245             else {
2246                 *handler = sub ($$) { shift->handle_request(@_) };
2247             }
2248
2249         }
2250
2251         elsif ( $software eq 'Zeus-Perl' ) {
2252             $engine = 'Catalyst::Engine::Zeus';
2253         }
2254
2255         else {
2256             Catalyst::Exception->throw(
2257                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2258         }
2259     }
2260
2261     unless ($engine) {
2262         $engine = $class->engine_class;
2263     }
2264
2265     Class::MOP::load_class($engine);
2266
2267     # check for old engines that are no longer compatible
2268     my $old_engine;
2269     if ( $engine->isa('Catalyst::Engine::Apache')
2270         && !Catalyst::Engine::Apache->VERSION )
2271     {
2272         $old_engine = 1;
2273     }
2274
2275     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2276         && Catalyst::Engine::Server->VERSION le '0.02' )
2277     {
2278         $old_engine = 1;
2279     }
2280
2281     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2282         && $engine->VERSION eq '0.01' )
2283     {
2284         $old_engine = 1;
2285     }
2286
2287     elsif ($engine->isa('Catalyst::Engine::Zeus')
2288         && $engine->VERSION eq '0.01' )
2289     {
2290         $old_engine = 1;
2291     }
2292
2293     if ($old_engine) {
2294         Catalyst::Exception->throw( message =>
2295               qq/Engine "$engine" is not supported by this version of Catalyst/
2296         );
2297     }
2298
2299     # engine instance
2300     $class->engine( $engine->new );
2301 }
2302
2303 =head2 $c->setup_home
2304
2305 Sets up the home directory.
2306
2307 =cut
2308
2309 sub setup_home {
2310     my ( $class, $home ) = @_;
2311
2312     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2313         $home = $env;
2314     }
2315
2316     $home ||= Catalyst::Utils::home($class);
2317
2318     if ($home) {
2319         #I remember recently being scolded for assigning config values like this
2320         $class->config->{home} ||= $home;
2321         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2322     }
2323 }
2324
2325 =head2 $c->setup_log
2326
2327 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2328 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2329 log to.
2330
2331 This method also installs a C<debug> method that returns a true value into the
2332 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2333 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2334
2335 Note that if the log has already been setup, by either a previous call to
2336 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2337 that this method won't actually set up the log object.
2338
2339 =cut
2340
2341 sub setup_log {
2342     my ( $class, $levels ) = @_;
2343
2344     $levels ||= '';
2345     $levels =~ s/^\s+//;
2346     $levels =~ s/\s+$//;
2347     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels || '';
2348
2349     unless ( $class->log ) {
2350         $class->log( Catalyst::Log->new(keys %levels) );
2351     }
2352
2353     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2354     if ( defined($env_debug) or $levels{debug} ) {
2355         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2356         $class->log->debug('Debug messages enabled');
2357     }
2358 }
2359
2360 =head2 $c->setup_plugins
2361
2362 Sets up plugins.
2363
2364 =cut
2365
2366 =head2 $c->setup_stats
2367
2368 Sets up timing statistics class.
2369
2370 =cut
2371
2372 sub setup_stats {
2373     my ( $class, $stats ) = @_;
2374
2375     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2376
2377     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2378     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2379         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2380         $class->log->debug('Statistics enabled');
2381     }
2382 }
2383
2384
2385 =head2 $c->registered_plugins
2386
2387 Returns a sorted list of the plugins which have either been stated in the
2388 import list or which have been added via C<< MyApp->plugin(@args); >>.
2389
2390 If passed a given plugin name, it will report a boolean value indicating
2391 whether or not that plugin is loaded.  A fully qualified name is required if
2392 the plugin name does not begin with C<Catalyst::Plugin::>.
2393
2394  if ($c->registered_plugins('Some::Plugin')) {
2395      ...
2396  }
2397
2398 =cut
2399
2400 {
2401
2402     sub registered_plugins {
2403         my $proto = shift;
2404         return sort keys %{ $proto->_plugins } unless @_;
2405         my $plugin = shift;
2406         return 1 if exists $proto->_plugins->{$plugin};
2407         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2408     }
2409
2410     sub _register_plugin {
2411         my ( $proto, $plugin, $instant ) = @_;
2412         my $class = ref $proto || $proto;
2413
2414         # no ignore_loaded here, the plugin may already have been
2415         # defined in memory and we don't want to error on "no file" if so
2416
2417         Class::MOP::load_class( $plugin );
2418
2419         $proto->_plugins->{$plugin} = 1;
2420         unless ($instant) {
2421             no strict 'refs';
2422             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2423               my @superclasses = ($plugin, $meta->superclasses );
2424               $meta->superclasses(@superclasses);
2425             } else {
2426               unshift @{"$class\::ISA"}, $plugin;
2427             }
2428         }
2429         return $class;
2430     }
2431
2432     sub setup_plugins {
2433         my ( $class, $plugins ) = @_;
2434
2435         $class->_plugins( {} ) unless $class->_plugins;
2436         $plugins ||= [];
2437         for my $plugin ( reverse @$plugins ) {
2438
2439             unless ( $plugin =~ s/\A\+// ) {
2440                 $plugin = "Catalyst::Plugin::$plugin";
2441             }
2442
2443             $class->_register_plugin($plugin);
2444         }
2445     }
2446 }
2447
2448 =head2 $c->stack
2449
2450 Returns an arrayref of the internal execution stack (actions that are
2451 currently executing).
2452
2453 =head2 $c->stats_class
2454
2455 Returns or sets the stats (timing statistics) class.
2456
2457 =head2 $c->use_stats
2458
2459 Returns 1 when stats collection is enabled.  Stats collection is enabled
2460 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2461 environment variable is set.
2462
2463 Note that this is a static method, not an accessor and should be overloaded
2464 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2465
2466 =cut
2467
2468 sub use_stats { 0 }
2469
2470
2471 =head2 $c->write( $data )
2472
2473 Writes $data to the output stream. When using this method directly, you
2474 will need to manually set the C<Content-Length> header to the length of
2475 your output data, if known.
2476
2477 =cut
2478
2479 sub write {
2480     my $c = shift;
2481
2482     # Finalize headers if someone manually writes output
2483     $c->finalize_headers;
2484
2485     return $c->engine->write( $c, @_ );
2486 }
2487
2488 =head2 version
2489
2490 Returns the Catalyst version number. Mostly useful for "powered by"
2491 messages in template systems.
2492
2493 =cut
2494
2495 sub version { return $Catalyst::VERSION }
2496
2497 =head1 INTERNAL ACTIONS
2498
2499 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2500 C<_ACTION>, and C<_END>. These are by default not shown in the private
2501 action table, but you can make them visible with a config parameter.
2502
2503     MyApp->config->{show_internal_actions} = 1;
2504
2505 =head1 CASE SENSITIVITY
2506
2507 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2508 mapped to C</foo/bar>. You can activate case sensitivity with a config
2509 parameter.
2510
2511     MyApp->config->{case_sensitive} = 1;
2512
2513 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2514
2515 =head1 ON-DEMAND PARSER
2516
2517 The request body is usually parsed at the beginning of a request,
2518 but if you want to handle input yourself, you can enable on-demand
2519 parsing with a config parameter.
2520
2521     MyApp->config->{parse_on_demand} = 1;
2522
2523 =head1 PROXY SUPPORT
2524
2525 Many production servers operate using the common double-server approach,
2526 with a lightweight frontend web server passing requests to a larger
2527 backend server. An application running on the backend server must deal
2528 with two problems: the remote user always appears to be C<127.0.0.1> and
2529 the server's hostname will appear to be C<localhost> regardless of the
2530 virtual host that the user connected through.
2531
2532 Catalyst will automatically detect this situation when you are running
2533 the frontend and backend servers on the same machine. The following
2534 changes are made to the request.
2535
2536     $c->req->address is set to the user's real IP address, as read from
2537     the HTTP X-Forwarded-For header.
2538
2539     The host value for $c->req->base and $c->req->uri is set to the real
2540     host, as read from the HTTP X-Forwarded-Host header.
2541
2542 Obviously, your web server must support these headers for this to work.
2543
2544 In a more complex server farm environment where you may have your
2545 frontend proxy server(s) on different machines, you will need to set a
2546 configuration option to tell Catalyst to read the proxied data from the
2547 headers.
2548
2549     MyApp->config->{using_frontend_proxy} = 1;
2550
2551 If you do not wish to use the proxy support at all, you may set:
2552
2553     MyApp->config->{ignore_frontend_proxy} = 1;
2554
2555 =head1 THREAD SAFETY
2556
2557 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2558 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2559 believe the Catalyst core to be thread-safe.
2560
2561 If you plan to operate in a threaded environment, remember that all other
2562 modules you are using must also be thread-safe. Some modules, most notably
2563 L<DBD::SQLite>, are not thread-safe.
2564
2565 =head1 SUPPORT
2566
2567 IRC:
2568
2569     Join #catalyst on irc.perl.org.
2570
2571 Mailing Lists:
2572
2573     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2574     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2575
2576 Web:
2577
2578     http://catalyst.perl.org
2579
2580 Wiki:
2581
2582     http://dev.catalyst.perl.org
2583
2584 =head1 SEE ALSO
2585
2586 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2587
2588 =head2 L<Catalyst::Manual> - The Catalyst Manual
2589
2590 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2591
2592 =head2 L<Catalyst::Engine> - Core engine
2593
2594 =head2 L<Catalyst::Log> - Log class.
2595
2596 =head2 L<Catalyst::Request> - Request object
2597
2598 =head2 L<Catalyst::Response> - Response object
2599
2600 =head2 L<Catalyst::Test> - The test suite.
2601
2602 =head1 PROJECT FOUNDER
2603
2604 sri: Sebastian Riedel <sri@cpan.org>
2605
2606 =head1 CONTRIBUTORS
2607
2608 abw: Andy Wardley
2609
2610 acme: Leon Brocard <leon@astray.com>
2611
2612 Andrew Bramble
2613
2614 Andrew Ford
2615
2616 Andrew Ruthven
2617
2618 andyg: Andy Grundman <andy@hybridized.org>
2619
2620 audreyt: Audrey Tang
2621
2622 bricas: Brian Cassidy <bricas@cpan.org>
2623
2624 Caelum: Rafael Kitover <rkitover@io.com>
2625
2626 chansen: Christian Hansen
2627
2628 chicks: Christopher Hicks
2629
2630 David E. Wheeler
2631
2632 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2633
2634 Drew Taylor
2635
2636 esskar: Sascha Kiefer
2637
2638 fireartist: Carl Franks <cfranks@cpan.org>
2639
2640 gabb: Danijel Milicevic
2641
2642 Gary Ashton Jones
2643
2644 Geoff Richards
2645
2646 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2647
2648 jcamacho: Juan Camacho
2649
2650 jhannah: Jay Hannah <jay@jays.net>
2651
2652 Jody Belka
2653
2654 Johan Lindstrom
2655
2656 jon: Jon Schutz <jjschutz@cpan.org>
2657
2658 marcus: Marcus Ramberg <mramberg@cpan.org>
2659
2660 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2661
2662 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2663
2664 mugwump: Sam Vilain
2665
2666 naughton: David Naughton
2667
2668 ningu: David Kamholz <dkamholz@cpan.org>
2669
2670 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2671
2672 numa: Dan Sully <daniel@cpan.org>
2673
2674 obra: Jesse Vincent
2675
2676 omega: Andreas Marienborg
2677
2678 Oleg Kostyuk <cub.uanic@gmail.com>
2679
2680 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2681
2682 rafl: Florian Ragwitz <rafl@debian.org>
2683
2684 sky: Arthur Bergman
2685
2686 the_jester: Jesse Sheidlower
2687
2688 t0m: Tomas Doran <bobtfish@bobtfish.net>
2689
2690 Ulf Edvinsson
2691
2692 willert: Sebastian Willert <willert@cpan.org>
2693
2694 =head1 LICENSE
2695
2696 This library is free software, you can redistribute it and/or modify it under
2697 the same terms as Perl itself.
2698
2699 =cut
2700
2701 no Moose;
2702
2703 __PACKAGE__->meta->make_immutable;
2704
2705 1;