lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use String::RewritePrefix;
  32 use Catalyst::EngineLoader;
  33 use utf8;
  34 use Carp qw/croak carp shortmess/;
  35 use Try::Tiny;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39 use Plack::Middleware::LighttpdScriptNameFix;
  40
  41 BEGIN { require 5.008003; }
  42
  43 has stack => (is => 'ro', default => sub { [] });
  44 has stash => (is => 'rw', default => sub { {} });
  45 has state => (is => 'rw', default => 0);
  46 has stats => (is => 'rw');
  47 has action => (is => 'rw');
  48 has counter => (is => 'rw', default => sub { {} });
  49 has request => (
  50     is => 'rw',
  51     default => sub {
  52         my $self = shift;
  53         my %p = ( _log => $self->log );
  54         $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  55         $self->request_class->new(\%p);
  56     },
  57     lazy => 1,
  58 );
  59 has response => (
  60     is => 'rw',
  61     default => sub {
  62         my $self = shift;
  63         $self->response_class->new({ _log => $self->log });
  64     },
  65     lazy => 1,
  66 );
  67 has namespace => (is => 'rw');
  68
  69 sub depth { scalar @{ shift->stack || [] }; }
  70 sub comp { shift->component(@_) }
  71
  72 sub req {
  73     my $self = shift; return $self->request(@_);
  74 }
  75 sub res {
  76     my $self = shift; return $self->response(@_);
  77 }
  78
  79 # For backwards compatibility
  80 sub finalize_output { shift->finalize_body(@_) };
  81
  82 # For statistics
  83 our $COUNT     = 1;
  84 our $START     = time;
  85 our $RECURSION = 1000;
  86 our $DETACH    = Catalyst::Exception::Detach->new;
  87 our $GO        = Catalyst::Exception::Go->new;
  88
  89 #I imagine that very few of these really need to be class variables. if any.
  90 #maybe we should just make them attributes with a default?
  91 __PACKAGE__->mk_classdata($_)
  92   for qw/components arguments dispatcher engine log dispatcher_class
  93   engine_loader context_class request_class response_class stats_class
  94   setup_finished _psgi_app loading_psgi_file run_options/;
  95
  96 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  97 __PACKAGE__->request_class('Catalyst::Request');
  98 __PACKAGE__->response_class('Catalyst::Response');
  99 __PACKAGE__->stats_class('Catalyst::Stats');
 100
 101 # Remember to update this in Catalyst::Runtime as well!
 102
 103 our $VERSION = '5.90012';
 104
 105 sub import {
 106     my ( $class, @arguments ) = @_;
 107
 108     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 109     # callers @ISA.
 110     return unless $class eq 'Catalyst';
 111
 112     my $caller = caller();
 113     return if $caller eq 'main';
 114
 115     my $meta = Moose::Meta::Class->initialize($caller);
 116     unless ( $caller->isa('Catalyst') ) {
 117         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 118         $meta->superclasses(@superclasses);
 119     }
 120     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 121     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 122
 123     unless( $meta->has_method('meta') ){
 124         if ($Moose::VERSION >= 1.15) {
 125             $meta->_add_meta_method('meta');
 126         }
 127         else {
 128             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 129         }
 130     }
 131
 132     $caller->arguments( [@arguments] );
 133     $caller->setup_home;
 134 }
 135
 136 sub _application { $_[0] }
 137
 138 =head1 NAME
 139
 140 Catalyst - The Elegant MVC Web Application Framework
 141
 142 =head1 SYNOPSIS
 143
 144 See the L<Catalyst::Manual> distribution for comprehensive
 145 documentation and tutorials.
 146
 147     # Install Catalyst::Devel for helpers and other development tools
 148     # use the helper to create a new application
 149     catalyst.pl MyApp
 150
 151     # add models, views, controllers
 152     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 153     script/myapp_create.pl view MyTemplate TT
 154     script/myapp_create.pl controller Search
 155
 156     # built in testserver -- use -r to restart automatically on changes
 157     # --help to see all available options
 158     script/myapp_server.pl
 159
 160     # command line testing interface
 161     script/myapp_test.pl /yada
 162
 163     ### in lib/MyApp.pm
 164     use Catalyst qw/-Debug/; # include plugins here as well
 165
 166     ### In lib/MyApp/Controller/Root.pm (autocreated)
 167     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 168         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 169         $c->stash->{template} = 'foo.tt'; # set the template
 170         # lookup something from db -- stash vars are passed to TT
 171         $c->stash->{data} =
 172           $c->model('Database::Foo')->search( { country => $args[0] } );
 173         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 174             $c->forward( 'bar' ); # process another action
 175             # do something else after forward returns
 176         }
 177     }
 178
 179     # The foo.tt TT template can use the stash data from the database
 180     [% WHILE (item = data.next) %]
 181         [% item.foo %]
 182     [% END %]
 183
 184     # called for /bar/of/soap, /bar/of/soap/10, etc.
 185     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 186
 187     # called after all actions are finished
 188     sub end : Action {
 189         my ( $self, $c ) = @_;
 190         if ( scalar @{ $c->error } ) { ... } # handle errors
 191         return if $c->res->body; # already have a response
 192         $c->forward( 'MyApp::View::TT' ); # render template
 193     }
 194
 195 See L<Catalyst::Manual::Intro> for additional information.
 196
 197 =head1 DESCRIPTION
 198
 199 Catalyst is a modern framework for making web applications without the
 200 pain usually associated with this process. This document is a reference
 201 to the main Catalyst application. If you are a new user, we suggest you
 202 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 203
 204 See L<Catalyst::Manual> for more documentation.
 205
 206 Catalyst plugins can be loaded by naming them as arguments to the "use
 207 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 208 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 209 C<My::Module>.
 210
 211     use Catalyst qw/My::Module/;
 212
 213 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 214 fully qualify the name by using a unary plus:
 215
 216     use Catalyst qw/
 217         My::Module
 218         +Fully::Qualified::Plugin::Name
 219     /;
 220
 221 Special flags like C<-Debug> can also be specified as
 222 arguments when Catalyst is loaded:
 223
 224     use Catalyst qw/-Debug My::Module/;
 225
 226 The position of plugins and flags in the chain is important, because
 227 they are loaded in the order in which they appear.
 228
 229 The following flags are supported:
 230
 231 =head2 -Debug
 232
 233 Enables debug output. You can also force this setting from the system
 234 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 235 settings override the application, with <MYAPP>_DEBUG having the highest
 236 priority.
 237
 238 This sets the log level to 'debug' and enables full debug output on the
 239 error screen. If you only want the latter, see L<< $c->debug >>.
 240
 241 =head2 -Home
 242
 243 Forces Catalyst to use a specific home directory, e.g.:
 244
 245     use Catalyst qw[-Home=/usr/mst];
 246
 247 This can also be done in the shell environment by setting either the
 248 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 249 is replaced with the uppercased name of your application, any "::" in
 250 the name will be replaced with underscores, e.g. MyApp::Web should use
 251 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 252
 253 If none of these are set, Catalyst will attempt to automatically detect the
 254 home directory. If you are working in a development environment, Catalyst
 255 will try and find the directory containing either Makefile.PL, Build.PL or
 256 dist.ini. If the application has been installed into the system (i.e.
 257 you have done C<make install>), then Catalyst will use the path to your
 258 application module, without the .pm extension (e.g., /foo/MyApp if your
 259 application was installed at /foo/MyApp.pm)
 260
 261 =head2 -Log
 262
 263     use Catalyst '-Log=warn,fatal,error';
 264
 265 Specifies a comma-delimited list of log levels.
 266
 267 =head2 -Stats
 268
 269 Enables statistics collection and reporting.
 270
 271    use Catalyst qw/-Stats=1/;
 272
 273 You can also force this setting from the system environment with CATALYST_STATS
 274 or <MYAPP>_STATS. The environment settings override the application, with
 275 <MYAPP>_STATS having the highest priority.
 276
 277 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 278
 279 =head1 METHODS
 280
 281 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 282
 283 =head2 $c->action
 284
 285 Returns a L<Catalyst::Action> object for the current action, which
 286 stringifies to the action name. See L<Catalyst::Action>.
 287
 288 =head2 $c->namespace
 289
 290 Returns the namespace of the current action, i.e., the URI prefix
 291 corresponding to the controller of the current action. For example:
 292
 293     # in Controller::Foo::Bar
 294     $c->namespace; # returns 'foo/bar';
 295
 296 =head2 $c->request
 297
 298 =head2 $c->req
 299
 300 Returns the current L<Catalyst::Request> object, giving access to
 301 information about the current client request (including parameters,
 302 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 303
 304 =head2 REQUEST FLOW HANDLING
 305
 306 =head2 $c->forward( $action [, \@arguments ] )
 307
 308 =head2 $c->forward( $class, $method, [, \@arguments ] )
 309
 310 Forwards processing to another action, by its private name. If you give a
 311 class name but no method, C<process()> is called. You may also optionally
 312 pass arguments in an arrayref. The action will receive the arguments in
 313 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 314 C<< $c->req->args >> will be restored to the previous values.
 315
 316 Any data C<return>ed from the action forwarded to, will be returned by the
 317 call to forward.
 318
 319     my $foodata = $c->forward('/foo');
 320     $c->forward('index');
 321     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 322     $c->forward('View::TT');
 323
 324 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 325 an C<< eval { } >> around the call (actually
 326 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 327 exceptions thrown by the called action non-fatal and pushing them onto
 328 $c->error instead. If you want C<die> to propagate you need to do something
 329 like:
 330
 331     $c->forward('foo');
 332     die join "\n", @{ $c->error } if @{ $c->error };
 333
 334 Or make sure to always return true values from your actions and write
 335 your code like this:
 336
 337     $c->forward('foo') || return;
 338
 339 Another note is that C<< $c->forward >> always returns a scalar because it
 340 actually returns $c->state which operates in a scalar context.
 341 Thus, something like:
 342
 343     return @array;
 344
 345 in an action that is forwarded to is going to return a scalar,
 346 i.e. how many items are in that array, which is probably not what you want.
 347 If you need to return an array then return a reference to it,
 348 or stash it like so:
 349
 350     $c->stash->{array} = \@array;
 351
 352 and access it from the stash.
 353
 354 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 355
 356 =cut
 357
 358 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 359
 360 =head2 $c->detach( $action [, \@arguments ] )
 361
 362 =head2 $c->detach( $class, $method, [, \@arguments ] )
 363
 364 =head2 $c->detach()
 365
 366 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 367 doesn't return to the previous action when processing is finished.
 368
 369 When called with no arguments it escapes the processing chain entirely.
 370
 371 =cut
 372
 373 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 374
 375 =head2 $c->visit( $action [, \@arguments ] )
 376
 377 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 378
 379 =head2 $c->visit( $class, $method, [, \@arguments ] )
 380
 381 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 382
 383 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 384 but does a full dispatch, instead of just calling the new C<$action> /
 385 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 386 you go to are called, just like a new request.
 387
 388 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 389 This means, for example, that C<< $c->action >> methods such as
 390 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 391 L<reverse|Catalyst::Action/reverse> return information for the visited action
 392 when they are invoked within the visited action.  This is different from the
 393 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 394 continues to use the $c->action object from the caller action even when
 395 invoked from the called action.
 396
 397 C<< $c->stash >> is kept unchanged.
 398
 399 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 400 allows you to "wrap" another action, just as it would have been called by
 401 dispatching from a URL, while the analogous
 402 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 403 transfer control to another action as if it had been reached directly from a URL.
 404
 405 =cut
 406
 407 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 408
 409 =head2 $c->go( $action [, \@arguments ] )
 410
 411 =head2 $c->go( $action [, \@captures, \@arguments ] )
 412
 413 =head2 $c->go( $class, $method, [, \@arguments ] )
 414
 415 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 416
 417 The relationship between C<go> and
 418 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 419 the relationship between
 420 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 421 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 422 C<< $c->go >> will perform a full dispatch on the specified action or method,
 423 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 424 C<go> escapes the processing of the current request chain on completion, and
 425 does not return to its caller.
 426
 427 @arguments are arguments to the final destination of $action. @captures are
 428 arguments to the intermediate steps, if any, on the way to the final sub of
 429 $action.
 430
 431 =cut
 432
 433 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 434
 435 =head2 $c->response
 436
 437 =head2 $c->res
 438
 439 Returns the current L<Catalyst::Response> object, see there for details.
 440
 441 =head2 $c->stash
 442
 443 Returns a hashref to the stash, which may be used to store data and pass
 444 it between components during a request. You can also set hash keys by
 445 passing arguments. The stash is automatically sent to the view. The
 446 stash is cleared at the end of a request; it cannot be used for
 447 persistent storage (for this you must use a session; see
 448 L<Catalyst::Plugin::Session> for a complete system integrated with
 449 Catalyst).
 450
 451     $c->stash->{foo} = $bar;
 452     $c->stash( { moose => 'majestic', qux => 0 } );
 453     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 454
 455     # stash is automatically passed to the view for use in a template
 456     $c->forward( 'MyApp::View::TT' );
 457
 458 =cut
 459
 460 around stash => sub {
 461     my $orig = shift;
 462     my $c = shift;
 463     my $stash = $orig->($c);
 464     if (@_) {
 465         my $new_stash = @_ > 1 ? {@_} : $_[0];
 466         croak('stash takes a hash or hashref') unless ref $new_stash;
 467         foreach my $key ( keys %$new_stash ) {
 468           $stash->{$key} = $new_stash->{$key};
 469         }
 470     }
 471
 472     return $stash;
 473 };
 474
 475
 476 =head2 $c->error
 477
 478 =head2 $c->error($error, ...)
 479
 480 =head2 $c->error($arrayref)
 481
 482 Returns an arrayref containing error messages.  If Catalyst encounters an
 483 error while processing a request, it stores the error in $c->error.  This
 484 method should only be used to store fatal error messages.
 485
 486     my @error = @{ $c->error };
 487
 488 Add a new error.
 489
 490     $c->error('Something bad happened');
 491
 492 =cut
 493
 494 sub error {
 495     my $c = shift;
 496     if ( $_[0] ) {
 497         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 498         croak @$error unless ref $c;
 499         push @{ $c->{error} }, @$error;
 500     }
 501     elsif ( defined $_[0] ) { $c->{error} = undef }
 502     return $c->{error} || [];
 503 }
 504
 505
 506 =head2 $c->state
 507
 508 Contains the return value of the last executed action.
 509 Note that << $c->state >> operates in a scalar context which means that all
 510 values it returns are scalar.
 511
 512 =head2 $c->clear_errors
 513
 514 Clear errors.  You probably don't want to clear the errors unless you are
 515 implementing a custom error screen.
 516
 517 This is equivalent to running
 518
 519     $c->error(0);
 520
 521 =cut
 522
 523 sub clear_errors {
 524     my $c = shift;
 525     $c->error(0);
 526 }
 527
 528 sub _comp_search_prefixes {
 529     my $c = shift;
 530     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 531 }
 532
 533 # search components given a name and some prefixes
 534 sub _comp_names_search_prefixes {
 535     my ( $c, $name, @prefixes ) = @_;
 536     my $appclass = ref $c || $c;
 537     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 538     $filter = qr/$filter/; # Compile regex now rather than once per loop
 539
 540     # map the original component name to the sub part that we will search against
 541     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 542         grep { /$filter/ } keys %{ $c->components };
 543
 544     # undef for a name will return all
 545     return keys %eligible if !defined $name;
 546
 547     my $query  = ref $name ? $name : qr/^$name$/i;
 548     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 549
 550     return @result if @result;
 551
 552     # if we were given a regexp to search against, we're done.
 553     return if ref $name;
 554
 555     # skip regexp fallback if configured
 556     return
 557         if $appclass->config->{disable_component_resolution_regex_fallback};
 558
 559     # regexp fallback
 560     $query  = qr/$name/i;
 561     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 562
 563     # no results? try against full names
 564     if( !@result ) {
 565         @result = grep { m{$query} } keys %eligible;
 566     }
 567
 568     # don't warn if we didn't find any results, it just might not exist
 569     if( @result ) {
 570         # Disgusting hack to work out correct method name
 571         my $warn_for = lc $prefixes[0];
 572         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 573            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 574            "component resolution is unreliable and unsafe.";
 575         my $short = $result[0];
 576         # remove the component namespace prefix
 577         $short =~ s/.*?(Model|Controller|View):://;
 578         my $shortmess = Carp::shortmess('');
 579         if ($shortmess =~ m#Catalyst/Plugin#) {
 580            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 581               "plugin's config";
 582         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 583            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 584               "component's config";
 585         } else {
 586            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 587               "but if you really wanted to search, pass in a regexp as the argument " .
 588               "like so: \$c->${warn_for}(qr/${name}/)";
 589         }
 590         $c->log->warn( "${msg}$shortmess" );
 591     }
 592
 593     return @result;
 594 }
 595
 596 # Find possible names for a prefix
 597 sub _comp_names {
 598     my ( $c, @prefixes ) = @_;
 599     my $appclass = ref $c || $c;
 600
 601     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 602
 603     my @names = map { s{$filter}{}; $_; }
 604         $c->_comp_names_search_prefixes( undef, @prefixes );
 605
 606     return @names;
 607 }
 608
 609 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 610 sub _filter_component {
 611     my ( $c, $comp, @args ) = @_;
 612
 613     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 614         return $comp->ACCEPT_CONTEXT( $c, @args );
 615     }
 616
 617     return $comp;
 618 }
 619
 620 =head2 COMPONENT ACCESSORS
 621
 622 =head2 $c->controller($name)
 623
 624 Gets a L<Catalyst::Controller> instance by name.
 625
 626     $c->controller('Foo')->do_stuff;
 627
 628 If the name is omitted, will return the controller for the dispatched
 629 action.
 630
 631 If you want to search for controllers, pass in a regexp as the argument.
 632
 633     # find all controllers that start with Foo
 634     my @foo_controllers = $c->controller(qr{^Foo});
 635
 636
 637 =cut
 638
 639 sub controller {
 640     my ( $c, $name, @args ) = @_;
 641
 642     my $appclass = ref($c) || $c;
 643     if( $name ) {
 644         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 645             my $comps = $c->components;
 646             my $check = $appclass."::Controller::".$name;
 647             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 648         }
 649         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 650         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 651         return $c->_filter_component( $result[ 0 ], @args );
 652     }
 653
 654     return $c->component( $c->action->class );
 655 }
 656
 657 =head2 $c->model($name)
 658
 659 Gets a L<Catalyst::Model> instance by name.
 660
 661     $c->model('Foo')->do_stuff;
 662
 663 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 664
 665 If the name is omitted, it will look for
 666  - a model object in $c->stash->{current_model_instance}, then
 667  - a model name in $c->stash->{current_model}, then
 668  - a config setting 'default_model', or
 669  - check if there is only one model, and return it if that's the case.
 670
 671 If you want to search for models, pass in a regexp as the argument.
 672
 673     # find all models that start with Foo
 674     my @foo_models = $c->model(qr{^Foo});
 675
 676 =cut
 677
 678 sub model {
 679     my ( $c, $name, @args ) = @_;
 680     my $appclass = ref($c) || $c;
 681     if( $name ) {
 682         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 683             my $comps = $c->components;
 684             my $check = $appclass."::Model::".$name;
 685             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 686         }
 687         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 688         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 689         return $c->_filter_component( $result[ 0 ], @args );
 690     }
 691
 692     if (ref $c) {
 693         return $c->stash->{current_model_instance}
 694           if $c->stash->{current_model_instance};
 695         return $c->model( $c->stash->{current_model} )
 696           if $c->stash->{current_model};
 697     }
 698     return $c->model( $appclass->config->{default_model} )
 699       if $appclass->config->{default_model};
 700
 701     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 702
 703     if( $rest ) {
 704         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 705         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 706         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 707         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 708         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 709     }
 710
 711     return $c->_filter_component( $comp );
 712 }
 713
 714
 715 =head2 $c->view($name)
 716
 717 Gets a L<Catalyst::View> instance by name.
 718
 719     $c->view('Foo')->do_stuff;
 720
 721 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 722
 723 If the name is omitted, it will look for
 724  - a view object in $c->stash->{current_view_instance}, then
 725  - a view name in $c->stash->{current_view}, then
 726  - a config setting 'default_view', or
 727  - check if there is only one view, and return it if that's the case.
 728
 729 If you want to search for views, pass in a regexp as the argument.
 730
 731     # find all views that start with Foo
 732     my @foo_views = $c->view(qr{^Foo});
 733
 734 =cut
 735
 736 sub view {
 737     my ( $c, $name, @args ) = @_;
 738
 739     my $appclass = ref($c) || $c;
 740     if( $name ) {
 741         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 742             my $comps = $c->components;
 743             my $check = $appclass."::View::".$name;
 744             if( exists $comps->{$check} ) {
 745                 return $c->_filter_component( $comps->{$check}, @args );
 746             }
 747             else {
 748                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 749             }
 750         }
 751         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 752         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 753         return $c->_filter_component( $result[ 0 ], @args );
 754     }
 755
 756     if (ref $c) {
 757         return $c->stash->{current_view_instance}
 758           if $c->stash->{current_view_instance};
 759         return $c->view( $c->stash->{current_view} )
 760           if $c->stash->{current_view};
 761     }
 762     return $c->view( $appclass->config->{default_view} )
 763       if $appclass->config->{default_view};
 764
 765     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 766
 767     if( $rest ) {
 768         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 769         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 770         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 771         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 772         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 773     }
 774
 775     return $c->_filter_component( $comp );
 776 }
 777
 778 =head2 $c->controllers
 779
 780 Returns the available names which can be passed to $c->controller
 781
 782 =cut
 783
 784 sub controllers {
 785     my ( $c ) = @_;
 786     return $c->_comp_names(qw/Controller C/);
 787 }
 788
 789 =head2 $c->models
 790
 791 Returns the available names which can be passed to $c->model
 792
 793 =cut
 794
 795 sub models {
 796     my ( $c ) = @_;
 797     return $c->_comp_names(qw/Model M/);
 798 }
 799
 800
 801 =head2 $c->views
 802
 803 Returns the available names which can be passed to $c->view
 804
 805 =cut
 806
 807 sub views {
 808     my ( $c ) = @_;
 809     return $c->_comp_names(qw/View V/);
 810 }
 811
 812 =head2 $c->comp($name)
 813
 814 =head2 $c->component($name)
 815
 816 Gets a component object by name. This method is not recommended,
 817 unless you want to get a specific component by full
 818 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 819 should be used instead.
 820
 821 If C<$name> is a regexp, a list of components matched against the full
 822 component name will be returned.
 823
 824 If Catalyst can't find a component by name, it will fallback to regex
 825 matching by default. To disable this behaviour set
 826 disable_component_resolution_regex_fallback to a true value.
 827
 828     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 829
 830 =cut
 831
 832 sub component {
 833     my ( $c, $name, @args ) = @_;
 834
 835     if( $name ) {
 836         my $comps = $c->components;
 837
 838         if( !ref $name ) {
 839             # is it the exact name?
 840             return $c->_filter_component( $comps->{ $name }, @args )
 841                        if exists $comps->{ $name };
 842
 843             # perhaps we just omitted "MyApp"?
 844             my $composed = ( ref $c || $c ) . "::${name}";
 845             return $c->_filter_component( $comps->{ $composed }, @args )
 846                        if exists $comps->{ $composed };
 847
 848             # search all of the models, views and controllers
 849             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 850             return $c->_filter_component( $comp, @args ) if $comp;
 851         }
 852
 853         return
 854             if $c->config->{disable_component_resolution_regex_fallback};
 855
 856         # This is here so $c->comp( '::M::' ) works
 857         my $query = ref $name ? $name : qr{$name}i;
 858
 859         my @result = grep { m{$query} } keys %{ $c->components };
 860         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 861
 862         if( $result[ 0 ] ) {
 863             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 864             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 865             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 866             return $c->_filter_component( $result[ 0 ], @args );
 867         }
 868
 869         # I would expect to return an empty list here, but that breaks back-compat
 870     }
 871
 872     # fallback
 873     return sort keys %{ $c->components };
 874 }
 875
 876 =head2 CLASS DATA AND HELPER CLASSES
 877
 878 =head2 $c->config
 879
 880 Returns or takes a hashref containing the application's configuration.
 881
 882     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 883
 884 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 885 like C<myapp.conf> in your applications home directory. See
 886 L<Catalyst::Plugin::ConfigLoader>.
 887
 888 =head3 Cascading configuration
 889
 890 The config method is present on all Catalyst components, and configuration
 891 will be merged when an application is started. Configuration loaded with
 892 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 893 followed by configuration in your top level C<MyApp> class. These two
 894 configurations are merged, and then configuration data whose hash key matches a
 895 component name is merged with configuration for that component.
 896
 897 The configuration for a component is then passed to the C<new> method when a
 898 component is constructed.
 899
 900 For example:
 901
 902     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 903     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 904
 905 will mean that C<MyApp::Model::Foo> receives the following data when
 906 constructed:
 907
 908     MyApp::Model::Foo->new({
 909         bar => 'baz',
 910         quux => 'frob',
 911         overrides => 'me',
 912     });
 913
 914 It's common practice to use a Moose attribute
 915 on the receiving component to access the config value.
 916
 917     package MyApp::Model::Foo;
 918
 919     use Moose;
 920
 921     # this attr will receive 'baz' at construction time
 922     has 'bar' => (
 923         is  => 'rw',
 924         isa => 'Str',
 925     );
 926
 927 You can then get the value 'baz' by calling $c->model('Foo')->bar
 928 (or $self->bar inside code in the model).
 929
 930 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 931 as a way of reading config within your code, as this B<will not> give you the
 932 correctly merged config back. You B<MUST> take the config values supplied to
 933 the constructor and use those instead.
 934
 935 =cut
 936
 937 around config => sub {
 938     my $orig = shift;
 939     my $c = shift;
 940
 941     croak('Setting config after setup has been run is not allowed.')
 942         if ( @_ and $c->setup_finished );
 943
 944     $c->$orig(@_);
 945 };
 946
 947 =head2 $c->log
 948
 949 Returns the logging object instance. Unless it is already set, Catalyst
 950 sets this up with a L<Catalyst::Log> object. To use your own log class,
 951 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 952 C<< __PACKAGE__->setup >>.
 953
 954  __PACKAGE__->log( MyLogger->new );
 955  __PACKAGE__->setup;
 956
 957 And later:
 958
 959     $c->log->info( 'Now logging with my own logger!' );
 960
 961 Your log class should implement the methods described in
 962 L<Catalyst::Log>.
 963
 964
 965 =head2 $c->debug
 966
 967 Returns 1 if debug mode is enabled, 0 otherwise.
 968
 969 You can enable debug mode in several ways:
 970
 971 =over
 972
 973 =item By calling myapp_server.pl with the -d flag
 974
 975 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 976
 977 =item The -Debug option in your MyApp.pm
 978
 979 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 980
 981 =back
 982
 983 The first three also set the log level to 'debug'.
 984
 985 Calling C<< $c->debug(1) >> has no effect.
 986
 987 =cut
 988
 989 sub debug { 0 }
 990
 991 =head2 $c->dispatcher
 992
 993 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 994
 995 =head2 $c->engine
 996
 997 Returns the engine instance. See L<Catalyst::Engine>.
 998
 999
1000 =head2 UTILITY METHODS
1001
1002 =head2 $c->path_to(@path)
1003
1004 Merges C<@path> with C<< $c->config->{home} >> and returns a
1005 L<Path::Class::Dir> object. Note you can usually use this object as
1006 a filename, but sometimes you will have to explicitly stringify it
1007 yourself by calling the C<< ->stringify >> method.
1008
1009 For example:
1010
1011     $c->path_to( 'db', 'sqlite.db' );
1012
1013 =cut
1014
1015 sub path_to {
1016     my ( $c, @path ) = @_;
1017     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1018     if ( -d $path ) { return $path }
1019     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1020 }
1021
1022 sub plugin {
1023     my ( $class, $name, $plugin, @args ) = @_;
1024
1025     # See block comment in t/unit_core_plugin.t
1026     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1027
1028     $class->_register_plugin( $plugin, 1 );
1029
1030     eval { $plugin->import };
1031     $class->mk_classdata($name);
1032     my $obj;
1033     eval { $obj = $plugin->new(@args) };
1034
1035     if ($@) {
1036         Catalyst::Exception->throw( message =>
1037               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1038     }
1039
1040     $class->$name($obj);
1041     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1042       if $class->debug;
1043 }
1044
1045 =head2 MyApp->setup
1046
1047 Initializes the dispatcher and engine, loads any plugins, and loads the
1048 model, view, and controller components. You may also specify an array
1049 of plugins to load here, if you choose to not load them in the C<use
1050 Catalyst> line.
1051
1052     MyApp->setup;
1053     MyApp->setup( qw/-Debug/ );
1054
1055 B<Note:> You B<should not> wrap this method with method modifiers
1056 or bad things will happen - wrap the C<setup_finalize> method instead.
1057
1058 =cut
1059
1060 sub setup {
1061     my ( $class, @arguments ) = @_;
1062     croak('Running setup more than once')
1063         if ( $class->setup_finished );
1064
1065     unless ( $class->isa('Catalyst') ) {
1066
1067         Catalyst::Exception->throw(
1068             message => qq/'$class' does not inherit from Catalyst/ );
1069     }
1070
1071     if ( $class->arguments ) {
1072         @arguments = ( @arguments, @{ $class->arguments } );
1073     }
1074
1075     # Process options
1076     my $flags = {};
1077
1078     foreach (@arguments) {
1079
1080         if (/^-Debug$/) {
1081             $flags->{log} =
1082               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1083         }
1084         elsif (/^-(\w+)=?(.*)$/) {
1085             $flags->{ lc $1 } = $2;
1086         }
1087         else {
1088             push @{ $flags->{plugins} }, $_;
1089         }
1090     }
1091
1092     $class->setup_home( delete $flags->{home} );
1093
1094     $class->setup_log( delete $flags->{log} );
1095     $class->setup_plugins( delete $flags->{plugins} );
1096     $class->setup_dispatcher( delete $flags->{dispatcher} );
1097     if (my $engine = delete $flags->{engine}) {
1098         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1099     }
1100     $class->setup_engine();
1101     $class->setup_stats( delete $flags->{stats} );
1102
1103     for my $flag ( sort keys %{$flags} ) {
1104
1105         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1106             &$code( $class, delete $flags->{$flag} );
1107         }
1108         else {
1109             $class->log->warn(qq/Unknown flag "$flag"/);
1110         }
1111     }
1112
1113     eval { require Catalyst::Devel; };
1114     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1115         $class->log->warn(<<"EOF");
1116 You are running an old script!
1117
1118   Please update by running (this will overwrite existing files):
1119     catalyst.pl -force -scripts $class
1120
1121   or (this will not overwrite existing files):
1122     catalyst.pl -scripts $class
1123
1124 EOF
1125     }
1126
1127     if ( $class->debug ) {
1128         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1129
1130         if (@plugins) {
1131             my $column_width = Catalyst::Utils::term_width() - 6;
1132             my $t = Text::SimpleTable->new($column_width);
1133             $t->row($_) for @plugins;
1134             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1135         }
1136
1137         my $dispatcher = $class->dispatcher;
1138         my $engine     = $class->engine;
1139         my $home       = $class->config->{home};
1140
1141         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1142         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1143
1144         $home
1145           ? ( -d $home )
1146           ? $class->log->debug(qq/Found home "$home"/)
1147           : $class->log->debug(qq/Home "$home" doesn't exist/)
1148           : $class->log->debug(q/Couldn't find home/);
1149     }
1150
1151     # Call plugins setup, this is stupid and evil.
1152     # Also screws C3 badly on 5.10, hack to avoid.
1153     {
1154         no warnings qw/redefine/;
1155         local *setup = sub { };
1156         $class->setup unless $Catalyst::__AM_RESTARTING;
1157     }
1158
1159     # Initialize our data structure
1160     $class->components( {} );
1161
1162     $class->setup_components;
1163
1164     if ( $class->debug ) {
1165         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1166         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1167         for my $comp ( sort keys %{ $class->components } ) {
1168             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1169             $t->row( $comp, $type );
1170         }
1171         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1172           if ( keys %{ $class->components } );
1173     }
1174
1175     # Add our self to components, since we are also a component
1176     if( $class->isa('Catalyst::Controller') ){
1177       $class->components->{$class} = $class;
1178     }
1179
1180     $class->setup_actions;
1181
1182     if ( $class->debug ) {
1183         my $name = $class->config->{name} || 'Application';
1184         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1185     }
1186
1187     if ($class->config->{case_sensitive}) {
1188         $class->log->warn($class . "->config->{case_sensitive} is set.");
1189         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1190     }
1191
1192     $class->setup_finalize;
1193     # Should be the last thing we do so that user things hooking
1194     # setup_finalize can log..
1195     $class->log->_flush() if $class->log->can('_flush');
1196     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1197 }
1198
1199 =head2 $app->setup_finalize
1200
1201 A hook to attach modifiers to. This method does not do anything except set the
1202 C<setup_finished> accessor.
1203
1204 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1205
1206 Example:
1207
1208     after setup_finalize => sub {
1209         my $app = shift;
1210
1211         ## do stuff here..
1212     };
1213
1214 =cut
1215
1216 sub setup_finalize {
1217     my ($class) = @_;
1218     $class->setup_finished(1);
1219 }
1220
1221 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1222
1223 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1224
1225 Constructs an absolute L<URI> object based on the application root, the
1226 provided path, and the additional arguments and query parameters provided.
1227 When used as a string, provides a textual URI.  If you need more flexibility
1228 than this (i.e. the option to provide relative URIs etc.) see
1229 L<Catalyst::Plugin::SmartURI>.
1230
1231 If no arguments are provided, the URI for the current action is returned.
1232 To return the current action and also provide @args, use
1233 C<< $c->uri_for( $c->action, @args ) >>.
1234
1235 If the first argument is a string, it is taken as a public URI path relative
1236 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1237 relative to the application root (if it does). It is then merged with
1238 C<< $c->request->base >>; any C<@args> are appended as additional path
1239 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1240
1241 If the first argument is a L<Catalyst::Action> it represents an action which
1242 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1243 optional C<\@captures> argument (an arrayref) allows passing the captured
1244 variables that are needed to fill in the paths of Chained and Regex actions;
1245 once the path is resolved, C<uri_for> continues as though a path was
1246 provided, appending any arguments or parameters and creating an absolute
1247 URI.
1248
1249 The captures for the current request can be found in
1250 C<< $c->request->captures >>, and actions can be resolved using
1251 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1252 path, use C<< $c->uri_for_action >> instead.
1253
1254   # Equivalent to $c->req->uri
1255   $c->uri_for($c->action, $c->req->captures,
1256       @{ $c->req->args }, $c->req->params);
1257
1258   # For the Foo action in the Bar controller
1259   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1260
1261   # Path to a static resource
1262   $c->uri_for('/static/images/logo.png');
1263
1264 =cut
1265
1266 sub uri_for {
1267     my ( $c, $path, @args ) = @_;
1268
1269     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1270         $path = $path->path_prefix;
1271         $path =~ s{/+\z}{};
1272         $path .= '/';
1273     }
1274
1275     undef($path) if (defined $path && $path eq '');
1276
1277     my $params =
1278       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1279
1280     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1281     foreach my $arg (@args) {
1282         utf8::encode($arg) if utf8::is_utf8($arg);
1283         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1284     }
1285
1286     if ( blessed($path) ) { # action object
1287         s|/|%2F|g for @args;
1288         my $captures = [ map { s|/|%2F|g; $_; }
1289                         ( scalar @args && ref $args[0] eq 'ARRAY'
1290                          ? @{ shift(@args) }
1291                          : ()) ];
1292
1293         foreach my $capture (@$captures) {
1294             utf8::encode($capture) if utf8::is_utf8($capture);
1295             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1296         }
1297
1298         my $action = $path;
1299         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1300         if( !@args && $action->number_of_args ) {
1301             my $expanded_action = $c->dispatcher->expand_action( $action );
1302
1303             my $num_captures = $expanded_action->number_of_captures;
1304             unshift @args, splice @$captures, $num_captures;
1305         }
1306
1307        $path = $c->dispatcher->uri_for_action($action, $captures);
1308         if (not defined $path) {
1309             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1310                 if $c->debug;
1311             return undef;
1312         }
1313         $path = '/' if $path eq '';
1314     }
1315
1316     unshift(@args, $path);
1317
1318     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1319         my $namespace = $c->namespace;
1320         if (defined $path) { # cheesy hack to handle path '../foo'
1321            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1322         }
1323         unshift(@args, $namespace || '');
1324     }
1325
1326     # join args with '/', or a blank string
1327     my $args = join('/', grep { defined($_) } @args);
1328     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1329     $args =~ s!^/+!!;
1330     my $base = $c->req->base;
1331     my $class = ref($base);
1332     $base =~ s{(?<!/)$}{/};
1333
1334     my $query = '';
1335
1336     if (my @keys = keys %$params) {
1337       # somewhat lifted from URI::_query's query_form
1338       $query = '?'.join('&', map {
1339           my $val = $params->{$_};
1340           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1341           s/ /+/g;
1342           my $key = $_;
1343           $val = '' unless defined $val;
1344           (map {
1345               my $param = "$_";
1346               utf8::encode( $param ) if utf8::is_utf8($param);
1347               # using the URI::Escape pattern here so utf8 chars survive
1348               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1349               $param =~ s/ /+/g;
1350               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1351       } @keys);
1352     }
1353
1354     my $res = bless(\"${base}${args}${query}", $class);
1355     $res;
1356 }
1357
1358 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1359
1360 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1361
1362 =over
1363
1364 =item $path
1365
1366 A private path to the Catalyst action you want to create a URI for.
1367
1368 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1369 >> and passing the resulting C<$action> and the remaining arguments to C<<
1370 $c->uri_for >>.
1371
1372 You can also pass in a Catalyst::Action object, in which case it is passed to
1373 C<< $c->uri_for >>.
1374
1375 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1376
1377 For example, if the action looks like:
1378
1379  package MyApp::Controller::Users;
1380
1381  sub lst : Path('the-list') {}
1382
1383 You can use:
1384
1385  $c->uri_for_action('/users/lst')
1386
1387 and it will create the URI /users/the-list.
1388
1389 =item \@captures_and_args?
1390
1391 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1392 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1393 to interpolate all the parameters in the URI.
1394
1395 =item @args?
1396
1397 Optional list of extra arguments - can be supplied in the
1398 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1399 code.
1400
1401 Your action can have zero, a fixed or a variable number of args (e.g.
1402 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1403
1404 =item \%query_values?
1405
1406 Optional array reference of query parameters to append. E.g.
1407
1408   { foo => 'bar' }
1409
1410 will generate
1411
1412   /rest/of/your/uri?foo=bar
1413
1414 =back
1415
1416 =cut
1417
1418 sub uri_for_action {
1419     my ( $c, $path, @args ) = @_;
1420     my $action = blessed($path)
1421       ? $path
1422       : $c->dispatcher->get_action_by_path($path);
1423     unless (defined $action) {
1424       croak "Can't find action for path '$path'";
1425     }
1426     return $c->uri_for( $action, @args );
1427 }
1428
1429 =head2 $c->welcome_message
1430
1431 Returns the Catalyst welcome HTML page.
1432
1433 =cut
1434
1435 sub welcome_message {
1436     my $c      = shift;
1437     my $name   = $c->config->{name};
1438     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1439     my $prefix = Catalyst::Utils::appprefix( ref $c );
1440     $c->response->content_type('text/html; charset=utf-8');
1441     return <<"EOF";
1442 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1443     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1444 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1445     <head>
1446     <meta http-equiv="Content-Language" content="en" />
1447     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1448         <title>$name on Catalyst $VERSION</title>
1449         <style type="text/css">
1450             body {
1451                 color: #000;
1452                 background-color: #eee;
1453             }
1454             div#content {
1455                 width: 640px;
1456                 margin-left: auto;
1457                 margin-right: auto;
1458                 margin-top: 10px;
1459                 margin-bottom: 10px;
1460                 text-align: left;
1461                 background-color: #ccc;
1462                 border: 1px solid #aaa;
1463             }
1464             p, h1, h2 {
1465                 margin-left: 20px;
1466                 margin-right: 20px;
1467                 font-family: verdana, tahoma, sans-serif;
1468             }
1469             a {
1470                 font-family: verdana, tahoma, sans-serif;
1471             }
1472             :link, :visited {
1473                     text-decoration: none;
1474                     color: #b00;
1475                     border-bottom: 1px dotted #bbb;
1476             }
1477             :link:hover, :visited:hover {
1478                     color: #555;
1479             }
1480             div#topbar {
1481                 margin: 0px;
1482             }
1483             pre {
1484                 margin: 10px;
1485                 padding: 8px;
1486             }
1487             div#answers {
1488                 padding: 8px;
1489                 margin: 10px;
1490                 background-color: #fff;
1491                 border: 1px solid #aaa;
1492             }
1493             h1 {
1494                 font-size: 0.9em;
1495                 font-weight: normal;
1496                 text-align: center;
1497             }
1498             h2 {
1499                 font-size: 1.0em;
1500             }
1501             p {
1502                 font-size: 0.9em;
1503             }
1504             p img {
1505                 float: right;
1506                 margin-left: 10px;
1507             }
1508             span#appname {
1509                 font-weight: bold;
1510                 font-size: 1.6em;
1511             }
1512         </style>
1513     </head>
1514     <body>
1515         <div id="content">
1516             <div id="topbar">
1517                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1518                     $VERSION</h1>
1519              </div>
1520              <div id="answers">
1521                  <p>
1522                  <img src="$logo" alt="Catalyst Logo" />
1523                  </p>
1524                  <p>Welcome to the  world of Catalyst.
1525                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1526                     framework will make web development something you had
1527                     never expected it to be: Fun, rewarding, and quick.</p>
1528                  <h2>What to do now?</h2>
1529                  <p>That really depends  on what <b>you</b> want to do.
1530                     We do, however, provide you with a few starting points.</p>
1531                  <p>If you want to jump right into web development with Catalyst
1532                     you might want to start with a tutorial.</p>
1533 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1534 </pre>
1535 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1536 <pre>
1537 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1538 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1539 </code></pre>
1540                  <h2>What to do next?</h2>
1541                  <p>Next it's time to write an actual application. Use the
1542                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1543                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1544                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1545                     they can save you a lot of work.</p>
1546                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1547                     <p>Also, be sure to check out the vast and growing
1548                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1549                     you are likely to find what you need there.
1550                     </p>
1551
1552                  <h2>Need help?</h2>
1553                  <p>Catalyst has a very active community. Here are the main places to
1554                     get in touch with us.</p>
1555                  <ul>
1556                      <li>
1557                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1558                      </li>
1559                      <li>
1560                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1561                      </li>
1562                      <li>
1563                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1564                      </li>
1565                  </ul>
1566                  <h2>In conclusion</h2>
1567                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1568                     as we enjoyed making it. Please contact us if you have ideas
1569                     for improvement or other feedback.</p>
1570              </div>
1571          </div>
1572     </body>
1573 </html>
1574 EOF
1575 }
1576
1577 =head2 run_options
1578
1579 Contains a hash of options passed from the application script, including
1580 the original ARGV the script received, the processed values from that
1581 ARGV and any extra arguments to the script which were not processed.
1582
1583 This can be used to add custom options to your application's scripts
1584 and setup your application differently depending on the values of these
1585 options.
1586
1587 =head1 INTERNAL METHODS
1588
1589 These methods are not meant to be used by end users.
1590
1591 =head2 $c->components
1592
1593 Returns a hash of components.
1594
1595 =head2 $c->context_class
1596
1597 Returns or sets the context class.
1598
1599 =head2 $c->counter
1600
1601 Returns a hashref containing coderefs and execution counts (needed for
1602 deep recursion detection).
1603
1604 =head2 $c->depth
1605
1606 Returns the number of actions on the current internal execution stack.
1607
1608 =head2 $c->dispatch
1609
1610 Dispatches a request to actions.
1611
1612 =cut
1613
1614 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1615
1616 =head2 $c->dispatcher_class
1617
1618 Returns or sets the dispatcher class.
1619
1620 =head2 $c->dump_these
1621
1622 Returns a list of 2-element array references (name, structure) pairs
1623 that will be dumped on the error page in debug mode.
1624
1625 =cut
1626
1627 sub dump_these {
1628     my $c = shift;
1629     [ Request => $c->req ],
1630     [ Response => $c->res ],
1631     [ Stash => $c->stash ],
1632     [ Config => $c->config ];
1633 }
1634
1635 =head2 $c->engine_class
1636
1637 Returns or sets the engine class.
1638
1639 =head2 $c->execute( $class, $coderef )
1640
1641 Execute a coderef in given class and catch exceptions. Errors are available
1642 via $c->error.
1643
1644 =cut
1645
1646 sub execute {
1647     my ( $c, $class, $code ) = @_;
1648     $class = $c->component($class) || $class;
1649     $c->state(0);
1650
1651     if ( $c->depth >= $RECURSION ) {
1652         my $action = $code->reverse();
1653         $action = "/$action" unless $action =~ /->/;
1654         my $error = qq/Deep recursion detected calling "${action}"/;
1655         $c->log->error($error);
1656         $c->error($error);
1657         $c->state(0);
1658         return $c->state;
1659     }
1660
1661     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1662
1663     push( @{ $c->stack }, $code );
1664
1665     no warnings 'recursion';
1666     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1667     #      I have no idea how, ergo $ret (which appears to fix the issue)
1668     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1669
1670     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1671
1672     my $last = pop( @{ $c->stack } );
1673
1674     if ( my $error = $@ ) {
1675         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1676             $error->rethrow if $c->depth > 1;
1677         }
1678         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1679             $error->rethrow if $c->depth > 0;
1680         }
1681         else {
1682             unless ( ref $error ) {
1683                 no warnings 'uninitialized';
1684                 chomp $error;
1685                 my $class = $last->class;
1686                 my $name  = $last->name;
1687                 $error = qq/Caught exception in $class->$name "$error"/;
1688             }
1689             $c->error($error);
1690         }
1691         $c->state(0);
1692     }
1693     return $c->state;
1694 }
1695
1696 sub _stats_start_execute {
1697     my ( $c, $code ) = @_;
1698     my $appclass = ref($c) || $c;
1699     return if ( ( $code->name =~ /^_.*/ )
1700         && ( !$appclass->config->{show_internal_actions} ) );
1701
1702     my $action_name = $code->reverse();
1703     $c->counter->{$action_name}++;
1704
1705     my $action = $action_name;
1706     $action = "/$action" unless $action =~ /->/;
1707
1708     # determine if the call was the result of a forward
1709     # this is done by walking up the call stack and looking for a calling
1710     # sub of Catalyst::forward before the eval
1711     my $callsub = q{};
1712     for my $index ( 2 .. 11 ) {
1713         last
1714         if ( ( caller($index) )[0] eq 'Catalyst'
1715             && ( caller($index) )[3] eq '(eval)' );
1716
1717         if ( ( caller($index) )[3] =~ /forward$/ ) {
1718             $callsub = ( caller($index) )[3];
1719             $action  = "-> $action";
1720             last;
1721         }
1722     }
1723
1724     my $uid = $action_name . $c->counter->{$action_name};
1725
1726     # is this a root-level call or a forwarded call?
1727     if ( $callsub =~ /forward$/ ) {
1728         my $parent = $c->stack->[-1];
1729
1730         # forward, locate the caller
1731         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1732             $c->stats->profile(
1733                 begin  => $action,
1734                 parent => "$parent" . $c->counter->{"$parent"},
1735                 uid    => $uid,
1736             );
1737         }
1738         else {
1739
1740             # forward with no caller may come from a plugin
1741             $c->stats->profile(
1742                 begin => $action,
1743                 uid   => $uid,
1744             );
1745         }
1746     }
1747     else {
1748
1749         # root-level call
1750         $c->stats->profile(
1751             begin => $action,
1752             uid   => $uid,
1753         );
1754     }
1755     return $action;
1756
1757 }
1758
1759 sub _stats_finish_execute {
1760     my ( $c, $info ) = @_;
1761     $c->stats->profile( end => $info );
1762 }
1763
1764 =head2 $c->finalize
1765
1766 Finalizes the request.
1767
1768 =cut
1769
1770 sub finalize {
1771     my $c = shift;
1772
1773     for my $error ( @{ $c->error } ) {
1774         $c->log->error($error);
1775     }
1776
1777     # Allow engine to handle finalize flow (for POE)
1778     my $engine = $c->engine;
1779     if ( my $code = $engine->can('finalize') ) {
1780         $engine->$code($c);
1781     }
1782     else {
1783
1784         $c->finalize_uploads;
1785
1786         # Error
1787         if ( $#{ $c->error } >= 0 ) {
1788             $c->finalize_error;
1789         }
1790
1791         $c->finalize_headers;
1792
1793         # HEAD request
1794         if ( $c->request->method eq 'HEAD' ) {
1795             $c->response->body('');
1796         }
1797
1798         $c->finalize_body;
1799     }
1800
1801     $c->log_response;
1802
1803     if ($c->use_stats) {
1804         my $elapsed = sprintf '%f', $c->stats->elapsed;
1805         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1806         $c->log->info(
1807             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1808     }
1809
1810     return $c->response->status;
1811 }
1812
1813 =head2 $c->finalize_body
1814
1815 Finalizes body.
1816
1817 =cut
1818
1819 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1820
1821 =head2 $c->finalize_cookies
1822
1823 Finalizes cookies.
1824
1825 =cut
1826
1827 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1828
1829 =head2 $c->finalize_error
1830
1831 Finalizes error.
1832
1833 =cut
1834
1835 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1836
1837 =head2 $c->finalize_headers
1838
1839 Finalizes headers.
1840
1841 =cut
1842
1843 sub finalize_headers {
1844     my $c = shift;
1845
1846     my $response = $c->response; #accessor calls can add up?
1847
1848     # Check if we already finalized headers
1849     return if $response->finalized_headers;
1850
1851     # Handle redirects
1852     if ( my $location = $response->redirect ) {
1853         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1854         $response->header( Location => $location );
1855
1856         if ( !$response->has_body ) {
1857             # Add a default body if none is already present
1858             $response->body(<<"EOF");
1859 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1860 <html xmlns="http://www.w3.org/1999/xhtml">
1861   <head>
1862     <title>Moved</title>
1863   </head>
1864   <body>
1865      <p>This item has moved <a href="$location">here</a>.</p>
1866   </body>
1867 </html>
1868 EOF
1869             $response->content_type('text/html; charset=utf-8');
1870         }
1871     }
1872
1873     # Content-Length
1874     if ( defined $response->body && length $response->body && !$response->content_length ) {
1875
1876         # get the length from a filehandle
1877         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1878         {
1879             my $size = -s $response->body;
1880             if ( $size ) {
1881                 $response->content_length( $size );
1882             }
1883             else {
1884                 $c->log->warn('Serving filehandle without a content-length');
1885             }
1886         }
1887         else {
1888             # everything should be bytes at this point, but just in case
1889             $response->content_length( length( $response->body ) );
1890         }
1891     }
1892
1893     # Errors
1894     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1895         $response->headers->remove_header("Content-Length");
1896         $response->body('');
1897     }
1898
1899     $c->finalize_cookies;
1900
1901     $c->engine->finalize_headers( $c, @_ );
1902
1903     # Done
1904     $response->finalized_headers(1);
1905 }
1906
1907 =head2 $c->finalize_output
1908
1909 An alias for finalize_body.
1910
1911 =head2 $c->finalize_read
1912
1913 Finalizes the input after reading is complete.
1914
1915 =cut
1916
1917 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1918
1919 =head2 $c->finalize_uploads
1920
1921 Finalizes uploads. Cleans up any temporary files.
1922
1923 =cut
1924
1925 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1926
1927 =head2 $c->get_action( $action, $namespace )
1928
1929 Gets an action in a given namespace.
1930
1931 =cut
1932
1933 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1934
1935 =head2 $c->get_actions( $action, $namespace )
1936
1937 Gets all actions of a given name in a namespace and all parent
1938 namespaces.
1939
1940 =cut
1941
1942 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1943
1944 =head2 $app->handle_request( @arguments )
1945
1946 Called to handle each HTTP request.
1947
1948 =cut
1949
1950 sub handle_request {
1951     my ( $class, @arguments ) = @_;
1952
1953     # Always expect worst case!
1954     my $status = -1;
1955     try {
1956         if ($class->debug) {
1957             my $secs = time - $START || 1;
1958             my $av = sprintf '%.3f', $COUNT / $secs;
1959             my $time = localtime time;
1960             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1961         }
1962
1963         my $c = $class->prepare(@arguments);
1964         $c->dispatch;
1965         $status = $c->finalize;
1966     }
1967     catch {
1968         chomp(my $error = $_);
1969         $class->log->error(qq/Caught exception in engine "$error"/);
1970     };
1971
1972     $COUNT++;
1973
1974     if(my $coderef = $class->log->can('_flush')){
1975         $class->log->$coderef();
1976     }
1977     return $status;
1978 }
1979
1980 =head2 $class->prepare( @arguments )
1981
1982 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1983 etc.).
1984
1985 =cut
1986
1987 has _uploadtmp => (
1988     is => 'ro',
1989     predicate => '_has_uploadtmp',
1990 );
1991
1992 sub prepare {
1993     my ( $class, @arguments ) = @_;
1994
1995     # XXX
1996     # After the app/ctxt split, this should become an attribute based on something passed
1997     # into the application.
1998     $class->context_class( ref $class || $class ) unless $class->context_class;
1999
2000     my $uploadtmp = $class->config->{uploadtmp};
2001     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2002
2003     #surely this is not the most efficient way to do things...
2004     $c->stats($class->stats_class->new)->enable($c->use_stats);
2005     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2006         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2007     }
2008
2009     try {
2010         # Allow engine to direct the prepare flow (for POE)
2011         if ( my $prepare = $c->engine->can('prepare') ) {
2012             $c->engine->$prepare( $c, @arguments );
2013         }
2014         else {
2015             $c->prepare_request(@arguments);
2016             $c->prepare_connection;
2017             $c->prepare_query_parameters;
2018             $c->prepare_headers; # Just hooks, no longer needed - they just
2019             $c->prepare_cookies; # cause the lazy attribute on req to build
2020             $c->prepare_path;
2021
2022             # Prepare the body for reading, either by prepare_body
2023             # or the user, if they are using $c->read
2024             $c->prepare_read;
2025
2026             # Parse the body unless the user wants it on-demand
2027             unless ( ref($c)->config->{parse_on_demand} ) {
2028                 $c->prepare_body;
2029             }
2030         }
2031         $c->prepare_action;
2032     }
2033     # VERY ugly and probably shouldn't rely on ->finalize actually working
2034     catch {
2035         # failed prepare is always due to an invalid request, right?
2036         $c->response->status(400);
2037         $c->response->content_type('text/plain');
2038         $c->response->body('Bad Request');
2039         # Note we call finalize and then die here, which escapes
2040         # finalize being called in the enclosing block..
2041         # It in fact couldn't be called, as we don't return $c..
2042         # This is a mess - but I'm unsure you can fix this without
2043         # breaking compat for people doing crazy things (we should set
2044         # the 400 and just return the ctx here IMO, letting finalize get called
2045         # above...
2046         $c->finalize;
2047         die $_;
2048     };
2049
2050     $c->log_request;
2051
2052     return $c;
2053 }
2054
2055 =head2 $c->prepare_action
2056
2057 Prepares action. See L<Catalyst::Dispatcher>.
2058
2059 =cut
2060
2061 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2062
2063 =head2 $c->prepare_body
2064
2065 Prepares message body.
2066
2067 =cut
2068
2069 sub prepare_body {
2070     my $c = shift;
2071
2072     return if $c->request->_has_body;
2073
2074     # Initialize on-demand data
2075     $c->engine->prepare_body( $c, @_ );
2076     $c->prepare_parameters;
2077     $c->prepare_uploads;
2078 }
2079
2080 =head2 $c->prepare_body_chunk( $chunk )
2081
2082 Prepares a chunk of data before sending it to L<HTTP::Body>.
2083
2084 See L<Catalyst::Engine>.
2085
2086 =cut
2087
2088 sub prepare_body_chunk {
2089     my $c = shift;
2090     $c->engine->prepare_body_chunk( $c, @_ );
2091 }
2092
2093 =head2 $c->prepare_body_parameters
2094
2095 Prepares body parameters.
2096
2097 =cut
2098
2099 sub prepare_body_parameters {
2100     my $c = shift;
2101     $c->engine->prepare_body_parameters( $c, @_ );
2102 }
2103
2104 =head2 $c->prepare_connection
2105
2106 Prepares connection.
2107
2108 =cut
2109
2110 sub prepare_connection {
2111     my $c = shift;
2112     # XXX - This is called on the engine (not the request) to maintain
2113     #       Engine::PSGI back compat.
2114     $c->engine->prepare_connection($c);
2115 }
2116
2117 =head2 $c->prepare_cookies
2118
2119 Prepares cookies by ensuring that the attribute on the request
2120 object has been built.
2121
2122 =cut
2123
2124 sub prepare_cookies { my $c = shift; $c->request->cookies }
2125
2126 =head2 $c->prepare_headers
2127
2128 Prepares request headers by ensuring that the attribute on the request
2129 object has been built.
2130
2131 =cut
2132
2133 sub prepare_headers { my $c = shift; $c->request->headers }
2134
2135 =head2 $c->prepare_parameters
2136
2137 Prepares parameters.
2138
2139 =cut
2140
2141 sub prepare_parameters {
2142     my $c = shift;
2143     $c->prepare_body_parameters;
2144     $c->engine->prepare_parameters( $c, @_ );
2145 }
2146
2147 =head2 $c->prepare_path
2148
2149 Prepares path and base.
2150
2151 =cut
2152
2153 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2154
2155 =head2 $c->prepare_query_parameters
2156
2157 Prepares query parameters.
2158
2159 =cut
2160
2161 sub prepare_query_parameters {
2162     my $c = shift;
2163
2164     $c->engine->prepare_query_parameters( $c, @_ );
2165 }
2166
2167 =head2 $c->log_request
2168
2169 Writes information about the request to the debug logs.  This includes:
2170
2171 =over 4
2172
2173 =item * Request method, path, and remote IP address
2174
2175 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2176
2177 =item * Request parameters
2178
2179 =item * File uploads
2180
2181 =back
2182
2183 =cut
2184
2185 sub log_request {
2186     my $c = shift;
2187
2188     return unless $c->debug;
2189
2190     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2191     my $request = $dump->[1];
2192
2193     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2194     $method ||= '';
2195     $path = '/' unless length $path;
2196     $address ||= '';
2197     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2198
2199     $c->log_request_headers($request->headers);
2200
2201     if ( my $keywords = $request->query_keywords ) {
2202         $c->log->debug("Query keywords are: $keywords");
2203     }
2204
2205     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2206
2207     $c->log_request_uploads($request);
2208 }
2209
2210 =head2 $c->log_response
2211
2212 Writes information about the response to the debug logs by calling
2213 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2214
2215 =cut
2216
2217 sub log_response {
2218     my $c = shift;
2219
2220     return unless $c->debug;
2221
2222     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2223     my $response = $dump->[1];
2224
2225     $c->log_response_status_line($response);
2226     $c->log_response_headers($response->headers);
2227 }
2228
2229 =head2 $c->log_response_status_line($response)
2230
2231 Writes one line of information about the response to the debug logs.  This includes:
2232
2233 =over 4
2234
2235 =item * Response status code
2236
2237 =item * Content-Type header (if present)
2238
2239 =item * Content-Length header (if present)
2240
2241 =back
2242
2243 =cut
2244
2245 sub log_response_status_line {
2246     my ($c, $response) = @_;
2247
2248     $c->log->debug(
2249         sprintf(
2250             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2251             $response->status                            || 'unknown',
2252             $response->headers->header('Content-Type')   || 'unknown',
2253             $response->headers->header('Content-Length') || 'unknown'
2254         )
2255     );
2256 }
2257
2258 =head2 $c->log_response_headers($headers);
2259
2260 Hook method which can be wrapped by plugins to log the response headers.
2261 No-op in the default implementation.
2262
2263 =cut
2264
2265 sub log_response_headers {}
2266
2267 =head2 $c->log_request_parameters( query => {}, body => {} )
2268
2269 Logs request parameters to debug logs
2270
2271 =cut
2272
2273 sub log_request_parameters {
2274     my $c          = shift;
2275     my %all_params = @_;
2276
2277     return unless $c->debug;
2278
2279     my $column_width = Catalyst::Utils::term_width() - 44;
2280     foreach my $type (qw(query body)) {
2281         my $params = $all_params{$type};
2282         next if ! keys %$params;
2283         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2284         for my $key ( sort keys %$params ) {
2285             my $param = $params->{$key};
2286             my $value = defined($param) ? $param : '';
2287             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2288         }
2289         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2290     }
2291 }
2292
2293 =head2 $c->log_request_uploads
2294
2295 Logs file uploads included in the request to the debug logs.
2296 The parameter name, filename, file type, and file size are all included in
2297 the debug logs.
2298
2299 =cut
2300
2301 sub log_request_uploads {
2302     my $c = shift;
2303     my $request = shift;
2304     return unless $c->debug;
2305     my $uploads = $request->uploads;
2306     if ( keys %$uploads ) {
2307         my $t = Text::SimpleTable->new(
2308             [ 12, 'Parameter' ],
2309             [ 26, 'Filename' ],
2310             [ 18, 'Type' ],
2311             [ 9,  'Size' ]
2312         );
2313         for my $key ( sort keys %$uploads ) {
2314             my $upload = $uploads->{$key};
2315             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2316                 $t->row( $key, $u->filename, $u->type, $u->size );
2317             }
2318         }
2319         $c->log->debug( "File Uploads are:\n" . $t->draw );
2320     }
2321 }
2322
2323 =head2 $c->log_request_headers($headers);
2324
2325 Hook method which can be wrapped by plugins to log the request headers.
2326 No-op in the default implementation.
2327
2328 =cut
2329
2330 sub log_request_headers {}
2331
2332 =head2 $c->log_headers($type => $headers)
2333
2334 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2335
2336 =cut
2337
2338 sub log_headers {
2339     my $c       = shift;
2340     my $type    = shift;
2341     my $headers = shift;    # an HTTP::Headers instance
2342
2343     return unless $c->debug;
2344
2345     my $column_width = Catalyst::Utils::term_width() - 28;
2346     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2347     $headers->scan(
2348         sub {
2349             my ( $name, $value ) = @_;
2350             $t->row( $name, $value );
2351         }
2352     );
2353     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2354 }
2355
2356
2357 =head2 $c->prepare_read
2358
2359 Prepares the input for reading.
2360
2361 =cut
2362
2363 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2364
2365 =head2 $c->prepare_request
2366
2367 Prepares the engine request.
2368
2369 =cut
2370
2371 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2372
2373 =head2 $c->prepare_uploads
2374
2375 Prepares uploads.
2376
2377 =cut
2378
2379 sub prepare_uploads {
2380     my $c = shift;
2381
2382     $c->engine->prepare_uploads( $c, @_ );
2383 }
2384
2385 =head2 $c->prepare_write
2386
2387 Prepares the output for writing.
2388
2389 =cut
2390
2391 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2392
2393 =head2 $c->request_class
2394
2395 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2396
2397 =head2 $c->response_class
2398
2399 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2400
2401 =head2 $c->read( [$maxlength] )
2402
2403 Reads a chunk of data from the request body. This method is designed to
2404 be used in a while loop, reading C<$maxlength> bytes on every call.
2405 C<$maxlength> defaults to the size of the request if not specified.
2406
2407 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2408 directly.
2409
2410 Warning: If you use read(), Catalyst will not process the body,
2411 so you will not be able to access POST parameters or file uploads via
2412 $c->request.  You must handle all body parsing yourself.
2413
2414 =cut
2415
2416 sub read { my $c = shift; return $c->request->read( @_ ) }
2417
2418 =head2 $c->run
2419
2420 Starts the engine.
2421
2422 =cut
2423
2424 sub run {
2425   my $app = shift;
2426   $app->_make_immutable_if_needed;
2427   $app->engine_loader->needs_psgi_engine_compat_hack ?
2428     $app->engine->run($app, @_) :
2429       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2430 }
2431
2432 sub _make_immutable_if_needed {
2433     my $class = shift;
2434     my $meta = Class::MOP::get_metaclass_by_name($class);
2435     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2436     if (
2437         $meta->is_immutable
2438         && ! { $meta->immutable_options }->{replace_constructor}
2439         && $isa_ca
2440     ) {
2441         warn("You made your application class ($class) immutable, "
2442             . "but did not inline the\nconstructor. "
2443             . "This will break catalyst, as your app \@ISA "
2444             . "Class::Accessor(::Fast)?\nPlease pass "
2445             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2446     }
2447     unless ($meta->is_immutable) {
2448         # XXX - FIXME warning here as you should make your app immutable yourself.
2449         $meta->make_immutable(
2450             replace_constructor => 1,
2451         );
2452     }
2453 }
2454
2455 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2456
2457 Sets an action in a given namespace.
2458
2459 =cut
2460
2461 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2462
2463 =head2 $c->setup_actions($component)
2464
2465 Sets up actions for a component.
2466
2467 =cut
2468
2469 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2470
2471 =head2 $c->setup_components
2472
2473 This method is called internally to set up the application's components.
2474
2475 It finds modules by calling the L<locate_components> method, expands them to
2476 package names with the L<expand_component_module> method, and then installs
2477 each component into the application.
2478
2479 The C<setup_components> config option is passed to both of the above methods.
2480
2481 Installation of each component is performed by the L<setup_component> method,
2482 below.
2483
2484 =cut
2485
2486 sub setup_components {
2487     my $class = shift;
2488
2489     my $config  = $class->config->{ setup_components };
2490
2491     my @comps = $class->locate_components($config);
2492     my %comps = map { $_ => 1 } @comps;
2493
2494     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2495     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2496         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2497     ) if $deprecatedcatalyst_component_names;
2498
2499     for my $component ( @comps ) {
2500
2501         # We pass ignore_loaded here so that overlay files for (e.g.)
2502         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2503         # we know M::P::O found a file on disk so this is safe
2504
2505         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2506     }
2507
2508     for my $component (@comps) {
2509         my $instance = $class->components->{ $component } = $class->setup_component($component);
2510         my @expanded_components = $instance->can('expand_modules')
2511             ? $instance->expand_modules( $component, $config )
2512             : $class->expand_component_module( $component, $config );
2513         for my $component (@expanded_components) {
2514             next if $comps{$component};
2515             $class->components->{ $component } = $class->setup_component($component);
2516         }
2517     }
2518 }
2519
2520 =head2 $c->locate_components( $setup_component_config )
2521
2522 This method is meant to provide a list of component modules that should be
2523 setup for the application.  By default, it will use L<Module::Pluggable>.
2524
2525 Specify a C<setup_components> config option to pass additional options directly
2526 to L<Module::Pluggable>. To add additional search paths, specify a key named
2527 C<search_extra> as an array reference. Items in the array beginning with C<::>
2528 will have the application class name prepended to them.
2529
2530 =cut
2531
2532 sub locate_components {
2533     my $class  = shift;
2534     my $config = shift;
2535
2536     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2537     my $extra   = delete $config->{ search_extra } || [];
2538
2539     push @paths, @$extra;
2540
2541     my $locator = Module::Pluggable::Object->new(
2542         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2543         %$config
2544     );
2545
2546     # XXX think about ditching this sort entirely
2547     my @comps = sort { length $a <=> length $b } $locator->plugins;
2548
2549     return @comps;
2550 }
2551
2552 =head2 $c->expand_component_module( $component, $setup_component_config )
2553
2554 Components found by C<locate_components> will be passed to this method, which
2555 is expected to return a list of component (package) names to be set up.
2556
2557 =cut
2558
2559 sub expand_component_module {
2560     my ($class, $module) = @_;
2561     return Devel::InnerPackage::list_packages( $module );
2562 }
2563
2564 =head2 $c->setup_component
2565
2566 =cut
2567
2568 sub setup_component {
2569     my( $class, $component ) = @_;
2570
2571     unless ( $component->can( 'COMPONENT' ) ) {
2572         return $component;
2573     }
2574
2575     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2576     my $config = $class->config->{ $suffix } || {};
2577     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2578     # methods also pass it. local to avoid pointlessly shitting in config
2579     # for the debug screen, as $component is already the key name.
2580     local $config->{catalyst_component_name} = $component;
2581
2582     my $instance = eval { $component->COMPONENT( $class, $config ); };
2583
2584     if ( my $error = $@ ) {
2585         chomp $error;
2586         Catalyst::Exception->throw(
2587             message => qq/Couldn't instantiate component "$component", "$error"/
2588         );
2589     }
2590
2591     unless (blessed $instance) {
2592         my $metaclass = Moose::Util::find_meta($component);
2593         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2594         my $component_method_from = $method_meta->associated_metaclass->name;
2595         my $value = defined($instance) ? $instance : 'undef';
2596         Catalyst::Exception->throw(
2597             message =>
2598             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2599         );
2600     }
2601     return $instance;
2602 }
2603
2604 =head2 $c->setup_dispatcher
2605
2606 Sets up dispatcher.
2607
2608 =cut
2609
2610 sub setup_dispatcher {
2611     my ( $class, $dispatcher ) = @_;
2612
2613     if ($dispatcher) {
2614         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2615     }
2616
2617     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2618         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2619     }
2620
2621     unless ($dispatcher) {
2622         $dispatcher = $class->dispatcher_class;
2623     }
2624
2625     Class::MOP::load_class($dispatcher);
2626
2627     # dispatcher instance
2628     $class->dispatcher( $dispatcher->new );
2629 }
2630
2631 =head2 $c->setup_engine
2632
2633 Sets up engine.
2634
2635 =cut
2636
2637 sub engine_class {
2638     my ($class, $requested_engine) = @_;
2639
2640     if (!$class->engine_loader || $requested_engine) {
2641         $class->engine_loader(
2642             Catalyst::EngineLoader->new({
2643                 application_name => $class,
2644                 (defined $requested_engine
2645                      ? (catalyst_engine_class => $requested_engine) : ()),
2646             }),
2647         );
2648     }
2649
2650     $class->engine_loader->catalyst_engine_class;
2651 }
2652
2653 sub setup_engine {
2654     my ($class, $requested_engine) = @_;
2655
2656     my $engine = do {
2657         my $loader = $class->engine_loader;
2658
2659         if (!$loader || $requested_engine) {
2660             $loader = Catalyst::EngineLoader->new({
2661                 application_name => $class,
2662                 (defined $requested_engine
2663                      ? (requested_engine => $requested_engine) : ()),
2664             }),
2665
2666             $class->engine_loader($loader);
2667         }
2668
2669         $loader->catalyst_engine_class;
2670     };
2671
2672     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2673     return if $class->loading_psgi_file;
2674
2675     Class::MOP::load_class($engine);
2676
2677     if ($ENV{MOD_PERL}) {
2678         my $apache = $class->engine_loader->auto;
2679
2680         my $meta = find_meta($class);
2681         my $was_immutable = $meta->is_immutable;
2682         my %immutable_options = $meta->immutable_options;
2683         $meta->make_mutable if $was_immutable;
2684
2685         $meta->add_method(handler => sub {
2686             my $r = shift;
2687             my $psgi_app = $class->_finalized_psgi_app;
2688             $apache->call_app($r, $psgi_app);
2689         });
2690
2691         $meta->make_immutable(%immutable_options) if $was_immutable;
2692     }
2693
2694     $class->engine( $engine->new );
2695
2696     return;
2697 }
2698
2699 sub _finalized_psgi_app {
2700     my ($app) = @_;
2701
2702     unless ($app->_psgi_app) {
2703         my $psgi_app = $app->_setup_psgi_app;
2704         $app->_psgi_app($psgi_app);
2705     }
2706
2707     return $app->_psgi_app;
2708 }
2709
2710 sub _setup_psgi_app {
2711     my ($app) = @_;
2712
2713     for my $home (Path::Class::Dir->new($app->config->{home})) {
2714         my $psgi_file = $home->file(
2715             Catalyst::Utils::appprefix($app) . '.psgi',
2716         );
2717
2718         next unless -e $psgi_file;
2719
2720         # If $psgi_file calls ->setup_engine, it's doing so to load
2721         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2722         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2723         # anyway. So set a flag (ick) that tells setup_engine not to populate
2724         # $c->engine or do any other things we might regret.
2725
2726         $app->loading_psgi_file(1);
2727         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2728         $app->loading_psgi_file(0);
2729
2730         return $psgi_app
2731             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2732
2733         warn <<"EOW";
2734 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2735
2736 Its content has been ignored. Please consult the Catalyst::Upgrading
2737 documentation on how to upgrade from Catalyst::Engine::PSGI.
2738 EOW
2739     }
2740
2741     return $app->apply_default_middlewares($app->psgi_app);
2742 }
2743
2744 =head2 $c->apply_default_middlewares
2745
2746 Adds the following L<Plack> middlewares to your application, since they are
2747 useful and commonly needed:
2748
2749 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2750 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2751 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2752 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2753 applied since this middleware is smart enough to conditionally apply itself).
2754
2755 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2756 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2757 $ENV{SCRIPT_NAME}
2758
2759 =cut
2760
2761
2762 sub apply_default_middlewares {
2763     my ($app, $psgi_app) = @_;
2764
2765     $psgi_app = Plack::Middleware::Conditional->wrap(
2766         $psgi_app,
2767         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2768         condition => sub {
2769             my ($env) = @_;
2770             return if $app->config->{ignore_frontend_proxy};
2771             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2772                 || $app->config->{using_frontend_proxy};
2773         },
2774     );
2775
2776     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2777     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2778     $psgi_app = Plack::Middleware::Conditional->wrap(
2779         $psgi_app,
2780         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2781         condition => sub {
2782             my ($env) = @_;
2783             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2784             return unless $1 < 4.23;
2785             1;
2786         },
2787     );
2788
2789     # we're applying this unconditionally as the middleware itself already makes
2790     # sure it doesn't fuck things up if it's not running under one of the right
2791     # IIS versions
2792     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2793
2794     return $psgi_app;
2795 }
2796
2797 =head2 $c->psgi_app
2798
2799 Returns a PSGI application code reference for the catalyst application
2800 C<$c>. This is the bare application without any middlewares
2801 applied. C<${myapp}.psgi> is not taken into account.
2802
2803 This is what you want to be using to retrieve the PSGI application code
2804 reference of your Catalyst application for use in F<.psgi> files.
2805
2806 =cut
2807
2808 sub psgi_app {
2809     my ($app) = @_;
2810     return $app->engine->build_psgi_app($app);
2811 }
2812
2813 =head2 $c->setup_home
2814
2815 Sets up the home directory.
2816
2817 =cut
2818
2819 sub setup_home {
2820     my ( $class, $home ) = @_;
2821
2822     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2823         $home = $env;
2824     }
2825
2826     $home ||= Catalyst::Utils::home($class);
2827
2828     if ($home) {
2829         #I remember recently being scolded for assigning config values like this
2830         $class->config->{home} ||= $home;
2831         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2832     }
2833 }
2834
2835 =head2 $c->setup_log
2836
2837 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2838 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2839 log to.
2840
2841 This method also installs a C<debug> method that returns a true value into the
2842 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2843 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2844
2845 Note that if the log has already been setup, by either a previous call to
2846 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2847 that this method won't actually set up the log object.
2848
2849 =cut
2850
2851 sub setup_log {
2852     my ( $class, $levels ) = @_;
2853
2854     $levels ||= '';
2855     $levels =~ s/^\s+//;
2856     $levels =~ s/\s+$//;
2857     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2858
2859     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2860     if ( defined $env_debug ) {
2861         $levels{debug} = 1 if $env_debug; # Ugly!
2862         delete($levels{debug}) unless $env_debug;
2863     }
2864
2865     unless ( $class->log ) {
2866         $class->log( Catalyst::Log->new(keys %levels) );
2867     }
2868
2869     if ( $levels{debug} ) {
2870         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2871         $class->log->debug('Debug messages enabled');
2872     }
2873 }
2874
2875 =head2 $c->setup_plugins
2876
2877 Sets up plugins.
2878
2879 =cut
2880
2881 =head2 $c->setup_stats
2882
2883 Sets up timing statistics class.
2884
2885 =cut
2886
2887 sub setup_stats {
2888     my ( $class, $stats ) = @_;
2889
2890     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2891
2892     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2893     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2894         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2895         $class->log->debug('Statistics enabled');
2896     }
2897 }
2898
2899
2900 =head2 $c->registered_plugins
2901
2902 Returns a sorted list of the plugins which have either been stated in the
2903 import list.
2904
2905 If passed a given plugin name, it will report a boolean value indicating
2906 whether or not that plugin is loaded.  A fully qualified name is required if
2907 the plugin name does not begin with C<Catalyst::Plugin::>.
2908
2909  if ($c->registered_plugins('Some::Plugin')) {
2910      ...
2911  }
2912
2913 =cut
2914
2915 {
2916
2917     sub registered_plugins {
2918         my $proto = shift;
2919         return sort keys %{ $proto->_plugins } unless @_;
2920         my $plugin = shift;
2921         return 1 if exists $proto->_plugins->{$plugin};
2922         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2923     }
2924
2925     sub _register_plugin {
2926         my ( $proto, $plugin, $instant ) = @_;
2927         my $class = ref $proto || $proto;
2928
2929         Class::MOP::load_class( $plugin );
2930         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2931             if $plugin->isa( 'Catalyst::Component' );
2932         my $plugin_meta = Moose::Meta::Class->create($plugin);
2933         if (!$plugin_meta->has_method('new')
2934             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
2935             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
2936         }
2937         if (!$instant && !$proto->_plugins->{$plugin}) {
2938             my $meta = Class::MOP::get_metaclass_by_name($class);
2939             $meta->superclasses($plugin, $meta->superclasses);
2940         }
2941         $proto->_plugins->{$plugin} = 1;
2942         return $class;
2943     }
2944
2945     sub setup_plugins {
2946         my ( $class, $plugins ) = @_;
2947
2948         $class->_plugins( {} ) unless $class->_plugins;
2949         $plugins = Data::OptList::mkopt($plugins || []);
2950
2951         my @plugins = map {
2952             [ Catalyst::Utils::resolve_namespace(
2953                   $class . '::Plugin',
2954                   'Catalyst::Plugin', $_->[0]
2955               ),
2956               $_->[1],
2957             ]
2958          } @{ $plugins };
2959
2960         for my $plugin ( reverse @plugins ) {
2961             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2962             my $meta = find_meta($plugin->[0]);
2963             next if $meta && $meta->isa('Moose::Meta::Role');
2964
2965             $class->_register_plugin($plugin->[0]);
2966         }
2967
2968         my @roles =
2969             map  { $_->[0]->name, $_->[1] }
2970             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2971             map  { [find_meta($_->[0]), $_->[1]] }
2972             @plugins;
2973
2974         Moose::Util::apply_all_roles(
2975             $class => @roles
2976         ) if @roles;
2977     }
2978 }
2979
2980 =head2 $c->stack
2981
2982 Returns an arrayref of the internal execution stack (actions that are
2983 currently executing).
2984
2985 =head2 $c->stats
2986
2987 Returns the current timing statistics object. By default Catalyst uses
2988 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2989 L<< stats_class|/"$c->stats_class" >>.
2990
2991 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2992 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2993 profile explicitly, although MyApp.pm still won't profile nor output anything
2994 by itself.
2995
2996 =head2 $c->stats_class
2997
2998 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2999
3000 =head2 $c->use_stats
3001
3002 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3003
3004 Note that this is a static method, not an accessor and should be overridden
3005 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3006
3007 =cut
3008
3009 sub use_stats { 0 }
3010
3011
3012 =head2 $c->write( $data )
3013
3014 Writes $data to the output stream. When using this method directly, you
3015 will need to manually set the C<Content-Length> header to the length of
3016 your output data, if known.
3017
3018 =cut
3019
3020 sub write {
3021     my $c = shift;
3022
3023     # Finalize headers if someone manually writes output (for compat)
3024     $c->finalize_headers;
3025
3026     return $c->response->write( @_ );
3027 }
3028
3029 =head2 version
3030
3031 Returns the Catalyst version number. Mostly useful for "powered by"
3032 messages in template systems.
3033
3034 =cut
3035
3036 sub version { return $Catalyst::VERSION }
3037
3038 =head1 CONFIGURATION
3039
3040 There are a number of 'base' config variables which can be set:
3041
3042 =over
3043
3044 =item *
3045
3046 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3047
3048 =item *
3049
3050 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3051
3052 =item *
3053
3054 C<disable_component_resolution_regex_fallback> - Turns
3055 off the deprecated component resolution functionality so
3056 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3057 are called then regex search will not be attempted on string values and
3058 instead C<undef> will be returned.
3059
3060 =item *
3061
3062 C<home> - The application home directory. In an uninstalled application,
3063 this is the top level application directory. In an installed application,
3064 this will be the directory containing C<< MyApp.pm >>.
3065
3066 =item *
3067
3068 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3069
3070 =item *
3071
3072 C<name> - The name of the application in debug messages and the debug and
3073 welcome screens
3074
3075 =item *
3076
3077 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3078 until it is accessed. This allows you to (for example) check authentication (and reject
3079 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3080
3081 =item *
3082
3083 C<root> - The root directory for templates. Usually this is just a
3084 subdirectory of the home directory, but you can set it to change the
3085 templates to a different directory.
3086
3087 =item *
3088
3089 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3090 namespaces from which components will be loaded (and constructed and stored in
3091 C<< $c->components >>).
3092
3093 =item *
3094
3095 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3096 to be shown in hit debug tables in the test server.
3097
3098 =item *
3099
3100 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3101 variable should be used for determining the request path.
3102
3103 Most web server environments pass the requested path to the application using environment variables,
3104 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3105 exposed as C<< $c->request->base >>) and the request path below that base.
3106
3107 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3108 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3109
3110 =over
3111
3112 =item use_request_uri_for_path => 0
3113
3114 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3115 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3116 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3117 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3118
3119 However this method has the major disadvantage that it is impossible to correctly decode some elements
3120 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3121 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3122 can't distinguish / vs %2F in paths (in addition to other encoded values).
3123
3124 =item use_request_uri_for_path => 1
3125
3126 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3127 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3128 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3129
3130 Given that this method of path resolution is provably more correct, it is recommended that you use
3131 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3132 aware of the implications of not being able to handle encoded URI paths correctly.
3133
3134 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3135 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3136 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3137 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3138 C<< $c->request->base >> will be incorrect.
3139
3140 =back
3141
3142 =item *
3143
3144 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3145
3146 =back
3147
3148 =head1 INTERNAL ACTIONS
3149
3150 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3151 C<_ACTION>, and C<_END>. These are by default not shown in the private
3152 action table, but you can make them visible with a config parameter.
3153
3154     MyApp->config(show_internal_actions => 1);
3155
3156 =head1 ON-DEMAND PARSER
3157
3158 The request body is usually parsed at the beginning of a request,
3159 but if you want to handle input yourself, you can enable on-demand
3160 parsing with a config parameter.
3161
3162     MyApp->config(parse_on_demand => 1);
3163
3164 =head1 PROXY SUPPORT
3165
3166 Many production servers operate using the common double-server approach,
3167 with a lightweight frontend web server passing requests to a larger
3168 backend server. An application running on the backend server must deal
3169 with two problems: the remote user always appears to be C<127.0.0.1> and
3170 the server's hostname will appear to be C<localhost> regardless of the
3171 virtual host that the user connected through.
3172
3173 Catalyst will automatically detect this situation when you are running
3174 the frontend and backend servers on the same machine. The following
3175 changes are made to the request.
3176
3177     $c->req->address is set to the user's real IP address, as read from
3178     the HTTP X-Forwarded-For header.
3179
3180     The host value for $c->req->base and $c->req->uri is set to the real
3181     host, as read from the HTTP X-Forwarded-Host header.
3182
3183 Additionally, you may be running your backend application on an insecure
3184 connection (port 80) while your frontend proxy is running under SSL.  If there
3185 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3186 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3187 be created properly.
3188
3189 In the case of passing in:
3190
3191     X-Forwarded-Port: 443
3192
3193 All calls to C<uri_for> will result in an https link, as is expected.
3194
3195 Obviously, your web server must support these headers for this to work.
3196
3197 In a more complex server farm environment where you may have your
3198 frontend proxy server(s) on different machines, you will need to set a
3199 configuration option to tell Catalyst to read the proxied data from the
3200 headers.
3201
3202     MyApp->config(using_frontend_proxy => 1);
3203
3204 If you do not wish to use the proxy support at all, you may set:
3205
3206     MyApp->config(ignore_frontend_proxy => 0);
3207
3208 =head2 Note about psgi files
3209
3210 Note that if you supply your own .psgi file, calling
3211 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3212
3213 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3214 in your psgi, for example:
3215
3216     builder {
3217         enable "Plack::Middleware::ReverseProxy";
3218         MyApp->psgi_app
3219     };
3220
3221 This will unconditionally add the ReverseProxy support, or you need to call
3222 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3223 apply the support depending upon your config).
3224
3225 See L<Catalyst::PSGI> for more information.
3226
3227 =head1 THREAD SAFETY
3228
3229 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3230 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3231 believe the Catalyst core to be thread-safe.
3232
3233 If you plan to operate in a threaded environment, remember that all other
3234 modules you are using must also be thread-safe. Some modules, most notably
3235 L<DBD::SQLite>, are not thread-safe.
3236
3237 =head1 SUPPORT
3238
3239 IRC:
3240
3241     Join #catalyst on irc.perl.org.
3242
3243 Mailing Lists:
3244
3245     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3246     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3247
3248 Web:
3249
3250     http://catalyst.perl.org
3251
3252 Wiki:
3253
3254     http://dev.catalyst.perl.org
3255
3256 =head1 SEE ALSO
3257
3258 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3259
3260 =head2 L<Catalyst::Manual> - The Catalyst Manual
3261
3262 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3263
3264 =head2 L<Catalyst::Engine> - Core engine
3265
3266 =head2 L<Catalyst::Log> - Log class.
3267
3268 =head2 L<Catalyst::Request> - Request object
3269
3270 =head2 L<Catalyst::Response> - Response object
3271
3272 =head2 L<Catalyst::Test> - The test suite.
3273
3274 =head1 PROJECT FOUNDER
3275
3276 sri: Sebastian Riedel <sri@cpan.org>
3277
3278 =head1 CONTRIBUTORS
3279
3280 abw: Andy Wardley
3281
3282 acme: Leon Brocard <leon@astray.com>
3283
3284 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3285
3286 Andrew Bramble
3287
3288 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3289
3290 Andrew Ruthven
3291
3292 andyg: Andy Grundman <andy@hybridized.org>
3293
3294 audreyt: Audrey Tang
3295
3296 bricas: Brian Cassidy <bricas@cpan.org>
3297
3298 Caelum: Rafael Kitover <rkitover@io.com>
3299
3300 chansen: Christian Hansen
3301
3302 chicks: Christopher Hicks
3303
3304 Chisel Wright C<pause@herlpacker.co.uk>
3305
3306 Danijel Milicevic C<me@danijel.de>
3307
3308 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3309
3310 David Naughton, C<naughton@umn.edu>
3311
3312 David E. Wheeler
3313
3314 dhoss: Devin Austin <dhoss@cpan.org>
3315
3316 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3317
3318 Drew Taylor
3319
3320 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3321
3322 esskar: Sascha Kiefer
3323
3324 fireartist: Carl Franks <cfranks@cpan.org>
3325
3326 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3327
3328 gabb: Danijel Milicevic
3329
3330 Gary Ashton Jones
3331
3332 Gavin Henry C<ghenry@perl.me.uk>
3333
3334 Geoff Richards
3335
3336 groditi: Guillermo Roditi <groditi@gmail.com>
3337
3338 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3339
3340 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3341
3342 jcamacho: Juan Camacho
3343
3344 jester: Jesse Sheidlower C<jester@panix.com>
3345
3346 jhannah: Jay Hannah <jay@jays.net>
3347
3348 Jody Belka
3349
3350 Johan Lindstrom
3351
3352 jon: Jon Schutz <jjschutz@cpan.org>
3353
3354 Jonathan Rockway C<< <jrockway@cpan.org> >>
3355
3356 Kieren Diment C<kd@totaldatasolution.com>
3357
3358 konobi: Scott McWhirter <konobi@cpan.org>
3359
3360 marcus: Marcus Ramberg <mramberg@cpan.org>
3361
3362 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3363
3364 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3365
3366 mugwump: Sam Vilain
3367
3368 naughton: David Naughton
3369
3370 ningu: David Kamholz <dkamholz@cpan.org>
3371
3372 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3373
3374 numa: Dan Sully <daniel@cpan.org>
3375
3376 obra: Jesse Vincent
3377
3378 Octavian Rasnita
3379
3380 omega: Andreas Marienborg
3381
3382 Oleg Kostyuk <cub.uanic@gmail.com>
3383
3384 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3385
3386 rafl: Florian Ragwitz <rafl@debian.org>
3387
3388 random: Roland Lammel <lammel@cpan.org>
3389
3390 Robert Sedlacek C<< <rs@474.at> >>
3391
3392 SpiceMan: Marcel Montes
3393
3394 sky: Arthur Bergman
3395
3396 szbalint: Balint Szilakszi <szbalint@cpan.org>
3397
3398 t0m: Tomas Doran <bobtfish@bobtfish.net>
3399
3400 Ulf Edvinsson
3401
3402 Viljo Marrandi C<vilts@yahoo.com>
3403
3404 Will Hawes C<info@whawes.co.uk>
3405
3406 willert: Sebastian Willert <willert@cpan.org>
3407
3408 wreis: Wallace Reis <wallace@reis.org.br>
3409
3410 Yuval Kogman, C<nothingmuch@woobling.org>
3411
3412 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3413
3414 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3415
3416 =head1 COPYRIGHT
3417
3418 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3419
3420 =head1 LICENSE
3421
3422 This library is free software. You can redistribute it and/or modify it under
3423 the same terms as Perl itself.
3424
3425 =cut
3426
3427 no Moose;
3428
3429 __PACKAGE__->meta->make_immutable;
3430
3431 1;