lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken blessed/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 __PACKAGE__->mk_accessors(
  34     qw/counter request response state action stack namespace stats/
  35 );
  36
  37 attributes->import( __PACKAGE__, \&namespace, 'lvalue' );
  38
  39 sub depth { scalar @{ shift->stack || [] }; }
  40
  41 # Laziness++
  42 *comp = \&component;
  43 *req  = \&request;
  44 *res  = \&response;
  45
  46 # For backwards compatibility
  47 *finalize_output = \&finalize_body;
  48
  49 # For statistics
  50 our $COUNT     = 1;
  51 our $START     = time;
  52 our $RECURSION = 1000;
  53 our $DETACH    = "catalyst_detach\n";
  54
  55 __PACKAGE__->mk_classdata($_)
  56   for qw/components arguments dispatcher engine log dispatcher_class
  57   engine_class context_class request_class response_class stats_class
  58   setup_finished/;
  59
  60 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  61 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  62 __PACKAGE__->request_class('Catalyst::Request');
  63 __PACKAGE__->response_class('Catalyst::Response');
  64 __PACKAGE__->stats_class('Catalyst::Stats');
  65
  66 # Remember to update this in Catalyst::Runtime as well!
  67
  68 our $VERSION = '5.7012';
  69
  70 sub import {
  71     my ( $class, @arguments ) = @_;
  72
  73     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  74     # callers @ISA.
  75     return unless $class eq 'Catalyst';
  76
  77     my $caller = caller(0);
  78
  79     unless ( $caller->isa('Catalyst') ) {
  80         no strict 'refs';
  81         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  82     }
  83
  84     $caller->arguments( [@arguments] );
  85     $caller->setup_home;
  86 }
  87
  88 =head1 NAME
  89
  90 Catalyst - The Elegant MVC Web Application Framework
  91
  92 =head1 SYNOPSIS
  93
  94 See the L<Catalyst::Manual> distribution for comprehensive
  95 documentation and tutorials.
  96
  97     # Install Catalyst::Devel for helpers and other development tools
  98     # use the helper to create a new application
  99     catalyst.pl MyApp
 100
 101     # add models, views, controllers
 102     script/myapp_create.pl model MyDatabase DBIC::Schema create=dynamic dbi:SQLite:/path/to/db
 103     script/myapp_create.pl view MyTemplate TT
 104     script/myapp_create.pl controller Search
 105
 106     # built in testserver -- use -r to restart automatically on changes
 107     # --help to see all available options
 108     script/myapp_server.pl
 109
 110     # command line testing interface
 111     script/myapp_test.pl /yada
 112
 113     ### in lib/MyApp.pm
 114     use Catalyst qw/-Debug/; # include plugins here as well
 115
 116     ### In lib/MyApp/Controller/Root.pm (autocreated)
 117     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 118         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 119         $c->stash->{template} = 'foo.tt'; # set the template
 120         # lookup something from db -- stash vars are passed to TT
 121         $c->stash->{data} =
 122           $c->model('Database::Foo')->search( { country => $args[0] } );
 123         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 124             $c->forward( 'bar' ); # process another action
 125             # do something else after forward returns
 126         }
 127     }
 128
 129     # The foo.tt TT template can use the stash data from the database
 130     [% WHILE (item = data.next) %]
 131         [% item.foo %]
 132     [% END %]
 133
 134     # called for /bar/of/soap, /bar/of/soap/10, etc.
 135     sub bar : Path('/bar/of/soap') { ... }
 136
 137     # called for all actions, from the top-most controller downwards
 138     sub auto : Private {
 139         my ( $self, $c ) = @_;
 140         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 141             $c->res->redirect( '/login' ); # require login
 142             return 0; # abort request and go immediately to end()
 143         }
 144         return 1; # success; carry on to next action
 145     }
 146
 147     # called after all actions are finished
 148     sub end : Private {
 149         my ( $self, $c ) = @_;
 150         if ( scalar @{ $c->error } ) { ... } # handle errors
 151         return if $c->res->body; # already have a response
 152         $c->forward( 'MyApp::View::TT' ); # render template
 153     }
 154
 155     ### in MyApp/Controller/Foo.pm
 156     # called for /foo/bar
 157     sub bar : Local { ... }
 158
 159     # called for /blargle
 160     sub blargle : Global { ... }
 161
 162     # an index action matches /foo, but not /foo/1, etc.
 163     sub index : Private { ... }
 164
 165     ### in MyApp/Controller/Foo/Bar.pm
 166     # called for /foo/bar/baz
 167     sub baz : Local { ... }
 168
 169     # first Root auto is called, then Foo auto, then this
 170     sub auto : Private { ... }
 171
 172     # powerful regular expression paths are also possible
 173     sub details : Regex('^product/(\w+)/details$') {
 174         my ( $self, $c ) = @_;
 175         # extract the (\w+) from the URI
 176         my $product = $c->req->captures->[0];
 177     }
 178
 179 See L<Catalyst::Manual::Intro> for additional information.
 180
 181 =head1 DESCRIPTION
 182
 183 Catalyst is a modern framework for making web applications without the
 184 pain usually associated with this process. This document is a reference
 185 to the main Catalyst application. If you are a new user, we suggest you
 186 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 187
 188 See L<Catalyst::Manual> for more documentation.
 189
 190 Catalyst plugins can be loaded by naming them as arguments to the "use
 191 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 192 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 193 C<My::Module>.
 194
 195     use Catalyst qw/My::Module/;
 196
 197 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 198 fully qualify the name by using a unary plus:
 199
 200     use Catalyst qw/
 201         My::Module
 202         +Fully::Qualified::Plugin::Name
 203     /;
 204
 205 Special flags like C<-Debug> and C<-Engine> can also be specified as
 206 arguments when Catalyst is loaded:
 207
 208     use Catalyst qw/-Debug My::Module/;
 209
 210 The position of plugins and flags in the chain is important, because
 211 they are loaded in the order in which they appear.
 212
 213 The following flags are supported:
 214
 215 =head2 -Debug
 216
 217 Enables debug output. You can also force this setting from the system
 218 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 219 settings override the application, with <MYAPP>_DEBUG having the highest
 220 priority.
 221
 222 =head2 -Engine
 223
 224 Forces Catalyst to use a specific engine. Omit the
 225 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 226
 227     use Catalyst qw/-Engine=CGI/;
 228
 229 =head2 -Home
 230
 231 Forces Catalyst to use a specific home directory, e.g.:
 232
 233     use Catalyst qw[-Home=/usr/mst];
 234
 235 This can also be done in the shell environment by setting either the
 236 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 237 is replaced with the uppercased name of your application, any "::" in
 238 the name will be replaced with underscores, e.g. MyApp::Web should use
 239 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 240
 241 =head2 -Log
 242
 243 Specifies log level.
 244
 245 =head2 -Stats
 246
 247 Enables statistics collection and reporting. You can also force this setting
 248 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 249 environment settings override the application, with <MYAPP>_STATS having the
 250 highest priority.
 251
 252 e.g.
 253
 254    use Catalyst qw/-Stats=1/
 255
 256 =head1 METHODS
 257
 258 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 259
 260 =head2 $c->action
 261
 262 Returns a L<Catalyst::Action> object for the current action, which
 263 stringifies to the action name. See L<Catalyst::Action>.
 264
 265 =head2 $c->namespace
 266
 267 Returns the namespace of the current action, i.e., the URI prefix
 268 corresponding to the controller of the current action. For example:
 269
 270     # in Controller::Foo::Bar
 271     $c->namespace; # returns 'foo/bar';
 272
 273 =head2 $c->request
 274
 275 =head2 $c->req
 276
 277 Returns the current L<Catalyst::Request> object, giving access to
 278 information about the current client request (including parameters,
 279 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 280
 281 =head2 REQUEST FLOW HANDLING
 282
 283 =head2 $c->forward( $action [, \@arguments ] )
 284
 285 =head2 $c->forward( $class, $method, [, \@arguments ] )
 286
 287 Forwards processing to another action, by its private name. If you give a
 288 class name but no method, C<process()> is called. You may also optionally
 289 pass arguments in an arrayref. The action will receive the arguments in
 290 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 291 C<< $c->req->args >> will be restored to the previous values.
 292
 293 Any data C<return>ed from the action forwarded to, will be returned by the
 294 call to forward.
 295
 296     my $foodata = $c->forward('/foo');
 297     $c->forward('index');
 298     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 299     $c->forward('MyApp::View::TT');
 300
 301 Note that forward implies an C<<eval { }>> around the call (actually
 302 C<execute> does), thus de-fatalizing all 'dies' within the called
 303 action. If you want C<die> to propagate you need to do something like:
 304
 305     $c->forward('foo');
 306     die $c->error if $c->error;
 307
 308 Or make sure to always return true values from your actions and write
 309 your code like this:
 310
 311     $c->forward('foo') || return;
 312
 313 =cut
 314
 315 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 316
 317 =head2 $c->detach( $action [, \@arguments ] )
 318
 319 =head2 $c->detach( $class, $method, [, \@arguments ] )
 320
 321 =head2 $c->detach()
 322
 323 The same as C<forward>, but doesn't return to the previous action when
 324 processing is finished.
 325
 326 When called with no arguments it escapes the processing chain entirely.
 327
 328 =cut
 329
 330 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 331
 332 =head2 $c->response
 333
 334 =head2 $c->res
 335
 336 Returns the current L<Catalyst::Response> object, see there for details.
 337
 338 =head2 $c->stash
 339
 340 Returns a hashref to the stash, which may be used to store data and pass
 341 it between components during a request. You can also set hash keys by
 342 passing arguments. The stash is automatically sent to the view. The
 343 stash is cleared at the end of a request; it cannot be used for
 344 persistent storage (for this you must use a session; see
 345 L<Catalyst::Plugin::Session> for a complete system integrated with
 346 Catalyst).
 347
 348     $c->stash->{foo} = $bar;
 349     $c->stash( { moose => 'majestic', qux => 0 } );
 350     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 351
 352     # stash is automatically passed to the view for use in a template
 353     $c->forward( 'MyApp::View::TT' );
 354
 355 =cut
 356
 357 sub stash {
 358     my $c = shift;
 359     if (@_) {
 360         my $stash = @_ > 1 ? {@_} : $_[0];
 361         croak('stash takes a hash or hashref') unless ref $stash;
 362         foreach my $key ( keys %$stash ) {
 363             $c->{stash}->{$key} = $stash->{$key};
 364         }
 365     }
 366     return $c->{stash};
 367 }
 368
 369 =head2 $c->error
 370
 371 =head2 $c->error($error, ...)
 372
 373 =head2 $c->error($arrayref)
 374
 375 Returns an arrayref containing error messages.  If Catalyst encounters an
 376 error while processing a request, it stores the error in $c->error.  This
 377 method should only be used to store fatal error messages.
 378
 379     my @error = @{ $c->error };
 380
 381 Add a new error.
 382
 383     $c->error('Something bad happened');
 384
 385 =cut
 386
 387 sub error {
 388     my $c = shift;
 389     if ( $_[0] ) {
 390         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 391         croak @$error unless ref $c;
 392         push @{ $c->{error} }, @$error;
 393     }
 394     elsif ( defined $_[0] ) { $c->{error} = undef }
 395     return $c->{error} || [];
 396 }
 397
 398
 399 =head2 $c->state
 400
 401 Contains the return value of the last executed action.
 402
 403 =head2 $c->clear_errors
 404
 405 Clear errors.  You probably don't want to clear the errors unless you are
 406 implementing a custom error screen.
 407
 408 This is equivalent to running
 409
 410     $c->error(0);
 411
 412 =cut
 413
 414 sub clear_errors {
 415     my $c = shift;
 416     $c->error(0);
 417 }
 418
 419
 420 # search via regex
 421 sub _comp_search {
 422     my ( $c, @names ) = @_;
 423
 424     foreach my $name (@names) {
 425         foreach my $component ( keys %{ $c->components } ) {
 426             return $c->components->{$component} if $component =~ /$name/i;
 427         }
 428     }
 429
 430     return undef;
 431 }
 432
 433 # try explicit component names
 434 sub _comp_explicit {
 435     my ( $c, @names ) = @_;
 436
 437     foreach my $try (@names) {
 438         return $c->components->{$try} if ( exists $c->components->{$try} );
 439     }
 440
 441     return undef;
 442 }
 443
 444 # like component, but try just these prefixes before regex searching,
 445 #  and do not try to return "sort keys %{ $c->components }"
 446 sub _comp_prefixes {
 447     my ( $c, $name, @prefixes ) = @_;
 448
 449     my $appclass = ref $c || $c;
 450
 451     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 452
 453     my $comp = $c->_comp_explicit(@names);
 454     return $comp if defined($comp);
 455     $comp = $c->_comp_search($name);
 456     return $comp;
 457 }
 458
 459 # Find possible names for a prefix
 460
 461 sub _comp_names {
 462     my ( $c, @prefixes ) = @_;
 463
 464     my $appclass = ref $c || $c;
 465
 466     my @pre = map { "${appclass}::${_}::" } @prefixes;
 467
 468     my @names;
 469
 470     COMPONENT: foreach my $comp ($c->component) {
 471         foreach my $p (@pre) {
 472             if ($comp =~ s/^$p//) {
 473                 push(@names, $comp);
 474                 next COMPONENT;
 475             }
 476         }
 477     }
 478
 479     return @names;
 480 }
 481
 482 # Return a component if only one matches.
 483 sub _comp_singular {
 484     my ( $c, @prefixes ) = @_;
 485
 486     my $appclass = ref $c || $c;
 487
 488     my ( $comp, $rest ) =
 489       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 490     return $comp unless $rest;
 491 }
 492
 493 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 494 sub _filter_component {
 495     my ( $c, $comp, @args ) = @_;
 496     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 497         return $comp->ACCEPT_CONTEXT( $c, @args );
 498     }
 499     else { return $comp }
 500 }
 501
 502 =head2 COMPONENT ACCESSORS
 503
 504 =head2 $c->controller($name)
 505
 506 Gets a L<Catalyst::Controller> instance by name.
 507
 508     $c->controller('Foo')->do_stuff;
 509
 510 If the name is omitted, will return the controller for the dispatched
 511 action.
 512
 513 =cut
 514
 515 sub controller {
 516     my ( $c, $name, @args ) = @_;
 517     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 518         @args )
 519       if ($name);
 520     return $c->component( $c->action->class );
 521 }
 522
 523 =head2 $c->model($name)
 524
 525 Gets a L<Catalyst::Model> instance by name.
 526
 527     $c->model('Foo')->do_stuff;
 528
 529 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 530
 531 If the name is omitted, it will look for
 532  - a model object in $c->stash{current_model_instance}, then
 533  - a model name in $c->stash->{current_model}, then
 534  - a config setting 'default_model', or
 535  - check if there is only one model, and return it if that's the case.
 536
 537 =cut
 538
 539 sub model {
 540     my ( $c, $name, @args ) = @_;
 541     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 542         @args )
 543       if $name;
 544     if (ref $c) {
 545         return $c->stash->{current_model_instance}
 546           if $c->stash->{current_model_instance};
 547         return $c->model( $c->stash->{current_model} )
 548           if $c->stash->{current_model};
 549     }
 550     return $c->model( $c->config->{default_model} )
 551       if $c->config->{default_model};
 552     return $c->_filter_component( $c->_comp_singular(qw/Model M/) );
 553
 554 }
 555
 556 =head2 $c->controllers
 557
 558 Returns the available names which can be passed to $c->controller
 559
 560 =cut
 561
 562 sub controllers {
 563     my ( $c ) = @_;
 564     return $c->_comp_names(qw/Controller C/);
 565 }
 566
 567
 568 =head2 $c->view($name)
 569
 570 Gets a L<Catalyst::View> instance by name.
 571
 572     $c->view('Foo')->do_stuff;
 573
 574 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 575
 576 If the name is omitted, it will look for
 577  - a view object in $c->stash{current_view_instance}, then
 578  - a view name in $c->stash->{current_view}, then
 579  - a config setting 'default_view', or
 580  - check if there is only one view, and return it if that's the case.
 581
 582 =cut
 583
 584 sub view {
 585     my ( $c, $name, @args ) = @_;
 586     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 587         @args )
 588       if $name;
 589     if (ref $c) {
 590         return $c->stash->{current_view_instance}
 591           if $c->stash->{current_view_instance};
 592         return $c->view( $c->stash->{current_view} )
 593           if $c->stash->{current_view};
 594     }
 595     return $c->view( $c->config->{default_view} )
 596       if $c->config->{default_view};
 597     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 598 }
 599
 600 =head2 $c->models
 601
 602 Returns the available names which can be passed to $c->model
 603
 604 =cut
 605
 606 sub models {
 607     my ( $c ) = @_;
 608     return $c->_comp_names(qw/Model M/);
 609 }
 610
 611
 612 =head2 $c->views
 613
 614 Returns the available names which can be passed to $c->view
 615
 616 =cut
 617
 618 sub views {
 619     my ( $c ) = @_;
 620     return $c->_comp_names(qw/View V/);
 621 }
 622
 623 =head2 $c->comp($name)
 624
 625 =head2 $c->component($name)
 626
 627 Gets a component object by name. This method is not recommended,
 628 unless you want to get a specific component by full
 629 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 630 should be used instead.
 631
 632 =cut
 633
 634 sub component {
 635     my $c = shift;
 636
 637     if (@_) {
 638
 639         my $name = shift;
 640
 641         my $appclass = ref $c || $c;
 642
 643         my @names = (
 644             $name, "${appclass}::${name}",
 645             map { "${appclass}::${_}::${name}" }
 646               qw/Model M Controller C View V/
 647         );
 648
 649         my $comp = $c->_comp_explicit(@names);
 650         return $c->_filter_component( $comp, @_ ) if defined($comp);
 651
 652         $comp = $c->_comp_search($name);
 653         return $c->_filter_component( $comp, @_ ) if defined($comp);
 654     }
 655
 656     return sort keys %{ $c->components };
 657 }
 658
 659
 660
 661 =head2 CLASS DATA AND HELPER CLASSES
 662
 663 =head2 $c->config
 664
 665 Returns or takes a hashref containing the application's configuration.
 666
 667     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 668
 669 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 670 like myapp.yml in your applications home directory. See
 671 L<Catalyst::Plugin::ConfigLoader>.
 672
 673     ---
 674     db: dsn:SQLite:foo.db
 675
 676
 677 =cut
 678
 679 sub config {
 680     my $c = shift;
 681
 682     $c->log->warn("Setting config after setup has been run is not a good idea.")
 683       if ( @_ and $c->setup_finished );
 684
 685     $c->NEXT::config(@_);
 686 }
 687
 688 =head2 $c->log
 689
 690 Returns the logging object instance. Unless it is already set, Catalyst
 691 sets this up with a L<Catalyst::Log> object. To use your own log class,
 692 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 693 C<< __PACKAGE__->setup >>.
 694
 695  __PACKAGE__->log( MyLogger->new );
 696  __PACKAGE__->setup;
 697
 698 And later:
 699
 700     $c->log->info( 'Now logging with my own logger!' );
 701
 702 Your log class should implement the methods described in
 703 L<Catalyst::Log>.
 704
 705
 706 =head2 $c->debug
 707
 708 Overload to enable debug messages (same as -Debug option).
 709
 710 Note that this is a static method, not an accessor and should be overloaded
 711 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 712
 713 =cut
 714
 715 sub debug { 0 }
 716
 717 =head2 $c->dispatcher
 718
 719 Returns the dispatcher instance. Stringifies to class name. See
 720 L<Catalyst::Dispatcher>.
 721
 722 =head2 $c->engine
 723
 724 Returns the engine instance. Stringifies to the class name. See
 725 L<Catalyst::Engine>.
 726
 727
 728 =head2 UTILITY METHODS
 729
 730 =head2 $c->path_to(@path)
 731
 732 Merges C<@path> with C<< $c->config->{home} >> and returns a
 733 L<Path::Class::Dir> object.
 734
 735 For example:
 736
 737     $c->path_to( 'db', 'sqlite.db' );
 738
 739 =cut
 740
 741 sub path_to {
 742     my ( $c, @path ) = @_;
 743     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 744     if ( -d $path ) { return $path }
 745     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 746 }
 747
 748 =head2 $c->plugin( $name, $class, @args )
 749
 750 Helper method for plugins. It creates a classdata accessor/mutator and
 751 loads and instantiates the given class.
 752
 753     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 754
 755     $c->prototype->define_javascript_functions;
 756
 757 =cut
 758
 759 sub plugin {
 760     my ( $class, $name, $plugin, @args ) = @_;
 761     $class->_register_plugin( $plugin, 1 );
 762
 763     eval { $plugin->import };
 764     $class->mk_classdata($name);
 765     my $obj;
 766     eval { $obj = $plugin->new(@args) };
 767
 768     if ($@) {
 769         Catalyst::Exception->throw( message =>
 770               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 771     }
 772
 773     $class->$name($obj);
 774     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 775       if $class->debug;
 776 }
 777
 778 =head2 MyApp->setup
 779
 780 Initializes the dispatcher and engine, loads any plugins, and loads the
 781 model, view, and controller components. You may also specify an array
 782 of plugins to load here, if you choose to not load them in the C<use
 783 Catalyst> line.
 784
 785     MyApp->setup;
 786     MyApp->setup( qw/-Debug/ );
 787
 788 =cut
 789
 790 sub setup {
 791     my ( $class, @arguments ) = @_;
 792
 793     $class->log->warn("Running setup twice is not a good idea.")
 794       if ( $class->setup_finished );
 795
 796     unless ( $class->isa('Catalyst') ) {
 797
 798         Catalyst::Exception->throw(
 799             message => qq/'$class' does not inherit from Catalyst/ );
 800     }
 801
 802     if ( $class->arguments ) {
 803         @arguments = ( @arguments, @{ $class->arguments } );
 804     }
 805
 806     # Process options
 807     my $flags = {};
 808
 809     foreach (@arguments) {
 810
 811         if (/^-Debug$/) {
 812             $flags->{log} =
 813               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 814         }
 815         elsif (/^-(\w+)=?(.*)$/) {
 816             $flags->{ lc $1 } = $2;
 817         }
 818         else {
 819             push @{ $flags->{plugins} }, $_;
 820         }
 821     }
 822
 823     $class->setup_home( delete $flags->{home} );
 824
 825     $class->setup_log( delete $flags->{log} );
 826     $class->setup_plugins( delete $flags->{plugins} );
 827     $class->setup_dispatcher( delete $flags->{dispatcher} );
 828     $class->setup_engine( delete $flags->{engine} );
 829     $class->setup_stats( delete $flags->{stats} );
 830
 831     for my $flag ( sort keys %{$flags} ) {
 832
 833         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 834             &$code( $class, delete $flags->{$flag} );
 835         }
 836         else {
 837             $class->log->warn(qq/Unknown flag "$flag"/);
 838         }
 839     }
 840
 841     eval { require Catalyst::Devel; };
 842     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 843         $class->log->warn(<<"EOF");
 844 You are running an old script!
 845
 846   Please update by running (this will overwrite existing files):
 847     catalyst.pl -force -scripts $class
 848
 849   or (this will not overwrite existing files):
 850     catalyst.pl -scripts $class
 851
 852 EOF
 853     }
 854
 855     if ( $class->debug ) {
 856         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 857
 858         if (@plugins) {
 859             my $t = Text::SimpleTable->new(74);
 860             $t->row($_) for @plugins;
 861             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 862         }
 863
 864         my $dispatcher = $class->dispatcher;
 865         my $engine     = $class->engine;
 866         my $home       = $class->config->{home};
 867
 868         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 869         $class->log->debug(qq/Loaded engine "$engine"/);
 870
 871         $home
 872           ? ( -d $home )
 873           ? $class->log->debug(qq/Found home "$home"/)
 874           : $class->log->debug(qq/Home "$home" doesn't exist/)
 875           : $class->log->debug(q/Couldn't find home/);
 876     }
 877
 878     # Call plugins setup
 879     {
 880         no warnings qw/redefine/;
 881         local *setup = sub { };
 882         $class->setup;
 883     }
 884
 885     # Initialize our data structure
 886     $class->components( {} );
 887
 888     $class->setup_components;
 889
 890     if ( $class->debug ) {
 891         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 892         for my $comp ( sort keys %{ $class->components } ) {
 893             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 894             $t->row( $comp, $type );
 895         }
 896         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 897           if ( keys %{ $class->components } );
 898     }
 899
 900     # Add our self to components, since we are also a component
 901     $class->components->{$class} = $class;
 902
 903     $class->setup_actions;
 904
 905     if ( $class->debug ) {
 906         my $name = $class->config->{name} || 'Application';
 907         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 908     }
 909     $class->log->_flush() if $class->log->can('_flush');
 910
 911     $class->setup_finished(1);
 912 }
 913
 914 =head2 $c->uri_for( $path, @args?, \%query_values? )
 915
 916 Merges path with C<< $c->request->base >> for absolute URIs and with
 917 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 918 object. If any args are passed, they are added at the end of the path.
 919 If the last argument to C<uri_for> is a hash reference, it is assumed to
 920 contain GET parameter key/value pairs, which will be appended to the URI
 921 in standard fashion.
 922
 923 Instead of C<$path>, you can also optionally pass a C<$action> object
 924 which will be resolved to a path using
 925 C<< $c->dispatcher->uri_for_action >>; if the first element of
 926 C<@args> is an arrayref it is treated as a list of captures to be passed
 927 to C<uri_for_action>.
 928
 929 =cut
 930
 931 sub uri_for {
 932     my ( $c, $path, @args ) = @_;
 933
 934     if ( Scalar::Util::blessed($path) ) { # action object
 935         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 936                          ? shift(@args)
 937                          : [] );
 938         $path = $c->dispatcher->uri_for_action($path, $captures);
 939         return undef unless defined($path);
 940         $path = '/' if $path eq '';
 941     }
 942
 943     undef($path) if (defined $path && $path eq '');
 944
 945     my $params =
 946       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 947
 948     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
 949     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
 950
 951     unshift(@args, $path);
 952
 953     unless (defined $path && $path =~ s!^/!!) { # in-place strip
 954         my $namespace = $c->namespace;
 955         if (defined $path) { # cheesy hack to handle path '../foo'
 956            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
 957         }
 958         unshift(@args, $namespace || '');
 959     }
 960
 961     # join args with '/', or a blank string
 962     my $args = join('/', grep { defined($_) } @args);
 963     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
 964     $args =~ s!^/!!;
 965     my $base = $c->req->base;
 966     my $class = ref($base);
 967     $base =~ s{(?<!/)$}{/};
 968
 969     my $query = '';
 970
 971     if (my @keys = keys %$params) {
 972       # somewhat lifted from URI::_query's query_form
 973       $query = '?'.join('&', map {
 974           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
 975           s/ /+/g;
 976           my $key = $_;
 977           my $val = $params->{$_};
 978           $val = '' unless defined $val;
 979           (map {
 980               $_ = "$_";
 981               utf8::encode( $_ ) if utf8::is_utf8($_);
 982               # using the URI::Escape pattern here so utf8 chars survive
 983               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
 984               s/ /+/g;
 985               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
 986       } @keys);
 987     }
 988
 989     my $res = bless(\"${base}${args}${query}", $class);
 990     $res;
 991 }
 992
 993 =head2 $c->welcome_message
 994
 995 Returns the Catalyst welcome HTML page.
 996
 997 =cut
 998
 999 sub welcome_message {
1000     my $c      = shift;
1001     my $name   = $c->config->{name};
1002     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1003     my $prefix = Catalyst::Utils::appprefix( ref $c );
1004     $c->response->content_type('text/html; charset=utf-8');
1005     return <<"EOF";
1006 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1007     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1008 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1009     <head>
1010     <meta http-equiv="Content-Language" content="en" />
1011     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1012         <title>$name on Catalyst $VERSION</title>
1013         <style type="text/css">
1014             body {
1015                 color: #000;
1016                 background-color: #eee;
1017             }
1018             div#content {
1019                 width: 640px;
1020                 margin-left: auto;
1021                 margin-right: auto;
1022                 margin-top: 10px;
1023                 margin-bottom: 10px;
1024                 text-align: left;
1025                 background-color: #ccc;
1026                 border: 1px solid #aaa;
1027             }
1028             p, h1, h2 {
1029                 margin-left: 20px;
1030                 margin-right: 20px;
1031                 font-family: verdana, tahoma, sans-serif;
1032             }
1033             a {
1034                 font-family: verdana, tahoma, sans-serif;
1035             }
1036             :link, :visited {
1037                     text-decoration: none;
1038                     color: #b00;
1039                     border-bottom: 1px dotted #bbb;
1040             }
1041             :link:hover, :visited:hover {
1042                     color: #555;
1043             }
1044             div#topbar {
1045                 margin: 0px;
1046             }
1047             pre {
1048                 margin: 10px;
1049                 padding: 8px;
1050             }
1051             div#answers {
1052                 padding: 8px;
1053                 margin: 10px;
1054                 background-color: #fff;
1055                 border: 1px solid #aaa;
1056             }
1057             h1 {
1058                 font-size: 0.9em;
1059                 font-weight: normal;
1060                 text-align: center;
1061             }
1062             h2 {
1063                 font-size: 1.0em;
1064             }
1065             p {
1066                 font-size: 0.9em;
1067             }
1068             p img {
1069                 float: right;
1070                 margin-left: 10px;
1071             }
1072             span#appname {
1073                 font-weight: bold;
1074                 font-size: 1.6em;
1075             }
1076         </style>
1077     </head>
1078     <body>
1079         <div id="content">
1080             <div id="topbar">
1081                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1082                     $VERSION</h1>
1083              </div>
1084              <div id="answers">
1085                  <p>
1086                  <img src="$logo" alt="Catalyst Logo" />
1087                  </p>
1088                  <p>Welcome to the  world of Catalyst.
1089                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1090                     framework will make web development something you had
1091                     never expected it to be: Fun, rewarding, and quick.</p>
1092                  <h2>What to do now?</h2>
1093                  <p>That really depends  on what <b>you</b> want to do.
1094                     We do, however, provide you with a few starting points.</p>
1095                  <p>If you want to jump right into web development with Catalyst
1096                     you might want want to start with a tutorial.</p>
1097 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1098 </pre>
1099 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1100 <pre>
1101 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1102 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1103 </code></pre>
1104                  <h2>What to do next?</h2>
1105                  <p>Next it's time to write an actual application. Use the
1106                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1107                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1108                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1109                     they can save you a lot of work.</p>
1110                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1111                     <p>Also, be sure to check out the vast and growing
1112                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1113                     you are likely to find what you need there.
1114                     </p>
1115
1116                  <h2>Need help?</h2>
1117                  <p>Catalyst has a very active community. Here are the main places to
1118                     get in touch with us.</p>
1119                  <ul>
1120                      <li>
1121                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1122                      </li>
1123                      <li>
1124                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1125                      </li>
1126                      <li>
1127                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1128                      </li>
1129                  </ul>
1130                  <h2>In conclusion</h2>
1131                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1132                     as we enjoyed making it. Please contact us if you have ideas
1133                     for improvement or other feedback.</p>
1134              </div>
1135          </div>
1136     </body>
1137 </html>
1138 EOF
1139 }
1140
1141 =head1 INTERNAL METHODS
1142
1143 These methods are not meant to be used by end users.
1144
1145 =head2 $c->components
1146
1147 Returns a hash of components.
1148
1149 =head2 $c->context_class
1150
1151 Returns or sets the context class.
1152
1153 =head2 $c->counter
1154
1155 Returns a hashref containing coderefs and execution counts (needed for
1156 deep recursion detection).
1157
1158 =head2 $c->depth
1159
1160 Returns the number of actions on the current internal execution stack.
1161
1162 =head2 $c->dispatch
1163
1164 Dispatches a request to actions.
1165
1166 =cut
1167
1168 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1169
1170 =head2 $c->dispatcher_class
1171
1172 Returns or sets the dispatcher class.
1173
1174 =head2 $c->dump_these
1175
1176 Returns a list of 2-element array references (name, structure) pairs
1177 that will be dumped on the error page in debug mode.
1178
1179 =cut
1180
1181 sub dump_these {
1182     my $c = shift;
1183     [ Request => $c->req ],
1184     [ Response => $c->res ],
1185     [ Stash => $c->stash ],
1186     [ Config => $c->config ];
1187 }
1188
1189 =head2 $c->engine_class
1190
1191 Returns or sets the engine class.
1192
1193 =head2 $c->execute( $class, $coderef )
1194
1195 Execute a coderef in given class and catch exceptions. Errors are available
1196 via $c->error.
1197
1198 =cut
1199
1200 sub execute {
1201     my ( $c, $class, $code ) = @_;
1202     $class = $c->component($class) || $class;
1203     $c->state(0);
1204
1205     if ( $c->depth >= $RECURSION ) {
1206         my $action = "$code";
1207         $action = "/$action" unless $action =~ /->/;
1208         my $error = qq/Deep recursion detected calling "$action"/;
1209         $c->log->error($error);
1210         $c->error($error);
1211         $c->state(0);
1212         return $c->state;
1213     }
1214
1215     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1216
1217     push( @{ $c->stack }, $code );
1218
1219     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1220
1221     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1222
1223     my $last = pop( @{ $c->stack } );
1224
1225     if ( my $error = $@ ) {
1226         if ( !ref($error) and $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1227         else {
1228             unless ( ref $error ) {
1229                 no warnings 'uninitialized';
1230                 chomp $error;
1231                 my $class = $last->class;
1232                 my $name  = $last->name;
1233                 $error = qq/Caught exception in $class->$name "$error"/;
1234             }
1235             $c->error($error);
1236             $c->state(0);
1237         }
1238     }
1239     return $c->state;
1240 }
1241
1242 sub _stats_start_execute {
1243     my ( $c, $code ) = @_;
1244
1245     return if ( ( $code->name =~ /^_.*/ )
1246         && ( !$c->config->{show_internal_actions} ) );
1247
1248     $c->counter->{"$code"}++;
1249
1250     my $action = "$code";
1251     $action = "/$action" unless $action =~ /->/;
1252
1253     # determine if the call was the result of a forward
1254     # this is done by walking up the call stack and looking for a calling
1255     # sub of Catalyst::forward before the eval
1256     my $callsub = q{};
1257     for my $index ( 2 .. 11 ) {
1258         last
1259         if ( ( caller($index) )[0] eq 'Catalyst'
1260             && ( caller($index) )[3] eq '(eval)' );
1261
1262         if ( ( caller($index) )[3] =~ /forward$/ ) {
1263             $callsub = ( caller($index) )[3];
1264             $action  = "-> $action";
1265             last;
1266         }
1267     }
1268
1269     my $uid = "$code" . $c->counter->{"$code"};
1270
1271     # is this a root-level call or a forwarded call?
1272     if ( $callsub =~ /forward$/ ) {
1273
1274         # forward, locate the caller
1275         if ( my $parent = $c->stack->[-1] ) {
1276             $c->stats->profile(
1277                 begin  => $action,
1278                 parent => "$parent" . $c->counter->{"$parent"},
1279                 uid    => $uid,
1280             );
1281         }
1282         else {
1283
1284             # forward with no caller may come from a plugin
1285             $c->stats->profile(
1286                 begin => $action,
1287                 uid   => $uid,
1288             );
1289         }
1290     }
1291     else {
1292
1293         # root-level call
1294         $c->stats->profile(
1295             begin => $action,
1296             uid   => $uid,
1297         );
1298     }
1299     return $action;
1300
1301 }
1302
1303 sub _stats_finish_execute {
1304     my ( $c, $info ) = @_;
1305     $c->stats->profile( end => $info );
1306 }
1307
1308 =head2 $c->_localize_fields( sub { }, \%keys );
1309
1310 =cut
1311
1312 sub _localize_fields {
1313     my ( $c, $localized, $code ) = ( @_ );
1314
1315     my $request = delete $localized->{request} || {};
1316     my $response = delete $localized->{response} || {};
1317
1318     local @{ $c }{ keys %$localized } = values %$localized;
1319     local @{ $c->request }{ keys %$request } = values %$request;
1320     local @{ $c->response }{ keys %$response } = values %$response;
1321
1322     $code->();
1323 }
1324
1325 =head2 $c->finalize
1326
1327 Finalizes the request.
1328
1329 =cut
1330
1331 sub finalize {
1332     my $c = shift;
1333
1334     for my $error ( @{ $c->error } ) {
1335         $c->log->error($error);
1336     }
1337
1338     # Allow engine to handle finalize flow (for POE)
1339     if ( $c->engine->can('finalize') ) {
1340         $c->engine->finalize($c);
1341     }
1342     else {
1343
1344         $c->finalize_uploads;
1345
1346         # Error
1347         if ( $#{ $c->error } >= 0 ) {
1348             $c->finalize_error;
1349         }
1350
1351         $c->finalize_headers;
1352
1353         # HEAD request
1354         if ( $c->request->method eq 'HEAD' ) {
1355             $c->response->body('');
1356         }
1357
1358         $c->finalize_body;
1359     }
1360
1361     if ($c->use_stats) {
1362         my $elapsed = sprintf '%f', $c->stats->elapsed;
1363         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1364         $c->log->info(
1365             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1366     }
1367
1368     return $c->response->status;
1369 }
1370
1371 =head2 $c->finalize_body
1372
1373 Finalizes body.
1374
1375 =cut
1376
1377 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1378
1379 =head2 $c->finalize_cookies
1380
1381 Finalizes cookies.
1382
1383 =cut
1384
1385 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1386
1387 =head2 $c->finalize_error
1388
1389 Finalizes error.
1390
1391 =cut
1392
1393 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1394
1395 =head2 $c->finalize_headers
1396
1397 Finalizes headers.
1398
1399 =cut
1400
1401 sub finalize_headers {
1402     my $c = shift;
1403
1404     # Check if we already finalized headers
1405     return if $c->response->{_finalized_headers};
1406
1407     # Handle redirects
1408     if ( my $location = $c->response->redirect ) {
1409         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1410         $c->response->header( Location => $location );
1411
1412         if ( !$c->response->body ) {
1413             # Add a default body if none is already present
1414             $c->response->body(
1415                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1416             );
1417         }
1418     }
1419
1420     # Content-Length
1421     if ( $c->response->body && !$c->response->content_length ) {
1422
1423         # get the length from a filehandle
1424         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1425         {
1426             my $stat = stat $c->response->body;
1427             if ( $stat && $stat->size > 0 ) {
1428                 $c->response->content_length( $stat->size );
1429             }
1430             else {
1431                 $c->log->warn('Serving filehandle without a content-length');
1432             }
1433         }
1434         else {
1435             # everything should be bytes at this point, but just in case
1436             $c->response->content_length( bytes::length( $c->response->body ) );
1437         }
1438     }
1439
1440     # Errors
1441     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1442         $c->response->headers->remove_header("Content-Length");
1443         $c->response->body('');
1444     }
1445
1446     $c->finalize_cookies;
1447
1448     $c->engine->finalize_headers( $c, @_ );
1449
1450     # Done
1451     $c->response->{_finalized_headers} = 1;
1452 }
1453
1454 =head2 $c->finalize_output
1455
1456 An alias for finalize_body.
1457
1458 =head2 $c->finalize_read
1459
1460 Finalizes the input after reading is complete.
1461
1462 =cut
1463
1464 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1465
1466 =head2 $c->finalize_uploads
1467
1468 Finalizes uploads. Cleans up any temporary files.
1469
1470 =cut
1471
1472 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1473
1474 =head2 $c->get_action( $action, $namespace )
1475
1476 Gets an action in a given namespace.
1477
1478 =cut
1479
1480 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1481
1482 =head2 $c->get_actions( $action, $namespace )
1483
1484 Gets all actions of a given name in a namespace and all parent
1485 namespaces.
1486
1487 =cut
1488
1489 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1490
1491 =head2 $c->handle_request( $class, @arguments )
1492
1493 Called to handle each HTTP request.
1494
1495 =cut
1496
1497 sub handle_request {
1498     my ( $class, @arguments ) = @_;
1499
1500     # Always expect worst case!
1501     my $status = -1;
1502     eval {
1503         if ($class->debug) {
1504             my $secs = time - $START || 1;
1505             my $av = sprintf '%.3f', $COUNT / $secs;
1506             my $time = localtime time;
1507             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1508         }
1509
1510         my $c = $class->prepare(@arguments);
1511         $c->dispatch;
1512         $status = $c->finalize;
1513     };
1514
1515     if ( my $error = $@ ) {
1516         chomp $error;
1517         $class->log->error(qq/Caught exception in engine "$error"/);
1518     }
1519
1520     $COUNT++;
1521     $class->log->_flush() if $class->log->can('_flush');
1522     return $status;
1523 }
1524
1525 =head2 $c->prepare( @arguments )
1526
1527 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1528 etc.).
1529
1530 =cut
1531
1532 sub prepare {
1533     my ( $class, @arguments ) = @_;
1534
1535     $class->context_class( ref $class || $class ) unless $class->context_class;
1536     my $c = $class->context_class->new(
1537         {
1538             counter => {},
1539             stack   => [],
1540             request => $class->request_class->new(
1541                 {
1542                     arguments        => [],
1543                     body_parameters  => {},
1544                     cookies          => {},
1545                     headers          => HTTP::Headers->new,
1546                     parameters       => {},
1547                     query_parameters => {},
1548                     secure           => 0,
1549                     captures         => [],
1550                     uploads          => {}
1551                 }
1552             ),
1553             response => $class->response_class->new(
1554                 {
1555                     body    => '',
1556                     cookies => {},
1557                     headers => HTTP::Headers->new(),
1558                     status  => 200
1559                 }
1560             ),
1561             stash => {},
1562             state => 0
1563         }
1564     );
1565
1566     $c->stats($class->stats_class->new)->enable($c->use_stats);
1567     if ( $c->debug ) {
1568         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1569     }
1570
1571     # For on-demand data
1572     $c->request->{_context}  = $c;
1573     $c->response->{_context} = $c;
1574     weaken( $c->request->{_context} );
1575     weaken( $c->response->{_context} );
1576
1577     # Allow engine to direct the prepare flow (for POE)
1578     if ( $c->engine->can('prepare') ) {
1579         $c->engine->prepare( $c, @arguments );
1580     }
1581     else {
1582         $c->prepare_request(@arguments);
1583         $c->prepare_connection;
1584         $c->prepare_query_parameters;
1585         $c->prepare_headers;
1586         $c->prepare_cookies;
1587         $c->prepare_path;
1588
1589         # Prepare the body for reading, either by prepare_body
1590         # or the user, if they are using $c->read
1591         $c->prepare_read;
1592
1593         # Parse the body unless the user wants it on-demand
1594         unless ( $c->config->{parse_on_demand} ) {
1595             $c->prepare_body;
1596         }
1597     }
1598
1599     my $method  = $c->req->method  || '';
1600     my $path    = $c->req->path    || '/';
1601     my $address = $c->req->address || '';
1602
1603     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1604       if $c->debug;
1605
1606     $c->prepare_action;
1607
1608     return $c;
1609 }
1610
1611 =head2 $c->prepare_action
1612
1613 Prepares action. See L<Catalyst::Dispatcher>.
1614
1615 =cut
1616
1617 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1618
1619 =head2 $c->prepare_body
1620
1621 Prepares message body.
1622
1623 =cut
1624
1625 sub prepare_body {
1626     my $c = shift;
1627
1628     # Do we run for the first time?
1629     return if defined $c->request->{_body};
1630
1631     # Initialize on-demand data
1632     $c->engine->prepare_body( $c, @_ );
1633     $c->prepare_parameters;
1634     $c->prepare_uploads;
1635
1636     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1637         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1638         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1639             my $param = $c->req->body_parameters->{$key};
1640             my $value = defined($param) ? $param : '';
1641             $t->row( $key,
1642                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1643         }
1644         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1645     }
1646 }
1647
1648 =head2 $c->prepare_body_chunk( $chunk )
1649
1650 Prepares a chunk of data before sending it to L<HTTP::Body>.
1651
1652 See L<Catalyst::Engine>.
1653
1654 =cut
1655
1656 sub prepare_body_chunk {
1657     my $c = shift;
1658     $c->engine->prepare_body_chunk( $c, @_ );
1659 }
1660
1661 =head2 $c->prepare_body_parameters
1662
1663 Prepares body parameters.
1664
1665 =cut
1666
1667 sub prepare_body_parameters {
1668     my $c = shift;
1669     $c->engine->prepare_body_parameters( $c, @_ );
1670 }
1671
1672 =head2 $c->prepare_connection
1673
1674 Prepares connection.
1675
1676 =cut
1677
1678 sub prepare_connection {
1679     my $c = shift;
1680     $c->engine->prepare_connection( $c, @_ );
1681 }
1682
1683 =head2 $c->prepare_cookies
1684
1685 Prepares cookies.
1686
1687 =cut
1688
1689 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1690
1691 =head2 $c->prepare_headers
1692
1693 Prepares headers.
1694
1695 =cut
1696
1697 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1698
1699 =head2 $c->prepare_parameters
1700
1701 Prepares parameters.
1702
1703 =cut
1704
1705 sub prepare_parameters {
1706     my $c = shift;
1707     $c->prepare_body_parameters;
1708     $c->engine->prepare_parameters( $c, @_ );
1709 }
1710
1711 =head2 $c->prepare_path
1712
1713 Prepares path and base.
1714
1715 =cut
1716
1717 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1718
1719 =head2 $c->prepare_query_parameters
1720
1721 Prepares query parameters.
1722
1723 =cut
1724
1725 sub prepare_query_parameters {
1726     my $c = shift;
1727
1728     $c->engine->prepare_query_parameters( $c, @_ );
1729
1730     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1731         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1732         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1733             my $param = $c->req->query_parameters->{$key};
1734             my $value = defined($param) ? $param : '';
1735             $t->row( $key,
1736                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1737         }
1738         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1739     }
1740 }
1741
1742 =head2 $c->prepare_read
1743
1744 Prepares the input for reading.
1745
1746 =cut
1747
1748 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1749
1750 =head2 $c->prepare_request
1751
1752 Prepares the engine request.
1753
1754 =cut
1755
1756 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1757
1758 =head2 $c->prepare_uploads
1759
1760 Prepares uploads.
1761
1762 =cut
1763
1764 sub prepare_uploads {
1765     my $c = shift;
1766
1767     $c->engine->prepare_uploads( $c, @_ );
1768
1769     if ( $c->debug && keys %{ $c->request->uploads } ) {
1770         my $t = Text::SimpleTable->new(
1771             [ 12, 'Parameter' ],
1772             [ 26, 'Filename' ],
1773             [ 18, 'Type' ],
1774             [ 9,  'Size' ]
1775         );
1776         for my $key ( sort keys %{ $c->request->uploads } ) {
1777             my $upload = $c->request->uploads->{$key};
1778             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1779                 $t->row( $key, $u->filename, $u->type, $u->size );
1780             }
1781         }
1782         $c->log->debug( "File Uploads are:\n" . $t->draw );
1783     }
1784 }
1785
1786 =head2 $c->prepare_write
1787
1788 Prepares the output for writing.
1789
1790 =cut
1791
1792 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1793
1794 =head2 $c->request_class
1795
1796 Returns or sets the request class.
1797
1798 =head2 $c->response_class
1799
1800 Returns or sets the response class.
1801
1802 =head2 $c->read( [$maxlength] )
1803
1804 Reads a chunk of data from the request body. This method is designed to
1805 be used in a while loop, reading C<$maxlength> bytes on every call.
1806 C<$maxlength> defaults to the size of the request if not specified.
1807
1808 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1809 directly.
1810
1811 Warning: If you use read(), Catalyst will not process the body,
1812 so you will not be able to access POST parameters or file uploads via
1813 $c->request.  You must handle all body parsing yourself.
1814
1815 =cut
1816
1817 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1818
1819 =head2 $c->run
1820
1821 Starts the engine.
1822
1823 =cut
1824
1825 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1826
1827 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1828
1829 Sets an action in a given namespace.
1830
1831 =cut
1832
1833 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1834
1835 =head2 $c->setup_actions($component)
1836
1837 Sets up actions for a component.
1838
1839 =cut
1840
1841 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1842
1843 =head2 $c->setup_components
1844
1845 Sets up components. Specify a C<setup_components> config option to pass
1846 additional options directly to L<Module::Pluggable>. To add additional
1847 search paths, specify a key named C<search_extra> as an array
1848 reference. Items in the array beginning with C<::> will have the
1849 application class name prepended to them.
1850
1851 =cut
1852
1853 sub setup_components {
1854     my $class = shift;
1855
1856     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1857     my $config  = $class->config->{ setup_components };
1858     my $extra   = delete $config->{ search_extra } || [];
1859
1860     push @paths, @$extra;
1861
1862     my $locator = Module::Pluggable::Object->new(
1863         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1864         %$config
1865     );
1866
1867     my @comps = sort { length $a <=> length $b } $locator->plugins;
1868     my %comps = map { $_ => 1 } @comps;
1869
1870     for my $component ( @comps ) {
1871
1872         # We pass ignore_loaded here so that overlay files for (e.g.)
1873         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
1874         # we know M::P::O found a file on disk so this is safe
1875
1876         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1877
1878         my $module  = $class->setup_component( $component );
1879         my %modules = (
1880             $component => $module,
1881             map {
1882                 $_ => $class->setup_component( $_ )
1883             } grep {
1884               not exists $comps{$_}
1885             } Devel::InnerPackage::list_packages( $component )
1886         );
1887
1888         for my $key ( keys %modules ) {
1889             $class->components->{ $key } = $modules{ $key };
1890         }
1891     }
1892 }
1893
1894 =head2 $c->setup_component
1895
1896 =cut
1897
1898 sub setup_component {
1899     my( $class, $component ) = @_;
1900
1901     unless ( $component->can( 'COMPONENT' ) ) {
1902         return $component;
1903     }
1904
1905     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1906     my $config = $class->config->{ $suffix } || {};
1907
1908     my $instance = eval { $component->COMPONENT( $class, $config ); };
1909
1910     if ( my $error = $@ ) {
1911         chomp $error;
1912         Catalyst::Exception->throw(
1913             message => qq/Couldn't instantiate component "$component", "$error"/
1914         );
1915     }
1916
1917     Catalyst::Exception->throw(
1918         message =>
1919         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1920     ) unless eval { $instance->can( 'can' ) };
1921
1922     return $instance;
1923 }
1924
1925 =head2 $c->setup_dispatcher
1926
1927 Sets up dispatcher.
1928
1929 =cut
1930
1931 sub setup_dispatcher {
1932     my ( $class, $dispatcher ) = @_;
1933
1934     if ($dispatcher) {
1935         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1936     }
1937
1938     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
1939         $dispatcher = 'Catalyst::Dispatcher::' . $env;
1940     }
1941
1942     unless ($dispatcher) {
1943         $dispatcher = $class->dispatcher_class;
1944     }
1945
1946     unless (Class::Inspector->loaded($dispatcher)) {
1947         require Class::Inspector->filename($dispatcher);
1948     }
1949
1950     # dispatcher instance
1951     $class->dispatcher( $dispatcher->new );
1952 }
1953
1954 =head2 $c->setup_engine
1955
1956 Sets up engine.
1957
1958 =cut
1959
1960 sub setup_engine {
1961     my ( $class, $engine ) = @_;
1962
1963     if ($engine) {
1964         $engine = 'Catalyst::Engine::' . $engine;
1965     }
1966
1967     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
1968         $engine = 'Catalyst::Engine::' . $env;
1969     }
1970
1971     if ( $ENV{MOD_PERL} ) {
1972
1973         # create the apache method
1974         {
1975             no strict 'refs';
1976             *{"$class\::apache"} = sub { shift->engine->apache };
1977         }
1978
1979         my ( $software, $version ) =
1980           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1981
1982         $version =~ s/_//g;
1983         $version =~ s/(\.[^.]+)\./$1/g;
1984
1985         if ( $software eq 'mod_perl' ) {
1986
1987             if ( !$engine ) {
1988
1989                 if ( $version >= 1.99922 ) {
1990                     $engine = 'Catalyst::Engine::Apache2::MP20';
1991                 }
1992
1993                 elsif ( $version >= 1.9901 ) {
1994                     $engine = 'Catalyst::Engine::Apache2::MP19';
1995                 }
1996
1997                 elsif ( $version >= 1.24 ) {
1998                     $engine = 'Catalyst::Engine::Apache::MP13';
1999                 }
2000
2001                 else {
2002                     Catalyst::Exception->throw( message =>
2003                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2004                 }
2005
2006             }
2007
2008             # install the correct mod_perl handler
2009             if ( $version >= 1.9901 ) {
2010                 *handler = sub  : method {
2011                     shift->handle_request(@_);
2012                 };
2013             }
2014             else {
2015                 *handler = sub ($$) { shift->handle_request(@_) };
2016             }
2017
2018         }
2019
2020         elsif ( $software eq 'Zeus-Perl' ) {
2021             $engine = 'Catalyst::Engine::Zeus';
2022         }
2023
2024         else {
2025             Catalyst::Exception->throw(
2026                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2027         }
2028     }
2029
2030     unless ($engine) {
2031         $engine = $class->engine_class;
2032     }
2033
2034     unless (Class::Inspector->loaded($engine)) {
2035         require Class::Inspector->filename($engine);
2036     }
2037
2038     # check for old engines that are no longer compatible
2039     my $old_engine;
2040     if ( $engine->isa('Catalyst::Engine::Apache')
2041         && !Catalyst::Engine::Apache->VERSION )
2042     {
2043         $old_engine = 1;
2044     }
2045
2046     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2047         && Catalyst::Engine::Server->VERSION le '0.02' )
2048     {
2049         $old_engine = 1;
2050     }
2051
2052     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2053         && $engine->VERSION eq '0.01' )
2054     {
2055         $old_engine = 1;
2056     }
2057
2058     elsif ($engine->isa('Catalyst::Engine::Zeus')
2059         && $engine->VERSION eq '0.01' )
2060     {
2061         $old_engine = 1;
2062     }
2063
2064     if ($old_engine) {
2065         Catalyst::Exception->throw( message =>
2066               qq/Engine "$engine" is not supported by this version of Catalyst/
2067         );
2068     }
2069
2070     # engine instance
2071     $class->engine( $engine->new );
2072 }
2073
2074 =head2 $c->setup_home
2075
2076 Sets up the home directory.
2077
2078 =cut
2079
2080 sub setup_home {
2081     my ( $class, $home ) = @_;
2082
2083     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2084         $home = $env;
2085     }
2086
2087     unless ($home) {
2088         $home = Catalyst::Utils::home($class);
2089     }
2090
2091     if ($home) {
2092         $class->config->{home} ||= $home;
2093         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2094     }
2095 }
2096
2097 =head2 $c->setup_log
2098
2099 Sets up log.
2100
2101 =cut
2102
2103 sub setup_log {
2104     my ( $class, $debug ) = @_;
2105
2106     unless ( $class->log ) {
2107         $class->log( Catalyst::Log->new );
2108     }
2109
2110     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2111     if ( defined($env_debug) ? $env_debug : $debug ) {
2112         no strict 'refs';
2113         *{"$class\::debug"} = sub { 1 };
2114         $class->log->debug('Debug messages enabled');
2115     }
2116 }
2117
2118 =head2 $c->setup_plugins
2119
2120 Sets up plugins.
2121
2122 =cut
2123
2124 =head2 $c->setup_stats
2125
2126 Sets up timing statistics class.
2127
2128 =cut
2129
2130 sub setup_stats {
2131     my ( $class, $stats ) = @_;
2132
2133     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2134
2135     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2136     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2137         no strict 'refs';
2138         *{"$class\::use_stats"} = sub { 1 };
2139         $class->log->debug('Statistics enabled');
2140     }
2141 }
2142
2143
2144 =head2 $c->registered_plugins
2145
2146 Returns a sorted list of the plugins which have either been stated in the
2147 import list or which have been added via C<< MyApp->plugin(@args); >>.
2148
2149 If passed a given plugin name, it will report a boolean value indicating
2150 whether or not that plugin is loaded.  A fully qualified name is required if
2151 the plugin name does not begin with C<Catalyst::Plugin::>.
2152
2153  if ($c->registered_plugins('Some::Plugin')) {
2154      ...
2155  }
2156
2157 =cut
2158
2159 {
2160
2161     sub registered_plugins {
2162         my $proto = shift;
2163         return sort keys %{ $proto->_plugins } unless @_;
2164         my $plugin = shift;
2165         return 1 if exists $proto->_plugins->{$plugin};
2166         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2167     }
2168
2169     sub _register_plugin {
2170         my ( $proto, $plugin, $instant ) = @_;
2171         my $class = ref $proto || $proto;
2172
2173         # no ignore_loaded here, the plugin may already have been
2174         # defined in memory and we don't want to error on "no file" if so
2175
2176         Catalyst::Utils::ensure_class_loaded( $plugin );
2177
2178         $proto->_plugins->{$plugin} = 1;
2179         unless ($instant) {
2180             no strict 'refs';
2181             unshift @{"$class\::ISA"}, $plugin;
2182         }
2183         return $class;
2184     }
2185
2186     sub setup_plugins {
2187         my ( $class, $plugins ) = @_;
2188
2189         $class->_plugins( {} ) unless $class->_plugins;
2190         $plugins ||= [];
2191         for my $plugin ( reverse @$plugins ) {
2192
2193             unless ( $plugin =~ s/\A\+// ) {
2194                 $plugin = "Catalyst::Plugin::$plugin";
2195             }
2196
2197             $class->_register_plugin($plugin);
2198         }
2199     }
2200 }
2201
2202 =head2 $c->stack
2203
2204 Returns an arrayref of the internal execution stack (actions that are
2205 currently executing).
2206
2207 =head2 $c->stats_class
2208
2209 Returns or sets the stats (timing statistics) class.
2210
2211 =head2 $c->use_stats
2212
2213 Returns 1 when stats collection is enabled.  Stats collection is enabled
2214 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2215 environment variable is set.
2216
2217 Note that this is a static method, not an accessor and should be overloaded
2218 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2219
2220 =cut
2221
2222 sub use_stats { 0 }
2223
2224
2225 =head2 $c->write( $data )
2226
2227 Writes $data to the output stream. When using this method directly, you
2228 will need to manually set the C<Content-Length> header to the length of
2229 your output data, if known.
2230
2231 =cut
2232
2233 sub write {
2234     my $c = shift;
2235
2236     # Finalize headers if someone manually writes output
2237     $c->finalize_headers;
2238
2239     return $c->engine->write( $c, @_ );
2240 }
2241
2242 =head2 version
2243
2244 Returns the Catalyst version number. Mostly useful for "powered by"
2245 messages in template systems.
2246
2247 =cut
2248
2249 sub version { return $Catalyst::VERSION }
2250
2251 =head1 INTERNAL ACTIONS
2252
2253 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2254 C<_ACTION>, and C<_END>. These are by default not shown in the private
2255 action table, but you can make them visible with a config parameter.
2256
2257     MyApp->config->{show_internal_actions} = 1;
2258
2259 =head1 CASE SENSITIVITY
2260
2261 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2262 mapped to C</foo/bar>. You can activate case sensitivity with a config
2263 parameter.
2264
2265     MyApp->config->{case_sensitive} = 1;
2266
2267 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2268
2269 =head1 ON-DEMAND PARSER
2270
2271 The request body is usually parsed at the beginning of a request,
2272 but if you want to handle input yourself, you can enable on-demand
2273 parsing with a config parameter.
2274
2275     MyApp->config->{parse_on_demand} = 1;
2276
2277 =head1 PROXY SUPPORT
2278
2279 Many production servers operate using the common double-server approach,
2280 with a lightweight frontend web server passing requests to a larger
2281 backend server. An application running on the backend server must deal
2282 with two problems: the remote user always appears to be C<127.0.0.1> and
2283 the server's hostname will appear to be C<localhost> regardless of the
2284 virtual host that the user connected through.
2285
2286 Catalyst will automatically detect this situation when you are running
2287 the frontend and backend servers on the same machine. The following
2288 changes are made to the request.
2289
2290     $c->req->address is set to the user's real IP address, as read from
2291     the HTTP X-Forwarded-For header.
2292
2293     The host value for $c->req->base and $c->req->uri is set to the real
2294     host, as read from the HTTP X-Forwarded-Host header.
2295
2296 Obviously, your web server must support these headers for this to work.
2297
2298 In a more complex server farm environment where you may have your
2299 frontend proxy server(s) on different machines, you will need to set a
2300 configuration option to tell Catalyst to read the proxied data from the
2301 headers.
2302
2303     MyApp->config->{using_frontend_proxy} = 1;
2304
2305 If you do not wish to use the proxy support at all, you may set:
2306
2307     MyApp->config->{ignore_frontend_proxy} = 1;
2308
2309 =head1 THREAD SAFETY
2310
2311 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2312 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2313 believe the Catalyst core to be thread-safe.
2314
2315 If you plan to operate in a threaded environment, remember that all other
2316 modules you are using must also be thread-safe. Some modules, most notably
2317 L<DBD::SQLite>, are not thread-safe.
2318
2319 =head1 SUPPORT
2320
2321 IRC:
2322
2323     Join #catalyst on irc.perl.org.
2324
2325 Mailing Lists:
2326
2327     http://lists.rawmode.org/mailman/listinfo/catalyst
2328     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2329
2330 Web:
2331
2332     http://catalyst.perl.org
2333
2334 Wiki:
2335
2336     http://dev.catalyst.perl.org
2337
2338 =head1 SEE ALSO
2339
2340 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2341
2342 =head2 L<Catalyst::Manual> - The Catalyst Manual
2343
2344 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2345
2346 =head2 L<Catalyst::Engine> - Core engine
2347
2348 =head2 L<Catalyst::Log> - Log class.
2349
2350 =head2 L<Catalyst::Request> - Request object
2351
2352 =head2 L<Catalyst::Response> - Response object
2353
2354 =head2 L<Catalyst::Test> - The test suite.
2355
2356 =head1 CREDITS
2357
2358 Andy Grundman
2359
2360 Andy Wardley
2361
2362 Andreas Marienborg
2363
2364 Andrew Bramble
2365
2366 Andrew Ford
2367
2368 Andrew Ruthven
2369
2370 Arthur Bergman
2371
2372 Autrijus Tang
2373
2374 Brian Cassidy
2375
2376 Carl Franks
2377
2378 Christian Hansen
2379
2380 Christopher Hicks
2381
2382 Dan Sully
2383
2384 Danijel Milicevic
2385
2386 David Kamholz
2387
2388 David Naughton
2389
2390 Drew Taylor
2391
2392 Gary Ashton Jones
2393
2394 Geoff Richards
2395
2396 Jesse Sheidlower
2397
2398 Jesse Vincent
2399
2400 Jody Belka
2401
2402 Johan Lindstrom
2403
2404 Juan Camacho
2405
2406 Leon Brocard
2407
2408 Marcus Ramberg
2409
2410 Matt S Trout
2411
2412 Robert Sedlacek
2413
2414 Sam Vilain
2415
2416 Sascha Kiefer
2417
2418 Sebastian Willert
2419
2420 Tatsuhiko Miyagawa
2421
2422 Ulf Edvinsson
2423
2424 Yuval Kogman
2425
2426 =head1 AUTHOR
2427
2428 Sebastian Riedel, C<sri@oook.de>
2429
2430 =head1 LICENSE
2431
2432 This library is free software, you can redistribute it and/or modify it under
2433 the same terms as Perl itself.
2434
2435 =cut
2436
2437 1;