lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Class::Data::Inheritable';
   5 use UNIVERSAL::require;
   6 use Catalyst::Log;
   7
   8 __PACKAGE__->mk_classdata($_) for qw/_config log/;
   9
  10 our $VERSION = '4.28';
  11 our @ISA;
  12
  13 =head1 NAME
  14
  15 Catalyst - The Elegant MVC Web Application Framework
  16
  17 =head1 SYNOPSIS
  18
  19     # use the helper to start a new application
  20     catalyst.pl MyApp
  21     cd MyApp
  22
  23     # add models, views, controllers
  24     script/create.pl model Something
  25     script/create.pl view Stuff
  26     script/create.pl controller Yada
  27
  28     # built in testserver
  29     script/server.pl
  30
  31     # command line interface
  32     script/test.pl /yada
  33
  34
  35     use Catalyst;
  36
  37     use Catalyst qw/My::Module My::OtherModule/;
  38
  39     use Catalyst '-Debug';
  40
  41     use Catalyst qw/-Debug -Engine=CGI/;
  42
  43     __PACKAGE__->action( '!default' => sub { $_[1]->res->output('Hello') } );
  44
  45     __PACKAGE__->action(
  46         'index.html' => sub {
  47             my ( $self, $c ) = @_;
  48             $c->res->output('Hello');
  49             $c->forward('_foo');
  50         }
  51     );
  52
  53     __PACKAGE__->action(
  54         '/^product[_]*(\d*).html$/' => sub {
  55             my ( $self, $c ) = @_;
  56             $c->stash->{template} = 'product.tt';
  57             $c->stash->{product} = $c->req->snippets->[0];
  58         }
  59     );
  60
  61 See also L<Catalyst::Manual::Intro>
  62
  63 =head1 DESCRIPTION
  64
  65 Catalyst is based upon L<Maypole>, which you should consider for smaller
  66 projects.
  67
  68 The key concept of Catalyst is DRY (Don't Repeat Yourself).
  69
  70 See L<Catalyst::Manual> for more documentation.
  71
  72 Catalyst plugins can be loaded by naming them as arguments to the "use Catalyst" statement.
  73 Omit the C<Catalyst::Plugin::> prefix from the plugin name,
  74 so C<Catalyst::Plugin::My::Module> becomes C<My::Module>.
  75
  76     use Catalyst 'My::Module';
  77
  78 Special flags like -Debug and -Engine can also be specifed as arguments when
  79 Catalyst is loaded:
  80
  81     use Catalyst qw/-Debug My::Module/;
  82
  83 The position of plugins and flags in the chain is important, because they are
  84 loaded in exactly the order that they appear.
  85
  86 The following flags are supported:
  87
  88 =over 4
  89
  90 =item -Debug
  91
  92 enables debug output, i.e.:
  93
  94     use Catalyst '-Debug';
  95
  96 this is equivalent to:
  97
  98     use Catalyst;
  99     sub debug { 1 }
 100
 101 =item -Engine
 102
 103 Force Catalyst to use a specific engine.
 104 Omit the C<Catalyst::Engine::> prefix of the engine name, i.e.:
 105
 106     use Catalyst '-Engine=CGI';
 107
 108 =back
 109
 110 =head1 METHODS
 111
 112 =over 4
 113
 114 =item debug
 115
 116 Overload to enable debug messages.
 117
 118 =cut
 119
 120 sub debug { 0 }
 121
 122 =item config
 123
 124 Returns a hashref containing your applications settings.
 125
 126 =cut
 127
 128 sub config {
 129     my $self = shift;
 130     $self->_config( {} ) unless $self->_config;
 131     if ( $_[0] ) {
 132         my $config = $_[1] ? {@_} : $_[0];
 133         while ( my ( $key, $val ) = each %$config ) {
 134             $self->_config->{$key} = $val;
 135         }
 136     }
 137     return $self->_config;
 138 }
 139
 140 sub import {
 141     my ( $self, @options ) = @_;
 142     my $caller = caller(0);
 143
 144     # Class
 145     {
 146         no strict 'refs';
 147         *{"$caller\::handler"} =
 148           sub { Catalyst::Engine::handler( $caller, @_ ) };
 149         push @{"$caller\::ISA"}, $self;
 150     }
 151     $self->log( Catalyst::Log->new );
 152
 153     # Options
 154     my $engine =
 155       $ENV{MOD_PERL} ? 'Catalyst::Engine::Apache' : 'Catalyst::Engine::CGI';
 156     foreach (@options) {
 157         if (/^\-Debug$/) {
 158             no warnings;
 159             no strict 'refs';
 160             *{"$self\::debug"} = sub { 1 };
 161             $caller->log->debug('Debug messages enabled');
 162         }
 163         elsif (/^-Engine=(.*)$/) { $engine = "Catalyst::Engine::$1" }
 164         elsif (/^-.*$/) { $caller->log->error(qq/Unknown flag "$_"/) }
 165         else {
 166             my $plugin = "Catalyst::Plugin::$_";
 167
 168             # Plugin caller should be our application class
 169             eval "package $caller; require $plugin";
 170             if ($@) {
 171                 $caller->log->error(qq/Couldn't load plugin "$plugin", "$@"/);
 172             }
 173             else {
 174                 $caller->log->debug(qq/Loaded plugin "$plugin"/)
 175                   if $caller->debug;
 176                 no strict 'refs';
 177                 push @{"$caller\::ISA"}, $plugin;
 178             }
 179         }
 180     }
 181
 182     # Engine
 183     $engine = "Catalyst::Engine::$ENV{CATALYST_ENGINE}"
 184       if $ENV{CATALYST_ENGINE};
 185     $engine->require;
 186     die qq/Couldn't load engine "$engine", "$@"/ if $@;
 187     {
 188         no strict 'refs';
 189         push @{"$caller\::ISA"}, $engine;
 190     }
 191     $caller->log->debug(qq/Loaded engine "$engine"/) if $caller->debug;
 192 }
 193
 194 =back
 195
 196 =head1 SUPPORT
 197
 198 IRC:
 199
 200     Join #catalyst on irc.perl.org.
 201
 202 Mailing-Lists:
 203
 204     http://lists.rawmode.org/mailman/listinfo/catalyst
 205     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
 206
 207 =head1 SEE ALSO
 208
 209 L<Catalyst::Manual>, L<Catalyst::Test>, L<Catalyst::Request>,
 210 L<Catalyst::Response>, L<Catalyst::Engine>
 211
 212 =head1 AUTHOR
 213
 214 Sebastian Riedel, C<sri@oook.de>
 215
 216 =head1 THANK YOU
 217
 218 Andrew Ruthven, Christian Hansen, Christopher Hicks, Danijel Milicevic,
 219 David Naughton, Gary Ashton Jones, Jesse Sheidlower, Johan Lindstrom,
 220 Marcus Ramberg, Tatsuhiko Miyagawa and all the others who've helped.
 221
 222 =head1 LICENSE
 223
 224 This library is free software . You can redistribute it and/or modify it under
 225 the same terms as perl itself.
 226
 227 =cut
 228
 229 1;