lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Util;
  48 use Class::Load 'load_class';
  49
  50 BEGIN { require 5.008003; }
  51
  52 has stack => (is => 'ro', default => sub { [] });
  53 has stash => (is => 'rw', default => sub { {} });
  54 has state => (is => 'rw', default => 0);
  55 has stats => (is => 'rw');
  56 has action => (is => 'rw');
  57 has counter => (is => 'rw', default => sub { {} });
  58 has request => (
  59     is => 'rw',
  60     default => sub {
  61         my $self = shift;
  62         $self->request_class->new($self->_build_request_constructor_args);
  63     },
  64     lazy => 1,
  65 );
  66 sub _build_request_constructor_args {
  67     my $self = shift;
  68     my %p = ( _log => $self->log );
  69     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  70     $p{data_handlers} = {$self->registered_data_handlers};
  71     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  72       if $self->config->{use_hash_multivalue_in_request};
  73     \%p;
  74 }
  75
  76 has response => (
  77     is => 'rw',
  78     default => sub {
  79         my $self = shift;
  80         $self->response_class->new($self->_build_response_constructor_args);
  81     },
  82     lazy => 1,
  83 );
  84 sub _build_response_constructor_args {
  85     my $self = shift;
  86     { _log => $self->log };
  87 }
  88
  89 has namespace => (is => 'rw');
  90
  91 sub depth { scalar @{ shift->stack || [] }; }
  92 sub comp { shift->component(@_) }
  93
  94 sub req {
  95     my $self = shift; return $self->request(@_);
  96 }
  97 sub res {
  98     my $self = shift; return $self->response(@_);
  99 }
 100
 101 # For backwards compatibility
 102 sub finalize_output { shift->finalize_body(@_) };
 103
 104 # For statistics
 105 our $COUNT     = 1;
 106 our $START     = time;
 107 our $RECURSION = 1000;
 108 our $DETACH    = Catalyst::Exception::Detach->new;
 109 our $GO        = Catalyst::Exception::Go->new;
 110
 111 #I imagine that very few of these really need to be class variables. if any.
 112 #maybe we should just make them attributes with a default?
 113 __PACKAGE__->mk_classdata($_)
 114   for qw/components arguments dispatcher engine log dispatcher_class
 115   engine_loader context_class request_class response_class stats_class
 116   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 117   _data_handlers/;
 118
 119 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 120 __PACKAGE__->request_class('Catalyst::Request');
 121 __PACKAGE__->response_class('Catalyst::Response');
 122 __PACKAGE__->stats_class('Catalyst::Stats');
 123
 124 # Remember to update this in Catalyst::Runtime as well!
 125
 126 our $VERSION = '5.90059_003';
 127
 128 sub import {
 129     my ( $class, @arguments ) = @_;
 130
 131     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 132     # callers @ISA.
 133     return unless $class eq 'Catalyst';
 134
 135     my $caller = caller();
 136     return if $caller eq 'main';
 137
 138     my $meta = Moose::Meta::Class->initialize($caller);
 139     unless ( $caller->isa('Catalyst') ) {
 140         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 141         $meta->superclasses(@superclasses);
 142     }
 143     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 144     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 145
 146     unless( $meta->has_method('meta') ){
 147         if ($Moose::VERSION >= 1.15) {
 148             $meta->_add_meta_method('meta');
 149         }
 150         else {
 151             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 152         }
 153     }
 154
 155     $caller->arguments( [@arguments] );
 156     $caller->setup_home;
 157 }
 158
 159 sub _application { $_[0] }
 160
 161 =encoding UTF-8
 162
 163 =head1 NAME
 164
 165 Catalyst - The Elegant MVC Web Application Framework
 166
 167 =head1 SYNOPSIS
 168
 169 See the L<Catalyst::Manual> distribution for comprehensive
 170 documentation and tutorials.
 171
 172     # Install Catalyst::Devel for helpers and other development tools
 173     # use the helper to create a new application
 174     catalyst.pl MyApp
 175
 176     # add models, views, controllers
 177     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 178     script/myapp_create.pl view MyTemplate TT
 179     script/myapp_create.pl controller Search
 180
 181     # built in testserver -- use -r to restart automatically on changes
 182     # --help to see all available options
 183     script/myapp_server.pl
 184
 185     # command line testing interface
 186     script/myapp_test.pl /yada
 187
 188     ### in lib/MyApp.pm
 189     use Catalyst qw/-Debug/; # include plugins here as well
 190
 191     ### In lib/MyApp/Controller/Root.pm (autocreated)
 192     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 193         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 194         $c->stash->{template} = 'foo.tt'; # set the template
 195         # lookup something from db -- stash vars are passed to TT
 196         $c->stash->{data} =
 197           $c->model('Database::Foo')->search( { country => $args[0] } );
 198         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 199             $c->forward( 'bar' ); # process another action
 200             # do something else after forward returns
 201         }
 202     }
 203
 204     # The foo.tt TT template can use the stash data from the database
 205     [% WHILE (item = data.next) %]
 206         [% item.foo %]
 207     [% END %]
 208
 209     # called for /bar/of/soap, /bar/of/soap/10, etc.
 210     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 211
 212     # called after all actions are finished
 213     sub end : Action {
 214         my ( $self, $c ) = @_;
 215         if ( scalar @{ $c->error } ) { ... } # handle errors
 216         return if $c->res->body; # already have a response
 217         $c->forward( 'MyApp::View::TT' ); # render template
 218     }
 219
 220 See L<Catalyst::Manual::Intro> for additional information.
 221
 222 =head1 DESCRIPTION
 223
 224 Catalyst is a modern framework for making web applications without the
 225 pain usually associated with this process. This document is a reference
 226 to the main Catalyst application. If you are a new user, we suggest you
 227 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 228
 229 See L<Catalyst::Manual> for more documentation.
 230
 231 Catalyst plugins can be loaded by naming them as arguments to the "use
 232 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 233 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 234 C<My::Module>.
 235
 236     use Catalyst qw/My::Module/;
 237
 238 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 239 fully qualify the name by using a unary plus:
 240
 241     use Catalyst qw/
 242         My::Module
 243         +Fully::Qualified::Plugin::Name
 244     /;
 245
 246 Special flags like C<-Debug> can also be specified as
 247 arguments when Catalyst is loaded:
 248
 249     use Catalyst qw/-Debug My::Module/;
 250
 251 The position of plugins and flags in the chain is important, because
 252 they are loaded in the order in which they appear.
 253
 254 The following flags are supported:
 255
 256 =head2 -Debug
 257
 258 Enables debug output. You can also force this setting from the system
 259 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 260 settings override the application, with <MYAPP>_DEBUG having the highest
 261 priority.
 262
 263 This sets the log level to 'debug' and enables full debug output on the
 264 error screen. If you only want the latter, see L<< $c->debug >>.
 265
 266 =head2 -Home
 267
 268 Forces Catalyst to use a specific home directory, e.g.:
 269
 270     use Catalyst qw[-Home=/usr/mst];
 271
 272 This can also be done in the shell environment by setting either the
 273 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 274 is replaced with the uppercased name of your application, any "::" in
 275 the name will be replaced with underscores, e.g. MyApp::Web should use
 276 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 277
 278 If none of these are set, Catalyst will attempt to automatically detect the
 279 home directory. If you are working in a development environment, Catalyst
 280 will try and find the directory containing either Makefile.PL, Build.PL,
 281 dist.ini, or cpanfile. If the application has been installed into the system
 282 (i.e. you have done C<make install>), then Catalyst will use the path to your
 283 application module, without the .pm extension (e.g., /foo/MyApp if your
 284 application was installed at /foo/MyApp.pm)
 285
 286 =head2 -Log
 287
 288     use Catalyst '-Log=warn,fatal,error';
 289
 290 Specifies a comma-delimited list of log levels.
 291
 292 =head2 -Stats
 293
 294 Enables statistics collection and reporting.
 295
 296    use Catalyst qw/-Stats=1/;
 297
 298 You can also force this setting from the system environment with CATALYST_STATS
 299 or <MYAPP>_STATS. The environment settings override the application, with
 300 <MYAPP>_STATS having the highest priority.
 301
 302 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 303
 304 =head1 METHODS
 305
 306 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 307
 308 =head2 $c->action
 309
 310 Returns a L<Catalyst::Action> object for the current action, which
 311 stringifies to the action name. See L<Catalyst::Action>.
 312
 313 =head2 $c->namespace
 314
 315 Returns the namespace of the current action, i.e., the URI prefix
 316 corresponding to the controller of the current action. For example:
 317
 318     # in Controller::Foo::Bar
 319     $c->namespace; # returns 'foo/bar';
 320
 321 =head2 $c->request
 322
 323 =head2 $c->req
 324
 325 Returns the current L<Catalyst::Request> object, giving access to
 326 information about the current client request (including parameters,
 327 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 328
 329 =head2 REQUEST FLOW HANDLING
 330
 331 =head2 $c->forward( $action [, \@arguments ] )
 332
 333 =head2 $c->forward( $class, $method, [, \@arguments ] )
 334
 335 This is one way of calling another action (method) in the same or
 336 a different controller. You can also use C<< $self->my_method($c, @args) >>
 337 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 338 in a different controller.
 339 The main difference is that 'forward' uses some of the Catalyst request
 340 cycle overhead, including debugging, which may be useful to you. On the
 341 other hand, there are some complications to using 'forward', restrictions
 342 on values returned from 'forward', and it may not handle errors as you prefer.
 343 Whether you use 'forward' or not is up to you; it is not considered superior to
 344 the other ways to call a method.
 345
 346 'forward' calls  another action, by its private name. If you give a
 347 class name but no method, C<process()> is called. You may also optionally
 348 pass arguments in an arrayref. The action will receive the arguments in
 349 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 350 C<< $c->req->args >> will be restored to the previous values.
 351
 352 Any data C<return>ed from the action forwarded to, will be returned by the
 353 call to forward.
 354
 355     my $foodata = $c->forward('/foo');
 356     $c->forward('index');
 357     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 358     $c->forward('View::TT');
 359
 360 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 361 an C<< eval { } >> around the call (actually
 362 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 363 exceptions thrown by the called action non-fatal and pushing them onto
 364 $c->error instead. If you want C<die> to propagate you need to do something
 365 like:
 366
 367     $c->forward('foo');
 368     die join "\n", @{ $c->error } if @{ $c->error };
 369
 370 Or make sure to always return true values from your actions and write
 371 your code like this:
 372
 373     $c->forward('foo') || return;
 374
 375 Another note is that C<< $c->forward >> always returns a scalar because it
 376 actually returns $c->state which operates in a scalar context.
 377 Thus, something like:
 378
 379     return @array;
 380
 381 in an action that is forwarded to is going to return a scalar,
 382 i.e. how many items are in that array, which is probably not what you want.
 383 If you need to return an array then return a reference to it,
 384 or stash it like so:
 385
 386     $c->stash->{array} = \@array;
 387
 388 and access it from the stash.
 389
 390 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 391
 392 =cut
 393
 394 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 395
 396 =head2 $c->detach( $action [, \@arguments ] )
 397
 398 =head2 $c->detach( $class, $method, [, \@arguments ] )
 399
 400 =head2 $c->detach()
 401
 402 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 403 doesn't return to the previous action when processing is finished.
 404
 405 When called with no arguments it escapes the processing chain entirely.
 406
 407 =cut
 408
 409 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 410
 411 =head2 $c->visit( $action [, \@arguments ] )
 412
 413 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 414
 415 =head2 $c->visit( $class, $method, [, \@arguments ] )
 416
 417 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 418
 419 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 420 but does a full dispatch, instead of just calling the new C<$action> /
 421 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 422 you go to are called, just like a new request.
 423
 424 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 425 This means, for example, that C<< $c->action >> methods such as
 426 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 427 L<reverse|Catalyst::Action/reverse> return information for the visited action
 428 when they are invoked within the visited action.  This is different from the
 429 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 430 continues to use the $c->action object from the caller action even when
 431 invoked from the called action.
 432
 433 C<< $c->stash >> is kept unchanged.
 434
 435 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 436 allows you to "wrap" another action, just as it would have been called by
 437 dispatching from a URL, while the analogous
 438 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 439 transfer control to another action as if it had been reached directly from a URL.
 440
 441 =cut
 442
 443 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 444
 445 =head2 $c->go( $action [, \@arguments ] )
 446
 447 =head2 $c->go( $action [, \@captures, \@arguments ] )
 448
 449 =head2 $c->go( $class, $method, [, \@arguments ] )
 450
 451 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 452
 453 The relationship between C<go> and
 454 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 455 the relationship between
 456 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 457 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 458 C<< $c->go >> will perform a full dispatch on the specified action or method,
 459 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 460 C<go> escapes the processing of the current request chain on completion, and
 461 does not return to its caller.
 462
 463 @arguments are arguments to the final destination of $action. @captures are
 464 arguments to the intermediate steps, if any, on the way to the final sub of
 465 $action.
 466
 467 =cut
 468
 469 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 470
 471 =head2 $c->response
 472
 473 =head2 $c->res
 474
 475 Returns the current L<Catalyst::Response> object, see there for details.
 476
 477 =head2 $c->stash
 478
 479 Returns a hashref to the stash, which may be used to store data and pass
 480 it between components during a request. You can also set hash keys by
 481 passing arguments. The stash is automatically sent to the view. The
 482 stash is cleared at the end of a request; it cannot be used for
 483 persistent storage (for this you must use a session; see
 484 L<Catalyst::Plugin::Session> for a complete system integrated with
 485 Catalyst).
 486
 487     $c->stash->{foo} = $bar;
 488     $c->stash( { moose => 'majestic', qux => 0 } );
 489     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 490
 491     # stash is automatically passed to the view for use in a template
 492     $c->forward( 'MyApp::View::TT' );
 493
 494 =cut
 495
 496 around stash => sub {
 497     my $orig = shift;
 498     my $c = shift;
 499     my $stash = $orig->($c);
 500     if (@_) {
 501         my $new_stash = @_ > 1 ? {@_} : $_[0];
 502         croak('stash takes a hash or hashref') unless ref $new_stash;
 503         foreach my $key ( keys %$new_stash ) {
 504           $stash->{$key} = $new_stash->{$key};
 505         }
 506     }
 507
 508     return $stash;
 509 };
 510
 511
 512 =head2 $c->error
 513
 514 =head2 $c->error($error, ...)
 515
 516 =head2 $c->error($arrayref)
 517
 518 Returns an arrayref containing error messages.  If Catalyst encounters an
 519 error while processing a request, it stores the error in $c->error.  This
 520 method should only be used to store fatal error messages.
 521
 522     my @error = @{ $c->error };
 523
 524 Add a new error.
 525
 526     $c->error('Something bad happened');
 527
 528 =cut
 529
 530 sub error {
 531     my $c = shift;
 532     if ( $_[0] ) {
 533         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 534         croak @$error unless ref $c;
 535         push @{ $c->{error} }, @$error;
 536     }
 537     elsif ( defined $_[0] ) { $c->{error} = undef }
 538     return $c->{error} || [];
 539 }
 540
 541
 542 =head2 $c->state
 543
 544 Contains the return value of the last executed action.
 545 Note that << $c->state >> operates in a scalar context which means that all
 546 values it returns are scalar.
 547
 548 =head2 $c->clear_errors
 549
 550 Clear errors.  You probably don't want to clear the errors unless you are
 551 implementing a custom error screen.
 552
 553 This is equivalent to running
 554
 555     $c->error(0);
 556
 557 =cut
 558
 559 sub clear_errors {
 560     my $c = shift;
 561     $c->error(0);
 562 }
 563
 564 sub _comp_search_prefixes {
 565     my $c = shift;
 566     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 567 }
 568
 569 # search components given a name and some prefixes
 570 sub _comp_names_search_prefixes {
 571     my ( $c, $name, @prefixes ) = @_;
 572     my $appclass = ref $c || $c;
 573     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 574     $filter = qr/$filter/; # Compile regex now rather than once per loop
 575
 576     # map the original component name to the sub part that we will search against
 577     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 578         grep { /$filter/ } keys %{ $c->components };
 579
 580     # undef for a name will return all
 581     return keys %eligible if !defined $name;
 582
 583     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 584     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 585
 586     return @result if @result;
 587
 588     # if we were given a regexp to search against, we're done.
 589     return if $name->$_isa('Regexp');
 590
 591     # skip regexp fallback if configured
 592     return
 593         if $appclass->config->{disable_component_resolution_regex_fallback};
 594
 595     # regexp fallback
 596     $query  = qr/$name/i;
 597     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 598
 599     # no results? try against full names
 600     if( !@result ) {
 601         @result = grep { m{$query} } keys %eligible;
 602     }
 603
 604     # don't warn if we didn't find any results, it just might not exist
 605     if( @result ) {
 606         # Disgusting hack to work out correct method name
 607         my $warn_for = lc $prefixes[0];
 608         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 609            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 610            "component resolution is unreliable and unsafe.";
 611         my $short = $result[0];
 612         # remove the component namespace prefix
 613         $short =~ s/.*?(Model|Controller|View):://;
 614         my $shortmess = Carp::shortmess('');
 615         if ($shortmess =~ m#Catalyst/Plugin#) {
 616            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 617               "plugin's config";
 618         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 619            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 620               "component's config";
 621         } else {
 622            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 623               "but if you really wanted to search, pass in a regexp as the argument " .
 624               "like so: \$c->${warn_for}(qr/${name}/)";
 625         }
 626         $c->log->warn( "${msg}$shortmess" );
 627     }
 628
 629     return @result;
 630 }
 631
 632 # Find possible names for a prefix
 633 sub _comp_names {
 634     my ( $c, @prefixes ) = @_;
 635     my $appclass = ref $c || $c;
 636
 637     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 638
 639     my @names = map { s{$filter}{}; $_; }
 640         $c->_comp_names_search_prefixes( undef, @prefixes );
 641
 642     return @names;
 643 }
 644
 645 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 646 sub _filter_component {
 647     my ( $c, $comp, @args ) = @_;
 648
 649     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 650         return $comp->ACCEPT_CONTEXT( $c, @args );
 651     }
 652
 653     return $comp;
 654 }
 655
 656 =head2 COMPONENT ACCESSORS
 657
 658 =head2 $c->controller($name)
 659
 660 Gets a L<Catalyst::Controller> instance by name.
 661
 662     $c->controller('Foo')->do_stuff;
 663
 664 If the name is omitted, will return the controller for the dispatched
 665 action.
 666
 667 If you want to search for controllers, pass in a regexp as the argument.
 668
 669     # find all controllers that start with Foo
 670     my @foo_controllers = $c->controller(qr{^Foo});
 671
 672
 673 =cut
 674
 675 sub controller {
 676     my ( $c, $name, @args ) = @_;
 677
 678     my $appclass = ref($c) || $c;
 679     if( $name ) {
 680         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 681             my $comps = $c->components;
 682             my $check = $appclass."::Controller::".$name;
 683             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 684         }
 685         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 686         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 687         return $c->_filter_component( $result[ 0 ], @args );
 688     }
 689
 690     return $c->component( $c->action->class );
 691 }
 692
 693 =head2 $c->model($name)
 694
 695 Gets a L<Catalyst::Model> instance by name.
 696
 697     $c->model('Foo')->do_stuff;
 698
 699 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 700
 701 If the name is omitted, it will look for
 702  - a model object in $c->stash->{current_model_instance}, then
 703  - a model name in $c->stash->{current_model}, then
 704  - a config setting 'default_model', or
 705  - check if there is only one model, and return it if that's the case.
 706
 707 If you want to search for models, pass in a regexp as the argument.
 708
 709     # find all models that start with Foo
 710     my @foo_models = $c->model(qr{^Foo});
 711
 712 =cut
 713
 714 sub model {
 715     my ( $c, $name, @args ) = @_;
 716     my $appclass = ref($c) || $c;
 717     if( $name ) {
 718         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 719             my $comps = $c->components;
 720             my $check = $appclass."::Model::".$name;
 721             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 722         }
 723         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 724         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 725         return $c->_filter_component( $result[ 0 ], @args );
 726     }
 727
 728     if (ref $c) {
 729         return $c->stash->{current_model_instance}
 730           if $c->stash->{current_model_instance};
 731         return $c->model( $c->stash->{current_model} )
 732           if $c->stash->{current_model};
 733     }
 734     return $c->model( $appclass->config->{default_model} )
 735       if $appclass->config->{default_model};
 736
 737     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 738
 739     if( $rest ) {
 740         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 741         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 742         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 743         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 744         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 745     }
 746
 747     return $c->_filter_component( $comp );
 748 }
 749
 750
 751 =head2 $c->view($name)
 752
 753 Gets a L<Catalyst::View> instance by name.
 754
 755     $c->view('Foo')->do_stuff;
 756
 757 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 758
 759 If the name is omitted, it will look for
 760  - a view object in $c->stash->{current_view_instance}, then
 761  - a view name in $c->stash->{current_view}, then
 762  - a config setting 'default_view', or
 763  - check if there is only one view, and return it if that's the case.
 764
 765 If you want to search for views, pass in a regexp as the argument.
 766
 767     # find all views that start with Foo
 768     my @foo_views = $c->view(qr{^Foo});
 769
 770 =cut
 771
 772 sub view {
 773     my ( $c, $name, @args ) = @_;
 774
 775     my $appclass = ref($c) || $c;
 776     if( $name ) {
 777         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 778             my $comps = $c->components;
 779             my $check = $appclass."::View::".$name;
 780             if( exists $comps->{$check} ) {
 781                 return $c->_filter_component( $comps->{$check}, @args );
 782             }
 783             else {
 784                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 785             }
 786         }
 787         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 788         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 789         return $c->_filter_component( $result[ 0 ], @args );
 790     }
 791
 792     if (ref $c) {
 793         return $c->stash->{current_view_instance}
 794           if $c->stash->{current_view_instance};
 795         return $c->view( $c->stash->{current_view} )
 796           if $c->stash->{current_view};
 797     }
 798     return $c->view( $appclass->config->{default_view} )
 799       if $appclass->config->{default_view};
 800
 801     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 802
 803     if( $rest ) {
 804         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 805         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 806         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 807         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 808         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 809     }
 810
 811     return $c->_filter_component( $comp );
 812 }
 813
 814 =head2 $c->controllers
 815
 816 Returns the available names which can be passed to $c->controller
 817
 818 =cut
 819
 820 sub controllers {
 821     my ( $c ) = @_;
 822     return $c->_comp_names(qw/Controller C/);
 823 }
 824
 825 =head2 $c->models
 826
 827 Returns the available names which can be passed to $c->model
 828
 829 =cut
 830
 831 sub models {
 832     my ( $c ) = @_;
 833     return $c->_comp_names(qw/Model M/);
 834 }
 835
 836
 837 =head2 $c->views
 838
 839 Returns the available names which can be passed to $c->view
 840
 841 =cut
 842
 843 sub views {
 844     my ( $c ) = @_;
 845     return $c->_comp_names(qw/View V/);
 846 }
 847
 848 =head2 $c->comp($name)
 849
 850 =head2 $c->component($name)
 851
 852 Gets a component object by name. This method is not recommended,
 853 unless you want to get a specific component by full
 854 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 855 should be used instead.
 856
 857 If C<$name> is a regexp, a list of components matched against the full
 858 component name will be returned.
 859
 860 If Catalyst can't find a component by name, it will fallback to regex
 861 matching by default. To disable this behaviour set
 862 disable_component_resolution_regex_fallback to a true value.
 863
 864     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 865
 866 =cut
 867
 868 sub component {
 869     my ( $c, $name, @args ) = @_;
 870
 871     if( $name ) {
 872         my $comps = $c->components;
 873
 874         if( !ref $name ) {
 875             # is it the exact name?
 876             return $c->_filter_component( $comps->{ $name }, @args )
 877                        if exists $comps->{ $name };
 878
 879             # perhaps we just omitted "MyApp"?
 880             my $composed = ( ref $c || $c ) . "::${name}";
 881             return $c->_filter_component( $comps->{ $composed }, @args )
 882                        if exists $comps->{ $composed };
 883
 884             # search all of the models, views and controllers
 885             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 886             return $c->_filter_component( $comp, @args ) if $comp;
 887         }
 888
 889         return
 890             if $c->config->{disable_component_resolution_regex_fallback};
 891
 892         # This is here so $c->comp( '::M::' ) works
 893         my $query = ref $name ? $name : qr{$name}i;
 894
 895         my @result = grep { m{$query} } keys %{ $c->components };
 896         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 897
 898         if( $result[ 0 ] ) {
 899             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 900             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 901             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 902             return $c->_filter_component( $result[ 0 ], @args );
 903         }
 904
 905         # I would expect to return an empty list here, but that breaks back-compat
 906     }
 907
 908     # fallback
 909     return sort keys %{ $c->components };
 910 }
 911
 912 =head2 CLASS DATA AND HELPER CLASSES
 913
 914 =head2 $c->config
 915
 916 Returns or takes a hashref containing the application's configuration.
 917
 918     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 919
 920 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 921 like C<myapp.conf> in your applications home directory. See
 922 L<Catalyst::Plugin::ConfigLoader>.
 923
 924 =head3 Cascading configuration
 925
 926 The config method is present on all Catalyst components, and configuration
 927 will be merged when an application is started. Configuration loaded with
 928 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 929 followed by configuration in your top level C<MyApp> class. These two
 930 configurations are merged, and then configuration data whose hash key matches a
 931 component name is merged with configuration for that component.
 932
 933 The configuration for a component is then passed to the C<new> method when a
 934 component is constructed.
 935
 936 For example:
 937
 938     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 939     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 940
 941 will mean that C<MyApp::Model::Foo> receives the following data when
 942 constructed:
 943
 944     MyApp::Model::Foo->new({
 945         bar => 'baz',
 946         quux => 'frob',
 947         overrides => 'me',
 948     });
 949
 950 It's common practice to use a Moose attribute
 951 on the receiving component to access the config value.
 952
 953     package MyApp::Model::Foo;
 954
 955     use Moose;
 956
 957     # this attr will receive 'baz' at construction time
 958     has 'bar' => (
 959         is  => 'rw',
 960         isa => 'Str',
 961     );
 962
 963 You can then get the value 'baz' by calling $c->model('Foo')->bar
 964 (or $self->bar inside code in the model).
 965
 966 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 967 as a way of reading config within your code, as this B<will not> give you the
 968 correctly merged config back. You B<MUST> take the config values supplied to
 969 the constructor and use those instead.
 970
 971 =cut
 972
 973 around config => sub {
 974     my $orig = shift;
 975     my $c = shift;
 976
 977     croak('Setting config after setup has been run is not allowed.')
 978         if ( @_ and $c->setup_finished );
 979
 980     $c->$orig(@_);
 981 };
 982
 983 =head2 $c->log
 984
 985 Returns the logging object instance. Unless it is already set, Catalyst
 986 sets this up with a L<Catalyst::Log> object. To use your own log class,
 987 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 988 C<< __PACKAGE__->setup >>.
 989
 990  __PACKAGE__->log( MyLogger->new );
 991  __PACKAGE__->setup;
 992
 993 And later:
 994
 995     $c->log->info( 'Now logging with my own logger!' );
 996
 997 Your log class should implement the methods described in
 998 L<Catalyst::Log>.
 999
1000
1001 =head2 $c->debug
1002
1003 Returns 1 if debug mode is enabled, 0 otherwise.
1004
1005 You can enable debug mode in several ways:
1006
1007 =over
1008
1009 =item By calling myapp_server.pl with the -d flag
1010
1011 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1012
1013 =item The -Debug option in your MyApp.pm
1014
1015 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1016
1017 =back
1018
1019 The first three also set the log level to 'debug'.
1020
1021 Calling C<< $c->debug(1) >> has no effect.
1022
1023 =cut
1024
1025 sub debug { 0 }
1026
1027 =head2 $c->dispatcher
1028
1029 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1030
1031 =head2 $c->engine
1032
1033 Returns the engine instance. See L<Catalyst::Engine>.
1034
1035
1036 =head2 UTILITY METHODS
1037
1038 =head2 $c->path_to(@path)
1039
1040 Merges C<@path> with C<< $c->config->{home} >> and returns a
1041 L<Path::Class::Dir> object. Note you can usually use this object as
1042 a filename, but sometimes you will have to explicitly stringify it
1043 yourself by calling the C<< ->stringify >> method.
1044
1045 For example:
1046
1047     $c->path_to( 'db', 'sqlite.db' );
1048
1049 =cut
1050
1051 sub path_to {
1052     my ( $c, @path ) = @_;
1053     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1054     if ( -d $path ) { return $path }
1055     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1056 }
1057
1058 sub plugin {
1059     my ( $class, $name, $plugin, @args ) = @_;
1060
1061     # See block comment in t/unit_core_plugin.t
1062     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1063
1064     $class->_register_plugin( $plugin, 1 );
1065
1066     eval { $plugin->import };
1067     $class->mk_classdata($name);
1068     my $obj;
1069     eval { $obj = $plugin->new(@args) };
1070
1071     if ($@) {
1072         Catalyst::Exception->throw( message =>
1073               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1074     }
1075
1076     $class->$name($obj);
1077     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1078       if $class->debug;
1079 }
1080
1081 =head2 MyApp->setup
1082
1083 Initializes the dispatcher and engine, loads any plugins, and loads the
1084 model, view, and controller components. You may also specify an array
1085 of plugins to load here, if you choose to not load them in the C<use
1086 Catalyst> line.
1087
1088     MyApp->setup;
1089     MyApp->setup( qw/-Debug/ );
1090
1091 B<Note:> You B<should not> wrap this method with method modifiers
1092 or bad things will happen - wrap the C<setup_finalize> method instead.
1093
1094 =cut
1095
1096 sub setup {
1097     my ( $class, @arguments ) = @_;
1098     croak('Running setup more than once')
1099         if ( $class->setup_finished );
1100
1101     unless ( $class->isa('Catalyst') ) {
1102
1103         Catalyst::Exception->throw(
1104             message => qq/'$class' does not inherit from Catalyst/ );
1105     }
1106
1107     if ( $class->arguments ) {
1108         @arguments = ( @arguments, @{ $class->arguments } );
1109     }
1110
1111     # Process options
1112     my $flags = {};
1113
1114     foreach (@arguments) {
1115
1116         if (/^-Debug$/) {
1117             $flags->{log} =
1118               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1119         }
1120         elsif (/^-(\w+)=?(.*)$/) {
1121             $flags->{ lc $1 } = $2;
1122         }
1123         else {
1124             push @{ $flags->{plugins} }, $_;
1125         }
1126     }
1127
1128     $class->setup_home( delete $flags->{home} );
1129
1130     $class->setup_log( delete $flags->{log} );
1131     $class->setup_plugins( delete $flags->{plugins} );
1132
1133     # Call plugins setup, this is stupid and evil.
1134     # Also screws C3 badly on 5.10, hack to avoid.
1135     {
1136         no warnings qw/redefine/;
1137         local *setup = sub { };
1138         $class->setup unless $Catalyst::__AM_RESTARTING;
1139     }
1140
1141     $class->setup_middleware();
1142     $class->setup_data_handlers();
1143     $class->setup_dispatcher( delete $flags->{dispatcher} );
1144     if (my $engine = delete $flags->{engine}) {
1145         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1146     }
1147     $class->setup_engine();
1148     $class->setup_stats( delete $flags->{stats} );
1149
1150     for my $flag ( sort keys %{$flags} ) {
1151
1152         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1153             &$code( $class, delete $flags->{$flag} );
1154         }
1155         else {
1156             $class->log->warn(qq/Unknown flag "$flag"/);
1157         }
1158     }
1159
1160     eval { require Catalyst::Devel; };
1161     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1162         $class->log->warn(<<"EOF");
1163 You are running an old script!
1164
1165   Please update by running (this will overwrite existing files):
1166     catalyst.pl -force -scripts $class
1167
1168   or (this will not overwrite existing files):
1169     catalyst.pl -scripts $class
1170
1171 EOF
1172     }
1173
1174     # Initialize our data structure
1175     $class->components( {} );
1176
1177     $class->setup_components;
1178
1179     if ( $class->debug ) {
1180         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1181
1182         if (@plugins) {
1183             my $column_width = Catalyst::Utils::term_width() - 6;
1184             my $t = Text::SimpleTable->new($column_width);
1185             $t->row($_) for @plugins;
1186             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1187         }
1188
1189         my @middleware = map {
1190           ref $_ eq 'CODE' ?
1191             "Inline Coderef" :
1192               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1193                 || '')  } $class->registered_middlewares;
1194
1195         if (@middleware) {
1196             my $column_width = Catalyst::Utils::term_width() - 6;
1197             my $t = Text::SimpleTable->new($column_width);
1198             $t->row($_) for @middleware;
1199             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1200         }
1201
1202         my %dh = $class->registered_data_handlers;
1203         if (my @data_handlers = keys %dh) {
1204             my $column_width = Catalyst::Utils::term_width() - 6;
1205             my $t = Text::SimpleTable->new($column_width);
1206             $t->row($_) for @data_handlers;
1207             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1208         }
1209
1210         my $dispatcher = $class->dispatcher;
1211         my $engine     = $class->engine;
1212         my $home       = $class->config->{home};
1213
1214         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1215         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1216
1217         $home
1218           ? ( -d $home )
1219           ? $class->log->debug(qq/Found home "$home"/)
1220           : $class->log->debug(qq/Home "$home" doesn't exist/)
1221           : $class->log->debug(q/Couldn't find home/);
1222
1223         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1224         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1225         for my $comp ( sort keys %{ $class->components } ) {
1226             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1227             $t->row( $comp, $type );
1228         }
1229         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1230           if ( keys %{ $class->components } );
1231     }
1232
1233     # Add our self to components, since we are also a component
1234     if( $class->isa('Catalyst::Controller') ){
1235       $class->components->{$class} = $class;
1236     }
1237
1238     $class->setup_actions;
1239
1240     if ( $class->debug ) {
1241         my $name = $class->config->{name} || 'Application';
1242         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1243     }
1244
1245     if ($class->config->{case_sensitive}) {
1246         $class->log->warn($class . "->config->{case_sensitive} is set.");
1247         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1248     }
1249
1250     $class->setup_finalize;
1251     # Should be the last thing we do so that user things hooking
1252     # setup_finalize can log..
1253     $class->log->_flush() if $class->log->can('_flush');
1254     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1255 }
1256
1257 =head2 $app->setup_finalize
1258
1259 A hook to attach modifiers to. This method does not do anything except set the
1260 C<setup_finished> accessor.
1261
1262 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1263
1264 Example:
1265
1266     after setup_finalize => sub {
1267         my $app = shift;
1268
1269         ## do stuff here..
1270     };
1271
1272 =cut
1273
1274 sub setup_finalize {
1275     my ($class) = @_;
1276     $class->setup_finished(1);
1277 }
1278
1279 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1280
1281 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1282
1283 Constructs an absolute L<URI> object based on the application root, the
1284 provided path, and the additional arguments and query parameters provided.
1285 When used as a string, provides a textual URI.  If you need more flexibility
1286 than this (i.e. the option to provide relative URIs etc.) see
1287 L<Catalyst::Plugin::SmartURI>.
1288
1289 If no arguments are provided, the URI for the current action is returned.
1290 To return the current action and also provide @args, use
1291 C<< $c->uri_for( $c->action, @args ) >>.
1292
1293 If the first argument is a string, it is taken as a public URI path relative
1294 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1295 relative to the application root (if it does). It is then merged with
1296 C<< $c->request->base >>; any C<@args> are appended as additional path
1297 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1298
1299 If the first argument is a L<Catalyst::Action> it represents an action which
1300 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1301 optional C<\@captures> argument (an arrayref) allows passing the captured
1302 variables that are needed to fill in the paths of Chained and Regex actions;
1303 once the path is resolved, C<uri_for> continues as though a path was
1304 provided, appending any arguments or parameters and creating an absolute
1305 URI.
1306
1307 The captures for the current request can be found in
1308 C<< $c->request->captures >>, and actions can be resolved using
1309 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1310 path, use C<< $c->uri_for_action >> instead.
1311
1312   # Equivalent to $c->req->uri
1313   $c->uri_for($c->action, $c->req->captures,
1314       @{ $c->req->args }, $c->req->params);
1315
1316   # For the Foo action in the Bar controller
1317   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1318
1319   # Path to a static resource
1320   $c->uri_for('/static/images/logo.png');
1321
1322 =cut
1323
1324 sub uri_for {
1325     my ( $c, $path, @args ) = @_;
1326
1327     if ( $path->$_isa('Catalyst::Controller') ) {
1328         $path = $path->path_prefix;
1329         $path =~ s{/+\z}{};
1330         $path .= '/';
1331     }
1332
1333     undef($path) if (defined $path && $path eq '');
1334
1335     my $params =
1336       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1337
1338     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1339     foreach my $arg (@args) {
1340         utf8::encode($arg) if utf8::is_utf8($arg);
1341         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1342     }
1343
1344     if ( $path->$_isa('Catalyst::Action') ) { # action object
1345         s|/|%2F|g for @args;
1346         my $captures = [ map { s|/|%2F|g; $_; }
1347                         ( scalar @args && ref $args[0] eq 'ARRAY'
1348                          ? @{ shift(@args) }
1349                          : ()) ];
1350
1351         foreach my $capture (@$captures) {
1352             utf8::encode($capture) if utf8::is_utf8($capture);
1353             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1354         }
1355
1356         my $action = $path;
1357         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1358         if( !@args && $action->number_of_args ) {
1359             my $expanded_action = $c->dispatcher->expand_action( $action );
1360
1361             my $num_captures = $expanded_action->number_of_captures;
1362             unshift @args, splice @$captures, $num_captures;
1363         }
1364
1365        $path = $c->dispatcher->uri_for_action($action, $captures);
1366         if (not defined $path) {
1367             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1368                 if $c->debug;
1369             return undef;
1370         }
1371         $path = '/' if $path eq '';
1372     }
1373
1374     unshift(@args, $path);
1375
1376     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1377         my $namespace = $c->namespace;
1378         if (defined $path) { # cheesy hack to handle path '../foo'
1379            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1380         }
1381         unshift(@args, $namespace || '');
1382     }
1383
1384     # join args with '/', or a blank string
1385     my $args = join('/', grep { defined($_) } @args);
1386     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1387     $args =~ s!^/+!!;
1388
1389     my ($base, $class) = ('/', 'URI::_generic');
1390     if(blessed($c)) {
1391       $base = $c->req->base;
1392       $class = ref($base);
1393       $base =~ s{(?<!/)$}{/};
1394     }
1395
1396     my $query = '';
1397
1398     if (my @keys = keys %$params) {
1399       # somewhat lifted from URI::_query's query_form
1400       $query = '?'.join('&', map {
1401           my $val = $params->{$_};
1402           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1403           s/ /+/g;
1404           my $key = $_;
1405           $val = '' unless defined $val;
1406           (map {
1407               my $param = "$_";
1408               utf8::encode( $param ) if utf8::is_utf8($param);
1409               # using the URI::Escape pattern here so utf8 chars survive
1410               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1411               $param =~ s/ /+/g;
1412               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1413       } @keys);
1414     }
1415
1416     my $res = bless(\"${base}${args}${query}", $class);
1417     $res;
1418 }
1419
1420 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1421
1422 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1423
1424 =over
1425
1426 =item $path
1427
1428 A private path to the Catalyst action you want to create a URI for.
1429
1430 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1431 >> and passing the resulting C<$action> and the remaining arguments to C<<
1432 $c->uri_for >>.
1433
1434 You can also pass in a Catalyst::Action object, in which case it is passed to
1435 C<< $c->uri_for >>.
1436
1437 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1438
1439 For example, if the action looks like:
1440
1441  package MyApp::Controller::Users;
1442
1443  sub lst : Path('the-list') {}
1444
1445 You can use:
1446
1447  $c->uri_for_action('/users/lst')
1448
1449 and it will create the URI /users/the-list.
1450
1451 =item \@captures_and_args?
1452
1453 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1454 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1455 to interpolate all the parameters in the URI.
1456
1457 =item @args?
1458
1459 Optional list of extra arguments - can be supplied in the
1460 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1461 code.
1462
1463 Your action can have zero, a fixed or a variable number of args (e.g.
1464 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1465
1466 =item \%query_values?
1467
1468 Optional array reference of query parameters to append. E.g.
1469
1470   { foo => 'bar' }
1471
1472 will generate
1473
1474   /rest/of/your/uri?foo=bar
1475
1476 =back
1477
1478 =cut
1479
1480 sub uri_for_action {
1481     my ( $c, $path, @args ) = @_;
1482     my $action = blessed($path)
1483       ? $path
1484       : $c->dispatcher->get_action_by_path($path);
1485     unless (defined $action) {
1486       croak "Can't find action for path '$path'";
1487     }
1488     return $c->uri_for( $action, @args );
1489 }
1490
1491 =head2 $c->welcome_message
1492
1493 Returns the Catalyst welcome HTML page.
1494
1495 =cut
1496
1497 sub welcome_message {
1498     my $c      = shift;
1499     my $name   = $c->config->{name};
1500     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1501     my $prefix = Catalyst::Utils::appprefix( ref $c );
1502     $c->response->content_type('text/html; charset=utf-8');
1503     return <<"EOF";
1504 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1505     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1506 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1507     <head>
1508     <meta http-equiv="Content-Language" content="en" />
1509     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1510         <title>$name on Catalyst $VERSION</title>
1511         <style type="text/css">
1512             body {
1513                 color: #000;
1514                 background-color: #eee;
1515             }
1516             div#content {
1517                 width: 640px;
1518                 margin-left: auto;
1519                 margin-right: auto;
1520                 margin-top: 10px;
1521                 margin-bottom: 10px;
1522                 text-align: left;
1523                 background-color: #ccc;
1524                 border: 1px solid #aaa;
1525             }
1526             p, h1, h2 {
1527                 margin-left: 20px;
1528                 margin-right: 20px;
1529                 font-family: verdana, tahoma, sans-serif;
1530             }
1531             a {
1532                 font-family: verdana, tahoma, sans-serif;
1533             }
1534             :link, :visited {
1535                     text-decoration: none;
1536                     color: #b00;
1537                     border-bottom: 1px dotted #bbb;
1538             }
1539             :link:hover, :visited:hover {
1540                     color: #555;
1541             }
1542             div#topbar {
1543                 margin: 0px;
1544             }
1545             pre {
1546                 margin: 10px;
1547                 padding: 8px;
1548             }
1549             div#answers {
1550                 padding: 8px;
1551                 margin: 10px;
1552                 background-color: #fff;
1553                 border: 1px solid #aaa;
1554             }
1555             h1 {
1556                 font-size: 0.9em;
1557                 font-weight: normal;
1558                 text-align: center;
1559             }
1560             h2 {
1561                 font-size: 1.0em;
1562             }
1563             p {
1564                 font-size: 0.9em;
1565             }
1566             p img {
1567                 float: right;
1568                 margin-left: 10px;
1569             }
1570             span#appname {
1571                 font-weight: bold;
1572                 font-size: 1.6em;
1573             }
1574         </style>
1575     </head>
1576     <body>
1577         <div id="content">
1578             <div id="topbar">
1579                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1580                     $VERSION</h1>
1581              </div>
1582              <div id="answers">
1583                  <p>
1584                  <img src="$logo" alt="Catalyst Logo" />
1585                  </p>
1586                  <p>Welcome to the  world of Catalyst.
1587                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1588                     framework will make web development something you had
1589                     never expected it to be: Fun, rewarding, and quick.</p>
1590                  <h2>What to do now?</h2>
1591                  <p>That really depends  on what <b>you</b> want to do.
1592                     We do, however, provide you with a few starting points.</p>
1593                  <p>If you want to jump right into web development with Catalyst
1594                     you might want to start with a tutorial.</p>
1595 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1596 </pre>
1597 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1598 <pre>
1599 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1600 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1601 </code></pre>
1602                  <h2>What to do next?</h2>
1603                  <p>Next it's time to write an actual application. Use the
1604                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1605                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1606                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1607                     they can save you a lot of work.</p>
1608                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1609                     <p>Also, be sure to check out the vast and growing
1610                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1611                     you are likely to find what you need there.
1612                     </p>
1613
1614                  <h2>Need help?</h2>
1615                  <p>Catalyst has a very active community. Here are the main places to
1616                     get in touch with us.</p>
1617                  <ul>
1618                      <li>
1619                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1620                      </li>
1621                      <li>
1622                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1623                      </li>
1624                      <li>
1625                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1626                      </li>
1627                  </ul>
1628                  <h2>In conclusion</h2>
1629                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1630                     as we enjoyed making it. Please contact us if you have ideas
1631                     for improvement or other feedback.</p>
1632              </div>
1633          </div>
1634     </body>
1635 </html>
1636 EOF
1637 }
1638
1639 =head2 run_options
1640
1641 Contains a hash of options passed from the application script, including
1642 the original ARGV the script received, the processed values from that
1643 ARGV and any extra arguments to the script which were not processed.
1644
1645 This can be used to add custom options to your application's scripts
1646 and setup your application differently depending on the values of these
1647 options.
1648
1649 =head1 INTERNAL METHODS
1650
1651 These methods are not meant to be used by end users.
1652
1653 =head2 $c->components
1654
1655 Returns a hash of components.
1656
1657 =head2 $c->context_class
1658
1659 Returns or sets the context class.
1660
1661 =head2 $c->counter
1662
1663 Returns a hashref containing coderefs and execution counts (needed for
1664 deep recursion detection).
1665
1666 =head2 $c->depth
1667
1668 Returns the number of actions on the current internal execution stack.
1669
1670 =head2 $c->dispatch
1671
1672 Dispatches a request to actions.
1673
1674 =cut
1675
1676 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1677
1678 =head2 $c->dispatcher_class
1679
1680 Returns or sets the dispatcher class.
1681
1682 =head2 $c->dump_these
1683
1684 Returns a list of 2-element array references (name, structure) pairs
1685 that will be dumped on the error page in debug mode.
1686
1687 =cut
1688
1689 sub dump_these {
1690     my $c = shift;
1691     [ Request => $c->req ],
1692     [ Response => $c->res ],
1693     [ Stash => $c->stash ],
1694     [ Config => $c->config ];
1695 }
1696
1697 =head2 $c->engine_class
1698
1699 Returns or sets the engine class.
1700
1701 =head2 $c->execute( $class, $coderef )
1702
1703 Execute a coderef in given class and catch exceptions. Errors are available
1704 via $c->error.
1705
1706 =cut
1707
1708 sub execute {
1709     my ( $c, $class, $code ) = @_;
1710     $class = $c->component($class) || $class;
1711     $c->state(0);
1712
1713     if ( $c->depth >= $RECURSION ) {
1714         my $action = $code->reverse();
1715         $action = "/$action" unless $action =~ /->/;
1716         my $error = qq/Deep recursion detected calling "${action}"/;
1717         $c->log->error($error);
1718         $c->error($error);
1719         $c->state(0);
1720         return $c->state;
1721     }
1722
1723     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1724
1725     push( @{ $c->stack }, $code );
1726
1727     no warnings 'recursion';
1728     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1729     #      I have no idea how, ergo $ret (which appears to fix the issue)
1730     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1731
1732     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1733
1734     my $last = pop( @{ $c->stack } );
1735
1736     if ( my $error = $@ ) {
1737         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1738             $error->rethrow if $c->depth > 1;
1739         }
1740         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1741             $error->rethrow if $c->depth > 0;
1742         }
1743         else {
1744             unless ( ref $error ) {
1745                 no warnings 'uninitialized';
1746                 chomp $error;
1747                 my $class = $last->class;
1748                 my $name  = $last->name;
1749                 $error = qq/Caught exception in $class->$name "$error"/;
1750             }
1751             $c->error($error);
1752         }
1753         $c->state(0);
1754     }
1755     return $c->state;
1756 }
1757
1758 sub _stats_start_execute {
1759     my ( $c, $code ) = @_;
1760     my $appclass = ref($c) || $c;
1761     return if ( ( $code->name =~ /^_.*/ )
1762         && ( !$appclass->config->{show_internal_actions} ) );
1763
1764     my $action_name = $code->reverse();
1765     $c->counter->{$action_name}++;
1766
1767     my $action = $action_name;
1768     $action = "/$action" unless $action =~ /->/;
1769
1770     # determine if the call was the result of a forward
1771     # this is done by walking up the call stack and looking for a calling
1772     # sub of Catalyst::forward before the eval
1773     my $callsub = q{};
1774     for my $index ( 2 .. 11 ) {
1775         last
1776         if ( ( caller($index) )[0] eq 'Catalyst'
1777             && ( caller($index) )[3] eq '(eval)' );
1778
1779         if ( ( caller($index) )[3] =~ /forward$/ ) {
1780             $callsub = ( caller($index) )[3];
1781             $action  = "-> $action";
1782             last;
1783         }
1784     }
1785
1786     my $uid = $action_name . $c->counter->{$action_name};
1787
1788     # is this a root-level call or a forwarded call?
1789     if ( $callsub =~ /forward$/ ) {
1790         my $parent = $c->stack->[-1];
1791
1792         # forward, locate the caller
1793         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1794             $c->stats->profile(
1795                 begin  => $action,
1796                 parent => "$parent" . $c->counter->{"$parent"},
1797                 uid    => $uid,
1798             );
1799         }
1800         else {
1801
1802             # forward with no caller may come from a plugin
1803             $c->stats->profile(
1804                 begin => $action,
1805                 uid   => $uid,
1806             );
1807         }
1808     }
1809     else {
1810
1811         # root-level call
1812         $c->stats->profile(
1813             begin => $action,
1814             uid   => $uid,
1815         );
1816     }
1817     return $action;
1818
1819 }
1820
1821 sub _stats_finish_execute {
1822     my ( $c, $info ) = @_;
1823     $c->stats->profile( end => $info );
1824 }
1825
1826 =head2 $c->finalize
1827
1828 Finalizes the request.
1829
1830 =cut
1831
1832 sub finalize {
1833     my $c = shift;
1834
1835     for my $error ( @{ $c->error } ) {
1836         $c->log->error($error);
1837     }
1838
1839     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1840     # stuff like cometd and websockets
1841
1842     if($c->request->_has_io_fh) {
1843       $c->log_response;
1844       return;
1845     }
1846
1847     # Allow engine to handle finalize flow (for POE)
1848     my $engine = $c->engine;
1849     if ( my $code = $engine->can('finalize') ) {
1850         $engine->$code($c);
1851     }
1852     else {
1853
1854         $c->finalize_uploads;
1855
1856         # Error
1857         if ( $#{ $c->error } >= 0 ) {
1858             $c->finalize_error;
1859         }
1860
1861         $c->finalize_headers unless $c->response->finalized_headers;
1862
1863         $c->finalize_body;
1864     }
1865
1866     $c->log_response;
1867
1868     if ($c->use_stats) {
1869         my $elapsed = $c->stats->elapsed;
1870         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1871         $c->log->info(
1872             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1873     }
1874
1875     return $c->response->status;
1876 }
1877
1878 =head2 $c->finalize_body
1879
1880 Finalizes body.
1881
1882 =cut
1883
1884 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1885
1886 =head2 $c->finalize_cookies
1887
1888 Finalizes cookies.
1889
1890 =cut
1891
1892 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1893
1894 =head2 $c->finalize_error
1895
1896 Finalizes error.
1897
1898 =cut
1899
1900 sub finalize_error {
1901     my $c = shift;
1902     if($#{$c->error} > 0) {
1903         $c->engine->finalize_error( $c, @_ );
1904     } else {
1905         my ($error) = @{$c->error};
1906         if(
1907           blessed $error &&
1908           ($error->can('as_psgi') || $error->can('code'))
1909         ) {
1910             # In the case where the error 'knows what it wants', becauses its PSGI
1911             # aware, just rethow and let middleware catch it
1912             $error->can('rethrow') ? $error->rethrow : croak $error;
1913             croak $error;
1914         } else {
1915             $c->engine->finalize_error( $c, @_ )
1916         }
1917     }
1918 }
1919
1920 =head2 $c->finalize_headers
1921
1922 Finalizes headers.
1923
1924 =cut
1925
1926 sub finalize_headers {
1927     my $c = shift;
1928
1929     my $response = $c->response; #accessor calls can add up?
1930
1931     # Check if we already finalized headers
1932     return if $response->finalized_headers;
1933
1934     # Handle redirects
1935     if ( my $location = $response->redirect ) {
1936         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1937         $response->header( Location => $location );
1938
1939         if ( !$response->has_body ) {
1940             # Add a default body if none is already present
1941             my $encoded_location = encode_entities($location);
1942             $response->body(<<"EOF");
1943 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1944 <html xmlns="http://www.w3.org/1999/xhtml">
1945   <head>
1946     <title>Moved</title>
1947   </head>
1948   <body>
1949      <p>This item has moved <a href="$encoded_location">here</a>.</p>
1950   </body>
1951 </html>
1952 EOF
1953             $response->content_type('text/html; charset=utf-8');
1954         }
1955     }
1956
1957     # Remove incorrectly added body and content related meta data when returning
1958     # an information response, or a response the is required to not include a body
1959
1960     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1961         if($response->has_body) {
1962           $c->log->debug('Removing body for informational or no content http responses');
1963           $response->body('');
1964           $response->headers->remove_header("Content-Length");
1965         }
1966     }
1967
1968     $c->finalize_cookies;
1969
1970     $c->response->finalize_headers();
1971
1972     # Done
1973     $response->finalized_headers(1);
1974 }
1975
1976 =head2 $c->finalize_output
1977
1978 An alias for finalize_body.
1979
1980 =head2 $c->finalize_read
1981
1982 Finalizes the input after reading is complete.
1983
1984 =cut
1985
1986 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1987
1988 =head2 $c->finalize_uploads
1989
1990 Finalizes uploads. Cleans up any temporary files.
1991
1992 =cut
1993
1994 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1995
1996 =head2 $c->get_action( $action, $namespace )
1997
1998 Gets an action in a given namespace.
1999
2000 =cut
2001
2002 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2003
2004 =head2 $c->get_actions( $action, $namespace )
2005
2006 Gets all actions of a given name in a namespace and all parent
2007 namespaces.
2008
2009 =cut
2010
2011 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2012
2013 =head2 $app->handle_request( @arguments )
2014
2015 Called to handle each HTTP request.
2016
2017 =cut
2018
2019 sub handle_request {
2020     my ( $class, @arguments ) = @_;
2021
2022     # Always expect worst case!
2023     my $status = -1;
2024     try {
2025         if ($class->debug) {
2026             my $secs = time - $START || 1;
2027             my $av = sprintf '%.3f', $COUNT / $secs;
2028             my $time = localtime time;
2029             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2030         }
2031
2032         my $c = $class->prepare(@arguments);
2033         $c->dispatch;
2034         $status = $c->finalize;
2035     } catch {
2036         chomp(my $error = $_);
2037         $class->log->error(qq/Caught exception in engine "$error"/);
2038         #rethow if this can be handled by middleware
2039         if(blessed $error && ($error->can('as_psgi') || $error->can('code'))) {
2040             $error->can('rethrow') ? $error->rethrow : croak $error;
2041         }
2042     };
2043
2044     $COUNT++;
2045
2046     if(my $coderef = $class->log->can('_flush')){
2047         $class->log->$coderef();
2048     }
2049     return $status;
2050 }
2051
2052 =head2 $class->prepare( @arguments )
2053
2054 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2055 etc.).
2056
2057 =cut
2058
2059 has _uploadtmp => (
2060     is => 'ro',
2061     predicate => '_has_uploadtmp',
2062 );
2063
2064 sub prepare {
2065     my ( $class, @arguments ) = @_;
2066
2067     # XXX
2068     # After the app/ctxt split, this should become an attribute based on something passed
2069     # into the application.
2070     $class->context_class( ref $class || $class ) unless $class->context_class;
2071
2072     my $uploadtmp = $class->config->{uploadtmp};
2073     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2074
2075     $c->response->_context($c);
2076
2077     #surely this is not the most efficient way to do things...
2078     $c->stats($class->stats_class->new)->enable($c->use_stats);
2079     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2080         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2081     }
2082
2083     try {
2084         # Allow engine to direct the prepare flow (for POE)
2085         if ( my $prepare = $c->engine->can('prepare') ) {
2086             $c->engine->$prepare( $c, @arguments );
2087         }
2088         else {
2089             $c->prepare_request(@arguments);
2090             $c->prepare_connection;
2091             $c->prepare_query_parameters;
2092             $c->prepare_headers; # Just hooks, no longer needed - they just
2093             $c->prepare_cookies; # cause the lazy attribute on req to build
2094             $c->prepare_path;
2095
2096             # Prepare the body for reading, either by prepare_body
2097             # or the user, if they are using $c->read
2098             $c->prepare_read;
2099
2100             # Parse the body unless the user wants it on-demand
2101             unless ( ref($c)->config->{parse_on_demand} ) {
2102                 $c->prepare_body;
2103             }
2104         }
2105         $c->prepare_action;
2106     }
2107     # VERY ugly and probably shouldn't rely on ->finalize actually working
2108     catch {
2109         # failed prepare is always due to an invalid request, right?
2110         $c->response->status(400);
2111         $c->response->content_type('text/plain');
2112         $c->response->body('Bad Request');
2113         # Note we call finalize and then die here, which escapes
2114         # finalize being called in the enclosing block..
2115         # It in fact couldn't be called, as we don't return $c..
2116         # This is a mess - but I'm unsure you can fix this without
2117         # breaking compat for people doing crazy things (we should set
2118         # the 400 and just return the ctx here IMO, letting finalize get called
2119         # above...
2120         $c->finalize;
2121         die $_;
2122     };
2123
2124     $c->log_request;
2125
2126     return $c;
2127 }
2128
2129 =head2 $c->prepare_action
2130
2131 Prepares action. See L<Catalyst::Dispatcher>.
2132
2133 =cut
2134
2135 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2136
2137 =head2 $c->prepare_body
2138
2139 Prepares message body.
2140
2141 =cut
2142
2143 sub prepare_body {
2144     my $c = shift;
2145
2146     return if $c->request->_has_body;
2147
2148     # Initialize on-demand data
2149     $c->engine->prepare_body( $c, @_ );
2150     $c->prepare_parameters;
2151     $c->prepare_uploads;
2152 }
2153
2154 =head2 $c->prepare_body_chunk( $chunk )
2155
2156 Prepares a chunk of data before sending it to L<HTTP::Body>.
2157
2158 See L<Catalyst::Engine>.
2159
2160 =cut
2161
2162 sub prepare_body_chunk {
2163     my $c = shift;
2164     $c->engine->prepare_body_chunk( $c, @_ );
2165 }
2166
2167 =head2 $c->prepare_body_parameters
2168
2169 Prepares body parameters.
2170
2171 =cut
2172
2173 sub prepare_body_parameters {
2174     my $c = shift;
2175     $c->engine->prepare_body_parameters( $c, @_ );
2176 }
2177
2178 =head2 $c->prepare_connection
2179
2180 Prepares connection.
2181
2182 =cut
2183
2184 sub prepare_connection {
2185     my $c = shift;
2186     # XXX - This is called on the engine (not the request) to maintain
2187     #       Engine::PSGI back compat.
2188     $c->engine->prepare_connection($c);
2189 }
2190
2191 =head2 $c->prepare_cookies
2192
2193 Prepares cookies by ensuring that the attribute on the request
2194 object has been built.
2195
2196 =cut
2197
2198 sub prepare_cookies { my $c = shift; $c->request->cookies }
2199
2200 =head2 $c->prepare_headers
2201
2202 Prepares request headers by ensuring that the attribute on the request
2203 object has been built.
2204
2205 =cut
2206
2207 sub prepare_headers { my $c = shift; $c->request->headers }
2208
2209 =head2 $c->prepare_parameters
2210
2211 Prepares parameters.
2212
2213 =cut
2214
2215 sub prepare_parameters {
2216     my $c = shift;
2217     $c->prepare_body_parameters;
2218     $c->engine->prepare_parameters( $c, @_ );
2219 }
2220
2221 =head2 $c->prepare_path
2222
2223 Prepares path and base.
2224
2225 =cut
2226
2227 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2228
2229 =head2 $c->prepare_query_parameters
2230
2231 Prepares query parameters.
2232
2233 =cut
2234
2235 sub prepare_query_parameters {
2236     my $c = shift;
2237
2238     $c->engine->prepare_query_parameters( $c, @_ );
2239 }
2240
2241 =head2 $c->log_request
2242
2243 Writes information about the request to the debug logs.  This includes:
2244
2245 =over 4
2246
2247 =item * Request method, path, and remote IP address
2248
2249 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2250
2251 =item * Request parameters
2252
2253 =item * File uploads
2254
2255 =back
2256
2257 =cut
2258
2259 sub log_request {
2260     my $c = shift;
2261
2262     return unless $c->debug;
2263
2264     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2265     my $request = $dump->[1];
2266
2267     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2268     $method ||= '';
2269     $path = '/' unless length $path;
2270     $address ||= '';
2271     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2272
2273     $c->log_request_headers($request->headers);
2274
2275     if ( my $keywords = $request->query_keywords ) {
2276         $c->log->debug("Query keywords are: $keywords");
2277     }
2278
2279     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2280
2281     $c->log_request_uploads($request);
2282 }
2283
2284 =head2 $c->log_response
2285
2286 Writes information about the response to the debug logs by calling
2287 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2288
2289 =cut
2290
2291 sub log_response {
2292     my $c = shift;
2293
2294     return unless $c->debug;
2295
2296     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2297     my $response = $dump->[1];
2298
2299     $c->log_response_status_line($response);
2300     $c->log_response_headers($response->headers);
2301 }
2302
2303 =head2 $c->log_response_status_line($response)
2304
2305 Writes one line of information about the response to the debug logs.  This includes:
2306
2307 =over 4
2308
2309 =item * Response status code
2310
2311 =item * Content-Type header (if present)
2312
2313 =item * Content-Length header (if present)
2314
2315 =back
2316
2317 =cut
2318
2319 sub log_response_status_line {
2320     my ($c, $response) = @_;
2321
2322     $c->log->debug(
2323         sprintf(
2324             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2325             $response->status                            || 'unknown',
2326             $response->headers->header('Content-Type')   || 'unknown',
2327             $response->headers->header('Content-Length') || 'unknown'
2328         )
2329     );
2330 }
2331
2332 =head2 $c->log_response_headers($headers);
2333
2334 Hook method which can be wrapped by plugins to log the response headers.
2335 No-op in the default implementation.
2336
2337 =cut
2338
2339 sub log_response_headers {}
2340
2341 =head2 $c->log_request_parameters( query => {}, body => {} )
2342
2343 Logs request parameters to debug logs
2344
2345 =cut
2346
2347 sub log_request_parameters {
2348     my $c          = shift;
2349     my %all_params = @_;
2350
2351     return unless $c->debug;
2352
2353     my $column_width = Catalyst::Utils::term_width() - 44;
2354     foreach my $type (qw(query body)) {
2355         my $params = $all_params{$type};
2356         next if ! keys %$params;
2357         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2358         for my $key ( sort keys %$params ) {
2359             my $param = $params->{$key};
2360             my $value = defined($param) ? $param : '';
2361             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2362         }
2363         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2364     }
2365 }
2366
2367 =head2 $c->log_request_uploads
2368
2369 Logs file uploads included in the request to the debug logs.
2370 The parameter name, filename, file type, and file size are all included in
2371 the debug logs.
2372
2373 =cut
2374
2375 sub log_request_uploads {
2376     my $c = shift;
2377     my $request = shift;
2378     return unless $c->debug;
2379     my $uploads = $request->uploads;
2380     if ( keys %$uploads ) {
2381         my $t = Text::SimpleTable->new(
2382             [ 12, 'Parameter' ],
2383             [ 26, 'Filename' ],
2384             [ 18, 'Type' ],
2385             [ 9,  'Size' ]
2386         );
2387         for my $key ( sort keys %$uploads ) {
2388             my $upload = $uploads->{$key};
2389             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2390                 $t->row( $key, $u->filename, $u->type, $u->size );
2391             }
2392         }
2393         $c->log->debug( "File Uploads are:\n" . $t->draw );
2394     }
2395 }
2396
2397 =head2 $c->log_request_headers($headers);
2398
2399 Hook method which can be wrapped by plugins to log the request headers.
2400 No-op in the default implementation.
2401
2402 =cut
2403
2404 sub log_request_headers {}
2405
2406 =head2 $c->log_headers($type => $headers)
2407
2408 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2409
2410 =cut
2411
2412 sub log_headers {
2413     my $c       = shift;
2414     my $type    = shift;
2415     my $headers = shift;    # an HTTP::Headers instance
2416
2417     return unless $c->debug;
2418
2419     my $column_width = Catalyst::Utils::term_width() - 28;
2420     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2421     $headers->scan(
2422         sub {
2423             my ( $name, $value ) = @_;
2424             $t->row( $name, $value );
2425         }
2426     );
2427     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2428 }
2429
2430
2431 =head2 $c->prepare_read
2432
2433 Prepares the input for reading.
2434
2435 =cut
2436
2437 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2438
2439 =head2 $c->prepare_request
2440
2441 Prepares the engine request.
2442
2443 =cut
2444
2445 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2446
2447 =head2 $c->prepare_uploads
2448
2449 Prepares uploads.
2450
2451 =cut
2452
2453 sub prepare_uploads {
2454     my $c = shift;
2455
2456     $c->engine->prepare_uploads( $c, @_ );
2457 }
2458
2459 =head2 $c->prepare_write
2460
2461 Prepares the output for writing.
2462
2463 =cut
2464
2465 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2466
2467 =head2 $c->request_class
2468
2469 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2470
2471 =head2 $c->response_class
2472
2473 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2474
2475 =head2 $c->read( [$maxlength] )
2476
2477 Reads a chunk of data from the request body. This method is designed to
2478 be used in a while loop, reading C<$maxlength> bytes on every call.
2479 C<$maxlength> defaults to the size of the request if not specified.
2480
2481 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2482 directly.
2483
2484 Warning: If you use read(), Catalyst will not process the body,
2485 so you will not be able to access POST parameters or file uploads via
2486 $c->request.  You must handle all body parsing yourself.
2487
2488 =cut
2489
2490 sub read { my $c = shift; return $c->request->read( @_ ) }
2491
2492 =head2 $c->run
2493
2494 Starts the engine.
2495
2496 =cut
2497
2498 sub run {
2499   my $app = shift;
2500   $app->_make_immutable_if_needed;
2501   $app->engine_loader->needs_psgi_engine_compat_hack ?
2502     $app->engine->run($app, @_) :
2503       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2504 }
2505
2506 sub _make_immutable_if_needed {
2507     my $class = shift;
2508     my $meta = find_meta($class);
2509     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2510     if (
2511         $meta->is_immutable
2512         && ! { $meta->immutable_options }->{replace_constructor}
2513         && $isa_ca
2514     ) {
2515         warn("You made your application class ($class) immutable, "
2516             . "but did not inline the\nconstructor. "
2517             . "This will break catalyst, as your app \@ISA "
2518             . "Class::Accessor(::Fast)?\nPlease pass "
2519             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2520     }
2521     unless ($meta->is_immutable) {
2522         # XXX - FIXME warning here as you should make your app immutable yourself.
2523         $meta->make_immutable(
2524             replace_constructor => 1,
2525         );
2526     }
2527 }
2528
2529 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2530
2531 Sets an action in a given namespace.
2532
2533 =cut
2534
2535 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2536
2537 =head2 $c->setup_actions($component)
2538
2539 Sets up actions for a component.
2540
2541 =cut
2542
2543 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2544
2545 =head2 $c->setup_components
2546
2547 This method is called internally to set up the application's components.
2548
2549 It finds modules by calling the L<locate_components> method, expands them to
2550 package names with the L<expand_component_module> method, and then installs
2551 each component into the application.
2552
2553 The C<setup_components> config option is passed to both of the above methods.
2554
2555 Installation of each component is performed by the L<setup_component> method,
2556 below.
2557
2558 =cut
2559
2560 sub setup_components {
2561     my $class = shift;
2562
2563     my $config  = $class->config->{ setup_components };
2564
2565     my @comps = $class->locate_components($config);
2566     my %comps = map { $_ => 1 } @comps;
2567
2568     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2569     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2570         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2571     ) if $deprecatedcatalyst_component_names;
2572
2573     for my $component ( @comps ) {
2574
2575         # We pass ignore_loaded here so that overlay files for (e.g.)
2576         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2577         # we know M::P::O found a file on disk so this is safe
2578
2579         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2580     }
2581
2582     for my $component (@comps) {
2583         my $instance = $class->components->{ $component } = $class->setup_component($component);
2584         my @expanded_components = $instance->can('expand_modules')
2585             ? $instance->expand_modules( $component, $config )
2586             : $class->expand_component_module( $component, $config );
2587         for my $component (@expanded_components) {
2588             next if $comps{$component};
2589             $class->components->{ $component } = $class->setup_component($component);
2590         }
2591     }
2592 }
2593
2594 =head2 $c->locate_components( $setup_component_config )
2595
2596 This method is meant to provide a list of component modules that should be
2597 setup for the application.  By default, it will use L<Module::Pluggable>.
2598
2599 Specify a C<setup_components> config option to pass additional options directly
2600 to L<Module::Pluggable>. To add additional search paths, specify a key named
2601 C<search_extra> as an array reference. Items in the array beginning with C<::>
2602 will have the application class name prepended to them.
2603
2604 =cut
2605
2606 sub locate_components {
2607     my $class  = shift;
2608     my $config = shift;
2609
2610     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2611     my $extra   = delete $config->{ search_extra } || [];
2612
2613     push @paths, @$extra;
2614
2615     my $locator = Module::Pluggable::Object->new(
2616         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2617         %$config
2618     );
2619
2620     # XXX think about ditching this sort entirely
2621     my @comps = sort { length $a <=> length $b } $locator->plugins;
2622
2623     return @comps;
2624 }
2625
2626 =head2 $c->expand_component_module( $component, $setup_component_config )
2627
2628 Components found by C<locate_components> will be passed to this method, which
2629 is expected to return a list of component (package) names to be set up.
2630
2631 =cut
2632
2633 sub expand_component_module {
2634     my ($class, $module) = @_;
2635     return Devel::InnerPackage::list_packages( $module );
2636 }
2637
2638 =head2 $c->setup_component
2639
2640 =cut
2641
2642 sub setup_component {
2643     my( $class, $component ) = @_;
2644
2645     unless ( $component->can( 'COMPONENT' ) ) {
2646         return $component;
2647     }
2648
2649     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2650     my $config = $class->config->{ $suffix } || {};
2651     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2652     # methods also pass it. local to avoid pointlessly shitting in config
2653     # for the debug screen, as $component is already the key name.
2654     local $config->{catalyst_component_name} = $component;
2655
2656     my $instance = eval { $component->COMPONENT( $class, $config ); };
2657
2658     if ( my $error = $@ ) {
2659         chomp $error;
2660         Catalyst::Exception->throw(
2661             message => qq/Couldn't instantiate component "$component", "$error"/
2662         );
2663     }
2664
2665     unless (blessed $instance) {
2666         my $metaclass = Moose::Util::find_meta($component);
2667         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2668         my $component_method_from = $method_meta->associated_metaclass->name;
2669         my $value = defined($instance) ? $instance : 'undef';
2670         Catalyst::Exception->throw(
2671             message =>
2672             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2673         );
2674     }
2675     return $instance;
2676 }
2677
2678 =head2 $c->setup_dispatcher
2679
2680 Sets up dispatcher.
2681
2682 =cut
2683
2684 sub setup_dispatcher {
2685     my ( $class, $dispatcher ) = @_;
2686
2687     if ($dispatcher) {
2688         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2689     }
2690
2691     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2692         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2693     }
2694
2695     unless ($dispatcher) {
2696         $dispatcher = $class->dispatcher_class;
2697     }
2698
2699     load_class($dispatcher);
2700
2701     # dispatcher instance
2702     $class->dispatcher( $dispatcher->new );
2703 }
2704
2705 =head2 $c->setup_engine
2706
2707 Sets up engine.
2708
2709 =cut
2710
2711 sub engine_class {
2712     my ($class, $requested_engine) = @_;
2713
2714     if (!$class->engine_loader || $requested_engine) {
2715         $class->engine_loader(
2716             Catalyst::EngineLoader->new({
2717                 application_name => $class,
2718                 (defined $requested_engine
2719                      ? (catalyst_engine_class => $requested_engine) : ()),
2720             }),
2721         );
2722     }
2723
2724     $class->engine_loader->catalyst_engine_class;
2725 }
2726
2727 sub setup_engine {
2728     my ($class, $requested_engine) = @_;
2729
2730     my $engine = do {
2731         my $loader = $class->engine_loader;
2732
2733         if (!$loader || $requested_engine) {
2734             $loader = Catalyst::EngineLoader->new({
2735                 application_name => $class,
2736                 (defined $requested_engine
2737                      ? (requested_engine => $requested_engine) : ()),
2738             }),
2739
2740             $class->engine_loader($loader);
2741         }
2742
2743         $loader->catalyst_engine_class;
2744     };
2745
2746     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2747     return if $class->loading_psgi_file;
2748
2749     load_class($engine);
2750
2751     if ($ENV{MOD_PERL}) {
2752         my $apache = $class->engine_loader->auto;
2753
2754         my $meta = find_meta($class);
2755         my $was_immutable = $meta->is_immutable;
2756         my %immutable_options = $meta->immutable_options;
2757         $meta->make_mutable if $was_immutable;
2758
2759         $meta->add_method(handler => sub {
2760             my $r = shift;
2761             my $psgi_app = $class->_finalized_psgi_app;
2762             $apache->call_app($r, $psgi_app);
2763         });
2764
2765         $meta->make_immutable(%immutable_options) if $was_immutable;
2766     }
2767
2768     $class->engine( $engine->new );
2769
2770     return;
2771 }
2772
2773 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2774 ## build in server support (back compat support for pre psgi port behavior).
2775 ## This is so that we don't build a new psgi app for each request when using
2776 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2777
2778 sub _finalized_psgi_app {
2779     my ($app) = @_;
2780
2781     unless ($app->_psgi_app) {
2782         my $psgi_app = $app->_setup_psgi_app;
2783         $app->_psgi_app($psgi_app);
2784     }
2785
2786     return $app->_psgi_app;
2787 }
2788
2789 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2790 ## home directory and load that and return it (just assume it is doing the
2791 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2792 ## in default_middleware and return it ( this is for backward compatibility
2793 ## with pre psgi port behavior ).
2794
2795 sub _setup_psgi_app {
2796     my ($app) = @_;
2797
2798     for my $home (Path::Class::Dir->new($app->config->{home})) {
2799         my $psgi_file = $home->file(
2800             Catalyst::Utils::appprefix($app) . '.psgi',
2801         );
2802
2803         next unless -e $psgi_file;
2804
2805         # If $psgi_file calls ->setup_engine, it's doing so to load
2806         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2807         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2808         # anyway. So set a flag (ick) that tells setup_engine not to populate
2809         # $c->engine or do any other things we might regret.
2810
2811         $app->loading_psgi_file(1);
2812         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2813         $app->loading_psgi_file(0);
2814
2815         return $psgi_app
2816             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2817
2818         warn <<"EOW";
2819 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2820
2821 Its content has been ignored. Please consult the Catalyst::Upgrading
2822 documentation on how to upgrade from Catalyst::Engine::PSGI.
2823 EOW
2824     }
2825
2826     return $app->apply_default_middlewares($app->psgi_app);
2827 }
2828
2829 =head2 $c->apply_default_middlewares
2830
2831 Adds the following L<Plack> middlewares to your application, since they are
2832 useful and commonly needed:
2833
2834 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2835 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2836 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2837 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2838 applied since this middleware is smart enough to conditionally apply itself).
2839
2840 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2841 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2842 $ENV{SCRIPT_NAME}
2843
2844 =cut
2845
2846
2847 sub apply_default_middlewares {
2848     my ($app, $psgi_app) = @_;
2849
2850     $psgi_app = Plack::Middleware::Conditional->wrap(
2851         $psgi_app,
2852         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2853         condition => sub {
2854             my ($env) = @_;
2855             return if $app->config->{ignore_frontend_proxy};
2856             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2857                 || $app->config->{using_frontend_proxy};
2858         },
2859     );
2860
2861     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2862     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2863     $psgi_app = Plack::Middleware::Conditional->wrap(
2864         $psgi_app,
2865         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2866         condition => sub {
2867             my ($env) = @_;
2868             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2869             return unless $1 < 4.23;
2870             1;
2871         },
2872     );
2873
2874     # we're applying this unconditionally as the middleware itself already makes
2875     # sure it doesn't fuck things up if it's not running under one of the right
2876     # IIS versions
2877     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2878
2879     # And another IIS issue, this time with IIS7.
2880     $psgi_app = Plack::Middleware::Conditional->wrap(
2881         $psgi_app,
2882         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2883         condition => sub {
2884             my ($env) = @_;
2885             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2886         },
2887     );
2888
2889     return $psgi_app;
2890 }
2891
2892 =head2 $c->psgi_app
2893
2894 Returns a PSGI application code reference for the catalyst application
2895 C<$c>. This is the bare application without any middlewares
2896 applied. C<${myapp}.psgi> is not taken into account.
2897
2898 This is what you want to be using to retrieve the PSGI application code
2899 reference of your Catalyst application for use in F<.psgi> files.
2900
2901 =cut
2902
2903 sub psgi_app {
2904     my ($app) = @_;
2905     my $psgi = $app->engine->build_psgi_app($app);
2906     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
2907 }
2908
2909 =head2 $c->setup_home
2910
2911 Sets up the home directory.
2912
2913 =cut
2914
2915 sub setup_home {
2916     my ( $class, $home ) = @_;
2917
2918     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2919         $home = $env;
2920     }
2921
2922     $home ||= Catalyst::Utils::home($class);
2923
2924     if ($home) {
2925         #I remember recently being scolded for assigning config values like this
2926         $class->config->{home} ||= $home;
2927         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2928     }
2929 }
2930
2931 =head2 $c->setup_log
2932
2933 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2934 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2935 log to.
2936
2937 This method also installs a C<debug> method that returns a true value into the
2938 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2939 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2940
2941 Note that if the log has already been setup, by either a previous call to
2942 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2943 that this method won't actually set up the log object.
2944
2945 =cut
2946
2947 sub setup_log {
2948     my ( $class, $levels ) = @_;
2949
2950     $levels ||= '';
2951     $levels =~ s/^\s+//;
2952     $levels =~ s/\s+$//;
2953     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2954
2955     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2956     if ( defined $env_debug ) {
2957         $levels{debug} = 1 if $env_debug; # Ugly!
2958         delete($levels{debug}) unless $env_debug;
2959     }
2960
2961     unless ( $class->log ) {
2962         $class->log( Catalyst::Log->new(keys %levels) );
2963     }
2964
2965     if ( $levels{debug} ) {
2966         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2967         $class->log->debug('Debug messages enabled');
2968     }
2969 }
2970
2971 =head2 $c->setup_plugins
2972
2973 Sets up plugins.
2974
2975 =cut
2976
2977 =head2 $c->setup_stats
2978
2979 Sets up timing statistics class.
2980
2981 =cut
2982
2983 sub setup_stats {
2984     my ( $class, $stats ) = @_;
2985
2986     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2987
2988     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2989     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2990         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2991         $class->log->debug('Statistics enabled');
2992     }
2993 }
2994
2995
2996 =head2 $c->registered_plugins
2997
2998 Returns a sorted list of the plugins which have either been stated in the
2999 import list.
3000
3001 If passed a given plugin name, it will report a boolean value indicating
3002 whether or not that plugin is loaded.  A fully qualified name is required if
3003 the plugin name does not begin with C<Catalyst::Plugin::>.
3004
3005  if ($c->registered_plugins('Some::Plugin')) {
3006      ...
3007  }
3008
3009 =cut
3010
3011 {
3012
3013     sub registered_plugins {
3014         my $proto = shift;
3015         return sort keys %{ $proto->_plugins } unless @_;
3016         my $plugin = shift;
3017         return 1 if exists $proto->_plugins->{$plugin};
3018         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3019     }
3020
3021     sub _register_plugin {
3022         my ( $proto, $plugin, $instant ) = @_;
3023         my $class = ref $proto || $proto;
3024
3025         load_class( $plugin );
3026         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3027             if $plugin->isa( 'Catalyst::Component' );
3028         my $plugin_meta = Moose::Meta::Class->create($plugin);
3029         if (!$plugin_meta->has_method('new')
3030             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3031             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3032         }
3033         if (!$instant && !$proto->_plugins->{$plugin}) {
3034             my $meta = Class::MOP::get_metaclass_by_name($class);
3035             $meta->superclasses($plugin, $meta->superclasses);
3036         }
3037         $proto->_plugins->{$plugin} = 1;
3038         return $class;
3039     }
3040
3041     sub _default_plugins { return qw(Unicode::Encoding) }
3042
3043     sub setup_plugins {
3044         my ( $class, $plugins ) = @_;
3045
3046         $class->_plugins( {} ) unless $class->_plugins;
3047         $plugins = [ grep {
3048             m/Unicode::Encoding/ ? do {
3049                 $class->log->warn(
3050                     'Unicode::Encoding plugin is auto-applied,'
3051                     . ' please remove this from your appclass'
3052                     . ' and make sure to define "encoding" config'
3053                 );
3054                 unless (exists $class->config->{'encoding'}) {
3055                   $class->config->{'encoding'} = 'UTF-8';
3056                 }
3057                 () }
3058                 : $_
3059         } @$plugins ];
3060         push @$plugins, $class->_default_plugins;
3061         $plugins = Data::OptList::mkopt($plugins || []);
3062
3063         my @plugins = map {
3064             [ Catalyst::Utils::resolve_namespace(
3065                   $class . '::Plugin',
3066                   'Catalyst::Plugin', $_->[0]
3067               ),
3068               $_->[1],
3069             ]
3070          } @{ $plugins };
3071
3072         for my $plugin ( reverse @plugins ) {
3073             load_class($plugin->[0], $plugin->[1]);
3074             my $meta = find_meta($plugin->[0]);
3075             next if $meta && $meta->isa('Moose::Meta::Role');
3076
3077             $class->_register_plugin($plugin->[0]);
3078         }
3079
3080         my @roles =
3081             map  { $_->[0]->name, $_->[1] }
3082             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3083             map  { [find_meta($_->[0]), $_->[1]] }
3084             @plugins;
3085
3086         Moose::Util::apply_all_roles(
3087             $class => @roles
3088         ) if @roles;
3089     }
3090 }
3091
3092 =head2 registered_middlewares
3093
3094 Read only accessor that returns an array of all the middleware in the order
3095 that they were added (which is the REVERSE of the order they will be applied).
3096
3097 The values returned will be either instances of L<Plack::Middleware> or of a
3098 compatible interface, or a coderef, which is assumed to be inlined middleware
3099
3100 =head2 setup_middleware (?@middleware)
3101
3102 Read configuration information stored in configuration key C<psgi_middleware> or
3103 from passed @args.
3104
3105 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3106 to use it to enable L<Plack::Middleware>
3107
3108 This method is automatically called during 'setup' of your application, so
3109 you really don't need to invoke it.  However you may do so if you find the idea
3110 of loading middleware via configuration weird :).  For example:
3111
3112     package MyApp;
3113
3114     use Catalyst;
3115
3116     __PACKAGE__->setup_middleware('Head');
3117     __PACKAGE__->setup;
3118
3119 When we read middleware definitions from configuration, we reverse the list
3120 which sounds odd but is likely how you expect it to work if you have prior
3121 experience with L<Plack::Builder> or if you previously used the plugin
3122 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3123
3124 =cut
3125
3126 sub registered_middlewares {
3127     my $class = shift;
3128     if(my $middleware = $class->_psgi_middleware) {
3129         return (
3130           Plack::Middleware::HTTPExceptions->new,
3131           Plack::Middleware::ContentLength->new,
3132           Plack::Middleware::Head->new,
3133           @$middleware);
3134     } else {
3135         die "You cannot call ->registered_middlewares until middleware has been setup";
3136     }
3137 }
3138
3139 sub setup_middleware {
3140     my $class = shift;
3141     my @middleware_definitions = @_ ?
3142       @_ : reverse(@{$class->config->{'psgi_middleware'}||[]});
3143
3144     my @middleware = ();
3145     while(my $next = shift(@middleware_definitions)) {
3146         if(ref $next) {
3147             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3148                 push @middleware, $next;
3149             } elsif(ref $next eq 'CODE') {
3150                 push @middleware, $next;
3151             } elsif(ref $next eq 'HASH') {
3152                 my $namespace = shift @middleware_definitions;
3153                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3154                 push @middleware, $mw;
3155             } else {
3156               die "I can't handle middleware definition ${\ref $next}";
3157             }
3158         } else {
3159           my $mw = $class->Catalyst::Utils::build_middleware($next);
3160           push @middleware, $mw;
3161         }
3162     }
3163
3164     my @existing = @{$class->_psgi_middleware || []};
3165     $class->_psgi_middleware([@middleware,@existing,]);
3166 }
3167
3168 =head2 registered_data_handlers
3169
3170 A read only copy of registered Data Handlers returned as a Hash, where each key
3171 is a content type and each value is a subref that attempts to decode that content
3172 type.
3173
3174 =head2 setup_data_handlers (?@data_handler)
3175
3176 Read configuration information stored in configuration key C<data_handlers> or
3177 from passed @args.
3178
3179 See under L</CONFIGURATION> information regarding C<data_handlers>.
3180
3181 This method is automatically called during 'setup' of your application, so
3182 you really don't need to invoke it.
3183
3184 =head2 default_data_handlers
3185
3186 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3187 only two default data handlers, for 'application/json' and an alternative to
3188 'application/x-www-form-urlencoded' which supposed nested form parameters via
3189 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3190
3191 The 'application/json' data handler is used to parse incoming JSON into a Perl
3192 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3193 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3194 JSON decoder, and has the smallest dependency impact.
3195
3196 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3197 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3198 order to get the best performance.  You should add either to your dependency
3199 list (Makefile.PL, dist.ini, cpanfile, etc.)
3200
3201 =cut
3202
3203 sub registered_data_handlers {
3204     my $class = shift;
3205     if(my $data_handlers = $class->_data_handlers) {
3206         return %$data_handlers;
3207     } else {
3208         die "You cannot call ->registered_data_handlers until data_handers has been setup";
3209     }
3210 }
3211
3212 sub setup_data_handlers {
3213     my ($class, %data_handler_callbacks) = @_;
3214     %data_handler_callbacks = (
3215       %{$class->default_data_handlers},
3216       %{$class->config->{'data_handlers'}||+{}},
3217       %data_handler_callbacks);
3218
3219     $class->_data_handlers(\%data_handler_callbacks);
3220 }
3221
3222 sub default_data_handlers {
3223     my ($class) = @_;
3224     return +{
3225       'application/x-www-form-urlencoded' => sub {
3226           my ($fh, $req) = @_;
3227           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3228           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3229             ->can('build_cgi_struct')->($params);
3230       },
3231       'application/json' => sub {
3232           Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON')
3233             ->can('decode_json')->(do { local $/; $_->getline });
3234       },
3235     };
3236 }
3237
3238 =head2 $c->stack
3239
3240 Returns an arrayref of the internal execution stack (actions that are
3241 currently executing).
3242
3243 =head2 $c->stats
3244
3245 Returns the current timing statistics object. By default Catalyst uses
3246 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3247 L<< stats_class|/"$c->stats_class" >>.
3248
3249 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3250 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3251 profile explicitly, although MyApp.pm still won't profile nor output anything
3252 by itself.
3253
3254 =head2 $c->stats_class
3255
3256 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3257
3258 =head2 $c->use_stats
3259
3260 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3261
3262 Note that this is a static method, not an accessor and should be overridden
3263 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3264
3265 =cut
3266
3267 sub use_stats { 0 }
3268
3269
3270 =head2 $c->write( $data )
3271
3272 Writes $data to the output stream. When using this method directly, you
3273 will need to manually set the C<Content-Length> header to the length of
3274 your output data, if known.
3275
3276 =cut
3277
3278 sub write {
3279     my $c = shift;
3280
3281     # Finalize headers if someone manually writes output (for compat)
3282     $c->finalize_headers;
3283
3284     return $c->response->write( @_ );
3285 }
3286
3287 =head2 version
3288
3289 Returns the Catalyst version number. Mostly useful for "powered by"
3290 messages in template systems.
3291
3292 =cut
3293
3294 sub version { return $Catalyst::VERSION }
3295
3296 =head1 CONFIGURATION
3297
3298 There are a number of 'base' config variables which can be set:
3299
3300 =over
3301
3302 =item *
3303
3304 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3305
3306 =item *
3307
3308 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3309
3310 =item *
3311
3312 C<disable_component_resolution_regex_fallback> - Turns
3313 off the deprecated component resolution functionality so
3314 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3315 are called then regex search will not be attempted on string values and
3316 instead C<undef> will be returned.
3317
3318 =item *
3319
3320 C<home> - The application home directory. In an uninstalled application,
3321 this is the top level application directory. In an installed application,
3322 this will be the directory containing C<< MyApp.pm >>.
3323
3324 =item *
3325
3326 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3327
3328 =item *
3329
3330 C<name> - The name of the application in debug messages and the debug and
3331 welcome screens
3332
3333 =item *
3334
3335 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3336 until it is accessed. This allows you to (for example) check authentication (and reject
3337 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3338
3339 =item *
3340
3341 C<root> - The root directory for templates. Usually this is just a
3342 subdirectory of the home directory, but you can set it to change the
3343 templates to a different directory.
3344
3345 =item *
3346
3347 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3348 namespaces from which components will be loaded (and constructed and stored in
3349 C<< $c->components >>).
3350
3351 =item *
3352
3353 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3354 to be shown in hit debug tables in the test server.
3355
3356 =item *
3357
3358 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3359 variable should be used for determining the request path.
3360
3361 Most web server environments pass the requested path to the application using environment variables,
3362 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3363 exposed as C<< $c->request->base >>) and the request path below that base.
3364
3365 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3366 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3367
3368 =over
3369
3370 =item use_request_uri_for_path => 0
3371
3372 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3373 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3374 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3375 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3376
3377 However this method has the major disadvantage that it is impossible to correctly decode some elements
3378 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3379 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3380 can't distinguish / vs %2F in paths (in addition to other encoded values).
3381
3382 =item use_request_uri_for_path => 1
3383
3384 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3385 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3386 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3387
3388 Given that this method of path resolution is provably more correct, it is recommended that you use
3389 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3390 aware of the implications of not being able to handle encoded URI paths correctly.
3391
3392 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3393 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3394 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3395 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3396 C<< $c->request->base >> will be incorrect.
3397
3398 =back
3399
3400 =item *
3401
3402 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3403
3404 =item *
3405
3406 C<encoding> - See L</ENCODING>
3407
3408 =item *
3409
3410 C<abort_chain_on_error_fix>
3411
3412 When there is an error in an action chain, the default behavior is to continue
3413 processing the remaining actions and then catch the error upon chain end.  This
3414 can lead to running actions when the application is in an unexpected state.  If
3415 you have this issue, setting this config value to true will promptly exit a
3416 chain when there is an error raised in any action (thus terminating the chain
3417 early.)
3418
3419 use like:
3420
3421     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3422
3423 In the future this might become the default behavior.
3424
3425 =item *
3426
3427 C<use_hash_multivalue_in_request>
3428
3429 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3430 and C<parameters> return a hashref where values might be scalar or an arrayref
3431 depending on the incoming data.  In many cases this can be undesirable as it
3432 leads one to writing defensive code like the following:
3433
3434     my ($val) = ref($c->req->parameters->{a}) ?
3435       @{$c->req->parameters->{a}} :
3436         $c->req->parameters->{a};
3437
3438 Setting this configuration item to true will make L<Catalyst> populate the
3439 attributes underlying these methods with an instance of L<Hash::MultiValue>
3440 which is used by L<Plack::Request> and others to solve this very issue.  You
3441 may prefer this behavior to the default, if so enable this option (be warned
3442 if you enable it in a legacy application we are not sure if it is completely
3443 backwardly compatible).
3444
3445 =item *
3446
3447 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3448
3449 =item *
3450
3451 C<data_handlers> - See L<DATA HANDLERS>.
3452
3453 =back
3454
3455 =head1 INTERNAL ACTIONS
3456
3457 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3458 C<_ACTION>, and C<_END>. These are by default not shown in the private
3459 action table, but you can make them visible with a config parameter.
3460
3461     MyApp->config(show_internal_actions => 1);
3462
3463 =head1 ON-DEMAND PARSER
3464
3465 The request body is usually parsed at the beginning of a request,
3466 but if you want to handle input yourself, you can enable on-demand
3467 parsing with a config parameter.
3468
3469     MyApp->config(parse_on_demand => 1);
3470
3471 =head1 PROXY SUPPORT
3472
3473 Many production servers operate using the common double-server approach,
3474 with a lightweight frontend web server passing requests to a larger
3475 backend server. An application running on the backend server must deal
3476 with two problems: the remote user always appears to be C<127.0.0.1> and
3477 the server's hostname will appear to be C<localhost> regardless of the
3478 virtual host that the user connected through.
3479
3480 Catalyst will automatically detect this situation when you are running
3481 the frontend and backend servers on the same machine. The following
3482 changes are made to the request.
3483
3484     $c->req->address is set to the user's real IP address, as read from
3485     the HTTP X-Forwarded-For header.
3486
3487     The host value for $c->req->base and $c->req->uri is set to the real
3488     host, as read from the HTTP X-Forwarded-Host header.
3489
3490 Additionally, you may be running your backend application on an insecure
3491 connection (port 80) while your frontend proxy is running under SSL.  If there
3492 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3493 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3494 be created properly.
3495
3496 In the case of passing in:
3497
3498     X-Forwarded-Port: 443
3499
3500 All calls to C<uri_for> will result in an https link, as is expected.
3501
3502 Obviously, your web server must support these headers for this to work.
3503
3504 In a more complex server farm environment where you may have your
3505 frontend proxy server(s) on different machines, you will need to set a
3506 configuration option to tell Catalyst to read the proxied data from the
3507 headers.
3508
3509     MyApp->config(using_frontend_proxy => 1);
3510
3511 If you do not wish to use the proxy support at all, you may set:
3512
3513     MyApp->config(ignore_frontend_proxy => 0);
3514
3515 =head2 Note about psgi files
3516
3517 Note that if you supply your own .psgi file, calling
3518 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3519
3520 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3521 in your psgi, for example:
3522
3523     builder {
3524         enable "Plack::Middleware::ReverseProxy";
3525         MyApp->psgi_app
3526     };
3527
3528 This will unconditionally add the ReverseProxy support, or you need to call
3529 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3530 apply the support depending upon your config).
3531
3532 See L<Catalyst::PSGI> for more information.
3533
3534 =head1 THREAD SAFETY
3535
3536 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3537 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3538 believe the Catalyst core to be thread-safe.
3539
3540 If you plan to operate in a threaded environment, remember that all other
3541 modules you are using must also be thread-safe. Some modules, most notably
3542 L<DBD::SQLite>, are not thread-safe.
3543
3544 =head1 DATA HANDLERS
3545
3546 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3547 form parameters and URL search query fields.  However it has become common
3548 for various alternative content types to be PUT or POSTed to your controllers
3549 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3550 XML and other content types when communicating with an application server.  In
3551 order to better support this use case, L<Catalyst> defines a global configuration
3552 option, C<data_handlers>, which lets you associate a content type with a coderef
3553 that parses that content type into something Perl can readily access.
3554
3555     package MyApp::Web;
3556
3557     use Catalyst;
3558     use JSON::Maybe;
3559
3560     __PACKAGE__->config(
3561       data_handlers => {
3562         'application/json' => sub { local $/; decode_json $_->getline },
3563       },
3564       ## Any other configuration.
3565     );
3566
3567     __PACKAGE__->setup;
3568
3569 By default L<Catalyst> comes with a generic JSON data handler similar to the
3570 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
3571 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
3572 it installed (if you want the faster XS parser, add it to you project Makefile.PL
3573 or dist.ini, cpanfile, etc.)
3574
3575 The C<data_handlers> configuation is a hashref whose keys are HTTP Content-Types
3576 (matched against the incoming request type using a regexp such as to be case
3577 insensitive) and whose values are coderefs that receive a localized version of
3578 C<$_> which is a filehandle object pointing to received body.
3579
3580 This feature is considered an early access release and we reserve the right
3581 to alter the interface in order to provide a performant and secure solution to
3582 alternative request body content.  Your reports welcomed!
3583
3584 =head1 PSGI MIDDLEWARE
3585
3586 You can define middleware, defined as L<Plack::Middleware> or a compatible
3587 interface in configuration.  Your middleware definitions are in the form of an
3588 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3589 with details to follow:
3590
3591     package MyApp::Web;
3592
3593     use Catalyst;
3594     use Plack::Middleware::StackTrace;
3595
3596     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3597
3598     __PACKAGE__->config(
3599       'psgi_middleware', [
3600         'Debug',
3601         '+MyApp::Custom',
3602         $stacktrace_middleware,
3603         'Session' => {store => 'File'},
3604         sub {
3605           my $app = shift;
3606           return sub {
3607             my $env = shift;
3608             $env->{myapp.customkey} = 'helloworld';
3609             $app->($env);
3610           },
3611         },
3612       ],
3613     );
3614
3615     __PACKAGE__->setup;
3616
3617 So the general form is:
3618
3619     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3620
3621 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3622 the order listed (to make it function similarly to L<Plack::Builder>:
3623
3624 Alternatively, you may also define middleware by calling the L</setup_middleware>
3625 package method:
3626
3627     package MyApp::Web;
3628
3629     use Catalyst;
3630
3631     __PACKAGE__->setup_middleware( \@middleware_definitions);
3632     __PACKAGE__->setup;
3633
3634 In the case where you do both (use 'setup_middleware' and configuration) the
3635 package call to setup_middleware will be applied earlier (in other words its
3636 middleware will wrap closer to the application).  Keep this in mind since in
3637 some cases the order of middleware is important.
3638
3639 The two approaches are not exclusive.
3640
3641 =over 4
3642
3643 =item Middleware Object
3644
3645 An already initialized object that conforms to the L<Plack::Middleware>
3646 specification:
3647
3648     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3649
3650     __PACKAGE__->config(
3651       'psgi_middleware', [
3652         $stacktrace_middleware,
3653       ]);
3654
3655
3656 =item coderef
3657
3658 A coderef that is an inlined middleware:
3659
3660     __PACKAGE__->config(
3661       'psgi_middleware', [
3662         sub {
3663           my $app = shift;
3664           return sub {
3665             my $env = shift;
3666             if($env->{PATH_INFO} =~m/forced/) {
3667               Plack::App::File
3668                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3669                 ->call($env);
3670             } else {
3671               return $app->($env);
3672             }
3673          },
3674       },
3675     ]);
3676
3677
3678
3679 =item a scalar
3680
3681 We assume the scalar refers to a namespace after normalizing it using the
3682 following rules:
3683
3684 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3685 is assumed to be 'as is', and we just install and use the middleware.
3686
3687 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3688 (the package name of your Catalyst application subclass), we also assume then
3689 that it is a full namespace, and use it.
3690
3691 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3692 resolve it first by looking for it under your application namespace (for example
3693 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3694 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3695 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3696 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3697 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3698 you find that a good idea.
3699
3700 Examples:
3701
3702     package MyApp::Web;
3703
3704     __PACKAGE__->config(
3705       'psgi_middleware', [
3706         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3707         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3708         '+MyApp::Custom',  ## MyApp::Custom->wrap
3709       ],
3710     );
3711
3712 =item a scalar followed by a hashref
3713
3714 Just like the previous, except the following C<HashRef> is used as arguments
3715 to initialize the middleware object.
3716
3717     __PACKAGE__->config(
3718       'psgi_middleware', [
3719          'Session' => {store => 'File'},
3720     ]);
3721
3722 =back
3723
3724 Please see L<PSGI> for more on middleware.
3725
3726 =head1 ENCODING
3727
3728 On request, decodes all params from encoding into a sequence of
3729 logical characters. On response, encodes body into encoding.
3730
3731 =head2 Methods
3732
3733 =over 4
3734
3735 =item encoding
3736
3737 Returns an instance of an C<Encode> encoding
3738
3739     print $c->encoding->name
3740
3741 =item handle_unicode_encoding_exception ($exception_context)
3742
3743 Method called when decoding process for a request fails.
3744
3745 An C<$exception_context> hashref is provided to allow you to override the
3746 behaviour of your application when given data with incorrect encodings.
3747
3748 The default method throws exceptions in the case of invalid request parameters
3749 (resulting in a 500 error), but ignores errors in upload filenames.
3750
3751 The keys passed in the C<$exception_context> hash are:
3752
3753 =over
3754
3755 =item param_value
3756
3757 The value which was not able to be decoded.
3758
3759 =item error_msg
3760
3761 The exception received from L<Encode>.
3762
3763 =item encoding_step
3764
3765 What type of data was being decoded. Valid values are (currently)
3766 C<params> - for request parameters / arguments / captures
3767 and C<uploads> - for request upload filenames.
3768
3769 =back
3770
3771 =back
3772
3773 =head1 SUPPORT
3774
3775 IRC:
3776
3777     Join #catalyst on irc.perl.org.
3778
3779 Mailing Lists:
3780
3781     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3782     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3783
3784 Web:
3785
3786     http://catalyst.perl.org
3787
3788 Wiki:
3789
3790     http://dev.catalyst.perl.org
3791
3792 =head1 SEE ALSO
3793
3794 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3795
3796 =head2 L<Catalyst::Manual> - The Catalyst Manual
3797
3798 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3799
3800 =head2 L<Catalyst::Engine> - Core engine
3801
3802 =head2 L<Catalyst::Log> - Log class.
3803
3804 =head2 L<Catalyst::Request> - Request object
3805
3806 =head2 L<Catalyst::Response> - Response object
3807
3808 =head2 L<Catalyst::Test> - The test suite.
3809
3810 =head1 PROJECT FOUNDER
3811
3812 sri: Sebastian Riedel <sri@cpan.org>
3813
3814 =head1 CONTRIBUTORS
3815
3816 abw: Andy Wardley
3817
3818 acme: Leon Brocard <leon@astray.com>
3819
3820 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3821
3822 Andrew Bramble
3823
3824 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3825
3826 Andrew Ruthven
3827
3828 andyg: Andy Grundman <andy@hybridized.org>
3829
3830 audreyt: Audrey Tang
3831
3832 bricas: Brian Cassidy <bricas@cpan.org>
3833
3834 Caelum: Rafael Kitover <rkitover@io.com>
3835
3836 chansen: Christian Hansen
3837
3838 chicks: Christopher Hicks
3839
3840 Chisel Wright C<pause@herlpacker.co.uk>
3841
3842 Danijel Milicevic C<me@danijel.de>
3843
3844 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3845
3846 David Naughton, C<naughton@umn.edu>
3847
3848 David E. Wheeler
3849
3850 dhoss: Devin Austin <dhoss@cpan.org>
3851
3852 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3853
3854 Drew Taylor
3855
3856 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3857
3858 esskar: Sascha Kiefer
3859
3860 fireartist: Carl Franks <cfranks@cpan.org>
3861
3862 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3863
3864 gabb: Danijel Milicevic
3865
3866 Gary Ashton Jones
3867
3868 Gavin Henry C<ghenry@perl.me.uk>
3869
3870 Geoff Richards
3871
3872 groditi: Guillermo Roditi <groditi@gmail.com>
3873
3874 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3875
3876 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3877
3878 jcamacho: Juan Camacho
3879
3880 jester: Jesse Sheidlower C<jester@panix.com>
3881
3882 jhannah: Jay Hannah <jay@jays.net>
3883
3884 Jody Belka
3885
3886 Johan Lindstrom
3887
3888 jon: Jon Schutz <jjschutz@cpan.org>
3889
3890 Jonathan Rockway C<< <jrockway@cpan.org> >>
3891
3892 Kieren Diment C<kd@totaldatasolution.com>
3893
3894 konobi: Scott McWhirter <konobi@cpan.org>
3895
3896 marcus: Marcus Ramberg <mramberg@cpan.org>
3897
3898 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3899
3900 mgrimes: Mark Grimes <mgrimes@cpan.org>
3901
3902 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3903
3904 mugwump: Sam Vilain
3905
3906 naughton: David Naughton
3907
3908 ningu: David Kamholz <dkamholz@cpan.org>
3909
3910 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3911
3912 numa: Dan Sully <daniel@cpan.org>
3913
3914 obra: Jesse Vincent
3915
3916 Octavian Rasnita
3917
3918 omega: Andreas Marienborg
3919
3920 Oleg Kostyuk <cub.uanic@gmail.com>
3921
3922 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3923
3924 rafl: Florian Ragwitz <rafl@debian.org>
3925
3926 random: Roland Lammel <lammel@cpan.org>
3927
3928 Robert Sedlacek C<< <rs@474.at> >>
3929
3930 SpiceMan: Marcel Montes
3931
3932 sky: Arthur Bergman
3933
3934 szbalint: Balint Szilakszi <szbalint@cpan.org>
3935
3936 t0m: Tomas Doran <bobtfish@bobtfish.net>
3937
3938 Ulf Edvinsson
3939
3940 Viljo Marrandi C<vilts@yahoo.com>
3941
3942 Will Hawes C<info@whawes.co.uk>
3943
3944 willert: Sebastian Willert <willert@cpan.org>
3945
3946 wreis: Wallace Reis <wreis@cpan.org>
3947
3948 Yuval Kogman, C<nothingmuch@woobling.org>
3949
3950 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3951
3952 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3953
3954 =head1 COPYRIGHT
3955
3956 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3957
3958 =head1 LICENSE
3959
3960 This library is free software. You can redistribute it and/or modify it under
3961 the same terms as Perl itself.
3962
3963 =cut
3964
3965 no Moose;
3966
3967 __PACKAGE__->meta->make_immutable;
3968
3969 1;