lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use bytes;
   8 use B::Hooks::EndOfScope ();
   9 use Catalyst::Exception;
  10 use Catalyst::Exception::Detach;
  11 use Catalyst::Exception::Go;
  12 use Catalyst::Log;
  13 use Catalyst::Request;
  14 use Catalyst::Request::Upload;
  15 use Catalyst::Response;
  16 use Catalyst::Utils;
  17 use Catalyst::Controller;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80013';
  83
  84 {
  85     my $dev_version = $VERSION =~ /_\d{2}$/;
  86     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  87 }
  88
  89 $VERSION = eval $VERSION;
  90
  91 sub import {
  92     my ( $class, @arguments ) = @_;
  93
  94     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  95     # callers @ISA.
  96     return unless $class eq 'Catalyst';
  97
  98     my $caller = caller();
  99     return if $caller eq 'main';
 100
 101     # Kill Adopt::NEXT warnings if we're a non-RC version
 102     unless (_IS_DEVELOPMENT_VERSION()) {
 103         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 104     }
 105
 106     my $meta = Moose::Meta::Class->initialize($caller);
 107     unless ( $caller->isa('Catalyst') ) {
 108         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 109         $meta->superclasses(@superclasses);
 110     }
 111     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 112     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 113
 114     unless( $meta->has_method('meta') ){
 115         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 116     }
 117
 118     $caller->arguments( [@arguments] );
 119     $caller->setup_home;
 120 }
 121
 122 sub _application { $_[0] }
 123
 124 =head1 NAME
 125
 126 Catalyst - The Elegant MVC Web Application Framework
 127
 128 =head1 SYNOPSIS
 129
 130 See the L<Catalyst::Manual> distribution for comprehensive
 131 documentation and tutorials.
 132
 133     # Install Catalyst::Devel for helpers and other development tools
 134     # use the helper to create a new application
 135     catalyst.pl MyApp
 136
 137     # add models, views, controllers
 138     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 139     script/myapp_create.pl view MyTemplate TT
 140     script/myapp_create.pl controller Search
 141
 142     # built in testserver -- use -r to restart automatically on changes
 143     # --help to see all available options
 144     script/myapp_server.pl
 145
 146     # command line testing interface
 147     script/myapp_test.pl /yada
 148
 149     ### in lib/MyApp.pm
 150     use Catalyst qw/-Debug/; # include plugins here as well
 151
 152     ### In lib/MyApp/Controller/Root.pm (autocreated)
 153     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 154         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 155         $c->stash->{template} = 'foo.tt'; # set the template
 156         # lookup something from db -- stash vars are passed to TT
 157         $c->stash->{data} =
 158           $c->model('Database::Foo')->search( { country => $args[0] } );
 159         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 160             $c->forward( 'bar' ); # process another action
 161             # do something else after forward returns
 162         }
 163     }
 164
 165     # The foo.tt TT template can use the stash data from the database
 166     [% WHILE (item = data.next) %]
 167         [% item.foo %]
 168     [% END %]
 169
 170     # called for /bar/of/soap, /bar/of/soap/10, etc.
 171     sub bar : Path('/bar/of/soap') { ... }
 172
 173     # called for all actions, from the top-most controller downwards
 174     sub auto : Private {
 175         my ( $self, $c ) = @_;
 176         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 177             $c->res->redirect( '/login' ); # require login
 178             return 0; # abort request and go immediately to end()
 179         }
 180         return 1; # success; carry on to next action
 181     }
 182
 183     # called after all actions are finished
 184     sub end : Private {
 185         my ( $self, $c ) = @_;
 186         if ( scalar @{ $c->error } ) { ... } # handle errors
 187         return if $c->res->body; # already have a response
 188         $c->forward( 'MyApp::View::TT' ); # render template
 189     }
 190
 191     ### in MyApp/Controller/Foo.pm
 192     # called for /foo/bar
 193     sub bar : Local { ... }
 194
 195     # called for /blargle
 196     sub blargle : Global { ... }
 197
 198     # an index action matches /foo, but not /foo/1, etc.
 199     sub index : Private { ... }
 200
 201     ### in MyApp/Controller/Foo/Bar.pm
 202     # called for /foo/bar/baz
 203     sub baz : Local { ... }
 204
 205     # first Root auto is called, then Foo auto, then this
 206     sub auto : Private { ... }
 207
 208     # powerful regular expression paths are also possible
 209     sub details : Regex('^product/(\w+)/details$') {
 210         my ( $self, $c ) = @_;
 211         # extract the (\w+) from the URI
 212         my $product = $c->req->captures->[0];
 213     }
 214
 215 See L<Catalyst::Manual::Intro> for additional information.
 216
 217 =head1 DESCRIPTION
 218
 219 Catalyst is a modern framework for making web applications without the
 220 pain usually associated with this process. This document is a reference
 221 to the main Catalyst application. If you are a new user, we suggest you
 222 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 223
 224 See L<Catalyst::Manual> for more documentation.
 225
 226 Catalyst plugins can be loaded by naming them as arguments to the "use
 227 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 228 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 229 C<My::Module>.
 230
 231     use Catalyst qw/My::Module/;
 232
 233 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 234 fully qualify the name by using a unary plus:
 235
 236     use Catalyst qw/
 237         My::Module
 238         +Fully::Qualified::Plugin::Name
 239     /;
 240
 241 Special flags like C<-Debug> and C<-Engine> can also be specified as
 242 arguments when Catalyst is loaded:
 243
 244     use Catalyst qw/-Debug My::Module/;
 245
 246 The position of plugins and flags in the chain is important, because
 247 they are loaded in the order in which they appear.
 248
 249 The following flags are supported:
 250
 251 =head2 -Debug
 252
 253 Enables debug output. You can also force this setting from the system
 254 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 255 settings override the application, with <MYAPP>_DEBUG having the highest
 256 priority.
 257
 258 =head2 -Engine
 259
 260 Forces Catalyst to use a specific engine. Omit the
 261 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 262
 263     use Catalyst qw/-Engine=CGI/;
 264
 265 =head2 -Home
 266
 267 Forces Catalyst to use a specific home directory, e.g.:
 268
 269     use Catalyst qw[-Home=/usr/mst];
 270
 271 This can also be done in the shell environment by setting either the
 272 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 273 is replaced with the uppercased name of your application, any "::" in
 274 the name will be replaced with underscores, e.g. MyApp::Web should use
 275 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 276
 277 =head2 -Log
 278
 279     use Catalyst '-Log=warn,fatal,error';
 280
 281 Specifies a comma-delimited list of log levels.
 282
 283 =head2 -Stats
 284
 285 Enables statistics collection and reporting. You can also force this setting
 286 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 287 environment settings override the application, with <MYAPP>_STATS having the
 288 highest priority.
 289
 290 e.g.
 291
 292    use Catalyst qw/-Stats=1/
 293
 294 =head1 METHODS
 295
 296 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 297
 298 =head2 $c->action
 299
 300 Returns a L<Catalyst::Action> object for the current action, which
 301 stringifies to the action name. See L<Catalyst::Action>.
 302
 303 =head2 $c->namespace
 304
 305 Returns the namespace of the current action, i.e., the URI prefix
 306 corresponding to the controller of the current action. For example:
 307
 308     # in Controller::Foo::Bar
 309     $c->namespace; # returns 'foo/bar';
 310
 311 =head2 $c->request
 312
 313 =head2 $c->req
 314
 315 Returns the current L<Catalyst::Request> object, giving access to
 316 information about the current client request (including parameters,
 317 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 318
 319 =head2 REQUEST FLOW HANDLING
 320
 321 =head2 $c->forward( $action [, \@arguments ] )
 322
 323 =head2 $c->forward( $class, $method, [, \@arguments ] )
 324
 325 Forwards processing to another action, by its private name. If you give a
 326 class name but no method, C<process()> is called. You may also optionally
 327 pass arguments in an arrayref. The action will receive the arguments in
 328 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 329 C<< $c->req->args >> will be restored to the previous values.
 330
 331 Any data C<return>ed from the action forwarded to, will be returned by the
 332 call to forward.
 333
 334     my $foodata = $c->forward('/foo');
 335     $c->forward('index');
 336     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 337     $c->forward('MyApp::View::TT');
 338
 339 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 340 an C<< eval { } >> around the call (actually
 341 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 342 all 'dies' within the called action. If you want C<die> to propagate you
 343 need to do something like:
 344
 345     $c->forward('foo');
 346     die $c->error if $c->error;
 347
 348 Or make sure to always return true values from your actions and write
 349 your code like this:
 350
 351     $c->forward('foo') || return;
 352
 353 =cut
 354
 355 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 356
 357 =head2 $c->detach( $action [, \@arguments ] )
 358
 359 =head2 $c->detach( $class, $method, [, \@arguments ] )
 360
 361 =head2 $c->detach()
 362
 363 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 364 doesn't return to the previous action when processing is finished.
 365
 366 When called with no arguments it escapes the processing chain entirely.
 367
 368 =cut
 369
 370 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 371
 372 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 373
 374 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 375
 376 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 377 but does a full dispatch, instead of just calling the new C<$action> /
 378 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 379 you go to are called, just like a new request.
 380
 381 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 382 This means, for example, that C<< $c->action >> methods such as
 383 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 384 L<reverse|Catalyst::Action/reverse> return information for the visited action
 385 when they are invoked within the visited action.  This is different from the
 386 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 387 continues to use the $c->action object from the caller action even when
 388 invoked from the callee.
 389
 390 C<< $c->stash >> is kept unchanged.
 391
 392 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 393 allows you to "wrap" another action, just as it would have been called by
 394 dispatching from a URL, while the analogous
 395 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 396 transfer control to another action as if it had been reached directly from a URL.
 397
 398 =cut
 399
 400 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 401
 402 =head2 $c->go( $action [, \@captures, \@arguments ] )
 403
 404 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 405
 406 The relationship between C<go> and
 407 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 408 the relationship between
 409 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 410 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 411 C<< $c->go >> will perform a full dispatch on the specified action or method,
 412 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 413 C<go> escapes the processing of the current request chain on completion, and
 414 does not return to its caller.
 415
 416 =cut
 417
 418 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 419
 420 =head2 $c->response
 421
 422 =head2 $c->res
 423
 424 Returns the current L<Catalyst::Response> object, see there for details.
 425
 426 =head2 $c->stash
 427
 428 Returns a hashref to the stash, which may be used to store data and pass
 429 it between components during a request. You can also set hash keys by
 430 passing arguments. The stash is automatically sent to the view. The
 431 stash is cleared at the end of a request; it cannot be used for
 432 persistent storage (for this you must use a session; see
 433 L<Catalyst::Plugin::Session> for a complete system integrated with
 434 Catalyst).
 435
 436     $c->stash->{foo} = $bar;
 437     $c->stash( { moose => 'majestic', qux => 0 } );
 438     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 439
 440     # stash is automatically passed to the view for use in a template
 441     $c->forward( 'MyApp::View::TT' );
 442
 443 =cut
 444
 445 around stash => sub {
 446     my $orig = shift;
 447     my $c = shift;
 448     my $stash = $orig->($c);
 449     if (@_) {
 450         my $new_stash = @_ > 1 ? {@_} : $_[0];
 451         croak('stash takes a hash or hashref') unless ref $new_stash;
 452         foreach my $key ( keys %$new_stash ) {
 453           $stash->{$key} = $new_stash->{$key};
 454         }
 455     }
 456
 457     return $stash;
 458 };
 459
 460
 461 =head2 $c->error
 462
 463 =head2 $c->error($error, ...)
 464
 465 =head2 $c->error($arrayref)
 466
 467 Returns an arrayref containing error messages.  If Catalyst encounters an
 468 error while processing a request, it stores the error in $c->error.  This
 469 method should only be used to store fatal error messages.
 470
 471     my @error = @{ $c->error };
 472
 473 Add a new error.
 474
 475     $c->error('Something bad happened');
 476
 477 =cut
 478
 479 sub error {
 480     my $c = shift;
 481     if ( $_[0] ) {
 482         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 483         croak @$error unless ref $c;
 484         push @{ $c->{error} }, @$error;
 485     }
 486     elsif ( defined $_[0] ) { $c->{error} = undef }
 487     return $c->{error} || [];
 488 }
 489
 490
 491 =head2 $c->state
 492
 493 Contains the return value of the last executed action.
 494
 495 =head2 $c->clear_errors
 496
 497 Clear errors.  You probably don't want to clear the errors unless you are
 498 implementing a custom error screen.
 499
 500 This is equivalent to running
 501
 502     $c->error(0);
 503
 504 =cut
 505
 506 sub clear_errors {
 507     my $c = shift;
 508     $c->error(0);
 509 }
 510
 511 sub _comp_search_prefixes {
 512     my $c = shift;
 513     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 514 }
 515
 516 # search components given a name and some prefixes
 517 sub _comp_names_search_prefixes {
 518     my ( $c, $name, @prefixes ) = @_;
 519     my $appclass = ref $c || $c;
 520     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 521     $filter = qr/$filter/; # Compile regex now rather than once per loop
 522
 523     # map the original component name to the sub part that we will search against
 524     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 525         grep { /$filter/ } keys %{ $c->components };
 526
 527     # undef for a name will return all
 528     return keys %eligible if !defined $name;
 529
 530     my $query  = ref $name ? $name : qr/^$name$/i;
 531     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 532
 533     return @result if @result;
 534
 535     # if we were given a regexp to search against, we're done.
 536     return if ref $name;
 537
 538     # regexp fallback
 539     $query  = qr/$name/i;
 540     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 541
 542     # no results? try against full names
 543     if( !@result ) {
 544         @result = grep { m{$query} } keys %eligible;
 545     }
 546
 547     # don't warn if we didn't find any results, it just might not exist
 548     if( @result ) {
 549         # Disgusting hack to work out correct method name
 550         my $warn_for = lc $prefixes[0];
 551         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 552            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 553            "component resolution is unreliable and unsafe.";
 554         my $short = $result[0];
 555         $short =~ s/.*?Model:://;
 556         my $shortmess = Carp::shortmess('');
 557         if ($shortmess =~ m#Catalyst/Plugin#) {
 558            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 559               "plugin's config";
 560         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 561            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 562               "component's config";
 563         } else {
 564            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 565               "but if you really wanted to search, pass in a regexp as the argument " .
 566               "like so: \$c->${warn_for}(qr/${name}/)";
 567         }
 568         $c->log->warn( "${msg}$shortmess" );
 569     }
 570
 571     return @result;
 572 }
 573
 574 # Find possible names for a prefix
 575 sub _comp_names {
 576     my ( $c, @prefixes ) = @_;
 577     my $appclass = ref $c || $c;
 578
 579     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 580
 581     my @names = map { s{$filter}{}; $_; }
 582         $c->_comp_names_search_prefixes( undef, @prefixes );
 583
 584     return @names;
 585 }
 586
 587 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 588 sub _filter_component {
 589     my ( $c, $comp, @args ) = @_;
 590
 591     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 592         return $comp->ACCEPT_CONTEXT( $c, @args );
 593     }
 594
 595     return $comp;
 596 }
 597
 598 =head2 COMPONENT ACCESSORS
 599
 600 =head2 $c->controller($name)
 601
 602 Gets a L<Catalyst::Controller> instance by name.
 603
 604     $c->controller('Foo')->do_stuff;
 605
 606 If the name is omitted, will return the controller for the dispatched
 607 action.
 608
 609 If you want to search for controllers, pass in a regexp as the argument.
 610
 611     # find all controllers that start with Foo
 612     my @foo_controllers = $c->controller(qr{^Foo});
 613
 614
 615 =cut
 616
 617 sub controller {
 618     my ( $c, $name, @args ) = @_;
 619
 620     if( $name ) {
 621         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 622         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 623         return $c->_filter_component( $result[ 0 ], @args );
 624     }
 625
 626     return $c->component( $c->action->class );
 627 }
 628
 629 =head2 $c->model($name)
 630
 631 Gets a L<Catalyst::Model> instance by name.
 632
 633     $c->model('Foo')->do_stuff;
 634
 635 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 636
 637 If the name is omitted, it will look for
 638  - a model object in $c->stash->{current_model_instance}, then
 639  - a model name in $c->stash->{current_model}, then
 640  - a config setting 'default_model', or
 641  - check if there is only one model, and return it if that's the case.
 642
 643 If you want to search for models, pass in a regexp as the argument.
 644
 645     # find all models that start with Foo
 646     my @foo_models = $c->model(qr{^Foo});
 647
 648 =cut
 649
 650 sub model {
 651     my ( $c, $name, @args ) = @_;
 652     my $appclass = ref($c) || $c;
 653     if( $name ) {
 654         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 655         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 656         return $c->_filter_component( $result[ 0 ], @args );
 657     }
 658
 659     if (ref $c) {
 660         return $c->stash->{current_model_instance}
 661           if $c->stash->{current_model_instance};
 662         return $c->model( $c->stash->{current_model} )
 663           if $c->stash->{current_model};
 664     }
 665     return $c->model( $appclass->config->{default_model} )
 666       if $appclass->config->{default_model};
 667
 668     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 669
 670     if( $rest ) {
 671         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 672         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 673         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 674         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 675         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 676     }
 677
 678     return $c->_filter_component( $comp );
 679 }
 680
 681
 682 =head2 $c->view($name)
 683
 684 Gets a L<Catalyst::View> instance by name.
 685
 686     $c->view('Foo')->do_stuff;
 687
 688 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 689
 690 If the name is omitted, it will look for
 691  - a view object in $c->stash->{current_view_instance}, then
 692  - a view name in $c->stash->{current_view}, then
 693  - a config setting 'default_view', or
 694  - check if there is only one view, and return it if that's the case.
 695
 696 If you want to search for views, pass in a regexp as the argument.
 697
 698     # find all views that start with Foo
 699     my @foo_views = $c->view(qr{^Foo});
 700
 701 =cut
 702
 703 sub view {
 704     my ( $c, $name, @args ) = @_;
 705
 706     my $appclass = ref($c) || $c;
 707     if( $name ) {
 708         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 709         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 710         return $c->_filter_component( $result[ 0 ], @args );
 711     }
 712
 713     if (ref $c) {
 714         return $c->stash->{current_view_instance}
 715           if $c->stash->{current_view_instance};
 716         return $c->view( $c->stash->{current_view} )
 717           if $c->stash->{current_view};
 718     }
 719     return $c->view( $appclass->config->{default_view} )
 720       if $appclass->config->{default_view};
 721
 722     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 723
 724     if( $rest ) {
 725         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 726         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 727         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 728         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 729         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 730     }
 731
 732     return $c->_filter_component( $comp );
 733 }
 734
 735 =head2 $c->controllers
 736
 737 Returns the available names which can be passed to $c->controller
 738
 739 =cut
 740
 741 sub controllers {
 742     my ( $c ) = @_;
 743     return $c->_comp_names(qw/Controller C/);
 744 }
 745
 746 =head2 $c->models
 747
 748 Returns the available names which can be passed to $c->model
 749
 750 =cut
 751
 752 sub models {
 753     my ( $c ) = @_;
 754     return $c->_comp_names(qw/Model M/);
 755 }
 756
 757
 758 =head2 $c->views
 759
 760 Returns the available names which can be passed to $c->view
 761
 762 =cut
 763
 764 sub views {
 765     my ( $c ) = @_;
 766     return $c->_comp_names(qw/View V/);
 767 }
 768
 769 =head2 $c->comp($name)
 770
 771 =head2 $c->component($name)
 772
 773 Gets a component object by name. This method is not recommended,
 774 unless you want to get a specific component by full
 775 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 776 should be used instead.
 777
 778 If C<$name> is a regexp, a list of components matched against the full
 779 component name will be returned.
 780
 781 =cut
 782
 783 sub component {
 784     my ( $c, $name, @args ) = @_;
 785
 786     if( $name ) {
 787         my $comps = $c->components;
 788
 789         if( !ref $name ) {
 790             # is it the exact name?
 791             return $c->_filter_component( $comps->{ $name }, @args )
 792                        if exists $comps->{ $name };
 793
 794             # perhaps we just omitted "MyApp"?
 795             my $composed = ( ref $c || $c ) . "::${name}";
 796             return $c->_filter_component( $comps->{ $composed }, @args )
 797                        if exists $comps->{ $composed };
 798
 799             # search all of the models, views and controllers
 800             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 801             return $c->_filter_component( $comp, @args ) if $comp;
 802         }
 803
 804         # This is here so $c->comp( '::M::' ) works
 805         my $query = ref $name ? $name : qr{$name}i;
 806
 807         my @result = grep { m{$query} } keys %{ $c->components };
 808         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 809
 810         if( $result[ 0 ] ) {
 811             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 812             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 813             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 814             return $c->_filter_component( $result[ 0 ], @args );
 815         }
 816
 817         # I would expect to return an empty list here, but that breaks back-compat
 818     }
 819
 820     # fallback
 821     return sort keys %{ $c->components };
 822 }
 823
 824 =head2 CLASS DATA AND HELPER CLASSES
 825
 826 =head2 $c->config
 827
 828 Returns or takes a hashref containing the application's configuration.
 829
 830     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 831
 832 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 833 like C<myapp.conf> in your applications home directory. See
 834 L<Catalyst::Plugin::ConfigLoader>.
 835
 836 =head3 Cascading configuration
 837
 838 The config method is present on all Catalyst components, and configuration
 839 will be merged when an application is started. Configuration loaded with
 840 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 841 followed by configuration in your top level C<MyApp> class. These two
 842 configurations are merged, and then configuration data whose hash key matches a
 843 component name is merged with configuration for that component.
 844
 845 The configuration for a component is then passed to the C<new> method when a
 846 component is constructed.
 847
 848 For example:
 849
 850     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 851     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 852
 853 will mean that C<MyApp::Model::Foo> receives the following data when
 854 constructed:
 855
 856     MyApp::Model::Foo->new({
 857         bar => 'baz',
 858         quux => 'frob',
 859         overrides => 'me',
 860     });
 861
 862 =cut
 863
 864 around config => sub {
 865     my $orig = shift;
 866     my $c = shift;
 867
 868     croak('Setting config after setup has been run is not allowed.')
 869         if ( @_ and $c->setup_finished );
 870
 871     $c->$orig(@_);
 872 };
 873
 874 =head2 $c->log
 875
 876 Returns the logging object instance. Unless it is already set, Catalyst
 877 sets this up with a L<Catalyst::Log> object. To use your own log class,
 878 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 879 C<< __PACKAGE__->setup >>.
 880
 881  __PACKAGE__->log( MyLogger->new );
 882  __PACKAGE__->setup;
 883
 884 And later:
 885
 886     $c->log->info( 'Now logging with my own logger!' );
 887
 888 Your log class should implement the methods described in
 889 L<Catalyst::Log>.
 890
 891
 892 =head2 $c->debug
 893
 894 Returns 1 if debug mode is enabled, 0 otherwise.
 895
 896 You can enable debug mode in several ways:
 897
 898 =over
 899
 900 =item By calling myapp_server.pl with the -d flag
 901
 902 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 903
 904 =item The -Debug option in your MyApp.pm
 905
 906 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 907
 908 =back
 909
 910 Calling C<< $c->debug(1) >> has no effect.
 911
 912 =cut
 913
 914 sub debug { 0 }
 915
 916 =head2 $c->dispatcher
 917
 918 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 919
 920 =head2 $c->engine
 921
 922 Returns the engine instance. See L<Catalyst::Engine>.
 923
 924
 925 =head2 UTILITY METHODS
 926
 927 =head2 $c->path_to(@path)
 928
 929 Merges C<@path> with C<< $c->config->{home} >> and returns a
 930 L<Path::Class::Dir> object. Note you can usually use this object as
 931 a filename, but sometimes you will have to explicitly stringify it
 932 yourself by calling the C<< ->stringify >> method.
 933
 934 For example:
 935
 936     $c->path_to( 'db', 'sqlite.db' );
 937
 938 =cut
 939
 940 sub path_to {
 941     my ( $c, @path ) = @_;
 942     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 943     if ( -d $path ) { return $path }
 944     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 945 }
 946
 947 =head2 $c->plugin( $name, $class, @args )
 948
 949 Helper method for plugins. It creates a class data accessor/mutator and
 950 loads and instantiates the given class.
 951
 952     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 953
 954     $c->prototype->define_javascript_functions;
 955
 956 B<Note:> This method of adding plugins is deprecated. The ability
 957 to add plugins like this B<will be removed> in a Catalyst 5.81.
 958 Please do not use this functionality in new code.
 959
 960 =cut
 961
 962 sub plugin {
 963     my ( $class, $name, $plugin, @args ) = @_;
 964
 965     # See block comment in t/unit_core_plugin.t
 966     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 967
 968     $class->_register_plugin( $plugin, 1 );
 969
 970     eval { $plugin->import };
 971     $class->mk_classdata($name);
 972     my $obj;
 973     eval { $obj = $plugin->new(@args) };
 974
 975     if ($@) {
 976         Catalyst::Exception->throw( message =>
 977               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 978     }
 979
 980     $class->$name($obj);
 981     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 982       if $class->debug;
 983 }
 984
 985 =head2 MyApp->setup
 986
 987 Initializes the dispatcher and engine, loads any plugins, and loads the
 988 model, view, and controller components. You may also specify an array
 989 of plugins to load here, if you choose to not load them in the C<use
 990 Catalyst> line.
 991
 992     MyApp->setup;
 993     MyApp->setup( qw/-Debug/ );
 994
 995 =cut
 996
 997 sub setup {
 998     my ( $class, @arguments ) = @_;
 999     croak('Running setup more than once')
1000         if ( $class->setup_finished );
1001
1002     unless ( $class->isa('Catalyst') ) {
1003
1004         Catalyst::Exception->throw(
1005             message => qq/'$class' does not inherit from Catalyst/ );
1006     }
1007
1008     if ( $class->arguments ) {
1009         @arguments = ( @arguments, @{ $class->arguments } );
1010     }
1011
1012     # Process options
1013     my $flags = {};
1014
1015     foreach (@arguments) {
1016
1017         if (/^-Debug$/) {
1018             $flags->{log} =
1019               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1020         }
1021         elsif (/^-(\w+)=?(.*)$/) {
1022             $flags->{ lc $1 } = $2;
1023         }
1024         else {
1025             push @{ $flags->{plugins} }, $_;
1026         }
1027     }
1028
1029     $class->setup_home( delete $flags->{home} );
1030
1031     $class->setup_log( delete $flags->{log} );
1032     $class->setup_plugins( delete $flags->{plugins} );
1033     $class->setup_dispatcher( delete $flags->{dispatcher} );
1034     $class->setup_engine( delete $flags->{engine} );
1035     $class->setup_stats( delete $flags->{stats} );
1036
1037     for my $flag ( sort keys %{$flags} ) {
1038
1039         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1040             &$code( $class, delete $flags->{$flag} );
1041         }
1042         else {
1043             $class->log->warn(qq/Unknown flag "$flag"/);
1044         }
1045     }
1046
1047     eval { require Catalyst::Devel; };
1048     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1049         $class->log->warn(<<"EOF");
1050 You are running an old script!
1051
1052   Please update by running (this will overwrite existing files):
1053     catalyst.pl -force -scripts $class
1054
1055   or (this will not overwrite existing files):
1056     catalyst.pl -scripts $class
1057
1058 EOF
1059     }
1060
1061     if ( $class->debug ) {
1062         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1063
1064         if (@plugins) {
1065             my $column_width = Catalyst::Utils::term_width() - 6;
1066             my $t = Text::SimpleTable->new($column_width);
1067             $t->row($_) for @plugins;
1068             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1069         }
1070
1071         my $dispatcher = $class->dispatcher;
1072         my $engine     = $class->engine;
1073         my $home       = $class->config->{home};
1074
1075         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1076         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1077
1078         $home
1079           ? ( -d $home )
1080           ? $class->log->debug(qq/Found home "$home"/)
1081           : $class->log->debug(qq/Home "$home" doesn't exist/)
1082           : $class->log->debug(q/Couldn't find home/);
1083     }
1084
1085     # Call plugins setup, this is stupid and evil.
1086     # Also screws C3 badly on 5.10, hack to avoid.
1087     {
1088         no warnings qw/redefine/;
1089         local *setup = sub { };
1090         $class->setup unless $Catalyst::__AM_RESTARTING;
1091     }
1092
1093     # Initialize our data structure
1094     $class->components( {} );
1095
1096     $class->setup_components;
1097
1098     if ( $class->debug ) {
1099         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1100         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1101         for my $comp ( sort keys %{ $class->components } ) {
1102             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1103             $t->row( $comp, $type );
1104         }
1105         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1106           if ( keys %{ $class->components } );
1107     }
1108
1109     # Add our self to components, since we are also a component
1110     if( $class->isa('Catalyst::Controller') ){
1111       $class->components->{$class} = $class;
1112     }
1113
1114     $class->setup_actions;
1115
1116     if ( $class->debug ) {
1117         my $name = $class->config->{name} || 'Application';
1118         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1119     }
1120     $class->log->_flush() if $class->log->can('_flush');
1121
1122     # Make sure that the application class becomes immutable at this point,
1123     B::Hooks::EndOfScope::on_scope_end {
1124         return if $@;
1125         my $meta = Class::MOP::get_metaclass_by_name($class);
1126         if (
1127             $meta->is_immutable
1128             && ! { $meta->immutable_options }->{replace_constructor}
1129             && (
1130                    $class->isa('Class::Accessor::Fast')
1131                 || $class->isa('Class::Accessor')
1132             )
1133         ) {
1134             warn "You made your application class ($class) immutable, "
1135                 . "but did not inline the\nconstructor. "
1136                 . "This will break catalyst, as your app \@ISA "
1137                 . "Class::Accessor(::Fast)?\nPlease pass "
1138                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1139         }
1140         $meta->make_immutable(
1141             replace_constructor => 1,
1142         ) unless $meta->is_immutable;
1143     };
1144
1145     $class->setup_finalize;
1146 }
1147
1148
1149 =head2 $app->setup_finalize
1150
1151 A hook to attach modifiers to.
1152 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1153 Also better than C< setup_finished(); >, as that is a getter method.
1154
1155     sub setup_finalize {
1156
1157         my $app = shift;
1158
1159         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1160
1161         $app->next::method(@_);
1162
1163
1164     }
1165
1166 =cut
1167
1168 sub setup_finalize {
1169     my ($class) = @_;
1170     $class->setup_finished(1);
1171 }
1172
1173 =head2 $c->uri_for( $path, @args?, \%query_values? )
1174
1175 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1176
1177 Constructs an absolute L<URI> object based on the application root, the
1178 provided path, and the additional arguments and query parameters provided.
1179 When used as a string, provides a textual URI.
1180
1181 If the first argument is a string, it is taken as a public URI path relative
1182 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1183 relative to the application root (if it does). It is then merged with
1184 C<< $c->request->base >>; any C<@args> are appended as additional path
1185 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1186
1187 If the first argument is a L<Catalyst::Action> it represents an action which
1188 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1189 optional C<\@captures> argument (an arrayref) allows passing the captured
1190 variables that are needed to fill in the paths of Chained and Regex actions;
1191 once the path is resolved, C<uri_for> continues as though a path was
1192 provided, appending any arguments or parameters and creating an absolute
1193 URI.
1194
1195 The captures for the current request can be found in
1196 C<< $c->request->captures >>, and actions can be resolved using
1197 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1198 path, use C<< $c->uri_for_action >> instead.
1199
1200   # Equivalent to $c->req->uri
1201   $c->uri_for($c->action, $c->req->captures,
1202       @{ $c->req->args }, $c->req->params);
1203
1204   # For the Foo action in the Bar controller
1205   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1206
1207   # Path to a static resource
1208   $c->uri_for('/static/images/logo.png');
1209
1210 =cut
1211
1212 sub uri_for {
1213     my ( $c, $path, @args ) = @_;
1214
1215     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1216         $path = $path->path_prefix;
1217         $path =~ s{/+\z}{};
1218         $path .= '/';
1219     }
1220
1221     if ( blessed($path) ) { # action object
1222         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1223                          ? shift(@args)
1224                          : [] );
1225         my $action = $path;
1226         $path = $c->dispatcher->uri_for_action($action, $captures);
1227         if (not defined $path) {
1228             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1229                 if $c->debug;
1230             return undef;
1231         }
1232         $path = '/' if $path eq '';
1233     }
1234
1235     undef($path) if (defined $path && $path eq '');
1236
1237     my $params =
1238       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1239
1240     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1241     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1242
1243     unshift(@args, $path);
1244
1245     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1246         my $namespace = $c->namespace;
1247         if (defined $path) { # cheesy hack to handle path '../foo'
1248            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1249         }
1250         unshift(@args, $namespace || '');
1251     }
1252
1253     # join args with '/', or a blank string
1254     my $args = join('/', grep { defined($_) } @args);
1255     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1256     $args =~ s!^/+!!;
1257     my $base = $c->req->base;
1258     my $class = ref($base);
1259     $base =~ s{(?<!/)$}{/};
1260
1261     my $query = '';
1262
1263     if (my @keys = keys %$params) {
1264       # somewhat lifted from URI::_query's query_form
1265       $query = '?'.join('&', map {
1266           my $val = $params->{$_};
1267           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1268           s/ /+/g;
1269           my $key = $_;
1270           $val = '' unless defined $val;
1271           (map {
1272               my $param = "$_";
1273               utf8::encode( $param ) if utf8::is_utf8($param);
1274               # using the URI::Escape pattern here so utf8 chars survive
1275               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1276               $param =~ s/ /+/g;
1277               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1278       } @keys);
1279     }
1280
1281     my $res = bless(\"${base}${args}${query}", $class);
1282     $res;
1283 }
1284
1285 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1286
1287 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1288
1289 =over
1290
1291 =item $path
1292
1293 A private path to the Catalyst action you want to create a URI for.
1294
1295 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1296 >> and passing the resulting C<$action> and the remaining arguments to C<<
1297 $c->uri_for >>.
1298
1299 You can also pass in a Catalyst::Action object, in which case it is passed to
1300 C<< $c->uri_for >>.
1301
1302 =back
1303
1304 =cut
1305
1306 sub uri_for_action {
1307     my ( $c, $path, @args ) = @_;
1308     my $action = blessed($path)
1309       ? $path
1310       : $c->dispatcher->get_action_by_path($path);
1311     unless (defined $action) {
1312       croak "Can't find action for path '$path'";
1313     }
1314     return $c->uri_for( $action, @args );
1315 }
1316
1317 =head2 $c->welcome_message
1318
1319 Returns the Catalyst welcome HTML page.
1320
1321 =cut
1322
1323 sub welcome_message {
1324     my $c      = shift;
1325     my $name   = $c->config->{name};
1326     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1327     my $prefix = Catalyst::Utils::appprefix( ref $c );
1328     $c->response->content_type('text/html; charset=utf-8');
1329     return <<"EOF";
1330 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1331     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1332 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1333     <head>
1334     <meta http-equiv="Content-Language" content="en" />
1335     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1336         <title>$name on Catalyst $VERSION</title>
1337         <style type="text/css">
1338             body {
1339                 color: #000;
1340                 background-color: #eee;
1341             }
1342             div#content {
1343                 width: 640px;
1344                 margin-left: auto;
1345                 margin-right: auto;
1346                 margin-top: 10px;
1347                 margin-bottom: 10px;
1348                 text-align: left;
1349                 background-color: #ccc;
1350                 border: 1px solid #aaa;
1351             }
1352             p, h1, h2 {
1353                 margin-left: 20px;
1354                 margin-right: 20px;
1355                 font-family: verdana, tahoma, sans-serif;
1356             }
1357             a {
1358                 font-family: verdana, tahoma, sans-serif;
1359             }
1360             :link, :visited {
1361                     text-decoration: none;
1362                     color: #b00;
1363                     border-bottom: 1px dotted #bbb;
1364             }
1365             :link:hover, :visited:hover {
1366                     color: #555;
1367             }
1368             div#topbar {
1369                 margin: 0px;
1370             }
1371             pre {
1372                 margin: 10px;
1373                 padding: 8px;
1374             }
1375             div#answers {
1376                 padding: 8px;
1377                 margin: 10px;
1378                 background-color: #fff;
1379                 border: 1px solid #aaa;
1380             }
1381             h1 {
1382                 font-size: 0.9em;
1383                 font-weight: normal;
1384                 text-align: center;
1385             }
1386             h2 {
1387                 font-size: 1.0em;
1388             }
1389             p {
1390                 font-size: 0.9em;
1391             }
1392             p img {
1393                 float: right;
1394                 margin-left: 10px;
1395             }
1396             span#appname {
1397                 font-weight: bold;
1398                 font-size: 1.6em;
1399             }
1400         </style>
1401     </head>
1402     <body>
1403         <div id="content">
1404             <div id="topbar">
1405                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1406                     $VERSION</h1>
1407              </div>
1408              <div id="answers">
1409                  <p>
1410                  <img src="$logo" alt="Catalyst Logo" />
1411                  </p>
1412                  <p>Welcome to the  world of Catalyst.
1413                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1414                     framework will make web development something you had
1415                     never expected it to be: Fun, rewarding, and quick.</p>
1416                  <h2>What to do now?</h2>
1417                  <p>That really depends  on what <b>you</b> want to do.
1418                     We do, however, provide you with a few starting points.</p>
1419                  <p>If you want to jump right into web development with Catalyst
1420                     you might want to start with a tutorial.</p>
1421 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1422 </pre>
1423 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1424 <pre>
1425 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1426 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1427 </code></pre>
1428                  <h2>What to do next?</h2>
1429                  <p>Next it's time to write an actual application. Use the
1430                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1431                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1432                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1433                     they can save you a lot of work.</p>
1434                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1435                     <p>Also, be sure to check out the vast and growing
1436                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1437                     you are likely to find what you need there.
1438                     </p>
1439
1440                  <h2>Need help?</h2>
1441                  <p>Catalyst has a very active community. Here are the main places to
1442                     get in touch with us.</p>
1443                  <ul>
1444                      <li>
1445                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1446                      </li>
1447                      <li>
1448                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1449                      </li>
1450                      <li>
1451                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1452                      </li>
1453                  </ul>
1454                  <h2>In conclusion</h2>
1455                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1456                     as we enjoyed making it. Please contact us if you have ideas
1457                     for improvement or other feedback.</p>
1458              </div>
1459          </div>
1460     </body>
1461 </html>
1462 EOF
1463 }
1464
1465 =head1 INTERNAL METHODS
1466
1467 These methods are not meant to be used by end users.
1468
1469 =head2 $c->components
1470
1471 Returns a hash of components.
1472
1473 =head2 $c->context_class
1474
1475 Returns or sets the context class.
1476
1477 =head2 $c->counter
1478
1479 Returns a hashref containing coderefs and execution counts (needed for
1480 deep recursion detection).
1481
1482 =head2 $c->depth
1483
1484 Returns the number of actions on the current internal execution stack.
1485
1486 =head2 $c->dispatch
1487
1488 Dispatches a request to actions.
1489
1490 =cut
1491
1492 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1493
1494 =head2 $c->dispatcher_class
1495
1496 Returns or sets the dispatcher class.
1497
1498 =head2 $c->dump_these
1499
1500 Returns a list of 2-element array references (name, structure) pairs
1501 that will be dumped on the error page in debug mode.
1502
1503 =cut
1504
1505 sub dump_these {
1506     my $c = shift;
1507     [ Request => $c->req ],
1508     [ Response => $c->res ],
1509     [ Stash => $c->stash ],
1510     [ Config => $c->config ];
1511 }
1512
1513 =head2 $c->engine_class
1514
1515 Returns or sets the engine class.
1516
1517 =head2 $c->execute( $class, $coderef )
1518
1519 Execute a coderef in given class and catch exceptions. Errors are available
1520 via $c->error.
1521
1522 =cut
1523
1524 sub execute {
1525     my ( $c, $class, $code ) = @_;
1526     $class = $c->component($class) || $class;
1527     $c->state(0);
1528
1529     if ( $c->depth >= $RECURSION ) {
1530         my $action = $code->reverse();
1531         $action = "/$action" unless $action =~ /->/;
1532         my $error = qq/Deep recursion detected calling "${action}"/;
1533         $c->log->error($error);
1534         $c->error($error);
1535         $c->state(0);
1536         return $c->state;
1537     }
1538
1539     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1540
1541     push( @{ $c->stack }, $code );
1542
1543     no warnings 'recursion';
1544     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1545
1546     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1547
1548     my $last = pop( @{ $c->stack } );
1549
1550     if ( my $error = $@ ) {
1551         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1552             $error->rethrow if $c->depth > 1;
1553         }
1554         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1555             $error->rethrow if $c->depth > 0;
1556         }
1557         else {
1558             unless ( ref $error ) {
1559                 no warnings 'uninitialized';
1560                 chomp $error;
1561                 my $class = $last->class;
1562                 my $name  = $last->name;
1563                 $error = qq/Caught exception in $class->$name "$error"/;
1564             }
1565             $c->error($error);
1566             $c->state(0);
1567         }
1568     }
1569     return $c->state;
1570 }
1571
1572 sub _stats_start_execute {
1573     my ( $c, $code ) = @_;
1574     my $appclass = ref($c) || $c;
1575     return if ( ( $code->name =~ /^_.*/ )
1576         && ( !$appclass->config->{show_internal_actions} ) );
1577
1578     my $action_name = $code->reverse();
1579     $c->counter->{$action_name}++;
1580
1581     my $action = $action_name;
1582     $action = "/$action" unless $action =~ /->/;
1583
1584     # determine if the call was the result of a forward
1585     # this is done by walking up the call stack and looking for a calling
1586     # sub of Catalyst::forward before the eval
1587     my $callsub = q{};
1588     for my $index ( 2 .. 11 ) {
1589         last
1590         if ( ( caller($index) )[0] eq 'Catalyst'
1591             && ( caller($index) )[3] eq '(eval)' );
1592
1593         if ( ( caller($index) )[3] =~ /forward$/ ) {
1594             $callsub = ( caller($index) )[3];
1595             $action  = "-> $action";
1596             last;
1597         }
1598     }
1599
1600     my $uid = $action_name . $c->counter->{$action_name};
1601
1602     # is this a root-level call or a forwarded call?
1603     if ( $callsub =~ /forward$/ ) {
1604
1605         # forward, locate the caller
1606         if ( my $parent = $c->stack->[-1] ) {
1607             $c->stats->profile(
1608                 begin  => $action,
1609                 parent => "$parent" . $c->counter->{"$parent"},
1610                 uid    => $uid,
1611             );
1612         }
1613         else {
1614
1615             # forward with no caller may come from a plugin
1616             $c->stats->profile(
1617                 begin => $action,
1618                 uid   => $uid,
1619             );
1620         }
1621     }
1622     else {
1623
1624         # root-level call
1625         $c->stats->profile(
1626             begin => $action,
1627             uid   => $uid,
1628         );
1629     }
1630     return $action;
1631
1632 }
1633
1634 sub _stats_finish_execute {
1635     my ( $c, $info ) = @_;
1636     $c->stats->profile( end => $info );
1637 }
1638
1639 =head2 $c->finalize
1640
1641 Finalizes the request.
1642
1643 =cut
1644
1645 sub finalize {
1646     my $c = shift;
1647
1648     for my $error ( @{ $c->error } ) {
1649         $c->log->error($error);
1650     }
1651
1652     # Allow engine to handle finalize flow (for POE)
1653     my $engine = $c->engine;
1654     if ( my $code = $engine->can('finalize') ) {
1655         $engine->$code($c);
1656     }
1657     else {
1658
1659         $c->finalize_uploads;
1660
1661         # Error
1662         if ( $#{ $c->error } >= 0 ) {
1663             $c->finalize_error;
1664         }
1665
1666         $c->finalize_headers;
1667
1668         # HEAD request
1669         if ( $c->request->method eq 'HEAD' ) {
1670             $c->response->body('');
1671         }
1672
1673         $c->finalize_body;
1674     }
1675
1676     if ($c->use_stats) {
1677         my $elapsed = sprintf '%f', $c->stats->elapsed;
1678         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1679         $c->log->info(
1680             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1681     }
1682
1683     return $c->response->status;
1684 }
1685
1686 =head2 $c->finalize_body
1687
1688 Finalizes body.
1689
1690 =cut
1691
1692 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1693
1694 =head2 $c->finalize_cookies
1695
1696 Finalizes cookies.
1697
1698 =cut
1699
1700 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1701
1702 =head2 $c->finalize_error
1703
1704 Finalizes error.
1705
1706 =cut
1707
1708 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1709
1710 =head2 $c->finalize_headers
1711
1712 Finalizes headers.
1713
1714 =cut
1715
1716 sub finalize_headers {
1717     my $c = shift;
1718
1719     my $response = $c->response; #accessor calls can add up?
1720
1721     # Check if we already finalized headers
1722     return if $response->finalized_headers;
1723
1724     # Handle redirects
1725     if ( my $location = $response->redirect ) {
1726         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1727         $response->header( Location => $location );
1728
1729         if ( !$response->has_body ) {
1730             # Add a default body if none is already present
1731             $response->body(
1732                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1733             );
1734         }
1735     }
1736
1737     # Content-Length
1738     if ( $response->body && !$response->content_length ) {
1739
1740         # get the length from a filehandle
1741         if ( blessed( $response->body ) && $response->body->can('read') )
1742         {
1743             my $stat = stat $response->body;
1744             if ( $stat && $stat->size > 0 ) {
1745                 $response->content_length( $stat->size );
1746             }
1747             else {
1748                 $c->log->warn('Serving filehandle without a content-length');
1749             }
1750         }
1751         else {
1752             # everything should be bytes at this point, but just in case
1753             $response->content_length( bytes::length( $response->body ) );
1754         }
1755     }
1756
1757     # Errors
1758     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1759         $response->headers->remove_header("Content-Length");
1760         $response->body('');
1761     }
1762
1763     $c->finalize_cookies;
1764
1765     $c->engine->finalize_headers( $c, @_ );
1766
1767     # Done
1768     $response->finalized_headers(1);
1769 }
1770
1771 =head2 $c->finalize_output
1772
1773 An alias for finalize_body.
1774
1775 =head2 $c->finalize_read
1776
1777 Finalizes the input after reading is complete.
1778
1779 =cut
1780
1781 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1782
1783 =head2 $c->finalize_uploads
1784
1785 Finalizes uploads. Cleans up any temporary files.
1786
1787 =cut
1788
1789 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1790
1791 =head2 $c->get_action( $action, $namespace )
1792
1793 Gets an action in a given namespace.
1794
1795 =cut
1796
1797 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1798
1799 =head2 $c->get_actions( $action, $namespace )
1800
1801 Gets all actions of a given name in a namespace and all parent
1802 namespaces.
1803
1804 =cut
1805
1806 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1807
1808 =head2 $c->handle_request( $class, @arguments )
1809
1810 Called to handle each HTTP request.
1811
1812 =cut
1813
1814 sub handle_request {
1815     my ( $class, @arguments ) = @_;
1816
1817     # Always expect worst case!
1818     my $status = -1;
1819     eval {
1820         if ($class->debug) {
1821             my $secs = time - $START || 1;
1822             my $av = sprintf '%.3f', $COUNT / $secs;
1823             my $time = localtime time;
1824             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1825         }
1826
1827         my $c = $class->prepare(@arguments);
1828         $c->dispatch;
1829         $status = $c->finalize;
1830     };
1831
1832     if ( my $error = $@ ) {
1833         chomp $error;
1834         $class->log->error(qq/Caught exception in engine "$error"/);
1835     }
1836
1837     $COUNT++;
1838
1839     if(my $coderef = $class->log->can('_flush')){
1840         $class->log->$coderef();
1841     }
1842     return $status;
1843 }
1844
1845 =head2 $c->prepare( @arguments )
1846
1847 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1848 etc.).
1849
1850 =cut
1851
1852 sub prepare {
1853     my ( $class, @arguments ) = @_;
1854
1855     # XXX
1856     # After the app/ctxt split, this should become an attribute based on something passed
1857     # into the application.
1858     $class->context_class( ref $class || $class ) unless $class->context_class;
1859
1860     my $c = $class->context_class->new({});
1861
1862     # For on-demand data
1863     $c->request->_context($c);
1864     $c->response->_context($c);
1865
1866     #surely this is not the most efficient way to do things...
1867     $c->stats($class->stats_class->new)->enable($c->use_stats);
1868     if ( $c->debug ) {
1869         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1870     }
1871
1872     #XXX reuse coderef from can
1873     # Allow engine to direct the prepare flow (for POE)
1874     if ( $c->engine->can('prepare') ) {
1875         $c->engine->prepare( $c, @arguments );
1876     }
1877     else {
1878         $c->prepare_request(@arguments);
1879         $c->prepare_connection;
1880         $c->prepare_query_parameters;
1881         $c->prepare_headers;
1882         $c->prepare_cookies;
1883         $c->prepare_path;
1884
1885         # Prepare the body for reading, either by prepare_body
1886         # or the user, if they are using $c->read
1887         $c->prepare_read;
1888
1889         # Parse the body unless the user wants it on-demand
1890         unless ( ref($c)->config->{parse_on_demand} ) {
1891             $c->prepare_body;
1892         }
1893     }
1894
1895     my $method  = $c->req->method  || '';
1896     my $path    = $c->req->path;
1897     $path       = '/' unless length $path;
1898     my $address = $c->req->address || '';
1899
1900     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1901       if $c->debug;
1902
1903     $c->prepare_action;
1904
1905     return $c;
1906 }
1907
1908 =head2 $c->prepare_action
1909
1910 Prepares action. See L<Catalyst::Dispatcher>.
1911
1912 =cut
1913
1914 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1915
1916 =head2 $c->prepare_body
1917
1918 Prepares message body.
1919
1920 =cut
1921
1922 sub prepare_body {
1923     my $c = shift;
1924
1925     return if $c->request->_has_body;
1926
1927     # Initialize on-demand data
1928     $c->engine->prepare_body( $c, @_ );
1929     $c->prepare_parameters;
1930     $c->prepare_uploads;
1931
1932     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1933         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1934         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1935             my $param = $c->req->body_parameters->{$key};
1936             my $value = defined($param) ? $param : '';
1937             $t->row( $key,
1938                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1939         }
1940         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1941     }
1942 }
1943
1944 =head2 $c->prepare_body_chunk( $chunk )
1945
1946 Prepares a chunk of data before sending it to L<HTTP::Body>.
1947
1948 See L<Catalyst::Engine>.
1949
1950 =cut
1951
1952 sub prepare_body_chunk {
1953     my $c = shift;
1954     $c->engine->prepare_body_chunk( $c, @_ );
1955 }
1956
1957 =head2 $c->prepare_body_parameters
1958
1959 Prepares body parameters.
1960
1961 =cut
1962
1963 sub prepare_body_parameters {
1964     my $c = shift;
1965     $c->engine->prepare_body_parameters( $c, @_ );
1966 }
1967
1968 =head2 $c->prepare_connection
1969
1970 Prepares connection.
1971
1972 =cut
1973
1974 sub prepare_connection {
1975     my $c = shift;
1976     $c->engine->prepare_connection( $c, @_ );
1977 }
1978
1979 =head2 $c->prepare_cookies
1980
1981 Prepares cookies.
1982
1983 =cut
1984
1985 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1986
1987 =head2 $c->prepare_headers
1988
1989 Prepares headers.
1990
1991 =cut
1992
1993 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1994
1995 =head2 $c->prepare_parameters
1996
1997 Prepares parameters.
1998
1999 =cut
2000
2001 sub prepare_parameters {
2002     my $c = shift;
2003     $c->prepare_body_parameters;
2004     $c->engine->prepare_parameters( $c, @_ );
2005 }
2006
2007 =head2 $c->prepare_path
2008
2009 Prepares path and base.
2010
2011 =cut
2012
2013 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2014
2015 =head2 $c->prepare_query_parameters
2016
2017 Prepares query parameters.
2018
2019 =cut
2020
2021 sub prepare_query_parameters {
2022     my $c = shift;
2023
2024     $c->engine->prepare_query_parameters( $c, @_ );
2025
2026     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
2027         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
2028         for my $key ( sort keys %{ $c->req->query_parameters } ) {
2029             my $param = $c->req->query_parameters->{$key};
2030             my $value = defined($param) ? $param : '';
2031             $t->row( $key,
2032                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2033         }
2034         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2035     }
2036 }
2037
2038 =head2 $c->prepare_read
2039
2040 Prepares the input for reading.
2041
2042 =cut
2043
2044 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2045
2046 =head2 $c->prepare_request
2047
2048 Prepares the engine request.
2049
2050 =cut
2051
2052 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2053
2054 =head2 $c->prepare_uploads
2055
2056 Prepares uploads.
2057
2058 =cut
2059
2060 sub prepare_uploads {
2061     my $c = shift;
2062
2063     $c->engine->prepare_uploads( $c, @_ );
2064
2065     if ( $c->debug && keys %{ $c->request->uploads } ) {
2066         my $t = Text::SimpleTable->new(
2067             [ 12, 'Parameter' ],
2068             [ 26, 'Filename' ],
2069             [ 18, 'Type' ],
2070             [ 9,  'Size' ]
2071         );
2072         for my $key ( sort keys %{ $c->request->uploads } ) {
2073             my $upload = $c->request->uploads->{$key};
2074             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2075                 $t->row( $key, $u->filename, $u->type, $u->size );
2076             }
2077         }
2078         $c->log->debug( "File Uploads are:\n" . $t->draw );
2079     }
2080 }
2081
2082 =head2 $c->prepare_write
2083
2084 Prepares the output for writing.
2085
2086 =cut
2087
2088 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2089
2090 =head2 $c->request_class
2091
2092 Returns or sets the request class.
2093
2094 =head2 $c->response_class
2095
2096 Returns or sets the response class.
2097
2098 =head2 $c->read( [$maxlength] )
2099
2100 Reads a chunk of data from the request body. This method is designed to
2101 be used in a while loop, reading C<$maxlength> bytes on every call.
2102 C<$maxlength> defaults to the size of the request if not specified.
2103
2104 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2105 directly.
2106
2107 Warning: If you use read(), Catalyst will not process the body,
2108 so you will not be able to access POST parameters or file uploads via
2109 $c->request.  You must handle all body parsing yourself.
2110
2111 =cut
2112
2113 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2114
2115 =head2 $c->run
2116
2117 Starts the engine.
2118
2119 =cut
2120
2121 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2122
2123 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2124
2125 Sets an action in a given namespace.
2126
2127 =cut
2128
2129 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2130
2131 =head2 $c->setup_actions($component)
2132
2133 Sets up actions for a component.
2134
2135 =cut
2136
2137 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2138
2139 =head2 $c->setup_components
2140
2141 This method is called internally to set up the application's components.
2142
2143 It finds modules by calling the L<locate_components> method, expands them to
2144 package names with the L<expand_component_module> method, and then installs
2145 each component into the application.
2146
2147 The C<setup_components> config option is passed to both of the above methods.
2148
2149 Installation of each component is performed by the L<setup_component> method,
2150 below.
2151
2152 =cut
2153
2154 sub setup_components {
2155     my $class = shift;
2156
2157     my $config  = $class->config->{ setup_components };
2158
2159     my @comps = sort { length $a <=> length $b }
2160                 $class->locate_components($config);
2161     my %comps = map { $_ => 1 } @comps;
2162
2163     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2164     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2165         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2166     ) if $deprecatedcatalyst_component_names;
2167
2168     for my $component ( @comps ) {
2169
2170         # We pass ignore_loaded here so that overlay files for (e.g.)
2171         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2172         # we know M::P::O found a file on disk so this is safe
2173
2174         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2175
2176         # Needs to be done as soon as the component is loaded, as loading a sub-component
2177         # (next time round the loop) can cause us to get the wrong metaclass..
2178         $class->_controller_init_base_classes($component);
2179     }
2180
2181     for my $component (@comps) {
2182         $class->components->{ $component } = $class->setup_component($component);
2183         for my $component ($class->expand_component_module( $component, $config )) {
2184             next if $comps{$component};
2185             $class->_controller_init_base_classes($component); # Also cover inner packages
2186             $class->components->{ $component } = $class->setup_component($component);
2187         }
2188     }
2189 }
2190
2191 =head2 $c->locate_components( $setup_component_config )
2192
2193 This method is meant to provide a list of component modules that should be
2194 setup for the application.  By default, it will use L<Module::Pluggable>.
2195
2196 Specify a C<setup_components> config option to pass additional options directly
2197 to L<Module::Pluggable>. To add additional search paths, specify a key named
2198 C<search_extra> as an array reference. Items in the array beginning with C<::>
2199 will have the application class name prepended to them.
2200
2201 =cut
2202
2203 sub locate_components {
2204     my $class  = shift;
2205     my $config = shift;
2206
2207     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2208     my $extra   = delete $config->{ search_extra } || [];
2209
2210     push @paths, @$extra;
2211
2212     my $locator = Module::Pluggable::Object->new(
2213         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2214         %$config
2215     );
2216
2217     my @comps = $locator->plugins;
2218
2219     return @comps;
2220 }
2221
2222 =head2 $c->expand_component_module( $component, $setup_component_config )
2223
2224 Components found by C<locate_components> will be passed to this method, which
2225 is expected to return a list of component (package) names to be set up.
2226
2227 =cut
2228
2229 sub expand_component_module {
2230     my ($class, $module) = @_;
2231     return Devel::InnerPackage::list_packages( $module );
2232 }
2233
2234 =head2 $c->setup_component
2235
2236 =cut
2237
2238 # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2239 #         nearest to Catalyst::Controller first, no matter what order stuff happens
2240 #         to be loaded. There are TODO tests in Moose for this, see
2241 #         f2391d17574eff81d911b97be15ea51080500003
2242 sub _controller_init_base_classes {
2243     my ($app_class, $component) = @_;
2244     return unless $component->isa('Catalyst::Controller');
2245     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2246         Moose::Meta::Class->initialize( $class )
2247             unless find_meta($class);
2248     }
2249 }
2250
2251 sub setup_component {
2252     my( $class, $component ) = @_;
2253
2254     unless ( $component->can( 'COMPONENT' ) ) {
2255         return $component;
2256     }
2257
2258     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2259     my $config = $class->config->{ $suffix } || {};
2260     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2261     # methods also pass it. local to avoid pointlessly shitting in config
2262     # for the debug screen, as $component is already the key name.
2263     local $config->{catalyst_component_name} = $component;
2264
2265     my $instance = eval { $component->COMPONENT( $class, $config ); };
2266
2267     if ( my $error = $@ ) {
2268         chomp $error;
2269         Catalyst::Exception->throw(
2270             message => qq/Couldn't instantiate component "$component", "$error"/
2271         );
2272     }
2273
2274     unless (blessed $instance) {
2275         my $metaclass = Moose::Util::find_meta($component);
2276         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2277         my $component_method_from = $method_meta->associated_metaclass->name;
2278         my $value = defined($instance) ? $instance : 'undef';
2279         Catalyst::Exception->throw(
2280             message =>
2281             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2282         );
2283     }
2284     return $instance;
2285 }
2286
2287 =head2 $c->setup_dispatcher
2288
2289 Sets up dispatcher.
2290
2291 =cut
2292
2293 sub setup_dispatcher {
2294     my ( $class, $dispatcher ) = @_;
2295
2296     if ($dispatcher) {
2297         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2298     }
2299
2300     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2301         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2302     }
2303
2304     unless ($dispatcher) {
2305         $dispatcher = $class->dispatcher_class;
2306     }
2307
2308     Class::MOP::load_class($dispatcher);
2309
2310     # dispatcher instance
2311     $class->dispatcher( $dispatcher->new );
2312 }
2313
2314 =head2 $c->setup_engine
2315
2316 Sets up engine.
2317
2318 =cut
2319
2320 sub setup_engine {
2321     my ( $class, $engine ) = @_;
2322
2323     if ($engine) {
2324         $engine = 'Catalyst::Engine::' . $engine;
2325     }
2326
2327     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2328         $engine = 'Catalyst::Engine::' . $env;
2329     }
2330
2331     if ( $ENV{MOD_PERL} ) {
2332         my $meta = Class::MOP::get_metaclass_by_name($class);
2333
2334         # create the apache method
2335         $meta->add_method('apache' => sub { shift->engine->apache });
2336
2337         my ( $software, $version ) =
2338           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2339
2340         $version =~ s/_//g;
2341         $version =~ s/(\.[^.]+)\./$1/g;
2342
2343         if ( $software eq 'mod_perl' ) {
2344
2345             if ( !$engine ) {
2346
2347                 if ( $version >= 1.99922 ) {
2348                     $engine = 'Catalyst::Engine::Apache2::MP20';
2349                 }
2350
2351                 elsif ( $version >= 1.9901 ) {
2352                     $engine = 'Catalyst::Engine::Apache2::MP19';
2353                 }
2354
2355                 elsif ( $version >= 1.24 ) {
2356                     $engine = 'Catalyst::Engine::Apache::MP13';
2357                 }
2358
2359                 else {
2360                     Catalyst::Exception->throw( message =>
2361                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2362                 }
2363
2364             }
2365
2366             # install the correct mod_perl handler
2367             if ( $version >= 1.9901 ) {
2368                 *handler = sub  : method {
2369                     shift->handle_request(@_);
2370                 };
2371             }
2372             else {
2373                 *handler = sub ($$) { shift->handle_request(@_) };
2374             }
2375
2376         }
2377
2378         elsif ( $software eq 'Zeus-Perl' ) {
2379             $engine = 'Catalyst::Engine::Zeus';
2380         }
2381
2382         else {
2383             Catalyst::Exception->throw(
2384                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2385         }
2386     }
2387
2388     unless ($engine) {
2389         $engine = $class->engine_class;
2390     }
2391
2392     Class::MOP::load_class($engine);
2393
2394     # check for old engines that are no longer compatible
2395     my $old_engine;
2396     if ( $engine->isa('Catalyst::Engine::Apache')
2397         && !Catalyst::Engine::Apache->VERSION )
2398     {
2399         $old_engine = 1;
2400     }
2401
2402     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2403         && Catalyst::Engine::Server->VERSION le '0.02' )
2404     {
2405         $old_engine = 1;
2406     }
2407
2408     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2409         && $engine->VERSION eq '0.01' )
2410     {
2411         $old_engine = 1;
2412     }
2413
2414     elsif ($engine->isa('Catalyst::Engine::Zeus')
2415         && $engine->VERSION eq '0.01' )
2416     {
2417         $old_engine = 1;
2418     }
2419
2420     if ($old_engine) {
2421         Catalyst::Exception->throw( message =>
2422               qq/Engine "$engine" is not supported by this version of Catalyst/
2423         );
2424     }
2425
2426     # engine instance
2427     $class->engine( $engine->new );
2428 }
2429
2430 =head2 $c->setup_home
2431
2432 Sets up the home directory.
2433
2434 =cut
2435
2436 sub setup_home {
2437     my ( $class, $home ) = @_;
2438
2439     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2440         $home = $env;
2441     }
2442
2443     $home ||= Catalyst::Utils::home($class);
2444
2445     if ($home) {
2446         #I remember recently being scolded for assigning config values like this
2447         $class->config->{home} ||= $home;
2448         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2449     }
2450 }
2451
2452 =head2 $c->setup_log
2453
2454 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2455 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2456 log to.
2457
2458 This method also installs a C<debug> method that returns a true value into the
2459 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2460 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2461
2462 Note that if the log has already been setup, by either a previous call to
2463 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2464 that this method won't actually set up the log object.
2465
2466 =cut
2467
2468 sub setup_log {
2469     my ( $class, $levels ) = @_;
2470
2471     $levels ||= '';
2472     $levels =~ s/^\s+//;
2473     $levels =~ s/\s+$//;
2474     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2475
2476     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2477     if ( defined $env_debug ) {
2478         $levels{debug} = 1 if $env_debug; # Ugly!
2479         delete($levels{debug}) unless $env_debug;
2480     }
2481
2482     unless ( $class->log ) {
2483         $class->log( Catalyst::Log->new(keys %levels) );
2484     }
2485
2486     if ( $levels{debug} ) {
2487         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2488         $class->log->debug('Debug messages enabled');
2489     }
2490 }
2491
2492 =head2 $c->setup_plugins
2493
2494 Sets up plugins.
2495
2496 =cut
2497
2498 =head2 $c->setup_stats
2499
2500 Sets up timing statistics class.
2501
2502 =cut
2503
2504 sub setup_stats {
2505     my ( $class, $stats ) = @_;
2506
2507     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2508
2509     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2510     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2511         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2512         $class->log->debug('Statistics enabled');
2513     }
2514 }
2515
2516
2517 =head2 $c->registered_plugins
2518
2519 Returns a sorted list of the plugins which have either been stated in the
2520 import list or which have been added via C<< MyApp->plugin(@args); >>.
2521
2522 If passed a given plugin name, it will report a boolean value indicating
2523 whether or not that plugin is loaded.  A fully qualified name is required if
2524 the plugin name does not begin with C<Catalyst::Plugin::>.
2525
2526  if ($c->registered_plugins('Some::Plugin')) {
2527      ...
2528  }
2529
2530 =cut
2531
2532 {
2533
2534     sub registered_plugins {
2535         my $proto = shift;
2536         return sort keys %{ $proto->_plugins } unless @_;
2537         my $plugin = shift;
2538         return 1 if exists $proto->_plugins->{$plugin};
2539         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2540     }
2541
2542     sub _register_plugin {
2543         my ( $proto, $plugin, $instant ) = @_;
2544         my $class = ref $proto || $proto;
2545
2546         Class::MOP::load_class( $plugin );
2547
2548         $proto->_plugins->{$plugin} = 1;
2549         unless ($instant) {
2550             no strict 'refs';
2551             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2552               my @superclasses = ($plugin, $meta->superclasses );
2553               $meta->superclasses(@superclasses);
2554             } else {
2555               unshift @{"$class\::ISA"}, $plugin;
2556             }
2557         }
2558         return $class;
2559     }
2560
2561     sub setup_plugins {
2562         my ( $class, $plugins ) = @_;
2563
2564         $class->_plugins( {} ) unless $class->_plugins;
2565         $plugins ||= [];
2566
2567         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2568
2569         for my $plugin ( reverse @plugins ) {
2570             Class::MOP::load_class($plugin);
2571             my $meta = find_meta($plugin);
2572             next if $meta && $meta->isa('Moose::Meta::Role');
2573
2574             $class->_register_plugin($plugin);
2575         }
2576
2577         my @roles =
2578             map { $_->name }
2579             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2580             map { find_meta($_) }
2581             @plugins;
2582
2583         Moose::Util::apply_all_roles(
2584             $class => @roles
2585         ) if @roles;
2586     }
2587 }
2588
2589 =head2 $c->stack
2590
2591 Returns an arrayref of the internal execution stack (actions that are
2592 currently executing).
2593
2594 =head2 $c->stats_class
2595
2596 Returns or sets the stats (timing statistics) class.
2597
2598 =head2 $c->use_stats
2599
2600 Returns 1 when stats collection is enabled.  Stats collection is enabled
2601 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2602 environment variable is set.
2603
2604 Note that this is a static method, not an accessor and should be overridden
2605 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2606
2607 =cut
2608
2609 sub use_stats { 0 }
2610
2611
2612 =head2 $c->write( $data )
2613
2614 Writes $data to the output stream. When using this method directly, you
2615 will need to manually set the C<Content-Length> header to the length of
2616 your output data, if known.
2617
2618 =cut
2619
2620 sub write {
2621     my $c = shift;
2622
2623     # Finalize headers if someone manually writes output
2624     $c->finalize_headers;
2625
2626     return $c->engine->write( $c, @_ );
2627 }
2628
2629 =head2 version
2630
2631 Returns the Catalyst version number. Mostly useful for "powered by"
2632 messages in template systems.
2633
2634 =cut
2635
2636 sub version { return $Catalyst::VERSION }
2637
2638 =head1 INTERNAL ACTIONS
2639
2640 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2641 C<_ACTION>, and C<_END>. These are by default not shown in the private
2642 action table, but you can make them visible with a config parameter.
2643
2644     MyApp->config(show_internal_actions => 1);
2645
2646 =head1 CASE SENSITIVITY
2647
2648 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2649 mapped to C</foo/bar>. You can activate case sensitivity with a config
2650 parameter.
2651
2652     MyApp->config(case_sensitive => 1);
2653
2654 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2655
2656 =head1 ON-DEMAND PARSER
2657
2658 The request body is usually parsed at the beginning of a request,
2659 but if you want to handle input yourself, you can enable on-demand
2660 parsing with a config parameter.
2661
2662     MyApp->config(parse_on_demand => 1);
2663
2664 =head1 PROXY SUPPORT
2665
2666 Many production servers operate using the common double-server approach,
2667 with a lightweight frontend web server passing requests to a larger
2668 backend server. An application running on the backend server must deal
2669 with two problems: the remote user always appears to be C<127.0.0.1> and
2670 the server's hostname will appear to be C<localhost> regardless of the
2671 virtual host that the user connected through.
2672
2673 Catalyst will automatically detect this situation when you are running
2674 the frontend and backend servers on the same machine. The following
2675 changes are made to the request.
2676
2677     $c->req->address is set to the user's real IP address, as read from
2678     the HTTP X-Forwarded-For header.
2679
2680     The host value for $c->req->base and $c->req->uri is set to the real
2681     host, as read from the HTTP X-Forwarded-Host header.
2682
2683 Additionally, you may be running your backend application on an insecure
2684 connection (port 80) while your frontend proxy is running under SSL.  If there
2685 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2686 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2687 be created properly.
2688
2689 In the case of passing in:
2690
2691     X-Forwarded-Port: 443
2692
2693 All calls to C<uri_for> will result in an https link, as is expected.
2694
2695 Obviously, your web server must support these headers for this to work.
2696
2697 In a more complex server farm environment where you may have your
2698 frontend proxy server(s) on different machines, you will need to set a
2699 configuration option to tell Catalyst to read the proxied data from the
2700 headers.
2701
2702     MyApp->config(using_frontend_proxy => 1);
2703
2704 If you do not wish to use the proxy support at all, you may set:
2705
2706     MyApp->config(ignore_frontend_proxy => 1);
2707
2708 =head1 THREAD SAFETY
2709
2710 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2711 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2712 believe the Catalyst core to be thread-safe.
2713
2714 If you plan to operate in a threaded environment, remember that all other
2715 modules you are using must also be thread-safe. Some modules, most notably
2716 L<DBD::SQLite>, are not thread-safe.
2717
2718 =head1 SUPPORT
2719
2720 IRC:
2721
2722     Join #catalyst on irc.perl.org.
2723
2724 Mailing Lists:
2725
2726     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2727     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2728
2729 Web:
2730
2731     http://catalyst.perl.org
2732
2733 Wiki:
2734
2735     http://dev.catalyst.perl.org
2736
2737 =head1 SEE ALSO
2738
2739 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2740
2741 =head2 L<Catalyst::Manual> - The Catalyst Manual
2742
2743 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2744
2745 =head2 L<Catalyst::Engine> - Core engine
2746
2747 =head2 L<Catalyst::Log> - Log class.
2748
2749 =head2 L<Catalyst::Request> - Request object
2750
2751 =head2 L<Catalyst::Response> - Response object
2752
2753 =head2 L<Catalyst::Test> - The test suite.
2754
2755 =head1 PROJECT FOUNDER
2756
2757 sri: Sebastian Riedel <sri@cpan.org>
2758
2759 =head1 CONTRIBUTORS
2760
2761 abw: Andy Wardley
2762
2763 acme: Leon Brocard <leon@astray.com>
2764
2765 Andrew Bramble
2766
2767 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
2768
2769 Andrew Ruthven
2770
2771 andyg: Andy Grundman <andy@hybridized.org>
2772
2773 audreyt: Audrey Tang
2774
2775 bricas: Brian Cassidy <bricas@cpan.org>
2776
2777 Caelum: Rafael Kitover <rkitover@io.com>
2778
2779 chansen: Christian Hansen
2780
2781 chicks: Christopher Hicks
2782
2783 Chisel Wright C<pause@herlpacker.co.uk>
2784
2785 Danijel Milicevic C<me@danijel.de>
2786
2787 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
2788
2789 David Naughton, C<naughton@umn.edu>
2790
2791 David E. Wheeler
2792
2793 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2794
2795 Drew Taylor
2796
2797 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2798
2799 esskar: Sascha Kiefer
2800
2801 fireartist: Carl Franks <cfranks@cpan.org>
2802
2803 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
2804
2805 gabb: Danijel Milicevic
2806
2807 Gary Ashton Jones
2808
2809 Gavin Henry C<ghenry@perl.me.uk>
2810
2811 Geoff Richards
2812
2813 groditi: Guillermo Roditi <groditi@gmail.com>
2814
2815 hobbs: Andrew Rodland <andrew@cleverdomain.org>
2816
2817 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2818
2819 jcamacho: Juan Camacho
2820
2821 jester: Jesse Sheidlower C<jester@panix.com>
2822
2823 jhannah: Jay Hannah <jay@jays.net>
2824
2825 Jody Belka
2826
2827 Johan Lindstrom
2828
2829 jon: Jon Schutz <jjschutz@cpan.org>
2830
2831 Jonathan Rockway C<< <jrockway@cpan.org> >>
2832
2833 Kieren Diment C<kd@totaldatasolution.com>
2834
2835 konobi: Scott McWhirter <konobi@cpan.org>
2836
2837 marcus: Marcus Ramberg <mramberg@cpan.org>
2838
2839 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2840
2841 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2842
2843 mugwump: Sam Vilain
2844
2845 naughton: David Naughton
2846
2847 ningu: David Kamholz <dkamholz@cpan.org>
2848
2849 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2850
2851 numa: Dan Sully <daniel@cpan.org>
2852
2853 obra: Jesse Vincent
2854
2855 omega: Andreas Marienborg
2856
2857 Oleg Kostyuk <cub.uanic@gmail.com>
2858
2859 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2860
2861 rafl: Florian Ragwitz <rafl@debian.org>
2862
2863 random: Roland Lammel <lammel@cpan.org>
2864
2865 Robert Sedlacek C<< <rs@474.at> >>
2866
2867 sky: Arthur Bergman
2868
2869 t0m: Tomas Doran <bobtfish@bobtfish.net>
2870
2871 Ulf Edvinsson
2872
2873 Viljo Marrandi C<vilts@yahoo.com>
2874
2875 Will Hawes C<info@whawes.co.uk>
2876
2877 willert: Sebastian Willert <willert@cpan.org>
2878
2879 Yuval Kogman, C<nothingmuch@woobling.org>
2880
2881 =head1 LICENSE
2882
2883 This library is free software. You can redistribute it and/or modify it under
2884 the same terms as Perl itself.
2885
2886 =cut
2887
2888 no Moose;
2889
2890 __PACKAGE__->meta->make_immutable;
2891
2892 1;