lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/container components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80032';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the callee.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@captures, \@arguments ] )
 425
 426 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 427
 428 The relationship between C<go> and
 429 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 430 the relationship between
 431 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 432 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 433 C<< $c->go >> will perform a full dispatch on the specified action or method,
 434 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 435 C<go> escapes the processing of the current request chain on completion, and
 436 does not return to its caller.
 437
 438 @arguments are arguments to the final destination of $action. @captures are
 439 arguments to the intermediate steps, if any, on the way to the final sub of
 440 $action.
 441
 442 =cut
 443
 444 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 445
 446 =head2 $c->response
 447
 448 =head2 $c->res
 449
 450 Returns the current L<Catalyst::Response> object, see there for details.
 451
 452 =head2 $c->stash
 453
 454 Returns a hashref to the stash, which may be used to store data and pass
 455 it between components during a request. You can also set hash keys by
 456 passing arguments. The stash is automatically sent to the view. The
 457 stash is cleared at the end of a request; it cannot be used for
 458 persistent storage (for this you must use a session; see
 459 L<Catalyst::Plugin::Session> for a complete system integrated with
 460 Catalyst).
 461
 462     $c->stash->{foo} = $bar;
 463     $c->stash( { moose => 'majestic', qux => 0 } );
 464     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 465
 466     # stash is automatically passed to the view for use in a template
 467     $c->forward( 'MyApp::View::TT' );
 468
 469 =cut
 470
 471 around stash => sub {
 472     my $orig = shift;
 473     my $c = shift;
 474     my $stash = $orig->($c);
 475     if (@_) {
 476         my $new_stash = @_ > 1 ? {@_} : $_[0];
 477         croak('stash takes a hash or hashref') unless ref $new_stash;
 478         foreach my $key ( keys %$new_stash ) {
 479           $stash->{$key} = $new_stash->{$key};
 480         }
 481     }
 482
 483     return $stash;
 484 };
 485
 486
 487 =head2 $c->error
 488
 489 =head2 $c->error($error, ...)
 490
 491 =head2 $c->error($arrayref)
 492
 493 Returns an arrayref containing error messages.  If Catalyst encounters an
 494 error while processing a request, it stores the error in $c->error.  This
 495 method should only be used to store fatal error messages.
 496
 497     my @error = @{ $c->error };
 498
 499 Add a new error.
 500
 501     $c->error('Something bad happened');
 502
 503 =cut
 504
 505 sub error {
 506     my $c = shift;
 507     if ( $_[0] ) {
 508         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 509         croak @$error unless ref $c;
 510         push @{ $c->{error} }, @$error;
 511     }
 512     elsif ( defined $_[0] ) { $c->{error} = undef }
 513     return $c->{error} || [];
 514 }
 515
 516
 517 =head2 $c->state
 518
 519 Contains the return value of the last executed action.
 520 Note that << $c->state >> operates in a scalar context which means that all
 521 values it returns are scalar.
 522
 523 =head2 $c->clear_errors
 524
 525 Clear errors.  You probably don't want to clear the errors unless you are
 526 implementing a custom error screen.
 527
 528 This is equivalent to running
 529
 530     $c->error(0);
 531
 532 =cut
 533
 534 sub clear_errors {
 535     my $c = shift;
 536     $c->error(0);
 537 }
 538
 539 =head2 COMPONENT ACCESSORS
 540
 541 =head2 $c->controller($name)
 542
 543 Gets a L<Catalyst::Controller> instance by name.
 544
 545     $c->controller('Foo')->do_stuff;
 546
 547 If the name is omitted, will return the controller for the dispatched
 548 action.
 549
 550 If you want to search for controllers, pass in a regexp as the argument.
 551
 552     # find all controllers that start with Foo
 553     my @foo_controllers = $c->controller(qr{^Foo});
 554
 555
 556 =cut
 557
 558 sub controller {
 559     my ( $c, $name, @args ) = @_;
 560     my $container = $c->container->get_sub_container('controller');
 561
 562     if( $name ) {
 563         # Direct component hash lookup to avoid costly regexps
 564         return $container->get_component( $name, $c, @args )
 565             if $container->has_service($name) && !ref $name;
 566
 567         return $container->get_component_regexp( $name, $c, @args );
 568     }
 569
 570     return $c->component( $c->action->class );
 571 }
 572
 573 =head2 $c->model($name)
 574
 575 Gets a L<Catalyst::Model> instance by name.
 576
 577     $c->model('Foo')->do_stuff;
 578
 579 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 580
 581 If the name is omitted, it will look for
 582  - a model object in $c->stash->{current_model_instance}, then
 583  - a model name in $c->stash->{current_model}, then
 584  - a config setting 'default_model', or
 585  - check if there is only one model, and return it if that's the case.
 586
 587 If you want to search for models, pass in a regexp as the argument.
 588
 589     # find all models that start with Foo
 590     my @foo_models = $c->model(qr{^Foo});
 591
 592 =cut
 593
 594 sub model {
 595     my ( $c, $name, @args ) = @_;
 596     my $appclass = ref($c) || $c;
 597     my $container = $c->container->get_sub_container('model');
 598
 599     if( $name ) {
 600         # Direct component hash lookup to avoid costly regexps
 601         return $container->get_component( $name, $c, @args )
 602             if $container->has_service($name) && !ref $name;
 603
 604         return $container->get_component_regexp( $name, $c, @args );
 605     }
 606
 607     if (ref $c) {
 608         return $c->stash->{current_model_instance}
 609           if $c->stash->{current_model_instance};
 610         return $c->model( $c->stash->{current_model} )
 611           if $c->stash->{current_model};
 612     }
 613     return $c->model( $appclass->config->{default_model} )
 614       if $appclass->config->{default_model};
 615
 616 # FIXME: will this still be mantained?
 617     my( $comp, $rest ) = $container->get_service_list;
 618
 619     if( $rest ) {
 620         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 621         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 622         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 623         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 624         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 625     }
 626
 627     return $container->get_component( $comp, $c, @args );
 628 }
 629
 630
 631 =head2 $c->view($name)
 632
 633 Gets a L<Catalyst::View> instance by name.
 634
 635     $c->view('Foo')->do_stuff;
 636
 637 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 638
 639 If the name is omitted, it will look for
 640  - a view object in $c->stash->{current_view_instance}, then
 641  - a view name in $c->stash->{current_view}, then
 642  - a config setting 'default_view', or
 643  - check if there is only one view, and return it if that's the case.
 644
 645 If you want to search for views, pass in a regexp as the argument.
 646
 647     # find all views that start with Foo
 648     my @foo_views = $c->view(qr{^Foo});
 649
 650 =cut
 651
 652 sub view {
 653     my ( $c, $name, @args ) = @_;
 654     my $appclass = ref($c) || $c;
 655     my $container = $c->container->get_sub_container('view');
 656
 657     if( $name ) {
 658         # Direct component hash lookup to avoid costly regexps
 659         return $container->get_component( $name, $c, @args )
 660             if !ref $name && $container->has_service($name);
 661
 662         $c->log->warn( "Attempted to use view '$name', but does not exist" );
 663
 664         return $container->get_component_regexp( $name, $c, @args );
 665     }
 666
 667     if (ref $c) {
 668         return $c->stash->{current_view_instance}
 669           if $c->stash->{current_view_instance};
 670         return $c->view( $c->stash->{current_view} )
 671           if $c->stash->{current_view};
 672     }
 673     return $c->view( $appclass->config->{default_view} )
 674       if $appclass->config->{default_view};
 675
 676     my( $comp, $rest ) = $container->get_service_list;
 677
 678     if( $rest ) {
 679         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 680         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 681         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 682         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 683         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 684     }
 685
 686     return $container->get_component( $comp, $c, @args );
 687 }
 688
 689 =head2 $c->controllers
 690
 691 Returns the available names which can be passed to $c->controller
 692
 693 =cut
 694
 695 sub controllers {
 696     my ( $c ) = @_;
 697     return $c->container->get_sub_container('controller')->get_service_list;
 698 }
 699
 700 =head2 $c->models
 701
 702 Returns the available names which can be passed to $c->model
 703
 704 =cut
 705
 706 sub models {
 707     my ( $c ) = @_;
 708     return $c->container->get_sub_container('model')->get_service_list;
 709 }
 710
 711
 712 =head2 $c->views
 713
 714 Returns the available names which can be passed to $c->view
 715
 716 =cut
 717
 718 sub views {
 719     my ( $c ) = @_;
 720     return $c->container->get_sub_container('view')->get_service_list;
 721 }
 722
 723 =head2 $c->comp($name)
 724
 725 =head2 $c->component($name)
 726
 727 Gets a component object by name. This method is not recommended,
 728 unless you want to get a specific component by full
 729 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 730 should be used instead.
 731
 732 If C<$name> is a regexp, a list of components matched against the full
 733 component name will be returned.
 734
 735 If Catalyst can't find a component by name, it will fallback to regex
 736 matching by default. To disable this behaviour set
 737 disable_component_resolution_regex_fallback to a true value.
 738
 739     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 740
 741 =cut
 742
 743 sub component {
 744     my ( $c, $component, @args ) = @_;
 745     unshift @args, $c;
 746
 747     if ( $component ) {
 748         my ($type, $name) = _get_component_type_name($component);
 749
 750         if ($type && $c->container->has_sub_container($type)) {
 751             my $container = $c->container->get_sub_container($type);
 752
 753             if( !ref $component && $container->has_service($name) ) {
 754                 return $container->get_component( $name, \@args );
 755             }
 756
 757             return $container->get_component_regexp( $c, $name, \@args );
 758         }
 759
 760         return
 761             if $c->config->{disable_component_resolution_regex_fallback} && !ref $component;
 762
 763         # This is here so $c->comp( '::M::' ) works
 764         my $query = ref $component ? $component : qr{$component}i;
 765
 766         for my $subcontainer_name (qw/model view controller/) {
 767             my $subcontainer = $c->container->get_sub_container($subcontainer_name);
 768             my @components   = $subcontainer->get_service_list;
 769             my @result       = grep { m{$query} } @components;
 770
 771             if (@result) {
 772                 return map { $subcontainer->get_component( $_, \@args ) } @result
 773                     if ref $component;
 774
 775                 $c->log->warn( Carp::shortmess(qq(Found results for "${component}" using regexp fallback)) );
 776                 $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 777                 $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 778
 779                 return $subcontainer->get_component( $result[0], \@args );
 780             }
 781         }
 782
 783         # I would expect to return an empty list here, but that breaks back-compat
 784     }
 785
 786     # fallback
 787     return sort keys %{ $c->components };
 788 }
 789
 790 =head2 CLASS DATA AND HELPER CLASSES
 791
 792 =head2 $c->config
 793
 794 Returns or takes a hashref containing the application's configuration.
 795
 796     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 797
 798 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 799 like C<myapp.conf> in your applications home directory. See
 800 L<Catalyst::Plugin::ConfigLoader>.
 801
 802 =head3 Cascading configuration
 803
 804 The config method is present on all Catalyst components, and configuration
 805 will be merged when an application is started. Configuration loaded with
 806 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 807 followed by configuration in your top level C<MyApp> class. These two
 808 configurations are merged, and then configuration data whose hash key matches a
 809 component name is merged with configuration for that component.
 810
 811 The configuration for a component is then passed to the C<new> method when a
 812 component is constructed.
 813
 814 For example:
 815
 816     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 817     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 818
 819 will mean that C<MyApp::Model::Foo> receives the following data when
 820 constructed:
 821
 822     MyApp::Model::Foo->new({
 823         bar => 'baz',
 824         quux => 'frob',
 825         overrides => 'me',
 826     });
 827
 828 It's common practice to use a Moose attribute
 829 on the receiving component to access the config value.
 830
 831     package MyApp::Model::Foo;
 832
 833     use Moose;
 834
 835     # this attr will receive 'baz' at construction time
 836     has 'bar' => (
 837         is  => 'rw',
 838         isa => 'Str',
 839     );
 840
 841 You can then get the value 'baz' by calling $c->model('Foo')->bar
 842 (or $self->bar inside code in the model).
 843
 844 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 845 as a way of reading config within your code, as this B<will not> give you the
 846 correctly merged config back. You B<MUST> take the config values supplied to
 847 the constructor and use those instead.
 848
 849 =cut
 850
 851 around config => sub {
 852     my $orig = shift;
 853     my $c = shift;
 854
 855     croak('Setting config after setup has been run is not allowed.')
 856         if ( @_ and $c->setup_finished );
 857
 858     $c->$orig(@_);
 859 };
 860
 861 =head2 $c->log
 862
 863 Returns the logging object instance. Unless it is already set, Catalyst
 864 sets this up with a L<Catalyst::Log> object. To use your own log class,
 865 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 866 C<< __PACKAGE__->setup >>.
 867
 868  __PACKAGE__->log( MyLogger->new );
 869  __PACKAGE__->setup;
 870
 871 And later:
 872
 873     $c->log->info( 'Now logging with my own logger!' );
 874
 875 Your log class should implement the methods described in
 876 L<Catalyst::Log>.
 877
 878
 879 =head2 $c->debug
 880
 881 Returns 1 if debug mode is enabled, 0 otherwise.
 882
 883 You can enable debug mode in several ways:
 884
 885 =over
 886
 887 =item By calling myapp_server.pl with the -d flag
 888
 889 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 890
 891 =item The -Debug option in your MyApp.pm
 892
 893 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 894
 895 =back
 896
 897 The first three also set the log level to 'debug'.
 898
 899 Calling C<< $c->debug(1) >> has no effect.
 900
 901 =cut
 902
 903 sub debug { 0 }
 904
 905 =head2 $c->dispatcher
 906
 907 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 908
 909 =head2 $c->engine
 910
 911 Returns the engine instance. See L<Catalyst::Engine>.
 912
 913
 914 =head2 UTILITY METHODS
 915
 916 =head2 $c->path_to(@path)
 917
 918 Merges C<@path> with C<< $c->config->{home} >> and returns a
 919 L<Path::Class::Dir> object. Note you can usually use this object as
 920 a filename, but sometimes you will have to explicitly stringify it
 921 yourself by calling the C<< ->stringify >> method.
 922
 923 For example:
 924
 925     $c->path_to( 'db', 'sqlite.db' );
 926
 927 =cut
 928
 929 sub path_to {
 930     my ( $c, @path ) = @_;
 931     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 932     if ( -d $path ) { return $path }
 933     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 934 }
 935
 936 =head2 $c->plugin( $name, $class, @args )
 937
 938 Helper method for plugins. It creates a class data accessor/mutator and
 939 loads and instantiates the given class.
 940
 941     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 942
 943     $c->prototype->define_javascript_functions;
 944
 945 B<Note:> This method of adding plugins is deprecated. The ability
 946 to add plugins like this B<will be removed> in a Catalyst 5.81.
 947 Please do not use this functionality in new code.
 948
 949 =cut
 950
 951 sub plugin {
 952     my ( $class, $name, $plugin, @args ) = @_;
 953
 954     # See block comment in t/unit_core_plugin.t
 955     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 956
 957     $class->_register_plugin( $plugin, 1 );
 958
 959     eval { $plugin->import };
 960     $class->mk_classdata($name);
 961     my $obj;
 962     eval { $obj = $plugin->new(@args) };
 963
 964     if ($@) {
 965         Catalyst::Exception->throw( message =>
 966               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 967     }
 968
 969     $class->$name($obj);
 970     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 971       if $class->debug;
 972 }
 973
 974 =head2 MyApp->setup
 975
 976 Initializes the dispatcher and engine, loads any plugins, and loads the
 977 model, view, and controller components. You may also specify an array
 978 of plugins to load here, if you choose to not load them in the C<use
 979 Catalyst> line.
 980
 981     MyApp->setup;
 982     MyApp->setup( qw/-Debug/ );
 983
 984 =cut
 985
 986 sub setup {
 987     my ( $class, @arguments ) = @_;
 988     croak('Running setup more than once')
 989         if ( $class->setup_finished );
 990
 991     unless ( $class->isa('Catalyst') ) {
 992
 993         Catalyst::Exception->throw(
 994             message => qq/'$class' does not inherit from Catalyst/ );
 995     }
 996
 997     if ( $class->arguments ) {
 998         @arguments = ( @arguments, @{ $class->arguments } );
 999     }
1000
1001     # Process options
1002     my $flags = {};
1003
1004     foreach (@arguments) {
1005
1006         if (/^-Debug$/) {
1007             $flags->{log} =
1008               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1009         }
1010         elsif (/^-(\w+)=?(.*)$/) {
1011             $flags->{ lc $1 } = $2;
1012         }
1013         else {
1014             push @{ $flags->{plugins} }, $_;
1015         }
1016     }
1017
1018     $class->setup_config();
1019     $class->setup_home( delete $flags->{home} );
1020
1021     $class->setup_log( delete $flags->{log} );
1022     $class->setup_plugins( delete $flags->{plugins} );
1023     $class->setup_dispatcher( delete $flags->{dispatcher} );
1024     $class->setup_engine( delete $flags->{engine} );
1025     $class->setup_stats( delete $flags->{stats} );
1026
1027     for my $flag ( sort keys %{$flags} ) {
1028
1029         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1030             &$code( $class, delete $flags->{$flag} );
1031         }
1032         else {
1033             $class->log->warn(qq/Unknown flag "$flag"/);
1034         }
1035     }
1036
1037     eval { require Catalyst::Devel; };
1038     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1039         $class->log->warn(<<"EOF");
1040 You are running an old script!
1041
1042   Please update by running (this will overwrite existing files):
1043     catalyst.pl -force -scripts $class
1044
1045   or (this will not overwrite existing files):
1046     catalyst.pl -scripts $class
1047
1048 EOF
1049     }
1050
1051     if ( $class->debug ) {
1052         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1053
1054         if (@plugins) {
1055             my $column_width = Catalyst::Utils::term_width() - 6;
1056             my $t = Text::SimpleTable->new($column_width);
1057             $t->row($_) for @plugins;
1058             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1059         }
1060
1061         my $dispatcher = $class->dispatcher;
1062         my $engine     = $class->engine;
1063         my $home       = $class->config->{home};
1064
1065         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1066         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1067
1068         $home
1069           ? ( -d $home )
1070           ? $class->log->debug(qq/Found home "$home"/)
1071           : $class->log->debug(qq/Home "$home" doesn't exist/)
1072           : $class->log->debug(q/Couldn't find home/);
1073     }
1074
1075     # Call plugins setup, this is stupid and evil.
1076     # Also screws C3 badly on 5.10, hack to avoid.
1077     {
1078         no warnings qw/redefine/;
1079         local *setup = sub { };
1080         $class->setup unless $Catalyst::__AM_RESTARTING;
1081     }
1082
1083     # Initialize our data structure
1084     $class->components( {} );
1085
1086     $class->setup_components;
1087
1088     if ( $class->debug ) {
1089         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1090         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1091         for my $comp ( sort keys %{ $class->components } ) {
1092             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1093             $t->row( $comp, $type );
1094         }
1095         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1096           if ( keys %{ $class->components } );
1097     }
1098
1099     # Add our self to components, since we are also a component
1100     if( $class->isa('Catalyst::Controller') ){
1101       $class->components->{$class} = $class;
1102     }
1103
1104     $class->setup_actions;
1105
1106     if ( $class->debug ) {
1107         my $name = $class->config->{name} || 'Application';
1108         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1109     }
1110
1111     # Make sure that the application class becomes immutable at this point,
1112     B::Hooks::EndOfScope::on_scope_end {
1113         return if $@;
1114         my $meta = Class::MOP::get_metaclass_by_name($class);
1115         if (
1116             $meta->is_immutable
1117             && ! { $meta->immutable_options }->{replace_constructor}
1118             && (
1119                    $class->isa('Class::Accessor::Fast')
1120                 || $class->isa('Class::Accessor')
1121             )
1122         ) {
1123             warn "You made your application class ($class) immutable, "
1124                 . "but did not inline the\nconstructor. "
1125                 . "This will break catalyst, as your app \@ISA "
1126                 . "Class::Accessor(::Fast)?\nPlease pass "
1127                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1128         }
1129         $meta->make_immutable(
1130             replace_constructor => 1,
1131         ) unless $meta->is_immutable;
1132     };
1133
1134     if ($class->config->{case_sensitive}) {
1135         $class->log->warn($class . "->config->{case_sensitive} is set.");
1136         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1137     }
1138
1139     $class->setup_finalize;
1140     # Should be the last thing we do so that user things hooking
1141     # setup_finalize can log..
1142     $class->log->_flush() if $class->log->can('_flush');
1143     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1144 }
1145
1146 =head2 $app->setup_finalize
1147
1148 A hook to attach modifiers to. This method does not do anything except set the
1149 C<setup_finished> accessor.
1150
1151 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1152
1153 Example:
1154
1155     after setup_finalize => sub {
1156         my $app = shift;
1157
1158         ## do stuff here..
1159     };
1160
1161 =cut
1162
1163 sub setup_finalize {
1164     my ($class) = @_;
1165     $class->setup_finished(1);
1166 }
1167
1168 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1169
1170 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1171
1172 Constructs an absolute L<URI> object based on the application root, the
1173 provided path, and the additional arguments and query parameters provided.
1174 When used as a string, provides a textual URI.  If you need more flexibility
1175 than this (i.e. the option to provide relative URIs etc.) see
1176 L<Catalyst::Plugin::SmartURI>.
1177
1178 If no arguments are provided, the URI for the current action is returned.
1179 To return the current action and also provide @args, use
1180 C<< $c->uri_for( $c->action, @args ) >>.
1181
1182 If the first argument is a string, it is taken as a public URI path relative
1183 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1184 relative to the application root (if it does). It is then merged with
1185 C<< $c->request->base >>; any C<@args> are appended as additional path
1186 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1187
1188 If the first argument is a L<Catalyst::Action> it represents an action which
1189 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1190 optional C<\@captures> argument (an arrayref) allows passing the captured
1191 variables that are needed to fill in the paths of Chained and Regex actions;
1192 once the path is resolved, C<uri_for> continues as though a path was
1193 provided, appending any arguments or parameters and creating an absolute
1194 URI.
1195
1196 The captures for the current request can be found in
1197 C<< $c->request->captures >>, and actions can be resolved using
1198 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1199 path, use C<< $c->uri_for_action >> instead.
1200
1201   # Equivalent to $c->req->uri
1202   $c->uri_for($c->action, $c->req->captures,
1203       @{ $c->req->args }, $c->req->params);
1204
1205   # For the Foo action in the Bar controller
1206   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1207
1208   # Path to a static resource
1209   $c->uri_for('/static/images/logo.png');
1210
1211 =cut
1212
1213 sub uri_for {
1214     my ( $c, $path, @args ) = @_;
1215
1216     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1217         $path = $path->path_prefix;
1218         $path =~ s{/+\z}{};
1219         $path .= '/';
1220     }
1221
1222     undef($path) if (defined $path && $path eq '');
1223
1224     my $params =
1225       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1226
1227     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1228     foreach my $arg (@args) {
1229         utf8::encode($arg) if utf8::is_utf8($arg);
1230         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1231     }
1232
1233     if ( blessed($path) ) { # action object
1234         s|/|%2F|g for @args;
1235         my $captures = [ map { s|/|%2F|g; $_; }
1236                         ( scalar @args && ref $args[0] eq 'ARRAY'
1237                          ? @{ shift(@args) }
1238                          : ()) ];
1239
1240         foreach my $capture (@$captures) {
1241             utf8::encode($capture) if utf8::is_utf8($capture);
1242             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1243         }
1244
1245         my $action = $path;
1246         $path = $c->dispatcher->uri_for_action($action, $captures);
1247         if (not defined $path) {
1248             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1249                 if $c->debug;
1250             return undef;
1251         }
1252         $path = '/' if $path eq '';
1253     }
1254
1255     unshift(@args, $path);
1256
1257     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1258         my $namespace = $c->namespace;
1259         if (defined $path) { # cheesy hack to handle path '../foo'
1260            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1261         }
1262         unshift(@args, $namespace || '');
1263     }
1264
1265     # join args with '/', or a blank string
1266     my $args = join('/', grep { defined($_) } @args);
1267     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1268     $args =~ s!^/+!!;
1269     my $base = $c->req->base;
1270     my $class = ref($base);
1271     $base =~ s{(?<!/)$}{/};
1272
1273     my $query = '';
1274
1275     if (my @keys = keys %$params) {
1276       # somewhat lifted from URI::_query's query_form
1277       $query = '?'.join('&', map {
1278           my $val = $params->{$_};
1279           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1280           s/ /+/g;
1281           my $key = $_;
1282           $val = '' unless defined $val;
1283           (map {
1284               my $param = "$_";
1285               utf8::encode( $param ) if utf8::is_utf8($param);
1286               # using the URI::Escape pattern here so utf8 chars survive
1287               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1288               $param =~ s/ /+/g;
1289               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1290       } @keys);
1291     }
1292
1293     my $res = bless(\"${base}${args}${query}", $class);
1294     $res;
1295 }
1296
1297 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1298
1299 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1300
1301 =over
1302
1303 =item $path
1304
1305 A private path to the Catalyst action you want to create a URI for.
1306
1307 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1308 >> and passing the resulting C<$action> and the remaining arguments to C<<
1309 $c->uri_for >>.
1310
1311 You can also pass in a Catalyst::Action object, in which case it is passed to
1312 C<< $c->uri_for >>.
1313
1314 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1315
1316 For example, if the action looks like:
1317
1318  package MyApp::Controller::Users;
1319
1320  sub lst : Path('the-list') {}
1321
1322 You can use:
1323
1324  $c->uri_for_action('/users/lst')
1325
1326 and it will create the URI /users/the-list.
1327
1328 =back
1329
1330 =cut
1331
1332 sub uri_for_action {
1333     my ( $c, $path, @args ) = @_;
1334     my $action = blessed($path)
1335       ? $path
1336       : $c->dispatcher->get_action_by_path($path);
1337     unless (defined $action) {
1338       croak "Can't find action for path '$path'";
1339     }
1340     return $c->uri_for( $action, @args );
1341 }
1342
1343 =head2 $c->welcome_message
1344
1345 Returns the Catalyst welcome HTML page.
1346
1347 =cut
1348
1349 sub welcome_message {
1350     my $c      = shift;
1351     my $name   = $c->config->{name};
1352     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1353     my $prefix = Catalyst::Utils::appprefix( ref $c );
1354     $c->response->content_type('text/html; charset=utf-8');
1355     return <<"EOF";
1356 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1357     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1358 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1359     <head>
1360     <meta http-equiv="Content-Language" content="en" />
1361     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1362         <title>$name on Catalyst $VERSION</title>
1363         <style type="text/css">
1364             body {
1365                 color: #000;
1366                 background-color: #eee;
1367             }
1368             div#content {
1369                 width: 640px;
1370                 margin-left: auto;
1371                 margin-right: auto;
1372                 margin-top: 10px;
1373                 margin-bottom: 10px;
1374                 text-align: left;
1375                 background-color: #ccc;
1376                 border: 1px solid #aaa;
1377             }
1378             p, h1, h2 {
1379                 margin-left: 20px;
1380                 margin-right: 20px;
1381                 font-family: verdana, tahoma, sans-serif;
1382             }
1383             a {
1384                 font-family: verdana, tahoma, sans-serif;
1385             }
1386             :link, :visited {
1387                     text-decoration: none;
1388                     color: #b00;
1389                     border-bottom: 1px dotted #bbb;
1390             }
1391             :link:hover, :visited:hover {
1392                     color: #555;
1393             }
1394             div#topbar {
1395                 margin: 0px;
1396             }
1397             pre {
1398                 margin: 10px;
1399                 padding: 8px;
1400             }
1401             div#answers {
1402                 padding: 8px;
1403                 margin: 10px;
1404                 background-color: #fff;
1405                 border: 1px solid #aaa;
1406             }
1407             h1 {
1408                 font-size: 0.9em;
1409                 font-weight: normal;
1410                 text-align: center;
1411             }
1412             h2 {
1413                 font-size: 1.0em;
1414             }
1415             p {
1416                 font-size: 0.9em;
1417             }
1418             p img {
1419                 float: right;
1420                 margin-left: 10px;
1421             }
1422             span#appname {
1423                 font-weight: bold;
1424                 font-size: 1.6em;
1425             }
1426         </style>
1427     </head>
1428     <body>
1429         <div id="content">
1430             <div id="topbar">
1431                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1432                     $VERSION</h1>
1433              </div>
1434              <div id="answers">
1435                  <p>
1436                  <img src="$logo" alt="Catalyst Logo" />
1437                  </p>
1438                  <p>Welcome to the  world of Catalyst.
1439                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1440                     framework will make web development something you had
1441                     never expected it to be: Fun, rewarding, and quick.</p>
1442                  <h2>What to do now?</h2>
1443                  <p>That really depends  on what <b>you</b> want to do.
1444                     We do, however, provide you with a few starting points.</p>
1445                  <p>If you want to jump right into web development with Catalyst
1446                     you might want to start with a tutorial.</p>
1447 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1448 </pre>
1449 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1450 <pre>
1451 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1452 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1453 </code></pre>
1454                  <h2>What to do next?</h2>
1455                  <p>Next it's time to write an actual application. Use the
1456                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1457                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1458                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1459                     they can save you a lot of work.</p>
1460                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1461                     <p>Also, be sure to check out the vast and growing
1462                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1463                     you are likely to find what you need there.
1464                     </p>
1465
1466                  <h2>Need help?</h2>
1467                  <p>Catalyst has a very active community. Here are the main places to
1468                     get in touch with us.</p>
1469                  <ul>
1470                      <li>
1471                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1472                      </li>
1473                      <li>
1474                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1475                      </li>
1476                      <li>
1477                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1478                      </li>
1479                  </ul>
1480                  <h2>In conclusion</h2>
1481                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1482                     as we enjoyed making it. Please contact us if you have ideas
1483                     for improvement or other feedback.</p>
1484              </div>
1485          </div>
1486     </body>
1487 </html>
1488 EOF
1489 }
1490
1491 =head1 INTERNAL METHODS
1492
1493 These methods are not meant to be used by end users.
1494
1495 =head2 $c->components
1496
1497 Returns a hash of components.
1498
1499 =cut
1500
1501 around components => sub {
1502     my $orig  = shift;
1503     my $class = shift;
1504     my $comps = shift;
1505
1506     return $class->$orig if ( !$comps );
1507
1508 # FIXME: should this ugly kludge exist?
1509     $class->setup_config unless defined $class->container;
1510
1511 # FIXME: should there be a warning here, not to use this accessor to create the components?
1512     my $components = {};
1513
1514     my $containers;
1515     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
1516
1517     for my $component ( keys %$comps ) {
1518         $components->{ $component } = $comps->{$component};
1519
1520         my ($type, $name) = _get_component_type_name($component);
1521
1522 # FIXME: shouldn't the service name be $name?
1523         $containers->{$type}->add_service(Catalyst::IOC::BlockInjection->new( name => $name, block => sub { return $class->setup_component($component) } ));
1524     }
1525
1526     return $class->$orig($components);
1527 };
1528
1529 =head2 $c->context_class
1530
1531 Returns or sets the context class.
1532
1533 =head2 $c->counter
1534
1535 Returns a hashref containing coderefs and execution counts (needed for
1536 deep recursion detection).
1537
1538 =head2 $c->depth
1539
1540 Returns the number of actions on the current internal execution stack.
1541
1542 =head2 $c->dispatch
1543
1544 Dispatches a request to actions.
1545
1546 =cut
1547
1548 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1549
1550 =head2 $c->dispatcher_class
1551
1552 Returns or sets the dispatcher class.
1553
1554 =head2 $c->dump_these
1555
1556 Returns a list of 2-element array references (name, structure) pairs
1557 that will be dumped on the error page in debug mode.
1558
1559 =cut
1560
1561 sub dump_these {
1562     my $c = shift;
1563     [ Request => $c->req ],
1564     [ Response => $c->res ],
1565     [ Stash => $c->stash ],
1566     [ Config => $c->config ];
1567 }
1568
1569 =head2 $c->engine_class
1570
1571 Returns or sets the engine class.
1572
1573 =head2 $c->execute( $class, $coderef )
1574
1575 Execute a coderef in given class and catch exceptions. Errors are available
1576 via $c->error.
1577
1578 =cut
1579
1580 sub execute {
1581     my ( $c, $class, $code ) = @_;
1582     $class = $c->component($class) || $class;
1583     $c->state(0);
1584
1585     if ( $c->depth >= $RECURSION ) {
1586         my $action = $code->reverse();
1587         $action = "/$action" unless $action =~ /->/;
1588         my $error = qq/Deep recursion detected calling "${action}"/;
1589         $c->log->error($error);
1590         $c->error($error);
1591         $c->state(0);
1592         return $c->state;
1593     }
1594
1595     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1596
1597     push( @{ $c->stack }, $code );
1598
1599     no warnings 'recursion';
1600     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1601     #      I have no idea how, ergo $ret (which appears to fix the issue)
1602     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1603
1604     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1605
1606     my $last = pop( @{ $c->stack } );
1607
1608     if ( my $error = $@ ) {
1609         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1610             $error->rethrow if $c->depth > 1;
1611         }
1612         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1613             $error->rethrow if $c->depth > 0;
1614         }
1615         else {
1616             unless ( ref $error ) {
1617                 no warnings 'uninitialized';
1618                 chomp $error;
1619                 my $class = $last->class;
1620                 my $name  = $last->name;
1621                 $error = qq/Caught exception in $class->$name "$error"/;
1622             }
1623             $c->error($error);
1624         }
1625         $c->state(0);
1626     }
1627     return $c->state;
1628 }
1629
1630 sub _stats_start_execute {
1631     my ( $c, $code ) = @_;
1632     my $appclass = ref($c) || $c;
1633     return if ( ( $code->name =~ /^_.*/ )
1634         && ( !$appclass->config->{show_internal_actions} ) );
1635
1636     my $action_name = $code->reverse();
1637     $c->counter->{$action_name}++;
1638
1639     my $action = $action_name;
1640     $action = "/$action" unless $action =~ /->/;
1641
1642     # determine if the call was the result of a forward
1643     # this is done by walking up the call stack and looking for a calling
1644     # sub of Catalyst::forward before the eval
1645     my $callsub = q{};
1646     for my $index ( 2 .. 11 ) {
1647         last
1648         if ( ( caller($index) )[0] eq 'Catalyst'
1649             && ( caller($index) )[3] eq '(eval)' );
1650
1651         if ( ( caller($index) )[3] =~ /forward$/ ) {
1652             $callsub = ( caller($index) )[3];
1653             $action  = "-> $action";
1654             last;
1655         }
1656     }
1657
1658     my $uid = $action_name . $c->counter->{$action_name};
1659
1660     # is this a root-level call or a forwarded call?
1661     if ( $callsub =~ /forward$/ ) {
1662         my $parent = $c->stack->[-1];
1663
1664         # forward, locate the caller
1665         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1666             $c->stats->profile(
1667                 begin  => $action,
1668                 parent => "$parent" . $c->counter->{"$parent"},
1669                 uid    => $uid,
1670             );
1671         }
1672         else {
1673
1674             # forward with no caller may come from a plugin
1675             $c->stats->profile(
1676                 begin => $action,
1677                 uid   => $uid,
1678             );
1679         }
1680     }
1681     else {
1682
1683         # root-level call
1684         $c->stats->profile(
1685             begin => $action,
1686             uid   => $uid,
1687         );
1688     }
1689     return $action;
1690
1691 }
1692
1693 sub _stats_finish_execute {
1694     my ( $c, $info ) = @_;
1695     $c->stats->profile( end => $info );
1696 }
1697
1698 =head2 $c->finalize
1699
1700 Finalizes the request.
1701
1702 =cut
1703
1704 sub finalize {
1705     my $c = shift;
1706
1707     for my $error ( @{ $c->error } ) {
1708         $c->log->error($error);
1709     }
1710
1711     # Allow engine to handle finalize flow (for POE)
1712     my $engine = $c->engine;
1713     if ( my $code = $engine->can('finalize') ) {
1714         $engine->$code($c);
1715     }
1716     else {
1717
1718         $c->finalize_uploads;
1719
1720         # Error
1721         if ( $#{ $c->error } >= 0 ) {
1722             $c->finalize_error;
1723         }
1724
1725         $c->finalize_headers;
1726
1727         # HEAD request
1728         if ( $c->request->method eq 'HEAD' ) {
1729             $c->response->body('');
1730         }
1731
1732         $c->finalize_body;
1733     }
1734
1735     $c->log_response;
1736
1737     if ($c->use_stats) {
1738         my $elapsed = sprintf '%f', $c->stats->elapsed;
1739         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1740         $c->log->info(
1741             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1742     }
1743
1744     return $c->response->status;
1745 }
1746
1747 =head2 $c->finalize_body
1748
1749 Finalizes body.
1750
1751 =cut
1752
1753 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1754
1755 =head2 $c->finalize_cookies
1756
1757 Finalizes cookies.
1758
1759 =cut
1760
1761 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1762
1763 =head2 $c->finalize_error
1764
1765 Finalizes error.
1766
1767 =cut
1768
1769 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1770
1771 =head2 $c->finalize_headers
1772
1773 Finalizes headers.
1774
1775 =cut
1776
1777 sub finalize_headers {
1778     my $c = shift;
1779
1780     my $response = $c->response; #accessor calls can add up?
1781
1782     # Check if we already finalized headers
1783     return if $response->finalized_headers;
1784
1785     # Handle redirects
1786     if ( my $location = $response->redirect ) {
1787         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1788         $response->header( Location => $location );
1789
1790         if ( !$response->has_body ) {
1791             # Add a default body if none is already present
1792             $response->body(
1793                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1794             );
1795         }
1796     }
1797
1798     # Content-Length
1799     if ( defined $response->body && length $response->body && !$response->content_length ) {
1800
1801         # get the length from a filehandle
1802         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1803         {
1804             my $stat = stat $response->body;
1805             if ( $stat && $stat->size > 0 ) {
1806                 $response->content_length( $stat->size );
1807             }
1808             else {
1809                 $c->log->warn('Serving filehandle without a content-length');
1810             }
1811         }
1812         else {
1813             # everything should be bytes at this point, but just in case
1814             $response->content_length( length( $response->body ) );
1815         }
1816     }
1817
1818     # Errors
1819     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1820         $response->headers->remove_header("Content-Length");
1821         $response->body('');
1822     }
1823
1824     $c->finalize_cookies;
1825
1826     $c->engine->finalize_headers( $c, @_ );
1827
1828     # Done
1829     $response->finalized_headers(1);
1830 }
1831
1832 =head2 $c->finalize_output
1833
1834 An alias for finalize_body.
1835
1836 =head2 $c->finalize_read
1837
1838 Finalizes the input after reading is complete.
1839
1840 =cut
1841
1842 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1843
1844 =head2 $c->finalize_uploads
1845
1846 Finalizes uploads. Cleans up any temporary files.
1847
1848 =cut
1849
1850 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1851
1852 =head2 $c->get_action( $action, $namespace )
1853
1854 Gets an action in a given namespace.
1855
1856 =cut
1857
1858 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1859
1860 =head2 $c->get_actions( $action, $namespace )
1861
1862 Gets all actions of a given name in a namespace and all parent
1863 namespaces.
1864
1865 =cut
1866
1867 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1868
1869 =head2 $app->handle_request( @arguments )
1870
1871 Called to handle each HTTP request.
1872
1873 =cut
1874
1875 sub handle_request {
1876     my ( $class, @arguments ) = @_;
1877
1878     # Always expect worst case!
1879     my $status = -1;
1880     eval {
1881         if ($class->debug) {
1882             my $secs = time - $START || 1;
1883             my $av = sprintf '%.3f', $COUNT / $secs;
1884             my $time = localtime time;
1885             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1886         }
1887
1888         my $c = $class->prepare(@arguments);
1889         $c->dispatch;
1890         $status = $c->finalize;
1891     };
1892
1893     if ( my $error = $@ ) {
1894         chomp $error;
1895         $class->log->error(qq/Caught exception in engine "$error"/);
1896     }
1897
1898     $COUNT++;
1899
1900     if(my $coderef = $class->log->can('_flush')){
1901         $class->log->$coderef();
1902     }
1903     return $status;
1904 }
1905
1906 =head2 $c->prepare( @arguments )
1907
1908 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1909 etc.).
1910
1911 =cut
1912
1913 sub prepare {
1914     my ( $class, @arguments ) = @_;
1915
1916     # XXX
1917     # After the app/ctxt split, this should become an attribute based on something passed
1918     # into the application.
1919     $class->context_class( ref $class || $class ) unless $class->context_class;
1920
1921     my $c = $class->context_class->new({});
1922
1923     # For on-demand data
1924     $c->request->_context($c);
1925     $c->response->_context($c);
1926
1927     #surely this is not the most efficient way to do things...
1928     $c->stats($class->stats_class->new)->enable($c->use_stats);
1929     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1930         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1931     }
1932
1933     #XXX reuse coderef from can
1934     # Allow engine to direct the prepare flow (for POE)
1935     if ( $c->engine->can('prepare') ) {
1936         $c->engine->prepare( $c, @arguments );
1937     }
1938     else {
1939         $c->prepare_request(@arguments);
1940         $c->prepare_connection;
1941         $c->prepare_query_parameters;
1942         $c->prepare_headers;
1943         $c->prepare_cookies;
1944         $c->prepare_path;
1945
1946         # Prepare the body for reading, either by prepare_body
1947         # or the user, if they are using $c->read
1948         $c->prepare_read;
1949
1950         # Parse the body unless the user wants it on-demand
1951         unless ( ref($c)->config->{parse_on_demand} ) {
1952             $c->prepare_body;
1953         }
1954     }
1955
1956     my $method  = $c->req->method  || '';
1957     my $path    = $c->req->path;
1958     $path       = '/' unless length $path;
1959     my $address = $c->req->address || '';
1960
1961     $c->log_request;
1962
1963     $c->prepare_action;
1964
1965     return $c;
1966 }
1967
1968 =head2 $c->prepare_action
1969
1970 Prepares action. See L<Catalyst::Dispatcher>.
1971
1972 =cut
1973
1974 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1975
1976 =head2 $c->prepare_body
1977
1978 Prepares message body.
1979
1980 =cut
1981
1982 sub prepare_body {
1983     my $c = shift;
1984
1985     return if $c->request->_has_body;
1986
1987     # Initialize on-demand data
1988     $c->engine->prepare_body( $c, @_ );
1989     $c->prepare_parameters;
1990     $c->prepare_uploads;
1991 }
1992
1993 =head2 $c->prepare_body_chunk( $chunk )
1994
1995 Prepares a chunk of data before sending it to L<HTTP::Body>.
1996
1997 See L<Catalyst::Engine>.
1998
1999 =cut
2000
2001 sub prepare_body_chunk {
2002     my $c = shift;
2003     $c->engine->prepare_body_chunk( $c, @_ );
2004 }
2005
2006 =head2 $c->prepare_body_parameters
2007
2008 Prepares body parameters.
2009
2010 =cut
2011
2012 sub prepare_body_parameters {
2013     my $c = shift;
2014     $c->engine->prepare_body_parameters( $c, @_ );
2015 }
2016
2017 =head2 $c->prepare_connection
2018
2019 Prepares connection.
2020
2021 =cut
2022
2023 sub prepare_connection {
2024     my $c = shift;
2025     $c->engine->prepare_connection( $c, @_ );
2026 }
2027
2028 =head2 $c->prepare_cookies
2029
2030 Prepares cookies.
2031
2032 =cut
2033
2034 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2035
2036 =head2 $c->prepare_headers
2037
2038 Prepares headers.
2039
2040 =cut
2041
2042 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2043
2044 =head2 $c->prepare_parameters
2045
2046 Prepares parameters.
2047
2048 =cut
2049
2050 sub prepare_parameters {
2051     my $c = shift;
2052     $c->prepare_body_parameters;
2053     $c->engine->prepare_parameters( $c, @_ );
2054 }
2055
2056 =head2 $c->prepare_path
2057
2058 Prepares path and base.
2059
2060 =cut
2061
2062 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2063
2064 =head2 $c->prepare_query_parameters
2065
2066 Prepares query parameters.
2067
2068 =cut
2069
2070 sub prepare_query_parameters {
2071     my $c = shift;
2072
2073     $c->engine->prepare_query_parameters( $c, @_ );
2074 }
2075
2076 =head2 $c->log_request
2077
2078 Writes information about the request to the debug logs.  This includes:
2079
2080 =over 4
2081
2082 =item * Request method, path, and remote IP address
2083
2084 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2085
2086 =item * Request parameters
2087
2088 =item * File uploads
2089
2090 =back
2091
2092 =cut
2093
2094 sub log_request {
2095     my $c = shift;
2096
2097     return unless $c->debug;
2098
2099     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2100     my $request = $dump->[1];
2101
2102     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2103     $method ||= '';
2104     $path = '/' unless length $path;
2105     $address ||= '';
2106     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2107
2108     $c->log_request_headers($request->headers);
2109
2110     if ( my $keywords = $request->query_keywords ) {
2111         $c->log->debug("Query keywords are: $keywords");
2112     }
2113
2114     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2115
2116     $c->log_request_uploads($request);
2117 }
2118
2119 =head2 $c->log_response
2120
2121 Writes information about the response to the debug logs by calling
2122 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2123
2124 =cut
2125
2126 sub log_response {
2127     my $c = shift;
2128
2129     return unless $c->debug;
2130
2131     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2132     my $response = $dump->[1];
2133
2134     $c->log_response_status_line($response);
2135     $c->log_response_headers($response->headers);
2136 }
2137
2138 =head2 $c->log_response_status_line($response)
2139
2140 Writes one line of information about the response to the debug logs.  This includes:
2141
2142 =over 4
2143
2144 =item * Response status code
2145
2146 =item * Content-Type header (if present)
2147
2148 =item * Content-Length header (if present)
2149
2150 =back
2151
2152 =cut
2153
2154 sub log_response_status_line {
2155     my ($c, $response) = @_;
2156
2157     $c->log->debug(
2158         sprintf(
2159             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2160             $response->status                            || 'unknown',
2161             $response->headers->header('Content-Type')   || 'unknown',
2162             $response->headers->header('Content-Length') || 'unknown'
2163         )
2164     );
2165 }
2166
2167 =head2 $c->log_response_headers($headers);
2168
2169 Hook method which can be wrapped by plugins to log the responseheaders.
2170 No-op in the default implementation.
2171
2172 =cut
2173
2174 sub log_response_headers {}
2175
2176 =head2 $c->log_request_parameters( query => {}, body => {} )
2177
2178 Logs request parameters to debug logs
2179
2180 =cut
2181
2182 sub log_request_parameters {
2183     my $c          = shift;
2184     my %all_params = @_;
2185
2186     return unless $c->debug;
2187
2188     my $column_width = Catalyst::Utils::term_width() - 44;
2189     foreach my $type (qw(query body)) {
2190         my $params = $all_params{$type};
2191         next if ! keys %$params;
2192         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2193         for my $key ( sort keys %$params ) {
2194             my $param = $params->{$key};
2195             my $value = defined($param) ? $param : '';
2196             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2197         }
2198         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2199     }
2200 }
2201
2202 =head2 $c->log_request_uploads
2203
2204 Logs file uploads included in the request to the debug logs.
2205 The parameter name, filename, file type, and file size are all included in
2206 the debug logs.
2207
2208 =cut
2209
2210 sub log_request_uploads {
2211     my $c = shift;
2212     my $request = shift;
2213     return unless $c->debug;
2214     my $uploads = $request->uploads;
2215     if ( keys %$uploads ) {
2216         my $t = Text::SimpleTable->new(
2217             [ 12, 'Parameter' ],
2218             [ 26, 'Filename' ],
2219             [ 18, 'Type' ],
2220             [ 9,  'Size' ]
2221         );
2222         for my $key ( sort keys %$uploads ) {
2223             my $upload = $uploads->{$key};
2224             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2225                 $t->row( $key, $u->filename, $u->type, $u->size );
2226             }
2227         }
2228         $c->log->debug( "File Uploads are:\n" . $t->draw );
2229     }
2230 }
2231
2232 =head2 $c->log_request_headers($headers);
2233
2234 Hook method which can be wrapped by plugins to log the request headers.
2235 No-op in the default implementation.
2236
2237 =cut
2238
2239 sub log_request_headers {}
2240
2241 =head2 $c->log_headers($type => $headers)
2242
2243 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2244
2245 =cut
2246
2247 sub log_headers {
2248     my $c       = shift;
2249     my $type    = shift;
2250     my $headers = shift;    # an HTTP::Headers instance
2251
2252     return unless $c->debug;
2253
2254     my $column_width = Catalyst::Utils::term_width() - 28;
2255     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2256     $headers->scan(
2257         sub {
2258             my ( $name, $value ) = @_;
2259             $t->row( $name, $value );
2260         }
2261     );
2262     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2263 }
2264
2265
2266 =head2 $c->prepare_read
2267
2268 Prepares the input for reading.
2269
2270 =cut
2271
2272 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2273
2274 =head2 $c->prepare_request
2275
2276 Prepares the engine request.
2277
2278 =cut
2279
2280 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2281
2282 =head2 $c->prepare_uploads
2283
2284 Prepares uploads.
2285
2286 =cut
2287
2288 sub prepare_uploads {
2289     my $c = shift;
2290
2291     $c->engine->prepare_uploads( $c, @_ );
2292 }
2293
2294 =head2 $c->prepare_write
2295
2296 Prepares the output for writing.
2297
2298 =cut
2299
2300 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2301
2302 =head2 $c->request_class
2303
2304 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2305
2306 =head2 $c->response_class
2307
2308 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2309
2310 =head2 $c->read( [$maxlength] )
2311
2312 Reads a chunk of data from the request body. This method is designed to
2313 be used in a while loop, reading C<$maxlength> bytes on every call.
2314 C<$maxlength> defaults to the size of the request if not specified.
2315
2316 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2317 directly.
2318
2319 Warning: If you use read(), Catalyst will not process the body,
2320 so you will not be able to access POST parameters or file uploads via
2321 $c->request.  You must handle all body parsing yourself.
2322
2323 =cut
2324
2325 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2326
2327 =head2 $c->run
2328
2329 Starts the engine.
2330
2331 =cut
2332
2333 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2334
2335 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2336
2337 Sets an action in a given namespace.
2338
2339 =cut
2340
2341 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2342
2343 =head2 $c->setup_actions($component)
2344
2345 Sets up actions for a component.
2346
2347 =cut
2348
2349 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2350
2351 =head2 $c->setup_config
2352
2353 =cut
2354
2355 sub setup_config {
2356     my $class = shift;
2357
2358     my %args = %{ $class->config || {} };
2359
2360     my @container_classes = ( "${class}::Container", 'Catalyst::IOC::Container');
2361     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2362
2363     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2364
2365     my $container = $container_class->new( %args,
2366         name                   => "$class",
2367         disable_regex_fallback =>
2368             $class->config->{disable_component_resolution_regex_fallback},
2369     );
2370     $class->container($container);
2371
2372     my $config = $container->resolve(service => 'config');
2373     $class->config($config);
2374     $class->finalize_config; # back-compat
2375 }
2376
2377 =head2 $c->finalize_config
2378
2379 =cut
2380
2381 sub finalize_config { }
2382
2383 =head2 $c->setup_components
2384
2385 This method is called internally to set up the application's components.
2386
2387 It finds modules by calling the L<locate_components> method, expands them to
2388 package names with the L<expand_component_module> method, and then installs
2389 each component into the application.
2390
2391 The C<setup_components> config option is passed to both of the above methods.
2392
2393 Installation of each component is performed by the L<setup_component> method,
2394 below.
2395
2396 =cut
2397
2398 sub setup_components {
2399     my $class = shift;
2400
2401     my $config  = $class->config->{ setup_components };
2402
2403     my @comps = $class->locate_components($config);
2404     my %comps = map { $_ => 1 } @comps;
2405
2406     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2407     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2408         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2409     ) if $deprecatedcatalyst_component_names;
2410
2411     for my $component ( @comps ) {
2412
2413         # We pass ignore_loaded here so that overlay files for (e.g.)
2414         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2415         # we know M::P::O found a file on disk so this is safe
2416
2417         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2418     }
2419
2420     my $containers;
2421     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
2422
2423     for my $component (@comps) {
2424         my $instance = $class->components->{ $component } = $class->setup_component($component);
2425         if ( my ($type, $name) = _get_component_type_name($component) ) {
2426             $containers->{$type}->add_service(Catalyst::IOC::BlockInjection->new( name => $name, block => sub { return $instance } ));
2427         }
2428         my @expanded_components = $instance->can('expand_modules')
2429             ? $instance->expand_modules( $component, $config )
2430             : $class->expand_component_module( $component, $config );
2431         for my $component (@expanded_components) {
2432             next if $comps{$component};
2433
2434             $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @expanded_components;
2435             $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2436                 qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2437             ) if $deprecatedcatalyst_component_names;
2438
2439             if (my ($type, $name) = _get_component_type_name($component)) {
2440                 $containers->{$type}->add_service(Catalyst::IOC::BlockInjection->new( name => $name, block => sub { return $class->setup_component($component) } ));
2441             }
2442
2443             $class->components->{ $component } = $class->setup_component($component);
2444         }
2445     }
2446 }
2447
2448 sub _get_component_type_name {
2449     my $component = shift;
2450     my @parts     = split /::/, $component;
2451
2452     while (my $type = shift @parts) {
2453         return ('controller', join '::', @parts)
2454             if $type =~ /^(c|controller)$/i;
2455
2456         return ('model', join '::', @parts)
2457             if $type =~ /^(m|model)$/i;
2458
2459         return ('view', join '::', @parts)
2460             if $type =~ /^(v|view)$/i;
2461     }
2462 }
2463
2464 =head2 $c->locate_components( $setup_component_config )
2465
2466 This method is meant to provide a list of component modules that should be
2467 setup for the application.  By default, it will use L<Module::Pluggable>.
2468
2469 Specify a C<setup_components> config option to pass additional options directly
2470 to L<Module::Pluggable>. To add additional search paths, specify a key named
2471 C<search_extra> as an array reference. Items in the array beginning with C<::>
2472 will have the application class name prepended to them.
2473
2474 =cut
2475
2476 sub locate_components {
2477     my $class  = shift;
2478     my $config = shift;
2479
2480     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2481     my $extra   = delete $config->{ search_extra } || [];
2482
2483     push @paths, @$extra;
2484
2485     my $locator = Module::Pluggable::Object->new(
2486         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2487         %$config
2488     );
2489
2490     # XXX think about ditching this sort entirely
2491     my @comps = sort { length $a <=> length $b } $locator->plugins;
2492
2493     return @comps;
2494 }
2495
2496 =head2 $c->expand_component_module( $component, $setup_component_config )
2497
2498 Components found by C<locate_components> will be passed to this method, which
2499 is expected to return a list of component (package) names to be set up.
2500
2501 =cut
2502
2503 sub expand_component_module {
2504     my ($class, $module) = @_;
2505     return Devel::InnerPackage::list_packages( $module );
2506 }
2507
2508 =head2 $c->setup_component
2509
2510 =cut
2511
2512 sub setup_component {
2513     my( $class, $component ) = @_;
2514
2515     unless ( $component->can( 'COMPONENT' ) ) {
2516         return $component;
2517     }
2518
2519     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2520     my $config = $class->config->{ $suffix } || {};
2521     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2522     # methods also pass it. local to avoid pointlessly shitting in config
2523     # for the debug screen, as $component is already the key name.
2524     local $config->{catalyst_component_name} = $component;
2525
2526     my $instance = eval { $component->COMPONENT( $class, $config ); };
2527
2528     if ( my $error = $@ ) {
2529         chomp $error;
2530         Catalyst::Exception->throw(
2531             message => qq/Couldn't instantiate component "$component", "$error"/
2532         );
2533     }
2534     elsif (!blessed $instance) {
2535         my $metaclass = Moose::Util::find_meta($component);
2536         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2537         my $component_method_from = $method_meta->associated_metaclass->name;
2538         my $value = defined($instance) ? $instance : 'undef';
2539         Catalyst::Exception->throw(
2540             message =>
2541             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2542         );
2543     }
2544
2545     return $instance;
2546 }
2547
2548 =head2 $c->setup_dispatcher
2549
2550 Sets up dispatcher.
2551
2552 =cut
2553
2554 sub setup_dispatcher {
2555     my ( $class, $dispatcher ) = @_;
2556
2557     if ($dispatcher) {
2558         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2559     }
2560
2561     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2562         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2563     }
2564
2565     unless ($dispatcher) {
2566         $dispatcher = $class->dispatcher_class;
2567     }
2568
2569     Class::MOP::load_class($dispatcher);
2570
2571     # dispatcher instance
2572     $class->dispatcher( $dispatcher->new );
2573 }
2574
2575 =head2 $c->setup_engine
2576
2577 Sets up engine.
2578
2579 =cut
2580
2581 sub setup_engine {
2582     my ( $class, $engine ) = @_;
2583
2584     if ($engine) {
2585         $engine = 'Catalyst::Engine::' . $engine;
2586     }
2587
2588     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2589         $engine = 'Catalyst::Engine::' . $env;
2590     }
2591
2592     if ( $ENV{MOD_PERL} ) {
2593         my $meta = Class::MOP::get_metaclass_by_name($class);
2594
2595         # create the apache method
2596         $meta->add_method('apache' => sub { shift->engine->apache });
2597
2598         my ( $software, $version ) =
2599           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2600
2601         $version =~ s/_//g;
2602         $version =~ s/(\.[^.]+)\./$1/g;
2603
2604         if ( $software eq 'mod_perl' ) {
2605
2606             if ( !$engine ) {
2607
2608                 if ( $version >= 1.99922 ) {
2609                     $engine = 'Catalyst::Engine::Apache2::MP20';
2610                 }
2611
2612                 elsif ( $version >= 1.9901 ) {
2613                     $engine = 'Catalyst::Engine::Apache2::MP19';
2614                 }
2615
2616                 elsif ( $version >= 1.24 ) {
2617                     $engine = 'Catalyst::Engine::Apache::MP13';
2618                 }
2619
2620                 else {
2621                     Catalyst::Exception->throw( message =>
2622                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2623                 }
2624
2625             }
2626
2627             # install the correct mod_perl handler
2628             if ( $version >= 1.9901 ) {
2629                 *handler = sub  : method {
2630                     shift->handle_request(@_);
2631                 };
2632             }
2633             else {
2634                 *handler = sub ($$) { shift->handle_request(@_) };
2635             }
2636
2637         }
2638
2639         elsif ( $software eq 'Zeus-Perl' ) {
2640             $engine = 'Catalyst::Engine::Zeus';
2641         }
2642
2643         else {
2644             Catalyst::Exception->throw(
2645                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2646         }
2647     }
2648
2649     unless ($engine) {
2650         $engine = $class->engine_class;
2651     }
2652
2653     Class::MOP::load_class($engine);
2654
2655     # check for old engines that are no longer compatible
2656     my $old_engine;
2657     if ( $engine->isa('Catalyst::Engine::Apache')
2658         && !Catalyst::Engine::Apache->VERSION )
2659     {
2660         $old_engine = 1;
2661     }
2662
2663     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2664         && Catalyst::Engine::Server->VERSION le '0.02' )
2665     {
2666         $old_engine = 1;
2667     }
2668
2669     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2670         && $engine->VERSION eq '0.01' )
2671     {
2672         $old_engine = 1;
2673     }
2674
2675     elsif ($engine->isa('Catalyst::Engine::Zeus')
2676         && $engine->VERSION eq '0.01' )
2677     {
2678         $old_engine = 1;
2679     }
2680
2681     if ($old_engine) {
2682         Catalyst::Exception->throw( message =>
2683               qq/Engine "$engine" is not supported by this version of Catalyst/
2684         );
2685     }
2686
2687     # engine instance
2688     $class->engine( $engine->new );
2689 }
2690
2691 =head2 $c->setup_home
2692
2693 Sets up the home directory.
2694
2695 =cut
2696
2697 sub setup_home {
2698     my ( $class, $home ) = @_;
2699
2700     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2701         $home = $env;
2702     }
2703
2704     $home ||= Catalyst::Utils::home($class);
2705
2706     if ($home) {
2707         #I remember recently being scolded for assigning config values like this
2708         $class->config->{home} ||= $home;
2709         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2710     }
2711 }
2712
2713 =head2 $c->setup_log
2714
2715 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2716 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2717 log to.
2718
2719 This method also installs a C<debug> method that returns a true value into the
2720 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2721 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2722
2723 Note that if the log has already been setup, by either a previous call to
2724 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2725 that this method won't actually set up the log object.
2726
2727 =cut
2728
2729 sub setup_log {
2730     my ( $class, $levels ) = @_;
2731
2732     $levels ||= '';
2733     $levels =~ s/^\s+//;
2734     $levels =~ s/\s+$//;
2735     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2736
2737     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2738     if ( defined $env_debug ) {
2739         $levels{debug} = 1 if $env_debug; # Ugly!
2740         delete($levels{debug}) unless $env_debug;
2741     }
2742
2743     unless ( $class->log ) {
2744         $class->log( Catalyst::Log->new(keys %levels) );
2745     }
2746
2747     if ( $levels{debug} ) {
2748         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2749         $class->log->debug('Debug messages enabled');
2750     }
2751 }
2752
2753 =head2 $c->setup_plugins
2754
2755 Sets up plugins.
2756
2757 =cut
2758
2759 =head2 $c->setup_stats
2760
2761 Sets up timing statistics class.
2762
2763 =cut
2764
2765 sub setup_stats {
2766     my ( $class, $stats ) = @_;
2767
2768     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2769
2770     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2771     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2772         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2773         $class->log->debug('Statistics enabled');
2774     }
2775 }
2776
2777
2778 =head2 $c->registered_plugins
2779
2780 Returns a sorted list of the plugins which have either been stated in the
2781 import list or which have been added via C<< MyApp->plugin(@args); >>.
2782
2783 If passed a given plugin name, it will report a boolean value indicating
2784 whether or not that plugin is loaded.  A fully qualified name is required if
2785 the plugin name does not begin with C<Catalyst::Plugin::>.
2786
2787  if ($c->registered_plugins('Some::Plugin')) {
2788      ...
2789  }
2790
2791 =cut
2792
2793 {
2794
2795     sub registered_plugins {
2796         my $proto = shift;
2797         return sort keys %{ $proto->_plugins } unless @_;
2798         my $plugin = shift;
2799         return 1 if exists $proto->_plugins->{$plugin};
2800         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2801     }
2802
2803     sub _register_plugin {
2804         my ( $proto, $plugin, $instant ) = @_;
2805         my $class = ref $proto || $proto;
2806
2807         Class::MOP::load_class( $plugin );
2808         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2809             if $plugin->isa( 'Catalyst::Component' );
2810         $proto->_plugins->{$plugin} = 1;
2811         unless ($instant) {
2812             my $meta = Class::MOP::get_metaclass_by_name($class);
2813             $meta->superclasses($plugin, $meta->superclasses);
2814         }
2815         return $class;
2816     }
2817
2818     sub setup_plugins {
2819         my ( $class, $plugins ) = @_;
2820
2821         $class->_plugins( {} ) unless $class->_plugins;
2822         $plugins = Data::OptList::mkopt($plugins || []);
2823
2824         my @plugins = map {
2825             [ Catalyst::Utils::resolve_namespace(
2826                   $class . '::Plugin',
2827                   'Catalyst::Plugin', $_->[0]
2828               ),
2829               $_->[1],
2830             ]
2831          } @{ $plugins };
2832
2833         for my $plugin ( reverse @plugins ) {
2834             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2835             my $meta = find_meta($plugin->[0]);
2836             next if $meta && $meta->isa('Moose::Meta::Role');
2837
2838             $class->_register_plugin($plugin->[0]);
2839         }
2840
2841         my @roles =
2842             map  { $_->[0]->name, $_->[1] }
2843             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2844             map  { [find_meta($_->[0]), $_->[1]] }
2845             @plugins;
2846
2847         Moose::Util::apply_all_roles(
2848             $class => @roles
2849         ) if @roles;
2850     }
2851 }
2852
2853 =head2 $c->stack
2854
2855 Returns an arrayref of the internal execution stack (actions that are
2856 currently executing).
2857
2858 =head2 $c->stats
2859
2860 Returns the current timing statistics object. By default Catalyst uses
2861 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2862 L<< stats_class|/"$c->stats_class" >>.
2863
2864 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2865 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2866 profile explicitly, although MyApp.pm still won't profile nor output anything
2867 by itself.
2868
2869 =head2 $c->stats_class
2870
2871 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2872
2873 =head2 $c->use_stats
2874
2875 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2876
2877 Note that this is a static method, not an accessor and should be overridden
2878 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2879
2880 =cut
2881
2882 sub use_stats { 0 }
2883
2884
2885 =head2 $c->write( $data )
2886
2887 Writes $data to the output stream. When using this method directly, you
2888 will need to manually set the C<Content-Length> header to the length of
2889 your output data, if known.
2890
2891 =cut
2892
2893 sub write {
2894     my $c = shift;
2895
2896     # Finalize headers if someone manually writes output
2897     $c->finalize_headers;
2898
2899     return $c->engine->write( $c, @_ );
2900 }
2901
2902 =head2 version
2903
2904 Returns the Catalyst version number. Mostly useful for "powered by"
2905 messages in template systems.
2906
2907 =cut
2908
2909 sub version { return $Catalyst::VERSION }
2910
2911 =head1 CONFIGURATION
2912
2913 There are a number of 'base' config variables which can be set:
2914
2915 =over
2916
2917 =item *
2918
2919 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2920
2921 =item *
2922
2923 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2924
2925 =item *
2926
2927 C<disable_component_resolution_regex_fallback> - Turns
2928 off the deprecated component resolution functionality so
2929 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2930 are called then regex search will not be attempted on string values and
2931 instead C<undef> will be returned.
2932
2933 =item *
2934
2935 C<home> - The application home directory. In an uninstalled application,
2936 this is the top level application directory. In an installed application,
2937 this will be the directory containing C<< MyApp.pm >>.
2938
2939 =item *
2940
2941 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2942
2943 =item *
2944
2945 C<name> - The name of the application in debug messages and the debug and
2946 welcome screens
2947
2948 =item *
2949
2950 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2951 until it is accessed. This allows you to (for example) check authentication (and reject
2952 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2953
2954 =item *
2955
2956 C<root> - The root directory for templates. Usually this is just a
2957 subdirectory of the home directory, but you can set it to change the
2958 templates to a different directory.
2959
2960 =item *
2961
2962 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2963 namespaces from which components will be loaded (and constructed and stored in
2964 C<< $c->components >>).
2965
2966 =item *
2967
2968 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2969 to be shown in hit debug tables in the test server.
2970
2971 =item *
2972
2973 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
2974 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
2975 for more information.
2976
2977 =item *
2978
2979 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2980
2981 =back
2982
2983 =head1 INTERNAL ACTIONS
2984
2985 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2986 C<_ACTION>, and C<_END>. These are by default not shown in the private
2987 action table, but you can make them visible with a config parameter.
2988
2989     MyApp->config(show_internal_actions => 1);
2990
2991 =head1 ON-DEMAND PARSER
2992
2993 The request body is usually parsed at the beginning of a request,
2994 but if you want to handle input yourself, you can enable on-demand
2995 parsing with a config parameter.
2996
2997     MyApp->config(parse_on_demand => 1);
2998
2999 =head1 PROXY SUPPORT
3000
3001 Many production servers operate using the common double-server approach,
3002 with a lightweight frontend web server passing requests to a larger
3003 backend server. An application running on the backend server must deal
3004 with two problems: the remote user always appears to be C<127.0.0.1> and
3005 the server's hostname will appear to be C<localhost> regardless of the
3006 virtual host that the user connected through.
3007
3008 Catalyst will automatically detect this situation when you are running
3009 the frontend and backend servers on the same machine. The following
3010 changes are made to the request.
3011
3012     $c->req->address is set to the user's real IP address, as read from
3013     the HTTP X-Forwarded-For header.
3014
3015     The host value for $c->req->base and $c->req->uri is set to the real
3016     host, as read from the HTTP X-Forwarded-Host header.
3017
3018 Additionally, you may be running your backend application on an insecure
3019 connection (port 80) while your frontend proxy is running under SSL.  If there
3020 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3021 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3022 be created properly.
3023
3024 In the case of passing in:
3025
3026     X-Forwarded-Port: 443
3027
3028 All calls to C<uri_for> will result in an https link, as is expected.
3029
3030 Obviously, your web server must support these headers for this to work.
3031
3032 In a more complex server farm environment where you may have your
3033 frontend proxy server(s) on different machines, you will need to set a
3034 configuration option to tell Catalyst to read the proxied data from the
3035 headers.
3036
3037     MyApp->config(using_frontend_proxy => 1);
3038
3039 If you do not wish to use the proxy support at all, you may set:
3040
3041     MyApp->config(ignore_frontend_proxy => 1);
3042
3043 =head1 THREAD SAFETY
3044
3045 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3046 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3047 believe the Catalyst core to be thread-safe.
3048
3049 If you plan to operate in a threaded environment, remember that all other
3050 modules you are using must also be thread-safe. Some modules, most notably
3051 L<DBD::SQLite>, are not thread-safe.
3052
3053 =head1 SUPPORT
3054
3055 IRC:
3056
3057     Join #catalyst on irc.perl.org.
3058
3059 Mailing Lists:
3060
3061     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3062     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3063
3064 Web:
3065
3066     http://catalyst.perl.org
3067
3068 Wiki:
3069
3070     http://dev.catalyst.perl.org
3071
3072 =head1 SEE ALSO
3073
3074 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3075
3076 =head2 L<Catalyst::Manual> - The Catalyst Manual
3077
3078 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3079
3080 =head2 L<Catalyst::Engine> - Core engine
3081
3082 =head2 L<Catalyst::Log> - Log class.
3083
3084 =head2 L<Catalyst::Request> - Request object
3085
3086 =head2 L<Catalyst::Response> - Response object
3087
3088 =head2 L<Catalyst::Test> - The test suite.
3089
3090 =head1 PROJECT FOUNDER
3091
3092 sri: Sebastian Riedel <sri@cpan.org>
3093
3094 =head1 CONTRIBUTORS
3095
3096 abw: Andy Wardley
3097
3098 acme: Leon Brocard <leon@astray.com>
3099
3100 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3101
3102 Andrew Bramble
3103
3104 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3105
3106 Andrew Ruthven
3107
3108 André Walker
3109
3110 andyg: Andy Grundman <andy@hybridized.org>
3111
3112 audreyt: Audrey Tang
3113
3114 bricas: Brian Cassidy <bricas@cpan.org>
3115
3116 Caelum: Rafael Kitover <rkitover@io.com>
3117
3118 chansen: Christian Hansen
3119
3120 chicks: Christopher Hicks
3121
3122 Chisel Wright C<pause@herlpacker.co.uk>
3123
3124 Danijel Milicevic C<me@danijel.de>
3125
3126 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3127
3128 David Naughton, C<naughton@umn.edu>
3129
3130 David E. Wheeler
3131
3132 dhoss: Devin Austin <dhoss@cpan.org>
3133
3134 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3135
3136 Drew Taylor
3137
3138 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3139
3140 esskar: Sascha Kiefer
3141
3142 fireartist: Carl Franks <cfranks@cpan.org>
3143
3144 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3145
3146 gabb: Danijel Milicevic
3147
3148 Gary Ashton Jones
3149
3150 Gavin Henry C<ghenry@perl.me.uk>
3151
3152 Geoff Richards
3153
3154 groditi: Guillermo Roditi <groditi@gmail.com>
3155
3156 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3157
3158 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3159
3160 jcamacho: Juan Camacho
3161
3162 jester: Jesse Sheidlower C<jester@panix.com>
3163
3164 jhannah: Jay Hannah <jay@jays.net>
3165
3166 Jody Belka
3167
3168 Johan Lindstrom
3169
3170 jon: Jon Schutz <jjschutz@cpan.org>
3171
3172 Jonathan Rockway C<< <jrockway@cpan.org> >>
3173
3174 Kieren Diment C<kd@totaldatasolution.com>
3175
3176 konobi: Scott McWhirter <konobi@cpan.org>
3177
3178 marcus: Marcus Ramberg <mramberg@cpan.org>
3179
3180 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3181
3182 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3183
3184 mugwump: Sam Vilain
3185
3186 naughton: David Naughton
3187
3188 ningu: David Kamholz <dkamholz@cpan.org>
3189
3190 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3191
3192 numa: Dan Sully <daniel@cpan.org>
3193
3194 obra: Jesse Vincent
3195
3196 Octavian Rasnita
3197
3198 omega: Andreas Marienborg
3199
3200 Oleg Kostyuk <cub.uanic@gmail.com>
3201
3202 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3203
3204 rafl: Florian Ragwitz <rafl@debian.org>
3205
3206 random: Roland Lammel <lammel@cpan.org>
3207
3208 Robert Sedlacek C<< <rs@474.at> >>
3209
3210 SpiceMan: Marcel Montes
3211
3212 sky: Arthur Bergman
3213
3214 szbalint: Balint Szilakszi <szbalint@cpan.org>
3215
3216 t0m: Tomas Doran <bobtfish@bobtfish.net>
3217
3218 Ulf Edvinsson
3219
3220 Viljo Marrandi C<vilts@yahoo.com>
3221
3222 Will Hawes C<info@whawes.co.uk>
3223
3224 willert: Sebastian Willert <willert@cpan.org>
3225
3226 wreis: Wallace Reis <wallace@reis.org.br>
3227
3228 Yuval Kogman, C<nothingmuch@woobling.org>
3229
3230 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3231
3232 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3233
3234 =head1 COPYRIGHT
3235
3236 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3237
3238 =head1 LICENSE
3239
3240 This library is free software. You can redistribute it and/or modify it under
3241 the same terms as Perl itself.
3242
3243 =cut
3244
3245 no Moose;
3246
3247 __PACKAGE__->meta->make_immutable;
3248
3249 1;