lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         my $class = ref $self;
  67         my $composed_request_class = $class->composed_request_class;
  68         return $composed_request_class->new( $self->_build_request_constructor_args);
  69     },
  70     lazy => 1,
  71 );
  72 sub _build_request_constructor_args {
  73     my $self = shift;
  74     my %p = ( _log => $self->log );
  75     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  76     $p{data_handlers} = {$self->registered_data_handlers};
  77     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  78       if $self->config->{use_hash_multivalue_in_request};
  79     \%p;
  80 }
  81
  82 sub composed_request_class {
  83   my $class = shift;
  84   my @traits = (@{$class->request_class_traits||[]}, @{$class->config->{request_class_traits}||[]});
  85
  86   # For each trait listed, figure out what the namespace is.  First we try the $trait
  87   # as it is in the config.  Then try $MyApp::TraitFor::Request:$trait. Last we try
  88   # Catalyst::TraitFor::Request::$trait.  If none load, throw error.
  89
  90   my $trait_ns = 'TraitFor::Request';
  91   my @normalized_traits = map {
  92     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
  93   } @traits;
  94
  95   return $class->_composed_request_class ||
  96     $class->_composed_request_class(Moose::Util::with_traits($class->request_class, @normalized_traits));
  97 }
  98
  99 has response => (
 100     is => 'rw',
 101     default => sub {
 102         my $self = shift;
 103         my $class = ref $self;
 104         my $composed_response_class = $class->composed_response_class;
 105         return $composed_response_class->new( $self->_build_response_constructor_args);
 106     },
 107     lazy => 1,
 108 );
 109 sub _build_response_constructor_args {
 110     return +{
 111       _log => $_[0]->log,
 112       encoding => $_[0]->encoding,
 113     };
 114 }
 115
 116 sub composed_response_class {
 117   my $class = shift;
 118   my @traits = (@{$class->response_class_traits||[]}, @{$class->config->{response_class_traits}||[]});
 119
 120   my $trait_ns = 'TraitFor::Response';
 121   my @normalized_traits = map {
 122     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 123   } @traits;
 124
 125   return $class->_composed_response_class ||
 126     $class->_composed_response_class(Moose::Util::with_traits($class->response_class, @normalized_traits));
 127 }
 128
 129 has namespace => (is => 'rw');
 130
 131 sub depth { scalar @{ shift->stack || [] }; }
 132 sub comp { shift->component(@_) }
 133
 134 sub req {
 135     my $self = shift; return $self->request(@_);
 136 }
 137 sub res {
 138     my $self = shift; return $self->response(@_);
 139 }
 140
 141 # For backwards compatibility
 142 sub finalize_output { shift->finalize_body(@_) };
 143
 144 # For statistics
 145 our $COUNT     = 1;
 146 our $START     = time;
 147 our $RECURSION = 1000;
 148 our $DETACH    = Catalyst::Exception::Detach->new;
 149 our $GO        = Catalyst::Exception::Go->new;
 150
 151 #I imagine that very few of these really
 152 #need to be class variables. if any.
 153 #maybe we should just make them attributes with a default?
 154 __PACKAGE__->mk_classdata($_)
 155   for qw/components arguments dispatcher engine log dispatcher_class
 156   engine_loader context_class request_class response_class stats_class
 157   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 158   _data_handlers _encoding _encode_check finalized_default_middleware
 159   request_class_traits response_class_traits stats_class_traits
 160   _composed_request_class _composed_response_class _composed_stats_class/;
 161
 162 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 163 __PACKAGE__->request_class('Catalyst::Request');
 164 __PACKAGE__->response_class('Catalyst::Response');
 165 __PACKAGE__->stats_class('Catalyst::Stats');
 166
 167 sub composed_stats_class {
 168   my $class = shift;
 169   my @traits = (@{$class->stats_class_traits||[]}, @{$class->config->{stats_class_traits}||[]});
 170
 171   my $trait_ns = 'TraitFor::Stats';
 172   my @normalized_traits = map {
 173     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 174   } @traits;
 175
 176   return $class->_composed_stats_class ||
 177     $class->_composed_stats_class(Moose::Util::with_traits($class->stats_class, @normalized_traits));
 178 }
 179
 180 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 181
 182 # Remember to update this in Catalyst::Runtime as well!
 183 our $VERSION = '5.90101';
 184 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 185
 186 sub import {
 187     my ( $class, @arguments ) = @_;
 188
 189     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 190     # callers @ISA.
 191     return unless $class eq 'Catalyst';
 192
 193     my $caller = caller();
 194     return if $caller eq 'main';
 195
 196     my $meta = Moose::Meta::Class->initialize($caller);
 197     unless ( $caller->isa('Catalyst') ) {
 198         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 199         $meta->superclasses(@superclasses);
 200     }
 201     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 202     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 203
 204     unless( $meta->has_method('meta') ){
 205         if ($Moose::VERSION >= 1.15) {
 206             $meta->_add_meta_method('meta');
 207         }
 208         else {
 209             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 210         }
 211     }
 212
 213     $caller->arguments( [@arguments] );
 214     $caller->setup_home;
 215 }
 216
 217 sub _application { $_[0] }
 218
 219 =encoding UTF-8
 220
 221 =head1 NAME
 222
 223 Catalyst - The Elegant MVC Web Application Framework
 224
 225 =for html
 226 <a href="https://badge.fury.io/pl/Catalyst-Runtime"><img src="https://badge.fury.io/pl/Catalyst-Runtime.svg" alt="CPAN version" height="18"></a>
 227 <a href="https://travis-ci.org/perl-catalyst/catalyst-runtime/"><img src="https://api.travis-ci.org/perl-catalyst/catalyst-runtime.png" alt="Catalyst></a>
 228 <a href="http://cpants.cpanauthors.org/dist/Catalyst-Runtime"><img src="http://cpants.cpanauthors.org/dist/Catalyst-Runtime.png" alt='Kwalitee Score' /></a>
 229
 230 =head1 SYNOPSIS
 231
 232 See the L<Catalyst::Manual> distribution for comprehensive
 233 documentation and tutorials.
 234
 235     # Install Catalyst::Devel for helpers and other development tools
 236     # use the helper to create a new application
 237     catalyst.pl MyApp
 238
 239     # add models, views, controllers
 240     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 241     script/myapp_create.pl view MyTemplate TT
 242     script/myapp_create.pl controller Search
 243
 244     # built in testserver -- use -r to restart automatically on changes
 245     # --help to see all available options
 246     script/myapp_server.pl
 247
 248     # command line testing interface
 249     script/myapp_test.pl /yada
 250
 251     ### in lib/MyApp.pm
 252     use Catalyst qw/-Debug/; # include plugins here as well
 253
 254     ### In lib/MyApp/Controller/Root.pm (autocreated)
 255     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 256         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 257         $c->stash->{template} = 'foo.tt'; # set the template
 258         # lookup something from db -- stash vars are passed to TT
 259         $c->stash->{data} =
 260           $c->model('Database::Foo')->search( { country => $args[0] } );
 261         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 262             $c->forward( 'bar' ); # process another action
 263             # do something else after forward returns
 264         }
 265     }
 266
 267     # The foo.tt TT template can use the stash data from the database
 268     [% WHILE (item = data.next) %]
 269         [% item.foo %]
 270     [% END %]
 271
 272     # called for /bar/of/soap, /bar/of/soap/10, etc.
 273     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 274
 275     # called after all actions are finished
 276     sub end : Action {
 277         my ( $self, $c ) = @_;
 278         if ( scalar @{ $c->error } ) { ... } # handle errors
 279         return if $c->res->body; # already have a response
 280         $c->forward( 'MyApp::View::TT' ); # render template
 281     }
 282
 283 See L<Catalyst::Manual::Intro> for additional information.
 284
 285 =head1 DESCRIPTION
 286
 287 Catalyst is a modern framework for making web applications without the
 288 pain usually associated with this process. This document is a reference
 289 to the main Catalyst application. If you are a new user, we suggest you
 290 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 291
 292 See L<Catalyst::Manual> for more documentation.
 293
 294 Catalyst plugins can be loaded by naming them as arguments to the "use
 295 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 296 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 297 C<My::Module>.
 298
 299     use Catalyst qw/My::Module/;
 300
 301 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 302 fully qualify the name by using a unary plus:
 303
 304     use Catalyst qw/
 305         My::Module
 306         +Fully::Qualified::Plugin::Name
 307     /;
 308
 309 Special flags like C<-Debug> can also be specified as
 310 arguments when Catalyst is loaded:
 311
 312     use Catalyst qw/-Debug My::Module/;
 313
 314 The position of plugins and flags in the chain is important, because
 315 they are loaded in the order in which they appear.
 316
 317 The following flags are supported:
 318
 319 =head2 -Debug
 320
 321 Enables debug output. You can also force this setting from the system
 322 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 323 settings override the application, with <MYAPP>_DEBUG having the highest
 324 priority.
 325
 326 This sets the log level to 'debug' and enables full debug output on the
 327 error screen. If you only want the latter, see L<< $c->debug >>.
 328
 329 =head2 -Home
 330
 331 Forces Catalyst to use a specific home directory, e.g.:
 332
 333     use Catalyst qw[-Home=/usr/mst];
 334
 335 This can also be done in the shell environment by setting either the
 336 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 337 is replaced with the uppercased name of your application, any "::" in
 338 the name will be replaced with underscores, e.g. MyApp::Web should use
 339 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 340
 341 If none of these are set, Catalyst will attempt to automatically detect the
 342 home directory. If you are working in a development environment, Catalyst
 343 will try and find the directory containing either Makefile.PL, Build.PL,
 344 dist.ini, or cpanfile. If the application has been installed into the system
 345 (i.e. you have done C<make install>), then Catalyst will use the path to your
 346 application module, without the .pm extension (e.g., /foo/MyApp if your
 347 application was installed at /foo/MyApp.pm)
 348
 349 =head2 -Log
 350
 351     use Catalyst '-Log=warn,fatal,error';
 352
 353 Specifies a comma-delimited list of log levels.
 354
 355 =head2 -Stats
 356
 357 Enables statistics collection and reporting.
 358
 359    use Catalyst qw/-Stats=1/;
 360
 361 You can also force this setting from the system environment with CATALYST_STATS
 362 or <MYAPP>_STATS. The environment settings override the application, with
 363 <MYAPP>_STATS having the highest priority.
 364
 365 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 366
 367 =head1 METHODS
 368
 369 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 370
 371 =head2 $c->action
 372
 373 Returns a L<Catalyst::Action> object for the current action, which
 374 stringifies to the action name. See L<Catalyst::Action>.
 375
 376 =head2 $c->namespace
 377
 378 Returns the namespace of the current action, i.e., the URI prefix
 379 corresponding to the controller of the current action. For example:
 380
 381     # in Controller::Foo::Bar
 382     $c->namespace; # returns 'foo/bar';
 383
 384 =head2 $c->request
 385
 386 =head2 $c->req
 387
 388 Returns the current L<Catalyst::Request> object, giving access to
 389 information about the current client request (including parameters,
 390 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 391
 392 =head2 REQUEST FLOW HANDLING
 393
 394 =head2 $c->forward( $action [, \@arguments ] )
 395
 396 =head2 $c->forward( $class, $method, [, \@arguments ] )
 397
 398 This is one way of calling another action (method) in the same or
 399 a different controller. You can also use C<< $self->my_method($c, @args) >>
 400 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 401 in a different controller.
 402 The main difference is that 'forward' uses some of the Catalyst request
 403 cycle overhead, including debugging, which may be useful to you. On the
 404 other hand, there are some complications to using 'forward', restrictions
 405 on values returned from 'forward', and it may not handle errors as you prefer.
 406 Whether you use 'forward' or not is up to you; it is not considered superior to
 407 the other ways to call a method.
 408
 409 'forward' calls  another action, by its private name. If you give a
 410 class name but no method, C<process()> is called. You may also optionally
 411 pass arguments in an arrayref. The action will receive the arguments in
 412 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 413 C<< $c->req->args >> will be restored to the previous values.
 414
 415 Any data C<return>ed from the action forwarded to, will be returned by the
 416 call to forward.
 417
 418     my $foodata = $c->forward('/foo');
 419     $c->forward('index');
 420     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 421     $c->forward('View::TT');
 422
 423 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 424 an C<< eval { } >> around the call (actually
 425 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 426 exceptions thrown by the called action non-fatal and pushing them onto
 427 $c->error instead. If you want C<die> to propagate you need to do something
 428 like:
 429
 430     $c->forward('foo');
 431     die join "\n", @{ $c->error } if @{ $c->error };
 432
 433 Or make sure to always return true values from your actions and write
 434 your code like this:
 435
 436     $c->forward('foo') || return;
 437
 438 Another note is that C<< $c->forward >> always returns a scalar because it
 439 actually returns $c->state which operates in a scalar context.
 440 Thus, something like:
 441
 442     return @array;
 443
 444 in an action that is forwarded to is going to return a scalar,
 445 i.e. how many items are in that array, which is probably not what you want.
 446 If you need to return an array then return a reference to it,
 447 or stash it like so:
 448
 449     $c->stash->{array} = \@array;
 450
 451 and access it from the stash.
 452
 453 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 454
 455 =cut
 456
 457 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 458
 459 =head2 $c->detach( $action [, \@arguments ] )
 460
 461 =head2 $c->detach( $class, $method, [, \@arguments ] )
 462
 463 =head2 $c->detach()
 464
 465 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 466 doesn't return to the previous action when processing is finished.
 467
 468 When called with no arguments it escapes the processing chain entirely.
 469
 470 =cut
 471
 472 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 473
 474 =head2 $c->visit( $action [, \@arguments ] )
 475
 476 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 477
 478 =head2 $c->visit( $class, $method, [, \@arguments ] )
 479
 480 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 481
 482 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 483 but does a full dispatch, instead of just calling the new C<$action> /
 484 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 485 you go to are called, just like a new request.
 486
 487 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 488 This means, for example, that C<< $c->action >> methods such as
 489 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 490 L<reverse|Catalyst::Action/reverse> return information for the visited action
 491 when they are invoked within the visited action.  This is different from the
 492 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 493 continues to use the $c->action object from the caller action even when
 494 invoked from the called action.
 495
 496 C<< $c->stash >> is kept unchanged.
 497
 498 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 499 allows you to "wrap" another action, just as it would have been called by
 500 dispatching from a URL, while the analogous
 501 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 502 transfer control to another action as if it had been reached directly from a URL.
 503
 504 =cut
 505
 506 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 507
 508 =head2 $c->go( $action [, \@arguments ] )
 509
 510 =head2 $c->go( $action [, \@captures, \@arguments ] )
 511
 512 =head2 $c->go( $class, $method, [, \@arguments ] )
 513
 514 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 515
 516 The relationship between C<go> and
 517 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 518 the relationship between
 519 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 520 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 521 C<< $c->go >> will perform a full dispatch on the specified action or method,
 522 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 523 C<go> escapes the processing of the current request chain on completion, and
 524 does not return to its caller.
 525
 526 @arguments are arguments to the final destination of $action. @captures are
 527 arguments to the intermediate steps, if any, on the way to the final sub of
 528 $action.
 529
 530 =cut
 531
 532 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 533
 534 =head2 $c->response
 535
 536 =head2 $c->res
 537
 538 Returns the current L<Catalyst::Response> object, see there for details.
 539
 540 =head2 $c->stash
 541
 542 Returns a hashref to the stash, which may be used to store data and pass
 543 it between components during a request. You can also set hash keys by
 544 passing arguments. The stash is automatically sent to the view. The
 545 stash is cleared at the end of a request; it cannot be used for
 546 persistent storage (for this you must use a session; see
 547 L<Catalyst::Plugin::Session> for a complete system integrated with
 548 Catalyst).
 549
 550     $c->stash->{foo} = $bar;
 551     $c->stash( { moose => 'majestic', qux => 0 } );
 552     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 553
 554     # stash is automatically passed to the view for use in a template
 555     $c->forward( 'MyApp::View::TT' );
 556
 557 The stash hash is currently stored in the PSGI C<$env> and is managed by
 558 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 559 the stash can be accessed in sub applications mounted under your main
 560 L<Catalyst> application.  For example if you delegate the response of an
 561 action to another L<Catalyst> application, that sub application will have
 562 access to all the stash keys of the main one, and if can of course add
 563 more keys of its own.  However those new keys will not 'bubble' back up
 564 to the main application.
 565
 566 For more information the best thing to do is to review the test case:
 567 t/middleware-stash.t in the distribution /t directory.
 568
 569 =cut
 570
 571 sub stash {
 572   my $c = shift;
 573   $c->log->error("You are requesting the stash but you don't have a context") unless blessed $c;
 574   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 575 }
 576
 577 =head2 $c->error
 578
 579 =head2 $c->error($error, ...)
 580
 581 =head2 $c->error($arrayref)
 582
 583 Returns an arrayref containing error messages.  If Catalyst encounters an
 584 error while processing a request, it stores the error in $c->error.  This
 585 method should only be used to store fatal error messages.
 586
 587     my @error = @{ $c->error };
 588
 589 Add a new error.
 590
 591     $c->error('Something bad happened');
 592
 593 Calling this will always return an arrayref (if there are no errors it
 594 will be an empty arrayref.
 595
 596 =cut
 597
 598 sub error {
 599     my $c = shift;
 600     if ( $_[0] ) {
 601         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 602         croak @$error unless ref $c;
 603         push @{ $c->{error} }, @$error;
 604     }
 605     elsif ( defined $_[0] ) { $c->{error} = undef }
 606     return $c->{error} || [];
 607 }
 608
 609
 610 =head2 $c->state
 611
 612 Contains the return value of the last executed action.
 613 Note that << $c->state >> operates in a scalar context which means that all
 614 values it returns are scalar.
 615
 616 =head2 $c->clear_errors
 617
 618 Clear errors.  You probably don't want to clear the errors unless you are
 619 implementing a custom error screen.
 620
 621 This is equivalent to running
 622
 623     $c->error(0);
 624
 625 =cut
 626
 627 sub clear_errors {
 628     my $c = shift;
 629     $c->error(0);
 630 }
 631
 632 =head2 $c->has_errors
 633
 634 Returns true if you have errors
 635
 636 =cut
 637
 638 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 639
 640 =head2 $c->last_error
 641
 642 Returns the most recent error in the stack (the one most recently added...)
 643 or nothing if there are no errors.  This does not modify the contents of the
 644 error stack.
 645
 646 =cut
 647
 648 sub last_error {
 649   my (@errs) = @{shift->error};
 650   return scalar(@errs) ? $errs[-1]: undef;
 651 }
 652
 653 =head2 shift_errors
 654
 655 shifts the most recently added error off the error stack and returns it.  Returns
 656 nothing if there are no more errors.
 657
 658 =cut
 659
 660 sub shift_errors {
 661     my ($self) = @_;
 662     my @errors = @{$self->error};
 663     my $err = shift(@errors);
 664     $self->{error} = \@errors;
 665     return $err;
 666 }
 667
 668 =head2 pop_errors
 669
 670 pops the most recently added error off the error stack and returns it.  Returns
 671 nothing if there are no more errors.
 672
 673 =cut
 674
 675 sub pop_errors {
 676     my ($self) = @_;
 677     my @errors = @{$self->error};
 678     my $err = pop(@errors);
 679     $self->{error} = \@errors;
 680     return $err;
 681 }
 682
 683 sub _comp_search_prefixes {
 684     my $c = shift;
 685     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 686 }
 687
 688 # search components given a name and some prefixes
 689 sub _comp_names_search_prefixes {
 690     my ( $c, $name, @prefixes ) = @_;
 691     my $appclass = ref $c || $c;
 692     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 693     $filter = qr/$filter/; # Compile regex now rather than once per loop
 694
 695     # map the original component name to the sub part that we will search against
 696     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 697         grep { /$filter/ } keys %{ $c->components };
 698
 699     # undef for a name will return all
 700     return keys %eligible if !defined $name;
 701
 702     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 703     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 704
 705     return @result if @result;
 706
 707     # if we were given a regexp to search against, we're done.
 708     return if $name->$_isa('Regexp');
 709
 710     # skip regexp fallback if configured
 711     return
 712         if $appclass->config->{disable_component_resolution_regex_fallback};
 713
 714     # regexp fallback
 715     $query  = qr/$name/i;
 716     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 717
 718     # no results? try against full names
 719     if( !@result ) {
 720         @result = grep { m{$query} } keys %eligible;
 721     }
 722
 723     # don't warn if we didn't find any results, it just might not exist
 724     if( @result ) {
 725         # Disgusting hack to work out correct method name
 726         my $warn_for = lc $prefixes[0];
 727         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 728            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 729            "component resolution is unreliable and unsafe.";
 730         my $short = $result[0];
 731         # remove the component namespace prefix
 732         $short =~ s/.*?(Model|Controller|View):://;
 733         my $shortmess = Carp::shortmess('');
 734         if ($shortmess =~ m#Catalyst/Plugin#) {
 735            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 736               "plugin's config";
 737         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 738            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 739               "component's config";
 740         } else {
 741            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 742               "but if you really wanted to search, pass in a regexp as the argument " .
 743               "like so: \$c->${warn_for}(qr/${name}/)";
 744         }
 745         $c->log->warn( "${msg}$shortmess" );
 746     }
 747
 748     return @result;
 749 }
 750
 751 # Find possible names for a prefix
 752 sub _comp_names {
 753     my ( $c, @prefixes ) = @_;
 754     my $appclass = ref $c || $c;
 755
 756     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 757
 758     my @names = map { s{$filter}{}; $_; }
 759         $c->_comp_names_search_prefixes( undef, @prefixes );
 760
 761     return @names;
 762 }
 763
 764 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 765
 766 sub _filter_component {
 767     my ( $c, $comp, @args ) = @_;
 768
 769     if(ref $comp eq 'CODE') {
 770       $comp = $comp->();
 771     }
 772
 773     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 774       return $comp->ACCEPT_CONTEXT( $c, @args );
 775     }
 776
 777     $c->log->warn("You called component '${\$comp->catalyst_component_name}' with arguments [@args], but this component does not ACCEPT_CONTEXT, so args are ignored.") if scalar(@args) && $c->debug;
 778
 779     return $comp;
 780 }
 781
 782 =head2 COMPONENT ACCESSORS
 783
 784 =head2 $c->controller($name)
 785
 786 Gets a L<Catalyst::Controller> instance by name.
 787
 788     $c->controller('Foo')->do_stuff;
 789
 790 If the name is omitted, will return the controller for the dispatched
 791 action.
 792
 793 If you want to search for controllers, pass in a regexp as the argument.
 794
 795     # find all controllers that start with Foo
 796     my @foo_controllers = $c->controller(qr{^Foo});
 797
 798
 799 =cut
 800
 801 sub controller {
 802     my ( $c, $name, @args ) = @_;
 803
 804     my $appclass = ref($c) || $c;
 805     if( $name ) {
 806         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 807             my $comps = $c->components;
 808             my $check = $appclass."::Controller::".$name;
 809             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 810         }
 811         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 812         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 813         return $c->_filter_component( $result[ 0 ], @args );
 814     }
 815
 816     return $c->component( $c->action->class );
 817 }
 818
 819 =head2 $c->model($name)
 820
 821 Gets a L<Catalyst::Model> instance by name.
 822
 823     $c->model('Foo')->do_stuff;
 824
 825 Any extra arguments are directly passed to ACCEPT_CONTEXT, if the model
 826 defines ACCEPT_CONTEXT.  If it does not, the args are discarded.
 827
 828 If the name is omitted, it will look for
 829  - a model object in $c->stash->{current_model_instance}, then
 830  - a model name in $c->stash->{current_model}, then
 831  - a config setting 'default_model', or
 832  - check if there is only one model, and return it if that's the case.
 833
 834 If you want to search for models, pass in a regexp as the argument.
 835
 836     # find all models that start with Foo
 837     my @foo_models = $c->model(qr{^Foo});
 838
 839 =cut
 840
 841 sub model {
 842     my ( $c, $name, @args ) = @_;
 843     my $appclass = ref($c) || $c;
 844     if( $name ) {
 845         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 846             my $comps = $c->components;
 847             my $check = $appclass."::Model::".$name;
 848             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 849         }
 850         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 851         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 852         return $c->_filter_component( $result[ 0 ], @args );
 853     }
 854
 855     if (ref $c) {
 856         return $c->stash->{current_model_instance}
 857           if $c->stash->{current_model_instance};
 858         return $c->model( $c->stash->{current_model} )
 859           if $c->stash->{current_model};
 860     }
 861     return $c->model( $appclass->config->{default_model} )
 862       if $appclass->config->{default_model};
 863
 864     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 865
 866     if( $rest ) {
 867         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 868         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 869         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 870         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 871         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 872     }
 873
 874     return $c->_filter_component( $comp );
 875 }
 876
 877
 878 =head2 $c->view($name)
 879
 880 Gets a L<Catalyst::View> instance by name.
 881
 882     $c->view('Foo')->do_stuff;
 883
 884 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 885
 886 If the name is omitted, it will look for
 887  - a view object in $c->stash->{current_view_instance}, then
 888  - a view name in $c->stash->{current_view}, then
 889  - a config setting 'default_view', or
 890  - check if there is only one view, and return it if that's the case.
 891
 892 If you want to search for views, pass in a regexp as the argument.
 893
 894     # find all views that start with Foo
 895     my @foo_views = $c->view(qr{^Foo});
 896
 897 =cut
 898
 899 sub view {
 900     my ( $c, $name, @args ) = @_;
 901
 902     my $appclass = ref($c) || $c;
 903     if( $name ) {
 904         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 905             my $comps = $c->components;
 906             my $check = $appclass."::View::".$name;
 907             if( exists $comps->{$check} ) {
 908                 return $c->_filter_component( $comps->{$check}, @args );
 909             }
 910             else {
 911                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 912             }
 913         }
 914         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 915         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 916         return $c->_filter_component( $result[ 0 ], @args );
 917     }
 918
 919     if (ref $c) {
 920         return $c->stash->{current_view_instance}
 921           if $c->stash->{current_view_instance};
 922         return $c->view( $c->stash->{current_view} )
 923           if $c->stash->{current_view};
 924     }
 925     return $c->view( $appclass->config->{default_view} )
 926       if $appclass->config->{default_view};
 927
 928     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 929
 930     if( $rest ) {
 931         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 932         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 933         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 934         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 935         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 936     }
 937
 938     return $c->_filter_component( $comp );
 939 }
 940
 941 =head2 $c->controllers
 942
 943 Returns the available names which can be passed to $c->controller
 944
 945 =cut
 946
 947 sub controllers {
 948     my ( $c ) = @_;
 949     return $c->_comp_names(qw/Controller C/);
 950 }
 951
 952 =head2 $c->models
 953
 954 Returns the available names which can be passed to $c->model
 955
 956 =cut
 957
 958 sub models {
 959     my ( $c ) = @_;
 960     return $c->_comp_names(qw/Model M/);
 961 }
 962
 963
 964 =head2 $c->views
 965
 966 Returns the available names which can be passed to $c->view
 967
 968 =cut
 969
 970 sub views {
 971     my ( $c ) = @_;
 972     return $c->_comp_names(qw/View V/);
 973 }
 974
 975 =head2 $c->comp($name)
 976
 977 =head2 $c->component($name)
 978
 979 Gets a component object by name. This method is not recommended,
 980 unless you want to get a specific component by full
 981 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 982 should be used instead.
 983
 984 If C<$name> is a regexp, a list of components matched against the full
 985 component name will be returned.
 986
 987 If Catalyst can't find a component by name, it will fallback to regex
 988 matching by default. To disable this behaviour set
 989 disable_component_resolution_regex_fallback to a true value.
 990
 991     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 992
 993 =cut
 994
 995 sub component {
 996     my ( $c, $name, @args ) = @_;
 997
 998     if( $name ) {
 999         my $comps = $c->components;
1000
1001         if( !ref $name ) {
1002             # is it the exact name?
1003             return $c->_filter_component( $comps->{ $name }, @args )
1004                        if exists $comps->{ $name };
1005
1006             # perhaps we just omitted "MyApp"?
1007             my $composed = ( ref $c || $c ) . "::${name}";
1008             return $c->_filter_component( $comps->{ $composed }, @args )
1009                        if exists $comps->{ $composed };
1010
1011             # search all of the models, views and controllers
1012             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
1013             return $c->_filter_component( $comp, @args ) if $comp;
1014         }
1015
1016         return
1017             if $c->config->{disable_component_resolution_regex_fallback};
1018
1019         # This is here so $c->comp( '::M::' ) works
1020         my $query = ref $name ? $name : qr{$name}i;
1021
1022         my @result = grep { m{$query} } keys %{ $c->components };
1023         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
1024
1025         if( $result[ 0 ] ) {
1026             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
1027             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
1028             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
1029             return $c->_filter_component( $result[ 0 ], @args );
1030         }
1031
1032         # I would expect to return an empty list here, but that breaks back-compat
1033     }
1034
1035     # fallback
1036     return sort keys %{ $c->components };
1037 }
1038
1039 =head2 CLASS DATA AND HELPER CLASSES
1040
1041 =head2 $c->config
1042
1043 Returns or takes a hashref containing the application's configuration.
1044
1045     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
1046
1047 You can also use a C<YAML>, C<XML> or L<Config::General> config file
1048 like C<myapp.conf> in your applications home directory. See
1049 L<Catalyst::Plugin::ConfigLoader>.
1050
1051 =head3 Cascading configuration
1052
1053 The config method is present on all Catalyst components, and configuration
1054 will be merged when an application is started. Configuration loaded with
1055 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
1056 followed by configuration in your top level C<MyApp> class. These two
1057 configurations are merged, and then configuration data whose hash key matches a
1058 component name is merged with configuration for that component.
1059
1060 The configuration for a component is then passed to the C<new> method when a
1061 component is constructed.
1062
1063 For example:
1064
1065     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
1066     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
1067
1068 will mean that C<MyApp::Model::Foo> receives the following data when
1069 constructed:
1070
1071     MyApp::Model::Foo->new({
1072         bar => 'baz',
1073         quux => 'frob',
1074         overrides => 'me',
1075     });
1076
1077 It's common practice to use a Moose attribute
1078 on the receiving component to access the config value.
1079
1080     package MyApp::Model::Foo;
1081
1082     use Moose;
1083
1084     # this attr will receive 'baz' at construction time
1085     has 'bar' => (
1086         is  => 'rw',
1087         isa => 'Str',
1088     );
1089
1090 You can then get the value 'baz' by calling $c->model('Foo')->bar
1091 (or $self->bar inside code in the model).
1092
1093 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1094 as a way of reading config within your code, as this B<will not> give you the
1095 correctly merged config back. You B<MUST> take the config values supplied to
1096 the constructor and use those instead.
1097
1098 =cut
1099
1100 around config => sub {
1101     my $orig = shift;
1102     my $c = shift;
1103
1104     croak('Setting config after setup has been run is not allowed.')
1105         if ( @_ and $c->setup_finished );
1106
1107     $c->$orig(@_);
1108 };
1109
1110 =head2 $c->log
1111
1112 Returns the logging object instance. Unless it is already set, Catalyst
1113 sets this up with a L<Catalyst::Log> object. To use your own log class,
1114 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1115 C<< __PACKAGE__->setup >>.
1116
1117  __PACKAGE__->log( MyLogger->new );
1118  __PACKAGE__->setup;
1119
1120 And later:
1121
1122     $c->log->info( 'Now logging with my own logger!' );
1123
1124 Your log class should implement the methods described in
1125 L<Catalyst::Log>.
1126
1127 =head2 has_encoding
1128
1129 Returned True if there's a valid encoding
1130
1131 =head2 clear_encoding
1132
1133 Clears the encoding for the current context
1134
1135 =head2 encoding
1136
1137 Sets or gets the application encoding.  Setting encoding takes either an
1138 Encoding object or a string that we try to resolve via L<Encode::find_encoding>.
1139
1140 You would expect to get the encoding object back if you attempt to set it.  If
1141 there is a failure you will get undef returned and an error message in the log.
1142
1143 =cut
1144
1145 sub has_encoding { shift->encoding ? 1:0 }
1146
1147 sub clear_encoding {
1148     my $c = shift;
1149     if(blessed $c) {
1150         $c->encoding(undef);
1151     } else {
1152         $c->log->error("You can't clear encoding on the application");
1153     }
1154 }
1155
1156 sub encoding {
1157     my $c = shift;
1158     my $encoding;
1159
1160     if ( scalar @_ ) {
1161
1162         # Don't let one change this once we are too far into the response
1163         if(blessed $c && $c->res->finalized_headers) {
1164           Carp::croak("You may not change the encoding once the headers are finalized");
1165           return;
1166         }
1167
1168         # Let it be set to undef
1169         if (my $wanted = shift)  {
1170             $encoding = Encode::find_encoding($wanted)
1171               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1172             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1173         }
1174         else {
1175             binmode(STDERR);
1176         }
1177
1178         $encoding = ref $c
1179                   ? $c->{encoding} = $encoding
1180                   : $c->_encoding($encoding);
1181     } else {
1182       $encoding = ref $c && exists $c->{encoding}
1183                 ? $c->{encoding}
1184                 : $c->_encoding;
1185     }
1186
1187     return $encoding;
1188 }
1189
1190 =head2 $c->debug
1191
1192 Returns 1 if debug mode is enabled, 0 otherwise.
1193
1194 You can enable debug mode in several ways:
1195
1196 =over
1197
1198 =item By calling myapp_server.pl with the -d flag
1199
1200 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1201
1202 =item The -Debug option in your MyApp.pm
1203
1204 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1205
1206 =back
1207
1208 The first three also set the log level to 'debug'.
1209
1210 Calling C<< $c->debug(1) >> has no effect.
1211
1212 =cut
1213
1214 sub debug { 0 }
1215
1216 =head2 $c->dispatcher
1217
1218 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1219
1220 =head2 $c->engine
1221
1222 Returns the engine instance. See L<Catalyst::Engine>.
1223
1224
1225 =head2 UTILITY METHODS
1226
1227 =head2 $c->path_to(@path)
1228
1229 Merges C<@path> with C<< $c->config->{home} >> and returns a
1230 L<Path::Class::Dir> object. Note you can usually use this object as
1231 a filename, but sometimes you will have to explicitly stringify it
1232 yourself by calling the C<< ->stringify >> method.
1233
1234 For example:
1235
1236     $c->path_to( 'db', 'sqlite.db' );
1237
1238 =cut
1239
1240 sub path_to {
1241     my ( $c, @path ) = @_;
1242     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1243     if ( -d $path ) { return $path }
1244     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1245 }
1246
1247 sub plugin {
1248     my ( $class, $name, $plugin, @args ) = @_;
1249
1250     # See block comment in t/unit_core_plugin.t
1251     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1252
1253     $class->_register_plugin( $plugin, 1 );
1254
1255     eval { $plugin->import };
1256     $class->mk_classdata($name);
1257     my $obj;
1258     eval { $obj = $plugin->new(@args) };
1259
1260     if ($@) {
1261         Catalyst::Exception->throw( message =>
1262               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1263     }
1264
1265     $class->$name($obj);
1266     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1267       if $class->debug;
1268 }
1269
1270 =head2 MyApp->setup
1271
1272 Initializes the dispatcher and engine, loads any plugins, and loads the
1273 model, view, and controller components. You may also specify an array
1274 of plugins to load here, if you choose to not load them in the C<use
1275 Catalyst> line.
1276
1277     MyApp->setup;
1278     MyApp->setup( qw/-Debug/ );
1279
1280 B<Note:> You B<should not> wrap this method with method modifiers
1281 or bad things will happen - wrap the C<setup_finalize> method instead.
1282
1283 B<Note:> You can create a custom setup stage that will execute when the
1284 application is starting.  Use this to customize setup.
1285
1286     MyApp->setup(-Custom=value);
1287
1288     sub setup_custom {
1289       my ($class, $value) = @_;
1290     }
1291
1292 Can be handy if you want to hook into the setup phase.
1293
1294 =cut
1295
1296 sub setup {
1297     my ( $class, @arguments ) = @_;
1298     croak('Running setup more than once')
1299         if ( $class->setup_finished );
1300
1301     unless ( $class->isa('Catalyst') ) {
1302
1303         Catalyst::Exception->throw(
1304             message => qq/'$class' does not inherit from Catalyst/ );
1305     }
1306
1307     if ( $class->arguments ) {
1308         @arguments = ( @arguments, @{ $class->arguments } );
1309     }
1310
1311     # Process options
1312     my $flags = {};
1313
1314     foreach (@arguments) {
1315
1316         if (/^-Debug$/) {
1317             $flags->{log} =
1318               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1319         }
1320         elsif (/^-(\w+)=?(.*)$/) {
1321             $flags->{ lc $1 } = $2;
1322         }
1323         else {
1324             push @{ $flags->{plugins} }, $_;
1325         }
1326     }
1327
1328     $class->setup_home( delete $flags->{home} );
1329
1330     $class->setup_log( delete $flags->{log} );
1331     $class->setup_plugins( delete $flags->{plugins} );
1332
1333     $class->setup_data_handlers();
1334     $class->setup_dispatcher( delete $flags->{dispatcher} );
1335     if (my $engine = delete $flags->{engine}) {
1336         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1337     }
1338     $class->setup_engine();
1339     $class->setup_stats( delete $flags->{stats} );
1340
1341     for my $flag ( sort keys %{$flags} ) {
1342
1343         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1344             &$code( $class, delete $flags->{$flag} );
1345         }
1346         else {
1347             $class->log->warn(qq/Unknown flag "$flag"/);
1348         }
1349     }
1350
1351     eval { require Catalyst::Devel; };
1352     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1353         $class->log->warn(<<"EOF");
1354 You are running an old script!
1355
1356   Please update by running (this will overwrite existing files):
1357     catalyst.pl -force -scripts $class
1358
1359   or (this will not overwrite existing files):
1360     catalyst.pl -scripts $class
1361
1362 EOF
1363     }
1364
1365     # Call plugins setup, this is stupid and evil.
1366     # Also screws C3 badly on 5.10, hack to avoid.
1367     {
1368         no warnings qw/redefine/;
1369         local *setup = sub { };
1370         $class->setup unless $Catalyst::__AM_RESTARTING;
1371     }
1372
1373     # If you are expecting configuration info as part of your setup, it needs
1374     # to get called here and below, since we need the above line to support
1375     # ConfigLoader based configs.
1376
1377     $class->setup_encoding();
1378     $class->setup_middleware();
1379
1380     # Initialize our data structure
1381     $class->components( {} );
1382
1383     $class->setup_components;
1384
1385     if ( $class->debug ) {
1386         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1387
1388         if (@plugins) {
1389             my $column_width = Catalyst::Utils::term_width() - 6;
1390             my $t = Text::SimpleTable->new($column_width);
1391             $t->row($_) for @plugins;
1392             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1393         }
1394
1395         my @middleware = map {
1396           ref $_ eq 'CODE' ?
1397             "Inline Coderef" :
1398               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1399                 || '')  } $class->registered_middlewares;
1400
1401         if (@middleware) {
1402             my $column_width = Catalyst::Utils::term_width() - 6;
1403             my $t = Text::SimpleTable->new($column_width);
1404             $t->row($_) for @middleware;
1405             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1406         }
1407
1408         my %dh = $class->registered_data_handlers;
1409         if (my @data_handlers = keys %dh) {
1410             my $column_width = Catalyst::Utils::term_width() - 6;
1411             my $t = Text::SimpleTable->new($column_width);
1412             $t->row($_) for @data_handlers;
1413             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1414         }
1415
1416         my $dispatcher = $class->dispatcher;
1417         my $engine     = $class->engine;
1418         my $home       = $class->config->{home};
1419
1420         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1421         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1422
1423         $home
1424           ? ( -d $home )
1425           ? $class->log->debug(qq/Found home "$home"/)
1426           : $class->log->debug(qq/Home "$home" doesn't exist/)
1427           : $class->log->debug(q/Couldn't find home/);
1428
1429         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1430
1431         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1432         for my $comp ( sort keys %{ $class->components } ) {
1433             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1434             $t->row( $comp, $type );
1435         }
1436         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1437           if ( keys %{ $class->components } );
1438     }
1439
1440     # Add our self to components, since we are also a component
1441     if( $class->isa('Catalyst::Controller') ){
1442       $class->components->{$class} = $class;
1443     }
1444
1445     $class->setup_actions;
1446
1447     if ( $class->debug ) {
1448         my $name = $class->config->{name} || 'Application';
1449         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1450     }
1451
1452     if ($class->config->{case_sensitive}) {
1453         $class->log->warn($class . "->config->{case_sensitive} is set.");
1454         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1455     }
1456
1457     $class->setup_finalize;
1458
1459     # Flush the log for good measure (in case something turned off 'autoflush' early)
1460     $class->log->_flush() if $class->log->can('_flush');
1461
1462     return $class || 1; # Just in case someone named their Application 0...
1463 }
1464
1465 =head2 $app->setup_finalize
1466
1467 A hook to attach modifiers to. This method does not do anything except set the
1468 C<setup_finished> accessor.
1469
1470 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1471
1472 Example:
1473
1474     after setup_finalize => sub {
1475         my $app = shift;
1476
1477         ## do stuff here..
1478     };
1479
1480 =cut
1481
1482 sub setup_finalize {
1483     my ($class) = @_;
1484     $class->setup_finished(1);
1485 }
1486
1487 =head2 $c->uri_for( $path?, @args?, \%query_values?, \$fragment? )
1488
1489 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values?, \$fragment? )
1490
1491 =head2 $c->uri_for( $action, [@captures, @args], \%query_values?, \$fragment? )
1492
1493 Constructs an absolute L<URI> object based on the application root, the
1494 provided path, and the additional arguments and query parameters provided.
1495 When used as a string, provides a textual URI.  If you need more flexibility
1496 than this (i.e. the option to provide relative URIs etc.) see
1497 L<Catalyst::Plugin::SmartURI>.
1498
1499 If no arguments are provided, the URI for the current action is returned.
1500 To return the current action and also provide @args, use
1501 C<< $c->uri_for( $c->action, @args ) >>.
1502
1503 If the first argument is a string, it is taken as a public URI path relative
1504 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1505 relative to the application root (if it does). It is then merged with
1506 C<< $c->request->base >>; any C<@args> are appended as additional path
1507 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1508
1509 B<NOTE> If you are using this 'stringy' first argument, we skip encoding and
1510 allow you to declare something like:
1511
1512     $c->uri_for('/foo/bar#baz')
1513
1514 Where 'baz' is a URI fragment.  We consider this first argument string to be
1515 'expert' mode where you are expected to create a valid URL and we for the most
1516 part just pass it through without a lot of internal effort to escape and encode.
1517
1518 If the first argument is a L<Catalyst::Action> it represents an action which
1519 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1520 optional C<\@captures> argument (an arrayref) allows passing the captured
1521 variables that are needed to fill in the paths of Chained and Regex actions;
1522 once the path is resolved, C<uri_for> continues as though a path was
1523 provided, appending any arguments or parameters and creating an absolute
1524 URI.
1525
1526 The captures for the current request can be found in
1527 C<< $c->request->captures >>, and actions can be resolved using
1528 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1529 path, use C<< $c->uri_for_action >> instead.
1530
1531   # Equivalent to $c->req->uri
1532   $c->uri_for($c->action, $c->req->captures,
1533       @{ $c->req->args }, $c->req->params);
1534
1535   # For the Foo action in the Bar controller
1536   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1537
1538   # Path to a static resource
1539   $c->uri_for('/static/images/logo.png');
1540
1541 In general the scheme of the generated URI object will follow the incoming request
1542 however if your targeted action or action chain has the Scheme attribute it will
1543 use that instead.
1544
1545 Also, if the targeted Action or Action chain declares Args/CaptureArgs that have
1546 type constraints, we will require that your proposed URL verify on those declared
1547 constraints.
1548
1549 =cut
1550
1551 sub uri_for {
1552     my ( $c, $path, @args ) = @_;
1553
1554     if ( $path->$_isa('Catalyst::Controller') ) {
1555         $path = $path->path_prefix;
1556         $path =~ s{/+\z}{};
1557         $path .= '/';
1558     }
1559
1560     my $fragment =  ((scalar(@args) && ref($args[-1]) eq 'SCALAR') ? pop @args : undef );
1561
1562     unless(blessed $path) {
1563       if ($path =~ s/#(.+)$//)  {
1564         if(defined($1) and $fragment) {
1565           carp "Abiguious fragment declaration: You cannot define a fragment in '$path' and as an argument '$fragment'";
1566         }
1567         if(defined($1)) {
1568           $fragment = $1;
1569         }
1570       }
1571     }
1572
1573     my $params =
1574       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1575
1576     undef($path) if (defined $path && $path eq '');
1577
1578     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1579
1580     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1581     if ( $path->$_isa('Catalyst::Action') ) { # action object
1582         s|/|%2F|g for @args;
1583         my $captures = [ map { s|/|%2F|g; $_; }
1584                         ( scalar @args && ref $args[0] eq 'ARRAY'
1585                          ? @{ shift(@args) }
1586                          : ()) ];
1587
1588         my $action = $path;
1589         my $expanded_action = $c->dispatcher->expand_action( $action );
1590         my $num_captures = $expanded_action->number_of_captures;
1591
1592         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1593         if( !@args && $action->number_of_args ) {
1594           unshift @args, splice @$captures, $num_captures;
1595         }
1596
1597         if($num_captures) {
1598           unless($expanded_action->match_captures_constraints($c, $captures)) {
1599             carp "captures [@{$captures}] do not match the type constraints in actionchain ending with '$expanded_action'";
1600             return;
1601           }
1602         }
1603
1604         $path = $c->dispatcher->uri_for_action($action, $captures);
1605         if (not defined $path) {
1606             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1607                 if $c->debug;
1608             return undef;
1609         }
1610         $path = '/' if $path eq '';
1611
1612         # At this point @encoded_args is the remaining Args (all captures removed).
1613         if($expanded_action->has_args_constraints) {
1614           unless($expanded_action->match_args($c,\@args)) {
1615              carp "args [@args] do not match the type constraints in action '$expanded_action'";
1616              return;
1617           }
1618         }
1619     }
1620
1621     unshift(@args, $path);
1622
1623     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1624         my $namespace = $c->namespace;
1625         if (defined $path) { # cheesy hack to handle path '../foo'
1626            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1627         }
1628         unshift(@args, $namespace || '');
1629     }
1630
1631     # join args with '/', or a blank string
1632     my $args = join('/', grep { defined($_) } @args);
1633     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1634     $args =~ s!^/+!!;
1635
1636     my ($base, $class) = ('/', 'URI::_generic');
1637     if(blessed($c)) {
1638       $base = $c->req->base;
1639       if($target_action) {
1640         $target_action = $c->dispatcher->expand_action($target_action);
1641         if(my $s = $target_action->scheme) {
1642           $s = lc($s);
1643           $class = "URI::$s";
1644           $base->scheme($s);
1645         } else {
1646           $class = ref($base);
1647         }
1648       } else {
1649         $class = ref($base);
1650       }
1651
1652       $base =~ s{(?<!/)$}{/};
1653     }
1654
1655     my $query = '';
1656     if (my @keys = keys %$params) {
1657       # somewhat lifted from URI::_query's query_form
1658       $query = '?'.join('&', map {
1659           my $val = $params->{$_};
1660           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1661           s/ /+/g;
1662           my $key = $_;
1663           $val = '' unless defined $val;
1664           (map {
1665               my $param = "$_";
1666               $param = encode_utf8($param);
1667               # using the URI::Escape pattern here so utf8 chars survive
1668               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1669               $param =~ s/ /+/g;
1670
1671               $key = encode_utf8($key);
1672               # using the URI::Escape pattern here so utf8 chars survive
1673               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1674               $key =~ s/ /+/g;
1675
1676               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1677       } @keys);
1678     }
1679
1680     $base = encode_utf8 $base;
1681     $base =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1682     $args = encode_utf8 $args;
1683     $args =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1684
1685     if(defined $fragment) {
1686       if(blessed $path) {
1687         $fragment = encode_utf8(${$fragment});
1688         $fragment =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1689         $fragment =~ s/ /+/g;
1690       }
1691       $query .= "#$fragment";
1692     }
1693
1694     my $res = bless(\"${base}${args}${query}", $class);
1695     $res;
1696 }
1697
1698 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1699
1700 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1701
1702 =over
1703
1704 =item $path
1705
1706 A private path to the Catalyst action you want to create a URI for.
1707
1708 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1709 >> and passing the resulting C<$action> and the remaining arguments to C<<
1710 $c->uri_for >>.
1711
1712 You can also pass in a Catalyst::Action object, in which case it is passed to
1713 C<< $c->uri_for >>.
1714
1715 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1716
1717 For example, if the action looks like:
1718
1719  package MyApp::Controller::Users;
1720
1721  sub lst : Path('the-list') {}
1722
1723 You can use:
1724
1725  $c->uri_for_action('/users/lst')
1726
1727 and it will create the URI /users/the-list.
1728
1729 =item \@captures_and_args?
1730
1731 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1732 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1733 to interpolate all the parameters in the URI.
1734
1735 =item @args?
1736
1737 Optional list of extra arguments - can be supplied in the
1738 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1739 code.
1740
1741 Your action can have zero, a fixed or a variable number of args (e.g.
1742 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1743
1744 =item \%query_values?
1745
1746 Optional array reference of query parameters to append. E.g.
1747
1748   { foo => 'bar' }
1749
1750 will generate
1751
1752   /rest/of/your/uri?foo=bar
1753
1754 =back
1755
1756 =cut
1757
1758 sub uri_for_action {
1759     my ( $c, $path, @args ) = @_;
1760     my $action = blessed($path)
1761       ? $path
1762       : $c->dispatcher->get_action_by_path($path);
1763     unless (defined $action) {
1764       croak "Can't find action for path '$path'";
1765     }
1766     return $c->uri_for( $action, @args );
1767 }
1768
1769 =head2 $c->welcome_message
1770
1771 Returns the Catalyst welcome HTML page.
1772
1773 =cut
1774
1775 sub welcome_message {
1776     my $c      = shift;
1777     my $name   = $c->config->{name};
1778     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1779     my $prefix = Catalyst::Utils::appprefix( ref $c );
1780     $c->response->content_type('text/html; charset=utf-8');
1781     return <<"EOF";
1782 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1783     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1784 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1785     <head>
1786     <meta http-equiv="Content-Language" content="en" />
1787     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1788         <title>$name on Catalyst $VERSION</title>
1789         <style type="text/css">
1790             body {
1791                 color: #000;
1792                 background-color: #eee;
1793             }
1794             div#content {
1795                 width: 640px;
1796                 margin-left: auto;
1797                 margin-right: auto;
1798                 margin-top: 10px;
1799                 margin-bottom: 10px;
1800                 text-align: left;
1801                 background-color: #ccc;
1802                 border: 1px solid #aaa;
1803             }
1804             p, h1, h2 {
1805                 margin-left: 20px;
1806                 margin-right: 20px;
1807                 font-family: verdana, tahoma, sans-serif;
1808             }
1809             a {
1810                 font-family: verdana, tahoma, sans-serif;
1811             }
1812             :link, :visited {
1813                     text-decoration: none;
1814                     color: #b00;
1815                     border-bottom: 1px dotted #bbb;
1816             }
1817             :link:hover, :visited:hover {
1818                     color: #555;
1819             }
1820             div#topbar {
1821                 margin: 0px;
1822             }
1823             pre {
1824                 margin: 10px;
1825                 padding: 8px;
1826             }
1827             div#answers {
1828                 padding: 8px;
1829                 margin: 10px;
1830                 background-color: #fff;
1831                 border: 1px solid #aaa;
1832             }
1833             h1 {
1834                 font-size: 0.9em;
1835                 font-weight: normal;
1836                 text-align: center;
1837             }
1838             h2 {
1839                 font-size: 1.0em;
1840             }
1841             p {
1842                 font-size: 0.9em;
1843             }
1844             p img {
1845                 float: right;
1846                 margin-left: 10px;
1847             }
1848             span#appname {
1849                 font-weight: bold;
1850                 font-size: 1.6em;
1851             }
1852         </style>
1853     </head>
1854     <body>
1855         <div id="content">
1856             <div id="topbar">
1857                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1858                     $VERSION</h1>
1859              </div>
1860              <div id="answers">
1861                  <p>
1862                  <img src="$logo" alt="Catalyst Logo" />
1863                  </p>
1864                  <p>Welcome to the  world of Catalyst.
1865                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1866                     framework will make web development something you had
1867                     never expected it to be: Fun, rewarding, and quick.</p>
1868                  <h2>What to do now?</h2>
1869                  <p>That really depends  on what <b>you</b> want to do.
1870                     We do, however, provide you with a few starting points.</p>
1871                  <p>If you want to jump right into web development with Catalyst
1872                     you might want to start with a tutorial.</p>
1873 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1874 </pre>
1875 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1876 <pre>
1877 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1878 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1879 </code></pre>
1880                  <h2>What to do next?</h2>
1881                  <p>Next it's time to write an actual application. Use the
1882                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1883                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1884                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1885                     they can save you a lot of work.</p>
1886                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1887                     <p>Also, be sure to check out the vast and growing
1888                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1889                     you are likely to find what you need there.
1890                     </p>
1891
1892                  <h2>Need help?</h2>
1893                  <p>Catalyst has a very active community. Here are the main places to
1894                     get in touch with us.</p>
1895                  <ul>
1896                      <li>
1897                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1898                      </li>
1899                      <li>
1900                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1901                      </li>
1902                      <li>
1903                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1904                      </li>
1905                  </ul>
1906                  <h2>In conclusion</h2>
1907                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1908                     as we enjoyed making it. Please contact us if you have ideas
1909                     for improvement or other feedback.</p>
1910              </div>
1911          </div>
1912     </body>
1913 </html>
1914 EOF
1915 }
1916
1917 =head2 run_options
1918
1919 Contains a hash of options passed from the application script, including
1920 the original ARGV the script received, the processed values from that
1921 ARGV and any extra arguments to the script which were not processed.
1922
1923 This can be used to add custom options to your application's scripts
1924 and setup your application differently depending on the values of these
1925 options.
1926
1927 =head1 INTERNAL METHODS
1928
1929 These methods are not meant to be used by end users.
1930
1931 =head2 $c->components
1932
1933 Returns a hash of components.
1934
1935 =head2 $c->context_class
1936
1937 Returns or sets the context class.
1938
1939 =head2 $c->counter
1940
1941 Returns a hashref containing coderefs and execution counts (needed for
1942 deep recursion detection).
1943
1944 =head2 $c->depth
1945
1946 Returns the number of actions on the current internal execution stack.
1947
1948 =head2 $c->dispatch
1949
1950 Dispatches a request to actions.
1951
1952 =cut
1953
1954 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1955
1956 =head2 $c->dispatcher_class
1957
1958 Returns or sets the dispatcher class.
1959
1960 =head2 $c->dump_these
1961
1962 Returns a list of 2-element array references (name, structure) pairs
1963 that will be dumped on the error page in debug mode.
1964
1965 =cut
1966
1967 sub dump_these {
1968     my $c = shift;
1969     [ Request => $c->req ],
1970     [ Response => $c->res ],
1971     [ Stash => $c->stash ],
1972     [ Config => $c->config ];
1973 }
1974
1975 =head2 $c->engine_class
1976
1977 Returns or sets the engine class.
1978
1979 =head2 $c->execute( $class, $coderef )
1980
1981 Execute a coderef in given class and catch exceptions. Errors are available
1982 via $c->error.
1983
1984 =cut
1985
1986 sub execute {
1987     my ( $c, $class, $code ) = @_;
1988     $class = $c->component($class) || $class;
1989     $c->state(0);
1990
1991     if ( $c->depth >= $RECURSION ) {
1992         my $action = $code->reverse();
1993         $action = "/$action" unless $action =~ /->/;
1994         my $error = qq/Deep recursion detected calling "${action}"/;
1995         $c->log->error($error);
1996         $c->error($error);
1997         $c->state(0);
1998         return $c->state;
1999     }
2000
2001     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
2002
2003     push( @{ $c->stack }, $code );
2004
2005     no warnings 'recursion';
2006     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
2007     #      I have no idea how, ergo $ret (which appears to fix the issue)
2008     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
2009
2010     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
2011
2012     my $last = pop( @{ $c->stack } );
2013
2014     if ( my $error = $@ ) {
2015         #rethow if this can be handled by middleware
2016         if ( $c->_handle_http_exception($error) ) {
2017             foreach my $err (@{$c->error}) {
2018                 $c->log->error($err);
2019             }
2020             $c->clear_errors;
2021             $c->log->_flush if $c->log->can('_flush');
2022
2023             $error->can('rethrow') ? $error->rethrow : croak $error;
2024         }
2025         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
2026             $error->rethrow if $c->depth > 1;
2027         }
2028         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
2029             $error->rethrow if $c->depth > 0;
2030         }
2031         else {
2032             unless ( ref $error ) {
2033                 no warnings 'uninitialized';
2034                 chomp $error;
2035                 my $class = $last->class;
2036                 my $name  = $last->name;
2037                 $error = qq/Caught exception in $class->$name "$error"/;
2038             }
2039             $c->error($error);
2040         }
2041         $c->state(0);
2042     }
2043     return $c->state;
2044 }
2045
2046 sub _stats_start_execute {
2047     my ( $c, $code ) = @_;
2048     my $appclass = ref($c) || $c;
2049     return if ( ( $code->name =~ /^_.*/ )
2050         && ( !$appclass->config->{show_internal_actions} ) );
2051
2052     my $action_name = $code->reverse();
2053     $c->counter->{$action_name}++;
2054
2055     my $action = $action_name;
2056     $action = "/$action" unless $action =~ /->/;
2057
2058     # determine if the call was the result of a forward
2059     # this is done by walking up the call stack and looking for a calling
2060     # sub of Catalyst::forward before the eval
2061     my $callsub = q{};
2062     for my $index ( 2 .. 11 ) {
2063         last
2064         if ( ( caller($index) )[0] eq 'Catalyst'
2065             && ( caller($index) )[3] eq '(eval)' );
2066
2067         if ( ( caller($index) )[3] =~ /forward$/ ) {
2068             $callsub = ( caller($index) )[3];
2069             $action  = "-> $action";
2070             last;
2071         }
2072     }
2073
2074     my $uid = $action_name . $c->counter->{$action_name};
2075
2076     # is this a root-level call or a forwarded call?
2077     if ( $callsub =~ /forward$/ ) {
2078         my $parent = $c->stack->[-1];
2079
2080         # forward, locate the caller
2081         if ( defined $parent && exists $c->counter->{"$parent"} ) {
2082             $c->stats->profile(
2083                 begin  => $action,
2084                 parent => "$parent" . $c->counter->{"$parent"},
2085                 uid    => $uid,
2086             );
2087         }
2088         else {
2089
2090             # forward with no caller may come from a plugin
2091             $c->stats->profile(
2092                 begin => $action,
2093                 uid   => $uid,
2094             );
2095         }
2096     }
2097     else {
2098
2099         # root-level call
2100         $c->stats->profile(
2101             begin => $action,
2102             uid   => $uid,
2103         );
2104     }
2105     return $action;
2106
2107 }
2108
2109 sub _stats_finish_execute {
2110     my ( $c, $info ) = @_;
2111     $c->stats->profile( end => $info );
2112 }
2113
2114 =head2 $c->finalize
2115
2116 Finalizes the request.
2117
2118 =cut
2119
2120 sub finalize {
2121     my $c = shift;
2122
2123     for my $error ( @{ $c->error } ) {
2124         $c->log->error($error);
2125     }
2126
2127     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
2128     # stuff like cometd and websockets
2129
2130     if($c->request->_has_io_fh) {
2131       $c->log_response;
2132       return;
2133     }
2134
2135     # Allow engine to handle finalize flow (for POE)
2136     my $engine = $c->engine;
2137     if ( my $code = $engine->can('finalize') ) {
2138         $engine->$code($c);
2139     }
2140     else {
2141
2142         $c->finalize_uploads;
2143
2144         # Error
2145         if ( $#{ $c->error } >= 0 ) {
2146             $c->finalize_error;
2147         }
2148
2149         $c->finalize_encoding;
2150         $c->finalize_headers unless $c->response->finalized_headers;
2151         $c->finalize_body;
2152     }
2153
2154     $c->log_response;
2155
2156     if ($c->use_stats) {
2157         my $elapsed = $c->stats->elapsed;
2158         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2159         $c->log->info(
2160             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2161     }
2162
2163     return $c->response->status;
2164 }
2165
2166 =head2 $c->finalize_body
2167
2168 Finalizes body.
2169
2170 =cut
2171
2172 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2173
2174 =head2 $c->finalize_cookies
2175
2176 Finalizes cookies.
2177
2178 =cut
2179
2180 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2181
2182 =head2 $c->finalize_error
2183
2184 Finalizes error.  If there is only one error in L</error> and it is an object that
2185 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2186 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2187 return the default error page (production mode).
2188
2189 =cut
2190
2191 sub finalize_error {
2192     my $c = shift;
2193     if($#{$c->error} > 0) {
2194         $c->engine->finalize_error( $c, @_ );
2195     } else {
2196         my ($error) = @{$c->error};
2197         if ( $c->_handle_http_exception($error) ) {
2198             # In the case where the error 'knows what it wants', becauses its PSGI
2199             # aware, just rethow and let middleware catch it
2200             $error->can('rethrow') ? $error->rethrow : croak $error;
2201         } else {
2202             $c->engine->finalize_error( $c, @_ )
2203         }
2204     }
2205 }
2206
2207 =head2 $c->finalize_headers
2208
2209 Finalizes headers.
2210
2211 =cut
2212
2213 sub finalize_headers {
2214     my $c = shift;
2215
2216     my $response = $c->response; #accessor calls can add up?
2217
2218     # Check if we already finalized headers
2219     return if $response->finalized_headers;
2220
2221     # Handle redirects
2222     if ( my $location = $response->redirect ) {
2223         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2224         $response->header( Location => $location );
2225     }
2226
2227     # Remove incorrectly added body and content related meta data when returning
2228     # an information response, or a response the is required to not include a body
2229
2230     $c->finalize_cookies;
2231
2232     # This currently is a NOOP but I don't want to remove it since I guess people
2233     # might have Response subclasses that use it for something... (JNAP)
2234     $c->response->finalize_headers();
2235
2236     # Done
2237     $response->finalized_headers(1);
2238 }
2239
2240 =head2 $c->finalize_encoding
2241
2242 Make sure your body is encoded properly IF you set an encoding.  By
2243 default the encoding is UTF-8 but you can disable it by explicitly setting the
2244 encoding configuration value to undef.
2245
2246 We can only encode when the body is a scalar.  Methods for encoding via the
2247 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2248 are available).
2249
2250 See L</ENCODING>.
2251
2252 =cut
2253
2254 sub finalize_encoding {
2255     my $c = shift;
2256     my $res = $c->res || return;
2257
2258     # Warn if the set charset is different from the one you put into encoding.  We need
2259     # to do this early since encodable_response is false for this condition and we need
2260     # to match the debug output for backcompat (there's a test for this...) -JNAP
2261     if(
2262       $res->content_type_charset and $c->encoding and
2263       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2264     ) {
2265         my $ct = lc($res->content_type_charset);
2266         $c->log->debug("Catalyst encoding config is set to encode in '" .
2267             $c->encoding->mime_name .
2268             "', content type is '$ct', not encoding ");
2269     }
2270
2271     if(
2272       ($res->encodable_response) and
2273       (defined($res->body)) and
2274       (ref(\$res->body) eq 'SCALAR')
2275     ) {
2276         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2277
2278         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2279         # is false when the set charset is not the same as the encoding mimetype (maybe
2280         # confusing action at a distance here..
2281         # Don't try to set the charset if one already exists or if headers are already finalized
2282         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2283           unless($c->res->content_type_charset ||
2284                 ($c->res->_context && $c->res->finalized_headers && !$c->res->_has_response_cb));
2285     }
2286 }
2287
2288 =head2 $c->finalize_output
2289
2290 An alias for finalize_body.
2291
2292 =head2 $c->finalize_read
2293
2294 Finalizes the input after reading is complete.
2295
2296 =cut
2297
2298 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2299
2300 =head2 $c->finalize_uploads
2301
2302 Finalizes uploads. Cleans up any temporary files.
2303
2304 =cut
2305
2306 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2307
2308 =head2 $c->get_action( $action, $namespace )
2309
2310 Gets an action in a given namespace.
2311
2312 =cut
2313
2314 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2315
2316 =head2 $c->get_actions( $action, $namespace )
2317
2318 Gets all actions of a given name in a namespace and all parent
2319 namespaces.
2320
2321 =cut
2322
2323 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2324
2325 =head2 $app->handle_request( @arguments )
2326
2327 Called to handle each HTTP request.
2328
2329 =cut
2330
2331 sub handle_request {
2332     my ( $class, @arguments ) = @_;
2333
2334     # Always expect worst case!
2335     my $status = -1;
2336     try {
2337         if ($class->debug) {
2338             my $secs = time - $START || 1;
2339             my $av = sprintf '%.3f', $COUNT / $secs;
2340             my $time = localtime time;
2341             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2342         }
2343
2344         my $c = $class->prepare(@arguments);
2345         $c->dispatch;
2346         $status = $c->finalize;
2347     } catch {
2348         #rethow if this can be handled by middleware
2349         if ( $class->_handle_http_exception($_) ) {
2350             $_->can('rethrow') ? $_->rethrow : croak $_;
2351         }
2352         chomp(my $error = $_);
2353         $class->log->error(qq/Caught exception in engine "$error"/);
2354     };
2355
2356     $COUNT++;
2357
2358     if(my $coderef = $class->log->can('_flush')){
2359         $class->log->$coderef();
2360     }
2361     return $status;
2362 }
2363
2364 =head2 $class->prepare( @arguments )
2365
2366 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2367 etc.).
2368
2369 =cut
2370
2371 has _uploadtmp => (
2372     is => 'ro',
2373     predicate => '_has_uploadtmp',
2374 );
2375
2376 sub prepare {
2377     my ( $class, @arguments ) = @_;
2378
2379     # XXX
2380     # After the app/ctxt split, this should become an attribute based on something passed
2381     # into the application.
2382     $class->context_class( ref $class || $class ) unless $class->context_class;
2383
2384     my $uploadtmp = $class->config->{uploadtmp};
2385     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2386
2387     $c->response->_context($c);
2388
2389     $c->stats($class->stats_class->new)->enable($c->use_stats);
2390
2391     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2392         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2393     }
2394
2395     try {
2396         # Allow engine to direct the prepare flow (for POE)
2397         if ( my $prepare = $c->engine->can('prepare') ) {
2398             $c->engine->$prepare( $c, @arguments );
2399         }
2400         else {
2401             $c->prepare_request(@arguments);
2402             $c->prepare_connection;
2403             $c->prepare_query_parameters;
2404             $c->prepare_headers; # Just hooks, no longer needed - they just
2405             $c->prepare_cookies; # cause the lazy attribute on req to build
2406             $c->prepare_path;
2407
2408             # Prepare the body for reading, either by prepare_body
2409             # or the user, if they are using $c->read
2410             $c->prepare_read;
2411
2412             # Parse the body unless the user wants it on-demand
2413             unless ( ref($c)->config->{parse_on_demand} ) {
2414                 $c->prepare_body;
2415             }
2416         }
2417         $c->prepare_action;
2418     }
2419     # VERY ugly and probably shouldn't rely on ->finalize actually working
2420     catch {
2421         # failed prepare is always due to an invalid request, right?
2422         $c->response->status(400);
2423         $c->response->content_type('text/plain');
2424         $c->response->body('Bad Request');
2425         # Note we call finalize and then die here, which escapes
2426         # finalize being called in the enclosing block..
2427         # It in fact couldn't be called, as we don't return $c..
2428         # This is a mess - but I'm unsure you can fix this without
2429         # breaking compat for people doing crazy things (we should set
2430         # the 400 and just return the ctx here IMO, letting finalize get called
2431         # above...
2432         $c->finalize;
2433         die $_;
2434     };
2435
2436     $c->log_request;
2437
2438     return $c;
2439 }
2440
2441 =head2 $c->prepare_action
2442
2443 Prepares action. See L<Catalyst::Dispatcher>.
2444
2445 =cut
2446
2447 sub prepare_action {
2448     my $c = shift;
2449     my $ret = $c->dispatcher->prepare_action( $c, @_);
2450
2451     if($c->encoding) {
2452         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2453           $_ = $c->_handle_param_unicode_decoding($_);
2454         }
2455     }
2456
2457     return $ret;
2458 }
2459
2460
2461 =head2 $c->prepare_body
2462
2463 Prepares message body.
2464
2465 =cut
2466
2467 sub prepare_body {
2468     my $c = shift;
2469
2470     return if $c->request->_has_body;
2471
2472     # Initialize on-demand data
2473     $c->engine->prepare_body( $c, @_ );
2474     $c->prepare_parameters;
2475     $c->prepare_uploads;
2476 }
2477
2478 =head2 $c->prepare_body_chunk( $chunk )
2479
2480 Prepares a chunk of data before sending it to L<HTTP::Body>.
2481
2482 See L<Catalyst::Engine>.
2483
2484 =cut
2485
2486 sub prepare_body_chunk {
2487     my $c = shift;
2488     $c->engine->prepare_body_chunk( $c, @_ );
2489 }
2490
2491 =head2 $c->prepare_body_parameters
2492
2493 Prepares body parameters.
2494
2495 =cut
2496
2497 sub prepare_body_parameters {
2498     my $c = shift;
2499     $c->request->prepare_body_parameters( $c, @_ );
2500 }
2501
2502 =head2 $c->prepare_connection
2503
2504 Prepares connection.
2505
2506 =cut
2507
2508 sub prepare_connection {
2509     my $c = shift;
2510     $c->request->prepare_connection($c);
2511 }
2512
2513 =head2 $c->prepare_cookies
2514
2515 Prepares cookies by ensuring that the attribute on the request
2516 object has been built.
2517
2518 =cut
2519
2520 sub prepare_cookies { my $c = shift; $c->request->cookies }
2521
2522 =head2 $c->prepare_headers
2523
2524 Prepares request headers by ensuring that the attribute on the request
2525 object has been built.
2526
2527 =cut
2528
2529 sub prepare_headers { my $c = shift; $c->request->headers }
2530
2531 =head2 $c->prepare_parameters
2532
2533 Prepares parameters.
2534
2535 =cut
2536
2537 sub prepare_parameters {
2538     my $c = shift;
2539     $c->prepare_body_parameters;
2540     $c->engine->prepare_parameters( $c, @_ );
2541 }
2542
2543 =head2 $c->prepare_path
2544
2545 Prepares path and base.
2546
2547 =cut
2548
2549 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2550
2551 =head2 $c->prepare_query_parameters
2552
2553 Prepares query parameters.
2554
2555 =cut
2556
2557 sub prepare_query_parameters {
2558     my $c = shift;
2559
2560     $c->engine->prepare_query_parameters( $c, @_ );
2561 }
2562
2563 =head2 $c->log_request
2564
2565 Writes information about the request to the debug logs.  This includes:
2566
2567 =over 4
2568
2569 =item * Request method, path, and remote IP address
2570
2571 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2572
2573 =item * Request parameters
2574
2575 =item * File uploads
2576
2577 =back
2578
2579 =cut
2580
2581 sub log_request {
2582     my $c = shift;
2583
2584     return unless $c->debug;
2585
2586     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2587     my $request = $dump->[1];
2588
2589     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2590     $method ||= '';
2591     $path = '/' unless length $path;
2592     $address ||= '';
2593
2594     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2595     $path = decode_utf8($path);
2596
2597     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2598
2599     $c->log_request_headers($request->headers);
2600
2601     if ( my $keywords = $request->query_keywords ) {
2602         $c->log->debug("Query keywords are: $keywords");
2603     }
2604
2605     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2606
2607     $c->log_request_uploads($request);
2608 }
2609
2610 =head2 $c->log_response
2611
2612 Writes information about the response to the debug logs by calling
2613 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2614
2615 =cut
2616
2617 sub log_response {
2618     my $c = shift;
2619
2620     return unless $c->debug;
2621
2622     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2623     my $response = $dump->[1];
2624
2625     $c->log_response_status_line($response);
2626     $c->log_response_headers($response->headers);
2627 }
2628
2629 =head2 $c->log_response_status_line($response)
2630
2631 Writes one line of information about the response to the debug logs.  This includes:
2632
2633 =over 4
2634
2635 =item * Response status code
2636
2637 =item * Content-Type header (if present)
2638
2639 =item * Content-Length header (if present)
2640
2641 =back
2642
2643 =cut
2644
2645 sub log_response_status_line {
2646     my ($c, $response) = @_;
2647
2648     $c->log->debug(
2649         sprintf(
2650             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2651             $response->status                            || 'unknown',
2652             $response->headers->header('Content-Type')   || 'unknown',
2653             $response->headers->header('Content-Length') || 'unknown'
2654         )
2655     );
2656 }
2657
2658 =head2 $c->log_response_headers($headers);
2659
2660 Hook method which can be wrapped by plugins to log the response headers.
2661 No-op in the default implementation.
2662
2663 =cut
2664
2665 sub log_response_headers {}
2666
2667 =head2 $c->log_request_parameters( query => {}, body => {} )
2668
2669 Logs request parameters to debug logs
2670
2671 =cut
2672
2673 sub log_request_parameters {
2674     my $c          = shift;
2675     my %all_params = @_;
2676
2677     return unless $c->debug;
2678
2679     my $column_width = Catalyst::Utils::term_width() - 44;
2680     foreach my $type (qw(query body)) {
2681         my $params = $all_params{$type};
2682         next if ! keys %$params;
2683         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2684         for my $key ( sort keys %$params ) {
2685             my $param = $params->{$key};
2686             my $value = defined($param) ? $param : '';
2687             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2688         }
2689         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2690     }
2691 }
2692
2693 =head2 $c->log_request_uploads
2694
2695 Logs file uploads included in the request to the debug logs.
2696 The parameter name, filename, file type, and file size are all included in
2697 the debug logs.
2698
2699 =cut
2700
2701 sub log_request_uploads {
2702     my $c = shift;
2703     my $request = shift;
2704     return unless $c->debug;
2705     my $uploads = $request->uploads;
2706     if ( keys %$uploads ) {
2707         my $t = Text::SimpleTable->new(
2708             [ 12, 'Parameter' ],
2709             [ 26, 'Filename' ],
2710             [ 18, 'Type' ],
2711             [ 9,  'Size' ]
2712         );
2713         for my $key ( sort keys %$uploads ) {
2714             my $upload = $uploads->{$key};
2715             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2716                 $t->row( $key, $u->filename, $u->type, $u->size );
2717             }
2718         }
2719         $c->log->debug( "File Uploads are:\n" . $t->draw );
2720     }
2721 }
2722
2723 =head2 $c->log_request_headers($headers);
2724
2725 Hook method which can be wrapped by plugins to log the request headers.
2726 No-op in the default implementation.
2727
2728 =cut
2729
2730 sub log_request_headers {}
2731
2732 =head2 $c->log_headers($type => $headers)
2733
2734 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2735
2736 =cut
2737
2738 sub log_headers {
2739     my $c       = shift;
2740     my $type    = shift;
2741     my $headers = shift;    # an HTTP::Headers instance
2742
2743     return unless $c->debug;
2744
2745     my $column_width = Catalyst::Utils::term_width() - 28;
2746     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2747     $headers->scan(
2748         sub {
2749             my ( $name, $value ) = @_;
2750             $t->row( $name, $value );
2751         }
2752     );
2753     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2754 }
2755
2756
2757 =head2 $c->prepare_read
2758
2759 Prepares the input for reading.
2760
2761 =cut
2762
2763 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2764
2765 =head2 $c->prepare_request
2766
2767 Prepares the engine request.
2768
2769 =cut
2770
2771 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2772
2773 =head2 $c->prepare_uploads
2774
2775 Prepares uploads.
2776
2777 =cut
2778
2779 sub prepare_uploads {
2780     my $c = shift;
2781     $c->engine->prepare_uploads( $c, @_ );
2782 }
2783
2784 =head2 $c->prepare_write
2785
2786 Prepares the output for writing.
2787
2788 =cut
2789
2790 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2791
2792 =head2 $c->request_class
2793
2794 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2795
2796 =head2 $app->request_class_traits
2797
2798 An arrayref of L<Moose::Role>s which are applied to the request class.  You can
2799 name the full namespace of the role, or a namespace suffix, which will then
2800 be tried against the following standard namespace prefixes.
2801
2802     $MyApp::TraitFor::Request::$trait_suffix
2803     Catalyst::TraitFor::Request::$trait_suffix
2804
2805 So for example if you set:
2806
2807     MyApp->request_class_traits(['Foo']);
2808
2809 We try each possible role in turn (and throw an error if none load)
2810
2811     Foo
2812     MyApp::TraitFor::Request::Foo
2813     Catalyst::TraitFor::Request::Foo
2814
2815 The namespace part 'TraitFor::Request' was chosen to assist in backwards
2816 compatibility with L<CatalystX::RoleApplicator> which previously provided
2817 these features in a stand alone package.
2818
2819 =head2 $app->composed_request_class
2820
2821 This is the request class which has been composed with any request_class_traits.
2822
2823 =head2 $c->response_class
2824
2825 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2826
2827 =head2 $app->response_class_traits
2828
2829 An arrayref of L<Moose::Role>s which are applied to the response class.  You can
2830 name the full namespace of the role, or a namespace suffix, which will then
2831 be tried against the following standard namespace prefixes.
2832
2833     $MyApp::TraitFor::Response::$trait_suffix
2834     Catalyst::TraitFor::Response::$trait_suffix
2835
2836 So for example if you set:
2837
2838     MyApp->response_class_traits(['Foo']);
2839
2840 We try each possible role in turn (and throw an error if none load)
2841
2842     Foo
2843     MyApp::TraitFor::Response::Foo
2844     Catalyst::TraitFor::Responset::Foo
2845
2846 The namespace part 'TraitFor::Response' was chosen to assist in backwards
2847 compatibility with L<CatalystX::RoleApplicator> which previously provided
2848 these features in a stand alone package.
2849
2850
2851 =head2 $app->composed_response_class
2852
2853 This is the request class which has been composed with any response_class_traits.
2854
2855 =head2 $c->read( [$maxlength] )
2856
2857 Reads a chunk of data from the request body. This method is designed to
2858 be used in a while loop, reading C<$maxlength> bytes on every call.
2859 C<$maxlength> defaults to the size of the request if not specified.
2860
2861 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2862 directly.
2863
2864 Warning: If you use read(), Catalyst will not process the body,
2865 so you will not be able to access POST parameters or file uploads via
2866 $c->request.  You must handle all body parsing yourself.
2867
2868 =cut
2869
2870 sub read { my $c = shift; return $c->request->read( @_ ) }
2871
2872 =head2 $c->run
2873
2874 Starts the engine.
2875
2876 =cut
2877
2878 sub run {
2879   my $app = shift;
2880   $app->_make_immutable_if_needed;
2881   $app->engine_loader->needs_psgi_engine_compat_hack ?
2882     $app->engine->run($app, @_) :
2883       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2884 }
2885
2886 sub _make_immutable_if_needed {
2887     my $class = shift;
2888     my $meta = find_meta($class);
2889     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2890     if (
2891         $meta->is_immutable
2892         && ! { $meta->immutable_options }->{replace_constructor}
2893         && $isa_ca
2894     ) {
2895         warn("You made your application class ($class) immutable, "
2896             . "but did not inline the\nconstructor. "
2897             . "This will break catalyst, as your app \@ISA "
2898             . "Class::Accessor(::Fast)?\nPlease pass "
2899             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2900     }
2901     unless ($meta->is_immutable) {
2902         # XXX - FIXME warning here as you should make your app immutable yourself.
2903         $meta->make_immutable(
2904             replace_constructor => 1,
2905         );
2906     }
2907 }
2908
2909 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2910
2911 Sets an action in a given namespace.
2912
2913 =cut
2914
2915 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2916
2917 =head2 $c->setup_actions($component)
2918
2919 Sets up actions for a component.
2920
2921 =cut
2922
2923 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2924
2925 =head2 $c->setup_components
2926
2927 This method is called internally to set up the application's components.
2928
2929 It finds modules by calling the L<locate_components> method, expands them to
2930 package names with the L<expand_component_module> method, and then installs
2931 each component into the application.
2932
2933 The C<setup_components> config option is passed to both of the above methods.
2934
2935 Installation of each component is performed by the L<setup_component> method,
2936 below.
2937
2938 =cut
2939
2940 sub setup_components {
2941     my $class = shift;
2942
2943     my $config  = $class->config->{ setup_components };
2944
2945     my @comps = $class->locate_components($config);
2946     my %comps = map { $_ => 1 } @comps;
2947
2948     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2949     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2950         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2951     ) if $deprecatedcatalyst_component_names;
2952
2953     for my $component ( @comps ) {
2954
2955         # We pass ignore_loaded here so that overlay files for (e.g.)
2956         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2957         # we know M::P::O found a file on disk so this is safe
2958
2959         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2960     }
2961
2962     for my $component (@comps) {
2963         my $instance = $class->components->{ $component } = $class->delayed_setup_component($component);
2964     }
2965
2966     # Inject a component or wrap a stand alone class in an adaptor. This makes a list
2967     # of named components in the configuration that are not actually existing (not a
2968     # real file).
2969
2970     my @injected = $class->setup_injected_components;
2971
2972     # All components are registered, now we need to 'init' them.
2973     foreach my $component_name (@comps, @injected) {
2974       $class->components->{$component_name} = $class->components->{$component_name}->() if
2975         (ref($class->components->{$component_name}) || '') eq 'CODE';
2976     }
2977 }
2978
2979 =head2 $app->setup_injected_components
2980
2981 Called by setup_compoents to setup components that are injected.
2982
2983 =cut
2984
2985 sub setup_injected_components {
2986     my ($class) = @_;
2987     my @injected_components = keys %{$class->config->{inject_components} ||+{}};
2988
2989     foreach my $injected_comp_name(@injected_components) {
2990         $class->setup_injected_component(
2991           $injected_comp_name,
2992           $class->config->{inject_components}->{$injected_comp_name});
2993     }
2994
2995     return map { $class ."::" . $_ }
2996       @injected_components;
2997 }
2998
2999 =head2 $app->setup_injected_component( $injected_component_name, $config )
3000
3001 Setup a given injected component.
3002
3003 =cut
3004
3005 sub setup_injected_component {
3006     my ($class, $injected_comp_name, $config) = @_;
3007     if(my $component_class = $config->{from_component}) {
3008         my @roles = @{$config->{roles} ||[]};
3009         Catalyst::Utils::inject_component(
3010           into => $class,
3011           component => $component_class,
3012           (scalar(@roles) ? (traits => \@roles) : ()),
3013           as => $injected_comp_name);
3014     }
3015 }
3016
3017 =head2 $app->inject_component($MyApp_Component_name => \%args);
3018
3019 Add a component that is injected at setup:
3020
3021     MyApp->inject_component( 'Model::Foo' => { from_component => 'Common::Foo' } );
3022
3023 Must be called before ->setup.  Expects a component name for your
3024 current application and \%args where
3025
3026 =over 4
3027
3028 =item from_component
3029
3030 The target component being injected into your application
3031
3032 =item roles
3033
3034 An arrayref of L<Moose::Role>s that are applied to your component.
3035
3036 =back
3037
3038 Example
3039
3040     MyApp->inject_component(
3041       'Model::Foo' => {
3042         from_component => 'Common::Model::Foo',
3043         roles => ['Role1', 'Role2'],
3044       });
3045
3046 =head2 $app->inject_components
3047
3048 Inject a list of components:
3049
3050     MyApp->inject_components(
3051       'Model::FooOne' => {
3052         from_component => 'Common::Model::Foo',
3053         roles => ['Role1', 'Role2'],
3054       },
3055       'Model::FooTwo' => {
3056         from_component => 'Common::Model::Foo',
3057         roles => ['Role1', 'Role2'],
3058       });
3059
3060 =cut
3061
3062 sub inject_component {
3063   my ($app, $name, $args) = @_;
3064   die "Component $name exists" if
3065     $app->config->{inject_components}->{$name};
3066   $app->config->{inject_components}->{$name} = $args;
3067 }
3068
3069 sub inject_components {
3070   my $app = shift;
3071   while(@_) {
3072     $app->inject_component(shift, shift);
3073   }
3074 }
3075
3076 =head2 $c->locate_components( $setup_component_config )
3077
3078 This method is meant to provide a list of component modules that should be
3079 setup for the application.  By default, it will use L<Module::Pluggable>.
3080
3081 Specify a C<setup_components> config option to pass additional options directly
3082 to L<Module::Pluggable>. To add additional search paths, specify a key named
3083 C<search_extra> as an array reference. Items in the array beginning with C<::>
3084 will have the application class name prepended to them.
3085
3086 =cut
3087
3088 sub locate_components {
3089     my $class  = shift;
3090     my $config = shift;
3091
3092     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
3093     my $extra   = delete $config->{ search_extra } || [];
3094
3095     unshift @paths, @$extra;
3096
3097     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
3098       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
3099       %$config
3100     )->plugins } @paths;
3101
3102     return @comps;
3103 }
3104
3105 =head2 $c->expand_component_module( $component, $setup_component_config )
3106
3107 Components found by C<locate_components> will be passed to this method, which
3108 is expected to return a list of component (package) names to be set up.
3109
3110 =cut
3111
3112 sub expand_component_module {
3113     my ($class, $module) = @_;
3114     return Devel::InnerPackage::list_packages( $module );
3115 }
3116
3117 =head2 $app->delayed_setup_component
3118
3119 Returns a coderef that points to a setup_component instance.  Used
3120 internally for when you want to delay setup until the first time
3121 the component is called.
3122
3123 =cut
3124
3125 sub delayed_setup_component {
3126   my($class, $component, @more) = @_;
3127   return sub {
3128     return my $instance = $class->setup_component($component, @more);
3129   };
3130 }
3131
3132 =head2 $c->setup_component
3133
3134 =cut
3135
3136 sub setup_component {
3137     my( $class, $component ) = @_;
3138
3139     unless ( $component->can( 'COMPONENT' ) ) {
3140         return $component;
3141     }
3142
3143     my $config = $class->config_for($component);
3144     # Stash catalyst_component_name in the config here, so that custom COMPONENT
3145     # methods also pass it. local to avoid pointlessly shitting in config
3146     # for the debug screen, as $component is already the key name.
3147     local $config->{catalyst_component_name} = $component;
3148
3149     my $instance = eval {
3150       $component->COMPONENT( $class, $config );
3151     } || do {
3152       my $error = $@;
3153       chomp $error;
3154       Catalyst::Exception->throw(
3155         message => qq/Couldn't instantiate component "$component", "$error"/
3156       );
3157     };
3158
3159     unless (blessed $instance) {
3160         my $metaclass = Moose::Util::find_meta($component);
3161         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
3162         my $component_method_from = $method_meta->associated_metaclass->name;
3163         my $value = defined($instance) ? $instance : 'undef';
3164         Catalyst::Exception->throw(
3165             message =>
3166             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
3167         );
3168     }
3169
3170     my @expanded_components = $instance->can('expand_modules')
3171       ? $instance->expand_modules( $component, $config )
3172       : $class->expand_component_module( $component, $config );
3173     for my $component (@expanded_components) {
3174       next if $class->components->{ $component };
3175       $class->components->{ $component } = $class->setup_component($component);
3176     }
3177
3178     return $instance;
3179 }
3180
3181 =head2 $app->config_for( $component_name )
3182
3183 Return the application level configuration (which is not yet merged with any
3184 local component configuration, via $component_class->config) for the named
3185 component or component object. Example:
3186
3187     MyApp->config(
3188       'Model::Foo' => { a => 1, b => 2},
3189     );
3190
3191     my $config = MyApp->config_for('MyApp::Model::Foo');
3192
3193 In this case $config is the hashref C< {a=>1, b=>2} >.
3194
3195 This is also handy for looking up configuration for a plugin, to make sure you follow
3196 existing L<Catalyst> standards for where a plugin should put its configuration.
3197
3198 =cut
3199
3200 sub config_for {
3201     my ($class, $component_name) = @_;
3202     my $component_suffix = Catalyst::Utils::class2classsuffix($component_name);
3203     my $config = $class->config->{ $component_suffix } || {};
3204
3205     return $config;
3206 }
3207
3208 =head2 $c->setup_dispatcher
3209
3210 Sets up dispatcher.
3211
3212 =cut
3213
3214 sub setup_dispatcher {
3215     my ( $class, $dispatcher ) = @_;
3216
3217     if ($dispatcher) {
3218         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
3219     }
3220
3221     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
3222         $dispatcher = 'Catalyst::Dispatcher::' . $env;
3223     }
3224
3225     unless ($dispatcher) {
3226         $dispatcher = $class->dispatcher_class;
3227     }
3228
3229     load_class($dispatcher);
3230
3231     # dispatcher instance
3232     $class->dispatcher( $dispatcher->new );
3233 }
3234
3235 =head2 $c->setup_engine
3236
3237 Sets up engine.
3238
3239 =cut
3240
3241 sub engine_class {
3242     my ($class, $requested_engine) = @_;
3243
3244     if (!$class->engine_loader || $requested_engine) {
3245         $class->engine_loader(
3246             Catalyst::EngineLoader->new({
3247                 application_name => $class,
3248                 (defined $requested_engine
3249                      ? (catalyst_engine_class => $requested_engine) : ()),
3250             }),
3251         );
3252     }
3253
3254     $class->engine_loader->catalyst_engine_class;
3255 }
3256
3257 sub setup_engine {
3258     my ($class, $requested_engine) = @_;
3259
3260     my $engine = do {
3261         my $loader = $class->engine_loader;
3262
3263         if (!$loader || $requested_engine) {
3264             $loader = Catalyst::EngineLoader->new({
3265                 application_name => $class,
3266                 (defined $requested_engine
3267                      ? (requested_engine => $requested_engine) : ()),
3268             }),
3269
3270             $class->engine_loader($loader);
3271         }
3272
3273         $loader->catalyst_engine_class;
3274     };
3275
3276     # Don't really setup_engine -- see _setup_psgi_app for explanation.
3277     return if $class->loading_psgi_file;
3278
3279     load_class($engine);
3280
3281     if ($ENV{MOD_PERL}) {
3282         my $apache = $class->engine_loader->auto;
3283
3284         my $meta = find_meta($class);
3285         my $was_immutable = $meta->is_immutable;
3286         my %immutable_options = $meta->immutable_options;
3287         $meta->make_mutable if $was_immutable;
3288
3289         $meta->add_method(handler => sub {
3290             my $r = shift;
3291             my $psgi_app = $class->_finalized_psgi_app;
3292             $apache->call_app($r, $psgi_app);
3293         });
3294
3295         $meta->make_immutable(%immutable_options) if $was_immutable;
3296     }
3297
3298     $class->engine( $engine->new );
3299
3300     return;
3301 }
3302
3303 ## This exists just to supply a prebuild psgi app for mod_perl and for the
3304 ## build in server support (back compat support for pre psgi port behavior).
3305 ## This is so that we don't build a new psgi app for each request when using
3306 ## the mod_perl handler or the built in servers (http and fcgi, etc).
3307
3308 sub _finalized_psgi_app {
3309     my ($app) = @_;
3310
3311     unless ($app->_psgi_app) {
3312         my $psgi_app = $app->_setup_psgi_app;
3313         $app->_psgi_app($psgi_app);
3314     }
3315
3316     return $app->_psgi_app;
3317 }
3318
3319 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
3320 ## home directory and load that and return it (just assume it is doing the
3321 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
3322 ## in default_middleware and return it ( this is for backward compatibility
3323 ## with pre psgi port behavior ).
3324
3325 sub _setup_psgi_app {
3326     my ($app) = @_;
3327
3328     for my $home (Path::Class::Dir->new($app->config->{home})) {
3329         my $psgi_file = $home->file(
3330             Catalyst::Utils::appprefix($app) . '.psgi',
3331         );
3332
3333         next unless -e $psgi_file;
3334
3335         # If $psgi_file calls ->setup_engine, it's doing so to load
3336         # Catalyst::Engine::PSGI. But if it does that, we're only going to
3337         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
3338         # anyway. So set a flag (ick) that tells setup_engine not to populate
3339         # $c->engine or do any other things we might regret.
3340
3341         $app->loading_psgi_file(1);
3342         my $psgi_app = Plack::Util::load_psgi($psgi_file);
3343         $app->loading_psgi_file(0);
3344
3345         return $psgi_app
3346             unless $app->engine_loader->needs_psgi_engine_compat_hack;
3347
3348         warn <<"EOW";
3349 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
3350
3351 Its content has been ignored. Please consult the Catalyst::Upgrading
3352 documentation on how to upgrade from Catalyst::Engine::PSGI.
3353 EOW
3354     }
3355
3356     return $app->apply_default_middlewares($app->psgi_app);
3357 }
3358
3359 =head2 $c->apply_default_middlewares
3360
3361 Adds the following L<Plack> middlewares to your application, since they are
3362 useful and commonly needed:
3363
3364 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3365 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3366 is smart enough to conditionally apply itself).
3367
3368 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3369 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3370 an indication that your server is running behind a proxy frontend.  However in
3371 2014 this is often not the case.  We preserve this code for backwards compatibility
3372 however I B<highly> recommend that if you are running the server behind a front
3373 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3374 setting to true for your environment configurations that run behind a proxy.  This
3375 way if you change your front end proxy address someday your code would inexplicably
3376 stop working as expected.
3377
3378 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3379 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3380 $ENV{SCRIPT_NAME}.
3381
3382 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3383 adding via C<registered_middleware> rather than this method.
3384
3385 If you are using Lighttpd or IIS6 you may wish to apply these middlewares.  In
3386 general this is no longer a common case but we have this here for backward
3387 compatibility.
3388
3389 =cut
3390
3391
3392 sub apply_default_middlewares {
3393     my ($app, $psgi_app) = @_;
3394
3395     # Don't add this conditional IF we are explicitly saying we want the
3396     # frontend proxy support.  We don't need it here since if that is the
3397     # case it will be always loaded in the default_middleware.
3398
3399     unless($app->config->{using_frontend_proxy}) {
3400       $psgi_app = Plack::Middleware::Conditional->wrap(
3401           $psgi_app,
3402           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3403           condition => sub {
3404               my ($env) = @_;
3405               return if $app->config->{ignore_frontend_proxy};
3406               return $env->{REMOTE_ADDR} eq '127.0.0.1';
3407           },
3408       );
3409     }
3410
3411     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3412     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3413     $psgi_app = Plack::Middleware::Conditional->wrap(
3414         $psgi_app,
3415         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3416         condition => sub {
3417             my ($env) = @_;
3418             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3419             return unless $1 < 4.23;
3420             1;
3421         },
3422     );
3423
3424     # we're applying this unconditionally as the middleware itself already makes
3425     # sure it doesn't fuck things up if it's not running under one of the right
3426     # IIS versions
3427     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3428
3429     # And another IIS issue, this time with IIS7.
3430     $psgi_app = Plack::Middleware::Conditional->wrap(
3431         $psgi_app,
3432         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3433         condition => sub {
3434             my ($env) = @_;
3435             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3436         },
3437     );
3438
3439     return $psgi_app;
3440 }
3441
3442 =head2 App->psgi_app
3443
3444 =head2 App->to_app
3445
3446 Returns a PSGI application code reference for the catalyst application
3447 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3448 method called.  We do however apply C<registered_middleware> since those are
3449 integral to how L<Catalyst> functions.  Also, unlike starting your application
3450 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3451 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3452 scripts in your $HOME directory.
3453
3454 B<NOTE> C<apply_default_middlewares> was originally created when the first PSGI
3455 port was done for v5.90000.  These are middlewares that are added to achieve
3456 backward compatibility with older applications.  If you start your application
3457 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3458 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3459 automatically.  This was done so that pre and post PSGI port applications would
3460 work the same way.
3461
3462 This is what you want to be using to retrieve the PSGI application code
3463 reference of your Catalyst application for use in a custom F<.psgi> or in your
3464 own created server modules.
3465
3466 =cut
3467
3468 *to_app = \&psgi_app;
3469
3470 sub psgi_app {
3471     my ($app) = @_;
3472     my $psgi = $app->engine->build_psgi_app($app);
3473     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3474 }
3475
3476 =head2 $c->setup_home
3477
3478 Sets up the home directory.
3479
3480 =cut
3481
3482 sub setup_home {
3483     my ( $class, $home ) = @_;
3484
3485     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3486         $home = $env;
3487     }
3488
3489     $home ||= Catalyst::Utils::home($class);
3490
3491     if ($home) {
3492         #I remember recently being scolded for assigning config values like this
3493         $class->config->{home} ||= $home;
3494         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3495     }
3496 }
3497
3498 =head2 $c->setup_encoding
3499
3500 Sets up the input/output encoding. See L<ENCODING>
3501
3502 =cut
3503
3504 sub setup_encoding {
3505     my $c = shift;
3506     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3507         # Ok, so the user has explicitly said "I don't want encoding..."
3508         return;
3509     } else {
3510       my $enc = defined($c->config->{encoding}) ?
3511         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3512       $c->encoding($enc);
3513     }
3514 }
3515
3516 =head2 handle_unicode_encoding_exception
3517
3518 Hook to let you customize how encoding errors are handled.  By default
3519 we just throw an exception.  Receives a hashref of debug information.
3520 Example:
3521
3522     $c->handle_unicode_encoding_exception({
3523         param_value => $value,
3524         error_msg => $_,
3525             encoding_step => 'params',
3526         });
3527
3528 =cut
3529
3530 sub handle_unicode_encoding_exception {
3531     my ( $self, $exception_ctx ) = @_;
3532     die $exception_ctx->{error_msg};
3533 }
3534
3535 # Some unicode helpers cargo culted from the old plugin.  These could likely
3536 # be neater.
3537
3538 sub _handle_unicode_decoding {
3539     my ( $self, $value ) = @_;
3540
3541     return unless defined $value;
3542
3543     ## I think this mess is to support the old nested
3544     if ( ref $value eq 'ARRAY' ) {
3545         foreach ( @$value ) {
3546             $_ = $self->_handle_unicode_decoding($_);
3547         }
3548         return $value;
3549     }
3550     elsif ( ref $value eq 'HASH' ) {
3551         foreach (keys %$value) {
3552             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3553             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3554
3555             # If the key was encoded we now have two (the original and current so
3556             # delete the original.
3557             delete $value->{$_} if $_ ne $encoded_key;
3558         }
3559         return $value;
3560     }
3561     else {
3562         return $self->_handle_param_unicode_decoding($value);
3563     }
3564 }
3565
3566 sub _handle_param_unicode_decoding {
3567     my ( $self, $value ) = @_;
3568     return unless defined $value; # not in love with just ignoring undefs - jnap
3569     return $value if blessed($value); #don't decode when the value is an object.
3570
3571     my $enc = $self->encoding;
3572     return try {
3573       $enc->decode( $value, $self->_encode_check );
3574     }
3575     catch {
3576         $self->handle_unicode_encoding_exception({
3577             param_value => $value,
3578             error_msg => $_,
3579             encoding_step => 'params',
3580         });
3581     };
3582 }
3583
3584 =head2 $c->setup_log
3585
3586 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3587 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3588 log to.
3589
3590 This method also installs a C<debug> method that returns a true value into the
3591 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3592 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3593
3594 Note that if the log has already been setup, by either a previous call to
3595 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3596 that this method won't actually set up the log object.
3597
3598 =cut
3599
3600 sub setup_log {
3601     my ( $class, $levels ) = @_;
3602
3603     $levels ||= '';
3604     $levels =~ s/^\s+//;
3605     $levels =~ s/\s+$//;
3606     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3607
3608     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3609     if ( defined $env_debug ) {
3610         $levels{debug} = 1 if $env_debug; # Ugly!
3611         delete($levels{debug}) unless $env_debug;
3612     }
3613
3614     unless ( $class->log ) {
3615         $class->log( Catalyst::Log->new(keys %levels) );
3616     }
3617
3618     if ( $levels{debug} ) {
3619         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3620         $class->log->debug('Debug messages enabled');
3621     }
3622 }
3623
3624 =head2 $c->setup_plugins
3625
3626 Sets up plugins.
3627
3628 =cut
3629
3630 =head2 $c->setup_stats
3631
3632 Sets up timing statistics class.
3633
3634 =cut
3635
3636 sub setup_stats {
3637     my ( $class, $stats ) = @_;
3638
3639     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3640
3641     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3642     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3643         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3644         $class->log->debug('Statistics enabled');
3645     }
3646 }
3647
3648
3649 =head2 $c->registered_plugins
3650
3651 Returns a sorted list of the plugins which have either been stated in the
3652 import list.
3653
3654 If passed a given plugin name, it will report a boolean value indicating
3655 whether or not that plugin is loaded.  A fully qualified name is required if
3656 the plugin name does not begin with C<Catalyst::Plugin::>.
3657
3658  if ($c->registered_plugins('Some::Plugin')) {
3659      ...
3660  }
3661
3662 =cut
3663
3664 {
3665
3666     sub registered_plugins {
3667         my $proto = shift;
3668         return sort keys %{ $proto->_plugins } unless @_;
3669         my $plugin = shift;
3670         return 1 if exists $proto->_plugins->{$plugin};
3671         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3672     }
3673
3674     sub _register_plugin {
3675         my ( $proto, $plugin, $instant ) = @_;
3676         my $class = ref $proto || $proto;
3677
3678         load_class( $plugin );
3679         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3680             if $plugin->isa( 'Catalyst::Component' );
3681         my $plugin_meta = Moose::Meta::Class->create($plugin);
3682         if (!$plugin_meta->has_method('new')
3683             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3684             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3685         }
3686         if (!$instant && !$proto->_plugins->{$plugin}) {
3687             my $meta = Class::MOP::get_metaclass_by_name($class);
3688             $meta->superclasses($plugin, $meta->superclasses);
3689         }
3690         $proto->_plugins->{$plugin} = 1;
3691         return $class;
3692     }
3693
3694     sub _default_plugins { return qw() }
3695
3696     sub setup_plugins {
3697         my ( $class, $plugins ) = @_;
3698
3699         $class->_plugins( {} ) unless $class->_plugins;
3700         $plugins = [ grep {
3701             m/Unicode::Encoding/ ? do {
3702                 $class->log->warn(
3703                     'Unicode::Encoding plugin is auto-applied,'
3704                     . ' please remove this from your appclass'
3705                     . ' and make sure to define "encoding" config'
3706                 );
3707                 unless (exists $class->config->{'encoding'}) {
3708                   $class->config->{'encoding'} = 'UTF-8';
3709                 }
3710                 () }
3711                 : $_
3712         } @$plugins ];
3713         push @$plugins, $class->_default_plugins;
3714         $plugins = Data::OptList::mkopt($plugins || []);
3715
3716         my @plugins = map {
3717             [ Catalyst::Utils::resolve_namespace(
3718                   $class . '::Plugin',
3719                   'Catalyst::Plugin', $_->[0]
3720               ),
3721               $_->[1],
3722             ]
3723          } @{ $plugins };
3724
3725         for my $plugin ( reverse @plugins ) {
3726             load_class($plugin->[0], $plugin->[1]);
3727             my $meta = find_meta($plugin->[0]);
3728             next if $meta && $meta->isa('Moose::Meta::Role');
3729
3730             $class->_register_plugin($plugin->[0]);
3731         }
3732
3733         my @roles =
3734             map  { $_->[0]->name, $_->[1] }
3735             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3736             map  { [find_meta($_->[0]), $_->[1]] }
3737             @plugins;
3738
3739         Moose::Util::apply_all_roles(
3740             $class => @roles
3741         ) if @roles;
3742     }
3743 }
3744
3745 =head2 default_middleware
3746
3747 Returns a list of instantiated PSGI middleware objects which is the default
3748 middleware that is active for this application (taking any configuration
3749 options into account, excluding your custom added middleware via the C<psgi_middleware>
3750 configuration option).  You can override this method if you wish to change
3751 the default middleware (although do so at risk since some middleware is vital
3752 to application function.)
3753
3754 The current default middleware list is:
3755
3756       Catalyst::Middleware::Stash
3757       Plack::Middleware::HTTPExceptions
3758       Plack::Middleware::RemoveRedundantBody
3759       Plack::Middleware::FixMissingBodyInRedirect
3760       Plack::Middleware::ContentLength
3761       Plack::Middleware::MethodOverride
3762       Plack::Middleware::Head
3763
3764 If the configuration setting C<using_frontend_proxy> is true we add:
3765
3766       Plack::Middleware::ReverseProxy
3767
3768 If the configuration setting C<using_frontend_proxy_path> is true we add:
3769
3770       Plack::Middleware::ReverseProxyPath
3771
3772 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3773 L<Catalyst> distribution so if you want to use this option you should add it to
3774 your project distribution file.
3775
3776 These middlewares will be added at L</setup_middleware> during the
3777 L</setup> phase of application startup.
3778
3779 =cut
3780
3781 sub default_middleware {
3782     my $class = shift;
3783     my @mw = (
3784       Catalyst::Middleware::Stash->new,
3785       Plack::Middleware::HTTPExceptions->new,
3786       Plack::Middleware::RemoveRedundantBody->new,
3787       Plack::Middleware::FixMissingBodyInRedirect->new,
3788       Plack::Middleware::ContentLength->new,
3789       Plack::Middleware::MethodOverride->new,
3790       Plack::Middleware::Head->new);
3791
3792     if($class->config->{using_frontend_proxy}) {
3793         push @mw, Plack::Middleware::ReverseProxy->new;
3794     }
3795
3796     if($class->config->{using_frontend_proxy_path}) {
3797         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3798             push @mw, Plack::Middleware::ReverseProxyPath->new;
3799         } else {
3800           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3801         }
3802     }
3803
3804     return @mw;
3805 }
3806
3807 =head2 registered_middlewares
3808
3809 Read only accessor that returns an array of all the middleware in the order
3810 that they were added (which is the REVERSE of the order they will be applied).
3811
3812 The values returned will be either instances of L<Plack::Middleware> or of a
3813 compatible interface, or a coderef, which is assumed to be inlined middleware
3814
3815 =head2 setup_middleware (?@middleware)
3816
3817 Read configuration information stored in configuration key C<psgi_middleware> or
3818 from passed @args.
3819
3820 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3821 to use it to enable L<Plack::Middleware>
3822
3823 This method is automatically called during 'setup' of your application, so
3824 you really don't need to invoke it.  However you may do so if you find the idea
3825 of loading middleware via configuration weird :).  For example:
3826
3827     package MyApp;
3828
3829     use Catalyst;
3830
3831     __PACKAGE__->setup_middleware('Head');
3832     __PACKAGE__->setup;
3833
3834 When we read middleware definitions from configuration, we reverse the list
3835 which sounds odd but is likely how you expect it to work if you have prior
3836 experience with L<Plack::Builder> or if you previously used the plugin
3837 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3838
3839 So basically your middleware handles an incoming request from the first
3840 registered middleware, down and handles the response from the last middleware
3841 up.
3842
3843 =cut
3844
3845 sub registered_middlewares {
3846     my $class = shift;
3847     if(my $middleware = $class->_psgi_middleware) {
3848         my @mw = ($class->default_middleware, @$middleware);
3849
3850         if($class->config->{using_frontend_proxy}) {
3851           push @mw, Plack::Middleware::ReverseProxy->new;
3852         }
3853
3854         return @mw;
3855     } else {
3856         die "You cannot call ->registered_middlewares until middleware has been setup";
3857     }
3858 }
3859
3860 sub setup_middleware {
3861     my $class = shift;
3862     my @middleware_definitions;
3863
3864     # If someone calls this method you can add middleware with args.  However if its
3865     # called without an arg we need to setup the configuration middleware.
3866     if(@_) {
3867       @middleware_definitions = reverse(@_);
3868     } else {
3869       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3870         unless $class->finalized_default_middleware;
3871       $class->finalized_default_middleware(1); # Only do this once, just in case some people call setup over and over...
3872     }
3873
3874     my @middleware = ();
3875     while(my $next = shift(@middleware_definitions)) {
3876         if(ref $next) {
3877             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3878                 push @middleware, $next;
3879             } elsif(ref $next eq 'CODE') {
3880                 push @middleware, $next;
3881             } elsif(ref $next eq 'HASH') {
3882                 my $namespace = shift @middleware_definitions;
3883                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3884                 push @middleware, $mw;
3885             } else {
3886               die "I can't handle middleware definition ${\ref $next}";
3887             }
3888         } else {
3889           my $mw = $class->Catalyst::Utils::build_middleware($next);
3890           push @middleware, $mw;
3891         }
3892     }
3893
3894     my @existing = @{$class->_psgi_middleware || []};
3895     $class->_psgi_middleware([@middleware,@existing,]);
3896 }
3897
3898 =head2 registered_data_handlers
3899
3900 A read only copy of registered Data Handlers returned as a Hash, where each key
3901 is a content type and each value is a subref that attempts to decode that content
3902 type.
3903
3904 =head2 setup_data_handlers (?@data_handler)
3905
3906 Read configuration information stored in configuration key C<data_handlers> or
3907 from passed @args.
3908
3909 See under L</CONFIGURATION> information regarding C<data_handlers>.
3910
3911 This method is automatically called during 'setup' of your application, so
3912 you really don't need to invoke it.
3913
3914 =head2 default_data_handlers
3915
3916 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3917 only two default data handlers, for 'application/json' and an alternative to
3918 'application/x-www-form-urlencoded' which supposed nested form parameters via
3919 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3920
3921 The 'application/json' data handler is used to parse incoming JSON into a Perl
3922 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3923 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3924 JSON decoder, and has the smallest dependency impact.
3925
3926 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3927 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3928 order to get the best performance.  You should add either to your dependency
3929 list (Makefile.PL, dist.ini, cpanfile, etc.)
3930
3931 =cut
3932
3933 sub registered_data_handlers {
3934     my $class = shift;
3935     if(my $data_handlers = $class->_data_handlers) {
3936         return %$data_handlers;
3937     } else {
3938         $class->setup_data_handlers;
3939         return $class->registered_data_handlers;
3940     }
3941 }
3942
3943 sub setup_data_handlers {
3944     my ($class, %data_handler_callbacks) = @_;
3945     %data_handler_callbacks = (
3946       %{$class->default_data_handlers},
3947       %{$class->config->{'data_handlers'}||+{}},
3948       %data_handler_callbacks);
3949
3950     $class->_data_handlers(\%data_handler_callbacks);
3951 }
3952
3953 sub default_data_handlers {
3954     my ($class) = @_;
3955     return +{
3956       'application/x-www-form-urlencoded' => sub {
3957           my ($fh, $req) = @_;
3958           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3959           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3960             ->can('build_cgi_struct')->($params);
3961       },
3962       'application/json' => sub {
3963           my ($fh, $req) = @_;
3964           my $parser = Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON');
3965           my $slurped;
3966           return eval {
3967             local $/;
3968             $slurped = $fh->getline;
3969             $parser->can("decode_json")->($slurped); # decode_json does utf8 decoding for us
3970           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
3971         },
3972     };
3973 }
3974
3975 sub _handle_http_exception {
3976     my ( $self, $error ) = @_;
3977     if (
3978            !$self->config->{always_catch_http_exceptions}
3979         && blessed $error
3980         && (
3981             $error->can('as_psgi')
3982             || (   $error->can('code')
3983                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
3984         )
3985       )
3986     {
3987         return 1;
3988     }
3989 }
3990
3991 =head2 $c->stack
3992
3993 Returns an arrayref of the internal execution stack (actions that are
3994 currently executing).
3995
3996 =head2 $c->stats
3997
3998 Returns the current timing statistics object. By default Catalyst uses
3999 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
4000 L<< stats_class|/"$c->stats_class" >>.
4001
4002 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
4003 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
4004 profile explicitly, although MyApp.pm still won't profile nor output anything
4005 by itself.
4006
4007 =head2 $c->stats_class
4008
4009 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
4010
4011 =head2 $app->stats_class_traits
4012
4013 A arrayref of L<Moose::Role>s that are applied to the stats_class before creating it.
4014
4015 =head2 $app->composed_stats_class
4016
4017 this is the stats_class composed with any 'stats_class_traits'.  You can
4018 name the full namespace of the role, or a namespace suffix, which will then
4019 be tried against the following standard namespace prefixes.
4020
4021     $MyApp::TraitFor::Stats::$trait_suffix
4022     Catalyst::TraitFor::Stats::$trait_suffix
4023
4024 So for example if you set:
4025
4026     MyApp->stats_class_traits(['Foo']);
4027
4028 We try each possible role in turn (and throw an error if none load)
4029
4030     Foo
4031     MyApp::TraitFor::Stats::Foo
4032     Catalyst::TraitFor::Stats::Foo
4033
4034 The namespace part 'TraitFor::Stats' was chosen to assist in backwards
4035 compatibility with L<CatalystX::RoleApplicator> which previously provided
4036 these features in a stand alone package.
4037
4038 =head2 $c->use_stats
4039
4040 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
4041
4042 Note that this is a static method, not an accessor and should be overridden
4043 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
4044
4045 =cut
4046
4047 sub use_stats { 0 }
4048
4049
4050 =head2 $c->write( $data )
4051
4052 Writes $data to the output stream. When using this method directly, you
4053 will need to manually set the C<Content-Length> header to the length of
4054 your output data, if known.
4055
4056 =cut
4057
4058 sub write {
4059     my $c = shift;
4060
4061     # Finalize headers if someone manually writes output (for compat)
4062     $c->finalize_headers;
4063
4064     return $c->response->write( @_ );
4065 }
4066
4067 =head2 version
4068
4069 Returns the Catalyst version number. Mostly useful for "powered by"
4070 messages in template systems.
4071
4072 =cut
4073
4074 sub version { return $Catalyst::VERSION }
4075
4076 =head1 CONFIGURATION
4077
4078 There are a number of 'base' config variables which can be set:
4079
4080 =over
4081
4082 =item *
4083
4084 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
4085 rethrows errors conforming to the interface described by
4086 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
4087 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
4088
4089 =item *
4090
4091 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
4092
4093 =item *
4094
4095 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
4096
4097 =item *
4098
4099 C<disable_component_resolution_regex_fallback> - Turns
4100 off the deprecated component resolution functionality so
4101 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
4102 are called then regex search will not be attempted on string values and
4103 instead C<undef> will be returned.
4104
4105 =item *
4106
4107 C<home> - The application home directory. In an uninstalled application,
4108 this is the top level application directory. In an installed application,
4109 this will be the directory containing C<< MyApp.pm >>.
4110
4111 =item *
4112
4113 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
4114
4115 =item *
4116
4117 C<name> - The name of the application in debug messages and the debug and
4118 welcome screens
4119
4120 =item *
4121
4122 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
4123 until it is accessed. This allows you to (for example) check authentication (and reject
4124 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
4125
4126 =item *
4127
4128 C<root> - The root directory for templates. Usually this is just a
4129 subdirectory of the home directory, but you can set it to change the
4130 templates to a different directory.
4131
4132 =item *
4133
4134 C<search_extra> - Array reference passed to Module::Pluggable to for additional
4135 namespaces from which components will be loaded (and constructed and stored in
4136 C<< $c->components >>).
4137
4138 =item *
4139
4140 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
4141 to be shown in hit debug tables in the test server.
4142
4143 =item *
4144
4145 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
4146 variable should be used for determining the request path.
4147
4148 Most web server environments pass the requested path to the application using environment variables,
4149 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
4150 exposed as C<< $c->request->base >>) and the request path below that base.
4151
4152 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
4153 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
4154
4155 =over
4156
4157 =item use_request_uri_for_path => 0
4158
4159 This is the default (and the) traditional method that Catalyst has used for determining the path information.
4160 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
4161 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
4162 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
4163
4164 However this method has the major disadvantage that it is impossible to correctly decode some elements
4165 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
4166 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
4167 can't distinguish / vs %2F in paths (in addition to other encoded values).
4168
4169 =item use_request_uri_for_path => 1
4170
4171 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
4172 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
4173 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
4174
4175 Given that this method of path resolution is provably more correct, it is recommended that you use
4176 this unless you have a specific need to deploy your application in a non-standard environment, and you are
4177 aware of the implications of not being able to handle encoded URI paths correctly.
4178
4179 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
4180 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
4181 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
4182 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
4183 C<< $c->request->base >> will be incorrect.
4184
4185 =back
4186
4187 =item *
4188
4189 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
4190
4191 =item *
4192
4193 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
4194 installed, otherwise log an error).  This is useful if your application is not running on the
4195 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
4196 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
4197 This has been done since not all people need this feature and we wish to restrict the growth of
4198 L<Catalyst> dependencies.
4199
4200 =item *
4201
4202 C<encoding> - See L</ENCODING>
4203
4204 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
4205 value to undef.
4206
4207 =item *
4208
4209 C<abort_chain_on_error_fix>
4210
4211 When there is an error in an action chain, the default behavior is to continue
4212 processing the remaining actions and then catch the error upon chain end.  This
4213 can lead to running actions when the application is in an unexpected state.  If
4214 you have this issue, setting this config value to true will promptly exit a
4215 chain when there is an error raised in any action (thus terminating the chain
4216 early.)
4217
4218 use like:
4219
4220     __PACKAGE__->config(abort_chain_on_error_fix => 1);
4221
4222 In the future this might become the default behavior.
4223
4224 =item *
4225
4226 C<use_hash_multivalue_in_request>
4227
4228 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
4229 and C<parameters> return a hashref where values might be scalar or an arrayref
4230 depending on the incoming data.  In many cases this can be undesirable as it
4231 leads one to writing defensive code like the following:
4232
4233     my ($val) = ref($c->req->parameters->{a}) ?
4234       @{$c->req->parameters->{a}} :
4235         $c->req->parameters->{a};
4236
4237 Setting this configuration item to true will make L<Catalyst> populate the
4238 attributes underlying these methods with an instance of L<Hash::MultiValue>
4239 which is used by L<Plack::Request> and others to solve this very issue.  You
4240 may prefer this behavior to the default, if so enable this option (be warned
4241 if you enable it in a legacy application we are not sure if it is completely
4242 backwardly compatible).
4243
4244 =item *
4245
4246 C<skip_complex_post_part_handling>
4247
4248 When creating body parameters from a POST, if we run into a multipart POST
4249 that does not contain uploads, but instead contains inlined complex data
4250 (very uncommon) we cannot reliably convert that into field => value pairs.  So
4251 instead we create an instance of L<Catalyst::Request::PartData>.  If this causes
4252 issue for you, you can disable this by setting C<skip_complex_post_part_handling>
4253 to true (default is false).
4254
4255 =item *
4256
4257 C<skip_body_param_unicode_decoding>
4258
4259 Generally we decode incoming POST params based on your declared encoding (the
4260 default for this is to decode UTF-8).  If this is causing you trouble and you
4261 do not wish to turn all encoding support off (with the C<encoding> configuration
4262 parameter) you may disable this step atomically by setting this configuration
4263 parameter to true.
4264
4265 =item *
4266
4267 C<do_not_decode_query>
4268
4269 If true, then do not try to character decode any wide characters in your
4270 request URL query or keywords.  Most readings of the relevant specifications
4271 suggest these should be UTF-* encoded, which is the default that L<Catalyst>
4272 will use, however if you are creating a lot of URLs manually or have external
4273 evil clients, this might cause you trouble.  If you find the changes introduced
4274 in Catalyst version 5.90080+ break some of your query code, you may disable
4275 the UTF-8 decoding globally using this configuration.
4276
4277 This setting takes precedence over C<default_query_encoding> and
4278 C<decode_query_using_global_encoding>
4279
4280 =item *
4281
4282 C<default_query_encoding>
4283
4284 By default we decode query and keywords in your request URL using UTF-8, which
4285 is our reading of the relevant specifications.  This setting allows one to
4286 specify a fixed value for how to decode your query.  You might need this if
4287 you are doing a lot of custom encoding of your URLs and not using UTF-8.
4288
4289 This setting take precedence over C<decode_query_using_global_encoding>.
4290
4291 =item *
4292
4293 C<decode_query_using_global_encoding>
4294
4295 Setting this to true will default your query decoding to whatever your
4296 general global encoding is (the default is UTF-8).
4297
4298 =item *
4299
4300 C<use_chained_args_0_special_case>
4301
4302 In older versions of Catalyst, when more than one action matched the same path
4303 AND all those matching actions declared Args(0), we'd break the tie by choosing
4304 the first action defined.  We now normalized how Args(0) works so that it
4305 follows the same rule as Args(N), which is to say when we need to break a tie
4306 we choose the LAST action defined.  If this breaks your code and you don't
4307 have time to update to follow the new normalized approach, you may set this
4308 value to true and it will globally revert to the original chaining behavior.
4309
4310 =item *
4311
4312 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
4313
4314 =item *
4315
4316 C<data_handlers> - See L<DATA HANDLERS>.
4317
4318 =item *
4319
4320 C<stats_class_traits>
4321
4322 An arrayref of L<Moose::Role>s that get composed into your stats class.
4323
4324 =item *
4325
4326 C<request_class_traits>
4327
4328 An arrayref of L<Moose::Role>s that get composed into your request class.
4329
4330 =item *
4331
4332 C<response_class_traits>
4333
4334 An arrayref of L<Moose::Role>s that get composed into your response class.
4335
4336 =item *
4337
4338 C<inject_components>
4339
4340 A Hashref of L<Catalyst::Component> subclasses that are 'injected' into configuration.
4341 For example:
4342
4343     MyApp->config({
4344       inject_components => {
4345         'Controller::Err' => { from_component => 'Local::Controller::Errors' },
4346         'Model::Zoo' => { from_component => 'Local::Model::Foo' },
4347         'Model::Foo' => { from_component => 'Local::Model::Foo', roles => ['TestRole'] },
4348       },
4349       'Controller::Err' => { a => 100, b=>200, namespace=>'error' },
4350       'Model::Zoo' => { a => 2 },
4351       'Model::Foo' => { a => 100 },
4352     });
4353
4354 Generally L<Catalyst> looks for components in your Model/View or Controller directories.
4355 However for cases when you which to use an existing component and you don't need any
4356 customization (where for when you can apply a role to customize it) you may inject those
4357 components into your application.  Please note any configuration should be done 'in the
4358 normal way', with a key under configuration named after the component affix, as in the
4359 above example.
4360
4361 Using this type of injection allows you to construct significant amounts of your application
4362 with only configuration!.  This may or may not lead to increased code understanding.
4363
4364 Please not you may also call the ->inject_components application method as well, although
4365 you must do so BEFORE setup.
4366
4367 =back
4368
4369 =head1 EXCEPTIONS
4370
4371 Generally when you throw an exception inside an Action (or somewhere in
4372 your stack, such as in a model that an Action is calling) that exception
4373 is caught by Catalyst and unless you either catch it yourself (via eval
4374 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
4375 will eventually reach L</finalize_errors> and return either the debugging
4376 error stack page, or the default error page.  However, if your exception
4377 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
4378 instead rethrow it so that it can be handled by that middleware (which
4379 is part of the default middleware).  For example this would allow
4380
4381     use HTTP::Throwable::Factory 'http_throw';
4382
4383     sub throws_exception :Local {
4384       my ($self, $c) = @_;
4385
4386       http_throw(SeeOther => { location =>
4387         $c->uri_for($self->action_for('redirect')) });
4388
4389     }
4390
4391 =head1 INTERNAL ACTIONS
4392
4393 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
4394 C<_ACTION>, and C<_END>. These are by default not shown in the private
4395 action table, but you can make them visible with a config parameter.
4396
4397     MyApp->config(show_internal_actions => 1);
4398
4399 =head1 ON-DEMAND PARSER
4400
4401 The request body is usually parsed at the beginning of a request,
4402 but if you want to handle input yourself, you can enable on-demand
4403 parsing with a config parameter.
4404
4405     MyApp->config(parse_on_demand => 1);
4406
4407 =head1 PROXY SUPPORT
4408
4409 Many production servers operate using the common double-server approach,
4410 with a lightweight frontend web server passing requests to a larger
4411 backend server. An application running on the backend server must deal
4412 with two problems: the remote user always appears to be C<127.0.0.1> and
4413 the server's hostname will appear to be C<localhost> regardless of the
4414 virtual host that the user connected through.
4415
4416 Catalyst will automatically detect this situation when you are running
4417 the frontend and backend servers on the same machine. The following
4418 changes are made to the request.
4419
4420     $c->req->address is set to the user's real IP address, as read from
4421     the HTTP X-Forwarded-For header.
4422
4423     The host value for $c->req->base and $c->req->uri is set to the real
4424     host, as read from the HTTP X-Forwarded-Host header.
4425
4426 Additionally, you may be running your backend application on an insecure
4427 connection (port 80) while your frontend proxy is running under SSL.  If there
4428 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
4429 tell Catalyst what port the frontend listens on.  This will allow all URIs to
4430 be created properly.
4431
4432 In the case of passing in:
4433
4434     X-Forwarded-Port: 443
4435
4436 All calls to C<uri_for> will result in an https link, as is expected.
4437
4438 Obviously, your web server must support these headers for this to work.
4439
4440 In a more complex server farm environment where you may have your
4441 frontend proxy server(s) on different machines, you will need to set a
4442 configuration option to tell Catalyst to read the proxied data from the
4443 headers.
4444
4445     MyApp->config(using_frontend_proxy => 1);
4446
4447 If you do not wish to use the proxy support at all, you may set:
4448
4449     MyApp->config(ignore_frontend_proxy => 0);
4450
4451 =head2 Note about psgi files
4452
4453 Note that if you supply your own .psgi file, calling
4454 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
4455
4456 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
4457 in your psgi, for example:
4458
4459     builder {
4460         enable "Plack::Middleware::ReverseProxy";
4461         MyApp->psgi_app
4462     };
4463
4464 This will unconditionally add the ReverseProxy support, or you need to call
4465 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
4466 apply the support depending upon your config).
4467
4468 See L<Catalyst::PSGI> for more information.
4469
4470 =head1 THREAD SAFETY
4471
4472 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
4473 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
4474 believe the Catalyst core to be thread-safe.
4475
4476 If you plan to operate in a threaded environment, remember that all other
4477 modules you are using must also be thread-safe. Some modules, most notably
4478 L<DBD::SQLite>, are not thread-safe.
4479
4480 =head1 DATA HANDLERS
4481
4482 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
4483 form parameters and URL search query fields.  However it has become common
4484 for various alternative content types to be PUT or POSTed to your controllers
4485 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
4486 XML and other content types when communicating with an application server.  In
4487 order to better support this use case, L<Catalyst> defines a global configuration
4488 option, C<data_handlers>, which lets you associate a content type with a coderef
4489 that parses that content type into something Perl can readily access.
4490
4491     package MyApp::Web;
4492
4493     use Catalyst;
4494     use JSON::Maybe;
4495
4496     __PACKAGE__->config(
4497       data_handlers => {
4498         'application/json' => sub { local $/; decode_json $_->getline },
4499       },
4500       ## Any other configuration.
4501     );
4502
4503     __PACKAGE__->setup;
4504
4505 By default L<Catalyst> comes with a generic JSON data handler similar to the
4506 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
4507 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4508 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4509 or dist.ini, cpanfile, etc.)
4510
4511 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4512 (matched against the incoming request type using a regexp such as to be case
4513 insensitive) and whose values are coderefs that receive a localized version of
4514 C<$_> which is a filehandle object pointing to received body.
4515
4516 This feature is considered an early access release and we reserve the right
4517 to alter the interface in order to provide a performant and secure solution to
4518 alternative request body content.  Your reports welcomed!
4519
4520 =head1 PSGI MIDDLEWARE
4521
4522 You can define middleware, defined as L<Plack::Middleware> or a compatible
4523 interface in configuration.  Your middleware definitions are in the form of an
4524 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4525 with details to follow:
4526
4527     package MyApp::Web;
4528
4529     use Catalyst;
4530     use Plack::Middleware::StackTrace;
4531
4532     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4533
4534     __PACKAGE__->config(
4535       'psgi_middleware', [
4536         'Debug',
4537         '+MyApp::Custom',
4538         $stacktrace_middleware,
4539         'Session' => {store => 'File'},
4540         sub {
4541           my $app = shift;
4542           return sub {
4543             my $env = shift;
4544             $env->{myapp.customkey} = 'helloworld';
4545             $app->($env);
4546           },
4547         },
4548       ],
4549     );
4550
4551     __PACKAGE__->setup;
4552
4553 So the general form is:
4554
4555     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4556
4557 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4558 the order listed (to make it function similarly to L<Plack::Builder>:
4559
4560 Alternatively, you may also define middleware by calling the L</setup_middleware>
4561 package method:
4562
4563     package MyApp::Web;
4564
4565     use Catalyst;
4566
4567     __PACKAGE__->setup_middleware( \@middleware_definitions);
4568     __PACKAGE__->setup;
4569
4570 In the case where you do both (use 'setup_middleware' and configuration) the
4571 package call to setup_middleware will be applied earlier (in other words its
4572 middleware will wrap closer to the application).  Keep this in mind since in
4573 some cases the order of middleware is important.
4574
4575 The two approaches are not exclusive.
4576
4577 =over 4
4578
4579 =item Middleware Object
4580
4581 An already initialized object that conforms to the L<Plack::Middleware>
4582 specification:
4583
4584     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4585
4586     __PACKAGE__->config(
4587       'psgi_middleware', [
4588         $stacktrace_middleware,
4589       ]);
4590
4591
4592 =item coderef
4593
4594 A coderef that is an inlined middleware:
4595
4596     __PACKAGE__->config(
4597       'psgi_middleware', [
4598         sub {
4599           my $app = shift;
4600           return sub {
4601             my $env = shift;
4602             if($env->{PATH_INFO} =~m/forced/) {
4603               Plack::App::File
4604                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4605                 ->call($env);
4606             } else {
4607               return $app->($env);
4608             }
4609          },
4610       },
4611     ]);
4612
4613
4614
4615 =item a scalar
4616
4617 We assume the scalar refers to a namespace after normalizing it using the
4618 following rules:
4619
4620 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4621 is assumed to be 'as is', and we just install and use the middleware.
4622
4623 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4624 (the package name of your Catalyst application subclass), we also assume then
4625 that it is a full namespace, and use it.
4626
4627 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4628 resolve it first by looking for it under your application namespace (for example
4629 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4630 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4631 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4632 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4633 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4634 you find that a good idea.
4635
4636 Examples:
4637
4638     package MyApp::Web;
4639
4640     __PACKAGE__->config(
4641       'psgi_middleware', [
4642         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4643         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4644         '+MyApp::Custom',  ## MyApp::Custom->wrap
4645       ],
4646     );
4647
4648 =item a scalar followed by a hashref
4649
4650 Just like the previous, except the following C<HashRef> is used as arguments
4651 to initialize the middleware object.
4652
4653     __PACKAGE__->config(
4654       'psgi_middleware', [
4655          'Session' => {store => 'File'},
4656     ]);
4657
4658 =back
4659
4660 Please see L<PSGI> for more on middleware.
4661
4662 =head1 ENCODING
4663
4664 Starting in L<Catalyst> version 5.90080 encoding is automatically enabled
4665 and set to encode all body responses to UTF8 when possible and applicable.
4666 Following is documentation on this process.  If you are using an older
4667 version of L<Catalyst> you should review documentation for that version since
4668 a lot has changed.
4669
4670 By default encoding is now 'UTF-8'.  You may turn it off by setting
4671 the encoding configuration to undef.
4672
4673     MyApp->config(encoding => undef);
4674
4675 This is recommended for temporary backwards compatibility only.
4676
4677 Encoding is automatically applied when the content-type is set to
4678 a type that can be encoded.  Currently we encode when the content type
4679 matches the following regular expression:
4680
4681     $content_type =~ /^text|xml$|javascript$/
4682
4683 Encoding is set on the application, but it is copied to the context object
4684 so that you can override it on a request basis.
4685
4686 Be default we don't automatically encode 'application/json' since the most
4687 common approaches to generating this type of response (Either via L<Catalyst::View::JSON>
4688 or L<Catalyst::Action::REST>) will do so already and we want to avoid double
4689 encoding issues.
4690
4691 If you are producing JSON response in an unconventional manner (such
4692 as via a template or manual strings) you should perform the UTF8 encoding
4693 manually as well such as to conform to the JSON specification.
4694
4695 NOTE: We also examine the value of $c->response->content_encoding.  If
4696 you set this (like for example 'gzip', and manually gzipping the body)
4697 we assume that you have done all the necessary encoding yourself, since
4698 we cannot encode the gzipped contents.  If you use a plugin like
4699 L<Catalyst::Plugin::Compress> you need to update to a modern version in order
4700 to have this function correctly  with the new UTF8 encoding code, or you
4701 can use L<Plack::Middleware::Deflater> or (probably best) do your compression on
4702 a front end proxy.
4703
4704 =head2 Methods
4705
4706 =over 4
4707
4708 =item encoding
4709
4710 Returns an instance of an C<Encode> encoding
4711
4712     print $c->encoding->name
4713
4714 =item handle_unicode_encoding_exception ($exception_context)
4715
4716 Method called when decoding process for a request fails.
4717
4718 An C<$exception_context> hashref is provided to allow you to override the
4719 behaviour of your application when given data with incorrect encodings.
4720
4721 The default method throws exceptions in the case of invalid request parameters
4722 (resulting in a 500 error), but ignores errors in upload filenames.
4723
4724 The keys passed in the C<$exception_context> hash are:
4725
4726 =over
4727
4728 =item param_value
4729
4730 The value which was not able to be decoded.
4731
4732 =item error_msg
4733
4734 The exception received from L<Encode>.
4735
4736 =item encoding_step
4737
4738 What type of data was being decoded. Valid values are (currently)
4739 C<params> - for request parameters / arguments / captures
4740 and C<uploads> - for request upload filenames.
4741
4742 =back
4743
4744 =back
4745
4746 =head1 SUPPORT
4747
4748 IRC:
4749
4750     Join #catalyst on irc.perl.org.
4751
4752 Mailing Lists:
4753
4754     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4755     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4756
4757 Web:
4758
4759     http://catalyst.perl.org
4760
4761 Wiki:
4762
4763     http://dev.catalyst.perl.org
4764
4765 =head1 SEE ALSO
4766
4767 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4768
4769 =head2 L<Catalyst::Manual> - The Catalyst Manual
4770
4771 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4772
4773 =head2 L<Catalyst::Engine> - Core engine
4774
4775 =head2 L<Catalyst::Log> - Log class.
4776
4777 =head2 L<Catalyst::Request> - Request object
4778
4779 =head2 L<Catalyst::Response> - Response object
4780
4781 =head2 L<Catalyst::Test> - The test suite.
4782
4783 =head1 PROJECT FOUNDER
4784
4785 sri: Sebastian Riedel <sri@cpan.org>
4786
4787 =head1 CONTRIBUTORS
4788
4789 abw: Andy Wardley
4790
4791 acme: Leon Brocard <leon@astray.com>
4792
4793 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4794
4795 andrewalker: André Walker <andre@cpan.org>
4796
4797 Andrew Bramble
4798
4799 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4800
4801 Andrew Ruthven
4802
4803 andyg: Andy Grundman <andy@hybridized.org>
4804
4805 audreyt: Audrey Tang
4806
4807 bricas: Brian Cassidy <bricas@cpan.org>
4808
4809 Caelum: Rafael Kitover <rkitover@io.com>
4810
4811 chansen: Christian Hansen
4812
4813 chicks: Christopher Hicks
4814
4815 Chisel Wright C<pause@herlpacker.co.uk>
4816
4817 Danijel Milicevic C<me@danijel.de>
4818
4819 davewood: David Schmidt <davewood@cpan.org>
4820
4821 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4822
4823 David Naughton, C<naughton@umn.edu>
4824
4825 David E. Wheeler
4826
4827 dhoss: Devin Austin <dhoss@cpan.org>
4828
4829 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4830
4831 Drew Taylor
4832
4833 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4834
4835 esskar: Sascha Kiefer
4836
4837 fireartist: Carl Franks <cfranks@cpan.org>
4838
4839 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4840
4841 gabb: Danijel Milicevic
4842
4843 Gary Ashton Jones
4844
4845 Gavin Henry C<ghenry@perl.me.uk>
4846
4847 Geoff Richards
4848
4849 groditi: Guillermo Roditi <groditi@gmail.com>
4850
4851 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4852
4853 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4854
4855 jcamacho: Juan Camacho
4856
4857 jester: Jesse Sheidlower C<jester@panix.com>
4858
4859 jhannah: Jay Hannah <jay@jays.net>
4860
4861 Jody Belka
4862
4863 Johan Lindstrom
4864
4865 jon: Jon Schutz <jjschutz@cpan.org>
4866
4867 Jonathan Rockway C<< <jrockway@cpan.org> >>
4868
4869 Kieren Diment C<kd@totaldatasolution.com>
4870
4871 konobi: Scott McWhirter <konobi@cpan.org>
4872
4873 marcus: Marcus Ramberg <mramberg@cpan.org>
4874
4875 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4876
4877 mgrimes: Mark Grimes <mgrimes@cpan.org>
4878
4879 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4880
4881 mugwump: Sam Vilain
4882
4883 naughton: David Naughton
4884
4885 ningu: David Kamholz <dkamholz@cpan.org>
4886
4887 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4888
4889 numa: Dan Sully <daniel@cpan.org>
4890
4891 obra: Jesse Vincent
4892
4893 Octavian Rasnita
4894
4895 omega: Andreas Marienborg
4896
4897 Oleg Kostyuk <cub.uanic@gmail.com>
4898
4899 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4900
4901 rafl: Florian Ragwitz <rafl@debian.org>
4902
4903 random: Roland Lammel <lammel@cpan.org>
4904
4905 Robert Sedlacek C<< <rs@474.at> >>
4906
4907 SpiceMan: Marcel Montes
4908
4909 sky: Arthur Bergman
4910
4911 szbalint: Balint Szilakszi <szbalint@cpan.org>
4912
4913 t0m: Tomas Doran <bobtfish@bobtfish.net>
4914
4915 Ulf Edvinsson
4916
4917 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4918
4919 Viljo Marrandi C<vilts@yahoo.com>
4920
4921 Will Hawes C<info@whawes.co.uk>
4922
4923 willert: Sebastian Willert <willert@cpan.org>
4924
4925 wreis: Wallace Reis <wreis@cpan.org>
4926
4927 Yuval Kogman, C<nothingmuch@woobling.org>
4928
4929 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4930
4931 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4932
4933 Upasana <me@upasana.me>
4934
4935 John Napiorkowski (jnap) <jjnapiork@cpan.org>
4936
4937 =head1 COPYRIGHT
4938
4939 Copyright (c) 2005-2015, the above named PROJECT FOUNDER and CONTRIBUTORS.
4940
4941 =head1 LICENSE
4942
4943 This library is free software. You can redistribute it and/or modify it under
4944 the same terms as Perl itself.
4945
4946 =cut
4947
4948 no Moose;
4949
4950 __PACKAGE__->meta->make_immutable;
4951
4952 1;