lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use Scalar::Util qw/weaken blessed/;
  23 use Tree::Simple qw/use_weak_refs/;
  24 use Tree::Simple::Visitor::FindByUID;
  25 use attributes;
  26 use utf8;
  27 use Carp qw/croak/;
  28
  29 BEGIN { require 5.008001; }
  30
  31 __PACKAGE__->mk_accessors(
  32     qw/counter request response state action stack namespace stats/
  33 );
  34
  35 attributes->import( __PACKAGE__, \&namespace, 'lvalue' );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class setup_finished/;
  56
  57 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  58 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  59 __PACKAGE__->request_class('Catalyst::Request');
  60 __PACKAGE__->response_class('Catalyst::Response');
  61
  62 # Remember to update this in Catalyst::Runtime as well!
  63
  64 our $VERSION = '5.7003';
  65
  66 sub import {
  67     my ( $class, @arguments ) = @_;
  68
  69     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  70     # callers @ISA.
  71     return unless $class eq 'Catalyst';
  72
  73     my $caller = caller(0);
  74
  75     unless ( $caller->isa('Catalyst') ) {
  76         no strict 'refs';
  77         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  78     }
  79
  80     $caller->arguments( [@arguments] );
  81     $caller->setup_home;
  82 }
  83
  84 =head1 NAME
  85
  86 Catalyst - The Elegant MVC Web Application Framework
  87
  88 =head1 SYNOPSIS
  89
  90     # Install Catalyst::Devel for helpers and other development tools
  91     # use the helper to create a new application
  92     catalyst.pl MyApp
  93
  94     # add models, views, controllers
  95     script/myapp_create.pl model Database DBIC::SchemaLoader dbi:SQLite:/path/to/db
  96     script/myapp_create.pl view TT TT
  97     script/myapp_create.pl controller Search
  98
  99     # built in testserver -- use -r to restart automatically on changes
 100     script/myapp_server.pl
 101
 102     # command line testing interface
 103     script/myapp_test.pl /yada
 104
 105     ### in lib/MyApp.pm
 106     use Catalyst qw/-Debug/; # include plugins here as well
 107
 108         ### In lib/MyApp/Controller/Root.pm (autocreated)
 109     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 110         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 111         $c->stash->{template} = 'foo.tt'; # set the template
 112         # lookup something from db -- stash vars are passed to TT
 113         $c->stash->{data} =
 114           $c->model('Database::Foo')->search( { country => $args[0] } );
 115         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 116             $c->forward( 'bar' ); # process another action
 117             # do something else after forward returns
 118         }
 119     }
 120
 121     # The foo.tt TT template can use the stash data from the database
 122     [% WHILE (item = data.next) %]
 123         [% item.foo %]
 124     [% END %]
 125
 126     # called for /bar/of/soap, /bar/of/soap/10, etc.
 127     sub bar : Path('/bar/of/soap') { ... }
 128
 129     # called for all actions, from the top-most controller downwards
 130     sub auto : Private {
 131         my ( $self, $c ) = @_;
 132         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 133             $c->res->redirect( '/login' ); # require login
 134             return 0; # abort request and go immediately to end()
 135         }
 136         return 1; # success; carry on to next action
 137     }
 138
 139     # called after all actions are finished
 140     sub end : Private {
 141         my ( $self, $c ) = @_;
 142         if ( scalar @{ $c->error } ) { ... } # handle errors
 143         return if $c->res->body; # already have a response
 144         $c->forward( 'MyApp::View::TT' ); # render template
 145     }
 146
 147     ### in MyApp/Controller/Foo.pm
 148     # called for /foo/bar
 149     sub bar : Local { ... }
 150
 151     # called for /blargle
 152     sub blargle : Global { ... }
 153
 154     # an index action matches /foo, but not /foo/1, etc.
 155     sub index : Private { ... }
 156
 157     ### in MyApp/Controller/Foo/Bar.pm
 158     # called for /foo/bar/baz
 159     sub baz : Local { ... }
 160
 161     # first Root auto is called, then Foo auto, then this
 162     sub auto : Private { ... }
 163
 164     # powerful regular expression paths are also possible
 165     sub details : Regex('^product/(\w+)/details$') {
 166         my ( $self, $c ) = @_;
 167         # extract the (\w+) from the URI
 168         my $product = $c->req->captures->[0];
 169     }
 170
 171 See L<Catalyst::Manual::Intro> for additional information.
 172
 173 =head1 DESCRIPTION
 174
 175 Catalyst is a modern framework for making web applications without the
 176 pain usually associated with this process. This document is a reference
 177 to the main Catalyst application. If you are a new user, we suggest you
 178 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 179
 180 See L<Catalyst::Manual> for more documentation.
 181
 182 Catalyst plugins can be loaded by naming them as arguments to the "use
 183 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 184 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 185 C<My::Module>.
 186
 187     use Catalyst qw/My::Module/;
 188
 189 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 190 fully qualify the name by using a unary plus:
 191
 192     use Catalyst qw/
 193         My::Module
 194         +Fully::Qualified::Plugin::Name
 195     /;
 196
 197 Special flags like C<-Debug> and C<-Engine> can also be specified as
 198 arguments when Catalyst is loaded:
 199
 200     use Catalyst qw/-Debug My::Module/;
 201
 202 The position of plugins and flags in the chain is important, because
 203 they are loaded in the order in which they appear.
 204
 205 The following flags are supported:
 206
 207 =head2 -Debug
 208
 209 Enables debug output. You can also force this setting from the system
 210 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 211 settings override the application, with <MYAPP>_DEBUG having the highest
 212 priority.
 213
 214 =head2 -Engine
 215
 216 Forces Catalyst to use a specific engine. Omit the
 217 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 218
 219     use Catalyst qw/-Engine=CGI/;
 220
 221 =head2 -Home
 222
 223 Forces Catalyst to use a specific home directory, e.g.:
 224
 225     use Catalyst qw[-Home=/usr/mst];
 226
 227 =head2 -Log
 228
 229 Specifies log level.
 230
 231 =head1 METHODS
 232
 233 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 234
 235 =head2 $c->action
 236
 237 Returns a L<Catalyst::Action> object for the current action, which
 238 stringifies to the action name. See L<Catalyst::Action>.
 239
 240 =head2 $c->namespace
 241
 242 Returns the namespace of the current action, i.e., the URI prefix
 243 corresponding to the controller of the current action. For example:
 244
 245     # in Controller::Foo::Bar
 246     $c->namespace; # returns 'foo/bar';
 247
 248 =head2 $c->request
 249
 250 =head2 $c->req
 251
 252 Returns the current L<Catalyst::Request> object, giving access to
 253 information about the current client request (including parameters,
 254 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 255
 256 =head2 REQUEST FLOW HANDLING
 257
 258 =head2 $c->forward( $action [, \@arguments ] )
 259
 260 =head2 $c->forward( $class, $method, [, \@arguments ] )
 261
 262 Forwards processing to another action, by its private name. If you give a
 263 class name but no method, C<process()> is called. You may also optionally
 264 pass arguments in an arrayref. The action will receive the arguments in
 265 C<@_> and C<$c-E<gt>req-E<gt>args>. Upon returning from the function,
 266 C<$c-E<gt>req-E<gt>args> will be restored to the previous values.
 267
 268 Any data C<return>ed from the action forwarded to, will be returned by the
 269 call to forward.
 270
 271     my $foodata = $c->forward('/foo');
 272     $c->forward('index');
 273     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 274     $c->forward('MyApp::View::TT');
 275
 276 Note that forward implies an C<<eval { }>> around the call (actually
 277 C<execute> does), thus de-fatalizing all 'dies' within the called
 278 action. If you want C<die> to propagate you need to do something like:
 279
 280     $c->forward('foo');
 281     die $c->error if $c->error;
 282
 283 Or make sure to always return true values from your actions and write
 284 your code like this:
 285
 286     $c->forward('foo') || return;
 287
 288 =cut
 289
 290 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 291
 292 =head2 $c->detach( $action [, \@arguments ] )
 293
 294 =head2 $c->detach( $class, $method, [, \@arguments ] )
 295
 296 =head2 $c->detach()
 297
 298 The same as C<forward>, but doesn't return to the previous action when
 299 processing is finished.
 300
 301 When called with no arguments it escapes the processing chain entirely.
 302
 303 =cut
 304
 305 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 306
 307 =head2 $c->response
 308
 309 =head2 $c->res
 310
 311 Returns the current L<Catalyst::Response> object, q.v.
 312
 313 =head2 $c->stash
 314
 315 Returns a hashref to the stash, which may be used to store data and pass
 316 it between components during a request. You can also set hash keys by
 317 passing arguments. The stash is automatically sent to the view. The
 318 stash is cleared at the end of a request; it cannot be used for
 319 persistent storage (for this you must use a session; see
 320 L<Catalyst::Plugin::Session> for a complete system integrated with
 321 Catalyst).
 322
 323     $c->stash->{foo} = $bar;
 324     $c->stash( { moose => 'majestic', qux => 0 } );
 325     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 326
 327     # stash is automatically passed to the view for use in a template
 328     $c->forward( 'MyApp::V::TT' );
 329
 330 =cut
 331
 332 sub stash {
 333     my $c = shift;
 334     if (@_) {
 335         my $stash = @_ > 1 ? {@_} : $_[0];
 336         croak('stash takes a hash or hashref') unless ref $stash;
 337         foreach my $key ( keys %$stash ) {
 338             $c->{stash}->{$key} = $stash->{$key};
 339         }
 340     }
 341     return $c->{stash};
 342 }
 343
 344 =head2 $c->error
 345
 346 =head2 $c->error($error, ...)
 347
 348 =head2 $c->error($arrayref)
 349
 350 Returns an arrayref containing error messages.  If Catalyst encounters an
 351 error while processing a request, it stores the error in $c->error.  This
 352 method should not be used to store non-fatal error messages.
 353
 354     my @error = @{ $c->error };
 355
 356 Add a new error.
 357
 358     $c->error('Something bad happened');
 359
 360 =cut
 361
 362 sub error {
 363     my $c = shift;
 364     if ( $_[0] ) {
 365         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 366         croak @$error unless ref $c;
 367         push @{ $c->{error} }, @$error;
 368     }
 369     elsif ( defined $_[0] ) { $c->{error} = undef }
 370     return $c->{error} || [];
 371 }
 372
 373
 374 =head2 $c->state
 375
 376 Contains the return value of the last executed action.
 377
 378 =head2 $c->clear_errors
 379
 380 Clear errors.  You probably don't want to clear the errors unless you are
 381 implementing a custom error screen.
 382
 383 This is equivalent to running
 384
 385     $c->error(0);
 386
 387 =cut
 388
 389 sub clear_errors {
 390     my $c = shift;
 391     $c->error(0);
 392 }
 393
 394
 395 # search via regex
 396 sub _comp_search {
 397     my ( $c, @names ) = @_;
 398
 399     foreach my $name (@names) {
 400         foreach my $component ( keys %{ $c->components } ) {
 401             return $c->components->{$component} if $component =~ /$name/i;
 402         }
 403     }
 404
 405     return undef;
 406 }
 407
 408 # try explicit component names
 409 sub _comp_explicit {
 410     my ( $c, @names ) = @_;
 411
 412     foreach my $try (@names) {
 413         return $c->components->{$try} if ( exists $c->components->{$try} );
 414     }
 415
 416     return undef;
 417 }
 418
 419 # like component, but try just these prefixes before regex searching,
 420 #  and do not try to return "sort keys %{ $c->components }"
 421 sub _comp_prefixes {
 422     my ( $c, $name, @prefixes ) = @_;
 423
 424     my $appclass = ref $c || $c;
 425
 426     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 427
 428     my $comp = $c->_comp_explicit(@names);
 429     return $comp if defined($comp);
 430     $comp = $c->_comp_search($name);
 431     return $comp;
 432 }
 433
 434 # Find possible names for a prefix
 435
 436 sub _comp_names {
 437     my ( $c, @prefixes ) = @_;
 438
 439     my $appclass = ref $c || $c;
 440
 441     my @pre = map { "${appclass}::${_}::" } @prefixes;
 442
 443     my @names;
 444
 445     COMPONENT: foreach my $comp ($c->component) {
 446         foreach my $p (@pre) {
 447             if ($comp =~ s/^$p//) {
 448                 push(@names, $comp);
 449                 next COMPONENT;
 450             }
 451         }
 452     }
 453
 454     return @names;
 455 }
 456
 457 # Return a component if only one matches.
 458 sub _comp_singular {
 459     my ( $c, @prefixes ) = @_;
 460
 461     my $appclass = ref $c || $c;
 462
 463     my ( $comp, $rest ) =
 464       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 465     return $comp unless $rest;
 466 }
 467
 468 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 469 sub _filter_component {
 470     my ( $c, $comp, @args ) = @_;
 471     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 472         return $comp->ACCEPT_CONTEXT( $c, @args );
 473     }
 474     else { return $comp }
 475 }
 476
 477 =head2 COMPONENT ACCESSORS
 478
 479 =head2 $c->controller($name)
 480
 481 Gets a L<Catalyst::Controller> instance by name.
 482
 483     $c->controller('Foo')->do_stuff;
 484
 485 If the name is omitted, will return the controller for the dispatched
 486 action.
 487
 488 =cut
 489
 490 sub controller {
 491     my ( $c, $name, @args ) = @_;
 492     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 493         @args )
 494       if ($name);
 495     return $c->component( $c->action->class );
 496 }
 497
 498 =head2 $c->model($name)
 499
 500 Gets a L<Catalyst::Model> instance by name.
 501
 502     $c->model('Foo')->do_stuff;
 503
 504 If the name is omitted, it will look for
 505  - a model object in $c->stash{current_model_instance}, then
 506  - a model name in $c->stash->{current_model}, then
 507  - a config setting 'default_model', or
 508  - check if there is only one model, and return it if that's the case.
 509
 510 =cut
 511
 512 sub model {
 513     my ( $c, $name, @args ) = @_;
 514     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 515         @args )
 516       if $name;
 517     if (ref $c) {
 518         return $c->stash->{current_model_instance}
 519           if $c->stash->{current_model_instance};
 520         return $c->model( $c->stash->{current_model} )
 521           if $c->stash->{current_model};
 522         return $c->model( $c->config->{default_model} )
 523           if $c->config->{default_model};
 524     }
 525     return $c->_filter_component( $c->_comp_singular(qw/Model M/), @args );
 526
 527 }
 528
 529 =head2 $c->controllers
 530
 531 Returns the available names which can be passed to $c->controller
 532
 533 =cut
 534
 535 sub controllers {
 536     my ( $c ) = @_;
 537     return $c->_comp_names(qw/Controller C/);
 538 }
 539
 540
 541 =head2 $c->view($name)
 542
 543 Gets a L<Catalyst::View> instance by name.
 544
 545     $c->view('Foo')->do_stuff;
 546
 547 If the name is omitted, it will look for
 548  - a view object in $c->stash{current_view_instance}, then
 549  - a view name in $c->stash->{current_view}, then
 550  - a config setting 'default_view', or
 551  - check if there is only one view, and return it if that's the case.
 552
 553 =cut
 554
 555 sub view {
 556     my ( $c, $name, @args ) = @_;
 557     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 558         @args )
 559       if $name;
 560     if (ref $c) {
 561         return $c->stash->{current_view_instance}
 562           if $c->stash->{current_view_instance};
 563         return $c->view( $c->stash->{current_view} )
 564           if $c->stash->{current_view};
 565         return $c->view( $c->config->{default_view} )
 566           if $c->config->{default_view};
 567     }
 568     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 569 }
 570
 571 =head2 $c->models
 572
 573 Returns the available names which can be passed to $c->model
 574
 575 =cut
 576
 577 sub models {
 578     my ( $c ) = @_;
 579     return $c->_comp_names(qw/Model M/);
 580 }
 581
 582
 583 =head2 $c->views
 584
 585 Returns the available names which can be passed to $c->view
 586
 587 =cut
 588
 589 sub views {
 590     my ( $c ) = @_;
 591     return $c->_comp_names(qw/View V/);
 592 }
 593
 594 =head2 $c->comp($name)
 595
 596 =head2 $c->component($name)
 597
 598 Gets a component object by name. This method is no longer recommended,
 599 unless you want to get a specific component by full
 600 class. C<$c-E<gt>controller>, C<$c-E<gt>model>, and C<$c-E<gt>view>
 601 should be used instead.
 602
 603 =cut
 604
 605 sub component {
 606     my $c = shift;
 607
 608     if (@_) {
 609
 610         my $name = shift;
 611
 612         my $appclass = ref $c || $c;
 613
 614         my @names = (
 615             $name, "${appclass}::${name}",
 616             map { "${appclass}::${_}::${name}" }
 617               qw/Model M Controller C View V/
 618         );
 619
 620         my $comp = $c->_comp_explicit(@names);
 621         return $c->_filter_component( $comp, @_ ) if defined($comp);
 622
 623         $comp = $c->_comp_search($name);
 624         return $c->_filter_component( $comp, @_ ) if defined($comp);
 625     }
 626
 627     return sort keys %{ $c->components };
 628 }
 629
 630
 631
 632 =head2 CLASS DATA AND HELPER CLASSES
 633
 634 =head2 $c->config
 635
 636 Returns or takes a hashref containing the application's configuration.
 637
 638     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 639
 640 You can also use a L<YAML> config file like myapp.yml in your
 641 applications home directory.
 642
 643     ---
 644     db: dsn:SQLite:foo.db
 645
 646
 647 =cut
 648
 649 sub config {
 650     my $c = shift;
 651
 652     $c->log->warn("Setting config after setup has been run is not a good idea.")
 653       if ( @_ and $c->setup_finished );
 654
 655     $c->NEXT::config(@_);
 656 }
 657
 658 =head2 $c->log
 659
 660 Returns the logging object instance. Unless it is already set, Catalyst
 661 sets this up with a L<Catalyst::Log> object. To use your own log class,
 662 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 663 C<< __PACKAGE__->setup >>.
 664
 665  __PACKAGE__->log( MyLogger->new );
 666  __PACKAGE__->setup;
 667
 668 And later:
 669
 670     $c->log->info( 'Now logging with my own logger!' );
 671
 672 Your log class should implement the methods described in
 673 L<Catalyst::Log>.
 674
 675
 676 =head2 $c->debug
 677
 678 Overload to enable debug messages (same as -Debug option).
 679
 680 Note that this is a static method, not an accessor and should be overloaded
 681 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 682
 683 =cut
 684
 685 sub debug { 0 }
 686
 687 =head2 $c->dispatcher
 688
 689 Returns the dispatcher instance. Stringifies to class name. See
 690 L<Catalyst::Dispatcher>.
 691
 692 =head2 $c->engine
 693
 694 Returns the engine instance. Stringifies to the class name. See
 695 L<Catalyst::Engine>.
 696
 697
 698 =head2 UTILITY METHODS
 699
 700 =head2 $c->path_to(@path)
 701
 702 Merges C<@path> with C<$c-E<gt>config-E<gt>{home}> and returns a
 703 L<Path::Class> object.
 704
 705 For example:
 706
 707     $c->path_to( 'db', 'sqlite.db' );
 708
 709 =cut
 710
 711 sub path_to {
 712     my ( $c, @path ) = @_;
 713     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 714     if ( -d $path ) { return $path }
 715     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 716 }
 717
 718 =head2 $c->plugin( $name, $class, @args )
 719
 720 Helper method for plugins. It creates a classdata accessor/mutator and
 721 loads and instantiates the given class.
 722
 723     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 724
 725     $c->prototype->define_javascript_functions;
 726
 727 =cut
 728
 729 sub plugin {
 730     my ( $class, $name, $plugin, @args ) = @_;
 731     $class->_register_plugin( $plugin, 1 );
 732
 733     eval { $plugin->import };
 734     $class->mk_classdata($name);
 735     my $obj;
 736     eval { $obj = $plugin->new(@args) };
 737
 738     if ($@) {
 739         Catalyst::Exception->throw( message =>
 740               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 741     }
 742
 743     $class->$name($obj);
 744     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 745       if $class->debug;
 746 }
 747
 748 =head2 MyApp->setup
 749
 750 Initializes the dispatcher and engine, loads any plugins, and loads the
 751 model, view, and controller components. You may also specify an array
 752 of plugins to load here, if you choose to not load them in the C<use
 753 Catalyst> line.
 754
 755     MyApp->setup;
 756     MyApp->setup( qw/-Debug/ );
 757
 758 =cut
 759
 760 sub setup {
 761     my ( $class, @arguments ) = @_;
 762
 763     $class->log->warn("Running setup twice is not a good idea.")
 764       if ( $class->setup_finished );
 765
 766     unless ( $class->isa('Catalyst') ) {
 767
 768         Catalyst::Exception->throw(
 769             message => qq/'$class' does not inherit from Catalyst/ );
 770     }
 771
 772     if ( $class->arguments ) {
 773         @arguments = ( @arguments, @{ $class->arguments } );
 774     }
 775
 776     # Process options
 777     my $flags = {};
 778
 779     foreach (@arguments) {
 780
 781         if (/^-Debug$/) {
 782             $flags->{log} =
 783               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 784         }
 785         elsif (/^-(\w+)=?(.*)$/) {
 786             $flags->{ lc $1 } = $2;
 787         }
 788         else {
 789             push @{ $flags->{plugins} }, $_;
 790         }
 791     }
 792
 793     $class->setup_home( delete $flags->{home} );
 794
 795     $class->setup_log( delete $flags->{log} );
 796     $class->setup_plugins( delete $flags->{plugins} );
 797     $class->setup_dispatcher( delete $flags->{dispatcher} );
 798     $class->setup_engine( delete $flags->{engine} );
 799
 800     for my $flag ( sort keys %{$flags} ) {
 801
 802         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 803             &$code( $class, delete $flags->{$flag} );
 804         }
 805         else {
 806             $class->log->warn(qq/Unknown flag "$flag"/);
 807         }
 808     }
 809
 810     eval { require Catalyst::Devel; };
 811     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 812         $class->log->warn(<<"EOF");
 813 You are running an old script!
 814
 815   Please update by running (this will overwrite existing files):
 816     catalyst.pl -force -scripts $class
 817
 818   or (this will not overwrite existing files):
 819     catalyst.pl -scripts $class
 820
 821 EOF
 822     }
 823
 824     if ( $class->debug ) {
 825         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 826
 827         if (@plugins) {
 828             my $t = Text::SimpleTable->new(74);
 829             $t->row($_) for @plugins;
 830             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 831         }
 832
 833         my $dispatcher = $class->dispatcher;
 834         my $engine     = $class->engine;
 835         my $home       = $class->config->{home};
 836
 837         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 838         $class->log->debug(qq/Loaded engine "$engine"/);
 839
 840         $home
 841           ? ( -d $home )
 842           ? $class->log->debug(qq/Found home "$home"/)
 843           : $class->log->debug(qq/Home "$home" doesn't exist/)
 844           : $class->log->debug(q/Couldn't find home/);
 845     }
 846
 847     # Call plugins setup
 848     {
 849         no warnings qw/redefine/;
 850         local *setup = sub { };
 851         $class->setup;
 852     }
 853
 854     # Initialize our data structure
 855     $class->components( {} );
 856
 857     $class->setup_components;
 858
 859     if ( $class->debug ) {
 860         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 861         for my $comp ( sort keys %{ $class->components } ) {
 862             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 863             $t->row( $comp, $type );
 864         }
 865         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 866           if ( keys %{ $class->components } );
 867     }
 868
 869     # Add our self to components, since we are also a component
 870     $class->components->{$class} = $class;
 871
 872     $class->setup_actions;
 873
 874     if ( $class->debug ) {
 875         my $name = $class->config->{name} || 'Application';
 876         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 877     }
 878     $class->log->_flush() if $class->log->can('_flush');
 879
 880     $class->setup_finished(1);
 881 }
 882
 883 =head2 $c->uri_for( $path, @args?, \%query_values? )
 884
 885 Merges path with C<< $c->request->base >> for absolute URIs and with
 886 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 887 object. If any args are passed, they are added at the end of the path.
 888 If the last argument to C<uri_for> is a hash reference, it is assumed to
 889 contain GET parameter key/value pairs, which will be appended to the URI
 890 in standard fashion.
 891
 892 Instead of C<$path>, you can also optionally pass a C<$action> object
 893 which will be resolved to a path using
 894 C<< $c->dispatcher->uri_for_action >>; if the first element of
 895 C<@args> is an arrayref it is treated as a list of captures to be passed
 896 to C<uri_for_action>.
 897
 898 =cut
 899
 900 sub uri_for {
 901     my ( $c, $path, @args ) = @_;
 902     my $base     = $c->request->base->clone;
 903     my $basepath = $base->path;
 904     $basepath =~ s/\/$//;
 905     $basepath .= '/';
 906     my $namespace = $c->namespace || '';
 907
 908     if ( Scalar::Util::blessed($path) ) { # action object
 909         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 910                          ? shift(@args)
 911                          : [] );
 912         $path = $c->dispatcher->uri_for_action($path, $captures);
 913         return undef unless defined($path);
 914         $path = '/' if $path eq '';
 915     }
 916
 917     # massage namespace, empty if absolute path
 918     $namespace =~ s/^\/// if $namespace;
 919     $namespace .= '/' if $namespace;
 920     $path ||= '';
 921     $namespace = '' if $path =~ /^\//;
 922     $path =~ s/^\///;
 923
 924     my $params =
 925       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 926
 927     for my $value ( values %$params ) {
 928         for ( ref $value eq 'ARRAY' ? @$value : $value ) {
 929             $_ = "$_";
 930             utf8::encode( $_ );
 931         }
 932     };
 933
 934     # join args with '/', or a blank string
 935     my $args = ( scalar @args ? '/' . join( '/', @args ) : '' );
 936     $args =~ s/^\/// unless $path;
 937     my $res =
 938       URI->new_abs( URI->new_abs( "$path$args", "$basepath$namespace" ), $base )
 939       ->canonical;
 940     $res->query_form(%$params);
 941     $res;
 942 }
 943
 944 =head2 $c->welcome_message
 945
 946 Returns the Catalyst welcome HTML page.
 947
 948 =cut
 949
 950 sub welcome_message {
 951     my $c      = shift;
 952     my $name   = $c->config->{name};
 953     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
 954     my $prefix = Catalyst::Utils::appprefix( ref $c );
 955     $c->response->content_type('text/html; charset=utf-8');
 956     return <<"EOF";
 957 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
 958     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
 959 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 960     <head>
 961         <meta http-equiv="Content-Language" content="en" />
 962         <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
 963         <title>$name on Catalyst $VERSION</title>
 964         <style type="text/css">
 965             body {
 966                 color: #000;
 967                 background-color: #eee;
 968             }
 969             div#content {
 970                 width: 640px;
 971                 margin-left: auto;
 972                 margin-right: auto;
 973                 margin-top: 10px;
 974                 margin-bottom: 10px;
 975                 text-align: left;
 976                 background-color: #ccc;
 977                 border: 1px solid #aaa;
 978             }
 979             p, h1, h2 {
 980                 margin-left: 20px;
 981                 margin-right: 20px;
 982                 font-family: verdana, tahoma, sans-serif;
 983             }
 984             a {
 985                 font-family: verdana, tahoma, sans-serif;
 986             }
 987             :link, :visited {
 988                     text-decoration: none;
 989                     color: #b00;
 990                     border-bottom: 1px dotted #bbb;
 991             }
 992             :link:hover, :visited:hover {
 993                     color: #555;
 994             }
 995             div#topbar {
 996                 margin: 0px;
 997             }
 998             pre {
 999                 margin: 10px;
1000                 padding: 8px;
1001             }
1002             div#answers {
1003                 padding: 8px;
1004                 margin: 10px;
1005                 background-color: #fff;
1006                 border: 1px solid #aaa;
1007             }
1008             h1 {
1009                 font-size: 0.9em;
1010                 font-weight: normal;
1011                 text-align: center;
1012             }
1013             h2 {
1014                 font-size: 1.0em;
1015             }
1016             p {
1017                 font-size: 0.9em;
1018             }
1019             p img {
1020                 float: right;
1021                 margin-left: 10px;
1022             }
1023             span#appname {
1024                 font-weight: bold;
1025                 font-size: 1.6em;
1026             }
1027         </style>
1028     </head>
1029     <body>
1030         <div id="content">
1031             <div id="topbar">
1032                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1033                     $VERSION</h1>
1034              </div>
1035              <div id="answers">
1036                  <p>
1037                  <img src="$logo" alt="Catalyst Logo" />
1038                  </p>
1039                  <p>Welcome to the wonderful world of Catalyst.
1040                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1041                     framework will make web development something you had
1042                     never expected it to be: Fun, rewarding, and quick.</p>
1043                  <h2>What to do now?</h2>
1044                  <p>That really depends  on what <b>you</b> want to do.
1045                     We do, however, provide you with a few starting points.</p>
1046                  <p>If you want to jump right into web development with Catalyst
1047                     you might want to check out the documentation.</p>
1048                  <pre><code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1049 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1050 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual.pod">Catalyst::Manual</a></code></pre>
1051                  <h2>What to do next?</h2>
1052                  <p>Next it's time to write an actual application. Use the
1053                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1054                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1055                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1056                     they can save you a lot of work.</p>
1057                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1058                     <p>Also, be sure to check out the vast and growing
1059                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1060                     you are likely to find what you need there.
1061                     </p>
1062
1063                  <h2>Need help?</h2>
1064                  <p>Catalyst has a very active community. Here are the main places to
1065                     get in touch with us.</p>
1066                  <ul>
1067                      <li>
1068                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1069                      </li>
1070                      <li>
1071                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1072                      </li>
1073                      <li>
1074                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1075                      </li>
1076                  </ul>
1077                  <h2>In conclusion</h2>
1078                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1079                     as we enjoyed making it. Please contact us if you have ideas
1080                     for improvement or other feedback.</p>
1081              </div>
1082          </div>
1083     </body>
1084 </html>
1085 EOF
1086 }
1087
1088 =head1 INTERNAL METHODS
1089
1090 These methods are not meant to be used by end users.
1091
1092 =head2 $c->components
1093
1094 Returns a hash of components.
1095
1096 =head2 $c->context_class
1097
1098 Returns or sets the context class.
1099
1100 =head2 $c->counter
1101
1102 Returns a hashref containing coderefs and execution counts (needed for
1103 deep recursion detection).
1104
1105 =head2 $c->depth
1106
1107 Returns the number of actions on the current internal execution stack.
1108
1109 =head2 $c->dispatch
1110
1111 Dispatches a request to actions.
1112
1113 =cut
1114
1115 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1116
1117 =head2 $c->dispatcher_class
1118
1119 Returns or sets the dispatcher class.
1120
1121 =head2 $c->dump_these
1122
1123 Returns a list of 2-element array references (name, structure) pairs
1124 that will be dumped on the error page in debug mode.
1125
1126 =cut
1127
1128 sub dump_these {
1129     my $c = shift;
1130     [ Request => $c->req ],
1131     [ Response => $c->res ],
1132     [ Stash => $c->stash ],
1133     [ Config => $c->config ];
1134 }
1135
1136 =head2 $c->engine_class
1137
1138 Returns or sets the engine class.
1139
1140 =head2 $c->execute( $class, $coderef )
1141
1142 Execute a coderef in given class and catch exceptions. Errors are available
1143 via $c->error.
1144
1145 =cut
1146
1147 sub execute {
1148     my ( $c, $class, $code ) = @_;
1149     $class = $c->component($class) || $class;
1150     $c->state(0);
1151
1152     if ( $c->depth >= $RECURSION ) {
1153         my $action = "$code";
1154         $action = "/$action" unless $action =~ /->/;
1155         my $error = qq/Deep recursion detected calling "$action"/;
1156         $c->log->error($error);
1157         $c->error($error);
1158         $c->state(0);
1159         return $c->state;
1160     }
1161
1162     my $stats_info = $c->_stats_start_execute( $code ) if $c->debug;
1163
1164     push( @{ $c->stack }, $code );
1165
1166     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1167
1168     $c->_stats_finish_execute( $stats_info ) if $c->debug and $stats_info;
1169
1170     my $last = pop( @{ $c->stack } );
1171
1172     if ( my $error = $@ ) {
1173         if ( !ref($error) and $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1174         else {
1175             unless ( ref $error ) {
1176                 no warnings 'uninitialized';
1177                 chomp $error;
1178                 my $class = $last->class;
1179                 my $name  = $last->name;
1180                 $error = qq/Caught exception in $class->$name "$error"/;
1181             }
1182             $c->error($error);
1183             $c->state(0);
1184         }
1185     }
1186     return $c->state;
1187 }
1188
1189 sub _stats_start_execute {
1190     my ( $c, $code ) = @_;
1191
1192     return if ( ( $code->name =~ /^_.*/ )
1193         && ( !$c->config->{show_internal_actions} ) );
1194
1195     $c->counter->{"$code"}++;
1196
1197     my $action = "$code";
1198     $action = "/$action" unless $action =~ /->/;
1199
1200     # determine if the call was the result of a forward
1201     # this is done by walking up the call stack and looking for a calling
1202     # sub of Catalyst::forward before the eval
1203     my $callsub = q{};
1204     for my $index ( 2 .. 11 ) {
1205         last
1206         if ( ( caller($index) )[0] eq 'Catalyst'
1207             && ( caller($index) )[3] eq '(eval)' );
1208
1209         if ( ( caller($index) )[3] =~ /forward$/ ) {
1210             $callsub = ( caller($index) )[3];
1211             $action  = "-> $action";
1212             last;
1213         }
1214     }
1215
1216     my $node = Tree::Simple->new(
1217         {
1218             action  => $action,
1219             elapsed => undef,     # to be filled in later
1220             comment => "",
1221         }
1222     );
1223     $node->setUID( "$code" . $c->counter->{"$code"} );
1224
1225     # is this a root-level call or a forwarded call?
1226     if ( $callsub =~ /forward$/ ) {
1227
1228         # forward, locate the caller
1229         if ( my $parent = $c->stack->[-1] ) {
1230             my $visitor = Tree::Simple::Visitor::FindByUID->new;
1231             $visitor->searchForUID(
1232                 "$parent" . $c->counter->{"$parent"} );
1233             $c->stats->accept($visitor);
1234             if ( my $result = $visitor->getResult ) {
1235                 $result->addChild($node);
1236             }
1237         }
1238         else {
1239
1240             # forward with no caller may come from a plugin
1241             $c->stats->addChild($node);
1242         }
1243     }
1244     else {
1245
1246         # root-level call
1247         $c->stats->addChild($node);
1248     }
1249
1250     return {
1251         start   => [gettimeofday],
1252         node    => $node,
1253     };
1254 }
1255
1256 sub _stats_finish_execute {
1257     my ( $c, $info ) = @_;
1258     my $elapsed = tv_interval $info->{start};
1259     my $value = $info->{node}->getNodeValue;
1260     $value->{elapsed} = sprintf( '%fs', $elapsed );
1261 }
1262
1263 =head2 $c->_localize_fields( sub { }, \%keys );
1264
1265 =cut
1266
1267 sub _localize_fields {
1268     my ( $c, $localized, $code ) = ( @_ );
1269
1270     my $request = delete $localized->{request} || {};
1271     my $response = delete $localized->{response} || {};
1272
1273     local @{ $c }{ keys %$localized } = values %$localized;
1274     local @{ $c->request }{ keys %$request } = values %$request;
1275     local @{ $c->response }{ keys %$response } = values %$response;
1276
1277     $code->();
1278 }
1279
1280 =head2 $c->finalize
1281
1282 Finalizes the request.
1283
1284 =cut
1285
1286 sub finalize {
1287     my $c = shift;
1288
1289     for my $error ( @{ $c->error } ) {
1290         $c->log->error($error);
1291     }
1292
1293     # Allow engine to handle finalize flow (for POE)
1294     if ( $c->engine->can('finalize') ) {
1295         $c->engine->finalize($c);
1296     }
1297     else {
1298
1299         $c->finalize_uploads;
1300
1301         # Error
1302         if ( $#{ $c->error } >= 0 ) {
1303             $c->finalize_error;
1304         }
1305
1306         $c->finalize_headers;
1307
1308         # HEAD request
1309         if ( $c->request->method eq 'HEAD' ) {
1310             $c->response->body('');
1311         }
1312
1313         $c->finalize_body;
1314     }
1315
1316     if ($c->debug) {
1317         my $elapsed = sprintf '%f', tv_interval($c->stats->getNodeValue);
1318         my $av = sprintf '%.3f', ( $elapsed == 0 ? '??' : ( 1 / $elapsed ) );
1319
1320         my $t = Text::SimpleTable->new( [ 62, 'Action' ], [ 9, 'Time' ] );
1321         $c->stats->traverse(
1322             sub {
1323                 my $action = shift;
1324                 my $stat   = $action->getNodeValue;
1325                 $t->row( ( q{ } x $action->getDepth ) . $stat->{action} . $stat->{comment},
1326                     $stat->{elapsed} || '??' );
1327             }
1328         );
1329
1330         $c->log->info(
1331             "Request took ${elapsed}s ($av/s)\n" . $t->draw . "\n" );
1332     }
1333
1334     return $c->response->status;
1335 }
1336
1337 =head2 $c->finalize_body
1338
1339 Finalizes body.
1340
1341 =cut
1342
1343 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1344
1345 =head2 $c->finalize_cookies
1346
1347 Finalizes cookies.
1348
1349 =cut
1350
1351 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1352
1353 =head2 $c->finalize_error
1354
1355 Finalizes error.
1356
1357 =cut
1358
1359 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1360
1361 =head2 $c->finalize_headers
1362
1363 Finalizes headers.
1364
1365 =cut
1366
1367 sub finalize_headers {
1368     my $c = shift;
1369
1370     # Check if we already finalized headers
1371     return if $c->response->{_finalized_headers};
1372
1373     # Handle redirects
1374     if ( my $location = $c->response->redirect ) {
1375         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1376         $c->response->header( Location => $location );
1377     }
1378
1379     # Content-Length
1380     if ( $c->response->body && !$c->response->content_length ) {
1381
1382         # get the length from a filehandle
1383         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1384         {
1385             if ( my $stat = stat $c->response->body ) {
1386                 $c->response->content_length( $stat->size );
1387             }
1388             else {
1389                 $c->log->warn('Serving filehandle without a content-length');
1390             }
1391         }
1392         else {
1393             $c->response->content_length( bytes::length( $c->response->body ) );
1394         }
1395     }
1396
1397     # Errors
1398     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1399         $c->response->headers->remove_header("Content-Length");
1400         $c->response->body('');
1401     }
1402
1403     $c->finalize_cookies;
1404
1405     $c->engine->finalize_headers( $c, @_ );
1406
1407     # Done
1408     $c->response->{_finalized_headers} = 1;
1409 }
1410
1411 =head2 $c->finalize_output
1412
1413 An alias for finalize_body.
1414
1415 =head2 $c->finalize_read
1416
1417 Finalizes the input after reading is complete.
1418
1419 =cut
1420
1421 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1422
1423 =head2 $c->finalize_uploads
1424
1425 Finalizes uploads. Cleans up any temporary files.
1426
1427 =cut
1428
1429 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1430
1431 =head2 $c->get_action( $action, $namespace )
1432
1433 Gets an action in a given namespace.
1434
1435 =cut
1436
1437 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1438
1439 =head2 $c->get_actions( $action, $namespace )
1440
1441 Gets all actions of a given name in a namespace and all parent
1442 namespaces.
1443
1444 =cut
1445
1446 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1447
1448 =head2 $c->handle_request( $class, @arguments )
1449
1450 Called to handle each HTTP request.
1451
1452 =cut
1453
1454 sub handle_request {
1455     my ( $class, @arguments ) = @_;
1456
1457     # Always expect worst case!
1458     my $status = -1;
1459     eval {
1460         if ($class->debug) {
1461             my $secs = time - $START || 1;
1462             my $av = sprintf '%.3f', $COUNT / $secs;
1463             my $time = localtime time;
1464             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1465         }
1466
1467         my $c = $class->prepare(@arguments);
1468         $c->dispatch;
1469         $status = $c->finalize;
1470     };
1471
1472     if ( my $error = $@ ) {
1473         chomp $error;
1474         $class->log->error(qq/Caught exception in engine "$error"/);
1475     }
1476
1477     $COUNT++;
1478     $class->log->_flush() if $class->log->can('_flush');
1479     return $status;
1480 }
1481
1482 =head2 $c->prepare( @arguments )
1483
1484 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1485 etc.).
1486
1487 =cut
1488
1489 sub prepare {
1490     my ( $class, @arguments ) = @_;
1491
1492     $class->context_class( ref $class || $class ) unless $class->context_class;
1493     my $c = $class->context_class->new(
1494         {
1495             counter => {},
1496             stack   => [],
1497             request => $class->request_class->new(
1498                 {
1499                     arguments        => [],
1500                     body_parameters  => {},
1501                     cookies          => {},
1502                     headers          => HTTP::Headers->new,
1503                     parameters       => {},
1504                     query_parameters => {},
1505                     secure           => 0,
1506                     captures         => [],
1507                     uploads          => {}
1508                 }
1509             ),
1510             response => $class->response_class->new(
1511                 {
1512                     body    => '',
1513                     cookies => {},
1514                     headers => HTTP::Headers->new(),
1515                     status  => 200
1516                 }
1517             ),
1518             stash => {},
1519             state => 0
1520         }
1521     );
1522
1523     if ( $c->debug ) {
1524         $c->stats(Tree::Simple->new([gettimeofday]));
1525         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1526     }
1527
1528     # For on-demand data
1529     $c->request->{_context}  = $c;
1530     $c->response->{_context} = $c;
1531     weaken( $c->request->{_context} );
1532     weaken( $c->response->{_context} );
1533
1534     # Allow engine to direct the prepare flow (for POE)
1535     if ( $c->engine->can('prepare') ) {
1536         $c->engine->prepare( $c, @arguments );
1537     }
1538     else {
1539         $c->prepare_request(@arguments);
1540         $c->prepare_connection;
1541         $c->prepare_query_parameters;
1542         $c->prepare_headers;
1543         $c->prepare_cookies;
1544         $c->prepare_path;
1545
1546         # On-demand parsing
1547         $c->prepare_body unless $c->config->{parse_on_demand};
1548     }
1549
1550     my $method  = $c->req->method  || '';
1551     my $path    = $c->req->path    || '/';
1552     my $address = $c->req->address || '';
1553
1554     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1555       if $c->debug;
1556
1557     $c->prepare_action;
1558
1559     return $c;
1560 }
1561
1562 =head2 $c->prepare_action
1563
1564 Prepares action. See L<Catalyst::Dispatcher>.
1565
1566 =cut
1567
1568 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1569
1570 =head2 $c->prepare_body
1571
1572 Prepares message body.
1573
1574 =cut
1575
1576 sub prepare_body {
1577     my $c = shift;
1578
1579     # Do we run for the first time?
1580     return if defined $c->request->{_body};
1581
1582     # Initialize on-demand data
1583     $c->engine->prepare_body( $c, @_ );
1584     $c->prepare_parameters;
1585     $c->prepare_uploads;
1586
1587     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1588         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1589         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1590             my $param = $c->req->body_parameters->{$key};
1591             my $value = defined($param) ? $param : '';
1592             $t->row( $key,
1593                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1594         }
1595         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1596     }
1597 }
1598
1599 =head2 $c->prepare_body_chunk( $chunk )
1600
1601 Prepares a chunk of data before sending it to L<HTTP::Body>.
1602
1603 See L<Catalyst::Engine>.
1604
1605 =cut
1606
1607 sub prepare_body_chunk {
1608     my $c = shift;
1609     $c->engine->prepare_body_chunk( $c, @_ );
1610 }
1611
1612 =head2 $c->prepare_body_parameters
1613
1614 Prepares body parameters.
1615
1616 =cut
1617
1618 sub prepare_body_parameters {
1619     my $c = shift;
1620     $c->engine->prepare_body_parameters( $c, @_ );
1621 }
1622
1623 =head2 $c->prepare_connection
1624
1625 Prepares connection.
1626
1627 =cut
1628
1629 sub prepare_connection {
1630     my $c = shift;
1631     $c->engine->prepare_connection( $c, @_ );
1632 }
1633
1634 =head2 $c->prepare_cookies
1635
1636 Prepares cookies.
1637
1638 =cut
1639
1640 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1641
1642 =head2 $c->prepare_headers
1643
1644 Prepares headers.
1645
1646 =cut
1647
1648 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1649
1650 =head2 $c->prepare_parameters
1651
1652 Prepares parameters.
1653
1654 =cut
1655
1656 sub prepare_parameters {
1657     my $c = shift;
1658     $c->prepare_body_parameters;
1659     $c->engine->prepare_parameters( $c, @_ );
1660 }
1661
1662 =head2 $c->prepare_path
1663
1664 Prepares path and base.
1665
1666 =cut
1667
1668 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1669
1670 =head2 $c->prepare_query_parameters
1671
1672 Prepares query parameters.
1673
1674 =cut
1675
1676 sub prepare_query_parameters {
1677     my $c = shift;
1678
1679     $c->engine->prepare_query_parameters( $c, @_ );
1680
1681     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1682         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1683         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1684             my $param = $c->req->query_parameters->{$key};
1685             my $value = defined($param) ? $param : '';
1686             $t->row( $key,
1687                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1688         }
1689         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1690     }
1691 }
1692
1693 =head2 $c->prepare_read
1694
1695 Prepares the input for reading.
1696
1697 =cut
1698
1699 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1700
1701 =head2 $c->prepare_request
1702
1703 Prepares the engine request.
1704
1705 =cut
1706
1707 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1708
1709 =head2 $c->prepare_uploads
1710
1711 Prepares uploads.
1712
1713 =cut
1714
1715 sub prepare_uploads {
1716     my $c = shift;
1717
1718     $c->engine->prepare_uploads( $c, @_ );
1719
1720     if ( $c->debug && keys %{ $c->request->uploads } ) {
1721         my $t = Text::SimpleTable->new(
1722             [ 12, 'Parameter' ],
1723             [ 26, 'Filename' ],
1724             [ 18, 'Type' ],
1725             [ 9,  'Size' ]
1726         );
1727         for my $key ( sort keys %{ $c->request->uploads } ) {
1728             my $upload = $c->request->uploads->{$key};
1729             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1730                 $t->row( $key, $u->filename, $u->type, $u->size );
1731             }
1732         }
1733         $c->log->debug( "File Uploads are:\n" . $t->draw );
1734     }
1735 }
1736
1737 =head2 $c->prepare_write
1738
1739 Prepares the output for writing.
1740
1741 =cut
1742
1743 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1744
1745 =head2 $c->request_class
1746
1747 Returns or sets the request class.
1748
1749 =head2 $c->response_class
1750
1751 Returns or sets the response class.
1752
1753 =head2 $c->read( [$maxlength] )
1754
1755 Reads a chunk of data from the request body. This method is designed to
1756 be used in a while loop, reading C<$maxlength> bytes on every call.
1757 C<$maxlength> defaults to the size of the request if not specified.
1758
1759 You have to set C<MyApp-E<gt>config-E<gt>{parse_on_demand}> to use this
1760 directly.
1761
1762 =cut
1763
1764 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1765
1766 =head2 $c->run
1767
1768 Starts the engine.
1769
1770 =cut
1771
1772 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1773
1774 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1775
1776 Sets an action in a given namespace.
1777
1778 =cut
1779
1780 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1781
1782 =head2 $c->setup_actions($component)
1783
1784 Sets up actions for a component.
1785
1786 =cut
1787
1788 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1789
1790 =head2 $c->setup_components
1791
1792 Sets up components. Specify a C<setup_components> config option to pass
1793 additional options directly to L<Module::Pluggable>. To add additional
1794 search paths, specify a key named C<search_extra> as an array
1795 reference. Items in the array beginning with C<::> will have the
1796 application class name prepended to them.
1797
1798 =cut
1799
1800 sub setup_components {
1801     my $class = shift;
1802
1803     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1804     my $config  = $class->config->{ setup_components };
1805     my $extra   = delete $config->{ search_extra } || [];
1806
1807     push @paths, @$extra;
1808
1809     my $locator = Module::Pluggable::Object->new(
1810         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1811         %$config
1812     );
1813
1814     for my $component ( sort { length $a <=> length $b } $locator->plugins ) {
1815         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1816
1817         my $module  = $class->setup_component( $component );
1818         my %modules = (
1819             $component => $module,
1820             map {
1821                 $_ => $class->setup_component( $_ )
1822             } Devel::InnerPackage::list_packages( $component )
1823         );
1824
1825         for my $key ( keys %modules ) {
1826             $class->components->{ $key } = $modules{ $key };
1827         }
1828     }
1829 }
1830
1831 =head2 $c->setup_component
1832
1833 =cut
1834
1835 sub setup_component {
1836     my( $class, $component ) = @_;
1837
1838     unless ( $component->can( 'COMPONENT' ) ) {
1839         return $component;
1840     }
1841
1842     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1843     my $config = $class->config->{ $suffix } || {};
1844
1845     my $instance = eval { $component->COMPONENT( $class, $config ); };
1846
1847     if ( my $error = $@ ) {
1848         chomp $error;
1849         Catalyst::Exception->throw(
1850             message => qq/Couldn't instantiate component "$component", "$error"/
1851         );
1852     }
1853
1854     Catalyst::Exception->throw(
1855         message =>
1856         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1857     ) unless eval { $instance->can( 'can' ) };
1858
1859     return $instance;
1860 }
1861
1862 =head2 $c->setup_dispatcher
1863
1864 Sets up dispatcher.
1865
1866 =cut
1867
1868 sub setup_dispatcher {
1869     my ( $class, $dispatcher ) = @_;
1870
1871     if ($dispatcher) {
1872         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1873     }
1874
1875     if ( $ENV{CATALYST_DISPATCHER} ) {
1876         $dispatcher = 'Catalyst::Dispatcher::' . $ENV{CATALYST_DISPATCHER};
1877     }
1878
1879     if ( $ENV{ uc($class) . '_DISPATCHER' } ) {
1880         $dispatcher =
1881           'Catalyst::Dispatcher::' . $ENV{ uc($class) . '_DISPATCHER' };
1882     }
1883
1884     unless ($dispatcher) {
1885         $dispatcher = $class->dispatcher_class;
1886     }
1887
1888     unless (Class::Inspector->loaded($dispatcher)) {
1889         require Class::Inspector->filename($dispatcher);
1890     }
1891
1892     # dispatcher instance
1893     $class->dispatcher( $dispatcher->new );
1894 }
1895
1896 =head2 $c->setup_engine
1897
1898 Sets up engine.
1899
1900 =cut
1901
1902 sub setup_engine {
1903     my ( $class, $engine ) = @_;
1904
1905     if ($engine) {
1906         $engine = 'Catalyst::Engine::' . $engine;
1907     }
1908
1909     if ( $ENV{CATALYST_ENGINE} ) {
1910         $engine = 'Catalyst::Engine::' . $ENV{CATALYST_ENGINE};
1911     }
1912
1913     if ( $ENV{ uc($class) . '_ENGINE' } ) {
1914         $engine = 'Catalyst::Engine::' . $ENV{ uc($class) . '_ENGINE' };
1915     }
1916
1917     if ( $ENV{MOD_PERL} ) {
1918
1919         # create the apache method
1920         {
1921             no strict 'refs';
1922             *{"$class\::apache"} = sub { shift->engine->apache };
1923         }
1924
1925         my ( $software, $version ) =
1926           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1927
1928         $version =~ s/_//g;
1929         $version =~ s/(\.[^.]+)\./$1/g;
1930
1931         if ( $software eq 'mod_perl' ) {
1932
1933             if ( !$engine ) {
1934
1935                 if ( $version >= 1.99922 ) {
1936                     $engine = 'Catalyst::Engine::Apache2::MP20';
1937                 }
1938
1939                 elsif ( $version >= 1.9901 ) {
1940                     $engine = 'Catalyst::Engine::Apache2::MP19';
1941                 }
1942
1943                 elsif ( $version >= 1.24 ) {
1944                     $engine = 'Catalyst::Engine::Apache::MP13';
1945                 }
1946
1947                 else {
1948                     Catalyst::Exception->throw( message =>
1949                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
1950                 }
1951
1952             }
1953
1954             # install the correct mod_perl handler
1955             if ( $version >= 1.9901 ) {
1956                 *handler = sub  : method {
1957                     shift->handle_request(@_);
1958                 };
1959             }
1960             else {
1961                 *handler = sub ($$) { shift->handle_request(@_) };
1962             }
1963
1964         }
1965
1966         elsif ( $software eq 'Zeus-Perl' ) {
1967             $engine = 'Catalyst::Engine::Zeus';
1968         }
1969
1970         else {
1971             Catalyst::Exception->throw(
1972                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
1973         }
1974     }
1975
1976     unless ($engine) {
1977         $engine = $class->engine_class;
1978     }
1979
1980     unless (Class::Inspector->loaded($engine)) {
1981         require Class::Inspector->filename($engine);
1982     }
1983
1984     # check for old engines that are no longer compatible
1985     my $old_engine;
1986     if ( $engine->isa('Catalyst::Engine::Apache')
1987         && !Catalyst::Engine::Apache->VERSION )
1988     {
1989         $old_engine = 1;
1990     }
1991
1992     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
1993         && Catalyst::Engine::Server->VERSION le '0.02' )
1994     {
1995         $old_engine = 1;
1996     }
1997
1998     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
1999         && $engine->VERSION eq '0.01' )
2000     {
2001         $old_engine = 1;
2002     }
2003
2004     elsif ($engine->isa('Catalyst::Engine::Zeus')
2005         && $engine->VERSION eq '0.01' )
2006     {
2007         $old_engine = 1;
2008     }
2009
2010     if ($old_engine) {
2011         Catalyst::Exception->throw( message =>
2012               qq/Engine "$engine" is not supported by this version of Catalyst/
2013         );
2014     }
2015
2016     # engine instance
2017     $class->engine( $engine->new );
2018 }
2019
2020 =head2 $c->setup_home
2021
2022 Sets up the home directory.
2023
2024 =cut
2025
2026 sub setup_home {
2027     my ( $class, $home ) = @_;
2028
2029     if ( $ENV{CATALYST_HOME} ) {
2030         $home = $ENV{CATALYST_HOME};
2031     }
2032
2033     if ( $ENV{ uc($class) . '_HOME' } ) {
2034         $home = $ENV{ uc($class) . '_HOME' };
2035     }
2036
2037     unless ($home) {
2038         $home = Catalyst::Utils::home($class);
2039     }
2040
2041     if ($home) {
2042         $class->config->{home} ||= $home;
2043         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2044     }
2045 }
2046
2047 =head2 $c->setup_log
2048
2049 Sets up log.
2050
2051 =cut
2052
2053 sub setup_log {
2054     my ( $class, $debug ) = @_;
2055
2056     unless ( $class->log ) {
2057         $class->log( Catalyst::Log->new );
2058     }
2059
2060     my $app_flag = Catalyst::Utils::class2env($class) . '_DEBUG';
2061
2062     if (
2063           ( defined( $ENV{CATALYST_DEBUG} ) || defined( $ENV{$app_flag} ) )
2064         ? ( $ENV{CATALYST_DEBUG} || $ENV{$app_flag} )
2065         : $debug
2066       )
2067     {
2068         no strict 'refs';
2069         *{"$class\::debug"} = sub { 1 };
2070         $class->log->debug('Debug messages enabled');
2071     }
2072 }
2073
2074 =head2 $c->setup_plugins
2075
2076 Sets up plugins.
2077
2078 =cut
2079
2080 =head2 $c->registered_plugins
2081
2082 Returns a sorted list of the plugins which have either been stated in the
2083 import list or which have been added via C<< MyApp->plugin(@args); >>.
2084
2085 If passed a given plugin name, it will report a boolean value indicating
2086 whether or not that plugin is loaded.  A fully qualified name is required if
2087 the plugin name does not begin with C<Catalyst::Plugin::>.
2088
2089  if ($c->registered_plugins('Some::Plugin')) {
2090      ...
2091  }
2092
2093 =cut
2094
2095 {
2096
2097     sub registered_plugins {
2098         my $proto = shift;
2099         return sort keys %{ $proto->_plugins } unless @_;
2100         my $plugin = shift;
2101         return 1 if exists $proto->_plugins->{$plugin};
2102         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2103     }
2104
2105     sub _register_plugin {
2106         my ( $proto, $plugin, $instant ) = @_;
2107         my $class = ref $proto || $proto;
2108
2109         unless (Class::Inspector->loaded($plugin)) {
2110             require Class::Inspector->filename($plugin);
2111         }
2112
2113         $proto->_plugins->{$plugin} = 1;
2114         unless ($instant) {
2115             no strict 'refs';
2116             unshift @{"$class\::ISA"}, $plugin;
2117         }
2118         return $class;
2119     }
2120
2121     sub setup_plugins {
2122         my ( $class, $plugins ) = @_;
2123
2124         $class->_plugins( {} ) unless $class->_plugins;
2125         $plugins ||= [];
2126         for my $plugin ( reverse @$plugins ) {
2127
2128             unless ( $plugin =~ s/\A\+// ) {
2129                 $plugin = "Catalyst::Plugin::$plugin";
2130             }
2131
2132             $class->_register_plugin($plugin);
2133         }
2134     }
2135 }
2136
2137 =head2 $c->stack
2138
2139 Returns an arrayref of the internal execution stack (actions that are
2140 currently executing).
2141
2142 =head2 $c->write( $data )
2143
2144 Writes $data to the output stream. When using this method directly, you
2145 will need to manually set the C<Content-Length> header to the length of
2146 your output data, if known.
2147
2148 =cut
2149
2150 sub write {
2151     my $c = shift;
2152
2153     # Finalize headers if someone manually writes output
2154     $c->finalize_headers;
2155
2156     return $c->engine->write( $c, @_ );
2157 }
2158
2159 =head2 version
2160
2161 Returns the Catalyst version number. Mostly useful for "powered by"
2162 messages in template systems.
2163
2164 =cut
2165
2166 sub version { return $Catalyst::VERSION }
2167
2168 =head1 INTERNAL ACTIONS
2169
2170 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2171 C<_ACTION>, and C<_END>. These are by default not shown in the private
2172 action table, but you can make them visible with a config parameter.
2173
2174     MyApp->config->{show_internal_actions} = 1;
2175
2176 =head1 CASE SENSITIVITY
2177
2178 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2179 mapped to C</foo/bar>. You can activate case sensitivity with a config
2180 parameter.
2181
2182     MyApp->config->{case_sensitive} = 1;
2183
2184 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2185
2186 =head1 ON-DEMAND PARSER
2187
2188 The request body is usually parsed at the beginning of a request,
2189 but if you want to handle input yourself or speed things up a bit,
2190 you can enable on-demand parsing with a config parameter.
2191
2192     MyApp->config->{parse_on_demand} = 1;
2193
2194 =head1 PROXY SUPPORT
2195
2196 Many production servers operate using the common double-server approach,
2197 with a lightweight frontend web server passing requests to a larger
2198 backend server. An application running on the backend server must deal
2199 with two problems: the remote user always appears to be C<127.0.0.1> and
2200 the server's hostname will appear to be C<localhost> regardless of the
2201 virtual host that the user connected through.
2202
2203 Catalyst will automatically detect this situation when you are running
2204 the frontend and backend servers on the same machine. The following
2205 changes are made to the request.
2206
2207     $c->req->address is set to the user's real IP address, as read from
2208     the HTTP X-Forwarded-For header.
2209
2210     The host value for $c->req->base and $c->req->uri is set to the real
2211     host, as read from the HTTP X-Forwarded-Host header.
2212
2213 Obviously, your web server must support these headers for this to work.
2214
2215 In a more complex server farm environment where you may have your
2216 frontend proxy server(s) on different machines, you will need to set a
2217 configuration option to tell Catalyst to read the proxied data from the
2218 headers.
2219
2220     MyApp->config->{using_frontend_proxy} = 1;
2221
2222 If you do not wish to use the proxy support at all, you may set:
2223
2224     MyApp->config->{ignore_frontend_proxy} = 1;
2225
2226 =head1 THREAD SAFETY
2227
2228 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2229 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2230 believe the Catalyst core to be thread-safe.
2231
2232 If you plan to operate in a threaded environment, remember that all other
2233 modules you are using must also be thread-safe. Some modules, most notably
2234 L<DBD::SQLite>, are not thread-safe.
2235
2236 =head1 SUPPORT
2237
2238 IRC:
2239
2240     Join #catalyst on irc.perl.org.
2241
2242 Mailing Lists:
2243
2244     http://lists.rawmode.org/mailman/listinfo/catalyst
2245     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2246
2247 Web:
2248
2249     http://catalyst.perl.org
2250
2251 Wiki:
2252
2253     http://dev.catalyst.perl.org
2254
2255 =head1 SEE ALSO
2256
2257 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2258
2259 =head2 L<Catalyst::Manual> - The Catalyst Manual
2260
2261 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2262
2263 =head2 L<Catalyst::Engine> - Core engine
2264
2265 =head2 L<Catalyst::Log> - Log class.
2266
2267 =head2 L<Catalyst::Request> - Request object
2268
2269 =head2 L<Catalyst::Response> - Response object
2270
2271 =head2 L<Catalyst::Test> - The test suite.
2272
2273 =head1 CREDITS
2274
2275 Andy Grundman
2276
2277 Andy Wardley
2278
2279 Andreas Marienborg
2280
2281 Andrew Bramble
2282
2283 Andrew Ford
2284
2285 Andrew Ruthven
2286
2287 Arthur Bergman
2288
2289 Autrijus Tang
2290
2291 Brian Cassidy
2292
2293 Carl Franks
2294
2295 Christian Hansen
2296
2297 Christopher Hicks
2298
2299 Dan Sully
2300
2301 Danijel Milicevic
2302
2303 David Kamholz
2304
2305 David Naughton
2306
2307 Drew Taylor
2308
2309 Gary Ashton Jones
2310
2311 Geoff Richards
2312
2313 Jesse Sheidlower
2314
2315 Jesse Vincent
2316
2317 Jody Belka
2318
2319 Johan Lindstrom
2320
2321 Juan Camacho
2322
2323 Leon Brocard
2324
2325 Marcus Ramberg
2326
2327 Matt S Trout
2328
2329 Robert Sedlacek
2330
2331 Sam Vilain
2332
2333 Sascha Kiefer
2334
2335 Tatsuhiko Miyagawa
2336
2337 Ulf Edvinsson
2338
2339 Yuval Kogman
2340
2341 =head1 AUTHOR
2342
2343 Sebastian Riedel, C<sri@oook.de>
2344
2345 =head1 LICENSE
2346
2347 This library is free software, you can redistribute it and/or modify it under
2348 the same terms as Perl itself.
2349
2350 =cut
2351
2352 1;