lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use UNIVERSAL::require;
   7 use Catalyst::Exception;
   8 use Catalyst::Log;
   9 use Catalyst::Request;
  10 use Catalyst::Request::Upload;
  11 use Catalyst::Response;
  12 use Catalyst::Utils;
  13 use Catalyst::Controller;
  14 use File::stat;
  15 use NEXT;
  16 use Text::SimpleTable;
  17 use Path::Class::Dir;
  18 use Path::Class::File;
  19 use Time::HiRes qw/gettimeofday tv_interval/;
  20 use URI;
  21 use Scalar::Util qw/weaken blessed/;
  22 use Tree::Simple qw/use_weak_refs/;
  23 use Tree::Simple::Visitor::FindByUID;
  24 use attributes;
  25 use utf8;
  26 use Carp qw/croak/;
  27
  28 __PACKAGE__->mk_accessors(
  29     qw/counter request response state action stack namespace stats/
  30 );
  31
  32 attributes->import( __PACKAGE__, \&namespace, 'lvalue' );
  33
  34 sub depth { scalar @{ shift->stack || [] }; }
  35
  36 # Laziness++
  37 *comp = \&component;
  38 *req  = \&request;
  39 *res  = \&response;
  40
  41 # For backwards compatibility
  42 *finalize_output = \&finalize_body;
  43
  44 # For statistics
  45 our $COUNT     = 1;
  46 our $START     = time;
  47 our $RECURSION = 1000;
  48 our $DETACH    = "catalyst_detach\n";
  49
  50 require Module::Pluggable::Fast;
  51
  52 # Helper script generation
  53 our $CATALYST_SCRIPT_GEN = 27;
  54
  55 __PACKAGE__->mk_classdata($_)
  56   for qw/components arguments dispatcher engine log dispatcher_class
  57   engine_class context_class request_class response_class setup_finished/;
  58
  59 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  60 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  61 __PACKAGE__->request_class('Catalyst::Request');
  62 __PACKAGE__->response_class('Catalyst::Response');
  63
  64 our $VERSION = '5.67';
  65
  66 sub import {
  67     my ( $class, @arguments ) = @_;
  68
  69     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  70     # callers @ISA.
  71     return unless $class eq 'Catalyst';
  72
  73     my $caller = caller(0);
  74
  75     unless ( $caller->isa('Catalyst') ) {
  76         no strict 'refs';
  77         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  78     }
  79
  80     $caller->arguments( [@arguments] );
  81     $caller->setup_home;
  82 }
  83
  84 =head1 NAME
  85
  86 Catalyst - The Elegant MVC Web Application Framework
  87
  88 =head1 SYNOPSIS
  89
  90     # use the helper to create a new application
  91     catalyst.pl MyApp
  92
  93     # add models, views, controllers
  94     script/myapp_create.pl model Database DBIC dbi:SQLite:/path/to/db
  95     script/myapp_create.pl view TT TT
  96     script/myapp_create.pl controller Search
  97
  98     # built in testserver -- use -r to restart automatically on changes
  99     script/myapp_server.pl
 100
 101     # command line testing interface
 102     script/myapp_test.pl /yada
 103
 104     ### in lib/MyApp.pm
 105     use Catalyst qw/-Debug/; # include plugins here as well
 106
 107         ### In libMyApp/Controller/Root.pm (autocreated)
 108     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 109         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 110         $c->stash->{template} = 'foo.tt'; # set the template
 111         # lookup something from db -- stash vars are passed to TT
 112         $c->stash->{data} =
 113           $c->model('Database::Foo')->search( { country => $args[0] } );
 114         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 115             $c->forward( 'bar' ); # process another action
 116             # do something else after forward returns
 117         }
 118     }
 119
 120     # The foo.tt TT template can use the stash data from the database
 121     [% WHILE (item = data.next) %]
 122         [% item.foo %]
 123     [% END %]
 124
 125     # called for /bar/of/soap, /bar/of/soap/10, etc.
 126     sub bar : Path('/bar/of/soap') { ... }
 127
 128     # called for all actions, from the top-most controller downwards
 129     sub auto : Private {
 130         my ( $self, $c ) = @_;
 131         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 132             $c->res->redirect( '/login' ); # require login
 133             return 0; # abort request and go immediately to end()
 134         }
 135         return 1; # success; carry on to next action
 136     }
 137
 138     # called after all actions are finished
 139     sub end : Private {
 140         my ( $self, $c ) = @_;
 141         if ( scalar @{ $c->error } ) { ... } # handle errors
 142         return if $c->res->body; # already have a response
 143         $c->forward( 'MyApp::View::TT' ); # render template
 144     }
 145
 146     ### in MyApp/Controller/Foo.pm
 147     # called for /foo/bar
 148     sub bar : Local { ... }
 149
 150     # called for /blargle
 151     sub blargle : Global { ... }
 152
 153     # an index action matches /foo, but not /foo/1, etc.
 154     sub index : Private { ... }
 155
 156     ### in MyApp/Controller/Foo/Bar.pm
 157     # called for /foo/bar/baz
 158     sub baz : Local { ... }
 159
 160     # first Root auto is called, then Foo auto, then this
 161     sub auto : Private { ... }
 162
 163     # powerful regular expression paths are also possible
 164     sub details : Regex('^product/(\w+)/details$') {
 165         my ( $self, $c ) = @_;
 166         # extract the (\w+) from the URI
 167         my $product = $c->req->snippets->[0];
 168     }
 169
 170 See L<Catalyst::Manual::Intro> for additional information.
 171
 172 =head1 DESCRIPTION
 173
 174 Catalyst is a modern framework for making web applications without the pain usually associated with this process. This document is a reference to the main Catalyst application. If you are a new user, we suggest you start with L<Catalyst::Manual::Tutorial> or  L<Catalyst::Manual::Intro>
 175
 176 See L<Catalyst::Manual> for more documentation.
 177
 178 Catalyst plugins can be loaded by naming them as arguments to the "use
 179 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 180 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 181 C<My::Module>.
 182
 183     use Catalyst qw/My::Module/;
 184
 185 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 186 fully qualify the name by using a unary plus:
 187
 188     use Catalyst qw/
 189         My::Module
 190         +Fully::Qualified::Plugin::Name
 191     /;
 192
 193 Special flags like C<-Debug> and C<-Engine> can also be specified as
 194 arguments when Catalyst is loaded:
 195
 196     use Catalyst qw/-Debug My::Module/;
 197
 198 The position of plugins and flags in the chain is important, because
 199 they are loaded in exactly the order in which they appear.
 200
 201 The following flags are supported:
 202
 203 =head2 -Debug
 204
 205 Enables debug output.
 206
 207 =head2 -Engine
 208
 209 Forces Catalyst to use a specific engine. Omit the
 210 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 211
 212     use Catalyst qw/-Engine=CGI/;
 213
 214 =head2 -Home
 215
 216 Forces Catalyst to use a specific home directory, e.g.:
 217
 218     use Catalyst qw[-Home=/usr/sri];
 219
 220 =head2 -Log
 221
 222 Specifies log level.
 223
 224 =head1 METHODS
 225
 226 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 227
 228 =head2 $c->action
 229
 230 Returns a L<Catalyst::Action> object for the current action, which
 231 stringifies to the action name. See L<Catalyst::Action>.
 232
 233 =head2 $c->namespace
 234
 235 Returns the namespace of the current action, i.e., the uri prefix
 236 corresponding to the controller of the current action. For example:
 237
 238     # in Controller::Foo::Bar
 239     $c->namespace; # returns 'foo/bar';
 240
 241 =head2 $c->request
 242
 243 =head2 $c->req
 244
 245 Returns the current L<Catalyst::Request> object. See
 246 L<Catalyst::Request>.
 247
 248 =head2 REQUEST FLOW HANDLING
 249
 250 =head2 $c->forward( $action [, \@arguments ] )
 251
 252 =head2 $c->forward( $class, $method, [, \@arguments ] )
 253
 254 Forwards processing to another action, by it's private name. If you give a
 255 class name but no method, C<process()> is called. You may also optionally
 256 pass arguments in an arrayref. The action will receive the arguments in
 257 C<@_> and C<$c-E<gt>req-E<gt>args>. Upon returning from the function,
 258 C<$c-E<gt>req-E<gt>args> will be restored to the previous values.
 259
 260 Any data C<return>ed from the action forwarded to, will be returned by the
 261 call to forward.
 262
 263     my $foodata = $c->forward('/foo');
 264     $c->forward('index');
 265     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 266     $c->forward('MyApp::View::TT');
 267
 268 Note that forward implies an C<<eval { }>> around the call (well, actually
 269 C<execute> does), thus de-fatalizing all 'dies' within the called action. If
 270 you want C<die> to propagate you need to do something like:
 271
 272     $c->forward('foo');
 273     die $c->error if $c->error;
 274
 275 Or make sure to always return true values from your actions and write your code
 276 like this:
 277
 278     $c->forward('foo') || return;
 279
 280 =cut
 281
 282 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 283
 284 =head2 $c->detach( $action [, \@arguments ] )
 285
 286 =head2 $c->detach( $class, $method, [, \@arguments ] )
 287
 288 The same as C<forward>, but doesn't return to the previous action when
 289 processing is finished.
 290
 291 =cut
 292
 293 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 294
 295 =head2 $c->response
 296
 297 =head2 $c->res
 298
 299 Returns the current L<Catalyst::Response> object.
 300
 301 =head2 $c->stash
 302
 303 Returns a hashref to the stash, which may be used to store data and pass
 304 it between components during a request. You can also set hash keys by
 305 passing arguments. The stash is automatically sent to the view. The
 306 stash is cleared at the end of a request; it cannot be used for
 307 persistent storage.
 308
 309     $c->stash->{foo} = $bar;
 310     $c->stash( { moose => 'majestic', qux => 0 } );
 311     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 312
 313     # stash is automatically passed to the view for use in a template
 314     $c->forward( 'MyApp::V::TT' );
 315
 316 =cut
 317
 318 sub stash {
 319     my $c = shift;
 320     if (@_) {
 321         my $stash = @_ > 1 ? {@_} : $_[0];
 322         while ( my ( $key, $val ) = each %$stash ) {
 323             $c->{stash}->{$key} = $val;
 324         }
 325     }
 326     return $c->{stash};
 327 }
 328
 329 =head2 $c->error
 330
 331 =head2 $c->error($error, ...)
 332
 333 =head2 $c->error($arrayref)
 334
 335 Returns an arrayref containing error messages.  If Catalyst encounters an
 336 error while processing a request, it stores the error in $c->error.  This
 337 method should not be used to store non-fatal error messages.
 338
 339     my @error = @{ $c->error };
 340
 341 Add a new error.
 342
 343     $c->error('Something bad happened');
 344
 345 =cut
 346
 347 sub error {
 348     my $c = shift;
 349     if ( $_[0] ) {
 350         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 351         croak @$error unless ref $c;
 352         push @{ $c->{error} }, @$error;
 353     }
 354     elsif ( defined $_[0] ) { $c->{error} = undef }
 355     return $c->{error} || [];
 356 }
 357
 358
 359 =head2 $c->state
 360
 361 Contains the return value of the last executed action.
 362
 363 =head2 $c->clear_errors
 364
 365 Clear errors.  You probably don't want to clear the errors unless you are
 366 implementing a custom error screen.
 367
 368 This is equivalent to running
 369
 370     $c->error(0);
 371
 372 =cut
 373
 374 sub clear_errors {
 375     my $c = shift;
 376     $c->error(0);
 377 }
 378
 379
 380
 381
 382 # search via regex
 383 sub _comp_search {
 384     my ( $c, @names ) = @_;
 385
 386     foreach my $name (@names) {
 387         foreach my $component ( keys %{ $c->components } ) {
 388             return $c->components->{$component} if $component =~ /$name/i;
 389         }
 390     }
 391
 392     return undef;
 393 }
 394
 395 # try explicit component names
 396 sub _comp_explicit {
 397     my ( $c, @names ) = @_;
 398
 399     foreach my $try (@names) {
 400         return $c->components->{$try} if ( exists $c->components->{$try} );
 401     }
 402
 403     return undef;
 404 }
 405
 406 # like component, but try just these prefixes before regex searching,
 407 #  and do not try to return "sort keys %{ $c->components }"
 408 sub _comp_prefixes {
 409     my ( $c, $name, @prefixes ) = @_;
 410
 411     my $appclass = ref $c || $c;
 412
 413     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 414
 415     my $comp = $c->_comp_explicit(@names);
 416     return $comp if defined($comp);
 417     $comp = $c->_comp_search($name);
 418     return $comp;
 419 }
 420
 421 # Find possible names for a prefix
 422
 423 sub _comp_names {
 424     my ( $c, @prefixes ) = @_;
 425
 426     my $appclass = ref $c || $c;
 427
 428     my @pre = map { "${appclass}::${_}::" } @prefixes;
 429
 430     my @names;
 431
 432     COMPONENT: foreach my $comp ($c->component) {
 433         foreach my $p (@pre) {
 434             if ($comp =~ s/^$p//) {
 435                 push(@names, $comp);
 436                 next COMPONENT;
 437             }
 438         }
 439     }
 440
 441     return @names;
 442 }
 443
 444 # Return a component if only one matches.
 445 sub _comp_singular {
 446     my ( $c, @prefixes ) = @_;
 447
 448     my $appclass = ref $c || $c;
 449
 450     my ( $comp, $rest ) =
 451       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 452     return $comp unless $rest;
 453 }
 454
 455 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 456 sub _filter_component {
 457     my ( $c, $comp, @args ) = @_;
 458     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 459         return $comp->ACCEPT_CONTEXT( $c, @args );
 460     }
 461     else { return $comp }
 462 }
 463
 464 =head2 COMPONENT ACCESSORS
 465
 466 =head2 $c->controller($name)
 467
 468 Gets a L<Catalyst::Controller> instance by name.
 469
 470     $c->controller('Foo')->do_stuff;
 471
 472 If name is omitted, will return the controller for the dispatched action.
 473
 474 =cut
 475
 476 sub controller {
 477     my ( $c, $name, @args ) = @_;
 478     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 479         @args )
 480       if ($name);
 481     return $c->component( $c->action->class );
 482 }
 483
 484 =head2 $c->model($name)
 485
 486 Gets a L<Catalyst::Model> instance by name.
 487
 488     $c->model('Foo')->do_stuff;
 489
 490 If the name is omitted, it will look for a config setting 'default_model',
 491 or check if there is only one model, and forward to it if that's the case.
 492
 493 =cut
 494
 495 sub model {
 496     my ( $c, $name, @args ) = @_;
 497     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 498         @args )
 499       if $name;
 500     return $c->component( $c->config->{default_model} )
 501       if $c->config->{default_model};
 502     return $c->_filter_component( $c->_comp_singular(qw/Model M/), @args );
 503
 504 }
 505
 506 =head2 $c->controllers
 507
 508 Returns the available names which can be passed to $c->controller
 509
 510 =cut
 511
 512 sub controllers {
 513     my ( $c ) = @_;
 514     return $c->_comp_names(qw/Controller C/);
 515 }
 516
 517
 518 =head2 $c->view($name)
 519
 520 Gets a L<Catalyst::View> instance by name.
 521
 522     $c->view('Foo')->do_stuff;
 523
 524 If the name is omitted, it will look for a config setting 'default_view',
 525 or check if there is only one view, and forward to it if that's the case.
 526
 527 =cut
 528
 529 sub view {
 530     my ( $c, $name, @args ) = @_;
 531     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 532         @args )
 533       if $name;
 534     return $c->component( $c->config->{default_view} )
 535       if $c->config->{default_view};
 536     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 537 }
 538
 539 =head2 $c->models
 540
 541 Returns the available names which can be passed to $c->model
 542
 543 =cut
 544
 545 sub models {
 546     my ( $c ) = @_;
 547     return $c->_comp_names(qw/Model M/);
 548 }
 549
 550
 551 =head2 $c->views
 552
 553 Returns the available names which can be passed to $c->view
 554
 555 =cut
 556
 557 sub views {
 558     my ( $c ) = @_;
 559     return $c->_comp_names(qw/View V/);
 560 }
 561
 562 =head2 $c->comp($name)
 563
 564 =head2 $c->component($name)
 565
 566 Gets a component object by name. This method is no longer recommended,
 567 unless you want to get a specific component by full
 568 class. C<$c-E<gt>controller>, C<$c-E<gt>model>, and C<$c-E<gt>view>
 569 should be used instead.
 570
 571 =cut
 572
 573 sub component {
 574     my $c = shift;
 575
 576     if (@_) {
 577
 578         my $name = shift;
 579
 580         my $appclass = ref $c || $c;
 581
 582         my @names = (
 583             $name, "${appclass}::${name}",
 584             map { "${appclass}::${_}::${name}" }
 585               qw/Model M Controller C View V/
 586         );
 587
 588         my $comp = $c->_comp_explicit(@names);
 589         return $c->_filter_component( $comp, @_ ) if defined($comp);
 590
 591         $comp = $c->_comp_search($name);
 592         return $c->_filter_component( $comp, @_ ) if defined($comp);
 593     }
 594
 595     return sort keys %{ $c->components };
 596 }
 597
 598
 599
 600 =head2 CLASS DATA AND HELPER CLASSES
 601
 602 =head2 $c->config
 603
 604 Returns or takes a hashref containing the application's configuration.
 605
 606     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 607
 608 You can also use a L<YAML> config file like myapp.yml in your
 609 applications home directory.
 610
 611     ---
 612     db: dsn:SQLite:foo.db
 613
 614
 615 =cut
 616
 617 sub config {
 618     my $c = shift;
 619
 620     $c->log->warn("Setting config after setup has been run is not a good idea.")
 621       if ( @_ and $c->setup_finished );
 622
 623     $c->NEXT::config(@_);
 624 }
 625
 626 =head2 $c->log
 627
 628 Returns the logging object instance. Unless it is already set, Catalyst sets
 629 this up with a L<Catalyst::Log> object. To use your own log class, set the
 630 logger with the C<< __PACKAGE__->log >> method prior to calling
 631 C<< __PACKAGE__->setup >>.
 632
 633  __PACKAGE__->log( MyLogger->new );
 634  __PACKAGE__->setup;
 635
 636 And later:
 637
 638     $c->log->info( 'Now logging with my own logger!' );
 639
 640 Your log class should implement the methods described in the
 641 L<Catalyst::Log> man page.
 642
 643
 644 =head2 $c->debug
 645
 646 Overload to enable debug messages (same as -Debug option).
 647
 648 =cut
 649
 650 sub debug { 0 }
 651
 652 =head2 $c->dispatcher
 653
 654 Returns the dispatcher instance. Stringifies to class name. See
 655 L<Catalyst::Dispatcher>.
 656
 657 =head2 $c->engine
 658
 659 Returns the engine instance. Stringifies to the class name. See
 660 L<Catalyst::Engine>.
 661
 662
 663 =head2 UTILITY METHODS
 664
 665 =head2 $c->path_to(@path)
 666
 667 Merges C<@path> with C<$c-E<gt>config-E<gt>{home}> and returns a
 668 L<Path::Class> object.
 669
 670 For example:
 671
 672     $c->path_to( 'db', 'sqlite.db' );
 673
 674 =cut
 675
 676 sub path_to {
 677     my ( $c, @path ) = @_;
 678     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 679     if ( -d $path ) { return $path }
 680     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 681 }
 682
 683 =head2 $c->plugin( $name, $class, @args )
 684
 685 Helper method for plugins. It creates a classdata accessor/mutator and
 686 loads and instantiates the given class.
 687
 688     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 689
 690     $c->prototype->define_javascript_functions;
 691
 692 =cut
 693
 694 sub plugin {
 695     my ( $class, $name, $plugin, @args ) = @_;
 696     $class->_register_plugin( $plugin, 1 );
 697
 698     eval { $plugin->import };
 699     $class->mk_classdata($name);
 700     my $obj;
 701     eval { $obj = $plugin->new(@args) };
 702
 703     if ($@) {
 704         Catalyst::Exception->throw( message =>
 705               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 706     }
 707
 708     $class->$name($obj);
 709     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 710       if $class->debug;
 711 }
 712
 713 =head2 MyApp->setup
 714
 715 Initializes the dispatcher and engine, loads any plugins, and loads the
 716 model, view, and controller components. You may also specify an array
 717 of plugins to load here, if you choose to not load them in the C<use
 718 Catalyst> line.
 719
 720     MyApp->setup;
 721     MyApp->setup( qw/-Debug/ );
 722
 723 =cut
 724
 725 sub setup {
 726     my ( $class, @arguments ) = @_;
 727
 728     unless ( $class->isa('Catalyst') ) {
 729
 730         Catalyst::Exception->throw(
 731             message => qq/'$class' does not inherit from Catalyst/ );
 732     }
 733
 734     if ( $class->arguments ) {
 735         @arguments = ( @arguments, @{ $class->arguments } );
 736     }
 737
 738     # Process options
 739     my $flags = {};
 740
 741     foreach (@arguments) {
 742
 743         if (/^-Debug$/) {
 744             $flags->{log} =
 745               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 746         }
 747         elsif (/^-(\w+)=?(.*)$/) {
 748             $flags->{ lc $1 } = $2;
 749         }
 750         else {
 751             push @{ $flags->{plugins} }, $_;
 752         }
 753     }
 754
 755     $class->setup_home( delete $flags->{home} );
 756
 757     $class->setup_log( delete $flags->{log} );
 758     $class->setup_plugins( delete $flags->{plugins} );
 759     $class->setup_dispatcher( delete $flags->{dispatcher} );
 760     $class->setup_engine( delete $flags->{engine} );
 761
 762     for my $flag ( sort keys %{$flags} ) {
 763
 764         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 765             &$code( $class, delete $flags->{$flag} );
 766         }
 767         else {
 768             $class->log->warn(qq/Unknown flag "$flag"/);
 769         }
 770     }
 771
 772     $class->log->warn(
 773         <<"EOF") if ( $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::CATALYST_SCRIPT_GEN ) );
 774 You are running an old script!
 775
 776   Please update by running (this will overwrite existing files):
 777     catalyst.pl -force -scripts $class
 778
 779   or (this will not overwrite existing files):
 780     catalyst.pl -scripts $class
 781 EOF
 782
 783     if ( $class->debug ) {
 784
 785         my @plugins = ();
 786
 787         {
 788             no strict 'refs';
 789             @plugins =
 790               map { $_ . ' ' . ( $_->VERSION || '' ) }
 791               grep { /^Catalyst::Plugin/ } @{"$class\::ISA"};
 792         }
 793
 794         if (@plugins) {
 795             my $t = Text::SimpleTable->new(76);
 796             $t->row($_) for @plugins;
 797             $class->log->debug( "Loaded plugins:\n" . $t->draw );
 798         }
 799
 800         my $dispatcher = $class->dispatcher;
 801         my $engine     = $class->engine;
 802         my $home       = $class->config->{home};
 803
 804         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 805         $class->log->debug(qq/Loaded engine "$engine"/);
 806
 807         $home
 808           ? ( -d $home )
 809           ? $class->log->debug(qq/Found home "$home"/)
 810           : $class->log->debug(qq/Home "$home" doesn't exist/)
 811           : $class->log->debug(q/Couldn't find home/);
 812     }
 813
 814     # Call plugins setup
 815     {
 816         no warnings qw/redefine/;
 817         local *setup = sub { };
 818         $class->setup;
 819     }
 820
 821     # Initialize our data structure
 822     $class->components( {} );
 823
 824     $class->setup_components;
 825
 826     if ( $class->debug ) {
 827         my $t = Text::SimpleTable->new( [ 65, 'Class' ], [ 8, 'Type' ] );
 828         for my $comp ( sort keys %{ $class->components } ) {
 829             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 830             $t->row( $comp, $type );
 831         }
 832         $class->log->debug( "Loaded components:\n" . $t->draw )
 833           if ( keys %{ $class->components } );
 834     }
 835
 836     # Add our self to components, since we are also a component
 837     $class->components->{$class} = $class;
 838
 839     $class->setup_actions;
 840
 841     if ( $class->debug ) {
 842         my $name = $class->config->{name} || 'Application';
 843         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 844     }
 845     $class->log->_flush() if $class->log->can('_flush');
 846
 847     $class->setup_finished(1);
 848 }
 849
 850 =head2 $c->uri_for( $path, @args?, \%query_values? )
 851
 852 Merges path with C<$c-E<gt>request-E<gt>base> for absolute uri's and
 853 with C<$c-E<gt>namespace> for relative uri's, then returns a
 854 normalized L<URI> object. If any args are passed, they are added at the
 855 end of the path.  If the last argument to uri_for is a hash reference,
 856 it is assumed to contain GET parameter key/value pairs, which will be
 857 appended to the URI in standard fashion.
 858
 859 =cut
 860
 861 sub uri_for {
 862     my ( $c, $path, @args ) = @_;
 863     my $base     = $c->request->base->clone;
 864     my $basepath = $base->path;
 865     $basepath =~ s/\/$//;
 866     $basepath .= '/';
 867     my $namespace = $c->namespace;
 868
 869     # massage namespace, empty if absolute path
 870     $namespace =~ s/^\///;
 871     $namespace .= '/' if $namespace;
 872     $path ||= '';
 873     $namespace = '' if $path =~ /^\//;
 874     $path =~ s/^\///;
 875
 876     my $params =
 877       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 878
 879     for my $value ( values %$params ) {\r
 880         my $isa_ref = ref $value;\r
 881         if( $isa_ref and $isa_ref ne 'ARRAY' ) {\r
 882             croak( "Non-array reference ($isa_ref) passed to uri_for()" );\r
 883         }\r
 884         utf8::encode( $_ ) for grep { defined } $isa_ref ? @$value : $value;\r
 885     };
 886
 887     # join args with '/', or a blank string
 888     my $args = ( scalar @args ? '/' . join( '/', @args ) : '' );
 889     $args =~ s/^\/// unless $path;
 890     my $res =
 891       URI->new_abs( URI->new_abs( "$path$args", "$basepath$namespace" ), $base )
 892       ->canonical;
 893     $res->query_form(%$params);
 894     $res;
 895 }
 896
 897 =head2 $c->welcome_message
 898
 899 Returns the Catalyst welcome HTML page.
 900
 901 =cut
 902
 903 sub welcome_message {
 904     my $c      = shift;
 905     my $name   = $c->config->{name};
 906     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
 907     my $prefix = Catalyst::Utils::appprefix( ref $c );
 908     $c->response->content_type('text/html; charset=utf-8');
 909     return <<"EOF";
 910 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
 911     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
 912 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 913     <head>
 914         <meta http-equiv="Content-Language" content="en" />
 915         <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
 916         <title>$name on Catalyst $VERSION</title>
 917         <style type="text/css">
 918             body {
 919                 color: #000;
 920                 background-color: #eee;
 921             }
 922             div#content {
 923                 width: 640px;
 924                 margin-left: auto;
 925                 margin-right: auto;
 926                 margin-top: 10px;
 927                 margin-bottom: 10px;
 928                 text-align: left;
 929                 background-color: #ccc;
 930                 border: 1px solid #aaa;
 931                 -moz-border-radius: 10px;
 932             }
 933             p, h1, h2 {
 934                 margin-left: 20px;
 935                 margin-right: 20px;
 936                 font-family: verdana, tahoma, sans-serif;
 937             }
 938             a {
 939                 font-family: verdana, tahoma, sans-serif;
 940             }
 941             :link, :visited {
 942                     text-decoration: none;
 943                     color: #b00;
 944                     border-bottom: 1px dotted #bbb;
 945             }
 946             :link:hover, :visited:hover {
 947                     color: #555;
 948             }
 949             div#topbar {
 950                 margin: 0px;
 951             }
 952             pre {
 953                 margin: 10px;
 954                 padding: 8px;
 955             }
 956             div#answers {
 957                 padding: 8px;
 958                 margin: 10px;
 959                 background-color: #fff;
 960                 border: 1px solid #aaa;
 961                 -moz-border-radius: 10px;
 962             }
 963             h1 {
 964                 font-size: 0.9em;
 965                 font-weight: normal;
 966                 text-align: center;
 967             }
 968             h2 {
 969                 font-size: 1.0em;
 970             }
 971             p {
 972                 font-size: 0.9em;
 973             }
 974             p img {
 975                 float: right;
 976                 margin-left: 10px;
 977             }
 978             span#appname {
 979                 font-weight: bold;
 980                 font-size: 1.6em;
 981             }
 982         </style>
 983     </head>
 984     <body>
 985         <div id="content">
 986             <div id="topbar">
 987                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
 988                     $VERSION</h1>
 989              </div>
 990              <div id="answers">
 991                  <p>
 992                  <img src="$logo" alt="Catalyst Logo" />
 993                  </p>
 994                  <p>Welcome to the wonderful world of Catalyst.
 995                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
 996                     framework will make web development something you had
 997                     never expected it to be: Fun, rewarding, and quick.</p>
 998                  <h2>What to do now?</h2>
 999                  <p>That really depends  on what <b>you</b> want to do.
1000                     We do, however, provide you with a few starting points.</p>
1001                  <p>If you want to jump right into web development with Catalyst
1002                     you might want to check out the documentation.</p>
1003                  <pre><code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1004 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1005 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual.pod">Catalyst::Manual</a></code></pre>
1006                  <h2>What to do next?</h2>
1007                  <p>Next it's time to write an actual application. Use the
1008                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1009                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1010                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1011                     they can save you a lot of work.</p>
1012                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1013                     <p>Also, be sure to check out the vast and growing
1014                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1015                     you are likely to find what you need there.
1016                     </p>
1017
1018                  <h2>Need help?</h2>
1019                  <p>Catalyst has a very active community. Here are the main places to
1020                     get in touch with us.</p>
1021                  <ul>
1022                      <li>
1023                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1024                      </li>
1025                      <li>
1026                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1027                      </li>
1028                      <li>
1029                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1030                      </li>
1031                  </ul>
1032                  <h2>In conclusion</h2>
1033                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1034                     as we enjoyed making it. Please contact us if you have ideas
1035                     for improvement or other feedback.</p>
1036              </div>
1037          </div>
1038     </body>
1039 </html>
1040 EOF
1041 }
1042
1043 =head1 INTERNAL METHODS
1044
1045 These methods are not meant to be used by end users.
1046
1047 =head2 $c->components
1048
1049 Returns a hash of components.
1050
1051 =head2 $c->context_class
1052
1053 Returns or sets the context class.
1054
1055 =head2 $c->counter
1056
1057 Returns a hashref containing coderefs and execution counts (needed for
1058 deep recursion detection).
1059
1060 =head2 $c->depth
1061
1062 Returns the number of actions on the current internal execution stack.
1063
1064 =head2 $c->dispatch
1065
1066 Dispatches a request to actions.
1067
1068 =cut
1069
1070 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1071
1072 =head2 $c->dispatcher_class
1073
1074 Returns or sets the dispatcher class.
1075
1076 =head2 $c->dump_these
1077
1078 Returns a list of 2-element array references (name, structure) pairs
1079 that will be dumped on the error page in debug mode.
1080
1081 =cut
1082
1083 sub dump_these {
1084     my $c = shift;
1085     [ Request => $c->req ], [ Response => $c->res ], [ Stash => $c->stash ],;
1086 }
1087
1088 =head2 $c->engine_class
1089
1090 Returns or sets the engine class.
1091
1092 =head2 $c->execute( $class, $coderef )
1093
1094 Execute a coderef in given class and catch exceptions. Errors are available
1095 via $c->error.
1096
1097 =cut
1098
1099 sub execute {
1100     my ( $c, $class, $code ) = @_;
1101     $class = $c->component($class) || $class;
1102     $c->state(0);
1103
1104     if ( $c->depth >= $RECURSION ) {
1105         my $action = "$code";
1106         $action = "/$action" unless $action =~ /\-\>/;
1107         my $error = qq/Deep recursion detected calling "$action"/;
1108         $c->log->error($error);
1109         $c->error($error);
1110         $c->state(0);
1111         return $c->state;
1112     }
1113
1114     my $stats_info = $c->_stats_start_execute( $code );
1115
1116     push( @{ $c->stack }, $code );
1117
1118     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1119
1120     $c->_stats_finish_execute( $stats_info );
1121
1122     my $last = ${ $c->stack }[-1];
1123     pop( @{ $c->stack } );
1124
1125     if ( my $error = $@ ) {
1126         if ( $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1127         else {
1128             unless ( ref $error ) {
1129                 chomp $error;
1130                 my $class = $last->class;
1131                 my $name  = $last->name;
1132                 $error = qq/Caught exception in $class->$name "$error"/;
1133             }
1134             $c->error($error);
1135             $c->state(0);
1136         }
1137     }
1138     return $c->state;
1139 }
1140
1141 sub _stats_start_execute {
1142     my ( $c, $code ) = @_;
1143
1144     return unless $c->debug;
1145
1146     my $action = "$code";
1147
1148     $action = "/$action" unless $action =~ /\-\>/;
1149     $c->counter->{"$code"}++;
1150
1151     # determine if the call was the result of a forward
1152     # this is done by walking up the call stack and looking for a calling
1153     # sub of Catalyst::forward before the eval
1154     my $callsub = q{};
1155     for my $index ( 2 .. 11 ) {
1156         last
1157         if ( ( caller($index) )[0] eq 'Catalyst'
1158             && ( caller($index) )[3] eq '(eval)' );
1159
1160         if ( ( caller($index) )[3] =~ /forward$/ ) {
1161             $callsub = ( caller($index) )[3];
1162             $action  = "-> $action";
1163             last;
1164         }
1165     }
1166
1167     my $node = Tree::Simple->new(
1168         {
1169             action  => $action,
1170             elapsed => undef,     # to be filled in later
1171             comment => "",
1172         }
1173     );
1174     $node->setUID( "$code" . $c->counter->{"$code"} );
1175
1176     unless ( ( $code->name =~ /^_.*/ )
1177         && ( !$c->config->{show_internal_actions} ) )
1178     {
1179         # is this a root-level call or a forwarded call?
1180         if ( $callsub =~ /forward$/ ) {
1181
1182             # forward, locate the caller
1183             if ( my $parent = $c->stack->[-1] ) {
1184                 my $visitor = Tree::Simple::Visitor::FindByUID->new;
1185                 $visitor->searchForUID(
1186                     "$parent" . $c->counter->{"$parent"} );
1187                 $c->stats->accept($visitor);
1188                 if ( my $result = $visitor->getResult ) {
1189                     $result->addChild($node);
1190                 }
1191             }
1192             else {
1193
1194                 # forward with no caller may come from a plugin
1195                 $c->stats->addChild($node);
1196             }
1197         }
1198         else {
1199
1200             # root-level call
1201             $c->stats->addChild($node);
1202         }
1203     }
1204
1205     my $start = [gettimeofday];
1206     my $elapsed = tv_interval($start);
1207
1208     return {
1209         code    => $code,
1210         elapsed => $elapsed,
1211         start   => $start,
1212         node    => $node,
1213       }
1214 }
1215
1216 sub _stats_finish_execute {
1217     my ( $c, $info ) = @_;
1218
1219     return unless $c->debug;
1220
1221     my ( $code, $start, $elapsed ) = @{ $info }{qw/code start elapsed/};
1222
1223     unless ( ( $code->name =~ /^_.*/ )
1224         && ( !$c->config->{show_internal_actions} ) )
1225     {
1226
1227         # FindByUID uses an internal die, so we save the existing error
1228         my $error = $@;
1229
1230         # locate the node in the tree and update the elapsed time
1231         my $visitor = Tree::Simple::Visitor::FindByUID->new;
1232         $visitor->searchForUID( "$code" . $c->counter->{"$code"} );
1233         $c->stats->accept($visitor);
1234         if ( my $result = $visitor->getResult ) {
1235             my $value = $result->getNodeValue;
1236             $value->{elapsed} = sprintf( '%fs', $elapsed );
1237             $result->setNodeValue($value);
1238         }
1239
1240         # restore error
1241         $@ = $error || undef;
1242     }
1243 }
1244
1245 =head2 $c->_localize_fields( sub { }, \%keys );
1246
1247 =cut
1248
1249 sub _localize_fields {
1250     my ( $c, $localized, $code ) = ( @_ );
1251
1252     my $request = delete $localized->{request} || {};
1253     my $response = delete $localized->{response} || {};
1254
1255     local @{ $c }{ keys %$localized } = values %$localized;
1256     local @{ $c->request }{ keys %$request } = values %$request;
1257     local @{ $c->response }{ keys %$response } = values %$response;
1258
1259     $code->();
1260 }
1261
1262 =head2 $c->finalize
1263
1264 Finalizes the request.
1265
1266 =cut
1267
1268 sub finalize {
1269     my $c = shift;
1270
1271     for my $error ( @{ $c->error } ) {
1272         $c->log->error($error);
1273     }
1274
1275     # Allow engine to handle finalize flow (for POE)
1276     if ( $c->engine->can('finalize') ) {
1277         $c->engine->finalize( $c );
1278     }
1279     else {
1280
1281         $c->finalize_uploads;
1282
1283         # Error
1284         if ( $#{ $c->error } >= 0 ) {
1285             $c->finalize_error;
1286         }
1287
1288         $c->finalize_headers;
1289
1290         # HEAD request
1291         if ( $c->request->method eq 'HEAD' ) {
1292             $c->response->body('');
1293         }
1294
1295         $c->finalize_body;
1296     }
1297
1298     return $c->response->status;
1299 }
1300
1301 =head2 $c->finalize_body
1302
1303 Finalizes body.
1304
1305 =cut
1306
1307 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1308
1309 =head2 $c->finalize_cookies
1310
1311 Finalizes cookies.
1312
1313 =cut
1314
1315 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1316
1317 =head2 $c->finalize_error
1318
1319 Finalizes error.
1320
1321 =cut
1322
1323 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1324
1325 =head2 $c->finalize_headers
1326
1327 Finalizes headers.
1328
1329 =cut
1330
1331 sub finalize_headers {
1332     my $c = shift;
1333
1334     # Check if we already finalized headers
1335     return if $c->response->{_finalized_headers};
1336
1337     # Handle redirects
1338     if ( my $location = $c->response->redirect ) {
1339         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1340         $c->response->header( Location => $location );
1341     }
1342
1343     # Content-Length
1344     if ( $c->response->body && !$c->response->content_length ) {
1345
1346         # get the length from a filehandle
1347         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1348         {
1349             if ( my $stat = stat $c->response->body ) {
1350                 $c->response->content_length( $stat->size );
1351             }
1352             else {
1353                 $c->log->warn('Serving filehandle without a content-length');
1354             }
1355         }
1356         else {
1357             $c->response->content_length( bytes::length( $c->response->body ) );
1358         }
1359     }
1360
1361     # Errors
1362     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1363         $c->response->headers->remove_header("Content-Length");
1364         $c->response->body('');
1365     }
1366
1367     $c->finalize_cookies;
1368
1369     $c->engine->finalize_headers( $c, @_ );
1370
1371     # Done
1372     $c->response->{_finalized_headers} = 1;
1373 }
1374
1375 =head2 $c->finalize_output
1376
1377 An alias for finalize_body.
1378
1379 =head2 $c->finalize_read
1380
1381 Finalizes the input after reading is complete.
1382
1383 =cut
1384
1385 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1386
1387 =head2 $c->finalize_uploads
1388
1389 Finalizes uploads. Cleans up any temporary files.
1390
1391 =cut
1392
1393 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1394
1395 =head2 $c->get_action( $action, $namespace )
1396
1397 Gets an action in a given namespace.
1398
1399 =cut
1400
1401 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1402
1403 =head2 $c->get_actions( $action, $namespace )
1404
1405 Gets all actions of a given name in a namespace and all parent
1406 namespaces.
1407
1408 =cut
1409
1410 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1411
1412 =head2 $c->handle_request( $class, @arguments )
1413
1414 Called to handle each HTTP request.
1415
1416 =cut
1417
1418 sub handle_request {
1419     my ( $class, @arguments ) = @_;
1420
1421     # Always expect worst case!
1422     my $status = -1;
1423     eval {
1424         my $stats = ( $class->debug ) ? Tree::Simple->new: q{};
1425
1426         my $handler = sub {
1427             my $c = $class->prepare(@arguments);
1428             $c->stats($stats);
1429             $c->dispatch;
1430             return $c->finalize;
1431         };
1432
1433         if ( $class->debug ) {
1434             my $start = [gettimeofday];
1435             $status = &$handler;
1436             my $elapsed = tv_interval $start;
1437             $elapsed = sprintf '%f', $elapsed;
1438             my $av = sprintf '%.3f',
1439               ( $elapsed == 0 ? '??' : ( 1 / $elapsed ) );
1440             my $t = Text::SimpleTable->new( [ 64, 'Action' ], [ 9, 'Time' ] );
1441
1442             $stats->traverse(
1443                 sub {
1444                     my $action = shift;
1445                     my $stat   = $action->getNodeValue;
1446                     $t->row( ( q{ } x $action->getDepth ) . $stat->{action} . $stat->{comment},
1447                         $stat->{elapsed} || '??' );
1448                 }
1449             );
1450
1451             $class->log->info(
1452                 "Request took ${elapsed}s ($av/s)\n" . $t->draw );
1453         }
1454         else { $status = &$handler }
1455
1456     };
1457
1458     if ( my $error = $@ ) {
1459         chomp $error;
1460         $class->log->error(qq/Caught exception in engine "$error"/);
1461     }
1462
1463     $COUNT++;
1464     $class->log->_flush() if $class->log->can('_flush');
1465     return $status;
1466 }
1467
1468 =head2 $c->prepare( @arguments )
1469
1470 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1471 etc.).
1472
1473 =cut
1474
1475 sub prepare {
1476     my ( $class, @arguments ) = @_;
1477
1478     $class->context_class( ref $class || $class ) unless $class->context_class;
1479     my $c = $class->context_class->new(
1480         {
1481             counter => {},
1482             stack   => [],
1483             request => $class->request_class->new(
1484                 {
1485                     arguments        => [],
1486                     body_parameters  => {},
1487                     cookies          => {},
1488                     headers          => HTTP::Headers->new,
1489                     parameters       => {},
1490                     query_parameters => {},
1491                     secure           => 0,
1492                     snippets         => [],
1493                     uploads          => {}
1494                 }
1495             ),
1496             response => $class->response_class->new(
1497                 {
1498                     body    => '',
1499                     cookies => {},
1500                     headers => HTTP::Headers->new(),
1501                     status  => 200
1502                 }
1503             ),
1504             stash => {},
1505             state => 0
1506         }
1507     );
1508
1509     # For on-demand data
1510     $c->request->{_context}  = $c;
1511     $c->response->{_context} = $c;
1512     weaken( $c->request->{_context} );
1513     weaken( $c->response->{_context} );
1514
1515     if ( $c->debug ) {
1516         my $secs = time - $START || 1;
1517         my $av = sprintf '%.3f', $COUNT / $secs;
1518         $c->log->debug('**********************************');
1519         $c->log->debug("* Request $COUNT ($av/s) [$$]");
1520         $c->log->debug('**********************************');
1521         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1522     }
1523
1524     # Allow engine to direct the prepare flow (for POE)
1525     if ( $c->engine->can('prepare') ) {
1526         $c->engine->prepare( $c, @arguments );
1527     }
1528     else {
1529         $c->prepare_request(@arguments);
1530         $c->prepare_connection;
1531         $c->prepare_query_parameters;
1532         $c->prepare_headers;
1533         $c->prepare_cookies;
1534         $c->prepare_path;
1535
1536         # On-demand parsing
1537         $c->prepare_body unless $c->config->{parse_on_demand};
1538     }
1539
1540     my $method  = $c->req->method  || '';
1541     my $path    = $c->req->path    || '';
1542     my $address = $c->req->address || '';
1543
1544     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1545       if $c->debug;
1546
1547     $c->prepare_action;
1548
1549     return $c;
1550 }
1551
1552 =head2 $c->prepare_action
1553
1554 Prepares action. See L<Catalyst::Dispatcher>.
1555
1556 =cut
1557
1558 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1559
1560 =head2 $c->prepare_body
1561
1562 Prepares message body.
1563
1564 =cut
1565
1566 sub prepare_body {
1567     my $c = shift;
1568
1569     # Do we run for the first time?
1570     return if defined $c->request->{_body};
1571
1572     # Initialize on-demand data
1573     $c->engine->prepare_body( $c, @_ );
1574     $c->prepare_parameters;
1575     $c->prepare_uploads;
1576
1577     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1578         my $t = Text::SimpleTable->new( [ 37, 'Key' ], [ 36, 'Value' ] );
1579         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1580             my $param = $c->req->body_parameters->{$key};
1581             my $value = defined($param) ? $param : '';
1582             $t->row( $key,
1583                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1584         }
1585         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1586     }
1587 }
1588
1589 =head2 $c->prepare_body_chunk( $chunk )
1590
1591 Prepares a chunk of data before sending it to L<HTTP::Body>.
1592
1593 See L<Catalyst::Engine>.
1594
1595 =cut
1596
1597 sub prepare_body_chunk {
1598     my $c = shift;
1599     $c->engine->prepare_body_chunk( $c, @_ );
1600 }
1601
1602 =head2 $c->prepare_body_parameters
1603
1604 Prepares body parameters.
1605
1606 =cut
1607
1608 sub prepare_body_parameters {
1609     my $c = shift;
1610     $c->engine->prepare_body_parameters( $c, @_ );
1611 }
1612
1613 =head2 $c->prepare_connection
1614
1615 Prepares connection.
1616
1617 =cut
1618
1619 sub prepare_connection {
1620     my $c = shift;
1621     $c->engine->prepare_connection( $c, @_ );
1622 }
1623
1624 =head2 $c->prepare_cookies
1625
1626 Prepares cookies.
1627
1628 =cut
1629
1630 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1631
1632 =head2 $c->prepare_headers
1633
1634 Prepares headers.
1635
1636 =cut
1637
1638 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1639
1640 =head2 $c->prepare_parameters
1641
1642 Prepares parameters.
1643
1644 =cut
1645
1646 sub prepare_parameters {
1647     my $c = shift;
1648     $c->prepare_body_parameters;
1649     $c->engine->prepare_parameters( $c, @_ );
1650 }
1651
1652 =head2 $c->prepare_path
1653
1654 Prepares path and base.
1655
1656 =cut
1657
1658 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1659
1660 =head2 $c->prepare_query_parameters
1661
1662 Prepares query parameters.
1663
1664 =cut
1665
1666 sub prepare_query_parameters {
1667     my $c = shift;
1668
1669     $c->engine->prepare_query_parameters( $c, @_ );
1670
1671     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1672         my $t = Text::SimpleTable->new( [ 37, 'Key' ], [ 36, 'Value' ] );
1673         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1674             my $param = $c->req->query_parameters->{$key};
1675             my $value = defined($param) ? $param : '';
1676             $t->row( $key,
1677                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1678         }
1679         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1680     }
1681 }
1682
1683 =head2 $c->prepare_read
1684
1685 Prepares the input for reading.
1686
1687 =cut
1688
1689 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1690
1691 =head2 $c->prepare_request
1692
1693 Prepares the engine request.
1694
1695 =cut
1696
1697 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1698
1699 =head2 $c->prepare_uploads
1700
1701 Prepares uploads.
1702
1703 =cut
1704
1705 sub prepare_uploads {
1706     my $c = shift;
1707
1708     $c->engine->prepare_uploads( $c, @_ );
1709
1710     if ( $c->debug && keys %{ $c->request->uploads } ) {
1711         my $t = Text::SimpleTable->new(
1712             [ 12, 'Key' ],
1713             [ 28, 'Filename' ],
1714             [ 18, 'Type' ],
1715             [ 9,  'Size' ]
1716         );
1717         for my $key ( sort keys %{ $c->request->uploads } ) {
1718             my $upload = $c->request->uploads->{$key};
1719             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1720                 $t->row( $key, $u->filename, $u->type, $u->size );
1721             }
1722         }
1723         $c->log->debug( "File Uploads are:\n" . $t->draw );
1724     }
1725 }
1726
1727 =head2 $c->prepare_write
1728
1729 Prepares the output for writing.
1730
1731 =cut
1732
1733 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1734
1735 =head2 $c->request_class
1736
1737 Returns or sets the request class.
1738
1739 =head2 $c->response_class
1740
1741 Returns or sets the response class.
1742
1743 =head2 $c->read( [$maxlength] )
1744
1745 Reads a chunk of data from the request body. This method is designed to
1746 be used in a while loop, reading C<$maxlength> bytes on every call.
1747 C<$maxlength> defaults to the size of the request if not specified.
1748
1749 You have to set C<MyApp-E<gt>config-E<gt>{parse_on_demand}> to use this
1750 directly.
1751
1752 =cut
1753
1754 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1755
1756 =head2 $c->run
1757
1758 Starts the engine.
1759
1760 =cut
1761
1762 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1763
1764 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1765
1766 Sets an action in a given namespace.
1767
1768 =cut
1769
1770 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1771
1772 =head2 $c->setup_actions($component)
1773
1774 Sets up actions for a component.
1775
1776 =cut
1777
1778 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1779
1780 =head2 $c->setup_components
1781
1782 Sets up components.
1783
1784 =cut
1785
1786 sub setup_components {
1787     my $class = shift;
1788
1789     my $callback = sub {
1790         my ( $component, $context ) = @_;
1791
1792         unless ( $component->can('COMPONENT') ) {
1793             return $component;
1794         }
1795
1796         my $suffix = Catalyst::Utils::class2classsuffix($component);
1797         my $config = $class->config->{$suffix} || {};
1798
1799         my $instance;
1800
1801         eval { $instance = $component->COMPONENT( $context, $config ); };
1802
1803         if ( my $error = $@ ) {
1804
1805             chomp $error;
1806
1807             Catalyst::Exception->throw( message =>
1808                   qq/Couldn't instantiate component "$component", "$error"/ );
1809         }
1810
1811         Catalyst::Exception->throw( message =>
1812 qq/Couldn't instantiate component "$component", "COMPONENT() didn't return a object"/
1813           )
1814           unless ref $instance;
1815         return $instance;
1816     };
1817
1818     eval "package $class;\n" . q!Module::Pluggable::Fast->import(
1819             name   => '_catalyst_components',
1820             search => [
1821                 "$class\::Controller", "$class\::C",
1822                 "$class\::Model",      "$class\::M",
1823                 "$class\::View",       "$class\::V"
1824             ],
1825             callback => $callback
1826         );
1827     !;
1828
1829     if ( my $error = $@ ) {
1830
1831         chomp $error;
1832
1833         Catalyst::Exception->throw(
1834             message => qq/Couldn't load components "$error"/ );
1835     }
1836
1837     for my $component ( $class->_catalyst_components($class) ) {
1838         $class->components->{ ref $component || $component } = $component;
1839     }
1840 }
1841
1842 =head2 $c->setup_dispatcher
1843
1844 Sets up dispatcher.
1845
1846 =cut
1847
1848 sub setup_dispatcher {
1849     my ( $class, $dispatcher ) = @_;
1850
1851     if ($dispatcher) {
1852         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1853     }
1854
1855     if ( $ENV{CATALYST_DISPATCHER} ) {
1856         $dispatcher = 'Catalyst::Dispatcher::' . $ENV{CATALYST_DISPATCHER};
1857     }
1858
1859     if ( $ENV{ uc($class) . '_DISPATCHER' } ) {
1860         $dispatcher =
1861           'Catalyst::Dispatcher::' . $ENV{ uc($class) . '_DISPATCHER' };
1862     }
1863
1864     unless ($dispatcher) {
1865         $dispatcher = $class->dispatcher_class;
1866     }
1867
1868     $dispatcher->require;
1869
1870     if ($@) {
1871         Catalyst::Exception->throw(
1872             message => qq/Couldn't load dispatcher "$dispatcher", "$@"/ );
1873     }
1874
1875     # dispatcher instance
1876     $class->dispatcher( $dispatcher->new );
1877 }
1878
1879 =head2 $c->setup_engine
1880
1881 Sets up engine.
1882
1883 =cut
1884
1885 sub setup_engine {
1886     my ( $class, $engine ) = @_;
1887
1888     if ($engine) {
1889         $engine = 'Catalyst::Engine::' . $engine;
1890     }
1891
1892     if ( $ENV{CATALYST_ENGINE} ) {
1893         $engine = 'Catalyst::Engine::' . $ENV{CATALYST_ENGINE};
1894     }
1895
1896     if ( $ENV{ uc($class) . '_ENGINE' } ) {
1897         $engine = 'Catalyst::Engine::' . $ENV{ uc($class) . '_ENGINE' };
1898     }
1899
1900     if ( $ENV{MOD_PERL} ) {
1901
1902         # create the apache method
1903         {
1904             no strict 'refs';
1905             *{"$class\::apache"} = sub { shift->engine->apache };
1906         }
1907
1908         my ( $software, $version ) =
1909           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1910
1911         $version =~ s/_//g;
1912         $version =~ s/(\.[^.]+)\./$1/g;
1913
1914         if ( $software eq 'mod_perl' ) {
1915
1916             if ( !$engine ) {
1917
1918                 if ( $version >= 1.99922 ) {
1919                     $engine = 'Catalyst::Engine::Apache2::MP20';
1920                 }
1921
1922                 elsif ( $version >= 1.9901 ) {
1923                     $engine = 'Catalyst::Engine::Apache2::MP19';
1924                 }
1925
1926                 elsif ( $version >= 1.24 ) {
1927                     $engine = 'Catalyst::Engine::Apache::MP13';
1928                 }
1929
1930                 else {
1931                     Catalyst::Exception->throw( message =>
1932                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
1933                 }
1934
1935             }
1936
1937             # install the correct mod_perl handler
1938             if ( $version >= 1.9901 ) {
1939                 *handler = sub  : method {
1940                     shift->handle_request(@_);
1941                 };
1942             }
1943             else {
1944                 *handler = sub ($$) { shift->handle_request(@_) };
1945             }
1946
1947         }
1948
1949         elsif ( $software eq 'Zeus-Perl' ) {
1950             $engine = 'Catalyst::Engine::Zeus';
1951         }
1952
1953         else {
1954             Catalyst::Exception->throw(
1955                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
1956         }
1957     }
1958
1959     unless ($engine) {
1960         $engine = $class->engine_class;
1961     }
1962
1963     $engine->require;
1964
1965     if ($@) {
1966         Catalyst::Exception->throw( message =>
1967 qq/Couldn't load engine "$engine" (maybe you forgot to install it?), "$@"/
1968         );
1969     }
1970
1971     # check for old engines that are no longer compatible
1972     my $old_engine;
1973     if ( $engine->isa('Catalyst::Engine::Apache')
1974         && !Catalyst::Engine::Apache->VERSION )
1975     {
1976         $old_engine = 1;
1977     }
1978
1979     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
1980         && Catalyst::Engine::Server->VERSION le '0.02' )
1981     {
1982         $old_engine = 1;
1983     }
1984
1985     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
1986         && $engine->VERSION eq '0.01' )
1987     {
1988         $old_engine = 1;
1989     }
1990
1991     elsif ($engine->isa('Catalyst::Engine::Zeus')
1992         && $engine->VERSION eq '0.01' )
1993     {
1994         $old_engine = 1;
1995     }
1996
1997     if ($old_engine) {
1998         Catalyst::Exception->throw( message =>
1999               qq/Engine "$engine" is not supported by this version of Catalyst/
2000         );
2001     }
2002
2003     # engine instance
2004     $class->engine( $engine->new );
2005 }
2006
2007 =head2 $c->setup_home
2008
2009 Sets up the home directory.
2010
2011 =cut
2012
2013 sub setup_home {
2014     my ( $class, $home ) = @_;
2015
2016     if ( $ENV{CATALYST_HOME} ) {
2017         $home = $ENV{CATALYST_HOME};
2018     }
2019
2020     if ( $ENV{ uc($class) . '_HOME' } ) {
2021         $home = $ENV{ uc($class) . '_HOME' };
2022     }
2023
2024     unless ($home) {
2025         $home = Catalyst::Utils::home($class);
2026     }
2027
2028     if ($home) {
2029         $class->config->{home} ||= $home;
2030         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2031     }
2032 }
2033
2034 =head2 $c->setup_log
2035
2036 Sets up log.
2037
2038 =cut
2039
2040 sub setup_log {
2041     my ( $class, $debug ) = @_;
2042
2043     unless ( $class->log ) {
2044         $class->log( Catalyst::Log->new );
2045     }
2046
2047     my $app_flag = Catalyst::Utils::class2env($class) . '_DEBUG';
2048
2049     if (
2050           ( defined( $ENV{CATALYST_DEBUG} ) || defined( $ENV{$app_flag} ) )
2051         ? ( $ENV{CATALYST_DEBUG} || $ENV{$app_flag} )
2052         : $debug
2053       )
2054     {
2055         no strict 'refs';
2056         *{"$class\::debug"} = sub { 1 };
2057         $class->log->debug('Debug messages enabled');
2058     }
2059 }
2060
2061 =head2 $c->setup_plugins
2062
2063 Sets up plugins.
2064
2065 =cut
2066
2067 =head2 $c->registered_plugins
2068
2069 Returns a sorted list of the plugins which have either been stated in the
2070 import list or which have been added via C<< MyApp->plugin(@args); >>.
2071
2072 If passed a given plugin name, it will report a boolean value indicating
2073 whether or not that plugin is loaded.  A fully qualified name is required if
2074 the plugin name does not begin with C<Catalyst::Plugin::>.
2075
2076  if ($c->registered_plugins('Some::Plugin')) {
2077      ...
2078  }
2079
2080 =cut
2081
2082 {
2083
2084     sub registered_plugins {
2085         my $proto = shift;
2086         return sort keys %{ $proto->_plugins } unless @_;
2087         my $plugin = shift;
2088         return 1 if exists $proto->_plugins->{$plugin};
2089         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2090     }
2091
2092     sub _register_plugin {
2093         my ( $proto, $plugin, $instant ) = @_;
2094         my $class = ref $proto || $proto;
2095
2096         $plugin->require;
2097
2098         if ( my $error = $@ ) {
2099             my $type = $instant ? "instant " : '';
2100             Catalyst::Exception->throw(
2101                 message => qq/Couldn't load ${type}plugin "$plugin", $error/ );
2102         }
2103
2104         $proto->_plugins->{$plugin} = 1;
2105         unless ($instant) {
2106             no strict 'refs';
2107             unshift @{"$class\::ISA"}, $plugin;
2108         }
2109         return $class;
2110     }
2111
2112     sub setup_plugins {
2113         my ( $class, $plugins ) = @_;
2114
2115         $class->_plugins( {} ) unless $class->_plugins;
2116         $plugins ||= [];
2117         for my $plugin ( reverse @$plugins ) {
2118
2119             unless ( $plugin =~ s/\A\+// ) {
2120                 $plugin = "Catalyst::Plugin::$plugin";
2121             }
2122
2123             $class->_register_plugin($plugin);
2124         }
2125     }
2126 }
2127
2128 =head2 $c->stack
2129
2130 Returns an arrayref of the internal execution stack (actions that are currently
2131 executing).
2132
2133 =head2 $c->write( $data )
2134
2135 Writes $data to the output stream. When using this method directly, you
2136 will need to manually set the C<Content-Length> header to the length of
2137 your output data, if known.
2138
2139 =cut
2140
2141 sub write {
2142     my $c = shift;
2143
2144     # Finalize headers if someone manually writes output
2145     $c->finalize_headers;
2146
2147     return $c->engine->write( $c, @_ );
2148 }
2149
2150 =head2 version
2151
2152 Returns the Catalyst version number. Mostly useful for "powered by"
2153 messages in template systems.
2154
2155 =cut
2156
2157 sub version { return $Catalyst::VERSION }
2158
2159 =head1 INTERNAL ACTIONS
2160
2161 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2162 C<_ACTION>, and C<_END>. These are by default not shown in the private
2163 action table, but you can make them visible with a config parameter.
2164
2165     MyApp->config->{show_internal_actions} = 1;
2166
2167 =head1 CASE SENSITIVITY
2168
2169 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2170 mapped to C</foo/bar>. You can activate case sensitivity with a config
2171 parameter.
2172
2173     MyApp->config->{case_sensitive} = 1;
2174
2175 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2176
2177 =head1 ON-DEMAND PARSER
2178
2179 The request body is usually parsed at the beginning of a request,
2180 but if you want to handle input yourself or speed things up a bit,
2181 you can enable on-demand parsing with a config parameter.
2182
2183     MyApp->config->{parse_on_demand} = 1;
2184
2185 =head1 PROXY SUPPORT
2186
2187 Many production servers operate using the common double-server approach,
2188 with a lightweight frontend web server passing requests to a larger
2189 backend server. An application running on the backend server must deal
2190 with two problems: the remote user always appears to be C<127.0.0.1> and
2191 the server's hostname will appear to be C<localhost> regardless of the
2192 virtual host that the user connected through.
2193
2194 Catalyst will automatically detect this situation when you are running
2195 the frontend and backend servers on the same machine. The following
2196 changes are made to the request.
2197
2198     $c->req->address is set to the user's real IP address, as read from
2199     the HTTP X-Forwarded-For header.
2200
2201     The host value for $c->req->base and $c->req->uri is set to the real
2202     host, as read from the HTTP X-Forwarded-Host header.
2203
2204 Obviously, your web server must support these headers for this to work.
2205
2206 In a more complex server farm environment where you may have your
2207 frontend proxy server(s) on different machines, you will need to set a
2208 configuration option to tell Catalyst to read the proxied data from the
2209 headers.
2210
2211     MyApp->config->{using_frontend_proxy} = 1;
2212
2213 If you do not wish to use the proxy support at all, you may set:
2214
2215     MyApp->config->{ignore_frontend_proxy} = 1;
2216
2217 =head1 THREAD SAFETY
2218
2219 Catalyst has been tested under Apache 2's threading mpm_worker, mpm_winnt,
2220 and the standalone forking HTTP server on Windows. We believe the Catalyst
2221 core to be thread-safe.
2222
2223 If you plan to operate in a threaded environment, remember that all other
2224 modules you are using must also be thread-safe. Some modules, most notably
2225 L<DBD::SQLite>, are not thread-safe.
2226
2227 =head1 SUPPORT
2228
2229 IRC:
2230
2231     Join #catalyst on irc.perl.org.
2232
2233 Mailing Lists:
2234
2235     http://lists.rawmode.org/mailman/listinfo/catalyst
2236     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2237
2238 Web:
2239
2240     http://catalyst.perl.org
2241
2242 Wiki:
2243
2244     http://dev.catalyst.perl.org
2245
2246 =head1 SEE ALSO
2247
2248 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2249
2250 =head2 L<Catalyst::Manual> - The Catalyst Manual
2251
2252 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2253
2254 =head2 L<Catalyst::Engine> - Core engine
2255
2256 =head2 L<Catalyst::Log> - Log class.
2257
2258 =head2 L<Catalyst::Request> - Request object
2259
2260 =head2 L<Catalyst::Response> - Response object
2261
2262 =head2 L<Catalyst::Test> - The test suite.
2263
2264 =head1 CREDITS
2265
2266 Andy Grundman
2267
2268 Andy Wardley
2269
2270 Andreas Marienborg
2271
2272 Andrew Bramble
2273
2274 Andrew Ford
2275
2276 Andrew Ruthven
2277
2278 Arthur Bergman
2279
2280 Autrijus Tang
2281
2282 Brian Cassidy
2283
2284 Carl Franks
2285
2286 Christian Hansen
2287
2288 Christopher Hicks
2289
2290 Dan Sully
2291
2292 Danijel Milicevic
2293
2294 David Kamholz
2295
2296 David Naughton
2297
2298 Drew Taylor
2299
2300 Gary Ashton Jones
2301
2302 Geoff Richards
2303
2304 Jesse Sheidlower
2305
2306 Jesse Vincent
2307
2308 Jody Belka
2309
2310 Johan Lindstrom
2311
2312 Juan Camacho
2313
2314 Leon Brocard
2315
2316 Marcus Ramberg
2317
2318 Matt S Trout
2319
2320 Robert Sedlacek
2321
2322 Sam Vilain
2323
2324 Sascha Kiefer
2325
2326 Tatsuhiko Miyagawa
2327
2328 Ulf Edvinsson
2329
2330 Yuval Kogman
2331
2332 =head1 AUTHOR
2333
2334 Sebastian Riedel, C<sri@oook.de>
2335
2336 =head1 LICENSE
2337
2338 This library is free software, you can redistribute it and/or modify it under
2339 the same terms as Perl itself.
2340
2341 =cut
2342
2343 1;