lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use File::stat;
  19 use Text::SimpleTable ();
  20 use Path::Class::Dir ();
  21 use Path::Class::File ();
  22 use URI ();
  23 use URI::http;
  24 use URI::https;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use Class::C3::Adopt::NEXT;
  28 use List::MoreUtils qw/uniq/;
  29 use attributes;
  30 use String::RewritePrefix;
  31 use Catalyst::EngineLoader;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34 use Try::Tiny;
  35 use Safe::Isa;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39 use Plack::Middleware::IIS7KeepAliveFix;
  40 use Plack::Middleware::LighttpdScriptNameFix;
  41
  42 BEGIN { require 5.008003; }
  43
  44 has stack => (is => 'ro', default => sub { [] });
  45 has stash => (is => 'rw', default => sub { {} });
  46 has state => (is => 'rw', default => 0);
  47 has stats => (is => 'rw');
  48 has action => (is => 'rw');
  49 has counter => (is => 'rw', default => sub { {} });
  50 has request => (
  51     is => 'rw',
  52     default => sub {
  53         my $self = shift;
  54         $self->request_class->new($self->_build_request_constructor_args);
  55     },
  56     lazy => 1,
  57 );
  58 sub _build_request_constructor_args {
  59     my $self = shift;
  60     my %p = ( _log => $self->log );
  61     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  62     \%p;
  63 }
  64
  65 has response => (
  66     is => 'rw',
  67     default => sub {
  68         my $self = shift;
  69         $self->response_class->new($self->_build_response_constructor_args);
  70     },
  71     lazy => 1,
  72 );
  73 sub _build_response_constructor_args {
  74     my $self = shift;
  75     { _log => $self->log };
  76 }
  77
  78 has namespace => (is => 'rw');
  79
  80 sub depth { scalar @{ shift->stack || [] }; }
  81 sub comp { shift->component(@_) }
  82
  83 sub req {
  84     my $self = shift; return $self->request(@_);
  85 }
  86 sub res {
  87     my $self = shift; return $self->response(@_);
  88 }
  89
  90 # For backwards compatibility
  91 sub finalize_output { shift->finalize_body(@_) };
  92
  93 # For statistics
  94 our $COUNT     = 1;
  95 our $START     = time;
  96 our $RECURSION = 1000;
  97 our $DETACH    = Catalyst::Exception::Detach->new;
  98 our $GO        = Catalyst::Exception::Go->new;
  99
 100 #I imagine that very few of these really need to be class variables. if any.
 101 #maybe we should just make them attributes with a default?
 102 __PACKAGE__->mk_classdata($_)
 103   for qw/container arguments dispatcher engine log dispatcher_class
 104   engine_loader context_class request_class response_class stats_class
 105   setup_finished _psgi_app loading_psgi_file run_options/;
 106
 107 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 108 __PACKAGE__->request_class('Catalyst::Request');
 109 __PACKAGE__->response_class('Catalyst::Response');
 110 __PACKAGE__->stats_class('Catalyst::Stats');
 111
 112 # Remember to update this in Catalyst::Runtime as well!
 113
 114 our $VERSION = '5.90017';
 115
 116 sub import {
 117     my ( $class, @arguments ) = @_;
 118
 119     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 120     # callers @ISA.
 121     return unless $class eq 'Catalyst';
 122
 123     my $caller = caller();
 124     return if $caller eq 'main';
 125
 126     my $meta = Moose::Meta::Class->initialize($caller);
 127
 128     unless ( $caller->isa('Catalyst') ) { # XXX - Remove!
 129         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Component'); # XXX - Remove!
 130         $meta->superclasses(@superclasses); # XXX - Remove!
 131     } # XXX - Remove!
 132
 133     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 134     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 135
 136     unless( $meta->has_method('meta') ){
 137         if ($Moose::VERSION >= 1.15) {
 138             $meta->_add_meta_method('meta');
 139         }
 140         else {
 141             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 142         }
 143     }
 144
 145     $caller->arguments( [@arguments] );
 146
 147     # FIXME
 148     # what is this for?
 149     # we call setup_home on import AND on ->setup
 150     # is there a reason for it?
 151     # anyway there is no point for setup_home without setup_config() so...
 152     $caller->setup_config;
 153     $caller->setup_home;
 154 }
 155
 156 sub MODIFY_CODE_ATTRIBUTES {
 157     Catalyst::Exception->throw(
 158         "Catalyst applications (aka MyApp) cannot be controllers anymore. " .
 159         "That has been deprecated and removed. You should create a " .
 160         "controller class called Root.pm, and move relevant code to that class."
 161     );
 162 }
 163
 164
 165 sub _application { $_[0] }
 166
 167 =encoding UTF-8
 168
 169 =head1 NAME
 170
 171 Catalyst - The Elegant MVC Web Application Framework
 172
 173 =head1 SYNOPSIS
 174
 175 See the L<Catalyst::Manual> distribution for comprehensive
 176 documentation and tutorials.
 177
 178     # Install Catalyst::Devel for helpers and other development tools
 179     # use the helper to create a new application
 180     catalyst.pl MyApp
 181
 182     # add models, views, controllers
 183     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 184     script/myapp_create.pl view MyTemplate TT
 185     script/myapp_create.pl controller Search
 186
 187     # built in testserver -- use -r to restart automatically on changes
 188     # --help to see all available options
 189     script/myapp_server.pl
 190
 191     # command line testing interface
 192     script/myapp_test.pl /yada
 193
 194     ### in lib/MyApp.pm
 195     use Catalyst qw/-Debug/; # include plugins here as well
 196
 197     ### In lib/MyApp/Controller/Root.pm (autocreated)
 198     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 199         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 200         $c->stash->{template} = 'foo.tt'; # set the template
 201         # lookup something from db -- stash vars are passed to TT
 202         $c->stash->{data} =
 203           $c->model('Database::Foo')->search( { country => $args[0] } );
 204         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 205             $c->forward( 'bar' ); # process another action
 206             # do something else after forward returns
 207         }
 208     }
 209
 210     # The foo.tt TT template can use the stash data from the database
 211     [% WHILE (item = data.next) %]
 212         [% item.foo %]
 213     [% END %]
 214
 215     # called for /bar/of/soap, /bar/of/soap/10, etc.
 216     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 217
 218     # called after all actions are finished
 219     sub end : Action {
 220         my ( $self, $c ) = @_;
 221         if ( scalar @{ $c->error } ) { ... } # handle errors
 222         return if $c->res->body; # already have a response
 223         $c->forward( 'MyApp::View::TT' ); # render template
 224     }
 225
 226 See L<Catalyst::Manual::Intro> for additional information.
 227
 228 =head1 DESCRIPTION
 229
 230 Catalyst is a modern framework for making web applications without the
 231 pain usually associated with this process. This document is a reference
 232 to the main Catalyst application. If you are a new user, we suggest you
 233 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 234
 235 See L<Catalyst::Manual> for more documentation.
 236
 237 Catalyst plugins can be loaded by naming them as arguments to the "use
 238 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 239 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 240 C<My::Module>.
 241
 242     use Catalyst qw/My::Module/;
 243
 244 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 245 fully qualify the name by using a unary plus:
 246
 247     use Catalyst qw/
 248         My::Module
 249         +Fully::Qualified::Plugin::Name
 250     /;
 251
 252 Special flags like C<-Debug> can also be specified as
 253 arguments when Catalyst is loaded:
 254
 255     use Catalyst qw/-Debug My::Module/;
 256
 257 The position of plugins and flags in the chain is important, because
 258 they are loaded in the order in which they appear.
 259
 260 The following flags are supported:
 261
 262 =head2 -Debug
 263
 264 Enables debug output. You can also force this setting from the system
 265 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 266 settings override the application, with <MYAPP>_DEBUG having the highest
 267 priority.
 268
 269 This sets the log level to 'debug' and enables full debug output on the
 270 error screen. If you only want the latter, see L<< $c->debug >>.
 271
 272 =head2 -Home
 273
 274 Forces Catalyst to use a specific home directory, e.g.:
 275
 276     use Catalyst qw[-Home=/usr/mst];
 277
 278 This can also be done in the shell environment by setting either the
 279 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 280 is replaced with the uppercased name of your application, any "::" in
 281 the name will be replaced with underscores, e.g. MyApp::Web should use
 282 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 283
 284 If none of these are set, Catalyst will attempt to automatically detect the
 285 home directory. If you are working in a development environment, Catalyst
 286 will try and find the directory containing either Makefile.PL, Build.PL or
 287 dist.ini. If the application has been installed into the system (i.e.
 288 you have done C<make install>), then Catalyst will use the path to your
 289 application module, without the .pm extension (e.g., /foo/MyApp if your
 290 application was installed at /foo/MyApp.pm)
 291
 292 =head2 -Log
 293
 294     use Catalyst '-Log=warn,fatal,error';
 295
 296 Specifies a comma-delimited list of log levels.
 297
 298 =head2 -Stats
 299
 300 Enables statistics collection and reporting.
 301
 302    use Catalyst qw/-Stats=1/;
 303
 304 You can also force this setting from the system environment with CATALYST_STATS
 305 or <MYAPP>_STATS. The environment settings override the application, with
 306 <MYAPP>_STATS having the highest priority.
 307
 308 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 309
 310 =head1 METHODS
 311
 312 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 313
 314 =head2 $c->action
 315
 316 Returns a L<Catalyst::Action> object for the current action, which
 317 stringifies to the action name. See L<Catalyst::Action>.
 318
 319 =head2 $c->namespace
 320
 321 Returns the namespace of the current action, i.e., the URI prefix
 322 corresponding to the controller of the current action. For example:
 323
 324     # in Controller::Foo::Bar
 325     $c->namespace; # returns 'foo/bar';
 326
 327 =head2 $c->request
 328
 329 =head2 $c->req
 330
 331 Returns the current L<Catalyst::Request> object, giving access to
 332 information about the current client request (including parameters,
 333 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 334
 335 =head2 REQUEST FLOW HANDLING
 336
 337 =head2 $c->forward( $action [, \@arguments ] )
 338
 339 =head2 $c->forward( $class, $method, [, \@arguments ] )
 340
 341 Forwards processing to another action, by its private name. If you give a
 342 class name but no method, C<process()> is called. You may also optionally
 343 pass arguments in an arrayref. The action will receive the arguments in
 344 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 345 C<< $c->req->args >> will be restored to the previous values.
 346
 347 Any data C<return>ed from the action forwarded to, will be returned by the
 348 call to forward.
 349
 350     my $foodata = $c->forward('/foo');
 351     $c->forward('index');
 352     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 353     $c->forward('View::TT');
 354
 355 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 356 an C<< eval { } >> around the call (actually
 357 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 358 exceptions thrown by the called action non-fatal and pushing them onto
 359 $c->error instead. If you want C<die> to propagate you need to do something
 360 like:
 361
 362     $c->forward('foo');
 363     die join "\n", @{ $c->error } if @{ $c->error };
 364
 365 Or make sure to always return true values from your actions and write
 366 your code like this:
 367
 368     $c->forward('foo') || return;
 369
 370 Another note is that C<< $c->forward >> always returns a scalar because it
 371 actually returns $c->state which operates in a scalar context.
 372 Thus, something like:
 373
 374     return @array;
 375
 376 in an action that is forwarded to is going to return a scalar,
 377 i.e. how many items are in that array, which is probably not what you want.
 378 If you need to return an array then return a reference to it,
 379 or stash it like so:
 380
 381     $c->stash->{array} = \@array;
 382
 383 and access it from the stash.
 384
 385 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 386
 387 =cut
 388
 389 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 390
 391 =head2 $c->detach( $action [, \@arguments ] )
 392
 393 =head2 $c->detach( $class, $method, [, \@arguments ] )
 394
 395 =head2 $c->detach()
 396
 397 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 398 doesn't return to the previous action when processing is finished.
 399
 400 When called with no arguments it escapes the processing chain entirely.
 401
 402 =cut
 403
 404 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 405
 406 =head2 $c->visit( $action [, \@arguments ] )
 407
 408 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 409
 410 =head2 $c->visit( $class, $method, [, \@arguments ] )
 411
 412 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 413
 414 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 415 but does a full dispatch, instead of just calling the new C<$action> /
 416 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 417 you go to are called, just like a new request.
 418
 419 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 420 This means, for example, that C<< $c->action >> methods such as
 421 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 422 L<reverse|Catalyst::Action/reverse> return information for the visited action
 423 when they are invoked within the visited action.  This is different from the
 424 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 425 continues to use the $c->action object from the caller action even when
 426 invoked from the called action.
 427
 428 C<< $c->stash >> is kept unchanged.
 429
 430 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 431 allows you to "wrap" another action, just as it would have been called by
 432 dispatching from a URL, while the analogous
 433 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 434 transfer control to another action as if it had been reached directly from a URL.
 435
 436 =cut
 437
 438 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 439
 440 =head2 $c->go( $action [, \@arguments ] )
 441
 442 =head2 $c->go( $action [, \@captures, \@arguments ] )
 443
 444 =head2 $c->go( $class, $method, [, \@arguments ] )
 445
 446 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 447
 448 The relationship between C<go> and
 449 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 450 the relationship between
 451 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 452 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 453 C<< $c->go >> will perform a full dispatch on the specified action or method,
 454 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 455 C<go> escapes the processing of the current request chain on completion, and
 456 does not return to its caller.
 457
 458 @arguments are arguments to the final destination of $action. @captures are
 459 arguments to the intermediate steps, if any, on the way to the final sub of
 460 $action.
 461
 462 =cut
 463
 464 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 465
 466 =head2 $c->response
 467
 468 =head2 $c->res
 469
 470 Returns the current L<Catalyst::Response> object, see there for details.
 471
 472 =head2 $c->stash
 473
 474 Returns a hashref to the stash, which may be used to store data and pass
 475 it between components during a request. You can also set hash keys by
 476 passing arguments. The stash is automatically sent to the view. The
 477 stash is cleared at the end of a request; it cannot be used for
 478 persistent storage (for this you must use a session; see
 479 L<Catalyst::Plugin::Session> for a complete system integrated with
 480 Catalyst).
 481
 482     $c->stash->{foo} = $bar;
 483     $c->stash( { moose => 'majestic', qux => 0 } );
 484     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 485
 486     # stash is automatically passed to the view for use in a template
 487     $c->forward( 'MyApp::View::TT' );
 488
 489 =cut
 490
 491 around stash => sub {
 492     my $orig = shift;
 493     my $c = shift;
 494     my $stash = $orig->($c);
 495     if (@_) {
 496         my $new_stash = @_ > 1 ? {@_} : $_[0];
 497         croak('stash takes a hash or hashref') unless ref $new_stash;
 498         foreach my $key ( keys %$new_stash ) {
 499           $stash->{$key} = $new_stash->{$key};
 500         }
 501     }
 502
 503     return $stash;
 504 };
 505
 506
 507 =head2 $c->error
 508
 509 =head2 $c->error($error, ...)
 510
 511 =head2 $c->error($arrayref)
 512
 513 Returns an arrayref containing error messages.  If Catalyst encounters an
 514 error while processing a request, it stores the error in $c->error.  This
 515 method should only be used to store fatal error messages.
 516
 517     my @error = @{ $c->error };
 518
 519 Add a new error.
 520
 521     $c->error('Something bad happened');
 522
 523 =cut
 524
 525 sub error {
 526     my $c = shift;
 527     if ( $_[0] ) {
 528         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 529         croak @$error unless ref $c;
 530         push @{ $c->{error} }, @$error;
 531     }
 532     elsif ( defined $_[0] ) { $c->{error} = undef }
 533     return $c->{error} || [];
 534 }
 535
 536
 537 =head2 $c->state
 538
 539 Contains the return value of the last executed action.
 540 Note that << $c->state >> operates in a scalar context which means that all
 541 values it returns are scalar.
 542
 543 =head2 $c->clear_errors
 544
 545 Clear errors.  You probably don't want to clear the errors unless you are
 546 implementing a custom error screen.
 547
 548 This is equivalent to running
 549
 550     $c->error(0);
 551
 552 =cut
 553
 554 sub clear_errors {
 555     my $c = shift;
 556     $c->error(0);
 557 }
 558
 559 =head2 COMPONENT ACCESSORS
 560
 561 =head2 $c->controller($name)
 562
 563 Gets a L<Catalyst::Controller> instance by name.
 564
 565     $c->controller('Foo')->do_stuff;
 566
 567 If the name is omitted, will return the controller for the dispatched
 568 action.
 569
 570 If you want to search for controllers, pass in a regexp as the argument.
 571
 572     # find all controllers that start with Foo
 573     my @foo_controllers = $c->controller(qr{^Foo});
 574
 575
 576 =cut
 577
 578 sub controller { shift->_lookup_mvc('controller', @_) }
 579
 580 =head2 $c->model($name)
 581
 582 Gets a L<Catalyst::Model> instance by name.
 583
 584     $c->model('Foo')->do_stuff;
 585
 586 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 587
 588 If the name is omitted, it will look for
 589  - a model object in $c->stash->{current_model_instance}, then
 590  - a model name in $c->stash->{current_model}, then
 591  - a config setting 'default_model', or
 592  - check if there is only one model, and return it if that's the case.
 593
 594 If you want to search for models, pass in a regexp as the argument.
 595
 596     # find all models that start with Foo
 597     my @foo_models = $c->model(qr{^Foo});
 598
 599 =cut
 600
 601 sub model { shift->_lookup_mvc('model', @_) }
 602
 603 =head2 $c->view($name)
 604
 605 Gets a L<Catalyst::View> instance by name.
 606
 607     $c->view('Foo')->do_stuff;
 608
 609 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 610
 611 If the name is omitted, it will look for
 612  - a view object in $c->stash->{current_view_instance}, then
 613  - a view name in $c->stash->{current_view}, then
 614  - a config setting 'default_view', or
 615  - check if there is only one view, and return it if that's the case.
 616
 617 If you want to search for views, pass in a regexp as the argument.
 618
 619     # find all views that start with Foo
 620     my @foo_views = $c->view(qr{^Foo});
 621
 622 =cut
 623
 624 sub view { shift->_lookup_mvc('view', @_) }
 625
 626 sub _lookup_mvc {
 627     my ( $c, $type, $name, @args ) = @_;
 628
 629     if (ref $c && !$name) {
 630         my $current_instance = $c->stash->{"current_${type}_instance"};
 631         return $current_instance
 632             if $current_instance && $type ne 'controller';
 633
 634         $name = $type eq 'controller'
 635               ? Catalyst::Utils::class2classshortsuffix($c->action->class)
 636               : $c->stash->{"current_${type}"}
 637               ;
 638     }
 639
 640     return $c->container->get_component_from_sub_container($type, $name, $c, @args);
 641 }
 642
 643 =head2 $c->controllers
 644
 645 Returns the available names which can be passed to $c->controller
 646
 647 =cut
 648
 649 sub controllers {
 650     my ( $c ) = @_;
 651     return $c->container->get_sub_container('controller')->get_service_list;
 652 }
 653
 654 =head2 $c->models
 655
 656 Returns the available names which can be passed to $c->model
 657
 658 =cut
 659
 660 sub models {
 661     my ( $c ) = @_;
 662     return $c->container->get_sub_container('model')->get_service_list;
 663 }
 664
 665
 666 =head2 $c->views
 667
 668 Returns the available names which can be passed to $c->view
 669
 670 =cut
 671
 672 sub views {
 673     my ( $c ) = @_;
 674     return $c->container->get_sub_container('view')->get_service_list;
 675 }
 676
 677 =head2 $c->comp($name)
 678
 679 =head2 $c->component($name)
 680
 681 Gets a component object by name. This method is not recommended,
 682 unless you want to get a specific component by full
 683 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 684 should be used instead.
 685
 686 If C<$name> is a regexp, a list of components matched against the full
 687 component name will be returned.
 688
 689 =cut
 690
 691 sub component {
 692     my ( $c, $component, @args ) = @_;
 693
 694     unless ($component) {
 695         $c->log->warn('Calling $c->component with no args is deprecated and ');
 696         $c->log->warn('will be removed in a future release.');
 697         $c->log->warn('Use $c->component_list instead.');
 698         return $c->component_list;
 699     }
 700
 701     my @result = $c->container->find_component( $component, $c, @args );
 702
 703     # list context for regexp searches
 704     return @result if ref $component;
 705
 706     # only one component (if it's found) for string searches
 707     return shift @result if @result;
 708
 709     if (ref $c eq $component) {
 710         $c->log->warn('You are calling $c->comp("MyApp"). This behaviour is');
 711         $c->log->warn('deprecated, and will be removed in a future release.');
 712         return $c;
 713     }
 714
 715     $c->log->warn("Looking for '$component', but nothing was found.");
 716
 717     # I would expect to return an empty list here, but that breaks back-compat
 718     $c->log->warn('Component not found, returning the list of existing');
 719     $c->log->warn('components. This behavior is deprecated and will be');
 720     $c->log->warn('removed in a future release. Use $c->component_list');
 721     $c->log->warn('instead.');
 722
 723     return $c->component_list;
 724 }
 725
 726 =head2 $c->component_list
 727
 728 Returns the sorted list of the component names of the application.
 729
 730 =cut
 731
 732 sub component_list { sort keys %{ shift->components } }
 733
 734 =head2 CLASS DATA AND HELPER CLASSES
 735
 736 =head2 $c->config
 737
 738 Returns or takes a hashref containing the application's configuration.
 739
 740     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 741
 742 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 743 like C<myapp.conf> in your applications home directory. See
 744 L<Catalyst::Plugin::ConfigLoader>.
 745
 746 =head3 Cascading configuration
 747
 748 The config method is present on all Catalyst components, and configuration
 749 will be merged when an application is started. Configuration loaded with
 750 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 751 followed by configuration in your top level C<MyApp> class. These two
 752 configurations are merged, and then configuration data whose hash key matches a
 753 component name is merged with configuration for that component.
 754
 755 The configuration for a component is then passed to the C<new> method when a
 756 component is constructed.
 757
 758 For example:
 759
 760     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 761     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 762
 763 will mean that C<MyApp::Model::Foo> receives the following data when
 764 constructed:
 765
 766     MyApp::Model::Foo->new({
 767         bar => 'baz',
 768         quux => 'frob',
 769         overrides => 'me',
 770     });
 771
 772 It's common practice to use a Moose attribute
 773 on the receiving component to access the config value.
 774
 775     package MyApp::Model::Foo;
 776
 777     use Moose;
 778
 779     # this attr will receive 'baz' at construction time
 780     has 'bar' => (
 781         is  => 'rw',
 782         isa => 'Str',
 783     );
 784
 785 You can then get the value 'baz' by calling $c->model('Foo')->bar
 786 (or $self->bar inside code in the model).
 787
 788 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 789 as a way of reading config within your code, as this B<will not> give you the
 790 correctly merged config back. You B<MUST> take the config values supplied to
 791 the constructor and use those instead.
 792
 793 =cut
 794
 795 around config => sub {
 796     my $orig = shift;
 797     my $c = shift;
 798
 799     croak('Setting config after setup has been run is not allowed.')
 800         if ( @_ and $c->setup_finished );
 801
 802     $c->$orig(@_);
 803 };
 804
 805 =head2 $c->log
 806
 807 Returns the logging object instance. Unless it is already set, Catalyst
 808 sets this up with a L<Catalyst::Log> object. To use your own log class,
 809 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 810 C<< __PACKAGE__->setup >>.
 811
 812  __PACKAGE__->log( MyLogger->new );
 813  __PACKAGE__->setup;
 814
 815 And later:
 816
 817     $c->log->info( 'Now logging with my own logger!' );
 818
 819 Your log class should implement the methods described in
 820 L<Catalyst::Log>.
 821
 822
 823 =head2 $c->debug
 824
 825 Returns 1 if debug mode is enabled, 0 otherwise.
 826
 827 You can enable debug mode in several ways:
 828
 829 =over
 830
 831 =item By calling myapp_server.pl with the -d flag
 832
 833 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 834
 835 =item The -Debug option in your MyApp.pm
 836
 837 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 838
 839 =back
 840
 841 The first three also set the log level to 'debug'.
 842
 843 Calling C<< $c->debug(1) >> has no effect.
 844
 845 =cut
 846
 847 sub debug { 0 }
 848
 849 =head2 $c->dispatcher
 850
 851 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 852
 853 =head2 $c->engine
 854
 855 Returns the engine instance. See L<Catalyst::Engine>.
 856
 857
 858 =head2 UTILITY METHODS
 859
 860 =head2 $c->path_to(@path)
 861
 862 Merges C<@path> with C<< $c->config->{home} >> and returns a
 863 L<Path::Class::Dir> object. Note you can usually use this object as
 864 a filename, but sometimes you will have to explicitly stringify it
 865 yourself by calling the C<< ->stringify >> method.
 866
 867 For example:
 868
 869     $c->path_to( 'db', 'sqlite.db' );
 870
 871 =cut
 872
 873 sub path_to {
 874     my ( $c, @path ) = @_;
 875     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 876     if ( -d $path ) { return $path }
 877     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 878 }
 879
 880 sub plugin {
 881     my ( $class, $name, $plugin, @args ) = @_;
 882
 883     # See block comment in t/aggregate/unit_core_plugin.t
 884     # See block comment in t/unit_core_plugin.t
 885     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
 886
 887     $class->_register_plugin( $plugin, 1 );
 888
 889     eval { $plugin->import };
 890     $class->mk_classdata($name);
 891     my $obj;
 892     eval { $obj = $plugin->new(@args) };
 893
 894     if ($@) {
 895         Catalyst::Exception->throw( message =>
 896               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 897     }
 898
 899     $class->$name($obj);
 900     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 901       if $class->debug;
 902 }
 903
 904 =head2 MyApp->setup
 905
 906 Initializes the dispatcher and engine, loads any plugins, and loads the
 907 model, view, and controller components. You may also specify an array
 908 of plugins to load here, if you choose to not load them in the C<use
 909 Catalyst> line.
 910
 911     MyApp->setup;
 912     MyApp->setup( qw/-Debug/ );
 913
 914 B<Note:> You B<should not> wrap this method with method modifiers
 915 or bad things will happen - wrap the C<setup_finalize> method instead.
 916
 917 =cut
 918
 919 sub setup {
 920     my ( $class, @arguments ) = @_;
 921     croak('Running setup more than once')
 922         if ( $class->setup_finished );
 923
 924     unless ( $class->isa('Catalyst') ) {
 925
 926         Catalyst::Exception->throw(
 927             message => qq/'$class' does not inherit from Catalyst/ );
 928     }
 929
 930     if ( $class->arguments ) {
 931         @arguments = ( @arguments, @{ $class->arguments } );
 932     }
 933
 934     # Process options
 935     my $flags = {};
 936
 937     foreach (@arguments) {
 938
 939         if (/^-Debug$/) {
 940             $flags->{log} =
 941               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 942         }
 943         elsif (/^-(\w+)=?(.*)$/) {
 944             $flags->{ lc $1 } = $2;
 945         }
 946         else {
 947             push @{ $flags->{plugins} }, $_;
 948         }
 949     }
 950
 951     $class->setup_config();
 952     $class->setup_home( delete $flags->{home} );
 953
 954     $class->setup_log( delete $flags->{log} );
 955     $class->setup_plugins( delete $flags->{plugins} );
 956     $class->setup_dispatcher( delete $flags->{dispatcher} );
 957     if (my $engine = delete $flags->{engine}) {
 958         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
 959     }
 960     $class->setup_engine();
 961     $class->setup_stats( delete $flags->{stats} );
 962
 963     for my $flag ( sort keys %{$flags} ) {
 964
 965         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 966             &$code( $class, delete $flags->{$flag} );
 967         }
 968         else {
 969             $class->log->warn(qq/Unknown flag "$flag"/);
 970         }
 971     }
 972
 973     eval { require Catalyst::Devel; };
 974     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 975         $class->log->warn(<<"EOF");
 976 You are running an old script!
 977
 978   Please update by running (this will overwrite existing files):
 979     catalyst.pl -force -scripts $class
 980
 981   or (this will not overwrite existing files):
 982     catalyst.pl -scripts $class
 983
 984 EOF
 985     }
 986
 987     if ( $class->debug ) {
 988         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 989
 990         if (@plugins) {
 991             my $column_width = Catalyst::Utils::term_width() - 6;
 992             my $t = Text::SimpleTable->new($column_width);
 993             $t->row($_) for @plugins;
 994             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 995         }
 996
 997         my $dispatcher = $class->dispatcher;
 998         my $engine     = $class->engine;
 999         my $home       = $class->config->{home};
1000
1001         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1002         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1003
1004         $home
1005           ? ( -d $home )
1006           ? $class->log->debug(qq/Found home "$home"/)
1007           : $class->log->debug(qq/Home "$home" doesn't exist/)
1008           : $class->log->debug(q/Couldn't find home/);
1009     }
1010
1011     # Call plugins setup, this is stupid and evil.
1012     # Also screws C3 badly on 5.10, hack to avoid.
1013     {
1014         no warnings qw/redefine/;
1015         local *setup = sub { };
1016         $class->setup unless $Catalyst::__AM_RESTARTING;
1017     }
1018
1019     $class->setup_components;
1020
1021     if (
1022         $class->debug and
1023         my $comps = $class->container->get_all_component_services($class)
1024     ) {
1025         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1026         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Lifecycle' ] );
1027
1028         # FIXME
1029         # I don't really know what we're going to show here
1030         while (my ($class, $info) = each %$comps) {
1031             my $lifecycle = $info->{backcompat_service}
1032                           ? $info->{backcompat_service}->lifecycle
1033                           : $info->{service}->lifecycle
1034                           ;
1035             $t->row( $class, $lifecycle );
1036         }
1037
1038         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" );
1039     }
1040
1041     $class->setup_actions;
1042
1043     if ( $class->debug ) {
1044         my $name = $class->config->{name} || 'Application';
1045         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1046     }
1047
1048     if ($class->config->{case_sensitive}) {
1049         $class->log->warn($class . "->config->{case_sensitive} is set.");
1050         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1051     }
1052
1053     $class->setup_finalize;
1054     # Should be the last thing we do so that user things hooking
1055     # setup_finalize can log..
1056     $class->log->_flush() if $class->log->can('_flush');
1057     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1058 }
1059
1060 =head2 $app->setup_finalize
1061
1062 A hook to attach modifiers to. This method does not do anything except set the
1063 C<setup_finished> accessor.
1064
1065 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1066
1067 Example:
1068
1069     after setup_finalize => sub {
1070         my $app = shift;
1071
1072         ## do stuff here..
1073     };
1074
1075 =cut
1076
1077 sub setup_finalize {
1078     my ($class) = @_;
1079     $class->setup_finished(1);
1080 }
1081
1082 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1083
1084 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1085
1086 Constructs an absolute L<URI> object based on the application root, the
1087 provided path, and the additional arguments and query parameters provided.
1088 When used as a string, provides a textual URI.  If you need more flexibility
1089 than this (i.e. the option to provide relative URIs etc.) see
1090 L<Catalyst::Plugin::SmartURI>.
1091
1092 If no arguments are provided, the URI for the current action is returned.
1093 To return the current action and also provide @args, use
1094 C<< $c->uri_for( $c->action, @args ) >>.
1095
1096 If the first argument is a string, it is taken as a public URI path relative
1097 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1098 relative to the application root (if it does). It is then merged with
1099 C<< $c->request->base >>; any C<@args> are appended as additional path
1100 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1101
1102 If the first argument is a L<Catalyst::Action> it represents an action which
1103 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1104 optional C<\@captures> argument (an arrayref) allows passing the captured
1105 variables that are needed to fill in the paths of Chained and Regex actions;
1106 once the path is resolved, C<uri_for> continues as though a path was
1107 provided, appending any arguments or parameters and creating an absolute
1108 URI.
1109
1110 The captures for the current request can be found in
1111 C<< $c->request->captures >>, and actions can be resolved using
1112 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1113 path, use C<< $c->uri_for_action >> instead.
1114
1115   # Equivalent to $c->req->uri
1116   $c->uri_for($c->action, $c->req->captures,
1117       @{ $c->req->args }, $c->req->params);
1118
1119   # For the Foo action in the Bar controller
1120   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1121
1122   # Path to a static resource
1123   $c->uri_for('/static/images/logo.png');
1124
1125 =cut
1126
1127 sub uri_for {
1128     my ( $c, $path, @args ) = @_;
1129
1130     if ( $path->$_isa('Catalyst::Controller') ) {
1131         $path = $path->path_prefix;
1132         $path =~ s{/+\z}{};
1133         $path .= '/';
1134     }
1135
1136     undef($path) if (defined $path && $path eq '');
1137
1138     my $params =
1139       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1140
1141     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1142     foreach my $arg (@args) {
1143         utf8::encode($arg) if utf8::is_utf8($arg);
1144         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1145     }
1146
1147     if ( $path->$_isa('Catalyst::Action') ) { # action object
1148         s|/|%2F|g for @args;
1149         my $captures = [ map { s|/|%2F|g; $_; }
1150                         ( scalar @args && ref $args[0] eq 'ARRAY'
1151                          ? @{ shift(@args) }
1152                          : ()) ];
1153
1154         foreach my $capture (@$captures) {
1155             utf8::encode($capture) if utf8::is_utf8($capture);
1156             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1157         }
1158
1159         my $action = $path;
1160         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1161         if( !@args && $action->number_of_args ) {
1162             my $expanded_action = $c->dispatcher->expand_action( $action );
1163
1164             my $num_captures = $expanded_action->number_of_captures;
1165             unshift @args, splice @$captures, $num_captures;
1166         }
1167
1168        $path = $c->dispatcher->uri_for_action($action, $captures);
1169         if (not defined $path) {
1170             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1171                 if $c->debug;
1172             return undef;
1173         }
1174         $path = '/' if $path eq '';
1175     }
1176
1177     unshift(@args, $path);
1178
1179     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1180         my $namespace = $c->namespace;
1181         if (defined $path) { # cheesy hack to handle path '../foo'
1182            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1183         }
1184         unshift(@args, $namespace || '');
1185     }
1186
1187     # join args with '/', or a blank string
1188     my $args = join('/', grep { defined($_) } @args);
1189     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1190     $args =~ s!^/+!!;
1191     my $base = $c->req->base;
1192     my $class = ref($base);
1193     $base =~ s{(?<!/)$}{/};
1194
1195     my $query = '';
1196
1197     if (my @keys = keys %$params) {
1198       # somewhat lifted from URI::_query's query_form
1199       $query = '?'.join('&', map {
1200           my $val = $params->{$_};
1201           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1202           s/ /+/g;
1203           my $key = $_;
1204           $val = '' unless defined $val;
1205           (map {
1206               my $param = "$_";
1207               utf8::encode( $param ) if utf8::is_utf8($param);
1208               # using the URI::Escape pattern here so utf8 chars survive
1209               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1210               $param =~ s/ /+/g;
1211               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1212       } @keys);
1213     }
1214
1215     my $res = bless(\"${base}${args}${query}", $class);
1216     $res;
1217 }
1218
1219 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1220
1221 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1222
1223 =over
1224
1225 =item $path
1226
1227 A private path to the Catalyst action you want to create a URI for.
1228
1229 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1230 >> and passing the resulting C<$action> and the remaining arguments to C<<
1231 $c->uri_for >>.
1232
1233 You can also pass in a Catalyst::Action object, in which case it is passed to
1234 C<< $c->uri_for >>.
1235
1236 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1237
1238 For example, if the action looks like:
1239
1240  package MyApp::Controller::Users;
1241
1242  sub lst : Path('the-list') {}
1243
1244 You can use:
1245
1246  $c->uri_for_action('/users/lst')
1247
1248 and it will create the URI /users/the-list.
1249
1250 =item \@captures_and_args?
1251
1252 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1253 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1254 to interpolate all the parameters in the URI.
1255
1256 =item @args?
1257
1258 Optional list of extra arguments - can be supplied in the
1259 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1260 code.
1261
1262 Your action can have zero, a fixed or a variable number of args (e.g.
1263 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1264
1265 =item \%query_values?
1266
1267 Optional array reference of query parameters to append. E.g.
1268
1269   { foo => 'bar' }
1270
1271 will generate
1272
1273   /rest/of/your/uri?foo=bar
1274
1275 =back
1276
1277 =cut
1278
1279 sub uri_for_action {
1280     my ( $c, $path, @args ) = @_;
1281     my $action = blessed($path)
1282       ? $path
1283       : $c->dispatcher->get_action_by_path($path);
1284     unless (defined $action) {
1285       croak "Can't find action for path '$path'";
1286     }
1287     return $c->uri_for( $action, @args );
1288 }
1289
1290 =head2 $c->welcome_message
1291
1292 Returns the Catalyst welcome HTML page.
1293
1294 =cut
1295
1296 sub welcome_message {
1297     my $c      = shift;
1298     my $name   = $c->config->{name};
1299     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1300     my $prefix = Catalyst::Utils::appprefix( ref $c );
1301     $c->response->content_type('text/html; charset=utf-8');
1302     return <<"EOF";
1303 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1304     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1305 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1306     <head>
1307     <meta http-equiv="Content-Language" content="en" />
1308     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1309         <title>$name on Catalyst $VERSION</title>
1310         <style type="text/css">
1311             body {
1312                 color: #000;
1313                 background-color: #eee;
1314             }
1315             div#content {
1316                 width: 640px;
1317                 margin-left: auto;
1318                 margin-right: auto;
1319                 margin-top: 10px;
1320                 margin-bottom: 10px;
1321                 text-align: left;
1322                 background-color: #ccc;
1323                 border: 1px solid #aaa;
1324             }
1325             p, h1, h2 {
1326                 margin-left: 20px;
1327                 margin-right: 20px;
1328                 font-family: verdana, tahoma, sans-serif;
1329             }
1330             a {
1331                 font-family: verdana, tahoma, sans-serif;
1332             }
1333             :link, :visited {
1334                     text-decoration: none;
1335                     color: #b00;
1336                     border-bottom: 1px dotted #bbb;
1337             }
1338             :link:hover, :visited:hover {
1339                     color: #555;
1340             }
1341             div#topbar {
1342                 margin: 0px;
1343             }
1344             pre {
1345                 margin: 10px;
1346                 padding: 8px;
1347             }
1348             div#answers {
1349                 padding: 8px;
1350                 margin: 10px;
1351                 background-color: #fff;
1352                 border: 1px solid #aaa;
1353             }
1354             h1 {
1355                 font-size: 0.9em;
1356                 font-weight: normal;
1357                 text-align: center;
1358             }
1359             h2 {
1360                 font-size: 1.0em;
1361             }
1362             p {
1363                 font-size: 0.9em;
1364             }
1365             p img {
1366                 float: right;
1367                 margin-left: 10px;
1368             }
1369             span#appname {
1370                 font-weight: bold;
1371                 font-size: 1.6em;
1372             }
1373         </style>
1374     </head>
1375     <body>
1376         <div id="content">
1377             <div id="topbar">
1378                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1379                     $VERSION</h1>
1380              </div>
1381              <div id="answers">
1382                  <p>
1383                  <img src="$logo" alt="Catalyst Logo" />
1384                  </p>
1385                  <p>Welcome to the  world of Catalyst.
1386                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1387                     framework will make web development something you had
1388                     never expected it to be: Fun, rewarding, and quick.</p>
1389                  <h2>What to do now?</h2>
1390                  <p>That really depends  on what <b>you</b> want to do.
1391                     We do, however, provide you with a few starting points.</p>
1392                  <p>If you want to jump right into web development with Catalyst
1393                     you might want to start with a tutorial.</p>
1394 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1395 </pre>
1396 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1397 <pre>
1398 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1399 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1400 </code></pre>
1401                  <h2>What to do next?</h2>
1402                  <p>Next it's time to write an actual application. Use the
1403                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1404                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1405                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1406                     they can save you a lot of work.</p>
1407                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1408                     <p>Also, be sure to check out the vast and growing
1409                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1410                     you are likely to find what you need there.
1411                     </p>
1412
1413                  <h2>Need help?</h2>
1414                  <p>Catalyst has a very active community. Here are the main places to
1415                     get in touch with us.</p>
1416                  <ul>
1417                      <li>
1418                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1419                      </li>
1420                      <li>
1421                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1422                      </li>
1423                      <li>
1424                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1425                      </li>
1426                  </ul>
1427                  <h2>In conclusion</h2>
1428                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1429                     as we enjoyed making it. Please contact us if you have ideas
1430                     for improvement or other feedback.</p>
1431              </div>
1432          </div>
1433     </body>
1434 </html>
1435 EOF
1436 }
1437
1438 =head2 run_options
1439
1440 Contains a hash of options passed from the application script, including
1441 the original ARGV the script received, the processed values from that
1442 ARGV and any extra arguments to the script which were not processed.
1443
1444 This can be used to add custom options to your application's scripts
1445 and setup your application differently depending on the values of these
1446 options.
1447
1448 =head1 INTERNAL METHODS
1449
1450 These methods are not meant to be used by end users.
1451
1452 =head2 $c->components
1453
1454 Returns a hash of components.
1455
1456 =cut
1457
1458 sub components {
1459     my ( $class, $comps ) = @_;
1460
1461     # people create components calling this sub directly, before setup
1462     $class->setup_config unless $class->container;
1463
1464     my $container = $class->container;
1465
1466     if ( $comps ) {
1467         $container->add_component( $_ ) for keys %$comps;
1468     }
1469
1470     return $container->get_all_components($class);
1471 }
1472
1473 =head2 $c->context_class
1474
1475 Returns or sets the context class.
1476
1477 =head2 $c->counter
1478
1479 Returns a hashref containing coderefs and execution counts (needed for
1480 deep recursion detection).
1481
1482 =head2 $c->depth
1483
1484 Returns the number of actions on the current internal execution stack.
1485
1486 =head2 $c->dispatch
1487
1488 Dispatches a request to actions.
1489
1490 =cut
1491
1492 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1493
1494 =head2 $c->dispatcher_class
1495
1496 Returns or sets the dispatcher class.
1497
1498 =head2 $c->dump_these
1499
1500 Returns a list of 2-element array references (name, structure) pairs
1501 that will be dumped on the error page in debug mode.
1502
1503 =cut
1504
1505 sub dump_these {
1506     my $c = shift;
1507     [ Request => $c->req ],
1508     [ Response => $c->res ],
1509     [ Stash => $c->stash ],
1510     [ Config => $c->config ];
1511 }
1512
1513 =head2 $c->engine_class
1514
1515 Returns or sets the engine class.
1516
1517 =head2 $c->execute( $class, $coderef )
1518
1519 Execute a coderef in given class and catch exceptions. Errors are available
1520 via $c->error.
1521
1522 =cut
1523
1524 sub execute {
1525     my ( $c, $class, $code ) = @_;
1526     $class = $c->component($class) || $class;
1527     $c->state(0);
1528
1529     if ( $c->depth >= $RECURSION ) {
1530         my $action = $code->reverse();
1531         $action = "/$action" unless $action =~ /->/;
1532         my $error = qq/Deep recursion detected calling "${action}"/;
1533         $c->log->error($error);
1534         $c->error($error);
1535         $c->state(0);
1536         return $c->state;
1537     }
1538
1539     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1540
1541     push( @{ $c->stack }, $code );
1542
1543     no warnings 'recursion';
1544     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1545     #      I have no idea how, ergo $ret (which appears to fix the issue)
1546     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1547
1548     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1549
1550     my $last = pop( @{ $c->stack } );
1551
1552     if ( my $error = $@ ) {
1553         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1554             $error->rethrow if $c->depth > 1;
1555         }
1556         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1557             $error->rethrow if $c->depth > 0;
1558         }
1559         else {
1560             unless ( ref $error ) {
1561                 no warnings 'uninitialized';
1562                 chomp $error;
1563                 my $class = $last->class;
1564                 my $name  = $last->name;
1565                 $error = qq/Caught exception in $class->$name "$error"/;
1566             }
1567             $c->error($error);
1568         }
1569         $c->state(0);
1570     }
1571     return $c->state;
1572 }
1573
1574 sub _stats_start_execute {
1575     my ( $c, $code ) = @_;
1576     my $appclass = ref($c) || $c;
1577     return if ( ( $code->name =~ /^_.*/ )
1578         && ( !$appclass->config->{show_internal_actions} ) );
1579
1580     my $action_name = $code->reverse();
1581     $c->counter->{$action_name}++;
1582
1583     my $action = $action_name;
1584     $action = "/$action" unless $action =~ /->/;
1585
1586     # determine if the call was the result of a forward
1587     # this is done by walking up the call stack and looking for a calling
1588     # sub of Catalyst::forward before the eval
1589     my $callsub = q{};
1590     for my $index ( 2 .. 11 ) {
1591         last
1592         if ( ( caller($index) )[0] eq 'Catalyst'
1593             && ( caller($index) )[3] eq '(eval)' );
1594
1595         if ( ( caller($index) )[3] =~ /forward$/ ) {
1596             $callsub = ( caller($index) )[3];
1597             $action  = "-> $action";
1598             last;
1599         }
1600     }
1601
1602     my $uid = $action_name . $c->counter->{$action_name};
1603
1604     # is this a root-level call or a forwarded call?
1605     if ( $callsub =~ /forward$/ ) {
1606         my $parent = $c->stack->[-1];
1607
1608         # forward, locate the caller
1609         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1610             $c->stats->profile(
1611                 begin  => $action,
1612                 parent => "$parent" . $c->counter->{"$parent"},
1613                 uid    => $uid,
1614             );
1615         }
1616         else {
1617
1618             # forward with no caller may come from a plugin
1619             $c->stats->profile(
1620                 begin => $action,
1621                 uid   => $uid,
1622             );
1623         }
1624     }
1625     else {
1626
1627         # root-level call
1628         $c->stats->profile(
1629             begin => $action,
1630             uid   => $uid,
1631         );
1632     }
1633     return $action;
1634
1635 }
1636
1637 sub _stats_finish_execute {
1638     my ( $c, $info ) = @_;
1639     $c->stats->profile( end => $info );
1640 }
1641
1642 =head2 $c->finalize
1643
1644 Finalizes the request.
1645
1646 =cut
1647
1648 sub finalize {
1649     my $c = shift;
1650
1651     for my $error ( @{ $c->error } ) {
1652         $c->log->error($error);
1653     }
1654
1655     # Allow engine to handle finalize flow (for POE)
1656     my $engine = $c->engine;
1657     if ( my $code = $engine->can('finalize') ) {
1658         $engine->$code($c);
1659     }
1660     else {
1661
1662         $c->finalize_uploads;
1663
1664         # Error
1665         if ( $#{ $c->error } >= 0 ) {
1666             $c->finalize_error;
1667         }
1668
1669         $c->finalize_headers unless $c->response->finalized_headers;
1670
1671         # HEAD request
1672         if ( $c->request->method eq 'HEAD' ) {
1673             $c->response->body('');
1674         }
1675
1676         $c->finalize_body;
1677     }
1678
1679     $c->log_response;
1680
1681     if ($c->use_stats) {
1682         my $elapsed = sprintf '%f', $c->stats->elapsed;
1683         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1684         $c->log->info(
1685             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1686     }
1687
1688     return $c->response->status;
1689 }
1690
1691 =head2 $c->finalize_body
1692
1693 Finalizes body.
1694
1695 =cut
1696
1697 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1698
1699 =head2 $c->finalize_cookies
1700
1701 Finalizes cookies.
1702
1703 =cut
1704
1705 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1706
1707 =head2 $c->finalize_error
1708
1709 Finalizes error.
1710
1711 =cut
1712
1713 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1714
1715 =head2 $c->finalize_headers
1716
1717 Finalizes headers.
1718
1719 =cut
1720
1721 sub finalize_headers {
1722     my $c = shift;
1723
1724     my $response = $c->response; #accessor calls can add up?
1725
1726     # Check if we already finalized headers
1727     return if $response->finalized_headers;
1728
1729     # Handle redirects
1730     if ( my $location = $response->redirect ) {
1731         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1732         $response->header( Location => $location );
1733
1734         if ( !$response->has_body ) {
1735             # Add a default body if none is already present
1736             $response->body(<<"EOF");
1737 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1738 <html xmlns="http://www.w3.org/1999/xhtml">
1739   <head>
1740     <title>Moved</title>
1741   </head>
1742   <body>
1743      <p>This item has moved <a href="$location">here</a>.</p>
1744   </body>
1745 </html>
1746 EOF
1747             $response->content_type('text/html; charset=utf-8');
1748         }
1749     }
1750
1751     # Content-Length
1752     if ( defined $response->body && length $response->body && !$response->content_length ) {
1753
1754         # get the length from a filehandle
1755         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1756         {
1757             my $size = -s $response->body;
1758             if ( $size ) {
1759                 $response->content_length( $size );
1760             }
1761             else {
1762                 $c->log->warn('Serving filehandle without a content-length');
1763             }
1764         }
1765         else {
1766             # everything should be bytes at this point, but just in case
1767             $response->content_length( length( $response->body ) );
1768         }
1769     }
1770
1771     # Errors
1772     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1773         $response->headers->remove_header("Content-Length");
1774         $response->body('');
1775     }
1776
1777     $c->finalize_cookies;
1778
1779     $c->response->finalize_headers();
1780
1781     # Done
1782     $response->finalized_headers(1);
1783 }
1784
1785 =head2 $c->finalize_output
1786
1787 An alias for finalize_body.
1788
1789 =head2 $c->finalize_read
1790
1791 Finalizes the input after reading is complete.
1792
1793 =cut
1794
1795 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1796
1797 =head2 $c->finalize_uploads
1798
1799 Finalizes uploads. Cleans up any temporary files.
1800
1801 =cut
1802
1803 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1804
1805 =head2 $c->get_action( $action, $namespace )
1806
1807 Gets an action in a given namespace.
1808
1809 =cut
1810
1811 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1812
1813 =head2 $c->get_actions( $action, $namespace )
1814
1815 Gets all actions of a given name in a namespace and all parent
1816 namespaces.
1817
1818 =cut
1819
1820 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1821
1822 =head2 $app->handle_request( @arguments )
1823
1824 Called to handle each HTTP request.
1825
1826 =cut
1827
1828 sub handle_request {
1829     my ( $class, @arguments ) = @_;
1830
1831     # Always expect worst case!
1832     my $status = -1;
1833     try {
1834         if ($class->debug) {
1835             my $secs = time - $START || 1;
1836             my $av = sprintf '%.3f', $COUNT / $secs;
1837             my $time = localtime time;
1838             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1839         }
1840
1841         my $c = $class->prepare(@arguments);
1842         $c->dispatch;
1843         $status = $c->finalize;
1844     }
1845     catch {
1846         chomp(my $error = $_);
1847         $class->log->error(qq/Caught exception in engine "$error"/);
1848     };
1849
1850     $COUNT++;
1851
1852     if(my $coderef = $class->log->can('_flush')){
1853         $class->log->$coderef();
1854     }
1855     return $status;
1856 }
1857
1858 =head2 $class->prepare( @arguments )
1859
1860 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1861 etc.).
1862
1863 =cut
1864
1865 has _uploadtmp => (
1866     is => 'ro',
1867     predicate => '_has_uploadtmp',
1868 );
1869
1870 sub prepare {
1871     my ( $class, @arguments ) = @_;
1872
1873     # XXX
1874     # After the app/ctxt split, this should become an attribute based on something passed
1875     # into the application.
1876     $class->context_class( ref $class || $class ) unless $class->context_class;
1877
1878     my $uploadtmp = $class->config->{uploadtmp};
1879     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
1880
1881     $c->response->_context($c);
1882
1883     #surely this is not the most efficient way to do things...
1884     $c->stats($class->stats_class->new)->enable($c->use_stats);
1885     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1886         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1887     }
1888
1889     try {
1890         # Allow engine to direct the prepare flow (for POE)
1891         if ( my $prepare = $c->engine->can('prepare') ) {
1892             $c->engine->$prepare( $c, @arguments );
1893         }
1894         else {
1895             $c->prepare_request(@arguments);
1896             $c->prepare_connection;
1897             $c->prepare_query_parameters;
1898             $c->prepare_headers; # Just hooks, no longer needed - they just
1899             $c->prepare_cookies; # cause the lazy attribute on req to build
1900             $c->prepare_path;
1901
1902             # Prepare the body for reading, either by prepare_body
1903             # or the user, if they are using $c->read
1904             $c->prepare_read;
1905
1906             # Parse the body unless the user wants it on-demand
1907             unless ( ref($c)->config->{parse_on_demand} ) {
1908                 $c->prepare_body;
1909             }
1910         }
1911         $c->prepare_action;
1912     }
1913     # VERY ugly and probably shouldn't rely on ->finalize actually working
1914     catch {
1915         # failed prepare is always due to an invalid request, right?
1916         $c->response->status(400);
1917         $c->response->content_type('text/plain');
1918         $c->response->body('Bad Request');
1919         # Note we call finalize and then die here, which escapes
1920         # finalize being called in the enclosing block..
1921         # It in fact couldn't be called, as we don't return $c..
1922         # This is a mess - but I'm unsure you can fix this without
1923         # breaking compat for people doing crazy things (we should set
1924         # the 400 and just return the ctx here IMO, letting finalize get called
1925         # above...
1926         $c->finalize;
1927         die $_;
1928     };
1929
1930     $c->log_request;
1931
1932     return $c;
1933 }
1934
1935 =head2 $c->prepare_action
1936
1937 Prepares action. See L<Catalyst::Dispatcher>.
1938
1939 =cut
1940
1941 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1942
1943 =head2 $c->prepare_body
1944
1945 Prepares message body.
1946
1947 =cut
1948
1949 sub prepare_body {
1950     my $c = shift;
1951
1952     return if $c->request->_has_body;
1953
1954     # Initialize on-demand data
1955     $c->engine->prepare_body( $c, @_ );
1956     $c->prepare_parameters;
1957     $c->prepare_uploads;
1958 }
1959
1960 =head2 $c->prepare_body_chunk( $chunk )
1961
1962 Prepares a chunk of data before sending it to L<HTTP::Body>.
1963
1964 See L<Catalyst::Engine>.
1965
1966 =cut
1967
1968 sub prepare_body_chunk {
1969     my $c = shift;
1970     $c->engine->prepare_body_chunk( $c, @_ );
1971 }
1972
1973 =head2 $c->prepare_body_parameters
1974
1975 Prepares body parameters.
1976
1977 =cut
1978
1979 sub prepare_body_parameters {
1980     my $c = shift;
1981     $c->engine->prepare_body_parameters( $c, @_ );
1982 }
1983
1984 =head2 $c->prepare_connection
1985
1986 Prepares connection.
1987
1988 =cut
1989
1990 sub prepare_connection {
1991     my $c = shift;
1992     # XXX - This is called on the engine (not the request) to maintain
1993     #       Engine::PSGI back compat.
1994     $c->engine->prepare_connection($c);
1995 }
1996
1997 =head2 $c->prepare_cookies
1998
1999 Prepares cookies by ensuring that the attribute on the request
2000 object has been built.
2001
2002 =cut
2003
2004 sub prepare_cookies { my $c = shift; $c->request->cookies }
2005
2006 =head2 $c->prepare_headers
2007
2008 Prepares request headers by ensuring that the attribute on the request
2009 object has been built.
2010
2011 =cut
2012
2013 sub prepare_headers { my $c = shift; $c->request->headers }
2014
2015 =head2 $c->prepare_parameters
2016
2017 Prepares parameters.
2018
2019 =cut
2020
2021 sub prepare_parameters {
2022     my $c = shift;
2023     $c->prepare_body_parameters;
2024     $c->engine->prepare_parameters( $c, @_ );
2025 }
2026
2027 =head2 $c->prepare_path
2028
2029 Prepares path and base.
2030
2031 =cut
2032
2033 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2034
2035 =head2 $c->prepare_query_parameters
2036
2037 Prepares query parameters.
2038
2039 =cut
2040
2041 sub prepare_query_parameters {
2042     my $c = shift;
2043
2044     $c->engine->prepare_query_parameters( $c, @_ );
2045 }
2046
2047 =head2 $c->log_request
2048
2049 Writes information about the request to the debug logs.  This includes:
2050
2051 =over 4
2052
2053 =item * Request method, path, and remote IP address
2054
2055 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2056
2057 =item * Request parameters
2058
2059 =item * File uploads
2060
2061 =back
2062
2063 =cut
2064
2065 sub log_request {
2066     my $c = shift;
2067
2068     return unless $c->debug;
2069
2070     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2071     my $request = $dump->[1];
2072
2073     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2074     $method ||= '';
2075     $path = '/' unless length $path;
2076     $address ||= '';
2077     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2078
2079     $c->log_request_headers($request->headers);
2080
2081     if ( my $keywords = $request->query_keywords ) {
2082         $c->log->debug("Query keywords are: $keywords");
2083     }
2084
2085     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2086
2087     $c->log_request_uploads($request);
2088 }
2089
2090 =head2 $c->log_response
2091
2092 Writes information about the response to the debug logs by calling
2093 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2094
2095 =cut
2096
2097 sub log_response {
2098     my $c = shift;
2099
2100     return unless $c->debug;
2101
2102     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2103     my $response = $dump->[1];
2104
2105     $c->log_response_status_line($response);
2106     $c->log_response_headers($response->headers);
2107 }
2108
2109 =head2 $c->log_response_status_line($response)
2110
2111 Writes one line of information about the response to the debug logs.  This includes:
2112
2113 =over 4
2114
2115 =item * Response status code
2116
2117 =item * Content-Type header (if present)
2118
2119 =item * Content-Length header (if present)
2120
2121 =back
2122
2123 =cut
2124
2125 sub log_response_status_line {
2126     my ($c, $response) = @_;
2127
2128     $c->log->debug(
2129         sprintf(
2130             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2131             $response->status                            || 'unknown',
2132             $response->headers->header('Content-Type')   || 'unknown',
2133             $response->headers->header('Content-Length') || 'unknown'
2134         )
2135     );
2136 }
2137
2138 =head2 $c->log_response_headers($headers);
2139
2140 Hook method which can be wrapped by plugins to log the response headers.
2141 No-op in the default implementation.
2142
2143 =cut
2144
2145 sub log_response_headers {}
2146
2147 =head2 $c->log_request_parameters( query => {}, body => {} )
2148
2149 Logs request parameters to debug logs
2150
2151 =cut
2152
2153 sub log_request_parameters {
2154     my $c          = shift;
2155     my %all_params = @_;
2156
2157     return unless $c->debug;
2158
2159     my $column_width = Catalyst::Utils::term_width() - 44;
2160     foreach my $type (qw(query body)) {
2161         my $params = $all_params{$type};
2162         next if ! keys %$params;
2163         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2164         for my $key ( sort keys %$params ) {
2165             my $param = $params->{$key};
2166             my $value = defined($param) ? $param : '';
2167             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2168         }
2169         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2170     }
2171 }
2172
2173 =head2 $c->log_request_uploads
2174
2175 Logs file uploads included in the request to the debug logs.
2176 The parameter name, filename, file type, and file size are all included in
2177 the debug logs.
2178
2179 =cut
2180
2181 sub log_request_uploads {
2182     my $c = shift;
2183     my $request = shift;
2184     return unless $c->debug;
2185     my $uploads = $request->uploads;
2186     if ( keys %$uploads ) {
2187         my $t = Text::SimpleTable->new(
2188             [ 12, 'Parameter' ],
2189             [ 26, 'Filename' ],
2190             [ 18, 'Type' ],
2191             [ 9,  'Size' ]
2192         );
2193         for my $key ( sort keys %$uploads ) {
2194             my $upload = $uploads->{$key};
2195             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2196                 $t->row( $key, $u->filename, $u->type, $u->size );
2197             }
2198         }
2199         $c->log->debug( "File Uploads are:\n" . $t->draw );
2200     }
2201 }
2202
2203 =head2 $c->log_request_headers($headers);
2204
2205 Hook method which can be wrapped by plugins to log the request headers.
2206 No-op in the default implementation.
2207
2208 =cut
2209
2210 sub log_request_headers {}
2211
2212 =head2 $c->log_headers($type => $headers)
2213
2214 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2215
2216 =cut
2217
2218 sub log_headers {
2219     my $c       = shift;
2220     my $type    = shift;
2221     my $headers = shift;    # an HTTP::Headers instance
2222
2223     return unless $c->debug;
2224
2225     my $column_width = Catalyst::Utils::term_width() - 28;
2226     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2227     $headers->scan(
2228         sub {
2229             my ( $name, $value ) = @_;
2230             $t->row( $name, $value );
2231         }
2232     );
2233     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2234 }
2235
2236
2237 =head2 $c->prepare_read
2238
2239 Prepares the input for reading.
2240
2241 =cut
2242
2243 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2244
2245 =head2 $c->prepare_request
2246
2247 Prepares the engine request.
2248
2249 =cut
2250
2251 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2252
2253 =head2 $c->prepare_uploads
2254
2255 Prepares uploads.
2256
2257 =cut
2258
2259 sub prepare_uploads {
2260     my $c = shift;
2261
2262     $c->engine->prepare_uploads( $c, @_ );
2263 }
2264
2265 =head2 $c->prepare_write
2266
2267 Prepares the output for writing.
2268
2269 =cut
2270
2271 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2272
2273 =head2 $c->request_class
2274
2275 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2276
2277 =head2 $c->response_class
2278
2279 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2280
2281 =head2 $c->read( [$maxlength] )
2282
2283 Reads a chunk of data from the request body. This method is designed to
2284 be used in a while loop, reading C<$maxlength> bytes on every call.
2285 C<$maxlength> defaults to the size of the request if not specified.
2286
2287 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2288 directly.
2289
2290 Warning: If you use read(), Catalyst will not process the body,
2291 so you will not be able to access POST parameters or file uploads via
2292 $c->request.  You must handle all body parsing yourself.
2293
2294 =cut
2295
2296 sub read { my $c = shift; return $c->request->read( @_ ) }
2297
2298 =head2 $c->run
2299
2300 Starts the engine.
2301
2302 =cut
2303
2304 sub run {
2305   my $app = shift;
2306   $app->_make_immutable_if_needed;
2307   $app->engine_loader->needs_psgi_engine_compat_hack ?
2308     $app->engine->run($app, @_) :
2309       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2310 }
2311
2312 sub _make_immutable_if_needed {
2313     my $class = shift;
2314     my $meta = Class::MOP::get_metaclass_by_name($class);
2315     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2316     if (
2317         $meta->is_immutable
2318         && ! { $meta->immutable_options }->{replace_constructor}
2319         && $isa_ca
2320     ) {
2321         warn("You made your application class ($class) immutable, "
2322             . "but did not inline the\nconstructor. "
2323             . "This will break catalyst, as your app \@ISA "
2324             . "Class::Accessor(::Fast)?\nPlease pass "
2325             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2326     }
2327     unless ($meta->is_immutable) {
2328         # XXX - FIXME warning here as you should make your app immutable yourself.
2329         $meta->make_immutable(
2330             replace_constructor => 1,
2331         );
2332     }
2333 }
2334
2335 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2336
2337 Sets an action in a given namespace.
2338
2339 =cut
2340
2341 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2342
2343 =head2 $c->setup_actions($component)
2344
2345 Sets up actions for a component.
2346
2347 =cut
2348
2349 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2350
2351 =head2 $c->setup_config
2352
2353 =cut
2354
2355 sub setup_config {
2356     my $class = shift;
2357
2358     my %args = %{ $class->config || {} };
2359
2360     my $container_class;
2361
2362     if ( exists $args{container_class} ) {
2363         $container_class = delete $args{container_class};
2364         Class::MOP::load_class($container_class);
2365     }
2366     else {
2367         $container_class = Class::MOP::load_first_existing_class("${class}::Container", 'Catalyst::IOC::Container');
2368     }
2369
2370     my $container = $container_class->new( %args, name => $class );
2371     $class->container($container);
2372
2373     my $config = $container->resolve( service => 'config' );
2374     $class->config($config);
2375     $class->finalize_config; # back-compat
2376 }
2377
2378 =head2 $c->finalize_config
2379
2380 =cut
2381
2382 sub finalize_config { }
2383
2384 =head2 $c->setup_components
2385
2386 This method is called internally to set up the application's components.
2387
2388 It finds modules by calling the L<locate_components> method, expands them to
2389 package names with the $container->expand_component_module method, and then
2390 installs each component into the application.
2391
2392 The C<setup_components> config option is passed to both of the above methods.
2393
2394 =cut
2395
2396 sub setup_components { shift->container->setup_components }
2397
2398 =head2 locate_components
2399
2400 =cut
2401
2402 sub locate_components {
2403     my $class = shift;
2404
2405     $class->log->warn('The locate_components method has been deprecated.');
2406     $class->log->warn('Please read Catalyst::IOC::Container documentation to');
2407     $class->log->warn('update your application.');
2408
2409     # XXX think about ditching this sort entirely
2410     return sort { length $a <=> length $b }
2411         @{ $class->container->resolve( service => 'locate_components' ) };
2412 }
2413
2414 =head2 $c->setup_dispatcher
2415
2416 Sets up dispatcher.
2417
2418 =cut
2419
2420 sub setup_dispatcher {
2421     my ( $class, $dispatcher ) = @_;
2422
2423     if ($dispatcher) {
2424         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2425     }
2426
2427     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2428         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2429     }
2430
2431     unless ($dispatcher) {
2432         $dispatcher = $class->dispatcher_class;
2433     }
2434
2435     Class::MOP::load_class($dispatcher);
2436
2437     # dispatcher instance
2438     $class->dispatcher( $dispatcher->new );
2439 }
2440
2441 =head2 $c->setup_engine
2442
2443 Sets up engine.
2444
2445 =cut
2446
2447 sub engine_class {
2448     my ($class, $requested_engine) = @_;
2449
2450     if (!$class->engine_loader || $requested_engine) {
2451         $class->engine_loader(
2452             Catalyst::EngineLoader->new({
2453                 application_name => $class,
2454                 (defined $requested_engine
2455                      ? (catalyst_engine_class => $requested_engine) : ()),
2456             }),
2457         );
2458     }
2459
2460     $class->engine_loader->catalyst_engine_class;
2461 }
2462
2463 sub setup_engine {
2464     my ($class, $requested_engine) = @_;
2465
2466     my $engine = do {
2467         my $loader = $class->engine_loader;
2468
2469         if (!$loader || $requested_engine) {
2470             $loader = Catalyst::EngineLoader->new({
2471                 application_name => $class,
2472                 (defined $requested_engine
2473                      ? (requested_engine => $requested_engine) : ()),
2474             }),
2475
2476             $class->engine_loader($loader);
2477         }
2478
2479         $loader->catalyst_engine_class;
2480     };
2481
2482     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2483     return if $class->loading_psgi_file;
2484
2485     Class::MOP::load_class($engine);
2486
2487     if ($ENV{MOD_PERL}) {
2488         my $apache = $class->engine_loader->auto;
2489
2490         my $meta = find_meta($class);
2491         my $was_immutable = $meta->is_immutable;
2492         my %immutable_options = $meta->immutable_options;
2493         $meta->make_mutable if $was_immutable;
2494
2495         $meta->add_method(handler => sub {
2496             my $r = shift;
2497             my $psgi_app = $class->_finalized_psgi_app;
2498             $apache->call_app($r, $psgi_app);
2499         });
2500
2501         $meta->make_immutable(%immutable_options) if $was_immutable;
2502     }
2503
2504     $class->engine( $engine->new );
2505
2506     return;
2507 }
2508
2509 sub _finalized_psgi_app {
2510     my ($app) = @_;
2511
2512     unless ($app->_psgi_app) {
2513         my $psgi_app = $app->_setup_psgi_app;
2514         $app->_psgi_app($psgi_app);
2515     }
2516
2517     return $app->_psgi_app;
2518 }
2519
2520 sub _setup_psgi_app {
2521     my ($app) = @_;
2522
2523     for my $home (Path::Class::Dir->new($app->config->{home})) {
2524         my $psgi_file = $home->file(
2525             Catalyst::Utils::appprefix($app) . '.psgi',
2526         );
2527
2528         next unless -e $psgi_file;
2529
2530         # If $psgi_file calls ->setup_engine, it's doing so to load
2531         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2532         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2533         # anyway. So set a flag (ick) that tells setup_engine not to populate
2534         # $c->engine or do any other things we might regret.
2535
2536         $app->loading_psgi_file(1);
2537         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2538         $app->loading_psgi_file(0);
2539
2540         return $psgi_app
2541             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2542
2543         warn <<"EOW";
2544 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2545
2546 Its content has been ignored. Please consult the Catalyst::Upgrading
2547 documentation on how to upgrade from Catalyst::Engine::PSGI.
2548 EOW
2549     }
2550
2551     return $app->apply_default_middlewares($app->psgi_app);
2552 }
2553
2554 =head2 $c->apply_default_middlewares
2555
2556 Adds the following L<Plack> middlewares to your application, since they are
2557 useful and commonly needed:
2558
2559 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2560 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2561 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2562 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2563 applied since this middleware is smart enough to conditionally apply itself).
2564
2565 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2566 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2567 $ENV{SCRIPT_NAME}
2568
2569 =cut
2570
2571
2572 sub apply_default_middlewares {
2573     my ($app, $psgi_app) = @_;
2574
2575     $psgi_app = Plack::Middleware::Conditional->wrap(
2576         $psgi_app,
2577         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2578         condition => sub {
2579             my ($env) = @_;
2580             return if $app->config->{ignore_frontend_proxy};
2581             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2582                 || $app->config->{using_frontend_proxy};
2583         },
2584     );
2585
2586     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2587     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2588     $psgi_app = Plack::Middleware::Conditional->wrap(
2589         $psgi_app,
2590         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2591         condition => sub {
2592             my ($env) = @_;
2593             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2594             return unless $1 < 4.23;
2595             1;
2596         },
2597     );
2598
2599     # we're applying this unconditionally as the middleware itself already makes
2600     # sure it doesn't fuck things up if it's not running under one of the right
2601     # IIS versions
2602     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2603
2604     # And another IIS issue, this time with IIS7.
2605     $psgi_app = Plack::Middleware::Conditional->wrap(
2606         $psgi_app,
2607         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2608         condition => sub {
2609             my ($env) = @_;
2610             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2611         },
2612     );
2613
2614     return $psgi_app;
2615 }
2616
2617 =head2 $c->psgi_app
2618
2619 Returns a PSGI application code reference for the catalyst application
2620 C<$c>. This is the bare application without any middlewares
2621 applied. C<${myapp}.psgi> is not taken into account.
2622
2623 This is what you want to be using to retrieve the PSGI application code
2624 reference of your Catalyst application for use in F<.psgi> files.
2625
2626 =cut
2627
2628 sub psgi_app {
2629     my ($app) = @_;
2630     return $app->engine->build_psgi_app($app);
2631 }
2632
2633 =head2 $c->setup_home
2634
2635 Sets up the home directory.
2636
2637 =cut
2638
2639 sub setup_home {
2640     my ( $class, $home_flag ) = @_;
2641
2642     my $home = $class->container->resolve(
2643         service    => 'home',
2644         parameters => {
2645             home_flag => $home_flag
2646         },
2647     );
2648
2649     if ($home) {
2650         #I remember recently being scolded for assigning config values like this
2651         $class->config->{home} ||= $home;
2652         $class->config->{root} ||= $class->container->resolve(service => 'root_dir');
2653     }
2654 }
2655
2656 =head2 $c->setup_log
2657
2658 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2659 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2660 log to.
2661
2662 This method also installs a C<debug> method that returns a true value into the
2663 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2664 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2665
2666 Note that if the log has already been setup, by either a previous call to
2667 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2668 that this method won't actually set up the log object.
2669
2670 =cut
2671
2672 sub setup_log {
2673     my ( $class, $levels ) = @_;
2674
2675     $levels ||= '';
2676     $levels =~ s/^\s+//;
2677     $levels =~ s/\s+$//;
2678     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2679
2680     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2681     if ( defined $env_debug ) {
2682         $levels{debug} = 1 if $env_debug; # Ugly!
2683         delete($levels{debug}) unless $env_debug;
2684     }
2685
2686     unless ( $class->log ) {
2687         $class->log( Catalyst::Log->new(keys %levels) );
2688     }
2689
2690     if ( $levels{debug} ) {
2691         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2692         $class->log->debug('Debug messages enabled');
2693     }
2694 }
2695
2696 =head2 $c->setup_plugins
2697
2698 Sets up plugins.
2699
2700 =cut
2701
2702 =head2 $c->setup_stats
2703
2704 Sets up timing statistics class.
2705
2706 =cut
2707
2708 sub setup_stats {
2709     my ( $class, $stats ) = @_;
2710
2711     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2712
2713     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2714     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2715         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2716         $class->log->debug('Statistics enabled');
2717     }
2718 }
2719
2720
2721 =head2 $c->registered_plugins
2722
2723 Returns a sorted list of the plugins which have either been stated in the
2724 import list.
2725
2726 If passed a given plugin name, it will report a boolean value indicating
2727 whether or not that plugin is loaded.  A fully qualified name is required if
2728 the plugin name does not begin with C<Catalyst::Plugin::>.
2729
2730  if ($c->registered_plugins('Some::Plugin')) {
2731      ...
2732  }
2733
2734 =cut
2735
2736 {
2737
2738     sub registered_plugins {
2739         my $proto = shift;
2740         return sort keys %{ $proto->_plugins } unless @_;
2741         my $plugin = shift;
2742         return 1 if exists $proto->_plugins->{$plugin};
2743         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2744     }
2745
2746     sub _register_plugin {
2747         my ( $proto, $plugin, $instant ) = @_;
2748         my $class = ref $proto || $proto;
2749
2750         Class::MOP::load_class( $plugin );
2751         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2752             if $plugin->isa( 'Catalyst::Component' );
2753         my $plugin_meta = Moose::Meta::Class->create($plugin);
2754         if (!$plugin_meta->has_method('new')
2755             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
2756             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
2757         }
2758         if (!$instant && !$proto->_plugins->{$plugin}) {
2759             my $meta = Class::MOP::get_metaclass_by_name($class);
2760             $meta->superclasses($plugin, $meta->superclasses);
2761         }
2762         $proto->_plugins->{$plugin} = 1;
2763         return $class;
2764     }
2765
2766     sub setup_plugins {
2767         my ( $class, $plugins ) = @_;
2768
2769         $class->_plugins( {} ) unless $class->_plugins;
2770         $plugins = Data::OptList::mkopt($plugins || []);
2771
2772         my @plugins = map {
2773             [ Catalyst::Utils::resolve_namespace(
2774                   $class . '::Plugin',
2775                   'Catalyst::Plugin', $_->[0]
2776               ),
2777               $_->[1],
2778             ]
2779          } @{ $plugins };
2780
2781         for my $plugin ( reverse @plugins ) {
2782             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2783             my $meta = find_meta($plugin->[0]);
2784             next if $meta && $meta->isa('Moose::Meta::Role');
2785
2786             $class->_register_plugin($plugin->[0]);
2787         }
2788
2789         my @roles =
2790             map  { $_->[0]->name, $_->[1] }
2791             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2792             map  { [find_meta($_->[0]), $_->[1]] }
2793             @plugins;
2794
2795         Moose::Util::apply_all_roles(
2796             $class => @roles
2797         ) if @roles;
2798     }
2799 }
2800
2801 =head2 $c->stack
2802
2803 Returns an arrayref of the internal execution stack (actions that are
2804 currently executing).
2805
2806 =head2 $c->stats
2807
2808 Returns the current timing statistics object. By default Catalyst uses
2809 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2810 L<< stats_class|/"$c->stats_class" >>.
2811
2812 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2813 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2814 profile explicitly, although MyApp.pm still won't profile nor output anything
2815 by itself.
2816
2817 =head2 $c->stats_class
2818
2819 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2820
2821 =head2 $c->use_stats
2822
2823 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2824
2825 Note that this is a static method, not an accessor and should be overridden
2826 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2827
2828 =cut
2829
2830 sub use_stats { 0 }
2831
2832
2833 =head2 $c->write( $data )
2834
2835 Writes $data to the output stream. When using this method directly, you
2836 will need to manually set the C<Content-Length> header to the length of
2837 your output data, if known.
2838
2839 =cut
2840
2841 sub write {
2842     my $c = shift;
2843
2844     # Finalize headers if someone manually writes output (for compat)
2845     $c->finalize_headers;
2846
2847     return $c->response->write( @_ );
2848 }
2849
2850 =head2 version
2851
2852 Returns the Catalyst version number. Mostly useful for "powered by"
2853 messages in template systems.
2854
2855 =cut
2856
2857 sub version { return $Catalyst::VERSION }
2858
2859 =head1 CONFIGURATION
2860
2861 There are a number of 'base' config variables which can be set:
2862
2863 =over
2864
2865 =item *
2866
2867 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2868
2869 =item *
2870
2871 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2872
2873 =item *
2874
2875 C<home> - The application home directory. In an uninstalled application,
2876 this is the top level application directory. In an installed application,
2877 this will be the directory containing C<< MyApp.pm >>.
2878
2879 =item *
2880
2881 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2882
2883 =item *
2884
2885 C<name> - The name of the application in debug messages and the debug and
2886 welcome screens
2887
2888 =item *
2889
2890 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2891 until it is accessed. This allows you to (for example) check authentication (and reject
2892 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
2893
2894 =item *
2895
2896 C<root> - The root directory for templates. Usually this is just a
2897 subdirectory of the home directory, but you can set it to change the
2898 templates to a different directory.
2899
2900 =item *
2901
2902 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2903 to be shown in hit debug tables in the test server.
2904
2905 =item *
2906
2907 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
2908 variable should be used for determining the request path.
2909
2910 Most web server environments pass the requested path to the application using environment variables,
2911 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
2912 exposed as C<< $c->request->base >>) and the request path below that base.
2913
2914 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
2915 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
2916
2917 =over
2918
2919 =item use_request_uri_for_path => 0
2920
2921 This is the default (and the) traditional method that Catalyst has used for determining the path information.
2922 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
2923 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
2924 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
2925
2926 However this method has the major disadvantage that it is impossible to correctly decode some elements
2927 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
2928 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
2929 can't distinguish / vs %2F in paths (in addition to other encoded values).
2930
2931 =item use_request_uri_for_path => 1
2932
2933 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
2934 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
2935 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
2936
2937 Given that this method of path resolution is provably more correct, it is recommended that you use
2938 this unless you have a specific need to deploy your application in a non-standard environment, and you are
2939 aware of the implications of not being able to handle encoded URI paths correctly.
2940
2941 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
2942 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
2943 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
2944 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
2945 C<< $c->request->base >> will be incorrect.
2946
2947 =back
2948
2949 =item *
2950
2951 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2952
2953 =back
2954
2955 =head1 INTERNAL ACTIONS
2956
2957 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2958 C<_ACTION>, and C<_END>. These are by default not shown in the private
2959 action table, but you can make them visible with a config parameter.
2960
2961     MyApp->config(show_internal_actions => 1);
2962
2963 =head1 ON-DEMAND PARSER
2964
2965 The request body is usually parsed at the beginning of a request,
2966 but if you want to handle input yourself, you can enable on-demand
2967 parsing with a config parameter.
2968
2969     MyApp->config(parse_on_demand => 1);
2970
2971 =head1 PROXY SUPPORT
2972
2973 Many production servers operate using the common double-server approach,
2974 with a lightweight frontend web server passing requests to a larger
2975 backend server. An application running on the backend server must deal
2976 with two problems: the remote user always appears to be C<127.0.0.1> and
2977 the server's hostname will appear to be C<localhost> regardless of the
2978 virtual host that the user connected through.
2979
2980 Catalyst will automatically detect this situation when you are running
2981 the frontend and backend servers on the same machine. The following
2982 changes are made to the request.
2983
2984     $c->req->address is set to the user's real IP address, as read from
2985     the HTTP X-Forwarded-For header.
2986
2987     The host value for $c->req->base and $c->req->uri is set to the real
2988     host, as read from the HTTP X-Forwarded-Host header.
2989
2990 Additionally, you may be running your backend application on an insecure
2991 connection (port 80) while your frontend proxy is running under SSL.  If there
2992 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2993 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2994 be created properly.
2995
2996 In the case of passing in:
2997
2998     X-Forwarded-Port: 443
2999
3000 All calls to C<uri_for> will result in an https link, as is expected.
3001
3002 Obviously, your web server must support these headers for this to work.
3003
3004 In a more complex server farm environment where you may have your
3005 frontend proxy server(s) on different machines, you will need to set a
3006 configuration option to tell Catalyst to read the proxied data from the
3007 headers.
3008
3009     MyApp->config(using_frontend_proxy => 1);
3010
3011 If you do not wish to use the proxy support at all, you may set:
3012
3013     MyApp->config(ignore_frontend_proxy => 0);
3014
3015 =head2 Note about psgi files
3016
3017 Note that if you supply your own .psgi file, calling
3018 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3019
3020 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3021 in your psgi, for example:
3022
3023     builder {
3024         enable "Plack::Middleware::ReverseProxy";
3025         MyApp->psgi_app
3026     };
3027
3028 This will unconditionally add the ReverseProxy support, or you need to call
3029 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3030 apply the support depending upon your config).
3031
3032 See L<Catalyst::PSGI> for more information.
3033
3034 =head1 THREAD SAFETY
3035
3036 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3037 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3038 believe the Catalyst core to be thread-safe.
3039
3040 If you plan to operate in a threaded environment, remember that all other
3041 modules you are using must also be thread-safe. Some modules, most notably
3042 L<DBD::SQLite>, are not thread-safe.
3043
3044 =head1 SUPPORT
3045
3046 IRC:
3047
3048     Join #catalyst on irc.perl.org.
3049
3050 Mailing Lists:
3051
3052     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3053     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3054
3055 Web:
3056
3057     http://catalyst.perl.org
3058
3059 Wiki:
3060
3061     http://dev.catalyst.perl.org
3062
3063 =head1 SEE ALSO
3064
3065 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3066
3067 =head2 L<Catalyst::Manual> - The Catalyst Manual
3068
3069 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3070
3071 =head2 L<Catalyst::Engine> - Core engine
3072
3073 =head2 L<Catalyst::Log> - Log class.
3074
3075 =head2 L<Catalyst::Request> - Request object
3076
3077 =head2 L<Catalyst::Response> - Response object
3078
3079 =head2 L<Catalyst::Test> - The test suite.
3080
3081 =head1 PROJECT FOUNDER
3082
3083 sri: Sebastian Riedel <sri@cpan.org>
3084
3085 =head1 CONTRIBUTORS
3086
3087 abw: Andy Wardley
3088
3089 acme: Leon Brocard <leon@astray.com>
3090
3091 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3092
3093 Andrew Bramble
3094
3095 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3096
3097 Andrew Ruthven
3098
3099 André Walker
3100
3101 andyg: Andy Grundman <andy@hybridized.org>
3102
3103 audreyt: Audrey Tang
3104
3105 bricas: Brian Cassidy <bricas@cpan.org>
3106
3107 Caelum: Rafael Kitover <rkitover@io.com>
3108
3109 chansen: Christian Hansen
3110
3111 chicks: Christopher Hicks
3112
3113 Chisel Wright C<pause@herlpacker.co.uk>
3114
3115 Danijel Milicevic C<me@danijel.de>
3116
3117 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3118
3119 David Naughton, C<naughton@umn.edu>
3120
3121 David E. Wheeler
3122
3123 dhoss: Devin Austin <dhoss@cpan.org>
3124
3125 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3126
3127 Drew Taylor
3128
3129 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3130
3131 esskar: Sascha Kiefer
3132
3133 fireartist: Carl Franks <cfranks@cpan.org>
3134
3135 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3136
3137 gabb: Danijel Milicevic
3138
3139 Gary Ashton Jones
3140
3141 Gavin Henry C<ghenry@perl.me.uk>
3142
3143 Geoff Richards
3144
3145 groditi: Guillermo Roditi <groditi@gmail.com>
3146
3147 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3148
3149 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3150
3151 jcamacho: Juan Camacho
3152
3153 jester: Jesse Sheidlower C<jester@panix.com>
3154
3155 jhannah: Jay Hannah <jay@jays.net>
3156
3157 Jody Belka
3158
3159 Johan Lindstrom
3160
3161 jon: Jon Schutz <jjschutz@cpan.org>
3162
3163 Jonathan Rockway C<< <jrockway@cpan.org> >>
3164
3165 Kieren Diment C<kd@totaldatasolution.com>
3166
3167 konobi: Scott McWhirter <konobi@cpan.org>
3168
3169 marcus: Marcus Ramberg <mramberg@cpan.org>
3170
3171 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3172
3173 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3174
3175 mugwump: Sam Vilain
3176
3177 naughton: David Naughton
3178
3179 ningu: David Kamholz <dkamholz@cpan.org>
3180
3181 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3182
3183 numa: Dan Sully <daniel@cpan.org>
3184
3185 obra: Jesse Vincent
3186
3187 Octavian Rasnita
3188
3189 omega: Andreas Marienborg
3190
3191 Oleg Kostyuk <cub.uanic@gmail.com>
3192
3193 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3194
3195 rafl: Florian Ragwitz <rafl@debian.org>
3196
3197 random: Roland Lammel <lammel@cpan.org>
3198
3199 Robert Sedlacek C<< <rs@474.at> >>
3200
3201 SpiceMan: Marcel Montes
3202
3203 sky: Arthur Bergman
3204
3205 szbalint: Balint Szilakszi <szbalint@cpan.org>
3206
3207 t0m: Tomas Doran <bobtfish@bobtfish.net>
3208
3209 Ulf Edvinsson
3210
3211 Viljo Marrandi C<vilts@yahoo.com>
3212
3213 Will Hawes C<info@whawes.co.uk>
3214
3215 willert: Sebastian Willert <willert@cpan.org>
3216
3217 wreis: Wallace Reis <wallace@reis.org.br>
3218
3219 Yuval Kogman, C<nothingmuch@woobling.org>
3220
3221 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3222
3223 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3224
3225 =head1 COPYRIGHT
3226
3227 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3228
3229 =head1 LICENSE
3230
3231 This library is free software. You can redistribute it and/or modify it under
3232 the same terms as Perl itself.
3233
3234 =cut
3235
3236 no Moose;
3237
3238 __PACKAGE__->meta->make_immutable;
3239
3240 1;