lib/Catalyst.pm

   1 package Catalyst;
   2
   3 # we don't need really need this, but if we load it before MRO::Compat gets
   4 # loaded (via Moose and Class::MOP), we can avoid some nasty warnings
   5 use Class::C3;
   6
   7 use Moose;
   8 use Class::MOP::Object ();
   9 extends 'Catalyst::Component';
  10 use bytes;
  11 use Catalyst::Exception;
  12 use Catalyst::Log;
  13 use Catalyst::Request;
  14 use Catalyst::Request::Upload;
  15 use Catalyst::Response;
  16 use Catalyst::Utils;
  17 use Catalyst::Controller;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use Time::HiRes qw/gettimeofday tv_interval/;
  25 use URI ();
  26 use URI::http;
  27 use URI::https;
  28 use Scalar::Util qw/weaken blessed/;
  29 use Tree::Simple qw/use_weak_refs/;
  30 use Tree::Simple::Visitor::FindByUID;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp/;
  34
  35 BEGIN { require 5.008001; }
  36
  37 has stack => (is => 'rw', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     # carp "the use of req() is deprecated in favour of request()";
  52     my $self = shift; return $self->request(@_);
  53 }
  54 sub res {
  55     # carp "the use of res() is deprecated in favour of response()";
  56     my $self = shift; return $self->response(@_);
  57 }
  58
  59 # For backwards compatibility
  60 sub finalize_output { shift->finalize_body(@_) };
  61
  62 # For statistics
  63 our $COUNT     = 1;
  64 our $START     = time;
  65 our $RECURSION = 1000;
  66 our $DETACH    = "catalyst_detach\n";
  67 our $GO        = "catalyst_go\n";
  68
  69 #I imagine that very few of these really need to be class variables. if any.
  70 #maybe we should just make them attributes with a default?
  71 __PACKAGE__->mk_classdata($_)
  72   for qw/components arguments dispatcher engine log dispatcher_class
  73   engine_class context_class request_class response_class stats_class
  74   setup_finished/;
  75
  76 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  77 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  78 __PACKAGE__->request_class('Catalyst::Request');
  79 __PACKAGE__->response_class('Catalyst::Response');
  80 __PACKAGE__->stats_class('Catalyst::Stats');
  81
  82 # Remember to update this in Catalyst::Runtime as well!
  83
  84 our $VERSION = '5.8000_04';
  85
  86 sub import {
  87     my ( $class, @arguments ) = @_;
  88
  89     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  90     # callers @ISA.
  91     return unless $class eq 'Catalyst';
  92
  93     my $caller = caller();
  94     return if $caller eq 'main';
  95     my $meta = Moose::Meta::Class->initialize($caller);
  96     #Moose->import({ into => $caller }); #do we want to do this?
  97
  98     unless ( $caller->isa('Catalyst') ) {
  99         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 100         $meta->superclasses(@superclasses);
 101     }
 102     unless( $meta->has_method('meta') ){
 103         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 104     }
 105
 106     $caller->arguments( [@arguments] );
 107     $caller->setup_home;
 108 }
 109
 110 =head1 NAME
 111
 112 Catalyst - The Elegant MVC Web Application Framework
 113
 114 =head1 SYNOPSIS
 115
 116 See the L<Catalyst::Manual> distribution for comprehensive
 117 documentation and tutorials.
 118
 119     # Install Catalyst::Devel for helpers and other development tools
 120     # use the helper to create a new application
 121     catalyst.pl MyApp
 122
 123     # add models, views, controllers
 124     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 125     script/myapp_create.pl view MyTemplate TT
 126     script/myapp_create.pl controller Search
 127
 128     # built in testserver -- use -r to restart automatically on changes
 129     # --help to see all available options
 130     script/myapp_server.pl
 131
 132     # command line testing interface
 133     script/myapp_test.pl /yada
 134
 135     ### in lib/MyApp.pm
 136     use Catalyst qw/-Debug/; # include plugins here as well
 137
 138     ### In lib/MyApp/Controller/Root.pm (autocreated)
 139     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 140         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 141         $c->stash->{template} = 'foo.tt'; # set the template
 142         # lookup something from db -- stash vars are passed to TT
 143         $c->stash->{data} =
 144           $c->model('Database::Foo')->search( { country => $args[0] } );
 145         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 146             $c->forward( 'bar' ); # process another action
 147             # do something else after forward returns
 148         }
 149     }
 150
 151     # The foo.tt TT template can use the stash data from the database
 152     [% WHILE (item = data.next) %]
 153         [% item.foo %]
 154     [% END %]
 155
 156     # called for /bar/of/soap, /bar/of/soap/10, etc.
 157     sub bar : Path('/bar/of/soap') { ... }
 158
 159     # called for all actions, from the top-most controller downwards
 160     sub auto : Private {
 161         my ( $self, $c ) = @_;
 162         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 163             $c->res->redirect( '/login' ); # require login
 164             return 0; # abort request and go immediately to end()
 165         }
 166         return 1; # success; carry on to next action
 167     }
 168
 169     # called after all actions are finished
 170     sub end : Private {
 171         my ( $self, $c ) = @_;
 172         if ( scalar @{ $c->error } ) { ... } # handle errors
 173         return if $c->res->body; # already have a response
 174         $c->forward( 'MyApp::View::TT' ); # render template
 175     }
 176
 177     ### in MyApp/Controller/Foo.pm
 178     # called for /foo/bar
 179     sub bar : Local { ... }
 180
 181     # called for /blargle
 182     sub blargle : Global { ... }
 183
 184     # an index action matches /foo, but not /foo/1, etc.
 185     sub index : Private { ... }
 186
 187     ### in MyApp/Controller/Foo/Bar.pm
 188     # called for /foo/bar/baz
 189     sub baz : Local { ... }
 190
 191     # first Root auto is called, then Foo auto, then this
 192     sub auto : Private { ... }
 193
 194     # powerful regular expression paths are also possible
 195     sub details : Regex('^product/(\w+)/details$') {
 196         my ( $self, $c ) = @_;
 197         # extract the (\w+) from the URI
 198         my $product = $c->req->captures->[0];
 199     }
 200
 201 See L<Catalyst::Manual::Intro> for additional information.
 202
 203 =head1 DESCRIPTION
 204
 205 Catalyst is a modern framework for making web applications without the
 206 pain usually associated with this process. This document is a reference
 207 to the main Catalyst application. If you are a new user, we suggest you
 208 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 209
 210 See L<Catalyst::Manual> for more documentation.
 211
 212 Catalyst plugins can be loaded by naming them as arguments to the "use
 213 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 214 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 215 C<My::Module>.
 216
 217     use Catalyst qw/My::Module/;
 218
 219 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 220 fully qualify the name by using a unary plus:
 221
 222     use Catalyst qw/
 223         My::Module
 224         +Fully::Qualified::Plugin::Name
 225     /;
 226
 227 Special flags like C<-Debug> and C<-Engine> can also be specified as
 228 arguments when Catalyst is loaded:
 229
 230     use Catalyst qw/-Debug My::Module/;
 231
 232 The position of plugins and flags in the chain is important, because
 233 they are loaded in the order in which they appear.
 234
 235 The following flags are supported:
 236
 237 =head2 -Debug
 238
 239 Enables debug output. You can also force this setting from the system
 240 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 241 settings override the application, with <MYAPP>_DEBUG having the highest
 242 priority.
 243
 244 =head2 -Engine
 245
 246 Forces Catalyst to use a specific engine. Omit the
 247 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 248
 249     use Catalyst qw/-Engine=CGI/;
 250
 251 =head2 -Home
 252
 253 Forces Catalyst to use a specific home directory, e.g.:
 254
 255     use Catalyst qw[-Home=/usr/mst];
 256
 257 This can also be done in the shell environment by setting either the
 258 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 259 is replaced with the uppercased name of your application, any "::" in
 260 the name will be replaced with underscores, e.g. MyApp::Web should use
 261 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 262
 263 =head2 -Log
 264
 265 Specifies log level.
 266
 267 =head2 -Stats
 268
 269 Enables statistics collection and reporting. You can also force this setting
 270 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 271 environment settings override the application, with <MYAPP>_STATS having the
 272 highest priority.
 273
 274 e.g.
 275
 276    use Catalyst qw/-Stats=1/
 277
 278 =head1 METHODS
 279
 280 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 281
 282 =head2 $c->action
 283
 284 Returns a L<Catalyst::Action> object for the current action, which
 285 stringifies to the action name. See L<Catalyst::Action>.
 286
 287 =head2 $c->namespace
 288
 289 Returns the namespace of the current action, i.e., the URI prefix
 290 corresponding to the controller of the current action. For example:
 291
 292     # in Controller::Foo::Bar
 293     $c->namespace; # returns 'foo/bar';
 294
 295 =head2 $c->request
 296
 297 =head2 $c->req
 298
 299 Returns the current L<Catalyst::Request> object, giving access to
 300 information about the current client request (including parameters,
 301 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 302
 303 =head2 REQUEST FLOW HANDLING
 304
 305 =head2 $c->forward( $action [, \@arguments ] )
 306
 307 =head2 $c->forward( $class, $method, [, \@arguments ] )
 308
 309 Forwards processing to another action, by its private name. If you give a
 310 class name but no method, C<process()> is called. You may also optionally
 311 pass arguments in an arrayref. The action will receive the arguments in
 312 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 313 C<< $c->req->args >> will be restored to the previous values.
 314
 315 Any data C<return>ed from the action forwarded to, will be returned by the
 316 call to forward.
 317
 318     my $foodata = $c->forward('/foo');
 319     $c->forward('index');
 320     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 321     $c->forward('MyApp::View::TT');
 322
 323 Note that forward implies an C<<eval { }>> around the call (actually
 324 C<execute> does), thus de-fatalizing all 'dies' within the called
 325 action. If you want C<die> to propagate you need to do something like:
 326
 327     $c->forward('foo');
 328     die $c->error if $c->error;
 329
 330 Or make sure to always return true values from your actions and write
 331 your code like this:
 332
 333     $c->forward('foo') || return;
 334
 335 =cut
 336
 337 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 338
 339 =head2 $c->detach( $action [, \@arguments ] )
 340
 341 =head2 $c->detach( $class, $method, [, \@arguments ] )
 342
 343 =head2 $c->detach()
 344
 345 The same as C<forward>, but doesn't return to the previous action when
 346 processing is finished.
 347
 348 When called with no arguments it escapes the processing chain entirely.
 349
 350 =cut
 351
 352 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 353
 354 =head2 $c->visit( $action [, \@arguments ] )
 355
 356 =head2 $c->visit( $class, $method, [, \@arguments ] )
 357
 358 Almost the same as C<forward>, but does a full dispatch, instead of just
 359 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 360 C<auto> and the method you go to are called, just like a new request.
 361
 362 C<$c-E<gt>stash> is kept unchanged.
 363
 364 In effect, C<visit> allows you to "wrap" another action, just as it
 365 would have been called by dispatching from a URL, while the analogous
 366 C<go> allows you to transfer control to another action as if it had
 367 been reached directly from a URL.
 368
 369 =cut
 370
 371 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 372
 373 =head2 $c->go( $action [, \@arguments ] )
 374
 375 =head2 $c->go( $class, $method, [, \@arguments ] )
 376
 377 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 378 instead of just calling the new C<$action> /
 379 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 380 method you visit are called, just like a new request.
 381
 382 C<$c-E<gt>stash> is kept unchanged.
 383
 384 =cut
 385
 386 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 387
 388 =head2 $c->response
 389
 390 =head2 $c->res
 391
 392 Returns the current L<Catalyst::Response> object, see there for details.
 393
 394 =head2 $c->stash
 395
 396 Returns a hashref to the stash, which may be used to store data and pass
 397 it between components during a request. You can also set hash keys by
 398 passing arguments. The stash is automatically sent to the view. The
 399 stash is cleared at the end of a request; it cannot be used for
 400 persistent storage (for this you must use a session; see
 401 L<Catalyst::Plugin::Session> for a complete system integrated with
 402 Catalyst).
 403
 404     $c->stash->{foo} = $bar;
 405     $c->stash( { moose => 'majestic', qux => 0 } );
 406     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 407
 408     # stash is automatically passed to the view for use in a template
 409     $c->forward( 'MyApp::View::TT' );
 410
 411 =cut
 412
 413 around stash => sub {
 414     my $orig = shift;
 415     my $c = shift;
 416     my $stash = $orig->($c);
 417     if (@_) {
 418         my $new_stash = @_ > 1 ? {@_} : $_[0];
 419         croak('stash takes a hash or hashref') unless ref $new_stash;
 420         foreach my $key ( keys %$new_stash ) {
 421           $stash->{$key} = $new_stash->{$key};
 422         }
 423     }
 424
 425     return $stash;
 426 };
 427
 428
 429 =head2 $c->error
 430
 431 =head2 $c->error($error, ...)
 432
 433 =head2 $c->error($arrayref)
 434
 435 Returns an arrayref containing error messages.  If Catalyst encounters an
 436 error while processing a request, it stores the error in $c->error.  This
 437 method should only be used to store fatal error messages.
 438
 439     my @error = @{ $c->error };
 440
 441 Add a new error.
 442
 443     $c->error('Something bad happened');
 444
 445 =cut
 446
 447 sub error {
 448     my $c = shift;
 449     if ( $_[0] ) {
 450         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 451         croak @$error unless ref $c;
 452         push @{ $c->{error} }, @$error;
 453     }
 454     elsif ( defined $_[0] ) { $c->{error} = undef }
 455     return $c->{error} || [];
 456 }
 457
 458
 459 =head2 $c->state
 460
 461 Contains the return value of the last executed action.
 462
 463 =head2 $c->clear_errors
 464
 465 Clear errors.  You probably don't want to clear the errors unless you are
 466 implementing a custom error screen.
 467
 468 This is equivalent to running
 469
 470     $c->error(0);
 471
 472 =cut
 473
 474 sub clear_errors {
 475     my $c = shift;
 476     $c->error(0);
 477 }
 478
 479 # search components given a name and some prefixes
 480 sub _comp_search_prefixes {
 481     my ( $c, $name, @prefixes ) = @_;
 482     my $appclass = ref $c || $c;
 483     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 484
 485     # map the original component name to the sub part that we will search against
 486     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 487         grep { /$filter/ } keys %{ $c->components };
 488
 489     # undef for a name will return all
 490     return keys %eligible if !defined $name;
 491
 492     my $query  = ref $name ? $name : qr/^$name$/i;
 493     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 494
 495     return map { $c->components->{ $_ } } @result if @result;
 496
 497     # if we were given a regexp to search against, we're done.
 498     return if ref $name;
 499
 500     # regexp fallback
 501     $query  = qr/$name/i;
 502     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 503
 504     # no results? try against full names
 505     if( !@result ) {
 506         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 507     }
 508
 509     # don't warn if we didn't find any results, it just might not exist
 510     if( @result ) {
 511         $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 512         $c->log->warn( 'Relying on the regexp fallback behavior for component resolution is unreliable and unsafe.' );
 513         $c->log->warn( 'If you really want to search, pass in a regexp as the argument.' );
 514     }
 515
 516     return @result;
 517 }
 518
 519 # Find possible names for a prefix
 520 sub _comp_names {
 521     my ( $c, @prefixes ) = @_;
 522     my $appclass = ref $c || $c;
 523
 524     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 525
 526     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 527     return @names;
 528 }
 529
 530 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 531 sub _filter_component {
 532     my ( $c, $comp, @args ) = @_;
 533
 534     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 535         return $comp->ACCEPT_CONTEXT( $c, @args );
 536     }
 537
 538     return $comp;
 539 }
 540
 541 =head2 COMPONENT ACCESSORS
 542
 543 =head2 $c->controller($name)
 544
 545 Gets a L<Catalyst::Controller> instance by name.
 546
 547     $c->controller('Foo')->do_stuff;
 548
 549 If the name is omitted, will return the controller for the dispatched
 550 action.
 551
 552 If you want to search for controllers, pass in a regexp as the argument.
 553
 554     # find all controllers that start with Foo
 555     my @foo_controllers = $c->controller(qr{^Foo});
 556
 557
 558 =cut
 559
 560 sub controller {
 561     my ( $c, $name, @args ) = @_;
 562
 563     if( $name ) {
 564         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 565         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 566         return $c->_filter_component( $result[ 0 ], @args );
 567     }
 568
 569     return $c->component( $c->action->class );
 570 }
 571
 572 =head2 $c->model($name)
 573
 574 Gets a L<Catalyst::Model> instance by name.
 575
 576     $c->model('Foo')->do_stuff;
 577
 578 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 579
 580 If the name is omitted, it will look for
 581  - a model object in $c->stash->{current_model_instance}, then
 582  - a model name in $c->stash->{current_model}, then
 583  - a config setting 'default_model', or
 584  - check if there is only one model, and return it if that's the case.
 585
 586 If you want to search for models, pass in a regexp as the argument.
 587
 588     # find all models that start with Foo
 589     my @foo_models = $c->model(qr{^Foo});
 590
 591 =cut
 592
 593 sub model {
 594     my ( $c, $name, @args ) = @_;
 595
 596     if( $name ) {
 597         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 598         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 599         return $c->_filter_component( $result[ 0 ], @args );
 600     }
 601
 602     if (ref $c) {
 603         return $c->stash->{current_model_instance}
 604           if $c->stash->{current_model_instance};
 605         return $c->model( $c->stash->{current_model} )
 606           if $c->stash->{current_model};
 607     }
 608     return $c->model( $c->config->{default_model} )
 609       if $c->config->{default_model};
 610
 611     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 612
 613     if( $rest ) {
 614         $c->log->warn( 'Calling $c->model() will return a random model unless you specify one of:' );
 615         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 616         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 617         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 618         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 619     }
 620
 621     return $c->_filter_component( $comp );
 622 }
 623
 624
 625 =head2 $c->view($name)
 626
 627 Gets a L<Catalyst::View> instance by name.
 628
 629     $c->view('Foo')->do_stuff;
 630
 631 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 632
 633 If the name is omitted, it will look for
 634  - a view object in $c->stash->{current_view_instance}, then
 635  - a view name in $c->stash->{current_view}, then
 636  - a config setting 'default_view', or
 637  - check if there is only one view, and return it if that's the case.
 638
 639 If you want to search for views, pass in a regexp as the argument.
 640
 641     # find all views that start with Foo
 642     my @foo_views = $c->view(qr{^Foo});
 643
 644 =cut
 645
 646 sub view {
 647     my ( $c, $name, @args ) = @_;
 648
 649     if( $name ) {
 650         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 651         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 652         return $c->_filter_component( $result[ 0 ], @args );
 653     }
 654
 655     if (ref $c) {
 656         return $c->stash->{current_view_instance}
 657           if $c->stash->{current_view_instance};
 658         return $c->view( $c->stash->{current_view} )
 659           if $c->stash->{current_view};
 660     }
 661     return $c->view( $c->config->{default_view} )
 662       if $c->config->{default_view};
 663
 664     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 665
 666     if( $rest ) {
 667         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 668         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 669         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 670         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 671         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 672     }
 673
 674     return $c->_filter_component( $comp );
 675 }
 676
 677 =head2 $c->controllers
 678
 679 Returns the available names which can be passed to $c->controller
 680
 681 =cut
 682
 683 sub controllers {
 684     my ( $c ) = @_;
 685     return $c->_comp_names(qw/Controller C/);
 686 }
 687
 688 =head2 $c->models
 689
 690 Returns the available names which can be passed to $c->model
 691
 692 =cut
 693
 694 sub models {
 695     my ( $c ) = @_;
 696     return $c->_comp_names(qw/Model M/);
 697 }
 698
 699
 700 =head2 $c->views
 701
 702 Returns the available names which can be passed to $c->view
 703
 704 =cut
 705
 706 sub views {
 707     my ( $c ) = @_;
 708     return $c->_comp_names(qw/View V/);
 709 }
 710
 711 =head2 $c->comp($name)
 712
 713 =head2 $c->component($name)
 714
 715 Gets a component object by name. This method is not recommended,
 716 unless you want to get a specific component by full
 717 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 718 should be used instead.
 719
 720 If C<$name> is a regexp, a list of components matched against the full
 721 component name will be returned.
 722
 723 =cut
 724
 725 sub component {
 726     my ( $c, $name, @args ) = @_;
 727
 728     if( $name ) {
 729         my $comps = $c->components;
 730
 731         if( !ref $name ) {
 732             # is it the exact name?
 733             return $c->_filter_component( $comps->{ $name }, @args )
 734                        if exists $comps->{ $name };
 735
 736             # perhaps we just omitted "MyApp"?
 737             my $composed = ( ref $c || $c ) . "::${name}";
 738             return $c->_filter_component( $comps->{ $composed }, @args )
 739                        if exists $comps->{ $composed };
 740
 741             # search all of the models, views and controllers
 742             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 743             return $c->_filter_component( $comp, @args ) if $comp;
 744         }
 745
 746         # This is here so $c->comp( '::M::' ) works
 747         my $query = ref $name ? $name : qr{$name}i;
 748
 749         my @result = grep { m{$query} } keys %{ $c->components };
 750         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 751
 752         if( $result[ 0 ] ) {
 753             $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 754             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 755             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 756             return $c->_filter_component( $result[ 0 ], @args );
 757         }
 758
 759         # I would expect to return an empty list here, but that breaks back-compat
 760     }
 761
 762     # fallback
 763     return sort keys %{ $c->components };
 764 }
 765
 766 =head2 CLASS DATA AND HELPER CLASSES
 767
 768 =head2 $c->config
 769
 770 Returns or takes a hashref containing the application's configuration.
 771
 772     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 773
 774 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 775 like myapp.yml in your applications home directory. See
 776 L<Catalyst::Plugin::ConfigLoader>.
 777
 778     ---
 779     db: dsn:SQLite:foo.db
 780
 781
 782 =cut
 783
 784 around config => sub {
 785     my $orig = shift;
 786     my $c = shift;
 787
 788     $c->log->warn("Setting config after setup has been run is not a good idea.")
 789       if ( @_ and $c->setup_finished );
 790
 791     $c->$orig(@_);
 792 };
 793
 794 =head2 $c->log
 795
 796 Returns the logging object instance. Unless it is already set, Catalyst
 797 sets this up with a L<Catalyst::Log> object. To use your own log class,
 798 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 799 C<< __PACKAGE__->setup >>.
 800
 801  __PACKAGE__->log( MyLogger->new );
 802  __PACKAGE__->setup;
 803
 804 And later:
 805
 806     $c->log->info( 'Now logging with my own logger!' );
 807
 808 Your log class should implement the methods described in
 809 L<Catalyst::Log>.
 810
 811
 812 =head2 $c->debug
 813
 814 Overload to enable debug messages (same as -Debug option).
 815
 816 Note that this is a static method, not an accessor and should be overloaded
 817 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 818
 819 =cut
 820
 821 sub debug { 0 }
 822
 823 =head2 $c->dispatcher
 824
 825 Returns the dispatcher instance. Stringifies to class name. See
 826 L<Catalyst::Dispatcher>.
 827
 828 =head2 $c->engine
 829
 830 Returns the engine instance. Stringifies to the class name. See
 831 L<Catalyst::Engine>.
 832
 833
 834 =head2 UTILITY METHODS
 835
 836 =head2 $c->path_to(@path)
 837
 838 Merges C<@path> with C<< $c->config->{home} >> and returns a
 839 L<Path::Class::Dir> object.
 840
 841 For example:
 842
 843     $c->path_to( 'db', 'sqlite.db' );
 844
 845 =cut
 846
 847 sub path_to {
 848     my ( $c, @path ) = @_;
 849     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 850     if ( -d $path ) { return $path }
 851     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 852 }
 853
 854 =head2 $c->plugin( $name, $class, @args )
 855
 856 Helper method for plugins. It creates a classdata accessor/mutator and
 857 loads and instantiates the given class.
 858
 859     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 860
 861     $c->prototype->define_javascript_functions;
 862
 863 =cut
 864
 865 sub plugin {
 866     my ( $class, $name, $plugin, @args ) = @_;
 867     $class->_register_plugin( $plugin, 1 );
 868
 869     eval { $plugin->import };
 870     $class->mk_classdata($name);
 871     my $obj;
 872     eval { $obj = $plugin->new(@args) };
 873
 874     if ($@) {
 875         Catalyst::Exception->throw( message =>
 876               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 877     }
 878
 879     $class->$name($obj);
 880     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 881       if $class->debug;
 882 }
 883
 884 =head2 MyApp->setup
 885
 886 Initializes the dispatcher and engine, loads any plugins, and loads the
 887 model, view, and controller components. You may also specify an array
 888 of plugins to load here, if you choose to not load them in the C<use
 889 Catalyst> line.
 890
 891     MyApp->setup;
 892     MyApp->setup( qw/-Debug/ );
 893
 894 =cut
 895
 896 sub setup {
 897     my ( $class, @arguments ) = @_;
 898     $class->log->warn("Running setup twice is not a good idea.")
 899       if ( $class->setup_finished );
 900
 901     unless ( $class->isa('Catalyst') ) {
 902
 903         Catalyst::Exception->throw(
 904             message => qq/'$class' does not inherit from Catalyst/ );
 905     }
 906
 907     if ( $class->arguments ) {
 908         @arguments = ( @arguments, @{ $class->arguments } );
 909     }
 910
 911     # Process options
 912     my $flags = {};
 913
 914     foreach (@arguments) {
 915
 916         if (/^-Debug$/) {
 917             $flags->{log} =
 918               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 919         }
 920         elsif (/^-(\w+)=?(.*)$/) {
 921             $flags->{ lc $1 } = $2;
 922         }
 923         else {
 924             push @{ $flags->{plugins} }, $_;
 925         }
 926     }
 927
 928     $class->setup_home( delete $flags->{home} );
 929
 930     $class->setup_log( delete $flags->{log} );
 931     $class->setup_plugins( delete $flags->{plugins} );
 932     $class->setup_dispatcher( delete $flags->{dispatcher} );
 933     $class->setup_engine( delete $flags->{engine} );
 934     $class->setup_stats( delete $flags->{stats} );
 935
 936     for my $flag ( sort keys %{$flags} ) {
 937
 938         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 939             &$code( $class, delete $flags->{$flag} );
 940         }
 941         else {
 942             $class->log->warn(qq/Unknown flag "$flag"/);
 943         }
 944     }
 945
 946     eval { require Catalyst::Devel; };
 947     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 948         $class->log->warn(<<"EOF");
 949 You are running an old script!
 950
 951   Please update by running (this will overwrite existing files):
 952     catalyst.pl -force -scripts $class
 953
 954   or (this will not overwrite existing files):
 955     catalyst.pl -scripts $class
 956
 957 EOF
 958     }
 959
 960     if ( $class->debug ) {
 961         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 962
 963         if (@plugins) {
 964             my $t = Text::SimpleTable->new(74);
 965             $t->row($_) for @plugins;
 966             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 967         }
 968
 969         my $dispatcher = $class->dispatcher;
 970         my $engine     = $class->engine;
 971         my $home       = $class->config->{home};
 972
 973         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 974         $class->log->debug(qq/Loaded engine "$engine"/);
 975
 976         $home
 977           ? ( -d $home )
 978           ? $class->log->debug(qq/Found home "$home"/)
 979           : $class->log->debug(qq/Home "$home" doesn't exist/)
 980           : $class->log->debug(q/Couldn't find home/);
 981     }
 982
 983     # Call plugins setup
 984     {
 985         no warnings qw/redefine/;
 986         local *setup = sub { };
 987         $class->setup;
 988     }
 989
 990     # Initialize our data structure
 991     $class->components( {} );
 992
 993     $class->setup_components;
 994
 995     if ( $class->debug ) {
 996         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 997         for my $comp ( sort keys %{ $class->components } ) {
 998             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 999             $t->row( $comp, $type );
1000         }
1001         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1002           if ( keys %{ $class->components } );
1003     }
1004
1005     # Add our self to components, since we are also a component
1006     if( $class->isa('Catalyst::Controller') ){
1007       $class->components->{$class} = $class;
1008     }
1009
1010     $class->setup_actions;
1011
1012     if ( $class->debug ) {
1013         my $name = $class->config->{name} || 'Application';
1014         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1015     }
1016     $class->log->_flush() if $class->log->can('_flush');
1017
1018     $class->setup_finished(1);
1019 }
1020
1021 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1022
1023 =head2 $c->uri_for( $path, @args?, \%query_values? )
1024
1025 =over
1026
1027 =item $action
1028
1029 A Catalyst::Action object representing the Catalyst action you want to
1030 create a URI for. To get one for an action in the current controller,
1031 use C<< $c->action('someactionname') >>. To get one from different
1032 controller, fetch the controller using C<< $c->controller() >>, then
1033 call C<action_for> on it.
1034
1035 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1036 using C<< $c->req->captures >>.
1037
1038   # For the current action
1039   $c->uri_for($c->action, $c->req->captures);
1040
1041   # For the Foo action in the Bar controller
1042   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1043
1044 =back
1045
1046 =cut
1047
1048 sub uri_for {
1049     my ( $c, $path, @args ) = @_;
1050
1051     if ( Scalar::Util::blessed($path) ) { # action object
1052         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1053                          ? shift(@args)
1054                          : [] );
1055         $path = $c->dispatcher->uri_for_action($path, $captures);
1056         return undef unless defined($path);
1057         $path = '/' if $path eq '';
1058     }
1059
1060     undef($path) if (defined $path && $path eq '');
1061
1062     my $params =
1063       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1064
1065     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1066     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1067
1068     unshift(@args, $path);
1069
1070     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1071         my $namespace = $c->namespace;
1072         if (defined $path) { # cheesy hack to handle path '../foo'
1073            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1074         }
1075         unshift(@args, $namespace || '');
1076     }
1077
1078     # join args with '/', or a blank string
1079     my $args = join('/', grep { defined($_) } @args);
1080     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1081     $args =~ s!^/+!!;
1082     my $base = $c->req->base;
1083     my $class = ref($base);
1084     $base =~ s{(?<!/)$}{/};
1085
1086     my $query = '';
1087
1088     if (my @keys = keys %$params) {
1089       # somewhat lifted from URI::_query's query_form
1090       $query = '?'.join('&', map {
1091           my $val = $params->{$_};
1092           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1093           s/ /+/g;
1094           my $key = $_;
1095           $val = '' unless defined $val;
1096           (map {
1097               $_ = "$_";
1098               utf8::encode( $_ ) if utf8::is_utf8($_);
1099               # using the URI::Escape pattern here so utf8 chars survive
1100               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1101               s/ /+/g;
1102               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1103       } @keys);
1104     }
1105
1106     my $res = bless(\"${base}${args}${query}", $class);
1107     $res;
1108 }
1109
1110 =head2 $c->welcome_message
1111
1112 Returns the Catalyst welcome HTML page.
1113
1114 =cut
1115
1116 sub welcome_message {
1117     my $c      = shift;
1118     my $name   = $c->config->{name};
1119     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1120     my $prefix = Catalyst::Utils::appprefix( ref $c );
1121     $c->response->content_type('text/html; charset=utf-8');
1122     return <<"EOF";
1123 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1124     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1125 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1126     <head>
1127     <meta http-equiv="Content-Language" content="en" />
1128     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1129         <title>$name on Catalyst $VERSION</title>
1130         <style type="text/css">
1131             body {
1132                 color: #000;
1133                 background-color: #eee;
1134             }
1135             div#content {
1136                 width: 640px;
1137                 margin-left: auto;
1138                 margin-right: auto;
1139                 margin-top: 10px;
1140                 margin-bottom: 10px;
1141                 text-align: left;
1142                 background-color: #ccc;
1143                 border: 1px solid #aaa;
1144             }
1145             p, h1, h2 {
1146                 margin-left: 20px;
1147                 margin-right: 20px;
1148                 font-family: verdana, tahoma, sans-serif;
1149             }
1150             a {
1151                 font-family: verdana, tahoma, sans-serif;
1152             }
1153             :link, :visited {
1154                     text-decoration: none;
1155                     color: #b00;
1156                     border-bottom: 1px dotted #bbb;
1157             }
1158             :link:hover, :visited:hover {
1159                     color: #555;
1160             }
1161             div#topbar {
1162                 margin: 0px;
1163             }
1164             pre {
1165                 margin: 10px;
1166                 padding: 8px;
1167             }
1168             div#answers {
1169                 padding: 8px;
1170                 margin: 10px;
1171                 background-color: #fff;
1172                 border: 1px solid #aaa;
1173             }
1174             h1 {
1175                 font-size: 0.9em;
1176                 font-weight: normal;
1177                 text-align: center;
1178             }
1179             h2 {
1180                 font-size: 1.0em;
1181             }
1182             p {
1183                 font-size: 0.9em;
1184             }
1185             p img {
1186                 float: right;
1187                 margin-left: 10px;
1188             }
1189             span#appname {
1190                 font-weight: bold;
1191                 font-size: 1.6em;
1192             }
1193         </style>
1194     </head>
1195     <body>
1196         <div id="content">
1197             <div id="topbar">
1198                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1199                     $VERSION</h1>
1200              </div>
1201              <div id="answers">
1202                  <p>
1203                  <img src="$logo" alt="Catalyst Logo" />
1204                  </p>
1205                  <p>Welcome to the  world of Catalyst.
1206                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1207                     framework will make web development something you had
1208                     never expected it to be: Fun, rewarding, and quick.</p>
1209                  <h2>What to do now?</h2>
1210                  <p>That really depends  on what <b>you</b> want to do.
1211                     We do, however, provide you with a few starting points.</p>
1212                  <p>If you want to jump right into web development with Catalyst
1213                     you might want to start with a tutorial.</p>
1214 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1215 </pre>
1216 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1217 <pre>
1218 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1219 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1220 </code></pre>
1221                  <h2>What to do next?</h2>
1222                  <p>Next it's time to write an actual application. Use the
1223                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1224                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1225                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1226                     they can save you a lot of work.</p>
1227                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1228                     <p>Also, be sure to check out the vast and growing
1229                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1230                     you are likely to find what you need there.
1231                     </p>
1232
1233                  <h2>Need help?</h2>
1234                  <p>Catalyst has a very active community. Here are the main places to
1235                     get in touch with us.</p>
1236                  <ul>
1237                      <li>
1238                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1239                      </li>
1240                      <li>
1241                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1242                      </li>
1243                      <li>
1244                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1245                      </li>
1246                  </ul>
1247                  <h2>In conclusion</h2>
1248                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1249                     as we enjoyed making it. Please contact us if you have ideas
1250                     for improvement or other feedback.</p>
1251              </div>
1252          </div>
1253     </body>
1254 </html>
1255 EOF
1256 }
1257
1258 =head1 INTERNAL METHODS
1259
1260 These methods are not meant to be used by end users.
1261
1262 =head2 $c->components
1263
1264 Returns a hash of components.
1265
1266 =head2 $c->context_class
1267
1268 Returns or sets the context class.
1269
1270 =head2 $c->counter
1271
1272 Returns a hashref containing coderefs and execution counts (needed for
1273 deep recursion detection).
1274
1275 =head2 $c->depth
1276
1277 Returns the number of actions on the current internal execution stack.
1278
1279 =head2 $c->dispatch
1280
1281 Dispatches a request to actions.
1282
1283 =cut
1284
1285 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1286
1287 =head2 $c->dispatcher_class
1288
1289 Returns or sets the dispatcher class.
1290
1291 =head2 $c->dump_these
1292
1293 Returns a list of 2-element array references (name, structure) pairs
1294 that will be dumped on the error page in debug mode.
1295
1296 =cut
1297
1298 sub dump_these {
1299     my $c = shift;
1300     [ Request => $c->req ],
1301     [ Response => $c->res ],
1302     [ Stash => $c->stash ],
1303     [ Config => $c->config ];
1304 }
1305
1306 =head2 $c->engine_class
1307
1308 Returns or sets the engine class.
1309
1310 =head2 $c->execute( $class, $coderef )
1311
1312 Execute a coderef in given class and catch exceptions. Errors are available
1313 via $c->error.
1314
1315 =cut
1316
1317 sub execute {
1318     my ( $c, $class, $code ) = @_;
1319     $class = $c->component($class) || $class;
1320     $c->state(0);
1321
1322     if ( $c->depth >= $RECURSION ) {
1323         my $action = $code->reverse();
1324         $action = "/$action" unless $action =~ /->/;
1325         my $error = qq/Deep recursion detected calling "${action}"/;
1326         $c->log->error($error);
1327         $c->error($error);
1328         $c->state(0);
1329         return $c->state;
1330     }
1331
1332     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1333
1334     push( @{ $c->stack }, $code );
1335
1336     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1337
1338     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1339
1340     my $last = pop( @{ $c->stack } );
1341
1342     if ( my $error = $@ ) {
1343         if ( !ref($error) and $error eq $DETACH ) {
1344             die $DETACH if($c->depth > 1);
1345         }
1346         elsif ( !ref($error) and $error eq $GO ) {
1347             die $GO if($c->depth > 0);
1348         }
1349         else {
1350             unless ( ref $error ) {
1351                 no warnings 'uninitialized';
1352                 chomp $error;
1353                 my $class = $last->class;
1354                 my $name  = $last->name;
1355                 $error = qq/Caught exception in $class->$name "$error"/;
1356             }
1357             $c->error($error);
1358             $c->state(0);
1359         }
1360     }
1361     return $c->state;
1362 }
1363
1364 sub _stats_start_execute {
1365     my ( $c, $code ) = @_;
1366
1367     return if ( ( $code->name =~ /^_.*/ )
1368         && ( !$c->config->{show_internal_actions} ) );
1369
1370     my $action_name = $code->reverse();
1371     $c->counter->{$action_name}++;
1372
1373     my $action = $action_name;
1374     $action = "/$action" unless $action =~ /->/;
1375
1376     # determine if the call was the result of a forward
1377     # this is done by walking up the call stack and looking for a calling
1378     # sub of Catalyst::forward before the eval
1379     my $callsub = q{};
1380     for my $index ( 2 .. 11 ) {
1381         last
1382         if ( ( caller($index) )[0] eq 'Catalyst'
1383             && ( caller($index) )[3] eq '(eval)' );
1384
1385         if ( ( caller($index) )[3] =~ /forward$/ ) {
1386             $callsub = ( caller($index) )[3];
1387             $action  = "-> $action";
1388             last;
1389         }
1390     }
1391
1392     my $uid = $action_name . $c->counter->{$action_name};
1393
1394     # is this a root-level call or a forwarded call?
1395     if ( $callsub =~ /forward$/ ) {
1396
1397         # forward, locate the caller
1398         if ( my $parent = $c->stack->[-1] ) {
1399             $c->stats->profile(
1400                 begin  => $action,
1401                 parent => "$parent" . $c->counter->{"$parent"},
1402                 uid    => $uid,
1403             );
1404         }
1405         else {
1406
1407             # forward with no caller may come from a plugin
1408             $c->stats->profile(
1409                 begin => $action,
1410                 uid   => $uid,
1411             );
1412         }
1413     }
1414     else {
1415
1416         # root-level call
1417         $c->stats->profile(
1418             begin => $action,
1419             uid   => $uid,
1420         );
1421     }
1422     return $action;
1423
1424 }
1425
1426 sub _stats_finish_execute {
1427     my ( $c, $info ) = @_;
1428     $c->stats->profile( end => $info );
1429 }
1430
1431 =head2 $c->_localize_fields( sub { }, \%keys );
1432
1433 =cut
1434
1435 #Why does this exist? This is no longer safe and WILL NOT WORK.
1436 # it doesnt seem to be used anywhere. can we remove it?
1437 sub _localize_fields {
1438     my ( $c, $localized, $code ) = ( @_ );
1439
1440     my $request = delete $localized->{request} || {};
1441     my $response = delete $localized->{response} || {};
1442
1443     local @{ $c }{ keys %$localized } = values %$localized;
1444     local @{ $c->request }{ keys %$request } = values %$request;
1445     local @{ $c->response }{ keys %$response } = values %$response;
1446
1447     $code->();
1448 }
1449
1450 =head2 $c->finalize
1451
1452 Finalizes the request.
1453
1454 =cut
1455
1456 sub finalize {
1457     my $c = shift;
1458
1459     for my $error ( @{ $c->error } ) {
1460         $c->log->error($error);
1461     }
1462
1463     # Allow engine to handle finalize flow (for POE)
1464     my $engine = $c->engine;
1465     if ( my $code = $engine->can('finalize') ) {
1466         $engine->$code($c);
1467     }
1468     else {
1469
1470         $c->finalize_uploads;
1471
1472         # Error
1473         if ( $#{ $c->error } >= 0 ) {
1474             $c->finalize_error;
1475         }
1476
1477         $c->finalize_headers;
1478
1479         # HEAD request
1480         if ( $c->request->method eq 'HEAD' ) {
1481             $c->response->body('');
1482         }
1483
1484         $c->finalize_body;
1485     }
1486
1487     if ($c->use_stats) {
1488         my $elapsed = sprintf '%f', $c->stats->elapsed;
1489         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1490         $c->log->info(
1491             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1492     }
1493
1494     return $c->response->status;
1495 }
1496
1497 =head2 $c->finalize_body
1498
1499 Finalizes body.
1500
1501 =cut
1502
1503 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1504
1505 =head2 $c->finalize_cookies
1506
1507 Finalizes cookies.
1508
1509 =cut
1510
1511 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1512
1513 =head2 $c->finalize_error
1514
1515 Finalizes error.
1516
1517 =cut
1518
1519 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1520
1521 =head2 $c->finalize_headers
1522
1523 Finalizes headers.
1524
1525 =cut
1526
1527 sub finalize_headers {
1528     my $c = shift;
1529
1530     my $response = $c->response; #accessor calls can add up?
1531
1532     # Check if we already finalized headers
1533     return if $response->finalized_headers;
1534
1535     # Handle redirects
1536     if ( my $location = $response->redirect ) {
1537         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1538         $response->header( Location => $location );
1539
1540         if ( !$response->has_body ) {
1541             # Add a default body if none is already present
1542             $response->body(
1543                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1544             );
1545         }
1546     }
1547
1548     # Content-Length
1549     if ( $response->body && !$response->content_length ) {
1550
1551         # get the length from a filehandle
1552         if ( blessed( $response->body ) && $response->body->can('read') )
1553         {
1554             my $stat = stat $response->body;
1555             if ( $stat && $stat->size > 0 ) {
1556                 $response->content_length( $stat->size );
1557             }
1558             else {
1559                 $c->log->warn('Serving filehandle without a content-length');
1560             }
1561         }
1562         else {
1563             # everything should be bytes at this point, but just in case
1564             $response->content_length( bytes::length( $response->body ) );
1565         }
1566     }
1567
1568     # Errors
1569     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1570         $response->headers->remove_header("Content-Length");
1571         $response->body('');
1572     }
1573
1574     $c->finalize_cookies;
1575
1576     $c->engine->finalize_headers( $c, @_ );
1577
1578     # Done
1579     $response->finalized_headers(1);
1580 }
1581
1582 =head2 $c->finalize_output
1583
1584 An alias for finalize_body.
1585
1586 =head2 $c->finalize_read
1587
1588 Finalizes the input after reading is complete.
1589
1590 =cut
1591
1592 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1593
1594 =head2 $c->finalize_uploads
1595
1596 Finalizes uploads. Cleans up any temporary files.
1597
1598 =cut
1599
1600 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1601
1602 =head2 $c->get_action( $action, $namespace )
1603
1604 Gets an action in a given namespace.
1605
1606 =cut
1607
1608 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1609
1610 =head2 $c->get_actions( $action, $namespace )
1611
1612 Gets all actions of a given name in a namespace and all parent
1613 namespaces.
1614
1615 =cut
1616
1617 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1618
1619 =head2 $c->handle_request( $class, @arguments )
1620
1621 Called to handle each HTTP request.
1622
1623 =cut
1624
1625 sub handle_request {
1626     my ( $class, @arguments ) = @_;
1627
1628     # Always expect worst case!
1629     my $status = -1;
1630     eval {
1631         if ($class->debug) {
1632             my $secs = time - $START || 1;
1633             my $av = sprintf '%.3f', $COUNT / $secs;
1634             my $time = localtime time;
1635             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1636         }
1637
1638         my $c = $class->prepare(@arguments);
1639         $c->dispatch;
1640         $status = $c->finalize;
1641     };
1642
1643     if ( my $error = $@ ) {
1644         chomp $error;
1645         $class->log->error(qq/Caught exception in engine "$error"/);
1646     }
1647
1648     $COUNT++;
1649
1650     if(my $coderef = $class->log->can('_flush')){
1651         $class->log->$coderef();
1652     }
1653     return $status;
1654 }
1655
1656 =head2 $c->prepare( @arguments )
1657
1658 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1659 etc.).
1660
1661 =cut
1662
1663 sub prepare {
1664     my ( $class, @arguments ) = @_;
1665
1666     # XXX
1667     # After the app/ctxt split, this should become an attribute based on something passed
1668     # into the application.
1669     $class->context_class( ref $class || $class ) unless $class->context_class;
1670
1671     my $c = $class->context_class->new({});
1672
1673     # For on-demand data
1674     $c->request->_context($c);
1675     $c->response->_context($c);
1676
1677     #surely this is not the most efficient way to do things...
1678     $c->stats($class->stats_class->new)->enable($c->use_stats);
1679     if ( $c->debug ) {
1680         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1681     }
1682
1683     #XXX reuse coderef from can
1684     # Allow engine to direct the prepare flow (for POE)
1685     if ( $c->engine->can('prepare') ) {
1686         $c->engine->prepare( $c, @arguments );
1687     }
1688     else {
1689         $c->prepare_request(@arguments);
1690         $c->prepare_connection;
1691         $c->prepare_query_parameters;
1692         $c->prepare_headers;
1693         $c->prepare_cookies;
1694         $c->prepare_path;
1695
1696         # Prepare the body for reading, either by prepare_body
1697         # or the user, if they are using $c->read
1698         $c->prepare_read;
1699
1700         # Parse the body unless the user wants it on-demand
1701         unless ( $c->config->{parse_on_demand} ) {
1702             $c->prepare_body;
1703         }
1704     }
1705
1706     my $method  = $c->req->method  || '';
1707     my $path    = $c->req->path;
1708     $path       = '/' unless length $path;
1709     my $address = $c->req->address || '';
1710
1711     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1712       if $c->debug;
1713
1714     $c->prepare_action;
1715
1716     return $c;
1717 }
1718
1719 =head2 $c->prepare_action
1720
1721 Prepares action. See L<Catalyst::Dispatcher>.
1722
1723 =cut
1724
1725 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1726
1727 =head2 $c->prepare_body
1728
1729 Prepares message body.
1730
1731 =cut
1732
1733 sub prepare_body {
1734     my $c = shift;
1735
1736     #Moose TODO: what is  _body ??
1737     # Do we run for the first time?
1738     return if defined $c->request->{_body};
1739
1740     # Initialize on-demand data
1741     $c->engine->prepare_body( $c, @_ );
1742     $c->prepare_parameters;
1743     $c->prepare_uploads;
1744
1745     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1746         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1747         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1748             my $param = $c->req->body_parameters->{$key};
1749             my $value = defined($param) ? $param : '';
1750             $t->row( $key,
1751                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1752         }
1753         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1754     }
1755 }
1756
1757 =head2 $c->prepare_body_chunk( $chunk )
1758
1759 Prepares a chunk of data before sending it to L<HTTP::Body>.
1760
1761 See L<Catalyst::Engine>.
1762
1763 =cut
1764
1765 sub prepare_body_chunk {
1766     my $c = shift;
1767     $c->engine->prepare_body_chunk( $c, @_ );
1768 }
1769
1770 =head2 $c->prepare_body_parameters
1771
1772 Prepares body parameters.
1773
1774 =cut
1775
1776 sub prepare_body_parameters {
1777     my $c = shift;
1778     $c->engine->prepare_body_parameters( $c, @_ );
1779 }
1780
1781 =head2 $c->prepare_connection
1782
1783 Prepares connection.
1784
1785 =cut
1786
1787 sub prepare_connection {
1788     my $c = shift;
1789     $c->engine->prepare_connection( $c, @_ );
1790 }
1791
1792 =head2 $c->prepare_cookies
1793
1794 Prepares cookies.
1795
1796 =cut
1797
1798 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1799
1800 =head2 $c->prepare_headers
1801
1802 Prepares headers.
1803
1804 =cut
1805
1806 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1807
1808 =head2 $c->prepare_parameters
1809
1810 Prepares parameters.
1811
1812 =cut
1813
1814 sub prepare_parameters {
1815     my $c = shift;
1816     $c->prepare_body_parameters;
1817     $c->engine->prepare_parameters( $c, @_ );
1818 }
1819
1820 =head2 $c->prepare_path
1821
1822 Prepares path and base.
1823
1824 =cut
1825
1826 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1827
1828 =head2 $c->prepare_query_parameters
1829
1830 Prepares query parameters.
1831
1832 =cut
1833
1834 sub prepare_query_parameters {
1835     my $c = shift;
1836
1837     $c->engine->prepare_query_parameters( $c, @_ );
1838
1839     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1840         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1841         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1842             my $param = $c->req->query_parameters->{$key};
1843             my $value = defined($param) ? $param : '';
1844             $t->row( $key,
1845                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1846         }
1847         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1848     }
1849 }
1850
1851 =head2 $c->prepare_read
1852
1853 Prepares the input for reading.
1854
1855 =cut
1856
1857 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1858
1859 =head2 $c->prepare_request
1860
1861 Prepares the engine request.
1862
1863 =cut
1864
1865 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1866
1867 =head2 $c->prepare_uploads
1868
1869 Prepares uploads.
1870
1871 =cut
1872
1873 sub prepare_uploads {
1874     my $c = shift;
1875
1876     $c->engine->prepare_uploads( $c, @_ );
1877
1878     if ( $c->debug && keys %{ $c->request->uploads } ) {
1879         my $t = Text::SimpleTable->new(
1880             [ 12, 'Parameter' ],
1881             [ 26, 'Filename' ],
1882             [ 18, 'Type' ],
1883             [ 9,  'Size' ]
1884         );
1885         for my $key ( sort keys %{ $c->request->uploads } ) {
1886             my $upload = $c->request->uploads->{$key};
1887             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1888                 $t->row( $key, $u->filename, $u->type, $u->size );
1889             }
1890         }
1891         $c->log->debug( "File Uploads are:\n" . $t->draw );
1892     }
1893 }
1894
1895 =head2 $c->prepare_write
1896
1897 Prepares the output for writing.
1898
1899 =cut
1900
1901 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1902
1903 =head2 $c->request_class
1904
1905 Returns or sets the request class.
1906
1907 =head2 $c->response_class
1908
1909 Returns or sets the response class.
1910
1911 =head2 $c->read( [$maxlength] )
1912
1913 Reads a chunk of data from the request body. This method is designed to
1914 be used in a while loop, reading C<$maxlength> bytes on every call.
1915 C<$maxlength> defaults to the size of the request if not specified.
1916
1917 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1918 directly.
1919
1920 Warning: If you use read(), Catalyst will not process the body,
1921 so you will not be able to access POST parameters or file uploads via
1922 $c->request.  You must handle all body parsing yourself.
1923
1924 =cut
1925
1926 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1927
1928 =head2 $c->run
1929
1930 Starts the engine.
1931
1932 =cut
1933
1934 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1935
1936 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1937
1938 Sets an action in a given namespace.
1939
1940 =cut
1941
1942 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1943
1944 =head2 $c->setup_actions($component)
1945
1946 Sets up actions for a component.
1947
1948 =cut
1949
1950 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1951
1952 =head2 $c->setup_components
1953
1954 Sets up components. Specify a C<setup_components> config option to pass
1955 additional options directly to L<Module::Pluggable>. To add additional
1956 search paths, specify a key named C<search_extra> as an array
1957 reference. Items in the array beginning with C<::> will have the
1958 application class name prepended to them.
1959
1960 All components found will also have any
1961 L<Devel::InnerPackage|inner packages> loaded and set up as components.
1962 Note, that modules which are B<not> an I<inner package> of the main
1963 file namespace loaded will not be instantiated as components.
1964
1965 =cut
1966
1967 sub setup_components {
1968     my $class = shift;
1969
1970     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1971     my $config  = $class->config->{ setup_components };
1972     my $extra   = delete $config->{ search_extra } || [];
1973
1974     push @paths, @$extra;
1975
1976     my $locator = Module::Pluggable::Object->new(
1977         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1978         %$config
1979     );
1980
1981     my @comps = sort { length $a <=> length $b } $locator->plugins;
1982     my %comps = map { $_ => 1 } @comps;
1983
1984     for my $component ( @comps ) {
1985
1986         # We pass ignore_loaded here so that overlay files for (e.g.)
1987         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
1988         # we know M::P::O found a file on disk so this is safe
1989
1990         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1991         #Class::MOP::load_class($component);
1992
1993         my $module  = $class->setup_component( $component );
1994         my %modules = (
1995             $component => $module,
1996             map {
1997                 $_ => $class->setup_component( $_ )
1998             } grep {
1999               not exists $comps{$_}
2000             } Devel::InnerPackage::list_packages( $component )
2001         );
2002
2003         for my $key ( keys %modules ) {
2004             $class->components->{ $key } = $modules{ $key };
2005         }
2006     }
2007 }
2008
2009 =head2 $c->setup_component
2010
2011 =cut
2012
2013 sub setup_component {
2014     my( $class, $component ) = @_;
2015
2016     unless ( $component->can( 'COMPONENT' ) ) {
2017         return $component;
2018     }
2019
2020     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2021     my $config = $class->config->{ $suffix } || {};
2022
2023     my $instance = eval { $component->COMPONENT( $class, $config ); };
2024
2025     if ( my $error = $@ ) {
2026         chomp $error;
2027         Catalyst::Exception->throw(
2028             message => qq/Couldn't instantiate component "$component", "$error"/
2029         );
2030     }
2031
2032     Catalyst::Exception->throw(
2033         message =>
2034         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2035     ) unless blessed($instance);
2036
2037     return $instance;
2038 }
2039
2040 =head2 $c->setup_dispatcher
2041
2042 Sets up dispatcher.
2043
2044 =cut
2045
2046 sub setup_dispatcher {
2047     my ( $class, $dispatcher ) = @_;
2048
2049     if ($dispatcher) {
2050         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2051     }
2052
2053     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2054         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2055     }
2056
2057     unless ($dispatcher) {
2058         $dispatcher = $class->dispatcher_class;
2059     }
2060
2061     Class::MOP::load_class($dispatcher);
2062
2063     # dispatcher instance
2064     $class->dispatcher( $dispatcher->new );
2065 }
2066
2067 =head2 $c->setup_engine
2068
2069 Sets up engine.
2070
2071 =cut
2072
2073 sub setup_engine {
2074     my ( $class, $engine ) = @_;
2075
2076     if ($engine) {
2077         $engine = 'Catalyst::Engine::' . $engine;
2078     }
2079
2080     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2081         $engine = 'Catalyst::Engine::' . $env;
2082     }
2083
2084     if ( $ENV{MOD_PERL} ) {
2085         my $meta = $class->Class::MOP::Object::meta();
2086
2087         # create the apache method
2088         $meta->add_method('apache' => sub { shift->engine->apache });
2089
2090         my ( $software, $version ) =
2091           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2092
2093         $version =~ s/_//g;
2094         $version =~ s/(\.[^.]+)\./$1/g;
2095
2096         if ( $software eq 'mod_perl' ) {
2097
2098             if ( !$engine ) {
2099
2100                 if ( $version >= 1.99922 ) {
2101                     $engine = 'Catalyst::Engine::Apache2::MP20';
2102                 }
2103
2104                 elsif ( $version >= 1.9901 ) {
2105                     $engine = 'Catalyst::Engine::Apache2::MP19';
2106                 }
2107
2108                 elsif ( $version >= 1.24 ) {
2109                     $engine = 'Catalyst::Engine::Apache::MP13';
2110                 }
2111
2112                 else {
2113                     Catalyst::Exception->throw( message =>
2114                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2115                 }
2116
2117             }
2118
2119             # install the correct mod_perl handler
2120             if ( $version >= 1.9901 ) {
2121                 *handler = sub  : method {
2122                     shift->handle_request(@_);
2123                 };
2124             }
2125             else {
2126                 *handler = sub ($$) { shift->handle_request(@_) };
2127             }
2128
2129         }
2130
2131         elsif ( $software eq 'Zeus-Perl' ) {
2132             $engine = 'Catalyst::Engine::Zeus';
2133         }
2134
2135         else {
2136             Catalyst::Exception->throw(
2137                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2138         }
2139     }
2140
2141     unless ($engine) {
2142         $engine = $class->engine_class;
2143     }
2144
2145     Class::MOP::load_class($engine);
2146
2147     # check for old engines that are no longer compatible
2148     my $old_engine;
2149     if ( $engine->isa('Catalyst::Engine::Apache')
2150         && !Catalyst::Engine::Apache->VERSION )
2151     {
2152         $old_engine = 1;
2153     }
2154
2155     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2156         && Catalyst::Engine::Server->VERSION le '0.02' )
2157     {
2158         $old_engine = 1;
2159     }
2160
2161     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2162         && $engine->VERSION eq '0.01' )
2163     {
2164         $old_engine = 1;
2165     }
2166
2167     elsif ($engine->isa('Catalyst::Engine::Zeus')
2168         && $engine->VERSION eq '0.01' )
2169     {
2170         $old_engine = 1;
2171     }
2172
2173     if ($old_engine) {
2174         Catalyst::Exception->throw( message =>
2175               qq/Engine "$engine" is not supported by this version of Catalyst/
2176         );
2177     }
2178
2179     # engine instance
2180     $class->engine( $engine->new );
2181 }
2182
2183 =head2 $c->setup_home
2184
2185 Sets up the home directory.
2186
2187 =cut
2188
2189 sub setup_home {
2190     my ( $class, $home ) = @_;
2191
2192     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2193         $home = $env;
2194     }
2195
2196     $home ||= Catalyst::Utils::home($class);
2197
2198     if ($home) {
2199         #I remember recently being scolded for assigning config values like this
2200         $class->config->{home} ||= $home;
2201         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2202     }
2203 }
2204
2205 =head2 $c->setup_log
2206
2207 Sets up log.
2208
2209 =cut
2210
2211 sub setup_log {
2212     my ( $class, $debug ) = @_;
2213
2214     unless ( $class->log ) {
2215         $class->log( Catalyst::Log->new );
2216     }
2217
2218     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2219     if ( defined($env_debug) ? $env_debug : $debug ) {
2220         $class->Class::MOP::Object::meta()->add_method('debug' => sub { 1 });
2221         $class->log->debug('Debug messages enabled');
2222     }
2223 }
2224
2225 =head2 $c->setup_plugins
2226
2227 Sets up plugins.
2228
2229 =cut
2230
2231 =head2 $c->setup_stats
2232
2233 Sets up timing statistics class.
2234
2235 =cut
2236
2237 sub setup_stats {
2238     my ( $class, $stats ) = @_;
2239
2240     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2241
2242     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2243     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2244         $class->Class::MOP::Object::meta()->add_method('use_stats' => sub { 1 });
2245         $class->log->debug('Statistics enabled');
2246     }
2247 }
2248
2249
2250 =head2 $c->registered_plugins
2251
2252 Returns a sorted list of the plugins which have either been stated in the
2253 import list or which have been added via C<< MyApp->plugin(@args); >>.
2254
2255 If passed a given plugin name, it will report a boolean value indicating
2256 whether or not that plugin is loaded.  A fully qualified name is required if
2257 the plugin name does not begin with C<Catalyst::Plugin::>.
2258
2259  if ($c->registered_plugins('Some::Plugin')) {
2260      ...
2261  }
2262
2263 =cut
2264
2265 {
2266
2267     sub registered_plugins {
2268         my $proto = shift;
2269         return sort keys %{ $proto->_plugins } unless @_;
2270         my $plugin = shift;
2271         return 1 if exists $proto->_plugins->{$plugin};
2272         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2273     }
2274
2275     sub _register_plugin {
2276         my ( $proto, $plugin, $instant ) = @_;
2277         my $class = ref $proto || $proto;
2278
2279         # no ignore_loaded here, the plugin may already have been
2280         # defined in memory and we don't want to error on "no file" if so
2281
2282         Class::MOP::load_class( $plugin );
2283
2284         $proto->_plugins->{$plugin} = 1;
2285         unless ($instant) {
2286             no strict 'refs';
2287             if ( my $meta = $class->Class::MOP::Object::meta() ) {
2288               my @superclasses = ($plugin, $meta->superclasses );
2289               $meta->superclasses(@superclasses);
2290             } else {
2291               unshift @{"$class\::ISA"}, $plugin;
2292             }
2293         }
2294         return $class;
2295     }
2296
2297     sub setup_plugins {
2298         my ( $class, $plugins ) = @_;
2299
2300         $class->_plugins( {} ) unless $class->_plugins;
2301         $plugins ||= [];
2302         for my $plugin ( reverse @$plugins ) {
2303
2304             unless ( $plugin =~ s/\A\+// ) {
2305                 $plugin = "Catalyst::Plugin::$plugin";
2306             }
2307
2308             $class->_register_plugin($plugin);
2309         }
2310     }
2311 }
2312
2313 =head2 $c->stack
2314
2315 Returns an arrayref of the internal execution stack (actions that are
2316 currently executing).
2317
2318 =head2 $c->stats_class
2319
2320 Returns or sets the stats (timing statistics) class.
2321
2322 =head2 $c->use_stats
2323
2324 Returns 1 when stats collection is enabled.  Stats collection is enabled
2325 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2326 environment variable is set.
2327
2328 Note that this is a static method, not an accessor and should be overloaded
2329 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2330
2331 =cut
2332
2333 sub use_stats { 0 }
2334
2335
2336 =head2 $c->write( $data )
2337
2338 Writes $data to the output stream. When using this method directly, you
2339 will need to manually set the C<Content-Length> header to the length of
2340 your output data, if known.
2341
2342 =cut
2343
2344 sub write {
2345     my $c = shift;
2346
2347     # Finalize headers if someone manually writes output
2348     $c->finalize_headers;
2349
2350     return $c->engine->write( $c, @_ );
2351 }
2352
2353 =head2 version
2354
2355 Returns the Catalyst version number. Mostly useful for "powered by"
2356 messages in template systems.
2357
2358 =cut
2359
2360 sub version { return $Catalyst::VERSION }
2361
2362 =head1 INTERNAL ACTIONS
2363
2364 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2365 C<_ACTION>, and C<_END>. These are by default not shown in the private
2366 action table, but you can make them visible with a config parameter.
2367
2368     MyApp->config->{show_internal_actions} = 1;
2369
2370 =head1 CASE SENSITIVITY
2371
2372 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2373 mapped to C</foo/bar>. You can activate case sensitivity with a config
2374 parameter.
2375
2376     MyApp->config->{case_sensitive} = 1;
2377
2378 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2379
2380 =head1 ON-DEMAND PARSER
2381
2382 The request body is usually parsed at the beginning of a request,
2383 but if you want to handle input yourself, you can enable on-demand
2384 parsing with a config parameter.
2385
2386     MyApp->config->{parse_on_demand} = 1;
2387
2388 =head1 PROXY SUPPORT
2389
2390 Many production servers operate using the common double-server approach,
2391 with a lightweight frontend web server passing requests to a larger
2392 backend server. An application running on the backend server must deal
2393 with two problems: the remote user always appears to be C<127.0.0.1> and
2394 the server's hostname will appear to be C<localhost> regardless of the
2395 virtual host that the user connected through.
2396
2397 Catalyst will automatically detect this situation when you are running
2398 the frontend and backend servers on the same machine. The following
2399 changes are made to the request.
2400
2401     $c->req->address is set to the user's real IP address, as read from
2402     the HTTP X-Forwarded-For header.
2403
2404     The host value for $c->req->base and $c->req->uri is set to the real
2405     host, as read from the HTTP X-Forwarded-Host header.
2406
2407 Obviously, your web server must support these headers for this to work.
2408
2409 In a more complex server farm environment where you may have your
2410 frontend proxy server(s) on different machines, you will need to set a
2411 configuration option to tell Catalyst to read the proxied data from the
2412 headers.
2413
2414     MyApp->config->{using_frontend_proxy} = 1;
2415
2416 If you do not wish to use the proxy support at all, you may set:
2417
2418     MyApp->config->{ignore_frontend_proxy} = 1;
2419
2420 =head1 THREAD SAFETY
2421
2422 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2423 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2424 believe the Catalyst core to be thread-safe.
2425
2426 If you plan to operate in a threaded environment, remember that all other
2427 modules you are using must also be thread-safe. Some modules, most notably
2428 L<DBD::SQLite>, are not thread-safe.
2429
2430 =head1 SUPPORT
2431
2432 IRC:
2433
2434     Join #catalyst on irc.perl.org.
2435
2436 Mailing Lists:
2437
2438     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2439     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2440
2441 Web:
2442
2443     http://catalyst.perl.org
2444
2445 Wiki:
2446
2447     http://dev.catalyst.perl.org
2448
2449 =head1 SEE ALSO
2450
2451 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2452
2453 =head2 L<Catalyst::Manual> - The Catalyst Manual
2454
2455 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2456
2457 =head2 L<Catalyst::Engine> - Core engine
2458
2459 =head2 L<Catalyst::Log> - Log class.
2460
2461 =head2 L<Catalyst::Request> - Request object
2462
2463 =head2 L<Catalyst::Response> - Response object
2464
2465 =head2 L<Catalyst::Test> - The test suite.
2466
2467 =head1 PROJECT FOUNDER
2468
2469 sri: Sebastian Riedel <sri@cpan.org>
2470
2471 =head1 CONTRIBUTORS
2472
2473 abw: Andy Wardley
2474
2475 acme: Leon Brocard <leon@astray.com>
2476
2477 Andrew Bramble
2478
2479 Andrew Ford
2480
2481 Andrew Ruthven
2482
2483 andyg: Andy Grundman <andy@hybridized.org>
2484
2485 audreyt: Audrey Tang
2486
2487 bricas: Brian Cassidy <bricas@cpan.org>
2488
2489 Caelum: Rafael Kitover <rkitover@io.com>
2490
2491 chansen: Christian Hansen
2492
2493 chicks: Christopher Hicks
2494
2495 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2496
2497 Drew Taylor
2498
2499 esskar: Sascha Kiefer
2500
2501 fireartist: Carl Franks <cfranks@cpan.org>
2502
2503 gabb: Danijel Milicevic
2504
2505 Gary Ashton Jones
2506
2507 Geoff Richards
2508
2509 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2510
2511 jcamacho: Juan Camacho
2512
2513 Jody Belka
2514
2515 Johan Lindstrom
2516
2517 jon: Jon Schutz <jjschutz@cpan.org>
2518
2519 marcus: Marcus Ramberg <mramberg@cpan.org>
2520
2521 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2522
2523 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2524
2525 mugwump: Sam Vilain
2526
2527 naughton: David Naughton
2528
2529 ningu: David Kamholz <dkamholz@cpan.org>
2530
2531 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2532
2533 numa: Dan Sully <daniel@cpan.org>
2534
2535 obra: Jesse Vincent
2536
2537 omega: Andreas Marienborg
2538
2539 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2540
2541 rafl: Florian Ragwitz <rafl@debian.org>
2542
2543 sky: Arthur Bergman
2544
2545 the_jester: Jesse Sheidlower
2546
2547 Ulf Edvinsson
2548
2549 willert: Sebastian Willert <willert@cpan.org>
2550
2551 =head1 LICENSE
2552
2553 This library is free software, you can redistribute it and/or modify it under
2554 the same terms as Perl itself.
2555
2556 =cut
2557
2558 no Moose;
2559
2560 __PACKAGE__->meta->make_immutable;
2561
2562 1;