lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use Moose::Util qw/find_meta/;
   6 use bytes;
   7 use Scope::Upper ();
   8 use Catalyst::Exception;
   9 use Catalyst::Log;
  10 use Catalyst::Request;
  11 use Catalyst::Request::Upload;
  12 use Catalyst::Response;
  13 use Catalyst::Utils;
  14 use Catalyst::Controller;
  15 use Devel::InnerPackage ();
  16 use File::stat;
  17 use Module::Pluggable::Object ();
  18 use Text::SimpleTable ();
  19 use Path::Class::Dir ();
  20 use Path::Class::File ();
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Tree::Simple qw/use_weak_refs/;
  25 use Tree::Simple::Visitor::FindByUID;
  26 use Class::C3::Adopt::NEXT;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp shortmess/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 has stack => (is => 'ro', default => sub { [] });
  34 has stash => (is => 'rw', default => sub { {} });
  35 has state => (is => 'rw', default => 0);
  36 has stats => (is => 'rw');
  37 has action => (is => 'rw');
  38 has counter => (is => 'rw', default => sub { {} });
  39 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  40 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  41 has namespace => (is => 'rw');
  42
  43 sub depth { scalar @{ shift->stack || [] }; }
  44 sub comp { shift->component(@_) }
  45
  46 sub req {
  47     my $self = shift; return $self->request(@_);
  48 }
  49 sub res {
  50     my $self = shift; return $self->response(@_);
  51 }
  52
  53 # For backwards compatibility
  54 sub finalize_output { shift->finalize_body(@_) };
  55
  56 # For statistics
  57 our $COUNT     = 1;
  58 our $START     = time;
  59 our $RECURSION = 1000;
  60 our $DETACH    = "catalyst_detach\n";
  61 our $GO        = "catalyst_go\n";
  62
  63 #I imagine that very few of these really need to be class variables. if any.
  64 #maybe we should just make them attributes with a default?
  65 __PACKAGE__->mk_classdata($_)
  66   for qw/components arguments dispatcher engine log dispatcher_class
  67   engine_class context_class request_class response_class stats_class
  68   setup_finished/;
  69
  70 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  71 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  72 __PACKAGE__->request_class('Catalyst::Request');
  73 __PACKAGE__->response_class('Catalyst::Response');
  74 __PACKAGE__->stats_class('Catalyst::Stats');
  75
  76 # Remember to update this in Catalyst::Runtime as well!
  77
  78 our $VERSION = '5.80003';
  79
  80 {
  81     my $dev_version = $VERSION =~ /_\d{2}$/;
  82     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  83 }
  84
  85 $VERSION = eval $VERSION;
  86
  87 sub import {
  88     my ( $class, @arguments ) = @_;
  89
  90     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  91     # callers @ISA.
  92     return unless $class eq 'Catalyst';
  93
  94     my $caller = caller();
  95     return if $caller eq 'main';
  96
  97     # Kill Adopt::NEXT warnings if we're a non-RC version
  98     unless (_IS_DEVELOPMENT_VERSION()) {
  99         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 100     }
 101
 102     my $meta = Moose::Meta::Class->initialize($caller);
 103     #Moose->import({ into => $caller }); #do we want to do this?
 104
 105     unless ( $caller->isa('Catalyst') ) {
 106         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 107         $meta->superclasses(@superclasses);
 108     }
 109     unless( $meta->has_method('meta') ){
 110         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 111     }
 112
 113     $caller->arguments( [@arguments] );
 114     $caller->setup_home;
 115 }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 =head2 -Engine
 252
 253 Forces Catalyst to use a specific engine. Omit the
 254 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 255
 256     use Catalyst qw/-Engine=CGI/;
 257
 258 =head2 -Home
 259
 260 Forces Catalyst to use a specific home directory, e.g.:
 261
 262     use Catalyst qw[-Home=/usr/mst];
 263
 264 This can also be done in the shell environment by setting either the
 265 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 266 is replaced with the uppercased name of your application, any "::" in
 267 the name will be replaced with underscores, e.g. MyApp::Web should use
 268 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 269
 270 =head2 -Log
 271
 272     use Catalyst '-Log=warn,fatal,error';
 273
 274 Specifies a comma-delimited list of log levels.
 275
 276 =head2 -Stats
 277
 278 Enables statistics collection and reporting. You can also force this setting
 279 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 280 environment settings override the application, with <MYAPP>_STATS having the
 281 highest priority.
 282
 283 e.g.
 284
 285    use Catalyst qw/-Stats=1/
 286
 287 =head1 METHODS
 288
 289 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 290
 291 =head2 $c->action
 292
 293 Returns a L<Catalyst::Action> object for the current action, which
 294 stringifies to the action name. See L<Catalyst::Action>.
 295
 296 =head2 $c->namespace
 297
 298 Returns the namespace of the current action, i.e., the URI prefix
 299 corresponding to the controller of the current action. For example:
 300
 301     # in Controller::Foo::Bar
 302     $c->namespace; # returns 'foo/bar';
 303
 304 =head2 $c->request
 305
 306 =head2 $c->req
 307
 308 Returns the current L<Catalyst::Request> object, giving access to
 309 information about the current client request (including parameters,
 310 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 311
 312 =head2 REQUEST FLOW HANDLING
 313
 314 =head2 $c->forward( $action [, \@arguments ] )
 315
 316 =head2 $c->forward( $class, $method, [, \@arguments ] )
 317
 318 Forwards processing to another action, by its private name. If you give a
 319 class name but no method, C<process()> is called. You may also optionally
 320 pass arguments in an arrayref. The action will receive the arguments in
 321 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 322 C<< $c->req->args >> will be restored to the previous values.
 323
 324 Any data C<return>ed from the action forwarded to, will be returned by the
 325 call to forward.
 326
 327     my $foodata = $c->forward('/foo');
 328     $c->forward('index');
 329     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 330     $c->forward('MyApp::View::TT');
 331
 332 Note that forward implies an C<<eval { }>> around the call (actually
 333 C<execute> does), thus de-fatalizing all 'dies' within the called
 334 action. If you want C<die> to propagate you need to do something like:
 335
 336     $c->forward('foo');
 337     die $c->error if $c->error;
 338
 339 Or make sure to always return true values from your actions and write
 340 your code like this:
 341
 342     $c->forward('foo') || return;
 343
 344 =cut
 345
 346 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 347
 348 =head2 $c->detach( $action [, \@arguments ] )
 349
 350 =head2 $c->detach( $class, $method, [, \@arguments ] )
 351
 352 =head2 $c->detach()
 353
 354 The same as C<forward>, but doesn't return to the previous action when
 355 processing is finished.
 356
 357 When called with no arguments it escapes the processing chain entirely.
 358
 359 =cut
 360
 361 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 362
 363 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 364
 365 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 366
 367 Almost the same as C<forward>, but does a full dispatch, instead of just
 368 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 369 C<auto> and the method you go to are called, just like a new request.
 370
 371 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 372 This means, for example, that $c->action methods such as C<name>, C<class> and
 373 C<reverse> return information for the visited action when they are invoked
 374 within the visited action.  This is different from the behavior of C<forward>
 375 which continues to use the $c->action object from the caller action even when
 376 invoked from the callee.
 377
 378 C<$c-E<gt>stash> is kept unchanged.
 379
 380 In effect, C<visit> allows you to "wrap" another action, just as it
 381 would have been called by dispatching from a URL, while the analogous
 382 C<go> allows you to transfer control to another action as if it had
 383 been reached directly from a URL.
 384
 385 =cut
 386
 387 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 388
 389 =head2 $c->go( $action [, \@captures, \@arguments ] )
 390
 391 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 392
 393 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 394 instead of just calling the new C<$action> /
 395 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 396 method you visit are called, just like a new request.
 397
 398 C<$c-E<gt>stash> is kept unchanged.
 399
 400 =cut
 401
 402 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 403
 404 =head2 $c->response
 405
 406 =head2 $c->res
 407
 408 Returns the current L<Catalyst::Response> object, see there for details.
 409
 410 =head2 $c->stash
 411
 412 Returns a hashref to the stash, which may be used to store data and pass
 413 it between components during a request. You can also set hash keys by
 414 passing arguments. The stash is automatically sent to the view. The
 415 stash is cleared at the end of a request; it cannot be used for
 416 persistent storage (for this you must use a session; see
 417 L<Catalyst::Plugin::Session> for a complete system integrated with
 418 Catalyst).
 419
 420     $c->stash->{foo} = $bar;
 421     $c->stash( { moose => 'majestic', qux => 0 } );
 422     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 423
 424     # stash is automatically passed to the view for use in a template
 425     $c->forward( 'MyApp::View::TT' );
 426
 427 =cut
 428
 429 around stash => sub {
 430     my $orig = shift;
 431     my $c = shift;
 432     my $stash = $orig->($c);
 433     if (@_) {
 434         my $new_stash = @_ > 1 ? {@_} : $_[0];
 435         croak('stash takes a hash or hashref') unless ref $new_stash;
 436         foreach my $key ( keys %$new_stash ) {
 437           $stash->{$key} = $new_stash->{$key};
 438         }
 439     }
 440
 441     return $stash;
 442 };
 443
 444
 445 =head2 $c->error
 446
 447 =head2 $c->error($error, ...)
 448
 449 =head2 $c->error($arrayref)
 450
 451 Returns an arrayref containing error messages.  If Catalyst encounters an
 452 error while processing a request, it stores the error in $c->error.  This
 453 method should only be used to store fatal error messages.
 454
 455     my @error = @{ $c->error };
 456
 457 Add a new error.
 458
 459     $c->error('Something bad happened');
 460
 461 =cut
 462
 463 sub error {
 464     my $c = shift;
 465     if ( $_[0] ) {
 466         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 467         croak @$error unless ref $c;
 468         push @{ $c->{error} }, @$error;
 469     }
 470     elsif ( defined $_[0] ) { $c->{error} = undef }
 471     return $c->{error} || [];
 472 }
 473
 474
 475 =head2 $c->state
 476
 477 Contains the return value of the last executed action.
 478
 479 =head2 $c->clear_errors
 480
 481 Clear errors.  You probably don't want to clear the errors unless you are
 482 implementing a custom error screen.
 483
 484 This is equivalent to running
 485
 486     $c->error(0);
 487
 488 =cut
 489
 490 sub clear_errors {
 491     my $c = shift;
 492     $c->error(0);
 493 }
 494
 495 # search components given a name and some prefixes
 496 sub _comp_search_prefixes {
 497     my ( $c, $name, @prefixes ) = @_;
 498     my $appclass = ref $c || $c;
 499     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 500     $filter = qr/$filter/; # Compile regex now rather than once per loop
 501
 502     # map the original component name to the sub part that we will search against
 503     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 504         grep { /$filter/ } keys %{ $c->components };
 505
 506     # undef for a name will return all
 507     return keys %eligible if !defined $name;
 508
 509     my $query  = ref $name ? $name : qr/^$name$/i;
 510     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 511
 512     return map { $c->components->{ $_ } } @result if @result;
 513
 514     # if we were given a regexp to search against, we're done.
 515     return if ref $name;
 516
 517     # regexp fallback
 518     $query  = qr/$name/i;
 519     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 520
 521     # no results? try against full names
 522     if( !@result ) {
 523         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 524     }
 525
 526     # don't warn if we didn't find any results, it just might not exist
 527     if( @result ) {
 528         # Disgusting hack to work out correct method name
 529         my $warn_for = lc $prefixes[0];
 530         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 531            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 532            "component resolution is unreliable and unsafe.";
 533         my $short = $result[0];
 534         $short =~ s/.*?Model:://;
 535         my $shortmess = Carp::shortmess('');
 536         if ($shortmess =~ m#Catalyst/Plugin#) {
 537            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 538               "plugin's config";
 539         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 540            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 541               "component's config";
 542         } else {
 543            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 544               "but if you really wanted to search, pass in a regexp as the argument " .
 545               "like so: \$c->${warn_for}(qr/${name}/)";
 546         }
 547         $c->log->warn( "${msg}$shortmess" );
 548     }
 549
 550     return @result;
 551 }
 552
 553 # Find possible names for a prefix
 554 sub _comp_names {
 555     my ( $c, @prefixes ) = @_;
 556     my $appclass = ref $c || $c;
 557
 558     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 559
 560     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 561     return @names;
 562 }
 563
 564 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 565 sub _filter_component {
 566     my ( $c, $comp, @args ) = @_;
 567
 568     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 569         return $comp->ACCEPT_CONTEXT( $c, @args );
 570     }
 571
 572     return $comp;
 573 }
 574
 575 =head2 COMPONENT ACCESSORS
 576
 577 =head2 $c->controller($name)
 578
 579 Gets a L<Catalyst::Controller> instance by name.
 580
 581     $c->controller('Foo')->do_stuff;
 582
 583 If the name is omitted, will return the controller for the dispatched
 584 action.
 585
 586 If you want to search for controllers, pass in a regexp as the argument.
 587
 588     # find all controllers that start with Foo
 589     my @foo_controllers = $c->controller(qr{^Foo});
 590
 591
 592 =cut
 593
 594 sub controller {
 595     my ( $c, $name, @args ) = @_;
 596
 597     if( $name ) {
 598         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 599         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 600         return $c->_filter_component( $result[ 0 ], @args );
 601     }
 602
 603     return $c->component( $c->action->class );
 604 }
 605
 606 =head2 $c->model($name)
 607
 608 Gets a L<Catalyst::Model> instance by name.
 609
 610     $c->model('Foo')->do_stuff;
 611
 612 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 613
 614 If the name is omitted, it will look for
 615  - a model object in $c->stash->{current_model_instance}, then
 616  - a model name in $c->stash->{current_model}, then
 617  - a config setting 'default_model', or
 618  - check if there is only one model, and return it if that's the case.
 619
 620 If you want to search for models, pass in a regexp as the argument.
 621
 622     # find all models that start with Foo
 623     my @foo_models = $c->model(qr{^Foo});
 624
 625 =cut
 626
 627 sub model {
 628     my ( $c, $name, @args ) = @_;
 629
 630     if( $name ) {
 631         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 632         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 633         return $c->_filter_component( $result[ 0 ], @args );
 634     }
 635
 636     if (ref $c) {
 637         return $c->stash->{current_model_instance}
 638           if $c->stash->{current_model_instance};
 639         return $c->model( $c->stash->{current_model} )
 640           if $c->stash->{current_model};
 641     }
 642     return $c->model( $c->config->{default_model} )
 643       if $c->config->{default_model};
 644
 645     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 646
 647     if( $rest ) {
 648         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 649         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 650         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 651         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 652         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 653     }
 654
 655     return $c->_filter_component( $comp );
 656 }
 657
 658
 659 =head2 $c->view($name)
 660
 661 Gets a L<Catalyst::View> instance by name.
 662
 663     $c->view('Foo')->do_stuff;
 664
 665 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 666
 667 If the name is omitted, it will look for
 668  - a view object in $c->stash->{current_view_instance}, then
 669  - a view name in $c->stash->{current_view}, then
 670  - a config setting 'default_view', or
 671  - check if there is only one view, and return it if that's the case.
 672
 673 If you want to search for views, pass in a regexp as the argument.
 674
 675     # find all views that start with Foo
 676     my @foo_views = $c->view(qr{^Foo});
 677
 678 =cut
 679
 680 sub view {
 681     my ( $c, $name, @args ) = @_;
 682
 683     if( $name ) {
 684         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 685         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 686         return $c->_filter_component( $result[ 0 ], @args );
 687     }
 688
 689     if (ref $c) {
 690         return $c->stash->{current_view_instance}
 691           if $c->stash->{current_view_instance};
 692         return $c->view( $c->stash->{current_view} )
 693           if $c->stash->{current_view};
 694     }
 695     return $c->view( $c->config->{default_view} )
 696       if $c->config->{default_view};
 697
 698     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 699
 700     if( $rest ) {
 701         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 702         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 703         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 704         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 705         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 706     }
 707
 708     return $c->_filter_component( $comp );
 709 }
 710
 711 =head2 $c->controllers
 712
 713 Returns the available names which can be passed to $c->controller
 714
 715 =cut
 716
 717 sub controllers {
 718     my ( $c ) = @_;
 719     return $c->_comp_names(qw/Controller C/);
 720 }
 721
 722 =head2 $c->models
 723
 724 Returns the available names which can be passed to $c->model
 725
 726 =cut
 727
 728 sub models {
 729     my ( $c ) = @_;
 730     return $c->_comp_names(qw/Model M/);
 731 }
 732
 733
 734 =head2 $c->views
 735
 736 Returns the available names which can be passed to $c->view
 737
 738 =cut
 739
 740 sub views {
 741     my ( $c ) = @_;
 742     return $c->_comp_names(qw/View V/);
 743 }
 744
 745 =head2 $c->comp($name)
 746
 747 =head2 $c->component($name)
 748
 749 Gets a component object by name. This method is not recommended,
 750 unless you want to get a specific component by full
 751 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 752 should be used instead.
 753
 754 If C<$name> is a regexp, a list of components matched against the full
 755 component name will be returned.
 756
 757 =cut
 758
 759 sub component {
 760     my ( $c, $name, @args ) = @_;
 761
 762     if( $name ) {
 763         my $comps = $c->components;
 764
 765         if( !ref $name ) {
 766             # is it the exact name?
 767             return $c->_filter_component( $comps->{ $name }, @args )
 768                        if exists $comps->{ $name };
 769
 770             # perhaps we just omitted "MyApp"?
 771             my $composed = ( ref $c || $c ) . "::${name}";
 772             return $c->_filter_component( $comps->{ $composed }, @args )
 773                        if exists $comps->{ $composed };
 774
 775             # search all of the models, views and controllers
 776             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 777             return $c->_filter_component( $comp, @args ) if $comp;
 778         }
 779
 780         # This is here so $c->comp( '::M::' ) works
 781         my $query = ref $name ? $name : qr{$name}i;
 782
 783         my @result = grep { m{$query} } keys %{ $c->components };
 784         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 785
 786         if( $result[ 0 ] ) {
 787             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 788             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 789             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 790             return $c->_filter_component( $result[ 0 ], @args );
 791         }
 792
 793         # I would expect to return an empty list here, but that breaks back-compat
 794     }
 795
 796     # fallback
 797     return sort keys %{ $c->components };
 798 }
 799
 800 =head2 CLASS DATA AND HELPER CLASSES
 801
 802 =head2 $c->config
 803
 804 Returns or takes a hashref containing the application's configuration.
 805
 806     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 807
 808 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 809 like myapp.conf in your applications home directory. See
 810 L<Catalyst::Plugin::ConfigLoader>.
 811
 812 =head3 Cascading configuration.
 813
 814 The config method is present on all Catalyst components, and configuration
 815 will be merged when an application is started. Configuration loaded with
 816 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 817 followed by configuration in your top level C<MyApp> class. These two
 818 configurations are merged, and then configuration data whose hash key matches a
 819 component name is merged with configuration for that component.
 820
 821 The configuration for a component is then passed to the C<new> method when a
 822 component is constructed.
 823
 824 For example:
 825
 826     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 827     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 828
 829 will mean that C<MyApp::Model::Foo> receives the following data when
 830 constructed:
 831
 832     MyApp::Model::Foo->new({
 833         bar => 'baz',
 834         quux => 'frob',
 835         overrides => 'me',
 836     });
 837
 838 =cut
 839
 840 around config => sub {
 841     my $orig = shift;
 842     my $c = shift;
 843
 844     croak('Setting config after setup has been run is not allowed.')
 845         if ( @_ and $c->setup_finished );
 846
 847     $c->$orig(@_);
 848 };
 849
 850 =head2 $c->log
 851
 852 Returns the logging object instance. Unless it is already set, Catalyst
 853 sets this up with a L<Catalyst::Log> object. To use your own log class,
 854 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 855 C<< __PACKAGE__->setup >>.
 856
 857  __PACKAGE__->log( MyLogger->new );
 858  __PACKAGE__->setup;
 859
 860 And later:
 861
 862     $c->log->info( 'Now logging with my own logger!' );
 863
 864 Your log class should implement the methods described in
 865 L<Catalyst::Log>.
 866
 867
 868 =head2 $c->debug
 869
 870 Returns 1 if debug mode is enabled, 0 otherwise.
 871
 872 You can enable debug mode in several ways:
 873
 874 =over
 875
 876 =item By calling myapp_server.pl with the -d flag
 877
 878 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 879
 880 =item The -Debug option in your MyApp.pm
 881
 882 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 883
 884 =back
 885
 886 Calling C<< $c->debug(1) >> has no effect.
 887
 888 =cut
 889
 890 sub debug { 0 }
 891
 892 =head2 $c->dispatcher
 893
 894 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 895
 896 =head2 $c->engine
 897
 898 Returns the engine instance. See L<Catalyst::Engine>.
 899
 900
 901 =head2 UTILITY METHODS
 902
 903 =head2 $c->path_to(@path)
 904
 905 Merges C<@path> with C<< $c->config->{home} >> and returns a
 906 L<Path::Class::Dir> object.
 907
 908 For example:
 909
 910     $c->path_to( 'db', 'sqlite.db' );
 911
 912 =cut
 913
 914 sub path_to {
 915     my ( $c, @path ) = @_;
 916     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 917     if ( -d $path ) { return $path }
 918     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 919 }
 920
 921 =head2 $c->plugin( $name, $class, @args )
 922
 923 Helper method for plugins. It creates a class data accessor/mutator and
 924 loads and instantiates the given class.
 925
 926     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 927
 928     $c->prototype->define_javascript_functions;
 929
 930 B<Note:> This method of adding plugins is deprecated. The ability
 931 to add plugins like this B<will be removed> in a Catalyst 5.81.
 932 Please do not use this functionality in new code.
 933
 934 =cut
 935
 936 sub plugin {
 937     my ( $class, $name, $plugin, @args ) = @_;
 938
 939     # See block comment in t/unit_core_plugin.t
 940     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 941
 942     $class->_register_plugin( $plugin, 1 );
 943
 944     eval { $plugin->import };
 945     $class->mk_classdata($name);
 946     my $obj;
 947     eval { $obj = $plugin->new(@args) };
 948
 949     if ($@) {
 950         Catalyst::Exception->throw( message =>
 951               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 952     }
 953
 954     $class->$name($obj);
 955     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 956       if $class->debug;
 957 }
 958
 959 =head2 MyApp->setup
 960
 961 Initializes the dispatcher and engine, loads any plugins, and loads the
 962 model, view, and controller components. You may also specify an array
 963 of plugins to load here, if you choose to not load them in the C<use
 964 Catalyst> line.
 965
 966     MyApp->setup;
 967     MyApp->setup( qw/-Debug/ );
 968
 969 =cut
 970
 971 sub setup {
 972     my ( $class, @arguments ) = @_;
 973     croak('Running setup more than once')
 974         if ( $class->setup_finished );
 975
 976     unless ( $class->isa('Catalyst') ) {
 977
 978         Catalyst::Exception->throw(
 979             message => qq/'$class' does not inherit from Catalyst/ );
 980     }
 981
 982     if ( $class->arguments ) {
 983         @arguments = ( @arguments, @{ $class->arguments } );
 984     }
 985
 986     # Process options
 987     my $flags = {};
 988
 989     foreach (@arguments) {
 990
 991         if (/^-Debug$/) {
 992             $flags->{log} =
 993               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 994         }
 995         elsif (/^-(\w+)=?(.*)$/) {
 996             $flags->{ lc $1 } = $2;
 997         }
 998         else {
 999             push @{ $flags->{plugins} }, $_;
1000         }
1001     }
1002
1003     $class->setup_home( delete $flags->{home} );
1004
1005     $class->setup_log( delete $flags->{log} );
1006     $class->setup_plugins( delete $flags->{plugins} );
1007     $class->setup_dispatcher( delete $flags->{dispatcher} );
1008     $class->setup_engine( delete $flags->{engine} );
1009     $class->setup_stats( delete $flags->{stats} );
1010
1011     for my $flag ( sort keys %{$flags} ) {
1012
1013         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1014             &$code( $class, delete $flags->{$flag} );
1015         }
1016         else {
1017             $class->log->warn(qq/Unknown flag "$flag"/);
1018         }
1019     }
1020
1021     eval { require Catalyst::Devel; };
1022     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1023         $class->log->warn(<<"EOF");
1024 You are running an old script!
1025
1026   Please update by running (this will overwrite existing files):
1027     catalyst.pl -force -scripts $class
1028
1029   or (this will not overwrite existing files):
1030     catalyst.pl -scripts $class
1031
1032 EOF
1033     }
1034
1035     if ( $class->debug ) {
1036         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1037
1038         if (@plugins) {
1039             my $column_width = Catalyst::Utils::term_width() - 6;
1040             my $t = Text::SimpleTable->new($column_width);
1041             $t->row($_) for @plugins;
1042             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1043         }
1044
1045         my $dispatcher = $class->dispatcher;
1046         my $engine     = $class->engine;
1047         my $home       = $class->config->{home};
1048
1049         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1050         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1051
1052         $home
1053           ? ( -d $home )
1054           ? $class->log->debug(qq/Found home "$home"/)
1055           : $class->log->debug(qq/Home "$home" doesn't exist/)
1056           : $class->log->debug(q/Couldn't find home/);
1057     }
1058
1059     # Call plugins setup, this is stupid and evil.
1060     # Also screws C3 badly on 5.10, hack to avoid.
1061     {
1062         no warnings qw/redefine/;
1063         local *setup = sub { };
1064         $class->setup unless $Catalyst::__AM_RESTARTING;
1065     }
1066
1067     # Initialize our data structure
1068     $class->components( {} );
1069
1070     $class->setup_components;
1071
1072     if ( $class->debug ) {
1073         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1074         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1075         for my $comp ( sort keys %{ $class->components } ) {
1076             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1077             $t->row( $comp, $type );
1078         }
1079         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1080           if ( keys %{ $class->components } );
1081     }
1082
1083     # Add our self to components, since we are also a component
1084     if( $class->isa('Catalyst::Controller') ){
1085       $class->components->{$class} = $class;
1086     }
1087
1088     $class->setup_actions;
1089
1090     if ( $class->debug ) {
1091         my $name = $class->config->{name} || 'Application';
1092         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1093     }
1094     $class->log->_flush() if $class->log->can('_flush');
1095
1096     # Make sure that the application class becomes immutable at this point,
1097     # which ensures that it gets an inlined constructor. This means that it
1098     # works even if the user has added a plugin which contains a new method.
1099     # Note however that we have to do the work on scope end, so that method
1100     # modifiers work correctly in MyApp (as you have to call setup _before_
1101     # applying modifiers).
1102     Scope::Upper::reap(sub {
1103         my $meta = Class::MOP::get_metaclass_by_name($class);
1104         if ( $meta->is_immutable && ! { $meta->immutable_options }->{inline_constructor} ) {
1105             die "You made your application class ($class) immutable, "
1106                 . "but did not inline the constructor.\n"
1107                 . "This will break catalyst, please pass "
1108                 . "(replace_constructor => 1) when making your class immutable.\n";
1109         }
1110         $meta->make_immutable(replace_constructor => 1) unless $meta->is_immutable;
1111     }, Scope::Upper::SCOPE(1));
1112
1113     $class->setup_finalize;
1114 }
1115
1116
1117 =head2 $app->setup_finalize
1118
1119 A hook to attach modifiers to.
1120 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1121 Also better than C< setup_finished(); >, as that is a getter method.
1122
1123     sub setup_finalize {
1124
1125         my $app = shift;
1126
1127         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1128
1129         $app->next::method(@_);
1130
1131
1132     }
1133
1134 =cut
1135
1136 sub setup_finalize {
1137     my ($class) = @_;
1138     $class->setup_finished(1);
1139 }
1140
1141 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1142
1143 =head2 $c->uri_for( $path, @args?, \%query_values? )
1144
1145 =over
1146
1147 =item $action
1148
1149 A Catalyst::Action object representing the Catalyst action you want to
1150 create a URI for. To get one for an action in the current controller,
1151 use C<< $c->action('someactionname') >>. To get one from different
1152 controller, fetch the controller using C<< $c->controller() >>, then
1153 call C<action_for> on it.
1154
1155 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1156 using C<< $c->req->captures >>.
1157
1158   # For the current action
1159   $c->uri_for($c->action, $c->req->captures);
1160
1161   # For the Foo action in the Bar controller
1162   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1163
1164 =back
1165
1166 =cut
1167
1168 sub uri_for {
1169     my ( $c, $path, @args ) = @_;
1170
1171     if ( blessed($path) ) { # action object
1172         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1173                          ? shift(@args)
1174                          : [] );
1175         my $action = $path;
1176         $path = $c->dispatcher->uri_for_action($action, $captures);
1177         if (not defined $path) {
1178             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1179                 if $c->debug;
1180             return undef;
1181         }
1182         $path = '/' if $path eq '';
1183     }
1184
1185     undef($path) if (defined $path && $path eq '');
1186
1187     my $params =
1188       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1189
1190     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1191     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1192
1193     unshift(@args, $path);
1194
1195     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1196         my $namespace = $c->namespace;
1197         if (defined $path) { # cheesy hack to handle path '../foo'
1198            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1199         }
1200         unshift(@args, $namespace || '');
1201     }
1202
1203     # join args with '/', or a blank string
1204     my $args = join('/', grep { defined($_) } @args);
1205     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1206     $args =~ s!^/+!!;
1207     my $base = $c->req->base;
1208     my $class = ref($base);
1209     $base =~ s{(?<!/)$}{/};
1210
1211     my $query = '';
1212
1213     if (my @keys = keys %$params) {
1214       # somewhat lifted from URI::_query's query_form
1215       $query = '?'.join('&', map {
1216           my $val = $params->{$_};
1217           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1218           s/ /+/g;
1219           my $key = $_;
1220           $val = '' unless defined $val;
1221           (map {
1222               $_ = "$_";
1223               utf8::encode( $_ ) if utf8::is_utf8($_);
1224               # using the URI::Escape pattern here so utf8 chars survive
1225               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1226               s/ /+/g;
1227               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1228       } @keys);
1229     }
1230
1231     my $res = bless(\"${base}${args}${query}", $class);
1232     $res;
1233 }
1234
1235 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1236
1237 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1238
1239 =over
1240
1241 =item $path
1242
1243 A private path to the Catalyst action you want to create a URI for.
1244
1245 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1246 >> and passing the resulting C<$action> and the remaining arguments to C<<
1247 $c->uri_for >>.
1248
1249 You can also pass in a Catalyst::Action object, in which case it is passed to
1250 C<< $c->uri_for >>.
1251
1252 =back
1253
1254 =cut
1255
1256 sub uri_for_action {
1257     my ( $c, $path, @args ) = @_;
1258     my $action = blessed($path)
1259       ? $path
1260       : $c->dispatcher->get_action_by_path($path);
1261     unless (defined $action) {
1262       croak "Can't find action for path '$path'";
1263     }
1264     return $c->uri_for( $action, @args );
1265 }
1266
1267 =head2 $c->welcome_message
1268
1269 Returns the Catalyst welcome HTML page.
1270
1271 =cut
1272
1273 sub welcome_message {
1274     my $c      = shift;
1275     my $name   = $c->config->{name};
1276     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1277     my $prefix = Catalyst::Utils::appprefix( ref $c );
1278     $c->response->content_type('text/html; charset=utf-8');
1279     return <<"EOF";
1280 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1281     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1282 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1283     <head>
1284     <meta http-equiv="Content-Language" content="en" />
1285     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1286         <title>$name on Catalyst $VERSION</title>
1287         <style type="text/css">
1288             body {
1289                 color: #000;
1290                 background-color: #eee;
1291             }
1292             div#content {
1293                 width: 640px;
1294                 margin-left: auto;
1295                 margin-right: auto;
1296                 margin-top: 10px;
1297                 margin-bottom: 10px;
1298                 text-align: left;
1299                 background-color: #ccc;
1300                 border: 1px solid #aaa;
1301             }
1302             p, h1, h2 {
1303                 margin-left: 20px;
1304                 margin-right: 20px;
1305                 font-family: verdana, tahoma, sans-serif;
1306             }
1307             a {
1308                 font-family: verdana, tahoma, sans-serif;
1309             }
1310             :link, :visited {
1311                     text-decoration: none;
1312                     color: #b00;
1313                     border-bottom: 1px dotted #bbb;
1314             }
1315             :link:hover, :visited:hover {
1316                     color: #555;
1317             }
1318             div#topbar {
1319                 margin: 0px;
1320             }
1321             pre {
1322                 margin: 10px;
1323                 padding: 8px;
1324             }
1325             div#answers {
1326                 padding: 8px;
1327                 margin: 10px;
1328                 background-color: #fff;
1329                 border: 1px solid #aaa;
1330             }
1331             h1 {
1332                 font-size: 0.9em;
1333                 font-weight: normal;
1334                 text-align: center;
1335             }
1336             h2 {
1337                 font-size: 1.0em;
1338             }
1339             p {
1340                 font-size: 0.9em;
1341             }
1342             p img {
1343                 float: right;
1344                 margin-left: 10px;
1345             }
1346             span#appname {
1347                 font-weight: bold;
1348                 font-size: 1.6em;
1349             }
1350         </style>
1351     </head>
1352     <body>
1353         <div id="content">
1354             <div id="topbar">
1355                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1356                     $VERSION</h1>
1357              </div>
1358              <div id="answers">
1359                  <p>
1360                  <img src="$logo" alt="Catalyst Logo" />
1361                  </p>
1362                  <p>Welcome to the  world of Catalyst.
1363                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1364                     framework will make web development something you had
1365                     never expected it to be: Fun, rewarding, and quick.</p>
1366                  <h2>What to do now?</h2>
1367                  <p>That really depends  on what <b>you</b> want to do.
1368                     We do, however, provide you with a few starting points.</p>
1369                  <p>If you want to jump right into web development with Catalyst
1370                     you might want to start with a tutorial.</p>
1371 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1372 </pre>
1373 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1374 <pre>
1375 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1376 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1377 </code></pre>
1378                  <h2>What to do next?</h2>
1379                  <p>Next it's time to write an actual application. Use the
1380                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1381                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1382                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1383                     they can save you a lot of work.</p>
1384                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1385                     <p>Also, be sure to check out the vast and growing
1386                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1387                     you are likely to find what you need there.
1388                     </p>
1389
1390                  <h2>Need help?</h2>
1391                  <p>Catalyst has a very active community. Here are the main places to
1392                     get in touch with us.</p>
1393                  <ul>
1394                      <li>
1395                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1396                      </li>
1397                      <li>
1398                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1399                      </li>
1400                      <li>
1401                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1402                      </li>
1403                  </ul>
1404                  <h2>In conclusion</h2>
1405                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1406                     as we enjoyed making it. Please contact us if you have ideas
1407                     for improvement or other feedback.</p>
1408              </div>
1409          </div>
1410     </body>
1411 </html>
1412 EOF
1413 }
1414
1415 =head1 INTERNAL METHODS
1416
1417 These methods are not meant to be used by end users.
1418
1419 =head2 $c->components
1420
1421 Returns a hash of components.
1422
1423 =head2 $c->context_class
1424
1425 Returns or sets the context class.
1426
1427 =head2 $c->counter
1428
1429 Returns a hashref containing coderefs and execution counts (needed for
1430 deep recursion detection).
1431
1432 =head2 $c->depth
1433
1434 Returns the number of actions on the current internal execution stack.
1435
1436 =head2 $c->dispatch
1437
1438 Dispatches a request to actions.
1439
1440 =cut
1441
1442 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1443
1444 =head2 $c->dispatcher_class
1445
1446 Returns or sets the dispatcher class.
1447
1448 =head2 $c->dump_these
1449
1450 Returns a list of 2-element array references (name, structure) pairs
1451 that will be dumped on the error page in debug mode.
1452
1453 =cut
1454
1455 sub dump_these {
1456     my $c = shift;
1457     [ Request => $c->req ],
1458     [ Response => $c->res ],
1459     [ Stash => $c->stash ],
1460     [ Config => $c->config ];
1461 }
1462
1463 =head2 $c->engine_class
1464
1465 Returns or sets the engine class.
1466
1467 =head2 $c->execute( $class, $coderef )
1468
1469 Execute a coderef in given class and catch exceptions. Errors are available
1470 via $c->error.
1471
1472 =cut
1473
1474 sub execute {
1475     my ( $c, $class, $code ) = @_;
1476     $class = $c->component($class) || $class;
1477     $c->state(0);
1478
1479     if ( $c->depth >= $RECURSION ) {
1480         my $action = $code->reverse();
1481         $action = "/$action" unless $action =~ /->/;
1482         my $error = qq/Deep recursion detected calling "${action}"/;
1483         $c->log->error($error);
1484         $c->error($error);
1485         $c->state(0);
1486         return $c->state;
1487     }
1488
1489     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1490
1491     push( @{ $c->stack }, $code );
1492
1493     no warnings 'recursion';
1494     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1495
1496     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1497
1498     my $last = pop( @{ $c->stack } );
1499
1500     if ( my $error = $@ ) {
1501         if ( !ref($error) and $error eq $DETACH ) {
1502             die $DETACH if($c->depth > 1);
1503         }
1504         elsif ( !ref($error) and $error eq $GO ) {
1505             die $GO if($c->depth > 0);
1506         }
1507         else {
1508             unless ( ref $error ) {
1509                 no warnings 'uninitialized';
1510                 chomp $error;
1511                 my $class = $last->class;
1512                 my $name  = $last->name;
1513                 $error = qq/Caught exception in $class->$name "$error"/;
1514             }
1515             $c->error($error);
1516             $c->state(0);
1517         }
1518     }
1519     return $c->state;
1520 }
1521
1522 sub _stats_start_execute {
1523     my ( $c, $code ) = @_;
1524
1525     return if ( ( $code->name =~ /^_.*/ )
1526         && ( !$c->config->{show_internal_actions} ) );
1527
1528     my $action_name = $code->reverse();
1529     $c->counter->{$action_name}++;
1530
1531     my $action = $action_name;
1532     $action = "/$action" unless $action =~ /->/;
1533
1534     # determine if the call was the result of a forward
1535     # this is done by walking up the call stack and looking for a calling
1536     # sub of Catalyst::forward before the eval
1537     my $callsub = q{};
1538     for my $index ( 2 .. 11 ) {
1539         last
1540         if ( ( caller($index) )[0] eq 'Catalyst'
1541             && ( caller($index) )[3] eq '(eval)' );
1542
1543         if ( ( caller($index) )[3] =~ /forward$/ ) {
1544             $callsub = ( caller($index) )[3];
1545             $action  = "-> $action";
1546             last;
1547         }
1548     }
1549
1550     my $uid = $action_name . $c->counter->{$action_name};
1551
1552     # is this a root-level call or a forwarded call?
1553     if ( $callsub =~ /forward$/ ) {
1554
1555         # forward, locate the caller
1556         if ( my $parent = $c->stack->[-1] ) {
1557             $c->stats->profile(
1558                 begin  => $action,
1559                 parent => "$parent" . $c->counter->{"$parent"},
1560                 uid    => $uid,
1561             );
1562         }
1563         else {
1564
1565             # forward with no caller may come from a plugin
1566             $c->stats->profile(
1567                 begin => $action,
1568                 uid   => $uid,
1569             );
1570         }
1571     }
1572     else {
1573
1574         # root-level call
1575         $c->stats->profile(
1576             begin => $action,
1577             uid   => $uid,
1578         );
1579     }
1580     return $action;
1581
1582 }
1583
1584 sub _stats_finish_execute {
1585     my ( $c, $info ) = @_;
1586     $c->stats->profile( end => $info );
1587 }
1588
1589 =head2 $c->_localize_fields( sub { }, \%keys );
1590
1591 =cut
1592
1593 #Why does this exist? This is no longer safe and WILL NOT WORK.
1594 # it doesnt seem to be used anywhere. can we remove it?
1595 sub _localize_fields {
1596     my ( $c, $localized, $code ) = ( @_ );
1597
1598     my $request = delete $localized->{request} || {};
1599     my $response = delete $localized->{response} || {};
1600
1601     local @{ $c }{ keys %$localized } = values %$localized;
1602     local @{ $c->request }{ keys %$request } = values %$request;
1603     local @{ $c->response }{ keys %$response } = values %$response;
1604
1605     $code->();
1606 }
1607
1608 =head2 $c->finalize
1609
1610 Finalizes the request.
1611
1612 =cut
1613
1614 sub finalize {
1615     my $c = shift;
1616
1617     for my $error ( @{ $c->error } ) {
1618         $c->log->error($error);
1619     }
1620
1621     # Allow engine to handle finalize flow (for POE)
1622     my $engine = $c->engine;
1623     if ( my $code = $engine->can('finalize') ) {
1624         $engine->$code($c);
1625     }
1626     else {
1627
1628         $c->finalize_uploads;
1629
1630         # Error
1631         if ( $#{ $c->error } >= 0 ) {
1632             $c->finalize_error;
1633         }
1634
1635         $c->finalize_headers;
1636
1637         # HEAD request
1638         if ( $c->request->method eq 'HEAD' ) {
1639             $c->response->body('');
1640         }
1641
1642         $c->finalize_body;
1643     }
1644
1645     if ($c->use_stats) {
1646         my $elapsed = sprintf '%f', $c->stats->elapsed;
1647         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1648         $c->log->info(
1649             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1650     }
1651
1652     return $c->response->status;
1653 }
1654
1655 =head2 $c->finalize_body
1656
1657 Finalizes body.
1658
1659 =cut
1660
1661 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1662
1663 =head2 $c->finalize_cookies
1664
1665 Finalizes cookies.
1666
1667 =cut
1668
1669 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1670
1671 =head2 $c->finalize_error
1672
1673 Finalizes error.
1674
1675 =cut
1676
1677 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1678
1679 =head2 $c->finalize_headers
1680
1681 Finalizes headers.
1682
1683 =cut
1684
1685 sub finalize_headers {
1686     my $c = shift;
1687
1688     my $response = $c->response; #accessor calls can add up?
1689
1690     # Check if we already finalized headers
1691     return if $response->finalized_headers;
1692
1693     # Handle redirects
1694     if ( my $location = $response->redirect ) {
1695         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1696         $response->header( Location => $location );
1697
1698         if ( !$response->has_body ) {
1699             # Add a default body if none is already present
1700             $response->body(
1701                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1702             );
1703         }
1704     }
1705
1706     # Content-Length
1707     if ( $response->body && !$response->content_length ) {
1708
1709         # get the length from a filehandle
1710         if ( blessed( $response->body ) && $response->body->can('read') )
1711         {
1712             my $stat = stat $response->body;
1713             if ( $stat && $stat->size > 0 ) {
1714                 $response->content_length( $stat->size );
1715             }
1716             else {
1717                 $c->log->warn('Serving filehandle without a content-length');
1718             }
1719         }
1720         else {
1721             # everything should be bytes at this point, but just in case
1722             $response->content_length( bytes::length( $response->body ) );
1723         }
1724     }
1725
1726     # Errors
1727     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1728         $response->headers->remove_header("Content-Length");
1729         $response->body('');
1730     }
1731
1732     $c->finalize_cookies;
1733
1734     $c->engine->finalize_headers( $c, @_ );
1735
1736     # Done
1737     $response->finalized_headers(1);
1738 }
1739
1740 =head2 $c->finalize_output
1741
1742 An alias for finalize_body.
1743
1744 =head2 $c->finalize_read
1745
1746 Finalizes the input after reading is complete.
1747
1748 =cut
1749
1750 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1751
1752 =head2 $c->finalize_uploads
1753
1754 Finalizes uploads. Cleans up any temporary files.
1755
1756 =cut
1757
1758 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1759
1760 =head2 $c->get_action( $action, $namespace )
1761
1762 Gets an action in a given namespace.
1763
1764 =cut
1765
1766 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1767
1768 =head2 $c->get_actions( $action, $namespace )
1769
1770 Gets all actions of a given name in a namespace and all parent
1771 namespaces.
1772
1773 =cut
1774
1775 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1776
1777 =head2 $c->handle_request( $class, @arguments )
1778
1779 Called to handle each HTTP request.
1780
1781 =cut
1782
1783 sub handle_request {
1784     my ( $class, @arguments ) = @_;
1785
1786     # Always expect worst case!
1787     my $status = -1;
1788     eval {
1789         if ($class->debug) {
1790             my $secs = time - $START || 1;
1791             my $av = sprintf '%.3f', $COUNT / $secs;
1792             my $time = localtime time;
1793             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1794         }
1795
1796         my $c = $class->prepare(@arguments);
1797         $c->dispatch;
1798         $status = $c->finalize;
1799     };
1800
1801     if ( my $error = $@ ) {
1802         chomp $error;
1803         $class->log->error(qq/Caught exception in engine "$error"/);
1804     }
1805
1806     $COUNT++;
1807
1808     if(my $coderef = $class->log->can('_flush')){
1809         $class->log->$coderef();
1810     }
1811     return $status;
1812 }
1813
1814 =head2 $c->prepare( @arguments )
1815
1816 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1817 etc.).
1818
1819 =cut
1820
1821 sub prepare {
1822     my ( $class, @arguments ) = @_;
1823
1824     # XXX
1825     # After the app/ctxt split, this should become an attribute based on something passed
1826     # into the application.
1827     $class->context_class( ref $class || $class ) unless $class->context_class;
1828
1829     my $c = $class->context_class->new({});
1830
1831     # For on-demand data
1832     $c->request->_context($c);
1833     $c->response->_context($c);
1834
1835     #surely this is not the most efficient way to do things...
1836     $c->stats($class->stats_class->new)->enable($c->use_stats);
1837     if ( $c->debug ) {
1838         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1839     }
1840
1841     #XXX reuse coderef from can
1842     # Allow engine to direct the prepare flow (for POE)
1843     if ( $c->engine->can('prepare') ) {
1844         $c->engine->prepare( $c, @arguments );
1845     }
1846     else {
1847         $c->prepare_request(@arguments);
1848         $c->prepare_connection;
1849         $c->prepare_query_parameters;
1850         $c->prepare_headers;
1851         $c->prepare_cookies;
1852         $c->prepare_path;
1853
1854         # Prepare the body for reading, either by prepare_body
1855         # or the user, if they are using $c->read
1856         $c->prepare_read;
1857
1858         # Parse the body unless the user wants it on-demand
1859         unless ( $c->config->{parse_on_demand} ) {
1860             $c->prepare_body;
1861         }
1862     }
1863
1864     my $method  = $c->req->method  || '';
1865     my $path    = $c->req->path;
1866     $path       = '/' unless length $path;
1867     my $address = $c->req->address || '';
1868
1869     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1870       if $c->debug;
1871
1872     $c->prepare_action;
1873
1874     return $c;
1875 }
1876
1877 =head2 $c->prepare_action
1878
1879 Prepares action. See L<Catalyst::Dispatcher>.
1880
1881 =cut
1882
1883 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1884
1885 =head2 $c->prepare_body
1886
1887 Prepares message body.
1888
1889 =cut
1890
1891 sub prepare_body {
1892     my $c = shift;
1893
1894     return if $c->request->_has_body;
1895
1896     # Initialize on-demand data
1897     $c->engine->prepare_body( $c, @_ );
1898     $c->prepare_parameters;
1899     $c->prepare_uploads;
1900
1901     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1902         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1903         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1904             my $param = $c->req->body_parameters->{$key};
1905             my $value = defined($param) ? $param : '';
1906             $t->row( $key,
1907                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1908         }
1909         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1910     }
1911 }
1912
1913 =head2 $c->prepare_body_chunk( $chunk )
1914
1915 Prepares a chunk of data before sending it to L<HTTP::Body>.
1916
1917 See L<Catalyst::Engine>.
1918
1919 =cut
1920
1921 sub prepare_body_chunk {
1922     my $c = shift;
1923     $c->engine->prepare_body_chunk( $c, @_ );
1924 }
1925
1926 =head2 $c->prepare_body_parameters
1927
1928 Prepares body parameters.
1929
1930 =cut
1931
1932 sub prepare_body_parameters {
1933     my $c = shift;
1934     $c->engine->prepare_body_parameters( $c, @_ );
1935 }
1936
1937 =head2 $c->prepare_connection
1938
1939 Prepares connection.
1940
1941 =cut
1942
1943 sub prepare_connection {
1944     my $c = shift;
1945     $c->engine->prepare_connection( $c, @_ );
1946 }
1947
1948 =head2 $c->prepare_cookies
1949
1950 Prepares cookies.
1951
1952 =cut
1953
1954 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1955
1956 =head2 $c->prepare_headers
1957
1958 Prepares headers.
1959
1960 =cut
1961
1962 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1963
1964 =head2 $c->prepare_parameters
1965
1966 Prepares parameters.
1967
1968 =cut
1969
1970 sub prepare_parameters {
1971     my $c = shift;
1972     $c->prepare_body_parameters;
1973     $c->engine->prepare_parameters( $c, @_ );
1974 }
1975
1976 =head2 $c->prepare_path
1977
1978 Prepares path and base.
1979
1980 =cut
1981
1982 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1983
1984 =head2 $c->prepare_query_parameters
1985
1986 Prepares query parameters.
1987
1988 =cut
1989
1990 sub prepare_query_parameters {
1991     my $c = shift;
1992
1993     $c->engine->prepare_query_parameters( $c, @_ );
1994
1995     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1996         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1997         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1998             my $param = $c->req->query_parameters->{$key};
1999             my $value = defined($param) ? $param : '';
2000             $t->row( $key,
2001                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2002         }
2003         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2004     }
2005 }
2006
2007 =head2 $c->prepare_read
2008
2009 Prepares the input for reading.
2010
2011 =cut
2012
2013 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2014
2015 =head2 $c->prepare_request
2016
2017 Prepares the engine request.
2018
2019 =cut
2020
2021 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2022
2023 =head2 $c->prepare_uploads
2024
2025 Prepares uploads.
2026
2027 =cut
2028
2029 sub prepare_uploads {
2030     my $c = shift;
2031
2032     $c->engine->prepare_uploads( $c, @_ );
2033
2034     if ( $c->debug && keys %{ $c->request->uploads } ) {
2035         my $t = Text::SimpleTable->new(
2036             [ 12, 'Parameter' ],
2037             [ 26, 'Filename' ],
2038             [ 18, 'Type' ],
2039             [ 9,  'Size' ]
2040         );
2041         for my $key ( sort keys %{ $c->request->uploads } ) {
2042             my $upload = $c->request->uploads->{$key};
2043             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2044                 $t->row( $key, $u->filename, $u->type, $u->size );
2045             }
2046         }
2047         $c->log->debug( "File Uploads are:\n" . $t->draw );
2048     }
2049 }
2050
2051 =head2 $c->prepare_write
2052
2053 Prepares the output for writing.
2054
2055 =cut
2056
2057 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2058
2059 =head2 $c->request_class
2060
2061 Returns or sets the request class.
2062
2063 =head2 $c->response_class
2064
2065 Returns or sets the response class.
2066
2067 =head2 $c->read( [$maxlength] )
2068
2069 Reads a chunk of data from the request body. This method is designed to
2070 be used in a while loop, reading C<$maxlength> bytes on every call.
2071 C<$maxlength> defaults to the size of the request if not specified.
2072
2073 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
2074 directly.
2075
2076 Warning: If you use read(), Catalyst will not process the body,
2077 so you will not be able to access POST parameters or file uploads via
2078 $c->request.  You must handle all body parsing yourself.
2079
2080 =cut
2081
2082 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2083
2084 =head2 $c->run
2085
2086 Starts the engine.
2087
2088 =cut
2089
2090 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2091
2092 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2093
2094 Sets an action in a given namespace.
2095
2096 =cut
2097
2098 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2099
2100 =head2 $c->setup_actions($component)
2101
2102 Sets up actions for a component.
2103
2104 =cut
2105
2106 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2107
2108 =head2 $c->setup_components
2109
2110 Sets up components. Specify a C<setup_components> config option to pass
2111 additional options directly to L<Module::Pluggable>. To add additional
2112 search paths, specify a key named C<search_extra> as an array
2113 reference. Items in the array beginning with C<::> will have the
2114 application class name prepended to them.
2115
2116 All components found will also have any
2117 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2118 Note, that modules which are B<not> an I<inner package> of the main
2119 file namespace loaded will not be instantiated as components.
2120
2121 =cut
2122
2123 sub setup_components {
2124     my $class = shift;
2125
2126     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2127     my $config  = $class->config->{ setup_components };
2128     my $extra   = delete $config->{ search_extra } || [];
2129
2130     push @paths, @$extra;
2131
2132     my $locator = Module::Pluggable::Object->new(
2133         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2134         %$config
2135     );
2136
2137     my @comps = sort { length $a <=> length $b } $locator->plugins;
2138     my %comps = map { $_ => 1 } @comps;
2139
2140     my $deprecated_component_names = grep { /::[CMV]::/ } @comps;
2141     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2142         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2143     ) if $deprecated_component_names;
2144
2145     for my $component ( @comps ) {
2146
2147         # We pass ignore_loaded here so that overlay files for (e.g.)
2148         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2149         # we know M::P::O found a file on disk so this is safe
2150
2151         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2152         #Class::MOP::load_class($component);
2153
2154         my $module  = $class->setup_component( $component );
2155         my %modules = (
2156             $component => $module,
2157             map {
2158                 $_ => $class->setup_component( $_ )
2159             } grep {
2160               not exists $comps{$_}
2161             } Devel::InnerPackage::list_packages( $component )
2162         );
2163
2164         for my $key ( keys %modules ) {
2165             $class->components->{ $key } = $modules{ $key };
2166         }
2167     }
2168 }
2169
2170 =head2 $c->setup_component
2171
2172 =cut
2173
2174 sub _controller_init_base_classes {
2175     my ($app_class, $component) = @_;
2176     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2177         Moose->init_meta( for_class => $class )
2178             unless find_meta($class);
2179     }
2180 }
2181
2182 sub setup_component {
2183     my( $class, $component ) = @_;
2184
2185     unless ( $component->can( 'COMPONENT' ) ) {
2186         return $component;
2187     }
2188
2189     # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2190     #         nearest to Catalyst::Controller first, no matter what order stuff happens
2191     #         to be loaded. There are TODO tests in Moose for this, see
2192     #         f2391d17574eff81d911b97be15ea51080500003
2193     if ($component->isa('Catalyst::Controller')) {
2194         $class->_controller_init_base_classes($component);
2195     }
2196
2197     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2198     my $config = $class->config->{ $suffix } || {};
2199
2200     my $instance = eval { $component->COMPONENT( $class, $config ); };
2201
2202     if ( my $error = $@ ) {
2203         chomp $error;
2204         Catalyst::Exception->throw(
2205             message => qq/Couldn't instantiate component "$component", "$error"/
2206         );
2207     }
2208
2209     unless (blessed $instance) {
2210         my $metaclass = Moose::Util::find_meta($component);
2211         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2212         my $component_method_from = $method_meta->associated_metaclass->name;
2213         my $value = defined($instance) ? $instance : 'undef';
2214         Catalyst::Exception->throw(
2215             message =>
2216             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2217         );
2218     }
2219     return $instance;
2220 }
2221
2222 =head2 $c->setup_dispatcher
2223
2224 Sets up dispatcher.
2225
2226 =cut
2227
2228 sub setup_dispatcher {
2229     my ( $class, $dispatcher ) = @_;
2230
2231     if ($dispatcher) {
2232         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2233     }
2234
2235     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2236         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2237     }
2238
2239     unless ($dispatcher) {
2240         $dispatcher = $class->dispatcher_class;
2241     }
2242
2243     Class::MOP::load_class($dispatcher);
2244
2245     # dispatcher instance
2246     $class->dispatcher( $dispatcher->new );
2247 }
2248
2249 =head2 $c->setup_engine
2250
2251 Sets up engine.
2252
2253 =cut
2254
2255 sub setup_engine {
2256     my ( $class, $engine ) = @_;
2257
2258     if ($engine) {
2259         $engine = 'Catalyst::Engine::' . $engine;
2260     }
2261
2262     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2263         $engine = 'Catalyst::Engine::' . $env;
2264     }
2265
2266     if ( $ENV{MOD_PERL} ) {
2267         my $meta = Class::MOP::get_metaclass_by_name($class);
2268
2269         # create the apache method
2270         $meta->add_method('apache' => sub { shift->engine->apache });
2271
2272         my ( $software, $version ) =
2273           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2274
2275         $version =~ s/_//g;
2276         $version =~ s/(\.[^.]+)\./$1/g;
2277
2278         if ( $software eq 'mod_perl' ) {
2279
2280             if ( !$engine ) {
2281
2282                 if ( $version >= 1.99922 ) {
2283                     $engine = 'Catalyst::Engine::Apache2::MP20';
2284                 }
2285
2286                 elsif ( $version >= 1.9901 ) {
2287                     $engine = 'Catalyst::Engine::Apache2::MP19';
2288                 }
2289
2290                 elsif ( $version >= 1.24 ) {
2291                     $engine = 'Catalyst::Engine::Apache::MP13';
2292                 }
2293
2294                 else {
2295                     Catalyst::Exception->throw( message =>
2296                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2297                 }
2298
2299             }
2300
2301             # install the correct mod_perl handler
2302             if ( $version >= 1.9901 ) {
2303                 *handler = sub  : method {
2304                     shift->handle_request(@_);
2305                 };
2306             }
2307             else {
2308                 *handler = sub ($$) { shift->handle_request(@_) };
2309             }
2310
2311         }
2312
2313         elsif ( $software eq 'Zeus-Perl' ) {
2314             $engine = 'Catalyst::Engine::Zeus';
2315         }
2316
2317         else {
2318             Catalyst::Exception->throw(
2319                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2320         }
2321     }
2322
2323     unless ($engine) {
2324         $engine = $class->engine_class;
2325     }
2326
2327     Class::MOP::load_class($engine);
2328
2329     # check for old engines that are no longer compatible
2330     my $old_engine;
2331     if ( $engine->isa('Catalyst::Engine::Apache')
2332         && !Catalyst::Engine::Apache->VERSION )
2333     {
2334         $old_engine = 1;
2335     }
2336
2337     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2338         && Catalyst::Engine::Server->VERSION le '0.02' )
2339     {
2340         $old_engine = 1;
2341     }
2342
2343     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2344         && $engine->VERSION eq '0.01' )
2345     {
2346         $old_engine = 1;
2347     }
2348
2349     elsif ($engine->isa('Catalyst::Engine::Zeus')
2350         && $engine->VERSION eq '0.01' )
2351     {
2352         $old_engine = 1;
2353     }
2354
2355     if ($old_engine) {
2356         Catalyst::Exception->throw( message =>
2357               qq/Engine "$engine" is not supported by this version of Catalyst/
2358         );
2359     }
2360
2361     # engine instance
2362     $class->engine( $engine->new );
2363 }
2364
2365 =head2 $c->setup_home
2366
2367 Sets up the home directory.
2368
2369 =cut
2370
2371 sub setup_home {
2372     my ( $class, $home ) = @_;
2373
2374     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2375         $home = $env;
2376     }
2377
2378     $home ||= Catalyst::Utils::home($class);
2379
2380     if ($home) {
2381         #I remember recently being scolded for assigning config values like this
2382         $class->config->{home} ||= $home;
2383         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2384     }
2385 }
2386
2387 =head2 $c->setup_log
2388
2389 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2390 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2391 log to.
2392
2393 This method also installs a C<debug> method that returns a true value into the
2394 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2395 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2396
2397 Note that if the log has already been setup, by either a previous call to
2398 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2399 that this method won't actually set up the log object.
2400
2401 =cut
2402
2403 sub setup_log {
2404     my ( $class, $levels ) = @_;
2405
2406     $levels ||= '';
2407     $levels =~ s/^\s+//;
2408     $levels =~ s/\s+$//;
2409     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2410
2411     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2412     if ( defined $env_debug ) {
2413         $levels{debug} = 1 if $env_debug; # Ugly!
2414         delete($levels{debug}) unless $env_debug;
2415     }
2416
2417     unless ( $class->log ) {
2418         $class->log( Catalyst::Log->new(keys %levels) );
2419     }
2420
2421     if ( $levels{debug} ) {
2422         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2423         $class->log->debug('Debug messages enabled');
2424     }
2425 }
2426
2427 =head2 $c->setup_plugins
2428
2429 Sets up plugins.
2430
2431 =cut
2432
2433 =head2 $c->setup_stats
2434
2435 Sets up timing statistics class.
2436
2437 =cut
2438
2439 sub setup_stats {
2440     my ( $class, $stats ) = @_;
2441
2442     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2443
2444     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2445     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2446         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2447         $class->log->debug('Statistics enabled');
2448     }
2449 }
2450
2451
2452 =head2 $c->registered_plugins
2453
2454 Returns a sorted list of the plugins which have either been stated in the
2455 import list or which have been added via C<< MyApp->plugin(@args); >>.
2456
2457 If passed a given plugin name, it will report a boolean value indicating
2458 whether or not that plugin is loaded.  A fully qualified name is required if
2459 the plugin name does not begin with C<Catalyst::Plugin::>.
2460
2461  if ($c->registered_plugins('Some::Plugin')) {
2462      ...
2463  }
2464
2465 =cut
2466
2467 {
2468
2469     sub registered_plugins {
2470         my $proto = shift;
2471         return sort keys %{ $proto->_plugins } unless @_;
2472         my $plugin = shift;
2473         return 1 if exists $proto->_plugins->{$plugin};
2474         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2475     }
2476
2477     sub _register_plugin {
2478         my ( $proto, $plugin, $instant ) = @_;
2479         my $class = ref $proto || $proto;
2480
2481         # no ignore_loaded here, the plugin may already have been
2482         # defined in memory and we don't want to error on "no file" if so
2483
2484         Class::MOP::load_class( $plugin );
2485
2486         $proto->_plugins->{$plugin} = 1;
2487         unless ($instant) {
2488             no strict 'refs';
2489             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2490               my @superclasses = ($plugin, $meta->superclasses );
2491               $meta->superclasses(@superclasses);
2492             } else {
2493               unshift @{"$class\::ISA"}, $plugin;
2494             }
2495         }
2496         return $class;
2497     }
2498
2499     sub setup_plugins {
2500         my ( $class, $plugins ) = @_;
2501
2502         $class->_plugins( {} ) unless $class->_plugins;
2503         $plugins ||= [];
2504         for my $plugin ( reverse @$plugins ) {
2505
2506             unless ( $plugin =~ s/\A\+// ) {
2507                 $plugin = "Catalyst::Plugin::$plugin";
2508             }
2509
2510             $class->_register_plugin($plugin);
2511         }
2512     }
2513 }
2514
2515 =head2 $c->stack
2516
2517 Returns an arrayref of the internal execution stack (actions that are
2518 currently executing).
2519
2520 =head2 $c->stats_class
2521
2522 Returns or sets the stats (timing statistics) class.
2523
2524 =head2 $c->use_stats
2525
2526 Returns 1 when stats collection is enabled.  Stats collection is enabled
2527 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2528 environment variable is set.
2529
2530 Note that this is a static method, not an accessor and should be overridden
2531 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2532
2533 =cut
2534
2535 sub use_stats { 0 }
2536
2537
2538 =head2 $c->write( $data )
2539
2540 Writes $data to the output stream. When using this method directly, you
2541 will need to manually set the C<Content-Length> header to the length of
2542 your output data, if known.
2543
2544 =cut
2545
2546 sub write {
2547     my $c = shift;
2548
2549     # Finalize headers if someone manually writes output
2550     $c->finalize_headers;
2551
2552     return $c->engine->write( $c, @_ );
2553 }
2554
2555 =head2 version
2556
2557 Returns the Catalyst version number. Mostly useful for "powered by"
2558 messages in template systems.
2559
2560 =cut
2561
2562 sub version { return $Catalyst::VERSION }
2563
2564 =head1 INTERNAL ACTIONS
2565
2566 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2567 C<_ACTION>, and C<_END>. These are by default not shown in the private
2568 action table, but you can make them visible with a config parameter.
2569
2570     MyApp->config->{show_internal_actions} = 1;
2571
2572 =head1 CASE SENSITIVITY
2573
2574 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2575 mapped to C</foo/bar>. You can activate case sensitivity with a config
2576 parameter.
2577
2578     MyApp->config->{case_sensitive} = 1;
2579
2580 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2581
2582 =head1 ON-DEMAND PARSER
2583
2584 The request body is usually parsed at the beginning of a request,
2585 but if you want to handle input yourself, you can enable on-demand
2586 parsing with a config parameter.
2587
2588     MyApp->config->{parse_on_demand} = 1;
2589
2590 =head1 PROXY SUPPORT
2591
2592 Many production servers operate using the common double-server approach,
2593 with a lightweight frontend web server passing requests to a larger
2594 backend server. An application running on the backend server must deal
2595 with two problems: the remote user always appears to be C<127.0.0.1> and
2596 the server's hostname will appear to be C<localhost> regardless of the
2597 virtual host that the user connected through.
2598
2599 Catalyst will automatically detect this situation when you are running
2600 the frontend and backend servers on the same machine. The following
2601 changes are made to the request.
2602
2603     $c->req->address is set to the user's real IP address, as read from
2604     the HTTP X-Forwarded-For header.
2605
2606     The host value for $c->req->base and $c->req->uri is set to the real
2607     host, as read from the HTTP X-Forwarded-Host header.
2608
2609 Obviously, your web server must support these headers for this to work.
2610
2611 In a more complex server farm environment where you may have your
2612 frontend proxy server(s) on different machines, you will need to set a
2613 configuration option to tell Catalyst to read the proxied data from the
2614 headers.
2615
2616     MyApp->config->{using_frontend_proxy} = 1;
2617
2618 If you do not wish to use the proxy support at all, you may set:
2619
2620     MyApp->config->{ignore_frontend_proxy} = 1;
2621
2622 =head1 THREAD SAFETY
2623
2624 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2625 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2626 believe the Catalyst core to be thread-safe.
2627
2628 If you plan to operate in a threaded environment, remember that all other
2629 modules you are using must also be thread-safe. Some modules, most notably
2630 L<DBD::SQLite>, are not thread-safe.
2631
2632 =head1 SUPPORT
2633
2634 IRC:
2635
2636     Join #catalyst on irc.perl.org.
2637
2638 Mailing Lists:
2639
2640     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2641     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2642
2643 Web:
2644
2645     http://catalyst.perl.org
2646
2647 Wiki:
2648
2649     http://dev.catalyst.perl.org
2650
2651 =head1 SEE ALSO
2652
2653 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2654
2655 =head2 L<Catalyst::Manual> - The Catalyst Manual
2656
2657 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2658
2659 =head2 L<Catalyst::Engine> - Core engine
2660
2661 =head2 L<Catalyst::Log> - Log class.
2662
2663 =head2 L<Catalyst::Request> - Request object
2664
2665 =head2 L<Catalyst::Response> - Response object
2666
2667 =head2 L<Catalyst::Test> - The test suite.
2668
2669 =head1 PROJECT FOUNDER
2670
2671 sri: Sebastian Riedel <sri@cpan.org>
2672
2673 =head1 CONTRIBUTORS
2674
2675 abw: Andy Wardley
2676
2677 acme: Leon Brocard <leon@astray.com>
2678
2679 Andrew Bramble
2680
2681 Andrew Ford
2682
2683 Andrew Ruthven
2684
2685 andyg: Andy Grundman <andy@hybridized.org>
2686
2687 audreyt: Audrey Tang
2688
2689 bricas: Brian Cassidy <bricas@cpan.org>
2690
2691 Caelum: Rafael Kitover <rkitover@io.com>
2692
2693 chansen: Christian Hansen
2694
2695 chicks: Christopher Hicks
2696
2697 David E. Wheeler
2698
2699 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2700
2701 Drew Taylor
2702
2703 esskar: Sascha Kiefer
2704
2705 fireartist: Carl Franks <cfranks@cpan.org>
2706
2707 gabb: Danijel Milicevic
2708
2709 Gary Ashton Jones
2710
2711 Geoff Richards
2712
2713 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2714
2715 jcamacho: Juan Camacho
2716
2717 jhannah: Jay Hannah <jay@jays.net>
2718
2719 Jody Belka
2720
2721 Johan Lindstrom
2722
2723 jon: Jon Schutz <jjschutz@cpan.org>
2724
2725 marcus: Marcus Ramberg <mramberg@cpan.org>
2726
2727 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2728
2729 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2730
2731 mugwump: Sam Vilain
2732
2733 naughton: David Naughton
2734
2735 ningu: David Kamholz <dkamholz@cpan.org>
2736
2737 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2738
2739 numa: Dan Sully <daniel@cpan.org>
2740
2741 obra: Jesse Vincent
2742
2743 omega: Andreas Marienborg
2744
2745 Oleg Kostyuk <cub.uanic@gmail.com>
2746
2747 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2748
2749 rafl: Florian Ragwitz <rafl@debian.org>
2750
2751 sky: Arthur Bergman
2752
2753 the_jester: Jesse Sheidlower
2754
2755 t0m: Tomas Doran <bobtfish@bobtfish.net>
2756
2757 Ulf Edvinsson
2758
2759 willert: Sebastian Willert <willert@cpan.org>
2760
2761 =head1 LICENSE
2762
2763 This library is free software, you can redistribute it and/or modify it under
2764 the same terms as Perl itself.
2765
2766 =cut
2767
2768 no Moose;
2769
2770 __PACKAGE__->meta->make_immutable;
2771
2772 1;