Fix removed methods that plugins are likely to be hooking
[catagits/Catalyst-Runtime.git] / lib / Catalyst.pm
1 package Catalyst;
2
3 use Moose;
4 use Moose::Meta::Class ();
5 extends 'Catalyst::Component';
6 use Moose::Util qw/find_meta/;
7 use B::Hooks::EndOfScope ();
8 use Catalyst::Exception;
9 use Catalyst::Exception::Detach;
10 use Catalyst::Exception::Go;
11 use Catalyst::Log;
12 use Catalyst::Request;
13 use Catalyst::Request::Upload;
14 use Catalyst::Response;
15 use Catalyst::Utils;
16 use Catalyst::Controller;
17 use Data::OptList;
18 use Devel::InnerPackage ();
19 use Module::Pluggable::Object ();
20 use Text::SimpleTable ();
21 use Path::Class::Dir ();
22 use Path::Class::File ();
23 use URI ();
24 use URI::http;
25 use URI::https;
26 use Tree::Simple qw/use_weak_refs/;
27 use Tree::Simple::Visitor::FindByUID;
28 use Class::C3::Adopt::NEXT;
29 use List::MoreUtils qw/uniq/;
30 use attributes;
31 use String::RewritePrefix;
32 use Catalyst::EngineLoader;
33 use utf8;
34 use Carp qw/croak carp shortmess/;
35 use Try::Tiny;
36 use Plack::Middleware::Conditional;
37 use Plack::Middleware::ReverseProxy;
38 use Plack::Middleware::IIS6ScriptNameFix;
39 use Plack::Middleware::LighttpdScriptNameFix;
40
41 BEGIN { require 5.008004; }
42
43 has stack => (is => 'ro', default => sub { [] });
44 has stash => (is => 'rw', default => sub { {} });
45 has state => (is => 'rw', default => 0);
46 has stats => (is => 'rw');
47 has action => (is => 'rw');
48 has counter => (is => 'rw', default => sub { {} });
49 has request => (
50     is => 'rw',
51     default => sub {
52         my $self = shift;
53         my %p = ( _log => $self->log );
54         $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
55         $self->request_class->new(\%p);
56     },
57     lazy => 1,
58 );
59 has response => (
60     is => 'rw',
61     default => sub {
62         my $self = shift;
63         $self->response_class->new({ _log => $self->log });
64     },
65     lazy => 1,
66 );
67 has namespace => (is => 'rw');
68
69 sub depth { scalar @{ shift->stack || [] }; }
70 sub comp { shift->component(@_) }
71
72 sub req {
73     my $self = shift; return $self->request(@_);
74 }
75 sub res {
76     my $self = shift; return $self->response(@_);
77 }
78
79 # For backwards compatibility
80 sub finalize_output { shift->finalize_body(@_) };
81
82 # For statistics
83 our $COUNT     = 1;
84 our $START     = time;
85 our $RECURSION = 1000;
86 our $DETACH    = Catalyst::Exception::Detach->new;
87 our $GO        = Catalyst::Exception::Go->new;
88
89 #I imagine that very few of these really need to be class variables. if any.
90 #maybe we should just make them attributes with a default?
91 __PACKAGE__->mk_classdata($_)
92   for qw/components arguments dispatcher engine log dispatcher_class
93   engine_loader context_class request_class response_class stats_class
94   setup_finished _psgi_app loading_psgi_file run_options/;
95
96 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
97 __PACKAGE__->request_class('Catalyst::Request');
98 __PACKAGE__->response_class('Catalyst::Response');
99 __PACKAGE__->stats_class('Catalyst::Stats');
100
101 # Remember to update this in Catalyst::Runtime as well!
102
103 our $VERSION = '5.90006';
104
105 sub import {
106     my ( $class, @arguments ) = @_;
107
108     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
109     # callers @ISA.
110     return unless $class eq 'Catalyst';
111
112     my $caller = caller();
113     return if $caller eq 'main';
114
115     my $meta = Moose::Meta::Class->initialize($caller);
116     unless ( $caller->isa('Catalyst') ) {
117         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
118         $meta->superclasses(@superclasses);
119     }
120     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
121     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
122
123     unless( $meta->has_method('meta') ){
124         if ($Moose::VERSION >= 1.15) {
125             $meta->_add_meta_method('meta');
126         }
127         else {
128             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
129         }
130     }
131
132     $caller->arguments( [@arguments] );
133     $caller->setup_home;
134 }
135
136 sub _application { $_[0] }
137
138 =head1 NAME
139
140 Catalyst - The Elegant MVC Web Application Framework
141
142 =head1 SYNOPSIS
143
144 See the L<Catalyst::Manual> distribution for comprehensive
145 documentation and tutorials.
146
147     # Install Catalyst::Devel for helpers and other development tools
148     # use the helper to create a new application
149     catalyst.pl MyApp
150
151     # add models, views, controllers
152     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
153     script/myapp_create.pl view MyTemplate TT
154     script/myapp_create.pl controller Search
155
156     # built in testserver -- use -r to restart automatically on changes
157     # --help to see all available options
158     script/myapp_server.pl
159
160     # command line testing interface
161     script/myapp_test.pl /yada
162
163     ### in lib/MyApp.pm
164     use Catalyst qw/-Debug/; # include plugins here as well
165
166     ### In lib/MyApp/Controller/Root.pm (autocreated)
167     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
168         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
169         $c->stash->{template} = 'foo.tt'; # set the template
170         # lookup something from db -- stash vars are passed to TT
171         $c->stash->{data} =
172           $c->model('Database::Foo')->search( { country => $args[0] } );
173         if ( $c->req->params->{bar} ) { # access GET or POST parameters
174             $c->forward( 'bar' ); # process another action
175             # do something else after forward returns
176         }
177     }
178
179     # The foo.tt TT template can use the stash data from the database
180     [% WHILE (item = data.next) %]
181         [% item.foo %]
182     [% END %]
183
184     # called for /bar/of/soap, /bar/of/soap/10, etc.
185     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
186
187     # called after all actions are finished
188     sub end : Action {
189         my ( $self, $c ) = @_;
190         if ( scalar @{ $c->error } ) { ... } # handle errors
191         return if $c->res->body; # already have a response
192         $c->forward( 'MyApp::View::TT' ); # render template
193     }
194
195 See L<Catalyst::Manual::Intro> for additional information.
196
197 =head1 DESCRIPTION
198
199 Catalyst is a modern framework for making web applications without the
200 pain usually associated with this process. This document is a reference
201 to the main Catalyst application. If you are a new user, we suggest you
202 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
203
204 See L<Catalyst::Manual> for more documentation.
205
206 Catalyst plugins can be loaded by naming them as arguments to the "use
207 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
208 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
209 C<My::Module>.
210
211     use Catalyst qw/My::Module/;
212
213 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
214 fully qualify the name by using a unary plus:
215
216     use Catalyst qw/
217         My::Module
218         +Fully::Qualified::Plugin::Name
219     /;
220
221 Special flags like C<-Debug> can also be specified as
222 arguments when Catalyst is loaded:
223
224     use Catalyst qw/-Debug My::Module/;
225
226 The position of plugins and flags in the chain is important, because
227 they are loaded in the order in which they appear.
228
229 The following flags are supported:
230
231 =head2 -Debug
232
233 Enables debug output. You can also force this setting from the system
234 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
235 settings override the application, with <MYAPP>_DEBUG having the highest
236 priority.
237
238 This sets the log level to 'debug' and enables full debug output on the
239 error screen. If you only want the latter, see L<< $c->debug >>.
240
241 =head2 -Home
242
243 Forces Catalyst to use a specific home directory, e.g.:
244
245     use Catalyst qw[-Home=/usr/mst];
246
247 This can also be done in the shell environment by setting either the
248 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
249 is replaced with the uppercased name of your application, any "::" in
250 the name will be replaced with underscores, e.g. MyApp::Web should use
251 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
252
253 If none of these are set, Catalyst will attempt to automatically detect the
254 home directory. If you are working in a development environment, Catalyst
255 will try and find the directory containing either Makefile.PL, Build.PL or
256 dist.ini. If the application has been installed into the system (i.e.
257 you have done C<make install>), then Catalyst will use the path to your
258 application module, without the .pm extension (e.g., /foo/MyApp if your
259 application was installed at /foo/MyApp.pm)
260
261 =head2 -Log
262
263     use Catalyst '-Log=warn,fatal,error';
264
265 Specifies a comma-delimited list of log levels.
266
267 =head2 -Stats
268
269 Enables statistics collection and reporting.
270
271    use Catalyst qw/-Stats=1/;
272
273 You can also force this setting from the system environment with CATALYST_STATS
274 or <MYAPP>_STATS. The environment settings override the application, with
275 <MYAPP>_STATS having the highest priority.
276
277 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
278
279 =head1 METHODS
280
281 =head2 INFORMATION ABOUT THE CURRENT REQUEST
282
283 =head2 $c->action
284
285 Returns a L<Catalyst::Action> object for the current action, which
286 stringifies to the action name. See L<Catalyst::Action>.
287
288 =head2 $c->namespace
289
290 Returns the namespace of the current action, i.e., the URI prefix
291 corresponding to the controller of the current action. For example:
292
293     # in Controller::Foo::Bar
294     $c->namespace; # returns 'foo/bar';
295
296 =head2 $c->request
297
298 =head2 $c->req
299
300 Returns the current L<Catalyst::Request> object, giving access to
301 information about the current client request (including parameters,
302 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
303
304 =head2 REQUEST FLOW HANDLING
305
306 =head2 $c->forward( $action [, \@arguments ] )
307
308 =head2 $c->forward( $class, $method, [, \@arguments ] )
309
310 Forwards processing to another action, by its private name. If you give a
311 class name but no method, C<process()> is called. You may also optionally
312 pass arguments in an arrayref. The action will receive the arguments in
313 C<@_> and C<< $c->req->args >>. Upon returning from the function,
314 C<< $c->req->args >> will be restored to the previous values.
315
316 Any data C<return>ed from the action forwarded to, will be returned by the
317 call to forward.
318
319     my $foodata = $c->forward('/foo');
320     $c->forward('index');
321     $c->forward(qw/Model::DBIC::Foo do_stuff/);
322     $c->forward('View::TT');
323
324 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
325 an C<< eval { } >> around the call (actually
326 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
327 exceptions thrown by the called action non-fatal and pushing them onto
328 $c->error instead. If you want C<die> to propagate you need to do something
329 like:
330
331     $c->forward('foo');
332     die join "\n", @{ $c->error } if @{ $c->error };
333
334 Or make sure to always return true values from your actions and write
335 your code like this:
336
337     $c->forward('foo') || return;
338
339 Another note is that C<< $c->forward >> always returns a scalar because it
340 actually returns $c->state which operates in a scalar context.
341 Thus, something like:
342
343     return @array;
344
345 in an action that is forwarded to is going to return a scalar,
346 i.e. how many items are in that array, which is probably not what you want.
347 If you need to return an array then return a reference to it,
348 or stash it like so:
349
350     $c->stash->{array} = \@array;
351
352 and access it from the stash.
353
354 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
355
356 =cut
357
358 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
359
360 =head2 $c->detach( $action [, \@arguments ] )
361
362 =head2 $c->detach( $class, $method, [, \@arguments ] )
363
364 =head2 $c->detach()
365
366 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
367 doesn't return to the previous action when processing is finished.
368
369 When called with no arguments it escapes the processing chain entirely.
370
371 =cut
372
373 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
374
375 =head2 $c->visit( $action [, \@captures, \@arguments ] )
376
377 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
378
379 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
380 but does a full dispatch, instead of just calling the new C<$action> /
381 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
382 you go to are called, just like a new request.
383
384 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
385 This means, for example, that C<< $c->action >> methods such as
386 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
387 L<reverse|Catalyst::Action/reverse> return information for the visited action
388 when they are invoked within the visited action.  This is different from the
389 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
390 continues to use the $c->action object from the caller action even when
391 invoked from the called action.
392
393 C<< $c->stash >> is kept unchanged.
394
395 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
396 allows you to "wrap" another action, just as it would have been called by
397 dispatching from a URL, while the analogous
398 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
399 transfer control to another action as if it had been reached directly from a URL.
400
401 =cut
402
403 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
404
405 =head2 $c->go( $action [, \@captures, \@arguments ] )
406
407 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
408
409 The relationship between C<go> and
410 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
411 the relationship between
412 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
413 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
414 C<< $c->go >> will perform a full dispatch on the specified action or method,
415 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
416 C<go> escapes the processing of the current request chain on completion, and
417 does not return to its caller.
418
419 @arguments are arguments to the final destination of $action. @captures are
420 arguments to the intermediate steps, if any, on the way to the final sub of
421 $action.
422
423 =cut
424
425 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
426
427 =head2 $c->response
428
429 =head2 $c->res
430
431 Returns the current L<Catalyst::Response> object, see there for details.
432
433 =head2 $c->stash
434
435 Returns a hashref to the stash, which may be used to store data and pass
436 it between components during a request. You can also set hash keys by
437 passing arguments. The stash is automatically sent to the view. The
438 stash is cleared at the end of a request; it cannot be used for
439 persistent storage (for this you must use a session; see
440 L<Catalyst::Plugin::Session> for a complete system integrated with
441 Catalyst).
442
443     $c->stash->{foo} = $bar;
444     $c->stash( { moose => 'majestic', qux => 0 } );
445     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
446
447     # stash is automatically passed to the view for use in a template
448     $c->forward( 'MyApp::View::TT' );
449
450 =cut
451
452 around stash => sub {
453     my $orig = shift;
454     my $c = shift;
455     my $stash = $orig->($c);
456     if (@_) {
457         my $new_stash = @_ > 1 ? {@_} : $_[0];
458         croak('stash takes a hash or hashref') unless ref $new_stash;
459         foreach my $key ( keys %$new_stash ) {
460           $stash->{$key} = $new_stash->{$key};
461         }
462     }
463
464     return $stash;
465 };
466
467
468 =head2 $c->error
469
470 =head2 $c->error($error, ...)
471
472 =head2 $c->error($arrayref)
473
474 Returns an arrayref containing error messages.  If Catalyst encounters an
475 error while processing a request, it stores the error in $c->error.  This
476 method should only be used to store fatal error messages.
477
478     my @error = @{ $c->error };
479
480 Add a new error.
481
482     $c->error('Something bad happened');
483
484 =cut
485
486 sub error {
487     my $c = shift;
488     if ( $_[0] ) {
489         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
490         croak @$error unless ref $c;
491         push @{ $c->{error} }, @$error;
492     }
493     elsif ( defined $_[0] ) { $c->{error} = undef }
494     return $c->{error} || [];
495 }
496
497
498 =head2 $c->state
499
500 Contains the return value of the last executed action.
501 Note that << $c->state >> operates in a scalar context which means that all
502 values it returns are scalar.
503
504 =head2 $c->clear_errors
505
506 Clear errors.  You probably don't want to clear the errors unless you are
507 implementing a custom error screen.
508
509 This is equivalent to running
510
511     $c->error(0);
512
513 =cut
514
515 sub clear_errors {
516     my $c = shift;
517     $c->error(0);
518 }
519
520 sub _comp_search_prefixes {
521     my $c = shift;
522     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
523 }
524
525 # search components given a name and some prefixes
526 sub _comp_names_search_prefixes {
527     my ( $c, $name, @prefixes ) = @_;
528     my $appclass = ref $c || $c;
529     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
530     $filter = qr/$filter/; # Compile regex now rather than once per loop
531
532     # map the original component name to the sub part that we will search against
533     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
534         grep { /$filter/ } keys %{ $c->components };
535
536     # undef for a name will return all
537     return keys %eligible if !defined $name;
538
539     my $query  = ref $name ? $name : qr/^$name$/i;
540     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
541
542     return @result if @result;
543
544     # if we were given a regexp to search against, we're done.
545     return if ref $name;
546
547     # skip regexp fallback if configured
548     return
549         if $appclass->config->{disable_component_resolution_regex_fallback};
550
551     # regexp fallback
552     $query  = qr/$name/i;
553     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
554
555     # no results? try against full names
556     if( !@result ) {
557         @result = grep { m{$query} } keys %eligible;
558     }
559
560     # don't warn if we didn't find any results, it just might not exist
561     if( @result ) {
562         # Disgusting hack to work out correct method name
563         my $warn_for = lc $prefixes[0];
564         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
565            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
566            "component resolution is unreliable and unsafe.";
567         my $short = $result[0];
568         # remove the component namespace prefix
569         $short =~ s/.*?(Model|Controller|View):://;
570         my $shortmess = Carp::shortmess('');
571         if ($shortmess =~ m#Catalyst/Plugin#) {
572            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
573               "plugin's config";
574         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
575            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
576               "component's config";
577         } else {
578            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
579               "but if you really wanted to search, pass in a regexp as the argument " .
580               "like so: \$c->${warn_for}(qr/${name}/)";
581         }
582         $c->log->warn( "${msg}$shortmess" );
583     }
584
585     return @result;
586 }
587
588 # Find possible names for a prefix
589 sub _comp_names {
590     my ( $c, @prefixes ) = @_;
591     my $appclass = ref $c || $c;
592
593     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
594
595     my @names = map { s{$filter}{}; $_; }
596         $c->_comp_names_search_prefixes( undef, @prefixes );
597
598     return @names;
599 }
600
601 # Filter a component before returning by calling ACCEPT_CONTEXT if available
602 sub _filter_component {
603     my ( $c, $comp, @args ) = @_;
604
605     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
606         return $comp->ACCEPT_CONTEXT( $c, @args );
607     }
608
609     return $comp;
610 }
611
612 =head2 COMPONENT ACCESSORS
613
614 =head2 $c->controller($name)
615
616 Gets a L<Catalyst::Controller> instance by name.
617
618     $c->controller('Foo')->do_stuff;
619
620 If the name is omitted, will return the controller for the dispatched
621 action.
622
623 If you want to search for controllers, pass in a regexp as the argument.
624
625     # find all controllers that start with Foo
626     my @foo_controllers = $c->controller(qr{^Foo});
627
628
629 =cut
630
631 sub controller {
632     my ( $c, $name, @args ) = @_;
633
634     my $appclass = ref($c) || $c;
635     if( $name ) {
636         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
637             my $comps = $c->components;
638             my $check = $appclass."::Controller::".$name;
639             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
640         }
641         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
642         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
643         return $c->_filter_component( $result[ 0 ], @args );
644     }
645
646     return $c->component( $c->action->class );
647 }
648
649 =head2 $c->model($name)
650
651 Gets a L<Catalyst::Model> instance by name.
652
653     $c->model('Foo')->do_stuff;
654
655 Any extra arguments are directly passed to ACCEPT_CONTEXT.
656
657 If the name is omitted, it will look for
658  - a model object in $c->stash->{current_model_instance}, then
659  - a model name in $c->stash->{current_model}, then
660  - a config setting 'default_model', or
661  - check if there is only one model, and return it if that's the case.
662
663 If you want to search for models, pass in a regexp as the argument.
664
665     # find all models that start with Foo
666     my @foo_models = $c->model(qr{^Foo});
667
668 =cut
669
670 sub model {
671     my ( $c, $name, @args ) = @_;
672     my $appclass = ref($c) || $c;
673     if( $name ) {
674         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
675             my $comps = $c->components;
676             my $check = $appclass."::Model::".$name;
677             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
678         }
679         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
680         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
681         return $c->_filter_component( $result[ 0 ], @args );
682     }
683
684     if (ref $c) {
685         return $c->stash->{current_model_instance}
686           if $c->stash->{current_model_instance};
687         return $c->model( $c->stash->{current_model} )
688           if $c->stash->{current_model};
689     }
690     return $c->model( $appclass->config->{default_model} )
691       if $appclass->config->{default_model};
692
693     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
694
695     if( $rest ) {
696         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
697         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
698         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
699         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
700         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
701     }
702
703     return $c->_filter_component( $comp );
704 }
705
706
707 =head2 $c->view($name)
708
709 Gets a L<Catalyst::View> instance by name.
710
711     $c->view('Foo')->do_stuff;
712
713 Any extra arguments are directly passed to ACCEPT_CONTEXT.
714
715 If the name is omitted, it will look for
716  - a view object in $c->stash->{current_view_instance}, then
717  - a view name in $c->stash->{current_view}, then
718  - a config setting 'default_view', or
719  - check if there is only one view, and return it if that's the case.
720
721 If you want to search for views, pass in a regexp as the argument.
722
723     # find all views that start with Foo
724     my @foo_views = $c->view(qr{^Foo});
725
726 =cut
727
728 sub view {
729     my ( $c, $name, @args ) = @_;
730
731     my $appclass = ref($c) || $c;
732     if( $name ) {
733         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
734             my $comps = $c->components;
735             my $check = $appclass."::View::".$name;
736             if( exists $comps->{$check} ) {
737                 return $c->_filter_component( $comps->{$check}, @args );
738             }
739             else {
740                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
741             }
742         }
743         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
744         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
745         return $c->_filter_component( $result[ 0 ], @args );
746     }
747
748     if (ref $c) {
749         return $c->stash->{current_view_instance}
750           if $c->stash->{current_view_instance};
751         return $c->view( $c->stash->{current_view} )
752           if $c->stash->{current_view};
753     }
754     return $c->view( $appclass->config->{default_view} )
755       if $appclass->config->{default_view};
756
757     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
758
759     if( $rest ) {
760         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
761         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
762         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
763         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
764         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
765     }
766
767     return $c->_filter_component( $comp );
768 }
769
770 =head2 $c->controllers
771
772 Returns the available names which can be passed to $c->controller
773
774 =cut
775
776 sub controllers {
777     my ( $c ) = @_;
778     return $c->_comp_names(qw/Controller C/);
779 }
780
781 =head2 $c->models
782
783 Returns the available names which can be passed to $c->model
784
785 =cut
786
787 sub models {
788     my ( $c ) = @_;
789     return $c->_comp_names(qw/Model M/);
790 }
791
792
793 =head2 $c->views
794
795 Returns the available names which can be passed to $c->view
796
797 =cut
798
799 sub views {
800     my ( $c ) = @_;
801     return $c->_comp_names(qw/View V/);
802 }
803
804 =head2 $c->comp($name)
805
806 =head2 $c->component($name)
807
808 Gets a component object by name. This method is not recommended,
809 unless you want to get a specific component by full
810 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
811 should be used instead.
812
813 If C<$name> is a regexp, a list of components matched against the full
814 component name will be returned.
815
816 If Catalyst can't find a component by name, it will fallback to regex
817 matching by default. To disable this behaviour set
818 disable_component_resolution_regex_fallback to a true value.
819
820     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
821
822 =cut
823
824 sub component {
825     my ( $c, $name, @args ) = @_;
826
827     if( $name ) {
828         my $comps = $c->components;
829
830         if( !ref $name ) {
831             # is it the exact name?
832             return $c->_filter_component( $comps->{ $name }, @args )
833                        if exists $comps->{ $name };
834
835             # perhaps we just omitted "MyApp"?
836             my $composed = ( ref $c || $c ) . "::${name}";
837             return $c->_filter_component( $comps->{ $composed }, @args )
838                        if exists $comps->{ $composed };
839
840             # search all of the models, views and controllers
841             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
842             return $c->_filter_component( $comp, @args ) if $comp;
843         }
844
845         return
846             if $c->config->{disable_component_resolution_regex_fallback};
847
848         # This is here so $c->comp( '::M::' ) works
849         my $query = ref $name ? $name : qr{$name}i;
850
851         my @result = grep { m{$query} } keys %{ $c->components };
852         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
853
854         if( $result[ 0 ] ) {
855             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
856             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
857             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
858             return $c->_filter_component( $result[ 0 ], @args );
859         }
860
861         # I would expect to return an empty list here, but that breaks back-compat
862     }
863
864     # fallback
865     return sort keys %{ $c->components };
866 }
867
868 =head2 CLASS DATA AND HELPER CLASSES
869
870 =head2 $c->config
871
872 Returns or takes a hashref containing the application's configuration.
873
874     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
875
876 You can also use a C<YAML>, C<XML> or L<Config::General> config file
877 like C<myapp.conf> in your applications home directory. See
878 L<Catalyst::Plugin::ConfigLoader>.
879
880 =head3 Cascading configuration
881
882 The config method is present on all Catalyst components, and configuration
883 will be merged when an application is started. Configuration loaded with
884 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
885 followed by configuration in your top level C<MyApp> class. These two
886 configurations are merged, and then configuration data whose hash key matches a
887 component name is merged with configuration for that component.
888
889 The configuration for a component is then passed to the C<new> method when a
890 component is constructed.
891
892 For example:
893
894     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
895     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
896
897 will mean that C<MyApp::Model::Foo> receives the following data when
898 constructed:
899
900     MyApp::Model::Foo->new({
901         bar => 'baz',
902         quux => 'frob',
903         overrides => 'me',
904     });
905
906 It's common practice to use a Moose attribute
907 on the receiving component to access the config value.
908
909     package MyApp::Model::Foo;
910
911     use Moose;
912
913     # this attr will receive 'baz' at construction time
914     has 'bar' => (
915         is  => 'rw',
916         isa => 'Str',
917     );
918
919 You can then get the value 'baz' by calling $c->model('Foo')->bar
920 (or $self->bar inside code in the model).
921
922 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
923 as a way of reading config within your code, as this B<will not> give you the
924 correctly merged config back. You B<MUST> take the config values supplied to
925 the constructor and use those instead.
926
927 =cut
928
929 around config => sub {
930     my $orig = shift;
931     my $c = shift;
932
933     croak('Setting config after setup has been run is not allowed.')
934         if ( @_ and $c->setup_finished );
935
936     $c->$orig(@_);
937 };
938
939 =head2 $c->log
940
941 Returns the logging object instance. Unless it is already set, Catalyst
942 sets this up with a L<Catalyst::Log> object. To use your own log class,
943 set the logger with the C<< __PACKAGE__->log >> method prior to calling
944 C<< __PACKAGE__->setup >>.
945
946  __PACKAGE__->log( MyLogger->new );
947  __PACKAGE__->setup;
948
949 And later:
950
951     $c->log->info( 'Now logging with my own logger!' );
952
953 Your log class should implement the methods described in
954 L<Catalyst::Log>.
955
956
957 =head2 $c->debug
958
959 Returns 1 if debug mode is enabled, 0 otherwise.
960
961 You can enable debug mode in several ways:
962
963 =over
964
965 =item By calling myapp_server.pl with the -d flag
966
967 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
968
969 =item The -Debug option in your MyApp.pm
970
971 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
972
973 =back
974
975 The first three also set the log level to 'debug'.
976
977 Calling C<< $c->debug(1) >> has no effect.
978
979 =cut
980
981 sub debug { 0 }
982
983 =head2 $c->dispatcher
984
985 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
986
987 =head2 $c->engine
988
989 Returns the engine instance. See L<Catalyst::Engine>.
990
991
992 =head2 UTILITY METHODS
993
994 =head2 $c->path_to(@path)
995
996 Merges C<@path> with C<< $c->config->{home} >> and returns a
997 L<Path::Class::Dir> object. Note you can usually use this object as
998 a filename, but sometimes you will have to explicitly stringify it
999 yourself by calling the C<< ->stringify >> method.
1000
1001 For example:
1002
1003     $c->path_to( 'db', 'sqlite.db' );
1004
1005 =cut
1006
1007 sub path_to {
1008     my ( $c, @path ) = @_;
1009     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1010     if ( -d $path ) { return $path }
1011     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1012 }
1013
1014 sub plugin {
1015     my ( $class, $name, $plugin, @args ) = @_;
1016
1017     # See block comment in t/unit_core_plugin.t
1018     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1019
1020     $class->_register_plugin( $plugin, 1 );
1021
1022     eval { $plugin->import };
1023     $class->mk_classdata($name);
1024     my $obj;
1025     eval { $obj = $plugin->new(@args) };
1026
1027     if ($@) {
1028         Catalyst::Exception->throw( message =>
1029               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1030     }
1031
1032     $class->$name($obj);
1033     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1034       if $class->debug;
1035 }
1036
1037 =head2 MyApp->setup
1038
1039 Initializes the dispatcher and engine, loads any plugins, and loads the
1040 model, view, and controller components. You may also specify an array
1041 of plugins to load here, if you choose to not load them in the C<use
1042 Catalyst> line.
1043
1044     MyApp->setup;
1045     MyApp->setup( qw/-Debug/ );
1046
1047 B<Note:> You B<should not> wrap this method with method modifiers
1048 or bad things will happen - wrap the C<setup_finalize> method instead.
1049
1050 =cut
1051
1052 sub setup {
1053     my ( $class, @arguments ) = @_;
1054     croak('Running setup more than once')
1055         if ( $class->setup_finished );
1056
1057     unless ( $class->isa('Catalyst') ) {
1058
1059         Catalyst::Exception->throw(
1060             message => qq/'$class' does not inherit from Catalyst/ );
1061     }
1062
1063     if ( $class->arguments ) {
1064         @arguments = ( @arguments, @{ $class->arguments } );
1065     }
1066
1067     # Process options
1068     my $flags = {};
1069
1070     foreach (@arguments) {
1071
1072         if (/^-Debug$/) {
1073             $flags->{log} =
1074               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1075         }
1076         elsif (/^-(\w+)=?(.*)$/) {
1077             $flags->{ lc $1 } = $2;
1078         }
1079         else {
1080             push @{ $flags->{plugins} }, $_;
1081         }
1082     }
1083
1084     $class->setup_home( delete $flags->{home} );
1085
1086     $class->setup_log( delete $flags->{log} );
1087     $class->setup_plugins( delete $flags->{plugins} );
1088     $class->setup_dispatcher( delete $flags->{dispatcher} );
1089     if (my $engine = delete $flags->{engine}) {
1090         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1091     }
1092     $class->setup_engine();
1093     $class->setup_stats( delete $flags->{stats} );
1094
1095     for my $flag ( sort keys %{$flags} ) {
1096
1097         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1098             &$code( $class, delete $flags->{$flag} );
1099         }
1100         else {
1101             $class->log->warn(qq/Unknown flag "$flag"/);
1102         }
1103     }
1104
1105     eval { require Catalyst::Devel; };
1106     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1107         $class->log->warn(<<"EOF");
1108 You are running an old script!
1109
1110   Please update by running (this will overwrite existing files):
1111     catalyst.pl -force -scripts $class
1112
1113   or (this will not overwrite existing files):
1114     catalyst.pl -scripts $class
1115
1116 EOF
1117     }
1118
1119     if ( $class->debug ) {
1120         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1121
1122         if (@plugins) {
1123             my $column_width = Catalyst::Utils::term_width() - 6;
1124             my $t = Text::SimpleTable->new($column_width);
1125             $t->row($_) for @plugins;
1126             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1127         }
1128
1129         my $dispatcher = $class->dispatcher;
1130         my $engine     = $class->engine;
1131         my $home       = $class->config->{home};
1132
1133         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1134         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1135
1136         $home
1137           ? ( -d $home )
1138           ? $class->log->debug(qq/Found home "$home"/)
1139           : $class->log->debug(qq/Home "$home" doesn't exist/)
1140           : $class->log->debug(q/Couldn't find home/);
1141     }
1142
1143     # Call plugins setup, this is stupid and evil.
1144     # Also screws C3 badly on 5.10, hack to avoid.
1145     {
1146         no warnings qw/redefine/;
1147         local *setup = sub { };
1148         $class->setup unless $Catalyst::__AM_RESTARTING;
1149     }
1150
1151     # Initialize our data structure
1152     $class->components( {} );
1153
1154     $class->setup_components;
1155
1156     if ( $class->debug ) {
1157         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1158         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1159         for my $comp ( sort keys %{ $class->components } ) {
1160             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1161             $t->row( $comp, $type );
1162         }
1163         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1164           if ( keys %{ $class->components } );
1165     }
1166
1167     # Add our self to components, since we are also a component
1168     if( $class->isa('Catalyst::Controller') ){
1169       $class->components->{$class} = $class;
1170     }
1171
1172     $class->setup_actions;
1173
1174     if ( $class->debug ) {
1175         my $name = $class->config->{name} || 'Application';
1176         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1177     }
1178
1179     # Make sure that the application class becomes immutable at this point,
1180     B::Hooks::EndOfScope::on_scope_end {
1181         return if $@;
1182         my $meta = Class::MOP::get_metaclass_by_name($class);
1183         if (
1184             $meta->is_immutable
1185             && ! { $meta->immutable_options }->{replace_constructor}
1186             && (
1187                    $class->isa('Class::Accessor::Fast')
1188                 || $class->isa('Class::Accessor')
1189             )
1190         ) {
1191             warn "You made your application class ($class) immutable, "
1192                 . "but did not inline the\nconstructor. "
1193                 . "This will break catalyst, as your app \@ISA "
1194                 . "Class::Accessor(::Fast)?\nPlease pass "
1195                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1196         }
1197         $meta->make_immutable(
1198             replace_constructor => 1,
1199         ) unless $meta->is_immutable;
1200     };
1201
1202     if ($class->config->{case_sensitive}) {
1203         $class->log->warn($class . "->config->{case_sensitive} is set.");
1204         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1205     }
1206
1207     $class->setup_finalize;
1208     # Should be the last thing we do so that user things hooking
1209     # setup_finalize can log..
1210     $class->log->_flush() if $class->log->can('_flush');
1211     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1212 }
1213
1214 =head2 $app->setup_finalize
1215
1216 A hook to attach modifiers to. This method does not do anything except set the
1217 C<setup_finished> accessor.
1218
1219 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1220
1221 Example:
1222
1223     after setup_finalize => sub {
1224         my $app = shift;
1225
1226         ## do stuff here..
1227     };
1228
1229 =cut
1230
1231 sub setup_finalize {
1232     my ($class) = @_;
1233     $class->setup_finished(1);
1234 }
1235
1236 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1237
1238 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1239
1240 Constructs an absolute L<URI> object based on the application root, the
1241 provided path, and the additional arguments and query parameters provided.
1242 When used as a string, provides a textual URI.  If you need more flexibility
1243 than this (i.e. the option to provide relative URIs etc.) see
1244 L<Catalyst::Plugin::SmartURI>.
1245
1246 If no arguments are provided, the URI for the current action is returned.
1247 To return the current action and also provide @args, use
1248 C<< $c->uri_for( $c->action, @args ) >>.
1249
1250 If the first argument is a string, it is taken as a public URI path relative
1251 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1252 relative to the application root (if it does). It is then merged with
1253 C<< $c->request->base >>; any C<@args> are appended as additional path
1254 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1255
1256 If the first argument is a L<Catalyst::Action> it represents an action which
1257 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1258 optional C<\@captures> argument (an arrayref) allows passing the captured
1259 variables that are needed to fill in the paths of Chained and Regex actions;
1260 once the path is resolved, C<uri_for> continues as though a path was
1261 provided, appending any arguments or parameters and creating an absolute
1262 URI.
1263
1264 The captures for the current request can be found in
1265 C<< $c->request->captures >>, and actions can be resolved using
1266 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1267 path, use C<< $c->uri_for_action >> instead.
1268
1269   # Equivalent to $c->req->uri
1270   $c->uri_for($c->action, $c->req->captures,
1271       @{ $c->req->args }, $c->req->params);
1272
1273   # For the Foo action in the Bar controller
1274   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1275
1276   # Path to a static resource
1277   $c->uri_for('/static/images/logo.png');
1278
1279 =cut
1280
1281 sub uri_for {
1282     my ( $c, $path, @args ) = @_;
1283
1284     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1285         $path = $path->path_prefix;
1286         $path =~ s{/+\z}{};
1287         $path .= '/';
1288     }
1289
1290     undef($path) if (defined $path && $path eq '');
1291
1292     my $params =
1293       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1294
1295     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1296     foreach my $arg (@args) {
1297         utf8::encode($arg) if utf8::is_utf8($arg);
1298         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1299     }
1300
1301     if ( blessed($path) ) { # action object
1302         s|/|%2F|g for @args;
1303         my $captures = [ map { s|/|%2F|g; $_; }
1304                         ( scalar @args && ref $args[0] eq 'ARRAY'
1305                          ? @{ shift(@args) }
1306                          : ()) ];
1307
1308         foreach my $capture (@$captures) {
1309             utf8::encode($capture) if utf8::is_utf8($capture);
1310             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1311         }
1312
1313         my $action = $path;
1314         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1315         if( !@args && $action->number_of_args ) {
1316             my $expanded_action = $c->dispatcher->expand_action( $action );
1317
1318             my $num_captures = $expanded_action->number_of_captures;
1319             unshift @args, splice @$captures, $num_captures;
1320         }
1321
1322        $path = $c->dispatcher->uri_for_action($action, $captures);
1323         if (not defined $path) {
1324             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1325                 if $c->debug;
1326             return undef;
1327         }
1328         $path = '/' if $path eq '';
1329     }
1330
1331     unshift(@args, $path);
1332
1333     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1334         my $namespace = $c->namespace;
1335         if (defined $path) { # cheesy hack to handle path '../foo'
1336            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1337         }
1338         unshift(@args, $namespace || '');
1339     }
1340
1341     # join args with '/', or a blank string
1342     my $args = join('/', grep { defined($_) } @args);
1343     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1344     $args =~ s!^/+!!;
1345     my $base = $c->req->base;
1346     my $class = ref($base);
1347     $base =~ s{(?<!/)$}{/};
1348
1349     my $query = '';
1350
1351     if (my @keys = keys %$params) {
1352       # somewhat lifted from URI::_query's query_form
1353       $query = '?'.join('&', map {
1354           my $val = $params->{$_};
1355           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1356           s/ /+/g;
1357           my $key = $_;
1358           $val = '' unless defined $val;
1359           (map {
1360               my $param = "$_";
1361               utf8::encode( $param ) if utf8::is_utf8($param);
1362               # using the URI::Escape pattern here so utf8 chars survive
1363               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1364               $param =~ s/ /+/g;
1365               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1366       } @keys);
1367     }
1368
1369     my $res = bless(\"${base}${args}${query}", $class);
1370     $res;
1371 }
1372
1373 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1374
1375 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1376
1377 =over
1378
1379 =item $path
1380
1381 A private path to the Catalyst action you want to create a URI for.
1382
1383 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1384 >> and passing the resulting C<$action> and the remaining arguments to C<<
1385 $c->uri_for >>.
1386
1387 You can also pass in a Catalyst::Action object, in which case it is passed to
1388 C<< $c->uri_for >>.
1389
1390 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1391
1392 For example, if the action looks like:
1393
1394  package MyApp::Controller::Users;
1395
1396  sub lst : Path('the-list') {}
1397
1398 You can use:
1399
1400  $c->uri_for_action('/users/lst')
1401
1402 and it will create the URI /users/the-list.
1403
1404 =item \@captures_and_args?
1405
1406 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1407 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1408 to interpolate all the parameters in the URI.
1409
1410 =item @args?
1411
1412 Optional list of extra arguments - can be supplied in the
1413 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1414 code.
1415
1416 Your action can have zero, a fixed or a variable number of args (e.g.
1417 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1418
1419 =item \%query_values?
1420
1421 Optional array reference of query parameters to append. E.g.
1422
1423   { foo => 'bar' }
1424
1425 will generate
1426
1427   /rest/of/your/uri?foo=bar
1428
1429 =back
1430
1431 =cut
1432
1433 sub uri_for_action {
1434     my ( $c, $path, @args ) = @_;
1435     my $action = blessed($path)
1436       ? $path
1437       : $c->dispatcher->get_action_by_path($path);
1438     unless (defined $action) {
1439       croak "Can't find action for path '$path'";
1440     }
1441     return $c->uri_for( $action, @args );
1442 }
1443
1444 =head2 $c->welcome_message
1445
1446 Returns the Catalyst welcome HTML page.
1447
1448 =cut
1449
1450 sub welcome_message {
1451     my $c      = shift;
1452     my $name   = $c->config->{name};
1453     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1454     my $prefix = Catalyst::Utils::appprefix( ref $c );
1455     $c->response->content_type('text/html; charset=utf-8');
1456     return <<"EOF";
1457 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1458     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1459 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1460     <head>
1461     <meta http-equiv="Content-Language" content="en" />
1462     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1463         <title>$name on Catalyst $VERSION</title>
1464         <style type="text/css">
1465             body {
1466                 color: #000;
1467                 background-color: #eee;
1468             }
1469             div#content {
1470                 width: 640px;
1471                 margin-left: auto;
1472                 margin-right: auto;
1473                 margin-top: 10px;
1474                 margin-bottom: 10px;
1475                 text-align: left;
1476                 background-color: #ccc;
1477                 border: 1px solid #aaa;
1478             }
1479             p, h1, h2 {
1480                 margin-left: 20px;
1481                 margin-right: 20px;
1482                 font-family: verdana, tahoma, sans-serif;
1483             }
1484             a {
1485                 font-family: verdana, tahoma, sans-serif;
1486             }
1487             :link, :visited {
1488                     text-decoration: none;
1489                     color: #b00;
1490                     border-bottom: 1px dotted #bbb;
1491             }
1492             :link:hover, :visited:hover {
1493                     color: #555;
1494             }
1495             div#topbar {
1496                 margin: 0px;
1497             }
1498             pre {
1499                 margin: 10px;
1500                 padding: 8px;
1501             }
1502             div#answers {
1503                 padding: 8px;
1504                 margin: 10px;
1505                 background-color: #fff;
1506                 border: 1px solid #aaa;
1507             }
1508             h1 {
1509                 font-size: 0.9em;
1510                 font-weight: normal;
1511                 text-align: center;
1512             }
1513             h2 {
1514                 font-size: 1.0em;
1515             }
1516             p {
1517                 font-size: 0.9em;
1518             }
1519             p img {
1520                 float: right;
1521                 margin-left: 10px;
1522             }
1523             span#appname {
1524                 font-weight: bold;
1525                 font-size: 1.6em;
1526             }
1527         </style>
1528     </head>
1529     <body>
1530         <div id="content">
1531             <div id="topbar">
1532                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1533                     $VERSION</h1>
1534              </div>
1535              <div id="answers">
1536                  <p>
1537                  <img src="$logo" alt="Catalyst Logo" />
1538                  </p>
1539                  <p>Welcome to the  world of Catalyst.
1540                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1541                     framework will make web development something you had
1542                     never expected it to be: Fun, rewarding, and quick.</p>
1543                  <h2>What to do now?</h2>
1544                  <p>That really depends  on what <b>you</b> want to do.
1545                     We do, however, provide you with a few starting points.</p>
1546                  <p>If you want to jump right into web development with Catalyst
1547                     you might want to start with a tutorial.</p>
1548 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1549 </pre>
1550 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1551 <pre>
1552 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1553 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1554 </code></pre>
1555                  <h2>What to do next?</h2>
1556                  <p>Next it's time to write an actual application. Use the
1557                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1558                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1559                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1560                     they can save you a lot of work.</p>
1561                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1562                     <p>Also, be sure to check out the vast and growing
1563                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1564                     you are likely to find what you need there.
1565                     </p>
1566
1567                  <h2>Need help?</h2>
1568                  <p>Catalyst has a very active community. Here are the main places to
1569                     get in touch with us.</p>
1570                  <ul>
1571                      <li>
1572                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1573                      </li>
1574                      <li>
1575                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1576                      </li>
1577                      <li>
1578                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1579                      </li>
1580                  </ul>
1581                  <h2>In conclusion</h2>
1582                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1583                     as we enjoyed making it. Please contact us if you have ideas
1584                     for improvement or other feedback.</p>
1585              </div>
1586          </div>
1587     </body>
1588 </html>
1589 EOF
1590 }
1591
1592 =head2 run_options
1593
1594 Contains a hash of options passed from the application script, including
1595 the original ARGV the script received, the processed values from that
1596 ARGV and any extra arguments to the script which were not processed.
1597
1598 This can be used to add custom options to your application's scripts
1599 and setup your application differently depending on the values of these
1600 options.
1601
1602 =head1 INTERNAL METHODS
1603
1604 These methods are not meant to be used by end users.
1605
1606 =head2 $c->components
1607
1608 Returns a hash of components.
1609
1610 =head2 $c->context_class
1611
1612 Returns or sets the context class.
1613
1614 =head2 $c->counter
1615
1616 Returns a hashref containing coderefs and execution counts (needed for
1617 deep recursion detection).
1618
1619 =head2 $c->depth
1620
1621 Returns the number of actions on the current internal execution stack.
1622
1623 =head2 $c->dispatch
1624
1625 Dispatches a request to actions.
1626
1627 =cut
1628
1629 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1630
1631 =head2 $c->dispatcher_class
1632
1633 Returns or sets the dispatcher class.
1634
1635 =head2 $c->dump_these
1636
1637 Returns a list of 2-element array references (name, structure) pairs
1638 that will be dumped on the error page in debug mode.
1639
1640 =cut
1641
1642 sub dump_these {
1643     my $c = shift;
1644     [ Request => $c->req ],
1645     [ Response => $c->res ],
1646     [ Stash => $c->stash ],
1647     [ Config => $c->config ];
1648 }
1649
1650 =head2 $c->engine_class
1651
1652 Returns or sets the engine class.
1653
1654 =head2 $c->execute( $class, $coderef )
1655
1656 Execute a coderef in given class and catch exceptions. Errors are available
1657 via $c->error.
1658
1659 =cut
1660
1661 sub execute {
1662     my ( $c, $class, $code ) = @_;
1663     $class = $c->component($class) || $class;
1664     $c->state(0);
1665
1666     if ( $c->depth >= $RECURSION ) {
1667         my $action = $code->reverse();
1668         $action = "/$action" unless $action =~ /->/;
1669         my $error = qq/Deep recursion detected calling "${action}"/;
1670         $c->log->error($error);
1671         $c->error($error);
1672         $c->state(0);
1673         return $c->state;
1674     }
1675
1676     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1677
1678     push( @{ $c->stack }, $code );
1679
1680     no warnings 'recursion';
1681     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1682     #      I have no idea how, ergo $ret (which appears to fix the issue)
1683     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1684
1685     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1686
1687     my $last = pop( @{ $c->stack } );
1688
1689     if ( my $error = $@ ) {
1690         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1691             $error->rethrow if $c->depth > 1;
1692         }
1693         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1694             $error->rethrow if $c->depth > 0;
1695         }
1696         else {
1697             unless ( ref $error ) {
1698                 no warnings 'uninitialized';
1699                 chomp $error;
1700                 my $class = $last->class;
1701                 my $name  = $last->name;
1702                 $error = qq/Caught exception in $class->$name "$error"/;
1703             }
1704             $c->error($error);
1705         }
1706         $c->state(0);
1707     }
1708     return $c->state;
1709 }
1710
1711 sub _stats_start_execute {
1712     my ( $c, $code ) = @_;
1713     my $appclass = ref($c) || $c;
1714     return if ( ( $code->name =~ /^_.*/ )
1715         && ( !$appclass->config->{show_internal_actions} ) );
1716
1717     my $action_name = $code->reverse();
1718     $c->counter->{$action_name}++;
1719
1720     my $action = $action_name;
1721     $action = "/$action" unless $action =~ /->/;
1722
1723     # determine if the call was the result of a forward
1724     # this is done by walking up the call stack and looking for a calling
1725     # sub of Catalyst::forward before the eval
1726     my $callsub = q{};
1727     for my $index ( 2 .. 11 ) {
1728         last
1729         if ( ( caller($index) )[0] eq 'Catalyst'
1730             && ( caller($index) )[3] eq '(eval)' );
1731
1732         if ( ( caller($index) )[3] =~ /forward$/ ) {
1733             $callsub = ( caller($index) )[3];
1734             $action  = "-> $action";
1735             last;
1736         }
1737     }
1738
1739     my $uid = $action_name . $c->counter->{$action_name};
1740
1741     # is this a root-level call or a forwarded call?
1742     if ( $callsub =~ /forward$/ ) {
1743         my $parent = $c->stack->[-1];
1744
1745         # forward, locate the caller
1746         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1747             $c->stats->profile(
1748                 begin  => $action,
1749                 parent => "$parent" . $c->counter->{"$parent"},
1750                 uid    => $uid,
1751             );
1752         }
1753         else {
1754
1755             # forward with no caller may come from a plugin
1756             $c->stats->profile(
1757                 begin => $action,
1758                 uid   => $uid,
1759             );
1760         }
1761     }
1762     else {
1763
1764         # root-level call
1765         $c->stats->profile(
1766             begin => $action,
1767             uid   => $uid,
1768         );
1769     }
1770     return $action;
1771
1772 }
1773
1774 sub _stats_finish_execute {
1775     my ( $c, $info ) = @_;
1776     $c->stats->profile( end => $info );
1777 }
1778
1779 =head2 $c->finalize
1780
1781 Finalizes the request.
1782
1783 =cut
1784
1785 sub finalize {
1786     my $c = shift;
1787
1788     for my $error ( @{ $c->error } ) {
1789         $c->log->error($error);
1790     }
1791
1792     # Allow engine to handle finalize flow (for POE)
1793     my $engine = $c->engine;
1794     if ( my $code = $engine->can('finalize') ) {
1795         $engine->$code($c);
1796     }
1797     else {
1798
1799         $c->finalize_uploads;
1800
1801         # Error
1802         if ( $#{ $c->error } >= 0 ) {
1803             $c->finalize_error;
1804         }
1805
1806         $c->finalize_headers;
1807
1808         # HEAD request
1809         if ( $c->request->method eq 'HEAD' ) {
1810             $c->response->body('');
1811         }
1812
1813         $c->finalize_body;
1814     }
1815
1816     $c->log_response;
1817
1818     if ($c->use_stats) {
1819         my $elapsed = sprintf '%f', $c->stats->elapsed;
1820         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1821         $c->log->info(
1822             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1823     }
1824
1825     return $c->response->status;
1826 }
1827
1828 =head2 $c->finalize_body
1829
1830 Finalizes body.
1831
1832 =cut
1833
1834 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1835
1836 =head2 $c->finalize_cookies
1837
1838 Finalizes cookies.
1839
1840 =cut
1841
1842 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1843
1844 =head2 $c->finalize_error
1845
1846 Finalizes error.
1847
1848 =cut
1849
1850 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1851
1852 =head2 $c->finalize_headers
1853
1854 Finalizes headers.
1855
1856 =cut
1857
1858 sub finalize_headers {
1859     my $c = shift;
1860
1861     my $response = $c->response; #accessor calls can add up?
1862
1863     # Check if we already finalized headers
1864     return if $response->finalized_headers;
1865
1866     # Handle redirects
1867     if ( my $location = $response->redirect ) {
1868         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1869         $response->header( Location => $location );
1870
1871         if ( !$response->has_body ) {
1872             # Add a default body if none is already present
1873             $response->body(<<"EOF");
1874 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1875 <html xmlns="http://www.w3.org/1999/xhtml"> 
1876   <head>
1877     <title>Moved</title>
1878   </head>
1879   <body>
1880      <p>This item has moved <a href="$location">here</a>.</p>
1881   </body>
1882 </html>
1883 EOF
1884             $response->content_type('text/html; charset=utf-8');
1885         }
1886     }
1887
1888     # Content-Length
1889     if ( defined $response->body && length $response->body && !$response->content_length ) {
1890
1891         # get the length from a filehandle
1892         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1893         {
1894             my $size = -s $response->body;
1895             if ( $size ) {
1896                 $response->content_length( $size );
1897             }
1898             else {
1899                 $c->log->warn('Serving filehandle without a content-length');
1900             }
1901         }
1902         else {
1903             # everything should be bytes at this point, but just in case
1904             $response->content_length( length( $response->body ) );
1905         }
1906     }
1907
1908     # Errors
1909     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1910         $response->headers->remove_header("Content-Length");
1911         $response->body('');
1912     }
1913
1914     $c->finalize_cookies;
1915
1916     $c->engine->finalize_headers( $c, @_ );
1917
1918     # Done
1919     $response->finalized_headers(1);
1920 }
1921
1922 =head2 $c->finalize_output
1923
1924 An alias for finalize_body.
1925
1926 =head2 $c->finalize_read
1927
1928 Finalizes the input after reading is complete.
1929
1930 =cut
1931
1932 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1933
1934 =head2 $c->finalize_uploads
1935
1936 Finalizes uploads. Cleans up any temporary files.
1937
1938 =cut
1939
1940 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1941
1942 =head2 $c->get_action( $action, $namespace )
1943
1944 Gets an action in a given namespace.
1945
1946 =cut
1947
1948 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1949
1950 =head2 $c->get_actions( $action, $namespace )
1951
1952 Gets all actions of a given name in a namespace and all parent
1953 namespaces.
1954
1955 =cut
1956
1957 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1958
1959 =head2 $app->handle_request( @arguments )
1960
1961 Called to handle each HTTP request.
1962
1963 =cut
1964
1965 sub handle_request {
1966     my ( $class, @arguments ) = @_;
1967
1968     # Always expect worst case!
1969     my $status = -1;
1970     try {
1971         if ($class->debug) {
1972             my $secs = time - $START || 1;
1973             my $av = sprintf '%.3f', $COUNT / $secs;
1974             my $time = localtime time;
1975             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1976         }
1977
1978         my $c = $class->prepare(@arguments);
1979         $c->dispatch;
1980         $status = $c->finalize;
1981     }
1982     catch {
1983         chomp(my $error = $_);
1984         $class->log->error(qq/Caught exception in engine "$error"/);
1985     };
1986
1987     $COUNT++;
1988
1989     if(my $coderef = $class->log->can('_flush')){
1990         $class->log->$coderef();
1991     }
1992     return $status;
1993 }
1994
1995 =head2 $class->prepare( @arguments )
1996
1997 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1998 etc.).
1999
2000 =cut
2001
2002 has _uploadtmp => (
2003     is => 'ro',
2004     predicate => '_has_uploadtmp',
2005 );
2006
2007 sub prepare {
2008     my ( $class, @arguments ) = @_;
2009
2010     # XXX
2011     # After the app/ctxt split, this should become an attribute based on something passed
2012     # into the application.
2013     $class->context_class( ref $class || $class ) unless $class->context_class;
2014
2015     my $uploadtmp = $class->config->{uploadtmp};
2016     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2017
2018     #surely this is not the most efficient way to do things...
2019     $c->stats($class->stats_class->new)->enable($c->use_stats);
2020     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2021         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2022     }
2023
2024     try {
2025         # Allow engine to direct the prepare flow (for POE)
2026         if ( my $prepare = $c->engine->can('prepare') ) {
2027             $c->engine->$prepare( $c, @arguments );
2028         }
2029         else {
2030             $c->prepare_request(@arguments);
2031             $c->prepare_connection;
2032             $c->prepare_query_parameters;
2033             $c->prepare_headers; # Just hooks, no longer needed - they just
2034             $c->prepare_cookies; # cause the lazy attribute on req to build
2035             $c->prepare_path;
2036
2037             # Prepare the body for reading, either by prepare_body
2038             # or the user, if they are using $c->read
2039             $c->prepare_read;
2040
2041             # Parse the body unless the user wants it on-demand
2042             unless ( ref($c)->config->{parse_on_demand} ) {
2043                 $c->prepare_body;
2044             }
2045         }
2046     }
2047     # VERY ugly and probably shouldn't rely on ->finalize actually working
2048     catch {
2049         # failed prepare is always due to an invalid request, right?
2050         $c->response->status(400);
2051         $c->response->content_type('text/plain');
2052         $c->response->body('Bad Request');
2053         $c->finalize;
2054         die $_;
2055     };
2056
2057     my $method  = $c->req->method  || '';
2058     my $path    = $c->req->path;
2059     $path       = '/' unless length $path;
2060     my $address = $c->req->address || '';
2061
2062     $c->log_request;
2063
2064     $c->prepare_action;
2065
2066     return $c;
2067 }
2068
2069 =head2 $c->prepare_action
2070
2071 Prepares action. See L<Catalyst::Dispatcher>.
2072
2073 =cut
2074
2075 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2076
2077 =head2 $c->prepare_body
2078
2079 Prepares message body.
2080
2081 =cut
2082
2083 sub prepare_body {
2084     my $c = shift;
2085
2086     return if $c->request->_has_body;
2087
2088     # Initialize on-demand data
2089     $c->engine->prepare_body( $c, @_ );
2090     $c->prepare_parameters;
2091     $c->prepare_uploads;
2092 }
2093
2094 =head2 $c->prepare_body_chunk( $chunk )
2095
2096 Prepares a chunk of data before sending it to L<HTTP::Body>.
2097
2098 See L<Catalyst::Engine>.
2099
2100 =cut
2101
2102 sub prepare_body_chunk {
2103     my $c = shift;
2104     $c->engine->prepare_body_chunk( $c, @_ );
2105 }
2106
2107 =head2 $c->prepare_body_parameters
2108
2109 Prepares body parameters.
2110
2111 =cut
2112
2113 sub prepare_body_parameters {
2114     my $c = shift;
2115     $c->engine->prepare_body_parameters( $c, @_ );
2116 }
2117
2118 =head2 $c->prepare_connection
2119
2120 Prepares connection.
2121
2122 =cut
2123
2124 sub prepare_connection {
2125     my $c = shift;
2126     # XXX - This is called on the engine (not the request) to maintain
2127     #       Engine::PSGI back compat.
2128     $c->engine->prepare_connection($c);
2129 }
2130
2131 =head2 $c->prepare_cookies
2132
2133 Prepares cookies by ensuring that the attribute on the request
2134 object has been built.
2135
2136 =cut
2137
2138 sub prepare_cookies { my $c = shift; $c->request->cookies }
2139
2140 =head2 $c->prepare_headers
2141
2142 Prepares request headers by ensuring that the attribute on the request
2143 object has been built.
2144
2145 =cut
2146
2147 sub prepare_headers { my $c = shift; $c->request->headers }
2148
2149 =head2 $c->prepare_parameters
2150
2151 Prepares parameters.
2152
2153 =cut
2154
2155 sub prepare_parameters {
2156     my $c = shift;
2157     $c->prepare_body_parameters;
2158     $c->engine->prepare_parameters( $c, @_ );
2159 }
2160
2161 =head2 $c->prepare_path
2162
2163 Prepares path and base.
2164
2165 =cut
2166
2167 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2168
2169 =head2 $c->prepare_query_parameters
2170
2171 Prepares query parameters.
2172
2173 =cut
2174
2175 sub prepare_query_parameters {
2176     my $c = shift;
2177
2178     $c->engine->prepare_query_parameters( $c, @_ );
2179 }
2180
2181 =head2 $c->log_request
2182
2183 Writes information about the request to the debug logs.  This includes:
2184
2185 =over 4
2186
2187 =item * Request method, path, and remote IP address
2188
2189 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2190
2191 =item * Request parameters
2192
2193 =item * File uploads
2194
2195 =back
2196
2197 =cut
2198
2199 sub log_request {
2200     my $c = shift;
2201
2202     return unless $c->debug;
2203
2204     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2205     my $request = $dump->[1];
2206
2207     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2208     $method ||= '';
2209     $path = '/' unless length $path;
2210     $address ||= '';
2211     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2212
2213     $c->log_request_headers($request->headers);
2214
2215     if ( my $keywords = $request->query_keywords ) {
2216         $c->log->debug("Query keywords are: $keywords");
2217     }
2218
2219     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2220
2221     $c->log_request_uploads($request);
2222 }
2223
2224 =head2 $c->log_response
2225
2226 Writes information about the response to the debug logs by calling
2227 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2228
2229 =cut
2230
2231 sub log_response {
2232     my $c = shift;
2233
2234     return unless $c->debug;
2235
2236     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2237     my $response = $dump->[1];
2238
2239     $c->log_response_status_line($response);
2240     $c->log_response_headers($response->headers);
2241 }
2242
2243 =head2 $c->log_response_status_line($response)
2244
2245 Writes one line of information about the response to the debug logs.  This includes:
2246
2247 =over 4
2248
2249 =item * Response status code
2250
2251 =item * Content-Type header (if present)
2252
2253 =item * Content-Length header (if present)
2254
2255 =back
2256
2257 =cut
2258
2259 sub log_response_status_line {
2260     my ($c, $response) = @_;
2261
2262     $c->log->debug(
2263         sprintf(
2264             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2265             $response->status                            || 'unknown',
2266             $response->headers->header('Content-Type')   || 'unknown',
2267             $response->headers->header('Content-Length') || 'unknown'
2268         )
2269     );
2270 }
2271
2272 =head2 $c->log_response_headers($headers);
2273
2274 Hook method which can be wrapped by plugins to log the response headers.
2275 No-op in the default implementation.
2276
2277 =cut
2278
2279 sub log_response_headers {}
2280
2281 =head2 $c->log_request_parameters( query => {}, body => {} )
2282
2283 Logs request parameters to debug logs
2284
2285 =cut
2286
2287 sub log_request_parameters {
2288     my $c          = shift;
2289     my %all_params = @_;
2290
2291     return unless $c->debug;
2292
2293     my $column_width = Catalyst::Utils::term_width() - 44;
2294     foreach my $type (qw(query body)) {
2295         my $params = $all_params{$type};
2296         next if ! keys %$params;
2297         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2298         for my $key ( sort keys %$params ) {
2299             my $param = $params->{$key};
2300             my $value = defined($param) ? $param : '';
2301             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2302         }
2303         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2304     }
2305 }
2306
2307 =head2 $c->log_request_uploads
2308
2309 Logs file uploads included in the request to the debug logs.
2310 The parameter name, filename, file type, and file size are all included in
2311 the debug logs.
2312
2313 =cut
2314
2315 sub log_request_uploads {
2316     my $c = shift;
2317     my $request = shift;
2318     return unless $c->debug;
2319     my $uploads = $request->uploads;
2320     if ( keys %$uploads ) {
2321         my $t = Text::SimpleTable->new(
2322             [ 12, 'Parameter' ],
2323             [ 26, 'Filename' ],
2324             [ 18, 'Type' ],
2325             [ 9,  'Size' ]
2326         );
2327         for my $key ( sort keys %$uploads ) {
2328             my $upload = $uploads->{$key};
2329             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2330                 $t->row( $key, $u->filename, $u->type, $u->size );
2331             }
2332         }
2333         $c->log->debug( "File Uploads are:\n" . $t->draw );
2334     }
2335 }
2336
2337 =head2 $c->log_request_headers($headers);
2338
2339 Hook method which can be wrapped by plugins to log the request headers.
2340 No-op in the default implementation.
2341
2342 =cut
2343
2344 sub log_request_headers {}
2345
2346 =head2 $c->log_headers($type => $headers)
2347
2348 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2349
2350 =cut
2351
2352 sub log_headers {
2353     my $c       = shift;
2354     my $type    = shift;
2355     my $headers = shift;    # an HTTP::Headers instance
2356
2357     return unless $c->debug;
2358
2359     my $column_width = Catalyst::Utils::term_width() - 28;
2360     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2361     $headers->scan(
2362         sub {
2363             my ( $name, $value ) = @_;
2364             $t->row( $name, $value );
2365         }
2366     );
2367     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2368 }
2369
2370
2371 =head2 $c->prepare_read
2372
2373 Prepares the input for reading.
2374
2375 =cut
2376
2377 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2378
2379 =head2 $c->prepare_request
2380
2381 Prepares the engine request.
2382
2383 =cut
2384
2385 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2386
2387 =head2 $c->prepare_uploads
2388
2389 Prepares uploads.
2390
2391 =cut
2392
2393 sub prepare_uploads {
2394     my $c = shift;
2395
2396     $c->engine->prepare_uploads( $c, @_ );
2397 }
2398
2399 =head2 $c->prepare_write
2400
2401 Prepares the output for writing.
2402
2403 =cut
2404
2405 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2406
2407 =head2 $c->request_class
2408
2409 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2410
2411 =head2 $c->response_class
2412
2413 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2414
2415 =head2 $c->read( [$maxlength] )
2416
2417 Reads a chunk of data from the request body. This method is designed to
2418 be used in a while loop, reading C<$maxlength> bytes on every call.
2419 C<$maxlength> defaults to the size of the request if not specified.
2420
2421 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2422 directly.
2423
2424 Warning: If you use read(), Catalyst will not process the body,
2425 so you will not be able to access POST parameters or file uploads via
2426 $c->request.  You must handle all body parsing yourself.
2427
2428 =cut
2429
2430 sub read { my $c = shift; return $c->request->read( @_ ) }
2431
2432 =head2 $c->run
2433
2434 Starts the engine.
2435
2436 =cut
2437
2438 sub run {
2439   my $app = shift;
2440   $app->engine_loader->needs_psgi_engine_compat_hack ?
2441     $app->engine->run($app, @_) :
2442       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2443 }
2444
2445 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2446
2447 Sets an action in a given namespace.
2448
2449 =cut
2450
2451 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2452
2453 =head2 $c->setup_actions($component)
2454
2455 Sets up actions for a component.
2456
2457 =cut
2458
2459 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2460
2461 =head2 $c->setup_components
2462
2463 This method is called internally to set up the application's components.
2464
2465 It finds modules by calling the L<locate_components> method, expands them to
2466 package names with the L<expand_component_module> method, and then installs
2467 each component into the application.
2468
2469 The C<setup_components> config option is passed to both of the above methods.
2470
2471 Installation of each component is performed by the L<setup_component> method,
2472 below.
2473
2474 =cut
2475
2476 sub setup_components {
2477     my $class = shift;
2478
2479     my $config  = $class->config->{ setup_components };
2480
2481     my @comps = $class->locate_components($config);
2482     my %comps = map { $_ => 1 } @comps;
2483
2484     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2485     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2486         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2487     ) if $deprecatedcatalyst_component_names;
2488
2489     for my $component ( @comps ) {
2490
2491         # We pass ignore_loaded here so that overlay files for (e.g.)
2492         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2493         # we know M::P::O found a file on disk so this is safe
2494
2495         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2496     }
2497
2498     for my $component (@comps) {
2499         my $instance = $class->components->{ $component } = $class->setup_component($component);
2500         my @expanded_components = $instance->can('expand_modules')
2501             ? $instance->expand_modules( $component, $config )
2502             : $class->expand_component_module( $component, $config );
2503         for my $component (@expanded_components) {
2504             next if $comps{$component};
2505             $class->components->{ $component } = $class->setup_component($component);
2506         }
2507     }
2508 }
2509
2510 =head2 $c->locate_components( $setup_component_config )
2511
2512 This method is meant to provide a list of component modules that should be
2513 setup for the application.  By default, it will use L<Module::Pluggable>.
2514
2515 Specify a C<setup_components> config option to pass additional options directly
2516 to L<Module::Pluggable>. To add additional search paths, specify a key named
2517 C<search_extra> as an array reference. Items in the array beginning with C<::>
2518 will have the application class name prepended to them.
2519
2520 =cut
2521
2522 sub locate_components {
2523     my $class  = shift;
2524     my $config = shift;
2525
2526     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2527     my $extra   = delete $config->{ search_extra } || [];
2528
2529     push @paths, @$extra;
2530
2531     my $locator = Module::Pluggable::Object->new(
2532         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2533         %$config
2534     );
2535
2536     # XXX think about ditching this sort entirely
2537     my @comps = sort { length $a <=> length $b } $locator->plugins;
2538
2539     return @comps;
2540 }
2541
2542 =head2 $c->expand_component_module( $component, $setup_component_config )
2543
2544 Components found by C<locate_components> will be passed to this method, which
2545 is expected to return a list of component (package) names to be set up.
2546
2547 =cut
2548
2549 sub expand_component_module {
2550     my ($class, $module) = @_;
2551     return Devel::InnerPackage::list_packages( $module );
2552 }
2553
2554 =head2 $c->setup_component
2555
2556 =cut
2557
2558 sub setup_component {
2559     my( $class, $component ) = @_;
2560
2561     unless ( $component->can( 'COMPONENT' ) ) {
2562         return $component;
2563     }
2564
2565     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2566     my $config = $class->config->{ $suffix } || {};
2567     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2568     # methods also pass it. local to avoid pointlessly shitting in config
2569     # for the debug screen, as $component is already the key name.
2570     local $config->{catalyst_component_name} = $component;
2571
2572     my $instance = eval { $component->COMPONENT( $class, $config ); };
2573
2574     if ( my $error = $@ ) {
2575         chomp $error;
2576         Catalyst::Exception->throw(
2577             message => qq/Couldn't instantiate component "$component", "$error"/
2578         );
2579     }
2580
2581     unless (blessed $instance) {
2582         my $metaclass = Moose::Util::find_meta($component);
2583         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2584         my $component_method_from = $method_meta->associated_metaclass->name;
2585         my $value = defined($instance) ? $instance : 'undef';
2586         Catalyst::Exception->throw(
2587             message =>
2588             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2589         );
2590     }
2591     return $instance;
2592 }
2593
2594 =head2 $c->setup_dispatcher
2595
2596 Sets up dispatcher.
2597
2598 =cut
2599
2600 sub setup_dispatcher {
2601     my ( $class, $dispatcher ) = @_;
2602
2603     if ($dispatcher) {
2604         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2605     }
2606
2607     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2608         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2609     }
2610
2611     unless ($dispatcher) {
2612         $dispatcher = $class->dispatcher_class;
2613     }
2614
2615     Class::MOP::load_class($dispatcher);
2616
2617     # dispatcher instance
2618     $class->dispatcher( $dispatcher->new );
2619 }
2620
2621 =head2 $c->setup_engine
2622
2623 Sets up engine.
2624
2625 =cut
2626
2627 sub engine_class {
2628     my ($class, $requested_engine) = @_;
2629
2630     if (!$class->engine_loader || $requested_engine) {
2631         $class->engine_loader(
2632             Catalyst::EngineLoader->new({
2633                 application_name => $class,
2634                 (defined $requested_engine
2635                      ? (catalyst_engine_class => $requested_engine) : ()),
2636             }),
2637         );
2638     }
2639
2640     $class->engine_loader->catalyst_engine_class;
2641 }
2642
2643 sub setup_engine {
2644     my ($class, $requested_engine) = @_;
2645
2646     my $engine = do {
2647         my $loader = $class->engine_loader;
2648
2649         if (!$loader || $requested_engine) {
2650             $loader = Catalyst::EngineLoader->new({
2651                 application_name => $class,
2652                 (defined $requested_engine
2653                      ? (requested_engine => $requested_engine) : ()),
2654             }),
2655
2656             $class->engine_loader($loader);
2657         }
2658
2659         $loader->catalyst_engine_class;
2660     };
2661
2662     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2663     return if $class->loading_psgi_file;
2664
2665     Class::MOP::load_class($engine);
2666
2667     if ($ENV{MOD_PERL}) {
2668         my $apache = $class->engine_loader->auto;
2669
2670         my $meta = find_meta($class);
2671         my $was_immutable = $meta->is_immutable;
2672         my %immutable_options = $meta->immutable_options;
2673         $meta->make_mutable if $was_immutable;
2674
2675         $meta->add_method(handler => sub {
2676             my $r = shift;
2677             my $psgi_app = $class->_finalized_psgi_app;
2678             $apache->call_app($r, $psgi_app);
2679         });
2680
2681         $meta->make_immutable(%immutable_options) if $was_immutable;
2682     }
2683
2684     $class->engine( $engine->new );
2685
2686     return;
2687 }
2688
2689 sub _finalized_psgi_app {
2690     my ($app) = @_;
2691
2692     unless ($app->_psgi_app) {
2693         my $psgi_app = $app->_setup_psgi_app;
2694         $app->_psgi_app($psgi_app);
2695     }
2696
2697     return $app->_psgi_app;
2698 }
2699
2700 sub _setup_psgi_app {
2701     my ($app) = @_;
2702
2703     for my $home (Path::Class::Dir->new($app->config->{home})) {
2704         my $psgi_file = $home->file(
2705             Catalyst::Utils::appprefix($app) . '.psgi',
2706         );
2707
2708         next unless -e $psgi_file;
2709
2710         # If $psgi_file calls ->setup_engine, it's doing so to load
2711         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2712         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2713         # anyway. So set a flag (ick) that tells setup_engine not to populate
2714         # $c->engine or do any other things we might regret.
2715
2716         $app->loading_psgi_file(1);
2717         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2718         $app->loading_psgi_file(0);
2719
2720         return $psgi_app
2721             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2722
2723         warn <<"EOW";
2724 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2725
2726 Its content has been ignored. Please consult the Catalyst::Upgrading
2727 documentation on how to upgrade from Catalyst::Engine::PSGI.
2728 EOW
2729     }
2730
2731     return $app->apply_default_middlewares($app->psgi_app);
2732 }
2733
2734 =head2 $c->apply_default_middlewares
2735
2736 Adds the following L<Plack> middlewares to your application, since they are
2737 useful and commonly needed:
2738
2739 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2740 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2741 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2742 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2743 applied since this middleware is smart enough to conditionally apply itself).
2744
2745 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2746 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2747 $ENV{SCRIPT_NAME}
2748
2749 =cut
2750
2751
2752 sub apply_default_middlewares {
2753     my ($app, $psgi_app) = @_;
2754
2755     $psgi_app = Plack::Middleware::Conditional->wrap(
2756         $psgi_app,
2757         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2758         condition => sub {
2759             my ($env) = @_;
2760             return if $app->config->{ignore_frontend_proxy};
2761             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2762                 || $app->config->{using_frontend_proxy};
2763         },
2764     );
2765
2766     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2767     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2768     $psgi_app = Plack::Middleware::LighttpdScriptNameFix->wrap($psgi_app);
2769
2770     # we're applying this unconditionally as the middleware itself already makes
2771     # sure it doesn't fuck things up if it's not running under one of the right
2772     # IIS versions
2773     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2774
2775     return $psgi_app;
2776 }
2777
2778 =head2 $c->psgi_app
2779
2780 Returns a PSGI application code reference for the catalyst application
2781 C<$c>. This is the bare application without any middlewares
2782 applied. C<${myapp}.psgi> is not taken into account.
2783
2784 This is what you want to be using to retrieve the PSGI application code
2785 reference of your Catalyst application for use in F<.psgi> files.
2786
2787 =cut
2788
2789 sub psgi_app {
2790     my ($app) = @_;
2791     return $app->engine->build_psgi_app($app);
2792 }
2793
2794 =head2 $c->setup_home
2795
2796 Sets up the home directory.
2797
2798 =cut
2799
2800 sub setup_home {
2801     my ( $class, $home ) = @_;
2802
2803     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2804         $home = $env;
2805     }
2806
2807     $home ||= Catalyst::Utils::home($class);
2808
2809     if ($home) {
2810         #I remember recently being scolded for assigning config values like this
2811         $class->config->{home} ||= $home;
2812         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2813     }
2814 }
2815
2816 =head2 $c->setup_log
2817
2818 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2819 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2820 log to.
2821
2822 This method also installs a C<debug> method that returns a true value into the
2823 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2824 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2825
2826 Note that if the log has already been setup, by either a previous call to
2827 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2828 that this method won't actually set up the log object.
2829
2830 =cut
2831
2832 sub setup_log {
2833     my ( $class, $levels ) = @_;
2834
2835     $levels ||= '';
2836     $levels =~ s/^\s+//;
2837     $levels =~ s/\s+$//;
2838     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2839
2840     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2841     if ( defined $env_debug ) {
2842         $levels{debug} = 1 if $env_debug; # Ugly!
2843         delete($levels{debug}) unless $env_debug;
2844     }
2845
2846     unless ( $class->log ) {
2847         $class->log( Catalyst::Log->new(keys %levels) );
2848     }
2849
2850     if ( $levels{debug} ) {
2851         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2852         $class->log->debug('Debug messages enabled');
2853     }
2854 }
2855
2856 =head2 $c->setup_plugins
2857
2858 Sets up plugins.
2859
2860 =cut
2861
2862 =head2 $c->setup_stats
2863
2864 Sets up timing statistics class.
2865
2866 =cut
2867
2868 sub setup_stats {
2869     my ( $class, $stats ) = @_;
2870
2871     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2872
2873     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2874     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2875         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2876         $class->log->debug('Statistics enabled');
2877     }
2878 }
2879
2880
2881 =head2 $c->registered_plugins
2882
2883 Returns a sorted list of the plugins which have either been stated in the
2884 import list.
2885
2886 If passed a given plugin name, it will report a boolean value indicating
2887 whether or not that plugin is loaded.  A fully qualified name is required if
2888 the plugin name does not begin with C<Catalyst::Plugin::>.
2889
2890  if ($c->registered_plugins('Some::Plugin')) {
2891      ...
2892  }
2893
2894 =cut
2895
2896 {
2897
2898     sub registered_plugins {
2899         my $proto = shift;
2900         return sort keys %{ $proto->_plugins } unless @_;
2901         my $plugin = shift;
2902         return 1 if exists $proto->_plugins->{$plugin};
2903         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2904     }
2905
2906     sub _register_plugin {
2907         my ( $proto, $plugin, $instant ) = @_;
2908         my $class = ref $proto || $proto;
2909
2910         Class::MOP::load_class( $plugin );
2911         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2912             if $plugin->isa( 'Catalyst::Component' );
2913         $proto->_plugins->{$plugin} = 1;
2914         unless ($instant) {
2915             my $meta = Class::MOP::get_metaclass_by_name($class);
2916             $meta->superclasses($plugin, $meta->superclasses);
2917         }
2918         return $class;
2919     }
2920
2921     sub setup_plugins {
2922         my ( $class, $plugins ) = @_;
2923
2924         $class->_plugins( {} ) unless $class->_plugins;
2925         $plugins = Data::OptList::mkopt($plugins || []);
2926
2927         my @plugins = map {
2928             [ Catalyst::Utils::resolve_namespace(
2929                   $class . '::Plugin',
2930                   'Catalyst::Plugin', $_->[0]
2931               ),
2932               $_->[1],
2933             ]
2934          } @{ $plugins };
2935
2936         for my $plugin ( reverse @plugins ) {
2937             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2938             my $meta = find_meta($plugin->[0]);
2939             next if $meta && $meta->isa('Moose::Meta::Role');
2940
2941             $class->_register_plugin($plugin->[0]);
2942         }
2943
2944         my @roles =
2945             map  { $_->[0]->name, $_->[1] }
2946             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2947             map  { [find_meta($_->[0]), $_->[1]] }
2948             @plugins;
2949
2950         Moose::Util::apply_all_roles(
2951             $class => @roles
2952         ) if @roles;
2953     }
2954 }
2955
2956 =head2 $c->stack
2957
2958 Returns an arrayref of the internal execution stack (actions that are
2959 currently executing).
2960
2961 =head2 $c->stats
2962
2963 Returns the current timing statistics object. By default Catalyst uses
2964 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2965 L<< stats_class|/"$c->stats_class" >>.
2966
2967 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2968 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2969 profile explicitly, although MyApp.pm still won't profile nor output anything
2970 by itself.
2971
2972 =head2 $c->stats_class
2973
2974 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2975
2976 =head2 $c->use_stats
2977
2978 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2979
2980 Note that this is a static method, not an accessor and should be overridden
2981 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2982
2983 =cut
2984
2985 sub use_stats { 0 }
2986
2987
2988 =head2 $c->write( $data )
2989
2990 Writes $data to the output stream. When using this method directly, you
2991 will need to manually set the C<Content-Length> header to the length of
2992 your output data, if known.
2993
2994 =cut
2995
2996 sub write {
2997     my $c = shift;
2998
2999     # Finalize headers if someone manually writes output (for compat)
3000     $c->finalize_headers;
3001
3002     return $c->response->write( @_ );
3003 }
3004
3005 =head2 version
3006
3007 Returns the Catalyst version number. Mostly useful for "powered by"
3008 messages in template systems.
3009
3010 =cut
3011
3012 sub version { return $Catalyst::VERSION }
3013
3014 =head1 CONFIGURATION
3015
3016 There are a number of 'base' config variables which can be set:
3017
3018 =over
3019
3020 =item *
3021
3022 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3023
3024 =item *
3025
3026 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3027
3028 =item *
3029
3030 C<disable_component_resolution_regex_fallback> - Turns
3031 off the deprecated component resolution functionality so
3032 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3033 are called then regex search will not be attempted on string values and
3034 instead C<undef> will be returned.
3035
3036 =item *
3037
3038 C<home> - The application home directory. In an uninstalled application,
3039 this is the top level application directory. In an installed application,
3040 this will be the directory containing C<< MyApp.pm >>.
3041
3042 =item *
3043
3044 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3045
3046 =item *
3047
3048 C<name> - The name of the application in debug messages and the debug and
3049 welcome screens
3050
3051 =item *
3052
3053 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3054 until it is accessed. This allows you to (for example) check authentication (and reject
3055 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3056
3057 =item *
3058
3059 C<root> - The root directory for templates. Usually this is just a
3060 subdirectory of the home directory, but you can set it to change the
3061 templates to a different directory.
3062
3063 =item *
3064
3065 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3066 namespaces from which components will be loaded (and constructed and stored in
3067 C<< $c->components >>).
3068
3069 =item *
3070
3071 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3072 to be shown in hit debug tables in the test server.
3073
3074 =item *
3075
3076 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3077 variable should be used for determining the request path. 
3078
3079 Most web server environments pass the requested path to the application using environment variables,
3080 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3081 exposed as C<< $c->request->base >>) and the request path below that base.
3082
3083 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3084 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3085
3086 =over
3087
3088 =item use_request_uri_for_path => 0
3089
3090 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3091 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3092 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3093 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3094
3095 However this method has the major disadvantage that it is impossible to correctly decode some elements
3096 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3097 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3098 can't distinguish / vs %2F in paths (in addition to other encoded values).
3099
3100 =item use_request_uri_for_path => 1
3101
3102 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3103 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3104 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3105
3106 Given that this method of path resolution is provably more correct, it is recommended that you use
3107 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3108 aware of the implications of not being able to handle encoded URI paths correctly.
3109
3110 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3111 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3112 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3113 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3114 C<< $c->request->base >> will be incorrect.
3115
3116 =back
3117
3118 =item *
3119
3120 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3121
3122 =back
3123
3124 =head1 INTERNAL ACTIONS
3125
3126 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3127 C<_ACTION>, and C<_END>. These are by default not shown in the private
3128 action table, but you can make them visible with a config parameter.
3129
3130     MyApp->config(show_internal_actions => 1);
3131
3132 =head1 ON-DEMAND PARSER
3133
3134 The request body is usually parsed at the beginning of a request,
3135 but if you want to handle input yourself, you can enable on-demand
3136 parsing with a config parameter.
3137
3138     MyApp->config(parse_on_demand => 1);
3139
3140 =head1 PROXY SUPPORT
3141
3142 Many production servers operate using the common double-server approach,
3143 with a lightweight frontend web server passing requests to a larger
3144 backend server. An application running on the backend server must deal
3145 with two problems: the remote user always appears to be C<127.0.0.1> and
3146 the server's hostname will appear to be C<localhost> regardless of the
3147 virtual host that the user connected through.
3148
3149 Catalyst will automatically detect this situation when you are running
3150 the frontend and backend servers on the same machine. The following
3151 changes are made to the request.
3152
3153     $c->req->address is set to the user's real IP address, as read from
3154     the HTTP X-Forwarded-For header.
3155
3156     The host value for $c->req->base and $c->req->uri is set to the real
3157     host, as read from the HTTP X-Forwarded-Host header.
3158
3159 Additionally, you may be running your backend application on an insecure
3160 connection (port 80) while your frontend proxy is running under SSL.  If there
3161 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3162 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3163 be created properly.
3164
3165 In the case of passing in:
3166
3167     X-Forwarded-Port: 443
3168
3169 All calls to C<uri_for> will result in an https link, as is expected.
3170
3171 Obviously, your web server must support these headers for this to work.
3172
3173 In a more complex server farm environment where you may have your
3174 frontend proxy server(s) on different machines, you will need to set a
3175 configuration option to tell Catalyst to read the proxied data from the
3176 headers.
3177
3178     MyApp->config(using_frontend_proxy => 1);
3179
3180 If you do not wish to use the proxy support at all, you may set:
3181
3182     MyApp->config(ignore_frontend_proxy => 0);
3183
3184 =head2 Note about psgi files
3185
3186 Note that if you supply your own .psgi file, calling
3187 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3188
3189 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3190 in your psgi, for example:
3191
3192     builder {
3193         enable "Plack::Middleware::ReverseProxy";
3194         MyApp->psgi_app
3195     };
3196
3197 This will unconditionally add the ReverseProxy support, or you need to call
3198 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3199 apply the support depending upon your config).
3200
3201 See L<Catalyst::PSGI> for more information.
3202
3203 =head1 THREAD SAFETY
3204
3205 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3206 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3207 believe the Catalyst core to be thread-safe.
3208
3209 If you plan to operate in a threaded environment, remember that all other
3210 modules you are using must also be thread-safe. Some modules, most notably
3211 L<DBD::SQLite>, are not thread-safe.
3212
3213 =head1 SUPPORT
3214
3215 IRC:
3216
3217     Join #catalyst on irc.perl.org.
3218
3219 Mailing Lists:
3220
3221     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3222     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3223
3224 Web:
3225
3226     http://catalyst.perl.org
3227
3228 Wiki:
3229
3230     http://dev.catalyst.perl.org
3231
3232 =head1 SEE ALSO
3233
3234 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3235
3236 =head2 L<Catalyst::Manual> - The Catalyst Manual
3237
3238 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3239
3240 =head2 L<Catalyst::Engine> - Core engine
3241
3242 =head2 L<Catalyst::Log> - Log class.
3243
3244 =head2 L<Catalyst::Request> - Request object
3245
3246 =head2 L<Catalyst::Response> - Response object
3247
3248 =head2 L<Catalyst::Test> - The test suite.
3249
3250 =begin stopwords
3251
3252 =head1 PROJECT FOUNDER
3253
3254 sri: Sebastian Riedel <sri@cpan.org>
3255
3256 =head1 CONTRIBUTORS
3257
3258 abw: Andy Wardley
3259
3260 acme: Leon Brocard <leon@astray.com>
3261
3262 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3263
3264 Andrew Bramble
3265
3266 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3267
3268 Andrew Ruthven
3269
3270 andyg: Andy Grundman <andy@hybridized.org>
3271
3272 audreyt: Audrey Tang
3273
3274 bricas: Brian Cassidy <bricas@cpan.org>
3275
3276 Caelum: Rafael Kitover <rkitover@io.com>
3277
3278 chansen: Christian Hansen
3279
3280 chicks: Christopher Hicks
3281
3282 Chisel Wright C<pause@herlpacker.co.uk>
3283
3284 Danijel Milicevic C<me@danijel.de>
3285
3286 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3287
3288 David Naughton, C<naughton@umn.edu>
3289
3290 David E. Wheeler
3291
3292 dhoss: Devin Austin <dhoss@cpan.org>
3293
3294 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3295
3296 Drew Taylor
3297
3298 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3299
3300 esskar: Sascha Kiefer
3301
3302 fireartist: Carl Franks <cfranks@cpan.org>
3303
3304 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3305
3306 gabb: Danijel Milicevic
3307
3308 Gary Ashton Jones
3309
3310 Gavin Henry C<ghenry@perl.me.uk>
3311
3312 Geoff Richards
3313
3314 groditi: Guillermo Roditi <groditi@gmail.com>
3315
3316 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3317
3318 ilmari: Dagfinn Ilmari MannsÃ¥ker <ilmari@ilmari.org>
3319
3320 jcamacho: Juan Camacho
3321
3322 jester: Jesse Sheidlower C<jester@panix.com>
3323
3324 jhannah: Jay Hannah <jay@jays.net>
3325
3326 Jody Belka
3327
3328 Johan Lindstrom
3329
3330 jon: Jon Schutz <jjschutz@cpan.org>
3331
3332 Jonathan Rockway C<< <jrockway@cpan.org> >>
3333
3334 Kieren Diment C<kd@totaldatasolution.com>
3335
3336 konobi: Scott McWhirter <konobi@cpan.org>
3337
3338 marcus: Marcus Ramberg <mramberg@cpan.org>
3339
3340 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3341
3342 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3343
3344 mugwump: Sam Vilain
3345
3346 naughton: David Naughton
3347
3348 ningu: David Kamholz <dkamholz@cpan.org>
3349
3350 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3351
3352 numa: Dan Sully <daniel@cpan.org>
3353
3354 obra: Jesse Vincent
3355
3356 Octavian Rasnita
3357
3358 omega: Andreas Marienborg
3359
3360 Oleg Kostyuk <cub.uanic@gmail.com>
3361
3362 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3363
3364 rafl: Florian Ragwitz <rafl@debian.org>
3365
3366 random: Roland Lammel <lammel@cpan.org>
3367
3368 Robert Sedlacek C<< <rs@474.at> >>
3369
3370 SpiceMan: Marcel Montes
3371
3372 sky: Arthur Bergman
3373
3374 szbalint: Balint Szilakszi <szbalint@cpan.org>
3375
3376 t0m: Tomas Doran <bobtfish@bobtfish.net>
3377
3378 Ulf Edvinsson
3379
3380 Viljo Marrandi C<vilts@yahoo.com>
3381
3382 Will Hawes C<info@whawes.co.uk>
3383
3384 willert: Sebastian Willert <willert@cpan.org>
3385
3386 wreis: Wallace Reis <wallace@reis.org.br>
3387
3388 Yuval Kogman, C<nothingmuch@woobling.org>
3389
3390 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3391
3392 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3393
3394 =end stopwords
3395
3396 =head1 COPYRIGHT
3397
3398 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3399
3400 =head1 LICENSE
3401
3402 This library is free software. You can redistribute it and/or modify it under
3403 the same terms as Perl itself.
3404
3405 =cut
3406
3407 no Moose;
3408
3409 __PACKAGE__->meta->make_immutable;
3410
3411 1;