lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use Scalar::Util qw/weaken blessed/;
  23 use Tree::Simple qw/use_weak_refs/;
  24 use Tree::Simple::Visitor::FindByUID;
  25 use attributes;
  26 use utf8;
  27 use Carp qw/croak/;
  28
  29 BEGIN { require 5.008001; }
  30
  31 __PACKAGE__->mk_accessors(
  32     qw/counter request response state action stack namespace stats/
  33 );
  34
  35 attributes->import( __PACKAGE__, \&namespace, 'lvalue' );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class setup_finished/;
  56
  57 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  58 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  59 __PACKAGE__->request_class('Catalyst::Request');
  60 __PACKAGE__->response_class('Catalyst::Response');
  61
  62 # Remember to update this in Catalyst::Runtime as well!
  63
  64 our $VERSION = '5.7003';
  65
  66 sub import {
  67     my ( $class, @arguments ) = @_;
  68
  69     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  70     # callers @ISA.
  71     return unless $class eq 'Catalyst';
  72
  73     my $caller = caller(0);
  74
  75     unless ( $caller->isa('Catalyst') ) {
  76         no strict 'refs';
  77         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  78     }
  79
  80     $caller->arguments( [@arguments] );
  81     $caller->setup_home;
  82 }
  83
  84 =head1 NAME
  85
  86 Catalyst - The Elegant MVC Web Application Framework
  87
  88 =head1 SYNOPSIS
  89
  90     # Install Catalyst::Devel for helpers and other development tools
  91     # use the helper to create a new application
  92     catalyst.pl MyApp
  93
  94     # add models, views, controllers
  95     script/myapp_create.pl model Database DBIC::SchemaLoader dbi:SQLite:/path/to/db
  96     script/myapp_create.pl view TT TT
  97     script/myapp_create.pl controller Search
  98
  99     # built in testserver -- use -r to restart automatically on changes
 100     script/myapp_server.pl
 101
 102     # command line testing interface
 103     script/myapp_test.pl /yada
 104
 105     ### in lib/MyApp.pm
 106     use Catalyst qw/-Debug/; # include plugins here as well
 107
 108         ### In lib/MyApp/Controller/Root.pm (autocreated)
 109     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 110         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 111         $c->stash->{template} = 'foo.tt'; # set the template
 112         # lookup something from db -- stash vars are passed to TT
 113         $c->stash->{data} =
 114           $c->model('Database::Foo')->search( { country => $args[0] } );
 115         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 116             $c->forward( 'bar' ); # process another action
 117             # do something else after forward returns
 118         }
 119     }
 120
 121     # The foo.tt TT template can use the stash data from the database
 122     [% WHILE (item = data.next) %]
 123         [% item.foo %]
 124     [% END %]
 125
 126     # called for /bar/of/soap, /bar/of/soap/10, etc.
 127     sub bar : Path('/bar/of/soap') { ... }
 128
 129     # called for all actions, from the top-most controller downwards
 130     sub auto : Private {
 131         my ( $self, $c ) = @_;
 132         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 133             $c->res->redirect( '/login' ); # require login
 134             return 0; # abort request and go immediately to end()
 135         }
 136         return 1; # success; carry on to next action
 137     }
 138
 139     # called after all actions are finished
 140     sub end : Private {
 141         my ( $self, $c ) = @_;
 142         if ( scalar @{ $c->error } ) { ... } # handle errors
 143         return if $c->res->body; # already have a response
 144         $c->forward( 'MyApp::View::TT' ); # render template
 145     }
 146
 147     ### in MyApp/Controller/Foo.pm
 148     # called for /foo/bar
 149     sub bar : Local { ... }
 150
 151     # called for /blargle
 152     sub blargle : Global { ... }
 153
 154     # an index action matches /foo, but not /foo/1, etc.
 155     sub index : Private { ... }
 156
 157     ### in MyApp/Controller/Foo/Bar.pm
 158     # called for /foo/bar/baz
 159     sub baz : Local { ... }
 160
 161     # first Root auto is called, then Foo auto, then this
 162     sub auto : Private { ... }
 163
 164     # powerful regular expression paths are also possible
 165     sub details : Regex('^product/(\w+)/details$') {
 166         my ( $self, $c ) = @_;
 167         # extract the (\w+) from the URI
 168         my $product = $c->req->captures->[0];
 169     }
 170
 171 See L<Catalyst::Manual::Intro> for additional information.
 172
 173 =head1 DESCRIPTION
 174
 175 Catalyst is a modern framework for making web applications without the
 176 pain usually associated with this process. This document is a reference
 177 to the main Catalyst application. If you are a new user, we suggest you
 178 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 179
 180 See L<Catalyst::Manual> for more documentation.
 181
 182 Catalyst plugins can be loaded by naming them as arguments to the "use
 183 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 184 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 185 C<My::Module>.
 186
 187     use Catalyst qw/My::Module/;
 188
 189 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 190 fully qualify the name by using a unary plus:
 191
 192     use Catalyst qw/
 193         My::Module
 194         +Fully::Qualified::Plugin::Name
 195     /;
 196
 197 Special flags like C<-Debug> and C<-Engine> can also be specified as
 198 arguments when Catalyst is loaded:
 199
 200     use Catalyst qw/-Debug My::Module/;
 201
 202 The position of plugins and flags in the chain is important, because
 203 they are loaded in the order in which they appear.
 204
 205 The following flags are supported:
 206
 207 =head2 -Debug
 208
 209 Enables debug output. You can also force this setting from the system
 210 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 211 settings override the application, with <MYAPP>_DEBUG having the highest
 212 priority.
 213
 214 =head2 -Engine
 215
 216 Forces Catalyst to use a specific engine. Omit the
 217 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 218
 219     use Catalyst qw/-Engine=CGI/;
 220
 221 =head2 -Home
 222
 223 Forces Catalyst to use a specific home directory, e.g.:
 224
 225     use Catalyst qw[-Home=/usr/mst];
 226
 227 =head2 -Log
 228
 229 Specifies log level.
 230
 231 =head1 METHODS
 232
 233 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 234
 235 =head2 $c->action
 236
 237 Returns a L<Catalyst::Action> object for the current action, which
 238 stringifies to the action name. See L<Catalyst::Action>.
 239
 240 =head2 $c->namespace
 241
 242 Returns the namespace of the current action, i.e., the URI prefix
 243 corresponding to the controller of the current action. For example:
 244
 245     # in Controller::Foo::Bar
 246     $c->namespace; # returns 'foo/bar';
 247
 248 =head2 $c->request
 249
 250 =head2 $c->req
 251
 252 Returns the current L<Catalyst::Request> object, giving access to
 253 information about the current client request (including parameters,
 254 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 255
 256 =head2 REQUEST FLOW HANDLING
 257
 258 =head2 $c->forward( $action [, \@arguments ] )
 259
 260 =head2 $c->forward( $class, $method, [, \@arguments ] )
 261
 262 Forwards processing to another action, by its private name. If you give a
 263 class name but no method, C<process()> is called. You may also optionally
 264 pass arguments in an arrayref. The action will receive the arguments in
 265 C<@_> and C<$c-E<gt>req-E<gt>args>. Upon returning from the function,
 266 C<$c-E<gt>req-E<gt>args> will be restored to the previous values.
 267
 268 Any data C<return>ed from the action forwarded to, will be returned by the
 269 call to forward.
 270
 271     my $foodata = $c->forward('/foo');
 272     $c->forward('index');
 273     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 274     $c->forward('MyApp::View::TT');
 275
 276 Note that forward implies an C<<eval { }>> around the call (actually
 277 C<execute> does), thus de-fatalizing all 'dies' within the called
 278 action. If you want C<die> to propagate you need to do something like:
 279
 280     $c->forward('foo');
 281     die $c->error if $c->error;
 282
 283 Or make sure to always return true values from your actions and write
 284 your code like this:
 285
 286     $c->forward('foo') || return;
 287
 288 =cut
 289
 290 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 291
 292 =head2 $c->detach( $action [, \@arguments ] )
 293
 294 =head2 $c->detach( $class, $method, [, \@arguments ] )
 295
 296 =head2 $c->detach()
 297
 298 The same as C<forward>, but doesn't return to the previous action when
 299 processing is finished.
 300
 301 When called with no arguments it escapes the processing chain entirely.
 302
 303 =cut
 304
 305 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 306
 307 =head2 $c->response
 308
 309 =head2 $c->res
 310
 311 Returns the current L<Catalyst::Response> object, q.v.
 312
 313 =head2 $c->stash
 314
 315 Returns a hashref to the stash, which may be used to store data and pass
 316 it between components during a request. You can also set hash keys by
 317 passing arguments. The stash is automatically sent to the view. The
 318 stash is cleared at the end of a request; it cannot be used for
 319 persistent storage (for this you must use a session; see
 320 L<Catalyst::Plugin::Session> for a complete system integrated with
 321 Catalyst).
 322
 323     $c->stash->{foo} = $bar;
 324     $c->stash( { moose => 'majestic', qux => 0 } );
 325     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 326
 327     # stash is automatically passed to the view for use in a template
 328     $c->forward( 'MyApp::V::TT' );
 329
 330 =cut
 331
 332 sub stash {
 333     my $c = shift;
 334     if (@_) {
 335         my $stash = @_ > 1 ? {@_} : $_[0];
 336         croak('stash takes a hash or hashref') unless ref $stash;
 337         foreach my $key ( keys %$stash ) {
 338             $c->{stash}->{$key} = $stash->{$key};
 339         }
 340     }
 341     return $c->{stash};
 342 }
 343
 344 =head2 $c->error
 345
 346 =head2 $c->error($error, ...)
 347
 348 =head2 $c->error($arrayref)
 349
 350 Returns an arrayref containing error messages.  If Catalyst encounters an
 351 error while processing a request, it stores the error in $c->error.  This
 352 method should not be used to store non-fatal error messages.
 353
 354     my @error = @{ $c->error };
 355
 356 Add a new error.
 357
 358     $c->error('Something bad happened');
 359
 360 =cut
 361
 362 sub error {
 363     my $c = shift;
 364     if ( $_[0] ) {
 365         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 366         croak @$error unless ref $c;
 367         push @{ $c->{error} }, @$error;
 368     }
 369     elsif ( defined $_[0] ) { $c->{error} = undef }
 370     return $c->{error} || [];
 371 }
 372
 373
 374 =head2 $c->state
 375
 376 Contains the return value of the last executed action.
 377
 378 =head2 $c->clear_errors
 379
 380 Clear errors.  You probably don't want to clear the errors unless you are
 381 implementing a custom error screen.
 382
 383 This is equivalent to running
 384
 385     $c->error(0);
 386
 387 =cut
 388
 389 sub clear_errors {
 390     my $c = shift;
 391     $c->error(0);
 392 }
 393
 394
 395 # search via regex
 396 sub _comp_search {
 397     my ( $c, @names ) = @_;
 398
 399     foreach my $name (@names) {
 400         foreach my $component ( keys %{ $c->components } ) {
 401             return $c->components->{$component} if $component =~ /$name/i;
 402         }
 403     }
 404
 405     return undef;
 406 }
 407
 408 # try explicit component names
 409 sub _comp_explicit {
 410     my ( $c, @names ) = @_;
 411
 412     foreach my $try (@names) {
 413         return $c->components->{$try} if ( exists $c->components->{$try} );
 414     }
 415
 416     return undef;
 417 }
 418
 419 # like component, but try just these prefixes before regex searching,
 420 #  and do not try to return "sort keys %{ $c->components }"
 421 sub _comp_prefixes {
 422     my ( $c, $name, @prefixes ) = @_;
 423
 424     my $appclass = ref $c || $c;
 425
 426     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 427
 428     my $comp = $c->_comp_explicit(@names);
 429     return $comp if defined($comp);
 430     $comp = $c->_comp_search($name);
 431     return $comp;
 432 }
 433
 434 # Find possible names for a prefix
 435
 436 sub _comp_names {
 437     my ( $c, @prefixes ) = @_;
 438
 439     my $appclass = ref $c || $c;
 440
 441     my @pre = map { "${appclass}::${_}::" } @prefixes;
 442
 443     my @names;
 444
 445     COMPONENT: foreach my $comp ($c->component) {
 446         foreach my $p (@pre) {
 447             if ($comp =~ s/^$p//) {
 448                 push(@names, $comp);
 449                 next COMPONENT;
 450             }
 451         }
 452     }
 453
 454     return @names;
 455 }
 456
 457 # Return a component if only one matches.
 458 sub _comp_singular {
 459     my ( $c, @prefixes ) = @_;
 460
 461     my $appclass = ref $c || $c;
 462
 463     my ( $comp, $rest ) =
 464       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 465     return $comp unless $rest;
 466 }
 467
 468 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 469 sub _filter_component {
 470     my ( $c, $comp, @args ) = @_;
 471     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 472         return $comp->ACCEPT_CONTEXT( $c, @args );
 473     }
 474     else { return $comp }
 475 }
 476
 477 =head2 COMPONENT ACCESSORS
 478
 479 =head2 $c->controller($name)
 480
 481 Gets a L<Catalyst::Controller> instance by name.
 482
 483     $c->controller('Foo')->do_stuff;
 484
 485 If the name is omitted, will return the controller for the dispatched
 486 action.
 487
 488 =cut
 489
 490 sub controller {
 491     my ( $c, $name, @args ) = @_;
 492     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 493         @args )
 494       if ($name);
 495     return $c->component( $c->action->class );
 496 }
 497
 498 =head2 $c->model($name)
 499
 500 Gets a L<Catalyst::Model> instance by name.
 501
 502     $c->model('Foo')->do_stuff;
 503
 504 If the name is omitted, it will look for
 505  - a model object in $c->stash{current_model_instance}, then
 506  - a model name in $c->stash->{current_model}, then
 507  - a config setting 'default_model', or
 508  - check if there is only one model, and return it if that's the case.
 509
 510 =cut
 511
 512 sub model {
 513     my ( $c, $name, @args ) = @_;
 514     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 515         @args )
 516       if $name;
 517     if (ref $c) {
 518         return $c->stash->{current_model_instance}
 519           if $c->stash->{current_model_instance};
 520         return $c->model( $c->stash->{current_model} )
 521           if $c->stash->{current_model};
 522         return $c->model( $c->config->{default_model} )
 523           if $c->config->{default_model};
 524     }
 525     return $c->_filter_component( $c->_comp_singular(qw/Model M/), @args );
 526
 527 }
 528
 529 =head2 $c->controllers
 530
 531 Returns the available names which can be passed to $c->controller
 532
 533 =cut
 534
 535 sub controllers {
 536     my ( $c ) = @_;
 537     return $c->_comp_names(qw/Controller C/);
 538 }
 539
 540
 541 =head2 $c->view($name)
 542
 543 Gets a L<Catalyst::View> instance by name.
 544
 545     $c->view('Foo')->do_stuff;
 546
 547 If the name is omitted, it will look for
 548  - a view object in $c->stash{current_view_instance}, then
 549  - a view name in $c->stash->{current_view}, then
 550  - a config setting 'default_view', or
 551  - check if there is only one view, and return it if that's the case.
 552
 553 =cut
 554
 555 sub view {
 556     my ( $c, $name, @args ) = @_;
 557     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 558         @args )
 559       if $name;
 560     if (ref $c) {
 561         return $c->stash->{current_view_instance}
 562           if $c->stash->{current_view_instance};
 563         return $c->view( $c->stash->{current_view} )
 564           if $c->stash->{current_view};
 565         return $c->view( $c->config->{default_view} )
 566           if $c->config->{default_view};
 567     }
 568     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 569 }
 570
 571 =head2 $c->models
 572
 573 Returns the available names which can be passed to $c->model
 574
 575 =cut
 576
 577 sub models {
 578     my ( $c ) = @_;
 579     return $c->_comp_names(qw/Model M/);
 580 }
 581
 582
 583 =head2 $c->views
 584
 585 Returns the available names which can be passed to $c->view
 586
 587 =cut
 588
 589 sub views {
 590     my ( $c ) = @_;
 591     return $c->_comp_names(qw/View V/);
 592 }
 593
 594 =head2 $c->comp($name)
 595
 596 =head2 $c->component($name)
 597
 598 Gets a component object by name. This method is no longer recommended,
 599 unless you want to get a specific component by full
 600 class. C<$c-E<gt>controller>, C<$c-E<gt>model>, and C<$c-E<gt>view>
 601 should be used instead.
 602
 603 =cut
 604
 605 sub component {
 606     my $c = shift;
 607
 608     if (@_) {
 609
 610         my $name = shift;
 611
 612         my $appclass = ref $c || $c;
 613
 614         my @names = (
 615             $name, "${appclass}::${name}",
 616             map { "${appclass}::${_}::${name}" }
 617               qw/Model M Controller C View V/
 618         );
 619
 620         my $comp = $c->_comp_explicit(@names);
 621         return $c->_filter_component( $comp, @_ ) if defined($comp);
 622
 623         $comp = $c->_comp_search($name);
 624         return $c->_filter_component( $comp, @_ ) if defined($comp);
 625     }
 626
 627     return sort keys %{ $c->components };
 628 }
 629
 630
 631
 632 =head2 CLASS DATA AND HELPER CLASSES
 633
 634 =head2 $c->config
 635
 636 Returns or takes a hashref containing the application's configuration.
 637
 638     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 639
 640 You can also use a L<YAML> config file like myapp.yml in your
 641 applications home directory.
 642
 643     ---
 644     db: dsn:SQLite:foo.db
 645
 646
 647 =cut
 648
 649 sub config {
 650     my $c = shift;
 651
 652     $c->log->warn("Setting config after setup has been run is not a good idea.")
 653       if ( @_ and $c->setup_finished );
 654
 655     $c->NEXT::config(@_);
 656 }
 657
 658 =head2 $c->log
 659
 660 Returns the logging object instance. Unless it is already set, Catalyst
 661 sets this up with a L<Catalyst::Log> object. To use your own log class,
 662 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 663 C<< __PACKAGE__->setup >>.
 664
 665  __PACKAGE__->log( MyLogger->new );
 666  __PACKAGE__->setup;
 667
 668 And later:
 669
 670     $c->log->info( 'Now logging with my own logger!' );
 671
 672 Your log class should implement the methods described in
 673 L<Catalyst::Log>.
 674
 675
 676 =head2 $c->debug
 677
 678 Overload to enable debug messages (same as -Debug option).
 679
 680 Note that this is a static method, not an accessor and should be overloaded
 681 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 682
 683 =cut
 684
 685 sub debug { 0 }
 686
 687 =head2 $c->dispatcher
 688
 689 Returns the dispatcher instance. Stringifies to class name. See
 690 L<Catalyst::Dispatcher>.
 691
 692 =head2 $c->engine
 693
 694 Returns the engine instance. Stringifies to the class name. See
 695 L<Catalyst::Engine>.
 696
 697
 698 =head2 UTILITY METHODS
 699
 700 =head2 $c->path_to(@path)
 701
 702 Merges C<@path> with C<$c-E<gt>config-E<gt>{home}> and returns a
 703 L<Path::Class> object.
 704
 705 For example:
 706
 707     $c->path_to( 'db', 'sqlite.db' );
 708
 709 =cut
 710
 711 sub path_to {
 712     my ( $c, @path ) = @_;
 713     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 714     if ( -d $path ) { return $path }
 715     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 716 }
 717
 718 =head2 $c->plugin( $name, $class, @args )
 719
 720 Helper method for plugins. It creates a classdata accessor/mutator and
 721 loads and instantiates the given class.
 722
 723     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 724
 725     $c->prototype->define_javascript_functions;
 726
 727 =cut
 728
 729 sub plugin {
 730     my ( $class, $name, $plugin, @args ) = @_;
 731     $class->_register_plugin( $plugin, 1 );
 732
 733     eval { $plugin->import };
 734     $class->mk_classdata($name);
 735     my $obj;
 736     eval { $obj = $plugin->new(@args) };
 737
 738     if ($@) {
 739         Catalyst::Exception->throw( message =>
 740               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 741     }
 742
 743     $class->$name($obj);
 744     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 745       if $class->debug;
 746 }
 747
 748 =head2 MyApp->setup
 749
 750 Initializes the dispatcher and engine, loads any plugins, and loads the
 751 model, view, and controller components. You may also specify an array
 752 of plugins to load here, if you choose to not load them in the C<use
 753 Catalyst> line.
 754
 755     MyApp->setup;
 756     MyApp->setup( qw/-Debug/ );
 757
 758 =cut
 759
 760 sub setup {
 761     my ( $class, @arguments ) = @_;
 762
 763     $class->log->warn("Running setup twice is not a good idea.")
 764       if ( $class->setup_finished );
 765
 766     unless ( $class->isa('Catalyst') ) {
 767
 768         Catalyst::Exception->throw(
 769             message => qq/'$class' does not inherit from Catalyst/ );
 770     }
 771
 772     if ( $class->arguments ) {
 773         @arguments = ( @arguments, @{ $class->arguments } );
 774     }
 775
 776     # Process options
 777     my $flags = {};
 778
 779     foreach (@arguments) {
 780
 781         if (/^-Debug$/) {
 782             $flags->{log} =
 783               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 784         }
 785         elsif (/^-(\w+)=?(.*)$/) {
 786             $flags->{ lc $1 } = $2;
 787         }
 788         else {
 789             push @{ $flags->{plugins} }, $_;
 790         }
 791     }
 792
 793     $class->setup_home( delete $flags->{home} );
 794
 795     $class->setup_log( delete $flags->{log} );
 796     $class->setup_plugins( delete $flags->{plugins} );
 797     $class->setup_dispatcher( delete $flags->{dispatcher} );
 798     $class->setup_engine( delete $flags->{engine} );
 799
 800     for my $flag ( sort keys %{$flags} ) {
 801
 802         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 803             &$code( $class, delete $flags->{$flag} );
 804         }
 805         else {
 806             $class->log->warn(qq/Unknown flag "$flag"/);
 807         }
 808     }
 809
 810     eval { require Catalyst::Devel; };
 811     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 812         $class->log->warn(<<"EOF");
 813 You are running an old script!
 814
 815   Please update by running (this will overwrite existing files):
 816     catalyst.pl -force -scripts $class
 817
 818   or (this will not overwrite existing files):
 819     catalyst.pl -scripts $class
 820 EOF
 821     }
 822
 823     if ( $class->debug ) {
 824         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 825
 826         if (@plugins) {
 827             my $t = Text::SimpleTable->new(74);
 828             $t->row($_) for @plugins;
 829             $class->log->debug( "Loaded plugins:\n" . $t->draw );
 830         }
 831
 832         my $dispatcher = $class->dispatcher;
 833         my $engine     = $class->engine;
 834         my $home       = $class->config->{home};
 835
 836         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 837         $class->log->debug(qq/Loaded engine "$engine"/);
 838
 839         $home
 840           ? ( -d $home )
 841           ? $class->log->debug(qq/Found home "$home"/)
 842           : $class->log->debug(qq/Home "$home" doesn't exist/)
 843           : $class->log->debug(q/Couldn't find home/);
 844     }
 845
 846     # Call plugins setup
 847     {
 848         no warnings qw/redefine/;
 849         local *setup = sub { };
 850         $class->setup;
 851     }
 852
 853     # Initialize our data structure
 854     $class->components( {} );
 855
 856     $class->setup_components;
 857
 858     if ( $class->debug ) {
 859         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 860         for my $comp ( sort keys %{ $class->components } ) {
 861             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 862             $t->row( $comp, $type );
 863         }
 864         $class->log->debug( "Loaded components:\n" . $t->draw )
 865           if ( keys %{ $class->components } );
 866     }
 867
 868     # Add our self to components, since we are also a component
 869     $class->components->{$class} = $class;
 870
 871     $class->setup_actions;
 872
 873     if ( $class->debug ) {
 874         my $name = $class->config->{name} || 'Application';
 875         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 876     }
 877     $class->log->_flush() if $class->log->can('_flush');
 878
 879     $class->setup_finished(1);
 880 }
 881
 882 =head2 $c->uri_for( $path, @args?, \%query_values? )
 883
 884 Merges path with C<< $c->request->base >> for absolute URIs and with
 885 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 886 object. If any args are passed, they are added at the end of the path.
 887 If the last argument to C<uri_for> is a hash reference, it is assumed to
 888 contain GET parameter key/value pairs, which will be appended to the URI
 889 in standard fashion.
 890
 891 Instead of C<$path>, you can also optionally pass a C<$action> object
 892 which will be resolved to a path using
 893 C<< $c->dispatcher->uri_for_action >>; if the first element of
 894 C<@args> is an arrayref it is treated as a list of captures to be passed
 895 to C<uri_for_action>.
 896
 897 =cut
 898
 899 sub uri_for {
 900     my ( $c, $path, @args ) = @_;
 901     my $base     = $c->request->base->clone;
 902     my $basepath = $base->path;
 903     $basepath =~ s/\/$//;
 904     $basepath .= '/';
 905     my $namespace = $c->namespace || '';
 906
 907     if ( Scalar::Util::blessed($path) ) { # action object
 908         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 909                          ? shift(@args)
 910                          : [] );
 911         $path = $c->dispatcher->uri_for_action($path, $captures);
 912         return undef unless defined($path);
 913         $path = '/' if $path eq '';
 914     }
 915
 916     # massage namespace, empty if absolute path
 917     $namespace =~ s/^\/// if $namespace;
 918     $namespace .= '/' if $namespace;
 919     $path ||= '';
 920     $namespace = '' if $path =~ /^\//;
 921     $path =~ s/^\///;
 922
 923     my $params =
 924       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 925
 926     for my $value ( values %$params ) {
 927         for ( ref $value eq 'ARRAY' ? @$value : $value ) {
 928             $_ = "$_";
 929             utf8::encode( $_ );
 930         }
 931     };
 932
 933     # join args with '/', or a blank string
 934     my $args = ( scalar @args ? '/' . join( '/', @args ) : '' );
 935     $args =~ s/^\/// unless $path;
 936     my $res =
 937       URI->new_abs( URI->new_abs( "$path$args", "$basepath$namespace" ), $base )
 938       ->canonical;
 939     $res->query_form(%$params);
 940     $res;
 941 }
 942
 943 =head2 $c->welcome_message
 944
 945 Returns the Catalyst welcome HTML page.
 946
 947 =cut
 948
 949 sub welcome_message {
 950     my $c      = shift;
 951     my $name   = $c->config->{name};
 952     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
 953     my $prefix = Catalyst::Utils::appprefix( ref $c );
 954     $c->response->content_type('text/html; charset=utf-8');
 955     return <<"EOF";
 956 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
 957     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
 958 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 959     <head>
 960         <meta http-equiv="Content-Language" content="en" />
 961         <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
 962         <title>$name on Catalyst $VERSION</title>
 963         <style type="text/css">
 964             body {
 965                 color: #000;
 966                 background-color: #eee;
 967             }
 968             div#content {
 969                 width: 640px;
 970                 margin-left: auto;
 971                 margin-right: auto;
 972                 margin-top: 10px;
 973                 margin-bottom: 10px;
 974                 text-align: left;
 975                 background-color: #ccc;
 976                 border: 1px solid #aaa;
 977             }
 978             p, h1, h2 {
 979                 margin-left: 20px;
 980                 margin-right: 20px;
 981                 font-family: verdana, tahoma, sans-serif;
 982             }
 983             a {
 984                 font-family: verdana, tahoma, sans-serif;
 985             }
 986             :link, :visited {
 987                     text-decoration: none;
 988                     color: #b00;
 989                     border-bottom: 1px dotted #bbb;
 990             }
 991             :link:hover, :visited:hover {
 992                     color: #555;
 993             }
 994             div#topbar {
 995                 margin: 0px;
 996             }
 997             pre {
 998                 margin: 10px;
 999                 padding: 8px;
1000             }
1001             div#answers {
1002                 padding: 8px;
1003                 margin: 10px;
1004                 background-color: #fff;
1005                 border: 1px solid #aaa;
1006             }
1007             h1 {
1008                 font-size: 0.9em;
1009                 font-weight: normal;
1010                 text-align: center;
1011             }
1012             h2 {
1013                 font-size: 1.0em;
1014             }
1015             p {
1016                 font-size: 0.9em;
1017             }
1018             p img {
1019                 float: right;
1020                 margin-left: 10px;
1021             }
1022             span#appname {
1023                 font-weight: bold;
1024                 font-size: 1.6em;
1025             }
1026         </style>
1027     </head>
1028     <body>
1029         <div id="content">
1030             <div id="topbar">
1031                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1032                     $VERSION</h1>
1033              </div>
1034              <div id="answers">
1035                  <p>
1036                  <img src="$logo" alt="Catalyst Logo" />
1037                  </p>
1038                  <p>Welcome to the wonderful world of Catalyst.
1039                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1040                     framework will make web development something you had
1041                     never expected it to be: Fun, rewarding, and quick.</p>
1042                  <h2>What to do now?</h2>
1043                  <p>That really depends  on what <b>you</b> want to do.
1044                     We do, however, provide you with a few starting points.</p>
1045                  <p>If you want to jump right into web development with Catalyst
1046                     you might want to check out the documentation.</p>
1047                  <pre><code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1048 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1049 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual.pod">Catalyst::Manual</a></code></pre>
1050                  <h2>What to do next?</h2>
1051                  <p>Next it's time to write an actual application. Use the
1052                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1053                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1054                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1055                     they can save you a lot of work.</p>
1056                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1057                     <p>Also, be sure to check out the vast and growing
1058                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1059                     you are likely to find what you need there.
1060                     </p>
1061
1062                  <h2>Need help?</h2>
1063                  <p>Catalyst has a very active community. Here are the main places to
1064                     get in touch with us.</p>
1065                  <ul>
1066                      <li>
1067                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1068                      </li>
1069                      <li>
1070                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1071                      </li>
1072                      <li>
1073                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1074                      </li>
1075                  </ul>
1076                  <h2>In conclusion</h2>
1077                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1078                     as we enjoyed making it. Please contact us if you have ideas
1079                     for improvement or other feedback.</p>
1080              </div>
1081          </div>
1082     </body>
1083 </html>
1084 EOF
1085 }
1086
1087 =head1 INTERNAL METHODS
1088
1089 These methods are not meant to be used by end users.
1090
1091 =head2 $c->components
1092
1093 Returns a hash of components.
1094
1095 =head2 $c->context_class
1096
1097 Returns or sets the context class.
1098
1099 =head2 $c->counter
1100
1101 Returns a hashref containing coderefs and execution counts (needed for
1102 deep recursion detection).
1103
1104 =head2 $c->depth
1105
1106 Returns the number of actions on the current internal execution stack.
1107
1108 =head2 $c->dispatch
1109
1110 Dispatches a request to actions.
1111
1112 =cut
1113
1114 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1115
1116 =head2 $c->dispatcher_class
1117
1118 Returns or sets the dispatcher class.
1119
1120 =head2 $c->dump_these
1121
1122 Returns a list of 2-element array references (name, structure) pairs
1123 that will be dumped on the error page in debug mode.
1124
1125 =cut
1126
1127 sub dump_these {
1128     my $c = shift;
1129     [ Request => $c->req ],
1130     [ Response => $c->res ],
1131     [ Stash => $c->stash ],
1132     [ Config => $c->config ];
1133 }
1134
1135 =head2 $c->engine_class
1136
1137 Returns or sets the engine class.
1138
1139 =head2 $c->execute( $class, $coderef )
1140
1141 Execute a coderef in given class and catch exceptions. Errors are available
1142 via $c->error.
1143
1144 =cut
1145
1146 sub execute {
1147     my ( $c, $class, $code ) = @_;
1148     $class = $c->component($class) || $class;
1149     $c->state(0);
1150
1151     if ( $c->depth >= $RECURSION ) {
1152         my $action = "$code";
1153         $action = "/$action" unless $action =~ /->/;
1154         my $error = qq/Deep recursion detected calling "$action"/;
1155         $c->log->error($error);
1156         $c->error($error);
1157         $c->state(0);
1158         return $c->state;
1159     }
1160
1161     my $stats_info = $c->_stats_start_execute( $code ) if $c->debug;
1162
1163     push( @{ $c->stack }, $code );
1164
1165     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1166
1167     $c->_stats_finish_execute( $stats_info ) if $c->debug and $stats_info;
1168
1169     my $last = pop( @{ $c->stack } );
1170
1171     if ( my $error = $@ ) {
1172         if ( !ref($error) and $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1173         else {
1174             unless ( ref $error ) {
1175                 no warnings 'uninitialized';
1176                 chomp $error;
1177                 my $class = $last->class;
1178                 my $name  = $last->name;
1179                 $error = qq/Caught exception in $class->$name "$error"/;
1180             }
1181             $c->error($error);
1182             $c->state(0);
1183         }
1184     }
1185     return $c->state;
1186 }
1187
1188 sub _stats_start_execute {
1189     my ( $c, $code ) = @_;
1190
1191     return if ( ( $code->name =~ /^_.*/ )
1192         && ( !$c->config->{show_internal_actions} ) );
1193
1194     $c->counter->{"$code"}++;
1195
1196     my $action = "$code";
1197     $action = "/$action" unless $action =~ /->/;
1198
1199     # determine if the call was the result of a forward
1200     # this is done by walking up the call stack and looking for a calling
1201     # sub of Catalyst::forward before the eval
1202     my $callsub = q{};
1203     for my $index ( 2 .. 11 ) {
1204         last
1205         if ( ( caller($index) )[0] eq 'Catalyst'
1206             && ( caller($index) )[3] eq '(eval)' );
1207
1208         if ( ( caller($index) )[3] =~ /forward$/ ) {
1209             $callsub = ( caller($index) )[3];
1210             $action  = "-> $action";
1211             last;
1212         }
1213     }
1214
1215     my $node = Tree::Simple->new(
1216         {
1217             action  => $action,
1218             elapsed => undef,     # to be filled in later
1219             comment => "",
1220         }
1221     );
1222     $node->setUID( "$code" . $c->counter->{"$code"} );
1223
1224     # is this a root-level call or a forwarded call?
1225     if ( $callsub =~ /forward$/ ) {
1226
1227         # forward, locate the caller
1228         if ( my $parent = $c->stack->[-1] ) {
1229             my $visitor = Tree::Simple::Visitor::FindByUID->new;
1230             $visitor->searchForUID(
1231                 "$parent" . $c->counter->{"$parent"} );
1232             $c->stats->accept($visitor);
1233             if ( my $result = $visitor->getResult ) {
1234                 $result->addChild($node);
1235             }
1236         }
1237         else {
1238
1239             # forward with no caller may come from a plugin
1240             $c->stats->addChild($node);
1241         }
1242     }
1243     else {
1244
1245         # root-level call
1246         $c->stats->addChild($node);
1247     }
1248
1249     return {
1250         start   => [gettimeofday],
1251         node    => $node,
1252     };
1253 }
1254
1255 sub _stats_finish_execute {
1256     my ( $c, $info ) = @_;
1257     my $elapsed = tv_interval $info->{start};
1258     my $value = $info->{node}->getNodeValue;
1259     $value->{elapsed} = sprintf( '%fs', $elapsed );
1260 }
1261
1262 =head2 $c->_localize_fields( sub { }, \%keys );
1263
1264 =cut
1265
1266 sub _localize_fields {
1267     my ( $c, $localized, $code ) = ( @_ );
1268
1269     my $request = delete $localized->{request} || {};
1270     my $response = delete $localized->{response} || {};
1271
1272     local @{ $c }{ keys %$localized } = values %$localized;
1273     local @{ $c->request }{ keys %$request } = values %$request;
1274     local @{ $c->response }{ keys %$response } = values %$response;
1275
1276     $code->();
1277 }
1278
1279 =head2 $c->finalize
1280
1281 Finalizes the request.
1282
1283 =cut
1284
1285 sub finalize {
1286     my $c = shift;
1287
1288     for my $error ( @{ $c->error } ) {
1289         $c->log->error($error);
1290     }
1291
1292     # Allow engine to handle finalize flow (for POE)
1293     if ( $c->engine->can('finalize') ) {
1294         $c->engine->finalize($c);
1295     }
1296     else {
1297
1298         $c->finalize_uploads;
1299
1300         # Error
1301         if ( $#{ $c->error } >= 0 ) {
1302             $c->finalize_error;
1303         }
1304
1305         $c->finalize_headers;
1306
1307         # HEAD request
1308         if ( $c->request->method eq 'HEAD' ) {
1309             $c->response->body('');
1310         }
1311
1312         $c->finalize_body;
1313     }
1314
1315     return $c->response->status;
1316 }
1317
1318 =head2 $c->finalize_body
1319
1320 Finalizes body.
1321
1322 =cut
1323
1324 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1325
1326 =head2 $c->finalize_cookies
1327
1328 Finalizes cookies.
1329
1330 =cut
1331
1332 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1333
1334 =head2 $c->finalize_error
1335
1336 Finalizes error.
1337
1338 =cut
1339
1340 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1341
1342 =head2 $c->finalize_headers
1343
1344 Finalizes headers.
1345
1346 =cut
1347
1348 sub finalize_headers {
1349     my $c = shift;
1350
1351     # Check if we already finalized headers
1352     return if $c->response->{_finalized_headers};
1353
1354     # Handle redirects
1355     if ( my $location = $c->response->redirect ) {
1356         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1357         $c->response->header( Location => $location );
1358     }
1359
1360     # Content-Length
1361     if ( $c->response->body && !$c->response->content_length ) {
1362
1363         # get the length from a filehandle
1364         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1365         {
1366             if ( my $stat = stat $c->response->body ) {
1367                 $c->response->content_length( $stat->size );
1368             }
1369             else {
1370                 $c->log->warn('Serving filehandle without a content-length');
1371             }
1372         }
1373         else {
1374             $c->response->content_length( bytes::length( $c->response->body ) );
1375         }
1376     }
1377
1378     # Errors
1379     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1380         $c->response->headers->remove_header("Content-Length");
1381         $c->response->body('');
1382     }
1383
1384     $c->finalize_cookies;
1385
1386     $c->engine->finalize_headers( $c, @_ );
1387
1388     # Done
1389     $c->response->{_finalized_headers} = 1;
1390 }
1391
1392 =head2 $c->finalize_output
1393
1394 An alias for finalize_body.
1395
1396 =head2 $c->finalize_read
1397
1398 Finalizes the input after reading is complete.
1399
1400 =cut
1401
1402 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1403
1404 =head2 $c->finalize_uploads
1405
1406 Finalizes uploads. Cleans up any temporary files.
1407
1408 =cut
1409
1410 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1411
1412 =head2 $c->get_action( $action, $namespace )
1413
1414 Gets an action in a given namespace.
1415
1416 =cut
1417
1418 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1419
1420 =head2 $c->get_actions( $action, $namespace )
1421
1422 Gets all actions of a given name in a namespace and all parent
1423 namespaces.
1424
1425 =cut
1426
1427 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1428
1429 =head2 $c->handle_request( $class, @arguments )
1430
1431 Called to handle each HTTP request.
1432
1433 =cut
1434
1435 sub handle_request {
1436     my ( $class, @arguments ) = @_;
1437
1438     # Always expect worst case!
1439     my $status = -1;
1440     eval {
1441         if ($class->debug) {
1442             my $start = [gettimeofday];
1443             my $c = $class->prepare(@arguments);
1444             $c->stats(Tree::Simple->new);
1445             $c->dispatch;
1446             $status = $c->finalize;
1447
1448             my $elapsed = tv_interval $start;
1449             $elapsed = sprintf '%f', $elapsed;
1450             my $av = sprintf '%.3f',
1451               ( $elapsed == 0 ? '??' : ( 1 / $elapsed ) );
1452             my $t = Text::SimpleTable->new( [ 62, 'Action' ], [ 9, 'Time' ] );
1453
1454             $c->stats->traverse(
1455                 sub {
1456                     my $action = shift;
1457                     my $stat   = $action->getNodeValue;
1458                     $t->row( ( q{ } x $action->getDepth ) . $stat->{action} . $stat->{comment},
1459                         $stat->{elapsed} || '??' );
1460                 }
1461             );
1462
1463             $class->log->info(
1464                 "Request took ${elapsed}s ($av/s)\n" . $t->draw );
1465         }
1466         else {
1467             my $c = $class->prepare(@arguments);
1468             $c->dispatch;
1469             $status = $c->finalize;
1470         }
1471     };
1472
1473     if ( my $error = $@ ) {
1474         chomp $error;
1475         $class->log->error(qq/Caught exception in engine "$error"/);
1476     }
1477
1478     $COUNT++;
1479     $class->log->_flush() if $class->log->can('_flush');
1480     return $status;
1481 }
1482
1483 =head2 $c->prepare( @arguments )
1484
1485 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1486 etc.).
1487
1488 =cut
1489
1490 sub prepare {
1491     my ( $class, @arguments ) = @_;
1492
1493     $class->context_class( ref $class || $class ) unless $class->context_class;
1494     my $c = $class->context_class->new(
1495         {
1496             counter => {},
1497             stack   => [],
1498             request => $class->request_class->new(
1499                 {
1500                     arguments        => [],
1501                     body_parameters  => {},
1502                     cookies          => {},
1503                     headers          => HTTP::Headers->new,
1504                     parameters       => {},
1505                     query_parameters => {},
1506                     secure           => 0,
1507                     captures         => [],
1508                     uploads          => {}
1509                 }
1510             ),
1511             response => $class->response_class->new(
1512                 {
1513                     body    => '',
1514                     cookies => {},
1515                     headers => HTTP::Headers->new(),
1516                     status  => 200
1517                 }
1518             ),
1519             stash => {},
1520             state => 0
1521         }
1522     );
1523
1524     # For on-demand data
1525     $c->request->{_context}  = $c;
1526     $c->response->{_context} = $c;
1527     weaken( $c->request->{_context} );
1528     weaken( $c->response->{_context} );
1529
1530     if ( $c->debug ) {
1531         my $secs = time - $START || 1;
1532         my $av = sprintf '%.3f', $COUNT / $secs;
1533         my $time = localtime time;
1534         $c->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1535         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1536     }
1537
1538     # Allow engine to direct the prepare flow (for POE)
1539     if ( $c->engine->can('prepare') ) {
1540         $c->engine->prepare( $c, @arguments );
1541     }
1542     else {
1543         $c->prepare_request(@arguments);
1544         $c->prepare_connection;
1545         $c->prepare_query_parameters;
1546         $c->prepare_headers;
1547         $c->prepare_cookies;
1548         $c->prepare_path;
1549
1550         # On-demand parsing
1551         $c->prepare_body unless $c->config->{parse_on_demand};
1552     }
1553
1554     my $method  = $c->req->method  || '';
1555     my $path    = $c->req->path    || '/';
1556     my $address = $c->req->address || '';
1557
1558     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1559       if $c->debug;
1560
1561     $c->prepare_action;
1562
1563     return $c;
1564 }
1565
1566 =head2 $c->prepare_action
1567
1568 Prepares action. See L<Catalyst::Dispatcher>.
1569
1570 =cut
1571
1572 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1573
1574 =head2 $c->prepare_body
1575
1576 Prepares message body.
1577
1578 =cut
1579
1580 sub prepare_body {
1581     my $c = shift;
1582
1583     # Do we run for the first time?
1584     return if defined $c->request->{_body};
1585
1586     # Initialize on-demand data
1587     $c->engine->prepare_body( $c, @_ );
1588     $c->prepare_parameters;
1589     $c->prepare_uploads;
1590
1591     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1592         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1593         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1594             my $param = $c->req->body_parameters->{$key};
1595             my $value = defined($param) ? $param : '';
1596             $t->row( $key,
1597                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1598         }
1599         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1600     }
1601 }
1602
1603 =head2 $c->prepare_body_chunk( $chunk )
1604
1605 Prepares a chunk of data before sending it to L<HTTP::Body>.
1606
1607 See L<Catalyst::Engine>.
1608
1609 =cut
1610
1611 sub prepare_body_chunk {
1612     my $c = shift;
1613     $c->engine->prepare_body_chunk( $c, @_ );
1614 }
1615
1616 =head2 $c->prepare_body_parameters
1617
1618 Prepares body parameters.
1619
1620 =cut
1621
1622 sub prepare_body_parameters {
1623     my $c = shift;
1624     $c->engine->prepare_body_parameters( $c, @_ );
1625 }
1626
1627 =head2 $c->prepare_connection
1628
1629 Prepares connection.
1630
1631 =cut
1632
1633 sub prepare_connection {
1634     my $c = shift;
1635     $c->engine->prepare_connection( $c, @_ );
1636 }
1637
1638 =head2 $c->prepare_cookies
1639
1640 Prepares cookies.
1641
1642 =cut
1643
1644 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1645
1646 =head2 $c->prepare_headers
1647
1648 Prepares headers.
1649
1650 =cut
1651
1652 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1653
1654 =head2 $c->prepare_parameters
1655
1656 Prepares parameters.
1657
1658 =cut
1659
1660 sub prepare_parameters {
1661     my $c = shift;
1662     $c->prepare_body_parameters;
1663     $c->engine->prepare_parameters( $c, @_ );
1664 }
1665
1666 =head2 $c->prepare_path
1667
1668 Prepares path and base.
1669
1670 =cut
1671
1672 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1673
1674 =head2 $c->prepare_query_parameters
1675
1676 Prepares query parameters.
1677
1678 =cut
1679
1680 sub prepare_query_parameters {
1681     my $c = shift;
1682
1683     $c->engine->prepare_query_parameters( $c, @_ );
1684
1685     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1686         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1687         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1688             my $param = $c->req->query_parameters->{$key};
1689             my $value = defined($param) ? $param : '';
1690             $t->row( $key,
1691                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1692         }
1693         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1694     }
1695 }
1696
1697 =head2 $c->prepare_read
1698
1699 Prepares the input for reading.
1700
1701 =cut
1702
1703 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1704
1705 =head2 $c->prepare_request
1706
1707 Prepares the engine request.
1708
1709 =cut
1710
1711 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1712
1713 =head2 $c->prepare_uploads
1714
1715 Prepares uploads.
1716
1717 =cut
1718
1719 sub prepare_uploads {
1720     my $c = shift;
1721
1722     $c->engine->prepare_uploads( $c, @_ );
1723
1724     if ( $c->debug && keys %{ $c->request->uploads } ) {
1725         my $t = Text::SimpleTable->new(
1726             [ 12, 'Parameter' ],
1727             [ 26, 'Filename' ],
1728             [ 18, 'Type' ],
1729             [ 9,  'Size' ]
1730         );
1731         for my $key ( sort keys %{ $c->request->uploads } ) {
1732             my $upload = $c->request->uploads->{$key};
1733             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1734                 $t->row( $key, $u->filename, $u->type, $u->size );
1735             }
1736         }
1737         $c->log->debug( "File Uploads are:\n" . $t->draw );
1738     }
1739 }
1740
1741 =head2 $c->prepare_write
1742
1743 Prepares the output for writing.
1744
1745 =cut
1746
1747 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1748
1749 =head2 $c->request_class
1750
1751 Returns or sets the request class.
1752
1753 =head2 $c->response_class
1754
1755 Returns or sets the response class.
1756
1757 =head2 $c->read( [$maxlength] )
1758
1759 Reads a chunk of data from the request body. This method is designed to
1760 be used in a while loop, reading C<$maxlength> bytes on every call.
1761 C<$maxlength> defaults to the size of the request if not specified.
1762
1763 You have to set C<MyApp-E<gt>config-E<gt>{parse_on_demand}> to use this
1764 directly.
1765
1766 =cut
1767
1768 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1769
1770 =head2 $c->run
1771
1772 Starts the engine.
1773
1774 =cut
1775
1776 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1777
1778 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1779
1780 Sets an action in a given namespace.
1781
1782 =cut
1783
1784 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1785
1786 =head2 $c->setup_actions($component)
1787
1788 Sets up actions for a component.
1789
1790 =cut
1791
1792 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1793
1794 =head2 $c->setup_components
1795
1796 Sets up components. Specify a C<setup_components> config option to pass
1797 additional options directly to L<Module::Pluggable>. To add additional
1798 search paths, specify a key named C<search_extra> as an array
1799 reference. Items in the array beginning with C<::> will have the
1800 application class name prepended to them.
1801
1802 =cut
1803
1804 sub setup_components {
1805     my $class = shift;
1806
1807     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1808     my $config  = $class->config->{ setup_components };
1809     my $extra   = delete $config->{ search_extra } || [];
1810
1811     push @paths, @$extra;
1812
1813     my $locator = Module::Pluggable::Object->new(
1814         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1815         %$config
1816     );
1817
1818     for my $component ( sort { length $a <=> length $b } $locator->plugins ) {
1819         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1820
1821         my $module  = $class->setup_component( $component );
1822         my %modules = (
1823             $component => $module,
1824             map {
1825                 $_ => $class->setup_component( $_ )
1826             } Devel::InnerPackage::list_packages( $component )
1827         );
1828
1829         for my $key ( keys %modules ) {
1830             $class->components->{ $key } = $modules{ $key };
1831         }
1832     }
1833 }
1834
1835 =head2 $c->setup_component
1836
1837 =cut
1838
1839 sub setup_component {
1840     my( $class, $component ) = @_;
1841
1842     unless ( $component->can( 'COMPONENT' ) ) {
1843         return $component;
1844     }
1845
1846     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1847     my $config = $class->config->{ $suffix } || {};
1848
1849     my $instance = eval { $component->COMPONENT( $class, $config ); };
1850
1851     if ( my $error = $@ ) {
1852         chomp $error;
1853         Catalyst::Exception->throw(
1854             message => qq/Couldn't instantiate component "$component", "$error"/
1855         );
1856     }
1857
1858     Catalyst::Exception->throw(
1859         message =>
1860         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1861     ) unless eval { $instance->can( 'can' ) };
1862
1863     return $instance;
1864 }
1865
1866 =head2 $c->setup_dispatcher
1867
1868 Sets up dispatcher.
1869
1870 =cut
1871
1872 sub setup_dispatcher {
1873     my ( $class, $dispatcher ) = @_;
1874
1875     if ($dispatcher) {
1876         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1877     }
1878
1879     if ( $ENV{CATALYST_DISPATCHER} ) {
1880         $dispatcher = 'Catalyst::Dispatcher::' . $ENV{CATALYST_DISPATCHER};
1881     }
1882
1883     if ( $ENV{ uc($class) . '_DISPATCHER' } ) {
1884         $dispatcher =
1885           'Catalyst::Dispatcher::' . $ENV{ uc($class) . '_DISPATCHER' };
1886     }
1887
1888     unless ($dispatcher) {
1889         $dispatcher = $class->dispatcher_class;
1890     }
1891
1892     unless (Class::Inspector->loaded($dispatcher)) {
1893         require Class::Inspector->filename($dispatcher);
1894     }
1895
1896     # dispatcher instance
1897     $class->dispatcher( $dispatcher->new );
1898 }
1899
1900 =head2 $c->setup_engine
1901
1902 Sets up engine.
1903
1904 =cut
1905
1906 sub setup_engine {
1907     my ( $class, $engine ) = @_;
1908
1909     if ($engine) {
1910         $engine = 'Catalyst::Engine::' . $engine;
1911     }
1912
1913     if ( $ENV{CATALYST_ENGINE} ) {
1914         $engine = 'Catalyst::Engine::' . $ENV{CATALYST_ENGINE};
1915     }
1916
1917     if ( $ENV{ uc($class) . '_ENGINE' } ) {
1918         $engine = 'Catalyst::Engine::' . $ENV{ uc($class) . '_ENGINE' };
1919     }
1920
1921     if ( $ENV{MOD_PERL} ) {
1922
1923         # create the apache method
1924         {
1925             no strict 'refs';
1926             *{"$class\::apache"} = sub { shift->engine->apache };
1927         }
1928
1929         my ( $software, $version ) =
1930           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1931
1932         $version =~ s/_//g;
1933         $version =~ s/(\.[^.]+)\./$1/g;
1934
1935         if ( $software eq 'mod_perl' ) {
1936
1937             if ( !$engine ) {
1938
1939                 if ( $version >= 1.99922 ) {
1940                     $engine = 'Catalyst::Engine::Apache2::MP20';
1941                 }
1942
1943                 elsif ( $version >= 1.9901 ) {
1944                     $engine = 'Catalyst::Engine::Apache2::MP19';
1945                 }
1946
1947                 elsif ( $version >= 1.24 ) {
1948                     $engine = 'Catalyst::Engine::Apache::MP13';
1949                 }
1950
1951                 else {
1952                     Catalyst::Exception->throw( message =>
1953                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
1954                 }
1955
1956             }
1957
1958             # install the correct mod_perl handler
1959             if ( $version >= 1.9901 ) {
1960                 *handler = sub  : method {
1961                     shift->handle_request(@_);
1962                 };
1963             }
1964             else {
1965                 *handler = sub ($$) { shift->handle_request(@_) };
1966             }
1967
1968         }
1969
1970         elsif ( $software eq 'Zeus-Perl' ) {
1971             $engine = 'Catalyst::Engine::Zeus';
1972         }
1973
1974         else {
1975             Catalyst::Exception->throw(
1976                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
1977         }
1978     }
1979
1980     unless ($engine) {
1981         $engine = $class->engine_class;
1982     }
1983
1984     unless (Class::Inspector->loaded($engine)) {
1985         require Class::Inspector->filename($engine);
1986     }
1987
1988     # check for old engines that are no longer compatible
1989     my $old_engine;
1990     if ( $engine->isa('Catalyst::Engine::Apache')
1991         && !Catalyst::Engine::Apache->VERSION )
1992     {
1993         $old_engine = 1;
1994     }
1995
1996     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
1997         && Catalyst::Engine::Server->VERSION le '0.02' )
1998     {
1999         $old_engine = 1;
2000     }
2001
2002     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2003         && $engine->VERSION eq '0.01' )
2004     {
2005         $old_engine = 1;
2006     }
2007
2008     elsif ($engine->isa('Catalyst::Engine::Zeus')
2009         && $engine->VERSION eq '0.01' )
2010     {
2011         $old_engine = 1;
2012     }
2013
2014     if ($old_engine) {
2015         Catalyst::Exception->throw( message =>
2016               qq/Engine "$engine" is not supported by this version of Catalyst/
2017         );
2018     }
2019
2020     # engine instance
2021     $class->engine( $engine->new );
2022 }
2023
2024 =head2 $c->setup_home
2025
2026 Sets up the home directory.
2027
2028 =cut
2029
2030 sub setup_home {
2031     my ( $class, $home ) = @_;
2032
2033     if ( $ENV{CATALYST_HOME} ) {
2034         $home = $ENV{CATALYST_HOME};
2035     }
2036
2037     if ( $ENV{ uc($class) . '_HOME' } ) {
2038         $home = $ENV{ uc($class) . '_HOME' };
2039     }
2040
2041     unless ($home) {
2042         $home = Catalyst::Utils::home($class);
2043     }
2044
2045     if ($home) {
2046         $class->config->{home} ||= $home;
2047         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2048     }
2049 }
2050
2051 =head2 $c->setup_log
2052
2053 Sets up log.
2054
2055 =cut
2056
2057 sub setup_log {
2058     my ( $class, $debug ) = @_;
2059
2060     unless ( $class->log ) {
2061         $class->log( Catalyst::Log->new );
2062     }
2063
2064     my $app_flag = Catalyst::Utils::class2env($class) . '_DEBUG';
2065
2066     if (
2067           ( defined( $ENV{CATALYST_DEBUG} ) || defined( $ENV{$app_flag} ) )
2068         ? ( $ENV{CATALYST_DEBUG} || $ENV{$app_flag} )
2069         : $debug
2070       )
2071     {
2072         no strict 'refs';
2073         *{"$class\::debug"} = sub { 1 };
2074         $class->log->debug('Debug messages enabled');
2075     }
2076 }
2077
2078 =head2 $c->setup_plugins
2079
2080 Sets up plugins.
2081
2082 =cut
2083
2084 =head2 $c->registered_plugins
2085
2086 Returns a sorted list of the plugins which have either been stated in the
2087 import list or which have been added via C<< MyApp->plugin(@args); >>.
2088
2089 If passed a given plugin name, it will report a boolean value indicating
2090 whether or not that plugin is loaded.  A fully qualified name is required if
2091 the plugin name does not begin with C<Catalyst::Plugin::>.
2092
2093  if ($c->registered_plugins('Some::Plugin')) {
2094      ...
2095  }
2096
2097 =cut
2098
2099 {
2100
2101     sub registered_plugins {
2102         my $proto = shift;
2103         return sort keys %{ $proto->_plugins } unless @_;
2104         my $plugin = shift;
2105         return 1 if exists $proto->_plugins->{$plugin};
2106         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2107     }
2108
2109     sub _register_plugin {
2110         my ( $proto, $plugin, $instant ) = @_;
2111         my $class = ref $proto || $proto;
2112
2113         unless (Class::Inspector->loaded($plugin)) {
2114             require Class::Inspector->filename($plugin);
2115         }
2116
2117         $proto->_plugins->{$plugin} = 1;
2118         unless ($instant) {
2119             no strict 'refs';
2120             unshift @{"$class\::ISA"}, $plugin;
2121         }
2122         return $class;
2123     }
2124
2125     sub setup_plugins {
2126         my ( $class, $plugins ) = @_;
2127
2128         $class->_plugins( {} ) unless $class->_plugins;
2129         $plugins ||= [];
2130         for my $plugin ( reverse @$plugins ) {
2131
2132             unless ( $plugin =~ s/\A\+// ) {
2133                 $plugin = "Catalyst::Plugin::$plugin";
2134             }
2135
2136             $class->_register_plugin($plugin);
2137         }
2138     }
2139 }
2140
2141 =head2 $c->stack
2142
2143 Returns an arrayref of the internal execution stack (actions that are
2144 currently executing).
2145
2146 =head2 $c->write( $data )
2147
2148 Writes $data to the output stream. When using this method directly, you
2149 will need to manually set the C<Content-Length> header to the length of
2150 your output data, if known.
2151
2152 =cut
2153
2154 sub write {
2155     my $c = shift;
2156
2157     # Finalize headers if someone manually writes output
2158     $c->finalize_headers;
2159
2160     return $c->engine->write( $c, @_ );
2161 }
2162
2163 =head2 version
2164
2165 Returns the Catalyst version number. Mostly useful for "powered by"
2166 messages in template systems.
2167
2168 =cut
2169
2170 sub version { return $Catalyst::VERSION }
2171
2172 =head1 INTERNAL ACTIONS
2173
2174 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2175 C<_ACTION>, and C<_END>. These are by default not shown in the private
2176 action table, but you can make them visible with a config parameter.
2177
2178     MyApp->config->{show_internal_actions} = 1;
2179
2180 =head1 CASE SENSITIVITY
2181
2182 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2183 mapped to C</foo/bar>. You can activate case sensitivity with a config
2184 parameter.
2185
2186     MyApp->config->{case_sensitive} = 1;
2187
2188 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2189
2190 =head1 ON-DEMAND PARSER
2191
2192 The request body is usually parsed at the beginning of a request,
2193 but if you want to handle input yourself or speed things up a bit,
2194 you can enable on-demand parsing with a config parameter.
2195
2196     MyApp->config->{parse_on_demand} = 1;
2197
2198 =head1 PROXY SUPPORT
2199
2200 Many production servers operate using the common double-server approach,
2201 with a lightweight frontend web server passing requests to a larger
2202 backend server. An application running on the backend server must deal
2203 with two problems: the remote user always appears to be C<127.0.0.1> and
2204 the server's hostname will appear to be C<localhost> regardless of the
2205 virtual host that the user connected through.
2206
2207 Catalyst will automatically detect this situation when you are running
2208 the frontend and backend servers on the same machine. The following
2209 changes are made to the request.
2210
2211     $c->req->address is set to the user's real IP address, as read from
2212     the HTTP X-Forwarded-For header.
2213
2214     The host value for $c->req->base and $c->req->uri is set to the real
2215     host, as read from the HTTP X-Forwarded-Host header.
2216
2217 Obviously, your web server must support these headers for this to work.
2218
2219 In a more complex server farm environment where you may have your
2220 frontend proxy server(s) on different machines, you will need to set a
2221 configuration option to tell Catalyst to read the proxied data from the
2222 headers.
2223
2224     MyApp->config->{using_frontend_proxy} = 1;
2225
2226 If you do not wish to use the proxy support at all, you may set:
2227
2228     MyApp->config->{ignore_frontend_proxy} = 1;
2229
2230 =head1 THREAD SAFETY
2231
2232 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2233 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2234 believe the Catalyst core to be thread-safe.
2235
2236 If you plan to operate in a threaded environment, remember that all other
2237 modules you are using must also be thread-safe. Some modules, most notably
2238 L<DBD::SQLite>, are not thread-safe.
2239
2240 =head1 SUPPORT
2241
2242 IRC:
2243
2244     Join #catalyst on irc.perl.org.
2245
2246 Mailing Lists:
2247
2248     http://lists.rawmode.org/mailman/listinfo/catalyst
2249     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2250
2251 Web:
2252
2253     http://catalyst.perl.org
2254
2255 Wiki:
2256
2257     http://dev.catalyst.perl.org
2258
2259 =head1 SEE ALSO
2260
2261 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2262
2263 =head2 L<Catalyst::Manual> - The Catalyst Manual
2264
2265 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2266
2267 =head2 L<Catalyst::Engine> - Core engine
2268
2269 =head2 L<Catalyst::Log> - Log class.
2270
2271 =head2 L<Catalyst::Request> - Request object
2272
2273 =head2 L<Catalyst::Response> - Response object
2274
2275 =head2 L<Catalyst::Test> - The test suite.
2276
2277 =head1 CREDITS
2278
2279 Andy Grundman
2280
2281 Andy Wardley
2282
2283 Andreas Marienborg
2284
2285 Andrew Bramble
2286
2287 Andrew Ford
2288
2289 Andrew Ruthven
2290
2291 Arthur Bergman
2292
2293 Autrijus Tang
2294
2295 Brian Cassidy
2296
2297 Carl Franks
2298
2299 Christian Hansen
2300
2301 Christopher Hicks
2302
2303 Dan Sully
2304
2305 Danijel Milicevic
2306
2307 David Kamholz
2308
2309 David Naughton
2310
2311 Drew Taylor
2312
2313 Gary Ashton Jones
2314
2315 Geoff Richards
2316
2317 Jesse Sheidlower
2318
2319 Jesse Vincent
2320
2321 Jody Belka
2322
2323 Johan Lindstrom
2324
2325 Juan Camacho
2326
2327 Leon Brocard
2328
2329 Marcus Ramberg
2330
2331 Matt S Trout
2332
2333 Robert Sedlacek
2334
2335 Sam Vilain
2336
2337 Sascha Kiefer
2338
2339 Tatsuhiko Miyagawa
2340
2341 Ulf Edvinsson
2342
2343 Yuval Kogman
2344
2345 =head1 AUTHOR
2346
2347 Sebastian Riedel, C<sri@oook.de>
2348
2349 =head1 LICENSE
2350
2351 This library is free software, you can redistribute it and/or modify it under
2352 the same terms as Perl itself.
2353
2354 =cut
2355
2356 1;