lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use bytes;
   8 use B::Hooks::EndOfScope ();
   9 use Catalyst::Exception;
  10 use Catalyst::Exception::Detach;
  11 use Catalyst::Exception::Go;
  12 use Catalyst::Log;
  13 use Catalyst::Request;
  14 use Catalyst::Request::Upload;
  15 use Catalyst::Response;
  16 use Catalyst::Utils;
  17 use Catalyst::Controller;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80011';
  83
  84 {
  85     my $dev_version = $VERSION =~ /_\d{2}$/;
  86     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  87 }
  88
  89 $VERSION = eval $VERSION;
  90
  91 sub import {
  92     my ( $class, @arguments ) = @_;
  93
  94     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  95     # callers @ISA.
  96     return unless $class eq 'Catalyst';
  97
  98     my $caller = caller();
  99     return if $caller eq 'main';
 100
 101     # Kill Adopt::NEXT warnings if we're a non-RC version
 102     unless (_IS_DEVELOPMENT_VERSION()) {
 103         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 104     }
 105
 106     my $meta = Moose::Meta::Class->initialize($caller);
 107     unless ( $caller->isa('Catalyst') ) {
 108         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 109         $meta->superclasses(@superclasses);
 110     }
 111     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 112     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 113
 114     unless( $meta->has_method('meta') ){
 115         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 116     }
 117
 118     $caller->arguments( [@arguments] );
 119     $caller->setup_home;
 120 }
 121
 122 sub _application { $_[0] }
 123
 124 =head1 NAME
 125
 126 Catalyst - The Elegant MVC Web Application Framework
 127
 128 =head1 SYNOPSIS
 129
 130 See the L<Catalyst::Manual> distribution for comprehensive
 131 documentation and tutorials.
 132
 133     # Install Catalyst::Devel for helpers and other development tools
 134     # use the helper to create a new application
 135     catalyst.pl MyApp
 136
 137     # add models, views, controllers
 138     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 139     script/myapp_create.pl view MyTemplate TT
 140     script/myapp_create.pl controller Search
 141
 142     # built in testserver -- use -r to restart automatically on changes
 143     # --help to see all available options
 144     script/myapp_server.pl
 145
 146     # command line testing interface
 147     script/myapp_test.pl /yada
 148
 149     ### in lib/MyApp.pm
 150     use Catalyst qw/-Debug/; # include plugins here as well
 151
 152     ### In lib/MyApp/Controller/Root.pm (autocreated)
 153     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 154         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 155         $c->stash->{template} = 'foo.tt'; # set the template
 156         # lookup something from db -- stash vars are passed to TT
 157         $c->stash->{data} =
 158           $c->model('Database::Foo')->search( { country => $args[0] } );
 159         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 160             $c->forward( 'bar' ); # process another action
 161             # do something else after forward returns
 162         }
 163     }
 164
 165     # The foo.tt TT template can use the stash data from the database
 166     [% WHILE (item = data.next) %]
 167         [% item.foo %]
 168     [% END %]
 169
 170     # called for /bar/of/soap, /bar/of/soap/10, etc.
 171     sub bar : Path('/bar/of/soap') { ... }
 172
 173     # called for all actions, from the top-most controller downwards
 174     sub auto : Private {
 175         my ( $self, $c ) = @_;
 176         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 177             $c->res->redirect( '/login' ); # require login
 178             return 0; # abort request and go immediately to end()
 179         }
 180         return 1; # success; carry on to next action
 181     }
 182
 183     # called after all actions are finished
 184     sub end : Private {
 185         my ( $self, $c ) = @_;
 186         if ( scalar @{ $c->error } ) { ... } # handle errors
 187         return if $c->res->body; # already have a response
 188         $c->forward( 'MyApp::View::TT' ); # render template
 189     }
 190
 191     ### in MyApp/Controller/Foo.pm
 192     # called for /foo/bar
 193     sub bar : Local { ... }
 194
 195     # called for /blargle
 196     sub blargle : Global { ... }
 197
 198     # an index action matches /foo, but not /foo/1, etc.
 199     sub index : Private { ... }
 200
 201     ### in MyApp/Controller/Foo/Bar.pm
 202     # called for /foo/bar/baz
 203     sub baz : Local { ... }
 204
 205     # first Root auto is called, then Foo auto, then this
 206     sub auto : Private { ... }
 207
 208     # powerful regular expression paths are also possible
 209     sub details : Regex('^product/(\w+)/details$') {
 210         my ( $self, $c ) = @_;
 211         # extract the (\w+) from the URI
 212         my $product = $c->req->captures->[0];
 213     }
 214
 215 See L<Catalyst::Manual::Intro> for additional information.
 216
 217 =head1 DESCRIPTION
 218
 219 Catalyst is a modern framework for making web applications without the
 220 pain usually associated with this process. This document is a reference
 221 to the main Catalyst application. If you are a new user, we suggest you
 222 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 223
 224 See L<Catalyst::Manual> for more documentation.
 225
 226 Catalyst plugins can be loaded by naming them as arguments to the "use
 227 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 228 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 229 C<My::Module>.
 230
 231     use Catalyst qw/My::Module/;
 232
 233 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 234 fully qualify the name by using a unary plus:
 235
 236     use Catalyst qw/
 237         My::Module
 238         +Fully::Qualified::Plugin::Name
 239     /;
 240
 241 Special flags like C<-Debug> and C<-Engine> can also be specified as
 242 arguments when Catalyst is loaded:
 243
 244     use Catalyst qw/-Debug My::Module/;
 245
 246 The position of plugins and flags in the chain is important, because
 247 they are loaded in the order in which they appear.
 248
 249 The following flags are supported:
 250
 251 =head2 -Debug
 252
 253 Enables debug output. You can also force this setting from the system
 254 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 255 settings override the application, with <MYAPP>_DEBUG having the highest
 256 priority.
 257
 258 =head2 -Engine
 259
 260 Forces Catalyst to use a specific engine. Omit the
 261 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 262
 263     use Catalyst qw/-Engine=CGI/;
 264
 265 =head2 -Home
 266
 267 Forces Catalyst to use a specific home directory, e.g.:
 268
 269     use Catalyst qw[-Home=/usr/mst];
 270
 271 This can also be done in the shell environment by setting either the
 272 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 273 is replaced with the uppercased name of your application, any "::" in
 274 the name will be replaced with underscores, e.g. MyApp::Web should use
 275 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 276
 277 =head2 -Log
 278
 279     use Catalyst '-Log=warn,fatal,error';
 280
 281 Specifies a comma-delimited list of log levels.
 282
 283 =head2 -Stats
 284
 285 Enables statistics collection and reporting. You can also force this setting
 286 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 287 environment settings override the application, with <MYAPP>_STATS having the
 288 highest priority.
 289
 290 e.g.
 291
 292    use Catalyst qw/-Stats=1/
 293
 294 =head1 METHODS
 295
 296 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 297
 298 =head2 $c->action
 299
 300 Returns a L<Catalyst::Action> object for the current action, which
 301 stringifies to the action name. See L<Catalyst::Action>.
 302
 303 =head2 $c->namespace
 304
 305 Returns the namespace of the current action, i.e., the URI prefix
 306 corresponding to the controller of the current action. For example:
 307
 308     # in Controller::Foo::Bar
 309     $c->namespace; # returns 'foo/bar';
 310
 311 =head2 $c->request
 312
 313 =head2 $c->req
 314
 315 Returns the current L<Catalyst::Request> object, giving access to
 316 information about the current client request (including parameters,
 317 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 318
 319 =head2 REQUEST FLOW HANDLING
 320
 321 =head2 $c->forward( $action [, \@arguments ] )
 322
 323 =head2 $c->forward( $class, $method, [, \@arguments ] )
 324
 325 Forwards processing to another action, by its private name. If you give a
 326 class name but no method, C<process()> is called. You may also optionally
 327 pass arguments in an arrayref. The action will receive the arguments in
 328 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 329 C<< $c->req->args >> will be restored to the previous values.
 330
 331 Any data C<return>ed from the action forwarded to, will be returned by the
 332 call to forward.
 333
 334     my $foodata = $c->forward('/foo');
 335     $c->forward('index');
 336     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 337     $c->forward('MyApp::View::TT');
 338
 339 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 340 an C<< eval { } >> around the call (actually
 341 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 342 all 'dies' within the called action. If you want C<die> to propagate you
 343 need to do something like:
 344
 345     $c->forward('foo');
 346     die $c->error if $c->error;
 347
 348 Or make sure to always return true values from your actions and write
 349 your code like this:
 350
 351     $c->forward('foo') || return;
 352
 353 =cut
 354
 355 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 356
 357 =head2 $c->detach( $action [, \@arguments ] )
 358
 359 =head2 $c->detach( $class, $method, [, \@arguments ] )
 360
 361 =head2 $c->detach()
 362
 363 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 364 doesn't return to the previous action when processing is finished.
 365
 366 When called with no arguments it escapes the processing chain entirely.
 367
 368 =cut
 369
 370 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 371
 372 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 373
 374 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 375
 376 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 377 but does a full dispatch, instead of just calling the new C<$action> /
 378 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 379 you go to are called, just like a new request.
 380
 381 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 382 This means, for example, that C<< $c->action >> methods such as
 383 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 384 L<reverse|Catalyst::Action/reverse> return information for the visited action
 385 when they are invoked within the visited action.  This is different from the
 386 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 387 continues to use the $c->action object from the caller action even when
 388 invoked from the callee.
 389
 390 C<< $c->stash >> is kept unchanged.
 391
 392 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 393 allows you to "wrap" another action, just as it would have been called by
 394 dispatching from a URL, while the analogous
 395 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 396 transfer control to another action as if it had been reached directly from a URL.
 397
 398 =cut
 399
 400 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 401
 402 =head2 $c->go( $action [, \@captures, \@arguments ] )
 403
 404 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 405
 406 Almost the same as L<< detach|/"$c->detach( $action [, \@arguments ] )" >>, but does a full dispatch like L</visit>,
 407 instead of just calling the new C<$action> /
 408 C<< $class->$method >>. This means that C<begin>, C<auto> and the
 409 method you visit are called, just like a new request.
 410
 411 C<< $c->stash >> is kept unchanged.
 412
 413 =cut
 414
 415 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 416
 417 =head2 $c->response
 418
 419 =head2 $c->res
 420
 421 Returns the current L<Catalyst::Response> object, see there for details.
 422
 423 =head2 $c->stash
 424
 425 Returns a hashref to the stash, which may be used to store data and pass
 426 it between components during a request. You can also set hash keys by
 427 passing arguments. The stash is automatically sent to the view. The
 428 stash is cleared at the end of a request; it cannot be used for
 429 persistent storage (for this you must use a session; see
 430 L<Catalyst::Plugin::Session> for a complete system integrated with
 431 Catalyst).
 432
 433     $c->stash->{foo} = $bar;
 434     $c->stash( { moose => 'majestic', qux => 0 } );
 435     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 436
 437     # stash is automatically passed to the view for use in a template
 438     $c->forward( 'MyApp::View::TT' );
 439
 440 =cut
 441
 442 around stash => sub {
 443     my $orig = shift;
 444     my $c = shift;
 445     my $stash = $orig->($c);
 446     if (@_) {
 447         my $new_stash = @_ > 1 ? {@_} : $_[0];
 448         croak('stash takes a hash or hashref') unless ref $new_stash;
 449         foreach my $key ( keys %$new_stash ) {
 450           $stash->{$key} = $new_stash->{$key};
 451         }
 452     }
 453
 454     return $stash;
 455 };
 456
 457
 458 =head2 $c->error
 459
 460 =head2 $c->error($error, ...)
 461
 462 =head2 $c->error($arrayref)
 463
 464 Returns an arrayref containing error messages.  If Catalyst encounters an
 465 error while processing a request, it stores the error in $c->error.  This
 466 method should only be used to store fatal error messages.
 467
 468     my @error = @{ $c->error };
 469
 470 Add a new error.
 471
 472     $c->error('Something bad happened');
 473
 474 =cut
 475
 476 sub error {
 477     my $c = shift;
 478     if ( $_[0] ) {
 479         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 480         croak @$error unless ref $c;
 481         push @{ $c->{error} }, @$error;
 482     }
 483     elsif ( defined $_[0] ) { $c->{error} = undef }
 484     return $c->{error} || [];
 485 }
 486
 487
 488 =head2 $c->state
 489
 490 Contains the return value of the last executed action.
 491
 492 =head2 $c->clear_errors
 493
 494 Clear errors.  You probably don't want to clear the errors unless you are
 495 implementing a custom error screen.
 496
 497 This is equivalent to running
 498
 499     $c->error(0);
 500
 501 =cut
 502
 503 sub clear_errors {
 504     my $c = shift;
 505     $c->error(0);
 506 }
 507
 508 sub _comp_search_prefixes {
 509     my $c = shift;
 510     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 511 }
 512
 513 # search components given a name and some prefixes
 514 sub _comp_names_search_prefixes {
 515     my ( $c, $name, @prefixes ) = @_;
 516     my $appclass = ref $c || $c;
 517     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 518     $filter = qr/$filter/; # Compile regex now rather than once per loop
 519
 520     # map the original component name to the sub part that we will search against
 521     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 522         grep { /$filter/ } keys %{ $c->components };
 523
 524     # undef for a name will return all
 525     return keys %eligible if !defined $name;
 526
 527     my $query  = ref $name ? $name : qr/^$name$/i;
 528     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 529
 530     return @result if @result;
 531
 532     # if we were given a regexp to search against, we're done.
 533     return if ref $name;
 534
 535     # regexp fallback
 536     $query  = qr/$name/i;
 537     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 538
 539     # no results? try against full names
 540     if( !@result ) {
 541         @result = grep { m{$query} } keys %eligible;
 542     }
 543
 544     # don't warn if we didn't find any results, it just might not exist
 545     if( @result ) {
 546         # Disgusting hack to work out correct method name
 547         my $warn_for = lc $prefixes[0];
 548         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 549            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 550            "component resolution is unreliable and unsafe.";
 551         my $short = $result[0];
 552         $short =~ s/.*?Model:://;
 553         my $shortmess = Carp::shortmess('');
 554         if ($shortmess =~ m#Catalyst/Plugin#) {
 555            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 556               "plugin's config";
 557         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 558            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 559               "component's config";
 560         } else {
 561            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 562               "but if you really wanted to search, pass in a regexp as the argument " .
 563               "like so: \$c->${warn_for}(qr/${name}/)";
 564         }
 565         $c->log->warn( "${msg}$shortmess" );
 566     }
 567
 568     return @result;
 569 }
 570
 571 # Find possible names for a prefix
 572 sub _comp_names {
 573     my ( $c, @prefixes ) = @_;
 574     my $appclass = ref $c || $c;
 575
 576     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 577
 578     my @names = map { s{$filter}{}; $_; }
 579         $c->_comp_names_search_prefixes( undef, @prefixes );
 580
 581     return @names;
 582 }
 583
 584 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 585 sub _filter_component {
 586     my ( $c, $comp, @args ) = @_;
 587
 588     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 589         return $comp->ACCEPT_CONTEXT( $c, @args );
 590     }
 591
 592     return $comp;
 593 }
 594
 595 =head2 COMPONENT ACCESSORS
 596
 597 =head2 $c->controller($name)
 598
 599 Gets a L<Catalyst::Controller> instance by name.
 600
 601     $c->controller('Foo')->do_stuff;
 602
 603 If the name is omitted, will return the controller for the dispatched
 604 action.
 605
 606 If you want to search for controllers, pass in a regexp as the argument.
 607
 608     # find all controllers that start with Foo
 609     my @foo_controllers = $c->controller(qr{^Foo});
 610
 611
 612 =cut
 613
 614 sub controller {
 615     my ( $c, $name, @args ) = @_;
 616
 617     if( $name ) {
 618         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 619         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 620         return $c->_filter_component( $result[ 0 ], @args );
 621     }
 622
 623     return $c->component( $c->action->class );
 624 }
 625
 626 =head2 $c->model($name)
 627
 628 Gets a L<Catalyst::Model> instance by name.
 629
 630     $c->model('Foo')->do_stuff;
 631
 632 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 633
 634 If the name is omitted, it will look for
 635  - a model object in $c->stash->{current_model_instance}, then
 636  - a model name in $c->stash->{current_model}, then
 637  - a config setting 'default_model', or
 638  - check if there is only one model, and return it if that's the case.
 639
 640 If you want to search for models, pass in a regexp as the argument.
 641
 642     # find all models that start with Foo
 643     my @foo_models = $c->model(qr{^Foo});
 644
 645 =cut
 646
 647 sub model {
 648     my ( $c, $name, @args ) = @_;
 649     my $appclass = ref($c) || $c;
 650     if( $name ) {
 651         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 652         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 653         return $c->_filter_component( $result[ 0 ], @args );
 654     }
 655
 656     if (ref $c) {
 657         return $c->stash->{current_model_instance}
 658           if $c->stash->{current_model_instance};
 659         return $c->model( $c->stash->{current_model} )
 660           if $c->stash->{current_model};
 661     }
 662     return $c->model( $appclass->config->{default_model} )
 663       if $appclass->config->{default_model};
 664
 665     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 666
 667     if( $rest ) {
 668         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 669         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 670         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 671         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 672         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 673     }
 674
 675     return $c->_filter_component( $comp );
 676 }
 677
 678
 679 =head2 $c->view($name)
 680
 681 Gets a L<Catalyst::View> instance by name.
 682
 683     $c->view('Foo')->do_stuff;
 684
 685 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 686
 687 If the name is omitted, it will look for
 688  - a view object in $c->stash->{current_view_instance}, then
 689  - a view name in $c->stash->{current_view}, then
 690  - a config setting 'default_view', or
 691  - check if there is only one view, and return it if that's the case.
 692
 693 If you want to search for views, pass in a regexp as the argument.
 694
 695     # find all views that start with Foo
 696     my @foo_views = $c->view(qr{^Foo});
 697
 698 =cut
 699
 700 sub view {
 701     my ( $c, $name, @args ) = @_;
 702
 703     my $appclass = ref($c) || $c;
 704     if( $name ) {
 705         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 706         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 707         return $c->_filter_component( $result[ 0 ], @args );
 708     }
 709
 710     if (ref $c) {
 711         return $c->stash->{current_view_instance}
 712           if $c->stash->{current_view_instance};
 713         return $c->view( $c->stash->{current_view} )
 714           if $c->stash->{current_view};
 715     }
 716     return $c->view( $appclass->config->{default_view} )
 717       if $appclass->config->{default_view};
 718
 719     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 720
 721     if( $rest ) {
 722         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 723         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 724         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 725         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 726         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 727     }
 728
 729     return $c->_filter_component( $comp );
 730 }
 731
 732 =head2 $c->controllers
 733
 734 Returns the available names which can be passed to $c->controller
 735
 736 =cut
 737
 738 sub controllers {
 739     my ( $c ) = @_;
 740     return $c->_comp_names(qw/Controller C/);
 741 }
 742
 743 =head2 $c->models
 744
 745 Returns the available names which can be passed to $c->model
 746
 747 =cut
 748
 749 sub models {
 750     my ( $c ) = @_;
 751     return $c->_comp_names(qw/Model M/);
 752 }
 753
 754
 755 =head2 $c->views
 756
 757 Returns the available names which can be passed to $c->view
 758
 759 =cut
 760
 761 sub views {
 762     my ( $c ) = @_;
 763     return $c->_comp_names(qw/View V/);
 764 }
 765
 766 =head2 $c->comp($name)
 767
 768 =head2 $c->component($name)
 769
 770 Gets a component object by name. This method is not recommended,
 771 unless you want to get a specific component by full
 772 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 773 should be used instead.
 774
 775 If C<$name> is a regexp, a list of components matched against the full
 776 component name will be returned.
 777
 778 =cut
 779
 780 sub component {
 781     my ( $c, $name, @args ) = @_;
 782
 783     if( $name ) {
 784         my $comps = $c->components;
 785
 786         if( !ref $name ) {
 787             # is it the exact name?
 788             return $c->_filter_component( $comps->{ $name }, @args )
 789                        if exists $comps->{ $name };
 790
 791             # perhaps we just omitted "MyApp"?
 792             my $composed = ( ref $c || $c ) . "::${name}";
 793             return $c->_filter_component( $comps->{ $composed }, @args )
 794                        if exists $comps->{ $composed };
 795
 796             # search all of the models, views and controllers
 797             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 798             return $c->_filter_component( $comp, @args ) if $comp;
 799         }
 800
 801         # This is here so $c->comp( '::M::' ) works
 802         my $query = ref $name ? $name : qr{$name}i;
 803
 804         my @result = grep { m{$query} } keys %{ $c->components };
 805         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 806
 807         if( $result[ 0 ] ) {
 808             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 809             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 810             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 811             return $c->_filter_component( $result[ 0 ], @args );
 812         }
 813
 814         # I would expect to return an empty list here, but that breaks back-compat
 815     }
 816
 817     # fallback
 818     return sort keys %{ $c->components };
 819 }
 820
 821 =head2 CLASS DATA AND HELPER CLASSES
 822
 823 =head2 $c->config
 824
 825 Returns or takes a hashref containing the application's configuration.
 826
 827     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 828
 829 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 830 like C<myapp.conf> in your applications home directory. See
 831 L<Catalyst::Plugin::ConfigLoader>.
 832
 833 =head3 Cascading configuration
 834
 835 The config method is present on all Catalyst components, and configuration
 836 will be merged when an application is started. Configuration loaded with
 837 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 838 followed by configuration in your top level C<MyApp> class. These two
 839 configurations are merged, and then configuration data whose hash key matches a
 840 component name is merged with configuration for that component.
 841
 842 The configuration for a component is then passed to the C<new> method when a
 843 component is constructed.
 844
 845 For example:
 846
 847     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 848     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 849
 850 will mean that C<MyApp::Model::Foo> receives the following data when
 851 constructed:
 852
 853     MyApp::Model::Foo->new({
 854         bar => 'baz',
 855         quux => 'frob',
 856         overrides => 'me',
 857     });
 858
 859 =cut
 860
 861 around config => sub {
 862     my $orig = shift;
 863     my $c = shift;
 864
 865     croak('Setting config after setup has been run is not allowed.')
 866         if ( @_ and $c->setup_finished );
 867
 868     $c->$orig(@_);
 869 };
 870
 871 =head2 $c->log
 872
 873 Returns the logging object instance. Unless it is already set, Catalyst
 874 sets this up with a L<Catalyst::Log> object. To use your own log class,
 875 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 876 C<< __PACKAGE__->setup >>.
 877
 878  __PACKAGE__->log( MyLogger->new );
 879  __PACKAGE__->setup;
 880
 881 And later:
 882
 883     $c->log->info( 'Now logging with my own logger!' );
 884
 885 Your log class should implement the methods described in
 886 L<Catalyst::Log>.
 887
 888
 889 =head2 $c->debug
 890
 891 Returns 1 if debug mode is enabled, 0 otherwise.
 892
 893 You can enable debug mode in several ways:
 894
 895 =over
 896
 897 =item By calling myapp_server.pl with the -d flag
 898
 899 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 900
 901 =item The -Debug option in your MyApp.pm
 902
 903 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 904
 905 =back
 906
 907 Calling C<< $c->debug(1) >> has no effect.
 908
 909 =cut
 910
 911 sub debug { 0 }
 912
 913 =head2 $c->dispatcher
 914
 915 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 916
 917 =head2 $c->engine
 918
 919 Returns the engine instance. See L<Catalyst::Engine>.
 920
 921
 922 =head2 UTILITY METHODS
 923
 924 =head2 $c->path_to(@path)
 925
 926 Merges C<@path> with C<< $c->config->{home} >> and returns a
 927 L<Path::Class::Dir> object. Note you can usually use this object as
 928 a filename, but sometimes you will have to explicitly stringify it
 929 yourself by calling the C<< ->stringify >> method.
 930
 931 For example:
 932
 933     $c->path_to( 'db', 'sqlite.db' );
 934
 935 =cut
 936
 937 sub path_to {
 938     my ( $c, @path ) = @_;
 939     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 940     if ( -d $path ) { return $path }
 941     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 942 }
 943
 944 =head2 $c->plugin( $name, $class, @args )
 945
 946 Helper method for plugins. It creates a class data accessor/mutator and
 947 loads and instantiates the given class.
 948
 949     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 950
 951     $c->prototype->define_javascript_functions;
 952
 953 B<Note:> This method of adding plugins is deprecated. The ability
 954 to add plugins like this B<will be removed> in a Catalyst 5.81.
 955 Please do not use this functionality in new code.
 956
 957 =cut
 958
 959 sub plugin {
 960     my ( $class, $name, $plugin, @args ) = @_;
 961
 962     # See block comment in t/unit_core_plugin.t
 963     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 964
 965     $class->_register_plugin( $plugin, 1 );
 966
 967     eval { $plugin->import };
 968     $class->mk_classdata($name);
 969     my $obj;
 970     eval { $obj = $plugin->new(@args) };
 971
 972     if ($@) {
 973         Catalyst::Exception->throw( message =>
 974               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 975     }
 976
 977     $class->$name($obj);
 978     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 979       if $class->debug;
 980 }
 981
 982 =head2 MyApp->setup
 983
 984 Initializes the dispatcher and engine, loads any plugins, and loads the
 985 model, view, and controller components. You may also specify an array
 986 of plugins to load here, if you choose to not load them in the C<use
 987 Catalyst> line.
 988
 989     MyApp->setup;
 990     MyApp->setup( qw/-Debug/ );
 991
 992 =cut
 993
 994 sub setup {
 995     my ( $class, @arguments ) = @_;
 996     croak('Running setup more than once')
 997         if ( $class->setup_finished );
 998
 999     unless ( $class->isa('Catalyst') ) {
1000
1001         Catalyst::Exception->throw(
1002             message => qq/'$class' does not inherit from Catalyst/ );
1003     }
1004
1005     if ( $class->arguments ) {
1006         @arguments = ( @arguments, @{ $class->arguments } );
1007     }
1008
1009     # Process options
1010     my $flags = {};
1011
1012     foreach (@arguments) {
1013
1014         if (/^-Debug$/) {
1015             $flags->{log} =
1016               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1017         }
1018         elsif (/^-(\w+)=?(.*)$/) {
1019             $flags->{ lc $1 } = $2;
1020         }
1021         else {
1022             push @{ $flags->{plugins} }, $_;
1023         }
1024     }
1025
1026     $class->setup_home( delete $flags->{home} );
1027
1028     $class->setup_log( delete $flags->{log} );
1029     $class->setup_plugins( delete $flags->{plugins} );
1030     $class->setup_dispatcher( delete $flags->{dispatcher} );
1031     $class->setup_engine( delete $flags->{engine} );
1032     $class->setup_stats( delete $flags->{stats} );
1033
1034     for my $flag ( sort keys %{$flags} ) {
1035
1036         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1037             &$code( $class, delete $flags->{$flag} );
1038         }
1039         else {
1040             $class->log->warn(qq/Unknown flag "$flag"/);
1041         }
1042     }
1043
1044     eval { require Catalyst::Devel; };
1045     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1046         $class->log->warn(<<"EOF");
1047 You are running an old script!
1048
1049   Please update by running (this will overwrite existing files):
1050     catalyst.pl -force -scripts $class
1051
1052   or (this will not overwrite existing files):
1053     catalyst.pl -scripts $class
1054
1055 EOF
1056     }
1057
1058     if ( $class->debug ) {
1059         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1060
1061         if (@plugins) {
1062             my $column_width = Catalyst::Utils::term_width() - 6;
1063             my $t = Text::SimpleTable->new($column_width);
1064             $t->row($_) for @plugins;
1065             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1066         }
1067
1068         my $dispatcher = $class->dispatcher;
1069         my $engine     = $class->engine;
1070         my $home       = $class->config->{home};
1071
1072         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1073         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1074
1075         $home
1076           ? ( -d $home )
1077           ? $class->log->debug(qq/Found home "$home"/)
1078           : $class->log->debug(qq/Home "$home" doesn't exist/)
1079           : $class->log->debug(q/Couldn't find home/);
1080     }
1081
1082     # Call plugins setup, this is stupid and evil.
1083     # Also screws C3 badly on 5.10, hack to avoid.
1084     {
1085         no warnings qw/redefine/;
1086         local *setup = sub { };
1087         $class->setup unless $Catalyst::__AM_RESTARTING;
1088     }
1089
1090     # Initialize our data structure
1091     $class->components( {} );
1092
1093     $class->setup_components;
1094
1095     if ( $class->debug ) {
1096         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1097         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1098         for my $comp ( sort keys %{ $class->components } ) {
1099             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1100             $t->row( $comp, $type );
1101         }
1102         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1103           if ( keys %{ $class->components } );
1104     }
1105
1106     # Add our self to components, since we are also a component
1107     if( $class->isa('Catalyst::Controller') ){
1108       $class->components->{$class} = $class;
1109     }
1110
1111     $class->setup_actions;
1112
1113     if ( $class->debug ) {
1114         my $name = $class->config->{name} || 'Application';
1115         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1116     }
1117     $class->log->_flush() if $class->log->can('_flush');
1118
1119     # Make sure that the application class becomes immutable at this point,
1120     B::Hooks::EndOfScope::on_scope_end {
1121         return if $@;
1122         my $meta = Class::MOP::get_metaclass_by_name($class);
1123         if (
1124             $meta->is_immutable
1125             && ! { $meta->immutable_options }->{replace_constructor}
1126             && (
1127                    $class->isa('Class::Accessor::Fast')
1128                 || $class->isa('Class::Accessor')
1129             )
1130         ) {
1131             warn "You made your application class ($class) immutable, "
1132                 . "but did not inline the\nconstructor. "
1133                 . "This will break catalyst, as your app \@ISA "
1134                 . "Class::Accessor(::Fast)?\nPlease pass "
1135                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1136         }
1137         $meta->make_immutable(replace_constructor => 1)
1138             unless $meta->is_immutable;
1139     };
1140
1141     $class->setup_finalize;
1142 }
1143
1144
1145 =head2 $app->setup_finalize
1146
1147 A hook to attach modifiers to.
1148 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1149 Also better than C< setup_finished(); >, as that is a getter method.
1150
1151     sub setup_finalize {
1152
1153         my $app = shift;
1154
1155         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1156
1157         $app->next::method(@_);
1158
1159
1160     }
1161
1162 =cut
1163
1164 sub setup_finalize {
1165     my ($class) = @_;
1166     $class->setup_finished(1);
1167 }
1168
1169 =head2 $c->uri_for( $path, @args?, \%query_values? )
1170
1171 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1172
1173 Constructs an absolute L<URI> object based on the application root, the
1174 provided path, and the additional arguments and query parameters provided.
1175 When used as a string, provides a textual URI.
1176
1177 If the first argument is a string, it is taken as a public URI path relative
1178 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1179 relative to the application root (if it does). It is then merged with
1180 C<< $c->request->base >>; any C<@args> are appended as additional path
1181 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1182
1183 If the first argument is a L<Catalyst::Action> it represents an action which
1184 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1185 optional C<\@captures> argument (an arrayref) allows passing the captured
1186 variables that are needed to fill in the paths of Chained and Regex actions;
1187 once the path is resolved, C<uri_for> continues as though a path was
1188 provided, appending any arguments or parameters and creating an absolute
1189 URI.
1190
1191 The captures for the current request can be found in
1192 C<< $c->request->captures >>, and actions can be resolved using
1193 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1194 path, use C<< $c->uri_for_action >> instead.
1195
1196   # Equivalent to $c->req->uri
1197   $c->uri_for($c->action, $c->req->captures,
1198       @{ $c->req->args }, $c->req->params);
1199
1200   # For the Foo action in the Bar controller
1201   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1202
1203   # Path to a static resource
1204   $c->uri_for('/static/images/logo.png');
1205
1206 =cut
1207
1208 sub uri_for {
1209     my ( $c, $path, @args ) = @_;
1210
1211     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1212         $path = $path->path_prefix;
1213         $path =~ s{/+\z}{};
1214         $path .= '/';
1215     }
1216
1217     if ( blessed($path) ) { # action object
1218         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1219                          ? shift(@args)
1220                          : [] );
1221         my $action = $path;
1222         $path = $c->dispatcher->uri_for_action($action, $captures);
1223         if (not defined $path) {
1224             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1225                 if $c->debug;
1226             return undef;
1227         }
1228         $path = '/' if $path eq '';
1229     }
1230
1231     undef($path) if (defined $path && $path eq '');
1232
1233     my $params =
1234       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1235
1236     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1237     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1238
1239     unshift(@args, $path);
1240
1241     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1242         my $namespace = $c->namespace;
1243         if (defined $path) { # cheesy hack to handle path '../foo'
1244            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1245         }
1246         unshift(@args, $namespace || '');
1247     }
1248
1249     # join args with '/', or a blank string
1250     my $args = join('/', grep { defined($_) } @args);
1251     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1252     $args =~ s!^/+!!;
1253     my $base = $c->req->base;
1254     my $class = ref($base);
1255     $base =~ s{(?<!/)$}{/};
1256
1257     my $query = '';
1258
1259     if (my @keys = keys %$params) {
1260       # somewhat lifted from URI::_query's query_form
1261       $query = '?'.join('&', map {
1262           my $val = $params->{$_};
1263           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1264           s/ /+/g;
1265           my $key = $_;
1266           $val = '' unless defined $val;
1267           (map {
1268               my $param = "$_";
1269               utf8::encode( $param ) if utf8::is_utf8($param);
1270               # using the URI::Escape pattern here so utf8 chars survive
1271               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1272               $param =~ s/ /+/g;
1273               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1274       } @keys);
1275     }
1276
1277     my $res = bless(\"${base}${args}${query}", $class);
1278     $res;
1279 }
1280
1281 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1282
1283 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1284
1285 =over
1286
1287 =item $path
1288
1289 A private path to the Catalyst action you want to create a URI for.
1290
1291 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1292 >> and passing the resulting C<$action> and the remaining arguments to C<<
1293 $c->uri_for >>.
1294
1295 You can also pass in a Catalyst::Action object, in which case it is passed to
1296 C<< $c->uri_for >>.
1297
1298 =back
1299
1300 =cut
1301
1302 sub uri_for_action {
1303     my ( $c, $path, @args ) = @_;
1304     my $action = blessed($path)
1305       ? $path
1306       : $c->dispatcher->get_action_by_path($path);
1307     unless (defined $action) {
1308       croak "Can't find action for path '$path'";
1309     }
1310     return $c->uri_for( $action, @args );
1311 }
1312
1313 =head2 $c->welcome_message
1314
1315 Returns the Catalyst welcome HTML page.
1316
1317 =cut
1318
1319 sub welcome_message {
1320     my $c      = shift;
1321     my $name   = $c->config->{name};
1322     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1323     my $prefix = Catalyst::Utils::appprefix( ref $c );
1324     $c->response->content_type('text/html; charset=utf-8');
1325     return <<"EOF";
1326 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1327     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1328 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1329     <head>
1330     <meta http-equiv="Content-Language" content="en" />
1331     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1332         <title>$name on Catalyst $VERSION</title>
1333         <style type="text/css">
1334             body {
1335                 color: #000;
1336                 background-color: #eee;
1337             }
1338             div#content {
1339                 width: 640px;
1340                 margin-left: auto;
1341                 margin-right: auto;
1342                 margin-top: 10px;
1343                 margin-bottom: 10px;
1344                 text-align: left;
1345                 background-color: #ccc;
1346                 border: 1px solid #aaa;
1347             }
1348             p, h1, h2 {
1349                 margin-left: 20px;
1350                 margin-right: 20px;
1351                 font-family: verdana, tahoma, sans-serif;
1352             }
1353             a {
1354                 font-family: verdana, tahoma, sans-serif;
1355             }
1356             :link, :visited {
1357                     text-decoration: none;
1358                     color: #b00;
1359                     border-bottom: 1px dotted #bbb;
1360             }
1361             :link:hover, :visited:hover {
1362                     color: #555;
1363             }
1364             div#topbar {
1365                 margin: 0px;
1366             }
1367             pre {
1368                 margin: 10px;
1369                 padding: 8px;
1370             }
1371             div#answers {
1372                 padding: 8px;
1373                 margin: 10px;
1374                 background-color: #fff;
1375                 border: 1px solid #aaa;
1376             }
1377             h1 {
1378                 font-size: 0.9em;
1379                 font-weight: normal;
1380                 text-align: center;
1381             }
1382             h2 {
1383                 font-size: 1.0em;
1384             }
1385             p {
1386                 font-size: 0.9em;
1387             }
1388             p img {
1389                 float: right;
1390                 margin-left: 10px;
1391             }
1392             span#appname {
1393                 font-weight: bold;
1394                 font-size: 1.6em;
1395             }
1396         </style>
1397     </head>
1398     <body>
1399         <div id="content">
1400             <div id="topbar">
1401                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1402                     $VERSION</h1>
1403              </div>
1404              <div id="answers">
1405                  <p>
1406                  <img src="$logo" alt="Catalyst Logo" />
1407                  </p>
1408                  <p>Welcome to the  world of Catalyst.
1409                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1410                     framework will make web development something you had
1411                     never expected it to be: Fun, rewarding, and quick.</p>
1412                  <h2>What to do now?</h2>
1413                  <p>That really depends  on what <b>you</b> want to do.
1414                     We do, however, provide you with a few starting points.</p>
1415                  <p>If you want to jump right into web development with Catalyst
1416                     you might want to start with a tutorial.</p>
1417 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1418 </pre>
1419 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1420 <pre>
1421 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1422 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1423 </code></pre>
1424                  <h2>What to do next?</h2>
1425                  <p>Next it's time to write an actual application. Use the
1426                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1427                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1428                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1429                     they can save you a lot of work.</p>
1430                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1431                     <p>Also, be sure to check out the vast and growing
1432                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1433                     you are likely to find what you need there.
1434                     </p>
1435
1436                  <h2>Need help?</h2>
1437                  <p>Catalyst has a very active community. Here are the main places to
1438                     get in touch with us.</p>
1439                  <ul>
1440                      <li>
1441                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1442                      </li>
1443                      <li>
1444                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1445                      </li>
1446                      <li>
1447                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1448                      </li>
1449                  </ul>
1450                  <h2>In conclusion</h2>
1451                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1452                     as we enjoyed making it. Please contact us if you have ideas
1453                     for improvement or other feedback.</p>
1454              </div>
1455          </div>
1456     </body>
1457 </html>
1458 EOF
1459 }
1460
1461 =head1 INTERNAL METHODS
1462
1463 These methods are not meant to be used by end users.
1464
1465 =head2 $c->components
1466
1467 Returns a hash of components.
1468
1469 =head2 $c->context_class
1470
1471 Returns or sets the context class.
1472
1473 =head2 $c->counter
1474
1475 Returns a hashref containing coderefs and execution counts (needed for
1476 deep recursion detection).
1477
1478 =head2 $c->depth
1479
1480 Returns the number of actions on the current internal execution stack.
1481
1482 =head2 $c->dispatch
1483
1484 Dispatches a request to actions.
1485
1486 =cut
1487
1488 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1489
1490 =head2 $c->dispatcher_class
1491
1492 Returns or sets the dispatcher class.
1493
1494 =head2 $c->dump_these
1495
1496 Returns a list of 2-element array references (name, structure) pairs
1497 that will be dumped on the error page in debug mode.
1498
1499 =cut
1500
1501 sub dump_these {
1502     my $c = shift;
1503     [ Request => $c->req ],
1504     [ Response => $c->res ],
1505     [ Stash => $c->stash ],
1506     [ Config => $c->config ];
1507 }
1508
1509 =head2 $c->engine_class
1510
1511 Returns or sets the engine class.
1512
1513 =head2 $c->execute( $class, $coderef )
1514
1515 Execute a coderef in given class and catch exceptions. Errors are available
1516 via $c->error.
1517
1518 =cut
1519
1520 sub execute {
1521     my ( $c, $class, $code ) = @_;
1522     $class = $c->component($class) || $class;
1523     $c->state(0);
1524
1525     if ( $c->depth >= $RECURSION ) {
1526         my $action = $code->reverse();
1527         $action = "/$action" unless $action =~ /->/;
1528         my $error = qq/Deep recursion detected calling "${action}"/;
1529         $c->log->error($error);
1530         $c->error($error);
1531         $c->state(0);
1532         return $c->state;
1533     }
1534
1535     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1536
1537     push( @{ $c->stack }, $code );
1538
1539     no warnings 'recursion';
1540     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1541
1542     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1543
1544     my $last = pop( @{ $c->stack } );
1545
1546     if ( my $error = $@ ) {
1547         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1548             $error->rethrow if $c->depth > 1;
1549         }
1550         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1551             $error->rethrow if $c->depth > 0;
1552         }
1553         else {
1554             unless ( ref $error ) {
1555                 no warnings 'uninitialized';
1556                 chomp $error;
1557                 my $class = $last->class;
1558                 my $name  = $last->name;
1559                 $error = qq/Caught exception in $class->$name "$error"/;
1560             }
1561             $c->error($error);
1562             $c->state(0);
1563         }
1564     }
1565     return $c->state;
1566 }
1567
1568 sub _stats_start_execute {
1569     my ( $c, $code ) = @_;
1570     my $appclass = ref($c) || $c;
1571     return if ( ( $code->name =~ /^_.*/ )
1572         && ( !$appclass->config->{show_internal_actions} ) );
1573
1574     my $action_name = $code->reverse();
1575     $c->counter->{$action_name}++;
1576
1577     my $action = $action_name;
1578     $action = "/$action" unless $action =~ /->/;
1579
1580     # determine if the call was the result of a forward
1581     # this is done by walking up the call stack and looking for a calling
1582     # sub of Catalyst::forward before the eval
1583     my $callsub = q{};
1584     for my $index ( 2 .. 11 ) {
1585         last
1586         if ( ( caller($index) )[0] eq 'Catalyst'
1587             && ( caller($index) )[3] eq '(eval)' );
1588
1589         if ( ( caller($index) )[3] =~ /forward$/ ) {
1590             $callsub = ( caller($index) )[3];
1591             $action  = "-> $action";
1592             last;
1593         }
1594     }
1595
1596     my $uid = $action_name . $c->counter->{$action_name};
1597
1598     # is this a root-level call or a forwarded call?
1599     if ( $callsub =~ /forward$/ ) {
1600
1601         # forward, locate the caller
1602         if ( my $parent = $c->stack->[-1] ) {
1603             $c->stats->profile(
1604                 begin  => $action,
1605                 parent => "$parent" . $c->counter->{"$parent"},
1606                 uid    => $uid,
1607             );
1608         }
1609         else {
1610
1611             # forward with no caller may come from a plugin
1612             $c->stats->profile(
1613                 begin => $action,
1614                 uid   => $uid,
1615             );
1616         }
1617     }
1618     else {
1619
1620         # root-level call
1621         $c->stats->profile(
1622             begin => $action,
1623             uid   => $uid,
1624         );
1625     }
1626     return $action;
1627
1628 }
1629
1630 sub _stats_finish_execute {
1631     my ( $c, $info ) = @_;
1632     $c->stats->profile( end => $info );
1633 }
1634
1635 =head2 $c->finalize
1636
1637 Finalizes the request.
1638
1639 =cut
1640
1641 sub finalize {
1642     my $c = shift;
1643
1644     for my $error ( @{ $c->error } ) {
1645         $c->log->error($error);
1646     }
1647
1648     # Allow engine to handle finalize flow (for POE)
1649     my $engine = $c->engine;
1650     if ( my $code = $engine->can('finalize') ) {
1651         $engine->$code($c);
1652     }
1653     else {
1654
1655         $c->finalize_uploads;
1656
1657         # Error
1658         if ( $#{ $c->error } >= 0 ) {
1659             $c->finalize_error;
1660         }
1661
1662         $c->finalize_headers;
1663
1664         # HEAD request
1665         if ( $c->request->method eq 'HEAD' ) {
1666             $c->response->body('');
1667         }
1668
1669         $c->finalize_body;
1670     }
1671
1672     if ($c->use_stats) {
1673         my $elapsed = sprintf '%f', $c->stats->elapsed;
1674         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1675         $c->log->info(
1676             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1677     }
1678
1679     return $c->response->status;
1680 }
1681
1682 =head2 $c->finalize_body
1683
1684 Finalizes body.
1685
1686 =cut
1687
1688 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1689
1690 =head2 $c->finalize_cookies
1691
1692 Finalizes cookies.
1693
1694 =cut
1695
1696 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1697
1698 =head2 $c->finalize_error
1699
1700 Finalizes error.
1701
1702 =cut
1703
1704 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1705
1706 =head2 $c->finalize_headers
1707
1708 Finalizes headers.
1709
1710 =cut
1711
1712 sub finalize_headers {
1713     my $c = shift;
1714
1715     my $response = $c->response; #accessor calls can add up?
1716
1717     # Check if we already finalized headers
1718     return if $response->finalized_headers;
1719
1720     # Handle redirects
1721     if ( my $location = $response->redirect ) {
1722         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1723         $response->header( Location => $location );
1724
1725         if ( !$response->has_body ) {
1726             # Add a default body if none is already present
1727             $response->body(
1728                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1729             );
1730         }
1731     }
1732
1733     # Content-Length
1734     if ( $response->body && !$response->content_length ) {
1735
1736         # get the length from a filehandle
1737         if ( blessed( $response->body ) && $response->body->can('read') )
1738         {
1739             my $stat = stat $response->body;
1740             if ( $stat && $stat->size > 0 ) {
1741                 $response->content_length( $stat->size );
1742             }
1743             else {
1744                 $c->log->warn('Serving filehandle without a content-length');
1745             }
1746         }
1747         else {
1748             # everything should be bytes at this point, but just in case
1749             $response->content_length( bytes::length( $response->body ) );
1750         }
1751     }
1752
1753     # Errors
1754     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1755         $response->headers->remove_header("Content-Length");
1756         $response->body('');
1757     }
1758
1759     $c->finalize_cookies;
1760
1761     $c->engine->finalize_headers( $c, @_ );
1762
1763     # Done
1764     $response->finalized_headers(1);
1765 }
1766
1767 =head2 $c->finalize_output
1768
1769 An alias for finalize_body.
1770
1771 =head2 $c->finalize_read
1772
1773 Finalizes the input after reading is complete.
1774
1775 =cut
1776
1777 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1778
1779 =head2 $c->finalize_uploads
1780
1781 Finalizes uploads. Cleans up any temporary files.
1782
1783 =cut
1784
1785 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1786
1787 =head2 $c->get_action( $action, $namespace )
1788
1789 Gets an action in a given namespace.
1790
1791 =cut
1792
1793 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1794
1795 =head2 $c->get_actions( $action, $namespace )
1796
1797 Gets all actions of a given name in a namespace and all parent
1798 namespaces.
1799
1800 =cut
1801
1802 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1803
1804 =head2 $c->handle_request( $class, @arguments )
1805
1806 Called to handle each HTTP request.
1807
1808 =cut
1809
1810 sub handle_request {
1811     my ( $class, @arguments ) = @_;
1812
1813     # Always expect worst case!
1814     my $status = -1;
1815     eval {
1816         if ($class->debug) {
1817             my $secs = time - $START || 1;
1818             my $av = sprintf '%.3f', $COUNT / $secs;
1819             my $time = localtime time;
1820             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1821         }
1822
1823         my $c = $class->prepare(@arguments);
1824         $c->dispatch;
1825         $status = $c->finalize;
1826     };
1827
1828     if ( my $error = $@ ) {
1829         chomp $error;
1830         $class->log->error(qq/Caught exception in engine "$error"/);
1831     }
1832
1833     $COUNT++;
1834
1835     if(my $coderef = $class->log->can('_flush')){
1836         $class->log->$coderef();
1837     }
1838     return $status;
1839 }
1840
1841 =head2 $c->prepare( @arguments )
1842
1843 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1844 etc.).
1845
1846 =cut
1847
1848 sub prepare {
1849     my ( $class, @arguments ) = @_;
1850
1851     # XXX
1852     # After the app/ctxt split, this should become an attribute based on something passed
1853     # into the application.
1854     $class->context_class( ref $class || $class ) unless $class->context_class;
1855
1856     my $c = $class->context_class->new({});
1857
1858     # For on-demand data
1859     $c->request->_context($c);
1860     $c->response->_context($c);
1861
1862     #surely this is not the most efficient way to do things...
1863     $c->stats($class->stats_class->new)->enable($c->use_stats);
1864     if ( $c->debug ) {
1865         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1866     }
1867
1868     #XXX reuse coderef from can
1869     # Allow engine to direct the prepare flow (for POE)
1870     if ( $c->engine->can('prepare') ) {
1871         $c->engine->prepare( $c, @arguments );
1872     }
1873     else {
1874         $c->prepare_request(@arguments);
1875         $c->prepare_connection;
1876         $c->prepare_query_parameters;
1877         $c->prepare_headers;
1878         $c->prepare_cookies;
1879         $c->prepare_path;
1880
1881         # Prepare the body for reading, either by prepare_body
1882         # or the user, if they are using $c->read
1883         $c->prepare_read;
1884
1885         # Parse the body unless the user wants it on-demand
1886         unless ( ref($c)->config->{parse_on_demand} ) {
1887             $c->prepare_body;
1888         }
1889     }
1890
1891     my $method  = $c->req->method  || '';
1892     my $path    = $c->req->path;
1893     $path       = '/' unless length $path;
1894     my $address = $c->req->address || '';
1895
1896     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1897       if $c->debug;
1898
1899     $c->prepare_action;
1900
1901     return $c;
1902 }
1903
1904 =head2 $c->prepare_action
1905
1906 Prepares action. See L<Catalyst::Dispatcher>.
1907
1908 =cut
1909
1910 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1911
1912 =head2 $c->prepare_body
1913
1914 Prepares message body.
1915
1916 =cut
1917
1918 sub prepare_body {
1919     my $c = shift;
1920
1921     return if $c->request->_has_body;
1922
1923     # Initialize on-demand data
1924     $c->engine->prepare_body( $c, @_ );
1925     $c->prepare_parameters;
1926     $c->prepare_uploads;
1927
1928     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1929         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1930         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1931             my $param = $c->req->body_parameters->{$key};
1932             my $value = defined($param) ? $param : '';
1933             $t->row( $key,
1934                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1935         }
1936         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1937     }
1938 }
1939
1940 =head2 $c->prepare_body_chunk( $chunk )
1941
1942 Prepares a chunk of data before sending it to L<HTTP::Body>.
1943
1944 See L<Catalyst::Engine>.
1945
1946 =cut
1947
1948 sub prepare_body_chunk {
1949     my $c = shift;
1950     $c->engine->prepare_body_chunk( $c, @_ );
1951 }
1952
1953 =head2 $c->prepare_body_parameters
1954
1955 Prepares body parameters.
1956
1957 =cut
1958
1959 sub prepare_body_parameters {
1960     my $c = shift;
1961     $c->engine->prepare_body_parameters( $c, @_ );
1962 }
1963
1964 =head2 $c->prepare_connection
1965
1966 Prepares connection.
1967
1968 =cut
1969
1970 sub prepare_connection {
1971     my $c = shift;
1972     $c->engine->prepare_connection( $c, @_ );
1973 }
1974
1975 =head2 $c->prepare_cookies
1976
1977 Prepares cookies.
1978
1979 =cut
1980
1981 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1982
1983 =head2 $c->prepare_headers
1984
1985 Prepares headers.
1986
1987 =cut
1988
1989 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1990
1991 =head2 $c->prepare_parameters
1992
1993 Prepares parameters.
1994
1995 =cut
1996
1997 sub prepare_parameters {
1998     my $c = shift;
1999     $c->prepare_body_parameters;
2000     $c->engine->prepare_parameters( $c, @_ );
2001 }
2002
2003 =head2 $c->prepare_path
2004
2005 Prepares path and base.
2006
2007 =cut
2008
2009 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2010
2011 =head2 $c->prepare_query_parameters
2012
2013 Prepares query parameters.
2014
2015 =cut
2016
2017 sub prepare_query_parameters {
2018     my $c = shift;
2019
2020     $c->engine->prepare_query_parameters( $c, @_ );
2021
2022     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
2023         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
2024         for my $key ( sort keys %{ $c->req->query_parameters } ) {
2025             my $param = $c->req->query_parameters->{$key};
2026             my $value = defined($param) ? $param : '';
2027             $t->row( $key,
2028                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2029         }
2030         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2031     }
2032 }
2033
2034 =head2 $c->prepare_read
2035
2036 Prepares the input for reading.
2037
2038 =cut
2039
2040 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2041
2042 =head2 $c->prepare_request
2043
2044 Prepares the engine request.
2045
2046 =cut
2047
2048 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2049
2050 =head2 $c->prepare_uploads
2051
2052 Prepares uploads.
2053
2054 =cut
2055
2056 sub prepare_uploads {
2057     my $c = shift;
2058
2059     $c->engine->prepare_uploads( $c, @_ );
2060
2061     if ( $c->debug && keys %{ $c->request->uploads } ) {
2062         my $t = Text::SimpleTable->new(
2063             [ 12, 'Parameter' ],
2064             [ 26, 'Filename' ],
2065             [ 18, 'Type' ],
2066             [ 9,  'Size' ]
2067         );
2068         for my $key ( sort keys %{ $c->request->uploads } ) {
2069             my $upload = $c->request->uploads->{$key};
2070             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2071                 $t->row( $key, $u->filename, $u->type, $u->size );
2072             }
2073         }
2074         $c->log->debug( "File Uploads are:\n" . $t->draw );
2075     }
2076 }
2077
2078 =head2 $c->prepare_write
2079
2080 Prepares the output for writing.
2081
2082 =cut
2083
2084 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2085
2086 =head2 $c->request_class
2087
2088 Returns or sets the request class.
2089
2090 =head2 $c->response_class
2091
2092 Returns or sets the response class.
2093
2094 =head2 $c->read( [$maxlength] )
2095
2096 Reads a chunk of data from the request body. This method is designed to
2097 be used in a while loop, reading C<$maxlength> bytes on every call.
2098 C<$maxlength> defaults to the size of the request if not specified.
2099
2100 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2101 directly.
2102
2103 Warning: If you use read(), Catalyst will not process the body,
2104 so you will not be able to access POST parameters or file uploads via
2105 $c->request.  You must handle all body parsing yourself.
2106
2107 =cut
2108
2109 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2110
2111 =head2 $c->run
2112
2113 Starts the engine.
2114
2115 =cut
2116
2117 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2118
2119 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2120
2121 Sets an action in a given namespace.
2122
2123 =cut
2124
2125 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2126
2127 =head2 $c->setup_actions($component)
2128
2129 Sets up actions for a component.
2130
2131 =cut
2132
2133 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2134
2135 =head2 $c->setup_components
2136
2137 This method is called internally to set up the application's components.
2138
2139 It finds modules by calling the L<locate_components> method, expands them to
2140 package names with the L<expand_component_module> method, and then installs
2141 each component into the application.
2142
2143 The C<setup_components> config option is passed to both of the above methods.
2144
2145 Installation of each component is performed by the L<setup_component> method,
2146 below.
2147
2148 =cut
2149
2150 sub setup_components {
2151     my $class = shift;
2152
2153     my $config  = $class->config->{ setup_components };
2154
2155     my @comps = sort { length $a <=> length $b }
2156                 $class->locate_components($config);
2157     my %comps = map { $_ => 1 } @comps;
2158
2159     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2160     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2161         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2162     ) if $deprecatedcatalyst_component_names;
2163
2164     for my $component ( @comps ) {
2165
2166         # We pass ignore_loaded here so that overlay files for (e.g.)
2167         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2168         # we know M::P::O found a file on disk so this is safe
2169
2170         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2171
2172         # Needs to be done as soon as the component is loaded, as loading a sub-component
2173         # (next time round the loop) can cause us to get the wrong metaclass..
2174         $class->_controller_init_base_classes($component);
2175     }
2176
2177     for my $component (@comps) {
2178         $class->components->{ $component } = $class->setup_component($component);
2179         for my $component ($class->expand_component_module( $component, $config )) {
2180             next if $comps{$component};
2181             $class->_controller_init_base_classes($component); # Also cover inner packages
2182             $class->components->{ $component } = $class->setup_component($component);
2183         }
2184     }
2185 }
2186
2187 =head2 $c->locate_components( $setup_component_config )
2188
2189 This method is meant to provide a list of component modules that should be
2190 setup for the application.  By default, it will use L<Module::Pluggable>.
2191
2192 Specify a C<setup_components> config option to pass additional options directly
2193 to L<Module::Pluggable>. To add additional search paths, specify a key named
2194 C<search_extra> as an array reference. Items in the array beginning with C<::>
2195 will have the application class name prepended to them.
2196
2197 =cut
2198
2199 sub locate_components {
2200     my $class  = shift;
2201     my $config = shift;
2202
2203     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2204     my $extra   = delete $config->{ search_extra } || [];
2205
2206     push @paths, @$extra;
2207
2208     my $locator = Module::Pluggable::Object->new(
2209         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2210         %$config
2211     );
2212
2213     my @comps = $locator->plugins;
2214
2215     return @comps;
2216 }
2217
2218 =head2 $c->expand_component_module( $component, $setup_component_config )
2219
2220 Components found by C<locate_components> will be passed to this method, which
2221 is expected to return a list of component (package) names to be set up.
2222
2223 =cut
2224
2225 sub expand_component_module {
2226     my ($class, $module) = @_;
2227     return Devel::InnerPackage::list_packages( $module );
2228 }
2229
2230 =head2 $c->setup_component
2231
2232 =cut
2233
2234 # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2235 #         nearest to Catalyst::Controller first, no matter what order stuff happens
2236 #         to be loaded. There are TODO tests in Moose for this, see
2237 #         f2391d17574eff81d911b97be15ea51080500003
2238 sub _controller_init_base_classes {
2239     my ($app_class, $component) = @_;
2240     return unless $component->isa('Catalyst::Controller');
2241     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2242         Moose::Meta::Class->initialize( $class )
2243             unless find_meta($class);
2244     }
2245 }
2246
2247 sub setup_component {
2248     my( $class, $component ) = @_;
2249
2250     unless ( $component->can( 'COMPONENT' ) ) {
2251         return $component;
2252     }
2253
2254     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2255     my $config = $class->config->{ $suffix } || {};
2256     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2257     # methods also pass it. local to avoid pointlessly shitting in config
2258     # for the debug screen, as $component is already the key name.
2259     local $config->{catalyst_component_name} = $component;
2260
2261     my $instance = eval { $component->COMPONENT( $class, $config ); };
2262
2263     if ( my $error = $@ ) {
2264         chomp $error;
2265         Catalyst::Exception->throw(
2266             message => qq/Couldn't instantiate component "$component", "$error"/
2267         );
2268     }
2269
2270     unless (blessed $instance) {
2271         my $metaclass = Moose::Util::find_meta($component);
2272         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2273         my $component_method_from = $method_meta->associated_metaclass->name;
2274         my $value = defined($instance) ? $instance : 'undef';
2275         Catalyst::Exception->throw(
2276             message =>
2277             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2278         );
2279     }
2280     return $instance;
2281 }
2282
2283 =head2 $c->setup_dispatcher
2284
2285 Sets up dispatcher.
2286
2287 =cut
2288
2289 sub setup_dispatcher {
2290     my ( $class, $dispatcher ) = @_;
2291
2292     if ($dispatcher) {
2293         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2294     }
2295
2296     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2297         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2298     }
2299
2300     unless ($dispatcher) {
2301         $dispatcher = $class->dispatcher_class;
2302     }
2303
2304     Class::MOP::load_class($dispatcher);
2305
2306     # dispatcher instance
2307     $class->dispatcher( $dispatcher->new );
2308 }
2309
2310 =head2 $c->setup_engine
2311
2312 Sets up engine.
2313
2314 =cut
2315
2316 sub setup_engine {
2317     my ( $class, $engine ) = @_;
2318
2319     if ($engine) {
2320         $engine = 'Catalyst::Engine::' . $engine;
2321     }
2322
2323     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2324         $engine = 'Catalyst::Engine::' . $env;
2325     }
2326
2327     if ( $ENV{MOD_PERL} ) {
2328         my $meta = Class::MOP::get_metaclass_by_name($class);
2329
2330         # create the apache method
2331         $meta->add_method('apache' => sub { shift->engine->apache });
2332
2333         my ( $software, $version ) =
2334           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2335
2336         $version =~ s/_//g;
2337         $version =~ s/(\.[^.]+)\./$1/g;
2338
2339         if ( $software eq 'mod_perl' ) {
2340
2341             if ( !$engine ) {
2342
2343                 if ( $version >= 1.99922 ) {
2344                     $engine = 'Catalyst::Engine::Apache2::MP20';
2345                 }
2346
2347                 elsif ( $version >= 1.9901 ) {
2348                     $engine = 'Catalyst::Engine::Apache2::MP19';
2349                 }
2350
2351                 elsif ( $version >= 1.24 ) {
2352                     $engine = 'Catalyst::Engine::Apache::MP13';
2353                 }
2354
2355                 else {
2356                     Catalyst::Exception->throw( message =>
2357                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2358                 }
2359
2360             }
2361
2362             # install the correct mod_perl handler
2363             if ( $version >= 1.9901 ) {
2364                 *handler = sub  : method {
2365                     shift->handle_request(@_);
2366                 };
2367             }
2368             else {
2369                 *handler = sub ($$) { shift->handle_request(@_) };
2370             }
2371
2372         }
2373
2374         elsif ( $software eq 'Zeus-Perl' ) {
2375             $engine = 'Catalyst::Engine::Zeus';
2376         }
2377
2378         else {
2379             Catalyst::Exception->throw(
2380                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2381         }
2382     }
2383
2384     unless ($engine) {
2385         $engine = $class->engine_class;
2386     }
2387
2388     Class::MOP::load_class($engine);
2389
2390     # check for old engines that are no longer compatible
2391     my $old_engine;
2392     if ( $engine->isa('Catalyst::Engine::Apache')
2393         && !Catalyst::Engine::Apache->VERSION )
2394     {
2395         $old_engine = 1;
2396     }
2397
2398     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2399         && Catalyst::Engine::Server->VERSION le '0.02' )
2400     {
2401         $old_engine = 1;
2402     }
2403
2404     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2405         && $engine->VERSION eq '0.01' )
2406     {
2407         $old_engine = 1;
2408     }
2409
2410     elsif ($engine->isa('Catalyst::Engine::Zeus')
2411         && $engine->VERSION eq '0.01' )
2412     {
2413         $old_engine = 1;
2414     }
2415
2416     if ($old_engine) {
2417         Catalyst::Exception->throw( message =>
2418               qq/Engine "$engine" is not supported by this version of Catalyst/
2419         );
2420     }
2421
2422     # engine instance
2423     $class->engine( $engine->new );
2424 }
2425
2426 =head2 $c->setup_home
2427
2428 Sets up the home directory.
2429
2430 =cut
2431
2432 sub setup_home {
2433     my ( $class, $home ) = @_;
2434
2435     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2436         $home = $env;
2437     }
2438
2439     $home ||= Catalyst::Utils::home($class);
2440
2441     if ($home) {
2442         #I remember recently being scolded for assigning config values like this
2443         $class->config->{home} ||= $home;
2444         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2445     }
2446 }
2447
2448 =head2 $c->setup_log
2449
2450 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2451 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2452 log to.
2453
2454 This method also installs a C<debug> method that returns a true value into the
2455 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2456 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2457
2458 Note that if the log has already been setup, by either a previous call to
2459 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2460 that this method won't actually set up the log object.
2461
2462 =cut
2463
2464 sub setup_log {
2465     my ( $class, $levels ) = @_;
2466
2467     $levels ||= '';
2468     $levels =~ s/^\s+//;
2469     $levels =~ s/\s+$//;
2470     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2471
2472     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2473     if ( defined $env_debug ) {
2474         $levels{debug} = 1 if $env_debug; # Ugly!
2475         delete($levels{debug}) unless $env_debug;
2476     }
2477
2478     unless ( $class->log ) {
2479         $class->log( Catalyst::Log->new(keys %levels) );
2480     }
2481
2482     if ( $levels{debug} ) {
2483         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2484         $class->log->debug('Debug messages enabled');
2485     }
2486 }
2487
2488 =head2 $c->setup_plugins
2489
2490 Sets up plugins.
2491
2492 =cut
2493
2494 =head2 $c->setup_stats
2495
2496 Sets up timing statistics class.
2497
2498 =cut
2499
2500 sub setup_stats {
2501     my ( $class, $stats ) = @_;
2502
2503     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2504
2505     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2506     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2507         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2508         $class->log->debug('Statistics enabled');
2509     }
2510 }
2511
2512
2513 =head2 $c->registered_plugins
2514
2515 Returns a sorted list of the plugins which have either been stated in the
2516 import list or which have been added via C<< MyApp->plugin(@args); >>.
2517
2518 If passed a given plugin name, it will report a boolean value indicating
2519 whether or not that plugin is loaded.  A fully qualified name is required if
2520 the plugin name does not begin with C<Catalyst::Plugin::>.
2521
2522  if ($c->registered_plugins('Some::Plugin')) {
2523      ...
2524  }
2525
2526 =cut
2527
2528 {
2529
2530     sub registered_plugins {
2531         my $proto = shift;
2532         return sort keys %{ $proto->_plugins } unless @_;
2533         my $plugin = shift;
2534         return 1 if exists $proto->_plugins->{$plugin};
2535         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2536     }
2537
2538     sub _register_plugin {
2539         my ( $proto, $plugin, $instant ) = @_;
2540         my $class = ref $proto || $proto;
2541
2542         Class::MOP::load_class( $plugin );
2543
2544         $proto->_plugins->{$plugin} = 1;
2545         unless ($instant) {
2546             no strict 'refs';
2547             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2548               my @superclasses = ($plugin, $meta->superclasses );
2549               $meta->superclasses(@superclasses);
2550             } else {
2551               unshift @{"$class\::ISA"}, $plugin;
2552             }
2553         }
2554         return $class;
2555     }
2556
2557     sub setup_plugins {
2558         my ( $class, $plugins ) = @_;
2559
2560         $class->_plugins( {} ) unless $class->_plugins;
2561         $plugins ||= [];
2562
2563         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2564
2565         for my $plugin ( reverse @plugins ) {
2566             Class::MOP::load_class($plugin);
2567             my $meta = find_meta($plugin);
2568             next if $meta && $meta->isa('Moose::Meta::Role');
2569
2570             $class->_register_plugin($plugin);
2571         }
2572
2573         my @roles =
2574             map { $_->name }
2575             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2576             map { find_meta($_) }
2577             @plugins;
2578
2579         Moose::Util::apply_all_roles(
2580             $class => @roles
2581         ) if @roles;
2582     }
2583 }
2584
2585 =head2 $c->stack
2586
2587 Returns an arrayref of the internal execution stack (actions that are
2588 currently executing).
2589
2590 =head2 $c->stats_class
2591
2592 Returns or sets the stats (timing statistics) class.
2593
2594 =head2 $c->use_stats
2595
2596 Returns 1 when stats collection is enabled.  Stats collection is enabled
2597 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2598 environment variable is set.
2599
2600 Note that this is a static method, not an accessor and should be overridden
2601 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2602
2603 =cut
2604
2605 sub use_stats { 0 }
2606
2607
2608 =head2 $c->write( $data )
2609
2610 Writes $data to the output stream. When using this method directly, you
2611 will need to manually set the C<Content-Length> header to the length of
2612 your output data, if known.
2613
2614 =cut
2615
2616 sub write {
2617     my $c = shift;
2618
2619     # Finalize headers if someone manually writes output
2620     $c->finalize_headers;
2621
2622     return $c->engine->write( $c, @_ );
2623 }
2624
2625 =head2 version
2626
2627 Returns the Catalyst version number. Mostly useful for "powered by"
2628 messages in template systems.
2629
2630 =cut
2631
2632 sub version { return $Catalyst::VERSION }
2633
2634 =head1 INTERNAL ACTIONS
2635
2636 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2637 C<_ACTION>, and C<_END>. These are by default not shown in the private
2638 action table, but you can make them visible with a config parameter.
2639
2640     MyApp->config(show_internal_actions => 1);
2641
2642 =head1 CASE SENSITIVITY
2643
2644 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2645 mapped to C</foo/bar>. You can activate case sensitivity with a config
2646 parameter.
2647
2648     MyApp->config(case_sensitive => 1);
2649
2650 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2651
2652 =head1 ON-DEMAND PARSER
2653
2654 The request body is usually parsed at the beginning of a request,
2655 but if you want to handle input yourself, you can enable on-demand
2656 parsing with a config parameter.
2657
2658     MyApp->config(parse_on_demand => 1);
2659
2660 =head1 PROXY SUPPORT
2661
2662 Many production servers operate using the common double-server approach,
2663 with a lightweight frontend web server passing requests to a larger
2664 backend server. An application running on the backend server must deal
2665 with two problems: the remote user always appears to be C<127.0.0.1> and
2666 the server's hostname will appear to be C<localhost> regardless of the
2667 virtual host that the user connected through.
2668
2669 Catalyst will automatically detect this situation when you are running
2670 the frontend and backend servers on the same machine. The following
2671 changes are made to the request.
2672
2673     $c->req->address is set to the user's real IP address, as read from
2674     the HTTP X-Forwarded-For header.
2675
2676     The host value for $c->req->base and $c->req->uri is set to the real
2677     host, as read from the HTTP X-Forwarded-Host header.
2678
2679 Additionally, you may be running your backend application on an insecure
2680 connection (port 80) while your frontend proxy is running under SSL.  If there
2681 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2682 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2683 be created properly.
2684
2685 In the case of passing in:
2686
2687     X-Forwarded-Port: 443
2688
2689 All calls to C<uri_for> will result in an https link, as is expected.
2690
2691 Obviously, your web server must support these headers for this to work.
2692
2693 In a more complex server farm environment where you may have your
2694 frontend proxy server(s) on different machines, you will need to set a
2695 configuration option to tell Catalyst to read the proxied data from the
2696 headers.
2697
2698     MyApp->config(using_frontend_proxy => 1);
2699
2700 If you do not wish to use the proxy support at all, you may set:
2701
2702     MyApp->config(ignore_frontend_proxy => 1);
2703
2704 =head1 THREAD SAFETY
2705
2706 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2707 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2708 believe the Catalyst core to be thread-safe.
2709
2710 If you plan to operate in a threaded environment, remember that all other
2711 modules you are using must also be thread-safe. Some modules, most notably
2712 L<DBD::SQLite>, are not thread-safe.
2713
2714 =head1 SUPPORT
2715
2716 IRC:
2717
2718     Join #catalyst on irc.perl.org.
2719
2720 Mailing Lists:
2721
2722     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2723     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2724
2725 Web:
2726
2727     http://catalyst.perl.org
2728
2729 Wiki:
2730
2731     http://dev.catalyst.perl.org
2732
2733 =head1 SEE ALSO
2734
2735 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2736
2737 =head2 L<Catalyst::Manual> - The Catalyst Manual
2738
2739 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2740
2741 =head2 L<Catalyst::Engine> - Core engine
2742
2743 =head2 L<Catalyst::Log> - Log class.
2744
2745 =head2 L<Catalyst::Request> - Request object
2746
2747 =head2 L<Catalyst::Response> - Response object
2748
2749 =head2 L<Catalyst::Test> - The test suite.
2750
2751 =head1 PROJECT FOUNDER
2752
2753 sri: Sebastian Riedel <sri@cpan.org>
2754
2755 =head1 CONTRIBUTORS
2756
2757 abw: Andy Wardley
2758
2759 acme: Leon Brocard <leon@astray.com>
2760
2761 Andrew Bramble
2762
2763 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
2764
2765 Andrew Ruthven
2766
2767 andyg: Andy Grundman <andy@hybridized.org>
2768
2769 audreyt: Audrey Tang
2770
2771 bricas: Brian Cassidy <bricas@cpan.org>
2772
2773 Caelum: Rafael Kitover <rkitover@io.com>
2774
2775 chansen: Christian Hansen
2776
2777 chicks: Christopher Hicks
2778
2779 Chisel Wright C<pause@herlpacker.co.uk>
2780
2781 Danijel Milicevic C<me@danijel.de>
2782
2783 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
2784
2785 David Naughton, C<naughton@umn.edu>
2786
2787 David E. Wheeler
2788
2789 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2790
2791 Drew Taylor
2792
2793 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2794
2795 esskar: Sascha Kiefer
2796
2797 fireartist: Carl Franks <cfranks@cpan.org>
2798
2799 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
2800
2801 gabb: Danijel Milicevic
2802
2803 Gary Ashton Jones
2804
2805 Gavin Henry C<ghenry@perl.me.uk>
2806
2807 Geoff Richards
2808
2809 hobbs: Andrew Rodland <andrew@cleverdomain.org>
2810
2811 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2812
2813 jcamacho: Juan Camacho
2814
2815 jester: Jesse Sheidlower C<jester@panix.com>
2816
2817 jhannah: Jay Hannah <jay@jays.net>
2818
2819 Jody Belka
2820
2821 Johan Lindstrom
2822
2823 jon: Jon Schutz <jjschutz@cpan.org>
2824
2825 Jonathan Rockway C<< <jrockway@cpan.org> >>
2826
2827 Kieren Diment C<kd@totaldatasolution.com>
2828
2829 konobi: Scott McWhirter <konobi@cpan.org>
2830
2831 marcus: Marcus Ramberg <mramberg@cpan.org>
2832
2833 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2834
2835 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2836
2837 mugwump: Sam Vilain
2838
2839 naughton: David Naughton
2840
2841 ningu: David Kamholz <dkamholz@cpan.org>
2842
2843 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2844
2845 numa: Dan Sully <daniel@cpan.org>
2846
2847 obra: Jesse Vincent
2848
2849 omega: Andreas Marienborg
2850
2851 Oleg Kostyuk <cub.uanic@gmail.com>
2852
2853 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2854
2855 rafl: Florian Ragwitz <rafl@debian.org>
2856
2857 random: Roland Lammel <lammel@cpan.org>
2858
2859 Robert Sedlacek C<< <rs@474.at> >>
2860
2861 sky: Arthur Bergman
2862
2863 t0m: Tomas Doran <bobtfish@bobtfish.net>
2864
2865 Ulf Edvinsson
2866
2867 Viljo Marrandi C<vilts@yahoo.com>
2868
2869 Will Hawes C<info@whawes.co.uk>
2870
2871 willert: Sebastian Willert <willert@cpan.org>
2872
2873 Yuval Kogman, C<nothingmuch@woobling.org>
2874
2875 =head1 LICENSE
2876
2877 This library is free software. You can redistribute it and/or modify it under
2878 the same terms as Perl itself.
2879
2880 =cut
2881
2882 no Moose;
2883
2884 __PACKAGE__->meta->make_immutable;
2885
2886 1;