lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use bytes;
   6 use Scope::Upper ();
   7 use Catalyst::Exception;
   8 use Catalyst::Log;
   9 use Catalyst::Request;
  10 use Catalyst::Request::Upload;
  11 use Catalyst::Response;
  12 use Catalyst::Utils;
  13 use Catalyst::Controller;
  14 use Devel::InnerPackage ();
  15 use File::stat;
  16 use Module::Pluggable::Object ();
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp shortmess/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 has stack => (is => 'ro', default => sub { [] });
  34 has stash => (is => 'rw', default => sub { {} });
  35 has state => (is => 'rw', default => 0);
  36 has stats => (is => 'rw');
  37 has action => (is => 'rw');
  38 has counter => (is => 'rw', default => sub { {} });
  39 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  40 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  41 has namespace => (is => 'rw');
  42
  43 sub depth { scalar @{ shift->stack || [] }; }
  44 sub comp { shift->component(@_) }
  45
  46 sub req {
  47     # carp "the use of req() is deprecated in favour of request()";
  48     my $self = shift; return $self->request(@_);
  49 }
  50 sub res {
  51     # carp "the use of res() is deprecated in favour of response()";
  52     my $self = shift; return $self->response(@_);
  53 }
  54
  55 # For backwards compatibility
  56 sub finalize_output { shift->finalize_body(@_) };
  57
  58 # For statistics
  59 our $COUNT     = 1;
  60 our $START     = time;
  61 our $RECURSION = 1000;
  62 our $DETACH    = "catalyst_detach\n";
  63 our $GO        = "catalyst_go\n";
  64
  65 #I imagine that very few of these really need to be class variables. if any.
  66 #maybe we should just make them attributes with a default?
  67 __PACKAGE__->mk_classdata($_)
  68   for qw/components arguments dispatcher engine log dispatcher_class
  69   engine_class context_class request_class response_class stats_class
  70   setup_finished/;
  71
  72 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  73 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  74 __PACKAGE__->request_class('Catalyst::Request');
  75 __PACKAGE__->response_class('Catalyst::Response');
  76 __PACKAGE__->stats_class('Catalyst::Stats');
  77
  78 # Remember to update this in Catalyst::Runtime as well!
  79
  80 our $VERSION = '5.8000_05';
  81
  82 sub import {
  83     my ( $class, @arguments ) = @_;
  84
  85     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  86     # callers @ISA.
  87     return unless $class eq 'Catalyst';
  88
  89     my $caller = caller();
  90     return if $caller eq 'main';
  91     my $meta = Moose::Meta::Class->initialize($caller);
  92     #Moose->import({ into => $caller }); #do we want to do this?
  93
  94     unless ( $caller->isa('Catalyst') ) {
  95         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  96         $meta->superclasses(@superclasses);
  97     }
  98     unless( $meta->has_method('meta') ){
  99         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 100     }
 101
 102     $caller->arguments( [@arguments] );
 103     $caller->setup_home;
 104 }
 105
 106 =head1 NAME
 107
 108 Catalyst - The Elegant MVC Web Application Framework
 109
 110 =head1 SYNOPSIS
 111
 112 See the L<Catalyst::Manual> distribution for comprehensive
 113 documentation and tutorials.
 114
 115     # Install Catalyst::Devel for helpers and other development tools
 116     # use the helper to create a new application
 117     catalyst.pl MyApp
 118
 119     # add models, views, controllers
 120     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 121     script/myapp_create.pl view MyTemplate TT
 122     script/myapp_create.pl controller Search
 123
 124     # built in testserver -- use -r to restart automatically on changes
 125     # --help to see all available options
 126     script/myapp_server.pl
 127
 128     # command line testing interface
 129     script/myapp_test.pl /yada
 130
 131     ### in lib/MyApp.pm
 132     use Catalyst qw/-Debug/; # include plugins here as well
 133
 134     ### In lib/MyApp/Controller/Root.pm (autocreated)
 135     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 136         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 137         $c->stash->{template} = 'foo.tt'; # set the template
 138         # lookup something from db -- stash vars are passed to TT
 139         $c->stash->{data} =
 140           $c->model('Database::Foo')->search( { country => $args[0] } );
 141         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 142             $c->forward( 'bar' ); # process another action
 143             # do something else after forward returns
 144         }
 145     }
 146
 147     # The foo.tt TT template can use the stash data from the database
 148     [% WHILE (item = data.next) %]
 149         [% item.foo %]
 150     [% END %]
 151
 152     # called for /bar/of/soap, /bar/of/soap/10, etc.
 153     sub bar : Path('/bar/of/soap') { ... }
 154
 155     # called for all actions, from the top-most controller downwards
 156     sub auto : Private {
 157         my ( $self, $c ) = @_;
 158         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 159             $c->res->redirect( '/login' ); # require login
 160             return 0; # abort request and go immediately to end()
 161         }
 162         return 1; # success; carry on to next action
 163     }
 164
 165     # called after all actions are finished
 166     sub end : Private {
 167         my ( $self, $c ) = @_;
 168         if ( scalar @{ $c->error } ) { ... } # handle errors
 169         return if $c->res->body; # already have a response
 170         $c->forward( 'MyApp::View::TT' ); # render template
 171     }
 172
 173     ### in MyApp/Controller/Foo.pm
 174     # called for /foo/bar
 175     sub bar : Local { ... }
 176
 177     # called for /blargle
 178     sub blargle : Global { ... }
 179
 180     # an index action matches /foo, but not /foo/1, etc.
 181     sub index : Private { ... }
 182
 183     ### in MyApp/Controller/Foo/Bar.pm
 184     # called for /foo/bar/baz
 185     sub baz : Local { ... }
 186
 187     # first Root auto is called, then Foo auto, then this
 188     sub auto : Private { ... }
 189
 190     # powerful regular expression paths are also possible
 191     sub details : Regex('^product/(\w+)/details$') {
 192         my ( $self, $c ) = @_;
 193         # extract the (\w+) from the URI
 194         my $product = $c->req->captures->[0];
 195     }
 196
 197 See L<Catalyst::Manual::Intro> for additional information.
 198
 199 =head1 DESCRIPTION
 200
 201 Catalyst is a modern framework for making web applications without the
 202 pain usually associated with this process. This document is a reference
 203 to the main Catalyst application. If you are a new user, we suggest you
 204 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 205
 206 See L<Catalyst::Manual> for more documentation.
 207
 208 Catalyst plugins can be loaded by naming them as arguments to the "use
 209 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 210 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 211 C<My::Module>.
 212
 213     use Catalyst qw/My::Module/;
 214
 215 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 216 fully qualify the name by using a unary plus:
 217
 218     use Catalyst qw/
 219         My::Module
 220         +Fully::Qualified::Plugin::Name
 221     /;
 222
 223 Special flags like C<-Debug> and C<-Engine> can also be specified as
 224 arguments when Catalyst is loaded:
 225
 226     use Catalyst qw/-Debug My::Module/;
 227
 228 The position of plugins and flags in the chain is important, because
 229 they are loaded in the order in which they appear.
 230
 231 The following flags are supported:
 232
 233 =head2 -Debug
 234
 235 Enables debug output. You can also force this setting from the system
 236 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 237 settings override the application, with <MYAPP>_DEBUG having the highest
 238 priority.
 239
 240 =head2 -Engine
 241
 242 Forces Catalyst to use a specific engine. Omit the
 243 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 244
 245     use Catalyst qw/-Engine=CGI/;
 246
 247 =head2 -Home
 248
 249 Forces Catalyst to use a specific home directory, e.g.:
 250
 251     use Catalyst qw[-Home=/usr/mst];
 252
 253 This can also be done in the shell environment by setting either the
 254 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 255 is replaced with the uppercased name of your application, any "::" in
 256 the name will be replaced with underscores, e.g. MyApp::Web should use
 257 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 258
 259 =head2 -Log
 260
 261     use Catalyst '-Log=warn,fatal,error';
 262
 263 Specifies a comma-delimited list of log levels.
 264
 265 =head2 -Stats
 266
 267 Enables statistics collection and reporting. You can also force this setting
 268 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 269 environment settings override the application, with <MYAPP>_STATS having the
 270 highest priority.
 271
 272 e.g.
 273
 274    use Catalyst qw/-Stats=1/
 275
 276 =head1 METHODS
 277
 278 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 279
 280 =head2 $c->action
 281
 282 Returns a L<Catalyst::Action> object for the current action, which
 283 stringifies to the action name. See L<Catalyst::Action>.
 284
 285 =head2 $c->namespace
 286
 287 Returns the namespace of the current action, i.e., the URI prefix
 288 corresponding to the controller of the current action. For example:
 289
 290     # in Controller::Foo::Bar
 291     $c->namespace; # returns 'foo/bar';
 292
 293 =head2 $c->request
 294
 295 =head2 $c->req
 296
 297 Returns the current L<Catalyst::Request> object, giving access to
 298 information about the current client request (including parameters,
 299 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 300
 301 =head2 REQUEST FLOW HANDLING
 302
 303 =head2 $c->forward( $action [, \@arguments ] )
 304
 305 =head2 $c->forward( $class, $method, [, \@arguments ] )
 306
 307 Forwards processing to another action, by its private name. If you give a
 308 class name but no method, C<process()> is called. You may also optionally
 309 pass arguments in an arrayref. The action will receive the arguments in
 310 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 311 C<< $c->req->args >> will be restored to the previous values.
 312
 313 Any data C<return>ed from the action forwarded to, will be returned by the
 314 call to forward.
 315
 316     my $foodata = $c->forward('/foo');
 317     $c->forward('index');
 318     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 319     $c->forward('MyApp::View::TT');
 320
 321 Note that forward implies an C<<eval { }>> around the call (actually
 322 C<execute> does), thus de-fatalizing all 'dies' within the called
 323 action. If you want C<die> to propagate you need to do something like:
 324
 325     $c->forward('foo');
 326     die $c->error if $c->error;
 327
 328 Or make sure to always return true values from your actions and write
 329 your code like this:
 330
 331     $c->forward('foo') || return;
 332
 333 =cut
 334
 335 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 336
 337 =head2 $c->detach( $action [, \@arguments ] )
 338
 339 =head2 $c->detach( $class, $method, [, \@arguments ] )
 340
 341 =head2 $c->detach()
 342
 343 The same as C<forward>, but doesn't return to the previous action when
 344 processing is finished.
 345
 346 When called with no arguments it escapes the processing chain entirely.
 347
 348 =cut
 349
 350 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 351
 352 =head2 $c->visit( $action [, \@arguments ] )
 353
 354 =head2 $c->visit( $class, $method, [, \@arguments ] )
 355
 356 Almost the same as C<forward>, but does a full dispatch, instead of just
 357 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 358 C<auto> and the method you go to are called, just like a new request.
 359
 360 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 361 This means, for example, that $c->action methods such as C<name>, C<class> and
 362 C<reverse> return information for the visited action when they are invoked
 363 within the visited action.  This is different from the behavior of C<forward>
 364 which continues to use the $c->action object from the caller action even when
 365 invoked from the callee.
 366
 367 C<$c-E<gt>stash> is kept unchanged.
 368
 369 In effect, C<visit> allows you to "wrap" another action, just as it
 370 would have been called by dispatching from a URL, while the analogous
 371 C<go> allows you to transfer control to another action as if it had
 372 been reached directly from a URL.
 373
 374 =cut
 375
 376 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 377
 378 =head2 $c->go( $action [, \@arguments ] )
 379
 380 =head2 $c->go( $class, $method, [, \@arguments ] )
 381
 382 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 383 instead of just calling the new C<$action> /
 384 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 385 method you visit are called, just like a new request.
 386
 387 C<$c-E<gt>stash> is kept unchanged.
 388
 389 =cut
 390
 391 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 392
 393 =head2 $c->response
 394
 395 =head2 $c->res
 396
 397 Returns the current L<Catalyst::Response> object, see there for details.
 398
 399 =head2 $c->stash
 400
 401 Returns a hashref to the stash, which may be used to store data and pass
 402 it between components during a request. You can also set hash keys by
 403 passing arguments. The stash is automatically sent to the view. The
 404 stash is cleared at the end of a request; it cannot be used for
 405 persistent storage (for this you must use a session; see
 406 L<Catalyst::Plugin::Session> for a complete system integrated with
 407 Catalyst).
 408
 409     $c->stash->{foo} = $bar;
 410     $c->stash( { moose => 'majestic', qux => 0 } );
 411     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 412
 413     # stash is automatically passed to the view for use in a template
 414     $c->forward( 'MyApp::View::TT' );
 415
 416 =cut
 417
 418 around stash => sub {
 419     my $orig = shift;
 420     my $c = shift;
 421     my $stash = $orig->($c);
 422     if (@_) {
 423         my $new_stash = @_ > 1 ? {@_} : $_[0];
 424         croak('stash takes a hash or hashref') unless ref $new_stash;
 425         foreach my $key ( keys %$new_stash ) {
 426           $stash->{$key} = $new_stash->{$key};
 427         }
 428     }
 429
 430     return $stash;
 431 };
 432
 433
 434 =head2 $c->error
 435
 436 =head2 $c->error($error, ...)
 437
 438 =head2 $c->error($arrayref)
 439
 440 Returns an arrayref containing error messages.  If Catalyst encounters an
 441 error while processing a request, it stores the error in $c->error.  This
 442 method should only be used to store fatal error messages.
 443
 444     my @error = @{ $c->error };
 445
 446 Add a new error.
 447
 448     $c->error('Something bad happened');
 449
 450 =cut
 451
 452 sub error {
 453     my $c = shift;
 454     if ( $_[0] ) {
 455         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 456         croak @$error unless ref $c;
 457         push @{ $c->{error} }, @$error;
 458     }
 459     elsif ( defined $_[0] ) { $c->{error} = undef }
 460     return $c->{error} || [];
 461 }
 462
 463
 464 =head2 $c->state
 465
 466 Contains the return value of the last executed action.
 467
 468 =head2 $c->clear_errors
 469
 470 Clear errors.  You probably don't want to clear the errors unless you are
 471 implementing a custom error screen.
 472
 473 This is equivalent to running
 474
 475     $c->error(0);
 476
 477 =cut
 478
 479 sub clear_errors {
 480     my $c = shift;
 481     $c->error(0);
 482 }
 483
 484 # search components given a name and some prefixes
 485 sub _comp_search_prefixes {
 486     my ( $c, $name, @prefixes ) = @_;
 487     my $appclass = ref $c || $c;
 488     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 489
 490     # map the original component name to the sub part that we will search against
 491     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 492         grep { /$filter/ } keys %{ $c->components };
 493
 494     # undef for a name will return all
 495     return keys %eligible if !defined $name;
 496
 497     my $query  = ref $name ? $name : qr/^$name$/i;
 498     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 499
 500     return map { $c->components->{ $_ } } @result if @result;
 501
 502     # if we were given a regexp to search against, we're done.
 503     return if ref $name;
 504
 505     # regexp fallback
 506     $query  = qr/$name/i;
 507     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 508
 509     # no results? try against full names
 510     if( !@result ) {
 511         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 512     }
 513
 514     # don't warn if we didn't find any results, it just might not exist
 515     if( @result ) {
 516         my $msg = "Used regexp fallback for \$c->model('${name}'), which found '" .
 517            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 518            "component resolution is unreliable and unsafe.";
 519         my $short = $result[0];
 520         $short =~ s/.*?Model:://;
 521         my $shortmess = Carp::shortmess('');
 522         if ($shortmess =~ m#Catalyst/Plugin#) {
 523            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 524               "plugin's config";
 525         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 526            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 527               "component's config";
 528         } else {
 529            $msg .= " You probably meant \$c->model('$short') instead of \$c->model{'${name}'}, " .
 530               "but if you really wanted to search, pass in a regexp as the argument " .
 531               "like so: \$c->model(qr/${name}/)";
 532         }
 533         $c->log->warn( "${msg}$shortmess" );
 534     }
 535
 536     return @result;
 537 }
 538
 539 # Find possible names for a prefix
 540 sub _comp_names {
 541     my ( $c, @prefixes ) = @_;
 542     my $appclass = ref $c || $c;
 543
 544     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 545
 546     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 547     return @names;
 548 }
 549
 550 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 551 sub _filter_component {
 552     my ( $c, $comp, @args ) = @_;
 553
 554     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 555         return $comp->ACCEPT_CONTEXT( $c, @args );
 556     }
 557
 558     return $comp;
 559 }
 560
 561 =head2 COMPONENT ACCESSORS
 562
 563 =head2 $c->controller($name)
 564
 565 Gets a L<Catalyst::Controller> instance by name.
 566
 567     $c->controller('Foo')->do_stuff;
 568
 569 If the name is omitted, will return the controller for the dispatched
 570 action.
 571
 572 If you want to search for controllers, pass in a regexp as the argument.
 573
 574     # find all controllers that start with Foo
 575     my @foo_controllers = $c->controller(qr{^Foo});
 576
 577
 578 =cut
 579
 580 sub controller {
 581     my ( $c, $name, @args ) = @_;
 582
 583     if( $name ) {
 584         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 585         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 586         return $c->_filter_component( $result[ 0 ], @args );
 587     }
 588
 589     return $c->component( $c->action->class );
 590 }
 591
 592 =head2 $c->model($name)
 593
 594 Gets a L<Catalyst::Model> instance by name.
 595
 596     $c->model('Foo')->do_stuff;
 597
 598 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 599
 600 If the name is omitted, it will look for
 601  - a model object in $c->stash->{current_model_instance}, then
 602  - a model name in $c->stash->{current_model}, then
 603  - a config setting 'default_model', or
 604  - check if there is only one model, and return it if that's the case.
 605
 606 If you want to search for models, pass in a regexp as the argument.
 607
 608     # find all models that start with Foo
 609     my @foo_models = $c->model(qr{^Foo});
 610
 611 =cut
 612
 613 sub model {
 614     my ( $c, $name, @args ) = @_;
 615
 616     if( $name ) {
 617         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 618         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 619         return $c->_filter_component( $result[ 0 ], @args );
 620     }
 621
 622     if (ref $c) {
 623         return $c->stash->{current_model_instance}
 624           if $c->stash->{current_model_instance};
 625         return $c->model( $c->stash->{current_model} )
 626           if $c->stash->{current_model};
 627     }
 628     return $c->model( $c->config->{default_model} )
 629       if $c->config->{default_model};
 630
 631     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 632
 633     if( $rest ) {
 634         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 635         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 636         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 637         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 638         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 639     }
 640
 641     return $c->_filter_component( $comp );
 642 }
 643
 644
 645 =head2 $c->view($name)
 646
 647 Gets a L<Catalyst::View> instance by name.
 648
 649     $c->view('Foo')->do_stuff;
 650
 651 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 652
 653 If the name is omitted, it will look for
 654  - a view object in $c->stash->{current_view_instance}, then
 655  - a view name in $c->stash->{current_view}, then
 656  - a config setting 'default_view', or
 657  - check if there is only one view, and return it if that's the case.
 658
 659 If you want to search for views, pass in a regexp as the argument.
 660
 661     # find all views that start with Foo
 662     my @foo_views = $c->view(qr{^Foo});
 663
 664 =cut
 665
 666 sub view {
 667     my ( $c, $name, @args ) = @_;
 668
 669     if( $name ) {
 670         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 671         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 672         return $c->_filter_component( $result[ 0 ], @args );
 673     }
 674
 675     if (ref $c) {
 676         return $c->stash->{current_view_instance}
 677           if $c->stash->{current_view_instance};
 678         return $c->view( $c->stash->{current_view} )
 679           if $c->stash->{current_view};
 680     }
 681     return $c->view( $c->config->{default_view} )
 682       if $c->config->{default_view};
 683
 684     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 685
 686     if( $rest ) {
 687         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 688         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 689         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 690         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 691         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 692     }
 693
 694     return $c->_filter_component( $comp );
 695 }
 696
 697 =head2 $c->controllers
 698
 699 Returns the available names which can be passed to $c->controller
 700
 701 =cut
 702
 703 sub controllers {
 704     my ( $c ) = @_;
 705     return $c->_comp_names(qw/Controller C/);
 706 }
 707
 708 =head2 $c->models
 709
 710 Returns the available names which can be passed to $c->model
 711
 712 =cut
 713
 714 sub models {
 715     my ( $c ) = @_;
 716     return $c->_comp_names(qw/Model M/);
 717 }
 718
 719
 720 =head2 $c->views
 721
 722 Returns the available names which can be passed to $c->view
 723
 724 =cut
 725
 726 sub views {
 727     my ( $c ) = @_;
 728     return $c->_comp_names(qw/View V/);
 729 }
 730
 731 =head2 $c->comp($name)
 732
 733 =head2 $c->component($name)
 734
 735 Gets a component object by name. This method is not recommended,
 736 unless you want to get a specific component by full
 737 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 738 should be used instead.
 739
 740 If C<$name> is a regexp, a list of components matched against the full
 741 component name will be returned.
 742
 743 =cut
 744
 745 sub component {
 746     my ( $c, $name, @args ) = @_;
 747
 748     if( $name ) {
 749         my $comps = $c->components;
 750
 751         if( !ref $name ) {
 752             # is it the exact name?
 753             return $c->_filter_component( $comps->{ $name }, @args )
 754                        if exists $comps->{ $name };
 755
 756             # perhaps we just omitted "MyApp"?
 757             my $composed = ( ref $c || $c ) . "::${name}";
 758             return $c->_filter_component( $comps->{ $composed }, @args )
 759                        if exists $comps->{ $composed };
 760
 761             # search all of the models, views and controllers
 762             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 763             return $c->_filter_component( $comp, @args ) if $comp;
 764         }
 765
 766         # This is here so $c->comp( '::M::' ) works
 767         my $query = ref $name ? $name : qr{$name}i;
 768
 769         my @result = grep { m{$query} } keys %{ $c->components };
 770         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 771
 772         if( $result[ 0 ] ) {
 773             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 774             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 775             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 776             return $c->_filter_component( $result[ 0 ], @args );
 777         }
 778
 779         # I would expect to return an empty list here, but that breaks back-compat
 780     }
 781
 782     # fallback
 783     return sort keys %{ $c->components };
 784 }
 785
 786 =head2 CLASS DATA AND HELPER CLASSES
 787
 788 =head2 $c->config
 789
 790 Returns or takes a hashref containing the application's configuration.
 791
 792     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 793
 794 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 795 like myapp.yml in your applications home directory. See
 796 L<Catalyst::Plugin::ConfigLoader>.
 797
 798     ---
 799     db: dsn:SQLite:foo.db
 800
 801
 802 =cut
 803
 804 around config => sub {
 805     my $orig = shift;
 806     my $c = shift;
 807
 808     $c->log->warn("Setting config after setup has been run is not a good idea.")
 809       if ( @_ and $c->setup_finished );
 810
 811     $c->$orig(@_);
 812 };
 813
 814 =head2 $c->log
 815
 816 Returns the logging object instance. Unless it is already set, Catalyst
 817 sets this up with a L<Catalyst::Log> object. To use your own log class,
 818 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 819 C<< __PACKAGE__->setup >>.
 820
 821  __PACKAGE__->log( MyLogger->new );
 822  __PACKAGE__->setup;
 823
 824 And later:
 825
 826     $c->log->info( 'Now logging with my own logger!' );
 827
 828 Your log class should implement the methods described in
 829 L<Catalyst::Log>.
 830
 831
 832 =head2 $c->debug
 833
 834 Overload to enable debug messages (same as -Debug option).
 835
 836 Note that this is a static method, not an accessor and should be overloaded
 837 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 838
 839 =cut
 840
 841 sub debug { 0 }
 842
 843 =head2 $c->dispatcher
 844
 845 Returns the dispatcher instance. Stringifies to class name. See
 846 L<Catalyst::Dispatcher>.
 847
 848 =head2 $c->engine
 849
 850 Returns the engine instance. Stringifies to the class name. See
 851 L<Catalyst::Engine>.
 852
 853
 854 =head2 UTILITY METHODS
 855
 856 =head2 $c->path_to(@path)
 857
 858 Merges C<@path> with C<< $c->config->{home} >> and returns a
 859 L<Path::Class::Dir> object.
 860
 861 For example:
 862
 863     $c->path_to( 'db', 'sqlite.db' );
 864
 865 =cut
 866
 867 sub path_to {
 868     my ( $c, @path ) = @_;
 869     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 870     if ( -d $path ) { return $path }
 871     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 872 }
 873
 874 =head2 $c->plugin( $name, $class, @args )
 875
 876 Helper method for plugins. It creates a classdata accessor/mutator and
 877 loads and instantiates the given class.
 878
 879     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 880
 881     $c->prototype->define_javascript_functions;
 882
 883 B<Note:> This method of adding plugins is deprecated. The ability
 884 to add plugins like this B<will be removed> in a Catalyst 5.9.
 885 Please do not use this functionality in new code.
 886
 887 =cut
 888
 889 sub plugin {
 890     my ( $class, $name, $plugin, @args ) = @_;
 891
 892     # See block comment in t/unit_core_plugin.t
 893     $class->log->debug(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.9/);
 894
 895     $class->_register_plugin( $plugin, 1 );
 896
 897     eval { $plugin->import };
 898     $class->mk_classdata($name);
 899     my $obj;
 900     eval { $obj = $plugin->new(@args) };
 901
 902     if ($@) {
 903         Catalyst::Exception->throw( message =>
 904               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 905     }
 906
 907     $class->$name($obj);
 908     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 909       if $class->debug;
 910 }
 911
 912 =head2 MyApp->setup
 913
 914 Initializes the dispatcher and engine, loads any plugins, and loads the
 915 model, view, and controller components. You may also specify an array
 916 of plugins to load here, if you choose to not load them in the C<use
 917 Catalyst> line.
 918
 919     MyApp->setup;
 920     MyApp->setup( qw/-Debug/ );
 921
 922 =cut
 923
 924 sub setup {
 925     my ( $class, @arguments ) = @_;
 926     $class->log->warn("Running setup twice is not a good idea.")
 927       if ( $class->setup_finished );
 928
 929     unless ( $class->isa('Catalyst') ) {
 930
 931         Catalyst::Exception->throw(
 932             message => qq/'$class' does not inherit from Catalyst/ );
 933     }
 934
 935     if ( $class->arguments ) {
 936         @arguments = ( @arguments, @{ $class->arguments } );
 937     }
 938
 939     # Process options
 940     my $flags = {};
 941
 942     foreach (@arguments) {
 943
 944         if (/^-Debug$/) {
 945             $flags->{log} =
 946               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 947         }
 948         elsif (/^-(\w+)=?(.*)$/) {
 949             $flags->{ lc $1 } = $2;
 950         }
 951         else {
 952             push @{ $flags->{plugins} }, $_;
 953         }
 954     }
 955
 956     $class->setup_home( delete $flags->{home} );
 957
 958     $class->setup_log( delete $flags->{log} );
 959     $class->setup_plugins( delete $flags->{plugins} );
 960     $class->setup_dispatcher( delete $flags->{dispatcher} );
 961     $class->setup_engine( delete $flags->{engine} );
 962     $class->setup_stats( delete $flags->{stats} );
 963
 964     for my $flag ( sort keys %{$flags} ) {
 965
 966         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 967             &$code( $class, delete $flags->{$flag} );
 968         }
 969         else {
 970             $class->log->warn(qq/Unknown flag "$flag"/);
 971         }
 972     }
 973
 974     eval { require Catalyst::Devel; };
 975     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 976         $class->log->warn(<<"EOF");
 977 You are running an old script!
 978
 979   Please update by running (this will overwrite existing files):
 980     catalyst.pl -force -scripts $class
 981
 982   or (this will not overwrite existing files):
 983     catalyst.pl -scripts $class
 984
 985 EOF
 986     }
 987
 988     if ( $class->debug ) {
 989         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 990
 991         if (@plugins) {
 992             my $t = Text::SimpleTable->new(74);
 993             $t->row($_) for @plugins;
 994             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 995         }
 996
 997         my $dispatcher = $class->dispatcher;
 998         my $engine     = $class->engine;
 999         my $home       = $class->config->{home};
1000
1001         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1002         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1003
1004         $home
1005           ? ( -d $home )
1006           ? $class->log->debug(qq/Found home "$home"/)
1007           : $class->log->debug(qq/Home "$home" doesn't exist/)
1008           : $class->log->debug(q/Couldn't find home/);
1009     }
1010
1011     # Call plugins setup, this is stupid and evil.
1012     {
1013         no warnings qw/redefine/;
1014         local *setup = sub { };
1015         $class->setup;
1016     }
1017
1018     # Initialize our data structure
1019     $class->components( {} );
1020
1021     $class->setup_components;
1022
1023     if ( $class->debug ) {
1024         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
1025         for my $comp ( sort keys %{ $class->components } ) {
1026             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1027             $t->row( $comp, $type );
1028         }
1029         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1030           if ( keys %{ $class->components } );
1031     }
1032
1033     # Add our self to components, since we are also a component
1034     if( $class->isa('Catalyst::Controller') ){
1035       $class->components->{$class} = $class;
1036     }
1037
1038     $class->setup_actions;
1039
1040     if ( $class->debug ) {
1041         my $name = $class->config->{name} || 'Application';
1042         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1043     }
1044     $class->log->_flush() if $class->log->can('_flush');
1045
1046     # Make sure that the application class becomes immutable at this point,
1047     # which ensures that it gets an inlined constructor. This means that it
1048     # works even if the user has added a plugin which contains a new method.
1049     # Note however that we have to do the work on scope end, so that method
1050     # modifiers work correctly in MyApp (as you have to call setup _before_
1051     # applying modifiers).
1052     Scope::Upper::reap(sub {
1053         my $meta = Class::MOP::get_metaclass_by_name($class);
1054         $meta->make_immutable unless $meta->is_immutable;
1055     }, Scope::Upper::SCOPE(1));
1056
1057     $class->setup_finalize;
1058 }
1059
1060 sub setup_finalize {
1061     my ($class) = @_;
1062     $class->setup_finished(1);
1063 }
1064
1065 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1066
1067 =head2 $c->uri_for( $path, @args?, \%query_values? )
1068
1069 =over
1070
1071 =item $action
1072
1073 A Catalyst::Action object representing the Catalyst action you want to
1074 create a URI for. To get one for an action in the current controller,
1075 use C<< $c->action('someactionname') >>. To get one from different
1076 controller, fetch the controller using C<< $c->controller() >>, then
1077 call C<action_for> on it.
1078
1079 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1080 using C<< $c->req->captures >>.
1081
1082   # For the current action
1083   $c->uri_for($c->action, $c->req->captures);
1084
1085   # For the Foo action in the Bar controller
1086   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1087
1088 =back
1089
1090 =cut
1091
1092 sub uri_for {
1093     my ( $c, $path, @args ) = @_;
1094
1095     if ( Scalar::Util::blessed($path) ) { # action object
1096         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1097                          ? shift(@args)
1098                          : [] );
1099         $path = $c->dispatcher->uri_for_action($path, $captures);
1100         return undef unless defined($path);
1101         $path = '/' if $path eq '';
1102     }
1103
1104     undef($path) if (defined $path && $path eq '');
1105
1106     my $params =
1107       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1108
1109     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1110     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1111
1112     unshift(@args, $path);
1113
1114     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1115         my $namespace = $c->namespace;
1116         if (defined $path) { # cheesy hack to handle path '../foo'
1117            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1118         }
1119         unshift(@args, $namespace || '');
1120     }
1121
1122     # join args with '/', or a blank string
1123     my $args = join('/', grep { defined($_) } @args);
1124     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1125     $args =~ s!^/+!!;
1126     my $base = $c->req->base;
1127     my $class = ref($base);
1128     $base =~ s{(?<!/)$}{/};
1129
1130     my $query = '';
1131
1132     if (my @keys = keys %$params) {
1133       # somewhat lifted from URI::_query's query_form
1134       $query = '?'.join('&', map {
1135           my $val = $params->{$_};
1136           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1137           s/ /+/g;
1138           my $key = $_;
1139           $val = '' unless defined $val;
1140           (map {
1141               $_ = "$_";
1142               utf8::encode( $_ ) if utf8::is_utf8($_);
1143               # using the URI::Escape pattern here so utf8 chars survive
1144               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1145               s/ /+/g;
1146               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1147       } @keys);
1148     }
1149
1150     my $res = bless(\"${base}${args}${query}", $class);
1151     $res;
1152 }
1153
1154 =head2 $c->welcome_message
1155
1156 Returns the Catalyst welcome HTML page.
1157
1158 =cut
1159
1160 sub welcome_message {
1161     my $c      = shift;
1162     my $name   = $c->config->{name};
1163     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1164     my $prefix = Catalyst::Utils::appprefix( ref $c );
1165     $c->response->content_type('text/html; charset=utf-8');
1166     return <<"EOF";
1167 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1168     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1169 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1170     <head>
1171     <meta http-equiv="Content-Language" content="en" />
1172     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1173         <title>$name on Catalyst $VERSION</title>
1174         <style type="text/css">
1175             body {
1176                 color: #000;
1177                 background-color: #eee;
1178             }
1179             div#content {
1180                 width: 640px;
1181                 margin-left: auto;
1182                 margin-right: auto;
1183                 margin-top: 10px;
1184                 margin-bottom: 10px;
1185                 text-align: left;
1186                 background-color: #ccc;
1187                 border: 1px solid #aaa;
1188             }
1189             p, h1, h2 {
1190                 margin-left: 20px;
1191                 margin-right: 20px;
1192                 font-family: verdana, tahoma, sans-serif;
1193             }
1194             a {
1195                 font-family: verdana, tahoma, sans-serif;
1196             }
1197             :link, :visited {
1198                     text-decoration: none;
1199                     color: #b00;
1200                     border-bottom: 1px dotted #bbb;
1201             }
1202             :link:hover, :visited:hover {
1203                     color: #555;
1204             }
1205             div#topbar {
1206                 margin: 0px;
1207             }
1208             pre {
1209                 margin: 10px;
1210                 padding: 8px;
1211             }
1212             div#answers {
1213                 padding: 8px;
1214                 margin: 10px;
1215                 background-color: #fff;
1216                 border: 1px solid #aaa;
1217             }
1218             h1 {
1219                 font-size: 0.9em;
1220                 font-weight: normal;
1221                 text-align: center;
1222             }
1223             h2 {
1224                 font-size: 1.0em;
1225             }
1226             p {
1227                 font-size: 0.9em;
1228             }
1229             p img {
1230                 float: right;
1231                 margin-left: 10px;
1232             }
1233             span#appname {
1234                 font-weight: bold;
1235                 font-size: 1.6em;
1236             }
1237         </style>
1238     </head>
1239     <body>
1240         <div id="content">
1241             <div id="topbar">
1242                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1243                     $VERSION</h1>
1244              </div>
1245              <div id="answers">
1246                  <p>
1247                  <img src="$logo" alt="Catalyst Logo" />
1248                  </p>
1249                  <p>Welcome to the  world of Catalyst.
1250                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1251                     framework will make web development something you had
1252                     never expected it to be: Fun, rewarding, and quick.</p>
1253                  <h2>What to do now?</h2>
1254                  <p>That really depends  on what <b>you</b> want to do.
1255                     We do, however, provide you with a few starting points.</p>
1256                  <p>If you want to jump right into web development with Catalyst
1257                     you might want to start with a tutorial.</p>
1258 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1259 </pre>
1260 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1261 <pre>
1262 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1263 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1264 </code></pre>
1265                  <h2>What to do next?</h2>
1266                  <p>Next it's time to write an actual application. Use the
1267                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1268                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1269                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1270                     they can save you a lot of work.</p>
1271                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1272                     <p>Also, be sure to check out the vast and growing
1273                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1274                     you are likely to find what you need there.
1275                     </p>
1276
1277                  <h2>Need help?</h2>
1278                  <p>Catalyst has a very active community. Here are the main places to
1279                     get in touch with us.</p>
1280                  <ul>
1281                      <li>
1282                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1283                      </li>
1284                      <li>
1285                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1286                      </li>
1287                      <li>
1288                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1289                      </li>
1290                  </ul>
1291                  <h2>In conclusion</h2>
1292                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1293                     as we enjoyed making it. Please contact us if you have ideas
1294                     for improvement or other feedback.</p>
1295              </div>
1296          </div>
1297     </body>
1298 </html>
1299 EOF
1300 }
1301
1302 =head1 INTERNAL METHODS
1303
1304 These methods are not meant to be used by end users.
1305
1306 =head2 $c->components
1307
1308 Returns a hash of components.
1309
1310 =head2 $c->context_class
1311
1312 Returns or sets the context class.
1313
1314 =head2 $c->counter
1315
1316 Returns a hashref containing coderefs and execution counts (needed for
1317 deep recursion detection).
1318
1319 =head2 $c->depth
1320
1321 Returns the number of actions on the current internal execution stack.
1322
1323 =head2 $c->dispatch
1324
1325 Dispatches a request to actions.
1326
1327 =cut
1328
1329 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1330
1331 =head2 $c->dispatcher_class
1332
1333 Returns or sets the dispatcher class.
1334
1335 =head2 $c->dump_these
1336
1337 Returns a list of 2-element array references (name, structure) pairs
1338 that will be dumped on the error page in debug mode.
1339
1340 =cut
1341
1342 sub dump_these {
1343     my $c = shift;
1344     [ Request => $c->req ],
1345     [ Response => $c->res ],
1346     [ Stash => $c->stash ],
1347     [ Config => $c->config ];
1348 }
1349
1350 =head2 $c->engine_class
1351
1352 Returns or sets the engine class.
1353
1354 =head2 $c->execute( $class, $coderef )
1355
1356 Execute a coderef in given class and catch exceptions. Errors are available
1357 via $c->error.
1358
1359 =cut
1360
1361 sub execute {
1362     my ( $c, $class, $code ) = @_;
1363     $class = $c->component($class) || $class;
1364     $c->state(0);
1365
1366     if ( $c->depth >= $RECURSION ) {
1367         my $action = $code->reverse();
1368         $action = "/$action" unless $action =~ /->/;
1369         my $error = qq/Deep recursion detected calling "${action}"/;
1370         $c->log->error($error);
1371         $c->error($error);
1372         $c->state(0);
1373         return $c->state;
1374     }
1375
1376     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1377
1378     push( @{ $c->stack }, $code );
1379
1380     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1381
1382     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1383
1384     my $last = pop( @{ $c->stack } );
1385
1386     if ( my $error = $@ ) {
1387         if ( !ref($error) and $error eq $DETACH ) {
1388             die $DETACH if($c->depth > 1);
1389         }
1390         elsif ( !ref($error) and $error eq $GO ) {
1391             die $GO if($c->depth > 0);
1392         }
1393         else {
1394             unless ( ref $error ) {
1395                 no warnings 'uninitialized';
1396                 chomp $error;
1397                 my $class = $last->class;
1398                 my $name  = $last->name;
1399                 $error = qq/Caught exception in $class->$name "$error"/;
1400             }
1401             $c->error($error);
1402             $c->state(0);
1403         }
1404     }
1405     return $c->state;
1406 }
1407
1408 sub _stats_start_execute {
1409     my ( $c, $code ) = @_;
1410
1411     return if ( ( $code->name =~ /^_.*/ )
1412         && ( !$c->config->{show_internal_actions} ) );
1413
1414     my $action_name = $code->reverse();
1415     $c->counter->{$action_name}++;
1416
1417     my $action = $action_name;
1418     $action = "/$action" unless $action =~ /->/;
1419
1420     # determine if the call was the result of a forward
1421     # this is done by walking up the call stack and looking for a calling
1422     # sub of Catalyst::forward before the eval
1423     my $callsub = q{};
1424     for my $index ( 2 .. 11 ) {
1425         last
1426         if ( ( caller($index) )[0] eq 'Catalyst'
1427             && ( caller($index) )[3] eq '(eval)' );
1428
1429         if ( ( caller($index) )[3] =~ /forward$/ ) {
1430             $callsub = ( caller($index) )[3];
1431             $action  = "-> $action";
1432             last;
1433         }
1434     }
1435
1436     my $uid = $action_name . $c->counter->{$action_name};
1437
1438     # is this a root-level call or a forwarded call?
1439     if ( $callsub =~ /forward$/ ) {
1440
1441         # forward, locate the caller
1442         if ( my $parent = $c->stack->[-1] ) {
1443             $c->stats->profile(
1444                 begin  => $action,
1445                 parent => "$parent" . $c->counter->{"$parent"},
1446                 uid    => $uid,
1447             );
1448         }
1449         else {
1450
1451             # forward with no caller may come from a plugin
1452             $c->stats->profile(
1453                 begin => $action,
1454                 uid   => $uid,
1455             );
1456         }
1457     }
1458     else {
1459
1460         # root-level call
1461         $c->stats->profile(
1462             begin => $action,
1463             uid   => $uid,
1464         );
1465     }
1466     return $action;
1467
1468 }
1469
1470 sub _stats_finish_execute {
1471     my ( $c, $info ) = @_;
1472     $c->stats->profile( end => $info );
1473 }
1474
1475 =head2 $c->_localize_fields( sub { }, \%keys );
1476
1477 =cut
1478
1479 #Why does this exist? This is no longer safe and WILL NOT WORK.
1480 # it doesnt seem to be used anywhere. can we remove it?
1481 sub _localize_fields {
1482     my ( $c, $localized, $code ) = ( @_ );
1483
1484     my $request = delete $localized->{request} || {};
1485     my $response = delete $localized->{response} || {};
1486
1487     local @{ $c }{ keys %$localized } = values %$localized;
1488     local @{ $c->request }{ keys %$request } = values %$request;
1489     local @{ $c->response }{ keys %$response } = values %$response;
1490
1491     $code->();
1492 }
1493
1494 =head2 $c->finalize
1495
1496 Finalizes the request.
1497
1498 =cut
1499
1500 sub finalize {
1501     my $c = shift;
1502
1503     for my $error ( @{ $c->error } ) {
1504         $c->log->error($error);
1505     }
1506
1507     # Allow engine to handle finalize flow (for POE)
1508     my $engine = $c->engine;
1509     if ( my $code = $engine->can('finalize') ) {
1510         $engine->$code($c);
1511     }
1512     else {
1513
1514         $c->finalize_uploads;
1515
1516         # Error
1517         if ( $#{ $c->error } >= 0 ) {
1518             $c->finalize_error;
1519         }
1520
1521         $c->finalize_headers;
1522
1523         # HEAD request
1524         if ( $c->request->method eq 'HEAD' ) {
1525             $c->response->body('');
1526         }
1527
1528         $c->finalize_body;
1529     }
1530
1531     if ($c->use_stats) {
1532         my $elapsed = sprintf '%f', $c->stats->elapsed;
1533         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1534         $c->log->info(
1535             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1536     }
1537
1538     return $c->response->status;
1539 }
1540
1541 =head2 $c->finalize_body
1542
1543 Finalizes body.
1544
1545 =cut
1546
1547 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1548
1549 =head2 $c->finalize_cookies
1550
1551 Finalizes cookies.
1552
1553 =cut
1554
1555 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1556
1557 =head2 $c->finalize_error
1558
1559 Finalizes error.
1560
1561 =cut
1562
1563 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1564
1565 =head2 $c->finalize_headers
1566
1567 Finalizes headers.
1568
1569 =cut
1570
1571 sub finalize_headers {
1572     my $c = shift;
1573
1574     my $response = $c->response; #accessor calls can add up?
1575
1576     # Check if we already finalized headers
1577     return if $response->finalized_headers;
1578
1579     # Handle redirects
1580     if ( my $location = $response->redirect ) {
1581         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1582         $response->header( Location => $location );
1583
1584         if ( !$response->has_body ) {
1585             # Add a default body if none is already present
1586             $response->body(
1587                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1588             );
1589         }
1590     }
1591
1592     # Content-Length
1593     if ( $response->body && !$response->content_length ) {
1594
1595         # get the length from a filehandle
1596         if ( blessed( $response->body ) && $response->body->can('read') )
1597         {
1598             my $stat = stat $response->body;
1599             if ( $stat && $stat->size > 0 ) {
1600                 $response->content_length( $stat->size );
1601             }
1602             else {
1603                 $c->log->warn('Serving filehandle without a content-length');
1604             }
1605         }
1606         else {
1607             # everything should be bytes at this point, but just in case
1608             $response->content_length( bytes::length( $response->body ) );
1609         }
1610     }
1611
1612     # Errors
1613     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1614         $response->headers->remove_header("Content-Length");
1615         $response->body('');
1616     }
1617
1618     $c->finalize_cookies;
1619
1620     $c->engine->finalize_headers( $c, @_ );
1621
1622     # Done
1623     $response->finalized_headers(1);
1624 }
1625
1626 =head2 $c->finalize_output
1627
1628 An alias for finalize_body.
1629
1630 =head2 $c->finalize_read
1631
1632 Finalizes the input after reading is complete.
1633
1634 =cut
1635
1636 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1637
1638 =head2 $c->finalize_uploads
1639
1640 Finalizes uploads. Cleans up any temporary files.
1641
1642 =cut
1643
1644 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1645
1646 =head2 $c->get_action( $action, $namespace )
1647
1648 Gets an action in a given namespace.
1649
1650 =cut
1651
1652 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1653
1654 =head2 $c->get_actions( $action, $namespace )
1655
1656 Gets all actions of a given name in a namespace and all parent
1657 namespaces.
1658
1659 =cut
1660
1661 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1662
1663 =head2 $c->handle_request( $class, @arguments )
1664
1665 Called to handle each HTTP request.
1666
1667 =cut
1668
1669 sub handle_request {
1670     my ( $class, @arguments ) = @_;
1671
1672     # Always expect worst case!
1673     my $status = -1;
1674     eval {
1675         if ($class->debug) {
1676             my $secs = time - $START || 1;
1677             my $av = sprintf '%.3f', $COUNT / $secs;
1678             my $time = localtime time;
1679             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1680         }
1681
1682         my $c = $class->prepare(@arguments);
1683         $c->dispatch;
1684         $status = $c->finalize;
1685     };
1686
1687     if ( my $error = $@ ) {
1688         chomp $error;
1689         $class->log->error(qq/Caught exception in engine "$error"/);
1690     }
1691
1692     $COUNT++;
1693
1694     if(my $coderef = $class->log->can('_flush')){
1695         $class->log->$coderef();
1696     }
1697     return $status;
1698 }
1699
1700 =head2 $c->prepare( @arguments )
1701
1702 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1703 etc.).
1704
1705 =cut
1706
1707 sub prepare {
1708     my ( $class, @arguments ) = @_;
1709
1710     # XXX
1711     # After the app/ctxt split, this should become an attribute based on something passed
1712     # into the application.
1713     $class->context_class( ref $class || $class ) unless $class->context_class;
1714
1715     my $c = $class->context_class->new({});
1716
1717     # For on-demand data
1718     $c->request->_context($c);
1719     $c->response->_context($c);
1720
1721     #surely this is not the most efficient way to do things...
1722     $c->stats($class->stats_class->new)->enable($c->use_stats);
1723     if ( $c->debug ) {
1724         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1725     }
1726
1727     #XXX reuse coderef from can
1728     # Allow engine to direct the prepare flow (for POE)
1729     if ( $c->engine->can('prepare') ) {
1730         $c->engine->prepare( $c, @arguments );
1731     }
1732     else {
1733         $c->prepare_request(@arguments);
1734         $c->prepare_connection;
1735         $c->prepare_query_parameters;
1736         $c->prepare_headers;
1737         $c->prepare_cookies;
1738         $c->prepare_path;
1739
1740         # Prepare the body for reading, either by prepare_body
1741         # or the user, if they are using $c->read
1742         $c->prepare_read;
1743
1744         # Parse the body unless the user wants it on-demand
1745         unless ( $c->config->{parse_on_demand} ) {
1746             $c->prepare_body;
1747         }
1748     }
1749
1750     my $method  = $c->req->method  || '';
1751     my $path    = $c->req->path;
1752     $path       = '/' unless length $path;
1753     my $address = $c->req->address || '';
1754
1755     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1756       if $c->debug;
1757
1758     $c->prepare_action;
1759
1760     return $c;
1761 }
1762
1763 =head2 $c->prepare_action
1764
1765 Prepares action. See L<Catalyst::Dispatcher>.
1766
1767 =cut
1768
1769 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1770
1771 =head2 $c->prepare_body
1772
1773 Prepares message body.
1774
1775 =cut
1776
1777 sub prepare_body {
1778     my $c = shift;
1779
1780     return if $c->request->_has_body;
1781
1782     # Initialize on-demand data
1783     $c->engine->prepare_body( $c, @_ );
1784     $c->prepare_parameters;
1785     $c->prepare_uploads;
1786
1787     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1788         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1789         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1790             my $param = $c->req->body_parameters->{$key};
1791             my $value = defined($param) ? $param : '';
1792             $t->row( $key,
1793                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1794         }
1795         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1796     }
1797 }
1798
1799 =head2 $c->prepare_body_chunk( $chunk )
1800
1801 Prepares a chunk of data before sending it to L<HTTP::Body>.
1802
1803 See L<Catalyst::Engine>.
1804
1805 =cut
1806
1807 sub prepare_body_chunk {
1808     my $c = shift;
1809     $c->engine->prepare_body_chunk( $c, @_ );
1810 }
1811
1812 =head2 $c->prepare_body_parameters
1813
1814 Prepares body parameters.
1815
1816 =cut
1817
1818 sub prepare_body_parameters {
1819     my $c = shift;
1820     $c->engine->prepare_body_parameters( $c, @_ );
1821 }
1822
1823 =head2 $c->prepare_connection
1824
1825 Prepares connection.
1826
1827 =cut
1828
1829 sub prepare_connection {
1830     my $c = shift;
1831     $c->engine->prepare_connection( $c, @_ );
1832 }
1833
1834 =head2 $c->prepare_cookies
1835
1836 Prepares cookies.
1837
1838 =cut
1839
1840 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1841
1842 =head2 $c->prepare_headers
1843
1844 Prepares headers.
1845
1846 =cut
1847
1848 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1849
1850 =head2 $c->prepare_parameters
1851
1852 Prepares parameters.
1853
1854 =cut
1855
1856 sub prepare_parameters {
1857     my $c = shift;
1858     $c->prepare_body_parameters;
1859     $c->engine->prepare_parameters( $c, @_ );
1860 }
1861
1862 =head2 $c->prepare_path
1863
1864 Prepares path and base.
1865
1866 =cut
1867
1868 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1869
1870 =head2 $c->prepare_query_parameters
1871
1872 Prepares query parameters.
1873
1874 =cut
1875
1876 sub prepare_query_parameters {
1877     my $c = shift;
1878
1879     $c->engine->prepare_query_parameters( $c, @_ );
1880
1881     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1882         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1883         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1884             my $param = $c->req->query_parameters->{$key};
1885             my $value = defined($param) ? $param : '';
1886             $t->row( $key,
1887                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1888         }
1889         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1890     }
1891 }
1892
1893 =head2 $c->prepare_read
1894
1895 Prepares the input for reading.
1896
1897 =cut
1898
1899 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1900
1901 =head2 $c->prepare_request
1902
1903 Prepares the engine request.
1904
1905 =cut
1906
1907 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1908
1909 =head2 $c->prepare_uploads
1910
1911 Prepares uploads.
1912
1913 =cut
1914
1915 sub prepare_uploads {
1916     my $c = shift;
1917
1918     $c->engine->prepare_uploads( $c, @_ );
1919
1920     if ( $c->debug && keys %{ $c->request->uploads } ) {
1921         my $t = Text::SimpleTable->new(
1922             [ 12, 'Parameter' ],
1923             [ 26, 'Filename' ],
1924             [ 18, 'Type' ],
1925             [ 9,  'Size' ]
1926         );
1927         for my $key ( sort keys %{ $c->request->uploads } ) {
1928             my $upload = $c->request->uploads->{$key};
1929             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1930                 $t->row( $key, $u->filename, $u->type, $u->size );
1931             }
1932         }
1933         $c->log->debug( "File Uploads are:\n" . $t->draw );
1934     }
1935 }
1936
1937 =head2 $c->prepare_write
1938
1939 Prepares the output for writing.
1940
1941 =cut
1942
1943 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1944
1945 =head2 $c->request_class
1946
1947 Returns or sets the request class.
1948
1949 =head2 $c->response_class
1950
1951 Returns or sets the response class.
1952
1953 =head2 $c->read( [$maxlength] )
1954
1955 Reads a chunk of data from the request body. This method is designed to
1956 be used in a while loop, reading C<$maxlength> bytes on every call.
1957 C<$maxlength> defaults to the size of the request if not specified.
1958
1959 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1960 directly.
1961
1962 Warning: If you use read(), Catalyst will not process the body,
1963 so you will not be able to access POST parameters or file uploads via
1964 $c->request.  You must handle all body parsing yourself.
1965
1966 =cut
1967
1968 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1969
1970 =head2 $c->run
1971
1972 Starts the engine.
1973
1974 =cut
1975
1976 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1977
1978 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1979
1980 Sets an action in a given namespace.
1981
1982 =cut
1983
1984 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1985
1986 =head2 $c->setup_actions($component)
1987
1988 Sets up actions for a component.
1989
1990 =cut
1991
1992 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1993
1994 =head2 $c->setup_components
1995
1996 Sets up components. Specify a C<setup_components> config option to pass
1997 additional options directly to L<Module::Pluggable>. To add additional
1998 search paths, specify a key named C<search_extra> as an array
1999 reference. Items in the array beginning with C<::> will have the
2000 application class name prepended to them.
2001
2002 All components found will also have any
2003 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2004 Note, that modules which are B<not> an I<inner package> of the main
2005 file namespace loaded will not be instantiated as components.
2006
2007 =cut
2008
2009 sub setup_components {
2010     my $class = shift;
2011
2012     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2013     my $config  = $class->config->{ setup_components };
2014     my $extra   = delete $config->{ search_extra } || [];
2015
2016     push @paths, @$extra;
2017
2018     my $locator = Module::Pluggable::Object->new(
2019         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2020         %$config
2021     );
2022
2023     my @comps = sort { length $a <=> length $b } $locator->plugins;
2024     my %comps = map { $_ => 1 } @comps;
2025
2026     for my $component ( @comps ) {
2027
2028         # We pass ignore_loaded here so that overlay files for (e.g.)
2029         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2030         # we know M::P::O found a file on disk so this is safe
2031
2032         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2033         #Class::MOP::load_class($component);
2034
2035         my $module  = $class->setup_component( $component );
2036         my %modules = (
2037             $component => $module,
2038             map {
2039                 $_ => $class->setup_component( $_ )
2040             } grep {
2041               not exists $comps{$_}
2042             } Devel::InnerPackage::list_packages( $component )
2043         );
2044
2045         for my $key ( keys %modules ) {
2046             $class->components->{ $key } = $modules{ $key };
2047         }
2048     }
2049 }
2050
2051 =head2 $c->setup_component
2052
2053 =cut
2054
2055 sub setup_component {
2056     my( $class, $component ) = @_;
2057
2058     unless ( $component->can( 'COMPONENT' ) ) {
2059         return $component;
2060     }
2061
2062     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2063     my $config = $class->config->{ $suffix } || {};
2064
2065     my $instance = eval { $component->COMPONENT( $class, $config ); };
2066
2067     if ( my $error = $@ ) {
2068         chomp $error;
2069         Catalyst::Exception->throw(
2070             message => qq/Couldn't instantiate component "$component", "$error"/
2071         );
2072     }
2073
2074     Catalyst::Exception->throw(
2075         message =>
2076         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2077     ) unless blessed($instance);
2078
2079     return $instance;
2080 }
2081
2082 =head2 $c->setup_dispatcher
2083
2084 Sets up dispatcher.
2085
2086 =cut
2087
2088 sub setup_dispatcher {
2089     my ( $class, $dispatcher ) = @_;
2090
2091     if ($dispatcher) {
2092         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2093     }
2094
2095     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2096         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2097     }
2098
2099     unless ($dispatcher) {
2100         $dispatcher = $class->dispatcher_class;
2101     }
2102
2103     Class::MOP::load_class($dispatcher);
2104
2105     # dispatcher instance
2106     $class->dispatcher( $dispatcher->new );
2107 }
2108
2109 =head2 $c->setup_engine
2110
2111 Sets up engine.
2112
2113 =cut
2114
2115 sub setup_engine {
2116     my ( $class, $engine ) = @_;
2117
2118     if ($engine) {
2119         $engine = 'Catalyst::Engine::' . $engine;
2120     }
2121
2122     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2123         $engine = 'Catalyst::Engine::' . $env;
2124     }
2125
2126     if ( $ENV{MOD_PERL} ) {
2127         my $meta = Class::MOP::get_metaclass_by_name($class);
2128
2129         # create the apache method
2130         $meta->add_method('apache' => sub { shift->engine->apache });
2131
2132         my ( $software, $version ) =
2133           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2134
2135         $version =~ s/_//g;
2136         $version =~ s/(\.[^.]+)\./$1/g;
2137
2138         if ( $software eq 'mod_perl' ) {
2139
2140             if ( !$engine ) {
2141
2142                 if ( $version >= 1.99922 ) {
2143                     $engine = 'Catalyst::Engine::Apache2::MP20';
2144                 }
2145
2146                 elsif ( $version >= 1.9901 ) {
2147                     $engine = 'Catalyst::Engine::Apache2::MP19';
2148                 }
2149
2150                 elsif ( $version >= 1.24 ) {
2151                     $engine = 'Catalyst::Engine::Apache::MP13';
2152                 }
2153
2154                 else {
2155                     Catalyst::Exception->throw( message =>
2156                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2157                 }
2158
2159             }
2160
2161             # install the correct mod_perl handler
2162             if ( $version >= 1.9901 ) {
2163                 *handler = sub  : method {
2164                     shift->handle_request(@_);
2165                 };
2166             }
2167             else {
2168                 *handler = sub ($$) { shift->handle_request(@_) };
2169             }
2170
2171         }
2172
2173         elsif ( $software eq 'Zeus-Perl' ) {
2174             $engine = 'Catalyst::Engine::Zeus';
2175         }
2176
2177         else {
2178             Catalyst::Exception->throw(
2179                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2180         }
2181     }
2182
2183     unless ($engine) {
2184         $engine = $class->engine_class;
2185     }
2186
2187     Class::MOP::load_class($engine);
2188
2189     # check for old engines that are no longer compatible
2190     my $old_engine;
2191     if ( $engine->isa('Catalyst::Engine::Apache')
2192         && !Catalyst::Engine::Apache->VERSION )
2193     {
2194         $old_engine = 1;
2195     }
2196
2197     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2198         && Catalyst::Engine::Server->VERSION le '0.02' )
2199     {
2200         $old_engine = 1;
2201     }
2202
2203     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2204         && $engine->VERSION eq '0.01' )
2205     {
2206         $old_engine = 1;
2207     }
2208
2209     elsif ($engine->isa('Catalyst::Engine::Zeus')
2210         && $engine->VERSION eq '0.01' )
2211     {
2212         $old_engine = 1;
2213     }
2214
2215     if ($old_engine) {
2216         Catalyst::Exception->throw( message =>
2217               qq/Engine "$engine" is not supported by this version of Catalyst/
2218         );
2219     }
2220
2221     # engine instance
2222     $class->engine( $engine->new );
2223 }
2224
2225 =head2 $c->setup_home
2226
2227 Sets up the home directory.
2228
2229 =cut
2230
2231 sub setup_home {
2232     my ( $class, $home ) = @_;
2233
2234     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2235         $home = $env;
2236     }
2237
2238     $home ||= Catalyst::Utils::home($class);
2239
2240     if ($home) {
2241         #I remember recently being scolded for assigning config values like this
2242         $class->config->{home} ||= $home;
2243         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2244     }
2245 }
2246
2247 =head2 $c->setup_log
2248
2249 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2250 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2251 log to.
2252
2253 This method also installs a C<debug> method that returns a true value into the
2254 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2255 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2256
2257 Note that if the log has already been setup, by either a previous call to
2258 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2259 that this method won't actually set up the log object.
2260
2261 =cut
2262
2263 sub setup_log {
2264     my ( $class, $levels ) = @_;
2265
2266     $levels ||= '';
2267     $levels =~ s/^\s+//;
2268     $levels =~ s/\s+$//;
2269     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels || '';
2270
2271     unless ( $class->log ) {
2272         $class->log( Catalyst::Log->new(keys %levels) );
2273     }
2274
2275     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2276     if ( defined($env_debug) or $levels{debug} ) {
2277         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2278         $class->log->debug('Debug messages enabled');
2279     }
2280 }
2281
2282 =head2 $c->setup_plugins
2283
2284 Sets up plugins.
2285
2286 =cut
2287
2288 =head2 $c->setup_stats
2289
2290 Sets up timing statistics class.
2291
2292 =cut
2293
2294 sub setup_stats {
2295     my ( $class, $stats ) = @_;
2296
2297     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2298
2299     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2300     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2301         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2302         $class->log->debug('Statistics enabled');
2303     }
2304 }
2305
2306
2307 =head2 $c->registered_plugins
2308
2309 Returns a sorted list of the plugins which have either been stated in the
2310 import list or which have been added via C<< MyApp->plugin(@args); >>.
2311
2312 If passed a given plugin name, it will report a boolean value indicating
2313 whether or not that plugin is loaded.  A fully qualified name is required if
2314 the plugin name does not begin with C<Catalyst::Plugin::>.
2315
2316  if ($c->registered_plugins('Some::Plugin')) {
2317      ...
2318  }
2319
2320 =cut
2321
2322 {
2323
2324     sub registered_plugins {
2325         my $proto = shift;
2326         return sort keys %{ $proto->_plugins } unless @_;
2327         my $plugin = shift;
2328         return 1 if exists $proto->_plugins->{$plugin};
2329         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2330     }
2331
2332     sub _register_plugin {
2333         my ( $proto, $plugin, $instant ) = @_;
2334         my $class = ref $proto || $proto;
2335
2336         # no ignore_loaded here, the plugin may already have been
2337         # defined in memory and we don't want to error on "no file" if so
2338
2339         Class::MOP::load_class( $plugin );
2340
2341         $proto->_plugins->{$plugin} = 1;
2342         unless ($instant) {
2343             no strict 'refs';
2344             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2345               my @superclasses = ($plugin, $meta->superclasses );
2346               $meta->superclasses(@superclasses);
2347             } else {
2348               unshift @{"$class\::ISA"}, $plugin;
2349             }
2350         }
2351         return $class;
2352     }
2353
2354     sub setup_plugins {
2355         my ( $class, $plugins ) = @_;
2356
2357         $class->_plugins( {} ) unless $class->_plugins;
2358         $plugins ||= [];
2359         for my $plugin ( reverse @$plugins ) {
2360
2361             unless ( $plugin =~ s/\A\+// ) {
2362                 $plugin = "Catalyst::Plugin::$plugin";
2363             }
2364
2365             $class->_register_plugin($plugin);
2366         }
2367     }
2368 }
2369
2370 =head2 $c->stack
2371
2372 Returns an arrayref of the internal execution stack (actions that are
2373 currently executing).
2374
2375 =head2 $c->stats_class
2376
2377 Returns or sets the stats (timing statistics) class.
2378
2379 =head2 $c->use_stats
2380
2381 Returns 1 when stats collection is enabled.  Stats collection is enabled
2382 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2383 environment variable is set.
2384
2385 Note that this is a static method, not an accessor and should be overloaded
2386 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2387
2388 =cut
2389
2390 sub use_stats { 0 }
2391
2392
2393 =head2 $c->write( $data )
2394
2395 Writes $data to the output stream. When using this method directly, you
2396 will need to manually set the C<Content-Length> header to the length of
2397 your output data, if known.
2398
2399 =cut
2400
2401 sub write {
2402     my $c = shift;
2403
2404     # Finalize headers if someone manually writes output
2405     $c->finalize_headers;
2406
2407     return $c->engine->write( $c, @_ );
2408 }
2409
2410 =head2 version
2411
2412 Returns the Catalyst version number. Mostly useful for "powered by"
2413 messages in template systems.
2414
2415 =cut
2416
2417 sub version { return $Catalyst::VERSION }
2418
2419 =head1 INTERNAL ACTIONS
2420
2421 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2422 C<_ACTION>, and C<_END>. These are by default not shown in the private
2423 action table, but you can make them visible with a config parameter.
2424
2425     MyApp->config->{show_internal_actions} = 1;
2426
2427 =head1 CASE SENSITIVITY
2428
2429 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2430 mapped to C</foo/bar>. You can activate case sensitivity with a config
2431 parameter.
2432
2433     MyApp->config->{case_sensitive} = 1;
2434
2435 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2436
2437 =head1 ON-DEMAND PARSER
2438
2439 The request body is usually parsed at the beginning of a request,
2440 but if you want to handle input yourself, you can enable on-demand
2441 parsing with a config parameter.
2442
2443     MyApp->config->{parse_on_demand} = 1;
2444
2445 =head1 PROXY SUPPORT
2446
2447 Many production servers operate using the common double-server approach,
2448 with a lightweight frontend web server passing requests to a larger
2449 backend server. An application running on the backend server must deal
2450 with two problems: the remote user always appears to be C<127.0.0.1> and
2451 the server's hostname will appear to be C<localhost> regardless of the
2452 virtual host that the user connected through.
2453
2454 Catalyst will automatically detect this situation when you are running
2455 the frontend and backend servers on the same machine. The following
2456 changes are made to the request.
2457
2458     $c->req->address is set to the user's real IP address, as read from
2459     the HTTP X-Forwarded-For header.
2460
2461     The host value for $c->req->base and $c->req->uri is set to the real
2462     host, as read from the HTTP X-Forwarded-Host header.
2463
2464 Obviously, your web server must support these headers for this to work.
2465
2466 In a more complex server farm environment where you may have your
2467 frontend proxy server(s) on different machines, you will need to set a
2468 configuration option to tell Catalyst to read the proxied data from the
2469 headers.
2470
2471     MyApp->config->{using_frontend_proxy} = 1;
2472
2473 If you do not wish to use the proxy support at all, you may set:
2474
2475     MyApp->config->{ignore_frontend_proxy} = 1;
2476
2477 =head1 THREAD SAFETY
2478
2479 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2480 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2481 believe the Catalyst core to be thread-safe.
2482
2483 If you plan to operate in a threaded environment, remember that all other
2484 modules you are using must also be thread-safe. Some modules, most notably
2485 L<DBD::SQLite>, are not thread-safe.
2486
2487 =head1 SUPPORT
2488
2489 IRC:
2490
2491     Join #catalyst on irc.perl.org.
2492
2493 Mailing Lists:
2494
2495     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2496     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2497
2498 Web:
2499
2500     http://catalyst.perl.org
2501
2502 Wiki:
2503
2504     http://dev.catalyst.perl.org
2505
2506 =head1 SEE ALSO
2507
2508 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2509
2510 =head2 L<Catalyst::Manual> - The Catalyst Manual
2511
2512 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2513
2514 =head2 L<Catalyst::Engine> - Core engine
2515
2516 =head2 L<Catalyst::Log> - Log class.
2517
2518 =head2 L<Catalyst::Request> - Request object
2519
2520 =head2 L<Catalyst::Response> - Response object
2521
2522 =head2 L<Catalyst::Test> - The test suite.
2523
2524 =head1 PROJECT FOUNDER
2525
2526 sri: Sebastian Riedel <sri@cpan.org>
2527
2528 =head1 CONTRIBUTORS
2529
2530 abw: Andy Wardley
2531
2532 acme: Leon Brocard <leon@astray.com>
2533
2534 Andrew Bramble
2535
2536 Andrew Ford
2537
2538 Andrew Ruthven
2539
2540 andyg: Andy Grundman <andy@hybridized.org>
2541
2542 audreyt: Audrey Tang
2543
2544 bricas: Brian Cassidy <bricas@cpan.org>
2545
2546 Caelum: Rafael Kitover <rkitover@io.com>
2547
2548 chansen: Christian Hansen
2549
2550 chicks: Christopher Hicks
2551
2552 David E. Wheeler
2553
2554 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2555
2556 Drew Taylor
2557
2558 esskar: Sascha Kiefer
2559
2560 fireartist: Carl Franks <cfranks@cpan.org>
2561
2562 gabb: Danijel Milicevic
2563
2564 Gary Ashton Jones
2565
2566 Geoff Richards
2567
2568 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2569
2570 jcamacho: Juan Camacho
2571
2572 jhannah: Jay Hannah <jay@jays.net>
2573
2574 Jody Belka
2575
2576 Johan Lindstrom
2577
2578 jon: Jon Schutz <jjschutz@cpan.org>
2579
2580 marcus: Marcus Ramberg <mramberg@cpan.org>
2581
2582 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2583
2584 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2585
2586 mugwump: Sam Vilain
2587
2588 naughton: David Naughton
2589
2590 ningu: David Kamholz <dkamholz@cpan.org>
2591
2592 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2593
2594 numa: Dan Sully <daniel@cpan.org>
2595
2596 obra: Jesse Vincent
2597
2598 omega: Andreas Marienborg
2599
2600 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2601
2602 rafl: Florian Ragwitz <rafl@debian.org>
2603
2604 sky: Arthur Bergman
2605
2606 the_jester: Jesse Sheidlower
2607
2608 t0m: Tomas Doran <bobtfish@bobtfish.net>
2609
2610 Ulf Edvinsson
2611
2612 willert: Sebastian Willert <willert@cpan.org>
2613
2614 =head1 LICENSE
2615
2616 This library is free software, you can redistribute it and/or modify it under
2617 the same terms as Perl itself.
2618
2619 =cut
2620
2621 no Moose;
2622
2623 __PACKAGE__->meta->make_immutable;
2624
2625 1;