lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use bytes;
   8 use B::Hooks::EndOfScope ();
   9 use Catalyst::Exception;
  10 use Catalyst::Log;
  11 use Catalyst::Request;
  12 use Catalyst::Request::Upload;
  13 use Catalyst::Response;
  14 use Catalyst::Utils;
  15 use Catalyst::Controller;
  16 use Devel::InnerPackage ();
  17 use File::stat;
  18 use Module::Pluggable::Object ();
  19 use Text::SimpleTable ();
  20 use Path::Class::Dir ();
  21 use Path::Class::File ();
  22 use URI ();
  23 use URI::http;
  24 use URI::https;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use Class::C3::Adopt::NEXT;
  28 use attributes;
  29 use utf8;
  30 use Carp qw/croak carp shortmess/;
  31
  32 BEGIN { require 5.008001; }
  33
  34 has stack => (is => 'ro', default => sub { [] });
  35 has stash => (is => 'rw', default => sub { {} });
  36 has state => (is => 'rw', default => 0);
  37 has stats => (is => 'rw');
  38 has action => (is => 'rw');
  39 has counter => (is => 'rw', default => sub { {} });
  40 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  41 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  42 has namespace => (is => 'rw');
  43
  44 sub depth { scalar @{ shift->stack || [] }; }
  45 sub comp { shift->component(@_) }
  46
  47 sub req {
  48     my $self = shift; return $self->request(@_);
  49 }
  50 sub res {
  51     my $self = shift; return $self->response(@_);
  52 }
  53
  54 # For backwards compatibility
  55 sub finalize_output { shift->finalize_body(@_) };
  56
  57 # For statistics
  58 our $COUNT     = 1;
  59 our $START     = time;
  60 our $RECURSION = 1000;
  61 our $DETACH    = "catalyst_detach\n";
  62 our $GO        = "catalyst_go\n";
  63
  64 #I imagine that very few of these really need to be class variables. if any.
  65 #maybe we should just make them attributes with a default?
  66 __PACKAGE__->mk_classdata($_)
  67   for qw/components arguments dispatcher engine log dispatcher_class
  68   engine_class context_class request_class response_class stats_class
  69   setup_finished/;
  70
  71 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  72 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  73 __PACKAGE__->request_class('Catalyst::Request');
  74 __PACKAGE__->response_class('Catalyst::Response');
  75 __PACKAGE__->stats_class('Catalyst::Stats');
  76
  77 # Remember to update this in Catalyst::Runtime as well!
  78
  79 our $VERSION = '5.80005';
  80
  81 {
  82     my $dev_version = $VERSION =~ /_\d{2}$/;
  83     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  84 }
  85
  86 $VERSION = eval $VERSION;
  87
  88 sub import {
  89     my ( $class, @arguments ) = @_;
  90
  91     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  92     # callers @ISA.
  93     return unless $class eq 'Catalyst';
  94
  95     my $caller = caller();
  96     return if $caller eq 'main';
  97
  98     # Kill Adopt::NEXT warnings if we're a non-RC version
  99     unless (_IS_DEVELOPMENT_VERSION()) {
 100         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 101     }
 102
 103     my $meta = Moose::Meta::Class->initialize($caller);
 104     #Moose->import({ into => $caller }); #do we want to do this?
 105
 106     unless ( $caller->isa('Catalyst') ) {
 107         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 108         $meta->superclasses(@superclasses);
 109     }
 110     unless( $meta->has_method('meta') ){
 111         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 112     }
 113
 114     $caller->arguments( [@arguments] );
 115     $caller->setup_home;
 116 }
 117
 118 =head1 NAME
 119
 120 Catalyst - The Elegant MVC Web Application Framework
 121
 122 =head1 SYNOPSIS
 123
 124 See the L<Catalyst::Manual> distribution for comprehensive
 125 documentation and tutorials.
 126
 127     # Install Catalyst::Devel for helpers and other development tools
 128     # use the helper to create a new application
 129     catalyst.pl MyApp
 130
 131     # add models, views, controllers
 132     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 133     script/myapp_create.pl view MyTemplate TT
 134     script/myapp_create.pl controller Search
 135
 136     # built in testserver -- use -r to restart automatically on changes
 137     # --help to see all available options
 138     script/myapp_server.pl
 139
 140     # command line testing interface
 141     script/myapp_test.pl /yada
 142
 143     ### in lib/MyApp.pm
 144     use Catalyst qw/-Debug/; # include plugins here as well
 145
 146     ### In lib/MyApp/Controller/Root.pm (autocreated)
 147     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 148         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 149         $c->stash->{template} = 'foo.tt'; # set the template
 150         # lookup something from db -- stash vars are passed to TT
 151         $c->stash->{data} =
 152           $c->model('Database::Foo')->search( { country => $args[0] } );
 153         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 154             $c->forward( 'bar' ); # process another action
 155             # do something else after forward returns
 156         }
 157     }
 158
 159     # The foo.tt TT template can use the stash data from the database
 160     [% WHILE (item = data.next) %]
 161         [% item.foo %]
 162     [% END %]
 163
 164     # called for /bar/of/soap, /bar/of/soap/10, etc.
 165     sub bar : Path('/bar/of/soap') { ... }
 166
 167     # called for all actions, from the top-most controller downwards
 168     sub auto : Private {
 169         my ( $self, $c ) = @_;
 170         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 171             $c->res->redirect( '/login' ); # require login
 172             return 0; # abort request and go immediately to end()
 173         }
 174         return 1; # success; carry on to next action
 175     }
 176
 177     # called after all actions are finished
 178     sub end : Private {
 179         my ( $self, $c ) = @_;
 180         if ( scalar @{ $c->error } ) { ... } # handle errors
 181         return if $c->res->body; # already have a response
 182         $c->forward( 'MyApp::View::TT' ); # render template
 183     }
 184
 185     ### in MyApp/Controller/Foo.pm
 186     # called for /foo/bar
 187     sub bar : Local { ... }
 188
 189     # called for /blargle
 190     sub blargle : Global { ... }
 191
 192     # an index action matches /foo, but not /foo/1, etc.
 193     sub index : Private { ... }
 194
 195     ### in MyApp/Controller/Foo/Bar.pm
 196     # called for /foo/bar/baz
 197     sub baz : Local { ... }
 198
 199     # first Root auto is called, then Foo auto, then this
 200     sub auto : Private { ... }
 201
 202     # powerful regular expression paths are also possible
 203     sub details : Regex('^product/(\w+)/details$') {
 204         my ( $self, $c ) = @_;
 205         # extract the (\w+) from the URI
 206         my $product = $c->req->captures->[0];
 207     }
 208
 209 See L<Catalyst::Manual::Intro> for additional information.
 210
 211 =head1 DESCRIPTION
 212
 213 Catalyst is a modern framework for making web applications without the
 214 pain usually associated with this process. This document is a reference
 215 to the main Catalyst application. If you are a new user, we suggest you
 216 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 217
 218 See L<Catalyst::Manual> for more documentation.
 219
 220 Catalyst plugins can be loaded by naming them as arguments to the "use
 221 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 222 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 223 C<My::Module>.
 224
 225     use Catalyst qw/My::Module/;
 226
 227 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 228 fully qualify the name by using a unary plus:
 229
 230     use Catalyst qw/
 231         My::Module
 232         +Fully::Qualified::Plugin::Name
 233     /;
 234
 235 Special flags like C<-Debug> and C<-Engine> can also be specified as
 236 arguments when Catalyst is loaded:
 237
 238     use Catalyst qw/-Debug My::Module/;
 239
 240 The position of plugins and flags in the chain is important, because
 241 they are loaded in the order in which they appear.
 242
 243 The following flags are supported:
 244
 245 =head2 -Debug
 246
 247 Enables debug output. You can also force this setting from the system
 248 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 249 settings override the application, with <MYAPP>_DEBUG having the highest
 250 priority.
 251
 252 =head2 -Engine
 253
 254 Forces Catalyst to use a specific engine. Omit the
 255 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 256
 257     use Catalyst qw/-Engine=CGI/;
 258
 259 =head2 -Home
 260
 261 Forces Catalyst to use a specific home directory, e.g.:
 262
 263     use Catalyst qw[-Home=/usr/mst];
 264
 265 This can also be done in the shell environment by setting either the
 266 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 267 is replaced with the uppercased name of your application, any "::" in
 268 the name will be replaced with underscores, e.g. MyApp::Web should use
 269 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 270
 271 =head2 -Log
 272
 273     use Catalyst '-Log=warn,fatal,error';
 274
 275 Specifies a comma-delimited list of log levels.
 276
 277 =head2 -Stats
 278
 279 Enables statistics collection and reporting. You can also force this setting
 280 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 281 environment settings override the application, with <MYAPP>_STATS having the
 282 highest priority.
 283
 284 e.g.
 285
 286    use Catalyst qw/-Stats=1/
 287
 288 =head1 METHODS
 289
 290 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 291
 292 =head2 $c->action
 293
 294 Returns a L<Catalyst::Action> object for the current action, which
 295 stringifies to the action name. See L<Catalyst::Action>.
 296
 297 =head2 $c->namespace
 298
 299 Returns the namespace of the current action, i.e., the URI prefix
 300 corresponding to the controller of the current action. For example:
 301
 302     # in Controller::Foo::Bar
 303     $c->namespace; # returns 'foo/bar';
 304
 305 =head2 $c->request
 306
 307 =head2 $c->req
 308
 309 Returns the current L<Catalyst::Request> object, giving access to
 310 information about the current client request (including parameters,
 311 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 312
 313 =head2 REQUEST FLOW HANDLING
 314
 315 =head2 $c->forward( $action [, \@arguments ] )
 316
 317 =head2 $c->forward( $class, $method, [, \@arguments ] )
 318
 319 Forwards processing to another action, by its private name. If you give a
 320 class name but no method, C<process()> is called. You may also optionally
 321 pass arguments in an arrayref. The action will receive the arguments in
 322 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 323 C<< $c->req->args >> will be restored to the previous values.
 324
 325 Any data C<return>ed from the action forwarded to, will be returned by the
 326 call to forward.
 327
 328     my $foodata = $c->forward('/foo');
 329     $c->forward('index');
 330     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 331     $c->forward('MyApp::View::TT');
 332
 333 Note that forward implies an C<<eval { }>> around the call (actually
 334 C<execute> does), thus de-fatalizing all 'dies' within the called
 335 action. If you want C<die> to propagate you need to do something like:
 336
 337     $c->forward('foo');
 338     die $c->error if $c->error;
 339
 340 Or make sure to always return true values from your actions and write
 341 your code like this:
 342
 343     $c->forward('foo') || return;
 344
 345 =cut
 346
 347 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 348
 349 =head2 $c->detach( $action [, \@arguments ] )
 350
 351 =head2 $c->detach( $class, $method, [, \@arguments ] )
 352
 353 =head2 $c->detach()
 354
 355 The same as C<forward>, but doesn't return to the previous action when
 356 processing is finished.
 357
 358 When called with no arguments it escapes the processing chain entirely.
 359
 360 =cut
 361
 362 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 363
 364 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 365
 366 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 367
 368 Almost the same as C<forward>, but does a full dispatch, instead of just
 369 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 370 C<auto> and the method you go to are called, just like a new request.
 371
 372 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 373 This means, for example, that $c->action methods such as C<name>, C<class> and
 374 C<reverse> return information for the visited action when they are invoked
 375 within the visited action.  This is different from the behavior of C<forward>
 376 which continues to use the $c->action object from the caller action even when
 377 invoked from the callee.
 378
 379 C<$c-E<gt>stash> is kept unchanged.
 380
 381 In effect, C<visit> allows you to "wrap" another action, just as it
 382 would have been called by dispatching from a URL, while the analogous
 383 C<go> allows you to transfer control to another action as if it had
 384 been reached directly from a URL.
 385
 386 =cut
 387
 388 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 389
 390 =head2 $c->go( $action [, \@captures, \@arguments ] )
 391
 392 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 393
 394 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 395 instead of just calling the new C<$action> /
 396 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 397 method you visit are called, just like a new request.
 398
 399 C<$c-E<gt>stash> is kept unchanged.
 400
 401 =cut
 402
 403 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 404
 405 =head2 $c->response
 406
 407 =head2 $c->res
 408
 409 Returns the current L<Catalyst::Response> object, see there for details.
 410
 411 =head2 $c->stash
 412
 413 Returns a hashref to the stash, which may be used to store data and pass
 414 it between components during a request. You can also set hash keys by
 415 passing arguments. The stash is automatically sent to the view. The
 416 stash is cleared at the end of a request; it cannot be used for
 417 persistent storage (for this you must use a session; see
 418 L<Catalyst::Plugin::Session> for a complete system integrated with
 419 Catalyst).
 420
 421     $c->stash->{foo} = $bar;
 422     $c->stash( { moose => 'majestic', qux => 0 } );
 423     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 424
 425     # stash is automatically passed to the view for use in a template
 426     $c->forward( 'MyApp::View::TT' );
 427
 428 =cut
 429
 430 around stash => sub {
 431     my $orig = shift;
 432     my $c = shift;
 433     my $stash = $orig->($c);
 434     if (@_) {
 435         my $new_stash = @_ > 1 ? {@_} : $_[0];
 436         croak('stash takes a hash or hashref') unless ref $new_stash;
 437         foreach my $key ( keys %$new_stash ) {
 438           $stash->{$key} = $new_stash->{$key};
 439         }
 440     }
 441
 442     return $stash;
 443 };
 444
 445
 446 =head2 $c->error
 447
 448 =head2 $c->error($error, ...)
 449
 450 =head2 $c->error($arrayref)
 451
 452 Returns an arrayref containing error messages.  If Catalyst encounters an
 453 error while processing a request, it stores the error in $c->error.  This
 454 method should only be used to store fatal error messages.
 455
 456     my @error = @{ $c->error };
 457
 458 Add a new error.
 459
 460     $c->error('Something bad happened');
 461
 462 =cut
 463
 464 sub error {
 465     my $c = shift;
 466     if ( $_[0] ) {
 467         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 468         croak @$error unless ref $c;
 469         push @{ $c->{error} }, @$error;
 470     }
 471     elsif ( defined $_[0] ) { $c->{error} = undef }
 472     return $c->{error} || [];
 473 }
 474
 475
 476 =head2 $c->state
 477
 478 Contains the return value of the last executed action.
 479
 480 =head2 $c->clear_errors
 481
 482 Clear errors.  You probably don't want to clear the errors unless you are
 483 implementing a custom error screen.
 484
 485 This is equivalent to running
 486
 487     $c->error(0);
 488
 489 =cut
 490
 491 sub clear_errors {
 492     my $c = shift;
 493     $c->error(0);
 494 }
 495
 496 sub _comp_search_prefixes {
 497     my $c = shift;
 498     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 499 }
 500
 501 # search components given a name and some prefixes
 502 sub _comp_names_search_prefixes {
 503     my ( $c, $name, @prefixes ) = @_;
 504     my $appclass = ref $c || $c;
 505     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 506     $filter = qr/$filter/; # Compile regex now rather than once per loop
 507
 508     # map the original component name to the sub part that we will search against
 509     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 510         grep { /$filter/ } keys %{ $c->components };
 511
 512     # undef for a name will return all
 513     return keys %eligible if !defined $name;
 514
 515     my $query  = ref $name ? $name : qr/^$name$/i;
 516     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 517
 518     return @result if @result;
 519
 520     # if we were given a regexp to search against, we're done.
 521     return if ref $name;
 522
 523     # regexp fallback
 524     $query  = qr/$name/i;
 525     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 526
 527     # no results? try against full names
 528     if( !@result ) {
 529         @result = grep { m{$query} } keys %eligible;
 530     }
 531
 532     # don't warn if we didn't find any results, it just might not exist
 533     if( @result ) {
 534         # Disgusting hack to work out correct method name
 535         my $warn_for = lc $prefixes[0];
 536         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 537            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 538            "component resolution is unreliable and unsafe.";
 539         my $short = $result[0];
 540         $short =~ s/.*?Model:://;
 541         my $shortmess = Carp::shortmess('');
 542         if ($shortmess =~ m#Catalyst/Plugin#) {
 543            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 544               "plugin's config";
 545         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 546            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 547               "component's config";
 548         } else {
 549            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 550               "but if you really wanted to search, pass in a regexp as the argument " .
 551               "like so: \$c->${warn_for}(qr/${name}/)";
 552         }
 553         $c->log->warn( "${msg}$shortmess" );
 554     }
 555
 556     return @result;
 557 }
 558
 559 # Find possible names for a prefix
 560 sub _comp_names {
 561     my ( $c, @prefixes ) = @_;
 562     my $appclass = ref $c || $c;
 563
 564     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 565
 566     my @names = map { s{$filter}{}; $_; }
 567         $c->_comp_names_search_prefixes( undef, @prefixes );
 568
 569     return @names;
 570 }
 571
 572 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 573 sub _filter_component {
 574     my ( $c, $comp, @args ) = @_;
 575
 576     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 577         return $comp->ACCEPT_CONTEXT( $c, @args );
 578     }
 579
 580     return $comp;
 581 }
 582
 583 =head2 COMPONENT ACCESSORS
 584
 585 =head2 $c->controller($name)
 586
 587 Gets a L<Catalyst::Controller> instance by name.
 588
 589     $c->controller('Foo')->do_stuff;
 590
 591 If the name is omitted, will return the controller for the dispatched
 592 action.
 593
 594 If you want to search for controllers, pass in a regexp as the argument.
 595
 596     # find all controllers that start with Foo
 597     my @foo_controllers = $c->controller(qr{^Foo});
 598
 599
 600 =cut
 601
 602 sub controller {
 603     my ( $c, $name, @args ) = @_;
 604
 605     if( $name ) {
 606         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 607         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 608         return $c->_filter_component( $result[ 0 ], @args );
 609     }
 610
 611     return $c->component( $c->action->class );
 612 }
 613
 614 =head2 $c->model($name)
 615
 616 Gets a L<Catalyst::Model> instance by name.
 617
 618     $c->model('Foo')->do_stuff;
 619
 620 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 621
 622 If the name is omitted, it will look for
 623  - a model object in $c->stash->{current_model_instance}, then
 624  - a model name in $c->stash->{current_model}, then
 625  - a config setting 'default_model', or
 626  - check if there is only one model, and return it if that's the case.
 627
 628 If you want to search for models, pass in a regexp as the argument.
 629
 630     # find all models that start with Foo
 631     my @foo_models = $c->model(qr{^Foo});
 632
 633 =cut
 634
 635 sub model {
 636     my ( $c, $name, @args ) = @_;
 637
 638     if( $name ) {
 639         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 640         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 641         return $c->_filter_component( $result[ 0 ], @args );
 642     }
 643
 644     if (ref $c) {
 645         return $c->stash->{current_model_instance}
 646           if $c->stash->{current_model_instance};
 647         return $c->model( $c->stash->{current_model} )
 648           if $c->stash->{current_model};
 649     }
 650     return $c->model( $c->config->{default_model} )
 651       if $c->config->{default_model};
 652
 653     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 654
 655     if( $rest ) {
 656         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 657         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 658         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 659         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 660         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 661     }
 662
 663     return $c->_filter_component( $comp );
 664 }
 665
 666
 667 =head2 $c->view($name)
 668
 669 Gets a L<Catalyst::View> instance by name.
 670
 671     $c->view('Foo')->do_stuff;
 672
 673 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 674
 675 If the name is omitted, it will look for
 676  - a view object in $c->stash->{current_view_instance}, then
 677  - a view name in $c->stash->{current_view}, then
 678  - a config setting 'default_view', or
 679  - check if there is only one view, and return it if that's the case.
 680
 681 If you want to search for views, pass in a regexp as the argument.
 682
 683     # find all views that start with Foo
 684     my @foo_views = $c->view(qr{^Foo});
 685
 686 =cut
 687
 688 sub view {
 689     my ( $c, $name, @args ) = @_;
 690
 691     if( $name ) {
 692         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 693         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 694         return $c->_filter_component( $result[ 0 ], @args );
 695     }
 696
 697     if (ref $c) {
 698         return $c->stash->{current_view_instance}
 699           if $c->stash->{current_view_instance};
 700         return $c->view( $c->stash->{current_view} )
 701           if $c->stash->{current_view};
 702     }
 703     return $c->view( $c->config->{default_view} )
 704       if $c->config->{default_view};
 705
 706     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 707
 708     if( $rest ) {
 709         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 710         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 711         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 712         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 713         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 714     }
 715
 716     return $c->_filter_component( $comp );
 717 }
 718
 719 =head2 $c->controllers
 720
 721 Returns the available names which can be passed to $c->controller
 722
 723 =cut
 724
 725 sub controllers {
 726     my ( $c ) = @_;
 727     return $c->_comp_names(qw/Controller C/);
 728 }
 729
 730 =head2 $c->models
 731
 732 Returns the available names which can be passed to $c->model
 733
 734 =cut
 735
 736 sub models {
 737     my ( $c ) = @_;
 738     return $c->_comp_names(qw/Model M/);
 739 }
 740
 741
 742 =head2 $c->views
 743
 744 Returns the available names which can be passed to $c->view
 745
 746 =cut
 747
 748 sub views {
 749     my ( $c ) = @_;
 750     return $c->_comp_names(qw/View V/);
 751 }
 752
 753 =head2 $c->comp($name)
 754
 755 =head2 $c->component($name)
 756
 757 Gets a component object by name. This method is not recommended,
 758 unless you want to get a specific component by full
 759 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 760 should be used instead.
 761
 762 If C<$name> is a regexp, a list of components matched against the full
 763 component name will be returned.
 764
 765 =cut
 766
 767 sub component {
 768     my ( $c, $name, @args ) = @_;
 769
 770     if( $name ) {
 771         my $comps = $c->components;
 772
 773         if( !ref $name ) {
 774             # is it the exact name?
 775             return $c->_filter_component( $comps->{ $name }, @args )
 776                        if exists $comps->{ $name };
 777
 778             # perhaps we just omitted "MyApp"?
 779             my $composed = ( ref $c || $c ) . "::${name}";
 780             return $c->_filter_component( $comps->{ $composed }, @args )
 781                        if exists $comps->{ $composed };
 782
 783             # search all of the models, views and controllers
 784             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 785             return $c->_filter_component( $comp, @args ) if $comp;
 786         }
 787
 788         # This is here so $c->comp( '::M::' ) works
 789         my $query = ref $name ? $name : qr{$name}i;
 790
 791         my @result = grep { m{$query} } keys %{ $c->components };
 792         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 793
 794         if( $result[ 0 ] ) {
 795             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 796             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 797             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 798             return $c->_filter_component( $result[ 0 ], @args );
 799         }
 800
 801         # I would expect to return an empty list here, but that breaks back-compat
 802     }
 803
 804     # fallback
 805     return sort keys %{ $c->components };
 806 }
 807
 808 =head2 CLASS DATA AND HELPER CLASSES
 809
 810 =head2 $c->config
 811
 812 Returns or takes a hashref containing the application's configuration.
 813
 814     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 815
 816 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 817 like myapp.conf in your applications home directory. See
 818 L<Catalyst::Plugin::ConfigLoader>.
 819
 820 =head3 Cascading configuration.
 821
 822 The config method is present on all Catalyst components, and configuration
 823 will be merged when an application is started. Configuration loaded with
 824 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 825 followed by configuration in your top level C<MyApp> class. These two
 826 configurations are merged, and then configuration data whose hash key matches a
 827 component name is merged with configuration for that component.
 828
 829 The configuration for a component is then passed to the C<new> method when a
 830 component is constructed.
 831
 832 For example:
 833
 834     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 835     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 836
 837 will mean that C<MyApp::Model::Foo> receives the following data when
 838 constructed:
 839
 840     MyApp::Model::Foo->new({
 841         bar => 'baz',
 842         quux => 'frob',
 843         overrides => 'me',
 844     });
 845
 846 =cut
 847
 848 around config => sub {
 849     my $orig = shift;
 850     my $c = shift;
 851
 852     croak('Setting config after setup has been run is not allowed.')
 853         if ( @_ and $c->setup_finished );
 854
 855     $c->$orig(@_);
 856 };
 857
 858 =head2 $c->log
 859
 860 Returns the logging object instance. Unless it is already set, Catalyst
 861 sets this up with a L<Catalyst::Log> object. To use your own log class,
 862 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 863 C<< __PACKAGE__->setup >>.
 864
 865  __PACKAGE__->log( MyLogger->new );
 866  __PACKAGE__->setup;
 867
 868 And later:
 869
 870     $c->log->info( 'Now logging with my own logger!' );
 871
 872 Your log class should implement the methods described in
 873 L<Catalyst::Log>.
 874
 875
 876 =head2 $c->debug
 877
 878 Returns 1 if debug mode is enabled, 0 otherwise.
 879
 880 You can enable debug mode in several ways:
 881
 882 =over
 883
 884 =item By calling myapp_server.pl with the -d flag
 885
 886 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 887
 888 =item The -Debug option in your MyApp.pm
 889
 890 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 891
 892 =back
 893
 894 Calling C<< $c->debug(1) >> has no effect.
 895
 896 =cut
 897
 898 sub debug { 0 }
 899
 900 =head2 $c->dispatcher
 901
 902 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 903
 904 =head2 $c->engine
 905
 906 Returns the engine instance. See L<Catalyst::Engine>.
 907
 908
 909 =head2 UTILITY METHODS
 910
 911 =head2 $c->path_to(@path)
 912
 913 Merges C<@path> with C<< $c->config->{home} >> and returns a
 914 L<Path::Class::Dir> object. Note you can usually use this object as
 915 a filename, but sometimes you will have to explicitly stringify it
 916 yourself by calling the C<<->stringify>> method.
 917
 918 For example:
 919
 920     $c->path_to( 'db', 'sqlite.db' );
 921
 922 =cut
 923
 924 sub path_to {
 925     my ( $c, @path ) = @_;
 926     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 927     if ( -d $path ) { return $path }
 928     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 929 }
 930
 931 =head2 $c->plugin( $name, $class, @args )
 932
 933 Helper method for plugins. It creates a class data accessor/mutator and
 934 loads and instantiates the given class.
 935
 936     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 937
 938     $c->prototype->define_javascript_functions;
 939
 940 B<Note:> This method of adding plugins is deprecated. The ability
 941 to add plugins like this B<will be removed> in a Catalyst 5.81.
 942 Please do not use this functionality in new code.
 943
 944 =cut
 945
 946 sub plugin {
 947     my ( $class, $name, $plugin, @args ) = @_;
 948
 949     # See block comment in t/unit_core_plugin.t
 950     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 951
 952     $class->_register_plugin( $plugin, 1 );
 953
 954     eval { $plugin->import };
 955     $class->mk_classdata($name);
 956     my $obj;
 957     eval { $obj = $plugin->new(@args) };
 958
 959     if ($@) {
 960         Catalyst::Exception->throw( message =>
 961               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 962     }
 963
 964     $class->$name($obj);
 965     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 966       if $class->debug;
 967 }
 968
 969 =head2 MyApp->setup
 970
 971 Initializes the dispatcher and engine, loads any plugins, and loads the
 972 model, view, and controller components. You may also specify an array
 973 of plugins to load here, if you choose to not load them in the C<use
 974 Catalyst> line.
 975
 976     MyApp->setup;
 977     MyApp->setup( qw/-Debug/ );
 978
 979 =cut
 980
 981 sub setup {
 982     my ( $class, @arguments ) = @_;
 983     croak('Running setup more than once')
 984         if ( $class->setup_finished );
 985
 986     unless ( $class->isa('Catalyst') ) {
 987
 988         Catalyst::Exception->throw(
 989             message => qq/'$class' does not inherit from Catalyst/ );
 990     }
 991
 992     if ( $class->arguments ) {
 993         @arguments = ( @arguments, @{ $class->arguments } );
 994     }
 995
 996     # Process options
 997     my $flags = {};
 998
 999     foreach (@arguments) {
1000
1001         if (/^-Debug$/) {
1002             $flags->{log} =
1003               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1004         }
1005         elsif (/^-(\w+)=?(.*)$/) {
1006             $flags->{ lc $1 } = $2;
1007         }
1008         else {
1009             push @{ $flags->{plugins} }, $_;
1010         }
1011     }
1012
1013     $class->setup_home( delete $flags->{home} );
1014
1015     $class->setup_log( delete $flags->{log} );
1016     $class->setup_plugins( delete $flags->{plugins} );
1017     $class->setup_dispatcher( delete $flags->{dispatcher} );
1018     $class->setup_engine( delete $flags->{engine} );
1019     $class->setup_stats( delete $flags->{stats} );
1020
1021     for my $flag ( sort keys %{$flags} ) {
1022
1023         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1024             &$code( $class, delete $flags->{$flag} );
1025         }
1026         else {
1027             $class->log->warn(qq/Unknown flag "$flag"/);
1028         }
1029     }
1030
1031     eval { require Catalyst::Devel; };
1032     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1033         $class->log->warn(<<"EOF");
1034 You are running an old script!
1035
1036   Please update by running (this will overwrite existing files):
1037     catalyst.pl -force -scripts $class
1038
1039   or (this will not overwrite existing files):
1040     catalyst.pl -scripts $class
1041
1042 EOF
1043     }
1044
1045     if ( $class->debug ) {
1046         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1047
1048         if (@plugins) {
1049             my $column_width = Catalyst::Utils::term_width() - 6;
1050             my $t = Text::SimpleTable->new($column_width);
1051             $t->row($_) for @plugins;
1052             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1053         }
1054
1055         my $dispatcher = $class->dispatcher;
1056         my $engine     = $class->engine;
1057         my $home       = $class->config->{home};
1058
1059         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1060         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1061
1062         $home
1063           ? ( -d $home )
1064           ? $class->log->debug(qq/Found home "$home"/)
1065           : $class->log->debug(qq/Home "$home" doesn't exist/)
1066           : $class->log->debug(q/Couldn't find home/);
1067     }
1068
1069     # Call plugins setup, this is stupid and evil.
1070     # Also screws C3 badly on 5.10, hack to avoid.
1071     {
1072         no warnings qw/redefine/;
1073         local *setup = sub { };
1074         $class->setup unless $Catalyst::__AM_RESTARTING;
1075     }
1076
1077     # Initialize our data structure
1078     $class->components( {} );
1079
1080     $class->setup_components;
1081
1082     if ( $class->debug ) {
1083         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1084         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1085         for my $comp ( sort keys %{ $class->components } ) {
1086             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1087             $t->row( $comp, $type );
1088         }
1089         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1090           if ( keys %{ $class->components } );
1091     }
1092
1093     # Add our self to components, since we are also a component
1094     if( $class->isa('Catalyst::Controller') ){
1095       $class->components->{$class} = $class;
1096     }
1097
1098     $class->setup_actions;
1099
1100     if ( $class->debug ) {
1101         my $name = $class->config->{name} || 'Application';
1102         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1103     }
1104     $class->log->_flush() if $class->log->can('_flush');
1105
1106     # Make sure that the application class becomes immutable at this point,
1107     # which ensures that it gets an inlined constructor. This means that it
1108     # works even if the user has added a plugin which contains a new method.
1109     # Note however that we have to do the work on scope end, so that method
1110     # modifiers work correctly in MyApp (as you have to call setup _before_
1111     # applying modifiers).
1112     B::Hooks::EndOfScope::on_scope_end {
1113         return if $@;
1114         my $meta = Class::MOP::get_metaclass_by_name($class);
1115         if ( $meta->is_immutable && ! { $meta->immutable_options }->{inline_constructor} ) {
1116             warn "You made your application class ($class) immutable, "
1117                 . "but did not inline the constructor.\n"
1118                 . "This will break catalyst, please pass "
1119                 . "(replace_constructor => 1) when making your class immutable.\n";
1120         }
1121         $meta->make_immutable(replace_constructor => 1) unless $meta->is_immutable;
1122     };
1123
1124     $class->setup_finalize;
1125     warn "Setup called";
1126 }
1127
1128
1129 =head2 $app->setup_finalize
1130
1131 A hook to attach modifiers to.
1132 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1133 Also better than C< setup_finished(); >, as that is a getter method.
1134
1135     sub setup_finalize {
1136
1137         my $app = shift;
1138
1139         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1140
1141         $app->next::method(@_);
1142
1143
1144     }
1145
1146 =cut
1147
1148 sub setup_finalize {
1149     my ($class) = @_;
1150     $class->setup_finished(1);
1151 }
1152
1153 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1154
1155 =head2 $c->uri_for( $path, @args?, \%query_values? )
1156
1157 =over
1158
1159 =item $action
1160
1161 A Catalyst::Action object representing the Catalyst action you want to
1162 create a URI for. To get one for an action in the current controller,
1163 use C<< $c->action('someactionname') >>. To get one from different
1164 controller, fetch the controller using C<< $c->controller() >>, then
1165 call C<action_for> on it.
1166
1167 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1168 using C<< $c->req->captures >>.
1169
1170   # For the current action
1171   $c->uri_for($c->action, $c->req->captures);
1172
1173   # For the Foo action in the Bar controller
1174   $c->uri_for($c->controller('Bar')->action_for('Foo'), $c->req->captures);
1175
1176 =back
1177
1178 =cut
1179
1180 sub uri_for {
1181     my ( $c, $path, @args ) = @_;
1182
1183     if ( blessed($path) ) { # action object
1184         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1185                          ? shift(@args)
1186                          : [] );
1187         my $action = $path;
1188         $path = $c->dispatcher->uri_for_action($action, $captures);
1189         if (not defined $path) {
1190             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1191                 if $c->debug;
1192             return undef;
1193         }
1194         $path = '/' if $path eq '';
1195     }
1196
1197     undef($path) if (defined $path && $path eq '');
1198
1199     my $params =
1200       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1201
1202     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1203     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1204
1205     unshift(@args, $path);
1206
1207     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1208         my $namespace = $c->namespace;
1209         if (defined $path) { # cheesy hack to handle path '../foo'
1210            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1211         }
1212         unshift(@args, $namespace || '');
1213     }
1214
1215     # join args with '/', or a blank string
1216     my $args = join('/', grep { defined($_) } @args);
1217     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1218     $args =~ s!^/+!!;
1219     my $base = $c->req->base;
1220     my $class = ref($base);
1221     $base =~ s{(?<!/)$}{/};
1222
1223     my $query = '';
1224
1225     if (my @keys = keys %$params) {
1226       # somewhat lifted from URI::_query's query_form
1227       $query = '?'.join('&', map {
1228           my $val = $params->{$_};
1229           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1230           s/ /+/g;
1231           my $key = $_;
1232           $val = '' unless defined $val;
1233           (map {
1234               $_ = "$_";
1235               utf8::encode( $_ ) if utf8::is_utf8($_);
1236               # using the URI::Escape pattern here so utf8 chars survive
1237               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1238               s/ /+/g;
1239               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1240       } @keys);
1241     }
1242
1243     my $res = bless(\"${base}${args}${query}", $class);
1244     $res;
1245 }
1246
1247 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1248
1249 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1250
1251 =over
1252
1253 =item $path
1254
1255 A private path to the Catalyst action you want to create a URI for.
1256
1257 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1258 >> and passing the resulting C<$action> and the remaining arguments to C<<
1259 $c->uri_for >>.
1260
1261 You can also pass in a Catalyst::Action object, in which case it is passed to
1262 C<< $c->uri_for >>.
1263
1264 =back
1265
1266 =cut
1267
1268 sub uri_for_action {
1269     my ( $c, $path, @args ) = @_;
1270     my $action = blessed($path)
1271       ? $path
1272       : $c->dispatcher->get_action_by_path($path);
1273     unless (defined $action) {
1274       croak "Can't find action for path '$path'";
1275     }
1276     return $c->uri_for( $action, @args );
1277 }
1278
1279 =head2 $c->welcome_message
1280
1281 Returns the Catalyst welcome HTML page.
1282
1283 =cut
1284
1285 sub welcome_message {
1286     my $c      = shift;
1287     my $name   = $c->config->{name};
1288     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1289     my $prefix = Catalyst::Utils::appprefix( ref $c );
1290     $c->response->content_type('text/html; charset=utf-8');
1291     return <<"EOF";
1292 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1293     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1294 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1295     <head>
1296     <meta http-equiv="Content-Language" content="en" />
1297     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1298         <title>$name on Catalyst $VERSION</title>
1299         <style type="text/css">
1300             body {
1301                 color: #000;
1302                 background-color: #eee;
1303             }
1304             div#content {
1305                 width: 640px;
1306                 margin-left: auto;
1307                 margin-right: auto;
1308                 margin-top: 10px;
1309                 margin-bottom: 10px;
1310                 text-align: left;
1311                 background-color: #ccc;
1312                 border: 1px solid #aaa;
1313             }
1314             p, h1, h2 {
1315                 margin-left: 20px;
1316                 margin-right: 20px;
1317                 font-family: verdana, tahoma, sans-serif;
1318             }
1319             a {
1320                 font-family: verdana, tahoma, sans-serif;
1321             }
1322             :link, :visited {
1323                     text-decoration: none;
1324                     color: #b00;
1325                     border-bottom: 1px dotted #bbb;
1326             }
1327             :link:hover, :visited:hover {
1328                     color: #555;
1329             }
1330             div#topbar {
1331                 margin: 0px;
1332             }
1333             pre {
1334                 margin: 10px;
1335                 padding: 8px;
1336             }
1337             div#answers {
1338                 padding: 8px;
1339                 margin: 10px;
1340                 background-color: #fff;
1341                 border: 1px solid #aaa;
1342             }
1343             h1 {
1344                 font-size: 0.9em;
1345                 font-weight: normal;
1346                 text-align: center;
1347             }
1348             h2 {
1349                 font-size: 1.0em;
1350             }
1351             p {
1352                 font-size: 0.9em;
1353             }
1354             p img {
1355                 float: right;
1356                 margin-left: 10px;
1357             }
1358             span#appname {
1359                 font-weight: bold;
1360                 font-size: 1.6em;
1361             }
1362         </style>
1363     </head>
1364     <body>
1365         <div id="content">
1366             <div id="topbar">
1367                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1368                     $VERSION</h1>
1369              </div>
1370              <div id="answers">
1371                  <p>
1372                  <img src="$logo" alt="Catalyst Logo" />
1373                  </p>
1374                  <p>Welcome to the  world of Catalyst.
1375                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1376                     framework will make web development something you had
1377                     never expected it to be: Fun, rewarding, and quick.</p>
1378                  <h2>What to do now?</h2>
1379                  <p>That really depends  on what <b>you</b> want to do.
1380                     We do, however, provide you with a few starting points.</p>
1381                  <p>If you want to jump right into web development with Catalyst
1382                     you might want to start with a tutorial.</p>
1383 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1384 </pre>
1385 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1386 <pre>
1387 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1388 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1389 </code></pre>
1390                  <h2>What to do next?</h2>
1391                  <p>Next it's time to write an actual application. Use the
1392                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1393                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1394                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1395                     they can save you a lot of work.</p>
1396                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1397                     <p>Also, be sure to check out the vast and growing
1398                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1399                     you are likely to find what you need there.
1400                     </p>
1401
1402                  <h2>Need help?</h2>
1403                  <p>Catalyst has a very active community. Here are the main places to
1404                     get in touch with us.</p>
1405                  <ul>
1406                      <li>
1407                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1408                      </li>
1409                      <li>
1410                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1411                      </li>
1412                      <li>
1413                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1414                      </li>
1415                  </ul>
1416                  <h2>In conclusion</h2>
1417                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1418                     as we enjoyed making it. Please contact us if you have ideas
1419                     for improvement or other feedback.</p>
1420              </div>
1421          </div>
1422     </body>
1423 </html>
1424 EOF
1425 }
1426
1427 =head1 INTERNAL METHODS
1428
1429 These methods are not meant to be used by end users.
1430
1431 =head2 $c->components
1432
1433 Returns a hash of components.
1434
1435 =head2 $c->context_class
1436
1437 Returns or sets the context class.
1438
1439 =head2 $c->counter
1440
1441 Returns a hashref containing coderefs and execution counts (needed for
1442 deep recursion detection).
1443
1444 =head2 $c->depth
1445
1446 Returns the number of actions on the current internal execution stack.
1447
1448 =head2 $c->dispatch
1449
1450 Dispatches a request to actions.
1451
1452 =cut
1453
1454 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1455
1456 =head2 $c->dispatcher_class
1457
1458 Returns or sets the dispatcher class.
1459
1460 =head2 $c->dump_these
1461
1462 Returns a list of 2-element array references (name, structure) pairs
1463 that will be dumped on the error page in debug mode.
1464
1465 =cut
1466
1467 sub dump_these {
1468     my $c = shift;
1469     [ Request => $c->req ],
1470     [ Response => $c->res ],
1471     [ Stash => $c->stash ],
1472     [ Config => $c->config ];
1473 }
1474
1475 =head2 $c->engine_class
1476
1477 Returns or sets the engine class.
1478
1479 =head2 $c->execute( $class, $coderef )
1480
1481 Execute a coderef in given class and catch exceptions. Errors are available
1482 via $c->error.
1483
1484 =cut
1485
1486 sub execute {
1487     my ( $c, $class, $code ) = @_;
1488     $class = $c->component($class) || $class;
1489     $c->state(0);
1490
1491     if ( $c->depth >= $RECURSION ) {
1492         my $action = $code->reverse();
1493         $action = "/$action" unless $action =~ /->/;
1494         my $error = qq/Deep recursion detected calling "${action}"/;
1495         $c->log->error($error);
1496         $c->error($error);
1497         $c->state(0);
1498         return $c->state;
1499     }
1500
1501     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1502
1503     push( @{ $c->stack }, $code );
1504
1505     no warnings 'recursion';
1506     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1507
1508     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1509
1510     my $last = pop( @{ $c->stack } );
1511
1512     if ( my $error = $@ ) {
1513         if ( !ref($error) and $error eq $DETACH ) {
1514             die $DETACH if($c->depth > 1);
1515         }
1516         elsif ( !ref($error) and $error eq $GO ) {
1517             die $GO if($c->depth > 0);
1518         }
1519         else {
1520             unless ( ref $error ) {
1521                 no warnings 'uninitialized';
1522                 chomp $error;
1523                 my $class = $last->class;
1524                 my $name  = $last->name;
1525                 $error = qq/Caught exception in $class->$name "$error"/;
1526             }
1527             $c->error($error);
1528             $c->state(0);
1529         }
1530     }
1531     return $c->state;
1532 }
1533
1534 sub _stats_start_execute {
1535     my ( $c, $code ) = @_;
1536
1537     return if ( ( $code->name =~ /^_.*/ )
1538         && ( !$c->config->{show_internal_actions} ) );
1539
1540     my $action_name = $code->reverse();
1541     $c->counter->{$action_name}++;
1542
1543     my $action = $action_name;
1544     $action = "/$action" unless $action =~ /->/;
1545
1546     # determine if the call was the result of a forward
1547     # this is done by walking up the call stack and looking for a calling
1548     # sub of Catalyst::forward before the eval
1549     my $callsub = q{};
1550     for my $index ( 2 .. 11 ) {
1551         last
1552         if ( ( caller($index) )[0] eq 'Catalyst'
1553             && ( caller($index) )[3] eq '(eval)' );
1554
1555         if ( ( caller($index) )[3] =~ /forward$/ ) {
1556             $callsub = ( caller($index) )[3];
1557             $action  = "-> $action";
1558             last;
1559         }
1560     }
1561
1562     my $uid = $action_name . $c->counter->{$action_name};
1563
1564     # is this a root-level call or a forwarded call?
1565     if ( $callsub =~ /forward$/ ) {
1566
1567         # forward, locate the caller
1568         if ( my $parent = $c->stack->[-1] ) {
1569             $c->stats->profile(
1570                 begin  => $action,
1571                 parent => "$parent" . $c->counter->{"$parent"},
1572                 uid    => $uid,
1573             );
1574         }
1575         else {
1576
1577             # forward with no caller may come from a plugin
1578             $c->stats->profile(
1579                 begin => $action,
1580                 uid   => $uid,
1581             );
1582         }
1583     }
1584     else {
1585
1586         # root-level call
1587         $c->stats->profile(
1588             begin => $action,
1589             uid   => $uid,
1590         );
1591     }
1592     return $action;
1593
1594 }
1595
1596 sub _stats_finish_execute {
1597     my ( $c, $info ) = @_;
1598     $c->stats->profile( end => $info );
1599 }
1600
1601 =head2 $c->_localize_fields( sub { }, \%keys );
1602
1603 =cut
1604
1605 #Why does this exist? This is no longer safe and WILL NOT WORK.
1606 # it doesnt seem to be used anywhere. can we remove it?
1607 sub _localize_fields {
1608     my ( $c, $localized, $code ) = ( @_ );
1609
1610     my $request = delete $localized->{request} || {};
1611     my $response = delete $localized->{response} || {};
1612
1613     local @{ $c }{ keys %$localized } = values %$localized;
1614     local @{ $c->request }{ keys %$request } = values %$request;
1615     local @{ $c->response }{ keys %$response } = values %$response;
1616
1617     $code->();
1618 }
1619
1620 =head2 $c->finalize
1621
1622 Finalizes the request.
1623
1624 =cut
1625
1626 sub finalize {
1627     my $c = shift;
1628
1629     for my $error ( @{ $c->error } ) {
1630         $c->log->error($error);
1631     }
1632
1633     # Allow engine to handle finalize flow (for POE)
1634     my $engine = $c->engine;
1635     if ( my $code = $engine->can('finalize') ) {
1636         $engine->$code($c);
1637     }
1638     else {
1639
1640         $c->finalize_uploads;
1641
1642         # Error
1643         if ( $#{ $c->error } >= 0 ) {
1644             $c->finalize_error;
1645         }
1646
1647         $c->finalize_headers;
1648
1649         # HEAD request
1650         if ( $c->request->method eq 'HEAD' ) {
1651             $c->response->body('');
1652         }
1653
1654         $c->finalize_body;
1655     }
1656
1657     if ($c->use_stats) {
1658         my $elapsed = sprintf '%f', $c->stats->elapsed;
1659         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1660         $c->log->info(
1661             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1662     }
1663
1664     return $c->response->status;
1665 }
1666
1667 =head2 $c->finalize_body
1668
1669 Finalizes body.
1670
1671 =cut
1672
1673 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1674
1675 =head2 $c->finalize_cookies
1676
1677 Finalizes cookies.
1678
1679 =cut
1680
1681 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1682
1683 =head2 $c->finalize_error
1684
1685 Finalizes error.
1686
1687 =cut
1688
1689 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1690
1691 =head2 $c->finalize_headers
1692
1693 Finalizes headers.
1694
1695 =cut
1696
1697 sub finalize_headers {
1698     my $c = shift;
1699
1700     my $response = $c->response; #accessor calls can add up?
1701
1702     # Check if we already finalized headers
1703     return if $response->finalized_headers;
1704
1705     # Handle redirects
1706     if ( my $location = $response->redirect ) {
1707         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1708         $response->header( Location => $location );
1709
1710         if ( !$response->has_body ) {
1711             # Add a default body if none is already present
1712             $response->body(
1713                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1714             );
1715         }
1716     }
1717
1718     # Content-Length
1719     if ( $response->body && !$response->content_length ) {
1720
1721         # get the length from a filehandle
1722         if ( blessed( $response->body ) && $response->body->can('read') )
1723         {
1724             my $stat = stat $response->body;
1725             if ( $stat && $stat->size > 0 ) {
1726                 $response->content_length( $stat->size );
1727             }
1728             else {
1729                 $c->log->warn('Serving filehandle without a content-length');
1730             }
1731         }
1732         else {
1733             # everything should be bytes at this point, but just in case
1734             $response->content_length( bytes::length( $response->body ) );
1735         }
1736     }
1737
1738     # Errors
1739     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1740         $response->headers->remove_header("Content-Length");
1741         $response->body('');
1742     }
1743
1744     $c->finalize_cookies;
1745
1746     $c->engine->finalize_headers( $c, @_ );
1747
1748     # Done
1749     $response->finalized_headers(1);
1750 }
1751
1752 =head2 $c->finalize_output
1753
1754 An alias for finalize_body.
1755
1756 =head2 $c->finalize_read
1757
1758 Finalizes the input after reading is complete.
1759
1760 =cut
1761
1762 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1763
1764 =head2 $c->finalize_uploads
1765
1766 Finalizes uploads. Cleans up any temporary files.
1767
1768 =cut
1769
1770 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1771
1772 =head2 $c->get_action( $action, $namespace )
1773
1774 Gets an action in a given namespace.
1775
1776 =cut
1777
1778 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1779
1780 =head2 $c->get_actions( $action, $namespace )
1781
1782 Gets all actions of a given name in a namespace and all parent
1783 namespaces.
1784
1785 =cut
1786
1787 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1788
1789 =head2 $c->handle_request( $class, @arguments )
1790
1791 Called to handle each HTTP request.
1792
1793 =cut
1794
1795 sub handle_request {
1796     my ( $class, @arguments ) = @_;
1797
1798     # Always expect worst case!
1799     my $status = -1;
1800     eval {
1801         if ($class->debug) {
1802             my $secs = time - $START || 1;
1803             my $av = sprintf '%.3f', $COUNT / $secs;
1804             my $time = localtime time;
1805             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1806         }
1807
1808         my $c = $class->prepare(@arguments);
1809         $c->dispatch;
1810         $status = $c->finalize;
1811     };
1812
1813     if ( my $error = $@ ) {
1814         chomp $error;
1815         $class->log->error(qq/Caught exception in engine "$error"/);
1816     }
1817
1818     $COUNT++;
1819
1820     if(my $coderef = $class->log->can('_flush')){
1821         $class->log->$coderef();
1822     }
1823     return $status;
1824 }
1825
1826 =head2 $c->prepare( @arguments )
1827
1828 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1829 etc.).
1830
1831 =cut
1832
1833 sub prepare {
1834     my ( $class, @arguments ) = @_;
1835
1836     # XXX
1837     # After the app/ctxt split, this should become an attribute based on something passed
1838     # into the application.
1839     $class->context_class( ref $class || $class ) unless $class->context_class;
1840
1841     my $c = $class->context_class->new({});
1842
1843     # For on-demand data
1844     $c->request->_context($c);
1845     $c->response->_context($c);
1846
1847     #surely this is not the most efficient way to do things...
1848     $c->stats($class->stats_class->new)->enable($c->use_stats);
1849     if ( $c->debug ) {
1850         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1851     }
1852
1853     #XXX reuse coderef from can
1854     # Allow engine to direct the prepare flow (for POE)
1855     if ( $c->engine->can('prepare') ) {
1856         $c->engine->prepare( $c, @arguments );
1857     }
1858     else {
1859         $c->prepare_request(@arguments);
1860         $c->prepare_connection;
1861         $c->prepare_query_parameters;
1862         $c->prepare_headers;
1863         $c->prepare_cookies;
1864         $c->prepare_path;
1865
1866         # Prepare the body for reading, either by prepare_body
1867         # or the user, if they are using $c->read
1868         $c->prepare_read;
1869
1870         # Parse the body unless the user wants it on-demand
1871         unless ( $c->config->{parse_on_demand} ) {
1872             $c->prepare_body;
1873         }
1874     }
1875
1876     my $method  = $c->req->method  || '';
1877     my $path    = $c->req->path;
1878     $path       = '/' unless length $path;
1879     my $address = $c->req->address || '';
1880
1881     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1882       if $c->debug;
1883
1884     $c->prepare_action;
1885
1886     return $c;
1887 }
1888
1889 =head2 $c->prepare_action
1890
1891 Prepares action. See L<Catalyst::Dispatcher>.
1892
1893 =cut
1894
1895 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1896
1897 =head2 $c->prepare_body
1898
1899 Prepares message body.
1900
1901 =cut
1902
1903 sub prepare_body {
1904     my $c = shift;
1905
1906     return if $c->request->_has_body;
1907
1908     # Initialize on-demand data
1909     $c->engine->prepare_body( $c, @_ );
1910     $c->prepare_parameters;
1911     $c->prepare_uploads;
1912
1913     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1914         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1915         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1916             my $param = $c->req->body_parameters->{$key};
1917             my $value = defined($param) ? $param : '';
1918             $t->row( $key,
1919                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1920         }
1921         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1922     }
1923 }
1924
1925 =head2 $c->prepare_body_chunk( $chunk )
1926
1927 Prepares a chunk of data before sending it to L<HTTP::Body>.
1928
1929 See L<Catalyst::Engine>.
1930
1931 =cut
1932
1933 sub prepare_body_chunk {
1934     my $c = shift;
1935     $c->engine->prepare_body_chunk( $c, @_ );
1936 }
1937
1938 =head2 $c->prepare_body_parameters
1939
1940 Prepares body parameters.
1941
1942 =cut
1943
1944 sub prepare_body_parameters {
1945     my $c = shift;
1946     $c->engine->prepare_body_parameters( $c, @_ );
1947 }
1948
1949 =head2 $c->prepare_connection
1950
1951 Prepares connection.
1952
1953 =cut
1954
1955 sub prepare_connection {
1956     my $c = shift;
1957     $c->engine->prepare_connection( $c, @_ );
1958 }
1959
1960 =head2 $c->prepare_cookies
1961
1962 Prepares cookies.
1963
1964 =cut
1965
1966 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1967
1968 =head2 $c->prepare_headers
1969
1970 Prepares headers.
1971
1972 =cut
1973
1974 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1975
1976 =head2 $c->prepare_parameters
1977
1978 Prepares parameters.
1979
1980 =cut
1981
1982 sub prepare_parameters {
1983     my $c = shift;
1984     $c->prepare_body_parameters;
1985     $c->engine->prepare_parameters( $c, @_ );
1986 }
1987
1988 =head2 $c->prepare_path
1989
1990 Prepares path and base.
1991
1992 =cut
1993
1994 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1995
1996 =head2 $c->prepare_query_parameters
1997
1998 Prepares query parameters.
1999
2000 =cut
2001
2002 sub prepare_query_parameters {
2003     my $c = shift;
2004
2005     $c->engine->prepare_query_parameters( $c, @_ );
2006
2007     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
2008         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
2009         for my $key ( sort keys %{ $c->req->query_parameters } ) {
2010             my $param = $c->req->query_parameters->{$key};
2011             my $value = defined($param) ? $param : '';
2012             $t->row( $key,
2013                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2014         }
2015         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2016     }
2017 }
2018
2019 =head2 $c->prepare_read
2020
2021 Prepares the input for reading.
2022
2023 =cut
2024
2025 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2026
2027 =head2 $c->prepare_request
2028
2029 Prepares the engine request.
2030
2031 =cut
2032
2033 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2034
2035 =head2 $c->prepare_uploads
2036
2037 Prepares uploads.
2038
2039 =cut
2040
2041 sub prepare_uploads {
2042     my $c = shift;
2043
2044     $c->engine->prepare_uploads( $c, @_ );
2045
2046     if ( $c->debug && keys %{ $c->request->uploads } ) {
2047         my $t = Text::SimpleTable->new(
2048             [ 12, 'Parameter' ],
2049             [ 26, 'Filename' ],
2050             [ 18, 'Type' ],
2051             [ 9,  'Size' ]
2052         );
2053         for my $key ( sort keys %{ $c->request->uploads } ) {
2054             my $upload = $c->request->uploads->{$key};
2055             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2056                 $t->row( $key, $u->filename, $u->type, $u->size );
2057             }
2058         }
2059         $c->log->debug( "File Uploads are:\n" . $t->draw );
2060     }
2061 }
2062
2063 =head2 $c->prepare_write
2064
2065 Prepares the output for writing.
2066
2067 =cut
2068
2069 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2070
2071 =head2 $c->request_class
2072
2073 Returns or sets the request class.
2074
2075 =head2 $c->response_class
2076
2077 Returns or sets the response class.
2078
2079 =head2 $c->read( [$maxlength] )
2080
2081 Reads a chunk of data from the request body. This method is designed to
2082 be used in a while loop, reading C<$maxlength> bytes on every call.
2083 C<$maxlength> defaults to the size of the request if not specified.
2084
2085 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
2086 directly.
2087
2088 Warning: If you use read(), Catalyst will not process the body,
2089 so you will not be able to access POST parameters or file uploads via
2090 $c->request.  You must handle all body parsing yourself.
2091
2092 =cut
2093
2094 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2095
2096 =head2 $c->run
2097
2098 Starts the engine.
2099
2100 =cut
2101
2102 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2103
2104 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2105
2106 Sets an action in a given namespace.
2107
2108 =cut
2109
2110 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2111
2112 =head2 $c->setup_actions($component)
2113
2114 Sets up actions for a component.
2115
2116 =cut
2117
2118 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2119
2120 =head2 $c->setup_components
2121
2122 Sets up components. Specify a C<setup_components> config option to pass
2123 additional options directly to L<Module::Pluggable>. To add additional
2124 search paths, specify a key named C<search_extra> as an array
2125 reference. Items in the array beginning with C<::> will have the
2126 application class name prepended to them.
2127
2128 All components found will also have any
2129 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2130 Note, that modules which are B<not> an I<inner package> of the main
2131 file namespace loaded will not be instantiated as components.
2132
2133 =cut
2134
2135 sub setup_components {
2136     my $class = shift;
2137
2138     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2139     my $config  = $class->config->{ setup_components };
2140     my $extra   = delete $config->{ search_extra } || [];
2141
2142     push @paths, @$extra;
2143
2144     my $locator = Module::Pluggable::Object->new(
2145         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2146         %$config
2147     );
2148
2149     my @comps = sort { length $a <=> length $b } $locator->plugins;
2150     my %comps = map { $_ => 1 } @comps;
2151
2152     my $deprecated_component_names = grep { /::[CMV]::/ } @comps;
2153     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2154         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2155     ) if $deprecated_component_names;
2156
2157     for my $component ( @comps ) {
2158
2159         # We pass ignore_loaded here so that overlay files for (e.g.)
2160         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2161         # we know M::P::O found a file on disk so this is safe
2162
2163         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2164         #Class::MOP::load_class($component);
2165
2166         my $module  = $class->setup_component( $component );
2167         my %modules = (
2168             $component => $module,
2169             map {
2170                 $_ => $class->setup_component( $_ )
2171             } grep {
2172               not exists $comps{$_}
2173             } Devel::InnerPackage::list_packages( $component )
2174         );
2175
2176         for my $key ( keys %modules ) {
2177             $class->components->{ $key } = $modules{ $key };
2178         }
2179     }
2180 }
2181
2182 =head2 $c->setup_component
2183
2184 =cut
2185
2186 sub _controller_init_base_classes {
2187     my ($app_class, $component) = @_;
2188     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2189         Moose::Meta::Class->initialize( $class )
2190             unless find_meta($class);
2191     }
2192 }
2193
2194 sub setup_component {
2195     my( $class, $component ) = @_;
2196
2197     unless ( $component->can( 'COMPONENT' ) ) {
2198         return $component;
2199     }
2200
2201     # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2202     #         nearest to Catalyst::Controller first, no matter what order stuff happens
2203     #         to be loaded. There are TODO tests in Moose for this, see
2204     #         f2391d17574eff81d911b97be15ea51080500003
2205     if ($component->isa('Catalyst::Controller')) {
2206         $class->_controller_init_base_classes($component);
2207     }
2208
2209     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2210     my $config = $class->config->{ $suffix } || {};
2211
2212     my $instance = eval { $component->COMPONENT( $class, $config ); };
2213
2214     if ( my $error = $@ ) {
2215         chomp $error;
2216         Catalyst::Exception->throw(
2217             message => qq/Couldn't instantiate component "$component", "$error"/
2218         );
2219     }
2220
2221     unless (blessed $instance) {
2222         my $metaclass = Moose::Util::find_meta($component);
2223         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2224         my $component_method_from = $method_meta->associated_metaclass->name;
2225         my $value = defined($instance) ? $instance : 'undef';
2226         Catalyst::Exception->throw(
2227             message =>
2228             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2229         );
2230     }
2231     return $instance;
2232 }
2233
2234 =head2 $c->setup_dispatcher
2235
2236 Sets up dispatcher.
2237
2238 =cut
2239
2240 sub setup_dispatcher {
2241     my ( $class, $dispatcher ) = @_;
2242
2243     if ($dispatcher) {
2244         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2245     }
2246
2247     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2248         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2249     }
2250
2251     unless ($dispatcher) {
2252         $dispatcher = $class->dispatcher_class;
2253     }
2254
2255     Class::MOP::load_class($dispatcher);
2256
2257     # dispatcher instance
2258     $class->dispatcher( $dispatcher->new );
2259 }
2260
2261 =head2 $c->setup_engine
2262
2263 Sets up engine.
2264
2265 =cut
2266
2267 sub setup_engine {
2268     my ( $class, $engine ) = @_;
2269
2270     if ($engine) {
2271         $engine = 'Catalyst::Engine::' . $engine;
2272     }
2273
2274     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2275         $engine = 'Catalyst::Engine::' . $env;
2276     }
2277
2278     if ( $ENV{MOD_PERL} ) {
2279         my $meta = Class::MOP::get_metaclass_by_name($class);
2280
2281         # create the apache method
2282         $meta->add_method('apache' => sub { shift->engine->apache });
2283
2284         my ( $software, $version ) =
2285           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2286
2287         $version =~ s/_//g;
2288         $version =~ s/(\.[^.]+)\./$1/g;
2289
2290         if ( $software eq 'mod_perl' ) {
2291
2292             if ( !$engine ) {
2293
2294                 if ( $version >= 1.99922 ) {
2295                     $engine = 'Catalyst::Engine::Apache2::MP20';
2296                 }
2297
2298                 elsif ( $version >= 1.9901 ) {
2299                     $engine = 'Catalyst::Engine::Apache2::MP19';
2300                 }
2301
2302                 elsif ( $version >= 1.24 ) {
2303                     $engine = 'Catalyst::Engine::Apache::MP13';
2304                 }
2305
2306                 else {
2307                     Catalyst::Exception->throw( message =>
2308                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2309                 }
2310
2311             }
2312
2313             # install the correct mod_perl handler
2314             if ( $version >= 1.9901 ) {
2315                 *handler = sub  : method {
2316                     shift->handle_request(@_);
2317                 };
2318             }
2319             else {
2320                 *handler = sub ($$) { shift->handle_request(@_) };
2321             }
2322
2323         }
2324
2325         elsif ( $software eq 'Zeus-Perl' ) {
2326             $engine = 'Catalyst::Engine::Zeus';
2327         }
2328
2329         else {
2330             Catalyst::Exception->throw(
2331                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2332         }
2333     }
2334
2335     unless ($engine) {
2336         $engine = $class->engine_class;
2337     }
2338
2339     Class::MOP::load_class($engine);
2340
2341     # check for old engines that are no longer compatible
2342     my $old_engine;
2343     if ( $engine->isa('Catalyst::Engine::Apache')
2344         && !Catalyst::Engine::Apache->VERSION )
2345     {
2346         $old_engine = 1;
2347     }
2348
2349     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2350         && Catalyst::Engine::Server->VERSION le '0.02' )
2351     {
2352         $old_engine = 1;
2353     }
2354
2355     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2356         && $engine->VERSION eq '0.01' )
2357     {
2358         $old_engine = 1;
2359     }
2360
2361     elsif ($engine->isa('Catalyst::Engine::Zeus')
2362         && $engine->VERSION eq '0.01' )
2363     {
2364         $old_engine = 1;
2365     }
2366
2367     if ($old_engine) {
2368         Catalyst::Exception->throw( message =>
2369               qq/Engine "$engine" is not supported by this version of Catalyst/
2370         );
2371     }
2372
2373     # engine instance
2374     $class->engine( $engine->new );
2375 }
2376
2377 =head2 $c->setup_home
2378
2379 Sets up the home directory.
2380
2381 =cut
2382
2383 sub setup_home {
2384     my ( $class, $home ) = @_;
2385
2386     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2387         $home = $env;
2388     }
2389
2390     $home ||= Catalyst::Utils::home($class);
2391
2392     if ($home) {
2393         #I remember recently being scolded for assigning config values like this
2394         $class->config->{home} ||= $home;
2395         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2396     }
2397 }
2398
2399 =head2 $c->setup_log
2400
2401 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2402 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2403 log to.
2404
2405 This method also installs a C<debug> method that returns a true value into the
2406 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2407 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2408
2409 Note that if the log has already been setup, by either a previous call to
2410 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2411 that this method won't actually set up the log object.
2412
2413 =cut
2414
2415 sub setup_log {
2416     my ( $class, $levels ) = @_;
2417
2418     $levels ||= '';
2419     $levels =~ s/^\s+//;
2420     $levels =~ s/\s+$//;
2421     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2422
2423     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2424     if ( defined $env_debug ) {
2425         $levels{debug} = 1 if $env_debug; # Ugly!
2426         delete($levels{debug}) unless $env_debug;
2427     }
2428
2429     unless ( $class->log ) {
2430         $class->log( Catalyst::Log->new(keys %levels) );
2431     }
2432
2433     if ( $levels{debug} ) {
2434         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2435         $class->log->debug('Debug messages enabled');
2436     }
2437 }
2438
2439 =head2 $c->setup_plugins
2440
2441 Sets up plugins.
2442
2443 =cut
2444
2445 =head2 $c->setup_stats
2446
2447 Sets up timing statistics class.
2448
2449 =cut
2450
2451 sub setup_stats {
2452     my ( $class, $stats ) = @_;
2453
2454     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2455
2456     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2457     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2458         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2459         $class->log->debug('Statistics enabled');
2460     }
2461 }
2462
2463
2464 =head2 $c->registered_plugins
2465
2466 Returns a sorted list of the plugins which have either been stated in the
2467 import list or which have been added via C<< MyApp->plugin(@args); >>.
2468
2469 If passed a given plugin name, it will report a boolean value indicating
2470 whether or not that plugin is loaded.  A fully qualified name is required if
2471 the plugin name does not begin with C<Catalyst::Plugin::>.
2472
2473  if ($c->registered_plugins('Some::Plugin')) {
2474      ...
2475  }
2476
2477 =cut
2478
2479 {
2480
2481     sub registered_plugins {
2482         my $proto = shift;
2483         return sort keys %{ $proto->_plugins } unless @_;
2484         my $plugin = shift;
2485         return 1 if exists $proto->_plugins->{$plugin};
2486         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2487     }
2488
2489     sub _register_plugin {
2490         my ( $proto, $plugin, $instant ) = @_;
2491         my $class = ref $proto || $proto;
2492
2493         Class::MOP::load_class( $plugin );
2494
2495         $proto->_plugins->{$plugin} = 1;
2496         unless ($instant) {
2497             no strict 'refs';
2498             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2499               my @superclasses = ($plugin, $meta->superclasses );
2500               $meta->superclasses(@superclasses);
2501             } else {
2502               unshift @{"$class\::ISA"}, $plugin;
2503             }
2504         }
2505         return $class;
2506     }
2507
2508     sub setup_plugins {
2509         my ( $class, $plugins ) = @_;
2510
2511         $class->_plugins( {} ) unless $class->_plugins;
2512         $plugins ||= [];
2513
2514         my @plugins = map { s/\A\+// ? $_ : "Catalyst::Plugin::$_" } @$plugins;
2515
2516         for my $plugin ( reverse @plugins ) {
2517             Class::MOP::load_class($plugin);
2518             my $meta = find_meta($plugin);
2519             next if $meta && $meta->isa('Moose::Meta::Role');
2520
2521             $class->_register_plugin($plugin);
2522         }
2523
2524         my @roles =
2525             map { $_->name }
2526             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2527             map { find_meta($_) }
2528             @plugins;
2529
2530         Moose::Util::apply_all_roles(
2531             $class => @roles
2532         ) if @roles;
2533     }
2534 }
2535
2536 =head2 $c->stack
2537
2538 Returns an arrayref of the internal execution stack (actions that are
2539 currently executing).
2540
2541 =head2 $c->stats_class
2542
2543 Returns or sets the stats (timing statistics) class.
2544
2545 =head2 $c->use_stats
2546
2547 Returns 1 when stats collection is enabled.  Stats collection is enabled
2548 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2549 environment variable is set.
2550
2551 Note that this is a static method, not an accessor and should be overridden
2552 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2553
2554 =cut
2555
2556 sub use_stats { 0 }
2557
2558
2559 =head2 $c->write( $data )
2560
2561 Writes $data to the output stream. When using this method directly, you
2562 will need to manually set the C<Content-Length> header to the length of
2563 your output data, if known.
2564
2565 =cut
2566
2567 sub write {
2568     my $c = shift;
2569
2570     # Finalize headers if someone manually writes output
2571     $c->finalize_headers;
2572
2573     return $c->engine->write( $c, @_ );
2574 }
2575
2576 =head2 version
2577
2578 Returns the Catalyst version number. Mostly useful for "powered by"
2579 messages in template systems.
2580
2581 =cut
2582
2583 sub version { return $Catalyst::VERSION }
2584
2585 =head1 INTERNAL ACTIONS
2586
2587 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2588 C<_ACTION>, and C<_END>. These are by default not shown in the private
2589 action table, but you can make them visible with a config parameter.
2590
2591     MyApp->config->{show_internal_actions} = 1;
2592
2593 =head1 CASE SENSITIVITY
2594
2595 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2596 mapped to C</foo/bar>. You can activate case sensitivity with a config
2597 parameter.
2598
2599     MyApp->config->{case_sensitive} = 1;
2600
2601 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2602
2603 =head1 ON-DEMAND PARSER
2604
2605 The request body is usually parsed at the beginning of a request,
2606 but if you want to handle input yourself, you can enable on-demand
2607 parsing with a config parameter.
2608
2609     MyApp->config->{parse_on_demand} = 1;
2610
2611 =head1 PROXY SUPPORT
2612
2613 Many production servers operate using the common double-server approach,
2614 with a lightweight frontend web server passing requests to a larger
2615 backend server. An application running on the backend server must deal
2616 with two problems: the remote user always appears to be C<127.0.0.1> and
2617 the server's hostname will appear to be C<localhost> regardless of the
2618 virtual host that the user connected through.
2619
2620 Catalyst will automatically detect this situation when you are running
2621 the frontend and backend servers on the same machine. The following
2622 changes are made to the request.
2623
2624     $c->req->address is set to the user's real IP address, as read from
2625     the HTTP X-Forwarded-For header.
2626
2627     The host value for $c->req->base and $c->req->uri is set to the real
2628     host, as read from the HTTP X-Forwarded-Host header.
2629
2630 Obviously, your web server must support these headers for this to work.
2631
2632 In a more complex server farm environment where you may have your
2633 frontend proxy server(s) on different machines, you will need to set a
2634 configuration option to tell Catalyst to read the proxied data from the
2635 headers.
2636
2637     MyApp->config->{using_frontend_proxy} = 1;
2638
2639 If you do not wish to use the proxy support at all, you may set:
2640
2641     MyApp->config->{ignore_frontend_proxy} = 1;
2642
2643 =head1 THREAD SAFETY
2644
2645 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2646 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2647 believe the Catalyst core to be thread-safe.
2648
2649 If you plan to operate in a threaded environment, remember that all other
2650 modules you are using must also be thread-safe. Some modules, most notably
2651 L<DBD::SQLite>, are not thread-safe.
2652
2653 =head1 SUPPORT
2654
2655 IRC:
2656
2657     Join #catalyst on irc.perl.org.
2658
2659 Mailing Lists:
2660
2661     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2662     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2663
2664 Web:
2665
2666     http://catalyst.perl.org
2667
2668 Wiki:
2669
2670     http://dev.catalyst.perl.org
2671
2672 =head1 SEE ALSO
2673
2674 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2675
2676 =head2 L<Catalyst::Manual> - The Catalyst Manual
2677
2678 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2679
2680 =head2 L<Catalyst::Engine> - Core engine
2681
2682 =head2 L<Catalyst::Log> - Log class.
2683
2684 =head2 L<Catalyst::Request> - Request object
2685
2686 =head2 L<Catalyst::Response> - Response object
2687
2688 =head2 L<Catalyst::Test> - The test suite.
2689
2690 =head1 PROJECT FOUNDER
2691
2692 sri: Sebastian Riedel <sri@cpan.org>
2693
2694 =head1 CONTRIBUTORS
2695
2696 abw: Andy Wardley
2697
2698 acme: Leon Brocard <leon@astray.com>
2699
2700 Andrew Bramble
2701
2702 Andrew Ford
2703
2704 Andrew Ruthven
2705
2706 andyg: Andy Grundman <andy@hybridized.org>
2707
2708 audreyt: Audrey Tang
2709
2710 bricas: Brian Cassidy <bricas@cpan.org>
2711
2712 Caelum: Rafael Kitover <rkitover@io.com>
2713
2714 chansen: Christian Hansen
2715
2716 chicks: Christopher Hicks
2717
2718 David E. Wheeler
2719
2720 dhoss: Devin Austin <dhoss@cpan.org>
2721
2722 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2723
2724 Drew Taylor
2725
2726 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2727
2728 esskar: Sascha Kiefer
2729
2730 fireartist: Carl Franks <cfranks@cpan.org>
2731
2732 gabb: Danijel Milicevic
2733
2734 Gary Ashton Jones
2735
2736 Geoff Richards
2737
2738 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2739
2740 jcamacho: Juan Camacho
2741
2742 jhannah: Jay Hannah <jay@jays.net>
2743
2744 Jody Belka
2745
2746 Johan Lindstrom
2747
2748 jon: Jon Schutz <jjschutz@cpan.org>
2749
2750 marcus: Marcus Ramberg <mramberg@cpan.org>
2751
2752 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2753
2754 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2755
2756 mugwump: Sam Vilain
2757
2758 naughton: David Naughton
2759
2760 ningu: David Kamholz <dkamholz@cpan.org>
2761
2762 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2763
2764 numa: Dan Sully <daniel@cpan.org>
2765
2766 obra: Jesse Vincent
2767
2768 omega: Andreas Marienborg
2769
2770 Oleg Kostyuk <cub.uanic@gmail.com>
2771
2772 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2773
2774 rafl: Florian Ragwitz <rafl@debian.org>
2775
2776 random: Roland Lammel <lammel@cpan.org>
2777
2778 sky: Arthur Bergman
2779
2780 the_jester: Jesse Sheidlower
2781
2782 t0m: Tomas Doran <bobtfish@bobtfish.net>
2783
2784 Ulf Edvinsson
2785
2786 willert: Sebastian Willert <willert@cpan.org>
2787
2788 =head1 LICENSE
2789
2790 This library is free software. You can redistribute it and/or modify it under
2791 the same terms as Perl itself.
2792
2793 =cut
2794
2795 no Moose;
2796
2797 __PACKAGE__->meta->make_immutable;
2798
2799 1;