lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use bytes;
   8 use B::Hooks::EndOfScope ();
   9 use Catalyst::Exception;
  10 use Catalyst::Exception::Detach;
  11 use Catalyst::Exception::Go;
  12 use Catalyst::Log;
  13 use Catalyst::Request;
  14 use Catalyst::Request::Upload;
  15 use Catalyst::Response;
  16 use Catalyst::Utils;
  17 use Catalyst::Controller;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80013';
  83
  84 {
  85     my $dev_version = $VERSION =~ /_\d{2}$/;
  86     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  87 }
  88
  89 $VERSION = eval $VERSION;
  90
  91 sub import {
  92     my ( $class, @arguments ) = @_;
  93
  94     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  95     # callers @ISA.
  96     return unless $class eq 'Catalyst';
  97
  98     my $caller = caller();
  99     return if $caller eq 'main';
 100
 101     # Kill Adopt::NEXT warnings if we're a non-RC version
 102     unless (_IS_DEVELOPMENT_VERSION()) {
 103         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 104     }
 105
 106     my $meta = Moose::Meta::Class->initialize($caller);
 107     unless ( $caller->isa('Catalyst') ) {
 108         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 109         $meta->superclasses(@superclasses);
 110     }
 111     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 112     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 113
 114     unless( $meta->has_method('meta') ){
 115         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 116     }
 117
 118     $caller->arguments( [@arguments] );
 119     $caller->setup_home;
 120 }
 121
 122 sub _application { $_[0] }
 123
 124 =head1 NAME
 125
 126 Catalyst - The Elegant MVC Web Application Framework
 127
 128 =head1 SYNOPSIS
 129
 130 See the L<Catalyst::Manual> distribution for comprehensive
 131 documentation and tutorials.
 132
 133     # Install Catalyst::Devel for helpers and other development tools
 134     # use the helper to create a new application
 135     catalyst.pl MyApp
 136
 137     # add models, views, controllers
 138     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 139     script/myapp_create.pl view MyTemplate TT
 140     script/myapp_create.pl controller Search
 141
 142     # built in testserver -- use -r to restart automatically on changes
 143     # --help to see all available options
 144     script/myapp_server.pl
 145
 146     # command line testing interface
 147     script/myapp_test.pl /yada
 148
 149     ### in lib/MyApp.pm
 150     use Catalyst qw/-Debug/; # include plugins here as well
 151
 152     ### In lib/MyApp/Controller/Root.pm (autocreated)
 153     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 154         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 155         $c->stash->{template} = 'foo.tt'; # set the template
 156         # lookup something from db -- stash vars are passed to TT
 157         $c->stash->{data} =
 158           $c->model('Database::Foo')->search( { country => $args[0] } );
 159         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 160             $c->forward( 'bar' ); # process another action
 161             # do something else after forward returns
 162         }
 163     }
 164
 165     # The foo.tt TT template can use the stash data from the database
 166     [% WHILE (item = data.next) %]
 167         [% item.foo %]
 168     [% END %]
 169
 170     # called for /bar/of/soap, /bar/of/soap/10, etc.
 171     sub bar : Path('/bar/of/soap') { ... }
 172
 173     # called for all actions, from the top-most controller downwards
 174     sub auto : Private {
 175         my ( $self, $c ) = @_;
 176         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 177             $c->res->redirect( '/login' ); # require login
 178             return 0; # abort request and go immediately to end()
 179         }
 180         return 1; # success; carry on to next action
 181     }
 182
 183     # called after all actions are finished
 184     sub end : Private {
 185         my ( $self, $c ) = @_;
 186         if ( scalar @{ $c->error } ) { ... } # handle errors
 187         return if $c->res->body; # already have a response
 188         $c->forward( 'MyApp::View::TT' ); # render template
 189     }
 190
 191     ### in MyApp/Controller/Foo.pm
 192     # called for /foo/bar
 193     sub bar : Local { ... }
 194
 195     # called for /blargle
 196     sub blargle : Global { ... }
 197
 198     # an index action matches /foo, but not /foo/1, etc.
 199     sub index : Private { ... }
 200
 201     ### in MyApp/Controller/Foo/Bar.pm
 202     # called for /foo/bar/baz
 203     sub baz : Local { ... }
 204
 205     # first Root auto is called, then Foo auto, then this
 206     sub auto : Private { ... }
 207
 208     # powerful regular expression paths are also possible
 209     sub details : Regex('^product/(\w+)/details$') {
 210         my ( $self, $c ) = @_;
 211         # extract the (\w+) from the URI
 212         my $product = $c->req->captures->[0];
 213     }
 214
 215 See L<Catalyst::Manual::Intro> for additional information.
 216
 217 =head1 DESCRIPTION
 218
 219 Catalyst is a modern framework for making web applications without the
 220 pain usually associated with this process. This document is a reference
 221 to the main Catalyst application. If you are a new user, we suggest you
 222 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 223
 224 See L<Catalyst::Manual> for more documentation.
 225
 226 Catalyst plugins can be loaded by naming them as arguments to the "use
 227 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 228 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 229 C<My::Module>.
 230
 231     use Catalyst qw/My::Module/;
 232
 233 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 234 fully qualify the name by using a unary plus:
 235
 236     use Catalyst qw/
 237         My::Module
 238         +Fully::Qualified::Plugin::Name
 239     /;
 240
 241 Special flags like C<-Debug> and C<-Engine> can also be specified as
 242 arguments when Catalyst is loaded:
 243
 244     use Catalyst qw/-Debug My::Module/;
 245
 246 The position of plugins and flags in the chain is important, because
 247 they are loaded in the order in which they appear.
 248
 249 The following flags are supported:
 250
 251 =head2 -Debug
 252
 253 Enables debug output. You can also force this setting from the system
 254 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 255 settings override the application, with <MYAPP>_DEBUG having the highest
 256 priority.
 257
 258 =head2 -Engine
 259
 260 Forces Catalyst to use a specific engine. Omit the
 261 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 262
 263     use Catalyst qw/-Engine=CGI/;
 264
 265 =head2 -Home
 266
 267 Forces Catalyst to use a specific home directory, e.g.:
 268
 269     use Catalyst qw[-Home=/usr/mst];
 270
 271 This can also be done in the shell environment by setting either the
 272 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 273 is replaced with the uppercased name of your application, any "::" in
 274 the name will be replaced with underscores, e.g. MyApp::Web should use
 275 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 276
 277 =head2 -Log
 278
 279     use Catalyst '-Log=warn,fatal,error';
 280
 281 Specifies a comma-delimited list of log levels.
 282
 283 =head2 -Stats
 284
 285 Enables statistics collection and reporting. You can also force this setting
 286 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 287 environment settings override the application, with <MYAPP>_STATS having the
 288 highest priority.
 289
 290 e.g.
 291
 292    use Catalyst qw/-Stats=1/
 293
 294 =head1 METHODS
 295
 296 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 297
 298 =head2 $c->action
 299
 300 Returns a L<Catalyst::Action> object for the current action, which
 301 stringifies to the action name. See L<Catalyst::Action>.
 302
 303 =head2 $c->namespace
 304
 305 Returns the namespace of the current action, i.e., the URI prefix
 306 corresponding to the controller of the current action. For example:
 307
 308     # in Controller::Foo::Bar
 309     $c->namespace; # returns 'foo/bar';
 310
 311 =head2 $c->request
 312
 313 =head2 $c->req
 314
 315 Returns the current L<Catalyst::Request> object, giving access to
 316 information about the current client request (including parameters,
 317 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 318
 319 =head2 REQUEST FLOW HANDLING
 320
 321 =head2 $c->forward( $action [, \@arguments ] )
 322
 323 =head2 $c->forward( $class, $method, [, \@arguments ] )
 324
 325 Forwards processing to another action, by its private name. If you give a
 326 class name but no method, C<process()> is called. You may also optionally
 327 pass arguments in an arrayref. The action will receive the arguments in
 328 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 329 C<< $c->req->args >> will be restored to the previous values.
 330
 331 Any data C<return>ed from the action forwarded to, will be returned by the
 332 call to forward.
 333
 334     my $foodata = $c->forward('/foo');
 335     $c->forward('index');
 336     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 337     $c->forward('MyApp::View::TT');
 338
 339 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 340 an C<< eval { } >> around the call (actually
 341 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 342 all 'dies' within the called action. If you want C<die> to propagate you
 343 need to do something like:
 344
 345     $c->forward('foo');
 346     die $c->error if $c->error;
 347
 348 Or make sure to always return true values from your actions and write
 349 your code like this:
 350
 351     $c->forward('foo') || return;
 352
 353 Another note is that C<< $c->forward >> always returns a scalar because it
 354 actually returns $c->state which operates in a scalar context.
 355 Thus, something like:
 356
 357     return @array;
 358
 359 in an action that is forwarded to is going to return a scalar,
 360 i.e. how many items are in that array, which is probably not what you want.
 361 If you need to return an array then return a reference to it,
 362 or stash it like so:
 363
 364     $c->stash->{array} = \@array;
 365
 366 and access it from the stash.
 367
 368 =cut
 369
 370 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 371
 372 =head2 $c->detach( $action [, \@arguments ] )
 373
 374 =head2 $c->detach( $class, $method, [, \@arguments ] )
 375
 376 =head2 $c->detach()
 377
 378 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 379 doesn't return to the previous action when processing is finished.
 380
 381 When called with no arguments it escapes the processing chain entirely.
 382
 383 =cut
 384
 385 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 386
 387 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 388
 389 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 390
 391 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 392 but does a full dispatch, instead of just calling the new C<$action> /
 393 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 394 you go to are called, just like a new request.
 395
 396 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 397 This means, for example, that C<< $c->action >> methods such as
 398 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 399 L<reverse|Catalyst::Action/reverse> return information for the visited action
 400 when they are invoked within the visited action.  This is different from the
 401 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 402 continues to use the $c->action object from the caller action even when
 403 invoked from the callee.
 404
 405 C<< $c->stash >> is kept unchanged.
 406
 407 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 408 allows you to "wrap" another action, just as it would have been called by
 409 dispatching from a URL, while the analogous
 410 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 411 transfer control to another action as if it had been reached directly from a URL.
 412
 413 =cut
 414
 415 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 416
 417 =head2 $c->go( $action [, \@captures, \@arguments ] )
 418
 419 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 420
 421 The relationship between C<go> and
 422 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 423 the relationship between
 424 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 425 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 426 C<< $c->go >> will perform a full dispatch on the specified action or method,
 427 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 428 C<go> escapes the processing of the current request chain on completion, and
 429 does not return to its caller.
 430
 431 =cut
 432
 433 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 434
 435 =head2 $c->response
 436
 437 =head2 $c->res
 438
 439 Returns the current L<Catalyst::Response> object, see there for details.
 440
 441 =head2 $c->stash
 442
 443 Returns a hashref to the stash, which may be used to store data and pass
 444 it between components during a request. You can also set hash keys by
 445 passing arguments. The stash is automatically sent to the view. The
 446 stash is cleared at the end of a request; it cannot be used for
 447 persistent storage (for this you must use a session; see
 448 L<Catalyst::Plugin::Session> for a complete system integrated with
 449 Catalyst).
 450
 451     $c->stash->{foo} = $bar;
 452     $c->stash( { moose => 'majestic', qux => 0 } );
 453     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 454
 455     # stash is automatically passed to the view for use in a template
 456     $c->forward( 'MyApp::View::TT' );
 457
 458 =cut
 459
 460 around stash => sub {
 461     my $orig = shift;
 462     my $c = shift;
 463     my $stash = $orig->($c);
 464     if (@_) {
 465         my $new_stash = @_ > 1 ? {@_} : $_[0];
 466         croak('stash takes a hash or hashref') unless ref $new_stash;
 467         foreach my $key ( keys %$new_stash ) {
 468           $stash->{$key} = $new_stash->{$key};
 469         }
 470     }
 471
 472     return $stash;
 473 };
 474
 475
 476 =head2 $c->error
 477
 478 =head2 $c->error($error, ...)
 479
 480 =head2 $c->error($arrayref)
 481
 482 Returns an arrayref containing error messages.  If Catalyst encounters an
 483 error while processing a request, it stores the error in $c->error.  This
 484 method should only be used to store fatal error messages.
 485
 486     my @error = @{ $c->error };
 487
 488 Add a new error.
 489
 490     $c->error('Something bad happened');
 491
 492 =cut
 493
 494 sub error {
 495     my $c = shift;
 496     if ( $_[0] ) {
 497         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 498         croak @$error unless ref $c;
 499         push @{ $c->{error} }, @$error;
 500     }
 501     elsif ( defined $_[0] ) { $c->{error} = undef }
 502     return $c->{error} || [];
 503 }
 504
 505
 506 =head2 $c->state
 507
 508 Contains the return value of the last executed action.
 509 Note that << $c->state >> operates in a scalar context which means that all
 510 values it returns are scalar.
 511
 512 =head2 $c->clear_errors
 513
 514 Clear errors.  You probably don't want to clear the errors unless you are
 515 implementing a custom error screen.
 516
 517 This is equivalent to running
 518
 519     $c->error(0);
 520
 521 =cut
 522
 523 sub clear_errors {
 524     my $c = shift;
 525     $c->error(0);
 526 }
 527
 528 sub _comp_search_prefixes {
 529     my $c = shift;
 530     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 531 }
 532
 533 # search components given a name and some prefixes
 534 sub _comp_names_search_prefixes {
 535     my ( $c, $name, @prefixes ) = @_;
 536     my $appclass = ref $c || $c;
 537     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 538     $filter = qr/$filter/; # Compile regex now rather than once per loop
 539
 540     # map the original component name to the sub part that we will search against
 541     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 542         grep { /$filter/ } keys %{ $c->components };
 543
 544     # undef for a name will return all
 545     return keys %eligible if !defined $name;
 546
 547     my $query  = ref $name ? $name : qr/^$name$/i;
 548     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 549
 550     return @result if @result;
 551
 552     # if we were given a regexp to search against, we're done.
 553     return if ref $name;
 554
 555     # skip regexp fallback if configured
 556     return
 557         if $appclass->config->{disable_component_resolution_regex_fallback};
 558
 559     # regexp fallback
 560     $query  = qr/$name/i;
 561     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 562
 563     # no results? try against full names
 564     if( !@result ) {
 565         @result = grep { m{$query} } keys %eligible;
 566     }
 567
 568     # don't warn if we didn't find any results, it just might not exist
 569     if( @result ) {
 570         # Disgusting hack to work out correct method name
 571         my $warn_for = lc $prefixes[0];
 572         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 573            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 574            "component resolution is unreliable and unsafe.";
 575         my $short = $result[0];
 576         # remove the component namespace prefix
 577         $short =~ s/.*?(Model|Controller|View):://;
 578         my $shortmess = Carp::shortmess('');
 579         if ($shortmess =~ m#Catalyst/Plugin#) {
 580            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 581               "plugin's config";
 582         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 583            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 584               "component's config";
 585         } else {
 586            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 587               "but if you really wanted to search, pass in a regexp as the argument " .
 588               "like so: \$c->${warn_for}(qr/${name}/)";
 589         }
 590         $c->log->warn( "${msg}$shortmess" );
 591     }
 592
 593     return @result;
 594 }
 595
 596 # Find possible names for a prefix
 597 sub _comp_names {
 598     my ( $c, @prefixes ) = @_;
 599     my $appclass = ref $c || $c;
 600
 601     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 602
 603     my @names = map { s{$filter}{}; $_; }
 604         $c->_comp_names_search_prefixes( undef, @prefixes );
 605
 606     return @names;
 607 }
 608
 609 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 610 sub _filter_component {
 611     my ( $c, $comp, @args ) = @_;
 612
 613     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 614         return $comp->ACCEPT_CONTEXT( $c, @args );
 615     }
 616
 617     return $comp;
 618 }
 619
 620 =head2 COMPONENT ACCESSORS
 621
 622 =head2 $c->controller($name)
 623
 624 Gets a L<Catalyst::Controller> instance by name.
 625
 626     $c->controller('Foo')->do_stuff;
 627
 628 If the name is omitted, will return the controller for the dispatched
 629 action.
 630
 631 If you want to search for controllers, pass in a regexp as the argument.
 632
 633     # find all controllers that start with Foo
 634     my @foo_controllers = $c->controller(qr{^Foo});
 635
 636
 637 =cut
 638
 639 sub controller {
 640     my ( $c, $name, @args ) = @_;
 641
 642     if( $name ) {
 643         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 644         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 645         return $c->_filter_component( $result[ 0 ], @args );
 646     }
 647
 648     return $c->component( $c->action->class );
 649 }
 650
 651 =head2 $c->model($name)
 652
 653 Gets a L<Catalyst::Model> instance by name.
 654
 655     $c->model('Foo')->do_stuff;
 656
 657 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 658
 659 If the name is omitted, it will look for
 660  - a model object in $c->stash->{current_model_instance}, then
 661  - a model name in $c->stash->{current_model}, then
 662  - a config setting 'default_model', or
 663  - check if there is only one model, and return it if that's the case.
 664
 665 If you want to search for models, pass in a regexp as the argument.
 666
 667     # find all models that start with Foo
 668     my @foo_models = $c->model(qr{^Foo});
 669
 670 =cut
 671
 672 sub model {
 673     my ( $c, $name, @args ) = @_;
 674     my $appclass = ref($c) || $c;
 675     if( $name ) {
 676         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 677         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 678         return $c->_filter_component( $result[ 0 ], @args );
 679     }
 680
 681     if (ref $c) {
 682         return $c->stash->{current_model_instance}
 683           if $c->stash->{current_model_instance};
 684         return $c->model( $c->stash->{current_model} )
 685           if $c->stash->{current_model};
 686     }
 687     return $c->model( $appclass->config->{default_model} )
 688       if $appclass->config->{default_model};
 689
 690     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 691
 692     if( $rest ) {
 693         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 694         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 695         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 696         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 697         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 698     }
 699
 700     return $c->_filter_component( $comp );
 701 }
 702
 703
 704 =head2 $c->view($name)
 705
 706 Gets a L<Catalyst::View> instance by name.
 707
 708     $c->view('Foo')->do_stuff;
 709
 710 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 711
 712 If the name is omitted, it will look for
 713  - a view object in $c->stash->{current_view_instance}, then
 714  - a view name in $c->stash->{current_view}, then
 715  - a config setting 'default_view', or
 716  - check if there is only one view, and return it if that's the case.
 717
 718 If you want to search for views, pass in a regexp as the argument.
 719
 720     # find all views that start with Foo
 721     my @foo_views = $c->view(qr{^Foo});
 722
 723 =cut
 724
 725 sub view {
 726     my ( $c, $name, @args ) = @_;
 727
 728     my $appclass = ref($c) || $c;
 729     if( $name ) {
 730         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 731         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 732         return $c->_filter_component( $result[ 0 ], @args );
 733     }
 734
 735     if (ref $c) {
 736         return $c->stash->{current_view_instance}
 737           if $c->stash->{current_view_instance};
 738         return $c->view( $c->stash->{current_view} )
 739           if $c->stash->{current_view};
 740     }
 741     return $c->view( $appclass->config->{default_view} )
 742       if $appclass->config->{default_view};
 743
 744     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 745
 746     if( $rest ) {
 747         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 748         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 749         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 750         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 751         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 752     }
 753
 754     return $c->_filter_component( $comp );
 755 }
 756
 757 =head2 $c->controllers
 758
 759 Returns the available names which can be passed to $c->controller
 760
 761 =cut
 762
 763 sub controllers {
 764     my ( $c ) = @_;
 765     return $c->_comp_names(qw/Controller C/);
 766 }
 767
 768 =head2 $c->models
 769
 770 Returns the available names which can be passed to $c->model
 771
 772 =cut
 773
 774 sub models {
 775     my ( $c ) = @_;
 776     return $c->_comp_names(qw/Model M/);
 777 }
 778
 779
 780 =head2 $c->views
 781
 782 Returns the available names which can be passed to $c->view
 783
 784 =cut
 785
 786 sub views {
 787     my ( $c ) = @_;
 788     return $c->_comp_names(qw/View V/);
 789 }
 790
 791 =head2 $c->comp($name)
 792
 793 =head2 $c->component($name)
 794
 795 Gets a component object by name. This method is not recommended,
 796 unless you want to get a specific component by full
 797 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 798 should be used instead.
 799
 800 If C<$name> is a regexp, a list of components matched against the full
 801 component name will be returned.
 802
 803 If Catalyst can't find a component by name, it will fallback to regex
 804 matching by default. To disable this behaviour set
 805 disable_component_resolution_regex_fallback to a true value.
 806
 807     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 808
 809 =cut
 810
 811 sub component {
 812     my ( $c, $name, @args ) = @_;
 813
 814     if( $name ) {
 815         my $comps = $c->components;
 816
 817         if( !ref $name ) {
 818             # is it the exact name?
 819             return $c->_filter_component( $comps->{ $name }, @args )
 820                        if exists $comps->{ $name };
 821
 822             # perhaps we just omitted "MyApp"?
 823             my $composed = ( ref $c || $c ) . "::${name}";
 824             return $c->_filter_component( $comps->{ $composed }, @args )
 825                        if exists $comps->{ $composed };
 826
 827             # search all of the models, views and controllers
 828             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 829             return $c->_filter_component( $comp, @args ) if $comp;
 830         }
 831
 832         # This is here so $c->comp( '::M::' ) works
 833         my $query = ref $name ? $name : qr{$name}i;
 834
 835         my @result = grep { m{$query} } keys %{ $c->components };
 836         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 837
 838         if( $result[ 0 ] ) {
 839             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 840             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 841             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 842             return $c->_filter_component( $result[ 0 ], @args );
 843         }
 844
 845         # I would expect to return an empty list here, but that breaks back-compat
 846     }
 847
 848     # fallback
 849     return sort keys %{ $c->components };
 850 }
 851
 852 =head2 CLASS DATA AND HELPER CLASSES
 853
 854 =head2 $c->config
 855
 856 Returns or takes a hashref containing the application's configuration.
 857
 858     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 859
 860 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 861 like C<myapp.conf> in your applications home directory. See
 862 L<Catalyst::Plugin::ConfigLoader>.
 863
 864 =head3 Cascading configuration
 865
 866 The config method is present on all Catalyst components, and configuration
 867 will be merged when an application is started. Configuration loaded with
 868 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 869 followed by configuration in your top level C<MyApp> class. These two
 870 configurations are merged, and then configuration data whose hash key matches a
 871 component name is merged with configuration for that component.
 872
 873 The configuration for a component is then passed to the C<new> method when a
 874 component is constructed.
 875
 876 For example:
 877
 878     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 879     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 880
 881 will mean that C<MyApp::Model::Foo> receives the following data when
 882 constructed:
 883
 884     MyApp::Model::Foo->new({
 885         bar => 'baz',
 886         quux => 'frob',
 887         overrides => 'me',
 888     });
 889
 890 =cut
 891
 892 around config => sub {
 893     my $orig = shift;
 894     my $c = shift;
 895
 896     croak('Setting config after setup has been run is not allowed.')
 897         if ( @_ and $c->setup_finished );
 898
 899     $c->$orig(@_);
 900 };
 901
 902 =head2 $c->log
 903
 904 Returns the logging object instance. Unless it is already set, Catalyst
 905 sets this up with a L<Catalyst::Log> object. To use your own log class,
 906 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 907 C<< __PACKAGE__->setup >>.
 908
 909  __PACKAGE__->log( MyLogger->new );
 910  __PACKAGE__->setup;
 911
 912 And later:
 913
 914     $c->log->info( 'Now logging with my own logger!' );
 915
 916 Your log class should implement the methods described in
 917 L<Catalyst::Log>.
 918
 919
 920 =head2 $c->debug
 921
 922 Returns 1 if debug mode is enabled, 0 otherwise.
 923
 924 You can enable debug mode in several ways:
 925
 926 =over
 927
 928 =item By calling myapp_server.pl with the -d flag
 929
 930 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 931
 932 =item The -Debug option in your MyApp.pm
 933
 934 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 935
 936 =back
 937
 938 Calling C<< $c->debug(1) >> has no effect.
 939
 940 =cut
 941
 942 sub debug { 0 }
 943
 944 =head2 $c->dispatcher
 945
 946 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 947
 948 =head2 $c->engine
 949
 950 Returns the engine instance. See L<Catalyst::Engine>.
 951
 952
 953 =head2 UTILITY METHODS
 954
 955 =head2 $c->path_to(@path)
 956
 957 Merges C<@path> with C<< $c->config->{home} >> and returns a
 958 L<Path::Class::Dir> object. Note you can usually use this object as
 959 a filename, but sometimes you will have to explicitly stringify it
 960 yourself by calling the C<< ->stringify >> method.
 961
 962 For example:
 963
 964     $c->path_to( 'db', 'sqlite.db' );
 965
 966 =cut
 967
 968 sub path_to {
 969     my ( $c, @path ) = @_;
 970     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 971     if ( -d $path ) { return $path }
 972     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 973 }
 974
 975 =head2 $c->plugin( $name, $class, @args )
 976
 977 Helper method for plugins. It creates a class data accessor/mutator and
 978 loads and instantiates the given class.
 979
 980     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 981
 982     $c->prototype->define_javascript_functions;
 983
 984 B<Note:> This method of adding plugins is deprecated. The ability
 985 to add plugins like this B<will be removed> in a Catalyst 5.81.
 986 Please do not use this functionality in new code.
 987
 988 =cut
 989
 990 sub plugin {
 991     my ( $class, $name, $plugin, @args ) = @_;
 992
 993     # See block comment in t/unit_core_plugin.t
 994     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 995
 996     $class->_register_plugin( $plugin, 1 );
 997
 998     eval { $plugin->import };
 999     $class->mk_classdata($name);
1000     my $obj;
1001     eval { $obj = $plugin->new(@args) };
1002
1003     if ($@) {
1004         Catalyst::Exception->throw( message =>
1005               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1006     }
1007
1008     $class->$name($obj);
1009     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1010       if $class->debug;
1011 }
1012
1013 =head2 MyApp->setup
1014
1015 Initializes the dispatcher and engine, loads any plugins, and loads the
1016 model, view, and controller components. You may also specify an array
1017 of plugins to load here, if you choose to not load them in the C<use
1018 Catalyst> line.
1019
1020     MyApp->setup;
1021     MyApp->setup( qw/-Debug/ );
1022
1023 =cut
1024
1025 sub setup {
1026     my ( $class, @arguments ) = @_;
1027     croak('Running setup more than once')
1028         if ( $class->setup_finished );
1029
1030     unless ( $class->isa('Catalyst') ) {
1031
1032         Catalyst::Exception->throw(
1033             message => qq/'$class' does not inherit from Catalyst/ );
1034     }
1035
1036     if ( $class->arguments ) {
1037         @arguments = ( @arguments, @{ $class->arguments } );
1038     }
1039
1040     # Process options
1041     my $flags = {};
1042
1043     foreach (@arguments) {
1044
1045         if (/^-Debug$/) {
1046             $flags->{log} =
1047               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1048         }
1049         elsif (/^-(\w+)=?(.*)$/) {
1050             $flags->{ lc $1 } = $2;
1051         }
1052         else {
1053             push @{ $flags->{plugins} }, $_;
1054         }
1055     }
1056
1057     $class->setup_home( delete $flags->{home} );
1058
1059     $class->setup_log( delete $flags->{log} );
1060     $class->setup_plugins( delete $flags->{plugins} );
1061     $class->setup_dispatcher( delete $flags->{dispatcher} );
1062     $class->setup_engine( delete $flags->{engine} );
1063     $class->setup_stats( delete $flags->{stats} );
1064
1065     for my $flag ( sort keys %{$flags} ) {
1066
1067         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1068             &$code( $class, delete $flags->{$flag} );
1069         }
1070         else {
1071             $class->log->warn(qq/Unknown flag "$flag"/);
1072         }
1073     }
1074
1075     eval { require Catalyst::Devel; };
1076     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1077         $class->log->warn(<<"EOF");
1078 You are running an old script!
1079
1080   Please update by running (this will overwrite existing files):
1081     catalyst.pl -force -scripts $class
1082
1083   or (this will not overwrite existing files):
1084     catalyst.pl -scripts $class
1085
1086 EOF
1087     }
1088
1089     if ( $class->debug ) {
1090         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1091
1092         if (@plugins) {
1093             my $column_width = Catalyst::Utils::term_width() - 6;
1094             my $t = Text::SimpleTable->new($column_width);
1095             $t->row($_) for @plugins;
1096             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1097         }
1098
1099         my $dispatcher = $class->dispatcher;
1100         my $engine     = $class->engine;
1101         my $home       = $class->config->{home};
1102
1103         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1104         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1105
1106         $home
1107           ? ( -d $home )
1108           ? $class->log->debug(qq/Found home "$home"/)
1109           : $class->log->debug(qq/Home "$home" doesn't exist/)
1110           : $class->log->debug(q/Couldn't find home/);
1111     }
1112
1113     # Call plugins setup, this is stupid and evil.
1114     # Also screws C3 badly on 5.10, hack to avoid.
1115     {
1116         no warnings qw/redefine/;
1117         local *setup = sub { };
1118         $class->setup unless $Catalyst::__AM_RESTARTING;
1119     }
1120
1121     # Initialize our data structure
1122     $class->components( {} );
1123
1124     $class->setup_components;
1125
1126     if ( $class->debug ) {
1127         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1128         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1129         for my $comp ( sort keys %{ $class->components } ) {
1130             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1131             $t->row( $comp, $type );
1132         }
1133         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1134           if ( keys %{ $class->components } );
1135     }
1136
1137     # Add our self to components, since we are also a component
1138     if( $class->isa('Catalyst::Controller') ){
1139       $class->components->{$class} = $class;
1140     }
1141
1142     $class->setup_actions;
1143
1144     if ( $class->debug ) {
1145         my $name = $class->config->{name} || 'Application';
1146         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1147     }
1148
1149     # Make sure that the application class becomes immutable at this point,
1150     B::Hooks::EndOfScope::on_scope_end {
1151         return if $@;
1152         my $meta = Class::MOP::get_metaclass_by_name($class);
1153         if (
1154             $meta->is_immutable
1155             && ! { $meta->immutable_options }->{replace_constructor}
1156             && (
1157                    $class->isa('Class::Accessor::Fast')
1158                 || $class->isa('Class::Accessor')
1159             )
1160         ) {
1161             warn "You made your application class ($class) immutable, "
1162                 . "but did not inline the\nconstructor. "
1163                 . "This will break catalyst, as your app \@ISA "
1164                 . "Class::Accessor(::Fast)?\nPlease pass "
1165                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1166         }
1167         $meta->make_immutable(
1168             replace_constructor => 1,
1169         ) unless $meta->is_immutable;
1170     };
1171
1172     $class->setup_finalize;
1173     # Should be the last thing we do so that user things hooking
1174     # setup_finalize can log..
1175     $class->log->_flush() if $class->log->can('_flush');
1176     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1177 }
1178
1179
1180 =head2 $app->setup_finalize
1181
1182 A hook to attach modifiers to.
1183 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1184 Also better than C< setup_finished(); >, as that is a getter method.
1185
1186     sub setup_finalize {
1187
1188         my $app = shift;
1189
1190         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1191
1192         $app->next::method(@_);
1193
1194
1195     }
1196
1197 =cut
1198
1199 sub setup_finalize {
1200     my ($class) = @_;
1201     $class->setup_finished(1);
1202 }
1203
1204 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1205
1206 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1207
1208 Constructs an absolute L<URI> object based on the application root, the
1209 provided path, and the additional arguments and query parameters provided.
1210 When used as a string, provides a textual URI.
1211
1212 If no arguments are provided, the URI for the current action is returned.
1213 To return the current action and also provide @args, use
1214 C<< $c->uri_for( $c->action, @args ) >>.
1215
1216 If the first argument is a string, it is taken as a public URI path relative
1217 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1218 relative to the application root (if it does). It is then merged with
1219 C<< $c->request->base >>; any C<@args> are appended as additional path
1220 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1221
1222 If the first argument is a L<Catalyst::Action> it represents an action which
1223 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1224 optional C<\@captures> argument (an arrayref) allows passing the captured
1225 variables that are needed to fill in the paths of Chained and Regex actions;
1226 once the path is resolved, C<uri_for> continues as though a path was
1227 provided, appending any arguments or parameters and creating an absolute
1228 URI.
1229
1230 The captures for the current request can be found in
1231 C<< $c->request->captures >>, and actions can be resolved using
1232 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1233 path, use C<< $c->uri_for_action >> instead.
1234
1235   # Equivalent to $c->req->uri
1236   $c->uri_for($c->action, $c->req->captures,
1237       @{ $c->req->args }, $c->req->params);
1238
1239   # For the Foo action in the Bar controller
1240   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1241
1242   # Path to a static resource
1243   $c->uri_for('/static/images/logo.png');
1244
1245 =cut
1246
1247 sub uri_for {
1248     my ( $c, $path, @args ) = @_;
1249
1250     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1251         $path = $path->path_prefix;
1252         $path =~ s{/+\z}{};
1253         $path .= '/';
1254     }
1255
1256     if ( blessed($path) ) { # action object
1257         my $captures = [ map { s|/|%2F|; $_; }
1258                         ( scalar @args && ref $args[0] eq 'ARRAY'
1259                          ? @{ shift(@args) }
1260                          : ()) ];
1261         my $action = $path;
1262         $path = $c->dispatcher->uri_for_action($action, $captures);
1263         if (not defined $path) {
1264             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1265                 if $c->debug;
1266             return undef;
1267         }
1268         $path = '/' if $path eq '';
1269     }
1270
1271     undef($path) if (defined $path && $path eq '');
1272
1273     my $params =
1274       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1275
1276     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1277     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1278     s|/|%2F| for @args;
1279
1280     unshift(@args, $path);
1281
1282     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1283         my $namespace = $c->namespace;
1284         if (defined $path) { # cheesy hack to handle path '../foo'
1285            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1286         }
1287         unshift(@args, $namespace || '');
1288     }
1289
1290     # join args with '/', or a blank string
1291     my $args = join('/', grep { defined($_) } @args);
1292     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1293     $args =~ s!^/+!!;
1294     my $base = $c->req->base;
1295     my $class = ref($base);
1296     $base =~ s{(?<!/)$}{/};
1297
1298     my $query = '';
1299
1300     if (my @keys = keys %$params) {
1301       # somewhat lifted from URI::_query's query_form
1302       $query = '?'.join('&', map {
1303           my $val = $params->{$_};
1304           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1305           s/ /+/g;
1306           my $key = $_;
1307           $val = '' unless defined $val;
1308           (map {
1309               my $param = "$_";
1310               utf8::encode( $param ) if utf8::is_utf8($param);
1311               # using the URI::Escape pattern here so utf8 chars survive
1312               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1313               $param =~ s/ /+/g;
1314               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1315       } @keys);
1316     }
1317
1318     my $res = bless(\"${base}${args}${query}", $class);
1319     $res;
1320 }
1321
1322 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1323
1324 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1325
1326 =over
1327
1328 =item $path
1329
1330 A private path to the Catalyst action you want to create a URI for.
1331
1332 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1333 >> and passing the resulting C<$action> and the remaining arguments to C<<
1334 $c->uri_for >>.
1335
1336 You can also pass in a Catalyst::Action object, in which case it is passed to
1337 C<< $c->uri_for >>.
1338
1339 =back
1340
1341 =cut
1342
1343 sub uri_for_action {
1344     my ( $c, $path, @args ) = @_;
1345     my $action = blessed($path)
1346       ? $path
1347       : $c->dispatcher->get_action_by_path($path);
1348     unless (defined $action) {
1349       croak "Can't find action for path '$path'";
1350     }
1351     return $c->uri_for( $action, @args );
1352 }
1353
1354 =head2 $c->welcome_message
1355
1356 Returns the Catalyst welcome HTML page.
1357
1358 =cut
1359
1360 sub welcome_message {
1361     my $c      = shift;
1362     my $name   = $c->config->{name};
1363     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1364     my $prefix = Catalyst::Utils::appprefix( ref $c );
1365     $c->response->content_type('text/html; charset=utf-8');
1366     return <<"EOF";
1367 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1368     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1369 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1370     <head>
1371     <meta http-equiv="Content-Language" content="en" />
1372     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1373         <title>$name on Catalyst $VERSION</title>
1374         <style type="text/css">
1375             body {
1376                 color: #000;
1377                 background-color: #eee;
1378             }
1379             div#content {
1380                 width: 640px;
1381                 margin-left: auto;
1382                 margin-right: auto;
1383                 margin-top: 10px;
1384                 margin-bottom: 10px;
1385                 text-align: left;
1386                 background-color: #ccc;
1387                 border: 1px solid #aaa;
1388             }
1389             p, h1, h2 {
1390                 margin-left: 20px;
1391                 margin-right: 20px;
1392                 font-family: verdana, tahoma, sans-serif;
1393             }
1394             a {
1395                 font-family: verdana, tahoma, sans-serif;
1396             }
1397             :link, :visited {
1398                     text-decoration: none;
1399                     color: #b00;
1400                     border-bottom: 1px dotted #bbb;
1401             }
1402             :link:hover, :visited:hover {
1403                     color: #555;
1404             }
1405             div#topbar {
1406                 margin: 0px;
1407             }
1408             pre {
1409                 margin: 10px;
1410                 padding: 8px;
1411             }
1412             div#answers {
1413                 padding: 8px;
1414                 margin: 10px;
1415                 background-color: #fff;
1416                 border: 1px solid #aaa;
1417             }
1418             h1 {
1419                 font-size: 0.9em;
1420                 font-weight: normal;
1421                 text-align: center;
1422             }
1423             h2 {
1424                 font-size: 1.0em;
1425             }
1426             p {
1427                 font-size: 0.9em;
1428             }
1429             p img {
1430                 float: right;
1431                 margin-left: 10px;
1432             }
1433             span#appname {
1434                 font-weight: bold;
1435                 font-size: 1.6em;
1436             }
1437         </style>
1438     </head>
1439     <body>
1440         <div id="content">
1441             <div id="topbar">
1442                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1443                     $VERSION</h1>
1444              </div>
1445              <div id="answers">
1446                  <p>
1447                  <img src="$logo" alt="Catalyst Logo" />
1448                  </p>
1449                  <p>Welcome to the  world of Catalyst.
1450                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1451                     framework will make web development something you had
1452                     never expected it to be: Fun, rewarding, and quick.</p>
1453                  <h2>What to do now?</h2>
1454                  <p>That really depends  on what <b>you</b> want to do.
1455                     We do, however, provide you with a few starting points.</p>
1456                  <p>If you want to jump right into web development with Catalyst
1457                     you might want to start with a tutorial.</p>
1458 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1459 </pre>
1460 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1461 <pre>
1462 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1463 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1464 </code></pre>
1465                  <h2>What to do next?</h2>
1466                  <p>Next it's time to write an actual application. Use the
1467                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1468                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1469                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1470                     they can save you a lot of work.</p>
1471                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1472                     <p>Also, be sure to check out the vast and growing
1473                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1474                     you are likely to find what you need there.
1475                     </p>
1476
1477                  <h2>Need help?</h2>
1478                  <p>Catalyst has a very active community. Here are the main places to
1479                     get in touch with us.</p>
1480                  <ul>
1481                      <li>
1482                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1483                      </li>
1484                      <li>
1485                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1486                      </li>
1487                      <li>
1488                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1489                      </li>
1490                  </ul>
1491                  <h2>In conclusion</h2>
1492                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1493                     as we enjoyed making it. Please contact us if you have ideas
1494                     for improvement or other feedback.</p>
1495              </div>
1496          </div>
1497     </body>
1498 </html>
1499 EOF
1500 }
1501
1502 =head1 INTERNAL METHODS
1503
1504 These methods are not meant to be used by end users.
1505
1506 =head2 $c->components
1507
1508 Returns a hash of components.
1509
1510 =head2 $c->context_class
1511
1512 Returns or sets the context class.
1513
1514 =head2 $c->counter
1515
1516 Returns a hashref containing coderefs and execution counts (needed for
1517 deep recursion detection).
1518
1519 =head2 $c->depth
1520
1521 Returns the number of actions on the current internal execution stack.
1522
1523 =head2 $c->dispatch
1524
1525 Dispatches a request to actions.
1526
1527 =cut
1528
1529 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1530
1531 =head2 $c->dispatcher_class
1532
1533 Returns or sets the dispatcher class.
1534
1535 =head2 $c->dump_these
1536
1537 Returns a list of 2-element array references (name, structure) pairs
1538 that will be dumped on the error page in debug mode.
1539
1540 =cut
1541
1542 sub dump_these {
1543     my $c = shift;
1544     [ Request => $c->req ],
1545     [ Response => $c->res ],
1546     [ Stash => $c->stash ],
1547     [ Config => $c->config ];
1548 }
1549
1550 =head2 $c->engine_class
1551
1552 Returns or sets the engine class.
1553
1554 =head2 $c->execute( $class, $coderef )
1555
1556 Execute a coderef in given class and catch exceptions. Errors are available
1557 via $c->error.
1558
1559 =cut
1560
1561 sub execute {
1562     my ( $c, $class, $code ) = @_;
1563     $class = $c->component($class) || $class;
1564     $c->state(0);
1565
1566     if ( $c->depth >= $RECURSION ) {
1567         my $action = $code->reverse();
1568         $action = "/$action" unless $action =~ /->/;
1569         my $error = qq/Deep recursion detected calling "${action}"/;
1570         $c->log->error($error);
1571         $c->error($error);
1572         $c->state(0);
1573         return $c->state;
1574     }
1575
1576     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1577
1578     push( @{ $c->stack }, $code );
1579
1580     no warnings 'recursion';
1581     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1582
1583     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1584
1585     my $last = pop( @{ $c->stack } );
1586
1587     if ( my $error = $@ ) {
1588         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1589             $error->rethrow if $c->depth > 1;
1590         }
1591         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1592             $error->rethrow if $c->depth > 0;
1593         }
1594         else {
1595             unless ( ref $error ) {
1596                 no warnings 'uninitialized';
1597                 chomp $error;
1598                 my $class = $last->class;
1599                 my $name  = $last->name;
1600                 $error = qq/Caught exception in $class->$name "$error"/;
1601             }
1602             $c->error($error);
1603             $c->state(0);
1604         }
1605     }
1606     return $c->state;
1607 }
1608
1609 sub _stats_start_execute {
1610     my ( $c, $code ) = @_;
1611     my $appclass = ref($c) || $c;
1612     return if ( ( $code->name =~ /^_.*/ )
1613         && ( !$appclass->config->{show_internal_actions} ) );
1614
1615     my $action_name = $code->reverse();
1616     $c->counter->{$action_name}++;
1617
1618     my $action = $action_name;
1619     $action = "/$action" unless $action =~ /->/;
1620
1621     # determine if the call was the result of a forward
1622     # this is done by walking up the call stack and looking for a calling
1623     # sub of Catalyst::forward before the eval
1624     my $callsub = q{};
1625     for my $index ( 2 .. 11 ) {
1626         last
1627         if ( ( caller($index) )[0] eq 'Catalyst'
1628             && ( caller($index) )[3] eq '(eval)' );
1629
1630         if ( ( caller($index) )[3] =~ /forward$/ ) {
1631             $callsub = ( caller($index) )[3];
1632             $action  = "-> $action";
1633             last;
1634         }
1635     }
1636
1637     my $uid = $action_name . $c->counter->{$action_name};
1638
1639     # is this a root-level call or a forwarded call?
1640     if ( $callsub =~ /forward$/ ) {
1641         my $parent = $c->stack->[-1];
1642
1643         # forward, locate the caller
1644         if ( exists $c->counter->{"$parent"} ) {
1645             $c->stats->profile(
1646                 begin  => $action,
1647                 parent => "$parent" . $c->counter->{"$parent"},
1648                 uid    => $uid,
1649             );
1650         }
1651         else {
1652
1653             # forward with no caller may come from a plugin
1654             $c->stats->profile(
1655                 begin => $action,
1656                 uid   => $uid,
1657             );
1658         }
1659     }
1660     else {
1661
1662         # root-level call
1663         $c->stats->profile(
1664             begin => $action,
1665             uid   => $uid,
1666         );
1667     }
1668     return $action;
1669
1670 }
1671
1672 sub _stats_finish_execute {
1673     my ( $c, $info ) = @_;
1674     $c->stats->profile( end => $info );
1675 }
1676
1677 =head2 $c->finalize
1678
1679 Finalizes the request.
1680
1681 =cut
1682
1683 sub finalize {
1684     my $c = shift;
1685
1686     for my $error ( @{ $c->error } ) {
1687         $c->log->error($error);
1688     }
1689
1690     # Allow engine to handle finalize flow (for POE)
1691     my $engine = $c->engine;
1692     if ( my $code = $engine->can('finalize') ) {
1693         $engine->$code($c);
1694     }
1695     else {
1696
1697         $c->finalize_uploads;
1698
1699         # Error
1700         if ( $#{ $c->error } >= 0 ) {
1701             $c->finalize_error;
1702         }
1703
1704         $c->finalize_headers;
1705
1706         # HEAD request
1707         if ( $c->request->method eq 'HEAD' ) {
1708             $c->response->body('');
1709         }
1710
1711         $c->finalize_body;
1712     }
1713
1714     if ($c->use_stats) {
1715         my $elapsed = sprintf '%f', $c->stats->elapsed;
1716         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1717         $c->log->info(
1718             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1719     }
1720
1721     return $c->response->status;
1722 }
1723
1724 =head2 $c->finalize_body
1725
1726 Finalizes body.
1727
1728 =cut
1729
1730 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1731
1732 =head2 $c->finalize_cookies
1733
1734 Finalizes cookies.
1735
1736 =cut
1737
1738 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1739
1740 =head2 $c->finalize_error
1741
1742 Finalizes error.
1743
1744 =cut
1745
1746 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1747
1748 =head2 $c->finalize_headers
1749
1750 Finalizes headers.
1751
1752 =cut
1753
1754 sub finalize_headers {
1755     my $c = shift;
1756
1757     my $response = $c->response; #accessor calls can add up?
1758
1759     # Check if we already finalized headers
1760     return if $response->finalized_headers;
1761
1762     # Handle redirects
1763     if ( my $location = $response->redirect ) {
1764         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1765         $response->header( Location => $location );
1766
1767         if ( !$response->has_body ) {
1768             # Add a default body if none is already present
1769             $response->body(
1770                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1771             );
1772         }
1773     }
1774
1775     # Content-Length
1776     if ( $response->body && !$response->content_length ) {
1777
1778         # get the length from a filehandle
1779         if ( blessed( $response->body ) && $response->body->can('read') )
1780         {
1781             my $stat = stat $response->body;
1782             if ( $stat && $stat->size > 0 ) {
1783                 $response->content_length( $stat->size );
1784             }
1785             else {
1786                 $c->log->warn('Serving filehandle without a content-length');
1787             }
1788         }
1789         else {
1790             # everything should be bytes at this point, but just in case
1791             $response->content_length( bytes::length( $response->body ) );
1792         }
1793     }
1794
1795     # Errors
1796     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1797         $response->headers->remove_header("Content-Length");
1798         $response->body('');
1799     }
1800
1801     $c->finalize_cookies;
1802
1803     $c->engine->finalize_headers( $c, @_ );
1804
1805     # Done
1806     $response->finalized_headers(1);
1807 }
1808
1809 =head2 $c->finalize_output
1810
1811 An alias for finalize_body.
1812
1813 =head2 $c->finalize_read
1814
1815 Finalizes the input after reading is complete.
1816
1817 =cut
1818
1819 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1820
1821 =head2 $c->finalize_uploads
1822
1823 Finalizes uploads. Cleans up any temporary files.
1824
1825 =cut
1826
1827 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1828
1829 =head2 $c->get_action( $action, $namespace )
1830
1831 Gets an action in a given namespace.
1832
1833 =cut
1834
1835 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1836
1837 =head2 $c->get_actions( $action, $namespace )
1838
1839 Gets all actions of a given name in a namespace and all parent
1840 namespaces.
1841
1842 =cut
1843
1844 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1845
1846 =head2 $c->handle_request( $class, @arguments )
1847
1848 Called to handle each HTTP request.
1849
1850 =cut
1851
1852 sub handle_request {
1853     my ( $class, @arguments ) = @_;
1854
1855     # Always expect worst case!
1856     my $status = -1;
1857     eval {
1858         if ($class->debug) {
1859             my $secs = time - $START || 1;
1860             my $av = sprintf '%.3f', $COUNT / $secs;
1861             my $time = localtime time;
1862             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1863         }
1864
1865         my $c = $class->prepare(@arguments);
1866         $c->dispatch;
1867         $status = $c->finalize;
1868     };
1869
1870     if ( my $error = $@ ) {
1871         chomp $error;
1872         $class->log->error(qq/Caught exception in engine "$error"/);
1873     }
1874
1875     $COUNT++;
1876
1877     if(my $coderef = $class->log->can('_flush')){
1878         $class->log->$coderef();
1879     }
1880     return $status;
1881 }
1882
1883 =head2 $c->prepare( @arguments )
1884
1885 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1886 etc.).
1887
1888 =cut
1889
1890 sub prepare {
1891     my ( $class, @arguments ) = @_;
1892
1893     # XXX
1894     # After the app/ctxt split, this should become an attribute based on something passed
1895     # into the application.
1896     $class->context_class( ref $class || $class ) unless $class->context_class;
1897
1898     my $c = $class->context_class->new({});
1899
1900     # For on-demand data
1901     $c->request->_context($c);
1902     $c->response->_context($c);
1903
1904     #surely this is not the most efficient way to do things...
1905     $c->stats($class->stats_class->new)->enable($c->use_stats);
1906     if ( $c->debug ) {
1907         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1908     }
1909
1910     #XXX reuse coderef from can
1911     # Allow engine to direct the prepare flow (for POE)
1912     if ( $c->engine->can('prepare') ) {
1913         $c->engine->prepare( $c, @arguments );
1914     }
1915     else {
1916         $c->prepare_request(@arguments);
1917         $c->prepare_connection;
1918         $c->prepare_query_parameters;
1919         $c->prepare_headers;
1920         $c->prepare_cookies;
1921         $c->prepare_path;
1922
1923         # Prepare the body for reading, either by prepare_body
1924         # or the user, if they are using $c->read
1925         $c->prepare_read;
1926
1927         # Parse the body unless the user wants it on-demand
1928         unless ( ref($c)->config->{parse_on_demand} ) {
1929             $c->prepare_body;
1930         }
1931     }
1932
1933     my $method  = $c->req->method  || '';
1934     my $path    = $c->req->path;
1935     $path       = '/' unless length $path;
1936     my $address = $c->req->address || '';
1937
1938     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1939       if $c->debug;
1940
1941     $c->prepare_action;
1942
1943     return $c;
1944 }
1945
1946 =head2 $c->prepare_action
1947
1948 Prepares action. See L<Catalyst::Dispatcher>.
1949
1950 =cut
1951
1952 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1953
1954 =head2 $c->prepare_body
1955
1956 Prepares message body.
1957
1958 =cut
1959
1960 sub prepare_body {
1961     my $c = shift;
1962
1963     return if $c->request->_has_body;
1964
1965     # Initialize on-demand data
1966     $c->engine->prepare_body( $c, @_ );
1967     $c->prepare_parameters;
1968     $c->prepare_uploads;
1969
1970     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1971         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1972         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1973             my $param = $c->req->body_parameters->{$key};
1974             my $value = defined($param) ? $param : '';
1975             $t->row( $key,
1976                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1977         }
1978         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1979     }
1980 }
1981
1982 =head2 $c->prepare_body_chunk( $chunk )
1983
1984 Prepares a chunk of data before sending it to L<HTTP::Body>.
1985
1986 See L<Catalyst::Engine>.
1987
1988 =cut
1989
1990 sub prepare_body_chunk {
1991     my $c = shift;
1992     $c->engine->prepare_body_chunk( $c, @_ );
1993 }
1994
1995 =head2 $c->prepare_body_parameters
1996
1997 Prepares body parameters.
1998
1999 =cut
2000
2001 sub prepare_body_parameters {
2002     my $c = shift;
2003     $c->engine->prepare_body_parameters( $c, @_ );
2004 }
2005
2006 =head2 $c->prepare_connection
2007
2008 Prepares connection.
2009
2010 =cut
2011
2012 sub prepare_connection {
2013     my $c = shift;
2014     $c->engine->prepare_connection( $c, @_ );
2015 }
2016
2017 =head2 $c->prepare_cookies
2018
2019 Prepares cookies.
2020
2021 =cut
2022
2023 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2024
2025 =head2 $c->prepare_headers
2026
2027 Prepares headers.
2028
2029 =cut
2030
2031 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2032
2033 =head2 $c->prepare_parameters
2034
2035 Prepares parameters.
2036
2037 =cut
2038
2039 sub prepare_parameters {
2040     my $c = shift;
2041     $c->prepare_body_parameters;
2042     $c->engine->prepare_parameters( $c, @_ );
2043 }
2044
2045 =head2 $c->prepare_path
2046
2047 Prepares path and base.
2048
2049 =cut
2050
2051 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2052
2053 =head2 $c->prepare_query_parameters
2054
2055 Prepares query parameters.
2056
2057 =cut
2058
2059 sub prepare_query_parameters {
2060     my $c = shift;
2061
2062     $c->engine->prepare_query_parameters( $c, @_ );
2063
2064     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
2065         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
2066         for my $key ( sort keys %{ $c->req->query_parameters } ) {
2067             my $param = $c->req->query_parameters->{$key};
2068             my $value = defined($param) ? $param : '';
2069             $t->row( $key,
2070                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2071         }
2072         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2073     }
2074 }
2075
2076 =head2 $c->prepare_read
2077
2078 Prepares the input for reading.
2079
2080 =cut
2081
2082 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2083
2084 =head2 $c->prepare_request
2085
2086 Prepares the engine request.
2087
2088 =cut
2089
2090 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2091
2092 =head2 $c->prepare_uploads
2093
2094 Prepares uploads.
2095
2096 =cut
2097
2098 sub prepare_uploads {
2099     my $c = shift;
2100
2101     $c->engine->prepare_uploads( $c, @_ );
2102
2103     if ( $c->debug && keys %{ $c->request->uploads } ) {
2104         my $t = Text::SimpleTable->new(
2105             [ 12, 'Parameter' ],
2106             [ 26, 'Filename' ],
2107             [ 18, 'Type' ],
2108             [ 9,  'Size' ]
2109         );
2110         for my $key ( sort keys %{ $c->request->uploads } ) {
2111             my $upload = $c->request->uploads->{$key};
2112             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2113                 $t->row( $key, $u->filename, $u->type, $u->size );
2114             }
2115         }
2116         $c->log->debug( "File Uploads are:\n" . $t->draw );
2117     }
2118 }
2119
2120 =head2 $c->prepare_write
2121
2122 Prepares the output for writing.
2123
2124 =cut
2125
2126 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2127
2128 =head2 $c->request_class
2129
2130 Returns or sets the request class.
2131
2132 =head2 $c->response_class
2133
2134 Returns or sets the response class.
2135
2136 =head2 $c->read( [$maxlength] )
2137
2138 Reads a chunk of data from the request body. This method is designed to
2139 be used in a while loop, reading C<$maxlength> bytes on every call.
2140 C<$maxlength> defaults to the size of the request if not specified.
2141
2142 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2143 directly.
2144
2145 Warning: If you use read(), Catalyst will not process the body,
2146 so you will not be able to access POST parameters or file uploads via
2147 $c->request.  You must handle all body parsing yourself.
2148
2149 =cut
2150
2151 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2152
2153 =head2 $c->run
2154
2155 Starts the engine.
2156
2157 =cut
2158
2159 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2160
2161 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2162
2163 Sets an action in a given namespace.
2164
2165 =cut
2166
2167 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2168
2169 =head2 $c->setup_actions($component)
2170
2171 Sets up actions for a component.
2172
2173 =cut
2174
2175 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2176
2177 =head2 $c->setup_components
2178
2179 This method is called internally to set up the application's components.
2180
2181 It finds modules by calling the L<locate_components> method, expands them to
2182 package names with the L<expand_component_module> method, and then installs
2183 each component into the application.
2184
2185 The C<setup_components> config option is passed to both of the above methods.
2186
2187 Installation of each component is performed by the L<setup_component> method,
2188 below.
2189
2190 =cut
2191
2192 sub setup_components {
2193     my $class = shift;
2194
2195     my $config  = $class->config->{ setup_components };
2196
2197     my @comps = sort { length $a <=> length $b }
2198                 $class->locate_components($config);
2199     my %comps = map { $_ => 1 } @comps;
2200
2201     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2202     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2203         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2204     ) if $deprecatedcatalyst_component_names;
2205
2206     for my $component ( @comps ) {
2207
2208         # We pass ignore_loaded here so that overlay files for (e.g.)
2209         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2210         # we know M::P::O found a file on disk so this is safe
2211
2212         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2213
2214         # Needs to be done as soon as the component is loaded, as loading a sub-component
2215         # (next time round the loop) can cause us to get the wrong metaclass..
2216         $class->_controller_init_base_classes($component);
2217     }
2218
2219     for my $component (@comps) {
2220         $class->components->{ $component } = $class->setup_component($component);
2221         for my $component ($class->expand_component_module( $component, $config )) {
2222             next if $comps{$component};
2223             $class->_controller_init_base_classes($component); # Also cover inner packages
2224             $class->components->{ $component } = $class->setup_component($component);
2225         }
2226     }
2227 }
2228
2229 =head2 $c->locate_components( $setup_component_config )
2230
2231 This method is meant to provide a list of component modules that should be
2232 setup for the application.  By default, it will use L<Module::Pluggable>.
2233
2234 Specify a C<setup_components> config option to pass additional options directly
2235 to L<Module::Pluggable>. To add additional search paths, specify a key named
2236 C<search_extra> as an array reference. Items in the array beginning with C<::>
2237 will have the application class name prepended to them.
2238
2239 =cut
2240
2241 sub locate_components {
2242     my $class  = shift;
2243     my $config = shift;
2244
2245     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2246     my $extra   = delete $config->{ search_extra } || [];
2247
2248     push @paths, @$extra;
2249
2250     my $locator = Module::Pluggable::Object->new(
2251         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2252         %$config
2253     );
2254
2255     my @comps = $locator->plugins;
2256
2257     return @comps;
2258 }
2259
2260 =head2 $c->expand_component_module( $component, $setup_component_config )
2261
2262 Components found by C<locate_components> will be passed to this method, which
2263 is expected to return a list of component (package) names to be set up.
2264
2265 =cut
2266
2267 sub expand_component_module {
2268     my ($class, $module) = @_;
2269     return Devel::InnerPackage::list_packages( $module );
2270 }
2271
2272 =head2 $c->setup_component
2273
2274 =cut
2275
2276 # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2277 #         nearest to Catalyst::Controller first, no matter what order stuff happens
2278 #         to be loaded. There are TODO tests in Moose for this, see
2279 #         f2391d17574eff81d911b97be15ea51080500003
2280 sub _controller_init_base_classes {
2281     my ($app_class, $component) = @_;
2282     return unless $component->isa('Catalyst::Controller');
2283     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2284         Moose::Meta::Class->initialize( $class )
2285             unless find_meta($class);
2286     }
2287 }
2288
2289 sub setup_component {
2290     my( $class, $component ) = @_;
2291
2292     unless ( $component->can( 'COMPONENT' ) ) {
2293         return $component;
2294     }
2295
2296     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2297     my $config = $class->config->{ $suffix } || {};
2298     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2299     # methods also pass it. local to avoid pointlessly shitting in config
2300     # for the debug screen, as $component is already the key name.
2301     local $config->{catalyst_component_name} = $component;
2302
2303     my $instance = eval { $component->COMPONENT( $class, $config ); };
2304
2305     if ( my $error = $@ ) {
2306         chomp $error;
2307         Catalyst::Exception->throw(
2308             message => qq/Couldn't instantiate component "$component", "$error"/
2309         );
2310     }
2311
2312     unless (blessed $instance) {
2313         my $metaclass = Moose::Util::find_meta($component);
2314         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2315         my $component_method_from = $method_meta->associated_metaclass->name;
2316         my $value = defined($instance) ? $instance : 'undef';
2317         Catalyst::Exception->throw(
2318             message =>
2319             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2320         );
2321     }
2322     return $instance;
2323 }
2324
2325 =head2 $c->setup_dispatcher
2326
2327 Sets up dispatcher.
2328
2329 =cut
2330
2331 sub setup_dispatcher {
2332     my ( $class, $dispatcher ) = @_;
2333
2334     if ($dispatcher) {
2335         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2336     }
2337
2338     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2339         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2340     }
2341
2342     unless ($dispatcher) {
2343         $dispatcher = $class->dispatcher_class;
2344     }
2345
2346     Class::MOP::load_class($dispatcher);
2347
2348     # dispatcher instance
2349     $class->dispatcher( $dispatcher->new );
2350 }
2351
2352 =head2 $c->setup_engine
2353
2354 Sets up engine.
2355
2356 =cut
2357
2358 sub setup_engine {
2359     my ( $class, $engine ) = @_;
2360
2361     if ($engine) {
2362         $engine = 'Catalyst::Engine::' . $engine;
2363     }
2364
2365     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2366         $engine = 'Catalyst::Engine::' . $env;
2367     }
2368
2369     if ( $ENV{MOD_PERL} ) {
2370         my $meta = Class::MOP::get_metaclass_by_name($class);
2371
2372         # create the apache method
2373         $meta->add_method('apache' => sub { shift->engine->apache });
2374
2375         my ( $software, $version ) =
2376           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2377
2378         $version =~ s/_//g;
2379         $version =~ s/(\.[^.]+)\./$1/g;
2380
2381         if ( $software eq 'mod_perl' ) {
2382
2383             if ( !$engine ) {
2384
2385                 if ( $version >= 1.99922 ) {
2386                     $engine = 'Catalyst::Engine::Apache2::MP20';
2387                 }
2388
2389                 elsif ( $version >= 1.9901 ) {
2390                     $engine = 'Catalyst::Engine::Apache2::MP19';
2391                 }
2392
2393                 elsif ( $version >= 1.24 ) {
2394                     $engine = 'Catalyst::Engine::Apache::MP13';
2395                 }
2396
2397                 else {
2398                     Catalyst::Exception->throw( message =>
2399                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2400                 }
2401
2402             }
2403
2404             # install the correct mod_perl handler
2405             if ( $version >= 1.9901 ) {
2406                 *handler = sub  : method {
2407                     shift->handle_request(@_);
2408                 };
2409             }
2410             else {
2411                 *handler = sub ($$) { shift->handle_request(@_) };
2412             }
2413
2414         }
2415
2416         elsif ( $software eq 'Zeus-Perl' ) {
2417             $engine = 'Catalyst::Engine::Zeus';
2418         }
2419
2420         else {
2421             Catalyst::Exception->throw(
2422                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2423         }
2424     }
2425
2426     unless ($engine) {
2427         $engine = $class->engine_class;
2428     }
2429
2430     Class::MOP::load_class($engine);
2431
2432     # check for old engines that are no longer compatible
2433     my $old_engine;
2434     if ( $engine->isa('Catalyst::Engine::Apache')
2435         && !Catalyst::Engine::Apache->VERSION )
2436     {
2437         $old_engine = 1;
2438     }
2439
2440     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2441         && Catalyst::Engine::Server->VERSION le '0.02' )
2442     {
2443         $old_engine = 1;
2444     }
2445
2446     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2447         && $engine->VERSION eq '0.01' )
2448     {
2449         $old_engine = 1;
2450     }
2451
2452     elsif ($engine->isa('Catalyst::Engine::Zeus')
2453         && $engine->VERSION eq '0.01' )
2454     {
2455         $old_engine = 1;
2456     }
2457
2458     if ($old_engine) {
2459         Catalyst::Exception->throw( message =>
2460               qq/Engine "$engine" is not supported by this version of Catalyst/
2461         );
2462     }
2463
2464     # engine instance
2465     $class->engine( $engine->new );
2466 }
2467
2468 =head2 $c->setup_home
2469
2470 Sets up the home directory.
2471
2472 =cut
2473
2474 sub setup_home {
2475     my ( $class, $home ) = @_;
2476
2477     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2478         $home = $env;
2479     }
2480
2481     $home ||= Catalyst::Utils::home($class);
2482
2483     if ($home) {
2484         #I remember recently being scolded for assigning config values like this
2485         $class->config->{home} ||= $home;
2486         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2487     }
2488 }
2489
2490 =head2 $c->setup_log
2491
2492 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2493 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2494 log to.
2495
2496 This method also installs a C<debug> method that returns a true value into the
2497 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2498 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2499
2500 Note that if the log has already been setup, by either a previous call to
2501 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2502 that this method won't actually set up the log object.
2503
2504 =cut
2505
2506 sub setup_log {
2507     my ( $class, $levels ) = @_;
2508
2509     $levels ||= '';
2510     $levels =~ s/^\s+//;
2511     $levels =~ s/\s+$//;
2512     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2513
2514     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2515     if ( defined $env_debug ) {
2516         $levels{debug} = 1 if $env_debug; # Ugly!
2517         delete($levels{debug}) unless $env_debug;
2518     }
2519
2520     unless ( $class->log ) {
2521         $class->log( Catalyst::Log->new(keys %levels) );
2522     }
2523
2524     if ( $levels{debug} ) {
2525         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2526         $class->log->debug('Debug messages enabled');
2527     }
2528 }
2529
2530 =head2 $c->setup_plugins
2531
2532 Sets up plugins.
2533
2534 =cut
2535
2536 =head2 $c->setup_stats
2537
2538 Sets up timing statistics class.
2539
2540 =cut
2541
2542 sub setup_stats {
2543     my ( $class, $stats ) = @_;
2544
2545     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2546
2547     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2548     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2549         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2550         $class->log->debug('Statistics enabled');
2551     }
2552 }
2553
2554
2555 =head2 $c->registered_plugins
2556
2557 Returns a sorted list of the plugins which have either been stated in the
2558 import list or which have been added via C<< MyApp->plugin(@args); >>.
2559
2560 If passed a given plugin name, it will report a boolean value indicating
2561 whether or not that plugin is loaded.  A fully qualified name is required if
2562 the plugin name does not begin with C<Catalyst::Plugin::>.
2563
2564  if ($c->registered_plugins('Some::Plugin')) {
2565      ...
2566  }
2567
2568 =cut
2569
2570 {
2571
2572     sub registered_plugins {
2573         my $proto = shift;
2574         return sort keys %{ $proto->_plugins } unless @_;
2575         my $plugin = shift;
2576         return 1 if exists $proto->_plugins->{$plugin};
2577         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2578     }
2579
2580     sub _register_plugin {
2581         my ( $proto, $plugin, $instant ) = @_;
2582         my $class = ref $proto || $proto;
2583
2584         Class::MOP::load_class( $plugin );
2585
2586         $proto->_plugins->{$plugin} = 1;
2587         unless ($instant) {
2588             no strict 'refs';
2589             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2590               my @superclasses = ($plugin, $meta->superclasses );
2591               $meta->superclasses(@superclasses);
2592             } else {
2593               unshift @{"$class\::ISA"}, $plugin;
2594             }
2595         }
2596         return $class;
2597     }
2598
2599     sub setup_plugins {
2600         my ( $class, $plugins ) = @_;
2601
2602         $class->_plugins( {} ) unless $class->_plugins;
2603         $plugins ||= [];
2604
2605         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2606
2607         for my $plugin ( reverse @plugins ) {
2608             Class::MOP::load_class($plugin);
2609             my $meta = find_meta($plugin);
2610             next if $meta && $meta->isa('Moose::Meta::Role');
2611
2612             $class->_register_plugin($plugin);
2613         }
2614
2615         my @roles =
2616             map { $_->name }
2617             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2618             map { find_meta($_) }
2619             @plugins;
2620
2621         Moose::Util::apply_all_roles(
2622             $class => @roles
2623         ) if @roles;
2624     }
2625 }
2626
2627 =head2 $c->stack
2628
2629 Returns an arrayref of the internal execution stack (actions that are
2630 currently executing).
2631
2632 =head2 $c->stats_class
2633
2634 Returns or sets the stats (timing statistics) class.
2635
2636 =head2 $c->use_stats
2637
2638 Returns 1 when stats collection is enabled.  Stats collection is enabled
2639 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2640 environment variable is set.
2641
2642 Note that this is a static method, not an accessor and should be overridden
2643 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2644
2645 =cut
2646
2647 sub use_stats { 0 }
2648
2649
2650 =head2 $c->write( $data )
2651
2652 Writes $data to the output stream. When using this method directly, you
2653 will need to manually set the C<Content-Length> header to the length of
2654 your output data, if known.
2655
2656 =cut
2657
2658 sub write {
2659     my $c = shift;
2660
2661     # Finalize headers if someone manually writes output
2662     $c->finalize_headers;
2663
2664     return $c->engine->write( $c, @_ );
2665 }
2666
2667 =head2 version
2668
2669 Returns the Catalyst version number. Mostly useful for "powered by"
2670 messages in template systems.
2671
2672 =cut
2673
2674 sub version { return $Catalyst::VERSION }
2675
2676 =head1 CONFIGURATION
2677
2678 There are a number of 'base' config variables which can be set:
2679
2680 =over
2681
2682 =item *
2683
2684 C<default_model> - The default model picked if you say C<< $c->model >>. See L</$c->model($name)>.
2685
2686 =item *
2687
2688 C<default_view> - The default view to be rendered or returned when C<< $c->view >>. See L</$c->view($name)>.
2689 is called.
2690
2691 =item *
2692
2693 C<disable_component_resolution_regex_fallback> - Turns
2694 off the deprecated component resolution functionality so
2695 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2696 are called then regex search will not be attempted on string values and
2697 instead C<undef> will be returned.
2698
2699 =item *
2700
2701 C<home> - The application home directory. In an uninstalled application,
2702 this is the top level application directory. In an installed application,
2703 this will be the directory containing C<< MyApp.pm >>.
2704
2705 =item *
2706
2707 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2708
2709 =item *
2710
2711 C<name> - The name of the application in debug messages and the debug and
2712 welcome screens
2713
2714 =item *
2715
2716 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2717 until it is accessed. This allows you to (for example) check authentication (and reject
2718 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2719
2720 =item *
2721
2722 C<root> - The root directory for templates. Usually this is just a
2723 subdirectory of the home directory, but you can set it to change the
2724 templates to a different directory.
2725
2726 =item *
2727
2728 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2729 namespaces from which components will be loaded (and constructed and stored in
2730 C<< $c->components >>).
2731
2732 =item *
2733
2734 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2735 to be shown in hit debug tables in the test server.
2736
2737 =item *
2738
2739 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2740
2741 =back
2742
2743 =head1 INTERNAL ACTIONS
2744
2745 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2746 C<_ACTION>, and C<_END>. These are by default not shown in the private
2747 action table, but you can make them visible with a config parameter.
2748
2749     MyApp->config(show_internal_actions => 1);
2750
2751 =head1 ON-DEMAND PARSER
2752
2753 The request body is usually parsed at the beginning of a request,
2754 but if you want to handle input yourself, you can enable on-demand
2755 parsing with a config parameter.
2756
2757     MyApp->config(parse_on_demand => 1);
2758
2759 =head1 PROXY SUPPORT
2760
2761 Many production servers operate using the common double-server approach,
2762 with a lightweight frontend web server passing requests to a larger
2763 backend server. An application running on the backend server must deal
2764 with two problems: the remote user always appears to be C<127.0.0.1> and
2765 the server's hostname will appear to be C<localhost> regardless of the
2766 virtual host that the user connected through.
2767
2768 Catalyst will automatically detect this situation when you are running
2769 the frontend and backend servers on the same machine. The following
2770 changes are made to the request.
2771
2772     $c->req->address is set to the user's real IP address, as read from
2773     the HTTP X-Forwarded-For header.
2774
2775     The host value for $c->req->base and $c->req->uri is set to the real
2776     host, as read from the HTTP X-Forwarded-Host header.
2777
2778 Additionally, you may be running your backend application on an insecure
2779 connection (port 80) while your frontend proxy is running under SSL.  If there
2780 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2781 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2782 be created properly.
2783
2784 In the case of passing in:
2785
2786     X-Forwarded-Port: 443
2787
2788 All calls to C<uri_for> will result in an https link, as is expected.
2789
2790 Obviously, your web server must support these headers for this to work.
2791
2792 In a more complex server farm environment where you may have your
2793 frontend proxy server(s) on different machines, you will need to set a
2794 configuration option to tell Catalyst to read the proxied data from the
2795 headers.
2796
2797     MyApp->config(using_frontend_proxy => 1);
2798
2799 If you do not wish to use the proxy support at all, you may set:
2800
2801     MyApp->config(ignore_frontend_proxy => 1);
2802
2803 =head1 THREAD SAFETY
2804
2805 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2806 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2807 believe the Catalyst core to be thread-safe.
2808
2809 If you plan to operate in a threaded environment, remember that all other
2810 modules you are using must also be thread-safe. Some modules, most notably
2811 L<DBD::SQLite>, are not thread-safe.
2812
2813 =head1 SUPPORT
2814
2815 IRC:
2816
2817     Join #catalyst on irc.perl.org.
2818
2819 Mailing Lists:
2820
2821     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2822     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2823
2824 Web:
2825
2826     http://catalyst.perl.org
2827
2828 Wiki:
2829
2830     http://dev.catalyst.perl.org
2831
2832 =head1 SEE ALSO
2833
2834 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2835
2836 =head2 L<Catalyst::Manual> - The Catalyst Manual
2837
2838 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2839
2840 =head2 L<Catalyst::Engine> - Core engine
2841
2842 =head2 L<Catalyst::Log> - Log class.
2843
2844 =head2 L<Catalyst::Request> - Request object
2845
2846 =head2 L<Catalyst::Response> - Response object
2847
2848 =head2 L<Catalyst::Test> - The test suite.
2849
2850 =head1 PROJECT FOUNDER
2851
2852 sri: Sebastian Riedel <sri@cpan.org>
2853
2854 =head1 CONTRIBUTORS
2855
2856 abw: Andy Wardley
2857
2858 acme: Leon Brocard <leon@astray.com>
2859
2860 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
2861
2862 Andrew Bramble
2863
2864 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
2865
2866 Andrew Ruthven
2867
2868 andyg: Andy Grundman <andy@hybridized.org>
2869
2870 audreyt: Audrey Tang
2871
2872 bricas: Brian Cassidy <bricas@cpan.org>
2873
2874 Caelum: Rafael Kitover <rkitover@io.com>
2875
2876 chansen: Christian Hansen
2877
2878 chicks: Christopher Hicks
2879
2880 Chisel Wright C<pause@herlpacker.co.uk>
2881
2882 Danijel Milicevic C<me@danijel.de>
2883
2884 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
2885
2886 David Naughton, C<naughton@umn.edu>
2887
2888 David E. Wheeler
2889
2890 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2891
2892 Drew Taylor
2893
2894 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2895
2896 esskar: Sascha Kiefer
2897
2898 fireartist: Carl Franks <cfranks@cpan.org>
2899
2900 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
2901
2902 gabb: Danijel Milicevic
2903
2904 Gary Ashton Jones
2905
2906 Gavin Henry C<ghenry@perl.me.uk>
2907
2908 Geoff Richards
2909
2910 groditi: Guillermo Roditi <groditi@gmail.com>
2911
2912 hobbs: Andrew Rodland <andrew@cleverdomain.org>
2913
2914 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2915
2916 jcamacho: Juan Camacho
2917
2918 jester: Jesse Sheidlower C<jester@panix.com>
2919
2920 jhannah: Jay Hannah <jay@jays.net>
2921
2922 Jody Belka
2923
2924 Johan Lindstrom
2925
2926 jon: Jon Schutz <jjschutz@cpan.org>
2927
2928 Jonathan Rockway C<< <jrockway@cpan.org> >>
2929
2930 Kieren Diment C<kd@totaldatasolution.com>
2931
2932 konobi: Scott McWhirter <konobi@cpan.org>
2933
2934 marcus: Marcus Ramberg <mramberg@cpan.org>
2935
2936 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2937
2938 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2939
2940 mugwump: Sam Vilain
2941
2942 naughton: David Naughton
2943
2944 ningu: David Kamholz <dkamholz@cpan.org>
2945
2946 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2947
2948 numa: Dan Sully <daniel@cpan.org>
2949
2950 obra: Jesse Vincent
2951
2952 omega: Andreas Marienborg
2953
2954 Oleg Kostyuk <cub.uanic@gmail.com>
2955
2956 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2957
2958 rafl: Florian Ragwitz <rafl@debian.org>
2959
2960 random: Roland Lammel <lammel@cpan.org>
2961
2962 Robert Sedlacek C<< <rs@474.at> >>
2963
2964 sky: Arthur Bergman
2965
2966 t0m: Tomas Doran <bobtfish@bobtfish.net>
2967
2968 Ulf Edvinsson
2969
2970 Viljo Marrandi C<vilts@yahoo.com>
2971
2972 Will Hawes C<info@whawes.co.uk>
2973
2974 willert: Sebastian Willert <willert@cpan.org>
2975
2976 Yuval Kogman, C<nothingmuch@woobling.org>
2977
2978 =head1 LICENSE
2979
2980 This library is free software. You can redistribute it and/or modify it under
2981 the same terms as Perl itself.
2982
2983 =cut
2984
2985 no Moose;
2986
2987 __PACKAGE__->meta->make_immutable;
2988
2989 1;