lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Plack::Middleware::Conditional;
  39 use Plack::Middleware::ReverseProxy;
  40 use Plack::Middleware::IIS6ScriptNameFix;
  41 use Plack::Middleware::IIS7KeepAliveFix;
  42 use Plack::Middleware::LighttpdScriptNameFix;
  43
  44 BEGIN { require 5.008003; }
  45
  46 has stack => (is => 'ro', default => sub { [] });
  47 has stash => (is => 'rw', default => sub { {} });
  48 has state => (is => 'rw', default => 0);
  49 has stats => (is => 'rw');
  50 has action => (is => 'rw');
  51 has counter => (is => 'rw', default => sub { {} });
  52 has request => (
  53     is => 'rw',
  54     default => sub {
  55         my $self = shift;
  56         $self->request_class->new($self->_build_request_constructor_args);
  57     },
  58     lazy => 1,
  59 );
  60 sub _build_request_constructor_args {
  61     my $self = shift;
  62     my %p = ( _log => $self->log );
  63     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  64     \%p;
  65 }
  66
  67 has response => (
  68     is => 'rw',
  69     default => sub {
  70         my $self = shift;
  71         $self->response_class->new($self->_build_response_constructor_args);
  72     },
  73     lazy => 1,
  74 );
  75 sub _build_response_constructor_args {
  76     my $self = shift;
  77     { _log => $self->log };
  78 }
  79
  80 has namespace => (is => 'rw');
  81
  82 sub depth { scalar @{ shift->stack || [] }; }
  83 sub comp { shift->component(@_) }
  84
  85 sub req {
  86     my $self = shift; return $self->request(@_);
  87 }
  88 sub res {
  89     my $self = shift; return $self->response(@_);
  90 }
  91
  92 # For backwards compatibility
  93 sub finalize_output { shift->finalize_body(@_) };
  94
  95 # For statistics
  96 our $COUNT     = 1;
  97 our $START     = time;
  98 our $RECURSION = 1000;
  99 our $DETACH    = Catalyst::Exception::Detach->new;
 100 our $GO        = Catalyst::Exception::Go->new;
 101
 102 #I imagine that very few of these really need to be class variables. if any.
 103 #maybe we should just make them attributes with a default?
 104 __PACKAGE__->mk_classdata($_)
 105   for qw/components arguments dispatcher engine log dispatcher_class
 106   engine_loader context_class request_class response_class stats_class
 107   setup_finished _psgi_app loading_psgi_file run_options/;
 108
 109 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 110 __PACKAGE__->request_class('Catalyst::Request');
 111 __PACKAGE__->response_class('Catalyst::Response');
 112 __PACKAGE__->stats_class('Catalyst::Stats');
 113
 114 # Remember to update this in Catalyst::Runtime as well!
 115
 116 our $VERSION = '5.90042';
 117
 118 sub import {
 119     my ( $class, @arguments ) = @_;
 120
 121     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 122     # callers @ISA.
 123     return unless $class eq 'Catalyst';
 124
 125     my $caller = caller();
 126     return if $caller eq 'main';
 127
 128     my $meta = Moose::Meta::Class->initialize($caller);
 129     unless ( $caller->isa('Catalyst') ) {
 130         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 131         $meta->superclasses(@superclasses);
 132     }
 133     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 134     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 135
 136     unless( $meta->has_method('meta') ){
 137         if ($Moose::VERSION >= 1.15) {
 138             $meta->_add_meta_method('meta');
 139         }
 140         else {
 141             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 142         }
 143     }
 144
 145     $caller->arguments( [@arguments] );
 146     $caller->setup_home;
 147 }
 148
 149 sub _application { $_[0] }
 150
 151 =encoding UTF-8
 152
 153 =head1 NAME
 154
 155 Catalyst - The Elegant MVC Web Application Framework
 156
 157 =head1 SYNOPSIS
 158
 159 See the L<Catalyst::Manual> distribution for comprehensive
 160 documentation and tutorials.
 161
 162     # Install Catalyst::Devel for helpers and other development tools
 163     # use the helper to create a new application
 164     catalyst.pl MyApp
 165
 166     # add models, views, controllers
 167     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 168     script/myapp_create.pl view MyTemplate TT
 169     script/myapp_create.pl controller Search
 170
 171     # built in testserver -- use -r to restart automatically on changes
 172     # --help to see all available options
 173     script/myapp_server.pl
 174
 175     # command line testing interface
 176     script/myapp_test.pl /yada
 177
 178     ### in lib/MyApp.pm
 179     use Catalyst qw/-Debug/; # include plugins here as well
 180
 181     ### In lib/MyApp/Controller/Root.pm (autocreated)
 182     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 183         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 184         $c->stash->{template} = 'foo.tt'; # set the template
 185         # lookup something from db -- stash vars are passed to TT
 186         $c->stash->{data} =
 187           $c->model('Database::Foo')->search( { country => $args[0] } );
 188         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 189             $c->forward( 'bar' ); # process another action
 190             # do something else after forward returns
 191         }
 192     }
 193
 194     # The foo.tt TT template can use the stash data from the database
 195     [% WHILE (item = data.next) %]
 196         [% item.foo %]
 197     [% END %]
 198
 199     # called for /bar/of/soap, /bar/of/soap/10, etc.
 200     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 201
 202     # called after all actions are finished
 203     sub end : Action {
 204         my ( $self, $c ) = @_;
 205         if ( scalar @{ $c->error } ) { ... } # handle errors
 206         return if $c->res->body; # already have a response
 207         $c->forward( 'MyApp::View::TT' ); # render template
 208     }
 209
 210 See L<Catalyst::Manual::Intro> for additional information.
 211
 212 =head1 DESCRIPTION
 213
 214 Catalyst is a modern framework for making web applications without the
 215 pain usually associated with this process. This document is a reference
 216 to the main Catalyst application. If you are a new user, we suggest you
 217 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 218
 219 See L<Catalyst::Manual> for more documentation.
 220
 221 Catalyst plugins can be loaded by naming them as arguments to the "use
 222 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 223 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 224 C<My::Module>.
 225
 226     use Catalyst qw/My::Module/;
 227
 228 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 229 fully qualify the name by using a unary plus:
 230
 231     use Catalyst qw/
 232         My::Module
 233         +Fully::Qualified::Plugin::Name
 234     /;
 235
 236 Special flags like C<-Debug> can also be specified as
 237 arguments when Catalyst is loaded:
 238
 239     use Catalyst qw/-Debug My::Module/;
 240
 241 The position of plugins and flags in the chain is important, because
 242 they are loaded in the order in which they appear.
 243
 244 The following flags are supported:
 245
 246 =head2 -Debug
 247
 248 Enables debug output. You can also force this setting from the system
 249 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 250 settings override the application, with <MYAPP>_DEBUG having the highest
 251 priority.
 252
 253 This sets the log level to 'debug' and enables full debug output on the
 254 error screen. If you only want the latter, see L<< $c->debug >>.
 255
 256 =head2 -Home
 257
 258 Forces Catalyst to use a specific home directory, e.g.:
 259
 260     use Catalyst qw[-Home=/usr/mst];
 261
 262 This can also be done in the shell environment by setting either the
 263 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 264 is replaced with the uppercased name of your application, any "::" in
 265 the name will be replaced with underscores, e.g. MyApp::Web should use
 266 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 267
 268 If none of these are set, Catalyst will attempt to automatically detect the
 269 home directory. If you are working in a development environment, Catalyst
 270 will try and find the directory containing either Makefile.PL, Build.PL,
 271 dist.ini, or cpanfile. If the application has been installed into the system
 272 (i.e. you have done C<make install>), then Catalyst will use the path to your
 273 application module, without the .pm extension (e.g., /foo/MyApp if your
 274 application was installed at /foo/MyApp.pm)
 275
 276 =head2 -Log
 277
 278     use Catalyst '-Log=warn,fatal,error';
 279
 280 Specifies a comma-delimited list of log levels.
 281
 282 =head2 -Stats
 283
 284 Enables statistics collection and reporting.
 285
 286    use Catalyst qw/-Stats=1/;
 287
 288 You can also force this setting from the system environment with CATALYST_STATS
 289 or <MYAPP>_STATS. The environment settings override the application, with
 290 <MYAPP>_STATS having the highest priority.
 291
 292 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 293
 294 =head1 METHODS
 295
 296 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 297
 298 =head2 $c->action
 299
 300 Returns a L<Catalyst::Action> object for the current action, which
 301 stringifies to the action name. See L<Catalyst::Action>.
 302
 303 =head2 $c->namespace
 304
 305 Returns the namespace of the current action, i.e., the URI prefix
 306 corresponding to the controller of the current action. For example:
 307
 308     # in Controller::Foo::Bar
 309     $c->namespace; # returns 'foo/bar';
 310
 311 =head2 $c->request
 312
 313 =head2 $c->req
 314
 315 Returns the current L<Catalyst::Request> object, giving access to
 316 information about the current client request (including parameters,
 317 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 318
 319 =head2 REQUEST FLOW HANDLING
 320
 321 =head2 $c->forward( $action [, \@arguments ] )
 322
 323 =head2 $c->forward( $class, $method, [, \@arguments ] )
 324
 325 Forwards processing to another action, by its private name. If you give a
 326 class name but no method, C<process()> is called. You may also optionally
 327 pass arguments in an arrayref. The action will receive the arguments in
 328 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 329 C<< $c->req->args >> will be restored to the previous values.
 330
 331 Any data C<return>ed from the action forwarded to, will be returned by the
 332 call to forward.
 333
 334     my $foodata = $c->forward('/foo');
 335     $c->forward('index');
 336     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 337     $c->forward('View::TT');
 338
 339 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 340 an C<< eval { } >> around the call (actually
 341 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 342 exceptions thrown by the called action non-fatal and pushing them onto
 343 $c->error instead. If you want C<die> to propagate you need to do something
 344 like:
 345
 346     $c->forward('foo');
 347     die join "\n", @{ $c->error } if @{ $c->error };
 348
 349 Or make sure to always return true values from your actions and write
 350 your code like this:
 351
 352     $c->forward('foo') || return;
 353
 354 Another note is that C<< $c->forward >> always returns a scalar because it
 355 actually returns $c->state which operates in a scalar context.
 356 Thus, something like:
 357
 358     return @array;
 359
 360 in an action that is forwarded to is going to return a scalar,
 361 i.e. how many items are in that array, which is probably not what you want.
 362 If you need to return an array then return a reference to it,
 363 or stash it like so:
 364
 365     $c->stash->{array} = \@array;
 366
 367 and access it from the stash.
 368
 369 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 370
 371 =cut
 372
 373 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 374
 375 =head2 $c->detach( $action [, \@arguments ] )
 376
 377 =head2 $c->detach( $class, $method, [, \@arguments ] )
 378
 379 =head2 $c->detach()
 380
 381 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 382 doesn't return to the previous action when processing is finished.
 383
 384 When called with no arguments it escapes the processing chain entirely.
 385
 386 =cut
 387
 388 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 389
 390 =head2 $c->visit( $action [, \@arguments ] )
 391
 392 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 393
 394 =head2 $c->visit( $class, $method, [, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the called action.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@arguments ] )
 425
 426 =head2 $c->go( $action [, \@captures, \@arguments ] )
 427
 428 =head2 $c->go( $class, $method, [, \@arguments ] )
 429
 430 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 431
 432 The relationship between C<go> and
 433 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 434 the relationship between
 435 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 436 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 437 C<< $c->go >> will perform a full dispatch on the specified action or method,
 438 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 439 C<go> escapes the processing of the current request chain on completion, and
 440 does not return to its caller.
 441
 442 @arguments are arguments to the final destination of $action. @captures are
 443 arguments to the intermediate steps, if any, on the way to the final sub of
 444 $action.
 445
 446 =cut
 447
 448 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 449
 450 =head2 $c->response
 451
 452 =head2 $c->res
 453
 454 Returns the current L<Catalyst::Response> object, see there for details.
 455
 456 =head2 $c->stash
 457
 458 Returns a hashref to the stash, which may be used to store data and pass
 459 it between components during a request. You can also set hash keys by
 460 passing arguments. The stash is automatically sent to the view. The
 461 stash is cleared at the end of a request; it cannot be used for
 462 persistent storage (for this you must use a session; see
 463 L<Catalyst::Plugin::Session> for a complete system integrated with
 464 Catalyst).
 465
 466     $c->stash->{foo} = $bar;
 467     $c->stash( { moose => 'majestic', qux => 0 } );
 468     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 469
 470     # stash is automatically passed to the view for use in a template
 471     $c->forward( 'MyApp::View::TT' );
 472
 473 =cut
 474
 475 around stash => sub {
 476     my $orig = shift;
 477     my $c = shift;
 478     my $stash = $orig->($c);
 479     if (@_) {
 480         my $new_stash = @_ > 1 ? {@_} : $_[0];
 481         croak('stash takes a hash or hashref') unless ref $new_stash;
 482         foreach my $key ( keys %$new_stash ) {
 483           $stash->{$key} = $new_stash->{$key};
 484         }
 485     }
 486
 487     return $stash;
 488 };
 489
 490
 491 =head2 $c->error
 492
 493 =head2 $c->error($error, ...)
 494
 495 =head2 $c->error($arrayref)
 496
 497 Returns an arrayref containing error messages.  If Catalyst encounters an
 498 error while processing a request, it stores the error in $c->error.  This
 499 method should only be used to store fatal error messages.
 500
 501     my @error = @{ $c->error };
 502
 503 Add a new error.
 504
 505     $c->error('Something bad happened');
 506
 507 =cut
 508
 509 sub error {
 510     my $c = shift;
 511     if ( $_[0] ) {
 512         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 513         croak @$error unless ref $c;
 514         push @{ $c->{error} }, @$error;
 515     }
 516     elsif ( defined $_[0] ) { $c->{error} = undef }
 517     return $c->{error} || [];
 518 }
 519
 520
 521 =head2 $c->state
 522
 523 Contains the return value of the last executed action.
 524 Note that << $c->state >> operates in a scalar context which means that all
 525 values it returns are scalar.
 526
 527 =head2 $c->clear_errors
 528
 529 Clear errors.  You probably don't want to clear the errors unless you are
 530 implementing a custom error screen.
 531
 532 This is equivalent to running
 533
 534     $c->error(0);
 535
 536 =cut
 537
 538 sub clear_errors {
 539     my $c = shift;
 540     $c->error(0);
 541 }
 542
 543 sub _comp_search_prefixes {
 544     my $c = shift;
 545     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 546 }
 547
 548 # search components given a name and some prefixes
 549 sub _comp_names_search_prefixes {
 550     my ( $c, $name, @prefixes ) = @_;
 551     my $appclass = ref $c || $c;
 552     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 553     $filter = qr/$filter/; # Compile regex now rather than once per loop
 554
 555     # map the original component name to the sub part that we will search against
 556     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 557         grep { /$filter/ } keys %{ $c->components };
 558
 559     # undef for a name will return all
 560     return keys %eligible if !defined $name;
 561
 562     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 563     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 564
 565     return @result if @result;
 566
 567     # if we were given a regexp to search against, we're done.
 568     return if $name->$_isa('Regexp');
 569
 570     # skip regexp fallback if configured
 571     return
 572         if $appclass->config->{disable_component_resolution_regex_fallback};
 573
 574     # regexp fallback
 575     $query  = qr/$name/i;
 576     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 577
 578     # no results? try against full names
 579     if( !@result ) {
 580         @result = grep { m{$query} } keys %eligible;
 581     }
 582
 583     # don't warn if we didn't find any results, it just might not exist
 584     if( @result ) {
 585         # Disgusting hack to work out correct method name
 586         my $warn_for = lc $prefixes[0];
 587         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 588            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 589            "component resolution is unreliable and unsafe.";
 590         my $short = $result[0];
 591         # remove the component namespace prefix
 592         $short =~ s/.*?(Model|Controller|View):://;
 593         my $shortmess = Carp::shortmess('');
 594         if ($shortmess =~ m#Catalyst/Plugin#) {
 595            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 596               "plugin's config";
 597         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 598            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 599               "component's config";
 600         } else {
 601            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 602               "but if you really wanted to search, pass in a regexp as the argument " .
 603               "like so: \$c->${warn_for}(qr/${name}/)";
 604         }
 605         $c->log->warn( "${msg}$shortmess" );
 606     }
 607
 608     return @result;
 609 }
 610
 611 # Find possible names for a prefix
 612 sub _comp_names {
 613     my ( $c, @prefixes ) = @_;
 614     my $appclass = ref $c || $c;
 615
 616     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 617
 618     my @names = map { s{$filter}{}; $_; }
 619         $c->_comp_names_search_prefixes( undef, @prefixes );
 620
 621     return @names;
 622 }
 623
 624 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 625 sub _filter_component {
 626     my ( $c, $comp, @args ) = @_;
 627
 628     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 629         return $comp->ACCEPT_CONTEXT( $c, @args );
 630     }
 631
 632     return $comp;
 633 }
 634
 635 =head2 COMPONENT ACCESSORS
 636
 637 =head2 $c->controller($name)
 638
 639 Gets a L<Catalyst::Controller> instance by name.
 640
 641     $c->controller('Foo')->do_stuff;
 642
 643 If the name is omitted, will return the controller for the dispatched
 644 action.
 645
 646 If you want to search for controllers, pass in a regexp as the argument.
 647
 648     # find all controllers that start with Foo
 649     my @foo_controllers = $c->controller(qr{^Foo});
 650
 651
 652 =cut
 653
 654 sub controller {
 655     my ( $c, $name, @args ) = @_;
 656
 657     my $appclass = ref($c) || $c;
 658     if( $name ) {
 659         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 660             my $comps = $c->components;
 661             my $check = $appclass."::Controller::".$name;
 662             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 663         }
 664         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 665         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 666         return $c->_filter_component( $result[ 0 ], @args );
 667     }
 668
 669     return $c->component( $c->action->class );
 670 }
 671
 672 =head2 $c->model($name)
 673
 674 Gets a L<Catalyst::Model> instance by name.
 675
 676     $c->model('Foo')->do_stuff;
 677
 678 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 679
 680 If the name is omitted, it will look for
 681  - a model object in $c->stash->{current_model_instance}, then
 682  - a model name in $c->stash->{current_model}, then
 683  - a config setting 'default_model', or
 684  - check if there is only one model, and return it if that's the case.
 685
 686 If you want to search for models, pass in a regexp as the argument.
 687
 688     # find all models that start with Foo
 689     my @foo_models = $c->model(qr{^Foo});
 690
 691 =cut
 692
 693 sub model {
 694     my ( $c, $name, @args ) = @_;
 695     my $appclass = ref($c) || $c;
 696     if( $name ) {
 697         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 698             my $comps = $c->components;
 699             my $check = $appclass."::Model::".$name;
 700             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 701         }
 702         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 703         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 704         return $c->_filter_component( $result[ 0 ], @args );
 705     }
 706
 707     if (ref $c) {
 708         return $c->stash->{current_model_instance}
 709           if $c->stash->{current_model_instance};
 710         return $c->model( $c->stash->{current_model} )
 711           if $c->stash->{current_model};
 712     }
 713     return $c->model( $appclass->config->{default_model} )
 714       if $appclass->config->{default_model};
 715
 716     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 717
 718     if( $rest ) {
 719         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 720         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 721         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 722         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 723         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 724     }
 725
 726     return $c->_filter_component( $comp );
 727 }
 728
 729
 730 =head2 $c->view($name)
 731
 732 Gets a L<Catalyst::View> instance by name.
 733
 734     $c->view('Foo')->do_stuff;
 735
 736 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 737
 738 If the name is omitted, it will look for
 739  - a view object in $c->stash->{current_view_instance}, then
 740  - a view name in $c->stash->{current_view}, then
 741  - a config setting 'default_view', or
 742  - check if there is only one view, and return it if that's the case.
 743
 744 If you want to search for views, pass in a regexp as the argument.
 745
 746     # find all views that start with Foo
 747     my @foo_views = $c->view(qr{^Foo});
 748
 749 =cut
 750
 751 sub view {
 752     my ( $c, $name, @args ) = @_;
 753
 754     my $appclass = ref($c) || $c;
 755     if( $name ) {
 756         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 757             my $comps = $c->components;
 758             my $check = $appclass."::View::".$name;
 759             if( exists $comps->{$check} ) {
 760                 return $c->_filter_component( $comps->{$check}, @args );
 761             }
 762             else {
 763                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 764             }
 765         }
 766         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 767         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 768         return $c->_filter_component( $result[ 0 ], @args );
 769     }
 770
 771     if (ref $c) {
 772         return $c->stash->{current_view_instance}
 773           if $c->stash->{current_view_instance};
 774         return $c->view( $c->stash->{current_view} )
 775           if $c->stash->{current_view};
 776     }
 777     return $c->view( $appclass->config->{default_view} )
 778       if $appclass->config->{default_view};
 779
 780     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 781
 782     if( $rest ) {
 783         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 784         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 785         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 786         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 787         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 788     }
 789
 790     return $c->_filter_component( $comp );
 791 }
 792
 793 =head2 $c->controllers
 794
 795 Returns the available names which can be passed to $c->controller
 796
 797 =cut
 798
 799 sub controllers {
 800     my ( $c ) = @_;
 801     return $c->_comp_names(qw/Controller C/);
 802 }
 803
 804 =head2 $c->models
 805
 806 Returns the available names which can be passed to $c->model
 807
 808 =cut
 809
 810 sub models {
 811     my ( $c ) = @_;
 812     return $c->_comp_names(qw/Model M/);
 813 }
 814
 815
 816 =head2 $c->views
 817
 818 Returns the available names which can be passed to $c->view
 819
 820 =cut
 821
 822 sub views {
 823     my ( $c ) = @_;
 824     return $c->_comp_names(qw/View V/);
 825 }
 826
 827 =head2 $c->comp($name)
 828
 829 =head2 $c->component($name)
 830
 831 Gets a component object by name. This method is not recommended,
 832 unless you want to get a specific component by full
 833 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 834 should be used instead.
 835
 836 If C<$name> is a regexp, a list of components matched against the full
 837 component name will be returned.
 838
 839 If Catalyst can't find a component by name, it will fallback to regex
 840 matching by default. To disable this behaviour set
 841 disable_component_resolution_regex_fallback to a true value.
 842
 843     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 844
 845 =cut
 846
 847 sub component {
 848     my ( $c, $name, @args ) = @_;
 849
 850     if( $name ) {
 851         my $comps = $c->components;
 852
 853         if( !ref $name ) {
 854             # is it the exact name?
 855             return $c->_filter_component( $comps->{ $name }, @args )
 856                        if exists $comps->{ $name };
 857
 858             # perhaps we just omitted "MyApp"?
 859             my $composed = ( ref $c || $c ) . "::${name}";
 860             return $c->_filter_component( $comps->{ $composed }, @args )
 861                        if exists $comps->{ $composed };
 862
 863             # search all of the models, views and controllers
 864             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 865             return $c->_filter_component( $comp, @args ) if $comp;
 866         }
 867
 868         return
 869             if $c->config->{disable_component_resolution_regex_fallback};
 870
 871         # This is here so $c->comp( '::M::' ) works
 872         my $query = ref $name ? $name : qr{$name}i;
 873
 874         my @result = grep { m{$query} } keys %{ $c->components };
 875         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 876
 877         if( $result[ 0 ] ) {
 878             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 879             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 880             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 881             return $c->_filter_component( $result[ 0 ], @args );
 882         }
 883
 884         # I would expect to return an empty list here, but that breaks back-compat
 885     }
 886
 887     # fallback
 888     return sort keys %{ $c->components };
 889 }
 890
 891 =head2 CLASS DATA AND HELPER CLASSES
 892
 893 =head2 $c->config
 894
 895 Returns or takes a hashref containing the application's configuration.
 896
 897     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 898
 899 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 900 like C<myapp.conf> in your applications home directory. See
 901 L<Catalyst::Plugin::ConfigLoader>.
 902
 903 =head3 Cascading configuration
 904
 905 The config method is present on all Catalyst components, and configuration
 906 will be merged when an application is started. Configuration loaded with
 907 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 908 followed by configuration in your top level C<MyApp> class. These two
 909 configurations are merged, and then configuration data whose hash key matches a
 910 component name is merged with configuration for that component.
 911
 912 The configuration for a component is then passed to the C<new> method when a
 913 component is constructed.
 914
 915 For example:
 916
 917     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 918     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 919
 920 will mean that C<MyApp::Model::Foo> receives the following data when
 921 constructed:
 922
 923     MyApp::Model::Foo->new({
 924         bar => 'baz',
 925         quux => 'frob',
 926         overrides => 'me',
 927     });
 928
 929 It's common practice to use a Moose attribute
 930 on the receiving component to access the config value.
 931
 932     package MyApp::Model::Foo;
 933
 934     use Moose;
 935
 936     # this attr will receive 'baz' at construction time
 937     has 'bar' => (
 938         is  => 'rw',
 939         isa => 'Str',
 940     );
 941
 942 You can then get the value 'baz' by calling $c->model('Foo')->bar
 943 (or $self->bar inside code in the model).
 944
 945 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 946 as a way of reading config within your code, as this B<will not> give you the
 947 correctly merged config back. You B<MUST> take the config values supplied to
 948 the constructor and use those instead.
 949
 950 =cut
 951
 952 around config => sub {
 953     my $orig = shift;
 954     my $c = shift;
 955
 956     croak('Setting config after setup has been run is not allowed.')
 957         if ( @_ and $c->setup_finished );
 958
 959     $c->$orig(@_);
 960 };
 961
 962 =head2 $c->log
 963
 964 Returns the logging object instance. Unless it is already set, Catalyst
 965 sets this up with a L<Catalyst::Log> object. To use your own log class,
 966 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 967 C<< __PACKAGE__->setup >>.
 968
 969  __PACKAGE__->log( MyLogger->new );
 970  __PACKAGE__->setup;
 971
 972 And later:
 973
 974     $c->log->info( 'Now logging with my own logger!' );
 975
 976 Your log class should implement the methods described in
 977 L<Catalyst::Log>.
 978
 979
 980 =head2 $c->debug
 981
 982 Returns 1 if debug mode is enabled, 0 otherwise.
 983
 984 You can enable debug mode in several ways:
 985
 986 =over
 987
 988 =item By calling myapp_server.pl with the -d flag
 989
 990 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 991
 992 =item The -Debug option in your MyApp.pm
 993
 994 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 995
 996 =back
 997
 998 The first three also set the log level to 'debug'.
 999
1000 Calling C<< $c->debug(1) >> has no effect.
1001
1002 =cut
1003
1004 sub debug { 0 }
1005
1006 =head2 $c->dispatcher
1007
1008 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1009
1010 =head2 $c->engine
1011
1012 Returns the engine instance. See L<Catalyst::Engine>.
1013
1014
1015 =head2 UTILITY METHODS
1016
1017 =head2 $c->path_to(@path)
1018
1019 Merges C<@path> with C<< $c->config->{home} >> and returns a
1020 L<Path::Class::Dir> object. Note you can usually use this object as
1021 a filename, but sometimes you will have to explicitly stringify it
1022 yourself by calling the C<< ->stringify >> method.
1023
1024 For example:
1025
1026     $c->path_to( 'db', 'sqlite.db' );
1027
1028 =cut
1029
1030 sub path_to {
1031     my ( $c, @path ) = @_;
1032     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1033     if ( -d $path ) { return $path }
1034     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1035 }
1036
1037 sub plugin {
1038     my ( $class, $name, $plugin, @args ) = @_;
1039
1040     # See block comment in t/unit_core_plugin.t
1041     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1042
1043     $class->_register_plugin( $plugin, 1 );
1044
1045     eval { $plugin->import };
1046     $class->mk_classdata($name);
1047     my $obj;
1048     eval { $obj = $plugin->new(@args) };
1049
1050     if ($@) {
1051         Catalyst::Exception->throw( message =>
1052               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1053     }
1054
1055     $class->$name($obj);
1056     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1057       if $class->debug;
1058 }
1059
1060 =head2 MyApp->setup
1061
1062 Initializes the dispatcher and engine, loads any plugins, and loads the
1063 model, view, and controller components. You may also specify an array
1064 of plugins to load here, if you choose to not load them in the C<use
1065 Catalyst> line.
1066
1067     MyApp->setup;
1068     MyApp->setup( qw/-Debug/ );
1069
1070 B<Note:> You B<should not> wrap this method with method modifiers
1071 or bad things will happen - wrap the C<setup_finalize> method instead.
1072
1073 =cut
1074
1075 sub setup {
1076     my ( $class, @arguments ) = @_;
1077     croak('Running setup more than once')
1078         if ( $class->setup_finished );
1079
1080     unless ( $class->isa('Catalyst') ) {
1081
1082         Catalyst::Exception->throw(
1083             message => qq/'$class' does not inherit from Catalyst/ );
1084     }
1085
1086     if ( $class->arguments ) {
1087         @arguments = ( @arguments, @{ $class->arguments } );
1088     }
1089
1090     # Process options
1091     my $flags = {};
1092
1093     foreach (@arguments) {
1094
1095         if (/^-Debug$/) {
1096             $flags->{log} =
1097               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1098         }
1099         elsif (/^-(\w+)=?(.*)$/) {
1100             $flags->{ lc $1 } = $2;
1101         }
1102         else {
1103             push @{ $flags->{plugins} }, $_;
1104         }
1105     }
1106
1107     $class->setup_home( delete $flags->{home} );
1108
1109     $class->setup_log( delete $flags->{log} );
1110     $class->setup_plugins( delete $flags->{plugins} );
1111     $class->setup_dispatcher( delete $flags->{dispatcher} );
1112     if (my $engine = delete $flags->{engine}) {
1113         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1114     }
1115     $class->setup_engine();
1116     $class->setup_stats( delete $flags->{stats} );
1117
1118     for my $flag ( sort keys %{$flags} ) {
1119
1120         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1121             &$code( $class, delete $flags->{$flag} );
1122         }
1123         else {
1124             $class->log->warn(qq/Unknown flag "$flag"/);
1125         }
1126     }
1127
1128     eval { require Catalyst::Devel; };
1129     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1130         $class->log->warn(<<"EOF");
1131 You are running an old script!
1132
1133   Please update by running (this will overwrite existing files):
1134     catalyst.pl -force -scripts $class
1135
1136   or (this will not overwrite existing files):
1137     catalyst.pl -scripts $class
1138
1139 EOF
1140     }
1141
1142     if ( $class->debug ) {
1143         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1144
1145         if (@plugins) {
1146             my $column_width = Catalyst::Utils::term_width() - 6;
1147             my $t = Text::SimpleTable->new($column_width);
1148             $t->row($_) for @plugins;
1149             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1150         }
1151
1152         my $dispatcher = $class->dispatcher;
1153         my $engine     = $class->engine;
1154         my $home       = $class->config->{home};
1155
1156         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1157         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1158
1159         $home
1160           ? ( -d $home )
1161           ? $class->log->debug(qq/Found home "$home"/)
1162           : $class->log->debug(qq/Home "$home" doesn't exist/)
1163           : $class->log->debug(q/Couldn't find home/);
1164     }
1165
1166     # Call plugins setup, this is stupid and evil.
1167     # Also screws C3 badly on 5.10, hack to avoid.
1168     {
1169         no warnings qw/redefine/;
1170         local *setup = sub { };
1171         $class->setup unless $Catalyst::__AM_RESTARTING;
1172     }
1173
1174     # Initialize our data structure
1175     $class->components( {} );
1176
1177     $class->setup_components;
1178
1179     if ( $class->debug ) {
1180         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1181         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1182         for my $comp ( sort keys %{ $class->components } ) {
1183             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1184             $t->row( $comp, $type );
1185         }
1186         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1187           if ( keys %{ $class->components } );
1188     }
1189
1190     # Add our self to components, since we are also a component
1191     if( $class->isa('Catalyst::Controller') ){
1192       $class->components->{$class} = $class;
1193     }
1194
1195     $class->setup_actions;
1196
1197     if ( $class->debug ) {
1198         my $name = $class->config->{name} || 'Application';
1199         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1200     }
1201
1202     if ($class->config->{case_sensitive}) {
1203         $class->log->warn($class . "->config->{case_sensitive} is set.");
1204         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1205     }
1206
1207     $class->setup_finalize;
1208     # Should be the last thing we do so that user things hooking
1209     # setup_finalize can log..
1210     $class->log->_flush() if $class->log->can('_flush');
1211     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1212 }
1213
1214 =head2 $app->setup_finalize
1215
1216 A hook to attach modifiers to. This method does not do anything except set the
1217 C<setup_finished> accessor.
1218
1219 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1220
1221 Example:
1222
1223     after setup_finalize => sub {
1224         my $app = shift;
1225
1226         ## do stuff here..
1227     };
1228
1229 =cut
1230
1231 sub setup_finalize {
1232     my ($class) = @_;
1233     $class->setup_finished(1);
1234 }
1235
1236 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1237
1238 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1239
1240 Constructs an absolute L<URI> object based on the application root, the
1241 provided path, and the additional arguments and query parameters provided.
1242 When used as a string, provides a textual URI.  If you need more flexibility
1243 than this (i.e. the option to provide relative URIs etc.) see
1244 L<Catalyst::Plugin::SmartURI>.
1245
1246 If no arguments are provided, the URI for the current action is returned.
1247 To return the current action and also provide @args, use
1248 C<< $c->uri_for( $c->action, @args ) >>.
1249
1250 If the first argument is a string, it is taken as a public URI path relative
1251 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1252 relative to the application root (if it does). It is then merged with
1253 C<< $c->request->base >>; any C<@args> are appended as additional path
1254 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1255
1256 If the first argument is a L<Catalyst::Action> it represents an action which
1257 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1258 optional C<\@captures> argument (an arrayref) allows passing the captured
1259 variables that are needed to fill in the paths of Chained and Regex actions;
1260 once the path is resolved, C<uri_for> continues as though a path was
1261 provided, appending any arguments or parameters and creating an absolute
1262 URI.
1263
1264 The captures for the current request can be found in
1265 C<< $c->request->captures >>, and actions can be resolved using
1266 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1267 path, use C<< $c->uri_for_action >> instead.
1268
1269   # Equivalent to $c->req->uri
1270   $c->uri_for($c->action, $c->req->captures,
1271       @{ $c->req->args }, $c->req->params);
1272
1273   # For the Foo action in the Bar controller
1274   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1275
1276   # Path to a static resource
1277   $c->uri_for('/static/images/logo.png');
1278
1279 =cut
1280
1281 sub uri_for {
1282     my ( $c, $path, @args ) = @_;
1283
1284     if ( $path->$_isa('Catalyst::Controller') ) {
1285         $path = $path->path_prefix;
1286         $path =~ s{/+\z}{};
1287         $path .= '/';
1288     }
1289
1290     undef($path) if (defined $path && $path eq '');
1291
1292     my $params =
1293       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1294
1295     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1296     foreach my $arg (@args) {
1297         utf8::encode($arg) if utf8::is_utf8($arg);
1298         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1299     }
1300
1301     if ( $path->$_isa('Catalyst::Action') ) { # action object
1302         s|/|%2F|g for @args;
1303         my $captures = [ map { s|/|%2F|g; $_; }
1304                         ( scalar @args && ref $args[0] eq 'ARRAY'
1305                          ? @{ shift(@args) }
1306                          : ()) ];
1307
1308         foreach my $capture (@$captures) {
1309             utf8::encode($capture) if utf8::is_utf8($capture);
1310             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1311         }
1312
1313         my $action = $path;
1314         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1315         if( !@args && $action->number_of_args ) {
1316             my $expanded_action = $c->dispatcher->expand_action( $action );
1317
1318             my $num_captures = $expanded_action->number_of_captures;
1319             unshift @args, splice @$captures, $num_captures;
1320         }
1321
1322        $path = $c->dispatcher->uri_for_action($action, $captures);
1323         if (not defined $path) {
1324             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1325                 if $c->debug;
1326             return undef;
1327         }
1328         $path = '/' if $path eq '';
1329     }
1330
1331     unshift(@args, $path);
1332
1333     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1334         my $namespace = $c->namespace;
1335         if (defined $path) { # cheesy hack to handle path '../foo'
1336            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1337         }
1338         unshift(@args, $namespace || '');
1339     }
1340
1341     # join args with '/', or a blank string
1342     my $args = join('/', grep { defined($_) } @args);
1343     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1344     $args =~ s!^/+!!;
1345
1346     my ($base, $class) = ('/', 'URI::_generic');
1347     if(blessed($c)) {
1348       $base = $c->req->base;
1349       $class = ref($base);
1350       $base =~ s{(?<!/)$}{/};
1351     }
1352
1353     my $query = '';
1354
1355     if (my @keys = keys %$params) {
1356       # somewhat lifted from URI::_query's query_form
1357       $query = '?'.join('&', map {
1358           my $val = $params->{$_};
1359           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1360           s/ /+/g;
1361           my $key = $_;
1362           $val = '' unless defined $val;
1363           (map {
1364               my $param = "$_";
1365               utf8::encode( $param ) if utf8::is_utf8($param);
1366               # using the URI::Escape pattern here so utf8 chars survive
1367               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1368               $param =~ s/ /+/g;
1369               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1370       } @keys);
1371     }
1372
1373     my $res = bless(\"${base}${args}${query}", $class);
1374     $res;
1375 }
1376
1377 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1378
1379 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1380
1381 =over
1382
1383 =item $path
1384
1385 A private path to the Catalyst action you want to create a URI for.
1386
1387 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1388 >> and passing the resulting C<$action> and the remaining arguments to C<<
1389 $c->uri_for >>.
1390
1391 You can also pass in a Catalyst::Action object, in which case it is passed to
1392 C<< $c->uri_for >>.
1393
1394 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1395
1396 For example, if the action looks like:
1397
1398  package MyApp::Controller::Users;
1399
1400  sub lst : Path('the-list') {}
1401
1402 You can use:
1403
1404  $c->uri_for_action('/users/lst')
1405
1406 and it will create the URI /users/the-list.
1407
1408 =item \@captures_and_args?
1409
1410 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1411 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1412 to interpolate all the parameters in the URI.
1413
1414 =item @args?
1415
1416 Optional list of extra arguments - can be supplied in the
1417 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1418 code.
1419
1420 Your action can have zero, a fixed or a variable number of args (e.g.
1421 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1422
1423 =item \%query_values?
1424
1425 Optional array reference of query parameters to append. E.g.
1426
1427   { foo => 'bar' }
1428
1429 will generate
1430
1431   /rest/of/your/uri?foo=bar
1432
1433 =back
1434
1435 =cut
1436
1437 sub uri_for_action {
1438     my ( $c, $path, @args ) = @_;
1439     my $action = blessed($path)
1440       ? $path
1441       : $c->dispatcher->get_action_by_path($path);
1442     unless (defined $action) {
1443       croak "Can't find action for path '$path'";
1444     }
1445     return $c->uri_for( $action, @args );
1446 }
1447
1448 =head2 $c->welcome_message
1449
1450 Returns the Catalyst welcome HTML page.
1451
1452 =cut
1453
1454 sub welcome_message {
1455     my $c      = shift;
1456     my $name   = $c->config->{name};
1457     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1458     my $prefix = Catalyst::Utils::appprefix( ref $c );
1459     $c->response->content_type('text/html; charset=utf-8');
1460     return <<"EOF";
1461 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1462     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1463 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1464     <head>
1465     <meta http-equiv="Content-Language" content="en" />
1466     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1467         <title>$name on Catalyst $VERSION</title>
1468         <style type="text/css">
1469             body {
1470                 color: #000;
1471                 background-color: #eee;
1472             }
1473             div#content {
1474                 width: 640px;
1475                 margin-left: auto;
1476                 margin-right: auto;
1477                 margin-top: 10px;
1478                 margin-bottom: 10px;
1479                 text-align: left;
1480                 background-color: #ccc;
1481                 border: 1px solid #aaa;
1482             }
1483             p, h1, h2 {
1484                 margin-left: 20px;
1485                 margin-right: 20px;
1486                 font-family: verdana, tahoma, sans-serif;
1487             }
1488             a {
1489                 font-family: verdana, tahoma, sans-serif;
1490             }
1491             :link, :visited {
1492                     text-decoration: none;
1493                     color: #b00;
1494                     border-bottom: 1px dotted #bbb;
1495             }
1496             :link:hover, :visited:hover {
1497                     color: #555;
1498             }
1499             div#topbar {
1500                 margin: 0px;
1501             }
1502             pre {
1503                 margin: 10px;
1504                 padding: 8px;
1505             }
1506             div#answers {
1507                 padding: 8px;
1508                 margin: 10px;
1509                 background-color: #fff;
1510                 border: 1px solid #aaa;
1511             }
1512             h1 {
1513                 font-size: 0.9em;
1514                 font-weight: normal;
1515                 text-align: center;
1516             }
1517             h2 {
1518                 font-size: 1.0em;
1519             }
1520             p {
1521                 font-size: 0.9em;
1522             }
1523             p img {
1524                 float: right;
1525                 margin-left: 10px;
1526             }
1527             span#appname {
1528                 font-weight: bold;
1529                 font-size: 1.6em;
1530             }
1531         </style>
1532     </head>
1533     <body>
1534         <div id="content">
1535             <div id="topbar">
1536                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1537                     $VERSION</h1>
1538              </div>
1539              <div id="answers">
1540                  <p>
1541                  <img src="$logo" alt="Catalyst Logo" />
1542                  </p>
1543                  <p>Welcome to the  world of Catalyst.
1544                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1545                     framework will make web development something you had
1546                     never expected it to be: Fun, rewarding, and quick.</p>
1547                  <h2>What to do now?</h2>
1548                  <p>That really depends  on what <b>you</b> want to do.
1549                     We do, however, provide you with a few starting points.</p>
1550                  <p>If you want to jump right into web development with Catalyst
1551                     you might want to start with a tutorial.</p>
1552 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1553 </pre>
1554 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1555 <pre>
1556 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1557 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1558 </code></pre>
1559                  <h2>What to do next?</h2>
1560                  <p>Next it's time to write an actual application. Use the
1561                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1562                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1563                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1564                     they can save you a lot of work.</p>
1565                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1566                     <p>Also, be sure to check out the vast and growing
1567                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1568                     you are likely to find what you need there.
1569                     </p>
1570
1571                  <h2>Need help?</h2>
1572                  <p>Catalyst has a very active community. Here are the main places to
1573                     get in touch with us.</p>
1574                  <ul>
1575                      <li>
1576                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1577                      </li>
1578                      <li>
1579                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1580                      </li>
1581                      <li>
1582                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1583                      </li>
1584                  </ul>
1585                  <h2>In conclusion</h2>
1586                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1587                     as we enjoyed making it. Please contact us if you have ideas
1588                     for improvement or other feedback.</p>
1589              </div>
1590          </div>
1591     </body>
1592 </html>
1593 EOF
1594 }
1595
1596 =head2 run_options
1597
1598 Contains a hash of options passed from the application script, including
1599 the original ARGV the script received, the processed values from that
1600 ARGV and any extra arguments to the script which were not processed.
1601
1602 This can be used to add custom options to your application's scripts
1603 and setup your application differently depending on the values of these
1604 options.
1605
1606 =head1 INTERNAL METHODS
1607
1608 These methods are not meant to be used by end users.
1609
1610 =head2 $c->components
1611
1612 Returns a hash of components.
1613
1614 =head2 $c->context_class
1615
1616 Returns or sets the context class.
1617
1618 =head2 $c->counter
1619
1620 Returns a hashref containing coderefs and execution counts (needed for
1621 deep recursion detection).
1622
1623 =head2 $c->depth
1624
1625 Returns the number of actions on the current internal execution stack.
1626
1627 =head2 $c->dispatch
1628
1629 Dispatches a request to actions.
1630
1631 =cut
1632
1633 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1634
1635 =head2 $c->dispatcher_class
1636
1637 Returns or sets the dispatcher class.
1638
1639 =head2 $c->dump_these
1640
1641 Returns a list of 2-element array references (name, structure) pairs
1642 that will be dumped on the error page in debug mode.
1643
1644 =cut
1645
1646 sub dump_these {
1647     my $c = shift;
1648     [ Request => $c->req ],
1649     [ Response => $c->res ],
1650     [ Stash => $c->stash ],
1651     [ Config => $c->config ];
1652 }
1653
1654 =head2 $c->engine_class
1655
1656 Returns or sets the engine class.
1657
1658 =head2 $c->execute( $class, $coderef )
1659
1660 Execute a coderef in given class and catch exceptions. Errors are available
1661 via $c->error.
1662
1663 =cut
1664
1665 sub execute {
1666     my ( $c, $class, $code ) = @_;
1667     $class = $c->component($class) || $class;
1668     $c->state(0);
1669
1670     if ( $c->depth >= $RECURSION ) {
1671         my $action = $code->reverse();
1672         $action = "/$action" unless $action =~ /->/;
1673         my $error = qq/Deep recursion detected calling "${action}"/;
1674         $c->log->error($error);
1675         $c->error($error);
1676         $c->state(0);
1677         return $c->state;
1678     }
1679
1680     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1681
1682     push( @{ $c->stack }, $code );
1683
1684     no warnings 'recursion';
1685     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1686     #      I have no idea how, ergo $ret (which appears to fix the issue)
1687     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1688
1689     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1690
1691     my $last = pop( @{ $c->stack } );
1692
1693     if ( my $error = $@ ) {
1694         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1695             $error->rethrow if $c->depth > 1;
1696         }
1697         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1698             $error->rethrow if $c->depth > 0;
1699         }
1700         else {
1701             unless ( ref $error ) {
1702                 no warnings 'uninitialized';
1703                 chomp $error;
1704                 my $class = $last->class;
1705                 my $name  = $last->name;
1706                 $error = qq/Caught exception in $class->$name "$error"/;
1707             }
1708             $c->error($error);
1709         }
1710         $c->state(0);
1711     }
1712     return $c->state;
1713 }
1714
1715 sub _stats_start_execute {
1716     my ( $c, $code ) = @_;
1717     my $appclass = ref($c) || $c;
1718     return if ( ( $code->name =~ /^_.*/ )
1719         && ( !$appclass->config->{show_internal_actions} ) );
1720
1721     my $action_name = $code->reverse();
1722     $c->counter->{$action_name}++;
1723
1724     my $action = $action_name;
1725     $action = "/$action" unless $action =~ /->/;
1726
1727     # determine if the call was the result of a forward
1728     # this is done by walking up the call stack and looking for a calling
1729     # sub of Catalyst::forward before the eval
1730     my $callsub = q{};
1731     for my $index ( 2 .. 11 ) {
1732         last
1733         if ( ( caller($index) )[0] eq 'Catalyst'
1734             && ( caller($index) )[3] eq '(eval)' );
1735
1736         if ( ( caller($index) )[3] =~ /forward$/ ) {
1737             $callsub = ( caller($index) )[3];
1738             $action  = "-> $action";
1739             last;
1740         }
1741     }
1742
1743     my $uid = $action_name . $c->counter->{$action_name};
1744
1745     # is this a root-level call or a forwarded call?
1746     if ( $callsub =~ /forward$/ ) {
1747         my $parent = $c->stack->[-1];
1748
1749         # forward, locate the caller
1750         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1751             $c->stats->profile(
1752                 begin  => $action,
1753                 parent => "$parent" . $c->counter->{"$parent"},
1754                 uid    => $uid,
1755             );
1756         }
1757         else {
1758
1759             # forward with no caller may come from a plugin
1760             $c->stats->profile(
1761                 begin => $action,
1762                 uid   => $uid,
1763             );
1764         }
1765     }
1766     else {
1767
1768         # root-level call
1769         $c->stats->profile(
1770             begin => $action,
1771             uid   => $uid,
1772         );
1773     }
1774     return $action;
1775
1776 }
1777
1778 sub _stats_finish_execute {
1779     my ( $c, $info ) = @_;
1780     $c->stats->profile( end => $info );
1781 }
1782
1783 =head2 $c->finalize
1784
1785 Finalizes the request.
1786
1787 =cut
1788
1789 sub finalize {
1790     my $c = shift;
1791
1792     for my $error ( @{ $c->error } ) {
1793         $c->log->error($error);
1794     }
1795
1796     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1797     # stuff like cometd and websockets
1798
1799     if($c->request->has_io_fh) {
1800       $c->log_response;
1801       return;
1802     }
1803
1804     # Allow engine to handle finalize flow (for POE)
1805     my $engine = $c->engine;
1806     if ( my $code = $engine->can('finalize') ) {
1807         $engine->$code($c);
1808     }
1809     else {
1810
1811         $c->finalize_uploads;
1812
1813         # Error
1814         if ( $#{ $c->error } >= 0 ) {
1815             $c->finalize_error;
1816         }
1817
1818         $c->finalize_headers unless $c->response->finalized_headers;
1819
1820         # HEAD request
1821         if ( $c->request->method eq 'HEAD' ) {
1822             $c->response->body('');
1823         }
1824
1825         $c->finalize_body;
1826     }
1827
1828     $c->log_response;
1829
1830     if ($c->use_stats) {
1831         my $elapsed = $c->stats->elapsed;
1832         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1833         $c->log->info(
1834             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1835     }
1836
1837     return $c->response->status;
1838 }
1839
1840 =head2 $c->finalize_body
1841
1842 Finalizes body.
1843
1844 =cut
1845
1846 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1847
1848 =head2 $c->finalize_cookies
1849
1850 Finalizes cookies.
1851
1852 =cut
1853
1854 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1855
1856 =head2 $c->finalize_error
1857
1858 Finalizes error.
1859
1860 =cut
1861
1862 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1863
1864 =head2 $c->finalize_headers
1865
1866 Finalizes headers.
1867
1868 =cut
1869
1870 sub finalize_headers {
1871     my $c = shift;
1872
1873     my $response = $c->response; #accessor calls can add up?
1874
1875     # Check if we already finalized headers
1876     return if $response->finalized_headers;
1877
1878     # Handle redirects
1879     if ( my $location = $response->redirect ) {
1880         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1881         $response->header( Location => $location );
1882
1883         if ( !$response->has_body ) {
1884             # Add a default body if none is already present
1885             my $encoded_location = encode_entities($location);
1886             $response->body(<<"EOF");
1887 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1888 <html xmlns="http://www.w3.org/1999/xhtml">
1889   <head>
1890     <title>Moved</title>
1891   </head>
1892   <body>
1893      <p>This item has moved <a href="$encoded_location">here</a>.</p>
1894   </body>
1895 </html>
1896 EOF
1897             $response->content_type('text/html; charset=utf-8');
1898         }
1899     }
1900
1901     # Content-Length
1902     if ( defined $response->body && length $response->body && !$response->content_length ) {
1903
1904         # get the length from a filehandle
1905         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1906         {
1907             my $size = -s $response->body;
1908             if ( $size ) {
1909                 $response->content_length( $size );
1910             }
1911             else {
1912                 $c->log->warn('Serving filehandle without a content-length');
1913             }
1914         }
1915         else {
1916             # everything should be bytes at this point, but just in case
1917             $response->content_length( length( $response->body ) );
1918         }
1919     }
1920
1921     # Errors
1922     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1923         $response->headers->remove_header("Content-Length");
1924         $response->body('');
1925     }
1926
1927     $c->finalize_cookies;
1928
1929     $c->response->finalize_headers();
1930
1931     # Done
1932     $response->finalized_headers(1);
1933 }
1934
1935 =head2 $c->finalize_output
1936
1937 An alias for finalize_body.
1938
1939 =head2 $c->finalize_read
1940
1941 Finalizes the input after reading is complete.
1942
1943 =cut
1944
1945 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1946
1947 =head2 $c->finalize_uploads
1948
1949 Finalizes uploads. Cleans up any temporary files.
1950
1951 =cut
1952
1953 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1954
1955 =head2 $c->get_action( $action, $namespace )
1956
1957 Gets an action in a given namespace.
1958
1959 =cut
1960
1961 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1962
1963 =head2 $c->get_actions( $action, $namespace )
1964
1965 Gets all actions of a given name in a namespace and all parent
1966 namespaces.
1967
1968 =cut
1969
1970 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1971
1972 =head2 $app->handle_request( @arguments )
1973
1974 Called to handle each HTTP request.
1975
1976 =cut
1977
1978 sub handle_request {
1979     my ( $class, @arguments ) = @_;
1980
1981     # Always expect worst case!
1982     my $status = -1;
1983     try {
1984         if ($class->debug) {
1985             my $secs = time - $START || 1;
1986             my $av = sprintf '%.3f', $COUNT / $secs;
1987             my $time = localtime time;
1988             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1989         }
1990
1991         my $c = $class->prepare(@arguments);
1992         $c->dispatch;
1993         $status = $c->finalize;
1994     }
1995     catch {
1996         chomp(my $error = $_);
1997         $class->log->error(qq/Caught exception in engine "$error"/);
1998     };
1999
2000     $COUNT++;
2001
2002     if(my $coderef = $class->log->can('_flush')){
2003         $class->log->$coderef();
2004     }
2005     return $status;
2006 }
2007
2008 =head2 $class->prepare( @arguments )
2009
2010 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2011 etc.).
2012
2013 =cut
2014
2015 has _uploadtmp => (
2016     is => 'ro',
2017     predicate => '_has_uploadtmp',
2018 );
2019
2020 sub prepare {
2021     my ( $class, @arguments ) = @_;
2022
2023     # XXX
2024     # After the app/ctxt split, this should become an attribute based on something passed
2025     # into the application.
2026     $class->context_class( ref $class || $class ) unless $class->context_class;
2027
2028     my $uploadtmp = $class->config->{uploadtmp};
2029     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2030
2031     $c->response->_context($c);
2032
2033     #surely this is not the most efficient way to do things...
2034     $c->stats($class->stats_class->new)->enable($c->use_stats);
2035     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2036         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2037     }
2038
2039     try {
2040         # Allow engine to direct the prepare flow (for POE)
2041         if ( my $prepare = $c->engine->can('prepare') ) {
2042             $c->engine->$prepare( $c, @arguments );
2043         }
2044         else {
2045             $c->prepare_request(@arguments);
2046             $c->prepare_connection;
2047             $c->prepare_query_parameters;
2048             $c->prepare_headers; # Just hooks, no longer needed - they just
2049             $c->prepare_cookies; # cause the lazy attribute on req to build
2050             $c->prepare_path;
2051
2052             # Prepare the body for reading, either by prepare_body
2053             # or the user, if they are using $c->read
2054             $c->prepare_read;
2055
2056             # Parse the body unless the user wants it on-demand
2057             unless ( ref($c)->config->{parse_on_demand} ) {
2058                 $c->prepare_body;
2059             }
2060         }
2061         $c->prepare_action;
2062     }
2063     # VERY ugly and probably shouldn't rely on ->finalize actually working
2064     catch {
2065         # failed prepare is always due to an invalid request, right?
2066         $c->response->status(400);
2067         $c->response->content_type('text/plain');
2068         $c->response->body('Bad Request');
2069         # Note we call finalize and then die here, which escapes
2070         # finalize being called in the enclosing block..
2071         # It in fact couldn't be called, as we don't return $c..
2072         # This is a mess - but I'm unsure you can fix this without
2073         # breaking compat for people doing crazy things (we should set
2074         # the 400 and just return the ctx here IMO, letting finalize get called
2075         # above...
2076         $c->finalize;
2077         die $_;
2078     };
2079
2080     $c->log_request;
2081
2082     return $c;
2083 }
2084
2085 =head2 $c->prepare_action
2086
2087 Prepares action. See L<Catalyst::Dispatcher>.
2088
2089 =cut
2090
2091 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2092
2093 =head2 $c->prepare_body
2094
2095 Prepares message body.
2096
2097 =cut
2098
2099 sub prepare_body {
2100     my $c = shift;
2101
2102     return if $c->request->_has_body;
2103
2104     # Initialize on-demand data
2105     $c->engine->prepare_body( $c, @_ );
2106     $c->prepare_parameters;
2107     $c->prepare_uploads;
2108 }
2109
2110 =head2 $c->prepare_body_chunk( $chunk )
2111
2112 Prepares a chunk of data before sending it to L<HTTP::Body>.
2113
2114 See L<Catalyst::Engine>.
2115
2116 =cut
2117
2118 sub prepare_body_chunk {
2119     my $c = shift;
2120     $c->engine->prepare_body_chunk( $c, @_ );
2121 }
2122
2123 =head2 $c->prepare_body_parameters
2124
2125 Prepares body parameters.
2126
2127 =cut
2128
2129 sub prepare_body_parameters {
2130     my $c = shift;
2131     $c->engine->prepare_body_parameters( $c, @_ );
2132 }
2133
2134 =head2 $c->prepare_connection
2135
2136 Prepares connection.
2137
2138 =cut
2139
2140 sub prepare_connection {
2141     my $c = shift;
2142     # XXX - This is called on the engine (not the request) to maintain
2143     #       Engine::PSGI back compat.
2144     $c->engine->prepare_connection($c);
2145 }
2146
2147 =head2 $c->prepare_cookies
2148
2149 Prepares cookies by ensuring that the attribute on the request
2150 object has been built.
2151
2152 =cut
2153
2154 sub prepare_cookies { my $c = shift; $c->request->cookies }
2155
2156 =head2 $c->prepare_headers
2157
2158 Prepares request headers by ensuring that the attribute on the request
2159 object has been built.
2160
2161 =cut
2162
2163 sub prepare_headers { my $c = shift; $c->request->headers }
2164
2165 =head2 $c->prepare_parameters
2166
2167 Prepares parameters.
2168
2169 =cut
2170
2171 sub prepare_parameters {
2172     my $c = shift;
2173     $c->prepare_body_parameters;
2174     $c->engine->prepare_parameters( $c, @_ );
2175 }
2176
2177 =head2 $c->prepare_path
2178
2179 Prepares path and base.
2180
2181 =cut
2182
2183 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2184
2185 =head2 $c->prepare_query_parameters
2186
2187 Prepares query parameters.
2188
2189 =cut
2190
2191 sub prepare_query_parameters {
2192     my $c = shift;
2193
2194     $c->engine->prepare_query_parameters( $c, @_ );
2195 }
2196
2197 =head2 $c->log_request
2198
2199 Writes information about the request to the debug logs.  This includes:
2200
2201 =over 4
2202
2203 =item * Request method, path, and remote IP address
2204
2205 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2206
2207 =item * Request parameters
2208
2209 =item * File uploads
2210
2211 =back
2212
2213 =cut
2214
2215 sub log_request {
2216     my $c = shift;
2217
2218     return unless $c->debug;
2219
2220     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2221     my $request = $dump->[1];
2222
2223     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2224     $method ||= '';
2225     $path = '/' unless length $path;
2226     $address ||= '';
2227     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2228
2229     $c->log_request_headers($request->headers);
2230
2231     if ( my $keywords = $request->query_keywords ) {
2232         $c->log->debug("Query keywords are: $keywords");
2233     }
2234
2235     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2236
2237     $c->log_request_uploads($request);
2238 }
2239
2240 =head2 $c->log_response
2241
2242 Writes information about the response to the debug logs by calling
2243 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2244
2245 =cut
2246
2247 sub log_response {
2248     my $c = shift;
2249
2250     return unless $c->debug;
2251
2252     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2253     my $response = $dump->[1];
2254
2255     $c->log_response_status_line($response);
2256     $c->log_response_headers($response->headers);
2257 }
2258
2259 =head2 $c->log_response_status_line($response)
2260
2261 Writes one line of information about the response to the debug logs.  This includes:
2262
2263 =over 4
2264
2265 =item * Response status code
2266
2267 =item * Content-Type header (if present)
2268
2269 =item * Content-Length header (if present)
2270
2271 =back
2272
2273 =cut
2274
2275 sub log_response_status_line {
2276     my ($c, $response) = @_;
2277
2278     $c->log->debug(
2279         sprintf(
2280             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2281             $response->status                            || 'unknown',
2282             $response->headers->header('Content-Type')   || 'unknown',
2283             $response->headers->header('Content-Length') || 'unknown'
2284         )
2285     );
2286 }
2287
2288 =head2 $c->log_response_headers($headers);
2289
2290 Hook method which can be wrapped by plugins to log the response headers.
2291 No-op in the default implementation.
2292
2293 =cut
2294
2295 sub log_response_headers {}
2296
2297 =head2 $c->log_request_parameters( query => {}, body => {} )
2298
2299 Logs request parameters to debug logs
2300
2301 =cut
2302
2303 sub log_request_parameters {
2304     my $c          = shift;
2305     my %all_params = @_;
2306
2307     return unless $c->debug;
2308
2309     my $column_width = Catalyst::Utils::term_width() - 44;
2310     foreach my $type (qw(query body)) {
2311         my $params = $all_params{$type};
2312         next if ! keys %$params;
2313         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2314         for my $key ( sort keys %$params ) {
2315             my $param = $params->{$key};
2316             my $value = defined($param) ? $param : '';
2317             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2318         }
2319         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2320     }
2321 }
2322
2323 =head2 $c->log_request_uploads
2324
2325 Logs file uploads included in the request to the debug logs.
2326 The parameter name, filename, file type, and file size are all included in
2327 the debug logs.
2328
2329 =cut
2330
2331 sub log_request_uploads {
2332     my $c = shift;
2333     my $request = shift;
2334     return unless $c->debug;
2335     my $uploads = $request->uploads;
2336     if ( keys %$uploads ) {
2337         my $t = Text::SimpleTable->new(
2338             [ 12, 'Parameter' ],
2339             [ 26, 'Filename' ],
2340             [ 18, 'Type' ],
2341             [ 9,  'Size' ]
2342         );
2343         for my $key ( sort keys %$uploads ) {
2344             my $upload = $uploads->{$key};
2345             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2346                 $t->row( $key, $u->filename, $u->type, $u->size );
2347             }
2348         }
2349         $c->log->debug( "File Uploads are:\n" . $t->draw );
2350     }
2351 }
2352
2353 =head2 $c->log_request_headers($headers);
2354
2355 Hook method which can be wrapped by plugins to log the request headers.
2356 No-op in the default implementation.
2357
2358 =cut
2359
2360 sub log_request_headers {}
2361
2362 =head2 $c->log_headers($type => $headers)
2363
2364 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2365
2366 =cut
2367
2368 sub log_headers {
2369     my $c       = shift;
2370     my $type    = shift;
2371     my $headers = shift;    # an HTTP::Headers instance
2372
2373     return unless $c->debug;
2374
2375     my $column_width = Catalyst::Utils::term_width() - 28;
2376     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2377     $headers->scan(
2378         sub {
2379             my ( $name, $value ) = @_;
2380             $t->row( $name, $value );
2381         }
2382     );
2383     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2384 }
2385
2386
2387 =head2 $c->prepare_read
2388
2389 Prepares the input for reading.
2390
2391 =cut
2392
2393 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2394
2395 =head2 $c->prepare_request
2396
2397 Prepares the engine request.
2398
2399 =cut
2400
2401 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2402
2403 =head2 $c->prepare_uploads
2404
2405 Prepares uploads.
2406
2407 =cut
2408
2409 sub prepare_uploads {
2410     my $c = shift;
2411
2412     $c->engine->prepare_uploads( $c, @_ );
2413 }
2414
2415 =head2 $c->prepare_write
2416
2417 Prepares the output for writing.
2418
2419 =cut
2420
2421 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2422
2423 =head2 $c->request_class
2424
2425 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2426
2427 =head2 $c->response_class
2428
2429 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2430
2431 =head2 $c->read( [$maxlength] )
2432
2433 Reads a chunk of data from the request body. This method is designed to
2434 be used in a while loop, reading C<$maxlength> bytes on every call.
2435 C<$maxlength> defaults to the size of the request if not specified.
2436
2437 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2438 directly.
2439
2440 Warning: If you use read(), Catalyst will not process the body,
2441 so you will not be able to access POST parameters or file uploads via
2442 $c->request.  You must handle all body parsing yourself.
2443
2444 =cut
2445
2446 sub read { my $c = shift; return $c->request->read( @_ ) }
2447
2448 =head2 $c->run
2449
2450 Starts the engine.
2451
2452 =cut
2453
2454 sub run {
2455   my $app = shift;
2456   $app->_make_immutable_if_needed;
2457   $app->engine_loader->needs_psgi_engine_compat_hack ?
2458     $app->engine->run($app, @_) :
2459       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2460 }
2461
2462 sub _make_immutable_if_needed {
2463     my $class = shift;
2464     my $meta = Class::MOP::get_metaclass_by_name($class);
2465     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2466     if (
2467         $meta->is_immutable
2468         && ! { $meta->immutable_options }->{replace_constructor}
2469         && $isa_ca
2470     ) {
2471         warn("You made your application class ($class) immutable, "
2472             . "but did not inline the\nconstructor. "
2473             . "This will break catalyst, as your app \@ISA "
2474             . "Class::Accessor(::Fast)?\nPlease pass "
2475             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2476     }
2477     unless ($meta->is_immutable) {
2478         # XXX - FIXME warning here as you should make your app immutable yourself.
2479         $meta->make_immutable(
2480             replace_constructor => 1,
2481         );
2482     }
2483 }
2484
2485 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2486
2487 Sets an action in a given namespace.
2488
2489 =cut
2490
2491 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2492
2493 =head2 $c->setup_actions($component)
2494
2495 Sets up actions for a component.
2496
2497 =cut
2498
2499 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2500
2501 =head2 $c->setup_components
2502
2503 This method is called internally to set up the application's components.
2504
2505 It finds modules by calling the L<locate_components> method, expands them to
2506 package names with the L<expand_component_module> method, and then installs
2507 each component into the application.
2508
2509 The C<setup_components> config option is passed to both of the above methods.
2510
2511 Installation of each component is performed by the L<setup_component> method,
2512 below.
2513
2514 =cut
2515
2516 sub setup_components {
2517     my $class = shift;
2518
2519     my $config  = $class->config->{ setup_components };
2520
2521     my @comps = $class->locate_components($config);
2522     my %comps = map { $_ => 1 } @comps;
2523
2524     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2525     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2526         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2527     ) if $deprecatedcatalyst_component_names;
2528
2529     for my $component ( @comps ) {
2530
2531         # We pass ignore_loaded here so that overlay files for (e.g.)
2532         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2533         # we know M::P::O found a file on disk so this is safe
2534
2535         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2536     }
2537
2538     for my $component (@comps) {
2539         my $instance = $class->components->{ $component } = $class->setup_component($component);
2540         my @expanded_components = $instance->can('expand_modules')
2541             ? $instance->expand_modules( $component, $config )
2542             : $class->expand_component_module( $component, $config );
2543         for my $component (@expanded_components) {
2544             next if $comps{$component};
2545             $class->components->{ $component } = $class->setup_component($component);
2546         }
2547     }
2548 }
2549
2550 =head2 $c->locate_components( $setup_component_config )
2551
2552 This method is meant to provide a list of component modules that should be
2553 setup for the application.  By default, it will use L<Module::Pluggable>.
2554
2555 Specify a C<setup_components> config option to pass additional options directly
2556 to L<Module::Pluggable>. To add additional search paths, specify a key named
2557 C<search_extra> as an array reference. Items in the array beginning with C<::>
2558 will have the application class name prepended to them.
2559
2560 =cut
2561
2562 sub locate_components {
2563     my $class  = shift;
2564     my $config = shift;
2565
2566     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2567     my $extra   = delete $config->{ search_extra } || [];
2568
2569     push @paths, @$extra;
2570
2571     my $locator = Module::Pluggable::Object->new(
2572         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2573         %$config
2574     );
2575
2576     # XXX think about ditching this sort entirely
2577     my @comps = sort { length $a <=> length $b } $locator->plugins;
2578
2579     return @comps;
2580 }
2581
2582 =head2 $c->expand_component_module( $component, $setup_component_config )
2583
2584 Components found by C<locate_components> will be passed to this method, which
2585 is expected to return a list of component (package) names to be set up.
2586
2587 =cut
2588
2589 sub expand_component_module {
2590     my ($class, $module) = @_;
2591     return Devel::InnerPackage::list_packages( $module );
2592 }
2593
2594 =head2 $c->setup_component
2595
2596 =cut
2597
2598 sub setup_component {
2599     my( $class, $component ) = @_;
2600
2601     unless ( $component->can( 'COMPONENT' ) ) {
2602         return $component;
2603     }
2604
2605     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2606     my $config = $class->config->{ $suffix } || {};
2607     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2608     # methods also pass it. local to avoid pointlessly shitting in config
2609     # for the debug screen, as $component is already the key name.
2610     local $config->{catalyst_component_name} = $component;
2611
2612     my $instance = eval { $component->COMPONENT( $class, $config ); };
2613
2614     if ( my $error = $@ ) {
2615         chomp $error;
2616         Catalyst::Exception->throw(
2617             message => qq/Couldn't instantiate component "$component", "$error"/
2618         );
2619     }
2620
2621     unless (blessed $instance) {
2622         my $metaclass = Moose::Util::find_meta($component);
2623         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2624         my $component_method_from = $method_meta->associated_metaclass->name;
2625         my $value = defined($instance) ? $instance : 'undef';
2626         Catalyst::Exception->throw(
2627             message =>
2628             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2629         );
2630     }
2631     return $instance;
2632 }
2633
2634 =head2 $c->setup_dispatcher
2635
2636 Sets up dispatcher.
2637
2638 =cut
2639
2640 sub setup_dispatcher {
2641     my ( $class, $dispatcher ) = @_;
2642
2643     if ($dispatcher) {
2644         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2645     }
2646
2647     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2648         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2649     }
2650
2651     unless ($dispatcher) {
2652         $dispatcher = $class->dispatcher_class;
2653     }
2654
2655     Class::MOP::load_class($dispatcher);
2656
2657     # dispatcher instance
2658     $class->dispatcher( $dispatcher->new );
2659 }
2660
2661 =head2 $c->setup_engine
2662
2663 Sets up engine.
2664
2665 =cut
2666
2667 sub engine_class {
2668     my ($class, $requested_engine) = @_;
2669
2670     if (!$class->engine_loader || $requested_engine) {
2671         $class->engine_loader(
2672             Catalyst::EngineLoader->new({
2673                 application_name => $class,
2674                 (defined $requested_engine
2675                      ? (catalyst_engine_class => $requested_engine) : ()),
2676             }),
2677         );
2678     }
2679
2680     $class->engine_loader->catalyst_engine_class;
2681 }
2682
2683 sub setup_engine {
2684     my ($class, $requested_engine) = @_;
2685
2686     my $engine = do {
2687         my $loader = $class->engine_loader;
2688
2689         if (!$loader || $requested_engine) {
2690             $loader = Catalyst::EngineLoader->new({
2691                 application_name => $class,
2692                 (defined $requested_engine
2693                      ? (requested_engine => $requested_engine) : ()),
2694             }),
2695
2696             $class->engine_loader($loader);
2697         }
2698
2699         $loader->catalyst_engine_class;
2700     };
2701
2702     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2703     return if $class->loading_psgi_file;
2704
2705     Class::MOP::load_class($engine);
2706
2707     if ($ENV{MOD_PERL}) {
2708         my $apache = $class->engine_loader->auto;
2709
2710         my $meta = find_meta($class);
2711         my $was_immutable = $meta->is_immutable;
2712         my %immutable_options = $meta->immutable_options;
2713         $meta->make_mutable if $was_immutable;
2714
2715         $meta->add_method(handler => sub {
2716             my $r = shift;
2717             my $psgi_app = $class->_finalized_psgi_app;
2718             $apache->call_app($r, $psgi_app);
2719         });
2720
2721         $meta->make_immutable(%immutable_options) if $was_immutable;
2722     }
2723
2724     $class->engine( $engine->new );
2725
2726     return;
2727 }
2728
2729 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2730 ## build in server support (back compat support for pre psgi port behavior).
2731 ## This is so that we don't build a new psgi app for each request when using
2732 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2733
2734 sub _finalized_psgi_app {
2735     my ($app) = @_;
2736
2737     unless ($app->_psgi_app) {
2738         my $psgi_app = $app->_setup_psgi_app;
2739         $app->_psgi_app($psgi_app);
2740     }
2741
2742     return $app->_psgi_app;
2743 }
2744
2745 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2746 ## home directory and load that and return it (just assume it is doing the
2747 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2748 ## in default_middleware and return it ( this is for backward compatibility
2749 ## with pre psgi port behavior ).
2750
2751 sub _setup_psgi_app {
2752     my ($app) = @_;
2753
2754     for my $home (Path::Class::Dir->new($app->config->{home})) {
2755         my $psgi_file = $home->file(
2756             Catalyst::Utils::appprefix($app) . '.psgi',
2757         );
2758
2759         next unless -e $psgi_file;
2760
2761         # If $psgi_file calls ->setup_engine, it's doing so to load
2762         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2763         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2764         # anyway. So set a flag (ick) that tells setup_engine not to populate
2765         # $c->engine or do any other things we might regret.
2766
2767         $app->loading_psgi_file(1);
2768         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2769         $app->loading_psgi_file(0);
2770
2771         return $psgi_app
2772             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2773
2774         warn <<"EOW";
2775 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2776
2777 Its content has been ignored. Please consult the Catalyst::Upgrading
2778 documentation on how to upgrade from Catalyst::Engine::PSGI.
2779 EOW
2780     }
2781
2782     return $app->apply_default_middlewares($app->psgi_app);
2783 }
2784
2785 =head2 $c->apply_default_middlewares
2786
2787 Adds the following L<Plack> middlewares to your application, since they are
2788 useful and commonly needed:
2789
2790 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2791 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2792 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2793 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2794 applied since this middleware is smart enough to conditionally apply itself).
2795
2796 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2797 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2798 $ENV{SCRIPT_NAME}
2799
2800 =cut
2801
2802
2803 sub apply_default_middlewares {
2804     my ($app, $psgi_app) = @_;
2805
2806     $psgi_app = Plack::Middleware::Conditional->wrap(
2807         $psgi_app,
2808         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2809         condition => sub {
2810             my ($env) = @_;
2811             return if $app->config->{ignore_frontend_proxy};
2812             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2813                 || $app->config->{using_frontend_proxy};
2814         },
2815     );
2816
2817     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2818     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2819     $psgi_app = Plack::Middleware::Conditional->wrap(
2820         $psgi_app,
2821         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2822         condition => sub {
2823             my ($env) = @_;
2824             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2825             return unless $1 < 4.23;
2826             1;
2827         },
2828     );
2829
2830     # we're applying this unconditionally as the middleware itself already makes
2831     # sure it doesn't fuck things up if it's not running under one of the right
2832     # IIS versions
2833     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2834
2835     # And another IIS issue, this time with IIS7.
2836     $psgi_app = Plack::Middleware::Conditional->wrap(
2837         $psgi_app,
2838         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2839         condition => sub {
2840             my ($env) = @_;
2841             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2842         },
2843     );
2844
2845     return $psgi_app;
2846 }
2847
2848 =head2 $c->psgi_app
2849
2850 Returns a PSGI application code reference for the catalyst application
2851 C<$c>. This is the bare application without any middlewares
2852 applied. C<${myapp}.psgi> is not taken into account.
2853
2854 This is what you want to be using to retrieve the PSGI application code
2855 reference of your Catalyst application for use in F<.psgi> files.
2856
2857 =cut
2858
2859 sub psgi_app {
2860     my ($app) = @_;
2861     return $app->engine->build_psgi_app($app);
2862 }
2863
2864 =head2 $c->setup_home
2865
2866 Sets up the home directory.
2867
2868 =cut
2869
2870 sub setup_home {
2871     my ( $class, $home ) = @_;
2872
2873     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2874         $home = $env;
2875     }
2876
2877     $home ||= Catalyst::Utils::home($class);
2878
2879     if ($home) {
2880         #I remember recently being scolded for assigning config values like this
2881         $class->config->{home} ||= $home;
2882         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2883     }
2884 }
2885
2886 =head2 $c->setup_log
2887
2888 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2889 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2890 log to.
2891
2892 This method also installs a C<debug> method that returns a true value into the
2893 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2894 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2895
2896 Note that if the log has already been setup, by either a previous call to
2897 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2898 that this method won't actually set up the log object.
2899
2900 =cut
2901
2902 sub setup_log {
2903     my ( $class, $levels ) = @_;
2904
2905     $levels ||= '';
2906     $levels =~ s/^\s+//;
2907     $levels =~ s/\s+$//;
2908     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2909
2910     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2911     if ( defined $env_debug ) {
2912         $levels{debug} = 1 if $env_debug; # Ugly!
2913         delete($levels{debug}) unless $env_debug;
2914     }
2915
2916     unless ( $class->log ) {
2917         $class->log( Catalyst::Log->new(keys %levels) );
2918     }
2919
2920     if ( $levels{debug} ) {
2921         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2922         $class->log->debug('Debug messages enabled');
2923     }
2924 }
2925
2926 =head2 $c->setup_plugins
2927
2928 Sets up plugins.
2929
2930 =cut
2931
2932 =head2 $c->setup_stats
2933
2934 Sets up timing statistics class.
2935
2936 =cut
2937
2938 sub setup_stats {
2939     my ( $class, $stats ) = @_;
2940
2941     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2942
2943     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2944     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2945         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2946         $class->log->debug('Statistics enabled');
2947     }
2948 }
2949
2950
2951 =head2 $c->registered_plugins
2952
2953 Returns a sorted list of the plugins which have either been stated in the
2954 import list.
2955
2956 If passed a given plugin name, it will report a boolean value indicating
2957 whether or not that plugin is loaded.  A fully qualified name is required if
2958 the plugin name does not begin with C<Catalyst::Plugin::>.
2959
2960  if ($c->registered_plugins('Some::Plugin')) {
2961      ...
2962  }
2963
2964 =cut
2965
2966 {
2967
2968     sub registered_plugins {
2969         my $proto = shift;
2970         return sort keys %{ $proto->_plugins } unless @_;
2971         my $plugin = shift;
2972         return 1 if exists $proto->_plugins->{$plugin};
2973         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2974     }
2975
2976     sub _register_plugin {
2977         my ( $proto, $plugin, $instant ) = @_;
2978         my $class = ref $proto || $proto;
2979
2980         Class::MOP::load_class( $plugin );
2981         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2982             if $plugin->isa( 'Catalyst::Component' );
2983         my $plugin_meta = Moose::Meta::Class->create($plugin);
2984         if (!$plugin_meta->has_method('new')
2985             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
2986             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
2987         }
2988         if (!$instant && !$proto->_plugins->{$plugin}) {
2989             my $meta = Class::MOP::get_metaclass_by_name($class);
2990             $meta->superclasses($plugin, $meta->superclasses);
2991         }
2992         $proto->_plugins->{$plugin} = 1;
2993         return $class;
2994     }
2995
2996     sub _default_plugins { return qw(Unicode::Encoding) }
2997
2998     sub setup_plugins {
2999         my ( $class, $plugins ) = @_;
3000
3001         $class->_plugins( {} ) unless $class->_plugins;
3002         $plugins = [ grep {
3003             m/Unicode::Encoding/ ? do {
3004                 $class->log->warn(
3005                     'Unicode::Encoding plugin is auto-applied,'
3006                     . ' please remove this from your appclass'
3007                     . ' and make sure to define "encoding" config'
3008                 );
3009                 unless (exists $class->config->{'encoding'}) {
3010                   $class->config->{'encoding'} = 'UTF-8';
3011                 }
3012                 () }
3013                 : $_
3014         } @$plugins ];
3015         push @$plugins, $class->_default_plugins;
3016         $plugins = Data::OptList::mkopt($plugins || []);
3017
3018         my @plugins = map {
3019             [ Catalyst::Utils::resolve_namespace(
3020                   $class . '::Plugin',
3021                   'Catalyst::Plugin', $_->[0]
3022               ),
3023               $_->[1],
3024             ]
3025          } @{ $plugins };
3026
3027         for my $plugin ( reverse @plugins ) {
3028             Class::MOP::load_class($plugin->[0], $plugin->[1]);
3029             my $meta = find_meta($plugin->[0]);
3030             next if $meta && $meta->isa('Moose::Meta::Role');
3031
3032             $class->_register_plugin($plugin->[0]);
3033         }
3034
3035         my @roles =
3036             map  { $_->[0]->name, $_->[1] }
3037             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3038             map  { [find_meta($_->[0]), $_->[1]] }
3039             @plugins;
3040
3041         Moose::Util::apply_all_roles(
3042             $class => @roles
3043         ) if @roles;
3044     }
3045 }
3046
3047 =head2 $c->stack
3048
3049 Returns an arrayref of the internal execution stack (actions that are
3050 currently executing).
3051
3052 =head2 $c->stats
3053
3054 Returns the current timing statistics object. By default Catalyst uses
3055 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3056 L<< stats_class|/"$c->stats_class" >>.
3057
3058 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3059 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3060 profile explicitly, although MyApp.pm still won't profile nor output anything
3061 by itself.
3062
3063 =head2 $c->stats_class
3064
3065 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3066
3067 =head2 $c->use_stats
3068
3069 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3070
3071 Note that this is a static method, not an accessor and should be overridden
3072 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3073
3074 =cut
3075
3076 sub use_stats { 0 }
3077
3078
3079 =head2 $c->write( $data )
3080
3081 Writes $data to the output stream. When using this method directly, you
3082 will need to manually set the C<Content-Length> header to the length of
3083 your output data, if known.
3084
3085 =cut
3086
3087 sub write {
3088     my $c = shift;
3089
3090     # Finalize headers if someone manually writes output (for compat)
3091     $c->finalize_headers;
3092
3093     return $c->response->write( @_ );
3094 }
3095
3096 =head2 version
3097
3098 Returns the Catalyst version number. Mostly useful for "powered by"
3099 messages in template systems.
3100
3101 =cut
3102
3103 sub version { return $Catalyst::VERSION }
3104
3105 =head1 CONFIGURATION
3106
3107 There are a number of 'base' config variables which can be set:
3108
3109 =over
3110
3111 =item *
3112
3113 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3114
3115 =item *
3116
3117 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3118
3119 =item *
3120
3121 C<disable_component_resolution_regex_fallback> - Turns
3122 off the deprecated component resolution functionality so
3123 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3124 are called then regex search will not be attempted on string values and
3125 instead C<undef> will be returned.
3126
3127 =item *
3128
3129 C<home> - The application home directory. In an uninstalled application,
3130 this is the top level application directory. In an installed application,
3131 this will be the directory containing C<< MyApp.pm >>.
3132
3133 =item *
3134
3135 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3136
3137 =item *
3138
3139 C<name> - The name of the application in debug messages and the debug and
3140 welcome screens
3141
3142 =item *
3143
3144 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3145 until it is accessed. This allows you to (for example) check authentication (and reject
3146 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3147
3148 =item *
3149
3150 C<root> - The root directory for templates. Usually this is just a
3151 subdirectory of the home directory, but you can set it to change the
3152 templates to a different directory.
3153
3154 =item *
3155
3156 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3157 namespaces from which components will be loaded (and constructed and stored in
3158 C<< $c->components >>).
3159
3160 =item *
3161
3162 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3163 to be shown in hit debug tables in the test server.
3164
3165 =item *
3166
3167 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3168 variable should be used for determining the request path.
3169
3170 Most web server environments pass the requested path to the application using environment variables,
3171 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3172 exposed as C<< $c->request->base >>) and the request path below that base.
3173
3174 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3175 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3176
3177 =over
3178
3179 =item use_request_uri_for_path => 0
3180
3181 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3182 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3183 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3184 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3185
3186 However this method has the major disadvantage that it is impossible to correctly decode some elements
3187 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3188 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3189 can't distinguish / vs %2F in paths (in addition to other encoded values).
3190
3191 =item use_request_uri_for_path => 1
3192
3193 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3194 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3195 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3196
3197 Given that this method of path resolution is provably more correct, it is recommended that you use
3198 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3199 aware of the implications of not being able to handle encoded URI paths correctly.
3200
3201 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3202 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3203 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3204 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3205 C<< $c->request->base >> will be incorrect.
3206
3207 =back
3208
3209 =item *
3210
3211 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3212
3213 =item *
3214
3215 C<encoding> - See L</ENCODING>
3216
3217 =item *
3218
3219 C<abort_chain_on_error_fix>
3220
3221 When there is an error in an action chain, the default behavior is to continue
3222 processing the remaining actions and then catch the error upon chain end.  This
3223 can lead to running actions when the application is in an unexpected state.  If
3224 you have this issue, setting this config value to true will promptly exit a
3225 chain when there is an error raised in any action (thus terminating the chain
3226 early.)
3227
3228 use like:
3229
3230     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3231
3232 In the future this might become the default behavior.
3233
3234 =back
3235
3236 =head1 INTERNAL ACTIONS
3237
3238 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3239 C<_ACTION>, and C<_END>. These are by default not shown in the private
3240 action table, but you can make them visible with a config parameter.
3241
3242     MyApp->config(show_internal_actions => 1);
3243
3244 =head1 ON-DEMAND PARSER
3245
3246 The request body is usually parsed at the beginning of a request,
3247 but if you want to handle input yourself, you can enable on-demand
3248 parsing with a config parameter.
3249
3250     MyApp->config(parse_on_demand => 1);
3251
3252 =head1 PROXY SUPPORT
3253
3254 Many production servers operate using the common double-server approach,
3255 with a lightweight frontend web server passing requests to a larger
3256 backend server. An application running on the backend server must deal
3257 with two problems: the remote user always appears to be C<127.0.0.1> and
3258 the server's hostname will appear to be C<localhost> regardless of the
3259 virtual host that the user connected through.
3260
3261 Catalyst will automatically detect this situation when you are running
3262 the frontend and backend servers on the same machine. The following
3263 changes are made to the request.
3264
3265     $c->req->address is set to the user's real IP address, as read from
3266     the HTTP X-Forwarded-For header.
3267
3268     The host value for $c->req->base and $c->req->uri is set to the real
3269     host, as read from the HTTP X-Forwarded-Host header.
3270
3271 Additionally, you may be running your backend application on an insecure
3272 connection (port 80) while your frontend proxy is running under SSL.  If there
3273 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3274 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3275 be created properly.
3276
3277 In the case of passing in:
3278
3279     X-Forwarded-Port: 443
3280
3281 All calls to C<uri_for> will result in an https link, as is expected.
3282
3283 Obviously, your web server must support these headers for this to work.
3284
3285 In a more complex server farm environment where you may have your
3286 frontend proxy server(s) on different machines, you will need to set a
3287 configuration option to tell Catalyst to read the proxied data from the
3288 headers.
3289
3290     MyApp->config(using_frontend_proxy => 1);
3291
3292 If you do not wish to use the proxy support at all, you may set:
3293
3294     MyApp->config(ignore_frontend_proxy => 0);
3295
3296 =head2 Note about psgi files
3297
3298 Note that if you supply your own .psgi file, calling
3299 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3300
3301 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3302 in your psgi, for example:
3303
3304     builder {
3305         enable "Plack::Middleware::ReverseProxy";
3306         MyApp->psgi_app
3307     };
3308
3309 This will unconditionally add the ReverseProxy support, or you need to call
3310 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3311 apply the support depending upon your config).
3312
3313 See L<Catalyst::PSGI> for more information.
3314
3315 =head1 THREAD SAFETY
3316
3317 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3318 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3319 believe the Catalyst core to be thread-safe.
3320
3321 If you plan to operate in a threaded environment, remember that all other
3322 modules you are using must also be thread-safe. Some modules, most notably
3323 L<DBD::SQLite>, are not thread-safe.
3324
3325 =head1 ENCODING
3326
3327 On request, decodes all params from encoding into a sequence of
3328 logical characters. On response, encodes body into encoding.
3329
3330 =head2 Methods
3331
3332 =over 4
3333
3334 =item encoding
3335
3336 Returns an instance of an C<Encode> encoding
3337
3338     print $c->encoding->name
3339
3340 =item handle_unicode_encoding_exception ($exception_context)
3341
3342 Method called when decoding process for a request fails.
3343
3344 An C<$exception_context> hashref is provided to allow you to override the
3345 behaviour of your application when given data with incorrect encodings.
3346
3347 The default method throws exceptions in the case of invalid request parameters
3348 (resulting in a 500 error), but ignores errors in upload filenames.
3349
3350 The keys passed in the C<$exception_context> hash are:
3351
3352 =over
3353
3354 =item param_value
3355
3356 The value which was not able to be decoded.
3357
3358 =item error_msg
3359
3360 The exception received from L<Encode>.
3361
3362 =item encoding_step
3363
3364 What type of data was being decoded. Valid values are (currently)
3365 C<params> - for request parameters / arguments / captures
3366 and C<uploads> - for request upload filenames.
3367
3368 =back
3369
3370 =back
3371
3372 =head1 SUPPORT
3373
3374 IRC:
3375
3376     Join #catalyst on irc.perl.org.
3377
3378 Mailing Lists:
3379
3380     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3381     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3382
3383 Web:
3384
3385     http://catalyst.perl.org
3386
3387 Wiki:
3388
3389     http://dev.catalyst.perl.org
3390
3391 =head1 SEE ALSO
3392
3393 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3394
3395 =head2 L<Catalyst::Manual> - The Catalyst Manual
3396
3397 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3398
3399 =head2 L<Catalyst::Engine> - Core engine
3400
3401 =head2 L<Catalyst::Log> - Log class.
3402
3403 =head2 L<Catalyst::Request> - Request object
3404
3405 =head2 L<Catalyst::Response> - Response object
3406
3407 =head2 L<Catalyst::Test> - The test suite.
3408
3409 =head1 PROJECT FOUNDER
3410
3411 sri: Sebastian Riedel <sri@cpan.org>
3412
3413 =head1 CONTRIBUTORS
3414
3415 abw: Andy Wardley
3416
3417 acme: Leon Brocard <leon@astray.com>
3418
3419 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3420
3421 Andrew Bramble
3422
3423 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3424
3425 Andrew Ruthven
3426
3427 andyg: Andy Grundman <andy@hybridized.org>
3428
3429 audreyt: Audrey Tang
3430
3431 bricas: Brian Cassidy <bricas@cpan.org>
3432
3433 Caelum: Rafael Kitover <rkitover@io.com>
3434
3435 chansen: Christian Hansen
3436
3437 chicks: Christopher Hicks
3438
3439 Chisel Wright C<pause@herlpacker.co.uk>
3440
3441 Danijel Milicevic C<me@danijel.de>
3442
3443 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3444
3445 David Naughton, C<naughton@umn.edu>
3446
3447 David E. Wheeler
3448
3449 dhoss: Devin Austin <dhoss@cpan.org>
3450
3451 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3452
3453 Drew Taylor
3454
3455 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3456
3457 esskar: Sascha Kiefer
3458
3459 fireartist: Carl Franks <cfranks@cpan.org>
3460
3461 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3462
3463 gabb: Danijel Milicevic
3464
3465 Gary Ashton Jones
3466
3467 Gavin Henry C<ghenry@perl.me.uk>
3468
3469 Geoff Richards
3470
3471 groditi: Guillermo Roditi <groditi@gmail.com>
3472
3473 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3474
3475 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3476
3477 jcamacho: Juan Camacho
3478
3479 jester: Jesse Sheidlower C<jester@panix.com>
3480
3481 jhannah: Jay Hannah <jay@jays.net>
3482
3483 Jody Belka
3484
3485 Johan Lindstrom
3486
3487 jon: Jon Schutz <jjschutz@cpan.org>
3488
3489 Jonathan Rockway C<< <jrockway@cpan.org> >>
3490
3491 Kieren Diment C<kd@totaldatasolution.com>
3492
3493 konobi: Scott McWhirter <konobi@cpan.org>
3494
3495 marcus: Marcus Ramberg <mramberg@cpan.org>
3496
3497 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3498
3499 mgrimes: Mark Grimes <mgrimes@cpan.org>
3500
3501 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3502
3503 mugwump: Sam Vilain
3504
3505 naughton: David Naughton
3506
3507 ningu: David Kamholz <dkamholz@cpan.org>
3508
3509 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3510
3511 numa: Dan Sully <daniel@cpan.org>
3512
3513 obra: Jesse Vincent
3514
3515 Octavian Rasnita
3516
3517 omega: Andreas Marienborg
3518
3519 Oleg Kostyuk <cub.uanic@gmail.com>
3520
3521 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3522
3523 rafl: Florian Ragwitz <rafl@debian.org>
3524
3525 random: Roland Lammel <lammel@cpan.org>
3526
3527 Robert Sedlacek C<< <rs@474.at> >>
3528
3529 SpiceMan: Marcel Montes
3530
3531 sky: Arthur Bergman
3532
3533 szbalint: Balint Szilakszi <szbalint@cpan.org>
3534
3535 t0m: Tomas Doran <bobtfish@bobtfish.net>
3536
3537 Ulf Edvinsson
3538
3539 Viljo Marrandi C<vilts@yahoo.com>
3540
3541 Will Hawes C<info@whawes.co.uk>
3542
3543 willert: Sebastian Willert <willert@cpan.org>
3544
3545 wreis: Wallace Reis <wreis@cpan.org>
3546
3547 Yuval Kogman, C<nothingmuch@woobling.org>
3548
3549 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3550
3551 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3552
3553 =head1 COPYRIGHT
3554
3555 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3556
3557 =head1 LICENSE
3558
3559 This library is free software. You can redistribute it and/or modify it under
3560 the same terms as Perl itself.
3561
3562 =cut
3563
3564 no Moose;
3565
3566 __PACKAGE__->meta->make_immutable;
3567
3568 1;