lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use bytes;
   6 use Scope::Upper ();
   7 use Catalyst::Exception;
   8 use Catalyst::Log;
   9 use Catalyst::Request;
  10 use Catalyst::Request::Upload;
  11 use Catalyst::Response;
  12 use Catalyst::Utils;
  13 use Catalyst::Controller;
  14 use Devel::InnerPackage ();
  15 use File::stat;
  16 use Module::Pluggable::Object ();
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp shortmess/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 has stack => (is => 'ro', default => sub { [] });
  34 has stash => (is => 'rw', default => sub { {} });
  35 has state => (is => 'rw', default => 0);
  36 has stats => (is => 'rw');
  37 has action => (is => 'rw');
  38 has counter => (is => 'rw', default => sub { {} });
  39 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  40 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  41 has namespace => (is => 'rw');
  42
  43 sub depth { scalar @{ shift->stack || [] }; }
  44 sub comp { shift->component(@_) }
  45
  46 sub req {
  47     # carp "the use of req() is deprecated in favour of request()";
  48     my $self = shift; return $self->request(@_);
  49 }
  50 sub res {
  51     # carp "the use of res() is deprecated in favour of response()";
  52     my $self = shift; return $self->response(@_);
  53 }
  54
  55 # For backwards compatibility
  56 sub finalize_output { shift->finalize_body(@_) };
  57
  58 # For statistics
  59 our $COUNT     = 1;
  60 our $START     = time;
  61 our $RECURSION = 1000;
  62 our $DETACH    = "catalyst_detach\n";
  63 our $GO        = "catalyst_go\n";
  64
  65 #I imagine that very few of these really need to be class variables. if any.
  66 #maybe we should just make them attributes with a default?
  67 __PACKAGE__->mk_classdata($_)
  68   for qw/components arguments dispatcher engine log dispatcher_class
  69   engine_class context_class request_class response_class stats_class
  70   setup_finished/;
  71
  72 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  73 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  74 __PACKAGE__->request_class('Catalyst::Request');
  75 __PACKAGE__->response_class('Catalyst::Response');
  76 __PACKAGE__->stats_class('Catalyst::Stats');
  77
  78 # Remember to update this in Catalyst::Runtime as well!
  79
  80 our $VERSION = '5.8000_05';
  81
  82 sub import {
  83     my ( $class, @arguments ) = @_;
  84
  85     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  86     # callers @ISA.
  87     return unless $class eq 'Catalyst';
  88
  89     my $caller = caller();
  90     return if $caller eq 'main';
  91     my $meta = Moose::Meta::Class->initialize($caller);
  92     #Moose->import({ into => $caller }); #do we want to do this?
  93
  94     unless ( $caller->isa('Catalyst') ) {
  95         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  96         $meta->superclasses(@superclasses);
  97     }
  98     unless( $meta->has_method('meta') ){
  99         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 100     }
 101
 102     $caller->arguments( [@arguments] );
 103     $caller->setup_home;
 104 }
 105
 106 =head1 NAME
 107
 108 Catalyst - The Elegant MVC Web Application Framework
 109
 110 =head1 SYNOPSIS
 111
 112 See the L<Catalyst::Manual> distribution for comprehensive
 113 documentation and tutorials.
 114
 115     # Install Catalyst::Devel for helpers and other development tools
 116     # use the helper to create a new application
 117     catalyst.pl MyApp
 118
 119     # add models, views, controllers
 120     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 121     script/myapp_create.pl view MyTemplate TT
 122     script/myapp_create.pl controller Search
 123
 124     # built in testserver -- use -r to restart automatically on changes
 125     # --help to see all available options
 126     script/myapp_server.pl
 127
 128     # command line testing interface
 129     script/myapp_test.pl /yada
 130
 131     ### in lib/MyApp.pm
 132     use Catalyst qw/-Debug/; # include plugins here as well
 133
 134     ### In lib/MyApp/Controller/Root.pm (autocreated)
 135     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 136         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 137         $c->stash->{template} = 'foo.tt'; # set the template
 138         # lookup something from db -- stash vars are passed to TT
 139         $c->stash->{data} =
 140           $c->model('Database::Foo')->search( { country => $args[0] } );
 141         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 142             $c->forward( 'bar' ); # process another action
 143             # do something else after forward returns
 144         }
 145     }
 146
 147     # The foo.tt TT template can use the stash data from the database
 148     [% WHILE (item = data.next) %]
 149         [% item.foo %]
 150     [% END %]
 151
 152     # called for /bar/of/soap, /bar/of/soap/10, etc.
 153     sub bar : Path('/bar/of/soap') { ... }
 154
 155     # called for all actions, from the top-most controller downwards
 156     sub auto : Private {
 157         my ( $self, $c ) = @_;
 158         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 159             $c->res->redirect( '/login' ); # require login
 160             return 0; # abort request and go immediately to end()
 161         }
 162         return 1; # success; carry on to next action
 163     }
 164
 165     # called after all actions are finished
 166     sub end : Private {
 167         my ( $self, $c ) = @_;
 168         if ( scalar @{ $c->error } ) { ... } # handle errors
 169         return if $c->res->body; # already have a response
 170         $c->forward( 'MyApp::View::TT' ); # render template
 171     }
 172
 173     ### in MyApp/Controller/Foo.pm
 174     # called for /foo/bar
 175     sub bar : Local { ... }
 176
 177     # called for /blargle
 178     sub blargle : Global { ... }
 179
 180     # an index action matches /foo, but not /foo/1, etc.
 181     sub index : Private { ... }
 182
 183     ### in MyApp/Controller/Foo/Bar.pm
 184     # called for /foo/bar/baz
 185     sub baz : Local { ... }
 186
 187     # first Root auto is called, then Foo auto, then this
 188     sub auto : Private { ... }
 189
 190     # powerful regular expression paths are also possible
 191     sub details : Regex('^product/(\w+)/details$') {
 192         my ( $self, $c ) = @_;
 193         # extract the (\w+) from the URI
 194         my $product = $c->req->captures->[0];
 195     }
 196
 197 See L<Catalyst::Manual::Intro> for additional information.
 198
 199 =head1 DESCRIPTION
 200
 201 Catalyst is a modern framework for making web applications without the
 202 pain usually associated with this process. This document is a reference
 203 to the main Catalyst application. If you are a new user, we suggest you
 204 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 205
 206 See L<Catalyst::Manual> for more documentation.
 207
 208 Catalyst plugins can be loaded by naming them as arguments to the "use
 209 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 210 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 211 C<My::Module>.
 212
 213     use Catalyst qw/My::Module/;
 214
 215 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 216 fully qualify the name by using a unary plus:
 217
 218     use Catalyst qw/
 219         My::Module
 220         +Fully::Qualified::Plugin::Name
 221     /;
 222
 223 Special flags like C<-Debug> and C<-Engine> can also be specified as
 224 arguments when Catalyst is loaded:
 225
 226     use Catalyst qw/-Debug My::Module/;
 227
 228 The position of plugins and flags in the chain is important, because
 229 they are loaded in the order in which they appear.
 230
 231 The following flags are supported:
 232
 233 =head2 -Debug
 234
 235 Enables debug output. You can also force this setting from the system
 236 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 237 settings override the application, with <MYAPP>_DEBUG having the highest
 238 priority.
 239
 240 =head2 -Engine
 241
 242 Forces Catalyst to use a specific engine. Omit the
 243 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 244
 245     use Catalyst qw/-Engine=CGI/;
 246
 247 =head2 -Home
 248
 249 Forces Catalyst to use a specific home directory, e.g.:
 250
 251     use Catalyst qw[-Home=/usr/mst];
 252
 253 This can also be done in the shell environment by setting either the
 254 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 255 is replaced with the uppercased name of your application, any "::" in
 256 the name will be replaced with underscores, e.g. MyApp::Web should use
 257 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 258
 259 =head2 -Log
 260
 261     use Catalyst '-Log=warn,fatal,error';
 262
 263 Specifies a comma-delimited list of log levels.
 264
 265 =head2 -Stats
 266
 267 Enables statistics collection and reporting. You can also force this setting
 268 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 269 environment settings override the application, with <MYAPP>_STATS having the
 270 highest priority.
 271
 272 e.g.
 273
 274    use Catalyst qw/-Stats=1/
 275
 276 =head1 METHODS
 277
 278 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 279
 280 =head2 $c->action
 281
 282 Returns a L<Catalyst::Action> object for the current action, which
 283 stringifies to the action name. See L<Catalyst::Action>.
 284
 285 =head2 $c->namespace
 286
 287 Returns the namespace of the current action, i.e., the URI prefix
 288 corresponding to the controller of the current action. For example:
 289
 290     # in Controller::Foo::Bar
 291     $c->namespace; # returns 'foo/bar';
 292
 293 =head2 $c->request
 294
 295 =head2 $c->req
 296
 297 Returns the current L<Catalyst::Request> object, giving access to
 298 information about the current client request (including parameters,
 299 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 300
 301 =head2 REQUEST FLOW HANDLING
 302
 303 =head2 $c->forward( $action [, \@arguments ] )
 304
 305 =head2 $c->forward( $class, $method, [, \@arguments ] )
 306
 307 Forwards processing to another action, by its private name. If you give a
 308 class name but no method, C<process()> is called. You may also optionally
 309 pass arguments in an arrayref. The action will receive the arguments in
 310 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 311 C<< $c->req->args >> will be restored to the previous values.
 312
 313 Any data C<return>ed from the action forwarded to, will be returned by the
 314 call to forward.
 315
 316     my $foodata = $c->forward('/foo');
 317     $c->forward('index');
 318     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 319     $c->forward('MyApp::View::TT');
 320
 321 Note that forward implies an C<<eval { }>> around the call (actually
 322 C<execute> does), thus de-fatalizing all 'dies' within the called
 323 action. If you want C<die> to propagate you need to do something like:
 324
 325     $c->forward('foo');
 326     die $c->error if $c->error;
 327
 328 Or make sure to always return true values from your actions and write
 329 your code like this:
 330
 331     $c->forward('foo') || return;
 332
 333 =cut
 334
 335 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 336
 337 =head2 $c->detach( $action [, \@arguments ] )
 338
 339 =head2 $c->detach( $class, $method, [, \@arguments ] )
 340
 341 =head2 $c->detach()
 342
 343 The same as C<forward>, but doesn't return to the previous action when
 344 processing is finished.
 345
 346 When called with no arguments it escapes the processing chain entirely.
 347
 348 =cut
 349
 350 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 351
 352 =head2 $c->visit( $action [, \@arguments ] )
 353
 354 =head2 $c->visit( $class, $method, [, \@arguments ] )
 355
 356 Almost the same as C<forward>, but does a full dispatch, instead of just
 357 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 358 C<auto> and the method you go to are called, just like a new request.
 359
 360 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 361 This means, for example, that $c->action methods such as C<name>, C<class> and
 362 C<reverse> return information for the visited action when they are invoked
 363 within the visited action.  This is different from the behavior of C<forward>
 364 which continues to use the $c->action object from the caller action even when
 365 invoked from the callee.
 366
 367 C<$c-E<gt>stash> is kept unchanged.
 368
 369 In effect, C<visit> allows you to "wrap" another action, just as it
 370 would have been called by dispatching from a URL, while the analogous
 371 C<go> allows you to transfer control to another action as if it had
 372 been reached directly from a URL.
 373
 374 =cut
 375
 376 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 377
 378 =head2 $c->go( $action [, \@arguments ] )
 379
 380 =head2 $c->go( $class, $method, [, \@arguments ] )
 381
 382 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 383 instead of just calling the new C<$action> /
 384 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 385 method you visit are called, just like a new request.
 386
 387 C<$c-E<gt>stash> is kept unchanged.
 388
 389 =cut
 390
 391 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 392
 393 =head2 $c->response
 394
 395 =head2 $c->res
 396
 397 Returns the current L<Catalyst::Response> object, see there for details.
 398
 399 =head2 $c->stash
 400
 401 Returns a hashref to the stash, which may be used to store data and pass
 402 it between components during a request. You can also set hash keys by
 403 passing arguments. The stash is automatically sent to the view. The
 404 stash is cleared at the end of a request; it cannot be used for
 405 persistent storage (for this you must use a session; see
 406 L<Catalyst::Plugin::Session> for a complete system integrated with
 407 Catalyst).
 408
 409     $c->stash->{foo} = $bar;
 410     $c->stash( { moose => 'majestic', qux => 0 } );
 411     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 412
 413     # stash is automatically passed to the view for use in a template
 414     $c->forward( 'MyApp::View::TT' );
 415
 416 =cut
 417
 418 around stash => sub {
 419     my $orig = shift;
 420     my $c = shift;
 421     my $stash = $orig->($c);
 422     if (@_) {
 423         my $new_stash = @_ > 1 ? {@_} : $_[0];
 424         croak('stash takes a hash or hashref') unless ref $new_stash;
 425         foreach my $key ( keys %$new_stash ) {
 426           $stash->{$key} = $new_stash->{$key};
 427         }
 428     }
 429
 430     return $stash;
 431 };
 432
 433
 434 =head2 $c->error
 435
 436 =head2 $c->error($error, ...)
 437
 438 =head2 $c->error($arrayref)
 439
 440 Returns an arrayref containing error messages.  If Catalyst encounters an
 441 error while processing a request, it stores the error in $c->error.  This
 442 method should only be used to store fatal error messages.
 443
 444     my @error = @{ $c->error };
 445
 446 Add a new error.
 447
 448     $c->error('Something bad happened');
 449
 450 =cut
 451
 452 sub error {
 453     my $c = shift;
 454     if ( $_[0] ) {
 455         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 456         croak @$error unless ref $c;
 457         push @{ $c->{error} }, @$error;
 458     }
 459     elsif ( defined $_[0] ) { $c->{error} = undef }
 460     return $c->{error} || [];
 461 }
 462
 463
 464 =head2 $c->state
 465
 466 Contains the return value of the last executed action.
 467
 468 =head2 $c->clear_errors
 469
 470 Clear errors.  You probably don't want to clear the errors unless you are
 471 implementing a custom error screen.
 472
 473 This is equivalent to running
 474
 475     $c->error(0);
 476
 477 =cut
 478
 479 sub clear_errors {
 480     my $c = shift;
 481     $c->error(0);
 482 }
 483
 484 # search components given a name and some prefixes
 485 sub _comp_search_prefixes {
 486     my ( $c, $name, @prefixes ) = @_;
 487     my $appclass = ref $c || $c;
 488     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 489
 490     # map the original component name to the sub part that we will search against
 491     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 492         grep { /$filter/ } keys %{ $c->components };
 493
 494     # undef for a name will return all
 495     return keys %eligible if !defined $name;
 496
 497     my $query  = ref $name ? $name : qr/^$name$/i;
 498     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 499
 500     return map { $c->components->{ $_ } } @result if @result;
 501
 502     # if we were given a regexp to search against, we're done.
 503     return if ref $name;
 504
 505     # regexp fallback
 506     $query  = qr/$name/i;
 507     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 508
 509     # no results? try against full names
 510     if( !@result ) {
 511         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 512     }
 513
 514     # don't warn if we didn't find any results, it just might not exist
 515     if( @result ) {
 516         my $msg = "Used regexp fallback for \$c->model('${name}'), which found '" .
 517            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 518            "component resolution is unreliable and unsafe.";
 519         my $short = $result[0];
 520         $short =~ s/.*?Model:://;
 521         my $shortmess = Carp::shortmess('');
 522         if ($shortmess =~ m#Catalyst/Plugin#) {
 523            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 524               "plugin's config";
 525         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 526            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 527               "component's config";
 528         } else {
 529            $msg .= " You probably meant \$c->model('$short') instead of \$c->model{'${name}'}, " .
 530               "but if you really wanted to search, pass in a regexp as the argument " .
 531               "like so: \$c->model(qr/${name}/)";
 532         }
 533         $c->log->warn( "${msg}$shortmess" );
 534     }
 535
 536     return @result;
 537 }
 538
 539 # Find possible names for a prefix
 540 sub _comp_names {
 541     my ( $c, @prefixes ) = @_;
 542     my $appclass = ref $c || $c;
 543
 544     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 545
 546     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 547     return @names;
 548 }
 549
 550 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 551 sub _filter_component {
 552     my ( $c, $comp, @args ) = @_;
 553
 554     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 555         return $comp->ACCEPT_CONTEXT( $c, @args );
 556     }
 557
 558     return $comp;
 559 }
 560
 561 =head2 COMPONENT ACCESSORS
 562
 563 =head2 $c->controller($name)
 564
 565 Gets a L<Catalyst::Controller> instance by name.
 566
 567     $c->controller('Foo')->do_stuff;
 568
 569 If the name is omitted, will return the controller for the dispatched
 570 action.
 571
 572 If you want to search for controllers, pass in a regexp as the argument.
 573
 574     # find all controllers that start with Foo
 575     my @foo_controllers = $c->controller(qr{^Foo});
 576
 577
 578 =cut
 579
 580 sub controller {
 581     my ( $c, $name, @args ) = @_;
 582
 583     if( $name ) {
 584         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 585         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 586         return $c->_filter_component( $result[ 0 ], @args );
 587     }
 588
 589     return $c->component( $c->action->class );
 590 }
 591
 592 =head2 $c->model($name)
 593
 594 Gets a L<Catalyst::Model> instance by name.
 595
 596     $c->model('Foo')->do_stuff;
 597
 598 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 599
 600 If the name is omitted, it will look for
 601  - a model object in $c->stash->{current_model_instance}, then
 602  - a model name in $c->stash->{current_model}, then
 603  - a config setting 'default_model', or
 604  - check if there is only one model, and return it if that's the case.
 605
 606 If you want to search for models, pass in a regexp as the argument.
 607
 608     # find all models that start with Foo
 609     my @foo_models = $c->model(qr{^Foo});
 610
 611 =cut
 612
 613 sub model {
 614     my ( $c, $name, @args ) = @_;
 615
 616     if( $name ) {
 617         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 618         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 619         return $c->_filter_component( $result[ 0 ], @args );
 620     }
 621
 622     if (ref $c) {
 623         return $c->stash->{current_model_instance}
 624           if $c->stash->{current_model_instance};
 625         return $c->model( $c->stash->{current_model} )
 626           if $c->stash->{current_model};
 627     }
 628     return $c->model( $c->config->{default_model} )
 629       if $c->config->{default_model};
 630
 631     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 632
 633     if( $rest ) {
 634         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 635         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 636         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 637         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 638         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 639     }
 640
 641     return $c->_filter_component( $comp );
 642 }
 643
 644
 645 =head2 $c->view($name)
 646
 647 Gets a L<Catalyst::View> instance by name.
 648
 649     $c->view('Foo')->do_stuff;
 650
 651 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 652
 653 If the name is omitted, it will look for
 654  - a view object in $c->stash->{current_view_instance}, then
 655  - a view name in $c->stash->{current_view}, then
 656  - a config setting 'default_view', or
 657  - check if there is only one view, and return it if that's the case.
 658
 659 If you want to search for views, pass in a regexp as the argument.
 660
 661     # find all views that start with Foo
 662     my @foo_views = $c->view(qr{^Foo});
 663
 664 =cut
 665
 666 sub view {
 667     my ( $c, $name, @args ) = @_;
 668
 669     if( $name ) {
 670         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 671         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 672         return $c->_filter_component( $result[ 0 ], @args );
 673     }
 674
 675     if (ref $c) {
 676         return $c->stash->{current_view_instance}
 677           if $c->stash->{current_view_instance};
 678         return $c->view( $c->stash->{current_view} )
 679           if $c->stash->{current_view};
 680     }
 681     return $c->view( $c->config->{default_view} )
 682       if $c->config->{default_view};
 683
 684     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 685
 686     if( $rest ) {
 687         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 688         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 689         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 690         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 691         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 692     }
 693
 694     return $c->_filter_component( $comp );
 695 }
 696
 697 =head2 $c->controllers
 698
 699 Returns the available names which can be passed to $c->controller
 700
 701 =cut
 702
 703 sub controllers {
 704     my ( $c ) = @_;
 705     return $c->_comp_names(qw/Controller C/);
 706 }
 707
 708 =head2 $c->models
 709
 710 Returns the available names which can be passed to $c->model
 711
 712 =cut
 713
 714 sub models {
 715     my ( $c ) = @_;
 716     return $c->_comp_names(qw/Model M/);
 717 }
 718
 719
 720 =head2 $c->views
 721
 722 Returns the available names which can be passed to $c->view
 723
 724 =cut
 725
 726 sub views {
 727     my ( $c ) = @_;
 728     return $c->_comp_names(qw/View V/);
 729 }
 730
 731 =head2 $c->comp($name)
 732
 733 =head2 $c->component($name)
 734
 735 Gets a component object by name. This method is not recommended,
 736 unless you want to get a specific component by full
 737 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 738 should be used instead.
 739
 740 If C<$name> is a regexp, a list of components matched against the full
 741 component name will be returned.
 742
 743 =cut
 744
 745 sub component {
 746     my ( $c, $name, @args ) = @_;
 747
 748     if( $name ) {
 749         my $comps = $c->components;
 750
 751         if( !ref $name ) {
 752             # is it the exact name?
 753             return $c->_filter_component( $comps->{ $name }, @args )
 754                        if exists $comps->{ $name };
 755
 756             # perhaps we just omitted "MyApp"?
 757             my $composed = ( ref $c || $c ) . "::${name}";
 758             return $c->_filter_component( $comps->{ $composed }, @args )
 759                        if exists $comps->{ $composed };
 760
 761             # search all of the models, views and controllers
 762             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 763             return $c->_filter_component( $comp, @args ) if $comp;
 764         }
 765
 766         # This is here so $c->comp( '::M::' ) works
 767         my $query = ref $name ? $name : qr{$name}i;
 768
 769         my @result = grep { m{$query} } keys %{ $c->components };
 770         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 771
 772         if( $result[ 0 ] ) {
 773             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 774             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 775             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 776             return $c->_filter_component( $result[ 0 ], @args );
 777         }
 778
 779         # I would expect to return an empty list here, but that breaks back-compat
 780     }
 781
 782     # fallback
 783     return sort keys %{ $c->components };
 784 }
 785
 786 =head2 CLASS DATA AND HELPER CLASSES
 787
 788 =head2 $c->config
 789
 790 Returns or takes a hashref containing the application's configuration.
 791
 792     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 793
 794 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 795 like myapp.yml in your applications home directory. See
 796 L<Catalyst::Plugin::ConfigLoader>.
 797
 798     ---
 799     db: dsn:SQLite:foo.db
 800
 801
 802 =cut
 803
 804 around config => sub {
 805     my $orig = shift;
 806     my $c = shift;
 807
 808     $c->log->warn("Setting config after setup has been run is not a good idea.")
 809       if ( @_ and $c->setup_finished );
 810
 811     $c->$orig(@_);
 812 };
 813
 814 =head2 $c->log
 815
 816 Returns the logging object instance. Unless it is already set, Catalyst
 817 sets this up with a L<Catalyst::Log> object. To use your own log class,
 818 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 819 C<< __PACKAGE__->setup >>.
 820
 821  __PACKAGE__->log( MyLogger->new );
 822  __PACKAGE__->setup;
 823
 824 And later:
 825
 826     $c->log->info( 'Now logging with my own logger!' );
 827
 828 Your log class should implement the methods described in
 829 L<Catalyst::Log>.
 830
 831
 832 =head2 $c->debug
 833
 834 Overload to enable debug messages (same as -Debug option).
 835
 836 Note that this is a static method, not an accessor and should be overloaded
 837 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 838
 839 =cut
 840
 841 sub debug { 0 }
 842
 843 =head2 $c->dispatcher
 844
 845 Returns the dispatcher instance. Stringifies to class name. See
 846 L<Catalyst::Dispatcher>.
 847
 848 =head2 $c->engine
 849
 850 Returns the engine instance. Stringifies to the class name. See
 851 L<Catalyst::Engine>.
 852
 853
 854 =head2 UTILITY METHODS
 855
 856 =head2 $c->path_to(@path)
 857
 858 Merges C<@path> with C<< $c->config->{home} >> and returns a
 859 L<Path::Class::Dir> object.
 860
 861 For example:
 862
 863     $c->path_to( 'db', 'sqlite.db' );
 864
 865 =cut
 866
 867 sub path_to {
 868     my ( $c, @path ) = @_;
 869     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 870     if ( -d $path ) { return $path }
 871     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 872 }
 873
 874 =head2 $c->plugin( $name, $class, @args )
 875
 876 Helper method for plugins. It creates a classdata accessor/mutator and
 877 loads and instantiates the given class.
 878
 879     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 880
 881     $c->prototype->define_javascript_functions;
 882
 883 B<Note:> This method of adding plugins is deprecated. The ability
 884 to add plugins like this B<will be removed> in a Catalyst 5.9.
 885 Please do not use this functionality in new code.
 886
 887 =cut
 888
 889 sub plugin {
 890     my ( $class, $name, $plugin, @args ) = @_;
 891
 892     # See block comment in t/unit_core_plugin.t
 893     $class->log->debug(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.9/);
 894
 895     $class->_register_plugin( $plugin, 1 );
 896
 897     eval { $plugin->import };
 898     $class->mk_classdata($name);
 899     my $obj;
 900     eval { $obj = $plugin->new(@args) };
 901
 902     if ($@) {
 903         Catalyst::Exception->throw( message =>
 904               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 905     }
 906
 907     $class->$name($obj);
 908     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 909       if $class->debug;
 910 }
 911
 912 =head2 MyApp->setup
 913
 914 Initializes the dispatcher and engine, loads any plugins, and loads the
 915 model, view, and controller components. You may also specify an array
 916 of plugins to load here, if you choose to not load them in the C<use
 917 Catalyst> line.
 918
 919     MyApp->setup;
 920     MyApp->setup( qw/-Debug/ );
 921
 922 =cut
 923
 924 sub setup {
 925     my ( $class, @arguments ) = @_;
 926     $class->log->warn("Running setup twice is not a good idea.")
 927       if ( $class->setup_finished );
 928
 929     unless ( $class->isa('Catalyst') ) {
 930
 931         Catalyst::Exception->throw(
 932             message => qq/'$class' does not inherit from Catalyst/ );
 933     }
 934
 935     if ( $class->arguments ) {
 936         @arguments = ( @arguments, @{ $class->arguments } );
 937     }
 938
 939     # Process options
 940     my $flags = {};
 941
 942     foreach (@arguments) {
 943
 944         if (/^-Debug$/) {
 945             $flags->{log} =
 946               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 947         }
 948         elsif (/^-(\w+)=?(.*)$/) {
 949             $flags->{ lc $1 } = $2;
 950         }
 951         else {
 952             push @{ $flags->{plugins} }, $_;
 953         }
 954     }
 955
 956     $class->setup_home( delete $flags->{home} );
 957
 958     $class->setup_log( delete $flags->{log} );
 959     $class->setup_plugins( delete $flags->{plugins} );
 960     $class->setup_dispatcher( delete $flags->{dispatcher} );
 961     $class->setup_engine( delete $flags->{engine} );
 962     $class->setup_stats( delete $flags->{stats} );
 963
 964     for my $flag ( sort keys %{$flags} ) {
 965
 966         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 967             &$code( $class, delete $flags->{$flag} );
 968         }
 969         else {
 970             $class->log->warn(qq/Unknown flag "$flag"/);
 971         }
 972     }
 973
 974     eval { require Catalyst::Devel; };
 975     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 976         $class->log->warn(<<"EOF");
 977 You are running an old script!
 978
 979   Please update by running (this will overwrite existing files):
 980     catalyst.pl -force -scripts $class
 981
 982   or (this will not overwrite existing files):
 983     catalyst.pl -scripts $class
 984
 985 EOF
 986     }
 987
 988     if ( $class->debug ) {
 989         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 990
 991         if (@plugins) {
 992             my $column_width = Catalyst::Utils::term_width() - 6;
 993             my $t = Text::SimpleTable->new($column_width);
 994             $t->row($_) for @plugins;
 995             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 996         }
 997
 998         my $dispatcher = $class->dispatcher;
 999         my $engine     = $class->engine;
1000         my $home       = $class->config->{home};
1001
1002         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1003         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1004
1005         $home
1006           ? ( -d $home )
1007           ? $class->log->debug(qq/Found home "$home"/)
1008           : $class->log->debug(qq/Home "$home" doesn't exist/)
1009           : $class->log->debug(q/Couldn't find home/);
1010     }
1011
1012     # Call plugins setup, this is stupid and evil.
1013     {
1014         no warnings qw/redefine/;
1015         local *setup = sub { };
1016         $class->setup;
1017     }
1018
1019     # Initialize our data structure
1020     $class->components( {} );
1021
1022     $class->setup_components;
1023
1024     if ( $class->debug ) {
1025         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1026         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1027         for my $comp ( sort keys %{ $class->components } ) {
1028             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1029             $t->row( $comp, $type );
1030         }
1031         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1032           if ( keys %{ $class->components } );
1033     }
1034
1035     # Add our self to components, since we are also a component
1036     if( $class->isa('Catalyst::Controller') ){
1037       $class->components->{$class} = $class;
1038     }
1039
1040     $class->setup_actions;
1041
1042     if ( $class->debug ) {
1043         my $name = $class->config->{name} || 'Application';
1044         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1045     }
1046     $class->log->_flush() if $class->log->can('_flush');
1047
1048     # Make sure that the application class becomes immutable at this point,
1049     # which ensures that it gets an inlined constructor. This means that it
1050     # works even if the user has added a plugin which contains a new method.
1051     # Note however that we have to do the work on scope end, so that method
1052     # modifiers work correctly in MyApp (as you have to call setup _before_
1053     # applying modifiers).
1054     Scope::Upper::reap(sub {
1055         my $meta = Class::MOP::get_metaclass_by_name($class);
1056         $meta->make_immutable unless $meta->is_immutable;
1057     }, Scope::Upper::SCOPE(1));
1058
1059     $class->setup_finalize;
1060 }
1061
1062
1063 =head2 $app->setup_finalize
1064
1065 A hook to attach modifiers to.
1066 Using C< after setup => sub{}; > doesn't work, because of quirky things done for plugin setup.
1067 Also better than C< setup_finished(); >, as that is a getter method.
1068
1069     sub setup_finalize {
1070
1071         my $app = shift;
1072
1073         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1074
1075         $app->next::method(@_);
1076
1077
1078     }
1079
1080 =cut
1081
1082 sub setup_finalize {
1083     my ($class) = @_;
1084     $class->setup_finished(1);
1085 }
1086
1087 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1088
1089 =head2 $c->uri_for( $path, @args?, \%query_values? )
1090
1091 =over
1092
1093 =item $action
1094
1095 A Catalyst::Action object representing the Catalyst action you want to
1096 create a URI for. To get one for an action in the current controller,
1097 use C<< $c->action('someactionname') >>. To get one from different
1098 controller, fetch the controller using C<< $c->controller() >>, then
1099 call C<action_for> on it.
1100
1101 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1102 using C<< $c->req->captures >>.
1103
1104   # For the current action
1105   $c->uri_for($c->action, $c->req->captures);
1106
1107   # For the Foo action in the Bar controller
1108   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1109
1110 =back
1111
1112 =cut
1113
1114 sub uri_for {
1115     my ( $c, $path, @args ) = @_;
1116
1117     if ( Scalar::Util::blessed($path) ) { # action object
1118         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1119                          ? shift(@args)
1120                          : [] );
1121         $path = $c->dispatcher->uri_for_action($path, $captures);
1122         return undef unless defined($path);
1123         $path = '/' if $path eq '';
1124     }
1125
1126     undef($path) if (defined $path && $path eq '');
1127
1128     my $params =
1129       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1130
1131     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1132     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1133
1134     unshift(@args, $path);
1135
1136     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1137         my $namespace = $c->namespace;
1138         if (defined $path) { # cheesy hack to handle path '../foo'
1139            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1140         }
1141         unshift(@args, $namespace || '');
1142     }
1143
1144     # join args with '/', or a blank string
1145     my $args = join('/', grep { defined($_) } @args);
1146     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1147     $args =~ s!^/+!!;
1148     my $base = $c->req->base;
1149     my $class = ref($base);
1150     $base =~ s{(?<!/)$}{/};
1151
1152     my $query = '';
1153
1154     if (my @keys = keys %$params) {
1155       # somewhat lifted from URI::_query's query_form
1156       $query = '?'.join('&', map {
1157           my $val = $params->{$_};
1158           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1159           s/ /+/g;
1160           my $key = $_;
1161           $val = '' unless defined $val;
1162           (map {
1163               $_ = "$_";
1164               utf8::encode( $_ ) if utf8::is_utf8($_);
1165               # using the URI::Escape pattern here so utf8 chars survive
1166               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1167               s/ /+/g;
1168               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1169       } @keys);
1170     }
1171
1172     my $res = bless(\"${base}${args}${query}", $class);
1173     $res;
1174 }
1175
1176 =head2 $c->welcome_message
1177
1178 Returns the Catalyst welcome HTML page.
1179
1180 =cut
1181
1182 sub welcome_message {
1183     my $c      = shift;
1184     my $name   = $c->config->{name};
1185     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1186     my $prefix = Catalyst::Utils::appprefix( ref $c );
1187     $c->response->content_type('text/html; charset=utf-8');
1188     return <<"EOF";
1189 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1190     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1191 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1192     <head>
1193     <meta http-equiv="Content-Language" content="en" />
1194     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1195         <title>$name on Catalyst $VERSION</title>
1196         <style type="text/css">
1197             body {
1198                 color: #000;
1199                 background-color: #eee;
1200             }
1201             div#content {
1202                 width: 640px;
1203                 margin-left: auto;
1204                 margin-right: auto;
1205                 margin-top: 10px;
1206                 margin-bottom: 10px;
1207                 text-align: left;
1208                 background-color: #ccc;
1209                 border: 1px solid #aaa;
1210             }
1211             p, h1, h2 {
1212                 margin-left: 20px;
1213                 margin-right: 20px;
1214                 font-family: verdana, tahoma, sans-serif;
1215             }
1216             a {
1217                 font-family: verdana, tahoma, sans-serif;
1218             }
1219             :link, :visited {
1220                     text-decoration: none;
1221                     color: #b00;
1222                     border-bottom: 1px dotted #bbb;
1223             }
1224             :link:hover, :visited:hover {
1225                     color: #555;
1226             }
1227             div#topbar {
1228                 margin: 0px;
1229             }
1230             pre {
1231                 margin: 10px;
1232                 padding: 8px;
1233             }
1234             div#answers {
1235                 padding: 8px;
1236                 margin: 10px;
1237                 background-color: #fff;
1238                 border: 1px solid #aaa;
1239             }
1240             h1 {
1241                 font-size: 0.9em;
1242                 font-weight: normal;
1243                 text-align: center;
1244             }
1245             h2 {
1246                 font-size: 1.0em;
1247             }
1248             p {
1249                 font-size: 0.9em;
1250             }
1251             p img {
1252                 float: right;
1253                 margin-left: 10px;
1254             }
1255             span#appname {
1256                 font-weight: bold;
1257                 font-size: 1.6em;
1258             }
1259         </style>
1260     </head>
1261     <body>
1262         <div id="content">
1263             <div id="topbar">
1264                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1265                     $VERSION</h1>
1266              </div>
1267              <div id="answers">
1268                  <p>
1269                  <img src="$logo" alt="Catalyst Logo" />
1270                  </p>
1271                  <p>Welcome to the  world of Catalyst.
1272                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1273                     framework will make web development something you had
1274                     never expected it to be: Fun, rewarding, and quick.</p>
1275                  <h2>What to do now?</h2>
1276                  <p>That really depends  on what <b>you</b> want to do.
1277                     We do, however, provide you with a few starting points.</p>
1278                  <p>If you want to jump right into web development with Catalyst
1279                     you might want to start with a tutorial.</p>
1280 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1281 </pre>
1282 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1283 <pre>
1284 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1285 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1286 </code></pre>
1287                  <h2>What to do next?</h2>
1288                  <p>Next it's time to write an actual application. Use the
1289                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1290                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1291                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1292                     they can save you a lot of work.</p>
1293                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1294                     <p>Also, be sure to check out the vast and growing
1295                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1296                     you are likely to find what you need there.
1297                     </p>
1298
1299                  <h2>Need help?</h2>
1300                  <p>Catalyst has a very active community. Here are the main places to
1301                     get in touch with us.</p>
1302                  <ul>
1303                      <li>
1304                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1305                      </li>
1306                      <li>
1307                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1308                      </li>
1309                      <li>
1310                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1311                      </li>
1312                  </ul>
1313                  <h2>In conclusion</h2>
1314                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1315                     as we enjoyed making it. Please contact us if you have ideas
1316                     for improvement or other feedback.</p>
1317              </div>
1318          </div>
1319     </body>
1320 </html>
1321 EOF
1322 }
1323
1324 =head1 INTERNAL METHODS
1325
1326 These methods are not meant to be used by end users.
1327
1328 =head2 $c->components
1329
1330 Returns a hash of components.
1331
1332 =head2 $c->context_class
1333
1334 Returns or sets the context class.
1335
1336 =head2 $c->counter
1337
1338 Returns a hashref containing coderefs and execution counts (needed for
1339 deep recursion detection).
1340
1341 =head2 $c->depth
1342
1343 Returns the number of actions on the current internal execution stack.
1344
1345 =head2 $c->dispatch
1346
1347 Dispatches a request to actions.
1348
1349 =cut
1350
1351 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1352
1353 =head2 $c->dispatcher_class
1354
1355 Returns or sets the dispatcher class.
1356
1357 =head2 $c->dump_these
1358
1359 Returns a list of 2-element array references (name, structure) pairs
1360 that will be dumped on the error page in debug mode.
1361
1362 =cut
1363
1364 sub dump_these {
1365     my $c = shift;
1366     [ Request => $c->req ],
1367     [ Response => $c->res ],
1368     [ Stash => $c->stash ],
1369     [ Config => $c->config ];
1370 }
1371
1372 =head2 $c->engine_class
1373
1374 Returns or sets the engine class.
1375
1376 =head2 $c->execute( $class, $coderef )
1377
1378 Execute a coderef in given class and catch exceptions. Errors are available
1379 via $c->error.
1380
1381 =cut
1382
1383 sub execute {
1384     my ( $c, $class, $code ) = @_;
1385     $class = $c->component($class) || $class;
1386     $c->state(0);
1387
1388     if ( $c->depth >= $RECURSION ) {
1389         my $action = $code->reverse();
1390         $action = "/$action" unless $action =~ /->/;
1391         my $error = qq/Deep recursion detected calling "${action}"/;
1392         $c->log->error($error);
1393         $c->error($error);
1394         $c->state(0);
1395         return $c->state;
1396     }
1397
1398     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1399
1400     push( @{ $c->stack }, $code );
1401
1402     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1403
1404     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1405
1406     my $last = pop( @{ $c->stack } );
1407
1408     if ( my $error = $@ ) {
1409         if ( !ref($error) and $error eq $DETACH ) {
1410             die $DETACH if($c->depth > 1);
1411         }
1412         elsif ( !ref($error) and $error eq $GO ) {
1413             die $GO if($c->depth > 0);
1414         }
1415         else {
1416             unless ( ref $error ) {
1417                 no warnings 'uninitialized';
1418                 chomp $error;
1419                 my $class = $last->class;
1420                 my $name  = $last->name;
1421                 $error = qq/Caught exception in $class->$name "$error"/;
1422             }
1423             $c->error($error);
1424             $c->state(0);
1425         }
1426     }
1427     return $c->state;
1428 }
1429
1430 sub _stats_start_execute {
1431     my ( $c, $code ) = @_;
1432
1433     return if ( ( $code->name =~ /^_.*/ )
1434         && ( !$c->config->{show_internal_actions} ) );
1435
1436     my $action_name = $code->reverse();
1437     $c->counter->{$action_name}++;
1438
1439     my $action = $action_name;
1440     $action = "/$action" unless $action =~ /->/;
1441
1442     # determine if the call was the result of a forward
1443     # this is done by walking up the call stack and looking for a calling
1444     # sub of Catalyst::forward before the eval
1445     my $callsub = q{};
1446     for my $index ( 2 .. 11 ) {
1447         last
1448         if ( ( caller($index) )[0] eq 'Catalyst'
1449             && ( caller($index) )[3] eq '(eval)' );
1450
1451         if ( ( caller($index) )[3] =~ /forward$/ ) {
1452             $callsub = ( caller($index) )[3];
1453             $action  = "-> $action";
1454             last;
1455         }
1456     }
1457
1458     my $uid = $action_name . $c->counter->{$action_name};
1459
1460     # is this a root-level call or a forwarded call?
1461     if ( $callsub =~ /forward$/ ) {
1462
1463         # forward, locate the caller
1464         if ( my $parent = $c->stack->[-1] ) {
1465             $c->stats->profile(
1466                 begin  => $action,
1467                 parent => "$parent" . $c->counter->{"$parent"},
1468                 uid    => $uid,
1469             );
1470         }
1471         else {
1472
1473             # forward with no caller may come from a plugin
1474             $c->stats->profile(
1475                 begin => $action,
1476                 uid   => $uid,
1477             );
1478         }
1479     }
1480     else {
1481
1482         # root-level call
1483         $c->stats->profile(
1484             begin => $action,
1485             uid   => $uid,
1486         );
1487     }
1488     return $action;
1489
1490 }
1491
1492 sub _stats_finish_execute {
1493     my ( $c, $info ) = @_;
1494     $c->stats->profile( end => $info );
1495 }
1496
1497 =head2 $c->_localize_fields( sub { }, \%keys );
1498
1499 =cut
1500
1501 #Why does this exist? This is no longer safe and WILL NOT WORK.
1502 # it doesnt seem to be used anywhere. can we remove it?
1503 sub _localize_fields {
1504     my ( $c, $localized, $code ) = ( @_ );
1505
1506     my $request = delete $localized->{request} || {};
1507     my $response = delete $localized->{response} || {};
1508
1509     local @{ $c }{ keys %$localized } = values %$localized;
1510     local @{ $c->request }{ keys %$request } = values %$request;
1511     local @{ $c->response }{ keys %$response } = values %$response;
1512
1513     $code->();
1514 }
1515
1516 =head2 $c->finalize
1517
1518 Finalizes the request.
1519
1520 =cut
1521
1522 sub finalize {
1523     my $c = shift;
1524
1525     for my $error ( @{ $c->error } ) {
1526         $c->log->error($error);
1527     }
1528
1529     # Allow engine to handle finalize flow (for POE)
1530     my $engine = $c->engine;
1531     if ( my $code = $engine->can('finalize') ) {
1532         $engine->$code($c);
1533     }
1534     else {
1535
1536         $c->finalize_uploads;
1537
1538         # Error
1539         if ( $#{ $c->error } >= 0 ) {
1540             $c->finalize_error;
1541         }
1542
1543         $c->finalize_headers;
1544
1545         # HEAD request
1546         if ( $c->request->method eq 'HEAD' ) {
1547             $c->response->body('');
1548         }
1549
1550         $c->finalize_body;
1551     }
1552
1553     if ($c->use_stats) {
1554         my $elapsed = sprintf '%f', $c->stats->elapsed;
1555         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1556         $c->log->info(
1557             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1558     }
1559
1560     return $c->response->status;
1561 }
1562
1563 =head2 $c->finalize_body
1564
1565 Finalizes body.
1566
1567 =cut
1568
1569 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1570
1571 =head2 $c->finalize_cookies
1572
1573 Finalizes cookies.
1574
1575 =cut
1576
1577 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1578
1579 =head2 $c->finalize_error
1580
1581 Finalizes error.
1582
1583 =cut
1584
1585 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1586
1587 =head2 $c->finalize_headers
1588
1589 Finalizes headers.
1590
1591 =cut
1592
1593 sub finalize_headers {
1594     my $c = shift;
1595
1596     my $response = $c->response; #accessor calls can add up?
1597
1598     # Check if we already finalized headers
1599     return if $response->finalized_headers;
1600
1601     # Handle redirects
1602     if ( my $location = $response->redirect ) {
1603         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1604         $response->header( Location => $location );
1605
1606         if ( !$response->has_body ) {
1607             # Add a default body if none is already present
1608             $response->body(
1609                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1610             );
1611         }
1612     }
1613
1614     # Content-Length
1615     if ( $response->body && !$response->content_length ) {
1616
1617         # get the length from a filehandle
1618         if ( blessed( $response->body ) && $response->body->can('read') )
1619         {
1620             my $stat = stat $response->body;
1621             if ( $stat && $stat->size > 0 ) {
1622                 $response->content_length( $stat->size );
1623             }
1624             else {
1625                 $c->log->warn('Serving filehandle without a content-length');
1626             }
1627         }
1628         else {
1629             # everything should be bytes at this point, but just in case
1630             $response->content_length( bytes::length( $response->body ) );
1631         }
1632     }
1633
1634     # Errors
1635     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1636         $response->headers->remove_header("Content-Length");
1637         $response->body('');
1638     }
1639
1640     $c->finalize_cookies;
1641
1642     $c->engine->finalize_headers( $c, @_ );
1643
1644     # Done
1645     $response->finalized_headers(1);
1646 }
1647
1648 =head2 $c->finalize_output
1649
1650 An alias for finalize_body.
1651
1652 =head2 $c->finalize_read
1653
1654 Finalizes the input after reading is complete.
1655
1656 =cut
1657
1658 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1659
1660 =head2 $c->finalize_uploads
1661
1662 Finalizes uploads. Cleans up any temporary files.
1663
1664 =cut
1665
1666 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1667
1668 =head2 $c->get_action( $action, $namespace )
1669
1670 Gets an action in a given namespace.
1671
1672 =cut
1673
1674 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1675
1676 =head2 $c->get_actions( $action, $namespace )
1677
1678 Gets all actions of a given name in a namespace and all parent
1679 namespaces.
1680
1681 =cut
1682
1683 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1684
1685 =head2 $c->handle_request( $class, @arguments )
1686
1687 Called to handle each HTTP request.
1688
1689 =cut
1690
1691 sub handle_request {
1692     my ( $class, @arguments ) = @_;
1693
1694     # Always expect worst case!
1695     my $status = -1;
1696     eval {
1697         if ($class->debug) {
1698             my $secs = time - $START || 1;
1699             my $av = sprintf '%.3f', $COUNT / $secs;
1700             my $time = localtime time;
1701             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1702         }
1703
1704         my $c = $class->prepare(@arguments);
1705         $c->dispatch;
1706         $status = $c->finalize;
1707     };
1708
1709     if ( my $error = $@ ) {
1710         chomp $error;
1711         $class->log->error(qq/Caught exception in engine "$error"/);
1712     }
1713
1714     $COUNT++;
1715
1716     if(my $coderef = $class->log->can('_flush')){
1717         $class->log->$coderef();
1718     }
1719     return $status;
1720 }
1721
1722 =head2 $c->prepare( @arguments )
1723
1724 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1725 etc.).
1726
1727 =cut
1728
1729 sub prepare {
1730     my ( $class, @arguments ) = @_;
1731
1732     # XXX
1733     # After the app/ctxt split, this should become an attribute based on something passed
1734     # into the application.
1735     $class->context_class( ref $class || $class ) unless $class->context_class;
1736
1737     my $c = $class->context_class->new({});
1738
1739     # For on-demand data
1740     $c->request->_context($c);
1741     $c->response->_context($c);
1742
1743     #surely this is not the most efficient way to do things...
1744     $c->stats($class->stats_class->new)->enable($c->use_stats);
1745     if ( $c->debug ) {
1746         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1747     }
1748
1749     #XXX reuse coderef from can
1750     # Allow engine to direct the prepare flow (for POE)
1751     if ( $c->engine->can('prepare') ) {
1752         $c->engine->prepare( $c, @arguments );
1753     }
1754     else {
1755         $c->prepare_request(@arguments);
1756         $c->prepare_connection;
1757         $c->prepare_query_parameters;
1758         $c->prepare_headers;
1759         $c->prepare_cookies;
1760         $c->prepare_path;
1761
1762         # Prepare the body for reading, either by prepare_body
1763         # or the user, if they are using $c->read
1764         $c->prepare_read;
1765
1766         # Parse the body unless the user wants it on-demand
1767         unless ( $c->config->{parse_on_demand} ) {
1768             $c->prepare_body;
1769         }
1770     }
1771
1772     my $method  = $c->req->method  || '';
1773     my $path    = $c->req->path;
1774     $path       = '/' unless length $path;
1775     my $address = $c->req->address || '';
1776
1777     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1778       if $c->debug;
1779
1780     $c->prepare_action;
1781
1782     return $c;
1783 }
1784
1785 =head2 $c->prepare_action
1786
1787 Prepares action. See L<Catalyst::Dispatcher>.
1788
1789 =cut
1790
1791 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1792
1793 =head2 $c->prepare_body
1794
1795 Prepares message body.
1796
1797 =cut
1798
1799 sub prepare_body {
1800     my $c = shift;
1801
1802     return if $c->request->_has_body;
1803
1804     # Initialize on-demand data
1805     $c->engine->prepare_body( $c, @_ );
1806     $c->prepare_parameters;
1807     $c->prepare_uploads;
1808
1809     if ( $c->debug ) {
1810         $c->log_parameters(
1811             'Body Parameters are', $c->request->body_parameters
1812         );
1813     }
1814 }
1815
1816 =head2 $c->prepare_body_chunk( $chunk )
1817
1818 Prepares a chunk of data before sending it to L<HTTP::Body>.
1819
1820 See L<Catalyst::Engine>.
1821
1822 =cut
1823
1824 sub prepare_body_chunk {
1825     my $c = shift;
1826     $c->engine->prepare_body_chunk( $c, @_ );
1827 }
1828
1829 =head2 $c->prepare_body_parameters
1830
1831 Prepares body parameters.
1832
1833 =cut
1834
1835 sub prepare_body_parameters {
1836     my $c = shift;
1837     $c->engine->prepare_body_parameters( $c, @_ );
1838 }
1839
1840 =head2 $c->prepare_connection
1841
1842 Prepares connection.
1843
1844 =cut
1845
1846 sub prepare_connection {
1847     my $c = shift;
1848     $c->engine->prepare_connection( $c, @_ );
1849 }
1850
1851 =head2 $c->prepare_cookies
1852
1853 Prepares cookies.
1854
1855 =cut
1856
1857 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1858
1859 =head2 $c->prepare_headers
1860
1861 Prepares headers.
1862
1863 =cut
1864
1865 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1866
1867 =head2 $c->prepare_parameters
1868
1869 Prepares parameters.
1870
1871 =cut
1872
1873 sub prepare_parameters {
1874     my $c = shift;
1875     $c->prepare_body_parameters;
1876     $c->engine->prepare_parameters( $c, @_ );
1877 }
1878
1879 =head2 $c->prepare_path
1880
1881 Prepares path and base.
1882
1883 =cut
1884
1885 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1886
1887 =head2 $c->prepare_query_parameters
1888
1889 Prepares query parameters.
1890
1891 =cut
1892
1893 sub prepare_query_parameters {
1894     my $c = shift;
1895
1896     $c->engine->prepare_query_parameters( $c, @_ );
1897
1898     if ( $c->debug ) {
1899         $c->log_parameters(
1900             'Query Parameters are', $c->request->query_parameters
1901         );
1902     }
1903 }
1904
1905 =head2 $c->log_parameters($name, $parameters)
1906
1907 Logs a hash reference of key value pairs, with a caption above the table.
1908
1909 Looks like:
1910
1911  [debug] Query Parameters are:
1912  .-------------------------------------+--------------------------------------.
1913  | Parameter                           | Value                                |
1914  +-------------------------------------+--------------------------------------+
1915  | search                              | Moose                                |
1916  | searchtype                          | modules                              |
1917  '-------------------------------------+--------------------------------------'
1918
1919 If there are query parameters you don't want to display in this output, such
1920 as passwords or other sensitive input, you can configure your application to
1921 redact those parameters:
1922
1923   C<< MyApp->config->{Debug}->{redact_parameters} = [ 'password' ] >>
1924
1925 In that case, the output will look like:
1926
1927  [debug] Query Parameters are:
1928  .-------------------------------------+--------------------------------------.
1929  | Parameter                           | Value                                |
1930  +-------------------------------------+--------------------------------------+
1931  | password                            | (redacted by config)                 |
1932  | username                            | some_user                            |
1933  '-------------------------------------+--------------------------------------'
1934
1935 =cut
1936
1937 sub log_parameters {
1938     my ( $c, $name, $parameters ) = @_;
1939
1940     my $skip = $c->config->{Debug}->{redact_parameters};
1941     if (
1942         ( not defined $skip or ref $skip eq 'ARRAY' )
1943         && keys %{ $parameters }
1944      ) {
1945         my $t = Text::SimpleTable->new(
1946             [ 35, 'Parameter' ], [ 36, 'Value' ] );
1947         my %skip_params = map { $_ => $_ } @{ $skip || [] };
1948         for my $key ( sort keys %$parameters ) {
1949             my $param = $parameters->{$key};
1950             my $value = defined($param) ? $param : '';
1951             $value = '(redacted by config)' if exists $skip_params{$key};
1952
1953             $t->row( $key,
1954                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1955         }
1956         $c->log->debug( "$name:\n" . $t->draw );
1957     }
1958 }
1959
1960 =head2 $c->prepare_read
1961
1962 Prepares the input for reading.
1963
1964 =cut
1965
1966 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1967
1968 =head2 $c->prepare_request
1969
1970 Prepares the engine request.
1971
1972 =cut
1973
1974 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1975
1976 =head2 $c->prepare_uploads
1977
1978 Prepares uploads.
1979
1980 =cut
1981
1982 sub prepare_uploads {
1983     my $c = shift;
1984
1985     $c->engine->prepare_uploads( $c, @_ );
1986
1987     if ( $c->debug && keys %{ $c->request->uploads } ) {
1988         my $t = Text::SimpleTable->new(
1989             [ 12, 'Parameter' ],
1990             [ 26, 'Filename' ],
1991             [ 18, 'Type' ],
1992             [ 9,  'Size' ]
1993         );
1994         for my $key ( sort keys %{ $c->request->uploads } ) {
1995             my $upload = $c->request->uploads->{$key};
1996             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1997                 $t->row( $key, $u->filename, $u->type, $u->size );
1998             }
1999         }
2000         $c->log->debug( "File Uploads are:\n" . $t->draw );
2001     }
2002 }
2003
2004 =head2 $c->prepare_write
2005
2006 Prepares the output for writing.
2007
2008 =cut
2009
2010 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2011
2012 =head2 $c->request_class
2013
2014 Returns or sets the request class.
2015
2016 =head2 $c->response_class
2017
2018 Returns or sets the response class.
2019
2020 =head2 $c->read( [$maxlength] )
2021
2022 Reads a chunk of data from the request body. This method is designed to
2023 be used in a while loop, reading C<$maxlength> bytes on every call.
2024 C<$maxlength> defaults to the size of the request if not specified.
2025
2026 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
2027 directly.
2028
2029 Warning: If you use read(), Catalyst will not process the body,
2030 so you will not be able to access POST parameters or file uploads via
2031 $c->request.  You must handle all body parsing yourself.
2032
2033 =cut
2034
2035 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2036
2037 =head2 $c->run
2038
2039 Starts the engine.
2040
2041 =cut
2042
2043 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2044
2045 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2046
2047 Sets an action in a given namespace.
2048
2049 =cut
2050
2051 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2052
2053 =head2 $c->setup_actions($component)
2054
2055 Sets up actions for a component.
2056
2057 =cut
2058
2059 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2060
2061 =head2 $c->setup_components
2062
2063 Sets up components. Specify a C<setup_components> config option to pass
2064 additional options directly to L<Module::Pluggable>. To add additional
2065 search paths, specify a key named C<search_extra> as an array
2066 reference. Items in the array beginning with C<::> will have the
2067 application class name prepended to them.
2068
2069 All components found will also have any
2070 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2071 Note, that modules which are B<not> an I<inner package> of the main
2072 file namespace loaded will not be instantiated as components.
2073
2074 =cut
2075
2076 sub setup_components {
2077     my $class = shift;
2078
2079     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2080     my $config  = $class->config->{ setup_components };
2081     my $extra   = delete $config->{ search_extra } || [];
2082
2083     push @paths, @$extra;
2084
2085     my $locator = Module::Pluggable::Object->new(
2086         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2087         %$config
2088     );
2089
2090     my @comps = sort { length $a <=> length $b } $locator->plugins;
2091     my %comps = map { $_ => 1 } @comps;
2092
2093     for my $component ( @comps ) {
2094
2095         # We pass ignore_loaded here so that overlay files for (e.g.)
2096         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2097         # we know M::P::O found a file on disk so this is safe
2098
2099         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2100         #Class::MOP::load_class($component);
2101
2102         my $module  = $class->setup_component( $component );
2103         my %modules = (
2104             $component => $module,
2105             map {
2106                 $_ => $class->setup_component( $_ )
2107             } grep {
2108               not exists $comps{$_}
2109             } Devel::InnerPackage::list_packages( $component )
2110         );
2111
2112         for my $key ( keys %modules ) {
2113             $class->components->{ $key } = $modules{ $key };
2114         }
2115     }
2116 }
2117
2118 =head2 $c->setup_component
2119
2120 =cut
2121
2122 sub setup_component {
2123     my( $class, $component ) = @_;
2124
2125     unless ( $component->can( 'COMPONENT' ) ) {
2126         return $component;
2127     }
2128
2129     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2130     my $config = $class->config->{ $suffix } || {};
2131
2132     my $instance = eval { $component->COMPONENT( $class, $config ); };
2133
2134     if ( my $error = $@ ) {
2135         chomp $error;
2136         Catalyst::Exception->throw(
2137             message => qq/Couldn't instantiate component "$component", "$error"/
2138         );
2139     }
2140
2141     Catalyst::Exception->throw(
2142         message =>
2143         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2144     ) unless blessed($instance);
2145
2146     return $instance;
2147 }
2148
2149 =head2 $c->setup_dispatcher
2150
2151 Sets up dispatcher.
2152
2153 =cut
2154
2155 sub setup_dispatcher {
2156     my ( $class, $dispatcher ) = @_;
2157
2158     if ($dispatcher) {
2159         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2160     }
2161
2162     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2163         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2164     }
2165
2166     unless ($dispatcher) {
2167         $dispatcher = $class->dispatcher_class;
2168     }
2169
2170     Class::MOP::load_class($dispatcher);
2171
2172     # dispatcher instance
2173     $class->dispatcher( $dispatcher->new );
2174 }
2175
2176 =head2 $c->setup_engine
2177
2178 Sets up engine.
2179
2180 =cut
2181
2182 sub setup_engine {
2183     my ( $class, $engine ) = @_;
2184
2185     if ($engine) {
2186         $engine = 'Catalyst::Engine::' . $engine;
2187     }
2188
2189     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2190         $engine = 'Catalyst::Engine::' . $env;
2191     }
2192
2193     if ( $ENV{MOD_PERL} ) {
2194         my $meta = Class::MOP::get_metaclass_by_name($class);
2195
2196         # create the apache method
2197         $meta->add_method('apache' => sub { shift->engine->apache });
2198
2199         my ( $software, $version ) =
2200           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2201
2202         $version =~ s/_//g;
2203         $version =~ s/(\.[^.]+)\./$1/g;
2204
2205         if ( $software eq 'mod_perl' ) {
2206
2207             if ( !$engine ) {
2208
2209                 if ( $version >= 1.99922 ) {
2210                     $engine = 'Catalyst::Engine::Apache2::MP20';
2211                 }
2212
2213                 elsif ( $version >= 1.9901 ) {
2214                     $engine = 'Catalyst::Engine::Apache2::MP19';
2215                 }
2216
2217                 elsif ( $version >= 1.24 ) {
2218                     $engine = 'Catalyst::Engine::Apache::MP13';
2219                 }
2220
2221                 else {
2222                     Catalyst::Exception->throw( message =>
2223                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2224                 }
2225
2226             }
2227
2228             # install the correct mod_perl handler
2229             if ( $version >= 1.9901 ) {
2230                 *handler = sub  : method {
2231                     shift->handle_request(@_);
2232                 };
2233             }
2234             else {
2235                 *handler = sub ($$) { shift->handle_request(@_) };
2236             }
2237
2238         }
2239
2240         elsif ( $software eq 'Zeus-Perl' ) {
2241             $engine = 'Catalyst::Engine::Zeus';
2242         }
2243
2244         else {
2245             Catalyst::Exception->throw(
2246                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2247         }
2248     }
2249
2250     unless ($engine) {
2251         $engine = $class->engine_class;
2252     }
2253
2254     Class::MOP::load_class($engine);
2255
2256     # check for old engines that are no longer compatible
2257     my $old_engine;
2258     if ( $engine->isa('Catalyst::Engine::Apache')
2259         && !Catalyst::Engine::Apache->VERSION )
2260     {
2261         $old_engine = 1;
2262     }
2263
2264     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2265         && Catalyst::Engine::Server->VERSION le '0.02' )
2266     {
2267         $old_engine = 1;
2268     }
2269
2270     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2271         && $engine->VERSION eq '0.01' )
2272     {
2273         $old_engine = 1;
2274     }
2275
2276     elsif ($engine->isa('Catalyst::Engine::Zeus')
2277         && $engine->VERSION eq '0.01' )
2278     {
2279         $old_engine = 1;
2280     }
2281
2282     if ($old_engine) {
2283         Catalyst::Exception->throw( message =>
2284               qq/Engine "$engine" is not supported by this version of Catalyst/
2285         );
2286     }
2287
2288     # engine instance
2289     $class->engine( $engine->new );
2290 }
2291
2292 =head2 $c->setup_home
2293
2294 Sets up the home directory.
2295
2296 =cut
2297
2298 sub setup_home {
2299     my ( $class, $home ) = @_;
2300
2301     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2302         $home = $env;
2303     }
2304
2305     $home ||= Catalyst::Utils::home($class);
2306
2307     if ($home) {
2308         #I remember recently being scolded for assigning config values like this
2309         $class->config->{home} ||= $home;
2310         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2311     }
2312 }
2313
2314 =head2 $c->setup_log
2315
2316 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2317 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2318 log to.
2319
2320 This method also installs a C<debug> method that returns a true value into the
2321 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2322 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2323
2324 Note that if the log has already been setup, by either a previous call to
2325 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2326 that this method won't actually set up the log object.
2327
2328 =cut
2329
2330 sub setup_log {
2331     my ( $class, $levels ) = @_;
2332
2333     $levels ||= '';
2334     $levels =~ s/^\s+//;
2335     $levels =~ s/\s+$//;
2336     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels || '';
2337
2338     unless ( $class->log ) {
2339         $class->log( Catalyst::Log->new(keys %levels) );
2340     }
2341
2342     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2343     if ( defined($env_debug) or $levels{debug} ) {
2344         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2345         $class->log->debug('Debug messages enabled');
2346     }
2347 }
2348
2349 =head2 $c->setup_plugins
2350
2351 Sets up plugins.
2352
2353 =cut
2354
2355 =head2 $c->setup_stats
2356
2357 Sets up timing statistics class.
2358
2359 =cut
2360
2361 sub setup_stats {
2362     my ( $class, $stats ) = @_;
2363
2364     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2365
2366     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2367     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2368         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2369         $class->log->debug('Statistics enabled');
2370     }
2371 }
2372
2373
2374 =head2 $c->registered_plugins
2375
2376 Returns a sorted list of the plugins which have either been stated in the
2377 import list or which have been added via C<< MyApp->plugin(@args); >>.
2378
2379 If passed a given plugin name, it will report a boolean value indicating
2380 whether or not that plugin is loaded.  A fully qualified name is required if
2381 the plugin name does not begin with C<Catalyst::Plugin::>.
2382
2383  if ($c->registered_plugins('Some::Plugin')) {
2384      ...
2385  }
2386
2387 =cut
2388
2389 {
2390
2391     sub registered_plugins {
2392         my $proto = shift;
2393         return sort keys %{ $proto->_plugins } unless @_;
2394         my $plugin = shift;
2395         return 1 if exists $proto->_plugins->{$plugin};
2396         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2397     }
2398
2399     sub _register_plugin {
2400         my ( $proto, $plugin, $instant ) = @_;
2401         my $class = ref $proto || $proto;
2402
2403         # no ignore_loaded here, the plugin may already have been
2404         # defined in memory and we don't want to error on "no file" if so
2405
2406         Class::MOP::load_class( $plugin );
2407
2408         $proto->_plugins->{$plugin} = 1;
2409         unless ($instant) {
2410             no strict 'refs';
2411             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2412               my @superclasses = ($plugin, $meta->superclasses );
2413               $meta->superclasses(@superclasses);
2414             } else {
2415               unshift @{"$class\::ISA"}, $plugin;
2416             }
2417         }
2418         return $class;
2419     }
2420
2421     sub setup_plugins {
2422         my ( $class, $plugins ) = @_;
2423
2424         $class->_plugins( {} ) unless $class->_plugins;
2425         $plugins ||= [];
2426         for my $plugin ( reverse @$plugins ) {
2427
2428             unless ( $plugin =~ s/\A\+// ) {
2429                 $plugin = "Catalyst::Plugin::$plugin";
2430             }
2431
2432             $class->_register_plugin($plugin);
2433         }
2434     }
2435 }
2436
2437 =head2 $c->stack
2438
2439 Returns an arrayref of the internal execution stack (actions that are
2440 currently executing).
2441
2442 =head2 $c->stats_class
2443
2444 Returns or sets the stats (timing statistics) class.
2445
2446 =head2 $c->use_stats
2447
2448 Returns 1 when stats collection is enabled.  Stats collection is enabled
2449 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2450 environment variable is set.
2451
2452 Note that this is a static method, not an accessor and should be overloaded
2453 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2454
2455 =cut
2456
2457 sub use_stats { 0 }
2458
2459
2460 =head2 $c->write( $data )
2461
2462 Writes $data to the output stream. When using this method directly, you
2463 will need to manually set the C<Content-Length> header to the length of
2464 your output data, if known.
2465
2466 =cut
2467
2468 sub write {
2469     my $c = shift;
2470
2471     # Finalize headers if someone manually writes output
2472     $c->finalize_headers;
2473
2474     return $c->engine->write( $c, @_ );
2475 }
2476
2477 =head2 version
2478
2479 Returns the Catalyst version number. Mostly useful for "powered by"
2480 messages in template systems.
2481
2482 =cut
2483
2484 sub version { return $Catalyst::VERSION }
2485
2486 =head1 INTERNAL ACTIONS
2487
2488 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2489 C<_ACTION>, and C<_END>. These are by default not shown in the private
2490 action table, but you can make them visible with a config parameter.
2491
2492     MyApp->config->{show_internal_actions} = 1;
2493
2494 =head1 CASE SENSITIVITY
2495
2496 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2497 mapped to C</foo/bar>. You can activate case sensitivity with a config
2498 parameter.
2499
2500     MyApp->config->{case_sensitive} = 1;
2501
2502 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2503
2504 =head1 ON-DEMAND PARSER
2505
2506 The request body is usually parsed at the beginning of a request,
2507 but if you want to handle input yourself, you can enable on-demand
2508 parsing with a config parameter.
2509
2510     MyApp->config->{parse_on_demand} = 1;
2511
2512 =head1 PROXY SUPPORT
2513
2514 Many production servers operate using the common double-server approach,
2515 with a lightweight frontend web server passing requests to a larger
2516 backend server. An application running on the backend server must deal
2517 with two problems: the remote user always appears to be C<127.0.0.1> and
2518 the server's hostname will appear to be C<localhost> regardless of the
2519 virtual host that the user connected through.
2520
2521 Catalyst will automatically detect this situation when you are running
2522 the frontend and backend servers on the same machine. The following
2523 changes are made to the request.
2524
2525     $c->req->address is set to the user's real IP address, as read from
2526     the HTTP X-Forwarded-For header.
2527
2528     The host value for $c->req->base and $c->req->uri is set to the real
2529     host, as read from the HTTP X-Forwarded-Host header.
2530
2531 Obviously, your web server must support these headers for this to work.
2532
2533 In a more complex server farm environment where you may have your
2534 frontend proxy server(s) on different machines, you will need to set a
2535 configuration option to tell Catalyst to read the proxied data from the
2536 headers.
2537
2538     MyApp->config->{using_frontend_proxy} = 1;
2539
2540 If you do not wish to use the proxy support at all, you may set:
2541
2542     MyApp->config->{ignore_frontend_proxy} = 1;
2543
2544 =head1 THREAD SAFETY
2545
2546 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2547 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2548 believe the Catalyst core to be thread-safe.
2549
2550 If you plan to operate in a threaded environment, remember that all other
2551 modules you are using must also be thread-safe. Some modules, most notably
2552 L<DBD::SQLite>, are not thread-safe.
2553
2554 =head1 SUPPORT
2555
2556 IRC:
2557
2558     Join #catalyst on irc.perl.org.
2559
2560 Mailing Lists:
2561
2562     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2563     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2564
2565 Web:
2566
2567     http://catalyst.perl.org
2568
2569 Wiki:
2570
2571     http://dev.catalyst.perl.org
2572
2573 =head1 SEE ALSO
2574
2575 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2576
2577 =head2 L<Catalyst::Manual> - The Catalyst Manual
2578
2579 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2580
2581 =head2 L<Catalyst::Engine> - Core engine
2582
2583 =head2 L<Catalyst::Log> - Log class.
2584
2585 =head2 L<Catalyst::Request> - Request object
2586
2587 =head2 L<Catalyst::Response> - Response object
2588
2589 =head2 L<Catalyst::Test> - The test suite.
2590
2591 =head1 PROJECT FOUNDER
2592
2593 sri: Sebastian Riedel <sri@cpan.org>
2594
2595 =head1 CONTRIBUTORS
2596
2597 abw: Andy Wardley
2598
2599 acme: Leon Brocard <leon@astray.com>
2600
2601 Andrew Bramble
2602
2603 Andrew Ford
2604
2605 Andrew Ruthven
2606
2607 andyg: Andy Grundman <andy@hybridized.org>
2608
2609 audreyt: Audrey Tang
2610
2611 bricas: Brian Cassidy <bricas@cpan.org>
2612
2613 Byron Young <Byron.Young@riverbed.com>
2614
2615 Caelum: Rafael Kitover <rkitover@io.com>
2616
2617 chansen: Christian Hansen
2618
2619 chicks: Christopher Hicks
2620
2621 David E. Wheeler
2622
2623 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2624
2625 Drew Taylor
2626
2627 esskar: Sascha Kiefer
2628
2629 fireartist: Carl Franks <cfranks@cpan.org>
2630
2631 gabb: Danijel Milicevic
2632
2633 Gary Ashton Jones
2634
2635 Geoff Richards
2636
2637 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2638
2639 jcamacho: Juan Camacho
2640
2641 jhannah: Jay Hannah <jay@jays.net>
2642
2643 Jody Belka
2644
2645 Johan Lindstrom
2646
2647 jon: Jon Schutz <jjschutz@cpan.org>
2648
2649 marcus: Marcus Ramberg <mramberg@cpan.org>
2650
2651 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2652
2653 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2654
2655 mugwump: Sam Vilain
2656
2657 naughton: David Naughton
2658
2659 ningu: David Kamholz <dkamholz@cpan.org>
2660
2661 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2662
2663 numa: Dan Sully <daniel@cpan.org>
2664
2665 obra: Jesse Vincent
2666
2667 omega: Andreas Marienborg
2668
2669 Oleg Kostyuk <cub.uanic@gmail.com>
2670
2671 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2672
2673 rafl: Florian Ragwitz <rafl@debian.org>
2674
2675 sky: Arthur Bergman
2676
2677 the_jester: Jesse Sheidlower
2678
2679 t0m: Tomas Doran <bobtfish@bobtfish.net>
2680
2681 Ulf Edvinsson
2682
2683 willert: Sebastian Willert <willert@cpan.org>
2684
2685 =head1 LICENSE
2686
2687 This library is free software, you can redistribute it and/or modify it under
2688 the same terms as Perl itself.
2689
2690 =cut
2691
2692 no Moose;
2693
2694 __PACKAGE__->meta->make_immutable;
2695
2696 1;