lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         my $class = ref $self;
  67         my $composed_request_class = $class->composed_request_class;
  68         return $composed_request_class->new( $self->_build_request_constructor_args);
  69     },
  70     lazy => 1,
  71 );
  72 sub _build_request_constructor_args {
  73     my $self = shift;
  74     my %p = ( _log => $self->log );
  75     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  76     $p{data_handlers} = {$self->registered_data_handlers};
  77     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  78       if $self->config->{use_hash_multivalue_in_request};
  79     \%p;
  80 }
  81
  82 sub composed_request_class {
  83   my $class = shift;
  84   my @traits = (@{$class->request_class_traits||[]}, @{$class->config->{request_class_traits}||[]});
  85   return $class->_composed_request_class ||
  86     $class->_composed_request_class(Moose::Util::with_traits($class->request_class, @traits));
  87 }
  88
  89 has response => (
  90     is => 'rw',
  91     default => sub {
  92         my $self = shift;
  93         my $class = ref $self;
  94         my $composed_response_class = $class->composed_response_class;
  95         return $composed_response_class->new( $self->_build_response_constructor_args);
  96     },
  97     lazy => 1,
  98 );
  99 sub _build_response_constructor_args {
 100     return +{
 101       _log => $_[0]->log,
 102       encoding => $_[0]->encoding,
 103     };
 104 }
 105
 106 sub composed_response_class {
 107   my $class = shift;
 108   my @traits = (@{$class->response_class_traits||[]}, @{$class->config->{response_class_traits}||[]});
 109   return $class->_composed_response_class ||
 110     $class->_composed_response_class(Moose::Util::with_traits($class->response_class, @traits));
 111 }
 112
 113 has namespace => (is => 'rw');
 114
 115 sub depth { scalar @{ shift->stack || [] }; }
 116 sub comp { shift->component(@_) }
 117
 118 sub req {
 119     my $self = shift; return $self->request(@_);
 120 }
 121 sub res {
 122     my $self = shift; return $self->response(@_);
 123 }
 124
 125 # For backwards compatibility
 126 sub finalize_output { shift->finalize_body(@_) };
 127
 128 # For statistics
 129 our $COUNT     = 1;
 130 our $START     = time;
 131 our $RECURSION = 1000;
 132 our $DETACH    = Catalyst::Exception::Detach->new;
 133 our $GO        = Catalyst::Exception::Go->new;
 134
 135 #I imagine that very few of these really need to be class variables. if any.
 136 #maybe we should just make them attributes with a default?
 137 __PACKAGE__->mk_classdata($_)
 138   for qw/components arguments dispatcher engine log dispatcher_class
 139   engine_loader context_class request_class response_class stats_class
 140   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 141   _data_handlers _encoding _encode_check finalized_default_middleware
 142   request_class_traits response_class_traits stats_class_traits
 143   _composed_request_class _composed_response_class _composed_stats_class/;
 144
 145 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 146 __PACKAGE__->request_class('Catalyst::Request');
 147 __PACKAGE__->response_class('Catalyst::Response');
 148 __PACKAGE__->stats_class('Catalyst::Stats');
 149
 150 sub composed_stats_class {
 151   my $class = shift;
 152   my @traits = (@{$class->stats_class_traits||[]}, @{$class->config->{stats_class_traits}||[]});
 153   return $class->_composed_stats_class ||
 154     $class->_composed_stats_class(Moose::Util::with_traits($class->stats_class, @traits));
 155 }
 156
 157 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 158
 159 # Remember to update this in Catalyst::Runtime as well!
 160 our $VERSION = '5.90089_003';
 161 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 162
 163 sub import {
 164     my ( $class, @arguments ) = @_;
 165
 166     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 167     # callers @ISA.
 168     return unless $class eq 'Catalyst';
 169
 170     my $caller = caller();
 171     return if $caller eq 'main';
 172
 173     my $meta = Moose::Meta::Class->initialize($caller);
 174     unless ( $caller->isa('Catalyst') ) {
 175         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 176         $meta->superclasses(@superclasses);
 177     }
 178     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 179     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 180
 181     unless( $meta->has_method('meta') ){
 182         if ($Moose::VERSION >= 1.15) {
 183             $meta->_add_meta_method('meta');
 184         }
 185         else {
 186             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 187         }
 188     }
 189
 190     $caller->arguments( [@arguments] );
 191     $caller->setup_home;
 192 }
 193
 194 sub _application { $_[0] }
 195
 196 =encoding UTF-8
 197
 198 =head1 NAME
 199
 200 Catalyst - The Elegant MVC Web Application Framework
 201
 202 =head1 SYNOPSIS
 203
 204 See the L<Catalyst::Manual> distribution for comprehensive
 205 documentation and tutorials.
 206
 207     # Install Catalyst::Devel for helpers and other development tools
 208     # use the helper to create a new application
 209     catalyst.pl MyApp
 210
 211     # add models, views, controllers
 212     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 213     script/myapp_create.pl view MyTemplate TT
 214     script/myapp_create.pl controller Search
 215
 216     # built in testserver -- use -r to restart automatically on changes
 217     # --help to see all available options
 218     script/myapp_server.pl
 219
 220     # command line testing interface
 221     script/myapp_test.pl /yada
 222
 223     ### in lib/MyApp.pm
 224     use Catalyst qw/-Debug/; # include plugins here as well
 225
 226     ### In lib/MyApp/Controller/Root.pm (autocreated)
 227     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 228         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 229         $c->stash->{template} = 'foo.tt'; # set the template
 230         # lookup something from db -- stash vars are passed to TT
 231         $c->stash->{data} =
 232           $c->model('Database::Foo')->search( { country => $args[0] } );
 233         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 234             $c->forward( 'bar' ); # process another action
 235             # do something else after forward returns
 236         }
 237     }
 238
 239     # The foo.tt TT template can use the stash data from the database
 240     [% WHILE (item = data.next) %]
 241         [% item.foo %]
 242     [% END %]
 243
 244     # called for /bar/of/soap, /bar/of/soap/10, etc.
 245     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 246
 247     # called after all actions are finished
 248     sub end : Action {
 249         my ( $self, $c ) = @_;
 250         if ( scalar @{ $c->error } ) { ... } # handle errors
 251         return if $c->res->body; # already have a response
 252         $c->forward( 'MyApp::View::TT' ); # render template
 253     }
 254
 255 See L<Catalyst::Manual::Intro> for additional information.
 256
 257 =head1 DESCRIPTION
 258
 259 Catalyst is a modern framework for making web applications without the
 260 pain usually associated with this process. This document is a reference
 261 to the main Catalyst application. If you are a new user, we suggest you
 262 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 263
 264 See L<Catalyst::Manual> for more documentation.
 265
 266 Catalyst plugins can be loaded by naming them as arguments to the "use
 267 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 268 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 269 C<My::Module>.
 270
 271     use Catalyst qw/My::Module/;
 272
 273 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 274 fully qualify the name by using a unary plus:
 275
 276     use Catalyst qw/
 277         My::Module
 278         +Fully::Qualified::Plugin::Name
 279     /;
 280
 281 Special flags like C<-Debug> can also be specified as
 282 arguments when Catalyst is loaded:
 283
 284     use Catalyst qw/-Debug My::Module/;
 285
 286 The position of plugins and flags in the chain is important, because
 287 they are loaded in the order in which they appear.
 288
 289 The following flags are supported:
 290
 291 =head2 -Debug
 292
 293 Enables debug output. You can also force this setting from the system
 294 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 295 settings override the application, with <MYAPP>_DEBUG having the highest
 296 priority.
 297
 298 This sets the log level to 'debug' and enables full debug output on the
 299 error screen. If you only want the latter, see L<< $c->debug >>.
 300
 301 =head2 -Home
 302
 303 Forces Catalyst to use a specific home directory, e.g.:
 304
 305     use Catalyst qw[-Home=/usr/mst];
 306
 307 This can also be done in the shell environment by setting either the
 308 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 309 is replaced with the uppercased name of your application, any "::" in
 310 the name will be replaced with underscores, e.g. MyApp::Web should use
 311 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 312
 313 If none of these are set, Catalyst will attempt to automatically detect the
 314 home directory. If you are working in a development environment, Catalyst
 315 will try and find the directory containing either Makefile.PL, Build.PL,
 316 dist.ini, or cpanfile. If the application has been installed into the system
 317 (i.e. you have done C<make install>), then Catalyst will use the path to your
 318 application module, without the .pm extension (e.g., /foo/MyApp if your
 319 application was installed at /foo/MyApp.pm)
 320
 321 =head2 -Log
 322
 323     use Catalyst '-Log=warn,fatal,error';
 324
 325 Specifies a comma-delimited list of log levels.
 326
 327 =head2 -Stats
 328
 329 Enables statistics collection and reporting.
 330
 331    use Catalyst qw/-Stats=1/;
 332
 333 You can also force this setting from the system environment with CATALYST_STATS
 334 or <MYAPP>_STATS. The environment settings override the application, with
 335 <MYAPP>_STATS having the highest priority.
 336
 337 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 338
 339 =head1 METHODS
 340
 341 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 342
 343 =head2 $c->action
 344
 345 Returns a L<Catalyst::Action> object for the current action, which
 346 stringifies to the action name. See L<Catalyst::Action>.
 347
 348 =head2 $c->namespace
 349
 350 Returns the namespace of the current action, i.e., the URI prefix
 351 corresponding to the controller of the current action. For example:
 352
 353     # in Controller::Foo::Bar
 354     $c->namespace; # returns 'foo/bar';
 355
 356 =head2 $c->request
 357
 358 =head2 $c->req
 359
 360 Returns the current L<Catalyst::Request> object, giving access to
 361 information about the current client request (including parameters,
 362 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 363
 364 =head2 REQUEST FLOW HANDLING
 365
 366 =head2 $c->forward( $action [, \@arguments ] )
 367
 368 =head2 $c->forward( $class, $method, [, \@arguments ] )
 369
 370 This is one way of calling another action (method) in the same or
 371 a different controller. You can also use C<< $self->my_method($c, @args) >>
 372 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 373 in a different controller.
 374 The main difference is that 'forward' uses some of the Catalyst request
 375 cycle overhead, including debugging, which may be useful to you. On the
 376 other hand, there are some complications to using 'forward', restrictions
 377 on values returned from 'forward', and it may not handle errors as you prefer.
 378 Whether you use 'forward' or not is up to you; it is not considered superior to
 379 the other ways to call a method.
 380
 381 'forward' calls  another action, by its private name. If you give a
 382 class name but no method, C<process()> is called. You may also optionally
 383 pass arguments in an arrayref. The action will receive the arguments in
 384 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 385 C<< $c->req->args >> will be restored to the previous values.
 386
 387 Any data C<return>ed from the action forwarded to, will be returned by the
 388 call to forward.
 389
 390     my $foodata = $c->forward('/foo');
 391     $c->forward('index');
 392     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 393     $c->forward('View::TT');
 394
 395 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 396 an C<< eval { } >> around the call (actually
 397 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 398 exceptions thrown by the called action non-fatal and pushing them onto
 399 $c->error instead. If you want C<die> to propagate you need to do something
 400 like:
 401
 402     $c->forward('foo');
 403     die join "\n", @{ $c->error } if @{ $c->error };
 404
 405 Or make sure to always return true values from your actions and write
 406 your code like this:
 407
 408     $c->forward('foo') || return;
 409
 410 Another note is that C<< $c->forward >> always returns a scalar because it
 411 actually returns $c->state which operates in a scalar context.
 412 Thus, something like:
 413
 414     return @array;
 415
 416 in an action that is forwarded to is going to return a scalar,
 417 i.e. how many items are in that array, which is probably not what you want.
 418 If you need to return an array then return a reference to it,
 419 or stash it like so:
 420
 421     $c->stash->{array} = \@array;
 422
 423 and access it from the stash.
 424
 425 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 426
 427 =cut
 428
 429 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 430
 431 =head2 $c->detach( $action [, \@arguments ] )
 432
 433 =head2 $c->detach( $class, $method, [, \@arguments ] )
 434
 435 =head2 $c->detach()
 436
 437 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 438 doesn't return to the previous action when processing is finished.
 439
 440 When called with no arguments it escapes the processing chain entirely.
 441
 442 =cut
 443
 444 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 445
 446 =head2 $c->visit( $action [, \@arguments ] )
 447
 448 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 449
 450 =head2 $c->visit( $class, $method, [, \@arguments ] )
 451
 452 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 453
 454 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 455 but does a full dispatch, instead of just calling the new C<$action> /
 456 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 457 you go to are called, just like a new request.
 458
 459 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 460 This means, for example, that C<< $c->action >> methods such as
 461 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 462 L<reverse|Catalyst::Action/reverse> return information for the visited action
 463 when they are invoked within the visited action.  This is different from the
 464 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 465 continues to use the $c->action object from the caller action even when
 466 invoked from the called action.
 467
 468 C<< $c->stash >> is kept unchanged.
 469
 470 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 471 allows you to "wrap" another action, just as it would have been called by
 472 dispatching from a URL, while the analogous
 473 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 474 transfer control to another action as if it had been reached directly from a URL.
 475
 476 =cut
 477
 478 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 479
 480 =head2 $c->go( $action [, \@arguments ] )
 481
 482 =head2 $c->go( $action [, \@captures, \@arguments ] )
 483
 484 =head2 $c->go( $class, $method, [, \@arguments ] )
 485
 486 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 487
 488 The relationship between C<go> and
 489 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 490 the relationship between
 491 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 492 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 493 C<< $c->go >> will perform a full dispatch on the specified action or method,
 494 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 495 C<go> escapes the processing of the current request chain on completion, and
 496 does not return to its cunless blessed $cunless blessed $caller.
 497
 498 @arguments are arguments to the final destination of $action. @captures are
 499 arguments to the intermediate steps, if any, on the way to the final sub of
 500 $action.
 501
 502 =cut
 503
 504 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 505
 506 =head2 $c->response
 507
 508 =head2 $c->res
 509
 510 Returns the current L<Catalyst::Response> object, see there for details.
 511
 512 =head2 $c->stash
 513
 514 Returns a hashref to the stash, which may be used to store data and pass
 515 it between components during a request. You can also set hash keys by
 516 passing arguments. The stash is automatically sent to the view. The
 517 stash is cleared at the end of a request; it cannot be used for
 518 persistent storage (for this you must use a session; see
 519 L<Catalyst::Plugin::Session> for a complete system integrated with
 520 Catalyst).
 521
 522     $c->stash->{foo} = $bar;
 523     $c->stash( { moose => 'majestic', qux => 0 } );
 524     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 525
 526     # stash is automatically passed to the view for use in a template
 527     $c->forward( 'MyApp::View::TT' );
 528
 529 The stash hash is currently stored in the PSGI C<$env> and is managed by
 530 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 531 the stash can be accessed in sub applications mounted under your main
 532 L<Catalyst> application.  For example if you delegate the response of an
 533 action to another L<Catalyst> application, that sub application will have
 534 access to all the stash keys of the main one, and if can of course add
 535 more keys of its own.  However those new keys will not 'bubble' back up
 536 to the main application.
 537
 538 For more information the best thing to do is to review the test case:
 539 t/middleware-stash.t in the distribution /t directory.
 540
 541 =cut
 542
 543 sub stash {
 544   my $c = shift;
 545   $c->log->error("You are requesting the stash but you don't have a context") unless blessed $c;
 546   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 547 }
 548
 549 =head2 $c->error
 550
 551 =head2 $c->error($error, ...)
 552
 553 =head2 $c->error($arrayref)
 554
 555 Returns an arrayref containing error messages.  If Catalyst encounters an
 556 error while processing a request, it stores the error in $c->error.  This
 557 method should only be used to store fatal error messages.
 558
 559     my @error = @{ $c->error };
 560
 561 Add a new error.
 562
 563     $c->error('Something bad happened');
 564
 565 Calling this will always return an arrayref (if there are no errors it
 566 will be an empty arrayref.
 567
 568 =cut
 569
 570 sub error {
 571     my $c = shift;
 572     if ( $_[0] ) {
 573         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 574         croak @$error unless ref $c;
 575         push @{ $c->{error} }, @$error;
 576     }
 577     elsif ( defined $_[0] ) { $c->{error} = undef }
 578     return $c->{error} || [];
 579 }
 580
 581
 582 =head2 $c->state
 583
 584 Contains the return value of the last executed action.
 585 Note that << $c->state >> operates in a scalar context which means that all
 586 values it returns are scalar.
 587
 588 =head2 $c->clear_errors
 589
 590 Clear errors.  You probably don't want to clear the errors unless you are
 591 implementing a custom error screen.
 592
 593 This is equivalent to running
 594
 595     $c->error(0);
 596
 597 =cut
 598
 599 sub clear_errors {
 600     my $c = shift;
 601     $c->error(0);
 602 }
 603
 604 =head2 $c->has_errors
 605
 606 Returns true if you have errors
 607
 608 =cut
 609
 610 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 611
 612 =head2 $c->last_error
 613
 614 Returns the most recent error in the stack (the one most recently added...)
 615 or nothing if there are no errors.
 616
 617 =cut
 618
 619 sub last_error { my ($err, @errs) = @{shift->error}; return $err }
 620
 621 =head2 shift_errors
 622
 623 shifts the most recently added error off the error stack and returns if.  Returns
 624 nothing if there are no more errors.
 625
 626 =cut
 627
 628 sub shift_errors {
 629     my ($self) = @_;
 630     my ($err, @errors) = @{$self->error};
 631     $self->{error} = \@errors;
 632     return $err;
 633 }
 634
 635 sub _comp_search_prefixes {
 636     my $c = shift;
 637     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 638 }
 639
 640 # search components given a name and some prefixes
 641 sub _comp_names_search_prefixes {
 642     my ( $c, $name, @prefixes ) = @_;
 643     my $appclass = ref $c || $c;
 644     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 645     $filter = qr/$filter/; # Compile regex now rather than once per loop
 646
 647     # map the original component name to the sub part that we will search against
 648     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 649         grep { /$filter/ } keys %{ $c->components };
 650
 651     # undef for a name will return all
 652     return keys %eligible if !defined $name;
 653
 654     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 655     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 656
 657     return @result if @result;
 658
 659     # if we were given a regexp to search against, we're done.
 660     return if $name->$_isa('Regexp');
 661
 662     # skip regexp fallback if configured
 663     return
 664         if $appclass->config->{disable_component_resolution_regex_fallback};
 665
 666     # regexp fallback
 667     $query  = qr/$name/i;
 668     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 669
 670     # no results? try against full names
 671     if( !@result ) {
 672         @result = grep { m{$query} } keys %eligible;
 673     }
 674
 675     # don't warn if we didn't find any results, it just might not exist
 676     if( @result ) {
 677         # Disgusting hack to work out correct method name
 678         my $warn_for = lc $prefixes[0];
 679         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 680            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 681            "component resolution is unreliable and unsafe.";
 682         my $short = $result[0];
 683         # remove the component namespace prefix
 684         $short =~ s/.*?(Model|Controller|View):://;
 685         my $shortmess = Carp::shortmess('');
 686         if ($shortmess =~ m#Catalyst/Plugin#) {
 687            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 688               "plugin's config";
 689         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 690            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 691               "component's config";
 692         } else {
 693            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 694               "but if you really wanted to search, pass in a regexp as the argument " .
 695               "like so: \$c->${warn_for}(qr/${name}/)";
 696         }
 697         $c->log->warn( "${msg}$shortmess" );
 698     }
 699
 700     return @result;
 701 }
 702
 703 # Find possible names for a prefix
 704 sub _comp_names {
 705     my ( $c, @prefixes ) = @_;
 706     my $appclass = ref $c || $c;
 707
 708     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 709
 710     my @names = map { s{$filter}{}; $_; }
 711         $c->_comp_names_search_prefixes( undef, @prefixes );
 712
 713     return @names;
 714 }
 715
 716 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 717
 718 sub _filter_component {
 719     my ( $c, $comp, @args ) = @_;
 720
 721     if(ref $comp eq 'CODE') {
 722       $comp = $comp->();
 723     }
 724
 725     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 726       return $comp->ACCEPT_CONTEXT( $c, @args );
 727     }
 728
 729     $c->log->warn("You called component '${\$comp->catalyst_component_name}' with arguments [@args], but this component does not ACCEPT_CONTEXT, so args are ignored.") if scalar(@args) && $c->debug;
 730
 731     return $comp;
 732 }
 733
 734 =head2 COMPONENT ACCESSORS
 735
 736 =head2 $c->controller($name)
 737
 738 Gets a L<Catalyst::Controller> instance by name.
 739
 740     $c->controller('Foo')->do_stuff;
 741
 742 If the name is omitted, will return the controller for the dispatched
 743 action.
 744
 745 If you want to search for controllers, pass in a regexp as the argument.
 746
 747     # find all controllers that start with Foo
 748     my @foo_controllers = $c->controller(qr{^Foo});
 749
 750
 751 =cut
 752
 753 sub controller {
 754     my ( $c, $name, @args ) = @_;
 755
 756     my $appclass = ref($c) || $c;
 757     if( $name ) {
 758         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 759             my $comps = $c->components;
 760             my $check = $appclass."::Controller::".$name;
 761             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 762         }
 763         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 764         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 765         return $c->_filter_component( $result[ 0 ], @args );
 766     }
 767
 768     return $c->component( $c->action->class );
 769 }
 770
 771 =head2 $c->model($name)
 772
 773 Gets a L<Catalyst::Model> instance by name.
 774
 775     $c->model('Foo')->do_stuff;
 776
 777 Any extra arguments are directly passed to ACCEPT_CONTEXT, if the model
 778 defines ACCEPT_CONTEXT.  If it does not, the args are discarded.
 779
 780 If the name is omitted, it will look for
 781  - a model object in $c->stash->{current_model_instance}, then
 782  - a model name in $c->stash->{current_model}, then
 783  - a config setting 'default_model', or
 784  - check if there is only one model, and return it if that's the case.
 785
 786 If you want to search for models, pass in a regexp as the argument.
 787
 788     # find all models that start with Foo
 789     my @foo_models = $c->model(qr{^Foo});
 790
 791 =cut
 792
 793 sub model {
 794     my ( $c, $name, @args ) = @_;
 795     my $appclass = ref($c) || $c;
 796     if( $name ) {
 797         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 798             my $comps = $c->components;
 799             my $check = $appclass."::Model::".$name;
 800             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 801         }
 802         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 803         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 804         return $c->_filter_component( $result[ 0 ], @args );
 805     }
 806
 807     if (ref $c) {
 808         return $c->stash->{current_model_instance}
 809           if $c->stash->{current_model_instance};
 810         return $c->model( $c->stash->{current_model} )
 811           if $c->stash->{current_model};
 812     }
 813     return $c->model( $appclass->config->{default_model} )
 814       if $appclass->config->{default_model};
 815
 816     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 817
 818     if( $rest ) {
 819         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 820         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 821         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 822         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 823         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 824     }
 825
 826     return $c->_filter_component( $comp );
 827 }
 828
 829
 830 =head2 $c->view($name)
 831
 832 Gets a L<Catalyst::View> instance by name.
 833
 834     $c->view('Foo')->do_stuff;
 835
 836 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 837
 838 If the name is omitted, it will look for
 839  - a view object in $c->stash->{current_view_instance}, then
 840  - a view name in $c->stash->{current_view}, then
 841  - a config setting 'default_view', or
 842  - check if there is only one view, and return it if that's the case.
 843
 844 If you want to search for views, pass in a regexp as the argument.
 845
 846     # find all views that start with Foo
 847     my @foo_views = $c->view(qr{^Foo});
 848
 849 =cut
 850
 851 sub view {
 852     my ( $c, $name, @args ) = @_;
 853
 854     my $appclass = ref($c) || $c;
 855     if( $name ) {
 856         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 857             my $comps = $c->components;
 858             my $check = $appclass."::View::".$name;
 859             if( exists $comps->{$check} ) {
 860                 return $c->_filter_component( $comps->{$check}, @args );
 861             }
 862             else {
 863                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 864             }
 865         }
 866         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 867         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 868         return $c->_filter_component( $result[ 0 ], @args );
 869     }
 870
 871     if (ref $c) {
 872         return $c->stash->{current_view_instance}
 873           if $c->stash->{current_view_instance};
 874         return $c->view( $c->stash->{current_view} )
 875           if $c->stash->{current_view};
 876     }
 877     return $c->view( $appclass->config->{default_view} )
 878       if $appclass->config->{default_view};
 879
 880     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 881
 882     if( $rest ) {
 883         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 884         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 885         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 886         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 887         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 888     }
 889
 890     return $c->_filter_component( $comp );
 891 }
 892
 893 =head2 $c->controllers
 894
 895 Returns the available names which can be passed to $c->controller
 896
 897 =cut
 898
 899 sub controllers {
 900     my ( $c ) = @_;
 901     return $c->_comp_names(qw/Controller C/);
 902 }
 903
 904 =head2 $c->models
 905
 906 Returns the available names which can be passed to $c->model
 907
 908 =cut
 909
 910 sub models {
 911     my ( $c ) = @_;
 912     return $c->_comp_names(qw/Model M/);
 913 }
 914
 915
 916 =head2 $c->views
 917
 918 Returns the available names which can be passed to $c->view
 919
 920 =cut
 921
 922 sub views {
 923     my ( $c ) = @_;
 924     return $c->_comp_names(qw/View V/);
 925 }
 926
 927 =head2 $c->comp($name)
 928
 929 =head2 $c->component($name)
 930
 931 Gets a component object by name. This method is not recommended,
 932 unless you want to get a specific component by full
 933 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 934 should be used instead.
 935
 936 If C<$name> is a regexp, a list of components matched against the full
 937 component name will be returned.
 938
 939 If Catalyst can't find a component by name, it will fallback to regex
 940 matching by default. To disable this behaviour set
 941 disable_component_resolution_regex_fallback to a true value.
 942
 943     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 944
 945 =cut
 946
 947 sub component {
 948     my ( $c, $name, @args ) = @_;
 949
 950     if( $name ) {
 951         my $comps = $c->components;
 952
 953         if( !ref $name ) {
 954             # is it the exact name?
 955             return $c->_filter_component( $comps->{ $name }, @args )
 956                        if exists $comps->{ $name };
 957
 958             # perhaps we just omitted "MyApp"?
 959             my $composed = ( ref $c || $c ) . "::${name}";
 960             return $c->_filter_component( $comps->{ $composed }, @args )
 961                        if exists $comps->{ $composed };
 962
 963             # search all of the models, views and controllers
 964             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 965             return $c->_filter_component( $comp, @args ) if $comp;
 966         }
 967
 968         return
 969             if $c->config->{disable_component_resolution_regex_fallback};
 970
 971         # This is here so $c->comp( '::M::' ) works
 972         my $query = ref $name ? $name : qr{$name}i;
 973
 974         my @result = grep { m{$query} } keys %{ $c->components };
 975         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 976
 977         if( $result[ 0 ] ) {
 978             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 979             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 980             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 981             return $c->_filter_component( $result[ 0 ], @args );
 982         }
 983
 984         # I would expect to return an empty list here, but that breaks back-compat
 985     }
 986
 987     # fallback
 988     return sort keys %{ $c->components };
 989 }
 990
 991 =head2 CLASS DATA AND HELPER CLASSES
 992
 993 =head2 $c->config
 994
 995 Returns or takes a hashref containing the application's configuration.
 996
 997     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 998
 999 You can also use a C<YAML>, C<XML> or L<Config::General> config file
1000 like C<myapp.conf> in your applications home directory. See
1001 L<Catalyst::Plugin::ConfigLoader>.
1002
1003 =head3 Cascading configuration
1004
1005 The config method is present on all Catalyst components, and configuration
1006 will be merged when an application is started. Configuration loaded with
1007 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
1008 followed by configuration in your top level C<MyApp> class. These two
1009 configurations are merged, and then configuration data whose hash key matches a
1010 component name is merged with configuration for that component.
1011
1012 The configuration for a component is then passed to the C<new> method when a
1013 component is constructed.
1014
1015 For example:
1016
1017     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
1018     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
1019
1020 will mean that C<MyApp::Model::Foo> receives the following data when
1021 constructed:
1022
1023     MyApp::Model::Foo->new({
1024         bar => 'baz',
1025         quux => 'frob',
1026         overrides => 'me',
1027     });
1028
1029 It's common practice to use a Moose attribute
1030 on the receiving component to access the config value.
1031
1032     package MyApp::Model::Foo;
1033
1034     use Moose;
1035
1036     # this attr will receive 'baz' at construction time
1037     has 'bar' => (
1038         is  => 'rw',
1039         isa => 'Str',
1040     );
1041
1042 You can then get the value 'baz' by calling $c->model('Foo')->bar
1043 (or $self->bar inside code in the model).
1044
1045 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1046 as a way of reading config within your code, as this B<will not> give you the
1047 correctly merged config back. You B<MUST> take the config values supplied to
1048 the constructor and use those instead.
1049
1050 =cut
1051
1052 around config => sub {
1053     my $orig = shift;
1054     my $c = shift;
1055
1056     croak('Setting config after setup has been run is not allowed.')
1057         if ( @_ and $c->setup_finished );
1058
1059     $c->$orig(@_);
1060 };
1061
1062 =head2 $c->log
1063
1064 Returns the logging object instance. Unless it is already set, Catalyst
1065 sets this up with a L<Catalyst::Log> object. To use your own log class,
1066 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1067 C<< __PACKAGE__->setup >>.
1068
1069  __PACKAGE__->log( MyLogger->new );
1070  __PACKAGE__->setup;
1071
1072 And later:
1073
1074     $c->log->info( 'Now logging with my own logger!' );
1075
1076 Your log class should implement the methods described in
1077 L<Catalyst::Log>.
1078
1079 =head2 has_encoding
1080
1081 Returned True if there's a valid encoding
1082
1083 =head2 clear_encoding
1084
1085 Clears the encoding for the current context
1086
1087 =head2 encoding
1088
1089 Sets or gets the application encoding.  Setting encoding takes either an
1090 Encoding object or a string that we try to resolve via L<Encode::find_encoding>.
1091
1092 You would expect to get the encoding object back if you attempt to set it.  If
1093 there is a failure you will get undef returned and an error message in the log.
1094
1095 =cut
1096
1097 sub has_encoding { shift->encoding ? 1:0 }
1098
1099 sub clear_encoding {
1100     my $c = shift;
1101     if(blessed $c) {
1102         $c->encoding(undef);
1103     } else {
1104         $c->log->error("You can't clear encoding on the application");
1105     }
1106 }
1107
1108 sub encoding {
1109     my $c = shift;
1110     my $encoding;
1111
1112     if ( scalar @_ ) {
1113
1114         # Don't let one change this once we are too far into the response
1115         if(blessed $c && $c->res->finalized_headers) {
1116           Carp::croak("You may not change the encoding once the headers are finalized");
1117           return;
1118         }
1119
1120         # Let it be set to undef
1121         if (my $wanted = shift)  {
1122             $encoding = Encode::find_encoding($wanted)
1123               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1124             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1125         }
1126         else {
1127             binmode(STDERR);
1128         }
1129
1130         $encoding = ref $c
1131                   ? $c->{encoding} = $encoding
1132                   : $c->_encoding($encoding);
1133     } else {
1134       $encoding = ref $c && exists $c->{encoding}
1135                 ? $c->{encoding}
1136                 : $c->_encoding;
1137     }
1138
1139     return $encoding;
1140 }
1141
1142 =head2 $c->debug
1143
1144 Returns 1 if debug mode is enabled, 0 otherwise.
1145
1146 You can enable debug mode in several ways:
1147
1148 =over
1149
1150 =item By calling myapp_server.pl with the -d flag
1151
1152 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1153
1154 =item The -Debug option in your MyApp.pm
1155
1156 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1157
1158 =back
1159
1160 The first three also set the log level to 'debug'.
1161
1162 Calling C<< $c->debug(1) >> has no effect.
1163
1164 =cut
1165
1166 sub debug { 0 }
1167
1168 =head2 $c->dispatcher
1169
1170 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1171
1172 =head2 $c->engine
1173
1174 Returns the engine instance. See L<Catalyst::Engine>.
1175
1176
1177 =head2 UTILITY METHODS
1178
1179 =head2 $c->path_to(@path)
1180
1181 Merges C<@path> with C<< $c->config->{home} >> and returns a
1182 L<Path::Class::Dir> object. Note you can usually use this object as
1183 a filename, but sometimes you will have to explicitly stringify it
1184 yourself by calling the C<< ->stringify >> method.
1185
1186 For example:
1187
1188     $c->path_to( 'db', 'sqlite.db' );
1189
1190 =cut
1191
1192 sub path_to {
1193     my ( $c, @path ) = @_;
1194     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1195     if ( -d $path ) { return $path }
1196     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1197 }
1198
1199 sub plugin {
1200     my ( $class, $name, $plugin, @args ) = @_;
1201
1202     # See block comment in t/unit_core_plugin.t
1203     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1204
1205     $class->_register_plugin( $plugin, 1 );
1206
1207     eval { $plugin->import };
1208     $class->mk_classdata($name);
1209     my $obj;
1210     eval { $obj = $plugin->new(@args) };
1211
1212     if ($@) {
1213         Catalyst::Exception->throw( message =>
1214               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1215     }
1216
1217     $class->$name($obj);
1218     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1219       if $class->debug;
1220 }
1221
1222 =head2 MyApp->setup
1223
1224 Initializes the dispatcher and engine, loads any plugins, and loads the
1225 model, view, and controller components. You may also specify an array
1226 of plugins to load here, if you choose to not load them in the C<use
1227 Catalyst> line.
1228
1229     MyApp->setup;
1230     MyApp->setup( qw/-Debug/ );
1231
1232 B<Note:> You B<should not> wrap this method with method modifiers
1233 or bad things will happen - wrap the C<setup_finalize> method instead.
1234
1235 B<Note:> You can create a custom setup stage that will execute when the
1236 application is starting.  Use this to customize setup.
1237
1238     MyApp->setup(-Custom=value);
1239
1240     sub setup_custom {
1241       my ($class, $value) = @_;
1242     }
1243
1244 Can be handy if you want to hook into the setup phase.
1245
1246 =cut
1247
1248 sub setup {
1249     my ( $class, @arguments ) = @_;
1250     croak('Running setup more than once')
1251         if ( $class->setup_finished );
1252
1253     unless ( $class->isa('Catalyst') ) {
1254
1255         Catalyst::Exception->throw(
1256             message => qq/'$class' does not inherit from Catalyst/ );
1257     }
1258
1259     if ( $class->arguments ) {
1260         @arguments = ( @arguments, @{ $class->arguments } );
1261     }
1262
1263     # Process options
1264     my $flags = {};
1265
1266     foreach (@arguments) {
1267
1268         if (/^-Debug$/) {
1269             $flags->{log} =
1270               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1271         }
1272         elsif (/^-(\w+)=?(.*)$/) {
1273             $flags->{ lc $1 } = $2;
1274         }
1275         else {
1276             push @{ $flags->{plugins} }, $_;
1277         }
1278     }
1279
1280     $class->setup_home( delete $flags->{home} );
1281
1282     $class->setup_log( delete $flags->{log} );
1283     $class->setup_plugins( delete $flags->{plugins} );
1284
1285     $class->setup_data_handlers();
1286     $class->setup_dispatcher( delete $flags->{dispatcher} );
1287     if (my $engine = delete $flags->{engine}) {
1288         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1289     }
1290     $class->setup_engine();
1291     $class->setup_stats( delete $flags->{stats} );
1292
1293     for my $flag ( sort keys %{$flags} ) {
1294
1295         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1296             &$code( $class, delete $flags->{$flag} );
1297         }
1298         else {
1299             $class->log->warn(qq/Unknown flag "$flag"/);
1300         }
1301     }
1302
1303     eval { require Catalyst::Devel; };
1304     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1305         $class->log->warn(<<"EOF");
1306 You are running an old script!
1307
1308   Please update by running (this will overwrite existing files):
1309     catalyst.pl -force -scripts $class
1310
1311   or (this will not overwrite existing files):
1312     catalyst.pl -scripts $class
1313
1314 EOF
1315     }
1316
1317     # Call plugins setup, this is stupid and evil.
1318     # Also screws C3 badly on 5.10, hack to avoid.
1319     {
1320         no warnings qw/redefine/;
1321         local *setup = sub { };
1322         $class->setup unless $Catalyst::__AM_RESTARTING;
1323     }
1324
1325     # If you are expecting configuration info as part of your setup, it needs
1326     # to get called here and below, since we need the above line to support
1327     # ConfigLoader based configs.
1328
1329     $class->setup_encoding();
1330     $class->setup_middleware();
1331
1332     # Initialize our data structure
1333     $class->components( {} );
1334
1335     $class->setup_components;
1336
1337     if ( $class->debug ) {
1338         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1339
1340         if (@plugins) {
1341             my $column_width = Catalyst::Utils::term_width() - 6;
1342             my $t = Text::SimpleTable->new($column_width);
1343             $t->row($_) for @plugins;
1344             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1345         }
1346
1347         my @middleware = map {
1348           ref $_ eq 'CODE' ?
1349             "Inline Coderef" :
1350               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1351                 || '')  } $class->registered_middlewares;
1352
1353         if (@middleware) {
1354             my $column_width = Catalyst::Utils::term_width() - 6;
1355             my $t = Text::SimpleTable->new($column_width);
1356             $t->row($_) for @middleware;
1357             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1358         }
1359
1360         my %dh = $class->registered_data_handlers;
1361         if (my @data_handlers = keys %dh) {
1362             my $column_width = Catalyst::Utils::term_width() - 6;
1363             my $t = Text::SimpleTable->new($column_width);
1364             $t->row($_) for @data_handlers;
1365             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1366         }
1367
1368         my $dispatcher = $class->dispatcher;
1369         my $engine     = $class->engine;
1370         my $home       = $class->config->{home};
1371
1372         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1373         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1374
1375         $home
1376           ? ( -d $home )
1377           ? $class->log->debug(qq/Found home "$home"/)
1378           : $class->log->debug(qq/Home "$home" doesn't exist/)
1379           : $class->log->debug(q/Couldn't find home/);
1380
1381         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1382         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1383         for my $comp ( sort keys %{ $class->components } ) {
1384             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1385             $t->row( $comp, $type );
1386         }
1387         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1388           if ( keys %{ $class->components } );
1389     }
1390
1391     # Add our self to components, since we are also a component
1392     if( $class->isa('Catalyst::Controller') ){
1393       $class->components->{$class} = $class;
1394     }
1395
1396     $class->setup_actions;
1397
1398     if ( $class->debug ) {
1399         my $name = $class->config->{name} || 'Application';
1400         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1401     }
1402
1403     if ($class->config->{case_sensitive}) {
1404         $class->log->warn($class . "->config->{case_sensitive} is set.");
1405         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1406     }
1407
1408     $class->setup_finalize;
1409
1410     # Flush the log for good measure (in case something turned off 'autoflush' early)
1411     $class->log->_flush() if $class->log->can('_flush');
1412
1413     return $class || 1; # Just in case someone named their Application 0...
1414 }
1415
1416 =head2 $app->setup_finalize
1417
1418 A hook to attach modifiers to. This method does not do anything except set the
1419 C<setup_finished> accessor.
1420
1421 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1422
1423 Example:
1424
1425     after setup_finalize => sub {
1426         my $app = shift;
1427
1428         ## do stuff here..
1429     };
1430
1431 =cut
1432
1433 sub setup_finalize {
1434     my ($class) = @_;
1435     $class->setup_finished(1);
1436 }
1437
1438 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1439
1440 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1441
1442 =head2 $c->uri_for( $action, [@captures, @args], \%query_values? )
1443
1444 Constructs an absolute L<URI> object based on the application root, the
1445 provided path, and the additional arguments and query parameters provided.
1446 When used as a string, provides a textual URI.  If you need more flexibility
1447 than this (i.e. the option to provide relative URIs etc.) see
1448 L<Catalyst::Plugin::SmartURI>.
1449
1450 If no arguments are provided, the URI for the current action is returned.
1451 To return the current action and also provide @args, use
1452 C<< $c->uri_for( $c->action, @args ) >>.
1453
1454 If the first argument is a string, it is taken as a public URI path relative
1455 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1456 relative to the application root (if it does). It is then merged with
1457 C<< $c->request->base >>; any C<@args> are appended as additional path
1458 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1459
1460 If the first argument is a L<Catalyst::Action> it represents an action which
1461 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1462 optional C<\@captures> argument (an arrayref) allows passing the captured
1463 variables that are needed to fill in the paths of Chained and Regex actions;
1464 once the path is resolved, C<uri_for> continues as though a path was
1465 provided, appending any arguments or parameters and creating an absolute
1466 URI.
1467
1468 The captures for the current request can be found in
1469 C<< $c->request->captures >>, and actions can be resolved using
1470 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1471 path, use C<< $c->uri_for_action >> instead.
1472
1473   # Equivalent to $c->req->uri
1474   $c->uri_for($c->action, $c->req->captures,
1475       @{ $c->req->args }, $c->req->params);
1476
1477   # For the Foo action in the Bar controller
1478   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1479
1480   # Path to a static resource
1481   $c->uri_for('/static/images/logo.png');
1482
1483 In general the scheme of the generated URI object will follow the incoming request
1484 however if your targeted action or action chain has the Scheme attribute it will
1485 use that instead.
1486
1487 Also, if the targeted Action or Action chain declares Args/CaptureArgs that have
1488 type constraints, we will require that your proposed URL verify on those declared
1489 constraints.
1490
1491 =cut
1492
1493 sub uri_for {
1494     my ( $c, $path, @args ) = @_;
1495
1496     if ( $path->$_isa('Catalyst::Controller') ) {
1497         $path = $path->path_prefix;
1498         $path =~ s{/+\z}{};
1499         $path .= '/';
1500     }
1501
1502     undef($path) if (defined $path && $path eq '');
1503
1504     my $params =
1505       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1506
1507     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1508
1509     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1510     if ( $path->$_isa('Catalyst::Action') ) { # action object
1511         s|/|%2F|g for @args;
1512         my $captures = [ map { s|/|%2F|g; $_; }
1513                         ( scalar @args && ref $args[0] eq 'ARRAY'
1514                          ? @{ shift(@args) }
1515                          : ()) ];
1516
1517         my $action = $path;
1518         my $expanded_action = $c->dispatcher->expand_action( $action );
1519         my $num_captures = $expanded_action->number_of_captures;
1520
1521         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1522         if( !@args && $action->number_of_args ) {
1523           unshift @args, splice @$captures, $num_captures;
1524         }
1525
1526         if($num_captures) {
1527           unless($expanded_action->match_captures_constraints($c, $captures)) {
1528             carp "captures [@{$captures}] do not match the type constraints in actionchain ending with '$expanded_action'";
1529             return;
1530           }
1531         }
1532
1533         $path = $c->dispatcher->uri_for_action($action, $captures);
1534         if (not defined $path) {
1535             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1536                 if $c->debug;
1537             return undef;
1538         }
1539         $path = '/' if $path eq '';
1540
1541         # At this point @encoded_args is the remaining Args (all captures removed).
1542         if($expanded_action->has_args_constraints) {
1543           unless($expanded_action->match_args($c,\@args)) {
1544              carp "args [@args] do not match the type constraints in action '$expanded_action'";
1545              return;
1546           }
1547         }
1548     }
1549
1550     unshift(@args, $path);
1551
1552     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1553         my $namespace = $c->namespace;
1554         if (defined $path) { # cheesy hack to handle path '../foo'
1555            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1556         }
1557         unshift(@args, $namespace || '');
1558     }
1559
1560     # join args with '/', or a blank string
1561     my $args = join('/', grep { defined($_) } @args);
1562     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1563     $args =~ s!^/+!!;
1564
1565     my ($base, $class) = ('/', 'URI::_generic');
1566     if(blessed($c)) {
1567       $base = $c->req->base;
1568       if($target_action) {
1569         $target_action = $c->dispatcher->expand_action($target_action);
1570         if(my $s = $target_action->scheme) {
1571           $s = lc($s);
1572           $class = "URI::$s";
1573           $base->scheme($s);
1574         } else {
1575           $class = ref($base);
1576         }
1577       } else {
1578         $class = ref($base);
1579       }
1580
1581       $base =~ s{(?<!/)$}{/};
1582     }
1583
1584     my $query = '';
1585
1586     if (my @keys = keys %$params) {
1587       # somewhat lifted from URI::_query's query_form
1588       $query = '?'.join('&', map {
1589           my $val = $params->{$_};
1590           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1591           s/ /+/g;
1592           my $key = $_;
1593           $val = '' unless defined $val;
1594           (map {
1595               my $param = "$_";
1596               $param = encode_utf8($param);
1597               # using the URI::Escape pattern here so utf8 chars survive
1598               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1599               $param =~ s/ /+/g;
1600
1601               $key = encode_utf8($key);
1602               # using the URI::Escape pattern here so utf8 chars survive
1603               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1604               $key =~ s/ /+/g;
1605
1606               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1607       } @keys);
1608     }
1609
1610     $base = encode_utf8 $base;
1611     $base =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1612     $args = encode_utf8 $args;
1613     $args =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1614
1615     my $res = bless(\"${base}${args}${query}", $class);
1616     $res;
1617 }
1618
1619 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1620
1621 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1622
1623 =over
1624
1625 =item $path
1626
1627 A private path to the Catalyst action you want to create a URI for.
1628
1629 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1630 >> and passing the resulting C<$action> and the remaining arguments to C<<
1631 $c->uri_for >>.
1632
1633 You can also pass in a Catalyst::Action object, in which case it is passed to
1634 C<< $c->uri_for >>.
1635
1636 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1637
1638 For example, if the action looks like:
1639
1640  package MyApp::Controller::Users;
1641
1642  sub lst : Path('the-list') {}
1643
1644 You can use:
1645
1646  $c->uri_for_action('/users/lst')
1647
1648 and it will create the URI /users/the-list.
1649
1650 =item \@captures_and_args?
1651
1652 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1653 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1654 to interpolate all the parameters in the URI.
1655
1656 =item @args?
1657
1658 Optional list of extra arguments - can be supplied in the
1659 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1660 code.
1661
1662 Your action can have zero, a fixed or a variable number of args (e.g.
1663 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1664
1665 =item \%query_values?
1666
1667 Optional array reference of query parameters to append. E.g.
1668
1669   { foo => 'bar' }
1670
1671 will generate
1672
1673   /rest/of/your/uri?foo=bar
1674
1675 =back
1676
1677 =cut
1678
1679 sub uri_for_action {
1680     my ( $c, $path, @args ) = @_;
1681     my $action = blessed($path)
1682       ? $path
1683       : $c->dispatcher->get_action_by_path($path);
1684     unless (defined $action) {
1685       croak "Can't find action for path '$path'";
1686     }
1687     return $c->uri_for( $action, @args );
1688 }
1689
1690 =head2 $c->welcome_message
1691
1692 Returns the Catalyst welcome HTML page.
1693
1694 =cut
1695
1696 sub welcome_message {
1697     my $c      = shift;
1698     my $name   = $c->config->{name};
1699     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1700     my $prefix = Catalyst::Utils::appprefix( ref $c );
1701     $c->response->content_type('text/html; charset=utf-8');
1702     return <<"EOF";
1703 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1704     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1705 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1706     <head>
1707     <meta http-equiv="Content-Language" content="en" />
1708     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1709         <title>$name on Catalyst $VERSION</title>
1710         <style type="text/css">
1711             body {
1712                 color: #000;
1713                 background-color: #eee;
1714             }
1715             div#content {
1716                 width: 640px;
1717                 margin-left: auto;
1718                 margin-right: auto;
1719                 margin-top: 10px;
1720                 margin-bottom: 10px;
1721                 text-align: left;
1722                 background-color: #ccc;
1723                 border: 1px solid #aaa;
1724             }
1725             p, h1, h2 {
1726                 margin-left: 20px;
1727                 margin-right: 20px;
1728                 font-family: verdana, tahoma, sans-serif;
1729             }
1730             a {
1731                 font-family: verdana, tahoma, sans-serif;
1732             }
1733             :link, :visited {
1734                     text-decoration: none;
1735                     color: #b00;
1736                     border-bottom: 1px dotted #bbb;
1737             }
1738             :link:hover, :visited:hover {
1739                     color: #555;
1740             }
1741             div#topbar {
1742                 margin: 0px;
1743             }
1744             pre {
1745                 margin: 10px;
1746                 padding: 8px;
1747             }
1748             div#answers {
1749                 padding: 8px;
1750                 margin: 10px;
1751                 background-color: #fff;
1752                 border: 1px solid #aaa;
1753             }
1754             h1 {
1755                 font-size: 0.9em;
1756                 font-weight: normal;
1757                 text-align: center;
1758             }
1759             h2 {
1760                 font-size: 1.0em;
1761             }
1762             p {
1763                 font-size: 0.9em;
1764             }
1765             p img {
1766                 float: right;
1767                 margin-left: 10px;
1768             }
1769             span#appname {
1770                 font-weight: bold;
1771                 font-size: 1.6em;
1772             }
1773         </style>
1774     </head>
1775     <body>
1776         <div id="content">
1777             <div id="topbar">
1778                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1779                     $VERSION</h1>
1780              </div>
1781              <div id="answers">
1782                  <p>
1783                  <img src="$logo" alt="Catalyst Logo" />
1784                  </p>
1785                  <p>Welcome to the  world of Catalyst.
1786                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1787                     framework will make web development something you had
1788                     never expected it to be: Fun, rewarding, and quick.</p>
1789                  <h2>What to do now?</h2>
1790                  <p>That really depends  on what <b>you</b> want to do.
1791                     We do, however, provide you with a few starting points.</p>
1792                  <p>If you want to jump right into web development with Catalyst
1793                     you might want to start with a tutorial.</p>
1794 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1795 </pre>
1796 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1797 <pre>
1798 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1799 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1800 </code></pre>
1801                  <h2>What to do next?</h2>
1802                  <p>Next it's time to write an actual application. Use the
1803                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1804                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1805                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1806                     they can save you a lot of work.</p>
1807                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1808                     <p>Also, be sure to check out the vast and growing
1809                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1810                     you are likely to find what you need there.
1811                     </p>
1812
1813                  <h2>Need help?</h2>
1814                  <p>Catalyst has a very active community. Here are the main places to
1815                     get in touch with us.</p>
1816                  <ul>
1817                      <li>
1818                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1819                      </li>
1820                      <li>
1821                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1822                      </li>
1823                      <li>
1824                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1825                      </li>
1826                  </ul>
1827                  <h2>In conclusion</h2>
1828                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1829                     as we enjoyed making it. Please contact us if you have ideas
1830                     for improvement or other feedback.</p>
1831              </div>
1832          </div>
1833     </body>
1834 </html>
1835 EOF
1836 }
1837
1838 =head2 run_options
1839
1840 Contains a hash of options passed from the application script, including
1841 the original ARGV the script received, the processed values from that
1842 ARGV and any extra arguments to the script which were not processed.
1843
1844 This can be used to add custom options to your application's scripts
1845 and setup your application differently depending on the values of these
1846 options.
1847
1848 =head1 INTERNAL METHODS
1849
1850 These methods are not meant to be used by end users.
1851
1852 =head2 $c->components
1853
1854 Returns a hash of components.
1855
1856 =head2 $c->context_class
1857
1858 Returns or sets the context class.
1859
1860 =head2 $c->counter
1861
1862 Returns a hashref containing coderefs and execution counts (needed for
1863 deep recursion detection).
1864
1865 =head2 $c->depth
1866
1867 Returns the number of actions on the current internal execution stack.
1868
1869 =head2 $c->dispatch
1870
1871 Dispatches a request to actions.
1872
1873 =cut
1874
1875 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1876
1877 =head2 $c->dispatcher_class
1878
1879 Returns or sets the dispatcher class.
1880
1881 =head2 $c->dump_these
1882
1883 Returns a list of 2-element array references (name, structure) pairs
1884 that will be dumped on the error page in debug mode.
1885
1886 =cut
1887
1888 sub dump_these {
1889     my $c = shift;
1890     [ Request => $c->req ],
1891     [ Response => $c->res ],
1892     [ Stash => $c->stash ],
1893     [ Config => $c->config ];
1894 }
1895
1896 =head2 $c->engine_class
1897
1898 Returns or sets the engine class.
1899
1900 =head2 $c->execute( $class, $coderef )
1901
1902 Execute a coderef in given class and catch exceptions. Errors are available
1903 via $c->error.
1904
1905 =cut
1906
1907 sub execute {
1908     my ( $c, $class, $code ) = @_;
1909     $class = $c->component($class) || $class;
1910     $c->state(0);
1911
1912     if ( $c->depth >= $RECURSION ) {
1913         my $action = $code->reverse();
1914         $action = "/$action" unless $action =~ /->/;
1915         my $error = qq/Deep recursion detected calling "${action}"/;
1916         $c->log->error($error);
1917         $c->error($error);
1918         $c->state(0);
1919         return $c->state;
1920     }
1921
1922     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1923
1924     push( @{ $c->stack }, $code );
1925
1926     no warnings 'recursion';
1927     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1928     #      I have no idea how, ergo $ret (which appears to fix the issue)
1929     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1930
1931     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1932
1933     my $last = pop( @{ $c->stack } );
1934
1935     if ( my $error = $@ ) {
1936         #rethow if this can be handled by middleware
1937         if ( $c->_handle_http_exception($error) ) {
1938             foreach my $err (@{$c->error}) {
1939                 $c->log->error($err);
1940             }
1941             $c->clear_errors;
1942             $c->log->_flush if $c->log->can('_flush');
1943
1944             $error->can('rethrow') ? $error->rethrow : croak $error;
1945         }
1946         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1947             $error->rethrow if $c->depth > 1;
1948         }
1949         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1950             $error->rethrow if $c->depth > 0;
1951         }
1952         else {
1953             unless ( ref $error ) {
1954                 no warnings 'uninitialized';
1955                 chomp $error;
1956                 my $class = $last->class;
1957                 my $name  = $last->name;
1958                 $error = qq/Caught exception in $class->$name "$error"/;
1959             }
1960             $c->error($error);
1961         }
1962         $c->state(0);
1963     }
1964     return $c->state;
1965 }
1966
1967 sub _stats_start_execute {
1968     my ( $c, $code ) = @_;
1969     my $appclass = ref($c) || $c;
1970     return if ( ( $code->name =~ /^_.*/ )
1971         && ( !$appclass->config->{show_internal_actions} ) );
1972
1973     my $action_name = $code->reverse();
1974     $c->counter->{$action_name}++;
1975
1976     my $action = $action_name;
1977     $action = "/$action" unless $action =~ /->/;
1978
1979     # determine if the call was the result of a forward
1980     # this is done by walking up the call stack and looking for a calling
1981     # sub of Catalyst::forward before the eval
1982     my $callsub = q{};
1983     for my $index ( 2 .. 11 ) {
1984         last
1985         if ( ( caller($index) )[0] eq 'Catalyst'
1986             && ( caller($index) )[3] eq '(eval)' );
1987
1988         if ( ( caller($index) )[3] =~ /forward$/ ) {
1989             $callsub = ( caller($index) )[3];
1990             $action  = "-> $action";
1991             last;
1992         }
1993     }
1994
1995     my $uid = $action_name . $c->counter->{$action_name};
1996
1997     # is this a root-level call or a forwarded call?
1998     if ( $callsub =~ /forward$/ ) {
1999         my $parent = $c->stack->[-1];
2000
2001         # forward, locate the caller
2002         if ( defined $parent && exists $c->counter->{"$parent"} ) {
2003             $c->stats->profile(
2004                 begin  => $action,
2005                 parent => "$parent" . $c->counter->{"$parent"},
2006                 uid    => $uid,
2007             );
2008         }
2009         else {
2010
2011             # forward with no caller may come from a plugin
2012             $c->stats->profile(
2013                 begin => $action,
2014                 uid   => $uid,
2015             );
2016         }
2017     }
2018     else {
2019
2020         # root-level call
2021         $c->stats->profile(
2022             begin => $action,
2023             uid   => $uid,
2024         );
2025     }
2026     return $action;
2027
2028 }
2029
2030 sub _stats_finish_execute {
2031     my ( $c, $info ) = @_;
2032     $c->stats->profile( end => $info );
2033 }
2034
2035 =head2 $c->finalize
2036
2037 Finalizes the request.
2038
2039 =cut
2040
2041 sub finalize {
2042     my $c = shift;
2043
2044     for my $error ( @{ $c->error } ) {
2045         $c->log->error($error);
2046     }
2047
2048     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
2049     # stuff like cometd and websockets
2050
2051     if($c->request->_has_io_fh) {
2052       $c->log_response;
2053       return;
2054     }
2055
2056     # Allow engine to handle finalize flow (for POE)
2057     my $engine = $c->engine;
2058     if ( my $code = $engine->can('finalize') ) {
2059         $engine->$code($c);
2060     }
2061     else {
2062
2063         $c->finalize_uploads;
2064
2065         # Error
2066         if ( $#{ $c->error } >= 0 ) {
2067             $c->finalize_error;
2068         }
2069
2070         $c->finalize_encoding;
2071         $c->finalize_headers unless $c->response->finalized_headers;
2072         $c->finalize_body;
2073     }
2074
2075     $c->log_response;
2076
2077     if ($c->use_stats) {
2078         my $elapsed = $c->stats->elapsed;
2079         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2080         $c->log->info(
2081             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2082     }
2083
2084     return $c->response->status;
2085 }
2086
2087 =head2 $c->finalize_body
2088
2089 Finalizes body.
2090
2091 =cut
2092
2093 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2094
2095 =head2 $c->finalize_cookies
2096
2097 Finalizes cookies.
2098
2099 =cut
2100
2101 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2102
2103 =head2 $c->finalize_error
2104
2105 Finalizes error.  If there is only one error in L</error> and it is an object that
2106 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2107 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2108 return the default error page (production mode).
2109
2110 =cut
2111
2112 sub finalize_error {
2113     my $c = shift;
2114     if($#{$c->error} > 0) {
2115         $c->engine->finalize_error( $c, @_ );
2116     } else {
2117         my ($error) = @{$c->error};
2118         if ( $c->_handle_http_exception($error) ) {
2119             # In the case where the error 'knows what it wants', becauses its PSGI
2120             # aware, just rethow and let middleware catch it
2121             $error->can('rethrow') ? $error->rethrow : croak $error;
2122         } else {
2123             $c->engine->finalize_error( $c, @_ )
2124         }
2125     }
2126 }
2127
2128 =head2 $c->finalize_headers
2129
2130 Finalizes headers.
2131
2132 =cut
2133
2134 sub finalize_headers {
2135     my $c = shift;
2136
2137     my $response = $c->response; #accessor calls can add up?
2138
2139     # Check if we already finalized headers
2140     return if $response->finalized_headers;
2141
2142     # Handle redirects
2143     if ( my $location = $response->redirect ) {
2144         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2145         $response->header( Location => $location );
2146     }
2147
2148     # Remove incorrectly added body and content related meta data when returning
2149     # an information response, or a response the is required to not include a body
2150
2151     $c->finalize_cookies;
2152
2153     # This currently is a NOOP but I don't want to remove it since I guess people
2154     # might have Response subclasses that use it for something... (JNAP)
2155     $c->response->finalize_headers();
2156
2157     # Done
2158     $response->finalized_headers(1);
2159 }
2160
2161 =head2 $c->finalize_encoding
2162
2163 Make sure your body is encoded properly IF you set an encoding.  By
2164 default the encoding is UTF-8 but you can disable it by explicitly setting the
2165 encoding configuration value to undef.
2166
2167 We can only encode when the body is a scalar.  Methods for encoding via the
2168 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2169 are available).
2170
2171 See L</ENCODING>.
2172
2173 =cut
2174
2175 sub finalize_encoding {
2176     my $c = shift;
2177     my $res = $c->res || return;
2178
2179     # Warn if the set charset is different from the one you put into encoding.  We need
2180     # to do this early since encodable_response is false for this condition and we need
2181     # to match the debug output for backcompat (there's a test for this...) -JNAP
2182     if(
2183       $res->content_type_charset and $c->encoding and
2184       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2185     ) {
2186         my $ct = lc($res->content_type_charset);
2187         $c->log->debug("Catalyst encoding config is set to encode in '" .
2188             $c->encoding->mime_name .
2189             "', content type is '$ct', not encoding ");
2190     }
2191
2192     if(
2193       ($res->encodable_response) and
2194       (defined($res->body)) and
2195       (ref(\$res->body) eq 'SCALAR')
2196     ) {
2197         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2198
2199         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2200         # is false when the set charset is not the same as the encoding mimetype (maybe
2201         # confusing action at a distance here..
2202         # Don't try to set the charset if one already exists
2203         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2204           unless($c->res->content_type_charset);
2205     }
2206 }
2207
2208 =head2 $c->finalize_output
2209
2210 An alias for finalize_body.
2211
2212 =head2 $c->finalize_read
2213
2214 Finalizes the input after reading is complete.
2215
2216 =cut
2217
2218 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2219
2220 =head2 $c->finalize_uploads
2221
2222 Finalizes uploads. Cleans up any temporary files.
2223
2224 =cut
2225
2226 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2227
2228 =head2 $c->get_action( $action, $namespace )
2229
2230 Gets an action in a given namespace.
2231
2232 =cut
2233
2234 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2235
2236 =head2 $c->get_actions( $action, $namespace )
2237
2238 Gets all actions of a given name in a namespace and all parent
2239 namespaces.
2240
2241 =cut
2242
2243 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2244
2245 =head2 $app->handle_request( @arguments )
2246
2247 Called to handle each HTTP request.
2248
2249 =cut
2250
2251 sub handle_request {
2252     my ( $class, @arguments ) = @_;
2253
2254     # Always expect worst case!
2255     my $status = -1;
2256     try {
2257         if ($class->debug) {
2258             my $secs = time - $START || 1;
2259             my $av = sprintf '%.3f', $COUNT / $secs;
2260             my $time = localtime time;
2261             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2262         }
2263
2264         my $c = $class->prepare(@arguments);
2265         $c->dispatch;
2266         $status = $c->finalize;
2267     } catch {
2268         #rethow if this can be handled by middleware
2269         if ( $class->_handle_http_exception($_) ) {
2270             $_->can('rethrow') ? $_->rethrow : croak $_;
2271         }
2272         chomp(my $error = $_);
2273         $class->log->error(qq/Caught exception in engine "$error"/);
2274     };
2275
2276     $COUNT++;
2277
2278     if(my $coderef = $class->log->can('_flush')){
2279         $class->log->$coderef();
2280     }
2281     return $status;
2282 }
2283
2284 =head2 $class->prepare( @arguments )
2285
2286 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2287 etc.).
2288
2289 =cut
2290
2291 has _uploadtmp => (
2292     is => 'ro',
2293     predicate => '_has_uploadtmp',
2294 );
2295
2296 sub prepare {
2297     my ( $class, @arguments ) = @_;
2298
2299     # XXX
2300     # After the app/ctxt split, this should become an attribute based on something passed
2301     # into the application.
2302     $class->context_class( ref $class || $class ) unless $class->context_class;
2303
2304     my $uploadtmp = $class->config->{uploadtmp};
2305     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2306
2307     $c->response->_context($c);
2308
2309     $c->stats($class->stats_class->new)->enable($c->use_stats);
2310
2311     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2312         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2313     }
2314
2315     try {
2316         # Allow engine to direct the prepare flow (for POE)
2317         if ( my $prepare = $c->engine->can('prepare') ) {
2318             $c->engine->$prepare( $c, @arguments );
2319         }
2320         else {
2321             $c->prepare_request(@arguments);
2322             $c->prepare_connection;
2323             $c->prepare_query_parameters;
2324             $c->prepare_headers; # Just hooks, no longer needed - they just
2325             $c->prepare_cookies; # cause the lazy attribute on req to build
2326             $c->prepare_path;
2327
2328             # Prepare the body for reading, either by prepare_body
2329             # or the user, if they are using $c->read
2330             $c->prepare_read;
2331
2332             # Parse the body unless the user wants it on-demand
2333             unless ( ref($c)->config->{parse_on_demand} ) {
2334                 $c->prepare_body;
2335             }
2336         }
2337         $c->prepare_action;
2338     }
2339     # VERY ugly and probably shouldn't rely on ->finalize actually working
2340     catch {
2341         # failed prepare is always due to an invalid request, right?
2342         $c->response->status(400);
2343         $c->response->content_type('text/plain');
2344         $c->response->body('Bad Request');
2345         # Note we call finalize and then die here, which escapes
2346         # finalize being called in the enclosing block..
2347         # It in fact couldn't be called, as we don't return $c..
2348         # This is a mess - but I'm unsure you can fix this without
2349         # breaking compat for people doing crazy things (we should set
2350         # the 400 and just return the ctx here IMO, letting finalize get called
2351         # above...
2352         $c->finalize;
2353         die $_;
2354     };
2355
2356     $c->log_request;
2357
2358     return $c;
2359 }
2360
2361 =head2 $c->prepare_action
2362
2363 Prepares action. See L<Catalyst::Dispatcher>.
2364
2365 =cut
2366
2367 sub prepare_action {
2368     my $c = shift;
2369     my $ret = $c->dispatcher->prepare_action( $c, @_);
2370
2371     if($c->encoding) {
2372         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2373           $_ = $c->_handle_param_unicode_decoding($_);
2374         }
2375     }
2376
2377     return $ret;
2378 }
2379
2380
2381 =head2 $c->prepare_body
2382
2383 Prepares message body.
2384
2385 =cut
2386
2387 sub prepare_body {
2388     my $c = shift;
2389
2390     return if $c->request->_has_body;
2391
2392     # Initialize on-demand data
2393     $c->engine->prepare_body( $c, @_ );
2394     $c->prepare_parameters;
2395     $c->prepare_uploads;
2396 }
2397
2398 =head2 $c->prepare_body_chunk( $chunk )
2399
2400 Prepares a chunk of data before sending it to L<HTTP::Body>.
2401
2402 See L<Catalyst::Engine>.
2403
2404 =cut
2405
2406 sub prepare_body_chunk {
2407     my $c = shift;
2408     $c->engine->prepare_body_chunk( $c, @_ );
2409 }
2410
2411 =head2 $c->prepare_body_parameters
2412
2413 Prepares body parameters.
2414
2415 =cut
2416
2417 sub prepare_body_parameters {
2418     my $c = shift;
2419     $c->request->prepare_body_parameters( $c, @_ );
2420 }
2421
2422 =head2 $c->prepare_connection
2423
2424 Prepares connection.
2425
2426 =cut
2427
2428 sub prepare_connection {
2429     my $c = shift;
2430     $c->request->prepare_connection($c);
2431 }
2432
2433 =head2 $c->prepare_cookies
2434
2435 Prepares cookies by ensuring that the attribute on the request
2436 object has been built.
2437
2438 =cut
2439
2440 sub prepare_cookies { my $c = shift; $c->request->cookies }
2441
2442 =head2 $c->prepare_headers
2443
2444 Prepares request headers by ensuring that the attribute on the request
2445 object has been built.
2446
2447 =cut
2448
2449 sub prepare_headers { my $c = shift; $c->request->headers }
2450
2451 =head2 $c->prepare_parameters
2452
2453 Prepares parameters.
2454
2455 =cut
2456
2457 sub prepare_parameters {
2458     my $c = shift;
2459     $c->prepare_body_parameters;
2460     $c->engine->prepare_parameters( $c, @_ );
2461 }
2462
2463 =head2 $c->prepare_path
2464
2465 Prepares path and base.
2466
2467 =cut
2468
2469 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2470
2471 =head2 $c->prepare_query_parameters
2472
2473 Prepares query parameters.
2474
2475 =cut
2476
2477 sub prepare_query_parameters {
2478     my $c = shift;
2479
2480     $c->engine->prepare_query_parameters( $c, @_ );
2481 }
2482
2483 =head2 $c->log_request
2484
2485 Writes information about the request to the debug logs.  This includes:
2486
2487 =over 4
2488
2489 =item * Request method, path, and remote IP address
2490
2491 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2492
2493 =item * Request parameters
2494
2495 =item * File uploads
2496
2497 =back
2498
2499 =cut
2500
2501 sub log_request {
2502     my $c = shift;
2503
2504     return unless $c->debug;
2505
2506     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2507     my $request = $dump->[1];
2508
2509     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2510     $method ||= '';
2511     $path = '/' unless length $path;
2512     $address ||= '';
2513
2514     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2515     $path = decode_utf8($path);
2516
2517     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2518
2519     $c->log_request_headers($request->headers);
2520
2521     if ( my $keywords = $request->query_keywords ) {
2522         $c->log->debug("Query keywords are: $keywords");
2523     }
2524
2525     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2526
2527     $c->log_request_uploads($request);
2528 }
2529
2530 =head2 $c->log_response
2531
2532 Writes information about the response to the debug logs by calling
2533 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2534
2535 =cut
2536
2537 sub log_response {
2538     my $c = shift;
2539
2540     return unless $c->debug;
2541
2542     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2543     my $response = $dump->[1];
2544
2545     $c->log_response_status_line($response);
2546     $c->log_response_headers($response->headers);
2547 }
2548
2549 =head2 $c->log_response_status_line($response)
2550
2551 Writes one line of information about the response to the debug logs.  This includes:
2552
2553 =over 4
2554
2555 =item * Response status code
2556
2557 =item * Content-Type header (if present)
2558
2559 =item * Content-Length header (if present)
2560
2561 =back
2562
2563 =cut
2564
2565 sub log_response_status_line {
2566     my ($c, $response) = @_;
2567
2568     $c->log->debug(
2569         sprintf(
2570             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2571             $response->status                            || 'unknown',
2572             $response->headers->header('Content-Type')   || 'unknown',
2573             $response->headers->header('Content-Length') || 'unknown'
2574         )
2575     );
2576 }
2577
2578 =head2 $c->log_response_headers($headers);
2579
2580 Hook method which can be wrapped by plugins to log the response headers.
2581 No-op in the default implementation.
2582
2583 =cut
2584
2585 sub log_response_headers {}
2586
2587 =head2 $c->log_request_parameters( query => {}, body => {} )
2588
2589 Logs request parameters to debug logs
2590
2591 =cut
2592
2593 sub log_request_parameters {
2594     my $c          = shift;
2595     my %all_params = @_;
2596
2597     return unless $c->debug;
2598
2599     my $column_width = Catalyst::Utils::term_width() - 44;
2600     foreach my $type (qw(query body)) {
2601         my $params = $all_params{$type};
2602         next if ! keys %$params;
2603         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2604         for my $key ( sort keys %$params ) {
2605             my $param = $params->{$key};
2606             my $value = defined($param) ? $param : '';
2607             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2608         }
2609         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2610     }
2611 }
2612
2613 =head2 $c->log_request_uploads
2614
2615 Logs file uploads included in the request to the debug logs.
2616 The parameter name, filename, file type, and file size are all included in
2617 the debug logs.
2618
2619 =cut
2620
2621 sub log_request_uploads {
2622     my $c = shift;
2623     my $request = shift;
2624     return unless $c->debug;
2625     my $uploads = $request->uploads;
2626     if ( keys %$uploads ) {
2627         my $t = Text::SimpleTable->new(
2628             [ 12, 'Parameter' ],
2629             [ 26, 'Filename' ],
2630             [ 18, 'Type' ],
2631             [ 9,  'Size' ]
2632         );
2633         for my $key ( sort keys %$uploads ) {
2634             my $upload = $uploads->{$key};
2635             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2636                 $t->row( $key, $u->filename, $u->type, $u->size );
2637             }
2638         }
2639         $c->log->debug( "File Uploads are:\n" . $t->draw );
2640     }
2641 }
2642
2643 =head2 $c->log_request_headers($headers);
2644
2645 Hook method which can be wrapped by plugins to log the request headers.
2646 No-op in the default implementation.
2647
2648 =cut
2649
2650 sub log_request_headers {}
2651
2652 =head2 $c->log_headers($type => $headers)
2653
2654 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2655
2656 =cut
2657
2658 sub log_headers {
2659     my $c       = shift;
2660     my $type    = shift;
2661     my $headers = shift;    # an HTTP::Headers instance
2662
2663     return unless $c->debug;
2664
2665     my $column_width = Catalyst::Utils::term_width() - 28;
2666     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2667     $headers->scan(
2668         sub {
2669             my ( $name, $value ) = @_;
2670             $t->row( $name, $value );
2671         }
2672     );
2673     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2674 }
2675
2676
2677 =head2 $c->prepare_read
2678
2679 Prepares the input for reading.
2680
2681 =cut
2682
2683 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2684
2685 =head2 $c->prepare_request
2686
2687 Prepares the engine request.
2688
2689 =cut
2690
2691 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2692
2693 =head2 $c->prepare_uploads
2694
2695 Prepares uploads.
2696
2697 =cut
2698
2699 sub prepare_uploads {
2700     my $c = shift;
2701     $c->engine->prepare_uploads( $c, @_ );
2702 }
2703
2704 =head2 $c->prepare_write
2705
2706 Prepares the output for writing.
2707
2708 =cut
2709
2710 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2711
2712 =head2 $c->request_class
2713
2714 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2715
2716 =head2 $app->request_class_traits
2717
2718 An arrayref of L<Moose::Role>s which are applied to the request class.
2719
2720 =head2 $app->composed_request_class
2721
2722 This is the request class which has been composed with any request_class_traits.
2723
2724 =head2 $c->response_class
2725
2726 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2727
2728 =head2 $app->response_class_traits
2729
2730 An arrayref of L<Moose::Role>s which are applied to the response class.
2731
2732 =head2 $app->composed_response_class
2733
2734 This is the request class which has been composed with any response_class_traits.
2735
2736 =head2 $c->read( [$maxlength] )
2737
2738 Reads a chunk of data from the request body. This method is designed to
2739 be used in a while loop, reading C<$maxlength> bytes on every call.
2740 C<$maxlength> defaults to the size of the request if not specified.
2741
2742 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2743 directly.
2744
2745 Warning: If you use read(), Catalyst will not process the body,
2746 so you will not be able to access POST parameters or file uploads via
2747 $c->request.  You must handle all body parsing yourself.
2748
2749 =cut
2750
2751 sub read { my $c = shift; return $c->request->read( @_ ) }
2752
2753 =head2 $c->run
2754
2755 Starts the engine.
2756
2757 =cut
2758
2759 sub run {
2760   my $app = shift;
2761   $app->_make_immutable_if_needed;
2762   $app->engine_loader->needs_psgi_engine_compat_hack ?
2763     $app->engine->run($app, @_) :
2764       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2765 }
2766
2767 sub _make_immutable_if_needed {
2768     my $class = shift;
2769     my $meta = find_meta($class);
2770     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2771     if (
2772         $meta->is_immutable
2773         && ! { $meta->immutable_options }->{replace_constructor}
2774         && $isa_ca
2775     ) {
2776         warn("You made your application class ($class) immutable, "
2777             . "but did not inline the\nconstructor. "
2778             . "This will break catalyst, as your app \@ISA "
2779             . "Class::Accessor(::Fast)?\nPlease pass "
2780             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2781     }
2782     unless ($meta->is_immutable) {
2783         # XXX - FIXME warning here as you should make your app immutable yourself.
2784         $meta->make_immutable(
2785             replace_constructor => 1,
2786         );
2787     }
2788 }
2789
2790 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2791
2792 Sets an action in a given namespace.
2793
2794 =cut
2795
2796 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2797
2798 =head2 $c->setup_actions($component)
2799
2800 Sets up actions for a component.
2801
2802 =cut
2803
2804 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2805
2806 =head2 $c->setup_components
2807
2808 This method is called internally to set up the application's components.
2809
2810 It finds modules by calling the L<locate_components> method, expands them to
2811 package names with the L<expand_component_module> method, and then installs
2812 each component into the application.
2813
2814 The C<setup_components> config option is passed to both of the above methods.
2815
2816 Installation of each component is performed by the L<setup_component> method,
2817 below.
2818
2819 =cut
2820
2821 sub setup_components {
2822     my $class = shift;
2823
2824     my $config  = $class->config->{ setup_components };
2825
2826     my @comps = $class->locate_components($config);
2827     my %comps = map { $_ => 1 } @comps;
2828
2829     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2830     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2831         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2832     ) if $deprecatedcatalyst_component_names;
2833
2834     for my $component ( @comps ) {
2835
2836         # We pass ignore_loaded here so that overlay files for (e.g.)
2837         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2838         # we know M::P::O found a file on disk so this is safe
2839
2840         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2841     }
2842
2843     for my $component (@comps) {
2844         my $instance = $class->components->{ $component } = $class->delayed_setup_component($component);
2845     }
2846
2847     # Inject a component or wrap a stand alone class in an adaptor. This makes a list
2848     # of named components in the configuration that are not actually existing (not a
2849     # real file).
2850
2851     my @injected_components = $class->setup_injected_components;
2852
2853     # All components are registered, now we need to 'init' them.
2854     foreach my $component_name (@comps, @injected_components) {
2855       $class->components->{$component_name} = $class->components->{$component_name}->() if
2856         (ref($class->components->{$component_name}) || '') eq 'CODE';
2857     }
2858 }
2859
2860 =head2 $app->setup_injected_components
2861
2862 Called by setup_compoents to setup components that are injected.
2863
2864 =cut
2865
2866 sub setup_injected_components {
2867     my ($class) = @_;
2868     my @injected_components = keys %{$class->config->{inject_components} ||+{}};
2869
2870     foreach my $injected_comp_name(@injected_components) {
2871         $class->setup_injected_component(
2872           $injected_comp_name,
2873           $class->config->{inject_components}->{$injected_comp_name});
2874     }
2875
2876     return @injected_components;
2877 }
2878
2879 =head2 $app->setup_injected_component( $injected_component_name, $config )
2880
2881 Setup a given injected component.
2882
2883 =cut
2884
2885 sub setup_injected_component {
2886     my ($class, $injected_comp_name, $config) = @_;
2887     if(my $component_class = $config->{from_component}) {
2888         my @roles = @{$config->{roles} ||[]};
2889         Catalyst::Utils::inject_component(
2890           into => $class,
2891           component => $component_class,
2892           (scalar(@roles) ? (traits => \@roles) : ()),
2893           as => $injected_comp_name);
2894     }
2895 }
2896
2897 =head2 $app->inject_component($MyApp_Component_name => \%args);
2898
2899 Add a component that is injected at setup:
2900
2901     MyApp->inject_component( 'Model::Foo' => { from_component => 'Common::Foo' } );
2902
2903 Must be called before ->setup.  Expects a component name for your
2904 current application and \%args where
2905
2906 =over 4
2907
2908 =item from_component
2909
2910 The target component being injected into your application
2911
2912 =item roles
2913
2914 An arrayref of L<Moose::Role>s that are applied to your component.
2915
2916 =back
2917
2918 Example
2919
2920     MyApp->inject_component(
2921       'Model::Foo' => {
2922         from_component => 'Common::Model::Foo',
2923         roles => ['Role1', 'Role2'],
2924       });
2925
2926 =head2 $app->inject_components
2927
2928 Inject a list of components:
2929
2930     MyApp->inject_components(
2931       'Model::FooOne' => {
2932         from_component => 'Common::Model::Foo',
2933         roles => ['Role1', 'Role2'],
2934       },
2935       'Model::FooTwo' => {
2936         from_component => 'Common::Model::Foo',
2937         roles => ['Role1', 'Role2'],
2938       });
2939
2940 =cut
2941
2942 sub inject_component {
2943   my ($app, $name, $args) = @_;
2944   die "Component $name exists" if
2945     $app->config->{inject_components}->{$name};
2946   $app->config->{inject_components}->{$name} = $args;
2947 }
2948
2949 sub inject_components {
2950   my $app = shift;
2951   while(@_) {
2952     $app->inject_component(shift, shift);
2953   }
2954 }
2955
2956 =head2 $c->locate_components( $setup_component_config )
2957
2958 This method is meant to provide a list of component modules that should be
2959 setup for the application.  By default, it will use L<Module::Pluggable>.
2960
2961 Specify a C<setup_components> config option to pass additional options directly
2962 to L<Module::Pluggable>. To add additional search paths, specify a key named
2963 C<search_extra> as an array reference. Items in the array beginning with C<::>
2964 will have the application class name prepended to them.
2965
2966 =cut
2967
2968 sub locate_components {
2969     my $class  = shift;
2970     my $config = shift;
2971
2972     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
2973     my $extra   = delete $config->{ search_extra } || [];
2974
2975     unshift @paths, @$extra;
2976
2977     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
2978       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
2979       %$config
2980     )->plugins } @paths;
2981
2982     return @comps;
2983 }
2984
2985 =head2 $c->expand_component_module( $component, $setup_component_config )
2986
2987 Components found by C<locate_components> will be passed to this method, which
2988 is expected to return a list of component (package) names to be set up.
2989
2990 =cut
2991
2992 sub expand_component_module {
2993     my ($class, $module) = @_;
2994     return Devel::InnerPackage::list_packages( $module );
2995 }
2996
2997 =head2 $app->delayed_setup_component
2998
2999 Returns a coderef that points to a setup_component instance.  Used
3000 internally for when you want to delay setup until the first time
3001 the component is called.
3002
3003 =cut
3004
3005 sub delayed_setup_component {
3006   my($class, $component, @more) = @_;
3007   return sub {
3008     return my $instance = $class->setup_component($component, @more);
3009   };
3010 }
3011
3012 =head2 $c->setup_component
3013
3014 =cut
3015
3016 sub setup_component {
3017     my( $class, $component ) = @_;
3018
3019     unless ( $component->can( 'COMPONENT' ) ) {
3020         return $component;
3021     }
3022
3023     my $config = $class->config_for($component);
3024     # Stash catalyst_component_name in the config here, so that custom COMPONENT
3025     # methods also pass it. local to avoid pointlessly shitting in config
3026     # for the debug screen, as $component is already the key name.
3027     local $config->{catalyst_component_name} = $component;
3028
3029     my $instance = eval {
3030       $component->COMPONENT( $class, $config );
3031     } || do {
3032       my $error = $@;
3033       chomp $error;
3034       Catalyst::Exception->throw(
3035         message => qq/Couldn't instantiate component "$component", "$error"/
3036       );
3037     };
3038
3039     unless (blessed $instance) {
3040         my $metaclass = Moose::Util::find_meta($component);
3041         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
3042         my $component_method_from = $method_meta->associated_metaclass->name;
3043         my $value = defined($instance) ? $instance : 'undef';
3044         Catalyst::Exception->throw(
3045             message =>
3046             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
3047         );
3048     }
3049
3050     my @expanded_components = $instance->can('expand_modules')
3051       ? $instance->expand_modules( $component, $config )
3052       : $class->expand_component_module( $component, $config );
3053     for my $component (@expanded_components) {
3054       next if $class->components->{ $component };
3055       $class->components->{ $component } = $class->setup_component($component);
3056     }
3057
3058     return $instance;
3059 }
3060
3061 =head2 $app->config_for( $component_name )
3062
3063 Return the application level configuration (which is not yet merged with any
3064 local component configuration, via $component_class->config) for the named
3065 component or component object. Example:
3066
3067     MyApp->config(
3068       'Model::Foo' => { a => 1, b => 2},
3069     );
3070
3071     my $config = MyApp->config_for('MyApp::Model::Foo');
3072
3073 In this case $config is the hashref C< {a=>1, b=>2} >.
3074
3075 This is also handy for looking up configuration for a plugin, to make sure you follow
3076 existing L<Catalyst> standards for where a plugin should put its configuration.
3077
3078 =cut
3079
3080 sub config_for {
3081     my ($class, $component_name) = @_;
3082     my $component_suffix = Catalyst::Utils::class2classsuffix($component_name);
3083     my $config = $class->config->{ $component_suffix } || {};
3084
3085     return $config;
3086 }
3087
3088 =head2 $c->setup_dispatcher
3089
3090 Sets up dispatcher.
3091
3092 =cut
3093
3094 sub setup_dispatcher {
3095     my ( $class, $dispatcher ) = @_;
3096
3097     if ($dispatcher) {
3098         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
3099     }
3100
3101     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
3102         $dispatcher = 'Catalyst::Dispatcher::' . $env;
3103     }
3104
3105     unless ($dispatcher) {
3106         $dispatcher = $class->dispatcher_class;
3107     }
3108
3109     load_class($dispatcher);
3110
3111     # dispatcher instance
3112     $class->dispatcher( $dispatcher->new );
3113 }
3114
3115 =head2 $c->setup_engine
3116
3117 Sets up engine.
3118
3119 =cut
3120
3121 sub engine_class {
3122     my ($class, $requested_engine) = @_;
3123
3124     if (!$class->engine_loader || $requested_engine) {
3125         $class->engine_loader(
3126             Catalyst::EngineLoader->new({
3127                 application_name => $class,
3128                 (defined $requested_engine
3129                      ? (catalyst_engine_class => $requested_engine) : ()),
3130             }),
3131         );
3132     }
3133
3134     $class->engine_loader->catalyst_engine_class;
3135 }
3136
3137 sub setup_engine {
3138     my ($class, $requested_engine) = @_;
3139
3140     my $engine = do {
3141         my $loader = $class->engine_loader;
3142
3143         if (!$loader || $requested_engine) {
3144             $loader = Catalyst::EngineLoader->new({
3145                 application_name => $class,
3146                 (defined $requested_engine
3147                      ? (requested_engine => $requested_engine) : ()),
3148             }),
3149
3150             $class->engine_loader($loader);
3151         }
3152
3153         $loader->catalyst_engine_class;
3154     };
3155
3156     # Don't really setup_engine -- see _setup_psgi_app for explanation.
3157     return if $class->loading_psgi_file;
3158
3159     load_class($engine);
3160
3161     if ($ENV{MOD_PERL}) {
3162         my $apache = $class->engine_loader->auto;
3163
3164         my $meta = find_meta($class);
3165         my $was_immutable = $meta->is_immutable;
3166         my %immutable_options = $meta->immutable_options;
3167         $meta->make_mutable if $was_immutable;
3168
3169         $meta->add_method(handler => sub {
3170             my $r = shift;
3171             my $psgi_app = $class->_finalized_psgi_app;
3172             $apache->call_app($r, $psgi_app);
3173         });
3174
3175         $meta->make_immutable(%immutable_options) if $was_immutable;
3176     }
3177
3178     $class->engine( $engine->new );
3179
3180     return;
3181 }
3182
3183 ## This exists just to supply a prebuild psgi app for mod_perl and for the
3184 ## build in server support (back compat support for pre psgi port behavior).
3185 ## This is so that we don't build a new psgi app for each request when using
3186 ## the mod_perl handler or the built in servers (http and fcgi, etc).
3187
3188 sub _finalized_psgi_app {
3189     my ($app) = @_;
3190
3191     unless ($app->_psgi_app) {
3192         my $psgi_app = $app->_setup_psgi_app;
3193         $app->_psgi_app($psgi_app);
3194     }
3195
3196     return $app->_psgi_app;
3197 }
3198
3199 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
3200 ## home directory and load that and return it (just assume it is doing the
3201 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
3202 ## in default_middleware and return it ( this is for backward compatibility
3203 ## with pre psgi port behavior ).
3204
3205 sub _setup_psgi_app {
3206     my ($app) = @_;
3207
3208     for my $home (Path::Class::Dir->new($app->config->{home})) {
3209         my $psgi_file = $home->file(
3210             Catalyst::Utils::appprefix($app) . '.psgi',
3211         );
3212
3213         next unless -e $psgi_file;
3214
3215         # If $psgi_file calls ->setup_engine, it's doing so to load
3216         # Catalyst::Engine::PSGI. But if it does that, we're only going to
3217         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
3218         # anyway. So set a flag (ick) that tells setup_engine not to populate
3219         # $c->engine or do any other things we might regret.
3220
3221         $app->loading_psgi_file(1);
3222         my $psgi_app = Plack::Util::load_psgi($psgi_file);
3223         $app->loading_psgi_file(0);
3224
3225         return $psgi_app
3226             unless $app->engine_loader->needs_psgi_engine_compat_hack;
3227
3228         warn <<"EOW";
3229 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
3230
3231 Its content has been ignored. Please consult the Catalyst::Upgrading
3232 documentation on how to upgrade from Catalyst::Engine::PSGI.
3233 EOW
3234     }
3235
3236     return $app->apply_default_middlewares($app->psgi_app);
3237 }
3238
3239 =head2 $c->apply_default_middlewares
3240
3241 Adds the following L<Plack> middlewares to your application, since they are
3242 useful and commonly needed:
3243
3244 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3245 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3246 is smart enough to conditionally apply itself).
3247
3248 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3249 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3250 an indication that your server is running behind a proxy frontend.  However in
3251 2014 this is often not the case.  We preserve this code for backwards compatibility
3252 however I B<highly> recommend that if you are running the server behind a front
3253 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3254 setting to true for your environment configurations that run behind a proxy.  This
3255 way if you change your front end proxy address someday your code would inexplicably
3256 stop working as expected.
3257
3258 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3259 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3260 $ENV{SCRIPT_NAME}.
3261
3262 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3263 adding via C<registered_middleware> rather than this method.
3264
3265 If you are using Lighttpd or IIS6 you may wish to apply these middlewares.  In
3266 general this is no longer a common case but we have this here for backward
3267 compatibility.
3268
3269 =cut
3270
3271
3272 sub apply_default_middlewares {
3273     my ($app, $psgi_app) = @_;
3274
3275     # Don't add this conditional IF we are explicitly saying we want the
3276     # frontend proxy support.  We don't need it here since if that is the
3277     # case it will be always loaded in the default_middleware.
3278
3279     unless($app->config->{using_frontend_proxy}) {
3280       $psgi_app = Plack::Middleware::Conditional->wrap(
3281           $psgi_app,
3282           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3283           condition => sub {
3284               my ($env) = @_;
3285               return if $app->config->{ignore_frontend_proxy};
3286               return $env->{REMOTE_ADDR} eq '127.0.0.1';
3287           },
3288       );
3289     }
3290
3291     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3292     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3293     $psgi_app = Plack::Middleware::Conditional->wrap(
3294         $psgi_app,
3295         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3296         condition => sub {
3297             my ($env) = @_;
3298             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3299             return unless $1 < 4.23;
3300             1;
3301         },
3302     );
3303
3304     # we're applying this unconditionally as the middleware itself already makes
3305     # sure it doesn't fuck things up if it's not running under one of the right
3306     # IIS versions
3307     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3308
3309     # And another IIS issue, this time with IIS7.
3310     $psgi_app = Plack::Middleware::Conditional->wrap(
3311         $psgi_app,
3312         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3313         condition => sub {
3314             my ($env) = @_;
3315             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3316         },
3317     );
3318
3319     return $psgi_app;
3320 }
3321
3322 =head2 App->psgi_app
3323
3324 =head2 App->to_app
3325
3326 Returns a PSGI application code reference for the catalyst application
3327 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3328 method called.  We do however apply C<registered_middleware> since those are
3329 integral to how L<Catalyst> functions.  Also, unlike starting your application
3330 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3331 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3332 scripts in your $HOME directory.
3333
3334 B<NOTE> C<apply_default_middlewares> was originally created when the first PSGI
3335 port was done for v5.90000.  These are middlewares that are added to achieve
3336 backward compatibility with older applications.  If you start your application
3337 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3338 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3339 automatically.  This was done so that pre and post PSGI port applications would
3340 work the same way.
3341
3342 This is what you want to be using to retrieve the PSGI application code
3343 reference of your Catalyst application for use in a custom F<.psgi> or in your
3344 own created server modules.
3345
3346 =cut
3347
3348 *to_app = \&psgi_app;
3349
3350 sub psgi_app {
3351     my ($app) = @_;
3352     my $psgi = $app->engine->build_psgi_app($app);
3353     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3354 }
3355
3356 =head2 $c->setup_home
3357
3358 Sets up the home directory.
3359
3360 =cut
3361
3362 sub setup_home {
3363     my ( $class, $home ) = @_;
3364
3365     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3366         $home = $env;
3367     }
3368
3369     $home ||= Catalyst::Utils::home($class);
3370
3371     if ($home) {
3372         #I remember recently being scolded for assigning config values like this
3373         $class->config->{home} ||= $home;
3374         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3375     }
3376 }
3377
3378 =head2 $c->setup_encoding
3379
3380 Sets up the input/output encoding. See L<ENCODING>
3381
3382 =cut
3383
3384 sub setup_encoding {
3385     my $c = shift;
3386     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3387         # Ok, so the user has explicitly said "I don't want encoding..."
3388         return;
3389     } else {
3390       my $enc = defined($c->config->{encoding}) ?
3391         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3392       $c->encoding($enc);
3393     }
3394 }
3395
3396 =head2 handle_unicode_encoding_exception
3397
3398 Hook to let you customize how encoding errors are handled.  By default
3399 we just throw an exception.  Receives a hashref of debug information.
3400 Example:
3401
3402     $c->handle_unicode_encoding_exception({
3403         param_value => $value,
3404         error_msg => $_,
3405             encoding_step => 'params',
3406         });
3407
3408 =cut
3409
3410 sub handle_unicode_encoding_exception {
3411     my ( $self, $exception_ctx ) = @_;
3412     die $exception_ctx->{error_msg};
3413 }
3414
3415 # Some unicode helpers cargo culted from the old plugin.  These could likely
3416 # be neater.
3417
3418 sub _handle_unicode_decoding {
3419     my ( $self, $value ) = @_;
3420
3421     return unless defined $value;
3422
3423     ## I think this mess is to support the old nested
3424     if ( ref $value eq 'ARRAY' ) {
3425         foreach ( @$value ) {
3426             $_ = $self->_handle_unicode_decoding($_);
3427         }
3428         return $value;
3429     }
3430     elsif ( ref $value eq 'HASH' ) {
3431         foreach (keys %$value) {
3432             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3433             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3434
3435             # If the key was encoded we now have two (the original and current so
3436             # delete the original.
3437             delete $value->{$_} if $_ ne $encoded_key;
3438         }
3439         return $value;
3440     }
3441     else {
3442         return $self->_handle_param_unicode_decoding($value);
3443     }
3444 }
3445
3446 sub _handle_param_unicode_decoding {
3447     my ( $self, $value ) = @_;
3448     return unless defined $value; # not in love with just ignoring undefs - jnap
3449     return $value if blessed($value); #don't decode when the value is an object.
3450
3451     my $enc = $self->encoding;
3452     return try {
3453       $enc->decode( $value, $self->_encode_check );
3454     }
3455     catch {
3456         $self->handle_unicode_encoding_exception({
3457             param_value => $value,
3458             error_msg => $_,
3459             encoding_step => 'params',
3460         });
3461     };
3462 }
3463
3464 =head2 $c->setup_log
3465
3466 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3467 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3468 log to.
3469
3470 This method also installs a C<debug> method that returns a true value into the
3471 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3472 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3473
3474 Note that if the log has already been setup, by either a previous call to
3475 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3476 that this method won't actually set up the log object.
3477
3478 =cut
3479
3480 sub setup_log {
3481     my ( $class, $levels ) = @_;
3482
3483     $levels ||= '';
3484     $levels =~ s/^\s+//;
3485     $levels =~ s/\s+$//;
3486     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3487
3488     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3489     if ( defined $env_debug ) {
3490         $levels{debug} = 1 if $env_debug; # Ugly!
3491         delete($levels{debug}) unless $env_debug;
3492     }
3493
3494     unless ( $class->log ) {
3495         $class->log( Catalyst::Log->new(keys %levels) );
3496     }
3497
3498     if ( $levels{debug} ) {
3499         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3500         $class->log->debug('Debug messages enabled');
3501     }
3502 }
3503
3504 =head2 $c->setup_plugins
3505
3506 Sets up plugins.
3507
3508 =cut
3509
3510 =head2 $c->setup_stats
3511
3512 Sets up timing statistics class.
3513
3514 =cut
3515
3516 sub setup_stats {
3517     my ( $class, $stats ) = @_;
3518
3519     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3520
3521     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3522     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3523         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3524         $class->log->debug('Statistics enabled');
3525     }
3526 }
3527
3528
3529 =head2 $c->registered_plugins
3530
3531 Returns a sorted list of the plugins which have either been stated in the
3532 import list.
3533
3534 If passed a given plugin name, it will report a boolean value indicating
3535 whether or not that plugin is loaded.  A fully qualified name is required if
3536 the plugin name does not begin with C<Catalyst::Plugin::>.
3537
3538  if ($c->registered_plugins('Some::Plugin')) {
3539      ...
3540  }
3541
3542 =cut
3543
3544 {
3545
3546     sub registered_plugins {
3547         my $proto = shift;
3548         return sort keys %{ $proto->_plugins } unless @_;
3549         my $plugin = shift;
3550         return 1 if exists $proto->_plugins->{$plugin};
3551         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3552     }
3553
3554     sub _register_plugin {
3555         my ( $proto, $plugin, $instant ) = @_;
3556         my $class = ref $proto || $proto;
3557
3558         load_class( $plugin );
3559         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3560             if $plugin->isa( 'Catalyst::Component' );
3561         my $plugin_meta = Moose::Meta::Class->create($plugin);
3562         if (!$plugin_meta->has_method('new')
3563             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3564             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3565         }
3566         if (!$instant && !$proto->_plugins->{$plugin}) {
3567             my $meta = Class::MOP::get_metaclass_by_name($class);
3568             $meta->superclasses($plugin, $meta->superclasses);
3569         }
3570         $proto->_plugins->{$plugin} = 1;
3571         return $class;
3572     }
3573
3574     sub _default_plugins { return qw() }
3575
3576     sub setup_plugins {
3577         my ( $class, $plugins ) = @_;
3578
3579         $class->_plugins( {} ) unless $class->_plugins;
3580         $plugins = [ grep {
3581             m/Unicode::Encoding/ ? do {
3582                 $class->log->warn(
3583                     'Unicode::Encoding plugin is auto-applied,'
3584                     . ' please remove this from your appclass'
3585                     . ' and make sure to define "encoding" config'
3586                 );
3587                 unless (exists $class->config->{'encoding'}) {
3588                   $class->config->{'encoding'} = 'UTF-8';
3589                 }
3590                 () }
3591                 : $_
3592         } @$plugins ];
3593         push @$plugins, $class->_default_plugins;
3594         $plugins = Data::OptList::mkopt($plugins || []);
3595
3596         my @plugins = map {
3597             [ Catalyst::Utils::resolve_namespace(
3598                   $class . '::Plugin',
3599                   'Catalyst::Plugin', $_->[0]
3600               ),
3601               $_->[1],
3602             ]
3603          } @{ $plugins };
3604
3605         for my $plugin ( reverse @plugins ) {
3606             load_class($plugin->[0], $plugin->[1]);
3607             my $meta = find_meta($plugin->[0]);
3608             next if $meta && $meta->isa('Moose::Meta::Role');
3609
3610             $class->_register_plugin($plugin->[0]);
3611         }
3612
3613         my @roles =
3614             map  { $_->[0]->name, $_->[1] }
3615             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3616             map  { [find_meta($_->[0]), $_->[1]] }
3617             @plugins;
3618
3619         Moose::Util::apply_all_roles(
3620             $class => @roles
3621         ) if @roles;
3622     }
3623 }
3624
3625 =head2 default_middleware
3626
3627 Returns a list of instantiated PSGI middleware objects which is the default
3628 middleware that is active for this application (taking any configuration
3629 options into account, excluding your custom added middleware via the C<psgi_middleware>
3630 configuration option).  You can override this method if you wish to change
3631 the default middleware (although do so at risk since some middleware is vital
3632 to application function.)
3633
3634 The current default middleware list is:
3635
3636       Catalyst::Middleware::Stash
3637       Plack::Middleware::HTTPExceptions
3638       Plack::Middleware::RemoveRedundantBody
3639       Plack::Middleware::FixMissingBodyInRedirect
3640       Plack::Middleware::ContentLength
3641       Plack::Middleware::MethodOverride
3642       Plack::Middleware::Head
3643
3644 If the configuration setting C<using_frontend_proxy> is true we add:
3645
3646       Plack::Middleware::ReverseProxy
3647
3648 If the configuration setting C<using_frontend_proxy_path> is true we add:
3649
3650       Plack::Middleware::ReverseProxyPath
3651
3652 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3653 L<Catalyst> distribution so if you want to use this option you should add it to
3654 your project distribution file.
3655
3656 These middlewares will be added at L</setup_middleware> during the
3657 L</setup> phase of application startup.
3658
3659 =cut
3660
3661 sub default_middleware {
3662     my $class = shift;
3663     my @mw = (
3664       Catalyst::Middleware::Stash->new,
3665       Plack::Middleware::HTTPExceptions->new,
3666       Plack::Middleware::RemoveRedundantBody->new,
3667       Plack::Middleware::FixMissingBodyInRedirect->new,
3668       Plack::Middleware::ContentLength->new,
3669       Plack::Middleware::MethodOverride->new,
3670       Plack::Middleware::Head->new);
3671
3672     if($class->config->{using_frontend_proxy}) {
3673         push @mw, Plack::Middleware::ReverseProxy->new;
3674     }
3675
3676     if($class->config->{using_frontend_proxy_path}) {
3677         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3678             push @mw, Plack::Middleware::ReverseProxyPath->new;
3679         } else {
3680           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3681         }
3682     }
3683
3684     return @mw;
3685 }
3686
3687 =head2 registered_middlewares
3688
3689 Read only accessor that returns an array of all the middleware in the order
3690 that they were added (which is the REVERSE of the order they will be applied).
3691
3692 The values returned will be either instances of L<Plack::Middleware> or of a
3693 compatible interface, or a coderef, which is assumed to be inlined middleware
3694
3695 =head2 setup_middleware (?@middleware)
3696
3697 Read configuration information stored in configuration key C<psgi_middleware> or
3698 from passed @args.
3699
3700 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3701 to use it to enable L<Plack::Middleware>
3702
3703 This method is automatically called during 'setup' of your application, so
3704 you really don't need to invoke it.  However you may do so if you find the idea
3705 of loading middleware via configuration weird :).  For example:
3706
3707     package MyApp;
3708
3709     use Catalyst;
3710
3711     __PACKAGE__->setup_middleware('Head');
3712     __PACKAGE__->setup;
3713
3714 When we read middleware definitions from configuration, we reverse the list
3715 which sounds odd but is likely how you expect it to work if you have prior
3716 experience with L<Plack::Builder> or if you previously used the plugin
3717 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3718
3719 So basically your middleware handles an incoming request from the first
3720 registered middleware, down and handles the response from the last middleware
3721 up.
3722
3723 =cut
3724
3725 sub registered_middlewares {
3726     my $class = shift;
3727     if(my $middleware = $class->_psgi_middleware) {
3728         my @mw = ($class->default_middleware, @$middleware);
3729
3730         if($class->config->{using_frontend_proxy}) {
3731           push @mw, Plack::Middleware::ReverseProxy->new;
3732         }
3733
3734         return @mw;
3735     } else {
3736         die "You cannot call ->registered_middlewares until middleware has been setup";
3737     }
3738 }
3739
3740 sub setup_middleware {
3741     my $class = shift;
3742     my @middleware_definitions;
3743
3744     # If someone calls this method you can add middleware with args.  However if its
3745     # called without an arg we need to setup the configuration middleware.
3746     if(@_) {
3747       @middleware_definitions = reverse(@_);
3748     } else {
3749       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3750         unless $class->finalized_default_middleware;
3751       $class->finalized_default_middleware(1); # Only do this once, just in case some people call setup over and over...
3752     }
3753
3754     my @middleware = ();
3755     while(my $next = shift(@middleware_definitions)) {
3756         if(ref $next) {
3757             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3758                 push @middleware, $next;
3759             } elsif(ref $next eq 'CODE') {
3760                 push @middleware, $next;
3761             } elsif(ref $next eq 'HASH') {
3762                 my $namespace = shift @middleware_definitions;
3763                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3764                 push @middleware, $mw;
3765             } else {
3766               die "I can't handle middleware definition ${\ref $next}";
3767             }
3768         } else {
3769           my $mw = $class->Catalyst::Utils::build_middleware($next);
3770           push @middleware, $mw;
3771         }
3772     }
3773
3774     my @existing = @{$class->_psgi_middleware || []};
3775     $class->_psgi_middleware([@middleware,@existing,]);
3776 }
3777
3778 =head2 registered_data_handlers
3779
3780 A read only copy of registered Data Handlers returned as a Hash, where each key
3781 is a content type and each value is a subref that attempts to decode that content
3782 type.
3783
3784 =head2 setup_data_handlers (?@data_handler)
3785
3786 Read configuration information stored in configuration key C<data_handlers> or
3787 from passed @args.
3788
3789 See under L</CONFIGURATION> information regarding C<data_handlers>.
3790
3791 This method is automatically called during 'setup' of your application, so
3792 you really don't need to invoke it.
3793
3794 =head2 default_data_handlers
3795
3796 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3797 only two default data handlers, for 'application/json' and an alternative to
3798 'application/x-www-form-urlencoded' which supposed nested form parameters via
3799 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3800
3801 The 'application/json' data handler is used to parse incoming JSON into a Perl
3802 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3803 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3804 JSON decoder, and has the smallest dependency impact.
3805
3806 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3807 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3808 order to get the best performance.  You should add either to your dependency
3809 list (Makefile.PL, dist.ini, cpanfile, etc.)
3810
3811 =cut
3812
3813 sub registered_data_handlers {
3814     my $class = shift;
3815     if(my $data_handlers = $class->_data_handlers) {
3816         return %$data_handlers;
3817     } else {
3818         $class->setup_data_handlers;
3819         return $class->registered_data_handlers;
3820     }
3821 }
3822
3823 sub setup_data_handlers {
3824     my ($class, %data_handler_callbacks) = @_;
3825     %data_handler_callbacks = (
3826       %{$class->default_data_handlers},
3827       %{$class->config->{'data_handlers'}||+{}},
3828       %data_handler_callbacks);
3829
3830     $class->_data_handlers(\%data_handler_callbacks);
3831 }
3832
3833 sub default_data_handlers {
3834     my ($class) = @_;
3835     return +{
3836       'application/x-www-form-urlencoded' => sub {
3837           my ($fh, $req) = @_;
3838           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3839           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3840             ->can('build_cgi_struct')->($params);
3841       },
3842       'application/json' => sub {
3843           my ($fh, $req) = @_;
3844           my $parser = Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON');
3845           my $slurped;
3846           return eval {
3847             local $/;
3848             $slurped = $fh->getline;
3849             $parser->can("decode_json")->($slurped); # decode_json does utf8 decoding for us
3850           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
3851         },
3852     };
3853 }
3854
3855 sub _handle_http_exception {
3856     my ( $self, $error ) = @_;
3857     if (
3858            !$self->config->{always_catch_http_exceptions}
3859         && blessed $error
3860         && (
3861             $error->can('as_psgi')
3862             || (   $error->can('code')
3863                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
3864         )
3865       )
3866     {
3867         return 1;
3868     }
3869 }
3870
3871 =head2 $c->stack
3872
3873 Returns an arrayref of the internal execution stack (actions that are
3874 currently executing).
3875
3876 =head2 $c->stats
3877
3878 Returns the current timing statistics object. By default Catalyst uses
3879 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3880 L<< stats_class|/"$c->stats_class" >>.
3881
3882 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3883 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3884 profile explicitly, although MyApp.pm still won't profile nor output anything
3885 by itself.
3886
3887 =head2 $c->stats_class
3888
3889 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3890
3891 =head2 $app->stats_class_traits
3892
3893 A arrayref of L<Moose::Role>s that are applied to the stats_class before creating it.
3894
3895 =head2 $app->composed_stats_class
3896
3897 this is the stats_class composed with any 'stats_class_traits'.
3898
3899 =head2 $c->use_stats
3900
3901 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3902
3903 Note that this is a static method, not an accessor and should be overridden
3904 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3905
3906 =cut
3907
3908 sub use_stats { 0 }
3909
3910
3911 =head2 $c->write( $data )
3912
3913 Writes $data to the output stream. When using this method directly, you
3914 will need to manually set the C<Content-Length> header to the length of
3915 your output data, if known.
3916
3917 =cut
3918
3919 sub write {
3920     my $c = shift;
3921
3922     # Finalize headers if someone manually writes output (for compat)
3923     $c->finalize_headers;
3924
3925     return $c->response->write( @_ );
3926 }
3927
3928 =head2 version
3929
3930 Returns the Catalyst version number. Mostly useful for "powered by"
3931 messages in template systems.
3932
3933 =cut
3934
3935 sub version { return $Catalyst::VERSION }
3936
3937 =head1 CONFIGURATION
3938
3939 There are a number of 'base' config variables which can be set:
3940
3941 =over
3942
3943 =item *
3944
3945 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
3946 rethrows errors conforming to the interface described by
3947 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
3948 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
3949
3950 =item *
3951
3952 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3953
3954 =item *
3955
3956 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3957
3958 =item *
3959
3960 C<disable_component_resolution_regex_fallback> - Turns
3961 off the deprecated component resolution functionality so
3962 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3963 are called then regex search will not be attempted on string values and
3964 instead C<undef> will be returned.
3965
3966 =item *
3967
3968 C<home> - The application home directory. In an uninstalled application,
3969 this is the top level application directory. In an installed application,
3970 this will be the directory containing C<< MyApp.pm >>.
3971
3972 =item *
3973
3974 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3975
3976 =item *
3977
3978 C<name> - The name of the application in debug messages and the debug and
3979 welcome screens
3980
3981 =item *
3982
3983 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3984 until it is accessed. This allows you to (for example) check authentication (and reject
3985 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3986
3987 =item *
3988
3989 C<root> - The root directory for templates. Usually this is just a
3990 subdirectory of the home directory, but you can set it to change the
3991 templates to a different directory.
3992
3993 =item *
3994
3995 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3996 namespaces from which components will be loaded (and constructed and stored in
3997 C<< $c->components >>).
3998
3999 =item *
4000
4001 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
4002 to be shown in hit debug tables in the test server.
4003
4004 =item *
4005
4006 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
4007 variable should be used for determining the request path.
4008
4009 Most web server environments pass the requested path to the application using environment variables,
4010 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
4011 exposed as C<< $c->request->base >>) and the request path below that base.
4012
4013 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
4014 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
4015
4016 =over
4017
4018 =item use_request_uri_for_path => 0
4019
4020 This is the default (and the) traditional method that Catalyst has used for determining the path information.
4021 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
4022 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
4023 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
4024
4025 However this method has the major disadvantage that it is impossible to correctly decode some elements
4026 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
4027 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
4028 can't distinguish / vs %2F in paths (in addition to other encoded values).
4029
4030 =item use_request_uri_for_path => 1
4031
4032 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
4033 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
4034 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
4035
4036 Given that this method of path resolution is provably more correct, it is recommended that you use
4037 this unless you have a specific need to deploy your application in a non-standard environment, and you are
4038 aware of the implications of not being able to handle encoded URI paths correctly.
4039
4040 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
4041 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
4042 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
4043 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
4044 C<< $c->request->base >> will be incorrect.
4045
4046 =back
4047
4048 =item *
4049
4050 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
4051
4052 =item *
4053
4054 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
4055 installed, otherwise log an error).  This is useful if your application is not running on the
4056 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
4057 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
4058 This has been done since not all people need this feature and we wish to restrict the growth of
4059 L<Catalyst> dependencies.
4060
4061 =item *
4062
4063 C<encoding> - See L</ENCODING>
4064
4065 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
4066 value to undef.
4067
4068 =item *
4069
4070 C<abort_chain_on_error_fix>
4071
4072 When there is an error in an action chain, the default behavior is to continue
4073 processing the remaining actions and then catch the error upon chain end.  This
4074 can lead to running actions when the application is in an unexpected state.  If
4075 you have this issue, setting this config value to true will promptly exit a
4076 chain when there is an error raised in any action (thus terminating the chain
4077 early.)
4078
4079 use like:
4080
4081     __PACKAGE__->config(abort_chain_on_error_fix => 1);
4082
4083 In the future this might become the default behavior.
4084
4085 =item *
4086
4087 C<use_hash_multivalue_in_request>
4088
4089 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
4090 and C<parameters> return a hashref where values might be scalar or an arrayref
4091 depending on the incoming data.  In many cases this can be undesirable as it
4092 leads one to writing defensive code like the following:
4093
4094     my ($val) = ref($c->req->parameters->{a}) ?
4095       @{$c->req->parameters->{a}} :
4096         $c->req->parameters->{a};
4097
4098 Setting this configuration item to true will make L<Catalyst> populate the
4099 attributes underlying these methods with an instance of L<Hash::MultiValue>
4100 which is used by L<Plack::Request> and others to solve this very issue.  You
4101 may prefer this behavior to the default, if so enable this option (be warned
4102 if you enable it in a legacy application we are not sure if it is completely
4103 backwardly compatible).
4104
4105 =item *
4106
4107 C<skip_complex_post_part_handling>
4108
4109 When creating body parameters from a POST, if we run into a multpart POST
4110 that does not contain uploads, but instead contains inlined complex data
4111 (very uncommon) we cannot reliably convert that into field => value pairs.  So
4112 instead we create an instance of L<Catalyst::Request::PartData>.  If this causes
4113 issue for you, you can disable this by setting C<skip_complex_post_part_handling>
4114 to true (default is false).
4115
4116 =item *
4117
4118 C<skip_body_param_unicode_decoding>
4119
4120 Generally we decode incoming POST params based on your declared encoding (the
4121 default for this is to decode UTF-8).  If this is causing you trouble and you
4122 do not wish to turn all encoding support off (with the C<encoding> configuration
4123 parameter) you may disable this step atomically by setting this configuration
4124 parameter to true.
4125
4126 =item *
4127
4128 C<do_not_decode_query>
4129
4130 If true, then do not try to character decode any wide characters in your
4131 request URL query or keywords.  Most readings of the relevent specifications
4132 suggest these should be UTF-* encoded, which is the default that L<Catalyst>
4133 will use, hwoever if you are creating a lot of URLs manually or have external
4134 evil clients, this might cause you trouble.  If you find the changes introduced
4135 in Catalyst version 5.90080+ break some of your query code, you may disable
4136 the UTF-8 decoding globally using this configuration.
4137
4138 This setting takes precedence over C<default_query_encoding> and
4139 C<decode_query_using_global_encoding>
4140
4141 =item *
4142
4143 C<default_query_encoding>
4144
4145 By default we decode query and keywords in your request URL using UTF-8, which
4146 is our reading of the relevent specifications.  This setting allows one to
4147 specify a fixed value for how to decode your query.  You might need this if
4148 you are doing a lot of custom encoding of your URLs and not using UTF-8.
4149
4150 This setting take precedence over C<decode_query_using_global_encoding>.
4151
4152 =item *
4153
4154 C<decode_query_using_global_encoding>
4155
4156 Setting this to true will default your query decoding to whatever your
4157 general global encoding is (the default is UTF-8).
4158
4159 =item *
4160
4161 C<use_chained_args_0_special_case>
4162
4163 In older versions of Catalyst, when more than one action matched the same path
4164 AND all those matching actions declared Args(0), we'd break the tie by choosing
4165 the first action defined.  We now normalized how Args(0) works so that it
4166 follows the same rule as Args(N), which is to say when we need to break a tie
4167 we choose the LAST action defined.  If this breaks your code and you don't
4168 have time to update to follow the new normalized approach, you may set this
4169 value to true and it will globally revert to the original chaining behavior.
4170
4171 =item *
4172
4173 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
4174
4175 =item *
4176
4177 C<data_handlers> - See L<DATA HANDLERS>.
4178
4179 =item *
4180
4181 C<stats_class_traits>
4182
4183 An arrayref of L<Moose::Role>s that get componsed into your stats class.
4184
4185 =item *
4186
4187 C<request_class_traits>
4188
4189 An arrayref of L<Moose::Role>s that get componsed into your request class.
4190
4191 =item *
4192
4193 C<response_class_traits>
4194
4195 An arrayref of L<Moose::Role>s that get componsed into your response class.
4196
4197 =item *
4198
4199 C<inject_components>
4200
4201 A Hashref of L<Catalyst::Component> subclasses that are 'injected' into configuration.
4202 For example:
4203
4204     MyApp->config({
4205       inject_components => {
4206         'Controller::Err' => { from_component => 'Local::Controller::Errors' },
4207         'Model::Zoo' => { from_component => 'Local::Model::Foo' },
4208         'Model::Foo' => { from_component => 'Local::Model::Foo', roles => ['TestRole'] },
4209       },
4210       'Controller::Err' => { a => 100, b=>200, namespace=>'error' },
4211       'Model::Zoo' => { a => 2 },
4212       'Model::Foo' => { a => 100 },
4213     });
4214
4215 Generally L<Catalyst> looks for components in your Model/View or Controller directories.
4216 However for cases when you which to use an existing component and you don't need any
4217 customization (where for when you can apply a role to customize it) you may inject those
4218 components into your application.  Please note any configuration should be done 'in the
4219 normal way', with a key under configuration named after the component affix, as in the
4220 above example.
4221
4222 Using this type of injection allows you to construct significant amounts of your application
4223 with only configuration!.  This may or may not lead to increased code understanding.
4224
4225 Please not you may also call the ->inject_components application method as well, although
4226 you must do so BEFORE setup.
4227
4228 =back
4229
4230 =head1 EXCEPTIONS
4231
4232 Generally when you throw an exception inside an Action (or somewhere in
4233 your stack, such as in a model that an Action is calling) that exception
4234 is caught by Catalyst and unless you either catch it yourself (via eval
4235 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
4236 will eventually reach L</finalize_errors> and return either the debugging
4237 error stack page, or the default error page.  However, if your exception
4238 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
4239 instead rethrow it so that it can be handled by that middleware (which
4240 is part of the default middleware).  For example this would allow
4241
4242     use HTTP::Throwable::Factory 'http_throw';
4243
4244     sub throws_exception :Local {
4245       my ($self, $c) = @_;
4246
4247       http_throw(SeeOther => { location =>
4248         $c->uri_for($self->action_for('redirect')) });
4249
4250     }
4251
4252 =head1 INTERNAL ACTIONS
4253
4254 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
4255 C<_ACTION>, and C<_END>. These are by default not shown in the private
4256 action table, but you can make them visible with a config parameter.
4257
4258     MyApp->config(show_internal_actions => 1);
4259
4260 =head1 ON-DEMAND PARSER
4261
4262 The request body is usually parsed at the beginning of a request,
4263 but if you want to handle input yourself, you can enable on-demand
4264 parsing with a config parameter.
4265
4266     MyApp->config(parse_on_demand => 1);
4267
4268 =head1 PROXY SUPPORT
4269
4270 Many production servers operate using the common double-server approach,
4271 with a lightweight frontend web server passing requests to a larger
4272 backend server. An application running on the backend server must deal
4273 with two problems: the remote user always appears to be C<127.0.0.1> and
4274 the server's hostname will appear to be C<localhost> regardless of the
4275 virtual host that the user connected through.
4276
4277 Catalyst will automatically detect this situation when you are running
4278 the frontend and backend servers on the same machine. The following
4279 changes are made to the request.
4280
4281     $c->req->address is set to the user's real IP address, as read from
4282     the HTTP X-Forwarded-For header.
4283
4284     The host value for $c->req->base and $c->req->uri is set to the real
4285     host, as read from the HTTP X-Forwarded-Host header.
4286
4287 Additionally, you may be running your backend application on an insecure
4288 connection (port 80) while your frontend proxy is running under SSL.  If there
4289 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
4290 tell Catalyst what port the frontend listens on.  This will allow all URIs to
4291 be created properly.
4292
4293 In the case of passing in:
4294
4295     X-Forwarded-Port: 443
4296
4297 All calls to C<uri_for> will result in an https link, as is expected.
4298
4299 Obviously, your web server must support these headers for this to work.
4300
4301 In a more complex server farm environment where you may have your
4302 frontend proxy server(s) on different machines, you will need to set a
4303 configuration option to tell Catalyst to read the proxied data from the
4304 headers.
4305
4306     MyApp->config(using_frontend_proxy => 1);
4307
4308 If you do not wish to use the proxy support at all, you may set:
4309
4310     MyApp->config(ignore_frontend_proxy => 0);
4311
4312 =head2 Note about psgi files
4313
4314 Note that if you supply your own .psgi file, calling
4315 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
4316
4317 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
4318 in your psgi, for example:
4319
4320     builder {
4321         enable "Plack::Middleware::ReverseProxy";
4322         MyApp->psgi_app
4323     };
4324
4325 This will unconditionally add the ReverseProxy support, or you need to call
4326 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
4327 apply the support depending upon your config).
4328
4329 See L<Catalyst::PSGI> for more information.
4330
4331 =head1 THREAD SAFETY
4332
4333 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
4334 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
4335 believe the Catalyst core to be thread-safe.
4336
4337 If you plan to operate in a threaded environment, remember that all other
4338 modules you are using must also be thread-safe. Some modules, most notably
4339 L<DBD::SQLite>, are not thread-safe.
4340
4341 =head1 DATA HANDLERS
4342
4343 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
4344 form parameters and URL search query fields.  However it has become common
4345 for various alternative content types to be PUT or POSTed to your controllers
4346 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
4347 XML and other content types when communicating with an application server.  In
4348 order to better support this use case, L<Catalyst> defines a global configuration
4349 option, C<data_handlers>, which lets you associate a content type with a coderef
4350 that parses that content type into something Perl can readily access.
4351
4352     package MyApp::Web;
4353
4354     use Catalyst;
4355     use JSON::Maybe;
4356
4357     __PACKAGE__->config(
4358       data_handlers => {
4359         'application/json' => sub { local $/; decode_json $_->getline },
4360       },
4361       ## Any other configuration.
4362     );
4363
4364     __PACKAGE__->setup;
4365
4366 By default L<Catalyst> comes with a generic JSON data handler similar to the
4367 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
4368 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4369 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4370 or dist.ini, cpanfile, etc.)
4371
4372 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4373 (matched against the incoming request type using a regexp such as to be case
4374 insensitive) and whose values are coderefs that receive a localized version of
4375 C<$_> which is a filehandle object pointing to received body.
4376
4377 This feature is considered an early access release and we reserve the right
4378 to alter the interface in order to provide a performant and secure solution to
4379 alternative request body content.  Your reports welcomed!
4380
4381 =head1 PSGI MIDDLEWARE
4382
4383 You can define middleware, defined as L<Plack::Middleware> or a compatible
4384 interface in configuration.  Your middleware definitions are in the form of an
4385 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4386 with details to follow:
4387
4388     package MyApp::Web;
4389
4390     use Catalyst;
4391     use Plack::Middleware::StackTrace;
4392
4393     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4394
4395     __PACKAGE__->config(
4396       'psgi_middleware', [
4397         'Debug',
4398         '+MyApp::Custom',
4399         $stacktrace_middleware,
4400         'Session' => {store => 'File'},
4401         sub {
4402           my $app = shift;
4403           return sub {
4404             my $env = shift;
4405             $env->{myapp.customkey} = 'helloworld';
4406             $app->($env);
4407           },
4408         },
4409       ],
4410     );
4411
4412     __PACKAGE__->setup;
4413
4414 So the general form is:
4415
4416     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4417
4418 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4419 the order listed (to make it function similarly to L<Plack::Builder>:
4420
4421 Alternatively, you may also define middleware by calling the L</setup_middleware>
4422 package method:
4423
4424     package MyApp::Web;
4425
4426     use Catalyst;
4427
4428     __PACKAGE__->setup_middleware( \@middleware_definitions);
4429     __PACKAGE__->setup;
4430
4431 In the case where you do both (use 'setup_middleware' and configuration) the
4432 package call to setup_middleware will be applied earlier (in other words its
4433 middleware will wrap closer to the application).  Keep this in mind since in
4434 some cases the order of middleware is important.
4435
4436 The two approaches are not exclusive.
4437
4438 =over 4
4439
4440 =item Middleware Object
4441
4442 An already initialized object that conforms to the L<Plack::Middleware>
4443 specification:
4444
4445     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4446
4447     __PACKAGE__->config(
4448       'psgi_middleware', [
4449         $stacktrace_middleware,
4450       ]);
4451
4452
4453 =item coderef
4454
4455 A coderef that is an inlined middleware:
4456
4457     __PACKAGE__->config(
4458       'psgi_middleware', [
4459         sub {
4460           my $app = shift;
4461           return sub {
4462             my $env = shift;
4463             if($env->{PATH_INFO} =~m/forced/) {
4464               Plack::App::File
4465                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4466                 ->call($env);
4467             } else {
4468               return $app->($env);
4469             }
4470          },
4471       },
4472     ]);
4473
4474
4475
4476 =item a scalar
4477
4478 We assume the scalar refers to a namespace after normalizing it using the
4479 following rules:
4480
4481 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4482 is assumed to be 'as is', and we just install and use the middleware.
4483
4484 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4485 (the package name of your Catalyst application subclass), we also assume then
4486 that it is a full namespace, and use it.
4487
4488 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4489 resolve it first by looking for it under your application namespace (for example
4490 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4491 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4492 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4493 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4494 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4495 you find that a good idea.
4496
4497 Examples:
4498
4499     package MyApp::Web;
4500
4501     __PACKAGE__->config(
4502       'psgi_middleware', [
4503         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4504         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4505         '+MyApp::Custom',  ## MyApp::Custom->wrap
4506       ],
4507     );
4508
4509 =item a scalar followed by a hashref
4510
4511 Just like the previous, except the following C<HashRef> is used as arguments
4512 to initialize the middleware object.
4513
4514     __PACKAGE__->config(
4515       'psgi_middleware', [
4516          'Session' => {store => 'File'},
4517     ]);
4518
4519 =back
4520
4521 Please see L<PSGI> for more on middleware.
4522
4523 =head1 ENCODING
4524
4525 Starting in L<Catalyst> version 5.90080 encoding is automatically enabled
4526 and set to encode all body responses to UTF8 when possible and applicable.
4527 Following is documentation on this process.  If you are using an older
4528 version of L<Catalyst> you should review documentation for that version since
4529 a lot has changed.
4530
4531 By default encoding is now 'UTF-8'.  You may turn it off by setting
4532 the encoding configuration to undef.
4533
4534     MyApp->config(encoding => undef);
4535
4536 This is recommended for temporary backwards compatibility only.
4537
4538 Encoding is automatically applied when the content-type is set to
4539 a type that can be encoded.  Currently we encode when the content type
4540 matches the following regular expression:
4541
4542     $content_type =~ /^text|xml$|javascript$/
4543
4544 Encoding is set on the application, but it is copied to the context object
4545 so that you can override it on a request basis.
4546
4547 Be default we don't automatically encode 'application/json' since the most
4548 common approaches to generating this type of response (Either via L<Catalyst::View::JSON>
4549 or L<Catalyst::Action::REST>) will do so already and we want to avoid double
4550 encoding issues.
4551
4552 If you are producing JSON response in an unconventional manner (such
4553 as via a template or manual strings) you should perform the UTF8 encoding
4554 manually as well such as to conform to the JSON specification.
4555
4556 NOTE: We also examine the value of $c->response->content_encoding.  If
4557 you set this (like for example 'gzip', and manually gzipping the body)
4558 we assume that you have done all the necessary encoding yourself, since
4559 we cannot encode the gzipped contents.  If you use a plugin like
4560 L<Catalyst::Plugin::Compress> you need to update to a modern version in order
4561 to have this function correctly  with the new UTF8 encoding code, or you
4562 can use L<Plack::Middleware::Deflater> or (probably best) do your compression on
4563 a front end proxy.
4564
4565 =head2 Methods
4566
4567 =over 4
4568
4569 =item encoding
4570
4571 Returns an instance of an C<Encode> encoding
4572
4573     print $c->encoding->name
4574
4575 =item handle_unicode_encoding_exception ($exception_context)
4576
4577 Method called when decoding process for a request fails.
4578
4579 An C<$exception_context> hashref is provided to allow you to override the
4580 behaviour of your application when given data with incorrect encodings.
4581
4582 The default method throws exceptions in the case of invalid request parameters
4583 (resulting in a 500 error), but ignores errors in upload filenames.
4584
4585 The keys passed in the C<$exception_context> hash are:
4586
4587 =over
4588
4589 =item param_value
4590
4591 The value which was not able to be decoded.
4592
4593 =item error_msg
4594
4595 The exception received from L<Encode>.
4596
4597 =item encoding_step
4598
4599 What type of data was being decoded. Valid values are (currently)
4600 C<params> - for request parameters / arguments / captures
4601 and C<uploads> - for request upload filenames.
4602
4603 =back
4604
4605 =back
4606
4607 =head1 SUPPORT
4608
4609 IRC:
4610
4611     Join #catalyst on irc.perl.org.
4612
4613 Mailing Lists:
4614
4615     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4616     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4617
4618 Web:
4619
4620     http://catalyst.perl.org
4621
4622 Wiki:
4623
4624     http://dev.catalyst.perl.org
4625
4626 =head1 SEE ALSO
4627
4628 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4629
4630 =head2 L<Catalyst::Manual> - The Catalyst Manual
4631
4632 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4633
4634 =head2 L<Catalyst::Engine> - Core engine
4635
4636 =head2 L<Catalyst::Log> - Log class.
4637
4638 =head2 L<Catalyst::Request> - Request object
4639
4640 =head2 L<Catalyst::Response> - Response object
4641
4642 =head2 L<Catalyst::Test> - The test suite.
4643
4644 =head1 PROJECT FOUNDER
4645
4646 sri: Sebastian Riedel <sri@cpan.org>
4647
4648 =head1 CONTRIBUTORS
4649
4650 abw: Andy Wardley
4651
4652 acme: Leon Brocard <leon@astray.com>
4653
4654 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4655
4656 andrewalker: André Walker <andre@cpan.org>
4657
4658 Andrew Bramble
4659
4660 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4661
4662 Andrew Ruthven
4663
4664 andyg: Andy Grundman <andy@hybridized.org>
4665
4666 audreyt: Audrey Tang
4667
4668 bricas: Brian Cassidy <bricas@cpan.org>
4669
4670 Caelum: Rafael Kitover <rkitover@io.com>
4671
4672 chansen: Christian Hansen
4673
4674 chicks: Christopher Hicks
4675
4676 Chisel Wright C<pause@herlpacker.co.uk>
4677
4678 Danijel Milicevic C<me@danijel.de>
4679
4680 davewood: David Schmidt <davewood@cpan.org>
4681
4682 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4683
4684 David Naughton, C<naughton@umn.edu>
4685
4686 David E. Wheeler
4687
4688 dhoss: Devin Austin <dhoss@cpan.org>
4689
4690 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4691
4692 Drew Taylor
4693
4694 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4695
4696 esskar: Sascha Kiefer
4697
4698 fireartist: Carl Franks <cfranks@cpan.org>
4699
4700 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4701
4702 gabb: Danijel Milicevic
4703
4704 Gary Ashton Jones
4705
4706 Gavin Henry C<ghenry@perl.me.uk>
4707
4708 Geoff Richards
4709
4710 groditi: Guillermo Roditi <groditi@gmail.com>
4711
4712 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4713
4714 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4715
4716 jcamacho: Juan Camacho
4717
4718 jester: Jesse Sheidlower C<jester@panix.com>
4719
4720 jhannah: Jay Hannah <jay@jays.net>
4721
4722 Jody Belka
4723
4724 Johan Lindstrom
4725
4726 jon: Jon Schutz <jjschutz@cpan.org>
4727
4728 Jonathan Rockway C<< <jrockway@cpan.org> >>
4729
4730 Kieren Diment C<kd@totaldatasolution.com>
4731
4732 konobi: Scott McWhirter <konobi@cpan.org>
4733
4734 marcus: Marcus Ramberg <mramberg@cpan.org>
4735
4736 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4737
4738 mgrimes: Mark Grimes <mgrimes@cpan.org>
4739
4740 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4741
4742 mugwump: Sam Vilain
4743
4744 naughton: David Naughton
4745
4746 ningu: David Kamholz <dkamholz@cpan.org>
4747
4748 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4749
4750 numa: Dan Sully <daniel@cpan.org>
4751
4752 obra: Jesse Vincent
4753
4754 Octavian Rasnita
4755
4756 omega: Andreas Marienborg
4757
4758 Oleg Kostyuk <cub.uanic@gmail.com>
4759
4760 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4761
4762 rafl: Florian Ragwitz <rafl@debian.org>
4763
4764 random: Roland Lammel <lammel@cpan.org>
4765
4766 Robert Sedlacek C<< <rs@474.at> >>
4767
4768 SpiceMan: Marcel Montes
4769
4770 sky: Arthur Bergman
4771
4772 szbalint: Balint Szilakszi <szbalint@cpan.org>
4773
4774 t0m: Tomas Doran <bobtfish@bobtfish.net>
4775
4776 Ulf Edvinsson
4777
4778 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4779
4780 Viljo Marrandi C<vilts@yahoo.com>
4781
4782 Will Hawes C<info@whawes.co.uk>
4783
4784 willert: Sebastian Willert <willert@cpan.org>
4785
4786 wreis: Wallace Reis <wreis@cpan.org>
4787
4788 Yuval Kogman, C<nothingmuch@woobling.org>
4789
4790 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4791
4792 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4793
4794 Upasana <me@upasana.me>
4795
4796 John Napiorkowski (jnap) <jjnapiork@cpan.org>
4797
4798 =head1 COPYRIGHT
4799
4800 Copyright (c) 2005-2015, the above named PROJECT FOUNDER and CONTRIBUTORS.
4801
4802 =head1 LICENSE
4803
4804 This library is free software. You can redistribute it and/or modify it under
4805 the same terms as Perl itself.
4806
4807 =cut
4808
4809 no Moose;
4810
4811 __PACKAGE__->meta->make_immutable;
4812
4813 1;