lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use bytes;
   6 use Scope::Upper ();
   7 use Catalyst::Exception;
   8 use Catalyst::Log;
   9 use Catalyst::Request;
  10 use Catalyst::Request::Upload;
  11 use Catalyst::Response;
  12 use Catalyst::Utils;
  13 use Catalyst::Controller;
  14 use Devel::InnerPackage ();
  15 use File::stat;
  16 use Module::Pluggable::Object ();
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp shortmess/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 has stack => (is => 'ro', default => sub { [] });
  34 has stash => (is => 'rw', default => sub { {} });
  35 has state => (is => 'rw', default => 0);
  36 has stats => (is => 'rw');
  37 has action => (is => 'rw');
  38 has counter => (is => 'rw', default => sub { {} });
  39 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  40 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  41 has namespace => (is => 'rw');
  42
  43 sub depth { scalar @{ shift->stack || [] }; }
  44 sub comp { shift->component(@_) }
  45
  46 sub req {
  47     # carp "the use of req() is deprecated in favour of request()";
  48     my $self = shift; return $self->request(@_);
  49 }
  50 sub res {
  51     # carp "the use of res() is deprecated in favour of response()";
  52     my $self = shift; return $self->response(@_);
  53 }
  54
  55 # For backwards compatibility
  56 sub finalize_output { shift->finalize_body(@_) };
  57
  58 # For statistics
  59 our $COUNT     = 1;
  60 our $START     = time;
  61 our $RECURSION = 1000;
  62 our $DETACH    = "catalyst_detach\n";
  63 our $GO        = "catalyst_go\n";
  64
  65 #I imagine that very few of these really need to be class variables. if any.
  66 #maybe we should just make them attributes with a default?
  67 __PACKAGE__->mk_classdata($_)
  68   for qw/components arguments dispatcher engine log dispatcher_class
  69   engine_class context_class request_class response_class stats_class
  70   setup_finished/;
  71
  72 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  73 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  74 __PACKAGE__->request_class('Catalyst::Request');
  75 __PACKAGE__->response_class('Catalyst::Response');
  76 __PACKAGE__->stats_class('Catalyst::Stats');
  77
  78 # Remember to update this in Catalyst::Runtime as well!
  79
  80 our $VERSION = '5.8000_05';
  81
  82 sub import {
  83     my ( $class, @arguments ) = @_;
  84
  85     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  86     # callers @ISA.
  87     return unless $class eq 'Catalyst';
  88
  89     my $caller = caller();
  90     return if $caller eq 'main';
  91     my $meta = Moose::Meta::Class->initialize($caller);
  92     #Moose->import({ into => $caller }); #do we want to do this?
  93
  94     unless ( $caller->isa('Catalyst') ) {
  95         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  96         $meta->superclasses(@superclasses);
  97     }
  98     unless( $meta->has_method('meta') ){
  99         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 100     }
 101
 102     $caller->arguments( [@arguments] );
 103     $caller->setup_home;
 104 }
 105
 106 =head1 NAME
 107
 108 Catalyst - The Elegant MVC Web Application Framework
 109
 110 =head1 SYNOPSIS
 111
 112 See the L<Catalyst::Manual> distribution for comprehensive
 113 documentation and tutorials.
 114
 115     # Install Catalyst::Devel for helpers and other development tools
 116     # use the helper to create a new application
 117     catalyst.pl MyApp
 118
 119     # add models, views, controllers
 120     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 121     script/myapp_create.pl view MyTemplate TT
 122     script/myapp_create.pl controller Search
 123
 124     # built in testserver -- use -r to restart automatically on changes
 125     # --help to see all available options
 126     script/myapp_server.pl
 127
 128     # command line testing interface
 129     script/myapp_test.pl /yada
 130
 131     ### in lib/MyApp.pm
 132     use Catalyst qw/-Debug/; # include plugins here as well
 133
 134     ### In lib/MyApp/Controller/Root.pm (autocreated)
 135     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 136         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 137         $c->stash->{template} = 'foo.tt'; # set the template
 138         # lookup something from db -- stash vars are passed to TT
 139         $c->stash->{data} =
 140           $c->model('Database::Foo')->search( { country => $args[0] } );
 141         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 142             $c->forward( 'bar' ); # process another action
 143             # do something else after forward returns
 144         }
 145     }
 146
 147     # The foo.tt TT template can use the stash data from the database
 148     [% WHILE (item = data.next) %]
 149         [% item.foo %]
 150     [% END %]
 151
 152     # called for /bar/of/soap, /bar/of/soap/10, etc.
 153     sub bar : Path('/bar/of/soap') { ... }
 154
 155     # called for all actions, from the top-most controller downwards
 156     sub auto : Private {
 157         my ( $self, $c ) = @_;
 158         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 159             $c->res->redirect( '/login' ); # require login
 160             return 0; # abort request and go immediately to end()
 161         }
 162         return 1; # success; carry on to next action
 163     }
 164
 165     # called after all actions are finished
 166     sub end : Private {
 167         my ( $self, $c ) = @_;
 168         if ( scalar @{ $c->error } ) { ... } # handle errors
 169         return if $c->res->body; # already have a response
 170         $c->forward( 'MyApp::View::TT' ); # render template
 171     }
 172
 173     ### in MyApp/Controller/Foo.pm
 174     # called for /foo/bar
 175     sub bar : Local { ... }
 176
 177     # called for /blargle
 178     sub blargle : Global { ... }
 179
 180     # an index action matches /foo, but not /foo/1, etc.
 181     sub index : Private { ... }
 182
 183     ### in MyApp/Controller/Foo/Bar.pm
 184     # called for /foo/bar/baz
 185     sub baz : Local { ... }
 186
 187     # first Root auto is called, then Foo auto, then this
 188     sub auto : Private { ... }
 189
 190     # powerful regular expression paths are also possible
 191     sub details : Regex('^product/(\w+)/details$') {
 192         my ( $self, $c ) = @_;
 193         # extract the (\w+) from the URI
 194         my $product = $c->req->captures->[0];
 195     }
 196
 197 See L<Catalyst::Manual::Intro> for additional information.
 198
 199 =head1 DESCRIPTION
 200
 201 Catalyst is a modern framework for making web applications without the
 202 pain usually associated with this process. This document is a reference
 203 to the main Catalyst application. If you are a new user, we suggest you
 204 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 205
 206 See L<Catalyst::Manual> for more documentation.
 207
 208 Catalyst plugins can be loaded by naming them as arguments to the "use
 209 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 210 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 211 C<My::Module>.
 212
 213     use Catalyst qw/My::Module/;
 214
 215 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 216 fully qualify the name by using a unary plus:
 217
 218     use Catalyst qw/
 219         My::Module
 220         +Fully::Qualified::Plugin::Name
 221     /;
 222
 223 Special flags like C<-Debug> and C<-Engine> can also be specified as
 224 arguments when Catalyst is loaded:
 225
 226     use Catalyst qw/-Debug My::Module/;
 227
 228 The position of plugins and flags in the chain is important, because
 229 they are loaded in the order in which they appear.
 230
 231 The following flags are supported:
 232
 233 =head2 -Debug
 234
 235 Enables debug output. You can also force this setting from the system
 236 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 237 settings override the application, with <MYAPP>_DEBUG having the highest
 238 priority.
 239
 240 =head2 -Engine
 241
 242 Forces Catalyst to use a specific engine. Omit the
 243 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 244
 245     use Catalyst qw/-Engine=CGI/;
 246
 247 =head2 -Home
 248
 249 Forces Catalyst to use a specific home directory, e.g.:
 250
 251     use Catalyst qw[-Home=/usr/mst];
 252
 253 This can also be done in the shell environment by setting either the
 254 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 255 is replaced with the uppercased name of your application, any "::" in
 256 the name will be replaced with underscores, e.g. MyApp::Web should use
 257 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 258
 259 =head2 -Log
 260
 261     use Catalyst '-Log=warn,fatal,error';
 262
 263 Specifies a comma-delimited list of log levels.
 264
 265 =head2 -Stats
 266
 267 Enables statistics collection and reporting. You can also force this setting
 268 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 269 environment settings override the application, with <MYAPP>_STATS having the
 270 highest priority.
 271
 272 e.g.
 273
 274    use Catalyst qw/-Stats=1/
 275
 276 =head1 METHODS
 277
 278 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 279
 280 =head2 $c->action
 281
 282 Returns a L<Catalyst::Action> object for the current action, which
 283 stringifies to the action name. See L<Catalyst::Action>.
 284
 285 =head2 $c->namespace
 286
 287 Returns the namespace of the current action, i.e., the URI prefix
 288 corresponding to the controller of the current action. For example:
 289
 290     # in Controller::Foo::Bar
 291     $c->namespace; # returns 'foo/bar';
 292
 293 =head2 $c->request
 294
 295 =head2 $c->req
 296
 297 Returns the current L<Catalyst::Request> object, giving access to
 298 information about the current client request (including parameters,
 299 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 300
 301 =head2 REQUEST FLOW HANDLING
 302
 303 =head2 $c->forward( $action [, \@arguments ] )
 304
 305 =head2 $c->forward( $class, $method, [, \@arguments ] )
 306
 307 Forwards processing to another action, by its private name. If you give a
 308 class name but no method, C<process()> is called. You may also optionally
 309 pass arguments in an arrayref. The action will receive the arguments in
 310 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 311 C<< $c->req->args >> will be restored to the previous values.
 312
 313 Any data C<return>ed from the action forwarded to, will be returned by the
 314 call to forward.
 315
 316     my $foodata = $c->forward('/foo');
 317     $c->forward('index');
 318     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 319     $c->forward('MyApp::View::TT');
 320
 321 Note that forward implies an C<<eval { }>> around the call (actually
 322 C<execute> does), thus de-fatalizing all 'dies' within the called
 323 action. If you want C<die> to propagate you need to do something like:
 324
 325     $c->forward('foo');
 326     die $c->error if $c->error;
 327
 328 Or make sure to always return true values from your actions and write
 329 your code like this:
 330
 331     $c->forward('foo') || return;
 332
 333 =cut
 334
 335 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 336
 337 =head2 $c->detach( $action [, \@arguments ] )
 338
 339 =head2 $c->detach( $class, $method, [, \@arguments ] )
 340
 341 =head2 $c->detach()
 342
 343 The same as C<forward>, but doesn't return to the previous action when
 344 processing is finished.
 345
 346 When called with no arguments it escapes the processing chain entirely.
 347
 348 =cut
 349
 350 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 351
 352 =head2 $c->visit( $action [, \@arguments ] )
 353
 354 =head2 $c->visit( $class, $method, [, \@arguments ] )
 355
 356 Almost the same as C<forward>, but does a full dispatch, instead of just
 357 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 358 C<auto> and the method you go to are called, just like a new request.
 359
 360 C<$c-E<gt>stash> is kept unchanged.
 361
 362 In effect, C<visit> allows you to "wrap" another action, just as it
 363 would have been called by dispatching from a URL, while the analogous
 364 C<go> allows you to transfer control to another action as if it had
 365 been reached directly from a URL.
 366
 367 =cut
 368
 369 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 370
 371 =head2 $c->go( $action [, \@arguments ] )
 372
 373 =head2 $c->go( $class, $method, [, \@arguments ] )
 374
 375 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 376 instead of just calling the new C<$action> /
 377 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 378 method you visit are called, just like a new request.
 379
 380 C<$c-E<gt>stash> is kept unchanged.
 381
 382 =cut
 383
 384 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 385
 386 =head2 $c->response
 387
 388 =head2 $c->res
 389
 390 Returns the current L<Catalyst::Response> object, see there for details.
 391
 392 =head2 $c->stash
 393
 394 Returns a hashref to the stash, which may be used to store data and pass
 395 it between components during a request. You can also set hash keys by
 396 passing arguments. The stash is automatically sent to the view. The
 397 stash is cleared at the end of a request; it cannot be used for
 398 persistent storage (for this you must use a session; see
 399 L<Catalyst::Plugin::Session> for a complete system integrated with
 400 Catalyst).
 401
 402     $c->stash->{foo} = $bar;
 403     $c->stash( { moose => 'majestic', qux => 0 } );
 404     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 405
 406     # stash is automatically passed to the view for use in a template
 407     $c->forward( 'MyApp::View::TT' );
 408
 409 =cut
 410
 411 around stash => sub {
 412     my $orig = shift;
 413     my $c = shift;
 414     my $stash = $orig->($c);
 415     if (@_) {
 416         my $new_stash = @_ > 1 ? {@_} : $_[0];
 417         croak('stash takes a hash or hashref') unless ref $new_stash;
 418         foreach my $key ( keys %$new_stash ) {
 419           $stash->{$key} = $new_stash->{$key};
 420         }
 421     }
 422
 423     return $stash;
 424 };
 425
 426
 427 =head2 $c->error
 428
 429 =head2 $c->error($error, ...)
 430
 431 =head2 $c->error($arrayref)
 432
 433 Returns an arrayref containing error messages.  If Catalyst encounters an
 434 error while processing a request, it stores the error in $c->error.  This
 435 method should only be used to store fatal error messages.
 436
 437     my @error = @{ $c->error };
 438
 439 Add a new error.
 440
 441     $c->error('Something bad happened');
 442
 443 =cut
 444
 445 sub error {
 446     my $c = shift;
 447     if ( $_[0] ) {
 448         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 449         croak @$error unless ref $c;
 450         push @{ $c->{error} }, @$error;
 451     }
 452     elsif ( defined $_[0] ) { $c->{error} = undef }
 453     return $c->{error} || [];
 454 }
 455
 456
 457 =head2 $c->state
 458
 459 Contains the return value of the last executed action.
 460
 461 =head2 $c->clear_errors
 462
 463 Clear errors.  You probably don't want to clear the errors unless you are
 464 implementing a custom error screen.
 465
 466 This is equivalent to running
 467
 468     $c->error(0);
 469
 470 =cut
 471
 472 sub clear_errors {
 473     my $c = shift;
 474     $c->error(0);
 475 }
 476
 477 # search components given a name and some prefixes
 478 sub _comp_search_prefixes {
 479     my ( $c, $name, @prefixes ) = @_;
 480     my $appclass = ref $c || $c;
 481     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 482
 483     # map the original component name to the sub part that we will search against
 484     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 485         grep { /$filter/ } keys %{ $c->components };
 486
 487     # undef for a name will return all
 488     return keys %eligible if !defined $name;
 489
 490     my $query  = ref $name ? $name : qr/^$name$/i;
 491     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 492
 493     return map { $c->components->{ $_ } } @result if @result;
 494
 495     # if we were given a regexp to search against, we're done.
 496     return if ref $name;
 497
 498     # regexp fallback
 499     $query  = qr/$name/i;
 500     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 501
 502     # no results? try against full names
 503     if( !@result ) {
 504         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 505     }
 506
 507     # don't warn if we didn't find any results, it just might not exist
 508     if( @result ) {
 509         my $msg = "Used regexp fallback for \$c->model('${name}'), which found '" .
 510            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 511            "component resolution is unreliable and unsafe.";
 512         my $short = $result[0];
 513         $short =~ s/.*?Model:://;
 514         my $shortmess = Carp::shortmess('');
 515         if ($shortmess =~ m#Catalyst/Plugin#) {
 516            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 517               "plugin's config";
 518         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 519            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 520               "component's config";
 521         } else {
 522            $msg .= " You probably meant \$c->model('$short') instead of \$c->model{'${name}'}, " .
 523               "but if you really wanted to search, pass in a regexp as the argument " .
 524               "like so: \$c->model(qr/${name}/)";
 525         }
 526         $c->log->warn( "${msg}$shortmess" );
 527     }
 528
 529     return @result;
 530 }
 531
 532 # Find possible names for a prefix
 533 sub _comp_names {
 534     my ( $c, @prefixes ) = @_;
 535     my $appclass = ref $c || $c;
 536
 537     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 538
 539     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 540     return @names;
 541 }
 542
 543 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 544 sub _filter_component {
 545     my ( $c, $comp, @args ) = @_;
 546
 547     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 548         return $comp->ACCEPT_CONTEXT( $c, @args );
 549     }
 550
 551     return $comp;
 552 }
 553
 554 =head2 COMPONENT ACCESSORS
 555
 556 =head2 $c->controller($name)
 557
 558 Gets a L<Catalyst::Controller> instance by name.
 559
 560     $c->controller('Foo')->do_stuff;
 561
 562 If the name is omitted, will return the controller for the dispatched
 563 action.
 564
 565 If you want to search for controllers, pass in a regexp as the argument.
 566
 567     # find all controllers that start with Foo
 568     my @foo_controllers = $c->controller(qr{^Foo});
 569
 570
 571 =cut
 572
 573 sub controller {
 574     my ( $c, $name, @args ) = @_;
 575
 576     if( $name ) {
 577         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 578         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 579         return $c->_filter_component( $result[ 0 ], @args );
 580     }
 581
 582     return $c->component( $c->action->class );
 583 }
 584
 585 =head2 $c->model($name)
 586
 587 Gets a L<Catalyst::Model> instance by name.
 588
 589     $c->model('Foo')->do_stuff;
 590
 591 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 592
 593 If the name is omitted, it will look for
 594  - a model object in $c->stash->{current_model_instance}, then
 595  - a model name in $c->stash->{current_model}, then
 596  - a config setting 'default_model', or
 597  - check if there is only one model, and return it if that's the case.
 598
 599 If you want to search for models, pass in a regexp as the argument.
 600
 601     # find all models that start with Foo
 602     my @foo_models = $c->model(qr{^Foo});
 603
 604 =cut
 605
 606 sub model {
 607     my ( $c, $name, @args ) = @_;
 608
 609     if( $name ) {
 610         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 611         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 612         return $c->_filter_component( $result[ 0 ], @args );
 613     }
 614
 615     if (ref $c) {
 616         return $c->stash->{current_model_instance}
 617           if $c->stash->{current_model_instance};
 618         return $c->model( $c->stash->{current_model} )
 619           if $c->stash->{current_model};
 620     }
 621     return $c->model( $c->config->{default_model} )
 622       if $c->config->{default_model};
 623
 624     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 625
 626     if( $rest ) {
 627         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 628         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 629         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 630         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 631         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 632     }
 633
 634     return $c->_filter_component( $comp );
 635 }
 636
 637
 638 =head2 $c->view($name)
 639
 640 Gets a L<Catalyst::View> instance by name.
 641
 642     $c->view('Foo')->do_stuff;
 643
 644 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 645
 646 If the name is omitted, it will look for
 647  - a view object in $c->stash->{current_view_instance}, then
 648  - a view name in $c->stash->{current_view}, then
 649  - a config setting 'default_view', or
 650  - check if there is only one view, and return it if that's the case.
 651
 652 If you want to search for views, pass in a regexp as the argument.
 653
 654     # find all views that start with Foo
 655     my @foo_views = $c->view(qr{^Foo});
 656
 657 =cut
 658
 659 sub view {
 660     my ( $c, $name, @args ) = @_;
 661
 662     if( $name ) {
 663         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 664         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 665         return $c->_filter_component( $result[ 0 ], @args );
 666     }
 667
 668     if (ref $c) {
 669         return $c->stash->{current_view_instance}
 670           if $c->stash->{current_view_instance};
 671         return $c->view( $c->stash->{current_view} )
 672           if $c->stash->{current_view};
 673     }
 674     return $c->view( $c->config->{default_view} )
 675       if $c->config->{default_view};
 676
 677     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 678
 679     if( $rest ) {
 680         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 681         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 682         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 683         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 684         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 685     }
 686
 687     return $c->_filter_component( $comp );
 688 }
 689
 690 =head2 $c->controllers
 691
 692 Returns the available names which can be passed to $c->controller
 693
 694 =cut
 695
 696 sub controllers {
 697     my ( $c ) = @_;
 698     return $c->_comp_names(qw/Controller C/);
 699 }
 700
 701 =head2 $c->models
 702
 703 Returns the available names which can be passed to $c->model
 704
 705 =cut
 706
 707 sub models {
 708     my ( $c ) = @_;
 709     return $c->_comp_names(qw/Model M/);
 710 }
 711
 712
 713 =head2 $c->views
 714
 715 Returns the available names which can be passed to $c->view
 716
 717 =cut
 718
 719 sub views {
 720     my ( $c ) = @_;
 721     return $c->_comp_names(qw/View V/);
 722 }
 723
 724 =head2 $c->comp($name)
 725
 726 =head2 $c->component($name)
 727
 728 Gets a component object by name. This method is not recommended,
 729 unless you want to get a specific component by full
 730 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 731 should be used instead.
 732
 733 If C<$name> is a regexp, a list of components matched against the full
 734 component name will be returned.
 735
 736 =cut
 737
 738 sub component {
 739     my ( $c, $name, @args ) = @_;
 740
 741     if( $name ) {
 742         my $comps = $c->components;
 743
 744         if( !ref $name ) {
 745             # is it the exact name?
 746             return $c->_filter_component( $comps->{ $name }, @args )
 747                        if exists $comps->{ $name };
 748
 749             # perhaps we just omitted "MyApp"?
 750             my $composed = ( ref $c || $c ) . "::${name}";
 751             return $c->_filter_component( $comps->{ $composed }, @args )
 752                        if exists $comps->{ $composed };
 753
 754             # search all of the models, views and controllers
 755             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 756             return $c->_filter_component( $comp, @args ) if $comp;
 757         }
 758
 759         # This is here so $c->comp( '::M::' ) works
 760         my $query = ref $name ? $name : qr{$name}i;
 761
 762         my @result = grep { m{$query} } keys %{ $c->components };
 763         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 764
 765         if( $result[ 0 ] ) {
 766             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 767             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 768             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 769             return $c->_filter_component( $result[ 0 ], @args );
 770         }
 771
 772         # I would expect to return an empty list here, but that breaks back-compat
 773     }
 774
 775     # fallback
 776     return sort keys %{ $c->components };
 777 }
 778
 779 =head2 CLASS DATA AND HELPER CLASSES
 780
 781 =head2 $c->config
 782
 783 Returns or takes a hashref containing the application's configuration.
 784
 785     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 786
 787 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 788 like myapp.yml in your applications home directory. See
 789 L<Catalyst::Plugin::ConfigLoader>.
 790
 791     ---
 792     db: dsn:SQLite:foo.db
 793
 794
 795 =cut
 796
 797 around config => sub {
 798     my $orig = shift;
 799     my $c = shift;
 800
 801     $c->log->warn("Setting config after setup has been run is not a good idea.")
 802       if ( @_ and $c->setup_finished );
 803
 804     $c->$orig(@_);
 805 };
 806
 807 =head2 $c->log
 808
 809 Returns the logging object instance. Unless it is already set, Catalyst
 810 sets this up with a L<Catalyst::Log> object. To use your own log class,
 811 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 812 C<< __PACKAGE__->setup >>.
 813
 814  __PACKAGE__->log( MyLogger->new );
 815  __PACKAGE__->setup;
 816
 817 And later:
 818
 819     $c->log->info( 'Now logging with my own logger!' );
 820
 821 Your log class should implement the methods described in
 822 L<Catalyst::Log>.
 823
 824
 825 =head2 $c->debug
 826
 827 Overload to enable debug messages (same as -Debug option).
 828
 829 Note that this is a static method, not an accessor and should be overloaded
 830 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 831
 832 =cut
 833
 834 sub debug { 0 }
 835
 836 =head2 $c->dispatcher
 837
 838 Returns the dispatcher instance. Stringifies to class name. See
 839 L<Catalyst::Dispatcher>.
 840
 841 =head2 $c->engine
 842
 843 Returns the engine instance. Stringifies to the class name. See
 844 L<Catalyst::Engine>.
 845
 846
 847 =head2 UTILITY METHODS
 848
 849 =head2 $c->path_to(@path)
 850
 851 Merges C<@path> with C<< $c->config->{home} >> and returns a
 852 L<Path::Class::Dir> object.
 853
 854 For example:
 855
 856     $c->path_to( 'db', 'sqlite.db' );
 857
 858 =cut
 859
 860 sub path_to {
 861     my ( $c, @path ) = @_;
 862     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 863     if ( -d $path ) { return $path }
 864     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 865 }
 866
 867 =head2 $c->plugin( $name, $class, @args )
 868
 869 Helper method for plugins. It creates a classdata accessor/mutator and
 870 loads and instantiates the given class.
 871
 872     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 873
 874     $c->prototype->define_javascript_functions;
 875
 876 B<Note:> This method of adding plugins is deprecated. The ability
 877 to add plugins like this B<will be removed> in a Catalyst 5.9.
 878 Please do not use this functionality in new code.
 879
 880 =cut
 881
 882 sub plugin {
 883     my ( $class, $name, $plugin, @args ) = @_;
 884
 885     # See block comment in t/unit_core_plugin.t
 886     $class->log->debug(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.9/);
 887
 888     $class->_register_plugin( $plugin, 1 );
 889
 890     eval { $plugin->import };
 891     $class->mk_classdata($name);
 892     my $obj;
 893     eval { $obj = $plugin->new(@args) };
 894
 895     if ($@) {
 896         Catalyst::Exception->throw( message =>
 897               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 898     }
 899
 900     $class->$name($obj);
 901     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 902       if $class->debug;
 903 }
 904
 905 =head2 MyApp->setup
 906
 907 Initializes the dispatcher and engine, loads any plugins, and loads the
 908 model, view, and controller components. You may also specify an array
 909 of plugins to load here, if you choose to not load them in the C<use
 910 Catalyst> line.
 911
 912     MyApp->setup;
 913     MyApp->setup( qw/-Debug/ );
 914
 915 =cut
 916
 917 sub setup {
 918     my ( $class, @arguments ) = @_;
 919     $class->log->warn("Running setup twice is not a good idea.")
 920       if ( $class->setup_finished );
 921
 922     unless ( $class->isa('Catalyst') ) {
 923
 924         Catalyst::Exception->throw(
 925             message => qq/'$class' does not inherit from Catalyst/ );
 926     }
 927
 928     if ( $class->arguments ) {
 929         @arguments = ( @arguments, @{ $class->arguments } );
 930     }
 931
 932     # Process options
 933     my $flags = {};
 934
 935     foreach (@arguments) {
 936
 937         if (/^-Debug$/) {
 938             $flags->{log} =
 939               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 940         }
 941         elsif (/^-(\w+)=?(.*)$/) {
 942             $flags->{ lc $1 } = $2;
 943         }
 944         else {
 945             push @{ $flags->{plugins} }, $_;
 946         }
 947     }
 948
 949     $class->setup_home( delete $flags->{home} );
 950
 951     $class->setup_log( delete $flags->{log} );
 952     $class->setup_plugins( delete $flags->{plugins} );
 953     $class->setup_dispatcher( delete $flags->{dispatcher} );
 954     $class->setup_engine( delete $flags->{engine} );
 955     $class->setup_stats( delete $flags->{stats} );
 956
 957     for my $flag ( sort keys %{$flags} ) {
 958
 959         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 960             &$code( $class, delete $flags->{$flag} );
 961         }
 962         else {
 963             $class->log->warn(qq/Unknown flag "$flag"/);
 964         }
 965     }
 966
 967     eval { require Catalyst::Devel; };
 968     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 969         $class->log->warn(<<"EOF");
 970 You are running an old script!
 971
 972   Please update by running (this will overwrite existing files):
 973     catalyst.pl -force -scripts $class
 974
 975   or (this will not overwrite existing files):
 976     catalyst.pl -scripts $class
 977
 978 EOF
 979     }
 980
 981     if ( $class->debug ) {
 982         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 983
 984         if (@plugins) {
 985             my $t = Text::SimpleTable->new(74);
 986             $t->row($_) for @plugins;
 987             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 988         }
 989
 990         my $dispatcher = $class->dispatcher;
 991         my $engine     = $class->engine;
 992         my $home       = $class->config->{home};
 993
 994         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
 995         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
 996
 997         $home
 998           ? ( -d $home )
 999           ? $class->log->debug(qq/Found home "$home"/)
1000           : $class->log->debug(qq/Home "$home" doesn't exist/)
1001           : $class->log->debug(q/Couldn't find home/);
1002     }
1003
1004     # Call plugins setup, this is stupid and evil.
1005     {
1006         no warnings qw/redefine/;
1007         local *setup = sub { };
1008         $class->setup;
1009     }
1010
1011     # Initialize our data structure
1012     $class->components( {} );
1013
1014     $class->setup_components;
1015
1016     if ( $class->debug ) {
1017         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
1018         for my $comp ( sort keys %{ $class->components } ) {
1019             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1020             $t->row( $comp, $type );
1021         }
1022         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1023           if ( keys %{ $class->components } );
1024     }
1025
1026     # Add our self to components, since we are also a component
1027     if( $class->isa('Catalyst::Controller') ){
1028       $class->components->{$class} = $class;
1029     }
1030
1031     $class->setup_actions;
1032
1033     if ( $class->debug ) {
1034         my $name = $class->config->{name} || 'Application';
1035         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1036     }
1037     $class->log->_flush() if $class->log->can('_flush');
1038
1039     # Make sure that the application class becomes immutable at this point,
1040     # which ensures that it gets an inlined constructor. This means that it
1041     # works even if the user has added a plugin which contains a new method.
1042     # Note however that we have to do the work on scope end, so that method
1043     # modifiers work correctly in MyApp (as you have to call setup _before_
1044     # applying modifiers).
1045     Scope::Upper::reap(sub {
1046         my $meta = Class::MOP::get_metaclass_by_name($class);
1047         $meta->make_immutable unless $meta->is_immutable;
1048     }, Scope::Upper::SCOPE(1));
1049
1050     $class->setup_finished(1);
1051 }
1052
1053 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1054
1055 =head2 $c->uri_for( $path, @args?, \%query_values? )
1056
1057 =over
1058
1059 =item $action
1060
1061 A Catalyst::Action object representing the Catalyst action you want to
1062 create a URI for. To get one for an action in the current controller,
1063 use C<< $c->action('someactionname') >>. To get one from different
1064 controller, fetch the controller using C<< $c->controller() >>, then
1065 call C<action_for> on it.
1066
1067 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1068 using C<< $c->req->captures >>.
1069
1070   # For the current action
1071   $c->uri_for($c->action, $c->req->captures);
1072
1073   # For the Foo action in the Bar controller
1074   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1075
1076 =back
1077
1078 =cut
1079
1080 sub uri_for {
1081     my ( $c, $path, @args ) = @_;
1082
1083     if ( Scalar::Util::blessed($path) ) { # action object
1084         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1085                          ? shift(@args)
1086                          : [] );
1087         $path = $c->dispatcher->uri_for_action($path, $captures);
1088         return undef unless defined($path);
1089         $path = '/' if $path eq '';
1090     }
1091
1092     undef($path) if (defined $path && $path eq '');
1093
1094     my $params =
1095       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1096
1097     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1098     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1099
1100     unshift(@args, $path);
1101
1102     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1103         my $namespace = $c->namespace;
1104         if (defined $path) { # cheesy hack to handle path '../foo'
1105            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1106         }
1107         unshift(@args, $namespace || '');
1108     }
1109
1110     # join args with '/', or a blank string
1111     my $args = join('/', grep { defined($_) } @args);
1112     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1113     $args =~ s!^/+!!;
1114     my $base = $c->req->base;
1115     my $class = ref($base);
1116     $base =~ s{(?<!/)$}{/};
1117
1118     my $query = '';
1119
1120     if (my @keys = keys %$params) {
1121       # somewhat lifted from URI::_query's query_form
1122       $query = '?'.join('&', map {
1123           my $val = $params->{$_};
1124           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1125           s/ /+/g;
1126           my $key = $_;
1127           $val = '' unless defined $val;
1128           (map {
1129               $_ = "$_";
1130               utf8::encode( $_ ) if utf8::is_utf8($_);
1131               # using the URI::Escape pattern here so utf8 chars survive
1132               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1133               s/ /+/g;
1134               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1135       } @keys);
1136     }
1137
1138     my $res = bless(\"${base}${args}${query}", $class);
1139     $res;
1140 }
1141
1142 =head2 $c->welcome_message
1143
1144 Returns the Catalyst welcome HTML page.
1145
1146 =cut
1147
1148 sub welcome_message {
1149     my $c      = shift;
1150     my $name   = $c->config->{name};
1151     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1152     my $prefix = Catalyst::Utils::appprefix( ref $c );
1153     $c->response->content_type('text/html; charset=utf-8');
1154     return <<"EOF";
1155 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1156     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1157 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1158     <head>
1159     <meta http-equiv="Content-Language" content="en" />
1160     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1161         <title>$name on Catalyst $VERSION</title>
1162         <style type="text/css">
1163             body {
1164                 color: #000;
1165                 background-color: #eee;
1166             }
1167             div#content {
1168                 width: 640px;
1169                 margin-left: auto;
1170                 margin-right: auto;
1171                 margin-top: 10px;
1172                 margin-bottom: 10px;
1173                 text-align: left;
1174                 background-color: #ccc;
1175                 border: 1px solid #aaa;
1176             }
1177             p, h1, h2 {
1178                 margin-left: 20px;
1179                 margin-right: 20px;
1180                 font-family: verdana, tahoma, sans-serif;
1181             }
1182             a {
1183                 font-family: verdana, tahoma, sans-serif;
1184             }
1185             :link, :visited {
1186                     text-decoration: none;
1187                     color: #b00;
1188                     border-bottom: 1px dotted #bbb;
1189             }
1190             :link:hover, :visited:hover {
1191                     color: #555;
1192             }
1193             div#topbar {
1194                 margin: 0px;
1195             }
1196             pre {
1197                 margin: 10px;
1198                 padding: 8px;
1199             }
1200             div#answers {
1201                 padding: 8px;
1202                 margin: 10px;
1203                 background-color: #fff;
1204                 border: 1px solid #aaa;
1205             }
1206             h1 {
1207                 font-size: 0.9em;
1208                 font-weight: normal;
1209                 text-align: center;
1210             }
1211             h2 {
1212                 font-size: 1.0em;
1213             }
1214             p {
1215                 font-size: 0.9em;
1216             }
1217             p img {
1218                 float: right;
1219                 margin-left: 10px;
1220             }
1221             span#appname {
1222                 font-weight: bold;
1223                 font-size: 1.6em;
1224             }
1225         </style>
1226     </head>
1227     <body>
1228         <div id="content">
1229             <div id="topbar">
1230                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1231                     $VERSION</h1>
1232              </div>
1233              <div id="answers">
1234                  <p>
1235                  <img src="$logo" alt="Catalyst Logo" />
1236                  </p>
1237                  <p>Welcome to the  world of Catalyst.
1238                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1239                     framework will make web development something you had
1240                     never expected it to be: Fun, rewarding, and quick.</p>
1241                  <h2>What to do now?</h2>
1242                  <p>That really depends  on what <b>you</b> want to do.
1243                     We do, however, provide you with a few starting points.</p>
1244                  <p>If you want to jump right into web development with Catalyst
1245                     you might want to start with a tutorial.</p>
1246 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1247 </pre>
1248 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1249 <pre>
1250 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1251 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1252 </code></pre>
1253                  <h2>What to do next?</h2>
1254                  <p>Next it's time to write an actual application. Use the
1255                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1256                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1257                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1258                     they can save you a lot of work.</p>
1259                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1260                     <p>Also, be sure to check out the vast and growing
1261                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1262                     you are likely to find what you need there.
1263                     </p>
1264
1265                  <h2>Need help?</h2>
1266                  <p>Catalyst has a very active community. Here are the main places to
1267                     get in touch with us.</p>
1268                  <ul>
1269                      <li>
1270                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1271                      </li>
1272                      <li>
1273                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1274                      </li>
1275                      <li>
1276                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1277                      </li>
1278                  </ul>
1279                  <h2>In conclusion</h2>
1280                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1281                     as we enjoyed making it. Please contact us if you have ideas
1282                     for improvement or other feedback.</p>
1283              </div>
1284          </div>
1285     </body>
1286 </html>
1287 EOF
1288 }
1289
1290 =head1 INTERNAL METHODS
1291
1292 These methods are not meant to be used by end users.
1293
1294 =head2 $c->components
1295
1296 Returns a hash of components.
1297
1298 =head2 $c->context_class
1299
1300 Returns or sets the context class.
1301
1302 =head2 $c->counter
1303
1304 Returns a hashref containing coderefs and execution counts (needed for
1305 deep recursion detection).
1306
1307 =head2 $c->depth
1308
1309 Returns the number of actions on the current internal execution stack.
1310
1311 =head2 $c->dispatch
1312
1313 Dispatches a request to actions.
1314
1315 =cut
1316
1317 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1318
1319 =head2 $c->dispatcher_class
1320
1321 Returns or sets the dispatcher class.
1322
1323 =head2 $c->dump_these
1324
1325 Returns a list of 2-element array references (name, structure) pairs
1326 that will be dumped on the error page in debug mode.
1327
1328 =cut
1329
1330 sub dump_these {
1331     my $c = shift;
1332     [ Request => $c->req ],
1333     [ Response => $c->res ],
1334     [ Stash => $c->stash ],
1335     [ Config => $c->config ];
1336 }
1337
1338 =head2 $c->engine_class
1339
1340 Returns or sets the engine class.
1341
1342 =head2 $c->execute( $class, $coderef )
1343
1344 Execute a coderef in given class and catch exceptions. Errors are available
1345 via $c->error.
1346
1347 =cut
1348
1349 sub execute {
1350     my ( $c, $class, $code ) = @_;
1351     $class = $c->component($class) || $class;
1352     $c->state(0);
1353
1354     if ( $c->depth >= $RECURSION ) {
1355         my $action = $code->reverse();
1356         $action = "/$action" unless $action =~ /->/;
1357         my $error = qq/Deep recursion detected calling "${action}"/;
1358         $c->log->error($error);
1359         $c->error($error);
1360         $c->state(0);
1361         return $c->state;
1362     }
1363
1364     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1365
1366     push( @{ $c->stack }, $code );
1367
1368     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1369
1370     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1371
1372     my $last = pop( @{ $c->stack } );
1373
1374     if ( my $error = $@ ) {
1375         if ( !ref($error) and $error eq $DETACH ) {
1376             die $DETACH if($c->depth > 1);
1377         }
1378         elsif ( !ref($error) and $error eq $GO ) {
1379             die $GO if($c->depth > 0);
1380         }
1381         else {
1382             unless ( ref $error ) {
1383                 no warnings 'uninitialized';
1384                 chomp $error;
1385                 my $class = $last->class;
1386                 my $name  = $last->name;
1387                 $error = qq/Caught exception in $class->$name "$error"/;
1388             }
1389             $c->error($error);
1390             $c->state(0);
1391         }
1392     }
1393     return $c->state;
1394 }
1395
1396 sub _stats_start_execute {
1397     my ( $c, $code ) = @_;
1398
1399     return if ( ( $code->name =~ /^_.*/ )
1400         && ( !$c->config->{show_internal_actions} ) );
1401
1402     my $action_name = $code->reverse();
1403     $c->counter->{$action_name}++;
1404
1405     my $action = $action_name;
1406     $action = "/$action" unless $action =~ /->/;
1407
1408     # determine if the call was the result of a forward
1409     # this is done by walking up the call stack and looking for a calling
1410     # sub of Catalyst::forward before the eval
1411     my $callsub = q{};
1412     for my $index ( 2 .. 11 ) {
1413         last
1414         if ( ( caller($index) )[0] eq 'Catalyst'
1415             && ( caller($index) )[3] eq '(eval)' );
1416
1417         if ( ( caller($index) )[3] =~ /forward$/ ) {
1418             $callsub = ( caller($index) )[3];
1419             $action  = "-> $action";
1420             last;
1421         }
1422     }
1423
1424     my $uid = $action_name . $c->counter->{$action_name};
1425
1426     # is this a root-level call or a forwarded call?
1427     if ( $callsub =~ /forward$/ ) {
1428
1429         # forward, locate the caller
1430         if ( my $parent = $c->stack->[-1] ) {
1431             $c->stats->profile(
1432                 begin  => $action,
1433                 parent => "$parent" . $c->counter->{"$parent"},
1434                 uid    => $uid,
1435             );
1436         }
1437         else {
1438
1439             # forward with no caller may come from a plugin
1440             $c->stats->profile(
1441                 begin => $action,
1442                 uid   => $uid,
1443             );
1444         }
1445     }
1446     else {
1447
1448         # root-level call
1449         $c->stats->profile(
1450             begin => $action,
1451             uid   => $uid,
1452         );
1453     }
1454     return $action;
1455
1456 }
1457
1458 sub _stats_finish_execute {
1459     my ( $c, $info ) = @_;
1460     $c->stats->profile( end => $info );
1461 }
1462
1463 =head2 $c->_localize_fields( sub { }, \%keys );
1464
1465 =cut
1466
1467 #Why does this exist? This is no longer safe and WILL NOT WORK.
1468 # it doesnt seem to be used anywhere. can we remove it?
1469 sub _localize_fields {
1470     my ( $c, $localized, $code ) = ( @_ );
1471
1472     my $request = delete $localized->{request} || {};
1473     my $response = delete $localized->{response} || {};
1474
1475     local @{ $c }{ keys %$localized } = values %$localized;
1476     local @{ $c->request }{ keys %$request } = values %$request;
1477     local @{ $c->response }{ keys %$response } = values %$response;
1478
1479     $code->();
1480 }
1481
1482 =head2 $c->finalize
1483
1484 Finalizes the request.
1485
1486 =cut
1487
1488 sub finalize {
1489     my $c = shift;
1490
1491     for my $error ( @{ $c->error } ) {
1492         $c->log->error($error);
1493     }
1494
1495     # Allow engine to handle finalize flow (for POE)
1496     my $engine = $c->engine;
1497     if ( my $code = $engine->can('finalize') ) {
1498         $engine->$code($c);
1499     }
1500     else {
1501
1502         $c->finalize_uploads;
1503
1504         # Error
1505         if ( $#{ $c->error } >= 0 ) {
1506             $c->finalize_error;
1507         }
1508
1509         $c->finalize_headers;
1510
1511         # HEAD request
1512         if ( $c->request->method eq 'HEAD' ) {
1513             $c->response->body('');
1514         }
1515
1516         $c->finalize_body;
1517     }
1518
1519     if ($c->use_stats) {
1520         my $elapsed = sprintf '%f', $c->stats->elapsed;
1521         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1522         $c->log->info(
1523             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1524     }
1525
1526     return $c->response->status;
1527 }
1528
1529 =head2 $c->finalize_body
1530
1531 Finalizes body.
1532
1533 =cut
1534
1535 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1536
1537 =head2 $c->finalize_cookies
1538
1539 Finalizes cookies.
1540
1541 =cut
1542
1543 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1544
1545 =head2 $c->finalize_error
1546
1547 Finalizes error.
1548
1549 =cut
1550
1551 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1552
1553 =head2 $c->finalize_headers
1554
1555 Finalizes headers.
1556
1557 =cut
1558
1559 sub finalize_headers {
1560     my $c = shift;
1561
1562     my $response = $c->response; #accessor calls can add up?
1563
1564     # Check if we already finalized headers
1565     return if $response->finalized_headers;
1566
1567     # Handle redirects
1568     if ( my $location = $response->redirect ) {
1569         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1570         $response->header( Location => $location );
1571
1572         if ( !$response->has_body ) {
1573             # Add a default body if none is already present
1574             $response->body(
1575                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1576             );
1577         }
1578     }
1579
1580     # Content-Length
1581     if ( $response->body && !$response->content_length ) {
1582
1583         # get the length from a filehandle
1584         if ( blessed( $response->body ) && $response->body->can('read') )
1585         {
1586             my $stat = stat $response->body;
1587             if ( $stat && $stat->size > 0 ) {
1588                 $response->content_length( $stat->size );
1589             }
1590             else {
1591                 $c->log->warn('Serving filehandle without a content-length');
1592             }
1593         }
1594         else {
1595             # everything should be bytes at this point, but just in case
1596             $response->content_length( bytes::length( $response->body ) );
1597         }
1598     }
1599
1600     # Errors
1601     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1602         $response->headers->remove_header("Content-Length");
1603         $response->body('');
1604     }
1605
1606     $c->finalize_cookies;
1607
1608     $c->engine->finalize_headers( $c, @_ );
1609
1610     # Done
1611     $response->finalized_headers(1);
1612 }
1613
1614 =head2 $c->finalize_output
1615
1616 An alias for finalize_body.
1617
1618 =head2 $c->finalize_read
1619
1620 Finalizes the input after reading is complete.
1621
1622 =cut
1623
1624 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1625
1626 =head2 $c->finalize_uploads
1627
1628 Finalizes uploads. Cleans up any temporary files.
1629
1630 =cut
1631
1632 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1633
1634 =head2 $c->get_action( $action, $namespace )
1635
1636 Gets an action in a given namespace.
1637
1638 =cut
1639
1640 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1641
1642 =head2 $c->get_actions( $action, $namespace )
1643
1644 Gets all actions of a given name in a namespace and all parent
1645 namespaces.
1646
1647 =cut
1648
1649 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1650
1651 =head2 $c->handle_request( $class, @arguments )
1652
1653 Called to handle each HTTP request.
1654
1655 =cut
1656
1657 sub handle_request {
1658     my ( $class, @arguments ) = @_;
1659
1660     # Always expect worst case!
1661     my $status = -1;
1662     eval {
1663         if ($class->debug) {
1664             my $secs = time - $START || 1;
1665             my $av = sprintf '%.3f', $COUNT / $secs;
1666             my $time = localtime time;
1667             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1668         }
1669
1670         my $c = $class->prepare(@arguments);
1671         $c->dispatch;
1672         $status = $c->finalize;
1673     };
1674
1675     if ( my $error = $@ ) {
1676         chomp $error;
1677         $class->log->error(qq/Caught exception in engine "$error"/);
1678     }
1679
1680     $COUNT++;
1681
1682     if(my $coderef = $class->log->can('_flush')){
1683         $class->log->$coderef();
1684     }
1685     return $status;
1686 }
1687
1688 =head2 $c->prepare( @arguments )
1689
1690 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1691 etc.).
1692
1693 =cut
1694
1695 sub prepare {
1696     my ( $class, @arguments ) = @_;
1697
1698     # XXX
1699     # After the app/ctxt split, this should become an attribute based on something passed
1700     # into the application.
1701     $class->context_class( ref $class || $class ) unless $class->context_class;
1702
1703     my $c = $class->context_class->new({});
1704
1705     # For on-demand data
1706     $c->request->_context($c);
1707     $c->response->_context($c);
1708
1709     #surely this is not the most efficient way to do things...
1710     $c->stats($class->stats_class->new)->enable($c->use_stats);
1711     if ( $c->debug ) {
1712         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1713     }
1714
1715     #XXX reuse coderef from can
1716     # Allow engine to direct the prepare flow (for POE)
1717     if ( $c->engine->can('prepare') ) {
1718         $c->engine->prepare( $c, @arguments );
1719     }
1720     else {
1721         $c->prepare_request(@arguments);
1722         $c->prepare_connection;
1723         $c->prepare_query_parameters;
1724         $c->prepare_headers;
1725         $c->prepare_cookies;
1726         $c->prepare_path;
1727
1728         # Prepare the body for reading, either by prepare_body
1729         # or the user, if they are using $c->read
1730         $c->prepare_read;
1731
1732         # Parse the body unless the user wants it on-demand
1733         unless ( $c->config->{parse_on_demand} ) {
1734             $c->prepare_body;
1735         }
1736     }
1737
1738     my $method  = $c->req->method  || '';
1739     my $path    = $c->req->path;
1740     $path       = '/' unless length $path;
1741     my $address = $c->req->address || '';
1742
1743     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1744       if $c->debug;
1745
1746     $c->prepare_action;
1747
1748     return $c;
1749 }
1750
1751 =head2 $c->prepare_action
1752
1753 Prepares action. See L<Catalyst::Dispatcher>.
1754
1755 =cut
1756
1757 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1758
1759 =head2 $c->prepare_body
1760
1761 Prepares message body.
1762
1763 =cut
1764
1765 sub prepare_body {
1766     my $c = shift;
1767
1768     return if $c->request->_has_body;
1769
1770     # Initialize on-demand data
1771     $c->engine->prepare_body( $c, @_ );
1772     $c->prepare_parameters;
1773     $c->prepare_uploads;
1774
1775     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1776         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1777         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1778             my $param = $c->req->body_parameters->{$key};
1779             my $value = defined($param) ? $param : '';
1780             $t->row( $key,
1781                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1782         }
1783         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1784     }
1785 }
1786
1787 =head2 $c->prepare_body_chunk( $chunk )
1788
1789 Prepares a chunk of data before sending it to L<HTTP::Body>.
1790
1791 See L<Catalyst::Engine>.
1792
1793 =cut
1794
1795 sub prepare_body_chunk {
1796     my $c = shift;
1797     $c->engine->prepare_body_chunk( $c, @_ );
1798 }
1799
1800 =head2 $c->prepare_body_parameters
1801
1802 Prepares body parameters.
1803
1804 =cut
1805
1806 sub prepare_body_parameters {
1807     my $c = shift;
1808     $c->engine->prepare_body_parameters( $c, @_ );
1809 }
1810
1811 =head2 $c->prepare_connection
1812
1813 Prepares connection.
1814
1815 =cut
1816
1817 sub prepare_connection {
1818     my $c = shift;
1819     $c->engine->prepare_connection( $c, @_ );
1820 }
1821
1822 =head2 $c->prepare_cookies
1823
1824 Prepares cookies.
1825
1826 =cut
1827
1828 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1829
1830 =head2 $c->prepare_headers
1831
1832 Prepares headers.
1833
1834 =cut
1835
1836 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1837
1838 =head2 $c->prepare_parameters
1839
1840 Prepares parameters.
1841
1842 =cut
1843
1844 sub prepare_parameters {
1845     my $c = shift;
1846     $c->prepare_body_parameters;
1847     $c->engine->prepare_parameters( $c, @_ );
1848 }
1849
1850 =head2 $c->prepare_path
1851
1852 Prepares path and base.
1853
1854 =cut
1855
1856 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1857
1858 =head2 $c->prepare_query_parameters
1859
1860 Prepares query parameters.
1861
1862 =cut
1863
1864 sub prepare_query_parameters {
1865     my $c = shift;
1866
1867     $c->engine->prepare_query_parameters( $c, @_ );
1868
1869     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1870         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1871         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1872             my $param = $c->req->query_parameters->{$key};
1873             my $value = defined($param) ? $param : '';
1874             $t->row( $key,
1875                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1876         }
1877         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1878     }
1879 }
1880
1881 =head2 $c->prepare_read
1882
1883 Prepares the input for reading.
1884
1885 =cut
1886
1887 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1888
1889 =head2 $c->prepare_request
1890
1891 Prepares the engine request.
1892
1893 =cut
1894
1895 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1896
1897 =head2 $c->prepare_uploads
1898
1899 Prepares uploads.
1900
1901 =cut
1902
1903 sub prepare_uploads {
1904     my $c = shift;
1905
1906     $c->engine->prepare_uploads( $c, @_ );
1907
1908     if ( $c->debug && keys %{ $c->request->uploads } ) {
1909         my $t = Text::SimpleTable->new(
1910             [ 12, 'Parameter' ],
1911             [ 26, 'Filename' ],
1912             [ 18, 'Type' ],
1913             [ 9,  'Size' ]
1914         );
1915         for my $key ( sort keys %{ $c->request->uploads } ) {
1916             my $upload = $c->request->uploads->{$key};
1917             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1918                 $t->row( $key, $u->filename, $u->type, $u->size );
1919             }
1920         }
1921         $c->log->debug( "File Uploads are:\n" . $t->draw );
1922     }
1923 }
1924
1925 =head2 $c->prepare_write
1926
1927 Prepares the output for writing.
1928
1929 =cut
1930
1931 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1932
1933 =head2 $c->request_class
1934
1935 Returns or sets the request class.
1936
1937 =head2 $c->response_class
1938
1939 Returns or sets the response class.
1940
1941 =head2 $c->read( [$maxlength] )
1942
1943 Reads a chunk of data from the request body. This method is designed to
1944 be used in a while loop, reading C<$maxlength> bytes on every call.
1945 C<$maxlength> defaults to the size of the request if not specified.
1946
1947 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1948 directly.
1949
1950 Warning: If you use read(), Catalyst will not process the body,
1951 so you will not be able to access POST parameters or file uploads via
1952 $c->request.  You must handle all body parsing yourself.
1953
1954 =cut
1955
1956 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1957
1958 =head2 $c->run
1959
1960 Starts the engine.
1961
1962 =cut
1963
1964 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1965
1966 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1967
1968 Sets an action in a given namespace.
1969
1970 =cut
1971
1972 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1973
1974 =head2 $c->setup_actions($component)
1975
1976 Sets up actions for a component.
1977
1978 =cut
1979
1980 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1981
1982 =head2 $c->setup_components
1983
1984 Sets up components. Specify a C<setup_components> config option to pass
1985 additional options directly to L<Module::Pluggable>. To add additional
1986 search paths, specify a key named C<search_extra> as an array
1987 reference. Items in the array beginning with C<::> will have the
1988 application class name prepended to them.
1989
1990 All components found will also have any
1991 L<Devel::InnerPackage|inner packages> loaded and set up as components.
1992 Note, that modules which are B<not> an I<inner package> of the main
1993 file namespace loaded will not be instantiated as components.
1994
1995 =cut
1996
1997 sub setup_components {
1998     my $class = shift;
1999
2000     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2001     my $config  = $class->config->{ setup_components };
2002     my $extra   = delete $config->{ search_extra } || [];
2003
2004     push @paths, @$extra;
2005
2006     my $locator = Module::Pluggable::Object->new(
2007         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2008         %$config
2009     );
2010
2011     my @comps = sort { length $a <=> length $b } $locator->plugins;
2012     my %comps = map { $_ => 1 } @comps;
2013
2014     for my $component ( @comps ) {
2015
2016         # We pass ignore_loaded here so that overlay files for (e.g.)
2017         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2018         # we know M::P::O found a file on disk so this is safe
2019
2020         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2021         #Class::MOP::load_class($component);
2022
2023         my $module  = $class->setup_component( $component );
2024         my %modules = (
2025             $component => $module,
2026             map {
2027                 $_ => $class->setup_component( $_ )
2028             } grep {
2029               not exists $comps{$_}
2030             } Devel::InnerPackage::list_packages( $component )
2031         );
2032
2033         for my $key ( keys %modules ) {
2034             $class->components->{ $key } = $modules{ $key };
2035         }
2036     }
2037 }
2038
2039 =head2 $c->setup_component
2040
2041 =cut
2042
2043 sub setup_component {
2044     my( $class, $component ) = @_;
2045
2046     unless ( $component->can( 'COMPONENT' ) ) {
2047         return $component;
2048     }
2049
2050     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2051     my $config = $class->config->{ $suffix } || {};
2052
2053     my $instance = eval { $component->COMPONENT( $class, $config ); };
2054
2055     if ( my $error = $@ ) {
2056         chomp $error;
2057         Catalyst::Exception->throw(
2058             message => qq/Couldn't instantiate component "$component", "$error"/
2059         );
2060     }
2061
2062     Catalyst::Exception->throw(
2063         message =>
2064         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2065     ) unless blessed($instance);
2066
2067     return $instance;
2068 }
2069
2070 =head2 $c->setup_dispatcher
2071
2072 Sets up dispatcher.
2073
2074 =cut
2075
2076 sub setup_dispatcher {
2077     my ( $class, $dispatcher ) = @_;
2078
2079     if ($dispatcher) {
2080         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2081     }
2082
2083     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2084         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2085     }
2086
2087     unless ($dispatcher) {
2088         $dispatcher = $class->dispatcher_class;
2089     }
2090
2091     Class::MOP::load_class($dispatcher);
2092
2093     # dispatcher instance
2094     $class->dispatcher( $dispatcher->new );
2095 }
2096
2097 =head2 $c->setup_engine
2098
2099 Sets up engine.
2100
2101 =cut
2102
2103 sub setup_engine {
2104     my ( $class, $engine ) = @_;
2105
2106     if ($engine) {
2107         $engine = 'Catalyst::Engine::' . $engine;
2108     }
2109
2110     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2111         $engine = 'Catalyst::Engine::' . $env;
2112     }
2113
2114     if ( $ENV{MOD_PERL} ) {
2115         my $meta = Class::MOP::get_metaclass_by_name($class);
2116
2117         # create the apache method
2118         $meta->add_method('apache' => sub { shift->engine->apache });
2119
2120         my ( $software, $version ) =
2121           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2122
2123         $version =~ s/_//g;
2124         $version =~ s/(\.[^.]+)\./$1/g;
2125
2126         if ( $software eq 'mod_perl' ) {
2127
2128             if ( !$engine ) {
2129
2130                 if ( $version >= 1.99922 ) {
2131                     $engine = 'Catalyst::Engine::Apache2::MP20';
2132                 }
2133
2134                 elsif ( $version >= 1.9901 ) {
2135                     $engine = 'Catalyst::Engine::Apache2::MP19';
2136                 }
2137
2138                 elsif ( $version >= 1.24 ) {
2139                     $engine = 'Catalyst::Engine::Apache::MP13';
2140                 }
2141
2142                 else {
2143                     Catalyst::Exception->throw( message =>
2144                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2145                 }
2146
2147             }
2148
2149             # install the correct mod_perl handler
2150             if ( $version >= 1.9901 ) {
2151                 *handler = sub  : method {
2152                     shift->handle_request(@_);
2153                 };
2154             }
2155             else {
2156                 *handler = sub ($$) { shift->handle_request(@_) };
2157             }
2158
2159         }
2160
2161         elsif ( $software eq 'Zeus-Perl' ) {
2162             $engine = 'Catalyst::Engine::Zeus';
2163         }
2164
2165         else {
2166             Catalyst::Exception->throw(
2167                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2168         }
2169     }
2170
2171     unless ($engine) {
2172         $engine = $class->engine_class;
2173     }
2174
2175     Class::MOP::load_class($engine);
2176
2177     # check for old engines that are no longer compatible
2178     my $old_engine;
2179     if ( $engine->isa('Catalyst::Engine::Apache')
2180         && !Catalyst::Engine::Apache->VERSION )
2181     {
2182         $old_engine = 1;
2183     }
2184
2185     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2186         && Catalyst::Engine::Server->VERSION le '0.02' )
2187     {
2188         $old_engine = 1;
2189     }
2190
2191     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2192         && $engine->VERSION eq '0.01' )
2193     {
2194         $old_engine = 1;
2195     }
2196
2197     elsif ($engine->isa('Catalyst::Engine::Zeus')
2198         && $engine->VERSION eq '0.01' )
2199     {
2200         $old_engine = 1;
2201     }
2202
2203     if ($old_engine) {
2204         Catalyst::Exception->throw( message =>
2205               qq/Engine "$engine" is not supported by this version of Catalyst/
2206         );
2207     }
2208
2209     # engine instance
2210     $class->engine( $engine->new );
2211 }
2212
2213 =head2 $c->setup_home
2214
2215 Sets up the home directory.
2216
2217 =cut
2218
2219 sub setup_home {
2220     my ( $class, $home ) = @_;
2221
2222     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2223         $home = $env;
2224     }
2225
2226     $home ||= Catalyst::Utils::home($class);
2227
2228     if ($home) {
2229         #I remember recently being scolded for assigning config values like this
2230         $class->config->{home} ||= $home;
2231         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2232     }
2233 }
2234
2235 =head2 $c->setup_log
2236
2237 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2238 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2239 log to.
2240
2241 This method also installs a C<debug> method that returns a true value into the
2242 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2243 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2244
2245 Note that if the log has already been setup, by either a previous call to
2246 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2247 that this method won't actually set up the log object.
2248
2249 =cut
2250
2251 sub setup_log {
2252     my ( $class, $levels ) = @_;
2253
2254     $levels ||= '';
2255     $levels =~ s/^\s+//;
2256     $levels =~ s/\s+$//;
2257     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels || '';
2258
2259     unless ( $class->log ) {
2260         $class->log( Catalyst::Log->new(keys %levels) );
2261     }
2262
2263     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2264     if ( defined($env_debug) or $levels{debug} ) {
2265         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2266         $class->log->debug('Debug messages enabled');
2267     }
2268 }
2269
2270 =head2 $c->setup_plugins
2271
2272 Sets up plugins.
2273
2274 =cut
2275
2276 =head2 $c->setup_stats
2277
2278 Sets up timing statistics class.
2279
2280 =cut
2281
2282 sub setup_stats {
2283     my ( $class, $stats ) = @_;
2284
2285     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2286
2287     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2288     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2289         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2290         $class->log->debug('Statistics enabled');
2291     }
2292 }
2293
2294
2295 =head2 $c->registered_plugins
2296
2297 Returns a sorted list of the plugins which have either been stated in the
2298 import list or which have been added via C<< MyApp->plugin(@args); >>.
2299
2300 If passed a given plugin name, it will report a boolean value indicating
2301 whether or not that plugin is loaded.  A fully qualified name is required if
2302 the plugin name does not begin with C<Catalyst::Plugin::>.
2303
2304  if ($c->registered_plugins('Some::Plugin')) {
2305      ...
2306  }
2307
2308 =cut
2309
2310 {
2311
2312     sub registered_plugins {
2313         my $proto = shift;
2314         return sort keys %{ $proto->_plugins } unless @_;
2315         my $plugin = shift;
2316         return 1 if exists $proto->_plugins->{$plugin};
2317         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2318     }
2319
2320     sub _register_plugin {
2321         my ( $proto, $plugin, $instant ) = @_;
2322         my $class = ref $proto || $proto;
2323
2324         # no ignore_loaded here, the plugin may already have been
2325         # defined in memory and we don't want to error on "no file" if so
2326
2327         Class::MOP::load_class( $plugin );
2328
2329         $proto->_plugins->{$plugin} = 1;
2330         unless ($instant) {
2331             no strict 'refs';
2332             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2333               my @superclasses = ($plugin, $meta->superclasses );
2334               $meta->superclasses(@superclasses);
2335             } else {
2336               unshift @{"$class\::ISA"}, $plugin;
2337             }
2338         }
2339         return $class;
2340     }
2341
2342     sub setup_plugins {
2343         my ( $class, $plugins ) = @_;
2344
2345         $class->_plugins( {} ) unless $class->_plugins;
2346         $plugins ||= [];
2347         for my $plugin ( reverse @$plugins ) {
2348
2349             unless ( $plugin =~ s/\A\+// ) {
2350                 $plugin = "Catalyst::Plugin::$plugin";
2351             }
2352
2353             $class->_register_plugin($plugin);
2354         }
2355     }
2356 }
2357
2358 =head2 $c->stack
2359
2360 Returns an arrayref of the internal execution stack (actions that are
2361 currently executing).
2362
2363 =head2 $c->stats_class
2364
2365 Returns or sets the stats (timing statistics) class.
2366
2367 =head2 $c->use_stats
2368
2369 Returns 1 when stats collection is enabled.  Stats collection is enabled
2370 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2371 environment variable is set.
2372
2373 Note that this is a static method, not an accessor and should be overloaded
2374 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2375
2376 =cut
2377
2378 sub use_stats { 0 }
2379
2380
2381 =head2 $c->write( $data )
2382
2383 Writes $data to the output stream. When using this method directly, you
2384 will need to manually set the C<Content-Length> header to the length of
2385 your output data, if known.
2386
2387 =cut
2388
2389 sub write {
2390     my $c = shift;
2391
2392     # Finalize headers if someone manually writes output
2393     $c->finalize_headers;
2394
2395     return $c->engine->write( $c, @_ );
2396 }
2397
2398 =head2 version
2399
2400 Returns the Catalyst version number. Mostly useful for "powered by"
2401 messages in template systems.
2402
2403 =cut
2404
2405 sub version { return $Catalyst::VERSION }
2406
2407 =head1 INTERNAL ACTIONS
2408
2409 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2410 C<_ACTION>, and C<_END>. These are by default not shown in the private
2411 action table, but you can make them visible with a config parameter.
2412
2413     MyApp->config->{show_internal_actions} = 1;
2414
2415 =head1 CASE SENSITIVITY
2416
2417 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2418 mapped to C</foo/bar>. You can activate case sensitivity with a config
2419 parameter.
2420
2421     MyApp->config->{case_sensitive} = 1;
2422
2423 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2424
2425 =head1 ON-DEMAND PARSER
2426
2427 The request body is usually parsed at the beginning of a request,
2428 but if you want to handle input yourself, you can enable on-demand
2429 parsing with a config parameter.
2430
2431     MyApp->config->{parse_on_demand} = 1;
2432
2433 =head1 PROXY SUPPORT
2434
2435 Many production servers operate using the common double-server approach,
2436 with a lightweight frontend web server passing requests to a larger
2437 backend server. An application running on the backend server must deal
2438 with two problems: the remote user always appears to be C<127.0.0.1> and
2439 the server's hostname will appear to be C<localhost> regardless of the
2440 virtual host that the user connected through.
2441
2442 Catalyst will automatically detect this situation when you are running
2443 the frontend and backend servers on the same machine. The following
2444 changes are made to the request.
2445
2446     $c->req->address is set to the user's real IP address, as read from
2447     the HTTP X-Forwarded-For header.
2448
2449     The host value for $c->req->base and $c->req->uri is set to the real
2450     host, as read from the HTTP X-Forwarded-Host header.
2451
2452 Obviously, your web server must support these headers for this to work.
2453
2454 In a more complex server farm environment where you may have your
2455 frontend proxy server(s) on different machines, you will need to set a
2456 configuration option to tell Catalyst to read the proxied data from the
2457 headers.
2458
2459     MyApp->config->{using_frontend_proxy} = 1;
2460
2461 If you do not wish to use the proxy support at all, you may set:
2462
2463     MyApp->config->{ignore_frontend_proxy} = 1;
2464
2465 =head1 THREAD SAFETY
2466
2467 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2468 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2469 believe the Catalyst core to be thread-safe.
2470
2471 If you plan to operate in a threaded environment, remember that all other
2472 modules you are using must also be thread-safe. Some modules, most notably
2473 L<DBD::SQLite>, are not thread-safe.
2474
2475 =head1 SUPPORT
2476
2477 IRC:
2478
2479     Join #catalyst on irc.perl.org.
2480
2481 Mailing Lists:
2482
2483     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2484     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2485
2486 Web:
2487
2488     http://catalyst.perl.org
2489
2490 Wiki:
2491
2492     http://dev.catalyst.perl.org
2493
2494 =head1 SEE ALSO
2495
2496 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2497
2498 =head2 L<Catalyst::Manual> - The Catalyst Manual
2499
2500 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2501
2502 =head2 L<Catalyst::Engine> - Core engine
2503
2504 =head2 L<Catalyst::Log> - Log class.
2505
2506 =head2 L<Catalyst::Request> - Request object
2507
2508 =head2 L<Catalyst::Response> - Response object
2509
2510 =head2 L<Catalyst::Test> - The test suite.
2511
2512 =head1 PROJECT FOUNDER
2513
2514 sri: Sebastian Riedel <sri@cpan.org>
2515
2516 =head1 CONTRIBUTORS
2517
2518 abw: Andy Wardley
2519
2520 acme: Leon Brocard <leon@astray.com>
2521
2522 Andrew Bramble
2523
2524 Andrew Ford
2525
2526 Andrew Ruthven
2527
2528 andyg: Andy Grundman <andy@hybridized.org>
2529
2530 audreyt: Audrey Tang
2531
2532 bricas: Brian Cassidy <bricas@cpan.org>
2533
2534 Caelum: Rafael Kitover <rkitover@io.com>
2535
2536 chansen: Christian Hansen
2537
2538 chicks: Christopher Hicks
2539
2540 David E. Wheeler
2541
2542 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2543
2544 Drew Taylor
2545
2546 esskar: Sascha Kiefer
2547
2548 fireartist: Carl Franks <cfranks@cpan.org>
2549
2550 gabb: Danijel Milicevic
2551
2552 Gary Ashton Jones
2553
2554 Geoff Richards
2555
2556 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2557
2558 jcamacho: Juan Camacho
2559
2560 jhannah: Jay Hannah <jay@jays.net>
2561
2562 Jody Belka
2563
2564 Johan Lindstrom
2565
2566 jon: Jon Schutz <jjschutz@cpan.org>
2567
2568 marcus: Marcus Ramberg <mramberg@cpan.org>
2569
2570 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2571
2572 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2573
2574 mugwump: Sam Vilain
2575
2576 naughton: David Naughton
2577
2578 ningu: David Kamholz <dkamholz@cpan.org>
2579
2580 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2581
2582 numa: Dan Sully <daniel@cpan.org>
2583
2584 obra: Jesse Vincent
2585
2586 omega: Andreas Marienborg
2587
2588 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2589
2590 rafl: Florian Ragwitz <rafl@debian.org>
2591
2592 sky: Arthur Bergman
2593
2594 the_jester: Jesse Sheidlower
2595
2596 t0m: Tomas Doran <bobtfish@bobtfish.net>
2597
2598 Ulf Edvinsson
2599
2600 willert: Sebastian Willert <willert@cpan.org>
2601
2602 =head1 LICENSE
2603
2604 This library is free software, you can redistribute it and/or modify it under
2605 the same terms as Perl itself.
2606
2607 =cut
2608
2609 no Moose;
2610
2611 __PACKAGE__->meta->make_immutable;
2612
2613 1;