lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use bytes;
   8 use B::Hooks::EndOfScope ();
   9 use Catalyst::Exception;
  10 use Catalyst::Exception::Detach;
  11 use Catalyst::Exception::Go;
  12 use Catalyst::Log;
  13 use Catalyst::Request;
  14 use Catalyst::Request::Upload;
  15 use Catalyst::Response;
  16 use Catalyst::Utils;
  17 use Catalyst::Controller;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use attributes;
  31 use utf8;
  32 use Carp qw/croak carp shortmess/;
  33
  34 BEGIN { require 5.008001; }
  35
  36 has stack => (is => 'ro', default => sub { [] });
  37 has stash => (is => 'rw', default => sub { {} });
  38 has state => (is => 'rw', default => 0);
  39 has stats => (is => 'rw');
  40 has action => (is => 'rw');
  41 has counter => (is => 'rw', default => sub { {} });
  42 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  43 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  44 has namespace => (is => 'rw');
  45
  46 sub depth { scalar @{ shift->stack || [] }; }
  47 sub comp { shift->component(@_) }
  48
  49 sub req {
  50     my $self = shift; return $self->request(@_);
  51 }
  52 sub res {
  53     my $self = shift; return $self->response(@_);
  54 }
  55
  56 # For backwards compatibility
  57 sub finalize_output { shift->finalize_body(@_) };
  58
  59 # For statistics
  60 our $COUNT     = 1;
  61 our $START     = time;
  62 our $RECURSION = 1000;
  63 our $DETACH    = Catalyst::Exception::Detach->new;
  64 our $GO        = Catalyst::Exception::Go->new;
  65
  66 #I imagine that very few of these really need to be class variables. if any.
  67 #maybe we should just make them attributes with a default?
  68 __PACKAGE__->mk_classdata($_)
  69   for qw/components arguments dispatcher engine log dispatcher_class
  70   engine_class context_class request_class response_class stats_class
  71   setup_finished/;
  72
  73 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  74 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  75 __PACKAGE__->request_class('Catalyst::Request');
  76 __PACKAGE__->response_class('Catalyst::Response');
  77 __PACKAGE__->stats_class('Catalyst::Stats');
  78
  79 # Remember to update this in Catalyst::Runtime as well!
  80
  81 our $VERSION = '5.80007';
  82
  83 {
  84     my $dev_version = $VERSION =~ /_\d{2}$/;
  85     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  86 }
  87
  88 $VERSION = eval $VERSION;
  89
  90 sub import {
  91     my ( $class, @arguments ) = @_;
  92
  93     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  94     # callers @ISA.
  95     return unless $class eq 'Catalyst';
  96
  97     my $caller = caller();
  98     return if $caller eq 'main';
  99
 100     # Kill Adopt::NEXT warnings if we're a non-RC version
 101     unless (_IS_DEVELOPMENT_VERSION()) {
 102         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 103     }
 104
 105     my $meta = Moose::Meta::Class->initialize($caller);
 106     unless ( $caller->isa('Catalyst') ) {
 107         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 108         $meta->superclasses(@superclasses);
 109     }
 110     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 111     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 112
 113     unless( $meta->has_method('meta') ){
 114         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 115     }
 116
 117     $caller->arguments( [@arguments] );
 118     $caller->setup_home;
 119 }
 120
 121 sub _application { $_[0] }
 122
 123 =head1 NAME
 124
 125 Catalyst - The Elegant MVC Web Application Framework
 126
 127 =head1 SYNOPSIS
 128
 129 See the L<Catalyst::Manual> distribution for comprehensive
 130 documentation and tutorials.
 131
 132     # Install Catalyst::Devel for helpers and other development tools
 133     # use the helper to create a new application
 134     catalyst.pl MyApp
 135
 136     # add models, views, controllers
 137     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 138     script/myapp_create.pl view MyTemplate TT
 139     script/myapp_create.pl controller Search
 140
 141     # built in testserver -- use -r to restart automatically on changes
 142     # --help to see all available options
 143     script/myapp_server.pl
 144
 145     # command line testing interface
 146     script/myapp_test.pl /yada
 147
 148     ### in lib/MyApp.pm
 149     use Catalyst qw/-Debug/; # include plugins here as well
 150
 151     ### In lib/MyApp/Controller/Root.pm (autocreated)
 152     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 153         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 154         $c->stash->{template} = 'foo.tt'; # set the template
 155         # lookup something from db -- stash vars are passed to TT
 156         $c->stash->{data} =
 157           $c->model('Database::Foo')->search( { country => $args[0] } );
 158         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 159             $c->forward( 'bar' ); # process another action
 160             # do something else after forward returns
 161         }
 162     }
 163
 164     # The foo.tt TT template can use the stash data from the database
 165     [% WHILE (item = data.next) %]
 166         [% item.foo %]
 167     [% END %]
 168
 169     # called for /bar/of/soap, /bar/of/soap/10, etc.
 170     sub bar : Path('/bar/of/soap') { ... }
 171
 172     # called for all actions, from the top-most controller downwards
 173     sub auto : Private {
 174         my ( $self, $c ) = @_;
 175         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 176             $c->res->redirect( '/login' ); # require login
 177             return 0; # abort request and go immediately to end()
 178         }
 179         return 1; # success; carry on to next action
 180     }
 181
 182     # called after all actions are finished
 183     sub end : Private {
 184         my ( $self, $c ) = @_;
 185         if ( scalar @{ $c->error } ) { ... } # handle errors
 186         return if $c->res->body; # already have a response
 187         $c->forward( 'MyApp::View::TT' ); # render template
 188     }
 189
 190     ### in MyApp/Controller/Foo.pm
 191     # called for /foo/bar
 192     sub bar : Local { ... }
 193
 194     # called for /blargle
 195     sub blargle : Global { ... }
 196
 197     # an index action matches /foo, but not /foo/1, etc.
 198     sub index : Private { ... }
 199
 200     ### in MyApp/Controller/Foo/Bar.pm
 201     # called for /foo/bar/baz
 202     sub baz : Local { ... }
 203
 204     # first Root auto is called, then Foo auto, then this
 205     sub auto : Private { ... }
 206
 207     # powerful regular expression paths are also possible
 208     sub details : Regex('^product/(\w+)/details$') {
 209         my ( $self, $c ) = @_;
 210         # extract the (\w+) from the URI
 211         my $product = $c->req->captures->[0];
 212     }
 213
 214 See L<Catalyst::Manual::Intro> for additional information.
 215
 216 =head1 DESCRIPTION
 217
 218 Catalyst is a modern framework for making web applications without the
 219 pain usually associated with this process. This document is a reference
 220 to the main Catalyst application. If you are a new user, we suggest you
 221 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 222
 223 See L<Catalyst::Manual> for more documentation.
 224
 225 Catalyst plugins can be loaded by naming them as arguments to the "use
 226 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 227 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 228 C<My::Module>.
 229
 230     use Catalyst qw/My::Module/;
 231
 232 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 233 fully qualify the name by using a unary plus:
 234
 235     use Catalyst qw/
 236         My::Module
 237         +Fully::Qualified::Plugin::Name
 238     /;
 239
 240 Special flags like C<-Debug> and C<-Engine> can also be specified as
 241 arguments when Catalyst is loaded:
 242
 243     use Catalyst qw/-Debug My::Module/;
 244
 245 The position of plugins and flags in the chain is important, because
 246 they are loaded in the order in which they appear.
 247
 248 The following flags are supported:
 249
 250 =head2 -Debug
 251
 252 Enables debug output. You can also force this setting from the system
 253 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 254 settings override the application, with <MYAPP>_DEBUG having the highest
 255 priority.
 256
 257 =head2 -Engine
 258
 259 Forces Catalyst to use a specific engine. Omit the
 260 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 261
 262     use Catalyst qw/-Engine=CGI/;
 263
 264 =head2 -Home
 265
 266 Forces Catalyst to use a specific home directory, e.g.:
 267
 268     use Catalyst qw[-Home=/usr/mst];
 269
 270 This can also be done in the shell environment by setting either the
 271 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 272 is replaced with the uppercased name of your application, any "::" in
 273 the name will be replaced with underscores, e.g. MyApp::Web should use
 274 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 275
 276 =head2 -Log
 277
 278     use Catalyst '-Log=warn,fatal,error';
 279
 280 Specifies a comma-delimited list of log levels.
 281
 282 =head2 -Stats
 283
 284 Enables statistics collection and reporting. You can also force this setting
 285 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 286 environment settings override the application, with <MYAPP>_STATS having the
 287 highest priority.
 288
 289 e.g.
 290
 291    use Catalyst qw/-Stats=1/
 292
 293 =head1 METHODS
 294
 295 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 296
 297 =head2 $c->action
 298
 299 Returns a L<Catalyst::Action> object for the current action, which
 300 stringifies to the action name. See L<Catalyst::Action>.
 301
 302 =head2 $c->namespace
 303
 304 Returns the namespace of the current action, i.e., the URI prefix
 305 corresponding to the controller of the current action. For example:
 306
 307     # in Controller::Foo::Bar
 308     $c->namespace; # returns 'foo/bar';
 309
 310 =head2 $c->request
 311
 312 =head2 $c->req
 313
 314 Returns the current L<Catalyst::Request> object, giving access to
 315 information about the current client request (including parameters,
 316 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 317
 318 =head2 REQUEST FLOW HANDLING
 319
 320 =head2 $c->forward( $action [, \@arguments ] )
 321
 322 =head2 $c->forward( $class, $method, [, \@arguments ] )
 323
 324 Forwards processing to another action, by its private name. If you give a
 325 class name but no method, C<process()> is called. You may also optionally
 326 pass arguments in an arrayref. The action will receive the arguments in
 327 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 328 C<< $c->req->args >> will be restored to the previous values.
 329
 330 Any data C<return>ed from the action forwarded to, will be returned by the
 331 call to forward.
 332
 333     my $foodata = $c->forward('/foo');
 334     $c->forward('index');
 335     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 336     $c->forward('MyApp::View::TT');
 337
 338 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 339 an C<< eval { } >> around the call (actually
 340 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 341 all 'dies' within the called action. If you want C<die> to propagate you
 342 need to do something like:
 343
 344     $c->forward('foo');
 345     die $c->error if $c->error;
 346
 347 Or make sure to always return true values from your actions and write
 348 your code like this:
 349
 350     $c->forward('foo') || return;
 351
 352 =cut
 353
 354 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 355
 356 =head2 $c->detach( $action [, \@arguments ] )
 357
 358 =head2 $c->detach( $class, $method, [, \@arguments ] )
 359
 360 =head2 $c->detach()
 361
 362 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 363 doesn't return to the previous action when processing is finished.
 364
 365 When called with no arguments it escapes the processing chain entirely.
 366
 367 =cut
 368
 369 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 370
 371 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 372
 373 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 374
 375 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 376 but does a full dispatch, instead of just calling the new C<$action> /
 377 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 378 you go to are called, just like a new request.
 379
 380 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 381 This means, for example, that C<< $c->action >> methods such as
 382 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 383 L<reverse|Catalyst::Action/reverse> return information for the visited action
 384 when they are invoked within the visited action.  This is different from the
 385 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 386 continues to use the $c->action object from the caller action even when
 387 invoked from the callee.
 388
 389 C<< $c->stash >> is kept unchanged.
 390
 391 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 392 allows you to "wrap" another action, just as it would have been called by
 393 dispatching from a URL, while the analogous
 394 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 395 transfer control to another action as if it had been reached directly from a URL.
 396
 397 =cut
 398
 399 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 400
 401 =head2 $c->go( $action [, \@captures, \@arguments ] )
 402
 403 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 404
 405 Almost the same as L<< detach|/"$c->detach( $action [, \@arguments ] )" >>, but does a full dispatch like L</visit>,
 406 instead of just calling the new C<$action> /
 407 C<< $class->$method >>. This means that C<begin>, C<auto> and the
 408 method you visit are called, just like a new request.
 409
 410 C<< $c->stash >> is kept unchanged.
 411
 412 =cut
 413
 414 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 415
 416 =head2 $c->response
 417
 418 =head2 $c->res
 419
 420 Returns the current L<Catalyst::Response> object, see there for details.
 421
 422 =head2 $c->stash
 423
 424 Returns a hashref to the stash, which may be used to store data and pass
 425 it between components during a request. You can also set hash keys by
 426 passing arguments. The stash is automatically sent to the view. The
 427 stash is cleared at the end of a request; it cannot be used for
 428 persistent storage (for this you must use a session; see
 429 L<Catalyst::Plugin::Session> for a complete system integrated with
 430 Catalyst).
 431
 432     $c->stash->{foo} = $bar;
 433     $c->stash( { moose => 'majestic', qux => 0 } );
 434     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 435
 436     # stash is automatically passed to the view for use in a template
 437     $c->forward( 'MyApp::View::TT' );
 438
 439 =cut
 440
 441 around stash => sub {
 442     my $orig = shift;
 443     my $c = shift;
 444     my $stash = $orig->($c);
 445     if (@_) {
 446         my $new_stash = @_ > 1 ? {@_} : $_[0];
 447         croak('stash takes a hash or hashref') unless ref $new_stash;
 448         foreach my $key ( keys %$new_stash ) {
 449           $stash->{$key} = $new_stash->{$key};
 450         }
 451     }
 452
 453     return $stash;
 454 };
 455
 456
 457 =head2 $c->error
 458
 459 =head2 $c->error($error, ...)
 460
 461 =head2 $c->error($arrayref)
 462
 463 Returns an arrayref containing error messages.  If Catalyst encounters an
 464 error while processing a request, it stores the error in $c->error.  This
 465 method should only be used to store fatal error messages.
 466
 467     my @error = @{ $c->error };
 468
 469 Add a new error.
 470
 471     $c->error('Something bad happened');
 472
 473 =cut
 474
 475 sub error {
 476     my $c = shift;
 477     if ( $_[0] ) {
 478         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 479         croak @$error unless ref $c;
 480         push @{ $c->{error} }, @$error;
 481     }
 482     elsif ( defined $_[0] ) { $c->{error} = undef }
 483     return $c->{error} || [];
 484 }
 485
 486
 487 =head2 $c->state
 488
 489 Contains the return value of the last executed action.
 490
 491 =head2 $c->clear_errors
 492
 493 Clear errors.  You probably don't want to clear the errors unless you are
 494 implementing a custom error screen.
 495
 496 This is equivalent to running
 497
 498     $c->error(0);
 499
 500 =cut
 501
 502 sub clear_errors {
 503     my $c = shift;
 504     $c->error(0);
 505 }
 506
 507 sub _comp_search_prefixes {
 508     my $c = shift;
 509     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 510 }
 511
 512 # search components given a name and some prefixes
 513 sub _comp_names_search_prefixes {
 514     my ( $c, $name, @prefixes ) = @_;
 515     my $appclass = ref $c || $c;
 516     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 517     $filter = qr/$filter/; # Compile regex now rather than once per loop
 518
 519     # map the original component name to the sub part that we will search against
 520     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 521         grep { /$filter/ } keys %{ $c->components };
 522
 523     # undef for a name will return all
 524     return keys %eligible if !defined $name;
 525
 526     my $query  = ref $name ? $name : qr/^$name$/i;
 527     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 528
 529     return @result if @result;
 530
 531     # if we were given a regexp to search against, we're done.
 532     return if ref $name;
 533
 534     # regexp fallback
 535     $query  = qr/$name/i;
 536     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 537
 538     # no results? try against full names
 539     if( !@result ) {
 540         @result = grep { m{$query} } keys %eligible;
 541     }
 542
 543     # don't warn if we didn't find any results, it just might not exist
 544     if( @result ) {
 545         # Disgusting hack to work out correct method name
 546         my $warn_for = lc $prefixes[0];
 547         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 548            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 549            "component resolution is unreliable and unsafe.";
 550         my $short = $result[0];
 551         $short =~ s/.*?Model:://;
 552         my $shortmess = Carp::shortmess('');
 553         if ($shortmess =~ m#Catalyst/Plugin#) {
 554            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 555               "plugin's config";
 556         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 557            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 558               "component's config";
 559         } else {
 560            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 561               "but if you really wanted to search, pass in a regexp as the argument " .
 562               "like so: \$c->${warn_for}(qr/${name}/)";
 563         }
 564         $c->log->warn( "${msg}$shortmess" );
 565     }
 566
 567     return @result;
 568 }
 569
 570 # Find possible names for a prefix
 571 sub _comp_names {
 572     my ( $c, @prefixes ) = @_;
 573     my $appclass = ref $c || $c;
 574
 575     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 576
 577     my @names = map { s{$filter}{}; $_; }
 578         $c->_comp_names_search_prefixes( undef, @prefixes );
 579
 580     return @names;
 581 }
 582
 583 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 584 sub _filter_component {
 585     my ( $c, $comp, @args ) = @_;
 586
 587     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 588         return $comp->ACCEPT_CONTEXT( $c, @args );
 589     }
 590
 591     return $comp;
 592 }
 593
 594 =head2 COMPONENT ACCESSORS
 595
 596 =head2 $c->controller($name)
 597
 598 Gets a L<Catalyst::Controller> instance by name.
 599
 600     $c->controller('Foo')->do_stuff;
 601
 602 If the name is omitted, will return the controller for the dispatched
 603 action.
 604
 605 If you want to search for controllers, pass in a regexp as the argument.
 606
 607     # find all controllers that start with Foo
 608     my @foo_controllers = $c->controller(qr{^Foo});
 609
 610
 611 =cut
 612
 613 sub controller {
 614     my ( $c, $name, @args ) = @_;
 615
 616     if( $name ) {
 617         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 618         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 619         return $c->_filter_component( $result[ 0 ], @args );
 620     }
 621
 622     return $c->component( $c->action->class );
 623 }
 624
 625 =head2 $c->model($name)
 626
 627 Gets a L<Catalyst::Model> instance by name.
 628
 629     $c->model('Foo')->do_stuff;
 630
 631 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 632
 633 If the name is omitted, it will look for
 634  - a model object in $c->stash->{current_model_instance}, then
 635  - a model name in $c->stash->{current_model}, then
 636  - a config setting 'default_model', or
 637  - check if there is only one model, and return it if that's the case.
 638
 639 If you want to search for models, pass in a regexp as the argument.
 640
 641     # find all models that start with Foo
 642     my @foo_models = $c->model(qr{^Foo});
 643
 644 =cut
 645
 646 sub model {
 647     my ( $c, $name, @args ) = @_;
 648
 649     if( $name ) {
 650         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 651         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 652         return $c->_filter_component( $result[ 0 ], @args );
 653     }
 654
 655     if (ref $c) {
 656         return $c->stash->{current_model_instance}
 657           if $c->stash->{current_model_instance};
 658         return $c->model( $c->stash->{current_model} )
 659           if $c->stash->{current_model};
 660     }
 661     return $c->model( $c->config->{default_model} )
 662       if $c->config->{default_model};
 663
 664     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 665
 666     if( $rest ) {
 667         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 668         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 669         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 670         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 671         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 672     }
 673
 674     return $c->_filter_component( $comp );
 675 }
 676
 677
 678 =head2 $c->view($name)
 679
 680 Gets a L<Catalyst::View> instance by name.
 681
 682     $c->view('Foo')->do_stuff;
 683
 684 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 685
 686 If the name is omitted, it will look for
 687  - a view object in $c->stash->{current_view_instance}, then
 688  - a view name in $c->stash->{current_view}, then
 689  - a config setting 'default_view', or
 690  - check if there is only one view, and return it if that's the case.
 691
 692 If you want to search for views, pass in a regexp as the argument.
 693
 694     # find all views that start with Foo
 695     my @foo_views = $c->view(qr{^Foo});
 696
 697 =cut
 698
 699 sub view {
 700     my ( $c, $name, @args ) = @_;
 701
 702     if( $name ) {
 703         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 704         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 705         return $c->_filter_component( $result[ 0 ], @args );
 706     }
 707
 708     if (ref $c) {
 709         return $c->stash->{current_view_instance}
 710           if $c->stash->{current_view_instance};
 711         return $c->view( $c->stash->{current_view} )
 712           if $c->stash->{current_view};
 713     }
 714     return $c->view( $c->config->{default_view} )
 715       if $c->config->{default_view};
 716
 717     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 718
 719     if( $rest ) {
 720         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 721         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 722         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 723         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 724         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 725     }
 726
 727     return $c->_filter_component( $comp );
 728 }
 729
 730 =head2 $c->controllers
 731
 732 Returns the available names which can be passed to $c->controller
 733
 734 =cut
 735
 736 sub controllers {
 737     my ( $c ) = @_;
 738     return $c->_comp_names(qw/Controller C/);
 739 }
 740
 741 =head2 $c->models
 742
 743 Returns the available names which can be passed to $c->model
 744
 745 =cut
 746
 747 sub models {
 748     my ( $c ) = @_;
 749     return $c->_comp_names(qw/Model M/);
 750 }
 751
 752
 753 =head2 $c->views
 754
 755 Returns the available names which can be passed to $c->view
 756
 757 =cut
 758
 759 sub views {
 760     my ( $c ) = @_;
 761     return $c->_comp_names(qw/View V/);
 762 }
 763
 764 =head2 $c->comp($name)
 765
 766 =head2 $c->component($name)
 767
 768 Gets a component object by name. This method is not recommended,
 769 unless you want to get a specific component by full
 770 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 771 should be used instead.
 772
 773 If C<$name> is a regexp, a list of components matched against the full
 774 component name will be returned.
 775
 776 =cut
 777
 778 sub component {
 779     my ( $c, $name, @args ) = @_;
 780
 781     if( $name ) {
 782         my $comps = $c->components;
 783
 784         if( !ref $name ) {
 785             # is it the exact name?
 786             return $c->_filter_component( $comps->{ $name }, @args )
 787                        if exists $comps->{ $name };
 788
 789             # perhaps we just omitted "MyApp"?
 790             my $composed = ( ref $c || $c ) . "::${name}";
 791             return $c->_filter_component( $comps->{ $composed }, @args )
 792                        if exists $comps->{ $composed };
 793
 794             # search all of the models, views and controllers
 795             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 796             return $c->_filter_component( $comp, @args ) if $comp;
 797         }
 798
 799         # This is here so $c->comp( '::M::' ) works
 800         my $query = ref $name ? $name : qr{$name}i;
 801
 802         my @result = grep { m{$query} } keys %{ $c->components };
 803         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 804
 805         if( $result[ 0 ] ) {
 806             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 807             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 808             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 809             return $c->_filter_component( $result[ 0 ], @args );
 810         }
 811
 812         # I would expect to return an empty list here, but that breaks back-compat
 813     }
 814
 815     # fallback
 816     return sort keys %{ $c->components };
 817 }
 818
 819 =head2 CLASS DATA AND HELPER CLASSES
 820
 821 =head2 $c->config
 822
 823 Returns or takes a hashref containing the application's configuration.
 824
 825     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 826
 827 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 828 like C<myapp.conf> in your applications home directory. See
 829 L<Catalyst::Plugin::ConfigLoader>.
 830
 831 =head3 Cascading configuration
 832
 833 The config method is present on all Catalyst components, and configuration
 834 will be merged when an application is started. Configuration loaded with
 835 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 836 followed by configuration in your top level C<MyApp> class. These two
 837 configurations are merged, and then configuration data whose hash key matches a
 838 component name is merged with configuration for that component.
 839
 840 The configuration for a component is then passed to the C<new> method when a
 841 component is constructed.
 842
 843 For example:
 844
 845     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 846     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 847
 848 will mean that C<MyApp::Model::Foo> receives the following data when
 849 constructed:
 850
 851     MyApp::Model::Foo->new({
 852         bar => 'baz',
 853         quux => 'frob',
 854         overrides => 'me',
 855     });
 856
 857 =cut
 858
 859 around config => sub {
 860     my $orig = shift;
 861     my $c = shift;
 862
 863     croak('Setting config after setup has been run is not allowed.')
 864         if ( @_ and $c->setup_finished );
 865
 866     $c->$orig(@_);
 867 };
 868
 869 =head2 $c->log
 870
 871 Returns the logging object instance. Unless it is already set, Catalyst
 872 sets this up with a L<Catalyst::Log> object. To use your own log class,
 873 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 874 C<< __PACKAGE__->setup >>.
 875
 876  __PACKAGE__->log( MyLogger->new );
 877  __PACKAGE__->setup;
 878
 879 And later:
 880
 881     $c->log->info( 'Now logging with my own logger!' );
 882
 883 Your log class should implement the methods described in
 884 L<Catalyst::Log>.
 885
 886
 887 =head2 $c->debug
 888
 889 Returns 1 if debug mode is enabled, 0 otherwise.
 890
 891 You can enable debug mode in several ways:
 892
 893 =over
 894
 895 =item By calling myapp_server.pl with the -d flag
 896
 897 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 898
 899 =item The -Debug option in your MyApp.pm
 900
 901 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 902
 903 =back
 904
 905 Calling C<< $c->debug(1) >> has no effect.
 906
 907 =cut
 908
 909 sub debug { 0 }
 910
 911 =head2 $c->dispatcher
 912
 913 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 914
 915 =head2 $c->engine
 916
 917 Returns the engine instance. See L<Catalyst::Engine>.
 918
 919
 920 =head2 UTILITY METHODS
 921
 922 =head2 $c->path_to(@path)
 923
 924 Merges C<@path> with C<< $c->config->{home} >> and returns a
 925 L<Path::Class::Dir> object. Note you can usually use this object as
 926 a filename, but sometimes you will have to explicitly stringify it
 927 yourself by calling the C<< ->stringify >> method.
 928
 929 For example:
 930
 931     $c->path_to( 'db', 'sqlite.db' );
 932
 933 =cut
 934
 935 sub path_to {
 936     my ( $c, @path ) = @_;
 937     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 938     if ( -d $path ) { return $path }
 939     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 940 }
 941
 942 =head2 $c->plugin( $name, $class, @args )
 943
 944 Helper method for plugins. It creates a class data accessor/mutator and
 945 loads and instantiates the given class.
 946
 947     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 948
 949     $c->prototype->define_javascript_functions;
 950
 951 B<Note:> This method of adding plugins is deprecated. The ability
 952 to add plugins like this B<will be removed> in a Catalyst 5.81.
 953 Please do not use this functionality in new code.
 954
 955 =cut
 956
 957 sub plugin {
 958     my ( $class, $name, $plugin, @args ) = @_;
 959
 960     # See block comment in t/unit_core_plugin.t
 961     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 962
 963     $class->_register_plugin( $plugin, 1 );
 964
 965     eval { $plugin->import };
 966     $class->mk_classdata($name);
 967     my $obj;
 968     eval { $obj = $plugin->new(@args) };
 969
 970     if ($@) {
 971         Catalyst::Exception->throw( message =>
 972               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 973     }
 974
 975     $class->$name($obj);
 976     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 977       if $class->debug;
 978 }
 979
 980 =head2 MyApp->setup
 981
 982 Initializes the dispatcher and engine, loads any plugins, and loads the
 983 model, view, and controller components. You may also specify an array
 984 of plugins to load here, if you choose to not load them in the C<use
 985 Catalyst> line.
 986
 987     MyApp->setup;
 988     MyApp->setup( qw/-Debug/ );
 989
 990 =cut
 991
 992 sub setup {
 993     my ( $class, @arguments ) = @_;
 994     croak('Running setup more than once')
 995         if ( $class->setup_finished );
 996
 997     unless ( $class->isa('Catalyst') ) {
 998
 999         Catalyst::Exception->throw(
1000             message => qq/'$class' does not inherit from Catalyst/ );
1001     }
1002
1003     if ( $class->arguments ) {
1004         @arguments = ( @arguments, @{ $class->arguments } );
1005     }
1006
1007     # Process options
1008     my $flags = {};
1009
1010     foreach (@arguments) {
1011
1012         if (/^-Debug$/) {
1013             $flags->{log} =
1014               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1015         }
1016         elsif (/^-(\w+)=?(.*)$/) {
1017             $flags->{ lc $1 } = $2;
1018         }
1019         else {
1020             push @{ $flags->{plugins} }, $_;
1021         }
1022     }
1023
1024     $class->setup_home( delete $flags->{home} );
1025
1026     $class->setup_log( delete $flags->{log} );
1027     $class->setup_plugins( delete $flags->{plugins} );
1028     $class->setup_dispatcher( delete $flags->{dispatcher} );
1029     $class->setup_engine( delete $flags->{engine} );
1030     $class->setup_stats( delete $flags->{stats} );
1031
1032     for my $flag ( sort keys %{$flags} ) {
1033
1034         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1035             &$code( $class, delete $flags->{$flag} );
1036         }
1037         else {
1038             $class->log->warn(qq/Unknown flag "$flag"/);
1039         }
1040     }
1041
1042     eval { require Catalyst::Devel; };
1043     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1044         $class->log->warn(<<"EOF");
1045 You are running an old script!
1046
1047   Please update by running (this will overwrite existing files):
1048     catalyst.pl -force -scripts $class
1049
1050   or (this will not overwrite existing files):
1051     catalyst.pl -scripts $class
1052
1053 EOF
1054     }
1055
1056     if ( $class->debug ) {
1057         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1058
1059         if (@plugins) {
1060             my $column_width = Catalyst::Utils::term_width() - 6;
1061             my $t = Text::SimpleTable->new($column_width);
1062             $t->row($_) for @plugins;
1063             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1064         }
1065
1066         my $dispatcher = $class->dispatcher;
1067         my $engine     = $class->engine;
1068         my $home       = $class->config->{home};
1069
1070         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1071         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1072
1073         $home
1074           ? ( -d $home )
1075           ? $class->log->debug(qq/Found home "$home"/)
1076           : $class->log->debug(qq/Home "$home" doesn't exist/)
1077           : $class->log->debug(q/Couldn't find home/);
1078     }
1079
1080     # Call plugins setup, this is stupid and evil.
1081     # Also screws C3 badly on 5.10, hack to avoid.
1082     {
1083         no warnings qw/redefine/;
1084         local *setup = sub { };
1085         $class->setup unless $Catalyst::__AM_RESTARTING;
1086     }
1087
1088     # Initialize our data structure
1089     $class->components( {} );
1090
1091     $class->setup_components;
1092
1093     if ( $class->debug ) {
1094         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1095         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1096         for my $comp ( sort keys %{ $class->components } ) {
1097             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1098             $t->row( $comp, $type );
1099         }
1100         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1101           if ( keys %{ $class->components } );
1102     }
1103
1104     # Add our self to components, since we are also a component
1105     if( $class->isa('Catalyst::Controller') ){
1106       $class->components->{$class} = $class;
1107     }
1108
1109     $class->setup_actions;
1110
1111     if ( $class->debug ) {
1112         my $name = $class->config->{name} || 'Application';
1113         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1114     }
1115     $class->log->_flush() if $class->log->can('_flush');
1116
1117     # Make sure that the application class becomes immutable at this point,
1118     B::Hooks::EndOfScope::on_scope_end {
1119         return if $@;
1120         my $meta = Class::MOP::get_metaclass_by_name($class);
1121         if (
1122             $meta->is_immutable
1123             && ! { $meta->immutable_options }->{replace_constructor}
1124             && (
1125                    $class->isa('Class::Accessor::Fast')
1126                 || $class->isa('Class::Accessor')
1127             )
1128         ) {
1129             warn "You made your application class ($class) immutable, "
1130                 . "but did not inline the\nconstructor. "
1131                 . "This will break catalyst, as your app \@ISA "
1132                 . "Class::Accessor(::Fast)?\nPlease pass "
1133                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1134         }
1135         $meta->make_immutable(replace_constructor => 1)
1136             unless $meta->is_immutable;
1137     };
1138
1139     $class->setup_finalize;
1140 }
1141
1142
1143 =head2 $app->setup_finalize
1144
1145 A hook to attach modifiers to.
1146 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1147 Also better than C< setup_finished(); >, as that is a getter method.
1148
1149     sub setup_finalize {
1150
1151         my $app = shift;
1152
1153         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1154
1155         $app->next::method(@_);
1156
1157
1158     }
1159
1160 =cut
1161
1162 sub setup_finalize {
1163     my ($class) = @_;
1164     $class->setup_finished(1);
1165 }
1166
1167 =head2 $c->uri_for( $path, @args?, \%query_values? )
1168
1169 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1170
1171 Constructs an absolute L<URI> object based on the application root, the
1172 provided path, and the additional arguments and query parameters provided.
1173 When used as a string, provides a textual URI.
1174
1175 If the first argument is a string, it is taken as a public URI path relative
1176 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1177 relative to the application root (if it does). It is then merged with
1178 C<< $c->request->base >>; any C<@args> are appended as additional path
1179 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1180
1181 If the first argument is a L<Catalyst::Action> it represents an action which
1182 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1183 optional C<\@captures> argument (an arrayref) allows passing the captured
1184 variables that are needed to fill in the paths of Chained and Regex actions;
1185 once the path is resolved, C<uri_for> continues as though a path was
1186 provided, appending any arguments or parameters and creating an absolute
1187 URI.
1188
1189 The captures for the current request can be found in
1190 C<< $c->request->captures >>, and actions can be resolved using
1191 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1192 path, use C<< $c->uri_for_action >> instead.
1193
1194   # Equivalent to $c->req->uri
1195   $c->uri_for($c->action, $c->req->captures,
1196       @{ $c->req->args }, $c->req->params);
1197
1198   # For the Foo action in the Bar controller
1199   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1200
1201   # Path to a static resource
1202   $c->uri_for('/static/images/logo.png');
1203
1204 =cut
1205
1206 sub uri_for {
1207     my ( $c, $path, @args ) = @_;
1208
1209     if ( blessed($path) ) { # action object
1210         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1211                          ? shift(@args)
1212                          : [] );
1213         my $action = $path;
1214         $path = $c->dispatcher->uri_for_action($action, $captures);
1215         if (not defined $path) {
1216             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1217                 if $c->debug;
1218             return undef;
1219         }
1220         $path = '/' if $path eq '';
1221     }
1222
1223     undef($path) if (defined $path && $path eq '');
1224
1225     my $params =
1226       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1227
1228     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1229     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1230
1231     unshift(@args, $path);
1232
1233     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1234         my $namespace = $c->namespace;
1235         if (defined $path) { # cheesy hack to handle path '../foo'
1236            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1237         }
1238         unshift(@args, $namespace || '');
1239     }
1240
1241     # join args with '/', or a blank string
1242     my $args = join('/', grep { defined($_) } @args);
1243     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1244     $args =~ s!^/+!!;
1245     my $base = $c->req->base;
1246     my $class = ref($base);
1247     $base =~ s{(?<!/)$}{/};
1248
1249     my $query = '';
1250
1251     if (my @keys = keys %$params) {
1252       # somewhat lifted from URI::_query's query_form
1253       $query = '?'.join('&', map {
1254           my $val = $params->{$_};
1255           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1256           s/ /+/g;
1257           my $key = $_;
1258           $val = '' unless defined $val;
1259           (map {
1260               my $param = "$_";
1261               utf8::encode( $param ) if utf8::is_utf8($param);
1262               # using the URI::Escape pattern here so utf8 chars survive
1263               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1264               $param =~ s/ /+/g;
1265               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1266       } @keys);
1267     }
1268
1269     my $res = bless(\"${base}${args}${query}", $class);
1270     $res;
1271 }
1272
1273 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1274
1275 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1276
1277 =over
1278
1279 =item $path
1280
1281 A private path to the Catalyst action you want to create a URI for.
1282
1283 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1284 >> and passing the resulting C<$action> and the remaining arguments to C<<
1285 $c->uri_for >>.
1286
1287 You can also pass in a Catalyst::Action object, in which case it is passed to
1288 C<< $c->uri_for >>.
1289
1290 =back
1291
1292 =cut
1293
1294 sub uri_for_action {
1295     my ( $c, $path, @args ) = @_;
1296     my $action = blessed($path)
1297       ? $path
1298       : $c->dispatcher->get_action_by_path($path);
1299     unless (defined $action) {
1300       croak "Can't find action for path '$path'";
1301     }
1302     return $c->uri_for( $action, @args );
1303 }
1304
1305 =head2 $c->welcome_message
1306
1307 Returns the Catalyst welcome HTML page.
1308
1309 =cut
1310
1311 sub welcome_message {
1312     my $c      = shift;
1313     my $name   = $c->config->{name};
1314     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1315     my $prefix = Catalyst::Utils::appprefix( ref $c );
1316     $c->response->content_type('text/html; charset=utf-8');
1317     return <<"EOF";
1318 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1319     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1320 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1321     <head>
1322     <meta http-equiv="Content-Language" content="en" />
1323     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1324         <title>$name on Catalyst $VERSION</title>
1325         <style type="text/css">
1326             body {
1327                 color: #000;
1328                 background-color: #eee;
1329             }
1330             div#content {
1331                 width: 640px;
1332                 margin-left: auto;
1333                 margin-right: auto;
1334                 margin-top: 10px;
1335                 margin-bottom: 10px;
1336                 text-align: left;
1337                 background-color: #ccc;
1338                 border: 1px solid #aaa;
1339             }
1340             p, h1, h2 {
1341                 margin-left: 20px;
1342                 margin-right: 20px;
1343                 font-family: verdana, tahoma, sans-serif;
1344             }
1345             a {
1346                 font-family: verdana, tahoma, sans-serif;
1347             }
1348             :link, :visited {
1349                     text-decoration: none;
1350                     color: #b00;
1351                     border-bottom: 1px dotted #bbb;
1352             }
1353             :link:hover, :visited:hover {
1354                     color: #555;
1355             }
1356             div#topbar {
1357                 margin: 0px;
1358             }
1359             pre {
1360                 margin: 10px;
1361                 padding: 8px;
1362             }
1363             div#answers {
1364                 padding: 8px;
1365                 margin: 10px;
1366                 background-color: #fff;
1367                 border: 1px solid #aaa;
1368             }
1369             h1 {
1370                 font-size: 0.9em;
1371                 font-weight: normal;
1372                 text-align: center;
1373             }
1374             h2 {
1375                 font-size: 1.0em;
1376             }
1377             p {
1378                 font-size: 0.9em;
1379             }
1380             p img {
1381                 float: right;
1382                 margin-left: 10px;
1383             }
1384             span#appname {
1385                 font-weight: bold;
1386                 font-size: 1.6em;
1387             }
1388         </style>
1389     </head>
1390     <body>
1391         <div id="content">
1392             <div id="topbar">
1393                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1394                     $VERSION</h1>
1395              </div>
1396              <div id="answers">
1397                  <p>
1398                  <img src="$logo" alt="Catalyst Logo" />
1399                  </p>
1400                  <p>Welcome to the  world of Catalyst.
1401                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1402                     framework will make web development something you had
1403                     never expected it to be: Fun, rewarding, and quick.</p>
1404                  <h2>What to do now?</h2>
1405                  <p>That really depends  on what <b>you</b> want to do.
1406                     We do, however, provide you with a few starting points.</p>
1407                  <p>If you want to jump right into web development with Catalyst
1408                     you might want to start with a tutorial.</p>
1409 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1410 </pre>
1411 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1412 <pre>
1413 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1414 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1415 </code></pre>
1416                  <h2>What to do next?</h2>
1417                  <p>Next it's time to write an actual application. Use the
1418                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1419                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1420                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1421                     they can save you a lot of work.</p>
1422                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1423                     <p>Also, be sure to check out the vast and growing
1424                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1425                     you are likely to find what you need there.
1426                     </p>
1427
1428                  <h2>Need help?</h2>
1429                  <p>Catalyst has a very active community. Here are the main places to
1430                     get in touch with us.</p>
1431                  <ul>
1432                      <li>
1433                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1434                      </li>
1435                      <li>
1436                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1437                      </li>
1438                      <li>
1439                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1440                      </li>
1441                  </ul>
1442                  <h2>In conclusion</h2>
1443                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1444                     as we enjoyed making it. Please contact us if you have ideas
1445                     for improvement or other feedback.</p>
1446              </div>
1447          </div>
1448     </body>
1449 </html>
1450 EOF
1451 }
1452
1453 =head1 INTERNAL METHODS
1454
1455 These methods are not meant to be used by end users.
1456
1457 =head2 $c->components
1458
1459 Returns a hash of components.
1460
1461 =head2 $c->context_class
1462
1463 Returns or sets the context class.
1464
1465 =head2 $c->counter
1466
1467 Returns a hashref containing coderefs and execution counts (needed for
1468 deep recursion detection).
1469
1470 =head2 $c->depth
1471
1472 Returns the number of actions on the current internal execution stack.
1473
1474 =head2 $c->dispatch
1475
1476 Dispatches a request to actions.
1477
1478 =cut
1479
1480 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1481
1482 =head2 $c->dispatcher_class
1483
1484 Returns or sets the dispatcher class.
1485
1486 =head2 $c->dump_these
1487
1488 Returns a list of 2-element array references (name, structure) pairs
1489 that will be dumped on the error page in debug mode.
1490
1491 =cut
1492
1493 sub dump_these {
1494     my $c = shift;
1495     [ Request => $c->req ],
1496     [ Response => $c->res ],
1497     [ Stash => $c->stash ],
1498     [ Config => $c->config ];
1499 }
1500
1501 =head2 $c->engine_class
1502
1503 Returns or sets the engine class.
1504
1505 =head2 $c->execute( $class, $coderef )
1506
1507 Execute a coderef in given class and catch exceptions. Errors are available
1508 via $c->error.
1509
1510 =cut
1511
1512 sub execute {
1513     my ( $c, $class, $code ) = @_;
1514     $class = $c->component($class) || $class;
1515     $c->state(0);
1516
1517     if ( $c->depth >= $RECURSION ) {
1518         my $action = $code->reverse();
1519         $action = "/$action" unless $action =~ /->/;
1520         my $error = qq/Deep recursion detected calling "${action}"/;
1521         $c->log->error($error);
1522         $c->error($error);
1523         $c->state(0);
1524         return $c->state;
1525     }
1526
1527     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1528
1529     push( @{ $c->stack }, $code );
1530
1531     no warnings 'recursion';
1532     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1533
1534     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1535
1536     my $last = pop( @{ $c->stack } );
1537
1538     if ( my $error = $@ ) {
1539         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1540             $error->rethrow if $c->depth > 1;
1541         }
1542         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1543             $error->rethrow if $c->depth > 0;
1544         }
1545         else {
1546             unless ( ref $error ) {
1547                 no warnings 'uninitialized';
1548                 chomp $error;
1549                 my $class = $last->class;
1550                 my $name  = $last->name;
1551                 $error = qq/Caught exception in $class->$name "$error"/;
1552             }
1553             $c->error($error);
1554             $c->state(0);
1555         }
1556     }
1557     return $c->state;
1558 }
1559
1560 sub _stats_start_execute {
1561     my ( $c, $code ) = @_;
1562
1563     return if ( ( $code->name =~ /^_.*/ )
1564         && ( !$c->config->{show_internal_actions} ) );
1565
1566     my $action_name = $code->reverse();
1567     $c->counter->{$action_name}++;
1568
1569     my $action = $action_name;
1570     $action = "/$action" unless $action =~ /->/;
1571
1572     # determine if the call was the result of a forward
1573     # this is done by walking up the call stack and looking for a calling
1574     # sub of Catalyst::forward before the eval
1575     my $callsub = q{};
1576     for my $index ( 2 .. 11 ) {
1577         last
1578         if ( ( caller($index) )[0] eq 'Catalyst'
1579             && ( caller($index) )[3] eq '(eval)' );
1580
1581         if ( ( caller($index) )[3] =~ /forward$/ ) {
1582             $callsub = ( caller($index) )[3];
1583             $action  = "-> $action";
1584             last;
1585         }
1586     }
1587
1588     my $uid = $action_name . $c->counter->{$action_name};
1589
1590     # is this a root-level call or a forwarded call?
1591     if ( $callsub =~ /forward$/ ) {
1592
1593         # forward, locate the caller
1594         if ( my $parent = $c->stack->[-1] ) {
1595             $c->stats->profile(
1596                 begin  => $action,
1597                 parent => "$parent" . $c->counter->{"$parent"},
1598                 uid    => $uid,
1599             );
1600         }
1601         else {
1602
1603             # forward with no caller may come from a plugin
1604             $c->stats->profile(
1605                 begin => $action,
1606                 uid   => $uid,
1607             );
1608         }
1609     }
1610     else {
1611
1612         # root-level call
1613         $c->stats->profile(
1614             begin => $action,
1615             uid   => $uid,
1616         );
1617     }
1618     return $action;
1619
1620 }
1621
1622 sub _stats_finish_execute {
1623     my ( $c, $info ) = @_;
1624     $c->stats->profile( end => $info );
1625 }
1626
1627 =head2 $c->finalize
1628
1629 Finalizes the request.
1630
1631 =cut
1632
1633 sub finalize {
1634     my $c = shift;
1635
1636     for my $error ( @{ $c->error } ) {
1637         $c->log->error($error);
1638     }
1639
1640     # Allow engine to handle finalize flow (for POE)
1641     my $engine = $c->engine;
1642     if ( my $code = $engine->can('finalize') ) {
1643         $engine->$code($c);
1644     }
1645     else {
1646
1647         $c->finalize_uploads;
1648
1649         # Error
1650         if ( $#{ $c->error } >= 0 ) {
1651             $c->finalize_error;
1652         }
1653
1654         $c->finalize_headers;
1655
1656         # HEAD request
1657         if ( $c->request->method eq 'HEAD' ) {
1658             $c->response->body('');
1659         }
1660
1661         $c->finalize_body;
1662     }
1663
1664     if ($c->use_stats) {
1665         my $elapsed = sprintf '%f', $c->stats->elapsed;
1666         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1667         $c->log->info(
1668             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1669     }
1670
1671     return $c->response->status;
1672 }
1673
1674 =head2 $c->finalize_body
1675
1676 Finalizes body.
1677
1678 =cut
1679
1680 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1681
1682 =head2 $c->finalize_cookies
1683
1684 Finalizes cookies.
1685
1686 =cut
1687
1688 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1689
1690 =head2 $c->finalize_error
1691
1692 Finalizes error.
1693
1694 =cut
1695
1696 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1697
1698 =head2 $c->finalize_headers
1699
1700 Finalizes headers.
1701
1702 =cut
1703
1704 sub finalize_headers {
1705     my $c = shift;
1706
1707     my $response = $c->response; #accessor calls can add up?
1708
1709     # Check if we already finalized headers
1710     return if $response->finalized_headers;
1711
1712     # Handle redirects
1713     if ( my $location = $response->redirect ) {
1714         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1715         $response->header( Location => $location );
1716
1717         if ( !$response->has_body ) {
1718             # Add a default body if none is already present
1719             $response->body(
1720                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1721             );
1722         }
1723     }
1724
1725     # Content-Length
1726     if ( $response->body && !$response->content_length ) {
1727
1728         # get the length from a filehandle
1729         if ( blessed( $response->body ) && $response->body->can('read') )
1730         {
1731             my $stat = stat $response->body;
1732             if ( $stat && $stat->size > 0 ) {
1733                 $response->content_length( $stat->size );
1734             }
1735             else {
1736                 $c->log->warn('Serving filehandle without a content-length');
1737             }
1738         }
1739         else {
1740             # everything should be bytes at this point, but just in case
1741             $response->content_length( bytes::length( $response->body ) );
1742         }
1743     }
1744
1745     # Errors
1746     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1747         $response->headers->remove_header("Content-Length");
1748         $response->body('');
1749     }
1750
1751     $c->finalize_cookies;
1752
1753     $c->engine->finalize_headers( $c, @_ );
1754
1755     # Done
1756     $response->finalized_headers(1);
1757 }
1758
1759 =head2 $c->finalize_output
1760
1761 An alias for finalize_body.
1762
1763 =head2 $c->finalize_read
1764
1765 Finalizes the input after reading is complete.
1766
1767 =cut
1768
1769 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1770
1771 =head2 $c->finalize_uploads
1772
1773 Finalizes uploads. Cleans up any temporary files.
1774
1775 =cut
1776
1777 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1778
1779 =head2 $c->get_action( $action, $namespace )
1780
1781 Gets an action in a given namespace.
1782
1783 =cut
1784
1785 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1786
1787 =head2 $c->get_actions( $action, $namespace )
1788
1789 Gets all actions of a given name in a namespace and all parent
1790 namespaces.
1791
1792 =cut
1793
1794 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1795
1796 =head2 $c->handle_request( $class, @arguments )
1797
1798 Called to handle each HTTP request.
1799
1800 =cut
1801
1802 sub handle_request {
1803     my ( $class, @arguments ) = @_;
1804
1805     # Always expect worst case!
1806     my $status = -1;
1807     eval {
1808         if ($class->debug) {
1809             my $secs = time - $START || 1;
1810             my $av = sprintf '%.3f', $COUNT / $secs;
1811             my $time = localtime time;
1812             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1813         }
1814
1815         my $c = $class->prepare(@arguments);
1816         $c->dispatch;
1817         $status = $c->finalize;
1818     };
1819
1820     if ( my $error = $@ ) {
1821         chomp $error;
1822         $class->log->error(qq/Caught exception in engine "$error"/);
1823     }
1824
1825     $COUNT++;
1826
1827     if(my $coderef = $class->log->can('_flush')){
1828         $class->log->$coderef();
1829     }
1830     return $status;
1831 }
1832
1833 =head2 $c->prepare( @arguments )
1834
1835 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1836 etc.).
1837
1838 =cut
1839
1840 sub prepare {
1841     my ( $class, @arguments ) = @_;
1842
1843     # XXX
1844     # After the app/ctxt split, this should become an attribute based on something passed
1845     # into the application.
1846     $class->context_class( ref $class || $class ) unless $class->context_class;
1847
1848     my $c = $class->context_class->new({});
1849
1850     # For on-demand data
1851     $c->request->_context($c);
1852     $c->response->_context($c);
1853
1854     #surely this is not the most efficient way to do things...
1855     $c->stats($class->stats_class->new)->enable($c->use_stats);
1856     if ( $c->debug ) {
1857         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1858     }
1859
1860     #XXX reuse coderef from can
1861     # Allow engine to direct the prepare flow (for POE)
1862     if ( $c->engine->can('prepare') ) {
1863         $c->engine->prepare( $c, @arguments );
1864     }
1865     else {
1866         $c->prepare_request(@arguments);
1867         $c->prepare_connection;
1868         $c->prepare_query_parameters;
1869         $c->prepare_headers;
1870         $c->prepare_cookies;
1871         $c->prepare_path;
1872
1873         # Prepare the body for reading, either by prepare_body
1874         # or the user, if they are using $c->read
1875         $c->prepare_read;
1876
1877         # Parse the body unless the user wants it on-demand
1878         unless ( $c->config->{parse_on_demand} ) {
1879             $c->prepare_body;
1880         }
1881     }
1882
1883     my $method  = $c->req->method  || '';
1884     my $path    = $c->req->path;
1885     $path       = '/' unless length $path;
1886     my $address = $c->req->address || '';
1887
1888     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1889       if $c->debug;
1890
1891     $c->prepare_action;
1892
1893     return $c;
1894 }
1895
1896 =head2 $c->prepare_action
1897
1898 Prepares action. See L<Catalyst::Dispatcher>.
1899
1900 =cut
1901
1902 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1903
1904 =head2 $c->prepare_body
1905
1906 Prepares message body.
1907
1908 =cut
1909
1910 sub prepare_body {
1911     my $c = shift;
1912
1913     return if $c->request->_has_body;
1914
1915     # Initialize on-demand data
1916     $c->engine->prepare_body( $c, @_ );
1917     $c->prepare_parameters;
1918     $c->prepare_uploads;
1919
1920     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1921         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1922         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1923             my $param = $c->req->body_parameters->{$key};
1924             my $value = defined($param) ? $param : '';
1925             $t->row( $key,
1926                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1927         }
1928         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1929     }
1930 }
1931
1932 =head2 $c->prepare_body_chunk( $chunk )
1933
1934 Prepares a chunk of data before sending it to L<HTTP::Body>.
1935
1936 See L<Catalyst::Engine>.
1937
1938 =cut
1939
1940 sub prepare_body_chunk {
1941     my $c = shift;
1942     $c->engine->prepare_body_chunk( $c, @_ );
1943 }
1944
1945 =head2 $c->prepare_body_parameters
1946
1947 Prepares body parameters.
1948
1949 =cut
1950
1951 sub prepare_body_parameters {
1952     my $c = shift;
1953     $c->engine->prepare_body_parameters( $c, @_ );
1954 }
1955
1956 =head2 $c->prepare_connection
1957
1958 Prepares connection.
1959
1960 =cut
1961
1962 sub prepare_connection {
1963     my $c = shift;
1964     $c->engine->prepare_connection( $c, @_ );
1965 }
1966
1967 =head2 $c->prepare_cookies
1968
1969 Prepares cookies.
1970
1971 =cut
1972
1973 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1974
1975 =head2 $c->prepare_headers
1976
1977 Prepares headers.
1978
1979 =cut
1980
1981 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1982
1983 =head2 $c->prepare_parameters
1984
1985 Prepares parameters.
1986
1987 =cut
1988
1989 sub prepare_parameters {
1990     my $c = shift;
1991     $c->prepare_body_parameters;
1992     $c->engine->prepare_parameters( $c, @_ );
1993 }
1994
1995 =head2 $c->prepare_path
1996
1997 Prepares path and base.
1998
1999 =cut
2000
2001 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2002
2003 =head2 $c->prepare_query_parameters
2004
2005 Prepares query parameters.
2006
2007 =cut
2008
2009 sub prepare_query_parameters {
2010     my $c = shift;
2011
2012     $c->engine->prepare_query_parameters( $c, @_ );
2013
2014     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
2015         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
2016         for my $key ( sort keys %{ $c->req->query_parameters } ) {
2017             my $param = $c->req->query_parameters->{$key};
2018             my $value = defined($param) ? $param : '';
2019             $t->row( $key,
2020                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2021         }
2022         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2023     }
2024 }
2025
2026 =head2 $c->prepare_read
2027
2028 Prepares the input for reading.
2029
2030 =cut
2031
2032 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2033
2034 =head2 $c->prepare_request
2035
2036 Prepares the engine request.
2037
2038 =cut
2039
2040 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2041
2042 =head2 $c->prepare_uploads
2043
2044 Prepares uploads.
2045
2046 =cut
2047
2048 sub prepare_uploads {
2049     my $c = shift;
2050
2051     $c->engine->prepare_uploads( $c, @_ );
2052
2053     if ( $c->debug && keys %{ $c->request->uploads } ) {
2054         my $t = Text::SimpleTable->new(
2055             [ 12, 'Parameter' ],
2056             [ 26, 'Filename' ],
2057             [ 18, 'Type' ],
2058             [ 9,  'Size' ]
2059         );
2060         for my $key ( sort keys %{ $c->request->uploads } ) {
2061             my $upload = $c->request->uploads->{$key};
2062             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2063                 $t->row( $key, $u->filename, $u->type, $u->size );
2064             }
2065         }
2066         $c->log->debug( "File Uploads are:\n" . $t->draw );
2067     }
2068 }
2069
2070 =head2 $c->prepare_write
2071
2072 Prepares the output for writing.
2073
2074 =cut
2075
2076 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2077
2078 =head2 $c->request_class
2079
2080 Returns or sets the request class.
2081
2082 =head2 $c->response_class
2083
2084 Returns or sets the response class.
2085
2086 =head2 $c->read( [$maxlength] )
2087
2088 Reads a chunk of data from the request body. This method is designed to
2089 be used in a while loop, reading C<$maxlength> bytes on every call.
2090 C<$maxlength> defaults to the size of the request if not specified.
2091
2092 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2093 directly.
2094
2095 Warning: If you use read(), Catalyst will not process the body,
2096 so you will not be able to access POST parameters or file uploads via
2097 $c->request.  You must handle all body parsing yourself.
2098
2099 =cut
2100
2101 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2102
2103 =head2 $c->run
2104
2105 Starts the engine.
2106
2107 =cut
2108
2109 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2110
2111 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2112
2113 Sets an action in a given namespace.
2114
2115 =cut
2116
2117 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2118
2119 =head2 $c->setup_actions($component)
2120
2121 Sets up actions for a component.
2122
2123 =cut
2124
2125 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2126
2127 =head2 $c->setup_components
2128
2129 Sets up components. Specify a C<setup_components> config option to pass
2130 additional options directly to L<Module::Pluggable>. To add additional
2131 search paths, specify a key named C<search_extra> as an array
2132 reference. Items in the array beginning with C<::> will have the
2133 application class name prepended to them.
2134
2135 All components found will also have any
2136 L<inner packages|Devel::InnerPackage> loaded and set up as components.
2137 Note, that modules which are B<not> an I<inner package> of the main
2138 file namespace loaded will not be instantiated as components.
2139
2140 =cut
2141
2142 sub setup_components {
2143     my $class = shift;
2144
2145     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2146     my $config  = $class->config->{ setup_components };
2147     my $extra   = delete $config->{ search_extra } || [];
2148
2149     push @paths, @$extra;
2150
2151     my $locator = Module::Pluggable::Object->new(
2152         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2153         %$config
2154     );
2155
2156     my @comps = sort { length $a <=> length $b } $locator->plugins;
2157     my %comps = map { $_ => 1 } @comps;
2158
2159     my $deprecated_component_names = grep { /::[CMV]::/ } @comps;
2160     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2161         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2162     ) if $deprecated_component_names;
2163
2164     for my $component ( @comps ) {
2165
2166         # We pass ignore_loaded here so that overlay files for (e.g.)
2167         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2168         # we know M::P::O found a file on disk so this is safe
2169
2170         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2171         #Class::MOP::load_class($component);
2172
2173         my $module  = $class->setup_component( $component );
2174         my %modules = (
2175             $component => $module,
2176             map {
2177                 $_ => $class->setup_component( $_ )
2178             } grep {
2179               not exists $comps{$_}
2180             } Devel::InnerPackage::list_packages( $component )
2181         );
2182
2183         for my $key ( keys %modules ) {
2184             $class->components->{ $key } = $modules{ $key };
2185         }
2186     }
2187 }
2188
2189 =head2 $c->setup_component
2190
2191 =cut
2192
2193 sub _controller_init_base_classes {
2194     my ($app_class, $component) = @_;
2195     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2196         Moose::Meta::Class->initialize( $class )
2197             unless find_meta($class);
2198     }
2199 }
2200
2201 sub setup_component {
2202     my( $class, $component ) = @_;
2203
2204     unless ( $component->can( 'COMPONENT' ) ) {
2205         return $component;
2206     }
2207
2208     # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2209     #         nearest to Catalyst::Controller first, no matter what order stuff happens
2210     #         to be loaded. There are TODO tests in Moose for this, see
2211     #         f2391d17574eff81d911b97be15ea51080500003
2212     if ($component->isa('Catalyst::Controller')) {
2213         $class->_controller_init_base_classes($component);
2214     }
2215
2216     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2217     my $config = $class->config->{ $suffix } || {};
2218
2219     my $instance = eval { $component->COMPONENT( $class, $config ); };
2220
2221     if ( my $error = $@ ) {
2222         chomp $error;
2223         Catalyst::Exception->throw(
2224             message => qq/Couldn't instantiate component "$component", "$error"/
2225         );
2226     }
2227
2228     unless (blessed $instance) {
2229         my $metaclass = Moose::Util::find_meta($component);
2230         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2231         my $component_method_from = $method_meta->associated_metaclass->name;
2232         my $value = defined($instance) ? $instance : 'undef';
2233         Catalyst::Exception->throw(
2234             message =>
2235             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2236         );
2237     }
2238     return $instance;
2239 }
2240
2241 =head2 $c->setup_dispatcher
2242
2243 Sets up dispatcher.
2244
2245 =cut
2246
2247 sub setup_dispatcher {
2248     my ( $class, $dispatcher ) = @_;
2249
2250     if ($dispatcher) {
2251         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2252     }
2253
2254     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2255         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2256     }
2257
2258     unless ($dispatcher) {
2259         $dispatcher = $class->dispatcher_class;
2260     }
2261
2262     Class::MOP::load_class($dispatcher);
2263
2264     # dispatcher instance
2265     $class->dispatcher( $dispatcher->new );
2266 }
2267
2268 =head2 $c->setup_engine
2269
2270 Sets up engine.
2271
2272 =cut
2273
2274 sub setup_engine {
2275     my ( $class, $engine ) = @_;
2276
2277     if ($engine) {
2278         $engine = 'Catalyst::Engine::' . $engine;
2279     }
2280
2281     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2282         $engine = 'Catalyst::Engine::' . $env;
2283     }
2284
2285     if ( $ENV{MOD_PERL} ) {
2286         my $meta = Class::MOP::get_metaclass_by_name($class);
2287
2288         # create the apache method
2289         $meta->add_method('apache' => sub { shift->engine->apache });
2290
2291         my ( $software, $version ) =
2292           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2293
2294         $version =~ s/_//g;
2295         $version =~ s/(\.[^.]+)\./$1/g;
2296
2297         if ( $software eq 'mod_perl' ) {
2298
2299             if ( !$engine ) {
2300
2301                 if ( $version >= 1.99922 ) {
2302                     $engine = 'Catalyst::Engine::Apache2::MP20';
2303                 }
2304
2305                 elsif ( $version >= 1.9901 ) {
2306                     $engine = 'Catalyst::Engine::Apache2::MP19';
2307                 }
2308
2309                 elsif ( $version >= 1.24 ) {
2310                     $engine = 'Catalyst::Engine::Apache::MP13';
2311                 }
2312
2313                 else {
2314                     Catalyst::Exception->throw( message =>
2315                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2316                 }
2317
2318             }
2319
2320             # install the correct mod_perl handler
2321             if ( $version >= 1.9901 ) {
2322                 *handler = sub  : method {
2323                     shift->handle_request(@_);
2324                 };
2325             }
2326             else {
2327                 *handler = sub ($$) { shift->handle_request(@_) };
2328             }
2329
2330         }
2331
2332         elsif ( $software eq 'Zeus-Perl' ) {
2333             $engine = 'Catalyst::Engine::Zeus';
2334         }
2335
2336         else {
2337             Catalyst::Exception->throw(
2338                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2339         }
2340     }
2341
2342     unless ($engine) {
2343         $engine = $class->engine_class;
2344     }
2345
2346     Class::MOP::load_class($engine);
2347
2348     # check for old engines that are no longer compatible
2349     my $old_engine;
2350     if ( $engine->isa('Catalyst::Engine::Apache')
2351         && !Catalyst::Engine::Apache->VERSION )
2352     {
2353         $old_engine = 1;
2354     }
2355
2356     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2357         && Catalyst::Engine::Server->VERSION le '0.02' )
2358     {
2359         $old_engine = 1;
2360     }
2361
2362     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2363         && $engine->VERSION eq '0.01' )
2364     {
2365         $old_engine = 1;
2366     }
2367
2368     elsif ($engine->isa('Catalyst::Engine::Zeus')
2369         && $engine->VERSION eq '0.01' )
2370     {
2371         $old_engine = 1;
2372     }
2373
2374     if ($old_engine) {
2375         Catalyst::Exception->throw( message =>
2376               qq/Engine "$engine" is not supported by this version of Catalyst/
2377         );
2378     }
2379
2380     # engine instance
2381     $class->engine( $engine->new );
2382 }
2383
2384 =head2 $c->setup_home
2385
2386 Sets up the home directory.
2387
2388 =cut
2389
2390 sub setup_home {
2391     my ( $class, $home ) = @_;
2392
2393     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2394         $home = $env;
2395     }
2396
2397     $home ||= Catalyst::Utils::home($class);
2398
2399     if ($home) {
2400         #I remember recently being scolded for assigning config values like this
2401         $class->config->{home} ||= $home;
2402         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2403     }
2404 }
2405
2406 =head2 $c->setup_log
2407
2408 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2409 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2410 log to.
2411
2412 This method also installs a C<debug> method that returns a true value into the
2413 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2414 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2415
2416 Note that if the log has already been setup, by either a previous call to
2417 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2418 that this method won't actually set up the log object.
2419
2420 =cut
2421
2422 sub setup_log {
2423     my ( $class, $levels ) = @_;
2424
2425     $levels ||= '';
2426     $levels =~ s/^\s+//;
2427     $levels =~ s/\s+$//;
2428     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2429
2430     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2431     if ( defined $env_debug ) {
2432         $levels{debug} = 1 if $env_debug; # Ugly!
2433         delete($levels{debug}) unless $env_debug;
2434     }
2435
2436     unless ( $class->log ) {
2437         $class->log( Catalyst::Log->new(keys %levels) );
2438     }
2439
2440     if ( $levels{debug} ) {
2441         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2442         $class->log->debug('Debug messages enabled');
2443     }
2444 }
2445
2446 =head2 $c->setup_plugins
2447
2448 Sets up plugins.
2449
2450 =cut
2451
2452 =head2 $c->setup_stats
2453
2454 Sets up timing statistics class.
2455
2456 =cut
2457
2458 sub setup_stats {
2459     my ( $class, $stats ) = @_;
2460
2461     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2462
2463     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2464     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2465         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2466         $class->log->debug('Statistics enabled');
2467     }
2468 }
2469
2470
2471 =head2 $c->registered_plugins
2472
2473 Returns a sorted list of the plugins which have either been stated in the
2474 import list or which have been added via C<< MyApp->plugin(@args); >>.
2475
2476 If passed a given plugin name, it will report a boolean value indicating
2477 whether or not that plugin is loaded.  A fully qualified name is required if
2478 the plugin name does not begin with C<Catalyst::Plugin::>.
2479
2480  if ($c->registered_plugins('Some::Plugin')) {
2481      ...
2482  }
2483
2484 =cut
2485
2486 {
2487
2488     sub registered_plugins {
2489         my $proto = shift;
2490         return sort keys %{ $proto->_plugins } unless @_;
2491         my $plugin = shift;
2492         return 1 if exists $proto->_plugins->{$plugin};
2493         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2494     }
2495
2496     sub _register_plugin {
2497         my ( $proto, $plugin, $instant ) = @_;
2498         my $class = ref $proto || $proto;
2499
2500         Class::MOP::load_class( $plugin );
2501
2502         $proto->_plugins->{$plugin} = 1;
2503         unless ($instant) {
2504             no strict 'refs';
2505             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2506               my @superclasses = ($plugin, $meta->superclasses );
2507               $meta->superclasses(@superclasses);
2508             } else {
2509               unshift @{"$class\::ISA"}, $plugin;
2510             }
2511         }
2512         return $class;
2513     }
2514
2515     sub setup_plugins {
2516         my ( $class, $plugins ) = @_;
2517
2518         $class->_plugins( {} ) unless $class->_plugins;
2519         $plugins ||= [];
2520
2521         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2522
2523         for my $plugin ( reverse @plugins ) {
2524             Class::MOP::load_class($plugin);
2525             my $meta = find_meta($plugin);
2526             next if $meta && $meta->isa('Moose::Meta::Role');
2527
2528             $class->_register_plugin($plugin);
2529         }
2530
2531         my @roles =
2532             map { $_->name }
2533             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2534             map { find_meta($_) }
2535             @plugins;
2536
2537         Moose::Util::apply_all_roles(
2538             $class => @roles
2539         ) if @roles;
2540     }
2541 }
2542
2543 =head2 $c->stack
2544
2545 Returns an arrayref of the internal execution stack (actions that are
2546 currently executing).
2547
2548 =head2 $c->stats_class
2549
2550 Returns or sets the stats (timing statistics) class.
2551
2552 =head2 $c->use_stats
2553
2554 Returns 1 when stats collection is enabled.  Stats collection is enabled
2555 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2556 environment variable is set.
2557
2558 Note that this is a static method, not an accessor and should be overridden
2559 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2560
2561 =cut
2562
2563 sub use_stats { 0 }
2564
2565
2566 =head2 $c->write( $data )
2567
2568 Writes $data to the output stream. When using this method directly, you
2569 will need to manually set the C<Content-Length> header to the length of
2570 your output data, if known.
2571
2572 =cut
2573
2574 sub write {
2575     my $c = shift;
2576
2577     # Finalize headers if someone manually writes output
2578     $c->finalize_headers;
2579
2580     return $c->engine->write( $c, @_ );
2581 }
2582
2583 =head2 version
2584
2585 Returns the Catalyst version number. Mostly useful for "powered by"
2586 messages in template systems.
2587
2588 =cut
2589
2590 sub version { return $Catalyst::VERSION }
2591
2592 =head1 INTERNAL ACTIONS
2593
2594 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2595 C<_ACTION>, and C<_END>. These are by default not shown in the private
2596 action table, but you can make them visible with a config parameter.
2597
2598     MyApp->config(show_internal_actions => 1);
2599
2600 =head1 CASE SENSITIVITY
2601
2602 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2603 mapped to C</foo/bar>. You can activate case sensitivity with a config
2604 parameter.
2605
2606     MyApp->config(case_sensitive => 1);
2607
2608 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2609
2610 =head1 ON-DEMAND PARSER
2611
2612 The request body is usually parsed at the beginning of a request,
2613 but if you want to handle input yourself, you can enable on-demand
2614 parsing with a config parameter.
2615
2616     MyApp->config(parse_on_demand => 1);
2617
2618 =head1 PROXY SUPPORT
2619
2620 Many production servers operate using the common double-server approach,
2621 with a lightweight frontend web server passing requests to a larger
2622 backend server. An application running on the backend server must deal
2623 with two problems: the remote user always appears to be C<127.0.0.1> and
2624 the server's hostname will appear to be C<localhost> regardless of the
2625 virtual host that the user connected through.
2626
2627 Catalyst will automatically detect this situation when you are running
2628 the frontend and backend servers on the same machine. The following
2629 changes are made to the request.
2630
2631     $c->req->address is set to the user's real IP address, as read from
2632     the HTTP X-Forwarded-For header.
2633
2634     The host value for $c->req->base and $c->req->uri is set to the real
2635     host, as read from the HTTP X-Forwarded-Host header.
2636
2637 Obviously, your web server must support these headers for this to work.
2638
2639 In a more complex server farm environment where you may have your
2640 frontend proxy server(s) on different machines, you will need to set a
2641 configuration option to tell Catalyst to read the proxied data from the
2642 headers.
2643
2644     MyApp->config(using_frontend_proxy => 1);
2645
2646 If you do not wish to use the proxy support at all, you may set:
2647
2648     MyApp->config(ignore_frontend_proxy => 1);
2649
2650 =head1 THREAD SAFETY
2651
2652 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2653 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2654 believe the Catalyst core to be thread-safe.
2655
2656 If you plan to operate in a threaded environment, remember that all other
2657 modules you are using must also be thread-safe. Some modules, most notably
2658 L<DBD::SQLite>, are not thread-safe.
2659
2660 =head1 SUPPORT
2661
2662 IRC:
2663
2664     Join #catalyst on irc.perl.org.
2665
2666 Mailing Lists:
2667
2668     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2669     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2670
2671 Web:
2672
2673     http://catalyst.perl.org
2674
2675 Wiki:
2676
2677     http://dev.catalyst.perl.org
2678
2679 =head1 SEE ALSO
2680
2681 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2682
2683 =head2 L<Catalyst::Manual> - The Catalyst Manual
2684
2685 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2686
2687 =head2 L<Catalyst::Engine> - Core engine
2688
2689 =head2 L<Catalyst::Log> - Log class.
2690
2691 =head2 L<Catalyst::Request> - Request object
2692
2693 =head2 L<Catalyst::Response> - Response object
2694
2695 =head2 L<Catalyst::Test> - The test suite.
2696
2697 =head1 PROJECT FOUNDER
2698
2699 sri: Sebastian Riedel <sri@cpan.org>
2700
2701 =head1 CONTRIBUTORS
2702
2703 abw: Andy Wardley
2704
2705 acme: Leon Brocard <leon@astray.com>
2706
2707 Andrew Bramble
2708
2709 Andrew Ford
2710
2711 Andrew Ruthven
2712
2713 andyg: Andy Grundman <andy@hybridized.org>
2714
2715 audreyt: Audrey Tang
2716
2717 bricas: Brian Cassidy <bricas@cpan.org>
2718
2719 Caelum: Rafael Kitover <rkitover@io.com>
2720
2721 chansen: Christian Hansen
2722
2723 chicks: Christopher Hicks
2724
2725 David E. Wheeler
2726
2727 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2728
2729 Drew Taylor
2730
2731 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2732
2733 esskar: Sascha Kiefer
2734
2735 fireartist: Carl Franks <cfranks@cpan.org>
2736
2737 gabb: Danijel Milicevic
2738
2739 Gary Ashton Jones
2740
2741 Geoff Richards
2742
2743 hobbs: Andrew Rodland <andrew@cleverdomain.org>
2744
2745 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2746
2747 jcamacho: Juan Camacho
2748
2749 jester: Jesse Sheidlower
2750
2751 jhannah: Jay Hannah <jay@jays.net>
2752
2753 Jody Belka
2754
2755 Johan Lindstrom
2756
2757 jon: Jon Schutz <jjschutz@cpan.org>
2758
2759 marcus: Marcus Ramberg <mramberg@cpan.org>
2760
2761 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2762
2763 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2764
2765 mugwump: Sam Vilain
2766
2767 naughton: David Naughton
2768
2769 ningu: David Kamholz <dkamholz@cpan.org>
2770
2771 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2772
2773 numa: Dan Sully <daniel@cpan.org>
2774
2775 obra: Jesse Vincent
2776
2777 omega: Andreas Marienborg
2778
2779 Oleg Kostyuk <cub.uanic@gmail.com>
2780
2781 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2782
2783 rafl: Florian Ragwitz <rafl@debian.org>
2784
2785 random: Roland Lammel <lammel@cpan.org>
2786
2787 sky: Arthur Bergman
2788
2789 t0m: Tomas Doran <bobtfish@bobtfish.net>
2790
2791 Ulf Edvinsson
2792
2793 willert: Sebastian Willert <willert@cpan.org>
2794
2795 =head1 LICENSE
2796
2797 This library is free software. You can redistribute it and/or modify it under
2798 the same terms as Perl itself.
2799
2800 =cut
2801
2802 no Moose;
2803
2804 __PACKAGE__->meta->make_immutable;
2805
2806 1;