lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use UNIVERSAL::require;
   7 use Catalyst::Exception;
   8 use Catalyst::Log;
   9 use Catalyst::Request;
  10 use Catalyst::Request::Upload;
  11 use Catalyst::Response;
  12 use Catalyst::Utils;
  13 use Catalyst::Controller;
  14 use File::stat;
  15 use NEXT;
  16 use Text::SimpleTable;
  17 use Path::Class::Dir;
  18 use Path::Class::File;
  19 use Time::HiRes qw/gettimeofday tv_interval/;
  20 use URI;
  21 use Scalar::Util qw/weaken blessed/;
  22 use Tree::Simple qw/use_weak_refs/;
  23 use Tree::Simple::Visitor::FindByUID;
  24 use attributes;
  25 use utf8;
  26 use Carp qw/croak/;
  27
  28 __PACKAGE__->mk_accessors(
  29     qw/counter request response state action stack namespace stats/
  30 );
  31
  32 attributes->import( __PACKAGE__, \&namespace, 'lvalue' );
  33
  34 sub depth { scalar @{ shift->stack || [] }; }
  35
  36 # Laziness++
  37 *comp = \&component;
  38 *req  = \&request;
  39 *res  = \&response;
  40
  41 # For backwards compatibility
  42 *finalize_output = \&finalize_body;
  43
  44 # For statistics
  45 our $COUNT     = 1;
  46 our $START     = time;
  47 our $RECURSION = 1000;
  48 our $DETACH    = "catalyst_detach\n";
  49
  50 require Module::Pluggable::Fast;
  51
  52 # Helper script generation
  53 our $CATALYST_SCRIPT_GEN = 27;
  54
  55 __PACKAGE__->mk_classdata($_)
  56   for qw/components arguments dispatcher engine log dispatcher_class
  57   engine_class context_class request_class response_class setup_finished/;
  58
  59 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  60 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  61 __PACKAGE__->request_class('Catalyst::Request');
  62 __PACKAGE__->response_class('Catalyst::Response');
  63
  64 our $VERSION = '5.6902';
  65
  66 sub import {
  67     my ( $class, @arguments ) = @_;
  68
  69     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  70     # callers @ISA.
  71     return unless $class eq 'Catalyst';
  72
  73     my $caller = caller(0);
  74
  75     unless ( $caller->isa('Catalyst') ) {
  76         no strict 'refs';
  77         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  78     }
  79
  80     $caller->arguments( [@arguments] );
  81     $caller->setup_home;
  82 }
  83
  84 =head1 NAME
  85
  86 Catalyst - The Elegant MVC Web Application Framework
  87
  88 =head1 SYNOPSIS
  89
  90     # use the helper to create a new application
  91     catalyst.pl MyApp
  92
  93     # add models, views, controllers
  94     script/myapp_create.pl model Database DBIC::SchemaLoader dbi:SQLite:/path/to/db
  95     script/myapp_create.pl view TT TT
  96     script/myapp_create.pl controller Search
  97
  98     # built in testserver -- use -r to restart automatically on changes
  99     script/myapp_server.pl
 100
 101     # command line testing interface
 102     script/myapp_test.pl /yada
 103
 104     ### in lib/MyApp.pm
 105     use Catalyst qw/-Debug/; # include plugins here as well
 106
 107         ### In libMyApp/Controller/Root.pm (autocreated)
 108     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 109         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 110         $c->stash->{template} = 'foo.tt'; # set the template
 111         # lookup something from db -- stash vars are passed to TT
 112         $c->stash->{data} =
 113           $c->model('Database::Foo')->search( { country => $args[0] } );
 114         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 115             $c->forward( 'bar' ); # process another action
 116             # do something else after forward returns
 117         }
 118     }
 119
 120     # The foo.tt TT template can use the stash data from the database
 121     [% WHILE (item = data.next) %]
 122         [% item.foo %]
 123     [% END %]
 124
 125     # called for /bar/of/soap, /bar/of/soap/10, etc.
 126     sub bar : Path('/bar/of/soap') { ... }
 127
 128     # called for all actions, from the top-most controller downwards
 129     sub auto : Private {
 130         my ( $self, $c ) = @_;
 131         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 132             $c->res->redirect( '/login' ); # require login
 133             return 0; # abort request and go immediately to end()
 134         }
 135         return 1; # success; carry on to next action
 136     }
 137
 138     # called after all actions are finished
 139     sub end : Private {
 140         my ( $self, $c ) = @_;
 141         if ( scalar @{ $c->error } ) { ... } # handle errors
 142         return if $c->res->body; # already have a response
 143         $c->forward( 'MyApp::View::TT' ); # render template
 144     }
 145
 146     ### in MyApp/Controller/Foo.pm
 147     # called for /foo/bar
 148     sub bar : Local { ... }
 149
 150     # called for /blargle
 151     sub blargle : Global { ... }
 152
 153     # an index action matches /foo, but not /foo/1, etc.
 154     sub index : Private { ... }
 155
 156     ### in MyApp/Controller/Foo/Bar.pm
 157     # called for /foo/bar/baz
 158     sub baz : Local { ... }
 159
 160     # first Root auto is called, then Foo auto, then this
 161     sub auto : Private { ... }
 162
 163     # powerful regular expression paths are also possible
 164     sub details : Regex('^product/(\w+)/details$') {
 165         my ( $self, $c ) = @_;
 166         # extract the (\w+) from the URI
 167         my $product = $c->req->captures->[0];
 168     }
 169
 170 See L<Catalyst::Manual::Intro> for additional information.
 171
 172 =head1 DESCRIPTION
 173
 174 Catalyst is a modern framework for making web applications without the pain usually associated with this process. This document is a reference to the main Catalyst application. If you are a new user, we suggest you start with L<Catalyst::Manual::Tutorial> or  L<Catalyst::Manual::Intro>
 175
 176 See L<Catalyst::Manual> for more documentation.
 177
 178 Catalyst plugins can be loaded by naming them as arguments to the "use
 179 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 180 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 181 C<My::Module>.
 182
 183     use Catalyst qw/My::Module/;
 184
 185 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 186 fully qualify the name by using a unary plus:
 187
 188     use Catalyst qw/
 189         My::Module
 190         +Fully::Qualified::Plugin::Name
 191     /;
 192
 193 Special flags like C<-Debug> and C<-Engine> can also be specified as
 194 arguments when Catalyst is loaded:
 195
 196     use Catalyst qw/-Debug My::Module/;
 197
 198 The position of plugins and flags in the chain is important, because
 199 they are loaded in exactly the order in which they appear.
 200
 201 The following flags are supported:
 202
 203 =head2 -Debug
 204
 205 Enables debug output.
 206
 207 =head2 -Engine
 208
 209 Forces Catalyst to use a specific engine. Omit the
 210 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 211
 212     use Catalyst qw/-Engine=CGI/;
 213
 214 =head2 -Home
 215
 216 Forces Catalyst to use a specific home directory, e.g.:
 217
 218     use Catalyst qw[-Home=/usr/sri];
 219
 220 =head2 -Log
 221
 222 Specifies log level.
 223
 224 =head1 METHODS
 225
 226 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 227
 228 =head2 $c->action
 229
 230 Returns a L<Catalyst::Action> object for the current action, which
 231 stringifies to the action name. See L<Catalyst::Action>.
 232
 233 =head2 $c->namespace
 234
 235 Returns the namespace of the current action, i.e., the uri prefix
 236 corresponding to the controller of the current action. For example:
 237
 238     # in Controller::Foo::Bar
 239     $c->namespace; # returns 'foo/bar';
 240
 241 =head2 $c->request
 242
 243 =head2 $c->req
 244
 245 Returns the current L<Catalyst::Request> object. See
 246 L<Catalyst::Request>.
 247
 248 =head2 REQUEST FLOW HANDLING
 249
 250 =head2 $c->forward( $action [, \@arguments ] )
 251
 252 =head2 $c->forward( $class, $method, [, \@arguments ] )
 253
 254 Forwards processing to another action, by it's private name. If you give a
 255 class name but no method, C<process()> is called. You may also optionally
 256 pass arguments in an arrayref. The action will receive the arguments in
 257 C<@_> and C<$c-E<gt>req-E<gt>args>. Upon returning from the function,
 258 C<$c-E<gt>req-E<gt>args> will be restored to the previous values.
 259
 260 Any data C<return>ed from the action forwarded to, will be returned by the
 261 call to forward.
 262
 263     my $foodata = $c->forward('/foo');
 264     $c->forward('index');
 265     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 266     $c->forward('MyApp::View::TT');
 267
 268 Note that forward implies an C<<eval { }>> around the call (well, actually
 269 C<execute> does), thus de-fatalizing all 'dies' within the called action. If
 270 you want C<die> to propagate you need to do something like:
 271
 272     $c->forward('foo');
 273     die $c->error if $c->error;
 274
 275 Or make sure to always return true values from your actions and write your code
 276 like this:
 277
 278     $c->forward('foo') || return;
 279
 280 =cut
 281
 282 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 283
 284 =head2 $c->detach( $action [, \@arguments ] )
 285
 286 =head2 $c->detach( $class, $method, [, \@arguments ] )
 287
 288 The same as C<forward>, but doesn't return to the previous action when
 289 processing is finished.
 290
 291 =cut
 292
 293 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 294
 295 =head2 $c->response
 296
 297 =head2 $c->res
 298
 299 Returns the current L<Catalyst::Response> object.
 300
 301 =head2 $c->stash
 302
 303 Returns a hashref to the stash, which may be used to store data and pass
 304 it between components during a request. You can also set hash keys by
 305 passing arguments. The stash is automatically sent to the view. The
 306 stash is cleared at the end of a request; it cannot be used for
 307 persistent storage.
 308
 309     $c->stash->{foo} = $bar;
 310     $c->stash( { moose => 'majestic', qux => 0 } );
 311     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 312
 313     # stash is automatically passed to the view for use in a template
 314     $c->forward( 'MyApp::V::TT' );
 315
 316 =cut
 317
 318 sub stash {
 319     my $c = shift;
 320     if (@_) {
 321         my $stash = @_ > 1 ? {@_} : $_[0];
 322         while ( my ( $key, $val ) = each %$stash ) {
 323             $c->{stash}->{$key} = $val;
 324         }
 325     }
 326     return $c->{stash};
 327 }
 328
 329 =head2 $c->error
 330
 331 =head2 $c->error($error, ...)
 332
 333 =head2 $c->error($arrayref)
 334
 335 Returns an arrayref containing error messages.  If Catalyst encounters an
 336 error while processing a request, it stores the error in $c->error.  This
 337 method should not be used to store non-fatal error messages.
 338
 339     my @error = @{ $c->error };
 340
 341 Add a new error.
 342
 343     $c->error('Something bad happened');
 344
 345 =cut
 346
 347 sub error {
 348     my $c = shift;
 349     if ( $_[0] ) {
 350         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 351         croak @$error unless ref $c;
 352         push @{ $c->{error} }, @$error;
 353     }
 354     elsif ( defined $_[0] ) { $c->{error} = undef }
 355     return $c->{error} || [];
 356 }
 357
 358
 359 =head2 $c->state
 360
 361 Contains the return value of the last executed action.
 362
 363 =head2 $c->clear_errors
 364
 365 Clear errors.  You probably don't want to clear the errors unless you are
 366 implementing a custom error screen.
 367
 368 This is equivalent to running
 369
 370     $c->error(0);
 371
 372 =cut
 373
 374 sub clear_errors {
 375     my $c = shift;
 376     $c->error(0);
 377 }
 378
 379
 380
 381
 382 # search via regex
 383 sub _comp_search {
 384     my ( $c, @names ) = @_;
 385
 386     foreach my $name (@names) {
 387         foreach my $component ( keys %{ $c->components } ) {
 388             return $c->components->{$component} if $component =~ /$name/i;
 389         }
 390     }
 391
 392     return undef;
 393 }
 394
 395 # try explicit component names
 396 sub _comp_explicit {
 397     my ( $c, @names ) = @_;
 398
 399     foreach my $try (@names) {
 400         return $c->components->{$try} if ( exists $c->components->{$try} );
 401     }
 402
 403     return undef;
 404 }
 405
 406 # like component, but try just these prefixes before regex searching,
 407 #  and do not try to return "sort keys %{ $c->components }"
 408 sub _comp_prefixes {
 409     my ( $c, $name, @prefixes ) = @_;
 410
 411     my $appclass = ref $c || $c;
 412
 413     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 414
 415     my $comp = $c->_comp_explicit(@names);
 416     return $comp if defined($comp);
 417     $comp = $c->_comp_search($name);
 418     return $comp;
 419 }
 420
 421 # Find possible names for a prefix
 422
 423 sub _comp_names {
 424     my ( $c, @prefixes ) = @_;
 425
 426     my $appclass = ref $c || $c;
 427
 428     my @pre = map { "${appclass}::${_}::" } @prefixes;
 429
 430     my @names;
 431
 432     COMPONENT: foreach my $comp ($c->component) {
 433         foreach my $p (@pre) {
 434             if ($comp =~ s/^$p//) {
 435                 push(@names, $comp);
 436                 next COMPONENT;
 437             }
 438         }
 439     }
 440
 441     return @names;
 442 }
 443
 444 # Return a component if only one matches.
 445 sub _comp_singular {
 446     my ( $c, @prefixes ) = @_;
 447
 448     my $appclass = ref $c || $c;
 449
 450     my ( $comp, $rest ) =
 451       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 452     return $comp unless $rest;
 453 }
 454
 455 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 456 sub _filter_component {
 457     my ( $c, $comp, @args ) = @_;
 458     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 459         return $comp->ACCEPT_CONTEXT( $c, @args );
 460     }
 461     else { return $comp }
 462 }
 463
 464 =head2 COMPONENT ACCESSORS
 465
 466 =head2 $c->controller($name)
 467
 468 Gets a L<Catalyst::Controller> instance by name.
 469
 470     $c->controller('Foo')->do_stuff;
 471
 472 If name is omitted, will return the controller for the dispatched action.
 473
 474 =cut
 475
 476 sub controller {
 477     my ( $c, $name, @args ) = @_;
 478     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 479         @args )
 480       if ($name);
 481     return $c->component( $c->action->class );
 482 }
 483
 484 =head2 $c->model($name)
 485
 486 Gets a L<Catalyst::Model> instance by name.
 487
 488     $c->model('Foo')->do_stuff;
 489
 490 If the name is omitted, it will look for a config setting 'default_model',
 491 or check if there is only one model, and forward to it if that's the case.
 492
 493 =cut
 494
 495 sub model {
 496     my ( $c, $name, @args ) = @_;
 497     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 498         @args )
 499       if $name;
 500     return $c->component( $c->config->{default_model} )
 501       if $c->config->{default_model};
 502     return $c->_filter_component( $c->_comp_singular(qw/Model M/), @args );
 503
 504 }
 505
 506 =head2 $c->controllers
 507
 508 Returns the available names which can be passed to $c->controller
 509
 510 =cut
 511
 512 sub controllers {
 513     my ( $c ) = @_;
 514     return $c->_comp_names(qw/Controller C/);
 515 }
 516
 517
 518 =head2 $c->view($name)
 519
 520 Gets a L<Catalyst::View> instance by name.
 521
 522     $c->view('Foo')->do_stuff;
 523
 524 If the name is omitted, it will look for a config setting 'default_view',
 525 or check if there is only one view, and forward to it if that's the case.
 526
 527 =cut
 528
 529 sub view {
 530     my ( $c, $name, @args ) = @_;
 531     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 532         @args )
 533       if $name;
 534     return $c->component( $c->config->{default_view} )
 535       if $c->config->{default_view};
 536     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 537 }
 538
 539 =head2 $c->models
 540
 541 Returns the available names which can be passed to $c->model
 542
 543 =cut
 544
 545 sub models {
 546     my ( $c ) = @_;
 547     return $c->_comp_names(qw/Model M/);
 548 }
 549
 550
 551 =head2 $c->views
 552
 553 Returns the available names which can be passed to $c->view
 554
 555 =cut
 556
 557 sub views {
 558     my ( $c ) = @_;
 559     return $c->_comp_names(qw/View V/);
 560 }
 561
 562 =head2 $c->comp($name)
 563
 564 =head2 $c->component($name)
 565
 566 Gets a component object by name. This method is no longer recommended,
 567 unless you want to get a specific component by full
 568 class. C<$c-E<gt>controller>, C<$c-E<gt>model>, and C<$c-E<gt>view>
 569 should be used instead.
 570
 571 =cut
 572
 573 sub component {
 574     my $c = shift;
 575
 576     if (@_) {
 577
 578         my $name = shift;
 579
 580         my $appclass = ref $c || $c;
 581
 582         my @names = (
 583             $name, "${appclass}::${name}",
 584             map { "${appclass}::${_}::${name}" }
 585               qw/Model M Controller C View V/
 586         );
 587
 588         my $comp = $c->_comp_explicit(@names);
 589         return $c->_filter_component( $comp, @_ ) if defined($comp);
 590
 591         $comp = $c->_comp_search($name);
 592         return $c->_filter_component( $comp, @_ ) if defined($comp);
 593     }
 594
 595     return sort keys %{ $c->components };
 596 }
 597
 598
 599
 600 =head2 CLASS DATA AND HELPER CLASSES
 601
 602 =head2 $c->config
 603
 604 Returns or takes a hashref containing the application's configuration.
 605
 606     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 607
 608 You can also use a L<YAML> config file like myapp.yml in your
 609 applications home directory.
 610
 611     ---
 612     db: dsn:SQLite:foo.db
 613
 614
 615 =cut
 616
 617 sub config {
 618     my $c = shift;
 619
 620     $c->log->warn("Setting config after setup has been run is not a good idea.")
 621       if ( @_ and $c->setup_finished );
 622
 623     $c->NEXT::config(@_);
 624 }
 625
 626 =head2 $c->log
 627
 628 Returns the logging object instance. Unless it is already set, Catalyst sets
 629 this up with a L<Catalyst::Log> object. To use your own log class, set the
 630 logger with the C<< __PACKAGE__->log >> method prior to calling
 631 C<< __PACKAGE__->setup >>.
 632
 633  __PACKAGE__->log( MyLogger->new );
 634  __PACKAGE__->setup;
 635
 636 And later:
 637
 638     $c->log->info( 'Now logging with my own logger!' );
 639
 640 Your log class should implement the methods described in the
 641 L<Catalyst::Log> man page.
 642
 643
 644 =head2 $c->debug
 645
 646 Overload to enable debug messages (same as -Debug option).
 647
 648 =cut
 649
 650 sub debug { 0 }
 651
 652 =head2 $c->dispatcher
 653
 654 Returns the dispatcher instance. Stringifies to class name. See
 655 L<Catalyst::Dispatcher>.
 656
 657 =head2 $c->engine
 658
 659 Returns the engine instance. Stringifies to the class name. See
 660 L<Catalyst::Engine>.
 661
 662
 663 =head2 UTILITY METHODS
 664
 665 =head2 $c->path_to(@path)
 666
 667 Merges C<@path> with C<$c-E<gt>config-E<gt>{home}> and returns a
 668 L<Path::Class> object.
 669
 670 For example:
 671
 672     $c->path_to( 'db', 'sqlite.db' );
 673
 674 =cut
 675
 676 sub path_to {
 677     my ( $c, @path ) = @_;
 678     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 679     if ( -d $path ) { return $path }
 680     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 681 }
 682
 683 =head2 $c->plugin( $name, $class, @args )
 684
 685 Helper method for plugins. It creates a classdata accessor/mutator and
 686 loads and instantiates the given class.
 687
 688     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 689
 690     $c->prototype->define_javascript_functions;
 691
 692 =cut
 693
 694 sub plugin {
 695     my ( $class, $name, $plugin, @args ) = @_;
 696     $class->_register_plugin( $plugin, 1 );
 697
 698     eval { $plugin->import };
 699     $class->mk_classdata($name);
 700     my $obj;
 701     eval { $obj = $plugin->new(@args) };
 702
 703     if ($@) {
 704         Catalyst::Exception->throw( message =>
 705               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 706     }
 707
 708     $class->$name($obj);
 709     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 710       if $class->debug;
 711 }
 712
 713 =head2 MyApp->setup
 714
 715 Initializes the dispatcher and engine, loads any plugins, and loads the
 716 model, view, and controller components. You may also specify an array
 717 of plugins to load here, if you choose to not load them in the C<use
 718 Catalyst> line.
 719
 720     MyApp->setup;
 721     MyApp->setup( qw/-Debug/ );
 722
 723 =cut
 724
 725 sub setup {
 726     my ( $class, @arguments ) = @_;
 727
 728     $class->log->warn("Running setup twice is not a good idea.")
 729       if ( $class->setup_finished );
 730
 731     unless ( $class->isa('Catalyst') ) {
 732
 733         Catalyst::Exception->throw(
 734             message => qq/'$class' does not inherit from Catalyst/ );
 735     }
 736
 737     if ( $class->arguments ) {
 738         @arguments = ( @arguments, @{ $class->arguments } );
 739     }
 740
 741     # Process options
 742     my $flags = {};
 743
 744     foreach (@arguments) {
 745
 746         if (/^-Debug$/) {
 747             $flags->{log} =
 748               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 749         }
 750         elsif (/^-(\w+)=?(.*)$/) {
 751             $flags->{ lc $1 } = $2;
 752         }
 753         else {
 754             push @{ $flags->{plugins} }, $_;
 755         }
 756     }
 757
 758     $class->setup_home( delete $flags->{home} );
 759
 760     $class->setup_log( delete $flags->{log} );
 761     $class->setup_plugins( delete $flags->{plugins} );
 762     $class->setup_dispatcher( delete $flags->{dispatcher} );
 763     $class->setup_engine( delete $flags->{engine} );
 764
 765     for my $flag ( sort keys %{$flags} ) {
 766
 767         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 768             &$code( $class, delete $flags->{$flag} );
 769         }
 770         else {
 771             $class->log->warn(qq/Unknown flag "$flag"/);
 772         }
 773     }
 774
 775     $class->log->warn(
 776         <<"EOF") if ( $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::CATALYST_SCRIPT_GEN ) );
 777 You are running an old script!
 778
 779   Please update by running (this will overwrite existing files):
 780     catalyst.pl -force -scripts $class
 781
 782   or (this will not overwrite existing files):
 783     catalyst.pl -scripts $class
 784 EOF
 785
 786     if ( $class->debug ) {
 787
 788         my @plugins = ();
 789
 790         {
 791             no strict 'refs';
 792             @plugins =
 793               map { $_ . ' ' . ( $_->VERSION || '' ) }
 794               grep { /^Catalyst::Plugin/ } @{"$class\::ISA"};
 795         }
 796
 797         if (@plugins) {
 798             my $t = Text::SimpleTable->new(74);
 799             $t->row($_) for @plugins;
 800             $class->log->debug( "Loaded plugins:\n" . $t->draw );
 801         }
 802
 803         my $dispatcher = $class->dispatcher;
 804         my $engine     = $class->engine;
 805         my $home       = $class->config->{home};
 806
 807         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 808         $class->log->debug(qq/Loaded engine "$engine"/);
 809
 810         $home
 811           ? ( -d $home )
 812           ? $class->log->debug(qq/Found home "$home"/)
 813           : $class->log->debug(qq/Home "$home" doesn't exist/)
 814           : $class->log->debug(q/Couldn't find home/);
 815     }
 816
 817     # Call plugins setup
 818     {
 819         no warnings qw/redefine/;
 820         local *setup = sub { };
 821         $class->setup;
 822     }
 823
 824     # Initialize our data structure
 825     $class->components( {} );
 826
 827     $class->setup_components;
 828
 829     if ( $class->debug ) {
 830         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 831         for my $comp ( sort keys %{ $class->components } ) {
 832             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 833             $t->row( $comp, $type );
 834         }
 835         $class->log->debug( "Loaded components:\n" . $t->draw )
 836           if ( keys %{ $class->components } );
 837     }
 838
 839     # Add our self to components, since we are also a component
 840     $class->components->{$class} = $class;
 841
 842     $class->setup_actions;
 843
 844     if ( $class->debug ) {
 845         my $name = $class->config->{name} || 'Application';
 846         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 847     }
 848     $class->log->_flush() if $class->log->can('_flush');
 849
 850     $class->setup_finished(1);
 851 }
 852
 853 =head2 $c->uri_for( $path, @args?, \%query_values? )
 854
 855 Merges path with C<$c-E<gt>request-E<gt>base> for absolute uri's and
 856 with C<$c-E<gt>namespace> for relative uri's, then returns a
 857 normalized L<URI> object. If any args are passed, they are added at the
 858 end of the path.  If the last argument to uri_for is a hash reference,
 859 it is assumed to contain GET parameter key/value pairs, which will be
 860 appended to the URI in standard fashion.
 861
 862 =cut
 863
 864 sub uri_for {
 865     my ( $c, $path, @args ) = @_;
 866     my $base     = $c->request->base->clone;
 867     my $basepath = $base->path;
 868     $basepath =~ s/\/$//;
 869     $basepath .= '/';
 870     my $namespace = $c->namespace || '';
 871
 872     # massage namespace, empty if absolute path
 873     $namespace =~ s/^\/// if $namespace;
 874     $namespace .= '/' if $namespace;
 875     $path ||= '';
 876     $namespace = '' if $path =~ /^\//;
 877     $path =~ s/^\///;
 878
 879     my $params =
 880       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 881
 882     for my $value ( values %$params ) {\r
 883         my $isa_ref = ref $value;\r
 884         if( $isa_ref and $isa_ref ne 'ARRAY' ) {\r
 885             croak( "Non-array reference ($isa_ref) passed to uri_for()" );\r
 886         }\r
 887         utf8::encode( $_ ) for grep { defined } $isa_ref ? @$value : $value;\r
 888     };
 889
 890     # join args with '/', or a blank string
 891     my $args = ( scalar @args ? '/' . join( '/', @args ) : '' );
 892     $args =~ s/^\/// unless $path;
 893     my $res =
 894       URI->new_abs( URI->new_abs( "$path$args", "$basepath$namespace" ), $base )
 895       ->canonical;
 896     $res->query_form(%$params);
 897     $res;
 898 }
 899
 900 =head2 $c->welcome_message
 901
 902 Returns the Catalyst welcome HTML page.
 903
 904 =cut
 905
 906 sub welcome_message {
 907     my $c      = shift;
 908     my $name   = $c->config->{name};
 909     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
 910     my $prefix = Catalyst::Utils::appprefix( ref $c );
 911     $c->response->content_type('text/html; charset=utf-8');
 912     return <<"EOF";
 913 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
 914     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
 915 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 916     <head>
 917         <meta http-equiv="Content-Language" content="en" />
 918         <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
 919         <title>$name on Catalyst $VERSION</title>
 920         <style type="text/css">
 921             body {
 922                 color: #000;
 923                 background-color: #eee;
 924             }
 925             div#content {
 926                 width: 640px;
 927                 margin-left: auto;
 928                 margin-right: auto;
 929                 margin-top: 10px;
 930                 margin-bottom: 10px;
 931                 text-align: left;
 932                 background-color: #ccc;
 933                 border: 1px solid #aaa;
 934             }
 935             p, h1, h2 {
 936                 margin-left: 20px;
 937                 margin-right: 20px;
 938                 font-family: verdana, tahoma, sans-serif;
 939             }
 940             a {
 941                 font-family: verdana, tahoma, sans-serif;
 942             }
 943             :link, :visited {
 944                     text-decoration: none;
 945                     color: #b00;
 946                     border-bottom: 1px dotted #bbb;
 947             }
 948             :link:hover, :visited:hover {
 949                     color: #555;
 950             }
 951             div#topbar {
 952                 margin: 0px;
 953             }
 954             pre {
 955                 margin: 10px;
 956                 padding: 8px;
 957             }
 958             div#answers {
 959                 padding: 8px;
 960                 margin: 10px;
 961                 background-color: #fff;
 962                 border: 1px solid #aaa;
 963             }
 964             h1 {
 965                 font-size: 0.9em;
 966                 font-weight: normal;
 967                 text-align: center;
 968             }
 969             h2 {
 970                 font-size: 1.0em;
 971             }
 972             p {
 973                 font-size: 0.9em;
 974             }
 975             p img {
 976                 float: right;
 977                 margin-left: 10px;
 978             }
 979             span#appname {
 980                 font-weight: bold;
 981                 font-size: 1.6em;
 982             }
 983         </style>
 984     </head>
 985     <body>
 986         <div id="content">
 987             <div id="topbar">
 988                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
 989                     $VERSION</h1>
 990              </div>
 991              <div id="answers">
 992                  <p>
 993                  <img src="$logo" alt="Catalyst Logo" />
 994                  </p>
 995                  <p>Welcome to the wonderful world of Catalyst.
 996                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
 997                     framework will make web development something you had
 998                     never expected it to be: Fun, rewarding, and quick.</p>
 999                  <h2>What to do now?</h2>
1000                  <p>That really depends  on what <b>you</b> want to do.
1001                     We do, however, provide you with a few starting points.</p>
1002                  <p>If you want to jump right into web development with Catalyst
1003                     you might want to check out the documentation.</p>
1004                  <pre><code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1005 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1006 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual.pod">Catalyst::Manual</a></code></pre>
1007                  <h2>What to do next?</h2>
1008                  <p>Next it's time to write an actual application. Use the
1009                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1010                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1011                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1012                     they can save you a lot of work.</p>
1013                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1014                     <p>Also, be sure to check out the vast and growing
1015                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1016                     you are likely to find what you need there.
1017                     </p>
1018
1019                  <h2>Need help?</h2>
1020                  <p>Catalyst has a very active community. Here are the main places to
1021                     get in touch with us.</p>
1022                  <ul>
1023                      <li>
1024                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1025                      </li>
1026                      <li>
1027                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1028                      </li>
1029                      <li>
1030                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1031                      </li>
1032                  </ul>
1033                  <h2>In conclusion</h2>
1034                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1035                     as we enjoyed making it. Please contact us if you have ideas
1036                     for improvement or other feedback.</p>
1037              </div>
1038          </div>
1039     </body>
1040 </html>
1041 EOF
1042 }
1043
1044 =head1 INTERNAL METHODS
1045
1046 These methods are not meant to be used by end users.
1047
1048 =head2 $c->components
1049
1050 Returns a hash of components.
1051
1052 =head2 $c->context_class
1053
1054 Returns or sets the context class.
1055
1056 =head2 $c->counter
1057
1058 Returns a hashref containing coderefs and execution counts (needed for
1059 deep recursion detection).
1060
1061 =head2 $c->depth
1062
1063 Returns the number of actions on the current internal execution stack.
1064
1065 =head2 $c->dispatch
1066
1067 Dispatches a request to actions.
1068
1069 =cut
1070
1071 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1072
1073 =head2 $c->dispatcher_class
1074
1075 Returns or sets the dispatcher class.
1076
1077 =head2 $c->dump_these
1078
1079 Returns a list of 2-element array references (name, structure) pairs
1080 that will be dumped on the error page in debug mode.
1081
1082 =cut
1083
1084 sub dump_these {
1085     my $c = shift;
1086     [ Request => $c->req ],
1087     [ Response => $c->res ],
1088     [ Stash => $c->stash ],
1089     [ Config => $c->config ];
1090 }
1091
1092 =head2 $c->engine_class
1093
1094 Returns or sets the engine class.
1095
1096 =head2 $c->execute( $class, $coderef )
1097
1098 Execute a coderef in given class and catch exceptions. Errors are available
1099 via $c->error.
1100
1101 =cut
1102
1103 sub execute {
1104     my ( $c, $class, $code ) = @_;
1105     $class = $c->component($class) || $class;
1106     $c->state(0);
1107
1108     if ( $c->depth >= $RECURSION ) {
1109         my $action = "$code";
1110         $action = "/$action" unless $action =~ /\-\>/;
1111         my $error = qq/Deep recursion detected calling "$action"/;
1112         $c->log->error($error);
1113         $c->error($error);
1114         $c->state(0);
1115         return $c->state;
1116     }
1117
1118     my $stats_info = $c->_stats_start_execute( $code );
1119
1120     push( @{ $c->stack }, $code );
1121
1122     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1123
1124     $c->_stats_finish_execute( $stats_info );
1125
1126     my $last = ${ $c->stack }[-1];
1127     pop( @{ $c->stack } );
1128
1129     if ( my $error = $@ ) {
1130         if ( $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1131         else {
1132             unless ( ref $error ) {
1133                 chomp $error;
1134                 my $class = $last->class;
1135                 my $name  = $last->name;
1136                 $error = qq/Caught exception in $class->$name "$error"/;
1137             }
1138             $c->error($error);
1139             $c->state(0);
1140         }
1141     }
1142     return $c->state;
1143 }
1144
1145 sub _stats_start_execute {
1146     my ( $c, $code ) = @_;
1147
1148     return unless $c->debug;
1149
1150     my $action = "$code";
1151
1152     $action = "/$action" unless $action =~ /\-\>/;
1153     $c->counter->{"$code"}++;
1154
1155     # determine if the call was the result of a forward
1156     # this is done by walking up the call stack and looking for a calling
1157     # sub of Catalyst::forward before the eval
1158     my $callsub = q{};
1159     for my $index ( 2 .. 11 ) {
1160         last
1161         if ( ( caller($index) )[0] eq 'Catalyst'
1162             && ( caller($index) )[3] eq '(eval)' );
1163
1164         if ( ( caller($index) )[3] =~ /forward$/ ) {
1165             $callsub = ( caller($index) )[3];
1166             $action  = "-> $action";
1167             last;
1168         }
1169     }
1170
1171     my $node = Tree::Simple->new(
1172         {
1173             action  => $action,
1174             elapsed => undef,     # to be filled in later
1175             comment => "",
1176         }
1177     );
1178     $node->setUID( "$code" . $c->counter->{"$code"} );
1179
1180     unless ( ( $code->name =~ /^_.*/ )
1181         && ( !$c->config->{show_internal_actions} ) )
1182     {
1183         # is this a root-level call or a forwarded call?
1184         if ( $callsub =~ /forward$/ ) {
1185
1186             # forward, locate the caller
1187             if ( my $parent = $c->stack->[-1] ) {
1188                 my $visitor = Tree::Simple::Visitor::FindByUID->new;
1189                 $visitor->searchForUID(
1190                     "$parent" . $c->counter->{"$parent"} );
1191                 $c->stats->accept($visitor);
1192                 if ( my $result = $visitor->getResult ) {
1193                     $result->addChild($node);
1194                 }
1195             }
1196             else {
1197
1198                 # forward with no caller may come from a plugin
1199                 $c->stats->addChild($node);
1200             }
1201         }
1202         else {
1203
1204             # root-level call
1205             $c->stats->addChild($node);
1206         }
1207     }
1208
1209     my $start = [gettimeofday];
1210     my $elapsed = tv_interval($start);
1211
1212     return {
1213         code    => $code,
1214         elapsed => $elapsed,
1215         start   => $start,
1216         node    => $node,
1217       }
1218 }
1219
1220 sub _stats_finish_execute {
1221     my ( $c, $info ) = @_;
1222
1223     return unless $c->debug;
1224
1225     my ( $code, $start, $elapsed ) = @{ $info }{qw/code start elapsed/};
1226
1227     unless ( ( $code->name =~ /^_.*/ )
1228         && ( !$c->config->{show_internal_actions} ) )
1229     {
1230
1231         # FindByUID uses an internal die, so we save the existing error
1232         my $error = $@;
1233
1234         # locate the node in the tree and update the elapsed time
1235         my $visitor = Tree::Simple::Visitor::FindByUID->new;
1236         $visitor->searchForUID( "$code" . $c->counter->{"$code"} );
1237         $c->stats->accept($visitor);
1238         if ( my $result = $visitor->getResult ) {
1239             my $value = $result->getNodeValue;
1240             $value->{elapsed} = sprintf( '%fs', $elapsed );
1241             $result->setNodeValue($value);
1242         }
1243
1244         # restore error
1245         $@ = $error || undef;
1246     }
1247 }
1248
1249 =head2 $c->_localize_fields( sub { }, \%keys );
1250
1251 =cut
1252
1253 sub _localize_fields {
1254     my ( $c, $localized, $code ) = ( @_ );
1255
1256     my $request = delete $localized->{request} || {};
1257     my $response = delete $localized->{response} || {};
1258
1259     local @{ $c }{ keys %$localized } = values %$localized;
1260     local @{ $c->request }{ keys %$request } = values %$request;
1261     local @{ $c->response }{ keys %$response } = values %$response;
1262
1263     $code->();
1264 }
1265
1266 =head2 $c->finalize
1267
1268 Finalizes the request.
1269
1270 =cut
1271
1272 sub finalize {
1273     my $c = shift;
1274
1275     for my $error ( @{ $c->error } ) {
1276         $c->log->error($error);
1277     }
1278
1279     # Allow engine to handle finalize flow (for POE)
1280     if ( $c->engine->can('finalize') ) {
1281         $c->engine->finalize($c);
1282     }
1283     else {
1284
1285         $c->finalize_uploads;
1286
1287         # Error
1288         if ( $#{ $c->error } >= 0 ) {
1289             $c->finalize_error;
1290         }
1291
1292         $c->finalize_headers;
1293
1294         # HEAD request
1295         if ( $c->request->method eq 'HEAD' ) {
1296             $c->response->body('');
1297         }
1298
1299         $c->finalize_body;
1300     }
1301
1302     return $c->response->status;
1303 }
1304
1305 =head2 $c->finalize_body
1306
1307 Finalizes body.
1308
1309 =cut
1310
1311 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1312
1313 =head2 $c->finalize_cookies
1314
1315 Finalizes cookies.
1316
1317 =cut
1318
1319 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1320
1321 =head2 $c->finalize_error
1322
1323 Finalizes error.
1324
1325 =cut
1326
1327 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1328
1329 =head2 $c->finalize_headers
1330
1331 Finalizes headers.
1332
1333 =cut
1334
1335 sub finalize_headers {
1336     my $c = shift;
1337
1338     # Check if we already finalized headers
1339     return if $c->response->{_finalized_headers};
1340
1341     # Handle redirects
1342     if ( my $location = $c->response->redirect ) {
1343         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1344         $c->response->header( Location => $location );
1345     }
1346
1347     # Content-Length
1348     if ( $c->response->body && !$c->response->content_length ) {
1349
1350         # get the length from a filehandle
1351         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1352         {
1353             if ( my $stat = stat $c->response->body ) {
1354                 $c->response->content_length( $stat->size );
1355             }
1356             else {
1357                 $c->log->warn('Serving filehandle without a content-length');
1358             }
1359         }
1360         else {
1361             $c->response->content_length( bytes::length( $c->response->body ) );
1362         }
1363     }
1364
1365     # Errors
1366     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1367         $c->response->headers->remove_header("Content-Length");
1368         $c->response->body('');
1369     }
1370
1371     $c->finalize_cookies;
1372
1373     $c->engine->finalize_headers( $c, @_ );
1374
1375     # Done
1376     $c->response->{_finalized_headers} = 1;
1377 }
1378
1379 =head2 $c->finalize_output
1380
1381 An alias for finalize_body.
1382
1383 =head2 $c->finalize_read
1384
1385 Finalizes the input after reading is complete.
1386
1387 =cut
1388
1389 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1390
1391 =head2 $c->finalize_uploads
1392
1393 Finalizes uploads. Cleans up any temporary files.
1394
1395 =cut
1396
1397 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1398
1399 =head2 $c->get_action( $action, $namespace )
1400
1401 Gets an action in a given namespace.
1402
1403 =cut
1404
1405 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1406
1407 =head2 $c->get_actions( $action, $namespace )
1408
1409 Gets all actions of a given name in a namespace and all parent
1410 namespaces.
1411
1412 =cut
1413
1414 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1415
1416 =head2 $c->handle_request( $class, @arguments )
1417
1418 Called to handle each HTTP request.
1419
1420 =cut
1421
1422 sub handle_request {
1423     my ( $class, @arguments ) = @_;
1424
1425     # Always expect worst case!
1426     my $status = -1;
1427     eval {
1428         my $stats = ( $class->debug ) ? Tree::Simple->new: q{};
1429
1430         my $handler = sub {
1431             my $c = $class->prepare(@arguments);
1432             $c->stats($stats);
1433             $c->dispatch;
1434             return $c->finalize;
1435         };
1436
1437         if ( $class->debug ) {
1438             my $start = [gettimeofday];
1439             $status = &$handler;
1440             my $elapsed = tv_interval $start;
1441             $elapsed = sprintf '%f', $elapsed;
1442             my $av = sprintf '%.3f',
1443               ( $elapsed == 0 ? '??' : ( 1 / $elapsed ) );
1444             my $t = Text::SimpleTable->new( [ 62, 'Action' ], [ 9, 'Time' ] );
1445
1446             $stats->traverse(
1447                 sub {
1448                     my $action = shift;
1449                     my $stat   = $action->getNodeValue;
1450                     $t->row( ( q{ } x $action->getDepth ) . $stat->{action} . $stat->{comment},
1451                         $stat->{elapsed} || '??' );
1452                 }
1453             );
1454
1455             $class->log->info(
1456                 "Request took ${elapsed}s ($av/s)\n" . $t->draw );
1457         }
1458         else { $status = &$handler }
1459
1460     };
1461
1462     if ( my $error = $@ ) {
1463         chomp $error;
1464         $class->log->error(qq/Caught exception in engine "$error"/);
1465     }
1466
1467     $COUNT++;
1468     $class->log->_flush() if $class->log->can('_flush');
1469     return $status;
1470 }
1471
1472 =head2 $c->prepare( @arguments )
1473
1474 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1475 etc.).
1476
1477 =cut
1478
1479 sub prepare {
1480     my ( $class, @arguments ) = @_;
1481
1482     $class->context_class( ref $class || $class ) unless $class->context_class;
1483     my $c = $class->context_class->new(
1484         {
1485             counter => {},
1486             stack   => [],
1487             request => $class->request_class->new(
1488                 {
1489                     arguments        => [],
1490                     body_parameters  => {},
1491                     cookies          => {},
1492                     headers          => HTTP::Headers->new,
1493                     parameters       => {},
1494                     query_parameters => {},
1495                     secure           => 0,
1496                     captures         => [],
1497                     uploads          => {}
1498                 }
1499             ),
1500             response => $class->response_class->new(
1501                 {
1502                     body    => '',
1503                     cookies => {},
1504                     headers => HTTP::Headers->new(),
1505                     status  => 200
1506                 }
1507             ),
1508             stash => {},
1509             state => 0
1510         }
1511     );
1512
1513     # For on-demand data
1514     $c->request->{_context}  = $c;
1515     $c->response->{_context} = $c;
1516     weaken( $c->request->{_context} );
1517     weaken( $c->response->{_context} );
1518
1519     if ( $c->debug ) {
1520         my $secs = time - $START || 1;
1521         my $av = sprintf '%.3f', $COUNT / $secs;
1522         my $time = localtime time;
1523         $c->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1524         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1525     }
1526
1527     # Allow engine to direct the prepare flow (for POE)
1528     if ( $c->engine->can('prepare') ) {
1529         $c->engine->prepare( $c, @arguments );
1530     }
1531     else {
1532         $c->prepare_request(@arguments);
1533         $c->prepare_connection;
1534         $c->prepare_query_parameters;
1535         $c->prepare_headers;
1536         $c->prepare_cookies;
1537         $c->prepare_path;
1538
1539         # On-demand parsing
1540         $c->prepare_body unless $c->config->{parse_on_demand};
1541     }
1542
1543     my $method  = $c->req->method  || '';
1544     my $path    = $c->req->path    || '/';
1545     my $address = $c->req->address || '';
1546
1547     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1548       if $c->debug;
1549
1550     $c->prepare_action;
1551
1552     return $c;
1553 }
1554
1555 =head2 $c->prepare_action
1556
1557 Prepares action. See L<Catalyst::Dispatcher>.
1558
1559 =cut
1560
1561 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1562
1563 =head2 $c->prepare_body
1564
1565 Prepares message body.
1566
1567 =cut
1568
1569 sub prepare_body {
1570     my $c = shift;
1571
1572     # Do we run for the first time?
1573     return if defined $c->request->{_body};
1574
1575     # Initialize on-demand data
1576     $c->engine->prepare_body( $c, @_ );
1577     $c->prepare_parameters;
1578     $c->prepare_uploads;
1579
1580     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1581         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1582         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1583             my $param = $c->req->body_parameters->{$key};
1584             my $value = defined($param) ? $param : '';
1585             $t->row( $key,
1586                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1587         }
1588         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1589     }
1590 }
1591
1592 =head2 $c->prepare_body_chunk( $chunk )
1593
1594 Prepares a chunk of data before sending it to L<HTTP::Body>.
1595
1596 See L<Catalyst::Engine>.
1597
1598 =cut
1599
1600 sub prepare_body_chunk {
1601     my $c = shift;
1602     $c->engine->prepare_body_chunk( $c, @_ );
1603 }
1604
1605 =head2 $c->prepare_body_parameters
1606
1607 Prepares body parameters.
1608
1609 =cut
1610
1611 sub prepare_body_parameters {
1612     my $c = shift;
1613     $c->engine->prepare_body_parameters( $c, @_ );
1614 }
1615
1616 =head2 $c->prepare_connection
1617
1618 Prepares connection.
1619
1620 =cut
1621
1622 sub prepare_connection {
1623     my $c = shift;
1624     $c->engine->prepare_connection( $c, @_ );
1625 }
1626
1627 =head2 $c->prepare_cookies
1628
1629 Prepares cookies.
1630
1631 =cut
1632
1633 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1634
1635 =head2 $c->prepare_headers
1636
1637 Prepares headers.
1638
1639 =cut
1640
1641 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1642
1643 =head2 $c->prepare_parameters
1644
1645 Prepares parameters.
1646
1647 =cut
1648
1649 sub prepare_parameters {
1650     my $c = shift;
1651     $c->prepare_body_parameters;
1652     $c->engine->prepare_parameters( $c, @_ );
1653 }
1654
1655 =head2 $c->prepare_path
1656
1657 Prepares path and base.
1658
1659 =cut
1660
1661 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1662
1663 =head2 $c->prepare_query_parameters
1664
1665 Prepares query parameters.
1666
1667 =cut
1668
1669 sub prepare_query_parameters {
1670     my $c = shift;
1671
1672     $c->engine->prepare_query_parameters( $c, @_ );
1673
1674     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1675         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1676         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1677             my $param = $c->req->query_parameters->{$key};
1678             my $value = defined($param) ? $param : '';
1679             $t->row( $key,
1680                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1681         }
1682         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1683     }
1684 }
1685
1686 =head2 $c->prepare_read
1687
1688 Prepares the input for reading.
1689
1690 =cut
1691
1692 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1693
1694 =head2 $c->prepare_request
1695
1696 Prepares the engine request.
1697
1698 =cut
1699
1700 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1701
1702 =head2 $c->prepare_uploads
1703
1704 Prepares uploads.
1705
1706 =cut
1707
1708 sub prepare_uploads {
1709     my $c = shift;
1710
1711     $c->engine->prepare_uploads( $c, @_ );
1712
1713     if ( $c->debug && keys %{ $c->request->uploads } ) {
1714         my $t = Text::SimpleTable->new(
1715             [ 12, 'Parameter' ],
1716             [ 26, 'Filename' ],
1717             [ 18, 'Type' ],
1718             [ 9,  'Size' ]
1719         );
1720         for my $key ( sort keys %{ $c->request->uploads } ) {
1721             my $upload = $c->request->uploads->{$key};
1722             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1723                 $t->row( $key, $u->filename, $u->type, $u->size );
1724             }
1725         }
1726         $c->log->debug( "File Uploads are:\n" . $t->draw );
1727     }
1728 }
1729
1730 =head2 $c->prepare_write
1731
1732 Prepares the output for writing.
1733
1734 =cut
1735
1736 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1737
1738 =head2 $c->request_class
1739
1740 Returns or sets the request class.
1741
1742 =head2 $c->response_class
1743
1744 Returns or sets the response class.
1745
1746 =head2 $c->read( [$maxlength] )
1747
1748 Reads a chunk of data from the request body. This method is designed to
1749 be used in a while loop, reading C<$maxlength> bytes on every call.
1750 C<$maxlength> defaults to the size of the request if not specified.
1751
1752 You have to set C<MyApp-E<gt>config-E<gt>{parse_on_demand}> to use this
1753 directly.
1754
1755 =cut
1756
1757 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1758
1759 =head2 $c->run
1760
1761 Starts the engine.
1762
1763 =cut
1764
1765 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1766
1767 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1768
1769 Sets an action in a given namespace.
1770
1771 =cut
1772
1773 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1774
1775 =head2 $c->setup_actions($component)
1776
1777 Sets up actions for a component.
1778
1779 =cut
1780
1781 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1782
1783 =head2 $c->setup_components
1784
1785 Sets up components.
1786
1787 =cut
1788
1789 sub setup_components {
1790     my $class = shift;
1791
1792     my $callback = sub {
1793         my ( $component, $context ) = @_;
1794
1795         unless ( $component->can('COMPONENT') ) {
1796             return $component;
1797         }
1798
1799         my $suffix = Catalyst::Utils::class2classsuffix($component);
1800         my $config = $class->config->{$suffix} || {};
1801
1802         my $instance;
1803
1804         eval { $instance = $component->COMPONENT( $context, $config ); };
1805
1806         if ( my $error = $@ ) {
1807
1808             chomp $error;
1809
1810             Catalyst::Exception->throw( message =>
1811                   qq/Couldn't instantiate component "$component", "$error"/ );
1812         }
1813
1814         Catalyst::Exception->throw( message =>
1815 qq/Couldn't instantiate component "$component", "COMPONENT() didn't return a object"/
1816           )
1817           unless ref $instance;
1818         return $instance;
1819     };
1820
1821     eval "package $class;\n" . q!Module::Pluggable::Fast->import(
1822             name   => '_catalyst_components',
1823             search => [
1824                 "$class\::Controller", "$class\::C",
1825                 "$class\::Model",      "$class\::M",
1826                 "$class\::View",       "$class\::V"
1827             ],
1828             callback => $callback
1829         );
1830     !;
1831
1832     if ( my $error = $@ ) {
1833
1834         chomp $error;
1835
1836         Catalyst::Exception->throw(
1837             message => qq/Couldn't load components "$error"/ );
1838     }
1839
1840     for my $component ( $class->_catalyst_components($class) ) {
1841         $class->components->{ ref $component || $component } = $component;
1842     }
1843 }
1844
1845 =head2 $c->setup_dispatcher
1846
1847 Sets up dispatcher.
1848
1849 =cut
1850
1851 sub setup_dispatcher {
1852     my ( $class, $dispatcher ) = @_;
1853
1854     if ($dispatcher) {
1855         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1856     }
1857
1858     if ( $ENV{CATALYST_DISPATCHER} ) {
1859         $dispatcher = 'Catalyst::Dispatcher::' . $ENV{CATALYST_DISPATCHER};
1860     }
1861
1862     if ( $ENV{ uc($class) . '_DISPATCHER' } ) {
1863         $dispatcher =
1864           'Catalyst::Dispatcher::' . $ENV{ uc($class) . '_DISPATCHER' };
1865     }
1866
1867     unless ($dispatcher) {
1868         $dispatcher = $class->dispatcher_class;
1869     }
1870
1871     $dispatcher->require;
1872
1873     if ($@) {
1874         Catalyst::Exception->throw(
1875             message => qq/Couldn't load dispatcher "$dispatcher", "$@"/ );
1876     }
1877
1878     # dispatcher instance
1879     $class->dispatcher( $dispatcher->new );
1880 }
1881
1882 =head2 $c->setup_engine
1883
1884 Sets up engine.
1885
1886 =cut
1887
1888 sub setup_engine {
1889     my ( $class, $engine ) = @_;
1890
1891     if ($engine) {
1892         $engine = 'Catalyst::Engine::' . $engine;
1893     }
1894
1895     if ( $ENV{CATALYST_ENGINE} ) {
1896         $engine = 'Catalyst::Engine::' . $ENV{CATALYST_ENGINE};
1897     }
1898
1899     if ( $ENV{ uc($class) . '_ENGINE' } ) {
1900         $engine = 'Catalyst::Engine::' . $ENV{ uc($class) . '_ENGINE' };
1901     }
1902
1903     if ( $ENV{MOD_PERL} ) {
1904
1905         # create the apache method
1906         {
1907             no strict 'refs';
1908             *{"$class\::apache"} = sub { shift->engine->apache };
1909         }
1910
1911         my ( $software, $version ) =
1912           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1913
1914         $version =~ s/_//g;
1915         $version =~ s/(\.[^.]+)\./$1/g;
1916
1917         if ( $software eq 'mod_perl' ) {
1918
1919             if ( !$engine ) {
1920
1921                 if ( $version >= 1.99922 ) {
1922                     $engine = 'Catalyst::Engine::Apache2::MP20';
1923                 }
1924
1925                 elsif ( $version >= 1.9901 ) {
1926                     $engine = 'Catalyst::Engine::Apache2::MP19';
1927                 }
1928
1929                 elsif ( $version >= 1.24 ) {
1930                     $engine = 'Catalyst::Engine::Apache::MP13';
1931                 }
1932
1933                 else {
1934                     Catalyst::Exception->throw( message =>
1935                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
1936                 }
1937
1938             }
1939
1940             # install the correct mod_perl handler
1941             if ( $version >= 1.9901 ) {
1942                 *handler = sub  : method {
1943                     shift->handle_request(@_);
1944                 };
1945             }
1946             else {
1947                 *handler = sub ($$) { shift->handle_request(@_) };
1948             }
1949
1950         }
1951
1952         elsif ( $software eq 'Zeus-Perl' ) {
1953             $engine = 'Catalyst::Engine::Zeus';
1954         }
1955
1956         else {
1957             Catalyst::Exception->throw(
1958                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
1959         }
1960     }
1961
1962     unless ($engine) {
1963         $engine = $class->engine_class;
1964     }
1965
1966     $engine->require;
1967
1968     if ($@) {
1969         Catalyst::Exception->throw( message =>
1970 qq/Couldn't load engine "$engine" (maybe you forgot to install it?), "$@"/
1971         );
1972     }
1973
1974     # check for old engines that are no longer compatible
1975     my $old_engine;
1976     if ( $engine->isa('Catalyst::Engine::Apache')
1977         && !Catalyst::Engine::Apache->VERSION )
1978     {
1979         $old_engine = 1;
1980     }
1981
1982     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
1983         && Catalyst::Engine::Server->VERSION le '0.02' )
1984     {
1985         $old_engine = 1;
1986     }
1987
1988     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
1989         && $engine->VERSION eq '0.01' )
1990     {
1991         $old_engine = 1;
1992     }
1993
1994     elsif ($engine->isa('Catalyst::Engine::Zeus')
1995         && $engine->VERSION eq '0.01' )
1996     {
1997         $old_engine = 1;
1998     }
1999
2000     if ($old_engine) {
2001         Catalyst::Exception->throw( message =>
2002               qq/Engine "$engine" is not supported by this version of Catalyst/
2003         );
2004     }
2005
2006     # engine instance
2007     $class->engine( $engine->new );
2008 }
2009
2010 =head2 $c->setup_home
2011
2012 Sets up the home directory.
2013
2014 =cut
2015
2016 sub setup_home {
2017     my ( $class, $home ) = @_;
2018
2019     if ( $ENV{CATALYST_HOME} ) {
2020         $home = $ENV{CATALYST_HOME};
2021     }
2022
2023     if ( $ENV{ uc($class) . '_HOME' } ) {
2024         $home = $ENV{ uc($class) . '_HOME' };
2025     }
2026
2027     unless ($home) {
2028         $home = Catalyst::Utils::home($class);
2029     }
2030
2031     if ($home) {
2032         $class->config->{home} ||= $home;
2033         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2034     }
2035 }
2036
2037 =head2 $c->setup_log
2038
2039 Sets up log.
2040
2041 =cut
2042
2043 sub setup_log {
2044     my ( $class, $debug ) = @_;
2045
2046     unless ( $class->log ) {
2047         $class->log( Catalyst::Log->new );
2048     }
2049
2050     my $app_flag = Catalyst::Utils::class2env($class) . '_DEBUG';
2051
2052     if (
2053           ( defined( $ENV{CATALYST_DEBUG} ) || defined( $ENV{$app_flag} ) )
2054         ? ( $ENV{CATALYST_DEBUG} || $ENV{$app_flag} )
2055         : $debug
2056       )
2057     {
2058         no strict 'refs';
2059         *{"$class\::debug"} = sub { 1 };
2060         $class->log->debug('Debug messages enabled');
2061     }
2062 }
2063
2064 =head2 $c->setup_plugins
2065
2066 Sets up plugins.
2067
2068 =cut
2069
2070 =head2 $c->registered_plugins
2071
2072 Returns a sorted list of the plugins which have either been stated in the
2073 import list or which have been added via C<< MyApp->plugin(@args); >>.
2074
2075 If passed a given plugin name, it will report a boolean value indicating
2076 whether or not that plugin is loaded.  A fully qualified name is required if
2077 the plugin name does not begin with C<Catalyst::Plugin::>.
2078
2079  if ($c->registered_plugins('Some::Plugin')) {
2080      ...
2081  }
2082
2083 =cut
2084
2085 {
2086
2087     sub registered_plugins {
2088         my $proto = shift;
2089         return sort keys %{ $proto->_plugins } unless @_;
2090         my $plugin = shift;
2091         return 1 if exists $proto->_plugins->{$plugin};
2092         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2093     }
2094
2095     sub _register_plugin {
2096         my ( $proto, $plugin, $instant ) = @_;
2097         my $class = ref $proto || $proto;
2098
2099         $plugin->require;
2100
2101         if ( my $error = $@ ) {
2102             my $type = $instant ? "instant " : '';
2103             Catalyst::Exception->throw(
2104                 message => qq/Couldn't load ${type}plugin "$plugin", $error/ );
2105         }
2106
2107         $proto->_plugins->{$plugin} = 1;
2108         unless ($instant) {
2109             no strict 'refs';
2110             unshift @{"$class\::ISA"}, $plugin;
2111         }
2112         return $class;
2113     }
2114
2115     sub setup_plugins {
2116         my ( $class, $plugins ) = @_;
2117
2118         $class->_plugins( {} ) unless $class->_plugins;
2119         $plugins ||= [];
2120         for my $plugin ( reverse @$plugins ) {
2121
2122             unless ( $plugin =~ s/\A\+// ) {
2123                 $plugin = "Catalyst::Plugin::$plugin";
2124             }
2125
2126             $class->_register_plugin($plugin);
2127         }
2128     }
2129 }
2130
2131 =head2 $c->stack
2132
2133 Returns an arrayref of the internal execution stack (actions that are currently
2134 executing).
2135
2136 =head2 $c->write( $data )
2137
2138 Writes $data to the output stream. When using this method directly, you
2139 will need to manually set the C<Content-Length> header to the length of
2140 your output data, if known.
2141
2142 =cut
2143
2144 sub write {
2145     my $c = shift;
2146
2147     # Finalize headers if someone manually writes output
2148     $c->finalize_headers;
2149
2150     return $c->engine->write( $c, @_ );
2151 }
2152
2153 =head2 version
2154
2155 Returns the Catalyst version number. Mostly useful for "powered by"
2156 messages in template systems.
2157
2158 =cut
2159
2160 sub version { return $Catalyst::VERSION }
2161
2162 =head1 INTERNAL ACTIONS
2163
2164 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2165 C<_ACTION>, and C<_END>. These are by default not shown in the private
2166 action table, but you can make them visible with a config parameter.
2167
2168     MyApp->config->{show_internal_actions} = 1;
2169
2170 =head1 CASE SENSITIVITY
2171
2172 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2173 mapped to C</foo/bar>. You can activate case sensitivity with a config
2174 parameter.
2175
2176     MyApp->config->{case_sensitive} = 1;
2177
2178 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2179
2180 =head1 ON-DEMAND PARSER
2181
2182 The request body is usually parsed at the beginning of a request,
2183 but if you want to handle input yourself or speed things up a bit,
2184 you can enable on-demand parsing with a config parameter.
2185
2186     MyApp->config->{parse_on_demand} = 1;
2187
2188 =head1 PROXY SUPPORT
2189
2190 Many production servers operate using the common double-server approach,
2191 with a lightweight frontend web server passing requests to a larger
2192 backend server. An application running on the backend server must deal
2193 with two problems: the remote user always appears to be C<127.0.0.1> and
2194 the server's hostname will appear to be C<localhost> regardless of the
2195 virtual host that the user connected through.
2196
2197 Catalyst will automatically detect this situation when you are running
2198 the frontend and backend servers on the same machine. The following
2199 changes are made to the request.
2200
2201     $c->req->address is set to the user's real IP address, as read from
2202     the HTTP X-Forwarded-For header.
2203
2204     The host value for $c->req->base and $c->req->uri is set to the real
2205     host, as read from the HTTP X-Forwarded-Host header.
2206
2207 Obviously, your web server must support these headers for this to work.
2208
2209 In a more complex server farm environment where you may have your
2210 frontend proxy server(s) on different machines, you will need to set a
2211 configuration option to tell Catalyst to read the proxied data from the
2212 headers.
2213
2214     MyApp->config->{using_frontend_proxy} = 1;
2215
2216 If you do not wish to use the proxy support at all, you may set:
2217
2218     MyApp->config->{ignore_frontend_proxy} = 1;
2219
2220 =head1 THREAD SAFETY
2221
2222 Catalyst has been tested under Apache 2's threading mpm_worker, mpm_winnt,
2223 and the standalone forking HTTP server on Windows. We believe the Catalyst
2224 core to be thread-safe.
2225
2226 If you plan to operate in a threaded environment, remember that all other
2227 modules you are using must also be thread-safe. Some modules, most notably
2228 L<DBD::SQLite>, are not thread-safe.
2229
2230 =head1 SUPPORT
2231
2232 IRC:
2233
2234     Join #catalyst on irc.perl.org.
2235
2236 Mailing Lists:
2237
2238     http://lists.rawmode.org/mailman/listinfo/catalyst
2239     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2240
2241 Web:
2242
2243     http://catalyst.perl.org
2244
2245 Wiki:
2246
2247     http://dev.catalyst.perl.org
2248
2249 =head1 SEE ALSO
2250
2251 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2252
2253 =head2 L<Catalyst::Manual> - The Catalyst Manual
2254
2255 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2256
2257 =head2 L<Catalyst::Engine> - Core engine
2258
2259 =head2 L<Catalyst::Log> - Log class.
2260
2261 =head2 L<Catalyst::Request> - Request object
2262
2263 =head2 L<Catalyst::Response> - Response object
2264
2265 =head2 L<Catalyst::Test> - The test suite.
2266
2267 =head1 CREDITS
2268
2269 Andy Grundman
2270
2271 Andy Wardley
2272
2273 Andreas Marienborg
2274
2275 Andrew Bramble
2276
2277 Andrew Ford
2278
2279 Andrew Ruthven
2280
2281 Arthur Bergman
2282
2283 Autrijus Tang
2284
2285 Brian Cassidy
2286
2287 Carl Franks
2288
2289 Christian Hansen
2290
2291 Christopher Hicks
2292
2293 Dan Sully
2294
2295 Danijel Milicevic
2296
2297 David Kamholz
2298
2299 David Naughton
2300
2301 Drew Taylor
2302
2303 Gary Ashton Jones
2304
2305 Geoff Richards
2306
2307 Jesse Sheidlower
2308
2309 Jesse Vincent
2310
2311 Jody Belka
2312
2313 Johan Lindstrom
2314
2315 Juan Camacho
2316
2317 Leon Brocard
2318
2319 Marcus Ramberg
2320
2321 Matt S Trout
2322
2323 Robert Sedlacek
2324
2325 Sam Vilain
2326
2327 Sascha Kiefer
2328
2329 Tatsuhiko Miyagawa
2330
2331 Ulf Edvinsson
2332
2333 Yuval Kogman
2334
2335 =head1 AUTHOR
2336
2337 Sebastian Riedel, C<sri@oook.de>
2338
2339 =head1 LICENSE
2340
2341 This library is free software, you can redistribute it and/or modify it under
2342 the same terms as Perl itself.
2343
2344 =cut
2345
2346 1;