lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken blessed/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp shortmess/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 __PACKAGE__->mk_accessors(
  34     qw/counter request response state action stack namespace stats/
  35 );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52 our $GO        = "catalyst_go\n";
  53
  54 __PACKAGE__->mk_classdata($_)
  55   for qw/components arguments dispatcher engine log dispatcher_class
  56   engine_class context_class request_class response_class stats_class
  57   setup_finished/;
  58
  59 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  60 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  61 __PACKAGE__->request_class('Catalyst::Request');
  62 __PACKAGE__->response_class('Catalyst::Response');
  63 __PACKAGE__->stats_class('Catalyst::Stats');
  64
  65 # Remember to update this in Catalyst::Runtime as well!
  66
  67 our $VERSION = '5.71000';
  68
  69 sub import {
  70     my ( $class, @arguments ) = @_;
  71
  72     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  73     # callers @ISA.
  74     return unless $class eq 'Catalyst';
  75
  76     my $caller = caller(0);
  77
  78     unless ( $caller->isa('Catalyst') ) {
  79         no strict 'refs';
  80         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  81     }
  82
  83     $caller->arguments( [@arguments] );
  84     $caller->setup_home;
  85 }
  86
  87 =head1 NAME
  88
  89 Catalyst - The Elegant MVC Web Application Framework
  90
  91 =head1 SYNOPSIS
  92
  93 See the L<Catalyst::Manual> distribution for comprehensive
  94 documentation and tutorials.
  95
  96     # Install Catalyst::Devel for helpers and other development tools
  97     # use the helper to create a new application
  98     catalyst.pl MyApp
  99
 100     # add models, views, controllers
 101     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 102     script/myapp_create.pl view MyTemplate TT
 103     script/myapp_create.pl controller Search
 104
 105     # built in testserver -- use -r to restart automatically on changes
 106     # --help to see all available options
 107     script/myapp_server.pl
 108
 109     # command line testing interface
 110     script/myapp_test.pl /yada
 111
 112     ### in lib/MyApp.pm
 113     use Catalyst qw/-Debug/; # include plugins here as well
 114
 115     ### In lib/MyApp/Controller/Root.pm (autocreated)
 116     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 117         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 118         $c->stash->{template} = 'foo.tt'; # set the template
 119         # lookup something from db -- stash vars are passed to TT
 120         $c->stash->{data} =
 121           $c->model('Database::Foo')->search( { country => $args[0] } );
 122         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 123             $c->forward( 'bar' ); # process another action
 124             # do something else after forward returns
 125         }
 126     }
 127
 128     # The foo.tt TT template can use the stash data from the database
 129     [% WHILE (item = data.next) %]
 130         [% item.foo %]
 131     [% END %]
 132
 133     # called for /bar/of/soap, /bar/of/soap/10, etc.
 134     sub bar : Path('/bar/of/soap') { ... }
 135
 136     # called for all actions, from the top-most controller downwards
 137     sub auto : Private {
 138         my ( $self, $c ) = @_;
 139         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 140             $c->res->redirect( '/login' ); # require login
 141             return 0; # abort request and go immediately to end()
 142         }
 143         return 1; # success; carry on to next action
 144     }
 145
 146     # called after all actions are finished
 147     sub end : Private {
 148         my ( $self, $c ) = @_;
 149         if ( scalar @{ $c->error } ) { ... } # handle errors
 150         return if $c->res->body; # already have a response
 151         $c->forward( 'MyApp::View::TT' ); # render template
 152     }
 153
 154     ### in MyApp/Controller/Foo.pm
 155     # called for /foo/bar
 156     sub bar : Local { ... }
 157
 158     # called for /blargle
 159     sub blargle : Global { ... }
 160
 161     # an index action matches /foo, but not /foo/1, etc.
 162     sub index : Private { ... }
 163
 164     ### in MyApp/Controller/Foo/Bar.pm
 165     # called for /foo/bar/baz
 166     sub baz : Local { ... }
 167
 168     # first Root auto is called, then Foo auto, then this
 169     sub auto : Private { ... }
 170
 171     # powerful regular expression paths are also possible
 172     sub details : Regex('^product/(\w+)/details$') {
 173         my ( $self, $c ) = @_;
 174         # extract the (\w+) from the URI
 175         my $product = $c->req->captures->[0];
 176     }
 177
 178 See L<Catalyst::Manual::Intro> for additional information.
 179
 180 =head1 DESCRIPTION
 181
 182 Catalyst is a modern framework for making web applications without the
 183 pain usually associated with this process. This document is a reference
 184 to the main Catalyst application. If you are a new user, we suggest you
 185 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 186
 187 See L<Catalyst::Manual> for more documentation.
 188
 189 Catalyst plugins can be loaded by naming them as arguments to the "use
 190 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 191 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 192 C<My::Module>.
 193
 194     use Catalyst qw/My::Module/;
 195
 196 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 197 fully qualify the name by using a unary plus:
 198
 199     use Catalyst qw/
 200         My::Module
 201         +Fully::Qualified::Plugin::Name
 202     /;
 203
 204 Special flags like C<-Debug> and C<-Engine> can also be specified as
 205 arguments when Catalyst is loaded:
 206
 207     use Catalyst qw/-Debug My::Module/;
 208
 209 The position of plugins and flags in the chain is important, because
 210 they are loaded in the order in which they appear.
 211
 212 The following flags are supported:
 213
 214 =head2 -Debug
 215
 216 Enables debug output. You can also force this setting from the system
 217 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 218 settings override the application, with <MYAPP>_DEBUG having the highest
 219 priority.
 220
 221 =head2 -Engine
 222
 223 Forces Catalyst to use a specific engine. Omit the
 224 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 225
 226     use Catalyst qw/-Engine=CGI/;
 227
 228 =head2 -Home
 229
 230 Forces Catalyst to use a specific home directory, e.g.:
 231
 232     use Catalyst qw[-Home=/usr/mst];
 233
 234 This can also be done in the shell environment by setting either the
 235 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 236 is replaced with the uppercased name of your application, any "::" in
 237 the name will be replaced with underscores, e.g. MyApp::Web should use
 238 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 239
 240 =head2 -Log
 241
 242 Specifies log level.
 243
 244 =head2 -Stats
 245
 246 Enables statistics collection and reporting. You can also force this setting
 247 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 248 environment settings override the application, with <MYAPP>_STATS having the
 249 highest priority.
 250
 251 e.g.
 252
 253    use Catalyst qw/-Stats=1/
 254
 255 =head1 METHODS
 256
 257 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 258
 259 =head2 $c->action
 260
 261 Returns a L<Catalyst::Action> object for the current action, which
 262 stringifies to the action name. See L<Catalyst::Action>.
 263
 264 =head2 $c->namespace
 265
 266 Returns the namespace of the current action, i.e., the URI prefix
 267 corresponding to the controller of the current action. For example:
 268
 269     # in Controller::Foo::Bar
 270     $c->namespace; # returns 'foo/bar';
 271
 272 =head2 $c->request
 273
 274 =head2 $c->req
 275
 276 Returns the current L<Catalyst::Request> object, giving access to
 277 information about the current client request (including parameters,
 278 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 279
 280 =head2 REQUEST FLOW HANDLING
 281
 282 =head2 $c->forward( $action [, \@arguments ] )
 283
 284 =head2 $c->forward( $class, $method, [, \@arguments ] )
 285
 286 Forwards processing to another action, by its private name. If you give a
 287 class name but no method, C<process()> is called. You may also optionally
 288 pass arguments in an arrayref. The action will receive the arguments in
 289 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 290 C<< $c->req->args >> will be restored to the previous values.
 291
 292 Any data C<return>ed from the action forwarded to, will be returned by the
 293 call to forward.
 294
 295     my $foodata = $c->forward('/foo');
 296     $c->forward('index');
 297     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 298     $c->forward('MyApp::View::TT');
 299
 300 Note that forward implies an C<<eval { }>> around the call (actually
 301 C<execute> does), thus de-fatalizing all 'dies' within the called
 302 action. If you want C<die> to propagate you need to do something like:
 303
 304     $c->forward('foo');
 305     die $c->error if $c->error;
 306
 307 Or make sure to always return true values from your actions and write
 308 your code like this:
 309
 310     $c->forward('foo') || return;
 311
 312 =cut
 313
 314 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 315
 316 =head2 $c->detach( $action [, \@arguments ] )
 317
 318 =head2 $c->detach( $class, $method, [, \@arguments ] )
 319
 320 =head2 $c->detach()
 321
 322 The same as C<forward>, but doesn't return to the previous action when
 323 processing is finished.
 324
 325 When called with no arguments it escapes the processing chain entirely.
 326
 327 =cut
 328
 329 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 330
 331 =head2 $c->visit( $action [, \@arguments ] )
 332
 333 =head2 $c->visit( $class, $method, [, \@arguments ] )
 334
 335 Almost the same as C<forward>, but does a full dispatch, instead of just
 336 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 337 C<auto> and the method you go to are called, just like a new request.
 338
 339 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 340 This means, for example, that $c->action methods such as C<name>, C<class> and
 341 C<reverse> return information for the visited action when they are invoked
 342 within the visited action.  This is different from the behavior of C<forward>
 343 which continues to use the $c->action object from the caller action even when
 344 invoked from the callee.
 345
 346 C<$c-E<gt>stash> is kept unchanged.
 347
 348 In effect, C<visit> allows you to "wrap" another action, just as it
 349 would have been called by dispatching from a URL, while the analogous
 350 C<go> allows you to transfer control to another action as if it had
 351 been reached directly from a URL.
 352
 353 =cut
 354
 355 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 356
 357 =head2 $c->go( $action [, \@arguments ] )
 358
 359 =head2 $c->go( $class, $method, [, \@arguments ] )
 360
 361 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 362 instead of just calling the new C<$action> /
 363 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 364 method you visit are called, just like a new request.
 365
 366 C<$c-E<gt>stash> is kept unchanged.
 367
 368 =cut
 369
 370 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 371
 372 =head2 $c->response
 373
 374 =head2 $c->res
 375
 376 Returns the current L<Catalyst::Response> object, see there for details.
 377
 378 =head2 $c->stash
 379
 380 Returns a hashref to the stash, which may be used to store data and pass
 381 it between components during a request. You can also set hash keys by
 382 passing arguments. The stash is automatically sent to the view. The
 383 stash is cleared at the end of a request; it cannot be used for
 384 persistent storage (for this you must use a session; see
 385 L<Catalyst::Plugin::Session> for a complete system integrated with
 386 Catalyst).
 387
 388     $c->stash->{foo} = $bar;
 389     $c->stash( { moose => 'majestic', qux => 0 } );
 390     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 391
 392     # stash is automatically passed to the view for use in a template
 393     $c->forward( 'MyApp::View::TT' );
 394
 395 =cut
 396
 397 sub stash {
 398     my $c = shift;
 399     if (@_) {
 400         my $stash = @_ > 1 ? {@_} : $_[0];
 401         croak('stash takes a hash or hashref') unless ref $stash;
 402         foreach my $key ( keys %$stash ) {
 403             $c->{stash}->{$key} = $stash->{$key};
 404         }
 405     }
 406     return $c->{stash};
 407 }
 408
 409 =head2 $c->error
 410
 411 =head2 $c->error($error, ...)
 412
 413 =head2 $c->error($arrayref)
 414
 415 Returns an arrayref containing error messages.  If Catalyst encounters an
 416 error while processing a request, it stores the error in $c->error.  This
 417 method should only be used to store fatal error messages.
 418
 419     my @error = @{ $c->error };
 420
 421 Add a new error.
 422
 423     $c->error('Something bad happened');
 424
 425 =cut
 426
 427 sub error {
 428     my $c = shift;
 429     if ( $_[0] ) {
 430         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 431         croak @$error unless ref $c;
 432         push @{ $c->{error} }, @$error;
 433     }
 434     elsif ( defined $_[0] ) { $c->{error} = undef }
 435     return $c->{error} || [];
 436 }
 437
 438
 439 =head2 $c->state
 440
 441 Contains the return value of the last executed action.
 442
 443 =head2 $c->clear_errors
 444
 445 Clear errors.  You probably don't want to clear the errors unless you are
 446 implementing a custom error screen.
 447
 448 This is equivalent to running
 449
 450     $c->error(0);
 451
 452 =cut
 453
 454 sub clear_errors {
 455     my $c = shift;
 456     $c->error(0);
 457 }
 458
 459 # search components given a name and some prefixes
 460 sub _comp_search_prefixes {
 461     my ( $c, $name, @prefixes ) = @_;
 462     my $appclass = ref $c || $c;
 463     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 464
 465     # map the original component name to the sub part that we will search against
 466     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 467         grep { /$filter/ } keys %{ $c->components };
 468
 469     # undef for a name will return all
 470     return keys %eligible if !defined $name;
 471
 472     my $query  = ref $name ? $name : qr/^$name$/i;
 473     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 474
 475     return map { $c->components->{ $_ } } @result if @result;
 476
 477     # if we were given a regexp to search against, we're done.
 478     return if ref $name;
 479
 480     # regexp fallback
 481     $query  = qr/$name/i;
 482     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 483
 484     # no results? try against full names
 485     if( !@result ) {
 486         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 487     }
 488
 489     # don't warn if we didn't find any results, it just might not exist
 490     if( @result ) {
 491         my $msg = "Used regexp fallback for \$c->model('${name}'), which found '" .
 492            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 493            "component resolution is unreliable and unsafe.";
 494         my $short = $result[0];
 495         $short =~ s/.*?Model:://;
 496         my $shortmess = Carp::shortmess('');
 497         if ($shortmess =~ m#Catalyst/Plugin#) {
 498            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 499               "plugin's config";
 500         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 501            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 502               "component's config";
 503         } else {
 504            $msg .= " You probably meant \$c->model('$short') instead of \$c->model{'${name}'}, " .
 505               "but if you really wanted to search, pass in a regexp as the argument " .
 506               "like so: \$c->model(qr/${name}/)";
 507         }
 508         $c->log->warn( "${msg}$shortmess" );
 509     }
 510
 511     return @result;
 512 }
 513
 514 # Find possible names for a prefix
 515 sub _comp_names {
 516     my ( $c, @prefixes ) = @_;
 517     my $appclass = ref $c || $c;
 518
 519     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 520
 521     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 522     return @names;
 523 }
 524
 525 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 526 sub _filter_component {
 527     my ( $c, $comp, @args ) = @_;
 528
 529     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 530         return $comp->ACCEPT_CONTEXT( $c, @args );
 531     }
 532
 533     return $comp;
 534 }
 535
 536 =head2 COMPONENT ACCESSORS
 537
 538 =head2 $c->controller($name)
 539
 540 Gets a L<Catalyst::Controller> instance by name.
 541
 542     $c->controller('Foo')->do_stuff;
 543
 544 If the name is omitted, will return the controller for the dispatched
 545 action.
 546
 547 If you want to search for controllers, pass in a regexp as the argument.
 548
 549     # find all controllers that start with Foo
 550     my @foo_controllers = $c->controller(qr{^Foo});
 551
 552
 553 =cut
 554
 555 sub controller {
 556     my ( $c, $name, @args ) = @_;
 557
 558     if( $name ) {
 559         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 560         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 561         return $c->_filter_component( $result[ 0 ], @args );
 562     }
 563
 564     return $c->component( $c->action->class );
 565 }
 566
 567 =head2 $c->model($name)
 568
 569 Gets a L<Catalyst::Model> instance by name.
 570
 571     $c->model('Foo')->do_stuff;
 572
 573 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 574
 575 If the name is omitted, it will look for
 576  - a model object in $c->stash->{current_model_instance}, then
 577  - a model name in $c->stash->{current_model}, then
 578  - a config setting 'default_model', or
 579  - check if there is only one model, and return it if that's the case.
 580
 581 If you want to search for models, pass in a regexp as the argument.
 582
 583     # find all models that start with Foo
 584     my @foo_models = $c->model(qr{^Foo});
 585
 586 =cut
 587
 588 sub model {
 589     my ( $c, $name, @args ) = @_;
 590
 591     if( $name ) {
 592         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 593         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 594         return $c->_filter_component( $result[ 0 ], @args );
 595     }
 596
 597     if (ref $c) {
 598         return $c->stash->{current_model_instance}
 599           if $c->stash->{current_model_instance};
 600         return $c->model( $c->stash->{current_model} )
 601           if $c->stash->{current_model};
 602     }
 603     return $c->model( $c->config->{default_model} )
 604       if $c->config->{default_model};
 605
 606     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 607
 608     if( $rest ) {
 609         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 610         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 611         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 612         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 613         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 614     }
 615
 616     return $c->_filter_component( $comp );
 617 }
 618
 619
 620 =head2 $c->view($name)
 621
 622 Gets a L<Catalyst::View> instance by name.
 623
 624     $c->view('Foo')->do_stuff;
 625
 626 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 627
 628 If the name is omitted, it will look for
 629  - a view object in $c->stash->{current_view_instance}, then
 630  - a view name in $c->stash->{current_view}, then
 631  - a config setting 'default_view', or
 632  - check if there is only one view, and return it if that's the case.
 633
 634 If you want to search for views, pass in a regexp as the argument.
 635
 636     # find all views that start with Foo
 637     my @foo_views = $c->view(qr{^Foo});
 638
 639 =cut
 640
 641 sub view {
 642     my ( $c, $name, @args ) = @_;
 643
 644     if( $name ) {
 645         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 646         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 647         return $c->_filter_component( $result[ 0 ], @args );
 648     }
 649
 650     if (ref $c) {
 651         return $c->stash->{current_view_instance}
 652           if $c->stash->{current_view_instance};
 653         return $c->view( $c->stash->{current_view} )
 654           if $c->stash->{current_view};
 655     }
 656     return $c->view( $c->config->{default_view} )
 657       if $c->config->{default_view};
 658
 659     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 660
 661     if( $rest ) {
 662         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 663         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 664         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 665         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 666         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 667     }
 668
 669     return $c->_filter_component( $comp );
 670 }
 671
 672 =head2 $c->controllers
 673
 674 Returns the available names which can be passed to $c->controller
 675
 676 =cut
 677
 678 sub controllers {
 679     my ( $c ) = @_;
 680     return $c->_comp_names(qw/Controller C/);
 681 }
 682
 683 =head2 $c->models
 684
 685 Returns the available names which can be passed to $c->model
 686
 687 =cut
 688
 689 sub models {
 690     my ( $c ) = @_;
 691     return $c->_comp_names(qw/Model M/);
 692 }
 693
 694
 695 =head2 $c->views
 696
 697 Returns the available names which can be passed to $c->view
 698
 699 =cut
 700
 701 sub views {
 702     my ( $c ) = @_;
 703     return $c->_comp_names(qw/View V/);
 704 }
 705
 706 =head2 $c->comp($name)
 707
 708 =head2 $c->component($name)
 709
 710 Gets a component object by name. This method is not recommended,
 711 unless you want to get a specific component by full
 712 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 713 should be used instead.
 714
 715 If C<$name> is a regexp, a list of components matched against the full
 716 component name will be returned.
 717
 718 =cut
 719
 720 sub component {
 721     my ( $c, $name, @args ) = @_;
 722
 723     if( $name ) {
 724         my $comps = $c->components;
 725
 726         if( !ref $name ) {
 727             # is it the exact name?
 728             return $c->_filter_component( $comps->{ $name }, @args )
 729                        if exists $comps->{ $name };
 730
 731             # perhaps we just omitted "MyApp"?
 732             my $composed = ( ref $c || $c ) . "::${name}";
 733             return $c->_filter_component( $comps->{ $composed }, @args )
 734                        if exists $comps->{ $composed };
 735
 736             # search all of the models, views and controllers
 737             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 738             return $c->_filter_component( $comp, @args ) if $comp;
 739         }
 740
 741         # This is here so $c->comp( '::M::' ) works
 742         my $query = ref $name ? $name : qr{$name}i;
 743
 744         my @result = grep { m{$query} } keys %{ $c->components };
 745         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 746
 747         if( $result[ 0 ] ) {
 748             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 749             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 750             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 751             return $c->_filter_component( $result[ 0 ], @args );
 752         }
 753
 754         # I would expect to return an empty list here, but that breaks back-compat
 755     }
 756
 757     # fallback
 758     return sort keys %{ $c->components };
 759 }
 760
 761 =head2 CLASS DATA AND HELPER CLASSES
 762
 763 =head2 $c->config
 764
 765 Returns or takes a hashref containing the application's configuration.
 766
 767     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 768
 769 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 770 like myapp.yml in your applications home directory. See
 771 L<Catalyst::Plugin::ConfigLoader>.
 772
 773     ---
 774     db: dsn:SQLite:foo.db
 775
 776
 777 =cut
 778
 779 sub config {
 780     my $c = shift;
 781
 782     $c->log->warn("Setting config after setup has been run is not a good idea.")
 783       if ( @_ and $c->setup_finished );
 784
 785     $c->NEXT::config(@_);
 786 }
 787
 788 =head2 $c->log
 789
 790 Returns the logging object instance. Unless it is already set, Catalyst
 791 sets this up with a L<Catalyst::Log> object. To use your own log class,
 792 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 793 C<< __PACKAGE__->setup >>.
 794
 795  __PACKAGE__->log( MyLogger->new );
 796  __PACKAGE__->setup;
 797
 798 And later:
 799
 800     $c->log->info( 'Now logging with my own logger!' );
 801
 802 Your log class should implement the methods described in
 803 L<Catalyst::Log>.
 804
 805
 806 =head2 $c->debug
 807
 808 Overload to enable debug messages (same as -Debug option).
 809
 810 Note that this is a static method, not an accessor and should be overloaded
 811 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 812
 813 =cut
 814
 815 sub debug { 0 }
 816
 817 =head2 $c->dispatcher
 818
 819 Returns the dispatcher instance. Stringifies to class name. See
 820 L<Catalyst::Dispatcher>.
 821
 822 =head2 $c->engine
 823
 824 Returns the engine instance. Stringifies to the class name. See
 825 L<Catalyst::Engine>.
 826
 827
 828 =head2 UTILITY METHODS
 829
 830 =head2 $c->path_to(@path)
 831
 832 Merges C<@path> with C<< $c->config->{home} >> and returns a
 833 L<Path::Class::Dir> object.
 834
 835 For example:
 836
 837     $c->path_to( 'db', 'sqlite.db' );
 838
 839 =cut
 840
 841 sub path_to {
 842     my ( $c, @path ) = @_;
 843     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 844     if ( -d $path ) { return $path }
 845     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 846 }
 847
 848 =head2 $c->plugin( $name, $class, @args )
 849
 850 Helper method for plugins. It creates a classdata accessor/mutator and
 851 loads and instantiates the given class.
 852
 853     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 854
 855     $c->prototype->define_javascript_functions;
 856
 857 =cut
 858
 859 sub plugin {
 860     my ( $class, $name, $plugin, @args ) = @_;
 861     $class->_register_plugin( $plugin, 1 );
 862
 863     eval { $plugin->import };
 864     $class->mk_classdata($name);
 865     my $obj;
 866     eval { $obj = $plugin->new(@args) };
 867
 868     if ($@) {
 869         Catalyst::Exception->throw( message =>
 870               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 871     }
 872
 873     $class->$name($obj);
 874     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 875       if $class->debug;
 876 }
 877
 878 =head2 MyApp->setup
 879
 880 Initializes the dispatcher and engine, loads any plugins, and loads the
 881 model, view, and controller components. You may also specify an array
 882 of plugins to load here, if you choose to not load them in the C<use
 883 Catalyst> line.
 884
 885     MyApp->setup;
 886     MyApp->setup( qw/-Debug/ );
 887
 888 =cut
 889
 890 sub setup {
 891     my ( $class, @arguments ) = @_;
 892
 893     $class->log->warn("Running setup twice is not a good idea.")
 894       if ( $class->setup_finished );
 895
 896     unless ( $class->isa('Catalyst') ) {
 897
 898         Catalyst::Exception->throw(
 899             message => qq/'$class' does not inherit from Catalyst/ );
 900     }
 901
 902     if ( $class->arguments ) {
 903         @arguments = ( @arguments, @{ $class->arguments } );
 904     }
 905
 906     # Process options
 907     my $flags = {};
 908
 909     foreach (@arguments) {
 910
 911         if (/^-Debug$/) {
 912             $flags->{log} =
 913               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 914         }
 915         elsif (/^-(\w+)=?(.*)$/) {
 916             $flags->{ lc $1 } = $2;
 917         }
 918         else {
 919             push @{ $flags->{plugins} }, $_;
 920         }
 921     }
 922
 923     $class->setup_home( delete $flags->{home} );
 924
 925     $class->setup_log( delete $flags->{log} );
 926     $class->setup_plugins( delete $flags->{plugins} );
 927     $class->setup_dispatcher( delete $flags->{dispatcher} );
 928     $class->setup_engine( delete $flags->{engine} );
 929     $class->setup_stats( delete $flags->{stats} );
 930
 931     for my $flag ( sort keys %{$flags} ) {
 932
 933         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 934             &$code( $class, delete $flags->{$flag} );
 935         }
 936         else {
 937             $class->log->warn(qq/Unknown flag "$flag"/);
 938         }
 939     }
 940
 941     eval { require Catalyst::Devel; };
 942     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 943         $class->log->warn(<<"EOF");
 944 You are running an old script!
 945
 946   Please update by running (this will overwrite existing files):
 947     catalyst.pl -force -scripts $class
 948
 949   or (this will not overwrite existing files):
 950     catalyst.pl -scripts $class
 951
 952 EOF
 953     }
 954
 955     if ( $class->debug ) {
 956         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 957
 958         if (@plugins) {
 959             my $column_width = Catalyst::Utils::term_width() - 6;
 960             my $t = Text::SimpleTable->new($column_width);
 961             $t->row($_) for @plugins;
 962             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 963         }
 964
 965         my $dispatcher = $class->dispatcher;
 966         my $engine     = $class->engine;
 967         my $home       = $class->config->{home};
 968
 969         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 970         $class->log->debug(qq/Loaded engine "$engine"/);
 971
 972         $home
 973           ? ( -d $home )
 974           ? $class->log->debug(qq/Found home "$home"/)
 975           : $class->log->debug(qq/Home "$home" doesn't exist/)
 976           : $class->log->debug(q/Couldn't find home/);
 977     }
 978
 979     # Call plugins setup
 980     {
 981         no warnings qw/redefine/;
 982         local *setup = sub { };
 983         $class->setup;
 984     }
 985
 986     # Initialize our data structure
 987     $class->components( {} );
 988
 989     $class->setup_components;
 990
 991     if ( $class->debug ) {
 992         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
 993         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
 994         for my $comp ( sort keys %{ $class->components } ) {
 995             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 996             $t->row( $comp, $type );
 997         }
 998         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 999           if ( keys %{ $class->components } );
1000     }
1001
1002     # Add our self to components, since we are also a component
1003     $class->components->{$class} = $class;
1004
1005     $class->setup_actions;
1006
1007     if ( $class->debug ) {
1008         my $name = $class->config->{name} || 'Application';
1009         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1010     }
1011     $class->log->_flush() if $class->log->can('_flush');
1012
1013     $class->setup_finished(1);
1014 }
1015
1016 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1017
1018 =head2 $c->uri_for( $path, @args?, \%query_values? )
1019
1020 =over
1021
1022 =item $action
1023
1024 A Catalyst::Action object representing the Catalyst action you want to
1025 create a URI for.
1026
1027 To get an action object:
1028
1029   From another controller, anywhere:
1030     C<< $c->controller('ControllerName')->action_for('someactionname') >>
1031   Shorter styles useful in particular places:
1032     In the current controller's action method:
1033       C<< $self->action_for('someactionname') >>
1034     From the view for currently dispatched action:
1035       C<< $c->controller->action_for('someactionname') >>
1036
1037
1038 This method must be used to create URIs for
1039 L<Catalyst::DispatchType::Chained> actions.
1040
1041 =item $path
1042
1043 The actual path you wish to create a URI for, this is a public path,
1044 not a private action path.
1045
1046 =item \@captures
1047
1048 If provided, this argument is used to insert values into a I<Chained>
1049 action in the parts where the definitions contain I<CaptureArgs>. If
1050 not needed, leave out this argument.
1051
1052 =item @args
1053
1054 If provided, this is used as a list of further path sections to append
1055 to the URI. In a I<Chained> action these are the equivalent to the
1056 endpoint L<Args>.
1057
1058 =item \%query_values
1059
1060 If provided, the query_values hashref is used to add query parameters
1061 to the URI, with the keys as the names, and the values as the values.
1062
1063 =back
1064
1065 Returns a L<URI> object.
1066
1067   ## Ex 1: a path with args and a query parameter
1068   $c->uri_for($c->controller('User')->action_for('list'), 'short', { page => 2});
1069   ## -> ($c->req->base is 'http://localhost:3000/'
1070   URI->new('http://localhost:3000/user/list/short?page=2)
1071
1072   ## Ex 2: a chained view action that captures the user id
1073   ## In controller:
1074   sub user : Chained('/'): PathPart('myuser'): CaptureArgs(1) {}
1075   sub viewuser : Chained('user'): PathPart('view') {}
1076
1077   ## In uri creating code:
1078   my $uaction = $c->controller('Users')->action_for('viewuser');
1079   $c->uri_for($uaction, [ 42 ]);
1080   ## outputs:
1081   URI->new('http://localhost:3000/myuser/42/view')
1082
1083   ## Ex 3: this style is deprecated and should be omitted
1084   $c->uri_for('user/list', 'short', { page => 2});
1085   ## -> ($c->req->base is 'http://localhost:3000/'
1086   URI->new('http://localhost:3000/user/list/short?page=2)
1087
1088 Creates a URI object using C<< $c->request->base >> and a path. If an
1089 Action object is given instead of a path, the path is constructed
1090 using C<< $c->dispatcher->uri_for_action >> and passing it the
1091 @captures array, if supplied.
1092
1093 If any query parameters are passed they are added to the end of the
1094 URI in the usual way.
1095
1096 Note that uri_for is destructive to the passed query values hashref.
1097 Subsequent calls with the same hashref may have unintended results.
1098
1099 =cut
1100
1101 sub uri_for {
1102     my ( $c, $path, @args ) = @_;
1103
1104     if ( Scalar::Util::blessed($path) ) { # action object
1105         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1106                          ? shift(@args)
1107                          : [] );
1108         $path = $c->dispatcher->uri_for_action($path, $captures);
1109         return undef unless defined($path);
1110         $path = '/' if $path eq '';
1111     }
1112
1113     undef($path) if (defined $path && $path eq '');
1114
1115     my $params =
1116       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1117
1118     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1119     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1120
1121     unshift(@args, $path);
1122
1123     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1124         my $namespace = $c->namespace;
1125         if (defined $path) { # cheesy hack to handle path '../foo'
1126            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1127         }
1128         unshift(@args, $namespace || '');
1129     }
1130
1131     # join args with '/', or a blank string
1132     my $args = join('/', grep { defined($_) } @args);
1133     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1134     $args =~ s!^/!!;
1135     my $base = $c->req->base;
1136     my $class = ref($base);
1137     $base =~ s{(?<!/)$}{/};
1138
1139     my $query = '';
1140
1141     if (my @keys = keys %$params) {
1142       # somewhat lifted from URI::_query's query_form
1143       $query = '?'.join('&', map {
1144           my $val = $params->{$_};
1145           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1146           s/ /+/g;
1147           my $key = $_;
1148           $val = '' unless defined $val;
1149           (map {
1150               $_ = "$_";
1151               utf8::encode( $_ ) if utf8::is_utf8($_);
1152               # using the URI::Escape pattern here so utf8 chars survive
1153               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1154               s/ /+/g;
1155               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1156       } @keys);
1157     }
1158
1159     my $res = bless(\"${base}${args}${query}", $class);
1160     $res;
1161 }
1162
1163 =head2 $c->welcome_message
1164
1165 Returns the Catalyst welcome HTML page.
1166
1167 =cut
1168
1169 sub welcome_message {
1170     my $c      = shift;
1171     my $name   = $c->config->{name};
1172     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1173     my $prefix = Catalyst::Utils::appprefix( ref $c );
1174     $c->response->content_type('text/html; charset=utf-8');
1175     return <<"EOF";
1176 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1177     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1178 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1179     <head>
1180     <meta http-equiv="Content-Language" content="en" />
1181     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1182         <title>$name on Catalyst $VERSION</title>
1183         <style type="text/css">
1184             body {
1185                 color: #000;
1186                 background-color: #eee;
1187             }
1188             div#content {
1189                 width: 640px;
1190                 margin-left: auto;
1191                 margin-right: auto;
1192                 margin-top: 10px;
1193                 margin-bottom: 10px;
1194                 text-align: left;
1195                 background-color: #ccc;
1196                 border: 1px solid #aaa;
1197             }
1198             p, h1, h2 {
1199                 margin-left: 20px;
1200                 margin-right: 20px;
1201                 font-family: verdana, tahoma, sans-serif;
1202             }
1203             a {
1204                 font-family: verdana, tahoma, sans-serif;
1205             }
1206             :link, :visited {
1207                     text-decoration: none;
1208                     color: #b00;
1209                     border-bottom: 1px dotted #bbb;
1210             }
1211             :link:hover, :visited:hover {
1212                     color: #555;
1213             }
1214             div#topbar {
1215                 margin: 0px;
1216             }
1217             pre {
1218                 margin: 10px;
1219                 padding: 8px;
1220             }
1221             div#answers {
1222                 padding: 8px;
1223                 margin: 10px;
1224                 background-color: #fff;
1225                 border: 1px solid #aaa;
1226             }
1227             h1 {
1228                 font-size: 0.9em;
1229                 font-weight: normal;
1230                 text-align: center;
1231             }
1232             h2 {
1233                 font-size: 1.0em;
1234             }
1235             p {
1236                 font-size: 0.9em;
1237             }
1238             p img {
1239                 float: right;
1240                 margin-left: 10px;
1241             }
1242             span#appname {
1243                 font-weight: bold;
1244                 font-size: 1.6em;
1245             }
1246         </style>
1247     </head>
1248     <body>
1249         <div id="content">
1250             <div id="topbar">
1251                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1252                     $VERSION</h1>
1253              </div>
1254              <div id="answers">
1255                  <p>
1256                  <img src="$logo" alt="Catalyst Logo" />
1257                  </p>
1258                  <p>Welcome to the  world of Catalyst.
1259                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1260                     framework will make web development something you had
1261                     never expected it to be: Fun, rewarding, and quick.</p>
1262                  <h2>What to do now?</h2>
1263                  <p>That really depends  on what <b>you</b> want to do.
1264                     We do, however, provide you with a few starting points.</p>
1265                  <p>If you want to jump right into web development with Catalyst
1266                     you might want to start with a tutorial.</p>
1267 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1268 </pre>
1269 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1270 <pre>
1271 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1272 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1273 </code></pre>
1274                  <h2>What to do next?</h2>
1275                  <p>Next it's time to write an actual application. Use the
1276                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1277                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1278                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1279                     they can save you a lot of work.</p>
1280                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1281                     <p>Also, be sure to check out the vast and growing
1282                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1283                     you are likely to find what you need there.
1284                     </p>
1285
1286                  <h2>Need help?</h2>
1287                  <p>Catalyst has a very active community. Here are the main places to
1288                     get in touch with us.</p>
1289                  <ul>
1290                      <li>
1291                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1292                      </li>
1293                      <li>
1294                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1295                      </li>
1296                      <li>
1297                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1298                      </li>
1299                  </ul>
1300                  <h2>In conclusion</h2>
1301                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1302                     as we enjoyed making it. Please contact us if you have ideas
1303                     for improvement or other feedback.</p>
1304              </div>
1305          </div>
1306     </body>
1307 </html>
1308 EOF
1309 }
1310
1311 =head1 INTERNAL METHODS
1312
1313 These methods are not meant to be used by end users.
1314
1315 =head2 $c->components
1316
1317 Returns a hash of components.
1318
1319 =head2 $c->context_class
1320
1321 Returns or sets the context class.
1322
1323 =head2 $c->counter
1324
1325 Returns a hashref containing coderefs and execution counts (needed for
1326 deep recursion detection).
1327
1328 =head2 $c->depth
1329
1330 Returns the number of actions on the current internal execution stack.
1331
1332 =head2 $c->dispatch
1333
1334 Dispatches a request to actions.
1335
1336 =cut
1337
1338 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1339
1340 =head2 $c->dispatcher_class
1341
1342 Returns or sets the dispatcher class.
1343
1344 =head2 $c->dump_these
1345
1346 Returns a list of 2-element array references (name, structure) pairs
1347 that will be dumped on the error page in debug mode.
1348
1349 =cut
1350
1351 sub dump_these {
1352     my $c = shift;
1353     [ Request => $c->req ],
1354     [ Response => $c->res ],
1355     [ Stash => $c->stash ],
1356     [ Config => $c->config ];
1357 }
1358
1359 =head2 $c->engine_class
1360
1361 Returns or sets the engine class.
1362
1363 =head2 $c->execute( $class, $coderef )
1364
1365 Execute a coderef in given class and catch exceptions. Errors are available
1366 via $c->error.
1367
1368 =cut
1369
1370 sub execute {
1371     my ( $c, $class, $code ) = @_;
1372     $class = $c->component($class) || $class;
1373     $c->state(0);
1374
1375     if ( $c->depth >= $RECURSION ) {
1376         my $action = "$code";
1377         $action = "/$action" unless $action =~ /->/;
1378         my $error = qq/Deep recursion detected calling "$action"/;
1379         $c->log->error($error);
1380         $c->error($error);
1381         $c->state(0);
1382         return $c->state;
1383     }
1384
1385     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1386
1387     push( @{ $c->stack }, $code );
1388
1389     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1390
1391     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1392
1393     my $last = pop( @{ $c->stack } );
1394
1395     if ( my $error = $@ ) {
1396         if ( !ref($error) and $error eq $DETACH ) {
1397             die $DETACH if($c->depth > 1);
1398         }
1399         elsif ( !ref($error) and $error eq $GO ) {
1400             die $GO if($c->depth > 0);
1401         }
1402         else {
1403             unless ( ref $error ) {
1404                 no warnings 'uninitialized';
1405                 chomp $error;
1406                 my $class = $last->class;
1407                 my $name  = $last->name;
1408                 $error = qq/Caught exception in $class->$name "$error"/;
1409             }
1410             $c->error($error);
1411             $c->state(0);
1412         }
1413     }
1414     return $c->state;
1415 }
1416
1417 sub _stats_start_execute {
1418     my ( $c, $code ) = @_;
1419
1420     return if ( ( $code->name =~ /^_.*/ )
1421         && ( !$c->config->{show_internal_actions} ) );
1422
1423     $c->counter->{"$code"}++;
1424
1425     my $action = "$code";
1426     $action = "/$action" unless $action =~ /->/;
1427
1428     # determine if the call was the result of a forward
1429     # this is done by walking up the call stack and looking for a calling
1430     # sub of Catalyst::forward before the eval
1431     my $callsub = q{};
1432     for my $index ( 2 .. 11 ) {
1433         last
1434         if ( ( caller($index) )[0] eq 'Catalyst'
1435             && ( caller($index) )[3] eq '(eval)' );
1436
1437         if ( ( caller($index) )[3] =~ /forward$/ ) {
1438             $callsub = ( caller($index) )[3];
1439             $action  = "-> $action";
1440             last;
1441         }
1442     }
1443
1444     my $uid = "$code" . $c->counter->{"$code"};
1445
1446     # is this a root-level call or a forwarded call?
1447     if ( $callsub =~ /forward$/ ) {
1448
1449         # forward, locate the caller
1450         if ( my $parent = $c->stack->[-1] ) {
1451             $c->stats->profile(
1452                 begin  => $action,
1453                 parent => "$parent" . $c->counter->{"$parent"},
1454                 uid    => $uid,
1455             );
1456         }
1457         else {
1458
1459             # forward with no caller may come from a plugin
1460             $c->stats->profile(
1461                 begin => $action,
1462                 uid   => $uid,
1463             );
1464         }
1465     }
1466     else {
1467
1468         # root-level call
1469         $c->stats->profile(
1470             begin => $action,
1471             uid   => $uid,
1472         );
1473     }
1474     return $action;
1475
1476 }
1477
1478 sub _stats_finish_execute {
1479     my ( $c, $info ) = @_;
1480     $c->stats->profile( end => $info );
1481 }
1482
1483 =head2 $c->_localize_fields( sub { }, \%keys );
1484
1485 =cut
1486
1487 sub _localize_fields {
1488     my ( $c, $localized, $code ) = ( @_ );
1489
1490     my $request = delete $localized->{request} || {};
1491     my $response = delete $localized->{response} || {};
1492
1493     local @{ $c }{ keys %$localized } = values %$localized;
1494     local @{ $c->request }{ keys %$request } = values %$request;
1495     local @{ $c->response }{ keys %$response } = values %$response;
1496
1497     $code->();
1498 }
1499
1500 =head2 $c->finalize
1501
1502 Finalizes the request.
1503
1504 =cut
1505
1506 sub finalize {
1507     my $c = shift;
1508
1509     for my $error ( @{ $c->error } ) {
1510         $c->log->error($error);
1511     }
1512
1513     # Allow engine to handle finalize flow (for POE)
1514     if ( $c->engine->can('finalize') ) {
1515         $c->engine->finalize($c);
1516     }
1517     else {
1518
1519         $c->finalize_uploads;
1520
1521         # Error
1522         if ( $#{ $c->error } >= 0 ) {
1523             $c->finalize_error;
1524         }
1525
1526         $c->finalize_headers;
1527
1528         # HEAD request
1529         if ( $c->request->method eq 'HEAD' ) {
1530             $c->response->body('');
1531         }
1532
1533         $c->finalize_body;
1534     }
1535
1536     if ($c->use_stats) {
1537         my $elapsed = sprintf '%f', $c->stats->elapsed;
1538         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1539         $c->log->info(
1540             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1541     }
1542
1543     return $c->response->status;
1544 }
1545
1546 =head2 $c->finalize_body
1547
1548 Finalizes body.
1549
1550 =cut
1551
1552 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1553
1554 =head2 $c->finalize_cookies
1555
1556 Finalizes cookies.
1557
1558 =cut
1559
1560 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1561
1562 =head2 $c->finalize_error
1563
1564 Finalizes error.
1565
1566 =cut
1567
1568 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1569
1570 =head2 $c->finalize_headers
1571
1572 Finalizes headers.
1573
1574 =cut
1575
1576 sub finalize_headers {
1577     my $c = shift;
1578
1579     # Check if we already finalized headers
1580     return if $c->response->{_finalized_headers};
1581
1582     # Handle redirects
1583     if ( my $location = $c->response->redirect ) {
1584         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1585         $c->response->header( Location => $location );
1586
1587         if ( !$c->response->body ) {
1588             # Add a default body if none is already present
1589             $c->response->body(
1590                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1591             );
1592         }
1593     }
1594
1595     # Content-Length
1596     if ( $c->response->body && !$c->response->content_length ) {
1597
1598         # get the length from a filehandle
1599         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1600         {
1601             my $stat = stat $c->response->body;
1602             if ( $stat && $stat->size > 0 ) {
1603                 $c->response->content_length( $stat->size );
1604             }
1605             else {
1606                 $c->log->warn('Serving filehandle without a content-length');
1607             }
1608         }
1609         else {
1610             # everything should be bytes at this point, but just in case
1611             $c->response->content_length( bytes::length( $c->response->body ) );
1612         }
1613     }
1614
1615     # Errors
1616     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1617         $c->response->headers->remove_header("Content-Length");
1618         $c->response->body('');
1619     }
1620
1621     $c->finalize_cookies;
1622
1623     $c->engine->finalize_headers( $c, @_ );
1624
1625     # Done
1626     $c->response->{_finalized_headers} = 1;
1627 }
1628
1629 =head2 $c->finalize_output
1630
1631 An alias for finalize_body.
1632
1633 =head2 $c->finalize_read
1634
1635 Finalizes the input after reading is complete.
1636
1637 =cut
1638
1639 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1640
1641 =head2 $c->finalize_uploads
1642
1643 Finalizes uploads. Cleans up any temporary files.
1644
1645 =cut
1646
1647 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1648
1649 =head2 $c->get_action( $action, $namespace )
1650
1651 Gets an action in a given namespace.
1652
1653 =cut
1654
1655 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1656
1657 =head2 $c->get_actions( $action, $namespace )
1658
1659 Gets all actions of a given name in a namespace and all parent
1660 namespaces.
1661
1662 =cut
1663
1664 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1665
1666 =head2 $c->handle_request( $class, @arguments )
1667
1668 Called to handle each HTTP request.
1669
1670 =cut
1671
1672 sub handle_request {
1673     my ( $class, @arguments ) = @_;
1674
1675     # Always expect worst case!
1676     my $status = -1;
1677     eval {
1678         if ($class->debug) {
1679             my $secs = time - $START || 1;
1680             my $av = sprintf '%.3f', $COUNT / $secs;
1681             my $time = localtime time;
1682             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1683         }
1684
1685         my $c = $class->prepare(@arguments);
1686         $c->dispatch;
1687         $status = $c->finalize;
1688     };
1689
1690     if ( my $error = $@ ) {
1691         chomp $error;
1692         $class->log->error(qq/Caught exception in engine "$error"/);
1693     }
1694
1695     $COUNT++;
1696     $class->log->_flush() if $class->log->can('_flush');
1697     return $status;
1698 }
1699
1700 =head2 $c->prepare( @arguments )
1701
1702 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1703 etc.).
1704
1705 =cut
1706
1707 sub prepare {
1708     my ( $class, @arguments ) = @_;
1709
1710     $class->context_class( ref $class || $class ) unless $class->context_class;
1711     my $c = $class->context_class->new(
1712         {
1713             counter => {},
1714             stack   => [],
1715             request => $class->request_class->new(
1716                 {
1717                     arguments        => [],
1718                     body_parameters  => {},
1719                     cookies          => {},
1720                     headers          => HTTP::Headers->new,
1721                     parameters       => {},
1722                     query_parameters => {},
1723                     secure           => 0,
1724                     captures         => [],
1725                     uploads          => {}
1726                 }
1727             ),
1728             response => $class->response_class->new(
1729                 {
1730                     body    => '',
1731                     cookies => {},
1732                     headers => HTTP::Headers->new(),
1733                     status  => 200
1734                 }
1735             ),
1736             stash => {},
1737             state => 0
1738         }
1739     );
1740
1741     $c->stats($class->stats_class->new)->enable($c->use_stats);
1742     if ( $c->debug ) {
1743         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1744     }
1745
1746     # For on-demand data
1747     $c->request->{_context}  = $c;
1748     $c->response->{_context} = $c;
1749     weaken( $c->request->{_context} );
1750     weaken( $c->response->{_context} );
1751
1752     # Allow engine to direct the prepare flow (for POE)
1753     if ( $c->engine->can('prepare') ) {
1754         $c->engine->prepare( $c, @arguments );
1755     }
1756     else {
1757         $c->prepare_request(@arguments);
1758         $c->prepare_connection;
1759         $c->prepare_query_parameters;
1760         $c->prepare_headers;
1761         $c->prepare_cookies;
1762         $c->prepare_path;
1763
1764         # Prepare the body for reading, either by prepare_body
1765         # or the user, if they are using $c->read
1766         $c->prepare_read;
1767
1768         # Parse the body unless the user wants it on-demand
1769         unless ( $c->config->{parse_on_demand} ) {
1770             $c->prepare_body;
1771         }
1772     }
1773
1774     my $method  = $c->req->method  || '';
1775     my $path    = $c->req->path;
1776     $path       = '/' unless length $path;
1777     my $address = $c->req->address || '';
1778
1779     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1780       if $c->debug;
1781
1782     $c->prepare_action;
1783
1784     return $c;
1785 }
1786
1787 =head2 $c->prepare_action
1788
1789 Prepares action. See L<Catalyst::Dispatcher>.
1790
1791 =cut
1792
1793 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1794
1795 =head2 $c->prepare_body
1796
1797 Prepares message body.
1798
1799 =cut
1800
1801 sub prepare_body {
1802     my $c = shift;
1803
1804     # Do we run for the first time?
1805     return if defined $c->request->{_body};
1806
1807     # Initialize on-demand data
1808     $c->engine->prepare_body( $c, @_ );
1809     $c->prepare_parameters;
1810     $c->prepare_uploads;
1811
1812     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1813         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1814         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1815             my $param = $c->req->body_parameters->{$key};
1816             my $value = defined($param) ? $param : '';
1817             $t->row( $key,
1818                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1819         }
1820         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1821     }
1822 }
1823
1824 =head2 $c->prepare_body_chunk( $chunk )
1825
1826 Prepares a chunk of data before sending it to L<HTTP::Body>.
1827
1828 See L<Catalyst::Engine>.
1829
1830 =cut
1831
1832 sub prepare_body_chunk {
1833     my $c = shift;
1834     $c->engine->prepare_body_chunk( $c, @_ );
1835 }
1836
1837 =head2 $c->prepare_body_parameters
1838
1839 Prepares body parameters.
1840
1841 =cut
1842
1843 sub prepare_body_parameters {
1844     my $c = shift;
1845     $c->engine->prepare_body_parameters( $c, @_ );
1846 }
1847
1848 =head2 $c->prepare_connection
1849
1850 Prepares connection.
1851
1852 =cut
1853
1854 sub prepare_connection {
1855     my $c = shift;
1856     $c->engine->prepare_connection( $c, @_ );
1857 }
1858
1859 =head2 $c->prepare_cookies
1860
1861 Prepares cookies.
1862
1863 =cut
1864
1865 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1866
1867 =head2 $c->prepare_headers
1868
1869 Prepares headers.
1870
1871 =cut
1872
1873 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1874
1875 =head2 $c->prepare_parameters
1876
1877 Prepares parameters.
1878
1879 =cut
1880
1881 sub prepare_parameters {
1882     my $c = shift;
1883     $c->prepare_body_parameters;
1884     $c->engine->prepare_parameters( $c, @_ );
1885 }
1886
1887 =head2 $c->prepare_path
1888
1889 Prepares path and base.
1890
1891 =cut
1892
1893 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1894
1895 =head2 $c->prepare_query_parameters
1896
1897 Prepares query parameters.
1898
1899 =cut
1900
1901 sub prepare_query_parameters {
1902     my $c = shift;
1903
1904     $c->engine->prepare_query_parameters( $c, @_ );
1905
1906     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1907         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1908         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1909             my $param = $c->req->query_parameters->{$key};
1910             my $value = defined($param) ? $param : '';
1911             $t->row( $key,
1912                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1913         }
1914         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1915     }
1916 }
1917
1918 =head2 $c->prepare_read
1919
1920 Prepares the input for reading.
1921
1922 =cut
1923
1924 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1925
1926 =head2 $c->prepare_request
1927
1928 Prepares the engine request.
1929
1930 =cut
1931
1932 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1933
1934 =head2 $c->prepare_uploads
1935
1936 Prepares uploads.
1937
1938 =cut
1939
1940 sub prepare_uploads {
1941     my $c = shift;
1942
1943     $c->engine->prepare_uploads( $c, @_ );
1944
1945     if ( $c->debug && keys %{ $c->request->uploads } ) {
1946         my $t = Text::SimpleTable->new(
1947             [ 12, 'Parameter' ],
1948             [ 26, 'Filename' ],
1949             [ 18, 'Type' ],
1950             [ 9,  'Size' ]
1951         );
1952         for my $key ( sort keys %{ $c->request->uploads } ) {
1953             my $upload = $c->request->uploads->{$key};
1954             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1955                 $t->row( $key, $u->filename, $u->type, $u->size );
1956             }
1957         }
1958         $c->log->debug( "File Uploads are:\n" . $t->draw );
1959     }
1960 }
1961
1962 =head2 $c->prepare_write
1963
1964 Prepares the output for writing.
1965
1966 =cut
1967
1968 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1969
1970 =head2 $c->request_class
1971
1972 Returns or sets the request class.
1973
1974 =head2 $c->response_class
1975
1976 Returns or sets the response class.
1977
1978 =head2 $c->read( [$maxlength] )
1979
1980 Reads a chunk of data from the request body. This method is designed to
1981 be used in a while loop, reading C<$maxlength> bytes on every call.
1982 C<$maxlength> defaults to the size of the request if not specified.
1983
1984 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1985 directly.
1986
1987 Warning: If you use read(), Catalyst will not process the body,
1988 so you will not be able to access POST parameters or file uploads via
1989 $c->request.  You must handle all body parsing yourself.
1990
1991 =cut
1992
1993 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1994
1995 =head2 $c->run
1996
1997 Starts the engine.
1998
1999 =cut
2000
2001 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2002
2003 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2004
2005 Sets an action in a given namespace.
2006
2007 =cut
2008
2009 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2010
2011 =head2 $c->setup_actions($component)
2012
2013 Sets up actions for a component.
2014
2015 =cut
2016
2017 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2018
2019 =head2 $c->setup_components
2020
2021 Sets up components. Specify a C<setup_components> config option to pass
2022 additional options directly to L<Module::Pluggable>. To add additional
2023 search paths, specify a key named C<search_extra> as an array
2024 reference. Items in the array beginning with C<::> will have the
2025 application class name prepended to them.
2026
2027 All components found will also have any
2028 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2029 Note, that modules which are B<not> an I<inner package> of the main
2030 file namespace loaded will not be instantiated as components.
2031
2032 =cut
2033
2034 sub setup_components {
2035     my $class = shift;
2036
2037     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2038     my $config  = $class->config->{ setup_components };
2039     my $extra   = delete $config->{ search_extra } || [];
2040
2041     push @paths, @$extra;
2042
2043     my $locator = Module::Pluggable::Object->new(
2044         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2045         %$config
2046     );
2047
2048     my @comps = sort { length $a <=> length $b } $locator->plugins;
2049     my %comps = map { $_ => 1 } @comps;
2050
2051     for my $component ( @comps ) {
2052
2053         # We pass ignore_loaded here so that overlay files for (e.g.)
2054         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2055         # we know M::P::O found a file on disk so this is safe
2056
2057         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2058
2059         my $module  = $class->setup_component( $component );
2060         my %modules = (
2061             $component => $module,
2062             map {
2063                 $_ => $class->setup_component( $_ )
2064             } grep {
2065               not exists $comps{$_}
2066             } Devel::InnerPackage::list_packages( $component )
2067         );
2068
2069         for my $key ( keys %modules ) {
2070             $class->components->{ $key } = $modules{ $key };
2071         }
2072     }
2073 }
2074
2075 =head2 $c->setup_component
2076
2077 =cut
2078
2079 sub setup_component {
2080     my( $class, $component ) = @_;
2081
2082     unless ( $component->can( 'COMPONENT' ) ) {
2083         return $component;
2084     }
2085
2086     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2087     my $config = $class->config->{ $suffix } || {};
2088
2089     my $instance = eval { $component->COMPONENT( $class, $config ); };
2090
2091     if ( my $error = $@ ) {
2092         chomp $error;
2093         Catalyst::Exception->throw(
2094             message => qq/Couldn't instantiate component "$component", "$error"/
2095         );
2096     }
2097
2098     Catalyst::Exception->throw(
2099         message =>
2100         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2101     ) unless eval { $instance->can( 'can' ) };
2102
2103     return $instance;
2104 }
2105
2106 =head2 $c->setup_dispatcher
2107
2108 Sets up dispatcher.
2109
2110 =cut
2111
2112 sub setup_dispatcher {
2113     my ( $class, $dispatcher ) = @_;
2114
2115     if ($dispatcher) {
2116         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2117     }
2118
2119     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2120         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2121     }
2122
2123     unless ($dispatcher) {
2124         $dispatcher = $class->dispatcher_class;
2125     }
2126
2127     unless (Class::Inspector->loaded($dispatcher)) {
2128         require Class::Inspector->filename($dispatcher);
2129     }
2130
2131     # dispatcher instance
2132     $class->dispatcher( $dispatcher->new );
2133 }
2134
2135 =head2 $c->setup_engine
2136
2137 Sets up engine.
2138
2139 =cut
2140
2141 sub setup_engine {
2142     my ( $class, $engine ) = @_;
2143
2144     if ($engine) {
2145         $engine = 'Catalyst::Engine::' . $engine;
2146     }
2147
2148     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2149         $engine = 'Catalyst::Engine::' . $env;
2150     }
2151
2152     if ( $ENV{MOD_PERL} ) {
2153
2154         # create the apache method
2155         {
2156             no strict 'refs';
2157             *{"$class\::apache"} = sub { shift->engine->apache };
2158         }
2159
2160         my ( $software, $version ) =
2161           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2162
2163         $version =~ s/_//g;
2164         $version =~ s/(\.[^.]+)\./$1/g;
2165
2166         if ( $software eq 'mod_perl' ) {
2167
2168             if ( !$engine ) {
2169
2170                 if ( $version >= 1.99922 ) {
2171                     $engine = 'Catalyst::Engine::Apache2::MP20';
2172                 }
2173
2174                 elsif ( $version >= 1.9901 ) {
2175                     $engine = 'Catalyst::Engine::Apache2::MP19';
2176                 }
2177
2178                 elsif ( $version >= 1.24 ) {
2179                     $engine = 'Catalyst::Engine::Apache::MP13';
2180                 }
2181
2182                 else {
2183                     Catalyst::Exception->throw( message =>
2184                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2185                 }
2186
2187             }
2188
2189             # install the correct mod_perl handler
2190             if ( $version >= 1.9901 ) {
2191                 *handler = sub  : method {
2192                     shift->handle_request(@_);
2193                 };
2194             }
2195             else {
2196                 *handler = sub ($$) { shift->handle_request(@_) };
2197             }
2198
2199         }
2200
2201         elsif ( $software eq 'Zeus-Perl' ) {
2202             $engine = 'Catalyst::Engine::Zeus';
2203         }
2204
2205         else {
2206             Catalyst::Exception->throw(
2207                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2208         }
2209     }
2210
2211     unless ($engine) {
2212         $engine = $class->engine_class;
2213     }
2214
2215     unless (Class::Inspector->loaded($engine)) {
2216         require Class::Inspector->filename($engine);
2217     }
2218
2219     # check for old engines that are no longer compatible
2220     my $old_engine;
2221     if ( $engine->isa('Catalyst::Engine::Apache')
2222         && !Catalyst::Engine::Apache->VERSION )
2223     {
2224         $old_engine = 1;
2225     }
2226
2227     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2228         && Catalyst::Engine::Server->VERSION le '0.02' )
2229     {
2230         $old_engine = 1;
2231     }
2232
2233     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2234         && $engine->VERSION eq '0.01' )
2235     {
2236         $old_engine = 1;
2237     }
2238
2239     elsif ($engine->isa('Catalyst::Engine::Zeus')
2240         && $engine->VERSION eq '0.01' )
2241     {
2242         $old_engine = 1;
2243     }
2244
2245     if ($old_engine) {
2246         Catalyst::Exception->throw( message =>
2247               qq/Engine "$engine" is not supported by this version of Catalyst/
2248         );
2249     }
2250
2251     # engine instance
2252     $class->engine( $engine->new );
2253 }
2254
2255 =head2 $c->setup_home
2256
2257 Sets up the home directory.
2258
2259 =cut
2260
2261 sub setup_home {
2262     my ( $class, $home ) = @_;
2263
2264     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2265         $home = $env;
2266     }
2267
2268     unless ($home) {
2269         $home = Catalyst::Utils::home($class);
2270     }
2271
2272     if ($home) {
2273         $class->config->{home} ||= $home;
2274         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2275     }
2276 }
2277
2278 =head2 $c->setup_log
2279
2280 Sets up log.
2281
2282 =cut
2283
2284 sub setup_log {
2285     my ( $class, $debug ) = @_;
2286
2287     unless ( $class->log ) {
2288         $class->log( Catalyst::Log->new );
2289     }
2290
2291     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2292     if ( defined($env_debug) ? $env_debug : $debug ) {
2293         no strict 'refs';
2294         *{"$class\::debug"} = sub { 1 };
2295         $class->log->debug('Debug messages enabled');
2296     }
2297 }
2298
2299 =head2 $c->setup_plugins
2300
2301 Sets up plugins.
2302
2303 =cut
2304
2305 =head2 $c->setup_stats
2306
2307 Sets up timing statistics class.
2308
2309 =cut
2310
2311 sub setup_stats {
2312     my ( $class, $stats ) = @_;
2313
2314     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2315
2316     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2317     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2318         no strict 'refs';
2319         *{"$class\::use_stats"} = sub { 1 };
2320         $class->log->debug('Statistics enabled');
2321     }
2322 }
2323
2324
2325 =head2 $c->registered_plugins
2326
2327 Returns a sorted list of the plugins which have either been stated in the
2328 import list or which have been added via C<< MyApp->plugin(@args); >>.
2329
2330 If passed a given plugin name, it will report a boolean value indicating
2331 whether or not that plugin is loaded.  A fully qualified name is required if
2332 the plugin name does not begin with C<Catalyst::Plugin::>.
2333
2334  if ($c->registered_plugins('Some::Plugin')) {
2335      ...
2336  }
2337
2338 =cut
2339
2340 {
2341
2342     sub registered_plugins {
2343         my $proto = shift;
2344         return sort keys %{ $proto->_plugins } unless @_;
2345         my $plugin = shift;
2346         return 1 if exists $proto->_plugins->{$plugin};
2347         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2348     }
2349
2350     sub _register_plugin {
2351         my ( $proto, $plugin, $instant ) = @_;
2352         my $class = ref $proto || $proto;
2353
2354         # no ignore_loaded here, the plugin may already have been
2355         # defined in memory and we don't want to error on "no file" if so
2356
2357         Catalyst::Utils::ensure_class_loaded( $plugin );
2358
2359         $proto->_plugins->{$plugin} = 1;
2360         unless ($instant) {
2361             no strict 'refs';
2362             unshift @{"$class\::ISA"}, $plugin;
2363         }
2364         return $class;
2365     }
2366
2367     sub setup_plugins {
2368         my ( $class, $plugins ) = @_;
2369
2370         $class->_plugins( {} ) unless $class->_plugins;
2371         $plugins ||= [];
2372         for my $plugin ( reverse @$plugins ) {
2373
2374             unless ( $plugin =~ s/\A\+// ) {
2375                 $plugin = "Catalyst::Plugin::$plugin";
2376             }
2377
2378             $class->_register_plugin($plugin);
2379         }
2380     }
2381 }
2382
2383 =head2 $c->stack
2384
2385 Returns an arrayref of the internal execution stack (actions that are
2386 currently executing).
2387
2388 =head2 $c->stats_class
2389
2390 Returns or sets the stats (timing statistics) class.
2391
2392 =head2 $c->use_stats
2393
2394 Returns 1 when stats collection is enabled.  Stats collection is enabled
2395 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2396 environment variable is set.
2397
2398 Note that this is a static method, not an accessor and should be overloaded
2399 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2400
2401 =cut
2402
2403 sub use_stats { 0 }
2404
2405
2406 =head2 $c->write( $data )
2407
2408 Writes $data to the output stream. When using this method directly, you
2409 will need to manually set the C<Content-Length> header to the length of
2410 your output data, if known.
2411
2412 =cut
2413
2414 sub write {
2415     my $c = shift;
2416
2417     # Finalize headers if someone manually writes output
2418     $c->finalize_headers;
2419
2420     return $c->engine->write( $c, @_ );
2421 }
2422
2423 =head2 version
2424
2425 Returns the Catalyst version number. Mostly useful for "powered by"
2426 messages in template systems.
2427
2428 =cut
2429
2430 sub version { return $Catalyst::VERSION }
2431
2432 =head1 INTERNAL ACTIONS
2433
2434 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2435 C<_ACTION>, and C<_END>. These are by default not shown in the private
2436 action table, but you can make them visible with a config parameter.
2437
2438     MyApp->config->{show_internal_actions} = 1;
2439
2440 =head1 CASE SENSITIVITY
2441
2442 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2443 mapped to C</foo/bar>. You can activate case sensitivity with a config
2444 parameter.
2445
2446     MyApp->config->{case_sensitive} = 1;
2447
2448 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2449
2450 =head1 ON-DEMAND PARSER
2451
2452 The request body is usually parsed at the beginning of a request,
2453 but if you want to handle input yourself, you can enable on-demand
2454 parsing with a config parameter.
2455
2456     MyApp->config->{parse_on_demand} = 1;
2457
2458 =head1 PROXY SUPPORT
2459
2460 Many production servers operate using the common double-server approach,
2461 with a lightweight frontend web server passing requests to a larger
2462 backend server. An application running on the backend server must deal
2463 with two problems: the remote user always appears to be C<127.0.0.1> and
2464 the server's hostname will appear to be C<localhost> regardless of the
2465 virtual host that the user connected through.
2466
2467 Catalyst will automatically detect this situation when you are running
2468 the frontend and backend servers on the same machine. The following
2469 changes are made to the request.
2470
2471     $c->req->address is set to the user's real IP address, as read from
2472     the HTTP X-Forwarded-For header.
2473
2474     The host value for $c->req->base and $c->req->uri is set to the real
2475     host, as read from the HTTP X-Forwarded-Host header.
2476
2477 Obviously, your web server must support these headers for this to work.
2478
2479 In a more complex server farm environment where you may have your
2480 frontend proxy server(s) on different machines, you will need to set a
2481 configuration option to tell Catalyst to read the proxied data from the
2482 headers.
2483
2484     MyApp->config->{using_frontend_proxy} = 1;
2485
2486 If you do not wish to use the proxy support at all, you may set:
2487
2488     MyApp->config->{ignore_frontend_proxy} = 1;
2489
2490 =head1 THREAD SAFETY
2491
2492 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2493 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2494 believe the Catalyst core to be thread-safe.
2495
2496 If you plan to operate in a threaded environment, remember that all other
2497 modules you are using must also be thread-safe. Some modules, most notably
2498 L<DBD::SQLite>, are not thread-safe.
2499
2500 =head1 SUPPORT
2501
2502 IRC:
2503
2504     Join #catalyst on irc.perl.org.
2505
2506 Mailing Lists:
2507
2508     http://lists.rawmode.org/mailman/listinfo/catalyst
2509     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2510
2511 Web:
2512
2513     http://catalyst.perl.org
2514
2515 Wiki:
2516
2517     http://dev.catalyst.perl.org
2518
2519 =head1 SEE ALSO
2520
2521 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2522
2523 =head2 L<Catalyst::Manual> - The Catalyst Manual
2524
2525 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2526
2527 =head2 L<Catalyst::Engine> - Core engine
2528
2529 =head2 L<Catalyst::Log> - Log class.
2530
2531 =head2 L<Catalyst::Request> - Request object
2532
2533 =head2 L<Catalyst::Response> - Response object
2534
2535 =head2 L<Catalyst::Test> - The test suite.
2536
2537 =head1 PROJECT FOUNDER
2538
2539 sri: Sebastian Riedel <sri@cpan.org>
2540
2541 =head1 CONTRIBUTORS
2542
2543 abw: Andy Wardley
2544
2545 acme: Leon Brocard <leon@astray.com>
2546
2547 Andrew Bramble
2548
2549 Andrew Ford
2550
2551 Andrew Ruthven
2552
2553 andyg: Andy Grundman <andy@hybridized.org>
2554
2555 audreyt: Audrey Tang
2556
2557 bricas: Brian Cassidy <bricas@cpan.org>
2558
2559 chansen: Christian Hansen
2560
2561 chicks: Christopher Hicks
2562
2563 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2564
2565 Drew Taylor
2566
2567 esskar: Sascha Kiefer
2568
2569 fireartist: Carl Franks <cfranks@cpan.org>
2570
2571 gabb: Danijel Milicevic
2572
2573 Gary Ashton Jones
2574
2575 Geoff Richards
2576
2577 jcamacho: Juan Camacho
2578
2579 jhannah: Jay Hannah <jay@jays.net>
2580
2581 Jody Belka
2582
2583 Johan Lindstrom
2584
2585 jon: Jon Schutz <jjschutz@cpan.org>
2586
2587 marcus: Marcus Ramberg <mramberg@cpan.org>
2588
2589 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2590
2591 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2592
2593 mugwump: Sam Vilain
2594
2595 naughton: David Naughton
2596
2597 ningu: David Kamholz <dkamholz@cpan.org>
2598
2599 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2600
2601 numa: Dan Sully <daniel@cpan.org>
2602
2603 obra: Jesse Vincent
2604
2605 omega: Andreas Marienborg
2606
2607 Oleg Kostyuk <cub.uanic@gmail.com>
2608
2609 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2610
2611 sky: Arthur Bergman
2612
2613 the_jester: Jesse Sheidlower
2614
2615 Ulf Edvinsson
2616
2617 willert: Sebastian Willert <willert@cpan.org>
2618
2619 batman: Jan Henning Thorsen <pm@flodhest.net>
2620
2621 =head1 LICENSE
2622
2623 This library is free software, you can redistribute it and/or modify it under
2624 the same terms as Perl itself.
2625
2626 =cut
2627
2628 1;