lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use bytes;
   8 use B::Hooks::EndOfScope ();
   9 use Catalyst::Exception;
  10 use Catalyst::Exception::Detach;
  11 use Catalyst::Exception::Go;
  12 use Catalyst::Log;
  13 use Catalyst::Request;
  14 use Catalyst::Request::Upload;
  15 use Catalyst::Response;
  16 use Catalyst::Utils;
  17 use Catalyst::Controller;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80012';
  83
  84 {
  85     my $dev_version = $VERSION =~ /_\d{2}$/;
  86     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  87 }
  88
  89 $VERSION = eval $VERSION;
  90
  91 sub import {
  92     my ( $class, @arguments ) = @_;
  93
  94     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  95     # callers @ISA.
  96     return unless $class eq 'Catalyst';
  97
  98     my $caller = caller();
  99     return if $caller eq 'main';
 100
 101     # Kill Adopt::NEXT warnings if we're a non-RC version
 102     unless (_IS_DEVELOPMENT_VERSION()) {
 103         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 104     }
 105
 106     my $meta = Moose::Meta::Class->initialize($caller);
 107     unless ( $caller->isa('Catalyst') ) {
 108         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 109         $meta->superclasses(@superclasses);
 110     }
 111     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 112     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 113
 114     unless( $meta->has_method('meta') ){
 115         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 116     }
 117
 118     $caller->arguments( [@arguments] );
 119     $caller->setup_home;
 120 }
 121
 122 sub _application { $_[0] }
 123
 124 =head1 NAME
 125
 126 Catalyst - The Elegant MVC Web Application Framework
 127
 128 =head1 SYNOPSIS
 129
 130 See the L<Catalyst::Manual> distribution for comprehensive
 131 documentation and tutorials.
 132
 133     # Install Catalyst::Devel for helpers and other development tools
 134     # use the helper to create a new application
 135     catalyst.pl MyApp
 136
 137     # add models, views, controllers
 138     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 139     script/myapp_create.pl view MyTemplate TT
 140     script/myapp_create.pl controller Search
 141
 142     # built in testserver -- use -r to restart automatically on changes
 143     # --help to see all available options
 144     script/myapp_server.pl
 145
 146     # command line testing interface
 147     script/myapp_test.pl /yada
 148
 149     ### in lib/MyApp.pm
 150     use Catalyst qw/-Debug/; # include plugins here as well
 151
 152     ### In lib/MyApp/Controller/Root.pm (autocreated)
 153     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 154         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 155         $c->stash->{template} = 'foo.tt'; # set the template
 156         # lookup something from db -- stash vars are passed to TT
 157         $c->stash->{data} =
 158           $c->model('Database::Foo')->search( { country => $args[0] } );
 159         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 160             $c->forward( 'bar' ); # process another action
 161             # do something else after forward returns
 162         }
 163     }
 164
 165     # The foo.tt TT template can use the stash data from the database
 166     [% WHILE (item = data.next) %]
 167         [% item.foo %]
 168     [% END %]
 169
 170     # called for /bar/of/soap, /bar/of/soap/10, etc.
 171     sub bar : Path('/bar/of/soap') { ... }
 172
 173     # called for all actions, from the top-most controller downwards
 174     sub auto : Private {
 175         my ( $self, $c ) = @_;
 176         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 177             $c->res->redirect( '/login' ); # require login
 178             return 0; # abort request and go immediately to end()
 179         }
 180         return 1; # success; carry on to next action
 181     }
 182
 183     # called after all actions are finished
 184     sub end : Private {
 185         my ( $self, $c ) = @_;
 186         if ( scalar @{ $c->error } ) { ... } # handle errors
 187         return if $c->res->body; # already have a response
 188         $c->forward( 'MyApp::View::TT' ); # render template
 189     }
 190
 191     ### in MyApp/Controller/Foo.pm
 192     # called for /foo/bar
 193     sub bar : Local { ... }
 194
 195     # called for /blargle
 196     sub blargle : Global { ... }
 197
 198     # an index action matches /foo, but not /foo/1, etc.
 199     sub index : Private { ... }
 200
 201     ### in MyApp/Controller/Foo/Bar.pm
 202     # called for /foo/bar/baz
 203     sub baz : Local { ... }
 204
 205     # first Root auto is called, then Foo auto, then this
 206     sub auto : Private { ... }
 207
 208     # powerful regular expression paths are also possible
 209     sub details : Regex('^product/(\w+)/details$') {
 210         my ( $self, $c ) = @_;
 211         # extract the (\w+) from the URI
 212         my $product = $c->req->captures->[0];
 213     }
 214
 215 See L<Catalyst::Manual::Intro> for additional information.
 216
 217 =head1 DESCRIPTION
 218
 219 Catalyst is a modern framework for making web applications without the
 220 pain usually associated with this process. This document is a reference
 221 to the main Catalyst application. If you are a new user, we suggest you
 222 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 223
 224 See L<Catalyst::Manual> for more documentation.
 225
 226 Catalyst plugins can be loaded by naming them as arguments to the "use
 227 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 228 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 229 C<My::Module>.
 230
 231     use Catalyst qw/My::Module/;
 232
 233 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 234 fully qualify the name by using a unary plus:
 235
 236     use Catalyst qw/
 237         My::Module
 238         +Fully::Qualified::Plugin::Name
 239     /;
 240
 241 Special flags like C<-Debug> and C<-Engine> can also be specified as
 242 arguments when Catalyst is loaded:
 243
 244     use Catalyst qw/-Debug My::Module/;
 245
 246 The position of plugins and flags in the chain is important, because
 247 they are loaded in the order in which they appear.
 248
 249 The following flags are supported:
 250
 251 =head2 -Debug
 252
 253 Enables debug output. You can also force this setting from the system
 254 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 255 settings override the application, with <MYAPP>_DEBUG having the highest
 256 priority.
 257
 258 =head2 -Engine
 259
 260 Forces Catalyst to use a specific engine. Omit the
 261 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 262
 263     use Catalyst qw/-Engine=CGI/;
 264
 265 =head2 -Home
 266
 267 Forces Catalyst to use a specific home directory, e.g.:
 268
 269     use Catalyst qw[-Home=/usr/mst];
 270
 271 This can also be done in the shell environment by setting either the
 272 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 273 is replaced with the uppercased name of your application, any "::" in
 274 the name will be replaced with underscores, e.g. MyApp::Web should use
 275 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 276
 277 =head2 -Log
 278
 279     use Catalyst '-Log=warn,fatal,error';
 280
 281 Specifies a comma-delimited list of log levels.
 282
 283 =head2 -Stats
 284
 285 Enables statistics collection and reporting. You can also force this setting
 286 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 287 environment settings override the application, with <MYAPP>_STATS having the
 288 highest priority.
 289
 290 e.g.
 291
 292    use Catalyst qw/-Stats=1/
 293
 294 =head1 METHODS
 295
 296 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 297
 298 =head2 $c->action
 299
 300 Returns a L<Catalyst::Action> object for the current action, which
 301 stringifies to the action name. See L<Catalyst::Action>.
 302
 303 =head2 $c->namespace
 304
 305 Returns the namespace of the current action, i.e., the URI prefix
 306 corresponding to the controller of the current action. For example:
 307
 308     # in Controller::Foo::Bar
 309     $c->namespace; # returns 'foo/bar';
 310
 311 =head2 $c->request
 312
 313 =head2 $c->req
 314
 315 Returns the current L<Catalyst::Request> object, giving access to
 316 information about the current client request (including parameters,
 317 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 318
 319 =head2 REQUEST FLOW HANDLING
 320
 321 =head2 $c->forward( $action [, \@arguments ] )
 322
 323 =head2 $c->forward( $class, $method, [, \@arguments ] )
 324
 325 Forwards processing to another action, by its private name. If you give a
 326 class name but no method, C<process()> is called. You may also optionally
 327 pass arguments in an arrayref. The action will receive the arguments in
 328 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 329 C<< $c->req->args >> will be restored to the previous values.
 330
 331 Any data C<return>ed from the action forwarded to, will be returned by the
 332 call to forward.
 333
 334     my $foodata = $c->forward('/foo');
 335     $c->forward('index');
 336     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 337     $c->forward('MyApp::View::TT');
 338
 339 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 340 an C<< eval { } >> around the call (actually
 341 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 342 all 'dies' within the called action. If you want C<die> to propagate you
 343 need to do something like:
 344
 345     $c->forward('foo');
 346     die $c->error if $c->error;
 347
 348 Or make sure to always return true values from your actions and write
 349 your code like this:
 350
 351     $c->forward('foo') || return;
 352
 353 =cut
 354
 355 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 356
 357 =head2 $c->detach( $action [, \@arguments ] )
 358
 359 =head2 $c->detach( $class, $method, [, \@arguments ] )
 360
 361 =head2 $c->detach()
 362
 363 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 364 doesn't return to the previous action when processing is finished.
 365
 366 When called with no arguments it escapes the processing chain entirely.
 367
 368 =cut
 369
 370 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 371
 372 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 373
 374 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 375
 376 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 377 but does a full dispatch, instead of just calling the new C<$action> /
 378 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 379 you go to are called, just like a new request.
 380
 381 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 382 This means, for example, that C<< $c->action >> methods such as
 383 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 384 L<reverse|Catalyst::Action/reverse> return information for the visited action
 385 when they are invoked within the visited action.  This is different from the
 386 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 387 continues to use the $c->action object from the caller action even when
 388 invoked from the callee.
 389
 390 C<< $c->stash >> is kept unchanged.
 391
 392 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 393 allows you to "wrap" another action, just as it would have been called by
 394 dispatching from a URL, while the analogous
 395 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 396 transfer control to another action as if it had been reached directly from a URL.
 397
 398 =cut
 399
 400 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 401
 402 =head2 $c->go( $action [, \@captures, \@arguments ] )
 403
 404 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 405
 406 The relationship between C<go> and
 407 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 408 the relationship between
 409 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 410 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 411 C<< $c->go >> will perform a full dispatch on the specified action or method,
 412 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 413 C<go> escapes the processing of the current request chain on completion, and
 414 does not return to its caller.
 415
 416 =cut
 417
 418 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 419
 420 =head2 $c->response
 421
 422 =head2 $c->res
 423
 424 Returns the current L<Catalyst::Response> object, see there for details.
 425
 426 =head2 $c->stash
 427
 428 Returns a hashref to the stash, which may be used to store data and pass
 429 it between components during a request. You can also set hash keys by
 430 passing arguments. The stash is automatically sent to the view. The
 431 stash is cleared at the end of a request; it cannot be used for
 432 persistent storage (for this you must use a session; see
 433 L<Catalyst::Plugin::Session> for a complete system integrated with
 434 Catalyst).
 435
 436     $c->stash->{foo} = $bar;
 437     $c->stash( { moose => 'majestic', qux => 0 } );
 438     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 439
 440     # stash is automatically passed to the view for use in a template
 441     $c->forward( 'MyApp::View::TT' );
 442
 443 =cut
 444
 445 around stash => sub {
 446     my $orig = shift;
 447     my $c = shift;
 448     my $stash = $orig->($c);
 449     if (@_) {
 450         my $new_stash = @_ > 1 ? {@_} : $_[0];
 451         croak('stash takes a hash or hashref') unless ref $new_stash;
 452         foreach my $key ( keys %$new_stash ) {
 453           $stash->{$key} = $new_stash->{$key};
 454         }
 455     }
 456
 457     return $stash;
 458 };
 459
 460
 461 =head2 $c->error
 462
 463 =head2 $c->error($error, ...)
 464
 465 =head2 $c->error($arrayref)
 466
 467 Returns an arrayref containing error messages.  If Catalyst encounters an
 468 error while processing a request, it stores the error in $c->error.  This
 469 method should only be used to store fatal error messages.
 470
 471     my @error = @{ $c->error };
 472
 473 Add a new error.
 474
 475     $c->error('Something bad happened');
 476
 477 =cut
 478
 479 sub error {
 480     my $c = shift;
 481     if ( $_[0] ) {
 482         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 483         croak @$error unless ref $c;
 484         push @{ $c->{error} }, @$error;
 485     }
 486     elsif ( defined $_[0] ) { $c->{error} = undef }
 487     return $c->{error} || [];
 488 }
 489
 490
 491 =head2 $c->state
 492
 493 Contains the return value of the last executed action.
 494
 495 =head2 $c->clear_errors
 496
 497 Clear errors.  You probably don't want to clear the errors unless you are
 498 implementing a custom error screen.
 499
 500 This is equivalent to running
 501
 502     $c->error(0);
 503
 504 =cut
 505
 506 sub clear_errors {
 507     my $c = shift;
 508     $c->error(0);
 509 }
 510
 511 sub _comp_search_prefixes {
 512     my $c = shift;
 513     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 514 }
 515
 516 # search components given a name and some prefixes
 517 sub _comp_names_search_prefixes {
 518     my ( $c, $name, @prefixes ) = @_;
 519     my $appclass = ref $c || $c;
 520     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 521     $filter = qr/$filter/; # Compile regex now rather than once per loop
 522
 523     # map the original component name to the sub part that we will search against
 524     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 525         grep { /$filter/ } keys %{ $c->components };
 526
 527     # undef for a name will return all
 528     return keys %eligible if !defined $name;
 529
 530     my $query  = ref $name ? $name : qr/^$name$/i;
 531     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 532
 533     return @result if @result;
 534
 535     # if we were given a regexp to search against, we're done.
 536     return if ref $name;
 537
 538     # regexp fallback
 539     $query  = qr/$name/i;
 540     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 541
 542     # no results? try against full names
 543     if( !@result ) {
 544         @result = grep { m{$query} } keys %eligible;
 545     }
 546
 547     # don't warn if we didn't find any results, it just might not exist
 548     if( @result ) {
 549         # Disgusting hack to work out correct method name
 550         my $warn_for = lc $prefixes[0];
 551         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 552            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 553            "component resolution is unreliable and unsafe.";
 554         my $short = $result[0];
 555         $short =~ s/.*?Model:://;
 556         my $shortmess = Carp::shortmess('');
 557         if ($shortmess =~ m#Catalyst/Plugin#) {
 558            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 559               "plugin's config";
 560         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 561            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 562               "component's config";
 563         } else {
 564            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 565               "but if you really wanted to search, pass in a regexp as the argument " .
 566               "like so: \$c->${warn_for}(qr/${name}/)";
 567         }
 568         $c->log->warn( "${msg}$shortmess" );
 569     }
 570
 571     return @result;
 572 }
 573
 574 # Find possible names for a prefix
 575 sub _comp_names {
 576     my ( $c, @prefixes ) = @_;
 577     my $appclass = ref $c || $c;
 578
 579     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 580
 581     my @names = map { s{$filter}{}; $_; }
 582         $c->_comp_names_search_prefixes( undef, @prefixes );
 583
 584     return @names;
 585 }
 586
 587 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 588 sub _filter_component {
 589     my ( $c, $comp, @args ) = @_;
 590
 591     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 592         return $comp->ACCEPT_CONTEXT( $c, @args );
 593     }
 594
 595     return $comp;
 596 }
 597
 598 =head2 COMPONENT ACCESSORS
 599
 600 =head2 $c->controller($name)
 601
 602 Gets a L<Catalyst::Controller> instance by name.
 603
 604     $c->controller('Foo')->do_stuff;
 605
 606 If the name is omitted, will return the controller for the dispatched
 607 action.
 608
 609 If you want to search for controllers, pass in a regexp as the argument.
 610
 611     # find all controllers that start with Foo
 612     my @foo_controllers = $c->controller(qr{^Foo});
 613
 614
 615 =cut
 616
 617 sub controller {
 618     my ( $c, $name, @args ) = @_;
 619
 620     if( $name ) {
 621         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 622         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 623         return $c->_filter_component( $result[ 0 ], @args );
 624     }
 625
 626     return $c->component( $c->action->class );
 627 }
 628
 629 =head2 $c->model($name)
 630
 631 Gets a L<Catalyst::Model> instance by name.
 632
 633     $c->model('Foo')->do_stuff;
 634
 635 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 636
 637 If the name is omitted, it will look for
 638  - a model object in $c->stash->{current_model_instance}, then
 639  - a model name in $c->stash->{current_model}, then
 640  - a config setting 'default_model', or
 641  - check if there is only one model, and return it if that's the case.
 642
 643 If you want to search for models, pass in a regexp as the argument.
 644
 645     # find all models that start with Foo
 646     my @foo_models = $c->model(qr{^Foo});
 647
 648 =cut
 649
 650 sub model {
 651     my ( $c, $name, @args ) = @_;
 652     my $appclass = ref($c) || $c;
 653     if( $name ) {
 654         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 655         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 656         return $c->_filter_component( $result[ 0 ], @args );
 657     }
 658
 659     if (ref $c) {
 660         return $c->stash->{current_model_instance}
 661           if $c->stash->{current_model_instance};
 662         return $c->model( $c->stash->{current_model} )
 663           if $c->stash->{current_model};
 664     }
 665     return $c->model( $appclass->config->{default_model} )
 666       if $appclass->config->{default_model};
 667
 668     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 669
 670     if( $rest ) {
 671         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 672         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 673         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 674         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 675         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 676     }
 677
 678     return $c->_filter_component( $comp );
 679 }
 680
 681
 682 =head2 $c->view($name)
 683
 684 Gets a L<Catalyst::View> instance by name.
 685
 686     $c->view('Foo')->do_stuff;
 687
 688 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 689
 690 If the name is omitted, it will look for
 691  - a view object in $c->stash->{current_view_instance}, then
 692  - a view name in $c->stash->{current_view}, then
 693  - a config setting 'default_view', or
 694  - check if there is only one view, and return it if that's the case.
 695
 696 If you want to search for views, pass in a regexp as the argument.
 697
 698     # find all views that start with Foo
 699     my @foo_views = $c->view(qr{^Foo});
 700
 701 =cut
 702
 703 sub view {
 704     my ( $c, $name, @args ) = @_;
 705
 706     my $appclass = ref($c) || $c;
 707     if( $name ) {
 708         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 709         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 710         return $c->_filter_component( $result[ 0 ], @args );
 711     }
 712
 713     if (ref $c) {
 714         return $c->stash->{current_view_instance}
 715           if $c->stash->{current_view_instance};
 716         return $c->view( $c->stash->{current_view} )
 717           if $c->stash->{current_view};
 718     }
 719     return $c->view( $appclass->config->{default_view} )
 720       if $appclass->config->{default_view};
 721
 722     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 723
 724     if( $rest ) {
 725         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 726         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 727         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 728         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 729         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 730     }
 731
 732     return $c->_filter_component( $comp );
 733 }
 734
 735 =head2 $c->controllers
 736
 737 Returns the available names which can be passed to $c->controller
 738
 739 =cut
 740
 741 sub controllers {
 742     my ( $c ) = @_;
 743     return $c->_comp_names(qw/Controller C/);
 744 }
 745
 746 =head2 $c->models
 747
 748 Returns the available names which can be passed to $c->model
 749
 750 =cut
 751
 752 sub models {
 753     my ( $c ) = @_;
 754     return $c->_comp_names(qw/Model M/);
 755 }
 756
 757
 758 =head2 $c->views
 759
 760 Returns the available names which can be passed to $c->view
 761
 762 =cut
 763
 764 sub views {
 765     my ( $c ) = @_;
 766     return $c->_comp_names(qw/View V/);
 767 }
 768
 769 =head2 $c->comp($name)
 770
 771 =head2 $c->component($name)
 772
 773 Gets a component object by name. This method is not recommended,
 774 unless you want to get a specific component by full
 775 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 776 should be used instead.
 777
 778 If C<$name> is a regexp, a list of components matched against the full
 779 component name will be returned.
 780
 781 =cut
 782
 783 sub component {
 784     my ( $c, $name, @args ) = @_;
 785
 786     if( $name ) {
 787         my $comps = $c->components;
 788
 789         if( !ref $name ) {
 790             # is it the exact name?
 791             return $c->_filter_component( $comps->{ $name }, @args )
 792                        if exists $comps->{ $name };
 793
 794             # perhaps we just omitted "MyApp"?
 795             my $composed = ( ref $c || $c ) . "::${name}";
 796             return $c->_filter_component( $comps->{ $composed }, @args )
 797                        if exists $comps->{ $composed };
 798
 799             # search all of the models, views and controllers
 800             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 801             return $c->_filter_component( $comp, @args ) if $comp;
 802         }
 803
 804         # This is here so $c->comp( '::M::' ) works
 805         my $query = ref $name ? $name : qr{$name}i;
 806
 807         my @result = grep { m{$query} } keys %{ $c->components };
 808         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 809
 810         if( $result[ 0 ] ) {
 811             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 812             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 813             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 814             return $c->_filter_component( $result[ 0 ], @args );
 815         }
 816
 817         # I would expect to return an empty list here, but that breaks back-compat
 818     }
 819
 820     # fallback
 821     return sort keys %{ $c->components };
 822 }
 823
 824 =head2 CLASS DATA AND HELPER CLASSES
 825
 826 =head2 $c->config
 827
 828 Returns or takes a hashref containing the application's configuration.
 829
 830     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 831
 832 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 833 like C<myapp.conf> in your applications home directory. See
 834 L<Catalyst::Plugin::ConfigLoader>.
 835
 836 =head3 Cascading configuration
 837
 838 The config method is present on all Catalyst components, and configuration
 839 will be merged when an application is started. Configuration loaded with
 840 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 841 followed by configuration in your top level C<MyApp> class. These two
 842 configurations are merged, and then configuration data whose hash key matches a
 843 component name is merged with configuration for that component.
 844
 845 The configuration for a component is then passed to the C<new> method when a
 846 component is constructed.
 847
 848 For example:
 849
 850     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 851     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 852
 853 will mean that C<MyApp::Model::Foo> receives the following data when
 854 constructed:
 855
 856     MyApp::Model::Foo->new({
 857         bar => 'baz',
 858         quux => 'frob',
 859         overrides => 'me',
 860     });
 861
 862 =cut
 863
 864 around config => sub {
 865     my $orig = shift;
 866     my $c = shift;
 867
 868     croak('Setting config after setup has been run is not allowed.')
 869         if ( @_ and $c->setup_finished );
 870
 871     $c->$orig(@_);
 872 };
 873
 874 =head2 $c->log
 875
 876 Returns the logging object instance. Unless it is already set, Catalyst
 877 sets this up with a L<Catalyst::Log> object. To use your own log class,
 878 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 879 C<< __PACKAGE__->setup >>.
 880
 881  __PACKAGE__->log( MyLogger->new );
 882  __PACKAGE__->setup;
 883
 884 And later:
 885
 886     $c->log->info( 'Now logging with my own logger!' );
 887
 888 Your log class should implement the methods described in
 889 L<Catalyst::Log>.
 890
 891
 892 =head2 $c->debug
 893
 894 Returns 1 if debug mode is enabled, 0 otherwise.
 895
 896 You can enable debug mode in several ways:
 897
 898 =over
 899
 900 =item By calling myapp_server.pl with the -d flag
 901
 902 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 903
 904 =item The -Debug option in your MyApp.pm
 905
 906 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 907
 908 =back
 909
 910 Calling C<< $c->debug(1) >> has no effect.
 911
 912 =cut
 913
 914 sub debug { 0 }
 915
 916 =head2 $c->dispatcher
 917
 918 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 919
 920 =head2 $c->engine
 921
 922 Returns the engine instance. See L<Catalyst::Engine>.
 923
 924
 925 =head2 UTILITY METHODS
 926
 927 =head2 $c->path_to(@path)
 928
 929 Merges C<@path> with C<< $c->config->{home} >> and returns a
 930 L<Path::Class::Dir> object. Note you can usually use this object as
 931 a filename, but sometimes you will have to explicitly stringify it
 932 yourself by calling the C<< ->stringify >> method.
 933
 934 For example:
 935
 936     $c->path_to( 'db', 'sqlite.db' );
 937
 938 =cut
 939
 940 sub path_to {
 941     my ( $c, @path ) = @_;
 942     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 943     if ( -d $path ) { return $path }
 944     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 945 }
 946
 947 =head2 $c->plugin( $name, $class, @args )
 948
 949 Helper method for plugins. It creates a class data accessor/mutator and
 950 loads and instantiates the given class.
 951
 952     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 953
 954     $c->prototype->define_javascript_functions;
 955
 956 B<Note:> This method of adding plugins is deprecated. The ability
 957 to add plugins like this B<will be removed> in a Catalyst 5.81.
 958 Please do not use this functionality in new code.
 959
 960 =cut
 961
 962 sub plugin {
 963     my ( $class, $name, $plugin, @args ) = @_;
 964
 965     # See block comment in t/unit_core_plugin.t
 966     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 967
 968     $class->_register_plugin( $plugin, 1 );
 969
 970     eval { $plugin->import };
 971     $class->mk_classdata($name);
 972     my $obj;
 973     eval { $obj = $plugin->new(@args) };
 974
 975     if ($@) {
 976         Catalyst::Exception->throw( message =>
 977               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 978     }
 979
 980     $class->$name($obj);
 981     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 982       if $class->debug;
 983 }
 984
 985 =head2 MyApp->setup
 986
 987 Initializes the dispatcher and engine, loads any plugins, and loads the
 988 model, view, and controller components. You may also specify an array
 989 of plugins to load here, if you choose to not load them in the C<use
 990 Catalyst> line.
 991
 992     MyApp->setup;
 993     MyApp->setup( qw/-Debug/ );
 994
 995 =cut
 996
 997 sub setup {
 998     my ( $class, @arguments ) = @_;
 999     croak('Running setup more than once')
1000         if ( $class->setup_finished );
1001
1002     unless ( $class->isa('Catalyst') ) {
1003
1004         Catalyst::Exception->throw(
1005             message => qq/'$class' does not inherit from Catalyst/ );
1006     }
1007
1008     if ( $class->arguments ) {
1009         @arguments = ( @arguments, @{ $class->arguments } );
1010     }
1011
1012     # Process options
1013     my $flags = {};
1014
1015     foreach (@arguments) {
1016
1017         if (/^-Debug$/) {
1018             $flags->{log} =
1019               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1020         }
1021         elsif (/^-(\w+)=?(.*)$/) {
1022             $flags->{ lc $1 } = $2;
1023         }
1024         else {
1025             push @{ $flags->{plugins} }, $_;
1026         }
1027     }
1028
1029     $class->setup_home( delete $flags->{home} );
1030
1031     $class->setup_log( delete $flags->{log} );
1032     $class->setup_plugins( delete $flags->{plugins} );
1033     $class->setup_dispatcher( delete $flags->{dispatcher} );
1034     $class->setup_engine( delete $flags->{engine} );
1035     $class->setup_stats( delete $flags->{stats} );
1036
1037     for my $flag ( sort keys %{$flags} ) {
1038
1039         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1040             &$code( $class, delete $flags->{$flag} );
1041         }
1042         else {
1043             $class->log->warn(qq/Unknown flag "$flag"/);
1044         }
1045     }
1046
1047     eval { require Catalyst::Devel; };
1048     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1049         $class->log->warn(<<"EOF");
1050 You are running an old script!
1051
1052   Please update by running (this will overwrite existing files):
1053     catalyst.pl -force -scripts $class
1054
1055   or (this will not overwrite existing files):
1056     catalyst.pl -scripts $class
1057
1058 EOF
1059     }
1060
1061     if ( $class->debug ) {
1062         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1063
1064         if (@plugins) {
1065             my $column_width = Catalyst::Utils::term_width() - 6;
1066             my $t = Text::SimpleTable->new($column_width);
1067             $t->row($_) for @plugins;
1068             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1069         }
1070
1071         my $dispatcher = $class->dispatcher;
1072         my $engine     = $class->engine;
1073         my $home       = $class->config->{home};
1074
1075         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1076         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1077
1078         $home
1079           ? ( -d $home )
1080           ? $class->log->debug(qq/Found home "$home"/)
1081           : $class->log->debug(qq/Home "$home" doesn't exist/)
1082           : $class->log->debug(q/Couldn't find home/);
1083     }
1084
1085     # Call plugins setup, this is stupid and evil.
1086     # Also screws C3 badly on 5.10, hack to avoid.
1087     {
1088         no warnings qw/redefine/;
1089         local *setup = sub { };
1090         $class->setup unless $Catalyst::__AM_RESTARTING;
1091     }
1092
1093     # Initialize our data structure
1094     $class->components( {} );
1095
1096     $class->setup_components;
1097
1098     if ( $class->debug ) {
1099         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1100         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1101         for my $comp ( sort keys %{ $class->components } ) {
1102             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1103             $t->row( $comp, $type );
1104         }
1105         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1106           if ( keys %{ $class->components } );
1107     }
1108
1109     # Add our self to components, since we are also a component
1110     if( $class->isa('Catalyst::Controller') ){
1111       $class->components->{$class} = $class;
1112     }
1113
1114     $class->setup_actions;
1115
1116     if ( $class->debug ) {
1117         my $name = $class->config->{name} || 'Application';
1118         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1119     }
1120     $class->log->_flush() if $class->log->can('_flush');
1121
1122     # Make sure that the application class becomes immutable at this point,
1123     B::Hooks::EndOfScope::on_scope_end {
1124         return if $@;
1125         my $meta = Class::MOP::get_metaclass_by_name($class);
1126         if (
1127             $meta->is_immutable
1128             && ! { $meta->immutable_options }->{replace_constructor}
1129             && (
1130                    $class->isa('Class::Accessor::Fast')
1131                 || $class->isa('Class::Accessor')
1132             )
1133         ) {
1134             warn "You made your application class ($class) immutable, "
1135                 . "but did not inline the\nconstructor. "
1136                 . "This will break catalyst, as your app \@ISA "
1137                 . "Class::Accessor(::Fast)?\nPlease pass "
1138                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1139         }
1140         $meta->make_immutable(
1141             replace_constructor => 1,
1142             allow_mutable_ancestors => 1,
1143         ) unless $meta->is_immutable;
1144     };
1145
1146     $class->setup_finalize;
1147 }
1148
1149
1150 =head2 $app->setup_finalize
1151
1152 A hook to attach modifiers to.
1153 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1154 Also better than C< setup_finished(); >, as that is a getter method.
1155
1156     sub setup_finalize {
1157
1158         my $app = shift;
1159
1160         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1161
1162         $app->next::method(@_);
1163
1164
1165     }
1166
1167 =cut
1168
1169 sub setup_finalize {
1170     my ($class) = @_;
1171     $class->setup_finished(1);
1172 }
1173
1174 =head2 $c->uri_for( $path, @args?, \%query_values? )
1175
1176 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1177
1178 Constructs an absolute L<URI> object based on the application root, the
1179 provided path, and the additional arguments and query parameters provided.
1180 When used as a string, provides a textual URI.
1181
1182 If the first argument is a string, it is taken as a public URI path relative
1183 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1184 relative to the application root (if it does). It is then merged with
1185 C<< $c->request->base >>; any C<@args> are appended as additional path
1186 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1187
1188 If the first argument is a L<Catalyst::Action> it represents an action which
1189 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1190 optional C<\@captures> argument (an arrayref) allows passing the captured
1191 variables that are needed to fill in the paths of Chained and Regex actions;
1192 once the path is resolved, C<uri_for> continues as though a path was
1193 provided, appending any arguments or parameters and creating an absolute
1194 URI.
1195
1196 The captures for the current request can be found in
1197 C<< $c->request->captures >>, and actions can be resolved using
1198 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1199 path, use C<< $c->uri_for_action >> instead.
1200
1201   # Equivalent to $c->req->uri
1202   $c->uri_for($c->action, $c->req->captures,
1203       @{ $c->req->args }, $c->req->params);
1204
1205   # For the Foo action in the Bar controller
1206   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1207
1208   # Path to a static resource
1209   $c->uri_for('/static/images/logo.png');
1210
1211 =cut
1212
1213 sub uri_for {
1214     my ( $c, $path, @args ) = @_;
1215
1216     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1217         $path = $path->path_prefix;
1218         $path =~ s{/+\z}{};
1219         $path .= '/';
1220     }
1221
1222     if ( blessed($path) ) { # action object
1223         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1224                          ? shift(@args)
1225                          : [] );
1226         my $action = $path;
1227         $path = $c->dispatcher->uri_for_action($action, $captures);
1228         if (not defined $path) {
1229             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1230                 if $c->debug;
1231             return undef;
1232         }
1233         $path = '/' if $path eq '';
1234     }
1235
1236     undef($path) if (defined $path && $path eq '');
1237
1238     my $params =
1239       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1240
1241     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1242     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1243
1244     unshift(@args, $path);
1245
1246     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1247         my $namespace = $c->namespace;
1248         if (defined $path) { # cheesy hack to handle path '../foo'
1249            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1250         }
1251         unshift(@args, $namespace || '');
1252     }
1253
1254     # join args with '/', or a blank string
1255     my $args = join('/', grep { defined($_) } @args);
1256     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1257     $args =~ s!^/+!!;
1258     my $base = $c->req->base;
1259     my $class = ref($base);
1260     $base =~ s{(?<!/)$}{/};
1261
1262     my $query = '';
1263
1264     if (my @keys = keys %$params) {
1265       # somewhat lifted from URI::_query's query_form
1266       $query = '?'.join('&', map {
1267           my $val = $params->{$_};
1268           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1269           s/ /+/g;
1270           my $key = $_;
1271           $val = '' unless defined $val;
1272           (map {
1273               my $param = "$_";
1274               utf8::encode( $param ) if utf8::is_utf8($param);
1275               # using the URI::Escape pattern here so utf8 chars survive
1276               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1277               $param =~ s/ /+/g;
1278               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1279       } @keys);
1280     }
1281
1282     my $res = bless(\"${base}${args}${query}", $class);
1283     $res;
1284 }
1285
1286 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1287
1288 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1289
1290 =over
1291
1292 =item $path
1293
1294 A private path to the Catalyst action you want to create a URI for.
1295
1296 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1297 >> and passing the resulting C<$action> and the remaining arguments to C<<
1298 $c->uri_for >>.
1299
1300 You can also pass in a Catalyst::Action object, in which case it is passed to
1301 C<< $c->uri_for >>.
1302
1303 =back
1304
1305 =cut
1306
1307 sub uri_for_action {
1308     my ( $c, $path, @args ) = @_;
1309     my $action = blessed($path)
1310       ? $path
1311       : $c->dispatcher->get_action_by_path($path);
1312     unless (defined $action) {
1313       croak "Can't find action for path '$path'";
1314     }
1315     return $c->uri_for( $action, @args );
1316 }
1317
1318 =head2 $c->welcome_message
1319
1320 Returns the Catalyst welcome HTML page.
1321
1322 =cut
1323
1324 sub welcome_message {
1325     my $c      = shift;
1326     my $name   = $c->config->{name};
1327     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1328     my $prefix = Catalyst::Utils::appprefix( ref $c );
1329     $c->response->content_type('text/html; charset=utf-8');
1330     return <<"EOF";
1331 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1332     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1333 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1334     <head>
1335     <meta http-equiv="Content-Language" content="en" />
1336     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1337         <title>$name on Catalyst $VERSION</title>
1338         <style type="text/css">
1339             body {
1340                 color: #000;
1341                 background-color: #eee;
1342             }
1343             div#content {
1344                 width: 640px;
1345                 margin-left: auto;
1346                 margin-right: auto;
1347                 margin-top: 10px;
1348                 margin-bottom: 10px;
1349                 text-align: left;
1350                 background-color: #ccc;
1351                 border: 1px solid #aaa;
1352             }
1353             p, h1, h2 {
1354                 margin-left: 20px;
1355                 margin-right: 20px;
1356                 font-family: verdana, tahoma, sans-serif;
1357             }
1358             a {
1359                 font-family: verdana, tahoma, sans-serif;
1360             }
1361             :link, :visited {
1362                     text-decoration: none;
1363                     color: #b00;
1364                     border-bottom: 1px dotted #bbb;
1365             }
1366             :link:hover, :visited:hover {
1367                     color: #555;
1368             }
1369             div#topbar {
1370                 margin: 0px;
1371             }
1372             pre {
1373                 margin: 10px;
1374                 padding: 8px;
1375             }
1376             div#answers {
1377                 padding: 8px;
1378                 margin: 10px;
1379                 background-color: #fff;
1380                 border: 1px solid #aaa;
1381             }
1382             h1 {
1383                 font-size: 0.9em;
1384                 font-weight: normal;
1385                 text-align: center;
1386             }
1387             h2 {
1388                 font-size: 1.0em;
1389             }
1390             p {
1391                 font-size: 0.9em;
1392             }
1393             p img {
1394                 float: right;
1395                 margin-left: 10px;
1396             }
1397             span#appname {
1398                 font-weight: bold;
1399                 font-size: 1.6em;
1400             }
1401         </style>
1402     </head>
1403     <body>
1404         <div id="content">
1405             <div id="topbar">
1406                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1407                     $VERSION</h1>
1408              </div>
1409              <div id="answers">
1410                  <p>
1411                  <img src="$logo" alt="Catalyst Logo" />
1412                  </p>
1413                  <p>Welcome to the  world of Catalyst.
1414                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1415                     framework will make web development something you had
1416                     never expected it to be: Fun, rewarding, and quick.</p>
1417                  <h2>What to do now?</h2>
1418                  <p>That really depends  on what <b>you</b> want to do.
1419                     We do, however, provide you with a few starting points.</p>
1420                  <p>If you want to jump right into web development with Catalyst
1421                     you might want to start with a tutorial.</p>
1422 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1423 </pre>
1424 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1425 <pre>
1426 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1427 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1428 </code></pre>
1429                  <h2>What to do next?</h2>
1430                  <p>Next it's time to write an actual application. Use the
1431                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1432                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1433                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1434                     they can save you a lot of work.</p>
1435                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1436                     <p>Also, be sure to check out the vast and growing
1437                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1438                     you are likely to find what you need there.
1439                     </p>
1440
1441                  <h2>Need help?</h2>
1442                  <p>Catalyst has a very active community. Here are the main places to
1443                     get in touch with us.</p>
1444                  <ul>
1445                      <li>
1446                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1447                      </li>
1448                      <li>
1449                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1450                      </li>
1451                      <li>
1452                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1453                      </li>
1454                  </ul>
1455                  <h2>In conclusion</h2>
1456                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1457                     as we enjoyed making it. Please contact us if you have ideas
1458                     for improvement or other feedback.</p>
1459              </div>
1460          </div>
1461     </body>
1462 </html>
1463 EOF
1464 }
1465
1466 =head1 INTERNAL METHODS
1467
1468 These methods are not meant to be used by end users.
1469
1470 =head2 $c->components
1471
1472 Returns a hash of components.
1473
1474 =head2 $c->context_class
1475
1476 Returns or sets the context class.
1477
1478 =head2 $c->counter
1479
1480 Returns a hashref containing coderefs and execution counts (needed for
1481 deep recursion detection).
1482
1483 =head2 $c->depth
1484
1485 Returns the number of actions on the current internal execution stack.
1486
1487 =head2 $c->dispatch
1488
1489 Dispatches a request to actions.
1490
1491 =cut
1492
1493 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1494
1495 =head2 $c->dispatcher_class
1496
1497 Returns or sets the dispatcher class.
1498
1499 =head2 $c->dump_these
1500
1501 Returns a list of 2-element array references (name, structure) pairs
1502 that will be dumped on the error page in debug mode.
1503
1504 =cut
1505
1506 sub dump_these {
1507     my $c = shift;
1508     [ Request => $c->req ],
1509     [ Response => $c->res ],
1510     [ Stash => $c->stash ],
1511     [ Config => $c->config ];
1512 }
1513
1514 =head2 $c->engine_class
1515
1516 Returns or sets the engine class.
1517
1518 =head2 $c->execute( $class, $coderef )
1519
1520 Execute a coderef in given class and catch exceptions. Errors are available
1521 via $c->error.
1522
1523 =cut
1524
1525 sub execute {
1526     my ( $c, $class, $code ) = @_;
1527     $class = $c->component($class) || $class;
1528     $c->state(0);
1529
1530     if ( $c->depth >= $RECURSION ) {
1531         my $action = $code->reverse();
1532         $action = "/$action" unless $action =~ /->/;
1533         my $error = qq/Deep recursion detected calling "${action}"/;
1534         $c->log->error($error);
1535         $c->error($error);
1536         $c->state(0);
1537         return $c->state;
1538     }
1539
1540     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1541
1542     push( @{ $c->stack }, $code );
1543
1544     no warnings 'recursion';
1545     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1546
1547     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1548
1549     my $last = pop( @{ $c->stack } );
1550
1551     if ( my $error = $@ ) {
1552         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1553             $error->rethrow if $c->depth > 1;
1554         }
1555         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1556             $error->rethrow if $c->depth > 0;
1557         }
1558         else {
1559             unless ( ref $error ) {
1560                 no warnings 'uninitialized';
1561                 chomp $error;
1562                 my $class = $last->class;
1563                 my $name  = $last->name;
1564                 $error = qq/Caught exception in $class->$name "$error"/;
1565             }
1566             $c->error($error);
1567             $c->state(0);
1568         }
1569     }
1570     return $c->state;
1571 }
1572
1573 sub _stats_start_execute {
1574     my ( $c, $code ) = @_;
1575     my $appclass = ref($c) || $c;
1576     return if ( ( $code->name =~ /^_.*/ )
1577         && ( !$appclass->config->{show_internal_actions} ) );
1578
1579     my $action_name = $code->reverse();
1580     $c->counter->{$action_name}++;
1581
1582     my $action = $action_name;
1583     $action = "/$action" unless $action =~ /->/;
1584
1585     # determine if the call was the result of a forward
1586     # this is done by walking up the call stack and looking for a calling
1587     # sub of Catalyst::forward before the eval
1588     my $callsub = q{};
1589     for my $index ( 2 .. 11 ) {
1590         last
1591         if ( ( caller($index) )[0] eq 'Catalyst'
1592             && ( caller($index) )[3] eq '(eval)' );
1593
1594         if ( ( caller($index) )[3] =~ /forward$/ ) {
1595             $callsub = ( caller($index) )[3];
1596             $action  = "-> $action";
1597             last;
1598         }
1599     }
1600
1601     my $uid = $action_name . $c->counter->{$action_name};
1602
1603     # is this a root-level call or a forwarded call?
1604     if ( $callsub =~ /forward$/ ) {
1605
1606         # forward, locate the caller
1607         if ( my $parent = $c->stack->[-1] ) {
1608             $c->stats->profile(
1609                 begin  => $action,
1610                 parent => "$parent" . $c->counter->{"$parent"},
1611                 uid    => $uid,
1612             );
1613         }
1614         else {
1615
1616             # forward with no caller may come from a plugin
1617             $c->stats->profile(
1618                 begin => $action,
1619                 uid   => $uid,
1620             );
1621         }
1622     }
1623     else {
1624
1625         # root-level call
1626         $c->stats->profile(
1627             begin => $action,
1628             uid   => $uid,
1629         );
1630     }
1631     return $action;
1632
1633 }
1634
1635 sub _stats_finish_execute {
1636     my ( $c, $info ) = @_;
1637     $c->stats->profile( end => $info );
1638 }
1639
1640 =head2 $c->finalize
1641
1642 Finalizes the request.
1643
1644 =cut
1645
1646 sub finalize {
1647     my $c = shift;
1648
1649     for my $error ( @{ $c->error } ) {
1650         $c->log->error($error);
1651     }
1652
1653     # Allow engine to handle finalize flow (for POE)
1654     my $engine = $c->engine;
1655     if ( my $code = $engine->can('finalize') ) {
1656         $engine->$code($c);
1657     }
1658     else {
1659
1660         $c->finalize_uploads;
1661
1662         # Error
1663         if ( $#{ $c->error } >= 0 ) {
1664             $c->finalize_error;
1665         }
1666
1667         $c->finalize_headers;
1668
1669         # HEAD request
1670         if ( $c->request->method eq 'HEAD' ) {
1671             $c->response->body('');
1672         }
1673
1674         $c->finalize_body;
1675     }
1676
1677     if ($c->use_stats) {
1678         my $elapsed = sprintf '%f', $c->stats->elapsed;
1679         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1680         $c->log->info(
1681             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1682     }
1683
1684     return $c->response->status;
1685 }
1686
1687 =head2 $c->finalize_body
1688
1689 Finalizes body.
1690
1691 =cut
1692
1693 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1694
1695 =head2 $c->finalize_cookies
1696
1697 Finalizes cookies.
1698
1699 =cut
1700
1701 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1702
1703 =head2 $c->finalize_error
1704
1705 Finalizes error.
1706
1707 =cut
1708
1709 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1710
1711 =head2 $c->finalize_headers
1712
1713 Finalizes headers.
1714
1715 =cut
1716
1717 sub finalize_headers {
1718     my $c = shift;
1719
1720     my $response = $c->response; #accessor calls can add up?
1721
1722     # Check if we already finalized headers
1723     return if $response->finalized_headers;
1724
1725     # Handle redirects
1726     if ( my $location = $response->redirect ) {
1727         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1728         $response->header( Location => $location );
1729
1730         if ( !$response->has_body ) {
1731             # Add a default body if none is already present
1732             $response->body(
1733                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1734             );
1735         }
1736     }
1737
1738     # Content-Length
1739     if ( $response->body && !$response->content_length ) {
1740
1741         # get the length from a filehandle
1742         if ( blessed( $response->body ) && $response->body->can('read') )
1743         {
1744             my $stat = stat $response->body;
1745             if ( $stat && $stat->size > 0 ) {
1746                 $response->content_length( $stat->size );
1747             }
1748             else {
1749                 $c->log->warn('Serving filehandle without a content-length');
1750             }
1751         }
1752         else {
1753             # everything should be bytes at this point, but just in case
1754             $response->content_length( bytes::length( $response->body ) );
1755         }
1756     }
1757
1758     # Errors
1759     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1760         $response->headers->remove_header("Content-Length");
1761         $response->body('');
1762     }
1763
1764     $c->finalize_cookies;
1765
1766     $c->engine->finalize_headers( $c, @_ );
1767
1768     # Done
1769     $response->finalized_headers(1);
1770 }
1771
1772 =head2 $c->finalize_output
1773
1774 An alias for finalize_body.
1775
1776 =head2 $c->finalize_read
1777
1778 Finalizes the input after reading is complete.
1779
1780 =cut
1781
1782 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1783
1784 =head2 $c->finalize_uploads
1785
1786 Finalizes uploads. Cleans up any temporary files.
1787
1788 =cut
1789
1790 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1791
1792 =head2 $c->get_action( $action, $namespace )
1793
1794 Gets an action in a given namespace.
1795
1796 =cut
1797
1798 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1799
1800 =head2 $c->get_actions( $action, $namespace )
1801
1802 Gets all actions of a given name in a namespace and all parent
1803 namespaces.
1804
1805 =cut
1806
1807 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1808
1809 =head2 $c->handle_request( $class, @arguments )
1810
1811 Called to handle each HTTP request.
1812
1813 =cut
1814
1815 sub handle_request {
1816     my ( $class, @arguments ) = @_;
1817
1818     # Always expect worst case!
1819     my $status = -1;
1820     eval {
1821         if ($class->debug) {
1822             my $secs = time - $START || 1;
1823             my $av = sprintf '%.3f', $COUNT / $secs;
1824             my $time = localtime time;
1825             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1826         }
1827
1828         my $c = $class->prepare(@arguments);
1829         $c->dispatch;
1830         $status = $c->finalize;
1831     };
1832
1833     if ( my $error = $@ ) {
1834         chomp $error;
1835         $class->log->error(qq/Caught exception in engine "$error"/);
1836     }
1837
1838     $COUNT++;
1839
1840     if(my $coderef = $class->log->can('_flush')){
1841         $class->log->$coderef();
1842     }
1843     return $status;
1844 }
1845
1846 =head2 $c->prepare( @arguments )
1847
1848 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1849 etc.).
1850
1851 =cut
1852
1853 sub prepare {
1854     my ( $class, @arguments ) = @_;
1855
1856     # XXX
1857     # After the app/ctxt split, this should become an attribute based on something passed
1858     # into the application.
1859     $class->context_class( ref $class || $class ) unless $class->context_class;
1860
1861     my $c = $class->context_class->new({});
1862
1863     # For on-demand data
1864     $c->request->_context($c);
1865     $c->response->_context($c);
1866
1867     #surely this is not the most efficient way to do things...
1868     $c->stats($class->stats_class->new)->enable($c->use_stats);
1869     if ( $c->debug ) {
1870         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1871     }
1872
1873     #XXX reuse coderef from can
1874     # Allow engine to direct the prepare flow (for POE)
1875     if ( $c->engine->can('prepare') ) {
1876         $c->engine->prepare( $c, @arguments );
1877     }
1878     else {
1879         $c->prepare_request(@arguments);
1880         $c->prepare_connection;
1881         $c->prepare_query_parameters;
1882         $c->prepare_headers;
1883         $c->prepare_cookies;
1884         $c->prepare_path;
1885
1886         # Prepare the body for reading, either by prepare_body
1887         # or the user, if they are using $c->read
1888         $c->prepare_read;
1889
1890         # Parse the body unless the user wants it on-demand
1891         unless ( ref($c)->config->{parse_on_demand} ) {
1892             $c->prepare_body;
1893         }
1894     }
1895
1896     my $method  = $c->req->method  || '';
1897     my $path    = $c->req->path;
1898     $path       = '/' unless length $path;
1899     my $address = $c->req->address || '';
1900
1901     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1902       if $c->debug;
1903
1904     $c->prepare_action;
1905
1906     return $c;
1907 }
1908
1909 =head2 $c->prepare_action
1910
1911 Prepares action. See L<Catalyst::Dispatcher>.
1912
1913 =cut
1914
1915 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1916
1917 =head2 $c->prepare_body
1918
1919 Prepares message body.
1920
1921 =cut
1922
1923 sub prepare_body {
1924     my $c = shift;
1925
1926     return if $c->request->_has_body;
1927
1928     # Initialize on-demand data
1929     $c->engine->prepare_body( $c, @_ );
1930     $c->prepare_parameters;
1931     $c->prepare_uploads;
1932
1933     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1934         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1935         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1936             my $param = $c->req->body_parameters->{$key};
1937             my $value = defined($param) ? $param : '';
1938             $t->row( $key,
1939                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1940         }
1941         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1942     }
1943 }
1944
1945 =head2 $c->prepare_body_chunk( $chunk )
1946
1947 Prepares a chunk of data before sending it to L<HTTP::Body>.
1948
1949 See L<Catalyst::Engine>.
1950
1951 =cut
1952
1953 sub prepare_body_chunk {
1954     my $c = shift;
1955     $c->engine->prepare_body_chunk( $c, @_ );
1956 }
1957
1958 =head2 $c->prepare_body_parameters
1959
1960 Prepares body parameters.
1961
1962 =cut
1963
1964 sub prepare_body_parameters {
1965     my $c = shift;
1966     $c->engine->prepare_body_parameters( $c, @_ );
1967 }
1968
1969 =head2 $c->prepare_connection
1970
1971 Prepares connection.
1972
1973 =cut
1974
1975 sub prepare_connection {
1976     my $c = shift;
1977     $c->engine->prepare_connection( $c, @_ );
1978 }
1979
1980 =head2 $c->prepare_cookies
1981
1982 Prepares cookies.
1983
1984 =cut
1985
1986 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1987
1988 =head2 $c->prepare_headers
1989
1990 Prepares headers.
1991
1992 =cut
1993
1994 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1995
1996 =head2 $c->prepare_parameters
1997
1998 Prepares parameters.
1999
2000 =cut
2001
2002 sub prepare_parameters {
2003     my $c = shift;
2004     $c->prepare_body_parameters;
2005     $c->engine->prepare_parameters( $c, @_ );
2006 }
2007
2008 =head2 $c->prepare_path
2009
2010 Prepares path and base.
2011
2012 =cut
2013
2014 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2015
2016 =head2 $c->prepare_query_parameters
2017
2018 Prepares query parameters.
2019
2020 =cut
2021
2022 sub prepare_query_parameters {
2023     my $c = shift;
2024
2025     $c->engine->prepare_query_parameters( $c, @_ );
2026
2027     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
2028         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
2029         for my $key ( sort keys %{ $c->req->query_parameters } ) {
2030             my $param = $c->req->query_parameters->{$key};
2031             my $value = defined($param) ? $param : '';
2032             $t->row( $key,
2033                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2034         }
2035         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2036     }
2037 }
2038
2039 =head2 $c->prepare_read
2040
2041 Prepares the input for reading.
2042
2043 =cut
2044
2045 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2046
2047 =head2 $c->prepare_request
2048
2049 Prepares the engine request.
2050
2051 =cut
2052
2053 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2054
2055 =head2 $c->prepare_uploads
2056
2057 Prepares uploads.
2058
2059 =cut
2060
2061 sub prepare_uploads {
2062     my $c = shift;
2063
2064     $c->engine->prepare_uploads( $c, @_ );
2065
2066     if ( $c->debug && keys %{ $c->request->uploads } ) {
2067         my $t = Text::SimpleTable->new(
2068             [ 12, 'Parameter' ],
2069             [ 26, 'Filename' ],
2070             [ 18, 'Type' ],
2071             [ 9,  'Size' ]
2072         );
2073         for my $key ( sort keys %{ $c->request->uploads } ) {
2074             my $upload = $c->request->uploads->{$key};
2075             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2076                 $t->row( $key, $u->filename, $u->type, $u->size );
2077             }
2078         }
2079         $c->log->debug( "File Uploads are:\n" . $t->draw );
2080     }
2081 }
2082
2083 =head2 $c->prepare_write
2084
2085 Prepares the output for writing.
2086
2087 =cut
2088
2089 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2090
2091 =head2 $c->request_class
2092
2093 Returns or sets the request class.
2094
2095 =head2 $c->response_class
2096
2097 Returns or sets the response class.
2098
2099 =head2 $c->read( [$maxlength] )
2100
2101 Reads a chunk of data from the request body. This method is designed to
2102 be used in a while loop, reading C<$maxlength> bytes on every call.
2103 C<$maxlength> defaults to the size of the request if not specified.
2104
2105 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2106 directly.
2107
2108 Warning: If you use read(), Catalyst will not process the body,
2109 so you will not be able to access POST parameters or file uploads via
2110 $c->request.  You must handle all body parsing yourself.
2111
2112 =cut
2113
2114 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2115
2116 =head2 $c->run
2117
2118 Starts the engine.
2119
2120 =cut
2121
2122 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2123
2124 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2125
2126 Sets an action in a given namespace.
2127
2128 =cut
2129
2130 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2131
2132 =head2 $c->setup_actions($component)
2133
2134 Sets up actions for a component.
2135
2136 =cut
2137
2138 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2139
2140 =head2 $c->setup_components
2141
2142 This method is called internally to set up the application's components.
2143
2144 It finds modules by calling the L<locate_components> method, expands them to
2145 package names with the L<expand_component_module> method, and then installs
2146 each component into the application.
2147
2148 The C<setup_components> config option is passed to both of the above methods.
2149
2150 Installation of each component is performed by the L<setup_component> method,
2151 below.
2152
2153 =cut
2154
2155 sub setup_components {
2156     my $class = shift;
2157
2158     my $config  = $class->config->{ setup_components };
2159
2160     my @comps = sort { length $a <=> length $b }
2161                 $class->locate_components($config);
2162     my %comps = map { $_ => 1 } @comps;
2163
2164     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2165     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2166         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2167     ) if $deprecatedcatalyst_component_names;
2168
2169     for my $component ( @comps ) {
2170
2171         # We pass ignore_loaded here so that overlay files for (e.g.)
2172         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2173         # we know M::P::O found a file on disk so this is safe
2174
2175         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2176
2177         # Needs to be done as soon as the component is loaded, as loading a sub-component
2178         # (next time round the loop) can cause us to get the wrong metaclass..
2179         $class->_controller_init_base_classes($component);
2180     }
2181
2182     for my $component (@comps) {
2183         $class->components->{ $component } = $class->setup_component($component);
2184         for my $component ($class->expand_component_module( $component, $config )) {
2185             next if $comps{$component};
2186             $class->_controller_init_base_classes($component); # Also cover inner packages
2187             $class->components->{ $component } = $class->setup_component($component);
2188         }
2189     }
2190 }
2191
2192 =head2 $c->locate_components( $setup_component_config )
2193
2194 This method is meant to provide a list of component modules that should be
2195 setup for the application.  By default, it will use L<Module::Pluggable>.
2196
2197 Specify a C<setup_components> config option to pass additional options directly
2198 to L<Module::Pluggable>. To add additional search paths, specify a key named
2199 C<search_extra> as an array reference. Items in the array beginning with C<::>
2200 will have the application class name prepended to them.
2201
2202 =cut
2203
2204 sub locate_components {
2205     my $class  = shift;
2206     my $config = shift;
2207
2208     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2209     my $extra   = delete $config->{ search_extra } || [];
2210
2211     push @paths, @$extra;
2212
2213     my $locator = Module::Pluggable::Object->new(
2214         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2215         %$config
2216     );
2217
2218     my @comps = $locator->plugins;
2219
2220     return @comps;
2221 }
2222
2223 =head2 $c->expand_component_module( $component, $setup_component_config )
2224
2225 Components found by C<locate_components> will be passed to this method, which
2226 is expected to return a list of component (package) names to be set up.
2227
2228 =cut
2229
2230 sub expand_component_module {
2231     my ($class, $module) = @_;
2232     return Devel::InnerPackage::list_packages( $module );
2233 }
2234
2235 =head2 $c->setup_component
2236
2237 =cut
2238
2239 # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2240 #         nearest to Catalyst::Controller first, no matter what order stuff happens
2241 #         to be loaded. There are TODO tests in Moose for this, see
2242 #         f2391d17574eff81d911b97be15ea51080500003
2243 sub _controller_init_base_classes {
2244     my ($app_class, $component) = @_;
2245     return unless $component->isa('Catalyst::Controller');
2246     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2247         Moose::Meta::Class->initialize( $class )
2248             unless find_meta($class);
2249     }
2250 }
2251
2252 sub setup_component {
2253     my( $class, $component ) = @_;
2254
2255     unless ( $component->can( 'COMPONENT' ) ) {
2256         return $component;
2257     }
2258
2259     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2260     my $config = $class->config->{ $suffix } || {};
2261     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2262     # methods also pass it. local to avoid pointlessly shitting in config
2263     # for the debug screen, as $component is already the key name.
2264     local $config->{catalyst_component_name} = $component;
2265
2266     my $instance = eval { $component->COMPONENT( $class, $config ); };
2267
2268     if ( my $error = $@ ) {
2269         chomp $error;
2270         Catalyst::Exception->throw(
2271             message => qq/Couldn't instantiate component "$component", "$error"/
2272         );
2273     }
2274
2275     unless (blessed $instance) {
2276         my $metaclass = Moose::Util::find_meta($component);
2277         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2278         my $component_method_from = $method_meta->associated_metaclass->name;
2279         my $value = defined($instance) ? $instance : 'undef';
2280         Catalyst::Exception->throw(
2281             message =>
2282             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2283         );
2284     }
2285     return $instance;
2286 }
2287
2288 =head2 $c->setup_dispatcher
2289
2290 Sets up dispatcher.
2291
2292 =cut
2293
2294 sub setup_dispatcher {
2295     my ( $class, $dispatcher ) = @_;
2296
2297     if ($dispatcher) {
2298         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2299     }
2300
2301     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2302         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2303     }
2304
2305     unless ($dispatcher) {
2306         $dispatcher = $class->dispatcher_class;
2307     }
2308
2309     Class::MOP::load_class($dispatcher);
2310
2311     # dispatcher instance
2312     $class->dispatcher( $dispatcher->new );
2313 }
2314
2315 =head2 $c->setup_engine
2316
2317 Sets up engine.
2318
2319 =cut
2320
2321 sub setup_engine {
2322     my ( $class, $engine ) = @_;
2323
2324     if ($engine) {
2325         $engine = 'Catalyst::Engine::' . $engine;
2326     }
2327
2328     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2329         $engine = 'Catalyst::Engine::' . $env;
2330     }
2331
2332     if ( $ENV{MOD_PERL} ) {
2333         my $meta = Class::MOP::get_metaclass_by_name($class);
2334
2335         # create the apache method
2336         $meta->add_method('apache' => sub { shift->engine->apache });
2337
2338         my ( $software, $version ) =
2339           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2340
2341         $version =~ s/_//g;
2342         $version =~ s/(\.[^.]+)\./$1/g;
2343
2344         if ( $software eq 'mod_perl' ) {
2345
2346             if ( !$engine ) {
2347
2348                 if ( $version >= 1.99922 ) {
2349                     $engine = 'Catalyst::Engine::Apache2::MP20';
2350                 }
2351
2352                 elsif ( $version >= 1.9901 ) {
2353                     $engine = 'Catalyst::Engine::Apache2::MP19';
2354                 }
2355
2356                 elsif ( $version >= 1.24 ) {
2357                     $engine = 'Catalyst::Engine::Apache::MP13';
2358                 }
2359
2360                 else {
2361                     Catalyst::Exception->throw( message =>
2362                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2363                 }
2364
2365             }
2366
2367             # install the correct mod_perl handler
2368             if ( $version >= 1.9901 ) {
2369                 *handler = sub  : method {
2370                     shift->handle_request(@_);
2371                 };
2372             }
2373             else {
2374                 *handler = sub ($$) { shift->handle_request(@_) };
2375             }
2376
2377         }
2378
2379         elsif ( $software eq 'Zeus-Perl' ) {
2380             $engine = 'Catalyst::Engine::Zeus';
2381         }
2382
2383         else {
2384             Catalyst::Exception->throw(
2385                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2386         }
2387     }
2388
2389     unless ($engine) {
2390         $engine = $class->engine_class;
2391     }
2392
2393     Class::MOP::load_class($engine);
2394
2395     # check for old engines that are no longer compatible
2396     my $old_engine;
2397     if ( $engine->isa('Catalyst::Engine::Apache')
2398         && !Catalyst::Engine::Apache->VERSION )
2399     {
2400         $old_engine = 1;
2401     }
2402
2403     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2404         && Catalyst::Engine::Server->VERSION le '0.02' )
2405     {
2406         $old_engine = 1;
2407     }
2408
2409     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2410         && $engine->VERSION eq '0.01' )
2411     {
2412         $old_engine = 1;
2413     }
2414
2415     elsif ($engine->isa('Catalyst::Engine::Zeus')
2416         && $engine->VERSION eq '0.01' )
2417     {
2418         $old_engine = 1;
2419     }
2420
2421     if ($old_engine) {
2422         Catalyst::Exception->throw( message =>
2423               qq/Engine "$engine" is not supported by this version of Catalyst/
2424         );
2425     }
2426
2427     # engine instance
2428     $class->engine( $engine->new );
2429 }
2430
2431 =head2 $c->setup_home
2432
2433 Sets up the home directory.
2434
2435 =cut
2436
2437 sub setup_home {
2438     my ( $class, $home ) = @_;
2439
2440     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2441         $home = $env;
2442     }
2443
2444     $home ||= Catalyst::Utils::home($class);
2445
2446     if ($home) {
2447         #I remember recently being scolded for assigning config values like this
2448         $class->config->{home} ||= $home;
2449         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2450     }
2451 }
2452
2453 =head2 $c->setup_log
2454
2455 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2456 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2457 log to.
2458
2459 This method also installs a C<debug> method that returns a true value into the
2460 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2461 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2462
2463 Note that if the log has already been setup, by either a previous call to
2464 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2465 that this method won't actually set up the log object.
2466
2467 =cut
2468
2469 sub setup_log {
2470     my ( $class, $levels ) = @_;
2471
2472     $levels ||= '';
2473     $levels =~ s/^\s+//;
2474     $levels =~ s/\s+$//;
2475     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2476
2477     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2478     if ( defined $env_debug ) {
2479         $levels{debug} = 1 if $env_debug; # Ugly!
2480         delete($levels{debug}) unless $env_debug;
2481     }
2482
2483     unless ( $class->log ) {
2484         $class->log( Catalyst::Log->new(keys %levels) );
2485     }
2486
2487     if ( $levels{debug} ) {
2488         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2489         $class->log->debug('Debug messages enabled');
2490     }
2491 }
2492
2493 =head2 $c->setup_plugins
2494
2495 Sets up plugins.
2496
2497 =cut
2498
2499 =head2 $c->setup_stats
2500
2501 Sets up timing statistics class.
2502
2503 =cut
2504
2505 sub setup_stats {
2506     my ( $class, $stats ) = @_;
2507
2508     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2509
2510     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2511     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2512         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2513         $class->log->debug('Statistics enabled');
2514     }
2515 }
2516
2517
2518 =head2 $c->registered_plugins
2519
2520 Returns a sorted list of the plugins which have either been stated in the
2521 import list or which have been added via C<< MyApp->plugin(@args); >>.
2522
2523 If passed a given plugin name, it will report a boolean value indicating
2524 whether or not that plugin is loaded.  A fully qualified name is required if
2525 the plugin name does not begin with C<Catalyst::Plugin::>.
2526
2527  if ($c->registered_plugins('Some::Plugin')) {
2528      ...
2529  }
2530
2531 =cut
2532
2533 {
2534
2535     sub registered_plugins {
2536         my $proto = shift;
2537         return sort keys %{ $proto->_plugins } unless @_;
2538         my $plugin = shift;
2539         return 1 if exists $proto->_plugins->{$plugin};
2540         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2541     }
2542
2543     sub _register_plugin {
2544         my ( $proto, $plugin, $instant ) = @_;
2545         my $class = ref $proto || $proto;
2546
2547         Class::MOP::load_class( $plugin );
2548
2549         $proto->_plugins->{$plugin} = 1;
2550         unless ($instant) {
2551             no strict 'refs';
2552             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2553               my @superclasses = ($plugin, $meta->superclasses );
2554               $meta->superclasses(@superclasses);
2555             } else {
2556               unshift @{"$class\::ISA"}, $plugin;
2557             }
2558         }
2559         return $class;
2560     }
2561
2562     sub setup_plugins {
2563         my ( $class, $plugins ) = @_;
2564
2565         $class->_plugins( {} ) unless $class->_plugins;
2566         $plugins ||= [];
2567
2568         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2569
2570         for my $plugin ( reverse @plugins ) {
2571             Class::MOP::load_class($plugin);
2572             my $meta = find_meta($plugin);
2573             next if $meta && $meta->isa('Moose::Meta::Role');
2574
2575             $class->_register_plugin($plugin);
2576         }
2577
2578         my @roles =
2579             map { $_->name }
2580             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2581             map { find_meta($_) }
2582             @plugins;
2583
2584         Moose::Util::apply_all_roles(
2585             $class => @roles
2586         ) if @roles;
2587     }
2588 }
2589
2590 =head2 $c->stack
2591
2592 Returns an arrayref of the internal execution stack (actions that are
2593 currently executing).
2594
2595 =head2 $c->stats_class
2596
2597 Returns or sets the stats (timing statistics) class.
2598
2599 =head2 $c->use_stats
2600
2601 Returns 1 when stats collection is enabled.  Stats collection is enabled
2602 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2603 environment variable is set.
2604
2605 Note that this is a static method, not an accessor and should be overridden
2606 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2607
2608 =cut
2609
2610 sub use_stats { 0 }
2611
2612
2613 =head2 $c->write( $data )
2614
2615 Writes $data to the output stream. When using this method directly, you
2616 will need to manually set the C<Content-Length> header to the length of
2617 your output data, if known.
2618
2619 =cut
2620
2621 sub write {
2622     my $c = shift;
2623
2624     # Finalize headers if someone manually writes output
2625     $c->finalize_headers;
2626
2627     return $c->engine->write( $c, @_ );
2628 }
2629
2630 =head2 version
2631
2632 Returns the Catalyst version number. Mostly useful for "powered by"
2633 messages in template systems.
2634
2635 =cut
2636
2637 sub version { return $Catalyst::VERSION }
2638
2639 =head1 INTERNAL ACTIONS
2640
2641 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2642 C<_ACTION>, and C<_END>. These are by default not shown in the private
2643 action table, but you can make them visible with a config parameter.
2644
2645     MyApp->config(show_internal_actions => 1);
2646
2647 =head1 CASE SENSITIVITY
2648
2649 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2650 mapped to C</foo/bar>. You can activate case sensitivity with a config
2651 parameter.
2652
2653     MyApp->config(case_sensitive => 1);
2654
2655 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2656
2657 =head1 ON-DEMAND PARSER
2658
2659 The request body is usually parsed at the beginning of a request,
2660 but if you want to handle input yourself, you can enable on-demand
2661 parsing with a config parameter.
2662
2663     MyApp->config(parse_on_demand => 1);
2664
2665 =head1 PROXY SUPPORT
2666
2667 Many production servers operate using the common double-server approach,
2668 with a lightweight frontend web server passing requests to a larger
2669 backend server. An application running on the backend server must deal
2670 with two problems: the remote user always appears to be C<127.0.0.1> and
2671 the server's hostname will appear to be C<localhost> regardless of the
2672 virtual host that the user connected through.
2673
2674 Catalyst will automatically detect this situation when you are running
2675 the frontend and backend servers on the same machine. The following
2676 changes are made to the request.
2677
2678     $c->req->address is set to the user's real IP address, as read from
2679     the HTTP X-Forwarded-For header.
2680
2681     The host value for $c->req->base and $c->req->uri is set to the real
2682     host, as read from the HTTP X-Forwarded-Host header.
2683
2684 Additionally, you may be running your backend application on an insecure
2685 connection (port 80) while your frontend proxy is running under SSL.  If there
2686 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2687 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2688 be created properly.
2689
2690 In the case of passing in:
2691
2692     X-Forwarded-Port: 443
2693
2694 All calls to C<uri_for> will result in an https link, as is expected.
2695
2696 Obviously, your web server must support these headers for this to work.
2697
2698 In a more complex server farm environment where you may have your
2699 frontend proxy server(s) on different machines, you will need to set a
2700 configuration option to tell Catalyst to read the proxied data from the
2701 headers.
2702
2703     MyApp->config(using_frontend_proxy => 1);
2704
2705 If you do not wish to use the proxy support at all, you may set:
2706
2707     MyApp->config(ignore_frontend_proxy => 1);
2708
2709 =head1 THREAD SAFETY
2710
2711 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2712 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2713 believe the Catalyst core to be thread-safe.
2714
2715 If you plan to operate in a threaded environment, remember that all other
2716 modules you are using must also be thread-safe. Some modules, most notably
2717 L<DBD::SQLite>, are not thread-safe.
2718
2719 =head1 SUPPORT
2720
2721 IRC:
2722
2723     Join #catalyst on irc.perl.org.
2724
2725 Mailing Lists:
2726
2727     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2728     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2729
2730 Web:
2731
2732     http://catalyst.perl.org
2733
2734 Wiki:
2735
2736     http://dev.catalyst.perl.org
2737
2738 =head1 SEE ALSO
2739
2740 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2741
2742 =head2 L<Catalyst::Manual> - The Catalyst Manual
2743
2744 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2745
2746 =head2 L<Catalyst::Engine> - Core engine
2747
2748 =head2 L<Catalyst::Log> - Log class.
2749
2750 =head2 L<Catalyst::Request> - Request object
2751
2752 =head2 L<Catalyst::Response> - Response object
2753
2754 =head2 L<Catalyst::Test> - The test suite.
2755
2756 =head1 PROJECT FOUNDER
2757
2758 sri: Sebastian Riedel <sri@cpan.org>
2759
2760 =head1 CONTRIBUTORS
2761
2762 abw: Andy Wardley
2763
2764 acme: Leon Brocard <leon@astray.com>
2765
2766 Andrew Bramble
2767
2768 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
2769
2770 Andrew Ruthven
2771
2772 andyg: Andy Grundman <andy@hybridized.org>
2773
2774 audreyt: Audrey Tang
2775
2776 bricas: Brian Cassidy <bricas@cpan.org>
2777
2778 Caelum: Rafael Kitover <rkitover@io.com>
2779
2780 chansen: Christian Hansen
2781
2782 chicks: Christopher Hicks
2783
2784 Chisel Wright C<pause@herlpacker.co.uk>
2785
2786 Danijel Milicevic C<me@danijel.de>
2787
2788 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
2789
2790 David Naughton, C<naughton@umn.edu>
2791
2792 David E. Wheeler
2793
2794 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2795
2796 Drew Taylor
2797
2798 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2799
2800 esskar: Sascha Kiefer
2801
2802 fireartist: Carl Franks <cfranks@cpan.org>
2803
2804 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
2805
2806 gabb: Danijel Milicevic
2807
2808 Gary Ashton Jones
2809
2810 Gavin Henry C<ghenry@perl.me.uk>
2811
2812 Geoff Richards
2813
2814 groditi: Guillermo Roditi <groditi@gmail.com>
2815
2816 hobbs: Andrew Rodland <andrew@cleverdomain.org>
2817
2818 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2819
2820 jcamacho: Juan Camacho
2821
2822 jester: Jesse Sheidlower C<jester@panix.com>
2823
2824 jhannah: Jay Hannah <jay@jays.net>
2825
2826 Jody Belka
2827
2828 Johan Lindstrom
2829
2830 jon: Jon Schutz <jjschutz@cpan.org>
2831
2832 Jonathan Rockway C<< <jrockway@cpan.org> >>
2833
2834 Kieren Diment C<kd@totaldatasolution.com>
2835
2836 konobi: Scott McWhirter <konobi@cpan.org>
2837
2838 marcus: Marcus Ramberg <mramberg@cpan.org>
2839
2840 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2841
2842 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2843
2844 mugwump: Sam Vilain
2845
2846 naughton: David Naughton
2847
2848 ningu: David Kamholz <dkamholz@cpan.org>
2849
2850 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2851
2852 numa: Dan Sully <daniel@cpan.org>
2853
2854 obra: Jesse Vincent
2855
2856 omega: Andreas Marienborg
2857
2858 Oleg Kostyuk <cub.uanic@gmail.com>
2859
2860 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2861
2862 rafl: Florian Ragwitz <rafl@debian.org>
2863
2864 random: Roland Lammel <lammel@cpan.org>
2865
2866 Robert Sedlacek C<< <rs@474.at> >>
2867
2868 sky: Arthur Bergman
2869
2870 t0m: Tomas Doran <bobtfish@bobtfish.net>
2871
2872 Ulf Edvinsson
2873
2874 Viljo Marrandi C<vilts@yahoo.com>
2875
2876 Will Hawes C<info@whawes.co.uk>
2877
2878 willert: Sebastian Willert <willert@cpan.org>
2879
2880 Yuval Kogman, C<nothingmuch@woobling.org>
2881
2882 =head1 LICENSE
2883
2884 This library is free software. You can redistribute it and/or modify it under
2885 the same terms as Perl itself.
2886
2887 =cut
2888
2889 no Moose;
2890
2891 __PACKAGE__->meta->make_immutable;
2892
2893 1;