lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use File::stat;
  19 use Text::SimpleTable ();
  20 use Path::Class::Dir ();
  21 use Path::Class::File ();
  22 use URI ();
  23 use URI::http;
  24 use URI::https;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use Class::C3::Adopt::NEXT;
  28 use List::MoreUtils qw/uniq/;
  29 use attributes;
  30 use String::RewritePrefix;
  31 use Catalyst::EngineLoader;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34 use Try::Tiny;
  35 use Plack::Middleware::Conditional;
  36 use Plack::Middleware::ReverseProxy;
  37 use Plack::Middleware::IIS6ScriptNameFix;
  38 use Plack::Middleware::LighttpdScriptNameFix;
  39
  40 BEGIN { require 5.008003; }
  41
  42 has stack => (is => 'ro', default => sub { [] });
  43 has stash => (is => 'rw', default => sub { {} });
  44 has state => (is => 'rw', default => 0);
  45 has stats => (is => 'rw');
  46 has action => (is => 'rw');
  47 has counter => (is => 'rw', default => sub { {} });
  48 has request => (
  49     is => 'rw',
  50     default => sub {
  51         my $self = shift;
  52         my %p = ( _log => $self->log );
  53         $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  54         $self->request_class->new(\%p);
  55     },
  56     lazy => 1,
  57 );
  58 has response => (
  59     is => 'rw',
  60     default => sub {
  61         my $self = shift;
  62         $self->response_class->new({ _log => $self->log });
  63     },
  64     lazy => 1,
  65 );
  66 has namespace => (is => 'rw');
  67
  68 sub depth { scalar @{ shift->stack || [] }; }
  69 sub comp { shift->component(@_) }
  70
  71 sub req {
  72     my $self = shift; return $self->request(@_);
  73 }
  74 sub res {
  75     my $self = shift; return $self->response(@_);
  76 }
  77
  78 # For backwards compatibility
  79 sub finalize_output { shift->finalize_body(@_) };
  80
  81 # For statistics
  82 our $COUNT     = 1;
  83 our $START     = time;
  84 our $RECURSION = 1000;
  85 our $DETACH    = Catalyst::Exception::Detach->new;
  86 our $GO        = Catalyst::Exception::Go->new;
  87
  88 #I imagine that very few of these really need to be class variables. if any.
  89 #maybe we should just make them attributes with a default?
  90 __PACKAGE__->mk_classdata($_)
  91   for qw/container arguments dispatcher engine log dispatcher_class
  92   engine_loader context_class request_class response_class stats_class
  93   setup_finished _psgi_app loading_psgi_file run_options/;
  94
  95 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  96 __PACKAGE__->request_class('Catalyst::Request');
  97 __PACKAGE__->response_class('Catalyst::Response');
  98 __PACKAGE__->stats_class('Catalyst::Stats');
  99
 100 # Remember to update this in Catalyst::Runtime as well!
 101
 102 our $VERSION = '5.90011';
 103
 104 sub import {
 105     my ( $class, @arguments ) = @_;
 106
 107     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 108     # callers @ISA.
 109     return unless $class eq 'Catalyst';
 110
 111     my $caller = caller();
 112     return if $caller eq 'main';
 113
 114     my $meta = Moose::Meta::Class->initialize($caller);
 115
 116     unless ( $caller->isa('Catalyst') ) { # XXX - Remove!
 117         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Component'); # XXX - Remove!
 118         $meta->superclasses(@superclasses); # XXX - Remove!
 119     } # XXX - Remove!
 120
 121     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 122     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 123
 124     unless( $meta->has_method('meta') ){
 125         if ($Moose::VERSION >= 1.15) {
 126             $meta->_add_meta_method('meta');
 127         }
 128         else {
 129             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 130         }
 131     }
 132
 133     $caller->arguments( [@arguments] );
 134     $caller->setup_home;
 135 }
 136
 137 sub MODIFY_CODE_ATTRIBUTES {
 138     Catalyst::Exception->throw(
 139         "Catalyst applications (aka MyApp) cannot be controllers anymore. " .
 140         "That has been deprecated and removed. You should create a " .
 141         "controller class called Root.pm, and move relevant code to that class."
 142     );
 143 }
 144
 145
 146 sub _application { $_[0] }
 147
 148 =head1 NAME
 149
 150 Catalyst - The Elegant MVC Web Application Framework
 151
 152 =head1 SYNOPSIS
 153
 154 See the L<Catalyst::Manual> distribution for comprehensive
 155 documentation and tutorials.
 156
 157     # Install Catalyst::Devel for helpers and other development tools
 158     # use the helper to create a new application
 159     catalyst.pl MyApp
 160
 161     # add models, views, controllers
 162     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 163     script/myapp_create.pl view MyTemplate TT
 164     script/myapp_create.pl controller Search
 165
 166     # built in testserver -- use -r to restart automatically on changes
 167     # --help to see all available options
 168     script/myapp_server.pl
 169
 170     # command line testing interface
 171     script/myapp_test.pl /yada
 172
 173     ### in lib/MyApp.pm
 174     use Catalyst qw/-Debug/; # include plugins here as well
 175
 176     ### In lib/MyApp/Controller/Root.pm (autocreated)
 177     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 178         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 179         $c->stash->{template} = 'foo.tt'; # set the template
 180         # lookup something from db -- stash vars are passed to TT
 181         $c->stash->{data} =
 182           $c->model('Database::Foo')->search( { country => $args[0] } );
 183         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 184             $c->forward( 'bar' ); # process another action
 185             # do something else after forward returns
 186         }
 187     }
 188
 189     # The foo.tt TT template can use the stash data from the database
 190     [% WHILE (item = data.next) %]
 191         [% item.foo %]
 192     [% END %]
 193
 194     # called for /bar/of/soap, /bar/of/soap/10, etc.
 195     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 196
 197     # called after all actions are finished
 198     sub end : Action {
 199         my ( $self, $c ) = @_;
 200         if ( scalar @{ $c->error } ) { ... } # handle errors
 201         return if $c->res->body; # already have a response
 202         $c->forward( 'MyApp::View::TT' ); # render template
 203     }
 204
 205 See L<Catalyst::Manual::Intro> for additional information.
 206
 207 =head1 DESCRIPTION
 208
 209 Catalyst is a modern framework for making web applications without the
 210 pain usually associated with this process. This document is a reference
 211 to the main Catalyst application. If you are a new user, we suggest you
 212 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 213
 214 See L<Catalyst::Manual> for more documentation.
 215
 216 Catalyst plugins can be loaded by naming them as arguments to the "use
 217 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 218 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 219 C<My::Module>.
 220
 221     use Catalyst qw/My::Module/;
 222
 223 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 224 fully qualify the name by using a unary plus:
 225
 226     use Catalyst qw/
 227         My::Module
 228         +Fully::Qualified::Plugin::Name
 229     /;
 230
 231 Special flags like C<-Debug> can also be specified as
 232 arguments when Catalyst is loaded:
 233
 234     use Catalyst qw/-Debug My::Module/;
 235
 236 The position of plugins and flags in the chain is important, because
 237 they are loaded in the order in which they appear.
 238
 239 The following flags are supported:
 240
 241 =head2 -Debug
 242
 243 Enables debug output. You can also force this setting from the system
 244 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 245 settings override the application, with <MYAPP>_DEBUG having the highest
 246 priority.
 247
 248 This sets the log level to 'debug' and enables full debug output on the
 249 error screen. If you only want the latter, see L<< $c->debug >>.
 250
 251 =head2 -Home
 252
 253 Forces Catalyst to use a specific home directory, e.g.:
 254
 255     use Catalyst qw[-Home=/usr/mst];
 256
 257 This can also be done in the shell environment by setting either the
 258 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 259 is replaced with the uppercased name of your application, any "::" in
 260 the name will be replaced with underscores, e.g. MyApp::Web should use
 261 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 262
 263 If none of these are set, Catalyst will attempt to automatically detect the
 264 home directory. If you are working in a development environment, Catalyst
 265 will try and find the directory containing either Makefile.PL, Build.PL or
 266 dist.ini. If the application has been installed into the system (i.e.
 267 you have done C<make install>), then Catalyst will use the path to your
 268 application module, without the .pm extension (e.g., /foo/MyApp if your
 269 application was installed at /foo/MyApp.pm)
 270
 271 =head2 -Log
 272
 273     use Catalyst '-Log=warn,fatal,error';
 274
 275 Specifies a comma-delimited list of log levels.
 276
 277 =head2 -Stats
 278
 279 Enables statistics collection and reporting.
 280
 281    use Catalyst qw/-Stats=1/;
 282
 283 You can also force this setting from the system environment with CATALYST_STATS
 284 or <MYAPP>_STATS. The environment settings override the application, with
 285 <MYAPP>_STATS having the highest priority.
 286
 287 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 288
 289 =head1 METHODS
 290
 291 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 292
 293 =head2 $c->action
 294
 295 Returns a L<Catalyst::Action> object for the current action, which
 296 stringifies to the action name. See L<Catalyst::Action>.
 297
 298 =head2 $c->namespace
 299
 300 Returns the namespace of the current action, i.e., the URI prefix
 301 corresponding to the controller of the current action. For example:
 302
 303     # in Controller::Foo::Bar
 304     $c->namespace; # returns 'foo/bar';
 305
 306 =head2 $c->request
 307
 308 =head2 $c->req
 309
 310 Returns the current L<Catalyst::Request> object, giving access to
 311 information about the current client request (including parameters,
 312 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 313
 314 =head2 REQUEST FLOW HANDLING
 315
 316 =head2 $c->forward( $action [, \@arguments ] )
 317
 318 =head2 $c->forward( $class, $method, [, \@arguments ] )
 319
 320 Forwards processing to another action, by its private name. If you give a
 321 class name but no method, C<process()> is called. You may also optionally
 322 pass arguments in an arrayref. The action will receive the arguments in
 323 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 324 C<< $c->req->args >> will be restored to the previous values.
 325
 326 Any data C<return>ed from the action forwarded to, will be returned by the
 327 call to forward.
 328
 329     my $foodata = $c->forward('/foo');
 330     $c->forward('index');
 331     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 332     $c->forward('View::TT');
 333
 334 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 335 an C<< eval { } >> around the call (actually
 336 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 337 exceptions thrown by the called action non-fatal and pushing them onto
 338 $c->error instead. If you want C<die> to propagate you need to do something
 339 like:
 340
 341     $c->forward('foo');
 342     die join "\n", @{ $c->error } if @{ $c->error };
 343
 344 Or make sure to always return true values from your actions and write
 345 your code like this:
 346
 347     $c->forward('foo') || return;
 348
 349 Another note is that C<< $c->forward >> always returns a scalar because it
 350 actually returns $c->state which operates in a scalar context.
 351 Thus, something like:
 352
 353     return @array;
 354
 355 in an action that is forwarded to is going to return a scalar,
 356 i.e. how many items are in that array, which is probably not what you want.
 357 If you need to return an array then return a reference to it,
 358 or stash it like so:
 359
 360     $c->stash->{array} = \@array;
 361
 362 and access it from the stash.
 363
 364 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 365
 366 =cut
 367
 368 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 369
 370 =head2 $c->detach( $action [, \@arguments ] )
 371
 372 =head2 $c->detach( $class, $method, [, \@arguments ] )
 373
 374 =head2 $c->detach()
 375
 376 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 377 doesn't return to the previous action when processing is finished.
 378
 379 When called with no arguments it escapes the processing chain entirely.
 380
 381 =cut
 382
 383 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 384
 385 =head2 $c->visit( $action [, \@arguments ] )
 386
 387 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 388
 389 =head2 $c->visit( $class, $method, [, \@arguments ] )
 390
 391 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 392
 393 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 394 but does a full dispatch, instead of just calling the new C<$action> /
 395 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 396 you go to are called, just like a new request.
 397
 398 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 399 This means, for example, that C<< $c->action >> methods such as
 400 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 401 L<reverse|Catalyst::Action/reverse> return information for the visited action
 402 when they are invoked within the visited action.  This is different from the
 403 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 404 continues to use the $c->action object from the caller action even when
 405 invoked from the called action.
 406
 407 C<< $c->stash >> is kept unchanged.
 408
 409 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 410 allows you to "wrap" another action, just as it would have been called by
 411 dispatching from a URL, while the analogous
 412 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 413 transfer control to another action as if it had been reached directly from a URL.
 414
 415 =cut
 416
 417 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 418
 419 =head2 $c->go( $action [, \@arguments ] )
 420
 421 =head2 $c->go( $action [, \@captures, \@arguments ] )
 422
 423 =head2 $c->go( $class, $method, [, \@arguments ] )
 424
 425 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 426
 427 The relationship between C<go> and
 428 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 429 the relationship between
 430 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 431 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 432 C<< $c->go >> will perform a full dispatch on the specified action or method,
 433 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 434 C<go> escapes the processing of the current request chain on completion, and
 435 does not return to its caller.
 436
 437 @arguments are arguments to the final destination of $action. @captures are
 438 arguments to the intermediate steps, if any, on the way to the final sub of
 439 $action.
 440
 441 =cut
 442
 443 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 444
 445 =head2 $c->response
 446
 447 =head2 $c->res
 448
 449 Returns the current L<Catalyst::Response> object, see there for details.
 450
 451 =head2 $c->stash
 452
 453 Returns a hashref to the stash, which may be used to store data and pass
 454 it between components during a request. You can also set hash keys by
 455 passing arguments. The stash is automatically sent to the view. The
 456 stash is cleared at the end of a request; it cannot be used for
 457 persistent storage (for this you must use a session; see
 458 L<Catalyst::Plugin::Session> for a complete system integrated with
 459 Catalyst).
 460
 461     $c->stash->{foo} = $bar;
 462     $c->stash( { moose => 'majestic', qux => 0 } );
 463     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 464
 465     # stash is automatically passed to the view for use in a template
 466     $c->forward( 'MyApp::View::TT' );
 467
 468 =cut
 469
 470 around stash => sub {
 471     my $orig = shift;
 472     my $c = shift;
 473     my $stash = $orig->($c);
 474     if (@_) {
 475         my $new_stash = @_ > 1 ? {@_} : $_[0];
 476         croak('stash takes a hash or hashref') unless ref $new_stash;
 477         foreach my $key ( keys %$new_stash ) {
 478           $stash->{$key} = $new_stash->{$key};
 479         }
 480     }
 481
 482     return $stash;
 483 };
 484
 485
 486 =head2 $c->error
 487
 488 =head2 $c->error($error, ...)
 489
 490 =head2 $c->error($arrayref)
 491
 492 Returns an arrayref containing error messages.  If Catalyst encounters an
 493 error while processing a request, it stores the error in $c->error.  This
 494 method should only be used to store fatal error messages.
 495
 496     my @error = @{ $c->error };
 497
 498 Add a new error.
 499
 500     $c->error('Something bad happened');
 501
 502 =cut
 503
 504 sub error {
 505     my $c = shift;
 506     if ( $_[0] ) {
 507         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 508         croak @$error unless ref $c;
 509         push @{ $c->{error} }, @$error;
 510     }
 511     elsif ( defined $_[0] ) { $c->{error} = undef }
 512     return $c->{error} || [];
 513 }
 514
 515
 516 =head2 $c->state
 517
 518 Contains the return value of the last executed action.
 519 Note that << $c->state >> operates in a scalar context which means that all
 520 values it returns are scalar.
 521
 522 =head2 $c->clear_errors
 523
 524 Clear errors.  You probably don't want to clear the errors unless you are
 525 implementing a custom error screen.
 526
 527 This is equivalent to running
 528
 529     $c->error(0);
 530
 531 =cut
 532
 533 sub clear_errors {
 534     my $c = shift;
 535     $c->error(0);
 536 }
 537
 538 =head2 COMPONENT ACCESSORS
 539
 540 =head2 $c->controller($name)
 541
 542 Gets a L<Catalyst::Controller> instance by name.
 543
 544     $c->controller('Foo')->do_stuff;
 545
 546 If the name is omitted, will return the controller for the dispatched
 547 action.
 548
 549 If you want to search for controllers, pass in a regexp as the argument.
 550
 551     # find all controllers that start with Foo
 552     my @foo_controllers = $c->controller(qr{^Foo});
 553
 554
 555 =cut
 556
 557 sub controller { shift->_lookup_mvc('controller', @_) }
 558
 559 =head2 $c->model($name)
 560
 561 Gets a L<Catalyst::Model> instance by name.
 562
 563     $c->model('Foo')->do_stuff;
 564
 565 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 566
 567 If the name is omitted, it will look for
 568  - a model object in $c->stash->{current_model_instance}, then
 569  - a model name in $c->stash->{current_model}, then
 570  - a config setting 'default_model', or
 571  - check if there is only one model, and return it if that's the case.
 572
 573 If you want to search for models, pass in a regexp as the argument.
 574
 575     # find all models that start with Foo
 576     my @foo_models = $c->model(qr{^Foo});
 577
 578 =cut
 579
 580 sub model { shift->_lookup_mvc('model', @_) }
 581
 582 =head2 $c->view($name)
 583
 584 Gets a L<Catalyst::View> instance by name.
 585
 586     $c->view('Foo')->do_stuff;
 587
 588 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 589
 590 If the name is omitted, it will look for
 591  - a view object in $c->stash->{current_view_instance}, then
 592  - a view name in $c->stash->{current_view}, then
 593  - a config setting 'default_view', or
 594  - check if there is only one view, and return it if that's the case.
 595
 596 If you want to search for views, pass in a regexp as the argument.
 597
 598     # find all views that start with Foo
 599     my @foo_views = $c->view(qr{^Foo});
 600
 601 =cut
 602
 603 sub view { shift->_lookup_mvc('view', @_) }
 604
 605 sub _lookup_mvc {
 606     my ( $c, $type, $name, @args ) = @_;
 607
 608     if (ref $c && !$name) {
 609         my $current_instance = $c->stash->{"current_${type}_instance"};
 610         return $current_instance
 611             if $current_instance && $type ne 'controller';
 612
 613         $name = $type eq 'controller'
 614               ? Catalyst::Utils::class2classshortsuffix($c->action->class)
 615               : $c->stash->{"current_${type}"}
 616               ;
 617     }
 618
 619     return $c->container->get_component_from_sub_container($type, $name, $c, @args);
 620 }
 621
 622 =head2 $c->controllers
 623
 624 Returns the available names which can be passed to $c->controller
 625
 626 =cut
 627
 628 sub controllers {
 629     my ( $c ) = @_;
 630     return $c->container->get_sub_container('controller')->get_service_list;
 631 }
 632
 633 =head2 $c->models
 634
 635 Returns the available names which can be passed to $c->model
 636
 637 =cut
 638
 639 sub models {
 640     my ( $c ) = @_;
 641     return $c->container->get_sub_container('model')->get_service_list;
 642 }
 643
 644
 645 =head2 $c->views
 646
 647 Returns the available names which can be passed to $c->view
 648
 649 =cut
 650
 651 sub views {
 652     my ( $c ) = @_;
 653     return $c->container->get_sub_container('view')->get_service_list;
 654 }
 655
 656 =head2 $c->comp($name)
 657
 658 =head2 $c->component($name)
 659
 660 Gets a component object by name. This method is not recommended,
 661 unless you want to get a specific component by full
 662 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 663 should be used instead.
 664
 665 If C<$name> is a regexp, a list of components matched against the full
 666 component name will be returned.
 667
 668 =cut
 669
 670 sub component {
 671     my ( $c, $component, @args ) = @_;
 672
 673     unless ($component) {
 674         $c->log->warn('Calling $c->component with no args is deprecated and ');
 675         $c->log->warn('will be removed in a future release.');
 676         $c->log->warn('Use $c->component_list instead.');
 677         return $c->component_list;
 678     }
 679
 680     my @result = $c->container->find_component( $component, $c, @args );
 681
 682     # list context for regexp searches
 683     return @result if ref $component;
 684
 685     # only one component (if it's found) for string searches
 686     return shift @result if @result;
 687
 688     if (ref $c eq $component) {
 689         $c->log->warn('You are calling $c->comp("MyApp"). This behaviour is');
 690         $c->log->warn('deprecated, and will be removed in a future release.');
 691         return $c;
 692     }
 693
 694     $c->log->warn("Looking for '$component', but nothing was found.");
 695
 696     # I would expect to return an empty list here, but that breaks back-compat
 697     $c->log->warn('Component not found, returning the list of existing');
 698     $c->log->warn('components. This behavior is deprecated and will be');
 699     $c->log->warn('removed in a future release. Use $c->component_list');
 700     $c->log->warn('instead.');
 701
 702     return $c->component_list;
 703 }
 704
 705 =head2 $c->component_list
 706
 707 Returns the sorted list of the component names of the application.
 708
 709 =cut
 710
 711 sub component_list { sort keys %{ shift->components } }
 712
 713 =head2 CLASS DATA AND HELPER CLASSES
 714
 715 =head2 $c->config
 716
 717 Returns or takes a hashref containing the application's configuration.
 718
 719     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 720
 721 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 722 like C<myapp.conf> in your applications home directory. See
 723 L<Catalyst::Plugin::ConfigLoader>.
 724
 725 =head3 Cascading configuration
 726
 727 The config method is present on all Catalyst components, and configuration
 728 will be merged when an application is started. Configuration loaded with
 729 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 730 followed by configuration in your top level C<MyApp> class. These two
 731 configurations are merged, and then configuration data whose hash key matches a
 732 component name is merged with configuration for that component.
 733
 734 The configuration for a component is then passed to the C<new> method when a
 735 component is constructed.
 736
 737 For example:
 738
 739     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 740     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 741
 742 will mean that C<MyApp::Model::Foo> receives the following data when
 743 constructed:
 744
 745     MyApp::Model::Foo->new({
 746         bar => 'baz',
 747         quux => 'frob',
 748         overrides => 'me',
 749     });
 750
 751 It's common practice to use a Moose attribute
 752 on the receiving component to access the config value.
 753
 754     package MyApp::Model::Foo;
 755
 756     use Moose;
 757
 758     # this attr will receive 'baz' at construction time
 759     has 'bar' => (
 760         is  => 'rw',
 761         isa => 'Str',
 762     );
 763
 764 You can then get the value 'baz' by calling $c->model('Foo')->bar
 765 (or $self->bar inside code in the model).
 766
 767 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 768 as a way of reading config within your code, as this B<will not> give you the
 769 correctly merged config back. You B<MUST> take the config values supplied to
 770 the constructor and use those instead.
 771
 772 =cut
 773
 774 around config => sub {
 775     my $orig = shift;
 776     my $c = shift;
 777
 778     croak('Setting config after setup has been run is not allowed.')
 779         if ( @_ and $c->setup_finished );
 780
 781     $c->$orig(@_);
 782 };
 783
 784 =head2 $c->log
 785
 786 Returns the logging object instance. Unless it is already set, Catalyst
 787 sets this up with a L<Catalyst::Log> object. To use your own log class,
 788 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 789 C<< __PACKAGE__->setup >>.
 790
 791  __PACKAGE__->log( MyLogger->new );
 792  __PACKAGE__->setup;
 793
 794 And later:
 795
 796     $c->log->info( 'Now logging with my own logger!' );
 797
 798 Your log class should implement the methods described in
 799 L<Catalyst::Log>.
 800
 801
 802 =head2 $c->debug
 803
 804 Returns 1 if debug mode is enabled, 0 otherwise.
 805
 806 You can enable debug mode in several ways:
 807
 808 =over
 809
 810 =item By calling myapp_server.pl with the -d flag
 811
 812 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 813
 814 =item The -Debug option in your MyApp.pm
 815
 816 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 817
 818 =back
 819
 820 The first three also set the log level to 'debug'.
 821
 822 Calling C<< $c->debug(1) >> has no effect.
 823
 824 =cut
 825
 826 sub debug { 0 }
 827
 828 =head2 $c->dispatcher
 829
 830 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 831
 832 =head2 $c->engine
 833
 834 Returns the engine instance. See L<Catalyst::Engine>.
 835
 836
 837 =head2 UTILITY METHODS
 838
 839 =head2 $c->path_to(@path)
 840
 841 Merges C<@path> with C<< $c->config->{home} >> and returns a
 842 L<Path::Class::Dir> object. Note you can usually use this object as
 843 a filename, but sometimes you will have to explicitly stringify it
 844 yourself by calling the C<< ->stringify >> method.
 845
 846 For example:
 847
 848     $c->path_to( 'db', 'sqlite.db' );
 849
 850 =cut
 851
 852 sub path_to {
 853     my ( $c, @path ) = @_;
 854     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 855     if ( -d $path ) { return $path }
 856     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 857 }
 858
 859 sub plugin {
 860     my ( $class, $name, $plugin, @args ) = @_;
 861
 862     # See block comment in t/aggregate/unit_core_plugin.t
 863     # See block comment in t/unit_core_plugin.t
 864     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
 865
 866     $class->_register_plugin( $plugin, 1 );
 867
 868     eval { $plugin->import };
 869     $class->mk_classdata($name);
 870     my $obj;
 871     eval { $obj = $plugin->new(@args) };
 872
 873     if ($@) {
 874         Catalyst::Exception->throw( message =>
 875               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 876     }
 877
 878     $class->$name($obj);
 879     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 880       if $class->debug;
 881 }
 882
 883 =head2 MyApp->setup
 884
 885 Initializes the dispatcher and engine, loads any plugins, and loads the
 886 model, view, and controller components. You may also specify an array
 887 of plugins to load here, if you choose to not load them in the C<use
 888 Catalyst> line.
 889
 890     MyApp->setup;
 891     MyApp->setup( qw/-Debug/ );
 892
 893 B<Note:> You B<should not> wrap this method with method modifiers
 894 or bad things will happen - wrap the C<setup_finalize> method instead.
 895
 896 =cut
 897
 898 sub setup {
 899     my ( $class, @arguments ) = @_;
 900     croak('Running setup more than once')
 901         if ( $class->setup_finished );
 902
 903     unless ( $class->isa('Catalyst') ) {
 904
 905         Catalyst::Exception->throw(
 906             message => qq/'$class' does not inherit from Catalyst/ );
 907     }
 908
 909     if ( $class->arguments ) {
 910         @arguments = ( @arguments, @{ $class->arguments } );
 911     }
 912
 913     # Process options
 914     my $flags = {};
 915
 916     foreach (@arguments) {
 917
 918         if (/^-Debug$/) {
 919             $flags->{log} =
 920               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 921         }
 922         elsif (/^-(\w+)=?(.*)$/) {
 923             $flags->{ lc $1 } = $2;
 924         }
 925         else {
 926             push @{ $flags->{plugins} }, $_;
 927         }
 928     }
 929
 930     $class->setup_config();
 931     $class->setup_home( delete $flags->{home} );
 932
 933     $class->setup_log( delete $flags->{log} );
 934     $class->setup_plugins( delete $flags->{plugins} );
 935     $class->setup_dispatcher( delete $flags->{dispatcher} );
 936     if (my $engine = delete $flags->{engine}) {
 937         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
 938     }
 939     $class->setup_engine();
 940     $class->setup_stats( delete $flags->{stats} );
 941
 942     for my $flag ( sort keys %{$flags} ) {
 943
 944         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 945             &$code( $class, delete $flags->{$flag} );
 946         }
 947         else {
 948             $class->log->warn(qq/Unknown flag "$flag"/);
 949         }
 950     }
 951
 952     eval { require Catalyst::Devel; };
 953     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 954         $class->log->warn(<<"EOF");
 955 You are running an old script!
 956
 957   Please update by running (this will overwrite existing files):
 958     catalyst.pl -force -scripts $class
 959
 960   or (this will not overwrite existing files):
 961     catalyst.pl -scripts $class
 962
 963 EOF
 964     }
 965
 966     if ( $class->debug ) {
 967         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 968
 969         if (@plugins) {
 970             my $column_width = Catalyst::Utils::term_width() - 6;
 971             my $t = Text::SimpleTable->new($column_width);
 972             $t->row($_) for @plugins;
 973             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 974         }
 975
 976         my $dispatcher = $class->dispatcher;
 977         my $engine     = $class->engine;
 978         my $home       = $class->config->{home};
 979
 980         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
 981         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
 982
 983         $home
 984           ? ( -d $home )
 985           ? $class->log->debug(qq/Found home "$home"/)
 986           : $class->log->debug(qq/Home "$home" doesn't exist/)
 987           : $class->log->debug(q/Couldn't find home/);
 988     }
 989
 990     # Call plugins setup, this is stupid and evil.
 991     # Also screws C3 badly on 5.10, hack to avoid.
 992     {
 993         no warnings qw/redefine/;
 994         local *setup = sub { };
 995         $class->setup unless $Catalyst::__AM_RESTARTING;
 996     }
 997
 998     $class->setup_components;
 999
1000     if (
1001         $class->debug and
1002         my $comps = $class->container->get_all_components($class)
1003     ) {
1004         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1005         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1006         $t->row( $_ => ref($comps->{$_}) ? 'instance' : 'class' ) for keys %$comps;
1007
1008         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" );
1009     }
1010
1011     $class->setup_actions;
1012
1013     if ( $class->debug ) {
1014         my $name = $class->config->{name} || 'Application';
1015         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1016     }
1017
1018     # Make sure that the application class becomes immutable at this point,
1019     B::Hooks::EndOfScope::on_scope_end {
1020         return if $@;
1021         my $meta = Class::MOP::get_metaclass_by_name($class);
1022         if (
1023             $meta->is_immutable
1024             && ! { $meta->immutable_options }->{replace_constructor}
1025             && (
1026                    $class->isa('Class::Accessor::Fast')
1027                 || $class->isa('Class::Accessor')
1028             )
1029         ) {
1030             warn "You made your application class ($class) immutable, "
1031                 . "but did not inline the\nconstructor. "
1032                 . "This will break catalyst, as your app \@ISA "
1033                 . "Class::Accessor(::Fast)?\nPlease pass "
1034                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1035         }
1036         $meta->make_immutable(
1037             replace_constructor => 1,
1038         ) unless $meta->is_immutable;
1039     };
1040
1041     if ($class->config->{case_sensitive}) {
1042         $class->log->warn($class . "->config->{case_sensitive} is set.");
1043         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1044     }
1045
1046     $class->setup_finalize;
1047     # Should be the last thing we do so that user things hooking
1048     # setup_finalize can log..
1049     $class->log->_flush() if $class->log->can('_flush');
1050     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1051 }
1052
1053 =head2 $app->setup_finalize
1054
1055 A hook to attach modifiers to. This method does not do anything except set the
1056 C<setup_finished> accessor.
1057
1058 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1059
1060 Example:
1061
1062     after setup_finalize => sub {
1063         my $app = shift;
1064
1065         ## do stuff here..
1066     };
1067
1068 =cut
1069
1070 sub setup_finalize {
1071     my ($class) = @_;
1072     $class->setup_finished(1);
1073 }
1074
1075 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1076
1077 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1078
1079 Constructs an absolute L<URI> object based on the application root, the
1080 provided path, and the additional arguments and query parameters provided.
1081 When used as a string, provides a textual URI.  If you need more flexibility
1082 than this (i.e. the option to provide relative URIs etc.) see
1083 L<Catalyst::Plugin::SmartURI>.
1084
1085 If no arguments are provided, the URI for the current action is returned.
1086 To return the current action and also provide @args, use
1087 C<< $c->uri_for( $c->action, @args ) >>.
1088
1089 If the first argument is a string, it is taken as a public URI path relative
1090 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1091 relative to the application root (if it does). It is then merged with
1092 C<< $c->request->base >>; any C<@args> are appended as additional path
1093 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1094
1095 If the first argument is a L<Catalyst::Action> it represents an action which
1096 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1097 optional C<\@captures> argument (an arrayref) allows passing the captured
1098 variables that are needed to fill in the paths of Chained and Regex actions;
1099 once the path is resolved, C<uri_for> continues as though a path was
1100 provided, appending any arguments or parameters and creating an absolute
1101 URI.
1102
1103 The captures for the current request can be found in
1104 C<< $c->request->captures >>, and actions can be resolved using
1105 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1106 path, use C<< $c->uri_for_action >> instead.
1107
1108   # Equivalent to $c->req->uri
1109   $c->uri_for($c->action, $c->req->captures,
1110       @{ $c->req->args }, $c->req->params);
1111
1112   # For the Foo action in the Bar controller
1113   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1114
1115   # Path to a static resource
1116   $c->uri_for('/static/images/logo.png');
1117
1118 =cut
1119
1120 sub uri_for {
1121     my ( $c, $path, @args ) = @_;
1122
1123     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1124         $path = $path->path_prefix;
1125         $path =~ s{/+\z}{};
1126         $path .= '/';
1127     }
1128
1129     undef($path) if (defined $path && $path eq '');
1130
1131     my $params =
1132       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1133
1134     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1135     foreach my $arg (@args) {
1136         utf8::encode($arg) if utf8::is_utf8($arg);
1137         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1138     }
1139
1140     if ( blessed($path) ) { # action object
1141         s|/|%2F|g for @args;
1142         my $captures = [ map { s|/|%2F|g; $_; }
1143                         ( scalar @args && ref $args[0] eq 'ARRAY'
1144                          ? @{ shift(@args) }
1145                          : ()) ];
1146
1147         foreach my $capture (@$captures) {
1148             utf8::encode($capture) if utf8::is_utf8($capture);
1149             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1150         }
1151
1152         my $action = $path;
1153         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1154         if( !@args && $action->number_of_args ) {
1155             my $expanded_action = $c->dispatcher->expand_action( $action );
1156
1157             my $num_captures = $expanded_action->number_of_captures;
1158             unshift @args, splice @$captures, $num_captures;
1159         }
1160
1161        $path = $c->dispatcher->uri_for_action($action, $captures);
1162         if (not defined $path) {
1163             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1164                 if $c->debug;
1165             return undef;
1166         }
1167         $path = '/' if $path eq '';
1168     }
1169
1170     unshift(@args, $path);
1171
1172     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1173         my $namespace = $c->namespace;
1174         if (defined $path) { # cheesy hack to handle path '../foo'
1175            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1176         }
1177         unshift(@args, $namespace || '');
1178     }
1179
1180     # join args with '/', or a blank string
1181     my $args = join('/', grep { defined($_) } @args);
1182     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1183     $args =~ s!^/+!!;
1184     my $base = $c->req->base;
1185     my $class = ref($base);
1186     $base =~ s{(?<!/)$}{/};
1187
1188     my $query = '';
1189
1190     if (my @keys = keys %$params) {
1191       # somewhat lifted from URI::_query's query_form
1192       $query = '?'.join('&', map {
1193           my $val = $params->{$_};
1194           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1195           s/ /+/g;
1196           my $key = $_;
1197           $val = '' unless defined $val;
1198           (map {
1199               my $param = "$_";
1200               utf8::encode( $param ) if utf8::is_utf8($param);
1201               # using the URI::Escape pattern here so utf8 chars survive
1202               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1203               $param =~ s/ /+/g;
1204               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1205       } @keys);
1206     }
1207
1208     my $res = bless(\"${base}${args}${query}", $class);
1209     $res;
1210 }
1211
1212 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1213
1214 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1215
1216 =over
1217
1218 =item $path
1219
1220 A private path to the Catalyst action you want to create a URI for.
1221
1222 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1223 >> and passing the resulting C<$action> and the remaining arguments to C<<
1224 $c->uri_for >>.
1225
1226 You can also pass in a Catalyst::Action object, in which case it is passed to
1227 C<< $c->uri_for >>.
1228
1229 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1230
1231 For example, if the action looks like:
1232
1233  package MyApp::Controller::Users;
1234
1235  sub lst : Path('the-list') {}
1236
1237 You can use:
1238
1239  $c->uri_for_action('/users/lst')
1240
1241 and it will create the URI /users/the-list.
1242
1243 =item \@captures_and_args?
1244
1245 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1246 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1247 to interpolate all the parameters in the URI.
1248
1249 =item @args?
1250
1251 Optional list of extra arguments - can be supplied in the
1252 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1253 code.
1254
1255 Your action can have zero, a fixed or a variable number of args (e.g.
1256 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1257
1258 =item \%query_values?
1259
1260 Optional array reference of query parameters to append. E.g.
1261
1262   { foo => 'bar' }
1263
1264 will generate
1265
1266   /rest/of/your/uri?foo=bar
1267
1268 =back
1269
1270 =cut
1271
1272 sub uri_for_action {
1273     my ( $c, $path, @args ) = @_;
1274     my $action = blessed($path)
1275       ? $path
1276       : $c->dispatcher->get_action_by_path($path);
1277     unless (defined $action) {
1278       croak "Can't find action for path '$path'";
1279     }
1280     return $c->uri_for( $action, @args );
1281 }
1282
1283 =head2 $c->welcome_message
1284
1285 Returns the Catalyst welcome HTML page.
1286
1287 =cut
1288
1289 sub welcome_message {
1290     my $c      = shift;
1291     my $name   = $c->config->{name};
1292     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1293     my $prefix = Catalyst::Utils::appprefix( ref $c );
1294     $c->response->content_type('text/html; charset=utf-8');
1295     return <<"EOF";
1296 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1297     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1298 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1299     <head>
1300     <meta http-equiv="Content-Language" content="en" />
1301     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1302         <title>$name on Catalyst $VERSION</title>
1303         <style type="text/css">
1304             body {
1305                 color: #000;
1306                 background-color: #eee;
1307             }
1308             div#content {
1309                 width: 640px;
1310                 margin-left: auto;
1311                 margin-right: auto;
1312                 margin-top: 10px;
1313                 margin-bottom: 10px;
1314                 text-align: left;
1315                 background-color: #ccc;
1316                 border: 1px solid #aaa;
1317             }
1318             p, h1, h2 {
1319                 margin-left: 20px;
1320                 margin-right: 20px;
1321                 font-family: verdana, tahoma, sans-serif;
1322             }
1323             a {
1324                 font-family: verdana, tahoma, sans-serif;
1325             }
1326             :link, :visited {
1327                     text-decoration: none;
1328                     color: #b00;
1329                     border-bottom: 1px dotted #bbb;
1330             }
1331             :link:hover, :visited:hover {
1332                     color: #555;
1333             }
1334             div#topbar {
1335                 margin: 0px;
1336             }
1337             pre {
1338                 margin: 10px;
1339                 padding: 8px;
1340             }
1341             div#answers {
1342                 padding: 8px;
1343                 margin: 10px;
1344                 background-color: #fff;
1345                 border: 1px solid #aaa;
1346             }
1347             h1 {
1348                 font-size: 0.9em;
1349                 font-weight: normal;
1350                 text-align: center;
1351             }
1352             h2 {
1353                 font-size: 1.0em;
1354             }
1355             p {
1356                 font-size: 0.9em;
1357             }
1358             p img {
1359                 float: right;
1360                 margin-left: 10px;
1361             }
1362             span#appname {
1363                 font-weight: bold;
1364                 font-size: 1.6em;
1365             }
1366         </style>
1367     </head>
1368     <body>
1369         <div id="content">
1370             <div id="topbar">
1371                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1372                     $VERSION</h1>
1373              </div>
1374              <div id="answers">
1375                  <p>
1376                  <img src="$logo" alt="Catalyst Logo" />
1377                  </p>
1378                  <p>Welcome to the  world of Catalyst.
1379                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1380                     framework will make web development something you had
1381                     never expected it to be: Fun, rewarding, and quick.</p>
1382                  <h2>What to do now?</h2>
1383                  <p>That really depends  on what <b>you</b> want to do.
1384                     We do, however, provide you with a few starting points.</p>
1385                  <p>If you want to jump right into web development with Catalyst
1386                     you might want to start with a tutorial.</p>
1387 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1388 </pre>
1389 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1390 <pre>
1391 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1392 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1393 </code></pre>
1394                  <h2>What to do next?</h2>
1395                  <p>Next it's time to write an actual application. Use the
1396                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1397                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1398                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1399                     they can save you a lot of work.</p>
1400                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1401                     <p>Also, be sure to check out the vast and growing
1402                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1403                     you are likely to find what you need there.
1404                     </p>
1405
1406                  <h2>Need help?</h2>
1407                  <p>Catalyst has a very active community. Here are the main places to
1408                     get in touch with us.</p>
1409                  <ul>
1410                      <li>
1411                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1412                      </li>
1413                      <li>
1414                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1415                      </li>
1416                      <li>
1417                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1418                      </li>
1419                  </ul>
1420                  <h2>In conclusion</h2>
1421                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1422                     as we enjoyed making it. Please contact us if you have ideas
1423                     for improvement or other feedback.</p>
1424              </div>
1425          </div>
1426     </body>
1427 </html>
1428 EOF
1429 }
1430
1431 =head2 run_options
1432
1433 Contains a hash of options passed from the application script, including
1434 the original ARGV the script received, the processed values from that
1435 ARGV and any extra arguments to the script which were not processed.
1436
1437 This can be used to add custom options to your application's scripts
1438 and setup your application differently depending on the values of these
1439 options.
1440
1441 =head1 INTERNAL METHODS
1442
1443 These methods are not meant to be used by end users.
1444
1445 =head2 $c->components
1446
1447 Returns a hash of components.
1448
1449 =cut
1450
1451 sub components {
1452     my ( $class, $comps ) = @_;
1453
1454     # people create components calling this sub directly, before setup
1455     $class->setup_config unless $class->container;
1456
1457     my $container = $class->container;
1458
1459     if ( $comps ) {
1460         $container->add_component( $_ ) for keys %$comps;
1461     }
1462
1463     return $container->get_all_components($class);
1464 }
1465
1466 =head2 $c->context_class
1467
1468 Returns or sets the context class.
1469
1470 =head2 $c->counter
1471
1472 Returns a hashref containing coderefs and execution counts (needed for
1473 deep recursion detection).
1474
1475 =head2 $c->depth
1476
1477 Returns the number of actions on the current internal execution stack.
1478
1479 =head2 $c->dispatch
1480
1481 Dispatches a request to actions.
1482
1483 =cut
1484
1485 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1486
1487 =head2 $c->dispatcher_class
1488
1489 Returns or sets the dispatcher class.
1490
1491 =head2 $c->dump_these
1492
1493 Returns a list of 2-element array references (name, structure) pairs
1494 that will be dumped on the error page in debug mode.
1495
1496 =cut
1497
1498 sub dump_these {
1499     my $c = shift;
1500     [ Request => $c->req ],
1501     [ Response => $c->res ],
1502     [ Stash => $c->stash ],
1503     [ Config => $c->config ];
1504 }
1505
1506 =head2 $c->engine_class
1507
1508 Returns or sets the engine class.
1509
1510 =head2 $c->execute( $class, $coderef )
1511
1512 Execute a coderef in given class and catch exceptions. Errors are available
1513 via $c->error.
1514
1515 =cut
1516
1517 sub execute {
1518     my ( $c, $class, $code ) = @_;
1519     $class = $c->component($class) || $class;
1520     $c->state(0);
1521
1522     if ( $c->depth >= $RECURSION ) {
1523         my $action = $code->reverse();
1524         $action = "/$action" unless $action =~ /->/;
1525         my $error = qq/Deep recursion detected calling "${action}"/;
1526         $c->log->error($error);
1527         $c->error($error);
1528         $c->state(0);
1529         return $c->state;
1530     }
1531
1532     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1533
1534     push( @{ $c->stack }, $code );
1535
1536     no warnings 'recursion';
1537     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1538     #      I have no idea how, ergo $ret (which appears to fix the issue)
1539     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1540
1541     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1542
1543     my $last = pop( @{ $c->stack } );
1544
1545     if ( my $error = $@ ) {
1546         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1547             $error->rethrow if $c->depth > 1;
1548         }
1549         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1550             $error->rethrow if $c->depth > 0;
1551         }
1552         else {
1553             unless ( ref $error ) {
1554                 no warnings 'uninitialized';
1555                 chomp $error;
1556                 my $class = $last->class;
1557                 my $name  = $last->name;
1558                 $error = qq/Caught exception in $class->$name "$error"/;
1559             }
1560             $c->error($error);
1561         }
1562         $c->state(0);
1563     }
1564     return $c->state;
1565 }
1566
1567 sub _stats_start_execute {
1568     my ( $c, $code ) = @_;
1569     my $appclass = ref($c) || $c;
1570     return if ( ( $code->name =~ /^_.*/ )
1571         && ( !$appclass->config->{show_internal_actions} ) );
1572
1573     my $action_name = $code->reverse();
1574     $c->counter->{$action_name}++;
1575
1576     my $action = $action_name;
1577     $action = "/$action" unless $action =~ /->/;
1578
1579     # determine if the call was the result of a forward
1580     # this is done by walking up the call stack and looking for a calling
1581     # sub of Catalyst::forward before the eval
1582     my $callsub = q{};
1583     for my $index ( 2 .. 11 ) {
1584         last
1585         if ( ( caller($index) )[0] eq 'Catalyst'
1586             && ( caller($index) )[3] eq '(eval)' );
1587
1588         if ( ( caller($index) )[3] =~ /forward$/ ) {
1589             $callsub = ( caller($index) )[3];
1590             $action  = "-> $action";
1591             last;
1592         }
1593     }
1594
1595     my $uid = $action_name . $c->counter->{$action_name};
1596
1597     # is this a root-level call or a forwarded call?
1598     if ( $callsub =~ /forward$/ ) {
1599         my $parent = $c->stack->[-1];
1600
1601         # forward, locate the caller
1602         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1603             $c->stats->profile(
1604                 begin  => $action,
1605                 parent => "$parent" . $c->counter->{"$parent"},
1606                 uid    => $uid,
1607             );
1608         }
1609         else {
1610
1611             # forward with no caller may come from a plugin
1612             $c->stats->profile(
1613                 begin => $action,
1614                 uid   => $uid,
1615             );
1616         }
1617     }
1618     else {
1619
1620         # root-level call
1621         $c->stats->profile(
1622             begin => $action,
1623             uid   => $uid,
1624         );
1625     }
1626     return $action;
1627
1628 }
1629
1630 sub _stats_finish_execute {
1631     my ( $c, $info ) = @_;
1632     $c->stats->profile( end => $info );
1633 }
1634
1635 =head2 $c->finalize
1636
1637 Finalizes the request.
1638
1639 =cut
1640
1641 sub finalize {
1642     my $c = shift;
1643
1644     for my $error ( @{ $c->error } ) {
1645         $c->log->error($error);
1646     }
1647
1648     # Allow engine to handle finalize flow (for POE)
1649     my $engine = $c->engine;
1650     if ( my $code = $engine->can('finalize') ) {
1651         $engine->$code($c);
1652     }
1653     else {
1654
1655         $c->finalize_uploads;
1656
1657         # Error
1658         if ( $#{ $c->error } >= 0 ) {
1659             $c->finalize_error;
1660         }
1661
1662         $c->finalize_headers;
1663
1664         # HEAD request
1665         if ( $c->request->method eq 'HEAD' ) {
1666             $c->response->body('');
1667         }
1668
1669         $c->finalize_body;
1670     }
1671
1672     $c->log_response;
1673
1674     if ($c->use_stats) {
1675         my $elapsed = sprintf '%f', $c->stats->elapsed;
1676         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1677         $c->log->info(
1678             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1679     }
1680
1681     return $c->response->status;
1682 }
1683
1684 =head2 $c->finalize_body
1685
1686 Finalizes body.
1687
1688 =cut
1689
1690 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1691
1692 =head2 $c->finalize_cookies
1693
1694 Finalizes cookies.
1695
1696 =cut
1697
1698 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1699
1700 =head2 $c->finalize_error
1701
1702 Finalizes error.
1703
1704 =cut
1705
1706 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1707
1708 =head2 $c->finalize_headers
1709
1710 Finalizes headers.
1711
1712 =cut
1713
1714 sub finalize_headers {
1715     my $c = shift;
1716
1717     my $response = $c->response; #accessor calls can add up?
1718
1719     # Check if we already finalized headers
1720     return if $response->finalized_headers;
1721
1722     # Handle redirects
1723     if ( my $location = $response->redirect ) {
1724         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1725         $response->header( Location => $location );
1726
1727         if ( !$response->has_body ) {
1728             # Add a default body if none is already present
1729             $response->body(<<"EOF");
1730 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1731 <html xmlns="http://www.w3.org/1999/xhtml">
1732   <head>
1733     <title>Moved</title>
1734   </head>
1735   <body>
1736      <p>This item has moved <a href="$location">here</a>.</p>
1737   </body>
1738 </html>
1739 EOF
1740             $response->content_type('text/html; charset=utf-8');
1741         }
1742     }
1743
1744     # Content-Length
1745     if ( defined $response->body && length $response->body && !$response->content_length ) {
1746
1747         # get the length from a filehandle
1748         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1749         {
1750             my $size = -s $response->body;
1751             if ( $size ) {
1752                 $response->content_length( $size );
1753             }
1754             else {
1755                 $c->log->warn('Serving filehandle without a content-length');
1756             }
1757         }
1758         else {
1759             # everything should be bytes at this point, but just in case
1760             $response->content_length( length( $response->body ) );
1761         }
1762     }
1763
1764     # Errors
1765     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1766         $response->headers->remove_header("Content-Length");
1767         $response->body('');
1768     }
1769
1770     $c->finalize_cookies;
1771
1772     $c->engine->finalize_headers( $c, @_ );
1773
1774     # Done
1775     $response->finalized_headers(1);
1776 }
1777
1778 =head2 $c->finalize_output
1779
1780 An alias for finalize_body.
1781
1782 =head2 $c->finalize_read
1783
1784 Finalizes the input after reading is complete.
1785
1786 =cut
1787
1788 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1789
1790 =head2 $c->finalize_uploads
1791
1792 Finalizes uploads. Cleans up any temporary files.
1793
1794 =cut
1795
1796 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1797
1798 =head2 $c->get_action( $action, $namespace )
1799
1800 Gets an action in a given namespace.
1801
1802 =cut
1803
1804 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1805
1806 =head2 $c->get_actions( $action, $namespace )
1807
1808 Gets all actions of a given name in a namespace and all parent
1809 namespaces.
1810
1811 =cut
1812
1813 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1814
1815 =head2 $app->handle_request( @arguments )
1816
1817 Called to handle each HTTP request.
1818
1819 =cut
1820
1821 sub handle_request {
1822     my ( $class, @arguments ) = @_;
1823
1824     # Always expect worst case!
1825     my $status = -1;
1826     try {
1827         if ($class->debug) {
1828             my $secs = time - $START || 1;
1829             my $av = sprintf '%.3f', $COUNT / $secs;
1830             my $time = localtime time;
1831             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1832         }
1833
1834         my $c = $class->prepare(@arguments);
1835         $c->dispatch;
1836         $status = $c->finalize;
1837     }
1838     catch {
1839         chomp(my $error = $_);
1840         $class->log->error(qq/Caught exception in engine "$error"/);
1841     };
1842
1843     $COUNT++;
1844
1845     if(my $coderef = $class->log->can('_flush')){
1846         $class->log->$coderef();
1847     }
1848     return $status;
1849 }
1850
1851 =head2 $class->prepare( @arguments )
1852
1853 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1854 etc.).
1855
1856 =cut
1857
1858 has _uploadtmp => (
1859     is => 'ro',
1860     predicate => '_has_uploadtmp',
1861 );
1862
1863 sub prepare {
1864     my ( $class, @arguments ) = @_;
1865
1866     # XXX
1867     # After the app/ctxt split, this should become an attribute based on something passed
1868     # into the application.
1869     $class->context_class( ref $class || $class ) unless $class->context_class;
1870
1871     my $uploadtmp = $class->config->{uploadtmp};
1872     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
1873
1874     #surely this is not the most efficient way to do things...
1875     $c->stats($class->stats_class->new)->enable($c->use_stats);
1876     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1877         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1878     }
1879
1880     try {
1881         # Allow engine to direct the prepare flow (for POE)
1882         if ( my $prepare = $c->engine->can('prepare') ) {
1883             $c->engine->$prepare( $c, @arguments );
1884         }
1885         else {
1886             $c->prepare_request(@arguments);
1887             $c->prepare_connection;
1888             $c->prepare_query_parameters;
1889             $c->prepare_headers; # Just hooks, no longer needed - they just
1890             $c->prepare_cookies; # cause the lazy attribute on req to build
1891             $c->prepare_path;
1892
1893             # Prepare the body for reading, either by prepare_body
1894             # or the user, if they are using $c->read
1895             $c->prepare_read;
1896
1897             # Parse the body unless the user wants it on-demand
1898             unless ( ref($c)->config->{parse_on_demand} ) {
1899                 $c->prepare_body;
1900             }
1901         }
1902         $c->prepare_action;
1903     }
1904     # VERY ugly and probably shouldn't rely on ->finalize actually working
1905     catch {
1906         # failed prepare is always due to an invalid request, right?
1907         $c->response->status(400);
1908         $c->response->content_type('text/plain');
1909         $c->response->body('Bad Request');
1910         # Note we call finalize and then die here, which escapes
1911         # finalize being called in the enclosing block..
1912         # It in fact couldn't be called, as we don't return $c..
1913         # This is a mess - but I'm unsure you can fix this without
1914         # breaking compat for people doing crazy things (we should set
1915         # the 400 and just return the ctx here IMO, letting finalize get called
1916         # above...
1917         $c->finalize;
1918         die $_;
1919     };
1920
1921     $c->log_request;
1922
1923     return $c;
1924 }
1925
1926 =head2 $c->prepare_action
1927
1928 Prepares action. See L<Catalyst::Dispatcher>.
1929
1930 =cut
1931
1932 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1933
1934 =head2 $c->prepare_body
1935
1936 Prepares message body.
1937
1938 =cut
1939
1940 sub prepare_body {
1941     my $c = shift;
1942
1943     return if $c->request->_has_body;
1944
1945     # Initialize on-demand data
1946     $c->engine->prepare_body( $c, @_ );
1947     $c->prepare_parameters;
1948     $c->prepare_uploads;
1949 }
1950
1951 =head2 $c->prepare_body_chunk( $chunk )
1952
1953 Prepares a chunk of data before sending it to L<HTTP::Body>.
1954
1955 See L<Catalyst::Engine>.
1956
1957 =cut
1958
1959 sub prepare_body_chunk {
1960     my $c = shift;
1961     $c->engine->prepare_body_chunk( $c, @_ );
1962 }
1963
1964 =head2 $c->prepare_body_parameters
1965
1966 Prepares body parameters.
1967
1968 =cut
1969
1970 sub prepare_body_parameters {
1971     my $c = shift;
1972     $c->engine->prepare_body_parameters( $c, @_ );
1973 }
1974
1975 =head2 $c->prepare_connection
1976
1977 Prepares connection.
1978
1979 =cut
1980
1981 sub prepare_connection {
1982     my $c = shift;
1983     # XXX - This is called on the engine (not the request) to maintain
1984     #       Engine::PSGI back compat.
1985     $c->engine->prepare_connection($c);
1986 }
1987
1988 =head2 $c->prepare_cookies
1989
1990 Prepares cookies by ensuring that the attribute on the request
1991 object has been built.
1992
1993 =cut
1994
1995 sub prepare_cookies { my $c = shift; $c->request->cookies }
1996
1997 =head2 $c->prepare_headers
1998
1999 Prepares request headers by ensuring that the attribute on the request
2000 object has been built.
2001
2002 =cut
2003
2004 sub prepare_headers { my $c = shift; $c->request->headers }
2005
2006 =head2 $c->prepare_parameters
2007
2008 Prepares parameters.
2009
2010 =cut
2011
2012 sub prepare_parameters {
2013     my $c = shift;
2014     $c->prepare_body_parameters;
2015     $c->engine->prepare_parameters( $c, @_ );
2016 }
2017
2018 =head2 $c->prepare_path
2019
2020 Prepares path and base.
2021
2022 =cut
2023
2024 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2025
2026 =head2 $c->prepare_query_parameters
2027
2028 Prepares query parameters.
2029
2030 =cut
2031
2032 sub prepare_query_parameters {
2033     my $c = shift;
2034
2035     $c->engine->prepare_query_parameters( $c, @_ );
2036 }
2037
2038 =head2 $c->log_request
2039
2040 Writes information about the request to the debug logs.  This includes:
2041
2042 =over 4
2043
2044 =item * Request method, path, and remote IP address
2045
2046 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2047
2048 =item * Request parameters
2049
2050 =item * File uploads
2051
2052 =back
2053
2054 =cut
2055
2056 sub log_request {
2057     my $c = shift;
2058
2059     return unless $c->debug;
2060
2061     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2062     my $request = $dump->[1];
2063
2064     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2065     $method ||= '';
2066     $path = '/' unless length $path;
2067     $address ||= '';
2068     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2069
2070     $c->log_request_headers($request->headers);
2071
2072     if ( my $keywords = $request->query_keywords ) {
2073         $c->log->debug("Query keywords are: $keywords");
2074     }
2075
2076     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2077
2078     $c->log_request_uploads($request);
2079 }
2080
2081 =head2 $c->log_response
2082
2083 Writes information about the response to the debug logs by calling
2084 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2085
2086 =cut
2087
2088 sub log_response {
2089     my $c = shift;
2090
2091     return unless $c->debug;
2092
2093     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2094     my $response = $dump->[1];
2095
2096     $c->log_response_status_line($response);
2097     $c->log_response_headers($response->headers);
2098 }
2099
2100 =head2 $c->log_response_status_line($response)
2101
2102 Writes one line of information about the response to the debug logs.  This includes:
2103
2104 =over 4
2105
2106 =item * Response status code
2107
2108 =item * Content-Type header (if present)
2109
2110 =item * Content-Length header (if present)
2111
2112 =back
2113
2114 =cut
2115
2116 sub log_response_status_line {
2117     my ($c, $response) = @_;
2118
2119     $c->log->debug(
2120         sprintf(
2121             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2122             $response->status                            || 'unknown',
2123             $response->headers->header('Content-Type')   || 'unknown',
2124             $response->headers->header('Content-Length') || 'unknown'
2125         )
2126     );
2127 }
2128
2129 =head2 $c->log_response_headers($headers);
2130
2131 Hook method which can be wrapped by plugins to log the response headers.
2132 No-op in the default implementation.
2133
2134 =cut
2135
2136 sub log_response_headers {}
2137
2138 =head2 $c->log_request_parameters( query => {}, body => {} )
2139
2140 Logs request parameters to debug logs
2141
2142 =cut
2143
2144 sub log_request_parameters {
2145     my $c          = shift;
2146     my %all_params = @_;
2147
2148     return unless $c->debug;
2149
2150     my $column_width = Catalyst::Utils::term_width() - 44;
2151     foreach my $type (qw(query body)) {
2152         my $params = $all_params{$type};
2153         next if ! keys %$params;
2154         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2155         for my $key ( sort keys %$params ) {
2156             my $param = $params->{$key};
2157             my $value = defined($param) ? $param : '';
2158             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2159         }
2160         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2161     }
2162 }
2163
2164 =head2 $c->log_request_uploads
2165
2166 Logs file uploads included in the request to the debug logs.
2167 The parameter name, filename, file type, and file size are all included in
2168 the debug logs.
2169
2170 =cut
2171
2172 sub log_request_uploads {
2173     my $c = shift;
2174     my $request = shift;
2175     return unless $c->debug;
2176     my $uploads = $request->uploads;
2177     if ( keys %$uploads ) {
2178         my $t = Text::SimpleTable->new(
2179             [ 12, 'Parameter' ],
2180             [ 26, 'Filename' ],
2181             [ 18, 'Type' ],
2182             [ 9,  'Size' ]
2183         );
2184         for my $key ( sort keys %$uploads ) {
2185             my $upload = $uploads->{$key};
2186             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2187                 $t->row( $key, $u->filename, $u->type, $u->size );
2188             }
2189         }
2190         $c->log->debug( "File Uploads are:\n" . $t->draw );
2191     }
2192 }
2193
2194 =head2 $c->log_request_headers($headers);
2195
2196 Hook method which can be wrapped by plugins to log the request headers.
2197 No-op in the default implementation.
2198
2199 =cut
2200
2201 sub log_request_headers {}
2202
2203 =head2 $c->log_headers($type => $headers)
2204
2205 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2206
2207 =cut
2208
2209 sub log_headers {
2210     my $c       = shift;
2211     my $type    = shift;
2212     my $headers = shift;    # an HTTP::Headers instance
2213
2214     return unless $c->debug;
2215
2216     my $column_width = Catalyst::Utils::term_width() - 28;
2217     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2218     $headers->scan(
2219         sub {
2220             my ( $name, $value ) = @_;
2221             $t->row( $name, $value );
2222         }
2223     );
2224     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2225 }
2226
2227
2228 =head2 $c->prepare_read
2229
2230 Prepares the input for reading.
2231
2232 =cut
2233
2234 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2235
2236 =head2 $c->prepare_request
2237
2238 Prepares the engine request.
2239
2240 =cut
2241
2242 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2243
2244 =head2 $c->prepare_uploads
2245
2246 Prepares uploads.
2247
2248 =cut
2249
2250 sub prepare_uploads {
2251     my $c = shift;
2252
2253     $c->engine->prepare_uploads( $c, @_ );
2254 }
2255
2256 =head2 $c->prepare_write
2257
2258 Prepares the output for writing.
2259
2260 =cut
2261
2262 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2263
2264 =head2 $c->request_class
2265
2266 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2267
2268 =head2 $c->response_class
2269
2270 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2271
2272 =head2 $c->read( [$maxlength] )
2273
2274 Reads a chunk of data from the request body. This method is designed to
2275 be used in a while loop, reading C<$maxlength> bytes on every call.
2276 C<$maxlength> defaults to the size of the request if not specified.
2277
2278 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2279 directly.
2280
2281 Warning: If you use read(), Catalyst will not process the body,
2282 so you will not be able to access POST parameters or file uploads via
2283 $c->request.  You must handle all body parsing yourself.
2284
2285 =cut
2286
2287 sub read { my $c = shift; return $c->request->read( @_ ) }
2288
2289 =head2 $c->run
2290
2291 Starts the engine.
2292
2293 =cut
2294
2295 sub run {
2296   my $app = shift;
2297   $app->engine_loader->needs_psgi_engine_compat_hack ?
2298     $app->engine->run($app, @_) :
2299       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2300 }
2301
2302 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2303
2304 Sets an action in a given namespace.
2305
2306 =cut
2307
2308 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2309
2310 =head2 $c->setup_actions($component)
2311
2312 Sets up actions for a component.
2313
2314 =cut
2315
2316 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2317
2318 =head2 $c->setup_config
2319
2320 =cut
2321
2322 sub setup_config {
2323     my $class = shift;
2324
2325     my %args = %{ $class->config || {} };
2326
2327     my $container_class;
2328
2329     if ( exists $args{container_class} ) {
2330         $container_class = delete $args{container_class};
2331         Class::MOP::load_class($container_class);
2332     }
2333     else {
2334         $container_class = Class::MOP::load_first_existing_class("${class}::Container", 'Catalyst::IOC::Container');
2335     }
2336
2337     my $container = $container_class->new( %args, application_name => "$class", name => "$class" );
2338     $class->container($container);
2339
2340     my $config = $container->resolve( service => 'config' );
2341     $class->config($config);
2342     $class->finalize_config; # back-compat
2343 }
2344
2345 =head2 $c->finalize_config
2346
2347 =cut
2348
2349 sub finalize_config { }
2350
2351 =head2 $c->setup_components
2352
2353 This method is called internally to set up the application's components.
2354
2355 It finds modules by calling the L<locate_components> method, expands them to
2356 package names with the $container->expand_component_module method, and then
2357 installs each component into the application.
2358
2359 The C<setup_components> config option is passed to both of the above methods.
2360
2361 =cut
2362
2363 sub setup_components { shift->container->setup_components }
2364
2365 =head2 locate_components
2366
2367 =cut
2368
2369 sub locate_components {
2370     my $class = shift;
2371
2372     $class->log->warn('The locate_components method has been deprecated.');
2373     $class->log->warn('Please read Catalyst::IOC::Container documentation to');
2374     $class->log->warn('update your application.');
2375
2376     # XXX think about ditching this sort entirely
2377     return sort { length $a <=> length $b }
2378         @{ $class->container->resolve( service => 'locate_components' ) };
2379 }
2380
2381 =head2 $c->setup_dispatcher
2382
2383 Sets up dispatcher.
2384
2385 =cut
2386
2387 sub setup_dispatcher {
2388     my ( $class, $dispatcher ) = @_;
2389
2390     if ($dispatcher) {
2391         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2392     }
2393
2394     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2395         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2396     }
2397
2398     unless ($dispatcher) {
2399         $dispatcher = $class->dispatcher_class;
2400     }
2401
2402     Class::MOP::load_class($dispatcher);
2403
2404     # dispatcher instance
2405     $class->dispatcher( $dispatcher->new );
2406 }
2407
2408 =head2 $c->setup_engine
2409
2410 Sets up engine.
2411
2412 =cut
2413
2414 sub engine_class {
2415     my ($class, $requested_engine) = @_;
2416
2417     if (!$class->engine_loader || $requested_engine) {
2418         $class->engine_loader(
2419             Catalyst::EngineLoader->new({
2420                 application_name => $class,
2421                 (defined $requested_engine
2422                      ? (catalyst_engine_class => $requested_engine) : ()),
2423             }),
2424         );
2425     }
2426
2427     $class->engine_loader->catalyst_engine_class;
2428 }
2429
2430 sub setup_engine {
2431     my ($class, $requested_engine) = @_;
2432
2433     my $engine = do {
2434         my $loader = $class->engine_loader;
2435
2436         if (!$loader || $requested_engine) {
2437             $loader = Catalyst::EngineLoader->new({
2438                 application_name => $class,
2439                 (defined $requested_engine
2440                      ? (requested_engine => $requested_engine) : ()),
2441             }),
2442
2443             $class->engine_loader($loader);
2444         }
2445
2446         $loader->catalyst_engine_class;
2447     };
2448
2449     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2450     return if $class->loading_psgi_file;
2451
2452     Class::MOP::load_class($engine);
2453
2454     if ($ENV{MOD_PERL}) {
2455         my $apache = $class->engine_loader->auto;
2456
2457         my $meta = find_meta($class);
2458         my $was_immutable = $meta->is_immutable;
2459         my %immutable_options = $meta->immutable_options;
2460         $meta->make_mutable if $was_immutable;
2461
2462         $meta->add_method(handler => sub {
2463             my $r = shift;
2464             my $psgi_app = $class->_finalized_psgi_app;
2465             $apache->call_app($r, $psgi_app);
2466         });
2467
2468         $meta->make_immutable(%immutable_options) if $was_immutable;
2469     }
2470
2471     $class->engine( $engine->new );
2472
2473     return;
2474 }
2475
2476 sub _finalized_psgi_app {
2477     my ($app) = @_;
2478
2479     unless ($app->_psgi_app) {
2480         my $psgi_app = $app->_setup_psgi_app;
2481         $app->_psgi_app($psgi_app);
2482     }
2483
2484     return $app->_psgi_app;
2485 }
2486
2487 sub _setup_psgi_app {
2488     my ($app) = @_;
2489
2490     for my $home (Path::Class::Dir->new($app->config->{home})) {
2491         my $psgi_file = $home->file(
2492             Catalyst::Utils::appprefix($app) . '.psgi',
2493         );
2494
2495         next unless -e $psgi_file;
2496
2497         # If $psgi_file calls ->setup_engine, it's doing so to load
2498         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2499         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2500         # anyway. So set a flag (ick) that tells setup_engine not to populate
2501         # $c->engine or do any other things we might regret.
2502
2503         $app->loading_psgi_file(1);
2504         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2505         $app->loading_psgi_file(0);
2506
2507         return $psgi_app
2508             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2509
2510         warn <<"EOW";
2511 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2512
2513 Its content has been ignored. Please consult the Catalyst::Upgrading
2514 documentation on how to upgrade from Catalyst::Engine::PSGI.
2515 EOW
2516     }
2517
2518     return $app->apply_default_middlewares($app->psgi_app);
2519 }
2520
2521 =head2 $c->apply_default_middlewares
2522
2523 Adds the following L<Plack> middlewares to your application, since they are
2524 useful and commonly needed:
2525
2526 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2527 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2528 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2529 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2530 applied since this middleware is smart enough to conditionally apply itself).
2531
2532 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2533 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2534 $ENV{SCRIPT_NAME}
2535
2536 =cut
2537
2538
2539 sub apply_default_middlewares {
2540     my ($app, $psgi_app) = @_;
2541
2542     $psgi_app = Plack::Middleware::Conditional->wrap(
2543         $psgi_app,
2544         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2545         condition => sub {
2546             my ($env) = @_;
2547             return if $app->config->{ignore_frontend_proxy};
2548             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2549                 || $app->config->{using_frontend_proxy};
2550         },
2551     );
2552
2553     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2554     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2555     $psgi_app = Plack::Middleware::Conditional->wrap(
2556         $psgi_app,
2557         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2558         condition => sub {
2559             my ($env) = @_;
2560             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2561             return unless $1 < 4.23;
2562             1;
2563         },
2564     );
2565
2566     # we're applying this unconditionally as the middleware itself already makes
2567     # sure it doesn't fuck things up if it's not running under one of the right
2568     # IIS versions
2569     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2570
2571     return $psgi_app;
2572 }
2573
2574 =head2 $c->psgi_app
2575
2576 Returns a PSGI application code reference for the catalyst application
2577 C<$c>. This is the bare application without any middlewares
2578 applied. C<${myapp}.psgi> is not taken into account.
2579
2580 This is what you want to be using to retrieve the PSGI application code
2581 reference of your Catalyst application for use in F<.psgi> files.
2582
2583 =cut
2584
2585 sub psgi_app {
2586     my ($app) = @_;
2587     return $app->engine->build_psgi_app($app);
2588 }
2589
2590 =head2 $c->setup_home
2591
2592 Sets up the home directory.
2593
2594 =cut
2595
2596 sub setup_home {
2597     my ( $class, $home ) = @_;
2598
2599     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2600         $home = $env;
2601     }
2602
2603     $home ||= Catalyst::Utils::home($class);
2604
2605     if ($home) {
2606         #I remember recently being scolded for assigning config values like this
2607         $class->config->{home} ||= $home;
2608         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2609     }
2610 }
2611
2612 =head2 $c->setup_log
2613
2614 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2615 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2616 log to.
2617
2618 This method also installs a C<debug> method that returns a true value into the
2619 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2620 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2621
2622 Note that if the log has already been setup, by either a previous call to
2623 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2624 that this method won't actually set up the log object.
2625
2626 =cut
2627
2628 sub setup_log {
2629     my ( $class, $levels ) = @_;
2630
2631     $levels ||= '';
2632     $levels =~ s/^\s+//;
2633     $levels =~ s/\s+$//;
2634     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2635
2636     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2637     if ( defined $env_debug ) {
2638         $levels{debug} = 1 if $env_debug; # Ugly!
2639         delete($levels{debug}) unless $env_debug;
2640     }
2641
2642     unless ( $class->log ) {
2643         $class->log( Catalyst::Log->new(keys %levels) );
2644     }
2645
2646     if ( $levels{debug} ) {
2647         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2648         $class->log->debug('Debug messages enabled');
2649     }
2650 }
2651
2652 =head2 $c->setup_plugins
2653
2654 Sets up plugins.
2655
2656 =cut
2657
2658 =head2 $c->setup_stats
2659
2660 Sets up timing statistics class.
2661
2662 =cut
2663
2664 sub setup_stats {
2665     my ( $class, $stats ) = @_;
2666
2667     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2668
2669     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2670     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2671         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2672         $class->log->debug('Statistics enabled');
2673     }
2674 }
2675
2676
2677 =head2 $c->registered_plugins
2678
2679 Returns a sorted list of the plugins which have either been stated in the
2680 import list.
2681
2682 If passed a given plugin name, it will report a boolean value indicating
2683 whether or not that plugin is loaded.  A fully qualified name is required if
2684 the plugin name does not begin with C<Catalyst::Plugin::>.
2685
2686  if ($c->registered_plugins('Some::Plugin')) {
2687      ...
2688  }
2689
2690 =cut
2691
2692 {
2693
2694     sub registered_plugins {
2695         my $proto = shift;
2696         return sort keys %{ $proto->_plugins } unless @_;
2697         my $plugin = shift;
2698         return 1 if exists $proto->_plugins->{$plugin};
2699         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2700     }
2701
2702     sub _register_plugin {
2703         my ( $proto, $plugin, $instant ) = @_;
2704         my $class = ref $proto || $proto;
2705
2706         Class::MOP::load_class( $plugin );
2707         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2708             if $plugin->isa( 'Catalyst::Component' );
2709         $proto->_plugins->{$plugin} = 1;
2710         unless ($instant) {
2711             my $meta = Class::MOP::get_metaclass_by_name($class);
2712             $meta->superclasses($plugin, $meta->superclasses);
2713         }
2714         return $class;
2715     }
2716
2717     sub setup_plugins {
2718         my ( $class, $plugins ) = @_;
2719
2720         $class->_plugins( {} ) unless $class->_plugins;
2721         $plugins = Data::OptList::mkopt($plugins || []);
2722
2723         my @plugins = map {
2724             [ Catalyst::Utils::resolve_namespace(
2725                   $class . '::Plugin',
2726                   'Catalyst::Plugin', $_->[0]
2727               ),
2728               $_->[1],
2729             ]
2730          } @{ $plugins };
2731
2732         for my $plugin ( reverse @plugins ) {
2733             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2734             my $meta = find_meta($plugin->[0]);
2735             next if $meta && $meta->isa('Moose::Meta::Role');
2736
2737             $class->_register_plugin($plugin->[0]);
2738         }
2739
2740         my @roles =
2741             map  { $_->[0]->name, $_->[1] }
2742             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2743             map  { [find_meta($_->[0]), $_->[1]] }
2744             @plugins;
2745
2746         Moose::Util::apply_all_roles(
2747             $class => @roles
2748         ) if @roles;
2749     }
2750 }
2751
2752 =head2 $c->stack
2753
2754 Returns an arrayref of the internal execution stack (actions that are
2755 currently executing).
2756
2757 =head2 $c->stats
2758
2759 Returns the current timing statistics object. By default Catalyst uses
2760 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2761 L<< stats_class|/"$c->stats_class" >>.
2762
2763 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2764 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2765 profile explicitly, although MyApp.pm still won't profile nor output anything
2766 by itself.
2767
2768 =head2 $c->stats_class
2769
2770 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2771
2772 =head2 $c->use_stats
2773
2774 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2775
2776 Note that this is a static method, not an accessor and should be overridden
2777 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2778
2779 =cut
2780
2781 sub use_stats { 0 }
2782
2783
2784 =head2 $c->write( $data )
2785
2786 Writes $data to the output stream. When using this method directly, you
2787 will need to manually set the C<Content-Length> header to the length of
2788 your output data, if known.
2789
2790 =cut
2791
2792 sub write {
2793     my $c = shift;
2794
2795     # Finalize headers if someone manually writes output (for compat)
2796     $c->finalize_headers;
2797
2798     return $c->response->write( @_ );
2799 }
2800
2801 =head2 version
2802
2803 Returns the Catalyst version number. Mostly useful for "powered by"
2804 messages in template systems.
2805
2806 =cut
2807
2808 sub version { return $Catalyst::VERSION }
2809
2810 =head1 CONFIGURATION
2811
2812 There are a number of 'base' config variables which can be set:
2813
2814 =over
2815
2816 =item *
2817
2818 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2819
2820 =item *
2821
2822 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2823
2824 =item *
2825
2826 C<home> - The application home directory. In an uninstalled application,
2827 this is the top level application directory. In an installed application,
2828 this will be the directory containing C<< MyApp.pm >>.
2829
2830 =item *
2831
2832 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2833
2834 =item *
2835
2836 C<name> - The name of the application in debug messages and the debug and
2837 welcome screens
2838
2839 =item *
2840
2841 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2842 until it is accessed. This allows you to (for example) check authentication (and reject
2843 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
2844
2845 =item *
2846
2847 C<root> - The root directory for templates. Usually this is just a
2848 subdirectory of the home directory, but you can set it to change the
2849 templates to a different directory.
2850
2851 =item *
2852
2853 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2854 to be shown in hit debug tables in the test server.
2855
2856 =item *
2857
2858 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
2859 variable should be used for determining the request path.
2860
2861 Most web server environments pass the requested path to the application using environment variables,
2862 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
2863 exposed as C<< $c->request->base >>) and the request path below that base.
2864
2865 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
2866 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
2867
2868 =over
2869
2870 =item use_request_uri_for_path => 0
2871
2872 This is the default (and the) traditional method that Catalyst has used for determining the path information.
2873 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
2874 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
2875 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
2876
2877 However this method has the major disadvantage that it is impossible to correctly decode some elements
2878 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
2879 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
2880 can't distinguish / vs %2F in paths (in addition to other encoded values).
2881
2882 =item use_request_uri_for_path => 1
2883
2884 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
2885 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
2886 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
2887
2888 Given that this method of path resolution is provably more correct, it is recommended that you use
2889 this unless you have a specific need to deploy your application in a non-standard environment, and you are
2890 aware of the implications of not being able to handle encoded URI paths correctly.
2891
2892 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
2893 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
2894 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
2895 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
2896 C<< $c->request->base >> will be incorrect.
2897
2898 =back
2899
2900 =item *
2901
2902 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2903
2904 =back
2905
2906 =head1 INTERNAL ACTIONS
2907
2908 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2909 C<_ACTION>, and C<_END>. These are by default not shown in the private
2910 action table, but you can make them visible with a config parameter.
2911
2912     MyApp->config(show_internal_actions => 1);
2913
2914 =head1 ON-DEMAND PARSER
2915
2916 The request body is usually parsed at the beginning of a request,
2917 but if you want to handle input yourself, you can enable on-demand
2918 parsing with a config parameter.
2919
2920     MyApp->config(parse_on_demand => 1);
2921
2922 =head1 PROXY SUPPORT
2923
2924 Many production servers operate using the common double-server approach,
2925 with a lightweight frontend web server passing requests to a larger
2926 backend server. An application running on the backend server must deal
2927 with two problems: the remote user always appears to be C<127.0.0.1> and
2928 the server's hostname will appear to be C<localhost> regardless of the
2929 virtual host that the user connected through.
2930
2931 Catalyst will automatically detect this situation when you are running
2932 the frontend and backend servers on the same machine. The following
2933 changes are made to the request.
2934
2935     $c->req->address is set to the user's real IP address, as read from
2936     the HTTP X-Forwarded-For header.
2937
2938     The host value for $c->req->base and $c->req->uri is set to the real
2939     host, as read from the HTTP X-Forwarded-Host header.
2940
2941 Additionally, you may be running your backend application on an insecure
2942 connection (port 80) while your frontend proxy is running under SSL.  If there
2943 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2944 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2945 be created properly.
2946
2947 In the case of passing in:
2948
2949     X-Forwarded-Port: 443
2950
2951 All calls to C<uri_for> will result in an https link, as is expected.
2952
2953 Obviously, your web server must support these headers for this to work.
2954
2955 In a more complex server farm environment where you may have your
2956 frontend proxy server(s) on different machines, you will need to set a
2957 configuration option to tell Catalyst to read the proxied data from the
2958 headers.
2959
2960     MyApp->config(using_frontend_proxy => 1);
2961
2962 If you do not wish to use the proxy support at all, you may set:
2963
2964     MyApp->config(ignore_frontend_proxy => 0);
2965
2966 =head2 Note about psgi files
2967
2968 Note that if you supply your own .psgi file, calling
2969 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
2970
2971 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
2972 in your psgi, for example:
2973
2974     builder {
2975         enable "Plack::Middleware::ReverseProxy";
2976         MyApp->psgi_app
2977     };
2978
2979 This will unconditionally add the ReverseProxy support, or you need to call
2980 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
2981 apply the support depending upon your config).
2982
2983 See L<Catalyst::PSGI> for more information.
2984
2985 =head1 THREAD SAFETY
2986
2987 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2988 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2989 believe the Catalyst core to be thread-safe.
2990
2991 If you plan to operate in a threaded environment, remember that all other
2992 modules you are using must also be thread-safe. Some modules, most notably
2993 L<DBD::SQLite>, are not thread-safe.
2994
2995 =head1 SUPPORT
2996
2997 IRC:
2998
2999     Join #catalyst on irc.perl.org.
3000
3001 Mailing Lists:
3002
3003     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3004     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3005
3006 Web:
3007
3008     http://catalyst.perl.org
3009
3010 Wiki:
3011
3012     http://dev.catalyst.perl.org
3013
3014 =head1 SEE ALSO
3015
3016 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3017
3018 =head2 L<Catalyst::Manual> - The Catalyst Manual
3019
3020 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3021
3022 =head2 L<Catalyst::Engine> - Core engine
3023
3024 =head2 L<Catalyst::Log> - Log class.
3025
3026 =head2 L<Catalyst::Request> - Request object
3027
3028 =head2 L<Catalyst::Response> - Response object
3029
3030 =head2 L<Catalyst::Test> - The test suite.
3031
3032 =head1 PROJECT FOUNDER
3033
3034 sri: Sebastian Riedel <sri@cpan.org>
3035
3036 =head1 CONTRIBUTORS
3037
3038 abw: Andy Wardley
3039
3040 acme: Leon Brocard <leon@astray.com>
3041
3042 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3043
3044 Andrew Bramble
3045
3046 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3047
3048 Andrew Ruthven
3049
3050 André Walker
3051
3052 andyg: Andy Grundman <andy@hybridized.org>
3053
3054 audreyt: Audrey Tang
3055
3056 bricas: Brian Cassidy <bricas@cpan.org>
3057
3058 Caelum: Rafael Kitover <rkitover@io.com>
3059
3060 chansen: Christian Hansen
3061
3062 chicks: Christopher Hicks
3063
3064 Chisel Wright C<pause@herlpacker.co.uk>
3065
3066 Danijel Milicevic C<me@danijel.de>
3067
3068 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3069
3070 David Naughton, C<naughton@umn.edu>
3071
3072 David E. Wheeler
3073
3074 dhoss: Devin Austin <dhoss@cpan.org>
3075
3076 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3077
3078 Drew Taylor
3079
3080 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3081
3082 esskar: Sascha Kiefer
3083
3084 fireartist: Carl Franks <cfranks@cpan.org>
3085
3086 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3087
3088 gabb: Danijel Milicevic
3089
3090 Gary Ashton Jones
3091
3092 Gavin Henry C<ghenry@perl.me.uk>
3093
3094 Geoff Richards
3095
3096 groditi: Guillermo Roditi <groditi@gmail.com>
3097
3098 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3099
3100 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3101
3102 jcamacho: Juan Camacho
3103
3104 jester: Jesse Sheidlower C<jester@panix.com>
3105
3106 jhannah: Jay Hannah <jay@jays.net>
3107
3108 Jody Belka
3109
3110 Johan Lindstrom
3111
3112 jon: Jon Schutz <jjschutz@cpan.org>
3113
3114 Jonathan Rockway C<< <jrockway@cpan.org> >>
3115
3116 Kieren Diment C<kd@totaldatasolution.com>
3117
3118 konobi: Scott McWhirter <konobi@cpan.org>
3119
3120 marcus: Marcus Ramberg <mramberg@cpan.org>
3121
3122 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3123
3124 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3125
3126 mugwump: Sam Vilain
3127
3128 naughton: David Naughton
3129
3130 ningu: David Kamholz <dkamholz@cpan.org>
3131
3132 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3133
3134 numa: Dan Sully <daniel@cpan.org>
3135
3136 obra: Jesse Vincent
3137
3138 Octavian Rasnita
3139
3140 omega: Andreas Marienborg
3141
3142 Oleg Kostyuk <cub.uanic@gmail.com>
3143
3144 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3145
3146 rafl: Florian Ragwitz <rafl@debian.org>
3147
3148 random: Roland Lammel <lammel@cpan.org>
3149
3150 Robert Sedlacek C<< <rs@474.at> >>
3151
3152 SpiceMan: Marcel Montes
3153
3154 sky: Arthur Bergman
3155
3156 szbalint: Balint Szilakszi <szbalint@cpan.org>
3157
3158 t0m: Tomas Doran <bobtfish@bobtfish.net>
3159
3160 Ulf Edvinsson
3161
3162 Viljo Marrandi C<vilts@yahoo.com>
3163
3164 Will Hawes C<info@whawes.co.uk>
3165
3166 willert: Sebastian Willert <willert@cpan.org>
3167
3168 wreis: Wallace Reis <wallace@reis.org.br>
3169
3170 Yuval Kogman, C<nothingmuch@woobling.org>
3171
3172 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3173
3174 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3175
3176 =head1 COPYRIGHT
3177
3178 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3179
3180 =head1 LICENSE
3181
3182 This library is free software. You can redistribute it and/or modify it under
3183 the same terms as Perl itself.
3184
3185 =cut
3186
3187 no Moose;
3188
3189 __PACKAGE__->meta->make_immutable;
3190
3191 1;