lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         $self->request_class->new($self->_build_request_constructor_args);
  67     },
  68     lazy => 1,
  69 );
  70 sub _build_request_constructor_args {
  71     my $self = shift;
  72     my %p = ( _log => $self->log );
  73     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  74     $p{data_handlers} = {$self->registered_data_handlers};
  75     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  76       if $self->config->{use_hash_multivalue_in_request};
  77     \%p;
  78 }
  79
  80 has response => (
  81     is => 'rw',
  82     default => sub {
  83         my $self = shift;
  84         $self->response_class->new($self->_build_response_constructor_args);
  85     },
  86     lazy => 1,
  87 );
  88 sub _build_response_constructor_args {
  89     return +{
  90       _log => $_[0]->log,
  91       encoding => $_[0]->encoding,
  92     };
  93 }
  94
  95 has namespace => (is => 'rw');
  96
  97 sub depth { scalar @{ shift->stack || [] }; }
  98 sub comp { shift->component(@_) }
  99
 100 sub req {
 101     my $self = shift; return $self->request(@_);
 102 }
 103 sub res {
 104     my $self = shift; return $self->response(@_);
 105 }
 106
 107 # For backwards compatibility
 108 sub finalize_output { shift->finalize_body(@_) };
 109
 110 # For statistics
 111 our $COUNT     = 1;
 112 our $START     = time;
 113 our $RECURSION = 1000;
 114 our $DETACH    = Catalyst::Exception::Detach->new;
 115 our $GO        = Catalyst::Exception::Go->new;
 116
 117 #I imagine that very few of these really need to be class variables. if any.
 118 #maybe we should just make them attributes with a default?
 119 __PACKAGE__->mk_classdata($_)
 120   for qw/components arguments dispatcher engine log dispatcher_class
 121   engine_loader context_class request_class response_class stats_class
 122   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 123   _data_handlers _encoding _encode_check finalized_default_middleware/;
 124
 125 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 126 __PACKAGE__->request_class('Catalyst::Request');
 127 __PACKAGE__->response_class('Catalyst::Response');
 128 __PACKAGE__->stats_class('Catalyst::Stats');
 129 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 130
 131 # Remember to update this in Catalyst::Runtime as well!
 132 our $VERSION = '5.90089_001';
 133 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 134
 135 sub import {
 136     my ( $class, @arguments ) = @_;
 137
 138     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 139     # callers @ISA.
 140     return unless $class eq 'Catalyst';
 141
 142     my $caller = caller();
 143     return if $caller eq 'main';
 144
 145     my $meta = Moose::Meta::Class->initialize($caller);
 146     unless ( $caller->isa('Catalyst') ) {
 147         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 148         $meta->superclasses(@superclasses);
 149     }
 150     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 151     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 152
 153     unless( $meta->has_method('meta') ){
 154         if ($Moose::VERSION >= 1.15) {
 155             $meta->_add_meta_method('meta');
 156         }
 157         else {
 158             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 159         }
 160     }
 161
 162     $caller->arguments( [@arguments] );
 163     $caller->setup_home;
 164 }
 165
 166 sub _application { $_[0] }
 167
 168 =encoding UTF-8
 169
 170 =head1 NAME
 171
 172 Catalyst - The Elegant MVC Web Application Framework
 173
 174 =head1 SYNOPSIS
 175
 176 See the L<Catalyst::Manual> distribution for comprehensive
 177 documentation and tutorials.
 178
 179     # Install Catalyst::Devel for helpers and other development tools
 180     # use the helper to create a new application
 181     catalyst.pl MyApp
 182
 183     # add models, views, controllers
 184     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 185     script/myapp_create.pl view MyTemplate TT
 186     script/myapp_create.pl controller Search
 187
 188     # built in testserver -- use -r to restart automatically on changes
 189     # --help to see all available options
 190     script/myapp_server.pl
 191
 192     # command line testing interface
 193     script/myapp_test.pl /yada
 194
 195     ### in lib/MyApp.pm
 196     use Catalyst qw/-Debug/; # include plugins here as well
 197
 198     ### In lib/MyApp/Controller/Root.pm (autocreated)
 199     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 200         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 201         $c->stash->{template} = 'foo.tt'; # set the template
 202         # lookup something from db -- stash vars are passed to TT
 203         $c->stash->{data} =
 204           $c->model('Database::Foo')->search( { country => $args[0] } );
 205         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 206             $c->forward( 'bar' ); # process another action
 207             # do something else after forward returns
 208         }
 209     }
 210
 211     # The foo.tt TT template can use the stash data from the database
 212     [% WHILE (item = data.next) %]
 213         [% item.foo %]
 214     [% END %]
 215
 216     # called for /bar/of/soap, /bar/of/soap/10, etc.
 217     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 218
 219     # called after all actions are finished
 220     sub end : Action {
 221         my ( $self, $c ) = @_;
 222         if ( scalar @{ $c->error } ) { ... } # handle errors
 223         return if $c->res->body; # already have a response
 224         $c->forward( 'MyApp::View::TT' ); # render template
 225     }
 226
 227 See L<Catalyst::Manual::Intro> for additional information.
 228
 229 =head1 DESCRIPTION
 230
 231 Catalyst is a modern framework for making web applications without the
 232 pain usually associated with this process. This document is a reference
 233 to the main Catalyst application. If you are a new user, we suggest you
 234 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 235
 236 See L<Catalyst::Manual> for more documentation.
 237
 238 Catalyst plugins can be loaded by naming them as arguments to the "use
 239 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 240 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 241 C<My::Module>.
 242
 243     use Catalyst qw/My::Module/;
 244
 245 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 246 fully qualify the name by using a unary plus:
 247
 248     use Catalyst qw/
 249         My::Module
 250         +Fully::Qualified::Plugin::Name
 251     /;
 252
 253 Special flags like C<-Debug> can also be specified as
 254 arguments when Catalyst is loaded:
 255
 256     use Catalyst qw/-Debug My::Module/;
 257
 258 The position of plugins and flags in the chain is important, because
 259 they are loaded in the order in which they appear.
 260
 261 The following flags are supported:
 262
 263 =head2 -Debug
 264
 265 Enables debug output. You can also force this setting from the system
 266 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 267 settings override the application, with <MYAPP>_DEBUG having the highest
 268 priority.
 269
 270 This sets the log level to 'debug' and enables full debug output on the
 271 error screen. If you only want the latter, see L<< $c->debug >>.
 272
 273 =head2 -Home
 274
 275 Forces Catalyst to use a specific home directory, e.g.:
 276
 277     use Catalyst qw[-Home=/usr/mst];
 278
 279 This can also be done in the shell environment by setting either the
 280 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 281 is replaced with the uppercased name of your application, any "::" in
 282 the name will be replaced with underscores, e.g. MyApp::Web should use
 283 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 284
 285 If none of these are set, Catalyst will attempt to automatically detect the
 286 home directory. If you are working in a development environment, Catalyst
 287 will try and find the directory containing either Makefile.PL, Build.PL,
 288 dist.ini, or cpanfile. If the application has been installed into the system
 289 (i.e. you have done C<make install>), then Catalyst will use the path to your
 290 application module, without the .pm extension (e.g., /foo/MyApp if your
 291 application was installed at /foo/MyApp.pm)
 292
 293 =head2 -Log
 294
 295     use Catalyst '-Log=warn,fatal,error';
 296
 297 Specifies a comma-delimited list of log levels.
 298
 299 =head2 -Stats
 300
 301 Enables statistics collection and reporting.
 302
 303    use Catalyst qw/-Stats=1/;
 304
 305 You can also force this setting from the system environment with CATALYST_STATS
 306 or <MYAPP>_STATS. The environment settings override the application, with
 307 <MYAPP>_STATS having the highest priority.
 308
 309 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 310
 311 =head1 METHODS
 312
 313 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 314
 315 =head2 $c->action
 316
 317 Returns a L<Catalyst::Action> object for the current action, which
 318 stringifies to the action name. See L<Catalyst::Action>.
 319
 320 =head2 $c->namespace
 321
 322 Returns the namespace of the current action, i.e., the URI prefix
 323 corresponding to the controller of the current action. For example:
 324
 325     # in Controller::Foo::Bar
 326     $c->namespace; # returns 'foo/bar';
 327
 328 =head2 $c->request
 329
 330 =head2 $c->req
 331
 332 Returns the current L<Catalyst::Request> object, giving access to
 333 information about the current client request (including parameters,
 334 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 335
 336 =head2 REQUEST FLOW HANDLING
 337
 338 =head2 $c->forward( $action [, \@arguments ] )
 339
 340 =head2 $c->forward( $class, $method, [, \@arguments ] )
 341
 342 This is one way of calling another action (method) in the same or
 343 a different controller. You can also use C<< $self->my_method($c, @args) >>
 344 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 345 in a different controller.
 346 The main difference is that 'forward' uses some of the Catalyst request
 347 cycle overhead, including debugging, which may be useful to you. On the
 348 other hand, there are some complications to using 'forward', restrictions
 349 on values returned from 'forward', and it may not handle errors as you prefer.
 350 Whether you use 'forward' or not is up to you; it is not considered superior to
 351 the other ways to call a method.
 352
 353 'forward' calls  another action, by its private name. If you give a
 354 class name but no method, C<process()> is called. You may also optionally
 355 pass arguments in an arrayref. The action will receive the arguments in
 356 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 357 C<< $c->req->args >> will be restored to the previous values.
 358
 359 Any data C<return>ed from the action forwarded to, will be returned by the
 360 call to forward.
 361
 362     my $foodata = $c->forward('/foo');
 363     $c->forward('index');
 364     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 365     $c->forward('View::TT');
 366
 367 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 368 an C<< eval { } >> around the call (actually
 369 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 370 exceptions thrown by the called action non-fatal and pushing them onto
 371 $c->error instead. If you want C<die> to propagate you need to do something
 372 like:
 373
 374     $c->forward('foo');
 375     die join "\n", @{ $c->error } if @{ $c->error };
 376
 377 Or make sure to always return true values from your actions and write
 378 your code like this:
 379
 380     $c->forward('foo') || return;
 381
 382 Another note is that C<< $c->forward >> always returns a scalar because it
 383 actually returns $c->state which operates in a scalar context.
 384 Thus, something like:
 385
 386     return @array;
 387
 388 in an action that is forwarded to is going to return a scalar,
 389 i.e. how many items are in that array, which is probably not what you want.
 390 If you need to return an array then return a reference to it,
 391 or stash it like so:
 392
 393     $c->stash->{array} = \@array;
 394
 395 and access it from the stash.
 396
 397 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 398
 399 =cut
 400
 401 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 402
 403 =head2 $c->detach( $action [, \@arguments ] )
 404
 405 =head2 $c->detach( $class, $method, [, \@arguments ] )
 406
 407 =head2 $c->detach()
 408
 409 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 410 doesn't return to the previous action when processing is finished.
 411
 412 When called with no arguments it escapes the processing chain entirely.
 413
 414 =cut
 415
 416 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 417
 418 =head2 $c->visit( $action [, \@arguments ] )
 419
 420 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 421
 422 =head2 $c->visit( $class, $method, [, \@arguments ] )
 423
 424 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 425
 426 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 427 but does a full dispatch, instead of just calling the new C<$action> /
 428 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 429 you go to are called, just like a new request.
 430
 431 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 432 This means, for example, that C<< $c->action >> methods such as
 433 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 434 L<reverse|Catalyst::Action/reverse> return information for the visited action
 435 when they are invoked within the visited action.  This is different from the
 436 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 437 continues to use the $c->action object from the caller action even when
 438 invoked from the called action.
 439
 440 C<< $c->stash >> is kept unchanged.
 441
 442 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 443 allows you to "wrap" another action, just as it would have been called by
 444 dispatching from a URL, while the analogous
 445 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 446 transfer control to another action as if it had been reached directly from a URL.
 447
 448 =cut
 449
 450 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 451
 452 =head2 $c->go( $action [, \@arguments ] )
 453
 454 =head2 $c->go( $action [, \@captures, \@arguments ] )
 455
 456 =head2 $c->go( $class, $method, [, \@arguments ] )
 457
 458 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 459
 460 The relationship between C<go> and
 461 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 462 the relationship between
 463 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 464 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 465 C<< $c->go >> will perform a full dispatch on the specified action or method,
 466 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 467 C<go> escapes the processing of the current request chain on completion, and
 468 does not return to its caller.
 469
 470 @arguments are arguments to the final destination of $action. @captures are
 471 arguments to the intermediate steps, if any, on the way to the final sub of
 472 $action.
 473
 474 =cut
 475
 476 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 477
 478 =head2 $c->response
 479
 480 =head2 $c->res
 481
 482 Returns the current L<Catalyst::Response> object, see there for details.
 483
 484 =head2 $c->stash
 485
 486 Returns a hashref to the stash, which may be used to store data and pass
 487 it between components during a request. You can also set hash keys by
 488 passing arguments. The stash is automatically sent to the view. The
 489 stash is cleared at the end of a request; it cannot be used for
 490 persistent storage (for this you must use a session; see
 491 L<Catalyst::Plugin::Session> for a complete system integrated with
 492 Catalyst).
 493
 494     $c->stash->{foo} = $bar;
 495     $c->stash( { moose => 'majestic', qux => 0 } );
 496     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 497
 498     # stash is automatically passed to the view for use in a template
 499     $c->forward( 'MyApp::View::TT' );
 500
 501 The stash hash is currently stored in the PSGI C<$env> and is managed by
 502 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 503 the stash can be accessed in sub applications mounted under your main
 504 L<Catalyst> application.  For example if you delegate the response of an
 505 action to another L<Catalyst> application, that sub application will have
 506 access to all the stash keys of the main one, and if can of course add
 507 more keys of its own.  However those new keys will not 'bubble' back up
 508 to the main application.
 509
 510 For more information the best thing to do is to review the test case:
 511 t/middleware-stash.t in the distribution /t directory.
 512
 513 =cut
 514
 515 sub stash {
 516   my $c = shift;
 517   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 518 }
 519
 520 =head2 $c->error
 521
 522 =head2 $c->error($error, ...)
 523
 524 =head2 $c->error($arrayref)
 525
 526 Returns an arrayref containing error messages.  If Catalyst encounters an
 527 error while processing a request, it stores the error in $c->error.  This
 528 method should only be used to store fatal error messages.
 529
 530     my @error = @{ $c->error };
 531
 532 Add a new error.
 533
 534     $c->error('Something bad happened');
 535
 536 Calling this will always return an arrayref (if there are no errors it
 537 will be an empty arrayref.
 538
 539 =cut
 540
 541 sub error {
 542     my $c = shift;
 543     if ( $_[0] ) {
 544         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 545         croak @$error unless ref $c;
 546         push @{ $c->{error} }, @$error;
 547     }
 548     elsif ( defined $_[0] ) { $c->{error} = undef }
 549     return $c->{error} || [];
 550 }
 551
 552
 553 =head2 $c->state
 554
 555 Contains the return value of the last executed action.
 556 Note that << $c->state >> operates in a scalar context which means that all
 557 values it returns are scalar.
 558
 559 =head2 $c->clear_errors
 560
 561 Clear errors.  You probably don't want to clear the errors unless you are
 562 implementing a custom error screen.
 563
 564 This is equivalent to running
 565
 566     $c->error(0);
 567
 568 =cut
 569
 570 sub clear_errors {
 571     my $c = shift;
 572     $c->error(0);
 573 }
 574
 575 =head2 $c->has_errors
 576
 577 Returns true if you have errors
 578
 579 =cut
 580
 581 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 582
 583 =head2 $c->last_error
 584
 585 Returns the most recent error in the stack (the one most recently added...)
 586 or nothing if there are no errors.
 587
 588 =cut
 589
 590 sub last_error { my ($err, @errs) = @{shift->error}; return $err }
 591
 592 =head2 shift_errors
 593
 594 shifts the most recently added error off the error stack and returns if.  Returns
 595 nothing if there are no more errors.
 596
 597 =cut
 598
 599 sub shift_errors {
 600     my ($self) = @_;
 601     my ($err, @errors) = @{$self->error};
 602     $self->{error} = \@errors;
 603     return $err;
 604 }
 605
 606 sub _comp_search_prefixes {
 607     my $c = shift;
 608     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 609 }
 610
 611 # search components given a name and some prefixes
 612 sub _comp_names_search_prefixes {
 613     my ( $c, $name, @prefixes ) = @_;
 614     my $appclass = ref $c || $c;
 615     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 616     $filter = qr/$filter/; # Compile regex now rather than once per loop
 617
 618     # map the original component name to the sub part that we will search against
 619     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 620         grep { /$filter/ } keys %{ $c->components };
 621
 622     # undef for a name will return all
 623     return keys %eligible if !defined $name;
 624
 625     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 626     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 627
 628     return @result if @result;
 629
 630     # if we were given a regexp to search against, we're done.
 631     return if $name->$_isa('Regexp');
 632
 633     # skip regexp fallback if configured
 634     return
 635         if $appclass->config->{disable_component_resolution_regex_fallback};
 636
 637     # regexp fallback
 638     $query  = qr/$name/i;
 639     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 640
 641     # no results? try against full names
 642     if( !@result ) {
 643         @result = grep { m{$query} } keys %eligible;
 644     }
 645
 646     # don't warn if we didn't find any results, it just might not exist
 647     if( @result ) {
 648         # Disgusting hack to work out correct method name
 649         my $warn_for = lc $prefixes[0];
 650         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 651            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 652            "component resolution is unreliable and unsafe.";
 653         my $short = $result[0];
 654         # remove the component namespace prefix
 655         $short =~ s/.*?(Model|Controller|View):://;
 656         my $shortmess = Carp::shortmess('');
 657         if ($shortmess =~ m#Catalyst/Plugin#) {
 658            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 659               "plugin's config";
 660         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 661            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 662               "component's config";
 663         } else {
 664            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 665               "but if you really wanted to search, pass in a regexp as the argument " .
 666               "like so: \$c->${warn_for}(qr/${name}/)";
 667         }
 668         $c->log->warn( "${msg}$shortmess" );
 669     }
 670
 671     return @result;
 672 }
 673
 674 # Find possible names for a prefix
 675 sub _comp_names {
 676     my ( $c, @prefixes ) = @_;
 677     my $appclass = ref $c || $c;
 678
 679     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 680
 681     my @names = map { s{$filter}{}; $_; }
 682         $c->_comp_names_search_prefixes( undef, @prefixes );
 683
 684     return @names;
 685 }
 686
 687 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 688 sub _filter_component {
 689     my ( $c, $comp, @args ) = @_;
 690
 691     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 692         return $comp->ACCEPT_CONTEXT( $c, @args );
 693     }
 694
 695     return $comp;
 696 }
 697
 698 =head2 COMPONENT ACCESSORS
 699
 700 =head2 $c->controller($name)
 701
 702 Gets a L<Catalyst::Controller> instance by name.
 703
 704     $c->controller('Foo')->do_stuff;
 705
 706 If the name is omitted, will return the controller for the dispatched
 707 action.
 708
 709 If you want to search for controllers, pass in a regexp as the argument.
 710
 711     # find all controllers that start with Foo
 712     my @foo_controllers = $c->controller(qr{^Foo});
 713
 714
 715 =cut
 716
 717 sub controller {
 718     my ( $c, $name, @args ) = @_;
 719
 720     my $appclass = ref($c) || $c;
 721     if( $name ) {
 722         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 723             my $comps = $c->components;
 724             my $check = $appclass."::Controller::".$name;
 725             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 726         }
 727         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 728         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 729         return $c->_filter_component( $result[ 0 ], @args );
 730     }
 731
 732     return $c->component( $c->action->class );
 733 }
 734
 735 =head2 $c->model($name)
 736
 737 Gets a L<Catalyst::Model> instance by name.
 738
 739     $c->model('Foo')->do_stuff;
 740
 741 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 742
 743 If the name is omitted, it will look for
 744  - a model object in $c->stash->{current_model_instance}, then
 745  - a model name in $c->stash->{current_model}, then
 746  - a config setting 'default_model', or
 747  - check if there is only one model, and return it if that's the case.
 748
 749 If you want to search for models, pass in a regexp as the argument.
 750
 751     # find all models that start with Foo
 752     my @foo_models = $c->model(qr{^Foo});
 753
 754 =cut
 755
 756 sub model {
 757     my ( $c, $name, @args ) = @_;
 758     my $appclass = ref($c) || $c;
 759     if( $name ) {
 760         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 761             my $comps = $c->components;
 762             my $check = $appclass."::Model::".$name;
 763             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 764         }
 765         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 766         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 767         return $c->_filter_component( $result[ 0 ], @args );
 768     }
 769
 770     if (ref $c) {
 771         return $c->stash->{current_model_instance}
 772           if $c->stash->{current_model_instance};
 773         return $c->model( $c->stash->{current_model} )
 774           if $c->stash->{current_model};
 775     }
 776     return $c->model( $appclass->config->{default_model} )
 777       if $appclass->config->{default_model};
 778
 779     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 780
 781     if( $rest ) {
 782         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 783         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 784         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 785         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 786         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 787     }
 788
 789     return $c->_filter_component( $comp );
 790 }
 791
 792
 793 =head2 $c->view($name)
 794
 795 Gets a L<Catalyst::View> instance by name.
 796
 797     $c->view('Foo')->do_stuff;
 798
 799 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 800
 801 If the name is omitted, it will look for
 802  - a view object in $c->stash->{current_view_instance}, then
 803  - a view name in $c->stash->{current_view}, then
 804  - a config setting 'default_view', or
 805  - check if there is only one view, and return it if that's the case.
 806
 807 If you want to search for views, pass in a regexp as the argument.
 808
 809     # find all views that start with Foo
 810     my @foo_views = $c->view(qr{^Foo});
 811
 812 =cut
 813
 814 sub view {
 815     my ( $c, $name, @args ) = @_;
 816
 817     my $appclass = ref($c) || $c;
 818     if( $name ) {
 819         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 820             my $comps = $c->components;
 821             my $check = $appclass."::View::".$name;
 822             if( exists $comps->{$check} ) {
 823                 return $c->_filter_component( $comps->{$check}, @args );
 824             }
 825             else {
 826                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 827             }
 828         }
 829         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 830         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 831         return $c->_filter_component( $result[ 0 ], @args );
 832     }
 833
 834     if (ref $c) {
 835         return $c->stash->{current_view_instance}
 836           if $c->stash->{current_view_instance};
 837         return $c->view( $c->stash->{current_view} )
 838           if $c->stash->{current_view};
 839     }
 840     return $c->view( $appclass->config->{default_view} )
 841       if $appclass->config->{default_view};
 842
 843     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 844
 845     if( $rest ) {
 846         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 847         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 848         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 849         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 850         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 851     }
 852
 853     return $c->_filter_component( $comp );
 854 }
 855
 856 =head2 $c->controllers
 857
 858 Returns the available names which can be passed to $c->controller
 859
 860 =cut
 861
 862 sub controllers {
 863     my ( $c ) = @_;
 864     return $c->_comp_names(qw/Controller C/);
 865 }
 866
 867 =head2 $c->models
 868
 869 Returns the available names which can be passed to $c->model
 870
 871 =cut
 872
 873 sub models {
 874     my ( $c ) = @_;
 875     return $c->_comp_names(qw/Model M/);
 876 }
 877
 878
 879 =head2 $c->views
 880
 881 Returns the available names which can be passed to $c->view
 882
 883 =cut
 884
 885 sub views {
 886     my ( $c ) = @_;
 887     return $c->_comp_names(qw/View V/);
 888 }
 889
 890 =head2 $c->comp($name)
 891
 892 =head2 $c->component($name)
 893
 894 Gets a component object by name. This method is not recommended,
 895 unless you want to get a specific component by full
 896 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 897 should be used instead.
 898
 899 If C<$name> is a regexp, a list of components matched against the full
 900 component name will be returned.
 901
 902 If Catalyst can't find a component by name, it will fallback to regex
 903 matching by default. To disable this behaviour set
 904 disable_component_resolution_regex_fallback to a true value.
 905
 906     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 907
 908 =cut
 909
 910 sub component {
 911     my ( $c, $name, @args ) = @_;
 912
 913     if( $name ) {
 914         my $comps = $c->components;
 915
 916         if( !ref $name ) {
 917             # is it the exact name?
 918             return $c->_filter_component( $comps->{ $name }, @args )
 919                        if exists $comps->{ $name };
 920
 921             # perhaps we just omitted "MyApp"?
 922             my $composed = ( ref $c || $c ) . "::${name}";
 923             return $c->_filter_component( $comps->{ $composed }, @args )
 924                        if exists $comps->{ $composed };
 925
 926             # search all of the models, views and controllers
 927             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 928             return $c->_filter_component( $comp, @args ) if $comp;
 929         }
 930
 931         return
 932             if $c->config->{disable_component_resolution_regex_fallback};
 933
 934         # This is here so $c->comp( '::M::' ) works
 935         my $query = ref $name ? $name : qr{$name}i;
 936
 937         my @result = grep { m{$query} } keys %{ $c->components };
 938         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 939
 940         if( $result[ 0 ] ) {
 941             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 942             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 943             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 944             return $c->_filter_component( $result[ 0 ], @args );
 945         }
 946
 947         # I would expect to return an empty list here, but that breaks back-compat
 948     }
 949
 950     # fallback
 951     return sort keys %{ $c->components };
 952 }
 953
 954 =head2 CLASS DATA AND HELPER CLASSES
 955
 956 =head2 $c->config
 957
 958 Returns or takes a hashref containing the application's configuration.
 959
 960     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 961
 962 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 963 like C<myapp.conf> in your applications home directory. See
 964 L<Catalyst::Plugin::ConfigLoader>.
 965
 966 =head3 Cascading configuration
 967
 968 The config method is present on all Catalyst components, and configuration
 969 will be merged when an application is started. Configuration loaded with
 970 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 971 followed by configuration in your top level C<MyApp> class. These two
 972 configurations are merged, and then configuration data whose hash key matches a
 973 component name is merged with configuration for that component.
 974
 975 The configuration for a component is then passed to the C<new> method when a
 976 component is constructed.
 977
 978 For example:
 979
 980     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 981     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 982
 983 will mean that C<MyApp::Model::Foo> receives the following data when
 984 constructed:
 985
 986     MyApp::Model::Foo->new({
 987         bar => 'baz',
 988         quux => 'frob',
 989         overrides => 'me',
 990     });
 991
 992 It's common practice to use a Moose attribute
 993 on the receiving component to access the config value.
 994
 995     package MyApp::Model::Foo;
 996
 997     use Moose;
 998
 999     # this attr will receive 'baz' at construction time
1000     has 'bar' => (
1001         is  => 'rw',
1002         isa => 'Str',
1003     );
1004
1005 You can then get the value 'baz' by calling $c->model('Foo')->bar
1006 (or $self->bar inside code in the model).
1007
1008 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1009 as a way of reading config within your code, as this B<will not> give you the
1010 correctly merged config back. You B<MUST> take the config values supplied to
1011 the constructor and use those instead.
1012
1013 =cut
1014
1015 around config => sub {
1016     my $orig = shift;
1017     my $c = shift;
1018
1019     croak('Setting config after setup has been run is not allowed.')
1020         if ( @_ and $c->setup_finished );
1021
1022     $c->$orig(@_);
1023 };
1024
1025 =head2 $c->log
1026
1027 Returns the logging object instance. Unless it is already set, Catalyst
1028 sets this up with a L<Catalyst::Log> object. To use your own log class,
1029 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1030 C<< __PACKAGE__->setup >>.
1031
1032  __PACKAGE__->log( MyLogger->new );
1033  __PACKAGE__->setup;
1034
1035 And later:
1036
1037     $c->log->info( 'Now logging with my own logger!' );
1038
1039 Your log class should implement the methods described in
1040 L<Catalyst::Log>.
1041
1042 =head2 has_encoding
1043
1044 Returned True if there's a valid encoding
1045
1046 =head2 clear_encoding
1047
1048 Clears the encoding for the current context
1049
1050 =head2 encoding
1051
1052 Sets or gets the application encoding.  Setting encoding takes either an
1053 Encoding object or a string that we try to resolve via L<Encode::find_encoding>.
1054
1055 You would expect to get the encoding object back if you attempt to set it.  If
1056 there is a failure you will get undef returned and an error message in the log.
1057
1058 =cut
1059
1060 sub has_encoding { shift->encoding ? 1:0 }
1061
1062 sub clear_encoding {
1063     my $c = shift;
1064     if(blessed $c) {
1065         $c->encoding(undef);
1066     } else {
1067         $c->log->error("You can't clear encoding on the application");
1068     }
1069 }
1070
1071 sub encoding {
1072     my $c = shift;
1073     my $encoding;
1074
1075     if ( scalar @_ ) {
1076
1077         # Don't let one change this once we are too far into the response
1078         if(blessed $c && $c->res->finalized_headers) {
1079           Carp::croak("You may not change the encoding once the headers are finalized");
1080           return;
1081         }
1082
1083         # Let it be set to undef
1084         if (my $wanted = shift)  {
1085             $encoding = Encode::find_encoding($wanted)
1086               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1087             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1088         }
1089         else {
1090             binmode(STDERR);
1091         }
1092
1093         $encoding = ref $c
1094                   ? $c->{encoding} = $encoding
1095                   : $c->_encoding($encoding);
1096     } else {
1097       $encoding = ref $c && exists $c->{encoding}
1098                 ? $c->{encoding}
1099                 : $c->_encoding;
1100     }
1101
1102     return $encoding;
1103 }
1104
1105 =head2 $c->debug
1106
1107 Returns 1 if debug mode is enabled, 0 otherwise.
1108
1109 You can enable debug mode in several ways:
1110
1111 =over
1112
1113 =item By calling myapp_server.pl with the -d flag
1114
1115 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1116
1117 =item The -Debug option in your MyApp.pm
1118
1119 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1120
1121 =back
1122
1123 The first three also set the log level to 'debug'.
1124
1125 Calling C<< $c->debug(1) >> has no effect.
1126
1127 =cut
1128
1129 sub debug { 0 }
1130
1131 =head2 $c->dispatcher
1132
1133 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1134
1135 =head2 $c->engine
1136
1137 Returns the engine instance. See L<Catalyst::Engine>.
1138
1139
1140 =head2 UTILITY METHODS
1141
1142 =head2 $c->path_to(@path)
1143
1144 Merges C<@path> with C<< $c->config->{home} >> and returns a
1145 L<Path::Class::Dir> object. Note you can usually use this object as
1146 a filename, but sometimes you will have to explicitly stringify it
1147 yourself by calling the C<< ->stringify >> method.
1148
1149 For example:
1150
1151     $c->path_to( 'db', 'sqlite.db' );
1152
1153 =cut
1154
1155 sub path_to {
1156     my ( $c, @path ) = @_;
1157     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1158     if ( -d $path ) { return $path }
1159     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1160 }
1161
1162 sub plugin {
1163     my ( $class, $name, $plugin, @args ) = @_;
1164
1165     # See block comment in t/unit_core_plugin.t
1166     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1167
1168     $class->_register_plugin( $plugin, 1 );
1169
1170     eval { $plugin->import };
1171     $class->mk_classdata($name);
1172     my $obj;
1173     eval { $obj = $plugin->new(@args) };
1174
1175     if ($@) {
1176         Catalyst::Exception->throw( message =>
1177               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1178     }
1179
1180     $class->$name($obj);
1181     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1182       if $class->debug;
1183 }
1184
1185 =head2 MyApp->setup
1186
1187 Initializes the dispatcher and engine, loads any plugins, and loads the
1188 model, view, and controller components. You may also specify an array
1189 of plugins to load here, if you choose to not load them in the C<use
1190 Catalyst> line.
1191
1192     MyApp->setup;
1193     MyApp->setup( qw/-Debug/ );
1194
1195 B<Note:> You B<should not> wrap this method with method modifiers
1196 or bad things will happen - wrap the C<setup_finalize> method instead.
1197
1198 B<Note:> You can create a custom setup stage that will execute when the
1199 application is starting.  Use this to customize setup.
1200
1201     MyApp->setup(-Custom=value);
1202
1203     sub setup_custom {
1204       my ($class, $value) = @_;
1205     }
1206
1207 Can be handy if you want to hook into the setup phase.
1208
1209 =cut
1210
1211 sub setup {
1212     my ( $class, @arguments ) = @_;
1213     croak('Running setup more than once')
1214         if ( $class->setup_finished );
1215
1216     unless ( $class->isa('Catalyst') ) {
1217
1218         Catalyst::Exception->throw(
1219             message => qq/'$class' does not inherit from Catalyst/ );
1220     }
1221
1222     if ( $class->arguments ) {
1223         @arguments = ( @arguments, @{ $class->arguments } );
1224     }
1225
1226     # Process options
1227     my $flags = {};
1228
1229     foreach (@arguments) {
1230
1231         if (/^-Debug$/) {
1232             $flags->{log} =
1233               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1234         }
1235         elsif (/^-(\w+)=?(.*)$/) {
1236             $flags->{ lc $1 } = $2;
1237         }
1238         else {
1239             push @{ $flags->{plugins} }, $_;
1240         }
1241     }
1242
1243     $class->setup_home( delete $flags->{home} );
1244
1245     $class->setup_log( delete $flags->{log} );
1246     $class->setup_plugins( delete $flags->{plugins} );
1247
1248     $class->setup_data_handlers();
1249     $class->setup_dispatcher( delete $flags->{dispatcher} );
1250     if (my $engine = delete $flags->{engine}) {
1251         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1252     }
1253     $class->setup_engine();
1254     $class->setup_stats( delete $flags->{stats} );
1255
1256     for my $flag ( sort keys %{$flags} ) {
1257
1258         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1259             &$code( $class, delete $flags->{$flag} );
1260         }
1261         else {
1262             $class->log->warn(qq/Unknown flag "$flag"/);
1263         }
1264     }
1265
1266     eval { require Catalyst::Devel; };
1267     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1268         $class->log->warn(<<"EOF");
1269 You are running an old script!
1270
1271   Please update by running (this will overwrite existing files):
1272     catalyst.pl -force -scripts $class
1273
1274   or (this will not overwrite existing files):
1275     catalyst.pl -scripts $class
1276
1277 EOF
1278     }
1279
1280     # Call plugins setup, this is stupid and evil.
1281     # Also screws C3 badly on 5.10, hack to avoid.
1282     {
1283         no warnings qw/redefine/;
1284         local *setup = sub { };
1285         $class->setup unless $Catalyst::__AM_RESTARTING;
1286     }
1287
1288     # If you are expecting configuration info as part of your setup, it needs
1289     # to get called here and below, since we need the above line to support
1290     # ConfigLoader based configs.
1291
1292     $class->setup_encoding();
1293     $class->setup_middleware();
1294
1295     # Initialize our data structure
1296     $class->components( {} );
1297
1298     $class->setup_components;
1299
1300     if ( $class->debug ) {
1301         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1302
1303         if (@plugins) {
1304             my $column_width = Catalyst::Utils::term_width() - 6;
1305             my $t = Text::SimpleTable->new($column_width);
1306             $t->row($_) for @plugins;
1307             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1308         }
1309
1310         my @middleware = map {
1311           ref $_ eq 'CODE' ?
1312             "Inline Coderef" :
1313               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1314                 || '')  } $class->registered_middlewares;
1315
1316         if (@middleware) {
1317             my $column_width = Catalyst::Utils::term_width() - 6;
1318             my $t = Text::SimpleTable->new($column_width);
1319             $t->row($_) for @middleware;
1320             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1321         }
1322
1323         my %dh = $class->registered_data_handlers;
1324         if (my @data_handlers = keys %dh) {
1325             my $column_width = Catalyst::Utils::term_width() - 6;
1326             my $t = Text::SimpleTable->new($column_width);
1327             $t->row($_) for @data_handlers;
1328             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1329         }
1330
1331         my $dispatcher = $class->dispatcher;
1332         my $engine     = $class->engine;
1333         my $home       = $class->config->{home};
1334
1335         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1336         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1337
1338         $home
1339           ? ( -d $home )
1340           ? $class->log->debug(qq/Found home "$home"/)
1341           : $class->log->debug(qq/Home "$home" doesn't exist/)
1342           : $class->log->debug(q/Couldn't find home/);
1343
1344         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1345         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1346         for my $comp ( sort keys %{ $class->components } ) {
1347             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1348             $t->row( $comp, $type );
1349         }
1350         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1351           if ( keys %{ $class->components } );
1352     }
1353
1354     # Add our self to components, since we are also a component
1355     if( $class->isa('Catalyst::Controller') ){
1356       $class->components->{$class} = $class;
1357     }
1358
1359     $class->setup_actions;
1360
1361     if ( $class->debug ) {
1362         my $name = $class->config->{name} || 'Application';
1363         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1364     }
1365
1366     if ($class->config->{case_sensitive}) {
1367         $class->log->warn($class . "->config->{case_sensitive} is set.");
1368         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1369     }
1370
1371     $class->setup_finalize;
1372
1373     # Flush the log for good measure (in case something turned off 'autoflush' early)
1374     $class->log->_flush() if $class->log->can('_flush');
1375
1376     return $class || 1; # Just in case someone named their Application 0...
1377 }
1378
1379 =head2 $app->setup_finalize
1380
1381 A hook to attach modifiers to. This method does not do anything except set the
1382 C<setup_finished> accessor.
1383
1384 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1385
1386 Example:
1387
1388     after setup_finalize => sub {
1389         my $app = shift;
1390
1391         ## do stuff here..
1392     };
1393
1394 =cut
1395
1396 sub setup_finalize {
1397     my ($class) = @_;
1398     $class->setup_finished(1);
1399 }
1400
1401 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1402
1403 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1404
1405 =head2 $c->uri_for( $action, [@captures, @args], \%query_values? )
1406
1407 Constructs an absolute L<URI> object based on the application root, the
1408 provided path, and the additional arguments and query parameters provided.
1409 When used as a string, provides a textual URI.  If you need more flexibility
1410 than this (i.e. the option to provide relative URIs etc.) see
1411 L<Catalyst::Plugin::SmartURI>.
1412
1413 If no arguments are provided, the URI for the current action is returned.
1414 To return the current action and also provide @args, use
1415 C<< $c->uri_for( $c->action, @args ) >>.
1416
1417 If the first argument is a string, it is taken as a public URI path relative
1418 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1419 relative to the application root (if it does). It is then merged with
1420 C<< $c->request->base >>; any C<@args> are appended as additional path
1421 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1422
1423 If the first argument is a L<Catalyst::Action> it represents an action which
1424 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1425 optional C<\@captures> argument (an arrayref) allows passing the captured
1426 variables that are needed to fill in the paths of Chained and Regex actions;
1427 once the path is resolved, C<uri_for> continues as though a path was
1428 provided, appending any arguments or parameters and creating an absolute
1429 URI.
1430
1431 The captures for the current request can be found in
1432 C<< $c->request->captures >>, and actions can be resolved using
1433 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1434 path, use C<< $c->uri_for_action >> instead.
1435
1436   # Equivalent to $c->req->uri
1437   $c->uri_for($c->action, $c->req->captures,
1438       @{ $c->req->args }, $c->req->params);
1439
1440   # For the Foo action in the Bar controller
1441   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1442
1443   # Path to a static resource
1444   $c->uri_for('/static/images/logo.png');
1445
1446 In general the scheme of the generated URI object will follow the incoming request
1447 however if your targeted action or action chain has the Scheme attribute it will
1448 use that instead.
1449
1450 =cut
1451
1452 sub uri_for {
1453     my ( $c, $path, @args ) = @_;
1454
1455     if ( $path->$_isa('Catalyst::Controller') ) {
1456         $path = $path->path_prefix;
1457         $path =~ s{/+\z}{};
1458         $path .= '/';
1459     }
1460
1461     undef($path) if (defined $path && $path eq '');
1462
1463     my $params =
1464       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1465
1466     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1467
1468     my @encoded_args = ();
1469     foreach my $arg (@args) {
1470       if(ref($arg)||'' eq 'ARRAY') {
1471         push @encoded_args, [map {
1472           my $encoded = encode_utf8 $_;
1473           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1474          $encoded;
1475         } @$arg];
1476       } else {
1477         push @encoded_args, do {
1478           my $encoded = encode_utf8 $arg;
1479           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1480           $encoded;
1481         }
1482       }
1483     }
1484
1485     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1486     if ( $path->$_isa('Catalyst::Action') ) { # action object
1487         s|/|%2F|g for @encoded_args;
1488         my $captures = [ map { s|/|%2F|g; $_; }
1489                         ( scalar @encoded_args && ref $encoded_args[0] eq 'ARRAY'
1490                          ? @{ shift(@encoded_args) }
1491                          : ()) ];
1492
1493         my $action = $path;
1494         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1495         if( !@encoded_args && $action->number_of_args ) {
1496             my $expanded_action = $c->dispatcher->expand_action( $action );
1497             my $num_captures = $expanded_action->number_of_captures;
1498             unshift @encoded_args, splice @$captures, $num_captures;
1499         }
1500
1501         # use Devel::Dwarn;Dwarn $captures;
1502
1503         if($action->has_captures_constraints) {
1504           unless($action->match_captures($c, $captures)) {
1505             carp "@{$captures} do not match the type constraints in $action";
1506           }
1507         }
1508
1509         $path = $c->dispatcher->uri_for_action($action, $captures);
1510         if (not defined $path) {
1511             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1512                 if $c->debug;
1513             return undef;
1514         }
1515         $path = '/' if $path eq '';
1516
1517         # At this point @encoded_args is the remaining Args (all captures removed).
1518         if($action->has_args_constraints) {
1519           unless($action->match_args($c,\@encoded_args)) {
1520             carp "@encoded_args do not match the type constraints in $action";
1521           }
1522         }
1523     }
1524
1525     unshift(@encoded_args, $path);
1526
1527     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1528         my $namespace = $c->namespace;
1529         if (defined $path) { # cheesy hack to handle path '../foo'
1530            $namespace =~ s{(?:^|/)[^/]+$}{} while $encoded_args[0] =~ s{^\.\./}{};
1531         }
1532         unshift(@encoded_args, $namespace || '');
1533     }
1534
1535     # join args with '/', or a blank string
1536     my $args = join('/', grep { defined($_) } @encoded_args);
1537     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1538     $args =~ s!^/+!!;
1539
1540     my ($base, $class) = ('/', 'URI::_generic');
1541     if(blessed($c)) {
1542       $base = $c->req->base;
1543       if($target_action) {
1544         $target_action = $c->dispatcher->expand_action($target_action);
1545         if(my $s = $target_action->scheme) {
1546           $s = lc($s);
1547           $class = "URI::$s";
1548           $base->scheme($s);
1549         } else {
1550           $class = ref($base);
1551         }
1552       } else {
1553         $class = ref($base);
1554       }
1555
1556       $base =~ s{(?<!/)$}{/};
1557     }
1558
1559     my $query = '';
1560
1561     if (my @keys = keys %$params) {
1562       # somewhat lifted from URI::_query's query_form
1563       $query = '?'.join('&', map {
1564           my $val = $params->{$_};
1565           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1566           s/ /+/g;
1567           my $key = $_;
1568           $val = '' unless defined $val;
1569           (map {
1570               my $param = "$_";
1571               $param = encode_utf8($param);
1572               # using the URI::Escape pattern here so utf8 chars survive
1573               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1574               $param =~ s/ /+/g;
1575
1576               $key = encode_utf8($key);
1577               # using the URI::Escape pattern here so utf8 chars survive
1578               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1579               $key =~ s/ /+/g;
1580
1581               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1582       } @keys);
1583     }
1584
1585     warn $base;
1586     warn $args;
1587
1588     my $res = bless(\"${base}${args}${query}", $class);
1589     $res;
1590 }
1591
1592 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1593
1594 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1595
1596 =over
1597
1598 =item $path
1599
1600 A private path to the Catalyst action you want to create a URI for.
1601
1602 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1603 >> and passing the resulting C<$action> and the remaining arguments to C<<
1604 $c->uri_for >>.
1605
1606 You can also pass in a Catalyst::Action object, in which case it is passed to
1607 C<< $c->uri_for >>.
1608
1609 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1610
1611 For example, if the action looks like:
1612
1613  package MyApp::Controller::Users;
1614
1615  sub lst : Path('the-list') {}
1616
1617 You can use:
1618
1619  $c->uri_for_action('/users/lst')
1620
1621 and it will create the URI /users/the-list.
1622
1623 =item \@captures_and_args?
1624
1625 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1626 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1627 to interpolate all the parameters in the URI.
1628
1629 =item @args?
1630
1631 Optional list of extra arguments - can be supplied in the
1632 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1633 code.
1634
1635 Your action can have zero, a fixed or a variable number of args (e.g.
1636 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1637
1638 =item \%query_values?
1639
1640 Optional array reference of query parameters to append. E.g.
1641
1642   { foo => 'bar' }
1643
1644 will generate
1645
1646   /rest/of/your/uri?foo=bar
1647
1648 =back
1649
1650 =cut
1651
1652 sub uri_for_action {
1653     my ( $c, $path, @args ) = @_;
1654     my $action = blessed($path)
1655       ? $path
1656       : $c->dispatcher->get_action_by_path($path);
1657     unless (defined $action) {
1658       croak "Can't find action for path '$path'";
1659     }
1660     return $c->uri_for( $action, @args );
1661 }
1662
1663 =head2 $c->welcome_message
1664
1665 Returns the Catalyst welcome HTML page.
1666
1667 =cut
1668
1669 sub welcome_message {
1670     my $c      = shift;
1671     my $name   = $c->config->{name};
1672     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1673     my $prefix = Catalyst::Utils::appprefix( ref $c );
1674     $c->response->content_type('text/html; charset=utf-8');
1675     return <<"EOF";
1676 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1677     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1678 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1679     <head>
1680     <meta http-equiv="Content-Language" content="en" />
1681     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1682         <title>$name on Catalyst $VERSION</title>
1683         <style type="text/css">
1684             body {
1685                 color: #000;
1686                 background-color: #eee;
1687             }
1688             div#content {
1689                 width: 640px;
1690                 margin-left: auto;
1691                 margin-right: auto;
1692                 margin-top: 10px;
1693                 margin-bottom: 10px;
1694                 text-align: left;
1695                 background-color: #ccc;
1696                 border: 1px solid #aaa;
1697             }
1698             p, h1, h2 {
1699                 margin-left: 20px;
1700                 margin-right: 20px;
1701                 font-family: verdana, tahoma, sans-serif;
1702             }
1703             a {
1704                 font-family: verdana, tahoma, sans-serif;
1705             }
1706             :link, :visited {
1707                     text-decoration: none;
1708                     color: #b00;
1709                     border-bottom: 1px dotted #bbb;
1710             }
1711             :link:hover, :visited:hover {
1712                     color: #555;
1713             }
1714             div#topbar {
1715                 margin: 0px;
1716             }
1717             pre {
1718                 margin: 10px;
1719                 padding: 8px;
1720             }
1721             div#answers {
1722                 padding: 8px;
1723                 margin: 10px;
1724                 background-color: #fff;
1725                 border: 1px solid #aaa;
1726             }
1727             h1 {
1728                 font-size: 0.9em;
1729                 font-weight: normal;
1730                 text-align: center;
1731             }
1732             h2 {
1733                 font-size: 1.0em;
1734             }
1735             p {
1736                 font-size: 0.9em;
1737             }
1738             p img {
1739                 float: right;
1740                 margin-left: 10px;
1741             }
1742             span#appname {
1743                 font-weight: bold;
1744                 font-size: 1.6em;
1745             }
1746         </style>
1747     </head>
1748     <body>
1749         <div id="content">
1750             <div id="topbar">
1751                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1752                     $VERSION</h1>
1753              </div>
1754              <div id="answers">
1755                  <p>
1756                  <img src="$logo" alt="Catalyst Logo" />
1757                  </p>
1758                  <p>Welcome to the  world of Catalyst.
1759                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1760                     framework will make web development something you had
1761                     never expected it to be: Fun, rewarding, and quick.</p>
1762                  <h2>What to do now?</h2>
1763                  <p>That really depends  on what <b>you</b> want to do.
1764                     We do, however, provide you with a few starting points.</p>
1765                  <p>If you want to jump right into web development with Catalyst
1766                     you might want to start with a tutorial.</p>
1767 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1768 </pre>
1769 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1770 <pre>
1771 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1772 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1773 </code></pre>
1774                  <h2>What to do next?</h2>
1775                  <p>Next it's time to write an actual application. Use the
1776                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1777                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1778                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1779                     they can save you a lot of work.</p>
1780                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1781                     <p>Also, be sure to check out the vast and growing
1782                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1783                     you are likely to find what you need there.
1784                     </p>
1785
1786                  <h2>Need help?</h2>
1787                  <p>Catalyst has a very active community. Here are the main places to
1788                     get in touch with us.</p>
1789                  <ul>
1790                      <li>
1791                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1792                      </li>
1793                      <li>
1794                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1795                      </li>
1796                      <li>
1797                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1798                      </li>
1799                  </ul>
1800                  <h2>In conclusion</h2>
1801                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1802                     as we enjoyed making it. Please contact us if you have ideas
1803                     for improvement or other feedback.</p>
1804              </div>
1805          </div>
1806     </body>
1807 </html>
1808 EOF
1809 }
1810
1811 =head2 run_options
1812
1813 Contains a hash of options passed from the application script, including
1814 the original ARGV the script received, the processed values from that
1815 ARGV and any extra arguments to the script which were not processed.
1816
1817 This can be used to add custom options to your application's scripts
1818 and setup your application differently depending on the values of these
1819 options.
1820
1821 =head1 INTERNAL METHODS
1822
1823 These methods are not meant to be used by end users.
1824
1825 =head2 $c->components
1826
1827 Returns a hash of components.
1828
1829 =head2 $c->context_class
1830
1831 Returns or sets the context class.
1832
1833 =head2 $c->counter
1834
1835 Returns a hashref containing coderefs and execution counts (needed for
1836 deep recursion detection).
1837
1838 =head2 $c->depth
1839
1840 Returns the number of actions on the current internal execution stack.
1841
1842 =head2 $c->dispatch
1843
1844 Dispatches a request to actions.
1845
1846 =cut
1847
1848 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1849
1850 =head2 $c->dispatcher_class
1851
1852 Returns or sets the dispatcher class.
1853
1854 =head2 $c->dump_these
1855
1856 Returns a list of 2-element array references (name, structure) pairs
1857 that will be dumped on the error page in debug mode.
1858
1859 =cut
1860
1861 sub dump_these {
1862     my $c = shift;
1863     [ Request => $c->req ],
1864     [ Response => $c->res ],
1865     [ Stash => $c->stash ],
1866     [ Config => $c->config ];
1867 }
1868
1869 =head2 $c->engine_class
1870
1871 Returns or sets the engine class.
1872
1873 =head2 $c->execute( $class, $coderef )
1874
1875 Execute a coderef in given class and catch exceptions. Errors are available
1876 via $c->error.
1877
1878 =cut
1879
1880 sub execute {
1881     my ( $c, $class, $code ) = @_;
1882     $class = $c->component($class) || $class;
1883     $c->state(0);
1884
1885     if ( $c->depth >= $RECURSION ) {
1886         my $action = $code->reverse();
1887         $action = "/$action" unless $action =~ /->/;
1888         my $error = qq/Deep recursion detected calling "${action}"/;
1889         $c->log->error($error);
1890         $c->error($error);
1891         $c->state(0);
1892         return $c->state;
1893     }
1894
1895     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1896
1897     push( @{ $c->stack }, $code );
1898
1899     no warnings 'recursion';
1900     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1901     #      I have no idea how, ergo $ret (which appears to fix the issue)
1902     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1903
1904     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1905
1906     my $last = pop( @{ $c->stack } );
1907
1908     if ( my $error = $@ ) {
1909         #rethow if this can be handled by middleware
1910         if ( $c->_handle_http_exception($error) ) {
1911             foreach my $err (@{$c->error}) {
1912                 $c->log->error($err);
1913             }
1914             $c->clear_errors;
1915             $c->log->_flush if $c->log->can('_flush');
1916
1917             $error->can('rethrow') ? $error->rethrow : croak $error;
1918         }
1919         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1920             $error->rethrow if $c->depth > 1;
1921         }
1922         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1923             $error->rethrow if $c->depth > 0;
1924         }
1925         else {
1926             unless ( ref $error ) {
1927                 no warnings 'uninitialized';
1928                 chomp $error;
1929                 my $class = $last->class;
1930                 my $name  = $last->name;
1931                 $error = qq/Caught exception in $class->$name "$error"/;
1932             }
1933             $c->error($error);
1934         }
1935         $c->state(0);
1936     }
1937     return $c->state;
1938 }
1939
1940 sub _stats_start_execute {
1941     my ( $c, $code ) = @_;
1942     my $appclass = ref($c) || $c;
1943     return if ( ( $code->name =~ /^_.*/ )
1944         && ( !$appclass->config->{show_internal_actions} ) );
1945
1946     my $action_name = $code->reverse();
1947     $c->counter->{$action_name}++;
1948
1949     my $action = $action_name;
1950     $action = "/$action" unless $action =~ /->/;
1951
1952     # determine if the call was the result of a forward
1953     # this is done by walking up the call stack and looking for a calling
1954     # sub of Catalyst::forward before the eval
1955     my $callsub = q{};
1956     for my $index ( 2 .. 11 ) {
1957         last
1958         if ( ( caller($index) )[0] eq 'Catalyst'
1959             && ( caller($index) )[3] eq '(eval)' );
1960
1961         if ( ( caller($index) )[3] =~ /forward$/ ) {
1962             $callsub = ( caller($index) )[3];
1963             $action  = "-> $action";
1964             last;
1965         }
1966     }
1967
1968     my $uid = $action_name . $c->counter->{$action_name};
1969
1970     # is this a root-level call or a forwarded call?
1971     if ( $callsub =~ /forward$/ ) {
1972         my $parent = $c->stack->[-1];
1973
1974         # forward, locate the caller
1975         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1976             $c->stats->profile(
1977                 begin  => $action,
1978                 parent => "$parent" . $c->counter->{"$parent"},
1979                 uid    => $uid,
1980             );
1981         }
1982         else {
1983
1984             # forward with no caller may come from a plugin
1985             $c->stats->profile(
1986                 begin => $action,
1987                 uid   => $uid,
1988             );
1989         }
1990     }
1991     else {
1992
1993         # root-level call
1994         $c->stats->profile(
1995             begin => $action,
1996             uid   => $uid,
1997         );
1998     }
1999     return $action;
2000
2001 }
2002
2003 sub _stats_finish_execute {
2004     my ( $c, $info ) = @_;
2005     $c->stats->profile( end => $info );
2006 }
2007
2008 =head2 $c->finalize
2009
2010 Finalizes the request.
2011
2012 =cut
2013
2014 sub finalize {
2015     my $c = shift;
2016
2017     for my $error ( @{ $c->error } ) {
2018         $c->log->error($error);
2019     }
2020
2021     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
2022     # stuff like cometd and websockets
2023
2024     if($c->request->_has_io_fh) {
2025       $c->log_response;
2026       return;
2027     }
2028
2029     # Allow engine to handle finalize flow (for POE)
2030     my $engine = $c->engine;
2031     if ( my $code = $engine->can('finalize') ) {
2032         $engine->$code($c);
2033     }
2034     else {
2035
2036         $c->finalize_uploads;
2037
2038         # Error
2039         if ( $#{ $c->error } >= 0 ) {
2040             $c->finalize_error;
2041         }
2042
2043         $c->finalize_encoding;
2044         $c->finalize_headers unless $c->response->finalized_headers;
2045         $c->finalize_body;
2046     }
2047
2048     $c->log_response;
2049
2050     if ($c->use_stats) {
2051         my $elapsed = $c->stats->elapsed;
2052         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2053         $c->log->info(
2054             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2055     }
2056
2057     return $c->response->status;
2058 }
2059
2060 =head2 $c->finalize_body
2061
2062 Finalizes body.
2063
2064 =cut
2065
2066 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2067
2068 =head2 $c->finalize_cookies
2069
2070 Finalizes cookies.
2071
2072 =cut
2073
2074 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2075
2076 =head2 $c->finalize_error
2077
2078 Finalizes error.  If there is only one error in L</error> and it is an object that
2079 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2080 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2081 return the default error page (production mode).
2082
2083 =cut
2084
2085 sub finalize_error {
2086     my $c = shift;
2087     if($#{$c->error} > 0) {
2088         $c->engine->finalize_error( $c, @_ );
2089     } else {
2090         my ($error) = @{$c->error};
2091         if ( $c->_handle_http_exception($error) ) {
2092             # In the case where the error 'knows what it wants', becauses its PSGI
2093             # aware, just rethow and let middleware catch it
2094             $error->can('rethrow') ? $error->rethrow : croak $error;
2095         } else {
2096             $c->engine->finalize_error( $c, @_ )
2097         }
2098     }
2099 }
2100
2101 =head2 $c->finalize_headers
2102
2103 Finalizes headers.
2104
2105 =cut
2106
2107 sub finalize_headers {
2108     my $c = shift;
2109
2110     my $response = $c->response; #accessor calls can add up?
2111
2112     # Check if we already finalized headers
2113     return if $response->finalized_headers;
2114
2115     # Handle redirects
2116     if ( my $location = $response->redirect ) {
2117         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2118         $response->header( Location => $location );
2119     }
2120
2121     # Remove incorrectly added body and content related meta data when returning
2122     # an information response, or a response the is required to not include a body
2123
2124     $c->finalize_cookies;
2125
2126     # This currently is a NOOP but I don't want to remove it since I guess people
2127     # might have Response subclasses that use it for something... (JNAP)
2128     $c->response->finalize_headers();
2129
2130     # Done
2131     $response->finalized_headers(1);
2132 }
2133
2134 =head2 $c->finalize_encoding
2135
2136 Make sure your body is encoded properly IF you set an encoding.  By
2137 default the encoding is UTF-8 but you can disable it by explicitly setting the
2138 encoding configuration value to undef.
2139
2140 We can only encode when the body is a scalar.  Methods for encoding via the
2141 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2142 are available).
2143
2144 See L</ENCODING>.
2145
2146 =cut
2147
2148 sub finalize_encoding {
2149     my $c = shift;
2150     my $res = $c->res || return;
2151
2152     # Warn if the set charset is different from the one you put into encoding.  We need
2153     # to do this early since encodable_response is false for this condition and we need
2154     # to match the debug output for backcompat (there's a test for this...) -JNAP
2155     if(
2156       $res->content_type_charset and $c->encoding and
2157       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2158     ) {
2159         my $ct = lc($res->content_type_charset);
2160         $c->log->debug("Catalyst encoding config is set to encode in '" .
2161             $c->encoding->mime_name .
2162             "', content type is '$ct', not encoding ");
2163     }
2164
2165     if(
2166       ($res->encodable_response) and
2167       (defined($res->body)) and
2168       (ref(\$res->body) eq 'SCALAR')
2169     ) {
2170         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2171
2172         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2173         # is false when the set charset is not the same as the encoding mimetype (maybe
2174         # confusing action at a distance here..
2175         # Don't try to set the charset if one already exists
2176         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2177           unless($c->res->content_type_charset);
2178     }
2179 }
2180
2181 =head2 $c->finalize_output
2182
2183 An alias for finalize_body.
2184
2185 =head2 $c->finalize_read
2186
2187 Finalizes the input after reading is complete.
2188
2189 =cut
2190
2191 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2192
2193 =head2 $c->finalize_uploads
2194
2195 Finalizes uploads. Cleans up any temporary files.
2196
2197 =cut
2198
2199 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2200
2201 =head2 $c->get_action( $action, $namespace )
2202
2203 Gets an action in a given namespace.
2204
2205 =cut
2206
2207 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2208
2209 =head2 $c->get_actions( $action, $namespace )
2210
2211 Gets all actions of a given name in a namespace and all parent
2212 namespaces.
2213
2214 =cut
2215
2216 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2217
2218 =head2 $app->handle_request( @arguments )
2219
2220 Called to handle each HTTP request.
2221
2222 =cut
2223
2224 sub handle_request {
2225     my ( $class, @arguments ) = @_;
2226
2227     # Always expect worst case!
2228     my $status = -1;
2229     try {
2230         if ($class->debug) {
2231             my $secs = time - $START || 1;
2232             my $av = sprintf '%.3f', $COUNT / $secs;
2233             my $time = localtime time;
2234             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2235         }
2236
2237         my $c = $class->prepare(@arguments);
2238         $c->dispatch;
2239         $status = $c->finalize;
2240     } catch {
2241         #rethow if this can be handled by middleware
2242         if ( $class->_handle_http_exception($_) ) {
2243             $_->can('rethrow') ? $_->rethrow : croak $_;
2244         }
2245         chomp(my $error = $_);
2246         $class->log->error(qq/Caught exception in engine "$error"/);
2247     };
2248
2249     $COUNT++;
2250
2251     if(my $coderef = $class->log->can('_flush')){
2252         $class->log->$coderef();
2253     }
2254     return $status;
2255 }
2256
2257 =head2 $class->prepare( @arguments )
2258
2259 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2260 etc.).
2261
2262 =cut
2263
2264 has _uploadtmp => (
2265     is => 'ro',
2266     predicate => '_has_uploadtmp',
2267 );
2268
2269 sub prepare {
2270     my ( $class, @arguments ) = @_;
2271
2272     # XXX
2273     # After the app/ctxt split, this should become an attribute based on something passed
2274     # into the application.
2275     $class->context_class( ref $class || $class ) unless $class->context_class;
2276
2277     my $uploadtmp = $class->config->{uploadtmp};
2278     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2279
2280     $c->response->_context($c);
2281
2282     #surely this is not the most efficient way to do things...
2283     $c->stats($class->stats_class->new)->enable($c->use_stats);
2284     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2285         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2286     }
2287
2288     try {
2289         # Allow engine to direct the prepare flow (for POE)
2290         if ( my $prepare = $c->engine->can('prepare') ) {
2291             $c->engine->$prepare( $c, @arguments );
2292         }
2293         else {
2294             $c->prepare_request(@arguments);
2295             $c->prepare_connection;
2296             $c->prepare_query_parameters;
2297             $c->prepare_headers; # Just hooks, no longer needed - they just
2298             $c->prepare_cookies; # cause the lazy attribute on req to build
2299             $c->prepare_path;
2300
2301             # Prepare the body for reading, either by prepare_body
2302             # or the user, if they are using $c->read
2303             $c->prepare_read;
2304
2305             # Parse the body unless the user wants it on-demand
2306             unless ( ref($c)->config->{parse_on_demand} ) {
2307                 $c->prepare_body;
2308             }
2309         }
2310         $c->prepare_action;
2311     }
2312     # VERY ugly and probably shouldn't rely on ->finalize actually working
2313     catch {
2314         # failed prepare is always due to an invalid request, right?
2315         $c->response->status(400);
2316         $c->response->content_type('text/plain');
2317         $c->response->body('Bad Request');
2318         # Note we call finalize and then die here, which escapes
2319         # finalize being called in the enclosing block..
2320         # It in fact couldn't be called, as we don't return $c..
2321         # This is a mess - but I'm unsure you can fix this without
2322         # breaking compat for people doing crazy things (we should set
2323         # the 400 and just return the ctx here IMO, letting finalize get called
2324         # above...
2325         $c->finalize;
2326         die $_;
2327     };
2328
2329     $c->log_request;
2330
2331     return $c;
2332 }
2333
2334 =head2 $c->prepare_action
2335
2336 Prepares action. See L<Catalyst::Dispatcher>.
2337
2338 =cut
2339
2340 sub prepare_action {
2341     my $c = shift;
2342     my $ret = $c->dispatcher->prepare_action( $c, @_);
2343
2344     if($c->encoding) {
2345         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2346           $_ = $c->_handle_param_unicode_decoding($_);
2347         }
2348     }
2349
2350     return $ret;
2351 }
2352
2353
2354 =head2 $c->prepare_body
2355
2356 Prepares message body.
2357
2358 =cut
2359
2360 sub prepare_body {
2361     my $c = shift;
2362
2363     return if $c->request->_has_body;
2364
2365     # Initialize on-demand data
2366     $c->engine->prepare_body( $c, @_ );
2367     $c->prepare_parameters;
2368     $c->prepare_uploads;
2369 }
2370
2371 =head2 $c->prepare_body_chunk( $chunk )
2372
2373 Prepares a chunk of data before sending it to L<HTTP::Body>.
2374
2375 See L<Catalyst::Engine>.
2376
2377 =cut
2378
2379 sub prepare_body_chunk {
2380     my $c = shift;
2381     $c->engine->prepare_body_chunk( $c, @_ );
2382 }
2383
2384 =head2 $c->prepare_body_parameters
2385
2386 Prepares body parameters.
2387
2388 =cut
2389
2390 sub prepare_body_parameters {
2391     my $c = shift;
2392     $c->request->prepare_body_parameters( $c, @_ );
2393 }
2394
2395 =head2 $c->prepare_connection
2396
2397 Prepares connection.
2398
2399 =cut
2400
2401 sub prepare_connection {
2402     my $c = shift;
2403     $c->request->prepare_connection($c);
2404 }
2405
2406 =head2 $c->prepare_cookies
2407
2408 Prepares cookies by ensuring that the attribute on the request
2409 object has been built.
2410
2411 =cut
2412
2413 sub prepare_cookies { my $c = shift; $c->request->cookies }
2414
2415 =head2 $c->prepare_headers
2416
2417 Prepares request headers by ensuring that the attribute on the request
2418 object has been built.
2419
2420 =cut
2421
2422 sub prepare_headers { my $c = shift; $c->request->headers }
2423
2424 =head2 $c->prepare_parameters
2425
2426 Prepares parameters.
2427
2428 =cut
2429
2430 sub prepare_parameters {
2431     my $c = shift;
2432     $c->prepare_body_parameters;
2433     $c->engine->prepare_parameters( $c, @_ );
2434 }
2435
2436 =head2 $c->prepare_path
2437
2438 Prepares path and base.
2439
2440 =cut
2441
2442 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2443
2444 =head2 $c->prepare_query_parameters
2445
2446 Prepares query parameters.
2447
2448 =cut
2449
2450 sub prepare_query_parameters {
2451     my $c = shift;
2452
2453     $c->engine->prepare_query_parameters( $c, @_ );
2454 }
2455
2456 =head2 $c->log_request
2457
2458 Writes information about the request to the debug logs.  This includes:
2459
2460 =over 4
2461
2462 =item * Request method, path, and remote IP address
2463
2464 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2465
2466 =item * Request parameters
2467
2468 =item * File uploads
2469
2470 =back
2471
2472 =cut
2473
2474 sub log_request {
2475     my $c = shift;
2476
2477     return unless $c->debug;
2478
2479     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2480     my $request = $dump->[1];
2481
2482     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2483     $method ||= '';
2484     $path = '/' unless length $path;
2485     $address ||= '';
2486
2487     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2488     $path = decode_utf8($path);
2489
2490     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2491
2492     $c->log_request_headers($request->headers);
2493
2494     if ( my $keywords = $request->query_keywords ) {
2495         $c->log->debug("Query keywords are: $keywords");
2496     }
2497
2498     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2499
2500     $c->log_request_uploads($request);
2501 }
2502
2503 =head2 $c->log_response
2504
2505 Writes information about the response to the debug logs by calling
2506 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2507
2508 =cut
2509
2510 sub log_response {
2511     my $c = shift;
2512
2513     return unless $c->debug;
2514
2515     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2516     my $response = $dump->[1];
2517
2518     $c->log_response_status_line($response);
2519     $c->log_response_headers($response->headers);
2520 }
2521
2522 =head2 $c->log_response_status_line($response)
2523
2524 Writes one line of information about the response to the debug logs.  This includes:
2525
2526 =over 4
2527
2528 =item * Response status code
2529
2530 =item * Content-Type header (if present)
2531
2532 =item * Content-Length header (if present)
2533
2534 =back
2535
2536 =cut
2537
2538 sub log_response_status_line {
2539     my ($c, $response) = @_;
2540
2541     $c->log->debug(
2542         sprintf(
2543             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2544             $response->status                            || 'unknown',
2545             $response->headers->header('Content-Type')   || 'unknown',
2546             $response->headers->header('Content-Length') || 'unknown'
2547         )
2548     );
2549 }
2550
2551 =head2 $c->log_response_headers($headers);
2552
2553 Hook method which can be wrapped by plugins to log the response headers.
2554 No-op in the default implementation.
2555
2556 =cut
2557
2558 sub log_response_headers {}
2559
2560 =head2 $c->log_request_parameters( query => {}, body => {} )
2561
2562 Logs request parameters to debug logs
2563
2564 =cut
2565
2566 sub log_request_parameters {
2567     my $c          = shift;
2568     my %all_params = @_;
2569
2570     return unless $c->debug;
2571
2572     my $column_width = Catalyst::Utils::term_width() - 44;
2573     foreach my $type (qw(query body)) {
2574         my $params = $all_params{$type};
2575         next if ! keys %$params;
2576         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2577         for my $key ( sort keys %$params ) {
2578             my $param = $params->{$key};
2579             my $value = defined($param) ? $param : '';
2580             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2581         }
2582         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2583     }
2584 }
2585
2586 =head2 $c->log_request_uploads
2587
2588 Logs file uploads included in the request to the debug logs.
2589 The parameter name, filename, file type, and file size are all included in
2590 the debug logs.
2591
2592 =cut
2593
2594 sub log_request_uploads {
2595     my $c = shift;
2596     my $request = shift;
2597     return unless $c->debug;
2598     my $uploads = $request->uploads;
2599     if ( keys %$uploads ) {
2600         my $t = Text::SimpleTable->new(
2601             [ 12, 'Parameter' ],
2602             [ 26, 'Filename' ],
2603             [ 18, 'Type' ],
2604             [ 9,  'Size' ]
2605         );
2606         for my $key ( sort keys %$uploads ) {
2607             my $upload = $uploads->{$key};
2608             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2609                 $t->row( $key, $u->filename, $u->type, $u->size );
2610             }
2611         }
2612         $c->log->debug( "File Uploads are:\n" . $t->draw );
2613     }
2614 }
2615
2616 =head2 $c->log_request_headers($headers);
2617
2618 Hook method which can be wrapped by plugins to log the request headers.
2619 No-op in the default implementation.
2620
2621 =cut
2622
2623 sub log_request_headers {}
2624
2625 =head2 $c->log_headers($type => $headers)
2626
2627 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2628
2629 =cut
2630
2631 sub log_headers {
2632     my $c       = shift;
2633     my $type    = shift;
2634     my $headers = shift;    # an HTTP::Headers instance
2635
2636     return unless $c->debug;
2637
2638     my $column_width = Catalyst::Utils::term_width() - 28;
2639     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2640     $headers->scan(
2641         sub {
2642             my ( $name, $value ) = @_;
2643             $t->row( $name, $value );
2644         }
2645     );
2646     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2647 }
2648
2649
2650 =head2 $c->prepare_read
2651
2652 Prepares the input for reading.
2653
2654 =cut
2655
2656 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2657
2658 =head2 $c->prepare_request
2659
2660 Prepares the engine request.
2661
2662 =cut
2663
2664 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2665
2666 =head2 $c->prepare_uploads
2667
2668 Prepares uploads.
2669
2670 =cut
2671
2672 sub prepare_uploads {
2673     my $c = shift;
2674     $c->engine->prepare_uploads( $c, @_ );
2675 }
2676
2677 =head2 $c->prepare_write
2678
2679 Prepares the output for writing.
2680
2681 =cut
2682
2683 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2684
2685 =head2 $c->request_class
2686
2687 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2688
2689 =head2 $c->response_class
2690
2691 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2692
2693 =head2 $c->read( [$maxlength] )
2694
2695 Reads a chunk of data from the request body. This method is designed to
2696 be used in a while loop, reading C<$maxlength> bytes on every call.
2697 C<$maxlength> defaults to the size of the request if not specified.
2698
2699 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2700 directly.
2701
2702 Warning: If you use read(), Catalyst will not process the body,
2703 so you will not be able to access POST parameters or file uploads via
2704 $c->request.  You must handle all body parsing yourself.
2705
2706 =cut
2707
2708 sub read { my $c = shift; return $c->request->read( @_ ) }
2709
2710 =head2 $c->run
2711
2712 Starts the engine.
2713
2714 =cut
2715
2716 sub run {
2717   my $app = shift;
2718   $app->_make_immutable_if_needed;
2719   $app->engine_loader->needs_psgi_engine_compat_hack ?
2720     $app->engine->run($app, @_) :
2721       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2722 }
2723
2724 sub _make_immutable_if_needed {
2725     my $class = shift;
2726     my $meta = find_meta($class);
2727     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2728     if (
2729         $meta->is_immutable
2730         && ! { $meta->immutable_options }->{replace_constructor}
2731         && $isa_ca
2732     ) {
2733         warn("You made your application class ($class) immutable, "
2734             . "but did not inline the\nconstructor. "
2735             . "This will break catalyst, as your app \@ISA "
2736             . "Class::Accessor(::Fast)?\nPlease pass "
2737             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2738     }
2739     unless ($meta->is_immutable) {
2740         # XXX - FIXME warning here as you should make your app immutable yourself.
2741         $meta->make_immutable(
2742             replace_constructor => 1,
2743         );
2744     }
2745 }
2746
2747 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2748
2749 Sets an action in a given namespace.
2750
2751 =cut
2752
2753 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2754
2755 =head2 $c->setup_actions($component)
2756
2757 Sets up actions for a component.
2758
2759 =cut
2760
2761 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2762
2763 =head2 $c->setup_components
2764
2765 This method is called internally to set up the application's components.
2766
2767 It finds modules by calling the L<locate_components> method, expands them to
2768 package names with the L<expand_component_module> method, and then installs
2769 each component into the application.
2770
2771 The C<setup_components> config option is passed to both of the above methods.
2772
2773 Installation of each component is performed by the L<setup_component> method,
2774 below.
2775
2776 =cut
2777
2778 sub setup_components {
2779     my $class = shift;
2780
2781     my $config  = $class->config->{ setup_components };
2782
2783     my @comps = $class->locate_components($config);
2784     my %comps = map { $_ => 1 } @comps;
2785
2786     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2787     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2788         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2789     ) if $deprecatedcatalyst_component_names;
2790
2791     for my $component ( @comps ) {
2792
2793         # We pass ignore_loaded here so that overlay files for (e.g.)
2794         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2795         # we know M::P::O found a file on disk so this is safe
2796
2797         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2798     }
2799
2800     for my $component (@comps) {
2801         my $instance = $class->components->{ $component } = $class->setup_component($component);
2802         my @expanded_components = $instance->can('expand_modules')
2803             ? $instance->expand_modules( $component, $config )
2804             : $class->expand_component_module( $component, $config );
2805         for my $component (@expanded_components) {
2806             next if $comps{$component};
2807             $class->components->{ $component } = $class->setup_component($component);
2808         }
2809     }
2810 }
2811
2812 =head2 $c->locate_components( $setup_component_config )
2813
2814 This method is meant to provide a list of component modules that should be
2815 setup for the application.  By default, it will use L<Module::Pluggable>.
2816
2817 Specify a C<setup_components> config option to pass additional options directly
2818 to L<Module::Pluggable>. To add additional search paths, specify a key named
2819 C<search_extra> as an array reference. Items in the array beginning with C<::>
2820 will have the application class name prepended to them.
2821
2822 =cut
2823
2824 sub locate_components {
2825     my $class  = shift;
2826     my $config = shift;
2827
2828     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
2829     my $extra   = delete $config->{ search_extra } || [];
2830
2831     unshift @paths, @$extra;
2832
2833     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
2834       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
2835       %$config
2836     )->plugins } @paths;
2837
2838     return @comps;
2839 }
2840
2841 =head2 $c->expand_component_module( $component, $setup_component_config )
2842
2843 Components found by C<locate_components> will be passed to this method, which
2844 is expected to return a list of component (package) names to be set up.
2845
2846 =cut
2847
2848 sub expand_component_module {
2849     my ($class, $module) = @_;
2850     return Devel::InnerPackage::list_packages( $module );
2851 }
2852
2853 =head2 $c->setup_component
2854
2855 =cut
2856
2857 sub setup_component {
2858     my( $class, $component ) = @_;
2859
2860     unless ( $component->can( 'COMPONENT' ) ) {
2861         return $component;
2862     }
2863
2864     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2865     my $config = $class->config->{ $suffix } || {};
2866     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2867     # methods also pass it. local to avoid pointlessly shitting in config
2868     # for the debug screen, as $component is already the key name.
2869     local $config->{catalyst_component_name} = $component;
2870
2871     my $instance = eval { $component->COMPONENT( $class, $config ); };
2872
2873     if ( my $error = $@ ) {
2874         chomp $error;
2875         Catalyst::Exception->throw(
2876             message => qq/Couldn't instantiate component "$component", "$error"/
2877         );
2878     }
2879
2880     unless (blessed $instance) {
2881         my $metaclass = Moose::Util::find_meta($component);
2882         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2883         my $component_method_from = $method_meta->associated_metaclass->name;
2884         my $value = defined($instance) ? $instance : 'undef';
2885         Catalyst::Exception->throw(
2886             message =>
2887             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2888         );
2889     }
2890     return $instance;
2891 }
2892
2893 =head2 $c->setup_dispatcher
2894
2895 Sets up dispatcher.
2896
2897 =cut
2898
2899 sub setup_dispatcher {
2900     my ( $class, $dispatcher ) = @_;
2901
2902     if ($dispatcher) {
2903         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2904     }
2905
2906     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2907         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2908     }
2909
2910     unless ($dispatcher) {
2911         $dispatcher = $class->dispatcher_class;
2912     }
2913
2914     load_class($dispatcher);
2915
2916     # dispatcher instance
2917     $class->dispatcher( $dispatcher->new );
2918 }
2919
2920 =head2 $c->setup_engine
2921
2922 Sets up engine.
2923
2924 =cut
2925
2926 sub engine_class {
2927     my ($class, $requested_engine) = @_;
2928
2929     if (!$class->engine_loader || $requested_engine) {
2930         $class->engine_loader(
2931             Catalyst::EngineLoader->new({
2932                 application_name => $class,
2933                 (defined $requested_engine
2934                      ? (catalyst_engine_class => $requested_engine) : ()),
2935             }),
2936         );
2937     }
2938
2939     $class->engine_loader->catalyst_engine_class;
2940 }
2941
2942 sub setup_engine {
2943     my ($class, $requested_engine) = @_;
2944
2945     my $engine = do {
2946         my $loader = $class->engine_loader;
2947
2948         if (!$loader || $requested_engine) {
2949             $loader = Catalyst::EngineLoader->new({
2950                 application_name => $class,
2951                 (defined $requested_engine
2952                      ? (requested_engine => $requested_engine) : ()),
2953             }),
2954
2955             $class->engine_loader($loader);
2956         }
2957
2958         $loader->catalyst_engine_class;
2959     };
2960
2961     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2962     return if $class->loading_psgi_file;
2963
2964     load_class($engine);
2965
2966     if ($ENV{MOD_PERL}) {
2967         my $apache = $class->engine_loader->auto;
2968
2969         my $meta = find_meta($class);
2970         my $was_immutable = $meta->is_immutable;
2971         my %immutable_options = $meta->immutable_options;
2972         $meta->make_mutable if $was_immutable;
2973
2974         $meta->add_method(handler => sub {
2975             my $r = shift;
2976             my $psgi_app = $class->_finalized_psgi_app;
2977             $apache->call_app($r, $psgi_app);
2978         });
2979
2980         $meta->make_immutable(%immutable_options) if $was_immutable;
2981     }
2982
2983     $class->engine( $engine->new );
2984
2985     return;
2986 }
2987
2988 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2989 ## build in server support (back compat support for pre psgi port behavior).
2990 ## This is so that we don't build a new psgi app for each request when using
2991 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2992
2993 sub _finalized_psgi_app {
2994     my ($app) = @_;
2995
2996     unless ($app->_psgi_app) {
2997         my $psgi_app = $app->_setup_psgi_app;
2998         $app->_psgi_app($psgi_app);
2999     }
3000
3001     return $app->_psgi_app;
3002 }
3003
3004 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
3005 ## home directory and load that and return it (just assume it is doing the
3006 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
3007 ## in default_middleware and return it ( this is for backward compatibility
3008 ## with pre psgi port behavior ).
3009
3010 sub _setup_psgi_app {
3011     my ($app) = @_;
3012
3013     for my $home (Path::Class::Dir->new($app->config->{home})) {
3014         my $psgi_file = $home->file(
3015             Catalyst::Utils::appprefix($app) . '.psgi',
3016         );
3017
3018         next unless -e $psgi_file;
3019
3020         # If $psgi_file calls ->setup_engine, it's doing so to load
3021         # Catalyst::Engine::PSGI. But if it does that, we're only going to
3022         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
3023         # anyway. So set a flag (ick) that tells setup_engine not to populate
3024         # $c->engine or do any other things we might regret.
3025
3026         $app->loading_psgi_file(1);
3027         my $psgi_app = Plack::Util::load_psgi($psgi_file);
3028         $app->loading_psgi_file(0);
3029
3030         return $psgi_app
3031             unless $app->engine_loader->needs_psgi_engine_compat_hack;
3032
3033         warn <<"EOW";
3034 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
3035
3036 Its content has been ignored. Please consult the Catalyst::Upgrading
3037 documentation on how to upgrade from Catalyst::Engine::PSGI.
3038 EOW
3039     }
3040
3041     return $app->apply_default_middlewares($app->psgi_app);
3042 }
3043
3044 =head2 $c->apply_default_middlewares
3045
3046 Adds the following L<Plack> middlewares to your application, since they are
3047 useful and commonly needed:
3048
3049 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3050 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3051 is smart enough to conditionally apply itself).
3052
3053 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3054 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3055 an indication that your server is running behind a proxy frontend.  However in
3056 2014 this is often not the case.  We preserve this code for backwards compatibility
3057 however I B<highly> recommend that if you are running the server behind a front
3058 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3059 setting to true for your environment configurations that run behind a proxy.  This
3060 way if you change your front end proxy address someday your code would inexplicably
3061 stop working as expected.
3062
3063 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3064 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3065 $ENV{SCRIPT_NAME}.
3066
3067 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3068 adding via C<registered_middleware> rather than this method.
3069
3070 If you are using Lighttpd or IIS6 you may wish to apply these middlewares.  In
3071 general this is no longer a common case but we have this here for backward
3072 compatibility.
3073
3074 =cut
3075
3076
3077 sub apply_default_middlewares {
3078     my ($app, $psgi_app) = @_;
3079
3080     # Don't add this conditional IF we are explicitly saying we want the
3081     # frontend proxy support.  We don't need it here since if that is the
3082     # case it will be always loaded in the default_middleware.
3083
3084     unless($app->config->{using_frontend_proxy}) {
3085       $psgi_app = Plack::Middleware::Conditional->wrap(
3086           $psgi_app,
3087           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3088           condition => sub {
3089               my ($env) = @_;
3090               return if $app->config->{ignore_frontend_proxy};
3091               return $env->{REMOTE_ADDR} eq '127.0.0.1';
3092           },
3093       );
3094     }
3095
3096     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3097     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3098     $psgi_app = Plack::Middleware::Conditional->wrap(
3099         $psgi_app,
3100         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3101         condition => sub {
3102             my ($env) = @_;
3103             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3104             return unless $1 < 4.23;
3105             1;
3106         },
3107     );
3108
3109     # we're applying this unconditionally as the middleware itself already makes
3110     # sure it doesn't fuck things up if it's not running under one of the right
3111     # IIS versions
3112     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3113
3114     # And another IIS issue, this time with IIS7.
3115     $psgi_app = Plack::Middleware::Conditional->wrap(
3116         $psgi_app,
3117         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3118         condition => sub {
3119             my ($env) = @_;
3120             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3121         },
3122     );
3123
3124     return $psgi_app;
3125 }
3126
3127 =head2 App->psgi_app
3128
3129 =head2 App->to_app
3130
3131 Returns a PSGI application code reference for the catalyst application
3132 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3133 method called.  We do however apply C<registered_middleware> since those are
3134 integral to how L<Catalyst> functions.  Also, unlike starting your application
3135 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3136 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3137 scripts in your $HOME directory.
3138
3139 B<NOTE> C<apply_default_middlewares> was originally created when the first PSGI
3140 port was done for v5.90000.  These are middlewares that are added to achieve
3141 backward compatibility with older applications.  If you start your application
3142 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3143 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3144 automatically.  This was done so that pre and post PSGI port applications would
3145 work the same way.
3146
3147 This is what you want to be using to retrieve the PSGI application code
3148 reference of your Catalyst application for use in a custom F<.psgi> or in your
3149 own created server modules.
3150
3151 =cut
3152
3153 *to_app = \&psgi_app;
3154
3155 sub psgi_app {
3156     my ($app) = @_;
3157     my $psgi = $app->engine->build_psgi_app($app);
3158     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3159 }
3160
3161 =head2 $c->setup_home
3162
3163 Sets up the home directory.
3164
3165 =cut
3166
3167 sub setup_home {
3168     my ( $class, $home ) = @_;
3169
3170     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3171         $home = $env;
3172     }
3173
3174     $home ||= Catalyst::Utils::home($class);
3175
3176     if ($home) {
3177         #I remember recently being scolded for assigning config values like this
3178         $class->config->{home} ||= $home;
3179         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3180     }
3181 }
3182
3183 =head2 $c->setup_encoding
3184
3185 Sets up the input/output encoding. See L<ENCODING>
3186
3187 =cut
3188
3189 sub setup_encoding {
3190     my $c = shift;
3191     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3192         # Ok, so the user has explicitly said "I don't want encoding..."
3193         return;
3194     } else {
3195       my $enc = defined($c->config->{encoding}) ?
3196         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3197       $c->encoding($enc);
3198     }
3199 }
3200
3201 =head2 handle_unicode_encoding_exception
3202
3203 Hook to let you customize how encoding errors are handled.  By default
3204 we just throw an exception.  Receives a hashref of debug information.
3205 Example:
3206
3207     $c->handle_unicode_encoding_exception({
3208         param_value => $value,
3209         error_msg => $_,
3210             encoding_step => 'params',
3211         });
3212
3213 =cut
3214
3215 sub handle_unicode_encoding_exception {
3216     my ( $self, $exception_ctx ) = @_;
3217     die $exception_ctx->{error_msg};
3218 }
3219
3220 # Some unicode helpers cargo culted from the old plugin.  These could likely
3221 # be neater.
3222
3223 sub _handle_unicode_decoding {
3224     my ( $self, $value ) = @_;
3225
3226     return unless defined $value;
3227
3228     ## I think this mess is to support the old nested
3229     if ( ref $value eq 'ARRAY' ) {
3230         foreach ( @$value ) {
3231             $_ = $self->_handle_unicode_decoding($_);
3232         }
3233         return $value;
3234     }
3235     elsif ( ref $value eq 'HASH' ) {
3236         foreach (keys %$value) {
3237             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3238             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3239
3240             # If the key was encoded we now have two (the original and current so
3241             # delete the original.
3242             delete $value->{$_} if $_ ne $encoded_key;
3243         }
3244         return $value;
3245     }
3246     else {
3247         return $self->_handle_param_unicode_decoding($value);
3248     }
3249 }
3250
3251 sub _handle_param_unicode_decoding {
3252     my ( $self, $value ) = @_;
3253     return unless defined $value; # not in love with just ignoring undefs - jnap
3254     return $value if blessed($value); #don't decode when the value is an object.
3255
3256     my $enc = $self->encoding;
3257     return try {
3258       $enc->decode( $value, $self->_encode_check );
3259     }
3260     catch {
3261         $self->handle_unicode_encoding_exception({
3262             param_value => $value,
3263             error_msg => $_,
3264             encoding_step => 'params',
3265         });
3266     };
3267 }
3268
3269 =head2 $c->setup_log
3270
3271 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3272 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3273 log to.
3274
3275 This method also installs a C<debug> method that returns a true value into the
3276 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3277 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3278
3279 Note that if the log has already been setup, by either a previous call to
3280 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3281 that this method won't actually set up the log object.
3282
3283 =cut
3284
3285 sub setup_log {
3286     my ( $class, $levels ) = @_;
3287
3288     $levels ||= '';
3289     $levels =~ s/^\s+//;
3290     $levels =~ s/\s+$//;
3291     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3292
3293     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3294     if ( defined $env_debug ) {
3295         $levels{debug} = 1 if $env_debug; # Ugly!
3296         delete($levels{debug}) unless $env_debug;
3297     }
3298
3299     unless ( $class->log ) {
3300         $class->log( Catalyst::Log->new(keys %levels) );
3301     }
3302
3303     if ( $levels{debug} ) {
3304         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3305         $class->log->debug('Debug messages enabled');
3306     }
3307 }
3308
3309 =head2 $c->setup_plugins
3310
3311 Sets up plugins.
3312
3313 =cut
3314
3315 =head2 $c->setup_stats
3316
3317 Sets up timing statistics class.
3318
3319 =cut
3320
3321 sub setup_stats {
3322     my ( $class, $stats ) = @_;
3323
3324     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3325
3326     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3327     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3328         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3329         $class->log->debug('Statistics enabled');
3330     }
3331 }
3332
3333
3334 =head2 $c->registered_plugins
3335
3336 Returns a sorted list of the plugins which have either been stated in the
3337 import list.
3338
3339 If passed a given plugin name, it will report a boolean value indicating
3340 whether or not that plugin is loaded.  A fully qualified name is required if
3341 the plugin name does not begin with C<Catalyst::Plugin::>.
3342
3343  if ($c->registered_plugins('Some::Plugin')) {
3344      ...
3345  }
3346
3347 =cut
3348
3349 {
3350
3351     sub registered_plugins {
3352         my $proto = shift;
3353         return sort keys %{ $proto->_plugins } unless @_;
3354         my $plugin = shift;
3355         return 1 if exists $proto->_plugins->{$plugin};
3356         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3357     }
3358
3359     sub _register_plugin {
3360         my ( $proto, $plugin, $instant ) = @_;
3361         my $class = ref $proto || $proto;
3362
3363         load_class( $plugin );
3364         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3365             if $plugin->isa( 'Catalyst::Component' );
3366         my $plugin_meta = Moose::Meta::Class->create($plugin);
3367         if (!$plugin_meta->has_method('new')
3368             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3369             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3370         }
3371         if (!$instant && !$proto->_plugins->{$plugin}) {
3372             my $meta = Class::MOP::get_metaclass_by_name($class);
3373             $meta->superclasses($plugin, $meta->superclasses);
3374         }
3375         $proto->_plugins->{$plugin} = 1;
3376         return $class;
3377     }
3378
3379     sub _default_plugins { return qw() }
3380
3381     sub setup_plugins {
3382         my ( $class, $plugins ) = @_;
3383
3384         $class->_plugins( {} ) unless $class->_plugins;
3385         $plugins = [ grep {
3386             m/Unicode::Encoding/ ? do {
3387                 $class->log->warn(
3388                     'Unicode::Encoding plugin is auto-applied,'
3389                     . ' please remove this from your appclass'
3390                     . ' and make sure to define "encoding" config'
3391                 );
3392                 unless (exists $class->config->{'encoding'}) {
3393                   $class->config->{'encoding'} = 'UTF-8';
3394                 }
3395                 () }
3396                 : $_
3397         } @$plugins ];
3398         push @$plugins, $class->_default_plugins;
3399         $plugins = Data::OptList::mkopt($plugins || []);
3400
3401         my @plugins = map {
3402             [ Catalyst::Utils::resolve_namespace(
3403                   $class . '::Plugin',
3404                   'Catalyst::Plugin', $_->[0]
3405               ),
3406               $_->[1],
3407             ]
3408          } @{ $plugins };
3409
3410         for my $plugin ( reverse @plugins ) {
3411             load_class($plugin->[0], $plugin->[1]);
3412             my $meta = find_meta($plugin->[0]);
3413             next if $meta && $meta->isa('Moose::Meta::Role');
3414
3415             $class->_register_plugin($plugin->[0]);
3416         }
3417
3418         my @roles =
3419             map  { $_->[0]->name, $_->[1] }
3420             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3421             map  { [find_meta($_->[0]), $_->[1]] }
3422             @plugins;
3423
3424         Moose::Util::apply_all_roles(
3425             $class => @roles
3426         ) if @roles;
3427     }
3428 }
3429
3430 =head2 default_middleware
3431
3432 Returns a list of instantiated PSGI middleware objects which is the default
3433 middleware that is active for this application (taking any configuration
3434 options into account, excluding your custom added middleware via the C<psgi_middleware>
3435 configuration option).  You can override this method if you wish to change
3436 the default middleware (although do so at risk since some middleware is vital
3437 to application function.)
3438
3439 The current default middleware list is:
3440
3441       Catalyst::Middleware::Stash
3442       Plack::Middleware::HTTPExceptions
3443       Plack::Middleware::RemoveRedundantBody
3444       Plack::Middleware::FixMissingBodyInRedirect
3445       Plack::Middleware::ContentLength
3446       Plack::Middleware::MethodOverride
3447       Plack::Middleware::Head
3448
3449 If the configuration setting C<using_frontend_proxy> is true we add:
3450
3451       Plack::Middleware::ReverseProxy
3452
3453 If the configuration setting C<using_frontend_proxy_path> is true we add:
3454
3455       Plack::Middleware::ReverseProxyPath
3456
3457 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3458 L<Catalyst> distribution so if you want to use this option you should add it to
3459 your project distribution file.
3460
3461 These middlewares will be added at L</setup_middleware> during the
3462 L</setup> phase of application startup.
3463
3464 =cut
3465
3466 sub default_middleware {
3467     my $class = shift;
3468     my @mw = (
3469       Catalyst::Middleware::Stash->new,
3470       Plack::Middleware::HTTPExceptions->new,
3471       Plack::Middleware::RemoveRedundantBody->new,
3472       Plack::Middleware::FixMissingBodyInRedirect->new,
3473       Plack::Middleware::ContentLength->new,
3474       Plack::Middleware::MethodOverride->new,
3475       Plack::Middleware::Head->new);
3476
3477     if($class->config->{using_frontend_proxy}) {
3478         push @mw, Plack::Middleware::ReverseProxy->new;
3479     }
3480
3481     if($class->config->{using_frontend_proxy_path}) {
3482         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3483             push @mw, Plack::Middleware::ReverseProxyPath->new;
3484         } else {
3485           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3486         }
3487     }
3488
3489     return @mw;
3490 }
3491
3492 =head2 registered_middlewares
3493
3494 Read only accessor that returns an array of all the middleware in the order
3495 that they were added (which is the REVERSE of the order they will be applied).
3496
3497 The values returned will be either instances of L<Plack::Middleware> or of a
3498 compatible interface, or a coderef, which is assumed to be inlined middleware
3499
3500 =head2 setup_middleware (?@middleware)
3501
3502 Read configuration information stored in configuration key C<psgi_middleware> or
3503 from passed @args.
3504
3505 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3506 to use it to enable L<Plack::Middleware>
3507
3508 This method is automatically called during 'setup' of your application, so
3509 you really don't need to invoke it.  However you may do so if you find the idea
3510 of loading middleware via configuration weird :).  For example:
3511
3512     package MyApp;
3513
3514     use Catalyst;
3515
3516     __PACKAGE__->setup_middleware('Head');
3517     __PACKAGE__->setup;
3518
3519 When we read middleware definitions from configuration, we reverse the list
3520 which sounds odd but is likely how you expect it to work if you have prior
3521 experience with L<Plack::Builder> or if you previously used the plugin
3522 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3523
3524 So basically your middleware handles an incoming request from the first
3525 registered middleware, down and handles the response from the last middleware
3526 up.
3527
3528 =cut
3529
3530 sub registered_middlewares {
3531     my $class = shift;
3532     if(my $middleware = $class->_psgi_middleware) {
3533         my @mw = ($class->default_middleware, @$middleware);
3534
3535         if($class->config->{using_frontend_proxy}) {
3536           push @mw, Plack::Middleware::ReverseProxy->new;
3537         }
3538
3539         return @mw;
3540     } else {
3541         die "You cannot call ->registered_middlewares until middleware has been setup";
3542     }
3543 }
3544
3545 sub setup_middleware {
3546     my $class = shift;
3547     my @middleware_definitions;
3548
3549     # If someone calls this method you can add middleware with args.  However if its
3550     # called without an arg we need to setup the configuration middleware.
3551     if(@_) {
3552       @middleware_definitions = reverse(@_);
3553     } else {
3554       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3555         unless $class->finalized_default_middleware;
3556       $class->finalized_default_middleware(1); # Only do this once, just in case some people call setup over and over...
3557     }
3558
3559     my @middleware = ();
3560     while(my $next = shift(@middleware_definitions)) {
3561         if(ref $next) {
3562             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3563                 push @middleware, $next;
3564             } elsif(ref $next eq 'CODE') {
3565                 push @middleware, $next;
3566             } elsif(ref $next eq 'HASH') {
3567                 my $namespace = shift @middleware_definitions;
3568                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3569                 push @middleware, $mw;
3570             } else {
3571               die "I can't handle middleware definition ${\ref $next}";
3572             }
3573         } else {
3574           my $mw = $class->Catalyst::Utils::build_middleware($next);
3575           push @middleware, $mw;
3576         }
3577     }
3578
3579     my @existing = @{$class->_psgi_middleware || []};
3580     $class->_psgi_middleware([@middleware,@existing,]);
3581 }
3582
3583 =head2 registered_data_handlers
3584
3585 A read only copy of registered Data Handlers returned as a Hash, where each key
3586 is a content type and each value is a subref that attempts to decode that content
3587 type.
3588
3589 =head2 setup_data_handlers (?@data_handler)
3590
3591 Read configuration information stored in configuration key C<data_handlers> or
3592 from passed @args.
3593
3594 See under L</CONFIGURATION> information regarding C<data_handlers>.
3595
3596 This method is automatically called during 'setup' of your application, so
3597 you really don't need to invoke it.
3598
3599 =head2 default_data_handlers
3600
3601 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3602 only two default data handlers, for 'application/json' and an alternative to
3603 'application/x-www-form-urlencoded' which supposed nested form parameters via
3604 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3605
3606 The 'application/json' data handler is used to parse incoming JSON into a Perl
3607 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3608 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3609 JSON decoder, and has the smallest dependency impact.
3610
3611 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3612 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3613 order to get the best performance.  You should add either to your dependency
3614 list (Makefile.PL, dist.ini, cpanfile, etc.)
3615
3616 =cut
3617
3618 sub registered_data_handlers {
3619     my $class = shift;
3620     if(my $data_handlers = $class->_data_handlers) {
3621         return %$data_handlers;
3622     } else {
3623         $class->setup_data_handlers;
3624         return $class->registered_data_handlers;
3625     }
3626 }
3627
3628 sub setup_data_handlers {
3629     my ($class, %data_handler_callbacks) = @_;
3630     %data_handler_callbacks = (
3631       %{$class->default_data_handlers},
3632       %{$class->config->{'data_handlers'}||+{}},
3633       %data_handler_callbacks);
3634
3635     $class->_data_handlers(\%data_handler_callbacks);
3636 }
3637
3638 sub default_data_handlers {
3639     my ($class) = @_;
3640     return +{
3641       'application/x-www-form-urlencoded' => sub {
3642           my ($fh, $req) = @_;
3643           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3644           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3645             ->can('build_cgi_struct')->($params);
3646       },
3647       'application/json' => sub {
3648           my ($fh, $req) = @_;
3649           my $parser = Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON');
3650           my $slurped;
3651           return eval {
3652             local $/;
3653             $slurped = $fh->getline;
3654             $parser->can("decode_json")->($slurped); # decode_json does utf8 decoding for us
3655           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
3656         },
3657     };
3658 }
3659
3660 sub _handle_http_exception {
3661     my ( $self, $error ) = @_;
3662     if (
3663            !$self->config->{always_catch_http_exceptions}
3664         && blessed $error
3665         && (
3666             $error->can('as_psgi')
3667             || (   $error->can('code')
3668                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
3669         )
3670       )
3671     {
3672         return 1;
3673     }
3674 }
3675
3676 =head2 $c->stack
3677
3678 Returns an arrayref of the internal execution stack (actions that are
3679 currently executing).
3680
3681 =head2 $c->stats
3682
3683 Returns the current timing statistics object. By default Catalyst uses
3684 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3685 L<< stats_class|/"$c->stats_class" >>.
3686
3687 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3688 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3689 profile explicitly, although MyApp.pm still won't profile nor output anything
3690 by itself.
3691
3692 =head2 $c->stats_class
3693
3694 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3695
3696 =head2 $c->use_stats
3697
3698 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3699
3700 Note that this is a static method, not an accessor and should be overridden
3701 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3702
3703 =cut
3704
3705 sub use_stats { 0 }
3706
3707
3708 =head2 $c->write( $data )
3709
3710 Writes $data to the output stream. When using this method directly, you
3711 will need to manually set the C<Content-Length> header to the length of
3712 your output data, if known.
3713
3714 =cut
3715
3716 sub write {
3717     my $c = shift;
3718
3719     # Finalize headers if someone manually writes output (for compat)
3720     $c->finalize_headers;
3721
3722     return $c->response->write( @_ );
3723 }
3724
3725 =head2 version
3726
3727 Returns the Catalyst version number. Mostly useful for "powered by"
3728 messages in template systems.
3729
3730 =cut
3731
3732 sub version { return $Catalyst::VERSION }
3733
3734 =head1 CONFIGURATION
3735
3736 There are a number of 'base' config variables which can be set:
3737
3738 =over
3739
3740 =item *
3741
3742 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
3743 rethrows errors conforming to the interface described by
3744 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
3745 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
3746
3747 =item *
3748
3749 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3750
3751 =item *
3752
3753 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3754
3755 =item *
3756
3757 C<disable_component_resolution_regex_fallback> - Turns
3758 off the deprecated component resolution functionality so
3759 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3760 are called then regex search will not be attempted on string values and
3761 instead C<undef> will be returned.
3762
3763 =item *
3764
3765 C<home> - The application home directory. In an uninstalled application,
3766 this is the top level application directory. In an installed application,
3767 this will be the directory containing C<< MyApp.pm >>.
3768
3769 =item *
3770
3771 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3772
3773 =item *
3774
3775 C<name> - The name of the application in debug messages and the debug and
3776 welcome screens
3777
3778 =item *
3779
3780 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3781 until it is accessed. This allows you to (for example) check authentication (and reject
3782 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3783
3784 =item *
3785
3786 C<root> - The root directory for templates. Usually this is just a
3787 subdirectory of the home directory, but you can set it to change the
3788 templates to a different directory.
3789
3790 =item *
3791
3792 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3793 namespaces from which components will be loaded (and constructed and stored in
3794 C<< $c->components >>).
3795
3796 =item *
3797
3798 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3799 to be shown in hit debug tables in the test server.
3800
3801 =item *
3802
3803 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3804 variable should be used for determining the request path.
3805
3806 Most web server environments pass the requested path to the application using environment variables,
3807 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3808 exposed as C<< $c->request->base >>) and the request path below that base.
3809
3810 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3811 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3812
3813 =over
3814
3815 =item use_request_uri_for_path => 0
3816
3817 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3818 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3819 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3820 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3821
3822 However this method has the major disadvantage that it is impossible to correctly decode some elements
3823 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3824 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3825 can't distinguish / vs %2F in paths (in addition to other encoded values).
3826
3827 =item use_request_uri_for_path => 1
3828
3829 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3830 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3831 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3832
3833 Given that this method of path resolution is provably more correct, it is recommended that you use
3834 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3835 aware of the implications of not being able to handle encoded URI paths correctly.
3836
3837 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3838 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3839 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3840 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3841 C<< $c->request->base >> will be incorrect.
3842
3843 =back
3844
3845 =item *
3846
3847 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3848
3849 =item *
3850
3851 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
3852 installed, otherwise log an error).  This is useful if your application is not running on the
3853 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
3854 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
3855 This has been done since not all people need this feature and we wish to restrict the growth of
3856 L<Catalyst> dependencies.
3857
3858 =item *
3859
3860 C<encoding> - See L</ENCODING>
3861
3862 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
3863 value to undef.
3864
3865 =item *
3866
3867 C<abort_chain_on_error_fix>
3868
3869 When there is an error in an action chain, the default behavior is to continue
3870 processing the remaining actions and then catch the error upon chain end.  This
3871 can lead to running actions when the application is in an unexpected state.  If
3872 you have this issue, setting this config value to true will promptly exit a
3873 chain when there is an error raised in any action (thus terminating the chain
3874 early.)
3875
3876 use like:
3877
3878     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3879
3880 In the future this might become the default behavior.
3881
3882 =item *
3883
3884 C<use_hash_multivalue_in_request>
3885
3886 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3887 and C<parameters> return a hashref where values might be scalar or an arrayref
3888 depending on the incoming data.  In many cases this can be undesirable as it
3889 leads one to writing defensive code like the following:
3890
3891     my ($val) = ref($c->req->parameters->{a}) ?
3892       @{$c->req->parameters->{a}} :
3893         $c->req->parameters->{a};
3894
3895 Setting this configuration item to true will make L<Catalyst> populate the
3896 attributes underlying these methods with an instance of L<Hash::MultiValue>
3897 which is used by L<Plack::Request> and others to solve this very issue.  You
3898 may prefer this behavior to the default, if so enable this option (be warned
3899 if you enable it in a legacy application we are not sure if it is completely
3900 backwardly compatible).
3901
3902 =item *
3903
3904 C<skip_complex_post_part_handling>
3905
3906 When creating body parameters from a POST, if we run into a multpart POST
3907 that does not contain uploads, but instead contains inlined complex data
3908 (very uncommon) we cannot reliably convert that into field => value pairs.  So
3909 instead we create an instance of L<Catalyst::Request::PartData>.  If this causes
3910 issue for you, you can disable this by setting C<skip_complex_post_part_handling>
3911 to true (default is false).
3912
3913 =item *
3914
3915 C<skip_body_param_unicode_decoding>
3916
3917 Generally we decode incoming POST params based on your declared encoding (the
3918 default for this is to decode UTF-8).  If this is causing you trouble and you
3919 do not wish to turn all encoding support off (with the C<encoding> configuration
3920 parameter) you may disable this step atomically by setting this configuration
3921 parameter to true.
3922
3923 =item *
3924
3925 C<do_not_decode_query>
3926
3927 If true, then do not try to character decode any wide characters in your
3928 request URL query or keywords.  Most readings of the relevent specifications
3929 suggest these should be UTF-* encoded, which is the default that L<Catalyst>
3930 will use, hwoever if you are creating a lot of URLs manually or have external
3931 evil clients, this might cause you trouble.  If you find the changes introduced
3932 in Catalyst version 5.90080+ break some of your query code, you may disable
3933 the UTF-8 decoding globally using this configuration.
3934
3935 This setting takes precedence over C<default_query_encoding> and
3936 C<decode_query_using_global_encoding>
3937
3938 =item *
3939
3940 C<default_query_encoding>
3941
3942 By default we decode query and keywords in your request URL using UTF-8, which
3943 is our reading of the relevent specifications.  This setting allows one to
3944 specify a fixed value for how to decode your query.  You might need this if
3945 you are doing a lot of custom encoding of your URLs and not using UTF-8.
3946
3947 This setting take precedence over C<decode_query_using_global_encoding>.
3948
3949 =item *
3950
3951 C<decode_query_using_global_encoding>
3952
3953 Setting this to true will default your query decoding to whatever your
3954 general global encoding is (the default is UTF-8).
3955
3956 =item *
3957
3958 C<use_chained_args_0_special_case>
3959
3960 In older versions of Catalyst, when more than one action matched the same path
3961 AND all those matching actions declared Args(0), we'd break the tie by choosing
3962 the first action defined.  We now normalized how Args(0) works so that it
3963 follows the same rule as Args(N), which is to say when we need to break a tie
3964 we choose the LAST action defined.  If this breaks your code and you don't
3965 have time to update to follow the new normalized approach, you may set this
3966 value to true and it will globally revert to the original chaining behavior.
3967
3968 =item *
3969
3970 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3971
3972 =item *
3973
3974 C<data_handlers> - See L<DATA HANDLERS>.
3975
3976 =back
3977
3978 =head1 EXCEPTIONS
3979
3980 Generally when you throw an exception inside an Action (or somewhere in
3981 your stack, such as in a model that an Action is calling) that exception
3982 is caught by Catalyst and unless you either catch it yourself (via eval
3983 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
3984 will eventually reach L</finalize_errors> and return either the debugging
3985 error stack page, or the default error page.  However, if your exception
3986 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
3987 instead rethrow it so that it can be handled by that middleware (which
3988 is part of the default middleware).  For example this would allow
3989
3990     use HTTP::Throwable::Factory 'http_throw';
3991
3992     sub throws_exception :Local {
3993       my ($self, $c) = @_;
3994
3995       http_throw(SeeOther => { location =>
3996         $c->uri_for($self->action_for('redirect')) });
3997
3998     }
3999
4000 =head1 INTERNAL ACTIONS
4001
4002 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
4003 C<_ACTION>, and C<_END>. These are by default not shown in the private
4004 action table, but you can make them visible with a config parameter.
4005
4006     MyApp->config(show_internal_actions => 1);
4007
4008 =head1 ON-DEMAND PARSER
4009
4010 The request body is usually parsed at the beginning of a request,
4011 but if you want to handle input yourself, you can enable on-demand
4012 parsing with a config parameter.
4013
4014     MyApp->config(parse_on_demand => 1);
4015
4016 =head1 PROXY SUPPORT
4017
4018 Many production servers operate using the common double-server approach,
4019 with a lightweight frontend web server passing requests to a larger
4020 backend server. An application running on the backend server must deal
4021 with two problems: the remote user always appears to be C<127.0.0.1> and
4022 the server's hostname will appear to be C<localhost> regardless of the
4023 virtual host that the user connected through.
4024
4025 Catalyst will automatically detect this situation when you are running
4026 the frontend and backend servers on the same machine. The following
4027 changes are made to the request.
4028
4029     $c->req->address is set to the user's real IP address, as read from
4030     the HTTP X-Forwarded-For header.
4031
4032     The host value for $c->req->base and $c->req->uri is set to the real
4033     host, as read from the HTTP X-Forwarded-Host header.
4034
4035 Additionally, you may be running your backend application on an insecure
4036 connection (port 80) while your frontend proxy is running under SSL.  If there
4037 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
4038 tell Catalyst what port the frontend listens on.  This will allow all URIs to
4039 be created properly.
4040
4041 In the case of passing in:
4042
4043     X-Forwarded-Port: 443
4044
4045 All calls to C<uri_for> will result in an https link, as is expected.
4046
4047 Obviously, your web server must support these headers for this to work.
4048
4049 In a more complex server farm environment where you may have your
4050 frontend proxy server(s) on different machines, you will need to set a
4051 configuration option to tell Catalyst to read the proxied data from the
4052 headers.
4053
4054     MyApp->config(using_frontend_proxy => 1);
4055
4056 If you do not wish to use the proxy support at all, you may set:
4057
4058     MyApp->config(ignore_frontend_proxy => 0);
4059
4060 =head2 Note about psgi files
4061
4062 Note that if you supply your own .psgi file, calling
4063 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
4064
4065 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
4066 in your psgi, for example:
4067
4068     builder {
4069         enable "Plack::Middleware::ReverseProxy";
4070         MyApp->psgi_app
4071     };
4072
4073 This will unconditionally add the ReverseProxy support, or you need to call
4074 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
4075 apply the support depending upon your config).
4076
4077 See L<Catalyst::PSGI> for more information.
4078
4079 =head1 THREAD SAFETY
4080
4081 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
4082 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
4083 believe the Catalyst core to be thread-safe.
4084
4085 If you plan to operate in a threaded environment, remember that all other
4086 modules you are using must also be thread-safe. Some modules, most notably
4087 L<DBD::SQLite>, are not thread-safe.
4088
4089 =head1 DATA HANDLERS
4090
4091 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
4092 form parameters and URL search query fields.  However it has become common
4093 for various alternative content types to be PUT or POSTed to your controllers
4094 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
4095 XML and other content types when communicating with an application server.  In
4096 order to better support this use case, L<Catalyst> defines a global configuration
4097 option, C<data_handlers>, which lets you associate a content type with a coderef
4098 that parses that content type into something Perl can readily access.
4099
4100     package MyApp::Web;
4101
4102     use Catalyst;
4103     use JSON::Maybe;
4104
4105     __PACKAGE__->config(
4106       data_handlers => {
4107         'application/json' => sub { local $/; decode_json $_->getline },
4108       },
4109       ## Any other configuration.
4110     );
4111
4112     __PACKAGE__->setup;
4113
4114 By default L<Catalyst> comes with a generic JSON data handler similar to the
4115 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
4116 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4117 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4118 or dist.ini, cpanfile, etc.)
4119
4120 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4121 (matched against the incoming request type using a regexp such as to be case
4122 insensitive) and whose values are coderefs that receive a localized version of
4123 C<$_> which is a filehandle object pointing to received body.
4124
4125 This feature is considered an early access release and we reserve the right
4126 to alter the interface in order to provide a performant and secure solution to
4127 alternative request body content.  Your reports welcomed!
4128
4129 =head1 PSGI MIDDLEWARE
4130
4131 You can define middleware, defined as L<Plack::Middleware> or a compatible
4132 interface in configuration.  Your middleware definitions are in the form of an
4133 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4134 with details to follow:
4135
4136     package MyApp::Web;
4137
4138     use Catalyst;
4139     use Plack::Middleware::StackTrace;
4140
4141     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4142
4143     __PACKAGE__->config(
4144       'psgi_middleware', [
4145         'Debug',
4146         '+MyApp::Custom',
4147         $stacktrace_middleware,
4148         'Session' => {store => 'File'},
4149         sub {
4150           my $app = shift;
4151           return sub {
4152             my $env = shift;
4153             $env->{myapp.customkey} = 'helloworld';
4154             $app->($env);
4155           },
4156         },
4157       ],
4158     );
4159
4160     __PACKAGE__->setup;
4161
4162 So the general form is:
4163
4164     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4165
4166 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4167 the order listed (to make it function similarly to L<Plack::Builder>:
4168
4169 Alternatively, you may also define middleware by calling the L</setup_middleware>
4170 package method:
4171
4172     package MyApp::Web;
4173
4174     use Catalyst;
4175
4176     __PACKAGE__->setup_middleware( \@middleware_definitions);
4177     __PACKAGE__->setup;
4178
4179 In the case where you do both (use 'setup_middleware' and configuration) the
4180 package call to setup_middleware will be applied earlier (in other words its
4181 middleware will wrap closer to the application).  Keep this in mind since in
4182 some cases the order of middleware is important.
4183
4184 The two approaches are not exclusive.
4185
4186 =over 4
4187
4188 =item Middleware Object
4189
4190 An already initialized object that conforms to the L<Plack::Middleware>
4191 specification:
4192
4193     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4194
4195     __PACKAGE__->config(
4196       'psgi_middleware', [
4197         $stacktrace_middleware,
4198       ]);
4199
4200
4201 =item coderef
4202
4203 A coderef that is an inlined middleware:
4204
4205     __PACKAGE__->config(
4206       'psgi_middleware', [
4207         sub {
4208           my $app = shift;
4209           return sub {
4210             my $env = shift;
4211             if($env->{PATH_INFO} =~m/forced/) {
4212               Plack::App::File
4213                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4214                 ->call($env);
4215             } else {
4216               return $app->($env);
4217             }
4218          },
4219       },
4220     ]);
4221
4222
4223
4224 =item a scalar
4225
4226 We assume the scalar refers to a namespace after normalizing it using the
4227 following rules:
4228
4229 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4230 is assumed to be 'as is', and we just install and use the middleware.
4231
4232 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4233 (the package name of your Catalyst application subclass), we also assume then
4234 that it is a full namespace, and use it.
4235
4236 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4237 resolve it first by looking for it under your application namespace (for example
4238 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4239 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4240 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4241 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4242 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4243 you find that a good idea.
4244
4245 Examples:
4246
4247     package MyApp::Web;
4248
4249     __PACKAGE__->config(
4250       'psgi_middleware', [
4251         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4252         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4253         '+MyApp::Custom',  ## MyApp::Custom->wrap
4254       ],
4255     );
4256
4257 =item a scalar followed by a hashref
4258
4259 Just like the previous, except the following C<HashRef> is used as arguments
4260 to initialize the middleware object.
4261
4262     __PACKAGE__->config(
4263       'psgi_middleware', [
4264          'Session' => {store => 'File'},
4265     ]);
4266
4267 =back
4268
4269 Please see L<PSGI> for more on middleware.
4270
4271 =head1 ENCODING
4272
4273 Starting in L<Catalyst> version 5.90080 encoding is automatically enabled
4274 and set to encode all body responses to UTF8 when possible and applicable.
4275 Following is documentation on this process.  If you are using an older
4276 version of L<Catalyst> you should review documentation for that version since
4277 a lot has changed.
4278
4279 By default encoding is now 'UTF-8'.  You may turn it off by setting
4280 the encoding configuration to undef.
4281
4282     MyApp->config(encoding => undef);
4283
4284 This is recommended for temporary backwards compatibility only.
4285
4286 Encoding is automatically applied when the content-type is set to
4287 a type that can be encoded.  Currently we encode when the content type
4288 matches the following regular expression:
4289
4290     $content_type =~ /^text|xml$|javascript$/
4291
4292 Encoding is set on the application, but it is copied to the context object
4293 so that you can override it on a request basis.
4294
4295 Be default we don't automatically encode 'application/json' since the most
4296 common approaches to generating this type of response (Either via L<Catalyst::View::JSON>
4297 or L<Catalyst::Action::REST>) will do so already and we want to avoid double
4298 encoding issues.
4299
4300 If you are producing JSON response in an unconventional manner (such
4301 as via a template or manual strings) you should perform the UTF8 encoding
4302 manually as well such as to conform to the JSON specification.
4303
4304 NOTE: We also examine the value of $c->response->content_encoding.  If
4305 you set this (like for example 'gzip', and manually gzipping the body)
4306 we assume that you have done all the necessary encoding yourself, since
4307 we cannot encode the gzipped contents.  If you use a plugin like
4308 L<Catalyst::Plugin::Compress> you need to update to a modern version in order
4309 to have this function correctly  with the new UTF8 encoding code, or you
4310 can use L<Plack::Middleware::Deflater> or (probably best) do your compression on
4311 a front end proxy.
4312
4313 =head2 Methods
4314
4315 =over 4
4316
4317 =item encoding
4318
4319 Returns an instance of an C<Encode> encoding
4320
4321     print $c->encoding->name
4322
4323 =item handle_unicode_encoding_exception ($exception_context)
4324
4325 Method called when decoding process for a request fails.
4326
4327 An C<$exception_context> hashref is provided to allow you to override the
4328 behaviour of your application when given data with incorrect encodings.
4329
4330 The default method throws exceptions in the case of invalid request parameters
4331 (resulting in a 500 error), but ignores errors in upload filenames.
4332
4333 The keys passed in the C<$exception_context> hash are:
4334
4335 =over
4336
4337 =item param_value
4338
4339 The value which was not able to be decoded.
4340
4341 =item error_msg
4342
4343 The exception received from L<Encode>.
4344
4345 =item encoding_step
4346
4347 What type of data was being decoded. Valid values are (currently)
4348 C<params> - for request parameters / arguments / captures
4349 and C<uploads> - for request upload filenames.
4350
4351 =back
4352
4353 =back
4354
4355 =head1 SUPPORT
4356
4357 IRC:
4358
4359     Join #catalyst on irc.perl.org.
4360
4361 Mailing Lists:
4362
4363     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4364     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4365
4366 Web:
4367
4368     http://catalyst.perl.org
4369
4370 Wiki:
4371
4372     http://dev.catalyst.perl.org
4373
4374 =head1 SEE ALSO
4375
4376 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4377
4378 =head2 L<Catalyst::Manual> - The Catalyst Manual
4379
4380 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4381
4382 =head2 L<Catalyst::Engine> - Core engine
4383
4384 =head2 L<Catalyst::Log> - Log class.
4385
4386 =head2 L<Catalyst::Request> - Request object
4387
4388 =head2 L<Catalyst::Response> - Response object
4389
4390 =head2 L<Catalyst::Test> - The test suite.
4391
4392 =head1 PROJECT FOUNDER
4393
4394 sri: Sebastian Riedel <sri@cpan.org>
4395
4396 =head1 CONTRIBUTORS
4397
4398 abw: Andy Wardley
4399
4400 acme: Leon Brocard <leon@astray.com>
4401
4402 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4403
4404 andrewalker: André Walker <andre@cpan.org>
4405
4406 Andrew Bramble
4407
4408 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4409
4410 Andrew Ruthven
4411
4412 andyg: Andy Grundman <andy@hybridized.org>
4413
4414 audreyt: Audrey Tang
4415
4416 bricas: Brian Cassidy <bricas@cpan.org>
4417
4418 Caelum: Rafael Kitover <rkitover@io.com>
4419
4420 chansen: Christian Hansen
4421
4422 chicks: Christopher Hicks
4423
4424 Chisel Wright C<pause@herlpacker.co.uk>
4425
4426 Danijel Milicevic C<me@danijel.de>
4427
4428 davewood: David Schmidt <davewood@cpan.org>
4429
4430 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4431
4432 David Naughton, C<naughton@umn.edu>
4433
4434 David E. Wheeler
4435
4436 dhoss: Devin Austin <dhoss@cpan.org>
4437
4438 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4439
4440 Drew Taylor
4441
4442 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4443
4444 esskar: Sascha Kiefer
4445
4446 fireartist: Carl Franks <cfranks@cpan.org>
4447
4448 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4449
4450 gabb: Danijel Milicevic
4451
4452 Gary Ashton Jones
4453
4454 Gavin Henry C<ghenry@perl.me.uk>
4455
4456 Geoff Richards
4457
4458 groditi: Guillermo Roditi <groditi@gmail.com>
4459
4460 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4461
4462 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4463
4464 jcamacho: Juan Camacho
4465
4466 jester: Jesse Sheidlower C<jester@panix.com>
4467
4468 jhannah: Jay Hannah <jay@jays.net>
4469
4470 Jody Belka
4471
4472 Johan Lindstrom
4473
4474 jon: Jon Schutz <jjschutz@cpan.org>
4475
4476 Jonathan Rockway C<< <jrockway@cpan.org> >>
4477
4478 Kieren Diment C<kd@totaldatasolution.com>
4479
4480 konobi: Scott McWhirter <konobi@cpan.org>
4481
4482 marcus: Marcus Ramberg <mramberg@cpan.org>
4483
4484 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4485
4486 mgrimes: Mark Grimes <mgrimes@cpan.org>
4487
4488 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4489
4490 mugwump: Sam Vilain
4491
4492 naughton: David Naughton
4493
4494 ningu: David Kamholz <dkamholz@cpan.org>
4495
4496 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4497
4498 numa: Dan Sully <daniel@cpan.org>
4499
4500 obra: Jesse Vincent
4501
4502 Octavian Rasnita
4503
4504 omega: Andreas Marienborg
4505
4506 Oleg Kostyuk <cub.uanic@gmail.com>
4507
4508 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4509
4510 rafl: Florian Ragwitz <rafl@debian.org>
4511
4512 random: Roland Lammel <lammel@cpan.org>
4513
4514 Robert Sedlacek C<< <rs@474.at> >>
4515
4516 SpiceMan: Marcel Montes
4517
4518 sky: Arthur Bergman
4519
4520 szbalint: Balint Szilakszi <szbalint@cpan.org>
4521
4522 t0m: Tomas Doran <bobtfish@bobtfish.net>
4523
4524 Ulf Edvinsson
4525
4526 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4527
4528 Viljo Marrandi C<vilts@yahoo.com>
4529
4530 Will Hawes C<info@whawes.co.uk>
4531
4532 willert: Sebastian Willert <willert@cpan.org>
4533
4534 wreis: Wallace Reis <wreis@cpan.org>
4535
4536 Yuval Kogman, C<nothingmuch@woobling.org>
4537
4538 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4539
4540 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4541
4542 Upasana <me@upasana.me>
4543
4544 John Napiorkowski (jnap) <jjnapiork@cpan.org>
4545
4546 =head1 COPYRIGHT
4547
4548 Copyright (c) 2005-2015, the above named PROJECT FOUNDER and CONTRIBUTORS.
4549
4550 =head1 LICENSE
4551
4552 This library is free software. You can redistribute it and/or modify it under
4553 the same terms as Perl itself.
4554
4555 =cut
4556
4557 no Moose;
4558
4559 __PACKAGE__->meta->make_immutable;
4560
4561 1;