lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use bytes;
   6 use Scope::Upper ();
   7 use Catalyst::Exception;
   8 use Catalyst::Log;
   9 use Catalyst::Request;
  10 use Catalyst::Request::Upload;
  11 use Catalyst::Response;
  12 use Catalyst::Utils;
  13 use Catalyst::Controller;
  14 use Devel::InnerPackage ();
  15 use File::stat;
  16 use Module::Pluggable::Object ();
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use URI ();
  21 use URI::http;
  22 use URI::https;
  23 use Tree::Simple qw/use_weak_refs/;
  24 use Tree::Simple::Visitor::FindByUID;
  25 use Class::C3::Adopt::NEXT;
  26 use attributes;
  27 use utf8;
  28 use Carp qw/croak carp shortmess/;
  29
  30 BEGIN { require 5.008001; }
  31
  32 has stack => (is => 'ro', default => sub { [] });
  33 has stash => (is => 'rw', default => sub { {} });
  34 has state => (is => 'rw', default => 0);
  35 has stats => (is => 'rw');
  36 has action => (is => 'rw');
  37 has counter => (is => 'rw', default => sub { {} });
  38 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  39 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  40 has namespace => (is => 'rw');
  41
  42 sub depth { scalar @{ shift->stack || [] }; }
  43 sub comp { shift->component(@_) }
  44
  45 sub req {
  46     # carp "the use of req() is deprecated in favour of request()";
  47     my $self = shift; return $self->request(@_);
  48 }
  49 sub res {
  50     # carp "the use of res() is deprecated in favour of response()";
  51     my $self = shift; return $self->response(@_);
  52 }
  53
  54 # For backwards compatibility
  55 sub finalize_output { shift->finalize_body(@_) };
  56
  57 # For statistics
  58 our $COUNT     = 1;
  59 our $START     = time;
  60 our $RECURSION = 1000;
  61 our $DETACH    = "catalyst_detach\n";
  62 our $GO        = "catalyst_go\n";
  63
  64 #I imagine that very few of these really need to be class variables. if any.
  65 #maybe we should just make them attributes with a default?
  66 __PACKAGE__->mk_classdata($_)
  67   for qw/components arguments dispatcher engine log dispatcher_class
  68   engine_class context_class request_class response_class stats_class
  69   setup_finished/;
  70
  71 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  72 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  73 __PACKAGE__->request_class('Catalyst::Request');
  74 __PACKAGE__->response_class('Catalyst::Response');
  75 __PACKAGE__->stats_class('Catalyst::Stats');
  76
  77 # Remember to update this in Catalyst::Runtime as well!
  78
  79 our $VERSION = '5.8000_06';
  80
  81 {
  82     my $dev_version = $VERSION =~ /_\d{2}$/;
  83     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  84 }
  85
  86 $VERSION = eval $VERSION;
  87
  88 sub import {
  89     my ( $class, @arguments ) = @_;
  90
  91     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  92     # callers @ISA.
  93     return unless $class eq 'Catalyst';
  94
  95     my $caller = caller();
  96     return if $caller eq 'main';
  97
  98     # Kill Adopt::NEXT warnings if we're a non-RC version
  99     unless (_IS_DEVELOPMENT_VERSION()) {
 100         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 101     }
 102
 103     my $meta = Moose::Meta::Class->initialize($caller);
 104     #Moose->import({ into => $caller }); #do we want to do this?
 105
 106     unless ( $caller->isa('Catalyst') ) {
 107         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 108         $meta->superclasses(@superclasses);
 109     }
 110     unless( $meta->has_method('meta') ){
 111         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 112     }
 113
 114     $caller->arguments( [@arguments] );
 115     $caller->setup_home;
 116 }
 117
 118 =head1 NAME
 119
 120 Catalyst - The Elegant MVC Web Application Framework
 121
 122 =head1 SYNOPSIS
 123
 124 See the L<Catalyst::Manual> distribution for comprehensive
 125 documentation and tutorials.
 126
 127     # Install Catalyst::Devel for helpers and other development tools
 128     # use the helper to create a new application
 129     catalyst.pl MyApp
 130
 131     # add models, views, controllers
 132     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 133     script/myapp_create.pl view MyTemplate TT
 134     script/myapp_create.pl controller Search
 135
 136     # built in testserver -- use -r to restart automatically on changes
 137     # --help to see all available options
 138     script/myapp_server.pl
 139
 140     # command line testing interface
 141     script/myapp_test.pl /yada
 142
 143     ### in lib/MyApp.pm
 144     use Catalyst qw/-Debug/; # include plugins here as well
 145
 146     ### In lib/MyApp/Controller/Root.pm (autocreated)
 147     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 148         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 149         $c->stash->{template} = 'foo.tt'; # set the template
 150         # lookup something from db -- stash vars are passed to TT
 151         $c->stash->{data} =
 152           $c->model('Database::Foo')->search( { country => $args[0] } );
 153         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 154             $c->forward( 'bar' ); # process another action
 155             # do something else after forward returns
 156         }
 157     }
 158
 159     # The foo.tt TT template can use the stash data from the database
 160     [% WHILE (item = data.next) %]
 161         [% item.foo %]
 162     [% END %]
 163
 164     # called for /bar/of/soap, /bar/of/soap/10, etc.
 165     sub bar : Path('/bar/of/soap') { ... }
 166
 167     # called for all actions, from the top-most controller downwards
 168     sub auto : Private {
 169         my ( $self, $c ) = @_;
 170         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 171             $c->res->redirect( '/login' ); # require login
 172             return 0; # abort request and go immediately to end()
 173         }
 174         return 1; # success; carry on to next action
 175     }
 176
 177     # called after all actions are finished
 178     sub end : Private {
 179         my ( $self, $c ) = @_;
 180         if ( scalar @{ $c->error } ) { ... } # handle errors
 181         return if $c->res->body; # already have a response
 182         $c->forward( 'MyApp::View::TT' ); # render template
 183     }
 184
 185     ### in MyApp/Controller/Foo.pm
 186     # called for /foo/bar
 187     sub bar : Local { ... }
 188
 189     # called for /blargle
 190     sub blargle : Global { ... }
 191
 192     # an index action matches /foo, but not /foo/1, etc.
 193     sub index : Private { ... }
 194
 195     ### in MyApp/Controller/Foo/Bar.pm
 196     # called for /foo/bar/baz
 197     sub baz : Local { ... }
 198
 199     # first Root auto is called, then Foo auto, then this
 200     sub auto : Private { ... }
 201
 202     # powerful regular expression paths are also possible
 203     sub details : Regex('^product/(\w+)/details$') {
 204         my ( $self, $c ) = @_;
 205         # extract the (\w+) from the URI
 206         my $product = $c->req->captures->[0];
 207     }
 208
 209 See L<Catalyst::Manual::Intro> for additional information.
 210
 211 =head1 DESCRIPTION
 212
 213 Catalyst is a modern framework for making web applications without the
 214 pain usually associated with this process. This document is a reference
 215 to the main Catalyst application. If you are a new user, we suggest you
 216 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 217
 218 See L<Catalyst::Manual> for more documentation.
 219
 220 Catalyst plugins can be loaded by naming them as arguments to the "use
 221 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 222 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 223 C<My::Module>.
 224
 225     use Catalyst qw/My::Module/;
 226
 227 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 228 fully qualify the name by using a unary plus:
 229
 230     use Catalyst qw/
 231         My::Module
 232         +Fully::Qualified::Plugin::Name
 233     /;
 234
 235 Special flags like C<-Debug> and C<-Engine> can also be specified as
 236 arguments when Catalyst is loaded:
 237
 238     use Catalyst qw/-Debug My::Module/;
 239
 240 The position of plugins and flags in the chain is important, because
 241 they are loaded in the order in which they appear.
 242
 243 The following flags are supported:
 244
 245 =head2 -Debug
 246
 247 Enables debug output. You can also force this setting from the system
 248 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 249 settings override the application, with <MYAPP>_DEBUG having the highest
 250 priority.
 251
 252 =head2 -Engine
 253
 254 Forces Catalyst to use a specific engine. Omit the
 255 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 256
 257     use Catalyst qw/-Engine=CGI/;
 258
 259 =head2 -Home
 260
 261 Forces Catalyst to use a specific home directory, e.g.:
 262
 263     use Catalyst qw[-Home=/usr/mst];
 264
 265 This can also be done in the shell environment by setting either the
 266 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 267 is replaced with the uppercased name of your application, any "::" in
 268 the name will be replaced with underscores, e.g. MyApp::Web should use
 269 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 270
 271 =head2 -Log
 272
 273     use Catalyst '-Log=warn,fatal,error';
 274
 275 Specifies a comma-delimited list of log levels.
 276
 277 =head2 -Stats
 278
 279 Enables statistics collection and reporting. You can also force this setting
 280 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 281 environment settings override the application, with <MYAPP>_STATS having the
 282 highest priority.
 283
 284 e.g.
 285
 286    use Catalyst qw/-Stats=1/
 287
 288 =head1 METHODS
 289
 290 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 291
 292 =head2 $c->action
 293
 294 Returns a L<Catalyst::Action> object for the current action, which
 295 stringifies to the action name. See L<Catalyst::Action>.
 296
 297 =head2 $c->namespace
 298
 299 Returns the namespace of the current action, i.e., the URI prefix
 300 corresponding to the controller of the current action. For example:
 301
 302     # in Controller::Foo::Bar
 303     $c->namespace; # returns 'foo/bar';
 304
 305 =head2 $c->request
 306
 307 =head2 $c->req
 308
 309 Returns the current L<Catalyst::Request> object, giving access to
 310 information about the current client request (including parameters,
 311 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 312
 313 =head2 REQUEST FLOW HANDLING
 314
 315 =head2 $c->forward( $action [, \@arguments ] )
 316
 317 =head2 $c->forward( $class, $method, [, \@arguments ] )
 318
 319 Forwards processing to another action, by its private name. If you give a
 320 class name but no method, C<process()> is called. You may also optionally
 321 pass arguments in an arrayref. The action will receive the arguments in
 322 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 323 C<< $c->req->args >> will be restored to the previous values.
 324
 325 Any data C<return>ed from the action forwarded to, will be returned by the
 326 call to forward.
 327
 328     my $foodata = $c->forward('/foo');
 329     $c->forward('index');
 330     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 331     $c->forward('MyApp::View::TT');
 332
 333 Note that forward implies an C<<eval { }>> around the call (actually
 334 C<execute> does), thus de-fatalizing all 'dies' within the called
 335 action. If you want C<die> to propagate you need to do something like:
 336
 337     $c->forward('foo');
 338     die $c->error if $c->error;
 339
 340 Or make sure to always return true values from your actions and write
 341 your code like this:
 342
 343     $c->forward('foo') || return;
 344
 345 =cut
 346
 347 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 348
 349 =head2 $c->detach( $action [, \@arguments ] )
 350
 351 =head2 $c->detach( $class, $method, [, \@arguments ] )
 352
 353 =head2 $c->detach()
 354
 355 The same as C<forward>, but doesn't return to the previous action when
 356 processing is finished.
 357
 358 When called with no arguments it escapes the processing chain entirely.
 359
 360 =cut
 361
 362 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 363
 364 =head2 $c->visit( $action [, \@arguments ] )
 365
 366 =head2 $c->visit( $class, $method, [, \@arguments ] )
 367
 368 Almost the same as C<forward>, but does a full dispatch, instead of just
 369 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 370 C<auto> and the method you go to are called, just like a new request.
 371
 372 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 373 This means, for example, that $c->action methods such as C<name>, C<class> and
 374 C<reverse> return information for the visited action when they are invoked
 375 within the visited action.  This is different from the behavior of C<forward>
 376 which continues to use the $c->action object from the caller action even when
 377 invoked from the callee.
 378
 379 C<$c-E<gt>stash> is kept unchanged.
 380
 381 In effect, C<visit> allows you to "wrap" another action, just as it
 382 would have been called by dispatching from a URL, while the analogous
 383 C<go> allows you to transfer control to another action as if it had
 384 been reached directly from a URL.
 385
 386 =cut
 387
 388 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 389
 390 =head2 $c->go( $action [, \@arguments ] )
 391
 392 =head2 $c->go( $class, $method, [, \@arguments ] )
 393
 394 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 395 instead of just calling the new C<$action> /
 396 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 397 method you visit are called, just like a new request.
 398
 399 C<$c-E<gt>stash> is kept unchanged.
 400
 401 =cut
 402
 403 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 404
 405 =head2 $c->response
 406
 407 =head2 $c->res
 408
 409 Returns the current L<Catalyst::Response> object, see there for details.
 410
 411 =head2 $c->stash
 412
 413 Returns a hashref to the stash, which may be used to store data and pass
 414 it between components during a request. You can also set hash keys by
 415 passing arguments. The stash is automatically sent to the view. The
 416 stash is cleared at the end of a request; it cannot be used for
 417 persistent storage (for this you must use a session; see
 418 L<Catalyst::Plugin::Session> for a complete system integrated with
 419 Catalyst).
 420
 421     $c->stash->{foo} = $bar;
 422     $c->stash( { moose => 'majestic', qux => 0 } );
 423     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 424
 425     # stash is automatically passed to the view for use in a template
 426     $c->forward( 'MyApp::View::TT' );
 427
 428 =cut
 429
 430 around stash => sub {
 431     my $orig = shift;
 432     my $c = shift;
 433     my $stash = $orig->($c);
 434     if (@_) {
 435         my $new_stash = @_ > 1 ? {@_} : $_[0];
 436         croak('stash takes a hash or hashref') unless ref $new_stash;
 437         foreach my $key ( keys %$new_stash ) {
 438           $stash->{$key} = $new_stash->{$key};
 439         }
 440     }
 441
 442     return $stash;
 443 };
 444
 445
 446 =head2 $c->error
 447
 448 =head2 $c->error($error, ...)
 449
 450 =head2 $c->error($arrayref)
 451
 452 Returns an arrayref containing error messages.  If Catalyst encounters an
 453 error while processing a request, it stores the error in $c->error.  This
 454 method should only be used to store fatal error messages.
 455
 456     my @error = @{ $c->error };
 457
 458 Add a new error.
 459
 460     $c->error('Something bad happened');
 461
 462 =cut
 463
 464 sub error {
 465     my $c = shift;
 466     if ( $_[0] ) {
 467         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 468         croak @$error unless ref $c;
 469         push @{ $c->{error} }, @$error;
 470     }
 471     elsif ( defined $_[0] ) { $c->{error} = undef }
 472     return $c->{error} || [];
 473 }
 474
 475
 476 =head2 $c->state
 477
 478 Contains the return value of the last executed action.
 479
 480 =head2 $c->clear_errors
 481
 482 Clear errors.  You probably don't want to clear the errors unless you are
 483 implementing a custom error screen.
 484
 485 This is equivalent to running
 486
 487     $c->error(0);
 488
 489 =cut
 490
 491 sub clear_errors {
 492     my $c = shift;
 493     $c->error(0);
 494 }
 495
 496 # search components given a name and some prefixes
 497 sub _comp_search_prefixes {
 498     my ( $c, $name, @prefixes ) = @_;
 499     my $appclass = ref $c || $c;
 500     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 501     $filter = qr/$filter/; # Compile regex now rather than once per loop
 502
 503     # map the original component name to the sub part that we will search against
 504     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 505         grep { /$filter/ } keys %{ $c->components };
 506
 507     # undef for a name will return all
 508     return keys %eligible if !defined $name;
 509
 510     my $query  = ref $name ? $name : qr/^$name$/i;
 511     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 512
 513     return map { $c->components->{ $_ } } @result if @result;
 514
 515     # if we were given a regexp to search against, we're done.
 516     return if ref $name;
 517
 518     # regexp fallback
 519     $query  = qr/$name/i;
 520     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 521
 522     # no results? try against full names
 523     if( !@result ) {
 524         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 525     }
 526
 527     # don't warn if we didn't find any results, it just might not exist
 528     if( @result ) {
 529         # Disgusting hack to work out correct method name
 530         my $warn_for = lc $prefixes[0];
 531         my $msg = "Used regexp fallback for \$c->{$warn_for}('${name}'), which found '" .
 532            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 533            "component resolution is unreliable and unsafe.";
 534         my $short = $result[0];
 535         $short =~ s/.*?Model:://;
 536         my $shortmess = Carp::shortmess('');
 537         if ($shortmess =~ m#Catalyst/Plugin#) {
 538            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 539               "plugin's config";
 540         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 541            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 542               "component's config";
 543         } else {
 544            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 545               "but if you really wanted to search, pass in a regexp as the argument " .
 546               "like so: \$c->${warn_for}(qr/${name}/)";
 547         }
 548         $c->log->warn( "${msg}$shortmess" );
 549     }
 550
 551     return @result;
 552 }
 553
 554 # Find possible names for a prefix
 555 sub _comp_names {
 556     my ( $c, @prefixes ) = @_;
 557     my $appclass = ref $c || $c;
 558
 559     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 560
 561     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 562     return @names;
 563 }
 564
 565 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 566 sub _filter_component {
 567     my ( $c, $comp, @args ) = @_;
 568
 569     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 570         return $comp->ACCEPT_CONTEXT( $c, @args );
 571     }
 572
 573     return $comp;
 574 }
 575
 576 =head2 COMPONENT ACCESSORS
 577
 578 =head2 $c->controller($name)
 579
 580 Gets a L<Catalyst::Controller> instance by name.
 581
 582     $c->controller('Foo')->do_stuff;
 583
 584 If the name is omitted, will return the controller for the dispatched
 585 action.
 586
 587 If you want to search for controllers, pass in a regexp as the argument.
 588
 589     # find all controllers that start with Foo
 590     my @foo_controllers = $c->controller(qr{^Foo});
 591
 592
 593 =cut
 594
 595 sub controller {
 596     my ( $c, $name, @args ) = @_;
 597
 598     if( $name ) {
 599         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 600         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 601         return $c->_filter_component( $result[ 0 ], @args );
 602     }
 603
 604     return $c->component( $c->action->class );
 605 }
 606
 607 =head2 $c->model($name)
 608
 609 Gets a L<Catalyst::Model> instance by name.
 610
 611     $c->model('Foo')->do_stuff;
 612
 613 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 614
 615 If the name is omitted, it will look for
 616  - a model object in $c->stash->{current_model_instance}, then
 617  - a model name in $c->stash->{current_model}, then
 618  - a config setting 'default_model', or
 619  - check if there is only one model, and return it if that's the case.
 620
 621 If you want to search for models, pass in a regexp as the argument.
 622
 623     # find all models that start with Foo
 624     my @foo_models = $c->model(qr{^Foo});
 625
 626 =cut
 627
 628 sub model {
 629     my ( $c, $name, @args ) = @_;
 630
 631     if( $name ) {
 632         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 633         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 634         return $c->_filter_component( $result[ 0 ], @args );
 635     }
 636
 637     if (ref $c) {
 638         return $c->stash->{current_model_instance}
 639           if $c->stash->{current_model_instance};
 640         return $c->model( $c->stash->{current_model} )
 641           if $c->stash->{current_model};
 642     }
 643     return $c->model( $c->config->{default_model} )
 644       if $c->config->{default_model};
 645
 646     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 647
 648     if( $rest ) {
 649         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 650         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 651         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 652         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 653         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 654     }
 655
 656     return $c->_filter_component( $comp );
 657 }
 658
 659
 660 =head2 $c->view($name)
 661
 662 Gets a L<Catalyst::View> instance by name.
 663
 664     $c->view('Foo')->do_stuff;
 665
 666 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 667
 668 If the name is omitted, it will look for
 669  - a view object in $c->stash->{current_view_instance}, then
 670  - a view name in $c->stash->{current_view}, then
 671  - a config setting 'default_view', or
 672  - check if there is only one view, and return it if that's the case.
 673
 674 If you want to search for views, pass in a regexp as the argument.
 675
 676     # find all views that start with Foo
 677     my @foo_views = $c->view(qr{^Foo});
 678
 679 =cut
 680
 681 sub view {
 682     my ( $c, $name, @args ) = @_;
 683
 684     if( $name ) {
 685         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 686         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 687         return $c->_filter_component( $result[ 0 ], @args );
 688     }
 689
 690     if (ref $c) {
 691         return $c->stash->{current_view_instance}
 692           if $c->stash->{current_view_instance};
 693         return $c->view( $c->stash->{current_view} )
 694           if $c->stash->{current_view};
 695     }
 696     return $c->view( $c->config->{default_view} )
 697       if $c->config->{default_view};
 698
 699     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 700
 701     if( $rest ) {
 702         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 703         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 704         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 705         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 706         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 707     }
 708
 709     return $c->_filter_component( $comp );
 710 }
 711
 712 =head2 $c->controllers
 713
 714 Returns the available names which can be passed to $c->controller
 715
 716 =cut
 717
 718 sub controllers {
 719     my ( $c ) = @_;
 720     return $c->_comp_names(qw/Controller C/);
 721 }
 722
 723 =head2 $c->models
 724
 725 Returns the available names which can be passed to $c->model
 726
 727 =cut
 728
 729 sub models {
 730     my ( $c ) = @_;
 731     return $c->_comp_names(qw/Model M/);
 732 }
 733
 734
 735 =head2 $c->views
 736
 737 Returns the available names which can be passed to $c->view
 738
 739 =cut
 740
 741 sub views {
 742     my ( $c ) = @_;
 743     return $c->_comp_names(qw/View V/);
 744 }
 745
 746 =head2 $c->comp($name)
 747
 748 =head2 $c->component($name)
 749
 750 Gets a component object by name. This method is not recommended,
 751 unless you want to get a specific component by full
 752 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 753 should be used instead.
 754
 755 If C<$name> is a regexp, a list of components matched against the full
 756 component name will be returned.
 757
 758 =cut
 759
 760 sub component {
 761     my ( $c, $name, @args ) = @_;
 762
 763     if( $name ) {
 764         my $comps = $c->components;
 765
 766         if( !ref $name ) {
 767             # is it the exact name?
 768             return $c->_filter_component( $comps->{ $name }, @args )
 769                        if exists $comps->{ $name };
 770
 771             # perhaps we just omitted "MyApp"?
 772             my $composed = ( ref $c || $c ) . "::${name}";
 773             return $c->_filter_component( $comps->{ $composed }, @args )
 774                        if exists $comps->{ $composed };
 775
 776             # search all of the models, views and controllers
 777             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 778             return $c->_filter_component( $comp, @args ) if $comp;
 779         }
 780
 781         # This is here so $c->comp( '::M::' ) works
 782         my $query = ref $name ? $name : qr{$name}i;
 783
 784         my @result = grep { m{$query} } keys %{ $c->components };
 785         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 786
 787         if( $result[ 0 ] ) {
 788             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 789             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 790             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 791             return $c->_filter_component( $result[ 0 ], @args );
 792         }
 793
 794         # I would expect to return an empty list here, but that breaks back-compat
 795     }
 796
 797     # fallback
 798     return sort keys %{ $c->components };
 799 }
 800
 801 =head2 CLASS DATA AND HELPER CLASSES
 802
 803 =head2 $c->config
 804
 805 Returns or takes a hashref containing the application's configuration.
 806
 807     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 808
 809 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 810 like myapp.yml in your applications home directory. See
 811 L<Catalyst::Plugin::ConfigLoader>.
 812
 813     ---
 814     db: dsn:SQLite:foo.db
 815
 816
 817 =cut
 818
 819 around config => sub {
 820     my $orig = shift;
 821     my $c = shift;
 822
 823     croak('Setting config after setup has been run is not allowed.')
 824         if ( @_ and $c->setup_finished );
 825
 826     $c->$orig(@_);
 827 };
 828
 829 =head2 $c->log
 830
 831 Returns the logging object instance. Unless it is already set, Catalyst
 832 sets this up with a L<Catalyst::Log> object. To use your own log class,
 833 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 834 C<< __PACKAGE__->setup >>.
 835
 836  __PACKAGE__->log( MyLogger->new );
 837  __PACKAGE__->setup;
 838
 839 And later:
 840
 841     $c->log->info( 'Now logging with my own logger!' );
 842
 843 Your log class should implement the methods described in
 844 L<Catalyst::Log>.
 845
 846
 847 =head2 $c->debug
 848
 849 Returns 1 if debug mode is enabled, 0 otherwise.
 850
 851 You can enable debug mode in several ways:
 852 (1) with the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 853 (2) the -Debug option in your MyApp.pm
 854 (3) by declaring "sub debug { 1 }" in your MyApp.pm.
 855
 856 Calling $c->debug(1) has no effect.
 857
 858 =cut
 859
 860 sub debug { 0 }
 861
 862 =head2 $c->dispatcher
 863
 864 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 865
 866 =head2 $c->engine
 867
 868 Returns the engine instance. See L<Catalyst::Engine>.
 869
 870
 871 =head2 UTILITY METHODS
 872
 873 =head2 $c->path_to(@path)
 874
 875 Merges C<@path> with C<< $c->config->{home} >> and returns a
 876 L<Path::Class::Dir> object.
 877
 878 For example:
 879
 880     $c->path_to( 'db', 'sqlite.db' );
 881
 882 =cut
 883
 884 sub path_to {
 885     my ( $c, @path ) = @_;
 886     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 887     if ( -d $path ) { return $path }
 888     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 889 }
 890
 891 =head2 $c->plugin( $name, $class, @args )
 892
 893 Helper method for plugins. It creates a class data accessor/mutator and
 894 loads and instantiates the given class.
 895
 896     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 897
 898     $c->prototype->define_javascript_functions;
 899
 900 B<Note:> This method of adding plugins is deprecated. The ability
 901 to add plugins like this B<will be removed> in a Catalyst 5.9.
 902 Please do not use this functionality in new code.
 903
 904 =cut
 905
 906 sub plugin {
 907     my ( $class, $name, $plugin, @args ) = @_;
 908
 909     # See block comment in t/unit_core_plugin.t
 910     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.9/);
 911
 912     $class->_register_plugin( $plugin, 1 );
 913
 914     eval { $plugin->import };
 915     $class->mk_classdata($name);
 916     my $obj;
 917     eval { $obj = $plugin->new(@args) };
 918
 919     if ($@) {
 920         Catalyst::Exception->throw( message =>
 921               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 922     }
 923
 924     $class->$name($obj);
 925     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 926       if $class->debug;
 927 }
 928
 929 =head2 MyApp->setup
 930
 931 Initializes the dispatcher and engine, loads any plugins, and loads the
 932 model, view, and controller components. You may also specify an array
 933 of plugins to load here, if you choose to not load them in the C<use
 934 Catalyst> line.
 935
 936     MyApp->setup;
 937     MyApp->setup( qw/-Debug/ );
 938
 939 =cut
 940
 941 sub setup {
 942     my ( $class, @arguments ) = @_;
 943     croak('Running setup more than once')
 944         if ( $class->setup_finished );
 945
 946     unless ( $class->isa('Catalyst') ) {
 947
 948         Catalyst::Exception->throw(
 949             message => qq/'$class' does not inherit from Catalyst/ );
 950     }
 951
 952     if ( $class->arguments ) {
 953         @arguments = ( @arguments, @{ $class->arguments } );
 954     }
 955
 956     # Process options
 957     my $flags = {};
 958
 959     foreach (@arguments) {
 960
 961         if (/^-Debug$/) {
 962             $flags->{log} =
 963               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 964         }
 965         elsif (/^-(\w+)=?(.*)$/) {
 966             $flags->{ lc $1 } = $2;
 967         }
 968         else {
 969             push @{ $flags->{plugins} }, $_;
 970         }
 971     }
 972
 973     $class->setup_home( delete $flags->{home} );
 974
 975     $class->setup_log( delete $flags->{log} );
 976     $class->setup_plugins( delete $flags->{plugins} );
 977     $class->setup_dispatcher( delete $flags->{dispatcher} );
 978     $class->setup_engine( delete $flags->{engine} );
 979     $class->setup_stats( delete $flags->{stats} );
 980
 981     for my $flag ( sort keys %{$flags} ) {
 982
 983         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 984             &$code( $class, delete $flags->{$flag} );
 985         }
 986         else {
 987             $class->log->warn(qq/Unknown flag "$flag"/);
 988         }
 989     }
 990
 991     eval { require Catalyst::Devel; };
 992     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 993         $class->log->warn(<<"EOF");
 994 You are running an old script!
 995
 996   Please update by running (this will overwrite existing files):
 997     catalyst.pl -force -scripts $class
 998
 999   or (this will not overwrite existing files):
1000     catalyst.pl -scripts $class
1001
1002 EOF
1003     }
1004
1005     if ( $class->debug ) {
1006         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1007
1008         if (@plugins) {
1009             my $column_width = Catalyst::Utils::term_width() - 6;
1010             my $t = Text::SimpleTable->new($column_width);
1011             $t->row($_) for @plugins;
1012             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1013         }
1014
1015         my $dispatcher = $class->dispatcher;
1016         my $engine     = $class->engine;
1017         my $home       = $class->config->{home};
1018
1019         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1020         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1021
1022         $home
1023           ? ( -d $home )
1024           ? $class->log->debug(qq/Found home "$home"/)
1025           : $class->log->debug(qq/Home "$home" doesn't exist/)
1026           : $class->log->debug(q/Couldn't find home/);
1027     }
1028
1029     # Call plugins setup, this is stupid and evil.
1030     {
1031         no warnings qw/redefine/;
1032         local *setup = sub { };
1033         $class->setup;
1034     }
1035
1036     # Initialize our data structure
1037     $class->components( {} );
1038
1039     $class->setup_components;
1040
1041     if ( $class->debug ) {
1042         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1043         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1044         for my $comp ( sort keys %{ $class->components } ) {
1045             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1046             $t->row( $comp, $type );
1047         }
1048         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1049           if ( keys %{ $class->components } );
1050     }
1051
1052     # Add our self to components, since we are also a component
1053     if( $class->isa('Catalyst::Controller') ){
1054       $class->components->{$class} = $class;
1055     }
1056
1057     $class->setup_actions;
1058
1059     if ( $class->debug ) {
1060         my $name = $class->config->{name} || 'Application';
1061         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1062     }
1063     $class->log->_flush() if $class->log->can('_flush');
1064
1065     # Make sure that the application class becomes immutable at this point,
1066     # which ensures that it gets an inlined constructor. This means that it
1067     # works even if the user has added a plugin which contains a new method.
1068     # Note however that we have to do the work on scope end, so that method
1069     # modifiers work correctly in MyApp (as you have to call setup _before_
1070     # applying modifiers).
1071     Scope::Upper::reap(sub {
1072         my $meta = Class::MOP::get_metaclass_by_name($class);
1073         $meta->make_immutable unless $meta->is_immutable;
1074     }, Scope::Upper::SCOPE(1));
1075
1076     $class->setup_finalize;
1077 }
1078
1079
1080 =head2 $app->setup_finalize
1081
1082 A hook to attach modifiers to.
1083 Using C< after setup => sub{}; > doesn't work, because of quirky things done for plugin setup.
1084 Also better than C< setup_finished(); >, as that is a getter method.
1085
1086     sub setup_finalize {
1087
1088         my $app = shift;
1089
1090         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1091
1092         $app->next::method(@_);
1093
1094
1095     }
1096
1097 =cut
1098
1099 sub setup_finalize {
1100     my ($class) = @_;
1101     $class->setup_finished(1);
1102 }
1103
1104 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1105
1106 =head2 $c->uri_for( $path, @args?, \%query_values? )
1107
1108 =over
1109
1110 =item $action
1111
1112 A Catalyst::Action object representing the Catalyst action you want to
1113 create a URI for. To get one for an action in the current controller,
1114 use C<< $c->action('someactionname') >>. To get one from different
1115 controller, fetch the controller using C<< $c->controller() >>, then
1116 call C<action_for> on it.
1117
1118 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1119 using C<< $c->req->captures >>.
1120
1121   # For the current action
1122   $c->uri_for($c->action, $c->req->captures);
1123
1124   # For the Foo action in the Bar controller
1125   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1126
1127 =back
1128
1129 =cut
1130
1131 sub uri_for {
1132     my ( $c, $path, @args ) = @_;
1133
1134     if ( blessed($path) ) { # action object
1135         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1136                          ? shift(@args)
1137                          : [] );
1138         $path = $c->dispatcher->uri_for_action($path, $captures);
1139         return undef unless defined($path);
1140         $path = '/' if $path eq '';
1141     }
1142
1143     undef($path) if (defined $path && $path eq '');
1144
1145     my $params =
1146       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1147
1148     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1149     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1150
1151     unshift(@args, $path);
1152
1153     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1154         my $namespace = $c->namespace;
1155         if (defined $path) { # cheesy hack to handle path '../foo'
1156            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1157         }
1158         unshift(@args, $namespace || '');
1159     }
1160
1161     # join args with '/', or a blank string
1162     my $args = join('/', grep { defined($_) } @args);
1163     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1164     $args =~ s!^/+!!;
1165     my $base = $c->req->base;
1166     my $class = ref($base);
1167     $base =~ s{(?<!/)$}{/};
1168
1169     my $query = '';
1170
1171     if (my @keys = keys %$params) {
1172       # somewhat lifted from URI::_query's query_form
1173       $query = '?'.join('&', map {
1174           my $val = $params->{$_};
1175           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1176           s/ /+/g;
1177           my $key = $_;
1178           $val = '' unless defined $val;
1179           (map {
1180               $_ = "$_";
1181               utf8::encode( $_ ) if utf8::is_utf8($_);
1182               # using the URI::Escape pattern here so utf8 chars survive
1183               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1184               s/ /+/g;
1185               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1186       } @keys);
1187     }
1188
1189     my $res = bless(\"${base}${args}${query}", $class);
1190     $res;
1191 }
1192
1193 =head2 $c->welcome_message
1194
1195 Returns the Catalyst welcome HTML page.
1196
1197 =cut
1198
1199 sub welcome_message {
1200     my $c      = shift;
1201     my $name   = $c->config->{name};
1202     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1203     my $prefix = Catalyst::Utils::appprefix( ref $c );
1204     $c->response->content_type('text/html; charset=utf-8');
1205     return <<"EOF";
1206 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1207     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1208 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1209     <head>
1210     <meta http-equiv="Content-Language" content="en" />
1211     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1212         <title>$name on Catalyst $VERSION</title>
1213         <style type="text/css">
1214             body {
1215                 color: #000;
1216                 background-color: #eee;
1217             }
1218             div#content {
1219                 width: 640px;
1220                 margin-left: auto;
1221                 margin-right: auto;
1222                 margin-top: 10px;
1223                 margin-bottom: 10px;
1224                 text-align: left;
1225                 background-color: #ccc;
1226                 border: 1px solid #aaa;
1227             }
1228             p, h1, h2 {
1229                 margin-left: 20px;
1230                 margin-right: 20px;
1231                 font-family: verdana, tahoma, sans-serif;
1232             }
1233             a {
1234                 font-family: verdana, tahoma, sans-serif;
1235             }
1236             :link, :visited {
1237                     text-decoration: none;
1238                     color: #b00;
1239                     border-bottom: 1px dotted #bbb;
1240             }
1241             :link:hover, :visited:hover {
1242                     color: #555;
1243             }
1244             div#topbar {
1245                 margin: 0px;
1246             }
1247             pre {
1248                 margin: 10px;
1249                 padding: 8px;
1250             }
1251             div#answers {
1252                 padding: 8px;
1253                 margin: 10px;
1254                 background-color: #fff;
1255                 border: 1px solid #aaa;
1256             }
1257             h1 {
1258                 font-size: 0.9em;
1259                 font-weight: normal;
1260                 text-align: center;
1261             }
1262             h2 {
1263                 font-size: 1.0em;
1264             }
1265             p {
1266                 font-size: 0.9em;
1267             }
1268             p img {
1269                 float: right;
1270                 margin-left: 10px;
1271             }
1272             span#appname {
1273                 font-weight: bold;
1274                 font-size: 1.6em;
1275             }
1276         </style>
1277     </head>
1278     <body>
1279         <div id="content">
1280             <div id="topbar">
1281                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1282                     $VERSION</h1>
1283              </div>
1284              <div id="answers">
1285                  <p>
1286                  <img src="$logo" alt="Catalyst Logo" />
1287                  </p>
1288                  <p>Welcome to the  world of Catalyst.
1289                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1290                     framework will make web development something you had
1291                     never expected it to be: Fun, rewarding, and quick.</p>
1292                  <h2>What to do now?</h2>
1293                  <p>That really depends  on what <b>you</b> want to do.
1294                     We do, however, provide you with a few starting points.</p>
1295                  <p>If you want to jump right into web development with Catalyst
1296                     you might want to start with a tutorial.</p>
1297 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1298 </pre>
1299 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1300 <pre>
1301 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1302 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1303 </code></pre>
1304                  <h2>What to do next?</h2>
1305                  <p>Next it's time to write an actual application. Use the
1306                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1307                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1308                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1309                     they can save you a lot of work.</p>
1310                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1311                     <p>Also, be sure to check out the vast and growing
1312                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1313                     you are likely to find what you need there.
1314                     </p>
1315
1316                  <h2>Need help?</h2>
1317                  <p>Catalyst has a very active community. Here are the main places to
1318                     get in touch with us.</p>
1319                  <ul>
1320                      <li>
1321                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1322                      </li>
1323                      <li>
1324                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1325                      </li>
1326                      <li>
1327                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1328                      </li>
1329                  </ul>
1330                  <h2>In conclusion</h2>
1331                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1332                     as we enjoyed making it. Please contact us if you have ideas
1333                     for improvement or other feedback.</p>
1334              </div>
1335          </div>
1336     </body>
1337 </html>
1338 EOF
1339 }
1340
1341 =head1 INTERNAL METHODS
1342
1343 These methods are not meant to be used by end users.
1344
1345 =head2 $c->components
1346
1347 Returns a hash of components.
1348
1349 =head2 $c->context_class
1350
1351 Returns or sets the context class.
1352
1353 =head2 $c->counter
1354
1355 Returns a hashref containing coderefs and execution counts (needed for
1356 deep recursion detection).
1357
1358 =head2 $c->depth
1359
1360 Returns the number of actions on the current internal execution stack.
1361
1362 =head2 $c->dispatch
1363
1364 Dispatches a request to actions.
1365
1366 =cut
1367
1368 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1369
1370 =head2 $c->dispatcher_class
1371
1372 Returns or sets the dispatcher class.
1373
1374 =head2 $c->dump_these
1375
1376 Returns a list of 2-element array references (name, structure) pairs
1377 that will be dumped on the error page in debug mode.
1378
1379 =cut
1380
1381 sub dump_these {
1382     my $c = shift;
1383     [ Request => $c->req ],
1384     [ Response => $c->res ],
1385     [ Stash => $c->stash ],
1386     [ Config => $c->config ];
1387 }
1388
1389 =head2 $c->engine_class
1390
1391 Returns or sets the engine class.
1392
1393 =head2 $c->execute( $class, $coderef )
1394
1395 Execute a coderef in given class and catch exceptions. Errors are available
1396 via $c->error.
1397
1398 =cut
1399
1400 sub execute {
1401     my ( $c, $class, $code ) = @_;
1402     $class = $c->component($class) || $class;
1403     $c->state(0);
1404
1405     if ( $c->depth >= $RECURSION ) {
1406         my $action = $code->reverse();
1407         $action = "/$action" unless $action =~ /->/;
1408         my $error = qq/Deep recursion detected calling "${action}"/;
1409         $c->log->error($error);
1410         $c->error($error);
1411         $c->state(0);
1412         return $c->state;
1413     }
1414
1415     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1416
1417     push( @{ $c->stack }, $code );
1418
1419     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1420
1421     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1422
1423     my $last = pop( @{ $c->stack } );
1424
1425     if ( my $error = $@ ) {
1426         if ( !ref($error) and $error eq $DETACH ) {
1427             die $DETACH if($c->depth > 1);
1428         }
1429         elsif ( !ref($error) and $error eq $GO ) {
1430             die $GO if($c->depth > 0);
1431         }
1432         else {
1433             unless ( ref $error ) {
1434                 no warnings 'uninitialized';
1435                 chomp $error;
1436                 my $class = $last->class;
1437                 my $name  = $last->name;
1438                 $error = qq/Caught exception in $class->$name "$error"/;
1439             }
1440             $c->error($error);
1441             $c->state(0);
1442         }
1443     }
1444     return $c->state;
1445 }
1446
1447 sub _stats_start_execute {
1448     my ( $c, $code ) = @_;
1449
1450     return if ( ( $code->name =~ /^_.*/ )
1451         && ( !$c->config->{show_internal_actions} ) );
1452
1453     my $action_name = $code->reverse();
1454     $c->counter->{$action_name}++;
1455
1456     my $action = $action_name;
1457     $action = "/$action" unless $action =~ /->/;
1458
1459     # determine if the call was the result of a forward
1460     # this is done by walking up the call stack and looking for a calling
1461     # sub of Catalyst::forward before the eval
1462     my $callsub = q{};
1463     for my $index ( 2 .. 11 ) {
1464         last
1465         if ( ( caller($index) )[0] eq 'Catalyst'
1466             && ( caller($index) )[3] eq '(eval)' );
1467
1468         if ( ( caller($index) )[3] =~ /forward$/ ) {
1469             $callsub = ( caller($index) )[3];
1470             $action  = "-> $action";
1471             last;
1472         }
1473     }
1474
1475     my $uid = $action_name . $c->counter->{$action_name};
1476
1477     # is this a root-level call or a forwarded call?
1478     if ( $callsub =~ /forward$/ ) {
1479
1480         # forward, locate the caller
1481         if ( my $parent = $c->stack->[-1] ) {
1482             $c->stats->profile(
1483                 begin  => $action,
1484                 parent => "$parent" . $c->counter->{"$parent"},
1485                 uid    => $uid,
1486             );
1487         }
1488         else {
1489
1490             # forward with no caller may come from a plugin
1491             $c->stats->profile(
1492                 begin => $action,
1493                 uid   => $uid,
1494             );
1495         }
1496     }
1497     else {
1498
1499         # root-level call
1500         $c->stats->profile(
1501             begin => $action,
1502             uid   => $uid,
1503         );
1504     }
1505     return $action;
1506
1507 }
1508
1509 sub _stats_finish_execute {
1510     my ( $c, $info ) = @_;
1511     $c->stats->profile( end => $info );
1512 }
1513
1514 =head2 $c->_localize_fields( sub { }, \%keys );
1515
1516 =cut
1517
1518 #Why does this exist? This is no longer safe and WILL NOT WORK.
1519 # it doesnt seem to be used anywhere. can we remove it?
1520 sub _localize_fields {
1521     my ( $c, $localized, $code ) = ( @_ );
1522
1523     my $request = delete $localized->{request} || {};
1524     my $response = delete $localized->{response} || {};
1525
1526     local @{ $c }{ keys %$localized } = values %$localized;
1527     local @{ $c->request }{ keys %$request } = values %$request;
1528     local @{ $c->response }{ keys %$response } = values %$response;
1529
1530     $code->();
1531 }
1532
1533 =head2 $c->finalize
1534
1535 Finalizes the request.
1536
1537 =cut
1538
1539 sub finalize {
1540     my $c = shift;
1541
1542     for my $error ( @{ $c->error } ) {
1543         $c->log->error($error);
1544     }
1545
1546     # Allow engine to handle finalize flow (for POE)
1547     my $engine = $c->engine;
1548     if ( my $code = $engine->can('finalize') ) {
1549         $engine->$code($c);
1550     }
1551     else {
1552
1553         $c->finalize_uploads;
1554
1555         # Error
1556         if ( $#{ $c->error } >= 0 ) {
1557             $c->finalize_error;
1558         }
1559
1560         $c->finalize_headers;
1561
1562         # HEAD request
1563         if ( $c->request->method eq 'HEAD' ) {
1564             $c->response->body('');
1565         }
1566
1567         $c->finalize_body;
1568     }
1569
1570     if ($c->use_stats) {
1571         my $elapsed = sprintf '%f', $c->stats->elapsed;
1572         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1573         $c->log->info(
1574             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1575     }
1576
1577     return $c->response->status;
1578 }
1579
1580 =head2 $c->finalize_body
1581
1582 Finalizes body.
1583
1584 =cut
1585
1586 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1587
1588 =head2 $c->finalize_cookies
1589
1590 Finalizes cookies.
1591
1592 =cut
1593
1594 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1595
1596 =head2 $c->finalize_error
1597
1598 Finalizes error.
1599
1600 =cut
1601
1602 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1603
1604 =head2 $c->finalize_headers
1605
1606 Finalizes headers.
1607
1608 =cut
1609
1610 sub finalize_headers {
1611     my $c = shift;
1612
1613     my $response = $c->response; #accessor calls can add up?
1614
1615     # Check if we already finalized headers
1616     return if $response->finalized_headers;
1617
1618     # Handle redirects
1619     if ( my $location = $response->redirect ) {
1620         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1621         $response->header( Location => $location );
1622
1623         if ( !$response->has_body ) {
1624             # Add a default body if none is already present
1625             $response->body(
1626                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1627             );
1628         }
1629     }
1630
1631     # Content-Length
1632     if ( $response->body && !$response->content_length ) {
1633
1634         # get the length from a filehandle
1635         if ( blessed( $response->body ) && $response->body->can('read') )
1636         {
1637             my $stat = stat $response->body;
1638             if ( $stat && $stat->size > 0 ) {
1639                 $response->content_length( $stat->size );
1640             }
1641             else {
1642                 $c->log->warn('Serving filehandle without a content-length');
1643             }
1644         }
1645         else {
1646             # everything should be bytes at this point, but just in case
1647             $response->content_length( bytes::length( $response->body ) );
1648         }
1649     }
1650
1651     # Errors
1652     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1653         $response->headers->remove_header("Content-Length");
1654         $response->body('');
1655     }
1656
1657     $c->finalize_cookies;
1658
1659     $c->engine->finalize_headers( $c, @_ );
1660
1661     # Done
1662     $response->finalized_headers(1);
1663 }
1664
1665 =head2 $c->finalize_output
1666
1667 An alias for finalize_body.
1668
1669 =head2 $c->finalize_read
1670
1671 Finalizes the input after reading is complete.
1672
1673 =cut
1674
1675 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1676
1677 =head2 $c->finalize_uploads
1678
1679 Finalizes uploads. Cleans up any temporary files.
1680
1681 =cut
1682
1683 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1684
1685 =head2 $c->get_action( $action, $namespace )
1686
1687 Gets an action in a given namespace.
1688
1689 =cut
1690
1691 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1692
1693 =head2 $c->get_actions( $action, $namespace )
1694
1695 Gets all actions of a given name in a namespace and all parent
1696 namespaces.
1697
1698 =cut
1699
1700 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1701
1702 =head2 $c->handle_request( $class, @arguments )
1703
1704 Called to handle each HTTP request.
1705
1706 =cut
1707
1708 sub handle_request {
1709     my ( $class, @arguments ) = @_;
1710
1711     # Always expect worst case!
1712     my $status = -1;
1713     eval {
1714         if ($class->debug) {
1715             my $secs = time - $START || 1;
1716             my $av = sprintf '%.3f', $COUNT / $secs;
1717             my $time = localtime time;
1718             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1719         }
1720
1721         my $c = $class->prepare(@arguments);
1722         $c->dispatch;
1723         $status = $c->finalize;
1724     };
1725
1726     if ( my $error = $@ ) {
1727         chomp $error;
1728         $class->log->error(qq/Caught exception in engine "$error"/);
1729     }
1730
1731     $COUNT++;
1732
1733     if(my $coderef = $class->log->can('_flush')){
1734         $class->log->$coderef();
1735     }
1736     return $status;
1737 }
1738
1739 =head2 $c->prepare( @arguments )
1740
1741 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1742 etc.).
1743
1744 =cut
1745
1746 sub prepare {
1747     my ( $class, @arguments ) = @_;
1748
1749     # XXX
1750     # After the app/ctxt split, this should become an attribute based on something passed
1751     # into the application.
1752     $class->context_class( ref $class || $class ) unless $class->context_class;
1753
1754     my $c = $class->context_class->new({});
1755
1756     # For on-demand data
1757     $c->request->_context($c);
1758     $c->response->_context($c);
1759
1760     #surely this is not the most efficient way to do things...
1761     $c->stats($class->stats_class->new)->enable($c->use_stats);
1762     if ( $c->debug ) {
1763         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1764     }
1765
1766     #XXX reuse coderef from can
1767     # Allow engine to direct the prepare flow (for POE)
1768     if ( $c->engine->can('prepare') ) {
1769         $c->engine->prepare( $c, @arguments );
1770     }
1771     else {
1772         $c->prepare_request(@arguments);
1773         $c->prepare_connection;
1774         $c->prepare_query_parameters;
1775         $c->prepare_headers;
1776         $c->prepare_cookies;
1777         $c->prepare_path;
1778
1779         # Prepare the body for reading, either by prepare_body
1780         # or the user, if they are using $c->read
1781         $c->prepare_read;
1782
1783         # Parse the body unless the user wants it on-demand
1784         unless ( $c->config->{parse_on_demand} ) {
1785             $c->prepare_body;
1786         }
1787     }
1788
1789     my $method  = $c->req->method  || '';
1790     my $path    = $c->req->path;
1791     $path       = '/' unless length $path;
1792     my $address = $c->req->address || '';
1793
1794     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1795       if $c->debug;
1796
1797     $c->prepare_action;
1798
1799     return $c;
1800 }
1801
1802 =head2 $c->prepare_action
1803
1804 Prepares action. See L<Catalyst::Dispatcher>.
1805
1806 =cut
1807
1808 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1809
1810 =head2 $c->prepare_body
1811
1812 Prepares message body.
1813
1814 =cut
1815
1816 sub prepare_body {
1817     my $c = shift;
1818
1819     return if $c->request->_has_body;
1820
1821     # Initialize on-demand data
1822     $c->engine->prepare_body( $c, @_ );
1823     $c->prepare_parameters;
1824     $c->prepare_uploads;
1825
1826     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1827         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1828         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1829             my $param = $c->req->body_parameters->{$key};
1830             my $value = defined($param) ? $param : '';
1831             $t->row( $key,
1832                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1833         }
1834         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1835     }
1836 }
1837
1838 =head2 $c->prepare_body_chunk( $chunk )
1839
1840 Prepares a chunk of data before sending it to L<HTTP::Body>.
1841
1842 See L<Catalyst::Engine>.
1843
1844 =cut
1845
1846 sub prepare_body_chunk {
1847     my $c = shift;
1848     $c->engine->prepare_body_chunk( $c, @_ );
1849 }
1850
1851 =head2 $c->prepare_body_parameters
1852
1853 Prepares body parameters.
1854
1855 =cut
1856
1857 sub prepare_body_parameters {
1858     my $c = shift;
1859     $c->engine->prepare_body_parameters( $c, @_ );
1860 }
1861
1862 =head2 $c->prepare_connection
1863
1864 Prepares connection.
1865
1866 =cut
1867
1868 sub prepare_connection {
1869     my $c = shift;
1870     $c->engine->prepare_connection( $c, @_ );
1871 }
1872
1873 =head2 $c->prepare_cookies
1874
1875 Prepares cookies.
1876
1877 =cut
1878
1879 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1880
1881 =head2 $c->prepare_headers
1882
1883 Prepares headers.
1884
1885 =cut
1886
1887 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1888
1889 =head2 $c->prepare_parameters
1890
1891 Prepares parameters.
1892
1893 =cut
1894
1895 sub prepare_parameters {
1896     my $c = shift;
1897     $c->prepare_body_parameters;
1898     $c->engine->prepare_parameters( $c, @_ );
1899 }
1900
1901 =head2 $c->prepare_path
1902
1903 Prepares path and base.
1904
1905 =cut
1906
1907 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1908
1909 =head2 $c->prepare_query_parameters
1910
1911 Prepares query parameters.
1912
1913 =cut
1914
1915 sub prepare_query_parameters {
1916     my $c = shift;
1917
1918     $c->engine->prepare_query_parameters( $c, @_ );
1919
1920     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1921         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1922         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1923             my $param = $c->req->query_parameters->{$key};
1924             my $value = defined($param) ? $param : '';
1925             $t->row( $key,
1926                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1927         }
1928         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1929     }
1930 }
1931
1932 =head2 $c->prepare_read
1933
1934 Prepares the input for reading.
1935
1936 =cut
1937
1938 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1939
1940 =head2 $c->prepare_request
1941
1942 Prepares the engine request.
1943
1944 =cut
1945
1946 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1947
1948 =head2 $c->prepare_uploads
1949
1950 Prepares uploads.
1951
1952 =cut
1953
1954 sub prepare_uploads {
1955     my $c = shift;
1956
1957     $c->engine->prepare_uploads( $c, @_ );
1958
1959     if ( $c->debug && keys %{ $c->request->uploads } ) {
1960         my $t = Text::SimpleTable->new(
1961             [ 12, 'Parameter' ],
1962             [ 26, 'Filename' ],
1963             [ 18, 'Type' ],
1964             [ 9,  'Size' ]
1965         );
1966         for my $key ( sort keys %{ $c->request->uploads } ) {
1967             my $upload = $c->request->uploads->{$key};
1968             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1969                 $t->row( $key, $u->filename, $u->type, $u->size );
1970             }
1971         }
1972         $c->log->debug( "File Uploads are:\n" . $t->draw );
1973     }
1974 }
1975
1976 =head2 $c->prepare_write
1977
1978 Prepares the output for writing.
1979
1980 =cut
1981
1982 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1983
1984 =head2 $c->request_class
1985
1986 Returns or sets the request class.
1987
1988 =head2 $c->response_class
1989
1990 Returns or sets the response class.
1991
1992 =head2 $c->read( [$maxlength] )
1993
1994 Reads a chunk of data from the request body. This method is designed to
1995 be used in a while loop, reading C<$maxlength> bytes on every call.
1996 C<$maxlength> defaults to the size of the request if not specified.
1997
1998 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1999 directly.
2000
2001 Warning: If you use read(), Catalyst will not process the body,
2002 so you will not be able to access POST parameters or file uploads via
2003 $c->request.  You must handle all body parsing yourself.
2004
2005 =cut
2006
2007 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2008
2009 =head2 $c->run
2010
2011 Starts the engine.
2012
2013 =cut
2014
2015 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2016
2017 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2018
2019 Sets an action in a given namespace.
2020
2021 =cut
2022
2023 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2024
2025 =head2 $c->setup_actions($component)
2026
2027 Sets up actions for a component.
2028
2029 =cut
2030
2031 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2032
2033 =head2 $c->setup_components
2034
2035 Sets up components. Specify a C<setup_components> config option to pass
2036 additional options directly to L<Module::Pluggable>. To add additional
2037 search paths, specify a key named C<search_extra> as an array
2038 reference. Items in the array beginning with C<::> will have the
2039 application class name prepended to them.
2040
2041 All components found will also have any
2042 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2043 Note, that modules which are B<not> an I<inner package> of the main
2044 file namespace loaded will not be instantiated as components.
2045
2046 =cut
2047
2048 sub setup_components {
2049     my $class = shift;
2050
2051     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2052     my $config  = $class->config->{ setup_components };
2053     my $extra   = delete $config->{ search_extra } || [];
2054
2055     push @paths, @$extra;
2056
2057     my $locator = Module::Pluggable::Object->new(
2058         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2059         %$config
2060     );
2061
2062     my @comps = sort { length $a <=> length $b } $locator->plugins;
2063     my %comps = map { $_ => 1 } @comps;
2064
2065     my $deprecated_component_names = grep { /::[CMV]::/ } @comps;
2066     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2067         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2068     ) if $deprecated_component_names;
2069
2070     for my $component ( @comps ) {
2071
2072         # We pass ignore_loaded here so that overlay files for (e.g.)
2073         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2074         # we know M::P::O found a file on disk so this is safe
2075
2076         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2077         #Class::MOP::load_class($component);
2078
2079         my $module  = $class->setup_component( $component );
2080         my %modules = (
2081             $component => $module,
2082             map {
2083                 $_ => $class->setup_component( $_ )
2084             } grep {
2085               not exists $comps{$_}
2086             } Devel::InnerPackage::list_packages( $component )
2087         );
2088
2089         for my $key ( keys %modules ) {
2090             $class->components->{ $key } = $modules{ $key };
2091         }
2092     }
2093 }
2094
2095 =head2 $c->setup_component
2096
2097 =cut
2098
2099 sub setup_component {
2100     my( $class, $component ) = @_;
2101
2102     unless ( $component->can( 'COMPONENT' ) ) {
2103         return $component;
2104     }
2105
2106     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2107     my $config = $class->config->{ $suffix } || {};
2108
2109     my $instance = eval { $component->COMPONENT( $class, $config ); };
2110
2111     if ( my $error = $@ ) {
2112         chomp $error;
2113         Catalyst::Exception->throw(
2114             message => qq/Couldn't instantiate component "$component", "$error"/
2115         );
2116     }
2117
2118     Catalyst::Exception->throw(
2119         message =>
2120         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2121     ) unless blessed($instance);
2122
2123     return $instance;
2124 }
2125
2126 =head2 $c->setup_dispatcher
2127
2128 Sets up dispatcher.
2129
2130 =cut
2131
2132 sub setup_dispatcher {
2133     my ( $class, $dispatcher ) = @_;
2134
2135     if ($dispatcher) {
2136         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2137     }
2138
2139     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2140         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2141     }
2142
2143     unless ($dispatcher) {
2144         $dispatcher = $class->dispatcher_class;
2145     }
2146
2147     Class::MOP::load_class($dispatcher);
2148
2149     # dispatcher instance
2150     $class->dispatcher( $dispatcher->new );
2151 }
2152
2153 =head2 $c->setup_engine
2154
2155 Sets up engine.
2156
2157 =cut
2158
2159 sub setup_engine {
2160     my ( $class, $engine ) = @_;
2161
2162     if ($engine) {
2163         $engine = 'Catalyst::Engine::' . $engine;
2164     }
2165
2166     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2167         $engine = 'Catalyst::Engine::' . $env;
2168     }
2169
2170     if ( $ENV{MOD_PERL} ) {
2171         my $meta = Class::MOP::get_metaclass_by_name($class);
2172
2173         # create the apache method
2174         $meta->add_method('apache' => sub { shift->engine->apache });
2175
2176         my ( $software, $version ) =
2177           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2178
2179         $version =~ s/_//g;
2180         $version =~ s/(\.[^.]+)\./$1/g;
2181
2182         if ( $software eq 'mod_perl' ) {
2183
2184             if ( !$engine ) {
2185
2186                 if ( $version >= 1.99922 ) {
2187                     $engine = 'Catalyst::Engine::Apache2::MP20';
2188                 }
2189
2190                 elsif ( $version >= 1.9901 ) {
2191                     $engine = 'Catalyst::Engine::Apache2::MP19';
2192                 }
2193
2194                 elsif ( $version >= 1.24 ) {
2195                     $engine = 'Catalyst::Engine::Apache::MP13';
2196                 }
2197
2198                 else {
2199                     Catalyst::Exception->throw( message =>
2200                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2201                 }
2202
2203             }
2204
2205             # install the correct mod_perl handler
2206             if ( $version >= 1.9901 ) {
2207                 *handler = sub  : method {
2208                     shift->handle_request(@_);
2209                 };
2210             }
2211             else {
2212                 *handler = sub ($$) { shift->handle_request(@_) };
2213             }
2214
2215         }
2216
2217         elsif ( $software eq 'Zeus-Perl' ) {
2218             $engine = 'Catalyst::Engine::Zeus';
2219         }
2220
2221         else {
2222             Catalyst::Exception->throw(
2223                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2224         }
2225     }
2226
2227     unless ($engine) {
2228         $engine = $class->engine_class;
2229     }
2230
2231     Class::MOP::load_class($engine);
2232
2233     # check for old engines that are no longer compatible
2234     my $old_engine;
2235     if ( $engine->isa('Catalyst::Engine::Apache')
2236         && !Catalyst::Engine::Apache->VERSION )
2237     {
2238         $old_engine = 1;
2239     }
2240
2241     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2242         && Catalyst::Engine::Server->VERSION le '0.02' )
2243     {
2244         $old_engine = 1;
2245     }
2246
2247     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2248         && $engine->VERSION eq '0.01' )
2249     {
2250         $old_engine = 1;
2251     }
2252
2253     elsif ($engine->isa('Catalyst::Engine::Zeus')
2254         && $engine->VERSION eq '0.01' )
2255     {
2256         $old_engine = 1;
2257     }
2258
2259     if ($old_engine) {
2260         Catalyst::Exception->throw( message =>
2261               qq/Engine "$engine" is not supported by this version of Catalyst/
2262         );
2263     }
2264
2265     # engine instance
2266     $class->engine( $engine->new );
2267 }
2268
2269 =head2 $c->setup_home
2270
2271 Sets up the home directory.
2272
2273 =cut
2274
2275 sub setup_home {
2276     my ( $class, $home ) = @_;
2277
2278     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2279         $home = $env;
2280     }
2281
2282     $home ||= Catalyst::Utils::home($class);
2283
2284     if ($home) {
2285         #I remember recently being scolded for assigning config values like this
2286         $class->config->{home} ||= $home;
2287         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2288     }
2289 }
2290
2291 =head2 $c->setup_log
2292
2293 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2294 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2295 log to.
2296
2297 This method also installs a C<debug> method that returns a true value into the
2298 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2299 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2300
2301 Note that if the log has already been setup, by either a previous call to
2302 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2303 that this method won't actually set up the log object.
2304
2305 =cut
2306
2307 sub setup_log {
2308     my ( $class, $levels ) = @_;
2309
2310     $levels ||= '';
2311     $levels =~ s/^\s+//;
2312     $levels =~ s/\s+$//;
2313     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels || '';
2314
2315     unless ( $class->log ) {
2316         $class->log( Catalyst::Log->new(keys %levels) );
2317     }
2318
2319     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2320     if ( defined($env_debug) or $levels{debug} ) {
2321         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2322         $class->log->debug('Debug messages enabled');
2323     }
2324 }
2325
2326 =head2 $c->setup_plugins
2327
2328 Sets up plugins.
2329
2330 =cut
2331
2332 =head2 $c->setup_stats
2333
2334 Sets up timing statistics class.
2335
2336 =cut
2337
2338 sub setup_stats {
2339     my ( $class, $stats ) = @_;
2340
2341     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2342
2343     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2344     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2345         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2346         $class->log->debug('Statistics enabled');
2347     }
2348 }
2349
2350
2351 =head2 $c->registered_plugins
2352
2353 Returns a sorted list of the plugins which have either been stated in the
2354 import list or which have been added via C<< MyApp->plugin(@args); >>.
2355
2356 If passed a given plugin name, it will report a boolean value indicating
2357 whether or not that plugin is loaded.  A fully qualified name is required if
2358 the plugin name does not begin with C<Catalyst::Plugin::>.
2359
2360  if ($c->registered_plugins('Some::Plugin')) {
2361      ...
2362  }
2363
2364 =cut
2365
2366 {
2367
2368     sub registered_plugins {
2369         my $proto = shift;
2370         return sort keys %{ $proto->_plugins } unless @_;
2371         my $plugin = shift;
2372         return 1 if exists $proto->_plugins->{$plugin};
2373         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2374     }
2375
2376     sub _register_plugin {
2377         my ( $proto, $plugin, $instant ) = @_;
2378         my $class = ref $proto || $proto;
2379
2380         # no ignore_loaded here, the plugin may already have been
2381         # defined in memory and we don't want to error on "no file" if so
2382
2383         Class::MOP::load_class( $plugin );
2384
2385         $proto->_plugins->{$plugin} = 1;
2386         unless ($instant) {
2387             no strict 'refs';
2388             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2389               my @superclasses = ($plugin, $meta->superclasses );
2390               $meta->superclasses(@superclasses);
2391             } else {
2392               unshift @{"$class\::ISA"}, $plugin;
2393             }
2394         }
2395         return $class;
2396     }
2397
2398     sub setup_plugins {
2399         my ( $class, $plugins ) = @_;
2400
2401         $class->_plugins( {} ) unless $class->_plugins;
2402         $plugins ||= [];
2403         for my $plugin ( reverse @$plugins ) {
2404
2405             unless ( $plugin =~ s/\A\+// ) {
2406                 $plugin = "Catalyst::Plugin::$plugin";
2407             }
2408
2409             $class->_register_plugin($plugin);
2410         }
2411     }
2412 }
2413
2414 =head2 $c->stack
2415
2416 Returns an arrayref of the internal execution stack (actions that are
2417 currently executing).
2418
2419 =head2 $c->stats_class
2420
2421 Returns or sets the stats (timing statistics) class.
2422
2423 =head2 $c->use_stats
2424
2425 Returns 1 when stats collection is enabled.  Stats collection is enabled
2426 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2427 environment variable is set.
2428
2429 Note that this is a static method, not an accessor and should be overloaded
2430 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2431
2432 =cut
2433
2434 sub use_stats { 0 }
2435
2436
2437 =head2 $c->write( $data )
2438
2439 Writes $data to the output stream. When using this method directly, you
2440 will need to manually set the C<Content-Length> header to the length of
2441 your output data, if known.
2442
2443 =cut
2444
2445 sub write {
2446     my $c = shift;
2447
2448     # Finalize headers if someone manually writes output
2449     $c->finalize_headers;
2450
2451     return $c->engine->write( $c, @_ );
2452 }
2453
2454 =head2 version
2455
2456 Returns the Catalyst version number. Mostly useful for "powered by"
2457 messages in template systems.
2458
2459 =cut
2460
2461 sub version { return $Catalyst::VERSION }
2462
2463 =head1 INTERNAL ACTIONS
2464
2465 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2466 C<_ACTION>, and C<_END>. These are by default not shown in the private
2467 action table, but you can make them visible with a config parameter.
2468
2469     MyApp->config->{show_internal_actions} = 1;
2470
2471 =head1 CASE SENSITIVITY
2472
2473 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2474 mapped to C</foo/bar>. You can activate case sensitivity with a config
2475 parameter.
2476
2477     MyApp->config->{case_sensitive} = 1;
2478
2479 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2480
2481 =head1 ON-DEMAND PARSER
2482
2483 The request body is usually parsed at the beginning of a request,
2484 but if you want to handle input yourself, you can enable on-demand
2485 parsing with a config parameter.
2486
2487     MyApp->config->{parse_on_demand} = 1;
2488
2489 =head1 PROXY SUPPORT
2490
2491 Many production servers operate using the common double-server approach,
2492 with a lightweight frontend web server passing requests to a larger
2493 backend server. An application running on the backend server must deal
2494 with two problems: the remote user always appears to be C<127.0.0.1> and
2495 the server's hostname will appear to be C<localhost> regardless of the
2496 virtual host that the user connected through.
2497
2498 Catalyst will automatically detect this situation when you are running
2499 the frontend and backend servers on the same machine. The following
2500 changes are made to the request.
2501
2502     $c->req->address is set to the user's real IP address, as read from
2503     the HTTP X-Forwarded-For header.
2504
2505     The host value for $c->req->base and $c->req->uri is set to the real
2506     host, as read from the HTTP X-Forwarded-Host header.
2507
2508 Obviously, your web server must support these headers for this to work.
2509
2510 In a more complex server farm environment where you may have your
2511 frontend proxy server(s) on different machines, you will need to set a
2512 configuration option to tell Catalyst to read the proxied data from the
2513 headers.
2514
2515     MyApp->config->{using_frontend_proxy} = 1;
2516
2517 If you do not wish to use the proxy support at all, you may set:
2518
2519     MyApp->config->{ignore_frontend_proxy} = 1;
2520
2521 =head1 THREAD SAFETY
2522
2523 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2524 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2525 believe the Catalyst core to be thread-safe.
2526
2527 If you plan to operate in a threaded environment, remember that all other
2528 modules you are using must also be thread-safe. Some modules, most notably
2529 L<DBD::SQLite>, are not thread-safe.
2530
2531 =head1 SUPPORT
2532
2533 IRC:
2534
2535     Join #catalyst on irc.perl.org.
2536
2537 Mailing Lists:
2538
2539     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2540     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2541
2542 Web:
2543
2544     http://catalyst.perl.org
2545
2546 Wiki:
2547
2548     http://dev.catalyst.perl.org
2549
2550 =head1 SEE ALSO
2551
2552 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2553
2554 =head2 L<Catalyst::Manual> - The Catalyst Manual
2555
2556 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2557
2558 =head2 L<Catalyst::Engine> - Core engine
2559
2560 =head2 L<Catalyst::Log> - Log class.
2561
2562 =head2 L<Catalyst::Request> - Request object
2563
2564 =head2 L<Catalyst::Response> - Response object
2565
2566 =head2 L<Catalyst::Test> - The test suite.
2567
2568 =head1 PROJECT FOUNDER
2569
2570 sri: Sebastian Riedel <sri@cpan.org>
2571
2572 =head1 CONTRIBUTORS
2573
2574 abw: Andy Wardley
2575
2576 acme: Leon Brocard <leon@astray.com>
2577
2578 Andrew Bramble
2579
2580 Andrew Ford
2581
2582 Andrew Ruthven
2583
2584 andyg: Andy Grundman <andy@hybridized.org>
2585
2586 audreyt: Audrey Tang
2587
2588 bricas: Brian Cassidy <bricas@cpan.org>
2589
2590 Caelum: Rafael Kitover <rkitover@io.com>
2591
2592 chansen: Christian Hansen
2593
2594 chicks: Christopher Hicks
2595
2596 David E. Wheeler
2597
2598 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2599
2600 Drew Taylor
2601
2602 esskar: Sascha Kiefer
2603
2604 fireartist: Carl Franks <cfranks@cpan.org>
2605
2606 gabb: Danijel Milicevic
2607
2608 Gary Ashton Jones
2609
2610 Geoff Richards
2611
2612 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2613
2614 jcamacho: Juan Camacho
2615
2616 jhannah: Jay Hannah <jay@jays.net>
2617
2618 Jody Belka
2619
2620 Johan Lindstrom
2621
2622 jon: Jon Schutz <jjschutz@cpan.org>
2623
2624 marcus: Marcus Ramberg <mramberg@cpan.org>
2625
2626 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2627
2628 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2629
2630 mugwump: Sam Vilain
2631
2632 naughton: David Naughton
2633
2634 ningu: David Kamholz <dkamholz@cpan.org>
2635
2636 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2637
2638 numa: Dan Sully <daniel@cpan.org>
2639
2640 obra: Jesse Vincent
2641
2642 omega: Andreas Marienborg
2643
2644 Oleg Kostyuk <cub.uanic@gmail.com>
2645
2646 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2647
2648 rafl: Florian Ragwitz <rafl@debian.org>
2649
2650 sky: Arthur Bergman
2651
2652 the_jester: Jesse Sheidlower
2653
2654 t0m: Tomas Doran <bobtfish@bobtfish.net>
2655
2656 Ulf Edvinsson
2657
2658 willert: Sebastian Willert <willert@cpan.org>
2659
2660 =head1 LICENSE
2661
2662 This library is free software, you can redistribute it and/or modify it under
2663 the same terms as Perl itself.
2664
2665 =cut
2666
2667 no Moose;
2668
2669 __PACKAGE__->meta->make_immutable;
2670
2671 1;