lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53
  54 BEGIN { require 5.008003; }
  55
  56 has stack => (is => 'ro', default => sub { [] });
  57 has state => (is => 'rw', default => 0);
  58 has stats => (is => 'rw');
  59 has action => (is => 'rw');
  60 has counter => (is => 'rw', default => sub { {} });
  61 has request => (
  62     is => 'rw',
  63     default => sub {
  64         my $self = shift;
  65         $self->request_class->new($self->_build_request_constructor_args);
  66     },
  67     lazy => 1,
  68 );
  69 sub _build_request_constructor_args {
  70     my $self = shift;
  71     my %p = ( _log => $self->log );
  72     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  73     $p{data_handlers} = {$self->registered_data_handlers};
  74     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  75       if $self->config->{use_hash_multivalue_in_request};
  76     \%p;
  77 }
  78
  79 has response => (
  80     is => 'rw',
  81     default => sub {
  82         my $self = shift;
  83         $self->response_class->new($self->_build_response_constructor_args);
  84     },
  85     lazy => 1,
  86 );
  87 sub _build_response_constructor_args {
  88     my $self = shift;
  89     { _log => $self->log };
  90 }
  91
  92 has namespace => (is => 'rw');
  93
  94 sub depth { scalar @{ shift->stack || [] }; }
  95 sub comp { shift->component(@_) }
  96
  97 sub req {
  98     my $self = shift; return $self->request(@_);
  99 }
 100 sub res {
 101     my $self = shift; return $self->response(@_);
 102 }
 103
 104 # For backwards compatibility
 105 sub finalize_output { shift->finalize_body(@_) };
 106
 107 # For statistics
 108 our $COUNT     = 1;
 109 our $START     = time;
 110 our $RECURSION = 1000;
 111 our $DETACH    = Catalyst::Exception::Detach->new;
 112 our $GO        = Catalyst::Exception::Go->new;
 113
 114 #I imagine that very few of these really need to be class variables. if any.
 115 #maybe we should just make them attributes with a default?
 116 __PACKAGE__->mk_classdata($_)
 117   for qw/components arguments dispatcher engine log dispatcher_class
 118   engine_loader context_class request_class response_class stats_class
 119   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 120   _data_handlers/;
 121
 122 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 123 __PACKAGE__->request_class('Catalyst::Request');
 124 __PACKAGE__->response_class('Catalyst::Response');
 125 __PACKAGE__->stats_class('Catalyst::Stats');
 126
 127 # Remember to update this in Catalyst::Runtime as well!
 128
 129 our $VERSION = '5.90069_002';
 130
 131 sub import {
 132     my ( $class, @arguments ) = @_;
 133
 134     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 135     # callers @ISA.
 136     return unless $class eq 'Catalyst';
 137
 138     my $caller = caller();
 139     return if $caller eq 'main';
 140
 141     my $meta = Moose::Meta::Class->initialize($caller);
 142     unless ( $caller->isa('Catalyst') ) {
 143         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 144         $meta->superclasses(@superclasses);
 145     }
 146     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 147     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 148
 149     unless( $meta->has_method('meta') ){
 150         if ($Moose::VERSION >= 1.15) {
 151             $meta->_add_meta_method('meta');
 152         }
 153         else {
 154             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 155         }
 156     }
 157
 158     $caller->arguments( [@arguments] );
 159     $caller->setup_home;
 160 }
 161
 162 sub _application { $_[0] }
 163
 164 =encoding UTF-8
 165
 166 =head1 NAME
 167
 168 Catalyst - The Elegant MVC Web Application Framework
 169
 170 =head1 SYNOPSIS
 171
 172 See the L<Catalyst::Manual> distribution for comprehensive
 173 documentation and tutorials.
 174
 175     # Install Catalyst::Devel for helpers and other development tools
 176     # use the helper to create a new application
 177     catalyst.pl MyApp
 178
 179     # add models, views, controllers
 180     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 181     script/myapp_create.pl view MyTemplate TT
 182     script/myapp_create.pl controller Search
 183
 184     # built in testserver -- use -r to restart automatically on changes
 185     # --help to see all available options
 186     script/myapp_server.pl
 187
 188     # command line testing interface
 189     script/myapp_test.pl /yada
 190
 191     ### in lib/MyApp.pm
 192     use Catalyst qw/-Debug/; # include plugins here as well
 193
 194     ### In lib/MyApp/Controller/Root.pm (autocreated)
 195     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 196         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 197         $c->stash->{template} = 'foo.tt'; # set the template
 198         # lookup something from db -- stash vars are passed to TT
 199         $c->stash->{data} =
 200           $c->model('Database::Foo')->search( { country => $args[0] } );
 201         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 202             $c->forward( 'bar' ); # process another action
 203             # do something else after forward returns
 204         }
 205     }
 206
 207     # The foo.tt TT template can use the stash data from the database
 208     [% WHILE (item = data.next) %]
 209         [% item.foo %]
 210     [% END %]
 211
 212     # called for /bar/of/soap, /bar/of/soap/10, etc.
 213     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 214
 215     # called after all actions are finished
 216     sub end : Action {
 217         my ( $self, $c ) = @_;
 218         if ( scalar @{ $c->error } ) { ... } # handle errors
 219         return if $c->res->body; # already have a response
 220         $c->forward( 'MyApp::View::TT' ); # render template
 221     }
 222
 223 See L<Catalyst::Manual::Intro> for additional information.
 224
 225 =head1 DESCRIPTION
 226
 227 Catalyst is a modern framework for making web applications without the
 228 pain usually associated with this process. This document is a reference
 229 to the main Catalyst application. If you are a new user, we suggest you
 230 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 231
 232 See L<Catalyst::Manual> for more documentation.
 233
 234 Catalyst plugins can be loaded by naming them as arguments to the "use
 235 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 236 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 237 C<My::Module>.
 238
 239     use Catalyst qw/My::Module/;
 240
 241 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 242 fully qualify the name by using a unary plus:
 243
 244     use Catalyst qw/
 245         My::Module
 246         +Fully::Qualified::Plugin::Name
 247     /;
 248
 249 Special flags like C<-Debug> can also be specified as
 250 arguments when Catalyst is loaded:
 251
 252     use Catalyst qw/-Debug My::Module/;
 253
 254 The position of plugins and flags in the chain is important, because
 255 they are loaded in the order in which they appear.
 256
 257 The following flags are supported:
 258
 259 =head2 -Debug
 260
 261 Enables debug output. You can also force this setting from the system
 262 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 263 settings override the application, with <MYAPP>_DEBUG having the highest
 264 priority.
 265
 266 This sets the log level to 'debug' and enables full debug output on the
 267 error screen. If you only want the latter, see L<< $c->debug >>.
 268
 269 =head2 -Home
 270
 271 Forces Catalyst to use a specific home directory, e.g.:
 272
 273     use Catalyst qw[-Home=/usr/mst];
 274
 275 This can also be done in the shell environment by setting either the
 276 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 277 is replaced with the uppercased name of your application, any "::" in
 278 the name will be replaced with underscores, e.g. MyApp::Web should use
 279 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 280
 281 If none of these are set, Catalyst will attempt to automatically detect the
 282 home directory. If you are working in a development environment, Catalyst
 283 will try and find the directory containing either Makefile.PL, Build.PL,
 284 dist.ini, or cpanfile. If the application has been installed into the system
 285 (i.e. you have done C<make install>), then Catalyst will use the path to your
 286 application module, without the .pm extension (e.g., /foo/MyApp if your
 287 application was installed at /foo/MyApp.pm)
 288
 289 =head2 -Log
 290
 291     use Catalyst '-Log=warn,fatal,error';
 292
 293 Specifies a comma-delimited list of log levels.
 294
 295 =head2 -Stats
 296
 297 Enables statistics collection and reporting.
 298
 299    use Catalyst qw/-Stats=1/;
 300
 301 You can also force this setting from the system environment with CATALYST_STATS
 302 or <MYAPP>_STATS. The environment settings override the application, with
 303 <MYAPP>_STATS having the highest priority.
 304
 305 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 306
 307 =head1 METHODS
 308
 309 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 310
 311 =head2 $c->action
 312
 313 Returns a L<Catalyst::Action> object for the current action, which
 314 stringifies to the action name. See L<Catalyst::Action>.
 315
 316 =head2 $c->namespace
 317
 318 Returns the namespace of the current action, i.e., the URI prefix
 319 corresponding to the controller of the current action. For example:
 320
 321     # in Controller::Foo::Bar
 322     $c->namespace; # returns 'foo/bar';
 323
 324 =head2 $c->request
 325
 326 =head2 $c->req
 327
 328 Returns the current L<Catalyst::Request> object, giving access to
 329 information about the current client request (including parameters,
 330 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 331
 332 =head2 REQUEST FLOW HANDLING
 333
 334 =head2 $c->forward( $action [, \@arguments ] )
 335
 336 =head2 $c->forward( $class, $method, [, \@arguments ] )
 337
 338 This is one way of calling another action (method) in the same or
 339 a different controller. You can also use C<< $self->my_method($c, @args) >>
 340 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 341 in a different controller.
 342 The main difference is that 'forward' uses some of the Catalyst request
 343 cycle overhead, including debugging, which may be useful to you. On the
 344 other hand, there are some complications to using 'forward', restrictions
 345 on values returned from 'forward', and it may not handle errors as you prefer.
 346 Whether you use 'forward' or not is up to you; it is not considered superior to
 347 the other ways to call a method.
 348
 349 'forward' calls  another action, by its private name. If you give a
 350 class name but no method, C<process()> is called. You may also optionally
 351 pass arguments in an arrayref. The action will receive the arguments in
 352 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 353 C<< $c->req->args >> will be restored to the previous values.
 354
 355 Any data C<return>ed from the action forwarded to, will be returned by the
 356 call to forward.
 357
 358     my $foodata = $c->forward('/foo');
 359     $c->forward('index');
 360     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 361     $c->forward('View::TT');
 362
 363 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 364 an C<< eval { } >> around the call (actually
 365 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 366 exceptions thrown by the called action non-fatal and pushing them onto
 367 $c->error instead. If you want C<die> to propagate you need to do something
 368 like:
 369
 370     $c->forward('foo');
 371     die join "\n", @{ $c->error } if @{ $c->error };
 372
 373 Or make sure to always return true values from your actions and write
 374 your code like this:
 375
 376     $c->forward('foo') || return;
 377
 378 Another note is that C<< $c->forward >> always returns a scalar because it
 379 actually returns $c->state which operates in a scalar context.
 380 Thus, something like:
 381
 382     return @array;
 383
 384 in an action that is forwarded to is going to return a scalar,
 385 i.e. how many items are in that array, which is probably not what you want.
 386 If you need to return an array then return a reference to it,
 387 or stash it like so:
 388
 389     $c->stash->{array} = \@array;
 390
 391 and access it from the stash.
 392
 393 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 394
 395 =cut
 396
 397 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 398
 399 =head2 $c->detach( $action [, \@arguments ] )
 400
 401 =head2 $c->detach( $class, $method, [, \@arguments ] )
 402
 403 =head2 $c->detach()
 404
 405 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 406 doesn't return to the previous action when processing is finished.
 407
 408 When called with no arguments it escapes the processing chain entirely.
 409
 410 =cut
 411
 412 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 413
 414 =head2 $c->visit( $action [, \@arguments ] )
 415
 416 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 417
 418 =head2 $c->visit( $class, $method, [, \@arguments ] )
 419
 420 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 421
 422 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 423 but does a full dispatch, instead of just calling the new C<$action> /
 424 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 425 you go to are called, just like a new request.
 426
 427 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 428 This means, for example, that C<< $c->action >> methods such as
 429 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 430 L<reverse|Catalyst::Action/reverse> return information for the visited action
 431 when they are invoked within the visited action.  This is different from the
 432 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 433 continues to use the $c->action object from the caller action even when
 434 invoked from the called action.
 435
 436 C<< $c->stash >> is kept unchanged.
 437
 438 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 439 allows you to "wrap" another action, just as it would have been called by
 440 dispatching from a URL, while the analogous
 441 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 442 transfer control to another action as if it had been reached directly from a URL.
 443
 444 =cut
 445
 446 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 447
 448 =head2 $c->go( $action [, \@arguments ] )
 449
 450 =head2 $c->go( $action [, \@captures, \@arguments ] )
 451
 452 =head2 $c->go( $class, $method, [, \@arguments ] )
 453
 454 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 455
 456 The relationship between C<go> and
 457 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 458 the relationship between
 459 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 460 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 461 C<< $c->go >> will perform a full dispatch on the specified action or method,
 462 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 463 C<go> escapes the processing of the current request chain on completion, and
 464 does not return to its caller.
 465
 466 @arguments are arguments to the final destination of $action. @captures are
 467 arguments to the intermediate steps, if any, on the way to the final sub of
 468 $action.
 469
 470 =cut
 471
 472 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 473
 474 =head2 $c->response
 475
 476 =head2 $c->res
 477
 478 Returns the current L<Catalyst::Response> object, see there for details.
 479
 480 =head2 $c->stash
 481
 482 Returns a hashref to the stash, which may be used to store data and pass
 483 it between components during a request. You can also set hash keys by
 484 passing arguments. The stash is automatically sent to the view. The
 485 stash is cleared at the end of a request; it cannot be used for
 486 persistent storage (for this you must use a session; see
 487 L<Catalyst::Plugin::Session> for a complete system integrated with
 488 Catalyst).
 489
 490     $c->stash->{foo} = $bar;
 491     $c->stash( { moose => 'majestic', qux => 0 } );
 492     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 493
 494     # stash is automatically passed to the view for use in a template
 495     $c->forward( 'MyApp::View::TT' );
 496
 497 =cut
 498
 499 sub stash {
 500   my $c = shift;
 501   my $stash = Catalyst::Middleware::Stash->get($c->req->env);
 502   if(@_) {
 503     my $new_stash = @_ > 1 ? {@_} : $_[0];
 504     croak('stash takes a hash or hashref') unless ref $new_stash;
 505     foreach my $key ( keys %$new_stash ) {
 506       $stash->{$key} = $new_stash->{$key};
 507     }
 508   }
 509   return $stash;
 510 }
 511
 512 =head2 $c->error
 513
 514 =head2 $c->error($error, ...)
 515
 516 =head2 $c->error($arrayref)
 517
 518 Returns an arrayref containing error messages.  If Catalyst encounters an
 519 error while processing a request, it stores the error in $c->error.  This
 520 method should only be used to store fatal error messages.
 521
 522     my @error = @{ $c->error };
 523
 524 Add a new error.
 525
 526     $c->error('Something bad happened');
 527
 528 =cut
 529
 530 sub error {
 531     my $c = shift;
 532     if ( $_[0] ) {
 533         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 534         croak @$error unless ref $c;
 535         push @{ $c->{error} }, @$error;
 536     }
 537     elsif ( defined $_[0] ) { $c->{error} = undef }
 538     return $c->{error} || [];
 539 }
 540
 541
 542 =head2 $c->state
 543
 544 Contains the return value of the last executed action.
 545 Note that << $c->state >> operates in a scalar context which means that all
 546 values it returns are scalar.
 547
 548 =head2 $c->clear_errors
 549
 550 Clear errors.  You probably don't want to clear the errors unless you are
 551 implementing a custom error screen.
 552
 553 This is equivalent to running
 554
 555     $c->error(0);
 556
 557 =cut
 558
 559 sub clear_errors {
 560     my $c = shift;
 561     $c->error(0);
 562 }
 563
 564 =head2 $c->has_errors
 565
 566 Returns true if you have errors
 567
 568 =cut
 569
 570 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 571
 572 sub _comp_search_prefixes {
 573     my $c = shift;
 574     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 575 }
 576
 577 # search components given a name and some prefixes
 578 sub _comp_names_search_prefixes {
 579     my ( $c, $name, @prefixes ) = @_;
 580     my $appclass = ref $c || $c;
 581     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 582     $filter = qr/$filter/; # Compile regex now rather than once per loop
 583
 584     # map the original component name to the sub part that we will search against
 585     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 586         grep { /$filter/ } keys %{ $c->components };
 587
 588     # undef for a name will return all
 589     return keys %eligible if !defined $name;
 590
 591     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 592     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 593
 594     return @result if @result;
 595
 596     # if we were given a regexp to search against, we're done.
 597     return if $name->$_isa('Regexp');
 598
 599     # skip regexp fallback if configured
 600     return
 601         if $appclass->config->{disable_component_resolution_regex_fallback};
 602
 603     # regexp fallback
 604     $query  = qr/$name/i;
 605     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 606
 607     # no results? try against full names
 608     if( !@result ) {
 609         @result = grep { m{$query} } keys %eligible;
 610     }
 611
 612     # don't warn if we didn't find any results, it just might not exist
 613     if( @result ) {
 614         # Disgusting hack to work out correct method name
 615         my $warn_for = lc $prefixes[0];
 616         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 617            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 618            "component resolution is unreliable and unsafe.";
 619         my $short = $result[0];
 620         # remove the component namespace prefix
 621         $short =~ s/.*?(Model|Controller|View):://;
 622         my $shortmess = Carp::shortmess('');
 623         if ($shortmess =~ m#Catalyst/Plugin#) {
 624            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 625               "plugin's config";
 626         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 627            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 628               "component's config";
 629         } else {
 630            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 631               "but if you really wanted to search, pass in a regexp as the argument " .
 632               "like so: \$c->${warn_for}(qr/${name}/)";
 633         }
 634         $c->log->warn( "${msg}$shortmess" );
 635     }
 636
 637     return @result;
 638 }
 639
 640 # Find possible names for a prefix
 641 sub _comp_names {
 642     my ( $c, @prefixes ) = @_;
 643     my $appclass = ref $c || $c;
 644
 645     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 646
 647     my @names = map { s{$filter}{}; $_; }
 648         $c->_comp_names_search_prefixes( undef, @prefixes );
 649
 650     return @names;
 651 }
 652
 653 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 654 sub _filter_component {
 655     my ( $c, $comp, @args ) = @_;
 656
 657     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 658         return $comp->ACCEPT_CONTEXT( $c, @args );
 659     }
 660
 661     return $comp;
 662 }
 663
 664 =head2 COMPONENT ACCESSORS
 665
 666 =head2 $c->controller($name)
 667
 668 Gets a L<Catalyst::Controller> instance by name.
 669
 670     $c->controller('Foo')->do_stuff;
 671
 672 If the name is omitted, will return the controller for the dispatched
 673 action.
 674
 675 If you want to search for controllers, pass in a regexp as the argument.
 676
 677     # find all controllers that start with Foo
 678     my @foo_controllers = $c->controller(qr{^Foo});
 679
 680
 681 =cut
 682
 683 sub controller {
 684     my ( $c, $name, @args ) = @_;
 685
 686     my $appclass = ref($c) || $c;
 687     if( $name ) {
 688         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 689             my $comps = $c->components;
 690             my $check = $appclass."::Controller::".$name;
 691             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 692         }
 693         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 694         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 695         return $c->_filter_component( $result[ 0 ], @args );
 696     }
 697
 698     return $c->component( $c->action->class );
 699 }
 700
 701 =head2 $c->model($name)
 702
 703 Gets a L<Catalyst::Model> instance by name.
 704
 705     $c->model('Foo')->do_stuff;
 706
 707 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 708
 709 If the name is omitted, it will look for
 710  - a model object in $c->stash->{current_model_instance}, then
 711  - a model name in $c->stash->{current_model}, then
 712  - a config setting 'default_model', or
 713  - check if there is only one model, and return it if that's the case.
 714
 715 If you want to search for models, pass in a regexp as the argument.
 716
 717     # find all models that start with Foo
 718     my @foo_models = $c->model(qr{^Foo});
 719
 720 =cut
 721
 722 sub model {
 723     my ( $c, $name, @args ) = @_;
 724     my $appclass = ref($c) || $c;
 725     if( $name ) {
 726         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 727             my $comps = $c->components;
 728             my $check = $appclass."::Model::".$name;
 729             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 730         }
 731         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 732         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 733         return $c->_filter_component( $result[ 0 ], @args );
 734     }
 735
 736     if (ref $c) {
 737         return $c->stash->{current_model_instance}
 738           if $c->stash->{current_model_instance};
 739         return $c->model( $c->stash->{current_model} )
 740           if $c->stash->{current_model};
 741     }
 742     return $c->model( $appclass->config->{default_model} )
 743       if $appclass->config->{default_model};
 744
 745     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 746
 747     if( $rest ) {
 748         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 749         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 750         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 751         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 752         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 753     }
 754
 755     return $c->_filter_component( $comp );
 756 }
 757
 758
 759 =head2 $c->view($name)
 760
 761 Gets a L<Catalyst::View> instance by name.
 762
 763     $c->view('Foo')->do_stuff;
 764
 765 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 766
 767 If the name is omitted, it will look for
 768  - a view object in $c->stash->{current_view_instance}, then
 769  - a view name in $c->stash->{current_view}, then
 770  - a config setting 'default_view', or
 771  - check if there is only one view, and return it if that's the case.
 772
 773 If you want to search for views, pass in a regexp as the argument.
 774
 775     # find all views that start with Foo
 776     my @foo_views = $c->view(qr{^Foo});
 777
 778 =cut
 779
 780 sub view {
 781     my ( $c, $name, @args ) = @_;
 782
 783     my $appclass = ref($c) || $c;
 784     if( $name ) {
 785         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 786             my $comps = $c->components;
 787             my $check = $appclass."::View::".$name;
 788             if( exists $comps->{$check} ) {
 789                 return $c->_filter_component( $comps->{$check}, @args );
 790             }
 791             else {
 792                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 793             }
 794         }
 795         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 796         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 797         return $c->_filter_component( $result[ 0 ], @args );
 798     }
 799
 800     if (ref $c) {
 801         return $c->stash->{current_view_instance}
 802           if $c->stash->{current_view_instance};
 803         return $c->view( $c->stash->{current_view} )
 804           if $c->stash->{current_view};
 805     }
 806     return $c->view( $appclass->config->{default_view} )
 807       if $appclass->config->{default_view};
 808
 809     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 810
 811     if( $rest ) {
 812         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 813         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 814         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 815         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 816         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 817     }
 818
 819     return $c->_filter_component( $comp );
 820 }
 821
 822 =head2 $c->controllers
 823
 824 Returns the available names which can be passed to $c->controller
 825
 826 =cut
 827
 828 sub controllers {
 829     my ( $c ) = @_;
 830     return $c->_comp_names(qw/Controller C/);
 831 }
 832
 833 =head2 $c->models
 834
 835 Returns the available names which can be passed to $c->model
 836
 837 =cut
 838
 839 sub models {
 840     my ( $c ) = @_;
 841     return $c->_comp_names(qw/Model M/);
 842 }
 843
 844
 845 =head2 $c->views
 846
 847 Returns the available names which can be passed to $c->view
 848
 849 =cut
 850
 851 sub views {
 852     my ( $c ) = @_;
 853     return $c->_comp_names(qw/View V/);
 854 }
 855
 856 =head2 $c->comp($name)
 857
 858 =head2 $c->component($name)
 859
 860 Gets a component object by name. This method is not recommended,
 861 unless you want to get a specific component by full
 862 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 863 should be used instead.
 864
 865 If C<$name> is a regexp, a list of components matched against the full
 866 component name will be returned.
 867
 868 If Catalyst can't find a component by name, it will fallback to regex
 869 matching by default. To disable this behaviour set
 870 disable_component_resolution_regex_fallback to a true value.
 871
 872     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 873
 874 =cut
 875
 876 sub component {
 877     my ( $c, $name, @args ) = @_;
 878
 879     if( $name ) {
 880         my $comps = $c->components;
 881
 882         if( !ref $name ) {
 883             # is it the exact name?
 884             return $c->_filter_component( $comps->{ $name }, @args )
 885                        if exists $comps->{ $name };
 886
 887             # perhaps we just omitted "MyApp"?
 888             my $composed = ( ref $c || $c ) . "::${name}";
 889             return $c->_filter_component( $comps->{ $composed }, @args )
 890                        if exists $comps->{ $composed };
 891
 892             # search all of the models, views and controllers
 893             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 894             return $c->_filter_component( $comp, @args ) if $comp;
 895         }
 896
 897         return
 898             if $c->config->{disable_component_resolution_regex_fallback};
 899
 900         # This is here so $c->comp( '::M::' ) works
 901         my $query = ref $name ? $name : qr{$name}i;
 902
 903         my @result = grep { m{$query} } keys %{ $c->components };
 904         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 905
 906         if( $result[ 0 ] ) {
 907             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 908             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 909             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 910             return $c->_filter_component( $result[ 0 ], @args );
 911         }
 912
 913         # I would expect to return an empty list here, but that breaks back-compat
 914     }
 915
 916     # fallback
 917     return sort keys %{ $c->components };
 918 }
 919
 920 =head2 CLASS DATA AND HELPER CLASSES
 921
 922 =head2 $c->config
 923
 924 Returns or takes a hashref containing the application's configuration.
 925
 926     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 927
 928 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 929 like C<myapp.conf> in your applications home directory. See
 930 L<Catalyst::Plugin::ConfigLoader>.
 931
 932 =head3 Cascading configuration
 933
 934 The config method is present on all Catalyst components, and configuration
 935 will be merged when an application is started. Configuration loaded with
 936 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 937 followed by configuration in your top level C<MyApp> class. These two
 938 configurations are merged, and then configuration data whose hash key matches a
 939 component name is merged with configuration for that component.
 940
 941 The configuration for a component is then passed to the C<new> method when a
 942 component is constructed.
 943
 944 For example:
 945
 946     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 947     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 948
 949 will mean that C<MyApp::Model::Foo> receives the following data when
 950 constructed:
 951
 952     MyApp::Model::Foo->new({
 953         bar => 'baz',
 954         quux => 'frob',
 955         overrides => 'me',
 956     });
 957
 958 It's common practice to use a Moose attribute
 959 on the receiving component to access the config value.
 960
 961     package MyApp::Model::Foo;
 962
 963     use Moose;
 964
 965     # this attr will receive 'baz' at construction time
 966     has 'bar' => (
 967         is  => 'rw',
 968         isa => 'Str',
 969     );
 970
 971 You can then get the value 'baz' by calling $c->model('Foo')->bar
 972 (or $self->bar inside code in the model).
 973
 974 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 975 as a way of reading config within your code, as this B<will not> give you the
 976 correctly merged config back. You B<MUST> take the config values supplied to
 977 the constructor and use those instead.
 978
 979 =cut
 980
 981 around config => sub {
 982     my $orig = shift;
 983     my $c = shift;
 984
 985     croak('Setting config after setup has been run is not allowed.')
 986         if ( @_ and $c->setup_finished );
 987
 988     $c->$orig(@_);
 989 };
 990
 991 =head2 $c->log
 992
 993 Returns the logging object instance. Unless it is already set, Catalyst
 994 sets this up with a L<Catalyst::Log> object. To use your own log class,
 995 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 996 C<< __PACKAGE__->setup >>.
 997
 998  __PACKAGE__->log( MyLogger->new );
 999  __PACKAGE__->setup;
1000
1001 And later:
1002
1003     $c->log->info( 'Now logging with my own logger!' );
1004
1005 Your log class should implement the methods described in
1006 L<Catalyst::Log>.
1007
1008
1009 =head2 $c->debug
1010
1011 Returns 1 if debug mode is enabled, 0 otherwise.
1012
1013 You can enable debug mode in several ways:
1014
1015 =over
1016
1017 =item By calling myapp_server.pl with the -d flag
1018
1019 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1020
1021 =item The -Debug option in your MyApp.pm
1022
1023 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1024
1025 =back
1026
1027 The first three also set the log level to 'debug'.
1028
1029 Calling C<< $c->debug(1) >> has no effect.
1030
1031 =cut
1032
1033 sub debug { 0 }
1034
1035 =head2 $c->dispatcher
1036
1037 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1038
1039 =head2 $c->engine
1040
1041 Returns the engine instance. See L<Catalyst::Engine>.
1042
1043
1044 =head2 UTILITY METHODS
1045
1046 =head2 $c->path_to(@path)
1047
1048 Merges C<@path> with C<< $c->config->{home} >> and returns a
1049 L<Path::Class::Dir> object. Note you can usually use this object as
1050 a filename, but sometimes you will have to explicitly stringify it
1051 yourself by calling the C<< ->stringify >> method.
1052
1053 For example:
1054
1055     $c->path_to( 'db', 'sqlite.db' );
1056
1057 =cut
1058
1059 sub path_to {
1060     my ( $c, @path ) = @_;
1061     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1062     if ( -d $path ) { return $path }
1063     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1064 }
1065
1066 sub plugin {
1067     my ( $class, $name, $plugin, @args ) = @_;
1068
1069     # See block comment in t/unit_core_plugin.t
1070     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1071
1072     $class->_register_plugin( $plugin, 1 );
1073
1074     eval { $plugin->import };
1075     $class->mk_classdata($name);
1076     my $obj;
1077     eval { $obj = $plugin->new(@args) };
1078
1079     if ($@) {
1080         Catalyst::Exception->throw( message =>
1081               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1082     }
1083
1084     $class->$name($obj);
1085     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1086       if $class->debug;
1087 }
1088
1089 =head2 MyApp->setup
1090
1091 Initializes the dispatcher and engine, loads any plugins, and loads the
1092 model, view, and controller components. You may also specify an array
1093 of plugins to load here, if you choose to not load them in the C<use
1094 Catalyst> line.
1095
1096     MyApp->setup;
1097     MyApp->setup( qw/-Debug/ );
1098
1099 B<Note:> You B<should not> wrap this method with method modifiers
1100 or bad things will happen - wrap the C<setup_finalize> method instead.
1101
1102 =cut
1103
1104 sub setup {
1105     my ( $class, @arguments ) = @_;
1106     croak('Running setup more than once')
1107         if ( $class->setup_finished );
1108
1109     unless ( $class->isa('Catalyst') ) {
1110
1111         Catalyst::Exception->throw(
1112             message => qq/'$class' does not inherit from Catalyst/ );
1113     }
1114
1115     if ( $class->arguments ) {
1116         @arguments = ( @arguments, @{ $class->arguments } );
1117     }
1118
1119     # Process options
1120     my $flags = {};
1121
1122     foreach (@arguments) {
1123
1124         if (/^-Debug$/) {
1125             $flags->{log} =
1126               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1127         }
1128         elsif (/^-(\w+)=?(.*)$/) {
1129             $flags->{ lc $1 } = $2;
1130         }
1131         else {
1132             push @{ $flags->{plugins} }, $_;
1133         }
1134     }
1135
1136     $class->setup_home( delete $flags->{home} );
1137
1138     $class->setup_log( delete $flags->{log} );
1139     $class->setup_plugins( delete $flags->{plugins} );
1140
1141     $class->setup_data_handlers();
1142     $class->setup_dispatcher( delete $flags->{dispatcher} );
1143     if (my $engine = delete $flags->{engine}) {
1144         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1145     }
1146     $class->setup_engine();
1147     $class->setup_stats( delete $flags->{stats} );
1148
1149     for my $flag ( sort keys %{$flags} ) {
1150
1151         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1152             &$code( $class, delete $flags->{$flag} );
1153         }
1154         else {
1155             $class->log->warn(qq/Unknown flag "$flag"/);
1156         }
1157     }
1158
1159     eval { require Catalyst::Devel; };
1160     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1161         $class->log->warn(<<"EOF");
1162 You are running an old script!
1163
1164   Please update by running (this will overwrite existing files):
1165     catalyst.pl -force -scripts $class
1166
1167   or (this will not overwrite existing files):
1168     catalyst.pl -scripts $class
1169
1170 EOF
1171     }
1172
1173     # Call plugins setup, this is stupid and evil.
1174     # Also screws C3 badly on 5.10, hack to avoid.
1175     {
1176         no warnings qw/redefine/;
1177         local *setup = sub { };
1178         $class->setup unless $Catalyst::__AM_RESTARTING;
1179     }
1180
1181     $class->setup_middleware();
1182
1183     # Initialize our data structure
1184     $class->components( {} );
1185
1186     $class->setup_components;
1187
1188     if ( $class->debug ) {
1189         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1190
1191         if (@plugins) {
1192             my $column_width = Catalyst::Utils::term_width() - 6;
1193             my $t = Text::SimpleTable->new($column_width);
1194             $t->row($_) for @plugins;
1195             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1196         }
1197
1198         my @middleware = map {
1199           ref $_ eq 'CODE' ?
1200             "Inline Coderef" :
1201               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1202                 || '')  } $class->registered_middlewares;
1203
1204         if (@middleware) {
1205             my $column_width = Catalyst::Utils::term_width() - 6;
1206             my $t = Text::SimpleTable->new($column_width);
1207             $t->row($_) for @middleware;
1208             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1209         }
1210
1211         my %dh = $class->registered_data_handlers;
1212         if (my @data_handlers = keys %dh) {
1213             my $column_width = Catalyst::Utils::term_width() - 6;
1214             my $t = Text::SimpleTable->new($column_width);
1215             $t->row($_) for @data_handlers;
1216             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1217         }
1218
1219         my $dispatcher = $class->dispatcher;
1220         my $engine     = $class->engine;
1221         my $home       = $class->config->{home};
1222
1223         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1224         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1225
1226         $home
1227           ? ( -d $home )
1228           ? $class->log->debug(qq/Found home "$home"/)
1229           : $class->log->debug(qq/Home "$home" doesn't exist/)
1230           : $class->log->debug(q/Couldn't find home/);
1231
1232         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1233         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1234         for my $comp ( sort keys %{ $class->components } ) {
1235             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1236             $t->row( $comp, $type );
1237         }
1238         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1239           if ( keys %{ $class->components } );
1240     }
1241
1242     # Add our self to components, since we are also a component
1243     if( $class->isa('Catalyst::Controller') ){
1244       $class->components->{$class} = $class;
1245     }
1246
1247     $class->setup_actions;
1248
1249     if ( $class->debug ) {
1250         my $name = $class->config->{name} || 'Application';
1251         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1252     }
1253
1254     if ($class->config->{case_sensitive}) {
1255         $class->log->warn($class . "->config->{case_sensitive} is set.");
1256         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1257     }
1258
1259     $class->setup_finalize;
1260
1261     # Flush the log for good measure (in case something turned off 'autoflush' early)
1262     $class->log->_flush() if $class->log->can('_flush');
1263
1264     return $class || 1; # Just in case someone named their Application 0...
1265 }
1266
1267 =head2 $app->setup_finalize
1268
1269 A hook to attach modifiers to. This method does not do anything except set the
1270 C<setup_finished> accessor.
1271
1272 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1273
1274 Example:
1275
1276     after setup_finalize => sub {
1277         my $app = shift;
1278
1279         ## do stuff here..
1280     };
1281
1282 =cut
1283
1284 sub setup_finalize {
1285     my ($class) = @_;
1286     $class->setup_finished(1);
1287 }
1288
1289 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1290
1291 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1292
1293 Constructs an absolute L<URI> object based on the application root, the
1294 provided path, and the additional arguments and query parameters provided.
1295 When used as a string, provides a textual URI.  If you need more flexibility
1296 than this (i.e. the option to provide relative URIs etc.) see
1297 L<Catalyst::Plugin::SmartURI>.
1298
1299 If no arguments are provided, the URI for the current action is returned.
1300 To return the current action and also provide @args, use
1301 C<< $c->uri_for( $c->action, @args ) >>.
1302
1303 If the first argument is a string, it is taken as a public URI path relative
1304 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1305 relative to the application root (if it does). It is then merged with
1306 C<< $c->request->base >>; any C<@args> are appended as additional path
1307 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1308
1309 If the first argument is a L<Catalyst::Action> it represents an action which
1310 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1311 optional C<\@captures> argument (an arrayref) allows passing the captured
1312 variables that are needed to fill in the paths of Chained and Regex actions;
1313 once the path is resolved, C<uri_for> continues as though a path was
1314 provided, appending any arguments or parameters and creating an absolute
1315 URI.
1316
1317 The captures for the current request can be found in
1318 C<< $c->request->captures >>, and actions can be resolved using
1319 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1320 path, use C<< $c->uri_for_action >> instead.
1321
1322   # Equivalent to $c->req->uri
1323   $c->uri_for($c->action, $c->req->captures,
1324       @{ $c->req->args }, $c->req->params);
1325
1326   # For the Foo action in the Bar controller
1327   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1328
1329   # Path to a static resource
1330   $c->uri_for('/static/images/logo.png');
1331
1332 =cut
1333
1334 sub uri_for {
1335     my ( $c, $path, @args ) = @_;
1336
1337     if ( $path->$_isa('Catalyst::Controller') ) {
1338         $path = $path->path_prefix;
1339         $path =~ s{/+\z}{};
1340         $path .= '/';
1341     }
1342
1343     undef($path) if (defined $path && $path eq '');
1344
1345     my $params =
1346       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1347
1348     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1349     foreach my $arg (@args) {
1350         utf8::encode($arg) if utf8::is_utf8($arg);
1351         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1352     }
1353
1354     if ( $path->$_isa('Catalyst::Action') ) { # action object
1355         s|/|%2F|g for @args;
1356         my $captures = [ map { s|/|%2F|g; $_; }
1357                         ( scalar @args && ref $args[0] eq 'ARRAY'
1358                          ? @{ shift(@args) }
1359                          : ()) ];
1360
1361         foreach my $capture (@$captures) {
1362             utf8::encode($capture) if utf8::is_utf8($capture);
1363             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1364         }
1365
1366         my $action = $path;
1367         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1368         if( !@args && $action->number_of_args ) {
1369             my $expanded_action = $c->dispatcher->expand_action( $action );
1370
1371             my $num_captures = $expanded_action->number_of_captures;
1372             unshift @args, splice @$captures, $num_captures;
1373         }
1374
1375        $path = $c->dispatcher->uri_for_action($action, $captures);
1376         if (not defined $path) {
1377             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1378                 if $c->debug;
1379             return undef;
1380         }
1381         $path = '/' if $path eq '';
1382     }
1383
1384     unshift(@args, $path);
1385
1386     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1387         my $namespace = $c->namespace;
1388         if (defined $path) { # cheesy hack to handle path '../foo'
1389            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1390         }
1391         unshift(@args, $namespace || '');
1392     }
1393
1394     # join args with '/', or a blank string
1395     my $args = join('/', grep { defined($_) } @args);
1396     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1397     $args =~ s!^/+!!;
1398
1399     my ($base, $class) = ('/', 'URI::_generic');
1400     if(blessed($c)) {
1401       $base = $c->req->base;
1402       $class = ref($base);
1403       $base =~ s{(?<!/)$}{/};
1404     }
1405
1406     my $query = '';
1407
1408     if (my @keys = keys %$params) {
1409       # somewhat lifted from URI::_query's query_form
1410       $query = '?'.join('&', map {
1411           my $val = $params->{$_};
1412           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1413           s/ /+/g;
1414           my $key = $_;
1415           $val = '' unless defined $val;
1416           (map {
1417               my $param = "$_";
1418               utf8::encode( $param ) if utf8::is_utf8($param);
1419               # using the URI::Escape pattern here so utf8 chars survive
1420               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1421               $param =~ s/ /+/g;
1422               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1423       } @keys);
1424     }
1425
1426     my $res = bless(\"${base}${args}${query}", $class);
1427     $res;
1428 }
1429
1430 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1431
1432 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1433
1434 =over
1435
1436 =item $path
1437
1438 A private path to the Catalyst action you want to create a URI for.
1439
1440 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1441 >> and passing the resulting C<$action> and the remaining arguments to C<<
1442 $c->uri_for >>.
1443
1444 You can also pass in a Catalyst::Action object, in which case it is passed to
1445 C<< $c->uri_for >>.
1446
1447 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1448
1449 For example, if the action looks like:
1450
1451  package MyApp::Controller::Users;
1452
1453  sub lst : Path('the-list') {}
1454
1455 You can use:
1456
1457  $c->uri_for_action('/users/lst')
1458
1459 and it will create the URI /users/the-list.
1460
1461 =item \@captures_and_args?
1462
1463 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1464 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1465 to interpolate all the parameters in the URI.
1466
1467 =item @args?
1468
1469 Optional list of extra arguments - can be supplied in the
1470 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1471 code.
1472
1473 Your action can have zero, a fixed or a variable number of args (e.g.
1474 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1475
1476 =item \%query_values?
1477
1478 Optional array reference of query parameters to append. E.g.
1479
1480   { foo => 'bar' }
1481
1482 will generate
1483
1484   /rest/of/your/uri?foo=bar
1485
1486 =back
1487
1488 =cut
1489
1490 sub uri_for_action {
1491     my ( $c, $path, @args ) = @_;
1492     my $action = blessed($path)
1493       ? $path
1494       : $c->dispatcher->get_action_by_path($path);
1495     unless (defined $action) {
1496       croak "Can't find action for path '$path'";
1497     }
1498     return $c->uri_for( $action, @args );
1499 }
1500
1501 =head2 $c->welcome_message
1502
1503 Returns the Catalyst welcome HTML page.
1504
1505 =cut
1506
1507 sub welcome_message {
1508     my $c      = shift;
1509     my $name   = $c->config->{name};
1510     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1511     my $prefix = Catalyst::Utils::appprefix( ref $c );
1512     $c->response->content_type('text/html; charset=utf-8');
1513     return <<"EOF";
1514 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1515     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1516 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1517     <head>
1518     <meta http-equiv="Content-Language" content="en" />
1519     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1520         <title>$name on Catalyst $VERSION</title>
1521         <style type="text/css">
1522             body {
1523                 color: #000;
1524                 background-color: #eee;
1525             }
1526             div#content {
1527                 width: 640px;
1528                 margin-left: auto;
1529                 margin-right: auto;
1530                 margin-top: 10px;
1531                 margin-bottom: 10px;
1532                 text-align: left;
1533                 background-color: #ccc;
1534                 border: 1px solid #aaa;
1535             }
1536             p, h1, h2 {
1537                 margin-left: 20px;
1538                 margin-right: 20px;
1539                 font-family: verdana, tahoma, sans-serif;
1540             }
1541             a {
1542                 font-family: verdana, tahoma, sans-serif;
1543             }
1544             :link, :visited {
1545                     text-decoration: none;
1546                     color: #b00;
1547                     border-bottom: 1px dotted #bbb;
1548             }
1549             :link:hover, :visited:hover {
1550                     color: #555;
1551             }
1552             div#topbar {
1553                 margin: 0px;
1554             }
1555             pre {
1556                 margin: 10px;
1557                 padding: 8px;
1558             }
1559             div#answers {
1560                 padding: 8px;
1561                 margin: 10px;
1562                 background-color: #fff;
1563                 border: 1px solid #aaa;
1564             }
1565             h1 {
1566                 font-size: 0.9em;
1567                 font-weight: normal;
1568                 text-align: center;
1569             }
1570             h2 {
1571                 font-size: 1.0em;
1572             }
1573             p {
1574                 font-size: 0.9em;
1575             }
1576             p img {
1577                 float: right;
1578                 margin-left: 10px;
1579             }
1580             span#appname {
1581                 font-weight: bold;
1582                 font-size: 1.6em;
1583             }
1584         </style>
1585     </head>
1586     <body>
1587         <div id="content">
1588             <div id="topbar">
1589                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1590                     $VERSION</h1>
1591              </div>
1592              <div id="answers">
1593                  <p>
1594                  <img src="$logo" alt="Catalyst Logo" />
1595                  </p>
1596                  <p>Welcome to the  world of Catalyst.
1597                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1598                     framework will make web development something you had
1599                     never expected it to be: Fun, rewarding, and quick.</p>
1600                  <h2>What to do now?</h2>
1601                  <p>That really depends  on what <b>you</b> want to do.
1602                     We do, however, provide you with a few starting points.</p>
1603                  <p>If you want to jump right into web development with Catalyst
1604                     you might want to start with a tutorial.</p>
1605 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1606 </pre>
1607 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1608 <pre>
1609 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1610 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1611 </code></pre>
1612                  <h2>What to do next?</h2>
1613                  <p>Next it's time to write an actual application. Use the
1614                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1615                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1616                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1617                     they can save you a lot of work.</p>
1618                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1619                     <p>Also, be sure to check out the vast and growing
1620                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1621                     you are likely to find what you need there.
1622                     </p>
1623
1624                  <h2>Need help?</h2>
1625                  <p>Catalyst has a very active community. Here are the main places to
1626                     get in touch with us.</p>
1627                  <ul>
1628                      <li>
1629                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1630                      </li>
1631                      <li>
1632                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1633                      </li>
1634                      <li>
1635                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1636                      </li>
1637                  </ul>
1638                  <h2>In conclusion</h2>
1639                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1640                     as we enjoyed making it. Please contact us if you have ideas
1641                     for improvement or other feedback.</p>
1642              </div>
1643          </div>
1644     </body>
1645 </html>
1646 EOF
1647 }
1648
1649 =head2 run_options
1650
1651 Contains a hash of options passed from the application script, including
1652 the original ARGV the script received, the processed values from that
1653 ARGV and any extra arguments to the script which were not processed.
1654
1655 This can be used to add custom options to your application's scripts
1656 and setup your application differently depending on the values of these
1657 options.
1658
1659 =head1 INTERNAL METHODS
1660
1661 These methods are not meant to be used by end users.
1662
1663 =head2 $c->components
1664
1665 Returns a hash of components.
1666
1667 =head2 $c->context_class
1668
1669 Returns or sets the context class.
1670
1671 =head2 $c->counter
1672
1673 Returns a hashref containing coderefs and execution counts (needed for
1674 deep recursion detection).
1675
1676 =head2 $c->depth
1677
1678 Returns the number of actions on the current internal execution stack.
1679
1680 =head2 $c->dispatch
1681
1682 Dispatches a request to actions.
1683
1684 =cut
1685
1686 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1687
1688 =head2 $c->dispatcher_class
1689
1690 Returns or sets the dispatcher class.
1691
1692 =head2 $c->dump_these
1693
1694 Returns a list of 2-element array references (name, structure) pairs
1695 that will be dumped on the error page in debug mode.
1696
1697 =cut
1698
1699 sub dump_these {
1700     my $c = shift;
1701     [ Request => $c->req ],
1702     [ Response => $c->res ],
1703     [ Stash => $c->stash ],
1704     [ Config => $c->config ];
1705 }
1706
1707 =head2 $c->engine_class
1708
1709 Returns or sets the engine class.
1710
1711 =head2 $c->execute( $class, $coderef )
1712
1713 Execute a coderef in given class and catch exceptions. Errors are available
1714 via $c->error.
1715
1716 =cut
1717
1718 sub execute {
1719     my ( $c, $class, $code ) = @_;
1720     $class = $c->component($class) || $class;
1721     $c->state(0);
1722
1723     if ( $c->depth >= $RECURSION ) {
1724         my $action = $code->reverse();
1725         $action = "/$action" unless $action =~ /->/;
1726         my $error = qq/Deep recursion detected calling "${action}"/;
1727         $c->log->error($error);
1728         $c->error($error);
1729         $c->state(0);
1730         return $c->state;
1731     }
1732
1733     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1734
1735     push( @{ $c->stack }, $code );
1736
1737     no warnings 'recursion';
1738     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1739     #      I have no idea how, ergo $ret (which appears to fix the issue)
1740     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1741
1742     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1743
1744     my $last = pop( @{ $c->stack } );
1745
1746     if ( my $error = $@ ) {
1747         #rethow if this can be handled by middleware
1748         if(blessed $error && ($error->can('as_psgi') || $error->can('code'))) {
1749             foreach my $err (@{$c->error}) {
1750                 $c->log->error($err);
1751             }
1752             $c->clear_errors;
1753             $c->log->_flush if $c->log->can('_flush');
1754
1755             $error->can('rethrow') ? $error->rethrow : croak $error;
1756         }
1757         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1758             $error->rethrow if $c->depth > 1;
1759         }
1760         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1761             $error->rethrow if $c->depth > 0;
1762         }
1763         else {
1764             unless ( ref $error ) {
1765                 no warnings 'uninitialized';
1766                 chomp $error;
1767                 my $class = $last->class;
1768                 my $name  = $last->name;
1769                 $error = qq/Caught exception in $class->$name "$error"/;
1770             }
1771             $c->error($error);
1772         }
1773         $c->state(0);
1774     }
1775     return $c->state;
1776 }
1777
1778 sub _stats_start_execute {
1779     my ( $c, $code ) = @_;
1780     my $appclass = ref($c) || $c;
1781     return if ( ( $code->name =~ /^_.*/ )
1782         && ( !$appclass->config->{show_internal_actions} ) );
1783
1784     my $action_name = $code->reverse();
1785     $c->counter->{$action_name}++;
1786
1787     my $action = $action_name;
1788     $action = "/$action" unless $action =~ /->/;
1789
1790     # determine if the call was the result of a forward
1791     # this is done by walking up the call stack and looking for a calling
1792     # sub of Catalyst::forward before the eval
1793     my $callsub = q{};
1794     for my $index ( 2 .. 11 ) {
1795         last
1796         if ( ( caller($index) )[0] eq 'Catalyst'
1797             && ( caller($index) )[3] eq '(eval)' );
1798
1799         if ( ( caller($index) )[3] =~ /forward$/ ) {
1800             $callsub = ( caller($index) )[3];
1801             $action  = "-> $action";
1802             last;
1803         }
1804     }
1805
1806     my $uid = $action_name . $c->counter->{$action_name};
1807
1808     # is this a root-level call or a forwarded call?
1809     if ( $callsub =~ /forward$/ ) {
1810         my $parent = $c->stack->[-1];
1811
1812         # forward, locate the caller
1813         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1814             $c->stats->profile(
1815                 begin  => $action,
1816                 parent => "$parent" . $c->counter->{"$parent"},
1817                 uid    => $uid,
1818             );
1819         }
1820         else {
1821
1822             # forward with no caller may come from a plugin
1823             $c->stats->profile(
1824                 begin => $action,
1825                 uid   => $uid,
1826             );
1827         }
1828     }
1829     else {
1830
1831         # root-level call
1832         $c->stats->profile(
1833             begin => $action,
1834             uid   => $uid,
1835         );
1836     }
1837     return $action;
1838
1839 }
1840
1841 sub _stats_finish_execute {
1842     my ( $c, $info ) = @_;
1843     $c->stats->profile( end => $info );
1844 }
1845
1846 =head2 $c->finalize
1847
1848 Finalizes the request.
1849
1850 =cut
1851
1852 sub finalize {
1853     my $c = shift;
1854
1855     for my $error ( @{ $c->error } ) {
1856         $c->log->error($error);
1857     }
1858
1859     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1860     # stuff like cometd and websockets
1861
1862     if($c->request->_has_io_fh) {
1863       $c->log_response;
1864       return;
1865     }
1866
1867     # Allow engine to handle finalize flow (for POE)
1868     my $engine = $c->engine;
1869     if ( my $code = $engine->can('finalize') ) {
1870         $engine->$code($c);
1871     }
1872     else {
1873
1874         $c->finalize_uploads;
1875
1876         # Error
1877         if ( $#{ $c->error } >= 0 ) {
1878             $c->finalize_error;
1879         }
1880
1881         $c->finalize_headers unless $c->response->finalized_headers;
1882
1883         $c->finalize_body;
1884     }
1885
1886     $c->log_response;
1887
1888     if ($c->use_stats) {
1889         my $elapsed = $c->stats->elapsed;
1890         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1891         $c->log->info(
1892             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1893     }
1894
1895     return $c->response->status;
1896 }
1897
1898 =head2 $c->finalize_body
1899
1900 Finalizes body.
1901
1902 =cut
1903
1904 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1905
1906 =head2 $c->finalize_cookies
1907
1908 Finalizes cookies.
1909
1910 =cut
1911
1912 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1913
1914 =head2 $c->finalize_error
1915
1916 Finalizes error.  If there is only one error in L</error> and it is an object that
1917 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
1918 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
1919 return the default error page (production mode).
1920
1921 =cut
1922
1923 sub finalize_error {
1924     my $c = shift;
1925     if($#{$c->error} > 0) {
1926         $c->engine->finalize_error( $c, @_ );
1927     } else {
1928         my ($error) = @{$c->error};
1929         if(
1930           blessed $error &&
1931           ($error->can('as_psgi') || $error->can('code'))
1932         ) {
1933             # In the case where the error 'knows what it wants', becauses its PSGI
1934             # aware, just rethow and let middleware catch it
1935             $error->can('rethrow') ? $error->rethrow : croak $error;
1936         } else {
1937             $c->engine->finalize_error( $c, @_ )
1938         }
1939     }
1940 }
1941
1942 =head2 $c->finalize_headers
1943
1944 Finalizes headers.
1945
1946 =cut
1947
1948 sub finalize_headers {
1949     my $c = shift;
1950
1951     my $response = $c->response; #accessor calls can add up?
1952
1953     # Check if we already finalized headers
1954     return if $response->finalized_headers;
1955
1956     # Handle redirects
1957     if ( my $location = $response->redirect ) {
1958         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1959         $response->header( Location => $location );
1960     }
1961
1962     # Remove incorrectly added body and content related meta data when returning
1963     # an information response, or a response the is required to not include a body
1964
1965     $c->finalize_cookies;
1966
1967     $c->response->finalize_headers();
1968
1969     # Done
1970     $response->finalized_headers(1);
1971 }
1972
1973 =head2 $c->finalize_output
1974
1975 An alias for finalize_body.
1976
1977 =head2 $c->finalize_read
1978
1979 Finalizes the input after reading is complete.
1980
1981 =cut
1982
1983 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1984
1985 =head2 $c->finalize_uploads
1986
1987 Finalizes uploads. Cleans up any temporary files.
1988
1989 =cut
1990
1991 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1992
1993 =head2 $c->get_action( $action, $namespace )
1994
1995 Gets an action in a given namespace.
1996
1997 =cut
1998
1999 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2000
2001 =head2 $c->get_actions( $action, $namespace )
2002
2003 Gets all actions of a given name in a namespace and all parent
2004 namespaces.
2005
2006 =cut
2007
2008 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2009
2010 =head2 $app->handle_request( @arguments )
2011
2012 Called to handle each HTTP request.
2013
2014 =cut
2015
2016 sub handle_request {
2017     my ( $class, @arguments ) = @_;
2018
2019     # Always expect worst case!
2020     my $status = -1;
2021     try {
2022         if ($class->debug) {
2023             my $secs = time - $START || 1;
2024             my $av = sprintf '%.3f', $COUNT / $secs;
2025             my $time = localtime time;
2026             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2027         }
2028
2029         my $c = $class->prepare(@arguments);
2030         $c->dispatch;
2031         $status = $c->finalize;
2032     } catch {
2033         #rethow if this can be handled by middleware
2034         if(blessed $_ && ($_->can('as_psgi') || $_->can('code'))) {
2035             $_->can('rethrow') ? $_->rethrow : croak $_;
2036         }
2037         chomp(my $error = $_);
2038         $class->log->error(qq/Caught exception in engine "$error"/);
2039     };
2040
2041     $COUNT++;
2042
2043     if(my $coderef = $class->log->can('_flush')){
2044         $class->log->$coderef();
2045     }
2046     return $status;
2047 }
2048
2049 =head2 $class->prepare( @arguments )
2050
2051 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2052 etc.).
2053
2054 =cut
2055
2056 has _uploadtmp => (
2057     is => 'ro',
2058     predicate => '_has_uploadtmp',
2059 );
2060
2061 sub prepare {
2062     my ( $class, @arguments ) = @_;
2063
2064     # XXX
2065     # After the app/ctxt split, this should become an attribute based on something passed
2066     # into the application.
2067     $class->context_class( ref $class || $class ) unless $class->context_class;
2068
2069     my $uploadtmp = $class->config->{uploadtmp};
2070     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2071
2072     $c->response->_context($c);
2073
2074     #surely this is not the most efficient way to do things...
2075     $c->stats($class->stats_class->new)->enable($c->use_stats);
2076     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2077         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2078     }
2079
2080     try {
2081         # Allow engine to direct the prepare flow (for POE)
2082         if ( my $prepare = $c->engine->can('prepare') ) {
2083             $c->engine->$prepare( $c, @arguments );
2084         }
2085         else {
2086             $c->prepare_request(@arguments);
2087             $c->prepare_connection;
2088             $c->prepare_query_parameters;
2089             $c->prepare_headers; # Just hooks, no longer needed - they just
2090             $c->prepare_cookies; # cause the lazy attribute on req to build
2091             $c->prepare_path;
2092
2093             # Prepare the body for reading, either by prepare_body
2094             # or the user, if they are using $c->read
2095             $c->prepare_read;
2096
2097             # Parse the body unless the user wants it on-demand
2098             unless ( ref($c)->config->{parse_on_demand} ) {
2099                 $c->prepare_body;
2100             }
2101         }
2102         $c->prepare_action;
2103     }
2104     # VERY ugly and probably shouldn't rely on ->finalize actually working
2105     catch {
2106         # failed prepare is always due to an invalid request, right?
2107         $c->response->status(400);
2108         $c->response->content_type('text/plain');
2109         $c->response->body('Bad Request');
2110         # Note we call finalize and then die here, which escapes
2111         # finalize being called in the enclosing block..
2112         # It in fact couldn't be called, as we don't return $c..
2113         # This is a mess - but I'm unsure you can fix this without
2114         # breaking compat for people doing crazy things (we should set
2115         # the 400 and just return the ctx here IMO, letting finalize get called
2116         # above...
2117         $c->finalize;
2118         die $_;
2119     };
2120
2121     $c->log_request;
2122
2123     return $c;
2124 }
2125
2126 =head2 $c->prepare_action
2127
2128 Prepares action. See L<Catalyst::Dispatcher>.
2129
2130 =cut
2131
2132 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2133
2134 =head2 $c->prepare_body
2135
2136 Prepares message body.
2137
2138 =cut
2139
2140 sub prepare_body {
2141     my $c = shift;
2142
2143     return if $c->request->_has_body;
2144
2145     # Initialize on-demand data
2146     $c->engine->prepare_body( $c, @_ );
2147     $c->prepare_parameters;
2148     $c->prepare_uploads;
2149 }
2150
2151 =head2 $c->prepare_body_chunk( $chunk )
2152
2153 Prepares a chunk of data before sending it to L<HTTP::Body>.
2154
2155 See L<Catalyst::Engine>.
2156
2157 =cut
2158
2159 sub prepare_body_chunk {
2160     my $c = shift;
2161     $c->engine->prepare_body_chunk( $c, @_ );
2162 }
2163
2164 =head2 $c->prepare_body_parameters
2165
2166 Prepares body parameters.
2167
2168 =cut
2169
2170 sub prepare_body_parameters {
2171     my $c = shift;
2172     $c->engine->prepare_body_parameters( $c, @_ );
2173 }
2174
2175 =head2 $c->prepare_connection
2176
2177 Prepares connection.
2178
2179 =cut
2180
2181 sub prepare_connection {
2182     my $c = shift;
2183     # XXX - This is called on the engine (not the request) to maintain
2184     #       Engine::PSGI back compat.
2185     $c->engine->prepare_connection($c);
2186 }
2187
2188 =head2 $c->prepare_cookies
2189
2190 Prepares cookies by ensuring that the attribute on the request
2191 object has been built.
2192
2193 =cut
2194
2195 sub prepare_cookies { my $c = shift; $c->request->cookies }
2196
2197 =head2 $c->prepare_headers
2198
2199 Prepares request headers by ensuring that the attribute on the request
2200 object has been built.
2201
2202 =cut
2203
2204 sub prepare_headers { my $c = shift; $c->request->headers }
2205
2206 =head2 $c->prepare_parameters
2207
2208 Prepares parameters.
2209
2210 =cut
2211
2212 sub prepare_parameters {
2213     my $c = shift;
2214     $c->prepare_body_parameters;
2215     $c->engine->prepare_parameters( $c, @_ );
2216 }
2217
2218 =head2 $c->prepare_path
2219
2220 Prepares path and base.
2221
2222 =cut
2223
2224 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2225
2226 =head2 $c->prepare_query_parameters
2227
2228 Prepares query parameters.
2229
2230 =cut
2231
2232 sub prepare_query_parameters {
2233     my $c = shift;
2234
2235     $c->engine->prepare_query_parameters( $c, @_ );
2236 }
2237
2238 =head2 $c->log_request
2239
2240 Writes information about the request to the debug logs.  This includes:
2241
2242 =over 4
2243
2244 =item * Request method, path, and remote IP address
2245
2246 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2247
2248 =item * Request parameters
2249
2250 =item * File uploads
2251
2252 =back
2253
2254 =cut
2255
2256 sub log_request {
2257     my $c = shift;
2258
2259     return unless $c->debug;
2260
2261     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2262     my $request = $dump->[1];
2263
2264     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2265     $method ||= '';
2266     $path = '/' unless length $path;
2267     $address ||= '';
2268     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2269
2270     $c->log_request_headers($request->headers);
2271
2272     if ( my $keywords = $request->query_keywords ) {
2273         $c->log->debug("Query keywords are: $keywords");
2274     }
2275
2276     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2277
2278     $c->log_request_uploads($request);
2279 }
2280
2281 =head2 $c->log_response
2282
2283 Writes information about the response to the debug logs by calling
2284 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2285
2286 =cut
2287
2288 sub log_response {
2289     my $c = shift;
2290
2291     return unless $c->debug;
2292
2293     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2294     my $response = $dump->[1];
2295
2296     $c->log_response_status_line($response);
2297     $c->log_response_headers($response->headers);
2298 }
2299
2300 =head2 $c->log_response_status_line($response)
2301
2302 Writes one line of information about the response to the debug logs.  This includes:
2303
2304 =over 4
2305
2306 =item * Response status code
2307
2308 =item * Content-Type header (if present)
2309
2310 =item * Content-Length header (if present)
2311
2312 =back
2313
2314 =cut
2315
2316 sub log_response_status_line {
2317     my ($c, $response) = @_;
2318
2319     $c->log->debug(
2320         sprintf(
2321             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2322             $response->status                            || 'unknown',
2323             $response->headers->header('Content-Type')   || 'unknown',
2324             $response->headers->header('Content-Length') || 'unknown'
2325         )
2326     );
2327 }
2328
2329 =head2 $c->log_response_headers($headers);
2330
2331 Hook method which can be wrapped by plugins to log the response headers.
2332 No-op in the default implementation.
2333
2334 =cut
2335
2336 sub log_response_headers {}
2337
2338 =head2 $c->log_request_parameters( query => {}, body => {} )
2339
2340 Logs request parameters to debug logs
2341
2342 =cut
2343
2344 sub log_request_parameters {
2345     my $c          = shift;
2346     my %all_params = @_;
2347
2348     return unless $c->debug;
2349
2350     my $column_width = Catalyst::Utils::term_width() - 44;
2351     foreach my $type (qw(query body)) {
2352         my $params = $all_params{$type};
2353         next if ! keys %$params;
2354         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2355         for my $key ( sort keys %$params ) {
2356             my $param = $params->{$key};
2357             my $value = defined($param) ? $param : '';
2358             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2359         }
2360         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2361     }
2362 }
2363
2364 =head2 $c->log_request_uploads
2365
2366 Logs file uploads included in the request to the debug logs.
2367 The parameter name, filename, file type, and file size are all included in
2368 the debug logs.
2369
2370 =cut
2371
2372 sub log_request_uploads {
2373     my $c = shift;
2374     my $request = shift;
2375     return unless $c->debug;
2376     my $uploads = $request->uploads;
2377     if ( keys %$uploads ) {
2378         my $t = Text::SimpleTable->new(
2379             [ 12, 'Parameter' ],
2380             [ 26, 'Filename' ],
2381             [ 18, 'Type' ],
2382             [ 9,  'Size' ]
2383         );
2384         for my $key ( sort keys %$uploads ) {
2385             my $upload = $uploads->{$key};
2386             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2387                 $t->row( $key, $u->filename, $u->type, $u->size );
2388             }
2389         }
2390         $c->log->debug( "File Uploads are:\n" . $t->draw );
2391     }
2392 }
2393
2394 =head2 $c->log_request_headers($headers);
2395
2396 Hook method which can be wrapped by plugins to log the request headers.
2397 No-op in the default implementation.
2398
2399 =cut
2400
2401 sub log_request_headers {}
2402
2403 =head2 $c->log_headers($type => $headers)
2404
2405 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2406
2407 =cut
2408
2409 sub log_headers {
2410     my $c       = shift;
2411     my $type    = shift;
2412     my $headers = shift;    # an HTTP::Headers instance
2413
2414     return unless $c->debug;
2415
2416     my $column_width = Catalyst::Utils::term_width() - 28;
2417     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2418     $headers->scan(
2419         sub {
2420             my ( $name, $value ) = @_;
2421             $t->row( $name, $value );
2422         }
2423     );
2424     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2425 }
2426
2427
2428 =head2 $c->prepare_read
2429
2430 Prepares the input for reading.
2431
2432 =cut
2433
2434 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2435
2436 =head2 $c->prepare_request
2437
2438 Prepares the engine request.
2439
2440 =cut
2441
2442 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2443
2444 =head2 $c->prepare_uploads
2445
2446 Prepares uploads.
2447
2448 =cut
2449
2450 sub prepare_uploads {
2451     my $c = shift;
2452
2453     $c->engine->prepare_uploads( $c, @_ );
2454 }
2455
2456 =head2 $c->prepare_write
2457
2458 Prepares the output for writing.
2459
2460 =cut
2461
2462 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2463
2464 =head2 $c->request_class
2465
2466 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2467
2468 =head2 $c->response_class
2469
2470 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2471
2472 =head2 $c->read( [$maxlength] )
2473
2474 Reads a chunk of data from the request body. This method is designed to
2475 be used in a while loop, reading C<$maxlength> bytes on every call.
2476 C<$maxlength> defaults to the size of the request if not specified.
2477
2478 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2479 directly.
2480
2481 Warning: If you use read(), Catalyst will not process the body,
2482 so you will not be able to access POST parameters or file uploads via
2483 $c->request.  You must handle all body parsing yourself.
2484
2485 =cut
2486
2487 sub read { my $c = shift; return $c->request->read( @_ ) }
2488
2489 =head2 $c->run
2490
2491 Starts the engine.
2492
2493 =cut
2494
2495 sub run {
2496   my $app = shift;
2497   $app->_make_immutable_if_needed;
2498   $app->engine_loader->needs_psgi_engine_compat_hack ?
2499     $app->engine->run($app, @_) :
2500       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2501 }
2502
2503 sub _make_immutable_if_needed {
2504     my $class = shift;
2505     my $meta = find_meta($class);
2506     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2507     if (
2508         $meta->is_immutable
2509         && ! { $meta->immutable_options }->{replace_constructor}
2510         && $isa_ca
2511     ) {
2512         warn("You made your application class ($class) immutable, "
2513             . "but did not inline the\nconstructor. "
2514             . "This will break catalyst, as your app \@ISA "
2515             . "Class::Accessor(::Fast)?\nPlease pass "
2516             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2517     }
2518     unless ($meta->is_immutable) {
2519         # XXX - FIXME warning here as you should make your app immutable yourself.
2520         $meta->make_immutable(
2521             replace_constructor => 1,
2522         );
2523     }
2524 }
2525
2526 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2527
2528 Sets an action in a given namespace.
2529
2530 =cut
2531
2532 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2533
2534 =head2 $c->setup_actions($component)
2535
2536 Sets up actions for a component.
2537
2538 =cut
2539
2540 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2541
2542 =head2 $c->setup_components
2543
2544 This method is called internally to set up the application's components.
2545
2546 It finds modules by calling the L<locate_components> method, expands them to
2547 package names with the L<expand_component_module> method, and then installs
2548 each component into the application.
2549
2550 The C<setup_components> config option is passed to both of the above methods.
2551
2552 Installation of each component is performed by the L<setup_component> method,
2553 below.
2554
2555 =cut
2556
2557 sub setup_components {
2558     my $class = shift;
2559
2560     my $config  = $class->config->{ setup_components };
2561
2562     my @comps = $class->locate_components($config);
2563     my %comps = map { $_ => 1 } @comps;
2564
2565     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2566     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2567         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2568     ) if $deprecatedcatalyst_component_names;
2569
2570     for my $component ( @comps ) {
2571
2572         # We pass ignore_loaded here so that overlay files for (e.g.)
2573         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2574         # we know M::P::O found a file on disk so this is safe
2575
2576         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2577     }
2578
2579     for my $component (@comps) {
2580         my $instance = $class->components->{ $component } = $class->setup_component($component);
2581         my @expanded_components = $instance->can('expand_modules')
2582             ? $instance->expand_modules( $component, $config )
2583             : $class->expand_component_module( $component, $config );
2584         for my $component (@expanded_components) {
2585             next if $comps{$component};
2586             $class->components->{ $component } = $class->setup_component($component);
2587         }
2588     }
2589 }
2590
2591 =head2 $c->locate_components( $setup_component_config )
2592
2593 This method is meant to provide a list of component modules that should be
2594 setup for the application.  By default, it will use L<Module::Pluggable>.
2595
2596 Specify a C<setup_components> config option to pass additional options directly
2597 to L<Module::Pluggable>. To add additional search paths, specify a key named
2598 C<search_extra> as an array reference. Items in the array beginning with C<::>
2599 will have the application class name prepended to them.
2600
2601 =cut
2602
2603 sub locate_components {
2604     my $class  = shift;
2605     my $config = shift;
2606
2607     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
2608     my $extra   = delete $config->{ search_extra } || [];
2609
2610     unshift @paths, @$extra;
2611
2612     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
2613       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
2614       %$config
2615     )->plugins } @paths;
2616
2617     return @comps;
2618 }
2619
2620 =head2 $c->expand_component_module( $component, $setup_component_config )
2621
2622 Components found by C<locate_components> will be passed to this method, which
2623 is expected to return a list of component (package) names to be set up.
2624
2625 =cut
2626
2627 sub expand_component_module {
2628     my ($class, $module) = @_;
2629     return Devel::InnerPackage::list_packages( $module );
2630 }
2631
2632 =head2 $c->setup_component
2633
2634 =cut
2635
2636 sub setup_component {
2637     my( $class, $component ) = @_;
2638
2639     unless ( $component->can( 'COMPONENT' ) ) {
2640         return $component;
2641     }
2642
2643     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2644     my $config = $class->config->{ $suffix } || {};
2645     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2646     # methods also pass it. local to avoid pointlessly shitting in config
2647     # for the debug screen, as $component is already the key name.
2648     local $config->{catalyst_component_name} = $component;
2649
2650     my $instance = eval { $component->COMPONENT( $class, $config ); };
2651
2652     if ( my $error = $@ ) {
2653         chomp $error;
2654         Catalyst::Exception->throw(
2655             message => qq/Couldn't instantiate component "$component", "$error"/
2656         );
2657     }
2658
2659     unless (blessed $instance) {
2660         my $metaclass = Moose::Util::find_meta($component);
2661         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2662         my $component_method_from = $method_meta->associated_metaclass->name;
2663         my $value = defined($instance) ? $instance : 'undef';
2664         Catalyst::Exception->throw(
2665             message =>
2666             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2667         );
2668     }
2669     return $instance;
2670 }
2671
2672 =head2 $c->setup_dispatcher
2673
2674 Sets up dispatcher.
2675
2676 =cut
2677
2678 sub setup_dispatcher {
2679     my ( $class, $dispatcher ) = @_;
2680
2681     if ($dispatcher) {
2682         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2683     }
2684
2685     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2686         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2687     }
2688
2689     unless ($dispatcher) {
2690         $dispatcher = $class->dispatcher_class;
2691     }
2692
2693     load_class($dispatcher);
2694
2695     # dispatcher instance
2696     $class->dispatcher( $dispatcher->new );
2697 }
2698
2699 =head2 $c->setup_engine
2700
2701 Sets up engine.
2702
2703 =cut
2704
2705 sub engine_class {
2706     my ($class, $requested_engine) = @_;
2707
2708     if (!$class->engine_loader || $requested_engine) {
2709         $class->engine_loader(
2710             Catalyst::EngineLoader->new({
2711                 application_name => $class,
2712                 (defined $requested_engine
2713                      ? (catalyst_engine_class => $requested_engine) : ()),
2714             }),
2715         );
2716     }
2717
2718     $class->engine_loader->catalyst_engine_class;
2719 }
2720
2721 sub setup_engine {
2722     my ($class, $requested_engine) = @_;
2723
2724     my $engine = do {
2725         my $loader = $class->engine_loader;
2726
2727         if (!$loader || $requested_engine) {
2728             $loader = Catalyst::EngineLoader->new({
2729                 application_name => $class,
2730                 (defined $requested_engine
2731                      ? (requested_engine => $requested_engine) : ()),
2732             }),
2733
2734             $class->engine_loader($loader);
2735         }
2736
2737         $loader->catalyst_engine_class;
2738     };
2739
2740     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2741     return if $class->loading_psgi_file;
2742
2743     load_class($engine);
2744
2745     if ($ENV{MOD_PERL}) {
2746         my $apache = $class->engine_loader->auto;
2747
2748         my $meta = find_meta($class);
2749         my $was_immutable = $meta->is_immutable;
2750         my %immutable_options = $meta->immutable_options;
2751         $meta->make_mutable if $was_immutable;
2752
2753         $meta->add_method(handler => sub {
2754             my $r = shift;
2755             my $psgi_app = $class->_finalized_psgi_app;
2756             $apache->call_app($r, $psgi_app);
2757         });
2758
2759         $meta->make_immutable(%immutable_options) if $was_immutable;
2760     }
2761
2762     $class->engine( $engine->new );
2763
2764     return;
2765 }
2766
2767 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2768 ## build in server support (back compat support for pre psgi port behavior).
2769 ## This is so that we don't build a new psgi app for each request when using
2770 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2771
2772 sub _finalized_psgi_app {
2773     my ($app) = @_;
2774
2775     unless ($app->_psgi_app) {
2776         my $psgi_app = $app->_setup_psgi_app;
2777         $app->_psgi_app($psgi_app);
2778     }
2779
2780     return $app->_psgi_app;
2781 }
2782
2783 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2784 ## home directory and load that and return it (just assume it is doing the
2785 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2786 ## in default_middleware and return it ( this is for backward compatibility
2787 ## with pre psgi port behavior ).
2788
2789 sub _setup_psgi_app {
2790     my ($app) = @_;
2791
2792     for my $home (Path::Class::Dir->new($app->config->{home})) {
2793         my $psgi_file = $home->file(
2794             Catalyst::Utils::appprefix($app) . '.psgi',
2795         );
2796
2797         next unless -e $psgi_file;
2798
2799         # If $psgi_file calls ->setup_engine, it's doing so to load
2800         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2801         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2802         # anyway. So set a flag (ick) that tells setup_engine not to populate
2803         # $c->engine or do any other things we might regret.
2804
2805         $app->loading_psgi_file(1);
2806         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2807         $app->loading_psgi_file(0);
2808
2809         return $psgi_app
2810             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2811
2812         warn <<"EOW";
2813 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2814
2815 Its content has been ignored. Please consult the Catalyst::Upgrading
2816 documentation on how to upgrade from Catalyst::Engine::PSGI.
2817 EOW
2818     }
2819
2820     return $app->apply_default_middlewares($app->psgi_app);
2821 }
2822
2823 =head2 $c->apply_default_middlewares
2824
2825 Adds the following L<Plack> middlewares to your application, since they are
2826 useful and commonly needed:
2827
2828 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2829 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2830 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2831 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2832 applied since this middleware is smart enough to conditionally apply itself).
2833
2834 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2835 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2836 $ENV{SCRIPT_NAME}
2837
2838 =cut
2839
2840
2841 sub apply_default_middlewares {
2842     my ($app, $psgi_app) = @_;
2843
2844     $psgi_app = Plack::Middleware::Conditional->wrap(
2845         $psgi_app,
2846         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2847         condition => sub {
2848             my ($env) = @_;
2849             return if $app->config->{ignore_frontend_proxy};
2850             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2851                 || $app->config->{using_frontend_proxy};
2852         },
2853     );
2854
2855     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2856     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2857     $psgi_app = Plack::Middleware::Conditional->wrap(
2858         $psgi_app,
2859         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2860         condition => sub {
2861             my ($env) = @_;
2862             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2863             return unless $1 < 4.23;
2864             1;
2865         },
2866     );
2867
2868     # we're applying this unconditionally as the middleware itself already makes
2869     # sure it doesn't fuck things up if it's not running under one of the right
2870     # IIS versions
2871     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2872
2873     # And another IIS issue, this time with IIS7.
2874     $psgi_app = Plack::Middleware::Conditional->wrap(
2875         $psgi_app,
2876         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2877         condition => sub {
2878             my ($env) = @_;
2879             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2880         },
2881     );
2882
2883     return $psgi_app;
2884 }
2885
2886 =head2 $c->psgi_app
2887
2888 Returns a PSGI application code reference for the catalyst application
2889 C<$c>. This is the bare application without any middlewares
2890 applied. C<${myapp}.psgi> is not taken into account.
2891
2892 This is what you want to be using to retrieve the PSGI application code
2893 reference of your Catalyst application for use in F<.psgi> files.
2894
2895 =cut
2896
2897 sub psgi_app {
2898     my ($app) = @_;
2899     my $psgi = $app->engine->build_psgi_app($app);
2900     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
2901 }
2902
2903 =head2 $c->setup_home
2904
2905 Sets up the home directory.
2906
2907 =cut
2908
2909 sub setup_home {
2910     my ( $class, $home ) = @_;
2911
2912     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2913         $home = $env;
2914     }
2915
2916     $home ||= Catalyst::Utils::home($class);
2917
2918     if ($home) {
2919         #I remember recently being scolded for assigning config values like this
2920         $class->config->{home} ||= $home;
2921         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2922     }
2923 }
2924
2925 =head2 $c->setup_log
2926
2927 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2928 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2929 log to.
2930
2931 This method also installs a C<debug> method that returns a true value into the
2932 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2933 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2934
2935 Note that if the log has already been setup, by either a previous call to
2936 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2937 that this method won't actually set up the log object.
2938
2939 =cut
2940
2941 sub setup_log {
2942     my ( $class, $levels ) = @_;
2943
2944     $levels ||= '';
2945     $levels =~ s/^\s+//;
2946     $levels =~ s/\s+$//;
2947     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2948
2949     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2950     if ( defined $env_debug ) {
2951         $levels{debug} = 1 if $env_debug; # Ugly!
2952         delete($levels{debug}) unless $env_debug;
2953     }
2954
2955     unless ( $class->log ) {
2956         $class->log( Catalyst::Log->new(keys %levels) );
2957     }
2958
2959     if ( $levels{debug} ) {
2960         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2961         $class->log->debug('Debug messages enabled');
2962     }
2963 }
2964
2965 =head2 $c->setup_plugins
2966
2967 Sets up plugins.
2968
2969 =cut
2970
2971 =head2 $c->setup_stats
2972
2973 Sets up timing statistics class.
2974
2975 =cut
2976
2977 sub setup_stats {
2978     my ( $class, $stats ) = @_;
2979
2980     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2981
2982     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2983     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2984         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2985         $class->log->debug('Statistics enabled');
2986     }
2987 }
2988
2989
2990 =head2 $c->registered_plugins
2991
2992 Returns a sorted list of the plugins which have either been stated in the
2993 import list.
2994
2995 If passed a given plugin name, it will report a boolean value indicating
2996 whether or not that plugin is loaded.  A fully qualified name is required if
2997 the plugin name does not begin with C<Catalyst::Plugin::>.
2998
2999  if ($c->registered_plugins('Some::Plugin')) {
3000      ...
3001  }
3002
3003 =cut
3004
3005 {
3006
3007     sub registered_plugins {
3008         my $proto = shift;
3009         return sort keys %{ $proto->_plugins } unless @_;
3010         my $plugin = shift;
3011         return 1 if exists $proto->_plugins->{$plugin};
3012         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3013     }
3014
3015     sub _register_plugin {
3016         my ( $proto, $plugin, $instant ) = @_;
3017         my $class = ref $proto || $proto;
3018
3019         load_class( $plugin );
3020         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3021             if $plugin->isa( 'Catalyst::Component' );
3022         my $plugin_meta = Moose::Meta::Class->create($plugin);
3023         if (!$plugin_meta->has_method('new')
3024             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3025             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3026         }
3027         if (!$instant && !$proto->_plugins->{$plugin}) {
3028             my $meta = Class::MOP::get_metaclass_by_name($class);
3029             $meta->superclasses($plugin, $meta->superclasses);
3030         }
3031         $proto->_plugins->{$plugin} = 1;
3032         return $class;
3033     }
3034
3035     sub _default_plugins { return qw(Unicode::Encoding) }
3036
3037     sub setup_plugins {
3038         my ( $class, $plugins ) = @_;
3039
3040         $class->_plugins( {} ) unless $class->_plugins;
3041         $plugins = [ grep {
3042             m/Unicode::Encoding/ ? do {
3043                 $class->log->warn(
3044                     'Unicode::Encoding plugin is auto-applied,'
3045                     . ' please remove this from your appclass'
3046                     . ' and make sure to define "encoding" config'
3047                 );
3048                 unless (exists $class->config->{'encoding'}) {
3049                   $class->config->{'encoding'} = 'UTF-8';
3050                 }
3051                 () }
3052                 : $_
3053         } @$plugins ];
3054         push @$plugins, $class->_default_plugins;
3055         $plugins = Data::OptList::mkopt($plugins || []);
3056
3057         my @plugins = map {
3058             [ Catalyst::Utils::resolve_namespace(
3059                   $class . '::Plugin',
3060                   'Catalyst::Plugin', $_->[0]
3061               ),
3062               $_->[1],
3063             ]
3064          } @{ $plugins };
3065
3066         for my $plugin ( reverse @plugins ) {
3067             load_class($plugin->[0], $plugin->[1]);
3068             my $meta = find_meta($plugin->[0]);
3069             next if $meta && $meta->isa('Moose::Meta::Role');
3070
3071             $class->_register_plugin($plugin->[0]);
3072         }
3073
3074         my @roles =
3075             map  { $_->[0]->name, $_->[1] }
3076             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3077             map  { [find_meta($_->[0]), $_->[1]] }
3078             @plugins;
3079
3080         Moose::Util::apply_all_roles(
3081             $class => @roles
3082         ) if @roles;
3083     }
3084 }
3085
3086 =head2 registered_middlewares
3087
3088 Read only accessor that returns an array of all the middleware in the order
3089 that they were added (which is the REVERSE of the order they will be applied).
3090
3091 The values returned will be either instances of L<Plack::Middleware> or of a
3092 compatible interface, or a coderef, which is assumed to be inlined middleware
3093
3094 =head2 setup_middleware (?@middleware)
3095
3096 Read configuration information stored in configuration key C<psgi_middleware> or
3097 from passed @args.
3098
3099 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3100 to use it to enable L<Plack::Middleware>
3101
3102 This method is automatically called during 'setup' of your application, so
3103 you really don't need to invoke it.  However you may do so if you find the idea
3104 of loading middleware via configuration weird :).  For example:
3105
3106     package MyApp;
3107
3108     use Catalyst;
3109
3110     __PACKAGE__->setup_middleware('Head');
3111     __PACKAGE__->setup;
3112
3113 When we read middleware definitions from configuration, we reverse the list
3114 which sounds odd but is likely how you expect it to work if you have prior
3115 experience with L<Plack::Builder> or if you previously used the plugin
3116 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3117
3118 So basically your middleware handles an incoming request from the first
3119 registered middleware, down and handles the response from the last middleware
3120 up.
3121
3122 =cut
3123
3124 sub registered_middlewares {
3125     my $class = shift;
3126     if(my $middleware = $class->_psgi_middleware) {
3127         return (
3128           Catalyst::Middleware::Stash->new,
3129           Plack::Middleware::HTTPExceptions->new,
3130           Plack::Middleware::RemoveRedundantBody->new,
3131           Plack::Middleware::FixMissingBodyInRedirect->new,
3132           Plack::Middleware::ContentLength->new,
3133           Plack::Middleware::MethodOverride->new,
3134           Plack::Middleware::Head->new,
3135           @$middleware);
3136     } else {
3137         die "You cannot call ->registered_middlewares until middleware has been setup";
3138     }
3139 }
3140
3141 sub setup_middleware {
3142     my $class = shift;
3143     my @middleware_definitions = @_ ?
3144       reverse(@_) : reverse(@{$class->config->{'psgi_middleware'}||[]});
3145
3146     my @middleware = ();
3147     while(my $next = shift(@middleware_definitions)) {
3148         if(ref $next) {
3149             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3150                 push @middleware, $next;
3151             } elsif(ref $next eq 'CODE') {
3152                 push @middleware, $next;
3153             } elsif(ref $next eq 'HASH') {
3154                 my $namespace = shift @middleware_definitions;
3155                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3156                 push @middleware, $mw;
3157             } else {
3158               die "I can't handle middleware definition ${\ref $next}";
3159             }
3160         } else {
3161           my $mw = $class->Catalyst::Utils::build_middleware($next);
3162           push @middleware, $mw;
3163         }
3164     }
3165
3166     my @existing = @{$class->_psgi_middleware || []};
3167     $class->_psgi_middleware([@middleware,@existing,]);
3168 }
3169
3170 =head2 registered_data_handlers
3171
3172 A read only copy of registered Data Handlers returned as a Hash, where each key
3173 is a content type and each value is a subref that attempts to decode that content
3174 type.
3175
3176 =head2 setup_data_handlers (?@data_handler)
3177
3178 Read configuration information stored in configuration key C<data_handlers> or
3179 from passed @args.
3180
3181 See under L</CONFIGURATION> information regarding C<data_handlers>.
3182
3183 This method is automatically called during 'setup' of your application, so
3184 you really don't need to invoke it.
3185
3186 =head2 default_data_handlers
3187
3188 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3189 only two default data handlers, for 'application/json' and an alternative to
3190 'application/x-www-form-urlencoded' which supposed nested form parameters via
3191 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3192
3193 The 'application/json' data handler is used to parse incoming JSON into a Perl
3194 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3195 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3196 JSON decoder, and has the smallest dependency impact.
3197
3198 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3199 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3200 order to get the best performance.  You should add either to your dependency
3201 list (Makefile.PL, dist.ini, cpanfile, etc.)
3202
3203 =cut
3204
3205 sub registered_data_handlers {
3206     my $class = shift;
3207     if(my $data_handlers = $class->_data_handlers) {
3208         return %$data_handlers;
3209     } else {
3210         $class->setup_data_handlers;
3211         return $class->registered_data_handlers;
3212     }
3213 }
3214
3215 sub setup_data_handlers {
3216     my ($class, %data_handler_callbacks) = @_;
3217     %data_handler_callbacks = (
3218       %{$class->default_data_handlers},
3219       %{$class->config->{'data_handlers'}||+{}},
3220       %data_handler_callbacks);
3221
3222     $class->_data_handlers(\%data_handler_callbacks);
3223 }
3224
3225 sub default_data_handlers {
3226     my ($class) = @_;
3227     return +{
3228       'application/x-www-form-urlencoded' => sub {
3229           my ($fh, $req) = @_;
3230           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3231           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3232             ->can('build_cgi_struct')->($params);
3233       },
3234       'application/json' => sub {
3235           Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON')
3236             ->can('decode_json')->(do { local $/; $_->getline });
3237       },
3238     };
3239 }
3240
3241 =head2 $c->stack
3242
3243 Returns an arrayref of the internal execution stack (actions that are
3244 currently executing).
3245
3246 =head2 $c->stats
3247
3248 Returns the current timing statistics object. By default Catalyst uses
3249 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3250 L<< stats_class|/"$c->stats_class" >>.
3251
3252 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3253 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3254 profile explicitly, although MyApp.pm still won't profile nor output anything
3255 by itself.
3256
3257 =head2 $c->stats_class
3258
3259 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3260
3261 =head2 $c->use_stats
3262
3263 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3264
3265 Note that this is a static method, not an accessor and should be overridden
3266 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3267
3268 =cut
3269
3270 sub use_stats { 0 }
3271
3272
3273 =head2 $c->write( $data )
3274
3275 Writes $data to the output stream. When using this method directly, you
3276 will need to manually set the C<Content-Length> header to the length of
3277 your output data, if known.
3278
3279 =cut
3280
3281 sub write {
3282     my $c = shift;
3283
3284     # Finalize headers if someone manually writes output (for compat)
3285     $c->finalize_headers;
3286
3287     return $c->response->write( @_ );
3288 }
3289
3290 =head2 version
3291
3292 Returns the Catalyst version number. Mostly useful for "powered by"
3293 messages in template systems.
3294
3295 =cut
3296
3297 sub version { return $Catalyst::VERSION }
3298
3299 =head1 CONFIGURATION
3300
3301 There are a number of 'base' config variables which can be set:
3302
3303 =over
3304
3305 =item *
3306
3307 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3308
3309 =item *
3310
3311 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3312
3313 =item *
3314
3315 C<disable_component_resolution_regex_fallback> - Turns
3316 off the deprecated component resolution functionality so
3317 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3318 are called then regex search will not be attempted on string values and
3319 instead C<undef> will be returned.
3320
3321 =item *
3322
3323 C<home> - The application home directory. In an uninstalled application,
3324 this is the top level application directory. In an installed application,
3325 this will be the directory containing C<< MyApp.pm >>.
3326
3327 =item *
3328
3329 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3330
3331 =item *
3332
3333 C<name> - The name of the application in debug messages and the debug and
3334 welcome screens
3335
3336 =item *
3337
3338 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3339 until it is accessed. This allows you to (for example) check authentication (and reject
3340 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3341
3342 =item *
3343
3344 C<root> - The root directory for templates. Usually this is just a
3345 subdirectory of the home directory, but you can set it to change the
3346 templates to a different directory.
3347
3348 =item *
3349
3350 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3351 namespaces from which components will be loaded (and constructed and stored in
3352 C<< $c->components >>).
3353
3354 =item *
3355
3356 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3357 to be shown in hit debug tables in the test server.
3358
3359 =item *
3360
3361 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3362 variable should be used for determining the request path.
3363
3364 Most web server environments pass the requested path to the application using environment variables,
3365 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3366 exposed as C<< $c->request->base >>) and the request path below that base.
3367
3368 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3369 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3370
3371 =over
3372
3373 =item use_request_uri_for_path => 0
3374
3375 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3376 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3377 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3378 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3379
3380 However this method has the major disadvantage that it is impossible to correctly decode some elements
3381 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3382 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3383 can't distinguish / vs %2F in paths (in addition to other encoded values).
3384
3385 =item use_request_uri_for_path => 1
3386
3387 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3388 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3389 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3390
3391 Given that this method of path resolution is provably more correct, it is recommended that you use
3392 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3393 aware of the implications of not being able to handle encoded URI paths correctly.
3394
3395 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3396 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3397 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3398 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3399 C<< $c->request->base >> will be incorrect.
3400
3401 =back
3402
3403 =item *
3404
3405 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3406
3407 =item *
3408
3409 C<encoding> - See L</ENCODING>
3410
3411 =item *
3412
3413 C<abort_chain_on_error_fix>
3414
3415 When there is an error in an action chain, the default behavior is to continue
3416 processing the remaining actions and then catch the error upon chain end.  This
3417 can lead to running actions when the application is in an unexpected state.  If
3418 you have this issue, setting this config value to true will promptly exit a
3419 chain when there is an error raised in any action (thus terminating the chain
3420 early.)
3421
3422 use like:
3423
3424     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3425
3426 In the future this might become the default behavior.
3427
3428 =item *
3429
3430 C<use_hash_multivalue_in_request>
3431
3432 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3433 and C<parameters> return a hashref where values might be scalar or an arrayref
3434 depending on the incoming data.  In many cases this can be undesirable as it
3435 leads one to writing defensive code like the following:
3436
3437     my ($val) = ref($c->req->parameters->{a}) ?
3438       @{$c->req->parameters->{a}} :
3439         $c->req->parameters->{a};
3440
3441 Setting this configuration item to true will make L<Catalyst> populate the
3442 attributes underlying these methods with an instance of L<Hash::MultiValue>
3443 which is used by L<Plack::Request> and others to solve this very issue.  You
3444 may prefer this behavior to the default, if so enable this option (be warned
3445 if you enable it in a legacy application we are not sure if it is completely
3446 backwardly compatible).
3447
3448 =item *
3449
3450 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3451
3452 =item *
3453
3454 C<data_handlers> - See L<DATA HANDLERS>.
3455
3456 =back
3457
3458 =head1 EXCEPTIONS
3459
3460 Generally when you throw an exception inside an Action (or somewhere in
3461 your stack, such as in a model that an Action is calling) that exception
3462 is caught by Catalyst and unless you either catch it yourself (via eval
3463 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
3464 will eventually reach L</finalize_errors> and return either the debugging
3465 error stack page, or the default error page.  However, if your exception
3466 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
3467 instead rethrow it so that it can be handled by that middleware (which
3468 is part of the default middleware).  For example this would allow
3469
3470     use HTTP::Throwable::Factory 'http_throw';
3471
3472     sub throws_exception :Local {
3473       my ($self, $c) = @_;
3474
3475       http_throw(SeeOther => { location =>
3476         $c->uri_for($self->action_for('redirect')) });
3477
3478     }
3479
3480 =head1 INTERNAL ACTIONS
3481
3482 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3483 C<_ACTION>, and C<_END>. These are by default not shown in the private
3484 action table, but you can make them visible with a config parameter.
3485
3486     MyApp->config(show_internal_actions => 1);
3487
3488 =head1 ON-DEMAND PARSER
3489
3490 The request body is usually parsed at the beginning of a request,
3491 but if you want to handle input yourself, you can enable on-demand
3492 parsing with a config parameter.
3493
3494     MyApp->config(parse_on_demand => 1);
3495
3496 =head1 PROXY SUPPORT
3497
3498 Many production servers operate using the common double-server approach,
3499 with a lightweight frontend web server passing requests to a larger
3500 backend server. An application running on the backend server must deal
3501 with two problems: the remote user always appears to be C<127.0.0.1> and
3502 the server's hostname will appear to be C<localhost> regardless of the
3503 virtual host that the user connected through.
3504
3505 Catalyst will automatically detect this situation when you are running
3506 the frontend and backend servers on the same machine. The following
3507 changes are made to the request.
3508
3509     $c->req->address is set to the user's real IP address, as read from
3510     the HTTP X-Forwarded-For header.
3511
3512     The host value for $c->req->base and $c->req->uri is set to the real
3513     host, as read from the HTTP X-Forwarded-Host header.
3514
3515 Additionally, you may be running your backend application on an insecure
3516 connection (port 80) while your frontend proxy is running under SSL.  If there
3517 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3518 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3519 be created properly.
3520
3521 In the case of passing in:
3522
3523     X-Forwarded-Port: 443
3524
3525 All calls to C<uri_for> will result in an https link, as is expected.
3526
3527 Obviously, your web server must support these headers for this to work.
3528
3529 In a more complex server farm environment where you may have your
3530 frontend proxy server(s) on different machines, you will need to set a
3531 configuration option to tell Catalyst to read the proxied data from the
3532 headers.
3533
3534     MyApp->config(using_frontend_proxy => 1);
3535
3536 If you do not wish to use the proxy support at all, you may set:
3537
3538     MyApp->config(ignore_frontend_proxy => 0);
3539
3540 =head2 Note about psgi files
3541
3542 Note that if you supply your own .psgi file, calling
3543 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3544
3545 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3546 in your psgi, for example:
3547
3548     builder {
3549         enable "Plack::Middleware::ReverseProxy";
3550         MyApp->psgi_app
3551     };
3552
3553 This will unconditionally add the ReverseProxy support, or you need to call
3554 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3555 apply the support depending upon your config).
3556
3557 See L<Catalyst::PSGI> for more information.
3558
3559 =head1 THREAD SAFETY
3560
3561 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3562 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3563 believe the Catalyst core to be thread-safe.
3564
3565 If you plan to operate in a threaded environment, remember that all other
3566 modules you are using must also be thread-safe. Some modules, most notably
3567 L<DBD::SQLite>, are not thread-safe.
3568
3569 =head1 DATA HANDLERS
3570
3571 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3572 form parameters and URL search query fields.  However it has become common
3573 for various alternative content types to be PUT or POSTed to your controllers
3574 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3575 XML and other content types when communicating with an application server.  In
3576 order to better support this use case, L<Catalyst> defines a global configuration
3577 option, C<data_handlers>, which lets you associate a content type with a coderef
3578 that parses that content type into something Perl can readily access.
3579
3580     package MyApp::Web;
3581
3582     use Catalyst;
3583     use JSON::Maybe;
3584
3585     __PACKAGE__->config(
3586       data_handlers => {
3587         'application/json' => sub { local $/; decode_json $_->getline },
3588       },
3589       ## Any other configuration.
3590     );
3591
3592     __PACKAGE__->setup;
3593
3594 By default L<Catalyst> comes with a generic JSON data handler similar to the
3595 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
3596 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
3597 it installed (if you want the faster XS parser, add it to you project Makefile.PL
3598 or dist.ini, cpanfile, etc.)
3599
3600 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
3601 (matched against the incoming request type using a regexp such as to be case
3602 insensitive) and whose values are coderefs that receive a localized version of
3603 C<$_> which is a filehandle object pointing to received body.
3604
3605 This feature is considered an early access release and we reserve the right
3606 to alter the interface in order to provide a performant and secure solution to
3607 alternative request body content.  Your reports welcomed!
3608
3609 =head1 PSGI MIDDLEWARE
3610
3611 You can define middleware, defined as L<Plack::Middleware> or a compatible
3612 interface in configuration.  Your middleware definitions are in the form of an
3613 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3614 with details to follow:
3615
3616     package MyApp::Web;
3617
3618     use Catalyst;
3619     use Plack::Middleware::StackTrace;
3620
3621     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3622
3623     __PACKAGE__->config(
3624       'psgi_middleware', [
3625         'Debug',
3626         '+MyApp::Custom',
3627         $stacktrace_middleware,
3628         'Session' => {store => 'File'},
3629         sub {
3630           my $app = shift;
3631           return sub {
3632             my $env = shift;
3633             $env->{myapp.customkey} = 'helloworld';
3634             $app->($env);
3635           },
3636         },
3637       ],
3638     );
3639
3640     __PACKAGE__->setup;
3641
3642 So the general form is:
3643
3644     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3645
3646 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3647 the order listed (to make it function similarly to L<Plack::Builder>:
3648
3649 Alternatively, you may also define middleware by calling the L</setup_middleware>
3650 package method:
3651
3652     package MyApp::Web;
3653
3654     use Catalyst;
3655
3656     __PACKAGE__->setup_middleware( \@middleware_definitions);
3657     __PACKAGE__->setup;
3658
3659 In the case where you do both (use 'setup_middleware' and configuration) the
3660 package call to setup_middleware will be applied earlier (in other words its
3661 middleware will wrap closer to the application).  Keep this in mind since in
3662 some cases the order of middleware is important.
3663
3664 The two approaches are not exclusive.
3665
3666 =over 4
3667
3668 =item Middleware Object
3669
3670 An already initialized object that conforms to the L<Plack::Middleware>
3671 specification:
3672
3673     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3674
3675     __PACKAGE__->config(
3676       'psgi_middleware', [
3677         $stacktrace_middleware,
3678       ]);
3679
3680
3681 =item coderef
3682
3683 A coderef that is an inlined middleware:
3684
3685     __PACKAGE__->config(
3686       'psgi_middleware', [
3687         sub {
3688           my $app = shift;
3689           return sub {
3690             my $env = shift;
3691             if($env->{PATH_INFO} =~m/forced/) {
3692               Plack::App::File
3693                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3694                 ->call($env);
3695             } else {
3696               return $app->($env);
3697             }
3698          },
3699       },
3700     ]);
3701
3702
3703
3704 =item a scalar
3705
3706 We assume the scalar refers to a namespace after normalizing it using the
3707 following rules:
3708
3709 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3710 is assumed to be 'as is', and we just install and use the middleware.
3711
3712 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3713 (the package name of your Catalyst application subclass), we also assume then
3714 that it is a full namespace, and use it.
3715
3716 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3717 resolve it first by looking for it under your application namespace (for example
3718 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3719 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3720 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3721 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3722 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3723 you find that a good idea.
3724
3725 Examples:
3726
3727     package MyApp::Web;
3728
3729     __PACKAGE__->config(
3730       'psgi_middleware', [
3731         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3732         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3733         '+MyApp::Custom',  ## MyApp::Custom->wrap
3734       ],
3735     );
3736
3737 =item a scalar followed by a hashref
3738
3739 Just like the previous, except the following C<HashRef> is used as arguments
3740 to initialize the middleware object.
3741
3742     __PACKAGE__->config(
3743       'psgi_middleware', [
3744          'Session' => {store => 'File'},
3745     ]);
3746
3747 =back
3748
3749 Please see L<PSGI> for more on middleware.
3750
3751 =head1 ENCODING
3752
3753 On request, decodes all params from encoding into a sequence of
3754 logical characters. On response, encodes body into encoding.
3755
3756 =head2 Methods
3757
3758 =over 4
3759
3760 =item encoding
3761
3762 Returns an instance of an C<Encode> encoding
3763
3764     print $c->encoding->name
3765
3766 =item handle_unicode_encoding_exception ($exception_context)
3767
3768 Method called when decoding process for a request fails.
3769
3770 An C<$exception_context> hashref is provided to allow you to override the
3771 behaviour of your application when given data with incorrect encodings.
3772
3773 The default method throws exceptions in the case of invalid request parameters
3774 (resulting in a 500 error), but ignores errors in upload filenames.
3775
3776 The keys passed in the C<$exception_context> hash are:
3777
3778 =over
3779
3780 =item param_value
3781
3782 The value which was not able to be decoded.
3783
3784 =item error_msg
3785
3786 The exception received from L<Encode>.
3787
3788 =item encoding_step
3789
3790 What type of data was being decoded. Valid values are (currently)
3791 C<params> - for request parameters / arguments / captures
3792 and C<uploads> - for request upload filenames.
3793
3794 =back
3795
3796 =back
3797
3798 =head1 SUPPORT
3799
3800 IRC:
3801
3802     Join #catalyst on irc.perl.org.
3803
3804 Mailing Lists:
3805
3806     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3807     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3808
3809 Web:
3810
3811     http://catalyst.perl.org
3812
3813 Wiki:
3814
3815     http://dev.catalyst.perl.org
3816
3817 =head1 SEE ALSO
3818
3819 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3820
3821 =head2 L<Catalyst::Manual> - The Catalyst Manual
3822
3823 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3824
3825 =head2 L<Catalyst::Engine> - Core engine
3826
3827 =head2 L<Catalyst::Log> - Log class.
3828
3829 =head2 L<Catalyst::Request> - Request object
3830
3831 =head2 L<Catalyst::Response> - Response object
3832
3833 =head2 L<Catalyst::Test> - The test suite.
3834
3835 =head1 PROJECT FOUNDER
3836
3837 sri: Sebastian Riedel <sri@cpan.org>
3838
3839 =head1 CONTRIBUTORS
3840
3841 abw: Andy Wardley
3842
3843 acme: Leon Brocard <leon@astray.com>
3844
3845 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3846
3847 Andrew Bramble
3848
3849 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3850
3851 Andrew Ruthven
3852
3853 andyg: Andy Grundman <andy@hybridized.org>
3854
3855 audreyt: Audrey Tang
3856
3857 bricas: Brian Cassidy <bricas@cpan.org>
3858
3859 Caelum: Rafael Kitover <rkitover@io.com>
3860
3861 chansen: Christian Hansen
3862
3863 chicks: Christopher Hicks
3864
3865 Chisel Wright C<pause@herlpacker.co.uk>
3866
3867 Danijel Milicevic C<me@danijel.de>
3868
3869 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3870
3871 David Naughton, C<naughton@umn.edu>
3872
3873 David E. Wheeler
3874
3875 dhoss: Devin Austin <dhoss@cpan.org>
3876
3877 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3878
3879 Drew Taylor
3880
3881 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3882
3883 esskar: Sascha Kiefer
3884
3885 fireartist: Carl Franks <cfranks@cpan.org>
3886
3887 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3888
3889 gabb: Danijel Milicevic
3890
3891 Gary Ashton Jones
3892
3893 Gavin Henry C<ghenry@perl.me.uk>
3894
3895 Geoff Richards
3896
3897 groditi: Guillermo Roditi <groditi@gmail.com>
3898
3899 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3900
3901 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3902
3903 jcamacho: Juan Camacho
3904
3905 jester: Jesse Sheidlower C<jester@panix.com>
3906
3907 jhannah: Jay Hannah <jay@jays.net>
3908
3909 Jody Belka
3910
3911 Johan Lindstrom
3912
3913 jon: Jon Schutz <jjschutz@cpan.org>
3914
3915 Jonathan Rockway C<< <jrockway@cpan.org> >>
3916
3917 Kieren Diment C<kd@totaldatasolution.com>
3918
3919 konobi: Scott McWhirter <konobi@cpan.org>
3920
3921 marcus: Marcus Ramberg <mramberg@cpan.org>
3922
3923 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3924
3925 mgrimes: Mark Grimes <mgrimes@cpan.org>
3926
3927 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3928
3929 mugwump: Sam Vilain
3930
3931 naughton: David Naughton
3932
3933 ningu: David Kamholz <dkamholz@cpan.org>
3934
3935 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3936
3937 numa: Dan Sully <daniel@cpan.org>
3938
3939 obra: Jesse Vincent
3940
3941 Octavian Rasnita
3942
3943 omega: Andreas Marienborg
3944
3945 Oleg Kostyuk <cub.uanic@gmail.com>
3946
3947 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3948
3949 rafl: Florian Ragwitz <rafl@debian.org>
3950
3951 random: Roland Lammel <lammel@cpan.org>
3952
3953 Robert Sedlacek C<< <rs@474.at> >>
3954
3955 SpiceMan: Marcel Montes
3956
3957 sky: Arthur Bergman
3958
3959 szbalint: Balint Szilakszi <szbalint@cpan.org>
3960
3961 t0m: Tomas Doran <bobtfish@bobtfish.net>
3962
3963 Ulf Edvinsson
3964
3965 vanstyn: Henry Van Styn <vanstyn@cpan.org>
3966
3967 Viljo Marrandi C<vilts@yahoo.com>
3968
3969 Will Hawes C<info@whawes.co.uk>
3970
3971 willert: Sebastian Willert <willert@cpan.org>
3972
3973 wreis: Wallace Reis <wreis@cpan.org>
3974
3975 Yuval Kogman, C<nothingmuch@woobling.org>
3976
3977 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3978
3979 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3980
3981 Upasana <me@upasana.me>
3982
3983 =head1 COPYRIGHT
3984
3985 Copyright (c) 2005-2014, the above named PROJECT FOUNDER and CONTRIBUTORS.
3986
3987 =head1 LICENSE
3988
3989 This library is free software. You can redistribute it and/or modify it under
3990 the same terms as Perl itself.
3991
3992 =cut
3993
3994 no Moose;
3995
3996 __PACKAGE__->meta->make_immutable;
3997
3998 1;