lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Devel::InnerPackage ();
  18 use File::stat;
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use utf8;
  32 use Carp qw/croak carp shortmess/;
  33
  34 BEGIN { require 5.008004; }
  35
  36 has stack => (is => 'ro', default => sub { [] });
  37 has stash => (is => 'rw', default => sub { {} });
  38 has state => (is => 'rw', default => 0);
  39 has stats => (is => 'rw');
  40 has action => (is => 'rw');
  41 has counter => (is => 'rw', default => sub { {} });
  42 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  43 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  44 has namespace => (is => 'rw');
  45
  46 sub depth { scalar @{ shift->stack || [] }; }
  47 sub comp { shift->component(@_) }
  48
  49 sub req {
  50     my $self = shift; return $self->request(@_);
  51 }
  52 sub res {
  53     my $self = shift; return $self->response(@_);
  54 }
  55
  56 # For backwards compatibility
  57 sub finalize_output { shift->finalize_body(@_) };
  58
  59 # For statistics
  60 our $COUNT     = 1;
  61 our $START     = time;
  62 our $RECURSION = 1000;
  63 our $DETACH    = Catalyst::Exception::Detach->new;
  64 our $GO        = Catalyst::Exception::Go->new;
  65
  66 #I imagine that very few of these really need to be class variables. if any.
  67 #maybe we should just make them attributes with a default?
  68 __PACKAGE__->mk_classdata($_)
  69   for qw/components arguments dispatcher engine log dispatcher_class
  70   engine_class context_class request_class response_class stats_class
  71   setup_finished/;
  72
  73 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  74 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  75 __PACKAGE__->request_class('Catalyst::Request');
  76 __PACKAGE__->response_class('Catalyst::Response');
  77 __PACKAGE__->stats_class('Catalyst::Stats');
  78
  79 # Remember to update this in Catalyst::Runtime as well!
  80
  81 our $VERSION = '5.80020';
  82 our $PRETTY_VERSION = $VERSION;
  83
  84 $VERSION = eval $VERSION;
  85
  86 sub import {
  87     my ( $class, @arguments ) = @_;
  88
  89     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  90     # callers @ISA.
  91     return unless $class eq 'Catalyst';
  92
  93     my $caller = caller();
  94     return if $caller eq 'main';
  95
  96     my $meta = Moose::Meta::Class->initialize($caller);
  97     unless ( $caller->isa('Catalyst') ) {
  98         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  99         $meta->superclasses(@superclasses);
 100     }
 101     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 102     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 103
 104     unless( $meta->has_method('meta') ){
 105         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 106     }
 107
 108     $caller->arguments( [@arguments] );
 109     $caller->setup_home;
 110 }
 111
 112 sub _application { $_[0] }
 113
 114 =head1 NAME
 115
 116 Catalyst - The Elegant MVC Web Application Framework
 117
 118 =head1 SYNOPSIS
 119
 120 See the L<Catalyst::Manual> distribution for comprehensive
 121 documentation and tutorials.
 122
 123     # Install Catalyst::Devel for helpers and other development tools
 124     # use the helper to create a new application
 125     catalyst.pl MyApp
 126
 127     # add models, views, controllers
 128     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 129     script/myapp_create.pl view MyTemplate TT
 130     script/myapp_create.pl controller Search
 131
 132     # built in testserver -- use -r to restart automatically on changes
 133     # --help to see all available options
 134     script/myapp_server.pl
 135
 136     # command line testing interface
 137     script/myapp_test.pl /yada
 138
 139     ### in lib/MyApp.pm
 140     use Catalyst qw/-Debug/; # include plugins here as well
 141
 142     ### In lib/MyApp/Controller/Root.pm (autocreated)
 143     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 144         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 145         $c->stash->{template} = 'foo.tt'; # set the template
 146         # lookup something from db -- stash vars are passed to TT
 147         $c->stash->{data} =
 148           $c->model('Database::Foo')->search( { country => $args[0] } );
 149         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 150             $c->forward( 'bar' ); # process another action
 151             # do something else after forward returns
 152         }
 153     }
 154
 155     # The foo.tt TT template can use the stash data from the database
 156     [% WHILE (item = data.next) %]
 157         [% item.foo %]
 158     [% END %]
 159
 160     # called for /bar/of/soap, /bar/of/soap/10, etc.
 161     sub bar : Path('/bar/of/soap') { ... }
 162
 163     # called for all actions, from the top-most controller downwards
 164     sub auto : Private {
 165         my ( $self, $c ) = @_;
 166         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 167             $c->res->redirect( '/login' ); # require login
 168             return 0; # abort request and go immediately to end()
 169         }
 170         return 1; # success; carry on to next action
 171     }
 172
 173     # called after all actions are finished
 174     sub end : Private {
 175         my ( $self, $c ) = @_;
 176         if ( scalar @{ $c->error } ) { ... } # handle errors
 177         return if $c->res->body; # already have a response
 178         $c->forward( 'MyApp::View::TT' ); # render template
 179     }
 180
 181     ### in MyApp/Controller/Foo.pm
 182     # called for /foo/bar
 183     sub bar : Local { ... }
 184
 185     # called for /blargle
 186     sub blargle : Global { ... }
 187
 188     # an index action matches /foo, but not /foo/1, etc.
 189     sub index : Private { ... }
 190
 191     ### in MyApp/Controller/Foo/Bar.pm
 192     # called for /foo/bar/baz
 193     sub baz : Local { ... }
 194
 195     # first Root auto is called, then Foo auto, then this
 196     sub auto : Private { ... }
 197
 198     # powerful regular expression paths are also possible
 199     sub details : Regex('^product/(\w+)/details$') {
 200         my ( $self, $c ) = @_;
 201         # extract the (\w+) from the URI
 202         my $product = $c->req->captures->[0];
 203     }
 204
 205 See L<Catalyst::Manual::Intro> for additional information.
 206
 207 =head1 DESCRIPTION
 208
 209 Catalyst is a modern framework for making web applications without the
 210 pain usually associated with this process. This document is a reference
 211 to the main Catalyst application. If you are a new user, we suggest you
 212 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 213
 214 See L<Catalyst::Manual> for more documentation.
 215
 216 Catalyst plugins can be loaded by naming them as arguments to the "use
 217 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 218 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 219 C<My::Module>.
 220
 221     use Catalyst qw/My::Module/;
 222
 223 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 224 fully qualify the name by using a unary plus:
 225
 226     use Catalyst qw/
 227         My::Module
 228         +Fully::Qualified::Plugin::Name
 229     /;
 230
 231 Special flags like C<-Debug> and C<-Engine> can also be specified as
 232 arguments when Catalyst is loaded:
 233
 234     use Catalyst qw/-Debug My::Module/;
 235
 236 The position of plugins and flags in the chain is important, because
 237 they are loaded in the order in which they appear.
 238
 239 The following flags are supported:
 240
 241 =head2 -Debug
 242
 243 Enables debug output. You can also force this setting from the system
 244 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 245 settings override the application, with <MYAPP>_DEBUG having the highest
 246 priority.
 247
 248 This sets the log level to 'debug' and enables full debug output on the
 249 error screen. If you only want the latter, see L<< $c->debug >>.
 250
 251 =head2 -Engine
 252
 253 Forces Catalyst to use a specific engine. Omit the
 254 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 255
 256     use Catalyst qw/-Engine=CGI/;
 257
 258 =head2 -Home
 259
 260 Forces Catalyst to use a specific home directory, e.g.:
 261
 262     use Catalyst qw[-Home=/usr/mst];
 263
 264 This can also be done in the shell environment by setting either the
 265 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 266 is replaced with the uppercased name of your application, any "::" in
 267 the name will be replaced with underscores, e.g. MyApp::Web should use
 268 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 269
 270 If none of these are set, Catalyst will attempt to automatically detect the
 271 home directory. If you are working in a development envirnoment, Catalyst
 272 will try and find the directory containing either Makefile.PL, Build.PL or
 273 dist.ini. If the application has been installed into the system (i.e.
 274 you have done C<make install>), then Catalyst will use the path to your
 275 application module, without the .pm extension (ie, /foo/MyApp if your
 276 application was installed at /foo/MyApp.pm)
 277
 278 =head2 -Log
 279
 280     use Catalyst '-Log=warn,fatal,error';
 281
 282 Specifies a comma-delimited list of log levels.
 283
 284 =head2 -Stats
 285
 286 Enables statistics collection and reporting. You can also force this setting
 287 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 288 environment settings override the application, with <MYAPP>_STATS having the
 289 highest priority.
 290
 291 e.g.
 292
 293    use Catalyst qw/-Stats=1/
 294
 295 =head1 METHODS
 296
 297 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 298
 299 =head2 $c->action
 300
 301 Returns a L<Catalyst::Action> object for the current action, which
 302 stringifies to the action name. See L<Catalyst::Action>.
 303
 304 =head2 $c->namespace
 305
 306 Returns the namespace of the current action, i.e., the URI prefix
 307 corresponding to the controller of the current action. For example:
 308
 309     # in Controller::Foo::Bar
 310     $c->namespace; # returns 'foo/bar';
 311
 312 =head2 $c->request
 313
 314 =head2 $c->req
 315
 316 Returns the current L<Catalyst::Request> object, giving access to
 317 information about the current client request (including parameters,
 318 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 319
 320 =head2 REQUEST FLOW HANDLING
 321
 322 =head2 $c->forward( $action [, \@arguments ] )
 323
 324 =head2 $c->forward( $class, $method, [, \@arguments ] )
 325
 326 Forwards processing to another action, by its private name. If you give a
 327 class name but no method, C<process()> is called. You may also optionally
 328 pass arguments in an arrayref. The action will receive the arguments in
 329 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 330 C<< $c->req->args >> will be restored to the previous values.
 331
 332 Any data C<return>ed from the action forwarded to, will be returned by the
 333 call to forward.
 334
 335     my $foodata = $c->forward('/foo');
 336     $c->forward('index');
 337     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 338     $c->forward('View::TT');
 339
 340 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 341 an C<< eval { } >> around the call (actually
 342 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 343 all 'dies' within the called action. If you want C<die> to propagate you
 344 need to do something like:
 345
 346     $c->forward('foo');
 347     die join "\n", @{ $c->error } if @{ $c->error };
 348
 349 Or make sure to always return true values from your actions and write
 350 your code like this:
 351
 352     $c->forward('foo') || return;
 353
 354 Another note is that C<< $c->forward >> always returns a scalar because it
 355 actually returns $c->state which operates in a scalar context.
 356 Thus, something like:
 357
 358     return @array;
 359
 360 in an action that is forwarded to is going to return a scalar,
 361 i.e. how many items are in that array, which is probably not what you want.
 362 If you need to return an array then return a reference to it,
 363 or stash it like so:
 364
 365     $c->stash->{array} = \@array;
 366
 367 and access it from the stash.
 368
 369 =cut
 370
 371 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 372
 373 =head2 $c->detach( $action [, \@arguments ] )
 374
 375 =head2 $c->detach( $class, $method, [, \@arguments ] )
 376
 377 =head2 $c->detach()
 378
 379 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 380 doesn't return to the previous action when processing is finished.
 381
 382 When called with no arguments it escapes the processing chain entirely.
 383
 384 =cut
 385
 386 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 387
 388 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 389
 390 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 391
 392 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 393 but does a full dispatch, instead of just calling the new C<$action> /
 394 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 395 you go to are called, just like a new request.
 396
 397 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 398 This means, for example, that C<< $c->action >> methods such as
 399 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 400 L<reverse|Catalyst::Action/reverse> return information for the visited action
 401 when they are invoked within the visited action.  This is different from the
 402 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 403 continues to use the $c->action object from the caller action even when
 404 invoked from the callee.
 405
 406 C<< $c->stash >> is kept unchanged.
 407
 408 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 409 allows you to "wrap" another action, just as it would have been called by
 410 dispatching from a URL, while the analogous
 411 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 412 transfer control to another action as if it had been reached directly from a URL.
 413
 414 =cut
 415
 416 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 417
 418 =head2 $c->go( $action [, \@captures, \@arguments ] )
 419
 420 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 421
 422 The relationship between C<go> and
 423 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 424 the relationship between
 425 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 426 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 427 C<< $c->go >> will perform a full dispatch on the specified action or method,
 428 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 429 C<go> escapes the processing of the current request chain on completion, and
 430 does not return to its caller.
 431
 432 =cut
 433
 434 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 435
 436 =head2 $c->response
 437
 438 =head2 $c->res
 439
 440 Returns the current L<Catalyst::Response> object, see there for details.
 441
 442 =head2 $c->stash
 443
 444 Returns a hashref to the stash, which may be used to store data and pass
 445 it between components during a request. You can also set hash keys by
 446 passing arguments. The stash is automatically sent to the view. The
 447 stash is cleared at the end of a request; it cannot be used for
 448 persistent storage (for this you must use a session; see
 449 L<Catalyst::Plugin::Session> for a complete system integrated with
 450 Catalyst).
 451
 452     $c->stash->{foo} = $bar;
 453     $c->stash( { moose => 'majestic', qux => 0 } );
 454     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 455
 456     # stash is automatically passed to the view for use in a template
 457     $c->forward( 'MyApp::View::TT' );
 458
 459 =cut
 460
 461 around stash => sub {
 462     my $orig = shift;
 463     my $c = shift;
 464     my $stash = $orig->($c);
 465     if (@_) {
 466         my $new_stash = @_ > 1 ? {@_} : $_[0];
 467         croak('stash takes a hash or hashref') unless ref $new_stash;
 468         foreach my $key ( keys %$new_stash ) {
 469           $stash->{$key} = $new_stash->{$key};
 470         }
 471     }
 472
 473     return $stash;
 474 };
 475
 476
 477 =head2 $c->error
 478
 479 =head2 $c->error($error, ...)
 480
 481 =head2 $c->error($arrayref)
 482
 483 Returns an arrayref containing error messages.  If Catalyst encounters an
 484 error while processing a request, it stores the error in $c->error.  This
 485 method should only be used to store fatal error messages.
 486
 487     my @error = @{ $c->error };
 488
 489 Add a new error.
 490
 491     $c->error('Something bad happened');
 492
 493 =cut
 494
 495 sub error {
 496     my $c = shift;
 497     if ( $_[0] ) {
 498         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 499         croak @$error unless ref $c;
 500         push @{ $c->{error} }, @$error;
 501     }
 502     elsif ( defined $_[0] ) { $c->{error} = undef }
 503     return $c->{error} || [];
 504 }
 505
 506
 507 =head2 $c->state
 508
 509 Contains the return value of the last executed action.
 510 Note that << $c->state >> operates in a scalar context which means that all
 511 values it returns are scalar.
 512
 513 =head2 $c->clear_errors
 514
 515 Clear errors.  You probably don't want to clear the errors unless you are
 516 implementing a custom error screen.
 517
 518 This is equivalent to running
 519
 520     $c->error(0);
 521
 522 =cut
 523
 524 sub clear_errors {
 525     my $c = shift;
 526     $c->error(0);
 527 }
 528
 529 sub _comp_search_prefixes {
 530     my $c = shift;
 531     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 532 }
 533
 534 # search components given a name and some prefixes
 535 sub _comp_names_search_prefixes {
 536     my ( $c, $name, @prefixes ) = @_;
 537     my $appclass = ref $c || $c;
 538     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 539     $filter = qr/$filter/; # Compile regex now rather than once per loop
 540
 541     # map the original component name to the sub part that we will search against
 542     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 543         grep { /$filter/ } keys %{ $c->components };
 544
 545     # undef for a name will return all
 546     return keys %eligible if !defined $name;
 547
 548     my $query  = ref $name ? $name : qr/^$name$/i;
 549     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 550
 551     return @result if @result;
 552
 553     # if we were given a regexp to search against, we're done.
 554     return if ref $name;
 555
 556     # skip regexp fallback if configured
 557     return
 558         if $appclass->config->{disable_component_resolution_regex_fallback};
 559
 560     # regexp fallback
 561     $query  = qr/$name/i;
 562     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 563
 564     # no results? try against full names
 565     if( !@result ) {
 566         @result = grep { m{$query} } keys %eligible;
 567     }
 568
 569     # don't warn if we didn't find any results, it just might not exist
 570     if( @result ) {
 571         # Disgusting hack to work out correct method name
 572         my $warn_for = lc $prefixes[0];
 573         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 574            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 575            "component resolution is unreliable and unsafe.";
 576         my $short = $result[0];
 577         # remove the component namespace prefix
 578         $short =~ s/.*?(Model|Controller|View):://;
 579         my $shortmess = Carp::shortmess('');
 580         if ($shortmess =~ m#Catalyst/Plugin#) {
 581            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 582               "plugin's config";
 583         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 584            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 585               "component's config";
 586         } else {
 587            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 588               "but if you really wanted to search, pass in a regexp as the argument " .
 589               "like so: \$c->${warn_for}(qr/${name}/)";
 590         }
 591         $c->log->warn( "${msg}$shortmess" );
 592     }
 593
 594     return @result;
 595 }
 596
 597 # Find possible names for a prefix
 598 sub _comp_names {
 599     my ( $c, @prefixes ) = @_;
 600     my $appclass = ref $c || $c;
 601
 602     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 603
 604     my @names = map { s{$filter}{}; $_; }
 605         $c->_comp_names_search_prefixes( undef, @prefixes );
 606
 607     return @names;
 608 }
 609
 610 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 611 sub _filter_component {
 612     my ( $c, $comp, @args ) = @_;
 613
 614     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 615         return $comp->ACCEPT_CONTEXT( $c, @args );
 616     }
 617
 618     return $comp;
 619 }
 620
 621 =head2 COMPONENT ACCESSORS
 622
 623 =head2 $c->controller($name)
 624
 625 Gets a L<Catalyst::Controller> instance by name.
 626
 627     $c->controller('Foo')->do_stuff;
 628
 629 If the name is omitted, will return the controller for the dispatched
 630 action.
 631
 632 If you want to search for controllers, pass in a regexp as the argument.
 633
 634     # find all controllers that start with Foo
 635     my @foo_controllers = $c->controller(qr{^Foo});
 636
 637
 638 =cut
 639
 640 sub controller {
 641     my ( $c, $name, @args ) = @_;
 642
 643     if( $name ) {
 644         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 645         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 646         return $c->_filter_component( $result[ 0 ], @args );
 647     }
 648
 649     return $c->component( $c->action->class );
 650 }
 651
 652 =head2 $c->model($name)
 653
 654 Gets a L<Catalyst::Model> instance by name.
 655
 656     $c->model('Foo')->do_stuff;
 657
 658 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 659
 660 If the name is omitted, it will look for
 661  - a model object in $c->stash->{current_model_instance}, then
 662  - a model name in $c->stash->{current_model}, then
 663  - a config setting 'default_model', or
 664  - check if there is only one model, and return it if that's the case.
 665
 666 If you want to search for models, pass in a regexp as the argument.
 667
 668     # find all models that start with Foo
 669     my @foo_models = $c->model(qr{^Foo});
 670
 671 =cut
 672
 673 sub model {
 674     my ( $c, $name, @args ) = @_;
 675     my $appclass = ref($c) || $c;
 676     if( $name ) {
 677         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 678         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 679         return $c->_filter_component( $result[ 0 ], @args );
 680     }
 681
 682     if (ref $c) {
 683         return $c->stash->{current_model_instance}
 684           if $c->stash->{current_model_instance};
 685         return $c->model( $c->stash->{current_model} )
 686           if $c->stash->{current_model};
 687     }
 688     return $c->model( $appclass->config->{default_model} )
 689       if $appclass->config->{default_model};
 690
 691     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 692
 693     if( $rest ) {
 694         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 695         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 696         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 697         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 698         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 699     }
 700
 701     return $c->_filter_component( $comp );
 702 }
 703
 704
 705 =head2 $c->view($name)
 706
 707 Gets a L<Catalyst::View> instance by name.
 708
 709     $c->view('Foo')->do_stuff;
 710
 711 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 712
 713 If the name is omitted, it will look for
 714  - a view object in $c->stash->{current_view_instance}, then
 715  - a view name in $c->stash->{current_view}, then
 716  - a config setting 'default_view', or
 717  - check if there is only one view, and return it if that's the case.
 718
 719 If you want to search for views, pass in a regexp as the argument.
 720
 721     # find all views that start with Foo
 722     my @foo_views = $c->view(qr{^Foo});
 723
 724 =cut
 725
 726 sub view {
 727     my ( $c, $name, @args ) = @_;
 728
 729     my $appclass = ref($c) || $c;
 730     if( $name ) {
 731         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 732         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 733         return $c->_filter_component( $result[ 0 ], @args );
 734     }
 735
 736     if (ref $c) {
 737         return $c->stash->{current_view_instance}
 738           if $c->stash->{current_view_instance};
 739         return $c->view( $c->stash->{current_view} )
 740           if $c->stash->{current_view};
 741     }
 742     return $c->view( $appclass->config->{default_view} )
 743       if $appclass->config->{default_view};
 744
 745     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 746
 747     if( $rest ) {
 748         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 749         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 750         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 751         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 752         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 753     }
 754
 755     return $c->_filter_component( $comp );
 756 }
 757
 758 =head2 $c->controllers
 759
 760 Returns the available names which can be passed to $c->controller
 761
 762 =cut
 763
 764 sub controllers {
 765     my ( $c ) = @_;
 766     return $c->_comp_names(qw/Controller C/);
 767 }
 768
 769 =head2 $c->models
 770
 771 Returns the available names which can be passed to $c->model
 772
 773 =cut
 774
 775 sub models {
 776     my ( $c ) = @_;
 777     return $c->_comp_names(qw/Model M/);
 778 }
 779
 780
 781 =head2 $c->views
 782
 783 Returns the available names which can be passed to $c->view
 784
 785 =cut
 786
 787 sub views {
 788     my ( $c ) = @_;
 789     return $c->_comp_names(qw/View V/);
 790 }
 791
 792 =head2 $c->comp($name)
 793
 794 =head2 $c->component($name)
 795
 796 Gets a component object by name. This method is not recommended,
 797 unless you want to get a specific component by full
 798 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 799 should be used instead.
 800
 801 If C<$name> is a regexp, a list of components matched against the full
 802 component name will be returned.
 803
 804 If Catalyst can't find a component by name, it will fallback to regex
 805 matching by default. To disable this behaviour set
 806 disable_component_resolution_regex_fallback to a true value.
 807
 808     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 809
 810 =cut
 811
 812 sub component {
 813     my ( $c, $name, @args ) = @_;
 814
 815     if( $name ) {
 816         my $comps = $c->components;
 817
 818         if( !ref $name ) {
 819             # is it the exact name?
 820             return $c->_filter_component( $comps->{ $name }, @args )
 821                        if exists $comps->{ $name };
 822
 823             # perhaps we just omitted "MyApp"?
 824             my $composed = ( ref $c || $c ) . "::${name}";
 825             return $c->_filter_component( $comps->{ $composed }, @args )
 826                        if exists $comps->{ $composed };
 827
 828             # search all of the models, views and controllers
 829             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 830             return $c->_filter_component( $comp, @args ) if $comp;
 831         }
 832
 833         # This is here so $c->comp( '::M::' ) works
 834         my $query = ref $name ? $name : qr{$name}i;
 835
 836         my @result = grep { m{$query} } keys %{ $c->components };
 837         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 838
 839         if( $result[ 0 ] ) {
 840             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 841             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 842             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 843             return $c->_filter_component( $result[ 0 ], @args );
 844         }
 845
 846         # I would expect to return an empty list here, but that breaks back-compat
 847     }
 848
 849     # fallback
 850     return sort keys %{ $c->components };
 851 }
 852
 853 =head2 CLASS DATA AND HELPER CLASSES
 854
 855 =head2 $c->config
 856
 857 Returns or takes a hashref containing the application's configuration.
 858
 859     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 860
 861 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 862 like C<myapp.conf> in your applications home directory. See
 863 L<Catalyst::Plugin::ConfigLoader>.
 864
 865 =head3 Cascading configuration
 866
 867 The config method is present on all Catalyst components, and configuration
 868 will be merged when an application is started. Configuration loaded with
 869 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 870 followed by configuration in your top level C<MyApp> class. These two
 871 configurations are merged, and then configuration data whose hash key matches a
 872 component name is merged with configuration for that component.
 873
 874 The configuration for a component is then passed to the C<new> method when a
 875 component is constructed.
 876
 877 For example:
 878
 879     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 880     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 881
 882 will mean that C<MyApp::Model::Foo> receives the following data when
 883 constructed:
 884
 885     MyApp::Model::Foo->new({
 886         bar => 'baz',
 887         quux => 'frob',
 888         overrides => 'me',
 889     });
 890
 891 =cut
 892
 893 around config => sub {
 894     my $orig = shift;
 895     my $c = shift;
 896
 897     croak('Setting config after setup has been run is not allowed.')
 898         if ( @_ and $c->setup_finished );
 899
 900     $c->$orig(@_);
 901 };
 902
 903 =head2 $c->log
 904
 905 Returns the logging object instance. Unless it is already set, Catalyst
 906 sets this up with a L<Catalyst::Log> object. To use your own log class,
 907 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 908 C<< __PACKAGE__->setup >>.
 909
 910  __PACKAGE__->log( MyLogger->new );
 911  __PACKAGE__->setup;
 912
 913 And later:
 914
 915     $c->log->info( 'Now logging with my own logger!' );
 916
 917 Your log class should implement the methods described in
 918 L<Catalyst::Log>.
 919
 920
 921 =head2 $c->debug
 922
 923 Returns 1 if debug mode is enabled, 0 otherwise.
 924
 925 You can enable debug mode in several ways:
 926
 927 =over
 928
 929 =item By calling myapp_server.pl with the -d flag
 930
 931 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 932
 933 =item The -Debug option in your MyApp.pm
 934
 935 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 936
 937 =back
 938
 939 The first three also set the log level to 'debug'.
 940
 941 Calling C<< $c->debug(1) >> has no effect.
 942
 943 =cut
 944
 945 sub debug { 0 }
 946
 947 =head2 $c->dispatcher
 948
 949 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 950
 951 =head2 $c->engine
 952
 953 Returns the engine instance. See L<Catalyst::Engine>.
 954
 955
 956 =head2 UTILITY METHODS
 957
 958 =head2 $c->path_to(@path)
 959
 960 Merges C<@path> with C<< $c->config->{home} >> and returns a
 961 L<Path::Class::Dir> object. Note you can usually use this object as
 962 a filename, but sometimes you will have to explicitly stringify it
 963 yourself by calling the C<< ->stringify >> method.
 964
 965 For example:
 966
 967     $c->path_to( 'db', 'sqlite.db' );
 968
 969 =cut
 970
 971 sub path_to {
 972     my ( $c, @path ) = @_;
 973     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 974     if ( -d $path ) { return $path }
 975     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 976 }
 977
 978 =head2 $c->plugin( $name, $class, @args )
 979
 980 Helper method for plugins. It creates a class data accessor/mutator and
 981 loads and instantiates the given class.
 982
 983     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 984
 985     $c->prototype->define_javascript_functions;
 986
 987 B<Note:> This method of adding plugins is deprecated. The ability
 988 to add plugins like this B<will be removed> in a Catalyst 5.81.
 989 Please do not use this functionality in new code.
 990
 991 =cut
 992
 993 sub plugin {
 994     my ( $class, $name, $plugin, @args ) = @_;
 995
 996     # See block comment in t/unit_core_plugin.t
 997     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 998
 999     $class->_register_plugin( $plugin, 1 );
1000
1001     eval { $plugin->import };
1002     $class->mk_classdata($name);
1003     my $obj;
1004     eval { $obj = $plugin->new(@args) };
1005
1006     if ($@) {
1007         Catalyst::Exception->throw( message =>
1008               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1009     }
1010
1011     $class->$name($obj);
1012     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1013       if $class->debug;
1014 }
1015
1016 =head2 MyApp->setup
1017
1018 Initializes the dispatcher and engine, loads any plugins, and loads the
1019 model, view, and controller components. You may also specify an array
1020 of plugins to load here, if you choose to not load them in the C<use
1021 Catalyst> line.
1022
1023     MyApp->setup;
1024     MyApp->setup( qw/-Debug/ );
1025
1026 =cut
1027
1028 sub setup {
1029     my ( $class, @arguments ) = @_;
1030     croak('Running setup more than once')
1031         if ( $class->setup_finished );
1032
1033     unless ( $class->isa('Catalyst') ) {
1034
1035         Catalyst::Exception->throw(
1036             message => qq/'$class' does not inherit from Catalyst/ );
1037     }
1038
1039     if ( $class->arguments ) {
1040         @arguments = ( @arguments, @{ $class->arguments } );
1041     }
1042
1043     # Process options
1044     my $flags = {};
1045
1046     foreach (@arguments) {
1047
1048         if (/^-Debug$/) {
1049             $flags->{log} =
1050               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1051         }
1052         elsif (/^-(\w+)=?(.*)$/) {
1053             $flags->{ lc $1 } = $2;
1054         }
1055         else {
1056             push @{ $flags->{plugins} }, $_;
1057         }
1058     }
1059
1060     $class->setup_home( delete $flags->{home} );
1061
1062     $class->setup_log( delete $flags->{log} );
1063     $class->setup_plugins( delete $flags->{plugins} );
1064     $class->setup_dispatcher( delete $flags->{dispatcher} );
1065     $class->setup_engine( delete $flags->{engine} );
1066     $class->setup_stats( delete $flags->{stats} );
1067
1068     for my $flag ( sort keys %{$flags} ) {
1069
1070         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1071             &$code( $class, delete $flags->{$flag} );
1072         }
1073         else {
1074             $class->log->warn(qq/Unknown flag "$flag"/);
1075         }
1076     }
1077
1078     eval { require Catalyst::Devel; };
1079     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1080         $class->log->warn(<<"EOF");
1081 You are running an old script!
1082
1083   Please update by running (this will overwrite existing files):
1084     catalyst.pl -force -scripts $class
1085
1086   or (this will not overwrite existing files):
1087     catalyst.pl -scripts $class
1088
1089 EOF
1090     }
1091
1092     if ( $class->debug ) {
1093         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1094
1095         if (@plugins) {
1096             my $column_width = Catalyst::Utils::term_width() - 6;
1097             my $t = Text::SimpleTable->new($column_width);
1098             $t->row($_) for @plugins;
1099             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1100         }
1101
1102         my $dispatcher = $class->dispatcher;
1103         my $engine     = $class->engine;
1104         my $home       = $class->config->{home};
1105
1106         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1107         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1108
1109         $home
1110           ? ( -d $home )
1111           ? $class->log->debug(qq/Found home "$home"/)
1112           : $class->log->debug(qq/Home "$home" doesn't exist/)
1113           : $class->log->debug(q/Couldn't find home/);
1114     }
1115
1116     # Call plugins setup, this is stupid and evil.
1117     # Also screws C3 badly on 5.10, hack to avoid.
1118     {
1119         no warnings qw/redefine/;
1120         local *setup = sub { };
1121         $class->setup unless $Catalyst::__AM_RESTARTING;
1122     }
1123
1124     # Initialize our data structure
1125     $class->components( {} );
1126
1127     $class->setup_components;
1128
1129     if ( $class->debug ) {
1130         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1131         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1132         for my $comp ( sort keys %{ $class->components } ) {
1133             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1134             $t->row( $comp, $type );
1135         }
1136         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1137           if ( keys %{ $class->components } );
1138     }
1139
1140     # Add our self to components, since we are also a component
1141     if( $class->isa('Catalyst::Controller') ){
1142       $class->components->{$class} = $class;
1143     }
1144
1145     $class->setup_actions;
1146
1147     if ( $class->debug ) {
1148         my $name = $class->config->{name} || 'Application';
1149         $class->log->info("$name powered by Catalyst $Catalyst::PRETTY_VERSION");
1150     }
1151
1152     # Make sure that the application class becomes immutable at this point,
1153     B::Hooks::EndOfScope::on_scope_end {
1154         return if $@;
1155         my $meta = Class::MOP::get_metaclass_by_name($class);
1156         if (
1157             $meta->is_immutable
1158             && ! { $meta->immutable_options }->{replace_constructor}
1159             && (
1160                    $class->isa('Class::Accessor::Fast')
1161                 || $class->isa('Class::Accessor')
1162             )
1163         ) {
1164             warn "You made your application class ($class) immutable, "
1165                 . "but did not inline the\nconstructor. "
1166                 . "This will break catalyst, as your app \@ISA "
1167                 . "Class::Accessor(::Fast)?\nPlease pass "
1168                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1169         }
1170         $meta->make_immutable(
1171             replace_constructor => 1,
1172         ) unless $meta->is_immutable;
1173     };
1174
1175     if ($class->config->{case_sensitive}) {
1176         $class->log->warn($class . "->config->{case_sensitive} is set.");
1177         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1178     }
1179
1180     $class->setup_finalize;
1181     # Should be the last thing we do so that user things hooking
1182     # setup_finalize can log..
1183     $class->log->_flush() if $class->log->can('_flush');
1184     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1185 }
1186
1187 =head2 $app->setup_finalize
1188
1189 A hook to attach modifiers to. This method does not do anything except set the
1190 C<setup_finished> accessor.
1191
1192 Applying method modifiers to the C<setup> method doesn't work, because of quirky thingsdone for plugin setup.
1193
1194 Example:
1195
1196     after setup_finalize => sub {
1197         my $app = shift;
1198
1199         ## do stuff here..
1200     };
1201
1202 =cut
1203
1204 sub setup_finalize {
1205     my ($class) = @_;
1206     $class->setup_finished(1);
1207 }
1208
1209 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1210
1211 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1212
1213 Constructs an absolute L<URI> object based on the application root, the
1214 provided path, and the additional arguments and query parameters provided.
1215 When used as a string, provides a textual URI.
1216
1217 If no arguments are provided, the URI for the current action is returned.
1218 To return the current action and also provide @args, use
1219 C<< $c->uri_for( $c->action, @args ) >>.
1220
1221 If the first argument is a string, it is taken as a public URI path relative
1222 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1223 relative to the application root (if it does). It is then merged with
1224 C<< $c->request->base >>; any C<@args> are appended as additional path
1225 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1226
1227 If the first argument is a L<Catalyst::Action> it represents an action which
1228 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1229 optional C<\@captures> argument (an arrayref) allows passing the captured
1230 variables that are needed to fill in the paths of Chained and Regex actions;
1231 once the path is resolved, C<uri_for> continues as though a path was
1232 provided, appending any arguments or parameters and creating an absolute
1233 URI.
1234
1235 The captures for the current request can be found in
1236 C<< $c->request->captures >>, and actions can be resolved using
1237 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1238 path, use C<< $c->uri_for_action >> instead.
1239
1240   # Equivalent to $c->req->uri
1241   $c->uri_for($c->action, $c->req->captures,
1242       @{ $c->req->args }, $c->req->params);
1243
1244   # For the Foo action in the Bar controller
1245   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1246
1247   # Path to a static resource
1248   $c->uri_for('/static/images/logo.png');
1249
1250 =cut
1251
1252 sub uri_for {
1253     my ( $c, $path, @args ) = @_;
1254
1255     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1256         $path = $path->path_prefix;
1257         $path =~ s{/+\z}{};
1258         $path .= '/';
1259     }
1260
1261     undef($path) if (defined $path && $path eq '');
1262
1263     my $params =
1264       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1265
1266     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1267     foreach my $arg (@args) {
1268         utf8::encode($arg) if utf8::is_utf8($arg);
1269     }
1270     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1271     if (blessed $path) { # Action object only.
1272         s|/|%2F|g for @args;
1273     }
1274
1275     if ( blessed($path) ) { # action object
1276         my $captures = [ map { s|/|%2F|g; $_; }
1277                         ( scalar @args && ref $args[0] eq 'ARRAY'
1278                          ? @{ shift(@args) }
1279                          : ()) ];
1280
1281         foreach my $capture (@$captures) {
1282             utf8::encode($capture) if utf8::is_utf8($capture);
1283             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1284         }
1285
1286         my $action = $path;
1287         $path = $c->dispatcher->uri_for_action($action, $captures);
1288         if (not defined $path) {
1289             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1290                 if $c->debug;
1291             return undef;
1292         }
1293         $path = '/' if $path eq '';
1294     }
1295
1296     undef($path) if (defined $path && $path eq '');
1297
1298     unshift(@args, $path);
1299
1300     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1301         my $namespace = $c->namespace;
1302         if (defined $path) { # cheesy hack to handle path '../foo'
1303            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1304         }
1305         unshift(@args, $namespace || '');
1306     }
1307
1308     # join args with '/', or a blank string
1309     my $args = join('/', grep { defined($_) } @args);
1310     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1311     $args =~ s!^/+!!;
1312     my $base = $c->req->base;
1313     my $class = ref($base);
1314     $base =~ s{(?<!/)$}{/};
1315
1316     my $query = '';
1317
1318     if (my @keys = keys %$params) {
1319       # somewhat lifted from URI::_query's query_form
1320       $query = '?'.join('&', map {
1321           my $val = $params->{$_};
1322           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1323           s/ /+/g;
1324           my $key = $_;
1325           $val = '' unless defined $val;
1326           (map {
1327               my $param = "$_";
1328               utf8::encode( $param ) if utf8::is_utf8($param);
1329               # using the URI::Escape pattern here so utf8 chars survive
1330               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1331               $param =~ s/ /+/g;
1332               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1333       } @keys);
1334     }
1335
1336     my $res = bless(\"${base}${args}${query}", $class);
1337     $res;
1338 }
1339
1340 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1341
1342 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1343
1344 =over
1345
1346 =item $path
1347
1348 A private path to the Catalyst action you want to create a URI for.
1349
1350 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1351 >> and passing the resulting C<$action> and the remaining arguments to C<<
1352 $c->uri_for >>.
1353
1354 You can also pass in a Catalyst::Action object, in which case it is passed to
1355 C<< $c->uri_for >>.
1356
1357 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1358
1359 For example, if the action looks like:
1360
1361  package MyApp::Controller::Users;
1362
1363  sub lst : Path('the-list') {}
1364
1365 You can use:
1366
1367  $c->uri_for_action('/users/lst')
1368
1369 and it will create the URI /users/the-list.
1370
1371 =back
1372
1373 =cut
1374
1375 sub uri_for_action {
1376     my ( $c, $path, @args ) = @_;
1377     my $action = blessed($path)
1378       ? $path
1379       : $c->dispatcher->get_action_by_path($path);
1380     unless (defined $action) {
1381       croak "Can't find action for path '$path'";
1382     }
1383     return $c->uri_for( $action, @args );
1384 }
1385
1386 =head2 $c->welcome_message
1387
1388 Returns the Catalyst welcome HTML page.
1389
1390 =cut
1391
1392 sub welcome_message {
1393     my $c      = shift;
1394     my $name   = $c->config->{name};
1395     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1396     my $prefix = Catalyst::Utils::appprefix( ref $c );
1397     $c->response->content_type('text/html; charset=utf-8');
1398     return <<"EOF";
1399 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1400     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1401 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1402     <head>
1403     <meta http-equiv="Content-Language" content="en" />
1404     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1405         <title>$name on Catalyst $VERSION</title>
1406         <style type="text/css">
1407             body {
1408                 color: #000;
1409                 background-color: #eee;
1410             }
1411             div#content {
1412                 width: 640px;
1413                 margin-left: auto;
1414                 margin-right: auto;
1415                 margin-top: 10px;
1416                 margin-bottom: 10px;
1417                 text-align: left;
1418                 background-color: #ccc;
1419                 border: 1px solid #aaa;
1420             }
1421             p, h1, h2 {
1422                 margin-left: 20px;
1423                 margin-right: 20px;
1424                 font-family: verdana, tahoma, sans-serif;
1425             }
1426             a {
1427                 font-family: verdana, tahoma, sans-serif;
1428             }
1429             :link, :visited {
1430                     text-decoration: none;
1431                     color: #b00;
1432                     border-bottom: 1px dotted #bbb;
1433             }
1434             :link:hover, :visited:hover {
1435                     color: #555;
1436             }
1437             div#topbar {
1438                 margin: 0px;
1439             }
1440             pre {
1441                 margin: 10px;
1442                 padding: 8px;
1443             }
1444             div#answers {
1445                 padding: 8px;
1446                 margin: 10px;
1447                 background-color: #fff;
1448                 border: 1px solid #aaa;
1449             }
1450             h1 {
1451                 font-size: 0.9em;
1452                 font-weight: normal;
1453                 text-align: center;
1454             }
1455             h2 {
1456                 font-size: 1.0em;
1457             }
1458             p {
1459                 font-size: 0.9em;
1460             }
1461             p img {
1462                 float: right;
1463                 margin-left: 10px;
1464             }
1465             span#appname {
1466                 font-weight: bold;
1467                 font-size: 1.6em;
1468             }
1469         </style>
1470     </head>
1471     <body>
1472         <div id="content">
1473             <div id="topbar">
1474                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1475                     $VERSION</h1>
1476              </div>
1477              <div id="answers">
1478                  <p>
1479                  <img src="$logo" alt="Catalyst Logo" />
1480                  </p>
1481                  <p>Welcome to the  world of Catalyst.
1482                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1483                     framework will make web development something you had
1484                     never expected it to be: Fun, rewarding, and quick.</p>
1485                  <h2>What to do now?</h2>
1486                  <p>That really depends  on what <b>you</b> want to do.
1487                     We do, however, provide you with a few starting points.</p>
1488                  <p>If you want to jump right into web development with Catalyst
1489                     you might want to start with a tutorial.</p>
1490 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1491 </pre>
1492 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1493 <pre>
1494 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1495 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1496 </code></pre>
1497                  <h2>What to do next?</h2>
1498                  <p>Next it's time to write an actual application. Use the
1499                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1500                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1501                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1502                     they can save you a lot of work.</p>
1503                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1504                     <p>Also, be sure to check out the vast and growing
1505                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1506                     you are likely to find what you need there.
1507                     </p>
1508
1509                  <h2>Need help?</h2>
1510                  <p>Catalyst has a very active community. Here are the main places to
1511                     get in touch with us.</p>
1512                  <ul>
1513                      <li>
1514                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1515                      </li>
1516                      <li>
1517                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1518                      </li>
1519                      <li>
1520                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1521                      </li>
1522                  </ul>
1523                  <h2>In conclusion</h2>
1524                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1525                     as we enjoyed making it. Please contact us if you have ideas
1526                     for improvement or other feedback.</p>
1527              </div>
1528          </div>
1529     </body>
1530 </html>
1531 EOF
1532 }
1533
1534 =head1 INTERNAL METHODS
1535
1536 These methods are not meant to be used by end users.
1537
1538 =head2 $c->components
1539
1540 Returns a hash of components.
1541
1542 =head2 $c->context_class
1543
1544 Returns or sets the context class.
1545
1546 =head2 $c->counter
1547
1548 Returns a hashref containing coderefs and execution counts (needed for
1549 deep recursion detection).
1550
1551 =head2 $c->depth
1552
1553 Returns the number of actions on the current internal execution stack.
1554
1555 =head2 $c->dispatch
1556
1557 Dispatches a request to actions.
1558
1559 =cut
1560
1561 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1562
1563 =head2 $c->dispatcher_class
1564
1565 Returns or sets the dispatcher class.
1566
1567 =head2 $c->dump_these
1568
1569 Returns a list of 2-element array references (name, structure) pairs
1570 that will be dumped on the error page in debug mode.
1571
1572 =cut
1573
1574 sub dump_these {
1575     my $c = shift;
1576     [ Request => $c->req ],
1577     [ Response => $c->res ],
1578     [ Stash => $c->stash ],
1579     [ Config => $c->config ];
1580 }
1581
1582 =head2 $c->engine_class
1583
1584 Returns or sets the engine class.
1585
1586 =head2 $c->execute( $class, $coderef )
1587
1588 Execute a coderef in given class and catch exceptions. Errors are available
1589 via $c->error.
1590
1591 =cut
1592
1593 sub execute {
1594     my ( $c, $class, $code ) = @_;
1595     $class = $c->component($class) || $class;
1596     $c->state(0);
1597
1598     if ( $c->depth >= $RECURSION ) {
1599         my $action = $code->reverse();
1600         $action = "/$action" unless $action =~ /->/;
1601         my $error = qq/Deep recursion detected calling "${action}"/;
1602         $c->log->error($error);
1603         $c->error($error);
1604         $c->state(0);
1605         return $c->state;
1606     }
1607
1608     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1609
1610     push( @{ $c->stack }, $code );
1611
1612     no warnings 'recursion';
1613     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1614
1615     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1616
1617     my $last = pop( @{ $c->stack } );
1618
1619     if ( my $error = $@ ) {
1620         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1621             $error->rethrow if $c->depth > 1;
1622         }
1623         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1624             $error->rethrow if $c->depth > 0;
1625         }
1626         else {
1627             unless ( ref $error ) {
1628                 no warnings 'uninitialized';
1629                 chomp $error;
1630                 my $class = $last->class;
1631                 my $name  = $last->name;
1632                 $error = qq/Caught exception in $class->$name "$error"/;
1633             }
1634             $c->error($error);
1635             $c->state(0);
1636         }
1637     }
1638     return $c->state;
1639 }
1640
1641 sub _stats_start_execute {
1642     my ( $c, $code ) = @_;
1643     my $appclass = ref($c) || $c;
1644     return if ( ( $code->name =~ /^_.*/ )
1645         && ( !$appclass->config->{show_internal_actions} ) );
1646
1647     my $action_name = $code->reverse();
1648     $c->counter->{$action_name}++;
1649
1650     my $action = $action_name;
1651     $action = "/$action" unless $action =~ /->/;
1652
1653     # determine if the call was the result of a forward
1654     # this is done by walking up the call stack and looking for a calling
1655     # sub of Catalyst::forward before the eval
1656     my $callsub = q{};
1657     for my $index ( 2 .. 11 ) {
1658         last
1659         if ( ( caller($index) )[0] eq 'Catalyst'
1660             && ( caller($index) )[3] eq '(eval)' );
1661
1662         if ( ( caller($index) )[3] =~ /forward$/ ) {
1663             $callsub = ( caller($index) )[3];
1664             $action  = "-> $action";
1665             last;
1666         }
1667     }
1668
1669     my $uid = $action_name . $c->counter->{$action_name};
1670
1671     # is this a root-level call or a forwarded call?
1672     if ( $callsub =~ /forward$/ ) {
1673         my $parent = $c->stack->[-1];
1674
1675         # forward, locate the caller
1676         if ( exists $c->counter->{"$parent"} ) {
1677             $c->stats->profile(
1678                 begin  => $action,
1679                 parent => "$parent" . $c->counter->{"$parent"},
1680                 uid    => $uid,
1681             );
1682         }
1683         else {
1684
1685             # forward with no caller may come from a plugin
1686             $c->stats->profile(
1687                 begin => $action,
1688                 uid   => $uid,
1689             );
1690         }
1691     }
1692     else {
1693
1694         # root-level call
1695         $c->stats->profile(
1696             begin => $action,
1697             uid   => $uid,
1698         );
1699     }
1700     return $action;
1701
1702 }
1703
1704 sub _stats_finish_execute {
1705     my ( $c, $info ) = @_;
1706     $c->stats->profile( end => $info );
1707 }
1708
1709 =head2 $c->finalize
1710
1711 Finalizes the request.
1712
1713 =cut
1714
1715 sub finalize {
1716     my $c = shift;
1717
1718     for my $error ( @{ $c->error } ) {
1719         $c->log->error($error);
1720     }
1721
1722     # Allow engine to handle finalize flow (for POE)
1723     my $engine = $c->engine;
1724     if ( my $code = $engine->can('finalize') ) {
1725         $engine->$code($c);
1726     }
1727     else {
1728
1729         $c->finalize_uploads;
1730
1731         # Error
1732         if ( $#{ $c->error } >= 0 ) {
1733             $c->finalize_error;
1734         }
1735
1736         $c->finalize_headers;
1737
1738         # HEAD request
1739         if ( $c->request->method eq 'HEAD' ) {
1740             $c->response->body('');
1741         }
1742
1743         $c->finalize_body;
1744     }
1745
1746     $c->log_response;
1747
1748     if ($c->use_stats) {
1749         my $elapsed = sprintf '%f', $c->stats->elapsed;
1750         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1751         $c->log->info(
1752             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1753     }
1754
1755     return $c->response->status;
1756 }
1757
1758 =head2 $c->finalize_body
1759
1760 Finalizes body.
1761
1762 =cut
1763
1764 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1765
1766 =head2 $c->finalize_cookies
1767
1768 Finalizes cookies.
1769
1770 =cut
1771
1772 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1773
1774 =head2 $c->finalize_error
1775
1776 Finalizes error.
1777
1778 =cut
1779
1780 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1781
1782 =head2 $c->finalize_headers
1783
1784 Finalizes headers.
1785
1786 =cut
1787
1788 sub finalize_headers {
1789     my $c = shift;
1790
1791     my $response = $c->response; #accessor calls can add up?
1792
1793     # Check if we already finalized headers
1794     return if $response->finalized_headers;
1795
1796     # Handle redirects
1797     if ( my $location = $response->redirect ) {
1798         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1799         $response->header( Location => $location );
1800
1801         if ( !$response->has_body ) {
1802             # Add a default body if none is already present
1803             $response->body(
1804                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1805             );
1806         }
1807     }
1808
1809     # Content-Length
1810     if ( $response->body && !$response->content_length ) {
1811
1812         # get the length from a filehandle
1813         if ( blessed( $response->body ) && $response->body->can('read') )
1814         {
1815             my $stat = stat $response->body;
1816             if ( $stat && $stat->size > 0 ) {
1817                 $response->content_length( $stat->size );
1818             }
1819             else {
1820                 $c->log->warn('Serving filehandle without a content-length');
1821             }
1822         }
1823         else {
1824             # everything should be bytes at this point, but just in case
1825             $response->content_length( length( $response->body ) );
1826         }
1827     }
1828
1829     # Errors
1830     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1831         $response->headers->remove_header("Content-Length");
1832         $response->body('');
1833     }
1834
1835     $c->finalize_cookies;
1836
1837     $c->engine->finalize_headers( $c, @_ );
1838
1839     # Done
1840     $response->finalized_headers(1);
1841 }
1842
1843 =head2 $c->finalize_output
1844
1845 An alias for finalize_body.
1846
1847 =head2 $c->finalize_read
1848
1849 Finalizes the input after reading is complete.
1850
1851 =cut
1852
1853 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1854
1855 =head2 $c->finalize_uploads
1856
1857 Finalizes uploads. Cleans up any temporary files.
1858
1859 =cut
1860
1861 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1862
1863 =head2 $c->get_action( $action, $namespace )
1864
1865 Gets an action in a given namespace.
1866
1867 =cut
1868
1869 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1870
1871 =head2 $c->get_actions( $action, $namespace )
1872
1873 Gets all actions of a given name in a namespace and all parent
1874 namespaces.
1875
1876 =cut
1877
1878 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1879
1880 =head2 $c->handle_request( $class, @arguments )
1881
1882 Called to handle each HTTP request.
1883
1884 =cut
1885
1886 sub handle_request {
1887     my ( $class, @arguments ) = @_;
1888
1889     # Always expect worst case!
1890     my $status = -1;
1891     eval {
1892         if ($class->debug) {
1893             my $secs = time - $START || 1;
1894             my $av = sprintf '%.3f', $COUNT / $secs;
1895             my $time = localtime time;
1896             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1897         }
1898
1899         my $c = $class->prepare(@arguments);
1900         $c->dispatch;
1901         $status = $c->finalize;
1902     };
1903
1904     if ( my $error = $@ ) {
1905         chomp $error;
1906         $class->log->error(qq/Caught exception in engine "$error"/);
1907     }
1908
1909     $COUNT++;
1910
1911     if(my $coderef = $class->log->can('_flush')){
1912         $class->log->$coderef();
1913     }
1914     return $status;
1915 }
1916
1917 =head2 $c->prepare( @arguments )
1918
1919 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1920 etc.).
1921
1922 =cut
1923
1924 sub prepare {
1925     my ( $class, @arguments ) = @_;
1926
1927     # XXX
1928     # After the app/ctxt split, this should become an attribute based on something passed
1929     # into the application.
1930     $class->context_class( ref $class || $class ) unless $class->context_class;
1931
1932     my $c = $class->context_class->new({});
1933
1934     # For on-demand data
1935     $c->request->_context($c);
1936     $c->response->_context($c);
1937
1938     #surely this is not the most efficient way to do things...
1939     $c->stats($class->stats_class->new)->enable($c->use_stats);
1940     if ( $c->debug ) {
1941         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1942     }
1943
1944     #XXX reuse coderef from can
1945     # Allow engine to direct the prepare flow (for POE)
1946     if ( $c->engine->can('prepare') ) {
1947         $c->engine->prepare( $c, @arguments );
1948     }
1949     else {
1950         $c->prepare_request(@arguments);
1951         $c->prepare_connection;
1952         $c->prepare_query_parameters;
1953         $c->prepare_headers;
1954         $c->prepare_cookies;
1955         $c->prepare_path;
1956
1957         # Prepare the body for reading, either by prepare_body
1958         # or the user, if they are using $c->read
1959         $c->prepare_read;
1960
1961         # Parse the body unless the user wants it on-demand
1962         unless ( ref($c)->config->{parse_on_demand} ) {
1963             $c->prepare_body;
1964         }
1965     }
1966
1967     my $method  = $c->req->method  || '';
1968     my $path    = $c->req->path;
1969     $path       = '/' unless length $path;
1970     my $address = $c->req->address || '';
1971
1972     $c->log_request;
1973
1974     $c->prepare_action;
1975
1976     return $c;
1977 }
1978
1979 =head2 $c->prepare_action
1980
1981 Prepares action. See L<Catalyst::Dispatcher>.
1982
1983 =cut
1984
1985 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1986
1987 =head2 $c->prepare_body
1988
1989 Prepares message body.
1990
1991 =cut
1992
1993 sub prepare_body {
1994     my $c = shift;
1995
1996     return if $c->request->_has_body;
1997
1998     # Initialize on-demand data
1999     $c->engine->prepare_body( $c, @_ );
2000     $c->prepare_parameters;
2001     $c->prepare_uploads;
2002 }
2003
2004 =head2 $c->prepare_body_chunk( $chunk )
2005
2006 Prepares a chunk of data before sending it to L<HTTP::Body>.
2007
2008 See L<Catalyst::Engine>.
2009
2010 =cut
2011
2012 sub prepare_body_chunk {
2013     my $c = shift;
2014     $c->engine->prepare_body_chunk( $c, @_ );
2015 }
2016
2017 =head2 $c->prepare_body_parameters
2018
2019 Prepares body parameters.
2020
2021 =cut
2022
2023 sub prepare_body_parameters {
2024     my $c = shift;
2025     $c->engine->prepare_body_parameters( $c, @_ );
2026 }
2027
2028 =head2 $c->prepare_connection
2029
2030 Prepares connection.
2031
2032 =cut
2033
2034 sub prepare_connection {
2035     my $c = shift;
2036     $c->engine->prepare_connection( $c, @_ );
2037 }
2038
2039 =head2 $c->prepare_cookies
2040
2041 Prepares cookies.
2042
2043 =cut
2044
2045 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2046
2047 =head2 $c->prepare_headers
2048
2049 Prepares headers.
2050
2051 =cut
2052
2053 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2054
2055 =head2 $c->prepare_parameters
2056
2057 Prepares parameters.
2058
2059 =cut
2060
2061 sub prepare_parameters {
2062     my $c = shift;
2063     $c->prepare_body_parameters;
2064     $c->engine->prepare_parameters( $c, @_ );
2065 }
2066
2067 =head2 $c->prepare_path
2068
2069 Prepares path and base.
2070
2071 =cut
2072
2073 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2074
2075 =head2 $c->prepare_query_parameters
2076
2077 Prepares query parameters.
2078
2079 =cut
2080
2081 sub prepare_query_parameters {
2082     my $c = shift;
2083
2084     $c->engine->prepare_query_parameters( $c, @_ );
2085 }
2086
2087 =head2 $c->log_request
2088
2089 Writes information about the request to the debug logs.  This includes:
2090
2091 =over 4
2092
2093 =item * Request method, path, and remote IP address
2094
2095 =item * Request headers (see L</log_headers>)
2096
2097 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2098
2099 =item * Request parameters
2100
2101 =item * File uploads
2102
2103 =back
2104
2105 =cut
2106
2107 sub log_request {
2108     my $c = shift;
2109
2110     return unless $c->debug;
2111
2112     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2113     my $request = $dump->[1];
2114
2115     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2116     $method ||= '';
2117     $path = '/' unless length $path;
2118     $address ||= '';
2119     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2120
2121     $c->log_headers('request', $request->headers);
2122
2123     if ( my $keywords = $request->query_keywords ) {
2124         $c->log->debug("Query keywords are: $keywords");
2125     }
2126
2127     $c->log_request_parameters( query => $request->query_parameters, body => $request->body_parameters );
2128
2129     $c->log_request_uploads($request);
2130 }
2131
2132 =head2 $c->log_response
2133
2134 Writes information about the response to the debug logs.  This includes:
2135
2136 =over 4
2137
2138 =item * Response status code
2139
2140 =item * Response headers (see L</log_headers>)
2141
2142 =back
2143
2144 =cut
2145
2146 sub log_response {
2147     my $c = shift;
2148
2149     return unless $c->debug;
2150
2151     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2152     my $response = $dump->[1];
2153
2154         $c->log->debug(
2155                 sprintf(
2156                         'Response Code: %s; Content-Type: %s; Content-Length: %s',
2157                         $response->status                            || 'unknown',
2158                         $response->headers->header('Content-Type')   || 'unknown',
2159                         $response->headers->header('Content-Length') || 'unknown'
2160                 )
2161         );
2162 }
2163
2164 =head2 $c->log_request_parameters( query => {}, body => {} )
2165
2166 Logs request parameters to debug logs
2167
2168 =cut
2169
2170 sub log_request_parameters {
2171     my $c          = shift;
2172     my %all_params = @_;
2173
2174     return unless $c->debug;
2175
2176     my $column_width = Catalyst::Utils::term_width() - 44;
2177     foreach my $type (qw(query body)) {
2178         my $params = $all_params{$type};
2179         next if ! keys %$params;
2180         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2181         for my $key ( sort keys %$params ) {
2182             my $param = $params->{$key};
2183             my $value = defined($param) ? $param : '';
2184             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2185         }
2186         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2187     }
2188 }
2189
2190 =head2 $c->log_request_uploads
2191
2192 Logs file uploads included in the request to the debug logs.
2193 The parameter name, filename, file type, and file size are all included in
2194 the debug logs.
2195
2196 =cut
2197
2198 sub log_request_uploads {
2199     my $c = shift;
2200     my $request = shift;
2201     return unless $c->debug;
2202     my $uploads = $request->uploads;
2203     if ( keys %$uploads ) {
2204         my $t = Text::SimpleTable->new(
2205             [ 12, 'Parameter' ],
2206             [ 26, 'Filename' ],
2207             [ 18, 'Type' ],
2208             [ 9,  'Size' ]
2209         );
2210         for my $key ( sort keys %$uploads ) {
2211             my $upload = $uploads->{$key};
2212             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2213                 $t->row( $key, $u->filename, $u->type, $u->size );
2214             }
2215         }
2216         $c->log->debug( "File Uploads are:\n" . $t->draw );
2217     }
2218 }
2219
2220 =head2 $c->log_headers($type => $headers)
2221
2222 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2223
2224 =cut
2225
2226 sub log_headers {
2227     my $c       = shift;
2228     my $type    = shift;
2229     my $headers = shift;    # an HTTP::Headers instance
2230
2231     return unless $c->debug;
2232
2233     my $t = Text::SimpleTable->new( [ 35, 'Header Name' ], [ 40, 'Value' ] );
2234     $headers->scan(
2235         sub {
2236             my ( $name, $value ) = @_;
2237             $t->row( $name, $value );
2238         }
2239     );
2240     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2241 }
2242
2243
2244 =head2 $c->prepare_read
2245
2246 Prepares the input for reading.
2247
2248 =cut
2249
2250 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2251
2252 =head2 $c->prepare_request
2253
2254 Prepares the engine request.
2255
2256 =cut
2257
2258 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2259
2260 =head2 $c->prepare_uploads
2261
2262 Prepares uploads.
2263
2264 =cut
2265
2266 sub prepare_uploads {
2267     my $c = shift;
2268
2269     $c->engine->prepare_uploads( $c, @_ );
2270 }
2271
2272 =head2 $c->prepare_write
2273
2274 Prepares the output for writing.
2275
2276 =cut
2277
2278 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2279
2280 =head2 $c->request_class
2281
2282 Returns or sets the request class.
2283
2284 =head2 $c->response_class
2285
2286 Returns or sets the response class.
2287
2288 =head2 $c->read( [$maxlength] )
2289
2290 Reads a chunk of data from the request body. This method is designed to
2291 be used in a while loop, reading C<$maxlength> bytes on every call.
2292 C<$maxlength> defaults to the size of the request if not specified.
2293
2294 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2295 directly.
2296
2297 Warning: If you use read(), Catalyst will not process the body,
2298 so you will not be able to access POST parameters or file uploads via
2299 $c->request.  You must handle all body parsing yourself.
2300
2301 =cut
2302
2303 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2304
2305 =head2 $c->run
2306
2307 Starts the engine.
2308
2309 =cut
2310
2311 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2312
2313 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2314
2315 Sets an action in a given namespace.
2316
2317 =cut
2318
2319 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2320
2321 =head2 $c->setup_actions($component)
2322
2323 Sets up actions for a component.
2324
2325 =cut
2326
2327 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2328
2329 =head2 $c->setup_components
2330
2331 This method is called internally to set up the application's components.
2332
2333 It finds modules by calling the L<locate_components> method, expands them to
2334 package names with the L<expand_component_module> method, and then installs
2335 each component into the application.
2336
2337 The C<setup_components> config option is passed to both of the above methods.
2338
2339 Installation of each component is performed by the L<setup_component> method,
2340 below.
2341
2342 =cut
2343
2344 sub setup_components {
2345     my $class = shift;
2346
2347     my $config  = $class->config->{ setup_components };
2348
2349     my @comps = sort { length $a <=> length $b }
2350                 $class->locate_components($config);
2351     my %comps = map { $_ => 1 } @comps;
2352
2353     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2354     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2355         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2356     ) if $deprecatedcatalyst_component_names;
2357
2358     for my $component ( @comps ) {
2359
2360         # We pass ignore_loaded here so that overlay files for (e.g.)
2361         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2362         # we know M::P::O found a file on disk so this is safe
2363
2364         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2365
2366         # Needs to be done as soon as the component is loaded, as loading a sub-component
2367         # (next time round the loop) can cause us to get the wrong metaclass..
2368         $class->_controller_init_base_classes($component);
2369     }
2370
2371     for my $component (@comps) {
2372         my $instance = $class->components->{ $component } = $class->setup_component($component);
2373         my @expanded_components = $instance->can('expand_modules')
2374             ? $instance->expand_modules( $component, $config )
2375             : $class->expand_component_module( $component, $config );
2376         for my $component (@expanded_components) {
2377             next if $comps{$component};
2378             $class->_controller_init_base_classes($component); # Also cover inner packages
2379             $class->components->{ $component } = $class->setup_component($component);
2380         }
2381     }
2382 }
2383
2384 =head2 $c->locate_components( $setup_component_config )
2385
2386 This method is meant to provide a list of component modules that should be
2387 setup for the application.  By default, it will use L<Module::Pluggable>.
2388
2389 Specify a C<setup_components> config option to pass additional options directly
2390 to L<Module::Pluggable>. To add additional search paths, specify a key named
2391 C<search_extra> as an array reference. Items in the array beginning with C<::>
2392 will have the application class name prepended to them.
2393
2394 =cut
2395
2396 sub locate_components {
2397     my $class  = shift;
2398     my $config = shift;
2399
2400     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2401     my $extra   = delete $config->{ search_extra } || [];
2402
2403     push @paths, @$extra;
2404
2405     my $locator = Module::Pluggable::Object->new(
2406         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2407         %$config
2408     );
2409
2410     my @comps = $locator->plugins;
2411
2412     return @comps;
2413 }
2414
2415 =head2 $c->expand_component_module( $component, $setup_component_config )
2416
2417 Components found by C<locate_components> will be passed to this method, which
2418 is expected to return a list of component (package) names to be set up.
2419
2420 =cut
2421
2422 sub expand_component_module {
2423     my ($class, $module) = @_;
2424     return Devel::InnerPackage::list_packages( $module );
2425 }
2426
2427 =head2 $c->setup_component
2428
2429 =cut
2430
2431 # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2432 #         nearest to Catalyst::Controller first, no matter what order stuff happens
2433 #         to be loaded. There are TODO tests in Moose for this, see
2434 #         f2391d17574eff81d911b97be15ea51080500003
2435 sub _controller_init_base_classes {
2436     my ($app_class, $component) = @_;
2437     return unless $component->isa('Catalyst::Controller');
2438     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2439         Moose::Meta::Class->initialize( $class )
2440             unless find_meta($class);
2441     }
2442 }
2443
2444 sub setup_component {
2445     my( $class, $component ) = @_;
2446
2447     unless ( $component->can( 'COMPONENT' ) ) {
2448         return $component;
2449     }
2450
2451     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2452     my $config = $class->config->{ $suffix } || {};
2453     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2454     # methods also pass it. local to avoid pointlessly shitting in config
2455     # for the debug screen, as $component is already the key name.
2456     local $config->{catalyst_component_name} = $component;
2457
2458     my $instance = eval { $component->COMPONENT( $class, $config ); };
2459
2460     if ( my $error = $@ ) {
2461         chomp $error;
2462         Catalyst::Exception->throw(
2463             message => qq/Couldn't instantiate component "$component", "$error"/
2464         );
2465     }
2466
2467     unless (blessed $instance) {
2468         my $metaclass = Moose::Util::find_meta($component);
2469         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2470         my $component_method_from = $method_meta->associated_metaclass->name;
2471         my $value = defined($instance) ? $instance : 'undef';
2472         Catalyst::Exception->throw(
2473             message =>
2474             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2475         );
2476     }
2477     return $instance;
2478 }
2479
2480 =head2 $c->setup_dispatcher
2481
2482 Sets up dispatcher.
2483
2484 =cut
2485
2486 sub setup_dispatcher {
2487     my ( $class, $dispatcher ) = @_;
2488
2489     if ($dispatcher) {
2490         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2491     }
2492
2493     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2494         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2495     }
2496
2497     unless ($dispatcher) {
2498         $dispatcher = $class->dispatcher_class;
2499     }
2500
2501     Class::MOP::load_class($dispatcher);
2502
2503     # dispatcher instance
2504     $class->dispatcher( $dispatcher->new );
2505 }
2506
2507 =head2 $c->setup_engine
2508
2509 Sets up engine.
2510
2511 =cut
2512
2513 sub setup_engine {
2514     my ( $class, $engine ) = @_;
2515
2516     if ($engine) {
2517         $engine = 'Catalyst::Engine::' . $engine;
2518     }
2519
2520     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2521         $engine = 'Catalyst::Engine::' . $env;
2522     }
2523
2524     if ( $ENV{MOD_PERL} ) {
2525         my $meta = Class::MOP::get_metaclass_by_name($class);
2526
2527         # create the apache method
2528         $meta->add_method('apache' => sub { shift->engine->apache });
2529
2530         my ( $software, $version ) =
2531           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2532
2533         $version =~ s/_//g;
2534         $version =~ s/(\.[^.]+)\./$1/g;
2535
2536         if ( $software eq 'mod_perl' ) {
2537
2538             if ( !$engine ) {
2539
2540                 if ( $version >= 1.99922 ) {
2541                     $engine = 'Catalyst::Engine::Apache2::MP20';
2542                 }
2543
2544                 elsif ( $version >= 1.9901 ) {
2545                     $engine = 'Catalyst::Engine::Apache2::MP19';
2546                 }
2547
2548                 elsif ( $version >= 1.24 ) {
2549                     $engine = 'Catalyst::Engine::Apache::MP13';
2550                 }
2551
2552                 else {
2553                     Catalyst::Exception->throw( message =>
2554                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2555                 }
2556
2557             }
2558
2559             # install the correct mod_perl handler
2560             if ( $version >= 1.9901 ) {
2561                 *handler = sub  : method {
2562                     shift->handle_request(@_);
2563                 };
2564             }
2565             else {
2566                 *handler = sub ($$) { shift->handle_request(@_) };
2567             }
2568
2569         }
2570
2571         elsif ( $software eq 'Zeus-Perl' ) {
2572             $engine = 'Catalyst::Engine::Zeus';
2573         }
2574
2575         else {
2576             Catalyst::Exception->throw(
2577                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2578         }
2579     }
2580
2581     unless ($engine) {
2582         $engine = $class->engine_class;
2583     }
2584
2585     Class::MOP::load_class($engine);
2586
2587     # check for old engines that are no longer compatible
2588     my $old_engine;
2589     if ( $engine->isa('Catalyst::Engine::Apache')
2590         && !Catalyst::Engine::Apache->VERSION )
2591     {
2592         $old_engine = 1;
2593     }
2594
2595     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2596         && Catalyst::Engine::Server->VERSION le '0.02' )
2597     {
2598         $old_engine = 1;
2599     }
2600
2601     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2602         && $engine->VERSION eq '0.01' )
2603     {
2604         $old_engine = 1;
2605     }
2606
2607     elsif ($engine->isa('Catalyst::Engine::Zeus')
2608         && $engine->VERSION eq '0.01' )
2609     {
2610         $old_engine = 1;
2611     }
2612
2613     if ($old_engine) {
2614         Catalyst::Exception->throw( message =>
2615               qq/Engine "$engine" is not supported by this version of Catalyst/
2616         );
2617     }
2618
2619     # engine instance
2620     $class->engine( $engine->new );
2621 }
2622
2623 =head2 $c->setup_home
2624
2625 Sets up the home directory.
2626
2627 =cut
2628
2629 sub setup_home {
2630     my ( $class, $home ) = @_;
2631
2632     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2633         $home = $env;
2634     }
2635
2636     $home ||= Catalyst::Utils::home($class);
2637
2638     if ($home) {
2639         #I remember recently being scolded for assigning config values like this
2640         $class->config->{home} ||= $home;
2641         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2642     }
2643 }
2644
2645 =head2 $c->setup_log
2646
2647 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2648 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2649 log to.
2650
2651 This method also installs a C<debug> method that returns a true value into the
2652 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2653 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2654
2655 Note that if the log has already been setup, by either a previous call to
2656 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2657 that this method won't actually set up the log object.
2658
2659 =cut
2660
2661 sub setup_log {
2662     my ( $class, $levels ) = @_;
2663
2664     $levels ||= '';
2665     $levels =~ s/^\s+//;
2666     $levels =~ s/\s+$//;
2667     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2668
2669     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2670     if ( defined $env_debug ) {
2671         $levels{debug} = 1 if $env_debug; # Ugly!
2672         delete($levels{debug}) unless $env_debug;
2673     }
2674
2675     unless ( $class->log ) {
2676         $class->log( Catalyst::Log->new(keys %levels) );
2677     }
2678
2679     if ( $levels{debug} ) {
2680         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2681         $class->log->debug('Debug messages enabled');
2682     }
2683 }
2684
2685 =head2 $c->setup_plugins
2686
2687 Sets up plugins.
2688
2689 =cut
2690
2691 =head2 $c->setup_stats
2692
2693 Sets up timing statistics class.
2694
2695 =cut
2696
2697 sub setup_stats {
2698     my ( $class, $stats ) = @_;
2699
2700     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2701
2702     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2703     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2704         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2705         $class->log->debug('Statistics enabled');
2706     }
2707 }
2708
2709
2710 =head2 $c->registered_plugins
2711
2712 Returns a sorted list of the plugins which have either been stated in the
2713 import list or which have been added via C<< MyApp->plugin(@args); >>.
2714
2715 If passed a given plugin name, it will report a boolean value indicating
2716 whether or not that plugin is loaded.  A fully qualified name is required if
2717 the plugin name does not begin with C<Catalyst::Plugin::>.
2718
2719  if ($c->registered_plugins('Some::Plugin')) {
2720      ...
2721  }
2722
2723 =cut
2724
2725 {
2726
2727     sub registered_plugins {
2728         my $proto = shift;
2729         return sort keys %{ $proto->_plugins } unless @_;
2730         my $plugin = shift;
2731         return 1 if exists $proto->_plugins->{$plugin};
2732         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2733     }
2734
2735     sub _register_plugin {
2736         my ( $proto, $plugin, $instant ) = @_;
2737         my $class = ref $proto || $proto;
2738
2739         Class::MOP::load_class( $plugin );
2740         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2741             if $plugin->isa( 'Catalyst::Component' );
2742         $proto->_plugins->{$plugin} = 1;
2743         unless ($instant) {
2744             no strict 'refs';
2745             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2746               my @superclasses = ($plugin, $meta->superclasses );
2747               $meta->superclasses(@superclasses);
2748             } else {
2749               unshift @{"$class\::ISA"}, $plugin;
2750             }
2751         }
2752         return $class;
2753     }
2754
2755     sub setup_plugins {
2756         my ( $class, $plugins ) = @_;
2757
2758         $class->_plugins( {} ) unless $class->_plugins;
2759         $plugins ||= [];
2760
2761         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2762
2763         for my $plugin ( reverse @plugins ) {
2764             Class::MOP::load_class($plugin);
2765             my $meta = find_meta($plugin);
2766             next if $meta && $meta->isa('Moose::Meta::Role');
2767
2768             $class->_register_plugin($plugin);
2769         }
2770
2771         my @roles =
2772             map { $_->name }
2773             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2774             map { find_meta($_) }
2775             @plugins;
2776
2777         Moose::Util::apply_all_roles(
2778             $class => @roles
2779         ) if @roles;
2780     }
2781 }
2782
2783 =head2 $c->stack
2784
2785 Returns an arrayref of the internal execution stack (actions that are
2786 currently executing).
2787
2788 =head2 $c->stats_class
2789
2790 Returns or sets the stats (timing statistics) class.
2791
2792 =head2 $c->use_stats
2793
2794 Returns 1 when stats collection is enabled.  Stats collection is enabled
2795 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2796 environment variable is set.
2797
2798 Note that this is a static method, not an accessor and should be overridden
2799 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2800
2801 =cut
2802
2803 sub use_stats { 0 }
2804
2805
2806 =head2 $c->write( $data )
2807
2808 Writes $data to the output stream. When using this method directly, you
2809 will need to manually set the C<Content-Length> header to the length of
2810 your output data, if known.
2811
2812 =cut
2813
2814 sub write {
2815     my $c = shift;
2816
2817     # Finalize headers if someone manually writes output
2818     $c->finalize_headers;
2819
2820     return $c->engine->write( $c, @_ );
2821 }
2822
2823 =head2 version
2824
2825 Returns the Catalyst version number. Mostly useful for "powered by"
2826 messages in template systems.
2827
2828 =cut
2829
2830 sub version { return $Catalyst::VERSION }
2831
2832 =head1 CONFIGURATION
2833
2834 There are a number of 'base' config variables which can be set:
2835
2836 =over
2837
2838 =item *
2839
2840 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2841
2842 =item *
2843
2844 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2845
2846 =item *
2847
2848 C<disable_component_resolution_regex_fallback> - Turns
2849 off the deprecated component resolution functionality so
2850 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2851 are called then regex search will not be attempted on string values and
2852 instead C<undef> will be returned.
2853
2854 =item *
2855
2856 C<home> - The application home directory. In an uninstalled application,
2857 this is the top level application directory. In an installed application,
2858 this will be the directory containing C<< MyApp.pm >>.
2859
2860 =item *
2861
2862 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2863
2864 =item *
2865
2866 C<name> - The name of the application in debug messages and the debug and
2867 welcome screens
2868
2869 =item *
2870
2871 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2872 until it is accessed. This allows you to (for example) check authentication (and reject
2873 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2874
2875 =item *
2876
2877 C<root> - The root directory for templates. Usually this is just a
2878 subdirectory of the home directory, but you can set it to change the
2879 templates to a different directory.
2880
2881 =item *
2882
2883 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2884 namespaces from which components will be loaded (and constructed and stored in
2885 C<< $c->components >>).
2886
2887 =item *
2888
2889 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2890 to be shown in hit debug tables in the test server.
2891
2892 =item *
2893
2894 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2895
2896 =back
2897
2898 =head1 INTERNAL ACTIONS
2899
2900 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2901 C<_ACTION>, and C<_END>. These are by default not shown in the private
2902 action table, but you can make them visible with a config parameter.
2903
2904     MyApp->config(show_internal_actions => 1);
2905
2906 =head1 ON-DEMAND PARSER
2907
2908 The request body is usually parsed at the beginning of a request,
2909 but if you want to handle input yourself, you can enable on-demand
2910 parsing with a config parameter.
2911
2912     MyApp->config(parse_on_demand => 1);
2913
2914 =head1 PROXY SUPPORT
2915
2916 Many production servers operate using the common double-server approach,
2917 with a lightweight frontend web server passing requests to a larger
2918 backend server. An application running on the backend server must deal
2919 with two problems: the remote user always appears to be C<127.0.0.1> and
2920 the server's hostname will appear to be C<localhost> regardless of the
2921 virtual host that the user connected through.
2922
2923 Catalyst will automatically detect this situation when you are running
2924 the frontend and backend servers on the same machine. The following
2925 changes are made to the request.
2926
2927     $c->req->address is set to the user's real IP address, as read from
2928     the HTTP X-Forwarded-For header.
2929
2930     The host value for $c->req->base and $c->req->uri is set to the real
2931     host, as read from the HTTP X-Forwarded-Host header.
2932
2933 Additionally, you may be running your backend application on an insecure
2934 connection (port 80) while your frontend proxy is running under SSL.  If there
2935 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2936 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2937 be created properly.
2938
2939 In the case of passing in:
2940
2941     X-Forwarded-Port: 443
2942
2943 All calls to C<uri_for> will result in an https link, as is expected.
2944
2945 Obviously, your web server must support these headers for this to work.
2946
2947 In a more complex server farm environment where you may have your
2948 frontend proxy server(s) on different machines, you will need to set a
2949 configuration option to tell Catalyst to read the proxied data from the
2950 headers.
2951
2952     MyApp->config(using_frontend_proxy => 1);
2953
2954 If you do not wish to use the proxy support at all, you may set:
2955
2956     MyApp->config(ignore_frontend_proxy => 1);
2957
2958 =head1 THREAD SAFETY
2959
2960 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2961 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2962 believe the Catalyst core to be thread-safe.
2963
2964 If you plan to operate in a threaded environment, remember that all other
2965 modules you are using must also be thread-safe. Some modules, most notably
2966 L<DBD::SQLite>, are not thread-safe.
2967
2968 =head1 SUPPORT
2969
2970 IRC:
2971
2972     Join #catalyst on irc.perl.org.
2973
2974 Mailing Lists:
2975
2976     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2977     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2978
2979 Web:
2980
2981     http://catalyst.perl.org
2982
2983 Wiki:
2984
2985     http://dev.catalyst.perl.org
2986
2987 =head1 SEE ALSO
2988
2989 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2990
2991 =head2 L<Catalyst::Manual> - The Catalyst Manual
2992
2993 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2994
2995 =head2 L<Catalyst::Engine> - Core engine
2996
2997 =head2 L<Catalyst::Log> - Log class.
2998
2999 =head2 L<Catalyst::Request> - Request object
3000
3001 =head2 L<Catalyst::Response> - Response object
3002
3003 =head2 L<Catalyst::Test> - The test suite.
3004
3005 =head1 PROJECT FOUNDER
3006
3007 sri: Sebastian Riedel <sri@cpan.org>
3008
3009 =head1 CONTRIBUTORS
3010
3011 abw: Andy Wardley
3012
3013 acme: Leon Brocard <leon@astray.com>
3014
3015 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3016
3017 Andrew Bramble
3018
3019 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3020
3021 Andrew Ruthven
3022
3023 andyg: Andy Grundman <andy@hybridized.org>
3024
3025 audreyt: Audrey Tang
3026
3027 bricas: Brian Cassidy <bricas@cpan.org>
3028
3029 Caelum: Rafael Kitover <rkitover@io.com>
3030
3031 chansen: Christian Hansen
3032
3033 chicks: Christopher Hicks
3034
3035 Chisel Wright C<pause@herlpacker.co.uk>
3036
3037 Danijel Milicevic C<me@danijel.de>
3038
3039 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3040
3041 David Naughton, C<naughton@umn.edu>
3042
3043 David E. Wheeler
3044
3045 dhoss: Devin Austin <dhoss@cpan.org>
3046
3047 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3048
3049 Drew Taylor
3050
3051 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3052
3053 esskar: Sascha Kiefer
3054
3055 fireartist: Carl Franks <cfranks@cpan.org>
3056
3057 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3058
3059 gabb: Danijel Milicevic
3060
3061 Gary Ashton Jones
3062
3063 Gavin Henry C<ghenry@perl.me.uk>
3064
3065 Geoff Richards
3066
3067 groditi: Guillermo Roditi <groditi@gmail.com>
3068
3069 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3070
3071 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3072
3073 jcamacho: Juan Camacho
3074
3075 jester: Jesse Sheidlower C<jester@panix.com>
3076
3077 jhannah: Jay Hannah <jay@jays.net>
3078
3079 Jody Belka
3080
3081 Johan Lindstrom
3082
3083 jon: Jon Schutz <jjschutz@cpan.org>
3084
3085 Jonathan Rockway C<< <jrockway@cpan.org> >>
3086
3087 Kieren Diment C<kd@totaldatasolution.com>
3088
3089 konobi: Scott McWhirter <konobi@cpan.org>
3090
3091 marcus: Marcus Ramberg <mramberg@cpan.org>
3092
3093 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3094
3095 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3096
3097 mugwump: Sam Vilain
3098
3099 naughton: David Naughton
3100
3101 ningu: David Kamholz <dkamholz@cpan.org>
3102
3103 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3104
3105 numa: Dan Sully <daniel@cpan.org>
3106
3107 obra: Jesse Vincent
3108
3109 Octavian Rasnita
3110
3111 omega: Andreas Marienborg
3112
3113 Oleg Kostyuk <cub.uanic@gmail.com>
3114
3115 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3116
3117 rafl: Florian Ragwitz <rafl@debian.org>
3118
3119 random: Roland Lammel <lammel@cpan.org>
3120
3121 Robert Sedlacek C<< <rs@474.at> >>
3122
3123 sky: Arthur Bergman
3124
3125 t0m: Tomas Doran <bobtfish@bobtfish.net>
3126
3127 Ulf Edvinsson
3128
3129 Viljo Marrandi C<vilts@yahoo.com>
3130
3131 Will Hawes C<info@whawes.co.uk>
3132
3133 willert: Sebastian Willert <willert@cpan.org>
3134
3135 Yuval Kogman, C<nothingmuch@woobling.org>
3136
3137 =head1 LICENSE
3138
3139 This library is free software. You can redistribute it and/or modify it under
3140 the same terms as Perl itself.
3141
3142 =cut
3143
3144 no Moose;
3145
3146 __PACKAGE__->meta->make_immutable;
3147
3148 1;