lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use bytes;
   8 use B::Hooks::EndOfScope ();
   9 use Catalyst::Exception;
  10 use Catalyst::Exception::Detach;
  11 use Catalyst::Exception::Go;
  12 use Catalyst::Log;
  13 use Catalyst::Request;
  14 use Catalyst::Request::Upload;
  15 use Catalyst::Response;
  16 use Catalyst::Utils;
  17 use Catalyst::Controller;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use attributes;
  31 use utf8;
  32 use Carp qw/croak carp shortmess/;
  33
  34 BEGIN { require 5.008001; }
  35
  36 has stack => (is => 'ro', default => sub { [] });
  37 has stash => (is => 'rw', default => sub { {} });
  38 has state => (is => 'rw', default => 0);
  39 has stats => (is => 'rw');
  40 has action => (is => 'rw');
  41 has counter => (is => 'rw', default => sub { {} });
  42 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  43 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  44 has namespace => (is => 'rw');
  45
  46 sub depth { scalar @{ shift->stack || [] }; }
  47 sub comp { shift->component(@_) }
  48
  49 sub req {
  50     my $self = shift; return $self->request(@_);
  51 }
  52 sub res {
  53     my $self = shift; return $self->response(@_);
  54 }
  55
  56 # For backwards compatibility
  57 sub finalize_output { shift->finalize_body(@_) };
  58
  59 # For statistics
  60 our $COUNT     = 1;
  61 our $START     = time;
  62 our $RECURSION = 1000;
  63 our $DETACH    = Catalyst::Exception::Detach->new;
  64 our $GO        = Catalyst::Exception::Go->new;
  65
  66 #I imagine that very few of these really need to be class variables. if any.
  67 #maybe we should just make them attributes with a default?
  68 __PACKAGE__->mk_classdata($_)
  69   for qw/components arguments dispatcher engine log dispatcher_class
  70   engine_class context_class request_class response_class stats_class
  71   setup_finished/;
  72
  73 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  74 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  75 __PACKAGE__->request_class('Catalyst::Request');
  76 __PACKAGE__->response_class('Catalyst::Response');
  77 __PACKAGE__->stats_class('Catalyst::Stats');
  78
  79 # Remember to update this in Catalyst::Runtime as well!
  80
  81 our $VERSION = '5.80007';
  82
  83 {
  84     my $dev_version = $VERSION =~ /_\d{2}$/;
  85     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  86 }
  87
  88 $VERSION = eval $VERSION;
  89
  90 sub import {
  91     my ( $class, @arguments ) = @_;
  92
  93     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  94     # callers @ISA.
  95     return unless $class eq 'Catalyst';
  96
  97     my $caller = caller();
  98     return if $caller eq 'main';
  99
 100     # Kill Adopt::NEXT warnings if we're a non-RC version
 101     unless (_IS_DEVELOPMENT_VERSION()) {
 102         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 103     }
 104
 105     my $meta = Moose::Meta::Class->initialize($caller);
 106     unless ( $caller->isa('Catalyst') ) {
 107         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 108         $meta->superclasses(@superclasses);
 109     }
 110     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 111     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 112
 113     unless( $meta->has_method('meta') ){
 114         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 115     }
 116
 117     $caller->arguments( [@arguments] );
 118     $caller->setup_home;
 119 }
 120
 121 sub _application { $_[0] }
 122
 123 =head1 NAME
 124
 125 Catalyst - The Elegant MVC Web Application Framework
 126
 127 =head1 SYNOPSIS
 128
 129 See the L<Catalyst::Manual> distribution for comprehensive
 130 documentation and tutorials.
 131
 132     # Install Catalyst::Devel for helpers and other development tools
 133     # use the helper to create a new application
 134     catalyst.pl MyApp
 135
 136     # add models, views, controllers
 137     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 138     script/myapp_create.pl view MyTemplate TT
 139     script/myapp_create.pl controller Search
 140
 141     # built in testserver -- use -r to restart automatically on changes
 142     # --help to see all available options
 143     script/myapp_server.pl
 144
 145     # command line testing interface
 146     script/myapp_test.pl /yada
 147
 148     ### in lib/MyApp.pm
 149     use Catalyst qw/-Debug/; # include plugins here as well
 150
 151     ### In lib/MyApp/Controller/Root.pm (autocreated)
 152     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 153         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 154         $c->stash->{template} = 'foo.tt'; # set the template
 155         # lookup something from db -- stash vars are passed to TT
 156         $c->stash->{data} =
 157           $c->model('Database::Foo')->search( { country => $args[0] } );
 158         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 159             $c->forward( 'bar' ); # process another action
 160             # do something else after forward returns
 161         }
 162     }
 163
 164     # The foo.tt TT template can use the stash data from the database
 165     [% WHILE (item = data.next) %]
 166         [% item.foo %]
 167     [% END %]
 168
 169     # called for /bar/of/soap, /bar/of/soap/10, etc.
 170     sub bar : Path('/bar/of/soap') { ... }
 171
 172     # called for all actions, from the top-most controller downwards
 173     sub auto : Private {
 174         my ( $self, $c ) = @_;
 175         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 176             $c->res->redirect( '/login' ); # require login
 177             return 0; # abort request and go immediately to end()
 178         }
 179         return 1; # success; carry on to next action
 180     }
 181
 182     # called after all actions are finished
 183     sub end : Private {
 184         my ( $self, $c ) = @_;
 185         if ( scalar @{ $c->error } ) { ... } # handle errors
 186         return if $c->res->body; # already have a response
 187         $c->forward( 'MyApp::View::TT' ); # render template
 188     }
 189
 190     ### in MyApp/Controller/Foo.pm
 191     # called for /foo/bar
 192     sub bar : Local { ... }
 193
 194     # called for /blargle
 195     sub blargle : Global { ... }
 196
 197     # an index action matches /foo, but not /foo/1, etc.
 198     sub index : Private { ... }
 199
 200     ### in MyApp/Controller/Foo/Bar.pm
 201     # called for /foo/bar/baz
 202     sub baz : Local { ... }
 203
 204     # first Root auto is called, then Foo auto, then this
 205     sub auto : Private { ... }
 206
 207     # powerful regular expression paths are also possible
 208     sub details : Regex('^product/(\w+)/details$') {
 209         my ( $self, $c ) = @_;
 210         # extract the (\w+) from the URI
 211         my $product = $c->req->captures->[0];
 212     }
 213
 214 See L<Catalyst::Manual::Intro> for additional information.
 215
 216 =head1 DESCRIPTION
 217
 218 Catalyst is a modern framework for making web applications without the
 219 pain usually associated with this process. This document is a reference
 220 to the main Catalyst application. If you are a new user, we suggest you
 221 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 222
 223 See L<Catalyst::Manual> for more documentation.
 224
 225 Catalyst plugins can be loaded by naming them as arguments to the "use
 226 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 227 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 228 C<My::Module>.
 229
 230     use Catalyst qw/My::Module/;
 231
 232 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 233 fully qualify the name by using a unary plus:
 234
 235     use Catalyst qw/
 236         My::Module
 237         +Fully::Qualified::Plugin::Name
 238     /;
 239
 240 Special flags like C<-Debug> and C<-Engine> can also be specified as
 241 arguments when Catalyst is loaded:
 242
 243     use Catalyst qw/-Debug My::Module/;
 244
 245 The position of plugins and flags in the chain is important, because
 246 they are loaded in the order in which they appear.
 247
 248 The following flags are supported:
 249
 250 =head2 -Debug
 251
 252 Enables debug output. You can also force this setting from the system
 253 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 254 settings override the application, with <MYAPP>_DEBUG having the highest
 255 priority.
 256
 257 =head2 -Engine
 258
 259 Forces Catalyst to use a specific engine. Omit the
 260 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 261
 262     use Catalyst qw/-Engine=CGI/;
 263
 264 =head2 -Home
 265
 266 Forces Catalyst to use a specific home directory, e.g.:
 267
 268     use Catalyst qw[-Home=/usr/mst];
 269
 270 This can also be done in the shell environment by setting either the
 271 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 272 is replaced with the uppercased name of your application, any "::" in
 273 the name will be replaced with underscores, e.g. MyApp::Web should use
 274 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 275
 276 =head2 -Log
 277
 278     use Catalyst '-Log=warn,fatal,error';
 279
 280 Specifies a comma-delimited list of log levels.
 281
 282 =head2 -Stats
 283
 284 Enables statistics collection and reporting. You can also force this setting
 285 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 286 environment settings override the application, with <MYAPP>_STATS having the
 287 highest priority.
 288
 289 e.g.
 290
 291    use Catalyst qw/-Stats=1/
 292
 293 =head1 METHODS
 294
 295 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 296
 297 =head2 $c->action
 298
 299 Returns a L<Catalyst::Action> object for the current action, which
 300 stringifies to the action name. See L<Catalyst::Action>.
 301
 302 =head2 $c->namespace
 303
 304 Returns the namespace of the current action, i.e., the URI prefix
 305 corresponding to the controller of the current action. For example:
 306
 307     # in Controller::Foo::Bar
 308     $c->namespace; # returns 'foo/bar';
 309
 310 =head2 $c->request
 311
 312 =head2 $c->req
 313
 314 Returns the current L<Catalyst::Request> object, giving access to
 315 information about the current client request (including parameters,
 316 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 317
 318 =head2 REQUEST FLOW HANDLING
 319
 320 =head2 $c->forward( $action [, \@arguments ] )
 321
 322 =head2 $c->forward( $class, $method, [, \@arguments ] )
 323
 324 Forwards processing to another action, by its private name. If you give a
 325 class name but no method, C<process()> is called. You may also optionally
 326 pass arguments in an arrayref. The action will receive the arguments in
 327 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 328 C<< $c->req->args >> will be restored to the previous values.
 329
 330 Any data C<return>ed from the action forwarded to, will be returned by the
 331 call to forward.
 332
 333     my $foodata = $c->forward('/foo');
 334     $c->forward('index');
 335     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 336     $c->forward('MyApp::View::TT');
 337
 338 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 339 an C<< eval { } >> around the call (actually
 340 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 341 all 'dies' within the called action. If you want C<die> to propagate you
 342 need to do something like:
 343
 344     $c->forward('foo');
 345     die $c->error if $c->error;
 346
 347 Or make sure to always return true values from your actions and write
 348 your code like this:
 349
 350     $c->forward('foo') || return;
 351
 352 =cut
 353
 354 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 355
 356 =head2 $c->detach( $action [, \@arguments ] )
 357
 358 =head2 $c->detach( $class, $method, [, \@arguments ] )
 359
 360 =head2 $c->detach()
 361
 362 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 363 doesn't return to the previous action when processing is finished.
 364
 365 When called with no arguments it escapes the processing chain entirely.
 366
 367 =cut
 368
 369 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 370
 371 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 372
 373 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 374
 375 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 376 but does a full dispatch, instead of just calling the new C<$action> /
 377 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 378 you go to are called, just like a new request.
 379
 380 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 381 This means, for example, that C<< $c->action >> methods such as
 382 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 383 L<reverse|Catalyst::Action/reverse> return information for the visited action
 384 when they are invoked within the visited action.  This is different from the
 385 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 386 continues to use the $c->action object from the caller action even when
 387 invoked from the callee.
 388
 389 C<< $c->stash >> is kept unchanged.
 390
 391 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 392 allows you to "wrap" another action, just as it would have been called by
 393 dispatching from a URL, while the analogous
 394 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 395 transfer control to another action as if it had been reached directly from a URL.
 396
 397 =cut
 398
 399 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 400
 401 =head2 $c->go( $action [, \@captures, \@arguments ] )
 402
 403 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 404
 405 Almost the same as L<< detach|/"$c->detach( $action [, \@arguments ] )" >>, but does a full dispatch like L</visit>,
 406 instead of just calling the new C<$action> /
 407 C<< $class->$method >>. This means that C<begin>, C<auto> and the
 408 method you visit are called, just like a new request.
 409
 410 C<< $c->stash >> is kept unchanged.
 411
 412 =cut
 413
 414 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 415
 416 =head2 $c->response
 417
 418 =head2 $c->res
 419
 420 Returns the current L<Catalyst::Response> object, see there for details.
 421
 422 =head2 $c->stash
 423
 424 Returns a hashref to the stash, which may be used to store data and pass
 425 it between components during a request. You can also set hash keys by
 426 passing arguments. The stash is automatically sent to the view. The
 427 stash is cleared at the end of a request; it cannot be used for
 428 persistent storage (for this you must use a session; see
 429 L<Catalyst::Plugin::Session> for a complete system integrated with
 430 Catalyst).
 431
 432     $c->stash->{foo} = $bar;
 433     $c->stash( { moose => 'majestic', qux => 0 } );
 434     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 435
 436     # stash is automatically passed to the view for use in a template
 437     $c->forward( 'MyApp::View::TT' );
 438
 439 =cut
 440
 441 around stash => sub {
 442     my $orig = shift;
 443     my $c = shift;
 444     my $stash = $orig->($c);
 445     if (@_) {
 446         my $new_stash = @_ > 1 ? {@_} : $_[0];
 447         croak('stash takes a hash or hashref') unless ref $new_stash;
 448         foreach my $key ( keys %$new_stash ) {
 449           $stash->{$key} = $new_stash->{$key};
 450         }
 451     }
 452
 453     return $stash;
 454 };
 455
 456
 457 =head2 $c->error
 458
 459 =head2 $c->error($error, ...)
 460
 461 =head2 $c->error($arrayref)
 462
 463 Returns an arrayref containing error messages.  If Catalyst encounters an
 464 error while processing a request, it stores the error in $c->error.  This
 465 method should only be used to store fatal error messages.
 466
 467     my @error = @{ $c->error };
 468
 469 Add a new error.
 470
 471     $c->error('Something bad happened');
 472
 473 =cut
 474
 475 sub error {
 476     my $c = shift;
 477     if ( $_[0] ) {
 478         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 479         croak @$error unless ref $c;
 480         push @{ $c->{error} }, @$error;
 481     }
 482     elsif ( defined $_[0] ) { $c->{error} = undef }
 483     return $c->{error} || [];
 484 }
 485
 486
 487 =head2 $c->state
 488
 489 Contains the return value of the last executed action.
 490
 491 =head2 $c->clear_errors
 492
 493 Clear errors.  You probably don't want to clear the errors unless you are
 494 implementing a custom error screen.
 495
 496 This is equivalent to running
 497
 498     $c->error(0);
 499
 500 =cut
 501
 502 sub clear_errors {
 503     my $c = shift;
 504     $c->error(0);
 505 }
 506
 507 sub _comp_search_prefixes {
 508     my $c = shift;
 509     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 510 }
 511
 512 # search components given a name and some prefixes
 513 sub _comp_names_search_prefixes {
 514     my ( $c, $name, @prefixes ) = @_;
 515     my $appclass = ref $c || $c;
 516     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 517     $filter = qr/$filter/; # Compile regex now rather than once per loop
 518
 519     # map the original component name to the sub part that we will search against
 520     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 521         grep { /$filter/ } keys %{ $c->components };
 522
 523     # undef for a name will return all
 524     return keys %eligible if !defined $name;
 525
 526     my $query  = ref $name ? $name : qr/^$name$/i;
 527     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 528
 529     return @result if @result;
 530
 531     # if we were given a regexp to search against, we're done.
 532     return if ref $name;
 533
 534     # regexp fallback
 535     $query  = qr/$name/i;
 536     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 537
 538     # no results? try against full names
 539     if( !@result ) {
 540         @result = grep { m{$query} } keys %eligible;
 541     }
 542
 543     # don't warn if we didn't find any results, it just might not exist
 544     if( @result ) {
 545         # Disgusting hack to work out correct method name
 546         my $warn_for = lc $prefixes[0];
 547         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 548            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 549            "component resolution is unreliable and unsafe.";
 550         my $short = $result[0];
 551         $short =~ s/.*?Model:://;
 552         my $shortmess = Carp::shortmess('');
 553         if ($shortmess =~ m#Catalyst/Plugin#) {
 554            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 555               "plugin's config";
 556         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 557            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 558               "component's config";
 559         } else {
 560            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 561               "but if you really wanted to search, pass in a regexp as the argument " .
 562               "like so: \$c->${warn_for}(qr/${name}/)";
 563         }
 564         $c->log->warn( "${msg}$shortmess" );
 565     }
 566
 567     return @result;
 568 }
 569
 570 # Find possible names for a prefix
 571 sub _comp_names {
 572     my ( $c, @prefixes ) = @_;
 573     my $appclass = ref $c || $c;
 574
 575     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 576
 577     my @names = map { s{$filter}{}; $_; }
 578         $c->_comp_names_search_prefixes( undef, @prefixes );
 579
 580     return @names;
 581 }
 582
 583 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 584 sub _filter_component {
 585     my ( $c, $comp, @args ) = @_;
 586
 587     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 588         return $comp->ACCEPT_CONTEXT( $c, @args );
 589     }
 590
 591     return $comp;
 592 }
 593
 594 =head2 COMPONENT ACCESSORS
 595
 596 =head2 $c->controller($name)
 597
 598 Gets a L<Catalyst::Controller> instance by name.
 599
 600     $c->controller('Foo')->do_stuff;
 601
 602 If the name is omitted, will return the controller for the dispatched
 603 action.
 604
 605 If you want to search for controllers, pass in a regexp as the argument.
 606
 607     # find all controllers that start with Foo
 608     my @foo_controllers = $c->controller(qr{^Foo});
 609
 610
 611 =cut
 612
 613 sub controller {
 614     my ( $c, $name, @args ) = @_;
 615
 616     if( $name ) {
 617         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 618         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 619         return $c->_filter_component( $result[ 0 ], @args );
 620     }
 621
 622     return $c->component( $c->action->class );
 623 }
 624
 625 =head2 $c->model($name)
 626
 627 Gets a L<Catalyst::Model> instance by name.
 628
 629     $c->model('Foo')->do_stuff;
 630
 631 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 632
 633 If the name is omitted, it will look for
 634  - a model object in $c->stash->{current_model_instance}, then
 635  - a model name in $c->stash->{current_model}, then
 636  - a config setting 'default_model', or
 637  - check if there is only one model, and return it if that's the case.
 638
 639 If you want to search for models, pass in a regexp as the argument.
 640
 641     # find all models that start with Foo
 642     my @foo_models = $c->model(qr{^Foo});
 643
 644 =cut
 645
 646 sub model {
 647     my ( $c, $name, @args ) = @_;
 648
 649     if( $name ) {
 650         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 651         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 652         return $c->_filter_component( $result[ 0 ], @args );
 653     }
 654
 655     if (ref $c) {
 656         return $c->stash->{current_model_instance}
 657           if $c->stash->{current_model_instance};
 658         return $c->model( $c->stash->{current_model} )
 659           if $c->stash->{current_model};
 660     }
 661     return $c->model( $c->config->{default_model} )
 662       if $c->config->{default_model};
 663
 664     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 665
 666     if( $rest ) {
 667         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 668         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 669         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 670         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 671         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 672     }
 673
 674     return $c->_filter_component( $comp );
 675 }
 676
 677
 678 =head2 $c->view($name)
 679
 680 Gets a L<Catalyst::View> instance by name.
 681
 682     $c->view('Foo')->do_stuff;
 683
 684 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 685
 686 If the name is omitted, it will look for
 687  - a view object in $c->stash->{current_view_instance}, then
 688  - a view name in $c->stash->{current_view}, then
 689  - a config setting 'default_view', or
 690  - check if there is only one view, and return it if that's the case.
 691
 692 If you want to search for views, pass in a regexp as the argument.
 693
 694     # find all views that start with Foo
 695     my @foo_views = $c->view(qr{^Foo});
 696
 697 =cut
 698
 699 sub view {
 700     my ( $c, $name, @args ) = @_;
 701
 702     if( $name ) {
 703         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 704         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 705         return $c->_filter_component( $result[ 0 ], @args );
 706     }
 707
 708     if (ref $c) {
 709         return $c->stash->{current_view_instance}
 710           if $c->stash->{current_view_instance};
 711         return $c->view( $c->stash->{current_view} )
 712           if $c->stash->{current_view};
 713     }
 714     return $c->view( $c->config->{default_view} )
 715       if $c->config->{default_view};
 716
 717     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 718
 719     if( $rest ) {
 720         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 721         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 722         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 723         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 724         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 725     }
 726
 727     return $c->_filter_component( $comp );
 728 }
 729
 730 =head2 $c->controllers
 731
 732 Returns the available names which can be passed to $c->controller
 733
 734 =cut
 735
 736 sub controllers {
 737     my ( $c ) = @_;
 738     return $c->_comp_names(qw/Controller C/);
 739 }
 740
 741 =head2 $c->models
 742
 743 Returns the available names which can be passed to $c->model
 744
 745 =cut
 746
 747 sub models {
 748     my ( $c ) = @_;
 749     return $c->_comp_names(qw/Model M/);
 750 }
 751
 752
 753 =head2 $c->views
 754
 755 Returns the available names which can be passed to $c->view
 756
 757 =cut
 758
 759 sub views {
 760     my ( $c ) = @_;
 761     return $c->_comp_names(qw/View V/);
 762 }
 763
 764 =head2 $c->comp($name)
 765
 766 =head2 $c->component($name)
 767
 768 Gets a component object by name. This method is not recommended,
 769 unless you want to get a specific component by full
 770 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 771 should be used instead.
 772
 773 If C<$name> is a regexp, a list of components matched against the full
 774 component name will be returned.
 775
 776 =cut
 777
 778 sub component {
 779     my ( $c, $name, @args ) = @_;
 780
 781     if( $name ) {
 782         my $comps = $c->components;
 783
 784         if( !ref $name ) {
 785             # is it the exact name?
 786             return $c->_filter_component( $comps->{ $name }, @args )
 787                        if exists $comps->{ $name };
 788
 789             # perhaps we just omitted "MyApp"?
 790             my $composed = ( ref $c || $c ) . "::${name}";
 791             return $c->_filter_component( $comps->{ $composed }, @args )
 792                        if exists $comps->{ $composed };
 793
 794             # search all of the models, views and controllers
 795             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 796             return $c->_filter_component( $comp, @args ) if $comp;
 797         }
 798
 799         # This is here so $c->comp( '::M::' ) works
 800         my $query = ref $name ? $name : qr{$name}i;
 801
 802         my @result = grep { m{$query} } keys %{ $c->components };
 803         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 804
 805         if( $result[ 0 ] ) {
 806             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 807             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 808             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 809             return $c->_filter_component( $result[ 0 ], @args );
 810         }
 811
 812         # I would expect to return an empty list here, but that breaks back-compat
 813     }
 814
 815     # fallback
 816     return sort keys %{ $c->components };
 817 }
 818
 819 =head2 CLASS DATA AND HELPER CLASSES
 820
 821 =head2 $c->config
 822
 823 Returns or takes a hashref containing the application's configuration.
 824
 825     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 826
 827 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 828 like C<myapp.conf> in your applications home directory. See
 829 L<Catalyst::Plugin::ConfigLoader>.
 830
 831 =head3 Cascading configuration
 832
 833 The config method is present on all Catalyst components, and configuration
 834 will be merged when an application is started. Configuration loaded with
 835 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 836 followed by configuration in your top level C<MyApp> class. These two
 837 configurations are merged, and then configuration data whose hash key matches a
 838 component name is merged with configuration for that component.
 839
 840 The configuration for a component is then passed to the C<new> method when a
 841 component is constructed.
 842
 843 For example:
 844
 845     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 846     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 847
 848 will mean that C<MyApp::Model::Foo> receives the following data when
 849 constructed:
 850
 851     MyApp::Model::Foo->new({
 852         bar => 'baz',
 853         quux => 'frob',
 854         overrides => 'me',
 855     });
 856
 857 =cut
 858
 859 around config => sub {
 860     my $orig = shift;
 861     my $c = shift;
 862
 863     croak('Setting config after setup has been run is not allowed.')
 864         if ( @_ and $c->setup_finished );
 865
 866     $c->$orig(@_);
 867 };
 868
 869 =head2 $c->log
 870
 871 Returns the logging object instance. Unless it is already set, Catalyst
 872 sets this up with a L<Catalyst::Log> object. To use your own log class,
 873 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 874 C<< __PACKAGE__->setup >>.
 875
 876  __PACKAGE__->log( MyLogger->new );
 877  __PACKAGE__->setup;
 878
 879 And later:
 880
 881     $c->log->info( 'Now logging with my own logger!' );
 882
 883 Your log class should implement the methods described in
 884 L<Catalyst::Log>.
 885
 886
 887 =head2 $c->debug
 888
 889 Returns 1 if debug mode is enabled, 0 otherwise.
 890
 891 You can enable debug mode in several ways:
 892
 893 =over
 894
 895 =item By calling myapp_server.pl with the -d flag
 896
 897 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 898
 899 =item The -Debug option in your MyApp.pm
 900
 901 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 902
 903 =back
 904
 905 Calling C<< $c->debug(1) >> has no effect.
 906
 907 =cut
 908
 909 sub debug { 0 }
 910
 911 =head2 $c->dispatcher
 912
 913 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 914
 915 =head2 $c->engine
 916
 917 Returns the engine instance. See L<Catalyst::Engine>.
 918
 919
 920 =head2 UTILITY METHODS
 921
 922 =head2 $c->path_to(@path)
 923
 924 Merges C<@path> with C<< $c->config->{home} >> and returns a
 925 L<Path::Class::Dir> object. Note you can usually use this object as
 926 a filename, but sometimes you will have to explicitly stringify it
 927 yourself by calling the C<< ->stringify >> method.
 928
 929 For example:
 930
 931     $c->path_to( 'db', 'sqlite.db' );
 932
 933 =cut
 934
 935 sub path_to {
 936     my ( $c, @path ) = @_;
 937     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 938     if ( -d $path ) { return $path }
 939     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 940 }
 941
 942 =head2 $c->plugin( $name, $class, @args )
 943
 944 Helper method for plugins. It creates a class data accessor/mutator and
 945 loads and instantiates the given class.
 946
 947     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 948
 949     $c->prototype->define_javascript_functions;
 950
 951 B<Note:> This method of adding plugins is deprecated. The ability
 952 to add plugins like this B<will be removed> in a Catalyst 5.81.
 953 Please do not use this functionality in new code.
 954
 955 =cut
 956
 957 sub plugin {
 958     my ( $class, $name, $plugin, @args ) = @_;
 959
 960     # See block comment in t/unit_core_plugin.t
 961     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 962
 963     $class->_register_plugin( $plugin, 1 );
 964
 965     eval { $plugin->import };
 966     $class->mk_classdata($name);
 967     my $obj;
 968     eval { $obj = $plugin->new(@args) };
 969
 970     if ($@) {
 971         Catalyst::Exception->throw( message =>
 972               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 973     }
 974
 975     $class->$name($obj);
 976     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 977       if $class->debug;
 978 }
 979
 980 =head2 MyApp->setup
 981
 982 Initializes the dispatcher and engine, loads any plugins, and loads the
 983 model, view, and controller components. You may also specify an array
 984 of plugins to load here, if you choose to not load them in the C<use
 985 Catalyst> line.
 986
 987     MyApp->setup;
 988     MyApp->setup( qw/-Debug/ );
 989
 990 =cut
 991
 992 sub setup {
 993     my ( $class, @arguments ) = @_;
 994     croak('Running setup more than once')
 995         if ( $class->setup_finished );
 996
 997     unless ( $class->isa('Catalyst') ) {
 998
 999         Catalyst::Exception->throw(
1000             message => qq/'$class' does not inherit from Catalyst/ );
1001     }
1002
1003     if ( $class->arguments ) {
1004         @arguments = ( @arguments, @{ $class->arguments } );
1005     }
1006
1007     # Process options
1008     my $flags = {};
1009
1010     foreach (@arguments) {
1011
1012         if (/^-Debug$/) {
1013             $flags->{log} =
1014               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1015         }
1016         elsif (/^-(\w+)=?(.*)$/) {
1017             $flags->{ lc $1 } = $2;
1018         }
1019         else {
1020             push @{ $flags->{plugins} }, $_;
1021         }
1022     }
1023
1024     $class->setup_home( delete $flags->{home} );
1025
1026     $class->setup_log( delete $flags->{log} );
1027     $class->setup_plugins( delete $flags->{plugins} );
1028     $class->setup_dispatcher( delete $flags->{dispatcher} );
1029     $class->setup_engine( delete $flags->{engine} );
1030     $class->setup_stats( delete $flags->{stats} );
1031
1032     for my $flag ( sort keys %{$flags} ) {
1033
1034         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1035             &$code( $class, delete $flags->{$flag} );
1036         }
1037         else {
1038             $class->log->warn(qq/Unknown flag "$flag"/);
1039         }
1040     }
1041
1042     eval { require Catalyst::Devel; };
1043     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1044         $class->log->warn(<<"EOF");
1045 You are running an old script!
1046
1047   Please update by running (this will overwrite existing files):
1048     catalyst.pl -force -scripts $class
1049
1050   or (this will not overwrite existing files):
1051     catalyst.pl -scripts $class
1052
1053 EOF
1054     }
1055
1056     if ( $class->debug ) {
1057         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1058
1059         if (@plugins) {
1060             my $column_width = Catalyst::Utils::term_width() - 6;
1061             my $t = Text::SimpleTable->new($column_width);
1062             $t->row($_) for @plugins;
1063             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1064         }
1065
1066         my $dispatcher = $class->dispatcher;
1067         my $engine     = $class->engine;
1068         my $home       = $class->config->{home};
1069
1070         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1071         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1072
1073         $home
1074           ? ( -d $home )
1075           ? $class->log->debug(qq/Found home "$home"/)
1076           : $class->log->debug(qq/Home "$home" doesn't exist/)
1077           : $class->log->debug(q/Couldn't find home/);
1078     }
1079
1080     # Call plugins setup, this is stupid and evil.
1081     # Also screws C3 badly on 5.10, hack to avoid.
1082     {
1083         no warnings qw/redefine/;
1084         local *setup = sub { };
1085         $class->setup unless $Catalyst::__AM_RESTARTING;
1086     }
1087
1088     # Initialize our data structure
1089     $class->components( {} );
1090
1091     $class->setup_components;
1092
1093     if ( $class->debug ) {
1094         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1095         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1096         for my $comp ( sort keys %{ $class->components } ) {
1097             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1098             $t->row( $comp, $type );
1099         }
1100         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1101           if ( keys %{ $class->components } );
1102     }
1103
1104     # Add our self to components, since we are also a component
1105     if( $class->isa('Catalyst::Controller') ){
1106       $class->components->{$class} = $class;
1107     }
1108
1109     $class->setup_actions;
1110
1111     if ( $class->debug ) {
1112         my $name = $class->config->{name} || 'Application';
1113         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1114     }
1115     $class->log->_flush() if $class->log->can('_flush');
1116
1117     # Make sure that the application class becomes immutable at this point,
1118     B::Hooks::EndOfScope::on_scope_end {
1119         return if $@;
1120         my $meta = Class::MOP::get_metaclass_by_name($class);
1121         if (
1122             $meta->is_immutable
1123             && ! { $meta->immutable_options }->{replace_constructor}
1124             && (
1125                    $class->isa('Class::Accessor::Fast')
1126                 || $class->isa('Class::Accessor')
1127             )
1128         ) {
1129             warn "You made your application class ($class) immutable, "
1130                 . "but did not inline the\nconstructor. "
1131                 . "This will break catalyst, as your app \@ISA "
1132                 . "Class::Accessor(::Fast)?\nPlease pass "
1133                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1134         }
1135         $meta->make_immutable(replace_constructor => 1)
1136             unless $meta->is_immutable;
1137     };
1138
1139     $class->setup_finalize;
1140 }
1141
1142
1143 =head2 $app->setup_finalize
1144
1145 A hook to attach modifiers to.
1146 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1147 Also better than C< setup_finished(); >, as that is a getter method.
1148
1149     sub setup_finalize {
1150
1151         my $app = shift;
1152
1153         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1154
1155         $app->next::method(@_);
1156
1157
1158     }
1159
1160 =cut
1161
1162 sub setup_finalize {
1163     my ($class) = @_;
1164     $class->setup_finished(1);
1165 }
1166
1167 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1168
1169 =head2 $c->uri_for( $path, @args?, \%query_values? )
1170
1171 =over
1172
1173 =item $action
1174
1175 A L<Catalyst::Action> object representing the Catalyst action you want to
1176 create a URI for. To get one for an action in the current controller,
1177 use C<< $c->action('someactionname') >>. To get one from a different
1178 controller, fetch the controller using C<< $c->controller() >>, then
1179 call C<action_for|Catalyst::Controller/"$self->action_for('name')"> on it.
1180
1181 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1182 using C<< $c->req->captures >>.
1183
1184   # For the current action
1185   $c->uri_for($c->action, $c->req->captures);
1186
1187   # For the Foo action in the Bar controller
1188   $c->uri_for($c->controller('Bar')->action_for('Foo'), $c->req->captures);
1189
1190 =back
1191
1192 =cut
1193
1194 sub uri_for {
1195     my ( $c, $path, @args ) = @_;
1196
1197     if ( blessed($path) ) { # action object
1198         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1199                          ? shift(@args)
1200                          : [] );
1201         my $action = $path;
1202         $path = $c->dispatcher->uri_for_action($action, $captures);
1203         if (not defined $path) {
1204             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1205                 if $c->debug;
1206             return undef;
1207         }
1208         $path = '/' if $path eq '';
1209     }
1210
1211     undef($path) if (defined $path && $path eq '');
1212
1213     my $params =
1214       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1215
1216     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1217     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1218
1219     unshift(@args, $path);
1220
1221     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1222         my $namespace = $c->namespace;
1223         if (defined $path) { # cheesy hack to handle path '../foo'
1224            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1225         }
1226         unshift(@args, $namespace || '');
1227     }
1228
1229     # join args with '/', or a blank string
1230     my $args = join('/', grep { defined($_) } @args);
1231     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1232     $args =~ s!^/+!!;
1233     my $base = $c->req->base;
1234     my $class = ref($base);
1235     $base =~ s{(?<!/)$}{/};
1236
1237     my $query = '';
1238
1239     if (my @keys = keys %$params) {
1240       # somewhat lifted from URI::_query's query_form
1241       $query = '?'.join('&', map {
1242           my $val = $params->{$_};
1243           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1244           s/ /+/g;
1245           my $key = $_;
1246           $val = '' unless defined $val;
1247           (map {
1248               my $param = "$_";
1249               utf8::encode( $param ) if utf8::is_utf8($param);
1250               # using the URI::Escape pattern here so utf8 chars survive
1251               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1252               $param =~ s/ /+/g;
1253               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1254       } @keys);
1255     }
1256
1257     my $res = bless(\"${base}${args}${query}", $class);
1258     $res;
1259 }
1260
1261 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1262
1263 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1264
1265 =over
1266
1267 =item $path
1268
1269 A private path to the Catalyst action you want to create a URI for.
1270
1271 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1272 >> and passing the resulting C<$action> and the remaining arguments to C<<
1273 $c->uri_for >>.
1274
1275 You can also pass in a Catalyst::Action object, in which case it is passed to
1276 C<< $c->uri_for >>.
1277
1278 =back
1279
1280 =cut
1281
1282 sub uri_for_action {
1283     my ( $c, $path, @args ) = @_;
1284     my $action = blessed($path)
1285       ? $path
1286       : $c->dispatcher->get_action_by_path($path);
1287     unless (defined $action) {
1288       croak "Can't find action for path '$path'";
1289     }
1290     return $c->uri_for( $action, @args );
1291 }
1292
1293 =head2 $c->welcome_message
1294
1295 Returns the Catalyst welcome HTML page.
1296
1297 =cut
1298
1299 sub welcome_message {
1300     my $c      = shift;
1301     my $name   = $c->config->{name};
1302     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1303     my $prefix = Catalyst::Utils::appprefix( ref $c );
1304     $c->response->content_type('text/html; charset=utf-8');
1305     return <<"EOF";
1306 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1307     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1308 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1309     <head>
1310     <meta http-equiv="Content-Language" content="en" />
1311     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1312         <title>$name on Catalyst $VERSION</title>
1313         <style type="text/css">
1314             body {
1315                 color: #000;
1316                 background-color: #eee;
1317             }
1318             div#content {
1319                 width: 640px;
1320                 margin-left: auto;
1321                 margin-right: auto;
1322                 margin-top: 10px;
1323                 margin-bottom: 10px;
1324                 text-align: left;
1325                 background-color: #ccc;
1326                 border: 1px solid #aaa;
1327             }
1328             p, h1, h2 {
1329                 margin-left: 20px;
1330                 margin-right: 20px;
1331                 font-family: verdana, tahoma, sans-serif;
1332             }
1333             a {
1334                 font-family: verdana, tahoma, sans-serif;
1335             }
1336             :link, :visited {
1337                     text-decoration: none;
1338                     color: #b00;
1339                     border-bottom: 1px dotted #bbb;
1340             }
1341             :link:hover, :visited:hover {
1342                     color: #555;
1343             }
1344             div#topbar {
1345                 margin: 0px;
1346             }
1347             pre {
1348                 margin: 10px;
1349                 padding: 8px;
1350             }
1351             div#answers {
1352                 padding: 8px;
1353                 margin: 10px;
1354                 background-color: #fff;
1355                 border: 1px solid #aaa;
1356             }
1357             h1 {
1358                 font-size: 0.9em;
1359                 font-weight: normal;
1360                 text-align: center;
1361             }
1362             h2 {
1363                 font-size: 1.0em;
1364             }
1365             p {
1366                 font-size: 0.9em;
1367             }
1368             p img {
1369                 float: right;
1370                 margin-left: 10px;
1371             }
1372             span#appname {
1373                 font-weight: bold;
1374                 font-size: 1.6em;
1375             }
1376         </style>
1377     </head>
1378     <body>
1379         <div id="content">
1380             <div id="topbar">
1381                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1382                     $VERSION</h1>
1383              </div>
1384              <div id="answers">
1385                  <p>
1386                  <img src="$logo" alt="Catalyst Logo" />
1387                  </p>
1388                  <p>Welcome to the  world of Catalyst.
1389                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1390                     framework will make web development something you had
1391                     never expected it to be: Fun, rewarding, and quick.</p>
1392                  <h2>What to do now?</h2>
1393                  <p>That really depends  on what <b>you</b> want to do.
1394                     We do, however, provide you with a few starting points.</p>
1395                  <p>If you want to jump right into web development with Catalyst
1396                     you might want to start with a tutorial.</p>
1397 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1398 </pre>
1399 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1400 <pre>
1401 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1402 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1403 </code></pre>
1404                  <h2>What to do next?</h2>
1405                  <p>Next it's time to write an actual application. Use the
1406                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1407                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1408                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1409                     they can save you a lot of work.</p>
1410                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1411                     <p>Also, be sure to check out the vast and growing
1412                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1413                     you are likely to find what you need there.
1414                     </p>
1415
1416                  <h2>Need help?</h2>
1417                  <p>Catalyst has a very active community. Here are the main places to
1418                     get in touch with us.</p>
1419                  <ul>
1420                      <li>
1421                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1422                      </li>
1423                      <li>
1424                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1425                      </li>
1426                      <li>
1427                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1428                      </li>
1429                  </ul>
1430                  <h2>In conclusion</h2>
1431                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1432                     as we enjoyed making it. Please contact us if you have ideas
1433                     for improvement or other feedback.</p>
1434              </div>
1435          </div>
1436     </body>
1437 </html>
1438 EOF
1439 }
1440
1441 =head1 INTERNAL METHODS
1442
1443 These methods are not meant to be used by end users.
1444
1445 =head2 $c->components
1446
1447 Returns a hash of components.
1448
1449 =head2 $c->context_class
1450
1451 Returns or sets the context class.
1452
1453 =head2 $c->counter
1454
1455 Returns a hashref containing coderefs and execution counts (needed for
1456 deep recursion detection).
1457
1458 =head2 $c->depth
1459
1460 Returns the number of actions on the current internal execution stack.
1461
1462 =head2 $c->dispatch
1463
1464 Dispatches a request to actions.
1465
1466 =cut
1467
1468 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1469
1470 =head2 $c->dispatcher_class
1471
1472 Returns or sets the dispatcher class.
1473
1474 =head2 $c->dump_these
1475
1476 Returns a list of 2-element array references (name, structure) pairs
1477 that will be dumped on the error page in debug mode.
1478
1479 =cut
1480
1481 sub dump_these {
1482     my $c = shift;
1483     [ Request => $c->req ],
1484     [ Response => $c->res ],
1485     [ Stash => $c->stash ],
1486     [ Config => $c->config ];
1487 }
1488
1489 =head2 $c->engine_class
1490
1491 Returns or sets the engine class.
1492
1493 =head2 $c->execute( $class, $coderef )
1494
1495 Execute a coderef in given class and catch exceptions. Errors are available
1496 via $c->error.
1497
1498 =cut
1499
1500 sub execute {
1501     my ( $c, $class, $code ) = @_;
1502     $class = $c->component($class) || $class;
1503     $c->state(0);
1504
1505     if ( $c->depth >= $RECURSION ) {
1506         my $action = $code->reverse();
1507         $action = "/$action" unless $action =~ /->/;
1508         my $error = qq/Deep recursion detected calling "${action}"/;
1509         $c->log->error($error);
1510         $c->error($error);
1511         $c->state(0);
1512         return $c->state;
1513     }
1514
1515     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1516
1517     push( @{ $c->stack }, $code );
1518
1519     no warnings 'recursion';
1520     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1521
1522     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1523
1524     my $last = pop( @{ $c->stack } );
1525
1526     if ( my $error = $@ ) {
1527         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1528             $error->rethrow if $c->depth > 1;
1529         }
1530         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1531             $error->rethrow if $c->depth > 0;
1532         }
1533         else {
1534             unless ( ref $error ) {
1535                 no warnings 'uninitialized';
1536                 chomp $error;
1537                 my $class = $last->class;
1538                 my $name  = $last->name;
1539                 $error = qq/Caught exception in $class->$name "$error"/;
1540             }
1541             $c->error($error);
1542             $c->state(0);
1543         }
1544     }
1545     return $c->state;
1546 }
1547
1548 sub _stats_start_execute {
1549     my ( $c, $code ) = @_;
1550
1551     return if ( ( $code->name =~ /^_.*/ )
1552         && ( !$c->config->{show_internal_actions} ) );
1553
1554     my $action_name = $code->reverse();
1555     $c->counter->{$action_name}++;
1556
1557     my $action = $action_name;
1558     $action = "/$action" unless $action =~ /->/;
1559
1560     # determine if the call was the result of a forward
1561     # this is done by walking up the call stack and looking for a calling
1562     # sub of Catalyst::forward before the eval
1563     my $callsub = q{};
1564     for my $index ( 2 .. 11 ) {
1565         last
1566         if ( ( caller($index) )[0] eq 'Catalyst'
1567             && ( caller($index) )[3] eq '(eval)' );
1568
1569         if ( ( caller($index) )[3] =~ /forward$/ ) {
1570             $callsub = ( caller($index) )[3];
1571             $action  = "-> $action";
1572             last;
1573         }
1574     }
1575
1576     my $uid = $action_name . $c->counter->{$action_name};
1577
1578     # is this a root-level call or a forwarded call?
1579     if ( $callsub =~ /forward$/ ) {
1580
1581         # forward, locate the caller
1582         if ( my $parent = $c->stack->[-1] ) {
1583             $c->stats->profile(
1584                 begin  => $action,
1585                 parent => "$parent" . $c->counter->{"$parent"},
1586                 uid    => $uid,
1587             );
1588         }
1589         else {
1590
1591             # forward with no caller may come from a plugin
1592             $c->stats->profile(
1593                 begin => $action,
1594                 uid   => $uid,
1595             );
1596         }
1597     }
1598     else {
1599
1600         # root-level call
1601         $c->stats->profile(
1602             begin => $action,
1603             uid   => $uid,
1604         );
1605     }
1606     return $action;
1607
1608 }
1609
1610 sub _stats_finish_execute {
1611     my ( $c, $info ) = @_;
1612     $c->stats->profile( end => $info );
1613 }
1614
1615 =head2 $c->finalize
1616
1617 Finalizes the request.
1618
1619 =cut
1620
1621 sub finalize {
1622     my $c = shift;
1623
1624     for my $error ( @{ $c->error } ) {
1625         $c->log->error($error);
1626     }
1627
1628     # Allow engine to handle finalize flow (for POE)
1629     my $engine = $c->engine;
1630     if ( my $code = $engine->can('finalize') ) {
1631         $engine->$code($c);
1632     }
1633     else {
1634
1635         $c->finalize_uploads;
1636
1637         # Error
1638         if ( $#{ $c->error } >= 0 ) {
1639             $c->finalize_error;
1640         }
1641
1642         $c->finalize_headers;
1643
1644         # HEAD request
1645         if ( $c->request->method eq 'HEAD' ) {
1646             $c->response->body('');
1647         }
1648
1649         $c->finalize_body;
1650     }
1651
1652     if ($c->use_stats) {
1653         my $elapsed = sprintf '%f', $c->stats->elapsed;
1654         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1655         $c->log->info(
1656             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1657     }
1658
1659     return $c->response->status;
1660 }
1661
1662 =head2 $c->finalize_body
1663
1664 Finalizes body.
1665
1666 =cut
1667
1668 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1669
1670 =head2 $c->finalize_cookies
1671
1672 Finalizes cookies.
1673
1674 =cut
1675
1676 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1677
1678 =head2 $c->finalize_error
1679
1680 Finalizes error.
1681
1682 =cut
1683
1684 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1685
1686 =head2 $c->finalize_headers
1687
1688 Finalizes headers.
1689
1690 =cut
1691
1692 sub finalize_headers {
1693     my $c = shift;
1694
1695     my $response = $c->response; #accessor calls can add up?
1696
1697     # Check if we already finalized headers
1698     return if $response->finalized_headers;
1699
1700     # Handle redirects
1701     if ( my $location = $response->redirect ) {
1702         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1703         $response->header( Location => $location );
1704
1705         if ( !$response->has_body ) {
1706             # Add a default body if none is already present
1707             $response->body(
1708                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1709             );
1710         }
1711     }
1712
1713     # Content-Length
1714     if ( $response->body && !$response->content_length ) {
1715
1716         # get the length from a filehandle
1717         if ( blessed( $response->body ) && $response->body->can('read') )
1718         {
1719             my $stat = stat $response->body;
1720             if ( $stat && $stat->size > 0 ) {
1721                 $response->content_length( $stat->size );
1722             }
1723             else {
1724                 $c->log->warn('Serving filehandle without a content-length');
1725             }
1726         }
1727         else {
1728             # everything should be bytes at this point, but just in case
1729             $response->content_length( bytes::length( $response->body ) );
1730         }
1731     }
1732
1733     # Errors
1734     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1735         $response->headers->remove_header("Content-Length");
1736         $response->body('');
1737     }
1738
1739     $c->finalize_cookies;
1740
1741     $c->engine->finalize_headers( $c, @_ );
1742
1743     # Done
1744     $response->finalized_headers(1);
1745 }
1746
1747 =head2 $c->finalize_output
1748
1749 An alias for finalize_body.
1750
1751 =head2 $c->finalize_read
1752
1753 Finalizes the input after reading is complete.
1754
1755 =cut
1756
1757 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1758
1759 =head2 $c->finalize_uploads
1760
1761 Finalizes uploads. Cleans up any temporary files.
1762
1763 =cut
1764
1765 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1766
1767 =head2 $c->get_action( $action, $namespace )
1768
1769 Gets an action in a given namespace.
1770
1771 =cut
1772
1773 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1774
1775 =head2 $c->get_actions( $action, $namespace )
1776
1777 Gets all actions of a given name in a namespace and all parent
1778 namespaces.
1779
1780 =cut
1781
1782 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1783
1784 =head2 $c->handle_request( $class, @arguments )
1785
1786 Called to handle each HTTP request.
1787
1788 =cut
1789
1790 sub handle_request {
1791     my ( $class, @arguments ) = @_;
1792
1793     # Always expect worst case!
1794     my $status = -1;
1795     eval {
1796         if ($class->debug) {
1797             my $secs = time - $START || 1;
1798             my $av = sprintf '%.3f', $COUNT / $secs;
1799             my $time = localtime time;
1800             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1801         }
1802
1803         my $c = $class->prepare(@arguments);
1804         $c->dispatch;
1805         $status = $c->finalize;
1806     };
1807
1808     if ( my $error = $@ ) {
1809         chomp $error;
1810         $class->log->error(qq/Caught exception in engine "$error"/);
1811     }
1812
1813     $COUNT++;
1814
1815     if(my $coderef = $class->log->can('_flush')){
1816         $class->log->$coderef();
1817     }
1818     return $status;
1819 }
1820
1821 =head2 $c->prepare( @arguments )
1822
1823 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1824 etc.).
1825
1826 =cut
1827
1828 sub prepare {
1829     my ( $class, @arguments ) = @_;
1830
1831     # XXX
1832     # After the app/ctxt split, this should become an attribute based on something passed
1833     # into the application.
1834     $class->context_class( ref $class || $class ) unless $class->context_class;
1835
1836     my $c = $class->context_class->new({});
1837
1838     # For on-demand data
1839     $c->request->_context($c);
1840     $c->response->_context($c);
1841
1842     #surely this is not the most efficient way to do things...
1843     $c->stats($class->stats_class->new)->enable($c->use_stats);
1844     if ( $c->debug ) {
1845         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1846     }
1847
1848     #XXX reuse coderef from can
1849     # Allow engine to direct the prepare flow (for POE)
1850     if ( $c->engine->can('prepare') ) {
1851         $c->engine->prepare( $c, @arguments );
1852     }
1853     else {
1854         $c->prepare_request(@arguments);
1855         $c->prepare_connection;
1856         $c->prepare_query_parameters;
1857         $c->prepare_headers;
1858         $c->prepare_cookies;
1859         $c->prepare_path;
1860
1861         # Prepare the body for reading, either by prepare_body
1862         # or the user, if they are using $c->read
1863         $c->prepare_read;
1864
1865         # Parse the body unless the user wants it on-demand
1866         unless ( $c->config->{parse_on_demand} ) {
1867             $c->prepare_body;
1868         }
1869     }
1870
1871     my $method  = $c->req->method  || '';
1872     my $path    = $c->req->path;
1873     $path       = '/' unless length $path;
1874     my $address = $c->req->address || '';
1875
1876     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1877       if $c->debug;
1878
1879     $c->prepare_action;
1880
1881     return $c;
1882 }
1883
1884 =head2 $c->prepare_action
1885
1886 Prepares action. See L<Catalyst::Dispatcher>.
1887
1888 =cut
1889
1890 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1891
1892 =head2 $c->prepare_body
1893
1894 Prepares message body.
1895
1896 =cut
1897
1898 sub prepare_body {
1899     my $c = shift;
1900
1901     return if $c->request->_has_body;
1902
1903     # Initialize on-demand data
1904     $c->engine->prepare_body( $c, @_ );
1905     $c->prepare_parameters;
1906     $c->prepare_uploads;
1907
1908     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1909         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1910         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1911             my $param = $c->req->body_parameters->{$key};
1912             my $value = defined($param) ? $param : '';
1913             $t->row( $key,
1914                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1915         }
1916         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1917     }
1918 }
1919
1920 =head2 $c->prepare_body_chunk( $chunk )
1921
1922 Prepares a chunk of data before sending it to L<HTTP::Body>.
1923
1924 See L<Catalyst::Engine>.
1925
1926 =cut
1927
1928 sub prepare_body_chunk {
1929     my $c = shift;
1930     $c->engine->prepare_body_chunk( $c, @_ );
1931 }
1932
1933 =head2 $c->prepare_body_parameters
1934
1935 Prepares body parameters.
1936
1937 =cut
1938
1939 sub prepare_body_parameters {
1940     my $c = shift;
1941     $c->engine->prepare_body_parameters( $c, @_ );
1942 }
1943
1944 =head2 $c->prepare_connection
1945
1946 Prepares connection.
1947
1948 =cut
1949
1950 sub prepare_connection {
1951     my $c = shift;
1952     $c->engine->prepare_connection( $c, @_ );
1953 }
1954
1955 =head2 $c->prepare_cookies
1956
1957 Prepares cookies.
1958
1959 =cut
1960
1961 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1962
1963 =head2 $c->prepare_headers
1964
1965 Prepares headers.
1966
1967 =cut
1968
1969 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1970
1971 =head2 $c->prepare_parameters
1972
1973 Prepares parameters.
1974
1975 =cut
1976
1977 sub prepare_parameters {
1978     my $c = shift;
1979     $c->prepare_body_parameters;
1980     $c->engine->prepare_parameters( $c, @_ );
1981 }
1982
1983 =head2 $c->prepare_path
1984
1985 Prepares path and base.
1986
1987 =cut
1988
1989 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1990
1991 =head2 $c->prepare_query_parameters
1992
1993 Prepares query parameters.
1994
1995 =cut
1996
1997 sub prepare_query_parameters {
1998     my $c = shift;
1999
2000     $c->engine->prepare_query_parameters( $c, @_ );
2001
2002     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
2003         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
2004         for my $key ( sort keys %{ $c->req->query_parameters } ) {
2005             my $param = $c->req->query_parameters->{$key};
2006             my $value = defined($param) ? $param : '';
2007             $t->row( $key,
2008                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2009         }
2010         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2011     }
2012 }
2013
2014 =head2 $c->prepare_read
2015
2016 Prepares the input for reading.
2017
2018 =cut
2019
2020 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2021
2022 =head2 $c->prepare_request
2023
2024 Prepares the engine request.
2025
2026 =cut
2027
2028 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2029
2030 =head2 $c->prepare_uploads
2031
2032 Prepares uploads.
2033
2034 =cut
2035
2036 sub prepare_uploads {
2037     my $c = shift;
2038
2039     $c->engine->prepare_uploads( $c, @_ );
2040
2041     if ( $c->debug && keys %{ $c->request->uploads } ) {
2042         my $t = Text::SimpleTable->new(
2043             [ 12, 'Parameter' ],
2044             [ 26, 'Filename' ],
2045             [ 18, 'Type' ],
2046             [ 9,  'Size' ]
2047         );
2048         for my $key ( sort keys %{ $c->request->uploads } ) {
2049             my $upload = $c->request->uploads->{$key};
2050             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2051                 $t->row( $key, $u->filename, $u->type, $u->size );
2052             }
2053         }
2054         $c->log->debug( "File Uploads are:\n" . $t->draw );
2055     }
2056 }
2057
2058 =head2 $c->prepare_write
2059
2060 Prepares the output for writing.
2061
2062 =cut
2063
2064 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2065
2066 =head2 $c->request_class
2067
2068 Returns or sets the request class.
2069
2070 =head2 $c->response_class
2071
2072 Returns or sets the response class.
2073
2074 =head2 $c->read( [$maxlength] )
2075
2076 Reads a chunk of data from the request body. This method is designed to
2077 be used in a while loop, reading C<$maxlength> bytes on every call.
2078 C<$maxlength> defaults to the size of the request if not specified.
2079
2080 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2081 directly.
2082
2083 Warning: If you use read(), Catalyst will not process the body,
2084 so you will not be able to access POST parameters or file uploads via
2085 $c->request.  You must handle all body parsing yourself.
2086
2087 =cut
2088
2089 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2090
2091 =head2 $c->run
2092
2093 Starts the engine.
2094
2095 =cut
2096
2097 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2098
2099 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2100
2101 Sets an action in a given namespace.
2102
2103 =cut
2104
2105 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2106
2107 =head2 $c->setup_actions($component)
2108
2109 Sets up actions for a component.
2110
2111 =cut
2112
2113 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2114
2115 =head2 $c->setup_components
2116
2117 Sets up components. Specify a C<setup_components> config option to pass
2118 additional options directly to L<Module::Pluggable>. To add additional
2119 search paths, specify a key named C<search_extra> as an array
2120 reference. Items in the array beginning with C<::> will have the
2121 application class name prepended to them.
2122
2123 All components found will also have any
2124 L<inner packages|Devel::InnerPackage> loaded and set up as components.
2125 Note, that modules which are B<not> an I<inner package> of the main
2126 file namespace loaded will not be instantiated as components.
2127
2128 =cut
2129
2130 sub setup_components {
2131     my $class = shift;
2132
2133     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2134     my $config  = $class->config->{ setup_components };
2135     my $extra   = delete $config->{ search_extra } || [];
2136
2137     push @paths, @$extra;
2138
2139     my $locator = Module::Pluggable::Object->new(
2140         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2141         %$config
2142     );
2143
2144     my @comps = sort { length $a <=> length $b } $locator->plugins;
2145     my %comps = map { $_ => 1 } @comps;
2146
2147     my $deprecated_component_names = grep { /::[CMV]::/ } @comps;
2148     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2149         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2150     ) if $deprecated_component_names;
2151
2152     for my $component ( @comps ) {
2153
2154         # We pass ignore_loaded here so that overlay files for (e.g.)
2155         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2156         # we know M::P::O found a file on disk so this is safe
2157
2158         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2159         #Class::MOP::load_class($component);
2160
2161         my $module  = $class->setup_component( $component );
2162         my %modules = (
2163             $component => $module,
2164             map {
2165                 $_ => $class->setup_component( $_ )
2166             } grep {
2167               not exists $comps{$_}
2168             } Devel::InnerPackage::list_packages( $component )
2169         );
2170
2171         for my $key ( keys %modules ) {
2172             $class->components->{ $key } = $modules{ $key };
2173         }
2174     }
2175 }
2176
2177 =head2 $c->setup_component
2178
2179 =cut
2180
2181 sub _controller_init_base_classes {
2182     my ($app_class, $component) = @_;
2183     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2184         Moose::Meta::Class->initialize( $class )
2185             unless find_meta($class);
2186     }
2187 }
2188
2189 sub setup_component {
2190     my( $class, $component ) = @_;
2191
2192     unless ( $component->can( 'COMPONENT' ) ) {
2193         return $component;
2194     }
2195
2196     # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2197     #         nearest to Catalyst::Controller first, no matter what order stuff happens
2198     #         to be loaded. There are TODO tests in Moose for this, see
2199     #         f2391d17574eff81d911b97be15ea51080500003
2200     if ($component->isa('Catalyst::Controller')) {
2201         $class->_controller_init_base_classes($component);
2202     }
2203
2204     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2205     my $config = $class->config->{ $suffix } || {};
2206
2207     my $instance = eval { $component->COMPONENT( $class, $config ); };
2208
2209     if ( my $error = $@ ) {
2210         chomp $error;
2211         Catalyst::Exception->throw(
2212             message => qq/Couldn't instantiate component "$component", "$error"/
2213         );
2214     }
2215
2216     unless (blessed $instance) {
2217         my $metaclass = Moose::Util::find_meta($component);
2218         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2219         my $component_method_from = $method_meta->associated_metaclass->name;
2220         my $value = defined($instance) ? $instance : 'undef';
2221         Catalyst::Exception->throw(
2222             message =>
2223             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2224         );
2225     }
2226     return $instance;
2227 }
2228
2229 =head2 $c->setup_dispatcher
2230
2231 Sets up dispatcher.
2232
2233 =cut
2234
2235 sub setup_dispatcher {
2236     my ( $class, $dispatcher ) = @_;
2237
2238     if ($dispatcher) {
2239         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2240     }
2241
2242     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2243         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2244     }
2245
2246     unless ($dispatcher) {
2247         $dispatcher = $class->dispatcher_class;
2248     }
2249
2250     Class::MOP::load_class($dispatcher);
2251
2252     # dispatcher instance
2253     $class->dispatcher( $dispatcher->new );
2254 }
2255
2256 =head2 $c->setup_engine
2257
2258 Sets up engine.
2259
2260 =cut
2261
2262 sub setup_engine {
2263     my ( $class, $engine ) = @_;
2264
2265     if ($engine) {
2266         $engine = 'Catalyst::Engine::' . $engine;
2267     }
2268
2269     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2270         $engine = 'Catalyst::Engine::' . $env;
2271     }
2272
2273     if ( $ENV{MOD_PERL} ) {
2274         my $meta = Class::MOP::get_metaclass_by_name($class);
2275
2276         # create the apache method
2277         $meta->add_method('apache' => sub { shift->engine->apache });
2278
2279         my ( $software, $version ) =
2280           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2281
2282         $version =~ s/_//g;
2283         $version =~ s/(\.[^.]+)\./$1/g;
2284
2285         if ( $software eq 'mod_perl' ) {
2286
2287             if ( !$engine ) {
2288
2289                 if ( $version >= 1.99922 ) {
2290                     $engine = 'Catalyst::Engine::Apache2::MP20';
2291                 }
2292
2293                 elsif ( $version >= 1.9901 ) {
2294                     $engine = 'Catalyst::Engine::Apache2::MP19';
2295                 }
2296
2297                 elsif ( $version >= 1.24 ) {
2298                     $engine = 'Catalyst::Engine::Apache::MP13';
2299                 }
2300
2301                 else {
2302                     Catalyst::Exception->throw( message =>
2303                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2304                 }
2305
2306             }
2307
2308             # install the correct mod_perl handler
2309             if ( $version >= 1.9901 ) {
2310                 *handler = sub  : method {
2311                     shift->handle_request(@_);
2312                 };
2313             }
2314             else {
2315                 *handler = sub ($$) { shift->handle_request(@_) };
2316             }
2317
2318         }
2319
2320         elsif ( $software eq 'Zeus-Perl' ) {
2321             $engine = 'Catalyst::Engine::Zeus';
2322         }
2323
2324         else {
2325             Catalyst::Exception->throw(
2326                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2327         }
2328     }
2329
2330     unless ($engine) {
2331         $engine = $class->engine_class;
2332     }
2333
2334     Class::MOP::load_class($engine);
2335
2336     # check for old engines that are no longer compatible
2337     my $old_engine;
2338     if ( $engine->isa('Catalyst::Engine::Apache')
2339         && !Catalyst::Engine::Apache->VERSION )
2340     {
2341         $old_engine = 1;
2342     }
2343
2344     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2345         && Catalyst::Engine::Server->VERSION le '0.02' )
2346     {
2347         $old_engine = 1;
2348     }
2349
2350     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2351         && $engine->VERSION eq '0.01' )
2352     {
2353         $old_engine = 1;
2354     }
2355
2356     elsif ($engine->isa('Catalyst::Engine::Zeus')
2357         && $engine->VERSION eq '0.01' )
2358     {
2359         $old_engine = 1;
2360     }
2361
2362     if ($old_engine) {
2363         Catalyst::Exception->throw( message =>
2364               qq/Engine "$engine" is not supported by this version of Catalyst/
2365         );
2366     }
2367
2368     # engine instance
2369     $class->engine( $engine->new );
2370 }
2371
2372 =head2 $c->setup_home
2373
2374 Sets up the home directory.
2375
2376 =cut
2377
2378 sub setup_home {
2379     my ( $class, $home ) = @_;
2380
2381     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2382         $home = $env;
2383     }
2384
2385     $home ||= Catalyst::Utils::home($class);
2386
2387     if ($home) {
2388         #I remember recently being scolded for assigning config values like this
2389         $class->config->{home} ||= $home;
2390         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2391     }
2392 }
2393
2394 =head2 $c->setup_log
2395
2396 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2397 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2398 log to.
2399
2400 This method also installs a C<debug> method that returns a true value into the
2401 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2402 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2403
2404 Note that if the log has already been setup, by either a previous call to
2405 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2406 that this method won't actually set up the log object.
2407
2408 =cut
2409
2410 sub setup_log {
2411     my ( $class, $levels ) = @_;
2412
2413     $levels ||= '';
2414     $levels =~ s/^\s+//;
2415     $levels =~ s/\s+$//;
2416     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2417
2418     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2419     if ( defined $env_debug ) {
2420         $levels{debug} = 1 if $env_debug; # Ugly!
2421         delete($levels{debug}) unless $env_debug;
2422     }
2423
2424     unless ( $class->log ) {
2425         $class->log( Catalyst::Log->new(keys %levels) );
2426     }
2427
2428     if ( $levels{debug} ) {
2429         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2430         $class->log->debug('Debug messages enabled');
2431     }
2432 }
2433
2434 =head2 $c->setup_plugins
2435
2436 Sets up plugins.
2437
2438 =cut
2439
2440 =head2 $c->setup_stats
2441
2442 Sets up timing statistics class.
2443
2444 =cut
2445
2446 sub setup_stats {
2447     my ( $class, $stats ) = @_;
2448
2449     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2450
2451     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2452     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2453         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2454         $class->log->debug('Statistics enabled');
2455     }
2456 }
2457
2458
2459 =head2 $c->registered_plugins
2460
2461 Returns a sorted list of the plugins which have either been stated in the
2462 import list or which have been added via C<< MyApp->plugin(@args); >>.
2463
2464 If passed a given plugin name, it will report a boolean value indicating
2465 whether or not that plugin is loaded.  A fully qualified name is required if
2466 the plugin name does not begin with C<Catalyst::Plugin::>.
2467
2468  if ($c->registered_plugins('Some::Plugin')) {
2469      ...
2470  }
2471
2472 =cut
2473
2474 {
2475
2476     sub registered_plugins {
2477         my $proto = shift;
2478         return sort keys %{ $proto->_plugins } unless @_;
2479         my $plugin = shift;
2480         return 1 if exists $proto->_plugins->{$plugin};
2481         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2482     }
2483
2484     sub _register_plugin {
2485         my ( $proto, $plugin, $instant ) = @_;
2486         my $class = ref $proto || $proto;
2487
2488         Class::MOP::load_class( $plugin );
2489
2490         $proto->_plugins->{$plugin} = 1;
2491         unless ($instant) {
2492             no strict 'refs';
2493             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2494               my @superclasses = ($plugin, $meta->superclasses );
2495               $meta->superclasses(@superclasses);
2496             } else {
2497               unshift @{"$class\::ISA"}, $plugin;
2498             }
2499         }
2500         return $class;
2501     }
2502
2503     sub setup_plugins {
2504         my ( $class, $plugins ) = @_;
2505
2506         $class->_plugins( {} ) unless $class->_plugins;
2507         $plugins ||= [];
2508
2509         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2510
2511         for my $plugin ( reverse @plugins ) {
2512             Class::MOP::load_class($plugin);
2513             my $meta = find_meta($plugin);
2514             next if $meta && $meta->isa('Moose::Meta::Role');
2515
2516             $class->_register_plugin($plugin);
2517         }
2518
2519         my @roles =
2520             map { $_->name }
2521             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2522             map { find_meta($_) }
2523             @plugins;
2524
2525         Moose::Util::apply_all_roles(
2526             $class => @roles
2527         ) if @roles;
2528     }
2529 }
2530
2531 =head2 $c->stack
2532
2533 Returns an arrayref of the internal execution stack (actions that are
2534 currently executing).
2535
2536 =head2 $c->stats_class
2537
2538 Returns or sets the stats (timing statistics) class.
2539
2540 =head2 $c->use_stats
2541
2542 Returns 1 when stats collection is enabled.  Stats collection is enabled
2543 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2544 environment variable is set.
2545
2546 Note that this is a static method, not an accessor and should be overridden
2547 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2548
2549 =cut
2550
2551 sub use_stats { 0 }
2552
2553
2554 =head2 $c->write( $data )
2555
2556 Writes $data to the output stream. When using this method directly, you
2557 will need to manually set the C<Content-Length> header to the length of
2558 your output data, if known.
2559
2560 =cut
2561
2562 sub write {
2563     my $c = shift;
2564
2565     # Finalize headers if someone manually writes output
2566     $c->finalize_headers;
2567
2568     return $c->engine->write( $c, @_ );
2569 }
2570
2571 =head2 version
2572
2573 Returns the Catalyst version number. Mostly useful for "powered by"
2574 messages in template systems.
2575
2576 =cut
2577
2578 sub version { return $Catalyst::VERSION }
2579
2580 =head1 INTERNAL ACTIONS
2581
2582 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2583 C<_ACTION>, and C<_END>. These are by default not shown in the private
2584 action table, but you can make them visible with a config parameter.
2585
2586     MyApp->config(show_internal_actions => 1);
2587
2588 =head1 CASE SENSITIVITY
2589
2590 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2591 mapped to C</foo/bar>. You can activate case sensitivity with a config
2592 parameter.
2593
2594     MyApp->config(case_sensitive => 1);
2595
2596 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2597
2598 =head1 ON-DEMAND PARSER
2599
2600 The request body is usually parsed at the beginning of a request,
2601 but if you want to handle input yourself, you can enable on-demand
2602 parsing with a config parameter.
2603
2604     MyApp->config(parse_on_demand => 1);
2605
2606 =head1 PROXY SUPPORT
2607
2608 Many production servers operate using the common double-server approach,
2609 with a lightweight frontend web server passing requests to a larger
2610 backend server. An application running on the backend server must deal
2611 with two problems: the remote user always appears to be C<127.0.0.1> and
2612 the server's hostname will appear to be C<localhost> regardless of the
2613 virtual host that the user connected through.
2614
2615 Catalyst will automatically detect this situation when you are running
2616 the frontend and backend servers on the same machine. The following
2617 changes are made to the request.
2618
2619     $c->req->address is set to the user's real IP address, as read from
2620     the HTTP X-Forwarded-For header.
2621
2622     The host value for $c->req->base and $c->req->uri is set to the real
2623     host, as read from the HTTP X-Forwarded-Host header.
2624
2625 Obviously, your web server must support these headers for this to work.
2626
2627 In a more complex server farm environment where you may have your
2628 frontend proxy server(s) on different machines, you will need to set a
2629 configuration option to tell Catalyst to read the proxied data from the
2630 headers.
2631
2632     MyApp->config(using_frontend_proxy => 1);
2633
2634 If you do not wish to use the proxy support at all, you may set:
2635
2636     MyApp->config(ignore_frontend_proxy => 1);
2637
2638 =head1 THREAD SAFETY
2639
2640 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2641 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2642 believe the Catalyst core to be thread-safe.
2643
2644 If you plan to operate in a threaded environment, remember that all other
2645 modules you are using must also be thread-safe. Some modules, most notably
2646 L<DBD::SQLite>, are not thread-safe.
2647
2648 =head1 SUPPORT
2649
2650 IRC:
2651
2652     Join #catalyst on irc.perl.org.
2653
2654 Mailing Lists:
2655
2656     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2657     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2658
2659 Web:
2660
2661     http://catalyst.perl.org
2662
2663 Wiki:
2664
2665     http://dev.catalyst.perl.org
2666
2667 =head1 SEE ALSO
2668
2669 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2670
2671 =head2 L<Catalyst::Manual> - The Catalyst Manual
2672
2673 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2674
2675 =head2 L<Catalyst::Engine> - Core engine
2676
2677 =head2 L<Catalyst::Log> - Log class.
2678
2679 =head2 L<Catalyst::Request> - Request object
2680
2681 =head2 L<Catalyst::Response> - Response object
2682
2683 =head2 L<Catalyst::Test> - The test suite.
2684
2685 =head1 PROJECT FOUNDER
2686
2687 sri: Sebastian Riedel <sri@cpan.org>
2688
2689 =head1 CONTRIBUTORS
2690
2691 abw: Andy Wardley
2692
2693 acme: Leon Brocard <leon@astray.com>
2694
2695 Andrew Bramble
2696
2697 Andrew Ford
2698
2699 Andrew Ruthven
2700
2701 andyg: Andy Grundman <andy@hybridized.org>
2702
2703 audreyt: Audrey Tang
2704
2705 bricas: Brian Cassidy <bricas@cpan.org>
2706
2707 Caelum: Rafael Kitover <rkitover@io.com>
2708
2709 chansen: Christian Hansen
2710
2711 chicks: Christopher Hicks
2712
2713 David E. Wheeler
2714
2715 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2716
2717 Drew Taylor
2718
2719 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2720
2721 esskar: Sascha Kiefer
2722
2723 fireartist: Carl Franks <cfranks@cpan.org>
2724
2725 gabb: Danijel Milicevic
2726
2727 Gary Ashton Jones
2728
2729 Geoff Richards
2730
2731 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2732
2733 jcamacho: Juan Camacho
2734
2735 jester: Jesse Sheidlower
2736
2737 jhannah: Jay Hannah <jay@jays.net>
2738
2739 Jody Belka
2740
2741 Johan Lindstrom
2742
2743 jon: Jon Schutz <jjschutz@cpan.org>
2744
2745 marcus: Marcus Ramberg <mramberg@cpan.org>
2746
2747 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2748
2749 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2750
2751 mugwump: Sam Vilain
2752
2753 naughton: David Naughton
2754
2755 ningu: David Kamholz <dkamholz@cpan.org>
2756
2757 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2758
2759 numa: Dan Sully <daniel@cpan.org>
2760
2761 obra: Jesse Vincent
2762
2763 omega: Andreas Marienborg
2764
2765 Oleg Kostyuk <cub.uanic@gmail.com>
2766
2767 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2768
2769 rafl: Florian Ragwitz <rafl@debian.org>
2770
2771 random: Roland Lammel <lammel@cpan.org>
2772
2773 sky: Arthur Bergman
2774
2775 t0m: Tomas Doran <bobtfish@bobtfish.net>
2776
2777 Ulf Edvinsson
2778
2779 willert: Sebastian Willert <willert@cpan.org>
2780
2781 =head1 LICENSE
2782
2783 This library is free software. You can redistribute it and/or modify it under
2784 the same terms as Perl itself.
2785
2786 =cut
2787
2788 no Moose;
2789
2790 __PACKAGE__->meta->make_immutable;
2791
2792 1;