lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/container components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80032';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the callee.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@captures, \@arguments ] )
 425
 426 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 427
 428 The relationship between C<go> and
 429 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 430 the relationship between
 431 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 432 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 433 C<< $c->go >> will perform a full dispatch on the specified action or method,
 434 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 435 C<go> escapes the processing of the current request chain on completion, and
 436 does not return to its caller.
 437
 438 @arguments are arguments to the final destination of $action. @captures are
 439 arguments to the intermediate steps, if any, on the way to the final sub of
 440 $action.
 441
 442 =cut
 443
 444 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 445
 446 =head2 $c->response
 447
 448 =head2 $c->res
 449
 450 Returns the current L<Catalyst::Response> object, see there for details.
 451
 452 =head2 $c->stash
 453
 454 Returns a hashref to the stash, which may be used to store data and pass
 455 it between components during a request. You can also set hash keys by
 456 passing arguments. The stash is automatically sent to the view. The
 457 stash is cleared at the end of a request; it cannot be used for
 458 persistent storage (for this you must use a session; see
 459 L<Catalyst::Plugin::Session> for a complete system integrated with
 460 Catalyst).
 461
 462     $c->stash->{foo} = $bar;
 463     $c->stash( { moose => 'majestic', qux => 0 } );
 464     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 465
 466     # stash is automatically passed to the view for use in a template
 467     $c->forward( 'MyApp::View::TT' );
 468
 469 =cut
 470
 471 around stash => sub {
 472     my $orig = shift;
 473     my $c = shift;
 474     my $stash = $orig->($c);
 475     if (@_) {
 476         my $new_stash = @_ > 1 ? {@_} : $_[0];
 477         croak('stash takes a hash or hashref') unless ref $new_stash;
 478         foreach my $key ( keys %$new_stash ) {
 479           $stash->{$key} = $new_stash->{$key};
 480         }
 481     }
 482
 483     return $stash;
 484 };
 485
 486
 487 =head2 $c->error
 488
 489 =head2 $c->error($error, ...)
 490
 491 =head2 $c->error($arrayref)
 492
 493 Returns an arrayref containing error messages.  If Catalyst encounters an
 494 error while processing a request, it stores the error in $c->error.  This
 495 method should only be used to store fatal error messages.
 496
 497     my @error = @{ $c->error };
 498
 499 Add a new error.
 500
 501     $c->error('Something bad happened');
 502
 503 =cut
 504
 505 sub error {
 506     my $c = shift;
 507     if ( $_[0] ) {
 508         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 509         croak @$error unless ref $c;
 510         push @{ $c->{error} }, @$error;
 511     }
 512     elsif ( defined $_[0] ) { $c->{error} = undef }
 513     return $c->{error} || [];
 514 }
 515
 516
 517 =head2 $c->state
 518
 519 Contains the return value of the last executed action.
 520 Note that << $c->state >> operates in a scalar context which means that all
 521 values it returns are scalar.
 522
 523 =head2 $c->clear_errors
 524
 525 Clear errors.  You probably don't want to clear the errors unless you are
 526 implementing a custom error screen.
 527
 528 This is equivalent to running
 529
 530     $c->error(0);
 531
 532 =cut
 533
 534 sub clear_errors {
 535     my $c = shift;
 536     $c->error(0);
 537 }
 538
 539 =head2 COMPONENT ACCESSORS
 540
 541 =head2 $c->controller($name)
 542
 543 Gets a L<Catalyst::Controller> instance by name.
 544
 545     $c->controller('Foo')->do_stuff;
 546
 547 If the name is omitted, will return the controller for the dispatched
 548 action.
 549
 550 If you want to search for controllers, pass in a regexp as the argument.
 551
 552     # find all controllers that start with Foo
 553     my @foo_controllers = $c->controller(qr{^Foo});
 554
 555
 556 =cut
 557
 558 sub controller {
 559     my ( $c, $name, @args ) = @_;
 560     my $container = $c->container->get_sub_container('controller');
 561
 562     my $appclass = ref $c || $c;
 563     if( $name ) {
 564         if ( !ref $name ) { # Direct component hash lookup to avoid costly regexps
 565             return $container->resolve(service => $name, parameters => { context => [ $c, @args ] } )
 566                 if $container->has_service($name);
 567         }
 568
 569         return
 570             if $c->config->{disable_component_resolution_regex_fallback} && !ref $name;
 571
 572         my $query = ref $name ? $name : qr{$name}i;
 573         $query =~ s/^${appclass}::(C|Controller):://;
 574         my @comps = $container->get_service_list;
 575         my @result;
 576         for (@comps) {
 577             push @result, $container->resolve( service => $_, parameters => { context => [ $c, @args ] } )
 578                 if m/$query/;
 579         }
 580
 581         if (@result) {
 582             if (!ref $name) {
 583                 $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 584                 $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 585                 $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 586                 return shift @result;
 587             }
 588
 589             return @result;
 590         }
 591
 592         return;
 593     }
 594
 595     return $c->component( $c->action->class );
 596 }
 597
 598 =head2 $c->model($name)
 599
 600 Gets a L<Catalyst::Model> instance by name.
 601
 602     $c->model('Foo')->do_stuff;
 603
 604 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 605
 606 If the name is omitted, it will look for
 607  - a model object in $c->stash->{current_model_instance}, then
 608  - a model name in $c->stash->{current_model}, then
 609  - a config setting 'default_model', or
 610  - check if there is only one model, and return it if that's the case.
 611
 612 If you want to search for models, pass in a regexp as the argument.
 613
 614     # find all models that start with Foo
 615     my @foo_models = $c->model(qr{^Foo});
 616
 617 =cut
 618
 619 sub model {
 620     my ( $c, $name, @args ) = @_;
 621     my $appclass = ref($c) || $c;
 622     my $container = $c->container->get_sub_container('model');
 623
 624     if( $name ) {
 625         if ( !ref $name && $container->has_service($name)) { # Direct component hash lookup to avoid costly regexps
 626             return $container->resolve( service => $name, parameters => { context => [ $c, @args ] } );
 627         }
 628
 629         return
 630             if $c->config->{disable_component_resolution_regex_fallback} && !ref $name;
 631
 632         my $query = ref $name ? $name : qr{$name}i;
 633         $query =~ s/^${appclass}::(M|Model):://;
 634         my @comps = $container->get_service_list;
 635         my @result;
 636         for (@comps) {
 637             push @result, $container->resolve( service => $_, parameters => { context => [ $c, @args ] } )
 638                 if m/$query/;
 639         }
 640
 641         if (@result) {
 642             if (!ref $name) {
 643                 $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 644                 $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 645                 $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 646                 return shift @result;
 647             }
 648
 649             return @result;
 650         }
 651
 652         return;
 653     }
 654
 655     if (ref $c) {
 656         return $c->stash->{current_model_instance}
 657           if $c->stash->{current_model_instance};
 658         return $c->model( $c->stash->{current_model} )
 659           if $c->stash->{current_model};
 660     }
 661     return $c->model( $appclass->config->{default_model} )
 662       if $appclass->config->{default_model};
 663
 664 # FIXME: will this still be mantained?
 665     my( $comp, $rest ) = $container->get_service_list;
 666
 667     if( $rest ) {
 668         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 669         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 670         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 671         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 672         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 673     }
 674
 675     return $container->resolve( service => $comp, parameters => { context => [ $c, @args ] } );
 676 }
 677
 678
 679 =head2 $c->view($name)
 680
 681 Gets a L<Catalyst::View> instance by name.
 682
 683     $c->view('Foo')->do_stuff;
 684
 685 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 686
 687 If the name is omitted, it will look for
 688  - a view object in $c->stash->{current_view_instance}, then
 689  - a view name in $c->stash->{current_view}, then
 690  - a config setting 'default_view', or
 691  - check if there is only one view, and return it if that's the case.
 692
 693 If you want to search for views, pass in a regexp as the argument.
 694
 695     # find all views that start with Foo
 696     my @foo_views = $c->view(qr{^Foo});
 697
 698 =cut
 699
 700 sub view {
 701     my ( $c, $name, @args ) = @_;
 702     my $appclass = ref($c) || $c;
 703     my $container = $c->container->get_sub_container('view');
 704
 705     if( $name ) {
 706         if ( !ref $name ) { # Direct component hash lookup to avoid costly regexps
 707             if ( $container->has_service($name) ) {
 708                 return $container->resolve( service => $name, parameters => { context => [ $c, @args ] } );
 709             }
 710             else {
 711                 $c->log->warn( "Attempted to use view '$name', but does not exist" );
 712             }
 713         }
 714
 715         return
 716             if $c->config->{disable_component_resolution_regex_fallback} && !ref $name;
 717
 718         my $query = ref $name ? $name : qr{$name}i;
 719         $query =~ s/^${appclass}::(V|View):://;
 720         my @comps = $container->get_service_list;
 721         my @result;
 722         for (@comps) {
 723             push @result, $container->resolve( service => $_, parameters => { context => [ $c, @args ] } )
 724                 if m/$query/;
 725         }
 726
 727         if (@result) {
 728             if (!ref $name) {
 729                 $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 730                 $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 731                 $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 732                 return shift @result;
 733             }
 734
 735             return @result;
 736         }
 737
 738         return;
 739     }
 740
 741     if (ref $c) {
 742         return $c->stash->{current_view_instance}
 743           if $c->stash->{current_view_instance};
 744         return $c->view( $c->stash->{current_view} )
 745           if $c->stash->{current_view};
 746     }
 747     return $c->view( $appclass->config->{default_view} )
 748       if $appclass->config->{default_view};
 749
 750     my( $comp, $rest ) = $container->get_service_list;
 751
 752     if( $rest ) {
 753         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 754         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 755         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 756         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 757         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 758     }
 759
 760     return $container->resolve( service => $comp, parameters => { context => [ $c, @args ] } );
 761 }
 762
 763 =head2 $c->controllers
 764
 765 Returns the available names which can be passed to $c->controller
 766
 767 =cut
 768
 769 sub controllers {
 770     my ( $c ) = @_;
 771     return $c->container->get_sub_container('controller')->get_service_list;
 772 }
 773
 774 =head2 $c->models
 775
 776 Returns the available names which can be passed to $c->model
 777
 778 =cut
 779
 780 sub models {
 781     my ( $c ) = @_;
 782     return $c->container->get_sub_container('model')->get_service_list;
 783 }
 784
 785
 786 =head2 $c->views
 787
 788 Returns the available names which can be passed to $c->view
 789
 790 =cut
 791
 792 sub views {
 793     my ( $c ) = @_;
 794     return $c->container->get_sub_container('view')->get_service_list;
 795 }
 796
 797 =head2 $c->comp($name)
 798
 799 =head2 $c->component($name)
 800
 801 Gets a component object by name. This method is not recommended,
 802 unless you want to get a specific component by full
 803 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 804 should be used instead.
 805
 806 If C<$name> is a regexp, a list of components matched against the full
 807 component name will be returned.
 808
 809 If Catalyst can't find a component by name, it will fallback to regex
 810 matching by default. To disable this behaviour set
 811 disable_component_resolution_regex_fallback to a true value.
 812
 813     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 814
 815 =cut
 816
 817 sub component {
 818     my ( $c, $component, @args ) = @_;
 819
 820     if ( $component ) {
 821         my ($type, $name) = _get_component_type_name($component);
 822
 823         if ($type && $c->container->has_sub_container($type)) {
 824             my $container = $c->container->get_sub_container($type);
 825
 826             if( !ref $component && $container->has_service($name) ) {
 827                 return $container->resolve( service => $name, parameters => { context => [ $c, @args ] } );
 828             }
 829
 830             return
 831                 if $c->config->{disable_component_resolution_regex_fallback};
 832
 833             my $query      = qr{$name}i;
 834             my @components = $container->get_service_list;
 835             my @result     = grep { m{$query} } @components;
 836
 837             if (@result) {
 838                 $c->log->warn( Carp::shortmess(qq(Found results for "${component}" using regexp fallback)) );
 839                 $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 840                 $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 841
 842                 return $container->resolve( service => $result[0], parameters => { context => [$c, @args] } );
 843             }
 844         }
 845
 846         return
 847             if $c->config->{disable_component_resolution_regex_fallback} && !ref $component;
 848
 849         # This is here so $c->comp( '::M::' ) works
 850         my $query = ref $component ? $component : qr{$component}i;
 851
 852         for my $subcontainer_name (qw/model view controller/) {
 853             my $subcontainer = $c->container->get_sub_container($subcontainer_name);
 854             my @components   = $subcontainer->get_service_list;
 855             my @result       = grep { m{$query} } @components;
 856
 857             if (@result) {
 858                 return map { $subcontainer->resolve( service => $_, parameters => { context => [$c, @args] } ) } @result
 859                     if ref $component;
 860
 861                 $c->log->warn( Carp::shortmess(qq(Found results for "${component}" using regexp fallback)) );
 862                 $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 863                 $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 864
 865                 return $subcontainer->resolve( service => $result[0], parameters => { context => [$c, @args] } );
 866             }
 867         }
 868
 869         # I would expect to return an empty list here, but that breaks back-compat
 870     }
 871
 872     # fallback
 873     return sort keys %{ $c->components };
 874 }
 875
 876 =head2 CLASS DATA AND HELPER CLASSES
 877
 878 =head2 $c->config
 879
 880 Returns or takes a hashref containing the application's configuration.
 881
 882     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 883
 884 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 885 like C<myapp.conf> in your applications home directory. See
 886 L<Catalyst::Plugin::ConfigLoader>.
 887
 888 =head3 Cascading configuration
 889
 890 The config method is present on all Catalyst components, and configuration
 891 will be merged when an application is started. Configuration loaded with
 892 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 893 followed by configuration in your top level C<MyApp> class. These two
 894 configurations are merged, and then configuration data whose hash key matches a
 895 component name is merged with configuration for that component.
 896
 897 The configuration for a component is then passed to the C<new> method when a
 898 component is constructed.
 899
 900 For example:
 901
 902     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 903     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 904
 905 will mean that C<MyApp::Model::Foo> receives the following data when
 906 constructed:
 907
 908     MyApp::Model::Foo->new({
 909         bar => 'baz',
 910         quux => 'frob',
 911         overrides => 'me',
 912     });
 913
 914 It's common practice to use a Moose attribute
 915 on the receiving component to access the config value.
 916
 917     package MyApp::Model::Foo;
 918
 919     use Moose;
 920
 921     # this attr will receive 'baz' at construction time
 922     has 'bar' => (
 923         is  => 'rw',
 924         isa => 'Str',
 925     );
 926
 927 You can then get the value 'baz' by calling $c->model('Foo')->bar
 928 (or $self->bar inside code in the model).
 929
 930 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 931 as a way of reading config within your code, as this B<will not> give you the
 932 correctly merged config back. You B<MUST> take the config values supplied to
 933 the constructor and use those instead.
 934
 935 =cut
 936
 937 around config => sub {
 938     my $orig = shift;
 939     my $c = shift;
 940
 941     croak('Setting config after setup has been run is not allowed.')
 942         if ( @_ and $c->setup_finished );
 943
 944     $c->$orig(@_);
 945 };
 946
 947 =head2 $c->log
 948
 949 Returns the logging object instance. Unless it is already set, Catalyst
 950 sets this up with a L<Catalyst::Log> object. To use your own log class,
 951 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 952 C<< __PACKAGE__->setup >>.
 953
 954  __PACKAGE__->log( MyLogger->new );
 955  __PACKAGE__->setup;
 956
 957 And later:
 958
 959     $c->log->info( 'Now logging with my own logger!' );
 960
 961 Your log class should implement the methods described in
 962 L<Catalyst::Log>.
 963
 964
 965 =head2 $c->debug
 966
 967 Returns 1 if debug mode is enabled, 0 otherwise.
 968
 969 You can enable debug mode in several ways:
 970
 971 =over
 972
 973 =item By calling myapp_server.pl with the -d flag
 974
 975 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 976
 977 =item The -Debug option in your MyApp.pm
 978
 979 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 980
 981 =back
 982
 983 The first three also set the log level to 'debug'.
 984
 985 Calling C<< $c->debug(1) >> has no effect.
 986
 987 =cut
 988
 989 sub debug { 0 }
 990
 991 =head2 $c->dispatcher
 992
 993 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 994
 995 =head2 $c->engine
 996
 997 Returns the engine instance. See L<Catalyst::Engine>.
 998
 999
1000 =head2 UTILITY METHODS
1001
1002 =head2 $c->path_to(@path)
1003
1004 Merges C<@path> with C<< $c->config->{home} >> and returns a
1005 L<Path::Class::Dir> object. Note you can usually use this object as
1006 a filename, but sometimes you will have to explicitly stringify it
1007 yourself by calling the C<< ->stringify >> method.
1008
1009 For example:
1010
1011     $c->path_to( 'db', 'sqlite.db' );
1012
1013 =cut
1014
1015 sub path_to {
1016     my ( $c, @path ) = @_;
1017     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1018     if ( -d $path ) { return $path }
1019     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1020 }
1021
1022 =head2 $c->plugin( $name, $class, @args )
1023
1024 Helper method for plugins. It creates a class data accessor/mutator and
1025 loads and instantiates the given class.
1026
1027     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1028
1029     $c->prototype->define_javascript_functions;
1030
1031 B<Note:> This method of adding plugins is deprecated. The ability
1032 to add plugins like this B<will be removed> in a Catalyst 5.81.
1033 Please do not use this functionality in new code.
1034
1035 =cut
1036
1037 sub plugin {
1038     my ( $class, $name, $plugin, @args ) = @_;
1039
1040     # See block comment in t/unit_core_plugin.t
1041     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1042
1043     $class->_register_plugin( $plugin, 1 );
1044
1045     eval { $plugin->import };
1046     $class->mk_classdata($name);
1047     my $obj;
1048     eval { $obj = $plugin->new(@args) };
1049
1050     if ($@) {
1051         Catalyst::Exception->throw( message =>
1052               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1053     }
1054
1055     $class->$name($obj);
1056     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1057       if $class->debug;
1058 }
1059
1060 =head2 MyApp->setup
1061
1062 Initializes the dispatcher and engine, loads any plugins, and loads the
1063 model, view, and controller components. You may also specify an array
1064 of plugins to load here, if you choose to not load them in the C<use
1065 Catalyst> line.
1066
1067     MyApp->setup;
1068     MyApp->setup( qw/-Debug/ );
1069
1070 =cut
1071
1072 sub setup {
1073     my ( $class, @arguments ) = @_;
1074     croak('Running setup more than once')
1075         if ( $class->setup_finished );
1076
1077     unless ( $class->isa('Catalyst') ) {
1078
1079         Catalyst::Exception->throw(
1080             message => qq/'$class' does not inherit from Catalyst/ );
1081     }
1082
1083     if ( $class->arguments ) {
1084         @arguments = ( @arguments, @{ $class->arguments } );
1085     }
1086
1087     # Process options
1088     my $flags = {};
1089
1090     foreach (@arguments) {
1091
1092         if (/^-Debug$/) {
1093             $flags->{log} =
1094               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1095         }
1096         elsif (/^-(\w+)=?(.*)$/) {
1097             $flags->{ lc $1 } = $2;
1098         }
1099         else {
1100             push @{ $flags->{plugins} }, $_;
1101         }
1102     }
1103
1104     $class->setup_config();
1105     $class->setup_home( delete $flags->{home} );
1106
1107     $class->setup_log( delete $flags->{log} );
1108     $class->setup_plugins( delete $flags->{plugins} );
1109     $class->setup_dispatcher( delete $flags->{dispatcher} );
1110     $class->setup_engine( delete $flags->{engine} );
1111     $class->setup_stats( delete $flags->{stats} );
1112
1113     for my $flag ( sort keys %{$flags} ) {
1114
1115         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1116             &$code( $class, delete $flags->{$flag} );
1117         }
1118         else {
1119             $class->log->warn(qq/Unknown flag "$flag"/);
1120         }
1121     }
1122
1123     eval { require Catalyst::Devel; };
1124     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1125         $class->log->warn(<<"EOF");
1126 You are running an old script!
1127
1128   Please update by running (this will overwrite existing files):
1129     catalyst.pl -force -scripts $class
1130
1131   or (this will not overwrite existing files):
1132     catalyst.pl -scripts $class
1133
1134 EOF
1135     }
1136
1137     if ( $class->debug ) {
1138         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1139
1140         if (@plugins) {
1141             my $column_width = Catalyst::Utils::term_width() - 6;
1142             my $t = Text::SimpleTable->new($column_width);
1143             $t->row($_) for @plugins;
1144             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1145         }
1146
1147         my $dispatcher = $class->dispatcher;
1148         my $engine     = $class->engine;
1149         my $home       = $class->config->{home};
1150
1151         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1152         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1153
1154         $home
1155           ? ( -d $home )
1156           ? $class->log->debug(qq/Found home "$home"/)
1157           : $class->log->debug(qq/Home "$home" doesn't exist/)
1158           : $class->log->debug(q/Couldn't find home/);
1159     }
1160
1161     # Call plugins setup, this is stupid and evil.
1162     # Also screws C3 badly on 5.10, hack to avoid.
1163     {
1164         no warnings qw/redefine/;
1165         local *setup = sub { };
1166         $class->setup unless $Catalyst::__AM_RESTARTING;
1167     }
1168
1169     # Initialize our data structure
1170     $class->components( {} );
1171
1172     $class->setup_components;
1173
1174     if ( $class->debug ) {
1175         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1176         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1177         for my $comp ( sort keys %{ $class->components } ) {
1178             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1179             $t->row( $comp, $type );
1180         }
1181         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1182           if ( keys %{ $class->components } );
1183     }
1184
1185     # Add our self to components, since we are also a component
1186     if( $class->isa('Catalyst::Controller') ){
1187       $class->components->{$class} = $class;
1188     }
1189
1190     $class->setup_actions;
1191
1192     if ( $class->debug ) {
1193         my $name = $class->config->{name} || 'Application';
1194         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1195     }
1196
1197     # Make sure that the application class becomes immutable at this point,
1198     B::Hooks::EndOfScope::on_scope_end {
1199         return if $@;
1200         my $meta = Class::MOP::get_metaclass_by_name($class);
1201         if (
1202             $meta->is_immutable
1203             && ! { $meta->immutable_options }->{replace_constructor}
1204             && (
1205                    $class->isa('Class::Accessor::Fast')
1206                 || $class->isa('Class::Accessor')
1207             )
1208         ) {
1209             warn "You made your application class ($class) immutable, "
1210                 . "but did not inline the\nconstructor. "
1211                 . "This will break catalyst, as your app \@ISA "
1212                 . "Class::Accessor(::Fast)?\nPlease pass "
1213                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1214         }
1215         $meta->make_immutable(
1216             replace_constructor => 1,
1217         ) unless $meta->is_immutable;
1218     };
1219
1220     if ($class->config->{case_sensitive}) {
1221         $class->log->warn($class . "->config->{case_sensitive} is set.");
1222         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1223     }
1224
1225     $class->setup_finalize;
1226     # Should be the last thing we do so that user things hooking
1227     # setup_finalize can log..
1228     $class->log->_flush() if $class->log->can('_flush');
1229     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1230 }
1231
1232 =head2 $app->setup_finalize
1233
1234 A hook to attach modifiers to. This method does not do anything except set the
1235 C<setup_finished> accessor.
1236
1237 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1238
1239 Example:
1240
1241     after setup_finalize => sub {
1242         my $app = shift;
1243
1244         ## do stuff here..
1245     };
1246
1247 =cut
1248
1249 sub setup_finalize {
1250     my ($class) = @_;
1251     $class->setup_finished(1);
1252 }
1253
1254 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1255
1256 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1257
1258 Constructs an absolute L<URI> object based on the application root, the
1259 provided path, and the additional arguments and query parameters provided.
1260 When used as a string, provides a textual URI.  If you need more flexibility
1261 than this (i.e. the option to provide relative URIs etc.) see
1262 L<Catalyst::Plugin::SmartURI>.
1263
1264 If no arguments are provided, the URI for the current action is returned.
1265 To return the current action and also provide @args, use
1266 C<< $c->uri_for( $c->action, @args ) >>.
1267
1268 If the first argument is a string, it is taken as a public URI path relative
1269 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1270 relative to the application root (if it does). It is then merged with
1271 C<< $c->request->base >>; any C<@args> are appended as additional path
1272 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1273
1274 If the first argument is a L<Catalyst::Action> it represents an action which
1275 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1276 optional C<\@captures> argument (an arrayref) allows passing the captured
1277 variables that are needed to fill in the paths of Chained and Regex actions;
1278 once the path is resolved, C<uri_for> continues as though a path was
1279 provided, appending any arguments or parameters and creating an absolute
1280 URI.
1281
1282 The captures for the current request can be found in
1283 C<< $c->request->captures >>, and actions can be resolved using
1284 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1285 path, use C<< $c->uri_for_action >> instead.
1286
1287   # Equivalent to $c->req->uri
1288   $c->uri_for($c->action, $c->req->captures,
1289       @{ $c->req->args }, $c->req->params);
1290
1291   # For the Foo action in the Bar controller
1292   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1293
1294   # Path to a static resource
1295   $c->uri_for('/static/images/logo.png');
1296
1297 =cut
1298
1299 sub uri_for {
1300     my ( $c, $path, @args ) = @_;
1301
1302     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1303         $path = $path->path_prefix;
1304         $path =~ s{/+\z}{};
1305         $path .= '/';
1306     }
1307
1308     undef($path) if (defined $path && $path eq '');
1309
1310     my $params =
1311       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1312
1313     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1314     foreach my $arg (@args) {
1315         utf8::encode($arg) if utf8::is_utf8($arg);
1316         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1317     }
1318
1319     if ( blessed($path) ) { # action object
1320         s|/|%2F|g for @args;
1321         my $captures = [ map { s|/|%2F|g; $_; }
1322                         ( scalar @args && ref $args[0] eq 'ARRAY'
1323                          ? @{ shift(@args) }
1324                          : ()) ];
1325
1326         foreach my $capture (@$captures) {
1327             utf8::encode($capture) if utf8::is_utf8($capture);
1328             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1329         }
1330
1331         my $action = $path;
1332         $path = $c->dispatcher->uri_for_action($action, $captures);
1333         if (not defined $path) {
1334             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1335                 if $c->debug;
1336             return undef;
1337         }
1338         $path = '/' if $path eq '';
1339     }
1340
1341     unshift(@args, $path);
1342
1343     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1344         my $namespace = $c->namespace;
1345         if (defined $path) { # cheesy hack to handle path '../foo'
1346            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1347         }
1348         unshift(@args, $namespace || '');
1349     }
1350
1351     # join args with '/', or a blank string
1352     my $args = join('/', grep { defined($_) } @args);
1353     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1354     $args =~ s!^/+!!;
1355     my $base = $c->req->base;
1356     my $class = ref($base);
1357     $base =~ s{(?<!/)$}{/};
1358
1359     my $query = '';
1360
1361     if (my @keys = keys %$params) {
1362       # somewhat lifted from URI::_query's query_form
1363       $query = '?'.join('&', map {
1364           my $val = $params->{$_};
1365           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1366           s/ /+/g;
1367           my $key = $_;
1368           $val = '' unless defined $val;
1369           (map {
1370               my $param = "$_";
1371               utf8::encode( $param ) if utf8::is_utf8($param);
1372               # using the URI::Escape pattern here so utf8 chars survive
1373               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1374               $param =~ s/ /+/g;
1375               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1376       } @keys);
1377     }
1378
1379     my $res = bless(\"${base}${args}${query}", $class);
1380     $res;
1381 }
1382
1383 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1384
1385 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1386
1387 =over
1388
1389 =item $path
1390
1391 A private path to the Catalyst action you want to create a URI for.
1392
1393 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1394 >> and passing the resulting C<$action> and the remaining arguments to C<<
1395 $c->uri_for >>.
1396
1397 You can also pass in a Catalyst::Action object, in which case it is passed to
1398 C<< $c->uri_for >>.
1399
1400 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1401
1402 For example, if the action looks like:
1403
1404  package MyApp::Controller::Users;
1405
1406  sub lst : Path('the-list') {}
1407
1408 You can use:
1409
1410  $c->uri_for_action('/users/lst')
1411
1412 and it will create the URI /users/the-list.
1413
1414 =back
1415
1416 =cut
1417
1418 sub uri_for_action {
1419     my ( $c, $path, @args ) = @_;
1420     my $action = blessed($path)
1421       ? $path
1422       : $c->dispatcher->get_action_by_path($path);
1423     unless (defined $action) {
1424       croak "Can't find action for path '$path'";
1425     }
1426     return $c->uri_for( $action, @args );
1427 }
1428
1429 =head2 $c->welcome_message
1430
1431 Returns the Catalyst welcome HTML page.
1432
1433 =cut
1434
1435 sub welcome_message {
1436     my $c      = shift;
1437     my $name   = $c->config->{name};
1438     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1439     my $prefix = Catalyst::Utils::appprefix( ref $c );
1440     $c->response->content_type('text/html; charset=utf-8');
1441     return <<"EOF";
1442 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1443     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1444 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1445     <head>
1446     <meta http-equiv="Content-Language" content="en" />
1447     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1448         <title>$name on Catalyst $VERSION</title>
1449         <style type="text/css">
1450             body {
1451                 color: #000;
1452                 background-color: #eee;
1453             }
1454             div#content {
1455                 width: 640px;
1456                 margin-left: auto;
1457                 margin-right: auto;
1458                 margin-top: 10px;
1459                 margin-bottom: 10px;
1460                 text-align: left;
1461                 background-color: #ccc;
1462                 border: 1px solid #aaa;
1463             }
1464             p, h1, h2 {
1465                 margin-left: 20px;
1466                 margin-right: 20px;
1467                 font-family: verdana, tahoma, sans-serif;
1468             }
1469             a {
1470                 font-family: verdana, tahoma, sans-serif;
1471             }
1472             :link, :visited {
1473                     text-decoration: none;
1474                     color: #b00;
1475                     border-bottom: 1px dotted #bbb;
1476             }
1477             :link:hover, :visited:hover {
1478                     color: #555;
1479             }
1480             div#topbar {
1481                 margin: 0px;
1482             }
1483             pre {
1484                 margin: 10px;
1485                 padding: 8px;
1486             }
1487             div#answers {
1488                 padding: 8px;
1489                 margin: 10px;
1490                 background-color: #fff;
1491                 border: 1px solid #aaa;
1492             }
1493             h1 {
1494                 font-size: 0.9em;
1495                 font-weight: normal;
1496                 text-align: center;
1497             }
1498             h2 {
1499                 font-size: 1.0em;
1500             }
1501             p {
1502                 font-size: 0.9em;
1503             }
1504             p img {
1505                 float: right;
1506                 margin-left: 10px;
1507             }
1508             span#appname {
1509                 font-weight: bold;
1510                 font-size: 1.6em;
1511             }
1512         </style>
1513     </head>
1514     <body>
1515         <div id="content">
1516             <div id="topbar">
1517                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1518                     $VERSION</h1>
1519              </div>
1520              <div id="answers">
1521                  <p>
1522                  <img src="$logo" alt="Catalyst Logo" />
1523                  </p>
1524                  <p>Welcome to the  world of Catalyst.
1525                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1526                     framework will make web development something you had
1527                     never expected it to be: Fun, rewarding, and quick.</p>
1528                  <h2>What to do now?</h2>
1529                  <p>That really depends  on what <b>you</b> want to do.
1530                     We do, however, provide you with a few starting points.</p>
1531                  <p>If you want to jump right into web development with Catalyst
1532                     you might want to start with a tutorial.</p>
1533 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1534 </pre>
1535 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1536 <pre>
1537 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1538 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1539 </code></pre>
1540                  <h2>What to do next?</h2>
1541                  <p>Next it's time to write an actual application. Use the
1542                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1543                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1544                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1545                     they can save you a lot of work.</p>
1546                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1547                     <p>Also, be sure to check out the vast and growing
1548                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1549                     you are likely to find what you need there.
1550                     </p>
1551
1552                  <h2>Need help?</h2>
1553                  <p>Catalyst has a very active community. Here are the main places to
1554                     get in touch with us.</p>
1555                  <ul>
1556                      <li>
1557                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1558                      </li>
1559                      <li>
1560                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1561                      </li>
1562                      <li>
1563                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1564                      </li>
1565                  </ul>
1566                  <h2>In conclusion</h2>
1567                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1568                     as we enjoyed making it. Please contact us if you have ideas
1569                     for improvement or other feedback.</p>
1570              </div>
1571          </div>
1572     </body>
1573 </html>
1574 EOF
1575 }
1576
1577 =head1 INTERNAL METHODS
1578
1579 These methods are not meant to be used by end users.
1580
1581 =head2 $c->components
1582
1583 Returns a hash of components.
1584
1585 =cut
1586
1587 around components => sub {
1588     my $orig  = shift;
1589     my $class = shift;
1590     my $comps = shift;
1591
1592     return $class->$orig if ( !$comps );
1593
1594 # FIXME: should this ugly kludge exist?
1595     $class->setup_config unless defined $class->container;
1596
1597 # FIXME: should there be a warning here, not to use this accessor to create the components?
1598     my $components = {};
1599
1600     my $containers;
1601     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
1602
1603     for my $component ( keys %$comps ) {
1604         $components->{ $component } = $comps->{$component};
1605
1606         my ($type, $name) = _get_component_type_name($component);
1607
1608 # FIXME: shouldn't the service name be $name?
1609         $containers->{$type}->add_service(Catalyst::BlockInjection->new( name => $name, block => sub { return $class->setup_component($component) } ));
1610     }
1611
1612     return $class->$orig($components);
1613 };
1614
1615 =head2 $c->context_class
1616
1617 Returns or sets the context class.
1618
1619 =head2 $c->counter
1620
1621 Returns a hashref containing coderefs and execution counts (needed for
1622 deep recursion detection).
1623
1624 =head2 $c->depth
1625
1626 Returns the number of actions on the current internal execution stack.
1627
1628 =head2 $c->dispatch
1629
1630 Dispatches a request to actions.
1631
1632 =cut
1633
1634 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1635
1636 =head2 $c->dispatcher_class
1637
1638 Returns or sets the dispatcher class.
1639
1640 =head2 $c->dump_these
1641
1642 Returns a list of 2-element array references (name, structure) pairs
1643 that will be dumped on the error page in debug mode.
1644
1645 =cut
1646
1647 sub dump_these {
1648     my $c = shift;
1649     [ Request => $c->req ],
1650     [ Response => $c->res ],
1651     [ Stash => $c->stash ],
1652     [ Config => $c->config ];
1653 }
1654
1655 =head2 $c->engine_class
1656
1657 Returns or sets the engine class.
1658
1659 =head2 $c->execute( $class, $coderef )
1660
1661 Execute a coderef in given class and catch exceptions. Errors are available
1662 via $c->error.
1663
1664 =cut
1665
1666 sub execute {
1667     my ( $c, $class, $code ) = @_;
1668     $class = $c->component($class) || $class;
1669     $c->state(0);
1670
1671     if ( $c->depth >= $RECURSION ) {
1672         my $action = $code->reverse();
1673         $action = "/$action" unless $action =~ /->/;
1674         my $error = qq/Deep recursion detected calling "${action}"/;
1675         $c->log->error($error);
1676         $c->error($error);
1677         $c->state(0);
1678         return $c->state;
1679     }
1680
1681     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1682
1683     push( @{ $c->stack }, $code );
1684
1685     no warnings 'recursion';
1686     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1687     #      I have no idea how, ergo $ret (which appears to fix the issue)
1688     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1689
1690     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1691
1692     my $last = pop( @{ $c->stack } );
1693
1694     if ( my $error = $@ ) {
1695         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1696             $error->rethrow if $c->depth > 1;
1697         }
1698         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1699             $error->rethrow if $c->depth > 0;
1700         }
1701         else {
1702             unless ( ref $error ) {
1703                 no warnings 'uninitialized';
1704                 chomp $error;
1705                 my $class = $last->class;
1706                 my $name  = $last->name;
1707                 $error = qq/Caught exception in $class->$name "$error"/;
1708             }
1709             $c->error($error);
1710         }
1711         $c->state(0);
1712     }
1713     return $c->state;
1714 }
1715
1716 sub _stats_start_execute {
1717     my ( $c, $code ) = @_;
1718     my $appclass = ref($c) || $c;
1719     return if ( ( $code->name =~ /^_.*/ )
1720         && ( !$appclass->config->{show_internal_actions} ) );
1721
1722     my $action_name = $code->reverse();
1723     $c->counter->{$action_name}++;
1724
1725     my $action = $action_name;
1726     $action = "/$action" unless $action =~ /->/;
1727
1728     # determine if the call was the result of a forward
1729     # this is done by walking up the call stack and looking for a calling
1730     # sub of Catalyst::forward before the eval
1731     my $callsub = q{};
1732     for my $index ( 2 .. 11 ) {
1733         last
1734         if ( ( caller($index) )[0] eq 'Catalyst'
1735             && ( caller($index) )[3] eq '(eval)' );
1736
1737         if ( ( caller($index) )[3] =~ /forward$/ ) {
1738             $callsub = ( caller($index) )[3];
1739             $action  = "-> $action";
1740             last;
1741         }
1742     }
1743
1744     my $uid = $action_name . $c->counter->{$action_name};
1745
1746     # is this a root-level call or a forwarded call?
1747     if ( $callsub =~ /forward$/ ) {
1748         my $parent = $c->stack->[-1];
1749
1750         # forward, locate the caller
1751         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1752             $c->stats->profile(
1753                 begin  => $action,
1754                 parent => "$parent" . $c->counter->{"$parent"},
1755                 uid    => $uid,
1756             );
1757         }
1758         else {
1759
1760             # forward with no caller may come from a plugin
1761             $c->stats->profile(
1762                 begin => $action,
1763                 uid   => $uid,
1764             );
1765         }
1766     }
1767     else {
1768
1769         # root-level call
1770         $c->stats->profile(
1771             begin => $action,
1772             uid   => $uid,
1773         );
1774     }
1775     return $action;
1776
1777 }
1778
1779 sub _stats_finish_execute {
1780     my ( $c, $info ) = @_;
1781     $c->stats->profile( end => $info );
1782 }
1783
1784 =head2 $c->finalize
1785
1786 Finalizes the request.
1787
1788 =cut
1789
1790 sub finalize {
1791     my $c = shift;
1792
1793     for my $error ( @{ $c->error } ) {
1794         $c->log->error($error);
1795     }
1796
1797     # Allow engine to handle finalize flow (for POE)
1798     my $engine = $c->engine;
1799     if ( my $code = $engine->can('finalize') ) {
1800         $engine->$code($c);
1801     }
1802     else {
1803
1804         $c->finalize_uploads;
1805
1806         # Error
1807         if ( $#{ $c->error } >= 0 ) {
1808             $c->finalize_error;
1809         }
1810
1811         $c->finalize_headers;
1812
1813         # HEAD request
1814         if ( $c->request->method eq 'HEAD' ) {
1815             $c->response->body('');
1816         }
1817
1818         $c->finalize_body;
1819     }
1820
1821     $c->log_response;
1822
1823     if ($c->use_stats) {
1824         my $elapsed = sprintf '%f', $c->stats->elapsed;
1825         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1826         $c->log->info(
1827             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1828     }
1829
1830     return $c->response->status;
1831 }
1832
1833 =head2 $c->finalize_body
1834
1835 Finalizes body.
1836
1837 =cut
1838
1839 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1840
1841 =head2 $c->finalize_cookies
1842
1843 Finalizes cookies.
1844
1845 =cut
1846
1847 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1848
1849 =head2 $c->finalize_error
1850
1851 Finalizes error.
1852
1853 =cut
1854
1855 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1856
1857 =head2 $c->finalize_headers
1858
1859 Finalizes headers.
1860
1861 =cut
1862
1863 sub finalize_headers {
1864     my $c = shift;
1865
1866     my $response = $c->response; #accessor calls can add up?
1867
1868     # Check if we already finalized headers
1869     return if $response->finalized_headers;
1870
1871     # Handle redirects
1872     if ( my $location = $response->redirect ) {
1873         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1874         $response->header( Location => $location );
1875
1876         if ( !$response->has_body ) {
1877             # Add a default body if none is already present
1878             $response->body(
1879                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1880             );
1881         }
1882     }
1883
1884     # Content-Length
1885     if ( defined $response->body && length $response->body && !$response->content_length ) {
1886
1887         # get the length from a filehandle
1888         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1889         {
1890             my $stat = stat $response->body;
1891             if ( $stat && $stat->size > 0 ) {
1892                 $response->content_length( $stat->size );
1893             }
1894             else {
1895                 $c->log->warn('Serving filehandle without a content-length');
1896             }
1897         }
1898         else {
1899             # everything should be bytes at this point, but just in case
1900             $response->content_length( length( $response->body ) );
1901         }
1902     }
1903
1904     # Errors
1905     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1906         $response->headers->remove_header("Content-Length");
1907         $response->body('');
1908     }
1909
1910     $c->finalize_cookies;
1911
1912     $c->engine->finalize_headers( $c, @_ );
1913
1914     # Done
1915     $response->finalized_headers(1);
1916 }
1917
1918 =head2 $c->finalize_output
1919
1920 An alias for finalize_body.
1921
1922 =head2 $c->finalize_read
1923
1924 Finalizes the input after reading is complete.
1925
1926 =cut
1927
1928 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1929
1930 =head2 $c->finalize_uploads
1931
1932 Finalizes uploads. Cleans up any temporary files.
1933
1934 =cut
1935
1936 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1937
1938 =head2 $c->get_action( $action, $namespace )
1939
1940 Gets an action in a given namespace.
1941
1942 =cut
1943
1944 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1945
1946 =head2 $c->get_actions( $action, $namespace )
1947
1948 Gets all actions of a given name in a namespace and all parent
1949 namespaces.
1950
1951 =cut
1952
1953 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1954
1955 =head2 $app->handle_request( @arguments )
1956
1957 Called to handle each HTTP request.
1958
1959 =cut
1960
1961 sub handle_request {
1962     my ( $class, @arguments ) = @_;
1963
1964     # Always expect worst case!
1965     my $status = -1;
1966     eval {
1967         if ($class->debug) {
1968             my $secs = time - $START || 1;
1969             my $av = sprintf '%.3f', $COUNT / $secs;
1970             my $time = localtime time;
1971             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1972         }
1973
1974         my $c = $class->prepare(@arguments);
1975         $c->dispatch;
1976         $status = $c->finalize;
1977     };
1978
1979     if ( my $error = $@ ) {
1980         chomp $error;
1981         $class->log->error(qq/Caught exception in engine "$error"/);
1982     }
1983
1984     $COUNT++;
1985
1986     if(my $coderef = $class->log->can('_flush')){
1987         $class->log->$coderef();
1988     }
1989     return $status;
1990 }
1991
1992 =head2 $c->prepare( @arguments )
1993
1994 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1995 etc.).
1996
1997 =cut
1998
1999 sub prepare {
2000     my ( $class, @arguments ) = @_;
2001
2002     # XXX
2003     # After the app/ctxt split, this should become an attribute based on something passed
2004     # into the application.
2005     $class->context_class( ref $class || $class ) unless $class->context_class;
2006
2007     my $c = $class->context_class->new({});
2008
2009     # For on-demand data
2010     $c->request->_context($c);
2011     $c->response->_context($c);
2012
2013     #surely this is not the most efficient way to do things...
2014     $c->stats($class->stats_class->new)->enable($c->use_stats);
2015     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2016         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2017     }
2018
2019     #XXX reuse coderef from can
2020     # Allow engine to direct the prepare flow (for POE)
2021     if ( $c->engine->can('prepare') ) {
2022         $c->engine->prepare( $c, @arguments );
2023     }
2024     else {
2025         $c->prepare_request(@arguments);
2026         $c->prepare_connection;
2027         $c->prepare_query_parameters;
2028         $c->prepare_headers;
2029         $c->prepare_cookies;
2030         $c->prepare_path;
2031
2032         # Prepare the body for reading, either by prepare_body
2033         # or the user, if they are using $c->read
2034         $c->prepare_read;
2035
2036         # Parse the body unless the user wants it on-demand
2037         unless ( ref($c)->config->{parse_on_demand} ) {
2038             $c->prepare_body;
2039         }
2040     }
2041
2042     my $method  = $c->req->method  || '';
2043     my $path    = $c->req->path;
2044     $path       = '/' unless length $path;
2045     my $address = $c->req->address || '';
2046
2047     $c->log_request;
2048
2049     $c->prepare_action;
2050
2051     return $c;
2052 }
2053
2054 =head2 $c->prepare_action
2055
2056 Prepares action. See L<Catalyst::Dispatcher>.
2057
2058 =cut
2059
2060 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2061
2062 =head2 $c->prepare_body
2063
2064 Prepares message body.
2065
2066 =cut
2067
2068 sub prepare_body {
2069     my $c = shift;
2070
2071     return if $c->request->_has_body;
2072
2073     # Initialize on-demand data
2074     $c->engine->prepare_body( $c, @_ );
2075     $c->prepare_parameters;
2076     $c->prepare_uploads;
2077 }
2078
2079 =head2 $c->prepare_body_chunk( $chunk )
2080
2081 Prepares a chunk of data before sending it to L<HTTP::Body>.
2082
2083 See L<Catalyst::Engine>.
2084
2085 =cut
2086
2087 sub prepare_body_chunk {
2088     my $c = shift;
2089     $c->engine->prepare_body_chunk( $c, @_ );
2090 }
2091
2092 =head2 $c->prepare_body_parameters
2093
2094 Prepares body parameters.
2095
2096 =cut
2097
2098 sub prepare_body_parameters {
2099     my $c = shift;
2100     $c->engine->prepare_body_parameters( $c, @_ );
2101 }
2102
2103 =head2 $c->prepare_connection
2104
2105 Prepares connection.
2106
2107 =cut
2108
2109 sub prepare_connection {
2110     my $c = shift;
2111     $c->engine->prepare_connection( $c, @_ );
2112 }
2113
2114 =head2 $c->prepare_cookies
2115
2116 Prepares cookies.
2117
2118 =cut
2119
2120 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2121
2122 =head2 $c->prepare_headers
2123
2124 Prepares headers.
2125
2126 =cut
2127
2128 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2129
2130 =head2 $c->prepare_parameters
2131
2132 Prepares parameters.
2133
2134 =cut
2135
2136 sub prepare_parameters {
2137     my $c = shift;
2138     $c->prepare_body_parameters;
2139     $c->engine->prepare_parameters( $c, @_ );
2140 }
2141
2142 =head2 $c->prepare_path
2143
2144 Prepares path and base.
2145
2146 =cut
2147
2148 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2149
2150 =head2 $c->prepare_query_parameters
2151
2152 Prepares query parameters.
2153
2154 =cut
2155
2156 sub prepare_query_parameters {
2157     my $c = shift;
2158
2159     $c->engine->prepare_query_parameters( $c, @_ );
2160 }
2161
2162 =head2 $c->log_request
2163
2164 Writes information about the request to the debug logs.  This includes:
2165
2166 =over 4
2167
2168 =item * Request method, path, and remote IP address
2169
2170 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2171
2172 =item * Request parameters
2173
2174 =item * File uploads
2175
2176 =back
2177
2178 =cut
2179
2180 sub log_request {
2181     my $c = shift;
2182
2183     return unless $c->debug;
2184
2185     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2186     my $request = $dump->[1];
2187
2188     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2189     $method ||= '';
2190     $path = '/' unless length $path;
2191     $address ||= '';
2192     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2193
2194     $c->log_request_headers($request->headers);
2195
2196     if ( my $keywords = $request->query_keywords ) {
2197         $c->log->debug("Query keywords are: $keywords");
2198     }
2199
2200     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2201
2202     $c->log_request_uploads($request);
2203 }
2204
2205 =head2 $c->log_response
2206
2207 Writes information about the response to the debug logs by calling
2208 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2209
2210 =cut
2211
2212 sub log_response {
2213     my $c = shift;
2214
2215     return unless $c->debug;
2216
2217     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2218     my $response = $dump->[1];
2219
2220     $c->log_response_status_line($response);
2221     $c->log_response_headers($response->headers);
2222 }
2223
2224 =head2 $c->log_response_status_line($response)
2225
2226 Writes one line of information about the response to the debug logs.  This includes:
2227
2228 =over 4
2229
2230 =item * Response status code
2231
2232 =item * Content-Type header (if present)
2233
2234 =item * Content-Length header (if present)
2235
2236 =back
2237
2238 =cut
2239
2240 sub log_response_status_line {
2241     my ($c, $response) = @_;
2242
2243     $c->log->debug(
2244         sprintf(
2245             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2246             $response->status                            || 'unknown',
2247             $response->headers->header('Content-Type')   || 'unknown',
2248             $response->headers->header('Content-Length') || 'unknown'
2249         )
2250     );
2251 }
2252
2253 =head2 $c->log_response_headers($headers);
2254
2255 Hook method which can be wrapped by plugins to log the responseheaders.
2256 No-op in the default implementation.
2257
2258 =cut
2259
2260 sub log_response_headers {}
2261
2262 =head2 $c->log_request_parameters( query => {}, body => {} )
2263
2264 Logs request parameters to debug logs
2265
2266 =cut
2267
2268 sub log_request_parameters {
2269     my $c          = shift;
2270     my %all_params = @_;
2271
2272     return unless $c->debug;
2273
2274     my $column_width = Catalyst::Utils::term_width() - 44;
2275     foreach my $type (qw(query body)) {
2276         my $params = $all_params{$type};
2277         next if ! keys %$params;
2278         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2279         for my $key ( sort keys %$params ) {
2280             my $param = $params->{$key};
2281             my $value = defined($param) ? $param : '';
2282             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2283         }
2284         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2285     }
2286 }
2287
2288 =head2 $c->log_request_uploads
2289
2290 Logs file uploads included in the request to the debug logs.
2291 The parameter name, filename, file type, and file size are all included in
2292 the debug logs.
2293
2294 =cut
2295
2296 sub log_request_uploads {
2297     my $c = shift;
2298     my $request = shift;
2299     return unless $c->debug;
2300     my $uploads = $request->uploads;
2301     if ( keys %$uploads ) {
2302         my $t = Text::SimpleTable->new(
2303             [ 12, 'Parameter' ],
2304             [ 26, 'Filename' ],
2305             [ 18, 'Type' ],
2306             [ 9,  'Size' ]
2307         );
2308         for my $key ( sort keys %$uploads ) {
2309             my $upload = $uploads->{$key};
2310             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2311                 $t->row( $key, $u->filename, $u->type, $u->size );
2312             }
2313         }
2314         $c->log->debug( "File Uploads are:\n" . $t->draw );
2315     }
2316 }
2317
2318 =head2 $c->log_request_headers($headers);
2319
2320 Hook method which can be wrapped by plugins to log the request headers.
2321 No-op in the default implementation.
2322
2323 =cut
2324
2325 sub log_request_headers {}
2326
2327 =head2 $c->log_headers($type => $headers)
2328
2329 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2330
2331 =cut
2332
2333 sub log_headers {
2334     my $c       = shift;
2335     my $type    = shift;
2336     my $headers = shift;    # an HTTP::Headers instance
2337
2338     return unless $c->debug;
2339
2340     my $column_width = Catalyst::Utils::term_width() - 28;
2341     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2342     $headers->scan(
2343         sub {
2344             my ( $name, $value ) = @_;
2345             $t->row( $name, $value );
2346         }
2347     );
2348     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2349 }
2350
2351
2352 =head2 $c->prepare_read
2353
2354 Prepares the input for reading.
2355
2356 =cut
2357
2358 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2359
2360 =head2 $c->prepare_request
2361
2362 Prepares the engine request.
2363
2364 =cut
2365
2366 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2367
2368 =head2 $c->prepare_uploads
2369
2370 Prepares uploads.
2371
2372 =cut
2373
2374 sub prepare_uploads {
2375     my $c = shift;
2376
2377     $c->engine->prepare_uploads( $c, @_ );
2378 }
2379
2380 =head2 $c->prepare_write
2381
2382 Prepares the output for writing.
2383
2384 =cut
2385
2386 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2387
2388 =head2 $c->request_class
2389
2390 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2391
2392 =head2 $c->response_class
2393
2394 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2395
2396 =head2 $c->read( [$maxlength] )
2397
2398 Reads a chunk of data from the request body. This method is designed to
2399 be used in a while loop, reading C<$maxlength> bytes on every call.
2400 C<$maxlength> defaults to the size of the request if not specified.
2401
2402 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2403 directly.
2404
2405 Warning: If you use read(), Catalyst will not process the body,
2406 so you will not be able to access POST parameters or file uploads via
2407 $c->request.  You must handle all body parsing yourself.
2408
2409 =cut
2410
2411 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2412
2413 =head2 $c->run
2414
2415 Starts the engine.
2416
2417 =cut
2418
2419 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2420
2421 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2422
2423 Sets an action in a given namespace.
2424
2425 =cut
2426
2427 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2428
2429 =head2 $c->setup_actions($component)
2430
2431 Sets up actions for a component.
2432
2433 =cut
2434
2435 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2436
2437 =head2 $c->setup_config
2438
2439 =cut
2440
2441 sub setup_config {
2442     my $class = shift;
2443
2444     my %args = %{ $class->config || {} };
2445
2446     my @container_classes = ( "${class}::Container", 'Catalyst::Container');
2447     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2448
2449     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2450
2451     my $container = $container_class->new( %args, name => "$class" );
2452     $class->container($container);
2453
2454     my $config = $container->resolve(service => 'config');
2455     $class->config($config);
2456     $class->finalize_config; # back-compat
2457 }
2458
2459 =head $c->finalize_config
2460
2461 =cut
2462
2463 sub finalize_config { }
2464
2465 =head2 $c->setup_components
2466
2467 This method is called internally to set up the application's components.
2468
2469 It finds modules by calling the L<locate_components> method, expands them to
2470 package names with the L<expand_component_module> method, and then installs
2471 each component into the application.
2472
2473 The C<setup_components> config option is passed to both of the above methods.
2474
2475 Installation of each component is performed by the L<setup_component> method,
2476 below.
2477
2478 =cut
2479
2480 sub setup_components {
2481     my $class = shift;
2482
2483     my $config  = $class->config->{ setup_components };
2484
2485     my @comps = $class->locate_components($config);
2486     my %comps = map { $_ => 1 } @comps;
2487
2488     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2489     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2490         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2491     ) if $deprecatedcatalyst_component_names;
2492
2493     for my $component ( @comps ) {
2494
2495         # We pass ignore_loaded here so that overlay files for (e.g.)
2496         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2497         # we know M::P::O found a file on disk so this is safe
2498
2499         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2500     }
2501
2502     my $containers;
2503     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
2504
2505     for my $component (@comps) {
2506         my $instance = $class->components->{ $component } = $class->setup_component($component);
2507         if ( my ($type, $name) = _get_component_type_name($component) ) {
2508             $containers->{$type}->add_service(Catalyst::BlockInjection->new( name => $name, block => sub { return $instance } ));
2509         }
2510         my @expanded_components = $instance->can('expand_modules')
2511             ? $instance->expand_modules( $component, $config )
2512             : $class->expand_component_module( $component, $config );
2513         for my $component (@expanded_components) {
2514             next if $comps{$component};
2515
2516             $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @expanded_components;
2517             $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2518                 qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2519             ) if $deprecatedcatalyst_component_names;
2520
2521             if (my ($type, $name) = _get_component_type_name($component)) {
2522                 $containers->{$type}->add_service(Catalyst::BlockInjection->new( name => $name, block => sub { return $class->setup_component($component) } ));
2523             }
2524
2525             $class->components->{ $component } = $class->setup_component($component);
2526         }
2527     }
2528 }
2529
2530 sub _get_component_type_name {
2531     my $component = shift;
2532     my @parts     = split /::/, $component;
2533
2534     while (my $type = shift @parts) {
2535         return ('controller', join '::', @parts)
2536             if $type =~ /^(c|controller)$/i;
2537
2538         return ('model', join '::', @parts)
2539             if $type =~ /^(m|model)$/i;
2540
2541         return ('view', join '::', @parts)
2542             if $type =~ /^(v|view)$/i;
2543     }
2544 }
2545
2546 =head2 $c->locate_components( $setup_component_config )
2547
2548 This method is meant to provide a list of component modules that should be
2549 setup for the application.  By default, it will use L<Module::Pluggable>.
2550
2551 Specify a C<setup_components> config option to pass additional options directly
2552 to L<Module::Pluggable>. To add additional search paths, specify a key named
2553 C<search_extra> as an array reference. Items in the array beginning with C<::>
2554 will have the application class name prepended to them.
2555
2556 =cut
2557
2558 sub locate_components {
2559     my $class  = shift;
2560     my $config = shift;
2561
2562     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2563     my $extra   = delete $config->{ search_extra } || [];
2564
2565     push @paths, @$extra;
2566
2567     my $locator = Module::Pluggable::Object->new(
2568         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2569         %$config
2570     );
2571
2572     # XXX think about ditching this sort entirely
2573     my @comps = sort { length $a <=> length $b } $locator->plugins;
2574
2575     return @comps;
2576 }
2577
2578 =head2 $c->expand_component_module( $component, $setup_component_config )
2579
2580 Components found by C<locate_components> will be passed to this method, which
2581 is expected to return a list of component (package) names to be set up.
2582
2583 =cut
2584
2585 sub expand_component_module {
2586     my ($class, $module) = @_;
2587     return Devel::InnerPackage::list_packages( $module );
2588 }
2589
2590 =head2 $c->setup_component
2591
2592 =cut
2593
2594 sub setup_component {
2595     my( $class, $component ) = @_;
2596
2597     unless ( $component->can( 'COMPONENT' ) ) {
2598         return $component;
2599     }
2600
2601     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2602     my $config = $class->config->{ $suffix } || {};
2603     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2604     # methods also pass it. local to avoid pointlessly shitting in config
2605     # for the debug screen, as $component is already the key name.
2606     local $config->{catalyst_component_name} = $component;
2607
2608     my $instance = eval { $component->COMPONENT( $class, $config ); };
2609
2610     if ( my $error = $@ ) {
2611         chomp $error;
2612         Catalyst::Exception->throw(
2613             message => qq/Couldn't instantiate component "$component", "$error"/
2614         );
2615     }
2616     elsif (!blessed $instance) {
2617         my $metaclass = Moose::Util::find_meta($component);
2618         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2619         my $component_method_from = $method_meta->associated_metaclass->name;
2620         my $value = defined($instance) ? $instance : 'undef';
2621         Catalyst::Exception->throw(
2622             message =>
2623             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2624         );
2625     }
2626
2627     return $instance;
2628 }
2629
2630 =head2 $c->setup_dispatcher
2631
2632 Sets up dispatcher.
2633
2634 =cut
2635
2636 sub setup_dispatcher {
2637     my ( $class, $dispatcher ) = @_;
2638
2639     if ($dispatcher) {
2640         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2641     }
2642
2643     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2644         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2645     }
2646
2647     unless ($dispatcher) {
2648         $dispatcher = $class->dispatcher_class;
2649     }
2650
2651     Class::MOP::load_class($dispatcher);
2652
2653     # dispatcher instance
2654     $class->dispatcher( $dispatcher->new );
2655 }
2656
2657 =head2 $c->setup_engine
2658
2659 Sets up engine.
2660
2661 =cut
2662
2663 sub setup_engine {
2664     my ( $class, $engine ) = @_;
2665
2666     if ($engine) {
2667         $engine = 'Catalyst::Engine::' . $engine;
2668     }
2669
2670     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2671         $engine = 'Catalyst::Engine::' . $env;
2672     }
2673
2674     if ( $ENV{MOD_PERL} ) {
2675         my $meta = Class::MOP::get_metaclass_by_name($class);
2676
2677         # create the apache method
2678         $meta->add_method('apache' => sub { shift->engine->apache });
2679
2680         my ( $software, $version ) =
2681           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2682
2683         $version =~ s/_//g;
2684         $version =~ s/(\.[^.]+)\./$1/g;
2685
2686         if ( $software eq 'mod_perl' ) {
2687
2688             if ( !$engine ) {
2689
2690                 if ( $version >= 1.99922 ) {
2691                     $engine = 'Catalyst::Engine::Apache2::MP20';
2692                 }
2693
2694                 elsif ( $version >= 1.9901 ) {
2695                     $engine = 'Catalyst::Engine::Apache2::MP19';
2696                 }
2697
2698                 elsif ( $version >= 1.24 ) {
2699                     $engine = 'Catalyst::Engine::Apache::MP13';
2700                 }
2701
2702                 else {
2703                     Catalyst::Exception->throw( message =>
2704                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2705                 }
2706
2707             }
2708
2709             # install the correct mod_perl handler
2710             if ( $version >= 1.9901 ) {
2711                 *handler = sub  : method {
2712                     shift->handle_request(@_);
2713                 };
2714             }
2715             else {
2716                 *handler = sub ($$) { shift->handle_request(@_) };
2717             }
2718
2719         }
2720
2721         elsif ( $software eq 'Zeus-Perl' ) {
2722             $engine = 'Catalyst::Engine::Zeus';
2723         }
2724
2725         else {
2726             Catalyst::Exception->throw(
2727                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2728         }
2729     }
2730
2731     unless ($engine) {
2732         $engine = $class->engine_class;
2733     }
2734
2735     Class::MOP::load_class($engine);
2736
2737     # check for old engines that are no longer compatible
2738     my $old_engine;
2739     if ( $engine->isa('Catalyst::Engine::Apache')
2740         && !Catalyst::Engine::Apache->VERSION )
2741     {
2742         $old_engine = 1;
2743     }
2744
2745     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2746         && Catalyst::Engine::Server->VERSION le '0.02' )
2747     {
2748         $old_engine = 1;
2749     }
2750
2751     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2752         && $engine->VERSION eq '0.01' )
2753     {
2754         $old_engine = 1;
2755     }
2756
2757     elsif ($engine->isa('Catalyst::Engine::Zeus')
2758         && $engine->VERSION eq '0.01' )
2759     {
2760         $old_engine = 1;
2761     }
2762
2763     if ($old_engine) {
2764         Catalyst::Exception->throw( message =>
2765               qq/Engine "$engine" is not supported by this version of Catalyst/
2766         );
2767     }
2768
2769     # engine instance
2770     $class->engine( $engine->new );
2771 }
2772
2773 =head2 $c->setup_home
2774
2775 Sets up the home directory.
2776
2777 =cut
2778
2779 sub setup_home {
2780     my ( $class, $home ) = @_;
2781
2782     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2783         $home = $env;
2784     }
2785
2786     $home ||= Catalyst::Utils::home($class);
2787
2788     if ($home) {
2789         #I remember recently being scolded for assigning config values like this
2790         $class->config->{home} ||= $home;
2791         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2792     }
2793 }
2794
2795 =head2 $c->setup_log
2796
2797 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2798 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2799 log to.
2800
2801 This method also installs a C<debug> method that returns a true value into the
2802 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2803 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2804
2805 Note that if the log has already been setup, by either a previous call to
2806 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2807 that this method won't actually set up the log object.
2808
2809 =cut
2810
2811 sub setup_log {
2812     my ( $class, $levels ) = @_;
2813
2814     $levels ||= '';
2815     $levels =~ s/^\s+//;
2816     $levels =~ s/\s+$//;
2817     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2818
2819     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2820     if ( defined $env_debug ) {
2821         $levels{debug} = 1 if $env_debug; # Ugly!
2822         delete($levels{debug}) unless $env_debug;
2823     }
2824
2825     unless ( $class->log ) {
2826         $class->log( Catalyst::Log->new(keys %levels) );
2827     }
2828
2829     if ( $levels{debug} ) {
2830         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2831         $class->log->debug('Debug messages enabled');
2832     }
2833 }
2834
2835 =head2 $c->setup_plugins
2836
2837 Sets up plugins.
2838
2839 =cut
2840
2841 =head2 $c->setup_stats
2842
2843 Sets up timing statistics class.
2844
2845 =cut
2846
2847 sub setup_stats {
2848     my ( $class, $stats ) = @_;
2849
2850     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2851
2852     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2853     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2854         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2855         $class->log->debug('Statistics enabled');
2856     }
2857 }
2858
2859
2860 =head2 $c->registered_plugins
2861
2862 Returns a sorted list of the plugins which have either been stated in the
2863 import list or which have been added via C<< MyApp->plugin(@args); >>.
2864
2865 If passed a given plugin name, it will report a boolean value indicating
2866 whether or not that plugin is loaded.  A fully qualified name is required if
2867 the plugin name does not begin with C<Catalyst::Plugin::>.
2868
2869  if ($c->registered_plugins('Some::Plugin')) {
2870      ...
2871  }
2872
2873 =cut
2874
2875 {
2876
2877     sub registered_plugins {
2878         my $proto = shift;
2879         return sort keys %{ $proto->_plugins } unless @_;
2880         my $plugin = shift;
2881         return 1 if exists $proto->_plugins->{$plugin};
2882         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2883     }
2884
2885     sub _register_plugin {
2886         my ( $proto, $plugin, $instant ) = @_;
2887         my $class = ref $proto || $proto;
2888
2889         Class::MOP::load_class( $plugin );
2890         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2891             if $plugin->isa( 'Catalyst::Component' );
2892         $proto->_plugins->{$plugin} = 1;
2893         unless ($instant) {
2894             my $meta = Class::MOP::get_metaclass_by_name($class);
2895             $meta->superclasses($plugin, $meta->superclasses);
2896         }
2897         return $class;
2898     }
2899
2900     sub setup_plugins {
2901         my ( $class, $plugins ) = @_;
2902
2903         $class->_plugins( {} ) unless $class->_plugins;
2904         $plugins = Data::OptList::mkopt($plugins || []);
2905
2906         my @plugins = map {
2907             [ Catalyst::Utils::resolve_namespace(
2908                   $class . '::Plugin',
2909                   'Catalyst::Plugin', $_->[0]
2910               ),
2911               $_->[1],
2912             ]
2913          } @{ $plugins };
2914
2915         for my $plugin ( reverse @plugins ) {
2916             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2917             my $meta = find_meta($plugin->[0]);
2918             next if $meta && $meta->isa('Moose::Meta::Role');
2919
2920             $class->_register_plugin($plugin->[0]);
2921         }
2922
2923         my @roles =
2924             map  { $_->[0]->name, $_->[1] }
2925             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2926             map  { [find_meta($_->[0]), $_->[1]] }
2927             @plugins;
2928
2929         Moose::Util::apply_all_roles(
2930             $class => @roles
2931         ) if @roles;
2932     }
2933 }
2934
2935 =head2 $c->stack
2936
2937 Returns an arrayref of the internal execution stack (actions that are
2938 currently executing).
2939
2940 =head2 $c->stats
2941
2942 Returns the current timing statistics object. By default Catalyst uses
2943 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2944 L<< stats_class|/"$c->stats_class" >>.
2945
2946 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2947 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2948 profile explicitly, although MyApp.pm still won't profile nor output anything
2949 by itself.
2950
2951 =head2 $c->stats_class
2952
2953 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2954
2955 =head2 $c->use_stats
2956
2957 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2958
2959 Note that this is a static method, not an accessor and should be overridden
2960 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2961
2962 =cut
2963
2964 sub use_stats { 0 }
2965
2966
2967 =head2 $c->write( $data )
2968
2969 Writes $data to the output stream. When using this method directly, you
2970 will need to manually set the C<Content-Length> header to the length of
2971 your output data, if known.
2972
2973 =cut
2974
2975 sub write {
2976     my $c = shift;
2977
2978     # Finalize headers if someone manually writes output
2979     $c->finalize_headers;
2980
2981     return $c->engine->write( $c, @_ );
2982 }
2983
2984 =head2 version
2985
2986 Returns the Catalyst version number. Mostly useful for "powered by"
2987 messages in template systems.
2988
2989 =cut
2990
2991 sub version { return $Catalyst::VERSION }
2992
2993 =head1 CONFIGURATION
2994
2995 There are a number of 'base' config variables which can be set:
2996
2997 =over
2998
2999 =item *
3000
3001 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3002
3003 =item *
3004
3005 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3006
3007 =item *
3008
3009 C<disable_component_resolution_regex_fallback> - Turns
3010 off the deprecated component resolution functionality so
3011 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3012 are called then regex search will not be attempted on string values and
3013 instead C<undef> will be returned.
3014
3015 =item *
3016
3017 C<home> - The application home directory. In an uninstalled application,
3018 this is the top level application directory. In an installed application,
3019 this will be the directory containing C<< MyApp.pm >>.
3020
3021 =item *
3022
3023 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3024
3025 =item *
3026
3027 C<name> - The name of the application in debug messages and the debug and
3028 welcome screens
3029
3030 =item *
3031
3032 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3033 until it is accessed. This allows you to (for example) check authentication (and reject
3034 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
3035
3036 =item *
3037
3038 C<root> - The root directory for templates. Usually this is just a
3039 subdirectory of the home directory, but you can set it to change the
3040 templates to a different directory.
3041
3042 =item *
3043
3044 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3045 namespaces from which components will be loaded (and constructed and stored in
3046 C<< $c->components >>).
3047
3048 =item *
3049
3050 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3051 to be shown in hit debug tables in the test server.
3052
3053 =item *
3054
3055 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
3056 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
3057 for more information.
3058
3059 =item *
3060
3061 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3062
3063 =back
3064
3065 =head1 INTERNAL ACTIONS
3066
3067 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3068 C<_ACTION>, and C<_END>. These are by default not shown in the private
3069 action table, but you can make them visible with a config parameter.
3070
3071     MyApp->config(show_internal_actions => 1);
3072
3073 =head1 ON-DEMAND PARSER
3074
3075 The request body is usually parsed at the beginning of a request,
3076 but if you want to handle input yourself, you can enable on-demand
3077 parsing with a config parameter.
3078
3079     MyApp->config(parse_on_demand => 1);
3080
3081 =head1 PROXY SUPPORT
3082
3083 Many production servers operate using the common double-server approach,
3084 with a lightweight frontend web server passing requests to a larger
3085 backend server. An application running on the backend server must deal
3086 with two problems: the remote user always appears to be C<127.0.0.1> and
3087 the server's hostname will appear to be C<localhost> regardless of the
3088 virtual host that the user connected through.
3089
3090 Catalyst will automatically detect this situation when you are running
3091 the frontend and backend servers on the same machine. The following
3092 changes are made to the request.
3093
3094     $c->req->address is set to the user's real IP address, as read from
3095     the HTTP X-Forwarded-For header.
3096
3097     The host value for $c->req->base and $c->req->uri is set to the real
3098     host, as read from the HTTP X-Forwarded-Host header.
3099
3100 Additionally, you may be running your backend application on an insecure
3101 connection (port 80) while your frontend proxy is running under SSL.  If there
3102 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3103 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3104 be created properly.
3105
3106 In the case of passing in:
3107
3108     X-Forwarded-Port: 443
3109
3110 All calls to C<uri_for> will result in an https link, as is expected.
3111
3112 Obviously, your web server must support these headers for this to work.
3113
3114 In a more complex server farm environment where you may have your
3115 frontend proxy server(s) on different machines, you will need to set a
3116 configuration option to tell Catalyst to read the proxied data from the
3117 headers.
3118
3119     MyApp->config(using_frontend_proxy => 1);
3120
3121 If you do not wish to use the proxy support at all, you may set:
3122
3123     MyApp->config(ignore_frontend_proxy => 1);
3124
3125 =head1 THREAD SAFETY
3126
3127 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3128 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3129 believe the Catalyst core to be thread-safe.
3130
3131 If you plan to operate in a threaded environment, remember that all other
3132 modules you are using must also be thread-safe. Some modules, most notably
3133 L<DBD::SQLite>, are not thread-safe.
3134
3135 =head1 SUPPORT
3136
3137 IRC:
3138
3139     Join #catalyst on irc.perl.org.
3140
3141 Mailing Lists:
3142
3143     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3144     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3145
3146 Web:
3147
3148     http://catalyst.perl.org
3149
3150 Wiki:
3151
3152     http://dev.catalyst.perl.org
3153
3154 =head1 SEE ALSO
3155
3156 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3157
3158 =head2 L<Catalyst::Manual> - The Catalyst Manual
3159
3160 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3161
3162 =head2 L<Catalyst::Engine> - Core engine
3163
3164 =head2 L<Catalyst::Log> - Log class.
3165
3166 =head2 L<Catalyst::Request> - Request object
3167
3168 =head2 L<Catalyst::Response> - Response object
3169
3170 =head2 L<Catalyst::Test> - The test suite.
3171
3172 =head1 PROJECT FOUNDER
3173
3174 sri: Sebastian Riedel <sri@cpan.org>
3175
3176 =head1 CONTRIBUTORS
3177
3178 abw: Andy Wardley
3179
3180 acme: Leon Brocard <leon@astray.com>
3181
3182 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3183
3184 Andrew Bramble
3185
3186 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3187
3188 Andrew Ruthven
3189
3190 andyg: Andy Grundman <andy@hybridized.org>
3191
3192 audreyt: Audrey Tang
3193
3194 bricas: Brian Cassidy <bricas@cpan.org>
3195
3196 Caelum: Rafael Kitover <rkitover@io.com>
3197
3198 chansen: Christian Hansen
3199
3200 chicks: Christopher Hicks
3201
3202 Chisel Wright C<pause@herlpacker.co.uk>
3203
3204 Danijel Milicevic C<me@danijel.de>
3205
3206 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3207
3208 David Naughton, C<naughton@umn.edu>
3209
3210 David E. Wheeler
3211
3212 dhoss: Devin Austin <dhoss@cpan.org>
3213
3214 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3215
3216 Drew Taylor
3217
3218 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3219
3220 esskar: Sascha Kiefer
3221
3222 fireartist: Carl Franks <cfranks@cpan.org>
3223
3224 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3225
3226 gabb: Danijel Milicevic
3227
3228 Gary Ashton Jones
3229
3230 Gavin Henry C<ghenry@perl.me.uk>
3231
3232 Geoff Richards
3233
3234 groditi: Guillermo Roditi <groditi@gmail.com>
3235
3236 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3237
3238 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3239
3240 jcamacho: Juan Camacho
3241
3242 jester: Jesse Sheidlower C<jester@panix.com>
3243
3244 jhannah: Jay Hannah <jay@jays.net>
3245
3246 Jody Belka
3247
3248 Johan Lindstrom
3249
3250 jon: Jon Schutz <jjschutz@cpan.org>
3251
3252 Jonathan Rockway C<< <jrockway@cpan.org> >>
3253
3254 Kieren Diment C<kd@totaldatasolution.com>
3255
3256 konobi: Scott McWhirter <konobi@cpan.org>
3257
3258 marcus: Marcus Ramberg <mramberg@cpan.org>
3259
3260 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3261
3262 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3263
3264 mugwump: Sam Vilain
3265
3266 naughton: David Naughton
3267
3268 ningu: David Kamholz <dkamholz@cpan.org>
3269
3270 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3271
3272 numa: Dan Sully <daniel@cpan.org>
3273
3274 obra: Jesse Vincent
3275
3276 Octavian Rasnita
3277
3278 omega: Andreas Marienborg
3279
3280 Oleg Kostyuk <cub.uanic@gmail.com>
3281
3282 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3283
3284 rafl: Florian Ragwitz <rafl@debian.org>
3285
3286 random: Roland Lammel <lammel@cpan.org>
3287
3288 Robert Sedlacek C<< <rs@474.at> >>
3289
3290 SpiceMan: Marcel Montes
3291
3292 sky: Arthur Bergman
3293
3294 szbalint: Balint Szilakszi <szbalint@cpan.org>
3295
3296 t0m: Tomas Doran <bobtfish@bobtfish.net>
3297
3298 Ulf Edvinsson
3299
3300 Viljo Marrandi C<vilts@yahoo.com>
3301
3302 Will Hawes C<info@whawes.co.uk>
3303
3304 willert: Sebastian Willert <willert@cpan.org>
3305
3306 wreis: Wallace Reis <wallace@reis.org.br>
3307
3308 Yuval Kogman, C<nothingmuch@woobling.org>
3309
3310 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3311
3312 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3313
3314 =head1 COPYRIGHT
3315
3316 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3317
3318 =head1 LICENSE
3319
3320 This library is free software. You can redistribute it and/or modify it under
3321 the same terms as Perl itself.
3322
3323 =cut
3324
3325 no Moose;
3326
3327 __PACKAGE__->meta->make_immutable;
3328
3329 1;