lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken blessed/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 __PACKAGE__->mk_accessors(
  34     qw/counter request response state action stack namespace stats/
  35 );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52 our $GO        = "catalyst_go\n";
  53
  54 __PACKAGE__->mk_classdata($_)
  55   for qw/components arguments dispatcher engine log dispatcher_class
  56   engine_class context_class request_class response_class stats_class
  57   setup_finished/;
  58
  59 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  60 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  61 __PACKAGE__->request_class('Catalyst::Request');
  62 __PACKAGE__->response_class('Catalyst::Response');
  63 __PACKAGE__->stats_class('Catalyst::Stats');
  64
  65 # Remember to update this in Catalyst::Runtime as well!
  66
  67 our $VERSION = '5.7099_02';
  68
  69 sub import {
  70     my ( $class, @arguments ) = @_;
  71
  72     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  73     # callers @ISA.
  74     return unless $class eq 'Catalyst';
  75
  76     my $caller = caller(0);
  77
  78     unless ( $caller->isa('Catalyst') ) {
  79         no strict 'refs';
  80         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  81     }
  82
  83     $caller->arguments( [@arguments] );
  84     $caller->setup_home;
  85 }
  86
  87 =head1 NAME
  88
  89 Catalyst - The Elegant MVC Web Application Framework
  90
  91 =head1 SYNOPSIS
  92
  93 See the L<Catalyst::Manual> distribution for comprehensive
  94 documentation and tutorials.
  95
  96     # Install Catalyst::Devel for helpers and other development tools
  97     # use the helper to create a new application
  98     catalyst.pl MyApp
  99
 100     # add models, views, controllers
 101     script/myapp_create.pl model MyDatabase DBIC::Schema create=dynamic dbi:SQLite:/path/to/db
 102     script/myapp_create.pl view MyTemplate TT
 103     script/myapp_create.pl controller Search
 104
 105     # built in testserver -- use -r to restart automatically on changes
 106     # --help to see all available options
 107     script/myapp_server.pl
 108
 109     # command line testing interface
 110     script/myapp_test.pl /yada
 111
 112     ### in lib/MyApp.pm
 113     use Catalyst qw/-Debug/; # include plugins here as well
 114
 115     ### In lib/MyApp/Controller/Root.pm (autocreated)
 116     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 117         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 118         $c->stash->{template} = 'foo.tt'; # set the template
 119         # lookup something from db -- stash vars are passed to TT
 120         $c->stash->{data} =
 121           $c->model('Database::Foo')->search( { country => $args[0] } );
 122         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 123             $c->forward( 'bar' ); # process another action
 124             # do something else after forward returns
 125         }
 126     }
 127
 128     # The foo.tt TT template can use the stash data from the database
 129     [% WHILE (item = data.next) %]
 130         [% item.foo %]
 131     [% END %]
 132
 133     # called for /bar/of/soap, /bar/of/soap/10, etc.
 134     sub bar : Path('/bar/of/soap') { ... }
 135
 136     # called for all actions, from the top-most controller downwards
 137     sub auto : Private {
 138         my ( $self, $c ) = @_;
 139         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 140             $c->res->redirect( '/login' ); # require login
 141             return 0; # abort request and go immediately to end()
 142         }
 143         return 1; # success; carry on to next action
 144     }
 145
 146     # called after all actions are finished
 147     sub end : Private {
 148         my ( $self, $c ) = @_;
 149         if ( scalar @{ $c->error } ) { ... } # handle errors
 150         return if $c->res->body; # already have a response
 151         $c->forward( 'MyApp::View::TT' ); # render template
 152     }
 153
 154     ### in MyApp/Controller/Foo.pm
 155     # called for /foo/bar
 156     sub bar : Local { ... }
 157
 158     # called for /blargle
 159     sub blargle : Global { ... }
 160
 161     # an index action matches /foo, but not /foo/1, etc.
 162     sub index : Private { ... }
 163
 164     ### in MyApp/Controller/Foo/Bar.pm
 165     # called for /foo/bar/baz
 166     sub baz : Local { ... }
 167
 168     # first Root auto is called, then Foo auto, then this
 169     sub auto : Private { ... }
 170
 171     # powerful regular expression paths are also possible
 172     sub details : Regex('^product/(\w+)/details$') {
 173         my ( $self, $c ) = @_;
 174         # extract the (\w+) from the URI
 175         my $product = $c->req->captures->[0];
 176     }
 177
 178 See L<Catalyst::Manual::Intro> for additional information.
 179
 180 =head1 DESCRIPTION
 181
 182 Catalyst is a modern framework for making web applications without the
 183 pain usually associated with this process. This document is a reference
 184 to the main Catalyst application. If you are a new user, we suggest you
 185 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 186
 187 See L<Catalyst::Manual> for more documentation.
 188
 189 Catalyst plugins can be loaded by naming them as arguments to the "use
 190 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 191 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 192 C<My::Module>.
 193
 194     use Catalyst qw/My::Module/;
 195
 196 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 197 fully qualify the name by using a unary plus:
 198
 199     use Catalyst qw/
 200         My::Module
 201         +Fully::Qualified::Plugin::Name
 202     /;
 203
 204 Special flags like C<-Debug> and C<-Engine> can also be specified as
 205 arguments when Catalyst is loaded:
 206
 207     use Catalyst qw/-Debug My::Module/;
 208
 209 The position of plugins and flags in the chain is important, because
 210 they are loaded in the order in which they appear.
 211
 212 The following flags are supported:
 213
 214 =head2 -Debug
 215
 216 Enables debug output. You can also force this setting from the system
 217 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 218 settings override the application, with <MYAPP>_DEBUG having the highest
 219 priority.
 220
 221 =head2 -Engine
 222
 223 Forces Catalyst to use a specific engine. Omit the
 224 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 225
 226     use Catalyst qw/-Engine=CGI/;
 227
 228 =head2 -Home
 229
 230 Forces Catalyst to use a specific home directory, e.g.:
 231
 232     use Catalyst qw[-Home=/usr/mst];
 233
 234 This can also be done in the shell environment by setting either the
 235 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 236 is replaced with the uppercased name of your application, any "::" in
 237 the name will be replaced with underscores, e.g. MyApp::Web should use
 238 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 239
 240 =head2 -Log
 241
 242 Specifies log level.
 243
 244 =head2 -Stats
 245
 246 Enables statistics collection and reporting. You can also force this setting
 247 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 248 environment settings override the application, with <MYAPP>_STATS having the
 249 highest priority.
 250
 251 e.g.
 252
 253    use Catalyst qw/-Stats=1/
 254
 255 =head1 METHODS
 256
 257 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 258
 259 =head2 $c->action
 260
 261 Returns a L<Catalyst::Action> object for the current action, which
 262 stringifies to the action name. See L<Catalyst::Action>.
 263
 264 =head2 $c->namespace
 265
 266 Returns the namespace of the current action, i.e., the URI prefix
 267 corresponding to the controller of the current action. For example:
 268
 269     # in Controller::Foo::Bar
 270     $c->namespace; # returns 'foo/bar';
 271
 272 =head2 $c->request
 273
 274 =head2 $c->req
 275
 276 Returns the current L<Catalyst::Request> object, giving access to
 277 information about the current client request (including parameters,
 278 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 279
 280 =head2 REQUEST FLOW HANDLING
 281
 282 =head2 $c->forward( $action [, \@arguments ] )
 283
 284 =head2 $c->forward( $class, $method, [, \@arguments ] )
 285
 286 Forwards processing to another action, by its private name. If you give a
 287 class name but no method, C<process()> is called. You may also optionally
 288 pass arguments in an arrayref. The action will receive the arguments in
 289 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 290 C<< $c->req->args >> will be restored to the previous values.
 291
 292 Any data C<return>ed from the action forwarded to, will be returned by the
 293 call to forward.
 294
 295     my $foodata = $c->forward('/foo');
 296     $c->forward('index');
 297     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 298     $c->forward('MyApp::View::TT');
 299
 300 Note that forward implies an C<<eval { }>> around the call (actually
 301 C<execute> does), thus de-fatalizing all 'dies' within the called
 302 action. If you want C<die> to propagate you need to do something like:
 303
 304     $c->forward('foo');
 305     die $c->error if $c->error;
 306
 307 Or make sure to always return true values from your actions and write
 308 your code like this:
 309
 310     $c->forward('foo') || return;
 311
 312 =cut
 313
 314 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 315
 316 =head2 $c->detach( $action [, \@arguments ] )
 317
 318 =head2 $c->detach( $class, $method, [, \@arguments ] )
 319
 320 =head2 $c->detach()
 321
 322 The same as C<forward>, but doesn't return to the previous action when
 323 processing is finished.
 324
 325 When called with no arguments it escapes the processing chain entirely.
 326
 327 =cut
 328
 329 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 330
 331 =head2 $c->go( $action [, \@arguments ] )
 332
 333 =head2 $c->go( $class, $method, [, \@arguments ] )
 334
 335 Almost the same as C<detach>, but does a full dispatch, instead of just
 336 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 337 C<auto> and the method you go to is called, just like a new request.
 338
 339 C<$c-E<gt>stash> is kept unchanged.
 340
 341 =cut
 342
 343 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 344
 345 =head2 $c->response
 346
 347 =head2 $c->res
 348
 349 Returns the current L<Catalyst::Response> object, see there for details.
 350
 351 =head2 $c->stash
 352
 353 Returns a hashref to the stash, which may be used to store data and pass
 354 it between components during a request. You can also set hash keys by
 355 passing arguments. The stash is automatically sent to the view. The
 356 stash is cleared at the end of a request; it cannot be used for
 357 persistent storage (for this you must use a session; see
 358 L<Catalyst::Plugin::Session> for a complete system integrated with
 359 Catalyst).
 360
 361     $c->stash->{foo} = $bar;
 362     $c->stash( { moose => 'majestic', qux => 0 } );
 363     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 364
 365     # stash is automatically passed to the view for use in a template
 366     $c->forward( 'MyApp::View::TT' );
 367
 368 =cut
 369
 370 sub stash {
 371     my $c = shift;
 372     if (@_) {
 373         my $stash = @_ > 1 ? {@_} : $_[0];
 374         croak('stash takes a hash or hashref') unless ref $stash;
 375         foreach my $key ( keys %$stash ) {
 376             $c->{stash}->{$key} = $stash->{$key};
 377         }
 378     }
 379     return $c->{stash};
 380 }
 381
 382 =head2 $c->error
 383
 384 =head2 $c->error($error, ...)
 385
 386 =head2 $c->error($arrayref)
 387
 388 Returns an arrayref containing error messages.  If Catalyst encounters an
 389 error while processing a request, it stores the error in $c->error.  This
 390 method should only be used to store fatal error messages.
 391
 392     my @error = @{ $c->error };
 393
 394 Add a new error.
 395
 396     $c->error('Something bad happened');
 397
 398 =cut
 399
 400 sub error {
 401     my $c = shift;
 402     if ( $_[0] ) {
 403         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 404         croak @$error unless ref $c;
 405         push @{ $c->{error} }, @$error;
 406     }
 407     elsif ( defined $_[0] ) { $c->{error} = undef }
 408     return $c->{error} || [];
 409 }
 410
 411
 412 =head2 $c->state
 413
 414 Contains the return value of the last executed action.
 415
 416 =head2 $c->clear_errors
 417
 418 Clear errors.  You probably don't want to clear the errors unless you are
 419 implementing a custom error screen.
 420
 421 This is equivalent to running
 422
 423     $c->error(0);
 424
 425 =cut
 426
 427 sub clear_errors {
 428     my $c = shift;
 429     $c->error(0);
 430 }
 431
 432 # search components given a name and some prefixes
 433 sub _comp_search_prefixes {
 434     my ( $c, $name, @prefixes ) = @_;
 435     my $appclass = ref $c || $c;
 436     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 437
 438     # map the original component name to the sub part that we will search against
 439     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 440         grep { /$filter/ } keys %{ $c->components };
 441
 442     # undef for a name will return all
 443     return keys %eligible if !defined $name;
 444
 445     my $query  = ref $name ? $name : qr/^$name$/i;
 446     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 447
 448     return map { $c->components->{ $_ } } @result if @result;
 449
 450     # if we were given a regexp to search against, we're done.
 451     return if ref $name;
 452
 453     # regexp fallback
 454     $query  = qr/$name/i;
 455     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 456
 457     # don't warn if we didn't find any results, it just might not exist
 458     if( @result ) {
 459         $c->log->warn( 'Relying on the regexp fallback behavior for component resolution is unreliable and unsafe.' );
 460         $c->log->warn( 'If you really want to search, pass in a regexp as the argument.' );
 461     }
 462
 463     return @result;
 464 }
 465
 466 # Find possible names for a prefix
 467 sub _comp_names {
 468     my ( $c, @prefixes ) = @_;
 469     my $appclass = ref $c || $c;
 470
 471     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 472
 473     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 474     return @names;
 475 }
 476
 477 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 478 sub _filter_component {
 479     my ( $c, $comp, @args ) = @_;
 480
 481     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 482         return $comp->ACCEPT_CONTEXT( $c, @args );
 483     }
 484
 485     return $comp;
 486 }
 487
 488 =head2 COMPONENT ACCESSORS
 489
 490 =head2 $c->controller($name)
 491
 492 Gets a L<Catalyst::Controller> instance by name.
 493
 494     $c->controller('Foo')->do_stuff;
 495
 496 If the name is omitted, will return the controller for the dispatched
 497 action.
 498
 499 If you want to search for controllers, pass in a regexp as the argument.
 500
 501     # find all controllers that start with Foo
 502     my @foo_controllers = $c->controller(qr{^Foo});
 503
 504
 505 =cut
 506
 507 sub controller {
 508     my ( $c, $name, @args ) = @_;
 509
 510     if( $name ) {
 511         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 512         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 513         return $c->_filter_component( $result[ 0 ], @args );
 514     }
 515
 516     return $c->component( $c->action->class );
 517 }
 518
 519 =head2 $c->model($name)
 520
 521 Gets a L<Catalyst::Model> instance by name.
 522
 523     $c->model('Foo')->do_stuff;
 524
 525 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 526
 527 If the name is omitted, it will look for
 528  - a model object in $c->stash->{current_model_instance}, then
 529  - a model name in $c->stash->{current_model}, then
 530  - a config setting 'default_model', or
 531  - check if there is only one model, and return it if that's the case.
 532
 533 If you want to search for models, pass in a regexp as the argument.
 534
 535     # find all models that start with Foo
 536     my @foo_models = $c->model(qr{^Foo});
 537
 538 =cut
 539
 540 sub model {
 541     my ( $c, $name, @args ) = @_;
 542
 543     if( $name ) {
 544         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 545         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 546         return $c->_filter_component( $result[ 0 ], @args );
 547     }
 548
 549     if (ref $c) {
 550         return $c->stash->{current_model_instance}
 551           if $c->stash->{current_model_instance};
 552         return $c->model( $c->stash->{current_model} )
 553           if $c->stash->{current_model};
 554     }
 555     return $c->model( $c->config->{default_model} )
 556       if $c->config->{default_model};
 557
 558     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 559
 560     if( $rest ) {
 561         $c->log->warn( 'Calling $c->model() will return a random model unless you specify one of:' );
 562         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 563         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 564         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 565         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 566     }
 567
 568     return $c->_filter_component( $comp );
 569 }
 570
 571
 572 =head2 $c->view($name)
 573
 574 Gets a L<Catalyst::View> instance by name.
 575
 576     $c->view('Foo')->do_stuff;
 577
 578 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 579
 580 If the name is omitted, it will look for
 581  - a view object in $c->stash->{current_view_instance}, then
 582  - a view name in $c->stash->{current_view}, then
 583  - a config setting 'default_view', or
 584  - check if there is only one view, and return it if that's the case.
 585
 586 If you want to search for views, pass in a regexp as the argument.
 587
 588     # find all views that start with Foo
 589     my @foo_views = $c->view(qr{^Foo});
 590
 591 =cut
 592
 593 sub view {
 594     my ( $c, $name, @args ) = @_;
 595
 596     if( $name ) {
 597         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 598         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 599         return $c->_filter_component( $result[ 0 ], @args );
 600     }
 601
 602     if (ref $c) {
 603         return $c->stash->{current_view_instance}
 604           if $c->stash->{current_view_instance};
 605         return $c->view( $c->stash->{current_view} )
 606           if $c->stash->{current_view};
 607     }
 608     return $c->view( $c->config->{default_view} )
 609       if $c->config->{default_view};
 610
 611     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 612
 613     if( $rest ) {
 614         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 615         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 616         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 617         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 618         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 619     }
 620
 621     return $c->_filter_component( $comp );
 622 }
 623
 624 =head2 $c->controllers
 625
 626 Returns the available names which can be passed to $c->controller
 627
 628 =cut
 629
 630 sub controllers {
 631     my ( $c ) = @_;
 632     return $c->_comp_names(qw/Controller C/);
 633 }
 634
 635 =head2 $c->models
 636
 637 Returns the available names which can be passed to $c->model
 638
 639 =cut
 640
 641 sub models {
 642     my ( $c ) = @_;
 643     return $c->_comp_names(qw/Model M/);
 644 }
 645
 646
 647 =head2 $c->views
 648
 649 Returns the available names which can be passed to $c->view
 650
 651 =cut
 652
 653 sub views {
 654     my ( $c ) = @_;
 655     return $c->_comp_names(qw/View V/);
 656 }
 657
 658 =head2 $c->comp($name)
 659
 660 =head2 $c->component($name)
 661
 662 Gets a component object by name. This method is not recommended,
 663 unless you want to get a specific component by full
 664 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 665 should be used instead.
 666
 667 If C<$name> is a regexp, a list of components matched against the full
 668 component name will be returned.
 669
 670 =cut
 671
 672 sub component {
 673     my ( $c, $name, @args ) = @_;
 674
 675     if( $name ) {
 676         my $comps = $c->components;
 677
 678         if( !ref $name ) {
 679             # is it the exact name?
 680             return $comps->{ $name } if exists $comps->{ $name };
 681
 682             # perhaps we just omitted "MyApp"?
 683             my $composed = ( ref $c || $c ) . "::${name}";
 684             return $comps->{ $composed } if exists $comps->{ $composed };
 685
 686             # search all of the models, views and controllers
 687             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 688             return $c->_filter_component( $comp, @args ) if $comp;
 689         }
 690
 691         # This is here so $c->comp( '::M::' ) works
 692         my $query = ref $name ? $name : qr{$name}i;
 693
 694         my @result = grep { m{$query} } keys %{ $c->components };
 695         return @result if ref $name;
 696
 697         if( $result[ 0 ] ) {
 698             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 699             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 700             return $result[ 0 ];
 701         }
 702
 703         # I would expect to return an empty list here, but that breaks back-compat
 704     }
 705
 706     # fallback
 707     return sort keys %{ $c->components };
 708 }
 709
 710 =head2 CLASS DATA AND HELPER CLASSES
 711
 712 =head2 $c->config
 713
 714 Returns or takes a hashref containing the application's configuration.
 715
 716     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 717
 718 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 719 like myapp.yml in your applications home directory. See
 720 L<Catalyst::Plugin::ConfigLoader>.
 721
 722     ---
 723     db: dsn:SQLite:foo.db
 724
 725
 726 =cut
 727
 728 sub config {
 729     my $c = shift;
 730
 731     $c->log->warn("Setting config after setup has been run is not a good idea.")
 732       if ( @_ and $c->setup_finished );
 733
 734     $c->NEXT::config(@_);
 735 }
 736
 737 =head2 $c->log
 738
 739 Returns the logging object instance. Unless it is already set, Catalyst
 740 sets this up with a L<Catalyst::Log> object. To use your own log class,
 741 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 742 C<< __PACKAGE__->setup >>.
 743
 744  __PACKAGE__->log( MyLogger->new );
 745  __PACKAGE__->setup;
 746
 747 And later:
 748
 749     $c->log->info( 'Now logging with my own logger!' );
 750
 751 Your log class should implement the methods described in
 752 L<Catalyst::Log>.
 753
 754
 755 =head2 $c->debug
 756
 757 Overload to enable debug messages (same as -Debug option).
 758
 759 Note that this is a static method, not an accessor and should be overloaded
 760 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 761
 762 =cut
 763
 764 sub debug { 0 }
 765
 766 =head2 $c->dispatcher
 767
 768 Returns the dispatcher instance. Stringifies to class name. See
 769 L<Catalyst::Dispatcher>.
 770
 771 =head2 $c->engine
 772
 773 Returns the engine instance. Stringifies to the class name. See
 774 L<Catalyst::Engine>.
 775
 776
 777 =head2 UTILITY METHODS
 778
 779 =head2 $c->path_to(@path)
 780
 781 Merges C<@path> with C<< $c->config->{home} >> and returns a
 782 L<Path::Class::Dir> object.
 783
 784 For example:
 785
 786     $c->path_to( 'db', 'sqlite.db' );
 787
 788 =cut
 789
 790 sub path_to {
 791     my ( $c, @path ) = @_;
 792     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 793     if ( -d $path ) { return $path }
 794     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 795 }
 796
 797 =head2 $c->plugin( $name, $class, @args )
 798
 799 Helper method for plugins. It creates a classdata accessor/mutator and
 800 loads and instantiates the given class.
 801
 802     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 803
 804     $c->prototype->define_javascript_functions;
 805
 806 =cut
 807
 808 sub plugin {
 809     my ( $class, $name, $plugin, @args ) = @_;
 810     $class->_register_plugin( $plugin, 1 );
 811
 812     eval { $plugin->import };
 813     $class->mk_classdata($name);
 814     my $obj;
 815     eval { $obj = $plugin->new(@args) };
 816
 817     if ($@) {
 818         Catalyst::Exception->throw( message =>
 819               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 820     }
 821
 822     $class->$name($obj);
 823     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 824       if $class->debug;
 825 }
 826
 827 =head2 MyApp->setup
 828
 829 Initializes the dispatcher and engine, loads any plugins, and loads the
 830 model, view, and controller components. You may also specify an array
 831 of plugins to load here, if you choose to not load them in the C<use
 832 Catalyst> line.
 833
 834     MyApp->setup;
 835     MyApp->setup( qw/-Debug/ );
 836
 837 =cut
 838
 839 sub setup {
 840     my ( $class, @arguments ) = @_;
 841
 842     $class->log->warn("Running setup twice is not a good idea.")
 843       if ( $class->setup_finished );
 844
 845     unless ( $class->isa('Catalyst') ) {
 846
 847         Catalyst::Exception->throw(
 848             message => qq/'$class' does not inherit from Catalyst/ );
 849     }
 850
 851     if ( $class->arguments ) {
 852         @arguments = ( @arguments, @{ $class->arguments } );
 853     }
 854
 855     # Process options
 856     my $flags = {};
 857
 858     foreach (@arguments) {
 859
 860         if (/^-Debug$/) {
 861             $flags->{log} =
 862               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 863         }
 864         elsif (/^-(\w+)=?(.*)$/) {
 865             $flags->{ lc $1 } = $2;
 866         }
 867         else {
 868             push @{ $flags->{plugins} }, $_;
 869         }
 870     }
 871
 872     $class->setup_home( delete $flags->{home} );
 873
 874     $class->setup_log( delete $flags->{log} );
 875     $class->setup_plugins( delete $flags->{plugins} );
 876     $class->setup_dispatcher( delete $flags->{dispatcher} );
 877     $class->setup_engine( delete $flags->{engine} );
 878     $class->setup_stats( delete $flags->{stats} );
 879
 880     for my $flag ( sort keys %{$flags} ) {
 881
 882         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 883             &$code( $class, delete $flags->{$flag} );
 884         }
 885         else {
 886             $class->log->warn(qq/Unknown flag "$flag"/);
 887         }
 888     }
 889
 890     eval { require Catalyst::Devel; };
 891     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 892         $class->log->warn(<<"EOF");
 893 You are running an old script!
 894
 895   Please update by running (this will overwrite existing files):
 896     catalyst.pl -force -scripts $class
 897
 898   or (this will not overwrite existing files):
 899     catalyst.pl -scripts $class
 900
 901 EOF
 902     }
 903
 904     if ( $class->debug ) {
 905         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 906
 907         if (@plugins) {
 908             my $t = Text::SimpleTable->new(74);
 909             $t->row($_) for @plugins;
 910             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 911         }
 912
 913         my $dispatcher = $class->dispatcher;
 914         my $engine     = $class->engine;
 915         my $home       = $class->config->{home};
 916
 917         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 918         $class->log->debug(qq/Loaded engine "$engine"/);
 919
 920         $home
 921           ? ( -d $home )
 922           ? $class->log->debug(qq/Found home "$home"/)
 923           : $class->log->debug(qq/Home "$home" doesn't exist/)
 924           : $class->log->debug(q/Couldn't find home/);
 925     }
 926
 927     # Call plugins setup
 928     {
 929         no warnings qw/redefine/;
 930         local *setup = sub { };
 931         $class->setup;
 932     }
 933
 934     # Initialize our data structure
 935     $class->components( {} );
 936
 937     $class->setup_components;
 938
 939     if ( $class->debug ) {
 940         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 941         for my $comp ( sort keys %{ $class->components } ) {
 942             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 943             $t->row( $comp, $type );
 944         }
 945         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 946           if ( keys %{ $class->components } );
 947     }
 948
 949     # Add our self to components, since we are also a component
 950     $class->components->{$class} = $class;
 951
 952     $class->setup_actions;
 953
 954     if ( $class->debug ) {
 955         my $name = $class->config->{name} || 'Application';
 956         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 957     }
 958     $class->log->_flush() if $class->log->can('_flush');
 959
 960     $class->setup_finished(1);
 961 }
 962
 963 =head2 $c->uri_for( $path, @args?, \%query_values? )
 964
 965 Merges path with C<< $c->request->base >> for absolute URIs and with
 966 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 967 object. If any args are passed, they are added at the end of the path.
 968 If the last argument to C<uri_for> is a hash reference, it is assumed to
 969 contain GET parameter key/value pairs, which will be appended to the URI
 970 in standard fashion.
 971
 972 Note that uri_for is destructive to the passed hashref.  Subsequent calls
 973 with the same hashref may have unintended results.
 974
 975 Instead of C<$path>, you can also optionally pass a C<$action> object
 976 which will be resolved to a path using
 977 C<< $c->dispatcher->uri_for_action >>; if the first element of
 978 C<@args> is an arrayref it is treated as a list of captures to be passed
 979 to C<uri_for_action>.
 980
 981 =cut
 982
 983 sub uri_for {
 984     my ( $c, $path, @args ) = @_;
 985
 986     if ( Scalar::Util::blessed($path) ) { # action object
 987         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 988                          ? shift(@args)
 989                          : [] );
 990         $path = $c->dispatcher->uri_for_action($path, $captures);
 991         return undef unless defined($path);
 992         $path = '/' if $path eq '';
 993     }
 994
 995     undef($path) if (defined $path && $path eq '');
 996
 997     my $params =
 998       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 999
1000     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1001     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1002
1003     unshift(@args, $path);
1004
1005     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1006         my $namespace = $c->namespace;
1007         if (defined $path) { # cheesy hack to handle path '../foo'
1008            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1009         }
1010         unshift(@args, $namespace || '');
1011     }
1012
1013     # join args with '/', or a blank string
1014     my $args = join('/', grep { defined($_) } @args);
1015     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1016     $args =~ s!^/!!;
1017     my $base = $c->req->base;
1018     my $class = ref($base);
1019     $base =~ s{(?<!/)$}{/};
1020
1021     my $query = '';
1022
1023     if (my @keys = keys %$params) {
1024       # somewhat lifted from URI::_query's query_form
1025       $query = '?'.join('&', map {
1026           my $val = $params->{$_};
1027           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1028           s/ /+/g;
1029           my $key = $_;
1030           $val = '' unless defined $val;
1031           (map {
1032               $_ = "$_";
1033               utf8::encode( $_ ) if utf8::is_utf8($_);
1034               # using the URI::Escape pattern here so utf8 chars survive
1035               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1036               s/ /+/g;
1037               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1038       } @keys);
1039     }
1040
1041     my $res = bless(\"${base}${args}${query}", $class);
1042     $res;
1043 }
1044
1045 =head2 $c->welcome_message
1046
1047 Returns the Catalyst welcome HTML page.
1048
1049 =cut
1050
1051 sub welcome_message {
1052     my $c      = shift;
1053     my $name   = $c->config->{name};
1054     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1055     my $prefix = Catalyst::Utils::appprefix( ref $c );
1056     $c->response->content_type('text/html; charset=utf-8');
1057     return <<"EOF";
1058 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1059     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1060 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1061     <head>
1062     <meta http-equiv="Content-Language" content="en" />
1063     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1064         <title>$name on Catalyst $VERSION</title>
1065         <style type="text/css">
1066             body {
1067                 color: #000;
1068                 background-color: #eee;
1069             }
1070             div#content {
1071                 width: 640px;
1072                 margin-left: auto;
1073                 margin-right: auto;
1074                 margin-top: 10px;
1075                 margin-bottom: 10px;
1076                 text-align: left;
1077                 background-color: #ccc;
1078                 border: 1px solid #aaa;
1079             }
1080             p, h1, h2 {
1081                 margin-left: 20px;
1082                 margin-right: 20px;
1083                 font-family: verdana, tahoma, sans-serif;
1084             }
1085             a {
1086                 font-family: verdana, tahoma, sans-serif;
1087             }
1088             :link, :visited {
1089                     text-decoration: none;
1090                     color: #b00;
1091                     border-bottom: 1px dotted #bbb;
1092             }
1093             :link:hover, :visited:hover {
1094                     color: #555;
1095             }
1096             div#topbar {
1097                 margin: 0px;
1098             }
1099             pre {
1100                 margin: 10px;
1101                 padding: 8px;
1102             }
1103             div#answers {
1104                 padding: 8px;
1105                 margin: 10px;
1106                 background-color: #fff;
1107                 border: 1px solid #aaa;
1108             }
1109             h1 {
1110                 font-size: 0.9em;
1111                 font-weight: normal;
1112                 text-align: center;
1113             }
1114             h2 {
1115                 font-size: 1.0em;
1116             }
1117             p {
1118                 font-size: 0.9em;
1119             }
1120             p img {
1121                 float: right;
1122                 margin-left: 10px;
1123             }
1124             span#appname {
1125                 font-weight: bold;
1126                 font-size: 1.6em;
1127             }
1128         </style>
1129     </head>
1130     <body>
1131         <div id="content">
1132             <div id="topbar">
1133                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1134                     $VERSION</h1>
1135              </div>
1136              <div id="answers">
1137                  <p>
1138                  <img src="$logo" alt="Catalyst Logo" />
1139                  </p>
1140                  <p>Welcome to the  world of Catalyst.
1141                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1142                     framework will make web development something you had
1143                     never expected it to be: Fun, rewarding, and quick.</p>
1144                  <h2>What to do now?</h2>
1145                  <p>That really depends  on what <b>you</b> want to do.
1146                     We do, however, provide you with a few starting points.</p>
1147                  <p>If you want to jump right into web development with Catalyst
1148                     you might want to start with a tutorial.</p>
1149 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1150 </pre>
1151 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1152 <pre>
1153 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1154 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1155 </code></pre>
1156                  <h2>What to do next?</h2>
1157                  <p>Next it's time to write an actual application. Use the
1158                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1159                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1160                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1161                     they can save you a lot of work.</p>
1162                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1163                     <p>Also, be sure to check out the vast and growing
1164                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1165                     you are likely to find what you need there.
1166                     </p>
1167
1168                  <h2>Need help?</h2>
1169                  <p>Catalyst has a very active community. Here are the main places to
1170                     get in touch with us.</p>
1171                  <ul>
1172                      <li>
1173                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1174                      </li>
1175                      <li>
1176                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1177                      </li>
1178                      <li>
1179                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1180                      </li>
1181                  </ul>
1182                  <h2>In conclusion</h2>
1183                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1184                     as we enjoyed making it. Please contact us if you have ideas
1185                     for improvement or other feedback.</p>
1186              </div>
1187          </div>
1188     </body>
1189 </html>
1190 EOF
1191 }
1192
1193 =head1 INTERNAL METHODS
1194
1195 These methods are not meant to be used by end users.
1196
1197 =head2 $c->components
1198
1199 Returns a hash of components.
1200
1201 =head2 $c->context_class
1202
1203 Returns or sets the context class.
1204
1205 =head2 $c->counter
1206
1207 Returns a hashref containing coderefs and execution counts (needed for
1208 deep recursion detection).
1209
1210 =head2 $c->depth
1211
1212 Returns the number of actions on the current internal execution stack.
1213
1214 =head2 $c->dispatch
1215
1216 Dispatches a request to actions.
1217
1218 =cut
1219
1220 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1221
1222 =head2 $c->dispatcher_class
1223
1224 Returns or sets the dispatcher class.
1225
1226 =head2 $c->dump_these
1227
1228 Returns a list of 2-element array references (name, structure) pairs
1229 that will be dumped on the error page in debug mode.
1230
1231 =cut
1232
1233 sub dump_these {
1234     my $c = shift;
1235     [ Request => $c->req ],
1236     [ Response => $c->res ],
1237     [ Stash => $c->stash ],
1238     [ Config => $c->config ];
1239 }
1240
1241 =head2 $c->engine_class
1242
1243 Returns or sets the engine class.
1244
1245 =head2 $c->execute( $class, $coderef )
1246
1247 Execute a coderef in given class and catch exceptions. Errors are available
1248 via $c->error.
1249
1250 =cut
1251
1252 sub execute {
1253     my ( $c, $class, $code ) = @_;
1254     $class = $c->component($class) || $class;
1255     $c->state(0);
1256
1257     if ( $c->depth >= $RECURSION ) {
1258         my $action = "$code";
1259         $action = "/$action" unless $action =~ /->/;
1260         my $error = qq/Deep recursion detected calling "$action"/;
1261         $c->log->error($error);
1262         $c->error($error);
1263         $c->state(0);
1264         return $c->state;
1265     }
1266
1267     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1268
1269     push( @{ $c->stack }, $code );
1270
1271     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1272
1273     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1274
1275     my $last = pop( @{ $c->stack } );
1276
1277     if ( my $error = $@ ) {
1278         if ( !ref($error) and $error eq $DETACH ) {
1279             die $DETACH if($c->depth > 1);
1280         }
1281         elsif ( !ref($error) and $error eq $GO ) {
1282             die $GO if($c->depth > 0);
1283         }
1284         else {
1285             unless ( ref $error ) {
1286                 no warnings 'uninitialized';
1287                 chomp $error;
1288                 my $class = $last->class;
1289                 my $name  = $last->name;
1290                 $error = qq/Caught exception in $class->$name "$error"/;
1291             }
1292             $c->error($error);
1293             $c->state(0);
1294         }
1295     }
1296     return $c->state;
1297 }
1298
1299 sub _stats_start_execute {
1300     my ( $c, $code ) = @_;
1301
1302     return if ( ( $code->name =~ /^_.*/ )
1303         && ( !$c->config->{show_internal_actions} ) );
1304
1305     $c->counter->{"$code"}++;
1306
1307     my $action = "$code";
1308     $action = "/$action" unless $action =~ /->/;
1309
1310     # determine if the call was the result of a forward
1311     # this is done by walking up the call stack and looking for a calling
1312     # sub of Catalyst::forward before the eval
1313     my $callsub = q{};
1314     for my $index ( 2 .. 11 ) {
1315         last
1316         if ( ( caller($index) )[0] eq 'Catalyst'
1317             && ( caller($index) )[3] eq '(eval)' );
1318
1319         if ( ( caller($index) )[3] =~ /forward$/ ) {
1320             $callsub = ( caller($index) )[3];
1321             $action  = "-> $action";
1322             last;
1323         }
1324     }
1325
1326     my $uid = "$code" . $c->counter->{"$code"};
1327
1328     # is this a root-level call or a forwarded call?
1329     if ( $callsub =~ /forward$/ ) {
1330
1331         # forward, locate the caller
1332         if ( my $parent = $c->stack->[-1] ) {
1333             $c->stats->profile(
1334                 begin  => $action,
1335                 parent => "$parent" . $c->counter->{"$parent"},
1336                 uid    => $uid,
1337             );
1338         }
1339         else {
1340
1341             # forward with no caller may come from a plugin
1342             $c->stats->profile(
1343                 begin => $action,
1344                 uid   => $uid,
1345             );
1346         }
1347     }
1348     else {
1349
1350         # root-level call
1351         $c->stats->profile(
1352             begin => $action,
1353             uid   => $uid,
1354         );
1355     }
1356     return $action;
1357
1358 }
1359
1360 sub _stats_finish_execute {
1361     my ( $c, $info ) = @_;
1362     $c->stats->profile( end => $info );
1363 }
1364
1365 =head2 $c->_localize_fields( sub { }, \%keys );
1366
1367 =cut
1368
1369 sub _localize_fields {
1370     my ( $c, $localized, $code ) = ( @_ );
1371
1372     my $request = delete $localized->{request} || {};
1373     my $response = delete $localized->{response} || {};
1374
1375     local @{ $c }{ keys %$localized } = values %$localized;
1376     local @{ $c->request }{ keys %$request } = values %$request;
1377     local @{ $c->response }{ keys %$response } = values %$response;
1378
1379     $code->();
1380 }
1381
1382 =head2 $c->finalize
1383
1384 Finalizes the request.
1385
1386 =cut
1387
1388 sub finalize {
1389     my $c = shift;
1390
1391     for my $error ( @{ $c->error } ) {
1392         $c->log->error($error);
1393     }
1394
1395     # Allow engine to handle finalize flow (for POE)
1396     if ( $c->engine->can('finalize') ) {
1397         $c->engine->finalize($c);
1398     }
1399     else {
1400
1401         $c->finalize_uploads;
1402
1403         # Error
1404         if ( $#{ $c->error } >= 0 ) {
1405             $c->finalize_error;
1406         }
1407
1408         $c->finalize_headers;
1409
1410         # HEAD request
1411         if ( $c->request->method eq 'HEAD' ) {
1412             $c->response->body('');
1413         }
1414
1415         $c->finalize_body;
1416     }
1417
1418     if ($c->use_stats) {
1419         my $elapsed = sprintf '%f', $c->stats->elapsed;
1420         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1421         $c->log->info(
1422             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1423     }
1424
1425     return $c->response->status;
1426 }
1427
1428 =head2 $c->finalize_body
1429
1430 Finalizes body.
1431
1432 =cut
1433
1434 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1435
1436 =head2 $c->finalize_cookies
1437
1438 Finalizes cookies.
1439
1440 =cut
1441
1442 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1443
1444 =head2 $c->finalize_error
1445
1446 Finalizes error.
1447
1448 =cut
1449
1450 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1451
1452 =head2 $c->finalize_headers
1453
1454 Finalizes headers.
1455
1456 =cut
1457
1458 sub finalize_headers {
1459     my $c = shift;
1460
1461     # Check if we already finalized headers
1462     return if $c->response->{_finalized_headers};
1463
1464     # Handle redirects
1465     if ( my $location = $c->response->redirect ) {
1466         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1467         $c->response->header( Location => $location );
1468
1469         if ( !$c->response->body ) {
1470             # Add a default body if none is already present
1471             $c->response->body(
1472                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1473             );
1474         }
1475     }
1476
1477     # Content-Length
1478     if ( $c->response->body && !$c->response->content_length ) {
1479
1480         # get the length from a filehandle
1481         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1482         {
1483             my $stat = stat $c->response->body;
1484             if ( $stat && $stat->size > 0 ) {
1485                 $c->response->content_length( $stat->size );
1486             }
1487             else {
1488                 $c->log->warn('Serving filehandle without a content-length');
1489             }
1490         }
1491         else {
1492             # everything should be bytes at this point, but just in case
1493             $c->response->content_length( bytes::length( $c->response->body ) );
1494         }
1495     }
1496
1497     # Errors
1498     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1499         $c->response->headers->remove_header("Content-Length");
1500         $c->response->body('');
1501     }
1502
1503     $c->finalize_cookies;
1504
1505     $c->engine->finalize_headers( $c, @_ );
1506
1507     # Done
1508     $c->response->{_finalized_headers} = 1;
1509 }
1510
1511 =head2 $c->finalize_output
1512
1513 An alias for finalize_body.
1514
1515 =head2 $c->finalize_read
1516
1517 Finalizes the input after reading is complete.
1518
1519 =cut
1520
1521 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1522
1523 =head2 $c->finalize_uploads
1524
1525 Finalizes uploads. Cleans up any temporary files.
1526
1527 =cut
1528
1529 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1530
1531 =head2 $c->get_action( $action, $namespace )
1532
1533 Gets an action in a given namespace.
1534
1535 =cut
1536
1537 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1538
1539 =head2 $c->get_actions( $action, $namespace )
1540
1541 Gets all actions of a given name in a namespace and all parent
1542 namespaces.
1543
1544 =cut
1545
1546 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1547
1548 =head2 $c->handle_request( $class, @arguments )
1549
1550 Called to handle each HTTP request.
1551
1552 =cut
1553
1554 sub handle_request {
1555     my ( $class, @arguments ) = @_;
1556
1557     # Always expect worst case!
1558     my $status = -1;
1559     eval {
1560         if ($class->debug) {
1561             my $secs = time - $START || 1;
1562             my $av = sprintf '%.3f', $COUNT / $secs;
1563             my $time = localtime time;
1564             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1565         }
1566
1567         my $c = $class->prepare(@arguments);
1568         $c->dispatch;
1569         $status = $c->finalize;
1570     };
1571
1572     if ( my $error = $@ ) {
1573         chomp $error;
1574         $class->log->error(qq/Caught exception in engine "$error"/);
1575     }
1576
1577     $COUNT++;
1578     $class->log->_flush() if $class->log->can('_flush');
1579     return $status;
1580 }
1581
1582 =head2 $c->prepare( @arguments )
1583
1584 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1585 etc.).
1586
1587 =cut
1588
1589 sub prepare {
1590     my ( $class, @arguments ) = @_;
1591
1592     $class->context_class( ref $class || $class ) unless $class->context_class;
1593     my $c = $class->context_class->new(
1594         {
1595             counter => {},
1596             stack   => [],
1597             request => $class->request_class->new(
1598                 {
1599                     arguments        => [],
1600                     body_parameters  => {},
1601                     cookies          => {},
1602                     headers          => HTTP::Headers->new,
1603                     parameters       => {},
1604                     query_parameters => {},
1605                     secure           => 0,
1606                     captures         => [],
1607                     uploads          => {}
1608                 }
1609             ),
1610             response => $class->response_class->new(
1611                 {
1612                     body    => '',
1613                     cookies => {},
1614                     headers => HTTP::Headers->new(),
1615                     status  => 200
1616                 }
1617             ),
1618             stash => {},
1619             state => 0
1620         }
1621     );
1622
1623     $c->stats($class->stats_class->new)->enable($c->use_stats);
1624     if ( $c->debug ) {
1625         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1626     }
1627
1628     # For on-demand data
1629     $c->request->{_context}  = $c;
1630     $c->response->{_context} = $c;
1631     weaken( $c->request->{_context} );
1632     weaken( $c->response->{_context} );
1633
1634     # Allow engine to direct the prepare flow (for POE)
1635     if ( $c->engine->can('prepare') ) {
1636         $c->engine->prepare( $c, @arguments );
1637     }
1638     else {
1639         $c->prepare_request(@arguments);
1640         $c->prepare_connection;
1641         $c->prepare_query_parameters;
1642         $c->prepare_headers;
1643         $c->prepare_cookies;
1644         $c->prepare_path;
1645
1646         # Prepare the body for reading, either by prepare_body
1647         # or the user, if they are using $c->read
1648         $c->prepare_read;
1649
1650         # Parse the body unless the user wants it on-demand
1651         unless ( $c->config->{parse_on_demand} ) {
1652             $c->prepare_body;
1653         }
1654     }
1655
1656     my $method  = $c->req->method  || '';
1657     my $path    = $c->req->path;
1658     $path       = '/' unless length $path;
1659     my $address = $c->req->address || '';
1660
1661     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1662       if $c->debug;
1663
1664     $c->prepare_action;
1665
1666     return $c;
1667 }
1668
1669 =head2 $c->prepare_action
1670
1671 Prepares action. See L<Catalyst::Dispatcher>.
1672
1673 =cut
1674
1675 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1676
1677 =head2 $c->prepare_body
1678
1679 Prepares message body.
1680
1681 =cut
1682
1683 sub prepare_body {
1684     my $c = shift;
1685
1686     # Do we run for the first time?
1687     return if defined $c->request->{_body};
1688
1689     # Initialize on-demand data
1690     $c->engine->prepare_body( $c, @_ );
1691     $c->prepare_parameters;
1692     $c->prepare_uploads;
1693
1694     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1695         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1696         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1697             my $param = $c->req->body_parameters->{$key};
1698             my $value = defined($param) ? $param : '';
1699             $t->row( $key,
1700                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1701         }
1702         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1703     }
1704 }
1705
1706 =head2 $c->prepare_body_chunk( $chunk )
1707
1708 Prepares a chunk of data before sending it to L<HTTP::Body>.
1709
1710 See L<Catalyst::Engine>.
1711
1712 =cut
1713
1714 sub prepare_body_chunk {
1715     my $c = shift;
1716     $c->engine->prepare_body_chunk( $c, @_ );
1717 }
1718
1719 =head2 $c->prepare_body_parameters
1720
1721 Prepares body parameters.
1722
1723 =cut
1724
1725 sub prepare_body_parameters {
1726     my $c = shift;
1727     $c->engine->prepare_body_parameters( $c, @_ );
1728 }
1729
1730 =head2 $c->prepare_connection
1731
1732 Prepares connection.
1733
1734 =cut
1735
1736 sub prepare_connection {
1737     my $c = shift;
1738     $c->engine->prepare_connection( $c, @_ );
1739 }
1740
1741 =head2 $c->prepare_cookies
1742
1743 Prepares cookies.
1744
1745 =cut
1746
1747 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1748
1749 =head2 $c->prepare_headers
1750
1751 Prepares headers.
1752
1753 =cut
1754
1755 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1756
1757 =head2 $c->prepare_parameters
1758
1759 Prepares parameters.
1760
1761 =cut
1762
1763 sub prepare_parameters {
1764     my $c = shift;
1765     $c->prepare_body_parameters;
1766     $c->engine->prepare_parameters( $c, @_ );
1767 }
1768
1769 =head2 $c->prepare_path
1770
1771 Prepares path and base.
1772
1773 =cut
1774
1775 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1776
1777 =head2 $c->prepare_query_parameters
1778
1779 Prepares query parameters.
1780
1781 =cut
1782
1783 sub prepare_query_parameters {
1784     my $c = shift;
1785
1786     $c->engine->prepare_query_parameters( $c, @_ );
1787
1788     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1789         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1790         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1791             my $param = $c->req->query_parameters->{$key};
1792             my $value = defined($param) ? $param : '';
1793             $t->row( $key,
1794                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1795         }
1796         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1797     }
1798 }
1799
1800 =head2 $c->prepare_read
1801
1802 Prepares the input for reading.
1803
1804 =cut
1805
1806 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1807
1808 =head2 $c->prepare_request
1809
1810 Prepares the engine request.
1811
1812 =cut
1813
1814 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1815
1816 =head2 $c->prepare_uploads
1817
1818 Prepares uploads.
1819
1820 =cut
1821
1822 sub prepare_uploads {
1823     my $c = shift;
1824
1825     $c->engine->prepare_uploads( $c, @_ );
1826
1827     if ( $c->debug && keys %{ $c->request->uploads } ) {
1828         my $t = Text::SimpleTable->new(
1829             [ 12, 'Parameter' ],
1830             [ 26, 'Filename' ],
1831             [ 18, 'Type' ],
1832             [ 9,  'Size' ]
1833         );
1834         for my $key ( sort keys %{ $c->request->uploads } ) {
1835             my $upload = $c->request->uploads->{$key};
1836             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1837                 $t->row( $key, $u->filename, $u->type, $u->size );
1838             }
1839         }
1840         $c->log->debug( "File Uploads are:\n" . $t->draw );
1841     }
1842 }
1843
1844 =head2 $c->prepare_write
1845
1846 Prepares the output for writing.
1847
1848 =cut
1849
1850 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1851
1852 =head2 $c->request_class
1853
1854 Returns or sets the request class.
1855
1856 =head2 $c->response_class
1857
1858 Returns or sets the response class.
1859
1860 =head2 $c->read( [$maxlength] )
1861
1862 Reads a chunk of data from the request body. This method is designed to
1863 be used in a while loop, reading C<$maxlength> bytes on every call.
1864 C<$maxlength> defaults to the size of the request if not specified.
1865
1866 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1867 directly.
1868
1869 Warning: If you use read(), Catalyst will not process the body,
1870 so you will not be able to access POST parameters or file uploads via
1871 $c->request.  You must handle all body parsing yourself.
1872
1873 =cut
1874
1875 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1876
1877 =head2 $c->run
1878
1879 Starts the engine.
1880
1881 =cut
1882
1883 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1884
1885 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1886
1887 Sets an action in a given namespace.
1888
1889 =cut
1890
1891 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1892
1893 =head2 $c->setup_actions($component)
1894
1895 Sets up actions for a component.
1896
1897 =cut
1898
1899 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1900
1901 =head2 $c->setup_components
1902
1903 Sets up components. Specify a C<setup_components> config option to pass
1904 additional options directly to L<Module::Pluggable>. To add additional
1905 search paths, specify a key named C<search_extra> as an array
1906 reference. Items in the array beginning with C<::> will have the
1907 application class name prepended to them.
1908
1909 All components found will also have any
1910 L<Devel::InnerPackage|inner packages> loaded and set up as components.
1911 Note, that modules which are B<not> an I<inner package> of the main
1912 file namespace loaded will not be instantiated as components.
1913
1914 =cut
1915
1916 sub setup_components {
1917     my $class = shift;
1918
1919     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1920     my $config  = $class->config->{ setup_components };
1921     my $extra   = delete $config->{ search_extra } || [];
1922
1923     push @paths, @$extra;
1924
1925     my $locator = Module::Pluggable::Object->new(
1926         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1927         %$config
1928     );
1929
1930     my @comps = sort { length $a <=> length $b } $locator->plugins;
1931     my %comps = map { $_ => 1 } @comps;
1932
1933     for my $component ( @comps ) {
1934
1935         # We pass ignore_loaded here so that overlay files for (e.g.)
1936         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
1937         # we know M::P::O found a file on disk so this is safe
1938
1939         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1940
1941         my $module  = $class->setup_component( $component );
1942         my %modules = (
1943             $component => $module,
1944             map {
1945                 $_ => $class->setup_component( $_ )
1946             } grep {
1947               not exists $comps{$_}
1948             } Devel::InnerPackage::list_packages( $component )
1949         );
1950
1951         for my $key ( keys %modules ) {
1952             $class->components->{ $key } = $modules{ $key };
1953         }
1954     }
1955 }
1956
1957 =head2 $c->setup_component
1958
1959 =cut
1960
1961 sub setup_component {
1962     my( $class, $component ) = @_;
1963
1964     unless ( $component->can( 'COMPONENT' ) ) {
1965         return $component;
1966     }
1967
1968     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1969     my $config = $class->config->{ $suffix } || {};
1970
1971     my $instance = eval { $component->COMPONENT( $class, $config ); };
1972
1973     if ( my $error = $@ ) {
1974         chomp $error;
1975         Catalyst::Exception->throw(
1976             message => qq/Couldn't instantiate component "$component", "$error"/
1977         );
1978     }
1979
1980     Catalyst::Exception->throw(
1981         message =>
1982         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1983     ) unless eval { $instance->can( 'can' ) };
1984
1985     return $instance;
1986 }
1987
1988 =head2 $c->setup_dispatcher
1989
1990 Sets up dispatcher.
1991
1992 =cut
1993
1994 sub setup_dispatcher {
1995     my ( $class, $dispatcher ) = @_;
1996
1997     if ($dispatcher) {
1998         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1999     }
2000
2001     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2002         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2003     }
2004
2005     unless ($dispatcher) {
2006         $dispatcher = $class->dispatcher_class;
2007     }
2008
2009     unless (Class::Inspector->loaded($dispatcher)) {
2010         require Class::Inspector->filename($dispatcher);
2011     }
2012
2013     # dispatcher instance
2014     $class->dispatcher( $dispatcher->new );
2015 }
2016
2017 =head2 $c->setup_engine
2018
2019 Sets up engine.
2020
2021 =cut
2022
2023 sub setup_engine {
2024     my ( $class, $engine ) = @_;
2025
2026     if ($engine) {
2027         $engine = 'Catalyst::Engine::' . $engine;
2028     }
2029
2030     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2031         $engine = 'Catalyst::Engine::' . $env;
2032     }
2033
2034     if ( $ENV{MOD_PERL} ) {
2035
2036         # create the apache method
2037         {
2038             no strict 'refs';
2039             *{"$class\::apache"} = sub { shift->engine->apache };
2040         }
2041
2042         my ( $software, $version ) =
2043           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2044
2045         $version =~ s/_//g;
2046         $version =~ s/(\.[^.]+)\./$1/g;
2047
2048         if ( $software eq 'mod_perl' ) {
2049
2050             if ( !$engine ) {
2051
2052                 if ( $version >= 1.99922 ) {
2053                     $engine = 'Catalyst::Engine::Apache2::MP20';
2054                 }
2055
2056                 elsif ( $version >= 1.9901 ) {
2057                     $engine = 'Catalyst::Engine::Apache2::MP19';
2058                 }
2059
2060                 elsif ( $version >= 1.24 ) {
2061                     $engine = 'Catalyst::Engine::Apache::MP13';
2062                 }
2063
2064                 else {
2065                     Catalyst::Exception->throw( message =>
2066                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2067                 }
2068
2069             }
2070
2071             # install the correct mod_perl handler
2072             if ( $version >= 1.9901 ) {
2073                 *handler = sub  : method {
2074                     shift->handle_request(@_);
2075                 };
2076             }
2077             else {
2078                 *handler = sub ($$) { shift->handle_request(@_) };
2079             }
2080
2081         }
2082
2083         elsif ( $software eq 'Zeus-Perl' ) {
2084             $engine = 'Catalyst::Engine::Zeus';
2085         }
2086
2087         else {
2088             Catalyst::Exception->throw(
2089                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2090         }
2091     }
2092
2093     unless ($engine) {
2094         $engine = $class->engine_class;
2095     }
2096
2097     unless (Class::Inspector->loaded($engine)) {
2098         require Class::Inspector->filename($engine);
2099     }
2100
2101     # check for old engines that are no longer compatible
2102     my $old_engine;
2103     if ( $engine->isa('Catalyst::Engine::Apache')
2104         && !Catalyst::Engine::Apache->VERSION )
2105     {
2106         $old_engine = 1;
2107     }
2108
2109     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2110         && Catalyst::Engine::Server->VERSION le '0.02' )
2111     {
2112         $old_engine = 1;
2113     }
2114
2115     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2116         && $engine->VERSION eq '0.01' )
2117     {
2118         $old_engine = 1;
2119     }
2120
2121     elsif ($engine->isa('Catalyst::Engine::Zeus')
2122         && $engine->VERSION eq '0.01' )
2123     {
2124         $old_engine = 1;
2125     }
2126
2127     if ($old_engine) {
2128         Catalyst::Exception->throw( message =>
2129               qq/Engine "$engine" is not supported by this version of Catalyst/
2130         );
2131     }
2132
2133     # engine instance
2134     $class->engine( $engine->new );
2135 }
2136
2137 =head2 $c->setup_home
2138
2139 Sets up the home directory.
2140
2141 =cut
2142
2143 sub setup_home {
2144     my ( $class, $home ) = @_;
2145
2146     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2147         $home = $env;
2148     }
2149
2150     unless ($home) {
2151         $home = Catalyst::Utils::home($class);
2152     }
2153
2154     if ($home) {
2155         $class->config->{home} ||= $home;
2156         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2157     }
2158 }
2159
2160 =head2 $c->setup_log
2161
2162 Sets up log.
2163
2164 =cut
2165
2166 sub setup_log {
2167     my ( $class, $debug ) = @_;
2168
2169     unless ( $class->log ) {
2170         $class->log( Catalyst::Log->new );
2171     }
2172
2173     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2174     if ( defined($env_debug) ? $env_debug : $debug ) {
2175         no strict 'refs';
2176         *{"$class\::debug"} = sub { 1 };
2177         $class->log->debug('Debug messages enabled');
2178     }
2179 }
2180
2181 =head2 $c->setup_plugins
2182
2183 Sets up plugins.
2184
2185 =cut
2186
2187 =head2 $c->setup_stats
2188
2189 Sets up timing statistics class.
2190
2191 =cut
2192
2193 sub setup_stats {
2194     my ( $class, $stats ) = @_;
2195
2196     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2197
2198     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2199     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2200         no strict 'refs';
2201         *{"$class\::use_stats"} = sub { 1 };
2202         $class->log->debug('Statistics enabled');
2203     }
2204 }
2205
2206
2207 =head2 $c->registered_plugins
2208
2209 Returns a sorted list of the plugins which have either been stated in the
2210 import list or which have been added via C<< MyApp->plugin(@args); >>.
2211
2212 If passed a given plugin name, it will report a boolean value indicating
2213 whether or not that plugin is loaded.  A fully qualified name is required if
2214 the plugin name does not begin with C<Catalyst::Plugin::>.
2215
2216  if ($c->registered_plugins('Some::Plugin')) {
2217      ...
2218  }
2219
2220 =cut
2221
2222 {
2223
2224     sub registered_plugins {
2225         my $proto = shift;
2226         return sort keys %{ $proto->_plugins } unless @_;
2227         my $plugin = shift;
2228         return 1 if exists $proto->_plugins->{$plugin};
2229         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2230     }
2231
2232     sub _register_plugin {
2233         my ( $proto, $plugin, $instant ) = @_;
2234         my $class = ref $proto || $proto;
2235
2236         # no ignore_loaded here, the plugin may already have been
2237         # defined in memory and we don't want to error on "no file" if so
2238
2239         Catalyst::Utils::ensure_class_loaded( $plugin );
2240
2241         $proto->_plugins->{$plugin} = 1;
2242         unless ($instant) {
2243             no strict 'refs';
2244             unshift @{"$class\::ISA"}, $plugin;
2245         }
2246         return $class;
2247     }
2248
2249     sub setup_plugins {
2250         my ( $class, $plugins ) = @_;
2251
2252         $class->_plugins( {} ) unless $class->_plugins;
2253         $plugins ||= [];
2254         for my $plugin ( reverse @$plugins ) {
2255
2256             unless ( $plugin =~ s/\A\+// ) {
2257                 $plugin = "Catalyst::Plugin::$plugin";
2258             }
2259
2260             $class->_register_plugin($plugin);
2261         }
2262     }
2263 }
2264
2265 =head2 $c->stack
2266
2267 Returns an arrayref of the internal execution stack (actions that are
2268 currently executing).
2269
2270 =head2 $c->stats_class
2271
2272 Returns or sets the stats (timing statistics) class.
2273
2274 =head2 $c->use_stats
2275
2276 Returns 1 when stats collection is enabled.  Stats collection is enabled
2277 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2278 environment variable is set.
2279
2280 Note that this is a static method, not an accessor and should be overloaded
2281 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2282
2283 =cut
2284
2285 sub use_stats { 0 }
2286
2287
2288 =head2 $c->write( $data )
2289
2290 Writes $data to the output stream. When using this method directly, you
2291 will need to manually set the C<Content-Length> header to the length of
2292 your output data, if known.
2293
2294 =cut
2295
2296 sub write {
2297     my $c = shift;
2298
2299     # Finalize headers if someone manually writes output
2300     $c->finalize_headers;
2301
2302     return $c->engine->write( $c, @_ );
2303 }
2304
2305 =head2 version
2306
2307 Returns the Catalyst version number. Mostly useful for "powered by"
2308 messages in template systems.
2309
2310 =cut
2311
2312 sub version { return $Catalyst::VERSION }
2313
2314 =head1 INTERNAL ACTIONS
2315
2316 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2317 C<_ACTION>, and C<_END>. These are by default not shown in the private
2318 action table, but you can make them visible with a config parameter.
2319
2320     MyApp->config->{show_internal_actions} = 1;
2321
2322 =head1 CASE SENSITIVITY
2323
2324 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2325 mapped to C</foo/bar>. You can activate case sensitivity with a config
2326 parameter.
2327
2328     MyApp->config->{case_sensitive} = 1;
2329
2330 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2331
2332 =head1 ON-DEMAND PARSER
2333
2334 The request body is usually parsed at the beginning of a request,
2335 but if you want to handle input yourself, you can enable on-demand
2336 parsing with a config parameter.
2337
2338     MyApp->config->{parse_on_demand} = 1;
2339
2340 =head1 PROXY SUPPORT
2341
2342 Many production servers operate using the common double-server approach,
2343 with a lightweight frontend web server passing requests to a larger
2344 backend server. An application running on the backend server must deal
2345 with two problems: the remote user always appears to be C<127.0.0.1> and
2346 the server's hostname will appear to be C<localhost> regardless of the
2347 virtual host that the user connected through.
2348
2349 Catalyst will automatically detect this situation when you are running
2350 the frontend and backend servers on the same machine. The following
2351 changes are made to the request.
2352
2353     $c->req->address is set to the user's real IP address, as read from
2354     the HTTP X-Forwarded-For header.
2355
2356     The host value for $c->req->base and $c->req->uri is set to the real
2357     host, as read from the HTTP X-Forwarded-Host header.
2358
2359 Obviously, your web server must support these headers for this to work.
2360
2361 In a more complex server farm environment where you may have your
2362 frontend proxy server(s) on different machines, you will need to set a
2363 configuration option to tell Catalyst to read the proxied data from the
2364 headers.
2365
2366     MyApp->config->{using_frontend_proxy} = 1;
2367
2368 If you do not wish to use the proxy support at all, you may set:
2369
2370     MyApp->config->{ignore_frontend_proxy} = 1;
2371
2372 =head1 THREAD SAFETY
2373
2374 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2375 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2376 believe the Catalyst core to be thread-safe.
2377
2378 If you plan to operate in a threaded environment, remember that all other
2379 modules you are using must also be thread-safe. Some modules, most notably
2380 L<DBD::SQLite>, are not thread-safe.
2381
2382 =head1 SUPPORT
2383
2384 IRC:
2385
2386     Join #catalyst on irc.perl.org.
2387
2388 Mailing Lists:
2389
2390     http://lists.rawmode.org/mailman/listinfo/catalyst
2391     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2392
2393 Web:
2394
2395     http://catalyst.perl.org
2396
2397 Wiki:
2398
2399     http://dev.catalyst.perl.org
2400
2401 =head1 SEE ALSO
2402
2403 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2404
2405 =head2 L<Catalyst::Manual> - The Catalyst Manual
2406
2407 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2408
2409 =head2 L<Catalyst::Engine> - Core engine
2410
2411 =head2 L<Catalyst::Log> - Log class.
2412
2413 =head2 L<Catalyst::Request> - Request object
2414
2415 =head2 L<Catalyst::Response> - Response object
2416
2417 =head2 L<Catalyst::Test> - The test suite.
2418
2419 =head1 PROJECT FOUNDER
2420
2421 sri: Sebastian Riedel <sri@cpan.org>
2422
2423 =head1 CONTRIBUTORS
2424
2425 abw: Andy Wardley
2426
2427 acme: Leon Brocard <leon@astray.com>
2428
2429 Andrew Bramble
2430
2431 Andrew Ford
2432
2433 Andrew Ruthven
2434
2435 andyg: Andy Grundman <andy@hybridized.org>
2436
2437 audreyt: Audrey Tang
2438
2439 bricas: Brian Cassidy <bricas@cpan.org>
2440
2441 chansen: Christian Hansen
2442
2443 chicks: Christopher Hicks
2444
2445 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2446
2447 Drew Taylor
2448
2449 esskar: Sascha Kiefer
2450
2451 fireartist: Carl Franks <cfranks@cpan.org>
2452
2453 gabb: Danijel Milicevic
2454
2455 Gary Ashton Jones
2456
2457 Geoff Richards
2458
2459 jcamacho: Juan Camacho
2460
2461 Jody Belka
2462
2463 Johan Lindstrom
2464
2465 jon: Jon Schutz <jjschutz@cpan.org>
2466
2467 marcus: Marcus Ramberg <mramberg@cpan.org>
2468
2469 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2470
2471 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2472
2473 mugwump: Sam Vilain
2474
2475 naughton: David Naughton
2476
2477 ningu: David Kamholz <dkamholz@cpan.org>
2478
2479 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2480
2481 numa: Dan Sully <daniel@cpan.org>
2482
2483 obra: Jesse Vincent
2484
2485 omega: Andreas Marienborg
2486
2487 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2488
2489 sky: Arthur Bergman
2490
2491 the_jester: Jesse Sheidlower
2492
2493 Ulf Edvinsson
2494
2495 willert: Sebastian Willert <willert@cpan.org>
2496
2497 =head1 LICENSE
2498
2499 This library is free software, you can redistribute it and/or modify it under
2500 the same terms as Perl itself.
2501
2502 =cut
2503
2504 1;