lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use String::RewritePrefix;
  32 use Catalyst::EngineLoader;
  33 use utf8;
  34 use Carp qw/croak carp shortmess/;
  35 use Try::Tiny;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39 use Plack::Middleware::LighttpdScriptNameFix;
  40
  41 BEGIN { require 5.008004; }
  42
  43 has stack => (is => 'ro', default => sub { [] });
  44 has stash => (is => 'rw', default => sub { {} });
  45 has state => (is => 'rw', default => 0);
  46 has stats => (is => 'rw');
  47 has action => (is => 'rw');
  48 has counter => (is => 'rw', default => sub { {} });
  49 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  50 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  51 has namespace => (is => 'rw');
  52
  53 sub depth { scalar @{ shift->stack || [] }; }
  54 sub comp { shift->component(@_) }
  55
  56 sub req {
  57     my $self = shift; return $self->request(@_);
  58 }
  59 sub res {
  60     my $self = shift; return $self->response(@_);
  61 }
  62
  63 # For backwards compatibility
  64 sub finalize_output { shift->finalize_body(@_) };
  65
  66 # For statistics
  67 our $COUNT     = 1;
  68 our $START     = time;
  69 our $RECURSION = 1000;
  70 our $DETACH    = Catalyst::Exception::Detach->new;
  71 our $GO        = Catalyst::Exception::Go->new;
  72
  73 #I imagine that very few of these really need to be class variables. if any.
  74 #maybe we should just make them attributes with a default?
  75 __PACKAGE__->mk_classdata($_)
  76   for qw/components arguments dispatcher engine log dispatcher_class
  77   engine_loader context_class request_class response_class stats_class
  78   setup_finished _psgi_app/;
  79
  80 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  81 __PACKAGE__->request_class('Catalyst::Request');
  82 __PACKAGE__->response_class('Catalyst::Response');
  83 __PACKAGE__->stats_class('Catalyst::Stats');
  84
  85 # Remember to update this in Catalyst::Runtime as well!
  86
  87 our $VERSION = '5.89002';
  88
  89 sub import {
  90     my ( $class, @arguments ) = @_;
  91
  92     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  93     # callers @ISA.
  94     return unless $class eq 'Catalyst';
  95
  96     my $caller = caller();
  97     return if $caller eq 'main';
  98
  99     my $meta = Moose::Meta::Class->initialize($caller);
 100     unless ( $caller->isa('Catalyst') ) {
 101         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 102         $meta->superclasses(@superclasses);
 103     }
 104     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 105     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 106
 107     unless( $meta->has_method('meta') ){
 108         if ($Moose::VERSION >= 1.15) {
 109             $meta->_add_meta_method('meta');
 110         }
 111         else {
 112             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 113         }
 114     }
 115
 116     $caller->arguments( [@arguments] );
 117     $caller->setup_home;
 118 }
 119
 120 sub _application { $_[0] }
 121
 122 =head1 NAME
 123
 124 Catalyst - The Elegant MVC Web Application Framework
 125
 126 =head1 SYNOPSIS
 127
 128 See the L<Catalyst::Manual> distribution for comprehensive
 129 documentation and tutorials.
 130
 131     # Install Catalyst::Devel for helpers and other development tools
 132     # use the helper to create a new application
 133     catalyst.pl MyApp
 134
 135     # add models, views, controllers
 136     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 137     script/myapp_create.pl view MyTemplate TT
 138     script/myapp_create.pl controller Search
 139
 140     # built in testserver -- use -r to restart automatically on changes
 141     # --help to see all available options
 142     script/myapp_server.pl
 143
 144     # command line testing interface
 145     script/myapp_test.pl /yada
 146
 147     ### in lib/MyApp.pm
 148     use Catalyst qw/-Debug/; # include plugins here as well
 149
 150     ### In lib/MyApp/Controller/Root.pm (autocreated)
 151     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 152         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 153         $c->stash->{template} = 'foo.tt'; # set the template
 154         # lookup something from db -- stash vars are passed to TT
 155         $c->stash->{data} =
 156           $c->model('Database::Foo')->search( { country => $args[0] } );
 157         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 158             $c->forward( 'bar' ); # process another action
 159             # do something else after forward returns
 160         }
 161     }
 162
 163     # The foo.tt TT template can use the stash data from the database
 164     [% WHILE (item = data.next) %]
 165         [% item.foo %]
 166     [% END %]
 167
 168     # called for /bar/of/soap, /bar/of/soap/10, etc.
 169     sub bar : Path('/bar/of/soap') { ... }
 170
 171     # called for all actions, from the top-most controller downwards
 172     sub auto : Private {
 173         my ( $self, $c ) = @_;
 174         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 175             $c->res->redirect( '/login' ); # require login
 176             return 0; # abort request and go immediately to end()
 177         }
 178         return 1; # success; carry on to next action
 179     }
 180
 181     # called after all actions are finished
 182     sub end : Private {
 183         my ( $self, $c ) = @_;
 184         if ( scalar @{ $c->error } ) { ... } # handle errors
 185         return if $c->res->body; # already have a response
 186         $c->forward( 'MyApp::View::TT' ); # render template
 187     }
 188
 189     ### in MyApp/Controller/Foo.pm
 190     # called for /foo/bar
 191     sub bar : Local { ... }
 192
 193     # called for /blargle
 194     sub blargle : Global { ... }
 195
 196     # an index action matches /foo, but not /foo/1, etc.
 197     sub index : Private { ... }
 198
 199     ### in MyApp/Controller/Foo/Bar.pm
 200     # called for /foo/bar/baz
 201     sub baz : Local { ... }
 202
 203     # first Root auto is called, then Foo auto, then this
 204     sub auto : Private { ... }
 205
 206     # powerful regular expression paths are also possible
 207     sub details : Regex('^product/(\w+)/details$') {
 208         my ( $self, $c ) = @_;
 209         # extract the (\w+) from the URI
 210         my $product = $c->req->captures->[0];
 211     }
 212
 213 See L<Catalyst::Manual::Intro> for additional information.
 214
 215 =head1 DESCRIPTION
 216
 217 Catalyst is a modern framework for making web applications without the
 218 pain usually associated with this process. This document is a reference
 219 to the main Catalyst application. If you are a new user, we suggest you
 220 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 221
 222 See L<Catalyst::Manual> for more documentation.
 223
 224 Catalyst plugins can be loaded by naming them as arguments to the "use
 225 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 226 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 227 C<My::Module>.
 228
 229     use Catalyst qw/My::Module/;
 230
 231 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 232 fully qualify the name by using a unary plus:
 233
 234     use Catalyst qw/
 235         My::Module
 236         +Fully::Qualified::Plugin::Name
 237     /;
 238
 239 Special flags like C<-Debug> and C<-Engine> can also be specified as
 240 arguments when Catalyst is loaded:
 241
 242     use Catalyst qw/-Debug My::Module/;
 243
 244 The position of plugins and flags in the chain is important, because
 245 they are loaded in the order in which they appear.
 246
 247 The following flags are supported:
 248
 249 =head2 -Debug
 250
 251 Enables debug output. You can also force this setting from the system
 252 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 253 settings override the application, with <MYAPP>_DEBUG having the highest
 254 priority.
 255
 256 This sets the log level to 'debug' and enables full debug output on the
 257 error screen. If you only want the latter, see L<< $c->debug >>.
 258
 259 =head2 -Engine
 260
 261 Forces Catalyst to use a specific engine. Omit the
 262 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 263
 264     use Catalyst qw/-Engine=CGI/;
 265
 266 =head2 -Home
 267
 268 Forces Catalyst to use a specific home directory, e.g.:
 269
 270     use Catalyst qw[-Home=/usr/mst];
 271
 272 This can also be done in the shell environment by setting either the
 273 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 274 is replaced with the uppercased name of your application, any "::" in
 275 the name will be replaced with underscores, e.g. MyApp::Web should use
 276 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 277
 278 If none of these are set, Catalyst will attempt to automatically detect the
 279 home directory. If you are working in a development envirnoment, Catalyst
 280 will try and find the directory containing either Makefile.PL, Build.PL or
 281 dist.ini. If the application has been installed into the system (i.e.
 282 you have done C<make install>), then Catalyst will use the path to your
 283 application module, without the .pm extension (ie, /foo/MyApp if your
 284 application was installed at /foo/MyApp.pm)
 285
 286 =head2 -Log
 287
 288     use Catalyst '-Log=warn,fatal,error';
 289
 290 Specifies a comma-delimited list of log levels.
 291
 292 =head2 -Stats
 293
 294 Enables statistics collection and reporting.
 295
 296    use Catalyst qw/-Stats=1/;
 297
 298 You can also force this setting from the system environment with CATALYST_STATS
 299 or <MYAPP>_STATS. The environment settings override the application, with
 300 <MYAPP>_STATS having the highest priority.
 301
 302 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 303
 304 =head1 METHODS
 305
 306 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 307
 308 =head2 $c->action
 309
 310 Returns a L<Catalyst::Action> object for the current action, which
 311 stringifies to the action name. See L<Catalyst::Action>.
 312
 313 =head2 $c->namespace
 314
 315 Returns the namespace of the current action, i.e., the URI prefix
 316 corresponding to the controller of the current action. For example:
 317
 318     # in Controller::Foo::Bar
 319     $c->namespace; # returns 'foo/bar';
 320
 321 =head2 $c->request
 322
 323 =head2 $c->req
 324
 325 Returns the current L<Catalyst::Request> object, giving access to
 326 information about the current client request (including parameters,
 327 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 328
 329 =head2 REQUEST FLOW HANDLING
 330
 331 =head2 $c->forward( $action [, \@arguments ] )
 332
 333 =head2 $c->forward( $class, $method, [, \@arguments ] )
 334
 335 Forwards processing to another action, by its private name. If you give a
 336 class name but no method, C<process()> is called. You may also optionally
 337 pass arguments in an arrayref. The action will receive the arguments in
 338 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 339 C<< $c->req->args >> will be restored to the previous values.
 340
 341 Any data C<return>ed from the action forwarded to, will be returned by the
 342 call to forward.
 343
 344     my $foodata = $c->forward('/foo');
 345     $c->forward('index');
 346     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 347     $c->forward('View::TT');
 348
 349 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 350 an C<< eval { } >> around the call (actually
 351 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 352 all 'dies' within the called action. If you want C<die> to propagate you
 353 need to do something like:
 354
 355     $c->forward('foo');
 356     die join "\n", @{ $c->error } if @{ $c->error };
 357
 358 Or make sure to always return true values from your actions and write
 359 your code like this:
 360
 361     $c->forward('foo') || return;
 362
 363 Another note is that C<< $c->forward >> always returns a scalar because it
 364 actually returns $c->state which operates in a scalar context.
 365 Thus, something like:
 366
 367     return @array;
 368
 369 in an action that is forwarded to is going to return a scalar,
 370 i.e. how many items are in that array, which is probably not what you want.
 371 If you need to return an array then return a reference to it,
 372 or stash it like so:
 373
 374     $c->stash->{array} = \@array;
 375
 376 and access it from the stash.
 377
 378 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 379
 380 =cut
 381
 382 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 383
 384 =head2 $c->detach( $action [, \@arguments ] )
 385
 386 =head2 $c->detach( $class, $method, [, \@arguments ] )
 387
 388 =head2 $c->detach()
 389
 390 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 391 doesn't return to the previous action when processing is finished.
 392
 393 When called with no arguments it escapes the processing chain entirely.
 394
 395 =cut
 396
 397 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 398
 399 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 400
 401 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 402
 403 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 404 but does a full dispatch, instead of just calling the new C<$action> /
 405 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 406 you go to are called, just like a new request.
 407
 408 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 409 This means, for example, that C<< $c->action >> methods such as
 410 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 411 L<reverse|Catalyst::Action/reverse> return information for the visited action
 412 when they are invoked within the visited action.  This is different from the
 413 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 414 continues to use the $c->action object from the caller action even when
 415 invoked from the callee.
 416
 417 C<< $c->stash >> is kept unchanged.
 418
 419 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 420 allows you to "wrap" another action, just as it would have been called by
 421 dispatching from a URL, while the analogous
 422 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 423 transfer control to another action as if it had been reached directly from a URL.
 424
 425 =cut
 426
 427 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 428
 429 =head2 $c->go( $action [, \@captures, \@arguments ] )
 430
 431 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 432
 433 The relationship between C<go> and
 434 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 435 the relationship between
 436 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 437 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 438 C<< $c->go >> will perform a full dispatch on the specified action or method,
 439 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 440 C<go> escapes the processing of the current request chain on completion, and
 441 does not return to its caller.
 442
 443 @arguments are arguments to the final destination of $action. @captures are
 444 arguments to the intermediate steps, if any, on the way to the final sub of
 445 $action.
 446
 447 =cut
 448
 449 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 450
 451 =head2 $c->response
 452
 453 =head2 $c->res
 454
 455 Returns the current L<Catalyst::Response> object, see there for details.
 456
 457 =head2 $c->stash
 458
 459 Returns a hashref to the stash, which may be used to store data and pass
 460 it between components during a request. You can also set hash keys by
 461 passing arguments. The stash is automatically sent to the view. The
 462 stash is cleared at the end of a request; it cannot be used for
 463 persistent storage (for this you must use a session; see
 464 L<Catalyst::Plugin::Session> for a complete system integrated with
 465 Catalyst).
 466
 467     $c->stash->{foo} = $bar;
 468     $c->stash( { moose => 'majestic', qux => 0 } );
 469     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 470
 471     # stash is automatically passed to the view for use in a template
 472     $c->forward( 'MyApp::View::TT' );
 473
 474 =cut
 475
 476 around stash => sub {
 477     my $orig = shift;
 478     my $c = shift;
 479     my $stash = $orig->($c);
 480     if (@_) {
 481         my $new_stash = @_ > 1 ? {@_} : $_[0];
 482         croak('stash takes a hash or hashref') unless ref $new_stash;
 483         foreach my $key ( keys %$new_stash ) {
 484           $stash->{$key} = $new_stash->{$key};
 485         }
 486     }
 487
 488     return $stash;
 489 };
 490
 491
 492 =head2 $c->error
 493
 494 =head2 $c->error($error, ...)
 495
 496 =head2 $c->error($arrayref)
 497
 498 Returns an arrayref containing error messages.  If Catalyst encounters an
 499 error while processing a request, it stores the error in $c->error.  This
 500 method should only be used to store fatal error messages.
 501
 502     my @error = @{ $c->error };
 503
 504 Add a new error.
 505
 506     $c->error('Something bad happened');
 507
 508 =cut
 509
 510 sub error {
 511     my $c = shift;
 512     if ( $_[0] ) {
 513         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 514         croak @$error unless ref $c;
 515         push @{ $c->{error} }, @$error;
 516     }
 517     elsif ( defined $_[0] ) { $c->{error} = undef }
 518     return $c->{error} || [];
 519 }
 520
 521
 522 =head2 $c->state
 523
 524 Contains the return value of the last executed action.
 525 Note that << $c->state >> operates in a scalar context which means that all
 526 values it returns are scalar.
 527
 528 =head2 $c->clear_errors
 529
 530 Clear errors.  You probably don't want to clear the errors unless you are
 531 implementing a custom error screen.
 532
 533 This is equivalent to running
 534
 535     $c->error(0);
 536
 537 =cut
 538
 539 sub clear_errors {
 540     my $c = shift;
 541     $c->error(0);
 542 }
 543
 544 sub _comp_search_prefixes {
 545     my $c = shift;
 546     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 547 }
 548
 549 # search components given a name and some prefixes
 550 sub _comp_names_search_prefixes {
 551     my ( $c, $name, @prefixes ) = @_;
 552     my $appclass = ref $c || $c;
 553     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 554     $filter = qr/$filter/; # Compile regex now rather than once per loop
 555
 556     # map the original component name to the sub part that we will search against
 557     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 558         grep { /$filter/ } keys %{ $c->components };
 559
 560     # undef for a name will return all
 561     return keys %eligible if !defined $name;
 562
 563     my $query  = ref $name ? $name : qr/^$name$/i;
 564     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 565
 566     return @result if @result;
 567
 568     # if we were given a regexp to search against, we're done.
 569     return if ref $name;
 570
 571     # skip regexp fallback if configured
 572     return
 573         if $appclass->config->{disable_component_resolution_regex_fallback};
 574
 575     # regexp fallback
 576     $query  = qr/$name/i;
 577     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 578
 579     # no results? try against full names
 580     if( !@result ) {
 581         @result = grep { m{$query} } keys %eligible;
 582     }
 583
 584     # don't warn if we didn't find any results, it just might not exist
 585     if( @result ) {
 586         # Disgusting hack to work out correct method name
 587         my $warn_for = lc $prefixes[0];
 588         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 589            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 590            "component resolution is unreliable and unsafe.";
 591         my $short = $result[0];
 592         # remove the component namespace prefix
 593         $short =~ s/.*?(Model|Controller|View):://;
 594         my $shortmess = Carp::shortmess('');
 595         if ($shortmess =~ m#Catalyst/Plugin#) {
 596            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 597               "plugin's config";
 598         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 599            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 600               "component's config";
 601         } else {
 602            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 603               "but if you really wanted to search, pass in a regexp as the argument " .
 604               "like so: \$c->${warn_for}(qr/${name}/)";
 605         }
 606         $c->log->warn( "${msg}$shortmess" );
 607     }
 608
 609     return @result;
 610 }
 611
 612 # Find possible names for a prefix
 613 sub _comp_names {
 614     my ( $c, @prefixes ) = @_;
 615     my $appclass = ref $c || $c;
 616
 617     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 618
 619     my @names = map { s{$filter}{}; $_; }
 620         $c->_comp_names_search_prefixes( undef, @prefixes );
 621
 622     return @names;
 623 }
 624
 625 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 626 sub _filter_component {
 627     my ( $c, $comp, @args ) = @_;
 628
 629     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 630         return $comp->ACCEPT_CONTEXT( $c, @args );
 631     }
 632
 633     return $comp;
 634 }
 635
 636 =head2 COMPONENT ACCESSORS
 637
 638 =head2 $c->controller($name)
 639
 640 Gets a L<Catalyst::Controller> instance by name.
 641
 642     $c->controller('Foo')->do_stuff;
 643
 644 If the name is omitted, will return the controller for the dispatched
 645 action.
 646
 647 If you want to search for controllers, pass in a regexp as the argument.
 648
 649     # find all controllers that start with Foo
 650     my @foo_controllers = $c->controller(qr{^Foo});
 651
 652
 653 =cut
 654
 655 sub controller {
 656     my ( $c, $name, @args ) = @_;
 657
 658     my $appclass = ref($c) || $c;
 659     if( $name ) {
 660         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 661             my $comps = $c->components;
 662             my $check = $appclass."::Controller::".$name;
 663             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 664         }
 665         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 666         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 667         return $c->_filter_component( $result[ 0 ], @args );
 668     }
 669
 670     return $c->component( $c->action->class );
 671 }
 672
 673 =head2 $c->model($name)
 674
 675 Gets a L<Catalyst::Model> instance by name.
 676
 677     $c->model('Foo')->do_stuff;
 678
 679 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 680
 681 If the name is omitted, it will look for
 682  - a model object in $c->stash->{current_model_instance}, then
 683  - a model name in $c->stash->{current_model}, then
 684  - a config setting 'default_model', or
 685  - check if there is only one model, and return it if that's the case.
 686
 687 If you want to search for models, pass in a regexp as the argument.
 688
 689     # find all models that start with Foo
 690     my @foo_models = $c->model(qr{^Foo});
 691
 692 =cut
 693
 694 sub model {
 695     my ( $c, $name, @args ) = @_;
 696     my $appclass = ref($c) || $c;
 697     if( $name ) {
 698         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 699             my $comps = $c->components;
 700             my $check = $appclass."::Model::".$name;
 701             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 702         }
 703         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 704         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 705         return $c->_filter_component( $result[ 0 ], @args );
 706     }
 707
 708     if (ref $c) {
 709         return $c->stash->{current_model_instance}
 710           if $c->stash->{current_model_instance};
 711         return $c->model( $c->stash->{current_model} )
 712           if $c->stash->{current_model};
 713     }
 714     return $c->model( $appclass->config->{default_model} )
 715       if $appclass->config->{default_model};
 716
 717     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 718
 719     if( $rest ) {
 720         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 721         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 722         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 723         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 724         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 725     }
 726
 727     return $c->_filter_component( $comp );
 728 }
 729
 730
 731 =head2 $c->view($name)
 732
 733 Gets a L<Catalyst::View> instance by name.
 734
 735     $c->view('Foo')->do_stuff;
 736
 737 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 738
 739 If the name is omitted, it will look for
 740  - a view object in $c->stash->{current_view_instance}, then
 741  - a view name in $c->stash->{current_view}, then
 742  - a config setting 'default_view', or
 743  - check if there is only one view, and return it if that's the case.
 744
 745 If you want to search for views, pass in a regexp as the argument.
 746
 747     # find all views that start with Foo
 748     my @foo_views = $c->view(qr{^Foo});
 749
 750 =cut
 751
 752 sub view {
 753     my ( $c, $name, @args ) = @_;
 754
 755     my $appclass = ref($c) || $c;
 756     if( $name ) {
 757         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 758             my $comps = $c->components;
 759             my $check = $appclass."::View::".$name;
 760             if( exists $comps->{$check} ) {
 761                 return $c->_filter_component( $comps->{$check}, @args );
 762             }
 763             else {
 764                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 765             }
 766         }
 767         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 768         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 769         return $c->_filter_component( $result[ 0 ], @args );
 770     }
 771
 772     if (ref $c) {
 773         return $c->stash->{current_view_instance}
 774           if $c->stash->{current_view_instance};
 775         return $c->view( $c->stash->{current_view} )
 776           if $c->stash->{current_view};
 777     }
 778     return $c->view( $appclass->config->{default_view} )
 779       if $appclass->config->{default_view};
 780
 781     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 782
 783     if( $rest ) {
 784         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 785         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 786         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 787         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 788         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 789     }
 790
 791     return $c->_filter_component( $comp );
 792 }
 793
 794 =head2 $c->controllers
 795
 796 Returns the available names which can be passed to $c->controller
 797
 798 =cut
 799
 800 sub controllers {
 801     my ( $c ) = @_;
 802     return $c->_comp_names(qw/Controller C/);
 803 }
 804
 805 =head2 $c->models
 806
 807 Returns the available names which can be passed to $c->model
 808
 809 =cut
 810
 811 sub models {
 812     my ( $c ) = @_;
 813     return $c->_comp_names(qw/Model M/);
 814 }
 815
 816
 817 =head2 $c->views
 818
 819 Returns the available names which can be passed to $c->view
 820
 821 =cut
 822
 823 sub views {
 824     my ( $c ) = @_;
 825     return $c->_comp_names(qw/View V/);
 826 }
 827
 828 =head2 $c->comp($name)
 829
 830 =head2 $c->component($name)
 831
 832 Gets a component object by name. This method is not recommended,
 833 unless you want to get a specific component by full
 834 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 835 should be used instead.
 836
 837 If C<$name> is a regexp, a list of components matched against the full
 838 component name will be returned.
 839
 840 If Catalyst can't find a component by name, it will fallback to regex
 841 matching by default. To disable this behaviour set
 842 disable_component_resolution_regex_fallback to a true value.
 843
 844     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 845
 846 =cut
 847
 848 sub component {
 849     my ( $c, $name, @args ) = @_;
 850
 851     if( $name ) {
 852         my $comps = $c->components;
 853
 854         if( !ref $name ) {
 855             # is it the exact name?
 856             return $c->_filter_component( $comps->{ $name }, @args )
 857                        if exists $comps->{ $name };
 858
 859             # perhaps we just omitted "MyApp"?
 860             my $composed = ( ref $c || $c ) . "::${name}";
 861             return $c->_filter_component( $comps->{ $composed }, @args )
 862                        if exists $comps->{ $composed };
 863
 864             # search all of the models, views and controllers
 865             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 866             return $c->_filter_component( $comp, @args ) if $comp;
 867         }
 868
 869         # This is here so $c->comp( '::M::' ) works
 870         my $query = ref $name ? $name : qr{$name}i;
 871
 872         my @result = grep { m{$query} } keys %{ $c->components };
 873         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 874
 875         if( $result[ 0 ] ) {
 876             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 877             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 878             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 879             return $c->_filter_component( $result[ 0 ], @args );
 880         }
 881
 882         # I would expect to return an empty list here, but that breaks back-compat
 883     }
 884
 885     # fallback
 886     return sort keys %{ $c->components };
 887 }
 888
 889 =head2 CLASS DATA AND HELPER CLASSES
 890
 891 =head2 $c->config
 892
 893 Returns or takes a hashref containing the application's configuration.
 894
 895     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 896
 897 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 898 like C<myapp.conf> in your applications home directory. See
 899 L<Catalyst::Plugin::ConfigLoader>.
 900
 901 =head3 Cascading configuration
 902
 903 The config method is present on all Catalyst components, and configuration
 904 will be merged when an application is started. Configuration loaded with
 905 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 906 followed by configuration in your top level C<MyApp> class. These two
 907 configurations are merged, and then configuration data whose hash key matches a
 908 component name is merged with configuration for that component.
 909
 910 The configuration for a component is then passed to the C<new> method when a
 911 component is constructed.
 912
 913 For example:
 914
 915     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 916     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 917
 918 will mean that C<MyApp::Model::Foo> receives the following data when
 919 constructed:
 920
 921     MyApp::Model::Foo->new({
 922         bar => 'baz',
 923         quux => 'frob',
 924         overrides => 'me',
 925     });
 926
 927 It's common practice to use a Moose attribute
 928 on the receiving component to access the config value.
 929
 930     package MyApp::Model::Foo;
 931
 932     use Moose;
 933
 934     # this attr will receive 'baz' at construction time
 935     has 'bar' => (
 936         is  => 'rw',
 937         isa => 'Str',
 938     );
 939
 940 You can then get the value 'baz' by calling $c->model('Foo')->bar
 941 (or $self->bar inside code in the model).
 942
 943 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 944 as a way of reading config within your code, as this B<will not> give you the
 945 correctly merged config back. You B<MUST> take the config values supplied to
 946 the constructor and use those instead.
 947
 948 =cut
 949
 950 around config => sub {
 951     my $orig = shift;
 952     my $c = shift;
 953
 954     croak('Setting config after setup has been run is not allowed.')
 955         if ( @_ and $c->setup_finished );
 956
 957     $c->$orig(@_);
 958 };
 959
 960 =head2 $c->log
 961
 962 Returns the logging object instance. Unless it is already set, Catalyst
 963 sets this up with a L<Catalyst::Log> object. To use your own log class,
 964 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 965 C<< __PACKAGE__->setup >>.
 966
 967  __PACKAGE__->log( MyLogger->new );
 968  __PACKAGE__->setup;
 969
 970 And later:
 971
 972     $c->log->info( 'Now logging with my own logger!' );
 973
 974 Your log class should implement the methods described in
 975 L<Catalyst::Log>.
 976
 977
 978 =head2 $c->debug
 979
 980 Returns 1 if debug mode is enabled, 0 otherwise.
 981
 982 You can enable debug mode in several ways:
 983
 984 =over
 985
 986 =item By calling myapp_server.pl with the -d flag
 987
 988 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 989
 990 =item The -Debug option in your MyApp.pm
 991
 992 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 993
 994 =back
 995
 996 The first three also set the log level to 'debug'.
 997
 998 Calling C<< $c->debug(1) >> has no effect.
 999
1000 =cut
1001
1002 sub debug { 0 }
1003
1004 =head2 $c->dispatcher
1005
1006 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1007
1008 =head2 $c->engine
1009
1010 Returns the engine instance. See L<Catalyst::Engine>.
1011
1012
1013 =head2 UTILITY METHODS
1014
1015 =head2 $c->path_to(@path)
1016
1017 Merges C<@path> with C<< $c->config->{home} >> and returns a
1018 L<Path::Class::Dir> object. Note you can usually use this object as
1019 a filename, but sometimes you will have to explicitly stringify it
1020 yourself by calling the C<< ->stringify >> method.
1021
1022 For example:
1023
1024     $c->path_to( 'db', 'sqlite.db' );
1025
1026 =cut
1027
1028 sub path_to {
1029     my ( $c, @path ) = @_;
1030     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1031     if ( -d $path ) { return $path }
1032     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1033 }
1034
1035 =head2 $c->plugin( $name, $class, @args )
1036
1037 Helper method for plugins. It creates a class data accessor/mutator and
1038 loads and instantiates the given class.
1039
1040     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1041
1042     $c->prototype->define_javascript_functions;
1043
1044 B<Note:> This method of adding plugins is deprecated. The ability
1045 to add plugins like this B<will be removed> in a Catalyst 5.81.
1046 Please do not use this functionality in new code.
1047
1048 =cut
1049
1050 sub plugin {
1051     my ( $class, $name, $plugin, @args ) = @_;
1052
1053     # See block comment in t/unit_core_plugin.t
1054     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1055
1056     $class->_register_plugin( $plugin, 1 );
1057
1058     eval { $plugin->import };
1059     $class->mk_classdata($name);
1060     my $obj;
1061     eval { $obj = $plugin->new(@args) };
1062
1063     if ($@) {
1064         Catalyst::Exception->throw( message =>
1065               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1066     }
1067
1068     $class->$name($obj);
1069     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1070       if $class->debug;
1071 }
1072
1073 =head2 MyApp->setup
1074
1075 Initializes the dispatcher and engine, loads any plugins, and loads the
1076 model, view, and controller components. You may also specify an array
1077 of plugins to load here, if you choose to not load them in the C<use
1078 Catalyst> line.
1079
1080     MyApp->setup;
1081     MyApp->setup( qw/-Debug/ );
1082
1083 =cut
1084
1085 sub setup {
1086     my ( $class, @arguments ) = @_;
1087     croak('Running setup more than once')
1088         if ( $class->setup_finished );
1089
1090     unless ( $class->isa('Catalyst') ) {
1091
1092         Catalyst::Exception->throw(
1093             message => qq/'$class' does not inherit from Catalyst/ );
1094     }
1095
1096     if ( $class->arguments ) {
1097         @arguments = ( @arguments, @{ $class->arguments } );
1098     }
1099
1100     # Process options
1101     my $flags = {};
1102
1103     foreach (@arguments) {
1104
1105         if (/^-Debug$/) {
1106             $flags->{log} =
1107               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1108         }
1109         elsif (/^-(\w+)=?(.*)$/) {
1110             $flags->{ lc $1 } = $2;
1111         }
1112         else {
1113             push @{ $flags->{plugins} }, $_;
1114         }
1115     }
1116
1117     $class->setup_home( delete $flags->{home} );
1118
1119     $class->setup_log( delete $flags->{log} );
1120     $class->setup_plugins( delete $flags->{plugins} );
1121     $class->setup_dispatcher( delete $flags->{dispatcher} );
1122     if (my $engine = delete $flags->{engine}) {
1123         $class->log->warn("Specifying the engine in ->setup is no longer supported, XXX FIXME");
1124     }
1125     $class->setup_engine();
1126     $class->setup_stats( delete $flags->{stats} );
1127
1128     for my $flag ( sort keys %{$flags} ) {
1129
1130         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1131             &$code( $class, delete $flags->{$flag} );
1132         }
1133         else {
1134             $class->log->warn(qq/Unknown flag "$flag"/);
1135         }
1136     }
1137
1138     eval { require Catalyst::Devel; };
1139     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1140         $class->log->warn(<<"EOF");
1141 You are running an old script!
1142
1143   Please update by running (this will overwrite existing files):
1144     catalyst.pl -force -scripts $class
1145
1146   or (this will not overwrite existing files):
1147     catalyst.pl -scripts $class
1148
1149 EOF
1150     }
1151
1152     if ( $class->debug ) {
1153         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1154
1155         if (@plugins) {
1156             my $column_width = Catalyst::Utils::term_width() - 6;
1157             my $t = Text::SimpleTable->new($column_width);
1158             $t->row($_) for @plugins;
1159             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1160         }
1161
1162         my $dispatcher = $class->dispatcher;
1163         my $engine     = $class->engine;
1164         my $home       = $class->config->{home};
1165
1166         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1167         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1168
1169         $home
1170           ? ( -d $home )
1171           ? $class->log->debug(qq/Found home "$home"/)
1172           : $class->log->debug(qq/Home "$home" doesn't exist/)
1173           : $class->log->debug(q/Couldn't find home/);
1174     }
1175
1176     # Call plugins setup, this is stupid and evil.
1177     # Also screws C3 badly on 5.10, hack to avoid.
1178     {
1179         no warnings qw/redefine/;
1180         local *setup = sub { };
1181         $class->setup unless $Catalyst::__AM_RESTARTING;
1182     }
1183
1184     # Initialize our data structure
1185     $class->components( {} );
1186
1187     $class->setup_components;
1188
1189     if ( $class->debug ) {
1190         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1191         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1192         for my $comp ( sort keys %{ $class->components } ) {
1193             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1194             $t->row( $comp, $type );
1195         }
1196         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1197           if ( keys %{ $class->components } );
1198     }
1199
1200     # Add our self to components, since we are also a component
1201     if( $class->isa('Catalyst::Controller') ){
1202       $class->components->{$class} = $class;
1203     }
1204
1205     $class->setup_actions;
1206
1207     if ( $class->debug ) {
1208         my $name = $class->config->{name} || 'Application';
1209         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1210     }
1211
1212     # Make sure that the application class becomes immutable at this point,
1213     B::Hooks::EndOfScope::on_scope_end {
1214         return if $@;
1215         my $meta = Class::MOP::get_metaclass_by_name($class);
1216         if (
1217             $meta->is_immutable
1218             && ! { $meta->immutable_options }->{replace_constructor}
1219             && (
1220                    $class->isa('Class::Accessor::Fast')
1221                 || $class->isa('Class::Accessor')
1222             )
1223         ) {
1224             warn "You made your application class ($class) immutable, "
1225                 . "but did not inline the\nconstructor. "
1226                 . "This will break catalyst, as your app \@ISA "
1227                 . "Class::Accessor(::Fast)?\nPlease pass "
1228                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1229         }
1230         $meta->make_immutable(
1231             replace_constructor => 1,
1232         ) unless $meta->is_immutable;
1233     };
1234
1235     if ($class->config->{case_sensitive}) {
1236         $class->log->warn($class . "->config->{case_sensitive} is set.");
1237         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1238     }
1239
1240     $class->setup_finalize;
1241     # Should be the last thing we do so that user things hooking
1242     # setup_finalize can log..
1243     $class->log->_flush() if $class->log->can('_flush');
1244     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1245 }
1246
1247 =head2 $app->setup_finalize
1248
1249 A hook to attach modifiers to. This method does not do anything except set the
1250 C<setup_finished> accessor.
1251
1252 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1253
1254 Example:
1255
1256     after setup_finalize => sub {
1257         my $app = shift;
1258
1259         ## do stuff here..
1260     };
1261
1262 =cut
1263
1264 sub setup_finalize {
1265     my ($class) = @_;
1266     $class->setup_finished(1);
1267 }
1268
1269 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1270
1271 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1272
1273 Constructs an absolute L<URI> object based on the application root, the
1274 provided path, and the additional arguments and query parameters provided.
1275 When used as a string, provides a textual URI.  If you need more flexibility
1276 than this (i.e. the option to provide relative URIs etc.) see
1277 L<Catalyst::Plugin::SmartURI>.
1278
1279 If no arguments are provided, the URI for the current action is returned.
1280 To return the current action and also provide @args, use
1281 C<< $c->uri_for( $c->action, @args ) >>.
1282
1283 If the first argument is a string, it is taken as a public URI path relative
1284 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1285 relative to the application root (if it does). It is then merged with
1286 C<< $c->request->base >>; any C<@args> are appended as additional path
1287 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1288
1289 If the first argument is a L<Catalyst::Action> it represents an action which
1290 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1291 optional C<\@captures> argument (an arrayref) allows passing the captured
1292 variables that are needed to fill in the paths of Chained and Regex actions;
1293 once the path is resolved, C<uri_for> continues as though a path was
1294 provided, appending any arguments or parameters and creating an absolute
1295 URI.
1296
1297 The captures for the current request can be found in
1298 C<< $c->request->captures >>, and actions can be resolved using
1299 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1300 path, use C<< $c->uri_for_action >> instead.
1301
1302   # Equivalent to $c->req->uri
1303   $c->uri_for($c->action, $c->req->captures,
1304       @{ $c->req->args }, $c->req->params);
1305
1306   # For the Foo action in the Bar controller
1307   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1308
1309   # Path to a static resource
1310   $c->uri_for('/static/images/logo.png');
1311
1312 =cut
1313
1314 sub uri_for {
1315     my ( $c, $path, @args ) = @_;
1316
1317     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1318         $path = $path->path_prefix;
1319         $path =~ s{/+\z}{};
1320         $path .= '/';
1321     }
1322
1323     undef($path) if (defined $path && $path eq '');
1324
1325     my $params =
1326       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1327
1328     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1329     foreach my $arg (@args) {
1330         utf8::encode($arg) if utf8::is_utf8($arg);
1331         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1332     }
1333
1334     if ( blessed($path) ) { # action object
1335         s|/|%2F|g for @args;
1336         my $captures = [ map { s|/|%2F|g; $_; }
1337                         ( scalar @args && ref $args[0] eq 'ARRAY'
1338                          ? @{ shift(@args) }
1339                          : ()) ];
1340
1341         foreach my $capture (@$captures) {
1342             utf8::encode($capture) if utf8::is_utf8($capture);
1343             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1344         }
1345
1346         my $action = $path;
1347         $path = $c->dispatcher->uri_for_action($action, $captures);
1348         if (not defined $path) {
1349             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1350                 if $c->debug;
1351             return undef;
1352         }
1353         $path = '/' if $path eq '';
1354     }
1355
1356     unshift(@args, $path);
1357
1358     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1359         my $namespace = $c->namespace;
1360         if (defined $path) { # cheesy hack to handle path '../foo'
1361            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1362         }
1363         unshift(@args, $namespace || '');
1364     }
1365
1366     # join args with '/', or a blank string
1367     my $args = join('/', grep { defined($_) } @args);
1368     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1369     $args =~ s!^/+!!;
1370     my $base = $c->req->base;
1371     my $class = ref($base);
1372     $base =~ s{(?<!/)$}{/};
1373
1374     my $query = '';
1375
1376     if (my @keys = keys %$params) {
1377       # somewhat lifted from URI::_query's query_form
1378       $query = '?'.join('&', map {
1379           my $val = $params->{$_};
1380           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1381           s/ /+/g;
1382           my $key = $_;
1383           $val = '' unless defined $val;
1384           (map {
1385               my $param = "$_";
1386               utf8::encode( $param ) if utf8::is_utf8($param);
1387               # using the URI::Escape pattern here so utf8 chars survive
1388               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1389               $param =~ s/ /+/g;
1390               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1391       } @keys);
1392     }
1393
1394     my $res = bless(\"${base}${args}${query}", $class);
1395     $res;
1396 }
1397
1398 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1399
1400 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1401
1402 =over
1403
1404 =item $path
1405
1406 A private path to the Catalyst action you want to create a URI for.
1407
1408 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1409 >> and passing the resulting C<$action> and the remaining arguments to C<<
1410 $c->uri_for >>.
1411
1412 You can also pass in a Catalyst::Action object, in which case it is passed to
1413 C<< $c->uri_for >>.
1414
1415 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1416
1417 For example, if the action looks like:
1418
1419  package MyApp::Controller::Users;
1420
1421  sub lst : Path('the-list') {}
1422
1423 You can use:
1424
1425  $c->uri_for_action('/users/lst')
1426
1427 and it will create the URI /users/the-list.
1428
1429 =back
1430
1431 =cut
1432
1433 sub uri_for_action {
1434     my ( $c, $path, @args ) = @_;
1435     my $action = blessed($path)
1436       ? $path
1437       : $c->dispatcher->get_action_by_path($path);
1438     unless (defined $action) {
1439       croak "Can't find action for path '$path'";
1440     }
1441     return $c->uri_for( $action, @args );
1442 }
1443
1444 =head2 $c->welcome_message
1445
1446 Returns the Catalyst welcome HTML page.
1447
1448 =cut
1449
1450 sub welcome_message {
1451     my $c      = shift;
1452     my $name   = $c->config->{name};
1453     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1454     my $prefix = Catalyst::Utils::appprefix( ref $c );
1455     $c->response->content_type('text/html; charset=utf-8');
1456     return <<"EOF";
1457 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1458     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1459 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1460     <head>
1461     <meta http-equiv="Content-Language" content="en" />
1462     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1463         <title>$name on Catalyst $VERSION</title>
1464         <style type="text/css">
1465             body {
1466                 color: #000;
1467                 background-color: #eee;
1468             }
1469             div#content {
1470                 width: 640px;
1471                 margin-left: auto;
1472                 margin-right: auto;
1473                 margin-top: 10px;
1474                 margin-bottom: 10px;
1475                 text-align: left;
1476                 background-color: #ccc;
1477                 border: 1px solid #aaa;
1478             }
1479             p, h1, h2 {
1480                 margin-left: 20px;
1481                 margin-right: 20px;
1482                 font-family: verdana, tahoma, sans-serif;
1483             }
1484             a {
1485                 font-family: verdana, tahoma, sans-serif;
1486             }
1487             :link, :visited {
1488                     text-decoration: none;
1489                     color: #b00;
1490                     border-bottom: 1px dotted #bbb;
1491             }
1492             :link:hover, :visited:hover {
1493                     color: #555;
1494             }
1495             div#topbar {
1496                 margin: 0px;
1497             }
1498             pre {
1499                 margin: 10px;
1500                 padding: 8px;
1501             }
1502             div#answers {
1503                 padding: 8px;
1504                 margin: 10px;
1505                 background-color: #fff;
1506                 border: 1px solid #aaa;
1507             }
1508             h1 {
1509                 font-size: 0.9em;
1510                 font-weight: normal;
1511                 text-align: center;
1512             }
1513             h2 {
1514                 font-size: 1.0em;
1515             }
1516             p {
1517                 font-size: 0.9em;
1518             }
1519             p img {
1520                 float: right;
1521                 margin-left: 10px;
1522             }
1523             span#appname {
1524                 font-weight: bold;
1525                 font-size: 1.6em;
1526             }
1527         </style>
1528     </head>
1529     <body>
1530         <div id="content">
1531             <div id="topbar">
1532                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1533                     $VERSION</h1>
1534              </div>
1535              <div id="answers">
1536                  <p>
1537                  <img src="$logo" alt="Catalyst Logo" />
1538                  </p>
1539                  <p>Welcome to the  world of Catalyst.
1540                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1541                     framework will make web development something you had
1542                     never expected it to be: Fun, rewarding, and quick.</p>
1543                  <h2>What to do now?</h2>
1544                  <p>That really depends  on what <b>you</b> want to do.
1545                     We do, however, provide you with a few starting points.</p>
1546                  <p>If you want to jump right into web development with Catalyst
1547                     you might want to start with a tutorial.</p>
1548 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1549 </pre>
1550 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1551 <pre>
1552 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1553 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1554 </code></pre>
1555                  <h2>What to do next?</h2>
1556                  <p>Next it's time to write an actual application. Use the
1557                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1558                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1559                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1560                     they can save you a lot of work.</p>
1561                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1562                     <p>Also, be sure to check out the vast and growing
1563                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1564                     you are likely to find what you need there.
1565                     </p>
1566
1567                  <h2>Need help?</h2>
1568                  <p>Catalyst has a very active community. Here are the main places to
1569                     get in touch with us.</p>
1570                  <ul>
1571                      <li>
1572                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1573                      </li>
1574                      <li>
1575                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1576                      </li>
1577                      <li>
1578                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1579                      </li>
1580                  </ul>
1581                  <h2>In conclusion</h2>
1582                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1583                     as we enjoyed making it. Please contact us if you have ideas
1584                     for improvement or other feedback.</p>
1585              </div>
1586          </div>
1587     </body>
1588 </html>
1589 EOF
1590 }
1591
1592 =head1 INTERNAL METHODS
1593
1594 These methods are not meant to be used by end users.
1595
1596 =head2 $c->components
1597
1598 Returns a hash of components.
1599
1600 =head2 $c->context_class
1601
1602 Returns or sets the context class.
1603
1604 =head2 $c->counter
1605
1606 Returns a hashref containing coderefs and execution counts (needed for
1607 deep recursion detection).
1608
1609 =head2 $c->depth
1610
1611 Returns the number of actions on the current internal execution stack.
1612
1613 =head2 $c->dispatch
1614
1615 Dispatches a request to actions.
1616
1617 =cut
1618
1619 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1620
1621 =head2 $c->dispatcher_class
1622
1623 Returns or sets the dispatcher class.
1624
1625 =head2 $c->dump_these
1626
1627 Returns a list of 2-element array references (name, structure) pairs
1628 that will be dumped on the error page in debug mode.
1629
1630 =cut
1631
1632 sub dump_these {
1633     my $c = shift;
1634     [ Request => $c->req ],
1635     [ Response => $c->res ],
1636     [ Stash => $c->stash ],
1637     [ Config => $c->config ];
1638 }
1639
1640 =head2 $c->engine_class
1641
1642 Returns or sets the engine class.
1643
1644 =head2 $c->execute( $class, $coderef )
1645
1646 Execute a coderef in given class and catch exceptions. Errors are available
1647 via $c->error.
1648
1649 =cut
1650
1651 sub execute {
1652     my ( $c, $class, $code ) = @_;
1653     $class = $c->component($class) || $class;
1654     $c->state(0);
1655
1656     if ( $c->depth >= $RECURSION ) {
1657         my $action = $code->reverse();
1658         $action = "/$action" unless $action =~ /->/;
1659         my $error = qq/Deep recursion detected calling "${action}"/;
1660         $c->log->error($error);
1661         $c->error($error);
1662         $c->state(0);
1663         return $c->state;
1664     }
1665
1666     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1667
1668     push( @{ $c->stack }, $code );
1669
1670     no warnings 'recursion';
1671     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1672     #      I have no idea how, ergo $ret (which appears to fix the issue)
1673     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1674
1675     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1676
1677     my $last = pop( @{ $c->stack } );
1678
1679     if ( my $error = $@ ) {
1680         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1681             $error->rethrow if $c->depth > 1;
1682         }
1683         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1684             $error->rethrow if $c->depth > 0;
1685         }
1686         else {
1687             unless ( ref $error ) {
1688                 no warnings 'uninitialized';
1689                 chomp $error;
1690                 my $class = $last->class;
1691                 my $name  = $last->name;
1692                 $error = qq/Caught exception in $class->$name "$error"/;
1693             }
1694             $c->error($error);
1695         }
1696         $c->state(0);
1697     }
1698     return $c->state;
1699 }
1700
1701 sub _stats_start_execute {
1702     my ( $c, $code ) = @_;
1703     my $appclass = ref($c) || $c;
1704     return if ( ( $code->name =~ /^_.*/ )
1705         && ( !$appclass->config->{show_internal_actions} ) );
1706
1707     my $action_name = $code->reverse();
1708     $c->counter->{$action_name}++;
1709
1710     my $action = $action_name;
1711     $action = "/$action" unless $action =~ /->/;
1712
1713     # determine if the call was the result of a forward
1714     # this is done by walking up the call stack and looking for a calling
1715     # sub of Catalyst::forward before the eval
1716     my $callsub = q{};
1717     for my $index ( 2 .. 11 ) {
1718         last
1719         if ( ( caller($index) )[0] eq 'Catalyst'
1720             && ( caller($index) )[3] eq '(eval)' );
1721
1722         if ( ( caller($index) )[3] =~ /forward$/ ) {
1723             $callsub = ( caller($index) )[3];
1724             $action  = "-> $action";
1725             last;
1726         }
1727     }
1728
1729     my $uid = $action_name . $c->counter->{$action_name};
1730
1731     # is this a root-level call or a forwarded call?
1732     if ( $callsub =~ /forward$/ ) {
1733         my $parent = $c->stack->[-1];
1734
1735         # forward, locate the caller
1736         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1737             $c->stats->profile(
1738                 begin  => $action,
1739                 parent => "$parent" . $c->counter->{"$parent"},
1740                 uid    => $uid,
1741             );
1742         }
1743         else {
1744
1745             # forward with no caller may come from a plugin
1746             $c->stats->profile(
1747                 begin => $action,
1748                 uid   => $uid,
1749             );
1750         }
1751     }
1752     else {
1753
1754         # root-level call
1755         $c->stats->profile(
1756             begin => $action,
1757             uid   => $uid,
1758         );
1759     }
1760     return $action;
1761
1762 }
1763
1764 sub _stats_finish_execute {
1765     my ( $c, $info ) = @_;
1766     $c->stats->profile( end => $info );
1767 }
1768
1769 =head2 $c->finalize
1770
1771 Finalizes the request.
1772
1773 =cut
1774
1775 sub finalize {
1776     my $c = shift;
1777
1778     for my $error ( @{ $c->error } ) {
1779         $c->log->error($error);
1780     }
1781
1782     # Allow engine to handle finalize flow (for POE)
1783     my $engine = $c->engine;
1784     if ( my $code = $engine->can('finalize') ) {
1785         $engine->$code($c);
1786     }
1787     else {
1788
1789         $c->finalize_uploads;
1790
1791         # Error
1792         if ( $#{ $c->error } >= 0 ) {
1793             $c->finalize_error;
1794         }
1795
1796         $c->finalize_headers;
1797
1798         # HEAD request
1799         if ( $c->request->method eq 'HEAD' ) {
1800             $c->response->body('');
1801         }
1802
1803         $c->finalize_body;
1804     }
1805
1806     $c->log_response;
1807
1808     if ($c->use_stats) {
1809         my $elapsed = sprintf '%f', $c->stats->elapsed;
1810         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1811         $c->log->info(
1812             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1813     }
1814
1815     return $c->response->status;
1816 }
1817
1818 =head2 $c->finalize_body
1819
1820 Finalizes body.
1821
1822 =cut
1823
1824 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1825
1826 =head2 $c->finalize_cookies
1827
1828 Finalizes cookies.
1829
1830 =cut
1831
1832 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1833
1834 =head2 $c->finalize_error
1835
1836 Finalizes error.
1837
1838 =cut
1839
1840 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1841
1842 =head2 $c->finalize_headers
1843
1844 Finalizes headers.
1845
1846 =cut
1847
1848 sub finalize_headers {
1849     my $c = shift;
1850
1851     my $response = $c->response; #accessor calls can add up?
1852
1853     # Check if we already finalized headers
1854     return if $response->finalized_headers;
1855
1856     # Handle redirects
1857     if ( my $location = $response->redirect ) {
1858         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1859         $response->header( Location => $location );
1860
1861         if ( !$response->has_body ) {
1862             # Add a default body if none is already present
1863             $response->body(
1864                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1865             );
1866         }
1867     }
1868
1869     # Content-Length
1870     if ( defined $response->body && length $response->body && !$response->content_length ) {
1871
1872         # get the length from a filehandle
1873         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1874         {
1875             my $size = -s $response->body;
1876             if ( $size ) {
1877                 $response->content_length( $size );
1878             }
1879             else {
1880                 $c->log->warn('Serving filehandle without a content-length');
1881             }
1882         }
1883         else {
1884             # everything should be bytes at this point, but just in case
1885             $response->content_length( length( $response->body ) );
1886         }
1887     }
1888
1889     # Errors
1890     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1891         $response->headers->remove_header("Content-Length");
1892         $response->body('');
1893     }
1894
1895     $c->finalize_cookies;
1896
1897     $c->engine->finalize_headers( $c, @_ );
1898
1899     # Done
1900     $response->finalized_headers(1);
1901 }
1902
1903 =head2 $c->finalize_output
1904
1905 An alias for finalize_body.
1906
1907 =head2 $c->finalize_read
1908
1909 Finalizes the input after reading is complete.
1910
1911 =cut
1912
1913 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1914
1915 =head2 $c->finalize_uploads
1916
1917 Finalizes uploads. Cleans up any temporary files.
1918
1919 =cut
1920
1921 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1922
1923 =head2 $c->get_action( $action, $namespace )
1924
1925 Gets an action in a given namespace.
1926
1927 =cut
1928
1929 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1930
1931 =head2 $c->get_actions( $action, $namespace )
1932
1933 Gets all actions of a given name in a namespace and all parent
1934 namespaces.
1935
1936 =cut
1937
1938 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1939
1940 =head2 $app->handle_request( @arguments )
1941
1942 Called to handle each HTTP request.
1943
1944 =cut
1945
1946 sub handle_request {
1947     my ( $class, @arguments ) = @_;
1948
1949     # Always expect worst case!
1950     my $status = -1;
1951     try {
1952         if ($class->debug) {
1953             my $secs = time - $START || 1;
1954             my $av = sprintf '%.3f', $COUNT / $secs;
1955             my $time = localtime time;
1956             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1957         }
1958
1959         my $c = $class->prepare(@arguments);
1960         $c->dispatch;
1961         $status = $c->finalize;
1962     }
1963     catch {
1964         chomp(my $error = $_);
1965         $class->log->error(qq/Caught exception in engine "$error"/);
1966     };
1967
1968     $COUNT++;
1969
1970     if(my $coderef = $class->log->can('_flush')){
1971         $class->log->$coderef();
1972     }
1973     return $status;
1974 }
1975
1976 =head2 $c->prepare( @arguments )
1977
1978 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1979 etc.).
1980
1981 =cut
1982
1983 sub prepare {
1984     my ( $class, @arguments ) = @_;
1985
1986     # XXX
1987     # After the app/ctxt split, this should become an attribute based on something passed
1988     # into the application.
1989     $class->context_class( ref $class || $class ) unless $class->context_class;
1990
1991     my $c = $class->context_class->new({});
1992
1993     # For on-demand data
1994     $c->request->_context($c);
1995     $c->response->_context($c);
1996
1997     #surely this is not the most efficient way to do things...
1998     $c->stats($class->stats_class->new)->enable($c->use_stats);
1999     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2000         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2001     }
2002
2003     try {
2004         # Allow engine to direct the prepare flow (for POE)
2005         if ( my $prepare = $c->engine->can('prepare') ) {
2006             $c->engine->$prepare( $c, @arguments );
2007         }
2008         else {
2009             $c->prepare_request(@arguments);
2010             $c->prepare_connection;
2011             $c->prepare_query_parameters;
2012             $c->prepare_headers;
2013             $c->prepare_cookies;
2014             $c->prepare_path;
2015
2016             # Prepare the body for reading, either by prepare_body
2017             # or the user, if they are using $c->read
2018             $c->prepare_read;
2019
2020             # Parse the body unless the user wants it on-demand
2021             unless ( ref($c)->config->{parse_on_demand} ) {
2022                 $c->prepare_body;
2023             }
2024         }
2025     }
2026     # VERY ugly and probably shouldn't rely on ->finalize actually working
2027     catch {
2028         # failed prepare is always due to an invalid request, right?
2029         $c->response->status(400);
2030         $c->response->content_type('text/plain');
2031         $c->response->body('Bad Request');
2032         $c->finalize;
2033         die $_;
2034     };
2035
2036     my $method  = $c->req->method  || '';
2037     my $path    = $c->req->path;
2038     $path       = '/' unless length $path;
2039     my $address = $c->req->address || '';
2040
2041     $c->log_request;
2042
2043     $c->prepare_action;
2044
2045     return $c;
2046 }
2047
2048 =head2 $c->prepare_action
2049
2050 Prepares action. See L<Catalyst::Dispatcher>.
2051
2052 =cut
2053
2054 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2055
2056 =head2 $c->prepare_body
2057
2058 Prepares message body.
2059
2060 =cut
2061
2062 sub prepare_body {
2063     my $c = shift;
2064
2065     return if $c->request->_has_body;
2066
2067     # Initialize on-demand data
2068     $c->engine->prepare_body( $c, @_ );
2069     $c->prepare_parameters;
2070     $c->prepare_uploads;
2071 }
2072
2073 =head2 $c->prepare_body_chunk( $chunk )
2074
2075 Prepares a chunk of data before sending it to L<HTTP::Body>.
2076
2077 See L<Catalyst::Engine>.
2078
2079 =cut
2080
2081 sub prepare_body_chunk {
2082     my $c = shift;
2083     $c->engine->prepare_body_chunk( $c, @_ );
2084 }
2085
2086 =head2 $c->prepare_body_parameters
2087
2088 Prepares body parameters.
2089
2090 =cut
2091
2092 sub prepare_body_parameters {
2093     my $c = shift;
2094     $c->engine->prepare_body_parameters( $c, @_ );
2095 }
2096
2097 =head2 $c->prepare_connection
2098
2099 Prepares connection.
2100
2101 =cut
2102
2103 sub prepare_connection {
2104     my $c = shift;
2105     $c->engine->prepare_connection( $c, @_ );
2106 }
2107
2108 =head2 $c->prepare_cookies
2109
2110 Prepares cookies.
2111
2112 =cut
2113
2114 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2115
2116 =head2 $c->prepare_headers
2117
2118 Prepares headers.
2119
2120 =cut
2121
2122 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2123
2124 =head2 $c->prepare_parameters
2125
2126 Prepares parameters.
2127
2128 =cut
2129
2130 sub prepare_parameters {
2131     my $c = shift;
2132     $c->prepare_body_parameters;
2133     $c->engine->prepare_parameters( $c, @_ );
2134 }
2135
2136 =head2 $c->prepare_path
2137
2138 Prepares path and base.
2139
2140 =cut
2141
2142 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2143
2144 =head2 $c->prepare_query_parameters
2145
2146 Prepares query parameters.
2147
2148 =cut
2149
2150 sub prepare_query_parameters {
2151     my $c = shift;
2152
2153     $c->engine->prepare_query_parameters( $c, @_ );
2154 }
2155
2156 =head2 $c->log_request
2157
2158 Writes information about the request to the debug logs.  This includes:
2159
2160 =over 4
2161
2162 =item * Request method, path, and remote IP address
2163
2164 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2165
2166 =item * Request parameters
2167
2168 =item * File uploads
2169
2170 =back
2171
2172 =cut
2173
2174 sub log_request {
2175     my $c = shift;
2176
2177     return unless $c->debug;
2178
2179     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2180     my $request = $dump->[1];
2181
2182     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2183     $method ||= '';
2184     $path = '/' unless length $path;
2185     $address ||= '';
2186     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2187
2188     $c->log_request_headers($request->headers);
2189
2190     if ( my $keywords = $request->query_keywords ) {
2191         $c->log->debug("Query keywords are: $keywords");
2192     }
2193
2194     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2195
2196     $c->log_request_uploads($request);
2197 }
2198
2199 =head2 $c->log_response
2200
2201 Writes information about the response to the debug logs by calling
2202 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2203
2204 =cut
2205
2206 sub log_response {
2207     my $c = shift;
2208
2209     return unless $c->debug;
2210
2211     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2212     my $response = $dump->[1];
2213
2214     $c->log_response_status_line($response);
2215     $c->log_response_headers($response->headers);
2216 }
2217
2218 =head2 $c->log_response_status_line($response)
2219
2220 Writes one line of information about the response to the debug logs.  This includes:
2221
2222 =over 4
2223
2224 =item * Response status code
2225
2226 =item * Content-Type header (if present)
2227
2228 =item * Content-Length header (if present)
2229
2230 =back
2231
2232 =cut
2233
2234 sub log_response_status_line {
2235     my ($c, $response) = @_;
2236
2237     $c->log->debug(
2238         sprintf(
2239             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2240             $response->status                            || 'unknown',
2241             $response->headers->header('Content-Type')   || 'unknown',
2242             $response->headers->header('Content-Length') || 'unknown'
2243         )
2244     );
2245 }
2246
2247 =head2 $c->log_response_headers($headers);
2248
2249 Hook method which can be wrapped by plugins to log the responseheaders.
2250 No-op in the default implementation.
2251
2252 =cut
2253
2254 sub log_response_headers {}
2255
2256 =head2 $c->log_request_parameters( query => {}, body => {} )
2257
2258 Logs request parameters to debug logs
2259
2260 =cut
2261
2262 sub log_request_parameters {
2263     my $c          = shift;
2264     my %all_params = @_;
2265
2266     return unless $c->debug;
2267
2268     my $column_width = Catalyst::Utils::term_width() - 44;
2269     foreach my $type (qw(query body)) {
2270         my $params = $all_params{$type};
2271         next if ! keys %$params;
2272         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2273         for my $key ( sort keys %$params ) {
2274             my $param = $params->{$key};
2275             my $value = defined($param) ? $param : '';
2276             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2277         }
2278         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2279     }
2280 }
2281
2282 =head2 $c->log_request_uploads
2283
2284 Logs file uploads included in the request to the debug logs.
2285 The parameter name, filename, file type, and file size are all included in
2286 the debug logs.
2287
2288 =cut
2289
2290 sub log_request_uploads {
2291     my $c = shift;
2292     my $request = shift;
2293     return unless $c->debug;
2294     my $uploads = $request->uploads;
2295     if ( keys %$uploads ) {
2296         my $t = Text::SimpleTable->new(
2297             [ 12, 'Parameter' ],
2298             [ 26, 'Filename' ],
2299             [ 18, 'Type' ],
2300             [ 9,  'Size' ]
2301         );
2302         for my $key ( sort keys %$uploads ) {
2303             my $upload = $uploads->{$key};
2304             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2305                 $t->row( $key, $u->filename, $u->type, $u->size );
2306             }
2307         }
2308         $c->log->debug( "File Uploads are:\n" . $t->draw );
2309     }
2310 }
2311
2312 =head2 $c->log_request_headers($headers);
2313
2314 Hook method which can be wrapped by plugins to log the request headers.
2315 No-op in the default implementation.
2316
2317 =cut
2318
2319 sub log_request_headers {}
2320
2321 =head2 $c->log_headers($type => $headers)
2322
2323 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2324
2325 =cut
2326
2327 sub log_headers {
2328     my $c       = shift;
2329     my $type    = shift;
2330     my $headers = shift;    # an HTTP::Headers instance
2331
2332     return unless $c->debug;
2333
2334     my $column_width = Catalyst::Utils::term_width() - 28;
2335     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2336     $headers->scan(
2337         sub {
2338             my ( $name, $value ) = @_;
2339             $t->row( $name, $value );
2340         }
2341     );
2342     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2343 }
2344
2345
2346 =head2 $c->prepare_read
2347
2348 Prepares the input for reading.
2349
2350 =cut
2351
2352 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2353
2354 =head2 $c->prepare_request
2355
2356 Prepares the engine request.
2357
2358 =cut
2359
2360 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2361
2362 =head2 $c->prepare_uploads
2363
2364 Prepares uploads.
2365
2366 =cut
2367
2368 sub prepare_uploads {
2369     my $c = shift;
2370
2371     $c->engine->prepare_uploads( $c, @_ );
2372 }
2373
2374 =head2 $c->prepare_write
2375
2376 Prepares the output for writing.
2377
2378 =cut
2379
2380 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2381
2382 =head2 $c->request_class
2383
2384 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2385
2386 =head2 $c->response_class
2387
2388 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2389
2390 =head2 $c->read( [$maxlength] )
2391
2392 Reads a chunk of data from the request body. This method is designed to
2393 be used in a while loop, reading C<$maxlength> bytes on every call.
2394 C<$maxlength> defaults to the size of the request if not specified.
2395
2396 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2397 directly.
2398
2399 Warning: If you use read(), Catalyst will not process the body,
2400 so you will not be able to access POST parameters or file uploads via
2401 $c->request.  You must handle all body parsing yourself.
2402
2403 =cut
2404
2405 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2406
2407 =head2 $c->run
2408
2409 Starts the engine.
2410
2411 =cut
2412
2413 sub run { my $c = shift; return $c->engine->run( $c, $c->_finalized_psgi_app, @_ ) }
2414
2415 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2416
2417 Sets an action in a given namespace.
2418
2419 =cut
2420
2421 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2422
2423 =head2 $c->setup_actions($component)
2424
2425 Sets up actions for a component.
2426
2427 =cut
2428
2429 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2430
2431 =head2 $c->setup_components
2432
2433 This method is called internally to set up the application's components.
2434
2435 It finds modules by calling the L<locate_components> method, expands them to
2436 package names with the L<expand_component_module> method, and then installs
2437 each component into the application.
2438
2439 The C<setup_components> config option is passed to both of the above methods.
2440
2441 Installation of each component is performed by the L<setup_component> method,
2442 below.
2443
2444 =cut
2445
2446 sub setup_components {
2447     my $class = shift;
2448
2449     my $config  = $class->config->{ setup_components };
2450
2451     my @comps = $class->locate_components($config);
2452     my %comps = map { $_ => 1 } @comps;
2453
2454     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2455     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2456         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2457     ) if $deprecatedcatalyst_component_names;
2458
2459     for my $component ( @comps ) {
2460
2461         # We pass ignore_loaded here so that overlay files for (e.g.)
2462         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2463         # we know M::P::O found a file on disk so this is safe
2464
2465         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2466     }
2467
2468     for my $component (@comps) {
2469         my $instance = $class->components->{ $component } = $class->setup_component($component);
2470         my @expanded_components = $instance->can('expand_modules')
2471             ? $instance->expand_modules( $component, $config )
2472             : $class->expand_component_module( $component, $config );
2473         for my $component (@expanded_components) {
2474             next if $comps{$component};
2475             $class->components->{ $component } = $class->setup_component($component);
2476         }
2477     }
2478 }
2479
2480 =head2 $c->locate_components( $setup_component_config )
2481
2482 This method is meant to provide a list of component modules that should be
2483 setup for the application.  By default, it will use L<Module::Pluggable>.
2484
2485 Specify a C<setup_components> config option to pass additional options directly
2486 to L<Module::Pluggable>. To add additional search paths, specify a key named
2487 C<search_extra> as an array reference. Items in the array beginning with C<::>
2488 will have the application class name prepended to them.
2489
2490 =cut
2491
2492 sub locate_components {
2493     my $class  = shift;
2494     my $config = shift;
2495
2496     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2497     my $extra   = delete $config->{ search_extra } || [];
2498
2499     push @paths, @$extra;
2500
2501     my $locator = Module::Pluggable::Object->new(
2502         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2503         %$config
2504     );
2505
2506     # XXX think about ditching this sort entirely
2507     my @comps = sort { length $a <=> length $b } $locator->plugins;
2508
2509     return @comps;
2510 }
2511
2512 =head2 $c->expand_component_module( $component, $setup_component_config )
2513
2514 Components found by C<locate_components> will be passed to this method, which
2515 is expected to return a list of component (package) names to be set up.
2516
2517 =cut
2518
2519 sub expand_component_module {
2520     my ($class, $module) = @_;
2521     return Devel::InnerPackage::list_packages( $module );
2522 }
2523
2524 =head2 $c->setup_component
2525
2526 =cut
2527
2528 sub setup_component {
2529     my( $class, $component ) = @_;
2530
2531     unless ( $component->can( 'COMPONENT' ) ) {
2532         return $component;
2533     }
2534
2535     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2536     my $config = $class->config->{ $suffix } || {};
2537     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2538     # methods also pass it. local to avoid pointlessly shitting in config
2539     # for the debug screen, as $component is already the key name.
2540     local $config->{catalyst_component_name} = $component;
2541
2542     my $instance = eval { $component->COMPONENT( $class, $config ); };
2543
2544     if ( my $error = $@ ) {
2545         chomp $error;
2546         Catalyst::Exception->throw(
2547             message => qq/Couldn't instantiate component "$component", "$error"/
2548         );
2549     }
2550
2551     unless (blessed $instance) {
2552         my $metaclass = Moose::Util::find_meta($component);
2553         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2554         my $component_method_from = $method_meta->associated_metaclass->name;
2555         my $value = defined($instance) ? $instance : 'undef';
2556         Catalyst::Exception->throw(
2557             message =>
2558             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2559         );
2560     }
2561     return $instance;
2562 }
2563
2564 =head2 $c->setup_dispatcher
2565
2566 Sets up dispatcher.
2567
2568 =cut
2569
2570 sub setup_dispatcher {
2571     my ( $class, $dispatcher ) = @_;
2572
2573     if ($dispatcher) {
2574         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2575     }
2576
2577     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2578         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2579     }
2580
2581     unless ($dispatcher) {
2582         $dispatcher = $class->dispatcher_class;
2583     }
2584
2585     Class::MOP::load_class($dispatcher);
2586
2587     # dispatcher instance
2588     $class->dispatcher( $dispatcher->new );
2589 }
2590
2591 =head2 $c->setup_engine
2592
2593 Sets up engine.
2594
2595 =cut
2596
2597 sub engine_class {
2598     my $class = shift;
2599     $class->engine_loader->catalyst_engine_class(@_);
2600 }
2601
2602 sub setup_engine {
2603     my ($class, $requested_engine) = @_;
2604
2605     $class->engine_loader(
2606         Catalyst::EngineLoader->new({
2607             application_name => $class,
2608             (defined $requested_engine
2609                  ? (requested_engine => $requested_engine) : ()),
2610         }),
2611     );
2612
2613     my $engine = $class->engine_class;
2614     Class::MOP::load_class($engine);
2615
2616     if ($ENV{MOD_PERL}) {
2617         my $apache = $class->engine_loader->auto;
2618         # FIXME - Immutable
2619         $class->meta->add_method(handler => sub {
2620             my $r = shift;
2621             my $psgi_app = $class->psgi_app;
2622             $apache->call_app($r, $psgi_app);
2623         });
2624     }
2625
2626     $class->engine( $engine->new );
2627
2628     return;
2629 }
2630
2631 sub _finalized_psgi_app {
2632     my ($app) = @_;
2633
2634     unless ($app->_psgi_app) {
2635         my $psgi_app = $app->_setup_psgi_app;
2636         $app->_psgi_app($psgi_app);
2637     }
2638
2639     return $app->_psgi_app;
2640 }
2641
2642 sub _setup_psgi_app {
2643     my ($app) = @_;
2644
2645     for my $home (Path::Class::Dir->new($app->config->{home})) {
2646         my $psgi_file = $home->file(
2647             Catalyst::Utils::appprefix($app) . '.psgi',
2648         );
2649
2650         next unless -e $psgi_file;
2651         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2652
2653         return $psgi_app
2654             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2655
2656         # load_psgi ran a .psgi file doing ->setup_engine('PSGI'). That's what
2657         # .psgi files generated by the old Engine::PSGI do. Those return an app
2658         # coderef calling into MyApp->run, which doesn't work anymore, so we're
2659         # just ignoring it and use the wrapped legacy psgi app
2660         warn <<"EOW";
2661 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2662
2663 Its content has been ignored. Please consult the Catalyst::Upgrading
2664 documentation on how to upgrade from Catalyst::Engine::PSGI.
2665 EOW
2666     }
2667
2668     return $app->apply_default_middlewares($app->psgi_app);
2669 }
2670
2671 =head2 $c->apply_default_middlewares
2672
2673 Adds the following L<Plack> middlewares to your application, since they are
2674 useful and commonly needed:
2675
2676 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2677 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2678 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2679 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2680 applied since this middleware is smart enough to conditionally apply itself).
2681
2682 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2683 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2684 $ENV{SCRIPT_NAME}
2685
2686 =cut
2687
2688
2689 sub apply_default_middlewares {
2690     my ($app, $psgi_app) = @_;
2691
2692     $psgi_app = Plack::Middleware::Conditional->wrap(
2693         $psgi_app,
2694         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2695         condition => sub {
2696             my ($env) = @_;
2697             return if $app->config->{ignore_frontend_proxy};
2698             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2699                 || $app->config->{using_frontend_proxy};
2700         },
2701     );
2702
2703     my $server_matches = sub {
2704         my ($re) = @_;
2705         return sub {
2706             my ($env) = @_;
2707             my $server = $env->{SERVER_SOFTWARE};
2708             return unless $server;
2709             return $server =~ $re ? 1 : 0;
2710         };
2711     };
2712
2713     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2714     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2715     $psgi_app = Plack::Middleware::LighttpdScriptNameFix->wrap($psgi_app);
2716
2717     $psgi_app = Plack::Middleware::Conditional->wrap(
2718         $psgi_app,
2719         condition => $server_matches->(qr/^nginx/),
2720         builder   => sub {
2721             my ($to_wrap) = @_;
2722             return sub {
2723                 my ($env) = @_;
2724                 my $script_name = $env->{SCRIPT_NAME};
2725                 $env->{PATH_INFO} =~ s/^$script_name//g;
2726                 return $to_wrap->($env);
2727             };
2728         },
2729     );
2730
2731     # we're applying this unconditionally as the middleware itself already makes
2732     # sure it doesn't fuck things up if it's not running under one of the right
2733     # IIS versions
2734     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2735
2736     return $psgi_app;
2737 }
2738
2739 =head2 $c->psgi_app
2740
2741 Returns a PSGI application code reference for the catalyst application
2742 C<$c>. This is the bare application without any middlewares
2743 applied. C<${myapp}.psgi> is not taken into account.
2744
2745 This is what you want to be using to retrieve the PSGI application code
2746 reference of your Catalyst application for use in F<.psgi> files.
2747
2748 =cut
2749
2750 sub psgi_app {
2751     my ($app) = @_;
2752     return $app->engine->build_psgi_app($app);
2753 }
2754
2755 =head2 $c->setup_home
2756
2757 Sets up the home directory.
2758
2759 =cut
2760
2761 sub setup_home {
2762     my ( $class, $home ) = @_;
2763
2764     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2765         $home = $env;
2766     }
2767
2768     $home ||= Catalyst::Utils::home($class);
2769
2770     if ($home) {
2771         #I remember recently being scolded for assigning config values like this
2772         $class->config->{home} ||= $home;
2773         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2774     }
2775 }
2776
2777 =head2 $c->setup_log
2778
2779 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2780 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2781 log to.
2782
2783 This method also installs a C<debug> method that returns a true value into the
2784 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2785 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2786
2787 Note that if the log has already been setup, by either a previous call to
2788 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2789 that this method won't actually set up the log object.
2790
2791 =cut
2792
2793 sub setup_log {
2794     my ( $class, $levels ) = @_;
2795
2796     $levels ||= '';
2797     $levels =~ s/^\s+//;
2798     $levels =~ s/\s+$//;
2799     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2800
2801     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2802     if ( defined $env_debug ) {
2803         $levels{debug} = 1 if $env_debug; # Ugly!
2804         delete($levels{debug}) unless $env_debug;
2805     }
2806
2807     unless ( $class->log ) {
2808         $class->log( Catalyst::Log->new(keys %levels) );
2809     }
2810
2811     if ( $levels{debug} ) {
2812         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2813         $class->log->debug('Debug messages enabled');
2814     }
2815 }
2816
2817 =head2 $c->setup_plugins
2818
2819 Sets up plugins.
2820
2821 =cut
2822
2823 =head2 $c->setup_stats
2824
2825 Sets up timing statistics class.
2826
2827 =cut
2828
2829 sub setup_stats {
2830     my ( $class, $stats ) = @_;
2831
2832     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2833
2834     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2835     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2836         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2837         $class->log->debug('Statistics enabled');
2838     }
2839 }
2840
2841
2842 =head2 $c->registered_plugins
2843
2844 Returns a sorted list of the plugins which have either been stated in the
2845 import list or which have been added via C<< MyApp->plugin(@args); >>.
2846
2847 If passed a given plugin name, it will report a boolean value indicating
2848 whether or not that plugin is loaded.  A fully qualified name is required if
2849 the plugin name does not begin with C<Catalyst::Plugin::>.
2850
2851  if ($c->registered_plugins('Some::Plugin')) {
2852      ...
2853  }
2854
2855 =cut
2856
2857 {
2858
2859     sub registered_plugins {
2860         my $proto = shift;
2861         return sort keys %{ $proto->_plugins } unless @_;
2862         my $plugin = shift;
2863         return 1 if exists $proto->_plugins->{$plugin};
2864         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2865     }
2866
2867     sub _register_plugin {
2868         my ( $proto, $plugin, $instant ) = @_;
2869         my $class = ref $proto || $proto;
2870
2871         Class::MOP::load_class( $plugin );
2872         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2873             if $plugin->isa( 'Catalyst::Component' );
2874         $proto->_plugins->{$plugin} = 1;
2875         unless ($instant) {
2876             my $meta = Class::MOP::get_metaclass_by_name($class);
2877             $meta->superclasses($plugin, $meta->superclasses);
2878         }
2879         return $class;
2880     }
2881
2882     sub setup_plugins {
2883         my ( $class, $plugins ) = @_;
2884
2885         $class->_plugins( {} ) unless $class->_plugins;
2886         $plugins = Data::OptList::mkopt($plugins || []);
2887
2888         my @plugins = map {
2889             [ Catalyst::Utils::resolve_namespace(
2890                   $class . '::Plugin',
2891                   'Catalyst::Plugin', $_->[0]
2892               ),
2893               $_->[1],
2894             ]
2895          } @{ $plugins };
2896
2897         for my $plugin ( reverse @plugins ) {
2898             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2899             my $meta = find_meta($plugin->[0]);
2900             next if $meta && $meta->isa('Moose::Meta::Role');
2901
2902             $class->_register_plugin($plugin->[0]);
2903         }
2904
2905         my @roles =
2906             map  { $_->[0]->name, $_->[1] }
2907             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2908             map  { [find_meta($_->[0]), $_->[1]] }
2909             @plugins;
2910
2911         Moose::Util::apply_all_roles(
2912             $class => @roles
2913         ) if @roles;
2914     }
2915 }
2916
2917 =head2 $c->stack
2918
2919 Returns an arrayref of the internal execution stack (actions that are
2920 currently executing).
2921
2922 =head2 $c->stats
2923
2924 Returns the current timing statistics object. By default Catalyst uses
2925 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2926 L<< stats_class|/"$c->stats_class" >>.
2927
2928 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2929 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2930 profile explicitly, although MyApp.pm still won't profile nor output anything
2931 by itself.
2932
2933 =head2 $c->stats_class
2934
2935 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2936
2937 =head2 $c->use_stats
2938
2939 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2940
2941 Note that this is a static method, not an accessor and should be overridden
2942 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2943
2944 =cut
2945
2946 sub use_stats { 0 }
2947
2948
2949 =head2 $c->write( $data )
2950
2951 Writes $data to the output stream. When using this method directly, you
2952 will need to manually set the C<Content-Length> header to the length of
2953 your output data, if known.
2954
2955 =cut
2956
2957 sub write {
2958     my $c = shift;
2959
2960     # Finalize headers if someone manually writes output
2961     $c->finalize_headers;
2962
2963     return $c->engine->write( $c, @_ );
2964 }
2965
2966 =head2 version
2967
2968 Returns the Catalyst version number. Mostly useful for "powered by"
2969 messages in template systems.
2970
2971 =cut
2972
2973 sub version { return $Catalyst::VERSION }
2974
2975 =head1 CONFIGURATION
2976
2977 There are a number of 'base' config variables which can be set:
2978
2979 =over
2980
2981 =item *
2982
2983 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2984
2985 =item *
2986
2987 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2988
2989 =item *
2990
2991 C<disable_component_resolution_regex_fallback> - Turns
2992 off the deprecated component resolution functionality so
2993 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2994 are called then regex search will not be attempted on string values and
2995 instead C<undef> will be returned.
2996
2997 =item *
2998
2999 C<home> - The application home directory. In an uninstalled application,
3000 this is the top level application directory. In an installed application,
3001 this will be the directory containing C<< MyApp.pm >>.
3002
3003 =item *
3004
3005 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3006
3007 =item *
3008
3009 C<name> - The name of the application in debug messages and the debug and
3010 welcome screens
3011
3012 =item *
3013
3014 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3015 until it is accessed. This allows you to (for example) check authentication (and reject
3016 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
3017
3018 =item *
3019
3020 C<root> - The root directory for templates. Usually this is just a
3021 subdirectory of the home directory, but you can set it to change the
3022 templates to a different directory.
3023
3024 =item *
3025
3026 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3027 namespaces from which components will be loaded (and constructed and stored in
3028 C<< $c->components >>).
3029
3030 =item *
3031
3032 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3033 to be shown in hit debug tables in the test server.
3034
3035 =item *
3036
3037 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
3038 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
3039 for more information.
3040
3041 =item *
3042
3043 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3044
3045 =back
3046
3047 =head1 INTERNAL ACTIONS
3048
3049 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3050 C<_ACTION>, and C<_END>. These are by default not shown in the private
3051 action table, but you can make them visible with a config parameter.
3052
3053     MyApp->config(show_internal_actions => 1);
3054
3055 =head1 ON-DEMAND PARSER
3056
3057 The request body is usually parsed at the beginning of a request,
3058 but if you want to handle input yourself, you can enable on-demand
3059 parsing with a config parameter.
3060
3061     MyApp->config(parse_on_demand => 1);
3062
3063 =head1 PROXY SUPPORT
3064
3065 Many production servers operate using the common double-server approach,
3066 with a lightweight frontend web server passing requests to a larger
3067 backend server. An application running on the backend server must deal
3068 with two problems: the remote user always appears to be C<127.0.0.1> and
3069 the server's hostname will appear to be C<localhost> regardless of the
3070 virtual host that the user connected through.
3071
3072 Catalyst will automatically detect this situation when you are running
3073 the frontend and backend servers on the same machine. The following
3074 changes are made to the request.
3075
3076     $c->req->address is set to the user's real IP address, as read from
3077     the HTTP X-Forwarded-For header.
3078
3079     The host value for $c->req->base and $c->req->uri is set to the real
3080     host, as read from the HTTP X-Forwarded-Host header.
3081
3082 Additionally, you may be running your backend application on an insecure
3083 connection (port 80) while your frontend proxy is running under SSL.  If there
3084 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3085 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3086 be created properly.
3087
3088 In the case of passing in:
3089
3090     X-Forwarded-Port: 443
3091
3092 All calls to C<uri_for> will result in an https link, as is expected.
3093
3094 Obviously, your web server must support these headers for this to work.
3095
3096 In a more complex server farm environment where you may have your
3097 frontend proxy server(s) on different machines, you will need to set a
3098 configuration option to tell Catalyst to read the proxied data from the
3099 headers.
3100
3101     MyApp->config(using_frontend_proxy => 1);
3102
3103 If you do not wish to use the proxy support at all, you may set:
3104
3105     MyApp->config(ignore_frontend_proxy => 1);
3106
3107 =head1 THREAD SAFETY
3108
3109 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3110 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3111 believe the Catalyst core to be thread-safe.
3112
3113 If you plan to operate in a threaded environment, remember that all other
3114 modules you are using must also be thread-safe. Some modules, most notably
3115 L<DBD::SQLite>, are not thread-safe.
3116
3117 =head1 SUPPORT
3118
3119 IRC:
3120
3121     Join #catalyst on irc.perl.org.
3122
3123 Mailing Lists:
3124
3125     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3126     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3127
3128 Web:
3129
3130     http://catalyst.perl.org
3131
3132 Wiki:
3133
3134     http://dev.catalyst.perl.org
3135
3136 =head1 SEE ALSO
3137
3138 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3139
3140 =head2 L<Catalyst::Manual> - The Catalyst Manual
3141
3142 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3143
3144 =head2 L<Catalyst::Engine> - Core engine
3145
3146 =head2 L<Catalyst::Log> - Log class.
3147
3148 =head2 L<Catalyst::Request> - Request object
3149
3150 =head2 L<Catalyst::Response> - Response object
3151
3152 =head2 L<Catalyst::Test> - The test suite.
3153
3154 =head1 PROJECT FOUNDER
3155
3156 sri: Sebastian Riedel <sri@cpan.org>
3157
3158 =head1 CONTRIBUTORS
3159
3160 abw: Andy Wardley
3161
3162 acme: Leon Brocard <leon@astray.com>
3163
3164 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3165
3166 Andrew Bramble
3167
3168 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3169
3170 Andrew Ruthven
3171
3172 andyg: Andy Grundman <andy@hybridized.org>
3173
3174 audreyt: Audrey Tang
3175
3176 bricas: Brian Cassidy <bricas@cpan.org>
3177
3178 Caelum: Rafael Kitover <rkitover@io.com>
3179
3180 chansen: Christian Hansen
3181
3182 chicks: Christopher Hicks
3183
3184 Chisel Wright C<pause@herlpacker.co.uk>
3185
3186 Danijel Milicevic C<me@danijel.de>
3187
3188 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3189
3190 David Naughton, C<naughton@umn.edu>
3191
3192 David E. Wheeler
3193
3194 dhoss: Devin Austin <dhoss@cpan.org>
3195
3196 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3197
3198 Drew Taylor
3199
3200 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3201
3202 esskar: Sascha Kiefer
3203
3204 fireartist: Carl Franks <cfranks@cpan.org>
3205
3206 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3207
3208 gabb: Danijel Milicevic
3209
3210 Gary Ashton Jones
3211
3212 Gavin Henry C<ghenry@perl.me.uk>
3213
3214 Geoff Richards
3215
3216 groditi: Guillermo Roditi <groditi@gmail.com>
3217
3218 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3219
3220 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3221
3222 jcamacho: Juan Camacho
3223
3224 jester: Jesse Sheidlower C<jester@panix.com>
3225
3226 jhannah: Jay Hannah <jay@jays.net>
3227
3228 Jody Belka
3229
3230 Johan Lindstrom
3231
3232 jon: Jon Schutz <jjschutz@cpan.org>
3233
3234 Jonathan Rockway C<< <jrockway@cpan.org> >>
3235
3236 Kieren Diment C<kd@totaldatasolution.com>
3237
3238 konobi: Scott McWhirter <konobi@cpan.org>
3239
3240 marcus: Marcus Ramberg <mramberg@cpan.org>
3241
3242 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3243
3244 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3245
3246 mugwump: Sam Vilain
3247
3248 naughton: David Naughton
3249
3250 ningu: David Kamholz <dkamholz@cpan.org>
3251
3252 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3253
3254 numa: Dan Sully <daniel@cpan.org>
3255
3256 obra: Jesse Vincent
3257
3258 Octavian Rasnita
3259
3260 omega: Andreas Marienborg
3261
3262 Oleg Kostyuk <cub.uanic@gmail.com>
3263
3264 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3265
3266 rafl: Florian Ragwitz <rafl@debian.org>
3267
3268 random: Roland Lammel <lammel@cpan.org>
3269
3270 Robert Sedlacek C<< <rs@474.at> >>
3271
3272 SpiceMan: Marcel Montes
3273
3274 sky: Arthur Bergman
3275
3276 szbalint: Balint Szilakszi <szbalint@cpan.org>
3277
3278 t0m: Tomas Doran <bobtfish@bobtfish.net>
3279
3280 Ulf Edvinsson
3281
3282 Viljo Marrandi C<vilts@yahoo.com>
3283
3284 Will Hawes C<info@whawes.co.uk>
3285
3286 willert: Sebastian Willert <willert@cpan.org>
3287
3288 wreis: Wallace Reis <wallace@reis.org.br>
3289
3290 Yuval Kogman, C<nothingmuch@woobling.org>
3291
3292 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3293
3294 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3295
3296 =head1 COPYRIGHT
3297
3298 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3299
3300 =head1 LICENSE
3301
3302 This library is free software. You can redistribute it and/or modify it under
3303 the same terms as Perl itself.
3304
3305 =cut
3306
3307 no Moose;
3308
3309 __PACKAGE__->meta->make_immutable;
3310
3311 1;