lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use String::RewritePrefix;
  32 use Catalyst::EngineLoader;
  33 use utf8;
  34 use Carp qw/croak carp shortmess/;
  35 use Try::Tiny;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39 use Plack::Middleware::LighttpdScriptNameFix;
  40
  41 BEGIN { require 5.008004; }
  42
  43 has stack => (is => 'ro', default => sub { [] });
  44 has stash => (is => 'rw', default => sub { {} });
  45 has state => (is => 'rw', default => 0);
  46 has stats => (is => 'rw');
  47 has action => (is => 'rw');
  48 has counter => (is => 'rw', default => sub { {} });
  49 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  50 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  51 has namespace => (is => 'rw');
  52
  53 sub depth { scalar @{ shift->stack || [] }; }
  54 sub comp { shift->component(@_) }
  55
  56 sub req {
  57     my $self = shift; return $self->request(@_);
  58 }
  59 sub res {
  60     my $self = shift; return $self->response(@_);
  61 }
  62
  63 # For backwards compatibility
  64 sub finalize_output { shift->finalize_body(@_) };
  65
  66 # For statistics
  67 our $COUNT     = 1;
  68 our $START     = time;
  69 our $RECURSION = 1000;
  70 our $DETACH    = Catalyst::Exception::Detach->new;
  71 our $GO        = Catalyst::Exception::Go->new;
  72
  73 #I imagine that very few of these really need to be class variables. if any.
  74 #maybe we should just make them attributes with a default?
  75 __PACKAGE__->mk_classdata($_)
  76   for qw/components arguments dispatcher engine log dispatcher_class
  77   engine_loader context_class request_class response_class stats_class
  78   setup_finished _psgi_app loading_psgi_file/;
  79
  80 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  81 __PACKAGE__->request_class('Catalyst::Request');
  82 __PACKAGE__->response_class('Catalyst::Response');
  83 __PACKAGE__->stats_class('Catalyst::Stats');
  84
  85 # Remember to update this in Catalyst::Runtime as well!
  86
  87 our $VERSION = '5.90004';
  88
  89 sub import {
  90     my ( $class, @arguments ) = @_;
  91
  92     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  93     # callers @ISA.
  94     return unless $class eq 'Catalyst';
  95
  96     my $caller = caller();
  97     return if $caller eq 'main';
  98
  99     my $meta = Moose::Meta::Class->initialize($caller);
 100     unless ( $caller->isa('Catalyst') ) {
 101         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 102         $meta->superclasses(@superclasses);
 103     }
 104     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 105     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 106
 107     unless( $meta->has_method('meta') ){
 108         if ($Moose::VERSION >= 1.15) {
 109             $meta->_add_meta_method('meta');
 110         }
 111         else {
 112             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 113         }
 114     }
 115
 116     $caller->arguments( [@arguments] );
 117     $caller->setup_home;
 118 }
 119
 120 sub _application { $_[0] }
 121
 122 =head1 NAME
 123
 124 Catalyst - The Elegant MVC Web Application Framework
 125
 126 =head1 SYNOPSIS
 127
 128 See the L<Catalyst::Manual> distribution for comprehensive
 129 documentation and tutorials.
 130
 131     # Install Catalyst::Devel for helpers and other development tools
 132     # use the helper to create a new application
 133     catalyst.pl MyApp
 134
 135     # add models, views, controllers
 136     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 137     script/myapp_create.pl view MyTemplate TT
 138     script/myapp_create.pl controller Search
 139
 140     # built in testserver -- use -r to restart automatically on changes
 141     # --help to see all available options
 142     script/myapp_server.pl
 143
 144     # command line testing interface
 145     script/myapp_test.pl /yada
 146
 147     ### in lib/MyApp.pm
 148     use Catalyst qw/-Debug/; # include plugins here as well
 149
 150     ### In lib/MyApp/Controller/Root.pm (autocreated)
 151     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 152         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 153         $c->stash->{template} = 'foo.tt'; # set the template
 154         # lookup something from db -- stash vars are passed to TT
 155         $c->stash->{data} =
 156           $c->model('Database::Foo')->search( { country => $args[0] } );
 157         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 158             $c->forward( 'bar' ); # process another action
 159             # do something else after forward returns
 160         }
 161     }
 162
 163     # The foo.tt TT template can use the stash data from the database
 164     [% WHILE (item = data.next) %]
 165         [% item.foo %]
 166     [% END %]
 167
 168     # called for /bar/of/soap, /bar/of/soap/10, etc.
 169     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 170
 171     # called after all actions are finished
 172     sub end : Action {
 173         my ( $self, $c ) = @_;
 174         if ( scalar @{ $c->error } ) { ... } # handle errors
 175         return if $c->res->body; # already have a response
 176         $c->forward( 'MyApp::View::TT' ); # render template
 177     }
 178
 179 See L<Catalyst::Manual::Intro> for additional information.
 180
 181 =head1 DESCRIPTION
 182
 183 Catalyst is a modern framework for making web applications without the
 184 pain usually associated with this process. This document is a reference
 185 to the main Catalyst application. If you are a new user, we suggest you
 186 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 187
 188 See L<Catalyst::Manual> for more documentation.
 189
 190 Catalyst plugins can be loaded by naming them as arguments to the "use
 191 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 192 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 193 C<My::Module>.
 194
 195     use Catalyst qw/My::Module/;
 196
 197 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 198 fully qualify the name by using a unary plus:
 199
 200     use Catalyst qw/
 201         My::Module
 202         +Fully::Qualified::Plugin::Name
 203     /;
 204
 205 Special flags like C<-Debug> can also be specified as
 206 arguments when Catalyst is loaded:
 207
 208     use Catalyst qw/-Debug My::Module/;
 209
 210 The position of plugins and flags in the chain is important, because
 211 they are loaded in the order in which they appear.
 212
 213 The following flags are supported:
 214
 215 =head2 -Debug
 216
 217 Enables debug output. You can also force this setting from the system
 218 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 219 settings override the application, with <MYAPP>_DEBUG having the highest
 220 priority.
 221
 222 This sets the log level to 'debug' and enables full debug output on the
 223 error screen. If you only want the latter, see L<< $c->debug >>.
 224
 225 =head2 -Home
 226
 227 Forces Catalyst to use a specific home directory, e.g.:
 228
 229     use Catalyst qw[-Home=/usr/mst];
 230
 231 This can also be done in the shell environment by setting either the
 232 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 233 is replaced with the uppercased name of your application, any "::" in
 234 the name will be replaced with underscores, e.g. MyApp::Web should use
 235 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 236
 237 If none of these are set, Catalyst will attempt to automatically detect the
 238 home directory. If you are working in a development envirnoment, Catalyst
 239 will try and find the directory containing either Makefile.PL, Build.PL or
 240 dist.ini. If the application has been installed into the system (i.e.
 241 you have done C<make install>), then Catalyst will use the path to your
 242 application module, without the .pm extension (ie, /foo/MyApp if your
 243 application was installed at /foo/MyApp.pm)
 244
 245 =head2 -Log
 246
 247     use Catalyst '-Log=warn,fatal,error';
 248
 249 Specifies a comma-delimited list of log levels.
 250
 251 =head2 -Stats
 252
 253 Enables statistics collection and reporting.
 254
 255    use Catalyst qw/-Stats=1/;
 256
 257 You can also force this setting from the system environment with CATALYST_STATS
 258 or <MYAPP>_STATS. The environment settings override the application, with
 259 <MYAPP>_STATS having the highest priority.
 260
 261 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 262
 263 =head1 METHODS
 264
 265 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 266
 267 =head2 $c->action
 268
 269 Returns a L<Catalyst::Action> object for the current action, which
 270 stringifies to the action name. See L<Catalyst::Action>.
 271
 272 =head2 $c->namespace
 273
 274 Returns the namespace of the current action, i.e., the URI prefix
 275 corresponding to the controller of the current action. For example:
 276
 277     # in Controller::Foo::Bar
 278     $c->namespace; # returns 'foo/bar';
 279
 280 =head2 $c->request
 281
 282 =head2 $c->req
 283
 284 Returns the current L<Catalyst::Request> object, giving access to
 285 information about the current client request (including parameters,
 286 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 287
 288 =head2 REQUEST FLOW HANDLING
 289
 290 =head2 $c->forward( $action [, \@arguments ] )
 291
 292 =head2 $c->forward( $class, $method, [, \@arguments ] )
 293
 294 Forwards processing to another action, by its private name. If you give a
 295 class name but no method, C<process()> is called. You may also optionally
 296 pass arguments in an arrayref. The action will receive the arguments in
 297 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 298 C<< $c->req->args >> will be restored to the previous values.
 299
 300 Any data C<return>ed from the action forwarded to, will be returned by the
 301 call to forward.
 302
 303     my $foodata = $c->forward('/foo');
 304     $c->forward('index');
 305     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 306     $c->forward('View::TT');
 307
 308 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 309 an C<< eval { } >> around the call (actually
 310 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 311 all 'dies' within the called action. If you want C<die> to propagate you
 312 need to do something like:
 313
 314     $c->forward('foo');
 315     die join "\n", @{ $c->error } if @{ $c->error };
 316
 317 Or make sure to always return true values from your actions and write
 318 your code like this:
 319
 320     $c->forward('foo') || return;
 321
 322 Another note is that C<< $c->forward >> always returns a scalar because it
 323 actually returns $c->state which operates in a scalar context.
 324 Thus, something like:
 325
 326     return @array;
 327
 328 in an action that is forwarded to is going to return a scalar,
 329 i.e. how many items are in that array, which is probably not what you want.
 330 If you need to return an array then return a reference to it,
 331 or stash it like so:
 332
 333     $c->stash->{array} = \@array;
 334
 335 and access it from the stash.
 336
 337 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 338
 339 =cut
 340
 341 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 342
 343 =head2 $c->detach( $action [, \@arguments ] )
 344
 345 =head2 $c->detach( $class, $method, [, \@arguments ] )
 346
 347 =head2 $c->detach()
 348
 349 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 350 doesn't return to the previous action when processing is finished.
 351
 352 When called with no arguments it escapes the processing chain entirely.
 353
 354 =cut
 355
 356 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 357
 358 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 359
 360 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 361
 362 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 363 but does a full dispatch, instead of just calling the new C<$action> /
 364 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 365 you go to are called, just like a new request.
 366
 367 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 368 This means, for example, that C<< $c->action >> methods such as
 369 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 370 L<reverse|Catalyst::Action/reverse> return information for the visited action
 371 when they are invoked within the visited action.  This is different from the
 372 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 373 continues to use the $c->action object from the caller action even when
 374 invoked from the callee.
 375
 376 C<< $c->stash >> is kept unchanged.
 377
 378 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 379 allows you to "wrap" another action, just as it would have been called by
 380 dispatching from a URL, while the analogous
 381 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 382 transfer control to another action as if it had been reached directly from a URL.
 383
 384 =cut
 385
 386 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 387
 388 =head2 $c->go( $action [, \@captures, \@arguments ] )
 389
 390 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 391
 392 The relationship between C<go> and
 393 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 394 the relationship between
 395 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 396 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 397 C<< $c->go >> will perform a full dispatch on the specified action or method,
 398 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 399 C<go> escapes the processing of the current request chain on completion, and
 400 does not return to its caller.
 401
 402 @arguments are arguments to the final destination of $action. @captures are
 403 arguments to the intermediate steps, if any, on the way to the final sub of
 404 $action.
 405
 406 =cut
 407
 408 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 409
 410 =head2 $c->response
 411
 412 =head2 $c->res
 413
 414 Returns the current L<Catalyst::Response> object, see there for details.
 415
 416 =head2 $c->stash
 417
 418 Returns a hashref to the stash, which may be used to store data and pass
 419 it between components during a request. You can also set hash keys by
 420 passing arguments. The stash is automatically sent to the view. The
 421 stash is cleared at the end of a request; it cannot be used for
 422 persistent storage (for this you must use a session; see
 423 L<Catalyst::Plugin::Session> for a complete system integrated with
 424 Catalyst).
 425
 426     $c->stash->{foo} = $bar;
 427     $c->stash( { moose => 'majestic', qux => 0 } );
 428     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 429
 430     # stash is automatically passed to the view for use in a template
 431     $c->forward( 'MyApp::View::TT' );
 432
 433 =cut
 434
 435 around stash => sub {
 436     my $orig = shift;
 437     my $c = shift;
 438     my $stash = $orig->($c);
 439     if (@_) {
 440         my $new_stash = @_ > 1 ? {@_} : $_[0];
 441         croak('stash takes a hash or hashref') unless ref $new_stash;
 442         foreach my $key ( keys %$new_stash ) {
 443           $stash->{$key} = $new_stash->{$key};
 444         }
 445     }
 446
 447     return $stash;
 448 };
 449
 450
 451 =head2 $c->error
 452
 453 =head2 $c->error($error, ...)
 454
 455 =head2 $c->error($arrayref)
 456
 457 Returns an arrayref containing error messages.  If Catalyst encounters an
 458 error while processing a request, it stores the error in $c->error.  This
 459 method should only be used to store fatal error messages.
 460
 461     my @error = @{ $c->error };
 462
 463 Add a new error.
 464
 465     $c->error('Something bad happened');
 466
 467 =cut
 468
 469 sub error {
 470     my $c = shift;
 471     if ( $_[0] ) {
 472         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 473         croak @$error unless ref $c;
 474         push @{ $c->{error} }, @$error;
 475     }
 476     elsif ( defined $_[0] ) { $c->{error} = undef }
 477     return $c->{error} || [];
 478 }
 479
 480
 481 =head2 $c->state
 482
 483 Contains the return value of the last executed action.
 484 Note that << $c->state >> operates in a scalar context which means that all
 485 values it returns are scalar.
 486
 487 =head2 $c->clear_errors
 488
 489 Clear errors.  You probably don't want to clear the errors unless you are
 490 implementing a custom error screen.
 491
 492 This is equivalent to running
 493
 494     $c->error(0);
 495
 496 =cut
 497
 498 sub clear_errors {
 499     my $c = shift;
 500     $c->error(0);
 501 }
 502
 503 sub _comp_search_prefixes {
 504     my $c = shift;
 505     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 506 }
 507
 508 # search components given a name and some prefixes
 509 sub _comp_names_search_prefixes {
 510     my ( $c, $name, @prefixes ) = @_;
 511     my $appclass = ref $c || $c;
 512     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 513     $filter = qr/$filter/; # Compile regex now rather than once per loop
 514
 515     # map the original component name to the sub part that we will search against
 516     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 517         grep { /$filter/ } keys %{ $c->components };
 518
 519     # undef for a name will return all
 520     return keys %eligible if !defined $name;
 521
 522     my $query  = ref $name ? $name : qr/^$name$/i;
 523     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 524
 525     return @result if @result;
 526
 527     # if we were given a regexp to search against, we're done.
 528     return if ref $name;
 529
 530     # skip regexp fallback if configured
 531     return
 532         if $appclass->config->{disable_component_resolution_regex_fallback};
 533
 534     # regexp fallback
 535     $query  = qr/$name/i;
 536     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 537
 538     # no results? try against full names
 539     if( !@result ) {
 540         @result = grep { m{$query} } keys %eligible;
 541     }
 542
 543     # don't warn if we didn't find any results, it just might not exist
 544     if( @result ) {
 545         # Disgusting hack to work out correct method name
 546         my $warn_for = lc $prefixes[0];
 547         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 548            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 549            "component resolution is unreliable and unsafe.";
 550         my $short = $result[0];
 551         # remove the component namespace prefix
 552         $short =~ s/.*?(Model|Controller|View):://;
 553         my $shortmess = Carp::shortmess('');
 554         if ($shortmess =~ m#Catalyst/Plugin#) {
 555            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 556               "plugin's config";
 557         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 558            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 559               "component's config";
 560         } else {
 561            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 562               "but if you really wanted to search, pass in a regexp as the argument " .
 563               "like so: \$c->${warn_for}(qr/${name}/)";
 564         }
 565         $c->log->warn( "${msg}$shortmess" );
 566     }
 567
 568     return @result;
 569 }
 570
 571 # Find possible names for a prefix
 572 sub _comp_names {
 573     my ( $c, @prefixes ) = @_;
 574     my $appclass = ref $c || $c;
 575
 576     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 577
 578     my @names = map { s{$filter}{}; $_; }
 579         $c->_comp_names_search_prefixes( undef, @prefixes );
 580
 581     return @names;
 582 }
 583
 584 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 585 sub _filter_component {
 586     my ( $c, $comp, @args ) = @_;
 587
 588     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 589         return $comp->ACCEPT_CONTEXT( $c, @args );
 590     }
 591
 592     return $comp;
 593 }
 594
 595 =head2 COMPONENT ACCESSORS
 596
 597 =head2 $c->controller($name)
 598
 599 Gets a L<Catalyst::Controller> instance by name.
 600
 601     $c->controller('Foo')->do_stuff;
 602
 603 If the name is omitted, will return the controller for the dispatched
 604 action.
 605
 606 If you want to search for controllers, pass in a regexp as the argument.
 607
 608     # find all controllers that start with Foo
 609     my @foo_controllers = $c->controller(qr{^Foo});
 610
 611
 612 =cut
 613
 614 sub controller {
 615     my ( $c, $name, @args ) = @_;
 616
 617     my $appclass = ref($c) || $c;
 618     if( $name ) {
 619         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 620             my $comps = $c->components;
 621             my $check = $appclass."::Controller::".$name;
 622             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 623         }
 624         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 625         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 626         return $c->_filter_component( $result[ 0 ], @args );
 627     }
 628
 629     return $c->component( $c->action->class );
 630 }
 631
 632 =head2 $c->model($name)
 633
 634 Gets a L<Catalyst::Model> instance by name.
 635
 636     $c->model('Foo')->do_stuff;
 637
 638 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 639
 640 If the name is omitted, it will look for
 641  - a model object in $c->stash->{current_model_instance}, then
 642  - a model name in $c->stash->{current_model}, then
 643  - a config setting 'default_model', or
 644  - check if there is only one model, and return it if that's the case.
 645
 646 If you want to search for models, pass in a regexp as the argument.
 647
 648     # find all models that start with Foo
 649     my @foo_models = $c->model(qr{^Foo});
 650
 651 =cut
 652
 653 sub model {
 654     my ( $c, $name, @args ) = @_;
 655     my $appclass = ref($c) || $c;
 656     if( $name ) {
 657         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 658             my $comps = $c->components;
 659             my $check = $appclass."::Model::".$name;
 660             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 661         }
 662         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 663         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 664         return $c->_filter_component( $result[ 0 ], @args );
 665     }
 666
 667     if (ref $c) {
 668         return $c->stash->{current_model_instance}
 669           if $c->stash->{current_model_instance};
 670         return $c->model( $c->stash->{current_model} )
 671           if $c->stash->{current_model};
 672     }
 673     return $c->model( $appclass->config->{default_model} )
 674       if $appclass->config->{default_model};
 675
 676     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 677
 678     if( $rest ) {
 679         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 680         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 681         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 682         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 683         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 684     }
 685
 686     return $c->_filter_component( $comp );
 687 }
 688
 689
 690 =head2 $c->view($name)
 691
 692 Gets a L<Catalyst::View> instance by name.
 693
 694     $c->view('Foo')->do_stuff;
 695
 696 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 697
 698 If the name is omitted, it will look for
 699  - a view object in $c->stash->{current_view_instance}, then
 700  - a view name in $c->stash->{current_view}, then
 701  - a config setting 'default_view', or
 702  - check if there is only one view, and return it if that's the case.
 703
 704 If you want to search for views, pass in a regexp as the argument.
 705
 706     # find all views that start with Foo
 707     my @foo_views = $c->view(qr{^Foo});
 708
 709 =cut
 710
 711 sub view {
 712     my ( $c, $name, @args ) = @_;
 713
 714     my $appclass = ref($c) || $c;
 715     if( $name ) {
 716         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 717             my $comps = $c->components;
 718             my $check = $appclass."::View::".$name;
 719             if( exists $comps->{$check} ) {
 720                 return $c->_filter_component( $comps->{$check}, @args );
 721             }
 722             else {
 723                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 724             }
 725         }
 726         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 727         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 728         return $c->_filter_component( $result[ 0 ], @args );
 729     }
 730
 731     if (ref $c) {
 732         return $c->stash->{current_view_instance}
 733           if $c->stash->{current_view_instance};
 734         return $c->view( $c->stash->{current_view} )
 735           if $c->stash->{current_view};
 736     }
 737     return $c->view( $appclass->config->{default_view} )
 738       if $appclass->config->{default_view};
 739
 740     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 741
 742     if( $rest ) {
 743         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 744         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 745         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 746         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 747         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 748     }
 749
 750     return $c->_filter_component( $comp );
 751 }
 752
 753 =head2 $c->controllers
 754
 755 Returns the available names which can be passed to $c->controller
 756
 757 =cut
 758
 759 sub controllers {
 760     my ( $c ) = @_;
 761     return $c->_comp_names(qw/Controller C/);
 762 }
 763
 764 =head2 $c->models
 765
 766 Returns the available names which can be passed to $c->model
 767
 768 =cut
 769
 770 sub models {
 771     my ( $c ) = @_;
 772     return $c->_comp_names(qw/Model M/);
 773 }
 774
 775
 776 =head2 $c->views
 777
 778 Returns the available names which can be passed to $c->view
 779
 780 =cut
 781
 782 sub views {
 783     my ( $c ) = @_;
 784     return $c->_comp_names(qw/View V/);
 785 }
 786
 787 =head2 $c->comp($name)
 788
 789 =head2 $c->component($name)
 790
 791 Gets a component object by name. This method is not recommended,
 792 unless you want to get a specific component by full
 793 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 794 should be used instead.
 795
 796 If C<$name> is a regexp, a list of components matched against the full
 797 component name will be returned.
 798
 799 If Catalyst can't find a component by name, it will fallback to regex
 800 matching by default. To disable this behaviour set
 801 disable_component_resolution_regex_fallback to a true value.
 802
 803     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 804
 805 =cut
 806
 807 sub component {
 808     my ( $c, $name, @args ) = @_;
 809
 810     if( $name ) {
 811         my $comps = $c->components;
 812
 813         if( !ref $name ) {
 814             # is it the exact name?
 815             return $c->_filter_component( $comps->{ $name }, @args )
 816                        if exists $comps->{ $name };
 817
 818             # perhaps we just omitted "MyApp"?
 819             my $composed = ( ref $c || $c ) . "::${name}";
 820             return $c->_filter_component( $comps->{ $composed }, @args )
 821                        if exists $comps->{ $composed };
 822
 823             # search all of the models, views and controllers
 824             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 825             return $c->_filter_component( $comp, @args ) if $comp;
 826         }
 827
 828         return
 829             if $c->config->{disable_component_resolution_regex_fallback};
 830
 831         # This is here so $c->comp( '::M::' ) works
 832         my $query = ref $name ? $name : qr{$name}i;
 833
 834         my @result = grep { m{$query} } keys %{ $c->components };
 835         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 836
 837         if( $result[ 0 ] ) {
 838             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 839             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 840             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 841             return $c->_filter_component( $result[ 0 ], @args );
 842         }
 843
 844         # I would expect to return an empty list here, but that breaks back-compat
 845     }
 846
 847     # fallback
 848     return sort keys %{ $c->components };
 849 }
 850
 851 =head2 CLASS DATA AND HELPER CLASSES
 852
 853 =head2 $c->config
 854
 855 Returns or takes a hashref containing the application's configuration.
 856
 857     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 858
 859 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 860 like C<myapp.conf> in your applications home directory. See
 861 L<Catalyst::Plugin::ConfigLoader>.
 862
 863 =head3 Cascading configuration
 864
 865 The config method is present on all Catalyst components, and configuration
 866 will be merged when an application is started. Configuration loaded with
 867 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 868 followed by configuration in your top level C<MyApp> class. These two
 869 configurations are merged, and then configuration data whose hash key matches a
 870 component name is merged with configuration for that component.
 871
 872 The configuration for a component is then passed to the C<new> method when a
 873 component is constructed.
 874
 875 For example:
 876
 877     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 878     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 879
 880 will mean that C<MyApp::Model::Foo> receives the following data when
 881 constructed:
 882
 883     MyApp::Model::Foo->new({
 884         bar => 'baz',
 885         quux => 'frob',
 886         overrides => 'me',
 887     });
 888
 889 It's common practice to use a Moose attribute
 890 on the receiving component to access the config value.
 891
 892     package MyApp::Model::Foo;
 893
 894     use Moose;
 895
 896     # this attr will receive 'baz' at construction time
 897     has 'bar' => (
 898         is  => 'rw',
 899         isa => 'Str',
 900     );
 901
 902 You can then get the value 'baz' by calling $c->model('Foo')->bar
 903 (or $self->bar inside code in the model).
 904
 905 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 906 as a way of reading config within your code, as this B<will not> give you the
 907 correctly merged config back. You B<MUST> take the config values supplied to
 908 the constructor and use those instead.
 909
 910 =cut
 911
 912 around config => sub {
 913     my $orig = shift;
 914     my $c = shift;
 915
 916     croak('Setting config after setup has been run is not allowed.')
 917         if ( @_ and $c->setup_finished );
 918
 919     $c->$orig(@_);
 920 };
 921
 922 =head2 $c->log
 923
 924 Returns the logging object instance. Unless it is already set, Catalyst
 925 sets this up with a L<Catalyst::Log> object. To use your own log class,
 926 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 927 C<< __PACKAGE__->setup >>.
 928
 929  __PACKAGE__->log( MyLogger->new );
 930  __PACKAGE__->setup;
 931
 932 And later:
 933
 934     $c->log->info( 'Now logging with my own logger!' );
 935
 936 Your log class should implement the methods described in
 937 L<Catalyst::Log>.
 938
 939
 940 =head2 $c->debug
 941
 942 Returns 1 if debug mode is enabled, 0 otherwise.
 943
 944 You can enable debug mode in several ways:
 945
 946 =over
 947
 948 =item By calling myapp_server.pl with the -d flag
 949
 950 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 951
 952 =item The -Debug option in your MyApp.pm
 953
 954 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 955
 956 =back
 957
 958 The first three also set the log level to 'debug'.
 959
 960 Calling C<< $c->debug(1) >> has no effect.
 961
 962 =cut
 963
 964 sub debug { 0 }
 965
 966 =head2 $c->dispatcher
 967
 968 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 969
 970 =head2 $c->engine
 971
 972 Returns the engine instance. See L<Catalyst::Engine>.
 973
 974
 975 =head2 UTILITY METHODS
 976
 977 =head2 $c->path_to(@path)
 978
 979 Merges C<@path> with C<< $c->config->{home} >> and returns a
 980 L<Path::Class::Dir> object. Note you can usually use this object as
 981 a filename, but sometimes you will have to explicitly stringify it
 982 yourself by calling the C<< ->stringify >> method.
 983
 984 For example:
 985
 986     $c->path_to( 'db', 'sqlite.db' );
 987
 988 =cut
 989
 990 sub path_to {
 991     my ( $c, @path ) = @_;
 992     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 993     if ( -d $path ) { return $path }
 994     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 995 }
 996
 997 =head2 $c->plugin( $name, $class, @args )
 998
 999 Helper method for plugins. It creates a class data accessor/mutator and
1000 loads and instantiates the given class.
1001
1002     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1003
1004     $c->prototype->define_javascript_functions;
1005
1006 B<Note:> This method of adding plugins is deprecated. The ability
1007 to add plugins like this B<will be removed> in a Catalyst 5.81.
1008 Please do not use this functionality in new code.
1009
1010 =cut
1011
1012 sub plugin {
1013     my ( $class, $name, $plugin, @args ) = @_;
1014
1015     # See block comment in t/unit_core_plugin.t
1016     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1017
1018     $class->_register_plugin( $plugin, 1 );
1019
1020     eval { $plugin->import };
1021     $class->mk_classdata($name);
1022     my $obj;
1023     eval { $obj = $plugin->new(@args) };
1024
1025     if ($@) {
1026         Catalyst::Exception->throw( message =>
1027               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1028     }
1029
1030     $class->$name($obj);
1031     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1032       if $class->debug;
1033 }
1034
1035 =head2 MyApp->setup
1036
1037 Initializes the dispatcher and engine, loads any plugins, and loads the
1038 model, view, and controller components. You may also specify an array
1039 of plugins to load here, if you choose to not load them in the C<use
1040 Catalyst> line.
1041
1042     MyApp->setup;
1043     MyApp->setup( qw/-Debug/ );
1044
1045 =cut
1046
1047 sub setup {
1048     my ( $class, @arguments ) = @_;
1049     croak('Running setup more than once')
1050         if ( $class->setup_finished );
1051
1052     unless ( $class->isa('Catalyst') ) {
1053
1054         Catalyst::Exception->throw(
1055             message => qq/'$class' does not inherit from Catalyst/ );
1056     }
1057
1058     if ( $class->arguments ) {
1059         @arguments = ( @arguments, @{ $class->arguments } );
1060     }
1061
1062     # Process options
1063     my $flags = {};
1064
1065     foreach (@arguments) {
1066
1067         if (/^-Debug$/) {
1068             $flags->{log} =
1069               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1070         }
1071         elsif (/^-(\w+)=?(.*)$/) {
1072             $flags->{ lc $1 } = $2;
1073         }
1074         else {
1075             push @{ $flags->{plugins} }, $_;
1076         }
1077     }
1078
1079     $class->setup_home( delete $flags->{home} );
1080
1081     $class->setup_log( delete $flags->{log} );
1082     $class->setup_plugins( delete $flags->{plugins} );
1083     $class->setup_dispatcher( delete $flags->{dispatcher} );
1084     if (my $engine = delete $flags->{engine}) {
1085         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1086     }
1087     $class->setup_engine();
1088     $class->setup_stats( delete $flags->{stats} );
1089
1090     for my $flag ( sort keys %{$flags} ) {
1091
1092         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1093             &$code( $class, delete $flags->{$flag} );
1094         }
1095         else {
1096             $class->log->warn(qq/Unknown flag "$flag"/);
1097         }
1098     }
1099
1100     eval { require Catalyst::Devel; };
1101     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1102         $class->log->warn(<<"EOF");
1103 You are running an old script!
1104
1105   Please update by running (this will overwrite existing files):
1106     catalyst.pl -force -scripts $class
1107
1108   or (this will not overwrite existing files):
1109     catalyst.pl -scripts $class
1110
1111 EOF
1112     }
1113
1114     if ( $class->debug ) {
1115         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1116
1117         if (@plugins) {
1118             my $column_width = Catalyst::Utils::term_width() - 6;
1119             my $t = Text::SimpleTable->new($column_width);
1120             $t->row($_) for @plugins;
1121             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1122         }
1123
1124         my $dispatcher = $class->dispatcher;
1125         my $engine     = $class->engine;
1126         my $home       = $class->config->{home};
1127
1128         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1129         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1130
1131         $home
1132           ? ( -d $home )
1133           ? $class->log->debug(qq/Found home "$home"/)
1134           : $class->log->debug(qq/Home "$home" doesn't exist/)
1135           : $class->log->debug(q/Couldn't find home/);
1136     }
1137
1138     # Call plugins setup, this is stupid and evil.
1139     # Also screws C3 badly on 5.10, hack to avoid.
1140     {
1141         no warnings qw/redefine/;
1142         local *setup = sub { };
1143         $class->setup unless $Catalyst::__AM_RESTARTING;
1144     }
1145
1146     # Initialize our data structure
1147     $class->components( {} );
1148
1149     $class->setup_components;
1150
1151     if ( $class->debug ) {
1152         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1153         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1154         for my $comp ( sort keys %{ $class->components } ) {
1155             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1156             $t->row( $comp, $type );
1157         }
1158         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1159           if ( keys %{ $class->components } );
1160     }
1161
1162     # Add our self to components, since we are also a component
1163     if( $class->isa('Catalyst::Controller') ){
1164       $class->components->{$class} = $class;
1165     }
1166
1167     $class->setup_actions;
1168
1169     if ( $class->debug ) {
1170         my $name = $class->config->{name} || 'Application';
1171         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1172     }
1173
1174     # Make sure that the application class becomes immutable at this point,
1175     B::Hooks::EndOfScope::on_scope_end {
1176         return if $@;
1177         my $meta = Class::MOP::get_metaclass_by_name($class);
1178         if (
1179             $meta->is_immutable
1180             && ! { $meta->immutable_options }->{replace_constructor}
1181             && (
1182                    $class->isa('Class::Accessor::Fast')
1183                 || $class->isa('Class::Accessor')
1184             )
1185         ) {
1186             warn "You made your application class ($class) immutable, "
1187                 . "but did not inline the\nconstructor. "
1188                 . "This will break catalyst, as your app \@ISA "
1189                 . "Class::Accessor(::Fast)?\nPlease pass "
1190                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1191         }
1192         $meta->make_immutable(
1193             replace_constructor => 1,
1194         ) unless $meta->is_immutable;
1195     };
1196
1197     if ($class->config->{case_sensitive}) {
1198         $class->log->warn($class . "->config->{case_sensitive} is set.");
1199         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1200     }
1201
1202     $class->setup_finalize;
1203     # Should be the last thing we do so that user things hooking
1204     # setup_finalize can log..
1205     $class->log->_flush() if $class->log->can('_flush');
1206     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1207 }
1208
1209 =head2 $app->setup_finalize
1210
1211 A hook to attach modifiers to. This method does not do anything except set the
1212 C<setup_finished> accessor.
1213
1214 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1215
1216 Example:
1217
1218     after setup_finalize => sub {
1219         my $app = shift;
1220
1221         ## do stuff here..
1222     };
1223
1224 =cut
1225
1226 sub setup_finalize {
1227     my ($class) = @_;
1228     $class->setup_finished(1);
1229 }
1230
1231 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1232
1233 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1234
1235 Constructs an absolute L<URI> object based on the application root, the
1236 provided path, and the additional arguments and query parameters provided.
1237 When used as a string, provides a textual URI.  If you need more flexibility
1238 than this (i.e. the option to provide relative URIs etc.) see
1239 L<Catalyst::Plugin::SmartURI>.
1240
1241 If no arguments are provided, the URI for the current action is returned.
1242 To return the current action and also provide @args, use
1243 C<< $c->uri_for( $c->action, @args ) >>.
1244
1245 If the first argument is a string, it is taken as a public URI path relative
1246 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1247 relative to the application root (if it does). It is then merged with
1248 C<< $c->request->base >>; any C<@args> are appended as additional path
1249 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1250
1251 If the first argument is a L<Catalyst::Action> it represents an action which
1252 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1253 optional C<\@captures> argument (an arrayref) allows passing the captured
1254 variables that are needed to fill in the paths of Chained and Regex actions;
1255 once the path is resolved, C<uri_for> continues as though a path was
1256 provided, appending any arguments or parameters and creating an absolute
1257 URI.
1258
1259 The captures for the current request can be found in
1260 C<< $c->request->captures >>, and actions can be resolved using
1261 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1262 path, use C<< $c->uri_for_action >> instead.
1263
1264   # Equivalent to $c->req->uri
1265   $c->uri_for($c->action, $c->req->captures,
1266       @{ $c->req->args }, $c->req->params);
1267
1268   # For the Foo action in the Bar controller
1269   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1270
1271   # Path to a static resource
1272   $c->uri_for('/static/images/logo.png');
1273
1274 =cut
1275
1276 sub uri_for {
1277     my ( $c, $path, @args ) = @_;
1278
1279     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1280         $path = $path->path_prefix;
1281         $path =~ s{/+\z}{};
1282         $path .= '/';
1283     }
1284
1285     undef($path) if (defined $path && $path eq '');
1286
1287     my $params =
1288       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1289
1290     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1291     foreach my $arg (@args) {
1292         utf8::encode($arg) if utf8::is_utf8($arg);
1293         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1294     }
1295
1296     if ( blessed($path) ) { # action object
1297         s|/|%2F|g for @args;
1298         my $captures = [ map { s|/|%2F|g; $_; }
1299                         ( scalar @args && ref $args[0] eq 'ARRAY'
1300                          ? @{ shift(@args) }
1301                          : ()) ];
1302
1303         foreach my $capture (@$captures) {
1304             utf8::encode($capture) if utf8::is_utf8($capture);
1305             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1306         }
1307
1308         my $action = $path;
1309         $path = $c->dispatcher->uri_for_action($action, $captures);
1310         if (not defined $path) {
1311             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1312                 if $c->debug;
1313             return undef;
1314         }
1315         $path = '/' if $path eq '';
1316     }
1317
1318     unshift(@args, $path);
1319
1320     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1321         my $namespace = $c->namespace;
1322         if (defined $path) { # cheesy hack to handle path '../foo'
1323            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1324         }
1325         unshift(@args, $namespace || '');
1326     }
1327
1328     # join args with '/', or a blank string
1329     my $args = join('/', grep { defined($_) } @args);
1330     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1331     $args =~ s!^/+!!;
1332     my $base = $c->req->base;
1333     my $class = ref($base);
1334     $base =~ s{(?<!/)$}{/};
1335
1336     my $query = '';
1337
1338     if (my @keys = keys %$params) {
1339       # somewhat lifted from URI::_query's query_form
1340       $query = '?'.join('&', map {
1341           my $val = $params->{$_};
1342           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1343           s/ /+/g;
1344           my $key = $_;
1345           $val = '' unless defined $val;
1346           (map {
1347               my $param = "$_";
1348               utf8::encode( $param ) if utf8::is_utf8($param);
1349               # using the URI::Escape pattern here so utf8 chars survive
1350               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1351               $param =~ s/ /+/g;
1352               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1353       } @keys);
1354     }
1355
1356     my $res = bless(\"${base}${args}${query}", $class);
1357     $res;
1358 }
1359
1360 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1361
1362 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1363
1364 =over
1365
1366 =item $path
1367
1368 A private path to the Catalyst action you want to create a URI for.
1369
1370 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1371 >> and passing the resulting C<$action> and the remaining arguments to C<<
1372 $c->uri_for >>.
1373
1374 You can also pass in a Catalyst::Action object, in which case it is passed to
1375 C<< $c->uri_for >>.
1376
1377 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1378
1379 For example, if the action looks like:
1380
1381  package MyApp::Controller::Users;
1382
1383  sub lst : Path('the-list') {}
1384
1385 You can use:
1386
1387  $c->uri_for_action('/users/lst')
1388
1389 and it will create the URI /users/the-list.
1390
1391 =back
1392
1393 =cut
1394
1395 sub uri_for_action {
1396     my ( $c, $path, @args ) = @_;
1397     my $action = blessed($path)
1398       ? $path
1399       : $c->dispatcher->get_action_by_path($path);
1400     unless (defined $action) {
1401       croak "Can't find action for path '$path'";
1402     }
1403     return $c->uri_for( $action, @args );
1404 }
1405
1406 =head2 $c->welcome_message
1407
1408 Returns the Catalyst welcome HTML page.
1409
1410 =cut
1411
1412 sub welcome_message {
1413     my $c      = shift;
1414     my $name   = $c->config->{name};
1415     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1416     my $prefix = Catalyst::Utils::appprefix( ref $c );
1417     $c->response->content_type('text/html; charset=utf-8');
1418     return <<"EOF";
1419 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1420     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1421 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1422     <head>
1423     <meta http-equiv="Content-Language" content="en" />
1424     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1425         <title>$name on Catalyst $VERSION</title>
1426         <style type="text/css">
1427             body {
1428                 color: #000;
1429                 background-color: #eee;
1430             }
1431             div#content {
1432                 width: 640px;
1433                 margin-left: auto;
1434                 margin-right: auto;
1435                 margin-top: 10px;
1436                 margin-bottom: 10px;
1437                 text-align: left;
1438                 background-color: #ccc;
1439                 border: 1px solid #aaa;
1440             }
1441             p, h1, h2 {
1442                 margin-left: 20px;
1443                 margin-right: 20px;
1444                 font-family: verdana, tahoma, sans-serif;
1445             }
1446             a {
1447                 font-family: verdana, tahoma, sans-serif;
1448             }
1449             :link, :visited {
1450                     text-decoration: none;
1451                     color: #b00;
1452                     border-bottom: 1px dotted #bbb;
1453             }
1454             :link:hover, :visited:hover {
1455                     color: #555;
1456             }
1457             div#topbar {
1458                 margin: 0px;
1459             }
1460             pre {
1461                 margin: 10px;
1462                 padding: 8px;
1463             }
1464             div#answers {
1465                 padding: 8px;
1466                 margin: 10px;
1467                 background-color: #fff;
1468                 border: 1px solid #aaa;
1469             }
1470             h1 {
1471                 font-size: 0.9em;
1472                 font-weight: normal;
1473                 text-align: center;
1474             }
1475             h2 {
1476                 font-size: 1.0em;
1477             }
1478             p {
1479                 font-size: 0.9em;
1480             }
1481             p img {
1482                 float: right;
1483                 margin-left: 10px;
1484             }
1485             span#appname {
1486                 font-weight: bold;
1487                 font-size: 1.6em;
1488             }
1489         </style>
1490     </head>
1491     <body>
1492         <div id="content">
1493             <div id="topbar">
1494                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1495                     $VERSION</h1>
1496              </div>
1497              <div id="answers">
1498                  <p>
1499                  <img src="$logo" alt="Catalyst Logo" />
1500                  </p>
1501                  <p>Welcome to the  world of Catalyst.
1502                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1503                     framework will make web development something you had
1504                     never expected it to be: Fun, rewarding, and quick.</p>
1505                  <h2>What to do now?</h2>
1506                  <p>That really depends  on what <b>you</b> want to do.
1507                     We do, however, provide you with a few starting points.</p>
1508                  <p>If you want to jump right into web development with Catalyst
1509                     you might want to start with a tutorial.</p>
1510 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1511 </pre>
1512 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1513 <pre>
1514 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1515 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1516 </code></pre>
1517                  <h2>What to do next?</h2>
1518                  <p>Next it's time to write an actual application. Use the
1519                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1520                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1521                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1522                     they can save you a lot of work.</p>
1523                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1524                     <p>Also, be sure to check out the vast and growing
1525                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1526                     you are likely to find what you need there.
1527                     </p>
1528
1529                  <h2>Need help?</h2>
1530                  <p>Catalyst has a very active community. Here are the main places to
1531                     get in touch with us.</p>
1532                  <ul>
1533                      <li>
1534                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1535                      </li>
1536                      <li>
1537                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1538                      </li>
1539                      <li>
1540                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1541                      </li>
1542                  </ul>
1543                  <h2>In conclusion</h2>
1544                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1545                     as we enjoyed making it. Please contact us if you have ideas
1546                     for improvement or other feedback.</p>
1547              </div>
1548          </div>
1549     </body>
1550 </html>
1551 EOF
1552 }
1553
1554 =head1 INTERNAL METHODS
1555
1556 These methods are not meant to be used by end users.
1557
1558 =head2 $c->components
1559
1560 Returns a hash of components.
1561
1562 =head2 $c->context_class
1563
1564 Returns or sets the context class.
1565
1566 =head2 $c->counter
1567
1568 Returns a hashref containing coderefs and execution counts (needed for
1569 deep recursion detection).
1570
1571 =head2 $c->depth
1572
1573 Returns the number of actions on the current internal execution stack.
1574
1575 =head2 $c->dispatch
1576
1577 Dispatches a request to actions.
1578
1579 =cut
1580
1581 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1582
1583 =head2 $c->dispatcher_class
1584
1585 Returns or sets the dispatcher class.
1586
1587 =head2 $c->dump_these
1588
1589 Returns a list of 2-element array references (name, structure) pairs
1590 that will be dumped on the error page in debug mode.
1591
1592 =cut
1593
1594 sub dump_these {
1595     my $c = shift;
1596     [ Request => $c->req ],
1597     [ Response => $c->res ],
1598     [ Stash => $c->stash ],
1599     [ Config => $c->config ];
1600 }
1601
1602 =head2 $c->engine_class
1603
1604 Returns or sets the engine class.
1605
1606 =head2 $c->execute( $class, $coderef )
1607
1608 Execute a coderef in given class and catch exceptions. Errors are available
1609 via $c->error.
1610
1611 =cut
1612
1613 sub execute {
1614     my ( $c, $class, $code ) = @_;
1615     $class = $c->component($class) || $class;
1616     $c->state(0);
1617
1618     if ( $c->depth >= $RECURSION ) {
1619         my $action = $code->reverse();
1620         $action = "/$action" unless $action =~ /->/;
1621         my $error = qq/Deep recursion detected calling "${action}"/;
1622         $c->log->error($error);
1623         $c->error($error);
1624         $c->state(0);
1625         return $c->state;
1626     }
1627
1628     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1629
1630     push( @{ $c->stack }, $code );
1631
1632     no warnings 'recursion';
1633     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1634     #      I have no idea how, ergo $ret (which appears to fix the issue)
1635     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1636
1637     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1638
1639     my $last = pop( @{ $c->stack } );
1640
1641     if ( my $error = $@ ) {
1642         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1643             $error->rethrow if $c->depth > 1;
1644         }
1645         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1646             $error->rethrow if $c->depth > 0;
1647         }
1648         else {
1649             unless ( ref $error ) {
1650                 no warnings 'uninitialized';
1651                 chomp $error;
1652                 my $class = $last->class;
1653                 my $name  = $last->name;
1654                 $error = qq/Caught exception in $class->$name "$error"/;
1655             }
1656             $c->error($error);
1657         }
1658         $c->state(0);
1659     }
1660     return $c->state;
1661 }
1662
1663 sub _stats_start_execute {
1664     my ( $c, $code ) = @_;
1665     my $appclass = ref($c) || $c;
1666     return if ( ( $code->name =~ /^_.*/ )
1667         && ( !$appclass->config->{show_internal_actions} ) );
1668
1669     my $action_name = $code->reverse();
1670     $c->counter->{$action_name}++;
1671
1672     my $action = $action_name;
1673     $action = "/$action" unless $action =~ /->/;
1674
1675     # determine if the call was the result of a forward
1676     # this is done by walking up the call stack and looking for a calling
1677     # sub of Catalyst::forward before the eval
1678     my $callsub = q{};
1679     for my $index ( 2 .. 11 ) {
1680         last
1681         if ( ( caller($index) )[0] eq 'Catalyst'
1682             && ( caller($index) )[3] eq '(eval)' );
1683
1684         if ( ( caller($index) )[3] =~ /forward$/ ) {
1685             $callsub = ( caller($index) )[3];
1686             $action  = "-> $action";
1687             last;
1688         }
1689     }
1690
1691     my $uid = $action_name . $c->counter->{$action_name};
1692
1693     # is this a root-level call or a forwarded call?
1694     if ( $callsub =~ /forward$/ ) {
1695         my $parent = $c->stack->[-1];
1696
1697         # forward, locate the caller
1698         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1699             $c->stats->profile(
1700                 begin  => $action,
1701                 parent => "$parent" . $c->counter->{"$parent"},
1702                 uid    => $uid,
1703             );
1704         }
1705         else {
1706
1707             # forward with no caller may come from a plugin
1708             $c->stats->profile(
1709                 begin => $action,
1710                 uid   => $uid,
1711             );
1712         }
1713     }
1714     else {
1715
1716         # root-level call
1717         $c->stats->profile(
1718             begin => $action,
1719             uid   => $uid,
1720         );
1721     }
1722     return $action;
1723
1724 }
1725
1726 sub _stats_finish_execute {
1727     my ( $c, $info ) = @_;
1728     $c->stats->profile( end => $info );
1729 }
1730
1731 =head2 $c->finalize
1732
1733 Finalizes the request.
1734
1735 =cut
1736
1737 sub finalize {
1738     my $c = shift;
1739
1740     for my $error ( @{ $c->error } ) {
1741         $c->log->error($error);
1742     }
1743
1744     # Allow engine to handle finalize flow (for POE)
1745     my $engine = $c->engine;
1746     if ( my $code = $engine->can('finalize') ) {
1747         $engine->$code($c);
1748     }
1749     else {
1750
1751         $c->finalize_uploads;
1752
1753         # Error
1754         if ( $#{ $c->error } >= 0 ) {
1755             $c->finalize_error;
1756         }
1757
1758         $c->finalize_headers;
1759
1760         # HEAD request
1761         if ( $c->request->method eq 'HEAD' ) {
1762             $c->response->body('');
1763         }
1764
1765         $c->finalize_body;
1766     }
1767
1768     $c->log_response;
1769
1770     if ($c->use_stats) {
1771         my $elapsed = sprintf '%f', $c->stats->elapsed;
1772         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1773         $c->log->info(
1774             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1775     }
1776
1777     return $c->response->status;
1778 }
1779
1780 =head2 $c->finalize_body
1781
1782 Finalizes body.
1783
1784 =cut
1785
1786 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1787
1788 =head2 $c->finalize_cookies
1789
1790 Finalizes cookies.
1791
1792 =cut
1793
1794 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1795
1796 =head2 $c->finalize_error
1797
1798 Finalizes error.
1799
1800 =cut
1801
1802 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1803
1804 =head2 $c->finalize_headers
1805
1806 Finalizes headers.
1807
1808 =cut
1809
1810 sub finalize_headers {
1811     my $c = shift;
1812
1813     my $response = $c->response; #accessor calls can add up?
1814
1815     # Check if we already finalized headers
1816     return if $response->finalized_headers;
1817
1818     # Handle redirects
1819     if ( my $location = $response->redirect ) {
1820         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1821         $response->header( Location => $location );
1822
1823         if ( !$response->has_body ) {
1824             # Add a default body if none is already present
1825             $response->body(<<"EOF");
1826 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1827 <html xmlns="http://www.w3.org/1999/xhtml">
1828   <head>
1829     <title>Moved</title>
1830   </head>
1831   <body>
1832      <p>This item has moved <a href="$location">here</a>.</p>
1833   </body>
1834 </html>
1835 EOF
1836             $response->content_type('text/html; charset=utf-8');
1837         }
1838     }
1839
1840     # Content-Length
1841     if ( defined $response->body && length $response->body && !$response->content_length ) {
1842
1843         # get the length from a filehandle
1844         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1845         {
1846             my $size = -s $response->body;
1847             if ( $size ) {
1848                 $response->content_length( $size );
1849             }
1850             else {
1851                 $c->log->warn('Serving filehandle without a content-length');
1852             }
1853         }
1854         else {
1855             # everything should be bytes at this point, but just in case
1856             $response->content_length( length( $response->body ) );
1857         }
1858     }
1859
1860     # Errors
1861     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1862         $response->headers->remove_header("Content-Length");
1863         $response->body('');
1864     }
1865
1866     $c->finalize_cookies;
1867
1868     $c->engine->finalize_headers( $c, @_ );
1869
1870     # Done
1871     $response->finalized_headers(1);
1872 }
1873
1874 =head2 $c->finalize_output
1875
1876 An alias for finalize_body.
1877
1878 =head2 $c->finalize_read
1879
1880 Finalizes the input after reading is complete.
1881
1882 =cut
1883
1884 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1885
1886 =head2 $c->finalize_uploads
1887
1888 Finalizes uploads. Cleans up any temporary files.
1889
1890 =cut
1891
1892 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1893
1894 =head2 $c->get_action( $action, $namespace )
1895
1896 Gets an action in a given namespace.
1897
1898 =cut
1899
1900 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1901
1902 =head2 $c->get_actions( $action, $namespace )
1903
1904 Gets all actions of a given name in a namespace and all parent
1905 namespaces.
1906
1907 =cut
1908
1909 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1910
1911 =head2 $app->handle_request( @arguments )
1912
1913 Called to handle each HTTP request.
1914
1915 =cut
1916
1917 sub handle_request {
1918     my ( $class, @arguments ) = @_;
1919
1920     # Always expect worst case!
1921     my $status = -1;
1922     try {
1923         if ($class->debug) {
1924             my $secs = time - $START || 1;
1925             my $av = sprintf '%.3f', $COUNT / $secs;
1926             my $time = localtime time;
1927             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1928         }
1929
1930         my $c = $class->prepare(@arguments);
1931         $c->dispatch;
1932         $status = $c->finalize;
1933     }
1934     catch {
1935         chomp(my $error = $_);
1936         $class->log->error(qq/Caught exception in engine "$error"/);
1937     };
1938
1939     $COUNT++;
1940
1941     if(my $coderef = $class->log->can('_flush')){
1942         $class->log->$coderef();
1943     }
1944     return $status;
1945 }
1946
1947 =head2 $class->prepare( @arguments )
1948
1949 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1950 etc.).
1951
1952 =cut
1953
1954 sub prepare {
1955     my ( $class, @arguments ) = @_;
1956
1957     # XXX
1958     # After the app/ctxt split, this should become an attribute based on something passed
1959     # into the application.
1960     $class->context_class( ref $class || $class ) unless $class->context_class;
1961
1962     my $c = $class->context_class->new({});
1963
1964     # For on-demand data
1965     $c->request->_context($c);
1966     $c->response->_context($c);
1967
1968     #surely this is not the most efficient way to do things...
1969     $c->stats($class->stats_class->new)->enable($c->use_stats);
1970     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1971         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1972     }
1973
1974     try {
1975         # Allow engine to direct the prepare flow (for POE)
1976         if ( my $prepare = $c->engine->can('prepare') ) {
1977             $c->engine->$prepare( $c, @arguments );
1978         }
1979         else {
1980             $c->prepare_request(@arguments);
1981             $c->prepare_connection;
1982             $c->prepare_query_parameters;
1983             $c->prepare_headers;
1984             $c->prepare_cookies;
1985             $c->prepare_path;
1986
1987             # Prepare the body for reading, either by prepare_body
1988             # or the user, if they are using $c->read
1989             $c->prepare_read;
1990
1991             # Parse the body unless the user wants it on-demand
1992             unless ( ref($c)->config->{parse_on_demand} ) {
1993                 $c->prepare_body;
1994             }
1995         }
1996     }
1997     # VERY ugly and probably shouldn't rely on ->finalize actually working
1998     catch {
1999         # failed prepare is always due to an invalid request, right?
2000         $c->response->status(400);
2001         $c->response->content_type('text/plain');
2002         $c->response->body('Bad Request');
2003         $c->finalize;
2004         die $_;
2005     };
2006
2007     my $method  = $c->req->method  || '';
2008     my $path    = $c->req->path;
2009     $path       = '/' unless length $path;
2010     my $address = $c->req->address || '';
2011
2012     $c->log_request;
2013
2014     $c->prepare_action;
2015
2016     return $c;
2017 }
2018
2019 =head2 $c->prepare_action
2020
2021 Prepares action. See L<Catalyst::Dispatcher>.
2022
2023 =cut
2024
2025 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2026
2027 =head2 $c->prepare_body
2028
2029 Prepares message body.
2030
2031 =cut
2032
2033 sub prepare_body {
2034     my $c = shift;
2035
2036     return if $c->request->_has_body;
2037
2038     # Initialize on-demand data
2039     $c->engine->prepare_body( $c, @_ );
2040     $c->prepare_parameters;
2041     $c->prepare_uploads;
2042 }
2043
2044 =head2 $c->prepare_body_chunk( $chunk )
2045
2046 Prepares a chunk of data before sending it to L<HTTP::Body>.
2047
2048 See L<Catalyst::Engine>.
2049
2050 =cut
2051
2052 sub prepare_body_chunk {
2053     my $c = shift;
2054     $c->engine->prepare_body_chunk( $c, @_ );
2055 }
2056
2057 =head2 $c->prepare_body_parameters
2058
2059 Prepares body parameters.
2060
2061 =cut
2062
2063 sub prepare_body_parameters {
2064     my $c = shift;
2065     $c->engine->prepare_body_parameters( $c, @_ );
2066 }
2067
2068 =head2 $c->prepare_connection
2069
2070 Prepares connection.
2071
2072 =cut
2073
2074 sub prepare_connection {
2075     my $c = shift;
2076     $c->engine->prepare_connection( $c, @_ );
2077 }
2078
2079 =head2 $c->prepare_cookies
2080
2081 Prepares cookies.
2082
2083 =cut
2084
2085 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2086
2087 =head2 $c->prepare_headers
2088
2089 Prepares headers.
2090
2091 =cut
2092
2093 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2094
2095 =head2 $c->prepare_parameters
2096
2097 Prepares parameters.
2098
2099 =cut
2100
2101 sub prepare_parameters {
2102     my $c = shift;
2103     $c->prepare_body_parameters;
2104     $c->engine->prepare_parameters( $c, @_ );
2105 }
2106
2107 =head2 $c->prepare_path
2108
2109 Prepares path and base.
2110
2111 =cut
2112
2113 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2114
2115 =head2 $c->prepare_query_parameters
2116
2117 Prepares query parameters.
2118
2119 =cut
2120
2121 sub prepare_query_parameters {
2122     my $c = shift;
2123
2124     $c->engine->prepare_query_parameters( $c, @_ );
2125 }
2126
2127 =head2 $c->log_request
2128
2129 Writes information about the request to the debug logs.  This includes:
2130
2131 =over 4
2132
2133 =item * Request method, path, and remote IP address
2134
2135 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2136
2137 =item * Request parameters
2138
2139 =item * File uploads
2140
2141 =back
2142
2143 =cut
2144
2145 sub log_request {
2146     my $c = shift;
2147
2148     return unless $c->debug;
2149
2150     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2151     my $request = $dump->[1];
2152
2153     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2154     $method ||= '';
2155     $path = '/' unless length $path;
2156     $address ||= '';
2157     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2158
2159     $c->log_request_headers($request->headers);
2160
2161     if ( my $keywords = $request->query_keywords ) {
2162         $c->log->debug("Query keywords are: $keywords");
2163     }
2164
2165     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2166
2167     $c->log_request_uploads($request);
2168 }
2169
2170 =head2 $c->log_response
2171
2172 Writes information about the response to the debug logs by calling
2173 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2174
2175 =cut
2176
2177 sub log_response {
2178     my $c = shift;
2179
2180     return unless $c->debug;
2181
2182     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2183     my $response = $dump->[1];
2184
2185     $c->log_response_status_line($response);
2186     $c->log_response_headers($response->headers);
2187 }
2188
2189 =head2 $c->log_response_status_line($response)
2190
2191 Writes one line of information about the response to the debug logs.  This includes:
2192
2193 =over 4
2194
2195 =item * Response status code
2196
2197 =item * Content-Type header (if present)
2198
2199 =item * Content-Length header (if present)
2200
2201 =back
2202
2203 =cut
2204
2205 sub log_response_status_line {
2206     my ($c, $response) = @_;
2207
2208     $c->log->debug(
2209         sprintf(
2210             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2211             $response->status                            || 'unknown',
2212             $response->headers->header('Content-Type')   || 'unknown',
2213             $response->headers->header('Content-Length') || 'unknown'
2214         )
2215     );
2216 }
2217
2218 =head2 $c->log_response_headers($headers);
2219
2220 Hook method which can be wrapped by plugins to log the responseheaders.
2221 No-op in the default implementation.
2222
2223 =cut
2224
2225 sub log_response_headers {}
2226
2227 =head2 $c->log_request_parameters( query => {}, body => {} )
2228
2229 Logs request parameters to debug logs
2230
2231 =cut
2232
2233 sub log_request_parameters {
2234     my $c          = shift;
2235     my %all_params = @_;
2236
2237     return unless $c->debug;
2238
2239     my $column_width = Catalyst::Utils::term_width() - 44;
2240     foreach my $type (qw(query body)) {
2241         my $params = $all_params{$type};
2242         next if ! keys %$params;
2243         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2244         for my $key ( sort keys %$params ) {
2245             my $param = $params->{$key};
2246             my $value = defined($param) ? $param : '';
2247             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2248         }
2249         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2250     }
2251 }
2252
2253 =head2 $c->log_request_uploads
2254
2255 Logs file uploads included in the request to the debug logs.
2256 The parameter name, filename, file type, and file size are all included in
2257 the debug logs.
2258
2259 =cut
2260
2261 sub log_request_uploads {
2262     my $c = shift;
2263     my $request = shift;
2264     return unless $c->debug;
2265     my $uploads = $request->uploads;
2266     if ( keys %$uploads ) {
2267         my $t = Text::SimpleTable->new(
2268             [ 12, 'Parameter' ],
2269             [ 26, 'Filename' ],
2270             [ 18, 'Type' ],
2271             [ 9,  'Size' ]
2272         );
2273         for my $key ( sort keys %$uploads ) {
2274             my $upload = $uploads->{$key};
2275             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2276                 $t->row( $key, $u->filename, $u->type, $u->size );
2277             }
2278         }
2279         $c->log->debug( "File Uploads are:\n" . $t->draw );
2280     }
2281 }
2282
2283 =head2 $c->log_request_headers($headers);
2284
2285 Hook method which can be wrapped by plugins to log the request headers.
2286 No-op in the default implementation.
2287
2288 =cut
2289
2290 sub log_request_headers {}
2291
2292 =head2 $c->log_headers($type => $headers)
2293
2294 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2295
2296 =cut
2297
2298 sub log_headers {
2299     my $c       = shift;
2300     my $type    = shift;
2301     my $headers = shift;    # an HTTP::Headers instance
2302
2303     return unless $c->debug;
2304
2305     my $column_width = Catalyst::Utils::term_width() - 28;
2306     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2307     $headers->scan(
2308         sub {
2309             my ( $name, $value ) = @_;
2310             $t->row( $name, $value );
2311         }
2312     );
2313     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2314 }
2315
2316
2317 =head2 $c->prepare_read
2318
2319 Prepares the input for reading.
2320
2321 =cut
2322
2323 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2324
2325 =head2 $c->prepare_request
2326
2327 Prepares the engine request.
2328
2329 =cut
2330
2331 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2332
2333 =head2 $c->prepare_uploads
2334
2335 Prepares uploads.
2336
2337 =cut
2338
2339 sub prepare_uploads {
2340     my $c = shift;
2341
2342     $c->engine->prepare_uploads( $c, @_ );
2343 }
2344
2345 =head2 $c->prepare_write
2346
2347 Prepares the output for writing.
2348
2349 =cut
2350
2351 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2352
2353 =head2 $c->request_class
2354
2355 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2356
2357 =head2 $c->response_class
2358
2359 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2360
2361 =head2 $c->read( [$maxlength] )
2362
2363 Reads a chunk of data from the request body. This method is designed to
2364 be used in a while loop, reading C<$maxlength> bytes on every call.
2365 C<$maxlength> defaults to the size of the request if not specified.
2366
2367 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2368 directly.
2369
2370 Warning: If you use read(), Catalyst will not process the body,
2371 so you will not be able to access POST parameters or file uploads via
2372 $c->request.  You must handle all body parsing yourself.
2373
2374 =cut
2375
2376 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2377
2378 =head2 $c->run
2379
2380 Starts the engine.
2381
2382 =cut
2383
2384 sub run {
2385   my $app = shift;
2386   $app->engine_loader->needs_psgi_engine_compat_hack ?
2387     $app->engine->run($app, @_) :
2388       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2389 }
2390
2391 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2392
2393 Sets an action in a given namespace.
2394
2395 =cut
2396
2397 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2398
2399 =head2 $c->setup_actions($component)
2400
2401 Sets up actions for a component.
2402
2403 =cut
2404
2405 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2406
2407 =head2 $c->setup_components
2408
2409 This method is called internally to set up the application's components.
2410
2411 It finds modules by calling the L<locate_components> method, expands them to
2412 package names with the L<expand_component_module> method, and then installs
2413 each component into the application.
2414
2415 The C<setup_components> config option is passed to both of the above methods.
2416
2417 Installation of each component is performed by the L<setup_component> method,
2418 below.
2419
2420 =cut
2421
2422 sub setup_components {
2423     my $class = shift;
2424
2425     my $config  = $class->config->{ setup_components };
2426
2427     my @comps = $class->locate_components($config);
2428     my %comps = map { $_ => 1 } @comps;
2429
2430     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2431     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2432         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2433     ) if $deprecatedcatalyst_component_names;
2434
2435     for my $component ( @comps ) {
2436
2437         # We pass ignore_loaded here so that overlay files for (e.g.)
2438         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2439         # we know M::P::O found a file on disk so this is safe
2440
2441         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2442     }
2443
2444     for my $component (@comps) {
2445         my $instance = $class->components->{ $component } = $class->setup_component($component);
2446         my @expanded_components = $instance->can('expand_modules')
2447             ? $instance->expand_modules( $component, $config )
2448             : $class->expand_component_module( $component, $config );
2449         for my $component (@expanded_components) {
2450             next if $comps{$component};
2451             $class->components->{ $component } = $class->setup_component($component);
2452         }
2453     }
2454 }
2455
2456 =head2 $c->locate_components( $setup_component_config )
2457
2458 This method is meant to provide a list of component modules that should be
2459 setup for the application.  By default, it will use L<Module::Pluggable>.
2460
2461 Specify a C<setup_components> config option to pass additional options directly
2462 to L<Module::Pluggable>. To add additional search paths, specify a key named
2463 C<search_extra> as an array reference. Items in the array beginning with C<::>
2464 will have the application class name prepended to them.
2465
2466 =cut
2467
2468 sub locate_components {
2469     my $class  = shift;
2470     my $config = shift;
2471
2472     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2473     my $extra   = delete $config->{ search_extra } || [];
2474
2475     push @paths, @$extra;
2476
2477     my $locator = Module::Pluggable::Object->new(
2478         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2479         %$config
2480     );
2481
2482     # XXX think about ditching this sort entirely
2483     my @comps = sort { length $a <=> length $b } $locator->plugins;
2484
2485     return @comps;
2486 }
2487
2488 =head2 $c->expand_component_module( $component, $setup_component_config )
2489
2490 Components found by C<locate_components> will be passed to this method, which
2491 is expected to return a list of component (package) names to be set up.
2492
2493 =cut
2494
2495 sub expand_component_module {
2496     my ($class, $module) = @_;
2497     return Devel::InnerPackage::list_packages( $module );
2498 }
2499
2500 =head2 $c->setup_component
2501
2502 =cut
2503
2504 sub setup_component {
2505     my( $class, $component ) = @_;
2506
2507     unless ( $component->can( 'COMPONENT' ) ) {
2508         return $component;
2509     }
2510
2511     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2512     my $config = $class->config->{ $suffix } || {};
2513     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2514     # methods also pass it. local to avoid pointlessly shitting in config
2515     # for the debug screen, as $component is already the key name.
2516     local $config->{catalyst_component_name} = $component;
2517
2518     my $instance = eval { $component->COMPONENT( $class, $config ); };
2519
2520     if ( my $error = $@ ) {
2521         chomp $error;
2522         Catalyst::Exception->throw(
2523             message => qq/Couldn't instantiate component "$component", "$error"/
2524         );
2525     }
2526
2527     unless (blessed $instance) {
2528         my $metaclass = Moose::Util::find_meta($component);
2529         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2530         my $component_method_from = $method_meta->associated_metaclass->name;
2531         my $value = defined($instance) ? $instance : 'undef';
2532         Catalyst::Exception->throw(
2533             message =>
2534             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2535         );
2536     }
2537     return $instance;
2538 }
2539
2540 =head2 $c->setup_dispatcher
2541
2542 Sets up dispatcher.
2543
2544 =cut
2545
2546 sub setup_dispatcher {
2547     my ( $class, $dispatcher ) = @_;
2548
2549     if ($dispatcher) {
2550         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2551     }
2552
2553     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2554         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2555     }
2556
2557     unless ($dispatcher) {
2558         $dispatcher = $class->dispatcher_class;
2559     }
2560
2561     Class::MOP::load_class($dispatcher);
2562
2563     # dispatcher instance
2564     $class->dispatcher( $dispatcher->new );
2565 }
2566
2567 =head2 $c->setup_engine
2568
2569 Sets up engine.
2570
2571 =cut
2572
2573 sub engine_class {
2574     my ($class, $requested_engine) = @_;
2575
2576     if (!$class->engine_loader || $requested_engine) {
2577         $class->engine_loader(
2578             Catalyst::EngineLoader->new({
2579                 application_name => $class,
2580                 (defined $requested_engine
2581                      ? (catalyst_engine_class => $requested_engine) : ()),
2582             }),
2583         );
2584     }
2585
2586     $class->engine_loader->catalyst_engine_class;
2587 }
2588
2589 sub setup_engine {
2590     my ($class, $requested_engine) = @_;
2591
2592     my $engine = do {
2593         my $loader = $class->engine_loader;
2594
2595         if (!$loader || $requested_engine) {
2596             $loader = Catalyst::EngineLoader->new({
2597                 application_name => $class,
2598                 (defined $requested_engine
2599                      ? (requested_engine => $requested_engine) : ()),
2600             }),
2601
2602             $class->engine_loader($loader);
2603         }
2604
2605         $loader->catalyst_engine_class;
2606     };
2607
2608     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2609     return if $class->loading_psgi_file;
2610
2611     Class::MOP::load_class($engine);
2612
2613     if ($ENV{MOD_PERL}) {
2614         my $apache = $class->engine_loader->auto;
2615
2616         my $meta = find_meta($class);
2617         my $was_immutable = $meta->is_immutable;
2618         my %immutable_options = $meta->immutable_options;
2619         $meta->make_mutable if $was_immutable;
2620
2621         $meta->add_method(handler => sub {
2622             my $r = shift;
2623             my $psgi_app = $class->psgi_app;
2624             $apache->call_app($r, $psgi_app);
2625         });
2626
2627         $meta->make_immutable(%immutable_options) if $was_immutable;
2628     }
2629
2630     $class->engine( $engine->new );
2631
2632     return;
2633 }
2634
2635 sub _finalized_psgi_app {
2636     my ($app) = @_;
2637
2638     unless ($app->_psgi_app) {
2639         my $psgi_app = $app->_setup_psgi_app;
2640         $app->_psgi_app($psgi_app);
2641     }
2642
2643     return $app->_psgi_app;
2644 }
2645
2646 sub _setup_psgi_app {
2647     my ($app) = @_;
2648
2649     for my $home (Path::Class::Dir->new($app->config->{home})) {
2650         my $psgi_file = $home->file(
2651             Catalyst::Utils::appprefix($app) . '.psgi',
2652         );
2653
2654         next unless -e $psgi_file;
2655
2656         # If $psgi_file calls ->setup_engine, it's doing so to load
2657         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2658         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2659         # anyway. So set a flag (ick) that tells setup_engine not to populate
2660         # $c->engine or do any other things we might regret.
2661
2662         $app->loading_psgi_file(1);
2663         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2664         $app->loading_psgi_file(0);
2665
2666         return $psgi_app
2667             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2668
2669         warn <<"EOW";
2670 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2671
2672 Its content has been ignored. Please consult the Catalyst::Upgrading
2673 documentation on how to upgrade from Catalyst::Engine::PSGI.
2674 EOW
2675     }
2676
2677     return $app->apply_default_middlewares($app->psgi_app);
2678 }
2679
2680 =head2 $c->apply_default_middlewares
2681
2682 Adds the following L<Plack> middlewares to your application, since they are
2683 useful and commonly needed:
2684
2685 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2686 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2687 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2688 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2689 applied since this middleware is smart enough to conditionally apply itself).
2690
2691 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2692 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2693 $ENV{SCRIPT_NAME}
2694
2695 =cut
2696
2697
2698 sub apply_default_middlewares {
2699     my ($app, $psgi_app) = @_;
2700
2701     $psgi_app = Plack::Middleware::Conditional->wrap(
2702         $psgi_app,
2703         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2704         condition => sub {
2705             my ($env) = @_;
2706             return if $app->config->{ignore_frontend_proxy};
2707             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2708                 || $app->config->{using_frontend_proxy};
2709         },
2710     );
2711
2712     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2713     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2714     $psgi_app = Plack::Middleware::LighttpdScriptNameFix->wrap($psgi_app);
2715
2716     # we're applying this unconditionally as the middleware itself already makes
2717     # sure it doesn't fuck things up if it's not running under one of the right
2718     # IIS versions
2719     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2720
2721     return $psgi_app;
2722 }
2723
2724 =head2 $c->psgi_app
2725
2726 Returns a PSGI application code reference for the catalyst application
2727 C<$c>. This is the bare application without any middlewares
2728 applied. C<${myapp}.psgi> is not taken into account.
2729
2730 This is what you want to be using to retrieve the PSGI application code
2731 reference of your Catalyst application for use in F<.psgi> files.
2732
2733 =cut
2734
2735 sub psgi_app {
2736     my ($app) = @_;
2737     return $app->engine->build_psgi_app($app);
2738 }
2739
2740 =head2 $c->setup_home
2741
2742 Sets up the home directory.
2743
2744 =cut
2745
2746 sub setup_home {
2747     my ( $class, $home ) = @_;
2748
2749     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2750         $home = $env;
2751     }
2752
2753     $home ||= Catalyst::Utils::home($class);
2754
2755     if ($home) {
2756         #I remember recently being scolded for assigning config values like this
2757         $class->config->{home} ||= $home;
2758         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2759     }
2760 }
2761
2762 =head2 $c->setup_log
2763
2764 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2765 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2766 log to.
2767
2768 This method also installs a C<debug> method that returns a true value into the
2769 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2770 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2771
2772 Note that if the log has already been setup, by either a previous call to
2773 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2774 that this method won't actually set up the log object.
2775
2776 =cut
2777
2778 sub setup_log {
2779     my ( $class, $levels ) = @_;
2780
2781     $levels ||= '';
2782     $levels =~ s/^\s+//;
2783     $levels =~ s/\s+$//;
2784     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2785
2786     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2787     if ( defined $env_debug ) {
2788         $levels{debug} = 1 if $env_debug; # Ugly!
2789         delete($levels{debug}) unless $env_debug;
2790     }
2791
2792     unless ( $class->log ) {
2793         $class->log( Catalyst::Log->new(keys %levels) );
2794     }
2795
2796     if ( $levels{debug} ) {
2797         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2798         $class->log->debug('Debug messages enabled');
2799     }
2800 }
2801
2802 =head2 $c->setup_plugins
2803
2804 Sets up plugins.
2805
2806 =cut
2807
2808 =head2 $c->setup_stats
2809
2810 Sets up timing statistics class.
2811
2812 =cut
2813
2814 sub setup_stats {
2815     my ( $class, $stats ) = @_;
2816
2817     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2818
2819     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2820     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2821         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2822         $class->log->debug('Statistics enabled');
2823     }
2824 }
2825
2826
2827 =head2 $c->registered_plugins
2828
2829 Returns a sorted list of the plugins which have either been stated in the
2830 import list or which have been added via C<< MyApp->plugin(@args); >>.
2831
2832 If passed a given plugin name, it will report a boolean value indicating
2833 whether or not that plugin is loaded.  A fully qualified name is required if
2834 the plugin name does not begin with C<Catalyst::Plugin::>.
2835
2836  if ($c->registered_plugins('Some::Plugin')) {
2837      ...
2838  }
2839
2840 =cut
2841
2842 {
2843
2844     sub registered_plugins {
2845         my $proto = shift;
2846         return sort keys %{ $proto->_plugins } unless @_;
2847         my $plugin = shift;
2848         return 1 if exists $proto->_plugins->{$plugin};
2849         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2850     }
2851
2852     sub _register_plugin {
2853         my ( $proto, $plugin, $instant ) = @_;
2854         my $class = ref $proto || $proto;
2855
2856         Class::MOP::load_class( $plugin );
2857         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2858             if $plugin->isa( 'Catalyst::Component' );
2859         $proto->_plugins->{$plugin} = 1;
2860         unless ($instant) {
2861             my $meta = Class::MOP::get_metaclass_by_name($class);
2862             $meta->superclasses($plugin, $meta->superclasses);
2863         }
2864         return $class;
2865     }
2866
2867     sub setup_plugins {
2868         my ( $class, $plugins ) = @_;
2869
2870         $class->_plugins( {} ) unless $class->_plugins;
2871         $plugins = Data::OptList::mkopt($plugins || []);
2872
2873         my @plugins = map {
2874             [ Catalyst::Utils::resolve_namespace(
2875                   $class . '::Plugin',
2876                   'Catalyst::Plugin', $_->[0]
2877               ),
2878               $_->[1],
2879             ]
2880          } @{ $plugins };
2881
2882         for my $plugin ( reverse @plugins ) {
2883             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2884             my $meta = find_meta($plugin->[0]);
2885             next if $meta && $meta->isa('Moose::Meta::Role');
2886
2887             $class->_register_plugin($plugin->[0]);
2888         }
2889
2890         my @roles =
2891             map  { $_->[0]->name, $_->[1] }
2892             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2893             map  { [find_meta($_->[0]), $_->[1]] }
2894             @plugins;
2895
2896         Moose::Util::apply_all_roles(
2897             $class => @roles
2898         ) if @roles;
2899     }
2900 }
2901
2902 =head2 $c->stack
2903
2904 Returns an arrayref of the internal execution stack (actions that are
2905 currently executing).
2906
2907 =head2 $c->stats
2908
2909 Returns the current timing statistics object. By default Catalyst uses
2910 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2911 L<< stats_class|/"$c->stats_class" >>.
2912
2913 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2914 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2915 profile explicitly, although MyApp.pm still won't profile nor output anything
2916 by itself.
2917
2918 =head2 $c->stats_class
2919
2920 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2921
2922 =head2 $c->use_stats
2923
2924 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2925
2926 Note that this is a static method, not an accessor and should be overridden
2927 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2928
2929 =cut
2930
2931 sub use_stats { 0 }
2932
2933
2934 =head2 $c->write( $data )
2935
2936 Writes $data to the output stream. When using this method directly, you
2937 will need to manually set the C<Content-Length> header to the length of
2938 your output data, if known.
2939
2940 =cut
2941
2942 sub write {
2943     my $c = shift;
2944
2945     # Finalize headers if someone manually writes output
2946     $c->finalize_headers;
2947
2948     return $c->engine->write( $c, @_ );
2949 }
2950
2951 =head2 version
2952
2953 Returns the Catalyst version number. Mostly useful for "powered by"
2954 messages in template systems.
2955
2956 =cut
2957
2958 sub version { return $Catalyst::VERSION }
2959
2960 =head1 CONFIGURATION
2961
2962 There are a number of 'base' config variables which can be set:
2963
2964 =over
2965
2966 =item *
2967
2968 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2969
2970 =item *
2971
2972 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2973
2974 =item *
2975
2976 C<disable_component_resolution_regex_fallback> - Turns
2977 off the deprecated component resolution functionality so
2978 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2979 are called then regex search will not be attempted on string values and
2980 instead C<undef> will be returned.
2981
2982 =item *
2983
2984 C<home> - The application home directory. In an uninstalled application,
2985 this is the top level application directory. In an installed application,
2986 this will be the directory containing C<< MyApp.pm >>.
2987
2988 =item *
2989
2990 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2991
2992 =item *
2993
2994 C<name> - The name of the application in debug messages and the debug and
2995 welcome screens
2996
2997 =item *
2998
2999 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3000 until it is accessed. This allows you to (for example) check authentication (and reject
3001 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
3002
3003 =item *
3004
3005 C<root> - The root directory for templates. Usually this is just a
3006 subdirectory of the home directory, but you can set it to change the
3007 templates to a different directory.
3008
3009 =item *
3010
3011 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3012 namespaces from which components will be loaded (and constructed and stored in
3013 C<< $c->components >>).
3014
3015 =item *
3016
3017 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3018 to be shown in hit debug tables in the test server.
3019
3020 =item *
3021
3022 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
3023 variable should be used for determining the request path.
3024
3025 Most web server environments pass the requested path to the application using environment variables,
3026 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3027 exposed as C<< $c->request->base >>) and the request path below that base.
3028
3029 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3030 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3031
3032 =over
3033
3034 =item use_request_uri_for_path => 0
3035
3036 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3037 The path is synthesised from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3038 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3039 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3040
3041 However this method has the major disadvantage that it is impossible to correctly decode some elements
3042 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3043 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3044 can't distinguish / vs %2F in paths (in addition to other encoded values).
3045
3046 =item use_request_uri_for_path => 1
3047
3048 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3049 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3050 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3051
3052 Given that this method of path resolution is provably more correct, it is recommended that you use
3053 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3054 aware of the implications of not being able to handle encoded URI paths correctly.
3055
3056 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3057 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3058 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3059 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3060 C<< $c->request->base >> will be incorrect.
3061
3062 =back
3063
3064 =item *
3065
3066 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3067
3068 =back
3069
3070 =head1 INTERNAL ACTIONS
3071
3072 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3073 C<_ACTION>, and C<_END>. These are by default not shown in the private
3074 action table, but you can make them visible with a config parameter.
3075
3076     MyApp->config(show_internal_actions => 1);
3077
3078 =head1 ON-DEMAND PARSER
3079
3080 The request body is usually parsed at the beginning of a request,
3081 but if you want to handle input yourself, you can enable on-demand
3082 parsing with a config parameter.
3083
3084     MyApp->config(parse_on_demand => 1);
3085
3086 =head1 PROXY SUPPORT
3087
3088 Many production servers operate using the common double-server approach,
3089 with a lightweight frontend web server passing requests to a larger
3090 backend server. An application running on the backend server must deal
3091 with two problems: the remote user always appears to be C<127.0.0.1> and
3092 the server's hostname will appear to be C<localhost> regardless of the
3093 virtual host that the user connected through.
3094
3095 Catalyst will automatically detect this situation when you are running
3096 the frontend and backend servers on the same machine. The following
3097 changes are made to the request.
3098
3099     $c->req->address is set to the user's real IP address, as read from
3100     the HTTP X-Forwarded-For header.
3101
3102     The host value for $c->req->base and $c->req->uri is set to the real
3103     host, as read from the HTTP X-Forwarded-Host header.
3104
3105 Additionally, you may be running your backend application on an insecure
3106 connection (port 80) while your frontend proxy is running under SSL.  If there
3107 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3108 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3109 be created properly.
3110
3111 In the case of passing in:
3112
3113     X-Forwarded-Port: 443
3114
3115 All calls to C<uri_for> will result in an https link, as is expected.
3116
3117 Obviously, your web server must support these headers for this to work.
3118
3119 In a more complex server farm environment where you may have your
3120 frontend proxy server(s) on different machines, you will need to set a
3121 configuration option to tell Catalyst to read the proxied data from the
3122 headers.
3123
3124     MyApp->config(using_frontend_proxy => 1);
3125
3126 If you do not wish to use the proxy support at all, you may set:
3127
3128     MyApp->config(ignore_frontend_proxy => 1);
3129
3130 =head1 THREAD SAFETY
3131
3132 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3133 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3134 believe the Catalyst core to be thread-safe.
3135
3136 If you plan to operate in a threaded environment, remember that all other
3137 modules you are using must also be thread-safe. Some modules, most notably
3138 L<DBD::SQLite>, are not thread-safe.
3139
3140 =head1 SUPPORT
3141
3142 IRC:
3143
3144     Join #catalyst on irc.perl.org.
3145
3146 Mailing Lists:
3147
3148     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3149     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3150
3151 Web:
3152
3153     http://catalyst.perl.org
3154
3155 Wiki:
3156
3157     http://dev.catalyst.perl.org
3158
3159 =head1 SEE ALSO
3160
3161 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3162
3163 =head2 L<Catalyst::Manual> - The Catalyst Manual
3164
3165 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3166
3167 =head2 L<Catalyst::Engine> - Core engine
3168
3169 =head2 L<Catalyst::Log> - Log class.
3170
3171 =head2 L<Catalyst::Request> - Request object
3172
3173 =head2 L<Catalyst::Response> - Response object
3174
3175 =head2 L<Catalyst::Test> - The test suite.
3176
3177 =head1 PROJECT FOUNDER
3178
3179 sri: Sebastian Riedel <sri@cpan.org>
3180
3181 =head1 CONTRIBUTORS
3182
3183 abw: Andy Wardley
3184
3185 acme: Leon Brocard <leon@astray.com>
3186
3187 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3188
3189 Andrew Bramble
3190
3191 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3192
3193 Andrew Ruthven
3194
3195 andyg: Andy Grundman <andy@hybridized.org>
3196
3197 audreyt: Audrey Tang
3198
3199 bricas: Brian Cassidy <bricas@cpan.org>
3200
3201 Caelum: Rafael Kitover <rkitover@io.com>
3202
3203 chansen: Christian Hansen
3204
3205 chicks: Christopher Hicks
3206
3207 Chisel Wright C<pause@herlpacker.co.uk>
3208
3209 Danijel Milicevic C<me@danijel.de>
3210
3211 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3212
3213 David Naughton, C<naughton@umn.edu>
3214
3215 David E. Wheeler
3216
3217 dhoss: Devin Austin <dhoss@cpan.org>
3218
3219 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3220
3221 Drew Taylor
3222
3223 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3224
3225 esskar: Sascha Kiefer
3226
3227 fireartist: Carl Franks <cfranks@cpan.org>
3228
3229 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3230
3231 gabb: Danijel Milicevic
3232
3233 Gary Ashton Jones
3234
3235 Gavin Henry C<ghenry@perl.me.uk>
3236
3237 Geoff Richards
3238
3239 groditi: Guillermo Roditi <groditi@gmail.com>
3240
3241 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3242
3243 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3244
3245 jcamacho: Juan Camacho
3246
3247 jester: Jesse Sheidlower C<jester@panix.com>
3248
3249 jhannah: Jay Hannah <jay@jays.net>
3250
3251 Jody Belka
3252
3253 Johan Lindstrom
3254
3255 jon: Jon Schutz <jjschutz@cpan.org>
3256
3257 Jonathan Rockway C<< <jrockway@cpan.org> >>
3258
3259 Kieren Diment C<kd@totaldatasolution.com>
3260
3261 konobi: Scott McWhirter <konobi@cpan.org>
3262
3263 marcus: Marcus Ramberg <mramberg@cpan.org>
3264
3265 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3266
3267 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3268
3269 mugwump: Sam Vilain
3270
3271 naughton: David Naughton
3272
3273 ningu: David Kamholz <dkamholz@cpan.org>
3274
3275 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3276
3277 numa: Dan Sully <daniel@cpan.org>
3278
3279 obra: Jesse Vincent
3280
3281 Octavian Rasnita
3282
3283 omega: Andreas Marienborg
3284
3285 Oleg Kostyuk <cub.uanic@gmail.com>
3286
3287 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3288
3289 rafl: Florian Ragwitz <rafl@debian.org>
3290
3291 random: Roland Lammel <lammel@cpan.org>
3292
3293 Robert Sedlacek C<< <rs@474.at> >>
3294
3295 SpiceMan: Marcel Montes
3296
3297 sky: Arthur Bergman
3298
3299 szbalint: Balint Szilakszi <szbalint@cpan.org>
3300
3301 t0m: Tomas Doran <bobtfish@bobtfish.net>
3302
3303 Ulf Edvinsson
3304
3305 Viljo Marrandi C<vilts@yahoo.com>
3306
3307 Will Hawes C<info@whawes.co.uk>
3308
3309 willert: Sebastian Willert <willert@cpan.org>
3310
3311 wreis: Wallace Reis <wallace@reis.org.br>
3312
3313 Yuval Kogman, C<nothingmuch@woobling.org>
3314
3315 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3316
3317 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3318
3319 =head1 COPYRIGHT
3320
3321 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3322
3323 =head1 LICENSE
3324
3325 This library is free software. You can redistribute it and/or modify it under
3326 the same terms as Perl itself.
3327
3328 =cut
3329
3330 no Moose;
3331
3332 __PACKAGE__->meta->make_immutable;
3333
3334 1;