lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use Moose::Util qw/find_meta/;
   6 use bytes;
   7 use Scope::Upper ();
   8 use Catalyst::Exception;
   9 use Catalyst::Log;
  10 use Catalyst::Request;
  11 use Catalyst::Request::Upload;
  12 use Catalyst::Response;
  13 use Catalyst::Utils;
  14 use Catalyst::Controller;
  15 use Devel::InnerPackage ();
  16 use File::stat;
  17 use Module::Pluggable::Object ();
  18 use Text::SimpleTable ();
  19 use Path::Class::Dir ();
  20 use Path::Class::File ();
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Tree::Simple qw/use_weak_refs/;
  25 use Tree::Simple::Visitor::FindByUID;
  26 use Class::C3::Adopt::NEXT;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp shortmess/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 has stack => (is => 'ro', default => sub { [] });
  34 has stash => (is => 'rw', default => sub { {} });
  35 has state => (is => 'rw', default => 0);
  36 has stats => (is => 'rw');
  37 has action => (is => 'rw');
  38 has counter => (is => 'rw', default => sub { {} });
  39 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  40 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  41 has namespace => (is => 'rw');
  42
  43 sub depth { scalar @{ shift->stack || [] }; }
  44 sub comp { shift->component(@_) }
  45
  46 sub req {
  47     my $self = shift; return $self->request(@_);
  48 }
  49 sub res {
  50     my $self = shift; return $self->response(@_);
  51 }
  52
  53 # For backwards compatibility
  54 sub finalize_output { shift->finalize_body(@_) };
  55
  56 # For statistics
  57 our $COUNT     = 1;
  58 our $START     = time;
  59 our $RECURSION = 1000;
  60 our $DETACH    = "catalyst_detach\n";
  61 our $GO        = "catalyst_go\n";
  62
  63 #I imagine that very few of these really need to be class variables. if any.
  64 #maybe we should just make them attributes with a default?
  65 __PACKAGE__->mk_classdata($_)
  66   for qw/components arguments dispatcher engine log dispatcher_class
  67   engine_class context_class request_class response_class stats_class
  68   setup_finished/;
  69
  70 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  71 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  72 __PACKAGE__->request_class('Catalyst::Request');
  73 __PACKAGE__->response_class('Catalyst::Response');
  74 __PACKAGE__->stats_class('Catalyst::Stats');
  75
  76 # Remember to update this in Catalyst::Runtime as well!
  77
  78 our $VERSION = '5.80001';
  79
  80 {
  81     my $dev_version = $VERSION =~ /_\d{2}$/;
  82     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  83 }
  84
  85 $VERSION = eval $VERSION;
  86
  87 sub import {
  88     my ( $class, @arguments ) = @_;
  89
  90     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  91     # callers @ISA.
  92     return unless $class eq 'Catalyst';
  93
  94     my $caller = caller();
  95     return if $caller eq 'main';
  96
  97     # Kill Adopt::NEXT warnings if we're a non-RC version
  98     unless (_IS_DEVELOPMENT_VERSION()) {
  99         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 100     }
 101
 102     my $meta = Moose::Meta::Class->initialize($caller);
 103     #Moose->import({ into => $caller }); #do we want to do this?
 104
 105     unless ( $caller->isa('Catalyst') ) {
 106         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 107         $meta->superclasses(@superclasses);
 108     }
 109     unless( $meta->has_method('meta') ){
 110         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 111     }
 112
 113     $caller->arguments( [@arguments] );
 114     $caller->setup_home;
 115 }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 =head2 -Engine
 252
 253 Forces Catalyst to use a specific engine. Omit the
 254 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 255
 256     use Catalyst qw/-Engine=CGI/;
 257
 258 =head2 -Home
 259
 260 Forces Catalyst to use a specific home directory, e.g.:
 261
 262     use Catalyst qw[-Home=/usr/mst];
 263
 264 This can also be done in the shell environment by setting either the
 265 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 266 is replaced with the uppercased name of your application, any "::" in
 267 the name will be replaced with underscores, e.g. MyApp::Web should use
 268 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 269
 270 =head2 -Log
 271
 272     use Catalyst '-Log=warn,fatal,error';
 273
 274 Specifies a comma-delimited list of log levels.
 275
 276 =head2 -Stats
 277
 278 Enables statistics collection and reporting. You can also force this setting
 279 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 280 environment settings override the application, with <MYAPP>_STATS having the
 281 highest priority.
 282
 283 e.g.
 284
 285    use Catalyst qw/-Stats=1/
 286
 287 =head1 METHODS
 288
 289 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 290
 291 =head2 $c->action
 292
 293 Returns a L<Catalyst::Action> object for the current action, which
 294 stringifies to the action name. See L<Catalyst::Action>.
 295
 296 =head2 $c->namespace
 297
 298 Returns the namespace of the current action, i.e., the URI prefix
 299 corresponding to the controller of the current action. For example:
 300
 301     # in Controller::Foo::Bar
 302     $c->namespace; # returns 'foo/bar';
 303
 304 =head2 $c->request
 305
 306 =head2 $c->req
 307
 308 Returns the current L<Catalyst::Request> object, giving access to
 309 information about the current client request (including parameters,
 310 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 311
 312 =head2 REQUEST FLOW HANDLING
 313
 314 =head2 $c->forward( $action [, \@arguments ] )
 315
 316 =head2 $c->forward( $class, $method, [, \@arguments ] )
 317
 318 Forwards processing to another action, by its private name. If you give a
 319 class name but no method, C<process()> is called. You may also optionally
 320 pass arguments in an arrayref. The action will receive the arguments in
 321 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 322 C<< $c->req->args >> will be restored to the previous values.
 323
 324 Any data C<return>ed from the action forwarded to, will be returned by the
 325 call to forward.
 326
 327     my $foodata = $c->forward('/foo');
 328     $c->forward('index');
 329     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 330     $c->forward('MyApp::View::TT');
 331
 332 Note that forward implies an C<<eval { }>> around the call (actually
 333 C<execute> does), thus de-fatalizing all 'dies' within the called
 334 action. If you want C<die> to propagate you need to do something like:
 335
 336     $c->forward('foo');
 337     die $c->error if $c->error;
 338
 339 Or make sure to always return true values from your actions and write
 340 your code like this:
 341
 342     $c->forward('foo') || return;
 343
 344 =cut
 345
 346 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 347
 348 =head2 $c->detach( $action [, \@arguments ] )
 349
 350 =head2 $c->detach( $class, $method, [, \@arguments ] )
 351
 352 =head2 $c->detach()
 353
 354 The same as C<forward>, but doesn't return to the previous action when
 355 processing is finished.
 356
 357 When called with no arguments it escapes the processing chain entirely.
 358
 359 =cut
 360
 361 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 362
 363 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 364
 365 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 366
 367 Almost the same as C<forward>, but does a full dispatch, instead of just
 368 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 369 C<auto> and the method you go to are called, just like a new request.
 370
 371 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 372 This means, for example, that $c->action methods such as C<name>, C<class> and
 373 C<reverse> return information for the visited action when they are invoked
 374 within the visited action.  This is different from the behavior of C<forward>
 375 which continues to use the $c->action object from the caller action even when
 376 invoked from the callee.
 377
 378 C<$c-E<gt>stash> is kept unchanged.
 379
 380 In effect, C<visit> allows you to "wrap" another action, just as it
 381 would have been called by dispatching from a URL, while the analogous
 382 C<go> allows you to transfer control to another action as if it had
 383 been reached directly from a URL.
 384
 385 =cut
 386
 387 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 388
 389 =head2 $c->go( $action [, \@captures, \@arguments ] )
 390
 391 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 392
 393 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 394 instead of just calling the new C<$action> /
 395 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 396 method you visit are called, just like a new request.
 397
 398 C<$c-E<gt>stash> is kept unchanged.
 399
 400 =cut
 401
 402 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 403
 404 =head2 $c->response
 405
 406 =head2 $c->res
 407
 408 Returns the current L<Catalyst::Response> object, see there for details.
 409
 410 =head2 $c->stash
 411
 412 Returns a hashref to the stash, which may be used to store data and pass
 413 it between components during a request. You can also set hash keys by
 414 passing arguments. The stash is automatically sent to the view. The
 415 stash is cleared at the end of a request; it cannot be used for
 416 persistent storage (for this you must use a session; see
 417 L<Catalyst::Plugin::Session> for a complete system integrated with
 418 Catalyst).
 419
 420     $c->stash->{foo} = $bar;
 421     $c->stash( { moose => 'majestic', qux => 0 } );
 422     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 423
 424     # stash is automatically passed to the view for use in a template
 425     $c->forward( 'MyApp::View::TT' );
 426
 427 =cut
 428
 429 around stash => sub {
 430     my $orig = shift;
 431     my $c = shift;
 432     my $stash = $orig->($c);
 433     if (@_) {
 434         my $new_stash = @_ > 1 ? {@_} : $_[0];
 435         croak('stash takes a hash or hashref') unless ref $new_stash;
 436         foreach my $key ( keys %$new_stash ) {
 437           $stash->{$key} = $new_stash->{$key};
 438         }
 439     }
 440
 441     return $stash;
 442 };
 443
 444
 445 =head2 $c->error
 446
 447 =head2 $c->error($error, ...)
 448
 449 =head2 $c->error($arrayref)
 450
 451 Returns an arrayref containing error messages.  If Catalyst encounters an
 452 error while processing a request, it stores the error in $c->error.  This
 453 method should only be used to store fatal error messages.
 454
 455     my @error = @{ $c->error };
 456
 457 Add a new error.
 458
 459     $c->error('Something bad happened');
 460
 461 =cut
 462
 463 sub error {
 464     my $c = shift;
 465     if ( $_[0] ) {
 466         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 467         croak @$error unless ref $c;
 468         push @{ $c->{error} }, @$error;
 469     }
 470     elsif ( defined $_[0] ) { $c->{error} = undef }
 471     return $c->{error} || [];
 472 }
 473
 474
 475 =head2 $c->state
 476
 477 Contains the return value of the last executed action.
 478
 479 =head2 $c->clear_errors
 480
 481 Clear errors.  You probably don't want to clear the errors unless you are
 482 implementing a custom error screen.
 483
 484 This is equivalent to running
 485
 486     $c->error(0);
 487
 488 =cut
 489
 490 sub clear_errors {
 491     my $c = shift;
 492     $c->error(0);
 493 }
 494
 495 # search components given a name and some prefixes
 496 sub _comp_search_prefixes {
 497     my ( $c, $name, @prefixes ) = @_;
 498     my $appclass = ref $c || $c;
 499     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 500     $filter = qr/$filter/; # Compile regex now rather than once per loop
 501
 502     # map the original component name to the sub part that we will search against
 503     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 504         grep { /$filter/ } keys %{ $c->components };
 505
 506     # undef for a name will return all
 507     return keys %eligible if !defined $name;
 508
 509     my $query  = ref $name ? $name : qr/^$name$/i;
 510     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 511
 512     return map { $c->components->{ $_ } } @result if @result;
 513
 514     # if we were given a regexp to search against, we're done.
 515     return if ref $name;
 516
 517     # regexp fallback
 518     $query  = qr/$name/i;
 519     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 520
 521     # no results? try against full names
 522     if( !@result ) {
 523         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 524     }
 525
 526     # don't warn if we didn't find any results, it just might not exist
 527     if( @result ) {
 528         # Disgusting hack to work out correct method name
 529         my $warn_for = lc $prefixes[0];
 530         my $msg = "Used regexp fallback for \$c->{$warn_for}('${name}'), which found '" .
 531            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 532            "component resolution is unreliable and unsafe.";
 533         my $short = $result[0];
 534         $short =~ s/.*?Model:://;
 535         my $shortmess = Carp::shortmess('');
 536         if ($shortmess =~ m#Catalyst/Plugin#) {
 537            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 538               "plugin's config";
 539         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 540            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 541               "component's config";
 542         } else {
 543            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 544               "but if you really wanted to search, pass in a regexp as the argument " .
 545               "like so: \$c->${warn_for}(qr/${name}/)";
 546         }
 547         $c->log->warn( "${msg}$shortmess" );
 548     }
 549
 550     return @result;
 551 }
 552
 553 # Find possible names for a prefix
 554 sub _comp_names {
 555     my ( $c, @prefixes ) = @_;
 556     my $appclass = ref $c || $c;
 557
 558     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 559
 560     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 561     return @names;
 562 }
 563
 564 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 565 sub _filter_component {
 566     my ( $c, $comp, @args ) = @_;
 567
 568     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 569         return $comp->ACCEPT_CONTEXT( $c, @args );
 570     }
 571
 572     return $comp;
 573 }
 574
 575 =head2 COMPONENT ACCESSORS
 576
 577 =head2 $c->controller($name)
 578
 579 Gets a L<Catalyst::Controller> instance by name.
 580
 581     $c->controller('Foo')->do_stuff;
 582
 583 If the name is omitted, will return the controller for the dispatched
 584 action.
 585
 586 If you want to search for controllers, pass in a regexp as the argument.
 587
 588     # find all controllers that start with Foo
 589     my @foo_controllers = $c->controller(qr{^Foo});
 590
 591
 592 =cut
 593
 594 sub controller {
 595     my ( $c, $name, @args ) = @_;
 596
 597     if( $name ) {
 598         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 599         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 600         return $c->_filter_component( $result[ 0 ], @args );
 601     }
 602
 603     return $c->component( $c->action->class );
 604 }
 605
 606 =head2 $c->model($name)
 607
 608 Gets a L<Catalyst::Model> instance by name.
 609
 610     $c->model('Foo')->do_stuff;
 611
 612 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 613
 614 If the name is omitted, it will look for
 615  - a model object in $c->stash->{current_model_instance}, then
 616  - a model name in $c->stash->{current_model}, then
 617  - a config setting 'default_model', or
 618  - check if there is only one model, and return it if that's the case.
 619
 620 If you want to search for models, pass in a regexp as the argument.
 621
 622     # find all models that start with Foo
 623     my @foo_models = $c->model(qr{^Foo});
 624
 625 =cut
 626
 627 sub model {
 628     my ( $c, $name, @args ) = @_;
 629
 630     if( $name ) {
 631         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 632         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 633         return $c->_filter_component( $result[ 0 ], @args );
 634     }
 635
 636     if (ref $c) {
 637         return $c->stash->{current_model_instance}
 638           if $c->stash->{current_model_instance};
 639         return $c->model( $c->stash->{current_model} )
 640           if $c->stash->{current_model};
 641     }
 642     return $c->model( $c->config->{default_model} )
 643       if $c->config->{default_model};
 644
 645     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 646
 647     if( $rest ) {
 648         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 649         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 650         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 651         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 652         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 653     }
 654
 655     return $c->_filter_component( $comp );
 656 }
 657
 658
 659 =head2 $c->view($name)
 660
 661 Gets a L<Catalyst::View> instance by name.
 662
 663     $c->view('Foo')->do_stuff;
 664
 665 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 666
 667 If the name is omitted, it will look for
 668  - a view object in $c->stash->{current_view_instance}, then
 669  - a view name in $c->stash->{current_view}, then
 670  - a config setting 'default_view', or
 671  - check if there is only one view, and return it if that's the case.
 672
 673 If you want to search for views, pass in a regexp as the argument.
 674
 675     # find all views that start with Foo
 676     my @foo_views = $c->view(qr{^Foo});
 677
 678 =cut
 679
 680 sub view {
 681     my ( $c, $name, @args ) = @_;
 682
 683     if( $name ) {
 684         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 685         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 686         return $c->_filter_component( $result[ 0 ], @args );
 687     }
 688
 689     if (ref $c) {
 690         return $c->stash->{current_view_instance}
 691           if $c->stash->{current_view_instance};
 692         return $c->view( $c->stash->{current_view} )
 693           if $c->stash->{current_view};
 694     }
 695     return $c->view( $c->config->{default_view} )
 696       if $c->config->{default_view};
 697
 698     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 699
 700     if( $rest ) {
 701         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 702         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 703         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 704         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 705         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 706     }
 707
 708     return $c->_filter_component( $comp );
 709 }
 710
 711 =head2 $c->controllers
 712
 713 Returns the available names which can be passed to $c->controller
 714
 715 =cut
 716
 717 sub controllers {
 718     my ( $c ) = @_;
 719     return $c->_comp_names(qw/Controller C/);
 720 }
 721
 722 =head2 $c->models
 723
 724 Returns the available names which can be passed to $c->model
 725
 726 =cut
 727
 728 sub models {
 729     my ( $c ) = @_;
 730     return $c->_comp_names(qw/Model M/);
 731 }
 732
 733
 734 =head2 $c->views
 735
 736 Returns the available names which can be passed to $c->view
 737
 738 =cut
 739
 740 sub views {
 741     my ( $c ) = @_;
 742     return $c->_comp_names(qw/View V/);
 743 }
 744
 745 =head2 $c->comp($name)
 746
 747 =head2 $c->component($name)
 748
 749 Gets a component object by name. This method is not recommended,
 750 unless you want to get a specific component by full
 751 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 752 should be used instead.
 753
 754 If C<$name> is a regexp, a list of components matched against the full
 755 component name will be returned.
 756
 757 =cut
 758
 759 sub component {
 760     my ( $c, $name, @args ) = @_;
 761
 762     if( $name ) {
 763         my $comps = $c->components;
 764
 765         if( !ref $name ) {
 766             # is it the exact name?
 767             return $c->_filter_component( $comps->{ $name }, @args )
 768                        if exists $comps->{ $name };
 769
 770             # perhaps we just omitted "MyApp"?
 771             my $composed = ( ref $c || $c ) . "::${name}";
 772             return $c->_filter_component( $comps->{ $composed }, @args )
 773                        if exists $comps->{ $composed };
 774
 775             # search all of the models, views and controllers
 776             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 777             return $c->_filter_component( $comp, @args ) if $comp;
 778         }
 779
 780         # This is here so $c->comp( '::M::' ) works
 781         my $query = ref $name ? $name : qr{$name}i;
 782
 783         my @result = grep { m{$query} } keys %{ $c->components };
 784         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 785
 786         if( $result[ 0 ] ) {
 787             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 788             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 789             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 790             return $c->_filter_component( $result[ 0 ], @args );
 791         }
 792
 793         # I would expect to return an empty list here, but that breaks back-compat
 794     }
 795
 796     # fallback
 797     return sort keys %{ $c->components };
 798 }
 799
 800 =head2 CLASS DATA AND HELPER CLASSES
 801
 802 =head2 $c->config
 803
 804 Returns or takes a hashref containing the application's configuration.
 805
 806     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 807
 808 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 809 like myapp.conf in your applications home directory. See
 810 L<Catalyst::Plugin::ConfigLoader>.
 811
 812 =head3 Cascading configuration.
 813
 814 The config method is present on all Catalyst components, and configuration
 815 will be merged when an application is started. Configuration loaded with
 816 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 817 followed by configuration in your top level C<MyApp> class. These two
 818 configurations are merged, and then configuration data whos hash key matches a
 819 component name is merged with configuration for that component.
 820
 821 The configuration for a component is then passed to the C<new> method when a
 822 component is constructed.
 823
 824 For example:
 825
 826     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 827     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 828
 829 will mean that C<MyApp::Model::Foo> receives the following data when
 830 constructed:
 831
 832     MyApp::Model::Foo->new({
 833         bar => 'baz',
 834         quux => 'frob',
 835         overrides => 'me',
 836     });
 837
 838 =cut
 839
 840 around config => sub {
 841     my $orig = shift;
 842     my $c = shift;
 843
 844     croak('Setting config after setup has been run is not allowed.')
 845         if ( @_ and $c->setup_finished );
 846
 847     $c->$orig(@_);
 848 };
 849
 850 =head2 $c->log
 851
 852 Returns the logging object instance. Unless it is already set, Catalyst
 853 sets this up with a L<Catalyst::Log> object. To use your own log class,
 854 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 855 C<< __PACKAGE__->setup >>.
 856
 857  __PACKAGE__->log( MyLogger->new );
 858  __PACKAGE__->setup;
 859
 860 And later:
 861
 862     $c->log->info( 'Now logging with my own logger!' );
 863
 864 Your log class should implement the methods described in
 865 L<Catalyst::Log>.
 866
 867
 868 =head2 $c->debug
 869
 870 Returns 1 if debug mode is enabled, 0 otherwise.
 871
 872 You can enable debug mode in several ways:
 873
 874 =over
 875
 876 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 877
 878 =item The -Debug option in your MyApp.pm
 879
 880 =item By declaring "sub debug { 1 }" in your MyApp.pm.
 881
 882 =back
 883
 884 Calling $c->debug(1) has no effect.
 885
 886 =cut
 887
 888 sub debug { 0 }
 889
 890 =head2 $c->dispatcher
 891
 892 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 893
 894 =head2 $c->engine
 895
 896 Returns the engine instance. See L<Catalyst::Engine>.
 897
 898
 899 =head2 UTILITY METHODS
 900
 901 =head2 $c->path_to(@path)
 902
 903 Merges C<@path> with C<< $c->config->{home} >> and returns a
 904 L<Path::Class::Dir> object.
 905
 906 For example:
 907
 908     $c->path_to( 'db', 'sqlite.db' );
 909
 910 =cut
 911
 912 sub path_to {
 913     my ( $c, @path ) = @_;
 914     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 915     if ( -d $path ) { return $path }
 916     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 917 }
 918
 919 =head2 $c->plugin( $name, $class, @args )
 920
 921 Helper method for plugins. It creates a class data accessor/mutator and
 922 loads and instantiates the given class.
 923
 924     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 925
 926     $c->prototype->define_javascript_functions;
 927
 928 B<Note:> This method of adding plugins is deprecated. The ability
 929 to add plugins like this B<will be removed> in a Catalyst 5.81.
 930 Please do not use this functionality in new code.
 931
 932 =cut
 933
 934 sub plugin {
 935     my ( $class, $name, $plugin, @args ) = @_;
 936
 937     # See block comment in t/unit_core_plugin.t
 938     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 939
 940     $class->_register_plugin( $plugin, 1 );
 941
 942     eval { $plugin->import };
 943     $class->mk_classdata($name);
 944     my $obj;
 945     eval { $obj = $plugin->new(@args) };
 946
 947     if ($@) {
 948         Catalyst::Exception->throw( message =>
 949               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 950     }
 951
 952     $class->$name($obj);
 953     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 954       if $class->debug;
 955 }
 956
 957 =head2 MyApp->setup
 958
 959 Initializes the dispatcher and engine, loads any plugins, and loads the
 960 model, view, and controller components. You may also specify an array
 961 of plugins to load here, if you choose to not load them in the C<use
 962 Catalyst> line.
 963
 964     MyApp->setup;
 965     MyApp->setup( qw/-Debug/ );
 966
 967 =cut
 968
 969 sub setup {
 970     my ( $class, @arguments ) = @_;
 971     croak('Running setup more than once')
 972         if ( $class->setup_finished );
 973
 974     unless ( $class->isa('Catalyst') ) {
 975
 976         Catalyst::Exception->throw(
 977             message => qq/'$class' does not inherit from Catalyst/ );
 978     }
 979
 980     if ( $class->arguments ) {
 981         @arguments = ( @arguments, @{ $class->arguments } );
 982     }
 983
 984     # Process options
 985     my $flags = {};
 986
 987     foreach (@arguments) {
 988
 989         if (/^-Debug$/) {
 990             $flags->{log} =
 991               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 992         }
 993         elsif (/^-(\w+)=?(.*)$/) {
 994             $flags->{ lc $1 } = $2;
 995         }
 996         else {
 997             push @{ $flags->{plugins} }, $_;
 998         }
 999     }
1000
1001     $class->setup_home( delete $flags->{home} );
1002
1003     $class->setup_log( delete $flags->{log} );
1004     $class->setup_plugins( delete $flags->{plugins} );
1005     $class->setup_dispatcher( delete $flags->{dispatcher} );
1006     $class->setup_engine( delete $flags->{engine} );
1007     $class->setup_stats( delete $flags->{stats} );
1008
1009     for my $flag ( sort keys %{$flags} ) {
1010
1011         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1012             &$code( $class, delete $flags->{$flag} );
1013         }
1014         else {
1015             $class->log->warn(qq/Unknown flag "$flag"/);
1016         }
1017     }
1018
1019     eval { require Catalyst::Devel; };
1020     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1021         $class->log->warn(<<"EOF");
1022 You are running an old script!
1023
1024   Please update by running (this will overwrite existing files):
1025     catalyst.pl -force -scripts $class
1026
1027   or (this will not overwrite existing files):
1028     catalyst.pl -scripts $class
1029
1030 EOF
1031     }
1032
1033     if ( $class->debug ) {
1034         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1035
1036         if (@plugins) {
1037             my $column_width = Catalyst::Utils::term_width() - 6;
1038             my $t = Text::SimpleTable->new($column_width);
1039             $t->row($_) for @plugins;
1040             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1041         }
1042
1043         my $dispatcher = $class->dispatcher;
1044         my $engine     = $class->engine;
1045         my $home       = $class->config->{home};
1046
1047         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1048         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1049
1050         $home
1051           ? ( -d $home )
1052           ? $class->log->debug(qq/Found home "$home"/)
1053           : $class->log->debug(qq/Home "$home" doesn't exist/)
1054           : $class->log->debug(q/Couldn't find home/);
1055     }
1056
1057     # Call plugins setup, this is stupid and evil.
1058     {
1059         no warnings qw/redefine/;
1060         local *setup = sub { };
1061         $class->setup;
1062     }
1063
1064     # Initialize our data structure
1065     $class->components( {} );
1066
1067     $class->setup_components;
1068
1069     if ( $class->debug ) {
1070         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1071         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1072         for my $comp ( sort keys %{ $class->components } ) {
1073             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1074             $t->row( $comp, $type );
1075         }
1076         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1077           if ( keys %{ $class->components } );
1078     }
1079
1080     # Add our self to components, since we are also a component
1081     if( $class->isa('Catalyst::Controller') ){
1082       $class->components->{$class} = $class;
1083     }
1084
1085     $class->setup_actions;
1086
1087     if ( $class->debug ) {
1088         my $name = $class->config->{name} || 'Application';
1089         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1090     }
1091     $class->log->_flush() if $class->log->can('_flush');
1092
1093     # Make sure that the application class becomes immutable at this point,
1094     # which ensures that it gets an inlined constructor. This means that it
1095     # works even if the user has added a plugin which contains a new method.
1096     # Note however that we have to do the work on scope end, so that method
1097     # modifiers work correctly in MyApp (as you have to call setup _before_
1098     # applying modifiers).
1099     Scope::Upper::reap(sub {
1100         my $meta = Class::MOP::get_metaclass_by_name($class);
1101         $meta->make_immutable unless $meta->is_immutable;
1102     }, Scope::Upper::SCOPE(1));
1103
1104     $class->setup_finalize;
1105 }
1106
1107
1108 =head2 $app->setup_finalize
1109
1110 A hook to attach modifiers to.
1111 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1112 Also better than C< setup_finished(); >, as that is a getter method.
1113
1114     sub setup_finalize {
1115
1116         my $app = shift;
1117
1118         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1119
1120         $app->next::method(@_);
1121
1122
1123     }
1124
1125 =cut
1126
1127 sub setup_finalize {
1128     my ($class) = @_;
1129     $class->setup_finished(1);
1130 }
1131
1132 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1133
1134 =head2 $c->uri_for( $path, @args?, \%query_values? )
1135
1136 =over
1137
1138 =item $action
1139
1140 A Catalyst::Action object representing the Catalyst action you want to
1141 create a URI for. To get one for an action in the current controller,
1142 use C<< $c->action('someactionname') >>. To get one from different
1143 controller, fetch the controller using C<< $c->controller() >>, then
1144 call C<action_for> on it.
1145
1146 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1147 using C<< $c->req->captures >>.
1148
1149   # For the current action
1150   $c->uri_for($c->action, $c->req->captures);
1151
1152   # For the Foo action in the Bar controller
1153   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1154
1155 =back
1156
1157 =cut
1158
1159 sub uri_for {
1160     my ( $c, $path, @args ) = @_;
1161
1162     if ( blessed($path) ) { # action object
1163         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1164                          ? shift(@args)
1165                          : [] );
1166         my $action = $path;
1167         $path = $c->dispatcher->uri_for_action($action, $captures);
1168         if (not defined $path) {
1169             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1170                 if $c->debug;
1171             return undef;
1172         }
1173         $path = '/' if $path eq '';
1174     }
1175
1176     undef($path) if (defined $path && $path eq '');
1177
1178     my $params =
1179       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1180
1181     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1182     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1183
1184     unshift(@args, $path);
1185
1186     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1187         my $namespace = $c->namespace;
1188         if (defined $path) { # cheesy hack to handle path '../foo'
1189            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1190         }
1191         unshift(@args, $namespace || '');
1192     }
1193
1194     # join args with '/', or a blank string
1195     my $args = join('/', grep { defined($_) } @args);
1196     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1197     $args =~ s!^/+!!;
1198     my $base = $c->req->base;
1199     my $class = ref($base);
1200     $base =~ s{(?<!/)$}{/};
1201
1202     my $query = '';
1203
1204     if (my @keys = keys %$params) {
1205       # somewhat lifted from URI::_query's query_form
1206       $query = '?'.join('&', map {
1207           my $val = $params->{$_};
1208           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1209           s/ /+/g;
1210           my $key = $_;
1211           $val = '' unless defined $val;
1212           (map {
1213               $_ = "$_";
1214               utf8::encode( $_ ) if utf8::is_utf8($_);
1215               # using the URI::Escape pattern here so utf8 chars survive
1216               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1217               s/ /+/g;
1218               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1219       } @keys);
1220     }
1221
1222     my $res = bless(\"${base}${args}${query}", $class);
1223     $res;
1224 }
1225
1226 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1227
1228 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1229
1230 =over
1231
1232 =item $path
1233
1234 A private path to the Catalyst action you want to create a URI for.
1235
1236 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1237 >> and passing the resulting C<$action> and the remaining arguments to C<<
1238 $c->uri_for >>.
1239
1240 You can also pass in a Catalyst::Action object, in which case it is passed to
1241 C<< $c->uri_for >>.
1242
1243 =back
1244
1245 =cut
1246
1247 sub uri_for_action {
1248     my ( $c, $path, @args ) = @_;
1249     my $action = blessed($path)
1250       ? $path
1251       : $c->dispatcher->get_action_by_path($path);
1252     unless (defined $action) {
1253       croak "Can't find action for path '$path'";
1254     }
1255     return $c->uri_for( $action, @args );
1256 }
1257
1258 =head2 $c->welcome_message
1259
1260 Returns the Catalyst welcome HTML page.
1261
1262 =cut
1263
1264 sub welcome_message {
1265     my $c      = shift;
1266     my $name   = $c->config->{name};
1267     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1268     my $prefix = Catalyst::Utils::appprefix( ref $c );
1269     $c->response->content_type('text/html; charset=utf-8');
1270     return <<"EOF";
1271 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1272     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1273 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1274     <head>
1275     <meta http-equiv="Content-Language" content="en" />
1276     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1277         <title>$name on Catalyst $VERSION</title>
1278         <style type="text/css">
1279             body {
1280                 color: #000;
1281                 background-color: #eee;
1282             }
1283             div#content {
1284                 width: 640px;
1285                 margin-left: auto;
1286                 margin-right: auto;
1287                 margin-top: 10px;
1288                 margin-bottom: 10px;
1289                 text-align: left;
1290                 background-color: #ccc;
1291                 border: 1px solid #aaa;
1292             }
1293             p, h1, h2 {
1294                 margin-left: 20px;
1295                 margin-right: 20px;
1296                 font-family: verdana, tahoma, sans-serif;
1297             }
1298             a {
1299                 font-family: verdana, tahoma, sans-serif;
1300             }
1301             :link, :visited {
1302                     text-decoration: none;
1303                     color: #b00;
1304                     border-bottom: 1px dotted #bbb;
1305             }
1306             :link:hover, :visited:hover {
1307                     color: #555;
1308             }
1309             div#topbar {
1310                 margin: 0px;
1311             }
1312             pre {
1313                 margin: 10px;
1314                 padding: 8px;
1315             }
1316             div#answers {
1317                 padding: 8px;
1318                 margin: 10px;
1319                 background-color: #fff;
1320                 border: 1px solid #aaa;
1321             }
1322             h1 {
1323                 font-size: 0.9em;
1324                 font-weight: normal;
1325                 text-align: center;
1326             }
1327             h2 {
1328                 font-size: 1.0em;
1329             }
1330             p {
1331                 font-size: 0.9em;
1332             }
1333             p img {
1334                 float: right;
1335                 margin-left: 10px;
1336             }
1337             span#appname {
1338                 font-weight: bold;
1339                 font-size: 1.6em;
1340             }
1341         </style>
1342     </head>
1343     <body>
1344         <div id="content">
1345             <div id="topbar">
1346                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1347                     $VERSION</h1>
1348              </div>
1349              <div id="answers">
1350                  <p>
1351                  <img src="$logo" alt="Catalyst Logo" />
1352                  </p>
1353                  <p>Welcome to the  world of Catalyst.
1354                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1355                     framework will make web development something you had
1356                     never expected it to be: Fun, rewarding, and quick.</p>
1357                  <h2>What to do now?</h2>
1358                  <p>That really depends  on what <b>you</b> want to do.
1359                     We do, however, provide you with a few starting points.</p>
1360                  <p>If you want to jump right into web development with Catalyst
1361                     you might want to start with a tutorial.</p>
1362 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1363 </pre>
1364 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1365 <pre>
1366 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1367 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1368 </code></pre>
1369                  <h2>What to do next?</h2>
1370                  <p>Next it's time to write an actual application. Use the
1371                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1372                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1373                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1374                     they can save you a lot of work.</p>
1375                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1376                     <p>Also, be sure to check out the vast and growing
1377                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1378                     you are likely to find what you need there.
1379                     </p>
1380
1381                  <h2>Need help?</h2>
1382                  <p>Catalyst has a very active community. Here are the main places to
1383                     get in touch with us.</p>
1384                  <ul>
1385                      <li>
1386                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1387                      </li>
1388                      <li>
1389                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1390                      </li>
1391                      <li>
1392                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1393                      </li>
1394                  </ul>
1395                  <h2>In conclusion</h2>
1396                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1397                     as we enjoyed making it. Please contact us if you have ideas
1398                     for improvement or other feedback.</p>
1399              </div>
1400          </div>
1401     </body>
1402 </html>
1403 EOF
1404 }
1405
1406 =head1 INTERNAL METHODS
1407
1408 These methods are not meant to be used by end users.
1409
1410 =head2 $c->components
1411
1412 Returns a hash of components.
1413
1414 =head2 $c->context_class
1415
1416 Returns or sets the context class.
1417
1418 =head2 $c->counter
1419
1420 Returns a hashref containing coderefs and execution counts (needed for
1421 deep recursion detection).
1422
1423 =head2 $c->depth
1424
1425 Returns the number of actions on the current internal execution stack.
1426
1427 =head2 $c->dispatch
1428
1429 Dispatches a request to actions.
1430
1431 =cut
1432
1433 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1434
1435 =head2 $c->dispatcher_class
1436
1437 Returns or sets the dispatcher class.
1438
1439 =head2 $c->dump_these
1440
1441 Returns a list of 2-element array references (name, structure) pairs
1442 that will be dumped on the error page in debug mode.
1443
1444 =cut
1445
1446 sub dump_these {
1447     my $c = shift;
1448     [ Request => $c->req ],
1449     [ Response => $c->res ],
1450     [ Stash => $c->stash ],
1451     [ Config => $c->config ];
1452 }
1453
1454 =head2 $c->engine_class
1455
1456 Returns or sets the engine class.
1457
1458 =head2 $c->execute( $class, $coderef )
1459
1460 Execute a coderef in given class and catch exceptions. Errors are available
1461 via $c->error.
1462
1463 =cut
1464
1465 sub execute {
1466     my ( $c, $class, $code ) = @_;
1467     $class = $c->component($class) || $class;
1468     $c->state(0);
1469
1470     if ( $c->depth >= $RECURSION ) {
1471         my $action = $code->reverse();
1472         $action = "/$action" unless $action =~ /->/;
1473         my $error = qq/Deep recursion detected calling "${action}"/;
1474         $c->log->error($error);
1475         $c->error($error);
1476         $c->state(0);
1477         return $c->state;
1478     }
1479
1480     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1481
1482     push( @{ $c->stack }, $code );
1483
1484     no warnings 'recursion';
1485     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1486
1487     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1488
1489     my $last = pop( @{ $c->stack } );
1490
1491     if ( my $error = $@ ) {
1492         if ( !ref($error) and $error eq $DETACH ) {
1493             die $DETACH if($c->depth > 1);
1494         }
1495         elsif ( !ref($error) and $error eq $GO ) {
1496             die $GO if($c->depth > 0);
1497         }
1498         else {
1499             unless ( ref $error ) {
1500                 no warnings 'uninitialized';
1501                 chomp $error;
1502                 my $class = $last->class;
1503                 my $name  = $last->name;
1504                 $error = qq/Caught exception in $class->$name "$error"/;
1505             }
1506             $c->error($error);
1507             $c->state(0);
1508         }
1509     }
1510     return $c->state;
1511 }
1512
1513 sub _stats_start_execute {
1514     my ( $c, $code ) = @_;
1515
1516     return if ( ( $code->name =~ /^_.*/ )
1517         && ( !$c->config->{show_internal_actions} ) );
1518
1519     my $action_name = $code->reverse();
1520     $c->counter->{$action_name}++;
1521
1522     my $action = $action_name;
1523     $action = "/$action" unless $action =~ /->/;
1524
1525     # determine if the call was the result of a forward
1526     # this is done by walking up the call stack and looking for a calling
1527     # sub of Catalyst::forward before the eval
1528     my $callsub = q{};
1529     for my $index ( 2 .. 11 ) {
1530         last
1531         if ( ( caller($index) )[0] eq 'Catalyst'
1532             && ( caller($index) )[3] eq '(eval)' );
1533
1534         if ( ( caller($index) )[3] =~ /forward$/ ) {
1535             $callsub = ( caller($index) )[3];
1536             $action  = "-> $action";
1537             last;
1538         }
1539     }
1540
1541     my $uid = $action_name . $c->counter->{$action_name};
1542
1543     # is this a root-level call or a forwarded call?
1544     if ( $callsub =~ /forward$/ ) {
1545
1546         # forward, locate the caller
1547         if ( my $parent = $c->stack->[-1] ) {
1548             $c->stats->profile(
1549                 begin  => $action,
1550                 parent => "$parent" . $c->counter->{"$parent"},
1551                 uid    => $uid,
1552             );
1553         }
1554         else {
1555
1556             # forward with no caller may come from a plugin
1557             $c->stats->profile(
1558                 begin => $action,
1559                 uid   => $uid,
1560             );
1561         }
1562     }
1563     else {
1564
1565         # root-level call
1566         $c->stats->profile(
1567             begin => $action,
1568             uid   => $uid,
1569         );
1570     }
1571     return $action;
1572
1573 }
1574
1575 sub _stats_finish_execute {
1576     my ( $c, $info ) = @_;
1577     $c->stats->profile( end => $info );
1578 }
1579
1580 =head2 $c->_localize_fields( sub { }, \%keys );
1581
1582 =cut
1583
1584 #Why does this exist? This is no longer safe and WILL NOT WORK.
1585 # it doesnt seem to be used anywhere. can we remove it?
1586 sub _localize_fields {
1587     my ( $c, $localized, $code ) = ( @_ );
1588
1589     my $request = delete $localized->{request} || {};
1590     my $response = delete $localized->{response} || {};
1591
1592     local @{ $c }{ keys %$localized } = values %$localized;
1593     local @{ $c->request }{ keys %$request } = values %$request;
1594     local @{ $c->response }{ keys %$response } = values %$response;
1595
1596     $code->();
1597 }
1598
1599 =head2 $c->finalize
1600
1601 Finalizes the request.
1602
1603 =cut
1604
1605 sub finalize {
1606     my $c = shift;
1607
1608     for my $error ( @{ $c->error } ) {
1609         $c->log->error($error);
1610     }
1611
1612     # Allow engine to handle finalize flow (for POE)
1613     my $engine = $c->engine;
1614     if ( my $code = $engine->can('finalize') ) {
1615         $engine->$code($c);
1616     }
1617     else {
1618
1619         $c->finalize_uploads;
1620
1621         # Error
1622         if ( $#{ $c->error } >= 0 ) {
1623             $c->finalize_error;
1624         }
1625
1626         $c->finalize_headers;
1627
1628         # HEAD request
1629         if ( $c->request->method eq 'HEAD' ) {
1630             $c->response->body('');
1631         }
1632
1633         $c->finalize_body;
1634     }
1635
1636     if ($c->use_stats) {
1637         my $elapsed = sprintf '%f', $c->stats->elapsed;
1638         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1639         $c->log->info(
1640             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1641     }
1642
1643     return $c->response->status;
1644 }
1645
1646 =head2 $c->finalize_body
1647
1648 Finalizes body.
1649
1650 =cut
1651
1652 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1653
1654 =head2 $c->finalize_cookies
1655
1656 Finalizes cookies.
1657
1658 =cut
1659
1660 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1661
1662 =head2 $c->finalize_error
1663
1664 Finalizes error.
1665
1666 =cut
1667
1668 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1669
1670 =head2 $c->finalize_headers
1671
1672 Finalizes headers.
1673
1674 =cut
1675
1676 sub finalize_headers {
1677     my $c = shift;
1678
1679     my $response = $c->response; #accessor calls can add up?
1680
1681     # Check if we already finalized headers
1682     return if $response->finalized_headers;
1683
1684     # Handle redirects
1685     if ( my $location = $response->redirect ) {
1686         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1687         $response->header( Location => $location );
1688
1689         if ( !$response->has_body ) {
1690             # Add a default body if none is already present
1691             $response->body(
1692                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1693             );
1694         }
1695     }
1696
1697     # Content-Length
1698     if ( $response->body && !$response->content_length ) {
1699
1700         # get the length from a filehandle
1701         if ( blessed( $response->body ) && $response->body->can('read') )
1702         {
1703             my $stat = stat $response->body;
1704             if ( $stat && $stat->size > 0 ) {
1705                 $response->content_length( $stat->size );
1706             }
1707             else {
1708                 $c->log->warn('Serving filehandle without a content-length');
1709             }
1710         }
1711         else {
1712             # everything should be bytes at this point, but just in case
1713             $response->content_length( bytes::length( $response->body ) );
1714         }
1715     }
1716
1717     # Errors
1718     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1719         $response->headers->remove_header("Content-Length");
1720         $response->body('');
1721     }
1722
1723     $c->finalize_cookies;
1724
1725     $c->engine->finalize_headers( $c, @_ );
1726
1727     # Done
1728     $response->finalized_headers(1);
1729 }
1730
1731 =head2 $c->finalize_output
1732
1733 An alias for finalize_body.
1734
1735 =head2 $c->finalize_read
1736
1737 Finalizes the input after reading is complete.
1738
1739 =cut
1740
1741 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1742
1743 =head2 $c->finalize_uploads
1744
1745 Finalizes uploads. Cleans up any temporary files.
1746
1747 =cut
1748
1749 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1750
1751 =head2 $c->get_action( $action, $namespace )
1752
1753 Gets an action in a given namespace.
1754
1755 =cut
1756
1757 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1758
1759 =head2 $c->get_actions( $action, $namespace )
1760
1761 Gets all actions of a given name in a namespace and all parent
1762 namespaces.
1763
1764 =cut
1765
1766 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1767
1768 =head2 $c->handle_request( $class, @arguments )
1769
1770 Called to handle each HTTP request.
1771
1772 =cut
1773
1774 sub handle_request {
1775     my ( $class, @arguments ) = @_;
1776
1777     # Always expect worst case!
1778     my $status = -1;
1779     eval {
1780         if ($class->debug) {
1781             my $secs = time - $START || 1;
1782             my $av = sprintf '%.3f', $COUNT / $secs;
1783             my $time = localtime time;
1784             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1785         }
1786
1787         my $c = $class->prepare(@arguments);
1788         $c->dispatch;
1789         $status = $c->finalize;
1790     };
1791
1792     if ( my $error = $@ ) {
1793         chomp $error;
1794         $class->log->error(qq/Caught exception in engine "$error"/);
1795     }
1796
1797     $COUNT++;
1798
1799     if(my $coderef = $class->log->can('_flush')){
1800         $class->log->$coderef();
1801     }
1802     return $status;
1803 }
1804
1805 =head2 $c->prepare( @arguments )
1806
1807 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1808 etc.).
1809
1810 =cut
1811
1812 sub prepare {
1813     my ( $class, @arguments ) = @_;
1814
1815     # XXX
1816     # After the app/ctxt split, this should become an attribute based on something passed
1817     # into the application.
1818     $class->context_class( ref $class || $class ) unless $class->context_class;
1819
1820     my $c = $class->context_class->new({});
1821
1822     # For on-demand data
1823     $c->request->_context($c);
1824     $c->response->_context($c);
1825
1826     #surely this is not the most efficient way to do things...
1827     $c->stats($class->stats_class->new)->enable($c->use_stats);
1828     if ( $c->debug ) {
1829         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1830     }
1831
1832     #XXX reuse coderef from can
1833     # Allow engine to direct the prepare flow (for POE)
1834     if ( $c->engine->can('prepare') ) {
1835         $c->engine->prepare( $c, @arguments );
1836     }
1837     else {
1838         $c->prepare_request(@arguments);
1839         $c->prepare_connection;
1840         $c->prepare_query_parameters;
1841         $c->prepare_headers;
1842         $c->prepare_cookies;
1843         $c->prepare_path;
1844
1845         # Prepare the body for reading, either by prepare_body
1846         # or the user, if they are using $c->read
1847         $c->prepare_read;
1848
1849         # Parse the body unless the user wants it on-demand
1850         unless ( $c->config->{parse_on_demand} ) {
1851             $c->prepare_body;
1852         }
1853     }
1854
1855     my $method  = $c->req->method  || '';
1856     my $path    = $c->req->path;
1857     $path       = '/' unless length $path;
1858     my $address = $c->req->address || '';
1859
1860     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1861       if $c->debug;
1862
1863     $c->prepare_action;
1864
1865     return $c;
1866 }
1867
1868 =head2 $c->prepare_action
1869
1870 Prepares action. See L<Catalyst::Dispatcher>.
1871
1872 =cut
1873
1874 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1875
1876 =head2 $c->prepare_body
1877
1878 Prepares message body.
1879
1880 =cut
1881
1882 sub prepare_body {
1883     my $c = shift;
1884
1885     return if $c->request->_has_body;
1886
1887     # Initialize on-demand data
1888     $c->engine->prepare_body( $c, @_ );
1889     $c->prepare_parameters;
1890     $c->prepare_uploads;
1891
1892     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1893         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1894         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1895             my $param = $c->req->body_parameters->{$key};
1896             my $value = defined($param) ? $param : '';
1897             $t->row( $key,
1898                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1899         }
1900         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1901     }
1902 }
1903
1904 =head2 $c->prepare_body_chunk( $chunk )
1905
1906 Prepares a chunk of data before sending it to L<HTTP::Body>.
1907
1908 See L<Catalyst::Engine>.
1909
1910 =cut
1911
1912 sub prepare_body_chunk {
1913     my $c = shift;
1914     $c->engine->prepare_body_chunk( $c, @_ );
1915 }
1916
1917 =head2 $c->prepare_body_parameters
1918
1919 Prepares body parameters.
1920
1921 =cut
1922
1923 sub prepare_body_parameters {
1924     my $c = shift;
1925     $c->engine->prepare_body_parameters( $c, @_ );
1926 }
1927
1928 =head2 $c->prepare_connection
1929
1930 Prepares connection.
1931
1932 =cut
1933
1934 sub prepare_connection {
1935     my $c = shift;
1936     $c->engine->prepare_connection( $c, @_ );
1937 }
1938
1939 =head2 $c->prepare_cookies
1940
1941 Prepares cookies.
1942
1943 =cut
1944
1945 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1946
1947 =head2 $c->prepare_headers
1948
1949 Prepares headers.
1950
1951 =cut
1952
1953 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1954
1955 =head2 $c->prepare_parameters
1956
1957 Prepares parameters.
1958
1959 =cut
1960
1961 sub prepare_parameters {
1962     my $c = shift;
1963     $c->prepare_body_parameters;
1964     $c->engine->prepare_parameters( $c, @_ );
1965 }
1966
1967 =head2 $c->prepare_path
1968
1969 Prepares path and base.
1970
1971 =cut
1972
1973 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1974
1975 =head2 $c->prepare_query_parameters
1976
1977 Prepares query parameters.
1978
1979 =cut
1980
1981 sub prepare_query_parameters {
1982     my $c = shift;
1983
1984     $c->engine->prepare_query_parameters( $c, @_ );
1985
1986     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1987         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1988         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1989             my $param = $c->req->query_parameters->{$key};
1990             my $value = defined($param) ? $param : '';
1991             $t->row( $key,
1992                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1993         }
1994         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1995     }
1996 }
1997
1998 =head2 $c->prepare_read
1999
2000 Prepares the input for reading.
2001
2002 =cut
2003
2004 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2005
2006 =head2 $c->prepare_request
2007
2008 Prepares the engine request.
2009
2010 =cut
2011
2012 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2013
2014 =head2 $c->prepare_uploads
2015
2016 Prepares uploads.
2017
2018 =cut
2019
2020 sub prepare_uploads {
2021     my $c = shift;
2022
2023     $c->engine->prepare_uploads( $c, @_ );
2024
2025     if ( $c->debug && keys %{ $c->request->uploads } ) {
2026         my $t = Text::SimpleTable->new(
2027             [ 12, 'Parameter' ],
2028             [ 26, 'Filename' ],
2029             [ 18, 'Type' ],
2030             [ 9,  'Size' ]
2031         );
2032         for my $key ( sort keys %{ $c->request->uploads } ) {
2033             my $upload = $c->request->uploads->{$key};
2034             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2035                 $t->row( $key, $u->filename, $u->type, $u->size );
2036             }
2037         }
2038         $c->log->debug( "File Uploads are:\n" . $t->draw );
2039     }
2040 }
2041
2042 =head2 $c->prepare_write
2043
2044 Prepares the output for writing.
2045
2046 =cut
2047
2048 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2049
2050 =head2 $c->request_class
2051
2052 Returns or sets the request class.
2053
2054 =head2 $c->response_class
2055
2056 Returns or sets the response class.
2057
2058 =head2 $c->read( [$maxlength] )
2059
2060 Reads a chunk of data from the request body. This method is designed to
2061 be used in a while loop, reading C<$maxlength> bytes on every call.
2062 C<$maxlength> defaults to the size of the request if not specified.
2063
2064 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
2065 directly.
2066
2067 Warning: If you use read(), Catalyst will not process the body,
2068 so you will not be able to access POST parameters or file uploads via
2069 $c->request.  You must handle all body parsing yourself.
2070
2071 =cut
2072
2073 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2074
2075 =head2 $c->run
2076
2077 Starts the engine.
2078
2079 =cut
2080
2081 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2082
2083 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2084
2085 Sets an action in a given namespace.
2086
2087 =cut
2088
2089 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2090
2091 =head2 $c->setup_actions($component)
2092
2093 Sets up actions for a component.
2094
2095 =cut
2096
2097 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2098
2099 =head2 $c->setup_components
2100
2101 Sets up components. Specify a C<setup_components> config option to pass
2102 additional options directly to L<Module::Pluggable>. To add additional
2103 search paths, specify a key named C<search_extra> as an array
2104 reference. Items in the array beginning with C<::> will have the
2105 application class name prepended to them.
2106
2107 All components found will also have any
2108 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2109 Note, that modules which are B<not> an I<inner package> of the main
2110 file namespace loaded will not be instantiated as components.
2111
2112 =cut
2113
2114 sub setup_components {
2115     my $class = shift;
2116
2117     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2118     my $config  = $class->config->{ setup_components };
2119     my $extra   = delete $config->{ search_extra } || [];
2120
2121     push @paths, @$extra;
2122
2123     my $locator = Module::Pluggable::Object->new(
2124         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2125         %$config
2126     );
2127
2128     my @comps = sort { length $a <=> length $b } $locator->plugins;
2129     my %comps = map { $_ => 1 } @comps;
2130
2131     my $deprecated_component_names = grep { /::[CMV]::/ } @comps;
2132     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2133         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2134     ) if $deprecated_component_names;
2135
2136     for my $component ( @comps ) {
2137
2138         # We pass ignore_loaded here so that overlay files for (e.g.)
2139         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2140         # we know M::P::O found a file on disk so this is safe
2141
2142         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2143         #Class::MOP::load_class($component);
2144
2145         my $module  = $class->setup_component( $component );
2146         my %modules = (
2147             $component => $module,
2148             map {
2149                 $_ => $class->setup_component( $_ )
2150             } grep {
2151               not exists $comps{$_}
2152             } Devel::InnerPackage::list_packages( $component )
2153         );
2154
2155         for my $key ( keys %modules ) {
2156             $class->components->{ $key } = $modules{ $key };
2157         }
2158     }
2159 }
2160
2161 =head2 $c->setup_component
2162
2163 =cut
2164
2165 sub _controller_init_base_classes {
2166     my ($class, $component) = @_;
2167     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2168         Moose->init_meta( for_class => $class )
2169             unless find_meta($class);
2170     }
2171 }
2172
2173 sub setup_component {
2174     my( $class, $component ) = @_;
2175
2176     unless ( $component->can( 'COMPONENT' ) ) {
2177         return $component;
2178     }
2179
2180     # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2181     #         nearest to Catalyst::Controller first, no matter what order stuff happens
2182     #         to be loaded. There are TODO tests in Moose for this, see
2183     #         f2391d17574eff81d911b97be15ea51080500003
2184     if ($component->isa('Catalyst::Controller')) {
2185         $class->_controller_init_base_classes($component);
2186     }
2187
2188     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2189     my $config = $class->config->{ $suffix } || {};
2190
2191     my $instance = eval { $component->COMPONENT( $class, $config ); };
2192
2193     if ( my $error = $@ ) {
2194         chomp $error;
2195         Catalyst::Exception->throw(
2196             message => qq/Couldn't instantiate component "$component", "$error"/
2197         );
2198     }
2199
2200     unless (blessed $instance) {
2201         my $metaclass = Moose::Util::find_meta($component);
2202         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2203         my $component_method_from = $method_meta->associated_metaclass->name;
2204         my $value = defined($instance) ? $instance : 'undef';
2205         Catalyst::Exception->throw(
2206             message =>
2207             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2208         );
2209     }
2210     return $instance;
2211 }
2212
2213 =head2 $c->setup_dispatcher
2214
2215 Sets up dispatcher.
2216
2217 =cut
2218
2219 sub setup_dispatcher {
2220     my ( $class, $dispatcher ) = @_;
2221
2222     if ($dispatcher) {
2223         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2224     }
2225
2226     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2227         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2228     }
2229
2230     unless ($dispatcher) {
2231         $dispatcher = $class->dispatcher_class;
2232     }
2233
2234     Class::MOP::load_class($dispatcher);
2235
2236     # dispatcher instance
2237     $class->dispatcher( $dispatcher->new );
2238 }
2239
2240 =head2 $c->setup_engine
2241
2242 Sets up engine.
2243
2244 =cut
2245
2246 sub setup_engine {
2247     my ( $class, $engine ) = @_;
2248
2249     if ($engine) {
2250         $engine = 'Catalyst::Engine::' . $engine;
2251     }
2252
2253     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2254         $engine = 'Catalyst::Engine::' . $env;
2255     }
2256
2257     if ( $ENV{MOD_PERL} ) {
2258         my $meta = Class::MOP::get_metaclass_by_name($class);
2259
2260         # create the apache method
2261         $meta->add_method('apache' => sub { shift->engine->apache });
2262
2263         my ( $software, $version ) =
2264           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2265
2266         $version =~ s/_//g;
2267         $version =~ s/(\.[^.]+)\./$1/g;
2268
2269         if ( $software eq 'mod_perl' ) {
2270
2271             if ( !$engine ) {
2272
2273                 if ( $version >= 1.99922 ) {
2274                     $engine = 'Catalyst::Engine::Apache2::MP20';
2275                 }
2276
2277                 elsif ( $version >= 1.9901 ) {
2278                     $engine = 'Catalyst::Engine::Apache2::MP19';
2279                 }
2280
2281                 elsif ( $version >= 1.24 ) {
2282                     $engine = 'Catalyst::Engine::Apache::MP13';
2283                 }
2284
2285                 else {
2286                     Catalyst::Exception->throw( message =>
2287                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2288                 }
2289
2290             }
2291
2292             # install the correct mod_perl handler
2293             if ( $version >= 1.9901 ) {
2294                 *handler = sub  : method {
2295                     shift->handle_request(@_);
2296                 };
2297             }
2298             else {
2299                 *handler = sub ($$) { shift->handle_request(@_) };
2300             }
2301
2302         }
2303
2304         elsif ( $software eq 'Zeus-Perl' ) {
2305             $engine = 'Catalyst::Engine::Zeus';
2306         }
2307
2308         else {
2309             Catalyst::Exception->throw(
2310                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2311         }
2312     }
2313
2314     unless ($engine) {
2315         $engine = $class->engine_class;
2316     }
2317
2318     Class::MOP::load_class($engine);
2319
2320     # check for old engines that are no longer compatible
2321     my $old_engine;
2322     if ( $engine->isa('Catalyst::Engine::Apache')
2323         && !Catalyst::Engine::Apache->VERSION )
2324     {
2325         $old_engine = 1;
2326     }
2327
2328     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2329         && Catalyst::Engine::Server->VERSION le '0.02' )
2330     {
2331         $old_engine = 1;
2332     }
2333
2334     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2335         && $engine->VERSION eq '0.01' )
2336     {
2337         $old_engine = 1;
2338     }
2339
2340     elsif ($engine->isa('Catalyst::Engine::Zeus')
2341         && $engine->VERSION eq '0.01' )
2342     {
2343         $old_engine = 1;
2344     }
2345
2346     if ($old_engine) {
2347         Catalyst::Exception->throw( message =>
2348               qq/Engine "$engine" is not supported by this version of Catalyst/
2349         );
2350     }
2351
2352     # engine instance
2353     $class->engine( $engine->new );
2354 }
2355
2356 =head2 $c->setup_home
2357
2358 Sets up the home directory.
2359
2360 =cut
2361
2362 sub setup_home {
2363     my ( $class, $home ) = @_;
2364
2365     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2366         $home = $env;
2367     }
2368
2369     $home ||= Catalyst::Utils::home($class);
2370
2371     if ($home) {
2372         #I remember recently being scolded for assigning config values like this
2373         $class->config->{home} ||= $home;
2374         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2375     }
2376 }
2377
2378 =head2 $c->setup_log
2379
2380 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2381 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2382 log to.
2383
2384 This method also installs a C<debug> method that returns a true value into the
2385 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2386 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2387
2388 Note that if the log has already been setup, by either a previous call to
2389 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2390 that this method won't actually set up the log object.
2391
2392 =cut
2393
2394 sub setup_log {
2395     my ( $class, $levels ) = @_;
2396
2397     $levels ||= '';
2398     $levels =~ s/^\s+//;
2399     $levels =~ s/\s+$//;
2400     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels || '';
2401
2402     unless ( $class->log ) {
2403         $class->log( Catalyst::Log->new(keys %levels) );
2404     }
2405
2406     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2407     if ( defined($env_debug) or $levels{debug} ) {
2408         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2409         $class->log->debug('Debug messages enabled');
2410     }
2411 }
2412
2413 =head2 $c->setup_plugins
2414
2415 Sets up plugins.
2416
2417 =cut
2418
2419 =head2 $c->setup_stats
2420
2421 Sets up timing statistics class.
2422
2423 =cut
2424
2425 sub setup_stats {
2426     my ( $class, $stats ) = @_;
2427
2428     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2429
2430     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2431     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2432         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2433         $class->log->debug('Statistics enabled');
2434     }
2435 }
2436
2437
2438 =head2 $c->registered_plugins
2439
2440 Returns a sorted list of the plugins which have either been stated in the
2441 import list or which have been added via C<< MyApp->plugin(@args); >>.
2442
2443 If passed a given plugin name, it will report a boolean value indicating
2444 whether or not that plugin is loaded.  A fully qualified name is required if
2445 the plugin name does not begin with C<Catalyst::Plugin::>.
2446
2447  if ($c->registered_plugins('Some::Plugin')) {
2448      ...
2449  }
2450
2451 =cut
2452
2453 {
2454
2455     sub registered_plugins {
2456         my $proto = shift;
2457         return sort keys %{ $proto->_plugins } unless @_;
2458         my $plugin = shift;
2459         return 1 if exists $proto->_plugins->{$plugin};
2460         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2461     }
2462
2463     sub _register_plugin {
2464         my ( $proto, $plugin, $instant ) = @_;
2465         my $class = ref $proto || $proto;
2466
2467         # no ignore_loaded here, the plugin may already have been
2468         # defined in memory and we don't want to error on "no file" if so
2469
2470         Class::MOP::load_class( $plugin );
2471
2472         $proto->_plugins->{$plugin} = 1;
2473         unless ($instant) {
2474             no strict 'refs';
2475             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2476               my @superclasses = ($plugin, $meta->superclasses );
2477               $meta->superclasses(@superclasses);
2478             } else {
2479               unshift @{"$class\::ISA"}, $plugin;
2480             }
2481         }
2482         return $class;
2483     }
2484
2485     sub setup_plugins {
2486         my ( $class, $plugins ) = @_;
2487
2488         $class->_plugins( {} ) unless $class->_plugins;
2489         $plugins ||= [];
2490         for my $plugin ( reverse @$plugins ) {
2491
2492             unless ( $plugin =~ s/\A\+// ) {
2493                 $plugin = "Catalyst::Plugin::$plugin";
2494             }
2495
2496             $class->_register_plugin($plugin);
2497         }
2498     }
2499 }
2500
2501 =head2 $c->stack
2502
2503 Returns an arrayref of the internal execution stack (actions that are
2504 currently executing).
2505
2506 =head2 $c->stats_class
2507
2508 Returns or sets the stats (timing statistics) class.
2509
2510 =head2 $c->use_stats
2511
2512 Returns 1 when stats collection is enabled.  Stats collection is enabled
2513 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2514 environment variable is set.
2515
2516 Note that this is a static method, not an accessor and should be overloaded
2517 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2518
2519 =cut
2520
2521 sub use_stats { 0 }
2522
2523
2524 =head2 $c->write( $data )
2525
2526 Writes $data to the output stream. When using this method directly, you
2527 will need to manually set the C<Content-Length> header to the length of
2528 your output data, if known.
2529
2530 =cut
2531
2532 sub write {
2533     my $c = shift;
2534
2535     # Finalize headers if someone manually writes output
2536     $c->finalize_headers;
2537
2538     return $c->engine->write( $c, @_ );
2539 }
2540
2541 =head2 version
2542
2543 Returns the Catalyst version number. Mostly useful for "powered by"
2544 messages in template systems.
2545
2546 =cut
2547
2548 sub version { return $Catalyst::VERSION }
2549
2550 =head1 INTERNAL ACTIONS
2551
2552 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2553 C<_ACTION>, and C<_END>. These are by default not shown in the private
2554 action table, but you can make them visible with a config parameter.
2555
2556     MyApp->config->{show_internal_actions} = 1;
2557
2558 =head1 CASE SENSITIVITY
2559
2560 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2561 mapped to C</foo/bar>. You can activate case sensitivity with a config
2562 parameter.
2563
2564     MyApp->config->{case_sensitive} = 1;
2565
2566 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2567
2568 =head1 ON-DEMAND PARSER
2569
2570 The request body is usually parsed at the beginning of a request,
2571 but if you want to handle input yourself, you can enable on-demand
2572 parsing with a config parameter.
2573
2574     MyApp->config->{parse_on_demand} = 1;
2575
2576 =head1 PROXY SUPPORT
2577
2578 Many production servers operate using the common double-server approach,
2579 with a lightweight frontend web server passing requests to a larger
2580 backend server. An application running on the backend server must deal
2581 with two problems: the remote user always appears to be C<127.0.0.1> and
2582 the server's hostname will appear to be C<localhost> regardless of the
2583 virtual host that the user connected through.
2584
2585 Catalyst will automatically detect this situation when you are running
2586 the frontend and backend servers on the same machine. The following
2587 changes are made to the request.
2588
2589     $c->req->address is set to the user's real IP address, as read from
2590     the HTTP X-Forwarded-For header.
2591
2592     The host value for $c->req->base and $c->req->uri is set to the real
2593     host, as read from the HTTP X-Forwarded-Host header.
2594
2595 Obviously, your web server must support these headers for this to work.
2596
2597 In a more complex server farm environment where you may have your
2598 frontend proxy server(s) on different machines, you will need to set a
2599 configuration option to tell Catalyst to read the proxied data from the
2600 headers.
2601
2602     MyApp->config->{using_frontend_proxy} = 1;
2603
2604 If you do not wish to use the proxy support at all, you may set:
2605
2606     MyApp->config->{ignore_frontend_proxy} = 1;
2607
2608 =head1 THREAD SAFETY
2609
2610 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2611 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2612 believe the Catalyst core to be thread-safe.
2613
2614 If you plan to operate in a threaded environment, remember that all other
2615 modules you are using must also be thread-safe. Some modules, most notably
2616 L<DBD::SQLite>, are not thread-safe.
2617
2618 =head1 SUPPORT
2619
2620 IRC:
2621
2622     Join #catalyst on irc.perl.org.
2623
2624 Mailing Lists:
2625
2626     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2627     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2628
2629 Web:
2630
2631     http://catalyst.perl.org
2632
2633 Wiki:
2634
2635     http://dev.catalyst.perl.org
2636
2637 =head1 SEE ALSO
2638
2639 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2640
2641 =head2 L<Catalyst::Manual> - The Catalyst Manual
2642
2643 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2644
2645 =head2 L<Catalyst::Engine> - Core engine
2646
2647 =head2 L<Catalyst::Log> - Log class.
2648
2649 =head2 L<Catalyst::Request> - Request object
2650
2651 =head2 L<Catalyst::Response> - Response object
2652
2653 =head2 L<Catalyst::Test> - The test suite.
2654
2655 =head1 PROJECT FOUNDER
2656
2657 sri: Sebastian Riedel <sri@cpan.org>
2658
2659 =head1 CONTRIBUTORS
2660
2661 abw: Andy Wardley
2662
2663 acme: Leon Brocard <leon@astray.com>
2664
2665 Andrew Bramble
2666
2667 Andrew Ford
2668
2669 Andrew Ruthven
2670
2671 andyg: Andy Grundman <andy@hybridized.org>
2672
2673 audreyt: Audrey Tang
2674
2675 bricas: Brian Cassidy <bricas@cpan.org>
2676
2677 Caelum: Rafael Kitover <rkitover@io.com>
2678
2679 chansen: Christian Hansen
2680
2681 chicks: Christopher Hicks
2682
2683 David E. Wheeler
2684
2685 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2686
2687 Drew Taylor
2688
2689 esskar: Sascha Kiefer
2690
2691 fireartist: Carl Franks <cfranks@cpan.org>
2692
2693 gabb: Danijel Milicevic
2694
2695 Gary Ashton Jones
2696
2697 Geoff Richards
2698
2699 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2700
2701 jcamacho: Juan Camacho
2702
2703 jhannah: Jay Hannah <jay@jays.net>
2704
2705 Jody Belka
2706
2707 Johan Lindstrom
2708
2709 jon: Jon Schutz <jjschutz@cpan.org>
2710
2711 marcus: Marcus Ramberg <mramberg@cpan.org>
2712
2713 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2714
2715 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2716
2717 mugwump: Sam Vilain
2718
2719 naughton: David Naughton
2720
2721 ningu: David Kamholz <dkamholz@cpan.org>
2722
2723 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2724
2725 numa: Dan Sully <daniel@cpan.org>
2726
2727 obra: Jesse Vincent
2728
2729 omega: Andreas Marienborg
2730
2731 Oleg Kostyuk <cub.uanic@gmail.com>
2732
2733 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2734
2735 rafl: Florian Ragwitz <rafl@debian.org>
2736
2737 sky: Arthur Bergman
2738
2739 the_jester: Jesse Sheidlower
2740
2741 t0m: Tomas Doran <bobtfish@bobtfish.net>
2742
2743 Ulf Edvinsson
2744
2745 willert: Sebastian Willert <willert@cpan.org>
2746
2747 =head1 LICENSE
2748
2749 This library is free software, you can redistribute it and/or modify it under
2750 the same terms as Perl itself.
2751
2752 =cut
2753
2754 no Moose;
2755
2756 __PACKAGE__->meta->make_immutable;
2757
2758 1;