lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use bytes;
   6 use Scope::Upper ();
   7 use Catalyst::Exception;
   8 use Catalyst::Log;
   9 use Catalyst::Request;
  10 use Catalyst::Request::Upload;
  11 use Catalyst::Response;
  12 use Catalyst::Utils;
  13 use Catalyst::Controller;
  14 use Devel::InnerPackage ();
  15 use File::stat;
  16 use Module::Pluggable::Object ();
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp shortmess/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 has stack => (is => 'ro', default => sub { [] });
  34 has stash => (is => 'rw', default => sub { {} });
  35 has state => (is => 'rw', default => 0);
  36 has stats => (is => 'rw');
  37 has action => (is => 'rw');
  38 has counter => (is => 'rw', default => sub { {} });
  39 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  40 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  41 has namespace => (is => 'rw');
  42
  43 sub depth { scalar @{ shift->stack || [] }; }
  44 sub comp { shift->component(@_) }
  45
  46 sub req {
  47     # carp "the use of req() is deprecated in favour of request()";
  48     my $self = shift; return $self->request(@_);
  49 }
  50 sub res {
  51     # carp "the use of res() is deprecated in favour of response()";
  52     my $self = shift; return $self->response(@_);
  53 }
  54
  55 # For backwards compatibility
  56 sub finalize_output { shift->finalize_body(@_) };
  57
  58 # For statistics
  59 our $COUNT     = 1;
  60 our $START     = time;
  61 our $RECURSION = 1000;
  62 our $DETACH    = "catalyst_detach\n";
  63 our $GO        = "catalyst_go\n";
  64
  65 #I imagine that very few of these really need to be class variables. if any.
  66 #maybe we should just make them attributes with a default?
  67 __PACKAGE__->mk_classdata($_)
  68   for qw/components arguments dispatcher engine log dispatcher_class
  69   engine_class context_class request_class response_class stats_class
  70   setup_finished/;
  71
  72 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  73 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  74 __PACKAGE__->request_class('Catalyst::Request');
  75 __PACKAGE__->response_class('Catalyst::Response');
  76 __PACKAGE__->stats_class('Catalyst::Stats');
  77
  78 # Remember to update this in Catalyst::Runtime as well!
  79
  80 our $VERSION = '5.8000_05';
  81
  82 sub import {
  83     my ( $class, @arguments ) = @_;
  84
  85     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  86     # callers @ISA.
  87     return unless $class eq 'Catalyst';
  88
  89     my $caller = caller();
  90     return if $caller eq 'main';
  91     my $meta = Moose::Meta::Class->initialize($caller);
  92     #Moose->import({ into => $caller }); #do we want to do this?
  93
  94     unless ( $caller->isa('Catalyst') ) {
  95         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  96         $meta->superclasses(@superclasses);
  97     }
  98     unless( $meta->has_method('meta') ){
  99         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 100     }
 101
 102     $caller->arguments( [@arguments] );
 103     $caller->setup_home;
 104 }
 105
 106 =head1 NAME
 107
 108 Catalyst - The Elegant MVC Web Application Framework
 109
 110 =head1 SYNOPSIS
 111
 112 See the L<Catalyst::Manual> distribution for comprehensive
 113 documentation and tutorials.
 114
 115     # Install Catalyst::Devel for helpers and other development tools
 116     # use the helper to create a new application
 117     catalyst.pl MyApp
 118
 119     # add models, views, controllers
 120     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 121     script/myapp_create.pl view MyTemplate TT
 122     script/myapp_create.pl controller Search
 123
 124     # built in testserver -- use -r to restart automatically on changes
 125     # --help to see all available options
 126     script/myapp_server.pl
 127
 128     # command line testing interface
 129     script/myapp_test.pl /yada
 130
 131     ### in lib/MyApp.pm
 132     use Catalyst qw/-Debug/; # include plugins here as well
 133
 134     ### In lib/MyApp/Controller/Root.pm (autocreated)
 135     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 136         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 137         $c->stash->{template} = 'foo.tt'; # set the template
 138         # lookup something from db -- stash vars are passed to TT
 139         $c->stash->{data} =
 140           $c->model('Database::Foo')->search( { country => $args[0] } );
 141         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 142             $c->forward( 'bar' ); # process another action
 143             # do something else after forward returns
 144         }
 145     }
 146
 147     # The foo.tt TT template can use the stash data from the database
 148     [% WHILE (item = data.next) %]
 149         [% item.foo %]
 150     [% END %]
 151
 152     # called for /bar/of/soap, /bar/of/soap/10, etc.
 153     sub bar : Path('/bar/of/soap') { ... }
 154
 155     # called for all actions, from the top-most controller downwards
 156     sub auto : Private {
 157         my ( $self, $c ) = @_;
 158         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 159             $c->res->redirect( '/login' ); # require login
 160             return 0; # abort request and go immediately to end()
 161         }
 162         return 1; # success; carry on to next action
 163     }
 164
 165     # called after all actions are finished
 166     sub end : Private {
 167         my ( $self, $c ) = @_;
 168         if ( scalar @{ $c->error } ) { ... } # handle errors
 169         return if $c->res->body; # already have a response
 170         $c->forward( 'MyApp::View::TT' ); # render template
 171     }
 172
 173     ### in MyApp/Controller/Foo.pm
 174     # called for /foo/bar
 175     sub bar : Local { ... }
 176
 177     # called for /blargle
 178     sub blargle : Global { ... }
 179
 180     # an index action matches /foo, but not /foo/1, etc.
 181     sub index : Private { ... }
 182
 183     ### in MyApp/Controller/Foo/Bar.pm
 184     # called for /foo/bar/baz
 185     sub baz : Local { ... }
 186
 187     # first Root auto is called, then Foo auto, then this
 188     sub auto : Private { ... }
 189
 190     # powerful regular expression paths are also possible
 191     sub details : Regex('^product/(\w+)/details$') {
 192         my ( $self, $c ) = @_;
 193         # extract the (\w+) from the URI
 194         my $product = $c->req->captures->[0];
 195     }
 196
 197 See L<Catalyst::Manual::Intro> for additional information.
 198
 199 =head1 DESCRIPTION
 200
 201 Catalyst is a modern framework for making web applications without the
 202 pain usually associated with this process. This document is a reference
 203 to the main Catalyst application. If you are a new user, we suggest you
 204 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 205
 206 See L<Catalyst::Manual> for more documentation.
 207
 208 Catalyst plugins can be loaded by naming them as arguments to the "use
 209 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 210 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 211 C<My::Module>.
 212
 213     use Catalyst qw/My::Module/;
 214
 215 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 216 fully qualify the name by using a unary plus:
 217
 218     use Catalyst qw/
 219         My::Module
 220         +Fully::Qualified::Plugin::Name
 221     /;
 222
 223 Special flags like C<-Debug> and C<-Engine> can also be specified as
 224 arguments when Catalyst is loaded:
 225
 226     use Catalyst qw/-Debug My::Module/;
 227
 228 The position of plugins and flags in the chain is important, because
 229 they are loaded in the order in which they appear.
 230
 231 The following flags are supported:
 232
 233 =head2 -Debug
 234
 235 Enables debug output. You can also force this setting from the system
 236 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 237 settings override the application, with <MYAPP>_DEBUG having the highest
 238 priority.
 239
 240 =head2 -Engine
 241
 242 Forces Catalyst to use a specific engine. Omit the
 243 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 244
 245     use Catalyst qw/-Engine=CGI/;
 246
 247 =head2 -Home
 248
 249 Forces Catalyst to use a specific home directory, e.g.:
 250
 251     use Catalyst qw[-Home=/usr/mst];
 252
 253 This can also be done in the shell environment by setting either the
 254 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 255 is replaced with the uppercased name of your application, any "::" in
 256 the name will be replaced with underscores, e.g. MyApp::Web should use
 257 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 258
 259 =head2 -Log
 260
 261     use Catalyst '-Log=warn,fatal,error';
 262
 263 Specifies a comma-delimited list of log levels.
 264
 265 =head2 -Stats
 266
 267 Enables statistics collection and reporting. You can also force this setting
 268 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 269 environment settings override the application, with <MYAPP>_STATS having the
 270 highest priority.
 271
 272 e.g.
 273
 274    use Catalyst qw/-Stats=1/
 275
 276 =head1 METHODS
 277
 278 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 279
 280 =head2 $c->action
 281
 282 Returns a L<Catalyst::Action> object for the current action, which
 283 stringifies to the action name. See L<Catalyst::Action>.
 284
 285 =head2 $c->namespace
 286
 287 Returns the namespace of the current action, i.e., the URI prefix
 288 corresponding to the controller of the current action. For example:
 289
 290     # in Controller::Foo::Bar
 291     $c->namespace; # returns 'foo/bar';
 292
 293 =head2 $c->request
 294
 295 =head2 $c->req
 296
 297 Returns the current L<Catalyst::Request> object, giving access to
 298 information about the current client request (including parameters,
 299 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 300
 301 =head2 REQUEST FLOW HANDLING
 302
 303 =head2 $c->forward( $action [, \@arguments ] )
 304
 305 =head2 $c->forward( $class, $method, [, \@arguments ] )
 306
 307 Forwards processing to another action, by its private name. If you give a
 308 class name but no method, C<process()> is called. You may also optionally
 309 pass arguments in an arrayref. The action will receive the arguments in
 310 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 311 C<< $c->req->args >> will be restored to the previous values.
 312
 313 Any data C<return>ed from the action forwarded to, will be returned by the
 314 call to forward.
 315
 316     my $foodata = $c->forward('/foo');
 317     $c->forward('index');
 318     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 319     $c->forward('MyApp::View::TT');
 320
 321 Note that forward implies an C<<eval { }>> around the call (actually
 322 C<execute> does), thus de-fatalizing all 'dies' within the called
 323 action. If you want C<die> to propagate you need to do something like:
 324
 325     $c->forward('foo');
 326     die $c->error if $c->error;
 327
 328 Or make sure to always return true values from your actions and write
 329 your code like this:
 330
 331     $c->forward('foo') || return;
 332
 333 =cut
 334
 335 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 336
 337 =head2 $c->detach( $action [, \@arguments ] )
 338
 339 =head2 $c->detach( $class, $method, [, \@arguments ] )
 340
 341 =head2 $c->detach()
 342
 343 The same as C<forward>, but doesn't return to the previous action when
 344 processing is finished.
 345
 346 When called with no arguments it escapes the processing chain entirely.
 347
 348 =cut
 349
 350 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 351
 352 =head2 $c->visit( $action [, \@arguments ] )
 353
 354 =head2 $c->visit( $class, $method, [, \@arguments ] )
 355
 356 Almost the same as C<forward>, but does a full dispatch, instead of just
 357 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 358 C<auto> and the method you go to are called, just like a new request.
 359
 360 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 361 This means, for example, that $c->action methods such as C<name>, C<class> and
 362 C<reverse> return information for the visited action when they are invoked
 363 within the visited action.  This is different from the behavior of C<forward>
 364 which continues to use the $c->action object from the caller action even when
 365 invoked from the callee.
 366
 367 C<$c-E<gt>stash> is kept unchanged.
 368
 369 In effect, C<visit> allows you to "wrap" another action, just as it
 370 would have been called by dispatching from a URL, while the analogous
 371 C<go> allows you to transfer control to another action as if it had
 372 been reached directly from a URL.
 373
 374 =cut
 375
 376 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 377
 378 =head2 $c->go( $action [, \@arguments ] )
 379
 380 =head2 $c->go( $class, $method, [, \@arguments ] )
 381
 382 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 383 instead of just calling the new C<$action> /
 384 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 385 method you visit are called, just like a new request.
 386
 387 C<$c-E<gt>stash> is kept unchanged.
 388
 389 =cut
 390
 391 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 392
 393 =head2 $c->response
 394
 395 =head2 $c->res
 396
 397 Returns the current L<Catalyst::Response> object, see there for details.
 398
 399 =head2 $c->stash
 400
 401 Returns a hashref to the stash, which may be used to store data and pass
 402 it between components during a request. You can also set hash keys by
 403 passing arguments. The stash is automatically sent to the view. The
 404 stash is cleared at the end of a request; it cannot be used for
 405 persistent storage (for this you must use a session; see
 406 L<Catalyst::Plugin::Session> for a complete system integrated with
 407 Catalyst).
 408
 409     $c->stash->{foo} = $bar;
 410     $c->stash( { moose => 'majestic', qux => 0 } );
 411     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 412
 413     # stash is automatically passed to the view for use in a template
 414     $c->forward( 'MyApp::View::TT' );
 415
 416 =cut
 417
 418 around stash => sub {
 419     my $orig = shift;
 420     my $c = shift;
 421     my $stash = $orig->($c);
 422     if (@_) {
 423         my $new_stash = @_ > 1 ? {@_} : $_[0];
 424         croak('stash takes a hash or hashref') unless ref $new_stash;
 425         foreach my $key ( keys %$new_stash ) {
 426           $stash->{$key} = $new_stash->{$key};
 427         }
 428     }
 429
 430     return $stash;
 431 };
 432
 433
 434 =head2 $c->error
 435
 436 =head2 $c->error($error, ...)
 437
 438 =head2 $c->error($arrayref)
 439
 440 Returns an arrayref containing error messages.  If Catalyst encounters an
 441 error while processing a request, it stores the error in $c->error.  This
 442 method should only be used to store fatal error messages.
 443
 444     my @error = @{ $c->error };
 445
 446 Add a new error.
 447
 448     $c->error('Something bad happened');
 449
 450 =cut
 451
 452 sub error {
 453     my $c = shift;
 454     if ( $_[0] ) {
 455         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 456         croak @$error unless ref $c;
 457         push @{ $c->{error} }, @$error;
 458     }
 459     elsif ( defined $_[0] ) { $c->{error} = undef }
 460     return $c->{error} || [];
 461 }
 462
 463
 464 =head2 $c->state
 465
 466 Contains the return value of the last executed action.
 467
 468 =head2 $c->clear_errors
 469
 470 Clear errors.  You probably don't want to clear the errors unless you are
 471 implementing a custom error screen.
 472
 473 This is equivalent to running
 474
 475     $c->error(0);
 476
 477 =cut
 478
 479 sub clear_errors {
 480     my $c = shift;
 481     $c->error(0);
 482 }
 483
 484 # search components given a name and some prefixes
 485 sub _comp_search_prefixes {
 486     my ( $c, $name, @prefixes ) = @_;
 487     my $appclass = ref $c || $c;
 488     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 489
 490     # map the original component name to the sub part that we will search against
 491     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 492         grep { /$filter/ } keys %{ $c->components };
 493
 494     # undef for a name will return all
 495     return keys %eligible if !defined $name;
 496
 497     my $query  = ref $name ? $name : qr/^$name$/i;
 498     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 499
 500     return map { $c->components->{ $_ } } @result if @result;
 501
 502     # if we were given a regexp to search against, we're done.
 503     return if ref $name;
 504
 505     # regexp fallback
 506     $query  = qr/$name/i;
 507     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 508
 509     # no results? try against full names
 510     if( !@result ) {
 511         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 512     }
 513
 514     # don't warn if we didn't find any results, it just might not exist
 515     if( @result ) {
 516         my $msg = "Used regexp fallback for \$c->model('${name}'), which found '" .
 517            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 518            "component resolution is unreliable and unsafe.";
 519         my $short = $result[0];
 520         $short =~ s/.*?Model:://;
 521         my $shortmess = Carp::shortmess('');
 522         if ($shortmess =~ m#Catalyst/Plugin#) {
 523            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 524               "plugin's config";
 525         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 526            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 527               "component's config";
 528         } else {
 529            $msg .= " You probably meant \$c->model('$short') instead of \$c->model{'${name}'}, " .
 530               "but if you really wanted to search, pass in a regexp as the argument " .
 531               "like so: \$c->model(qr/${name}/)";
 532         }
 533         $c->log->warn( "${msg}$shortmess" );
 534     }
 535
 536     return @result;
 537 }
 538
 539 # Find possible names for a prefix
 540 sub _comp_names {
 541     my ( $c, @prefixes ) = @_;
 542     my $appclass = ref $c || $c;
 543
 544     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 545
 546     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 547     return @names;
 548 }
 549
 550 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 551 sub _filter_component {
 552     my ( $c, $comp, @args ) = @_;
 553
 554     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 555         return $comp->ACCEPT_CONTEXT( $c, @args );
 556     }
 557
 558     return $comp;
 559 }
 560
 561 =head2 COMPONENT ACCESSORS
 562
 563 =head2 $c->controller($name)
 564
 565 Gets a L<Catalyst::Controller> instance by name.
 566
 567     $c->controller('Foo')->do_stuff;
 568
 569 If the name is omitted, will return the controller for the dispatched
 570 action.
 571
 572 If you want to search for controllers, pass in a regexp as the argument.
 573
 574     # find all controllers that start with Foo
 575     my @foo_controllers = $c->controller(qr{^Foo});
 576
 577
 578 =cut
 579
 580 sub controller {
 581     my ( $c, $name, @args ) = @_;
 582
 583     if( $name ) {
 584         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 585         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 586         return $c->_filter_component( $result[ 0 ], @args );
 587     }
 588
 589     return $c->component( $c->action->class );
 590 }
 591
 592 =head2 $c->model($name)
 593
 594 Gets a L<Catalyst::Model> instance by name.
 595
 596     $c->model('Foo')->do_stuff;
 597
 598 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 599
 600 If the name is omitted, it will look for
 601  - a model object in $c->stash->{current_model_instance}, then
 602  - a model name in $c->stash->{current_model}, then
 603  - a config setting 'default_model', or
 604  - check if there is only one model, and return it if that's the case.
 605
 606 If you want to search for models, pass in a regexp as the argument.
 607
 608     # find all models that start with Foo
 609     my @foo_models = $c->model(qr{^Foo});
 610
 611 =cut
 612
 613 sub model {
 614     my ( $c, $name, @args ) = @_;
 615
 616     if( $name ) {
 617         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 618         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 619         return $c->_filter_component( $result[ 0 ], @args );
 620     }
 621
 622     if (ref $c) {
 623         return $c->stash->{current_model_instance}
 624           if $c->stash->{current_model_instance};
 625         return $c->model( $c->stash->{current_model} )
 626           if $c->stash->{current_model};
 627     }
 628     return $c->model( $c->config->{default_model} )
 629       if $c->config->{default_model};
 630
 631     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 632
 633     if( $rest ) {
 634         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 635         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 636         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 637         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 638         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 639     }
 640
 641     return $c->_filter_component( $comp );
 642 }
 643
 644
 645 =head2 $c->view($name)
 646
 647 Gets a L<Catalyst::View> instance by name.
 648
 649     $c->view('Foo')->do_stuff;
 650
 651 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 652
 653 If the name is omitted, it will look for
 654  - a view object in $c->stash->{current_view_instance}, then
 655  - a view name in $c->stash->{current_view}, then
 656  - a config setting 'default_view', or
 657  - check if there is only one view, and return it if that's the case.
 658
 659 If you want to search for views, pass in a regexp as the argument.
 660
 661     # find all views that start with Foo
 662     my @foo_views = $c->view(qr{^Foo});
 663
 664 =cut
 665
 666 sub view {
 667     my ( $c, $name, @args ) = @_;
 668
 669     if( $name ) {
 670         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 671         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 672         return $c->_filter_component( $result[ 0 ], @args );
 673     }
 674
 675     if (ref $c) {
 676         return $c->stash->{current_view_instance}
 677           if $c->stash->{current_view_instance};
 678         return $c->view( $c->stash->{current_view} )
 679           if $c->stash->{current_view};
 680     }
 681     return $c->view( $c->config->{default_view} )
 682       if $c->config->{default_view};
 683
 684     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 685
 686     if( $rest ) {
 687         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 688         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 689         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 690         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 691         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 692     }
 693
 694     return $c->_filter_component( $comp );
 695 }
 696
 697 =head2 $c->controllers
 698
 699 Returns the available names which can be passed to $c->controller
 700
 701 =cut
 702
 703 sub controllers {
 704     my ( $c ) = @_;
 705     return $c->_comp_names(qw/Controller C/);
 706 }
 707
 708 =head2 $c->models
 709
 710 Returns the available names which can be passed to $c->model
 711
 712 =cut
 713
 714 sub models {
 715     my ( $c ) = @_;
 716     return $c->_comp_names(qw/Model M/);
 717 }
 718
 719
 720 =head2 $c->views
 721
 722 Returns the available names which can be passed to $c->view
 723
 724 =cut
 725
 726 sub views {
 727     my ( $c ) = @_;
 728     return $c->_comp_names(qw/View V/);
 729 }
 730
 731 =head2 $c->comp($name)
 732
 733 =head2 $c->component($name)
 734
 735 Gets a component object by name. This method is not recommended,
 736 unless you want to get a specific component by full
 737 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 738 should be used instead.
 739
 740 If C<$name> is a regexp, a list of components matched against the full
 741 component name will be returned.
 742
 743 =cut
 744
 745 sub component {
 746     my ( $c, $name, @args ) = @_;
 747
 748     if( $name ) {
 749         my $comps = $c->components;
 750
 751         if( !ref $name ) {
 752             # is it the exact name?
 753             return $c->_filter_component( $comps->{ $name }, @args )
 754                        if exists $comps->{ $name };
 755
 756             # perhaps we just omitted "MyApp"?
 757             my $composed = ( ref $c || $c ) . "::${name}";
 758             return $c->_filter_component( $comps->{ $composed }, @args )
 759                        if exists $comps->{ $composed };
 760
 761             # search all of the models, views and controllers
 762             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 763             return $c->_filter_component( $comp, @args ) if $comp;
 764         }
 765
 766         # This is here so $c->comp( '::M::' ) works
 767         my $query = ref $name ? $name : qr{$name}i;
 768
 769         my @result = grep { m{$query} } keys %{ $c->components };
 770         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 771
 772         if( $result[ 0 ] ) {
 773             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 774             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 775             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 776             return $c->_filter_component( $result[ 0 ], @args );
 777         }
 778
 779         # I would expect to return an empty list here, but that breaks back-compat
 780     }
 781
 782     # fallback
 783     return sort keys %{ $c->components };
 784 }
 785
 786 =head2 CLASS DATA AND HELPER CLASSES
 787
 788 =head2 $c->config
 789
 790 Returns or takes a hashref containing the application's configuration.
 791
 792     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 793
 794 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 795 like myapp.yml in your applications home directory. See
 796 L<Catalyst::Plugin::ConfigLoader>.
 797
 798     ---
 799     db: dsn:SQLite:foo.db
 800
 801
 802 =cut
 803
 804 around config => sub {
 805     my $orig = shift;
 806     my $c = shift;
 807
 808     croak('Setting config after setup has been run is not allowed.')
 809         if ( @_ and $c->setup_finished );
 810
 811     $c->$orig(@_);
 812 };
 813
 814 =head2 $c->log
 815
 816 Returns the logging object instance. Unless it is already set, Catalyst
 817 sets this up with a L<Catalyst::Log> object. To use your own log class,
 818 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 819 C<< __PACKAGE__->setup >>.
 820
 821  __PACKAGE__->log( MyLogger->new );
 822  __PACKAGE__->setup;
 823
 824 And later:
 825
 826     $c->log->info( 'Now logging with my own logger!' );
 827
 828 Your log class should implement the methods described in
 829 L<Catalyst::Log>.
 830
 831
 832 =head2 $c->debug
 833
 834 Overload to enable debug messages (same as -Debug option).
 835
 836 Note that this is a static method, not an accessor and should be overloaded
 837 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 838
 839 =cut
 840
 841 sub debug { 0 }
 842
 843 =head2 $c->dispatcher
 844
 845 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 846
 847 =head2 $c->engine
 848
 849 Returns the engine instance. See L<Catalyst::Engine>.
 850
 851
 852 =head2 UTILITY METHODS
 853
 854 =head2 $c->path_to(@path)
 855
 856 Merges C<@path> with C<< $c->config->{home} >> and returns a
 857 L<Path::Class::Dir> object.
 858
 859 For example:
 860
 861     $c->path_to( 'db', 'sqlite.db' );
 862
 863 =cut
 864
 865 sub path_to {
 866     my ( $c, @path ) = @_;
 867     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 868     if ( -d $path ) { return $path }
 869     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 870 }
 871
 872 =head2 $c->plugin( $name, $class, @args )
 873
 874 Helper method for plugins. It creates a class data accessor/mutator and
 875 loads and instantiates the given class.
 876
 877     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 878
 879     $c->prototype->define_javascript_functions;
 880
 881 B<Note:> This method of adding plugins is deprecated. The ability
 882 to add plugins like this B<will be removed> in a Catalyst 5.9.
 883 Please do not use this functionality in new code.
 884
 885 =cut
 886
 887 sub plugin {
 888     my ( $class, $name, $plugin, @args ) = @_;
 889
 890     # See block comment in t/unit_core_plugin.t
 891     $class->log->debug(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.9/);
 892
 893     $class->_register_plugin( $plugin, 1 );
 894
 895     eval { $plugin->import };
 896     $class->mk_classdata($name);
 897     my $obj;
 898     eval { $obj = $plugin->new(@args) };
 899
 900     if ($@) {
 901         Catalyst::Exception->throw( message =>
 902               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 903     }
 904
 905     $class->$name($obj);
 906     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 907       if $class->debug;
 908 }
 909
 910 =head2 MyApp->setup
 911
 912 Initializes the dispatcher and engine, loads any plugins, and loads the
 913 model, view, and controller components. You may also specify an array
 914 of plugins to load here, if you choose to not load them in the C<use
 915 Catalyst> line.
 916
 917     MyApp->setup;
 918     MyApp->setup( qw/-Debug/ );
 919
 920 =cut
 921
 922 sub setup {
 923     my ( $class, @arguments ) = @_;
 924     croak('Running setup more than once')
 925         if ( $class->setup_finished );
 926
 927     unless ( $class->isa('Catalyst') ) {
 928
 929         Catalyst::Exception->throw(
 930             message => qq/'$class' does not inherit from Catalyst/ );
 931     }
 932
 933     if ( $class->arguments ) {
 934         @arguments = ( @arguments, @{ $class->arguments } );
 935     }
 936
 937     # Process options
 938     my $flags = {};
 939
 940     foreach (@arguments) {
 941
 942         if (/^-Debug$/) {
 943             $flags->{log} =
 944               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 945         }
 946         elsif (/^-(\w+)=?(.*)$/) {
 947             $flags->{ lc $1 } = $2;
 948         }
 949         else {
 950             push @{ $flags->{plugins} }, $_;
 951         }
 952     }
 953
 954     $class->setup_home( delete $flags->{home} );
 955
 956     $class->setup_log( delete $flags->{log} );
 957     $class->setup_plugins( delete $flags->{plugins} );
 958     $class->setup_dispatcher( delete $flags->{dispatcher} );
 959     $class->setup_engine( delete $flags->{engine} );
 960     $class->setup_stats( delete $flags->{stats} );
 961
 962     for my $flag ( sort keys %{$flags} ) {
 963
 964         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 965             &$code( $class, delete $flags->{$flag} );
 966         }
 967         else {
 968             $class->log->warn(qq/Unknown flag "$flag"/);
 969         }
 970     }
 971
 972     eval { require Catalyst::Devel; };
 973     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 974         $class->log->warn(<<"EOF");
 975 You are running an old script!
 976
 977   Please update by running (this will overwrite existing files):
 978     catalyst.pl -force -scripts $class
 979
 980   or (this will not overwrite existing files):
 981     catalyst.pl -scripts $class
 982
 983 EOF
 984     }
 985
 986     if ( $class->debug ) {
 987         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 988
 989         if (@plugins) {
 990             my $column_width = Catalyst::Utils::term_width() - 6;
 991             my $t = Text::SimpleTable->new($column_width);
 992             $t->row($_) for @plugins;
 993             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 994         }
 995
 996         my $dispatcher = $class->dispatcher;
 997         my $engine     = $class->engine;
 998         my $home       = $class->config->{home};
 999
1000         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1001         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1002
1003         $home
1004           ? ( -d $home )
1005           ? $class->log->debug(qq/Found home "$home"/)
1006           : $class->log->debug(qq/Home "$home" doesn't exist/)
1007           : $class->log->debug(q/Couldn't find home/);
1008     }
1009
1010     # Call plugins setup, this is stupid and evil.
1011     {
1012         no warnings qw/redefine/;
1013         local *setup = sub { };
1014         $class->setup;
1015     }
1016
1017     # Initialize our data structure
1018     $class->components( {} );
1019
1020     $class->setup_components;
1021
1022     if ( $class->debug ) {
1023         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1024         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1025         for my $comp ( sort keys %{ $class->components } ) {
1026             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1027             $t->row( $comp, $type );
1028         }
1029         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1030           if ( keys %{ $class->components } );
1031     }
1032
1033     # Add our self to components, since we are also a component
1034     if( $class->isa('Catalyst::Controller') ){
1035       $class->components->{$class} = $class;
1036     }
1037
1038     $class->setup_actions;
1039
1040     if ( $class->debug ) {
1041         my $name = $class->config->{name} || 'Application';
1042         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1043     }
1044     $class->log->_flush() if $class->log->can('_flush');
1045
1046     # Make sure that the application class becomes immutable at this point,
1047     # which ensures that it gets an inlined constructor. This means that it
1048     # works even if the user has added a plugin which contains a new method.
1049     # Note however that we have to do the work on scope end, so that method
1050     # modifiers work correctly in MyApp (as you have to call setup _before_
1051     # applying modifiers).
1052     Scope::Upper::reap(sub {
1053         my $meta = Class::MOP::get_metaclass_by_name($class);
1054         $meta->make_immutable unless $meta->is_immutable;
1055     }, Scope::Upper::SCOPE(1));
1056
1057     $class->setup_finalize;
1058 }
1059
1060
1061 =head2 $app->setup_finalize
1062
1063 A hook to attach modifiers to.
1064 Using C< after setup => sub{}; > doesn't work, because of quirky things done for plugin setup.
1065 Also better than C< setup_finished(); >, as that is a getter method.
1066
1067     sub setup_finalize {
1068
1069         my $app = shift;
1070
1071         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1072
1073         $app->next::method(@_);
1074
1075
1076     }
1077
1078 =cut
1079
1080 sub setup_finalize {
1081     my ($class) = @_;
1082     $class->setup_finished(1);
1083 }
1084
1085 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1086
1087 =head2 $c->uri_for( $path, @args?, \%query_values? )
1088
1089 =over
1090
1091 =item $action
1092
1093 A Catalyst::Action object representing the Catalyst action you want to
1094 create a URI for. To get one for an action in the current controller,
1095 use C<< $c->action('someactionname') >>. To get one from different
1096 controller, fetch the controller using C<< $c->controller() >>, then
1097 call C<action_for> on it.
1098
1099 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1100 using C<< $c->req->captures >>.
1101
1102   # For the current action
1103   $c->uri_for($c->action, $c->req->captures);
1104
1105   # For the Foo action in the Bar controller
1106   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1107
1108 =back
1109
1110 =cut
1111
1112 sub uri_for {
1113     my ( $c, $path, @args ) = @_;
1114
1115     if ( Scalar::Util::blessed($path) ) { # action object
1116         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1117                          ? shift(@args)
1118                          : [] );
1119         $path = $c->dispatcher->uri_for_action($path, $captures);
1120         return undef unless defined($path);
1121         $path = '/' if $path eq '';
1122     }
1123
1124     undef($path) if (defined $path && $path eq '');
1125
1126     my $params =
1127       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1128
1129     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1130     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1131
1132     unshift(@args, $path);
1133
1134     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1135         my $namespace = $c->namespace;
1136         if (defined $path) { # cheesy hack to handle path '../foo'
1137            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1138         }
1139         unshift(@args, $namespace || '');
1140     }
1141
1142     # join args with '/', or a blank string
1143     my $args = join('/', grep { defined($_) } @args);
1144     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1145     $args =~ s!^/+!!;
1146     my $base = $c->req->base;
1147     my $class = ref($base);
1148     $base =~ s{(?<!/)$}{/};
1149
1150     my $query = '';
1151
1152     if (my @keys = keys %$params) {
1153       # somewhat lifted from URI::_query's query_form
1154       $query = '?'.join('&', map {
1155           my $val = $params->{$_};
1156           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1157           s/ /+/g;
1158           my $key = $_;
1159           $val = '' unless defined $val;
1160           (map {
1161               $_ = "$_";
1162               utf8::encode( $_ ) if utf8::is_utf8($_);
1163               # using the URI::Escape pattern here so utf8 chars survive
1164               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1165               s/ /+/g;
1166               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1167       } @keys);
1168     }
1169
1170     my $res = bless(\"${base}${args}${query}", $class);
1171     $res;
1172 }
1173
1174 =head2 $c->welcome_message
1175
1176 Returns the Catalyst welcome HTML page.
1177
1178 =cut
1179
1180 sub welcome_message {
1181     my $c      = shift;
1182     my $name   = $c->config->{name};
1183     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1184     my $prefix = Catalyst::Utils::appprefix( ref $c );
1185     $c->response->content_type('text/html; charset=utf-8');
1186     return <<"EOF";
1187 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1188     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1189 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1190     <head>
1191     <meta http-equiv="Content-Language" content="en" />
1192     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1193         <title>$name on Catalyst $VERSION</title>
1194         <style type="text/css">
1195             body {
1196                 color: #000;
1197                 background-color: #eee;
1198             }
1199             div#content {
1200                 width: 640px;
1201                 margin-left: auto;
1202                 margin-right: auto;
1203                 margin-top: 10px;
1204                 margin-bottom: 10px;
1205                 text-align: left;
1206                 background-color: #ccc;
1207                 border: 1px solid #aaa;
1208             }
1209             p, h1, h2 {
1210                 margin-left: 20px;
1211                 margin-right: 20px;
1212                 font-family: verdana, tahoma, sans-serif;
1213             }
1214             a {
1215                 font-family: verdana, tahoma, sans-serif;
1216             }
1217             :link, :visited {
1218                     text-decoration: none;
1219                     color: #b00;
1220                     border-bottom: 1px dotted #bbb;
1221             }
1222             :link:hover, :visited:hover {
1223                     color: #555;
1224             }
1225             div#topbar {
1226                 margin: 0px;
1227             }
1228             pre {
1229                 margin: 10px;
1230                 padding: 8px;
1231             }
1232             div#answers {
1233                 padding: 8px;
1234                 margin: 10px;
1235                 background-color: #fff;
1236                 border: 1px solid #aaa;
1237             }
1238             h1 {
1239                 font-size: 0.9em;
1240                 font-weight: normal;
1241                 text-align: center;
1242             }
1243             h2 {
1244                 font-size: 1.0em;
1245             }
1246             p {
1247                 font-size: 0.9em;
1248             }
1249             p img {
1250                 float: right;
1251                 margin-left: 10px;
1252             }
1253             span#appname {
1254                 font-weight: bold;
1255                 font-size: 1.6em;
1256             }
1257         </style>
1258     </head>
1259     <body>
1260         <div id="content">
1261             <div id="topbar">
1262                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1263                     $VERSION</h1>
1264              </div>
1265              <div id="answers">
1266                  <p>
1267                  <img src="$logo" alt="Catalyst Logo" />
1268                  </p>
1269                  <p>Welcome to the  world of Catalyst.
1270                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1271                     framework will make web development something you had
1272                     never expected it to be: Fun, rewarding, and quick.</p>
1273                  <h2>What to do now?</h2>
1274                  <p>That really depends  on what <b>you</b> want to do.
1275                     We do, however, provide you with a few starting points.</p>
1276                  <p>If you want to jump right into web development with Catalyst
1277                     you might want to start with a tutorial.</p>
1278 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1279 </pre>
1280 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1281 <pre>
1282 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1283 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1284 </code></pre>
1285                  <h2>What to do next?</h2>
1286                  <p>Next it's time to write an actual application. Use the
1287                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1288                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1289                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1290                     they can save you a lot of work.</p>
1291                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1292                     <p>Also, be sure to check out the vast and growing
1293                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1294                     you are likely to find what you need there.
1295                     </p>
1296
1297                  <h2>Need help?</h2>
1298                  <p>Catalyst has a very active community. Here are the main places to
1299                     get in touch with us.</p>
1300                  <ul>
1301                      <li>
1302                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1303                      </li>
1304                      <li>
1305                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1306                      </li>
1307                      <li>
1308                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1309                      </li>
1310                  </ul>
1311                  <h2>In conclusion</h2>
1312                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1313                     as we enjoyed making it. Please contact us if you have ideas
1314                     for improvement or other feedback.</p>
1315              </div>
1316          </div>
1317     </body>
1318 </html>
1319 EOF
1320 }
1321
1322 =head1 INTERNAL METHODS
1323
1324 These methods are not meant to be used by end users.
1325
1326 =head2 $c->components
1327
1328 Returns a hash of components.
1329
1330 =head2 $c->context_class
1331
1332 Returns or sets the context class.
1333
1334 =head2 $c->counter
1335
1336 Returns a hashref containing coderefs and execution counts (needed for
1337 deep recursion detection).
1338
1339 =head2 $c->depth
1340
1341 Returns the number of actions on the current internal execution stack.
1342
1343 =head2 $c->dispatch
1344
1345 Dispatches a request to actions.
1346
1347 =cut
1348
1349 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1350
1351 =head2 $c->dispatcher_class
1352
1353 Returns or sets the dispatcher class.
1354
1355 =head2 $c->dump_these
1356
1357 Returns a list of 2-element array references (name, structure) pairs
1358 that will be dumped on the error page in debug mode.
1359
1360 =cut
1361
1362 sub dump_these {
1363     my $c = shift;
1364     [ Request => $c->req ],
1365     [ Response => $c->res ],
1366     [ Stash => $c->stash ],
1367     [ Config => $c->config ];
1368 }
1369
1370 =head2 $c->engine_class
1371
1372 Returns or sets the engine class.
1373
1374 =head2 $c->execute( $class, $coderef )
1375
1376 Execute a coderef in given class and catch exceptions. Errors are available
1377 via $c->error.
1378
1379 =cut
1380
1381 sub execute {
1382     my ( $c, $class, $code ) = @_;
1383     $class = $c->component($class) || $class;
1384     $c->state(0);
1385
1386     if ( $c->depth >= $RECURSION ) {
1387         my $action = $code->reverse();
1388         $action = "/$action" unless $action =~ /->/;
1389         my $error = qq/Deep recursion detected calling "${action}"/;
1390         $c->log->error($error);
1391         $c->error($error);
1392         $c->state(0);
1393         return $c->state;
1394     }
1395
1396     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1397
1398     push( @{ $c->stack }, $code );
1399
1400     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1401
1402     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1403
1404     my $last = pop( @{ $c->stack } );
1405
1406     if ( my $error = $@ ) {
1407         if ( !ref($error) and $error eq $DETACH ) {
1408             die $DETACH if($c->depth > 1);
1409         }
1410         elsif ( !ref($error) and $error eq $GO ) {
1411             die $GO if($c->depth > 0);
1412         }
1413         else {
1414             unless ( ref $error ) {
1415                 no warnings 'uninitialized';
1416                 chomp $error;
1417                 my $class = $last->class;
1418                 my $name  = $last->name;
1419                 $error = qq/Caught exception in $class->$name "$error"/;
1420             }
1421             $c->error($error);
1422             $c->state(0);
1423         }
1424     }
1425     return $c->state;
1426 }
1427
1428 sub _stats_start_execute {
1429     my ( $c, $code ) = @_;
1430
1431     return if ( ( $code->name =~ /^_.*/ )
1432         && ( !$c->config->{show_internal_actions} ) );
1433
1434     my $action_name = $code->reverse();
1435     $c->counter->{$action_name}++;
1436
1437     my $action = $action_name;
1438     $action = "/$action" unless $action =~ /->/;
1439
1440     # determine if the call was the result of a forward
1441     # this is done by walking up the call stack and looking for a calling
1442     # sub of Catalyst::forward before the eval
1443     my $callsub = q{};
1444     for my $index ( 2 .. 11 ) {
1445         last
1446         if ( ( caller($index) )[0] eq 'Catalyst'
1447             && ( caller($index) )[3] eq '(eval)' );
1448
1449         if ( ( caller($index) )[3] =~ /forward$/ ) {
1450             $callsub = ( caller($index) )[3];
1451             $action  = "-> $action";
1452             last;
1453         }
1454     }
1455
1456     my $uid = $action_name . $c->counter->{$action_name};
1457
1458     # is this a root-level call or a forwarded call?
1459     if ( $callsub =~ /forward$/ ) {
1460
1461         # forward, locate the caller
1462         if ( my $parent = $c->stack->[-1] ) {
1463             $c->stats->profile(
1464                 begin  => $action,
1465                 parent => "$parent" . $c->counter->{"$parent"},
1466                 uid    => $uid,
1467             );
1468         }
1469         else {
1470
1471             # forward with no caller may come from a plugin
1472             $c->stats->profile(
1473                 begin => $action,
1474                 uid   => $uid,
1475             );
1476         }
1477     }
1478     else {
1479
1480         # root-level call
1481         $c->stats->profile(
1482             begin => $action,
1483             uid   => $uid,
1484         );
1485     }
1486     return $action;
1487
1488 }
1489
1490 sub _stats_finish_execute {
1491     my ( $c, $info ) = @_;
1492     $c->stats->profile( end => $info );
1493 }
1494
1495 =head2 $c->_localize_fields( sub { }, \%keys );
1496
1497 =cut
1498
1499 #Why does this exist? This is no longer safe and WILL NOT WORK.
1500 # it doesnt seem to be used anywhere. can we remove it?
1501 sub _localize_fields {
1502     my ( $c, $localized, $code ) = ( @_ );
1503
1504     my $request = delete $localized->{request} || {};
1505     my $response = delete $localized->{response} || {};
1506
1507     local @{ $c }{ keys %$localized } = values %$localized;
1508     local @{ $c->request }{ keys %$request } = values %$request;
1509     local @{ $c->response }{ keys %$response } = values %$response;
1510
1511     $code->();
1512 }
1513
1514 =head2 $c->finalize
1515
1516 Finalizes the request.
1517
1518 =cut
1519
1520 sub finalize {
1521     my $c = shift;
1522
1523     for my $error ( @{ $c->error } ) {
1524         $c->log->error($error);
1525     }
1526
1527     # Allow engine to handle finalize flow (for POE)
1528     my $engine = $c->engine;
1529     if ( my $code = $engine->can('finalize') ) {
1530         $engine->$code($c);
1531     }
1532     else {
1533
1534         $c->finalize_uploads;
1535
1536         # Error
1537         if ( $#{ $c->error } >= 0 ) {
1538             $c->finalize_error;
1539         }
1540
1541         $c->finalize_headers;
1542
1543         # HEAD request
1544         if ( $c->request->method eq 'HEAD' ) {
1545             $c->response->body('');
1546         }
1547
1548         $c->finalize_body;
1549     }
1550
1551     if ($c->use_stats) {
1552         my $elapsed = sprintf '%f', $c->stats->elapsed;
1553         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1554         $c->log->info(
1555             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1556     }
1557
1558     return $c->response->status;
1559 }
1560
1561 =head2 $c->finalize_body
1562
1563 Finalizes body.
1564
1565 =cut
1566
1567 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1568
1569 =head2 $c->finalize_cookies
1570
1571 Finalizes cookies.
1572
1573 =cut
1574
1575 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1576
1577 =head2 $c->finalize_error
1578
1579 Finalizes error.
1580
1581 =cut
1582
1583 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1584
1585 =head2 $c->finalize_headers
1586
1587 Finalizes headers.
1588
1589 =cut
1590
1591 sub finalize_headers {
1592     my $c = shift;
1593
1594     my $response = $c->response; #accessor calls can add up?
1595
1596     # Check if we already finalized headers
1597     return if $response->finalized_headers;
1598
1599     # Handle redirects
1600     if ( my $location = $response->redirect ) {
1601         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1602         $response->header( Location => $location );
1603
1604         if ( !$response->has_body ) {
1605             # Add a default body if none is already present
1606             $response->body(
1607                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1608             );
1609         }
1610     }
1611
1612     # Content-Length
1613     if ( $response->body && !$response->content_length ) {
1614
1615         # get the length from a filehandle
1616         if ( blessed( $response->body ) && $response->body->can('read') )
1617         {
1618             my $stat = stat $response->body;
1619             if ( $stat && $stat->size > 0 ) {
1620                 $response->content_length( $stat->size );
1621             }
1622             else {
1623                 $c->log->warn('Serving filehandle without a content-length');
1624             }
1625         }
1626         else {
1627             # everything should be bytes at this point, but just in case
1628             $response->content_length( bytes::length( $response->body ) );
1629         }
1630     }
1631
1632     # Errors
1633     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1634         $response->headers->remove_header("Content-Length");
1635         $response->body('');
1636     }
1637
1638     $c->finalize_cookies;
1639
1640     $c->engine->finalize_headers( $c, @_ );
1641
1642     # Done
1643     $response->finalized_headers(1);
1644 }
1645
1646 =head2 $c->finalize_output
1647
1648 An alias for finalize_body.
1649
1650 =head2 $c->finalize_read
1651
1652 Finalizes the input after reading is complete.
1653
1654 =cut
1655
1656 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1657
1658 =head2 $c->finalize_uploads
1659
1660 Finalizes uploads. Cleans up any temporary files.
1661
1662 =cut
1663
1664 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1665
1666 =head2 $c->get_action( $action, $namespace )
1667
1668 Gets an action in a given namespace.
1669
1670 =cut
1671
1672 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1673
1674 =head2 $c->get_actions( $action, $namespace )
1675
1676 Gets all actions of a given name in a namespace and all parent
1677 namespaces.
1678
1679 =cut
1680
1681 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1682
1683 =head2 $c->handle_request( $class, @arguments )
1684
1685 Called to handle each HTTP request.
1686
1687 =cut
1688
1689 sub handle_request {
1690     my ( $class, @arguments ) = @_;
1691
1692     # Always expect worst case!
1693     my $status = -1;
1694     eval {
1695         if ($class->debug) {
1696             my $secs = time - $START || 1;
1697             my $av = sprintf '%.3f', $COUNT / $secs;
1698             my $time = localtime time;
1699             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1700         }
1701
1702         my $c = $class->prepare(@arguments);
1703         $c->dispatch;
1704         $status = $c->finalize;
1705     };
1706
1707     if ( my $error = $@ ) {
1708         chomp $error;
1709         $class->log->error(qq/Caught exception in engine "$error"/);
1710     }
1711
1712     $COUNT++;
1713
1714     if(my $coderef = $class->log->can('_flush')){
1715         $class->log->$coderef();
1716     }
1717     return $status;
1718 }
1719
1720 =head2 $c->prepare( @arguments )
1721
1722 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1723 etc.).
1724
1725 =cut
1726
1727 sub prepare {
1728     my ( $class, @arguments ) = @_;
1729
1730     # XXX
1731     # After the app/ctxt split, this should become an attribute based on something passed
1732     # into the application.
1733     $class->context_class( ref $class || $class ) unless $class->context_class;
1734
1735     my $c = $class->context_class->new({});
1736
1737     # For on-demand data
1738     $c->request->_context($c);
1739     $c->response->_context($c);
1740
1741     #surely this is not the most efficient way to do things...
1742     $c->stats($class->stats_class->new)->enable($c->use_stats);
1743     if ( $c->debug ) {
1744         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1745     }
1746
1747     #XXX reuse coderef from can
1748     # Allow engine to direct the prepare flow (for POE)
1749     if ( $c->engine->can('prepare') ) {
1750         $c->engine->prepare( $c, @arguments );
1751     }
1752     else {
1753         $c->prepare_request(@arguments);
1754         $c->prepare_connection;
1755         $c->prepare_query_parameters;
1756         $c->prepare_headers;
1757         $c->prepare_cookies;
1758         $c->prepare_path;
1759
1760         # Prepare the body for reading, either by prepare_body
1761         # or the user, if they are using $c->read
1762         $c->prepare_read;
1763
1764         # Parse the body unless the user wants it on-demand
1765         unless ( $c->config->{parse_on_demand} ) {
1766             $c->prepare_body;
1767         }
1768     }
1769
1770     my $method  = $c->req->method  || '';
1771     my $path    = $c->req->path;
1772     $path       = '/' unless length $path;
1773     my $address = $c->req->address || '';
1774
1775     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1776       if $c->debug;
1777
1778     $c->prepare_action;
1779
1780     return $c;
1781 }
1782
1783 =head2 $c->prepare_action
1784
1785 Prepares action. See L<Catalyst::Dispatcher>.
1786
1787 =cut
1788
1789 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1790
1791 =head2 $c->prepare_body
1792
1793 Prepares message body.
1794
1795 =cut
1796
1797 sub prepare_body {
1798     my $c = shift;
1799
1800     return if $c->request->_has_body;
1801
1802     # Initialize on-demand data
1803     $c->engine->prepare_body( $c, @_ );
1804     $c->prepare_parameters;
1805     $c->prepare_uploads;
1806
1807     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1808         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1809         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1810             my $param = $c->req->body_parameters->{$key};
1811             my $value = defined($param) ? $param : '';
1812             $t->row( $key,
1813                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1814         }
1815         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1816     }
1817 }
1818
1819 =head2 $c->prepare_body_chunk( $chunk )
1820
1821 Prepares a chunk of data before sending it to L<HTTP::Body>.
1822
1823 See L<Catalyst::Engine>.
1824
1825 =cut
1826
1827 sub prepare_body_chunk {
1828     my $c = shift;
1829     $c->engine->prepare_body_chunk( $c, @_ );
1830 }
1831
1832 =head2 $c->prepare_body_parameters
1833
1834 Prepares body parameters.
1835
1836 =cut
1837
1838 sub prepare_body_parameters {
1839     my $c = shift;
1840     $c->engine->prepare_body_parameters( $c, @_ );
1841 }
1842
1843 =head2 $c->prepare_connection
1844
1845 Prepares connection.
1846
1847 =cut
1848
1849 sub prepare_connection {
1850     my $c = shift;
1851     $c->engine->prepare_connection( $c, @_ );
1852 }
1853
1854 =head2 $c->prepare_cookies
1855
1856 Prepares cookies.
1857
1858 =cut
1859
1860 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1861
1862 =head2 $c->prepare_headers
1863
1864 Prepares headers.
1865
1866 =cut
1867
1868 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1869
1870 =head2 $c->prepare_parameters
1871
1872 Prepares parameters.
1873
1874 =cut
1875
1876 sub prepare_parameters {
1877     my $c = shift;
1878     $c->prepare_body_parameters;
1879     $c->engine->prepare_parameters( $c, @_ );
1880 }
1881
1882 =head2 $c->prepare_path
1883
1884 Prepares path and base.
1885
1886 =cut
1887
1888 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1889
1890 =head2 $c->prepare_query_parameters
1891
1892 Prepares query parameters.
1893
1894 =cut
1895
1896 sub prepare_query_parameters {
1897     my $c = shift;
1898
1899     $c->engine->prepare_query_parameters( $c, @_ );
1900
1901     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1902         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1903         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1904             my $param = $c->req->query_parameters->{$key};
1905             my $value = defined($param) ? $param : '';
1906             $t->row( $key,
1907                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1908         }
1909         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1910     }
1911 }
1912
1913 =head2 $c->prepare_read
1914
1915 Prepares the input for reading.
1916
1917 =cut
1918
1919 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1920
1921 =head2 $c->prepare_request
1922
1923 Prepares the engine request.
1924
1925 =cut
1926
1927 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1928
1929 =head2 $c->prepare_uploads
1930
1931 Prepares uploads.
1932
1933 =cut
1934
1935 sub prepare_uploads {
1936     my $c = shift;
1937
1938     $c->engine->prepare_uploads( $c, @_ );
1939
1940     if ( $c->debug && keys %{ $c->request->uploads } ) {
1941         my $t = Text::SimpleTable->new(
1942             [ 12, 'Parameter' ],
1943             [ 26, 'Filename' ],
1944             [ 18, 'Type' ],
1945             [ 9,  'Size' ]
1946         );
1947         for my $key ( sort keys %{ $c->request->uploads } ) {
1948             my $upload = $c->request->uploads->{$key};
1949             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1950                 $t->row( $key, $u->filename, $u->type, $u->size );
1951             }
1952         }
1953         $c->log->debug( "File Uploads are:\n" . $t->draw );
1954     }
1955 }
1956
1957 =head2 $c->prepare_write
1958
1959 Prepares the output for writing.
1960
1961 =cut
1962
1963 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1964
1965 =head2 $c->request_class
1966
1967 Returns or sets the request class.
1968
1969 =head2 $c->response_class
1970
1971 Returns or sets the response class.
1972
1973 =head2 $c->read( [$maxlength] )
1974
1975 Reads a chunk of data from the request body. This method is designed to
1976 be used in a while loop, reading C<$maxlength> bytes on every call.
1977 C<$maxlength> defaults to the size of the request if not specified.
1978
1979 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1980 directly.
1981
1982 Warning: If you use read(), Catalyst will not process the body,
1983 so you will not be able to access POST parameters or file uploads via
1984 $c->request.  You must handle all body parsing yourself.
1985
1986 =cut
1987
1988 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1989
1990 =head2 $c->run
1991
1992 Starts the engine.
1993
1994 =cut
1995
1996 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1997
1998 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1999
2000 Sets an action in a given namespace.
2001
2002 =cut
2003
2004 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2005
2006 =head2 $c->setup_actions($component)
2007
2008 Sets up actions for a component.
2009
2010 =cut
2011
2012 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2013
2014 =head2 $c->setup_components
2015
2016 Sets up components. Specify a C<setup_components> config option to pass
2017 additional options directly to L<Module::Pluggable>. To add additional
2018 search paths, specify a key named C<search_extra> as an array
2019 reference. Items in the array beginning with C<::> will have the
2020 application class name prepended to them.
2021
2022 All components found will also have any
2023 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2024 Note, that modules which are B<not> an I<inner package> of the main
2025 file namespace loaded will not be instantiated as components.
2026
2027 =cut
2028
2029 sub setup_components {
2030     my $class = shift;
2031
2032     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2033     my $config  = $class->config->{ setup_components };
2034     my $extra   = delete $config->{ search_extra } || [];
2035
2036     push @paths, @$extra;
2037
2038     my $locator = Module::Pluggable::Object->new(
2039         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2040         %$config
2041     );
2042
2043     my @comps = sort { length $a <=> length $b } $locator->plugins;
2044     my %comps = map { $_ => 1 } @comps;
2045
2046     for my $component ( @comps ) {
2047
2048         # We pass ignore_loaded here so that overlay files for (e.g.)
2049         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2050         # we know M::P::O found a file on disk so this is safe
2051
2052         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2053         #Class::MOP::load_class($component);
2054
2055         my $module  = $class->setup_component( $component );
2056         my %modules = (
2057             $component => $module,
2058             map {
2059                 $_ => $class->setup_component( $_ )
2060             } grep {
2061               not exists $comps{$_}
2062             } Devel::InnerPackage::list_packages( $component )
2063         );
2064
2065         for my $key ( keys %modules ) {
2066             $class->components->{ $key } = $modules{ $key };
2067         }
2068     }
2069 }
2070
2071 =head2 $c->setup_component
2072
2073 =cut
2074
2075 sub setup_component {
2076     my( $class, $component ) = @_;
2077
2078     unless ( $component->can( 'COMPONENT' ) ) {
2079         return $component;
2080     }
2081
2082     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2083     my $config = $class->config->{ $suffix } || {};
2084
2085     my $instance = eval { $component->COMPONENT( $class, $config ); };
2086
2087     if ( my $error = $@ ) {
2088         chomp $error;
2089         Catalyst::Exception->throw(
2090             message => qq/Couldn't instantiate component "$component", "$error"/
2091         );
2092     }
2093
2094     Catalyst::Exception->throw(
2095         message =>
2096         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2097     ) unless blessed($instance);
2098
2099     return $instance;
2100 }
2101
2102 =head2 $c->setup_dispatcher
2103
2104 Sets up dispatcher.
2105
2106 =cut
2107
2108 sub setup_dispatcher {
2109     my ( $class, $dispatcher ) = @_;
2110
2111     if ($dispatcher) {
2112         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2113     }
2114
2115     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2116         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2117     }
2118
2119     unless ($dispatcher) {
2120         $dispatcher = $class->dispatcher_class;
2121     }
2122
2123     Class::MOP::load_class($dispatcher);
2124
2125     # dispatcher instance
2126     $class->dispatcher( $dispatcher->new );
2127 }
2128
2129 =head2 $c->setup_engine
2130
2131 Sets up engine.
2132
2133 =cut
2134
2135 sub setup_engine {
2136     my ( $class, $engine ) = @_;
2137
2138     if ($engine) {
2139         $engine = 'Catalyst::Engine::' . $engine;
2140     }
2141
2142     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2143         $engine = 'Catalyst::Engine::' . $env;
2144     }
2145
2146     if ( $ENV{MOD_PERL} ) {
2147         my $meta = Class::MOP::get_metaclass_by_name($class);
2148
2149         # create the apache method
2150         $meta->add_method('apache' => sub { shift->engine->apache });
2151
2152         my ( $software, $version ) =
2153           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2154
2155         $version =~ s/_//g;
2156         $version =~ s/(\.[^.]+)\./$1/g;
2157
2158         if ( $software eq 'mod_perl' ) {
2159
2160             if ( !$engine ) {
2161
2162                 if ( $version >= 1.99922 ) {
2163                     $engine = 'Catalyst::Engine::Apache2::MP20';
2164                 }
2165
2166                 elsif ( $version >= 1.9901 ) {
2167                     $engine = 'Catalyst::Engine::Apache2::MP19';
2168                 }
2169
2170                 elsif ( $version >= 1.24 ) {
2171                     $engine = 'Catalyst::Engine::Apache::MP13';
2172                 }
2173
2174                 else {
2175                     Catalyst::Exception->throw( message =>
2176                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2177                 }
2178
2179             }
2180
2181             # install the correct mod_perl handler
2182             if ( $version >= 1.9901 ) {
2183                 *handler = sub  : method {
2184                     shift->handle_request(@_);
2185                 };
2186             }
2187             else {
2188                 *handler = sub ($$) { shift->handle_request(@_) };
2189             }
2190
2191         }
2192
2193         elsif ( $software eq 'Zeus-Perl' ) {
2194             $engine = 'Catalyst::Engine::Zeus';
2195         }
2196
2197         else {
2198             Catalyst::Exception->throw(
2199                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2200         }
2201     }
2202
2203     unless ($engine) {
2204         $engine = $class->engine_class;
2205     }
2206
2207     Class::MOP::load_class($engine);
2208
2209     # check for old engines that are no longer compatible
2210     my $old_engine;
2211     if ( $engine->isa('Catalyst::Engine::Apache')
2212         && !Catalyst::Engine::Apache->VERSION )
2213     {
2214         $old_engine = 1;
2215     }
2216
2217     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2218         && Catalyst::Engine::Server->VERSION le '0.02' )
2219     {
2220         $old_engine = 1;
2221     }
2222
2223     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2224         && $engine->VERSION eq '0.01' )
2225     {
2226         $old_engine = 1;
2227     }
2228
2229     elsif ($engine->isa('Catalyst::Engine::Zeus')
2230         && $engine->VERSION eq '0.01' )
2231     {
2232         $old_engine = 1;
2233     }
2234
2235     if ($old_engine) {
2236         Catalyst::Exception->throw( message =>
2237               qq/Engine "$engine" is not supported by this version of Catalyst/
2238         );
2239     }
2240
2241     # engine instance
2242     $class->engine( $engine->new );
2243 }
2244
2245 =head2 $c->setup_home
2246
2247 Sets up the home directory.
2248
2249 =cut
2250
2251 sub setup_home {
2252     my ( $class, $home ) = @_;
2253
2254     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2255         $home = $env;
2256     }
2257
2258     $home ||= Catalyst::Utils::home($class);
2259
2260     if ($home) {
2261         #I remember recently being scolded for assigning config values like this
2262         $class->config->{home} ||= $home;
2263         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2264     }
2265 }
2266
2267 =head2 $c->setup_log
2268
2269 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2270 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2271 log to.
2272
2273 This method also installs a C<debug> method that returns a true value into the
2274 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2275 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2276
2277 Note that if the log has already been setup, by either a previous call to
2278 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2279 that this method won't actually set up the log object.
2280
2281 =cut
2282
2283 sub setup_log {
2284     my ( $class, $levels ) = @_;
2285
2286     $levels ||= '';
2287     $levels =~ s/^\s+//;
2288     $levels =~ s/\s+$//;
2289     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels || '';
2290
2291     unless ( $class->log ) {
2292         $class->log( Catalyst::Log->new(keys %levels) );
2293     }
2294
2295     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2296     if ( defined($env_debug) or $levels{debug} ) {
2297         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2298         $class->log->debug('Debug messages enabled');
2299     }
2300 }
2301
2302 =head2 $c->setup_plugins
2303
2304 Sets up plugins.
2305
2306 =cut
2307
2308 =head2 $c->setup_stats
2309
2310 Sets up timing statistics class.
2311
2312 =cut
2313
2314 sub setup_stats {
2315     my ( $class, $stats ) = @_;
2316
2317     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2318
2319     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2320     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2321         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2322         $class->log->debug('Statistics enabled');
2323     }
2324 }
2325
2326
2327 =head2 $c->registered_plugins
2328
2329 Returns a sorted list of the plugins which have either been stated in the
2330 import list or which have been added via C<< MyApp->plugin(@args); >>.
2331
2332 If passed a given plugin name, it will report a boolean value indicating
2333 whether or not that plugin is loaded.  A fully qualified name is required if
2334 the plugin name does not begin with C<Catalyst::Plugin::>.
2335
2336  if ($c->registered_plugins('Some::Plugin')) {
2337      ...
2338  }
2339
2340 =cut
2341
2342 {
2343
2344     sub registered_plugins {
2345         my $proto = shift;
2346         return sort keys %{ $proto->_plugins } unless @_;
2347         my $plugin = shift;
2348         return 1 if exists $proto->_plugins->{$plugin};
2349         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2350     }
2351
2352     sub _register_plugin {
2353         my ( $proto, $plugin, $instant ) = @_;
2354         my $class = ref $proto || $proto;
2355
2356         # no ignore_loaded here, the plugin may already have been
2357         # defined in memory and we don't want to error on "no file" if so
2358
2359         Class::MOP::load_class( $plugin );
2360
2361         $proto->_plugins->{$plugin} = 1;
2362         unless ($instant) {
2363             no strict 'refs';
2364             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2365               my @superclasses = ($plugin, $meta->superclasses );
2366               $meta->superclasses(@superclasses);
2367             } else {
2368               unshift @{"$class\::ISA"}, $plugin;
2369             }
2370         }
2371         return $class;
2372     }
2373
2374     sub setup_plugins {
2375         my ( $class, $plugins ) = @_;
2376
2377         $class->_plugins( {} ) unless $class->_plugins;
2378         $plugins ||= [];
2379         for my $plugin ( reverse @$plugins ) {
2380
2381             unless ( $plugin =~ s/\A\+// ) {
2382                 $plugin = "Catalyst::Plugin::$plugin";
2383             }
2384
2385             $class->_register_plugin($plugin);
2386         }
2387     }
2388 }
2389
2390 =head2 $c->stack
2391
2392 Returns an arrayref of the internal execution stack (actions that are
2393 currently executing).
2394
2395 =head2 $c->stats_class
2396
2397 Returns or sets the stats (timing statistics) class.
2398
2399 =head2 $c->use_stats
2400
2401 Returns 1 when stats collection is enabled.  Stats collection is enabled
2402 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2403 environment variable is set.
2404
2405 Note that this is a static method, not an accessor and should be overloaded
2406 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2407
2408 =cut
2409
2410 sub use_stats { 0 }
2411
2412
2413 =head2 $c->write( $data )
2414
2415 Writes $data to the output stream. When using this method directly, you
2416 will need to manually set the C<Content-Length> header to the length of
2417 your output data, if known.
2418
2419 =cut
2420
2421 sub write {
2422     my $c = shift;
2423
2424     # Finalize headers if someone manually writes output
2425     $c->finalize_headers;
2426
2427     return $c->engine->write( $c, @_ );
2428 }
2429
2430 =head2 version
2431
2432 Returns the Catalyst version number. Mostly useful for "powered by"
2433 messages in template systems.
2434
2435 =cut
2436
2437 sub version { return $Catalyst::VERSION }
2438
2439 =head1 INTERNAL ACTIONS
2440
2441 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2442 C<_ACTION>, and C<_END>. These are by default not shown in the private
2443 action table, but you can make them visible with a config parameter.
2444
2445     MyApp->config->{show_internal_actions} = 1;
2446
2447 =head1 CASE SENSITIVITY
2448
2449 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2450 mapped to C</foo/bar>. You can activate case sensitivity with a config
2451 parameter.
2452
2453     MyApp->config->{case_sensitive} = 1;
2454
2455 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2456
2457 =head1 ON-DEMAND PARSER
2458
2459 The request body is usually parsed at the beginning of a request,
2460 but if you want to handle input yourself, you can enable on-demand
2461 parsing with a config parameter.
2462
2463     MyApp->config->{parse_on_demand} = 1;
2464
2465 =head1 PROXY SUPPORT
2466
2467 Many production servers operate using the common double-server approach,
2468 with a lightweight frontend web server passing requests to a larger
2469 backend server. An application running on the backend server must deal
2470 with two problems: the remote user always appears to be C<127.0.0.1> and
2471 the server's hostname will appear to be C<localhost> regardless of the
2472 virtual host that the user connected through.
2473
2474 Catalyst will automatically detect this situation when you are running
2475 the frontend and backend servers on the same machine. The following
2476 changes are made to the request.
2477
2478     $c->req->address is set to the user's real IP address, as read from
2479     the HTTP X-Forwarded-For header.
2480
2481     The host value for $c->req->base and $c->req->uri is set to the real
2482     host, as read from the HTTP X-Forwarded-Host header.
2483
2484 Obviously, your web server must support these headers for this to work.
2485
2486 In a more complex server farm environment where you may have your
2487 frontend proxy server(s) on different machines, you will need to set a
2488 configuration option to tell Catalyst to read the proxied data from the
2489 headers.
2490
2491     MyApp->config->{using_frontend_proxy} = 1;
2492
2493 If you do not wish to use the proxy support at all, you may set:
2494
2495     MyApp->config->{ignore_frontend_proxy} = 1;
2496
2497 =head1 THREAD SAFETY
2498
2499 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2500 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2501 believe the Catalyst core to be thread-safe.
2502
2503 If you plan to operate in a threaded environment, remember that all other
2504 modules you are using must also be thread-safe. Some modules, most notably
2505 L<DBD::SQLite>, are not thread-safe.
2506
2507 =head1 SUPPORT
2508
2509 IRC:
2510
2511     Join #catalyst on irc.perl.org.
2512
2513 Mailing Lists:
2514
2515     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2516     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2517
2518 Web:
2519
2520     http://catalyst.perl.org
2521
2522 Wiki:
2523
2524     http://dev.catalyst.perl.org
2525
2526 =head1 SEE ALSO
2527
2528 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2529
2530 =head2 L<Catalyst::Manual> - The Catalyst Manual
2531
2532 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2533
2534 =head2 L<Catalyst::Engine> - Core engine
2535
2536 =head2 L<Catalyst::Log> - Log class.
2537
2538 =head2 L<Catalyst::Request> - Request object
2539
2540 =head2 L<Catalyst::Response> - Response object
2541
2542 =head2 L<Catalyst::Test> - The test suite.
2543
2544 =head1 PROJECT FOUNDER
2545
2546 sri: Sebastian Riedel <sri@cpan.org>
2547
2548 =head1 CONTRIBUTORS
2549
2550 abw: Andy Wardley
2551
2552 acme: Leon Brocard <leon@astray.com>
2553
2554 Andrew Bramble
2555
2556 Andrew Ford
2557
2558 Andrew Ruthven
2559
2560 andyg: Andy Grundman <andy@hybridized.org>
2561
2562 audreyt: Audrey Tang
2563
2564 bricas: Brian Cassidy <bricas@cpan.org>
2565
2566 Caelum: Rafael Kitover <rkitover@io.com>
2567
2568 chansen: Christian Hansen
2569
2570 chicks: Christopher Hicks
2571
2572 David E. Wheeler
2573
2574 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2575
2576 Drew Taylor
2577
2578 esskar: Sascha Kiefer
2579
2580 fireartist: Carl Franks <cfranks@cpan.org>
2581
2582 gabb: Danijel Milicevic
2583
2584 Gary Ashton Jones
2585
2586 Geoff Richards
2587
2588 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2589
2590 jcamacho: Juan Camacho
2591
2592 jhannah: Jay Hannah <jay@jays.net>
2593
2594 Jody Belka
2595
2596 Johan Lindstrom
2597
2598 jon: Jon Schutz <jjschutz@cpan.org>
2599
2600 marcus: Marcus Ramberg <mramberg@cpan.org>
2601
2602 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2603
2604 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2605
2606 mugwump: Sam Vilain
2607
2608 naughton: David Naughton
2609
2610 ningu: David Kamholz <dkamholz@cpan.org>
2611
2612 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2613
2614 numa: Dan Sully <daniel@cpan.org>
2615
2616 obra: Jesse Vincent
2617
2618 omega: Andreas Marienborg
2619
2620 Oleg Kostyuk <cub.uanic@gmail.com>
2621
2622 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2623
2624 rafl: Florian Ragwitz <rafl@debian.org>
2625
2626 sky: Arthur Bergman
2627
2628 the_jester: Jesse Sheidlower
2629
2630 t0m: Tomas Doran <bobtfish@bobtfish.net>
2631
2632 Ulf Edvinsson
2633
2634 willert: Sebastian Willert <willert@cpan.org>
2635
2636 =head1 LICENSE
2637
2638 This library is free software, you can redistribute it and/or modify it under
2639 the same terms as Perl itself.
2640
2641 =cut
2642
2643 no Moose;
2644
2645 __PACKAGE__->meta->make_immutable;
2646
2647 1;