lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use String::RewritePrefix;
  32 use Catalyst::EngineLoader;
  33 use utf8;
  34 use Carp qw/croak carp shortmess/;
  35 use Try::Tiny;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39 use Plack::Middleware::LighttpdScriptNameFix;
  40
  41 BEGIN { require 5.008004; }
  42
  43 has stack => (is => 'ro', default => sub { [] });
  44 has stash => (is => 'rw', default => sub { {} });
  45 has state => (is => 'rw', default => 0);
  46 has stats => (is => 'rw');
  47 has action => (is => 'rw');
  48 has counter => (is => 'rw', default => sub { {} });
  49 has request => (
  50     is => 'rw',
  51     default => sub {
  52         my $self = shift;
  53         my %p;
  54         $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  55         $self->request_class->new(\%p);
  56     },
  57     lazy => 1,
  58 );
  59 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  60 has namespace => (is => 'rw');
  61
  62 sub depth { scalar @{ shift->stack || [] }; }
  63 sub comp { shift->component(@_) }
  64
  65 sub req {
  66     my $self = shift; return $self->request(@_);
  67 }
  68 sub res {
  69     my $self = shift; return $self->response(@_);
  70 }
  71
  72 # For backwards compatibility
  73 sub finalize_output { shift->finalize_body(@_) };
  74
  75 # For statistics
  76 our $COUNT     = 1;
  77 our $START     = time;
  78 our $RECURSION = 1000;
  79 our $DETACH    = Catalyst::Exception::Detach->new;
  80 our $GO        = Catalyst::Exception::Go->new;
  81
  82 #I imagine that very few of these really need to be class variables. if any.
  83 #maybe we should just make them attributes with a default?
  84 __PACKAGE__->mk_classdata($_)
  85   for qw/components arguments dispatcher engine log dispatcher_class
  86   engine_loader context_class request_class response_class stats_class
  87   setup_finished _psgi_app loading_psgi_file run_options/;
  88
  89 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  90 __PACKAGE__->request_class('Catalyst::Request');
  91 __PACKAGE__->response_class('Catalyst::Response');
  92 __PACKAGE__->stats_class('Catalyst::Stats');
  93
  94 # Remember to update this in Catalyst::Runtime as well!
  95
  96 our $VERSION = '5.90006';
  97
  98 sub import {
  99     my ( $class, @arguments ) = @_;
 100
 101     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 102     # callers @ISA.
 103     return unless $class eq 'Catalyst';
 104
 105     my $caller = caller();
 106     return if $caller eq 'main';
 107
 108     my $meta = Moose::Meta::Class->initialize($caller);
 109     unless ( $caller->isa('Catalyst') ) {
 110         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 111         $meta->superclasses(@superclasses);
 112     }
 113     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 114     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 115
 116     unless( $meta->has_method('meta') ){
 117         if ($Moose::VERSION >= 1.15) {
 118             $meta->_add_meta_method('meta');
 119         }
 120         else {
 121             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 122         }
 123     }
 124
 125     $caller->arguments( [@arguments] );
 126     $caller->setup_home;
 127 }
 128
 129 sub _application { $_[0] }
 130
 131 =head1 NAME
 132
 133 Catalyst - The Elegant MVC Web Application Framework
 134
 135 =head1 SYNOPSIS
 136
 137 See the L<Catalyst::Manual> distribution for comprehensive
 138 documentation and tutorials.
 139
 140     # Install Catalyst::Devel for helpers and other development tools
 141     # use the helper to create a new application
 142     catalyst.pl MyApp
 143
 144     # add models, views, controllers
 145     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 146     script/myapp_create.pl view MyTemplate TT
 147     script/myapp_create.pl controller Search
 148
 149     # built in testserver -- use -r to restart automatically on changes
 150     # --help to see all available options
 151     script/myapp_server.pl
 152
 153     # command line testing interface
 154     script/myapp_test.pl /yada
 155
 156     ### in lib/MyApp.pm
 157     use Catalyst qw/-Debug/; # include plugins here as well
 158
 159     ### In lib/MyApp/Controller/Root.pm (autocreated)
 160     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 161         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 162         $c->stash->{template} = 'foo.tt'; # set the template
 163         # lookup something from db -- stash vars are passed to TT
 164         $c->stash->{data} =
 165           $c->model('Database::Foo')->search( { country => $args[0] } );
 166         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 167             $c->forward( 'bar' ); # process another action
 168             # do something else after forward returns
 169         }
 170     }
 171
 172     # The foo.tt TT template can use the stash data from the database
 173     [% WHILE (item = data.next) %]
 174         [% item.foo %]
 175     [% END %]
 176
 177     # called for /bar/of/soap, /bar/of/soap/10, etc.
 178     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 179
 180     # called after all actions are finished
 181     sub end : Action {
 182         my ( $self, $c ) = @_;
 183         if ( scalar @{ $c->error } ) { ... } # handle errors
 184         return if $c->res->body; # already have a response
 185         $c->forward( 'MyApp::View::TT' ); # render template
 186     }
 187
 188 See L<Catalyst::Manual::Intro> for additional information.
 189
 190 =head1 DESCRIPTION
 191
 192 Catalyst is a modern framework for making web applications without the
 193 pain usually associated with this process. This document is a reference
 194 to the main Catalyst application. If you are a new user, we suggest you
 195 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 196
 197 See L<Catalyst::Manual> for more documentation.
 198
 199 Catalyst plugins can be loaded by naming them as arguments to the "use
 200 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 201 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 202 C<My::Module>.
 203
 204     use Catalyst qw/My::Module/;
 205
 206 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 207 fully qualify the name by using a unary plus:
 208
 209     use Catalyst qw/
 210         My::Module
 211         +Fully::Qualified::Plugin::Name
 212     /;
 213
 214 Special flags like C<-Debug> can also be specified as
 215 arguments when Catalyst is loaded:
 216
 217     use Catalyst qw/-Debug My::Module/;
 218
 219 The position of plugins and flags in the chain is important, because
 220 they are loaded in the order in which they appear.
 221
 222 The following flags are supported:
 223
 224 =head2 -Debug
 225
 226 Enables debug output. You can also force this setting from the system
 227 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 228 settings override the application, with <MYAPP>_DEBUG having the highest
 229 priority.
 230
 231 This sets the log level to 'debug' and enables full debug output on the
 232 error screen. If you only want the latter, see L<< $c->debug >>.
 233
 234 =head2 -Home
 235
 236 Forces Catalyst to use a specific home directory, e.g.:
 237
 238     use Catalyst qw[-Home=/usr/mst];
 239
 240 This can also be done in the shell environment by setting either the
 241 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 242 is replaced with the uppercased name of your application, any "::" in
 243 the name will be replaced with underscores, e.g. MyApp::Web should use
 244 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 245
 246 If none of these are set, Catalyst will attempt to automatically detect the
 247 home directory. If you are working in a development environment, Catalyst
 248 will try and find the directory containing either Makefile.PL, Build.PL or
 249 dist.ini. If the application has been installed into the system (i.e.
 250 you have done C<make install>), then Catalyst will use the path to your
 251 application module, without the .pm extension (e.g., /foo/MyApp if your
 252 application was installed at /foo/MyApp.pm)
 253
 254 =head2 -Log
 255
 256     use Catalyst '-Log=warn,fatal,error';
 257
 258 Specifies a comma-delimited list of log levels.
 259
 260 =head2 -Stats
 261
 262 Enables statistics collection and reporting.
 263
 264    use Catalyst qw/-Stats=1/;
 265
 266 You can also force this setting from the system environment with CATALYST_STATS
 267 or <MYAPP>_STATS. The environment settings override the application, with
 268 <MYAPP>_STATS having the highest priority.
 269
 270 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 271
 272 =head1 METHODS
 273
 274 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 275
 276 =head2 $c->action
 277
 278 Returns a L<Catalyst::Action> object for the current action, which
 279 stringifies to the action name. See L<Catalyst::Action>.
 280
 281 =head2 $c->namespace
 282
 283 Returns the namespace of the current action, i.e., the URI prefix
 284 corresponding to the controller of the current action. For example:
 285
 286     # in Controller::Foo::Bar
 287     $c->namespace; # returns 'foo/bar';
 288
 289 =head2 $c->request
 290
 291 =head2 $c->req
 292
 293 Returns the current L<Catalyst::Request> object, giving access to
 294 information about the current client request (including parameters,
 295 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 296
 297 =head2 REQUEST FLOW HANDLING
 298
 299 =head2 $c->forward( $action [, \@arguments ] )
 300
 301 =head2 $c->forward( $class, $method, [, \@arguments ] )
 302
 303 Forwards processing to another action, by its private name. If you give a
 304 class name but no method, C<process()> is called. You may also optionally
 305 pass arguments in an arrayref. The action will receive the arguments in
 306 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 307 C<< $c->req->args >> will be restored to the previous values.
 308
 309 Any data C<return>ed from the action forwarded to, will be returned by the
 310 call to forward.
 311
 312     my $foodata = $c->forward('/foo');
 313     $c->forward('index');
 314     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 315     $c->forward('View::TT');
 316
 317 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 318 an C<< eval { } >> around the call (actually
 319 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 320 exceptions thrown by the called action non-fatal and pushing them onto
 321 $c->error instead. If you want C<die> to propagate you need to do something
 322 like:
 323
 324     $c->forward('foo');
 325     die join "\n", @{ $c->error } if @{ $c->error };
 326
 327 Or make sure to always return true values from your actions and write
 328 your code like this:
 329
 330     $c->forward('foo') || return;
 331
 332 Another note is that C<< $c->forward >> always returns a scalar because it
 333 actually returns $c->state which operates in a scalar context.
 334 Thus, something like:
 335
 336     return @array;
 337
 338 in an action that is forwarded to is going to return a scalar,
 339 i.e. how many items are in that array, which is probably not what you want.
 340 If you need to return an array then return a reference to it,
 341 or stash it like so:
 342
 343     $c->stash->{array} = \@array;
 344
 345 and access it from the stash.
 346
 347 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 348
 349 =cut
 350
 351 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 352
 353 =head2 $c->detach( $action [, \@arguments ] )
 354
 355 =head2 $c->detach( $class, $method, [, \@arguments ] )
 356
 357 =head2 $c->detach()
 358
 359 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 360 doesn't return to the previous action when processing is finished.
 361
 362 When called with no arguments it escapes the processing chain entirely.
 363
 364 =cut
 365
 366 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 367
 368 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 369
 370 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 371
 372 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 373 but does a full dispatch, instead of just calling the new C<$action> /
 374 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 375 you go to are called, just like a new request.
 376
 377 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 378 This means, for example, that C<< $c->action >> methods such as
 379 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 380 L<reverse|Catalyst::Action/reverse> return information for the visited action
 381 when they are invoked within the visited action.  This is different from the
 382 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 383 continues to use the $c->action object from the caller action even when
 384 invoked from the called action.
 385
 386 C<< $c->stash >> is kept unchanged.
 387
 388 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 389 allows you to "wrap" another action, just as it would have been called by
 390 dispatching from a URL, while the analogous
 391 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 392 transfer control to another action as if it had been reached directly from a URL.
 393
 394 =cut
 395
 396 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 397
 398 =head2 $c->go( $action [, \@captures, \@arguments ] )
 399
 400 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 401
 402 The relationship between C<go> and
 403 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 404 the relationship between
 405 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 406 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 407 C<< $c->go >> will perform a full dispatch on the specified action or method,
 408 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 409 C<go> escapes the processing of the current request chain on completion, and
 410 does not return to its caller.
 411
 412 @arguments are arguments to the final destination of $action. @captures are
 413 arguments to the intermediate steps, if any, on the way to the final sub of
 414 $action.
 415
 416 =cut
 417
 418 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 419
 420 =head2 $c->response
 421
 422 =head2 $c->res
 423
 424 Returns the current L<Catalyst::Response> object, see there for details.
 425
 426 =head2 $c->stash
 427
 428 Returns a hashref to the stash, which may be used to store data and pass
 429 it between components during a request. You can also set hash keys by
 430 passing arguments. The stash is automatically sent to the view. The
 431 stash is cleared at the end of a request; it cannot be used for
 432 persistent storage (for this you must use a session; see
 433 L<Catalyst::Plugin::Session> for a complete system integrated with
 434 Catalyst).
 435
 436     $c->stash->{foo} = $bar;
 437     $c->stash( { moose => 'majestic', qux => 0 } );
 438     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 439
 440     # stash is automatically passed to the view for use in a template
 441     $c->forward( 'MyApp::View::TT' );
 442
 443 =cut
 444
 445 around stash => sub {
 446     my $orig = shift;
 447     my $c = shift;
 448     my $stash = $orig->($c);
 449     if (@_) {
 450         my $new_stash = @_ > 1 ? {@_} : $_[0];
 451         croak('stash takes a hash or hashref') unless ref $new_stash;
 452         foreach my $key ( keys %$new_stash ) {
 453           $stash->{$key} = $new_stash->{$key};
 454         }
 455     }
 456
 457     return $stash;
 458 };
 459
 460
 461 =head2 $c->error
 462
 463 =head2 $c->error($error, ...)
 464
 465 =head2 $c->error($arrayref)
 466
 467 Returns an arrayref containing error messages.  If Catalyst encounters an
 468 error while processing a request, it stores the error in $c->error.  This
 469 method should only be used to store fatal error messages.
 470
 471     my @error = @{ $c->error };
 472
 473 Add a new error.
 474
 475     $c->error('Something bad happened');
 476
 477 =cut
 478
 479 sub error {
 480     my $c = shift;
 481     if ( $_[0] ) {
 482         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 483         croak @$error unless ref $c;
 484         push @{ $c->{error} }, @$error;
 485     }
 486     elsif ( defined $_[0] ) { $c->{error} = undef }
 487     return $c->{error} || [];
 488 }
 489
 490
 491 =head2 $c->state
 492
 493 Contains the return value of the last executed action.
 494 Note that << $c->state >> operates in a scalar context which means that all
 495 values it returns are scalar.
 496
 497 =head2 $c->clear_errors
 498
 499 Clear errors.  You probably don't want to clear the errors unless you are
 500 implementing a custom error screen.
 501
 502 This is equivalent to running
 503
 504     $c->error(0);
 505
 506 =cut
 507
 508 sub clear_errors {
 509     my $c = shift;
 510     $c->error(0);
 511 }
 512
 513 sub _comp_search_prefixes {
 514     my $c = shift;
 515     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 516 }
 517
 518 # search components given a name and some prefixes
 519 sub _comp_names_search_prefixes {
 520     my ( $c, $name, @prefixes ) = @_;
 521     my $appclass = ref $c || $c;
 522     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 523     $filter = qr/$filter/; # Compile regex now rather than once per loop
 524
 525     # map the original component name to the sub part that we will search against
 526     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 527         grep { /$filter/ } keys %{ $c->components };
 528
 529     # undef for a name will return all
 530     return keys %eligible if !defined $name;
 531
 532     my $query  = ref $name ? $name : qr/^$name$/i;
 533     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 534
 535     return @result if @result;
 536
 537     # if we were given a regexp to search against, we're done.
 538     return if ref $name;
 539
 540     # skip regexp fallback if configured
 541     return
 542         if $appclass->config->{disable_component_resolution_regex_fallback};
 543
 544     # regexp fallback
 545     $query  = qr/$name/i;
 546     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 547
 548     # no results? try against full names
 549     if( !@result ) {
 550         @result = grep { m{$query} } keys %eligible;
 551     }
 552
 553     # don't warn if we didn't find any results, it just might not exist
 554     if( @result ) {
 555         # Disgusting hack to work out correct method name
 556         my $warn_for = lc $prefixes[0];
 557         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 558            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 559            "component resolution is unreliable and unsafe.";
 560         my $short = $result[0];
 561         # remove the component namespace prefix
 562         $short =~ s/.*?(Model|Controller|View):://;
 563         my $shortmess = Carp::shortmess('');
 564         if ($shortmess =~ m#Catalyst/Plugin#) {
 565            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 566               "plugin's config";
 567         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 568            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 569               "component's config";
 570         } else {
 571            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 572               "but if you really wanted to search, pass in a regexp as the argument " .
 573               "like so: \$c->${warn_for}(qr/${name}/)";
 574         }
 575         $c->log->warn( "${msg}$shortmess" );
 576     }
 577
 578     return @result;
 579 }
 580
 581 # Find possible names for a prefix
 582 sub _comp_names {
 583     my ( $c, @prefixes ) = @_;
 584     my $appclass = ref $c || $c;
 585
 586     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 587
 588     my @names = map { s{$filter}{}; $_; }
 589         $c->_comp_names_search_prefixes( undef, @prefixes );
 590
 591     return @names;
 592 }
 593
 594 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 595 sub _filter_component {
 596     my ( $c, $comp, @args ) = @_;
 597
 598     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 599         return $comp->ACCEPT_CONTEXT( $c, @args );
 600     }
 601
 602     return $comp;
 603 }
 604
 605 =head2 COMPONENT ACCESSORS
 606
 607 =head2 $c->controller($name)
 608
 609 Gets a L<Catalyst::Controller> instance by name.
 610
 611     $c->controller('Foo')->do_stuff;
 612
 613 If the name is omitted, will return the controller for the dispatched
 614 action.
 615
 616 If you want to search for controllers, pass in a regexp as the argument.
 617
 618     # find all controllers that start with Foo
 619     my @foo_controllers = $c->controller(qr{^Foo});
 620
 621
 622 =cut
 623
 624 sub controller {
 625     my ( $c, $name, @args ) = @_;
 626
 627     my $appclass = ref($c) || $c;
 628     if( $name ) {
 629         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 630             my $comps = $c->components;
 631             my $check = $appclass."::Controller::".$name;
 632             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 633         }
 634         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 635         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 636         return $c->_filter_component( $result[ 0 ], @args );
 637     }
 638
 639     return $c->component( $c->action->class );
 640 }
 641
 642 =head2 $c->model($name)
 643
 644 Gets a L<Catalyst::Model> instance by name.
 645
 646     $c->model('Foo')->do_stuff;
 647
 648 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 649
 650 If the name is omitted, it will look for
 651  - a model object in $c->stash->{current_model_instance}, then
 652  - a model name in $c->stash->{current_model}, then
 653  - a config setting 'default_model', or
 654  - check if there is only one model, and return it if that's the case.
 655
 656 If you want to search for models, pass in a regexp as the argument.
 657
 658     # find all models that start with Foo
 659     my @foo_models = $c->model(qr{^Foo});
 660
 661 =cut
 662
 663 sub model {
 664     my ( $c, $name, @args ) = @_;
 665     my $appclass = ref($c) || $c;
 666     if( $name ) {
 667         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 668             my $comps = $c->components;
 669             my $check = $appclass."::Model::".$name;
 670             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 671         }
 672         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 673         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 674         return $c->_filter_component( $result[ 0 ], @args );
 675     }
 676
 677     if (ref $c) {
 678         return $c->stash->{current_model_instance}
 679           if $c->stash->{current_model_instance};
 680         return $c->model( $c->stash->{current_model} )
 681           if $c->stash->{current_model};
 682     }
 683     return $c->model( $appclass->config->{default_model} )
 684       if $appclass->config->{default_model};
 685
 686     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 687
 688     if( $rest ) {
 689         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 690         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 691         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 692         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 693         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 694     }
 695
 696     return $c->_filter_component( $comp );
 697 }
 698
 699
 700 =head2 $c->view($name)
 701
 702 Gets a L<Catalyst::View> instance by name.
 703
 704     $c->view('Foo')->do_stuff;
 705
 706 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 707
 708 If the name is omitted, it will look for
 709  - a view object in $c->stash->{current_view_instance}, then
 710  - a view name in $c->stash->{current_view}, then
 711  - a config setting 'default_view', or
 712  - check if there is only one view, and return it if that's the case.
 713
 714 If you want to search for views, pass in a regexp as the argument.
 715
 716     # find all views that start with Foo
 717     my @foo_views = $c->view(qr{^Foo});
 718
 719 =cut
 720
 721 sub view {
 722     my ( $c, $name, @args ) = @_;
 723
 724     my $appclass = ref($c) || $c;
 725     if( $name ) {
 726         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 727             my $comps = $c->components;
 728             my $check = $appclass."::View::".$name;
 729             if( exists $comps->{$check} ) {
 730                 return $c->_filter_component( $comps->{$check}, @args );
 731             }
 732             else {
 733                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 734             }
 735         }
 736         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 737         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 738         return $c->_filter_component( $result[ 0 ], @args );
 739     }
 740
 741     if (ref $c) {
 742         return $c->stash->{current_view_instance}
 743           if $c->stash->{current_view_instance};
 744         return $c->view( $c->stash->{current_view} )
 745           if $c->stash->{current_view};
 746     }
 747     return $c->view( $appclass->config->{default_view} )
 748       if $appclass->config->{default_view};
 749
 750     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 751
 752     if( $rest ) {
 753         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 754         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 755         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 756         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 757         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 758     }
 759
 760     return $c->_filter_component( $comp );
 761 }
 762
 763 =head2 $c->controllers
 764
 765 Returns the available names which can be passed to $c->controller
 766
 767 =cut
 768
 769 sub controllers {
 770     my ( $c ) = @_;
 771     return $c->_comp_names(qw/Controller C/);
 772 }
 773
 774 =head2 $c->models
 775
 776 Returns the available names which can be passed to $c->model
 777
 778 =cut
 779
 780 sub models {
 781     my ( $c ) = @_;
 782     return $c->_comp_names(qw/Model M/);
 783 }
 784
 785
 786 =head2 $c->views
 787
 788 Returns the available names which can be passed to $c->view
 789
 790 =cut
 791
 792 sub views {
 793     my ( $c ) = @_;
 794     return $c->_comp_names(qw/View V/);
 795 }
 796
 797 =head2 $c->comp($name)
 798
 799 =head2 $c->component($name)
 800
 801 Gets a component object by name. This method is not recommended,
 802 unless you want to get a specific component by full
 803 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 804 should be used instead.
 805
 806 If C<$name> is a regexp, a list of components matched against the full
 807 component name will be returned.
 808
 809 If Catalyst can't find a component by name, it will fallback to regex
 810 matching by default. To disable this behaviour set
 811 disable_component_resolution_regex_fallback to a true value.
 812
 813     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 814
 815 =cut
 816
 817 sub component {
 818     my ( $c, $name, @args ) = @_;
 819
 820     if( $name ) {
 821         my $comps = $c->components;
 822
 823         if( !ref $name ) {
 824             # is it the exact name?
 825             return $c->_filter_component( $comps->{ $name }, @args )
 826                        if exists $comps->{ $name };
 827
 828             # perhaps we just omitted "MyApp"?
 829             my $composed = ( ref $c || $c ) . "::${name}";
 830             return $c->_filter_component( $comps->{ $composed }, @args )
 831                        if exists $comps->{ $composed };
 832
 833             # search all of the models, views and controllers
 834             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 835             return $c->_filter_component( $comp, @args ) if $comp;
 836         }
 837
 838         return
 839             if $c->config->{disable_component_resolution_regex_fallback};
 840
 841         # This is here so $c->comp( '::M::' ) works
 842         my $query = ref $name ? $name : qr{$name}i;
 843
 844         my @result = grep { m{$query} } keys %{ $c->components };
 845         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 846
 847         if( $result[ 0 ] ) {
 848             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 849             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 850             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 851             return $c->_filter_component( $result[ 0 ], @args );
 852         }
 853
 854         # I would expect to return an empty list here, but that breaks back-compat
 855     }
 856
 857     # fallback
 858     return sort keys %{ $c->components };
 859 }
 860
 861 =head2 CLASS DATA AND HELPER CLASSES
 862
 863 =head2 $c->config
 864
 865 Returns or takes a hashref containing the application's configuration.
 866
 867     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 868
 869 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 870 like C<myapp.conf> in your applications home directory. See
 871 L<Catalyst::Plugin::ConfigLoader>.
 872
 873 =head3 Cascading configuration
 874
 875 The config method is present on all Catalyst components, and configuration
 876 will be merged when an application is started. Configuration loaded with
 877 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 878 followed by configuration in your top level C<MyApp> class. These two
 879 configurations are merged, and then configuration data whose hash key matches a
 880 component name is merged with configuration for that component.
 881
 882 The configuration for a component is then passed to the C<new> method when a
 883 component is constructed.
 884
 885 For example:
 886
 887     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 888     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 889
 890 will mean that C<MyApp::Model::Foo> receives the following data when
 891 constructed:
 892
 893     MyApp::Model::Foo->new({
 894         bar => 'baz',
 895         quux => 'frob',
 896         overrides => 'me',
 897     });
 898
 899 It's common practice to use a Moose attribute
 900 on the receiving component to access the config value.
 901
 902     package MyApp::Model::Foo;
 903
 904     use Moose;
 905
 906     # this attr will receive 'baz' at construction time
 907     has 'bar' => (
 908         is  => 'rw',
 909         isa => 'Str',
 910     );
 911
 912 You can then get the value 'baz' by calling $c->model('Foo')->bar
 913 (or $self->bar inside code in the model).
 914
 915 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 916 as a way of reading config within your code, as this B<will not> give you the
 917 correctly merged config back. You B<MUST> take the config values supplied to
 918 the constructor and use those instead.
 919
 920 =cut
 921
 922 around config => sub {
 923     my $orig = shift;
 924     my $c = shift;
 925
 926     croak('Setting config after setup has been run is not allowed.')
 927         if ( @_ and $c->setup_finished );
 928
 929     $c->$orig(@_);
 930 };
 931
 932 =head2 $c->log
 933
 934 Returns the logging object instance. Unless it is already set, Catalyst
 935 sets this up with a L<Catalyst::Log> object. To use your own log class,
 936 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 937 C<< __PACKAGE__->setup >>.
 938
 939  __PACKAGE__->log( MyLogger->new );
 940  __PACKAGE__->setup;
 941
 942 And later:
 943
 944     $c->log->info( 'Now logging with my own logger!' );
 945
 946 Your log class should implement the methods described in
 947 L<Catalyst::Log>.
 948
 949
 950 =head2 $c->debug
 951
 952 Returns 1 if debug mode is enabled, 0 otherwise.
 953
 954 You can enable debug mode in several ways:
 955
 956 =over
 957
 958 =item By calling myapp_server.pl with the -d flag
 959
 960 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 961
 962 =item The -Debug option in your MyApp.pm
 963
 964 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 965
 966 =back
 967
 968 The first three also set the log level to 'debug'.
 969
 970 Calling C<< $c->debug(1) >> has no effect.
 971
 972 =cut
 973
 974 sub debug { 0 }
 975
 976 =head2 $c->dispatcher
 977
 978 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 979
 980 =head2 $c->engine
 981
 982 Returns the engine instance. See L<Catalyst::Engine>.
 983
 984
 985 =head2 UTILITY METHODS
 986
 987 =head2 $c->path_to(@path)
 988
 989 Merges C<@path> with C<< $c->config->{home} >> and returns a
 990 L<Path::Class::Dir> object. Note you can usually use this object as
 991 a filename, but sometimes you will have to explicitly stringify it
 992 yourself by calling the C<< ->stringify >> method.
 993
 994 For example:
 995
 996     $c->path_to( 'db', 'sqlite.db' );
 997
 998 =cut
 999
1000 sub path_to {
1001     my ( $c, @path ) = @_;
1002     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1003     if ( -d $path ) { return $path }
1004     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1005 }
1006
1007 sub plugin {
1008     my ( $class, $name, $plugin, @args ) = @_;
1009
1010     # See block comment in t/unit_core_plugin.t
1011     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1012
1013     $class->_register_plugin( $plugin, 1 );
1014
1015     eval { $plugin->import };
1016     $class->mk_classdata($name);
1017     my $obj;
1018     eval { $obj = $plugin->new(@args) };
1019
1020     if ($@) {
1021         Catalyst::Exception->throw( message =>
1022               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1023     }
1024
1025     $class->$name($obj);
1026     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1027       if $class->debug;
1028 }
1029
1030 =head2 MyApp->setup
1031
1032 Initializes the dispatcher and engine, loads any plugins, and loads the
1033 model, view, and controller components. You may also specify an array
1034 of plugins to load here, if you choose to not load them in the C<use
1035 Catalyst> line.
1036
1037     MyApp->setup;
1038     MyApp->setup( qw/-Debug/ );
1039
1040 B<Note:> You B<should not> wrap this method with method modifiers
1041 or bad things will happen - wrap the C<setup_finalize> method instead.
1042
1043 =cut
1044
1045 sub setup {
1046     my ( $class, @arguments ) = @_;
1047     croak('Running setup more than once')
1048         if ( $class->setup_finished );
1049
1050     unless ( $class->isa('Catalyst') ) {
1051
1052         Catalyst::Exception->throw(
1053             message => qq/'$class' does not inherit from Catalyst/ );
1054     }
1055
1056     if ( $class->arguments ) {
1057         @arguments = ( @arguments, @{ $class->arguments } );
1058     }
1059
1060     # Process options
1061     my $flags = {};
1062
1063     foreach (@arguments) {
1064
1065         if (/^-Debug$/) {
1066             $flags->{log} =
1067               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1068         }
1069         elsif (/^-(\w+)=?(.*)$/) {
1070             $flags->{ lc $1 } = $2;
1071         }
1072         else {
1073             push @{ $flags->{plugins} }, $_;
1074         }
1075     }
1076
1077     $class->setup_home( delete $flags->{home} );
1078
1079     $class->setup_log( delete $flags->{log} );
1080     $class->setup_plugins( delete $flags->{plugins} );
1081     $class->setup_dispatcher( delete $flags->{dispatcher} );
1082     if (my $engine = delete $flags->{engine}) {
1083         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1084     }
1085     $class->setup_engine();
1086     $class->setup_stats( delete $flags->{stats} );
1087
1088     for my $flag ( sort keys %{$flags} ) {
1089
1090         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1091             &$code( $class, delete $flags->{$flag} );
1092         }
1093         else {
1094             $class->log->warn(qq/Unknown flag "$flag"/);
1095         }
1096     }
1097
1098     eval { require Catalyst::Devel; };
1099     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1100         $class->log->warn(<<"EOF");
1101 You are running an old script!
1102
1103   Please update by running (this will overwrite existing files):
1104     catalyst.pl -force -scripts $class
1105
1106   or (this will not overwrite existing files):
1107     catalyst.pl -scripts $class
1108
1109 EOF
1110     }
1111
1112     if ( $class->debug ) {
1113         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1114
1115         if (@plugins) {
1116             my $column_width = Catalyst::Utils::term_width() - 6;
1117             my $t = Text::SimpleTable->new($column_width);
1118             $t->row($_) for @plugins;
1119             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1120         }
1121
1122         my $dispatcher = $class->dispatcher;
1123         my $engine     = $class->engine;
1124         my $home       = $class->config->{home};
1125
1126         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1127         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1128
1129         $home
1130           ? ( -d $home )
1131           ? $class->log->debug(qq/Found home "$home"/)
1132           : $class->log->debug(qq/Home "$home" doesn't exist/)
1133           : $class->log->debug(q/Couldn't find home/);
1134     }
1135
1136     # Call plugins setup, this is stupid and evil.
1137     # Also screws C3 badly on 5.10, hack to avoid.
1138     {
1139         no warnings qw/redefine/;
1140         local *setup = sub { };
1141         $class->setup unless $Catalyst::__AM_RESTARTING;
1142     }
1143
1144     # Initialize our data structure
1145     $class->components( {} );
1146
1147     $class->setup_components;
1148
1149     if ( $class->debug ) {
1150         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1151         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1152         for my $comp ( sort keys %{ $class->components } ) {
1153             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1154             $t->row( $comp, $type );
1155         }
1156         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1157           if ( keys %{ $class->components } );
1158     }
1159
1160     # Add our self to components, since we are also a component
1161     if( $class->isa('Catalyst::Controller') ){
1162       $class->components->{$class} = $class;
1163     }
1164
1165     $class->setup_actions;
1166
1167     if ( $class->debug ) {
1168         my $name = $class->config->{name} || 'Application';
1169         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1170     }
1171
1172     # Make sure that the application class becomes immutable at this point,
1173     B::Hooks::EndOfScope::on_scope_end {
1174         return if $@;
1175         my $meta = Class::MOP::get_metaclass_by_name($class);
1176         if (
1177             $meta->is_immutable
1178             && ! { $meta->immutable_options }->{replace_constructor}
1179             && (
1180                    $class->isa('Class::Accessor::Fast')
1181                 || $class->isa('Class::Accessor')
1182             )
1183         ) {
1184             warn "You made your application class ($class) immutable, "
1185                 . "but did not inline the\nconstructor. "
1186                 . "This will break catalyst, as your app \@ISA "
1187                 . "Class::Accessor(::Fast)?\nPlease pass "
1188                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1189         }
1190         $meta->make_immutable(
1191             replace_constructor => 1,
1192         ) unless $meta->is_immutable;
1193     };
1194
1195     if ($class->config->{case_sensitive}) {
1196         $class->log->warn($class . "->config->{case_sensitive} is set.");
1197         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1198     }
1199
1200     $class->setup_finalize;
1201     # Should be the last thing we do so that user things hooking
1202     # setup_finalize can log..
1203     $class->log->_flush() if $class->log->can('_flush');
1204     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1205 }
1206
1207 =head2 $app->setup_finalize
1208
1209 A hook to attach modifiers to. This method does not do anything except set the
1210 C<setup_finished> accessor.
1211
1212 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1213
1214 Example:
1215
1216     after setup_finalize => sub {
1217         my $app = shift;
1218
1219         ## do stuff here..
1220     };
1221
1222 =cut
1223
1224 sub setup_finalize {
1225     my ($class) = @_;
1226     $class->setup_finished(1);
1227 }
1228
1229 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1230
1231 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1232
1233 Constructs an absolute L<URI> object based on the application root, the
1234 provided path, and the additional arguments and query parameters provided.
1235 When used as a string, provides a textual URI.  If you need more flexibility
1236 than this (i.e. the option to provide relative URIs etc.) see
1237 L<Catalyst::Plugin::SmartURI>.
1238
1239 If no arguments are provided, the URI for the current action is returned.
1240 To return the current action and also provide @args, use
1241 C<< $c->uri_for( $c->action, @args ) >>.
1242
1243 If the first argument is a string, it is taken as a public URI path relative
1244 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1245 relative to the application root (if it does). It is then merged with
1246 C<< $c->request->base >>; any C<@args> are appended as additional path
1247 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1248
1249 If the first argument is a L<Catalyst::Action> it represents an action which
1250 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1251 optional C<\@captures> argument (an arrayref) allows passing the captured
1252 variables that are needed to fill in the paths of Chained and Regex actions;
1253 once the path is resolved, C<uri_for> continues as though a path was
1254 provided, appending any arguments or parameters and creating an absolute
1255 URI.
1256
1257 The captures for the current request can be found in
1258 C<< $c->request->captures >>, and actions can be resolved using
1259 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1260 path, use C<< $c->uri_for_action >> instead.
1261
1262   # Equivalent to $c->req->uri
1263   $c->uri_for($c->action, $c->req->captures,
1264       @{ $c->req->args }, $c->req->params);
1265
1266   # For the Foo action in the Bar controller
1267   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1268
1269   # Path to a static resource
1270   $c->uri_for('/static/images/logo.png');
1271
1272 =cut
1273
1274 sub uri_for {
1275     my ( $c, $path, @args ) = @_;
1276
1277     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1278         $path = $path->path_prefix;
1279         $path =~ s{/+\z}{};
1280         $path .= '/';
1281     }
1282
1283     undef($path) if (defined $path && $path eq '');
1284
1285     my $params =
1286       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1287
1288     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1289     foreach my $arg (@args) {
1290         utf8::encode($arg) if utf8::is_utf8($arg);
1291         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1292     }
1293
1294     if ( blessed($path) ) { # action object
1295         s|/|%2F|g for @args;
1296         my $captures = [ map { s|/|%2F|g; $_; }
1297                         ( scalar @args && ref $args[0] eq 'ARRAY'
1298                          ? @{ shift(@args) }
1299                          : ()) ];
1300
1301         foreach my $capture (@$captures) {
1302             utf8::encode($capture) if utf8::is_utf8($capture);
1303             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1304         }
1305
1306         my $action = $path;
1307         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1308         if( !@args && $action->number_of_args ) {
1309             my $expanded_action = $c->dispatcher->expand_action( $action );
1310
1311             my $num_captures = $expanded_action->number_of_captures;
1312             unshift @args, splice @$captures, $num_captures;
1313         }
1314
1315        $path = $c->dispatcher->uri_for_action($action, $captures);
1316         if (not defined $path) {
1317             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1318                 if $c->debug;
1319             return undef;
1320         }
1321         $path = '/' if $path eq '';
1322     }
1323
1324     unshift(@args, $path);
1325
1326     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1327         my $namespace = $c->namespace;
1328         if (defined $path) { # cheesy hack to handle path '../foo'
1329            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1330         }
1331         unshift(@args, $namespace || '');
1332     }
1333
1334     # join args with '/', or a blank string
1335     my $args = join('/', grep { defined($_) } @args);
1336     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1337     $args =~ s!^/+!!;
1338     my $base = $c->req->base;
1339     my $class = ref($base);
1340     $base =~ s{(?<!/)$}{/};
1341
1342     my $query = '';
1343
1344     if (my @keys = keys %$params) {
1345       # somewhat lifted from URI::_query's query_form
1346       $query = '?'.join('&', map {
1347           my $val = $params->{$_};
1348           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1349           s/ /+/g;
1350           my $key = $_;
1351           $val = '' unless defined $val;
1352           (map {
1353               my $param = "$_";
1354               utf8::encode( $param ) if utf8::is_utf8($param);
1355               # using the URI::Escape pattern here so utf8 chars survive
1356               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1357               $param =~ s/ /+/g;
1358               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1359       } @keys);
1360     }
1361
1362     my $res = bless(\"${base}${args}${query}", $class);
1363     $res;
1364 }
1365
1366 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1367
1368 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1369
1370 =over
1371
1372 =item $path
1373
1374 A private path to the Catalyst action you want to create a URI for.
1375
1376 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1377 >> and passing the resulting C<$action> and the remaining arguments to C<<
1378 $c->uri_for >>.
1379
1380 You can also pass in a Catalyst::Action object, in which case it is passed to
1381 C<< $c->uri_for >>.
1382
1383 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1384
1385 For example, if the action looks like:
1386
1387  package MyApp::Controller::Users;
1388
1389  sub lst : Path('the-list') {}
1390
1391 You can use:
1392
1393  $c->uri_for_action('/users/lst')
1394
1395 and it will create the URI /users/the-list.
1396
1397 =item \@captures_and_args?
1398
1399 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1400 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1401 to interpolate all the parameters in the URI.
1402
1403 =item @args?
1404
1405 Optional list of extra arguments - can be supplied in the
1406 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1407 code.
1408
1409 Your action can have zero, a fixed or a variable number of args (e.g.
1410 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1411
1412 =item \%query_values?
1413
1414 Optional array reference of query parameters to append. E.g.
1415
1416   { foo => 'bar' }
1417
1418 will generate
1419
1420   /rest/of/your/uri?foo=bar
1421
1422 =back
1423
1424 =cut
1425
1426 sub uri_for_action {
1427     my ( $c, $path, @args ) = @_;
1428     my $action = blessed($path)
1429       ? $path
1430       : $c->dispatcher->get_action_by_path($path);
1431     unless (defined $action) {
1432       croak "Can't find action for path '$path'";
1433     }
1434     return $c->uri_for( $action, @args );
1435 }
1436
1437 =head2 $c->welcome_message
1438
1439 Returns the Catalyst welcome HTML page.
1440
1441 =cut
1442
1443 sub welcome_message {
1444     my $c      = shift;
1445     my $name   = $c->config->{name};
1446     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1447     my $prefix = Catalyst::Utils::appprefix( ref $c );
1448     $c->response->content_type('text/html; charset=utf-8');
1449     return <<"EOF";
1450 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1451     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1452 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1453     <head>
1454     <meta http-equiv="Content-Language" content="en" />
1455     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1456         <title>$name on Catalyst $VERSION</title>
1457         <style type="text/css">
1458             body {
1459                 color: #000;
1460                 background-color: #eee;
1461             }
1462             div#content {
1463                 width: 640px;
1464                 margin-left: auto;
1465                 margin-right: auto;
1466                 margin-top: 10px;
1467                 margin-bottom: 10px;
1468                 text-align: left;
1469                 background-color: #ccc;
1470                 border: 1px solid #aaa;
1471             }
1472             p, h1, h2 {
1473                 margin-left: 20px;
1474                 margin-right: 20px;
1475                 font-family: verdana, tahoma, sans-serif;
1476             }
1477             a {
1478                 font-family: verdana, tahoma, sans-serif;
1479             }
1480             :link, :visited {
1481                     text-decoration: none;
1482                     color: #b00;
1483                     border-bottom: 1px dotted #bbb;
1484             }
1485             :link:hover, :visited:hover {
1486                     color: #555;
1487             }
1488             div#topbar {
1489                 margin: 0px;
1490             }
1491             pre {
1492                 margin: 10px;
1493                 padding: 8px;
1494             }
1495             div#answers {
1496                 padding: 8px;
1497                 margin: 10px;
1498                 background-color: #fff;
1499                 border: 1px solid #aaa;
1500             }
1501             h1 {
1502                 font-size: 0.9em;
1503                 font-weight: normal;
1504                 text-align: center;
1505             }
1506             h2 {
1507                 font-size: 1.0em;
1508             }
1509             p {
1510                 font-size: 0.9em;
1511             }
1512             p img {
1513                 float: right;
1514                 margin-left: 10px;
1515             }
1516             span#appname {
1517                 font-weight: bold;
1518                 font-size: 1.6em;
1519             }
1520         </style>
1521     </head>
1522     <body>
1523         <div id="content">
1524             <div id="topbar">
1525                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1526                     $VERSION</h1>
1527              </div>
1528              <div id="answers">
1529                  <p>
1530                  <img src="$logo" alt="Catalyst Logo" />
1531                  </p>
1532                  <p>Welcome to the  world of Catalyst.
1533                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1534                     framework will make web development something you had
1535                     never expected it to be: Fun, rewarding, and quick.</p>
1536                  <h2>What to do now?</h2>
1537                  <p>That really depends  on what <b>you</b> want to do.
1538                     We do, however, provide you with a few starting points.</p>
1539                  <p>If you want to jump right into web development with Catalyst
1540                     you might want to start with a tutorial.</p>
1541 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1542 </pre>
1543 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1544 <pre>
1545 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1546 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1547 </code></pre>
1548                  <h2>What to do next?</h2>
1549                  <p>Next it's time to write an actual application. Use the
1550                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1551                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1552                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1553                     they can save you a lot of work.</p>
1554                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1555                     <p>Also, be sure to check out the vast and growing
1556                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1557                     you are likely to find what you need there.
1558                     </p>
1559
1560                  <h2>Need help?</h2>
1561                  <p>Catalyst has a very active community. Here are the main places to
1562                     get in touch with us.</p>
1563                  <ul>
1564                      <li>
1565                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1566                      </li>
1567                      <li>
1568                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1569                      </li>
1570                      <li>
1571                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1572                      </li>
1573                  </ul>
1574                  <h2>In conclusion</h2>
1575                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1576                     as we enjoyed making it. Please contact us if you have ideas
1577                     for improvement or other feedback.</p>
1578              </div>
1579          </div>
1580     </body>
1581 </html>
1582 EOF
1583 }
1584
1585 =head2 run_options
1586
1587 Contains a hash of options passed from the application script, including
1588 the original ARGV the script received, the processed values from that
1589 ARGV and any extra arguments to the script which were not processed.
1590
1591 This can be used to add custom options to your application's scripts
1592 and setup your application differently depending on the values of these
1593 options.
1594
1595 =head1 INTERNAL METHODS
1596
1597 These methods are not meant to be used by end users.
1598
1599 =head2 $c->components
1600
1601 Returns a hash of components.
1602
1603 =head2 $c->context_class
1604
1605 Returns or sets the context class.
1606
1607 =head2 $c->counter
1608
1609 Returns a hashref containing coderefs and execution counts (needed for
1610 deep recursion detection).
1611
1612 =head2 $c->depth
1613
1614 Returns the number of actions on the current internal execution stack.
1615
1616 =head2 $c->dispatch
1617
1618 Dispatches a request to actions.
1619
1620 =cut
1621
1622 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1623
1624 =head2 $c->dispatcher_class
1625
1626 Returns or sets the dispatcher class.
1627
1628 =head2 $c->dump_these
1629
1630 Returns a list of 2-element array references (name, structure) pairs
1631 that will be dumped on the error page in debug mode.
1632
1633 =cut
1634
1635 sub dump_these {
1636     my $c = shift;
1637     [ Request => $c->req ],
1638     [ Response => $c->res ],
1639     [ Stash => $c->stash ],
1640     [ Config => $c->config ];
1641 }
1642
1643 =head2 $c->engine_class
1644
1645 Returns or sets the engine class.
1646
1647 =head2 $c->execute( $class, $coderef )
1648
1649 Execute a coderef in given class and catch exceptions. Errors are available
1650 via $c->error.
1651
1652 =cut
1653
1654 sub execute {
1655     my ( $c, $class, $code ) = @_;
1656     $class = $c->component($class) || $class;
1657     $c->state(0);
1658
1659     if ( $c->depth >= $RECURSION ) {
1660         my $action = $code->reverse();
1661         $action = "/$action" unless $action =~ /->/;
1662         my $error = qq/Deep recursion detected calling "${action}"/;
1663         $c->log->error($error);
1664         $c->error($error);
1665         $c->state(0);
1666         return $c->state;
1667     }
1668
1669     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1670
1671     push( @{ $c->stack }, $code );
1672
1673     no warnings 'recursion';
1674     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1675     #      I have no idea how, ergo $ret (which appears to fix the issue)
1676     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1677
1678     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1679
1680     my $last = pop( @{ $c->stack } );
1681
1682     if ( my $error = $@ ) {
1683         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1684             $error->rethrow if $c->depth > 1;
1685         }
1686         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1687             $error->rethrow if $c->depth > 0;
1688         }
1689         else {
1690             unless ( ref $error ) {
1691                 no warnings 'uninitialized';
1692                 chomp $error;
1693                 my $class = $last->class;
1694                 my $name  = $last->name;
1695                 $error = qq/Caught exception in $class->$name "$error"/;
1696             }
1697             $c->error($error);
1698         }
1699         $c->state(0);
1700     }
1701     return $c->state;
1702 }
1703
1704 sub _stats_start_execute {
1705     my ( $c, $code ) = @_;
1706     my $appclass = ref($c) || $c;
1707     return if ( ( $code->name =~ /^_.*/ )
1708         && ( !$appclass->config->{show_internal_actions} ) );
1709
1710     my $action_name = $code->reverse();
1711     $c->counter->{$action_name}++;
1712
1713     my $action = $action_name;
1714     $action = "/$action" unless $action =~ /->/;
1715
1716     # determine if the call was the result of a forward
1717     # this is done by walking up the call stack and looking for a calling
1718     # sub of Catalyst::forward before the eval
1719     my $callsub = q{};
1720     for my $index ( 2 .. 11 ) {
1721         last
1722         if ( ( caller($index) )[0] eq 'Catalyst'
1723             && ( caller($index) )[3] eq '(eval)' );
1724
1725         if ( ( caller($index) )[3] =~ /forward$/ ) {
1726             $callsub = ( caller($index) )[3];
1727             $action  = "-> $action";
1728             last;
1729         }
1730     }
1731
1732     my $uid = $action_name . $c->counter->{$action_name};
1733
1734     # is this a root-level call or a forwarded call?
1735     if ( $callsub =~ /forward$/ ) {
1736         my $parent = $c->stack->[-1];
1737
1738         # forward, locate the caller
1739         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1740             $c->stats->profile(
1741                 begin  => $action,
1742                 parent => "$parent" . $c->counter->{"$parent"},
1743                 uid    => $uid,
1744             );
1745         }
1746         else {
1747
1748             # forward with no caller may come from a plugin
1749             $c->stats->profile(
1750                 begin => $action,
1751                 uid   => $uid,
1752             );
1753         }
1754     }
1755     else {
1756
1757         # root-level call
1758         $c->stats->profile(
1759             begin => $action,
1760             uid   => $uid,
1761         );
1762     }
1763     return $action;
1764
1765 }
1766
1767 sub _stats_finish_execute {
1768     my ( $c, $info ) = @_;
1769     $c->stats->profile( end => $info );
1770 }
1771
1772 =head2 $c->finalize
1773
1774 Finalizes the request.
1775
1776 =cut
1777
1778 sub finalize {
1779     my $c = shift;
1780
1781     for my $error ( @{ $c->error } ) {
1782         $c->log->error($error);
1783     }
1784
1785     # Allow engine to handle finalize flow (for POE)
1786     my $engine = $c->engine;
1787     if ( my $code = $engine->can('finalize') ) {
1788         $engine->$code($c);
1789     }
1790     else {
1791
1792         $c->finalize_uploads;
1793
1794         # Error
1795         if ( $#{ $c->error } >= 0 ) {
1796             $c->finalize_error;
1797         }
1798
1799         $c->finalize_headers;
1800
1801         # HEAD request
1802         if ( $c->request->method eq 'HEAD' ) {
1803             $c->response->body('');
1804         }
1805
1806         $c->finalize_body;
1807     }
1808
1809     $c->log_response;
1810
1811     if ($c->use_stats) {
1812         my $elapsed = sprintf '%f', $c->stats->elapsed;
1813         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1814         $c->log->info(
1815             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1816     }
1817
1818     return $c->response->status;
1819 }
1820
1821 =head2 $c->finalize_body
1822
1823 Finalizes body.
1824
1825 =cut
1826
1827 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1828
1829 =head2 $c->finalize_cookies
1830
1831 Finalizes cookies.
1832
1833 =cut
1834
1835 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1836
1837 =head2 $c->finalize_error
1838
1839 Finalizes error.
1840
1841 =cut
1842
1843 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1844
1845 =head2 $c->finalize_headers
1846
1847 Finalizes headers.
1848
1849 =cut
1850
1851 sub finalize_headers {
1852     my $c = shift;
1853
1854     my $response = $c->response; #accessor calls can add up?
1855
1856     # Check if we already finalized headers
1857     return if $response->finalized_headers;
1858
1859     # Handle redirects
1860     if ( my $location = $response->redirect ) {
1861         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1862         $response->header( Location => $location );
1863
1864         if ( !$response->has_body ) {
1865             # Add a default body if none is already present
1866             $response->body(<<"EOF");
1867 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1868 <html xmlns="http://www.w3.org/1999/xhtml">
1869   <head>
1870     <title>Moved</title>
1871   </head>
1872   <body>
1873      <p>This item has moved <a href="$location">here</a>.</p>
1874   </body>
1875 </html>
1876 EOF
1877             $response->content_type('text/html; charset=utf-8');
1878         }
1879     }
1880
1881     # Content-Length
1882     if ( defined $response->body && length $response->body && !$response->content_length ) {
1883
1884         # get the length from a filehandle
1885         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1886         {
1887             my $size = -s $response->body;
1888             if ( $size ) {
1889                 $response->content_length( $size );
1890             }
1891             else {
1892                 $c->log->warn('Serving filehandle without a content-length');
1893             }
1894         }
1895         else {
1896             # everything should be bytes at this point, but just in case
1897             $response->content_length( length( $response->body ) );
1898         }
1899     }
1900
1901     # Errors
1902     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1903         $response->headers->remove_header("Content-Length");
1904         $response->body('');
1905     }
1906
1907     $c->finalize_cookies;
1908
1909     $c->engine->finalize_headers( $c, @_ );
1910
1911     # Done
1912     $response->finalized_headers(1);
1913 }
1914
1915 =head2 $c->finalize_output
1916
1917 An alias for finalize_body.
1918
1919 =head2 $c->finalize_read
1920
1921 Finalizes the input after reading is complete.
1922
1923 =cut
1924
1925 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1926
1927 =head2 $c->finalize_uploads
1928
1929 Finalizes uploads. Cleans up any temporary files.
1930
1931 =cut
1932
1933 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1934
1935 =head2 $c->get_action( $action, $namespace )
1936
1937 Gets an action in a given namespace.
1938
1939 =cut
1940
1941 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1942
1943 =head2 $c->get_actions( $action, $namespace )
1944
1945 Gets all actions of a given name in a namespace and all parent
1946 namespaces.
1947
1948 =cut
1949
1950 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1951
1952 =head2 $app->handle_request( @arguments )
1953
1954 Called to handle each HTTP request.
1955
1956 =cut
1957
1958 sub handle_request {
1959     my ( $class, @arguments ) = @_;
1960
1961     # Always expect worst case!
1962     my $status = -1;
1963     try {
1964         if ($class->debug) {
1965             my $secs = time - $START || 1;
1966             my $av = sprintf '%.3f', $COUNT / $secs;
1967             my $time = localtime time;
1968             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1969         }
1970
1971         my $c = $class->prepare(@arguments);
1972         $c->dispatch;
1973         $status = $c->finalize;
1974     }
1975     catch {
1976         chomp(my $error = $_);
1977         $class->log->error(qq/Caught exception in engine "$error"/);
1978     };
1979
1980     $COUNT++;
1981
1982     if(my $coderef = $class->log->can('_flush')){
1983         $class->log->$coderef();
1984     }
1985     return $status;
1986 }
1987
1988 =head2 $class->prepare( @arguments )
1989
1990 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1991 etc.).
1992
1993 =cut
1994
1995 has _uploadtmp => (
1996     is => 'ro',
1997     predicate => '_has_uploadtmp',
1998 );
1999
2000 sub prepare {
2001     my ( $class, @arguments ) = @_;
2002
2003     # XXX
2004     # After the app/ctxt split, this should become an attribute based on something passed
2005     # into the application.
2006     $class->context_class( ref $class || $class ) unless $class->context_class;
2007
2008     my $uploadtmp = $class->config->{uploadtmp};
2009     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2010
2011     # For on-demand data
2012     $c->request->_context($c);
2013     $c->response->_context($c);
2014
2015     #surely this is not the most efficient way to do things...
2016     $c->stats($class->stats_class->new)->enable($c->use_stats);
2017     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2018         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2019     }
2020
2021     try {
2022         # Allow engine to direct the prepare flow (for POE)
2023         if ( my $prepare = $c->engine->can('prepare') ) {
2024             $c->engine->$prepare( $c, @arguments );
2025         }
2026         else {
2027             $c->prepare_request(@arguments);
2028             $c->prepare_connection;
2029             $c->prepare_query_parameters;
2030             $c->prepare_path;
2031
2032             # Prepare the body for reading, either by prepare_body
2033             # or the user, if they are using $c->read
2034             $c->prepare_read;
2035
2036             # Parse the body unless the user wants it on-demand
2037             unless ( ref($c)->config->{parse_on_demand} ) {
2038                 $c->prepare_body;
2039             }
2040         }
2041     }
2042     # VERY ugly and probably shouldn't rely on ->finalize actually working
2043     catch {
2044         # failed prepare is always due to an invalid request, right?
2045         $c->response->status(400);
2046         $c->response->content_type('text/plain');
2047         $c->response->body('Bad Request');
2048         $c->finalize;
2049         die $_;
2050     };
2051
2052     my $method  = $c->req->method  || '';
2053     my $path    = $c->req->path;
2054     $path       = '/' unless length $path;
2055     my $address = $c->req->address || '';
2056
2057     $c->log_request;
2058
2059     $c->prepare_action;
2060
2061     return $c;
2062 }
2063
2064 =head2 $c->prepare_action
2065
2066 Prepares action. See L<Catalyst::Dispatcher>.
2067
2068 =cut
2069
2070 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2071
2072 =head2 $c->prepare_body
2073
2074 Prepares message body.
2075
2076 =cut
2077
2078 sub prepare_body {
2079     my $c = shift;
2080
2081     return if $c->request->_has_body;
2082
2083     # Initialize on-demand data
2084     $c->engine->prepare_body( $c, @_ );
2085     $c->prepare_parameters;
2086     $c->prepare_uploads;
2087 }
2088
2089 =head2 $c->prepare_body_chunk( $chunk )
2090
2091 Prepares a chunk of data before sending it to L<HTTP::Body>.
2092
2093 See L<Catalyst::Engine>.
2094
2095 =cut
2096
2097 sub prepare_body_chunk {
2098     my $c = shift;
2099     $c->engine->prepare_body_chunk( $c, @_ );
2100 }
2101
2102 =head2 $c->prepare_body_parameters
2103
2104 Prepares body parameters.
2105
2106 =cut
2107
2108 sub prepare_body_parameters {
2109     my $c = shift;
2110     $c->engine->prepare_body_parameters( $c, @_ );
2111 }
2112
2113 =head2 $c->prepare_connection
2114
2115 Prepares connection.
2116
2117 =cut
2118
2119 sub prepare_connection {
2120     my $c = shift;
2121     $c->request->prepare_connection;
2122 }
2123
2124 =head2 $c->prepare_parameters
2125
2126 Prepares parameters.
2127
2128 =cut
2129
2130 sub prepare_parameters {
2131     my $c = shift;
2132     $c->prepare_body_parameters;
2133     $c->engine->prepare_parameters( $c, @_ );
2134 }
2135
2136 =head2 $c->prepare_path
2137
2138 Prepares path and base.
2139
2140 =cut
2141
2142 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2143
2144 =head2 $c->prepare_query_parameters
2145
2146 Prepares query parameters.
2147
2148 =cut
2149
2150 sub prepare_query_parameters {
2151     my $c = shift;
2152
2153     $c->engine->prepare_query_parameters( $c, @_ );
2154 }
2155
2156 =head2 $c->log_request
2157
2158 Writes information about the request to the debug logs.  This includes:
2159
2160 =over 4
2161
2162 =item * Request method, path, and remote IP address
2163
2164 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2165
2166 =item * Request parameters
2167
2168 =item * File uploads
2169
2170 =back
2171
2172 =cut
2173
2174 sub log_request {
2175     my $c = shift;
2176
2177     return unless $c->debug;
2178
2179     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2180     my $request = $dump->[1];
2181
2182     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2183     $method ||= '';
2184     $path = '/' unless length $path;
2185     $address ||= '';
2186     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2187
2188     $c->log_request_headers($request->headers);
2189
2190     if ( my $keywords = $request->query_keywords ) {
2191         $c->log->debug("Query keywords are: $keywords");
2192     }
2193
2194     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2195
2196     $c->log_request_uploads($request);
2197 }
2198
2199 =head2 $c->log_response
2200
2201 Writes information about the response to the debug logs by calling
2202 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2203
2204 =cut
2205
2206 sub log_response {
2207     my $c = shift;
2208
2209     return unless $c->debug;
2210
2211     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2212     my $response = $dump->[1];
2213
2214     $c->log_response_status_line($response);
2215     $c->log_response_headers($response->headers);
2216 }
2217
2218 =head2 $c->log_response_status_line($response)
2219
2220 Writes one line of information about the response to the debug logs.  This includes:
2221
2222 =over 4
2223
2224 =item * Response status code
2225
2226 =item * Content-Type header (if present)
2227
2228 =item * Content-Length header (if present)
2229
2230 =back
2231
2232 =cut
2233
2234 sub log_response_status_line {
2235     my ($c, $response) = @_;
2236
2237     $c->log->debug(
2238         sprintf(
2239             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2240             $response->status                            || 'unknown',
2241             $response->headers->header('Content-Type')   || 'unknown',
2242             $response->headers->header('Content-Length') || 'unknown'
2243         )
2244     );
2245 }
2246
2247 =head2 $c->log_response_headers($headers);
2248
2249 Hook method which can be wrapped by plugins to log the response headers.
2250 No-op in the default implementation.
2251
2252 =cut
2253
2254 sub log_response_headers {}
2255
2256 =head2 $c->log_request_parameters( query => {}, body => {} )
2257
2258 Logs request parameters to debug logs
2259
2260 =cut
2261
2262 sub log_request_parameters {
2263     my $c          = shift;
2264     my %all_params = @_;
2265
2266     return unless $c->debug;
2267
2268     my $column_width = Catalyst::Utils::term_width() - 44;
2269     foreach my $type (qw(query body)) {
2270         my $params = $all_params{$type};
2271         next if ! keys %$params;
2272         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2273         for my $key ( sort keys %$params ) {
2274             my $param = $params->{$key};
2275             my $value = defined($param) ? $param : '';
2276             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2277         }
2278         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2279     }
2280 }
2281
2282 =head2 $c->log_request_uploads
2283
2284 Logs file uploads included in the request to the debug logs.
2285 The parameter name, filename, file type, and file size are all included in
2286 the debug logs.
2287
2288 =cut
2289
2290 sub log_request_uploads {
2291     my $c = shift;
2292     my $request = shift;
2293     return unless $c->debug;
2294     my $uploads = $request->uploads;
2295     if ( keys %$uploads ) {
2296         my $t = Text::SimpleTable->new(
2297             [ 12, 'Parameter' ],
2298             [ 26, 'Filename' ],
2299             [ 18, 'Type' ],
2300             [ 9,  'Size' ]
2301         );
2302         for my $key ( sort keys %$uploads ) {
2303             my $upload = $uploads->{$key};
2304             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2305                 $t->row( $key, $u->filename, $u->type, $u->size );
2306             }
2307         }
2308         $c->log->debug( "File Uploads are:\n" . $t->draw );
2309     }
2310 }
2311
2312 =head2 $c->log_request_headers($headers);
2313
2314 Hook method which can be wrapped by plugins to log the request headers.
2315 No-op in the default implementation.
2316
2317 =cut
2318
2319 sub log_request_headers {}
2320
2321 =head2 $c->log_headers($type => $headers)
2322
2323 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2324
2325 =cut
2326
2327 sub log_headers {
2328     my $c       = shift;
2329     my $type    = shift;
2330     my $headers = shift;    # an HTTP::Headers instance
2331
2332     return unless $c->debug;
2333
2334     my $column_width = Catalyst::Utils::term_width() - 28;
2335     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2336     $headers->scan(
2337         sub {
2338             my ( $name, $value ) = @_;
2339             $t->row( $name, $value );
2340         }
2341     );
2342     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2343 }
2344
2345
2346 =head2 $c->prepare_read
2347
2348 Prepares the input for reading.
2349
2350 =cut
2351
2352 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2353
2354 =head2 $c->prepare_request
2355
2356 Prepares the engine request.
2357
2358 =cut
2359
2360 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2361
2362 =head2 $c->prepare_uploads
2363
2364 Prepares uploads.
2365
2366 =cut
2367
2368 sub prepare_uploads {
2369     my $c = shift;
2370
2371     $c->engine->prepare_uploads( $c, @_ );
2372 }
2373
2374 =head2 $c->prepare_write
2375
2376 Prepares the output for writing.
2377
2378 =cut
2379
2380 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2381
2382 =head2 $c->request_class
2383
2384 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2385
2386 =head2 $c->response_class
2387
2388 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2389
2390 =head2 $c->read( [$maxlength] )
2391
2392 Reads a chunk of data from the request body. This method is designed to
2393 be used in a while loop, reading C<$maxlength> bytes on every call.
2394 C<$maxlength> defaults to the size of the request if not specified.
2395
2396 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2397 directly.
2398
2399 Warning: If you use read(), Catalyst will not process the body,
2400 so you will not be able to access POST parameters or file uploads via
2401 $c->request.  You must handle all body parsing yourself.
2402
2403 =cut
2404
2405 sub read { my $c = shift; return $c->request->read( @_ ) }
2406
2407 =head2 $c->run
2408
2409 Starts the engine.
2410
2411 =cut
2412
2413 sub run {
2414   my $app = shift;
2415   $app->engine_loader->needs_psgi_engine_compat_hack ?
2416     $app->engine->run($app, @_) :
2417       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2418 }
2419
2420 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2421
2422 Sets an action in a given namespace.
2423
2424 =cut
2425
2426 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2427
2428 =head2 $c->setup_actions($component)
2429
2430 Sets up actions for a component.
2431
2432 =cut
2433
2434 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2435
2436 =head2 $c->setup_components
2437
2438 This method is called internally to set up the application's components.
2439
2440 It finds modules by calling the L<locate_components> method, expands them to
2441 package names with the L<expand_component_module> method, and then installs
2442 each component into the application.
2443
2444 The C<setup_components> config option is passed to both of the above methods.
2445
2446 Installation of each component is performed by the L<setup_component> method,
2447 below.
2448
2449 =cut
2450
2451 sub setup_components {
2452     my $class = shift;
2453
2454     my $config  = $class->config->{ setup_components };
2455
2456     my @comps = $class->locate_components($config);
2457     my %comps = map { $_ => 1 } @comps;
2458
2459     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2460     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2461         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2462     ) if $deprecatedcatalyst_component_names;
2463
2464     for my $component ( @comps ) {
2465
2466         # We pass ignore_loaded here so that overlay files for (e.g.)
2467         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2468         # we know M::P::O found a file on disk so this is safe
2469
2470         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2471     }
2472
2473     for my $component (@comps) {
2474         my $instance = $class->components->{ $component } = $class->setup_component($component);
2475         my @expanded_components = $instance->can('expand_modules')
2476             ? $instance->expand_modules( $component, $config )
2477             : $class->expand_component_module( $component, $config );
2478         for my $component (@expanded_components) {
2479             next if $comps{$component};
2480             $class->components->{ $component } = $class->setup_component($component);
2481         }
2482     }
2483 }
2484
2485 =head2 $c->locate_components( $setup_component_config )
2486
2487 This method is meant to provide a list of component modules that should be
2488 setup for the application.  By default, it will use L<Module::Pluggable>.
2489
2490 Specify a C<setup_components> config option to pass additional options directly
2491 to L<Module::Pluggable>. To add additional search paths, specify a key named
2492 C<search_extra> as an array reference. Items in the array beginning with C<::>
2493 will have the application class name prepended to them.
2494
2495 =cut
2496
2497 sub locate_components {
2498     my $class  = shift;
2499     my $config = shift;
2500
2501     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2502     my $extra   = delete $config->{ search_extra } || [];
2503
2504     push @paths, @$extra;
2505
2506     my $locator = Module::Pluggable::Object->new(
2507         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2508         %$config
2509     );
2510
2511     # XXX think about ditching this sort entirely
2512     my @comps = sort { length $a <=> length $b } $locator->plugins;
2513
2514     return @comps;
2515 }
2516
2517 =head2 $c->expand_component_module( $component, $setup_component_config )
2518
2519 Components found by C<locate_components> will be passed to this method, which
2520 is expected to return a list of component (package) names to be set up.
2521
2522 =cut
2523
2524 sub expand_component_module {
2525     my ($class, $module) = @_;
2526     return Devel::InnerPackage::list_packages( $module );
2527 }
2528
2529 =head2 $c->setup_component
2530
2531 =cut
2532
2533 sub setup_component {
2534     my( $class, $component ) = @_;
2535
2536     unless ( $component->can( 'COMPONENT' ) ) {
2537         return $component;
2538     }
2539
2540     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2541     my $config = $class->config->{ $suffix } || {};
2542     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2543     # methods also pass it. local to avoid pointlessly shitting in config
2544     # for the debug screen, as $component is already the key name.
2545     local $config->{catalyst_component_name} = $component;
2546
2547     my $instance = eval { $component->COMPONENT( $class, $config ); };
2548
2549     if ( my $error = $@ ) {
2550         chomp $error;
2551         Catalyst::Exception->throw(
2552             message => qq/Couldn't instantiate component "$component", "$error"/
2553         );
2554     }
2555
2556     unless (blessed $instance) {
2557         my $metaclass = Moose::Util::find_meta($component);
2558         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2559         my $component_method_from = $method_meta->associated_metaclass->name;
2560         my $value = defined($instance) ? $instance : 'undef';
2561         Catalyst::Exception->throw(
2562             message =>
2563             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2564         );
2565     }
2566     return $instance;
2567 }
2568
2569 =head2 $c->setup_dispatcher
2570
2571 Sets up dispatcher.
2572
2573 =cut
2574
2575 sub setup_dispatcher {
2576     my ( $class, $dispatcher ) = @_;
2577
2578     if ($dispatcher) {
2579         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2580     }
2581
2582     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2583         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2584     }
2585
2586     unless ($dispatcher) {
2587         $dispatcher = $class->dispatcher_class;
2588     }
2589
2590     Class::MOP::load_class($dispatcher);
2591
2592     # dispatcher instance
2593     $class->dispatcher( $dispatcher->new );
2594 }
2595
2596 =head2 $c->setup_engine
2597
2598 Sets up engine.
2599
2600 =cut
2601
2602 sub engine_class {
2603     my ($class, $requested_engine) = @_;
2604
2605     if (!$class->engine_loader || $requested_engine) {
2606         $class->engine_loader(
2607             Catalyst::EngineLoader->new({
2608                 application_name => $class,
2609                 (defined $requested_engine
2610                      ? (catalyst_engine_class => $requested_engine) : ()),
2611             }),
2612         );
2613     }
2614
2615     $class->engine_loader->catalyst_engine_class;
2616 }
2617
2618 sub setup_engine {
2619     my ($class, $requested_engine) = @_;
2620
2621     my $engine = do {
2622         my $loader = $class->engine_loader;
2623
2624         if (!$loader || $requested_engine) {
2625             $loader = Catalyst::EngineLoader->new({
2626                 application_name => $class,
2627                 (defined $requested_engine
2628                      ? (requested_engine => $requested_engine) : ()),
2629             }),
2630
2631             $class->engine_loader($loader);
2632         }
2633
2634         $loader->catalyst_engine_class;
2635     };
2636
2637     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2638     return if $class->loading_psgi_file;
2639
2640     Class::MOP::load_class($engine);
2641
2642     if ($ENV{MOD_PERL}) {
2643         my $apache = $class->engine_loader->auto;
2644
2645         my $meta = find_meta($class);
2646         my $was_immutable = $meta->is_immutable;
2647         my %immutable_options = $meta->immutable_options;
2648         $meta->make_mutable if $was_immutable;
2649
2650         $meta->add_method(handler => sub {
2651             my $r = shift;
2652             my $psgi_app = $class->_finalized_psgi_app;
2653             $apache->call_app($r, $psgi_app);
2654         });
2655
2656         $meta->make_immutable(%immutable_options) if $was_immutable;
2657     }
2658
2659     $class->engine( $engine->new );
2660
2661     return;
2662 }
2663
2664 sub _finalized_psgi_app {
2665     my ($app) = @_;
2666
2667     unless ($app->_psgi_app) {
2668         my $psgi_app = $app->_setup_psgi_app;
2669         $app->_psgi_app($psgi_app);
2670     }
2671
2672     return $app->_psgi_app;
2673 }
2674
2675 sub _setup_psgi_app {
2676     my ($app) = @_;
2677
2678     for my $home (Path::Class::Dir->new($app->config->{home})) {
2679         my $psgi_file = $home->file(
2680             Catalyst::Utils::appprefix($app) . '.psgi',
2681         );
2682
2683         next unless -e $psgi_file;
2684
2685         # If $psgi_file calls ->setup_engine, it's doing so to load
2686         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2687         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2688         # anyway. So set a flag (ick) that tells setup_engine not to populate
2689         # $c->engine or do any other things we might regret.
2690
2691         $app->loading_psgi_file(1);
2692         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2693         $app->loading_psgi_file(0);
2694
2695         return $psgi_app
2696             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2697
2698         warn <<"EOW";
2699 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2700
2701 Its content has been ignored. Please consult the Catalyst::Upgrading
2702 documentation on how to upgrade from Catalyst::Engine::PSGI.
2703 EOW
2704     }
2705
2706     return $app->apply_default_middlewares($app->psgi_app);
2707 }
2708
2709 =head2 $c->apply_default_middlewares
2710
2711 Adds the following L<Plack> middlewares to your application, since they are
2712 useful and commonly needed:
2713
2714 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2715 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2716 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2717 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2718 applied since this middleware is smart enough to conditionally apply itself).
2719
2720 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2721 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2722 $ENV{SCRIPT_NAME}
2723
2724 =cut
2725
2726
2727 sub apply_default_middlewares {
2728     my ($app, $psgi_app) = @_;
2729
2730     $psgi_app = Plack::Middleware::Conditional->wrap(
2731         $psgi_app,
2732         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2733         condition => sub {
2734             my ($env) = @_;
2735             return if $app->config->{ignore_frontend_proxy};
2736             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2737                 || $app->config->{using_frontend_proxy};
2738         },
2739     );
2740
2741     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2742     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2743     $psgi_app = Plack::Middleware::LighttpdScriptNameFix->wrap($psgi_app);
2744
2745     # we're applying this unconditionally as the middleware itself already makes
2746     # sure it doesn't fuck things up if it's not running under one of the right
2747     # IIS versions
2748     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2749
2750     return $psgi_app;
2751 }
2752
2753 =head2 $c->psgi_app
2754
2755 Returns a PSGI application code reference for the catalyst application
2756 C<$c>. This is the bare application without any middlewares
2757 applied. C<${myapp}.psgi> is not taken into account.
2758
2759 This is what you want to be using to retrieve the PSGI application code
2760 reference of your Catalyst application for use in F<.psgi> files.
2761
2762 =cut
2763
2764 sub psgi_app {
2765     my ($app) = @_;
2766     return $app->engine->build_psgi_app($app);
2767 }
2768
2769 =head2 $c->setup_home
2770
2771 Sets up the home directory.
2772
2773 =cut
2774
2775 sub setup_home {
2776     my ( $class, $home ) = @_;
2777
2778     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2779         $home = $env;
2780     }
2781
2782     $home ||= Catalyst::Utils::home($class);
2783
2784     if ($home) {
2785         #I remember recently being scolded for assigning config values like this
2786         $class->config->{home} ||= $home;
2787         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2788     }
2789 }
2790
2791 =head2 $c->setup_log
2792
2793 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2794 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2795 log to.
2796
2797 This method also installs a C<debug> method that returns a true value into the
2798 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2799 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2800
2801 Note that if the log has already been setup, by either a previous call to
2802 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2803 that this method won't actually set up the log object.
2804
2805 =cut
2806
2807 sub setup_log {
2808     my ( $class, $levels ) = @_;
2809
2810     $levels ||= '';
2811     $levels =~ s/^\s+//;
2812     $levels =~ s/\s+$//;
2813     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2814
2815     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2816     if ( defined $env_debug ) {
2817         $levels{debug} = 1 if $env_debug; # Ugly!
2818         delete($levels{debug}) unless $env_debug;
2819     }
2820
2821     unless ( $class->log ) {
2822         $class->log( Catalyst::Log->new(keys %levels) );
2823     }
2824
2825     if ( $levels{debug} ) {
2826         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2827         $class->log->debug('Debug messages enabled');
2828     }
2829 }
2830
2831 =head2 $c->setup_plugins
2832
2833 Sets up plugins.
2834
2835 =cut
2836
2837 =head2 $c->setup_stats
2838
2839 Sets up timing statistics class.
2840
2841 =cut
2842
2843 sub setup_stats {
2844     my ( $class, $stats ) = @_;
2845
2846     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2847
2848     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2849     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2850         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2851         $class->log->debug('Statistics enabled');
2852     }
2853 }
2854
2855
2856 =head2 $c->registered_plugins
2857
2858 Returns a sorted list of the plugins which have either been stated in the
2859 import list.
2860
2861 If passed a given plugin name, it will report a boolean value indicating
2862 whether or not that plugin is loaded.  A fully qualified name is required if
2863 the plugin name does not begin with C<Catalyst::Plugin::>.
2864
2865  if ($c->registered_plugins('Some::Plugin')) {
2866      ...
2867  }
2868
2869 =cut
2870
2871 {
2872
2873     sub registered_plugins {
2874         my $proto = shift;
2875         return sort keys %{ $proto->_plugins } unless @_;
2876         my $plugin = shift;
2877         return 1 if exists $proto->_plugins->{$plugin};
2878         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2879     }
2880
2881     sub _register_plugin {
2882         my ( $proto, $plugin, $instant ) = @_;
2883         my $class = ref $proto || $proto;
2884
2885         Class::MOP::load_class( $plugin );
2886         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2887             if $plugin->isa( 'Catalyst::Component' );
2888         $proto->_plugins->{$plugin} = 1;
2889         unless ($instant) {
2890             my $meta = Class::MOP::get_metaclass_by_name($class);
2891             $meta->superclasses($plugin, $meta->superclasses);
2892         }
2893         return $class;
2894     }
2895
2896     sub setup_plugins {
2897         my ( $class, $plugins ) = @_;
2898
2899         $class->_plugins( {} ) unless $class->_plugins;
2900         $plugins = Data::OptList::mkopt($plugins || []);
2901
2902         my @plugins = map {
2903             [ Catalyst::Utils::resolve_namespace(
2904                   $class . '::Plugin',
2905                   'Catalyst::Plugin', $_->[0]
2906               ),
2907               $_->[1],
2908             ]
2909          } @{ $plugins };
2910
2911         for my $plugin ( reverse @plugins ) {
2912             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2913             my $meta = find_meta($plugin->[0]);
2914             next if $meta && $meta->isa('Moose::Meta::Role');
2915
2916             $class->_register_plugin($plugin->[0]);
2917         }
2918
2919         my @roles =
2920             map  { $_->[0]->name, $_->[1] }
2921             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2922             map  { [find_meta($_->[0]), $_->[1]] }
2923             @plugins;
2924
2925         Moose::Util::apply_all_roles(
2926             $class => @roles
2927         ) if @roles;
2928     }
2929 }
2930
2931 =head2 $c->stack
2932
2933 Returns an arrayref of the internal execution stack (actions that are
2934 currently executing).
2935
2936 =head2 $c->stats
2937
2938 Returns the current timing statistics object. By default Catalyst uses
2939 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2940 L<< stats_class|/"$c->stats_class" >>.
2941
2942 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2943 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2944 profile explicitly, although MyApp.pm still won't profile nor output anything
2945 by itself.
2946
2947 =head2 $c->stats_class
2948
2949 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2950
2951 =head2 $c->use_stats
2952
2953 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2954
2955 Note that this is a static method, not an accessor and should be overridden
2956 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2957
2958 =cut
2959
2960 sub use_stats { 0 }
2961
2962
2963 =head2 $c->write( $data )
2964
2965 Writes $data to the output stream. When using this method directly, you
2966 will need to manually set the C<Content-Length> header to the length of
2967 your output data, if known.
2968
2969 =cut
2970
2971 sub write {
2972     my $c = shift;
2973
2974     # Finalize headers if someone manually writes output
2975     $c->finalize_headers;
2976
2977     return $c->engine->write( $c, @_ );
2978 }
2979
2980 =head2 version
2981
2982 Returns the Catalyst version number. Mostly useful for "powered by"
2983 messages in template systems.
2984
2985 =cut
2986
2987 sub version { return $Catalyst::VERSION }
2988
2989 =head1 CONFIGURATION
2990
2991 There are a number of 'base' config variables which can be set:
2992
2993 =over
2994
2995 =item *
2996
2997 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2998
2999 =item *
3000
3001 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3002
3003 =item *
3004
3005 C<disable_component_resolution_regex_fallback> - Turns
3006 off the deprecated component resolution functionality so
3007 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3008 are called then regex search will not be attempted on string values and
3009 instead C<undef> will be returned.
3010
3011 =item *
3012
3013 C<home> - The application home directory. In an uninstalled application,
3014 this is the top level application directory. In an installed application,
3015 this will be the directory containing C<< MyApp.pm >>.
3016
3017 =item *
3018
3019 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3020
3021 =item *
3022
3023 C<name> - The name of the application in debug messages and the debug and
3024 welcome screens
3025
3026 =item *
3027
3028 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3029 until it is accessed. This allows you to (for example) check authentication (and reject
3030 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3031
3032 =item *
3033
3034 C<root> - The root directory for templates. Usually this is just a
3035 subdirectory of the home directory, but you can set it to change the
3036 templates to a different directory.
3037
3038 =item *
3039
3040 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3041 namespaces from which components will be loaded (and constructed and stored in
3042 C<< $c->components >>).
3043
3044 =item *
3045
3046 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3047 to be shown in hit debug tables in the test server.
3048
3049 =item *
3050
3051 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3052 variable should be used for determining the request path.
3053
3054 Most web server environments pass the requested path to the application using environment variables,
3055 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3056 exposed as C<< $c->request->base >>) and the request path below that base.
3057
3058 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3059 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3060
3061 =over
3062
3063 =item use_request_uri_for_path => 0
3064
3065 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3066 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3067 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3068 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3069
3070 However this method has the major disadvantage that it is impossible to correctly decode some elements
3071 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3072 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3073 can't distinguish / vs %2F in paths (in addition to other encoded values).
3074
3075 =item use_request_uri_for_path => 1
3076
3077 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3078 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3079 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3080
3081 Given that this method of path resolution is provably more correct, it is recommended that you use
3082 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3083 aware of the implications of not being able to handle encoded URI paths correctly.
3084
3085 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3086 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3087 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3088 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3089 C<< $c->request->base >> will be incorrect.
3090
3091 =back
3092
3093 =item *
3094
3095 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3096
3097 =back
3098
3099 =head1 INTERNAL ACTIONS
3100
3101 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3102 C<_ACTION>, and C<_END>. These are by default not shown in the private
3103 action table, but you can make them visible with a config parameter.
3104
3105     MyApp->config(show_internal_actions => 1);
3106
3107 =head1 ON-DEMAND PARSER
3108
3109 The request body is usually parsed at the beginning of a request,
3110 but if you want to handle input yourself, you can enable on-demand
3111 parsing with a config parameter.
3112
3113     MyApp->config(parse_on_demand => 1);
3114
3115 =head1 PROXY SUPPORT
3116
3117 Many production servers operate using the common double-server approach,
3118 with a lightweight frontend web server passing requests to a larger
3119 backend server. An application running on the backend server must deal
3120 with two problems: the remote user always appears to be C<127.0.0.1> and
3121 the server's hostname will appear to be C<localhost> regardless of the
3122 virtual host that the user connected through.
3123
3124 Catalyst will automatically detect this situation when you are running
3125 the frontend and backend servers on the same machine. The following
3126 changes are made to the request.
3127
3128     $c->req->address is set to the user's real IP address, as read from
3129     the HTTP X-Forwarded-For header.
3130
3131     The host value for $c->req->base and $c->req->uri is set to the real
3132     host, as read from the HTTP X-Forwarded-Host header.
3133
3134 Additionally, you may be running your backend application on an insecure
3135 connection (port 80) while your frontend proxy is running under SSL.  If there
3136 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3137 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3138 be created properly.
3139
3140 In the case of passing in:
3141
3142     X-Forwarded-Port: 443
3143
3144 All calls to C<uri_for> will result in an https link, as is expected.
3145
3146 Obviously, your web server must support these headers for this to work.
3147
3148 In a more complex server farm environment where you may have your
3149 frontend proxy server(s) on different machines, you will need to set a
3150 configuration option to tell Catalyst to read the proxied data from the
3151 headers.
3152
3153     MyApp->config(using_frontend_proxy => 1);
3154
3155 If you do not wish to use the proxy support at all, you may set:
3156
3157     MyApp->config(ignore_frontend_proxy => 0);
3158
3159 =head2 Note about psgi files
3160
3161 Note that if you supply your own .psgi file, calling
3162 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3163
3164 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3165 in your psgi, for example:
3166
3167     builder {
3168         enable "Plack::Middleware::ReverseProxy";
3169         MyApp->psgi_app
3170     };
3171
3172 This will unconditionally add the ReverseProxy support, or you need to call
3173 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3174 apply the support depending upon your config).
3175
3176 See L<Catalyst::PSGI> for more information.
3177
3178 =head1 THREAD SAFETY
3179
3180 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3181 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3182 believe the Catalyst core to be thread-safe.
3183
3184 If you plan to operate in a threaded environment, remember that all other
3185 modules you are using must also be thread-safe. Some modules, most notably
3186 L<DBD::SQLite>, are not thread-safe.
3187
3188 =head1 SUPPORT
3189
3190 IRC:
3191
3192     Join #catalyst on irc.perl.org.
3193
3194 Mailing Lists:
3195
3196     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3197     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3198
3199 Web:
3200
3201     http://catalyst.perl.org
3202
3203 Wiki:
3204
3205     http://dev.catalyst.perl.org
3206
3207 =head1 SEE ALSO
3208
3209 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3210
3211 =head2 L<Catalyst::Manual> - The Catalyst Manual
3212
3213 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3214
3215 =head2 L<Catalyst::Engine> - Core engine
3216
3217 =head2 L<Catalyst::Log> - Log class.
3218
3219 =head2 L<Catalyst::Request> - Request object
3220
3221 =head2 L<Catalyst::Response> - Response object
3222
3223 =head2 L<Catalyst::Test> - The test suite.
3224
3225 =begin stopwords
3226
3227 =head1 PROJECT FOUNDER
3228
3229 sri: Sebastian Riedel <sri@cpan.org>
3230
3231 =head1 CONTRIBUTORS
3232
3233 abw: Andy Wardley
3234
3235 acme: Leon Brocard <leon@astray.com>
3236
3237 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3238
3239 Andrew Bramble
3240
3241 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3242
3243 Andrew Ruthven
3244
3245 andyg: Andy Grundman <andy@hybridized.org>
3246
3247 audreyt: Audrey Tang
3248
3249 bricas: Brian Cassidy <bricas@cpan.org>
3250
3251 Caelum: Rafael Kitover <rkitover@io.com>
3252
3253 chansen: Christian Hansen
3254
3255 chicks: Christopher Hicks
3256
3257 Chisel Wright C<pause@herlpacker.co.uk>
3258
3259 Danijel Milicevic C<me@danijel.de>
3260
3261 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3262
3263 David Naughton, C<naughton@umn.edu>
3264
3265 David E. Wheeler
3266
3267 dhoss: Devin Austin <dhoss@cpan.org>
3268
3269 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3270
3271 Drew Taylor
3272
3273 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3274
3275 esskar: Sascha Kiefer
3276
3277 fireartist: Carl Franks <cfranks@cpan.org>
3278
3279 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3280
3281 gabb: Danijel Milicevic
3282
3283 Gary Ashton Jones
3284
3285 Gavin Henry C<ghenry@perl.me.uk>
3286
3287 Geoff Richards
3288
3289 groditi: Guillermo Roditi <groditi@gmail.com>
3290
3291 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3292
3293 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3294
3295 jcamacho: Juan Camacho
3296
3297 jester: Jesse Sheidlower C<jester@panix.com>
3298
3299 jhannah: Jay Hannah <jay@jays.net>
3300
3301 Jody Belka
3302
3303 Johan Lindstrom
3304
3305 jon: Jon Schutz <jjschutz@cpan.org>
3306
3307 Jonathan Rockway C<< <jrockway@cpan.org> >>
3308
3309 Kieren Diment C<kd@totaldatasolution.com>
3310
3311 konobi: Scott McWhirter <konobi@cpan.org>
3312
3313 marcus: Marcus Ramberg <mramberg@cpan.org>
3314
3315 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3316
3317 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3318
3319 mugwump: Sam Vilain
3320
3321 naughton: David Naughton
3322
3323 ningu: David Kamholz <dkamholz@cpan.org>
3324
3325 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3326
3327 numa: Dan Sully <daniel@cpan.org>
3328
3329 obra: Jesse Vincent
3330
3331 Octavian Rasnita
3332
3333 omega: Andreas Marienborg
3334
3335 Oleg Kostyuk <cub.uanic@gmail.com>
3336
3337 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3338
3339 rafl: Florian Ragwitz <rafl@debian.org>
3340
3341 random: Roland Lammel <lammel@cpan.org>
3342
3343 Robert Sedlacek C<< <rs@474.at> >>
3344
3345 SpiceMan: Marcel Montes
3346
3347 sky: Arthur Bergman
3348
3349 szbalint: Balint Szilakszi <szbalint@cpan.org>
3350
3351 t0m: Tomas Doran <bobtfish@bobtfish.net>
3352
3353 Ulf Edvinsson
3354
3355 Viljo Marrandi C<vilts@yahoo.com>
3356
3357 Will Hawes C<info@whawes.co.uk>
3358
3359 willert: Sebastian Willert <willert@cpan.org>
3360
3361 wreis: Wallace Reis <wallace@reis.org.br>
3362
3363 Yuval Kogman, C<nothingmuch@woobling.org>
3364
3365 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3366
3367 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3368
3369 =end stopwords
3370
3371 =head1 COPYRIGHT
3372
3373 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3374
3375 =head1 LICENSE
3376
3377 This library is free software. You can redistribute it and/or modify it under
3378 the same terms as Perl itself.
3379
3380 =cut
3381
3382 no Moose;
3383
3384 __PACKAGE__->meta->make_immutable;
3385
3386 1;